*comment ñáéç
*temp combat
*set combat 0
*set combat +(fighting*1.5)
*set combat +strength
*set combat +agility
*if shapeshifting = 3
	*set combat +2
	*goto city_screen
*if shapeshifting > 3
	*set combat +4
	*goto city_screen
*else
	*goto city_screen

*label city_screen 
*set recent_misdeed -1
*set progression_in_time +1
*if Blood > 15
	*set blood 15
	*goto city_screen_2
*if Blood <= 15
	*goto city_screen_2

*label city_screen_2
*set Blood -1
*if Blood = 0
	I'm out of blood.
	*page_break
	The hunger is too great... I cannot control it.
	*page_break
	I am covered with blood.  There is a dead body before me... I don't recognize him.  I am full, but now I must flee...
	*set Blood +10
	*set Compassion %+10
	*set Exposure +1
	*set recent_misdeed 3
	*set Wealth +25
	*goto city_screen
*if Blood > 0
	*goto city_screen_3

*label city_screen_3
*if exposure > 15
	*goto execution_by_quaestor
*if exposure <= 15
	*goto city_screen_4

*label city_screen_4	
*if exposure > 10 
	*if (status > 2) and (savedbyquaestor = false)
		A 'messenger' from the Quaestor has come to fetch me.
		*page_break
		The Quaestor informs you icily that you have been drawing too much attention to yourself.  Because of your stature, he offers to help you, but warns that this is the limit of his generosity.
		*set exposure -3
		*set savedbyquaestor true
		*goto city_screen
	*elseif (presented_boston) and (helpedbyquaestor = false)
		
		A 'messenger' comes from the Quaestor.  My presence is 'requested'.
		*page_break
		The Quaestor clearly expresses his displeasure at how you have been drawing attention to yourself lately.
		*choice
			*selectable_if (wealth > 25000)	#Offer to compensate the Quaestor, immediate-like.
				*set wealth -25000
				*set exposure -3
				*set discretion %-5
				*set helpedbyquaestor true
				*goto city_screen
			*selectable_if (income > 250) #Offer the Quaestor a portion of my income.
				*set income -250
				*set exposure -3
				*set discretion %-5 
				*set helpedbyquaestor true 
				*goto city_screen 
			*selectable_if (bloodflow > 0) #Offer the Quaestor a portion of my bloodflow.
				*set bloodflow -1
				*set exposure -3
				*set discretion %-5 
				*set helpedbyquaestor true 
				*goto city_screen 
			#I have nothing to offer him at this time.
				The Quaestor is clearly disappointed by your shortcomings:  "I fear you are not long for this world.  Be warned, though... if you draw too much attention to yourself, I will have to do the deed myself.  And you do not want to know the sort of end to which I will subject you."
				*set helpedbyquaestor true 
				*set discretion %-5 
				*goto city_screen
	*elseif presented_boston and helpedbyquaestor
		TODO
		*goto_scene scoring
	*else
		TODO
		*goto_scene scoring
*else
	*set Blood +bloodflow
	*set Wealth +(income*10)
	*if income = 0 
		*set bank_refinance 0
	*goto city_screen_5

*label city_screen_5
	
The city spreads out before you, unfolding in space and time.  Eternity is yours.  What will you do with it? 

*set blood round(blood)
Your current blood supply: ${Blood}
*line_break
*set bloodflow round(bloodflow)
Your current blood-flow: ${bloodflow}
*line_break
*set income round(income)
Your current income: ${income}
*line_break
*set wealth round(wealth)
Your current wealth: ${wealth}

*choice
	*if bank_ctrl = 3
		#Bank.  Wainwright Bank & Trust.  When I say 'Jump!' they say 'How high?'
			*goto_scene bank 
	*if bank_ctrl = 2
		#Bank.  Wainwright Bank & Trust.
			*goto_scene bank 
		*if bankdirectorappt
			#I have an appointment with Mr. Warner of Wainwright Bank & Trust.
				*set bankdirectorappt false
				*goto bank_3_appt 
	*if bank_ctrl = 1
		#Bank.  Maybe this Winston fellow I've heard so much about is in today...
			*rand bankmanagerpresence 1 10
			*goto_scene bank 
	*if bank_ctrl = 0
		#Bank.  Wainwright Bank & Trust is a locally owned bank... just the sort of place that will respond well to my patronage.
			*goto_scene bank
	*if bar_ctrl = 3 
		#Bar.  The Flatiron is calling to me!
			*rand exposurerisk 1 10 
			*if Stealth > 2
				*set exposurerisk +1
			*if Stealth > 0
				*set exposurerisk +1
			*if anachronism < 40
				*set exposurerisk -1
			*goto_scene bar
	*if bar_ctrl = 2
		#Bar.  The Flatiron is calling to me.
			*rand exposurerisk 1 10
			*if Stealth > 2
				*set exposurerisk +1
			*if Stealth > 0
				*set exposurerisk +1 
			*if anachronism < 40
				*set exposurerisk -1
			*goto_scene bar 
		*if bardirectorappt
			#Call on Joel.  You want a stake in his business.
				*set bardirectorappt false
				*goto bar_3_appt
	*if bar_ctrl = 1
		#Bar.  Take a turn by the Flatiron.
			*rand barmanagerpresence 1 10
			*rand exposurerisk 1 10 
			*if Stealth > 2
				*set exposurerisk +1
			*if Stealth > 0
				*set exposurerisk +1
			*if anachronism < 40
				*set exposurerisk -1
			*goto_scene bar
	*if bar_ctrl = 0
		#Bar.  Drop by a bar.  Maybe it's time to feed? 
			*rand exposurerisk 1 10 
			*if Stealth > 2
				*set exposurerisk +1
			*if Stealth > 0
				*set exposurerisk +1
			*if anachronism < 40
				*set exposurerisk -1				
			*goto_scene bar 
	*if church_ctrl = 3 
		#Church.  The belltower of the Cathedral of the Holy Cross beckons!
			*goto_scene church
	*if church_ctrl = 2
		#Church.  The belltower of the Cathedral of the Holy Cross beckons.
			*goto_scene church 
	*if church_ctrl = 1
		#Church.  The deacon of the Cathedral of the Holy Cross will welcome you.
			*goto_scene church 
	*if church_ctrl = 0
		#Church.  There is a magnificent Cathedral on the South End...
			*goto_scene church 
	*if shelter_ctrl = 3 
		#Homeless Shelter.  The Pine Street Inn is waiting for me.
			*goto_scene shelter 
	*if shelter_ctrl = 2
		#Homeless Shelter.  The Pine Street Inn is waiting for me.${empty}${empty}
			*goto_scene shelter 
	*if discretion < 80
		*if shelter_ctrl = 1
			#Homeless Shelter.  The Pine Street Inn is waiting for me.${empty}${empty}${empty}
				*rand shelterdirectorpresence 1 10
				*goto_scene shelter 
	*if discretion < 80
		*if Streetwise > 0
			*if shelter_ctrl = 0
				#Homeless Shelter.  I've heard of a place called the Pine Street Inn down on Southside... the pickings should be easy there.
					*goto_scene shelter 
	*if hospital_ctrl = 3
		#Hospital.  Boston Medical Center calls to you...
			*goto_scene hospital 
	*if hospital_ctrl = 2
		#Hospital.  What would it take to gain some real control over the Medical Center?
			*goto_scene hospital 
	*if hospital_ctrl = 1
		#Hospital.  Maybe Marisol could introduce you to some of the doctors?
			*goto_scene hospital 
	*if hospital_ctrl = 0
		#Hospital.  Boston Medical Center is a significant medical complex on the south side of town....
			*goto_scene hospital
	*if library_ctrl = 3
		#Library. It is like your own private fief.
			*goto_scene library
	*if library_ctrl = 2
		#Library.  Time to drop in and see Marge. 
			*goto_scene library 
	*if library_ctrl = 2
		*if librarydirectorappt
			#Time to call on the Treasurer for the Library's Board of Directors.
				*set librarydirectorappt false 
				*goto library_3_appt    
	*if library_ctrl = 1
		#Library.  There are so many things to read...
			*rand librarianpresence 1 10 
			*goto_scene library 
	*if library_ctrl = 0
		#Library.  Maybe you can learn something useful?
			*goto_scene library 
	*if library_li_date_accepted
		*if wealth > 100
			#Call on Jamal to go visit the haunted house. 
				*set library_li_date_accepted false
				*goto library_date
	*if library_li_bribe
		*if uni_ctrl > 1
			#It's time to drop by the Sociology department.  Clearly, I need to have words with Jamal's professor. 
				*goto library_li_bribe_scene
	*if library_li = 3
		*if compassion < 60
			#It's time to revel yourself to ${lover_name}!
				*set library_li_present false
				*goto the_big_reveal_yes
	*if library_li = 3
		*if compassion >= 60
			#It's time to revel yourself to ${lover_name}. 
				*set library_li_present false 
				*goto the_big_reveal_no 
	*if museum_ctrl = 3 
		#Museum.  The Museum of Fine Arts is reputed to have some amazing exhibits.
			*rand boston_quaestor_presence 1 10 
			*goto_scene museum 
	*if museum_ctrl = 2 
		#Museum.  The Museum of Fine Arts is reputed to have some amazing exhibits.${empty}
			*rand boston_quaestor_presence 1 10 
			*goto_scene museum 
	*if museum_ctrl = 1 
		#Museum.  The Museum of Fine Arts is reputed to have some amazing exhibits.${empty}${empty}
			*rand boston_quaestor_presence 1 10 
			*rand curatorpresence 1 10
			*goto_scene museum
	*if museum_ctrl = 0 
		#Museum.  The Museum of Fine Arts is reputed to have some amazing exhibits.${empty}${empty}${empty}
			*rand boston_quaestor_presence 1 10
			*goto_scene museum
	#Newbury St.  A fashionable street that serves as a shopping and dining destination.
		*rand exposurerisk 1 10
		*if Stealth > 2
			*set exposurerisk +1
		*if Stealth > 0
			*set exposurerisk +1
		*if anachronism < 40
			*set exposurerisk -1
		*goto_scene newbury
	*if news_ctrl = 3
		#Newspaper.  The Boston Globe is the paper of record for this city.${empty}${empty}${empty}
			*goto_scene newspaper
	*if news_ctrl = 2
		#Newspaper.  The Boston Globe is the paper of record for this city. 
			*goto_scene newspaper 
	*if news_ctrl = 2
		*if editorappt
			#It's time to call on the editor-in-chief of the Globe.
				*set editorappt false
				*goto news_3_appt
	*if news_ctrl = 1
		#Newspaper.  The Boston Globe is the paper of record for this city.${empty}${empty}
			*rand editorpresence 1 10
			*goto_scene newspaper 
	*if news_ctrl = 0
		#Newspaper.  The Boston Globe is the paper of record for this city.${empty}
			*goto_scene newspaper 
	*if wealth > 100
		*if news_li_date_accepted = "museum"
			#Time to arrange that tour of the museum for Lisa.
				*set news_li_date_accepted false
				*goto news_date_museum 
	*if wealth > 100
		*if news_li_date_accepted = "ap"
			#Time to take Lisa to Adventureland!
				*set news_li_date_accepted false
				*goto news_date_ap
	*if wealth > 100
		*if news_li_date_accepted = "theater"
			#Tonight is the night of my date with Lisa at the Charles Playhouse.
				*set news_li_date_accepted false
				*goto news_date_theater 
	*if news_li_bribe
		*if police_ctrl > 1
			#Have Saul arrested.  He already has a record, so that should put him away for a good while. 
				*goto news_li_bribe_scene_police 
	*if news_li_bribe
		*if ch_ctrl = 3 
			#Have a warrant issued for Saul's arrest.  He already has a record, so that should put him away for a good while. 
				*goto news_li_bribe_scene_ch
	*if news_li_bribe
		*if psych_ctrl = 3
			#Have Saul committed to the psych institute.  Once there, I can arrange for his paperwork to be lost and it'll be years before he's released.
				*goto news_li_bribe_scene_psych
	*if news_li_bribe
		*if compassion > 40
			#I'll deal with Saul myself.
				*goto news_li_bribe_scene_personal
	*if news_li = 3
		*if compassion < 60
			#It's time to revel myself to Lisa. 
				*set news_li_present false
				*goto the_big_reveal_yes
	*if news_li = 3			
		*if compassion >= 60
			#It's time to revel myself to Lisa! 
				*set news_li_present false 
				*goto the_big_reveal_no 
	*if police_ctrl = 3
		#Police Department.${empty}${empty}${empty}
			*goto_scene police
	*if police_ctrl = 2
		#Police Department.${empty}${empty}
			*goto_scene police 
	*if discretion > 40 
		*if police_ctrl = 1
			#Police Department.${empty}
				*rand captainpresence 1 10
				*goto_scene police 
	*if discretion > 40
		*if police_ctrl = 0
			#Police Department.
				*goto_scene police 
	*if psych_ctrl = 0
		#Psychiatric Ward at the Massachusetts Mental Health Center, a home away from home for the "insane".
			*goto_scene psych
	*if slum_ctrl = 3
		#Slums. While the feeding may be easy, it's not because the people there are friendly.${empty}${empty}${empty}
			*rand exposurerisk 1 10
			*if Stealth > 2
				*set exposurerisk +1
			*if Stealth > 0
				*set exposurerisk +1
			*if anachronism < 40
				*set exposurerisk -1
			*goto_scene slum 
	*if slum_ctrl = 2
		#Slums. While the feeding may be easy, it's not because the people there are friendly.${empty}${empty}
			*rand exposurerisk 1 10
			*if Stealth > 2
				*set exposurerisk +1
			*if Stealth > 0
				*set exposurerisk +1
			*if anachronism < 40
				*set exposurerisk -1
			*goto_scene slum 
	*if slum_ctrl = 1
		#Slums. While the feeding may be easy, it's not because the people there are friendly.${empty}
			*rand exposurerisk 1 10
			*if Stealth > 2
				*set exposurerisk +1
			*if Stealth > 0
				*set exposurerisk +1
			*if anachronism < 40
				*set exposurerisk -1
			*goto_scene slum 
	*if slum_ctrl = 0
		#Slums.  While the feeding may be easy, it's not because the people there are friendly.
			*rand exposurerisk 1 10
			*if Stealth > 2
				*set exposurerisk +1
			*if Stealth > 0
				*set exposurerisk +1
			*if anachronism < 40
				*set exposurerisk -1
			*goto_scene slum 
	*if rationalism < 85
		*if theater_ctrl = 3
			#Theater.  Take in a play at the Charles Playhouse. 
				*goto_scene theater
	*if rationalism < 85
		*if theater_ctrl = 2
			#Theater.  Take in a play at the Charles Playhouse.${empty}
				*goto_scene theater 
			*if theaterdirectorappt
				*goto theater_3_appt
	*if rationalism < 85
		*if theater_ctrl = 1
			#Theater.  I bet Daniel would love to tell me about how he pulled off those pyrotechnics during the last show... 
				*rand dramaturgepresence 1 10
				*goto_scene theater 
	*if rationalism < 85
		*if theater_ctrl = 0
			#Theater.  Take in a play at the Charles Playhouse.${empty}${empty}
				*goto_scene theater 
	*if rationalism < 85
		*if theater_li_date_accepted
			#Meet Serena at the Pine Street Inn.
				*set theater_li_date_accepted false
				*goto theater_date
	*if rationalism < 85
		*if theater_li_bribe
			*if Stealth > 2
				#I need to drop by Boston Medical Center and see about Serena's father.  My powers of Stealth are such that they'll never even know I was there.
					*goto theater_li_bribe_scene_mis
	*if rationalism < 85
		*if theater_li_bribe				
			*if hospital_ctrl > 1
				*if Perception > 2 
					*if Wealth > 2500 
						#I'll identify a nurse and bribe her to deliver a lethal dose of morphine to Serena's father, and then use my connections to make sure there is no investigation.
							*set Wealth -2500 
							*goto theater_li_bribe_scene_infl 
	*if rationalism < 85
		*if theater_li_bribe				
			*if hospital_ctrl > 1
				*if Perception > 2
					*if Charm > 3 
						#I'll identify a nurse and convince her to deliver a lethal dose of morphine to Serena's father, and then use my connections to make sure there is no investigation.
							*goto theater_li_bribe_scene_infl 
	*if rationalism < 85
		*if theater_li = 3 
			*if compassion < 60
				#It's time to revel myself to ${lover_name}. 
					*set theater_li_present false
					*goto the_big_reveal_yes
			*if compassion >= 60
				#It's time to revel myself to ${lover_name}. 
					*set theater_li_present false 
					*goto the_big_reveal_no 
	*if uni_ctrl = 3
		#University. 
			*goto_scene university
	*if uni_ctrl = 2
		#University.  I wonder if I'm beginning to feel too comfortable there... 
			*goto_scene university 
	*if uni_ctrl = 2
		*if uniregentappt
			#I'd like to call on the University Regent that Bradley the dean was so kind as to phone for me.
				*set uniregentappt false 
				*goto uni_3_appt 
	*if uni_ctrl = 1
		#University.  May I'll run into Bradley the dean. 
			*rand deanpresence 1 10 
			*goto_scene university
	*if uni_ctrl = 0
		#University.  Maybe I can learn something useful. 
			*goto_scene university
	*if lore > 0
		*if speaks_english
			*if occult_ctrl = 3
				#Ye Olde Magick Shoppe.
					*goto_scene occult 
	*if lore > 0
		*if speaks_english
			*if occult_ctrl = 2 
				#Ye Olde Magick Shoppe.${empty}
					*goto_scene occult
	*if lore > 0
		*if speaks_english
			*if occult_ctrl = 1
				#Ye Olde Magick Shoppe.${empty}${empty}
					*goto_scene occult
	*if lore > 0
		*if speaks_english
			*if occult_ctrl = 0
				#Ye Olde Magick Shoppe.  Drop by the local 'occult' bookstore. 
					*goto_scene occult 
	*if Status > 2 
		*if accepted_by_lover
			#Ask the Quaestor if I can bestow the Gift upon ${lover_name}.
				*goto permission_to_sire_lover
	*if accepted_by_lover 
		#It is time.  I am ready to offer the Gift to ${lover_name}. 
			*goto embrace_lover 
	*if Anachronism < 50
		*if Lore > 2
			#Retirement.  I'm happy with my place in the world.  It is time to slip into a slumber for the ages.  Perhaps there will be a time when I will find myself relevant.  Until then, I will sleep, perchance to dream.
				*set torpor true
				*goto torpor 
	*if Anachronism < 30
		*if Willpower > 3
			#Greet the dawn.  Time has passed me by.  The days are long and the nights are short and I have no more desire to exist as a cursed being in this world.
				*goto suicide
	*if lovermurdered
		*if Willpower > 3
			#Greet the dawn.  I have no more desire to live, now that my love is gone.
				*goto suicide 

*label bank_3_appt

Bank 3 appt.

*goto city_screen

*label bar_3_appt 

Joel has an office above a laundromat.  The stink of the chemicals permeates the place.  He doesn't keep you waiting for long. 

When you enter, you are struck by the fact that Joel is a big dude.  Both literally and figuratively.  He's surely connected, if you know what I mean.  Thanks to Benny's good word, he's willing to give you a few minutes of his time. 

*choice 
	*if Wealth > 10000 
		#Offer to buy-in for $10000. 
			*set bar_ctrl +1 
			*set income +250
			*set Wealth -10000
			*goto city_screen 
	*if Charm > 5 
		#I sweetly inform Joel that I would like a piece of the action.  It will be to his benefit, anyway. 
			*set bar_ctrl +1 
			*set income +250 
			*set discretion %+2 
			*goto city_screen 
	*if police_ctrl = 3
		#"You know, Joel, it'd be a real shame if the police started aggressively testing you with underage drinkers."  
			*set bar_ctrl +1 
			*set discretion %+2
			*set income +250
			*goto city_screen 
	*if Fighting > 3
		*if Strength > 3
			*if Wealth > 1000
				#I make it known that I want a piece of the pie.  I'm willing to pay for it, but he's going to give me a real fair price.
					*set bar_ctrl +1
					*set income +250
					*set discretion %+10
					*set Wealth -1000
					*goto city_screen
	#Talk about the weather. 
		Joel seems less than amused.
		*goto city_screen 

*label library_date 

After an hour or two on the highway, you turn off onto a rural route through one of those nigh-colonial communities that dot the Massachusetts countryside.  You arrive at the 'haunted house,' well prepared for the evening.  You take him on a tour of the crumbling building, and when his eyes are filled most with wonder, you take him. 

It's clear that he's never been fed on before.  He is clearly disoriented afterwards.  It is, in your opinion, a ravishing experience.  His blood is like fireworks on your throat.  It is, in fact, so delicious that you have a hard time pulling yourself back from the edge... only barely managing to do so. 

Before the night is over, you return him to his home after feeding him and making sure there will be no permanent repercussions to your blood-orgy. 

*choice 
	#Dawn is coming soon.
		*set Blood +3 
		*set library_li +1 
		*set Wealth -100 
		*goto city_screen 

*label library_li_bribe_scene 

It doesn't take much to arrange for a meeting with Jamal's professor.  In fact, by the time you actually come face to face with the woman, she is quaking in her pumps.  You set her straight about Jamal's abilities, and look forward to sharing the good news with him. 

*choice 
	#I head home with a smile on my face.
		*set lover_name "Jamal"
		*set lover_nom_pro "He"
		*set lover_acc_pro "him"
		*set lover_nom_pro_l "he"
		*set lover_pos_pro "his"
		*set lover_claimed true
		*set library_li +1
		*set library_li_present false 
		*set lovers_claimed +1
		*goto city_screen

*label library_3_appt 

The meeting arranged, you head over to a less-than-impressive office to meet with the Library's Treasurer, Terrence Jacobs. 

Terrence Jacobs, esq. is a weaselly lawyer who is probably embezzling from what little funding the city and state direct towards the Library's foundation.  However, no one else apparently wanted the job.  That said, he seems supremely interested in using what little influence he has to acquire anything he can get for himself. 

*choice 
	*if cc_ctrl = 3
		#After some light conversation, I realize that Mark is desperate to join the local country club.  Convenient, that.  A simple call and his membership is assured.
			*set library_ctrl +1
			*goto city_screen
	*if court_ctrl = 3
		#You know, considering your pull at the courthouse, it would be very unfortunate if Mr. Jacobs was subjected to an ethics review.  They're such nasty little inquests, after all.
			*set library_ctrl +1
			*goto city_screen 
	*if Wealth > 5000
		#Offer to make a substantial donation to Mr. Jacobs' private charity foundation.
			*set library_ctrl +1
			*set Wealth -5000
			*goto city_screen 
	*if Charm > 5
		#"Really, Mr. Jacobs, you should just give me a seat on the board of directors."
			Mr. Jacobs smiles almost vacantly at your radiant presence.  A few signatures and the whole matter is taken care of.
			*set library_ctrl +1
			*set discretion %+2 
			*goto city_screen
	#Talk about the weather. 
		*set librarydirectorappt false
		*goto city_screen 

*label news_date_ap 

A private romp through Adventureland is definitely an ostentatious first date.  That said, Lisa is clearly swept off her feet.  While atop the Ferris wheel, you lean in to introduce her to real pleasure... 

*choice 
	#Dawn is coming soon.
		*set Blood +3 
		*set news_li +1 
		*set Wealth -100 
		*goto city_screen 

*label news_date_museum 

She is clearly thrilled to be seeing the items that aren't on display.  It evokes a since of conspiracy to be able to see and touch things that are normally carefully supervised at all times.  Not that she goes around touching the paintings, but there's a proximity to the works that she's never experienced before. 

Standing in front of a Van Gogh undergoing restoration, you catch her eye and move in for the taste... 

*choice 
	#Dawn is coming soon.
		*set Blood +3 
		*set news_li +1 
		*set Wealth -100 
		*goto city_screen 

*label news_date_theater 

The performance is mediocre, but you're able to laugh about it afterwards.

*choice 
	#Dawn is coming soon.
		*set Blood +3 
		*set news_li +1 
		*set Wealth -100 
		*goto city_screen 

*label news_li_bribe_scene_police 

You place a call to Frank, letting him know about Saul's problem and indiscretions.  Frank promises that he'll take care of immediately.

A few days later, Frank calls you back to inform you that Saul has been arrested, and was found to be in possession of a variety of illegal drugs.  Further, he was not able to post bail. 
*page_break 

You meet up with Lisa at her work, to share the good news with her.  She collapses into your arms, sobbing in gratitude.
*choice 
	#I head home with a smile on my face.
		*set lover_name "Lisa"
		*set lover_nom_pro "She"
		*set lover_acc_pro "her"
		*set lover_nom_pro_l "she"
		*set lover_pos_pro "her"
		*set lover_claimed true
		*set news_li +1
		*set news_li_present false 
		*set lovers_claimed +1
		*goto city_screen 

*label news_li_bribe_scene_ch 

You place a call to Judge Parsons, letting him know about Saul's problem and indiscretions.  He says that he'll issue a warrant and have the police execute it immediately.

A few days later, Larry calls you back to inform you that Saul has been arrested, and was found to be in possession of a variety of illegal drugs.  Further, he was not able to post bail. 
*page_break 

You meet up with Lisa at her work, to share the good news with her.  She collapses into your arms, sobbing in gratitude. 

*choice 
	#I head home with a smile on my face.
		*set lover_name "Lisa"
		*set lover_nom_pro "She"
		*set lover_acc_pro "her"
		*set lover_nom_pro_l "she"
		*set lover_pos_pro "her"
		*set lover_claimed true
		*set news_li +1
		*set news_li_present false 
		*set lovers_claimed +1
		*goto city_screen 

*label news_li_bribe_scene_psych 

You put down the phone and shiver.  You may be a soulless predator, but the voice of Phoebe Marshall sends a shiver down your spine.  She arranges for a temporary admission for Saul... apparently he's threatened suicide.  Hadn't you heard? 

Once in the system, Dr. Marshall arranges for his documents to be confused and misplaced, and without anyone on the outside to advocate for him, he disappears into the system. 
*page_break 

You meet up with Lisa at her work, to share the good news with her.  She collapses into your arms, sobbing in gratitude. 

*choice 
	#I head home with a smile on my face.
		*set lover_name "Lisa"
		*set lover_nom_pro "She"
		*set lover_acc_pro "her"
		*set lover_nom_pro_l "she"
		*set lover_pos_pro "her"
		*set lover_claimed true
		*set news_li +1
		*set news_li_present false 
		*set lovers_claimed +1
		*goto city_screen 

*label news_li_bribe_scene_personal 

You locate Saul's home in the slums, and begin staking it out.  He's about 5'9" and heavily muscled... it looks almost comical if it weren't clear that he may very well pose a threat to you.  The question is, how will you deal with him? 

*choice 
	*if discretion < 60
		#Lay in wait, and then put an end to his miserable existence. 
			*if (stealth > 1) and (combat >= 5)
				You knock him unconscious with a sock to the jaw.
				*goto saul_killed
			*else
				*if combat >= 7
					Unfortunately, you are not quite as subtle as you might wish.  Fortunately, however, the lack of surprise does not weigh to heavily against you.  Despite Saul's 'roid-fueld rage, you are able to carry the day.
					*goto saul_killed
				*elseif combat <= 4
					Unfortunately, you are not quite as subtle as you might wish.  
					*goto killed_by_saul
				*else
					While you manage to land the first blow, he pulls a knife on you and jams it into your gut.  Only when you unleash the animal inside you are you able to fend him off enough to run away. 
					*set blood -3
					*set exposure +1
					*goto city_screen
	*if fighting > 0
		#In some fit of chivalry--or perhaps arrogance--I challenge him to a knife duel.
			*set discretion %+10
			*if combat >= 8
				Conveniently, Saul has his own knife already.  Despite his amped-up muscles and pharmaceutically-induced rage, you make quick work of him.
				*goto saul_killed
			*else
				*goto killed_by_saul
	#In some fit of chivalry--or perhaps arrogance--I challenge him to a sort of fisticuffs.
		*set discretion %+10
		*if combat >= 8
			Despite his amped-up muscles and pharmaceutically-induced rage, you make quick work of him.
			*goto saul_killed
		*else
			*goto killed_by_saul
	#Reconsider.  This is too dangerous.
		Lisa's body turns up in the reservoir a few days later.  But she was just a piece of meat anyway.
		*set discretion %-5
		*set compassion %+5
		*set lisamurdered true
		*set news_li_present false
		*goto city_screen

*label saul_killed
*choice 
	#Feed on him.
		*set Blood +10
		*set discretion %+5
		You dump his drained body into the reservoir.
		*goto news_li_bribe_resolution
	#Raid his home.
		*set Wealth +1000
		*set discretion %+5
		You dump his corpse into the reservoir after you rifle through his home for valuables.
		*goto news_li_bribe_resolution 
	#Feed on him and raid his home.
		*set Wealth +1000 
		*set Blood +10
		*set discretion %+5 
		You dump his drained body into the reservoir after you rifle through his home for valuables.
		*goto news_li_bribe_resolution 
	#Leave well enough alone. 
		*set discretion %+5
		You dump his corpse into the reservoir.
		*goto news_li_bribe_resolution

*label killed_by_saul 
His steroid-fueled rage overwhelms you, and he tears you limb from limb.

It's hard for you to believe it, but this mortal has bested you.  After cutting you several times with his knife, he smashes a nearby oilcan over you and sets you alight.  Only then does he even have an inkling that he has killed something more than human. 

Luckily for your fellow vampires, all you leave is an ashen mess on the cement walkway to his door. 

*set killedbymortal true
*goto_scene scoring 

*label news_li_bribe_resolution 

Lisa seems shaken when you come to her with the 'good' news.  She knew that something about you was... predatory, but murder? 

*choice 
	#Dawn is coming soon.
		*set lover_name "Lisa"
		*set lover_nom_pro "She"
		*set lover_acc_pro "her"
		*set lover_nom_pro_l "she"
		*set lover_pos_pro "her"
		*set lover_claimed true
		*set news_li +1
		*set news_li_present false 
		*set lovers_claimed +1 
		*goto city_screen

*label news_3_appt 

The editor-in-chief, never much of one for the office, invites you to meet him at the State Room, a steak-house and bar downtown.  

*choice 
	*if charm > 5
		#Inform him of how fortunate he is to have made your acquaintance.
			*set news_ctrl +1
			*goto city_screen
	*if radio_ctrl > 1
		#"I've been reading your op-eds, I thought you might be due for a weekly radio spot..."
			*set news_ctrl +1
			*goto city_screen 
	*if uni_ctrl > 1
		*if wealth > 50000
			#"I was thinking about endowing a professorship in the journalism department at the university... of course, I need a paragon of journalistic ethics to name the professorship after..."
				*set news_ctrl +1
				*goto city_screen
	#Talk about the weather.
		*goto city_screen


*label theater_date 

Unexpected would be the watchword of the evening.  Both on your part and hers.  The individuals and families lined up along Harrison street are a sorry lot, but the children are absolutely entranced by Serena's princess-like demeanor.  For her part, though, Serena handles herself with grace and compassion.  You lose sight of her for a time while helping to clean up, and are only mildly surprised to later find her deep in conversation with a grizzled veteran. 

Her face lights up as you approach, and she introduces you to Hank.  Hank clearly doesn't like you, however.  His mutterings about beasts and cannibals gives you the impression that he can sense that, well, something is amiss about you.  But that is neither here nor there. 

You patiently guide Serena into a stroll down to the waterfront, where you stand quietly, watching the blinking lights.  The serenity of the place is only marred by your hunger for her blood. 

From this quiet interlude it is only a small step for you to sink your teeth into her neck.  She exhales exquisitely as your fangs pierce her skin. 

*choice 
	#Dawn is coming soon.
		*set theater_li +1
		*set Blood +3
		*goto city_screen 

*label theater_li_bribe_scene_mis 

It is, in truth, a simple matter to slip into the hospital.  It's a little more difficult to find a moment alone with Serena's father, but not beyond your means.  He is clearly in intense pain.  Machines fill the room with their beeping and flashing, each one a little reminder that a life is about to end. 

*choice 
	*if Anachronism > 80 
		#If I just adjust the settings on the morphine drip, he will, after a fashion, kill himself. 
			You press a few buttons, turn a nob, and presto, the machine will do the work for you.  You slip out the door to the sound of a long, slow exhale...
			*page_break

			Later, you call on Serena to give her the good news.  She is overjoyed, and falls sobbing into your arms, proclaiming her love for you. 
			*set lover_name "Serena"
			*set lover_nom_pro "She"
			*set lover_acc_pro "her"
			*set lover_nom_pro_l "she"
			*set lover_pos_pro "her"
			*set lover_claimed true
			*set theater_li +1
			*set theater_li_present false 
			*set discretion %-1
			*set compassion %-1
			*goto city_screen 
	*if Anachronism > 50 
		#All I need to do is 'borrow' a morphine injection from the nurse's station...

			You lift the syringe from the drawer, and head back to the room... 
			*page_break

			Later, you call on Serena to give her the good news.  She is overjoyed, and falls sobbing into your arms, proclaiming her love for you. 
			*set lover_name "Serena"
			*set lover_nom_pro "She"
			*set lover_acc_pro "her"
			*set lover_nom_pro_l "she"
			*set lover_pos_pro "her"
			*set lover_claimed true
			*set theater_li +1
			*set theater_li_present false 
			*set discretion %+1
			*set exposure +1 
			*goto city_screen 
	*if Compassion < 30
		#I just don't have the heart for this. 
			You leave Serena's father alone with the sound of the wheezing ventilators.
			*page_break

			You are too ashamed to ever see Serena again.  Whoever she is, she is not for you.
			*set theater_li_present false
			*set compassion %-10
			*goto city_screen
	#A pillow should do the trick nicely.
		He barely struggles as you put the pillow over his face.  There is not much life that needs smothering.

		*page_break
		Later, you call on Serena to give her the good news.  She is overjoyed, and falls sobbing into your arms, proclaiming her love for you. 
		*set lover_name "Serena"
		*set lover_nom_pro "She"
		*set lover_acc_pro "her"
		*set lover_nom_pro_l "she"
		*set lover_pos_pro "her"
		*set lover_claimed true
		*set theater_li +1
		*set theater_li_present false 
		*set discretion %+5
		*set compassion %+5
		*set exposure +1
		*goto city_screen 

*label theater_li_bribe_scene_infl 

You decide that you should arrange for the termination of Serena's father's life, rather than risk doing it yourself.  It's actually fairly easy to find a nurse that is willing to send him on his way peacefully.  It will be more difficult, however, covering up the nurse's activities to prevent any blowback on yourself. 

*choice 
	#I am confident in my connections.
		Once the nurse signals you her success, you call on Serena to give her the good news.  She is overjoyed, and falls sobbing into your arms, proclaiming her love for you.
		*set lover_name "Serena"
		*set lover_nom_pro "She"
		*set lover_acc_pro "her"
		*set lover_nom_pro_l "she"
		*set lover_pos_pro "her"
		*set lover_claimed true
		*set theater_li +1 
		*set theater_li_present false 
		*set lovers_claimed +1
		*set Blood +1
		*set discretion %-10
		*goto city_screen

*label theater_3_appt 

Mary McDonnell spares a moment for you between meetings in the theater conference room. 

*choice 
	*if charm > 5
		#My charm is irresistible.
			*set discretion %+2
			*set theater_ctrl +1
			*goto city_screen
	*if wealth > 10000
		#"I want to talk to you about a donation to the theater's operating fund..."
			*set wealth -10000
			*set theater_ctrl +1
			*goto city_screen
	#Talk about the weather.
		McDonnell is clearly annoyed at how you are wasting her time.
		*goto city_screen

*label uni_3_appt 

Getting your schedule to fit with Mrs. Samantha Walmsley is, unsurprisingly, difficult.  She comes from old, old money, and - so it is rumored - inherited the position on the Board of Regents from her father.  That said, she has a forceful personality and is more than capable of delivering on the fundraising front. 

After a few moments of discussing your recent move to Boston, she inquires as to the purpose of your visit. 

*choice 
	*if Charm > 5
		#"It's clear to me that you are a woman of discriminating taste..."
			You charm the skirt off of her.
			*set Blood +1
			*set uni_ctrl +1
			*set discretion %+2 
			*goto city_screen
	*if Wealth > 50000
		#"About that endowment drive..."
			*set Wealth -50000
			*set uni_ctrl +1
			*goto city_screen 
	*if Perception > 3
		*if news_ctrl > 0
			#"Mrs. Walmsley, it would be unfortunate if word of your daughter's unintended pregnancy were to find its way into the Monday papers."
				*set uni_ctrl +1
				*set compassion %+10
				*goto city_screen
	*if Perception > 3
		*if hospital_ctrl = 3
			#"Mrs. Walmsley, I understand your daughter is in medical distress.  I'm sure you would like the situation handled with discretion." 
				*set uni_ctrl +1
				*goto city_screen 
	*if Perception > 3
		*if rationalism > 70
			*if church_ctrl > 1
				#"This may seem a little old fashioned, Mrs. Walmsley, but there is a convent in the Berkshires.  Your troubled daughter could go there for the next nine months..."
					*set uni_ctrl +1 
					*goto city_screen                    
	#Talk about the weather. 
		Mrs. Walmsley is distinctly unimpressed. 
		*goto city_screen

*label the_big_reveal_yes

You summon ${lover_name} to you.  ${lover_nom_pro} meets you at your home, where you are waiting for ${lover_acc_pro} in your study, reading quietly. 

"The time has come.  There is much that we have to discuss, ${lover_name}.  But first, do you love me as I love you?" 

"I do," ${lover_nom_pro_l} replies.  "You are my life.  I would do anything for you." 

"That is good to hear.  Because what I am about to tell you, well, it will change your life... forever." 

"I am prepared." 

"You wondered once why you never saw me eat.  It is because I am no longer human.  Some two hundred years ago, my sire, ${sire_name}, turned me into a vampire. Whether it was a blessing or a curse, I still cannot say.  But tonight, I believe that it is, in fact, a blessing.  For tonight, I can say to you, ${lover_name}, that I have finally found my purpose.  I love you, I cannot exist without you.  I want to be with you forever." 

Your soliloquy continues in a similarly overwrought style for several minutes more, while ${lover_name} listens intently.  When you have finished speaking your mind, ${lover_nom_pro_l} replies: "The horror, the horror!  And yet, I cannot bring myself to turn from you, ${given_name}.  You have found your way into my life and into my heart, and it is too late to halt your advance!  I am yours, body and soul."  

*choice 
	#You feed on ${lover_name} to celebrate.
		*set Blood +3
		*set accepted_by_lover true
		*goto city_screen

*label the_big_reveal_no 

You summon ${lover_name} to you.  ${lover_nom_pro} meets you at your home, where you are waiting for ${lover_acc_pro} in your study, reading quietly. 

"The time has come.  There is much that we have to discuss, ${lover_name}.  But first, do you love me as I love you?" 

"Love you?  Love you!?  How could I love a creature such as yourself?  You are cruel and vicious.  You care only for yourself, and you would run an old woman into the ground if it meant getting your way..." 

${lover_name} does get the chance to finish his reply. 

*choice 
	#You are devastated.  Thankfully, ${lover_name}'s marrow is tasty.
		*set Blood +10
		*set Compassion %+15
		*set lover_claimed false
		*goto city_screen

*label embrace_scene 

Your nights have been bliss, while your days are spent in the arms of your lover.  You feel as though nothing can stop you.  Soon, however, it becomes clear to you that you must make a decision.  Your lover: will you Embrace him, or will you not?

The choice is one of agony.  To Embrace ${lover_acc_pro} is to bestow the undead thirst, to spend every night for eternity hunting mortals for their blood.  But to leave ${lover_acc_pro} mortal is to watch ${lover_acc_pro} grow old and die, while you remain unchanged. 

You have called ${lover_name} to your haven once again.

*choice 
	*if compassion < 35
		#This is a decision I should leave to ${lover_name}. 
			*goto lover_decides 
	#This is a decision I must make for ${lover_acc_pro}.
		*goto character_decides 

*label character_decides 

And so the moment is here.  ${lover_name} kneels before you, expectantly. 

*choice 
	#I pull ${lover_pos_pro} head back, exposing ${lover_pos_pro} throat.  Now is the time!
		*set Blood +2 
		*set lover_claimed false
		*goto lover_embraced
	#I push ${lover_acc_pro} away.  I cannot subject ${lover_acc_pro} to such an existence!
		*set Compassion %+10 
		*set lover_claimed false 
		*goto lover_rejected

*label lover_decides 

"Will you accept the Gift of eternal life, ${lover_name}?" 

"Yes!  Yes!  A thousand times, yes!" 

*choice 
	#It is time.  You draw back ${lover_pos_pro} head, exposing ${lover_pos_pro} throat... 
		*goto lover_embraced
	*if compassion < 15
		#I can't.  My conscience demands that I not subject another to the Eternal Hunger... 
			*goto lover_rejected
	*if rationalism > 75
		#I can't.  We are the rejects of heaven.  I cannot commit another to the fires of hell...
			*set compassion %-10
			*goto lover_rejected 

*label lover_embraced 

${lover_name} awakes the next evening in your arms.  ${lover_nom_pro} stretches luxuriously, and then opens ${lover_pos_pro} eyes wide: "I... I... hunger!" 

The night belongs to the two of you. 

*goto_scene loves_demise 

*label lover_rejected

Tears of blood stream down your face.  ${lover_name} clutches you, begging for you to change your mind, but it has been decided.  You cannot do this.  It would not be right.  But now another decision stares you in the face: what will you do with ${lover_acc_pro}? 

*choice 
	*if compassion > 50 
		#${lover_name} knows too much.  If ${lover_nom_pro_l} ever breathes a word of it... to anyone... your existence would be in extreme danger.  Better to resolve the issue now. 
			*set Blood +10 
			*set lovermurdered true
			*goto city_screen 
	#I will keep ${lover_acc_pro} by my side, until ${lover_nom_pro_l} turns to dust.
		In time, it becomes clear to you that you have made a mistake.  ${lover_name} changes, grows, evolves into someone new.  Such is the way of humans, after all.  But the more ${lover_nom_pro_l} changes, the more you stay the same.  Within a few years, you grow tired of the arguing.  ${lover_nom_pro} has grown jealous as your attentions have turned elsewhere.  And then one evening, you find that ${lover_name}'s skull makes for a handy goblet, from which to enjoy the blood of your newest toy.  Of course, if ${lover_name} had really really loved you, this wouldn't have happened.  
		*set compassion %+10
		*set anachronism %-5
		*set Blood +10
		*set lovermurdered true
		*goto city_screen
	#Better to have loved and lost... I think it would be best to send ${lover_acc_pro} away.  Another town.  Another life.  Only then will ${lover_nom_pro_l} be safe. 
		*set Exposure +1 
		*set Wealth -5000
		*set loverbanished true
		*goto city_screen

*label execution_by_quaestor

*goto_scene scoring

*label suicide 

You find your way to the top of one of the skyscrapers in downtown Boston.  The sun is rising soon.  You look out over the city, and muse upon the deeds of your undeath. 

*choice 
	#Yes, I really go through with it.
		You are at peace with your decision.  At first the light causes you intense pain, but before long, you begin to rejoice in the purifying effects of its rays.  The last the world hears of you is your laughter as a strong breeze spreads your ashes across the skyline.
		*set suicide true
		*goto_scene scoring
	#Perhaps there is another way.
		This cannot be the answer!  Your will to live overwhelms your will to die, and you flee from the roof, finding succor below the city's streets.  You will awake tonight, and seek out something more than this bleak ending.
		*goto city_screen

*label torpor 

You spend several days putting your affairs in order, so that when you are awoken decades hence, you will enjoy much the same in creature comforts.  Cliché though it may be, you have had a coffin prepared... the better to fend off the maggots that would grow fat on your immortal blood.  Looking down at your crimson rest, you pause briefly to consider... 

*choice 
	#Yes, it is time to sleep.
		Slipping into your bed, you feel the locking of the lid in your bones.  It is time to sleep, perchance to dream...
		*goto_scene scoring
	#Maybe I should think this through again.
		You resist the siren's song of the great slumber.  There are still worlds to conquer!
		*goto city_screen