*comment ñáéç
*temp combat
*set combat 0
*set combat +strength
*if shapeshifting > 3
	*set combat +4
*set combat +agility
*if shapeshifting = 3
	*set combat +2
*set combat +(fighting*1.5)

It is with great care that you slowly undo the inside latch on your travelling-coffin, and peer out into the warehouse.  It seems as though you have successfully been delivered to your destination.  Keeping a wary eye out for night watchmen, you push open the lid further and step onto the dirt floor.  Nearby you spot the other crate you sent, which contains your personal effects.  These too you retrieve quietly, and then you proceed to find an exit.

There's a door right over there, an exit from the warehouse.  You have been travelling for days, and are hungry for blood.

*if Perception > 0
	You can hear the faint coughing of someone on the other side.

How do you proceed?

*set blood -1
*choice
	*if Stealth > 2
		#Using my powers of stealth, I saunter right out the door, trusting in the fact that anyone on the other side will just ignore me.
			You have prepared yourself well for the challenges of undeath.  The watchman on the other side of the door looks right through you as you exit, blissfully unaware that death has just passed him by.
			*goto later_that_night
	*if shapeshifting > 3
		#I turn into a bat and fly out an exhaust in the roof of the warehouse.
			*set blood -1
			*goto later_that_night
	*if Perception > 4
		#I put sounds into his head, causing him to leave his post and ease my escape.
			The watchman shouts out a 'Who's there?' before cautiously heading around the corner of the building.  You quietly open the door and slip into the night.
			*goto later_that_night
	*if agility > 3
		#I try to find another exit... something higher up.  I'm an agile climber, I should be able to make it.
			*temp climb
			*rand climb 1 10
			*if agility = 5
				*set climb +1
			*if agility = 6
				*set climb +2
			*if agility = 7
				*set climb +3
			*if climb < 6
				*goto failed_climb
			*else
				You manage to make your way up into the rafters, from there through an open window, and thence to the ground below.  Not the cleanest exit you've ever made, but at least it was successful.
				*goto later_that_night
	#I open the door.  I'll deal with what's on the other side as necessary.
		*goto opened_door
		
*label failed_climb
*set blood -1

Halfway up the wall, you lose your hold on a rafter, and fall to the floor of the warehouse with a loud thud.  Immediately you hear a commotion outside, as the watchman throws open the door.  From where you are, there is no line of sight, so you have a moment to collect your thoughts and prepare a plan.

*choice
	*if Stealth > 1
		#I can sneak past him.
			While the watchman is exploring the warehouse, you slip past him and out the door.
			*goto later_that_night
	*if Stealth = 1
		#I think I can sneak past him.
			*temp sneak
			*rand sneak 1 10
			*if sneak > 5
				While the watchman is exploring the warehouse, you slip past him and out the door.
				*goto later_that_night
			*else
				He's discovered you!
				*goto fight_watchman
	*if agility > 3
		#It may come back to haunt me, but I will call upon my undead speed to run past him.
			*set blood -1
			*temp run
			*rand run 1 10
			*if agility = 5
				*set run +1
			*if agility = 6
				*set run +2
			*if agility = 7
				*set run +3
			*if run < 6
				*set exposure +1
			You can't be sure if he saw anything, but you certainly were a blur as you sped past him into the night.	
			*goto later_that_night
	#Ambush him.
		*if combat <= 6
			*goto fight_watchman
		*else
			With a quick blow to the back of his head, you knock him unconscious.
			*choice
				#While I'm here, I might as well feed.
					After a quick nip, you head out the door.
					*set blood +3
					*goto later_that_night
				#Or perhaps I'll just put an end to his miserable existence.
					You drain the man dry, and then clean your face on his ragged clothes.
					*set blood +10
					*set compassion %+20
					*set discretion %+5
					*goto later_that_night
			
*label fight_watchman

The watchman is staring out you, somewhat in disbelief.  His baton is at the ready.

*if speaks_german
	He yells out in German, "Stop!"
	*goto fight_watchman_german
*else
	He yells something out in German, but you can't understand him.
	*goto fight_watchman_2
	
*label fight_watchman_german

*choice
	*if charm > 2
		#I talk my way past him.
			Johann is very pleased to make your acquaintance, and suggests that you come back during normal business hours to collect your things next time.  He is very excited to find out you are German, even if your accent is a little archaic.
			*goto later_that_night
	#It is no matter.  I must put an end to him now that he has seen my face.
		*if combat <= 7
			*set exposure +1
			*set blood -1
			While you manage to land a few blows on him, he gives as good as he gets.  Seeing that this will not be decided immediately, he turns and runs, screaming for help.
			
			You decide it is probably better that you flee.  The chances of you taking him down before he draws further attention to you seems unlikely.
			*goto later_that_night
		*else
			His lifeless body slumps to the floor.  You bend to take a drink of his blood.  After all, waste not want not...
			*set compassion %+20
			*set blood +6
			*goto later_that_night
			
*label fight_watchman_2

He pulls back with the baton and lunges at you!

*if combat <= 6
	*set exposure +1
	*set blood -1
	While you manage to land a few blows on him, he gives as good as he gets.  Seeing that this will not be decided immediately, he turns and runs, screaming for help.
	
	You decide it is probably better that you flee.  The chances of you taking him down before he draws further attention to you seems unlikely.
	*goto later_that_night
*else
	His lifeless body slumps to the floor.  You bend to take a drink of his blood.  After all, waste not want not...
	*set compassion %+20
	*set blood +6
	*goto later_that_night

*label opened_door

The watchman on the other side of the door starts in surprise when you open the door that he was guarding.

*if speaks_german
	He yells out in German, "Stop!"
	*goto fight_watchman_german
*else
	He yells something out in German, but you can't understand him.
	*goto fight_watchman_2

*label later_that_night

*if blood = 0
	Leaving the warehouse, you are overcome with the hunger.  You slowly give in to the beast within as you pursue the scent of a nearby mortal...
	*page_break
	When you come to, you are covered in blood.  You'll need to clean yourself up before you can be seen in public.
	*set blood +10
	*set compassion %+10
	*set wealth +50
	*goto later_that_night_2
*else
	*goto later_that_night_2

*label later_that_night_2

Finding a place to spend the day may be challenging.

*choice
	*if wealth > 2
		#Find a flophouse and rent a room.
			The whores are a little surprised at your lack of interest, but when you drop your silver in their hands, they stop asking questions.
			*set wealth -2
			*finish
	*if wealth > 20
		#Find a proper hotel and take a room.
			A proper wash and shave and you feel like a new... vampire.
			*set wealth -20
			*finish
	*if charm > 2
		#I accost some poor soul on the street, and convince them that they need to take me home and give me shelter.
			You find a middle-aged workman, who seems excited to have someone to help keep his home warm for the night.
			
			Too bad you don't produce any body heat.
			*finish
	*if fighting > 2
		#I break into someone's apartment, kill the inhabitants and make a haven for myself.
			The tenement you decide to terrorize is in Lincoln Park.
			
			The inhabitants whimper as you kill them one by one.
			*set chicago_haven_neighborhood "lincoln_park"
			*set blood +10
			*set compassion %+20
			*set discretion %+10
			*finish
	#I find a place with disturbed soil, and dig myself a grave for the day.
		When you wake the next evening, you spend some time brushing the dirt from yourself in a nigh-futile attempt to make yourself presentable.
		*finish