*comment ñáéç…—
*hide_reuse
*set year 1873
*advertisement
*gosub_scene util check_flow
*gosub_scene util combat_value
*temp precise "precise"
*if sire_name = "Padre Carlos"
	*set precise "elegant"
*if sire_surname = "Villanueva"
	*set precise "inartful"
*temp mr_gullah "Massa'"
*if male = false
	*set mr_gullah "Mam'selle"
*temp hire_stennis false
*temp carothers_angered false
Summer arrives, uncompromising in its sultry heat.
*temp tick false
*if amount_invested_freedmans > 0
	*set tick true
	*set wealth +round(amount_invested_freedmans * 0.15)
	With the heat comes another dividend from the Freedman's Bank & Trust. The local branch continues to grow its investment portfolio in and around Memphis.
*if municipal_debt > 0
	*set wealth +((municipal_debt * 0.14) * 17)
	@{tick In addition to that, you receive an interest payment from your municipal bonds.|With the heat comes an interest payment from your municipal bonds.}

It is mid-July when you receive an invitation from Quaestor Carothers—hand-delivered by his servant, Hermes.  It seems he plans on attending a [i]crapaud[/i]-den, and thought you might enjoy joining him for an evening of gambling.
*if feeding_style = "gamblers"
	@{literate Looking closely at the directions,|When Franklin relates the directions to you,} you realize that the destination in question has been one of your favorite hunting-haunts of late.  You hope you have not committed any [i]faux pas[/i] by prowling there.
*choice
	#I reply in the affirmative.
		*set carothers_rapport %+10
		*set independence %+5
		*set invitation_to_reception_accepted true
	#I decline the invitation.
		*set carothers_rapport %-10
		*set discretion %+5
		*set independence %-30
		*goto invitation_rejected
	#I do not reply, but I will surprise him with my presence.
		*set carothers_rapport %+5
		*set discretion %+5
		*set invitation_to_reception_accepted true
	#I ignore the note.
		*set carothers_rapport %-20
		*set discretion %+10
		*set independence %-50
		*label invitation_rejected
		*set carothers_humanity +2
		One day, your audacity will be the stuff of legend.
		
		In the meantime, it mostly feels lonely.
		*gosub final_wilson_check
		*if observing_kkk or (joined_kkk or ((shepherd_credentials < 35) or (watching_james)))
			*page_break
			On July 21st, the James-Younger Gang dons the hoods of the Ku Klux Klan and derails a train outside Adair, Iowa.  The engineer is thrown from the cabin and crushed, but the passengers are otherwise unharmed.  The Gang leaves the passengers unmolested, explaining politely that they target thieving corporations and heartless capitalists, not common folk.
			
			Former Confederates throughout the city cheer for Jesse James and his one-man war agaist the Union.
		*finish

The [i]crapaud[/i]-den is located in the basement of a dry-goods store.  A bouncer admits you without your even having to introduce yourself.

*if feeding_style = "gamblers"
	As you make your way down the stairs, the smoke from cheap tallow candles and pipeweed stings your eyes. You suppress a smile; the sensation is like an [i]amuse bouche[/i] teasing you before the degenerate main course.
*elseif intelligence > 2
	The thought occurs to you—as the smoke from the tallow candles and cheap pipeweed stings your eyes—that this must be something like Dante's descent into Hell; unfortunately, your psychopomp is nothing more than a young boy, and he has none of the Mantuan's wisdom to offer you.  
*else
	As you make your way down the stairs, the smoke from cheap tallow candles and pipeweed stings your eyes.  When you reach the floor of the basement, you are thankful for once that you no longer have to breathe, as you would surely find the air noxious were you required to do so.

Carothers is standing at one of the tables—head and shoulders above most of the other people in the room—throwing dice. You wait for his streak to end before approaching.

*if feeding_style = "gamblers"
	*set carothers_rapport %-5
	*set knows_about_territories true
	"I understand that you are familiar with this place?"  Carothers begins.

	"I am. Is that a problem?"
	
	Carothers peers at you, trying to evaluate your sincerity. "Among our kind, feeding in another's territory is considered a violation. I will forgive it this time. Do not let it happen again."
	
	"I apologize, Quaestor; I did not know."

	"Now that you know, I trust that you shall take your hunger elsewhere?"

	"Of course, Quaestor."

	Carothers nods in approval before launching into what is really on his mind.
*else
	Once pleasantries have been exchanged, Carothers launches into more important subjects.  

*gosub final_wilson_check

*if joined_kkk
	"It has come to my attention that you have joined the Ku Klux Klan."
	
	Caught off guard, you do not deny the accusation.  "That is correct, Quaestor."
	
	"It is good to see that you do not insult me by denying it.  But tell me, ${mr} ${surname}, what drove you to this despicable deed?"
	*choice
		#"I did not realize you exerted influence over them, Quaestor.  I seek to bend them to my will."
			*set carothers_rapport %-5
			Carothers seems ambivalent about this answer.  "Is it your will that they string up my people at will, torch their homes and fields, and endeavor to disenfranchise them again?"
			
			"No, Quaestor, my control over them is only just beginning…"
			
			"I see.  If you make any progress there, please, let me know."
		#"I was seeking to infiltrate them, to undermine them from within."
			*set carothers_rapport %+15
			"I appreciate your efforts, ${mr} ${surname}, and I applaud your objectives."

			"Thank you, Quaestor."

			"If you find any success, I trust that I will be the first to know of it?"

			"Of course!"
		*if compassion < 60
			*selectable_if (discretion > 30) #"I agree with their objectives.  The Catholics and the Negroes are ruining this country."
				*set carothers_angered true
				*set carothers_rapport %-60
				*set anachronism %-10
				It is only Dido's hand on Carothers' arm that stops him from tearing you head from your shoulders.  He grits his teeth, and though he changes the subject, his next words are closer to snarls than proper language.
				*goto invitation_to_reception
*elseif kkk_1869_resolution = "disrupted"
	*set carothers_rapport %+15
	*set revolutionary_credentials %+5
	"I have heard that you caused quite a ruckus at the home of General Forrest."
	
	"I did, Quaestor."
	
	"Of course, I'm happy to say that you managed to do it without drawing undue attention to yourself."
	
	"But of course, Quaestor."
	
	"If I'm not careful, ${mr} ${surname}, I shall soon begin thinking of you as a friend."
	
	"That would be most certainly unfortunate, Quaestor."
	
	Apollo smiles broadly before moving on to the next topic of conversation.
*elseif kkk_1869_resolution = "dispersed"
	*set carothers_rapport %+15
	*set revolutionary_credentials %+5
	"I have heard that you caused quite a ruckus at the home of General Forrest."
	
	"I did, Quaestor."
	
	"Perhaps you could do it next time without drawing so much attention to yourself?"
	
	"My apologies, Quaestor."
	
	"If I'm not careful, ${mr} ${surname}, I shall soon begin thinking of you as a friend."
	
	"That would be most certainly unfortunate, Quaestor."
	
	Apollo smiles broadly before moving on to the next topic of conversation.
*elseif kkk_1869_resolution = "saved"
	*set carothers_rapport %+20
	*set revolutionary_credentials %+5
	"I have heard that you saved a man that was about to be lynched."

	"I did, Quaestor."

	"As much as I appreciate your efforts, might you do so again next time without drawing so much attention to yourself?"

	"My apologies, Quaestor."
	
	"If I'm not careful, ${mr} ${surname}, I shall soon begin thinking of you as a friend."
	
	"That would be most certainly unfortunate, Quaestor."
	
	Apollo smiles broadly before moving on to the next topic of conversation.

*set heard_of_harding true
"I suppose that you have not had the pleasure of meeting my broodmate, Quaestor Harding of Louisville?"

"No, I can't say that I have."

"Yes, well, she and I do not see eye-to-eye."
*set harding_animosity_known 2

*if jesse_is_broodmate and met_jesse
	*if jesse_rapport >= 60
		"Considering how close I am with my broodmate, I have a hard time conceiving of what unlife must be like if one were always at odds with one's broodmate."
		
		"You are fortunate to partake of such a friendship.  I regret that my maker did not better understand her…predispositions.  But I imagine that he had his reasons for his deeds.  He always seemed to, anyway."
		
		"Predispositions?"
		
		"Yes.  She is my elder, but he left Memphis to me.  She cannot abide such a slight."
	*elseif jesse_rapport >= 40
		"Broodmates can be a challenge to one's tranquility. Mine own, Jesse Whitaker, 
		*if avoided_new_orleans
			is mostly unknown to me.  We have yet to become truly acquainted."
		*else
			has been alternately friend and foe.  After some decades, we have yet to decide how we are to spend our unlife with each other."
		
		"I suppose that you are fortunate to still wonder.  Harding and I…well, I often wonder what service she provided our maker that would drive him to bless the both of us, yet leave Memphis to me."
	*else
		*if avoided_new_orleans
			"I, unfortunately, cannot sympathize with your troubles.  The interactions I have had with my broodmate, Jesse Whitaker, were short and violent.  None of this ongoing feud business."
			
			"At the very least, then, you can understand my desire for independence," he concludes.  "And yet, we are bound by the maker that we share, and the hate that she harbors for me."
		*else
			"I can sympathize with your troubles.  My broodmate, Jesse Whitaker, and I do not often find ourselves in accord."
		
		"Then you can understand my frustration at our maker.  He looked into both of our souls, and despite that, he left Memphis to me."

"Who was your maker?"

Were you not surrounded by men throwing dice, drinking and laughing, you would have sworn that the earth had gone silent at your question.  Finally, Carothers brings himself to answer your question.  "He is not to be named."

*if discretion < 70
	"My apologies, Quaestor Carothers.  I did not mean to offend you."
	
	"You do not offend me; rather, I understand better what your life must have been like in Vicksburg."
	
	"It was rather…isolated."
*elseif (carothers_rapport <= 60)
	*set carothers_rapport %-5
	"Why not?"
	
	Carothers' eyes narrow at your impertinence.  "Your complete lack of tact is truly astonishing, ${mr} ${surname}.  Believe me when I tell you [i]he is not to be named[/i], I mean that he is not to be named."
	
	"I see."
*else
	"Why not?"
	
	Carothers rolls his eyes at your impertinence, but thankfully seems to dismiss it.  "${given_name}, when I say he is not to be named, believe you me, he is not to be named."
	
	"I see."

"Well, whatever the matter, Elinor and I do not agree about many things." Elinor, you deduce, must be his broodmate, Quaestor Harding of Louisville.  "This makes what I have to tell you all the more difficult."  You fall still, anxious to hear Apollo's confidence.  
*label inform_about_election
"It seems that the Senate has decided that Memphis warrants a Senator.  An election will be held here soon."

*if chasing_wilson = false
	*if discretion > 70
		*set carothers_rapport %-5
		"Well, yes, that is why I am here, after all."
		
		"That is why you are here?"
		
		"Of course.  I wish to make my way in Society.  How better else to do so than to attend such an event?"
		
		Carothers looks at you suspiciously.
	*elseif discretion >= 40
		You find yourself on the verge of dismissing Carothers' declaration, but decide at the last moment that it may be best to feign ignorance.
	*else
		Deciding to keep your machinations to yourself, you try to look surprised at his declaration.  You ask a few leading questions, and he happily explains what he knows of the process.  Unfortunately, it is nothing more substantive than what was previously explained to you by Samantha.
	
	*label invitation_to_reception

	"As you have probably realized ${mr} ${surname}, this city fared well under the occupation, and especially now that Tennessee has been readmitted to the Union, its influence will only continue to expand.  In light of this, the Senate recently announced their decision."
	
	"Shall I extend my congratulations now or later, Quaestor?"
	
	"I am not entirely sure that congratulations are in order, ${mr} ${surname}."
	
	"Oh?"
	
	"A Senator's presence will bring some benefit, but it will also bring the attention of the Senate.  Moreover, I shall have to host the gathering here.  That shall be quite the undertaking."
	
	"I can only imagine, Quaestor."
*else
	"An election?"

	"Has no one explained this to you?"

	"I'm afraid not."

	"If it is any consolation, I must admit mine own ignorance in the matter.  What I do know is that Senators will gather here, and before they depart they will have appointed a Senator."

	*if (discretion > 50) and ((compassion < 40) and (anachronism > 60))
		"You have no say in the matter?  That doesn't seem very fair."

		Carothers scoffs.  "Fairness has nothing to do with it, ${mr} ${surname}.  The Society is not a democracy, and the Senator of Memphis does not represent me to them, but rather them to us."

		You find yourself somewhat at a loss in the face of this onslaught of new information.
	*else
		"I suppose that congratulations are in order?"

		"Something like that, yes."  He grimaces at the thought.

*if attended_marignys_party

	"Are you familiar with this game, ${mr} ${surname}?"

	"[i]Crapaud?[/i]  I am, in fact."

	He seems a little disappointed.  "Oh?  I would have thought that it had not reached Vicksburg yet."

	*if taught_crapaud
		*temp devil_he "he"
		*temp devil_his "his"
		*if male = false
			*set devil_he "she"
			*set devil_his "her"
		"Not reached Vicksburg?" you repeat in surprise.  "How else would it have come to Memphis, but up the river?"

		"I am not sure…" he begins, trailing off.  Turning, he shouts a name…Jean-Baptiste, perhaps?  

		A few moments later, a young black man appears at the side of Carothers.  "Yessuh?"

		"Jean-Baptiste, were you the one telling me about coming her with your brother, and setting up this pastime in Memphis?"

		"Yessuh, I wuz."

		"Where did you and your brother learn this game?"

		"Ous daddy, suh."

		"And where did he learn the game?"

		"From his daddy, suh."

		"And he from his, I suppose?"

		"Wul, no suh.  My grandaddy—his name wuz Cupid—learn it from uh devil."  

		Carothers' eyes crease with a barely-suppressed smile.  "A devil?"

		"Yes, suh.  A devil come an' live in ous town, and taught dis here game to evah-one."

		Carothers laughs.  "And was this person a devil because he taught your town this game?"

		"No, suh.  !${devil_he} was a devil because ${devil_he} fait dodo all day long, and drank blood all night.  Uhn den dey burnt down ${devil_his} hus."

		You can sense Carothers growing increasingly incredulous as this story unfolds.  You, however, hearing the retelling of your own exploits, decide it best to change the subject.  "I'm sure it's just a story, quaestor.  Come, you had something you wanted to discuss?"

		"How strange…" he mutters, still distracted by Jean-Baptiste's story.  "I hear these stories, that may or may not describe the presence of another of our kind.  It is so rare that we have the opportunity to spend time with fellow members of the Society, flung here and there as they are."  He pauses to muse a final minute, before continuing.
	*else
		"I learned it at the home of M. de Marigny, in New Orleans.  He threw a party in celebration of the victory over the British, and all were playing it.  It seems as though the rules have a changed a bit since I last saw it played, however."

		"That is interesting to hear.  Perhaps sometime soon you would be so kind as to show me how they used to play it."  He pauses a moment, seemingly troubled by what he is about to discuss.

"This brings me to the matter at hand.  I will be holding a reception for the Senators next month, and I wished to extend an invitation for you to attend.  There is a banquet hall off of Beale Street that Dido intends to outfit for the occasion."
*if (lore > 2) or ((status > 1) and (status != 0))
	This, you realize, is an excellent opportunity for you to earn some recognition within the Society.  There is most likely much to be done to prepare for the event, and an offer to help would likely be well-received by Carothers.
*if (lore > 2) and (status = 0)
	This, you realize, is an opportunity for you to earn some recognition within the Society.  At present, you will not be able to attend the caucus; perhaps with a suitable demonstration of loyalty, you might earn a seat at the proverbial able?

*label invitation_to_reception_3
*if (creation > 0) and ((intelligence > 2) and (wealth < 15000))

	As you consider your response, it occurs to you that you might organizing the reception for the visiting Senators.  At the same time, however, you fear that you may not have the resources to execute any grand designs.
*choice
	#"I should be most honored, Quaestor."
		*set carothers_humanity +2
		*set discretion %-5
		*set carothers_rapport %-5
		*set independence %+5
		*if carothers_angered
			"I am happy to hear that.  Now, get out of my sight."

			Apparently, he is still furious about your earlier pledge of support for the Ku Klux Klan.  You decide it best to not anger him further, and make a hasty exit.
		*else
			"I am glad to hear it.  We shall enjoy the company of our guests as best we can," he says.
			*gosub carothers_reflection

			"If you will excuse me, Quaestor."

			"Until tomorrow, ${mr} ${surname}."
			*if hire_stennis
				*gosub hire_stennis
		*gosub letter_from_sire
		*finish Next
	*if met_hugh_in_vicksburg and (carothers_angered = false)
		*hide_reuse #"Will Mr. Gallagher be in attendance?  I have not seen him since my arrival."
			*set mentioned_gallagher_to_carothers true
			"Mr. Gallagher?"

			"Yes.  One of our kind I met a few months ago in Vicksburg."

			"I'm afraid that I am unacquainted with this individual.  What more can you tell me about him?"

			"Very little.  An Irishman, he had a gap between his front teeth and ginger hair.  He was on a boat, and refrained from stepping ashore, lest he draw the ire of Withers.
			*if speaks_english
				He said he was on his way here, to make a home among his people."

				"This individual has not made himself known to me.  I trust that, if you see him again, you will compel him to do so?"

				"I most certainly shall, Quaestor."

				"Now, about the reception…will you be attending?"
			*else
				I learned from a member of his crew that the boat was destined for this port, but was unable to ask him anything else directly."

				"This individual has not made himself known to me.  I trust that, if you see him again, you will comp ell him to do so?"

				"I most certainly shall, quaestor."

				"Now, about the reception…will you be attending?"
			*goto invitation_to_reception_3
	#"I should be most honored, Quaestor.  But tell me, is there anything that I could do to help you prepare?"
		*set discretion %+5
		*if carothers_angered
			*set carothers_humanity +2
			"No.  Now, get out of my sight."

			Apparently, he is still furious about your earlier pledge of support for the Ku Klux Klan.  You decide it best to not anger him further, and make a hasty exit.
			*gosub letter_from_sire
			*finish Next
		Carothers seems somewhat relieved by your offer.  "As you can imagine, the vampiric population of the city will swell to well beyond our normal numbers shortly.  It will be part of my responsibilities to provide sustenance to the guests and maintain order during their stay.  If you could acquire some vessels for me, it would be of immense value to me."

		Of course, what he means by "acquire some vessels" is to procure some mortals who will not be missed, as they shall not survive the event.
		*comment Should this play on Carothers' personal history?
		*if (intelligence >= 3) and (((((combat + stealth) <= 8) and (priest = false)) and ((streetwise + charm) < 5)) and (charm != 4)) 
			Reflecting on the matter for a moment, you are not sure how you would go about accomplishing this task.
		*choice
			*if debt_to_carothers 
				*if carothers_debt_wilson = 1
					*selectable_if (independence >= 20) #"Would you consider such a deed to be sufficient to discharge my debt to you, Quaestor?"
						*set carothers_rapport %-10
						*set compassion %+25
						*set independence %+5
						*set debt_check true
						Carothers' eyes narrow at your question.  "Yes, I suppose I would."
						
						"It is agreed then.  I shall arrange for the procurement of the necessary vessels."
	
						"And, upon delivery of those vessels, I shall consider your debt nullified."
	
						"So it is agreed," you reply.
	
						*gosub carothers_reflection
						*if hire_stennis
							*gosub hire_stennis
						*page_break
						*goto hunting_preparations
				*if carothers_debt_wilson = 3
					#"The pursuit of ${wilson} will discharge my current debt to you, but perhaps I might earn a debt by doing this for you?"
						*set carothers_rapport %-15
						*set compassion %+25
						*set independence %+5
						*set debt_check true
						Carothers shuffles uncomfortably.  "Yes, I suppose you could."

						"It is agreed then.  I shall arrange for the procurement of the necessary vessels."

						There is a pained look on Carothers' face.  "I thank you, ${mr} ${surname}," he says.
						*gosub carothers_reflection
						*if hire_stennis
							*gosub hire_stennis
						*page_break
						*goto hunting_preparations
			*elseif status = 0
				#"Might this earn me an invitation to the election itself?"
					*set independence %+20
					*set carothers_rapport %+10
					*set compassion %+15
					*set carothers_rapport %+10
					Carothers pauses a moment, and then nods.  "Yes, yes it would.  Accomplish this for me, and all will hear about your devotion to the Society."
					
					"Thank you, Quaestor," you say.
					
					*gosub carothers_reflection
					*if hire_stennis
						*gosub hire_stennis
					*page_break
					*goto hunting_preparations
			*else
				#"With pleasure, Quaestor.  I shall set out immediately to gather some vessels."
					*set carothers_rapport %+15
					*set independence %+15
					Carothers clearly seems relieved.  "I must admit, of all the parts of this affair that displease me, providing the vessels for our guests' consumption was the most repugnant."
					*choice
						*selectable_if (independence > 40) #"Would you consider this a matter worthy of a debt, Quaestor?"
							*set carothers_rapport %-15
							*set compassion %+25
							*set independence %+5
							*set debt_check true
							Carothers shuffles uncomfortably.  "Yes, I suppose I would."

							"It is agreed then.  I shall arrange for the procurement of the necessary vessels."

							There is a pained look on Carothers' face.  "I thank you, ${mr} ${surname}," he says.
							*gosub carothers_reflection
						*selectable_if (discretion > 40) #"Clearly, I do not share your aversion to our nature.  But no matter, I am glad to be of service."
							*set shepherd_credentials %-10
							*set discretion %+5
							*set carothers_rapport %-5
							*set compassion %+20
							Carothers bristles at your words.  "I am glad to hear that I will not inconvenience you, ${mr} ${surname}.  Please, if you will excuse me, I would like to return to my amusements."

							"Then good evening, Quaestor."  You're not sure what it is that you said to anger Carothers so, but neither do you particularly care.
							*gosub carothers_reflection
						*selectable_if (discretion < 60) #"It would be my honor to relieve you of such a burden, Quaestor."
							*set discretion %-5
							*set compassion %+25
							*set independence %+10
							*set carothers_rapport %+5
							Carothers seems a little perturbed at your callousness, but that changes nothing.  "Your service is appreciated, ${mr} ${surname}."

							"I am ever your servant, Quaestor."

							*gosub carothers_reflection
							"Come, let us return to the game before us!"  With that, the two of you spend the rest of your night enjoying the rhythm of the dice and drink that flow everywhere around you.
						*if independence > 40
							*selectable_if (compassion < 50) #"I find the matter unfortunate and distasteful as you, but it must be done.  The success of the event depends on it.  Besides, to not provide the guests with sustenance would prove a greater danger to the mortal denizens of the city."
								*set shepherd_credentials %-10
								*set independence %+10
								*set compassion %+20
								*set carothers_rapport %+10
								Carothers seems relieved at your evaluation of the situation.  "I am grateful for your assistance, ${mr} ${surname}."

								"It is my honor, quaestor."

								*gosub carothers_reflection
					*if hire_stennis
						*gosub hire_stennis
					*page_break
					*goto hunting_preparations
			#"I'm afraid I cannot aide you in this, quaestor."
				*set carothers_rapport %-10
				*set compassion %-5
				*set independence %-10
				*set shepherd_credentials %+10
				*set carothers_humanity +2
				Carothers looks uncomfortable.  "I suppose that I cannot blame you, ${mr} ${surname}.  The idea of herding mortals into some sort of pen and keeping them imprisoned until there is need for them does not appeal to me either.  Unfortunately, the obligations of my title are many."
				
				*if compassion < 35
					"Obligations? Who obliges you to do this?"
					
					"It is my duty as a quaestor to provide for the visiting senators. I would not be quaestor for long if I refused to provide for their sustenance and entertainment."
					
					"But how can you do such a thing?"
					
					"If I refused, ${mr} ${surname}, Governor Overstreet would replace me with someone who did not hold such concerns. If I am to protect my city, someone must do this. And since you have refused, the task falls to me."
				*choice
					#I am grateful that I do not bear this burden.
						*set compassion %-5
						*gosub carothers_reflection
						"Will there be anything else, quaestor?"

						"No, that is all.  If you will excuse me, I have some dice to cast."

						Offering a farewell, you depart from the [i]crapaud[/i]-den.
						*if compassion < 40
							As you return to your haven, you do your best not to wonder whether it would have been more merciful to take on the burden yourself.  At least you could have ensured that the vessels were well-treated until their violent demise.
						*if hire_stennis
							*gosub hire_stennis
						*gosub letter_from_sire
						*finish Next
					#The task that Carothers proposes is fraught with danger; it is best not to exert myself without clear benefit.
						*set discretion %-10
						*set independence %+10
						*label dice_to_cast
						*gosub carothers_reflection
						"Will there be anything else, Quaestor?"

						"No, that is all.  If you will excuse me, I have some dice to cast."

						Offering a farewell, you depart from the [i]crapaud[/i]-den.
						*if hire_stennis
							*gosub hire_stennis
						*gosub letter_from_sire
						*finish Next
					#I am curious to see how the quaestor discharges this obligation.
						*set discretion %-5
						*set independence %+5
						*goto dice_to_cast
					*if compassion < 35
						#I cannot consign Carothers to this. I inform him that I discharge his obligation.
							*set carothers_rapport %+25
							*set independence %+15
							*set discretion %+5
							*set compassion %+20
							*set carothers_humanity -3
							He sighs and thanks you for your sacrifice. He knows that this is a task which you will detest.
							
							*gosub carothers_reflection
							*if hire_stennis
								*gosub hire_stennis
							*page_break
							*goto hunting_preparations
					*if feeding_style = "vegetarian"
						#Considering your aversion to the blood of humans, you do not wish to tempt yourself by undertaking such a task.
							*set discretion %-5
							*if compassion < 35
								*set compassion %+5
							*goto dice_to_cast
	#"I should be most honored, Quaestor.  Moreover, I hope that you would allow me to organize the festivities.  A banquet hall simply won't do!"
		*set carothers_humanity +2
		*if carothers_angered
			"No, I do not need your help.  Now, get out of my sight."

			Apparently, he is still furious about your earlier pledge of support for the Ku Klux Klan.  You decide it best to not anger him further, and make a hasty exit.
		*elseif carothers_rapport > 40
			*goto party_preparations
		*else
			Carothers tries to hide his distrust.  "I thank you for your offer, ${mr} ${surname}, but Dido has already begun making those preparations."

			"I see.  I suppose, then, the next time we meet will be for the reception?"

			"I believe so.  Until then."

			"Until then, Quaestor."
			*if hire_stennis
				*gosub hire_stennis
		*gosub letter_from_sire
		*finish Next

*label carothers_reflection
*if noticed_paving and (technology > 1)
	He looks at you a moment, seemingly aware that there is something else on your mind.  "What is it?"
	
	"The paving blocks, Quaestor."
	
	"What about them?"
	
	"I think they may have been a mistake.  I did some investigating, and I learned that they are likely to rot…"
	
	Carothers waves his hand at you dismissively.  "Percival assured me that the investment is sound.  Beside, several other cities are using the same method.  And look how much they improve the downtown!"
	
	"How handsome they are will matter little—"
	
	"Enough, ${mr} ${surname}.  Besides, this work is long done.  It is now the responsibiltiy of the citizens of the city to pay their taxes, so that the city's debt may be retired."
	
	"Yes, Quaestor," you reply.  Apparently, he is not interested in hearing about your findings.
*elseif carothers_rapport > 55
	*set rumors_of_plague true
	"One more thing before you go," he says.

	"Yes, Quaestor?"

	"Have you heard the rumors?"
	
	"What rumors?"

	"Rumors of the plague.  It is said that the yellow fever may have come to Memphis."

	"That is worrisome, Quaestor," you reply, not quite certain what this would mean to one of your kind.

	Carothers looks around the room before continuing.  "Look at them, my children, with their billiard cues and dice, here in the hopes that I can protect them.  Here, while their families cry out in pain.  I, Apollo Carothers, whom all acknowledge as Quaestor of this city.  But what can you tell me, my newest citizen, of the plague that afflicts my city?  I would be hard-hearted indeed if I did not do all that was in my power to aid my people."

	"I have no intelligence to offer, Quaestor."

	"We shall have to pray, then, that this plague leaves our city untouched," he says.  His face is clearly troubled by these considerations.
*return

*label hunting_preparations
Before you leave, Hermes gives you instructions as to where the vessels can be stored until the reception.  Realizing that the night is already well underway, you resolve to begin immediately.  Kidnapping enough mortals in time will be quite a feat.

*if memphis_haven = "yankees"
	The area near your haven is too insular to be raided for such numbers comfortably.
	*choice
		#I head north to the Irish ghetto, the Pinch.
			*goto round_pinch
		#I head south to the area around Beale Street, home of both free blacks and former slaves.
			*goto round_beale
*if memphis_haven = "pinch"
	*label round_pinch
	The population of the Pinch is constantly in flux.  Easy access to the water, as well as the residents' inclination to drink, means that individuals go missing all the time.
	*if feeding_style = "itinerants"
		You dislike the idea of preying on the same sorts of individuals on whom you rely for your own sustenance, but can see no other way to corral so many in such a short span of time.
*if memphis_haven = "beale"
	*label round_beale
	The population of the Beale district is constantly in flux.  The arrival and departure of freedmen, still exuberant from their newly-acquired right to such, results in a periodic change in the area's composition.
	*if feeding_style = "itinerants"
		You dislike the idea of preying on the same sorts of individuals on whom you rely for your own sustenance, but can see no other way to corral so many in such a short span of time.

*comment endif
Arriving at your destination, you steel yourself for what lies ahead.
*if priest
	*set acquiring_vessels "success"
	One by one, you offer consolation to those in need of such.  Trusting in your cassock and collar, your victims seem willing to follow you to the ends of the earth.  Instead, you take them to something approximating hell.
	*goto hunting_preparations_resolution
*elseif (charm > 3) or ((charm = 3) and (male = false))
	*set acquiring_vessels "success"
	One by one, you begin leading men (and the occasional woman) to the holding pen.  Taken in by your charms, they willingly follow you, realizing only too late that your offer was too good to be true.

	*label hunting_preparations_resolution
	The next night is much the same, and the night after that as well.  Soon, the pen fills with the stink of people piled one on top of the other.  Carothers will be pleased.
	*if compassion < 45
		You, on the other hand, find your handiwork distressing.  The cries of the captives haunt your dreams.
	*if (compassion >= 45) and (compassion < 70)
		You, on the other hand, find your handiwork unpleasant.  You find it difficult to set aside the cries of the captives once you have sealed them away.
	*if compassion >= 70
		You take special delight in tormenting the captives, spitting on them, taunting them with the misery that is to come.  The memory of their cries and wails rocks you to sleep in the morning.
	*if debt_check
		*if debt_to_carothers and (carothers_debt_wilson = 1)
			*set debt_to_carothers false
		*else
			*set debt_from_carothers true
	*elseif status = 0
		*set train_status true
	*gosub letter_from_sire
	*finish Next
*elseif (stealth > 2) and (combat > 4)
	*set acquiring_vessels "success"
	One by one, you follow lone individuals into places from which they will not return.  With the assistance of your valet, you port their comatose bodies to Carothers' pen.
	*goto hunting_preparations_resolution
*elseif (stealth > 1) and (combat > 6)
	*set acquiring_vessels "success"
	You wait in alleys, invisible to the minds of your prey, waiting for the right moment to strike.  One by one, you subdue your victims.  With the assistance of your valet, you port their comatose bodies to Carothers' pen.
	*goto hunting_preparations_resolution
*elseif (stealth > 0) and (combat > 7)
	*set acquiring_vessels "success"
	You wait in alleys, hoping that no one notices you while you wait for the right moment to strike.  Thankfully, you long ago stopped breathing, and that certainly limits the sound that you would otherwise make while perched in the shadows.

	One by one, you subdue your victims.  With the assistance of your valet, you port their comatose bodies to Carothers's pen.
	*goto hunting_preparations_resolution
*elseif combat > 8
	*set acquiring_vessels "success"
	One by one, you follow lone individuals through the streets, waiting for the right moment to strike.  With the assistance of your valet, you port their comatose bodies to Carothers' pen.
	*goto hunting_preparations_resolution
*elseif (streetwise > 1) and ((charm > 2) or ((charm = 2) and (male = false)))
	*set acquiring_vessels "success"
	Thankfully, the time you have spent in the company of the criminal elements of the city means that you already know who would be most susceptible to small enticements.  It is easy enough to tempt these poor souls away from the company of others, at which point they are easily subdued.
	*goto hunting_preparations_resolution
*else	
	*set carothers_humanity +3
	*set acquiring_vessels "failed"
	*set carothers_rapport %-30
	Unfortunately, your skills at hunting are still not to the point at which you can corral such a large number of individuals in such a short amount of time.  You are not charming enough to easily entice them in sufficient numbers, or martial enough to subdue them in an efficient manner.

	After several nights of effort, you are forced to inform the furious Carothers of your inability to complete the task for which you volunteered.

	*if debt_check
		*if debt_to_carothers and (carothers_debt_wilson = 1)
			"I'm sure you have surmised that your debt is by no means cleared."

			"I have."

			*label finish_this
			"Do you have any idea to what lengths I will have to go in order to accomplish this task in the days that remain?"

			"I do, Quaestor."

			"Leave my presence.  Now!"  Grateful that your audience is over, you flee from his incendiary presence.
			*gosub letter_from_sire
			*finish Next
		*else
			*if status > 0
				*set status -1
			"And you were so arrogant as to demand a debt from me for your services!  Do you have any idea to what lengths I will have to go in order to accomplish this task in the days that remain?"

			"I do, Quaestor."

			"You are a disgrace to your dominus and to the blood that sustains you. Leave my presence. Now!"  Grateful that your audience is over, you flee from his incandescent presence.
			*gosub letter_from_sire
			*finish Next
	*else
		*goto finish_this

*label party_preparations
"That would be most generous of you, ${mr} ${surname}.  I shall make sure that Dido will be on-hand to assist you."

"Thank you, Quaestor."

"No, thank you, ${mr} ${surname}.  I am sure you shall not disappoint." You ${bow} graciously.
*gosub carothers_reflection
*if hire_stennis
	*gosub hire_stennis
*gosub letter_from_sire
*page_break
*set memphis_reception_planner given_name
*if discretion < 65
	As you begin to prepare for the reception, the thought occurs to you that you might have oversold yourself.
	*choice
		*selectable_if ((discretion > 30) or (creation > 1)) #No, no…I am more than capable of throwing this party.
			*set discretion %+5
			*if (creation > 1) and (wealth >= 10000)
				*set party_preparations 2
				*if (creation = 3) and (wealth >= 15000)
					*set party_preparations 3	
				*if (creation > 3) and (wealth >= 20000)
					*set party_preparations 4
				*set wealth -(creation * 5000)
				*set party_preparations_1873 "success"
			*elseif (creation >= 1) and (wealth >= 5000)
				*set wealth -5000
				*set party_preparations 1
				*set party_preparations_1873 "fair"
			*elseif wealth < 5000
				*set party_preparations 0
				*set party_preparations_1873 "failure"
				Unfortuantely, you do not have the funds to execute your vision for the evening.  You do your best to scrounge about for materials, but there is no time to successfully prepare.
			*else
				*set party_preparations 0
				*set party_preparations_1873 "failure"
			*goto prepare_alone
		*if (met_olivia_hill) and (ruined_relationship_olivia_hill = false)
			#Olivia Polk Hill seems to have a talent for festivities.
				*set discretion %-5
				*set party_preparations 2
				*set memphis_reception_planner "Olivia"
				*set memphis_reception_planner_1873 "Olivia"
				*set party_preparations_1873 "success"
				*if wealth > 5000
					*set wealth -5000
				*else
					*set wealth 0
				Olivia is only too happy to oblige.  Within moments of broaching the topic with her, you can already see her mind spinning in uncountable directions.  "What a party we shall throw, dear ${given_name}!  Like none that has been seen since the war!"

				Were you still alive, you would no doubt breathe a deep sigh of relief.  Instead, you can simply smile and divert your mind to more relaxing thoughts.
				*finish Next
		#Surely there is someone that I can hire to do this for me.
			*set discretion %-5
			*set party_preparations 1
			*if temperance_movement and (wealth > 10000)
				*set memphis_reception_planner "Harriet"
				*set memphis_reception_planner_1873 "Harriet"
				*set party_preparations_1873 "success"
				*set wealth -8500
				You contact Mary Ann Forrest, and she introduces you to Harriet Lane, a woman instrumental in organizing the temperance events of the city.  Considering the fact that none of your guests will be consuming alcohol you figure that she will not object to the task.

				During your meeting, Miss Lane warns you that extravagance is not her [i]modus operandi[/i].  But she promises that no man or woman will leave your soirée disappointed.  She eventually turns the subject around to her efforts at educating the papists of the Pinch, and the financial needs that she incurs in these efforts.  You wave away this stipulation, noting that "…we have many details to confirm, and little in the way of time.  Please, let us concentrate on the task before us.
			*elseif met_percival_little and (wealth > 10000)
				*set memphis_reception_planner "Sally"
				*set memphis_reception_planner_1873 "Sally"
				*set party_preparations_1873 "fair"
				*set wealth -8500
				It occurs to you that Percival Little mentioned his wife's fund-raising activities on behalf of the various charities in which the Freedman's Bank invests.

				Mrs. Little is happy to oblige you and her husband's associate, Mr. Carothers.  She warns you, however, that extravagance is not her [i]modus operandi[/i].  But she promises that no man or woman will leave your soirée disappointed.
			*elseif (memphis_haven = "beale") and (wealth > 10000)
				*set memphis_reception_planner "Sally"
				*set memphis_reception_planner_1873 "Sally"
				*set party_preparations_1873 "fair"
				*set wealth -8500
				There is a woman about town, Sally Little, who is responsible for many of the social events of the Beale district.  After some pointed questions, you learn that she is the wife of one of the managers at the Freedman's Bank, and her reputation is founded on throwing parties for the various charities in which the Bank invests.

				When you approach her about the event, she is happy to take up the task.  She does make it clear, however, that she will require a donation to one of the orphans' charities, a stipulation to which you agree with a wave of your hand.  "We have little in the way of time, Mrs. Little.  Let us begin discussing the details…"

				Mrs. Little is happy to oblige you and her husband's associate, Mr. Carothers.  She warns you, however, that extravagance is not her modus operandi.  But she promises that no man or woman will leave your soirée disappointed.
			*elseif wealth > 10000
				*set memphis_reception_planner "Harriet"
				*set memphis_reception_planner_1873 "Harriet"
				*set party_preparations_1873 "fair"
				*set wealth -8500
				You cast about the city, seeking an individual to organize the event on your behalf.  You find a local temperance advocate by the name of Harriet Lane who is willing to see you.  Considering the fact that none of the guests will be consuming alcohol, you figure that she will do well enough.
				
				During your meeting, Miss Lane warns you that extravagance is not her [i]modus operandi[/i].  But she promises that no man or woman will leave your soirée disappointed.  She eventually turns the subject around to her efforts at educating the papists of the Pinch, and the monetary needs that she occurs in these efforts.  You wave away this stipulation, noting that "…we have many details to confirm, and little in the way of time.  Please, let us concentrate on the task before us."
			*else
				*set memphis_reception_planner given_name
				*set memphis_reception_planner_1873 given_name
				*set party_preparations_1873 "failure"
				*set party_preparations 0
				Unfortuantely, your limited financial means prevent you from finding anyone of talent to plan.  You are left to your own impoverished devices.
				
				As the night of the reception draws near, you grow increasingly terrified over your contribution.  You are certain that—unfortunately—this is a night which the Society will never forget.
			*finish Next
*else
	*set party_preparations_1873 "failure"
	*if (creation >= 1) and (wealth >= 5000)
		*set party_preparations 1
		*set party_preparations_1873 "fair"
	*if (creation >= 2) and (wealth >= 10000)
		*set party_preparations 2
		*set party_preparations_1873 "success"
	*if (creation = 3) and (wealth >= 15000)
		*set party_preparations 3	
		*set party_preparations_1873 "success"
	*if (creation > 3) and (wealth >= 20000)
		*set party_preparations 4
		*set party_preparations_1873 "success"
	*set wealth -(creation * 5000)
	*if wealth < 0
		*set wealth 0
	*label prepare_alone
	*set memphis_reception_planner_1873 given_name
	*if party_preparations >= 3
		*set train_status true
	You set about making the necessary preparations for the reception.  Much of the intervening week is consumed by these efforts as you seek to effect your vision for the evening.

	As the night of the reception draws near, you grow increasingly excited over your contribution.  You are certain that this is a night which the Society will never forget.
	*finish Next

*label hire_stennis
*page_break
*if wealth > 1000
	*set wealth -1000
*if wealth <= 1000
	*set wealth 0
To aide in your search for ${wilson}, you direct Franklin to spread some coin about the city.  A one-@{maddox_num eared freedman|eyed Cajun} that only skulks about at night should catch someone's attention, right?
*return

*label letter_from_sire
*if sire_alive = false
	*return
*elseif (sire_name = "West") or ((sire_name = "Guillaume de Sainte-Chapelle") or (sire_name = "Wallace Winters"))
	*return
*elseif sire_formerly_quaestor and (sire_surname = "Villanueva")
	*return
*else
	*page_break
	A few evenings later, you are surprised by a knock at the door of your haven.
	
	Franklin enters your study a few moments later to announce the arrival of Miss Dido Applethorp.
	*if acquiring_vessels = "failed"
		You tremble at the thought of what news she might bear.
	*comment endif
	
	*if compassion < 40
		*set applethorp_rapport %+5
		You stand to greet her, a gesture which she seems to appreciate.
	*else
		You gesture for her to sit, which she does.
	*if speaks_english = false
		Once mute pleasantries are exchanged, she furnishes you with a letter.  Glancing at the exterior, you are surprised to see the ${precise} handwriting of your dominus, identifying you as the addressee.
		
		You thank her as best as you can, and she excuses herself.
		*if (acquiring_vessels = "failed") and (compassion < 35)
			You catch yourself breathing a sigh of relief once she has left the room; Carothers has not called for your head this particular evening.
	*else
		"Good evening, Miss Applethorp," you begin.
		
		"Good evenin' to you as well, ${mr_gullah} ${surname}.  Ah is jus' here to bring you this here letter," she says, pulling one from her valise.
		
		@{literate "Thank you…" you begin, only to fall silent when you notice the ${precise} handwriting of your dominus on the exterior, identifying you as the addressee.|"Thank you," you say, curious as to who would write to you by means of the Quaestor.}
		
		"It arrived to A'pallah yesterday evenin', an' he reckoned you'd want to see it right quick."
		
		"Yes, extend my gratitude to him.  And thank you for coming and delivering this yourself."

		*if applethorp_rapport > 45
			@{(applethorp_rapport > 55) "It were mah pleasure,|"It weren't no burden,} ${mr_gullah} ${surname}.  G'night, then," she says, allowing Franklin to escort her to the door.
		*else
			"Ah does wut A'pallah asks.  G'night, then," she says, allowing Franklin to escort her to the door.
	*if (acquiring_vessels = "failed") and (compassion < 35)
		You catch yourself breathing a sigh of relief once she has left the room; Carothers has not called for your head this particular evening.
	
	Finding yourself alone, @{literate you hesitate no longer and tear open the letter.|you call for Franklin to come and read the letter to you.}
	*if sire_name = "Padre Carlos"
		It seems that Padre Carlos has learned of your presence in Memphis, as well as the upcoming election for the Senate.  In the letter, he observes that while he is somewhat removed from Senatorial politics, he is certain that there will be a candidate present who clearly represents Stone's interests.  He urges you to do everything you can to support the election of such a candidate.  
		
		Before closing, he takes a few moments to describe to you something of the work he has been doing for Stone as Praetor over the past few years, seeking heretics within the Society, as well as investigating overt rejections of Stone's authority.
		
		In closing, he extends his well-wishes, and again urges you to attend his words.
		*if (independence < 60) or (sire_rapport < 50)
			Apparently, he does not recall that you are not his to command any longer.
	*elseif sire_surname = "Villanueva"
		*set heard_of_chiara_santagostino true
		It seems that Quaestor Villanueva has learned of your presence in Memphis.  In the letter, he points out that the Senator of New Orleans, Chiara Santagostino, will be in attendence.  He informs you that the two of them are in agreement that Stone and his revolution are worthy endeavors, and that you should do everything in your power to support the election of a candidate who will further Stone's agenda in the Senate.
		
		*if (independence < 60) or (sire_rapport < 50)
			Apparently, he does not recall that you are not his to command any longer.
	*else
		*set heard_of_chiara_santagostino true
		*set heard_of_lockridge true
		It seems that Heer Van der Velde has learned of your presence in Memphis.  In the letter, he points out that Chiara Santagostino, the Senator of New Orleans, will be in attendance at the upcoming election.  He warns you that she is an inveterate supporter of Stone, and counsels against trusting her.  Instead, he recommends looking to Arthur Lockridge, the Senator of Charleston, for guidance.  Moreover, he urges you to do everything in your power to support the election of someone who will work to undo Stone's agenda in the Senate.
		
		*if (independence < 60) or (sire_rapport < 50)
			Apparently, he does not recall that you are not his to command any longer.
	*return

*label final_wilson_check
*if (chasing_wilson = false) and (rejected_sam_wilson)
	*set chasing_wilson true
	*set hire_stennis true
	*set wilson_lately true
	*set carothers_ignorant_of_pb false
	*if invitation_to_reception_accepted = false
		Unfortunately, your efforts to remain entirely above the fray are for naught.
		
		One evening, Carothers descends upon you out of nowhere. You recoil—but he does not seek your death.
	"I have received a letter from Quaestor Withers."

	"Oh?" @{invitation_to_reception_accepted |You try to sound nonchanlant.}

	"It seems that her offspring has gone missing."

	"${wilson} ${maddox}?"

	"You are acquainted with the man?"

	"I am.  He was once my valet."

	"Then it seems to me that you are the perfect individual to hunt down this errant whelp."

	*if rejected_sam_wilson
		"Quaestor, I already said no to Quaestor Withers when she asked me about this."
		
		"Do you think that I will accept a no, ${mr} ${surname}?"
		
		"I suppose not. But…"
	*else
		"Quaestor?"

	*if debt_to_carothers
		*set carothers_debt_wilson 3
		"Yes, if you find your former valet, and render him unto me, I shall absolve you of your debt to me."
		
		Not really in a position to say no to your new Quaestor, you nod your assent.  "Good, I am glad to hear it," he says, patting you on the shoulder with one of those huge hands of his.
	*else
		"Yes, yes, I shall be in your debt, should you apprehend him.  I trust you can see to the matter efficiently?"
	
		Not really in a position to say no to you new Quaestor, you nod your assent.  "Good, I am glad to hear it," he says, patting you on the shoulder with one of those huge hands of his.
*return