*comment ñáéç…—
*hide_reuse
*advertisement
*gosub_scene util check_flow
*set first_memphis_reception_attended 1
*temp jesse_toa ("dear" & (" " & given_name))
*if jesse_rapport < 45
	*set jesse_toa (mr & (" " & surname))
	*comment jesse_toa = jesse's term of address for the player.
*if jesse_rapport < 40
	*if revolutionary_credentials > 60
		*set jesses_revolutionary_credentials %-10
	*if revolutionary_credentials < 40
		*set jesses_revolutionary_credentials %+10
*if jesse_rapport > 60
	*if revolutionary_credentials > 60
		*set jesses_revolutionary_credentials %+10
	*if revolutionary_credentials < 40
		*set jesses_revolutionary_credentials %-10
*temp mista "Massa"
*if male = false
	*set mista "Mam'selle"
*temp already_recognized false
*temp whiskey_allowed true
*temp voting_il_name "name"
*temp voting_il_address "Quaestor Carothers"
*temp voting_il_he "he"
*temp voting_il_him "him"
*temp voting_il_his "his"
*temp rebuff_query false
*temp questions 0
*temp sick_driver false
*temp interlocutors 0
*temp bailey_introduces_malloy false
*temp whitaker_unspoken true
*temp harding_unspoken true
*temp applethorp_unspoken true
*temp earned_status false
*temp senator_question_unasked true
*temp sire_question_unasked true
*temp sw_question_unasked true
*temp party_foul false
*temp partridge_bailey_hidden false
*temp jesse_hidden false
*temp initiated_jesse false
*temp thank_carothers_thought true
*temp recognition_sequence true
*temp gould_q false
*set senator_count 0
A hired carriage arrives to convey you to the reception.  
*if (memphis_haven = "pinch") and (male = false)
	*set sick_driver true
	As he helps you into the carriage, you note that the driver feels abnormally warm to the touch.
*if (memphis_haven = "pinch") and (male and (perception > 1))
	*set sick_driver true
	The driver seems to be burning with a fever, though he does his best to power through it.
You settle into the @{sick_driver cushions, replacing any concerns of a fever which cannot hurt you with those of the politics which can,|cushions} and then signal the driver to depart.

*if ((avoided_new_orleans = false) and (exiled_from_new_orleans = false)) or ((exiled_from_new_orleans) and (frenzied_on_jesse))
	The jostling of the carriage reminds you of that evening, decades ago, when you set out to attend the Governor's reception in New Orleans.  This night, as with that one, has the potential to further your standing in the Society.  But you must step carefully, lest you see your fortunes fall.
	
	These pavement stones are different, however.  The carriage wheels rattle at a different tempo, and the echo off the buildings rebounds disconcertingly.  The thought occurs to you, is this what unlife is?  Fleeing from city to city, trying to salvage what you can of your reputation and your influence, trying not to go mad at the thought of how many times you have embarked upon what amounts to being the same night, regardless of the space and time that differentiates them?
	
	You shake your head, trying to ward away such thoughts.  There is too much to be done to lose yourself to them right now.
*else
	The carriage jostles along the paving-stones.  Thoughts of your time in St. Charles parish come to mind; never were so many buildings so close together!  You wonder how many of those families still reside there.
	*if ending_saintcharles_rapport = "good"
		It was not exactly love that the people of the parish bore for you, but respect at least.
	*elseif ending_saintcharles_rapport = "fair"
		And while their opinion of you can be said to be only marginally better than hate and fear, you do think of them somewhat wistfully.
	*else
		Moreover, the stark terror with which your "neighbors" there viewed you provided no end of amusement.
	*if discretion > 50
		Never did you doubt that you were the first thing on their mind when they woke and the last before they went to sleep at night.  Maybe one night you will again rule as you did then.
			
*page_break
*if memphis_reception_planner = "Dido"
	The banquet hall is brightly lit with gaslamps.  It is one of the more lavish halls of the Beale district but is still clearly the product of its surroundings.  
*elseif memphis_reception_planner = "Harriet"
	The community hall of a Methodist Church stands somberly before you.  A handful of temperance workers stand by, opening carriages for the guests and escorting them to the door.  They seem thrilled that there is no evidence of drunkenness among the attendees.  
*elseif memphis_reception_planner = "Sally"
	The church-hall stands lit before you.  Apparently, someone has funded the addition of gaslamps to the building; their brass and chrome further reflects the light, as of yet unmarred by soot.  The lights are rather out of place, however, in that it is the only building so lit for blocks around.  
*elseif memphis_reception_planner = "Olivia"
	The Gayoso Hotel is gayly lit by gaslamps and chandeliers.  Olivia certainly did a fine job with the preparations, making the most of the venue to amaze and delight the guests.
*elseif memphis_reception_planner = given_name
	*if party_preparations >= 2
		The Gayoso Hotel is gayly lit by gaslamps and chandeliers.  You are confident that you made a wise choice in venue.
	*else
		The house that you rented for the event is lit brightly by gaslamps.
*else
	The Greenlaw Opera House is gayly lit by gaslamps and chandeliers.  Dido requisitioned it for the evening.

*temp circle_presence false

Surveying the main room, you take in the sight of the gathered guests.
*if met_partridge or (met_bailey or (heard_of_bailey or heard_of_partridge))
	You see Senators Partridge and Bailey, thick as thieves, speaking with
	*if heard_of_malloy or met_malloy
		Siobhan Malloy, the candidate. She is all laughter and red hair, a sore thumb among the otherwise dour vampires.
	*elseif memphis_chance_encounter = "partridge_bailey"
		the Irishwoman from the tavern the other night. She seems just as jovial tonight as then—a marked departure from the otherwise dour vampires.
	*else
		a woman who is unknown to you. You surmise that she is Irish, and she is all laughter and red hair—a marked departure from the otherwise dour vampires.
*if (met_partridge = false) and ((met_bailey = false) and ((heard_of_bailey = false) and (heard_of_partridge = false)))
	Two men in particular stand close together: one fair-haired and clean-shaven, the other dark and bearded and in Colonial-era coat, breeches, and stockings. @{(memphis_chance_encounter = "siobhan") You recognize them from the tavern the other night.|} Though they smile and laugh at the approach of others, they are clearly close allies. At the moment, they are speaking with 
	*if heard_of_malloy or met_malloy
		Siobhan Malloy, the candidate, who sticks out like a sore thumb, all laughter and red hair
	*else
		an Irishwoman, all laughter and red hair, who sticks out like a sore thumb
	among the otherwise dour vampires.
*if met_lockridge or (heard_of_lockridge or (met_coffin or heard_of_coffin))
	*if met_coffin or heard_of_coffin
		*if met_lockridge or heard_of_lockridge
			You see Senator Lockridge, deep in discussion with Senator Coffin and @{met_pickering Absalom Pickering, the candidate|another man}.
			*if heard_of_pickering and (met_pickering = false)
				From what you have heard, this other man must be Absalom Pickering, the candidate.
		*else
			You see Senator Coffin, deep in discussion with a gentleman from the Carolinas and @{met_pickering Absalom Pickering, the candidate|another southern man}.
			*if heard_of_pickering and (met_pickering = false)
				From what you have heard, this other man must be Absalom Pickering, the candidate.
	*else
		*if met_lockridge or heard_of_lockridge
			You see Senator Lockridge, deep in discussion with the Puritan woman and @{met_pickering Absalom Pickering, the candidate|another southern man}.
			*if heard_of_pickering and (met_pickering = false)
				From what you have heard, this other man must be Absalom Pickering, the candidate.
*if (met_lockridge = false) and ((heard_of_lockridge = false) and ((met_coffin = false) and (heard_of_coffin = false)))
	You see a woman, dressed in the clothes of a Puritan, deep in conversation with a gentleman from the Carolinas and @{met_pickering Absalom Pickering, the candidate|another southern man}.
	*if heard_of_pickering and (met_pickering = false)
			From what you have heard, this other man must be Absalom Pickering, the candidate.
A fourth person—a woman in fashionable attire—listens absent-mindedly.
*if met_chiara
	Senator Santagostino is speaking animatedly with another man.
	*if (lore > 2) or ((intelligence > 2) or able_to_identify_jews)
		*set able_to_identify_jews true
		This man, on the other hand, wears the kippah and payot of a child of Israel.
		*if heard_of_lesczynski
			After a moment of consideration, you realize that this must be Ascher Lescyznski, the candidate.
		*if (rationalism > 80) and (religious_tradition != "pagan")
			Try as you might, you can detect no horns atop his head.  Perhaps they are hidden by his headwear?
	*else
		He, on the other hand, has a funny sort of hat on his head and curls of hair sprouting from his temples.
*elseif (heard_of_chiara_santagostino)
	You see an Italian woman deep in conversation with another man.  You wonder if this might be Senator Santagostino of New Orleans?
	*if (lore > 2) or ((intelligence > 2) or able_to_identify_jews)
		*set able_to_identify_jews true
		The man, on the other hand, wears the kippah and payot of a child of Israel.
		*if heard_of_lesczynski
			After a moment of consideration, you realize that this must be Ascher Lescyznski, the candidate.
		*if (rationalism > 80) and (religious_tradition != "pagan")
			Try as you might, you can detect no horns atop his head.  Perhaps they are hidden by his headwear?
	*else
		He, on the other hand, has a funny sort of hat on his head, and has curls of hair sprouting from his temples.
*else
	There is also a woman of perhaps Lombard or Piedmontese extraction, speaking with
	*if (lore > 2) or ((intelligence > 2) or able_to_identify_jews)
		*set able_to_identify_jews true
		a man who wears the kippah and payot of a child of Israel.
		*if heard_of_lesczynski
			After a moment of consideration, you realize that this must be Ascher Lescyznski, the candidate.
		*if (rationalism > 80) and (religious_tradition != "pagan")
			Try as you might, you can detect no horns atop his head.  Perhaps they are hidden by his headwear?
	*else
		a man who wears a funny sort of hat on his head, with curls of hair sprouting from his temples.

*if invitation_to_reception_accepted = false
	*set carothers_rapport %-5
	Before you can speak with anyone, Applethorp accosts you.
	*if speaks_english
	
		"You dune came."
		
		"I did. Is that such a surprise?"
		
		"Wul, you didn' come when Apallah axked you tah."
		
		@{(independence > 50) "Please extend my apologies to the Quaestor."|"I'm here now, aren't I?"}
		
		Applethorp looks at you carefully. "Ah wul lets him know."
		
		Your chastisement concluded, you turn your attention back to the guests. It takes you some time to consider each of these vampires in turn.  Which of them will be your enemies, and which your purported allies?
	*else
		*set applethorp_rapport %-5
		She has Hermes in tow. She speaks to him in an exasperated manner; he listens to her carefully, and then turns his ruddy face to you.
		
		"Mistress Applethorp is surprised to see you here. After all, you did not reply to the missive that I hand-delivered to you."
		
		@{(independence > 45) "I wouldn't miss it."|"Should I go?"}
		
		Hermes translates your response. Applethorp scowls at you. She turns on her heel and returns to her guests.
		
		"You are welcome to stay, @{male suh|ma'am}."
		
		You nod at Hermes and he excuses himself. Your chastisement concluded, you turn your attention back to the guests. It takes you some time to consider each of these vampires in turn.  Which of them will be your enemies, and which your purported allies?
*elseif party_preparations >= 3

	*set carothers_rapport %+20
	*set santagostino_rapport %+10
	*set coffin_rapport %+10
	*set lockridge_rapport %+10
	*set lesczynski_rapport %+10
	*set malloy_rapport %+10
	*set bailey_rapport %+10
	*set partridge_rapport %+10
	*set pickering_rapport %+10
	*set thank_carothers_thought false
	Carothers, standing amidst several other individuals, claps his hands at the sight of you.  His voice booms through the room as he addresses you.  All turn in your direction.
	
	"${mr} ${surname}!  What a wonderful event you have organized for us!"
	
	*if discretion < 60
		*set circle_presence true
		"You do me too much honor, Quaestor."
		
		"Come now, you have thrown a magnificent soirée.  We must enjoy it!"  He gestures for you to join his circle.
		*if party_preparations > 3
			*set earned_status true
	*elseif discretion <= 80
		*set applethorp_rapport %-10
		*set carothers_rapport %-10
		"I am grateful that you had the good sense to listen to me.  Who knows what sort of churchyard we would be meeting in, were it not for me?"
		
		You do not say this so loud that the whole room can hear, but those nearby certainly can.  Certainly Dido does, as her skin turns several shades paler in the aftermath of your barbs.  Carothers' eyes narrow at you before he finally grumbles out a response: "Well, we are all grateful for your indulgence."
		
		"I am glad to hear it."
		*if party_preparations > 3
			*set earned_status true
	*else
		*set applethorp_rapport %-25
		*set carothers_rapport %-10
		"Well, I couldn't very well let your miserable offspring go and put on this soirée; not with your most esteemed guest list, anyway."
		
		Dido's skin turns several shades lighter at this outright insult to her and her dominus.  Carothers himself seems to barely be able to choke back his own surprise at your hubris.  "Well, we are all grateful for your indulgence."
		
		"I am glad to hear it."
		
		The gathered vampires are clearly in agreement with the quaestor
		*if party_preparations > 3
			*set earned_status true
			over your audacity, yet cannot offer reproach: the soirée truly is fantastic.
		*else
			with regard to your audacity, but the quality of the soirée dissuades them from offering reproach.
*elseif speaks_english and (party_preparations >= 2)

	From somewhere amongst the crowd, Dido appears.  "${mista} ${surname}!  Ahs so glad yous ah here!  You done a ma'velous job with the fete!"
	
	*if (discretion > 70) and (applethorp_rapport < 40)
		"Did you really expect something different?"
		
		"Ah…ah don' unna'stan…"
		
		*if (ethnicity = "african") and (compassion < 60)
			*set applethorp_rapport %-10
			"Pay attention now, sister: I do what needs doing."
			
			"Ah does wut needs doin'!"
			
			"Den you bedda gwine learn deh buckrah-talk."
			
			She's almost startled by your transition to patois.  "Ah don' need deh buckrah-talk down Memphis-town."
			
			"Memphis and the Society are two very different places, Ms. Applethorp.  Take it from me, you'd best learn, and learn quick."
			
			She nods, considering this, before wandering away.
		*else
			*set applethorp_rapport %-20
			"When I am given something to do, I do it.  I suppose that is outside your typical experience."
			
			Hatred flashes behind the eyes of Dido.  "Ah s'pose ah gwine git learnd fom you.  An Ah aint gwine fuhget," she mutters as she departs.
	*elseif (applethorp_rapport > 60) and (compassion < 50)
		*set applethorp_rapport %+5
		"You are too kind, Dido."
		
		"You don' gotta sey dat.  It da truth."
		
		"Thank you, all the same."  The two of you exchange a few more pleasantries before parting ways.
	*else
		"Thank you, Ms. Applethorp.  It did take some effort, but as you can see, it paid off."
		
		"Deh Quaestor, he real happy wid you for dis."
		
		You nod in acknowledgment.  The two of you exchange a few more pleasantries before parting ways.
*elseif (memphis_reception_planner = given_name) and (party_preparations = 0)
	
	*set carothers_rapport %-50
	*set discretion %-30
	*set party_foul true
	*set thank_carothers_thought false
	You are alerted to the presence of Carothers by a smothered growl.  "What have you done, ${mr} ${surname}?"

	"What do you mean, Quaestor?"

	"This is a disaster!" he says, gesturing to the room.

	Looking around, with eyes suddenly clear, you realize that he is right.  It is a disaster.  The décor does not match the venue, the footmen are inappropriately dressed, the music is out of fashion…in short, every misstep that you could have made, you made.

	You do your best to apologize to Carothers, but he will have none of it.  He soon stalks away, clearly livid at how you have embarrassed him.
*elseif (acquiring_vessels = "success") and speaks_english

	From somewhere in the crowd, Dido appears.  She inclines her head slightly, indicating her desire to speak with you privately.
	
	"The Quaestor wan for you know how grateful he was for you helpin' 'im."
	
	"It was nothing, Ms. Applethorp."
	
	"So you be sayin', ${mista} ${surname}.  Now, Ah gwine see dem bout de 'lection…"  Your brows furrow as you wonder whether she meant that as a slight or as a complement.
	
	"But of course," you reply, stepping aside for her to pass.
	*page_break
*else
	
	It takes you some time to consider each of these vampires in turn.  Which of them will be your enemies, and which your purported allies?

*if (perception > 1) and ((rumors_of_plague = false) and speaks_english)
	*set rumors_of_plague true
	
	As you slide through the room, you cannot help but overhear some of the conversations being held around you. The most interesting of these seems to be the one between 
	*if heard_of_bailey or met_bailey
		Senators Partridge and Bailey, who are expressing their relief that refreshments are being provided by Quaestor Carothers.
	*else
		the two male vampires who stand so close together.  They are expressing their relief that refreshments are being provided by Quaestor Carothers.
	It seems that several of the servants hired to tend their shared accommodations for their visit have fallen ill.  Whatever the cause of this illness is uncertain, but it does have them perturbed.

*if avoided_new_orleans
	*if met_jesse
		By chance, you happen to settle your gaze on the main entrance just as he enters.  It has been several decades since you met him in St. Charles parish,
		*if jesse_is_broodmate
			but the sight of your broodmate brings a chill to your spine.  Within a few minutes, he catches sight of you as well and shortly makes his way towards you.
		*else
			so you are somewhat surprised at how clearly you recognize the progeny of the Quaestor of New Orleans, Jesse Whitaker.
		
		"It has been some years, ${jesse_toa}.  I trust they have treated you well?" he begins.
		
		"Well enough," you reply.
		
		"What brings you to Memphis?" he inquires politely.
		
		"Other than an election, you mean?"
		
		"Considering your affection for the swamp, I can't imagine that you decided to grace us with your presence for such a purpose."
		
		*if independence < 50 
			"Give me time. I may very well return to the bayou."
			
			"I'm holding my breath!" he exclaims.
		*else
			"I'm sorry that you have such a low opinion of me, Mr. Whitaker."
		
			"One of my favorite pairs of boots were ruined by that trip to your horrid home!" he says.
		*if jesse_is_broodmate
			"Now, we may be broodmates, but I'm afraid I have business to conduct. Please excuse me."
			
			You nod with as much grace as you can summon.
		*else
			"If there's nothing else?" he finishes.
			
			You shake your head, ready to be done with the conversation yourself.
	*else
		By chance, you happen to settle your gaze on the main entrance to the room just as he enters.  You are not sure what draws your gaze so ardently towards him, but drawn it is.
		
		Apparently, however, you are not the only one to notice his arrival.
		*if met_chiara
		
			"He is breathtaking, isn't he?"	Turning ever so slightly, you see Senator Santagostino gliding up to stand beside you.
				
			"Quite.  Who is he?"
		*else
			*set met_chiara true
		
			"He is breathtaking, isn't he?"	Turning ever so slightly, you see the Italian woman gliding up to stand beside you.
			
			"And you are?"
			
			"Senator Santagostino, of New Orleans."
			
			"An honor, Senator.  I am ${given_name} ${surname}, offspring of ${sire_name}."  She bows at this.  "So, who is he?"
			
		*if jesse_is_broodmate
			Chiara is so surprised that she actually draws breath.  "Why, that is Jesse Whitaker, your broodmate!"
			
			"My broodmate?"
			
			"Why, yes!  The offspring of ${sire_name}.  He has spent much of the past fifty years in New Orleans."
			
			"What is he doing here?"
			
			"No doubt trying to make a name for himself in the Society.  What else would he be doing?"  She pauses a moment.  "Come, you must meet him!"  Taking your hand, Chiara drags you towards Jesse.
		*else
			"That is Jesse Whitaker, the offspring of ${jesse_sire_name}."
			
			"He is from New Orleans, then?"
			
			*if jesses_sire_formerly_quaestor
				"He was until his dominus was replaced as Quaestor by Consul Stone, yes."
			*else
				"He has spent much of the past fifty years there, yes."
			
			"What is he doing here?"
			
			"No doubt trying to make a name for himself in the Society.  What else would he be doing?"  She pauses a moment.  "Come, you must meet him!"  Taking your hand, Chiara drags you towards Jesse.
		*page_break
		*set met_jesse true
		*if jesse_is_broodmate
			*set jesse_rapport %+10
			Chiara can barely contain herself.  "Jesse!"  You are being dragged along by the sheer force of her buoyancy.
			
			Jesse turns.  "Yes, Senator?"
			
			"I have someone I want you to meet!"
		
			"Oh?"
			
			"Jesse Whitaker, allow me to introduce ${given_name} ${surname}.  Your broodmate."
			
			Several vampires in the vicinity go still at this statement.  Jesse himself barely skips a beat.  "${mr} ${surname}!  What a pleasure to finally make your acquaintance!"
			
			"And I yours," you reply with a ${bow}.
			
			"Tell me, how is it that we have never met, and yet we share a maker?"
			
			"Our maker and I did not see eye-to-eye."
			
			"Nor did I with him," he says, chuckling.
		*else
			"Jesse," begins Chiara, "may I introduce ${given_name} ${surname}.  I believe ${he} is from New Orleans, originally."
			
			"That is correct, Senator."
			
			"And yet, I have never seen you there?"
			
			"I did not visit after joining the Society."
			
			"Ah, yes.  But you did reside nearby, did you not?"
			
			*if met_estefania
				"I did.  I believe your maker, the Quaestor, sent Sra. Rios to call on me in St. Charles parish."
				
				"He did indeed.  Well, it is good to finally make your acquaintance."
				
				"Agreed."
				
			*else
				*set jesse_rapport %-5
				"I did."
				
				"There was some unfortunate business with the slaves…"
				
				"What about it?"
				
				"Well, from what I understand, the matter was quickly resolved. But then there was no further word of you!"
				
				"Well, here I am, Mr. Whitaker."
				
				"So I see," Jesse replies.
			"What brings you to Memphis, ${mr} ${surname}?"
			
			"I suppose you could say that I am here seeking a house and a home…as does every vampire."
			
			"Well, your home shall soon have a new neighbor."
			
			"That is true."
			
			"Do you think it will be me?"
			*choice
				#"I certainly hope so."
					*label flatter_jesse
					*set jesse_rapport %+5
					"Ah, idle flattery.  I love it, even if it means nothing."
					
					You smile back at him knowingly.  "What else could I have said?"
					
					"I suppose so, but it still pleasing to hear it," he says, flashing you a grin which he has no doubt spent altogether too much time practicing in the mirror.
				*selectable_if (discretion > 30) #"I hope to be made Senator."
					*label player_for_senator
					*set discretion %+5
					*if status > 2
						*set player_for_senator true
						*set jesse_rapport %+5
						Jesse looks at you long and hard.  "I suppose that is not outside the realm of possibility; I hear that you have made quite a name for yourself in the Society, after all."
						
						"Yes, and I intend to capitalize on that."
						
						"And capitalize you must, ${jesse_toa}, for you have a long battle before you."
					*else
						*set jesse_rapport %-5
						"Oh, hear you this?  Tell me, ${mr} ${surname}," he declares in the most mocking tone he can summon, "what do you bring to the table?  What friends do you have in the Senate?  What powers do you call your own?
						
						"My talents…"
						
						"It takes far more than talent and pluck to be a Senator, ${jesse_toa}," interjects, brushing away your dreams with a sweep of his hand.
				*if heard_of_pickering or (heard_of_malloy or heard_of_lesczynski)
					#"Actually, I think that someone else is better suited for the position…"
						*set discretion %+5
						"Oh, truly?  Who would that be?"
						*choice
							*if heard_of_lesczynski
								#"Ascher Lesczynski."
									"What recommends him?"
									
									"That he is puppet of neither Adonis nor Stone."
									
									"An interesting position to take, ${jesse_toa}.  Admirable, if perhaps naïve."
									*if (jesses_revolutionary_credentials < 60) and (jesses_revolutionary_credentials > 40)
										*set jesse_rapport %+5
							*if heard_of_malloy
								#"Siobhan Malloy."
									*set revolutionary_credentials %+10
									"I did not realize support for Stone's revolution was so widespread."
									
									"It is."
									
									"So I see."
									*if jesses_revolutionary_credentials > 60
										He flashes you that grin of his, which seems to say that all is right in the world.
										*set jesse_rapport %+10
									*if jesses_revolutionary_credentials < 40
										A cloud seems to form over Jesse's thoughts, as he considers your position.
										*set jesse_rapport %-10
							*if heard_of_pickering
								#"Absalom Pickering."
									*set revolutionary_credentials %-10
									"I did not realize the opposition to Stone's revolution was so widespread."
									
									"It is."
									
									"So I see."
									*if jesses_revolutionary_credentials < 40
										He flashes you that grin of his, which seems to say that all is right in the world.
										*set jesse_rapport %+10
									*if jesses_revolutionary_credentials > 60
										A cloud seems form over Jesse's thoughts, as he considers your position.
										*set jesse_rapport %-10
							#"Actually, you're right, I think you would be best suited to the position."
								Jesse seems surprised by your change of heart, but that does not stop him from enjoying his little victory.
								*goto flatter_jesse
							*selectable_if (discretion > 30) #"Actually, I think that I am the one best suited for the position.
								*goto player_for_senator
				*selectable_if (discretion < 80) #"I cannot say.  I am only recently acquainted with these affairs."
					*set discretion %-5
					*set jesse_rapport %+5
					"How very coy of you, ${jesse_toa}."
					
					"There are many ears in this room, Mr. Whitaker."
					
					"That there are, that there are," he says, casually looking around for any obvious eavesdroppers.

		*if jesse_is_broodmate
			"Considering we are spawned from the same primordial ooze, don't you think we should become better acquaintances?"
		
			You pause a moment to consider what you know of Jesse and what sort of outing he might enjoy.
			*gosub ask_jesse_out
		*else
		
			"Well, it was a pleasure meeting you, Mr. Whitaker.  Perhaps we shall have a chance to speak again soon?"
			
			"Yes, that would be delightful.
			*if jesse_for_senator
				Now go and see that I gain my seat."
				
				"I most certainly shall."
			*elseif player_for_senator
				Now, I'm sure you have some arms to twist if you are to have any chance at winning this election."
				
				"You speak truly, Mr. Whitaker."
			*else
				Now, if you will excuse me, I have much still to accomplish this evening."
				
				"Of course."
*else
	*page_break
	You feel it when he enters the room.  Turning your head, you immediately lock eyes with Jesse Whitaker.
	
	And he too senses your presence, as his eyes rise without hesitation to meet yours.  The memories come back:
	*if clotho_ordered_killed
		the execution of Clotho,
	*if withers_embarrassed
		the embarrassment of Samantha,
	*elseif ((avoided_new_orleans = false) and (exiled_from_new_orleans = false))
		his embarrassment by Samantha Withers,
	*if exiled_from_new_orleans
		and your exile from the city.
	*elseif (jesse_rapport < 40)
		and the rivalry which eventually drove you from the city.
	*elseif (jesse_rapport < 60)
		and the strained goodbyes as you took your leave of New Orleans.
	*else
		and the fond farewells as you left the Crescent City.
	The decades have refined him somewhat.  He stands a little taller, his swagger is a little more pronounced.  His smile is mostly unchanged.
	*if circle_presence
		Excusing yourself from the company of the quaestor, you approach him.
	
	"It has been some years, ${jesse_toa}.  I trust they have treated you well?" he begins.
	
	*if discretion > 60
		*if exiled_from_vicksburg = false
			"I have managed to avoid any serious embarrassments since we parted."
			
			"I am glad to hear it.  You learned something from our time together, then?"
			
			"I'm not sure that avoiding embarrassment would be one of those things."
			
			"[i]Touché[/i]," he replies, flashing you his signature grin.
		*elseif exiled_from_vicksburg and exiled_from_new_orleans
			"It seems that my tendency to offend other members of the Society continues; I am recently fled from Vicksburg."
			
			"Exiled from not one but two cities?  My, you have been busy!" he remarks, before flashing you his signature grin.  "I would expect nothing less of you."
			
			You clench your jaw and try not to let the beast whisper too many calls for violence in your ear. But that grin—you would love to tear those lips from that face.
		*else
			*if withers_embarrassed
				"I should have paid better attention to your treatment of Withers."
				
				"Oh?"
				
				"Yes.  I spent some time with her in Vicksburg and found her to be as wretched as you."
				
				"Still so young," he says, flashing his signature grin.  "I suppose there is only one cure for stupidity."
				
				"And this is not the place to discuss that cure!"
				
				"No, of course not," he says, preparing to change the subject.
			*else
				*set jesse_rapport %+5
				"I made the mistake of following Withers to Vicksburg."
				
				"Whatever you experienced there was your own doing.  I tried to warn you about her."
				
				"And I failed to listen."
				
				"Perhaps next time you will consider my words more carefully?"
				
				"You can count on it," you reply.
				
	*elseif (discretion >= 40)
		"No doubt better than they have treated you," you reply with a smile.
		
		*if jesses_sire_formerly_quaestor
			*if jesse_sire_name = "Padre Carlos"
				"The choice of dear Padre Carlos to be the new Praetor was an interesting one, I will grant you that."
				
				"How does New Orleans fare without him?"
				
				"Heer Van der Velde is competent.  Yet, the city prospered under the Padre, and his presence is missed."
				
				"I understand," you reply.
				
			*else
				*set jesse_rapport %-5
				"Do not gloat.  It is unbecoming."
				
				"I meant nothing…"
				
				"The deposition of @{jesse_is_broodmate our|my} dominus was unfortunate for New Orleans as a whole, not just for he and I."
					
				"Of course, my apologies," you reply, looking for a way to change the subject.
				
		*else
			"I doubt that.  ${new_orleans_quaestor_address} flourishes, and I benefit from it."
			
			"You remain on good terms with him?"
			
			"As good as is possible," he replies with his signature grin.
	*else
		"They have treated me well enough."  He seems unfazed by your reservation.
		
		"So I see." He pauses a moment.
	"@{(jesse_rapport > 55) It's been a pleasure catching up, but if|If} you'll excuse me, I @{(jesse_rapport > 55) can't spend the whole evening gabbing with you|do have some business to attend to.}"

*label what_is_happening
*page_break
*if voting_explained
	Surveying the room, you consider whom you should approach.
	*goto choice_of_conversation
Casting about for an opening, you are forced to confront how isolated you are in the Society. It certaily feels that way right now, in this room. The thought occurs to you that perhaps you should inquire as to how the election will proceed.

*choice
	#I ask @{(jesse_rapport > 55) Jesse|Whitaker}—though it is likely to annoy him.
		*set voting_il_name "Jesse"
		*set voting_il_address "Mr. Whitaker"
		*if jesse_rapport > 50
			*set voting_il_address "Jesse"
		*goto voting_procedure
	*selectable_if (carothers_rapport > 40) #@{(carothers_rapport > 45) I ask Carothers|I would ask Carothers, but his glares tell me not to}.
		*set voting_il_name "Apollo"
		*set voting_il_address "Quaestor Carothers"
		*goto voting_procedure
	*selectable_if (speaks_english) #I ask Applethorp.
		*set voting_il_name "Dido"
		*set voting_il_address "Miss Applethorp"
		*set voting_il_he "she"
		*set voting_il_him "her"
		*set voting_il_his "her"
		*goto voting_procedure_dido
	*if met_chiara
		*selectable_if (santagostino_rapport > 40) #I ask Senator Santagostino.
			*set voting_il_name "Chiara"
			*set voting_il_address "Sig.ra Santagostino"
			*set voting_il_he "she"
			*set voting_il_him "her"
			*set voting_il_his "her"
			*goto voting_procedure
	*if met_lockridge and (speaks_english or speaks_french)
		*selectable_if (lockridge_rapport > 40) #I ask Senator Lockridge.
			*set voting_il_name "Arthur"
			*set voting_il_address "Senator Lockridge"
			*set voting_il_he "he"
			*set voting_il_him "him"
			*set voting_il_his "his"
			*goto voting_procedure
	#I try to strike up a conversation with a stranger.
		There are so many individuals here!  How will you choose from among them?

		You spend some time surveying the crowd, trying to understand its ebb and flow.  After a time, you identify several individuals who seem like they might be approachable.

		*if (lore > 2) or ((intelligence > 2) or able_to_identify_jews)
			There is a Jewish man in the kippah and curls of his people.  He is clearly working the room, shaking hands and conversing with as many as possible.  
		*else
			There is a male vampire, wearing a round head-covering, and sporting curls that sprout from his temples.  He is clearly working the room, shaking hands with as many people as possible.
		*if met_chiara
			Senator Santagostino is here, of course.
			*if santagostino_rapport > 50
				At one point, you catch her eye, and she nods in greeting.
		*else
			There is a woman, probably from Provence, Piedmont, or Lombardy.
			*if heard_of_chiara_santagostino
				After a moment's reflection, the thought occurs to you that this might be Chiara Santagostino, the Senator of New Orleans.

		Whom do you approach?
		*label approach_interlocutor
		*choice
			#@{able_to_identify_jews The Jewish man in the kippah.|The bearded man with the hat and curls.}
				*set met_lesczynski true
				*set heard_of_lesczynski true
				*set voting_il_name "Ascher"
				*set voting_il_address "Mr. Lesczynski"
				*goto voting_procedure
			*if (met_chiara = false) and (heard_of_chiara_santagostino = false)
				#The Italian woman.
					*set met_chiara true
					*set heard_of_chiara_santagostino true
					*set voting_il_name "Chiara"
					*set voting_il_address "Sig.ra Santagostino"
					*set voting_il_he "she"
					*set voting_il_him "her"
					*set voting_il_his "her"
					*goto voting_procedure_senator
			*if (met_chiara = false) and heard_of_chiara_santagostino
				#The woman whom I imagine to be Chiara Santagostino.
					*set met_chiara true
					*set heard_of_chiara_santagostino true
					*set voting_il_name "Chiara"
					*set voting_il_address "Sig.ra Santagostino"
					*set voting_il_he "she"
					*set voting_il_him "her"
					*set voting_il_his "her"
					*goto voting_procedure_senator
			*if met_chiara
				#Chiara Santagostino.
					*set met_chiara true
					*set heard_of_chiara_santagostino true
					*set voting_il_name "Chiara"
					*set voting_il_address "Sig.ra Santagostino"
					*set voting_il_he "she"
					*set voting_il_him "her"
					*set voting_il_his "her"
					*goto voting_procedure_senator
			*if heard_of_harding = false
				#The fashionably dressed white woman.
					*if (ethnicity = "african") or (ethnicity = "choctaw")
						*label harding_prejudice
						*set rebuffed_by_harding true
						*set harding_rapport %-15
						As you approach the woman, you feel her effortless move to cut you off from addressing her.  You try again to maneuver your way into her view, but almost as if by magic, you find yourself completely unable to do so.
						*if discretion > 60
							*set harding_rapport %-10
							Frustrated, you decide to just address her.
	
							"Pardon me, ma'am…" you begin.
	
							The woman turns and stares at you.  Suddenly, you feel very small.
	
							*if speaks_english
								"It is unfortunate…not only that your dominus made you, but that he was so short-sighted as to fail to instruct you in the rules of etiquette.  If someone excludes you from a conversation, you should understand that they do not wish to speak to you.  And believe me, I would never want to speak to one such as you."  She is nearly spitting as she says these words.
		
								Stunned by this attack, you back away, trying to end this confrontation as quickly as possible.  Once you are far enough away, she turns and does her best to put you from her mind.
							*else
								She says something to you in English, and while you cannot understand the words, you understand the gist: you are not welcome in her presence.
								
								Stunned by this attack, you back away, trying to end this confrontation as quickly as possible.  Once you are far enough away, she turns and does her best to put you from her mind.
						*else
							You decide it best to try someone else.
					*else
						*set carothers_rapport %-5
						@{(perception > 1) You can feel Carothers' eyes on you as you approach this woman.|}
	
						After introducing yourself, she introduces herself in turn: she is Elinor Harding, Quaestor of Louisville.  Inspecting her features, you estimate that she must have been turned into a vampire while in her early thirties; even so, though, her face is lined with cares.
						*if heard_of_harding
							This must be Carothers' broodmate, the one of whom he spoke so harshly. @{(perception > 1) Now you understand why he was glaring at you.|}
						*set met_harding true
						*if (revolutionary_credentials < 40) and (carothers_rapport < 45)
							*set harding_rapport %+5
							"I have heard something of you, ${mr} ${surname}."
	
							"Oh?"
	
							"Yes…and, if it's a tutorial in the mechanism of the election, I believe that I could spare you a few moments to explain."
	
							"That would be most appreciated, Quaestor Harding."
							*set voting_il_name "Elinor"
							*set voting_il_address "Quaestor Harding"
							*set voting_il_he "she"
							*set voting_il_him "her"
							*set voting_il_his "her"
							*page_break
							*goto voting_procedure
						*else
							*set harding_rapport %-5
							Perhaps someone else will be more helpful?
							
							Her reception of you is chilly, to say the least.  You decide it best not to ask her about the mechanism of the election and quickly excuse yourself from the conversation.
					*goto approach_interlocutor
			*else
				#Elinor Harding, Quaestor of Louisville.
					*if (ethnicity = "african") or (ethnicity = "choctaw")
						*goto harding_prejudice
					*else
						*set carothers_rapport %-5
						You can feel Carothers' eyes on you as you approach Harding.
						
						*set met_harding true
						*if (revolutionary_credentials < 40) and (carothers_rapport < 45)
							*set harding_rapport %+5
							After introducing yourself, she immediately takes control of the conversation.  "I have heard something of you, ${mr} ${surname}."
	
							"Oh?"
	
							"Yes…and, if it's a tutorial in the mechanism of the election, I believe that I could spare you a few moments to explain."
	
							"That would be most appreciated, Quaestor Harding."
							*set voting_il_name "Elinor"
							*set voting_il_address "Quaestor Harding"
							*set voting_il_he "she"
							*set voting_il_him "her"
							*set voting_il_his "her"
							*page_break
							*goto voting_procedure
						*else
							*set harding_rapport %-5
							Her reception of you is chilly, to say the least.  You decide it best not to ask her about the mechanism of the election and quickly excuse yourself from the conversation.
							
							Perhaps someone else will be more helpful?
							*goto approach_interlocutor
			*if met_partridge or heard_of_partridge
				#Senators Partridge and Bailey.
					*goto voting_procedure_partridge_and_bailey
			*if (met_partridge = false) and (heard_of_partridge = false)
				#The two gentlemen who seem so conspiratorial.
					*goto voting_procedure_partridge_and_bailey
			*if (met_lockridge = false) and (heard_of_lockridge = false)
				#The gentleman from the Carolinas.
					*set met_lockridge true
					*set heard_of_lockridge true
					*set voting_il_name "Arthur"
					*set voting_il_address "Senator Lockridge"
					*goto voting_procedure_senator
			*if (met_lockridge = false) and (heard_of_lockridge)
				#The gentleman from the Carolinas who must be Senator Lockridge.
					*set met_lockridge true
					*set voting_il_name "Arthur"
					*set voting_il_address "Senator Lockridge"
					*goto voting_procedure_senator
	*selectable_if (discretion > 55) #I don't need anyone's guidance!  "Come, where are the ballots!  Let us vote!"
		*set revolutionary_credentials %+10
		*if (jesse_rapport > 55) and (avoided_new_orleans = false)
			*set voting_il_name "Jesse"
			*set voting_il_address "Jesse"
			*set jesses_revolutionary_credentials %+5
			Jesse's sense of hearing always was spectacular.  Almost before you've opened your mouth, he is beside you, trying to prevent you from finishing your sentence, but to no avail; several of the vampires in your vicinity took note of your rather crass proclamation.  You can almost feel the chill as they turn ever so slightly further away from you.

			"Yes!  We'll vote for our favorite cuisine!" Jesse chimes in.  The attempt at obfuscation fools no one, but his demonstration of loyalty surely counts for something.  In the meantime, Jesse has grabbed your elbow and is whispering for you to be silent.  "Has no one explained to you how this works?"

			"No." @{(memphis_reception_planner = "Harriet") The temperance workers who are still tending to the needs of the guests frown at you, clearly assuming your outburst to be the result of drink.|}

			"Here.  Be silent for a moment and listen."
			
			"Very well."
			*page_break
			*goto voting_procedure
		*elseif carothers_rapport > 50
			*set voting_il_name "Apollo"
			*set voting_il_address "Quaestor Carothers"
			*set carothers_rapport %-5
			"Are you mad?" hisses Carothers from somewhere behind you.
			
			"What?"
			
			"Are you trying to embarrass me?"
			
			"No, I simply want…"
			
			"Do you know nothing?  Be quiet for a moment and listen."  You pause, waiting for him to begin.
			*goto voting_procedure_terse
		*elseif speaks_english
			*set carothers_rapport %-5
			As you begin your outburst, you notice that Carothers has already sent Dido to contain any damage you might cause.

			"${Mista} ${surname}!" she says, attempting to distract you from your decided course of action. @{(memphis_reception_planner = "Harriet") The temperance workers who are still tending to the needs of the guests frown at you, clearly assuming your outburst to be the result of drink.|} "Let me 'splain some thin's to you," she continues.

			Momentarily mollified, you allow her to begin.
			*set voting_il_name "Dido"
			*set voting_il_address "Miss Applethorp"
			*set voting_il_he "she"
			*set voting_il_him "her"
			*set voting_il_his "her"
			*goto voting_procedure_dido_terse
		*elseif (frenzied_on_santagostino = false) and ((santagostino_rapport > 40) and (met_chiara))
			*set santagostino_rapport %-5
			As you begin your outburst, you realize that Santagostino has already moved to silence you.
			
			"${mr} ${surname}, I do not think this is the time or the place…"
			
			"I'm sorry?" @{(memphis_reception_planner = "Harriet") The temperance workers who are still tending to the needs of the guests frown at you, clearly assuming your outburst to be the result of drink.|}
			
			"Has no one explained the course of the election to you?"
			
			"No…"
			
			"Then be silent for a moment, and let me do so…"
			*set voting_il_name "Chiara"
			*set voting_il_address "Sig.ra Santagostino"
			*set voting_il_he "she"
			*set voting_il_him "her"
			*set voting_il_his "her"
			*goto voting_procedure_senator_terse
		*else
			*set pickering_rapport %-5
			*set voting_il_name "Absalom"
			*set voting_il_address "Mr. Pickering"
			As you begin your outburst, you realize that
			*if met_pickering or heard_of_pickering
				Absalom Pickering
			*if (met_pickering = false) and (heard_of_pickering = false)
				a man whom you have not yet met
			has already moved to silence you.
			
			"This is neither the time nor the place…"
			
			"I'm sorry?" @{(memphis_reception_planner = "Harriet") The temperance workers who are still in the room, tending to the needs of the guests, frown at you, clearly assuming your outburst to be the result of drink.|}
			
			"Has no one explained the course of the election to you?"
			
			"No…
			*if heard_of_pickering and (met_pickering = false)
				*set met_pickering true
				and who are you, anyway?"  As if you didn't know…but forms must be observed.
				
				"Absalom Pickering, and I intend to win this election."
				
				"That doesn't sound like the way you should treat a possible supporter."
				
				"You're not a Senator, so your support is relatively unimportant.  Now, be silent for a moment, and let me explain this to you…"
				
				"Yes, please, explain."
				*goto voting_procedure_terse
			*elseif (met_pickering = false) and (heard_of_pickering = false)
				*set met_pickering true
				*set heard_of_pickering true
				and who are you, anyway?"
				
				"Absalom Pickering, and I intend to win this election."
				
				"That doesn't sound like the way you should treat a possible supporter."
				
				"You're not a Senator, so your support is relatively unimportant.  Now, be silent for a moment, and let me explain this to you…"
				
				"Yes, please, explain."
				*goto voting_procedure_terse
			*else
				but I'm sure that you will."
				
				Pickering seems to grit his teeth at this.  "I'm afraid that you are correct.  Now, if I may begin…"
				
				"Yes, please."
				*goto voting_procedure_terse
	#I am too proud to ask anyone's guidance.  Surely, my time would be better spent asking more pointed questions.
		*set independence %-5
		*set discretion %-5
		*set questions -1
		With whom, then, would you like to converse?
		*goto choice_of_conversation

*label voting_procedure
*if voting_il_name = "Jesse"
	*set jesse_rapport %-5
	"Wait, one more thing!" you call after Jesse. He returns, listens to your question, and rolls his eyes at your ignorance.
*elseif (voting_il_name = "Apollo") and (carothers_rapport <= 45)
	You can feel Apollo's baleful glare boring into you as you approach. He is clearly displeased that you are coming to him for information. You state your question as simply as you can, hoping that brevity will save you; thankfully, Carothers is interested in brevity as well.
*else
	Pleasantries having been exchanged, ${voting_il_name} does ${voting_il_his} best to answer your question in a whisper; this farce, by which ${voting_il_he} pretends to not be instructing you in the ways of the election, is undoubtedly noted by the older vampires in the room.  From what little you have observed of older vampires, their hearing definitely seems to improve with age.

*label voting_procedure_terse
*set voting_explained true
"Tomorrow night, we will gather all into one room; only members of the Society will be allowed.  We sit and gossip, as we do most nights, but the candidates will sit in prominent locations."

"What does that have to do with electing a Senator?"

"The decision is made by consensus.  Throughout the night, the vampires in the room will show their support by approaching the various candidates, chat with them a while, and then retire to their seats.  When all the Senators have spoken with the same candidate, they will ask the rest of us to leave the room, and when we are invited back in, they will have 'elected' their choice."

You pause a moment, staring at ${voting_il_him}.  "And that is how the Senator is chosen?" you say, somewhat incredulously.

"It is."

*if consul_praetor_explained = false
	*set consul_praetor_explained true
	"As long as you are educating me in the ways of the Society, I have another question," you venture.
	
	${voting_il_name} sighs.  "Yes?"
	
	"These terms, Praetor and Consul…they've been thrown about quite a bit recently…"
	*if speaks_latin or ((lore + intelligence) >= 4)
		From your extensive classical education, you know that consuls were the elected rulers of the Roman Republic—until they weren't. For generations after the transition to dictatorship, what are now called emperors continued to style themselves consuls in an attempt to maintain the illusion of representative government. Similarly, praetors were judges, appointed by consuls, to adjudicate the law. But the application of those titles here remains a mystery to you.
	
	"Go on…"
	
	"I'm afraid I do not understand them."
	
	"Have you been living under a rock?"
	
	"No, I have been in Vicksburg."
	
	${voting_il_name} lets out an exasperated growl.  "The Consul is the head of the Society.  He appoints the Governors who govern the Provinces.  The Praetor is also appointed by the Consul and travels the Provinces, rooting out treason and heresy."
	
	"Treason and heresy?"
	
	"Yes.  They are very grave crimes in the Society."
	
	"But…wouldn't Stone's murder of Praetor Miele be considered treasonous?"
	
	"Well, yes."
*if voting_il_name = "Apollo"
	You thank Carothers for the tutorial and then excuse yourself.  If you are going to effect anything here, you have limited time to gather intelligence before the election begins.  You see the opportunity to engage most of the vampires in the room in conversation.  The only question is, whom will you choose?
	*goto choice_of_conversation
*else
	*goto sort_mingle

*label voting_procedure_dido
*page_break
Pleasantries having been exchanged, ${voting_il_name} does ${voting_il_his} best to answer your question in a whisper; this farce, by which ${voting_il_he} pretends to not be instructing you in the ways of the election, is undoubtedly noted by the older vampires in the room.  From what little you have observed of older vampires, their hearing definitely seems to improve with age.

*label voting_procedure_dido_terse
*set voting_explained true
"Tamarrah nighe, we wul all git ourselves into a room; only th' mem'bers of the Societay is allowed.  We wul jus sit 'n watch, like we usually do, but the folks who wanna be 'lected wul sit in da center."

"What does that have to do with electing a Senator?"

"Theys decidin' all th' time.  All nighe long, the vampires wul show their respect by goin' up and talkin to th' hopefuls, chat wit dem a while, and then they wul go back to their seats.  When all the Senators is in agreement, they wul tell th' rest of us to git, and when they calls us back, they wul have made their choice."

You pause a moment, staring at ${voting_il_him}.  "And that is how the Senator is chosen?"

"So Ah is given ta' unnerstand."

You thank Applethorp for the tutorial and then excuse yourself.  If you are going to affect anything here, you have limited time to gather intelligence before the election begins.  You see the opportunity to engage most of the vampires in the room in conversation.  The only question is, whom will you choose?
*goto choice_of_conversation

*label voting_procedure_senator
*page_break
Pleasantries having been exchanged, ${voting_il_name} does ${voting_il_his} best to answer your question in a whisper; this farce, by which ${voting_il_he} pretends to not be instructing you in the ways of the election, is undoubtedly noted by the older vampires in the room.  From what little you have observed of older vampires, their hearing definitely seems to improve with age.

*label voting_procedure_senator_terse
*set voting_explained true
"Tomorrow night, we will gather all into one room; only members of the Society will be allowed.  We sit and gossip, as we do most nights, but the candidates will sit in prominent locations."

"What does that have to do with electing a Senator?"

"The decision is made by consensus.  Throughout the night, the vampires in the room will show their support by approaching the various candidates, chat with them a while, and then retire to their seats.  When all the Senators have spoken with the same candidate, we will ask the rest of you to leave.  When you are invited back in, we will announce the identity of the new Senator."

You pause a moment, staring at ${voting_il_him}.  "And that is how the Senator is chosen?" you say, somewhat incredulously.

"It is."

*if consul_praetor_explained = false
	*set consul_praetor_explained true
	"As long as you are educating me in the ways of the Society, I have another question," you venture.
	
	${voting_il_name} sighs.  "Yes?"
	
	"These terms, Praetor and Consul…they've been thrown about quite a bit recently…"
	*if speaks_latin or ((lore + intelligence) >= 4)
		From your extensive classical education, you know that consuls were the elected rulers of the Roman Republic—until they weren't. For generations after the transition to dictatorship, what are now called emperors continued to style themselves consuls in an attempt to maintain the illusion of representative government. Similarly, praetors were judges, appointed by consuls, to adjudicate the law. But the application of those titles here remains a mystery to you.
	
	"Go on…"
	
	"I'm afraid I do not understand them."
	
	"Have you been living under a rock?"
	
	"No, I have been in Vicksburg."
	
	${voting_il_name} lets out an exasperated growl.  "The Consul is the head of the Society.  He appoints the Governors who govern the Provinces.  The Praetor is also appointed by the Consul, and travels the Provinces, rooting out treason and heresy."
	
	"Treason and heresy?"
	
	"Yes.  They are very grave crimes in the Society."
	
	"But…wouldn't Stone's murder of Praetor Miele be considered treasonous?"
	
	"Well, yes."
*goto sort_mingle

*label voting_procedure_partridge_and_bailey
*set voting_il_name "Samson and John"
*set heard_of_bailey true
*set heard_of_partridge true
*page_break
*if met_bailey
	"Oh, good evening, ${mr} ${surname}!" begins Bailey.
	
	"Good evening, Senators," you reply.
	
	"What can we do for you this evening?" continues Partridge.	
*elseif bailey_correspondence
	"Gentlemen, allow me to introduce myself.  I am ${given_name} ${surname}," you say with a ${bow}.
	
	"Oh, I should have known!" the clean-shaven one replies. "I am John Bailey. Such a pleasure to put a face with a name."
	
	"Senator Bailey! A pleasure," you reply.
	
	"Please, this is Samson," he continues, gesturing to his companion. "I'm sure you'll get along famously."
	
	The bearded one extends his hand. "Samson Partridge, Senator of Louisville."
	
	"Senator," you reply with a @{male nod|half-curtsy}.
	
	"Tell us," Bailey continues, "what can we do for you this evening?"
*else
	"Gentlemen, allow me to introduce myself.  I am ${given_name} ${surname}," you say with a ${bow}.
	
	"A pleasure, ${mr} ${surname}.  I am Senator Bailey, of St. Louis," says the fair-haired one.
	
	"And I am Senator Partridge, of Louisville," continues the bearded one.
	
	"Are you a citizen of Memphis?" inquires Bailey.
	
	"I am, Senator.  Though I only took up residence here recently."
	
	"I thought so, as I had not yet heard of you," says Partridge.

	"Do you keep up on the residents of Memphis?" you inquire.

	*set heard_of_harding true
	"Not me so much as the Quaestor of Louisville, Elinor Harding."  Your brows furrow in confusion.  Seeing this, Partridge continues softly, "Harding and Carothers are broodmates.  She has an unhealthy obsession with him."
	
	"Yes, very unhealthy," Bailey whispers.
	
	"But you did not come for such gossip.  Tell us, what can we do for you this evening?"
*set met_bailey true
*set met_partridge true

"The election…pardon my ignorance, but how does it work?" you reply.

The two look at each other.  "Tomorrow night, we will gather all into one room," begins Bailey.
*set voting_explained true

"Only members of the Society will be allowed, of course," continues Partridge.

"We sit and gossip…"

"…as we do most nights…" Partridge interjects.

"…but the candidates will sit in prominent locations," finishes Bailey.

"What does that have to do with electing a Senator?"

"The decision is made by consensus. Throughout the night, the vampires in the room will show their support by approaching the various candidates, chat with them a while, and then retire to their seats." Partridge says.

"When we have all spoken with same candidate, the election will begin.  We will eject those who are not Senators, so that we may vote in private."

"And when we emerge, it will be to announce the new Senator," concludes Partridge.

You pause a moment, staring at ${voting_il_him}.  Your mind spins at these revelations.  "And that is how the Senator is chosen?" you say, somewhat incredulously.

"It is."

Of course, now you have the attention of the Senators.  Would you like to take this opportunity to speak further with them, or seek out someone else with whom to converse?
*goto sort_mingle_choice

*label sort_mingle
Of course, now you have the attention of ${voting_il_address}.  Would you like to take this opportunity to speak further with ${voting_il_him}, or seek out someone else with whom to converse?

*label sort_mingle_choice
*fake_choice
	#Yes, I would like to continue this conversation.
		*set questions 0
		*if voting_il_name = "Arthur"
			*goto speak_lockridge
		*elseif voting_il_name = "Chiara"
			*goto speak_santagostino
		*elseif voting_il_name = "Abigail"
			*goto speak_coffin
		*elseif voting_il_name = "Ascher"
			*goto speak_lesczynski
		*elseif voting_il_name = "Jesse"
			*goto speak_whitaker
		*elseif voting_il_name = "John"
			*goto speak_partridge_and_bailey
		*elseif voting_il_name = "Elinor"
			*goto speak_harding
		*elseif voting_il_name = "Siobhan"
			*goto speak_malloy
		*elseif voting_il_name = "Samson and John"
			*goto speak_partridge_and_bailey
		*elseif voting_il_name = "Absalom"
			*goto speak_pickering
		*elseif voting_il_name = "Dido"
			*goto speak_applethorp
		*else
			*bug
	#No, I will find someone else to speak with.
*label choice_of_conversation
*if recognition_sequence
	*set recognition_sequence false
	*if (heard_of_lockridge = false) and (lore > 3)
		*label recognize_lockridge
		*set heard_of_lockridge true
		*set already_recognized true
		Looking around the room, you realize that you can put a face with a name: the man from the Carolinas must be Arthur Lockridge, Senator of Charleston.  You have heard of the individual, but this is the first you have laid eyes on him.  He is a well-known supporter of Adonis.
	*if (heard_of_lockridge = false) and ((lore = 3) and ((heard_of_shepherds_and_wolves) or (revolutionary_credentials < 30)))
		*goto recognize_lockridge
	*if (heard_of_bailey = false) and (lore > 3)
		*label recognize_bailey
		*set heard_of_bailey true
		*if already_recognized

			You also recognize John Bailey, a fair-haired and clean-shaven vampire, as the Senator of St. Louis.
		*else
			*set already_recognized true
			Looking about the room, you realize that you can put a face with a name: the fair-haired, clean-shaven vampire must be John Bailey, Senator of St. Louis.  He is a well-known supporter of Isaiah Stone.
	*if (heard_of_bailey = false) and ((lore = 3) and (revolutionary_credentials > 70))
		*goto recognize_bailey
*if (interlocutors = 1) and ((indifferent_to_temperance_workers_plight = false) and ((memphis_reception_planner = "Harriet") or (memphis_reception_planner = "Sally")))
	*gosub temperance_incident
*set senator_count 0
*if met_bailey or heard_of_bailey
	*set senator_count +1
*if met_partridge or heard_of_partridge
	*set senator_count +1	
*if met_coffin or heard_of_coffin
	*set senator_count +1
*if met_lockridge or heard_of_lockridge
	*set senator_count +1
*if met_chiara or heard_of_chiara_santagostino
	*set senator_count +1

@{already_recognized |Surveying the room, you consider your options.}
*if thank_carothers_thought
	*set thank_carothers_thought false
	*if invitation_to_reception_accepted and (voting_il_name != "Apollo")
		The thought occurs to you that you should perhaps thank the host of the evening. However, Carothers @{(interlocutors = 0) is clearly|still seems} preoccupied with his guests and is not available at the moment.
	*if (invitation_to_reception_accepted = false)
		Thankfully, Carothers seems occupied with his guests; there does not seem to be a need to make small talk with him.
*set questions 0
*choice
	*if applethorp_unspoken and ((voting_il_name != "Dido") and speaks_english)
		#Dido Applethorp.
			*set interlocutors +1
			*if applethorp_rapport > 55
				Dido smiles warmly at your approach.
				
				"What can Ah do for ya, ${mista} ${surname}?"
			*elseif applethorp_rapport > 35
				Dido nods at your approach.
				
				"What can Ah do for ya, ${mista} ${surname}?"
			*else
				Dido can barely contain her discomfort as you approach.
				
				"What can Ah do for ya, ${mista} ${surname}?"
			*goto speak_applethorp
	*if (memphis_partridge_bailey_convo = false) and ((voting_il_name != "Samson and John") and (partridge_bailey_hidden = false))
		*if heard_of_bailey or met_bailey
			#Senator Bailey.
				*set interlocutors +1
				Whether fortunately or no, Bailey and Partridge seem inseparable.  Any conversation with him will be had with them both.
				
				Nearing them, they turn to greet you.
				*if met_bailey
					*label greeted_by_bailey_partridge
					"Hello again, ${mr} ${surname}," begins Bailey.
					
					"A pleasure as always," continues Partridge.
					
					"Gentlemen, I was wondering if we could continue our conversation…"
					
					"But of course!" says Bailey.
					
					"Please, ask away," says Partridge.
					*goto speak_partridge_and_bailey
				*elseif bailey_correspondence
					*set heard_of_partridge true
					"Senators Partridge and Bailey, I presume?"
					
					"Yes?" says Partridge.
					
					"I am ${given_name} ${surname}, a recent…"
					
					"Oh, I should have known!" Bailey interjects. "I'm John. Such a pleasure to put a face with a name."
	
					"Senator Bailey! A pleasure," you reply.
					
					"Please, this is Samson," he continues, gesturing to his companion. "I'm sure you'll get along famously."
					
					Partridge extends his hand. "Samson Partridge, Senator of Louisville."
					
					"Senator," you reply with a @{male nod|half-curtsy}.
				*else
					*label heard_of_bailey
					*set heard_of_partridge true
					"Senators Partridge and Bailey, I presume?"
					
					"You are correct," says Bailey.
					
					"You must be ${mr} ${surname}," continues Partridge.
					
					"The one and only," you reply with a grin.
					
					"Please, what can we do for you?" inquires Bailey.
				*goto speak_partridge_and_bailey
		*else
			#The fair-haired gentleman.
				*set interlocutors +1
				The fair-haired gentleman seems inseparable from his bearded companion.  Any conversation with the one will no doubt involve them both.
				
				*label unacquainted_bailey
				*set heard_of_bailey true
				*set heard_of_partridge true
				Nearing them, they turn to greet you.
				*if speaks_english = false
					*set memphis_bailey_couldnt_communicate true
					Unforutnately, when you attempt to introduce yourself, you discover that you do not share a common tongue with them.

					Frustrated, you excuse yourself.
					*goto choice_of_conversation
				
				"Good evening," the bearded one says.
				
				"Welcome," the other continues.
				
				"Please, allow me to introduce myself.  I am ${given_name} ${surname}, @{(lore > 2) scion of ${sire_name},|} citizen of Memphis."
				
				*if bailey_correspondence
					"Oh, I should have known!" Bailey replies. "I'm John. Such a pleasure to put a face with a name."
	
					"Senator Bailey! A pleasure," you reply.
					
					"Please, this is Samson," he continues, gesturing to his companion. "I'm sure you'll get along famously."
					
					Partridge extends his hand. "Samson Partridge, Senator of Louisville."
					
					"Senator," you reply with a @{male nod|half-curtsy}.
				*else
					"A pleasure, ${mr} ${surname}.  I am John Bailey, Senator of St. Louis," replies the fair-haired gentleman, "and this is Samson Partridge, Senator of Louisville."
					*if lore > 2
						*set knows_partridge_childe_of_stone true
						Samson Partridge?  You've heard this name before.  Yes, of course, he is the offspring of Isaiah Stone!
					
					"An honor to meet you, gentlemen."
					
				"What can we do for you, ${mr} ${surname}?" replies Partridge.
				*goto speak_partridge_and_bailey
	*if (memphis_coffin_convo = false) and (voting_il_name != "Abigail")
		*if heard_of_coffin or met_coffin
			#Senator Coffin.
				*set interlocutors +1
				*if met_coffin
					Senator Coffin nods at your approach.
					*if party_foul
						*gosub coffin_party_foul
					*goto speak_coffin
				*else
					*if speaks_english
						Approaching the Senator, you offer a deep ${bow}.  Returning your eyes to her level, you introduce yourself.  "Good evening, Senator, my name is ${given_name} ${surname}.  It is an honor to meet you."

						"Thou art too kind, ${mr} ${surname}."

						"Do you have a moment?"

						*if priest
								She seems to look at your collar and cassock suspiciously.
						*if party_foul
							*gosub coffin_party_foul
							*goto speak_coffin
						*else
							"I suppose so.  Please, tell me, what might I do for thee?"
							*goto speak_coffin
					*else
						*label meet_coffin_telepathy
						*set discovered_telepathy true
						"Good evening, my name is…" you begin, until you realize that she does not understand your tongue.  You begin to make your apologies and back away, when suddenly you hear her voice, clear as day.
						
						"I am sorry; what sayest thou?"
						
						Strangely, her lips do not move.  But she looks at you directly.
						
						"I'm sorry?" you say.
						
						"No no…do not speak, I cannot understand thy tongue.  Thou must imagine the words, and thus may we speak."
						
						She is in your head!  "You can hear my thoughts?"
						
						"I can."
						
						"But…how?"
						
						"The gifts of the blood are manifold, ${mr} ${surname}."
						
						"Who…who are you?"
						
						"I am Abigail Coffin, Senator of Cincinnati."

						"It is an honor, Senator."
						*if party_foul

							*gosub coffin_party_foul
						*goto speak_coffin
		*else
			#The Puritan woman.
				*if speaks_english
					"Good evening, ma'am.  Allow me to introduce myself," you begin with a ${bow}, "my name…"
					
					"Have no fear, I know thee already, ${mr} ${surname}," she interjects.
					
					"I…I…" you stutter, startled by this and unsure as to how to ask for her name in return.
					
					She seems to sense this, however, and obliges you.  "I am Abigail Coffin, Senator of Cincinnati."
					
					"An honor, Senator."
					
					"Well, I can see that thou wishes to ask me something.  Out with it."
					*set interlocutors +1
					*goto speak_coffin
				*else
					*goto meet_coffin_telepathy
	*if (voting_il_name != "Elinor") and ((rebuffed_by_harding = false) and harding_unspoken)
		*if heard_of_harding or met_harding
			#Quaestor Harding.
				*if (ethnicity = "african") or (ethnicity = "choctaw")
					*label harding_rebuffs_inquiry
					*set rebuffed_by_harding true
					*set harding_rapport %-15
					As you approach the woman, you feel her effortless move to cut you off from addressing her.  You try again to maneuver your way into her view, but almost as if by magic, you find yourself completely unable to do so.
					*if discretion > 60
						*set harding_rapport %-10
						Frustrated, you decide to just address her.

						"Pardon me, ma'am…" you begin.

						The woman turns and stares at you.  Suddenly, you feel very small.

						*if speaks_english	
							"It is unfortunate…not only that your dominus made you, but that he was so short-sighted as to fail to instruct you in the rules of etiquette.  If someone excludes you from a conversation, you should understand that they do not wish to speak to you.  And, believe me, I would never want to speak to one such as you."  She is nearly spitting as she says these words.
	
							Stunned by this attack, you back away, trying to end this confrontation as quickly as possible.  Once you are far enough away, she turns and does her best to put you from her mind.
							*goto choice_of_conversation
						*else
							She says something to you in English, and while you cannot understand the words, you understand the gist: you are not welcome in her presence.
							
							Stunned by this attack, you back away, trying to end this confrontation as quickly as possible.  Once you are far enough away, she turns and does her best to put you from her mind.
							*goto choice_of_conversation
					*else
						Doing your best to contain your shame, you withdraw from this rebuff.  Her animosity towards you is clear, even if its source is not.
						*goto choice_of_conversation
				*elseif speaks_english or speaks_french
					*set interlocutors +1
					*if met_harding = false
						*set carothers_rapport %-5
						You can feel Carothers' eyes on you as you approach the Quaestor of Louisville.
					*comment endif
					
					*if met_harding
						"Quaestor Harding, if I may have a moment of your time…?"
						
						"Yes, of course, ${mr} ${surname}.  Always a pleasure."
						*goto speak_harding
					*else
						After introducing yourself, she introduces herself in turn: she is Elinor Harding, Quaestor of Louisville. @{heard_of_harding This must be Carothers' broodmate, the one of whom he spoke so harshly. Now you understand why he was glaring at you.|}
						
						"If I may, I hoped you might tell me something about this gathering."
						
						"Please, ask away."
						*goto speak_harding
				*else
					*set harding_rapport %-5
					Your attempts to engage Quaestor Harding in conversation go poorly, as you soon discover that you hold no tongue in common.  Withdrawing, you seek someone else with whom to converse.
					*goto choice_of_conversation
		*else
			#The fashionable woman.
				*if (ethnicity = "african") or (ethnicity = "choctaw")
					*goto harding_rebuffs_inquiry
				*elseif speaks_english or speaks_french
					*set harding_rapport %+5
					"I'm afraid I have not had the pleasure of your acquaintance, ma'am."

					"No, I'm afraid not.  I am Elinor Harding, Quaestor of Louisville."

					"I am ${given_name} ${surname}, and it is an honor to meet you," you reply with a ${bow}.
					*set interlocutors +1
					*goto speak_harding
				*else
					*set harding_rapport %-5
					Your attempt to engage the fashionable woman in conversation goes poorly, as you discover that you hold no tongue in common.  Withdrawing, you seek someone else with whom to converse.
					*goto choice_of_conversation
	*if (memphis_lockridge_convo = false) and ((voting_il_name != "Arthur") and (speaks_english or speaks_french))
		*if heard_of_lockridge
			#Senator Lockridge.
				*set interlocutors +1
				*if met_lockridge
					"Senator Lockridge," you begin.

					*if party_foul
						*gosub lockridge_party_foul
						*goto speak_lockridge
					*else
						"${mr} ${surname}, it is good to see you this evening."
						
						"And you, Senator."
						
						"Please, what can I do for you?"
						*goto speak_lockridge
				*else
					*label meet_lockridge
					"Pardon me, sir," you begin.
					
					"Yes?" the man says, turning.
					
					"If I may, I am ${mr} ${surname}, a citizen of Memphis."
					
					"Ah, I have heard about the new resident of the city.  I am Arthur Lockridge, progeny of Ethelmarr, Senator of Charleston."
					*set heard_of_ethelmarr true
					
					"It is an honor, Senator."
					
					*if party_foul
						*gosub lockridge_party_foul
						*goto speak_lockridge
					*else
						"Yes, yes…pleasantries exchanged.  There is too much business to be done to stand on etiquette this evening.  What can I do for you?"
						*goto speak_lockridge
		*else
			#The gentleman from the Carolinas.
				*set interlocutors +1
				*set heard_of_lockridge true
				*goto meet_lockridge
	*if (memphis_malloy_convo = false) and (voting_il_name != "Siobhan")
		*if heard_of_malloy
			#Siobhan Malloy.
				*set interlocutors +1
				It takes you a moment to locate her, but soon she emerges from the refreshment room, wiping her mouth daintily with a now-bloody handkerchief.
				*if met_malloy
					*set malloy_rapport %+10
					"Well, hullo again, ${mr} ${surname}!" she says, welcoming you heartily.
					
					"Good evening to you, Miss Malloy."
					
					"What can I do for ya this evenin'?" she replies.
					*goto speak_malloy
				*else
					*label introduce_to_malloy
					*set heard_of_malloy true
					"Good evening!" you begin.
					
					"Good evenin' ta ya!" she replies heartily.
					
					"Please, allow me to introduce myself.  I am ${given_name} ${surname}, a citizen of Memphis."
					
					"A pleasure, ${mr} ${surname}.  I am hopin' ta be a citizen here as well!"
					
					"Actually, that's what I wanted to talk to you about," you begin.
					
					"At yer service," she replies.
					*goto speak_malloy
		*else
			#The Irishwoman.
				*set interlocutors +1
				*goto introduce_to_malloy
	*if (memphis_partridge_bailey_convo = false) and ((voting_il_name != "Samson and John") and (partridge_bailey_hidden = false))
		*if heard_of_partridge or met_partridge
			#Senator Partridge.
				*set interlocutors +1
				*if met_partridge
					*goto greeted_by_bailey_partridge
				*else
					*goto heard_of_bailey
		*else
			#The bearded man in Colonial-era dress.
				*set interlocutors +1
				The bearded man seems inseparable from his fair-haired companion.  Any conversation with the one will no doubt involve them both.
				
				*goto unacquainted_bailey
	*if (memphis_pickering_convo = false) and (voting_il_name != "Absalom")
		*if heard_of_pickering
			#Absalom Pickering.
				*set interlocutors +1
				*if met_pickering
					"Yes, ${mr} ${surname}, what can I do for you?" Pickering inquires as you approach.
					*goto speak_pickering
				*else
					When the moment seems right, you approach and introduce yourself to Mr. Pickering.
					*label meet_pickering
					*set heard_of_pickering true
					He is a man of English descent with brown hair and eyes, along with a well-kept goatee that hides what would otherwise be a weak chin.  His hair is parted to the side, somewhat low for your taste.  Moreover, he is not shy about his desire to win the election and is eager to answer any questions you may have for him.
					*goto speak_pickering
		*else
			#A southern gentleman speaking with @{speaks_english an Alabaman drawl|a heavy Southern accent}.
				*set interlocutors +1
				When it seems appropriate, you approach the gentleman with the Alabaman drawl.  He introduces himself as Absalom Pickering, a citizen of Mobile.
				*goto meet_pickering
	*if (memphis_lesczynski_convo = false) and (voting_il_name != "Ascher")
		*if heard_of_lesczynski or met_lesczynski
			#Ascher Lesczynski.
				*set interlocutors +1
				*if met_lesczynski
					"Hello again, ${mr} ${surname}, what can I do for you?" he inquires.
					*goto speak_lesczynski
				*else
					*goto meet_lesczynski
		*else
			*if able_to_identify_jews
				#The Jewish man in the kippah.
					*set interlocutors +1
					*label meet_lesczynski
					*set heard_of_lesczynski true
					"Good evening, sir, do you have a moment?"
					
					"Of course!  Please," he says, gesturing for you to join him at a window.
					
					"If you would, allow me to introduce myself.  I am ${given_name} ${surname}, a citizen of this city."
					
					"A pleasure.  I am Ascher Lesczynski.  I hope to be your Senator soon."
					*goto speak_lesczynski
			*else
				#The man with the funny hat and curls.
					*set able_to_identify_jews true
					*set interlocutors +1
					*set heard_of_lesczynski true
					"Pardon me," you begin, "my name is ${given_name} ${surname}."
					
					The man turns, smiles, @{male and extends a hand in greeting.|and nods by way of greeting.} "Please, don't be shy.  My name is Ascher Lesczynski."
					
					"A pleasure, Mr. Lesczynski.  What brings you to Memphis?"
					
					"The election!  What else would I be here for?" he says, as though it were the most obvious thing in the world.
					
					*if discretion > 60
						*set lesczynski_rapport %-5
						"Considering your outfit, I didn't know what to think."
						
						"My outfit?"
						
						"Yes, the hat and curls.  Is that the style in New-York?"
						
						"What is this [i]michegas[/i]?  Have you never seen a Jew before?"
						
						You pause a moment.  "No."
						
						"[i]Oy vey[/i]!  You must be young," he says with a roll of the eyes.

						"Not so young," you retort, before changing the subject to something a little less confrontational.
						*goto speak_lesczynski
					*else
						"I don't know.  I am unfamiliar with the style of your clothing."
						
						"Have you never met a Jew before?"
						
						"No, I can't say that I have."
						
						"Well, I suppose I have the honor of being your first."
						
						"So it seems."
						*goto speak_lesczynski
	*if (memphis_santagostino_convo = false) and (voting_il_name != "Chiara")
		*if frenzied_on_santagostino
			#Perhaps I should take this opportunity to apologize to Senator Santagostino.
				*set santagostino_rapport %+5
				*set questions +1
				*set discretion %+5
				*set apologized_to_santagostino true
				Santagostino's eyebrow arches at your approach.
				
				"Senator, I wanted to apologize for my outburst last night…"
				
				"Outburst?" she laughs. "Your complete and utter loss of control, you mean?"
				
				You squirm under her gaze.  You feel as though all the eyes in the room are upon you now.  "Yes, that."
				
				"I must acknowledge that it is brave of you to offer an apology, especially in such a public forum.  After all, had you not been so young and weak-willed, you might have broken one of the Rules, and then where would we be?"
				
				"I suppose you would be dead and I would be on the run."
				
				She narrows her eyes at the impertinence of your response.  "Yes, I suppose so."
				
				"May I consider the matter closed?"
				
				After a moment's consideration, she replies: "Yes, you may."
				
				"Thank you, Senator."  She nods, leaving you a momentary opening during which you might ask her a question.
				*set interlocutors +1
				*goto speak_santagostino
		*else
			#@{(heard_of_chiara_santagostino or met_chiara) Senator Santagostino.|The woman from northern Italy.}
				*set interlocutors +1
				*if met_chiara
					"Senator," you say, by way of greeting.
					
					"${mr} ${surname}!  What a surprise," she says, deadpan.
					
					*if charm > 3
						*set santagostino_rapport %+5
						"Yes, I thought I'd take a jaunt off to New-York, but the train schedules were all a mess, so I decided to rough it out here with the bloodsuckers this evening instead."
						
						"Well, I hope we don't bore you!"
						
						"I'll do my best not to show it, Senator," you reply.
						*goto speak_santagostino
					*else
						"Did you not think I would make it?"
						
						"No, I was speaking in jest.  What can I do for you this evening?"
						*goto speak_santagostino
				*else
					"If I may," you begin as she turns to greet you, "allow me to introduce myself.  I am ${given_name} ${surname}."
					
					"A pleasure.  I am Chiara Santagostino, Senator of New Orleans."
					
					"New Orleans?  My dominus, ${sire_name}…"
					
					*if sire_name = "West"
						*if patricide
							*set rumors_of_west_dead true
							"You are the offspring of that beast?"
							
							"I am.  What of it?"
							
							"Have you not heard?"
							
							"Heard?  No…" you say, you blood running cold.  Has someone found out your secret?
						*elseif status > 2
							*set rumors_of_west true
							"You are the offspring of that beast?"
							
							"I am."
							
							"But, you are an upstanding member of the Society!"
							
							"I am my own vampire."
							
							"So I see."
							
							"Tell me, what news of him?"
						*else
							*set rumors_of_west true
							"I have heard of that beast.  It makes more sense now, that I would not have heard of you."
			
							You @{(sire_rapport > 40) do your best not to bristle at this dismissal of your maker.|shrug off this barb; after all, you hold your maker in little esteem.} "But what of him?" you manage to whisper.
						*set sire_question_unasked false
						
						"There are rumors that he has been driven mad."
						
						"Mad?"
						
						"Alas, I know little else.  Perhaps he has simply been more removed from the Society than is typical?"
						
						"Perhaps," you reply, your world aflutter at this intelligence.
						*goto speak_santagostino
					*elseif avoided_new_orleans and sire_alive
						"Yes, it seems that a reputation precedes both of us.  Your dominus has spoken often of you in your absence."
			
						"Truly?  I would have thought he had forgotten me by now."
			
						"By no means, ${mr} ${surname}, by no means."
						*goto speak_santagostino
					*elseif exiled_from_new_orleans
						"I have heard of your exploits."
				
						"Oh?"
				
						"Of course.  Your departure is the stuff of legend.  We seldom have such unequivocal displays of incompetence."
						*if (discretion > 70) and (willpower <= 3)
							*set flirting_with_chiara false
							*set frenzied_on_santagostino true
							*set booted_from_memphis_reception_1873 true
							Your face twists into a mask of rage.  For a brief moment, you see concern cross Chiara's face as you crouch to pounce on her.
							
							Leaping towards her, you let out a snarl; the two of you fall to the ground and begin to roll through the room.  Your fingers claw at her eyes and throat.
							
							It is only a few moments before you are torn away from her.  Carothers is livid.  You are carried bodily into another room, where you can calm down.  The door is locked.
							*page_break
							*if status > 0
								*set status -1
							*set carothers_rapport %-20
							When Carothers returns, it is just before dawn.
							
							"You are not welcome here tomorrow night."
							
							@{(independence > 30) You grit your teeth.  To be denied entry to the political event of the decade is an enormous embarrassment.  Though, not at all incommensurate with your crime.|You do your best to not seem too disinterested in this punishment.  You wouldn't want him to find a punishment befitting the name.}
							
							*if maddox_num = 3
								"You might be interested to know, however, that Dido has spotted another of our kind in the city, one that has not made himself known to me.  He calls himself Hugh Gallagher.  If you want to have a chance at redeeming yourself in my eyes, I would suggest dealing with this interloper tomorrow.  All the better to keep you away from here.
								
								"Yes, Quaestor."
								
								"There is a man named Stennis.  Tomorrow night, he will meet you in the Pinch…"
								*page_break
								The next morning you wake, and immediately throw yourself into your commission.  Once dressed with the aide of Franklin, you hurry on your way.
							*else
								"Occupy yourself with something else.  I want you nowhere near here tomorrow night."
								
								"Yes, Quaestor."
								*page_break
								You wake up on the evening of the election to find a note waiting for you. @{literate Unfolding it, you scan the lines quickly.  One of the individuals you hired years ago to keep an eye out for ${wilson} claims to have spotted him.|You rap your fingers impatiently as you wait for Franklin to read it to you.}
								
								Of course, you cannot imagine a worse moment for ${wilson} to come crawling out of the woodwork.  Should the senators catch wind of this scandal, well,
								*if wilson_embraced
									you would never live it down.
								*elseif wilson_embraced_by_withers
									Samantha would never live it down.
								
								Sighing deeply, you dress yourself and set out to meet your informant.  It seems that you will end up honoring Carothers' wishes tonight, regardless of your previous intentions.
								*page_break Next
							*goto_scene memphis_1873_plague
						*elseif discretion > 50

							You feel the animal inside you rise at this barb, but you manage to hold it tight.  Clenching your teeth, you think it best to change the subject.
						*elseif charm > 2
							"I am glad to hear that they are still talking about me.  The worst would be if I had simply been forgotten."
			
							"No chance of that, ${mr} ${surname}.  No chance of that."
						*else
							"Do you often go about insulting people so?"
			
							"When they deserve it, yes."
			
							Gritting your teeth at her effrontery, you think it best to change the subject.
						*goto speak_santagostino
					*elseif (sire_alive = false)
						"Ah, yes. ${new_orleans_quaestor_surname} spoke of you 
						*if new_orleans_quaestor_rapport > 60
							quite fondly.  Almost as though you were one of his own."

							"I should hope so.  I do hold him in the highest esteem."

							"As he does you."
						*elseif new_orleans_quaestor_rapport >= 40
							regularly."

							"That is interesting.  I did not know I rated so highly in his esteem."
				
							"Do not misunderstand.  His remarks are ambivalent.  Sometimes he praises you and your accomplishments, other times he seems to think that you betrayed him."
				
							"He is fickle like that."
				
							"Yes, so he is."
						*else
							regularly."

							"I find that surprising."
				
							"I did not say that he spoke highly of you."
				
							"No, I suppose not," you reply with a grimace.
						*goto speak_santagostino
					*else
						"Ah, yes. Your dominus spoke regularly of @{sire_formerly_quaestor you before his departure."|you."}
				
						*if sire_rapport > 60
							"I should hope so.  I do hold him in the highest esteem."
				
							"As he does you."
						*elseif sire_rapport >= 40
							"That is interesting.  I did not know I rated so highly in his esteem."
				
							"His remarks are ambivalent.  Sometimes he praises you and your accomplishments, other times he seems to think that you betrayed him."
				
							"He is fickle like that."
				
							"Yes, so he is."
						*else
							"I find that surprising."
				
							"I did not say that he spoke highly of you."
				
							"No, I suppose not," you reply with a grimace.
						*goto speak_santagostino
	*if whitaker_unspoken and ((voting_il_name != "Jesse") and (jesse_hidden = false))
		#Jesse Whitaker.
			*set interlocutors +1
			Jesse turns to greet you as you approach.  "$!{jesse_toa}," he begins.  "Are you enjoying yourself this evening?"

			You smile at him.  "It is quite an affair."

			"That it is.  Not enough naked flesh for my tastes, but I suppose we can't all be dissolute, now can we?" he says, loudly. @{(perception > 1) Really, too loudly.  It's as though he wanted that to be overheard.|} "Now, what can I do for you?"
			*goto speak_whitaker

*label coffin_party_foul
*set questions +1
*set coffin_rapport %-20
"Art thou responsible for this disaster?"

You look around sheepishly.  "I am, Senator."

"I'm surprised thou would have the temerity to continue to show thy face in this company, considering."

"I can only beg the forgiveness of you and the other Senators."

"Yes, beg thou should."

"Please, indulge me a moment."

"Only a moment."
*return

*label lockridge_party_foul
*set questions +1
*set lockridge_rapport %-20
"Are you the one who organized this evening?"

You look around sheepishly.  "I am, Senator."

"I'm surprised you're still here.  Your audacity is astounding."

"I can only beg the forgiveness of you and the other Senators."

"Yes, you should beg."

"Please, indulge me a moment."  

He waves his hand for you to proceed.  Clearly, though, he means for you to be quick about it.
*return

*label temperance_incident
*temp harriet "Harriet"
*temp temperance_worker "temperance worker"
*if memphis_reception_planner = "Sally"
	*set harriet "Sally"
	*set temperance_worker "church volunteer"
As you survey the room, deciding with whom you should speak next, you notice one of ${harriet}'s ${temperance_worker}s in something of a compromising position with
*if whitaker_unspoken
	Jesse.  If you do not intervene, the woman will probably not live the night.  @{(compassion < 60) And ${harriet} would never forgive you for that.|}
	*choice
		#I move quickly to interject myself.
			*set compassion %-15
			*set discretion %+5
			*set interlocutors +1
			"Excuse me, Jesse…" you say, closing the distance between the two of you.  Jesse's head snaps around.  You sense that his fangs were withdrawn right before they came into view.
			
			The interruption is all that the ${temperance_worker} needs; with the vampire's attention on you, she slips away.  You, meanwhile, are saddled with continuing the distraction.  Perhaps the right question will drive the matter from his mind.
			*goto speak_whitaker
		#Where's Dido?  This would no doubt be considered inappropriate by Carothers.
			*set compassion %-5
			*set discretion %-10
			*set carothers_rapport %+5
			You alert Dido to Jesse's actions.  She moves in quickly, separating the two without further incident.
			
			As the three go their separate ways, Applethorp nods in your direction.
			*return
		#What do I care about this ${temperance_worker}?
			*set indifferent_to_temperance_workers_plight true
			*set jesse_hidden true
			*set compassion %+15
			*set discretion %-5
			You avert your gaze as Jesse drags the ${temperance_worker} into the adjoining refreshments room.
			*return
*elseif heard_of_partridge
	Senator Partridge.  If you do not intervene, the woman will probably not live the night. @{(compassion < 60) And ${harriet} would never forgive you for that.|}
	*choice
		#I move quickly to interject myself.
			*set compassion %-15
			*set discretion %+5
			*set interlocutors +1
			"Excuse me, Senator…" you say, closing the distance between the two of you.  Partridge's head snaps around.  You sense that his fangs were withdrawn right before they came into view.
			
			*if met_partridge
				The interruption is all that the ${temperance_worker} needs; with the vampire's attention on you, she slips away.  You, meanwhile, do you best to continue distracting him.  Within a few moments, though, his ever-present companion, Senator Bailey, has appeared at his side.  You think that the right question could make the matter slip from their minds.
				*goto speak_partridge_and_bailey
			*else
				*set met_partridge true
				The interruption is all that the ${temperance_worker} needs; with the vampire's attention on you, she slips away.  You, meanwhile, proceed to introduce yourself.  When it is his turn, he introduces himself as Senator Samson Partridge.  By this point, his companion, a fair-haired fellow by the name of John Bailey, Senator of St. Louis, has joined the two of you.  Perhaps with the right question, your little indiscretion would slip from their minds.
				*goto speak_partridge_and_bailey
		#Where's Dido?  This would no doubt be considered inappropriate by Carothers.
			*set compassion %-5
			*set discretion %-10
			*set carothers_rapport %+5
			You alert Dido to Partridge's actions.  She moves in quickly, separating the two without further incident.
			
			As the three go their separate ways, Applethorp nods in your direction.
			*return
		#What do I care about this ${temperance_worker}?
			*set indifferent_to_temperance_workers_plight true
			*set partridge_bailey_hidden true
			*set compassion +10
			*set discretion %-5
			You avert your gaze as Partridge drags the ${temperance_worker} into the adjoining refreshments room.
			*return
*else
	the bearded gentleman in colonial dress.  If you do not intervene, the woman will probably not live the night. @{(compassion < 60) And ${harriet} would never forgive you for that.|}
	*choice
		#I move quickly to interject myself.
			*set compassion %-15
			*set discretion %+5
			*set interlocutors +1
			"Excuse me, sir…" you say, closing the distance between the two of you.  The bearded gentleman snaps his head around.  You sense that his fangs were withdrawn right before they came into view.  "I don't believe we've been properly introduced…"
			
			The interruption is all that the ${temperance_worker} needs; with the vampire's attention on you, she slips away.  You, meanwhile, proceed to introduce yourself.  When it is his turn, he introduces himself as Senator Samson Partridge.  By this point, his companion, a fair-haired fellow by the name of John Bailey, Senator of St. Louis, has joined the two of you.
			*set heard_of_bailey true
			*set heard_of_partridge true
			*goto speak_partridge_and_bailey
		#Where's Dido?  This would no doubt be considered inappropriate by Carothers.
			*set compassion %-5
			*set discretion %-10
			*set carothers_rapport %+5
			You alert Dido to the bearded man's actions.  She moves in quickly, separating the two without further incident.
			
			As the three go their separate ways, Applethorp nods in your direction.
			*return
		#What do I care about this ${temperance_worker}?
			*set indifferent_to_temperance_workers_plight true
			*set partridge_bailey_hidden true
			*set compassion +10
			*set discretion %-5
			You avert your gaze as the bearded gentleman drags the ${temperance_worker} into the adjoining refreshments room.
			*return

*label speak_applethorp
*comment 4
*set questions +1
*set applethorp_unspoken false
*choice
	#"What do you think of the candidates for the Senate?"
		*set applethorp_rapport %+5
		*set heard_of_malloy true
		*set heard_of_lesczynski true
		*set heard_of_pickering true
		She seems flattered that you would ask her and does not shy away from expressing her opinions.  "Ah cants say dat deys been willin' ta spend too much time tawkin' wid me, but Ah be watchin' dem."
		
		"And what have you noticed, Ms. Applethorp?"
		
		"That buckruh from Alabama, Massa Pickren', he be lookin' at me funny.  Ah don' thinks he likes me none."
		
		"But what do you think of him?"
		
		"Thats hard to say.  They some chilluns got fed 'cause of him, over Sycamore way, or so Ah hears."
		
		"He fed some children?"
		
		"Not hisself, no, but there is some chilluns got fed, an Ah thinks it wuz him dat did it."
		
		"Do you mean at the Methodist Orphanage on Sycamore?"
		
		"$!{es_suh}, there."
		
		You pause a moment, letting this sink in.  "And the others?"
		
		"That red misses, she be a hard one, that Mam'selle Malloy.  Ah don' think you better upset her none, ya hear?"
		
		"Are you saying she can carry a grudge?"
		
		"Ah is sayin' she gwine tear you up like a roast chicken ifn you cross her."
		
		"Oh.  That is not what I thought you meant."
		
		"An that other one, Les-chin-ski," she says, very slowly, "he be keepin' his cards close to his chest."
		
		"So you don't know anything useful?"
		
		"Ah din' say dat, now!  He be askin' me 'bout the folks in this town.  The ones that still be breathin', hear?  He wants to know who got the silver, and who use that for buyin' books."
		
		"He was asking you which mortals have assembled libraries in the city?"
		
		"Y${es_suh}."
		*temp tick false
		
		*if jesse_for_senator
			"And what of Jesse Whitaker?"
			
			*if heard_of_maffi
				"After what he done down in Haïti, Ah don' think nobody gwine give him much of a chance."
				
				"Does this have something to do with the death of Governor Praz?"
				
				"The very same!"
			*else
				*set heard_of_maffi true
				*set tick true
				
				Applethorp shoots Whitaker a glance across the room. "He done got hisself in trouble down in Haïti."
				
				"Oh?"
				
				"Yus. There was this mean ol Guv'ner by the name of Az'met Praz. But this young thing by the name o' Thérèse killed him. Now, was in Cap-Français at the time and nobody knows if he helped her or what."
				
			"But no one has made any accusations against him?"
			
			"No, they haven't. But folks talk, you knowd."
			
			You nod in agreement.		
		"How strange.  All of it."  
		
		She nods @{tick as well|in agreement}.  "The whole thing, Ah is tryin' to make sense of it." She sighs.
	#"What does the Quaestor think of the candidates for Senate?"
		"Ah don' think they spend much time worryin' 'bout Apollo.  He don' git to vote, after all."
		
		"True, but his opinion does carry some weight, doesn't it?"
		
		"Ah thinks he'd most like the Jew to win the title."
		
		*if able_to_identify_jews = false
			*set able_to_identify_jews true	
			"The man with the curls and hat?"
			
			"Yeayah, dats him."
			
		"I did not expect that."
		
		"Well, Ah thinks them Irish in the Pinch is makin trouble for our people.  An' he don' wan' no plantation-ownin' buckrah to move into town, neither."
		
		"That is most understandable." @{avoided_new_orleans You think it best to avoid commenting on your own ownership of a plantation in St. Charles Parish.|}

	*if memphis_reception_planner = "Dido"
		*selectable_if (compassion < 60) #"You did a marvelous job on the reception, Ms. Applethorp."
			*set applethorp_rapport %+15
			"You's kind ta say dat, ${mista} ${surname}.  Ah werked real hard to make it look right."  She beams under this praise.
			
			"Well, it shows."
			
			"Ah wuz afeared dat dey wuldnt liek it, but Ah thinks dey does."
			
			"You may put your mind at rest, dear."
	*if rebuffed_by_harding and (heard_of_harding and (rebuff_query = false))
		#"When I tried to introduce myself to Quaestor Harding, she was very rude."
			*label applethorp_explains_harding
			*set rebuff_query true
			*set harding_bigot_known true
			"Ah knows.  Ifn Ah could drops her into the deepest parts o' hell, Ah woulds."
			
			"Why is that?"
			
			"It don' matter that we is all vampires.  She still only sees that we is negroes."
			
			*if ethnicity = "choctaw"
				"But I'm not a negro."
				
				Dido sizes you up.  "You is close enough."
			
			"Is that why she and the Quaestor do not get along?"
			
			"Ah thinks that has sometin' to do with it, y${es_suh}," she says, nodding.
	*if rebuffed_by_harding and ((heard_of_harding = false) and (rebuff_query = false))
		#"When I tried to introduce myself to that woman in the fashionable dress…"
			*set heard_of_harding true
			"That was Quaestah Harding, from Louisville."
			
			"She was very rude."
			*goto applethorp_explains_harding
*if questions > 1
	*if interlocutors > 1
		"Ifn you forgive me, that daylight is comin', an' we gots to say goodnight toi all them folks that came."
		
		"Yes, of course.  Thank you for your time, Ms. Applethorp."
		*goto caucus
	*else
		"Ifn you forgive me, Ah gotta tend to somethin'.  This fete not gwine take care o' itself, now is it?"
		*goto choice_of_conversation
*else
	After a pause, she looks at you, expectantly.
	*goto speak_applethorp

*label speak_coffin
*comment 5
*set questions +1
*set met_coffin true
*set memphis_coffin_convo true
*choice
	*if discovered_telepathy
		#"Tell me, do many of our kind possess a power such as yours?" you think at her.
			*set discretion %+2
			@{speaks_english |Her voice rings out clearly in your mind.} "I cannot say.  We are not known for freely divulging the extent to which the decades have benefited us."
			
			"But, somenight I may develop such power?"
			
			"I imagine it is possible, yes.  But it will no doubt take centuries."
			
			You do your best not to seem crestfallen at this statement.  Of course, she can probably "hear" it all the same.
			*label resolve_coffin
			*if questions > 1
				
				*if interlocutors > 1
					"Now, if thou wilt excuse me, ${mr} ${surname}, the dawn approaches, and I must bid you farewell."
					
					"Goodnight, Senator." @{speaks_english |You feel her presence leave your mind.}
					*goto caucus
				*else
					"Now, if thou wilt excuse me, I feel the need for some refreshment," she says, eyeing the door to the captured humans.
					
					*if acquiring_vessels = "success"
						*set coffin_rapport %+5
						"I hope you enjoy them; I acquired them myself."
						
						"Oh, didst thee?  Such an intrepid young vampire thou art."
					*else
						"Yes, Senator."
					@{speaks_english |You feel her presence leave your mind.}
					*goto choice_of_conversation
			*else
				A pause in the conversation leaves you with the opportunity to ask another question.
				*goto speak_coffin
	*if rebuffed_by_harding and (heard_of_harding and (rebuff_query = false))
		#"When I tried to introduce myself to Quaestor Harding, she was very rude…"
			"Yes, I saw.  As did everyone else."
			
			*goto coffin_explains_harding
	*if rebuffed_by_harding and ((heard_of_harding = false) and (rebuff_query = false))
		#"When I tried to introduce myself to that woman in the fashionable dress, she was very rude…"
			*set heard_of_harding true
			"Quaestor Harding?"
			
			"I cannot say."
			
			"It was; I saw the exchange.  As did everyone else."
			
			*label coffin_explains_harding
			*set rebuff_query true
			*set harding_bigot_known true
			"Did I offend her?"
			
			"The color of thy skin offends her, ${mr} ${surname}."
			
			*if compassion > 60
				"She still maintains such mortal prejudices?"
				
				"Immortality afflicts us all differently.  But do not forget the identity of her broodmate."
				
				"Quaestor Carothers?"
				
				"Thou mayest imagine the love they share."
				
				*if jesse_is_broodmate and (jesse_rapport > 55)
					"That is unfortunate for them.  One's broodmates should be one's closest confidantes."
					
					"Not all vampires have such a high opinion of their kin."
					
					"So I am beginning to see, Senator."
				*else
					"I can only imagine."
				*goto resolve_coffin
			*elseif knows_coffin_anti_semitic and ((discretion > 55) and (justice < 50))
				*set coffin_rapport %-15
				"Do all of the elders harbor such hatreds?"
				
				"What dost thou mean by 'all elders?' Do not lump me in with her."
				
				"And yet you just told me how you despise the Children of Israel."
				
				"That is different!" she
				*if speaks_english
					screeches—drawing the eyes of several interested vampires.
				*else
					screeches in your mind.
				
				"How so?"
				
				She blinks before responding. "The Jews murdered our Lord and Savior. The children of Africa simply had the misfortune of being born in a different climate. The two are incomparable. Now, ${mr} ${surname}, if thou wilt excuse me, I believe this interview is concluded."
				
				You nod your head deferentially.
				*if interlocutors > 1
					*goto caucus
				*else
					*goto choice_of_conversation
			*elseif compassion >= 35
				"While her commitment to her humanity is admirable, perhaps there is more to it than retaining one's hatreds."
				
				You think you might have made Coffin laugh.  It sounds more like a cough, though.  "Thou speakest truly, ${mr} ${surname}." @{knows_coffin_anti_semitic Curious, though, that she does not seem to apply this opinion to herself.|}
				
				"It's good to see we agree," you reply.
				*goto resolve_coffin
			*else
				"How abhorrent.  She is gifted with immortality and squanders it on mortal prejudices." 
				
				"A waste of time and effort, yes," Coffin agrees. @{(knows_coffin_anti_semitic and (justice < 50)) You pause for a moment, half-expecting some sort of qualification by Coffin—an explanation of how her bigotry is different from that of Harding's—but nothing is forthcoming.|}
			
				"Thank you for your explanation," you conclude.
				*goto resolve_coffin
	*if (memphis_chance_encounter != "coffin") or ((memphis_chance_encounter = "coffin") and (knows_coffin_anti_semitic = false))
		#"What do you think of the candidates for the election?"
			*set heard_of_lesczynski true
			*set knows_coffin_anti_semitic true
			"Mr. Lesczynski passed through Cincinnati recently.  Though there was no formal announcement of such—as it would be crass—I expect that he sought to elicit my support.  He lavished several gifts upon me."
	
			"And what did you think of him?"
	
			"He is a Jew.  What more need be said?"
	
			*if (religious_tradition = "pagan") and (discretion >= 40)
				*set coffin_rapport %-10
				"I suppose you cannot hang that particular albatross around my neck."
				
				"Excuse me?"
				
				"I can't imagine what you must think of my people and their faith."
				
				Coffin looks down her nose at you.  "Barbarians.  Your people have already been chased across the Mississippi.  It will not be long before the last of you has been hunted down and exterminated."
				
				"I appreciate your candor, Senator," you say, before excusing yourself.
				*if speaks_english = false
					You feel her presence leave your mind as you walk away.
				*goto choice_of_conversation
			*elseif priest and (discretion > 35)
				*set coffin_rapport %-10
				"I suspect that you would also be disappointed were I to be elected?"
				
				She glances down to your priest's collar and then meets your eyes again.  "Better a papist than a Jew, I suppose" she muses aloud.
				
				"Thank you for that vote of confidence, Senator," you say, before excusing yourself.
				*goto resolve_coffin
			*elseif (religious_tradition != "pagan") and ((rationalism > 65) and (compassion < 35))
				*set coffin_rapport %+10
				"A Christkiller must not be allowed to take a seat in the Senate!"
	
				"Unfortunately, it would not be the first time such had occurred, but I do appreciate thy sentiments, ${mr} ${surname}."
	
				"Whatever I can do to aide you in preventing this…"
	
				"I may very well accept thine offer, ${mr} ${surname}."
	
				"I am at your service, Senator."
				*set offer_to_help_coffin_stop_ascher true
				*goto resolve_coffin
			*elseif (rationalism < 50) and ((discretion > 50) and (compassion < 50))
				*set coffin_rapport %-10
				"You say that as though it should disqualify him for the position, Senator."
	
				"As well it should."
	
				"For practicing a different faith?"
	
				"For bearing the blood of the Christ on his hands."
	
				"But, he does not…"
	
				"His people put Our Lord to death.  All of their kind bear the responsibility for that crime.  If thou canst not recognize that, I am afraid we have nothing more to discuss."  You look at her, a tad bewildered.
				*goto resolve_coffin
			*elseif discretion < 40
				*set coffin_rapport %+2
				"And it would be disastrous were a Jew to join the Senate?" you venture.
	
				"Unfortunately, it has happened before.  But I am loath to see it happen again."
	
				"I appreciate your insight into this, Senator."
				
				*goto resolve_coffin
			*else
				*set coffin_rapport %-2
				"I see."
	
				Abigail seems to catch herself before embarking upon a rant.  "If that means nothing to thee, I suppose thou must simply await the consequences of such an event."  You resist the urge to prod her further.
				*goto resolve_coffin
	*else
		#"What do you think of the other candidates?"
			*set heard_of_malloy true
			*set heard_of_pickering true
			"That Irishwoman," the words come to her mouth with such distaste that you imagine the Senator wishes she could still spit something of consequence, "is an outspoken supporter of the rebellion.  Thou canst see her there," she says, nodding towards Siobhan Malloy, "…sticking out like the spoiled brat that she is."
			
			At this very moment, a merry smile has just graced Malloy's lips.  She seems enchanting, if you do say so yourself.
			
			"Which leaves Mr. Pickering as the only option."
			*choice
				#"But what of my candidacy?"
					*set discretion %+15
					*set independence %+5
					*if (coffin_rapport > 60) or (status > 2)
						*set player_for_senator true
						"That is an interesting thought, ${mr} ${surname}.  See what other support thou canst garner, and we shall see what unfolds tomorrow."
						
						"Yes, Senator."
						*goto resolve_coffin
					*else
						"Jests on such serious matters are inappropriate to the circumstances, ${mr} ${surname}."
						
						"But I…"
						
						"Of course it was a jest.  Who could take you seriously as a candidate?  You have nothing to recommend you and no Senators supporting you."
						
						You do your best not to appear crestfallen.
						*goto resolve_coffin
				#"But what of the candidacy of Mr. Whitaker?"
					*set independence %+5
					*if jesses_revolutionary_credentials > 60
						*set coffin_rapport %-5
						The Senator's eyes go wide at this.  "Mr. Whitaker is no better than the Malloy woman.  His affiliation with the rebellion is well-known, and that is unacceptable."
						
						"I did not realize he was so affiliated."
						
						"Thou had best pay better attention to the whispers of the Society, ${mr} ${surname}."
						*goto resolve_coffin
					*elseif jesses_revolutionary_credentials >= 40
						She wrinkles her nose at this.  "Mr. Whitaker is too much of an unknown.  He has yet to make his allegiance clear, and I will brook no confusion on that front."
						
						"But, if he were to make clear his opposition to Stone…"
						
						"Then I would give it some consideration, yes."
						*goto resolve_coffin
					*else
						*set jesse_for_senator true
						*set coffin_rapport %+5
						Her eyes brighten at this suggestion.  "Why, what a thought thou hast, ${mr} ${surname}.  Mr. Whitaker's allegiance to Adonis is well-known, and he is so much more interesting than that Pickering fellow."
						
						"You will support him, then?"
						
						"I shall certainly give it some thought."
						*goto resolve_coffin
				#"Are there other qualities to recommend Mr. Pickering?"
					"There are.  He has made his opposition to Stone clear."
					
					"Is that not a dangerous position, to oppose the Consul?"
					
					"Only if he loses."
					*goto resolve_coffin
	*if offer_to_help_coffin_stop_ascher
		#"How are we to stop Mr. Lesczynski?"
			*set coffin_rapport %+5
			"For the time being, ${mr} ${surname}, thou must only attend to the ebb and flow of the election.  The opportunity to one so unconnected as yourself to influence events will only arrive through patience."
			
			"I see."
			
			"Thou must learn as much as thou canst of the other Senators, their hopes and fears.  Through these things, thou mayest gain power over them."
			*goto resolve_coffin
	*if sw_question_unasked
		#"Do you think mortals should be managed by us, or simply used?"
			*set sw_question_unasked false
			*if shepherds_and_wolves
				*set discretion %+5
				"I have struggled with that very question, ${mr} ${surname}."

				"And have you come to any answer?"
				*label coffin_answers_shepherds

				"So often, the mortals are at cross-purposes to myself, and yet, I cannot bring myself to completely discount their needs."

				"A reluctant shepherd, then?"

				"Yes, I suppose thou couldst call me such.  And you?  How doth thou esteem the their treatment?"
				*choice
					#"I think we must be involved with them, lest they destroy themselves."
						*set shepherd_credentials %+10
						*set coffin_rapport %+10
						"Yes, they are inclined towards self-destruction.  It is amazing they have survived as long as they have."  You wonder if she is often this generous to other young vampires.
						*goto resolve_coffin
					#"No, I believe they can take care of themselves and are there for our use."
						*set shepherd_credentials %-10
						"I can certainly see the appeal of your position, ${mr} ${surname}," she replies.
						*goto resolve_coffin
					#"Like you, I am—as of yet–uncertain."
						*set coffin_rapport %+5
						She actually smiles at you.  "I suppose I cannot judge thee harshly for your indecision, when I am guilty of the same."  You wonder if she is often this generous to other young vampires.
						*goto resolve_coffin
			*if heard_of_shepherds_and_wolves
				*set shepherds_and_wolves true
				*set sw_question_unasked false
				"Am I to understand that thou inquireth whether I consider myself a shepherd or a wolf?"
				
				"Yes, I suppose so?  I have some idea of what those words mean."
				
				"Yes, the two philosophies by which our kind exist.  To tend the mortals, or to take from them as suits us."
				
				"And how would you answer the question?"
				
				"I have struggled with this matter, ${mr} ${surname}."

				"And what has been the result?"
				*goto coffin_answers_shepherds
			*else
				*set shepherds_and_wolves true
				*set heard_of_shepherds_and_wolves true
				*set sw_question_unasked false
				"Am I to understand that thou asketh whether I consider myself a shepherd or a wolf?"

				"A what…or a…what?"

				"A shepherd or a wolf.  The two philosophies by which our kind exist.  To tend the mortals, or to take from them as it suits us."

				"There is a name for this?"

				"There is."

				"And how would you answer the question, then?"

				"I have struggled with this matter, ${mr} ${surname}."

				"And what has been the result?"
				*goto coffin_answers_shepherds
	#"How did you become Senator of Cincinnati?"
		*set discretion %+5
		*set coffin_rapport %+10
		*set heard_of_townsend true
		"It was a natural progression.  The city has grown dramatically since it was founded.  I relocated there when work on the canal began and was soon named Quaestor by Governor Townsend.  By the time the canal was completed twenty years later, the city had grown in importance such that a Senator was deemed necessary."
		
		"And you were elected?"
		
		"I was.  It was a small caucus, not unlike this one."
		
		"I see.  Thank you for enlightening me, Senator," you reply.
		*goto resolve_coffin

*label speak_harding
*comment 5
*set questions +1
*set met_harding true
*set harding_unspoken false
*choice
	*if shepherds_and_wolves
		#"I've heard people speaking of shepherds and wolves.  What do they mean by this?"
			*set heard_of_eusebius true
			*set knows_about_shepherds_and_wolves_text true
			Harding rolls her eyes at you.  When she finally speaks, it is like a governess to her students who have been too busy playing with raspberries and milk to pay her heed.  "It is from a dialogue attributed to Eusebius of Damascus, where two vampires debate the virtues of how mortals should be treated."
			
			"And they describe themselves as such?"
			
			"Not exactly.  One of the speakers relates this metaphor about shepherds and wolves…really, it's the only thing that anyone remembers from the dialogue."
			*if heresies_explained
			
				"And such things are not considered heretical?"
				
				"Why no, you silly thing.  It discusses how we should be towards men; the Society has no position on that.  The heresies are cults that seek to spread lies about our origins."
				
				"What, then, is the position of the Society on our origins?"
				
				"The Society has no position on that."
				
				You are tempted to push harder, but you can see that you will get no further with this line of questioning.
			*else
				
				"Does anyone still read it?"
				
				"It is very hard to come by.  I have never seen a copy myself."
				
				"Does anyone still pay attention to it?"
				
				"Why would you be asking otherwise?  Though the Society is not divided up along such lines, at events like these, someone will wax philosophical and likely try to persuade the gathered vampires one way or the other."
				
				"And no one has yet done that?"
				
				"There is still tomorrow."
				
				"There is still tomorrow," you conclude.
			*label resolve_harding
			*if questions > 1
				*if interlocutors > 1
					"The sun is rising," observes Harding, changing the subject.
					
					"It is."
					
					"You must excuse me; I must bid my farewells."
					
					"Of course, Quaestor."
					*goto caucus
				*else
					"I have much business still to conduct this evening, ${mr} ${surname}."
					
					"Forgive me, Quaestor.  I do not wish to impede you."
					
					"That is kind of you.  If you will excuse me," she says.
					
					"Of course," you say with a ${bow}, before turning and leaving.
					*goto choice_of_conversation
			*else
				There is a pause in the conversation; you sense the opportunity to ask another question.
				*goto speak_harding
	#"What do you think of the candidates for the Senate?"
		*set heard_of_lesczynski true
		"Lesczynski is the eldest of the three."
		
		"And that qualifies him how?"
		
		"He knows the most of what it means to be a member of the Society.  The other two are wide-eyed starlings."
		*if perception > 2
			Though you do not doubt that she does support Lesczynski, you sense that his age is not the primary reason for it.
		*comment endif
		
		"I think they are both older than me."
		
		"That does not change my point."  You try not to show your annoyance at this barb.
		
		"Then the matter of Stone's deeds bears little impact upon your decision-making?"
		
		"Whether it is Stone in Baltimore or Adonis in Rome, both are far away.  I am more concerned with what transpires here."
		
		"Lesczynski it is, then."
		*goto resolve_harding
	#"I am given to understand that you do not see eye-to-eye with your broodmate, Quaestor Carothers."
		"Did he tell you that?"
		
		*if charm <= 3
			"I…I…" you stutter.
		*if charm > 3
			"I would not…" you begin.
		*comment endif
		
		"No matter.  He is a walking ape that my beloved dominus, in a moment of madness, turned into a vampire.  I am, in fact, surprised that the gift took; it does not work on most beasts.  Do not be fooled: just because he can talk like a person does not mean that he has instincts any more sophisticated than his brethren."
		
		"A walking ape?"
		
		"Yes.  As with the rest of them.  And those stupid abolitionists, trying to free something that cannot even take care of itself.  They destroyed the world that was my home."
		
		"By freeing the slaves?"
		
		"And driving the nation to war.  Soon, this whole continent will be a smouldering heap, ruined by a lesser species that cannot control its primal urges," she says, a certain fire illuminating her eyes.
		*goto resolve_harding
	#"Might I inquire as to the identity of your dominus?"
		*set discretion %+5
		"You may not."
		
		"I meant no offense…"
		
		"His name is not to be spoken."
		
		"Did he commit some crime?"
		
		"This matter bores me," she says, waving away any further inquiry into the matter.
		*goto resolve_harding
	*if (senator_count = 5) and (senator_question_unasked)
		#"Will there only be five senators here for the vote tomorrow night?"
			*set heard_of_simmons true
			*set heard_of_pickering true
			"There is supposed to be a sixth: Charles Simmons of Mobile."
			
			"Where is he?"
			
			"He has been delayed."
			
			"Will he make it in time?"
			
			"Perhaps.  He is coming by train; the fact that he is not here yet is noteworthy."
			
			"What happens if he doesn't make it?"
			
			"Then Mr. Pickering will be able to count on one less vote in his favor."
			*if perception > 2
				Though you can't be sure, you sense that Harding would not be distraught if Simmons were unable to vote.
			*comment endif
			
			"Simmons is likely to vote for him?"
			
			"I would imagine so.  Simmons is close with the dominus of Pickering, as well as with Senator Lockridge."
			
			"I was not aware."
			*goto resolve_harding

*label speak_lesczynski
*comment 6
*set questions +1
*set memphis_lesczynski_convo true
*set met_lesczynski true
*choice
	*if (rationalism > 40) and ((religious_tradition != "pagan") and (able_to_identify_jews and (memphis_haven != "pinch")))
		*selectable_if (discretion > 35) #"Do you hide your horns under your hat?"  After all, I've been told all my mortal life that Jews have horns.
			*gosub lesczynskis_horns
	*selectable_if (discretion > 20) #"What do you think of Isaiah Stone's deeds?"
		*set discretion %+5
		"[i]Oy![/i]" he exclaims with a roll of his eyes.  "Always they want to know about the revolution. Do I support Stone, or do I not?  What if I haven't decided?  Tell me that?"

		"Then you would make a curious candidate, if you have no position on the revolution."

		"I think the perceived importance of the matter of the revolution will subside as the years grind on. There are so many other things with which we should be occupied."
		
		"That is a shocking position, Mr. Lesczynski."
		
		"Pragmatic, if you ask me.  We are immortal, after all."

		*if independence <=30
			"I do hope that you are right."
		*else
			*if (revolutionary_credentials >= 40) and (revolutionary_credentials <= 60)
				"Only time will tell."
			*else
				"Though I appreciate the sentiment, I cannot imagine such an outcome."
	*if able_to_identify_jews = false
		#"What is this hat you are wearing?"
			*set discretion %+2
			*set able_to_identify_jews true
			"$!{he} asks me what this is?" he raises his hands up in exasperation. "It is a kippah; my people wear it so that we do not offend God by leaving our heads uncovered."

			"Your people?"

			"Yes, the Israelites.  You might know us as Jews."

			"Oh, yes, of course, I've heard of your people.  But I don't believe I've ever met one before."

			He looks at you in surprise.  "We are not so uncommon.  Perhaps you simply did not know how to look."

			"That may be, Mr. Lesczynski."
	#"Why do you want to be Senator of Memphis?"
		*set lesczynskis_interest_in_memphis true
		"This is a great city, and it will soon be even greater.  It would be an honor to be its Senator."
		
		You do your best not to roll your eyes at this.  "But what does that mean, Memphis is a great city?"
		
		"It means that it was founded by a man who became President of the United States, who named it for one of the most ancient cities of the world, and who has since died a peaceful death."
		
		*if met_andrew_jackson and (discretion > 40)
			"You know, I met the General once, decades ago."  Lesczynski suddenly looks very interested.  "It was right after the Battle of New Orleans.  I tried to feed from him, but he knew what I was and stopped me."
			
			"That does not surprise me."
			
			"How do you mean?"
			
			"${mr} ${surname}, if you do not know, I cannot be the one to tell you."  You look at him in confusion.
			*if questions > 1
				*if interlocutors > 1
					"Please, we should end the conversation here.  The dawn approaches, and we must bid our goodbyes."
					
					"Yes, of course," you reply, still bewildered.
					*goto caucus
				*else
					"Please, we should end the conversation here.  I have much campaigning still to do this evening."
					
					"Yes, of course," you reply, still bewildered.
					*goto choice_of_conversation
			*else
				"Please, let us change the subject," he says, eyeing the room.
				*goto speak_lesczynski
		*elseif met_andrew_jackson or attended_marignys_party
			"I attended a soirée with him once, in fact.  Just after the Battle of New Orleans.  He was a luminous presence."
			
			"That does not surprise me.  I never met the man, but I hear he was most extraordinary."
			
			"Extraordinary…yes. That," you confirm.
		*else
			"And that is to be envied?"
			
			"Very much so, ${mr} ${surname}.  To die a peaceful death?  How many of our kind will find that?"
			
			"Not many."
	*if able_to_identify_jews and ((compassion < 60) and (memphis_haven != "pinch"))
		#"Would you feel lonely here in Memphis, without your people?"
			*set compassion %-5
			*set lesczynski_rapport %+15
			*set anachronism %+10
			Lesczynski smiles broadly at your question.  "This tells me much about what sort of vampire you are, ${mr} ${surname}.  There is, in fact, a healthy community of my people here."

			"There is?"

			"Indeed.  There is the congregation of B'nai Israel at the corner of Main and Exchange."

			"Oh, yes!  I have seen that building.  I did not realize that it was a Jewish congregation."

			"It is what we called a Reformed congregation; it didn't used to be one, but their new rabbi, Max Samfield, has encouraged a certain amount of secularism.  He is even a Freemason!"  He throws his hands up in exasperation.  "But that is why they do not dress as I do. They do not follow the same customs that I do.  Should I be elected, I will guide them back to a truer path."

			You look at him askance.  "Well, it is good that you will have an undertaking ready for your arrival."

			"Your concern is appreciated," he returns.
	*if able_to_identify_jews
		#"What did you think of the @{(justice <= 50) Civil War|War between the States}?"
			*set discretion %+5
			"At first I supported the North fully, but then there was Grant and his General Order No. 11…"

			"General Order No. 11?"

			"Yes! He issued a directive expelling Jews from his military district: Tennessee, Kentucky, and Mississippi!"

			"He did what?"

			"He ordered them to leave; he was angered by the black-market cotton trade and blamed my people for it.  Thankfully, President Lincoln rescinded the order not long afterwards.  And so I loved him and the North that much more.  But then they elected Grant as President!"

			"Your faith in the North has wavered?"

			"No, I like an anti-Semite in the White House," he replies, exasperated.
			
			"No, of course not," you reply hurriedly.

*label resolve_lesczynski
*if questions > 1
	*if interlocutors > 1
		"If you will excuse me, ${mr} ${surname}, the dawn is approaching, and I must bid my goodbyes."
		
		"Yes, of course.  A pleasure, Mr. Lesczynski."
		*goto caucus
	*else
		"If you will excuse me, ${mr} ${surname}, there is much campaigning still to be done this evening."
		
		"Of course.  Best of luck to you," you reply.
		
		"Thank you.  And I look forward to seeing you tomorrow evening."
		
		"Until then."
		*goto choice_of_conversation
*else
	You sense that you have not totally alienated him; perhaps you can fit in another question?
	*goto speak_lesczynski

*label lesczynskis_horns
*set discretion %+5
*set anachronism %+5
*set rationalism %-5
It takes a few moments for Lesczynski to formulate a response to this query. "Did a bird get stuck between your ears?" he asks, exasperated.

"A bird between my ears?" you stumble.

He shakes his head. "I am sorry to disappoint you, but there are no horns.  In fact, none of us have horns.  Rather, there was a misunderstanding by your Saint Jerome: when he said that Moses "grew horns," what it actually said was "emit rays of light."  Until that Luther fellow, all you Christians used that same translation, and it has caused us no end of [i]fardeiget[/i]."

You look at him quizzically, the strange word unfamiliar to you.  "Perhaps I shall have to learn Hebrew some night, and see for myself.  I had always been told that your people had horns."

"I'm telling you, we do not.  If you do not believe me, take a look," he says, gesturing towards his head.

You pause a moment, considering this offer.
*if ethnicity = "african"
	*set lesczynski_rapport %+10
	"Why don't we make a deal. You don't ask to touch my hair and I won't ask to see your horns?"
	
	Lesczynski laughs. It's a genuine laugh, unlike anything else you've heard this evening. "I will take that deal."
	
	"It is agreed."
*elseif (ethnicity = "choctaw") and (rationalism < 80)
	*set lesczynski_rapport %+5
	"On second thought, it does not surprise me that the @{(religious_tradition = "catholic") priests|ministers} would lie. They lie about my people all the time."
	
	Lesczynski nods. "In my faith, we not only encourage you to read the torah, but the midrash and the talmud as well. You must make sense of the texts, not accept them without scrutiny."
	
	"That is not how we were taught."
	
	Lesczynski shakes his head sadly.
*else
	*if discretion > 50
		*set lesczynski_rapport %-10
		"Very well, I shall."  Reaching forward, you take a hold of his head, seeking evidence of any devilry.  It seems, however, that he is speaking the truth.

		The room goes quiet at this display but quickly returns to its normal volume once it is determined that you mean no violence.  "I trust that you are satisfied, then?"

		"Yes, thank you."
	*else
		"No, I believe you."
*return

*label speak_lockridge
*comment 8
*set met_lockridge true
*set memphis_lockridge_convo true
*set questions +1
*choice
	*if heard_of_lesczynski or met_lesczynski
		#"What do you think of the candidacy of Mr. Lesczynski, Senator?"
			"It is difficult for me to muster an opinion of Mr. Lesczynski.  Though he has no obvious deficiencies, he also has not made his position on Stone's rebellion clear.  Therefore, he has little to recommend him."
			
			"And if he were to make his position clear?"
			
			"I am still inclined to support Mr. Pickering.  I have been acquainted with him for some decades, you understand.  Moreover, his opposition to Stone stems from conviction, not a political stance."
			
			"I understand, Senator."
			*label resolve_lockridge
			*if questions > 1

				*if interlocutors > 1
					"Now, if you will forgive me, ${mr} ${surname}, I sense that the hour has grown late."

					"Yes, of course, Senator," you reply.
					*goto caucus
				*else
					"Now, if you will excuse me, ${mr} ${surname}…" he says.  It seems that this is your opportunity to depart.
					*goto choice_of_conversation
			*else
				A pause in the conversation leaves you with the opportunity to ask another question.
				*goto speak_lockridge
	*if heard_of_malloy or met_malloy
		#"What do you think of the candidacy of Miss Malloy, Senator?"
			"She is young, loud, and obnoxious.  Just as Stone likes them, no doubt."
			
			"I'm sorry?"
			
			"She's spent the past few years in Baltimore, no doubt having her head filled with his democratic drivel.  The likelihood of my supporting her is non-existent."
			
			"I see."
			*goto resolve_lockridge
	*if (memphis_chance_encounter != "arthur") and (met_pickering or heard_of_pickering)
		#"What do you think of the candidacy of Mr. Pickering, Senator?"
			"His opposition to Stone's rebellion is well-known.  And I am personally acquainted with him; he came to Charleston before heading to Memphis, to introduce himself and to urge me to attend the election."
			
			"And his opinion on the rebellion is enough to recommend him?"
			
			"Unfortunately, whether we like it or not, the whole Society is watching us here in Memphis."
			
			"I had not realized…" you begin, before being interrupted by Lockridge.
			
			"And because the whole Society is watching, the particulars are filed away in favor of the broader picture: putting an end to Stone's little experiment."
			
			"It is good to know where you stand, Senator.  Let no one doubt your dedication to Consul Adonis."
			*goto resolve_lockridge
	*if (senator_count = 5) and senator_question_unasked
		#"Will there only be five Senators voting tomorrow?"
			*set heard_of_simmons true
			*set senator_question_unasked false
			*if perception > 1
				An ever-so faint shadow of concern passes over the face of Lockridge.
			"Senator Simmons of Mobile was supposed to arrive this evening, but apparently his train has been delayed until tomorrow."
			
			"What happens if he does not arrive?"
			
			"Then he will not be able to vote."
			
			*if heard_of_pickering or met_pickering
				"Isn't Mr. Pickering from Mobile?"
				
				"Yes.  I expect that Senator Simmons will support Mr. Pickering's candidacy."
				*if heard_of_quintana
					*set lockridge_rapport %+5
					
					"Is Isabella Quintaña Garcia still Quaestor there?"
					
					"Why, she is!  In fact, she is the dominus of Mr. Pickering.  Have you met her?"
					
					"No, but I have heard her name mentioned."
			*goto resolve_lockridge
	*if lockridge_judging_party
		#"Senator, have you had a chance to tour the event?"  After all, he did say he was going to be judging you on its success.
			*set discretion %+5
			"I have, ${mr} ${surname}.
			*if party_preparations = 1
				*set lockridge_rapport %-10
				Truly, though, I am surprised you would seek to brag on the matter."
				
				"I'm sorry?"
				
				"The decorations look like they've been used before.  The venue is bleak, the lighting questionable…"
				
				"I…I…" you stammer, shamed through and through.
				
				"It's really not worth discussing."
				*goto resolve_lockridge
			*elseif party_preparations = 2
				*set lockridge_rapport %-5
				Truly, I was expecting something more, the way you spoke of this."
				
				"I'm sorry?"
				
				"The venue is acceptable and the lighting adequate, but there is no amazement here.  I had anticipated a spectacle."
				
				*if discretion < 50
					"There was only a short time…"
					
					"Don't make excuses.  It makes you look weak."
					
					"Yes, Senator."
					*goto resolve_lockridge
				*else
					*set lockridge_rapport %-5
					"Perhaps you aren't looking hard enough," you mutter.
					
					"I'm sorry?" Lockridge inquires, glaring at you.
					
					"Nothing, Senator."
					*goto resolve_lockridge
			*else
				*set lockridge_rapport %+10
				And I must say, I am impressed.  I had not anticipated your success in this.  It pleases me to see that I can still be surprised."
				
				"You do me too much honor, Senator."
				
				"If you keep at this, there may be a future in it for you.  Too often these events are stuffy and boring.  But this…this is marvelous."
				
				You beam under this praise.
				*goto resolve_lockridge
	*if knows_lockridge_wolf and ((lockridge_treatise = 1) and (sw_question_unasked))
		#"I have heard that you are famous for your philosophical musings."
			*set sw_question_unasked false
			Lockridge bursts out laughing; all eyes in the room turn to take in the sight.   When he finishes—he recovers quickly—he looks you in the eyes before speaking.  "You could say that, yes."
			
			"What has made you famous, exactly?"

			"I wrote a treatise on what it means to be a Wolf."

			"I see.  Maybe…somenight…you could send me a copy?"

			*label treatise_copy
			*if (lockridge_rapport > 40) or (shepherd_credentials > 50)
				*set shepherd_credentials %+5
				*set lockridge_contactable true
				*set lockridge_treatise 2
				"I don't see why not.  You'll have to remind me, but I'd be happy to forward one to you."  With that, he offers a way for you to contact him in Charleston, should you have need of such.
				*goto resolve_lockridge
			*else
				"I'm not sure that I have any laying about."  He seems on the verge of boredom.
				*goto resolve_lockridge
	*if (knows_lockridge_wolf = false) and ((shepherds_and_wolves) and (sw_question_unasked))
		#"Where did these terms come from, Shepherd and Wolf?"
			*set heard_of_eusebius true
			*set sw_question_unasked false
			*set knows_about_shepherds_and_wolves_text true
			*set knows_lockridge_wolf true
			"Eusebius of Damascus wrote a dialogue about the relationships between vampires and men, many centuries ago."

			"Did he intend to give them these names?"

			"No, it was part of an extended analogy by one of the characters.  It is amazing what happens when you give something a name," he muses more to himself than you, "and soon vampires the world over were identifying with one side or another.
			*if lockridge_treatise > 1
				The idea, put so simply, took the world by storm."  He pauses a moment, allowing this to sink in.
				*goto resolve_lockridge
			*else
				I even wrote an analysis of the text."
	
				"You did?"
	
				"I did.  A statement of facts, in favor of the Wolves."
	
				"Perhaps you might send me a copy?"
				
				*goto treatise_copy
	*if (knows_lockridge_wolf = false) and ((shepherds_and_wolves = false) and (sw_question_unasked))
		#I try to ascertain Lockridge's thoughts on the treatment of mortals.
			*set sw_question_unasked false
			*if heard_of_shepherds_and_wolves
				*set shepherds_and_wolves true
				"Ah, the eternal question of shepherds and wolves, the two philosophies that motivate our kind."

				"I have heard these terms before, but am unaware of their exact meaning."

				*goto shepherd_wolf_explanation
			*else
				*set heard_of_shepherds_and_wolves true
				*set shepherds_and_wolves true
				*set lockridge_rapport %-5
				"Ah, the eternal question of shepherds and wolves."

				"Shepherds…and wolves?"

				He looks at you incredulously.  "Did your dominus teach you nothing?"

				"I am sorry to say, I have never heard those terms before.  Not in the context of the Society, anyway."

				*label shepherd_wolf_explanation
				"The question, ${mr} ${surname}, is well-posed by you.  How are we to engage with the mortal world?"

				"How do you mean?"

				"Are we to coddle the mortals, protect them from themselves, spend our immortality tending these inferior beings?"

				"Or…?"

				"Shall we take what we can, enjoy it unabashedly, and leave the humans to take care of themselves?"
				*choice
					#"I think we should guide the mortals as best we can; we have experience and foresight that they lack…"
						*set shepherd_credentials %+20
						*set lockridge_rapport %-10
						*set compassion %-10
						Lockridge begins shaking his head at you, clearly disappointed in your answer.  "You are still young.  In time, you will come to see things clearly."

						You pause a moment, and consider how best to recover from this setback.
						*goto resolve_lockridge
					#"Perhaps there is some middle way?  Where we tend to them without coddling them?  We can still take what we need…"
						*set compassion %-5
						*set shepherd_credentials %+5
						*set lockridge_rapport %+5
						"You are still young, but I can respect the inkling of insight you have acquired.  In time, you will discover that we both can't be the master.  It is either us…or them."

						He pauses for effect, allowing these words to sink in.
						*goto resolve_lockridge
					#"I think I agree with you, Senator.  We should take what we need and let our prey take care of themselves."
						*set shepherd_credentials %-20
						*set lockridge_rapport %+20
						*set compassion %+10
						"You have pleased me this evening, ${mr} ${surname}."

						You stand a little straighter under his predatory smile.
						*goto resolve_lockridge
	#"How long have you lived in Charleston?"
		*set discretion %+5
		*set lockridge_rapport %+10
		Lockridge looks at you suspiciously for a few moments before answering.  "A little over a century.  I came to the New World before the Revolution; my dominus feared—correctly, it turns out—for his investments here."
		
		"You were born in England, then?"
		
		"Yes, several centuries ago.  Sussex, to be more precise."
		
		"And do you remain in contact with your dominus?"
		
		Again, his eyes narrow.  "I do."  Sensing a sensitive subject, you decide to change the topic of conversation.
		*goto resolve_lockridge
	*if (heard_of_malloy = false) or ((heard_of_pickering = false) or (heard_of_lesczynski = false))
		#"I'm not sure I know everyone who is standing for the caucus tomorrow."
			*set questions -1
			*if jesse_for_senator
				*if jesses_revolutionary_credentials > 40
					"As far as I am concerned, there are three: Ms. Siobhan Malloy, Mr. Ascher Lesczynski, and Mr. Absalom Pickering. However, someone foolishly thinks that Jesse Whitaker might be a suitable candidate."
				*else
					"There are four, ${mr} ${surname}: Ms. Siobhan Malloy, Mr. Ascher Lesczynski, Mr. Absalom Pickering, and Mr. Jesse Whitaker."
			*else
				"There are three, ${mr} ${surname}:  Ms. Siobhan Malloy, Mr. Ascher Lesczynski, and Mr. Absalom Pickering."
				
			"Thank you, Senator," you reply.
			*set heard_of_malloy true
			*set heard_of_pickering true
			*set heard_of_lesczynski true
			*goto resolve_lockridge
				
*label speak_malloy
*comment 4
*set met_malloy true
*set memphis_malloy_convo true
*set questions +1
*choice
	*selectable_if (discretion > 25) #"Why do you want to be Senator?"
		*set discretion %+5
		Malloy laughs.  It sounds something like baritone wind chimes: throaty and deep, yet still harmonic.  "You're not one for the politics of our kind, are ya?"
		
		"How do you mean?"
		
		"E'en I know you're not supposed to be askin' such things so directly," she says with a smile.
		
		Your ears burn a bit at this remonstration.  "I was simply curious…"
		
		"Yes, yes…I'm here to stand for Stone an' his revolution.  I can' let a bunch of ol' codgers undo all that he's gone an' done."
		
		"So, you're mostly here for the cause?"
		
		"Aye.  What would I want with a bunch of crusty bastards?  I don' want none o' that 'cept for what needs doin'."
		
		*if (carothers_rapport > 50) and (compassion < 50)
			*set revolutionary_credentials %+5
			"It sounds like you would get along with Quaestor Carothers."
			
			"I've not had the pleasure of his acquaintance yet."
			
			"You should see to it, and soon."
		*else
			"You take quite a burden on yourself, then."
			
			"Someone has to, ${mr} ${surname}," she replies.
	#"What do you think of Isaiah Stone's deeds?"
		*set praetors_explained true
		*set knows_ogier_heretic true
		"Miele was a right bastard," she says, spitting out his name.  "He murdered my dominus."
		
		"And no one punished him for violating the Rule of Restraint?"
		
		"Miele accused him o' heresy.  Said he was a Child o' Abraham.  An' since he was the Praetor at the time, no one could say otherwise."
		
		*if (heresy_of_abraham > 0) or (heard_of_heresy_of_abraham)
			"What is that?  A Child of Abraham, I mean," you say, feigning ignorance.
		*if (heresy_of_abraham = 0) and (heard_of_heresy_of_abraham = false)
			*set heard_of_heresy_of_abraham true
			"What is that?  A Child of Abraham, I mean."
		*comment endif
		
		Malloy looks over her shoulder, making sure none of the other bloodsuckers are all that close.  "The Children of Abraham are a cult of vampires, outlawed by the Society.  They believe something about vampires bein' created when God saved Isaac from the blade o' Abraham.  The bloody fools think the Bible will tell 'em how to get right with the Lord, or some such shite.  Anyway, the Praetors, they be tasked with huntin' down such nonsense."
		
		*if heard_of_ogier = false
			*set heard_of_ogier true
			"Who was your dominus?"
			
			"Arnoult Ogier.  A devout Huguenot, he jus' wanted ta' worship in peace.  But there is no peace for our kind.  Not under the rule of Adonis, anyway."
		
		*comment endif
		"And you think it will be different under Stone?"
		
		"Aye, I do," she concludes.
		
		"For your sake, I hope you're right."
	#"Where are you from?  Tell me something of yourself, Miss Malloy."
		*set malloy_rapport %+5
		*set gould_q true
		Malloy sighs ever so slightly, preparing to launch into a speech she has no doubt delivered several times already this evening.  "The gift of the night was given to me by my dominus just afore the War of 1812. If you've heard of my broodmate, Edwin Lefferts, you should know that we are not on speakin' terms.  
		*set heard_of_lefferts true
		
		"I spent the next few decades in New-York, where I made a reputation for wrangling the undead runts that found their way to the city.  Later, I relocated to Baltimore, where I had the pleasure of making the acquaintance of Senator Stone, as he was then known."
		
		*if maddox_num = 3
			*set bounty_on_hugh true
			"Wrangling runts?"
			
			"Aye.  Vampires from the old country have a way of showin' up unannounced."
			*if met_hugh_in_vicksburg
				*set heard_about_bounty_on_hugh true
				
				"Funny you should mention.  I met an Irishman in Vicksburg, said he was from New-York.  He had a funny gap between his front teeth."
				
				"Oh?  What was his name?"
				
				"Hugh Gallagher."
				
				"You've seen him?"
				
				"I have."
				
				"There's a bounty on his head."
				
				"A bounty?"
				
				"Aye.  I'll have to take a look around for him while I'm here."
				
				"And if I were to find him?"
				
				"Then ya oughta write to me.  My quaestor would like to see him returned.  Here…" she says, offering you a way to write to her.
				
				"I thank you," you reply.
				*set malloy_contactable true
			*else
			
				"That doesn't sound so hard."
				
				"So you may think.  There's this one vampire, Hugh Gallagher…they placed a bounty on his head, and still no one can find him."
				
				"I'll keep that in mind."
		*elseif chasing_wilson
			"I have my own problems with wayward vampires, Miss Malloy," you reply, the elusive ${wilson} ${maddox} coming to mind.
			
			"Then ya can appreciate how hard-earned such a reputation was."
			
			"I most certainly can."
		*elseif rejected_sam_wilson and (discretion > 40)
			"Wrangling runts.  Yes, I suppose you could call it that."

			"How do ya mean?"

			"Oh, someone asked me to wrangle a runt, as you so eloquently put it, and I refused."

			She looks at you a little incredulously.  "Tasks such as those are a quick way to prominence in the Society, ${mr} ${surname}.  I would recommend accepting such charges in the future, should ya be so fortunate as to be offered such again."

			"I shall keep that in mind, Miss Malloy."
		*elseif discretion > 50
			*set malloy_rapport %-5
			"The War of 1812? So…you are little more than six decades dead?"
			
			"That is so…"
			
			"That seems awfully young for a Senator. Will you be able to hold your own against the likes of
			*if heard_of_lockridge
				Arthur Lockridge?
			*elseif heard_of_bailey
				John Bailey?
			*elseif heard_of_coffin
				Abigail Coffin?
			*else
				*bug what senators has the player heard of?
			
			Malloy glares at you. "Yes, I have only a few years behind me, but I'm ready to spar with the other senators."
	*if (gould_q) #"@{(ethnicity = "yankee") I never made it to New-York myself, though I was sorely tempted. So|New-York must be a wild place! So many people…so} much opportunity!"
		*set shepherd_credentials %+5
		*set gould_plot +1
		Malloy lets out a laugh. "Opportunity for mischief, if ya be asking me!"
		
		"Oh?"
		
		"Have you not heard of the recent trial of Lord Gordon-Gordon?"
		
		"No?"
		
		"A fella somehow made the acquaintance of Jay Gould and convinced him that he was a Scottish lord! He got Gould to give him a whole million dollars before he slipped up and everyone figured out that he weren't nothing but a fraud."
		
		"He swindled Gould out of a million dollars!"
		
		"Aye! I never would have thought Gould could have fallen for such a scheme, but he did. But I can understand, after a fashion: he was fighting for his life over the Erie Railroad and he needed the help. When someone offered what looked like help, he took it; but this nearly ruined him and he has now lost control of the railroad."
		
		"How unfortunate for him!"
		
		"And for several of our kind! There will surely be consequences, as I ken several vampires had invested heavily in his corporations. Like my brother, Edwin," she says, shaking her head.
		
		"Besides your brother, anyone else that I might have heard of?"
		
		"Are ya familiar with Senator Ashmore? She is neck-deep with the banks of Philadelphia; I have to imagine that she lost a pretty penny in the affair."
		
		*if ashmore_banks = 2
			*set malloy_rapport %+5
			"I had, in fact, heard that."
			
			"So I see…" she replies, impressed.
		*elseif ashmore_banks > 2
			*bug
		*else
			*set ashmore_banks 2
			*set heard_of_ashmore true
			"I am now," you reply.
			
			"Put that in yer pipe an' smoke it, then," she says.			
*if questions > 1
	*if interlocutors > 1
		"Now, if you will excuse me, ${mr} ${surname}, I 'ave much more to accomplish this evening."
		
		"Of course, Miss Malloy, do not let me interfere," you reply.
		*goto caucus
	*else
		"Now, if you will excuse me, ${mr} ${surname}, I 'ave much more to accomplish this evening."
		
		"Of course, Miss Malloy, do not let me interfere," you reply.  Your farewells made, you look around the room, seeking someone else with whom you may speak.
		*goto choice_of_conversation
*else
	There is an awkward pause in the conversation.  Perhaps she is waiting for you to ask another question?
	*goto speak_malloy


*label speak_partridge_and_bailey
*comment 12
*set memphis_partridge_bailey_convo true
*set met_partridge true
*set met_bailey true
*if heard_of_bailey = false
	*bug
*if heard_of_partridge = false
	*bug
*set questions +1
*choice
	*if (heard_of_malloy = false) and (bailey_introduces_malloy = false)
		#"Whom will you support for the election?"
			*set heard_of_malloy true
			*set bailey_introduces_malloy true
			"Why, Ms. Siobhan Malloy, of course!" exclaims Senator Bailey.  "She is a resident of New-York."

			"Yes, Miss Malloy.  Who else could we support?" says Partridge.

			"That woman has spirit," continues Bailey.
			*goto bailey_introduces_malloy
	*if memphis_chance_encounter != "partridge_bailey"
		*if met_malloy or heard_of_malloy
			#"What do you think of the candidacy of Miss Malloy, Senators?"
				"That woman has spirit," begins Bailey.
				
				*label bailey_introduces_malloy
				"She certainly makes the election more interesting," continues Partridge.
				
				"I think her too young for the position, though," says Bailey.
				
				"Youth does not indicate incompetence," replies Partridge.
				
				"No, but it does indicate influence; as in, being the subject thereof."
				
				"Are you saying that, were she elected, she would be the puppet of someone else?" Partridge says in mock incredulity.  His well-groomed beard bobs with the words, making every expression more comical.
				
				"Oh, Heavens no!  Perish the thought!"  Bailey replies, his hand lifted daintily to his forehead.
				
				"And on the matter of the revolution?" you inquire, trying to bring the conversation back to more important matters.
				
				"Oh, she is an ardent supporter of it.  But I suspect that is simply because neither of the other two have come out in favor of it," says Partridge.
				
				"I would concur," says Bailey.
				*label resolve_partridge_bailey
				*if questions > 1
					*if interlocutors > 1
					
						"Now, if you will excuse us, I sense dawn approaching," says Partridge.
						*set whiskey_allowed false
						
						"Of course, Senators.  Do not let me impede you."
						
						"Have no fear of that, ${mr} ${surname}," replies Bailey.
						*goto caucus
					*else
						
						"Now, if you would excuse us," Partridge begins.
						
						"We have some business to conduct," Bailey concludes.
						
						"Yes, of course, Senators," you reply.
						
						After excusing yourself, you look around the reception.  The night is not yet over; with whom would you like to speak?
						*goto choice_of_conversation
				*else
					It seems you have the opportunity to pose another question.
					*goto speak_partridge_and_bailey
		*if met_lesczynski or heard_of_lesczynski
			#"What do you think of the candidacy of Mr. Lesczynski, Senators?"
				"He is very much an unknown," begins Bailey.
				
				"Yes, he came through Louisville seeking my support, but he has not made his position on Stone definitive," continues Partridge.
				
				"Hedging his bets?" you say.
				
				"Most certainly," Bailey concludes.
				*goto resolve_partridge_bailey
		*if met_pickering or heard_of_pickering
			#"What do you think of the candidacy of Mr. Pickering, Senators?"
				*set heard_of_quintana true
				"Simply out of the question," replies Bailey.
				
				"He is an ardent counter-revolutionary," continues Partridge.
				
				"He would seek to undermine Consul Stone, and that is unacceptable."
				
				"I did not realize that he had staked out such a position," you venture.
				
				"As the child of Quaestor Quintaña, could you expect anything less?" says Bailey.
				
				"Yes, she is still angry over the machinations of Overstreet and Jackson, to bring the Floridas under the purview of an American Governor rather than a European one," continues Partridge.
				
				You shake your head at all this new information.  "And Pickering is loyal to his dominus?"
				
				"As far was we know, yes," replies Bailey.
				*goto resolve_partridge_bailey
	*if avoided_new_orleans = false
		#"Do you think Jesse Whitaker could win the title?"
			*if jesses_revolutionary_credentials > 60
				*set jesse_for_senator true
				"Now, that's an idea," replies Bailey after a moment's consideration.
				
				"Why didn't we think of that?" continues Partridge.
				
				"There isn't much time to organize support."
				
				"Maybe the others will be so disappointed in the other candidates, they will simply follow our lead."
				
				"It's not like there are so many Senators here that need persuading."
				
				"Thank you for your suggestion, ${mr} ${surname}; perhaps tomorrow the election will be even more exciting than any of us had hoped," concludes Partridge.
				*goto resolve_partridge_bailey
			*elseif jesses_revolutionary_credentials >= 40
				"He is too much of an unknown," replies Bailey.
				
				"Yes, he has not made his stance on the revolution known," continues Partridge.
				
				"We need a known quantity.  The Senate must vote in favor of Stone."
				
				"Anything else would be a disaster."
				
				"Yes, a disaster," concludes Bailey.
				*goto resolve_partridge_bailey
			*else
				"Most certainly not!" cries Bailey.
				
				"I'm sorry?"
				
				Partridge's hand reaches out to calm Bailey.  "Mr. Whitaker has made his opposition to the revolution of my dominus clear, is what John means."
				*if knows_partridge_childe_of_stone = false
					*set knows_partridge_childe_of_stone true
					Partridge is the offspring of Isaiah Stone?  That is an interesting bit of intelligence, you remark silently to yourself.
				*comment endif
				
				"I had not realized he had taken such a position."
				
				"Well, he has, and I am sure you can understand our opposition to it," continues Partridge.
				
				"Yes, that does make sense."
				*goto resolve_partridge_bailey
	*if knows_partridge_childe_of_stone			
		#"Senator Partridge, how fares your dominus?"
			*set discretion %+2
			Partridge smiles briefly.  "He is well.  As you can imagine, he is very interested in the outcome of this election."
			
			"I can imagine.  Does he have a favored candidate?"
			
			"It would be…inappropriate for the Consul to attempt to interfere with the workings of the Senate, ${mr} ${surname}."
			
			"I am sure he meant nothing by it, Samson," interjects Bailey.
			
			"Of course," replies Partridge.
			*goto resolve_partridge_bailey
	*if rumors_of_plague = false
		#"Do you find Memphis to your liking?"
			*set rumors_of_plague true
			The two Senators look at each other before responding.  "As a matter of fact," the bearded Partridge begins, "we have found things somewhat distressing here."
	
			"Oh?  How so?"
	
			"We procured a residence for ourselves, and upon our arrival found that several of our servants had fallen ill in the days immediately prior."

			*if sick_driver
				"My carriage-driver this evening was burning with fever!"
				
				"He may already be dead," Partridge quips.
				
				"Should you need another way to your haven, we would be happy to provide transportation," continues Bailey.
				
				"Hopefully it will not come to that, but I thank you all the same."
				*goto resolve_partridge_bailey
			*elseif compassion > 60
				"Your point?" you reply.
	
				Bailey seems a little surprised by your callousness, but he takes it in stride.  "It is simply inconvenient to have to worry about our valets falling ill themselves, besides having to find others to fill the empty roles."
	
				"Of course.  That is inconvenient."
				*goto resolve_partridge_bailey
			*elseif compassion >= 40
				"That is unfortunate.  Will they recover?"
	
				"I am uncertain," interjects Bailey, "but some have, in fact, already succumbed to the infection."
	
				"It is virulent, then?"
	
				"Quite."
	
				"I shall have to warn mine own servants.  I cannot afford for them to take ill at the moment."
				*goto resolve_partridge_bailey
			*else
				"How horrible!  Did any die?"
	
				"Several!" exclaims Bailey.
	
				"Have you found the source of the infection?"
	
				"Unfortunately, no.  In fact, the health officials of the city seem most perplexed by the outbreak."
	
				"I shall have to warn mine own employees to be especially careful, as long as whatever this is runs rampant."
				*goto resolve_partridge_bailey
	*if patricide and ((sire_name = "West") and ((memphis_chance_encounter != "partridge_bailey") and sire_question_unasked))
		#"I have not heard from my maker, West, in some time.  Have you any word of him?"
			*set rumors_of_west_dead true
			*set sire_question_unasked false
			*goto rumors_of_west_2
	*if sire_alive and ((memphis_chance_encounter != "partridge_bailey") and sire_question_unasked)
		*if sire_name = "Padre Carlos"
			#"My dominus, Padre Carlos, was, until recently, Quaestor of New Orleans.  Have you heard anything of him as of late?"
				*set sire_question_unasked false
				*set partridge_rapport %+5
				*set bailey_rapport %-5
				"Why, he serves as the new Praetor!" exclaims Partridge.

				"I was aware of that, but I had not heard of his whereabouts or activities otherwise."

				Partridge considers a moment.  "I believe I heard that he spent some time in the Caribbean, but nothing more specific than that."

				You look to Bailey, who does not meet your gaze.  "No, I have heard nothing of him."
				*goto resolve_partridge_bailey
		*if sire_name = "Guillaume de Sainte-Chapelle"
			#"My dominus, ${sire_name}, was, until recently, Quaestor of New Orleans.  Have you heard anything of him as of late?"
				*set sire_question_unasked false
				Partridge shakes his head, but Bailey speaks up: "As a matter of fact, he passed through St. Louis a few years ago.  He stayed for a while, but then continued north."

				"I thank you for this intelligence, sir."

				"You are most welcome, ${mr} ${surname}."
				*goto resolve_partridge_bailey
		*if (sire_name = "West") and (rumors_of_west = false)
			#"I have not heard from my maker, West, in some time.  Have you any word of him?"
				*set sire_question_unasked false
				*set rumors_of_west true
				*label rumors_of_west_2
				"Have you not heard?" begins Bailey incredulously.
				
				*if rumors_of_west_dead
					Your suddenly blood runs cold.  Has your secret been uncovered?  Doing your best to keep your voice level, you finally ask, 
				"Heard what?"
				
				"That he was driven mad by the war!" continues Partridge.
				
				"Driven mad?  By what war?"
				
				"The Civil War!" exclaims Bailey.
				
				"That doesn't make any sense…what would he care about the Civil War?"
				*if rumors_of_west_dead
					What mischief is this?  You burned his body yourself!
				*comment endif
				
				"I cannot say the cause…I can only relate what we have heard," says Partridge.
				
				"We are very sorry to be the ones to impart this news to you, ${mr} ${surname}.  Were you close?" inquires Bailey.
				
				*if patricide
					"As close as was possible," you reply through clenched teeth.
					*goto resolve_partridge_bailey
				*elseif sire_rapport > 60
					"As close as was possible," you reply.
					*goto resolve_partridge_bailey
				*elseif sire_rapport >= 40
					"How could one be close with a beast?" you ask rhetorically.  They seem satisfied to let the matter drop.
					*goto resolve_partridge_bailey
				*else
					"I would not say so, no.  But what could anyone expect of him, living alone in the wilderness like that?"
					
					"Yes, what could one expect?" concludes Partridge.
					*goto resolve_partridge_bailey
	*if (senator_count = 5) and senator_question_unasked
		#"Will there only be five Senators voting tomorrow?"
			*set heard_of_simmons true
			*set heard_of_pickering true
			*set senator_question_unasked false
			The two Senators look at each other while formulating an answer.
			*if revolutionary_credentials > 60
				Bailey begins, with an almost audible wink and a nod, "We're very concerned that Senator Simmons, from Mobile, will not arrive in time."
				
				"Yes, he was supposed to arrive today, but it seems he's been delayed.  It would be just terrible if he missed the vote tomorrow," continues Partridge.
				
				"I'm sure you weren't involved with that, were you, ${mr} ${surname}?" says Bailey.
				
				"No, Senator, I was not."
				
				"Unfortunate, that…such cleverness would be rewarded by certain, shall we say, revolutionary elements?" continues Partridge.
				
				"I see," you reply.  Are they suggesting that you try to arrange for Simmons to be waylaid on his way to the election?
				*if heard_of_quintana
					*set bailey_rapport %+5
					*set partridge_rapport %+5
					You decide to change the subject to something a little less politically charged, especially considering the preponderance of eavesdroppers nearby: "Tell me, is Quintaña still Quaestor of Mobile?"
					
					"She is, and she is Pickering's dominus, in fact," replies Partridge, clearly impressed with your knowledge of lesser luminaries of the Society.
					
					"Oh!  I did not realize," you exclaim.  Such an interesting bit of intelligence!
				*goto resolve_partridge_bailey
			*else
				"Senator Simmons, of Mobile, was scheduled to arrive today, but has not as of yet," begins Bailey.
				
				"What happens if he does not arrive?"
				
				"Then he will not vote," replies Partridge.
				
				"Is his position known?"
				
				"He and Mr. Pickering have shared a home for the past few decades; I would assume that he support is guaranteed," replies Bailey.
				
				*if heard_of_quintana
					*set bailey_rapport %+5
					*set partridge_rapport %+5
					"Tell me, is Quintaña still Quaestor of Mobile?" you inquire.
					
					"She is, and she is Pickering's dominus, in fact," replies Partridge, clearly impressed with your knowledge of lesser luminaries of the Society.
					
					"Oh!  I did not realize," you exclaim.  Such an interesting bit of intelligence!
				*goto resolve_partridge_bailey
	*if sw_question_unasked
		*if shepherds_and_wolves
			#"Where do these terms, Shepherd and Wolf, come from?"
				*set heard_of_eusebius true
				*set knows_about_shepherds_and_wolves_text true
				*set sw_question_unasked false
				"Eusebius of Damascus…" begins Bailey.
				
				"He was a vampire-philosopher…" continues Partridge.
				
				"Never a Governor, though," smiles Bailey.
				
				"A philosopher-Governor!" titters Partridge.
				
				"Yes, a vampire-philosopher who wrote dialogues.  I'm not sure if any of them were any good…"
				
				"I would say not," interjects Partridge.
				
				"But everyone remembers Eusebius, because he gave names to the two sides in the debate."
				
				"And the world has never been the same," sighs Partridge.
				*goto resolve_partridge_bailey
		*elseif heard_of_shepherds_and_wolves
			#"Pardon my ignorance, but I've heard some sort of…philosophical disagreement amongst our kind.  Something about shepherds and wolves?"
				Partridge and Bailey smile at each other.  "It is funny that you should ask that, ${mr} ${surname}," begins Bailey.
	
				"It is a topic which we discuss with some regularity."
	
				"Yes, see, that is because dear Samson is a shepherd," says Bailey.
	
				"…and my dear John here is a wolf," finishes Partridge.
	
				"And what does that mean, exactly?" you inquire.
	
				Partridge smiles benevolently before answering.
				*goto partridge_bailey_sw
		*else
			#"Tell me, do you spend much time tending to the ebb and flow of the mortal world?"
				*set heard_of_shepherds_and_wolves true
				*set shepherds_and_wolves true
				Partridge and Bailey smile at each other.  "It is funny that you should ask that, ${mr} ${surname}," begins Bailey.
	
				"It is a topic which we discuss with some regularity."
	
				"Yes, see, that is because dear Samson is a shepherd," says Bailey.
	
				"…and my dear John here is a wolf," finishes Partridge.
	
				"A shepherd…and a…wolf?"
	
				"Why yes," begins Bailey.
	
				*label partridge_bailey_sw
				*set questions -1
				"John thinks that he is superior to humans.  Or, at least, that they are here to serve him…"
	
				"…while Samson believes that they need careful tending, like rare flowers."
	
				"I never said like a rare flower!" exclaims Partridge.
	
				Bailey rolls his eyes.  "You might as well have.  You're always coddling them.  Believe me, they will survive our worst depredations."
	
				"That may be, but that doesn't mean we can't guide them to our benefit."
	
				"Yes, see, dear Samson is no more moral than I; he simply wants to make sure that the humans are happy and oblivious to their situation.  I am a tad more…sanguine."  The two twitter at Bailey's witticism. "I think that we have little to fear, so long as we take responsibility for our actions.  We should be capable of managing any problems that may arise.  Otherwise, who is the master here?  Us?  Or our food?" Partridge is clearly annoyed by Bailey's soliloquy but allows him to finish uninterrupted.
				*goto resolve_partridge_bailey
	*if heard_of_memeskia = false
		#"What is St. Louis like, Senator Bailey?"
			*set bailey_rapport %+10
			*set anachronism %+10
			*set heard_of_memeskia true
			Bailey smiles broadly.  "It is the gateway to the West, ${mr} ${surname}.  Already, those headed for California come to us as the last bit of civilization before the Pacific Ocean."
			
			"And who is your Quaestor?"
			
			"It is funny that you should ask.
			*if ethnicity = "choctaw"
				Like you, he is an Indian.  Memeskia by name."
				
				"An Indian?  Is a Quaestor?"
				
				"Yes.  He is not so old, but he does well enough.  We have an excellent working relationship."
				
				*if compassion < 50
					"That warms the depths of my heart, Senator," you reply.
					*goto resolve_partridge_bailey
				*else
					"That's interesting.  I've never heard of such before," you reply.
					*goto resolve_partridge_bailey
			*else
				He is an Indian.  Memeskia by name."
				
				"That's interesting.  I've never heard of such before," you reply.
				*goto resolve_partridge_bailey
	#"What is Louisville like, Senator Partridge?"
		*set partridge_rapport %+10
		*set anachronism %+10
		"Well, Elinor Harding is the Quaestor, of course," he begins.

		*if heard_of_harding
			"Of course," you reply.
		*else
			*set heard_of_harding true
			"Quaestor Harding?" you begin.  Seeing that you are unfamiliar with the name, he gestures ever so slightly in the direction of the fashionable woman you had previously noticed.

		"The city grew up because of the rapids in the Ohio River there.  Otherwise, the river is clear from its source until it joins the Mississippi.  Because of these rapids, boats had to stop, unload, and reload on a different boat on the other side.  Louisville was the natural result of this process.  As for its name, it honors Louis XVI, whose soldiers were aiding the Continentals during the Revolution."

		"And when did you settle there?"

		"When I was elected Senator in 1853."

		"And can you say what recommends the city?"

		"The thoroughbreds."

		"I'm sorry?"

		At this, Bailey interjects to explain.  "Dear John has an absurd affection for horseflesh.  He likes to watch them race.  If I didn't know better, I would say that he enjoys the races more than the politics of the Society."

		Partridge smiles grimly.  "One must find some way to pass the decades."

		"You speak truly, Senator," you reply agreeably.
		*goto resolve_partridge_bailey

*label speak_pickering
*comment 5
*set met_pickering true
*set memphis_pickering_convo true
*set questions +1
*choice
	#"Where do you stand on Stone's revolution?"
		*set discretion %+5
		"Revolution?  Revolution?" he says, his face flushing ever so slightly, and his voice rising the tiniest bit—as much as a vampire would allow himself to show, even in his greatest pique.
		
		"I'm sorry.  His act of indiscretion."
		
		"Indiscretion?  I do not know what is worse, ${mr} ${surname}.  To validate it by calling it a revolution, or dismiss it by calling it an indiscretion.  Act of treason is more like it."
		
		"I think, sir, that you have made your position clear."
		
		"I should hope so.  I hope to see him left out for the sun."
		
		The nearby vampires hush at this outburst.  Or, again, what passes for an outburst amongst the dead.  If there were any doubts in the room as to Pickering's feelings on the matter, they have been lain to rest.
		*label resolve_pickering
		*if questions > 1
			*if interlocutors > 1
				"Now, if you will excuse me, ${mr} ${surname}, the dawn approaches," Pickering offers by way of leave-taking.
				
				"Yes, of course."
				
				"I look forward to speaking with you again tomorrow evening."
				
				*if discretion > 60
					"I'm sure you do," you say, knowing how much he will need every shred of support he can muster.
					*goto caucus
				*else
					"Until then," you say, doing your best to avoid committing to anything yet.
					*goto caucus
			*else
				"If you will excuse me, ${mr} ${surname}, I have much business to conduct still this evening."
				
				"Yes, of course Mr. Pickering.  Do not let me impede your campaign."
				
				"I look forward to speaking with you again tomorrow evening."
				
				*if discretion > 60
					"I'm sure you do," you say, knowing how much he will need every shred of support he can muster.
					*goto choice_of_conversation
				*else
					"Until then," you say, doing your best to avoid committing to anything yet.
					*goto choice_of_conversation
		*else
			A momentary pause in the conversation leaves you with an opening to ask another question of him.
			*goto speak_pickering
	*if heard_of_quintana
		#"What do you think of the other candidates?"
			*set heard_of_malloy true
			*set heard_of_lesczynski true
			"I know little about them.  The Malloy woman seems charming enough, but she does not strike me as someone who would treat the post with sufficient seriousness.  And, I hear it rumored that she supports Stone's rebellion!"
			
			"Heavens no!" you reply.
			
			"Yes!  And this Lesczynski fellow, well, he is from New-York.  And really, is there much of a difference between Baltimore and New-York?"
			
			"Is there much of a difference between Mobile and New Orleans?"
			
			Pickering seems consternated by that question.
			*goto resolve_pickering
	#"Why do you want to be the Senator for Memphis?"
		*set discretion %+10
		Pickering seems a little taken aback by the directness of your question.

		"To serve the Society as best I can, of course."
		
		"To serve the Society?"
		
		"Yes.  It is in grave danger.  All of these democrats, abolitionists, papists…the threats are manifold."
		*if ethnicity = "african"
		
			"Threats like me?"
			
			"Well, you're not seeking to free your former people, are you?  After all, slavery has been around for millennia.  It's in the Bible."
			
			"As a matter of fact, I was elated to see the slaves freed."
			
			"Then yes, I suppose it is best that I am standing for the Senate seat, and not you."  You allow yourself the momentary fantasy of wondering what it would be like to watch the blood drip out of his body over the course of several weeks, but soon push this thought from your mind.
			*goto resolve_pickering
		*elseif (religious_tradition = "catholic") and (rationalism > 65)
			
			"Threats like me, you mean?"
			
			"You don't still swear fealty to the Pope, do you?"
			
			"The Pope is Christ's Vicar on earth.  I do."
			
			"Then yes, I suppose it is best that I am standing for the Senate seat, and not you."    You allow yourself the momentary fantasy of wondering what it would be like to watch the blood drip out of his body over the course of several weeks, but soon push this thought from your mind.
			*goto resolve_pickering
		*else
		
			"And these forces seek to destroy the Society?"
			
			"They do.  Look at Stone: an abolitionist, democratic papist!"
			
			"I had no idea.  I have never met the man."
			
			"Well, neither have I, but I can imagine."  Apparently, he has a vivid imagination.
			*goto resolve_pickering
	*if heard_of_quintana and question_quintana_unasked
		#"I understand that Isabella Quintaña Garcia is your dominus?"
			*set question_quintana_unasked false
			"She is.
			*if patricide
				She has long served the Society, recently coming to the Quaestorship of Mobile."
				
				"How did she end up there?" you inquire, trying not to turn your nose up at the mention of that city.
				*label explain_quintana
				
				"It's not as bad as all that, I promise you.  But, after Jackson conquered the Floridas, the citizens of those territories were dispersed and placed under the jurisdiction of Overstreet.  As you can imagine, this caused quite an uproar, as they had been under the purview of the Governor of Spain until that time.  My dominus relocated to Mobile, and by way of amends, Overstreet later acknowledged her claim on the city."
				
				"She resided in St. Augustine originally?" @{met_overstreet The thought that Governor Overstreet needed to make amends with anyone seems a little far-fetched to you, but you refrain from commenting on it.|}
				
				"San Agustín, she would be quick to point out."
				
				"Yes, San Agustín, of course."
				
				*goto resolve_pickering
			*elseif sire_name = "West"
				*set pickering_rapport %-10
				She has long served the Society, recently coming to the Quaestorship of Mobile."

				"During my travels with my maker, West, we never made it there."

				"Oh?  You are one of West's get?"

				"I am."

				"I dare say, I saw him once.  He came through Mobile, and we were still talking about the visit some two decades later."
				*if perception > 1
					Though subtle, your superior senses detect a slight roll of his eyes.  Clearly, your lineage has lowered you in his esteem.
				*comment endif

				*if sire_rapport > 60
					*set pickering_rapport %-5
					"Though I cannot speak for him, Senator, I can tell you that we parted ways under the best of circumstances.  Should you ever have the chance, I would recommend taking the opportunity to get better acquainted."

					A small smile wrinkles Pickering's lips at this.
					*goto resolve_pickering
				*elseif sire_rapport >= 40
					"Though I cannot speak for him, Senator, I can tell you that we parted ways under circumstances that were amicable enough.  Though I did not know it at the time, I was not entirely prepared for the Society when I first made my debut."

					"That does not surprise me," he replies, a small smile wrinkling his lips.
					*goto resolve_pickering
				*else
					*set pickering_rapport %+5
					"We did not see eye to eye.  I have not corresponded with him since we parted ways, and I do not miss him."

					"You are no doubt the better for it," he replies.
					*goto resolve_pickering
			*elseif sire_formerly_quaestor
				*if sire_name != "Padre Carlos"
					As Quaestor of Mobile, she was grieved to hear that your own dominus was deposed.  After all, they were neighbors of sorts."
					
					You do your best not to seem surprised that he knows the identity of your dominus.  "That is kind of you to say, Mr. Pickering.  But tell me, how did she end up there?" You allow your nose to wrinkle just enough, to indicate your distaste for that city.
					*goto explain_quintana
				*else
					As Quaestor of Mobile, she thrilled to hear that your dominus was honored with the title of Praetor.  After all, they were neighbors of sorts."
					
					You do your best not to seem surprised that he knows the identity of your dominus.  "That is kind of you to say, Mr. Pickering.  But tell me, how did she end up there?" You allow your nose to wrinkle just enough, to indicate your distaste for that city.
					*goto explain_quintana
			*else
				*set pickering_rapport %+5
				She thinks highly of your dominus, ${new_orleans_quaestor_address}.  You are fortunate to descend from such a lineage."
				
				You do your best not to seem surprised that he knows the identity of your dominus.  "That is kind of you to say, Mr. Pickering.  But tell me, how did she end up there?" You allow your nose to wrinkle just enough, to indicate your distaste for that city.
				*goto explain_quintana
	*else
		#"Tell me about your dominus."
			*set question_quintana_unasked false
			*set heard_of_quintana true
			"Her name is Isabella Quintaña Garcia, and she is the Quaestor of Mobile."
			
			"Mobile?  How did she end up there?" You allow your nose to wrinkle just enough, to indicate your distaste for that city.
			*goto explain_quintana
	*if shepherds_and_wolves
		#"Do you consider yourself a shepherd or wolf?"
			*set discretion %+5
			For the first time, Pickering looks a little discomforted.  "Humans are nothing," he begins, "they are our food, and need no more consideration than that."
			*if perception > 1
				*set knows_pickering_is_shepherd true
				Though you can't be sure, you're fairly certain Pickering is lying through his teeth.  But why would he lie?
			
			*if (compassion > 60) or (shepherd_credentials < 40)
				"I couldn't agree with you more, Mr. Pickering."
				
				If it were possible, he looks even more discomfited.  "I'm glad to hear that."  He is clearly uninterested in pursuing the topic.
				*goto resolve_pickering
			*elseif compassion >= 40
				"I would think they deserve some consideration.  After all, they could be a danger to us…"
				
				"Impossible."

				*if met_andrew_jackson
					Your experiences with General Jackson would incline you to disagree, but you think better of such flippancy.
					*goto resolve_pickering
				*else
					You are not so certain, but decide it best to keep any further disagreements to yourself.
					*goto resolve_pickering
			*else
				"And they deserve no mercy, at least?"
				
				"No more than they offer their own sheep," he replies.
				*goto resolve_pickering

*label speak_santagostino
*comment 5
*set questions +1
*set memphis_santagostino_convo true
*set met_chiara true
*choice
	*if (hre_theory = false) #"You're from Italy, yes? Did you ever meet Adonis?"
		*set independence %+3
		*set hre_theory true
		Santagostino smiles. "That's all any vampire in the New World wants to know: have you met Adonis? What does he look like? Is he as cruel as they say?"
		
		"Well, is he?"
		
		"I don't know. I was never invited to the court of Rome. My time was spent in the court of Mediolanum."
		
		*if speaks_latin or (intelligence > 2)
			Mediolanum, you know, is the Roman name for Milan. "I see.
		*else
			"Mediolanum?"
			
			"You might know it as Milano."
			
			"Ah, yes.
		And he never graced the court of Milan with his presence?"
		
		"No."
		
		"And what of Praetor Miele? Were you acquainted with him?"
		
		"I was. He was from Lombardy, and spent much of his time in Milano. He was a cruel man, and a crueler vampire."
		
		"Why would Adonis inflict such an individual on the Americas?"
		
		"Do you know what happened in 1806?"
		
		"I'm sure many things happened in 1806, Senator."
		
		"In 1806, the Holy Roman Empire was disbanded by Napoléon Bonaparte, Emperor of the French. Now, you may not think much of the Holy Roman Empire, but to some, it was the direct descendant of the Roman Empire, the Roman Republic, even the Roman kings that predated the Republic."
		
		"What's your point?"
		
		"In 1803, President Thomas Jefferson bought Louisiana from Napoléon and Napoléon used that money to fund his European conquests. One might say that your President financed the destruction of a two-thousand year polity."
		
		"That seems a bit of a stretch."
		
		"Not to many vampires of the Society."
		
		Is this what the revolution is about? The dissolution of the Holy Roman Empire?
	*if jesse_is_broodmate
		#"Do you think my dear brother has a chance at winning the election?"
			"If there is anything I have learned from my years in New Orleans, it is to never underestimate Jesse Whitaker."
			
			"Would you support him for the position?"
			
			*if jesses_sire_formerly_quaestor = false
				*set jesse_for_senator true
				"Of course; your dominus would expect nothing less."
			*else
				"I would consider it, but I see no immediate reason to do so.  Your dominus is deposed, and the new Quaestor of New Orleans has no relationship with Jesse."
			
			"I see."
			
	*else
		#"Do you think Mr. Whitaker has a chance at winning the election?"
			"If there is anything I have learned from my years in New Orleans, it is to never underestimate Jesse Whitaker."
			
			"Would you support him for the position?"
			
			*if jesses_sire_formerly_quaestor = false
				*set jesse_for_senator true
				"Of course; he is the offspring of ${new_orleans_quaestor_address}.  Whitaker is a known quantity, someone whose opinions I can anticipate.  It is so much easier to work with someone on the Senate that way."

				"I do not doubt it."
				
			*else
				"I would consider it, for I see no immediate reason to do so.  His dominus is deposed, and the new Quaestor of New Orleans has no relationship with Jesse."
				
				"That is good to know."
				
	*if (memphis_chance_encounter != "chiara") and (maddox_num = 3)
		#"Did you come to Memphis alone?"
			*set knows_santagostino_seeks_gallagher true
			"I brought a valet, but no other members of the Society accompany me, if that is what you mean."

			"Yes, of course."

			"Though, it is strange that you should ask, as I am supposed to keep an eye out for a vampire who passed through New Orleans some time ago, an Irishman by the name of Hugh Gallagher."

			*if met_hugh_in_Vicksburg
				Your eyes widen in surprise. "Why, I met such a man at the docks of Vicksburg."

				"How long ago?"

				"It was sometime this spring, not long before I came to Memphis."

				"Did you shake his hand?"

				"I did not.  He did not come ashore, lest he violate the Rule of Respect."

				Santagostino chuckles at this.  "The Rule of Respect," she mutters.

				"What does ${new_orleans_quaestor_address} seek of him?"

				"He wishes to ask a few questions of him.  Tell me, were his eyes watery when you saw him?"

				"In fact, they were.  I thought little of it at the time."
				
			*else
				"Why do you seek him?"

				"It is nothing terribly important, but ${new_orleans_quaestor_address} wishes words with him."
				
				"I see," you reply, noncommittally.
				
	*if (memphis_chance_encounter != "chiara") and sire_question_unasked
		*if patricide
			#"Tell me, have you heard anything of my maker?  It has been so long since we parted ways…"  Pretending to be interested in the welfare of your maker every once in a while should continue to avert any suspicion about his untimely death, right?
				*set sire_question_unasked false
				*set discretion %+5
				"Your maker?"
				
				"Yes, ${sire_name}."
				
				Santagostino's brow furrows.  "No, I can't say that I have heard anything of him.  I'm not even sure that I've heard his name mentioned before."
				
				"I'm sorry to hear that."
				
				"It most certainly is!  The dominus and his offspring share a bond like no other; to be deprived of that bond for so long…I simply cannot imagine it."
				
				"And yet, I must endure it," you say woefully.
				
		*elseif sire_name = "West"
			#"Have you heard any news regarding my maker, West?"
				*set sire_question_unasked false
				*set rumors_of_west true
				*set independence %+5
				Chiara's eyes go wide.  "The beast?  Why, have you not heard the rumors?"
				
				"No, what rumors?"
				
				"That he has gone mad!"
				
				"Mad?"
				
				"It is said he was driven mad with grief over the war."
				
				"Grief? Over the war? What does he care about the conflicts of mortals?"
				
				"That I cannot answer, ${mr} ${surname}."
				
				"I thank you for this intelligence, Senator."
				
				She nods by way of reply.
		*elseif sire_formerly_quaestor
			#"What can you tell me of my dominus, before and after his removal as Quaestor of New Orleans?"
				*set independence %+5
				*set sire_question_unasked false
				*if sire_name = "Padre Carlos"
					"Alas, I can tell you little more than you no doubt already know.  Since his appointment as Praetor, he has been travelling throughout the Americas on the business of Consul Stone."
					
					"And his current whereabouts?"
					
					"I heard a rumor about him investigating heresies in the Caribbean, but little more than that."
					
					"Thank you, Senator."
				*elseif sire_name = "Guillaume de Sainte-Chapelle"
					"Alas, I can tell you little more than you already know.  After being replaced by Heer Van der Velde, he traveled up the Mississippi; to Chicago, I believe."
					
					"Up the Mississippi?  To Chicago?  And he did not stop along the way to see his offspring?"
					
					"That is a question I cannot answer for you, ${mr} ${surname}."
					
					"I will have to ask him myself, I suppose," you muse.
				*else
					*set questions -1
					"Alas, I can tell you little.  After his departure from the city, I lost contact with him."
					
					"That is unfortunate."
					
		*else
			#"What news of my dominus, the Quaestor?"
				*set independence %+5
				*set sire_rapport %+5
				*set sire_question_unasked false
				"New Orleans prospers, as does ${new_orleans_quaestor_address}.  I shall make sure to inform him that you inquired after his well-being."
				
				"I thank you for that, Senator."

	*if flirting_with_chiara
		#I continue flirting with her.
			*set santagostino_rapport %+20
			*if santagostino_contactable
				Chiara pretends to resist your amorous advances, but any time you think you might excuse yourself, she makes sure to draw you back into conversation. When you do finally part, she implies heavily that she would like to hear from you again.
			*else
				*set santagostino_contactable true
				Chiara pretends to resist your amorous advances, but when she slips you an address at which you can write to her, you know that your advances are not entirely unwanted.
	*else
		#I try and flirt with her.
			*if santagostino_rapport > 50	
				*set flirting_with_chiara true
				*set santagostino_contactable true
				She greets your innuendos with some witty repartee of her own; it seems that your amorous advances are not entirely unwanted.  So much so that she presses a note into your hand containing an address in New Orleans, by means of which you may correspond with her.
			*elseif revolutionary_credentials > 60
				*set santagostino_contactable true
				Santagostino resists your flirtations, but acknowledges her gratitude for your dedication to Stone's cause.  She squeezes a note into your hand containing an address in New Orleans by means of which you may correspond with her.
			*else
				*set santagostino_rapport %-10
				She seems uninterested in your flirtations.
				*if questions > 1
					It seems that you don't have time to change the subject to something more of interest to her.

					*if interlocutors > 1
						"If you will excuse me, I can feel the sun rising in my blood."
						
						"Yes, I as well."
						
						"[i]Buona notte[/i]."
						*goto caucus
					*else
						"If you will excuse me, there is much I must address still this evening."
						
						"Of course, Senator."
						*goto choice_of_conversation
				*else
					Perhaps you can still salvage something from this conversation.
*if questions > 1
	*if interlocutors > 1
		"If you will excuse me, I can feel the sun rising in my blood," she says.
		
		"Yes, I as well."
		
		"[i]Buona notte[/i]."
		*goto caucus
	*else
		"If you will excuse me, there is much I must address still this evening."
		
		"Of course, Senator."
		*goto choice_of_conversation
*else
	A pause in the conversation leaves you with the opportunity to ask another question.
	*goto speak_santagostino

*label speak_whitaker
*comment 5
*set questions +1
*set whitaker_unspoken false
*choice
	#"Do you want to be Senator of Memphis?"
		"I certainly would not turn the position down."
		
		"But that is not a yes?"
		
		"It is not my immediate goal, no."
		
		"Then why did you come here?"
		
		"Well, I hope to be a Senator somenight.  Even if that is not tonight."

		*if jesse_rapport > 60
			"You know that you have my support, whatever night that it is."

			"Thank you, dear ${given_name}.  Your support means much to me."  He squeezes your hand in his.
		*if (jesse_rapport >= 40) and (jesse_rapport <= 60)
			"Knowing you, I cannot imagine that night to be far off."

			He stares at you, unsure as to whether this is a slight or a complement.  Apparently having given up trying to decide, he changes the subject.
		*if jesse_rapport < 40
			"That does not surprise me in the least," you rejoin, doing your best not to snort.

			He glares at you while attempting to change the subject.
		*label resolve_whitaker
		*if questions > 1
			*if interlocutors > 1
				"The sun is rising."
				
				"I can feel it too."
				
				"Goodnight, then.  I must bid my farewells and find my resting place."
				
				"Until tomorrow."
				*goto caucus
			*else
				"You must forgive me, but I have more business to conduct this evening."
				
				"Of course."
				
				"We shall continue this conversation soon?"
				
				"Yes…" you begin, but Jesse has already drifted away.
				*goto choice_of_conversation
		*else
			He looks at you, waiting for you to continue the conversation or end it.
			*goto speak_whitaker
	#"What do you think of Stone's deeds?"
		*if jesses_revolutionary_credentials > 60
			"They were long overdue."
			
			"Overdue?"
			
			"Yes, it was time for the Americas to throw off the yoke of Adonis.  This is a new world, in need of new leadership."
			
			"It is good to see you have such a clear opinion."

			*goto resolve_whitaker
		*elseif jesses_revolutionary_credentials >= 40
			"The consequences are still unfolding.  Consequences that will reverberate throughout the continents and the centuries.  It is too early to have an opinion."
			
			"Pragmatic."
			
			"You could say that," he says, grinning.
			
			Self-interested is more like it, you think to yourself.
			*goto resolve_whitaker
		*else
			"In a word?  Reprehensible."
			
			"Reprehensible?"
			
			"Yes.  To murder a Praetor in cold blood, to throw the Society into chaos, to stomp on centuries of tradition?  Reprehensible."
			
			"It is good to see you have such a clear opinion."

			"I see," you reply, noncommittal.
			*goto resolve_whitaker
	*if sire_alive and ((sire_name = "West") and (rumors_of_west = false))
		#"Have you heard news of my dominus, West?"
			*set sire_question_unasked false
			*set rumors_of_west true
			"As a matter of fact, yes."
			
			"Oh?  Do not keep me in suspense!"
			
			"I heard that he has been driven mad."
			
			"Mad?  West?"
			
			"Yes.  Sometime during the war."
			
			"Over what?"
			
			"I cannot say.  They are only rumors, after all."
			
			"I thank you for this news, Mr. Whitaker."

			*goto resolve_whitaker
	*if sire_alive and ((sire_surname = "Van der Velde") and (avoided_new_orleans = false))
		#"And how is our maker doing?  Does New Orleans flourish under his leadership?"
			*set new_orleans_quaestor_rapport %+5
			*set jesse_rapport %+10
			*if revolutionary_credentials > 60
				*if letter_from_jesse_about_quaestor_of_new_orleans
					"As I wrote to you when Stone first began his revolt, Heer Van der Velde does not support or condone these activities.  And New Orleans has, in fact, prospered by means of his strong ties with the Old World.  It is one of the few great port cities where supporters of Adonis are welcomed."

					"I see."

					"You could say, then, that he is disappointed with your activities."

					"Disappointed?"

					"Come now, ${mr} ${surname}…your reputation as a revolutionary has been noted.  Did you think that word of your actions would not reach our dominus?"

					"He does retain an interest in his offspring, I suppose…though he does precious little to demonstrate it."

					"I would venture that he assumes you will return to the fold.  Some night, anyway."

					"I suppose that I shall have to keep him guessing, dear brother."

					*goto resolve_whitaker
				*else
					"Unlike you, our dominus has made his opposition to Stone and his revolution clear.  And New Orleans has, in fact, prospered by means of his strong ties with the Old World.  It is one of the few great port cities where supporters of Adonis are welcomed."

					"I see."

					"You could say, then, that he is disappointed with your activities."

					"Disappointed?"

					"Come now, ${mr} ${surname}…your reputation as a revolutionary has been noted.  Did you think that word of your actions would not reach our dominus?"

					"I have heard precious little from our dominus since we parted ways; I had no expectation that he would monitor me."

					"Ah, but we are his progeny.  Until his bones are ash there is little you can do to escape his attentions."

					"I am unsure whether I should be comforted or chastised by such a statement, dear brother."

					"Perhaps a little of both."

					"Yes, perhaps."

					*goto resolve_whitaker
			*else
				*if jesses_revolutionary_credentials < 60
					"It does.  And those that oppose Stone and his so-called revolution know that they have a friend in New Orleans.  You should take pride in the knowledge that he has taken a stand against these upstarts."

					"I certainly do, dear brother," you reply.
					
					*goto resolve_whitaker
				*else
					"Flourish…I suppose you could say that."
					
					"How do you mean?"
					
					"The city has become a hotbed of Loyalists…individuals committed to reversing Stone's revolutionary tide."
					
					"And you disapprove?"
					
					"Just as New Orleans fell to the Union, so too will the old guard fall before Stone's cause."
					
					"You seem very confident in Stone's prospects."
					
					Jesse narrows his eyes at you, a tad suspiciously.
					*goto resolve_whitaker
	*if jesse_is_broodmate and sire_formerly_quaestor
		*if letter_from_jesse_about_quaestor_of_new_orleans
			#"What news of our maker, brother?  I have heard little since you wrote to me…"
				*label jesse_on_sire
				*set jesse_rapport %+10
				*if sire_surname = "Villanueva"
					"Unfortunately, the Gulf of Mexico is not the place that it was fifty years ago; there is little room for piracy in those waters now."

					"If he has not set out to sea…"

					"Oh, he has.  One man's pirate is another man's revolutionary: he has joined with the Cubans, fighting for their independence from Spain.  Unfortunately, I hear even his herculean efforts have not brought the island victory.  His fleet was burnt to the waterline and he took to the highlands.  I have not heard from him now in several years, but the fighting does not go well."

					"I did not realize he cared so for the Cuban cause."

					"I don't think that he does.  He relishes the battle itself, and the blood that he can spill in its name."

					"Then he has not changed with the decades."

					"Nor should you expect him to."

					"I suppose not."

					*goto resolve_whitaker
				*elseif sire_surname = "Sainte-Chapelle"
					"Last I heard, he went north."

					"North?  North, past Memphis?"

					"Yes.  Past St. Louis, even.  To Chicago, maybe?"

					"Why would he do that?"

					"I suspect that there will be a new Governor appointed, for that part of the world.  I think he intends to be play a part in that decision."

					"Could he become Governor?"

					"I doubt it, but I suppose it is possible."

					@{(sire_rapport >= 50) "That is good news!"|"I see."}

					*goto resolve_whitaker
				*elseif sire_surname = "Padre Carlos"
					*if jesses_revolutionary_credentials < 40
						"I am embarrassed to say that he is now based in Baltimore, in the court of Stone.  He goes out as necessary to expunge heretics.  Unfortuantely, it is often unclear if the accusations of heresy are true, or rather part of a pogrom by Stone."

						*if revolutionary_credentials < 40
							*set jesse_rapport %+10
							"That is horrible.  I do understand how he could betray Adonis like that."

							"I could not agree with you more.  However, I feel as though his service is one of opportunity, rather than loyalty to the revolutionary cause."

							"May it be so!  In the meantime, I can only hope that his treachery does not poison the true members of the Society against us."

							*goto resolve_whitaker
						*else
							*set jesse_rapport %-10
							"Those are strong words, brother."

							"I speak the truth."

							"As you see it, perhaps.  But to accuse Stone of using his praetor for political ends…"

							"Is hitting the mark, I know."
							
							"But…" you sputter.

							*goto resolve_whitaker
					*else
						"He is now based in Baltimore, in the court of Consul Stone.  He goes out as necessary to expunge heretics."

						*if (revolutionary_credentials < 40) and (discretion > 55)
							*set jesse_rapport %-30
							"By which you mean that he is a lap-dog for the traitor?"

							"A lap-dog!"

							"Yes, going out and murdering members of the Society, and using accusations of heresy to justify it…"

							Jesse's eyes flash with fury.  "I suggest you quit my presence, ${mr} ${surname}.  We would not want to further disturb this soirée with our family affairs."

							"You are right, dear brother," you reply, before stalking away.
							*if interlocutors > 1
								*goto caucus
							*else
								*goto choice_of_conversation
						*else
							"That does not surprise me."

							"Nor me, to be truthful," he says with that rakish grin of his.  "I'm more surprised that he hasn't taken to burning them at the stake.  But I imagine there will be time yet for that." @{heretic Your laughter is forced, but Jesse does not seem to take note.|The two of you have a good chuckle at that.}
							*goto resolve_whitaker
				*else
					*set questions -1
					"I have heard little.  He was a shadow in life, and he remains a shadow in death."

					"That is unfortunate.  I had hoped for more news."

					"I wish I had more to give you."

					"I do appreciate it, though."

					*goto resolve_whitaker
		*else
			#"What news of our maker, brother?  I have heard that he is no longer quaestor…"
				*goto jesse_on_sire
	#"What do you think of the candidates for the position?"
		*set heard_of_lesczynski true
		*set heard_of_malloy true
		*set heard_of_pickering true
		*set heard_of_quintana true
		*if jesses_revolutionary_credentials > 60
			"Malloy has kept the counsel of Consul Stone for several years now.  Obviously, she would advance his agenda in the Senate."
			
			"Clearly."
			
			"Pickering, on the other hand, is an instrument of his dominus, an antiquated bitch if ever I had the pleasure of meeting one."
			
			"Jesse!"
			
			"I only speak the truth," he says with a scowl. Thankfully, Mr. Pickering is occupied with cajoling @{(met_coffin or heard_of_coffin) Senator Coffin|the Puritan woman} at the moment. "And, believe me, Isabella Quintaña is that and more."
			
			"Not everyone always wants to hear the truth."
			
			"Well, that Lesczynski fellow, he's up to something, I just don't know what it is."
			
			"Like seeking power?"
			
			"Yes, but I don't think it's the Senate seat that he's after, in the long term, anyway.  It is just a means to an end."
			
			"Of course," you say with a wink and a nod.

			*goto resolve_whitaker
		*elseif jesses_revolutionary_credentials >= 40
			"That Malloy woman has been sucking at the teat of Stone for the past several decades.  Obviously, she would advance his agenda in the Senate."
			
			"Clearly."
			
			"Pickering, on the other hand, is an instrument of his dominus, an antiquated bitch if ever I had the pleasure of meeting one."
			
			"Jesse!"
			
			"I only speak the truth," he says with a scowl. Thankfully, Mr. Pickering is occupied with cajoling @{(met_coffin or heard_of_coffin) Senator Coffin|the Puritan woman} at the moment. "And, believe me, Isabella Quintaña is that and more."
			
			"Not everyone always wants to hear the truth."
			
			"Well, that Lesczynski fellow, he's up to something, I just don't know what it is."
			
			"Like seeking power?"
			
			"Yes, but I don't think it's the Senate seat that he's after, in the long term, anyway.  It is just a means to an end."
			
			"Of course," you say with a wink and a nod.

			*goto resolve_whitaker
		*else
			"That Malloy woman has been sucking at the teat of Stone for the past several decades.  Obviously, she would advance his agenda in the Senate."
			
			"Clearly."
			
			"Pickering, on the other hand, would be a puppet of his dominus, Isabella Quintaña.  And she and Lockridge are clearly allies in putting an end to Stone's rebellion."
			
			"I hadn't realized."
			
			"And Lesczynski?  Well, he's up to something, I just don't know what it is.
			
			"Like seeking power?"
			
			"Yes, but I don't think it's the Senate seat that he's after, in the long term, anyway.  It is just a means to an end."
			
			"Of course," you say, with a wink and a nod.

			*goto resolve_whitaker
	*if (outing_with_jesse = false) and ((outing_invitation_rejected = false) and (questions > 1))
		#In fact, I want to inquire if Jesse might want to arrange a rendezvous for after the caucus.
			*set initiated_jesse true
			*gosub ask_jesse_out
			*if interlocutors > 1
				*goto caucus
			*else
				*goto choice_of_conversation

*label caucus
*if whiskey_allowed and (speaks_english and (heard_of_bailey and ((perception > 0) and ((carothers_rapport > 50) or (bailey_rapport > 50)))))
	*gosub whiskey_ring
*page_break
By now, even the youngest in the room can sense the approach of dawn.
*if ((memphis_reception_planner = "Harriet") or (memphis_reception_planner = "Sally"))
	The @{((memphis_reception_planner = "Harriet")) temperance workers|church volunteers} have already begun to clean up the room, and they seem anxious to be rid of the guests.
*if earned_status
	
	To close the evening, Carothers gathers the other vampires around to publicly thank you for the effort you put into the reception.  The attendees murmur their approval, and each bids you goodnight as they file out the door.  It seems you have made your mark upon them.
	*set status +1
*elseif train_status and (status = 0)
	
	To close the evening, Carothers gathers the other vampires around to publicly thank you for your efforts @{(party_preparations >= 3) organizing the reception|gathering refreshments for the evening}. The attendees murmur their approval, and each bids you goodnight as they file out the door. Malloy, Lesczynski, and Pickering all make sure to observe in some form or another that they will now have the pleasure of your company for the following evening.
	
	It seems you have made your mark upon them.
	*set status +1
*else
	The tension mounts steadily until, one by one, the gathered vampires begin offering their final words before departing for their temporary havens.  Several of them acknowledge you on their way out, acknowledgments which you return in kind.
@{offer_to_help_coffin_stop_ascher Senator Coffin, in particular, gives a sly sort of wink on her way out the door.|}

*if (heresy_of_masons > 0) and (jesse_rapport > 35)
	*set jesse_rapport %+20
	*set knows_jesse_mason true	
	Among these farewells is a gesture from Jesse.  A sign, a subtle one though unmistakable one, made with his hand.  You return the sign with the appropriate response, and soon you find yourself in a quick conversation with another Mason!

	"I had no idea!" you exclaim.

	"We share a maker, dear ${given_name}.  What did you expect?  We shall speak more later.  The sun is rising."

	"Yes, let us."

	*if carothers_rapport > 40
		Carothers also catches you before you leave.
		*goto carothers_farewell
	*elseif status = 0
		*goto early_no_status
*elseif jesse_rapport > 60
	Among these farewells is the one from Jesse, who drifts over one last time.  You can sense his desire to propose something…intimate?…but this day is not the day for such.  And so he embraces you and then sets out on his merry way.
	
	*if carothers_rapport > 40
		Carothers also catches you before you leave.
		*label carothers_farewell
		"It was quite a reception."
		
		"It was, Quaestor.  Just think, tomorrow night we will have a new Senator."
		
		*if status = 0
			*goto no_status
		*else
			"Let us hope.  I do not think I could do this again."
			
			"Good night."
	*elseif status = 0
		*goto early_no_status
*elseif carothers_rapport > 40

	Before you leave, Carothers approaches you.
	*goto carothers_farewell
*elseif status = 0
	*label early_no_status
	Carothers corners you on your way out.

	*label no_status
	"You understand that your presence will not be required tomorrow evening?"

	"Excuse me?"

	"You have no standing in the Society.  
	*if carothers_rapport > 55
		Though I would have you there if it were up to me, the Senators have made it clear to me that you are not welcome at the caucus."

		"I…"

		"I trust you can otherwise occupy yourself."

		"Of course, Quaestor…"

		"Good.  Good night, then."
	*else
		Your presence is not welcome at the caucus.  I trust that you understand?"

		"I…"

		"Good.  Good night."
*if (senator_question_unasked = false) and ((streetwise > 1) or (joined_kkk))
	*page_break
	The thought occurs to you on your way home that if Senator Simmons is coming on the train, perhaps you might see that his travelling-coffin is waylaid for a few hours?  If it were diverted and he missed the election tomorrow, Pickering would have a much harder go of things.
	*choice
		*if joined_kkk
			#I will contact General Forrest—he is President of the Memphis-Charleston railroad, after all—and ask that Simmons' coffin be misplaced for a few hours.
				*set revolutionary_credentials %+5
				*set simmons_waylaid true
				You lay down for the day, confident that tomorrow's election will be full of excitement.  With Simmons absent, someone other than Pickering might actually win.
		*if streetwise > 1
			#I will contact some of the workers at the rail depot.  I'm sure Simmons' coffin can be left trapped under some other heavy things for a few hours.
				*set revolutionary_credentials %+5
				*set simmons_waylaid true
				You lay down for the day, confident that tomorrow's election will be full of excitement.  With Simmons absent, someone other than Pickering might actually win.
		#Interfere?  If anything, I want to speed his delivery!
			*set revolutionary_credentials %-5
			Unfortunately, there is little you can do to speed his delivery, but you go to sleep knowing that tomorrow night, Stone's rebellion will be quashed.

*page_break
*if chasing_wilson
	*set letter_directing_to_stennis true
	You wake up on the evening of the election to find a note waiting for you. @{literate Unfolding it, you scan the lines quickly.|You rap your fingers impatiently as you wait for Franklin to read it to you.}
	
	One of the individuals you hired years ago to keep an eye out for ${wilson}—a man by the name of Stennis—claims to have spotted the errant whelp.  He requests that you join him in the Pinch.
	
	Of course, you cannot imagine a worse moment for ${wilson} to come crawling out of the woodwork.
	*if status = 0
		It seems you have your work cut out for you.
		*page_break Next
		*goto_scene memphis_1873_plague
	*elseif (withers_rapport < 35) and (wilson_embraced_by_withers)
		Should the Senators catch wind of this, Withers would be terrifically embarrassed.
	
		Besides, what are you going to do, shirk the most important event of the decade?
	*elseif rejected_sam_wilson
		For Withers, anyway—she would surely be mortified were this matter to become a subject of gossip.
	*else
		Should the senators catch wind of this scandal, well,
		*if wilson_embraced
			you would never live it down.
		*if wilson_embraced_by_withers
			Samantha would never live it down.
		But what can you do?  Would you dare to shirk the most important event of the decade?
	
	*choice
		*if wilson_embraced
			#I must rein in my errant offspring.
				*label resolve_pinch
				You dress yourself and head towards the Pinch.
				*page_break
				*goto_scene memphis_1873_plague
			#I cannot miss this soirée.  I can always hunt down ${wilson} after the gathered vampires depart.
				*goto_scene memphis_1873_caucus
		*elseif rejected_sam_wilson
			#Carothers did order to me to pursue ${wilson}; I will accede to his wishes.
				*goto resolve_pinch
			#Regardless of Carothers's orders, ${wilson} is a threat to the people of Memphis. He must be stopped!
				*set compassion %-5
				*goto resolve_pinch
			#Carothers may have ordered me to pursue ${wilson}, but that can surely wait for another night.
				*set independence %+5
				With Franklin's assistance, you attend to your appearance as hastily as you dare. You must not keep a room full of vampires waiting!
				*finish Next
		*else
			#I gave my word to @{(carothers_debt_wilson > 1) Carothers that I would capture Withers's|Withers that I would capture her} errant offspring.
				You dress yourself and head towards the Pinch.
				*page_break
				*goto_scene memphis_1873_plague
			#I may have given my word to @{(carothers_debt_wilson > 1) Carothers|Withers}, but I certainly didn't mean for that to take precedence over an event such as this!  Besides, I can always hunt down ${wilson} after the gathered vampires depart.
				The next evening, your eyes snap open the moment the sun sets. With Franklin's assistance, you attend to your appearance as hastily as you dare. You must not keep a room full of vampires waiting!
				*finish Next
*else
	*if rejected_sam_wilson
		*bug should be $chasing_wilson
	Your eyes snap open the moment the sun sets.  The caucus is this evening.
	*choice
		*if (status > 0) #Time to go.
			With Franklin's assistance, you attend to your appearance as hastily as you dare. You must not keep a room full of vampires waiting!
			*finish Next
		*selectable_if (status > 1) #I will be fashionably late.
			*set discretion %+10
			*label exit_caucus
			You take your time getting ready.  They wouldn't start without you, would they?
			*finish Next
		#I've had enough of the Society for now; I want to avoid the snake-pit that tomorrow night will bring.
			*set independence %-20
			*set carothers_rapport %-10
			*goto_scene memphis_1873_plague
		*if (status = 0) #I wish that I could go to the caucus, but I cannot due to my lack of standing in the Society.
			*set independence %+10
			*goto_scene memphis_1873_plague

*label ask_jesse_out
*choice
	*if memphis_reception_planner = "Dido"
		#"Two nights hence, there is a performance here at the Greenlaw Opera House…."
			*label jesse_greenlaw
			*set date_location "greenlaw"
			*set jesse_rapport %+10
			*set outing_with_jesse true
			"I suppose that wouldn't be a terrible way to spend the evening.  I'm almost curious to know what passes for culture in a city like this."
			
			You think that was a yes?
			*return
	*else
		#"Two nights hence, there is a performance at the Greenlaw Opera House…."
			*goto jesse_greenlaw
	*if (streetwise > 0) or ((feeding_style = "prostitutes") or (feeding_style = "gamblers"))
		#"I was just thinking we should have a night on the town.  There are some less-than-reputable corners to this town worth exploring…"
			*set jesse_rapport %+15
			*set outing_with_jesse true
			Jesse nearly claps his hands in excitement.  "I did not realize we would get along so famously, dear ${given_name}!  Let us plan for such after this whole election mess is finished?"
			
			"Yes, let us do so."
			*return
	*if (creation > 0) or (memphis_reception_planner = "Olivia")
		#"There is a salon held by one of the local debutantes, Olivia…she manages to gather an interesting crowd of artists and writers, such as there are in this town."
			*if jesse_rapport > 40
				*set outing_with_jesse true
				*set jesse_rapport %+10
				"I suppose that that doesn't sound dreadful.  But after tonght, I think I would prefer to not be surrounded by idle prattle.  Shall we take a walk along the river instead?"

				You nod agreeably.  "Tomorrow night, then?"

				"Yes, tomorrow night."  
				*if compassion < 45
					You do your best not to clap your hands with excitement at the prospect of some time alone with Jesse.
				*return
			*else
				*set outing_invitation_rejected true
				*set jesse_rapport %-5
				"That sounds dreadful."

				"No, truly…"

				He gestures dismissively.  "Please, we are in the middle of an election.  We can speak of this another time."

				Crestfallen, you take your leave of him.
				*return
	*if technology > 0
		#"There is the most amazing devices they have developed here, for the sorting and processing of cotton…"
			*set outing_invitation_rejected true
			Jesse instantly looks bored.  "Cotton is sold to make money.  I like spending money.  How cotton is made is of little interest to me, ${mr} ${surname}."
			
			*if discretion > 50
				"I'm sorry if I bore you, Mr. Whitaker.  I'll try to do better next time."
				
				*if male
					"Plucky, aren't you?  Well, I suppose our dominus did have a reason for giving you the gift.  Now, if you will excuse me…"
					*return
				*else
					*set jesse_rapport %+5
					"Spirited, aren't you?  Well, I suppose our dominus did have a reason for giving you the gift.  Now, if you will excuse me…"
					*return
			*else
				*set jesse_rapport %-5
				"Pardon me, Mr. Whitaker.  I thought you might want to take in some of the sights of Memphis, indications that the economy is reviving…"
				
				"Most certainly not.  Now, if you will excuse me…"
				*return
	*if religious_tradition = "catholic"
		*selectable_if (rationalism > 60) #"I was just thinking to myself, we should attend a mass together."
			*set outing_invitation_rejected true
			*set rationalism %+5
			*set jesse_rapport %-5
			Jesse looks at you askance.
			*if sires_faith = "faithful"
				"I had enough of that mumbo-jumbo while I resided with our maker.  I need no more of it from you."
				
				"Mumbo-jumbo?"
				
				"I wasn't even Catholic when I was alive.  Now, if you will excuse me…" he says, taking his leave of you.
				*return
			*else
				"I was not a Catholic when I was alive, and I have found no reason to change that since dying."
				
				"But, your immortal soul…"
				
				"If it exists, it is long past redemption.  Now, if you will excuse me…" he says, taking his leave of you.
				*return
	*if religious_tradition = "reformed"
		*selectable_if (rationalism > 60) #"I was just thinking to myself, we should attend a service together."
			*set outing_invitation_rejected true
			*set rationalism %+5
			*set jesse_rapport %-5
			Jesse looks at you askance.
			*if sires_faith = "faithful"
				"I had enough of that mumbo-jumbo while I resided with our maker.  I need no more of it from you."
				
				"Mumbo-jumbo?"
				
				"Now, if you will excuse me," he says, taking his leave of you.
				*return
			*else
				"I was not a religious man when I was alive, and I have found no reason to change that since dying."
				
				"But, your immortal soul…"
				
				"If it exists, it is long past redemption.  Now, if you will excuse me…" he says, taking his leave of you.
				*return
	*if initiated_jesse = false
		#"I shall think on it, Mr. Whitaker." Anything to get this reprobate away from you.
			*set jesse_rapport %+5
			"I look forward to your thoughts.  But do not think on it too long; I may not be here forever."
			
			"Noted," you reply while drifting away from him.
			*return

*label whiskey_ring
*page_break
Your conversation ended, you take a moment to survey the room one last time. The night will surely be called to an end shortly, but @{met_bailey Bailey|the fair-haired, clean-shaven Senator} seems to have something on his mind: he has cornered Carothers while in your vicinity. You do your best to drift casually into the conversation.

"…Aichinger's machinations are unacceptable.  And while I assume that you have an affection for the Republicans and President Grant in particular, do you really think this is in the best interest of you and your people?"
*set heard_of_aichinger true

"Aichinger?" you inquire mildly.

Bailey stiffens, having just noticed your presence.
*if met_bailey
	*if bailey_rapport > 60
		When he realizes it is you, he smiles.
	*elseif (bailey_rapport >= 40)
		He nods at you courteously.
	*else
		He rolls his eyes, clearly displeased.
	"Yes, Lothar Aichinger.  He is a citizen of St. Louis, and he has set up a ring of mortal criminals who are defrauding the Federal government."
*else
	*set heard_of_bailey true
	*set met_bailey true
	Carothers takes note of you.  "Senator Bailey, this is ${given_name} ${surname}, a citizen of Memphis."

	You ${bow} by way of greeting.  "Pardon my interruption, Senator.  You were saying…"

	He looks at you a moment, then continues.  "Yes, Lothar Aichinger.  He is a citizen of St. Louis, and he has set up a ring of mortal criminals who are defrauding the Federal government."
*comment endif

"I am still unclear as to what you want me to do about this, Senator," Carothers says.

"I have received intelligence that they intend to extend their corruption to other cities.  I hope that you will see to it that any efforts to expand the enterprise to Memphis will fail."
*set whiskey_ring_plot true

"You will forgive me, Senator, if I do not overcommit myself at this time.  Though I am not pleased by the idea of this Aichinger extending his operation to my city, the fact that this was organized to support the reelection of President Grant certainly stands in its favor."

"That is well and good, Quaestor, but the election is won, and now this corruption eats at the heart of the democracy which you cherish so dearly."

"I will consider your words carefully, Senator," replies Carothers with finality.

"Thank you, Quaestor Carothers."  With that, Bailey excuses himself.

Carothers turns and addresses you. "The night is nearly finished.  We will discuss this later."

"Yes, Quaestor," you reply.
*return