*comment ñáéç…—
*hide_reuse
*advertisement
*temp that_negro "that freedman"
*temp that_one_eared_negro "that one-eared freedman"
*if maddox_num = 2
	*set that_negro "that Cajun"
	*set that_one_eared_negro "that one-eyed bumpkin"
*if chasing_wilson = false
	*set that_negro "that Irishman"
	*set that_one_eared_negro "that gap-toothed Irishman"
*temp shaft_discovered false
*temp stennis_investigates false
*if (second_memphis_reception_attended = 1) or (second_memphis_reception_attended = 5)
	Your eyes flutter open.  Quickly, you shut them again, as if to block out the memory of 
	*if acquiring_vessels_1877 = "failed"
		your encounter with Carothers several nights ago.  The memory has not improved with time.
	*else
		the previous night.
	
	After several minutes spent composing yourself, you emerge from your resting-place.  There is a note waiting for you.
	*if chasing_wilson
		*if met_stennis
			It is from Stennis.  He has seen ${wilson} and urges you to join him.
		*else
			It is from a man by the name of Stennis; he is one of several individuals you hired to keep an eye out for ${wilson} when you arrived in Memphis.
		He invites you to join him in the Pinch.
		*if wilson_embraced
			Your offspring is on the loose.  Perhaps you will regain the approval of Carothers if you can finally rid yourself of this albatross.
		*else
			Withers' offspring is on the loose.  Perhaps you will regain some of Carothers' opinion of you if you can capture this miscreant.
	*elseif heard_about_bounty_on_hugh
		*if met_stennis
			It is from Stennis.  He has caught wind of Hugh Gallagher and urges you to meet with him.
		*else
			It is from a man named Stennis.  He identifies himself as an agent of Carothers and reminds you of the bounty on Hugh Gallagher.  It seems that the Irishman has been seen about the Pinch.
	*else
		The note is from Carothers.  He implies that there is a way to get back into his good graces: Hugh Gallagher has been spotted wandering the Pinch.  Carothers expects for you to find him and deal with him.
		*if met_stennis
			Stennis is waiting for you.
		*else
			His agent, Stennis, is waiting for you.
	
	*if literate
		You hand the note back to Franklin to dispose of.
	*else
		@{(compassion < 50) You thank Franklin for reading the letter with a brief nod.|You wave Franklin—and the note he just read you—away.}
	He slips out of the room, leaving you to dress yourself.
	
	The caucus is this evening. @{(independence > 30) You try to force down the tide of shame that rises at the thought of your banishment from those proceedings.|} Perhaps the night will see some sort of redemption for you.
	
	One can hope.	
*elseif (second_memphis_reception_attended = 3) or (second_memphis_reception_attended = 4)
	Your eyes flutter open.  The caucus is this evening, but you have other concerns: $!{wilson} $!{maddox}.

	When you emerge from your sleeping-place, Franklin is ready for you.  Within minutes, you are cleaned, dressed, and ready to hunt.
	*if memphis_affair
		It is hard to leave Clotho.  She is delirious with fever.  But say goodbye to her you do.
	You close the door to your home behind you, focusing your mind on the task at hand.
	
	Tonight, you shall find this villain.
*elseif second_memphis_reception_attended = 2
	*comment TODO make this cooler.
	Unfortunately, lacking fresh intelligence of ${wilson}, the night is fruitless.

	Yet, when you return from your searches, you are greeted by a welcome discovery: a note from Stennis.
	*if literate
		Opening it, you see that Stennis requests your presence.  Perhaps your luck has finally turned.
	*else
		Handing it to Franklin, you direct him to read it aloud.

		Clearing his throat, Franklin informs you that Stennis requests your presence.  Perhaps your luck has finally turned.
	*page_break
	Your eyes flutter open.  Tonight is the night.  You dress hurriedly and head towards the Pinch to meet with Stennis.
*else
	*bug

*page_break
*if first_memphis_caucus_attended = false
	He stands beneath the streetlamp.  You have a weird sense of [i]déjà vu[/i]: here he stands, beneath the same streetlamp as four years ago, waiting to impart word of ${wilson}.
	
	Stennis waves hello when he sees you approaching.
	*if stealth > 1
		You thought it best not to terrify him with a sudden appearance; it might make the interrogation more difficult than it needs to be.
	*goto meet_stennis_1
*elseif chasing_wilson
	Stennis stands beneath a streetlamp, as promised.  It is an unassuming corner in the Pinch, where the plague has seen the most victims.  Stennis wears a cloth over his face, but you recognize him all the same.
	*label meet_stennis_1
	"Evenin', ${sir}."
	
	"Good evening, Stennis."
	
	"I think I've found him.  I seen ${that_one_eared_negro}."
	
	"Where?"
	
	"I will take you there."
*else
	@{met_stennis Stennis|A man} stands beneath the promised streetlamp.  The intersection is an unassuming one in the middle of the Pinch, where the plague has seen the most victims.  @{met_stennis Stennis wears |Stennis—or the man whom you assume to be Stennis—wears} a cloth over his face.  Whether it is to block out the smell of decomposing bodies or to somehow ward off the fever is unclear.  
	*if met_stennis
		You greet him, and then he speaks.
	*else

		"Hello.  ${mr} ${surname}, I take it?"
		
		"Yes."
	*comment endif
	
	"Well, I seen him.  $!{that_one_eared_negro}."
	
	"Where?"
	
	"I'll take you there."
*page_break
"I see a house, rotting from the plague."
*if (first_memphis_caucus_attended = false) and (compassion < 60)
	You also note that it is just a few doors down from the Casey household, the fever-stricken family whom Stennis brought you to see four years ago.

"Yes, ${sir}.  I'm tellin' you, ${that_negro}, he's the cause of this plague."
*set knows_pb_diseased 2

"That's impossible, Stennis."

"Why's that?  He can get sick, just like the rest of us."

"No, he can't."

"Why not?"

"Just tell me why you think this is the place."

"'cause I seen 'im comin' and goin' from here."

"You mean, he lives here?"

"I couldn't say."  You look from Stennis to the house and back at Stennis again.  The house is unassuming, more of a shack at the edge of the Pinch.  Could ${wilson} have been holed up here for the past four years, with Apollo, Dido, and you none the wiser?

@{(discretion >= 50) "Follow me," you say, moving to knock on the door.|"Please, lead the way…" you say, motioning for Stennis to knock on the door.}

There is no response.  Another knock.  When still no one answers, the two of you force your way inside; there is no lock.  
*page_break
The room contains the typical items of a family: a bed, a table, a stove and cookware, clothes and bedding.  The room also has five bodies, decomposing rapidly in the August heat.  Stennis gags and rushes outside to vomit. @{(compassion < 40) You idly wonder what the name of the family was.  Glancing around the dark room, you can find no answer to your question.|}

When the sounds of retching have stilled, Stennis returns.  "We should burn it down, ${mr} ${surname}.  This whole part o' town.  Burn it down, clear away the plague, start over."

@{(compassion >= 50) "Tempting, Mr. Stennis, but the chances of the fire spreading to mine own home are too great.|"Don't be absurd, Mr. Stennis…can you imagine all the still-healthy people that would die?} Besides…"

"Besides what?"

"He's not sick.  That's all."  The questions are starting to get uncomfortable.  "We're here now.  Where is ${maddox}?"
*page_break
It's obvious, after a fashion, but not so obvious that it doesn't take a while to find it.  On the back of the door—which you had kept open to let some fresh air in—is a note, from ${wilson} no less. @{literate It's addressed to you and invites you to join him at a warehouse a few miles from here.|Stennis clears his throat before reading it aloud.  The note is addressed to you and invites you to join ${wilson} at a warehouse a few miles from here.} 

@{met_hugh How does he know your name?|} "Perhaps he wishes to turn himself in?" Stennis ventures.

@{(compassion > 50) "After running for this long? I doubt it."|"We can hope."}

*if perception >= 2
	*set shaft_discovered true
	Taking a final walk around the room, a slight difference in the sound of your feet on the wooden floor alerts you to the presence of a hatch, probably leading to some sort of basement.  Looking closer, you realize that the hatch is extremely well-made, almost impossible to notice if you didn't know that it is there.
	*choice
		*selectable_if (discretion < 60) #I order Stennis to investigate.
			*set discretion %-10
			Opening the shaft, you see a ladder extending into darkness.  Stennis hesistates, but at your urging, descends.

			An hour passes.  Then another.  There is no sign of Stennis. @{chasing_wilson Your obligation to pursue ${wilson} weighs heavily on your thoughts.  If you let him slip through your fingers…|}
			*choice
				#I descend into the shaft after him.
					*set discretion %+5
					*set independence %-10
					*set transformation_chamber_found true
					*achieve creationchamber
					At the bottom of the shaft is a tunnel, leading away into the darkness.  You proceed cautiously down it, until you begin to hear…whimpering?
					
					"Stennis?"
					
					"${mr} ${surname}?"  You hear his pained, hopeful voice reach out towards you.
					
					"What happened?"  He's still a ways down the tunnel, but his voice is carried by the stone.
					
					"There's some sort of chamber.  With an altar.  I was comin' back to tell you, but something got my leg."
					
					"What sort of something?"
					
					"I don't know.  A hole in the floor."  You stop.  Feeling around, you realize that the tunnel has narrowed ever so slightly right before you.  Feeling gently along the ground, you discover something…another trap?  Thinking back, you realize there was another narrowing further up the passage.
					
					"I think I've found what you're talking about."
					
					"Are you alright?"
					
					"Yes, yes…I'll be right there."  It is then that Stennis starts to scream.  "Stop that!"
					
					"The ceiling!"
					
					"What?"
					
					"It's lowering!"
					
					"What are you talking about?"
					
					"It's going to crush me!"
					
					"You can't even see…how can you…"
					
					Unfortunately, his screams overwhelm your words.  That is, until they're silenced by a sickening crunch.
					*page_break
					It's then that you realize air is being pushed past you, back towards the shaft.
					
					Turning, you begin hurrying back to the ladder.  Behind you, the gusts of wind get closer and closer.  You break into a run, leaping over the traps where the tunnel narrows.
					
					Throwing yourself into the safety of the shaft, you turn around and watch as a final piece of masonry lowers, closing off the tunnel.  Whatever room Stennis was talking about will not be accessed by this route.
					*page_break
					To make matters worse, you emerge to discover that dawn has come.  Sticking your head out of the plague-ridden house, you realize that you were down there for much longer than you had intended.  Thankfully, your coupé is still waiting for you, Franklin asleep inside.  Waking him, you tell him to hurry home.  You do your best to hide from the sun's rays as the wheels bounce along the newly-laid paving stones.
					*finish Next
				#I have no more time for this.  I must go see ${wilson}.
					*set discretion %-10
					*set independence %+10
					*set stennis_investigates true
					You leave the shaft open for Stennis when he returns.
		*selectable_if (discretion > 30) #I tell Stennis to wait here while I descend.
			*set discretion %+20
			Opening the shaft, you see a ladder extending into the darkness.  

			Shrugging, you motion for Stennis to stay up here, while you descend into the darkness.  Lacking your superior senses, he would just be a hindrance.
			*label explore_shaft_alone
			*set transformation_chamber_found true
			*achieve creationchamber
			At the bottom of the shaft you find a rough-hewn tunnel.  You progress cautiously for about ten minutes, when the walls suddenly become much more polished.  Finally, you come to a doorway, though the doorway lacks a door.  The doorway itself is made of mortared stone, smooth to the touch.
			
			Peering into the room but lacking any sort of illumination, you listen closely.  Putting one foot in front of the other, you begin to trace the dimensions of the room, which must be about forty feet square.  You cannot touch the ceiling, try though you might to reach it.  The walls are graven, as is the floor, 
			*if (perception > 2) and joined_kkk
				and suddenly you realize that you have been here before—or a room very much like it.  The walls are covered with hieroglyphs, like the room in which you were inducted into the Klan.
			*if (perception <= 2) or (joined_kkk = false)
				but lacking even the tiniest shred of light, you cannot make a guess as to their significance.  
			
			Continuing your investigations, you find what must be a table or altar in the middle of the room.
			*if perception >= 4
				*set rationalism %+10
				Planting your hands on it firmly, you reach back into its history, looking for what happened here before.  Immediately, tears of blood begin to stream down your face.  The amount of joy and relief found on this altar is overwhelming.  Someone found redemption here.
			
			At the far side of the room from where you entered is another doorway, though larger.  A tunnel extends deeper into the earth.
			
			Suddenly, you hear a cry from the direction in which you came.  It sounds like Stennis.	 "Stennis?"  You hurry back down the tunnel; you can hear his strained breathing echoing off the walls.  
			
			"${mr} ${surname}?" he says when you approach.
			
			"Yes."
			
			"I can't see anything!"
			
			"Do you think I can?" @{(perception > 1) It's true. There is no light down here for your eyes to magnify. You are blind.|}
			
			"I think my leg's broke.  It's caught in something."
			
			"I told you to keep watch upstairs."
			
			"I know, but you was gone for such a long time, I got worried…"
			
			Feeling around his foot, you find some sort of device in the floor, a trap that has the entire lower leg in its grip.  "I'm going to have to go get a lamp.  I can't free you if I can't see what has you."  Stennis curses loudly at the thought of being left down here in the dark for any length of time.  "I'll be back as soon as I can." @{(compassion < 50) All thoughts of ${wilson} have slipped from your mind.|Maybe tomorrow night; after all, ${wilson} is still waiting for you.  And it's not your fault that Stennis didn't listen to your instructions.} Standing again, you realize that the tunnel is ever so slightly narrower here.  You must have noticed the difference without registering it when you came through here the first time.  
			*label stennis_trapped
			*set stennis_dead true
			You resolve to pay more attention on your way back.  You have no interest in being trapped down here as well.
			*page_break
			It turns out there are two more narrowings between you and the shaft.  Examining closely, you find similar traps to whatever has Stennis pinned.  You were fortunate that you avoided them the first time through.
			
			Ahead of you, you can make out the little bit of light that seeps into the tunnel through the shaft.  Suddenly, a rush of air pushes past you.
			
			"Stennis?"
			
			The ground under your feet rumbles.  Putting thoughts of Stennis aside, you start running for the shaft.  Another gust of air pushes past you.  Looking over your shoulder, you watch as the ceiling lowers itself into the tunnel, completely blocking off access.  From the look of those blocks, Stennis has already been turned into a pulpy mess.  You reach the shaft and watch as the last of the ceiling blocks lowers into place.
			
			Whatever that was—that room—is sealed.
			*page_break
			What's worse is that dawn has come.  Emerging from the plague-ridden house, you realize that you were down there for much longer than you had intended.  Thankfully, your coupé is still waiting for you, Franklin asleep inside.  Waking him, you tell him to hurry home.  You do your best to hide from the sun's rays on the brief return home.
			*finish Next
		#I head down the shaft and bring Stennis with me.
			*set discretion %+10
			*set transformation_chamber_found true
			*achieve creationchamber
			At the bottom of the shaft you find a rough-hewn tunnel.  You progress cautiously for about ten minutes, when the walls suddenly become much more polished.  Finally, you come to a doorway, though the doorway lacks a door.  The doorway itself is made of mortared stone, smooth to the touch.
			
			Peering into the room but lacking any sort of illumination, you listen closely.  Putting one foot in front of the other, you begin to trace the dimensions of the room, which much be about forty feet square.  You cannot reach the ceiling, try though you might to reach it.  
			*if (perception > 2) and joined_kkk
				and suddenly you realize that you have been here before—or a room very much like it.  The walls are covered with hieroglyphs, like the room in which you were inducted into the Klan.
			*else
				but lacking even the tiniest shred of light, you cannot make a guess as to their significance.  
			
			Continuing your investigations, you find what must be a table or altar in the middel of the room.
			*if perception >= 4
				*set rationalism %+10
				Planting your hands on it firmly, you reach back into its history, looking for what happened here before.  Immediately, tears of blood begin to stream down your face.  The amount of joy and relief found on this altar is overwhelming.  Someone found redemption here.
			
			At the far side of the room from where you entered is another doorway, though larger.  A tunnel extends deeper into the earth.
			
			"What is this place?"
			
			"I don't know."
			
			"Can we go?  I don't exactly like all this wandering around in the dark."
			
			"There's another tunnel on the other side of this chamber."
			
			"What about ${wilson}?  Besides, don't you want to see what's down here?"
			
			"You're right.  Let's go back."
			
			You lead Stennis back the way you came.  About a third of the way through the tunnel, you notice that the tunnel narrows ever so slightly for a moment.  A few feet later, you stop to remark upon it to Stennis, but it is too late.  He screams in pain.
			
			"What happened?"
			
			"I don't know.  Somethin's got my leg!"
			
			Feeling around his foot, you find some sort of device in the floor, a trap that has the entire lower leg in its grip.  "I'm going to have to go get a lamp.  I can't free you if I can't see what has you."  Stennis curses loudly at the thought of being left down here in the dark for any length of time.  "I'll be back as soon as I can."
			*if compassion < 50
				All thoughts of ${wilson} have slipped from your mind.
			*else
				Maybe tomorrow night; after all, ${wilson} is still waiting for you.
			*goto stennis_trapped
		*selectable_if (independence > 30) #Who knows how long ${wilson} will wait; I must be away.
			*set discretion %-10
		*selectable_if (compassion > 40) #Who cares what a bunch of dead mortals have in their basement?
			*set compassion %+5

*page_break
You shut the door of the house behind you.
*if (compassion > 30) and (stennis_dead = false)
	Stennis' idea of burning it to the ground crosses your mind again, but you quickly push such thoughts aside.
Someone will come and clean out the bodies.  
*if compassion < 60
	You've heard about Citizens' Committees that have been organized in response to the plague.  They are burning the dead and tending to the ill as best they can.
You have other things to worry about.
*page_break

The address leads you to a building a few miles away, one of many warehouses in the neighborhood.  There are no street-lamps; the only light is from the half-moon above.

You watch the building from across the street.  Even from this distance, you can see that the front door is slightly ajar.  Your quarry waits for you inside.
*label outside_warehouse_1
*fake_choice
	#I wait outside.  He has to emerge eventually.
		*set discretion %-10
		You wait for almost an hour.  There is no sign of ${wilson}.  The sun will be up in another hour or so.
		*fake_choice
			#I continue waiting.
				*set discretion %-10
				You wait until the last possible moment.  Still, there is no sign of ${wilson}.  With the sun's first light nipping at your heels, you rush home and into your resting place.  Before you do, though, you instruct Franklin to investigate the warehouse.  ${wilson} must have gone to ground inside.
				*page_break
				When you awake, it is to disappointing news.  The warehouse had a back exit that was concealed from the outside.  ${wilson} must have left at some point during the night.
				
				The good news is that the place was doused with lamp oil.  It appears he had set a trap for you.  Had you entered, it might have been the last thing you ever did.
				
				Of course, explaining all of this to Carothers will be something of a chore.  Better a chore than a fiery death, though.
				*finish Next
			#I enter.
	#I enter.
	#I circle around the warehouse, looking for another entrance.
		*set discretion %-5
		There is a loading bay, but it is locked down tight. @{(strength > 3) You could probably break it open, but doing so would produce so much noise that any surprise would be negated.|} You circle back around to the main entrance.
		*goto outside_warehouse_1

*set discretion %+5
You enter through the front door.  The inside is dark, with only the occasional slant of moonlight through some window or other lighting the way.  Huge bales of cotton and hay fill the space, reaching almost to the ceiling.
*if perception > 1
	Thankfully, your senses are attuned to the point that the darkness does not hinder you. You can smell ${wilson}; he is near.
	*page_break
*elseif shapeshifting > 0
	You can smell ${wilson}; he is near.
	*page_break

Threading your way through the dry goods, you search for your quarry. @{(stealth > 1) Your movements, though almost completely silent, are not enough to keep your presence a secret.|} He has been waiting for you.
*if maddox_num = 1
	"${massa} ${surname}?  Ah is ovah heah."
*elseif maddox_num = 2
	"@{male Master|Mistress}? Over here."
*else
	"${mr} ${surname}?  Over here."
*page_break
Rounding a rather tall bale of cotton, you catch sight of ${wilson}.  He stands at the end of the aisle, amidst a number of heavy wooden crates stacked higher than you are tall.  The smell of oil assaults your nose; has he laid a trap for you?  He holds a lamp in his hands, suspended over what you assume must be a puddle of oil. @{(perception > 2) Taking a moment to look beyond him and into the emotions that swirl around his form, you estimate that he does not intend—or even hope—to kill you.|}

*if (maddox_num = 3) and (met_hugh = false)
	*set met_hugh true
	*if speaks_english
		"It seems we finally meet," you begin.
		
		"Why're you huntin' on me, ${given_name}?" Hugh replies.
		
		You furrow your brow; how did he learn your name? "To begin, you're breaking the Three Rules."
		
		"I came to this country to get away from those Rules. And now here you are chasing me over them?"
		
		"If you are looking for an existence beyond the life of the Society, it is not here, my friend."
		
		He hefts the lamp. "Maybe I should just end this for both of us."
	*else
		You address Hugh, but he doesn't speak your tongue. It seems his plan to parlay with you has been foiled. He hefts the lamp.
		
	You look from Hugh, to the lamp, to the bales of cotton. Your options are somewhat limited.

*choice
	*selectable_if (discretion > 40) #I charge.
		*set discretion %+10
		*label lunge
		
		*if agility > 3
			You are fast, there is no denying that.  You close the distance between the two of you, your hand closing around his arm.  In the struggle, the lamp drops from his hands.  He pushes you back, while the lamp shatters into a thousand pieces.
			*goto fire_barrier
		*else
			There is far too much distance for you to cover.  ${wilson} drops the lamp, which shatters into a thousand pieces.
			*goto fire_barrier
	#I try to distract him by talking while closing the distance between us.
		*set discretion %-10
		It looks for a moment like your soothing words might let you near enough to seize the lamp.
		*if chasing_wilson
			Unfortunately, he wisens to your tactics before you can get close enough to leap.  The lamp drops to the ground, shattering into a thousand pieces.
			*goto fire_barrier
		*elseif maddox_num < 3
			*bug
		*elseif met_hugh_in_vicksburg and speaks_english
			"It has been a while, Hugh."
			
			"That it has."

			*goto talk_hugh_aggressive
		*elseif speaks_english
			"Tryin' to sweet talk me, eh?"
			
			*label talk_hugh_aggressive
			"There's a lot of people looking for you, Hugh."
			
			"I know it."
		
			You sidle a step closer.  "You know, if you put down that lamp, we can have a peaceable conversation about your future."

			"My future?" he demands, before finding himself wracked with a cough.  

			Seeing your opportunity, you begin to move in on him, but the lamp is already falling from his hands.  He could no longer hold on to it.
			*goto fire_barrier
		*else
			Of course, you don't speak English, and he doesn't speak your tongue. 

			The lamp drops to the ground, shattering into a thousand pieces.
			*goto fire_barrier
	#I stay where I am.  I can speak with him from here.
		*set discretion %-5
		*temp maker "maker"
		*if rationalism < 60
			*set maker "death"
		*if chasing_wilson
			@{maddox_num "Is you afeared o' me?"|"Are you afraid o me?"}
			
			"I smell the oil.  I do not wish to meet my ${maker} this evening."
			
			@{maddox_num "You always wuz a smart one."|"You always were clever. Too clever for me."}
			
			"You know, I've been very worried about you."
			
			*if wilson_embraced
				@{maddox_num "Ah didn' mean ta' embarrass you, in front of de Societee.  I jus' couldn'…"|"I didn mean ta' embarrass you in front of the Soceity. I jus' couldn't…"}
				
				"Couldn't what, ${wilson}?" you say.
				
				@{maddox_num "All dis power…and yet so powerless…"|"All this power…and yet so powerless…"}
				
				"Are you alright, Wilson?"
				
				"No!" he says, coughing. @{(perception > 1) You could be wrong, but you think he just coughed up blood.|}
				
				"${wilson}…" you begin.  The coughing fit wracks his body.  The lamp rolls out of his hands, shattering on the ground.  
				
				He looks at you, fury in his eyes.  @{maddox_num "You see wut you done?"|"You see what you've gone and done?"}  Unfortunately, you're not sure if he's talking about the shattered lamp or his vampiric condition.
				*goto fire_barrier
			*else
				@{maddox_num "So worried you let Quaestah Withers turn me in to a vam-piah?"|"So worried you let Quaestor Withers turn me in to a leech?"}
				
				"She didn't ask me first."
				
				"She didn' ask me, neither."
				*if compassion < 40
					He pauses. @{maddox_num "You done me a good turn ovah dah years, but dat don' mean Ah's fuhgivin yuh."|"You werent the worsen boss, I'll give you that, but that don' mean I'm forgivin you."}
					
					"Forgiving me? For what? What have I done that needs forgiveness?"
					
					@{maddox_num "Fuh draggin me inta dis here world. Dis Societee. Eve'thin you touch done turn tah shit."|"For draggin me into this world. This Society. Errythin you touch turns ta shit."}
				
					You shake your head sadly. The truth of his words does not matter, though.
				"Well, it's time for you to go home, ${wilson}.  Time to leave Memphis," you say, a slight edge to your tone.
				
				"Oh no you don'!" he says, noticing your movement.  Within moments, the lamp has shattered into a thousand pieces on the floor.
				*goto fire_barrier
		*elseif met_hugh_in_vicksburg
			"It has been a while, Hugh."
			
			"That it has."
			
			*goto talk_hugh_cautious
		*else
			*set met_hugh true
			"Are you afraid of me, ${mr} ${surname}?"
			
			"You know my name?"
			
			"You ain't that Carothers fellow, so I guessed."
			
			*label talk_hugh_cautious
			"People are looking for you."
			
			"I figured that."
			
			*if debt_from_gallagher
				"Now, considering the debt you owe me, why don't we go see the Quaestor?  A nice little walk, and I'd consider the debt paid."
				
				Hugh laughs at you.  "That'd be the end of me, I reckon." He's not wrong—between his violations of the Rule of Respect and Reserve, Carothers would be well within his rights to put an end to Hugh.
				
			"You can't run forever," you say.
			
			"I'm doing alright so far."
			
			"Oh?  Seems you've been here for a while.  I think you're tired."
			
			"I am tired," he says with a cough.  Seeing an opportunity, you dart forward.
			*goto lunge
	*selectable_if (discretion < 60) #I flee. Cotton and hay and oil? Sounds like a deathtrap to me.
		*set discretion %-15
		*set independence %-5
		Discretion is the better part of valor, or so they say.
		
		You nearly tear the front door from its hinges as you spill out onto the street.  You cannot put distance between you and that madman fast enough.
		
		It seems that Carothers will still have an unwelcome resident come tomorrow evening.  You do not look forward to explaining why ${wilson} is still free.
		*finish Next

*label fire_barrier
*set cotton_warehouse_fire true
The lamp oil catches fire in the blink of an eye.  Within moments, there is a raging barrier between you and ${wilson}.  Both of you shrink back from the flames.  Though it may be your imagination, it looks to you like they reach for your dead flesh.

*if speaks_english or (maddox_num < 3)
	"Why don't you leave me alone?" ${wilson} cries over the flames.
*else
	He whinges something over the whooshing of the flames.
*choice
	*if wilson_embraced
		#"You are my offspring, and I your dominus.  You are my responsibility…and my burden."
			*set independence %+15
			*set discretion %+5
			@{maddox_num "I serve you fo' a long time.  Why can' you jus' let me go?"|"I served you for fifty years. Why can't you jus let me go?"}
			
			"It doesn't work like that, ${wilson}. @{(independence > 30) You must spend years with me, learning the ways of the Society.|You must spend years with me, learning how to be a vampire.} Only when I see fit to release you are you free to go.  It is for the good of all vampires that we do this."
			
			@{maddox_num "Ah don' care 'bout dem otha vam-piahs.  Ah jus' wan' ta' be left alone."|"I don't care 'bout them othah leeches. I jus' wanna be left alone."}
			
			"It doesn't work like that, ${wilson}.  Come with me now, and maybe we can work something out…"
			
			@{maddox_num "No…Ah don' want nuttin' ta' do wit' de Societee.  Ah don' want ta' be a vam-piah.  Ah hates de way dey looks at me when Ah's about ta' drink dere blood.  Why can't wes jus' go back?  Live and breathe an' sleep an' et…dat's all Ah wants ta do now."|"No…I don't want nothin' to do with the Society. I don't want to even be leech. I hate the way they look when I ask if I can drink their blood. Why can't we just go back? Live and breathe and eat and sleep and die when we're supposed to, because we're old and we've lived a full life and have our grandkids sittin' around our feets? That's all I want to do now."}
			
			"${wilson}…"
			
			@{maddox_num "You bes' be headin' out dat a-way,"|"You best be headin out that way,"} he says, motioning behind you.  @{maddox_num "Wont be long now fo' dis here cotton goes up real quick."|"It won't be long before this cotton catches fire."}
	*if wilson_embraced_by_withers
		*if debt_offered_from_withers = false
			#"Your dominus asked for me to return you to her."
				*set discretion %-5
				*set independence %+5
				@{maddox_num "Mamselle Withuhs?  No way, no how is Ah goin' back ta' her."|"Quaestor Withers? No way am I going back to her."}

				"${wilson}, you must."
				
				@{(maddox_num = 1) "Nuh-uh.  She was worsen Massa Maddox, de way she used dat cane on me.  You bes' be thinkin' up somethin' else ta' say ta' her, cuz dere ain't no way Ah is goin' back."|"No way, no how. I am done serving others."}
					
				@{(independence < 50) "I understand your yearning to be free. I truly do. I feel it myself. But if you want to be free, you must first be Released. If not, you will be hunted to the ends of the earth.|"But you must.  You are a vampire, and you must learn what it means to be a vampire.  That takes decades.}  You cannot just abandon your dominus like this."
				
				"Ah can, an' Ah did."
				
				"And I am here to bring you back."
				
				*if maddox_num = 1
					"You kno', Ah thought Ah done had my freedom when Ah's bought it from old Mista Maddox.  Now Ah sees that you is just anuddah slave-huntah, come ta' put me back in dem chains."
					
					"I am not a slave-hunter…"
					
					"Ah didn' ask to be born no slave, an' Ah didn' ask to be made no vam-piah.  But lookee heah…you is come ta' get me all de same."
		*if debt_offered_from_withers
			#"Your domina offered me a debt, should I manage to bring you to account for your trespasses."
				*set compassion %+5
				*set discretion %-5
				*set independence %+15
				"You know, I thought I'd received my freedom when I bought it from old Mista Maddox.  Now I see that you're just another slave-hunter, come to put me back in chains."
				
				"I am not a slave-hunter…"
				
				"Ah didn' ask to be born no slave, an' Ah didn' ask to be made no vam-piah.  But lookee heah…you is come ta' get me all de same."
		*selectable_if (compassion < 75) #"I'm sorry that this happened to you, ${wilson}.  But we find ourselves here, and you need to stop this madness."
			*set compassion %-10
			He stops and gazes at you across the flames. @{(perception > 1) The glistening trails of his bloodtears reflect the light of the fire back at you.|You're not sure, but you think you see the faint reflection of bloodtears on his face.}
			
			@{maddox_num "Ah ain't givin' up yet.  There's gotta be some way ta' go back.  Ah ain' afeared uh dyin' no mo'.  Ah jus' afeard uh dyin' uh vampiah."|"I ain' givin up yet. There's gotta be some way somehow ta' go back. I ain't afraid of dying annymo', I'm just afraid of dying a vampire."}
			
			"And you think you can find some way to become mortal again?"
			
			@{maddox_num "Ah can hope.  It's all dis ol' body 'as got leff."|"I can hope. It's all this ol' body's got left."}
	*if heard_about_bounty_on_hugh
		#"There's a bounty on your head.  That's all the motivation I need."
			*set compassion %+10
			*set discretion %+10
			*set independence %+5
			Hugh looks at you across the flame, clearly startled by your candor.  "I did not take you for a bounty-hunter, ${mr} ${surname}.  I wish you luck with your quarry."
	*selectable_if (independence > 30) #"You have rejected the Society and the Three Rules.  That is unacceptable."
		*set independence %+15
		*if wilson = "Wilson"
			"Ah hopes dem rules keep you warm durin' de day."
			
			"I'm sorry?"
			
			"Dem rules you is holdin' so tight to your chest.  Ah hopes dey keeps you warm when yous sleepin'.  'Cause dat's all you got to keeps you warm."
		*else
			"I hope those rules keep you warm during the day."
			
			"I'm sorry?"
			
			"Those rules you hold so tight to your chest.  I hope they keep you warm while you sleep; I imagine that's all you have, them three silly rules."
	*if knows_pb_diseased = 3
		*selectable_if (compassion < 60) #"You are diseased, and you are spreading that disease.  The people of Memphis must be protected from the fever you carry."
			*set compassion %-10
			A look of pain crosses his face.
			*if wilson = "Wilson"
				"An' Ah knows it."
				
				"Then come with me.  Maybe we can find a solution to this."
				
				"Mah end is comin', but it ain' tonight, ${massa} ${surname}."
			*else
				"I know."
				
				"Then come with me.  Maybe we can find a solution to this."
				
				"My end may be coming, but it will not be tonight."
		*selectable_if (independence > 30) #"Your very existence is a threat to the Rule of Reserve.  This cannot stand."
			*set independence %+10
			*set discretion %+5
			${wilson} looks at you across the flames, misery clearly etched into his face.  After a few moments, he draws himself up a little straighter, and finally shouts across the flames: 
			*if wilson = "Wilson"
				"Den com an' get me."
			*else
				"Then come and get me."
	#"You are here without permission from Quaestor Carothers.  This is a violation of the Rule of Respect.  He demands your presence…"
		*set independence %+20
		${wilson} laughs.
		*if wilson = "Wilson"
			"Of all de t'ings," he says from across the flames.  Standing a little straighter, he addresses you calmly.  "Den com an' get me."
		*else
			"Of all the things…" he says, a rueful grin on his face.  Standing a little straighter, he addresses you calmly.  "Well, come and get me."

With that, he turns and exits the warehouse; apparently, he had an exit prepared, one you had not noticed earlier.  You watch him go, the flames between you still roaring.
*page_break
You exit the warehouse@{(compassion <= 50) , shouting for the fire brigade.  Once the fire seems under control, you disappear into the night.| to find the fire brigade already setting up their bucket-chain.  Not wanting to face any questions, you quickly disappear into the night.} One more misery for a city already teetering on the brink.

Returning to your haven, you review the evening, wondering how you might have done it differently, how you might have seized ${maddox} in your unholy grip.  Next time, you will be ready.
*if shaft_discovered and stennis_investigates
	*set stennis_dead true
	*page_break
	The next night, there is still no word from Stennis.  Returning to the plague-ridden house, you find the shaft much as you left it.  Opening it is not simple, but soon enough the cover yields to your efforts.
	
	Descending into the darkness, you find no sign of Stennis.  A tunnel extends for several feet away from the shaft but ends in a sold stone wall.
	
	You do not hear from Stennis again.
*elseif shaft_discovered and (transformation_chamber_found = false)
	*page_break
	The next night, you return to the plague-ridden house to investigate the shaft.  Arriving, you find it much as you left it.

	Descending into the darkness, you find a tunnel that extends for several feet to the south, ending in a solid stone wall.

	You marvel at the quality of the masonry for a moment, but can find no other clues as to the origin of the construct.

	Baffled, you return to your haven.
*finish Next