*comment ñáéç…—
*hide_reuse
*advertisement
*set train_status false
*temp plague_round_two false
*temp interlocutors 0
*set player_obstinate false
*temp son_of_ham false
*temp num_senators "ten"
*temp here_for_election false
*temp sire_question_unasked true
*temp bailey_introduces_malloy false
*temp draper_convo false
*temp rebuff_query false
*temp ashmore_questions 0
*temp pike_question true
*temp why_revolt true
*comment question about why people would support Stone's revolution; currently only used in Ashmore.
*temp senator_question_unasked true
*if (calkins_status = 2) or (calkins_status = 3)
	*if calkins_rapport > 55
		*set bowater_rapport %+20
	*if calkins_rapport < 45
		*set bowater_rapport %-20
*temp a_freedman "a freedman"
*temp a_one_eared_freedman "a one-eared freedman"
*if maddox_num = 2
	*set a_freedman "a German-Cajun"
	*set a_one_eared_freedman "a one-eyed German-Cajun"
*if maddox_num = 3
	*set a_freedman "a Irishman"
	*set a_one_eared_freedman "a gap-toothed Irishman"
*temp suh "suh"
*if male = false
	*set suh "Mam'selle"
*temp carothers_strips_status false
*temp overheard_treatment_vessels false
*temp questions 0
*temp seat_num 3
*if player_for_senator
	*set seat_num +1
*if malloy_out
	*set seat_num -1
*if pickering_out
	*set seat_num -1
*temp question_bowater true
*temp ashmore_comment false
*temp earned_status false
*temp already_recognized false
*temp gould_q false
*temp fragala_name 3
*if intelligence > 2
	*set fragala_name 2
*if heard_of_fragala
	*set fragala_name 1

Carothers returns to Memphis barely two weeks before the reception.
*if (acquiring_vessels_1877 = "attempting")
	When he returns, he writes you a note, reminding you of your promise to provide refreshments for the reception.  
	*if acquiring_vessels = "success"
		He notes that you may store them in the same place as last time.
	*if acquiring_vessels = "failed"	
		He notes that he has a new place for you to gather the vessels and includes directions.
	*if acquiring_vessels = "na"
		He also includes an address where you may store the vessels until they are needed.

*if heard_about_great_railroad_strike
	Though the Great Railroad Strike has been quelled—Federal troops and deputized police have killed enough of the striking workers that the rest fell into line—you wonder if it will have any lingering effect on the Senators' arrivals. They are due to arrive in a few days.
*else
	*set heard_about_great_railroad_strike true
	It turns out that his return was delayed due to a massive series of strikes that have erupted across the country, mostly based in cities served by the Baltimore & Ohio Railroad.  The strikers paralyzed the nation for two weeks, with people and goods no longer able to cross the Appalachians through the Cumberland Narrows.
	
	The matter was put to an end when federal troops and deputized police began killing the strikers.  The strike is now over, but the railroad system is still putting itself back together—and the various senators are due to start arriving in a few days.
	
*if memphis_affair
	*if wealth > 1000
		*set wealth -1000
	*else
		*set wealth 0
	*set plague_round_two true
	To add to your worries, Clotho has taken ill—it is possible that she has come down with the yellow fever.  You have summoned the best doctor in Memphis to attend her.
	*if independence > 40
		You have found it hard to leave her bedside, and several important things have gone undone.  However, your sense of obligation overrides your worry, and you make sure that everything is as it needs to be.
	*else
		You have not left her bedside.
		*if acquiring_vessels_1877 = "attempting"
			*set acquiring_vessels_1877 "abandoned"
			In fact, you have not even begun gathering refreshments for the guests.  You suppose that they shall have to fend for themselves; you cannot abandon your love in her hour of need.
		*if (memphis_reception_planner = given_name) or (memphis_reception_planner = "Clotho")
			*set memphis_reception_planner "abandoned"
			*if party_preparations > 1
				*set party_preparations 1
			In fact, most of your effort to organize the reception is falling apart without your constant attention.  Carothers will surely be angry with you, but you cannot bear to part with her.
		*page_break
		"You are a fool, ${given_name}," croaks Clotho.
		
		The sun has set, and the reception for the Senators is beginning.  You, however, are at Clotho's beside, pressing a moist cloth against her forehead.
		
		"You are a fool.  How will you ever gain permission to give me eternal life if you have ostracized yourself from their highest ceremonies?"  You try to quiet her, but she will not relent.  "My dearest, you must go.  Everything that you have told me about this night makes me certain that you tread too closely to the edge by spurning these functions."
		
		After much negotiation, you finally agree to leave her side.  However…
		*choice
			#Just because you have promised to attend one of these functions doesn't mean that you will attend both.  You will stay by her side tonight, and attend the caucus tomorrow.
				*set discretion %+15
				*set compassion %-15
				*set independence %-10
				She laughs—coughs, really—at the creative interpretation of your promise.  She relents, however, and allows you to stay beside her through the night.
		
				Unfortunately, as the dawn approaches, there is a knock at the door.  A few moments later, Franklin appears with a note from Carothers.  The note chastises you for your failure to appear at the reception this evening.
				*if acquiring_vessels_1877 = "abandoned"
					Further, he excoriates you for not only failing to provide "refreshments", but further for not bothering to warn him that you had failed.
				He expresses hope that you too have heard the rumors of a ${a_one_eared_freedman} prowling about the city.
		
				"${wilson} is about?" you say aloud.
		
				"It would seem so, ${suh}," supplies Franklin.
		
				You promised her that you would attend the caucus.  But ${wilson} may be within your reach!  The dawn is approaching.  What will you do when the sun sets?  You must tell Franklin now, so that he may spend the day preparing.
				*choice
					#I inform Franklin that I will attend the election.
						*set independence %+10
						"Dat sounds smaht, ${massa} ${surname}."
		
						You lay down to sleep, worry about both Clotho and the impending caucus furrowing your brow.
						*page_break Next
						*goto_scene memphis_1877_caucus
					#I inform Franklin that I will pursue ${wilson}.
						*set independence %-10
						"Dat sounds smaht, ${massa} ${surname}."
		
						You lay down to sleep, worry about both Clotho and the errant ${wilson} furrowing your brow.
						*page_break Next
						*goto_scene memphis_1877_plague
			#I leave her side.  She is right, I must tend to these obligations.
				*set independence %+10
				*set discretion %-10
				With a final kiss, you leave her in Franklin's capable hands.  You have visitors to greet.
				*goto first_arrival
*elseif shepherd_credentials > 58
	*set plague_round_two true
	Also in July, rumors begin to circulate that yellow fever has flared up again in Memphis. This puts the citizenry on edge.

*if acquiring_vessels_1877 = "attempting"

	When it is almost too late, you start the process of gathering the humans for the reception.
	*if acquiring_vessels = "success"
		*set anachronism %-10
		Nothing if not a creature of habit, you are delighted to discover that the tactic that worked for you last time works again.  Soon, Carothers' pens are full of people, crying and huddling, unsure as to what awaits them.

		He will be pleased.
		*goto hunting_preparations_resolution_1
	*elseif acquiring_vessels = "na"
		Casting about, you struggle to devise how you are to set about this task.  Eventually, however, you decide to go with what you know best.
		*if priest
			*set acquiring_vessels_1877 "success"
			One by one, you offer consolation to those in need of such.  Trusting in your uniform, your victims seem willing to follow you to the ends of the earth.  Instead, you take them to something approximating hell.
		*elseif (charm > 3) or ((charm = 3) and (male = false))
			*set acquiring_vessels_1877 "success"
			One by one, you begin leading men (and the occasional woman) to the holding pen.  Taken in by your charms, they willingly follow you, realizing only too late that your offer was too good to be true.
		*elseif (stealth > 2) and (combat > 5)
			*set acquiring_vessels_1877 "success"
			*set stlouis_valet_loyalty %-15
			One by one, you follow lone individuals into places from which they will not return.  With the assistance of Franklin, you port their comatose bodies to Carothers's pen.
		*elseif (stealth > 1) and (combat > 6)
			*set acquiring_vessels_1877 "success"
			*set stlouis_valet_loyalty %-15
			You wait in alleys, invisible to the minds of your prey, waiting for the right moment to strike.  One by one, you subdue your victims.  With the assistance of Franklin, you port their comatose bodies to Carothers's pen.
		*elseif (stealth > 0) and (combat > 7)
			*set acquiring_vessels_1877 "success"
			*set stlouis_valet_loyalty %-15
			You wait in alleys, hoping that no one notices you while you wait for the right moment to strike.  One by one, you subdue your victims.  With the assistance of Franklin, you port their comatose bodies to Carothers's pen.
		*elseif combat > 8
			*set acquiring_vessels_1877 "success"
			*set stlouis_valet_loyalty %-15
			One by one, you follow lone individuals through the streets, waiting for the right moment to strike.  With the assistance of Franklin, you port their comatose bodies to Carothers's pen.
		*elseif (streetwise > 1) and (charm > 2)
			*set acquiring_vessels_1877 "success"
			Thankfully, the time you have spent in the company of the pickpockets, thugs, and burglars of the city means that you already know who would be most susceptible to small enticements.  It is easy enough to tempt these poor souls away from the company of others, at which point they are easily subdued.
		*else
			*set acquiring_vessels_1877 "failure"
			*set carothers_rapport %-30
			Unfortunately, your skills at hunting are still not to the point at which you can corral such a large number of individuals in such a short amount of time.  You are not charming enough to easily entice them in sufficient numbers, or martial enough to subdue them in an efficient manner.
		
			After several nights of effort, you are forced to inform the furious Carothers of your inability to complete the task for which you volunteered.
			
			*label confess_failure
			*set carothers_humanity +3
			*if debt_check
				*if debt_to_carothers
					"I'm sure you have surmised that your debt is by no means cleared."
		
					"I have."
		
					*label finish_this
					"Do you have any idea to what lengths I will have to go in order to accomplish this task in the days that remain?"
		
					"I do, Quaestor."
		
					"Leave my presence.  Now!"  Grateful that your audience is over, you flee from his incendiary fury.
					*goto first_arrival
				*else
					"And you were so arrogant as to demand a debt from me for your services!  Do you have any idea to what lengths I will have to go in order to accomplish this task in the days that remain?"
		
					"I do, Quaestor."
		
					"Leave my presence.  Now!"  Grateful that your audience is over, you flee from his incendiary fury.
					*goto party_preparations
			*else
				*goto finish_this
		*label hunting_preparations_resolution
		*if plague_round_two
			The work is complicated by the whispers of the return of the fever. As with four years ago, your customary methods of hunting have become suddenly constrained by the rising fears of contagion.
		*else
			*set plague_round_two true
			The work is complicated by the fact that the yellow fever may have returned. The city is once again on edge and your customary methods of hunting are constrained by the rising fears of contagion.
		
		The next night is much the same, and the night after that as well.  Regardless, the pen eventually fills with the stink of people piled one on top of the other.  Carothers will be pleased.
		*label hunting_preparations_resolution_1
		*if compassion < 35
			You, on the other hand, find your handiwork distressing.  The cries of the captives haunt your dreams.
			*if ((compassion < 25) and (willpower <= 2)) or ((willpower = 1) and (compassion < 35))
				*set acquiring_vessels_1877 "failure"
				*set carothers_humanity +3
				*set second_memphis_reception_attended 1
				*set compassion %-30
				*if status > 0
					*set status -1
				After another sleepless day, you realize that you cannot be a party to this travesty.
				
				Returning to the pens, you free the captives, urging them to flee before you are discovered.
				
				It is not long before Carothers appears in a cloud of fury.  Moving faster than you can comprehend, he seizes several of the fleeing captives by the scruff of their necks and returns them to the pen.
				
				"What in Satan's fiery asshole are you doing, ${given_name}?"
				
				"I couldn't…I just…what I was doing to those people…"
				
				"You are an embarrassment to our kind.  Go, now.  Your assistance is no longer required.  And do not bother attending the reception; no one there will tolerate your presence after they hear of this."
				
				You slink back home, grateful that some of the prisoners may live to see another day.
				*page_break
				*goto_scene memphis_1877_plague
		*elseif compassion < 65
			You, on the other hand, find your handiwork unpleasant.  You find it difficult to set aside the cries of the captives once you have sealed them away.
		*else
			You take special delight in tormenting the captives, spitting on them, taunting them with the misery that is to come.  The memory of their cries and wails rocks you to sleep in the morning.
		*if debt_check
			*if debt_to_carothers
				*set debt_to_carothers false
			*else
				*set debt_from_carothers true
			*goto party_preparations
		*elseif status = 0
			*set train_status true
			*goto party_preparations
		*else
			*goto first_arrival
	*elseif acquiring_vessels = "failed"
		*if wealth > 100000
			*set wealth -10000
			*set acquiring_vessels_1877 "success"
			Considering your failure the last time you attempted this, you resort to outright bribery this time.  By spreading your money in the right places, you are able to convince enough people, one by one, to follow you to the holding pen.  Like the pied piper, you escort them to their doom.
			*goto hunting_preparations_resolution
		*else
			You had thought that perhaps you could buy your way to success this time, but even in that you have failed to accurately judge your finances.  Unable to gather the necessary vessels through your strength or your wiles, and further unable to drawn them to you with money, you are forced to inform the furious Carothers of your inability to complete the task before you.
			*goto confess_failure
	*else
	
		Acquiring Vessels status: ${acquiring_vessels}
		*page_break
		*bug
*if memphis_reception_planner = given_name
	*if memphis_affair
		Of course, the reception that you are planning is foremost among these concerns.  You console yourself that, considering the illness of your love, the reception will go as well as is possible.
	*else
		These last two weeks are a whirlwind as you finalize the preparations for the reception.  Everything is as ready as it will ever be, or so you whisper to yourself when no one is listening.
*elseif memphis_reception_planner != "Dido"
	${memphis_reception_planner} needs little input from you, but all the same, as the nights tick by, you find yourself running errands and performing other little last-minute tasks for her.  You hope that she lives up to your expectations.
		
*label party_preparations
*if memphis_reception_planner = "abandoned"
	*set carothers_rapport %-30
	*set applethorp_rapport %-15
	*set bailey_rapport %-10
	*set partridge_rapport %-10
	*set santagostino_rapport %-10
	*if ashmore_revolutionary
		*set ashmore_rapport %-10
	*if davison_waylaid = false
		*set davison_rapport %-10
	*set revolutionary_credentials %-10
	*if status > 2
		*set status -1
	Arriving at the venue, your eye easily picks out the errors in the decorations. The musicians are playing the songs without any sort of order. And the attendants' outfits are not appropriately coordinated.
	
	This is going to be a long night of sideways looks and silent recriminations. Except for Carothers. He will tell you exactly what he thinks.
	
	Meeting you on the front steps, he hisses at you: "What is this travesty?"
	
	"I'm sorry…"
	*if party_preparations_1873 = "failure"
	
		"I suppose this was mine own failing; I should not have given you a chance to redeem yourself.  What, truly, could I expect?"
		
		"But I…"

	"I do not want your apologies!  I want to know why you seek to ruin me!"
	
	"I do not seek to ruin you.  My love is sick…"
	
	"You embarrass me in front of the Senate, because your food is ill?"
	
	"She is not…"
	
	"Silence.  I do not want to see you this evening.  
	*if chasing_wilson
		Isn't there a vampire you're supposed to be looking for?  Go, I do not want you here."
	*else
		I would suggest doing something worthwhile in the next few nights, before I reconsider your residency here.  Now go, I do not want you here."
	
	"Yes, Quaestor."  Turning, you try to catch up with your [i]coupé[/i] before it disappears around the corner.
	*goto booted_epilogue
*elseif memphis_reception_planner != "Dido"
	Arriving at the venue, you are proud to see the scene is set as you envisioned it.
	*if memphis_reception_planner = "Harriet"
		The community hall of a Methodist Church stands somberly before you.  A handful of temperance workers stand by, opening carriages for the guests and escorting them to the door.  They seem thrilled that there is no evidence of drunkenness among the attendees.  
	*if memphis_reception_planner = "Sally"
		The church-hall stands lit before you.  Apparently, someone has funded the addition of gas lamps to the building; their brass and chrome further reflects the light, as of yet unmarred by soot.  The lights are rather out of place, however, in that it is the only building so lit for blocks around.  
	*if memphis_reception_planner = "Olivia"
		The Gayoso Hotel is gayly lit by gas lamps and chandeliers.  Olivia certainly did a fine job with the preparations.
	*if memphis_reception_planner = given_name
		@{(party_preparations >= 2) The Gayoso Hotel is gayly lit by gas lamps and chandeliers.  You are confident that you made a wise choice in venue.|The house that you rented for the event is lit brightly by gas lamps.}
	*if memphis_reception_planner = "Clotho"
		*set carothers_rapport %+20
		*set applethorp_rapport %+10
		You wish that Clotho were here to see what she has wrought.
		
		"I am astounded, ${mr} ${surname}."  With that, Carothers greets you, a broad smile on his face.
		*if party_preparations_1873 = "success"
		
			"I would have thought my last efforts would ease any fears…"
			
			"But you have outdone yourself… truly outdone yourself," Carothers continues to marvel at the twinkling lights and the music that drifts lazily on the summer breeze.
		*comment endif
		
		"You are too kind, Quaestor.
		*if discretion < 40
			I must admit, however, that I am not fully responsible for this.  My love, a woman who goes by the name of Clotho, is responsible for the lion's share."
			
			"A mortal woman?"  He inquires, frowning.
			
			"Yes…" you say, worried about what is to come next.
			
			Carothers considers a moment, but after glancing at the scene again, seems to think the better of whatever he was going to say.  "We can discuss this after the election.  Come now, I think tonight will be a good night."  With a gesture, he invites you to pass through the doors before him.  Graciously, you accept.
			*goto first_arrival
		*else
			Doing it was a pleasure."
			
			"I think it will be a good night…" he beams.  With a gesture, he invites you to pass through the doors before him.  Graciously, you accept.
			*goto first_arrival
	*elseif party_preparations >= 3
		*set carothers_rapport %+20
		*set applethorp_rapport %+10
		*if (status <= 2) and (party_preparations > 3)
			*set earned_status true
		*elseif status = 0
			*set train_status true
		"I am astounded, ${mr} ${surname}."  With that, Carothers greets you, a broad smile on his face.
		*if party_preparations_1873 = "success"
		
			"I would have thought my last efforts would ease any fears…"
			
			"But you have outdone yourself…truly outdone yourself," Carothers continues to marvel at the twinkling lights and the music that drifts lazily on the summer breeze.
		
		"You are too kind, Quaestor."
		
		"I think it will be a good night…" he beams.  With a gesture, he invites you to pass through the doors before him.  Graciously, you accept.
		*goto first_arrival
	*elseif party_preparations = 2
		*set carothers_rapport %+5
		*set applethorp_rapport %+5
		"Well done, ${mr} ${surname}," Carothers says, upon seeing your arrival.
		
		*if discretion >= 50
			"I hope you did not expect anything less."
			
			"No, of course not.
		*else
			"You do me too much honor, sir."
			
			"You deserve it, ${mr} ${surname}.
		Come now, the guests will be arriving shortly."
		
		"Yes, I must make sure there is no last-minute things that need my attention."
		*goto first_arrival
	*elseif party_preparations = 1
		*set carothers_rapport %-15
		*set applethorp_rapport %-10
		
		Unfortunately, Carothers does not seem to be as impressed.
		*if (party_preparations_1873 = "failure") or (party_preparations_1873 = "fair")
			"I suppose this was mine own failing; I should not have given you a chance to redeem yourself.  What, truly, could I expect?"
			
			"But I…"
			
		*comment endif
		"I am disappointed.  The Senate has gathered in my city, and you offer this as a sign of my hospitality.  I am ashamed to show my face."
		
		"Yes, Quaestor."
		
		"Stay out of my way this evening, ${mr} ${surname}," he says, storming off.		
		*goto first_arrival
	*else
		*set carothers_rapport %-30
		*set applethorp_rapport %-15
		*set bailey_rapport %-10
		*set partridge_rapport %-10
		*set santagostino_rapport %-10
		*if ashmore_revolutionary
			*set ashmore_rapport %-10
		*if davison_waylaid = false
			*set davison_rapport %-10
		*if status > 2
			*set status -1
		
		Unfortunately, Carothers does not seem to be nearly as impressed.  "What is this travesty?"
		
		"I'm sorry, Quaestor?"
		
		"Are you trying to ruin me?  The Senate has gathered in my city, and this is the reception you organize for them?"
		
		"I…I…"
		*if party_preparations_1873 = "failure"
		
			"I suppose this was mine own failing; I should not have given you a chance to redeem yourself.  What, truly, could I expect?"
			
			"But I…"
		*comment endif
		
		*if status <= 2
			"I do not want to hear any excuses.  Go now, you are not welcome here."
			*goto booted_epilogue
		*else
			*set carothers_strips_status true
			"Leave my sight.  Now."

			Backing away slowly, you retreat from Carothers in as orderly of a fashion as you can manage.
			*goto first_arrival
*else
	*if (acquiring_vessels_1877 != "attempting") and (memphis_reception_planner = "Dido")
		Luckily for you, you have avoided any obligations and can relax while waiting for them to arrive.
		*page_break
	The night of the reception has arrived.
	*temp pb_choice false
	*if plague_round_two and (knows_pb_diseased = 2)
		*set pb_choice true

		If Stennis is right, though, and ${wilson} has the yellow fever—then perhaps he has returned? Could the rumors of the fever be a harbinger of his arrival?
	*choice
		*if ((avoiding_second_reception = false) and (debt_to_lesczynski = false)) #I will attend.
			*set independence %+10
			Surveying the Gayoso Hotel, you decide that Dido has done an adequate job with the preparations.  It is gayly lit by gas lamps and chandeliers.
			*if (memphis_reception_planner_1873 = "Dido") and (first_memphis_reception_attended = 1)
				You would have thought, though, that she might have improved on things, at least a little, in four years.
			*if memphis_reception_planner_1873 = given_name
				*if discretion >= 40
					You do your best not to sneer at them, though.  Your efforts last time around far outclass these.
				*else
					Though you hesitate to make the comparison, you think your efforts from a few years ago put this to shame.
			*if (memphis_reception_planner_1873 != "Dido") and (memphis_reception_planner_1873 != given_name)
				It is unfortunate that Carothers didn't try harder to recruit you again for the task; ${memphis_reception_planner_1873} would have done a better job.  She certainly did last time around.
			*goto first_arrival
		#I will avoid that place as though they were the ones with the plague.
			*set second_memphis_reception_attended 2
			*set independence %-20
			Besides, there are more pressing things to pursue.  ${maddox} is still on the loose.
			
			*goto_scene memphis_1877_plague
		*if (pb_choice) #I have more important things to tend to: ${wilson} ${maddox}.
			*set independence %-10
			*set compassion %-5
			*set second_memphis_reception_attended 3
			*goto_scene memphis_1877_plague

*label first_arrival
*page_break
*gosub allegiance_count
*if heard_of_bailey and heard_of_partridge
	Senators Bailey and Partridge are the first to arrive.
	*if met_bailey
		*if (bailey_rapport > 50) or (revolutionary_credentials > 50)
			They greet you warmly.  Bailey expresses his concern over the resurgence of the yellow fever in the city.  You thank him for his concern, and assure him that he has nothing to worry about during their visit.
			*goto more_arrivals
		*elseif (status > 2)
			They greet you with false smiles, forced to be polite because of your standing in the Society.  They ask after your condition, in light of the resurgent yellow fever.  You assure them that you are fine, and that they have nothing to fear during their visit.
			*goto more_arrivals
		*else
			They greet you perfunctorily.  You stand awkwardly in their proximity, anxiously awaiting the arrival of more guests.  
			*if speaks_english
				In the meantime, they discuss the potential threat of the yellow fever to the city, not really including you in the conversation.
			*else
				They continue to chatter in English, not really trying to include you in the conversation.
			*goto more_arrivals
	*else
		*label do_they_introduce
		*if ((status >= 2) or bailey_correspondence) and (speaks_english)
			*label partridge_bailey_introduce_themselves
			*set heard_of_bailey true
			*set heard_of_partridge true
			*set met_bailey true
			*set met_partridge true
			The two introduce themselves as Senators John Bailey, of St. Louis, and Samson Partridge, of Louisville. @{bailey_correspondence Bailey is excited to put a face with the name. |}They invite you to speak to them later in the evening, once the festivities have gotten fully underway.
			*goto more_arrivals
		*else
			They are very deep in their discussion and do not seem to take note of you.
			*goto more_arrivals
*if heard_of_bailey
	Senator Bailey and a dark-haired and bearded companion are the first to arrive.
	*if met_bailey
		They are very deep in their discussion, and do not seem to take note of you.
		*goto more_arrivals
	*else
		*goto do_they_introduce
*if (heard_of_bailey = false) and ((lore > 3))
	*label recognize_bailey_arrival
	*set heard_of_bailey true
	Two white men are the first to arrive.  One you recognize as John Bailey, Senator of St. Louis; he has blond hair and is clean-shaven.  The other you do not recognize, but he his brown-haired and youthful, and he sports a beard.
	*goto do_they_introduce
*if (heard_of_bailey = false) and ((lore = 3) and (revolutionary_credentials > 70))
	*goto recognize_bailey_arrival
*if heard_of_partridge
	Two white men are the first to arrive.  One you recognize as Samson Partridge, Senator of Louisville; he has brown hair, a beard, and has a youthful look about him.  The other you do not recognize, but he has blond hair and is clean-shaven.
	*goto do_they_introduce
*else
	*if (first_memphis_reception_attended = 1) or first_memphis_caucus_attended
		The fair-haired, clean-shaven vampire and his dark-haired and bearded companion are the first guests to arrive.  You recognize them from the gathering four years ago.
		*goto do_they_introduce
	*else
		A fair-haired, clean-shaven vampire and his dark-haired and bearded companion are the first guests to arrive.  
		*goto do_they_introduce

*label more_arrivals

Soon, the other guests begin to arrive, and you are no longer alone with Bailey and Partridge.
*if first_memphis_reception_attended = 1
	@{heard_of_lockridge Lockridge|The gentleman from the Carolinas}, @{heard_of_coffin Coffin|the woman in Puritan dress}, the candidates…and others whom you do not recognize.
*else
	@{heard_of_lockridge Lockridge|The gentleman from the Carolinas}, @{heard_of_coffin Coffin|the woman in Puritan dress}…and many others whom you do not recognize.
*if debt_to_lesczynski
	The new arrivals—the ones with whom you are acquainted, anyway—are notably cool to you; they are likely wary of your outburst four years ago. You will have to be on your best behavior if you are to make any inroads this evening.
*if (santagostino_rapport > 40) and (jesse_rapport > 40)
	You do not spot Chiara or Jesse, however.
*elseif santagostino_rapport > 40
	You do not spot Chiara, however.
*elseif jesse_rapport > 40
	You do not spot Jesse, however.
*elseif jesse_is_broodmate
	You do not spot your broodmate, however.

*temp knows_leper false
*if intelligence > 2
	*set knows_leper true

One of these newcomers is quite monstrous. His face is an inflamed patchwork of wrinkles, growths, and scaled skin. @{(intelligence > 2) One look at him and you conclude that he suffers from leprosy.|} @{((intelligence < 2) and ((rationalism > 70) and (religious_tradition != "pagan"))) You wonder what sin this man committed to be cursed by God so.|} Looking beyond the scales, however, you see that the man is heavyset and has bronze skin and black @{((met_estefania) and (ethnicity != "spanish")) hair—he could be related to Estefania Rios.|hair.} @{(ethnicity = "spanish") If you squint, you muse that he could be related to you. To your mortal self, anyway.|}

Most of the arriving vampires cycle through the adjoining rooms where the @{(compassion < 50) [i]vessels[/i]|mortals} are kept. Occassionally, a scream can be heard@{(compassion < 35)  and it sends a shiver of horror down your back|}.
*if acquiring_vessels_1877 = "success"
	*set applethorp_rapport %+10
	*set ashmore_rapport %+10
	*set bailey_rapport %+10
	*set bowater_rapport %+10
	*set coffin_rapport %+10
	*if davison_waylaid = false
		*set davison_rapport %+10
	*set harding_rapport %+10
	*set lesczynski_rapport %+10
	*set lockridge_rapport %+10
	*if malloy_out = false
		*set malloy_rapport %+10
	*set partridge_rapport %+10
	*if pickering_out = false
		*set pickering_rapport %+10
	*set santagostino_rapport %+10
	*if simmons_waylaid = false
		*set simmons_rapport %+10
	*set timmers_rapport %+10

	Word of your contribution to the evening spreads quickly through the gathered attendees.  Their gratitude is plain.
*elseif (acquiring_vessels_1877 = "abandoned") or (acquiring_vessels_1877 = "failure")
	*set applethorp_rapport %-10
	*set ashmore_rapport %-10
	*set bailey_rapport %-10
	*set bowater_rapport %+10
	*set coffin_rapport %-10
	*if davison_waylaid = false
		*set davison_rapport %-10
	*set harding_rapport %-10
	*set lesczynski_rapport %-10
	*set lockridge_rapport %-10
	*if malloy_out = false
		*set malloy_rapport %-10
	*set partridge_rapport %-10
	*if pickering_out = false
		*set pickering_rapport %-10
	*set santagostino_rapport %-10
	*if simmons_waylaid = false
		*set simmons_rapport %-10
	*set timmers_rapport %-10

	You soon begin to feel as though the eyes of the room are on you.  Before long you realize that word has quickly spread about your failure to procure refreshments for the gathering.  It is clear that everyone is disappointed and on edge. @{memphis_affair You corner Dido, and try to explain to her that you were tending to your love, but she does not want to hear it.  You will have to bear this shame alone.|}
	
	Glimpsing Carothers out of the corner of your eye, you prepare yourself for what is about to transpire.  "${mr} ${surname}!"
		
	"Yes, Quaestor?"

	*if (acquiring_vessels = "failed") and (status <= 2)	
		"Leave."
		
		"I'm sorry?"
		
		"You have embarrassed me a second time; I would have thought you had the good sense not to show your face here.  Leave now, before I tear your head from your shoulders."
		
		"Yes…yes, Quaestor…"  To the sound of vicious laughter, you scurry from the room.  Your presence is not wanted there.
		*goto booted_epilogue
	*else
		*set carothers_strips_status true
		He grits his teeth.  "You have failed me.  If you were wise, you would stay out of my way this evening."

		You nod vigorously.  Realizing that you have been dismissed, you slip away as quickly as you can.
*elseif carothers_humanity >= 5
	*temp senator_bowater "Senator Bowater"
	*if bowater_correspondence = false
		*set senator_bowater "a man in Quaker dress"
	*set overheard_treatment_vessels true

	It is not long before you hear some grumbling from ${senator_bowater}.  It seems he finds the condition of the refreshments deplorable.
	
	You have not had time to look in on them; perhaps you will make time later.  For now, however, a hush falls over the room as the main door opens.

*page_break
*set second_memphis_reception_attended 4
Senator Santagostino enters the room.
*if flirting_with_chiara
	You do your best to suppress the smile that comes unbidden to your face.
The gathered vampires circle her, preparing to welcome or ignore her, as suits their taste.  Within a few moments, she lets it be known that Jesse Whitaker will not be in attendance, neither tonight nor for the election.
*if avoided_new_orleans = false
	*if jesses_revolutionary_credentials >= 60
		Senator Bailey does not look pleased at this news.
	*if jesses_revolutionary_credentials <= 40
		Senator Lockridge does not look pleased at this news.
	*if jesse_waylaid and (jesse_rapport <= 40)
		You do your best to look surprised; it seems that suspicion has rightly fallen on you for this inconvenience.
	*elseif jesse_waylaid
		You do your best not to smile.  No one seems to suspect your hand in this; no reason to disabuse them.
	*else
		You furrow your brow in concern; what could possibly keep Jesse away from such a hotbed of intrigue?
*if flirting_with_chiara
	*page_break
	Once the rest of the guests have welcomed or snubbed Chiara, she finally makes her way to you.  The air between is laden with desire.  "It is good to see you, Chiara."

	"It has been too long, ${given_name}.  How have you been?"
	*choice
		*if memphis_affair
			*if jesse_waylaid = false
				#I avoid the subject of Clotho by inquiring after the whereabouts of Jesse.
					*set discretion %-10
					*label wheres_jesse
					*set santagostino_rapport %-10
					Chiara seems a little disappointed that, after being apart for so long, the first thing you inquire after is Jesse.  A slight pout mars her features.
					
					"Maybe he didn't want to see you, ${given_name}."

					"That's ridiculous.  He and I…"

					"Well, I surely don't know anything about his absence."  With that, she turns and leaves your presence.  You stare after her, unsure as to whether or not you were supposed to follow.
			#I avoid the subject of Clotho by asking after Estefania Rios e Hidalgo.
				*gosub news_of_estefania
			#I avoid the subject of Clotho by continuing to flirt with Chiara.
				*if charm >= 3
					*set flirting_with_chiara true
					*set santagostino_rapport %+20
					And flirt you do.  Soon, her laughter ripples through the room.
					*if perception > 2
						You notice several of the other guests shooting glares in your general direction.  Clearly, this is not the correct environment for such mirth.
					"It has been too long, dear ${given_name}, but I'm afraid I can't spend the whole evening at your side."

					"That is unfortunate, Chiara."

					"I look forward to continuing this later."

					"As do I."
				*else
					*set santagostino_rapport %+10
					She smiles at your sophomoric attempts at flirtation.  "Your efforts are endearing, you know."

					*if (compassion < 45) and (discretion < 45)
						*set flirting_with_chiara true
						"Then I have succeeded where I am sure many others have failed."

						"Yes, quite."

						The conversation continues a little while longer, but alas, all good things must come to an end.
					*else
						*set santagostino_rapport %-15
						You growl at her.  "My purpose was not to be endearing."

						She titters at you.  "Well, your attempts to compare my beauty to a mirror were novel…"

						You shake your head in frustrated embarrassment.  Santagostino does her best to exit with whatever grace still remains to the two of you.
						*goto meet_ashmore_4
			*selectable_if (discretion > 40) #"I must confess…I have fallen in love.  There is a woman here, a mortal woman…"
				*set compassion %-20
				*set discretion %+10
				*set santagostino_rapport %-10
				*set spurned_chiara true
				*set flirting_with_chiara false
				"And this concerns me how?"

				"I thought you should know…"

				"It is no concern of mine what you do with your food, ${given_name}."  Your name suddenly sounds venomous on her lips.

				"She is not my food!" you protest.

				She rolls her eyes at you.  "I have no time for this."  Turning on her heel, she quickly puts as much distance as she can between the two of you.
			*if (sire_name = "Pieter van der Velde") and (sire_alive)
				#I ask after my maker.
					*goto ask_after_maker
		*else
			*if jesse_waylaid = false
				#I inquire after the location of Jesse.
					"I can't really say.  He's been very secretive of late.  Not the old Jesse, so taken with whores and dice.  It's as though he has found a higher calling."

					*if heresy_of_masons > 0
						"I'm sure that it's nothing.  He'll be back to his old habits in no time."  You hope that she does not share her views widely; Jesse's devotion to the Freemasons may very well be the source of this change, and you hope to quiet any suspicions about him.
					*if heresy_of_masons = 0
						"That is strange."

						"Yes.  I've tried to speak with him about this change of heart, but he does not take my jests as he did of old."
			#I flirt with her shamelessly.
				*set discretion %+10
				*if charm >= 3
					*set flirting_with_chiara true
					*set santagostino_rapport %+20
					And flirt you do.  Soon, her laughter ripples through the room.
					*if perception > 2
						You notice several of the other guests shooting glares in your general direction.  Clearly, this is not the correct environment for such mirth.
					"It has been too long, dear ${given_name}, but I'm afraid I can't spend the whole evening at your side."

					"That is unfortunate, Chiara."

					"I look forward to continuing this later."

					"As do I."
				*else
					*set santagostino_rapport %+10
					She smiles at your sophomoric attempts at flirtation.  "Your efforts are endearing, you know."

					*if (compassion < 45) and (discretion < 45)
						*set flirting_with_chiara true
						"Then I have succeeded where I am sure many others have failed."

						"Yes, quite."

						The conversation continues a little while longer, but alas, all good things must come to an end.
					*else
						*set santagostino_rapport %-15
						You growl at her.  "My purpose was not to be endearing."

						She titters at you.  "Well, your attempts to compare my beauty to a mirror were novel…"

						You shake your head in frustrated embarrassment.  Santagostino does her best to exit with whatever grace still remains to the two of you.
						*goto meet_ashmore_4
			#I ask after Estefania Rios e Hidalgo.
				*gosub news_of_estefania
			*if (sire_name = "Pieter van der Velde") and (sire_alive)
				#I ask after my maker.
					*label ask_after_maker
					*set independence %+5
					*set discretion %-5
					*set sire_rapport %+5
					"Heer Van der Velde has been making his opposition to Stone more apparent.
					*if revolutionary_credentials > 60
						In fact, he is somewhat disappointed in your reputation for being a supporter of Mr. Stone."
					*elseif (revolutionary_credentials >= 40)
						I'm sure he'd like to see you make a more ardent stand on behalf of Consul Adonis."
					*else
						In fact, he is quite proud of the display of loyalty that you have made since coming here."
					
					"But you…"
					
					"I most certainly disagree with him, yes."
					
					"That must make social gatherings…challenging."
					
					She laughs; a hearty, unself-conscious laugh.  "I could not have said it better myself, dear ${given_name}."

	You sense that she is in need of continuing her rounds.
	*if flirting_with_chiara
		"It is delightful to be graced with your presence again, [i]cara mia[/i]."

		Chiara kisses you lightly on the cheek, squeezes your arm, and departs.
	*else
		"It is good to see you again, Senator."

		"And you as well, ${given_name}"
	*label meet_ashmore_4
	*page_break
	Standing there, watching her go, you are startled to find @{heard_of_ashmore Rebecca Ashmore descending upon you.|a woman in antebellum dress descending upon you.}
*else

	You only have a few moments to observe the effect of this news on the guests before @{heard_of_ashmore Rebecca Ashmore, adorned in antebellum dress and bearing a fan, descends upon you.|a woman in antebellum dress descends upon you, fluttering a fan.}
*if ashmore_correspondence
	"It is so good to finally put a face with a name," she begins.
	*if speaks_english and ((ethnicity = "german") or ((ethnicity = "spanish") or ((ethnicity = "french") or (ethnicity = "choctaw"))))
		*set ashmore_comment true
		You are surprised that she addresses you in your native tongue.
	*comment endif
	
	*if ethnicity = "choctaw"
		You do a double-take. 
	"The pleasure is all mine, Senator."
	*if ethnicity = "choctaw"
		*set ashmore_rapport %+10
		The words feel almost strange in your mouth. "You know my tongue?"
		
		She mangles the next sentence…something about the sun rising and friendship.
		
		"I am flattered, Senator. But perhaps English would be easier?"
		
		"Yes, perhaps. I have not yet mastered your language."
		
		"I am very impressed that you would try, Senator."
		
		She smiles at you, fluttering the fan coyly.
	
*set met_ashmore true
*set heard_of_ashmore true
*gosub check_senators_achieve
"I understand you spent some time with my aunt in Vicksburg," she says.
*if (speaks_english = false) and (ashmore_comment = false)
	You are surprised that she addresses you in your native tongue.
*comment endif

*if (slept_through_vicksburg) or (fled_from_vicksburg)
	*if heard_of_ashmore
		"Not as much as you might think.  The war was not to my liking."
		
		"I fully understand.  I found it most distasteful as well."

		"You must be…"

		"Rebecca Ashmore, Senator of Philadelphia."

		"A pleasure, Senator," you say with a ${bow}.

		She titters, "No need for such formality, ${mr} ${surname}.  I have the feeling we will be good friends."
		*goto ashmore_choice
	*else
		"Your aunt?  Quaestor Withers?"
		
		"Of course!  Don't you know who I am?"
		
		"I…"
		
		"Rebecca Ashmore, Senator of Philadelphia, scion of Governor Overstreet."
		
		"Pardon my ignorance.  Perhaps if I had spent more time in the company of Quaestor Withers, I would have known that."
		
		"More time?"
		
		"Yes…I did not find the war to my liking, and so my time with the Quaestor was rather brief."
		
		"I fully understand.  I found it most distasteful as well."
		*goto ashmore_choice
*elseif heard_of_ashmore
	"Why yes, I spent some years with her.  You must be Senator Ashmore."
	
	"Guilty as charged."
	
	"It is a pleasure to make your acquaintance, Senator."
*else
	*set heard_of_ashmore true
	"Your aunt?  Quaestor Withers?"
	
	"Of course!  Don't you know who I am?"
	
	"I…"
	
	"Rebecca Ashmore, Senator of Philadelphia, scion of Governor Overstreet."
	
	"Then, yes, I did spend several years in her company."

"She is well, I trust?" she says, the fan gesticulating with her words.

*if chasing_wilson and (wilson_embraced_by_withers and (discretion > 40))
	*if carothers_debt_wilson > 1
		"I am, in fact, tasked with cleaning up her mess."
		
		"Her mess?" Ashmore exclaims.
		
		"Some trouble with a scion of her hers, in fact."
		
		Ashmore sighs. "I wish her…and you…the very best in this endeavor."
	*else
		*if wilson_embraced_by_withers
			"I am here, in fact, on business for her."
			
			"Business?"
			
			"Some trouble with a scion of her own, in fact."
			
			"That is most generous of you to go so out of your way for her, ${mr} ${surname}."
			
			*if (discretion > 50) and (withers_rapport < 40)
				"I don't think it has anything to do with generosity, Senator.  I would rather not be so tasked."
				
				"I see.  Perhaps you should not be relating the nature of your charge so freely, then."
			*else
				*set ashmore_rapport %+15
				"I'm not sure she left me with much of a choice, Senator."  You do your best to offer a knowing smile as you say this.
				
				Ashmore titters at this.  "Yes, she can be persuasive when she puts her mind to something."
		*else
			"Last I heard, yes," you reply noncommittally.
*else
	*if flirting_with_withers
		"She is delightful.  It pains me to be so far away from her, in fact."
		
		Ashmore titters at this.  "I shall make sure to tell my dominus that Sam has an admirer."
		
		"I suspect I am not the only one."
		
		"No, I daren't say that you are."
	*else
		*if (discretion > 50) and (withers_rapport < 40)
			*set ashmore_rapport %+5
			"If by well, do you mean well-positioned by your dominus, where she can do no harm to the Society?  Why yes, she is."
			
			"I beg your pardon?"
			
			"Your aunt is incompetent, if charming.  Your dominus was wise to grant her the quaestorship of an insignificant town.  Prestigious, but inconsequential."  Ashmore is clearly taken aback by your blunt appraisal of the situation.
			
			"Your honesty is a breath of fresh air, ${mr} ${surname}."
		*else
			"She is well.  Perhaps a bit bored—Vicksburg is not the crossroads of our kind—but she endures the tedium admirably."
			
			"I am glad to hear it."

Sensing a pause, you change the subject.  "And you?  A Senator?  You outshine your aunt!"

"I serve the Society, no more."  Her false modesty is transparent.
	
*label ashmore_choice
*choice
	#I ask her about the @{knows_leper leper|disfigured man}.
		*set ashmore_rapport %-10
		She frowns at you. "Why would you want to talk about that poor man? He really should walk into the sun and put himself out of his misery."
		
		*if compassion < 40
			*if discretion > 50
				*set ashmore_rapport %-10
				"That is a rather cavalier response to a man's suffering."
				
				"It is an honest one," she retorts.
				
				This introduction could have gone better.
			*else
				"Is his suffering so burdensome to you?"
				
				"He puts us all in jeopardy."
				
				"And that is a burden on you?"
				
				"Of course it is!" she snaps.
				
				This introduction could have gone better.
		*else
			"One could say that about half of this room," you remark.
			
			She widens her eyes and flutters her fan. "Why yes, yes you could." She pauses.
			*goto ashmore_choice
	#I continue to flatter her.
		*set ashmore_rapport %+20
		*set discretion %+5
		*set independence %+5
		You continue exchanging pleasantries; she titters suggestively at your jests.  It seems that your flirtations are well-received.
	*if heard_about_great_railroad_strike
		#"What of the railroad strikes?  Weren't you afraid to make the journey here?"
			*set discretion %+10
			*set ashmore_rapport %+5
			*set heard_of_quarrington true
			"Dreadful, I tell you.  Simply dreadful.  And poor Quaestor Quarrington."

			"Quaestor Quarrington?"

			"Yes, he was slain during the strike."

			"Quaestor of what city?"

			"Cumberland, Maryland.  He really was so hospitable to me whenever I needed to cross those wretched mountains.  Of course, things are so much easier now with the railroads; it used to be an absolutely dreadful experience."

			"He was slain?"

			"Yes.  A mob of those horrible workingmen stormed his home and burnt him to ash."

			"That is dreadful!"
			*goto ashmore_choice
	*if great_swap = false
		#I try to ascertain how she came to be a Senator.
			*set discretion %+5
			*if ashmore_rapport > 40
				*set great_swap true
				Rebecca seems only too happy to expound upon the power and influence of her dominus, Governor Overstreet.  It seems that, when the time came for senators to be elected for Savannah and, at the same time, Philadelphia, Overstreet and her counterpart Governor Townsend of Philadelphia engineered what became known as the Great Swap.  She, Rebecca, was sent to be the Senator of Philadelphia.  Meanwhile, Abel Bowater, the progeny of Governor Townsend, was sent to become the Senator of Savannah.  That way, neither Governor would exert undue influence on the Senate.
			*else
				You try to dance around the subject of her election as best you can, without being too indelicate.  Unfortunately, either your tact is too tactful or Ashmore is being intentionally obtuse.  Either way, she avoids satisfying your curiosity.
				*goto ashmore_choice
	#I try to ascertain her opinion of Stone and his revolution.
		*set ashmore_position true
		*if ashmore_revolutionary
			*if revolutionary_credentials >= 60
				"Considering your well-known allegiance to Consul Stone, I do not hesitate to tell you that I am a fervent supporter of him as well."

				"I am glad to hear it, Senator."

				"Yes, you are in good company, ${sir}."
			*else
				You try to dance around the topic of loyalties as best you can, without being too indelicate.  Unfortunately, either your tact is too tactful or Ashmore is being intentionally obtuse.  Either way, she avoids satisfying your curiosity.
		*else
			*if revolutionary_credentials <= 40
				"Considering your well-known opposition to Consul Stone, I do not hesitate to tell you that I am a fervent opponent of his as well."

				"I am glad to hear it, Senator."

				"Yes, you are in good company, ${sir}."
			*else
				You try to dance around the topic of loyalties as best you can, without being too indelicate.  Unfortunately, either your tact is too tactful or Ashmore is being intentionally obtuse.  Either way, she avoids satisfying your curiosity.
	*if player_for_senator = false
		*if ashmore_support = 1
			*if (malloy_out = false) and (heard_of_malloy)
				#I urge her to support Miss Malloy in the caucus tomorrow night.
					*set revolutionary_credentials %+10
					*if ashmore_revolutionary
						*set ashmore_rapport %+10
						*set ashmore_support 3
						"Have no doubt that I will.  She is clearly the only acceptable candidate for the position."
					*else
						*set ashmore_rapport %-10
						*set ashmore_support 2
						She looks at you with thinly-disguised contempt.  "I shall take your advice under consideration."
			*if (malloy_out or pickering_out) and (heard_of_lesczynski)
				#I urge her to support Mr. Lesczynski in the caucus tomorrow night.
					*if malloy_out
						*set ashmore_support true
						*set revolutionary_credentials %+10
						*if ashmore_revolutionary
							*set ashmore_rapport %+10
							*set ashmore_support 4
							"Considering Miss Malloy's absence, I suppose that I shall be forced to support Mr. Lesczynski.  After all, Mr. Pickering is clearly unacceptable."
						*else
							*set ashmore_rapport %-10
							*set ashmore_support 2
							She looks at you skeptically.  "I shall take your advice under consideration."
					*else
						*set revolutionary_credentials %-10
						*if ashmore_revolutionary
							*set ashmore_rapport %-10
							*set ashmore_support 2
							She looks at you skeptically.  "I shall take your advice under consideration."
						*else
							*set ashmore_rapport %+10
							*set ashmore_support 4
							"I suppose that I shall have to.  With Mr. Pickering absent, Mr. Lesczynski is the only viable option."
			*if (pickering_out = false) and (heard_of_pickering)
				#I urge her to support Mr. Pickering in the caucus tomorrow night.
					*set revolutionary_credentials %-10
					*if ashmore_revolutionary
						*set ashmore_rapport %-10
						*set ashmore_support 2
						She looks at you with thinly-disguised contempt.  "I shall take your advice under consideration."
					*else
						*set ashmore_rapport %+10
						*set ashmore_support 5
						"Have no doubt that I will.  He is clearly the only acceptable candidate for the position."
		*if player_for_senator
			#I urge her to support my bid for the position of Senator.
				*set discretion %+10
				*if (ashmore_rapport > 50) or (status > 2)
					*if ashmore_revolutionary and (revolutionary_credentials > 60)
						*if malloy_out
							"With Siobhan no longer in the running, I must admit, you seem an excellent candidate for the position, ${mr} ${surname}."
							
							"Why thank you, Senator."
							
							"I cannot commit to you at this time, but I will tell you that I am pleased by this request of yours."
						*else
							"And what of Siobhan?  She is a perfectly suitable candidate, ${mr} ${surname}."
							
							"She is not a citizen of Memphis, she is not attuned to its needs…"
							
							"I cannot commit my support to you at this time, but rest assured that your petition has been favorably received."
					*elseif (ashmore_revolutionary = false) and (revolutionary_credentials < 40)
						*if pickering_out
							"With Absalom no longer in the running, I must admit, you seem an excellent candidate for the position, ${mr} ${surname}."
							
							"Why thank you, Senator."
							
							"I cannot commit to you at this time, but I will tell you that I am pleased by this request of yours."
						*else
							"And what of Absalom?  He is a perfectly suitable candidate, ${mr} ${surname}."
							
							"He is not a citizen of Memphis, he is not attuned to its needs…"
							
							"I cannot commit my support to you at this time, but rest assured that your petition has been favorably received."
					*elseif ashmore_revolutionary and (revolutionary_credentials < 40)
						"You make a compelling argument, ${mr} ${surname}, but you must know that I do not agree with your political affiliations."
						
						"Can the greater concerns of the Society be the only factor for consideration in this election?  What of Memphis?"
						
						"You argue eloquently, and I find you a worthy candidate, but I cannot promise you my support."
					*elseif (ashmore_revolutionary = false) and (revolutionary_credentials > 60)
						"You make a compelling argument, ${mr} ${surname}, but you must know that I do not agree with your political affiliations."
						
						"Can the greater concerns of the Society be the only factor for consideration in this election?  What of Memphis?"
						
						"You argue eloquently, and I find you a worthy candidate, but I cannot promise you my support."
					*else
						She smiles at you.  "I would be happy to consider it.  Of course, I could be more easily persuaded if you were to make @{ashmore_revolutionary a stronger commitment to Stone's cause."|you were to make your opposition to Stone clear."}
						
						"I will consider your suggestion, Senator."
						
						"It would please me if you did, ${mr} ${surname}."
				*else
					*set ashmore_rapport %-10
					She looks at you skeptically.  "I'm afraid I can't do that.  I do not think you are prepared for the responsibility."
				
*label exit_ashmore
*set ashmore_questions +1
*if ashmore_questions <= 1

	There is a momentary pause in the conversation.  It seems up to you to fill it.
	*goto ashmore_choice
*else
	The noise in the room increases suddenly.  Realizing that more guests have arrived—is that Quaestor Harding you spy?—Ashmore's attention wanders.  Returning it to you for a moment, she excuses herself: "If you will forgive me…"

	"But of course, Senator."
	
	*if pickering_out and (revolutionary_credentials <= 40)
		*page_break
		Your conversation ended, you turn, only to find yourself face-to-face with Senator Lockridge.  He smiles politely in greeting.  "It was good of you to alert me to this…blemish on the record of Mr. Pickering."
		
		"I was only doing my duty for the cause, Senator."
		
		He grimaces at that.  "Enthusiastic.  I suppose that's good.  Now, if you will excuse me…" @{(compassion < 40) You find yourself exhaling in relief.  Funny, since you don't need to breathe.|}
	*elseif pickering_out and ((revolutionary_credentials >= 60) and (status > 2))
		*page_break
		Your conversation ended, you turn, only to find yourself face-to-face with Senator Lockridge.  He smiles politely in greeting.  "So kind of you to bring the information regarding Mr. Pickering to my attention."
		
		"I serve the Society, Senator."
		
		"Yes, clearly.  And Isaiah Stone."
		
		"And Consul Stone, yes."
		
		His eyes turn into slits.  "Yes, of course, Consul Stone."  Without another word, he brushes past you. @{(compassion < 40) 	You find yourself exhaling in relief.  Funny, since you don't need to breathe.|}
	*elseif malloy_out and (revolutionary_credentials >= 60)
		*page_break
		Your conversation ended, you turn, only to find yourself face-to-face with Senator Bailey.  He smiles politely in greeting.  "It was good of you to alert me to this…blemish on the record of Miss Malloy."
		
		"I was only doing my duty for the cause, Senator."
		
		He grimaces at that.  "Enthusiastic.  Sometimes enthusiasm can be…misplaced.  Now, if you will excuse me…" @{(compassion < 40) You find yourself exhaling in relief.  Funny, since you don't need to breathe.|}
	*elseif malloy_out and ((revolutionary_credentials <= 40) and (status > 2))
		*page_break
		Your conversation ended, you turn, only to find yourself face-to-face with Senator Bailey.  He smiles politely in greeting.  "It was good of you to alert me to this…blemish on the record of Miss Malloy."
		
		"I serve the Society, Senator."
		
		"And yet, Consul Stone…"
		
		"Isaiah Stone, you mean.  The Senate has not officially recognized him as Consul."
		
		"Yes, I see."  Without another word, he brushes past you.
		*if compassion < 40
			You find yourself exhaling in relief.  Funny, since you don't need to breathe.

*if (calkins_status = 3) and ((calkins_rapport >= 50) and depot_burned)
	*page_break
	"It seems thou makes friends wherever thou goest, ${mr} ${surname}."
	
	Turning,
	*if heard_of_bowater
		you find yourself face-to-face with Abel Bowater, Senator of Savannah.
		
		"I do?"
	*else
		you see the man in Quaker dress before you.
		
		"I don't believe I've had the pleasure…" you begin.
		
		"Abel Bowater, Senator of Savannah."
		
		"An honor, sir."
	*set met_bowater true
	*set heard_of_bowater true
	*gosub check_senators_achieve
	
	"Yes.  My dear friend Andrew wrote to me, saything that I should heed thy words, should we ever have the chance to meet."  You look at Senator Bowater, surprised.  Andrew Calkins, the vampire who snuck into Vicksburg with the intention of destroying the ammo depot?  Friends with a Senator, no less?
	
	You choose your words carefully.  "Andrew was…enthusiastic.  He sought to end the war single-handedly."
	
	"Yes, his schemes always were grand.  Now, tell me, what do thou think of this whole affair…?"
	
	*if independence >= 30
		You spend the next forty minutes discussing the advantages and drawbacks of the various candidates, while Bowater listens, rapt. @{player_for_senator You make sure he understands that you seek the position yourself, and would very much appreciate his support.|} When you are finished, you are confident that Bowater will vote in accordance with your reputation.
	*if independence < 30
		*set bowater_rapport %+20
		"I think very little of it, to tell the truth.  I am only here out of the direst of obligations, and I shall depart as soon as is humanly possible."
		
		Bowater nods slowly.  "It gladdens me to hear thou say this.  I wish that I might treat these matters in the same way, but alas, I cannot.  Now, if you will excuse me.…"
*elseif (calkins_status > 3) and (perception > 1)
	*page_break
	It is at this moment that your ears perk at the mention of a name.  Glancing out of the corner of your eye, you spy
	*if heard_of_bowater
		Abel Bowater
	*if heard_of_bowater = false
		*set heard_of_bowater true
		a man in Quaker dress
	in conversation with Apollo Carothers.  "Andrew Calkins was his name.  I know he came down this way during the war, but I have not heard from him in some time."  You freeze at the mention of that name.

	"No, I do not recall such an individual, Senator."

	"Perhaps Ms. Applethorp…?"

	"She would have told me if someone had passed through the city.  I'm afraid this man did not stop long enough to warrant an audience."

	The Senator purses his lips and nods, thanking Carothers for his time.  Thinking it best not to linger, you continue on.
	
*if lockridge_waylays_davison
	*page_break
	Drifting through the crowd, you find Bailey seated alone.  Surprised to find him without Partridge, you take a moment to join him.
	
	"Senator," you begin.
	
	"Senator Davison will not be joining us."
	
	"Oh?  Why not?"
	
	"I cannot say for certain, but I suspect that my good friend Arthur is responsible for this maneuver."
	
	"Would he do such a thing?"
	
	"Without a doubt."
	
	"Is she well?"
	
	"Yes, but she is in Chicago.  Her traveling-coffin was transferred to the wrong steamboat."
	
	"And there is no way…"
	
	"No.  She will not make it."
	
	"How much does this hurt our cause?"
	
	"Significantly."
*elseif santagostino_waylays_simmons
	*page_break
	Drifting through the crowd, you find Lockridge just out of conversation with one of his mortal valets.  You can see his jaw clinched as he nods in greeting.  "It seems that Senator Simmons will not be joining us."
	
	"Really?  Why so?"
	
	"His traveling-coffin was put on the wrong steamboat in New Orleans.  He sent a message…I'm not sure how it reached here so quickly…my valet was trying to explain Morse code to me, but I think he was jesting with me.  It is no matter; Simmons is not here, and it seems likely that he will not be attending."
	
	*if (technology > 1) and (discretion > 50)
		"He did not jest.  Senator Simmons must have sent a telegraph.  It's really a very simple device…" your words trail off as you realize that Lockridge is not really interested in your explanation.  You clear your throat, and try to change the subject. 	"How much does that damage our cause?"
	
		"Significantly, ${mr} ${surname}.  Significantly."
	*elseif anachronism > 50
		Is this what you have to look forward to?  When you begin to assume that the inventions of the day are conspiracies by your underlings to embarrass you?
		
		You shake these thoughts away.  "How much does that damage our cause?"
	
		"Significantly, ${mr} ${surname}.  Significantly."
	*else
		Morse code?  What sort of jest was that?  And why would Lockridge's servant be so impudent?  You clear your throat and try to change the subject. 	"How much does that damage our cause?"
	
		"Significantly, ${mr} ${surname}.  Significantly."

*if applethorp_rapport > 55
	*page_break
	Dido appears at your elbow, a pained look upon her face.  "Do you need something, Dido?"
	
	"Y${es_suh}, Ah does."
	
	"What's that?"
	
	"Ah is afeared for deh Quaestah.  He ain't like he was."
	
	"How do you mean?"
	
	"He use' tah be nice to me.  Take me for promenades.  We'd go an' hunt ta'gedder.  Now he jus' wants me to bring him folks.  He don' take no pleasure in the world no mo'."
	*choice
		#"Really, I hadn't noticed.  Is he not always ornery?"
			*set compassion %+5
		#"You are right.  His whole demeanor has changed.  The administration of the city weighs upon him."
			*set independence %+5
			*set compassion %-5
		*if compassion < 50
			*selectable_if (rationalism > 50) #"We are all soulless beings; it is only a matter of time before we all end up like him."
				*set rationalism %+5
				*set compassion %-5
				Dido's face contorts in misery.  "We all gwine end up like dat?"
				
				"We are cursed by God.  What did you expect?"
				
				She lets out a little shriek and runs from your presence.  Several of the other guests cast a glance in your direction.  You return their looks with a blank stare.
		*selectable_if (carothers_rapport < 45) #"I wouldn't know.  We're not on the best of terms."
			*set applethorp_rapport %-10
			"But…you don' see no change?"
			
			"No."  She seems crestfallen.  "Is there anything else I can do for you?"
			
			"No, dat's all Ah was wantin'," she replies.  She shakes her head and turns away.

*label open_choice
*page_break
You sense a sudden ebb in attention.  The gathered vampires are busy in their conversations, and you have a moment to ponder.  Had you any breath to catch, now would be the time.
*label open_choice_1
*if (heard_of_lockridge = false) and (lore > 3)
	*label recognize_lockridge
	*set heard_of_lockridge true
	*set already_recognized true

	Looking around the room, you realize that you can put a face with a name: the man from the Carolinas must be Arthur Lockridge, Senator of Charleston.  You have heard of the individual, but this is the first you have laid eyes on him.  He is a well-known supporter of Adonis.
*if (heard_of_lockridge = false) and ((lore = 3) and ((heard_of_shepherds_and_wolves) or (revolutionary_credentials < 30)))
	*goto recognize_lockridge
*if (heard_of_bailey = false) and (lore > 3)
	*label recognize_bailey
	*set heard_of_bailey true
	*if already_recognized

		You also recognize John Bailey, a fair-haired and clean-shaven vampire, as the Senator of St. Louis.
	*else
		*set already_recognized true

		Looking about the room, you realize that you can put a face with a name: the fair-haired, clean-shaven vampire must be John Bailey, Senator of St. Louis.  He is a well-known supporter of Isaiah Stone.
*if (heard_of_bailey = false) and ((lore = 3) and (revolutionary_credentials > 70))
	*goto recognize_bailey

Surveying the room, you debate what to do.
*choice
	*if met_ashmore
		#I'd like to speak with Senator Ashmore again.
			*set ashmore_rapport %+10
			*if ashmore_rapport > 45
				"Hello again, ${mr} ${surname}," she says when you near.

				"Senator, there was something I wanted to speak with you about…" you begin.
				*gosub speak_ashmore
				*goto plans_for_tomorrow
			*else
				She rolls her eyes at your approach.  "Yes?" she says with no attempt to hide her exasperation.

				"Senator, there was something I wanted to speak with you about…" you begin.
				*gosub speak_ashmore
				*goto plans_for_tomorrow
	*if heard_of_ashmore and (met_ashmore = false)
		#I'd like to introduce myself to Rebecca Ashmore, Senator of Philadelphia.
			*if ashmore_correspondence
				"A pleasure to finally meet you, ${mr} ${surname}," she says once you introduce yourself.

				"The pleasure is mine," you reply with a ${bow}.

				"Are you enjoying the evening so far?"

				"Yes, quite.  If you forgive me, I had a question to ask you…"
				*gosub speak_ashmore
				*goto plans_for_tomorrow
			*else
				"Pardon me…" you begin.

				"Yes?" she says, turning to greet you.  "Oh!  You must be ${mr} ${surname}." Her eyes @{(overstreet_rapport >= 45) light up with|narrow at} the realization.   "My dominus has spoken @{(overstreet_rapport >= 45) highly|} of you."

				*if ashmores_sire
					"Ah, yes, how is Governor Overstreet?"

					"Well, last I heard.  Thank you for asking."
				*if ashmores_sire = false
					*set ashmores_sire true
					"Your dominus?"

					"Governor Overstreet."
				*comment endif

				"I see."  There is an uncomfortable pause before you move on to the next topic.  "Tell me, Senator…"
				*gosub speak_ashmore
				*goto plans_for_tomorrow
	*if heard_of_ashmore = false
		#I'd like to introduce myself to a striking white woman in Southern dress.
			"Pardon me…" you begin.

			"Yes?" she says, turning to greet you.  "Oh!  You must be ${mr} ${surname}." Her eyes @{(overstreet_rapport >= 45) light up with the realization.   "My dominus has spoken highly of you."|narrow at the realization.  "Yes, my dominus has spoken of you."}

			"Your dominus?"

			"Governor Overstreet."

			"And you are…?"

			"Rebecca Ashmore, Senator of Philadelphia."

			*if (discretion > 50) and (anachronism > 60)
				"I see you maintain the style of your home, then?"

				"Yes, it is so hard to part ways with one's upbringing."

				"Yes, quite.  Tell me…"
				*gosub speak_ashmore
				*goto plans_for_tomorrow
			*else
				"It is an honor to meet you, Senator."

				"And you, ${mr} ${surname}.  Please, how may I help you this evening?"
				*if overstreet_rapport <= 45
					Her voice is dripping with sarcasm.
				*comment endif

				"I had a question for you…"
				*gosub speak_ashmore
				*goto plans_for_tomorrow
	*if met_bailey and (memphis_partridge_bailey_convo = false)
		#Our meeting at the last gathering was so brief; I'd like to speak with Senator Bailey again.
			Whether fortunately or no, Bailey and Partridge seem inseparable.  Any conversation with him will be had with them both.
			
			Nearing them, they turn to greet you.  "Senator Bailey, our chance to speak last time was so brief…" you begin.

			"Oh, yes!  ${mr} ${surname}!  A pleasure to see you again," says Bailey.

			"Yes, a pleasure," continues Partridge.

			"Please, what can we do for you?" inquires Bailey.
			*gosub speak_partridge_and_bailey
			*goto plans_for_tomorrow
	*elseif heard_of_bailey and ((met_bailey = false) and (bailey_correspondence = false))
		#I'd like to introduce myself to Senator Bailey.
			Whether fortunately or no, Bailey and Partridge seem inseparable.  Any conversation with him will be had with them both.
			
			Nearing them, they turn to greet you.
			*label heard_of_bailey
			"Senators Partridge and Bailey, I presume?"
			
			"You are correct," says Bailey.
			
			"You must be ${mr} ${surname}," continues Partridge.
			
			"The one and only," you reply with a grin.
			
			"Please, what can we do for you?" inquires Bailey.
			*gosub speak_partridge_and_bailey
			*goto plans_for_tomorrow
	*elseif (heard_of_bailey = false) or bailey_correspondence
		#I'd like to introduce myself to the fair-haired gentleman@{bailey_correspondence , whom I deduce is Senator Bailey|}.
			@{bailey_correspondence Bailey|The fair-haired gentleman} seems inseparable from his bearded companion.  Any conversation with the one will no doubt involve them both.
			
			*label unacquainted_bailey
			Nearing them, they turn to greet you.
			*if speaks_english = false
				*set memphis_bailey_couldnt_communicate true
				Unfortunately, when you attempt to introduce yourself, you discover that you do not share a common tongue with them.

				Frustrated, you excuse yourself.
				*goto open_choice_1
			
			"Good evening," the bearded one says.
			
			"Welcome," @{bailey_correspondence Bailey|the other} continues.
			
			"Please, allow me to introduce myself.  I am ${given_name} ${surname}, @{(lore > 2) scion of ${sire_name},|} citizen of Memphis."
			
			*if bailey_correspondence
				"Oh, I should have known!" Bailey replies. "I am John Bailey. Such a pleasure to put a face with a name."
	
				"Senator Bailey! A pleasure," you feign surprise.
				
				"Please, this is Samson," he continues, gesturing to his companion. "I'm sure you'll get along famously."
				
				The bearded one extends his hand. "Samson Partridge, Senator of Louisville."
				
				"Senator," you reply with a @{male nod|half-curtsy}.
			*else
				"A pleasure, ${mr} ${surname}.  I am John Bailey, Senator of St. Louis," replies the fair-haired gentleman, "and this is Samson Partridge, Senator of Louisville."
				*if lore > 2
					*set knows_partridge_childe_of_stone true
					Samson Partridge?  You've heard this name before.  Yes, of course, he is the offspring of Isaiah Stone!
				
			"An honor to meet you, gentlemen."
			
			"What can we do for you, ${mr} ${surname}," replies Partridge.
			*gosub speak_partridge_and_bailey
			*goto plans_for_tomorrow
	*if (met_bowater = false) and (heard_of_bowater or bowater_correspondence)
		#I seek out Senator Bowater and try to determine how he will vote tomorrow.
			*if met_bowater = false
				*set met_bowater true
				*gosub check_senators_achieve
				You approach Senator Abel Bowater.  His Quaker garb sets him apart even in this room of anachronisms.  "Senator, allow me to introduce myself…" you begin.

				He turns to greet you, and you stop.  You see something different in his eyes.  Might that be kindness?  So unfamiliar of a sight is it that it stops you cold.  He smiles at you, and suddenly time starts flowing again.  

				"…I am ${given_name} ${surname}."

				"A pleasure to make thine acquaintance, ${given_name} ${surname}.  Art thou enjoying thyself this evening?"

				"I am, Senator.  Thank you for asking."

				"Not at all.  The fact that we are immortal predators bent on destroying each other does not mean that we cannot take some small interest in the well-being of one another."
			*if (calkins_status = 3) and (independence > 30)
				*set bowater_determined true
				*if (calkins_rapport >= 50) and (revolutionary_credentials >= 50)
					*set bowater_revolutionary true
				*if (calkins_rapport < 50) and (revolutionary_credentials < 50)
					*set bowater_revolutionary true
			*if calkins_status > 3
				*set bowater_determined true
				*if ashmore_determined and (ashmore_revolutionary = false)
					*set bowater_revolutionary true
			*if bowater_determined
				*if bowater_revolutionary
					"I do not hesitate to inform thee that I shall be supporting @{malloy_out Mr. Lesczynski."|Miss Malloy."}

					*if revolutionary_credentials > 60
						"I am glad to hear that, Senator."

						"I thought thou mightst be," he says, with almost a twinkle in his eye.
						*goto plans_for_tomorrow
					*elseif revolutionary_credentials >= 40
						"That is good to know, Senator."

						Before he can ask you about your own intentions, you slip away and into another conversation.
						*goto plans_for_tomorrow
					*else
						"That is unfortunate, Senator."

						"I thought thou mightst think it so," he says, with almost a twinkle in his eye.
						*goto plans_for_tomorrow
				*else
					"I do not hesitate to inform you that I will be supporting @{pickering_out Mr. Lesczynski."|Mr. Pickering."}

					*if revolutionary_credentials > 60
						"That is unfortunate, Senator."

						"I thought thou mightst think it so," he says, with almost a twinkle in his eye.
						*goto plans_for_tomorrow
					*elseif revolutionary_credentials >= 40
						"That is good to know, Senator."

						Before he can ask you about your own intentions, you slip away and into another conversation.
						*goto plans_for_tomorrow
					*else
						"I am glad to hear that, Senator."

						"I thought thou mightst be," he says, with almost a twinkle in his eye.
						*goto plans_for_tomorrow
			*else
				"You might not believe this, ${mr} ${surname}, but I am, as of yet, undecided."

				*if revolutionary_credentials > 60
					"Surely, Senator, there is only one option…"

					"Yes, I know whom thou wouldst have me vote for.  But I cannot make any promises yet."

					"There must be something I can do to persuade…"

					"No, but I do appreciate thine interest."

					Sensing that you have begun to try his patience, you excuse yourself.
					*goto plans_for_tomorrow
				*elseif revolutionary_credentials >= 40
					"I see."

					"And you, ${mr} ${surname}?  Whom wouldst thou prefer…" but you don't catch the last of it, as you slip away into another conversation.  You wouldn't want to have to commit yourself, after all.
					*goto plans_for_tomorrow
				*else
					"Surely, Senator, there is only one option…"

					"Yes, I know whom thou wouldst have me vote for.  But I cannot make any promises yet."

					"There must be something I can do to persuade…"

					"No, but I do appreciate thine interest."

					Sensing that you have begun to try his patience, you excuse yourself.
					*goto plans_for_tomorrow
	*if question_bowater
		*if met_bowater and (heard_of_shepherds_and_wolves = false)
			#I want to ask Senator Bowater what compelled Andrew Calkins to such heights of seeming foolishness.
				*set heard_of_shepherds_and_wolves true
				*set discretion %+5
				*set question_bowater false
				"Have thou ever heard of the Shepherds and the Wolves?"
				
				"No…?"
				
				"It encapsulates a debate amongst our kind, a debate over how we should conduct ourselves with regards to the mortals."
				
				"Go on," you urge.
				
				"The question is simple enough: do we tend them, care for them, and make sure they do not rush off of any cliffs?  Or do we prey upon them, taking what we need, when we need it?"
				
				"And this is something which our kind debates?"
				
				"Some of us do, certainly.  Senator Lockridge, there, is a famous Wolf.  He has written several treatises on the matter."
				*set knows_lockridge_wolf true
				
				"Defending his position?"
				
				"Asserting, rather.  I do not think Senator Lockridge feels the need to defend any of his actions."
				
				"Of course."
				
				"Now, if thou will excuse me, ${mr} ${surname}…"
				
				"Do not let me keep you, Senator."
				*page_break
				Feeling that the night is not yet done, you survey the room, judging how best to conduct yourself.
				*goto open_choice_1
		*if met_bowater and (heard_of_shepherds_and_wolves and (shepherds_and_wolves = false))
			#I want to ask Senator Bowater if Andrew Calkins would be considered a shepherd.
				*set discretion %+5
				*set shepherd_credentials %+5
				*set shepherds_and_wolves true
				*set question_bowater false
				A smile creases his face.  "I should think so, ${mr} ${surname}.  Though, he takes his philosophy a little more serious than most."
				
				"How do you mean?"
				
				"Most of our kind—even the Shepherds—are content to guide things slowly.  Calkins, as thou may have noticed, takes direct action in the hopes of achieving a better world for mortals."
				
				"A better world?"
				
				"Yes, have thou heard this word, utopia? Men of letters and men of science imagine a world in which there is no misery, where everyone lives in peace and harmony.  I doubt that Calkins has squandered his time reading such, but I suspect he envisions something like that."
				
				"So uncharacteristic for one of our kind!"
				
				"Many of our kind treat the mortals with such disregard.  At least he is different."
				
				"Different is right, Senator."
				
				"Now, if thou will excuse me, ${mr} ${surname}…" he says.
				
				"Yes, yes, of course."
				*page_break
				Feeling that the night is not yet done, you survey the room, judging how best to conduct yourself.
				*goto open_choice_1
		*if met_bowater and knows_about_shepherds_and_wolves_text
			#I want to ask Senator Bowater if he knows about the actual text, [i]the Shepherds and the Wolves[/i].
				*set discretion %+5
				*set question_bowater false
				*set heard_of_eusebius true
				*set can_ask_bowater_for_saw_text true
				*set bowater_rapport %+10
				"The text itself?  By Eusebius of Damascus?  I could send thee my copy sometime.  Or, at the least, I could try to find one."
				
				"That would be most appreciated, Senator."
				
				"Please, write to me, and I will see what I can find."
				*if bowater_contactable = false
					*set bowater_contactable true
					He provides you with a way to write to contact him.
				*page_break
				Feeling that the night is not yet done, you survey the room, judging how best to conduct yourself.
				*goto open_choice_1
	*if met_coffin
		#I'd like to reintroduce myself to Senator Coffin.
			Approaching the Senator, you offer a deep ${bow}.  Returning your eyes to her level, you introduce yourself.  "Good evening, Senator, my name is ${given_name} ${surname}.  It is an honor to meet you."

			*if status > 1
				"Do not be coy, ${mr} ${surname}. I am not so quick to forget one such as thee."
				
				"I was not sure if you remembered…"
				
				"Congratulations on several more years of this existence," she says, brushing away your false humility.
				
			*else
				"Yes, I remember thee from the last time I was here, ${mr} ${surname}.  We are already acquainted."
	
				"I was not sure if you remembered…"
	
				"Of course I remember," she retorts.
	
			Deciding it best to get down to business, you try a different tactic.  "I was wondering if I might ask you something?"

			@{priest She seems to look at your collar and cassock suspiciously.|} "I suppose so.  Please, tell me, what might I do for thee?"
			*gosub speak_coffin
			*goto plans_for_tomorrow
	*if heard_of_coffin and (met_coffin = false)
		#I'd like to introduce myself to Senator Coffin.
			*if speaks_english
				Approaching the Senator, you offer a deep ${bow}.  Returning your eyes to her level, you introduce yourself.  "Good evening, Senator, my name is ${given_name} ${surname}.  It is an honor to meet you."

				"Thou are too kind, ${mr} ${surname}."

				"Do you have a moment?"

				*if priest
						She seems to look at your collar and cassock suspiciously.
				"I suppose so.  Please, tell me, what might I do for thee?"
				*gosub speak_coffin
				*goto plans_for_tomorrow
			*else
				*label meet_coffin_telepathy
				*set discovered_telepathy true
				"Good evening, my name is…" you begin, until you realize that she does not understand your tongue.  You begin to make your apologies and back away, when suddenly you hear her voice, clear as day.
				
				"I am sorry; what were thou saying?"
				
				Strangely, her lips do not move.  But she looks at you directly.
				
				"I'm sorry?" you say.
				
				"No no…do not speak, I cannot understand thy tongue.  Thou must think the words, and thus may we speak."
				
				She is in your head!  "You can hear my thoughts?"
				
				"I can."
				
				"But…how?"
				
				"The gifts of the blood are manifold, ${mr} ${surname}."
				
				"Who…who are you?"
				
				"I am Abigail Coffin, Senator of Cincinnati."

				"It is an honor, Senator."
				*gosub speak_coffin
				*goto plans_for_tomorrow
	*if (heard_of_coffin = false) and (met_coffin = false)
		#I'd like to introduce myself to the Puritan woman.
			*if speaks_english
				"Good evening, ma'am.  Allow me to introduce myself," you begin with a ${bow}. "My name…"
				
				"Have no fear, I know thee already, ${mr} ${surname}," she interjects.
				
				"I…I…" you stutter, startled by this, and unsure as to how to ask for her name in return.
				
				She seems to sense this, however, and obliges you.  "I am Abigail Coffin, Senator of Cincinnati."
				
				"An honor, Senator."
				
				"Well, I can see that thou wishes to ask me something.  Out with it."
				*gosub speak_coffin
				*goto plans_for_tomorrow
			*else
				*goto meet_coffin_telepathy
	#I'd like to introduce myself to @{fragala_name Fragalà|the leper|the disfigured man}.
		You approach the man
		*if (afflicted_vicksburg and (compassion < 50)) and ((knows_leper or heard_of_fragala) and male)
			*set fragala_rapport %+40
			and extend your hand. Having already been exposed to the yellow fever and survived, you surmise that the danger here is negligible.
			
			The leper looks you in the eye and then at your hand. After only a moment's hesitation, he extends his own and shakes it.
			
			"Calogero Fragalà," he offers.
			
			"${given_name} ${surname}," you return.
			
			"You are not afraid?"
			
			"Should I be?"
			
			"No."
			
			"What brings you to Memphis?"
			
			He smiles expansively and indicates the room. "Haven't you heard? There's a Senatorial caucus to be had."
			
			You give a mock look of surprise. "No!"
			
			You exchange a chuckle.
		*else
			and ${bow}. "Good evening, sir, I don't believe we've been introduced."
			
			"No, I don't believe we have," he rejoins.
			
			"${given_name} ${surname}," you offer.
			
			"Calogero Fragalà," he returns.
			
			"Welcome to Memphis," you begin.
			
			"Thank you."
			
			You hesitate. You had hoped for more…engagement. @{(compassion > 60) Enthusiasm. Something. Especially from one such as he.|}
		*gosub speak_fragala
		*goto plans_for_tomorrow		
	*if heard_of_harding and ((met_harding = false) and (rebuffed_by_harding = false))
		#I'd like to introduce myself to Quaestor Harding.
			*if (ethnicity = "african") or (ethnicity = "choctaw")
				*label harding_rebuffs_inquiry
				*set rebuffed_by_harding true
				*set harding_rapport %-15
				As you approach the woman, you feel her effortless move to cut you off from addressing her.  You try again to maneuver your way into her view, but, almost as if by magic, you find yourself completely unable to do so.
				*if discretion > 60
					*set harding_rapport %-10
					Frustrated, you decide to just address her.

					"Pardon me, ma'am…" you begin.

					The woman turns and stares at you.  Suddenly, you feel very small.

					*if speaks_english	
						"It is unfortunate…not only that your dominus made you, but that he was so short-sighted as to fail to instruct you in the rules of etiquette.  If someone excludes you from a conversation, you should understand that they do not wish to speak to you.  And, believe me, I would never want to speak to one such as you."  She is nearly spitting as she says these words.

						Stunned by this attack, you back away, trying to end this confrontation as quickly as possible.  Once you are far enough away, she turns and does her best to put you from her mind.
					*else
						She says something to you in English, and while you cannot understand the words, you understand the gist: you are not welcome in her presence.
						
						Stunned by this attack, you back away, trying to end this confrontation as quickly as possible.  Once you are far enough away, she turns and does her best to put you from her mind.
				*else
					Doing your best to contain your shame, you withdraw from this rebuff.  Her animosity towards you is clear, even if its source is not.
				*goto open_choice_1
			*elseif speaks_english or speaks_french
				*if met_harding = false
					*set carothers_rapport %-5
					You can feel Carothers' eyes on you as you approach the Quaestor of Louisville.
				
				*if met_harding
					"Quaestor Harding, if I may have a moment of your time…?"
					
					"Yes, of course, ${mr} ${surname}.  Always a pleasure."
				*else
					After introducing yourself, she introduces herself in turn: she is Elinor Harding, Quaestor of Louisville.
					*if heard_of_harding
						This must be Carothers' broodmate, the one of whom he spoke so harshly.  Now you understand why he was glaring at you.
					*comment endif
					
					"If I may, I hoped you might tell me something about this gathering."
					
					"Please, ask away."
				*gosub speak_harding
				*goto plans_for_tomorrow
			*else
				*set harding_rapport %-5
				Your attempts to engage Quaestor Harding in conversation go poorly, as you soon discover that you hold no tongue in common.  Withdrawing, you seek someone else with whom to converse.
				*goto open_choice_1
	*if heard_of_harding = false
		#I'd like to introduce myself to one of the more fashionable guests, a white woman dressed in contemporary garb.
			*if (ethnicity = "african") or (ethnicity = "choctaw")
				*goto harding_rebuffs_inquiry
			*elseif speaks_english or speaks_french
				*set harding_rapport %+5
				*set heard_of_harding true
				"I'm afraid I have not had the pleasure of your acquaintance, ma'am."

				"No, I'm afraid not.  I am Elinor Harding, Quaestor of Louisville."

				"I am ${given_name} ${surname}, and it is an honor to meet you," you reply with a ${bow}.
			*else
				*set harding_rapport %-5
				Your attempt to engage the fashionable woman in conversation goes poorly, as you discover that you hold no tongue in common.  Withdrawing, you seek someone else with whom to converse.
			*gosub speak_harding
			*goto plans_for_tomorrow
	*if heard_of_lesczynski and ((met_lesczynski = false) and (lesczynski_correspondence = false))
		#I'd like to introduce myself to Ascher Lesczynski.
			"Good evening, sir, do you have a moment?"
				
			"Of course!  Please," he says, gesturing for you to join him at a window.
			
			"If you would, allow me to introduce myself.  I am ${given_name} ${surname}, a citizen of this city."
			
			"A pleasure.  I am Ascher Lesczynski.  I hope to be your Senator soon."
			*gosub speak_lesczynski
			*goto plans_for_tomorrow
	*if (heard_of_lesczynski = false)
		*if able_to_identify_jews
			#I'd like to introduce myself to the Jew.
				"Good evening, sir, do you have a moment?"
				
				"Of course!  Please," he says, gesturing for you to join him at a window.
				
				"If you would, allow me to introduce myself.  I am ${given_name} ${surname}, a citizen of this city."
				
				"A pleasure.  I am Ascher Lesczynski.  I hope to be your Senator soon."
				*gosub speak_lesczynski
				*goto plans_for_tomorrow
		*else
			#I'd like to introduce myself to the man with the funny hat and curls.
				*set able_to_identify_jews true
				"Pardon me," you begin, "my name is ${given_name} ${surname}."
				
				The man turns, smiles, @{male and extends a hand in greeting.|and nods by way of greeting.} "Please, do not be shy.  My name is Ascher Lesczynski."
				
				"A pleasure, Mr. Lesczynski.  What brings you to Memphis?"
				
				"The election!  What else would I be here for?" he says.
				
				*if discretion > 60
					*set lesczynski_rapport %-5
					"Considering your outfit, I didn't know what to think."
					
					"My outfit?"
					
					"Yes, the hat and curls.  Is that the style in New-York?"
					
					"What is this [i]michegas[/i]?  Have you never seen a Jew before?"
					
					You pause a moment.  "No?"
					
					"[i]Oy vey![/i] You must be young," he says with a roll of the eyes.

					"Not so young," you retort, before changing the subject to something a little less confrontational.
					*gosub speak_lesczynski
					*goto plans_for_tomorrow
				*else
					"I don't know.  I am unfamiliar with the style of your clothing."
					
					"Have you never met a Jew before?"
					
					"No, I can't say that I have."
					
					"Well, I suppose I have the honor of being your first."
					
					"So it seems."
					*gosub speak_lesczynski
					*goto plans_for_tomorrow
	*if (met_lockridge) and (memphis_lockridge_convo = false)
		#I'd like to speak with Arthur Lockridge, Senator of Charleston again.
			"Pardon me, sir," you begin.
			
			"Yes?" the man says, turning.

			"If I may…"

			"Yes, ${mr} ${surname}.  I remember you from the last time I was here."

			"It is an honor, Senator…"

			"Yes, yes…pleasantries exchanged.  There is too much business to be done to stand on etiquette this evening.  What can I do for you?"
			*gosub speak_lockridge
			*goto plans_for_tomorrow
	*if heard_of_lockridge and ((met_lockridge = false) and (lockridge_correspondence = false))
		#I'd like to introduce myself to Arthur Lockridge, Senator of Charleston.
			*label meet_lockridge
			"Pardon me, sir," you begin.
			
			"Yes?" the man says, turning.
			
			"If I may, I am ${mr} ${surname}, a citizen of Memphis."
			
			"Ah, I have heard about the new resident of the city.  I am Arthur Lockridge, progeny of Ethelmarr, Senator of Charleston."
			*set heard_of_ethelmarr true
			
			"It is an honor, Senator."

			"Yes, yes…pleasantries exchanged.  There is too much business to be done to stand on etiquette this evening.  What can I do for you?"
			*gosub speak_lockridge
			*goto plans_for_tomorrow
	*if heard_of_lockridge = false
		#I'd like to introduce myself to the gentleman from the Carolinas.
			*set heard_of_lockridge true
			*goto meet_lockridge
	*if (met_malloy) and (memphis_malloy_convo = false)
		#I'd like to reintroduce myself to Siobhan Malloy.
			It takes you a moment to locate her, but soon she emerges from the refreshment room, wiping her mouth daintily with a now-bloody handkerchief.  "Good evening," you begin.

			"It's good ta' see ya again, ${mr} ${surname}," she replies heartily.

			"And you, Miss Malloy.  There was somethig I wanted to ask you…"

			"At yer service," she replies.
			*gosub speak_malloy
			*goto plans_for_tomorrow
	*if heard_of_malloy and (met_malloy = false)
		#I'd like to introduce myself to Siobhan Malloy.
			It takes you a moment to locate her, but soon she emerges from the refreshment room, wiping her mouth daintily with a now-bloody handkerchief.
			*label introduce_to_malloy
			"Good evening," you begin.
			
			"Good evenin' ta ya!" she replies heartily.
			
			"Please, allow me to introduce myself.  I am ${given_name} ${surname}, a citizen of Memphis."
			
			"A pleasure, ${mr} ${surname}.  I am hopin' ta be a citizen here as well!"
			
			"Actually, that is what I wanted to talk to you about," you begin.
			
			"At yer service," she replies.
			*gosub speak_malloy
			*goto plans_for_tomorrow
	*if (heard_of_malloy = false) and (met_malloy = false)
		#The Irishwoman.
			*goto introduce_to_malloy
	*if heard_of_partridge and ((met_partridge = false) and (partridge_correspondence = false))
		#I'd like to introduce myself to Senator Partridge.
			*goto heard_of_bailey
	*if heard_of_partridge = false
		#I'd like to introduce myself to the bearded man in Colonial-era dress.
			The bearded man seems inseparable from his fair-haired companion.  Any conversation with the one will no doubt involve them both.
			
			*goto unacquainted_bailey
	*if met_chiara and (memphis_santagostino_convo = false)
		#I'd like to speak further with Senator Santagostino.
			"If I may…" you begin.  Chiara turns to greet you.

			"Oh, ${mr} ${surname}!  A pleasure to see you again."

			"And I you, Senator."

			"Tell me, what might I do for you this evening?"
			*goto speak_santagostino
	*if met_chiara = false
		*if heard_of_chiara_santagostino
			#I'd like to introduce myself to Senator Santagostino.
				*label meet_chiara
				"If I may," you begin as she turns to greet you, "allow me to introduce myself.  I am ${given_name} ${surname}."
				
				"A pleasure.  I am Chiara Santagostino, Senator of New Orleans."
				
				"New Orleans?  My dominus, ${sire_name}…"
				
				*if (sire_name = "West") and (sire_alive = false)
					*set rumors_of_west_dead true
					"I have heard of that beast."
					
					"But what of him?" you say, knowing full well that he is nothing more than ash in a Louisiana bayou.
					*goto rumors_of_west
				*if avoided_new_orleans and sire_alive
					*if sire_name = "West"
						*label chiara_speaks_of_west
						*set rumors_of_west true
						*if status > 2
							"You are the offspring of that beast?"
							
							"I am."
							
							"But, you are an upstanding member of the Society!"
							
							"I am my own vampire."
							
							"So I see."
							
							"Tell me, what news of him?"
							*goto rumors_of_west
						*else
							"I have heard of that beast.  It makes more sense now, that I would not have heard of you."
			
							@{(sire_rapport > 40) You do your best not to bristle at this dismissal of your maker.|You shrug off this barb; after all, you hold your maker in little esteem.} "But what of him?" you manage to whisper.
							*label rumors_of_west
							*set sire_question_unasked false
							
							"There are rumors that he has been driven mad."
							
							"Mad?" @{rumors_of_west_dead you sputter.  That was not the response you were expecting.|}
							
							"Alas, I know little else.  Perhaps he has simply been more removed from the Society than is typical?"
							
							"Perhaps," you reply, your world aflutter at this intelligence.
							*if rumors_of_west_dead
								What could this possibly mean?  West is dead?  What are these rumors of his madness?
					*else
						"Yes, it seems that a reputation precedes both of us.  Your dominus has spoken often of you in your absence."
			
						"Truly?  I would have thought he had forgotten me by now."
			
						"By no means, ${mr} ${surname}, by no means."
				*elseif exiled_from_new_orleans
					"I have heard of your exploits."
			
					"Oh?"
			
					"Of course.  Your departure is the stuff of legend.  We seldom have such unequivocal displays of incompetence."
					*if discretion > 70
						*if willpower > 3
							*label bristle
			
							You feel the animal inside you rise at this barb, but you manage to hold it tight.  Clenching your teeth, you think it best to change the subject.
							*goto resolve_santagostino
						*else
							*set flirting_with_chiara false
							*set frenzied_on_santagostino true
							*set second_memphis_reception_attended 5
							Your face twists into a mask of rage.  For a brief moment, you see concern cross Chiara's face as you crouch to pounce on her.
							
							Leaping towards her, you let out a snarl; the two of you fall to the ground and begin to roll through the room.  Your fingers claw at her eyes and her throat.
							
							It is only a few moments before you are torn away from her.  Carothers is livid.  You are carried bodily into another room, where you can call down.  The door is locked.
							*page_break
							*if status > 1
								*set status -1
							*set carothers_rapport %-20
							When Carothers returns, it is just before dawn.
							
							"You are not welcome here tomorrow night."
							
							*if independence > 30
								You grit your teeth.  To be denied entry to the political event of the decade is an enormous embarrassment.  Though, not at all incommensurate with your crime.
							*else
								You do your best to not seem too disinterested in this punishment.  You wouldn't want him to find a punishment befitting the name.
							
							*if maddox_status = "dead"
								"You might be interested to know, however, that Dido has spotted another of our kind in the city, one that has not made himself known to me.  He calls himself Hugh Gallagher.  If you want to have a chance at redeeming yourself in my eyes, I would suggest dealing with this interloper tomorrow.  All the better to keep you away from here.
								
								"Yes, Quaestor."
								
								"There is a man named Stennis.  Tomorrow night, he will meet you in the Pinch…"
								*page_break
								The next morning you wake and immediately throw yourself into your commission.  Once dressed with the aide of Franklin, you hurry on your way.
								*goto_scene memphis_1873_plague
							*else
								"Occupy yourself with something else.  I want you nowhere near here tomorrow night."
								
								"Yes, Quaestor."
								*page_break
								You wake up on the evening of the election to find a note waiting for you. @{literate Unfolding it, you scan the lines quickly.  One of the individuals you hired years ago to keep an eye out for ${wilson} claims to have spotted him.|You rap your fingers impatiently as you wait for Franklin to read it to you.}
								
								Of course, you cannot imagine a worse moment for ${wilson} to come crawling out of the woodwork.  Should the senators catch wind of this scandal, well,
								*if wilson_embraced
									you would never live it down.
								*elseif wilson_embraced_by_withers
									Samantha would never live it down.
								*else
									*bug
								
								Sighing deeply, you dress yourself and set out to meet your informant.  It seems that you will end up honoring Carothers' wishes tonight, regardless of your previous intentions.
								*page_break Next
								*goto_scene memphis_1873_plague
					*elseif discretion > 50
						*goto bristle
					*else
			
						*if charm > 2
							"I am glad to hear that they are still talking about me.  The worst would be if I had simply been forgotten."
			
							"No chance of that, ${mr} ${surname}.  No chance of that."
						*else
							"Do you often go about insulting people so?"
			
							"When they deserve it, yes."
			
							Gritting your teeth at her effrontery, you think it best to change the subject.
				*elseif (sire_alive = false) and (sire_name != "West")
					"Ah, yes.  
					*if new_orleans_quaestor_rapport > 60
						${new_orleans_quaestor_surname} spoke of you quite fondly.  Almost as though you were one of his own."

						"I should hope so.  I do hold him in the highest esteem."

						"As he does you."
					*elseif new_orleans_quaestor_rapport >= 40
						${new_orleans_quaestor_surname} spoke of you regularly."

						"That is interesting.  I did not know I rated so highly in his esteem."
			
						"Do not misunderstand.  His remarks are ambivalent.  Sometimes he praises you and your accomplishments, other times he seems to think that you betrayed him."
			
						"He is fickle like that."
			
						"Yes, so he is."
					*else
						${new_orleans_quaestor_surname} spoke of you regularly."
						
						"I find that surprising."
			
						"I did not say that he spoke highly of you."
			
						"No, I suppose not," you reply with a grimace.
				*else
					*if sire_name = "West"
						*goto chiara_speaks_of_west
					"Ah, yes. @{sire_formerly_quaestor Your dominus spoke regularly of you, before his departure."|Your dominus speaks regularly of you."}
			
					*if sire_rapport > 60
						"I should hope so.  I do hold him in the highest esteem."
			
						"As he does you."
					*elseif sire_rapport >= 40
						"That is interesting.  I did not know I rated so highly in his esteem."
			
						"His remarks are ambivalent.  Sometimes he praises you and your accomplishments, other times he seems to think that you betrayed him."
			
						"He is fickle like that."
			
						"Yes, so he is."
					*else
						"I find that surprising."
			
						"I did not say that he spoke highly of you."
			
						"No, I suppose not," you reply with a grimace.
				*goto speak_santagostino
		*else
			#I'd like to introduce myself to the woman from northern Italy.
				*goto meet_chiara
	*if (heresy_of_abraham > 0) and (timmers_on_heresy_of_abraham = false)
		#I use the hand-signal taught to me by Estefania, in the hopes that someone here can tell me more of the Children of Abraham.
			*set discretion %+10
			*set timmers_on_heresy_of_abraham true
			"Do the young still pass those secrets around?" whispers a voice in your ear.
			
			Turning, you lay your eyes on
			*if heard_of_timmers
				Gerard Timmers, Senator of Buffalo.
			*if heard_of_timmers = false
				a young-looking vampire, 
				*if anachronism > 60
					in clothes a few decades out of style.
				*if anachronism <= 60
					*if ethnicity = "yankee"
						in clothes which make you long for home.  He is clearly from the other side of the Mason-Dixon line.
					*if ethnicity != "yankee"
						in clothes that are stylish, if a bit Northern for your tastes.
				*comment endif
				
				"I don't believe I've had the pleasure," you say.
				
				"Gerard Timmers, Senator of Buffalo."
			*comment endif
			
			"It is an honor, sir.  As I'm sure you already know, I am ${given_name} ${surname}."
			
			He looks at you flatly.  "Allow me to impart to you what little wisdom I have earned over the past two centuries.  You will find no answer with those whom you seek.  They practice mummery and gematria, neither of which lead to any true insights."
			
			"But…" you stutter.
			
			He grabs your elbow and leads you around a corner.  "I offer you a century of experience.  This condition into which we have been thrust…there is no secret to it.  No great mystery.  We are cursed, like Job, to suffer and to watch those that we love suffer.  And we must not turn from Him, we must not curse His name, lest we spend eternity in darkness.  The Children of Abraham have nothing more profound to teach you than that, and I learned that as a child on my grandmother's knee.  Do you understand?"
			
			His eyes are no longer flat.  Instead, they have hardened, determined to batter down any resistance you might offer.
			
			"Yes, I understand," you reply.
			
			"Good.  Do not waste your time in pursuit of them.  At best it will get you killed for heresy.  At worst, you will waste even more time than I did."
			
			"Thank you, Senator."
			
			"Let your deeds thank me, ${mr} ${surname}."
			
			With that, the Senator slips away, leaving you to wonder at his words.
			*goto plans_for_tomorrow
	*if (timmers_on_heresy_of_abraham) and (timmers_details_on_abraham = false)
		#I seek out Senator Timmers, and press him for more details on the Children of Abraham.
			*set timmers_details_on_abraham true
			*set discretion %+10
			*set heard_of_ogier true
			*set knows_ogier_heretic true
			Timmers eyes you suspiciously as you approach him.  
			*if anachronism > 60
				As you approach, you note that his clothes are only a few decades out of style.
			*if (anachronism <= 60) and (ethnicity = "yankee")
				You find his choice in clothing pleasing.  He clearly hails from north of the Mason-Dixon line.
			*if (anachronism <= 60) and (ethnicity != "yankee")
				You find his choice in attire pleasing, if a bit Northern for your tastes.
			*comment endif
			
			"Senator, if I may…" you begin.
			
			"You must be ${mr} ${surname}."
			
			"I am.  It is an honor to meet you, Senator.  If I may…"
			
			"You must be very occupied with your duties in this city.  What with it growing in importance so."
			
			"Yes, I do find myself occupied.  But…"
			
			"I cannot recommend enough that you busy yourself with such things, rather than pursuing other…more fruitless…ones."
			
			You pause.  "Fruitless?"
			
			"Take it from one who has grown disillusioned after too many decades spent in the pursuit of something which was already revealed to us.  There are no secrets to be found amongst the Children.  They are misguided fools.  Soon they will all end up staked and left for the sun, not unlike M. Ogier."
			
			"You speak from experience?"
			
			Timmers draws up stiffly, suddenly suspicious.  "I said that I spoke from disillusionment. Now, if you will excuse me…" he says, cutting you off from further inquiry.
			*goto plans_for_tomorrow
	*if (heresy_of_masons > 0) and (mason_sign_in_memphis = false)
		#I use the hand-signal of the Masons, in the hopes of finding another member of the Order.
			*set mason_sign_in_memphis true
			*if (pickering_out = false) and (knows_pickering_mason = false)
				*if (pickering_rapport > 40) or (revolutionary_credentials < 40)
					*set knows_pickering_mason true
					*if (ethnicity = "african") or (ethnicity = "choctaw")
						*set pickering_bigot true
						To your consternation, someone does respond to your gesture.  Taking you by the elbow, Absalom Pickering manages to arrange a word in semi-private with you.

						"Who dared admit you to our Order?" he demands.  This was not quite the greeting you had anticipated.

						"It is a family affair…" you stammer.

						"Of course.  Some have taken these notions of equality too far."

						"Too far?"

						"Admitting those taken from the lesser races.  It is disgusting."  You look at him with shock.  He continues before you can reply.  "Do not be so flagrant in your display of the sign.  If you jeopardize the Order, I shall make your whole lineage regret your introduction to it."

						With that, he turns on his heel and departs.
						*goto plans_for_tomorrow
					*else
						To your delight, someone does respond to your gesture.  Taking you by the elbow, Absalom Pickering manages to arrange a word in semi-private with you.

						"It is good to make your acquaintance, brother," he begins.

						"And I yours," you reply.  "Please, if you have need of me while you are in my city…"

						"Only that you do everything in your power to assure my victory here."

						Seeing no other possible response, you reply: "Of course, brother."

						The two of you part ways quickly, before you draw too much attention to yourselves.  Were you still alive, your heart would no doubt be beating with excitement at the discovery of a fellow conspirator.
						*goto plans_for_tomorrow
				*elseif perception > 3
					*set knows_pickering_mason true
					You are disappointed that no one overtly responds to your gesture.  However, you feel as though Absalom Pickering recognizes the gesture, but elects to ignore it.  To be generous, you have made your opposition to him clear.
					*goto plans_for_tomorrow
				*else
					Unfortunately, no one seems to recognize the signs.  Or, at least, no one returns the counter-sign.
					*goto plans_for_tomorrow
			*if (pickering_out = false) and (knows_pickering_mason)
				You make sure to keep your gestures out of the sight of Absalom Pickering, lest he disapprove of your search for other members of the Order.  Unfortunately, no one else in the gathering seems to recognize your secret signs.
				*goto plans_for_tomorrow
			*else
				Unfortunately, no one seems to recognize the signs.  Or, at least, no one returns the counter-sign.
				*goto plans_for_tomorrow
	*selectable_if (discretion > 40) #I campaign to become the Senator of Memphis.
		*set discretion %+20
		*set player_for_senator true
		*set seat_num +1
		*if revolutionary_credentials > 60
			*if malloy_out
				*set lesczynski_rapport %-30
				*set revolutionary_credentials %+20
				When you announce your intentions, the gathered supporters of Consul Stone seem to welcome it.  Their [i]de facto[/i] support of Lesczynski may very well swing your way.
				*goto plans_for_tomorrow
			*elseif (status > 2) or (charm > 3)
				*set malloy_rapport %-30
				When you announce your intentions, the gathered supporters of Consul Stone seem to welcome it.  Siobhan, on the other hand, is clearly displeased by the news.   You have no doubt that she will do everything in her power to sink your candidacy.
				*goto plans_for_tomorrow
			*else
				*set bailey_rapport %-10
				Senator Bailey looks at you askance.  "We have a candidate already.  There is no need for you to muddy the waters."

				"Muddy the waters?"

				"Your presence would imply dissension within our ranks.  It may discourage some of the more persuadable from holding the line."

				"What are you saying?"

				"I am saying that your candidacy would hinder the cause.  I demand that you withdraw your candidacy immediately."
				*choice
					#"Yes, Senator."
						"Good.  Now, enough of this matter.  There is still much to be done before tomorrow."

						"Of course, Senator."
						*goto plans_for_tomorrow
					#"I refuse to withdraw."
						*set bailey_rapport %-20
						*set player_for_senator false
						The words hang in the air while Bailey's eyes harden.  "Very well," he replies.

						Feeling the sudden need to leave his presence, you do so.  As you turn, you sense that it is not only Bailey who stares at you with malice.
						*goto plans_for_tomorrow
		*elseif revolutionary_credentials < 40
			*if pickering_out
				*set revolutionary_credentials %-20
				*set lesczynski_rapport %-30
				When you announce your intentions, the gathered loyalists seem to welcome it.  Their [i]de facto[/i] support of Lesczynski may very well swing your way.
				*goto plans_for_tomorrow
			*elseif (status > 2) or (charm > 3)
				*set pickering_rapport %-30
				When you announce your intentions, the gathered loyalists seem to welcome it.  Absalom, however, is clearly displeased by the news.  You have no doubt that he will do everything in his power to sink your candidacy.
				*goto plans_for_tomorrow
			*else
				*set lockridge_rapport %-10
				Senator Lockridge looks at you askance.  "We have a candidate already.  There is no need for you to muddy the waters."

				"Muddy the waters?"

				"Your presence would imply dissension within our ranks.  It may discourage some of the more weak-willed from holding the line."

				"What are you saying?"

				"I am saying that your candidacy would hinder the cause.  I demand that you withdraw your candidacy immediately."
				*choice
					#"Yes, Senator."
						"Good.  Now, enough of this matter.  There is still much to be done before tomorrow."

						"Of course, Senator."
						*goto plans_for_tomorrow
					#"I refuse to withdraw."
						*set lockridge_rapport %-20
						*set player_for_senator false
						The words hang in the air while Bailey's eyes harden.  "Very well," he replies.

						Feeling the sudden need to leave his presence, you do so.  As you turn, you sense that it is not only Bailey who stares at you with malice.
						*goto plans_for_tomorrow
		*else
			Your announcement is met with some confusion.  Your lack of allegiance means that no one knows whether to laugh or to tremble.

			Upon reflection, you are not sure either.
			*goto plans_for_tomorrow
	*if (malloy_out = false) and (heard_of_malloy)
		#I agitate for Siobhan Malloy.
			*set revolutionary_credentials %+10
			*set bailey_rapport %+10
			*set malloy_rapport %+10
			*set lockridge_rapport %-10
			*set pickering_rapport %-10
			*set lesczynski_rapport %-10
			You make your rounds through the room, offering words of support for Malloy.  Unfortunately, it seems as though most of the gathered vampires have already made up their minds.
			*goto plans_for_tomorrow
	*if (pickering_out = false) and (heard_of_pickering)
		#I agitate for Absalom Pickering.
			*set revolutionary_credentials %-10
			*set bailey_rapport %-10
			*set malloy_rapport %-10
			*set lockridge_rapport %+10
			*set pickering_rapport %+10
			*set lesczynski_rapport %-10
			You make your rounds through the room, offering words of support for Pickering.  Unfortunately, it seems as though most of the gathered vampires have already made up their minds.
			*goto plans_for_tomorrow
	*if heard_of_lesczynski and (lesczynski_out = false)
		#I agitate for Ascher Lesczynski.
			*set coffin_rapport %-20
			*set lesczynski_rapport %+10
			*if malloy_out
				*set revolutionary_credentials %+15
				*set bailey_rapport %+10
				*set malloy_rapport %+10
				*set lockridge_rapport %-10
				*set pickering_rapport %-10
				You make your rounds through the room, offering words of support for Lesczynski. Unfortunately, it seems as though most of the gathered vampires have already made up their minds.
				*goto plans_for_tomorrow
			*elseif pickering_out
				*set revolutionary_credentials %-15
				*set bailey_rapport %-10
				*set malloy_rapport %-10
				*set lockridge_rapport %+10
				*set pickering_rapport %+10
				You make your rounds through the room, offering words of support for Lesczynski. Unfortunately, it seems as though most of the gathered vampires have already made up their minds.
				*goto plans_for_tomorrow
			*else
				*set bailey_rapport %-10
				*set malloy_rapport %-10
				*set lockridge_rapport %-10
				*set pickering_rapport %-10
				You make your rounds through the room, offering words of support for Lesczynski. Unfortunately, it seems as though most of the gathered vampires have already made up their minds.  And none of them seem to agree with you.
				*goto plans_for_tomorrow
	#I seek news of ${wilson}.
		*set discretion %+10
		*set independence %+10
		The gathered vampires are horrified by the little bit that you share about the errant ${wilson}.  
		*if (malloy_rapport > 50) and (malloy_out = false) 
			*if (maddox_status = "dead") or bounty_on_hugh
				You have about given up hope of learning anything when Siobhan Malloy takes you aside and confirms that she has seen ${a_one_eared_freedman} in the Pinch.  She looks a tad sheepish that she should frequent such a section of town, but you put her at ease by focusing on the facts of the matter.
				*if heard_about_bounty_on_hugh
					She reminds you about the bounty on his head.  His death is still a matter of interest to the Quaestor of New-York.
					*goto plans_for_tomorrow
				*else
					*set heard_about_bounty_on_hugh true
					She informs you that the Quaestor of New-York has placed a bounty on the head of Hugh Gallagher.  She intimates that you would be well compensated for your trouble.
					*goto plans_for_tomorrow
			*else
				You have just about given up hope of learning anything, when Siobhan Malloy takes you aside, and confirms that she has seen ${a_one_eared_freedman} in the Pinch.  She looks a tad sheepish that she should frequent such a section of town, but you put her at ease by focusing on the facts of the matter.
				
				You thank her for this intelligence and promise to make good use of it.
				*goto plans_for_tomorrow
		*if (maddox_status = "dead") and ((timmers_rapport > 40) and (bounty_on_hugh = false))
			Senator Timmers speaks up, informing you that a bounty has been placed on the head of this Hugh Gallagher by the Quaestor of New-York.  He implies that the vampire who does this deed will be well-compensated.
			
			You are surprised by this bit of news and promise to take it into consideration.  
			*if timmers_contactable = false
				He offers you a way to contact him, should your endeavors bear fruit.
				*set timmers_contactable true
			*goto plans_for_tomorrow
		*else
			Unfortunately, no one offers any new information for you.
			*goto plans_for_tomorrow
	*if overheard_treatment_vessels
		*selectable_if (compassion < 70) #I investigate Senator Bowater's complaints about the condition of the refreshments.
			*set discretion %+5
			*set compassion %-5
			*goto investigate_conditions
	*selectable_if (compassion > 30) #I indulge in the refreshments.
		*set compassion %+10
		*label investigate_conditions
		Slipping away into another room, you find the gathered humans cowering in fear.  The room stinks of urine and feces, and the wails of the women grate on your ears when they become aware of your presence.
		*if acquiring_vessels_1877 = "success"
			*if compassion < 50
				This is not how you imagined the captives would be treated.  
				*if first_memphis_reception_attended = 1
					Four years ago, they were confined, yes, but treated with some amount of dignity.  You assumed when you took on this task that they would be treated similarly.  What you see before you, however, is a disgrace.
				*label vessel_choice
				*choice
					#I drink my fill and return to the soirée.
						*set compassion %+10
						They moan when you approach but offer no resistance. @{(perception > 2) Unfortunately, the [i]terroir[/i] is somewhat ruined by the conditions.|}
						
						When you are finished, you clean your face and return to the gathering.
						*goto plans_for_tomorrow
					#I cannot bring myself to partake.
						*set discretion %-10
						*set compassion %-5
						You turn, doing your best not to flee from the cries for mercy that follow you back to the hall.
						*goto plans_for_tomorrow
					*selectable_if (discretion > 50) #I put these sorry creatures out of their misery.
						*set discretion %+10
						*set compassion %+10
						*set carothers_rapport %-20
						You find a weapon and begin executing the captives one by one.
						
						Their screams and wails rise to a fever pitch.  You raise your hand to bring your weapon down on the head of some old man for a third and final time when a fist closes over yours.  "That is enough, ${mr} ${surname}," says the gravelly voice of Carothers.
						
						You look at him blankly.  "I could not stand to see them suffer so."
						
						"They will rest soon enough.  Go home."
						
						"Yes, Quaestor," you reply.  You turn and walk away.  Behind you, you hear Carothers put the old man out of his bubbling misery.
						
						Shrieks follow you down the hall.  You do your best to push them from your thoughts.
						*page_break
						*label leave_solitaire
						You leave without saying goodbye to anyone.  You hasten home, alone with your thoughts.
						
						*goto plans_for_tomorrow_2
					*if priest
						#I offer the last rites to the dying.
							*set rationalism %+10
							*set compassion %-10
							*set discretion %-10
							Several take you up on the offer, and they seem comforted by your small act of kindness.
							
							Your duty done, you turn and return to the gathering, doing your best to ignore the sobs and moans that follow you back to the hall.
							*goto plans_for_tomorrow
					*selectable_if (compassion < 60) #I confront Carothers about the treatment of these mortals.
						*set discretion %+10
						*set compassion %-10
						*if status >= 2
							*comment TODO Dido intervene if you have a high enough relationship? Or what if you have Status?
							*set carothers_humanity -1
							*set applethorp_rapport %+10
							*set bowater_rapport %+15
							Carothers looks like he swalled an egg whole. Which must have been a goose egg, considering the size of his neck.
							
							Through gritted teeth, he nods. "Yes, perhaps we could take better care of them next time."
							
							You pause. Did you just…win a concession?
							*goto plans_for_tomorrow
						*else							
							"Now is not the time to discuss this, ${mr} ${surname}," Carothers hisses through clenched teeth.
	
							"Then when is the time?" you demand.
	
							"After the caucus is over."
	
							"And will you listen…"
	
							"Enough.  This night is over for you.  Leave here, now, before you anger me any further."
	
							Looking into his eyes, you decide it best to listen to him.
							*page_break
							*goto booted_epilogue
			*else
				*if first_memphis_reception_attended = 1
					It seems that Carothers is no longer wasting his time coddling the chattel.  So much the better for him.
				*else
					It surprises you a little that Carothers would treat the chattel with so little regard, but so much the better for him.
				*if perception > 2
					Unfortunately, the [i]terroir[/i] is somewhat ruined by the circumstances.
				*comment endif
				
				You drink your fill and return to the soirée.
				*goto plans_for_tomorrow
		*else
			*if first_memphis_reception_attended = 1
				*if compassion < 60
					This is not how things were done four years ago.  Four years ago, they were confined, yes, but treated with some amount of dignity.  What you see before you is a disgrace.
					*goto vessel_choice
				*else
					*label indifferent_to_vessel_condition
					It seems that Carothers is no longer wasting his time coddling the chattel.  So much the better for him. @{(perception > 2) Unfortunately, the [i]terroir[/i] is somewhat ruined by the circumstances.|}
					
					You drink your fill and return to the soirée.
					*goto plans_for_tomorrow
			*else
				*if compassion < 60
					For some reason, you had expected better from Carothers.  You did not realize he could be so…inhuman.
					*goto vessel_choice
				*else
					*goto indifferent_to_vessel_condition

*label speak_ashmore
*comment 10
*set interlocutors +1
*set met_ashmore true
*gosub check_senators_achieve
*label speak_ashmore_loop
*set questions +1
*choice
	*if (draper_convo = false) #"Are there any other vampires that you would have expected to put themselves forward for Senator?"
		*set independence %+3
		*set questions -1
		*set draper_convo true
		"John Draper."
		
		*if met_draper
			"Oh? Why John?"
		*elseif heard_of_draper
			"I've not met the man."
			
			"An inveterate gambler."
			
			"So I've heard. Why him?"
		*else
			*set heard_of_draper true
			"Who?"
			
			"John Draper. An inveterate gambler that frequents my dominus's court."
			
			"I haven't heard of him."
			
			"I'm surprised."
			
			"Why him?"
		
		"A vampire of a certain age, committed to Stone's revolution, without a current position of stature…he would have been a natural candidate."
			
		"Do you know why he's not here?"
		
		"I do not."
	#"Were you present at the election of Senator Santagostino?"
		*set revolutionary_credentials %+5
		*set independence %+5
		*set ashmore_rapport %+5
		"I was, as a matter of fact."
		
		"Was her election this…fractured?"
		
		"Not at all.  Obviously, Stone had not yet made his move.  Santagostino was the eldest of the candidates, and her pedigree is most esteemed.  Her dominus is the governor of one of the Italian cities, if I recall."
		
		"And how many senators were present?"
		
		"Eleven?  Twelve?  Stone himself was there…he was still a senator, after all."
		
		"Unfortuante that I was not present."
		
		*if status = 0
			*set ashmore_rapport %-5
			"You would not have been admitted had you 
			*if sire_formerly_quaestor or (sire_alive and (sire_name != "West"))
				been present, regardless of your dominus.  I'm somewhat surprised that Carothers allowed you to attend this reception, but what else can one expect from such a peripheral domain?"
				
				You bite your tongue before it provokes your removal from the premises.
			*else
				been. I'm suppose I shouldn't be surprised that Carothers allowed you to attend this reception, for what else can one expect from such a peripheral domain?"
				
				You bite your tongue before it provokes your removal from the premises.
		*else
			"You would have witnessed a much more elegant election.  Lockridge was premature in calling for the Senate to elect a senator for Memphis if he did not have the votes."
			
			"Will he suffer any repercussions?"
			
			"Only if the vote goes against him.  If a supporter of Stone is elected, it will be that much more challenging during the next election.  This really is pivotal."
			
			"I must thank you for these insights, Senator," you say.
	*if great_swap and heard_of_townsend
		#"What do you think of Philadelphia?"
			*set ashmore_rapport %+10
			*set independence %+5
			Ashmore sighs deeply.  "I must admit, I miss Savannah."
			
			"But the court of Governor Townsend must be magnificent?"
			
			"I have seen the courts of London and Paris.  Philadelphia is a provincial backwater in comparison."
			
			"I shudder to consider what you must think of Memphis, then."
			
			"You are right…it is best not to ask," she sniffs.
	*if (heard_of_quarrington = false) and (heard_about_great_railroad_strike)
		#"What of the railroad strikes?  Were you worried about making the journey here?"
			*set discretion %+10
			*set ashmore_rapport %+5
			*set heard_of_quarrington true
			"Dreadful, I tell you.  Simply dreadful.  And poor Quaestor Quarrington."

			"Quaestor Quarrington?"

			"Yes, he was slain during the strike."

			"Quaestor of what city?"

			"Cumberland, Maryland.  He really was so hospitable to me whenever I needed to cross those wretched mountains.  Of course, things are so much easier now with the railroads; it used to be an absolutely dreadful experience."

			"He was slain?"

			"Yes.  A mob of those horrible workingmen stormed his home and burnt him to ash."

			"That is dreadful!"
	*if great_swap = false
		#"…I imagine it's not a coincidence that you are a Senator and your dominus a Governor?"
			*set great_swap true
			*set heard_of_townsend true
			She smiles thinly at you.  "You are astute, ${mr} ${surname}.  When it came time for Senators to be elected for Philadelphia and Savannah, Governor Townsend and my dominus came to an understanding: Abel Bowater would become the Senator of Savannah, and I the Senator of Philadelphia."

			"It is curious that you are so forthright about these arrangements.  I would one would be more circumspect about their rise to power.
			"

			"Alas, everyone else already knows.  I see no reason to leave you alone in the dark."

			"It is kind of you to take pity on me, Senator."
	*if ashmore_position = false
		#"…what do you think of the deeds of Isaiah Stone?"
			*set ashmore_position true
			"Murdering Miele you mean?  Good riddance."

			"So you support him?"

			"I didn't say that.  I said good riddance to Praetor Miele.  He was insufferable."

			"You knew him?"

			"Of course I did.  He was a fixture of the Society, traveling throughout its courts seeking heretics."

			"So you don't support Mr. Stone?"

			*if ashmore_revolutionary
				"I didn't say that either," she says with a smile.

				You try not to show your frustration.

				"I am not convinced by him," she continues, "but I am open to seeing where this course of events takes us."
				*if revolutionary_credentials > 60
					*set ashmore_rapport %+10
					She offers you a conspiratorial smile with this observation.
				*comment endif

				You suppose that, for a sitting Senator and progeny of a Governor, that is about as committed of a response you are going to get.
			*else
				"I didn't say that either," she says with a smile.

				You try not to show your frustration.

				"I am not convinced by him," she continues, "and I imagine that his efforts will eventually be reversed.  Of course, I cannot guarantee such a thing…"
				*if revolutionary_credentials < 40
					*set ashmore_rapport %+10
					She offers you a conspiratorial smile with this observation.
				*comment endif

				You suppose that, for a sitting Senator and progeny of a Governor, that is about as committed of a response you are going to get.
	*if ashmore_position and why_revolt
		#"If Stone's revolution endures, how do you think the Society will change?  What does is he fighting for?"
			*set why_revolt false
			*set discretion %+10
			Senator Ashmore pauses a moment to consider before answering.  "I suspect that Stone's supporters believe that questions of our past—and our future—will be more open to public discussion."
			
			"Questions of our past and future?"
			
			"Where did we come from?  What is our purpose?  What is our destiny?  These questions are rarely asked or debated in the Society, for fear that a Praetor will interpret one's answers as heretical.  Sure, there is the debate over Eusebius's [i]Of Shepherds and Wolves[/i], but that debate does not address begin to answer these questions."
			*set heard_of_eusebius true
			*set heard_of_shepherds_and_wolves true
			
			"And will the Society make space for such debates under Stone's leadership?"
			
			*if sire_name = "Padre Carlos"
				She looks you squarely in the eyes before answering.  "Perhaps that question would be better posed to your dominus, ${mr} ${surname}."
				
				"Yes, yes…of course," you reply.
			*else
				*set heard_of_carlos true
				"One of his first acts as Consul was to name a former inquisitor by the name of Padre Carlos to be his new Praetor.  I leave you to draw your own conclusions."
				
				"I will think on that, Senator," you reply.
	*if (lesczynski_out = false) and (heard_of_lesczynski)
		#I urge her to support Mr. Lesczynski.
			Senator Ashmore listens to your encouragements impassively.  When you have finished, 
			*if malloy_out
				*set revolutionary_credentials %+20
				*if ashmore_revolutionary
					*set ashmore_rapport %+20
					she falls silent for a time, before confiding in you that you have convinced her.  She will support Mr. Lesczynski for the position.
				*else
					*set ashmore_rapport %-10
					she pauses to consider her words carefully.  "I'm afraid my support is already promised to Mr. Pickering, ${mr} ${surname}.  I do appreciate your concern, however…"  It seems that your words have fallen on deaf ears.
			*elseif pickering_out
				*set revolutionary_credentials %-20
				*if ashmore_revolutionary
					*set ashmore_rapport %-10
					she pauses to consider her words carefully.  "I'm afraid my support is already promised to Miss Malloy, ${mr} ${surname}.  I do appreciate your concern, however…"  It seems that your words have fallen on deaf ears.
				*else
					*set ashmore_rapport %+20
					she falls silent for a time, before confiding in you that you have convinced her.  She will support Mr. Lesczynski for the position.
			*else
				*set ashmore_rapport %-10
				she pauses a moment, considering her words carefully.  "This affair is already hopelessly confused, and you would have me confuse it further by supporting an individual for whom there is no organized support?"

				"You could be the source of that support, Senator…"

				"I would prefer to be on the winning side, ${mr} ${surname}.  Not the quixotic one."
	*if (malloy_out = false) and (heard_of_malloy)
		#I urge her to support Miss Malloy.
			Senator Ashmore listens to your encouragements impassively.  When you have finished, she 
			*set revolutionary_credentials %+20
			*if ashmore_revolutionary
				*set ashmore_rapport %+20
				falls silent for a time, before confiding in you that you have convinced her.  She will support Miss Malloy for the position.
			*else
				*set ashmore_rapport %-10
				pauses to consider her words carefully. "I'm afraid my support is already promised to Mr. Pickering, ${mr} ${surname}.  I do appreciate your concern, however…"  It seems that your words have fallen on deaf ears.
	*if (pickering_out = false) and (heard_of_pickering)
		#I urge her to support Mr. Pickering.
			Senator Ashmore listens to your encouragements impassively.  When you have finished, she 
			*set revolutionary_credentials %-20
			*if ashmore_revolutionary
				*set ashmore_rapport %-10
				pauses to consider her words carefully. "I'm afraid my support is already promised to Miss Malloy, ${mr} ${surname}.  I do appreciate your concern, however…"  It seems that your words have fallen on deaf ears.
			*else
				*set ashmore_rapport %+20
				falls silent for a time, before confiding in you that you have convinced her.  She will support Mr. Pickering for the position.
*if questions > 1
	"Now, if you will excuse me, ${mr} ${surname}, I feel the sun beginning to rise…"

	"Yes of course, Senator.  It's been a pleasure."

	"Yes, a pleasure," she concludes.
	*return
*else
	A pause in the conversation leaves you with the opportunity to ask another question.
	*goto speak_ashmore_loop

*label speak_coffin
*comment 5
*set interlocutors +1
*set met_coffin true
*set memphis_coffin_convo true
*gosub check_senators_achieve
*label speak_coffin_loop
*set questions +1
*choice
	*if discovered_telepathy
		#"Tell me, do many of our kind possess a power such as yours?" you think at her.
			*set discretion %+2
			*if speaks_english = false
				Her voice rings out clearly in your mind.
			"I cannot say.  We are not known for freely divulging the extent to which the decades have benefited us."
			
			"But, someday I may develop such power?"
			
			"I imagine it is possible, yes.  But it will no doubt take centuries."
			
			You do your best not to seem crestfallen at this statement.  Of course, she can probably "hear" it all the same.
	*if rebuffed_by_harding and ((heard_of_harding = false) and (rebuff_query = false))
		#"When I tried to introduce myself to @{heard_of_harding Quaestor Harding|that woman in the fashionable dress}, she was very rude…"
			*if heard_of_harding
				"Yes, I saw.  As did everyone else."
			*else
				*set heard_of_harding true
				"Quaestor Harding?"
				
				"I cannot say."
				
				"It was; I saw the exchange.  As did everyone else."
			
			*set rebuff_query true
			*set harding_bigot_known true
			"Did I offend her?"
			
			"The color of thy skin offends her, ${mr} ${surname}."
			
			*if compassion > 60
				"She still maintains such mortal prejudices?"
				
				"Immortality afflicts us all differently.  But do not forget the identity of her broodmate."
				
				"Quaestor Carothers?"
				
				"Thou may imagine the love they share."
				
				*if jesse_is_broodmate and (jesse_rapport > 55)
					"That is unfortunate for them.  One's broodmates should be one's closest confidantes."
					
					"Not all vampires have such a high opinion of their kin."
					
					"So I am beginning to see, Senator."
				*else
					"I can only imagine."
			*elseif compassion >= 35
				"While her commitment to her humanity is admirable, perhaps there is more to it than retaining one's hatreds."
				
				You think you might have made Coffin laugh.  It sounds more like a cough, though.  "Thou speaks truly, ${mr} ${surname}."
			*else
				"How abhorrent.  She is gifted with immortality and squanders it on things which cannot be changed."
				
				"But thou could die."
			
				"Let us not consider such a possibility, Senator."
	*if (memphis_chance_encounter != "coffin") or ((memphis_chance_encounter = "coffin") and (knows_coffin_anti_semitic = false))
		#"What do you think of the candidates for the election?"
			*set heard_of_lesczynski true
			*set knows_coffin_anti_semitic true
			"Mr. Lesczynski passed through Cincinnati recently.  Though there was no formal announcement of such—as it would be crass—I expect that he was seeking to garner my support.  He lavished several gifts upon me."
	
			"And what did you think of him?"
	
			"He is a Jew.  What more need be said?"
	
			*if (religious_tradition = "pagan") and (discretion >= 40)
				*set coffin_rapport %-10
				"I suppose you cannot hang that particular albatross around my neck."
				
				"Excuse me?"
				
				"I can't imagine what you must think of my people and their faith."
				
				Coffin looks down her nose at you.  "Barbarians.  Your people have already been chased across the Mississippi.  It will not be long before the last of you has been hunted down and exterminated."
				
				"I appreciate your candor, Senator," you say, before excusing yourself. @{speaks_english |You feel her presence leave your mind as you walk away.}
				*return
			*elseif priest and (discretion > 35)
				*set coffin_rapport %-10
				"I suspect that you would also be disappointed were I to be elected?"
				
				She glances down to your priest's collar and then meets your eyes again.  "Better a papist than a Jew, I suppose" she muses aloud.
				
				"Thank you for that vote of confidence, Senator," you say, before excusing yourself.
			*elseif (religious_tradition != "pagan") and ((rationalism > 65) and (compassion < 35))
				*set coffin_rapport %+10
				"A Christkiller must not be allowed to take a seat in the Senate!"
	
				"Unfortunately, it would not be the first time such had occurred, but I do appreciate thy sentiments, ${mr} ${surname}."
	
				"Whatever I can do to aide you in preventing this…"
	
				"I may very well accept thine offer, ${mr} ${surname}."
	
				"I am at your service, Senator."
				*set offer_to_help_coffin_stop_ascher true
			*elseif (rationalism < 50) and ((discretion > 50) and (compassion < 50))
				*set coffin_rapport %-10
				"You say that as though it should disqualify him for the position, Senator."
	
				"As well it should."
	
				"For practicing a different faith?"
	
				"For bearing the blood of the Christ on his hands."
	
				"But, he does not…"
	
				"His people put Our Lord to death.  All of their kind bear the responsibility for that crime.  If thou canst not recognize that, I am afraid we have nothing more to discuss."
			*elseif discretion < 40
				*set coffin_rapport %+2
				"And it would be disastrous were a Jew to join the Senate?" you venture.
	
				"Unfortunately, if has happened before.  But I am loath to see it happen again."
	
				"Well, I appreciate your insight into this."
			*else
				*set coffin_rapport %-2
				"I see."
	
				Abigail seems to catch herself before embarking upon a rant.  "If that means nothing to thee, I suppose thou must simply await the consequences of such an event."
	*else
		#"What do you think of the other candidates?"
			*set heard_of_malloy true
			*set heard_of_pickering true
			"That Irishwoman," the words coming to her mouth with such distaste that you imagine the Senator wishes she could still spit something of consequence, "is an outspoken supporter of the rebellion.  You can see her there," she says, nodding towards Siobhan Malloy, "sticking out like the spoiled brat that she is."
			
			At this very moment, a merry smile has just graced Malloy's lips.  She seems enchanting, if you do say so yourself.
			
			"Which leaves Mr. Pickering as the only option."
			*choice
				#"But what of my candidacy?"
					*set discretion %+15
					*set independence %+5
					*if (coffin_rapport > 60) or (status > 2)
						*set player_for_senator true
						*set seat_num +1
						"That is an interesting thought, ${mr} ${surname}.  See what other support you can garner, and we shall see what unfolds tomorrow."
						
						"Yes, Senator."
					*else
						"Jests on such serious matters are inappropriate to the circumstances, ${mr} ${surname}."
						
						"But I…"
						
						"Of course it was a jest.  Who could take you seriously as a candidate?  You have nothing to recommend you, and no Senators supporting you."
						
						You do your best not to appear crestfallen.
				#"But what of the candidacy of Mr. Whitaker?"
					*set independence %+5
					*if jesses_revolutionary_credentials > 60
						*set coffin_rapport %-5
						The Senator's eyes go wide at this.  "Mr. Whitaker is no better than the Malloy woman.  His affiliation with the rebellion is well-known, and that is unacceptable."
						
						"I did not realize he was so affiliated."
						
						"Thou had best pay better attention to the whispers of the Society, ${mr} ${surname}."
					*elseif jesses_revolutionary_credentials >= 40
						She wrinkles her nose at this.  "Mr. Whitaker is too much of an unknown.  He has yet to make his allegiance clear, and I will brook no confusion on that front."
						
						"But, if he were to make clear his opposition to Stone…"
						
						"Then I would give it some consideration, yes."
					*else
						*set jesse_for_senator true
						*set coffin_rapport %+5
						Her eyes brighten at this suggestion.  "Why, what a thought thou has, ${mr} ${surname}.  Mr. Whitaker's allegiance to Adonis is well-known, and he is so much more interesting than that Pickering fellow."
						
						"You will support him, then?"
						
						"I shall certainly give it some thought."
				#"Are there other qualities to recommend Mr. Pickering?"
					"There are.  He has made his opposition to Stone clear."
					
					"Is that not a dangerous position, to oppose the Consul?"
					
					"Only if he loses."
	*if offer_to_help_coffin_stop_ascher
		#"How are we to stop Mr. Lesczynski?"
			*set coffin_rapport %+5
			"For the time being, ${mr} ${surname}, thou must only attend to the ebb and flow of the election.  The opportunity to one so unconnected as yourself to influence events will only arrive through patience."
			
			"I see."
			
			"Thou must learn as much as thou can of the other Senators, their hopes and fears.  Through these things, thou may gain power over them."
	#"Do you think mortals should be managed by us, or simply used?"
		*if shepherds_and_wolves
			*set discretion %+5
			"I have struggled with that very question, ${mr} ${surname}."

			"And have you come to any answer?"
		*elseif heard_of_shepherds_and_wolves
			*set shepherds_and_wolves true
			"Am I to understand that thou ask whether I consider myself a shepherd or a wolf?"
			
			"I have heard these terms before—and I have some sense as to their meaning—but perhaps you could elaborate further?"
			
			"It comes from an old dialogue, but the idea is useful enough, I suppose."
			
			"And what of it?"
			
			"To tend the mortals, or to take from them as suits us. Shepherds and wolves."
			
			"And how would you answer the question, then?"

			"I have struggled with this matter, ${mr} ${surname}."

			"And what has been the result?"
		*else
			*set shepherds_and_wolves true
			*set heard_of_shepherds_and_wolves true
			"Am I to understand that thou ask whether I consider myself a shepherd or a wolf?"

			"A what…or a…what?"

			"A shepherd or a wolf.  The two philosophies by which our kind exist.  To tend the mortals, or to take from them as suits us."

			"There is a name for this?"

			"There is."

			"And how would you answer the question, then?"

			"I have struggled with this matter, ${mr} ${surname}."

			"And what has been the result?"
			
		"So often, the mortals are at cross-purposes to myself, and yet, I cannot bring myself to completely discount their needs."

		"A reluctant shepherd, then?"

		"Yes, I suppose thou could call me such.  And thee?  How does thou think they ought to be treated?"
		*choice
			#"I think we must be involved with them, lest they destroy themselves."
				*set shepherd_credentials %+10
				*set coffin_rapport %+10
				"Yes, they are inclined towards self-destruction.  It is amazing they have survived as long as they have."  You wonder if she is often this generous to other young vampires.
			#"No, I believe they can take care of themselves, and are there for our use."
				*set shepherd_credentials %-10
				"I can certainly see the appeal of your position, ${mr} ${surname}," she replies.
			#"Like you, I am—as of yet–uncertain."
				*set coffin_rapport %+5
				She actually smiles at you.  "I suppose I cannot judge thee harshly for your indecision, when I am guilty of the same."  You wonder if she is often this generous to other young vampires.
	#"How did you become Senator of Cincinnati?"
		*set discretion %+5
		*set coffin_rapport %+10
		*set heard_of_townsend true
		"It was a natural progression.  The city has grown dramatically since it was founded.  I relocated there when work on the canal began, and was soon named Quaestor by Governor Townsend.  By the time the canal was completed twenty years later, the city had grown in importance such that a Senator was deemed necessary."
		
		"And you were elected?"
		
		"I was.  It was a small caucus, smaller than this one in fact."
		
		"I see.  Thank you for enlightening me, Senator," you reply.
	*if (intelligence > 1) #"Were you familiar with Quaestor Quarrington?"
		*set questions -1
		*set independence %+5
		"Giles? Yes, he and I were acquainted."

		"Do tell," you prompt.

		"He was a bitter old vampire. It's almost a good thing that he is gone…he had long since lost touch with modern times. He had a house built in the hills above the town that could have been a Renaissance castle."

		"He lived in a castle?"

		"He did. And because of the problems with the railroad, he would invite vampires trying to cross the mountains to stay with him at it for a time."

		"How strange?"

		"I suppose. But he used the opportunity extract all manner of gossip from. He often seemed one step ahead of everyone on the continent, as so many people came through and stayed as his guest."

		"Yet, you are not saddened by his demise?"

		"I am saddened only to the degree that it reminds me of mine own impending demise."

		"His death reminds you of your own?"

		She looks at you askance. "Isn't that what all mourning is? The recognitin of your own insignificance?"

		"I can't say I had looked at it that way before, Senator."
		
*if questions > 1
	"Now, if you will excuse me, ${mr} ${surname}, the dawn approaches, and I must bid you farewell."
	
	"Goodnight, Senator."
	*if speaks_english = false
		You feel her presence leave your mind.
	*return
*else
	A pause in the conversation leaves you with the opportunity to ask another question.
	*goto speak_coffin_loop

*label speak_fragala
*temp knows_fra_rev false
*temp knows_palermo false
*if second_memphis_caucus_attended
	*hide_reuse
	*temp questions 0
	*temp interlocutors 0
	*temp knows_leper false
*set met_fragala true
*label fragala_loop
*set questions +1
*set interlocutors +1
*choice
	#"Are you…a Senator?"
		*set independence %+5
		*if knows_palermo
			Fragalà shakes his head no. "No, I am a new arrival on these shores."
		*else
			Fragalà chuckles. "I have only just arrived! Do you think I could establish myself so quickly?"
			
			"No, but your presence here is still noteworthy."
			
			"That may be, ${mr} ${surname}."
		
		"Have you taken up residence somewhere?"
		
		"I have not, in fact. I passed through New Orleans and came here with Senator Santagostino. With all of our kind here, I was hoping to discern a home for myself."
		
		"Are there any likely candidates? I can't say Memphis is particularly hospitable at the moment."
		
		He gestures to his face. "Perhaps Memphis is less bothersome to me than to others, but no, not here. I was thinking of some place further west. But I do not know where, yet."
		
		"I am sure you will find a suitable home," you offer. He nods, noncommittal.
	#"Where are you from?"
		*set fragala_rapport %+5
		*set knows_palermo true
		"Palermo. It's a city on the island of Sicily. Perhaps you've heard of it?"
		
		"@{intelligence No.|Perhaps?|Yes, of course.|Yes. It was unfortunate for Palermo when Sicily was merged with Naples.|Yes. It was unfortunate for Palermo when Sicily was merged with Naples.}"
		
		*if intelligence > 3
			He nods in agreement.
		"It was my home for decades, but I relocated to Naples as it eclipsed Palermo. Everything is different now. Garibaldi has unified the country to the detriment of Naples and Sicily…and to those vampires who lived there. I have come to these shores in the hopes of new fortunes."
		
		"Was Adonis involved in this?"
		
		"What makes you say that?"
		
		"I would think that a unified Italy would be something to which Adonis aspires."
		
		Fragalà cuts his eyes at you. "You did not hear it from me."
	
		*if (intelligence > 2) and (revolutionary_credentials > 60)
			*set fragala_rapport %+15
			*set knows_fra_rev true
			"Can I assume, then, that you were attracted to Stone's revolution?"
			
			"You may."
			
			"I see."
	*if (knows_palermo and (hre_theory = false)) #"Did you ever meet Adonis or Praetor Miele while you were in Sicily?"
		*set independence %+3
		*set hre_theory true
		*set heard_of_heresy_of_lazarus true
		"Miele? Yes. He came to Naples once. He was a cruel vampire."
		
		"Oh?"
		
		"I witnessed his interrogation of a heretic."
		
		"You mean torture."
		
		"Yes. He found a Lazarene and was determined to uncover her accomplices."
		
		"Did he succeed?"
		
		"Yes."
		
		"Pardon my ignorance, but what is a Lazarene?"
		
		"You've heard the story of Jesus resurrecting Lazarus, yes?"
		
		*if (intelligence > 1) or priest
			"Of course."
			
			"They believe that when Jesus resurrected Lazarus, he in fact made him into a vampire."
		*else
			"No?"
			
			Fragalà look at you in surprise. "In the Gospel of John, chapter 11, it is said that a respected man—Lazarus—died, while waiting for Jesus to come and heal him. Jesus, in fact, waited for the man to die before coming to town. Arriving at the tomb, four days after the man's death, Jesus ordered the man to 'come forth!' and he did."
			
			"He brought a man back to life?"
			
			"Did he? Or did he make him a vampire?"
			
		"You're saying Jesus was a vampire?"
		
		"I never met the man."
		
		"The Lazarenes, then…they say that Jesus was a vampire?"
		
		"I've never met a Lazarene."
		
		"Other than the one that you saw tortured?"
		
		"I didn't know she was a Lazarene at the time."
		
		You growl at Fragalà's obfuscations. "What do you know, then?"
		
		"I know that a heresy revolving around Lazarus exists, and that it involves Lazarus rising from the dead. The rest I must leave to your conjecture."
		
		"So why do you think that Miele was sent here?" you say, trying to return the conversation to your original question.
		
		"As punishment, surely."
		
		"Punishment? What did the vampires of the New World do to deserve him?
		
		"They destroyed the Roman Empire."
		
		You frown. "The Roman Empire fell a thousand years before America was colonized."
		
		"The Holy Roman Empire was vanquished in 1806. Which was the heir to the Roman Empire, which was the heir to the Republic, which was the heir to the Roman kings."
		
		"I still don't see what that has to do…"
		
		"Napoléon Bonaparte sold Louisiana to President Thomas Jefferson in 1803. He used that money to finance his conquest of Europe. Now you have a Fair," he says, gesturing to the extravagance around you, "and a two-thousand year old polity, beloved by numerous older vampires, is gone."
		
		You stop. "Is that…that can't be…"
		
		Fragalà shrugs. "It's just a thought I had."
		
		You fall silent as you try to weave what you know of vampiric rumor with the ebb and flow of human history.
	#"Whom do you support for Senator?"
		*set independence %+5
		"Malloy@{knows_fra_rev , of course|}. Not that my opinion carries much weight."
		
		*if knows_fra_rev = false
			*if revolutionary_credentials > 60
				"I am glad to hear it," you begin. "Your preference, I mean. Not your lack of influence."
				
				"Yes, I understood," he waves your apology away.
			*if revolutionary_credentials < 40
				*set fragala_rapport %-5
				"Thank goodness, then."
				
				He scowls at you. "I see you've cast your lot with Adonis."
				
				"So I have."
			*set knows_fra_rev true
	*if (knows_palermo and ((intelligence > 2) or (anachronism > 75))) #"What did you do during 1848?" There were numerous revolutions throughout Italy that year.
		*set fragala_rapport %+10
		*set heard_of_dinapoli true
		"I fled Palermo, in fact. It was the site of the very first revolution."
		
		"Oh? What was it like?"
		
		"The revolutionaries had no idea what they were getting in to. Into this leadership vacuum stepped the local gentry. Had they not been at war with Naples, the transition might have been peaceful. But the island was ill-prepared for a sustained conflict and soon King Ferdinand's armies recaptured the island."
		
		"And you?"
		
		"I was already looking to leave the city of my birth. I had been there for too long already. When it became clear that the revolution was going to fail, I slipped through the blockade and established myself in Naples."
		
		"And were you welcomed there?"
		
		Fragalà smirks. "You could say that. Elena was suspicious of everyone that came to her court, seeing minions of Adonis everywhere."
		
		"Elena?"
		
		"Elena of Naples. One of the oldest vampires that I know of. Other than Adonis, of course."
		
		"Is she the governor?"
		
		"She is."
		
		"And if she is a loyal governor…"
		
		"If she is a loyal governor, she should have nothing to fear from Adonis. Yes, in theory. In practice, one must always be wary of Adonis and his inquisitions."
	*if (knows_leper = false) #@{(discretion > 60) "You have something wrong with your face," I observe.|"Your skin…" I begin, unsure as to how to ask about his condition.}
		*set questions -1
		*set discretion %+5
		*set knows_leper true
		"Yes, I have leprosy."
		
		"Is it…contagious?"
		
		"Not to you, no."
		
		"And to mortals?"
		
		"Yes, unfortunately."
	*if (knows_leper) #"How do you feed without…sharing your affliction?"
		*set discretion %+5
		*set fragala_rapport %-5
		*if status <= 2
			"Do you usually ask after the feeding habits of your new acquaintances?"
			
			"I suppose not."
			
			"Then let me be the first to inform you that it is quite rude."
			
			*if discretion > 60
				*set fragala_rapport %-50
				"No more rude than you daring to show your face here."
				
				He looks as though you have slapped him. "Well, it is clear that this conversation is over," he concludes.
				*return
			*else
				"Forgive me, Mr. Fragalà."
				
				He accepts your apology with a nod.
		*else
			He looks uncomfortable and shifts his weight to his other foot. "We do not need to drink directly from the source, as I'm sure you're aware."
			
			"I am," you reply.
			
			"I simply have to be discreet about how I draw the blood."
			
			"Clever."
			*if (compassion > 50) and (discretion > 50)
				You consider a moment. "But doesn't it get…boring after a while? Suppressing your nature in that way?"
				
				He shifts again. "Boring isn't the word that I would choose, no."
				
				"Torturous?" you say with a sharp grin.
				
				He doesn't answer.
*if questions > 2
	*set heard_of_fragala true
	*set met_fragala true
	"If you will excuse me, ${mr} ${surname}, I have more business to conduct."
	
	"Of course, Mr. Fragalà," you reply.
	*return
*else
	He looks at you. It seems you have the opportunity to ask another question.
	*goto fragala_loop
		

*label speak_harding
*comment 5
*set interlocutors +1
*set met_harding true
*label speak_harding_loop
*set questions +1
*choice
	*if shepherds_and_wolves and (heard_of_eusebius = false)
		#"I've heard people speaking of shepherds and wolves.  What do they mean by this?"
			*set heard_of_eusebius true
			*set knows_about_shepherds_and_wolves_text true
			Harding rolls her eyes at you.  When she finally speaks, it is like a governess to her students who have been too busy playing with raspberries and milk to pay her heed.  "It is from a dialogue, attributed to Eusebius of Damascus, where two vampires debate the virtues of how mortals should be treated."
			
			"And they describe themselves as such?"
			
			"Not exactly.  One of the speakers relates this metaphor about shepherds and wolves…really, it's the only thing that anyone remembers from the dialogue."
			*if heresies_explained
			
				"And such things are not considered heretical?"
				
				"Why no, you silly thing.  It discusses how we should be towards men; the Society has no position on that.  The heresies are cults that seek to spread lies about our origins."
				
				"What, then, is the position of the Society on our origins?"
				
				"The Society has no position on that."
				
				You are tempted to push harder, but you can see that you will get no further with this line of questioning.
			*if heresies_explained = false
				
				"Does anyone still read it?"
				
				"It is very hard to come by.  I have never seen a copy myself."
				
				"Does anyone still pay attention to it?"
				
				"Why would you be asking otherwise?  Though the Society is not divided up along such lines, at events like these, someone will wax philosophical and likely try to persuade the gathered vampires one way or the other."
				
				"And no one has yet done that?"
				
				"There is still tomorrow."
				
				"There is still tomorrow," you conclude.
			*label resolve_harding
			*if questions > 1
				"The sun is rising," observes Harding, changing the subject.
				
				"It is."
				
				"You must excuse me; I must bid my farewells."
				
				"Of course, Quaestor."
				*return
			*else
				There is a pause in the conversation; you sense the opportunity to ask another question.
				*goto speak_harding_loop
	#"What do you think of the candidates for the Senate?"
		*set heard_of_lesczynski true
		"Lesczynski is the eldest of the three."
		
		"And that qualifies him how?"
		
		"He knows the most of what it means to be a member of the Society.  The other two are wide-eyed starlings."
		*if perception > 2
			Though you do not doubt that she does support Lesczynski, you sense that his age is not the primary reason for it.
		*comment endif
		
		"I think they are both older than me."
		
		"That does not change my point."  You try not to show your annoyance at this barb.
		
		"Then the matter of Stone's deeds bears little impact upon your decision-making?"
		
		"Whether it is Stone in Baltimore or Adonis in Rome, both are far away.  I am more concerned with what transpires here."
		
		"Lesczynski it is, then."
		*goto resolve_harding
	#"I am given to understand that you do not see eye-to-eye with your broodmate, Quaestor Carothers."
		"Did he tell you that?"
		
		@{(charm > 3) "I would not…" you begin.|"I…I…" you stutter.}
		
		"No matter.  He is a walking ape that my beloved dominus, in a moment of madness, turned into a vampire.  I am, in fact, surprised that the gift took; it does not work on most beasts.  Do not be fooled: just because he can talk like a person does not mean that he has instincts any more sophisticated than his brethren."
		
		"A walking ape?"
		
		"Yes.  As with the rest of them.  And those stupid abolitionists, trying to free something that cannot even take care of itself.  They destroyed the world that was my home."
		
		"By freeing the slaves?"
		
		"And driving the nation to war.  Soon, this whole continent will be a smoldering heap, ruined by a lesser species that cannot control its primal urges," she says, a certain fire illuminating her eyes.
		*goto resolve_harding
	#"Might I inquire as to the identity of your dominus?"
		*set discretion %+5
		"You may not."
		
		"I meant no offense…"
		
		"His name is not to be spoken."
		
		"Did he commit some crime?"
		
		"This matter bores me," she says, waving away any further inquiry into the matter.
		*goto resolve_harding
	*if senator_question_unasked
		#"Will there only be ${num_senators} senators here for the vote tomorrow night?"
			*set senator_question_unasked false
			*if senator_count = 10
				*set questions -1
				"Yes, that is everyone that was expected to attend."

				"Thank you."
				*goto resolve_harding
			*elseif senator_count = 9
				*set heard_of_simmons true
				"No, Charles Simmons, Senator of Mobile, is missing."

				"Do you think he will make it?

				"If he is not yet here, I doubt that he will make it in time."
				*goto resolve_harding
			*elseif senator_count = 8
				*set heard_of_davison true
				*set heard_of_simmons true
				"No, there are two that are missing.  Anne Davison of Montréal was supposed to attend, as was Senator Charles Simmons of Mobile."

				"Do you think that they will make it?"

				"If they are not yet here, I doubt that they will make it in time."
				*goto resolve_harding
			*else
				REPORT THIS RESULT TO JASON.
				*link mailto:jason@choiceofgames.com
				*goto resolve_harding

*label speak_lesczynski
*comment 7
*set interlocutors +1
*set memphis_lesczynski_convo true
*set met_lesczynski true
*label speak_lesczynski_loop
*set questions +1
*choice
	*if heard_of_quarrington and (quarringtons_allegiances = false)
		#"The railroad strikes and the death of Quaestor Quarrington did not dissuade you from making the journey here?"
			*set lesczynski_rapport %+5
			Lesczynski lets out a little chuckle.  "I have not been as great an irritant to Consul Stone as Quarrington.  I would dare say things are even safer now for our kind on the railroads than they were before the strike."

			"What do you mean?"
			*goto lesczynski_on_quarrington
	*if (heard_of_quarrington = false)
		#"I'm somewhat surprised the railroad strikes didn't stop you from coming, Mr. Lesczynski."
			*set lesczynski_rapport %+5
			*set heard_of_quarrington true
			"These strikes will not keep me home.  If anything, I feel safer now that I did before.  What with Quaestor Quarrington now dead."

			"Quaestor Quarrington?"

			"Yes, he was the Quaestor of Cumberland, Maryland, the site of one of the earliest strikes.  He died when a mob of workers stormed his home and burnt him to ash."

			"And now you feel safer?"
			*label lesczynski_on_quarrington
			*set questions -1
			*set quarringtons_allegiances true

			"Quarrington was an avowed Loyalist.  He did everything in his power—which, considering the position of his city at the Cumberland Narrows, was quite a lot—to create mischief for the new Consul."

			You lower your voice.  "Do you think that one of our kind had something to with his demise?"

			"I do not doubt it, ${mr} ${surname}, I do not doubt it."

			You take a moment to consider this it of intelligence.
	*if (rationalism > 40) and ((religious_tradition != "pagan") and (able_to_identify_jews and (memphis_haven != "pinch")))
		*selectable_if (discretion > 35) #"Do you hide your horns under your hat?"  After all, you were told all your mortal life that Jews have horns!
			*gosub_scene memphis_1873_reception lesczynskis_horns
	*selectable_if (discretion > 20) #"What do you think of Isaiah Stone's deeds?"
		*set discretion %+5
		*if malloy_out
			Lesczynski eyes the other vampires nearby.  "Considering my current predicament, I would say there is only one right answer to that."
			
			"Oh?"
			
			"I support him whole-heartedly."
			
			"I see.  Have you always done so?"
			
			He winks at you.  "No, I am not able to say that I have.  Then again, it is not me or my dominus that he killed, so I have never been opposed to him, either."
			
			You take a moment to consider this.
		*elseif pickering_out
			Lesczynski eyes the other vampires nearby.  "Considering my current predicament, I would say there is only one right answer to that."
			
			"Oh?"
			
			"I oppose him whole-heartedly."
			
			"I see.  Have you always done so?"
			
			He winks at you.  "No, I am not able to say that I have.  Then again, it is not me or my dominus that he killed, so I never supported him, either."
			
			You take a moment to consider this.
		*else
			"[i]Oy[/i]!" he exclaims with a roll of his eyes.  "Always they want to know about the revolution.  Do I support Stone, or do I not?  What if I haven't decided?  Tell me that?"

			"Then you would make a curious candidate, if you have no position on the revolution."

			"I think the perceived importance of the matter of the revolution will subside as the years grind on.  There are so many other things with which we should be occupied."
			
			"That is a shocking position, Mr. Lesczynski."
			
			"Pragmatic, if you ask me.  We are immortal, after all."

			*if independence <=30
				"I do hope that you are right."
			*else
				*if (revolutionary_credentials >= 40) and (revolutionary_credentials <= 60)
					"Only time will tell."
				*else
					"Though I appreciate the sentiment, I cannot imagine such an outcome."

	*if able_to_identify_jews = false
		#"What is this hat you are wearing?"
			*set discretion %+2
			*set able_to_identify_jews true
			"$!{he} asks me what this is?  It is a kippah, and my people wear it so that we do not offend Yahweh by leaving our heads uncovered."

			"Your people?"

			"Yes, the Israelites.  You might know us as Jews."

			"Oh, yes, of course, I've heard of your people.  But I don't believe I've ever met one before."

			He looks at you in surprise.  "We are not so uncommon.  Perhaps you simply did not know how to look."

			"That may be, Mr. Lesczynski."

	#"Why do you want to be Senator of Memphis?"
		*set lesczynskis_interest_in_memphis true
		"This is a great city, and it will soon be even greater.  It would be an honor to be its Senator."
		
		You do your best not to roll your eyes at this.  "But what does that mean, Memphis is a great city?"
		
		"It means that it was founded by a man who became President of the United States, who named it for one of the most ancient cities of the world, and who has since died a peaceful death."
		
		*if met_andrew_jackson and (discretion > 40)
			"You know, I met the General once, decades ago."  Lesczynski suddenly looks very interested.  "It was right after the Battle of New Orleans.  I tried to feed from him, but he knew what I was and stopped me."
			
			"That does not surprise me."
			
			"How do you mean?"
			
			"${mr} ${surname}, if you do not know, I cannot be the one to tell you."  You look at him in confusion.
			*if questions > 2
				"Please, we should end the conversation here.  The dawn approaches, and we must bid our goodbyes."
				
				"Yes, of course," you reply, still bewildered.
				*return
			*else
				"Please, let us change the subject," he says, eyeing the room.
				*goto speak_lesczynski_loop
		*elseif met_andrew_jackson or attended_marignys_party
			"I attended a soirée with him once, in fact.  Just after the Battle of New Orleans.  He was a luminous presence."
			
			"That does not surprise me.  I never met the man, but I hear he was most extraordinary."
		*else
			"And that is to be envied?"
			
			"Very much so, ${mr} ${surname}.  To die a peaceful death?  How many of our kind will find that?"
			
			"Not many."
	*if able_to_identify_jews and (compassion < 60)
		#"Would you feel lonely here in Memphis, without your people?"
			*set compassion %-5
			*set lesczynski_rapport %+15
			*set anachronism %+10
			Lesczynski smiles broadly at your question.  "This tells me much about what sort of vampire you are, ${mr} ${surname}.  There is, in fact, a healthy community of my people here."

			"There is?"

			"Indeed.  There is the congregation of B'nai Israel at the corner of Main and Exchange."

			"Oh, yes!  I have seen that building.  I did not realize that it was a Jewish congregation."

			"It is what we called a Reformed congregation; it didn't used to be one, but their new rabbi, Max Samfield, has encouraged a certain amount of secularism.  He is even a Freemason!"  He throws his hands up in exasperation.  "But that is why they do not dress as I do. They do not follow the same customs that I do.  Should I be elected, I will guide them back to a truer path."

			You look at him askance.  "Well, it is good that you will have an undertaking ready for your arrival."

			"Your concern is appreciated," he returns.
	*if able_to_identify_jews
		#"What did you think of the War between the States?"
			*set discretion %+2
			*set shepherd_credentials %+2
			"At first I supported the North fully, but then there was Grant and his General Order No. 11…"

			"General Order No. 11?"

			"Yes. He issued a directive expelling Jews from his military district: Tennessee, Kentucky and Mississippi!"

			"He did what?"

			"He ordered them to leave; he was angered by the black market cotton-trade, and blamed my people for it. Thankfully, President Lincoln rescinded the order not long afterwards.  And so I loved him and the North that much more.  But then they elected Grant as President?"

			"Your faith in the North has wavered?"

			"No, I like an anti-Semite in the White House," he replies, exasperated.
			
			You fall silent, @{(compassion < 50) chastened|unsure what to ask next}.
		#"Do you maintain your contacts with your family in Europe?"
			*set compassion %-2
			Lesczynski looks downcast for a moment. "I do."
			
			"And yet, you seem dismayed by my question?"
			
			"You know that the Prussians have united the German Empire."
			
			"I do."
			
			"But I do not think you understand what this means. The Prussians…they treat war like a math problem. You must solve for X in order to win."
			
			"And so they did?"
			
			"Yes, they won, but at what cost to humanity?"
			
			"How do you mean?"
			
			"Have you ever heard of dynamite, ${mr} ${surname}?"
			
			@{literate "I have seen the adverstisements, yes."|"No."}
			
			"When used in war, it is most devastating. It turns men into meat without warning."
			
			"How is that different from cannonfire? We experienced that here."
			
			"Ah, but for cannonfire, you need a cannon. And shot. With dynamite, you need only a stick and a source of fire to ignite it. Anyone can throw a stick of dynamite. Members of my old [i]shul[/i] have described the results of some of these engagements to me…and I shudder at what it portends for the future."
			
			@{(anachronism < 80) "Come now, it can't be as bad as all that," you reply, shrugging off his concerns.|"For all our sakes, I hope your fears are misplaced," you sympathize.}
*if questions > 2

	"If you will excuse me, ${mr} ${surname}, there is much campaigning still to be done this evening."
	
	"Of course.  Best of luck to you," you reply.
	
	"Thank you.  And I look forward to seeing you tomorrow evening."
	
	"Until then."
	*return
*else
	You sense that you have not totally alienated him; perhaps you can fit in another question?
	*goto speak_lesczynski_loop

*label speak_lockridge
*comment 7
*set interlocutors +1
*set met_lockridge true
*set memphis_lockridge_convo true
*gosub check_senators_achieve
*label speak_lockridge_loop
*set questions +1
*choice
	*if heard_of_lesczynski or met_lesczynski
		#"What do you think of the candidacy of Mr. Lesczynski, Senator?"
			"It is difficult for me to muster an opinion of Mr. Lesczynski.  Though he has no obvious deficiencies, he also has not made his position on Stone's rebellion clear.  Therefore, he has little to recommend him."
			
			"And if he were to make his position clear?"
			
			"I am still inclined to support Mr. Pickering.  I have been acquainted with him for some decades, you understand.  Moreover, his opposition to Stone stems from conviction, not a political stance."
			
			"I understand, Senator."
			*label resolve_lockridge
			*if questions > 1
				He looks at you impatiently.  "The sun is rising."
				
				"It is."
				
				"You must excuse me; I must bid my farewells."
				
				"Of course, Senator."
				*return
			*else
				A pause in the conversation leaves you with the opportunity to ask another question.
				*goto speak_lockridge_loop
	*if heard_of_malloy or met_malloy
		#"What do you think of the candidacy of Miss Malloy, Senator?"
			"She is young, loud, and obnoxious.  Just as Stone prefers them, no doubt."
			
			"I'm sorry?"
			
			"She's spent the past few years in Baltimore, no doubt having her head filled with his democratic drivel.  The likelihood of my supporting her is non-existent."
			
			"I see."

			*goto resolve_lockridge
	*if (memphis_chance_encounter != "arthur") and (met_pickering or heard_of_pickering)
		#"What do you think of the candidacy of Mr. Pickering, Senator?"
			"His opposition to Stone's rebellion is well-known.  And I am personally acquainted with him; he came to Charleston before heading to Memphis, to introduce himself and to urge me to attend the election."
			
			"And his opinion on the rebellion is enough to recommend him?"
			
			"Unfortunately, whether we like it or not, the whole Society is watching us here in Memphis."
			
			"I had not realized…" you begin, before being interrupted by Lockridge.
			
			"And because the whole Society is watching, the particulars are filed away in favor of the broader picture: putting an end to Stone's little experiment."
			*goto resolve_lockridge
	*if (senator_count = 9) and senator_question_unasked
		#"Will there only be nine Senators voting tomorrow?"
			*set heard_of_simmons true
			*set senator_question_unasked false
			*if perception > 1
				An ever-so faint shadow of concern passes over the face of Lockridge.
			"Senator Simmons of Mobile was supposed to arrive this evening, but apparently his train has been delayed until tomorrow."
			
			"What happens if he does not arrive?"
			
			"Then he will not be able to vote."
			*if heard_of_pickering or met_pickering

				"Isn't Mr. Pickering from Mobile?"
				
				"Yes.  I expect that Senator Simmons will support Mr. Pickering's candidacy."
				*if heard_of_quintana
					*set lockridge_rapport %+5
					
					"Is Isabella Quintaña Garcia still Quaestor there?"
					
					"Why, she is!  In fact, she is the dominus of Mr. Pickering.  Have you met her?"
					
					"No, but I have heard her name mentioned."
			*goto resolve_lockridge
	*if lockridge_judging_party
		#"Senator, have you had a chance to tour the event?"  After all, he did say he was going to be judging you on its success.
			*set discretion %+5
			"I have, ${mr} ${surname}.
			*if party_preparations = 1
				*set lockridge_rapport %-10
				Truly, though, I am surprised you would seek to brag on the matter."
				
				"I'm sorry?"
				
				"The decorations look like they've been used before.  The venue is bleak, the lighting questionable…"
				
				"I…I…" you stammer, shamed through and through.
				
				"It's really not worth discussing."
				*goto resolve_lockridge
			*elseif party_preparations = 2
				*set lockridge_rapport %-5
				Truly, I was expecting something more, the way you spoke of this."
				
				"I'm sorry?"
				
				"The venue is acceptable and the lighting adequate, but there is no amazement here.  I had anticipated a spectacle."
				
				*if discretion < 50
					"There was only a short time…"
					
					"Don't make excuses.  It makes you look weak."
					
					"Yes, Senator."
					*goto resolve_lockridge
				*else
					*set lockridge_rapport %-5
					"Perhaps you aren't looking hard enough," you mutter.
					
					"I'm sorry?" Lockridge inquires, glaring at you.
					
					"Nothing, Senator."

					*goto resolve_lockridge
			*else
				*set lockridge_rapport %+10
				And I must say, I am impressed.  I had not anticipated your success in this.  It pleases me to see that I can still be surprised."
				
				"You do me too much honor, Senator."
				
				"If you keep at this, there may be a future in it for you.  Too often these events are stuffy and boring.  But this…this is marvelous."
				
				You beam under this praise.

				*goto resolve_lockridge
	*if knows_lockridge_wolf and (lockridge_treatise = 1)
		#"I have heard that you are famous for your philosophical musings."
			Lockridge bursts out laughing; all eyes in the room turn to take in the sight.   When he finishes—he recovers quickly—he looks you in the eyes before speaking.  "You could say that, yes."
			
			"What has made you famous, exactly?"

			"I wrote a treatise on what it means to be a Wolf."

			"I see.  Maybe…someday…you could send me a copy?"

			*label treatise_copy
			*if (lockridge_rapport > 40) or (shepherd_credentials > 50)
				*set shepherd_credentials %-5
				*set lockridge_contactable true
				*set lockridge_treatise 2
				"I don't see why not.  You'll have to remind me, but I'd be happy to forward one to you."  With that, he offers a way for you to contact him in Charleston, should you have need of such.
				*goto resolve_lockridge
			*else
				"I'm not sure that I have any laying about."  He seems on the verge of boredom.

				You cast about for some other topic with which to occupy him.
				*goto resolve_lockridge
	*if (knows_lockridge_wolf = false) and (shepherds_and_wolves)
		#"Where did these terms come from, Shepherd and Wolf?"
			*set heard_of_eusebius true
			*set knows_about_shepherds_and_wolves_text true
			*set knows_lockridge_wolf true
			"Eusebius of Damascus wrote a dialogue about the relationships between vampires and men, many centuries ago."

			"Did he intend to give them these names?"

			"No, it was part of an extended analogy by one of the characters.  It is amazing what happens when you give something a name," he muses more to himself than you, "and soon vampires the world over were identifying with one side or another.
			*if lockridge_treatise > 1
				The idea, put so simply, took the world by storm."  He pauses a moment, allowing this to sink in.
				*goto resolve_lockridge
			*else
				I even wrote an analysis of the text."
	
				"You did?"
	
				"I did.  A statement of facts, in favor of the Wolves."
	
				"Perhaps you might send me a copy?"
				
				*goto treatise_copy
	*if (knows_lockridge_wolf = false) and (shepherds_and_wolves = false)
		#I try to ascertain Lockridge's thoughts on the treatment of mortals.
			*if heard_of_shepherds_and_wolves
				*set shepherds_and_wolves true
				"Ah, the eternal question of shepherds and wolves, the two philosophies that motivate our kind."

				"I have heard these terms before, but am unaware of their exact meaning."
				*goto shepherd_wolf_explanation
			*else
				*set heard_of_shepherds_and_wolves true
				*set shepherds_and_wolves true
				*set lockridge_rapport %-5
				"Ah, the eternal question of shepherds and wolves."

				"Shepherds…and wolves?"

				He looks at you incredulously.  "Did your dominus teach you nothing?"

				"I am sorry to say, I have never heard those terms before.  Not in the context of the Society, anyway."

				*label shepherd_wolf_explanation
				"The question, ${mr} ${surname}, is well-posed by you.  How are we to engage with the mortal world?"

				"How do you mean?"

				"Are we to coddle the mortals, protect them from themselves, spend our immortality tending these inferior beings?"

				"Or…?"

				"Shall we take what we can, enjoy it unabashedly, and leave the humans to take care of themselves?"
				*choice
					#"I think we should guide the mortals as best we can; we have experience and foresight that they lack…"
						*set shepherd_credentials %+20
						*set lockridge_rapport %-10
						*set compassion %-10
						Lockridge begins shaking his head at you, clearly disappointed in your answer.  "You are still young.  In time, you will come to see things clearly."

						You pause a moment and consider how best to recover from this setback.
						*goto resolve_lockridge
					#"Perhaps there is some middle way?  Where we tend to them without coddling them?  We can still take what we need…"
						*set compassion %-5
						*set shepherd_credentials %+5
						*set lockridge_rapport %+5
						"You are still young, but I can respect the inkling of insight you have acquired.  In time, you will discover that we both can't be the master.  It is either us…or them."

						He pauses for effect, allowing his words to sink in.
						*goto resolve_lockridge
					#"I think I agree with you, Senator.  We should take what we need, and let our prey take care of themselves."
						*set shepherd_credentials %-20
						*set lockridge_rapport %+20
						*set compassion %+10
						"You have pleased me this evening, ${mr} ${surname}."

						You stand a little straighter under his predatory smile.
						*goto resolve_lockridge
	*if (pickering_and_pike_unused = false) and pike_question
		#"At the last election, Mr. Pickering was forced to withdraw when I pointed out his affiliation with Albert Pike…"
			*set discretion %+10
			*set pike_question false
			*set revolutionary_credentials %-10
			*set heard_of_heresy_of_masons true
			"Yes, he did."
			
			"Why was that?"
			
			Lockridge looks at you, a little surprised.  "Were you not implying that he was a heretic?"
			
			"Not intentionally, no."
			
			Lockridge snorts.  That must be his version of a laugh.  "I had to spend quite a bit of time recovering from that misstep of yours, ${mr} ${surname}."
			
			"I did not realize, Senator."
			
			"The Freemasons are a heresy that seeks to abolish the Society.  Membership in their fraternity is a death sentence."
			
			"I see," you reply.
			*if heresy_of_masons > 0
				You do your best not to show how nervous you are.
			*goto resolve_lockridge
	#"How long have you lived in Charleston?"
		*set discretion %+5
		*set lockridge_rapport %+10
		*set heard_of_ethelmarr true
		Lockridge looks at you suspiciously for a few moments before answering.  "A little over a century.  I came to the New World before the Revolution; my dominus feared—correctly, it turns out—for his investments here."
		
		"You were born in England, then?"
		
		"Yes, several centuries ago.  Sussex, to be more precise.  It is there that the great Ethelmarr gave me the dark gift."
		
		"And do you remain in contact with your dominus?"
		
		Again, his eyes narrow.  "I do."  Sensing a sensitive subject, you decide to change the topic of conversation.
		*goto resolve_lockridge
	#"The Presidential election was decided by South Carolina…" you prompt.
		TODO
		*goto resolve_lockridge
	*if (heard_of_malloy = false) or ((heard_of_pickering = false) or (heard_of_lesczynski = false))
		#"I'm not sure I know everyone who is standing for the caucus tomorrow."
			*set questions -1
			"There are three, ${mr} ${surname}.  Ms. Siobhan Malloy, Mr. Ascher Lesczynski, and Mr. Absalom Pickering."
			
			"Thank you, Senator," you reply.
			*set heard_of_malloy true
			*set heard_of_pickering true
			*set heard_of_lesczynski true
			*goto resolve_lockridge

*label speak_malloy
*comment 6
*set interlocutors +1
*set met_malloy true
*set memphis_malloy_convo true
*label speak_malloy_loop
*set questions +1
*choice
	*if (draper_convo = false) #"Is there anyone other vampires that you would have expected to put themselves forward for Senator?"
		*set independence %+3
		*set questions -1
		*set draper_convo true
		"John Draper."
		
		*if met_draper
			"Oh? Why John?"
		*elseif heard_of_draper
			"I've not met the man."
			
			"He likes the ponies, if you know what I mean."
			
			"So I've heard. Why him?"
		*else
			*set heard_of_draper true
			"Who?"
			
			"John Draper. He frequents the court of Savannah. And he has a thing for the ponies."
			
			"I haven't heard of him."
			
			"I'm surprised."
			
			"Why him?"
		
		"A vampire of a certain age, committed to Stone's revolution, without a current position of stature…he would have been a natural candidate."
			
		"Do you know why he's not here?"
		
		"I do not."
	*if heard_of_quarrington and (quarringtons_allegiances = false)
		#"Weren't you afraid of coming here?  With the strikes and the death of Quaestor Quarrington, I would think most would have avoided this gathering."
			*set malloy_rapport %+10
			"If I weren't here, then Pickering would surely win the election.  Besides, I have much less ta' fear now that Quarrington is dead."

			"Much less to fear?"

			*goto malloy_explains_quarrington
	*if heard_of_quarrington = false
		#"Coming here from Baltimore, were you not concerned about the strikes?"
			*set heard_of_quarrington true
			*set malloy_rapport %+10
			Malloy laughs.  "Now that Quarrington is dead, I have much less ta' fear from the railroads.  It was never the strikers that I was afraid of."

			"Quarrington?"

			"Yes, Giles Quarrington, the Quaestor of Cumberland, Maryland.  During the strike, a mob attacked his home.  He were burnt to ash."

			"How dreaful!"

			"Dreadful, yes," she says dryly.

			"You feared Quarrington?"

			*label malloy_explains_quarrington
			*set quarringtons_allegiances true
			*set questions -1
			"Quaestor Quarrington was a staunch loyalist.  From 'is position in Cumberlan', he did everything he could ta' interfere with Consul Stone's affairs.  And since so many things had to pass through his city, he was in a position to create much mischief."

			"And now that he is dead, you do not fear the traveling by rail?"

			"Not in the least, ${mr} ${surname}.  Not in the least."

			You take a moment to process this bit of intelligence.
	*selectable_if (discretion > 25) #"Why do you want to be Senator?"
		*set discretion %+5
		Malloy laughs.  It sounds something like baritone windchimes: throaty and deep, yet still harmonic.  "You're not one for the politics of our kind, are ya?"
		
		"How do you mean?"
		
		"E'en I know you're not supposed to be askin' such things so directly," she says with a smile.
		
		Your ears burn a bit at this remonstration.  "I was simply curious…"
		
		"Yes, yes…I'm here to stand for Stone an' his revolution.  I can' let a bunch of ol' codgers undo all that he's gone an' done."
		
		"So, you're mostly here for the cause?"
		
		"Aye.  What would I want with a bunch of crusty bastards?  I don' want none o' that 'cept for what needs doin'."
		
		*if (carothers_rapport > 50) and (compassion < 50)
			*set revolutionary_credentials %+5
			"It sounds like you would get along with Quaestor Carothers."
			
			"I've not had the pleasure of his acquaintance yet."
			
			"You should see to it, and soon."
			
			"I will take that under consideration."
		*else
			"You take quite a burden on yourself, then."
			
			"Someone has ta, ${mr} ${surname}," she replies.
			
			"I suppose I should be grateful that it isn't me."
	#"What do you think of Isaiah Stone's deeds?"
		*set praetors_explained true
		*set knows_ogier_heretic true
		"Miele was a right bastard," she says, spitting out his name.  "He murdered my dominus."
		
		"And no one punished him for violating the Rule of Restraint?"
		
		"Miele accused him o' heresy.  Said he was a Child o' Abraham.  An' since he was the Praetor at the time, no one could say otherwise."
		
		*if (heresy_of_abraham > 0) or (heard_of_heresy_of_abraham)
			"What is that?  A Child of Abraham, I mean," you say, feigning ignorance.
		*else
			*set heard_of_heresy_of_abraham true
			"What is that?  A Child of Abraham, I mean."
		
		Malloy looks over her shoulder, making sure none of the other bloodsuckers are all that close.  "The Children of Abraham are a cult of vampires, outlawed by the Society.  They believe something about vampires bein' created when God saved Isaac from the blade o' Abraham.  The bloody fools think the Bible will tell 'em how to get right with the Lord, or some such shite.  Anyway, the Praetors, they be tasked with huntin' down such nonsense."
		
		*if heard_of_ogier = false
			*set heard_of_ogier true
			"Who was your dominus?"
			
			"Arnoult Ogier.  A devout Huguenot, he jus' wanted ta' worship in peace.  But there is no peace for our kind.  Not under the rule of Adonis, anyway."
		
		"And you think it will be different under Stone?"
		
		"Aye, I do," she concludes.
		
		"Let us hope."
	#"Where are you from?  Tell me something of yourself, Miss Malloy."
		*set malloy_rapport %+5
		*set gould_q true
		Malloy sighs ever so slightly, preparing to launch into a speech she has no doubt delivered several times already this evening.  "The gift of the night was given to me by my dominus just afore the War of 1812. If you've heard of my broodmate, Edwin Lefferts, you should know that we are not on speakin' terms.
		*set heard_of_lefferts true
		
		"I spent the next few decades in New-York, where I made a reputation for wrangling the undead runts that found their way to the city.  Later, I relocated to Baltimore, where I had the pleasure of making the acquaintance of Senator Stone, as he was then known."
		
		*if maddox_status = "dead"
			*set bounty_on_hugh true
			"Wrangling runts?"
			
			"Aye.  Vampires from the old country have a way of showin' up unannounced."
			*if met_hugh_in_vicksburg
				*set heard_about_bounty_on_hugh true
				
				"Funny you should mention.  I met an Irishman in Vicksburg, said he was from New-York.  He had a funny gap between his front teeth."
				
				"Oh?  What was his name?"
				
				"Hugh Gallagher."
				
				"You've seen him?"
				
				"I have."
				
				"There's a bounty on his head."
				
				"A bounty?"
				
				"Aye.  I'll have to take a look around for him while I'm here."
				
				"And if I were to find him?"
				
				"Then ya oughta write to me.  My quaestor would like to see him returned.  Here…" she says, offering you a way to write to her.
				
				"I thank you," you reply.
				*set malloy_contactable true
			*else
			
				"That doesn't sound so hard."
				
				"So you may think.  There's this one vampire, Hugh Gallagher…they placed a bounty on his head, and still no one can find him."
				
				"I'll keep that in mind."
		*else
			"I have my own problems with wayward vampires, Miss Malloy," you reply, the elusive ${wilson} ${maddox} coming to mind.
			
			"Then you can appreciate how hard-earned such a reputation was."
			
			"I most certainly can," you reply.
		*if discretion > 50
			*set malloy_rapport %-5
			Then, a thought strikes you. "The War of 1812? So…you are little more than six decades dead?"
			
			"That is so…"
			
			"That seems awfully young for a Senator. Will you be able to hold your own against the likes of
			*if heard_of_lockridge
				Arthur Lockridge?"
			*elseif heard_of_bailey
				John Bailey?"
			*elseif heard_of_coffin
				Abigail Coffin?"
			*elseif heard_of_partridge
				Samson Partridge?"
			*elseif heard_of_ashmore
				Rebecca Ashmore?"
			*elseif heard_of_timmers
				Gerard Timmers?"
			*else
				*bug what senators has the player heard of?
			
			Malloy glares at you. "Yes, I have only a few years behind me, but I'm ready to spar with the other senators."
			
			"For you sake, I hope so," you reply.
	*if ((gould_q) and (gould_plot = 1)) #"@{(ethnicity = "yankee") I never made it to New-York myself, though I was sorely tempted. So|New-York must be a wild place! So many people…so} much opportunity!"
		*set shepherd_credentials %+5
		Malloy lets out a laugh. "Opportunity for mischief, if ya be asking me!"
		
		"Oh?"
		
		"Have you not heard of the trial of Lord Gordon-Gordon?"
		
		"No?"
		
		"A fella somehow made the acquaintance of Jay Gould and convinced him that he was a Scottish lord! He got Gould to give him a whole million dollars before he was exposed for being a fraud."
		
		"He swindled Gould out of a million dollars!"
		
		"Aye! I never would have thought Gould could have fallen for such a scheme, but he did. But I can understand, after a fashion: he was locked in a life-or-death struggle over the Erie Railroad. But this move nearly ruined him and he has now lost control of it."
		
		"How unfortunate for him!"
		
		"And for several of our kind! There will surely be consequences, as I ken several vampires had invested heavily in his corporations. Like my brother, Edwin," she says, shaking her head.
		
		"Besides your brother, anyone else that I might have heard of?"
		
		"Are ya familiar with Senator Ashmore? She is neck-deep with the banks of Philadelphia; I have to imagine that she lost a pretty penny in the affair."
		*if ashmore_banks = 2
			*set malloy_rapport %+5
			"I had, in fact, heard that."
			
			"So I see…" she replies, impressed.
		*else
			*set ashmore_banks true
			*set heard_of_ashmore true
			"I am now," you reply.
			
			"Put that in yer pipe an' smoke it, then," she says.
*if questions > 1
	"Now, if'n you will be excusin' me, ${mr} ${surname}, 
	*if interlocutors > 1
		the evening has gotten away from me."
	*else
		I 'ave much more to accomplish this evening."
		
	"Of course, Miss Malloy, do not let me interfere," you reply.
	*return
*else
	There is an awkward pause in the conversation.  Perhaps she is waiting for you to ask another question?
	*goto speak_malloy_loop


*label speak_partridge_and_bailey
*comment 8
*set interlocutors +1
*set met_partridge true
*set met_bailey true
*set memphis_partridge_bailey_convo true
*gosub check_senators_achieve
*label speak_partridge_and_bailey_loop
*set questions +1
*choice
	*if heard_about_great_railroad_strike
		#"What has been happening in St. Louis, Senator?  The newspapers have been full of descriptions of this strike…"
			*set bailey_rapport %+10
			*set partridge_rapport %+10
			*set questions -1
			Partridge interjects before Bailey can answer.  "Well, the election was stolen.  And this after years and years of scandals in the Grant Administration.  The workingman is tired of being used and abused.  And when the B&O Railroad lowered their wages, they decided that they'd had enough."

			Bailey rolls his eyes at his companion.  "They are thugs, that is all.  They saw the opportunity to cause mischief, and you see what has ensued.  The working class must be kept in their place, otherwise there would be chaos."

			*if quarringtons_allegiances
				"You do not find the contemporaneous death of Quaestor Quarrington curious?"

				Bailey's face goes still.  "Quarrington threatened Stone's revolution.  His demise was unfortunate, but you will not find me mourning his passing."
				*goto resolve_partridge_bailey
			*else
				"Well, I am happy to see that you are still in one
				*if heard_of_quarrington
					piece, unlike Quaestor Quarrington."

					*set quarringtons_allegiances true
					Bailey's face goes still.  "Quarrington threatened Stone's revolution.  His demise was unfortunate, but you will not find me mourning his passing."

					"Are you saying his death had something to do with Stone and his revolution?"

					Partridge interjects here: "What my dear companion is saying is that Quarrington was an avowed Loyalist.  There were no doubt many who would have been happy to see his demise.  My dominus certainly being one of them.  But to imply that Consul Stone had something to do with it…"
					*if knows_partridge_childe_of_stone = false
						*set knows_partridge_childe_of_stone true
						You infer from this that Partridge is the offspring of Isaiah Stone!  How curious!
					*comment endif

					"By no means, Senator!"

					"Do not fear, I did not think that that is what you meant," Partridge concludes.
					*goto resolve_partridge_bailey
				*else
					piece."

					"Yes, unlike Quarrington…" Partridge says, with a wry smile.

					"Quarrington?"

					"Yes, Giles Quarrington, Quaestor of Cumberland, Maryland," replies Bailey.
					*set heard_of_quarrington true

					"What happened to him?"

					"During the strike in his city, a mob stormed his home…"

					"…and burnt him to ash.  He is no more," finishes Partridge.

					"How dreadful!"

					"Yes, dreadful," Partridge echoes.
					*goto resolve_partridge_bailey
	*if whiskey_ring_plot and (heard_of_aichinger = false)
		#"What of this Whiskey Ring conspiracy that began in St. Louis?"
			*set heard_of_aichinger true
			*set questions -1			
			"Lothar Aichinger," replies Bailey.

			"Excuse me?"

			"Oh, was he the one behind that?" interjects Partridge.

			"Yes.  He has friends throughout the Republican party in Missouri—friends who wanted to see Grant reelected.  They began under-assessing the whiskey…"

			"…and producing fradulent receipts of taxation…" interjects Partridge again.

			"…thereby creating a slush fund that they could use to finance Grant's reelection campaign, as well as other Republicans through the state."

			"And after the election?"

			"They saw no reason to put an end to the conspiracy," replies Bailey.

			"Why would they?  Easy money after all…" opines Partridge.

			*if whiskey_ring_status = "exposed"
				*set bailey_rapport %+25
				*set partridge_rapport %+15
				*set revolutionary_credentials %+10
				"That is, until someone published those records in the newspaper here…" you point out.
				*label bailey_impressed

				Bailey's eyes go wide.  "I don't suppose you would be responsible for that, ${mr} ${surname}?"  You sputter out something self-deprecating, but Bailey waves it away.  "You are my new favorite vampire, ${mr} ${surname}."

				Partridge looks a little dismayed by this.  "But, John…"

				"Shush, Samson.  You know no one will ever replace you," finishes Bailey.
				*goto resolve_partridge_bailey
			*elseif whiskey_ring_status = "merodach"
				*set bailey_rapport %+25
				*set partridge_rapport %+15
				*set revolutionary_credentials %+10
				"That is, until a local preacher decided to set fire to their warehouse…" you point out.
				*goto bailey_impressed
			*else
				"That is, until various undeniable documents were published in the St. Louis papers.  Soon enough, the Treasury Department began its investigation, and the mattter was finally resolved.  And not soon enough, for my tastes," says Bailey.
				*if (whiskey_ring_status = "joined") or (whiskey_ring_status = "encouraged")

					"Yes, not soon enough…" you say.  It would seem that this is the vampire that put an end to your criminal enterprise.  Unfortunate, that.
				*goto resolve_partridge_bailey
	*if (heard_of_malloy = false) and (bailey_introduces_malloy = false)
		#"Whom will you support for the election?"
			*set heard_of_malloy true
			*set bailey_introduces_malloy true
			"Why, Ms. Siobhan Malloy, of course!" exclaims Senator Bailey.  "She is a resident of New-York."

			"Yes, Miss Malloy.  Who else could we support?" says Partridge.

			"That woman has spirit," continues Bailey.
			*goto bailey_introduces_malloy
	*if memphis_chance_encounter != "partridge_bailey"
		*if met_malloy or heard_of_malloy
			#"What do you think of the candidacy of Miss Malloy, Senators?"
				"That woman has spirit," begins Bailey.
				
				*label bailey_introduces_malloy
				"She certainly makes the election more interesting," continues Partridge.
				
				"I think her too young for the position, though," says Bailey.
				
				"Youth does not indicate incompetence," replies Partridge.
				
				"No, but it does indicate influence; as in, being the subject thereof."
				
				"Are you saying that, were she elected, she would be the puppet of someone else?" Pickering says in mock incredulity.  His well-groomed beard bobs with the words, making every expression more comical.
				
				"Oh, Heavens no!  Perish the thought!"  Bailey replies, his hand lifted daintily to his forehead.
				
				"And on the matter of the revolution?" you inquire, trying to bring the conversation back to more important matters.
				
				"Oh, she is an ardent supporter of it.  But I suspect that is simply because neither of the other two have come out in favor of it," says Partridge.
				
				"I would concur," says Bailey.
				*label resolve_partridge_bailey
				*if questions > 1
					*if interlocutors > 1
					
						"Now, if you will excuse us, I sense dawn approaching," says Partridge.
						
						"Of course, Senators.  Do not let me impede you."
						
						"Have no fear of that, ${mr} ${surname}," replies Bailey.
						*return
					*else

						"Now, if you will excuse us," says Patridge.

						"Yes, we have obligations still to fulfill," continues Bailey.

						"Of course, Senators.  Do not let me impede you."

						"Have no fear of that, ${mr} ${surname}," replies Bailey.
						*return
				*else
					It seems you have the opportunity to pose another question.
					*goto speak_partridge_and_bailey_loop
		*if met_lesczynski or heard_of_lesczynski
			#"What do you think of the candidacy of Mr. Lesczynski, Senators?"
				"He is very much an unknown," begins Bailey.
				
				"Yes, he came through Louisville, seeking my support, but he has not made his position on Stone definitive," continues Partridge.
				
				"Hedging his bets?" you say.
				
				"Most certainly," Bailey concludes.
				*goto resolve_partridge_bailey
		*if met_pickering or heard_of_pickering
			#"What do you think of the candidacy of Mr. Pickering, Senators?"
				*set heard_of_quintana true
				"Simply out of the question," replies Bailey.
				
				"He is an ardent counter-revolutionary," continues Partridge.
				
				"He would seek to undermine Consul Stone, and that is unacceptable."
				
				"I did not realize that he had staked out such a position," you venture.
				
				"As the child of Quaestor Quintaña, could you expect anything less?" says Bailey.
				
				"Yes, she is still angry over the machinations of Overstreet and Jackson, to bring the Floridas under the purview of an American Governor, rather than a European one," continues Partridge.
				
				You shake your head at all this new information.  "And Pickering is loyal to his dominus?"
				
				"As far was we know, yes," replies Bailey.
				*goto resolve_partridge_bailey
	*if knows_partridge_childe_of_stone			
		#"Senator Partridge, how fares your dominus?"
			*set discretion %+2
			Partridge smiles briefly.  "He is well.  As you can imagine, he is very interested in the outcome of this election."
			
			"I can imagine.  Does he have a favored candidate?"
			
			"It would be…inappropriate for the Consul to attempt to interfere with the workings of the Senate, ${mr} ${surname}."
			
			"I am sure he meant nothing by it, Samson," interjects Bailey.
			
			"Of course," replies Partridge.
			*goto resolve_partridge_bailey
	*if rumors_of_plague = false
		#"Do you find Memphis to your liking?"
			*set rumors_of_plague true
			The two Senators look at each other before responding.  "As a matter of fact," the bearded Partridge begins, "we have found things somewhat distressing here."
	
			"Oh?  How so?"
	
			"We procured a temporary residence for ourselves, and upon our arrival, found that several of our servants had fallen ill in the days immediately prior."

			*if compassion > 60
				"Your point?" you reply.
	
				Bailey seems a little surprised by your callousness, but takes it in stride.  "It is simply inconvenient to have to worry about our valets falling ill themselves, besides having to find others to fill the empty roles."
	
				"Of course.  That is inconvenient."
				*goto resolve_partridge_bailey
			*elseif compassion >= 40
				"That is unfortunate.  Will they recover?"
	
				"I am uncertain," interjects Bailey, "but some have, in fact, already succumbed to the infection."
	
				"It is virulent, then?"
	
				"Quite."
	
				"I shall have to warn mine own servants.  I cannot afford for them to take ill at the moment."
				*goto resolve_partridge_bailey
			*else
				"How horrible!  Did any die?"
	
				"Several!" exclaims Bailey.
	
				"Have you found the source of the infection?"
	
				"Unfortunately, no.  In fact, the health officials of the city seem most perplexed by the outbreak."
	
				"I shall have to warn mine own employees to be especially careful, as long as whatever this is runs rampant."
				*goto resolve_partridge_bailey
	*if sire_alive and ((memphis_chance_encounter != "partridge_bailey") and sire_question_unasked)
		*if sire_name = "Padre Carlos"
			#"My dominus, Padre Carlos, was, until recently, Quaestor of New Orleans.  Have you heard anything of him as of late?"
				*set sire_question_unasked false
				*set partridge_rapport %+5
				*set bailey_rapport %-5
				"Why, he serves as the new Praetor!" exclaims Partridge.

				"I was aware of that, but I had not heard of his whereabouts or activities otherwise."

				Partridge considers a moment.  "I believe I heard that he spent some time in the Caribbean, but nothing more specific than that."

				You look to Bailey, who does not meet your gaze.  "No, I have heard nothing of him."
				*goto resolve_partridge_bailey
		*if sire_name = "Guillaume de Sainte-Chapelle"
			#"My dominus, ${sire_name}, was, until recently, Quaestor of New Orleans.  Have you heard anything of him as of late?"
				*set sire_question_unasked false
				Partridge shakes his head, but Bailey speaks up: "As a matter of fact, he passed through St. Louis a few years ago.  He stayed for a while, but then continued north."

				"I thank you for this intelligence, sir."

				"You are most welcome, ${mr} ${surname}."
				*goto resolve_partridge_bailey
		*if (sire_name = "West") and (rumors_of_west = false)
			#"I have not heard from my dominus, West, in some time. Have you any word of him?"
				*set sire_question_unasked false
				*set rumors_of_west true
				*label bailey_and_partridge_on_west
				"Have you not heard?" begins Bailey incredulously.
				
				"Heard what?"
				
				"That he was driven mad by the war!" continues Partridge.
				
				"Driven mad?  By what war?"
				
				"The Civil War!" exclaims Bailey.
				
				"That doesn't make any sense…what would he care about the Civil War?" @{rumors_of_west_dead Nevermind the fact that he's supposed to be dead.|}
				
				"I cannot say the cause…I can only relate what we have heard," says Partridge.
				
				"We are very sorry to be the ones to impart this news to you, ${mr} ${surname}. Were you close?" inquires Bailey.
				
				*if rumors_of_west_dead
					"As close as was possible," you lie, through clenched teeth.
					*goto resolve_partridge_bailey
				*elseif sire_rapport > 60
					"As close as was possible," you reply.
					*goto resolve_partridge_bailey
				*elseif sire_rapport >= 40
					"How could one be close with a beast?" you ask rhetorically.  They seem satisfied to let the matter drop.
					*goto resolve_partridge_bailey
				*else
					"I would not say so, no.  But what could anyone expect of him, living alone in the wilderness like that?"
					
					"Yes, what could one expect?" concludes Partridge.
					*goto resolve_partridge_bailey
	*if (sire_alive = false) and ((rumors_of_west_dead = false) and ((sire_name = "West") and ((memphis_chance_encounter != "partridge_bailey") and sire_question_unasked)))
		#"I have not heard from my dominus, West, in some time.  Have you any word of him?"  Of course, you know full well that West is no more than ash scattered throughout a Louisiana bayou.
			*set sire_question_unasked false
			*set rumors_of_west_dead true
			*goto bailey_and_partridge_on_west
	*if senator_question_unasked
		#"Will there only be ${num_senators} Senators here for the vote tomorrow night?"
			*if senator_count = 10
				"Ten is what we were expecting," begins Bailey.

				"Yes, ten," continues Partridge.

				"Were you expecting more?" inquires Bailey.

				"No…I simply didn't know.  And, considering the railroad strikes…"

				"We might have expected some others," says Partridge.  "But you're right, considering the strikes…"

				"It would have been good to have seen Senator MacKenzie…"

				"…or Adamantius.  It's been too long."

				"The Elder?"

				"No no…the Younger."

				"Oh, of course.  Forgive me," says Bailey, somewhat chagrined for his enthusiasm.  The two of them banter back and forth, leaving little opportunity for you to interject, mentioning individuals throughout the New World of whom you are ignorant.
				*goto resolve_partridge_bailey
			*elseif senator_count = 9
				"We are relieved, in fact, that Senator Simmons seems, yet again, to be unable to attend."

				"Yes, that is most unfortunate @{pickering_out for Mr. Lesczynski,"|for Mr. Pickering,"} says Partridge flatly. @{(perception > 2) Though he manages to hide it well, you can sense that he is unhappy about this state of affairs.|}

				"Were you expecting more?" inquires Bailey.

				"No…I simply didn't know.  And, considering the strikes…"

				"We might have expected some others," says Partridge.  "But you are correct, the strikes have dissuaded several from attending."

				"It would have been good to have seen Senator MacKenzie…"

				"…or Adamantius.  It's been too long."

				"The Elder?"

				"No no…the Younger."

				"Oh, of course.  Forgive me," says Bailey, somewhat chagrined for his enthusiasm.  The two of them banter back and forth, leaving little opportunity for you to interject, mentioning individuals throughout the New World of whom you are ignorant.
				*goto resolve_partridge_bailey
			*elseif senator_count = 8
				"We are relieved, in fact, that Senator Simmons seems, yet again, to be unable to attend."

				"Yes, that is most unfortunate
				*if pickering_out
					for Mr. Lesczynski,"
				*if pickering_out = false
					for Mr. Pickering,"
				says Partridge, with a wink.

				"On the other hand, the absence of Senator Davison…" begins Bailey.

				"…she is a staunch ally of Consul Stone…" sighs Partridge.

				"…will hurt the chances of
				*if malloy_out
					Mr. Lesczynski,"
				*if malloy_out = false
					Miss Malloy,"
				finishes Bailey.

				"There are so many interested parties.  It is hard to keep them straight," you say.

				They both smile at you.  "Welcome to the Society, ${mr} ${surname}," says Bailey.  

				"This is only the beginning," says Partridge.
				*goto resolve_partridge_bailey
			*else
				*bug
				THIS IS AN ERROR.  SUBMIT A BUG REPORT.

				MENTION: SENATOR COUNT PARTRIDGE/BAILEY 1877 RECEPTION.
				*link mailto:jason@choiceofgames.com
				*goto resolve_partridge_bailey
	*if shepherds_and_wolves
		#I do my best to determine whether Bailey and Partridge consider themselves shepherds or wolves.
			The two are straightforward in their answers: Partridge considers himself a shepherd, while Bailey is a wolf.  This does not seem to come between them.
			*goto resolve_partridge_bailey
	*elseif heard_of_shepherds_and_wolves
		#"Pardon my ignorance, but I've heard some sort of…philosophical disagreement amongst our kind.  Something about shepherds and wolves?"
			Partridge and Bailey smile at each other.  "It is funny that you should ask that, ${mr} ${surname}," begins Bailey.

			"It is a topic which we discuss with some regularity."

			"Yes, see, that is because dear Samson is a shepherd," says Bailey.

			"and my dear John here is a wolf," finishes Partridge.

			"And what does that mean, exactly?" you inquire.

			Partridge smiles benevolently before answering.
			*goto partridge_bailey_sw
	*else
		#"Tell me, do you spend much time tending to the ebb and flow of the mortal world?"
			*set heard_of_shepherds_and_wolves true
			*set shepherds_and_wolves true
			Partridge and Bailey smile at each other.  "It is funny that you should ask that, ${mr} ${surname}," begins Bailey.

			"It is a topic which we discuss with some regularity."

			"Yes, see, that is because dear Samson is a shepherd," says Bailey.

			"and my dear John here is a wolf," finishes Partridge.

			"A shepherd…and a…wolf?"

			"Why yes," begins Bailey.

			*label partridge_bailey_sw
			"John thinks that he superior to humans.  Or, at least, that they are here to serve him…"

			"…while Samson believes that they need careful tending, like rare flowers."

			"I never said like a rare flower!" exclaims Partridge.

			Bailey rolls his eyes.  "You might as well have.  You're always coddling them.  Believe me, they will survive our worst depredations."

			"That may be, but that doesn't mean we can't guide them to our benefit."

			"Yes, see, dear Samson is no more moral than I; he simply wants to make sure that the humans are happy and oblivious to their situation.  I am a tad more…sanguine."  The two twitter at Bailey's witticism.  "I think that we have have little to fear, as long as we take responsibility for our actions.  We should be capable of managing any problems that may arise.  Otherwise, who is the master here?  Us?  Or our food?"  Partridge is clearly annoyed by Bailey's soliloquy but allows him to finish uninterrupted.
			*goto resolve_partridge_bailey
	*if (pickering_and_pike_unused = false) and (pike_question)
		#"At the last election, Mr. Pickering was forced to withdraw when I pointed out his affiliation with Albert Pike…"
			*set discretion %+10
			*set heard_of_heresy_of_masons true
			*set pike_question false
			"Why yes, he did," exclaims Partridge.
			
			"A brilliant move, if I do say so myself, ${mr} ${surname}," continues Bailey.
			
			"Why was that?"
			
			They look at you, a little surprised.  "Were you not implying that he was a heretic?"
			
			"Not intentionally, no."
			
			They titter.  "How marvelous…" whispers Partridge.
			
			"Senator Lockridge had to spend most of the past four years refuting your unintentional allegations!" observes Bailey.
			
			"It really was a masterstroke," finishes Partridge.
			
			"I did not realize, Senators."
			
			"The Freemasons are a heresy that seeks to abolish the Society," continues Bailey.
			
			"Membership in their fraternity is a death sentence," says Partridge.
			
			"And you drew a link between his candidate and members of the mortal branch of that heresy," says Bailey.
			
			"It was rather well done, if we do say so," concludes Partridge.
			
			"I see," you reply.
			*if heresy_of_masons > 0
				You do your best not to show how nervous this discussion makes you.
			*goto resolve_partridge_bailey
	*if heard_of_memeskia = false
		#"What is St. Louis like, Senator Bailey?"
			*set bailey_rapport %+10
			*set anachronism %+10
			*set heard_of_memeskia true
			Bailey smiles broadly.  "It is the gateway to the West, ${mr} ${surname}.  Already, those headed for California come to us as the last bit of civilization before the Pacific Ocean."
			
			"And who is your Quaestor?"
			
			"It is funny that you should ask.
			*if ethnicity = "choctaw"
				Like you, he is an Indian.  Memeskia by name."
				
				"An Indian? Is a Quaestor?"
				
				"Yes.  He is ancient, but he does well enough.  We have an excellent working relationship."
				
				*if compassion < 50
					"That warms the depths of my heart, Senator," you reply.
				*else
					"That's interesting.  I've never heard of such before," you reply.
			*else
				He is an Indian.  Memeskia by name."
				
				"How curious.  I've never heard of such before," you reply.
			*goto resolve_partridge_bailey
	#"What is Louisville like, Senator Partridge?"
		*set partridge_rapport %+10
		*set anachronism %+10
		"Well, Elinor Harding is the Quaestor, of course," he begins.

		*if heard_of_harding
			"Of course," you reply.
		*else
			*set heard_of_harding true
			"Quaestor Harding?" you begin.  Seeing that you are unfamiliar with the name, he gestures ever so slightly in the direction of the fashionable woman you had previously noticed.

		"The city grew up because of the rapids in the Ohio River there.  Otherwise, the river is clear from its source until it joins the Mississippi.  Because of these rapids, boats had to stop, unload, and reload on a different boat on the other side.  Louisville was the natural result of this process.  As for its name, it honors Louis XVI, whose soldiers were aiding the Continentals during the Revolution."

		"And when did you settle there?"

		"When I was elected Senator in 1853."

		"And can you say what recommends the city?"

		"The thoroughbreds."

		"I'm sorry?"

		At this, Bailey interjects to explain.  "Dear John has an absurd affection for horseflesh.  He likes to bet on their races.  If I didn't know better, I would say that he enjoys the racetrack more than the politics of the Society."

		Partridge smiles grimly.  "One must find some way to pass the decades."

		"You are full of surprises, Senator," you reply.

		"Since we were last here, I have involved myself with the organization of an annual race called the Kentucky Derby.  The third occurrence was this May, and I am told it was magnificent."

		"I can only imagine."
		*goto resolve_partridge_bailey

*label speak_santagostino
*comment 5
*set interlocutors +1
*set met_chiara true
*set memphis_santagostino_convo true
*gosub check_senators_achieve
*label speak_santagostino_loop
*set questions +1
*choice
	*if (hre_theory = false) #"You're from Italy, yes? Did you ever meet Adonis?"
		*set independence %+3
		*set hre_theory true
		Santagostino smiles. "That's all any vampire in the New World wants to know: have you met Adonis? What does he look like? Is he as cruel as they say?"
		
		"Well, is he?"
		
		"I don't know. I was never invited to the court of Rome. My time was spent in the court of Mediolanum."
		
		*if speaks_latin or (intelligence > 2)
			Mediolanum, you know, is the Roman name for Milan. "I see.
		*else
			"Mediolanum?"
			
			"You might know it as Milano."
			
			"Ah, yes.
		And he never graced the court of Milan with his presence?"
		
		"No."
		
		"And what of Praetor Miele? Were you acquainted with him?"
		
		"I was. He was from Lombardy, and spent much of his time in Milano. He was a cruel man, and a crueler vampire."
		
		"Why would Adonis inflict such an individual on the Americas?"
		
		"Do you know what happened in 1806?"
		
		"I'm sure many things happened in 1806, Senator."
		
		"In 1806, the Holy Roman Empire was disbanded by Napoléon Bonaparte, Emperor of the French. Now, you may not think much of the Holy Roman Empire, but to some, it was the direct descendant of the Roman Empire, the Roman Republic, even the Roman kings that predated the Republic."
		
		"What's your point?"
		
		"In 1803, President Thomas Jefferson bought Louisiana from Napoléon and Napoléon used that money to fund his European conquests. One might say that your President financed the destruction of a two-thousand year polity."
		
		"That seems a bit of a stretch."
		
		"Not to many vampires of the Society."
		
		Is this what Stone's Revolution is all about? The dissolution of the Holy Roman Empire?
		
	*if (memphis_chance_encounter != "chiara") and (maddox_status = "dead")
		#"Did you come to Memphis alone?"
			*set knows_santagostino_seeks_gallagher true
			"I brought a valet, but no other members of the Society accompany me, if that is what you mean."

			"Yes, of course."

			"Though, it is strange that you should ask, as I am supposed to keep an eye out for a vampire who passed through New Orleans some time ago, an Irishman by the name of Hugh Gallagher."

			*if met_hugh_in_Vicksburg
				Your eyes widen in surprise.  "Why, I met such a man, at the docks of Vicksburg."

				"How long ago?"

				"It was sometime this spring, not long before I came to Memphis."

				"Did you shake his hand?"

				"I did not.  He did not come ashore, lest he violate the Rule of Respect."

				Santagostino chuckles at this.  "The Rule of Respect," she mutters.

				"What does ${new_orleans_quaestor_address} seek of him?"

				"He wishes to ask a few questions of him.  Tell me, were his eyes watery, when you saw him?"

				"In fact, they were.  I thought little of it at the time."
			*else
				"Why do you seek him?"

				"It is nothing terribly important, but ${new_orleans_quaestor_address} wishes words with him."
	*if (memphis_chance_encounter != "chiara") and sire_question_unasked
		*if patricide
			*if sire_name = "West"
				#"Tell me, have you heard anything of my maker, West?  It has been so long since we parted ways…"  Pretending to be interested in the welfare of your maker every once in a while should continue to avert any suspicion about his untimely death, right?
					*set sire_question_unasked false
					*set rumors_of_west_dead true
					*goto rumors_of_west_2
			*else
				#"Tell me, have you heard anything of my dominus?  It has been so long since we parted ways…"  Pretending to be interested in the welfare of your maker every once in a while should continue to avert any suspicion about his untimely death, right?
					*set sire_question_unasked false
					*set discretion %+5
					"Your maker?"
					
					"Yes, ${sire_name}."
					
					Santagostino's brow furrows.  "No, I can't say that I have heard anything of him.  I'm not even sure that I've heard his name mentioned before."
					
					"That is unfortunate."
					
					"It most certainly is!  The dominus and his offspring share a bond like no other; to be deprived of that bond for so long…I simply cannot imagine it."
					
					"And yet I must endure it," you reply woefully.
					
		*elseif sire_name = "West"
			#"Have you heard any news regarding my maker, West?"
				*set sire_question_unasked false
				*set rumors_of_west true
				*set independence %+5
				*label rumors_of_west_2
				Chiara's eyes go wide.  "The beast?  Why, have you not heard the rumors?"
				
				"No, what rumors?"
				
				"That he has gone mad!"
				
				*if rumors_of_west
					"Mad?"
				*elseif rumors_of_west_dead
					"Mad?" you sputter.
				
				"It is said he was driven mad with grief over the war." @{rumors_of_west_dead What mischief is this?  You burned him to ash yourself.|}
				
				"Grief?  Over the war?  What does he care about the conflicts of mortals?" @{rumors_of_west_dead you say flippantly, trying to cover your disquiet.|}
				
				"That I cannot answer, ${mr} ${surname}."
				
				"I thank you for this intelligence, Senator."
				
				She nods by way of reply.
		*elseif sire_formerly_quaestor
			#"What can you tell me of my dominus, before and after his removal as Quaestor of New Orleans?"
				*set independence %+5
				*set sire_question_unasked false
				*if sire_name = "Padre Carlos"
					"Alas, I can tell you little more than you no doubt already know.  Since his appointment as Praetor, he has been traveling throughout the Americas on the business of Consul Stone."
					
					"And his current whereabouts?"
					
					"I heard a rumor about him investigating heresies in the Caribbean, but little more than that."
					
					"Thank you, Senator."
					
				*elseif sire_name = "Guillaume de Sainte-Chapelle"
					"Alas, I can tell you little more than you already no.  After being replaced by Heer Van der Velde, he travelled up the Mississippi; to Chicago, I believe."
					
					"Up the Mississippi?  To Chicago?  And he did not stop along the way to see his offspring?"
					
					"That is a question I cannot answer for you, ${mr} ${surname}."
				*else
					*set questions -1
					"Alas, I can tell you little.  After his departure from the city, I lost contact with him."
		*else
			#"What news of my dominus, the Quaestor?"
				*set independence %+5
				*set sire_rapport %+5
				*set sire_question_unasked false
				"New Orleans prospers, as does ${new_orleans_quaestor_address}.  I shall make sure to inform him that you inquired after his well-being."
				
				"I thank you for that, Senator."
				
	*if flirting_with_chiara
		#I continue flirting with her.
			*set santagostino_contactable true
			*set santagostino_rapport %+20
			Chiara pretends to resist your amorous advances, but when she slips you an address at which you can write to her, you know that your advances are not entirely unwanted.
			
	*else
		#I try and flirt with her.
			*if santagostino_rapport > 50	
				*set flirting_with_chiara true
				*set santagostino_contactable true
				She greets your innuendos with some witty repartee of her own; it seems that your amorous advances are not entirely unwanted.  So much so that she presses a note into your hand containing an address in New Orleans, by means of which you may correspond with her.
			*elseif revolutionary_credentials > 60
				*set santagostino_contactable true
				Santagostino resists your flirtations but acknowledges her gratitude for your dedication to Stone's cause.  She squeezes a note into your hand containing an address in New Orleans, by means of which you may correspond with her.
			*else
				*set santagostino_rapport %-10
				She seems uninterested in your flirtations.
				
	*if (pickering_and_pike_unused = false) and pike_question
		#"At the last election, Mr. Pickering was forced to withdraw when I pointed out his affiliation with Albert Pike…"
			*set discretion %+10
			*set pike_question false
			*set heard_of_heresy_of_masons true
			"Yes, he did."
			
			"Why was that?" @{(heresy_of_masons > 0) Obviously, you know to the answer to this question, but you wonder how Chiara will answer it.|}
			
			Chiara looks at you, a little surprised.  "Were you not implying that he was a heretic?"
			
			"Not intentionally, no."
			
			She laughs.  The sound is delightful.  "Senator Lockridge has spent most of the past four years recovering from that little comment of yours, dear %{given_name}."
			
			"He did, Senator?"
			
			"The Freemasons are a heresy that seeks to abolish the Society.  Membership in their fraternity is a death sentence.  You drew a link between his candidate and members of the mortal branch of that heresy.  It was rather well done, if I do say so myself."
			
			"Thank you," you reply tentatively. @{(heresy_of_masons > 0) You do your best not to show how nervous you are.|}
				
	#"How did you come to live in New Orleans?"
		*set santagostino_rapport %+10
		Chiara smiles at you.  "The Old World has grown stiff and unyielding. Truth be told, I think I was seeking someone like Isaiah Stone, someone willing to clear some of the dead brush and let the Society grow again."
		
		"You became a vampire before arriving there?"
		
		"Yes.  I was actually born in Milano.  It was a long journey to the New World, but well worth it."
		*if flirting_with_chiara
		
			"We are fortunate to have you here," you say with a smile.  
			
			She rolls her eyes at this idle flattery.
*label resolve_santagostino
*if questions > 1
	At the most inopportune moment, she brings the conversation to more serious matters. "If you will excuse me, I 
	*if interlocutors > 1
		can feel the sun rising in my blood."
	*else
		have business yet to conduct."

	"Yes, I as well."
	
	"[i]Buona notte[/i]."
	*goto plans_for_tomorrow
*else
	A pause in the conversation leaves you with the opportunity to ask another question.
	*goto speak_santagostino_loop
			
*label plans_for_tomorrow
*if interlocutors = 1
	*goto open_choice_1
*page_break
The night is beginning to wrap up. Amid the restlessness, Applethorp approaches you.

"Good evening," you begin.

@{(applethorp_rapport > 55) "An' to yah!" she begins.|"Yeeyah," she replies curtly.} "Ah knows you is lookin' for ${maddox}. Now Ah knows that the humans be dyin' left an' right from the fever, but Ah been hearin' that folks is dyin' straight-away. It ain' jus' the fever."

"What are you saying?"

"That Ah thinks that ${maddox} is back."

You purse your lips. "Thank you, Ms. Applethorp."

She nods and continues on her rounds, bidding the other vampires good day.
*if earned_status
	*set status +1
	Before the attendees depart, Carothers gathers them around for a brief moment to publicly thank you for your efforts in organizing the soirée.  The guests murmur their approval and bid you goodnight one by one as they depart.

	Clearly, your star is on the rise in the Society.

	*if memphis_reception_planner != "Dido"
		You give some final instructions to the organizers, making sure that everything is in order before you leave.
	Satisfied, you give the room one final glance and head for home.
*elseif train_status
	*set status +1
	Before the attendees depart, Carothers gathers them around for a brief moment to publicly thank you for your efforts @{(acquiring_vessels_1877 = "success") in providing the refreshments for the evening|in organizing the reception}.  The guests murmur their approval and bid you goodnight one by one as they depart.  
	*if (malloy_out = false) and ((lesczynski_out = false) and (pickering_out = false))
		Malloy, Lesczynski, and Pickering all make sure to observe in some form or another that they will now have the pleasure of your company for the following evening.
	*if malloy_out
		Lesczynski and Pickering both make sure to observe in some form or another that they will now have the pleasure of your company for the following evening.
	*if lesczynski_out
		Malloy and Pickering both make sure to observe in some form or another that they will now have the pleasure of your company for the following evening.
	*if pickering_out
		Malloy and Lesczynski both make sure to observe in some form or another that they will now have the pleasure of your company for the following evening.
	
	Clearly, your star is on the rise in the Society.
*else
	The gathered vampires begin to depart one by one.  
	*if memphis_reception_planner != "Dido"
		You give some final instructions to the organizers, making sure that everything is in order before you leave.
	*if (status = 0) and (first_memphis_reception_attended > 1)

		Carothers corners you on the way out.

		"You understand that your presence will not be required tomorrow evening?"

		"Excuse me?"

		"You have no standing in the Society.  Your presence is not welcome at the caucus.  I trust I have made myself clear?"

		"I…"

		"Good.  Good night."
		*goto plans_for_tomorrow_2
	Finally, you bid your goodnights and hasten home before the sun rises.

*label plans_for_tomorrow_2
On the way, you take stock of your situation: $!{wilson} is loose in the city. @{memphis_affair Clotho is definitely abed with the yellow fever.|} Senators from cities across the continent are gathered to choose their newest member@{debt_to_lesczynski —an event which you are forbidden from attending|}.

Where will you go when the sun sets?
*choice
	*if memphis_affair
		#I will stay with Clotho; I cannot leave her in this condition!
			*set compassion %-20
			*set discretion %-10
			*set independence %-20
			*goto_scene memphis_second_intermission
	#I will hunt down $!{wilson}.
		*set discretion %+5
		*goto_scene memphis_1877_plague
	*selectable_if ((status > 0) and (debt_to_lesczynski = false)) #I must attend the caucus.
		*set independence %+10
		*goto_scene memphis_1877_caucus
		
*label booted_epilogue
*page_break
*if ((memphis_reception_planner = "abandoned") or ((acquiring_vessels = "failed") and (status <= 2))) or ((party_preparations = 0) and (memphis_reception_planner = given_name))
	Your shame accompanies you all the way back to your haven.
	*if carothers_rapport < 40
		Even if your relationship with Carothers has not been the best, your name will be linked to his failures this evening.
	*if revolutionary_credentials > 60
		In particular, Stone's cause will be hurt by your failure to help Carothers put his best foot forward.
	Your presence will not be required for tomorrow evening.
*else
	Being ordered from the reception and forbidden from tomorrow night's caucus is not how you'd intended for the night to end.
*page_break
*goto_scene memphis_1877_plague

*label allegiance_count
*set senator_count 10
*set r_count 0
*set cr_count 0
*set r_count +1
*comment Bailey
*set cr_count +1
*comment Lockridge
*comment the below is for Simmons's voting.
*if simmons_waylaid
	*set senator_count -1
*if simmons_waylaid = false
	*set cr_count +1
*comment the below is for Davison's voting.
*if davison_waylaid
	*set senator_count -1
*if davison_waylaid = false
	*set r_count +1
*if senator_count = 9
	*goto partridge_exposed_loop
*comment the below is for Santagostino's voting.
*set r_count +1
*comment the below is for Coffin's voting.
*if pickering_out
	*set r_count +1 
	*comment Coffin hates Lesczynski
*if pickering_out = false
	*set cr_count +1
*comment the below is to determine Ashmore's voting
*if ashmore_determined = false
	*if (ashmore_rapport >= 50) and (revolutionary_credentials >= 50)
		*set r_count +1
		*set ashmore_revolutionary true
	*if (ashmore_rapport < 50) and (revolutionary_credentials < 50)
		*set r_count +1
		*set ashmore_revolutionary true
	*if (ashmore_rapport >= 50) and (revolutionary_credentials < 50)
		*set cr_count +1
	*if (ashmore_rapport < 50) and (revolutionary_credentials >= 50)
		*set cr_count +1
*comment the below is for Bowater's voting
*if bowater_determined
	*goto post_bowater
*if (calkins_status = 3) and (independence > 30)
	*set bowater_determined true
	*if player_for_senator
		*set bowater_for_player true
		*goto post_bowater
	*if (calkins_rapport >= 50) and (revolutionary_credentials >= 50)
		*set r_count +1
		*set bowater_revolutionary true
	*if (calkins_rapport >= 50) and (revolutionary_credentials < 50)
		*set cr_count +1
	*if (calkins_rapport < 50) and (revolutionary_credentials < 50)
		*set r_count +1
		*set bowater_revolutionary true
	*if (calkins_rapport < 50) and (revolutionary_credentials >= 50)
		*set cr_count +1
*if calkins_status > 3
	*set bowater_determined true
	*if ashmore_revolutionary
		*set cr_count -1
	*if ashmore_revolutionary = false
		*set bowater_revolutionary true
		*set r_count +1
*if bowater_determined = false
	*if r_count >= cr_count
		*set cr_count +1
	*if r_count < cr_count
		*set r_count +1
*label post_bowater
*comment the below is for Timmers' voting
*if r_count >= cr_count
	*set cr_count +1
*if r_count < cr_count
	*set r_count +1
	*set timmers_cr false
*comment the next four sections are to re-balance too-excellent politicking on the player's part.
*if (r_count < (cr_count-1)) and (simmons_waylaid = false)
	*set simmons_waylaid true
	*set cr_count -1
	*set santagostino_waylays_simmons true
*if (r_count > (cr_count+1)) and (davison_waylaid = false)
	*set davison_waylaid true
	*set r_count -1
	*set lockridge_waylays_davison true
*if (r_count > (cr_count+1)) and ((ashmore_determined = false) and (ashmore_revolutionary = true))
	*set ashmore_determined true
	*set ashmore_revolutionary false
	*set r_count -1
	*set cr_count +1
*if (r_count < (cr_count - 1)) and ((ashmore_determined = false) and (ashmore_revolutionary = false))
	*set ashmore_determined true
	*set ashmore_revolutionary true
	*set r_count +1
	*set cr_count -1
*comment the below is for Partridge's voting
*set r_count +1
*if r_count > cr_count
	*set partridge_betrayal true
	*set r_count -1
	*if r_count = cr_count
		*set partridge_uncommitted true
	*if r_count != cr_count
		*set cr_count +1
*if senator_count = 10
	*set num_senators "ten"
*if senator_count = 9
	*set num_senators "nine"
*if senator_count = 8
	*set num_senators "eight"
*if senator_count = 7
	*set num_senators "seven"
*if senator_count = 6
	*set num_senators "six"
*return

*label partridge_exposed_loop
*comment the below is for Santagostino's voting.
*set r_count +1
*comment the below is for Coffin's voting.
*if pickering_out
	*set r_count +1 
	*comment Coffin hates Lesczynski
*if pickering_out = false
	*set cr_count +1
*comment the below is to determine Ashmore's voting
*if ashmore_determined = false
	*if (ashmore_rapport >= 50) and (revolutionary_credentials >= 50)
		*set r_count +1
		*set ashmore_revolutionary true
	*if (ashmore_rapport < 50) and (revolutionary_credentials < 50)
		*set r_count +1
		*set ashmore_revolutionary true
	*if (ashmore_rapport >= 50) and (revolutionary_credentials < 50)
		*set cr_count +1
	*if (ashmore_rapport < 50) and (revolutionary_credentials >= 50)
		*set cr_count +1
*comment the below is for Bowater's voting
*if bowater_determined
	*goto post_bowater_loop
*if (calkins_status = 3) and (independence > 30)
	*set bowater_determined true
	*if player_for_senator
		*set bowater_for_player true
		*goto post_bowater_loop
	*if (calkins_rapport >= 50) and (revolutionary_credentials >= 50)
		*set r_count +1
		*set bowater_revolutionary true
	*if (calkins_rapport >= 50) and (revolutionary_credentials < 50)
		*set cr_count +1
	*if (calkins_rapport < 50) and (revolutionary_credentials < 50)
		*set r_count +1
		*set bowater_revolutionary true
	*if (calkins_rapport < 50) and (revolutionary_credentials >= 50)
		*set cr_count +1
*if calkins_status > 3
	*set bowater_determined true
	*if ashmore_revolutionary
		*set cr_count -1
	*if ashmore_revolutionary = false
		*set bowater_revolutionary true
		*set r_count +1
*if bowater_determined = false
	*if r_count >= cr_count
		*set cr_count +1
	*if r_count < cr_count
		*set r_count +1
*label post_bowater_loop
*comment the below is for Timmers' voting
*if r_count >= cr_count
	*set cr_count +1
*if r_count < cr_count
	*set r_count +1
	*set timmers_cr false
*comment the next three sections are to re-balance too-excellent politicking on the player's part.
*if (r_count < (cr_count-1)) and (simmons_waylaid = false)
	*set simmons_waylaid true
	*set cr_count -1
	*set santagostino_waylays_simmons true
*if (r_count > (cr_count+2)) and ((ashmore_determined = false) and (ashmore_revolutionary = true))
	*set ashmore_determined true
	*set ashmore_revolutionary false
	*set r_count -1
	*set cr_count +1
*if (r_count < (cr_count - 1)) and ((ashmore_determined = false) and (ashmore_revolutionary = false))
	*set ashmore_determined true
	*set ashmore_revolutionary true
	*set r_count +1
	*set cr_count -1
*comment the below is for Partridge's voting
*set r_count +1
*if r_count > cr_count
	*set partridge_betrayal true
	*set r_count -1
	*if r_count = cr_count
		*set partridge_uncommitted true
	*if r_count != cr_count
		*set cr_count +1
*if senator_count = 10
	*set num_senators "ten"
*if senator_count = 9
	*set num_senators "nine"
*if senator_count = 8
	*set num_senators "eight"
*return

*label check_senators_achieve
*if (met_ashmore) and (met_bailey and (met_bowater and (met_coffin and (met_davison and (met_lockridge and (met_partridge and (met_chiara and (met_simmons and (met_timmers)))))))))
	*if achieve_meet_senators = false
		*set achieve_meet_senators true
		*achieve tensenators
*return
	
*label news_of_estefania
*if flirting_with_chiara
	*set santagostino_rapport %-20
	Chiara tries to hide her disappointment that you are more interested in Estefania than her.  Thankfully, that does not stop her from answering your question.
"She has left New Orleans.  I believe she went north, to the cities of industry.  New-York, Buffalo, Cleveland…something about the way the labor and the soot changes the [i]terroir[/i] of her prey."

"Always following her taste buds.  I suppose I should have expected nothing less."

*if estefania_is_kin
	*if sire_alive
		"I think it more that she was disappointed when Villanueva was replaced.  As much as she loved that city, without her dear brother, its flavors turned to ash."
	*else
		"I think it more sorrow that there is still no word of your maker.  The city was too haunted by his ghost to offer her comfort any longer.  Without his company, the flavors of the city turned to ash."

		You do your best to change the subject, uncomfortable as always when the subject of your maker arises.
*return