*comment ñáéç…—
*hide_reuse
*advertisement
*temp one_eared_negro "one-eared freedman"
*if maddox_num = 2
	*set one_eared_negro "one-eyed German-Cajun"
*if maddox_num = 3
	*set one_eared_negro "gap-toothed Irishman"
*temp bluffs false
*temp for_new_york false
*temp no_suh "No suh"
*if male = false
	*set no_suh "No'um"
*temp pray "pray"
*temp praying "praying"
*if rationalism < 60
	*set praying "hoping"
	*set pray "hope"
*temp knows_stakes false
*if knows_about_stakes or (lore > 2)
	*set knows_stakes true
*temp wanna_feed false
Leaving the hall, you are confronted with a young man. @{(perception > 0) He breathes heavily with exertion.|}
*if speaks_english = false
	He gestures for you to follow him.  The two of you share no common tongue, but you do understand the word "Dido."
	*page_break
	You follow the messenger to the Pinch.  You had wondered why Applethorp was not with Carothers in his haven; your curiosity is satisfied when you follow the messenger into an alley and find her whimpering between two barrels.

	Closing the distance between you, you see that she has a stake through her chest. It clearly hurts, @{knows_stakes but apparently it missed her heart.|but she is still conscious.}

	You try to ask her who did this: 
	*if carothers_ignorant_of_pb
		she shakes her head.
	*else
		"${wilson}," she replies.
	
	You gesture at the stake, and she shakes her head.  She is clearly terrified.    
	*if knows_stakes
		*set knows_about_stakes true
		Annoyed at your inability to communicate and her @{(compassion > 50) incessant whimpering|soft cries of pain}, you bend over and yank the stake out. She screams in agony—you try to calm her down, but she doesn't understand your words—but a minute or so later you can see the wound starting to close.  She looks surprised at this, but grateful all the same.
	*else

		Lacking any better ideas, you gesture towards the stake. "I'm going to take it out, Dido."

		Her eyes are wide. She doesn't understand, but she understands. She shakes her head and tries to push you away.

		"Do you want me to just leave you here? What if @{carothers_ignorant_of_pb whoever did this|${wilson}} comes back?"

		She screams in agony as you pull the stake from her chest. She sounds like she's dying. You stop. She doesn't die. You start pulling on it again and it finally emerges with a wet slurp. You drop the stake to the ground while suppressing the urge to staunch the bleeding; there will be no bleeding. A minute or two later, you notice that the hole is starting to knit back together. You gesture towards it and Dido regards it with a certain amount of disbelief. A minute later and the skin is restored, with no sign of a blemish from the wounds.

	A gasp reminds you of the continuing presence of the messenger, who has been standing and watching all of this transpire, progressing through several stages of shock in the process.  Once Dido is standing again, she glances at you; you can read in her eyes that she intends to kill him.
*else
	"Is you ${mr} ${surname}?"

	"I am.  Who are you?"

	"Miss Dido sent me.  She says to come right quick now."

	*if compassion < 50
		"Where is she?"
		
		"Thisa way."
	*else
		"Who is Dido Applethorp to command my presence?"
		
		"She is hurt real bad."
		
		"Hurt?"
		
		"Yeayuh.  She got a hunk of wood stickin' outta her chest."
		 
		*if (compassion < 50) or (applethorp_rapport > 60)
			"Take me to her," you say with no further hesitation.
		*else
			"Lead on," you growl in annoyance.

	*page_break
	You follow the messenger to the Pinch.  You wondered why she hadn't been in attendance earlier this evening.  Following the messenger into an alley, you find Dido whimpering between two barrels.

	"Ahs glad you is here," she says through clenched teeth.

	"What happened to you?"

	"Ah don' rightly know.  Ah thinks 
	*if carothers_ignorant_of_pb
		it were that fella Ah done seen hereabouts. The one @{maddox_num with jus' one ear|with jus' one eye|with the red hair}. Ah thinks Ah was right: he is one of us."
		
		"I don't know. We'll figure that out later," you lie.
	*else
		that fella ${maddox} got the jump on me.  He put this stake right on through me.  Then he looks me in the eye, all grinnin' like he was touched."

		"${wilson} did this?"

	She nods. "Is Ah gonna be alright?"

	*if knows_stakes
		*set knows_about_stakes true
		*if compassion >= 50
			"Yes, you ninny.  Just pull out the stake.  You'll be fine."  She looks at you suspiciously.  
		*else
			"Yes, you're going to be alright.  You just need to pull it out."  She seems unsure as to whether to trust you or not.
		"Here, I'll do it," you say, leaning in and grabbing ahold of the sharpened piece of wood.  Over her protestations, you draw it out.  Her teeth are clenched and she howls in pain.
		
		Once it's out, you can see the hole already starting to close.  She continues to howl.  You point out the fact that she's not dying.  She doesn't seem to believe you.  "Didn't your dominus teach you about stakes?"
		
		"${no_suh}, he didn'."
		
		"Well, they won't kill you.  If he'd pierced your heart, you'd be paralyzed, but not dead.  You'll be fine once you feed."
	*else
		"I…I don't know."
		
		"Well…do somethin'!"
		
		"I…well…should I take it out?"
		
		"Hows Ah s'ppose to know?"
		
		"Just…I don't know! I'll take it out…just hold still…"  She screams when you touch the sharpened piece of wood.  You shush her and then continue pulling it out.
		
		It emerges with a slurp.  You can see the flesh already starting to knit back together now that the wood has been removed.  Dido continues to howl, until you point out the fact that she isn't dying.  She doesn't seem to believe you, but eventually her protestations quiet and finally cease. 

		She touches her chest gingerly in disbelief, marveling at where the stake had been scant minutes ago.

	*page_break

	Once Dido has had a few minutes to recover, you begin interrogating her about ${wilson}.  She relates how she was picking something up for the event earlier this evening in the Pinch, and lured into the very alley where you now stand.  When ${wilson} drove the stake through her chest, she played dead.  Once he was gone, she cried out until an onlooker came to her rescue—the very messenger who came and fetched you.

	Speaking of, said messenger has been standing and watching all of this transpire, progressing through several stages of shock in the process.  Once Dido is standing again, she glances at you; you can read in her eyes that she intends to kill him.
	*if taste_for_vampire_blood or ((discretion > 75) and (applethorp_rapport < 55))
		*set wanna_feed true
		Looking back at her, however, you see that she is weakened from her wound. If you were ever to have a chance to kill her, it would be now; you just have to dispose of the messenger without her feeding from him and regaining his strength.

*choice
	#Let her.  What he has seen would be considered a violation of the Rule of Reserve.
		*set discretion %+5
		*set independence %+10
		*set compassion %-5
		*set wanna_feed false
		You watch indifferently as Dido sinks her teeth into the messenger's neck.  She drinks deeply, clearly depleted from her wound.
		
		When she finishes, she assures you that she will take care of the body.
	*selectable_if (discretion < 60) #Prevent her from doing this in public—someone might be watching.
		*set discretion %-10
		*set independence %+10
		*set wanna_feed false
		*if speaks_english
			Dido nods at the wisdom of your claim.  Grabbing the messenger by the scruff of the neck, the two of you adjourn inside a house recently emptied by the plague.  
		*else
			Dido looks confused, until you grab the messenger by the scruff of the neck and push him inside a house recently emptied by the plague.  
		Once inside, Dido sinks her teeth deeply into the messenger's neck.  She is clearly very hungry.
			
		When she finishes, she assures you that she will take care of the body.
	*selectable_if ((discretion > 40) or (wanna_feed)) #Let me do it.  @{wanna_feed She can't get her strength back if I'm going to kill her.|She's weak and will probably botch the job.}
		*set discretion %-10
		*set independence %+10
		*set compassion %+15
		You close the distance between you and the messenger before he has time to realize what's happening.  Once you sink your teeth into his neck, it is too late for him.  
		*if wanna_feed
			Dido looks at you, baffled, while you drain him dry right before her.
		*else
			You pass him off to Dido, and let her drink him dry.  She is clearly starved for blood, weakened by the wound she has just healed.
			
			When she finishes, she assures you that she will take care of the body.
	*selectable_if (compassion < 60) #Stop her.  Mortals are not playthings.
		*set compassion %-15
		*set wanna_feed false
		@{speaks_english You point out that he has already served her faithfully; perhaps she can make use of him somehow.  Finally, she relents, promising to take the messenger on as a servant.|You try to stop her, but without a common tongue to explain your reasoning, she disregards your concerns and sinks her fangs into the messenger's neck.}
	*if (speaks_english) and (charm > 3)
		*selectable_if (charm > 4) #I wipe the memory of these events from his mind.
			*set compassion %-5
			*set discretion %-5
			*set wanna_feed false
			Smiling at the man, you take his gaze into yours.  Whispering sweet nothings, you wipe the memory of these things from his mind.  Soon, you send him on his way, none the wiser for how close he came to death this evening.

The matter of the messenger resolved, you turn back to the problem at hand: 
*if wanna_feed
	killing Dido Applethorp.
	
	Turning to face her, your face still dripping with the messenger's blood, you smile. It's a cruel smile.
	
	Brandishing the stake you so recently pulled from her chest, you lunge towards her,
	*if combat >= 4
		driving it deep into her chest. You miss her heart, but she shrieks in pain as the point pierces her breastbone. With a groan, you sink your fangs into her neck and begin sucking as hard as you can.
		*set applethorp_alive 3
		
		She struggles against you, but in her weakened state, she cannot fight you off.
		
		You drink and drink until you begin to taste the heady taste of her heartsblood. And then you drink some more.
		*gosub_scene util diablerie
		
		Finally, she is empty. You drop her body to the ground. Even now the flesh is withering away; soon, the corpse of an old woman lays before you.
		
		You attempt to wipe your face clean, but you suspect you have mostly just smeared the blood around. You pull the stake from her breast and pocket it; it might come in handy later.
		*page_break
		
		Still intoxicated from Applethorp's heartsblood, you contemplate what—if anything—you should do about ${wilson}. Looking down at the body, you realize that you didn't take the time to ask her if he had given any indication of where he was headed.
		
		*choice
			#I head home. ${wilson} can do what he likes.
				*goto home_no_harm
			#I head home—but only because I don't know how to find ${maddox}.
				*goto pursue_pb
			#I go find Carothers and blame ${wilson} for Applethorp's death.
				*if maddox_num < 3
					*set maddox_status "shirked"
				*else
					*set gallagher_status "shirked"
				*set carothers_rapport %-25
				*set memphis_haven_torched true
				*set franklin_dead true
				*set haven_value * 0.1
				*set carothers_humanity +1
				You hurry to find Carothers.  @{(carothers_humanity >= 7) He is strangely indifferent to word of Applethorp's death at the hands of ${wilson}|He is distraught at the news of Applethorp's demise.} The fact that you have not brought him the head of the perpetrator on a silver platter only adds to his ire.
				
				"I will deal with this myself.  Go, now.  I do not want to see you."
				
				You flee Carothers' presence.  Thinking it wise to avoid your haven for fear of meeting ${wilson} there, you find a house emptied by the plague and set yourself down there for the day.
				
				When the sun rises, you fall into rest, ${praying} that tomorrow will be better.
				*page_break
				When you do return to your haven, you find it nothing more than a pile of smoking ruins. What you presume to be Franklin's remains are slumped in what was once the kitchen.

				*gosub consequences_of_torching
				*finish Next
	*else
		but even in her weakened state, you are not much of a fighter. A blow to your face dislocates your jaw and you howl in pain. A kick to your leg shatters your femur.
		
		Wincing from the pain, Applethorp stands over you. @{speaks_english "Ah s'pose Ah shud thank you fuh showin' me wut tah do wid dis ere,"|She mutters somthing in English,} brandishing the stake you recently pulled from her chest.
		
		You reach your hand out to stop her, but she drives the stake into your heart.
		*page_break Eveything Goes Black
		You wake up to Carothers pulling the stake from your chest.
		
		He gives you a brief opportunity to explain yourself, but in the end he pronounces your sentence: death.
		
		Lifting you in the air, he crushes your skull between his hands until it bursts. You last sight is a smile of delight on his lips.
		*set killed_by_vampire true
		*page_break
		*goto_scene scoring
*else
	${wilson}.
	*if speaks_english = false
		You try to ask if she knows where he went.  She points at you, and says a word which you understand: "haven."  ${wilson} is going to your haven.
		*choice
			#I will head home and confront ${wilson} there.
				You hop into your coupé and head home.  You ${pray} that it will still be there when you arrive.
				*page_break
				*goto pursue_pb_1
			#I gesture that the two of us should go see Carothers.
				Dido shakes her head violently.  But you insist.
	
				*goto shirk_hunt
			#I gesture that the two of us should confront ${wilson}.
				Dido shakes her head violently.  She gestures for you to head to your haven, and she will go see Carothers.
	
				Seeing that she will not be moved, you relent.
	
				You hop into your coupé and head home.  You ${pray} that it will still be there when you arrive.
				*page_break
				*goto pursue_pb_1
			*if wilson_embraced_by_withers and (first_memphis_caucus_attended and second_memphis_caucus_attended)
				#You gesture that she should leave.  You will head home; ${wilson} has done you no great harm, and your enthusiasm for this hunt is non-existent.
					*goto home_no_harm
	*else
		"Do you know where @{carothers_ignorant_of_pb this stranger|${wilson}} was going?"
	
		"Well, he said he was lookin' fo' you."
	
		"He was looking for me?"
	
		"Yeayah. Ah thoughts he was gwine kill me."
	
		"What did you say?"
	
		"Ah tolds him where you live.  Then he put that stake in me and took off on that nag o' his."  You look at her in dismay.  "Ah thoughts he was gonna kill me!"
	
		Thoughts of chastising her loudly and repeatedly are quickly replaced by concern for your haven.

*label tell_dido
*choice
	#"Go, tell Carothers what has happened.  I'll go to my home and try to catch @{carothers_ignorant_of_pb this stranger|${wilson}} there."
		*set discretion %+5
		She turns and heads for Carothers' home. 
		*label pursue_pb
		You hop into your coupé and head home.  @{(applethorp_alive != 3) You ${pray} that it will still be there when you arrive.|}
		*page_break
		*label pursue_pb_1
		*if applethorp_alive = 3
			As you approach your home, you instantly feel that something is amiss. There is no sign of Franklin; the rear door is ajar; an old nag, hitched to a post in the alley behind the house, munches quietly from a feedbag tied around her head.  From inside, you can hear some sort of commotion.
		
			Slipping up to the door, you see ${wilson} inside. He has Franklin cornered.  Luckily, Franklin has a poker from the fireplace in his hand, and is using it to keep ${wilson} at a reasonable distance.
			
			@{(discretion > 50) It seeems ${wilson} intended to kill you as well!|How did he find your home? Applethorp must have told him, you conclude.} Now that you've found him, though, what will you do?
		*else
			*gosub first_sight_of_haven
		*choice
			*selectable_if (charm >= 4) #I call out for ${wilson}'s attention, and hold him in my gaze while Franklin knocks him unconscious.
				*set discretion %-10
				When you call out his name, ${wilson} turns around immediately.  You speak to him in a soothing voice.
				*if cotton_warehouse_fire
					This time, however, there is no raging inferno distracting you.  
				You are able to lock eyes with him, and once you do, his fate is sealed.
				
				Seeing an opportunity, Franklin cracks ${wilson} over the head with the iron poker.  ${wilson} crumples to the floor.  Once Franklin has caught his breath, he fetches a rope and trusses ${wilson}.
				*label pb_subdued
				*page_break
				*goto pb_convo
			#I try to subdue ${wilson}.
				*gosub_scene util combat_value_stealth
				*if combat >= 7
					Leaping across the room, you slam into $!{wilson} from behind.  He lets out a yelp of surprise.  He does his best to recover, but within a few moments, you have him subdued.  Franklin fetches some rope, and before long, you have a trussed vampire in the middle of your kitchen floor.
					*goto pb_subdued
				*else
					Leaping across the room, you strike $!{wilson} a glancing blow.  He recovers quickly, and you soon find yourself on the ground.  Seeing himself outnumbered, he flees outside.  Franklin helps you up, but by the time you make it outside, ${wilson} has untied his horse and is galloping away.
					*if shapeshifting > 1
						Reaching out your hand, you call to $!{wilson}'s horse.  It gives a squeal and rises up on its hind legs, throwing ${wilson} to the ground.

						Franklin throws you a rope, and you run to subdue $!{wilson} before he recovers his senses.
						*goto pb_subdued
					*label to_the_cliffs
					*page_break
					@{franklin_dead You fetch your sack of vampire-hunting tools on your way|Franklin takes a moment to catch his breath before following you out} to the coupé. You untie the horse from the carriage and mount up.
					*if franklin_dead = false
						You have some catching up to do. Franklin hands you your sack of vampire-hunting tools.  At this moment, you are grateful for Carothers's advice.
					You kick your heels into the horse's sides and race off into the night after $!{wilson}.
					*page_break
					*goto chickasaw_bluffs
			*selectable_if (discretion > 40) #I set my house on fire.  Yes, Franklin will probably die, but so will $!{wilson}.
				*if stealth > 2
					*set discretion %+20
					*set compassion %+20
					*set franklin_dead true
					*set memphis_haven_torched true
					*set haven_value * 0.1
					You slip inside while Franklin and ${wilson} continue their dance.  A fire still burns in the kitchen stove.  It is a small thing to grab an armful of linens and throw them into the stove.  Your superior powers of misdirection prevent Franklin and ${wilson} from noticing your deeds until the linens are already ablaze.
					
					Unfortunately, while you have successfully set your house on fire—and Franklin with it!—$!{wilson} has escaped through a window.  
					*if shapeshifting > 1
						He rushes to his horse, jumping astride it and kicking it in its sides.  Reaching out your hand, though, you call to the horse, and with a loud neigh, it throws ${wilson} to the ground.

						Fetching a rope, you rush to subdue $!{wilson} before he can recover his senses.
						*goto pb_subdued
					He speeds away on his horse, which broke free of its hitch once it noticed the flames.
					*goto to_the_cliffs
				*else
					*set discretion %+10
					*set compassion %+10
					*set stlouis_valet_loyalty %-50
					Unfortunately, you are not so stealthy as to pass unnoticed.  ${wilson} abandons the fight with Franklin and flees to his horse outside.
					
					Franklin looks at you askance as he sees you trying to set your own house on fire—with him still inside. But now is not the time for that particular discussion; ${wilson} is getting away! You head out to your coupé and untie the horse; you'll be faster on horseback than wrestling with the carriage.
					
					@{carothers_ignorant_of_pb |As you're preparing to set out, Franklin appears and hands you your sack of vampire-hunting tools. At this moment, you are grateful for Carothers's advice.}
					
					You kick your heels into the horse's sides and race off into the night after $!{wilson}.
					*page_break
					*goto chickasaw_bluffs
		
		*label first_sight_of_haven
		Thankfully, your home still stands.  There is no sign of Franklin, but the rear door is ajar; an old nag, hitched to a post in the alley behind the house, munches quietly from a feedbag tied around her head.  From inside, you can hear some sort of commotion.
		
		Slipping up to the door, you see ${wilson} inside. He has Franklin cornered.  Luckily, Franklin has a poker from the fireplace in his hand, and is using it to keep ${wilson} at a reasonable distance.
		*return
	*selectable_if (discretion < 60) #"Let's go tell Carothers together."  Clearly, this situation is beyond my capabilities.
		*set discretion %-10
		"You is sho' bout that?  Ah 'spect he be wantin' you to take care o' dis right quick."
		*choice
			#Yes, I can't do this alone.
				*label shirk_hunt
				*set discretion %-30
				*if maddox_num < 3
					*set maddox_status "shirked"
				*else
					*set gallagher_status "shirked"
				*set carothers_rapport %-15
				*set memphis_haven_torched true
				*set franklin_dead true
				*set haven_value * 0.1
				The two of you hurry to find Carothers.  He is clearly displeased by your failure to deal with this threat.
				
				"I will deal with this myself.  Go, now.  I do not want to see you."
				
				You flee Carothers' presence.  Thinking it wise to avoid your haven for fear of meeting ${wilson} there, you find a house emptied by the plague and set yourself down there for the day.
				
				When the sun rises, you fall into rest, ${praying} that tomorrow will be better.
				*page_break
				When you do return to your haven, you find it nothing more than a pile of smoking ruins. What you presume to be Franklin's remains are slumped in what was once the kitchen.

				*gosub consequences_of_torching			
				*finish Next
			#No, she's right, I need to handle this.
				*goto pursue_pb
	#"Come with me to my haven.  Together, we can catch @{carothers_ignorant_of_pb this stranger|${wilson}}."
		*set discretion %-5
		"No way, no how.  Ah is seen enuf o' stakes 'n things fo' one night."
		
		She looks at you, waiting for your decision.
		*goto tell_dido
	*if wilson_embraced_by_withers and (first_memphis_caucus_attended and second_memphis_caucus_attended)
		#"You'd better hurry home…" I suggest.  I really have no interest in pursuing ${wilson}; he has done me no great harm.
			*label home_no_harm
			@{(applethorp_alive != 3) Dido nods and trundles off. |}You hop into your coupé and head home.  @{(applethorp_alive != 3) You ${pray} that it will still be there when you arrive.|}
			*page_break
			*if applethorp_alive = 3
				As you approach your home, you sense something amiss. There is no sign of Franklin, but the rear door is ajar; an old nag, hitched to a post in the alley behind the house, munches quietly from a feedbag tied around her head.  From inside, you can hear some sort of commotion.
		
				Slipping up to the door, you see ${wilson} inside. He has Franklin cornered.  Luckily, Franklin has a poker from the fireplace in his hand, and is using it to keep ${wilson} at a reasonable distance.
			*else
				*gosub first_sight_of_haven
			
			"Stop this nonsense, ${wilson}."
			
			Taking his eyes of Franklin for a moment, you make eye contact with him.  "Why you been chasin' me?"
			
			"I'm not chasing you.  Not really, anyway.@{wilson_embraced_by_withers  In fact, I'm still angry that Withers took you for herself.|}"
			
			@{maddox_num "But…but wut 'bout all Ah's done?"|"But what about errything I've done?"|"But what about everything I done?"}
			
			"What have you done, ${wilson}?"
			
			@{maddox_num "Ah done made ev'rybody sick.  Ah's been bad."|"I've made erryone sick. I've killed folks."|"I made everyone sick."}
			
			"That's impossible, ${wilson}.  We're vampires.  The fever can't live in our bodies for more than a few hours."
			
			"But…" he begins, before a cough racks his body, @{maddox_num "Ah don think…"|"I don't think…"|"I don't think…"}
			*choice
				*if memphis_affair
					#If he wants to take the blame for Clotho's death, you are more than willing to extract revenge upon him.
						"Perhaps you are right."
						
						"Huh?" he says, before you pounce upon him.  Franklin moves to aide you, and within moments, you have ${wilson} bound.
						
						*goto kill_pb
				#"Don't be absurd.  Go, now, away from the city.  Make a home for yourself where there are no others of our kind."
					*set maddox_status "freed" 
					*set independence %-15
					*set compassion %-10
					He looks at you in surprise, and then slowly relaxes his stance.  "Y${es_suh}," he says, for the last time.  Turning, he makes his way out of your home.
					*finish Next
				*if rejected_sam_wilson
					#If it's punishment he wants, why withhold that from him?  Especially when it may come with a reward.
						*set independence %+10
						*set compassion %+10
						"Perhaps you are right."
						
						"Huh?" he says, before you pounce upon him.  Franklin moves to aide you, and within moments, you have ${wilson} bound.
						
						*goto kill_pb
				*if debt_offered_from_withers
					#If it's punishment he wants, why withhold that from him?  You may despise Withers, but the debt that she has offered is not worthless.
						*set independence %+10
						*set compassion %+10
						"Perhaps you are right."
						
						"Huh?" he says, before you pounce upon him.  Franklin moves to aide you, and within moments, you have ${wilson} bound.
						
						*goto kill_pb
				*if (taste_for_vampire_blood or (applethorp_alive = 3))
					#If he wants to be punished, you can think of a fitting punishment.  "You were granted the blood.  Now I shall take what you were given in error."
						*goto diablerize_pb
					

*label chickasaw_bluffs
*set bluffs true
$!{wilson} is clearly not a horseman.  Though he has made his nag trot, you can see him bouncing uncomfortably along ahead of you.  Hearing the sounds of pursuit in the quiet night, he turns and sees you several blocks behind him.  Losing all concern for decorum—if he ever had such—he begins whipping the nag mercilessly.  As best she can, she summons some sort of fast canter, heading straight for the bluffs over the Mississippi.

*if bought_memphis_bonds
	You smile wryly at the thought that the money invested in the municipal bonds was not a total waste: ${wilson}'s horse would not find the going so easy if the street were still packed dirt.
*page_break
You arrive at the Chickasaw Bluffs to find $!{wilson} sprawled on the ground, trying to regain his footing.  The nag stands a few feet away, having returned her attention to the feedbag which is still tied around her head.

He scrambles to stand; you take your time dismounting.  By the time you are down, ${wilson} is up.  He is clearly looking for an escape route.

The wind whips through your hair.
*if (strength > 3) and (discretion > 40) 
	Striding forward, you stun your quarry with your decisiveness.  You take hold of $!{wilson} by the throat.  His feet dangle in space, the river drifting along far below.
	
	@{maddox_num "Don' let me go!"|"Don' drop me!"|"Please, don't let me go!"} he implores. Surely, a vampire could survive the fall to the water below, but that doesn't mean the still-human part of $!{wilson} isn't afraid.
*elseif charm > 3
	Looking him straight in the eye, you compel him to stand still.  He melts under your awesome gaze, unable to flee your presence.
*else
	"You are cornered, $!{wilson}.  You have nowhere to go."  You're bluffing, of course.  ${wilson} could jump off the cliff, and his vampiric form would certainly survive the fall.  Clearly, though, some still-human part of $!{wilson} fears the precipitous drop.
	
*label pb_convo
@{maddox_num "Wut you want from me?" he exclaims.  "Ahs didn' do nuttin."|"What d'yah wan from me?" he exclaims. "I didn' do nuttin."|"What do you want from me?" he exclaims.  "I didn't do anything."} Apparently, he has a short memory.  Dido would certainly beg to differ.

*if (applethorp_alive = 3) and taste_for_vampire_blood
	Of course, looking at him, you feel Applethorp's blood coursing in your veins; you can feel it making your limbs vibrate with…power. What would one more victim tonight be to you? Nothing.
*choice
	*if memphis_affair
		#"You are the reason that my love is dead.  You do not deserve to live."
			*set compassion %+10
			*if norestraint = false
				*set norestraint true
				*achieve norestraint
			*if maddox_status = "dead"
				*set gallagher_status "dead"
			*else
				*set maddox_status "dead"
			@{(applethorp_alive = 3) You wonder what Carothers would think of your claims of love?|}
			
			*if bluffs
				*if strength > 3
					Tearing ${wilson}'s throat out, you hold him while wheezes through the bloodied hole; apparently, he is trying to protest.  His hands claw at your arms, his nails unable to pierce your flesh.  You pull out the implements you brought along.
					*goto kill_pb_1
				*else
					*if charm > 4
						You advance slowly, maintaining eye-contact.  Taking his hands gently in yours, so as not to break the spell, you begin to tie them together.  By the time you release him from your gaze, he is trussed, ready for the slaughter.
						*goto kill_pb_1
					*else
						*if (combat > 8) or ((applethorp_alive = 3) and (combat > 6))
							Picking up a nearby branch, you club ${wilson} over the head.  He crumples under the blow.
							
							It does not take long for you to anchor him firmly to the ground.  Though he has already begun to stir, he will not free himself before dawn.
							*page_break
							*goto walk_away
						*else
							*if maddox_status = "dead"
								*set gallagher_status "free"
							*else
								*set maddox_status "free"
							Cornered, ${wilson} shows his true colors.  Picking up a nearby branch, he clubs you over the head.
							
							You crumple to the ground, idly musing on the sudden proliferation of stars in the night sky.
							*page_break
							When your vision clears, there is no sign of ${wilson}.  Defeated, you hurry home before the sun rises.
							*finish Next
			*else
				He struggles against his bonds.  Absent a physical strength akin to that of Carothers, you do not see how he could free himself.

				You send Franklin to fetch some implements.  Once Franklin returns, he drags $!{wilson} into the courtyard.
			Within a few minutes, $!{wilson} is staked to the ground; he offers little in the way of resistance.
			
			*if strength > 3	
				*if priest
					He reaches towards you, gurgling.  "No, I will not hear your last confession.  You will go to hell unshriven."  With that, you leave $!{wilson} to the rays of the dawn.
				*else
					You turn @{bluffs and leave.|and reenter your home.} You can hear him gurgling something behind you, but you have no interest in hearing his last words.
				*finish Next
			*else
				*goto walk_away
		*selectable_if ((compassion < 75) and (applethorp_alive != 3)) #"Though you are the reason that my love is dead, she would not want me to visit the same upon you."
			*set compassion %-40
			*if maddox_num = 3
				*set gallagher_status "freed"
			*else
				*set maddox_status "freed"
			He looks at you in surprise.  He opens his mouth to speak, but closes it again, unsure as to how to respond.

			"Go.  Now.  Before I change my mind.  Leave this city, and do not return.  Go where you can find some peace, and bring no more misery to the people of this land."

			*if memphis_haven_torched
				Turning, you set out to find a place to spend the day.  With your haven gone, you will have to hurry.  The knowledge that Clotho would celebrate your decision is some small comfort.
				*page_break
				The next evening, you return to your haven to inspect the remains. Everything is gone.

				*gosub consequences_of_torching
			*elseif bluffs
				Turning, you set your feet to carry you home, comforted by the idea that Clotho would be proud of you.
			*else
				Turning, you walk back into your home, shutting the door behind you, comforted by the idea that Clotho would be proud of you.
			*finish Next
	*if applethorp_alive = 1
		*if wilson_embraced_by_withers and knows_stakes
			#@{rejected_sam_wilson "I will deliver you to Quaestor Carothers, so that he may return you to Withers."|"I will send you back to Quaestor Withers.  Surely, she will exact her vengeance on you for your embarrassment of her."}
				*set independence %+10
				*set discretion %-5
				*if rejected_sam_wilson
					*set maddox_status "carothers"
				*else
					*set withers_rapport %+30
					*set overstreet_rapport %+15
					*set maddox_status "withers"
				*if bluffs
					Drawing a stake from the bag of implements you brought with you, you push it through his heart.  You watch as the light fades from his eyes.
				
					You cover his body, enough that he will make it through the day.  Returning to your haven, you wake Franklin and send him to fetch the subdued ${wilson}.
				*else
					You instruct Franklin to fashion a stake out of a piece of firewood.  He returns a few minutes later.  Ignoring ${wilson}'s protests, you drive it slowly into his heart.  You watch as the light fades from his eyes.
				
				Quaestor @{rejected_sam_wilson Carothers|Withers} will be most grateful for the package @{rejected_sam_wilson he|she} will soon receive.
				*finish Next
		*if (carothers_ignorant_of_pb = false) #"Carothers demands your presence.  He is most anxious to meet you."
			*if maddox_num = 3
				*set gallagher_status "carothers"
			*else
				*set maddox_status "carothers"
			*set compassion %+10
			*set independence %+10
			*if knows_stakes
				*if bluffs
					Drawing a stake from the bag of implements, you position it over his heart.  Slowly, you begin to push it in.
				*elseif franklin_dead
					Though your house may be burning, your bag of implements are still accessible.  Withdrawing a stake, you position it over $!{wilson}'s heart.  Slowly, you begin to push it in.
				*else
					You instruct Franklin to fetch you a piece of sharpened firewood.  You position it over $!{wilson}'s heart, and slowly drive it in.
				He begins to laugh, and continues laughing until the light goes out of his eyes.
	
				*if franklin_dead
					You dust off your hands—the stake was surprisingly dirty—and set about trying to figure out what your going to do with the body during the day.  You have a gift for the Quaestor, but it will be of little use if the sun burns it to ash.
				*else
					You dust off your hands—the stake was surprisingly dirty—and direct Franklin to tend to the body.  You have a gift for the Quaestor.
			*else
				*label inquiry_no_stake
				*if memphis_haven_torched
					*set compassion %+20
					*set discretion %+15
					Quickly, you bind $!{wilson}'s hands and feet.
					
					Unfortunately, with your haven burnt, you have no safe place to flee on short notice.  Lacking any other option, you knock ferociously on the door of a random house.  When the door opens, you dart inside, and kill all the inhabitants as quickly as you can.
					
					Returning to the trussed $!{wilson}, you drag him into the hovel just as the sun begins to rise, slamming the door behind you.  Here, the two of you will wait out the day in something resembling safety.
					*page_break
					You wake the next evening to find your haven demolished.

					*gosub consequences_of_torching
				*elseif bluffs
					You bind his wrists and then wrap the rope around him, until his arms are restrained as well. He offers no resistance; he seems almost relieved that his escapade is over.
					
					You lead him back to your home, where you have Franklin confine him to the basement for the day. Tomorrow, you can deliver him to Carothers. @{(independence > 50) You expect that he will be pleased.|}
				*else
					"Gag him, and put him in the basement."
		
					"Y${es_suh}," replies Franklin.  There has been enough activity for the evening.  ${wilson} can wait out the day in the basement, and tomorrow you can 
					*if carothers_ignorant_of_pb
						*if wilson_embraced_by_withers
							arrange for him to be sent to Withers.
						*else
							*bug
					*else
						deliver him to Carothers.  You expect that he will be pleased.
			*finish Next
	*if (maddox_num < 3) #"@{wilson_embraced I granted you eternal life, and this is how you repay me? You do not deserve this gift."|Withers granted you eternal life, and this is how you repay her?"}
		*set independence %+20
		*set compassion %+10
		*goto kill_pb
	*if (taste_for_vampire_blood or (applethorp_alive = 3)) and (afflicted_vicksburg = false)
			#"@{wilson_embraced I granted you the blood.  Now, I will take it back.|You were granted the blood.  Now I shall take what you were given in error.}"
				*label diablerize_pb
				*set compassion %+30
				*set rationalism %+5
				*gosub_scene util diablerie
				*if applethorp_alive = 3
					*achieve double_whammy
				*if maddox_num = 3
					*set gallagher_status "consumed"
				*else
					*set maddox_status "consumed"
				$!{wilson} looks at you in confusion, a confusion that evaporates once he sees your bare fangs and the way you hunger for his neck.  He tries to resist, but his body cannot muster the power to force you away.  You drink deeply, his cold blood possessed of a sickly sweetness.
				
				*if applethorp_alive = 3
					*set discretion %+40
					It is different from Applethorp's. Unsurprising, you suppose. But with the blood of two vampires running through your veins, you feel as though you could defeat the world.
				@{maddox_num His already bony frame becomes more pronounced as the skin tightens around it.|His elderly frame becomes even more withered as the skin tightens to his bones.|His ginger hair turns ashen before you.} In the last moments, his eyes widen in fear, terrified by what he sees. He exhales one final time—as though he had been holding his breath since becoming a vampire—a long, rattling breath.  And it is over.
				
				@{bluffs You leave the drained corpse where the sun will find it.|You instruct Franklin to leave the corpse where the sun will find it.} No evidence will remain by midday.
				*finish Next
	*if (heard_about_bounty_on_hugh) #"There is a bounty of your head.  I intend to claim it."
		*set independence %+15
		*if knows_stakes
			*set discretion %+5
			*set compassion %+10
			*set gallagher_status "quaestor"
			*if bluffs
				Drawing a stake from the bag of implements you brought with you, you push it through his heart.  You watch as the light fades from his eyes.
			
				You cover his body, enough that he will make it through the day.  Returning to your haven, you wake Franklin and send him to fetch the subdued Hugh.

				The Quaestor of New-York will no doubt reward you handsomely for this gift.
			*elseif franklin_dead
				Though the fire is consuming your home, your bag of implements is still accessible.  Fetching it, you pull a stake from the bag.  Ignoring Hugh's protests, you drive it slowly into his heart.  You watch as the light fades from his eyes.

				The Quaestor of New-York will no doubt reward you handsomely for this gift.
			*else
				You instruct Franklin to fashion a stake out of a piece of firewood.  He returns a few minutes later.  Ignoring Hugh's protests, you drive it slowly into his heart.  You watch as the light fades from his eyes.
			
				The Quaestor of New-York will no doubt reward you handsomely for this gift.
			*finish Next
		*elseif norestraint
			The only problem is, if you kill Gallagher, there will be nothing left to send to New-York.  You'll have to bind him and figure out the logistics later.  Maybe Carothers can offer some assistance.

			Regardless, you bind Gallagher as best you can, and put him away for the day.  Tomorrow you will figure out what to do with him.
			*set gallagher_status "carothers"
			*finish Next
		*else
			*set compassion %+20
			*set discretion %+15
			*set for_new_york true
			*goto kill_pb
	*if (maddox_num = 3)
		#"You have caused the Quaestor quite a bit of consternation.  I think it is time that you left the city."
			*set independence %-10
			*set compassion %-5
			Gallagher looks at you in wonder.  "You ain't gonna kill me?"

			"No."

			"But…why not?" he stammers.
			*choice
				*if (applethorp_alive = 3) #"It serves my purposes for you to be on the run," you reply. No need to tell him about your murder of Applethorp.
					*goto free_gallagher
				#"Though I may be a vampire, I do not murder.  Moreover, I have no right to judge you for your crimes."
					*set compassion %-20
					*label free_gallagher
					*set gallagher_status "freed"
					"Yes, the Society may hunt you…" you continue, "but I will not condemn you to death.  Go, now, and do not return."
					
					"Thank you…" he grovels.

					"Do not be here when the sun sets tomorrow," you say by way of goodbye.
					*finish Next
				*selectable_if (carothers_rapport < 50) #"Carothers is no friend of mine.  He commanded me to find you, but I am not his to command."
					*set independence %-20
					*set gallagher_status "freed"
					"He may hunt you unto the limits of his domain…" you continue, "but that is no concern of mine.  Go, now, and do not return."
					
					"Thank you…" he grovels.

					"Do not be here when the sun sets tomorrow," you say by way of goodbye.
					*finish Next
				#"In fact, all I want is to know why some seem to think that you are connected to the outbreaks of the plague in Memphis."
					*set rationalism %-10
					"Because it's mah fault."

					"What is."

					"The fever."

					"How so?"

					"I've had it these twenty years I been dead.  Whenever I feed, if I don't kill my prey, they come down with the plague.  Ev'r once in a while I try an' let one live, to see if I still got it.  An' ev'r time, they get sick.  And if I'm not careful, soon ev'rbody around 'em gets sick as well."

					You look at him in wonder.  How could a vampire be sick with the plague…for twenty years, no less?
					*goto gallagher_revealed
				#"I have enjoyed watching the chaos you have caused.  If I killed you, who would be here to entertain me so?"
					*set compassion %+10
					"You…you enjoy watchin' all these people die?"

					"The ones from whom you feed?"

					"No, the ones that catch tha' fever if I don' kill 'em."

					"Are you saying that you are responsible for the outbreaks?  How is that possible?"

					"I don' know.   But I know that I still got it, twenty years on.  Whenever I feed, if I don' kill the fellah, they catch it.  And soon it spreads around."

					"Well you are a mystery, Mr. Gallagher."

					He looks at you.  You take a moment to reconsider, based upon this intelligence.
					*label gallagher_revealed
					*choice
						#Let him go.
							*set gallagher_status "freed"
							You gesture for Gallagher to go.  He nods, scraping and bowing as he leaves your presence.
							
							"Just so long as he spreads the plague elsewhere," you muse.
							*finish Next
						#He's right, he deserves to die.
							*goto kill_pb_1
						#I will take him to Carothers.  This deserves further inquiry.
							*set gallagher_status "inquiry"
							*if knows_stakes
								*if bluffs
									You pull a stake from your bag of implements.
								*elseif (franklin_dead)
									You fetch your bag of implements from the burning house.  It contains a stake, which you draw out deliberately.
								*else
									You order Franklin to fashion a stake from a piece of wood.
								$!{wilson} offers nothing in the way of resistance as you approach.  Positioning it carefully, you drive it true into $!{wilson}'s heart.  
	
								*if compassion > 55
									You watch dispassionately as the light goes out from his eyes.
								*elseif compassion > 35
									A feeling of revulsion washes over you as you watch the light go out of his eyes.
								*else
									You do your best to bite back the tears as you watch the light go out from his eyes.
								*finish Next
							*else
								*goto inquiry_no_stake
	*if (afflicted_vicksburg) #"You are menace to both humans and vampires, and you cannot be allowed to live."
		${wilson}'s shoulders sag.  @{maddox_num "Ah is."|"I am."|ERROR}

		"You do not deny your condition?"

		@{maddox_num "Nah."|"No."|ERROR}

		You pause, observing your progeny confront his fate.
		*goto kill_pb
	*if afflicted_vicksburg = false
		*selectable_if (compassion <= 60) #"You are responsible for the deaths of thousands of mortals.  You do not deserve to live."
			*label kill_pb
			Then, the unexpected happens.  ${wilson} begins to cry. @{maddox_num "Ah's afeared,"|"I'm afraid,"|"I'm scared,"} he whimpers.
			
			@{(compassion < 60) You feel yourself softening towards him.|} "What?" you demand, incredulously.  Here is a blood-drinking vampire, creature of the night, responsible for the deaths of thousands of people because of the plague he carries inside him, and he's wimpering before you.
			
			@{maddox_num "Ah's goin' ta hell.  When yous kill me.  Ah's goin' ta' get roasted up somethin' good."|"When you kill me, I'm going to hell. I'll be stuck on a spit and roasted for eternity."|"I'm going to hell.  When you kill me…I'm going straight to hell."}
			
			*if rationalism >= 60
				@{(compassion <= 50) "Yes, yes you are."|"Don't worry.  Someday, I'll see you there."}
			*if rationalism <= 40
				"Don't worry, there is no hell."
				
				@{maddox_num "Den where is Ah goin'?"|"Then where am I going?"|"Then where am I going?"}
				
				"Nowhere."
				
				@{(maddox_num = 1) "Is dat mo' betta o' worse?"|"Is that better or worse?"}
				
				"I don't know."
			*choice
				#"And good riddance."
					*set compassion %+10
					*if maddox_status != "dead"
						*set maddox_status "dead"
					*label kill_pb_1
					*if norestraint = false
						*set norestraint true
						*achieve norestraint
					*if bluffs
						*if for_new_york
							*set gallagher_status "decapitated"
							You pull a hatchet out of the bag of implements that you brought along.  
							*label decap_hugh
							If the Quaestor of New-York wants Gallagher's head, you intend to give it to him.

							It's a messy affair.  Thankfully Gallagher obliges, offering no resistance as you begin hacking at his neck.
							*if (bluffs = false) and (franklin_dead = false)
								The sound and smell of Franklin retching does nothing to improve the situation, however.

							It takes several blows, but finally you cut through the spinal cord and sinew.  The blood oozes from the wounds; with no heartbeat to drive it, it just meanders its way to the lowest point. @{(calkins_status = 6) Unlike with Calkins, the flesh does not simply melt from Gallagher's skull. Rather, it withers while remaining both intact and recognizable.|Once the head is removed, the flesh withers to the point of being a dessicated corpse. You do your best not to recoil at the sight.}

							You put the head into the sack, and @{bluffs turn for home|retire inside}.  The daylight will surely take care of the body.
							*finish Next
						*else
							You pull out the implements you brought along.  Within a few minutes, ${wilson} is staked to the ground; he offers little in the way of resistance.
							
							You turn and leave.  
							*label psalm23
							*set gallagher_status "dead"
							Behind you, you hear ${wilson} reciting the twenty-third Psalm: @{(maddox_num = 1) "De Lord, he my shephurd.  Ah don' want for nuttin'.  He puts me down in de green pastures…"|"The Lord is my shepherd, I shall not want.  He makes me lie down in green pastures…"}
							*finish Next
					*elseif franklin_dead
						*if for_new_york
							*set gallagher_status "decapitated"
							You haul Hugh outside.  
							*goto decap_hugh
						*else
							You haul ${wilson} outside, and begin to lash him to the ground.  The sun will take care of him for you.

							Once you have finished the matter, you turn to reenter your home.
							*goto psalm23
					*else
						*if for_new_york
							*set gallagher_status "decapitated"
							You instruct Franklin to haul Hugh outside.
							*goto decap_hugh
						*else
							You instruct Franklin to haul ${wilson} outside.  "Make sure he greets the sun," you say.  Confident that Franklin can handle the still-tied ${wilson}, you reenter your home.
						
							*goto psalm23
				*if (rationalism > 50) and (knows_stakes and (franklin_dead = false))
					*selectable_if (compassion < 40) #"But, I cannot condemn you to that place.  Instead, you will sleep."
						*set compassion %-10
						*if maddox_num = 3
							*set gallagher_status "buried"
						*else
							*set maddox_status "buried"
						*if bluffs
							With $!{wilson}'s help, you begin digging.  
						*else
							The three of you head to a field not far from your home.  With Franklin's help, ${wilson} begins digging.
						By the time the false dawn has appeared on the horizon, a hole has been dug.
						
						"Thank you," he says.  Nodding, you drive a stake through his heart.  He falls into the hole, @{bluffs and you rush to throw dirt onto him.|and Franklin begins throwing dirt over him.}
						
						The slapdash job finished, you rush home, the sun's first rays nipping at your heels.
						*finish Next
				*if (taste_for_vampire_blood or (applethorp_alive = 3)) and (afflicted_vicksburg = false)
					#"Now I will take back what @{wilson_embraced I gave to you|was given to you in error}.  You were not fit for the blood."
						*goto diablerize_pb
				*if (speaks_english or (maddox_num < 3)) #"I cannot do it."
					*if maddox_num = 3
						*set gallagher_status "dead"
					*else
						*set maddox_status "dead"
					*set compassion %-20
					*set discretion %+5
					*temp suh "suh"
					*if male = false
						*set suh "mam'selle"
					@{maddox_num "But, Ahs deserve it."| "I deserve it."|"But, I deserve to die."}
					
					"Perhaps, but it shall not be by my hand."
					
					@{maddox_num "Please, ${suh}…"|"Please, ${sir}…"|"Please…${given_name}…"}
					
					"Now you are begging me?  To help you die?"
					
					@{maddox_num "Ah's been caught.  Ah's guilty.  Ah don' deserve nuttin else."|"I've been caught. I'm guilty. I don't deserve mercy."|"I have been caught.  I am guilty.  I do not deserve to live."}
					
					"You will have to impale yourself.  Otherwise, you will flee the sun, finding shelter by instinct alone."
					
					@{maddox_num "Ah knows it.  Ah done tried that 'fore."|"I know; I tried before."|"I know.  I have tried before."}
					
					@{bluffs "Then here," you say, offering him a hammer that you brought with you, "I can hold the spike."|"Franklin, fetch this man a hammer and spike."}
					
					You watch as ${wilson} grits his teeth, pounding the spike through his palm and into the earth beneath.  With help, he affixes his feet and good hand.  It is a bloody affair.
					
					When you are finished, you bid him goodbye; the sun is rising. @{(maddox_num = 1) "Thankee," he says.|"Thank you," he says.}
					
					*label walk_away
					*if bluffs
						@{(religious_tradition = "pagan") As you leave, you hear him reciting something unfamiliar.  It sounds like Scripture.|As you leave, you hear him reciting the twenty-third Psalm:}
					*else
						@{(religious_tradition = "pagan") As you reenter your home, you hear him reciting something unfamiliar.  It sounds like Scripture.|As you reenter your home, you hear him reciting the twenty-third Psalm:}
					@{(maddox_num = 1) "De Lord, he my shephurd.  Ah don' want for nuttin'.  He puts me down in de green pastures…"|"The Lord is my shepherd, I shall not want.  He makes me lie down in green pastures…"}

					*if priest and ((rationalism > 50) and ((compassion < 50) and (wilson = "Hugh")))
						*set rationalism %+10
						*set compassion %-10
						You stop in your tracks.  As a priest, it is your duty to offer the last rites to a Catholic that begs for repentance.  You return to Hugh's side, and listen to his last confession.  Once shriven, you commend his soul to heaven; he thanks you for this final kindness.  
						
						@{memphis_haven_torched Unfortunately, you have to find temporary accommodations.  Thankfully, the plague has cleared out enough homes that finding a place for the day isn't too hard.|Your duty finished, you return to your resting-place.  Behind you, a cleansed soul makes its way to heaven.}
					*else
						You hope it is a comfort to him. @{memphis_haven_torched Unfortunately, you have to find temporary accommodations.  Thankfully, the plague has cleared out enough homes that finding a place for the day isn't too hard.|}
					*finish Next

*label consequences_of_torching
*if tiozzo_portrait_1831 = 3
	*set tiozzo_portrait_1831 1

	The portrait that Orelia Tiozzo painted of you lies charred on the ground.
*if kept_clotho_letter and kept_silas_letter
	*set kept_clotho_letter false
	*set kept_silas_letter false

	The letters from Clotho and Silas declaring their eternal love for you are both lost.
*elseif kept_clotho_letter
	*set kept_clotho_letter false

	The letters from Clotho declaring her eternal love for you is lost.
*elseif kept_silas_letter
	*set kept_silas_letter false

	The letters from Silas declaring his eternal love for you is lost.
*return