*comment ñáéç…—
*hide_reuse
*advertisement
*set party_preparations 0
*temp negro "negro"
*temp one_eared_negro "one-eared freedman"
*if chasing_wilson = false
	*set negro "German-Cajun"
	*set negro "Irishman"
	*set one_eared_negro "one-eyed German-Cajun"
	*set one_eared_negro "gap-toothed Irishman"
*temp refreshments false
*temp reception_planner "none"
*temp warning_letter_ignored_bailey false
*temp warning_letter_ignored_lockridge false
*temp coffin_present true
*temp chiara_out false
*temp jesse_out false
*temp timmers_out false
*temp elinor_out false
*temp hope "hope"
*temp hoping "hoping"
*if rationalism >= 60
	*set hope "pray"
	*set hoping "praying"
*temp frightened false
*temp observed_bailey_and_lockridge false
*if first_memphis_reception_attended = 1
	*set observed_bailey_and_lockridge true
*if second_memphis_reception_attended >= 4
	*set observed_bailey_and_lockridge true

As the summer progresses, a sinking feeling begins to descend upon you.  Very much as in '73 and '77, the heat is sweltering.  Moreover, the financial situation of the city means that the streets are cleaned only irregularly, and the sewers that have been installed since the first outbreak of yellow fever get stopped up regularly. @{knows_pb_diseased The city seems ripe for another outbreak.|Even without ${wilson}—if Stennis were to be believed—the city seems ripe for another outbreak.|Even without ${wilson} and his plague, the city seems ripe for another outbreak.}

To make matters worse, another flaw has been discovered in the Nicholson pavement: the wooden blocks absorb liquids, and when the heat becomes oppressive, the blocks release the odors trapped within.  After ten years the wooden blocks are soaked with horse urine and the summer heat means that the whole city is enveloped by the smell.  Most people now walk through town with handkerchiefs over their faces, praying for the wind to blow and provide some momentary relief.
*page_break
*temp time_mentioned false
How do you want to prepare for the upcoming election?
*choice
	#I want to find ${wilson} before the Senators arrive.
		*set discretion %-5
		*set independence %+10
		
		Because the phenomenon is so odd, it goes mostly unreported.  But to your investigating eye, you begin to suspect a pattern: about once a month through the winter, spring, and summer, someone comes down with the yellow fever.  The fever doesn't spread beyond that initial patient, but it is incontrovertibly the same plague.

		You ask the ill about their lives, and they all report the same thing: the recent acquaintanceship of a ${one_eared_negro}.
		
		*if knows_pb_diseased = 3
			Your conclude that your suspicions are sound: ${wilson} carries the plague inside him somehow, without himself dying of it. That certainly makes him dangerous to both vampires and humans.
		*elseif (knows_pb_diseased = 2) and (rationalism < 70)
			*set knows_pb_diseased 3
			Could Stennis be right? Observing the evidence, you don't see how you could come to another conclusion. The only possible answer to this puzzle seems to be the one where ${wilson} somehow carries the Yellow Fever and transmits it to those from whom he feeds.
		*elseif rationalism < 60
			*set knows_pb_diseased 2
			You begin to wonder if ${wilson} is somehow responsible for these outbreaks. What could the connection be?
		*else
			You muse on the misfortune of these people that have come into contact with ${wilson}; to meet one such as he and to fall prey to the Yellow Fever?
			*if religious_tradition = "reformed"
				God must have designated them for suffering.
			*elseif religious_tradition = "catholic"
				God must be punishing them for their crimes.
			*else
				Their misfortunes multiple themselves.				

		Try as you might, though, ${maddox} always seems just ahead of you.  Moreover, unlike you, he seems to only be feeding about once a month, which makes it much harder to identify any sort of pattern or otherwise lay in wait for him.
	*if (transformation_chamber_found) #I want to try to find my way back into the chamber where ${wilson} was hiding.
		*set independence %-5
		You bend your will to finding the underground chamber that you happened upon during your pursuit of ${wilson}.  Unfortunately, the passage is well and clearly blocked.  Consulting an engineer, your suspicions are confirmed: to dig through it would require a civil disturbance of unacceptable magnitude.
		
		However, the engineer is amazed by the quality of the masonry.  He marvels aloud at the question of who could have done this in secret.  His best estimate is that it must have been done before the city was built, or soon thereafter.  At no time since could it have been done without provoking unwanted interest.
	*if (independence > 30) and ((first_memphis_reception_attended = 1) or (second_memphis_reception_attended > 3))
		*selectable_if (wealth > 5000) #Superstitious mummery!  We cannot predict another outbreak!  Instead, I set about planning a reception for the Senators.
			*set independence %+15
			*set discretion %+10
			*if (memphis_reception_planner = "Olivia")
				*label olivia_plans_reception
				*set wealth -5000
				*set reception_planner "Olivia"
				*set party_preparations 2
				You contact Olivia again, and recruit her to plan the reception.  She is only too happy to oblige you.
			*elseif memphis_reception_planner = "Harriet"
				*label harriet_plans_reception
				*if indifferent_to_temperance_workers_plight
					*goto plan_reception_self
				*set wealth -3000
				*set party_preparations 1
				*set reception_planner "Harriet"
				You contact Harriet again, and recruit her to plan the reception.  She gruffly assents.
			*elseif memphis_reception_planner = "Sally"
				*label sally_plans_reception
				*set wealth -3000
				*set reception_planner "Sally"
				*set party_preparations 1
				You contact Sally again, and recruit her to plan the reception.  She accepts the commission without comment.
			*elseif memphis_reception_planner = "Dido"
				*if memphis_reception_planner_1873 = "Olivia"
					*goto olivia_plans_reception
				*elseif memphis_reception_planner_1873 = "Harriet"
					*goto harriet_plans_reception
				*elseif memphis_reception_planner_1873 = "Sally"
					*goto sally_plans_reception
				*else
					*goto plan_reception_self
			*else
				*label plan_reception_self
				*set wealth -(creation*3000)
				*set reception_planner given_name
				*set party_preparations creation
				You set about planning the reception, bending all your creative powers to a soirée that will be remembered throughout the ages.
			*page_break
		*selectable_if (compassion > 35) #Superstitious mummery!  We cannot predict another outbreak!  Instead, I plan on acquiring refreshments for the Senators.
			*set compassion %+20
			*set discretion %+10
			*set independence %+15
			*set refreshments true
			*set time_mentioned true
			A few weeks before the arrival of the Senators, you begin corralling the poor souls who will serve as the refreshments for the guests. @{(compassion < 70) Some part of you is horrified at what you now find commonplace.|}

			The men and women beg and plead with you for mercy.  You turn a deaf ear to their cries.
			
	*if bailey_correspondence or (bailey_contactable and met_bailey)
		#I write to Senator Bailey, to warn him about the danger of the yellow fever, and discourage he and the other supporters of Stone from attending.
			*set compassion %-5
			*if (bailey_rapport > 40) or (revolutionary_credentials > 40)
				*set bailey_rapport %+10
				Senator Bailey's reply is swift.  He thanks you for your providential care for him and the other supporters of Stone.  He promises to write to warn the others immediately.  In closing, he wishes you fortitude during the coming weeks.
				*goto senators_arrival_loyalists
			*else
				*set bailey_rapport %-10
				*set warning_letter_ignored_bailey true
				Your letter is signed, sealed and—presumably—delivered, but no response is forthcoming.
		#I write to Senator Bailey, to frighten him and the other supporters of Stone with the danger of the yellow fever.
			*set discretion %+5
			*if status > 2
				*set frightened true
				Senator Bailey's response is swift.  He thanks you graciously for your warning, and promises to warn his allies of the danger that Memphis would pose to them.
				*goto senators_arrival_loyalists
			*elseif (revolutionary_credentials > 60) or (bailey_rapport > 60)
				Senator Bailey's response is swift.  You can sense his hesitation in trusting you, but apparently feels obligated to do so.  He thanks you graciously, and promises to warn the other supporters of Stone of the danger of traveling to Memphis.
				*goto senators_arrival_loyalists
			*else
				*set bailey_rapport %-10
				*set revolutionary_credentials %-10
				Your letter is signed, sealed, and delivered.  

				The response is filled with scorn; he declares that he sees through your deceptions, and that he will not be dissuaded from attending the election.
	*if lockridge_correspondence or (lockridge_contactable and met_lockridge)
		#I write to Senator Lockridge, to warn him about the danger of the yellow fever, and discourage he and the other supporters of Consul Adonis from attending.
			*set compassion %-5
			*if (lockridge_rapport > 40) or (revolutionary_credentials < 60)
				*set lockridge_rapport %+10
				Senator Lockridge's reply is swift.  He thanks you for your providential care for him and the other loyal members of the Society.  He promises to write to warn the others immediately.  In closing, he wishes you fortitude during the coming weeks.
				*goto senators_arrival_revolutionaries
			*else
				*set lockridge_rapport %-10
				*set warning_letter_ignored_lockridge true
				Your letter is signed, sealed and—presumably—delivered, but no response is forthcoming.
		#I write to Senator Lockridge, to frighten him and the other supporters of Consul Adonis with the danger of the yellow fever.
			*set discretion %+5
			*if status > 2
				*set frightened true
				*set coffin_present false
				Senator Lockridge's response is swift.  He thanks you graciously for your warning, and promises to warn his allies of the danger that Memphis would pose to them.
				*goto senators_arrival_revolutionaries
			*elseif (lockridge_rapport > 60) or (revolutionary_credentials < 40)
				*set coffin_present false
				Senator Lockridge's response is swift.  You can sense his hesitation in trusting you, but apparently feels obligated to do so.  He thanks you graciously, and promises to warn the other supporters of Stone of the danger of traveling to Memphis.
				*goto senators_arrival_revolutionaries
			*else
				*set lockridge_rapport %-10
				*set revolutionary_credentials %+10
				Your letter is signed, sealed, and delivered.  

				The response is filled with scorn; he declares that he sees through your deceptions, and that he will not be dissuaded from attending the election.
	*if municipal_debt > 0
		#I'm too worried about these municipal bonds I still hold.  I'm going to negotiate a sale of them.
			*set independence %-15
			*if (ashmore_banks = 3)
				*set debt_to_ashmore true
				It seems that Senator Ashmore was as good as her word.  Or, rather, you are able to find a representative of a Philadelphia bank willing to buy them at a very reasonable price.
				*set wealth +(municipal_debt*0.3)
			*elseif (technology > 0) and (charm >= 3)
				You manage to set up a scheme where your bonds are invested in the funding of a new set of telegraph cables throughout Tennessee.  While you still are unable to recoup their face value, you are confident that you did the best that you could in recovering some of your money.
				*set wealth +(municipal_debt*0.25)
			*elseif charm > 3
				Using your supernatural charm, you are able to negotiate a better rate than the rest of the city on your remaining notes.
				*set wealth +(municipal_debt*0.20)
			*elseif finance > 0
				Using your skills in finance, you are able to negotiate a marginally better rate than the rest of the city on your remaining notes.
				*set wealth +(municipal_debt*0.18)
			*else
				You are forced to accept fifteen cents on the dollar.  It is not much, but at least it is something.
				*set wealth +(municipal_debt*0.15)
			*set municipal_debt 0

*if wealth < 0
	*set thief true
	*set wealth 0
	*set income +3
	*set discretion %+3
	Due to your improverished conditions, you are forced to begin stealing from those people upon whom you feed. @{(discretion > 55) You reason that this is proper; they already sustain your with their blood, why should they not also help sustain your circumstances?|}
*page_break
As the @{time_mentioned remaining few weeks pass|summer months progress}, you watch helplessly as your worst fears come true. With the sweltering heat comes the fever.  And where the fever goes, death follows close behind. Anticipating the destruction wreaked by the fever the previous year, the wealthier inhabitants of the city depart.

*if feeding_style = "artists"
	Obviously, with their departure, so too goes the artists with means of any sort.  You are forced to resort to the common craftsmen of the city, but you find yourself doing your best to stretch out the time between encounters.  You ache with the hunger, but your choices are limited.  Even when you do feed, you must wait in fear for several hours, lest you fall victim to the fever yourself.
*if feeding_style = "children"
	The children that remain in the city are kept close at hand, making it difficult for you to find yourself alone with them.  You are forced to resort to [i]hoi polloi[/i] to sate your hunger, but you find yourself doing your best to stretch out the time between encounters.  You ache with the hunger, but have no one from whom you care to feed.  Even when you do feed, you must wait in fear for several hours, lest you fall victim to the fever yourself.
*if feeding_style = "clergy"
	The clergy who do not flee the city spring to action, tending to the sick and dying.  Father Martin Walsh, of St. Brigid's, is one of the first to fall.  Unwilling to fall ill yourself, you are forced to resort to [i]hoi polloi[/i], but you find yourself doing your best to stretch out the time between encounters.  You ache with the hunger, but have no one from whom you care to feed.  Even when you do feed, you must wait in fear for several hours, lest you fall victim to the fever yourself.
*if (feeding_style = "drunks") or ((feeding_style = "gamblers") or (feeding_style = "prostitutes"))
	The brothels, public houses, taverns, and [i]crapaud[/i]-dens of the city are closed.  Without those places to frequent, your choice of prey are hard to find.  You are forced to resort to [i]hoi polloi[/i] to sate your hunger, but you find yourself doing your best to stretch out the time between encounters.  You ache with the hunger, but have no one from whom you care to feed.  Even when you do feed, you must wait in fear for several hours, lest you fall victim to the fever yourself.
*if feeding_style = "itinerants"
	Needless to say, under these circumstance, few visitors come calling on Memphis.  Absent your customary prey, you are forced to resort to [i]hoi polloi[/i] to sate your hunger, but you find yourself doing your best to stretch out the time between encounters.  You ache with the hunger, but have no one from whom you care to feed.  Even when you do feed, you must wait in fear for several hours, lest you fall victim to the fever yourself.
*if feeding_style = "laborers"
	Though your customary prey has not fled the city, that does not mean that you do not fear contracting the plague yourself.  Whenever you feed, you must wait in fear for several hours, lest you fall victim to the fever yourself.
*if feeding_style = "socialites"
	Obviously, with their departure, so goes your customary prey.  You are forced to resort to [i]hoi polloi[/i] to sate your hunger, but you find yourself doing your best to stretch out the time between encounters.  You ache with the hunger, but have no one from whom you care to feed.  Even when you do feed, you must wait in fear for several hours, lest you fall victim to the fever yourself.
*if feeding_style = "soldiers"
	Because the veterans of the war are mostly unable to flee the city, many of their number fall ill as well.  You find yourself doing your best to stretch out the occasions on which you feed; you ache with the hunger, and when you do indulge, you spend hours in fear, lest you fall victim to the fever yourself.
*if feeding_style = "vegetarian"
	With proliferation of bodies, and the departure of the living, the city plays host to a new visitor: rats.  Thankfully for you, they have taken the opportunity to multiply, and though you humble yourself to do so, you are able to catch them and drink your fill.  Though they eat upon the corpses of the dead, they do not seem to transmit the plague to you when you consume them.
*page_break
*if (technology > 0) and ((warning_letter_ignored_bailey = false) and (warning_letter_ignored_lockridge = false))
	Though the hour is late, it is possible that a telegraph could reach some of the coming Senators in time.  Would you like to warn someone of the imminent danger?
	*if (independence < 40) and (compassion > 55)
		On the other hand, knowing you, you would probably like for them to all come, just so you can watch their fear and misery.
	*choice
		*if (bailey_correspondence) or ((met_bailey) and (bailey_contactable))
			#Yes, I warn Senator Bailey.
				You rush to the telegraph office, and send the missive without delay.  You ${hope} that your words will reach his ears in time.
				*set bailey_rapport %+10
				*set revolutionary_credentials %+10
				*page_break
				*goto senators_arrival_loyalists_2
		*if (lockridge_correspondence) or ((met_lockridge) and (lockridge_contactable))
			#Yes, I warn Senator Lockridge.
				You rush to the telegraph office, and send the missive without delay.  You ${hope} that your words will reach his ears in time.
				*set lockridge_rapport %+10
				*set revolutionary_credentials %-10
				*page_break
				*goto senators_arrival_revolutionaries_2
		*if (flirting_with_chiara) and ((santagostino_correspondence) or ((met_chiara) and (santagostino_contactable)))
			#Yes, I warn Senator Santagostino.
				*set santagostino_rapport %+15
				You rush to the telegraph office, and send the missive without delay.  You ${hope} that your words will reach her ears in time.
				*set chiara_out true
				*page_break
		*if (jesse_rapport > 40) and (avoided_new_orleans = false)
			#Yes, I warn Jesse.
				You rush to the telegraph office, and send the missive without delay.  You ${hope} that your words will reach his ears in time.
				*set jesse_rapport %+15
				*set jesse_out true
				*page_break
		*if (timmers_on_heresy_of_abraham) and ((timmers_contactable) or (timmers_correspondence))
			#Yes, I warn Senator Timmers.
				*set timmers_rapport %+15
				You rush to the telegraph office, and send the missive without delay.  You ${hope} that your words will reach his ears in time.
				*set timmers_out true
				*page_break
		*if harding_correspondence or ((met_harding) and (harding_contactable))
			#Yes, I warn Quaestor Harding; I may need a new city to call my home soon.
				*set harding_rapport %+15
				You rush to the telegraph office, and send the missive without delay.  You ${hope} that your words will reach her ears in time.
				*set elinor_out true
				*page_break
		#Let them come!  Let them experience this hell on earth!
			*set independence %-15
			*set compassion %+5
		#I will not interfere; I am curious to know how this will unfold.
			*set independence %+10
			*set compassion %+5
*if (first_memphis_reception_attended > 1) and (second_memphis_reception_attended < 4)
	The night when the reception was to occur arrives. Though you have avoided the first two reception, you feel yourself compelled to attend this one. The fact that vampires from across the continent will be descending on Memphis amid this mortal disaster is simply irresistable.
	
	You have heard that Carothers will welcome the guests at a celebration hall on Beale Street. You shake your head in disbelief, unsure as to what horrors are about to unfold.
*elseif reception_planner = "none"
	The night when the reception was to occur arrives.  Senators from across the country have arrived in Memphis, and all too soon you will find yourself in their company.

	Carothers has convened a small gathering at a celebration hall on Beale Street.  You hurry, fearful of being late.
*elseif (compassion >= 50)
	The night of the reception arrives.  Senators have come from across the country for the event.  You arrive at the reception as early as possible, ${hoping} that the plague will not put a damper on your soirée.
*else
	The night of the reception arrives.  Senators have come from across the country for the event.  You arrive at the reception as early as possible, ${hoping} that the senators will not judge you too harshly for your preparations, when the city is falling apart around you.
*page_break
*gosub warned_off

*if party_preparations = 0
	The gathered senators are clearly unimpressed by the décor.  However, their disappointment has only just begun.
*if party_preparations = 1
	The gathered senators are clearly unimpressed by the décor.  However, considering what Carothers is about to say, you suppose that they should be grateful for your efforts.
*if party_preparations = 2
	*gosub party_fives
*if party_preparations >= 3
	*gosub party_tens
*if (perception >= 2) and observed_bailey_and_lockridge
	Though they stand on opposite sides of the room from each other, Bailey and Lockridge do not radiate animosity at each other for once.  Whatever is coming, they are in agreement about it.

Finally, Carothers enters the room; Dido is conspicuously absent.  His face is a mask of resolution.  When he opens his mouth to speak, the room falls silent.

*if speaks_english
	"Welcome, Senators, to the city of Memphis…" he begins.

	@{heard_of_lockridge "Please, Quaestor Carothers," Senator Lockridge interrupts.|"Please, Quaestor Carothers," a man with the lilt of the Carolinas interrupts.  Dressed in the garb of a colonial planter, he is clearly displeased.} You thought it impossible for the room to become any more silent, but it does. @{((perception >= 3) and met_bailey) Though you might have expected him to leap to Carothers's defense, you note that Bailey does not flinch at the interjection.|} "There is no longer a city to which you might welcome us."

	Carothers's face remains impassive.  "I did not invite you here, Senator.  It was the decision of the Senate to elect a Senator for Memphis.  My opinion was neither sought nor given weight when offered."

	"Perhaps that is true, Quaestor," @{heard_of_bailey Bailey|a clean-shaven man} interjects, "but it is normally seen as a blessing to have so many illustrious members of the Society in one's city.  You, however, seem determined to drive us away."

	A little voice in your head answers on behalf of Carothers, retorting loudly, "As a matter of fact, yes.  Please leave my city.  Now." @{(independence <= 40) Unfortunately,|Instead,} Carothers takes a moment to consider his words before replying.  "Honored guests, I mean no disrespect.  The city has suffered a series of misfortunes from which it will take decades to recover.  Perhaps there would be another time at which you might convene, when we are not all discomfited by the troubles that currently afflict Memphis."

	@{heard_of_bailey Bailey is the first to respond.  "Have no doubt, Quaestor…"|The clean-shaven man is first to respond.  "Have no doubt, Quaestor…"}
	
	"…it will be quite some time before the Senate gathers in your city to elect a Senator again," finishes @{heard_of_lockridge Lockridge.|the man from the Carolinas.}

	"It is kind of you to hold out the hope of such a possibility, no matter how distant," Carothers replies perfunctorily.

	"We are happy to offer you such small comfort," @{heard_of_lockridge Lockridge says.|says the man from the Carolinas.} @{(perception > 2) His upper lip quivers with fury.|}
	
	"Now, good Senators, is there anything left to discuss?"  Carothers inquires.  
	*if heard_of_bailey and heard_of_lockridge
		Bailey and Lockridge look at each other, and once their gaze is broken, Bailey shakes his head "no,"
	*if heard_of_bailey and (heard_of_lockridge = false)
		Bailey and the man from the Carolinas look at each other, and once their gaze is broken, Bailey shakes his head "no,"
	*if (heard_of_bailey = false) and (heard_of_lockridge)
		The clean-shaven man and Lockridge look at each other, and once their gaze is broken, the clean-shaven man shakes his head "no,"
	*if (heard_of_bailey = false) and (heard_of_lockridge = false)
		The two interlocutors look at each other, and once their gaze is broken, the clean-shaven man shakes his head "no," 
	ever so slightly.
	*goto dismissal
*else
	He addresses the room in English, though it is clearly a welcoming address.

	Suddenly, @{heard_of_lockridge Lockridge|a man in the garb of the colonial elite} interrupts. He and Carothers exchange sharp words.

	In the end, Carothers seems to tell all the guests to leave. Whether the hall or the city, you're unsure, but one would surely lead to the other.

	Before he leaves, the man from the Carolinas makes a final verbal jab, leaving Carothers steaming in his absence.

	Quickly, the rest of the guests depart.
	*goto dismissal

*label party_fives
*set applethorp_rapport %+5
*set ashmore_rapport %+5
*set bailey_rapport %+5
*set bowater_rapport %+5
*set carothers_rapport %+5
*set coffin_rapport %+5
*set davison_rapport %+5
*set harding_rapport %-5
*set lesczynski_rapport %+5
*set lockridge_rapport %+5
*set malloy_rapport %+5
*set partridge_rapport %+5
*set pickering_rapport %+5
*set simmons_rapport %+5
*set timmers_rapport %+5
*if chiara_out = false
	*set santagostino_rapport %+5
*if jesse_out = false
	*set jesse_rapport %+5
The senators seem indifferent to the décor.  Considering what Carothers is about to say,
*if compassion > 50
	they should be grateful that any effort was expended on their behalf.
*if compassion <= 50
	they are unlikely to remember much past their impending fury anyway.
*if knows_hardings_plan or (perception > 3)
	The one exception to this is Quaestor Harding, who seems to be observing everything with a scowl on her face.
*return

*label party_tens
*set applethorp_rapport %+10
*set ashmore_rapport %+10
*set bailey_rapport %+10
*set bowater_rapport %+10
*set carothers_rapport %+15
*set coffin_rapport %+10
*set davison_rapport %+10
*set harding_rapport %-10
*set lesczynski_rapport %+10
*set lockridge_rapport %+10
*set malloy_rapport %+10
*set partridge_rapport %+10
*set pickering_rapport %+10
*set simmons_rapport %+10
*set timmers_rapport %+10
*if chiara_out = false
	*set santagostino_rapport %+10
*if jesse_out = false
	*set jesse_rapport %+10
Despite their efforts at nonchalance, the gathered senators are clearly impressed by your efforts.
*if knows_hardings_plan or (perception > 3)
	The one exception to this is Quaestor Harding, who seems to be observing everything with a scowl on her face.
In the few minutes @{(discretion >= 40) available to you before anyone address the gathering, you make sure to let it be known that the effort expended was all your doing.|before anyone addresses the gathering, you overhear Lesczynski giving you the credit for your efforts.}
*return

*label warned_off
You look around the room.  The gathered vampires are clearly on edge, their eyes twitching at the threat of an impending hunger.  There is no emergency yet, but the condition of the city combined with the number of blood-sucking guests puts everyone on edge.
*if chiara_out
	To your relief, Chiara is not one of the arrivals.  She must have received your missive in time!
*if jesse_out
	To your relief, Jesse is not one of the arrivals.  He must have received your missive in time!
*if timmers_out
	To your relief, Girard is not one of the arrivals.  He must have received your missive in time!
*if elinor_out
	To your relief, Elinor is not one of the arrivals.  She must have received your missive in time!
*return

*label senators_arrival_loyalists
*page_break
*set bailey_rapport %+10
As the summer months progress, you watch helplessly as your worst fears come true.

With the sweltering heat comes the fever.  And where the fever goes, death follows close behind.
*page_break
*label senators_arrival_loyalists_2
*if reception_planner = "none"
	The night when the reception would have occurred arrives.  Senators from across the country have arrived in Memphis, and all too soon you will find yourself in their company.

	Carothers has convened a small gathering at a celebration hall on Beale Street.  You hurry, fearful of being late.
*if (reception_planner != "none") and (compassion >= 50)
	The night of the reception arrives.  Senators have come from across the country for the event.  You arrive at the reception as early as possible, ${hoping} that the plague will not put a damper on your soirée.
*if (reception_planner != "none") and (compassion < 50)
	The night of the reception arrives.  Senators have come from across the country for the event.  You arrive at the reception as early as possible, ${hoping} that the senators will not judge you too harshly for your preparations, when the city is falling apart around you.
*page_break
You look around the room.  The gathered vampires are clearly on edge, their eyes twitching at the threat of an impending hunger.  There is no emergency yet, but the condition of the city combined with the number of blood-sucking guests puts everyone on edge.
*if elinor_out
	To your relief, Elinor is not one of the arrivals.  She must have received your missive in time!
*if party_preparations = 0
	The gathered senators are clearly unimpressed by the décor.  However, their disappointment has only just begun.
*if party_preparations = 1
	The gathered senators are clearly unimpressed by the décor.  However, considering what Carothers is about to say, you suppose that they should be grateful for your efforts.
*if party_preparations = 2
	*gosub party_fives
*if party_preparations >= 3
	*gosub party_tens
*if frightened
	*set lockridge_rapport %+10
	*set revolutionary_credentials %-10
	*if heard_of_lockridge
		*set met_lockridge true
		In the tumult, Senator Lockridge approaches you.  "Are you the reason that Stone's supporters are not here this evening?"
		
	*if heard_of_lockridge = false
		*set heard_of_lockridge true
		*set met_lockridge true
		In the tumult, a man in colonial planter's garb approaches you.  "Are you the reason that Stone's supporters are not here this evening?"  His voice bears the sonorous lilt of the Carolinas.
		
		"I'm sorry, but we haven't been introduced…"
		
		"I am Arthur Lockridge, Senator of Charleston.  Now, answer my question."
		
	"I am, Senator."
	
	"We appreciate your efforts, ${mr} ${surname}.  Unfortunately, circumstances have intervened to render your efforts naught."

	"That is unfortunate."

	"Do not think that they have gone unnoticed, however."

	"Thank you, Senator."
	*page_break

Finally, Carothers enters the room; Dido is conspicuously absent.  His face is a mask of resolution.  When he opens his mouth to speak, the room falls silent.

"Welcome, Senators, to the city of Memphis…" he begins.

"Please, Quaestor Carothers," @{heard_of_lockridge Senator Lockridge interrupts.|a man in colonial planter's garb interrupts.} You thought it impossible for the room to become any more silent, but it does. @{((perception >= 3) and met_bailey) Though you might have expected him to leap to Carothers's defense, you note that Bailey does not flinch at the interjection.|} "There is no longer a city to which you might welcome us." @{heard_of_lockridge |He speaks in the sonorous lilt of the Carolinas.}

Carothers's face remains impassive.  "I did not invite you here, Senator.  It was the decision of the Senate to elect a Senator for Memphis.  My opinion was neither sought nor given weight when offered."

"Perhaps that is true, Quaestor," @{heard_of_lockridge Lockridge continues,|the man from the Carolinas continues.} "but it is normally seen as a blessing to have so many illustrious members of the Society in one's city.  You, however, seem determined to drive us away."

A little voice in your head answers on behalf of Carothers, retorting loudly, "As a matter of fact, yes.  Please leave my city.  Now." @{(independence <= 40) Unfortunately,|Instead,} Carothers takes a moment to consider his words before replying.  "Honored guests, I mean no disrespect.  The city has suffered a series of misfortunes from which it will take decades to recover.  Perhaps there would be another time at which you might convene, when we are not all discomfited by the troubles that currently afflict Memphis."

@{heard_of_lockridge Lockridge takes a moment before responding.|The man from the Carolinas takes a moment before responding.} "Have no doubt, Quaestor, it will be quite some time before the Senate gathers in your city to elect a Senator again."

"It is kind of you to hold out the hope of such a possibility, no matter how distant," Carothers replies.

"We are happy to offer you such small comfort," @{heard_of_lockridge says Lockridge.|says the man from the Carolinas.} @{(perception > 2) His upper lip quivers with fury.|}

"Now, good Senators, is there anything left to discuss?"  Carothers inquires of the room. @{heard_of_lockridge Lockridge shakes his head no ever so slightly.|His interlocutor shakes his head no ever so slightly.}
*goto dismissal

*label senators_arrival_revolutionaries
*set lockridge_rapport %+10
As the summer months progress, you watch helplessly as your worst fears come true.

With the sweltering heat comes the fever.  And where the fever goes, death follows close behind.
*page_break
*label senators_arrival_revolutionaries_2
*if reception_planner = "none"
	The night when the reception would have occurred arrives.  Senators from across the country have arrived in Memphis, and all too soon you will find yourself in their company.

	Carothers has convened a small gathering at a celebration hall on Beale Street.  You hurry, fearful of being late.
*if (reception_planner != "none") and (compassion >= 50)
	The night of the reception arrives.  Senators have come from across the country for the event.  You arrive at the reception as early as possible, ${hoping} that the plague will not put a damper on your soirée.
*if (reception_planner != "none") and (compassion < 50)
	The night of the reception arrives.  Senators have come from across the country for the event.  You arrive at the reception as early as possible, ${hoping} that the senators will not judge you too harshly for your preparations, when the city is falling apart around you.
*page_break
*gosub warned_off

*if party_preparations = 0
	The gathered senators are clearly unimpressed by the décor.  However, their disappointment has only just begun.
*if party_preparations = 1
	The gathered senators are clearly unimpressed by the décor.  However, considering what Carothers is about to say, you suppose that they should be grateful for your efforts.
*if party_preparations = 2
	*gosub party_fives
*if party_preparations >= 3
	*gosub party_tens
*if frightened
	*set bailey_rapport %+10
	*set revolutionary_credentials %+10
	*if heard_of_bailey
		*set met_bailey true
		In the tumult, Senator Bailey approaches you.  "Are you the reason that Stone's opponents are not here this evening?"

	*if heard_of_bailey = false
		*set heard_of_bailey true
		*set met_bailey true
		In the tumult, a clean-shaven man approaches you.  "Are you the reason that Stone's opponents are not here this evening?"
		
		"Excuse me?"
		
		"Yes, yes, we have not yet met.  I am John Bailey, Senator of St. Louis.  Now, answer my question: are the origin of this?"

		After considering for a moment, you decide to be truthful:
	"I am, Senator."

	"We appreciate your efforts, ${mr} ${surname}.  Unfortunately, circumstances have intervened to render your efforts naught."

	"That is unfortunate."

	"Do not think that they have gone unnoticed, however."

	"Thank you, Senator."
	*page_break

Finally, Carothers enters the room; Dido is conspicuously absent.  His face is a mask of resolution.  When he opens his mouth to speak, the room falls silent.

"Welcome, Senators, to the city of Memphis…" he begins.

"Please, Quaestor Carothers," @{heard_of_bailey Senator Bailey interrupts.|a clean-shaven man interrupts.} You thought it impossible for the room to become any more silent, but it does.
*if (perception >= 3) and (met_bailey)
	Though you might have expected him to leap to Carothers's defense, you note that Bailey does not flinch at the interjection.
"there is no longer a city to which you might welcome us."

Carothers's face remains impassive.  "I did not invite you here, Senator.  It was the decision of the Senate to elect a Senator for Memphis.  My opinion was neither sought nor given weight when offered."

"This is true, Quaestor,"  @{heard_of_bailey Bailey continues,|the clean-shaven man continues,} "but it is considered a blessing to have so many illustrious members of the Society in one's city.  Unfortunately, events have conspired to turn our visitations into curse."

A little voice in your head answers on behalf of Carothers, retorting loudly "As a matter of fact, yes.  Please leave my city.  Now." @{(independence <= 40) Unfortunately,|Instead,} Carothers takes a moment to consider his words before replying.  "Honored guests, I mean no disrespect.  The city has suffered a series of misfortunes from which it will take decades to recover.  Perhaps there would be another time at which you might convene, when we are not all discomfited by the troubles that currently afflict Memphis."

@{heard_of_bailey Bailey takes a moment before responding.|The clean-shaven senator takes a moment before responding.} "Alas, Quaestor, it will be quite some time before the Senate gathers in your city to elect a Senator again."

"It is kind of you to hold out the hope of such a possibility, no matter how distant," Carothers replies.

"We are happy to offer you such small comfort," @{heard_of_bailey Bailey says.|he replies.} @{(perception > 2) His upper lip quivers with fury.|}

"Now, good Senators, is there anything left to discuss?"  Carothers inquires of the room.  @{heard_of_bailey Bailey shakes his head no ever so slightly.|His interlocutor shakes his head no ever so slightly.}

*label dismissal
Observing this, Carothers 
*if speaks_english
	continues: "I thank you all for the efforts you made to be here this evening.  I hope that you find your way home safely."  His duties concluded, he turns and exits the room.
*else
	addresses the room in English. You infer that it is some sort of farewell, as he exits the room at its conclusion.

Though the guests are too polite to speak their frustration, you can feel waves of anger undulating through the room.  You have to wonder how long Carothers will be able to hold on to his quaestorship after this.

*if coffin_present and (lesczynski_out and offer_to_help_coffin_stop_ascher)
	*set debt_from_coffin true
	*set coffin_rapport %+20
	Before she leaves, Senator Coffin stops and speaks with you.  "We have succeeded in our designs."
	
	"Excuse me?"
	
	"Mr. Lesczynski.  He will never be Senator of Memphis.  And for that, I have you to thank."
	
	"I am glad that I could be of service to you, Senator."
	
	"Someday, you may call on me to return the favor."
	
	"Thank you," you reply.  
	*if coffin_contactable
		She nods, and follows the other vampires out.  
	*else
		*set coffin_contactable true
		She takes a final moment to explain how to contact her, should you need to write her.  She nods a final farewell, and follows the other vampires out.
	
	Once her back has turned, you find it hard to suppress a grin.  A debt from a senator! That is quite a prize indeed. @{(independence < 35) You're actually a little disgusted by the thrill that courses through your body at the news. You have often sought to distance yourself from the machinations of the Society, and here you find yourself rejoicing in them.|}
	*page_break
*if speaks_english
	Once the gathered senators have departed, you take a moment to reflect on what transpired here this evening.
	*choice
		#Carothers was right to hold his tongue.  If he wants to retain his position, he must keep the Senate happy.
			*set independence %+20
			*set discretion %-10
			You understand his discretion.  By not speaking out, he did not worsen a situation that was already extremely dangerous for him.  You are fortunate to have the opportunity to watch a young quaestor at work.
		#Carothers is the victim here.  He should not be punished for the calamities that have befallen the city.
			*set compassion %-20
			*set discretion %-10
			Your sympathy for Carothers is noteworthy.  He would probably reject any overtures of support, but that does not mean you cannot hold them in your heart.
		#Carothers should have stood up to the Senate.  It was embarrassing to watch him be so meek.
			*set discretion %+15
			*set independence %-15
			Perhaps someday, when you are a quaestor, you will be free to improve upon Carothers's decisions.  Until then, you are relegated to imagining how you would put those insolent Senators in their place.
		#Carothers is an embarrassment to vampire kind.  I would have torn the fangs out of the head of any vampire who spoke to me like that.
			*set compassion %+20
			*set discretion %+30
			@{(independence > 40) Perhaps someday, when you are a quaestor, you will be free to act upon your more murderous impulses.  A wide grin splits your face at the thought.|If only the pressures of the Society didn't prevent you from acting on these impulses.}
		*if party_preparations > 0
			#Really, I'm just glad the whole matter is over.  Playing host was getting tiring.
				*set independence %-10
				*set compassion %+10
				The effort that you have expended on the behalf of these individuals has gone completely unrewarded.  Good riddance to the whole affair.

	The second thing that crosses your mind is, why wasn't @{(applethorp_rapport > 55) Dido|Applethorp} present?
*if speaks_english = false
	You wish you could have better understood what transpired here this evening.

The other vampires now gone, a silence settles over the hall.  A silence so still you wonder if they were ever there in the first place.
*finish Next