*comment ñáéç
*hide_reuse
*advertisement
*gosub_scene util check_flow
*temp mr_gullah "Massa'"
*if male = false
	*set mr_gullah "Mam'selle"
*temp dido_introduced false
*temp seeking_quaestor false
*temp only_vampires false
Founded by Andrew Jackson and John Overton in 1819, Memphis was named for the ancient capital of the Egyptians.  Captured early on in the war, it prospered as a staging ground for the invasion of the Confederacy by the Union armies.  This drew two groups in particular: unskilled Irish laborers, seeking employment in the war effort; and former slaves, seeking both their freedom and some sort of respite from the conflict.

*if fled_from_vicksburg = false
	Those former slaves were given rations by the Union army as long as the war continued, and even for some time afterwards.  In recent months, however, the Federal Government has withdrawn the distribution of food, and the city is roiled by unrest.  On May 1st, 1866, the mostly Irish police force riots against the blacks, murdering, assaulting, and raping their way through the "refugee" section of town.  When the dust settled, over a hundred buildings had been burned down, including churches and schools.

	Since then, an uneasy peace has fallen over the city.
	*page_break
*if introduction_made_to_carothers_by_withers
	*if (ethnicity != "african") and (ethnicity != "choctaw")
		Your arrival in Memphis is a smooth one.  You take a room at a hotel while you look for a more permanent haven, and leave a note at the post office as to how Quaestor Carothers can reach you.
		*if literate = false
			Thankfully, you'd had the foresight to have Withers compose such a note for you before you left Vicksburg.
	*else
		*if wealth <= 250
			*set wealth 0
		*else
			*set wealth -250
		Your arrival in Memphis is a—relatively—smooth one.  Unfortunately, the hotels of the city will not offer you a room.  Moreover, the boarding houses in the black section of town do not inspire confidence in you; the risk of sunlight and interruption is too great.  Instead, you are forced to dig a grave to rest in each night.  This does nothing for the condition of your clothing.
		
		That aside, you leave word for Carothers at the post office, arranging for a meeting. @{literate |Thankfully, you'd had the foresight to have Withers compose such a note for you before you left Vicksburg.}
	*goto note_from_carothers
*elseif exiled_from_vicksburg
	
	You are grateful to have found some small amount of respite; your flight from Vicksburg has given you little chance to rest.  Here, much to your relief, Samantha Withers holds no sway.
	
Surely there is a quaestor here; it goes without saying that you are obligated to present yourself to them, in accordance with the Rule of Respect.
*choice
	#I seek out the Quaestor.
		*set independence %+5
		*set seeking_quaestor true
		*if (ethnicity = "african")
			At first, you are surprised at how easy it is to find evidence of vampirism in Memphis, but once you lay your eyes on the offspring of the quaestor, it is clear why you found them so quickly.
			*label discover_dido

			The two of you lock eyes from across the square. @{(perception > 2) Suspicious, you extend your mind to confirm that she is one like you.|Even though she is too far for you to sense whether she breathes or has a pulse, she wears the attitude of a predator.} The mortals unconsciously make way as she approaches you.  

			She is tall for a woman, her hair cut close to her scalp, and she wears a sleeveless dress that eschews any sense of fashion.  As she nears, her choice of clothing gains even more significance, as you note the network of lash-marks across her upper arms.  All signs point to their continuing well out of sight.
			*if speaks_english
				*goto meet_dido_without_introduction
			*else
				*label cant_converse_with_dido
				*set applethorp_rapport %-5
				
				Seeing that she does not seem interested in hearing what you have to say, you listen politely as she launches into a tirade.  From her tone, you gather that she is displeased that you have taken up residence in Memphis without a letter of introduction.  When she finally pauses, presumably to give you a chance to defend yourself, you finally make it known to her that you have not understood a word that she has said.
			
				She throws her hands up in despair.  After a few invocations to the heavens, invocations which clearly go unanswered, she finally motions for you to follow her.
				*page_break
				*goto meet_carothers
		*elseif streetwise > 1
			Your investigation of the watering-holes and bordellos soon leads you to a [i]crapaud[/i]-den in the southern part of the city.  Here, you soon lay your eyes upon a particular freedwoman.  She is tall, her hair cut close to her scalp, and she wears a sleeveless dress that eschews any sense of fashion.  As she nears, her choice of clothing gains even more significance, as you note the network of lash-marks across her upper arms.  All signs point to their continuing well out of sight.
			
			The mortals part before her unconsciously as she makes her way to you.
			*if speaks_english
				*goto meet_dido_without_introduction
			*else
				*goto cant_converse_with_dido
		*else
			You begin to make your way through the normal channels—spending time where the rich and fashionable spend their evenings—but you can uncover no evidence of vampires in the city.
			*if (streetwise > 0) and (ethnicity != "irish")
				
				Once the standard avenues are exhausted, you turn to some of the more shady pathways, seeking out the brothels and the gambling parlors.  In this you are rewarded, as you learn of a man by the name of Apollo Carothers who rules the shantytown that has sprung up to house the flood of freedmen.
				
				By means of intermediaries, you soon arrange a meeting with a representative of Carothers.
				*page_break
				*goto meet_dido_without_introduction
			*else
				*goto cornered_by_apollo
	*if chasing_wilson
		*selectable_if (independence < 50) #I'm here for ${wilson}.  I don't really care about the quaestor.
			*set independence %-10
			*set discretion %+10
			You spend the next few weeks trying to track down ${wilson}.  It is frustrating, as at first, you find several people who claim to have seen him, but soon the trail goes cold.
			
			On your way back to your quarters one morning, however, you feel that you are no longer alone.
			*goto cornered_by_apollo
	*selectable_if (independence < 60) #I let the Quaestor come to me.
		*set discretion %+15
		*set independence %-15
		Deciding it best to let the Quaestor come to you; after all, if he can't find you, he isn't much of a quaestor, is he?
		
		That said, it is not long before someone finds you.
		*page_break
		*goto discover_dido

*label note_from_carothers
A few days later, you check back at the post office, and discover a reply.
*if literate and speaks_english
	In the note, Carothers invites you to join him the following evening.  He anxiously awaits the opportunity to meet you in person.
*elseif speaks_english = false
	*if wealth <= 1000
		*set wealth 0
	*else
		*set wealth -1000
	It is challenging to find an attorney that speaks your tongue, but eventually you do.  You have him read and translate the note for you.

	In it, Carothers welcomes you to the city, and invites you to join him this very evening; you will have to worry, lest he think you impolite.  The note says that he anxiously awaits the opportunity to meet you in person.

	Taking the note from the attorney, you hastily recommend that he not mention this to anyone.  He assures you of his discretion.
	*if (compassion > 50) or (discretion > 50)
		The thought occurs to you that you might kill the attorney, but it would take so long to dispose of the body, and besides, finding this one was challenging enough.  Finding a replacement would likely be even more so.
	*page_break
	*goto meet_carothers
*else
	*if wealth <= 5
		*set wealth 0
	*else
		*set wealth -5
	Taking the note, you set out to find someone to read it to you.  For a quarter, you persuade a schoolboy to read it aloud.
	
	In the note, Carothers welcomes you to the city, and invites you to join him the following evening.  He anxiously awaits the opportunity to meet you in person.
	
	Taking the note from the boy, you recommend to him that he not mention this to anyone.  The boy nods sagely.
*page_break

*if speaks_english = false
	Following the instructions in the note, you go the meeting-place: a particular public bench in Court Square.

	It is not long before you approached by your contact, a black woman wearing a simple, sleeveless dress.  She clearly cares little for the fashions of the day, as the well-dressed sport bustles, parasols, sleeves and petticoats.  However, the choice is even more provocative for its disclosure of a network of lash-marks on her upper arms, and all signs point to those scars continuing well out of sight.

	She attempts to greet you, but you soon find that she only speaks English.  All the same, she invites you to follow her to meet the Quaestor.
	*page_break
	*goto meet_carothers
"You mus' be ${mr_gullah} ${surname}.  Ah's Dido Applethorp.  Itsa pleasure to make yous acquaintance."  The person speaking to you is a tall, black woman that moves with the grace of a predator.  She wears a simple, sleeveless dress.  She must care little for the fashions of the day, as the well-dressed sport bustles, parasols, sleeves and petticoats.  However, the choice is even more provocative for its disclosure of a network of lash-marks on her upper arms, and all signs point to those scars continuing well out of sight.
*set dido_introduced true

The two of you are standing at an intersection in the refugee quarter of Memphis.  The surrounding buildings mostly look like a stiff wind could knock them down.
*choice
	#"It is a pleasure to make your acquaintance, Miss Applethorp.  I trust that Quaestor Carothers is prepared for me?"
		*set applethorp_rapport %+10
		"He be 'spectin you."
		
		"Please, lead the way,"
		*if male and (discretion > 50)
			*set applethorp_rapport %+10
			you say with a flourish.  Smiling at your gallantry, she puts her arm through yours, and off the two of you go, threading your way through the recently rebuilt neighborhood.
			*goto meet_carothers
		*else
			you reply.  She seems a little relieved that you have not made this situation difficult for her.  Building on the moment, you offer her your arm, which she takes.  Within moments, the two of you are threading your way through the recently rebuilt neighborhood.
			*goto meet_carothers
	*if compassion > 50
		*selectable_if (discretion > 40) #"It seems that you have a hard time learning from your mistakes," I observe, nodding towards her scars.  "I trust I will not have to treat you similarly?"
			*set discretion %+15
			*set compassion %+5
			*set applethorp_rapport %-25
			*set carothers_rapport %-15
			Dido looks as though she has been slapped across the face, but soon surprise turns to a bristling anger.
			*if status > 1
				She opens her mouth to reply, but then shuts it again, apparently thinking better of her words.  After another moment of silent struggle, she speaks: "Please, ${mr_gullah} ${surname}, Quaestah Carudders be 'spectin you.  Ifn you'd fallah me."
				
				She turns on her heel and starts off, seemingly indifferent to whether or not you follow.
				*goto meet_carothers
			*else
				*set applethorp_rapport %-10
				*set carothers_rapport %-5
				"Is yous always so rude ta yourn hosts?"
				
				"Only when they are as unattractive as yourself.  Tell me, did your maker turn you just so he could laugh at you for all of eternity?"
				
				You can see the rage building behind her eyes.  Somehow, though, she manages to get the better of it.  "Was you not here on bidness fuh Quaestah Withers, Ah woulds pluck you like uh chicken here an' now.  Come, de quaestah be waitin'."
				
				She turns on her heel and starts off, seemingly indifferent to whether or not you follow.
				*goto meet_carothers
	*if (ethnicity != "african") and (ethnicity != "choctaw")
		*selectable_if (discretion > 35) #"What sort of quaestor would deign reside in such a wretched section of town?"
			*set discretion %+10
			*set applethorp_rapport %-5
			"Quaestah Carudders likes dah company o' his folks.  He wants tah help dem when deys in need, like now."
			
			*choice
				*selectable_if (compassion < 60) #"He aids his former people?  That is noble of him."
					*set compassion %-5
					*set applethorp_rapport %+10
					"Ahs heard tell dat the other quaestah don' do the same.  Dat be true?"

					"Most certainly not.  I have never met one that took an interest in the well-being of the mortals of his city."

					"Ahs always knows he wuz special."
					*goto meet_carothers
				*if shepherds_and_wolves
					*selectable_if (discretion > 40) #"He considers himself a shepherd, then?"
						*set discretion %+5
						She looks at you blankly. "Uh shepherd? Ah hope you ain't…"
						
						"No, no…I meant nothing. Please, lead the way."
						
						Still confused, she gestures for you to follow.
						*goto meet_carothers
				*selectable_if (compassion > 40) #"He aids his former people? How quaint!"
					*set compassion %+5
					*set discretion %+5
					*set applethorp_rapport %-10
					*set carothers_rapport %-5
					"Quaint?"
					
					"Yes, that he still cares about the mortals. I suppose he moans about the steady erosion of his humanity as well? And does he seek to cause as little pain as possible when he feeds?  Yes, I know the type."
					
					"He ain't doin' nuttin' wrong…"
					
					"Yes, but that's just it, don't you see!  He does nothing wrong!  Why bother being immortal if you're going to do nothing wrong?"	 Applethorp stops at this question, as though she were considering it for the first time.  "Don't think on it too long, now.  We might be here all night, and into next year.  Come, lead the way."
					
					Too confabulated to devise a retort, she simply nods and begins to make her way through the shantytown.
					*goto meet_carothers
				*if religious_tradition = "catholic"
					*selectable_if (discretion > 40) #"Does he seek to repent for some sin?"
						*set discretion %+5
						Dido narrows her eyes at your bluntness.  "Ain't no sin uh which Ah's aware.  Now, he be waitin' on us."
						
						"Yes, please, lead the way."
						
						She turns sharply and begins to make her way through the shantytown.
						*goto meet_carothers
	*if (independence < 60) and chasing_wilson
		*selectable_if (discretion > 35) #"Believe me, I would have preferred to have come and gone without having to disturb you, but Quaestor Withers insisted on my following protocol."
			*set discretion %+5
			*set applethorp_rapport %-5
			*set carothers_ignorant_of_pb false
			"Ah 'spect that it woulda disturbed Quaestah Carudders ta' learn that yous done come and gone wid'out introducing yo'self, so Ah say that she done made the right choice.  For yourn sake, anyway."
			
			"That is possible.  Now, please, lead the way."
			
			She turns sharply and begins to make her way through the shantytown.
			*goto meet_carothers

*label meet_dido_without_introduction

"You don' belong heah."

"Is that any way to greet a guest?"

"Mayhaps.  Who is you, whatcha doin' here, and why ain't you made a beeline for Quaestor Carothers?"
*if seeking_quaestor
	
	"I apologize. I was looking for them, but did not know either their name nor how to contact them."
	
	She harrumphs. "Well, go on then. Who is you an' what is you doin' here?"

"My name is ${given_name} ${surname},
*if chasing_wilson and (discretion > 55)
	and I am here chasing an errant young vampire by the name of ${wilson} ${maddox}.  I hope to find and deal with him before he brings any misfortune to your city."
	
	"Ah ain't met no ${maddox}.  But its good to meet you. Mah name is Dida Applethor'."
	
	"Well, it is a pleasure to make your aquaintance, Ms. Applethorp.  About ${wilson}, though…it seems that he has done a better job than I was anticipating of blending in.  Perhaps you would be so kind as to take me to your quaestor, so that I can get the formalities out of the way?"
	
	"Yeayah, Ah think that'd be right smart of yourself," she replies.  "Why doncha come with me now?"
	
	"With pleasure," you say with a ${bow}.
*elseif (status > 1) and (charm > 2)
	*set applethorp_rapport %+10
	*set carothers_rapport %+10
	and I came here seeking a new home.  I have heard tell the wonders of Memphis, and I thought to come and see it for myself."

	She looks at you askance, seemingly skeptical of your pretty words.  "Ah don' know 'bout no wonders, but you can see fo' yo'self, I s'pose. Mah name is Dida Applethor', an' Ahs the chillun o' Apallah Carudders.  Please, ${mr_gullah} ${surname}, why doncha come wid me?"
	
	"Lead the way, Miss Applethorp."
*else
	and I am seeking a new home.  Vicksburg was becoming rather tiresome."
	*set applethorp_rapport %-5
	*set carothers_rapport %-10
	
	*if seeking_quaestor
		"Wul, Ah s'pose you done right by comin' tah find me.
	*else
		"And you don' think it importune' tah make the 'kwaintance o' the quaestah o' this here city?"
		
		"Well, if the quaestor were worth the title, I figured that he would make himself known to me."
		
		"Ah would say dat question's done been answered.  
	Mah name is Dida Applethor', an' Ahs the chillun o' Apallah Carudders.  Please, ${mr_gullah} ${surname}, why doncha come wid me?"
		
	"Lead the way, Miss Applethorp."

*label meet_carothers
*page_break
*set presented_memphis true
*if speaks_english = false
	Thankfully, Quaestor Carothers is conversant in your tongue.

"…and so, Quaestor Carothers, I humbly request your permission to @{chasing_wilson reside in your city until I have located my quarry."|take up residence in your fair city."} 
*if chasing_wilson
	*set carothers_ignorant_of_pb false

You stand before Apollo Carothers, attempting to suppress an instinctual fear of this individual.  He is a former slave, possessed of a strength both internal and external; he moves with a confidence born of decades spent laboring under the sun.  Even from this distance, you can clearly see the size of his hands: massive and deadly.  He conducts his business with you here at the top of the Chickasaw Bluffs, which rise above the Mississippi.  

"You are well-spoken, ${mr} ${surname}.  Tell me first, who is your dominus?"  His voice, like boulders rumbling, carries clearly across the distance to you, despite the wind coming up from below.
@{speaks_english |You were relieved to discover that he speaks your tongue.  You can't imagine how this would go otherwise.}

"${sire_name}."

"I am afraid that I am unacquainted with ${sire_name}, but that does not mean that I have not heard of him.
*if sire_name = "Fernando de Villanueva e Itamaraca"
	*set carothers_rapport %+25
	*set applethorp_rapport %+10
	His exploits along the Spanish Main are legendary, as was his role in the Battle of New Orleans.  It is an honor to meet you, ${mr} ${surname}."
	
	You are somewhat surprised by the warmth of this welcome.  "I did not realize his reputation carried so far."
	
	Carothers looks surprisingly discomforted by this observation.  "I'm told that his convincing Lafitte to join the battle on the side of Jackson is what saved the day," he observes.  
	*if sire_alive
		"I am sorry to hear that he is no longer Quaestor of New Orleans."
		
		*if heard_about_new_orleans_quaestor_change
			"You are well informed, Quaestor Carothers.  I only just heard myself that he no longer holds that title."
			
			*goto revolution_check
		*else
			"No longer Quaestor?" you exclaim. "Are you certain?"
			*gosub_scene util update_new_orleans_quaestor
			
			"Most certain. Your esteemed pirate is no longer Quaestor; he has been replaced by a Dutchman by the name of Pieter van der Velde."
			
			"Did he anger the Governor?"
			
			"I cannot say."
				
			"I must thank you for this intelligence, Quaestor Carothers. But, I must say, it is probably for the best. He was already growing weary of his responsibilities when I left that city."
			
			Carothers smirks at this.
			*goto revolution_check
	*else
		*set carothers_rapport %-10
		"Though, I have heard no word of him in since the battle."
		
		"That is where he turned me, Quaestor. And that is also where he orphaned me. I have not seen him since that very same day."
		
		There is a slight pause in his movements as he considers your response; if you were alive you might have held your breath.
		*goto revolution_check
*elseif (sire_name = "Pieter van der Velde") and sire_alive
	Is he not the Quaestor of New Orleans?"
	
	"The very same."

	"May you bring honor to your lineage during your stay here." @{(compassion > 40) Honor? Since when has your kind been concerned with honor?|}

	"I shall do my best, Quaestor."
	
	*goto revolution_check
*elseif sire_name = "West"
	After all, he typifies the American spirit, does he not?  Wandering around the frontier, more animal than vampire?"
	
	"He does have his eccentricities, yes."
	
	*goto revolution_check
*elseif (sire_name != "Pieter van der Velde") and sire_alive
	Was he not, until very recently, Quaestor of New Orleans?"
	
	*if heard_about_new_orleans_quaestor_change	
		"You are well informed, Quaestor Carothers.  I only just heard myself that he no longer holds that title."
		
		*goto revolution_check
	*else
		"Until recently?  What news is this?"
		*gosub_scene util update_new_orleans_quaestor
		
		*if sire_name = "Padre Carlos"
			"Padre Carlos has been named the first Praetor of the Americas.  You should be very proud of him."
			
			"I…don't know what to say."
			
			*goto revolution_check
		*else
			"Your dominus is no longer quaestor.  He has been replaced by a Dutchman by the name of Pieter van der Velde.  It seems that he displeased Governor Overstreet."
			
			"I must thank you for this intelligence, Quaestor Carothers."
			
			*goto revolution_check
*else
	It has been some years since word of him has reached my ears, however.  How is he?"
	
	"I cannot say; we have not spoken in some time.  He does have a way of keeping his head down, when it suits him."
	
	*goto revolution_check

*label cornered_by_apollo
*page_break
*set carothers_rapport %-20
*set applethorp_rapport %-10
*set presented_memphis true
"Would you care to tell me what you are doing in my city, without having sought an audience with me?"

You are sitting on a public bench in Court Square, watching the bustle of the early evening.  You had all but given up finding the quaestor, but it seems that he has found you; his voice rings out across the distance between you.

You turn around slowly, taking in the sight of the vampire to whom you will shortly abase yourself.  He is a former slave, possessed of a strength both internal and external; he moves with a confidence born of decades spent laboring under the sun.  Even from this distance, you can clearly see the size of his hands: massive and deadly.

Moreover, he is not alone; a woman accompanies him.  She is tall for her sex, hair cut close to her scalp, and she wears a sleeveless dress that eschews any sense of fashion.  As she nears, her choice of clothing gains even more significance: you note the network of lash-marks across her upper arms.  All signs point to their continuing well out of sight.
*choice
	*if chasing_wilson
		*if wilson_embraced
			#"I apologize.  I have been chasing my errant offspring.  He fled my tutelage, and I tracked him here.  I hoped to find him before disturbing you."
				*set carothers_rapport %-5
				*set carothers_ignorant_of_pb false
				"Errant offspring?  That is most embarrassing."
				
				"Yes, unfortunately.  With your permission, I will remain here until he has been found."
		*else
			#"I apologize.  I have been chasing the offspring of Quaestor Withers of Vicksburg.  He fled her tutelage, and she asked me to come here and retrieve him.  I had hoped to find him before disturbing you."
				*set carothers_rapport %+5
				*set carothers_ignorant_of_pb false
				"How embarrassing for Quaestor Withers!" he replies with a smirk.
			
				"Yes, well, with your permission, I will remain here until he has been found."
	*if exiled_from_vicksburg
		*selectable_if (discretion > 40) #"I apologize.  I was recently exiled from the city of Vicksburg.  I come here to throw myself upon your mercy."
			"Ah, yes, she wrote to me about you. ${given_name} ${surname}, unless I am mistaken? But she did not explain her reasons. What crime did you commit?"
			
			*if rejected_sam_wilson
				*set carothers_rapport %+5
				"I refused to be her unquestioning lackey."

				Carothers guffaws.  "I can see where your irreverance might have irked her, ${mr} ${surname}."

				"I hope my irreverance towards her does not discomfort you."

				"No, I daresay it amuses me."

				"Excellent.  Now, with your permission, I would like to take up residence here…"
			*else
				*set carothers_rapport %+20
				*set discretion %+10
				"I sabotaged the Confederate defenses."

				"Sabotaged their defenses?"

				"Yes.  I helped detonate the munitions depot.  The defenders could not stand without gunpowder to fuel their rifles or cannon."

				"That was quite brave of you."

				"It was all that I could do to bring a swift end to the siege."  He nods in appreciation.  "Now, with your permission, I would like to take up residence here…"
	#"Oh!  There you are!  I've been looking everywhere for you!" I exclaim sarcastically.
		*if chasing_wilson
			*set discretion %+15
		*elseif (maddox_num < 3)
			*set discretion %+5
		*else
			*set discretion %-5
		"Looking everywhere, eh?  It certainly doesn't seem as though you've been looking everywhere for me."
		
		"Well, you found me, didn't you?"
		
		"And who are you?"
		
		"${given_name} ${surname}, at your service," you say with a ${bow}. @{(hasty_exit_from_vicksburg or exiled_from_vicksburg) A flicker of recognition crosses his brow at the mention of your name.|}
	*selectable_if (discretion > 40) #"It certainly took you long enough…"
		*set carothers_rapport %-15
		*set discretion %+10
		His eyes narrow at your insolence.  "It is not my duty to find you.  It is yours to find me."

		"I hoped that your command of the city was greater than that of my last Quaestor.  You have impressed me."

		"I am happy to know that I have impressed you," he says through clenched teeth.

		"${given_name} ${surname}, at your service," you say with a ${bow}. @{(hasty_exit_from_vicksburg or exiled_from_vicksburg) A flicker of recognition crosses his brow at the mention of your name.|}

He considers you for a moment, before introducing himself formally.  "I am Apollo Carothers, Quaestor of Memphis."

"An honor to make your acquaintance, Quaestor Carothers."
*if maddox_status = "with"
	Gesturing to ${wilson}, you introduce your offspring.  "Please, allow me to introduce ${wilson} ${maddox}."
	
	@{maddox_num "Itsah hono', suh."|"It's an honor, sir,"|ERROR} ${wilson} says, hat in hand, as he bows before Carothers.  Carothers nods his greeting.
*set dido_introduced true

"And this," Carothers says, gesturing to his companion, "is Dido Applethorp, my offspring."  You ${bow} in greeting.

*label revolution_check
*if speaks_english
	He does not waste any further time closing in on what concerns him most about your arrival.
*else

	"How is it that you do not speak English, ${mr} ${surname}?" he continues.
	
	"I have not found it necessary to learn it yet."
	
	"I would recommend applying yourself to its study.  It is the tongue of this nation.  Though you may not think yourself beholden to it, soon enough you will need to accommodate it."
	
	"You are wise, Quaestor," you say, before he changes the subject to more pressing matters.
	
"And Consul Stone?  What do you think of his revolution?"
*if (maddox_status = "with") and (heard_about_revolution = false)
	${wilson} looks at you, concern clearly etched on his face.
*choice
	*if heard_about_revolution
		*selectable_if (discretion > 35) #"I think Consul Stone has done us all a favor.  It was time for the Americas to go their own way."
			*set carothers_rapport %+5
			*set revolutionary_credentials %+25
			*set anachronism %+5
			Carothers's face lights up at your reply. "I cannot agree with you more, ${mr} ${surname}.  A move such as this was long overdue."
			
			"I am so glad we see eye-to-eye, Quaestor."
			*goto welcome_to_stay
		*selectable_if (discretion < 65) #"Revolution?  Consul Stone?  I'm afraid I am unaware of what you speak." @{heard_about_revolution I am lying, but perhaps it is best to let Carothers show his inclinations.|}
			*set discretion %-10
			*if heard_about_revolution
				*set independence %+10
				*set discretion %-5
			*goto apollo_explains_revolution
		*selectable_if (anachronism < 65) #"I find the very idea repulsive.  If Adonis has ruled for millennia, what hubris must Stone possess, to think himself more fit to rule?"
			*set revolutionary_credentials %-10
			*set carothers_rapport %-15
			For a moment, you fear that the Quaestor will be struck with a bout of apoplexy.

			"Hubris?  Hubris?  I think someone else here is guilty of hubris!"

			"Excuse me?" you reply, startled by his reaction.

			"The injustices of Adonis are beyond calculation!  His crimes against both humans and vampires…"

			With this, Dido lays a hand on Apollo's chest.  "Apallah, ${he} dinna mean nuttin' by it.  $!{he} be young, ${he} don' know no betta'."

			Carothers stops himself, and his rage slowly begins to dissapate.  As it does, you consider his reaction to your words.
			*if compassion <= 35
				You must admit, you find it admirable that he would become so irate at the thought of the crimes of a vampire against humans.
			*elseif (compassion < 60)
				You are surprised that he would become so irate at the thought of the crimes of a vampire against humans.
			*else
				How absurd that he would become irate at the thought of crimes against humans.  He clearly coddles his food.
			
			After a few more moments to compose himself, he launches into a more reasoned defense of Stone.
			*goto apollo_justifies_revolution
		*selectable_if (discretion < 70) #"I had hoped to find a city where such divisions would not disturb my peace."
			*set discretion %-15
			*if revolutionary_credentials > 60
				*set revolutionary_credentials %-5
			*if revolutionary_credentials < 40
				*set revolutionary_credentials %+5
			*set only_vampires true
			Carothers laughs. It is a deep, rolling thunder. "We—Dido and I—are the only vampires in this city, and we support Consul Stone unconditionally. Let us agree, then, that there are no divisions here?"
			
			You smile and nod. "There are no divisions here, Quaestor."
			
			*goto welcome_to_stay
	*if heard_about_revolution = false
		#"Revolution?  Consul Stone?  I'm afraid I am unaware of what you speak."
			*set discretion %-5
			*goto apollo_explains_revolution
		*selectable_if (anachronism < 60) #"I know nothing of this revolution, but I can't imagine that it's a good idea.  Haven't we had enough of revolutions of late?"
			*set justice %+10
			*set revolutionary_credentials %-10
			*set carothers_rapport %-10
			*set discretion %-5
			"Enough revolutions? I would say that we have not had enough!" Carothers retorts. "That bastard Johnson is seeking to undo everything that the war achieved. No, the revolutions have not gone far enough, ${mr} ${surname}."
			
			"I, for one, have had enough of violence, Quaestor."
			
			"But has violence had enough of you?"
			
			Seeking to defuse the situation, you try again. "Quaestor, I do not seek to rile you. I am merely looking for a place to better establish myself."
			
			He peers at you for a long while, clearly distrustful.
			*goto apollo_justifies_revolution
		*if fled_from_vicksburg
			#"What misfortune is this? I have just fled the siege of Vicksburg! I had thought I came to more peaceful shores."
				*label fled_vicksburg
				*set applethorp_rapport %+10
				"Fear not, the revolution has yet to claim any casualties here."
				
				You wonder if his words double as a threat. "Let us pray that it remains that way, Quaestor."
				
				*goto apollo_explains_revolution
		*if fled_from_vicksburg = false
			#"What misfortune is this? I have just fled the sack of Vicksburg! I had thought I came to more peaceful shores."
				*goto fled_vicksburg
		*if sire_alive
			#"A revolution in the Society? For which side does my maker fight? As you shall find me by his side."
				*set anachronism %-10
				*set compassion %+10
				*if (sire_surname = "Van der Velde")
					*set carothers_rapport %-20
					*set revolutionary_credentials %-20
					*set new_orleans_quaestor_rapport %+25
					*label counterrevolutionary_sire
					"Though I appreciate your dedication to your dominus, ${mr} ${surname}, I fear that he has made his opposition to Consul Stone quite clear."
					
					"I meant no disrespect, Quaestor," you reply.
					
					After a few more moments to gain control of his obvious temper, Carothers turns to a more reasoned explanation of the revolution.
					*goto apollo_explains_revolution
				*elseif (sire_surname = "Sainte-Chapelle")
					*set carothers_rapport %-20
					*set revolutionary_credentials %-20
					*set sire_rapport %+25
					*goto counterrevolutionary_sire
				*elseif (sire_name = "Padre Carlos")
					*set carothers_rapport %-20
					*set revolutionary_credentials %+20
					*set sire_rapport %+10
					"Oh, ho! The blood must be strong in your lineage. It is good to see, ${mr} ${surname}," Carothers says.
					
					You must have answered correctly, though you are still uncertain as to on which side Carothers—and Padre Carlos—fall. It does not take long for Carothers to launch into an explanation, however.
					*goto apollo_explains_revolution
				*elseif sire_name = "West"
					*set carothers_rapport %+10
					*set applethorp_rapport %+10
					Carothers laughs. "I don't know much of the venerable West, but I suspect that he cares little for the turmoil of the Society. But I appreciate your loyalty to your maker."
					
					"I suppose you are correct, Quaestor."
					
					*goto apollo_explains_revolution
				*else
					*set carothers_rapport %+20
					*set applethorp_rapport %+10
					*set revolutionary_credentials %+10
					*set sire_rapport %+10
					"Your maker would be proud to hear you say that, ${mr} ${surname}," Carothers replies.
					
					"But please, Quaestor, tell me more of this revolution."
					
					*goto apollo_explains_revolution

*label apollo_explains_revolution
*set revolutionary_credentials %+5
*set carothers_rapport %+5
*set heard_about_revolution true
*set consul_praetor_explained true
"How long have you been gone from the circles of the Society?  It is on the lips of every vampire from Calcutta to San Francisco."

"I have been…preoccupied.  But please, tell me about this revolution."

"Senator Stone of Baltimore slew Praetor Miele, and declared himself Consul of the Americas."

"But, I've never heard of a consul or praetor before."

"Consul Adonis has been at the apex of the Society for millennia.  Praetors are his traveling judges, those individuals tasked with uncovering and prosecuting treason and heresy."

"And Stone now claims himself equal to this…Adonis?"

"He does.  And the whole vampiric world has been waiting for Adonis's retort."

"When did this murder happen?"

"June of 1863."

"Right before Vicksburg fell."

"And the Confederate loss at Gettysburg," observes Carothers.

"Do you think them connected?"

"Considering the British support for the Confederacy…I would not be surprised."

"But…England never entered the war!"

"Exactly!"

"I see."  You do your best not to visibly doubt Carothers's convoluted thinking.
*goto welcome_to_stay

*label apollo_justifies_revolution
*set revolutionary_credentials %-5
*set carothers_rapport %-5
"I will not seek to change your opinion, other than to observe that the vampires who have come to these shores over the past three and a half centuries have done so more often than not to escape the crushing weight of the Society of Adonis.  Here, we are few and far between.  We are not at each others' throats, as they are there.  Here, we can make our own way in the world."
*choice
	*selectable_if (discretion > 50) #"You are very old, then?"
		*set discretion %+10
		*set carothers_rapport %-5
		Apollo's face contracts in consternation at this question.  "Just because I have never been to the Old World doesn't mean that I haven't been learned on the difficulties of our kind there."
		
		"So, you are not very old."
		
		"Are you always so brazen in your questions, ${mr} ${surname}?"
		
		"I am simply trying to ascertain the source of your knowledge about these things."
		
		"My dominus was kind enough to explain the ways of the Society to me, in excruciating detail.  And I have him to thank for everything that I am."
		
		"And who is your dominus?" you inquire sweetly.
		
		Carothers ignores your question—it is almost as though he didn't hear it—deciding instead to launch into the next part of the conversation.
	#"I take it, then, that you support Stone's revolution?"
		"I do, most whole-heartedly.  Adonis can send his praetors here to punish me if he wishes, and I will send them to greet the sun."
		
		"It is good to know where one stands, Quaestor Carothers."  
		
		These introductions concluded, Apollo seems to relax a bit.  You can imagine him being quite jovial when he was alive.

*label welcome_to_stay

*if dido_introduced = false
	*if perception > 1
		You notice the woman nudge Apollo ever so slightly.
	"Oh, and of course, this is Dido Applethorp," he says, gesturing to his companion.  She curtseys in greeting.

*if chasing_wilson
	"Well, ${mr} ${surname}, you are welcome to stay in Memphis while you pursue your quarry.  I do hope that you will locate him soon, 
	*if wilson_embraced
		before he brings any more shame to you."
		
		"I do hope it does not come to that.  Thank you for your gracious hospitality, Quaestor Carothers."
		
		"You are welcome.  Please keep me informed of your progress."
		
		"I shall," you reply.  After a moment's consideration, you have another question: "Tell me, though, are there any more of our kind in the city?"
		
		"You, me, Dido.  And your errant offspring.  That is more than there should be."
		
		"Of course, Quaestor."
		
		"Good evening, then," he concludes.
		
		Taking your leave of Carothers, you survey your new city.  The tips of your fingers tingle with the anticipation of all the things you have to accomplish here.
		*finish Next
	*else
		before he brings any more shame to Quaestor Withers."
		
		"I do hope it does not come to that.  Thank you for your gracious hospitality, Quaestor Carothers."
		
		"You are welcome.  Please keep me informed of your progress."
		
		"I shall," you reply.  After a moment's consideration, you have another question: "Tell me, though, are there any more of our kind in the city?"
		
		"You, me, Dido.  And the errant offspring of Samantha Withers.  That is more than there should be."
		
		"Of course, Quaestor."
		
		"Good evening," he concludes.
		
		Taking your leave of Carothers, you survey your new city.  The tips of your fingers tingle with the anticipation of all the things you have to accomplish here.
		*finish Next
*elseif exiled_from_vicksburg or hasty_exit_from_vicksburg
	*set debt_to_carothers true
	"Well, ${mr} ${surname}, I would welcome you to Memphis, but considering your disagreements with Quaestor Withers, the broodmate of Governor Overstreet, I'm afraid I will have to ask for something in return."
	
	You clench your jaw; Withers must have informed other Carothers and other quaestors of @{exiled_from_vicksburg your exile|the betrayal of her confidence}. "What would that be, Quaestor?"
	
	"You will owe me a debt.  I will have to defend your presence here, so close to Vicksburg.  Withers may take it as an affront."
	
	Seeing few other options, you nod.  "So be it, Quaestor."

	"Very good.  Then you are most welcome here."
	
	"Thank you," you reply.  After a moment's consideration, you have another question: "Tell me one more thing, Quaestor: are there any more of our kind in this city?"
	
	"You, me, Dido.  Any others would be here without my permission."
	
	"I see, Quaestor.  Good evening to you."
	
	Taking your leave of Carothers, you survey your new city.  The tips of your fingers tingle with the anticipation of all the things you have to accomplish here.
	*finish Next
*elseif maddox_status = "with"
	*set debt_to_carothers true
	"Well, ${mr} ${surname} and Mr. ${maddox}, I would welcome you to Memphis, but I must admit, the two of you will be something of a burden on our resources."
	
	"We will…" you begin, before a wave of his hand interrupts you.
	
	"If you acknowledge a debt to me, ${mr} ${surname}, I will welcome the two of you into the city.  It would be good to have others of our kind here."
	
	"It would be my honor, Quaestor."
	
	"Very well.  The two of you are welcome here in Memphis."
	
	"Thank you, Quaestor," you reply.  After a moment's consideration, you have one last question: "Tell me one more thing, Quaestor: are there any more of our kind in the city?"
	
	"You, me, and our respective offspring.  It already sounds quite crowded to me."
	
	"And you are most gracious for welcoming us, Quaestor.  Now, if you will excuse us…"
	
	Taking your leave of Carothers, you and ${wilson} survey your new city.  The tips of your fingers tingle with the anticipation of all the things you have to accomplish here.
	*finish Next
*else
	"Well, ${mr} ${surname}, you are welcome to take up residence in Memphis.  It would be good to have another of our kind in the city."
	
	"Thank you for your hospitality, Quaestor Carothers," you reply.  
	*if only_vampires
		"Tell me, though, are there any more of our kind in the city?"
		
		"You, me, Dido.  Any others would be here without my permission."
		
		"Understood."
	
	Taking your leave of Carothers, you survey your new city.  The tips of your fingers tingle with the anticipation of all the things you will accomplish here.
	*finish Next