*comment ñáéç…—
*hide_reuse
*advertisement
*gosub_scene util check_flow
*set met_jesse true
*temp com_jesse true
*temp answer_to_estefania 0
*temp quaestor_num 6
*temp jesse_mum false
*if (new_orleans_quaestor_surname = "Van der Velde")
	*set quaestor_num 1
*if (new_orleans_quaestor_surname = "Sainte-Chapelle")
	*set quaestor_num 2
*if (new_orleans_quaestor_surname = "Padre Carlos")
	*set quaestor_num 3
*if (new_orleans_quaestor_surname = "Winters")
	*set quaestor_num 4
*if (new_orleans_quaestor_surname = "Villanueva")
	*set quaestor_num 5
*if quaestor_num = 6
	*bug
*temp dominus "dominus"
*if jesse_is_broodmate = false
	*set dominus "quaestor"
*if (sire_name = "West") and ((fled_from_sire = false) and sire_alive)
	*goto meet_jesse_beast
*else
	Arriving at the haven of the quaestor, Ajax the valet sneaks you inside quietly—you are somewhat tardy.
	
	It is uncanny to see Jesse before you after all that you have heard.  ${new_orleans_quaestor_surname} filled you with conflicting impressions of him; sometimes he is cursed as a self-centered traitor, other times esteemed as the apple of his maker's eye.  Even the circumstances of Jesse's departure change with the phases of the moon: sometimes ${new_orleans_quaestor_surname} claims that he exiled him, and other times that he was abandoned by Jesse in his hour of need.
	
	*if speaks_english
		Jesse stands before ${new_orleans_quaestor_surname}, making a sort of petition to be welcomed back into his maker's arms: "Dominus, it is with great pleasure that I find you well and perhaps even flourishing in your adopted home.  It has been some years since our time together here, but it is good to be back.  It is with great humility that I bow before you, and ask for succor in your fair city."
	*elseif speaks_french
		Jesse stands before ${new_orleans_quaestor_surname}, making a sort of petition to be welcomed back into his maker's arms, a petition which ${new_orleans_quaestor_surname} demands be made in French, for your benefit: "Dominus, it is with great pleasure that I find you well and perhaps even flourishing in your adopted home.  It has been some years since our time together here, but it is good to be back.  It is with great humility that I bow before you, and ask for succor in your fair city."
	*elseif speaks_spanish and (((sire_name = "Fernando de Villanueva e Itamaraca") or (sire_name = "Padre Carlos")) and (sire_alive = true))
		Jesse stands before ${new_orleans_quaestor_surname}, making a sort of petition to be welcomed back into his maker's arms, a petition which ${new_orleans_quaestor_surname} demands be made in Castilian, for your benefit: "Dominus, it is with great pleasure that I find you well and perhaps even flourishing in your adopted home.  It has been some years since our time together here, but it is good to be back.  It is with great humility that I bow before you, and ask for succor in your fair city."  You sense that 'humility' is something of an overstatement.
	*else
		*set jesse_rapport %-10
		*set com_jesse false

		Jesse speaks before ${new_orleans_quaestor_surname} for some time, apparently offering an apology and recounting the details of his adventures.  You can tell that, while he may try to hide it, ${new_orleans_quaestor_surname} is thrilled to have his firstmade back home.  At some point, it comes time to introduce you, a task made a little more difficult by your lack of a common tongue, but goes well enough.
		
		The interview and reprimand concluded, ${new_orleans_quaestor_surname} claps his hands together in joy and announces a celebration.
		
		*page_break
		*goto impression_of_jesse

Given the opportunity to observe him, you see that Jesse possesses a rugged charm and a ready smile; you no longer wonder how he first attracted the attention of ${new_orleans_quaestor_surname}.

While they may have parted under adverse circumstances, right now ${new_orleans_quaestor_surname} does little to conceal his joy at Jesse's return.  Lest he seem too lenient, he does make a halfhearted attempt at scolding Jesse, quite possibly just for your benefit: "Jesse, your departure was ill-timed and ill-considered.  Much has transpired in your absence…as happens when you abandon your maker for nearly two decades."

"Your reprimand is just, dominus.  I can do naught but beg for your forgiveness."

"And your travels, where have they taken you?"

"As befitted our separation, I first went to Port-au-Prince, where I stayed for some years.  Most recently, though, I have been in Savannah, at the court of Governor Overstreet.  She spoke highly of you to me, and intimated that the title of quaestor would soon be yours in fact, dominus."

"You are the bearer of good tidings, Jesse.  But I should inform you that some things have changed in your absence, as they must.  I don't believe you've met ${mr} ${given_name} ${surname}.  ${mr} ${surname}, allow me to introduce Jesse Whitaker, my firstmade."  

You greet Jesse with a ${bow}.
*if jesse_is_broodmate
	*set jesse_rapport %-10
	"Dear brother, it is a pleasure to finally make your acquaintance.  I look forward to our friendship."
	
	"The honor is all mine, ${mr} ${surname}," Jesse returns.
*else
	"I have heard so much about you, Mr. Whitaker.  I imagine our time together will be rewarding."
	
	"I can only imagine the times we shall have, ${mr} ${surname}."

"Let us celebrate!  I'm sure we can find something exotic to feast upon, here in lovely New-Orleans," ${new_orleans_quaestor_surname} concludes with a clap.  And with that, Jesse Whitaker is brought back into his maker's fold.
*page_break
*label impression_of_jesse

As ${new_orleans_quaestor_surname} leads Jesse away, you have a quick moment to reflect on what has transpired, and how you will conduct yourself for the immediate future.  This Jesse Whitaker could become a rival of yours, but he could also turn out to be a powerful ally.

How do you envision your comportment towards him?

*choice
	*if jesse_is_broodmate
		#He is my broodmate; I will welcome him home!
			*set jesse_rapport %+10
			*set independence %+15
	*if jesse_is_broodmate and embrace_of_affection
		#Is it possible?  Could this Jesse come between ${new_orleans_quaestor_surname} and myself?
			*set jesse_rapport %-10
			*set independence %+15
	*if jesse_is_broodmate = false
		#This snake will soon come between ${new_orleans_quaestor_surname} and me!
			*set jesse_rapport %-10
			*set independence %+5
	#I am wary of this newcomer; he could have designs on ${new_orleans_quaestor_surname}'s position.
		*set discretion %-5
		*set independence %-5
	#The backbiting of our kind is of no interest to me.  If Jesse desires ${new_orleans_quaestor_surname}'s affection, let him have it.
		*set independence %-15
		*set discretion %+5
	*if (met_lynch) #I do not fear for my position as most favored.
		*set discretion %+10
		*set jesse_rapport %-5

*if speaks_english or speaks_french
	As dawn is nearing, Jesse approaches you.  After making sure that ${new_orleans_quaestor_surname} is out of earshot, he surprises you with a request.  
	
	"As you know, I have only just arrived in the city.  I am in need of a place to stay for the day.  Perhaps you could recommend something?"
	*choice
		*if jesse_is_broodmate
			#"Surely you would be welcome at my home, brother."
				*set jesse_rapport %+20
				"You are too kind."
				
				Jesse retires to your haven with you.  As a house-guest, he is somewhat questionable.  Fortunately, he establishes a haven of his own within a few days, and none too soon takes his leave of you.
				*goto charles_x
		*else
			#"Surely you would be welcome at my home, Mr. Whitaker."
				*set jesse_rapport %+20
				"You are too kind, ${mr} ${surname}."
				
				Jesse retires to your haven with you.  As a house-guest, he is somewhat questionable.  Fortunately, he establishes a haven of his own within a few days, and none too soon takes his leave of you.
				*goto charles_x
		#"I am sure that ${new_orleans_quaestor_address} would be happy to provide you with a place to rest for the day."
			*set jesse_rapport %-15
			"You think I am not aware of that?" he growls at you before storming off.
			*goto charles_x
		*selectable_if (streetwise > 0) #"I can recommend a well-appointed house of whores.  With a few words from me, they would welcome you in their midst."
			*set jesse_rapport %+10
			A large smile splits Jesse's face.  "I have the feeling we shall become fast friends, ${mr} ${surname}."
			
			You give him directions to the house of ill repute, as well as one of your calling cards.  A few evenings later, you drop by to smooth things over with the madame, but by then Jesse has already moved on to a place of his own.
			*goto charles_x
		*if jesse_is_broodmate
			#"You are on your own…brother."
				*set jesse_rapport %-20
				"I see," he says simply.  After taking in the sight of you for a moment, he turns on his heel and departs.
				*goto charles_x
		#"I'm afraid I cannot help you, Mr. Whitaker."
			*set jesse_rapport %-10
			"I see," he says simply.  After taking in the sight of you for a moment, he turns on his heel and departs.
			*goto charles_x

	*label charles_x
	*page_break
*comment November, 1824
*temp heard_of_charles_x false

*if priest or ((ethnicity = "french") or ((ethnicity = "southern") or (literate and (intelligence > 2))))
	*set heard_of_charles_x true
	Word travels fast these days.
	
	In September, Louix XVIII, the king of France, dies of gangrene. His (slightly) younger brother, Charles X, assumes the throne.
	
	*if priest
		The ecclesiasts of New-Orleans rejoice at the news. The Catholic Church despises the French Revolution and its expropriation of the monasteries and churches of France. Charles X, an ultra-conservative, is rumored to be considering an anti-blasphemy law as well as potentially returning the stolen land.
		
		The bishops practically foam at the mouth at the thought of reclaiming their lost wealth.
		
		Besides this legislative priorities, Charles X has also reasserted the divine power of kings, proclaiming the power of the Royal Touch to heal the sick.
		
	*if priest = false
		*if (ethnicity = "french") or (ethnicity = "southern")
			The salons and dinner parties of New-Orleans are rife with speculation with what this might mean. There are a number of monarchists among the wealthy members of the New-Orleans élite who wish that France would reclaim Louisiana for the Empire. Others wonder what it means for the fate of the American experiment.
		*if (ethnicity != "french") and (ethnicity != "southern")
			The newspapers are rife with speculation about what this might mean. Some go so far as to argue that Louisiana should rise up and rejoin the French Empire. Many more wonder what this will mean for the former French colonies of the Caribbean. Still others wonder what it might mean for the American experiment.
		
		Notably, Charles X is reputed to be an ultra-conservative, having undermined his elder brother's attempts to maintain some of the French Revolution's liberalizations. Charles X's dedication to the traditions of monarchy even extends to its thaumaturgical powers—his heralds announce that he will use his divine authority to heal the sick once he is properly anointed king.
		
	Thus, when he is officially crowned the following summer at the cathedral of Reims, a crowd of chronically ill individuals has gathered. @{literate The journals describe how he|He} walks among them, touching them, blessing them, pronouncing them healed—all to rapturous applause from his courtiers. Many supplicants go into fits of rapture at his passing. And then King Charles leads a massive parade back to Paris.
	
	*if priest = false
		In the aftermath of the pomp and circumstance, there are no reports of any illnesses being cured.
	
	*fake_choice
		*if ((priest) or ((rationalism > 75) and (religious_tradition = "catholic"))) #It is good to see the return of the proper ordering of heaven and earth and the restoration of the prestige of the Church.
			*set rationalism %+5
			*set discretion %+5
			*set compassion %+5
		*if (priest) #The Divine Right of Kings is theologically bankrupt—and Charles's attempts to heal the sick are hubris.
			*set rationalism %+5
			*set discretion %-5
		#There is no Divine Right of Kings—and Charles is foolish to think that his touch could heal anyone.
			*set rationalism %-5
		#This bodes ill for the ideals of the American and French Revolutions—reactionaries are attempting to restore traditional hierarchies.
			*set compassion %-5
			*set laborvscapital %+5
		#If the mortals return to traditional relationships, it will be that much easier for vampires to exert their will.
			*set shepherd_credentials %+5
			*set discretion %+5
			*set laborvscapital %-5
		#An ocean separates New-Orleans from Paris. The vagaries of the French crown do not interest me.
			*set shepherd_credentials %-5
			*set discretion %+5
	
	The consequences of Charles's coronation arrive even earlier than you had anticipated.

*page_break
*set met_maffi 2
*set heard_of_maffi true
Arriving at the home of ${new_orleans_quaestor_surname}, you are greeted by Ajax. He indicates that there are unexpected guests this evening.

Entering the salon, you find ${new_orleans_quaestor_surname} sitting with a woman wearing trousers and sporting natural hair. ${new_orleans_quaestor_surname} greets you and then turns to introduce you to the woman.

"Please, ${given_name} ${surname}, allow me to introduce you to…well, how should we address you?"

"Thérèse is fine," she replies. @{speaks_french She has a cultured, Parisian accent.|}

"A pleasure, madame," you begin.

"Please, don't call me that," she replies.

"Mademoi…?" you begin.

"No. No titles, if you please."

"Thérèse, then?"

"Yes."

"What brings you to New-Orleans…Thérèse?" you hesitate. 
*if ((ethnicity = "french") or (ethnicity = "southern")) or ((ethnicity = "spanish") or (independence > 65))
	The informality is off-putting to you.

"I need your Quaestor's help."

Does she know that ${new_orleans_quaestor_surname} is not officially the Quaestor of New-Orleans? Does she care? Perhaps she is flattering him by according him the respect he demands? You suppose that—if she needs his help—it would serve no value for her to antagonize him by bringing up the provisional nature of his title.
*page_break
Thérèse explains that the new king of France has finally offered to recognize the independence of Haiti—if Haiti and its President Boyer reimburse the French slave-holders for their losses during the revolution. Of course, Haiti was the wealthiest colony in all of the New World before its revolution—it was more valuable than the entirety of the Thirteen Colonies combined. And the king wants every [i]sous[/i] repaid.

"This offer will return the country to slavery. They will be free in name, but this debt will hold them in shackles for generations."

@{(quaestor_num <= 3) "Perhaps they should have thought about that before they revolted," ${new_orleans_quaestor_surname} replies.|"The rich care nothing for anyone but themselves. I wish I could say that this suprises me, but it does not," ${new_orleans_quaestor_surname} concludes.}

Before Thérèse can reply, however, Jesse arrives. When he catches sight of Thérèse, he stops cold.

"Thérèse?" he says.

"Jesse," she returns. There is no warmth there.

"What are you doing here?"

She @{com_jesse |presumably} explains Haiti's predicament again, to which Jesse nods along. 

*if com_jesse = false
	At this point, the conversation switches to French, since Jesse does not speak @{speaks_spanish Spanish|German}.
	
	The three argue back and forth for a time. At some point, ${new_orleans_quaestor_surname} takes a moment to explain that Thérèse admits to killing the former Governor of Cap-Français, but refuses to claim the title of Governor herself. He has offered aid on the condition that she declare herself such.

	Since ${new_orleans_quaestor_surname} has turned the conversation back into your tongue, you realize that you could offer your thoughts.
	*goto skip_dialogue
When she finishes, ${new_orleans_quaestor_surname} brings up a different matter. "Tell me, where has Governor Praz gone?" @{(perception > 1) Both Thérèse and Jesse become even more still. He looks from one to the other.|He looks from her to Jesse and back.} "I suppose that confirms it. Praz is dead. 
*if quaestor_num <= 3
	Most likely at your hands…Thérèse—" he says, spitting her name out "—and you come here begging for my help? I should put you to death in the name of the Rule of Restraint."
*else
	And you killed him." He pauses to muse a momemt. "He deserved it, I'm sure; I thought he had the personality of a donkey's backside. But shouldn't I punish you for violating the Three Rules?"

"Yes, I killed Governor Praz. But by the customs of the Society, you have no authority to punish me for it, as it did not occur in your city, much less in this province." 

"Perhaps I should just kill you anyway. As you note, you are in my city. And acknowledge your crimes…"

Thérèse bares the slightest hint of fang. "I'd like to see you try."

@{(quaestor_num <= 3) He scowls at her.|He nods.} "Is there a new Governor of Cap—Français, then?"

"You mean Cap-Haïtien. And no."

"Why not?"

Thérèse purses her lips. "There are so few of our kind on the island. Why do we need a Governor?"

"Then a quaestor?"

"No."

"Why not?"

"We don't need one."

"You mean, you don't need the Society."

"That's…"

"That's exactly what you mean. So you must choose. Do you wish to belong to the Society, or do you wish to…be indebted to France?"

Jesse interjects. "Dominus, perhaps we could aid her…"

"Jesse, I do not know what your rôle in this was, but I do not think you should be opining at this moment." Jesse goes silent. ${new_orleans_quaestor_surname} turns back to Thérèse: "Choose, now. Declare yourself Governor and I will aid you. Decline, and return home empty-handed."

As the room falls silent, you sense the opportunity to speak.
*label skip_dialogue
*if taught_about_governors = false
	
	"Governor?" you inquire.
	
	${new_orleans_quaestor_surname} frowns. "Yes, the ruler of a province of the Society—some suitably large territory and its population. The governor is the individual that appoints quaestors within that province."
	
	"So…she @{(compassion < 50) murdered|deposed} a vampire even more powerful than you?"
	
	${new_orleans_quaestor_surname} nods. "She did."

*temp advocate_killing false
*choice
	#"You should just kill her, $!{dominus}. You will only regret not doing so later."
		*set shepherd_credentials %-5
		*set independence %+5
		*set compassion %+5
		*set discretion %+10
		*set maffi_rapport %-20
		*set new_orleans_quaestor_rapport %+5
		*set advocate_killing true
		"I appreciate the sentiment, ${given_name}. But I want Thérèse to realize the error of her ways—to see the power and the security of the Society. If she is dead…"

		"You are no different from the French king," she spits. "You want us back under your thumb!"

		"Would you rather be under the thumb of the Society or the thumb of the French king?"

		She growls in frustration. A moment passes.
	#"Please, Thérèse, let us help you. The Society may have its flaws, but you must see its benefits…"
		*set independence %+10
		*set revolutionary_credentials %-10
		Thérèse shakes her head sadly. "No, ${given_name}. Too many have fought and bled and died to surrender our independence now."
		
		"Are you speaking of the people of Haiti, or the vampires that reside there?"
		
		"As I said, too many have fought and bled and died to surrender now." 
		
		*if perception > 1
			*set jesse_mum true
			You observe that Jesse is looking away. Is he…crying?

		"Which is to say…" ${new_orleans_quaestor_surname} begins.

	#"I applaud your courage, Thérèse."
		*set revolutionary_credentials %+5
		*set new_orleans_quaestor_rapport %-15
		*set jesse_rapport %+5
		*set independence %-10
		*set laborvscapital %+5
		She looks at you. "Your applause is does nothing for me, ${given_name}. I cannot take it to the bank to pay these debts. It will not feed the children like grain will. It is not lead, that can turned into bullets that we can fire at the French. Do not think that your patronizing applause washes away your responsibility here."

		You recoil at her retort; it was not what you were anticipating. You sputter, trying to find your words, until she makes up her mind.
	#"$!{dominus}, allow me to go with her to fight the French."
		*set revolutionary_credentials %+15
		*set maffi_rapport %+15
		*set compassion %+5
		*set discretion %+10
		*set independence %+5
		*set laborvscapital %+10

		"Absolutely not," ${new_orleans_quaestor_surname} replies. "I have not released you from my tutelage, and I will not release you @{(quaestor_num <= 3) so that you may embark on such foolishness|now, regardless of how much either of us would enjoy the escapade}."

		"But, $!{dominus}…"

		A throat clears.
	#"$!{dominus}, you have spoken often of the system of debts that underpin the Society. Is there no debt you would be willing to accept in exchange for aiding your guest?"
		*set independence %-5
		*set new_orleans_quaestor_rapport %+5
		"I appreciate the thought, ${given_name}, but no. If our guest does not believe in the Society, why would she respect its system of debts?"

		"Surely, Thérèse, your sense of honor would obligate you to respect such a debt," you proffer.

		After a moment's hesitation. "It would."

		"$!{dominus}, I think we have ourselves a solution."

		He considers a moment. "No. My conditions remain. Declare yourself Governor and I will aid you; there is no alternative."

"I will not declare myself Governor," Thérèse says finally.

"Then we have nothing more to speak of," ${new_orleans_quaestor_surname} replies.

Thérèse nods, stands, and makes for the exit.

*choice
	*if (advocate_killing = false) #I go after her.
		*set new_orleans_quaestor_rapport %-10
		*set jesse_rapport %-5
		*if jesse_rapport > 50
			"Be careful, ${given_name}…" Jesse says. as you stand to follow.

			You wave away his concerns.
			*page_break
		*gosub therese_convo
	#I stay with ${new_orleans_quaestor_surname} and Jesse.
		*set new_orleans_quaestor_rapport %+10
		*set jesse_rapport %+5
		*set maffi_rapport %-5
		*set jesse_mum true
		The three of you gossip for a few hours about the woman from Cap-Haïtien and her disorderly notions. 

		Jesse remains notably mum throughout.
	#I excuse myself and return to my haven.
		*set independence %-10
		*set maffi_rapport %-5

A few weeks later, President Boyer of Haiti signs the indemnity treaty, committing the young nation to a debt of 150 million francs. The Haitians may be free in name, but the weight of their debt, its interest, and the consequences thereof will impoverish them for centuries to come.

*if com_jesse
	*page_break
	
	One evening you find yourself in a drawing room with Jesse and several members of the city's young élite. At the direction of ${new_orleans_quaestor_surname}, he lets you join him on his adventures; ${new_orleans_quaestor_surname} cannot be bothered to spend all his time teaching you the ways of unlife.
	
	Jesse was never one for cards—he wrinkles his nose when he's bluffing, not that you'd ever point that out to him—but you have seen him turn aside threats with little more than a stare and a whisper. And now he does it again.
	
	The stakes have gotten quite high, but everyone in the room other than you, Jesse, and M. Lamarlere is otherwise occupied. Lamarlere wins the hand, which should be the end of the game, as Jesse's last [i]dix[/i] is in the pot. But Jesse expresses surprise and picks up the too-trusting Lamarlere's cards, while casually tossing his own before his opponent. Lamarlere smiles broadly, basking in his victory. 
	
	And then, with a wave of his hands and a whisper, Jesse drops Lamarlere's cards to the table, leans forward, and draws the pot to himself. M. Lamarlere grunts in confusion, looking from "his" cards to "Jesse's" and back again, before banging his fist on the table. Yet, rather than dragging the money back or raising a stink, he stands and stalks out of the room.
	
	Jesse gathers the [i]dix[/i] as calmly as he can. "I think it is time for us to depart, ${given_name}."
	
	"Yes, let's," you agree.
	
	The two of you plead your obligations to the hostess and are soon released from your social obligations.
	
	Once again on the Rue Melpomene, you grab Jesse by the shoulder and turn him to face you. "What did you do to him?" you demand.
	
	"The [i]verba oblivionis?[/i]"
	
	*if speaks_latin
		"The words of oblivion?" you reply. The phrase means nothing to you.
		
		"Exactly!"
		
		"But what are the 'words of oblivion?'"
	*else
		"Pardon?"
	
	"Ah, of course. It is one of the powers of the blood. With a little bit of effort, I can make a human forgetful—even susceptible—for the briefest of moments."
	
	"Forgetful?"
	
	"Say you show your fangs at the wrong moment. Invoke the [i]verba oblivionis[/i] and the error is forgotten. It only works in the moment, and only a few minutes can be occluded. But as you can see, the briefest of moments can be enough."
	
	*choice
		#"I see how this could cover a multitude of crimes."
			*set discretion %-5
			*set shepherd_credentials %-5
			*set jesse_rapport %+5
			"It has certainly concealed a number of mine," he replies.
		#"Do you always use it to steal?"
			*set justice %+5
			*set shepherd_credentials %+5
			"Stealing? From humans? They are our food, ${given_name}. They are not entitled to such considerations."
		#"I cannot imagine using such a power to toy with someone's memories. It seems—unforgivable."
			*set compassion %-10
			*set jesse_rapport %-5
			"I wouldn't know; I've never asked for their forgiveness," he replies.

	Before you can say anything further, Jesse elicits a shout; he has just spied an acquaintance in the street. One of his favorite sources of blood, in fact. With a wink and a smile, he excuses himself, and you are left to make your way home on your own.

*page_break
*set year 1825
*set met_estefania true

*if (new_orleans_quaestor_surname = "Villanueva")
	*if jesse_is_broodmate
		*set rios_rapport %+10
		As the summer continues, your relationship with Jesse continues to fray. It seems, however, that you are not the only one having trouble with your broodmate—one of your patron's own has arrived in town.
		
		Introductions concluded, the newcomer bursts out with "Aren't we one big happy family?"  With that, Estefania Rios e Hidalgo gazes around at her broodmate and his two offspring.
		
		"It is a pleasure to have you here, Señora…" you were saying, at least until Jesse overrides you.
		
		"Together, we shall see that New-Orleans becomes the most magnificent city of the New World!"  
		*if ethnicity = "spanish"
			*set rios_rapport %+15
			*set jesse_rapport %-20
			He seems to be a little overwhelmed at being surrounded by three Spaniards. Or, a Galician, a Castilian, and an @{male [i]Isleño[/i]|[i]Isleña[/i]}—not that he can tell the difference.
		
		"That we shall, Jesse," says Villanueva.
		
		"If only our dear dominus would join us here…" Rios exclaims in the general direction of Villanueva.
		
		"Yes, if only he were here," Villanueva replies without warmth.  You have heard precious little about Martin Garcia Vargas, the maker of your maker, but the idea of coexisting with a being of such age does not exactly sit well with you.  Consequently, you find your dominus's lack of enthusiasm comforting.
		*page_break
		*goto estefanias_question
	*else
		*if speaks_german and ((speaks_english = false) and (speaks_french = false))
			*set rios_rapport %-10
			If you weren't certain already, it becomes suddenly much clearer to you that the life of a quaestor is rather challenging, as evidenced by the arrival of one of ${new_orleans_quaestor_surname}'s own broodmates.
					
			"Señora Estefania Rios e Hidalgo, allow me to introduce ${mr} ${surname} to you."

			"It is my great pleasure, Sra. Rios," you begin, momentarily entranced by the depth of her brown—almost black—eyes.

			She smiles and nods at you, and says something back in Spanish.  ${new_orleans_quaestor_surname} is kind enough to translate:  "She says that it must be a little overwhelming for you, being the only one not of our bloodline in the city."

			After a moment's hesitation: "Please, let her know that I hadn't given it a moment's thought," but suddenly you wonder if you should.  And with that exchange, you suddenly grasp the political earthquake that is underway.

			*page_break
			*goto estefanias_question
		*else
			*set rios_rapport %-5
			If you weren't certain already, it becomes suddenly much clearer to you that the life of a quaestor is rather challenging, as evidenced by the arrival of one of ${new_orleans_quaestor_surname}'s own broodmates.
					
			"Señora Estefania Rios e Hidalgo, allow me to introduce to you ${mr} ${surname}."

			"It is my great pleasure, Sra. Rios," you begin, momentarily entranced by the depth of her brown—almost black—eyes.

			"It must be a little overwhelming for you, being the only one not of our bloodline in the city," Rios pointedly observes.

			"I…I hadn't…" you begin to stammer.

			"Well, now you have considered it, ${mr} ${surname}.  Perhaps you can excuse us now, as we have family business to attend to."

			"Yes, yes of course."  And with that exchange, you suddenly grasp the political earthquake that is underway.
			*page_break
			*goto estefanias_question
*elseif (sire_name = "Fernando de Villanueva e Itamaraca") and (sire_alive = false)
	*set estefanias_protection true
	*set rios_rapport %+10
	Later that summer, yet another vampire arrives on a boat from points south.  Her arrival comes as a surprise to everyone.  ${new_orleans_quaestor_surname} quickly arranges a time for her meet the citizens of New-Orleans—a time at which both you and Jesse can attend.
	
	Once there, you stand at attention while she petitions ${new_orleans_quaestor_surname} for succor.
	*if speaks_english or (speaks_french or speaks_spanish)
		*set rios_rapport %+5
		
		"…and so I stand before you, ${new_orleans_quaestor_address}, to seek succor in New-Orleans."  With that, Estefania Rios e Hidalgo concludes her petition, but you can barely hear her words.
		
		"The broodmate of Sr. Villanueva e Itamaraca, you say?  Please, are you acquainted with his offspring, ${mr} ${surname}?"  With that, ${new_orleans_quaestor_surname} turns to you.
		
		"His offspring?" she exclaims, turning in your direction.  "No, I have not met this one.  Please, would you do me the honor?"
		
		"Sra. Rios, allow me to introduce ${mr} ${surname}, a most valued citizen of New-Orleans."  You ${bow} at the introduction.
		
		"A pleasure, ${mr} ${surname}."
		
		"The pleasure is all mine, Sra. Rios."
		
		"Tell me, what news of my broodmate?"
		
		"Alas, Sra. Rios, I have none.  It has been many years since we crossed paths, and, truth be told, I wish for his company as well."
		
		"I am sorry to hear that.  But I am sure that we shall become fast friends.  Tell me do you play cards?"
		
		"But of course."
		
		"Then we shall be even faster friends."
		
		"Shall we adjourn to the salon?  We can all get better acquainted there," ${new_orleans_quaestor_surname} interjects.
		
		"Yes, let's!" Estefania says.  With that, the petition is concluded.
		*page_break
		*goto estefanias_question
	*else
		Though you cannot understand the petition of this vampire, you do catch her name: Estefania Rios e Hidalgo.  And when she recites her immediate family, you hear mentioned a name that makes you go weak in the knees: Fernando de Villanueva e Itamaraca.
		
		Soon, ${new_orleans_quaestor_surname} is translating for you.
		
		"It seems that Sra. Rios is the broodmate of your maker, Sr. Villanueva.  She is most anxious to make your acquaintance."
		
		Turning to Estefania, you ${bow} in greeting.
		
		"She asks what news do you have of her dear broodmate?"
		
		"Please inform her that I have little to share; I have not seen him in some years.  I myself wish for his company."
		
		Estefania appears crestfallen once this is translated back to her.  After a moment, she speaks again.  There is some back and forth between her and ${new_orleans_quaestor_surname}, before he translates.
		
		"She says that she looks forward to better acquainting herself with you.  I have told her that you would be most pleased to join her for a game of cards."
		
		"But of course, ${new_orleans_quaestor_address}."
		
		"Good.  Now, I believe it is time to celebrate our new citizen."  With that, the petition is adjourned.
		*page_break
		*goto estefanias_question
*else
	Later that summer, yet another vampire arrives on a boat from points south. Her arrival comes as a surprise to everyone. ${new_orleans_quaestor_surname} quickly arranges an occasion for her to observe the Rule of Respect, choosing a time when both you and Jesse can attend.
	*page_break 
	*if speaks_english or (speaks_french or (speaks_spanish and (sire_name = "Padre Carlos")))
		*set rios_rapport %-5

		"…and so I stand before you, ${new_orleans_quaestor_address}, to seek succor in New-Orleans."  With that, Estefania Rios e Hidalgo concludes her petition.  During her speech, you have learned that she is the broodmate of a pirate by the name of Fernando de Villanueva e Itamaraca.

		"I am honored to have one of your lineage wish to take up residence in our city, Sra. Rios."

		"You do me too much honor, Quaestor," she replies, "the Lord has truly blessed me this night."

		*if jesse_is_broodmate
			*if sires_faith = "atheist"
				*set rios_rapport %-5
				${new_orleans_quaestor_surname} hisses at these words.  "There will be none of that here.  There is no God, Yahweh or Allah, and I will brook no superstition among the vampires of my city." @{(religious_tradition = "pagan") You notice that he doesn't even mention Hushtahli.  He has made his opinion on your god very clear.|}

				Estefania is clearly distraught by this response.  Unfortunately, propriety limits her available responses.  Like a woman trying to decide which child to save from a fire, Estefania has to choose between her faith and her place in the Society.  It seems that temporal concerns win out.  "Yes, Quaestor, you will hear no such drivel from me in the future."

				${new_orleans_quaestor_surname} seems to take a special pleasure in this response.  He takes a moment to breathe in the breaking of her heart before he turns to other business.
			*elseif sires_faith = "faithful"
				*set rios_rapport %+5
				"Oh, Sra. Rios, you are most welcome here.  It is always a relief to meet another member of our Lord's flock," ${new_orleans_quaestor_surname} exclaims.  

				Estefania gasps in delight.  "How wonderful to know that I am welcome here.  So few of our kind remember our origins as the shepherds of the mortal flock."

				${new_orleans_quaestor_surname} looks mildly uncomfortable at this remark.  Deciding to avoid the topic, he turns to other business.
			*elseif perception > 0
				You notice that ${new_orleans_quaestor_surname} does little to hide rolling his eyes at this remark.

		"Allow me to introduce 
		*if jesse_is_broodmate
			my offspring: Mr. Jesse Whitaker," with a gesture towards him, "and ${mr} ${given_name} ${surname}," which you accompany with a ${bow}.  When
		*else
			the other citizens of New-Orleans: my offspring, Mr. Jesse Whitaker," to which Jesse nods, "and ${mr} ${given_name} ${surname}, offspring of ${sire_name}."  You ${bow} at the introduction; when 
		you raise your eyes to hers again, you find yourself momentarily entranced by the depth of their color, so brown they're almost black.
		
		*if priest
			*set rios_rapport %+5
			She returns your ${bow} with a curtsey of her own. Even in death, she honors your vocation.
		"The pleasure is all mine," Estefania says with a smile.
		
		Her arrival certainly changes the political calculus of the city.
		*if jesse_is_broodmate and (sire_alive and (estefania_is_kin = false))
			Your happy little family now has a stranger observing—and thereby complicating—your affairs.
		*if jesse_is_broodmate and (sire_alive and estefania_is_kin)
			Your happy little family isn't so little anymore.
		*if ethnicity = "spanish"
			*set rios_rapport %+15
			*set jesse_rapport %-20
			Jesse, in particular, seems to be a little overwhelmed at being surrounded by three Spaniards. Or, a Catalan, a Castilian, and an @{male [i]Isleño[/i]|[i]Isleña[/i]}—not that he can tell the difference.
			
		The nights pass quickly…
		*page_break
		*goto estefanias_question
	*else
		Her name is Estefania Rios e Hidalgo, and her petition is made in French; though you are unable to understand, you are able to pick out the name of her patron, Fernando de Villanueva e Itamaraca, and that she has either just arrived from or recently spent some time in Panama.

		Once she is formally received, you are introduced to her.  
		*if priest
			*set rios_rapport %+5
			She curtsies to you when you are introduced; it appears that, even in death, she respects your vocation.
			
			Whatever the case, her arrival certainly changes the political calculus of the city.
			*if jesse_is_broodmate and (sire_alive and (estefania_is_kin = false))
				Your happy little family now has a stranger observing—and thereby complicating—your affairs.
			*if jesse_is_broodmate and (sire_alive and estefania_is_kin)
				*set new_orleans_quaestor_rapport %+10
				*set jesse_rapport %-20
				Your happy little family isn't so little anymore.
		*elseif speaks_spanish
			*set rios_rapport %+30
			She is thrilled to make your acquaintance, and you do your best to make her feel welcome. Perhaps the vestiges of your mortal culture will provoke a certain sympathy between you?
			
			Whatever the case, her arrival certainly changes the political calculus of the city.
			*if jesse_is_broodmate and (sire_alive and (estefania_is_kin = false))
				Your happy little family now has a stranger observing—and thereby complicating—your affairs.
			*if jesse_is_broodmate and (sire_alive and estefania_is_kin)
				*set new_orleans_quaestor_rapport %+10
				*set jesse_rapport %-20
				Your happy little family isn't so little anymore.

				That said, Jesse seems a little overwhelmed to be surrounded by so many Spaniards.
		*else
			*set rios_rapport %-25
			The conversation is short and awkward, only marginally facilitated by ${new_orleans_quaestor_surname}'s disinterested translations.
			
			Her arrival certainly changes the political calculus of the city.
			*if jesse_is_broodmate and (sire_alive and (estefania_is_kin = false))
				Your happy little family now has a stranger observing—and thereby complicating—your affairs.
			*if jesse_is_broodmate and (sire_alive and estefania_is_kin)
				Your happy little family isn't so little anymore.
			
		The nights pass quickly…
		*page_break 
		*goto estefanias_question

*label meet_jesse_beast

It is not long after your arrival in New-Orleans that you have the pleasure of making the acquaintance of Mr. Jesse Whitaker, the firstmade of the quaestor of New-Orleans.  
*if speaks_english
	*if (ethnicity != "african") and (ethnicity != "choctaw")
		It is while you are in attendance at the Marigny family's spring ball that he pulls you aside for a private tête-à-tête.
	*else
		You have made a habit of prowling the market at Congo Square, as good a place as any to meet potential prey, and it is on such an occasion that you are addressed by this strange white man.
*elseif speaks_french
	*if ethnicity != "african"
		It is while you are in attendance at the Marigny family's spring ball that he pulls you aside for a private tête-à-tête.  He is perfectly comfortable addressing you in French, even if he does little to disguise his annoyance that you do not speak English.
	*else
		You have made a habit of prowling the market at Congo Square, as good a place as any to meet potential prey, and it is on an occasion such as this when you are addressed by this strange white man.
*else
	*set jesse_rapport %-25
	
	You establish a haven quickly upon arriving in the city.  You begin to scout the area, identify the best places to hunt for prey.
	
	It soon becomes clear that you are not the only vampire in New-Orleans.  One of your kind accosts you one evening; besides being frustrated at your very existence, he is further angered to discover that you share no common tongue.
	
	The vampire indicates clearly that you must follow him; his demeanor does not brook dissension.  He leads you to a house lit by candlelight.
	
	*page_break 
	*set met_estefania true
	Entering the house, the vampire escorts you into a room where there are two more vampires: a Spanish woman, and a Dutchman in archaic garb.
	*if speaks_german
		The Dutchman introduces himself in German as Pieter van der Velde, Quaestor of New-Orleans.  He introduces the Spanish woman—Estefania Rios e Hidalgo—and your escort, Jesse Whitaker.
	*else
		By means of the Spanish woman—Estefania Rios e Hidalgo—you are introduced to the Dutchman—Pieter van der Velde, Quaestor of New-Orleans—and your escort, Jesse Whitaker.
	*if priest
		*set rios_rapport %+5
	
		Curiously, Sra. Rios curtsies to you when you are introduced; it appears that, even in death, she respects your vocation.
	*goto meet_quaestor_1
	
*set jesse_rapport %-20

"I suppose that you were simply waiting for the opportune moment in which to make yourself known to ${new_orleans_quaestor_address}?"

"If by opportune moment you mean waiting to meet you, then yes."

"Well, you may consider yourself blessed, as this evening you have made the acquaintance of Jesse Whitaker, firstmade of ${new_orleans_quaestor_address}."

"It is my honor, sir.  I am ${mr} ${given_name} ${surname}, progeny of West."

At this, Jesse smiles mischievously: "I am surprised to see you standing upright and clothed in something other than rags.  I have had intermittent dealings with West in the past, and he always seemed to be squandering his immortality on the most trivial things.  And his odor," an exclamation which he reinforces with a dramatic gesture, "I thought I would never get it out of Governor Overstreet's drawing room!"
*set heard_of_overstreet true

*choice
	#"Well, I assure you, I both walk upright and tend to my physical affects with care."
		"That is a relief. Well,
	#"You've been misinformed," you reply dryly.
		"Oh? Have I? Are you quite certain? Well, regardless,
	#"Somehow, I escaped that particular curse. Though, I hear his other progeny were not so fortunate," you extemporize.
		"How dreadful! I am so glad that you escaped. You must come soon.
I am sure that ${new_orleans_quaestor_address} will be anxious to make your acquaintance."

"Please, let him know that I am looking forward to it."

"Enjoy the ball.  The belle is almost…effervescent…if you ask me."  At that moment you see him glance across the room to the young lady of the house, who blushes under his gaze and quickly turns back to her bevy of suitors.

After Whitaker's departure, much of the enjoyment of the evening drains away.  As dangerous as others of your kind are, their presence is ever so much more exciting than simple humans.

*page_break
*set met_estefania true
You are @{(independence > 50) invited|summoned} to another soirée a few nights later. It seems the vampires of New-Orleans @{(independence < 50) are not done with you.|desire your company.}
*if (speaks_english = false) and (speaks_french = false)
	*bug Not possible.
	*if speaks_german = false
		Conveniently, there is a vampire of youthful appearance—identified as Estefania Rios e Hidalgo—who serves as a translator for you.
	*else
		${new_orleans_quaestor_surname}, conveniently, speaks German, and is thus able to conduct the interview in that language.
				
		Besides ${new_orleans_quaestor_surname} and Jesse, there is also a vampire of youthful appearance who is introduced to you as Estefania Rios e Hidalgo.
*else
	Besides ${new_orleans_quaestor_surname} and Jesse, there is also a vampire of youthful appearance who is introduced to you as Estefania Rios e Hidalgo.
*if priest
	*set rios_rapport %+5

	Curiously, Sra. Rios curtsies to you when you are introduced; it appears that, even in death, she respects your vocation.
			
*label meet_quaestor_1

${new_orleans_quaestor_surname} begins: "The offspring of West, standing before me as well-dressed as any other upstanding citizen.  Never did I anticipate this, but I should know by now that all things under heaven are possible.  I am told that you desire to live in my city?"

"I do, ${new_orleans_quaestor_address}."

"And I assume that West fulfilled the duties of a dominus, and instructed you in the Rules of our kind?"

"He did, ${new_orleans_quaestor_address}."

"That is good to hear.  Please know that I have regular gatherings at my haven to keep everyone abreast of things in my city.  I will expect your attendance."

"Of course, ${new_orleans_quaestor_address}."
*page_break
Over the next few weeks, it becomes clear to you that all is not tranquil among the vampires of New-Orleans.  It seems that Mr. Whitaker is recently returned from a peregrination abroad.  Apparently his separation from ${new_orleans_quaestor_surname} occurred under questionable circumstances, and his return has been greeted with a mixture of joy and suspicion.

The presence of Sra. Rios, moreover, does nothing to ease the situation.  You learn that she too is a recent arrival, hailing from the Caribbean.  Her objectives remain obscure, but they may have something to do with her broodmate, Fernando de Villanueva e Itamaraca, a vampire pirate notorious for his ruthlessness.  Villaneuva has long consorted with Jean Lafitte, a mortal pirate who sheltered at nearby Barataria Bay, and the presence of Sra. Rios puts some sort of pressure on ${new_orleans_quaestor_surname}. But Lafitte recently died during a sea battle with the Spanish, and so the balance of power has shifted again.

In other words, there is no peace to be had in New-Orleans.
*set heard_of_villanueva true
*page_break 

*label estefanias_question
*if maffi_contactable
	*set haitian_sugar_plot 2
	*temp multiple streetwise
	During this period, you begin work on a smuggling operation. It is designed to help Haitian sugar arrive in New-Orleans, evading the embargo levied against the young republic by the slaveholders that dominate the US Congress.
	*if ethnicity = "spanish"
		*set multiple +1
		You even reach out to some of Lafitte's former associates in Barataria Bay to help; they are only too happy to oblige.
	
	You can't say that the effort changes anything for Haiti, but Thérèse writes to you to express her gratitude.
	*set maffi_rapport %+(multiple * 5)
	*if compassion > 40
		*set income +multiple
		*set haitian_sugar_plot 3
		Moreover, you skim some of the profits off the top for yourself. You're certainly entitled to such, since you are facilitating the whole thing.
	*page_break
*set year 1827
It is not uncommon for ${new_orleans_quaestor_surname} to host evenings at his haven, welcoming Jesse, Estefania, and yourself there to make sure all is well in his city.

One particular evening, while Jesse and ${new_orleans_quaestor_surname} are engrossed in a game of billiards, Estefania begins plying you with questions.
*if (speaks_english = false) and ((speaks_french = false) and (speaks_spanish = false))
	On occasions such as this, she has learned to bring a translator along, so that she can actually understand your responses.  Once you've made it through the confusion of translations and innuendo, what she seems to be asking is this: what is it that you intend to do with your immortal existence?
*else
	Once you've sifted through the innuendo and implications, what she seems to be asking is this: what is it that you intend to do with your immortal existence?

*temp answer_1
*set answer_1 "empty"

*choice
	#I hope to serve @{jesse_is_broodmate my dominus, |}${new_orleans_quaestor_address}, to the best of my abilities.
		*set rios_rapport %+5
		*set new_orleans_quaestor_rapport %+5
		"That is very dutiful of you, ${mr} ${surname}.  I hope ${new_orleans_quaestor_surname} appreciates your devotion."

		Perhaps more important than your answer is whether or not you are telling the truth.
		*choice
			#Yes, I speak the truth.
				*set discretion %+10
				*set goal 13
				You are surprisingly forthright for a vampire.
				*goto estefanias_question_2
			#No, I am lying.
				*set answer_1 "serve"
				*set discretion %-10
				*goto real_answer
	#I hope to become fabulously wealthy and to luxuriate until the end of time.
		"How very interesting.  I suppose that is one way to fritter away one's immortality," she replies with a hint of distaste.
		*set rios_rapport %-10

		Perhaps more important than your answer is whether or not you are telling the truth.
		*choice
			#Yes, I speak the truth.
				*set discretion %+10
				*set goal 6
				You are surprisingly forthright for a vampire.
				*goto estefanias_question_2
			#No, I am lying.
				*set discretion %-10
				*set answer_1 "wealth"
				*goto real_answer
	#I hope to learn the secrets of our kind.
		*set discretion %+5
		"I have watched many of our kind, older and wiser than yourself, drive themselves mad seeking out the truth of our origins.  You might want to reconsider such quixotic pursuits."

		Perhaps more important than your answer is whether or not you are telling the truth.
		*choice
			#Yes, I speak the truth.
				*set discretion %+10
				*set goal 7
				You are surprisingly forthright for a vampire.
				*goto estefanias_question_2
			#No, I am lying.
				*set discretion %-10
				*set answer_1 "lore"
				*goto real_answer
	#I hope to advance my standing in the Society; maybe I can become a quaestor@{senators_explained  or even a senator|} some day.
		*set rios_rapport %+5
		"I like to see a young vampire with ambition.  But I would recommend that you not seek to rise too far too quickly," she concludes.

		Perhaps more important than your answer is whether or not you are telling the truth.
		*choice
			#Yes, I speak the truth.
				*set goal 3
				*set discretion %+10
				You are surprisingly forthright for a vampire.
				*goto estefanias_question_2
			#No, I am lying.
				*set discretion %-10
				*set answer_1 "status"
				*goto real_answer
	*if (religious_tradition = "catholic") or (religious_tradition = "reformed")
		*selectable_if (rationalism >= 50) #I hope to redeem myself in the eyes of God.
			*set rios_rapport %+15
			She grows momentarily sober and her eyes soften.  
			*if speaks_english or (speaks_spanish or speaks_french)
				Looking around the room, she leans in to whisper in your ear.
			*if (speaks_english = false) and ((speaks_french = false) and (speaks_spanish = false))
				Looking around the room, she waits until Jesse is clearly distracted before speaking to the translator.
			*comment endif
			
			"I wish you good fortune with that.  Too many of our kind have turned away from our Our Lord and Savior, not realizing that we are still his disciples.  After all, do we not partake of His blood whenever we sup on His mortal children?"
			
			She leans back, releases a fake laugh, and directs the conversation to other things.

			Perhaps more important than your answer is whether or not you are telling the truth.
			*choice
				#Yes, I speak the truth.
					*set discretion %+10
					*set rationalism %+20
					*set compassion %-5
					*set goal 4
					You are surprisingly forthright for a vampire.
					*goto estefanias_question_2
				#No, I am lying.
					*set discretion %-10
					*set answer_1 "redemption"
					*goto real_answer
	*if religious_tradition = "pagan"
		*selectable_if (rationalism >= 50) #I hope to redeem myself in the eyes of Hushtahli.
			*set rios_rapport %-15
			She scoffs at your primitive faith.  "I hope that somenight soon you realize your folly, before it is too late to redeem yourself."

			Perhaps more important than your answer is whether or not you are telling the truth.
			*choice
				#Yes, I speak the truth.
					*set goal 5
					*set discretion %+10
					*set rationalism %+20
					*set compassion %-5
					You are surprisingly forthright for a vampire.
					*goto estefanias_question_2
				#No, I am lying.
					*set discretion %-10
					*set answer_1 "redemption"
					*goto real_answer
	*selectable_if (creation > 0) #I hope to make art that will withstand the test of time.
		"That is an interesting thought.  I hope that some day I will be fortunate enough to see such a work of yours."

		Perhaps more important than your answer is whether or not you are telling the truth.
		*choice
			#Yes, I speak the truth.
				*set goal 8
				*set discretion %+10
				You are surprisingly forthright for a vampire.
				*goto estefanias_question_2
			#No, I am lying.
				*set discretion %-10
				*set answer_1 "art"
				*goto real_answer
	*selectable_if (compassion <= 60) #I hope to find a love that will transcend death itself.
		"You are so young and idealistic.  Has ${new_orleans_quaestor_address} failed to teach you that love is not for vampires?"

		Perhaps more important than your answer is whether or not you are telling the truth.
		*choice
			#Yes, I speak the truth.
				*set goal 10
				*set discretion %+10
				You are surprisingly forthright for a vampire.
				*goto estefanias_question_2
			#No, I am lying.
				*set discretion %-10
				*set answer_1 "love"
				*goto real_answer
	*selectable_if ((technology > 0) or (rationalism < 40)) #I want to know the secrets of Nature; to a scientific mind such as mine, everything will be revealed!
		"Nature? Are you one of those…philosophers?"
		
		"There has been some debate about the terms philosopher and man of science…"
		*if male = false
			you clear your throat. "Clearly, I wish there were another term than that."
		
		"And between the two?"
		
		"I am, as of yet, undecided. I wish to know more…discover more…before I decide on the which schema of knowledge is best."
		
		Perhaps more important than your answer is whether or not you are telling the truth.
		*choice
			#Yes, I speak the truth.
				*set goal 11
				*set discretion %+10
				*set rationalism %-20
				You are surprisingly forthright for a vampire.
				*goto estefanias_question_2
			#No, I am lying.
				*set discretion %-10
				*set answer_1 "science"
				*goto real_answer

*label real_answer

Thus, the real question is, what do you really hope to accomplish with your existence?

*choice
	*if (sirethoughthewasagod or idea_for_cult) or (discretion > 65)
		#I wish to become a god, worshipped by mortals far and wide.
			*set idea_for_cult true
			*set independence %-10
			*set discretion %+30
			*set goal 2
			Perhaps some day you will be able to establish such a temple to yourself.
	*if answer_1 != "status"
		#I want to be respected and feared by the other members of the Society!  I want titles for myself!
			*set independence %+20
			*set discretion %+20
			*set goal 3
			It's a good thing you're honest with yourself.
	*if (answer_1 != "redemption") and ((religious_tradition = "catholic") or (religious_tradition = "reformed"))
		*selectable_if (rationalism >= 50) #I hope to redeem myself in the eyes of God.
			*set rationalism %+25
			*set compassion %-10
			*set goal 4
			Perhaps, in time, your devotion and good works will redeem you in the eyes of your Lord.
	*if (answer_1 != "redemption") and (religious_tradition = "pagan")
		*selectable_if (rationalism >= 50) #I hope to redeem myself in the eyes of Hushtahli.
			*set rationalism %+25
			*set compassion %-10
			*set goal 5
			Perhaps, in time, your devotion will reconcile you with the Sun God.
	*if answer_1 != "wealth"
		#I hope to become fabulously wealthy, never to worry again about my creature comforts.
			*set discretion %+10
			*set goal 6
			It's a good thing you are honest with yourself.
	*if answer_1 != "lore"
		#I hope to discover the origins of our kind.
			*set goal 7
			Perhaps, in time, you will unveil the secrets of vampirism.
	*if answer_1 != "art"
		*selectable_if (creation > 0) #I hope to make a work of art to stand the test of time.
			*set goal 8
			Ah, the young and idealistic.
	*selectable_if (compassion < 65) #I wish that there were some way to become human again…
		*set rationalism %+10
		*set compassion %-20
		*set goal 9
		You probably should not put stock in such fairy tales.
	*if answer_1 != "love"
		*selectable_if (compassion < 65) #I hope to find a love that will transcend death itself.
			*set goal 10
			Ah, the young and idealistic.
	*if answer_1 != "science"
		*selectable_if ((technology > 0) or (rationalism < 40)) #I want to know the secrets of Nature; to a scientific mind such as mine, everything will be revealed!
			*set goal 11
			*set rationalism %-20
			In the fullness of time, who knows what secrets will reveal themselves to your experiments!
	#I hate all vampire-kind and I wish to destroy them all.
		*set compassion %+10
		*set discretion %+5
		*set independence %-25
		*set goal 12
		No wonder you didn't confess your desires to Estefania!
		
		Surely you have a hard and lonely road ahead of you, but if your goal is to put an end to others of your kind, there is no doubt that time and patience will present you with suitable opportunities.
		
*label estefanias_question_2

In addition to her questions about your immortal objectives, Estefania likes to talk about blood.  Or, rather, she enjoys discussing the flavors of her prey, much as a mortal would discuss the notes of their wine.
*if perception = 0
	Unfortunately, as far as you're concerned, blood pretty much tastes like blood.  About the only thing you can say is that you don't particularly care for the blood of rats.
*if perception = 1
	While you can distinguish broad strokes, Estefania clearly has a palate that dwarfs yours.
*if perception = 2
	While you are far from impressing Estefania with your refinement, she clearly sees potential.
*if perception > 2
	It is with great pleasure that you can discuss the subtleties of the bouquets of various mortals.

"You know, a vampire's choice of prey really does say a lot about them.  What's more, each individual has what the French called a [i]terroir[/i]…the essence of their lives.  How your prey spends their time and what they themselves consume communicates a unique flavor to the blood.  What sort do you prefer?" @{(perception <= 1) Even if the taste is indistinguishable to you, the preferences expressed by the choice is clearly of interest to her.|}
*choice
	#I like to feed from the itinerant, the better to disguise my presence.
		*set rios_rapport %-5
		*set answer_to_estefania 1
		Are you being honest?
		*choice
			#Yes, I speak the truth.
				*set discretion %-10
				*set feeding_style "itinerants"
				*goto estefanias_response
			#No, I am lying.
				*set discretion %-5
				*goto real_answer_4
	#I like to feed from among the wealthy and high-born; their refinement carries into the quality of their blood.
		*set rios_rapport %+10
		*set answer_to_estefania 2
		Are you being honest?
		*choice
			#Yes, I speak the truth.
				*set discretion %+5
				*set income +5
				*set feeding_style "socialites"
				*goto estefanias_response
			#No, I am lying.
				*set discretion %-5
				*goto real_answer_4
	*if creation > 0
		#I like to feed from craftsmen, musicians and actors; their blood imparts a taste of their creative soul.
			*set answer_to_estefania 3
			*set rios_rapport %+15
			Are you being honest?
			*choice
				#Yes, I speak the truth.
					*set anachronism %+5
					*set compassion %-5
					*set feeding_style "artists"
					*goto estefanias_response
				#No, I am lying.
					*set discretion %-5
					*goto real_answer_4
	#I like to feed from soldiers and other military types, as it sustains my warrior's soul.
		*set rios_rapport %-5
		*set answer_to_estefania 4
		Are you being honest?
		*choice
			#Yes, I speak the truth.
				*set discretion %+5
				*set feeding_style "soldiers"
				*goto estefanias_response
			#No, I am lying.
				*set discretion %-5
				*goto real_answer_4
	*if (streetwise > 0) and (perception > 0)
		#I like to feed from gamblers.  The rush of the win and the loss communicates itself through the blood.
			*set answer_to_estefania 11
			Are you being honest?
			*choice
				#Yes, I speak the truth.
					*set discretion %-5
					*set compassion %+10
					*set feeding_style "gamblers"
					*goto estefanias_response
				#No, I am lying.
					*set discretion %-5
					*goto real_answer_4
	*if streetwise > 0
		#I like to feed from whores.  If one goes missing, no one cares.
			*set rios_rapport %-10
			*set answer_to_estefania 5
			Are you being honest?
			*choice
				#Yes, I speak the truth.
					*set discretion %-5
					*set compassion %+10
					*set feeding_style "prostitutes"
					*goto estefanias_response
				#No, I am lying.
					*set discretion %-5
					*goto real_answer_4
	#I like to feed from children.  Their innocence is intoxicating.
		*set rios_rapport %-15
		*set answer_to_estefania 6
		Are you being honest?
		*choice
			*selectable_if (compassion > 55) #Yes, I speak the truth.
				*set compassion %+15
				*set feeding_style "children"
				*goto estefanias_response
			#No, I am lying.
				*set discretion %-5
				*goto real_answer_4
	*if (knows_about_vegetarianism) and (compassion < 40)
		#I strive to only feed from animals; I cannot bear the suffering I cause to humans.
			*set rios_rapport %-20
			*set answer_to_estefania 7
			Are you being honest?  Only those with a strong sense of will can force themselves to consistently feed from animals.
			*choice
				*selectable_if (willpower > 2) #Yes, I speak the truth.
					*set compassion %-10
					*set independence %-5
					*set feeding_style "vegetarian"
					*achieve vegetarian
					*set achieve_vegetarian true
					*goto estefanias_response
				#No, I am lying.
					*set discretion %-5
					*goto real_answer_4
	#I feed from workmen.  An honest day's labor provides a musk that is unmistakable.
		*set rios_rapport %-10
		*set answer_to_estefania 8
		Are you being honest?
		*choice
			#Yes, I speak the truth.
				*set compassion %+10
				*set feeding_style "laborers"
				*goto estefanias_response
			#No, I am lying.
				*set discretion %-5
				*goto real_answer_4
	*if (discretion >= 40) and (compassion >= 40)
		#I like to feed from members of the clergy.  There is a special irony in showing them the futility of their faith.
			*set rios_rapport %-15
			*set answer_to_estefania 9
			
			Are you being honest?
			*choice
				*selectable_if (rationalism <= 80) #Yes, I speak the truth.
					*set compassion %-10
					*set discretion %+10
					*set feeding_style "clergy"
					*goto estefanias_response
				#No, I am lying.
					*set discretion %-5
					*goto real_answer_4
	#I like to feed from the intoxicated.  They do not resist, and further a portion of the intoxicant is passed along with the blood…
		*set rios_rapport %-15
		*set answer_to_estefania 10
		Are you being honest?
		*choice
			#Yes, I speak the truth.
				*set compassion %-10
				*set discretion %+10
				*set feeding_style "drunks"
				*goto estefanias_response
			#No, I am lying.
				*set discretion %-5
				*goto real_answer_4
					
*label real_answer_4

From whom do you really like to feed?

*choice
	*if answer_to_estefania != 3
		*selectable_if (creation > 0) #I like to feed from craftsmen, musicians and actors…their blood imparts a taste of their creative soul.
			*set anachronism %+5
			*set compassion %-5
			*set feeding_style "artists"
			*goto estefanias_response
	*if answer_to_estefania != 1
		#I like to feed from the itinerant, the better to disguise my presence.
			*set discretion %-10
			*set feeding_style "itinerants"
			*goto estefanias_response
	*if answer_to_estefania != 5
		*selectable_if (streetwise > 0) #I like to feed from whores.  If one goes missing, no one cares.
			*set discretion %-5
			*set compassion %+10
			*set feeding_style "prostitutes"
			*goto estefanias_response
	*if answer_to_estefania != 2
		#I like to feed from among the wealthy and high-born; their refinement carries into the quality of their blood.
			*set discretion %+5
			*set income +5
			*set feeding_style "socialites"
			*goto estefanias_response
	*if answer_to_estefania != 4
		#I like to feed from soldiers and other military types…their blood sustains my warrior's soul.
			*set discretion %+5
			*set feeding_style "soldiers"
			*goto estefanias_response
	*if answer_to_estefania != 6
		*if compassion > 50
			#I like to feed from children.  Their innocence is intoxicating.
				*set compassion %+15
				*set feeding_style "children"
				*goto estefanias_response
	*if answer_to_estefania != 7
		*if (compassion < 40) and (knows_about_vegetarianism)
			*selectable_if (willpower > 2) #I strive to only feed from animals; I truly cannot bear the suffering I cause to humans.
				*set compassion %-10
				*set independence %-5
				*achieve vegetarian
				*set feeding_style "vegetarian"
				*goto estefanias_response
	*if answer_to_estefania != 8
		#I like to feed from laborers.  An honest day's labor provides a musk that is unmistakable.
			*set compassion %+10
			*set feeding_style "laborers"
			*goto estefanias_response
	*if answer_to_estefania != 9
		*if (discretion >= 40) and (compassion >= 40)
			*selectable_if (rationalism < 50) #I like to feed from members of the clergy.  There is a special irony in showing them the futility of their faith.
				*set compassion %+10
				*set discretion %+10
				*set feeding_style "clergy"
				*goto estefanias_response
	*if answer_to_estefania != 11
		*if (streetwise > 0) and (perception > 0)
			#I like to feed from gamblers.  The rush of the win and the loss communicates itself through the blood.
				*set feeding_style "gamblers"
				*set discretion %+5
				*goto estefanias_response
	*if answer_to_estefania != 10
		#I like to feed from the intoxicated.  Not only do they not resist, but a portion of the intoxicant is passed along with the blood…
			*set discretion %-10
			*set feeding_style "drunks"
			*goto estefanias_response

*label estefanias_response

*if answer_to_estefania = 1
	"Oh, but the quality of their blood is so…haphazard.  You never know what you're getting until it is too late.  Here, there is a young man that you simply must meet.  He is something of a dilettante, but there really is something to him.  Perhaps you will change your mind; let me give you his card."
*elseif answer_to_estefania = 2
	"How lovely to hear that!  You simply must meet M. Hébert!  I may have tired of him, but you will no doubt find him delightful.  Let me give you his card."
*elseif answer_to_estefania = 3
	*set knows_estefania_likes_musicians true
	"I know exactly what you mean.  Mine own affinity for the arts often leads me to the same.  There's nothing like playing a little Mozart after feeding from a young musician."  She sighs, seemingly lost in reverie.  When she returns her attention to you, she does so with a smile.  "There is a fledgling musician by the name of Hébert who lives on Rue Conti.  His blood is most intoxicating.  Here is his card; you should call on him."
*elseif (answer_to_estefania = 4) or (answer_to_estefania = 5)
	"${mr} ${surname}, we really must work on refining your sense of taste.  This will never do.  Here," she says, handing you a calling card, "there's a young dilettante of whom I've grown tired.  You should call on him."
*elseif answer_to_estefania = 6
	"That is…reprehensible, ${mr} ${surname}."

	"Reprehensible?"

	"Truly, it is.  Here is the card of M. Yves Hébert.  His blood has an ethereal quality.  Perhaps it can wean you from your cruel pastime."
*elseif answer_to_estefania = 7
	"If I were you, I would not be so cavalier about revealing such.  You are young and tender-hearted, you will grow out of it in time.  After all, one cannot maintain such a diet forever.  Until then, however, do not speak of such things.  It is improper."

	"Improper?"

	"Yes.  Here, there is a young man that you simply must meet.  He is something of a dilettante, but there really is something to him.  I am sure that you will change your mind once you've met him; here, let me give you his card."
*elseif answer_to_estefania = 9
	"[i]Ay, dios mio[/i]!" she exclaims, crossing herself.  "What sort of animal are you, feeding from Our Lord's anointed?  Please, please, I beg of you, do not do this.  Here, my most prized vessel…name is Hébert.  Here is his card.  Go see him, and I shall pray for you that he turns you from this path of wickedness."
*elseif answer_to_estefania = 10
	"Then you will love my dear friend M. Hébert.  He loves his whiskey so.  Here, let me give you his card…"
*elseif answer_to_estefania = 11
	"I have observed this game which the M. de Marigny brought to these shores.  I confess, it makes little sense to me.  As you are surely aware, I prefer cards.  And, while I can imagine that the rush of their emotions would provide a heady draught, I would urge you to call upon an acquaintance of mine, M. Hébert."
	
	"M. Hébert?"
	
	"Yes, he has the most exquisite [i]terroir[/i] to his blood.  Believe me, you will no longer seek the blood of those dice-throwers if you taste him, even just once."
*else
	"That is so…avant-garde.  A little too avant-garde for my tastes.  Here, there is a young man that you simply must meet.  He is something of a dilettante, but there really is something to him.  Perhaps you will change your mind; here, let me give you his card."

*if ethnicity = "yankee"

	"I would be happy to make his acquaintance."
	
	"Well, be aware that he may be a little hesitant being seen with one of your sort.  So I would suggest not trying to go out on the town with him."
	
	"One of my sort?"
	
	"A Yankee, dear ${given_name}.  You know how the Creoles detest their new lords.  But perhaps, for you, he can make an exception."
	
	"Let us hope…"

*if (feeding_style = "artists") or (feeding_style = "socialites")
	*finish Next
*elseif feeding_style = "prostitutes"
	*page_break
	*set knows_parts_dont_work true
	A few nights later, you find yourself in one of your favorite brothels, preparing to feed.  The thought occurs to you that you have not engaged in intercourse per se since your conversion.  In fact, possessed as you are by your hunger, the subject of sex has held little interest for you.  But here, surrounded by mostly naked flesh, the thought occurs to you that you should have your way with someone.

	To your frustration, you discover that your body does not respond to stimulation the way it did when you were alive.  Despite the whore's best efforts, your dead flesh remains cold and sensationless.  In frustration, you sink your fangs into her throat, and let the blood flowing past your lips momentarily erase the thoughts of what you have lost.
	*page_break
	Recalling Estefania's offer, you finger M. Hébert's calling card impatiently.  If the pleasures of the flesh are beyond your grasp, perhaps she is right that there is something more to be learned about the taste of blood.
*else
	*page_break
	A few nights later, you happen upon M. Hébert's calling card on your desk.  Though you do not normally fancy the idle rich, Estefania's description of him has a strange appeal…

*choice
	#Yes, I will take Estefania up on this offer, and call on M. Hébert.
		*goto_scene new_orleans_affair
	#No.  I discard the calling card.
		*set invitation_to_hebert_ignored true
		*goto_scene new_orleans_rapport

*label therese_convo
"Thérèse!" you call.

She has made it to the front door; Ajax stands there, holding it open for her. "What?"

"Please, don't let ${new_orleans_quaestor_surname} chase you from New-Orleans so quickly."

"I think he made his position perfectly clear," she says as she dons her coat. It is a rich blue color, with a high collar.

"We are not all so callous…"

"${given_name}, I have other matters to attend to. If you wish to accompany me on my way, you may, but I will not stand here and debate this with you in the door of a house where I am not welcome." With that, she steps out into the street.

Hesitating for only a moment, you fetch your own coat and follow her.
*temp questions 0
*temp rev_sequence 1
*temp veg_question false
*page_break
You catch up to her moments later. She strides purposefully forward without looking in your direction.
*label therese_loop
*set questions +1
*if questions = 2
	She steps over a puddle—leaving you to @{(agility > 2) narrowly skirt it|stumble into it}. You emit a small curse and try to organize your thoughts.
*if questions > 3
	"We're here," she announces suddenly.

	You look up. It is the Bank of New-Orleans. A sleepy gendarme emerges with a lantern to greet Thérèse; inside, you can see a banker shifting from one foot to the other uncomfortably.

	"As I said, I have other matters to attend to, ${given_name}. Perhaps we shall meet again some day."

	"Yes. Goodnight, Thérèse."

	She turns on her heel and sweeps past the gendarme and into the marble temple of currency.
	*return
*choice
	#"Who is your maker?"
		*set independence %+5
		"He thought of himself as a philosopher. Enlightened. He thought that the secrets of the Society should be shared rather than hidden."

		"Sounds like an ideal dominus."

		"He was a monster like the rest of them."

		"Does that include me?"

		"Are you a vampire? Do you drink the blood of the living to keep you in a state of perpetual youth?"

		"Don't you?"

		"No."
		*if knows_about_vegetarianism
			"Do you mean that you feed from animals alone?"

			"Yes."

			*if feeding_style = "vegetarian"
				*set maffi_rapport %+30
				"As do I."

				She stops for the first time and looks at you. Really looks at you. "You may have potential yet, ${given_name}."
			*else
				"I have heard of your kind. How do you manage it? Isn't the blood foul-tasting?"

				"So it is. But it is unethical to feed from humans, and so I do not."
			*goto therese_loop
		*else
			*set veg_question true
			You draw back in surprise. That was not the answer you were anticipating.
			*goto therese_loop
	*if (veg_question) #"What do you mean you don't drink the blood of the living?"
		*set knows_about_vegetarianism true
		*set met_maffi 3
		"I mean that I feed exclusively from animals."

		You recoil at the thought. "But their blood…it smells…rotten. Befouled."

		"So it does."

		"But how can you?"

		"How can you not? How have you accepted that you must drink the blood of humans?"

		You bite back an angry retort. As incriminating as those conclusions may be for you, you cannot refute them.
		*goto therese_loop
	#"Are you from Haiti?"
		*set rev_sequence +1
		"I was born outside Cap-Français, yes."

		"But you seem…"

		"So cultured? Urbane?"

		"Yes, that."

		"My father was a complicated man. He sent me to Paris for what passes for education for young women. I was introduced to the philosophers of the Enlightenment."

		"And that turned you into a revolutionary?"

		"How could it not? When you look at the injustices of the world and apply the principles of reason without regard to prejudice or affection, there is no other conclusion."

		"So you believe in the French Revolution?"

		"I believe in the ideals of the French Revolution, yes."
		*if compassion < 60
		
			"And do you believe in the guillotines as well?"
			
			"There are many who will never reject the customs of their youth or their own self-interest. Those individuals will always work to undermine justice and return society to a previous state. In a perfect world, perhaps they could be shown the error of their ways. But this is not a perfect world."
			
		"I see," you reply.
		
		*goto therese_loop
	*if (rev_sequence = 2) #"You believe in the ideals, but not the revolution itself?"
		*set rev_sequence +1
		*set maffi_rapport %+5
		*if questions = 3
			*set questions -1
		"Men are born and remain free and equal in rights," she quotes. "And, while some in the revolution applied that principle fairly—to women and Africans—the majority did not.

		"I thought that, in time, the French would come around, but not of their own accord. Not as long as the colonies were funding the Revolutionary government. So, when I heard about the uprising back home, I knew where I needed to be. I took the first ship that I could, and once I landed in Saint-Domingue, I sought out the army of liberators.

		"The French National Assembly did eventually abolish slavery, but only because the white aristocrats of Haïti had declared themselves for Great Britain. The French Revolutionaries needed the former slaves to fight off the British, the Spanish, and the former slave-holders. Suddenly, they needed us in order to maintain possession of the colony.

		"And we won. We defeated the British and the Spanish and our former masters. But then Napoleon came to power and decided that he needed Haiti back in chains. He revoked the abolition of slavery and launched an invasion with the goal of recapturing the island. And we defeated him too.

		"To answer your question, then: I do believe in the ideals of the French Revolution. But those ideals have only been carried to their logical conclusion in Haïti. Not in the United States, and not in France."
		*goto therese_loop
	*if (rev_sequence = 3) #"You mean to say that women have been given the right to vote in Haiti?"
		*set rev_sequence +1
		*if questions < 4
			*set questions -1
		Thérèse's face twists as though she sank her fangs into a lemon. "No, not yet."

		"So what do you mean that the ideals have been carried to their logical conclusion?"

		"I am working on it," she snaps.
		*goto therese_loop
	#"What can I do to help?"
		*set maffi_rapport %+5
		"Do you have ten milliion francs? Five million?"

		"No…"

		"Can you get it?"

		"I don't think so."

		"What about a squadron of ships, capable of defeating the French navy?"

		"No…"

		"Can you convince your President to recognize Haïti?"

		*if (ethnicity = "african") or (ethnicity = "choctaw")
			"He is not my President and this is not my country," you retort.
			
			For the first time she stops and looks at you. "No, I suppose not. Forgive me."
			
			You nod. "I know Congress will never recognize Haiti. To do so would encourage @{(ethnicity = "african") our brothers and sisters|the slaves here} to revolt."
			
			"Exactly. And, more to the point, American privateers are free to raid our merchantships and take what they want, since—as far as they are concerned—we do not exist."
			
			You clench your jaw. The hypocrisy of the United States—whose ideals are hamstrung by the Southern élites—is consistantly galling.
			
			"We must not dally," she says, continuing on.
		*elseif (ethnicity = "irish") or ((ethnicity = "spanish") and (priest = false))
			"My President? I have no President."
			
			She rolls her eyes at you. "That's one way of looking at the matter, I suppose."
			
			You growl, allowing her to gloss over the subject. "Congress will never recognize Haiti. To do so would encourage the slave here to revolt."
			
			"Exactly. And, more to the point, American privateers are free to raid our merchantships and take what they want, since—as far as they are concerned—we do not exist."
			
			You clench your jaw. The hypocrisy of the United States—whose ideals are hamstrung by the Southern élites—is consistantly galling.
			
			"We must not dally," she says, continuing on.
		*else
			"We don't recognize Haiti?"

			"No. Your government is too afraid that we will encourage your slaves to revolt. And since we don't exist, your privateers are free to raid our merchantships and take what they want. Could you help with that?"

			"I suppose not."
			
			She shrugs.
		"You are a young vampire, yes?"

		"Yes."

		"I am not so old. It is not bad to be young. But you must use the time that you have. What have you been doing? Attending salons and dinner parties and gossiping with ${new_orleans_quaestor_surname} about the other members of the Society?"

		*if marigny_investment > 0
			*set maffi_rapport %-5
			"I have invested some capital with Bernard de Marigny. Perhaps he could help?"

			"Do you know what Bernard invests in?"

			You suddenly feel as though your esteem with Thérèse has declined. "Sugar?"

			"By which you mean slaves. Do you think someone whose livelihood depends on slavery will help Haiti?"

			If you were mortal you suspect that your ears would be burning. "I take your point."
		*if marigny_investment = 0
			It is difficult to refute her.

		"Ask me again when you have something to offer."

		*if streetwise > 0
			*set maffi_rapport %+5
			"What about smuggling?"

			"Smuggling?"

			"There's an embargo of warships. You need to get Haitian goods out of Haiti and supplies in. What if I could help with that?"

			"Do you know any smugglers?"

			*if (ethnicity = "spanish")
				"I did, but he died recently." Jean Lafitte was a hero to the [i]Isleños[/i]. @{(new_orleans_quaestor_surname = "Villanueva") |He recently died while attempt to seize a pair of Spanish silver transports.} "But I can find others!"
			*else
				"It would not be hard for me to meet them."

			She stops. "Very well. Let me know when and how."

			She dictates the manner in which you may contact her.
			*set maffi_contactable true
		*goto therese_loop
	*if (jesse_mum) #"What happened between you and Jesse? How do you know each other?"
		She stops and looks at you. "It's not what you think."

		"What do I think?"

		"You think we were lovers."

		"I didn't…"

		"You did."

		"Well, were you?"

		Thérèse snorts. "Not a chance. His journey to Saint-Domingue was a lark, an adventure. He was playing. Jesse, for all his talk, is not ready for revolution. When it came time, he had no stomach for it. The best he could do was get out of the way."

		"How do you know he has no stomach for it? Can't getting out of the way be enough?"

		"Perhaps, if he had continued afterwards. But he didn't, did he? No, he came home. Back to the world and the systems with which he was comfortable."
		*goto therese_loop
	*if (choice_randomtest = false) #I've heard enough. I take my leave of her.
		"Thank you for your time, Thérèse. It has been enlightening."

		"Good night," she says, without stopping.

		You watch as she strides away, indifferent to your new destination.
		*return