*comment ñáéç…—
*hide_reuse
*advertisement
*gosub_scene util check_flow
*gosub_scene util combat_value
*temp newcomer_pinned false
*temp man "man"
*if male = false
	*set man "woman"
*temp lies 0
*temp question_church false
*temp pinned_by_newcomer false
*temp helios_answers 0
*temp death_by_helios false
*temp heard_of_governor false
*temp before_quaestor false
*temp trounced false
*temp cecil_no_rules false 
*temp cname false
*if (new_orleans_quaestor_surname = "Villanueva") and ((new_orleans_quaestor_rapport > 55) or ((sire_surname = "Villanueva") and (new_orleans_quaestor_rapport >= 40)))
	*comment March 1823
	"He's dead."  Villanueva holds a letter in his hand.  He looks tired. 

	"Who's dead?"

	"Lafitte.  This letter says that he was buried at sea, in the Gulf of Honduras."

	"How did he die?" you inquire.

	"His ship was attempting to capture two Spanish merchantmen.  He was wounded in the battle, and died soon thereafter."
	*choice
		#"I suppose, once a pirate, always a pirate…"
			*set new_orleans_quaestor_rapport %+10
			*set discretion %-5
			Villanueva laughs.  "Yes, I suppose so.  He brought this on himself."

			*if compassion < 45
				You catch yourself exhaling—a curious thing, considering you no longer need to breathe—in relief.  You feel that this was a more delicate affair it might otherwise seem.
			"And you?  Do you miss the open sea?"

			Villanueva gets a faraway look in his eyes.  "I do.  But this is not why I summoned you here."

			"No?"

			"Alas, no.  And please, forgive me for the directness of this question…"

			"By all means, ${new_orleans_quaestor_address}!"
		*selectable_if (discretion > 30) #"Another criminal dying an ignominious death.  What of it?"
			*set new_orleans_quaestor_rapport %-25
			*set compassion %-10
			*set discretion %+10
			"It is not becoming to speak ill of the dead, ${mr} ${surname}."

			"If that were the case, then we vampires would be entirely unfit for the Society."

			Villanueva looks at you for a moment, and then breaks into a laugh.  "Right you are, right you are…"  You're not entirely sure that you meant that to be a jest, but you seem to have averted any immediate crises.  "But let us speak of the matter at hand," he continues.

			"The matter at hand?"
		#"It was as good a death as a man like him could have asked for.  Would you have preferred that he died of old age?"
			*set new_orleans_quaestor_rapport %+15
			"You speak truly, dear ${given_name}.  Tonight, I will feed in his honor."

			"That seems fitting, Quaestor.  Should I—"

			"Which brings me to why I called you here."

			"It was not for this?"

			"Alas, no.  And please, forgive me for the directness of this question…"

			"By all means, ${new_orleans_quaestor_address}!"
*elseif (new_orleans_quaestor_surname = "Sainte-Chapelle") and ((new_orleans_quaestor_rapport > 55) or ((sire_surname = "Sainte-Chapelle") and (new_orleans_quaestor_rapport >= 40)))
	"He's done it." Sainte-Chapelle holds a letter in hand. He's peering out the window of his library while you nervously wait for him to speak his mind.
	
	"Who's done what?"
	
	"My broodmate, Louis-Josephe. He's become the Governor of Montréal."
	*set heard_of_saint_cyr true
	
	*if taught_about_governors = false
		*bug
		"Governor?"
	
	*choice
		#"Congratulations?" you venture.
			*set new_orleans_quaestor_rapport %-5
			Sainte-Chapelle throws the letter he's holding onto his bureau. "My broodmate is a governor, and I am not yet even a quaestor!" he fumes.
			
			"I'm sure…" you begin.
			
			"I didn't ask you here to comfort me, ${given_name}. I asked you here to answer a question."
			
			"Oh, well—"
		#"I am certain that the Governor will rectify this situation soon…"
			*if independence >= 55
				*set new_orleans_quaestor_rapport %+5
				He seems calmed by your words. "Yes, of course. You're right."
				
				After a moment, you continue "Is that what you asked me here for?"
				
				"Oh, no. I had something much more pressing to ask of you."
				
				"Yes, Quaestor?" you say, emphasizing the use of his title.
			*else
				*set new_orleans_quaestor_rapport %-10
				"Since when have you cared about my position?" he grouses.
				
				"I thought—"
				
				"Enough. I didn't ask you here to comfort me, ${given_name}. I asked you here to answer a question."
				
				"Then please, ask away."
		#"Montréal is far away. I fail to see how this affects either of us."
			*if independence <= 45
				*set new_orleans_quaestor_rapport %+5
				Sainte-Chapelle rolls his eyes at you. "I suppose I cannot begrudge you answering me truthfully."
				
				"How do you mean?"
				
				"Your indifference to such news should not surprise me. But no matter, this is not why I asked you here in the first place."
			*else
				*set new_orleans_quaestor_rapport %-10
				"I'm disappointed in you, ${given_name}. You are generally much more interested in the machinations of the Society."
				
				"Not tonight, I suppose."
				
				"Clearly. But no matter; I asked you here for a different matter altogether."
		
			"Go on," you prompt.	
*else
	"${mr} ${surname}, please excuse the directness of this question."

	"But of course, ${new_orleans_quaestor_address}!"

"Have you been leaving the remains of your feeding in the Faubourg Marigny?" The Faubourg Marigny is an area being developed just to the east of the main city by Bernard de Marigny, @{attended_marignys_party whose celebration of the Battle of New-Orleans you attended.|a local businessman and philanthropist.} The neighborhood sprawls north from Marigny's mansion on Victory Street (a continuation of the rue de la Levée), the naming of which surely had nothing to do with Marigny's own role in the Battle of New-Orleans.

The significance of ${new_orleans_quaestor_surname}'s question dawning upon you—such deeds being a clear violation of the Rule of Reserve—you go pale with terror.  "No, ${new_orleans_quaestor_address}!  Most certainly not!  I would never draw such attention to us!"

"I thought not.  
*if knows_how_to_heal_bites = false
	After all, I did teach you how to heal the wounds that your fangs cause."
	
	"You did?"
	
	"Of course!  That is why they call it blood-spittle.  When a vampire applies his blood to a mortal's wound, it is instantly healed!"
	
	"Yes, you did teach me that.  I'm sorry, I had forgotten," you reply, deciding it best not to argue.
	
	"Well, anyway, it seems like someone has not learned this trick.  An unannounced guest.  As I'm sure you're aware, the presence of these anarchists cannot be tolerated.  Perhaps you would be so kind as to find this individual and attempt to remedy the situation?"
*else
	I could not imagine that one that I had spent so much time educating would do such a thing.  Unfortunately, that means that we have an unannounced guest.  As I'm sure you're aware, the presence of these anarchists cannot be tolerated.  Perhaps you would be so kind as to find this individual and attempt to remedy the situation?"
*if lore > 1

	Of course, since ${new_orleans_quaestor_surname} is not actually a quaestor yet, he has no authority to force you to go after this newcomer.  In fact, because his title is unofficial, this interloper has just as much of a right to be here as ${new_orleans_quaestor_surname} does.
*choice
	#"I am ever your servant, ${new_orleans_quaestor_address}."
		*set independence %+10
		*set new_orleans_quaestor_rapport %+10
			
		"I knew I could rely upon you, dear ${given_name}.  Not like Jesse.  Such a useless excuse for a vampire."
		
		"I'm sorry, ${new_orleans_quaestor_address}?"
		
		"Oh, nothing. @{jesse_is_broodmate Your elder broodmate|My firstmade}, Jesse Whitaker. He would never have assented so quickly.  That is why I prefer your company to his."
		
		"I…didn't know…"
		
		"Yes, yes…another time, we can discuss him."

		Realizing that you have been dismissed, you take your leave of ${new_orleans_quaestor_surname}.
	*if lore > 1
		*selectable_if (discretion > 40) #"I think it rather improper for you to seek to assert an authority you have no right to claim."
			*set independence %-5
			*set new_orleans_quaestor_rapport %-10
			*set discretion %+10
			${new_orleans_quaestor_surname}'s countenance goes slack at your brazen retort.  "This is quite a position you claim for yourself.  I hope you understand that, should you follow on this course, when the time comes that I am appointed as quaestor, I may no longer have room for you in this city?"
			
			"I hope it does not come to that, Quaestor."
			
			"Then I pray that you reconsider.  Answer me truly, now, ${mr} ${surname}.
			*goto reconsider
	*if lore > 1
		*selectable_if (status > 1) #"Perhaps Ajax would be better suited to this task?  After all, there are so many things to which I must attend."
			*set discretion %+5
			*set new_orleans_quaestor_rapport %-5
			*set independence %-5
			"I know that such errands are beneath one of your stature, ${mr} ${surname}, but I do feel that this should be attended to by one of our kind, and not left to the wisdom of a mortal."
			
			"You flatter me, Quaestor."
			
			He grits his teeth.  "It is not my intention to do so.  Please, answer my question again.
			*goto reconsider
	#"I really have better things to do."
		*set discretion %+10
		*set new_orleans_quaestor_rapport %-5
		*set independence %-10
		"Are you sure you wish to deny this request of mine?  I do not take kindly to those who refuse my requests, ${mr} ${surname}.
		*label reconsider
		Will you seek out and deal with this invader?"
		*choice
			#"Yes."
				"I am glad to see you reconsider.  I was afraid that you were taking after @{jesse_is_broodmate your elder broodmate|my firstmade} for a moment there."
				
				"I'm sorry?"
				
				"Jesse Whitaker.  A thorn in my side if ever I met one."
				
				"You have @{jesse_is_broodmate another|} progeny?"
				
				"Of course.  Now, go, we will discuss Mr. Whitaker and his indiscretions another time."	 Seeing that you have been dismissed, you take your leave of ${new_orleans_quaestor_surname}.
			#"No."
				*set independence %-20
				*set new_orleans_quaestor_rapport %-15
					
				"I am most disappointed by your decision, ${mr} ${surname}.  Jesse would never have refused me."
				
				"I'm sorry?"
				
				@{jesse_is_broodmate "Your elder broodmate.|"My firstmade.} Jesse Whitaker.  He never would have been so insolent."
				
				"I…"
				
				"No, nothing more.  I will take care of this myself.  Go now."
				
				At that, you excuse yourself.
				*page_break 
				
				Apparently ${new_orleans_quaestor_surname} is efficient in his dealings with the interloper, as you hear nothing more about corpses appearing in the Marigny.  However, it becomes clear that ${new_orleans_quaestor_surname} is displeased with you.  You are, as they say, no longer the apple of his eye.
				*goto introduce_jesse_2

*page_break

The following evening you set out to find this vampire who has ignored the Rule of Respect.  You begin your investigation with the assumption that, since this interloper is being so careless as to leave corpses around one neighborhood, he most likely does not take the time to travel very far from his haven to feed.  Your first destination, then, is the Faubourg Marigny itself.
*set met_lynch true

*if perception > 4
	*set discretion %-5
	Once there, it is easy enough for you to empathically glean from the nigh-palpable fear of the locals that he has been seen nearby.  Choosing carefully who to approach, you settle on an old-timer whose transparent thoughts easily communicate the necessary details.

	Armed with a description of a stout, ginger-headed man, you set out to find this miscreant.
*elseif priest
	Your cassock commands respect whenever you move amongst the mortal population.  By lending an ear to those in need, and waiting patiently for the opportunity to ask a question or two, it is simple enough for you to learn about a stout, ginger-headed fellow that has been seen about the Faubourg as of late.
	
	Armed with his description, you set out to find this miscreant.
*elseif (streetwise > 0) and (speaks_english or speaks_french)
	*set discretion %-5
	Asking around to your contacts among the whores and the players of [i]crapaud,[/i] you learn about a stout, ginger-headed fellow that has been seen about the Faubourg as of late.
	
	Armed with his description, you set out to find this miscreant.
*elseif shapeshifting > 0
	*set discretion %-5
	You decide to use your rudimentary powers of Shapeshifting to ask whatever birds, dogs, cats and horses you can about a stranger to the area that smells of death.  While your furred and feathered friends are quick to recall the fellow, it is difficult to extract any more of a description than the one you have already provided; they are not ones to remember height or hair color.

	However, you are able to identify what you assume to be his regular haunts, based upon the animals that see him most often.  From there, it is a simple matter to make 'friends' with a young bachelor with a balcony that overlooks one of the interloper's most frequented intersections.  Spending the next few nights sipping on the bachelor and watching for this miscreant won't be so bad…
*elseif (charm > 3) and (speaks_english or speaks_french)
	*set discretion %+5
	As with many of the challenges in your existence both mortal and undying, the path before you is eased by the grace and beauty with which you are blessed.  Strangers on the street often fall over themselves with the desire to help you, and this instance is no different; a few conversations later, you have what you need.
	
	Armed with his description, you set out to find this stout, ginger-headed miscreant.
*elseif (charm = 3) and ((male = false) and (speaks_english or speaks_french))
	*set discretion %+5
	As with many of the challenges in your existence both mortal and undying, the path before you is eased by the grace and beauty with which you are blessed.  Strangers on the street often fall over themselves with the desire to help you, and this instance is no different; a few conversations later, you have what you need.
	
	Armed with his description, you set out to find this stout, ginger-headed miscreant.
*else
	Unfortunately, your investigations seem to reveal little to you…but much to your adversary.  It is with some shame, then, that you find a knife in your back, a hand on your mouth and a husky voice whispering in your ear…
	
	@{speaks_english "Who are you, and why're you lookin for me?"|He whispers something coarse in English.}
		
	*page_break
	Do you think you can take him?
	*choice
		#This ruffian needs to know who is in charge here.
			*set lynch_rapport %-10
			*goto combat_check
		*if speaks_english
			#"You have trespassed upon a city under the jurisdiction of a quaestor.  I am seeking to uncover the reason for this breach of the Three Rules."
				*set lynch_rapport %-15
				*set pinned_by_newcomer true
				
				"But…what?  I don know wha you is tawkin about."
				*goto confront_newcomer_1
		*if speaks_english
			#"Do you have any idea who I am?  You had best put that thing away before I am forced to destroy you."
				*set lynch_rapport %-10
				*if (charm >= 3)
					"Forgive me, I didn know who you was."
					*goto confront_newcomer_2
				*else
					*set pinned_by_newcomer true
					"I don' care who you is.  Riht now, yous belongs to me."
					
					"Perhaps you would be so kind as to introduce yourself.  I would like to know who uses me so."
					
					"Mah name is Cecil Lynch.  An' I asked ya wut dya wahnt witd me?"
					*goto confront_newcomer_3
		*if speaks_english
			#"Allow me to welcome you to New-Orleans."
				*set lynch_rapport %+10
				*set pinned_by_newcomer true
				
				He looks about uncomfortably.  "Why is you lookin fo' me?"
				
				"Because you have made a mess of yourself since your arrival."
				
				"A mess?"
				
				"Yes, leaving corpses all over the place."
				
				"Oh…I guess I is sorrys 'bout that."
				*goto confront_newcomer_2
		*if speaks_english = false
			#I try my best to indicate that I mean no harm.
				*set pinned_by_newcomer false
				*set discretion %-10
				
				After some careful exchanges, you persuade the interloper to let you go.  With some more coaxing, you convince him to follow you to the haven of ${new_orleans_quaestor_surname}.
				
				The trip there is somewhat nerve-wracking, but eventually you arrive at the Quaestor's haven.
				*page_break 
				*goto present_newcomer_to_quaestor_no_english

*page_break

It takes several more nights for you to track down your quarry.  Now, however, the interloper stands before you.  He is a man of middling height, barrel-chested and still bearing the vestiges of a ruddy complexion; he was probably a farmer or lumberjack before receiving the gift of immortality. @{(stealth > 0) You have done your best not to be seen, and you think that you have succeeded.|}

How do you approach this miscreant?
*choice
	*selectable_if (stealth > 0) #Ambush him, while I have the element of surprise!
		*set combat +1
		*goto combat_check
	*if (stealth > 0) and (male or ((male = false) and (ethnicity = "german")))
		#Forgo my hiding spot and attack him like a ${man} of honor.
			*set discretion %+10
			*goto combat_check
	*else
		#Attack him.  Force is the only thing these anarchists understand.
			*set independence %+5
			*goto combat_check
	#Address him.
		*set lynch_rapport %+10
		*if speaks_english
			"Good evening, sir. Welcome to New-Orleans," you begin. @{(stealth > 0) He is clearly startled by your sudden presence.|}
			
			He looks at you carefully before responding. "Thank ya.  Issa purdy city."  He seems to realize at this that you too are a vampire, but whether he relaxes or becomes more tense at the realization is not immediately clear.
			*label confront_newcomer_1
			
			"Do you realize what a mess you have been making in the Faubourg Marigny?" you demand.
			
			"Huh?  Whut mess?"
			*if ethnicity = "yankee"
				You try not to sneer at this hillbilly's accent; he is clearly from somewhere in Appalachia.
			*elseif ethnicity = "scotch"
				His accent clearly marks him as having lived in Appalachia.
			
			"Did you think the bodies you were leaving around just disappeared of their own accord?  That the mortals were just ignoring the fact their their sons and daughters were turning up in alleyways, drained of blood?"
			
			"Wha…wha…uh…y${es_suh}?"
			
			"Well, they weren't.  The Quaestor has been cleaning up after you, and he is very angry about it."
			
			"I dinn know."
			*goto confront_newcomer_2
		*else
			The interloper looks at you quizzically when you address him.  He clearly does not speak your tongue.  You try to indicate to him that he should follow you…surely ${new_orleans_quaestor_surname} can translate.  However, he is either incredibly stupid or being intentionally dull.
			*choice
				#Attempt to subdue him.
					*goto combat_check
				#Try to convince him to follow you…back to the haven of the quaestor.
					With some steady coaxing via pantomime, you convince him to follow you to the haven of ${new_orleans_quaestor_surname}.
			
					The trip there is somewhat nerve-wracking, but eventually you arrive at the quaestor's haven.
					*page_break 
					*goto present_newcomer_to_quaestor_no_english
				#Let him go.  ${new_orleans_quaestor_surname} will have to deal with this.
					*set lynch_rapport %+10
					You return to ${new_orleans_quaestor_surname} and report that you were unable to communicate with the fellow.  ${new_orleans_quaestor_surname} is furious.  After he has finished chastising you, he sets out to deal with the interloper himself.
					
					When next you see the quaestor, he is not shy about communicating his disappointment in your capacity to execute his will.
					*goto introduce_jesse_2

*label combat_check
*set compassion %+10
*if combat >= 6
	*set discretion %+10
	*goto newcomer_pinned
*else
	He shouts in alarm and dismay as you pounce upon him.
	*if speaks_english = false
		Though his words were in English, which you do not understand, the intent is clear enough.
	Within moments, though, it becomes clear that this brute of a man is too mighty for you to defeat. Confronted with the possibility of defeat, you feel the growling of the beast, wanting to be unleashed.  If you do, it may mean the difference between success and defeat…but the repercussions could be dire…
	*choice
		#Yes, unleash the beast!
			*set compassion %+10
			*set discretion %+10
			*set combat +(willpower/2)
			*if combat >= 6
				*set combat -(willpower/2)
				*set taste_for_vampire_blood true
				Releasing a guttural howl, you tear into the stranger.  It is exhilerating—your conscious mind contracts to a pinhole as the beast inside you takes charge. The thought of blood coursing down your throat is the only thing that motivates you.
				
				Pinning him against the wall, you sink your fangs into his neck, drinking deeply of his blood.
				*goto drink_from_cecil
			*else
				*set trounced true
				*set combat -(willpower/2)
				Even slavering and howling like a dog, you cannot muster the strength or speed to best this stranger.
				
				He presses your face into the wall of a building, while you hiss and spit in impotent rage.  Once he has had a moment to think, he uses both hands to pull your head back, just far enough to slam it into the wall, with more force this time.  He repeats this until you are unconscious.
				*page_break
				*goto attack_foiled_1
		#No, I cannot give in to my bestial nature!
			*set trounced true
			*set compassion %-10
			*set discretion %-10
			*goto attack_foiled

*label drink_from_cecil
*if willpower = 1
	*set kill_cecil true
	*if norestraint = false
		*set norestraint true
		*achieve norestraint
	*gosub_scene util diablerie
	*set compassion %+10
	*set independence %-5
	Once you have the taste of his blood on your lips, you find that you cannot stop.  The blood of vampires is a heady rush, thick and lush in its flavor…and now that you have tasted it, you find that you cannot stop.
	
	@{cname Cecil|The stranger} wails pitifully as you drain the final drops from his animate corpse.  Even when he has been emptied, you still bite and suck in the hopes of extracting some final sip from his remains.
	
	*page_break
	
	It takes some time for you to regain control of yourself.  
	*if compassion >= 55
		Surveying the scene, you smile at your handiwork.  Of course, you'll have to clean yourself up before you report back to ${new_orleans_quaestor_surname}, but he can wait for tomorrow.
	*else
		When you do, you are horrified by what you see before you.  The alley is splattered with blood, your clothes are ruined, and the corpse of the ginger-headed stranger lies mangled on the ground.
		
		Sick to your stomach, you flee the scene of your crimes, praying all the while that the daylight will cleanse the earth of them.
	*page_break
	*goto introduce_jesse
*else
	For being cold and putrid, the taste of his blood is absolutely delicious.  Except for your maker—and then only when he made you—you have never tasted the blood of another vampire, and you find that you like it.
	
	@{cname Cecil|The stranger} is growing weaker, however.  If you continue to drain him, you will kill him.
	
	*choice
		#Finish him!
			*set independence %-15
			*set compassion %+15
			*set discretion %+5
			*set kill_cecil true
			*if norestraint = false
				*set norestraint true
				*achieve norestraint
			*gosub_scene util diablerie
			Drinking the last of his life-force, you drop his empty corpse to the ground.
			
			You lick your lips, admire your handiwork, and then set out to find a fresh set of clothes.
			*page_break
			*goto introduce_jesse
		#Relent.
			*set independence %+10
			*set compassion %-5
			*set discretion %-5
			You pull back from the edge, forcing yourself to stop before he is expunged.
			
			@{cname Cecil|The stranger} is weakened and submissive.  It takes very little to guide him back to ${new_orleans_quaestor_surname} for his interrogation.
			*page_break
			
			*if speaks_english
				*set before_quaestor true
				${new_orleans_quaestor_surname} looks at you askance when you drag the weakened and terrified individual before him.  He leaves your remonstration for another time, though.
				
				"Identify yourself, stranger."
				
				"Mah name is Cecil Lynch."
				
				"Well, Mr. Lynch, you do understand that you have violated the Rule of Respect, in not coming before me until now?"

				"I dinn mean no disrespect, sir."
				
				"Do you know what the Rule of Respect is?"
				
				"No, sir," Lynch replies weakly.
				
				"Quaestor."
				
				"Kwai-store?"
				
				"You may address me as 'Quaestor,' not 'sir.'"
				
				"Yes, sir…Quaestor."
				
				"Do you know what the Three Rules are?"
				*set cecil_no_rules true
				
				"No, Quaestor."
				
				${new_orleans_quaestor_surname} sighs dramatically.  "And I suppose you don't know what the Society is, either.  What is this world coming to, when domini no longer tend to their offspring?  ${mr} ${surname}, would you be so kind as to enlighten our guest?"
				*goto what_to_tell_cecil
			*else
				*goto present_newcomer_to_quaestor_no_english

*label newcomer_pinned
*set newcomer_pinned true

Moving faster than your adversary can comprehend, you spin around and disarm him.  Looking at you with shock, he fails to respond before you twist his arm behind his back and slam him into a wall.

"I want to ask you some questions.  Do you have a problem with that?"

*if speaks_english	
	"No!  No!  Ima lis'nin!"
	*goto confront_newcomer_2
*else
	He responds to you in English.  Clearly, this will not work.
	*goto present_newcomer_to_quaestor_no_english

*label confront_newcomer_2
*set cname true

"Let me begin by asking your name, stranger."

"Cecil.  Cecil Lynch."

Now that you have his attention…

*label confront_newcomer_3
*choice
	*if (newcomer_pinned) #After making sure no one is watching, I kill him.
		*set compassion %+25
		*set discretion %+25
		*set independence %-20
		*set exposure +1
		*set taste_for_vampire_blood true
		While you were no intructed to do so, you doubt that ${new_orleans_quaestor_surname} will ask many questions about the fate of this interloper.
		
		Baring your fangs, you sink them into his neck and begin tearing chunks of flesh away. He screams and struggles against you. Finally, you pick up a nearby piece of masonry and slam it into the back of his head until it is nothing more than a bloody pulp.
		
		His blood leaks from his body in a black pool. Looking down, you see that you are sprayed with it.
		
		You wipe your lips and, inspired, lick your finger. It tastes…wonderful. Suddenly, you wonder if you missed an opportunity here. Sniffing the pooled blood, you are repulsed. Whatever the appeal, it is not dead blood.
		*label corpse_to_waterfront

		You drag the body to the waterfront and drop it in the water, one more corpse carried away by the river.
		
		You return to the quaestor.
		*set kill_cecil true
		*if norestraint = false
			*set norestraint true
			*achieve norestraint
		*page_break 
		*goto introduce_jesse
	#"It seems to me that you are somewhat ignorant of the customs of our kind, Mr. Lynch.  I think you need some instruction."
		*if newcomer_pinned
			Cecil continues to struggle against your grip. "I nevah was no good at learnin. But it don' seem like I gots anywhere to go at the moment."
			*goto what_to_tell_cecil
		*elseif pinned_by_newcomer
			"Oh? Yous gonna tell me what I need to know?"
			
			"If you will allow me to."
			
			He thinks a minute, still holding you tight. "Wut chyu think I should know?"
			*goto what_to_tell_cecil
		*else
			He looks at you a little askance.  "Wul, I can' says that yous wrong.  Wut chyu think I should know?"
			*goto what_to_tell_cecil
	#"The Quaestor demands that you leave the city."
		*if pinned_by_newcomer
			*goto character_pinned
		*elseif newcomer_pinned
			"You ain' gonna hurt me none?"
			
			"Though you have violated the Rule of Respect by not introducing yourself to the Quaestor, I see no reason at this moment to violate the Rule of Restraint by harming you.  Please do not make me regret that evaluation."
			
			"No…no…I wul go riht now."
			
			*page_break
			*goto introduce_jesse
		*else
			"Wut?  Who is the Kwaister?  And why does I haveta leave New-Orleans?"
			
			"You have violated the Rules of the Society.  And the Quaestor, as administrator of the city, is within his rights to demand your departure."
			
			"The Society?  Wut is that?  An' it has rules?"
			*goto what_to_tell_cecil
	#"The Quaestor commands your presence."  Of course, the Quaestor really wants me to deal with this myself, but no matter.
		*if pinned_by_newcomer
			*goto character_pinned
		*elseif newcomer_pinned
			"I guess I don' have much say in the matter."
			
			"No, you don't."
			*page_break
			*goto lynch_before_quaestor
		*else
			"An wut if I don' wanna come?"
			*choice
				#"Then I will have to kill you."
					"Good luck with that," he retorts.  You lunge at him.
					
					*if combat > 7
						*set taste_for_vampire_blood true
						Though he attempts to dodge your first attack, you are too quick for him.  Within moments, he is subdued, and you are tearing at his throat with your fangs. He is at your mercy, you could easily drag him before ${new_orleans_quaestor_surname} now.  Or you could kill him.
						
						Also, at the back of you mind, you feel this sudden desire to drink more of his blood.  It has a thickness that trumps the watery blood of mortals…
						*choice
							#Kill him.
								*set compassion %+20
								*set discretion %+20
								With a sense of quiet satisfaction, you grind the interloper's face into something resembling a fine powder.
								*goto corpse_to_waterfront
							#Drink from him.
								*goto drink_from_cecil
							#Drag him before the Quaestor.
								*set independence %+10
								*goto lynch_before_quaestor
					*else
						He dodges to his left, leaving his leg behind to trip you.  You sprawl to the ground, and moments later, he is on top of you.  Grabbing your hair, he pounds your head into the ground until you are rendered unconscious.
						*page_break
						When you regain consciousness, dawn is nearing.  You hurry home, making it into your daytime shelter as the rays of the sun are already streaming through your windows.
						*page_break
						*goto introduce_jesse_fail
				*if (charm > 3) #"Oh, but you have no choice in the matter."  Using my powers of Charm, I force him to accompany me to the Quaestor.
					*ending
					*goto lynch_before_quaestor
				#"Then you had best flee, as the Quaestor will be angered that he has to dirty his hands with you himself."
					*if charm > 2
						He seems to give this some thought, before finally nodding.  You escort him back to ${new_orleans_quaestor_surname}'s haven.
						*goto lynch_before_quaestor
					*else
						"You bes' tell him to come 'n git me."
						
						You shake your head sadly before departing.
						*page_break
						*goto introduce_jesse_fail

*label character_pinned
"Those is big words comin' from somebody whos eatin' dirt right now."

"I had no choice in coming here to find you.  Just as you have no choice in leaving the city."

"An wut if I kills you?"

"Then the quaestor will find you and make you suffer.  If he manages to hold his anger in check, he might even summon a Tribunal, to authorize decades of torture before you are finally put to death."

This threat seems to give him pause.  "This kwaister…how come he gets to do these things?"

*label what_to_tell_cecil
*choice
	#I tell him about the Three Rules of the Society.
		*goto explain_three_rules
	#I may be a little less than honest in explaining things to him.
		*goto lies_about_three_rules
	*if before_quaestor = false
		*if speaks_latin or ((ethnicity != "choctaw") and (intelligence > 2))
			#I tell him about our deity, Helios the Sun-King.  Of course, I'm lying through my teeth the whole time.
				*goto helios_story
		*if ethnicity = "choctaw"
			#I tell him about our deity, Hushtahli the Sun-King.  Of course, I'm lying through my teeth the whole time.
				*set helios "Hushtahli"
				*goto helios_story
	*if before_quaestor
		#"Quaestor, I think it simpler for you to explain."
			"Very well.  Mr. Lynch, I am the Quaestor of New-Orleans, appointed by the Governor of this Province, Theresa Overstreet.  As quaestor, it is my responsibility to enforce the Three Rules of the Society.  It is these Three Rules that prevent the sort of carnage that you have been inflicting on my city these past few weeks, and it was the responsibility of your dominus—the one who made you—to instruct you in these matters.  Clearly he has failed in this matter.
			
			"To whit: the Rule of Respect, which demands that you formally petition the quaestor for permission to reside in a city.  As, ultimately, your conduct is his to police.  The Rule of Restraint, which demands that you refrain from killing others of our kind.  And, most importantly, the Rule of Reserve, which demands circumspection in your activities, so that the mortal remain ignorant of us.
			
			"While on this matter, who is your dominus, Mr. Lynch?"
			
			"Dominoe, sir?"
			
			"The one who made you what you are."
			
			"Uh, that'd be Sir Robert, I s'pose."
			*set knows_lynch_sire true
			*set heard_of_gruffyd true
			
			"I am unfamiliar with Sir Robert.  I will write to Governor Overstreet to inquire about him and suggest a suitable punishment for releasing one so woefully uneducated.  That aside, I will conclude by noting that there are subtleties and exceptions to the Three Rules.  One of those is that, as Quaestor, I have the authority to terminate the existence of those vampires who violate these rules.  Due to your youth and ignorance, I will simply exile you from my city.  Your crime is more the fault of this Sir Robert.  But do not confuse mercy with weakness.
			
			"Leave now.  Do not return, or I shall put an end to you myself."
			
			You escort Cecil from the quaestor's presence.
			*page_break 
			*goto introduce_jesse_0

*label explain_three_rules
*set lynch_rapport %+40

"The Quaestor of New-Orleans enforces the Three Rules of the Society.  The Rules are what allow us to continue to exist in a civilized manner through the centuries.  The first rule, the Rule of Respect, demands that you seek permission from the quaestor of a city before setting up a haven therein.  Something you have clearly failed to do.  The Rule of Restraint demands that vampires not kill one another.  And most importantly, the Rule of Reserve demands that we keep our activities circumspect, lest we reveal our existence to the mortals.

"There are, of course, subtleties and exceptions to these rules.  Such as, if you violate them, a quaestor would be free to put an end to your existence.  But my Quaestor has offered you the option of exile instead."

"Ecks-isle?  Is that a place 'round here?"

"No.  It means leave now and do not return, or you will be destroyed."

He looks surprised by this, but takes a moment to consider.  Finally, showing more intelligence than you had given him credit for, he nods his assent.  "I will go."

"Then go."

*if before_quaestor
	He bows before ${new_orleans_quaestor_surname} before heading to the door.  Ajax seems him out.
	
	"That was succinctly put, ${mr} ${surname}."
	
	"Thank you, ${new_orleans_quaestor_address}."
	
	"Now if you will excuse me, the sun will be up soon," he says, taking his leave of you.
	
	*page_break 
	*goto introduce_jesse_0
*else
	You watch him disappear into the night.
	*page_break 
	*goto introduce_jesse

*label helios_story

"The Quaestor is the priest of ${helios} the Sun-King, it is he who guides us on to righteousness.  We, as members of the Society, are brothers in the worship of this god."

"The Kwaister?  Sun-King?"  Cecil looks very confused.

"Yes, there are three rules that we must obey: the Rules of Respect, Restraint, and Reserve.  The Rule of Respect expresses our duty to honor and worship ${helios}."

*if priest
	"So yous ain't a Papist?"
	
	"No, I am a priest of the sun-god.  This cassock is an expression of our duty collective duty to the sun-god."
	
"Our duty to the sun-god?  I thought the sun wuz a problem fo' us."

"If you honor the Three Rules, you will be invincible.  The sun itself will bow to your commands, and you will have no need to fear him.  The sun harms you because you have failed to honor him.  But that is because you have not heeded the Rule of Restraint, and listened to the words of the Quaestors."

"The Kwaisters…them is preachers?"

"You could think of them like that, yes."

"Wul…how d'ya like that?"

"And the Rule of Reserve explains how we must offer the Sun-King our tributes of blood."

"Try-bute of blood?"

"Yes…that is how we earn his blessings."

"Is that whuy iss so hard to get folks to let me feeds offa them?"

"It very well could be, Mr. Lynch."
*goto helios_story_resolve

*label lies_about_three_rules

"Your dominus, the one who made you, should have taught you about the Society."

The Society is the organization of vampires that enforces the Three Rules.  But what do you tell him that it is?
*choice
	#"The Quaestor is an administrator for the Society, the term for the agreement between vampires and mortals, which dictates the conditions under which we can cull the flock."
		*set lies +1
		*set independence %-5
		"They knows about us?"

		"Yes, and we live in peace, except when someone does something like what you are doing."

		"I…I dinn know!" he wails in anguish.  "Wut else do I need to know about this kwaister!"
	#"The Quaestor is an administrator for the Society, the organization of vampires that keeps the laws and customs of our kind as described by the Three Rules, and protects us from the mortals through the ages."
		*set independence %+5
		*set lynch_rapport %+10
		"There is mo' of us?"

		"Hundreds.  Maybe even thousands.  And you've been drawing attention to our activities!"

		"I…I dinn know!" he wails in anguish.  "Wut else do I need to know about this Kwaister!"
	*if sirethoughthewasagod
		#"The Quaestor is the leader of the Society, the cult of vampires that worship my maker, ${sire_name}.  ${sire_name} is a great and powerful vampire, godlike in his powers."
			Cecil's eyes widen in fear.  "He…he idn't nearby, is he?"
	
			"He is, and he's watching us right now."

			Looking around, he announces to the darkness, "I dinn mean no harm mista' vampire god!  No sir! No harm!  Tell me what I needs ta know about him!"
			*set lies +1	
			
*label lies_about_three_rules_1

The Quaestor is the administrator of a city charged with the enforcement of the Three Rules of the Society.

*choice
	#"The Quaestor is the vampire that rules the city with an iron fist, meting out death and dismemberment to any who dare oppose him."
		*set lies +1
		@{before_quaestor You sense that ${new_orleans_quaestor_surname} is smiling at your explanation of his role.|} "No, I ain' nevah heard a no Kwaister b'fore," Cecil exclaims.
		
		*if cecil_no_rules = false
			"Or the Three Rules?"
			
			"Or the Three Rules."
	#"The Quaestor is the appointee of the Governor, designated to enforce the Three Rules in the Governor's name."
		*set lynch_rapport %+5
		*set heard_of_governor true
		"I ain't heard a no kwaister b'fore.  Nor a guv'nor."
		
		*if cecil_no_rules = false
			"Or the Three Rules?"
			
			"Or the Three Rules."
	*if sirethoughthewasagod
		#"That is the name given to the servants of the vampire-god, my dominus."
			*set lies +1
			"I wunder why Sir Robert nevah tole me nun o this."
			*set knows_lynch_sire true
			*set heard_of_gruffyd true
			
			*if cecil_no_rules = false
				"I suppose he also didn't tell you about the Three Rules?"
				
				"Three Rules?"
	*if speaks_latin
		*if before_quaestor = false
			#"The Quaestor distributes the blood-rations to the vampires of the city."
				"Blood rations?"
				
				"Yes.  If you were a recognized member of the Society, you would be entitled to them."
				
				"You mean, sos I don' have to go huntin'?"
				
				"Exactly."
				
				"Tell me mo' bout these rules."
				*set lies +1
				*goto lies_about_three_rules_1

The Rule of Respect demands that vampires heed the commands of quaestors, and seek permission to reside in cities administered by one.

*choice
	#"The Rule of Respect demands our submission to the governor, and thus to her quaestors.  And if you are living in her Province, then you must render honor unto her quaestors."
		*set independence %+5
		*set lynch_rapport %+5

		"Wut are you sayin?"

		"I'm saying that if you want to live here, you need to seek the quaestor's permission to do so.  And since you have not done that, you are not welcome to stay."

		"This place is worse 'n home."
	#"The Rule of Respect describes the way in which you may go about selecting your prey from among the mortals, per our agreements with them. After all, there are very specific guidelines for how you may go about feeding."
		*set lies +1
		*set compassion %+5
		
		"I…I had no idear."
	*if heard_of_governor
		#"The Rule of Respect outlines the titles we use to address our superiors in the Society."
			*set lies +1
			*set compassion %+5
			
			"You mean like kwaister and guv'ner?
			
			"Yes, like that."
			
			"Are there others I shoulds know about?"
			
			"Well, yes, but they are less important right now."
			
			"I reckon I'll have ta take yur word for it."
	*if speaks_latin
		*if before_quaestor = false
			#"The Rule of Respect defines the order in which we receive our blood-rations from the quaestor.  The elder vampires receive their ration first, for example."
				
				"Do we gots ta get in a line or sumthin?"
				
				"Not formally, no.  But you must wait your turn, yes.
			
				"I guess I'd be one of the last to get mine, then."
				
				"Yes, but in time you would rise to prominence."
				
				"Huh.  What else does this kwaister do?"
				*set lies +1

The Rule of Restraint demands that vampires not kill one another.

*choice
	#"The Rule of Restraint demands that we conduct ourselves with dignity and decorum when in the presence of others of our kind."
		*set lies +1
		*set lynch_rapport %+5
		*set compassion %+5
		*if pinned_by_newcomer
			"I reckon this don' exacktly count for bein' dignified, now do it?"

			"You mean, with my face pressed up against this wall?  No, it doesn't."

			"Mebbe I shouldnt be doin' it then?"
		*elseif newcomer_pinned
			"This don' seem like iss too dignified, if you wuz gonna ask me."

			"You have not currently earned the reciprocation of that dignity," you note as you twist his arm a little tighter.

			"Owww!" he howls.
		*else
			"You mean like the way we talks to each others?"

			"You could express it that way, if you wanted to.  It really describes the social dance of the Society."
	#"The Rule of Restraint demands that we not assault or kill others of our kind."
		*set independence %+5
		*set lynch_rapport %+5
		*if pinned_by_newcomer
			"Are you sayin' Ima in trouble for gettin the drop on you?"

			"Well, if you let me go, perhaps we can overlook things."
			
			"Wul, I guess I'll do that then," he says, releasing you.
			*set pinned_by_newcomer false
		*elseif newcomer_pinned
			"So why you got me up 'gainst the wall like this?"

			"As the representative of the Quaestor, I am allowed to bend the rules."
			
			"I s'ppose you ain't in trouble for hurtin' me like this then.

			"No.  In fact, I will probably be commended."
		*else
			"So you're not gonna do anythin' to hurt me?"

			"As long as you obey the Three Rules, which at this point means doing what I say, I see no reason to."  Your interlocutor seems to take this recommendation under consideration.
	#"The Rule of Restraint specifies when and how we feed from the mortals."
		*set lies +1
		*set lynch_rapport %+5
		*set compassion %+5
		"There is rules about that?"
		
		"Yes, Mr. Lynch, there are."
		
		"My…domino?…dinn' tell me none of this."
	*if speaks_latin and (before_quaestor = false)
		#"The Rule of Restraint is what demands our submission to the order of Respect.  Tempted as we may be to do otherwise, we must learn to control our urges, and obey our elders and the quaestor."
		
			"Sos, like, it means no jumpin in line."
			
			"You could put it like that, yes."
			
			"I hate them folks that jumps in line."
			*set lies +1
	*if (newcomer_pinned) #"The Rule of Restraint is the one I'm going to break right now…" you say, sinking your teeth into his neck.
		*goto drink_from_cecil

The Rule of Reserve demands that vampires be circumspect in their actions, lest the mortals discover their existence.

*choice
	#"The Rule of Reserve outlines the manner in which we can establish a herd of mortals to service our needs."
		*set lies +1
		*set compassion %+5
		"A herd?"

		"Or flock.  I've even heard of 'coop'.  As you will.  The group of mortals that offers up their life and goods for our pleasure."

		"They do that for us?"

		"If you go about it in the right way, yes."
		
		"Wul…who'da thunk it?"
	#"The Rule of Reserve demands that we remain hidden from the mortals, lest they organize to destroy us."
		*set independence %+5
		*set lynch_rapport %+5
		"Is that why yo' Kwaister is so upset about the bodies?"

		"Yes, exactly."

		"I s'ppose I should 'pologize about that."
	#"The Rule of Reserve is the way in which we manage the flow of blood within our bodies, to create a sympathy between ourselves and the world around us."
		*set lies +1
		*set compassion %+5
		"I thought a sinphony had som'thin ta do wid music."
		
		"Yes, yes…exactly!  You must learn to guide the music in your blood to harness its full potential."
		
		"There's so much I dinn' know! I can' thank yous enuf!"

"Now, child, the Quaestor is displeased with your ignorance. @{before_quaestor Look, do you see the scowl upon his face? How long must he tolerate this affront?|He has sent me to command you to leave the city. Will you obey his command?}"

*if before_quaestor
	"He don' look to happy, no," Cecil replies, looking back and forth between ${new_orleans_quaestor_surname} and you.
	
	"What, then will you do about it, Mr. Lynch?"
	
	"…Leave?" he offers.
*else
	"I wull obeys."

"Good.  Now go forth and make your way in the world, free from the ignorance which so recently held you captive."

*if before_quaestor
	He bows before ${new_orleans_quaestor_surname} before heading to the door.  Ajax sees Cecil out.
	
	*if lies = 0
		"That was succinctly put, ${mr} ${surname}."
	
		"Thank you, ${new_orleans_quaestor_address}."
		
		"Now if you will excuse me, the sun will be up soon," he says, taking his leave of you.
	*else
		"You have an interesting way of 'educating' the young, ${mr} ${surname}."
		
		*choice
			#"I was simply accentuating his maker's failure."
				"Well, you have certainly done that, ${mr} ${surname}.  Sir Robert, if he is still alive, will undoubtedly be mortified by his offspring's misconceptions."
				*set knows_lynch_sire true
				*set heard_of_gruffyd true
				
				"Have you met Sir Robert?"
				
				"I believe we did cross paths once, yes.  But it was some time ago.  Now if you will excuse me, the sun will be up soon," he says, taking his leave of you.
			#"I thought you would be amused!"
				${new_orleans_quaestor_surname} rolls his eyes at you.  "So I am, ${mr} ${surname}.  However, should Mr. Lynch cause some grevious harm to the Society, it will be on your head, not mine."
				
				"I understand, ${new_orleans_quaestor_address}."
				
				"Now if you will excuse me, the sun will be up soon," he says, taking his leave of you.
			#"You mean, I was wrong?"
				${new_orleans_quaestor_surname} rolls his eyes at you.  "Clearly, I have failed in my efforts at educating you."
				
				"Clearly, ${new_orleans_quaestor_address}."
				
				${new_orleans_quaestor_surname} grows serious.  "If Mr. Lynch commits some horrible atrocity against the Society because of the lies you have told him, it will be on your shoulders, not mine."
				
				"I understand, ${new_orleans_quaestor_address}."
				
				"Now if you will excuse me, the sun will be up soon," he says, taking his leave of you.
	*page_break
	*goto introduce_jesse_0
*else
	You watch as Cecil disappears into the night.
	*page_break 
	*goto introduce_jesse

*label helios_story_resolve
*achieve liar
*choice
	#Send him forth.
		*set helios_plot true
		"Go, now, and take part in the world and in the Society as I have instructed you."
		
		"Yes.  Yes I will."  You watch as the thoroughly confused Cecil disappears into the night.
		*page_break 
		*goto introduce_jesse
	#Invite him to greet the sun.
		*if (charm > 2) and (willpower > 2)
			*goto death_by_helios
		*else
			*set helios_plot true
			"I don' know about.  I s'pose I'll think on wut you been tellin' me a bit, an' mebbe I'll try that in a few days.  For now, though, I'll leave you be.  I is sorry about all the bodies."
			
			"I forgive you.  Some day you will come to see the light, my brother."  You watch as the thoroughly confused Cecil disappears into the night.
			*page_break
			*goto introduce_jesse

*label lynch_before_quaestor
*set new_orleans_quaestor_rapport %-5
*set before_quaestor true

${new_orleans_quaestor_surname}'s displeasure is evident to you, but Cecil probably does not notice; later, you will surely be chastised for not dealing with this yourself.

"Mr. Lynch, you do understand that you have violated the Rule of Respect, in not coming before me until now?"

"I dinn mean no disrespect, sir, but these Rules that ${mr} ${surname} wuz talkin' about?  I nevah heard of 'em."

${new_orleans_quaestor_surname} sighs dramatically.  "What is this world coming to, when domini no longer tend to their offspring?  ${mr} ${surname}, would you be so kind as to enlighten our guest?"
*goto what_to_tell_cecil

*label death_by_helios
*set compassion %+20
*set death_by_helios true
*set kill_cecil true
*if norestraint = false
	*set norestraint true
	*achieve norestraint
*set lies 0

Cecil looks a little nervous at this suggestion, but when you begin to dress his face with your own blood in some sort of mock-initiation ceremony, he slowly warms to the idea.

"Well, I reckon yous a riht kind fella, fillin me in on all this learnin I missed."

"Be quiet child, I must not be interrupted," you chide him.  You continue with the preparations.
*page_break
From a safe vantage point, you watch as he does his best to withstand the searing kiss of the sun.  By the time he realizes that he has been deceived, it is too late.  Mr. Cecil Lynch will see the moon rise no more.
*goto introduce_jesse

*label attack_foiled

Your attempts to best your adversary fail miserably.  You are rewarded with a knife through the lungs for your trouble, temporarily interfering with your ability to speak very loudly.  Your knees buckle, and you fall to the ground.  From behind, your opponent grabs you by your hair and slams your head into a wall.  The first time does not render you senseless, but he does not hesitate to do it again and again until you lose your grip on the world.

*page_break
*label attack_foiled_1

When you regain consciousness, dawn is nearing.  You hurry home, making it into your daytime shelter as the rays of the sun are already streaming through your windows.

*page_break
*label introduce_jesse_fail

Apparently, while you are nursing your wounded pride the next evening, ${new_orleans_quaestor_surname} has an encounter of his own with the interloper, and deals with the fellow himself.  When next you see the quaestor, he is clearly disappointed with your ability to execute his will.
*goto introduce_jesse_2

*label present_newcomer_to_quaestor_no_english
*set new_orleans_quaestor_rapport %+5

${new_orleans_quaestor_surname} seems amused at the linguistic barrier separating you and your prisoner.  He proceeds to interrogate the prisoner—whose name turns out to be Cecil Lynch—and pronounces the young vampire exiled from New-Orleans at the conclusion of the interview. @{taste_for_vampire_blood Once Lynch is gone, ${new_orleans_quaestor_surname} politely suggests that you learn to better control yourself—letting the beast loose like that can have unfortunate consequences.|}

*if jesse_is_broodmate and (sires_faith = "faithful")
	${new_orleans_quaestor_surname} explains once Lynch has left: "I could not bring myself to kill one of our kind simply for his ignorance.  Without a clear imperative, I wish to cause no further affronts to God than absolutely necessary."
	*if trounced and (discretion < 50)
		*set new_orleans_quaestor_rapport %-5
		*set trounced false
		
		"But he nearly killed me!" you whinge.
		
		${new_orleans_quaestor_surname} looks at you scornfully.  "Just because you are a vampire does not make you all-powerful.  You will come to learn that, should you seek to resolve your obstacles with tooth and claw, it would be best to sharpen both.  Elsewise, learn to deal with those same obstacles more subtly."
*else
	"If you see him again inside the city, ${mr} ${surname}, I grant you leave to end his miserable existence.  The poor thing was abandoned by his maker…I probably should have just put an end to him myself, but, well…"
	*if trounced and (discretion < 50)
		*set trounced false
		*set new_orleans_quaestor_rapport %-5
		
		"But he nearly killed me!" you whinge.

		${new_orleans_quaestor_surname} looks at you scornfully.  "Just because you are a vampire does not make you all-powerful.  You will come to learn that, should you seek to resolve your obstacles with tooth and claw, it would be best to sharpen both.  Now, surely you are clever enough to solve this problem without my further involvement."
	
		"Yes, Questor," you reply, chastised.
	*if (lore > 1) and (intelligence > 1)
		Closing the door behind you, you consider the questor's commands.  Put more clearly, since he is not yet officially quaestor, he does not officially have the authority to execute Mr. Lynch.  Which makes you wonder: were you see Mr. Lynch again, would you be in the right to end him?  And what would befall you were you to fail?
	*else
		He lets the thought trail off, and then quickly changes the topic to the need for you to broaden your linguistic horizons.
*page_break
*goto introduce_jesse_1

*label introduce_jesse
*set new_orleans_quaestor_rapport %+5
*if before_quaestor
	${new_orleans_quaestor_surname} seems satisfied with your handling of the interloper.  Satisfied enough, anyway, to send you on your way with no further orders.
	*page_break
	*goto introduce_jesse_0
You return to ${new_orleans_quaestor_surname} to inform him that the interloper has been dealt with.  He thanks you for the service that you have rendered to him.
*if kill_cecil
	*if taste_for_vampire_blood = false
		That said, you decide it best to leave out how exactly you dealt with Mr. Lynch.  After all, it's not like you killed him yourself.…
		*goto introduce_jesse_0
	*else
		You notice him staring a bit queerly at you, and you wonder whether he can somehow sense the blood of another on your fangs.
		
		*choice
			*selectable_if (compassion < 70) #I break down in tear, and confess my horror at my crimes.
				*set compassion %-10
				*set independence %+15
				*set new_orleans_quaestor_rapport %-5
				"${new_orleans_quaestor_given_name}, forgive me, for I have taken the existence of another."
				
				"Pardon me?"
				
				"The stranger…we came to blows, and I lost control of myself…he is no more."
				
				"How many times do I nave to tell you, you are to address me as ${new_orleans_quaestor_address}."
				
				You are a little surprised by his priorities at this moment.  "Of…of course…forgive me, ${new_orleans_quaestor_address}.  As you can see, I am very distraught…"
				
				"Yes, yes, and you killed one of our kind.  It happens, especially with regards to the young and ill-informed.  Now do you see why I have taken such pains to educate you?  This stranger violated the Rule of Respect, and he attacked you when you approached him.  You are young, and you overreacted.  You will most likely be shriven of this sin should it ever be brought before the Governor, so do your best to put it out of your mind."
				
				"Yes, ${new_orleans_quaestor_address}."
				
				"Good, now go."
				*page_break
				*goto introduce_jesse_2
			*selectable_if (discretion > 30) #I boast of my deeds to the Quaestor.
				*set discretion %+10
				*set independence %-5
				*set compassion %+5
				*set new_orleans_quaestor_rapport %-10
				"I put an end to that vampire.  He was being insolent."
				
				"You killed him?"
				
				"Yes."
				
				"No, you didn't."
				
				"I'm sorry?"
				
				"You did not kill him.  You escorted him to the edge of the city, and sent him on his way."
				
				"I did?"
				
				"Yes.  And we will never speak of this again, you fool.  If it became known that I permitted you to slay one of our kind so recklessly, we would both be put to death.  Though I appreciate the enthusiasm with which you prosecute my orders, your methods need review.  Do I make myself clear?"
				
				"Yes, ${new_orleans_quaestor_address}."
				*page_break
				*goto introduce_jesse_2
			#I say nothing.
				*set discretion %-10
				*set independence %-5
				${new_orleans_quaestor_surname} continues to peer at you for another moment before he turns the conversation to other matters.
				*goto introduce_jesse_2
*elseif trounced and (discretion < 60)
	Once he has thanked you, however, you do your best to bring up the trouble you had attempting to subdue the interloper.  The quaestor senses how you are stumbling over your words, and asks you to speak more directly.  Once you have explained yourself, he makes this reply: "Just because you are now a vampire, it does not make you undefeatable.  If you seek to resolve your conflicts with tooth and claw, you had best sharpen both.  Elsewise, you should seek other solutions."

	Chastised, you take your leave of him.
	*page_break
	*goto introduce_jesse_2

*label introduce_jesse_0
*if kill_cecil
	*goto introduce_jesse_2
*elseif (lies = 0) and ((helios_plot = false) and (lore < 3))
	*set lore +1

*label introduce_jesse_1
*if lies >= 4
	That misfortunate fellow will probably spend years trying to distinguish the truth from the lies that you told him.  If they don't get him killed first.
*elseif lies > 0
	It could be decades before that poor vampire figures out that you misled him.

*label introduce_jesse_2
*if (priest = false) and (background > 2)
	*if (ethnicity = "french") or ((ethnicity = "southern") or (male and (ethnicity = "african")))
		*page_break
		As the nights pass with increasing rapidity, you do what you can to find entertainment. As was your custom before, you often find yourself at the salons and [i]soirées[/i] of the New-Orleans elite.
		
		Unfortunately, the young and impetuous members of this elite are just that: young and impetuous. This impetuousness results in a penchant for dueling.
		
		In City Park, there are a series of liveoaks known as the Dueling Oaks, where duelists go to resolve their differences. Some duels are with swords, others with pistols; some are to first blood, others are to the death. On Saturdays in particular, there can be as many as a dozen duels in a single day.
		
		*if male
			Just the other evening, you were enjoying a rousing and flirtatious conversation when a young scion of the Claiborne family took offense at your jibe. 
			*if (compassion > 50) and (discretion > 50)
				(You had previously noted his awkwardness around the opposite sex, and when his dance card ended up embarrassingly empty, you took the opportunity to point it out to your clique.)
			He challenged you to a duel, and in a fit of pique, you accepted.
			
			Now, here you are. The sun has set, and the young Claiborne is testing the heft of his blade. Several slaves hold torches aloft to illuminate the night. The young man has quite the reputation as a fencer—you've checked.
			
		*else
			Just the other evening, you were enjoying a rousing and flirtatious conversation when a young scion of the Claiborne family asked you to dance. You rejected him—you found him awkward and generally beneath your notice—and he took offense.
			
			To everyone's surprise, the young man's sister challenged you to a duel. Duels between women are rather rare, but not entirely unheard of. Perhaps foolishly, perhaps out of sheer surprise, you accepted.
			
			Now, here you are. The sun has set, and the young Claiborne is testing the heft of her blade. Several slaves hold torches aloft to illuminate the night. The young woman has quite the reputation as a fencer—you've checked.
			
		You're still in the shadows, observing. @{(fighting > 0) This contest will be decided on grace and skill; you know enough of swordplay to know that brute strength will not serve you here.|} You ponder what to do.

		*temp wager false
		*temp wager_value 0
		*label after_wager
		*choice
			*if (wealth > 20000) #First, I place a wager on myself.
				*set wager true
				How much would you like to bet?

				*fake_choice
					#$250.
						*set wealth -5500
						*set wager_value 5500
					*selectable_if (wealth > 40000) #$500.
						*set wealth -11000
						*set wager_value 11000
					*selectable_if (wealth > 80000) #$1000.
						*set wealth -22000
						*set wager_value 22000

				The bookmaker takes your bet. @{male |He's seen very few women's duels, and he leers at you uncomfortably.} He wishes you luck.
				*goto after_wager
			*if (wager = false) #The risks are too great. I simply walk away.
				*set nola_duel_status 2
				*set discretion %-10
				*set independence %+10
				*set local_fame %+5
				For failing to appear at a duel, your reputation and honor is forever tarnished. In the aftermath, you find it very difficult to impossible to gain entry to the salons and [i]soirées[/i] to which you were previously accustomed.
				
				On the other hand, you upheld the Three Rules, and the young Claiborne will continue to enjoy the pleasures of breathing…at least until @{male his|her} next duel.
			#A fair fight to first blood.
				*set combat (agility + (fighting * 1.5))
				*if combat >= 5
					*set local_fame %+5
					*set nola_duel_status 4
					When you draw your blade across ${his} upper arm, the blood wells up instantly. The duel is called in your favor. To most everyone's surprise, you have bested the young @{male |wo}man at ${his} own game. $!{he} was as talented as they said, but you happen to have been the more skilled fencer.
					
					@{male He storms away, furious that his winning streak has been ended.|She accepts the defeat graciously, satisfied that the family's honor has been defended.}
				*else
					*set nola_duel_status 3
					Alas, @{male he|she} is as good as they say. After a few minutes of sparring, @{male his|her} blade draws a line on your cheek. The duel is called in @{male his|her} favor, and you do your best to disguise the fact that no blood flows from the wound.
					
					Matters of honor satisfied, you hasten away before you endanger the existence of your kind.
				
				You are welcomed graciously in the following months and years, as someone who understands and accepts the rules of this society.
			#Knowing that my wounds will heal, I use that to simply kill ${him}.
				*set independence %-10
				*set discretion %+10
				*set compassion %+5
				*set combat (agility + (fighting * 1.5))
				*set nola_duel_status 5
				*if combat >= 5
					It's actually easier than you anticipated; you are, in fact, the better swords@{male |wo}man. Within a few moments, you pierce @{male his|her} heart with your blade.
					
					@{male He|She} sputters blood and dies in the arms of @{male his elder brother|her brother}.
				*else
					*set exposure +2
					@{male His|Her} foil pierces your flesh multiple times. It hurts, but you do your best to push away the pain and charge. You hack at the youth until @{male his|her} face is almost unrecognizable and the onlookers are screaming for the matter to end.
					
				A hush falls over the crowd. You wipe your blade clean and excuse yourself.
				
				In subsequent nights, you are given a wide berth at the salons and [i]soirées[/i] that you attend, except among those attracted to your disproportionate use of violence.

		*if wager and (nola_duel_status > 3)
			*if male
				*set wager_value * 3
			*else
				*set wager_value * 2
			*set wealth +wager_value
			The bookmaker @{(nola_duel_status = 5) carefully|reluctantly} pays out your winnings. @{male It turns out that the odds were three to two, due to your opponent's reputation as a duelist.|} You hurry home before anyone grows concerned with the disposition of your purse.
		*page_break

Unfortunately, any effort to keep the vampiric population of New-Orleans down to two is doomed to failure.  Like moths to a flame, the burgeoning multitudes of New-Orleans beckon to vampires near and far.  Yet, the arrival of the next of these comes as a shock to both you and ${new_orleans_quaestor_surname}.

In retrospect, you realize that you shouldn't have been so surprised when you are informed that the prodigal son has returned and will be petitioning his maker for succor.  After all, since the subject was finally broached, ${new_orleans_quaestor_surname} has been unable to stop talking about his errant firstmade.
*finish Next