*comment ñáéç…—
*set year 1889
*hide_reuse
*advertisement
*temp num 1
*rand num 1 2
*temp suffocation (num = 1)
*temp involved_baseball false
*set wealth +(income * 2500)
*temp west_prob (m_sib and patricide)
*temp imposter "the imposter"
*if west_prob and stl_heard_of_wotton
	*set imposter "Wotton"
*if baseball_failed = false
	*if (sporting_goods = 4) or (sporting_goods = 3)
		*set involved_baseball true
		In the intervening years, you have seen a steady income from ${spalding_sporting_goods}. This new sport has found some widespread appeal throughout the country.
	*if (sporting_goods = 2)
		*set involved_baseball true
		In the intervening years, you have seen a steady stream of payments from Von der Ahe. It seems his ${spalding_sporting_goods} stores are at least moderately successful.
	*if (sporting_goods = 1)
		In the intervening years, baseball has exploded in popularity across the country, and in St. Louis in particular.
	The fact that Charles Comiskey has guided the Browns to four pennants in a row has helped fuel this mania.
	
	And with all those games on hot summer days comes the drinking of beer. Lots of beer.
	*if browns_sundays_moved
		Unfortunately, those opportunities have been somewhat curtailed by the prohibition of playing on Sundays.
		
	*if (speaks_english and literate) and (intelligence > 1)
		About this time, you observe that the New-York Times has changed the way they write base ball, now preferring "baseball." (This was, notably, after an earlier change from base-ball in the 1840s.)
		
		The very idea of standardized spelling has only recently come into vogue. Various philological societies have come into being in the past ten years, and they have promulgated the idea of spelling rules in order to facilitate communication.
		*choice
			#Standardized spelling is the way of the future. It will make the populations of the United States into one nation.
				*set anachronism %+5
				*set laborvscapital %-5
				*set justice %+10
				The newspapers of St. Louis—the ${post_dispatch} chief among them—soon adopt these spelling rules. From the newspapers, the standardizations begin spreading out into other fields. Soon, there will be a clearly right way to spell every word in the lexicon.
			#The loss of regional and dialectical spellings will coincide with a loss of culture.
				*set justice %-5
				*set compassion %-5
				Something is lost when everyone or everything is the same everywhere. Having lived through the past few decades, you can already see how the Irish, Germans, and French have begun to assimilate into the Anglo-American culture of New-York, Philadelphia, and Baltimore. @{((ethnicity = "choctaw") or (justice < 35)) To say nothing of the eradication of the Cherokee, Creek, Iroquois, Powhatan, or any of the other Native languages.|}
			*if (ethnicity = "german") #Thankfully, the Germans have their own newspapers. We are not bound by the American Philological Society's rules.
				*set discretion %+5
				*set justice %+5
				It is true: the German newspapers are free to pursue their own route.
			*if (stlouis_enterprise = 1) #I urge the newspapers of St. Louis to resist this linguistic imperialism!
				*set stlouis_business_climate %-5
				*set justice %-5
				The local newspapers largely hew to your wishes. This makes commerce between St. Louis and the rest of the country somewhat more difficult, as misunderstandings occur and differences are emphasized. However, the locals take a visceral enjoyment in being different from the rest of the country.
	*page_break
*temp disruption "none"

*if (finance > 0) or ((local_fame > 45) or (ethnicity = "german"))
	*set heard_of_ellis_wainwright true
	Adolphus Busch Sr., the Griesedieck brothers, William and Billy Lemp, Jospeh Schnaider @{schnaiders_closed [i]fils[/i]—looking glum since the closing of the family biergarten,|[i]fils,[/i]} and a score of other local brewers have gathered to discuss the future of the beer industry in St. Louis. They sit around the massive dining room table in Ellis Wainwright's Lafayette Square mansion, with a handful of the least important ones consigned to chairs along the wall.
	*if (male = false) and ((ethnicity != "african") and (ethnicity != "choctaw"))
		*set disruption "small"
		When the meeting is brought to order, one man, Fletcher, stands to protest your presence—the only woman in attendance—but Schnaider assures them that your presence is warranted.
	*if male and ((ethnicity = "african") or (ethnicity = "choctaw"))
		*set disruption "large"
		When the meeting is brought to order, one man, Fletcher, stands to protest your presence—the only colored person in attendance—but Schnaider assures them that your presence is warranted.
	*if (male = false) and ((ethnicity = "african") or (ethnicity = "choctaw"))
		*set disruption "large"
		When the meeting is brought to order, one man, Fletcher, stands to protest your presence—the only woman or colored person in attendance—but Schnaider assures them that your presence is warranted.
	*if (disruption != "none") and (charm > 3)
		Your supernatural charm gives further weight to Schaider's words, and Fletcher sinks into his chair, suitably chagrinned.
	*if (disruption != "none") and (charm <= 3)
		All the same, 
		*if (local_fame > 65)
			your well-known presence in the affairs of St. Louis soon quiets Fletcher's outburst.
		*else
			Fletcher and @{(disruption = "small") a few|several} of the other men depart in anger.
		
		Wainwright raps the meeting back to order.
	In the corner, a young man—Billy Reedy—takes notes at Wainwright's behest. Peter Busch, one of Adolphus's youngers sons, fetches refreshments as needed for the men.
	*set stl_met_pbusch 2
	
	After what seems like an interminably long series of introductions, benedictions, and disquisitions on the state of business in the city, state, and country, the host finally turns to the matter at hand: forming a brewers' syndicate. "Why do we compete with one another? Let us merge our efforts and reap the benefits. Buck Duke has dominated the pre-rolled tobacco market from North Carolina; why can we not do the same for bottled beer?"
	
	William Lemp stands to speak. "And by merging our efforts, you mean to compensate us?"
	
	"I do."
	
	"And where will you find the money for this? It is my understanding that you are…extended…at the moment."
	
	"I represent a group of investors—"
	
	"English investors, I'm given to understand?" Lemp interrupts.
	
	"Yes, they are from London. I have made them see the opportunity that is here…the opportunity for all of us."
	
	The room breaks out into pandemonium. There is no small amount of animosity between the attendees; an appeal to cooperation and collaboration provokes kneejerk objections. The fact that the money originates in London does not help the matter.
	
	"What about Von der Ahe? Why is he not here?" one of the Griesedieck brothers inquires.
	
	"[i]Ja,[/i] perhaps he could fund this merger, instead of the English," the other concurs.
	
	*choice
		*if ((sporting_goods = 2) or (sporting_goods = 3)) #"He has expanded his interests in other directions. This will not interest him," I opine. I want nothing to interfere with the operation of ${spalding_sporting_goods}.
			The grey-haired heads nod in agreement around the table.
		*if (stl_vda_drama) #"Do we really want Von der Ahe to be part of this? He seems more trouble than any contribution might be worth."
			The grey-haired heads nod in agreement around the table.
		#"I am sure that, if there were a local solution, Mr. Wainwright would have identified it by now," I suggest.
			*set local_fame %+3
			The grey-haired heads nod in agreement around the table. Wainwright nods his head in your direction; some sign of thanks.
		#I say nothing; I'm curious why Von der Ahe wasn't invited myself.
			*set discretion %-5
			"Please," Wainwright answers the brothers. "Mr. Von der Ahe is not interested in a consortium. Truly, can you imagine him agreeing to abide by the results of a vote?"
			
			The room breaks out into laughter; clearly not.
	
	The matter of Von der Ahe aside, Wainwright tries to bring the conversation back to the matter at hand. "We must form one association or find ourselves dominated by the brewers of Milwaukee, Newark, and Pottsville. Do you want to see your fellow St. Louisans drinking Pabst at our baseball games? Do you want to them drinking Ballantine in our [i]biergärten?[/i] Yuengling in our saloons? Let me answer that for you: no." A number of the men pound the table in hearty agreement. "Now is the time to come together as one operation. For the good of our families and the good of St. Louis."
	
	Cheers break out from a preponderance of the guests, but others seem unconvinced. Adolphus Busch, seated at the foot of the table across from Wainwright, is clearly the most sceptical.
	
	When the room has calmed again, Busch stands to address the crowd. "I see no reason to merge with you, Mr. Wainwright. I have listened to your argument, and I do not dissent with your observations. However, let me state clearly that I intend to be the brewer to accomplish this goal of yours and that you have already lost. Why should I hobble myself by joining my fate to yours? No. If you want to participate in the future, I offer each of you, right now, an opportunity to sell your concerns to me. I will make you a fair offer, and you can even continue managing it until your retirement. But no, I will not diminish my future by merging it with yours. This offer will stand for three days. But, for now, I have heard enough of this proposal."
	
	With that, Busch stands and departs. The room erupts into shouts and exclamations as the door closes behind him.
	*choice
		#Wainwright is right; the brewers must merge. Given the opportunity, I advocate for such.
			*if (charm > 3)
				Your powers of persuasion aide you as you make the case for cooperation and affiliation.
				*goto association_formed
			*elseif (exposure > 5) and (local_fame > 40)
				It's not so much your words as the person speaking them. There are enough rumors about you to silence extensive dissent.
				*goto association_formed
			*elseif (local_fame > 50)
				Your stature in the city contributes to the weight of your words as you advocate for cooperation and affiliation. The discussion continues for some time longer.
				*goto association_formed
			*else
				Your words seem to have a minimal effect upon the gathered, but the clear benefits of such an association eventually turns the tide.
				*goto association_formed
		#Wainwright is wrong; the brewers should go their own way. Given the opportunity, I advocate for such.
			*if (charm > 3)
				Your powers of persuasion aide you as you make a case against affiliation.
				*label slba_not_formed
				*set slba_formed false
				*set beer_antitrust true
				The discussion continues for some time longer, but eventually Wainwright concedes that no association will be formed, and the meeting adjourns.
				
				It seems that each will go their own way, whatever that may mean.
			*elseif (exposure > 5) and (local_fame > 40)
				Your stature in the city contributes to the weight of your words as you advocate for cooperation and affiliation.
				*goto slba_not_formed
			*else
				*label persuade_fail
				Unfortunately, your urgings fall on deaf ears. The attendees are swayed by the clear benefits of cooperation, and slowly the climate of the room changes.
				*goto association_formed
		#Busch is right; the attendees should sell their concerns while they have the opportunity to do so.
			*if (charm > 3) or ((exposure > 5) and (local_fame > 40))
				*label busch_triumphant
				*set slba_formed false
				*set slba_subjugated true
				*set beer_antitrust true
				*set wainwright "Busch"
				And so they do.
				
				The individual breweries each sell their companies for the best price they can obtain. Of course, those that sell first receive the highest payouts; those who drag their feet come later as beggars. As a result, Anheuser-Busch becomes the dominant beer distributor of the region, if not the country.
			*else
				*goto persuade_fail
		*if (charm > 3)
			#I rush after Busch; he must be persuaded to return to the negotiating table.
				*set beer_antitrust true
				*set budweiser "Falstaff"
				*set exposure +1
				*set local_fame %+10
				*set stlouis_business_climate %+10
				You reach Adolphus at the cloakroom. With a few strong words, you persuade him to return with you to the meeting. A silence falls over the attendees when you open the door and reenter; they are clearly amazed at your powers of persuasion.
				*label association_formed
				The hard-hearted among the attendees set aside their animosities and agree to work together for the common good.
				
				Before the sun has risen, the St. Louis Brewers Association has been formed.
*page_break
*if has_saw_manuscript = 4
	The provost of St. Louis University delivers the original and the copy of Bowater's manuscript to you. You thank him and arrange for the balance of the payment to the institution.
	
	*if read_saw_manuscript = false
		*if (intelligence > 2) and (speaks_latin and (willpower > 2))
			*gosub_scene util read_saw
	
	Your use for it complete, you carefully package and return Bowater's original to the Senator of Savannah.
*elseif has_saw_manuscript = 14
	*set has_saw_manuscript -10
	The scrivener delivers the copy of Bowater's manuscript when it is complete. You pay him the last of his fee and send him on his way.
	
	*if read_saw_manuscript = false
		*if (intelligence > 2) and (speaks_latin and (willpower > 2))
			*gosub_scene util read_saw
	
	Your use for it complete, you carefully package and return Bowater's original to the Senator of Savannah.

*if renter and suffocation
	*page_break
	The house that you exist in is old and decrepit. While your landlady does her best to keep the roof from leaking, for example, there are some problems that are bone-deep.
	*temp acquire_tenement false
	*temp empty_tenement false

	One evening, you find yourself
	*if literate and ((intelligence > 2) and (laborvscapital > 60))
		reading [i]Das Capital[/i],
	*elseif literate and (intelligence > 2)
		reading@{speaks_german | a translation of} Schopenhauer,
	*elseif literate and (intelligence > 1)
		reading [i]Jane Eyre[/i],
	*elseif literate
		reading the newspaper,
	*elseif (religious_tradition != "pagan") and (rationalism > 70)
		offering your evening prayers,
	*elseif (tiozzo_portrait_1831 = 3) and (discretion > 50)
		admiring Tiozzo's portrait of you,
	*elseif finance > 0
		reviewing your accounts,
	*elseif kept_clotho_letter and (compassion < 45)
		idly fingering Clotho's letter to you,
	*elseif kept_silas_letter and (compassion < 45)
		idly fingering Silas's letter to you,
	*elseif creation > 0
		idly whittling a small figure,
	*else
		musing on how you might defeat @{west_prob ${imposter}|West},
	when you realize that you have not been disturbed by ${stlouis_valet} in quite a while.

	Rising, you venture into the front room of your quarters to find ${valet_him} slouched in a chair beside the stove. $!{valet_his} breathing is quite shallow.

	You @{(discretion > 50) slap ${valet_him} across the|caress ${valet_his}} face but ${valet_he} barely responds.

	Looking at the stove, you realize that the air has a peculiar taste to it. You have heard that coal stoves can get backed up and poison their users—you, of course, are unaffected.

	Not wanting to see ${stlouis_valet} die@{(compassion > 50) —valets are hard to train—|, }you throw open the door and drag ${valet_him} outside.

	It only takes a moment for ${valet_him} to revive, but as you do, you look over your shoulder and realize that the other tenants may be, at this very moment suffocating in their quarters.
	*choice
		#I've already saved one life tonight. No need to put myself out.
			*set compassion %+10
			*set acquire_tenement true
			*set empty_tenement true
			When ${stlouis_valet} fully revives, he summons the fire department.

			The firemen kick down the door to find most of the residents of the tenement dead from coal-air poisoning. One woman and her child that lived in the garret are still alive; the rest of the tenants are dead.
		#I can't expose myself, but I raise a cry and hope that a crowd can save the residents.
			*set discretion %-10
			*set compassion %+5
			*set acquire_tenement true
			You start shouting for the fire department, and soon others in the neighborhood echo your cry. People begin gathering with the intention of forming a water brigade, but when they understand the situation, they set about opening the windows and doors, while some enterprising individuals plunge into the house with the hope of finding some of the residents.

			One by one, the other tenants are pulled from the house. Several have suffocated—including your landlady—but most of them have survived.
		#I rush back into the house and start dragging people out.
			*set compassion %-5
			*set local_fame %+5
			*set exposure +1
			You start by throwing rocks at several windows, shattering them—and releasing some of the noxious fumes. You then run inside and begin dragging everyone outside.

			While you are hard at work, ${stlouis_valet} summons the fire department. They arrive just in time to see you carry a woman and her baby down from the garret. They marvel at your courage and resilience in the face of poisoned air.

			Once your landlady regains her senses, she kisses you on the cheek, tears streaming down her face.

	*if acquire_tenement
		In the subsequent weeks, the landlady's son approaches you and inquires if you would like to purchase the property.
		*temp slattery false
	
		*choice
			*if wealth > 50000
				*selectable_if (charm > 3) #I encourage him to offer an even better price.
					*label induced_sale
					*set laborvscapital %-5
					*set wealth -25000
					*set haven_value 50000
					*set renter false
					The young heir soon sees the wisdom of @{slattery Slattery's|your} words.
					
					The papers are drawn up, you sign the documents, and soon thereafter take legal control of the building.
			*selectable_if (wealth > 100000) #I pay the price demanded.
				*set wealth -50000
				*set haven_value 50000
				*set renter false
				The young heir offers you a fair price and you accept. With the assistance of ${stlouis_valet}, the documents are drawn up, executed, and filed, and soon you take legal possession of the building.
			#No, I'm content renting.
				*set laborvscapital %+10
				The young man is clearly disappointed; he has no interest in running a rooming house.
				
				He will survive.
			*if ((stlouis_enterprise = 2) and (wealth > 50000)) #With the assitance of some of my criminal associates, we make him an offer he can't refuse.
				*set local_fame %+5
				The boys are only too happy to communicate your desires.
				*goto induced_sale
			*if (stl_met_slattery = 4) #With the help of Judge Cranch, I force the sale at a better price.
				*set slattery true
				*goto induced_sale
		*if renter = false
			*temp cult false

			Of course, now that you have a rooming house, you must decide if you want to fill the empty apartments.
			*choice
				#I suppose I'm now a landlord.
					*set income +5
					*set exposure +1
					*set laborvscapital %-5
					*set stlouis_valet_loyalty %-5
					${stlouis_valet} is now a property manager; ${valet_he} adds it to his list of other titles. He sets about filling @{empty_tenement the apartments|the empty apartments}.
				#@{empty_tenement I take the building for myself.|I kick the woman and her baby out.}
					*set shepherd_credentials %-10
					*label kick
					*set local_fame %+5
					*set justice %+5
					*if haven_value > 200000
						*set bloodflow +1
					*if (stl_met_slattery > 7) and (empty_tenement = false)
						Unfortunately, Captain Slattery @{(stl_met_slattery = 9) and his pal Judge Cranch don't|doesn't} allow you to evict the woman and her baby so easily. Police visit your house daily to make sure you aren't harassing them unnecessarily.
						
						Eventually, you are forced to pay the woman to leave. That ended up being much more expensive than you had anticipated.
						*set wealth -10000
						*set stl_met_slattery 8
					*elseif empty_tenement
						With all property already empty, there is no one to oppose your decision.
					*else
						*set compassion %+5
						You expel the woman and her baby. The woman does her best to depart with dignity, but you can see that you have crushed her with your cruelty.
					*if cult

						Once they move in, the disciplines call out your name in gratitude. Amanda sets about organizing the new residents.
				*if (stlouis_cult) #I @{empty_tenement invite the members of the cult to fill the apartments|kick the survivors out and replace them with members of the cult}.
					*set stlouis_cult_power %+5
					*set cult true
					*goto kick
			*gosub_scene stlouis_haven household_maintenance
*elseif haven_decrepit and suffocation
	*page_break

	You have not been able to keep up with the maintenance on your home over the years. The roof has begun to leak, the doors stick, and it takes an inordinate amount of coal to heat the house during the winter—which you are resistent to spending money on, since the fire's warmth does next to nothing for you.

	One evening, you find yourself
	*if literate and ((intelligence > 2) and (laborvscapital > 60))
		reading [i]Das Capital[/i],
	*elseif literate and (intelligence > 2)
		reading@{speaks_german | a translation of} Schopenhauer,
	*elseif literate and (intelligence > 1)
		reading [i]Jane Eyre[/i],
	*elseif literate
		reading the newspaper,
	*elseif finance > 0
		reviewing your accounts,
	*elseif creation > 0
		idly whittling a small figure,
	*else
		contemplating some new additions to your wardrobe,
	when you realize that you have not been disturbed by ${stlouis_valet} in quite a while.

	Rising, you venture into the front room of your quarters to find ${valet_him} slouched in a chair beside the stove. $!{valet_his} breathing is quite shallow.

	You @{(discretion > 50) slap ${valet_him} across the|caress ${valet_his}} face but ${valet_he} barely responds.

	Looking at the stove, you realize that the air has a peculiar taste to it. You have heard that coal stoves can get backed up and poison their users—you, of course, are unaffected.

	You throw open the front door and drag ${stlouis_valet} out. You leave ${valet_him} there to recover while you return inside to try and extinguish the fire in the stove. In doing so, you manage to burn yourself; the Beast inside you screams in rage and fear. It wants to hurt someone or something.
	*temp temper false
	*if (strength > 3) or ((willpower > 2) or (discretion < 35))
		*set temper true

	Once you have succeeded in venting the kitchen, you emerge in a ball of fury to find ${stlouis_valet} surrounded by several of your neighbors. They are befuddled by your apparent imperviousness to the noxious fumes.

	*choice
		#I excoriate ${stlouis_valet} for being so careless.
			*set stlouis_valet_loyalty %-30
			${stlouis_valet} sets ${valet_his} jaw under your scorn. $!{valet_he} is used to such tirades.

			The neighbors soon dismiss their concerns about your health and join you in looking down their noses at ${stlouis_valet}.
		*if charm > 3
			*selectable_if (temper) #@{temper I hold on to my temper and use my powers of persuasion to disperse the crowd.|I'm too angry to use my powers of persuasion on the neighbors.}
				*set discretion %-5
				Through gritted teeth, you make up some nonsense and send the neighbors on their way.

				${stlouis_valet} hurries inside to begin putting things back where they belong.
		*if (creation > 0)
			*selectable_if (temper) #@{temper I hold on to my temper and pretend to be near-delirious from the fumes—I just hope I'm a good enough actor.|I'm too angry to pass myself off as sick from the fumes.}
				*set discretion %-5
				*if creation > 2
					*set local_fame %+5
					It takes masterful control of your mien and comportment to turn your fury into dismay, but you are a talented performer. The neighbors rush to your side as you collapse beside ${stlouis_valet}, pretending to faint.

					Some smelling salts are brought round and you feign jerking awake to cheers and "atta @{male boys|girls}."
				*else
					*set exposure +1
					You do your best to feign delirium, but you've had no time to prepare or study. They don't buy it for a moment.

					Of course, they have no better explanation for your invulnerability, so they pretend to accept it. But you can see that their suspicions have been raised.
		*if shapeshifting > 1
			*selectable_if (temper) #@{temper I spook one of the neighbor's horses to distract from me.|I'm too angry to try and spook the neighbor's horse.}
				*set exposure +1
				*set discretion %-5
				With a glare and whisper, the horse rears and throws its rider into the mud. Several women shout it surprise and dismay. Chaos ensues, and the matter of you being indifferent to the coal fumes is quickly set aside.

	Thankfully, within a fortnight the whole affair is seemingly forgotten.
	
*if ((ethnicity = "irish") or ((streetwise = 1) and (stlouis_haven = "kerry"))) or ((streetwise > 1) or (stlouis_enterprise = 2))
	*page_break
	*set egans_rats_plot 2
	About this time, you become acquainted with a young man from the Kerry Patch by the name of Thomas "Snake" Kinney. A poolshark, burglar, and all-round crook, he and his brothers and friends have organized a group known as the Ashley Street Gang. They've taken up an extortion racket in the Kerry Patch and are pushing south into Downtown.
	*if (ethnicity = "irish") and (compassion < 60)
		*set income +5
		*set egans_rats_plot 3
		*set stlouis_business_climate %-5
		And @{(stlouis_haven = "kerry") from your haven in the Kerry Patch|} you've been guiding them the whole way.
	
	Snake and his friend Tommy Egan are surprisingly charismatic; you sense that they have a real future in this business. On the other hand, there is a sadistic gang leader by the name of Baldy Higgins who controls the portion of the Kerry Patch closest to the waterfront. He could give the Ashley Street boys a run for their money.
	
	*if (ethnicity != "irish") or (compassion >= 60)
		*choice
			#I think it's time to make friends with Snake and Tommy.
				*set income +3
				*set egans_rats_plot 3
				*set stlouis_business_climate %-5
				They are begrudgingly willing to cut you in on their business. You, of course, bring your own talents to the matter.
				
				With your support, the Ashley Street Gang is able to push harder and faster into new territory than before.
			#I attempt to stymie their efforts; extortion rackets are bad for business.
				*set laborvscapital %-5
				*set stlouis_business_climate %+5
				*set egans_rats_plot 4
				Snake and Tommy are both wily and determined. While you are able to counter some of their schemes, you are not able to outright defeat them without slaughtering their whole gang.
				
				And, you suspect, Memeskia would prefer that you did not do that.
			#I'm going to throw my weight behind Baldy Higgins, the closest thing that Snake has to a rival.
				*set compassion %+5
				*set income +3
				*set egans_rats_plot 5
				*set egans_rats "Baldy's Rats"
				If Snake were to be described as refined—not that anyone would—then Baldy Higgins would be his crass reflection. George "Baldy" Higgins enjoys hurting people. It's not even about watching them beg for mercy; he's just fascinated by the way their bodies react when bleeding or maimed.
				
				Baldy looks at you askance when you approach him about an alliance. He doesn't try to kill you, so you suspect that he has accepted your overture.
			#Let the Ashley Street Gang attend to itself. My interests are elsewhere.
				*set discretion %-5
				*set shepherd_credentials %-5
				You watch as the Ashley Street Gang slowly solidifies its control of the Kerry Patch and Downtown. Someday, they will be a force to be reckoned with.

	*if stl_met_slattery = 2
		*if egans_rats_plot = 3
			You are unsurprised to discover that Sergeant Slattery is well-acquainted with Snake Kinney.
		*elseif egans_rats_plot = 5	
			You are unsurprised to discover that Sergeant Slatter is well-acquainted with Baldy Higgins.
	*elseif stl_met_slattery = 1
		*if egans_rats_plot = 3
			*set stl_met_slattery +1
			Through Snake Kinney, you are introduced to Sergeant Slattery, a youngish sergeant with the St. Louis police. He is a mercenary, willing to work for whomever can pay.
		*elseif egans_rats_plot = 5	
			*set stl_met_slattery +1
			Through Baldy Higgins, you are introduced to Sergeant Slattery, a youngish sergeant with the St. Louis police. He is a mercenary, willing to work for whomever can pay.

*temp date_mentioned false
*temp tick false
*if (shepherd_credentials > 40) or (stl_merchants_bridge > 1)
	*page_break
	*comment 1889-05
	*set date_mentioned true
	*set tick true
	With great fanfare, the Merchant's Bridge opens. The whole city comes out to see the first railcar cross its tracks.
	
	@{(stl_merchants_bridge = 3) Gould is reportedly pleased at the pace of construction.|Gould is no doubt stewing over this new threat to his empire.}
	
	At midnight, commercial traffic begins crossing the bridge. And with that, a new artery to the west is opened. Or, at least, so it appears. Within a few months, despite the lower rates on freight, it becomes clear that the Merchant's Bridge faces stiff competition from the Eads Bridge and the Wiggins Ferry. The Merchant's Bridge corporation assumed incorrectly that building a bridge would suffice, but the infrastructure around the bridge—loading and unloading, railyards, maintenance yards, [i]et cetera[/i]—matters. Building those facilities will require another infusion of capital or some other solution.
	
	For the time being, the Merchant's Bridge tries to lower their prices and beat the competition that way, but it is a difficult sell.
*if (stl_merchants_bridge > 1) or ((local_fame > 45) or (stlouis_haven = "lafayette"))
	*page_break @{tick While On Your Way To A Celebration|Next}
	"Pardon me, ${sir}!" a voice cries out. "You're going to the Bridge reception, aren't you? You'll need a cigar if you're to look the part!"
	
	You're in the Southern Hotel—and the salesman is right, you're on your way to a reception for the opening of the Merchant's Bridge. You walk down this thoroughfare regularly—all patrons must run the gauntlet of concessions as they make their way into the heart of the hotel.
	
	*choice
		*selectable_if ((stealth > 0) or (streetwise > 0)) #I usually take the servants' entrance to avoid these concessions.
			*set discretion %-3
		#I actually enjoy the thoroughfare; it's another way to remain attuned to the fashions of the day.
			*set anachronism %+1
		#It is the most direct route; I see no reason to take any other.
			*set discretion %+2
		
	You pause for the briefest moment. The salesman is not wrong; every man there will have a cigar. @{male |You're surprised that he would stop you, though.}
	*temp cigar false
	
	*if male
		*choice
			#I will buy one to better fit in with the mortals.
				*set discretion %-3
				*set cigar true
			#I am not a mortal and I do not aspire to be one.
				*set compassion %+1
				*set discretion %+1
				You brush past the salesman and make your way to the reception.
				*goto skip_cap
			*if (trans = false) #I buy one out of nostalgia for when I could truly enjoy such a thing.
				*set compassion %-3
				*set anachronism %-1
				*set cigar true
			#I don't buy one, but I do want to make the acquaintance of this salesman.
				*set discretion %-2
	*else
		"You think it would be appropriate for me to sport one?" you ask.
		
		"I sense something special about you," he says with a grin. "Sometimes, you need to show it off. And from what I hear, tonight is the real deal."
	
		*choice
			#I will buy one; it will be delightfully scandalous.
				*set local_fame %+3
				*set cigar true
				Women smoke cigars, yes. But no woman at this reception will be smoking one. You will certainly turn some heads with the affectation.
			#I will buy one to make a political point.
				*set justice %-3
				*set local_fame %+1
				*set cigar true
			#I am not a mortal and I do not aspire to be one.
				*set compassion %+1
				*set discretion %+1
				You brush past the salesman and make your way to the reception.
				*goto skip_cap
			#I don't buy one, but I do want to make the acquaintance of this salesman.
				*set discretion %-2
				
	While the salesman shows you his wares, you learn his name: Cap Tilles. This is his concession and he knows his product line in and out.
	
	*if cigar
		What kind of cigar do you buy?
		
		*fake_choice
			#Something thin and elegant.
				*set discretion %-2
			#Something fat and juicy.
				*set discretion %+3
			#Something expensive, to show these folks that I mean business.
				*set exposure +1
				*set local_fame %+5
				*set discretion %+3
		
		You thank him and pay your bill. He smiles and @{male shakes your hand|tips his hat to you}, promising you that you won't regret your purchase.
	*else
		You let him talk for several more minutes, asking several pointed questions along the way.
	*temp tick false
	*if (male = false) and (perception > 0)
		*set tick true
		You observe over the course of the exchange that he is very careful to never touch you. Curious. But no matter;
	@{tick you|You} have the feeling this fellow is going places. @{cigar |That said, by the time you say goodbye he's so confounded he doesn't even realize that you didn't buy anything.}
	*set stl_met_tilles true
	*label skip_cap
*if ((ethnicity = "african") or (justice < 35)) or ((shepherd_credentials > 80) or (stlouis_enterprise = 7))
	*page_break
	@{date_mentioned Later that month,|In May,} a truly remarkable thing happens: a black man, the son of former slaves, graduates from Washington University Law School.
	
	What is less remarkable, however, is that the white students refuse to march with Walter Moran Farmer during the graduation ceremony. The dean of the law school, who had championed Farmer's presence throughout his enrollment, volunteers to march alongside Farmer.
	
	Within a few months, Farmer is admitted to the bar association and opens his own law practice. The black newspapers cannot get enough of the story, covering every inch of his life and doings for his first few years as a lawyer. Rightly so, as his name sells papers.
*if (stlouis_affair > 1)
	*page_break
	A handbill advertising a circus—not Barnum & Bailey's—brings Annie Jones to mind.
	*if (stlouis_affair = 10) or (stlouis_affair = 5)
		Her blood was something special.
		*goto after_annie
	*elseif stlouis_affair = 3
		You've maintained an intermittent correspondence with her in the interim. The conversation has alternated between salacious and poignant. She has a way with words and further seems to recall your assignation with fondness, though she occasionally dips into less-cheery reflections on her condition.
	*elseif stlouis_affair = 2
		You haven't seen or corresponded with her since feeding from her a few years ago.
	
		Would you like to write to her?
		
		*fake_choice
			#Yes! I think I might care for her.
				*set compassion %-5
				*set stlouis_affair 3
				Upon returning home, you direct ${stlouis_valet} to search the newspapers for the itinerary of the Barnum & Bailey Circus. Once ascertained, you compose a letter and send it along to meet her in a few days.
				
				Over the next few months, you strike up an increasingly salacious correspondence. She has a way with words and—more importantly—seems to recall your assignation with fondness.
			#No, she has bored me.
				*set stlouis_affair 1
				You crumple the handbill and continue on your way.
				*goto after_annie
		
	You frequently remark on your desire to see her again; she responds to these velleities with warmth.
	
	One particular day, you inquire about her choice of profession. Why maintain her beard? Why put it on display for all to see?
	
	It is several months before you receive a response. It is carefully composed, balancing the delicacy of her feelings for you with the need to express herself:
	
	[i]My beard makes me who I am. Who would I be without it? Another housewife struggling to keep her ratpack of children in line? No, I have no desire to be a housewife. The road with all its vagaries is my home: the people, the places, the sights…. Yes, I could shave and be just like everyone else, but how could I live like that? I would be living a lie. Better to be the best version of yourself than some cruel manifestation of someone else's expectations.[/i]
	
	She continues much in that manner for a while yet.
	
	She closes by urging you to strive to not judge others for what they do with their bodies. They seek only to be their best selves. 
	*label after_annie
*if baseball_failed = false
	*page_break
	*comment 1889
	*if involved_baseball
		When the Browns are stopped just shy of their fifth pennant by the Brooklyn Bridegrooms, Von der Ahe and Comiskey exchange heated words. The two men have very different ideas about why the Browns were beaten.
		
		Shortly thereafter, Comiskey accepts a position coaching a team in Chicago.
	*else
		At the conclusion of the baseball season, Charles Comiskey accepts a position coaching a team in Chicago.
	The city is torn over his departure; many wanted him to stay, and just as many wanted him to go.
*if stl_met_slattery = 2
	*page_break
	*temp kinney "Kinney"
	*if egans_rats_plot = 5
		*set kinney "Higgins"
	*if joined_kkk
		*set stl_met_slattery 3
		About this time, a former Confederate officer that you have grown chummy with introduces you to Judge Cranch. Cranch works closely with Sergeant Slattery. Cranch makes it clear that the two of you should have a close working relationship. You agree.

	*elseif (egans_rats_plot = 3) or (egans_rats_plot = 5)
		*set stl_met_slattery 3
		About this time, ${kinney} reaches out to you about a judge. It seems Judge Cranch is making life difficult for a certain burglar in ${kinney}'s employ. 

		Cranch's pride has been injured: the burglar robbed from Cranch's cousin's silversmithy. ${kinney} tried to convince Slattery to intervene, but it seems Slattery's loyalty to Judge Cranch goes deeper than money.

		*choice
			#I persuade Cranch to go easy on the thief.
				Once Cranch has released the thief, he informs you that this deal was a two-way street; soon, he'll call in the favor.
			#I pay Cranch off.
				Once Cranch has released the thief, he informs you that this deal was a two-way street; soon, he'll call in the favor.
			#I want nothing to do with these reprobates.
				*set stl_met_slattery 8
				That's rich, coming from someone who consorts with the likes of ${kinney}.
	*elseif (renter = false)
		*set stl_met_slattery 3
		As far-fetched as it may sound, you have found yourself in a quarrel with your neighbor over a tree. You have observed this tree growing in the direction of your 
		property for a decade now, and it has begun shedding leaves on your property. In particular, its limbs have a tendency to break off in storms, and you've had to replace several windows and even repair a roof due to the damage caused. One evening, you order ${stlouis_valet} to chop down the tree and be done with it.

		Unfortunately, your neighbor files suit against you, and your case goes before a judge by the name of Cranch. Before a trial date can be set, however, Sergeant Slattery pays you a visit, offering you the opportunity to bribe him. Of course, it's clear this isn't really an opportunity—so much as a demand.

		*choice
			#I pay the bribe.
				*set wealth -2500
				Once Cranch has dismissed the suit, he meets with you at the Planter's House Hotel and informs you that his dismissal comes at a higher price than a few dollars. Someday soon, he'll call on you for something more.
			#I negotiate a lower amount.
				*set wealth -1500
				Once Cranch has dismissed the suit, he meets with you at the Planter's House Hotel and informs you that his dismissal comes at a higher price than a few dollars. Someday soon, he'll call on you for something more.
			#I want nothing to do with these reprobates.
				*set stl_met_slattery 8
				*set wealth -20000
				Cranch and Slattery are displeased that you have crossed them.
				
				Cranch issues a judgment against you that is disproportionate to the situation, but the matter is best resolved by paying the judgment and being clear of the two of them.
	*elseif (stlouis_enterprise = 2)
		*set stl_met_slattery 3
		About this time, a young newsie who doubles as a pickpocket and hustler gets caught running a scam on your behalf. He squeals, but thankfully only to Sergeant Slattery.

		The newsie is brought before Judge Cranch, who delays the hearing long enough to entertain a meeting with you.

		*fake_choice
			#I persuade Cranch to go easy on the thief.
			#I pay Cranch off.

		Once Cranch has released the thief, he informs you that this deal was a two-way street; soon, he'll call in the favor.
		*if discretion > 70
			Meanwhile, you make sure the newsie never squeals again.
*if ((has_saw_manuscript >= 5) and (has_saw_manuscript <= 9))
	The provost of St. Louis University delivers the original and the translation of Bowater's manuscript to you. You thank him and arrange for the balance of the payment to the institution. When you ask after the monk, you are informed that he has taken a vow of silence.
	
	*if read_saw_manuscript = false
		*if has_saw_manuscript = 5
			*if speaks_latin
				*gosub_scene util read_saw
		*if has_saw_manuscript > 5
			*gosub_scene util read_saw
	
	Your use for it complete, you carefully package and return Bowater's original to the Senator of Savannah.

*if (stl_praetor_carlos > 1) and ((sire_rapport > 40) or embrace_of_affection)
	*page_break
	*set beast_of_gevaudan true
	*set knows_about_silver true
	To your surprise, ${stlouis_valet} furnishes you with a letter one evening. @{literate It has been decades since you have seen a letter written in this hand; you shake as you turn it over to break its seal.|Though you are no master of letters, one glance at the handwriting and you know exactly who sent it.}
	
	@{literate Trembling, you pull the letter out.|You hand the letter to ${stlouis_valet} to read to you.}
	
	*if embrace_of_affection
		*if sire_rapport > 60
			[i]Dearest[/i]
		*elseif sire_rapport > 40
			[i]Scion[i]
		*else
			[i]Apostate[/i]
	*else
		[i]Scion[i]
	[i]${original_name}[/i],
	
	[i]I received your letter. I understand that you wrote it some time ago. @{(sire_rapport > 55) I apologize for my tardiness in replying.|}[/i]
	
	[i]I believe that the answer you seek is this: silver.[/i]
	
	[i]There are many stories about why this simple metal may be the bane of Beasts. I do not know the truth of them. But it is clear that when a vampire loses their humanity, they become somehow susceptible to silver.[/i]
	
	[i]If my duties permitted me, I would come to St. Louis to aid you in this; but alas, I cannot yet.[/i]
	
	[i]I hope that my presence will not be needed, but if Quaestor Memeskia truly feels it necessary, urge him to write to me.[/i]
	
	[i]Your Dominus,[/i]
	*line_break
	[i]Carlos Teixidó Mas[/i]
	*line_break
	[i]Praetor of the Americas[/i]
	
	Silver? You roll this thought over in your mind.
	
	You look at the stamps and postmarks on the letter: @{literate |with ${stlouis_valet}'s help,} you see that your maker wrote to you from Nicaragua.
	
	What is he doing in Nicaragua?
*finish Next