*comment ñáéç…—
*hide_reuse
*advertisement
*set year 1879
*temp gonsoulin false
*comment mention bulldozers
*temp mr_german "Herr"
*if male = false
	*set mr_german "Fräulein"
*if priest
	*set mr_german "Hochwürden"

Snow is still on the ground when they first arrive. Shivering and underdressed, they leave their steamboat and proceed to mill about the riverfront, waiting for their deliverance. Young, old, men, women…their numbers swell by the day. What began with a few families soon sees disembarkations of two to three hundred souls at a time. Their arrival sends the city into an uproar; by the middle of April, there are headlines in the newspapers when a day passes without the arrival of more of these individuals.
*temp tick false

These recently freed men and women have arrived in St. Louis—largely destitute—having heard that upon arrival, a Federal steamboat would take them upriver to Kansas. Kansas, which joined the Union immediately before the outbreak of the war as a Free State, considered its devotion to equality a point of pride. With plenty of land available for free for homesteaders, these migrants set out on the Mississippi for a better life.
*if (shepherd_credentials > 50) or (ethnicity = "african")
	*set tick true
	Even more than seeking a better life, though, they are also fleeing the vengeance of the Southern planter class. The white landowners of Louisiana, stripped of their former prestige and power by Emancipation, used every method at their disposal to legally entrap and ensare their former slaves. But now that Reconstruction has ended and Federal supervision has been withdrawn, the true terror has begun.

@{tick At the urging of friends and associates in Louisiana, |}Mayor Overstolz threatens to sue the steamboat companies for leaving these mostly destitute @{tick refugees|migrants} on his doorstep, but relents when the steamboat companies invoke the Civil Rights Act of 1875 in their defense. Instead, he sends the police to the docks to read various proclamations, encouraging the @{tick refugees|migrants} to return to their plantations in Mississippi and Louisiana. He even arranges for free transportation back, but these men and women did not make the journey in St. Louis just to return home.

*if finance > 0
	Of course, you could always encourage the Exodusters to stay in St. Louis. It would deepen the racial tensions in the city—a large, unskilled labor pool like the Exodusters means that when whites going on strike, a business can bring in freemen to cross the picket lines—but it would lower the costs of labor.

*choice
	*if (feeding_style = "itinerants") or (feeding_style = "laborers")
		#My favorite! I use the opportunity to drink my fill.
			*label hunt_exodusters
			*set compassion %+10
			*if (ethnicity != "african") and (ethnicity != "choctaw")
				*set stlouis_race_relations %-5
			*if (stealth <= 3) and (ethnicity != "african")
				*set exposure +1
			It's actually a little more difficult that you had anticipated, but the problems are not insurmountable. Their conditions along the riverbanks are squalid at best, with little space or opportunity for you to mix without attracting attention. However, on occasion, one will separate from the crowd and go into the town proper. When this occurs, you make sure to arrange an encounter to serve your own purposes.
			
			To your annoyance,
			*gosub arsonist_first_strike
			Their insularity makes your depredations even more difficult.
			
			*goto the_committee
	*elseif (compassion > 65)
		#Migrants that no one will miss? I use the opportunity to drink my fill.
			*goto hunt_exodusters
	*if stlouis_enterprise = 4
		#I reach out to the [i]turnverein[/i] to solicit aid for the refugees.
			*set local_fame %+10
			*set anti_german_sentiment %-10
			*set stlouis_business_climate %+5
			*set stlouis_race_relations %+20
			*set shepherd_credentials %+15
			*set aichinger_rapport %+10
			*set push_for_desegregation %+5
			Though the Germans are more inclined to help their own countrymen arriving from Europe, a few choice words from you opens their eyes to the wisdom of helping the Exodusters on their way to Kansas. Funds are raised and distributed and—with typical German precision—the Exodusters are sent onwards to their new home. During these interactions,
			*gosub wheeler_and_turner
			
			The black community of St. Louis is awed by the generosity of their German neighbors. Reports about the special relationship between the two peoples begin to appear in newspapers across the region.
			
			Unfortunately,
			*gosub arsonist_first_strike
			In solidarity, the German immigrants redouble their efforts.
			*goto questions_of_faith
	*if stlouis_enterprise = 2
		#They may say that they are destitute, but there is always more to take. The thieves and pickpockets of St. Louis will uncover the refugees' hidden wealth.
			*set local_fame %+5
			*set wealth +5000
			*if streetwise > 2
				*set wealth +5000
			*set shepherd_credentials %+15
			*set carothers_rapport %-20
			*set stlouis_race_relations %-10
			*set stlouis_business_climate %-5
			*set compassion %+20
			Between outright fraud, confidence games, extortion rackets, and pickpockets, the criminal underworld of St. Louis deprives the migrants of whatever wealth they have managed to retain through their journey. And a significant portion of each take finds its way in your pockets.
			
			Though it does not interefere with these activities,
			*gosub arsonist_first_strike
			Their insularity complicates your efforts, but not overly so.
			
			Before long, some so-called Committee of Twenty-Five organizes and tries to usher the improverished migrants on their way. The rest of the city is only too happy to see them go.
			*goto questions_of_faith
	*if (stlouis_enterprise = 5) and (wealth > 20000)
		#As a patron of the arts, I want to identify and induce the most talented individuals to stay in St. Louis.
			*set local_fame %+5
			*set wealth -5000
			*if wealth > 100000
				*set wealth -10000
			*if (perception > 1) and (creation > 2)
				*comment TODO integrate St Louis Choral-Symphony??
				*set stlouis_race_relations %+10
				*set shepherd_credentials %+10
				*set stlouis_exoduster_artists_recruited true
				With much effort and perservence, you manage to find a number of very talented musicians among the migrants. It is not simple to convince them to stay—they believe in the Exodus movement—but you can be very persuasive when you put your mind to it. The matter comes to a head when,
				*gosub arsonist_first_strike
				Some of the musicians decide stay in St. Louis alone; others convince their families to stay with them. Either way, the break with the rest of the Exodusters is painful for everyone. Of course, your financial support goes a long way to making these transitions bearable. 
				
				*goto the_committee
			*else
				*set shepherd_credentials %+5
				You find it surprisingly difficult to convince any of these refugees to hear you out, and those that do are not the sort worth recruiting to your cause. Complicating matters,
				*gosub arsonist_first_strike
				This only makes your task more difficult and you soon abandon it altogether.
				*label the_committee
				
				In time, an organization calling itself the Committee of the Twenty-Five forms. The Committee sets about raising money to expedite the departure of the migrants and—somewhat to the surprise of the white population of the city—succeeds in the effort.
				*goto questions_of_faith
	#I do my best to encourage the refugees to stay in St. Louis.
		*set local_fame %+10
		This doesn't involve standing in front of the migrants and making some grand speech. Rather, you arrange quiet tête-à-têtes with local leaders and make them see the value in the expansion of the city's labor pool.
		*if (charm > 3) or ((ethnicity = "african") and (charm = 3))
			*set stlouis_business_climate %+20
			*set stlouis_race_relations %-30
			*set aichinger_rapport %+10
			*set push_for_desegregation %-12
			*set exodusters true
			*if feeding_style != "vegetarian"
				*set bloodflow +1
			*if (stlouis_valet_num = 1) or (stlouis_valet_num = 4)
				*set stlouis_valet_loyalty %+10
			In particular,
			*gosub wheeler_and_turner
			With your encouragement, the Committee focuses on integrating the migrants into St. Louis.
			
			Unfortunately,
			*gosub arsonist_first_strike
			This complicates matters, but the Committee shines amid the misfortune, organizing the purchase of burial plots and hosting wakes for the dead.
			
			Not all of the Exodusters end up staying, but there are enough to make a difference. Soon, Chestnut Valley is booming with the expansion of rooming houses and the construction of other living quarters. As their numbers continue to swell, however, a shanty city sprouts in the fields to the north and quickly expands. @{(finance > 0) Additionally, the presence of the extra workers depresses wages for everyone.|}
			*goto questions_of_faith
		*else
			*set stlouis_business_climate %+5
			*set stlouis_race_relations %-15
			
			Unfortunately,
			*gosub arsonist_first_strike
			This makes your efforts only more difficult, as few have the time or inclination to hear out a relative newcomer to the city.
			
			Without your involvement, an organization called the Committee of Twenty-Five forms. It is an organization of local blacks formed to aid the migrants in their journey. They seem to largely stymie your efforts, raising money from their own community as well as individuals across the country and abroad. You take comfort in the fact, however, that a small shanty town has sprouted in the fields north of the city to house those migrants who have decided to stay. @{(finance > 0) However, the presence of the extra workers depresses wages for everyone.|}
			*goto questions_of_faith
	*selectable_if (wealth > 200000) #I contribute to the effort to see the refugees on their way.
		*set wealth -20000
		*set local_fame %+15
		*if (stlouis_valet_num = 1) or (stlouis_valet_num = 4)
			*set stlouis_valet_loyalty %+5
		This doesn't involve standing in front of the migrants and making some grand speech. Rather, you arrange quiet tête-à-têtes with local leaders
		*if (charm > 2) or ((ethnicity = "african") and (charm = 2))
			*set stlouis_race_relations %+10
			and discuss how best to alleviate the suffering of the travelers and aid them in their journey. In particular,
			*gosub wheeler_and_turner
			
			Flush with your contributions as well as other contributions from across the country and even abroad, the Committee contracts an entire steamboat to take the migrants upriver to their destination. This happens several times over the course of the year; these days are greeted with much fanfare by the city.
			
			It is not all wine and roses, however, as
			*gosub arsonist_first_strike
			But sustained by your contribution, the Committee continues undaunted with its work, organizing the purchase of burial plots and hosting wakes for the dead.
			
			Across the region, newspapers trumpet the self-reliance and communal spirit of the black community of St. Louis. 
			*goto questions_of_faith
		*else
			and make your interest in the matter known. Your money is graciously accepted by a representative of the Committee of Twenty-Five, but you are curiously unable to obtain an invitation to any of their meetings.
			
			To complicate matters,
			*gosub arsonist_first_strike
			The Committee does its best to respond to this misfortune, offering to organize the purchase of burial plots and host wakes. 
			
			Absent the support of the city, the state, or the Federal government, the Committee struggles to raise funds to aid the refugees. To the surprise of many, they largely succeed, and the majority of the refugees continue on their journey within a few months of their arrival.
			*goto questions_of_faith

*label wheeler_and_turner
*set met_wheeler_and_turner true
you have the opportunity to meet two luminaries of the local black community: John Wheeler and James Milton Turner. A tobacconnist originally from Kentucky, Wheeler has served on several Republican councils already, and indicates his intention to further his political career. Turner, on the other hand, was born a slave and sold as a baby out of the arms of his mother on the steps of the St. Louis courthouse. Through good fortune and unflinching resolve, he eventually became the US Ambassador to Liberia after the war. With the change in administrations, he has recently returned home to St. Louis to continue his law practice and advocate for the advancement of his people.

The two men are part of the Committee of Twenty-Five that have organized to support the migrants.
*if ethnicity != "african"
	They are somewhat surprised by your interest in the affairs of their community, but you convince them of your good intentions.
*return

*label arsonist_first_strike
at the height of the influx, tragedy strikes. Several tents housing the refugees go up in flames, and two dozen men, women, and children die in the blaze. 
*if (ethnicity = "african") or ((stlouis_enterprise = 1) or (stlouis_enterprise = 2))
	*set stlouis_arsonist_investigation +1
	There are rumors that a white man was seen in the vicinity of the tents immediately before the first started, but no witnesses step forward.

The Exodusters grow only more tight-knit in the wake of the misfortune, committing themselves to each other and their shared vision of the future.
*return

*label questions_of_faith
*page_break
*temp inside_church false
*temp stlouis_priest "priest"
*temp stlouis_cathedral "cathedral" 
*temp stlouis_the_cathedral "the cathedral"
*temp oshaun "Father O'Shaunghnessy"
*temp stlouis_mass "mass"
*temp fullconfession false
*temp partialconfession false
*temp disguised false
*if nola_met_gonsoulin and ((rationalism > 45) and (religious_tradition = "catholic"))
	*set oshaun "Father Gonsoulin"
	*if rationalism > 65
		Though decades have passed since your death, your faith remains strong. However, that means you refrain from sullying the cathedral with your footsteps. Instead, you frequent the streets around it, doing your best to observe the comings and goings without becoming obtrusive.
	*else
		*set inside_church true
		Over the decades since your death, your faith has wavered. Sometimes you still attend mass at the cathedral, but very rarely.
	
	Tonight, as you are @{inside_church preparing to leave|walking pass the rectory}, an old priest drops an offering box.
		
	*if compassion > 35
		*choice
			#An offering box? I take it and run.
				*set compassion %+3
				*set discretion %+3
				*set wealth +2500
				The old priest is in no condition to give chase. Between his eyesight and the darkness, he wouldn't even be able to give a description of you.
				
				Had anyone asked him.
				*goto 1879_court
			#I walk on by. I've really grown past these concerns.
				*set shepherd_credentials %-3
				*set rationalism %-15
				Behind you, the old priest fumbles with the offering box; you can hear its contents clinking.
				
				You stride @{inside_church out the front door and|} into the night, doing your best to put your past behind you.
				*goto 1879_court
			#I fetch it for him.
				*set compassion %-5
	You bend to pick it up, and when you rise, your eyes lock. The priest's rheumy eyes dilate in surprise, and then focus.
	
	"${mr} ${surname}?" he says. "But…how is it possible?"
	
	"I'm sorry…I don't believe…"
	
	"You haven't aged a day! It's been—let me see—sixty-four years. And you…you're the same as you were at the President's Ball in New Orleans. In 1815."
	
	It comes back to you. The victory reception at Bernard de Marigny's. The young deacon traveling with Bishop Dubourg.
	*achieve full_circle
	*set gonsoulin true
	
	You @{(compassion < 50) try to|successfully} stifle any sign of recognition. "Perhaps we should go somewhere more private…" you offer. You lead the befuddled priest @{inside_church through the nave and down into the bowels of the church|around the back of the church and into a nearby saloon}. You take the time to consider your next move.
	*label confront_loop
	*choice
		#I kill him. Better safe than sorry.
			*if feeding_style = "vegetarian"
				*set compassion %+10
				*set exposure +1
				An old man is easy to strangle. He balls his fists and lands a surprising number of blows, but he is no match for your immortal vigor.
			*else
				*set compassion %+5
				*set exposure +2
				@{(feeding_style = "clergy") You had not expected to drink the lifeblood of a priest this evening, but you will not turn the opportunity down.|Never one to waste blood, though the clergy are not your preference, you drink him dry.} He stares at you the whole time, his eyes a silent accusation. @{(perception > 2) The blood is dry and brittle, much like man.|}
			
			Having covered your tracks, you depart the @{inside_church church|saloon} swiftly.
		#I try to play off the resemblance; he must be referring to my grand@{male father|mother}.
			He looks at you askance.
			*if priest
				"Your grandfather abandoned the church?" he inquires.
				
				"He did."
				
				"And you too became a priest?"
				
				"Yes."
				
				"Which parish are you assigned to? Why have we not met?"
				
				"I'm actually on my way to Colorado. They need more parish priests there. I just happened to have a transfer in St. Louis and thought that I would see your magnificent cathedral."
				
				*if charm > 2
					"This is highly irregular, Father…" he stumbles. "What did you say your name was?"
					
					*if dead_in_stlouis >= 2
						"${given_name}. ${given_name} ${surname}."
					*if dead_in_stlouis = 1
						@{trans "Michelle. Michelle ${original_surname}|"Michael. Michael ${original_surname}}." The lie comes to you easily.
					
					"Yes, well, as I said. Highly irregular."
					
					"Forgive me, Father."
					
					"Yes, well. How is your grandfather?" he inquires.
					
					"Dead," you blurt out@{(dead_in_stlouis != 2) , silently praying that Gonsoulin will not investigate the matter later|}. "You knew him?"
					
					"I met him, briefly. Years ago. You are @{speaks_french the spit and image|another droplet} of ${him}."
					*comment COPYEDITOR the original form of the idiom was "spit and image," only becoming mispronounced around 1900. https://idioms.thefreedictionary.com/spitting+image
					
					*if speaks_french = false
						"Excuse me?"
						
						"Ah, excuse me. You are…the spit and image?…of him."
					
					"So I've been told," you say with relief.
					
					"Too bad he's in hell."
					
					You recoil a little. But of course. To abandon the priesthood, likely for lust, would surely condemn a priest to hell. Of course, he's talking about you, and if you've been condemned, it was likely for any number of other crimes you've committed over the decades. "I pray for him nonetheless, Father."
					
					"That's charitable of you."
					
					You spend another short time in conversation before you excuse yourself. No need to risk this charade any further. He bids you goodnight.
					
					Afterwards, you make sure to steer clear of the St. Louis Cathedral; there are other parish churches you can haunt if you still feel the need.
				*else
					He peers at you again. "No, no…I'm sure of it…" he says, trying to make sense of the irreconcilable.
					*goto confront_loop
			*else
				*if trans
					"Your grand@{male mother|father} was ${original_name} ${original_surname}?" You suppress the urge to wince at the sound of your old name.
				*else
					"Your grand@{male father|mother} was @{(dead_in_stlouis > 1) ${original_name} ${original_surname}|${given_name} ${surname}}?"
				
				"Yes, @{trans ${original_he}|${he}} was."
				
				*if charm > 1
					"Well, I suppose that makes sense. You are @{speaks_french the spit and image|another droplet} of @{trans ${original_him}|${him}}."
					
					*if speaks_french = false
						"Excuse me?"
						
						"Ah, excuse me. You are…the spit and image?…of @{trans ${original_him}|${him}}."
					
					"So I've been told," you say with a smile.
					
					"Have you confessed recently? If you've been here for some time, and we haven't met, I am compelled to observe…"
					
					You interrupt, "No, I can't say that I have."
					
					"You should."
				*else
					He peers at you again. "No, no…I'm sure of it…" he says, trying to make sense of the irreconcilable.
					*goto confront_loop
		#I confess my condition.
			*gosub full_confession
		#I claim that I am an angel.
			*set idea_for_cult true
			*set discretion %+5
			*set rationalism %-5
			*set exposure +1
			Father Gonsoulin blinks—repeatedly. You can see him trying to reconcile the irreconcilable. When he finally speaks: "Of course, that must be it! How else could you be unchanged after all these decades?"
			
			Scrambling for something suitably angelic to say, you reply, "you are hereby bound to secrecy, Father Gonsoulin. You must not reveal my presence to the people, lest my divine mission is compromised."
			
			"No, of course not! I would never seek to disrupt Our Father's deeds!"
			
			The conversation continues much in that style as you stitch up the tear in the fabric of Gonsoulin's understanding of reality.
			
			He has so many questions for you, but you put them off as being too dangerous for you to answer. Eventually, you part ways, mildy energized by the thought of your own divinity.
			*page_break
			Over the next few nights, the idea of your divinity continues to evolve in your consciousness. Could you, in fact, be some sort of angel? Or demon? Perhaps, even, a god@{male |dess}?
			*goto gonsoulin_to_cult
	*goto 1879_court
*elseif idea_for_cult and (discretion > 25)
	The religious fervor of the migrants has caught the imagination of the city, and that fever has in turn spread to you. Inbetween your other activities, you find yourself contemplating the nature of divinity. It is a fact that you are more than human. One that cannot be denied. On those occasions that humans witness your vampiric nature, they are filled with awe.
	*if rationalism >= 40
		This has contributed to the idea that you yourself may be some sort of divine being. From life to more life.
		*label gonsoulin_to_cult
		*if heresy_of_abraham > 1
			Were vampires not created when Abraham sacrificed his son Isaac? You are the direct descendant of that act of creation.
		*if heresy_of_abraham = 1
			There have been hints of such possibilities in the little tidbits that you have received of the story of Abraham and Isaac, but you must know more!
		*if heresy_of_abraham = 0
			Of course, you must keep such ideas to yourself; you have no doubt that the Society would disapprove.
		*comment endif
		
		The Rule of Reserve has governed your actions and those of your peers for so long. But is it really necessary?
		*label cult_choice
		*choice
			*if rationalism >= 40
				#The humans should worship me. I am a being worthy of such.
					*set discretion %+30
					*set rationalism %+30
					*label cult_founded
					*achieve stl_cult
					*set stlouis_cult true
					*set local_fame %+20
					*set exposure +3
					But what kind of divine being will you be?
					*choice
						*selectable_if (compassion < 35) #I encourage them to perform acts of charity in the world.
							*set exposure +1
							*set local_fame %+5
							*set stlouis_cult_power %-20
						*if (religious_tradition = "pagan") #I invoke the old ways, trying to bring my culture's traditions to these colonists.
							*set exposure +1
							*set stlouis_cult_purpose 2
						#The important part of this that they donate to the maintenance of my lifestyle.
							*set wealth +100000
							*set stlouis_cult_purpose 3
							*if finance > 1
								*set stlouis_cult_power %+10
								You preach a prosperity gospel that asserts that material success is a sign of divine blessing. The fact that you are able to advise people on how to prosper through your grasp of the intricacies of finance, means that they fall over themselves donating to your ministry.
						#I just want to be able to feed safely.
							*set discretion %-10
							*set wealth +10000
							*set stlouis_cult_purpose 4
							*set exposure -1
						*if ((religious_tradition != "pagan") and (rationalism > 60))
							#God has turned His back on me, I turn my back on him. The cult will be about human sacrifice, desecration of the holy, and the corruption of the pure.
								*set exposure +2
								*set compassion %+50
								*set discretion %+30
								*set stlouis_cult_purpose 5
								Drinking blood is so much more fun when it's a spectacle. And you are happy to make it into one.
						*if (stlouis_enterprise = 6) or (temperance_movement)
							#I use it to extend the reach of women's rights—both temperance and suffrage.
								*set stlouis_cult_purpose 6
								*set missouri_prohibition +1
								*set missouri_suffrage +1
					*set income +10
					*set bloodflow +2
						
					After several months of effort, you are pleased to see your cult taking root in the fertile soil of St. Louis. As it is, feeding has already become easier, as you are able to prey upon your disciples on occasion. The organization is young and fluid, but it will grow and take shape in time.
					*if charm > 3
						*set stlouis_cult_power %+10
						Your supernatural charm is able to sway those who would resist or disprove your divine nature.
					*if creation > 1
						*set stlouis_cult_power %+10
						Your artistic talents also contribute to the development of the cult. The artful arrangement of props—candles, incense, etc—leaves the worshippers in awe.
						*if stlouis_enterprise = 2
							*set stlouis_cult_power %+10
							The tendrils reach even further, wrapping themselves around the criminal element that you have been cultivating in the city.
					*if (stlouis_enterprise = 2) and (creation <= 1)
						*set stlouis_cult_power %+10
						Due to your involvement in their affairs, the criminal element of the city quickly falls under the sway of the cult.
					*if exodusters
						*set stlouis_cult_power %+10
						The refugees from downriver—seeking purpose now that their journey has been interrupted—are particularly susceptible to your call.
					*if stlouis_enterprise = 8
						*set stlouis_cult_power %+10
						Unsurprisingly, the First Spiritual Society of St. Louis becomes a fruitful hunting ground for you. Those already inclined to look beyond the accepted customs of society are only too eager to lend their ear to your honeyed words.
					*if (spencer_sister_status = 7)
						*set stlouis_cult_power %+5
						Even the Spencer sisters help in small ways, sending certain lost souls in your direction.
					
					Your new followers will multiply. And with them, your power.
					*goto 1879_court
			*else
				#The humans should worship me; I can use them to further my own schemes.
					*set rationalism %-20
					*set discretion %+20
					*set compassion %+10
					*goto cult_founded
			#Worship me? I am cursed by @{(religious_tradition = "pagan") Hushtahli|God}. I push the very thought from my mind.
				*set rationalism %+25
				*set compassion %-25
				*goto second_check
			#The Rule of Reserve exists for a reason. I will obey it.
				*set independence %+20
				*set discretion %-10
				They do say that discretion is the better part of valor.
				*page_break
				*label second_check
				*if (rationalism > 50) and ((religious_tradition != "pagan") and (compassion < 45))
					As vampires age, they sometimes return to the faith of their mortal lives as a source of comfort. Are you such a vampire?
					*goto church
				*elseif knows_about_vegetarianism
					*goto maybe_veg
				*elseif (stlouis_enterprise = 3) or ((finance > 1) or ((technology > 1) or (anachronism > 85)))
					*goto utopianists
				*else
					*goto blavatsky
	*else
		You have no delusions about your own divinity, but that does not mean that others would not acknowledge it. It would be a small thing to encourage your worship. Besides, the Rule of Reserve has kept you and your peers hiding in the dark for so long. Is it truly necessary?
		*goto cult_choice
*elseif (rationalism > 50) and ((religious_tradition != "pagan") and (compassion < 55))
	The religious fervor of the migrants has caught the imagination of the city and that fever has spread to you. Inbetween your other activities, you find yourself contemplating your relationship with your faith. Decades have now passed since your death and rebirth. Have you considered reconciling yourself with the Supreme Being?
	*label church
	*if religious_tradition = "pagan"
		*bug
	*choice
		#My faith has never wavered.
			*set anachronism %-5
			*goto church_var_set
		#Yes, I have sought the peace of religious faith.
			*set rationalism %+20
			*label church_var_set
			*set inside_church true
			*if religious_tradition = "reformed"
				*set stlouis_priest "pastor"
				*set stlouis_cathedral "church"
				*set stlouis_the_cathedral "a church"
				*set stlouis_mass "service"
				*set oshaun "Pastor Michaels"
			*goto religious_discussion
		#No, I will not defile the holy places with my footsteps.
			*set rationalism %+20
			*if religious_tradition = "reformed"
				*set stlouis_priest "pastor"
				*set stlouis_cathedral "church"
				*set stlouis_the_cathedral "a church"
				*set stlouis_mass "service"
				*set oshaun "Pastor Michaels"
			You may not set foot inside the holy places, but you clearly yearn to. You spend nights outside of ${stlouis_the_cathedral}, enough that a ${stlouis_priest} takes note of you. He introduces himself as ${oshaun} and invites you inside. To your relief, something in your declination compels him to press the matter.
			*goto religious_discussion
		*if heresy_of_abraham > 0
			#Now that I know of the Heresy of Abraham, my faith turns to greater things than mortal concerns.
				*set compassion %+10
				Progress in this quest is, of course, slow and difficult. However, you hope to take up your studies again soon.
				*goto veg_check
		#No, God plays no role in my life.
			*goto blavatsky
		*if knows_about_vegetarianism and ((feeding_style != "vegetarian") and (compassion < 40))
			*if (willpower > 3) #Before I can ask God to forgive me, I must stop sinning. To do that, I must cease drinking the blood of humans.
				*goto convert_to_vegetarianism
*elseif knows_about_vegetarianism and ((feeding_style != "vegetarian") and (compassion < 40))
	*label maybe_veg
	As vampires age, they sometimes reevaluate their decisions. You have learned of the possibility that vampires can survive without drinking from humans. Do you feel the need to pursue such a course?
	*choice
		*if (willpower > 3) #Yes, I will endeavor to stop drinking the blood of humans.
			*label convert_to_vegetarianism
			*set skip_hunting_check true
			*set compassion %-20
			It is with great determination and not a few missteps that you begin to wean yourself from human blood.
			
			The blood of animals—rats, cows, horses, pigs—is too thick or too thin. It tastes of waste and short-sightedness. For months, you are weak from the lack of sustenance, as you find yourself vomiting your dinner at the most inopportune times.
			*label veg_check
			*if (stlouis_enterprise = 3) or ((technology > 1) or (anachronism > 85))
				*page_break
				*goto utopianists
			*else
				*goto 1879_court
		#What is the point of being a vampire if one does not drink the blood of humans?
			*set compassion %+10
			*if perception > 1
				The blood is the source of most of your enjoyment of eternity. The smells, the taste…the way it rolls across your tongue and into your gullet. To abstain is madness.
				*goto veg_check
			*else
				Blood is blood is blood. You exist, and you must feed. Why question that?
				*goto veg_check
		#I am not yet ready to abstain from human blood.
			*set compassion %-10
			Perhaps some night you will find a higher path. Tonight is not yet that night.
			*goto veg_check
*elseif (stlouis_enterprise = 3) or ((finance > 0) or ((technology > 1) or (anachronism > 85)))
	*label utopianists
	Due to your efforts to penetrate certain elements of St. Louis society, tonight you find yourself in the company of a society of @{(ethnicity = "german") German |}intellectuals and businessmen interested in the future of society and the nation. They regularly address speeches to each other and then discuss the merits of their arguments. The gathering consists almost entirely of men, but a handful of women are in attendance as well.
	
	Tonight, a man by the name of Olbers has discussed the abolition of private property, with the aim of collectivising and sharing the gains of a nation. Many of the individuals in the room nod in agreement, though others voice their objections. The names of Rousseau, Fourier, and Marx are mentioned frequently.
	
	At a certain moment, you find the oppotunity to speak to the gathering.
	
	*choice
		*if religious_tradition = "reformed"
			#I make an intellectual argument that, without the evidence of success, how would we know who is righteous?
				*set rationalism %+10
				Take a page from Calvin and his intellectual heirs, you make an argument about success being a sign of election.
				*if (intelligence + lore) >= 5
					*set local_fame %+10
					*set stlouis_business_climate %+10
					The gathering seems taken by the intellectual rigor of your position. They ask for more details, and it is only dawn that draws you away from their company.
				*else
					*set local_fame %-10
					
					They listen to you politely, but when given the opportunity to interject, another attendee does so. 
					*if perception > 1
						More than one person rolls their eyes in relief.
					The conversation quickly moves on from spiritual matters.
					
					You do not stay much longer.
		#I argue against the idea of socialization. Capital and free markets will find utopia for us.
			*set compassion %+10
			Based upon statistical models as well as appeals to philosophy, you make a substantive argument for the right of capital to regulate itself. It will identify its own best use, and that best use will be the best for the nation.
			*if (finance > 1) and (intelligence > 1)
				*set stlouis_business_climate %+15
				*set local_fame %+10
				
				The gathering seems resistant to your argument—they are more inclined to a collectivist utopia—but you sense that your words have not fallen on entirely deaf ears.
				
				Several of the merchants in the room, for example, gather close once the official dialogue is over for the evening. 
				*label bad_argument_success
				You sense that they seek to bask in the glory of your success.
				
				When you feel the itch of the dawn in your veins, you make your excuses and set out for home.
			*else
				*set stlouis_business_climate %-10
				*label fail_argument
				*set local_fame %-10
					
				They listen to you politely, but when given the opportunity to interject, another attendee does so. 
				*if perception > 1
					More than one person rolls their eyes in relief.
				From there, the conversation quickly moves on to other things, and you are not inclined to try and insert yourself again.
				
				You do not stay much longer.
		#@{exodusters Due to its effects on wages, I argue for racial and gender integration of the workforce, pointing to the effect of the recent migrants from Louisiana on the city.|Based on its effects on wages, I argue for the racial and gender integration of the workforce.}
			*set compassion %+10
			*set shepherd_credentials %+10
			Your argument turns on the fact that having a larger pool of potential workers will erode the workers' ability to demand higher wages, thus lowering manufacturing costs.
			*if exodusters
				You point to the already-perceptible effects from the decision by the migrants to put down roots here.
			*if (finance > 1) and (intelligence > 1)
				*set stlouis_business_climate %+10
				*set local_fame %+10
				*set stlouis_race_relations %-10
				*set push_for_desegregation %+5
				
				The attendees—largely ethical collectivists—seem discomfited by your utilitarian approach. A significant portion of them are feminists, abolitionists, or both, and your indifference to the suffering your proposals would cause conflicts with their eagerness for the effect of your conclusions. @{(ethnicity = "african") The color of your skin only further contributes to their confusion.|}
				
				Regardless, some of the merchants in the room seem intrigued by your proposals and a small circle gathers around you once the official dialogue of the evening is concluded.
				*goto bad_argument_success
			*else
				*set local_fame %-10
				*comment yes, that's supposed to be a double hit to local_fame.
				*goto fail_argument
		*if technology > 0
			#Based on my understanding of technological advacements, I make an argument for the eventual automation of labor. It may not affect life today, but it might impress them.
				*set anachronism %+5
				Marx makes an argument that man—after the revolution—will be free to labor when and how he wishes. Pointing to the invention of the arithometer, the railroad, and the rapid spread of gas lighting through the nation, you opine that eventually, man will be free to not labor, should he so choose.
				
				The question is whether or not the benefits are shared—as argued for by the majority of the gathered—or whether those benefits will accrue to those who own those means of production.
				*if (technology + charm) >= 5
					*set local_fame %+30
					
					When you finish, the room bursts into an uproar. People shout at each other, gesticulating wildly. Two men have to be forcibly separated before they devolve into fisticuffs.
					
					It seems your words had their desired effect.
				*else
					*set local_fame %-10
					*goto fail_argument
		*if (religious_tradition != "pagan") and (rationalism > 50)
			#I argue for a Christian version of this utopia.
				*set rationalism %+10
				*set compassion %-10
				You suspect that some of the attendees in the room are atheists, but you pay them no mind. Instead, you focus on the teachings of Jesus and his rejection of earthly trappings.
				*if (intelligence + (charm + lore)) >= 7
					*set local_fame %+10
					*set stlouis_business_climate %-10
					You soon see several in the room nodding along. By the time you are finished, you seem to have made quite an argument for compassion and mutual aid.
					
					You are right that the atheists do not approve of arguing from Scripture, but they cannot argue with your conclusions.
					
					Once the official dialogue of the evening is concluded, you find yourself surrounded by various individuals wanting to discuss your ideas for the future of the city. It is only when you feel the blood begin to sing in your veins that you excuse yourself and make your way home.
				*else
					*goto fail_argument
*elseif (stlouis_enterprise = 7) or (technology > 0)
	The men of science at Washington University are a peculiar bunch: studious during the day and with beer-fueled conviviality during the evening. The affection for beer comes naturally to them, as there are many Germans among them—like many of the other German immigrants to St. Louis, these are individuals who have fled the Kaiser's grasp. This is all very convenient for you, though, as you are able to pass among them without too many questions or raised eyebrows.
	
	Tonight, the subject seems to have again turned to the matter of evolution. The room is fully aware of Darwin's theories, but the practical effects of those theories comes under constant scrutiny.
	*comment if I felt like I could do it, this would be a discussion about asinine theories of the hierarchy of races.
	
	One man of science argues from behind his massive white beard that Darwin's professions of faith were simply lies to keep him from the pyre; that he was an atheist and cannot therefore be trusted. Another argues that Darwin's faith has no bearing on his observations. Yet a third seems to want to focus on the flaws in Darwin's claims, such as they are: what are the origins of what can only be described as errors in evolution?
	*choice
		*if (false) #todo
			*comment TODO connect to Monsanto plot
		#I opine on the theory of germs and how it intersects with the theory of evolution.
			*if ((intelligence + lore) + technology) >= 7
				*set tuberculosis_vaccine +1
				*set anachronism %+5
				*set stl_met_cousins true
				Dr. Cousins, one of the men of science, is intrigued by your proposition. The Ancient Greek philosopher Galen proposed the theory of germs, yes, but only recently have men of science begun to seriously put aside the miasma theory in favor of something more precise. @{((knows_pb_diseased > 1) and (rationalism < 60)) You offer your own recent observations from the Yellow Fever outbreak in Memphis as evidence.|}
				
				You can see the wheels turning in his head. He promises to pursue your idea to its fullest.				
			*else
				*set exposure +1
				Unfortunately, you do not have much to offer on the matter. You grasp of both the theory of evolution and the theory of germs is rudimentary, and you are baffled by the first questions posed to you.
				
				You can sense the confusion behind the eyes of these men of science, wondering who exactly you are and how you gained entry to their circle. You decide to remain mum for the rest of the evening.
		#The objective here is to make my mark upon these intellectuals. I argue with sophistry so that they will not forget me.
			*set discretion %+5
			You stand and offer your opinion on the debate, drawing on several threads in the conversation to synthesize an innovative and unanticipated solution.
			
			*if (technology + (intelligence + (charm + lore))) >= 8
				*set local_fame %+15
				While your conclusions may be hogwash, they are delivered in the trappings of fact, allusion, and appeals to authority, such that your audience is suitably impressed. One man of science even proposes an experiment to test your hypothesis.
				
				You never hear what comes of the experiment, nor do you care. But your objective has been met.
			*else
				*set local_fame %+5
				*set exposure +2
				They will remember your name, yes, but not because they were impressed by your words. Rather, they will wonder how you were ever admitted to their circle.
				
				You decide to remain mum for the rest of the evening.
		*selectable_if (choice_randomtest = false) #I only listen as much as is necessary to be ignored. I am here to feed and to manipulate, not to debate the nature of the universe.
			*set anachronism %-5
			*set shepherd_credentials %-5
			*set independence %+5
			Thankfully, the gathered men are only too happy to speak at length without any input from you. They seem suitably impressed with your intense interest in their theories and experiments; you have long since mastered the art of smiling and nodding while fantasizing about the taste of your interlocutor's blood.
*else
	*label blavatsky
	In 1877, a Russian [i]émigrée[/i] by the name of Madame Blavatsky publishes a book on ancient wisdom that she had divined through the wide course of her travels—most notably to Tibet—and through her extensive reading of religious and historical texts from a multitude of traditions. The book is titled [i]Isis Unveiled[/i] and purports to explore the secret principles that underpin all human religious experience.
	
	The teachings of the book also codify the teachings of her Theosophical Society, which she founded in 1875 with several American occultists. With the publication of the book and a lecture, Blavatsky draws many adherents to her vision. She advocates for equality of the sexes and races, as well as recommending celibacy, abstinence from alcohol and tobacco, and vegetarianism as necessary steps on the path to enlightenment. While she believes in the Spiritualism movement, she asserts that most spiritualists and mediums are frauds, and that the real ones are mistaken—they do not communicate with the dead, [i]per se,[/i] but merely with the "shells" of the dead at best, and frequently malevolent or merely mischievious spirits at worst.
	
	Earlier this year, however, Blavatsky and her immediate entourage adjourned to Madras, India, leaving her American students to study her works and converse with her via post.
	
	The most prominent students of Blavatsky in St. Louis are a pair of friends by the names of Elliott Page and William Kelsoe. Page and Kelsoe have organized a regular meeting at their home for the study of [i]Isis Unveiled[/i] as well as other works by Blavatsky.
	
	*choice
		#The more people believe in the supernatural, the easier it will be to explain away violations of the Rule of Reserve.
			*set exposure -1
			*set rationalism %-5
			*set shepherd_credentials %+3
			*if wealth > 250000
				*set wealth -50000
				*set exposure -1
				You donate a tidy sum of money to Page and Kelsoe, freeing them up to devote themselves to advocacy.
			*else
				Whenever you can, you direct pliable individuals towards Page and Kelsoe.
			The two occultists establish themselves as some of the leading spiritualists in the
			*if stlouis_enterprise = 8
				city, alongside 
				*if (spencer_sister_status > 1) and (spencer_sister_status != 6)
					the Spencer sisters and
				Joseph Brown and the First Spiritual Society.
			*elseif (spencer_sister_status > 1) and (spencer_sister_status != 6)
				city, alongside the Spencer sisters.
			*else
				city.

			In the near future, Page and Kelsoe will be granted the first charter for a lodge of the Theosophical Society in the United States. Within five years, there will be another dozen lodges scattered through the country, with more in Canada and Mexico.
		*selectable_if (income > 20) #The equality of the sexes and races? That seems like a worthy cause. I will donate some investments to help Page and Kelsoe amplify their message.
			*set stlouis_race_relations %+5
			*set missouri_prohibition +1
			*set income -3
			*set shepherd_credentials %+3
			Page and Kelsoe are thrilled with your donation to their nascent society. They immediately set out working towards sharing the vision of Madame Blavatsky with St. Louis.
			
			In the near future, Page and Kelsoe will be granted the first charter for a lodge of the Theosophical Society in the United States. Within five years, there will be another dozen lodges scattered through the country, with more in Canada and Mexico.
		*if (false and (heresy_of_masons > 0)) #TODO Something about the Masonic lodge in St. Louis.
		*selectable_if (literate) #I study [i]Isis Unveiled[/i] myself.
			*set rationalism %+5
			@{(intelligence > 2) Blavatsky is extremely well-read, though that evinces itself in a curious way; she frequently quotes or paraphrases the words and thoughts of others, yet without framing those statements as originating elsewhere.|You find the reading engaging and evocative. She seems to pluck thoughts and phrases out of the air and express them in words in ways that seem both novel and obvious.}
			
			Most interesting of all, however, is her ruminations on the condition of death and reincarnation. She spends one whole chapter on the idea of bodies that die but where the so-called "shell" refuses to vacate the body, instead feasting on negative energy to perpetuate its ongoing presence in the world.
			
			Has she somehow divined the nature of vampiredom? @{(intelligence > 2) Or has she merely sifted through enough religious and philosophical texts that your kinds' existence has become self-evident?|} Is she a danger to you and yours?
			
			In the near future, Page and Kelsoe will be granted the first charter for a lodge of the Theosophical Society in the United States. Within five years, there will be another dozen lodges scattered through the country, with more in Canada and Mexico.
		*if (stlouis_enterprise = 8) #Joseph Brown and the First Spiritual Society are philosophically adrift; they should study Blavatsky's texts.
			*set shepherd_credentials %+3
			You make the introduction between Brown on the one hand and Page and Kelsoe on the other. Brown is extremely reluctant to let go of the idea that spirits of the dead are not, in fact, the entities that he has been communicating with through mediums. He is even more reluctant to stop having sex with his wife. However, within a few months, he has become a devoted student of Blavatsky. When Page obtains a charter for a lodge, Brown is the third name on the initiate list.
			
			Page's lodge is, in fact, the first Theosophical lodge in the United States. Within five years, another dozen have been organized in cities across the country.
		*if (spencer_sister_status = 8) #I want to point Page and Kelsoe towards the Spencer sisters and have them exposed as frauds.
			*set spencer_sister_status 6
			*set shepherd_credentials %+3
			Page and Kelsoe are aware of the Spencer sisters, and with a little encouragement are only too happy to expose them as the frauds they are.
			
			They develop a ruse between them, and before a crowd of witnesses, trap the sisters in an obvious lie. The crowd grows angry at the deception, vacillating between the sisters and the men. Finally, the sisters break and run, and Page and Kelsoe declare victory.
			
			In the near future, the two men will be granted the first charter for a lodge of the Theosophical Society in the United States. Within five years, there will be another dozen lodges scattered through the country, with more in Canada and Mexico. The fact that they exposed the Spencer sisters as frauds—a favorite pastime of Madame Blavatsky—serves to raise their profile within the larger Society.
		#The dead are dead—with the possible exception of vampires—and this organization is simply another fraud that holds no interest for me.
			*set shepherd_credentials %-5
			*set discretion %-5
			*set rationalism %-5
			In 1882, Page and Kelsoe are granted the first charter for a lodge in the United States. Within five years, there will be another dozen lodges scattered through the country, with more in Canada and Mexico. Whether you see them as frauds or not, a certain type of person hungers for the answers the Theosophical Society offers.
*goto 1879_court

*label religious_discussion
*if inside_church
	*if rationalism >= 70
		*set inside_church false
		While your may seek the peace of religious faith, the blood in your veins whistles a different tune.
		
		Seeking to step on holy ground, you find your knees incapable of rising. You reach out your hand, only to see it fall to your side.
		
		You try this on several nights—in relation to the phase of the moon, for example—to no improvement. These attempts, however, soon attract the attention of a ${stlouis_priest} by the name of ${oshaun}. He invites you to speak with him inside, and when you decline he promises to find another place that the two of you can speak.
		*page_break
		*goto church_arrangements
	*else
		You begin to frequent ${stlouis_the_cathedral}
		*if religious_tradition = "reformed"
			of your choice
		and find yourself welcomed there. You make the acquaintance of a ${stlouis_priest} by the name of ${oshaun}, and in time are invited to private counsel.
		
		He closes the door to his office and invites you to sit.
*else
	*label church_arrangements
	
	The ${stlouis_priest} arranges a quiet place to sit and talk in a home close to ${stlouis_the_cathedral}. He promises you that the hosts' discretion is assured.
*comment endif

The ${stlouis_priest} is not a small man, and he wheezes a bit with the exertion of movement. After the two of you are ensconced in your respective chairs, he invites you to unburden yourself.
*choice
	#I focus on speaking of my heavy heart, rather than confessing to any crimes.
		*set discretion %-15
		*set compassion %-15
		*set independence %+5
		*if charm >= 3
			By the time you are finished speaking, there are tears in the ${stlouis_priest}'s eyes. He places his hand over yours, offering words of sympathy and comfort, while simultaneously blowing his nose into a handkercher.
			*gosub unburdened
			*goto 1879_court
		*else
			The ${stlouis_priest} listens to your concerns dispassionately.
			*gosub unburdened
			*goto 1879_court
	#I confess to my crimes, without saying anything to violate the Rule of Reserve.
		*set compassion %-10
		*set discretion %+15
		*set independence %-5
		*set rationalism %+5
		*set partialconfession true
		
		Once you start speaking, it is difficult to stop the torrent of words. It's almost like all the blood that you have consumed over the decades is now being vomited back in the form of guilt-ridden admissions.
		*gosub unburdened
		*goto 1879_court
	#I confess it all.
		*gosub full_confession
		*goto 1879_court
		
		*label full_confession
		*set fullconfession true
		*set discretion %+25
		*set independence %-10
		*set rationalism %+15
		
		You begin slowly, but hold nothing back. At first the priest must think that you jest—he even stands to leave—but soon realizes you are deadly serious. His eyes widen with each new revelation. It's almost like all the blood that you have consumed over the decades is now being vomited back in the form of guilt-ridden admissions.
		*label unburdened
		
		It is nearly dawn when you are finished unburdening yourself; you can feel the sinister creep of the rising sun in your blood.
		
		*choice
			*if charm > 2
				*selectable_if (charm > 4) #I wipe his memory of the conversation.
					*set discretion %-30
					*set compassion %+5
					*set independence %+10
					With a great sadness, you compel him to forget the night's conversation. @{gonsoulin It is rare to meet someone who knew you when you were so youthful. Saying goodbye to that recognition wounds you to your core.|}
					
					As much of a relief as it was to share your burden, you can't help but wonder if it has only grown.
					*return
			*if perception > 2
				*selectable_if (perception > 3) #These chairs have an emotional history involving the good ${stlouis_priest}; given a few moments, maybe I can use that to silence him.
					*set discretion %-10
					*set compassion %+10
					*gosub sod_founder_check
					${oshaun} is guilty of some rather torrid indiscretions, indiscretions that began in this very chair. Standing, you turn to get a better look at the chair—at its history.
					
					Already terrified of you, his ruddy face goes pale when you disclose your discoveries. You suspect that he will carry your secrets to the grave.
					*return
			#I kill him. Better safe than sorry.
				*set compassion %+25
				*set discretion %+15
				*set exposure +1
				He is not anticipating violence and 
				*if rationalism < 70
					you give him no opportunity to avoid it. You sink your teeth into his @{gonsoulin withered|flabby} neck and drink your fill. @{(feeding_style = "clergy") |It's not your prefered cuisine, but there's no sense in letting it go to waste.}
					
					Of course, disposing of a body—and the body of a clergyman at that!—is no small feat. 
					*if discretion > 55
						*if stlouis_valet_motivation != 1
							*set stlouis_valet_loyalty %-15
						Thankfully, that is why you employ ${stlouis_valet}.
						
						You entrust the ${stlouis_priest} to ${stlouis_valet}'s care and saunter home.
						*return
					*else
						You decide to play the pity card and yell out for aid. You've already licked away the evidence of your crime—both the wounds and his blood—and prepare to stage a scene of despair.
						
						*if (inside_church = false) and (gonsoulin)
							*if stealth < 4
								*set exposure +1
							The saloonkeeper rushes over to investigate—always attentive to the presence of Father Gonsoulin. He is distraught to find the priest sitting rigidly, a look of horror on his face.
							
							"What did you say to him?" the saloonkeeper demands.
							
							"Nothing! I said nothing!" you exclaim.
							
							"I'm going…" You don't give the man the opportunity to finish the thought; you rise and walk out the front door. "Wait! Police!" he yells after you.
							*return
						*else
							A young man appears at the door, stopping when he sees you over the body of ${oshaun}.
							*if (charm > 3)
								You explain the matter very convincingly, as well as why it is absolutely necessary for you to leave right now. The young man nods in agreement and calls for the coroner.
								*return
							*elseif (stealth > 3)
								You offer a half-hearted explanation, but having taking the face of someone else, you are not particularly concerned if he believes you. When he leaves the room to fetch the police, you beat a retreat, confident that you will not be recognized.
								*return
							*else
								*set exposure +2
								It is difficult to explain why you must depart from the side of a dead ${stlouis_priest} with such haste, but the sun is rising. You leave your calling card and offer to appear at any inquest. Thankfully, the young man takes you at your word.
								
								Over the next few weeks, the matter becomes much more complicated than you had intended. However, the absence of any signs of foul play and the general health of the deceased result in the coroner ascribing the passing to natural causes.
								*return
				*else
					*set exposure +3
					*gosub sod_founder_check
					you intend to give him no opportunity to avoid it. You open your mouth wide and your teeth extend in a flash of hunger and cruelty. As you move in for the kill, however, you find yourself rebuffed by some invisible force. Though absolutely terrified, ${oshaun} senses your weakness. He grasps his @{(religious_tradition = "reformed") cross|crucifix} and brandishes it at you.
					
					You scream in pain.
					*if disguised
						Unable to maintain your concentration through the agony, your disguise falls away, only adding to the ${stlouis_priest}'s confusion.
					Finally, you make a break for it. Thankfully, the privacy of your confession meant that no one is present to hinder your escape.
					
					You disappear into the night, fleeing the power of the divine.
					*page_break
					Though you bear no physical injuries, you spend the next few nights tending your wounded pride. You comfort yourself with the thought that surely no one will believe the wild stories of a beast with a @{male man|woman}'s face.
					
					So you hope.
					*return
			#I bid him goodnight and leave.
				*label goodbye
				*if fullconfession
					*gosub sod_founder_check
					*if disguised = false
						*set exposure +3
						*set local_fame %+10
					*set discretion %+30
					*set independence %-30
					Really, who would believe him anyway?
					
					He looks to be in shock, in fact. His eyes are wide, and if you didn't know better, you'd think his hair was notably whiter than then night before.
					
					With a smile and a ${bow}, you take your leave.
					*goto 1879_court
				*elseif partialconfession
					*if disguised = false
						*set exposure +1
					*if religious_tradition = "catholic"
						Before you leave, he pronounces a penance and absolves you of your sins. You bow your head in submission.
						
						It has been so long since you felt the sensation of hope that you don't recognize it at first. Upon further reflection, however, you cannot deny the elevation of your spirits.
						*return
					*else
						${oshaun} offers a few words of advice about how you might better conduct yourself in the future, words which you mostly wave away. Your conduct is unlikely to change anytime soon.
						
						All the same, the act of speaking has lightened your spirits somewhat. Your sleep that day is the most untroubled that you've had in decades.
						*return
				*else
					*set compassion %+10
					${oshaun} seems almost relieved when you stand to leave.
					
					You thank him for his time and set out for home. In the early morning quiet, you wonder what good can come from honest counsel when one is unwilling to speak the truth.
					*return
			*if stealth > 2
				*selectable_if (stealth > 3) #It's fortunate that I've disguised my visage through this entire conversation.
					*set disguised true
					*return
	*if feeding_style = "clergy"
		#I confess, I just wanted a moment alone to feed on a ${stlouis_priest}.
			*set compassion %+10
			*set exposure +1
			*set skip_hunting_check true
			@{(perception > 1) You do love the [i]terroir[/i] of an overstuffed cleric.|}
			
			When you are finished, you wipe ${oshaun}'s blood onto a handkercher and toss it into the hearth. It takes a moment, but eventually it begins to smoulder and finally ignites.
			
			You watch it burn.
			*goto 1879_court

*label 1879_court
*if (renter = false)
	*page_break
	About this time, ${stlouis_valet} comes to you on behalf of ${valet_his} nephew, Thomas.
	
	Thomas was wounded @{(ethnicity = "choctaw") in a construction accident|fighting on the frontier against the Cheyenne}. He's in need of a job, and has talents as a gardener and handyman. Your haven does need regular upkeep, and ${stlouis_valet} is already overworked with ${valet_his} other duties on your behalf.
	
	You assent. @{(discretion > 50) After all, you don't really care to spend your nights managing the upkeep of your home. Better to have someone tasked with that.|You conclude that it is probably better to have one person skulking about the property than a rotating cast.} ${stlouis_valet} thanks you repeatedly for your compassion.
	*set stlouis_valet_loyalty %+5
	
	That said, Thomas certainly has his cycles. Some evenings he is lethargic and withdrawn. Other evenings he is gregarious and focused. Still others, irritable and caustic. And while he is paid a reasonable wage for his efforts, his clothes and tools never seem to improve.
*page_break
The flow of migrants slows—but does not entirely stop—as the spring and summer wheel by. As fall approaches, the newspapers begin to tire of the matter, and return to politics and other scandalous affairs. In particular, in even more breathless fashion than the prior year, they begin speculating on the upcoming Veiled Prophet Parade. Not one to disappoint, the Veiled Prophet Society sets about organizing a second outing to once again conclude Fair Week. The articles trumpet the ascendant success of the United States and the key role that St. Louis plays in that.

As with last year, a gathering is arranged to coincide with the beginning of the Fair Week. You receive word that the affair will be held at Schnaider's once again.
*temp common_lang 1
*if speaks_english = false
	*if speaks_french
		*set common_lang 2
	*elseif speaks_german
		*set common_lang 3
	*else
		*set common_lang 4

You enter the private room where the vampires can speak unguardedly. You are immediately struck by the presence of a woman—Sabine Bécard, you presume—deep in conversation with Eliot.
*if met_partridge
	Senator Partridge is here as well. As is his custom, he sits beside Senator Bailey, hands entwined.
*elseif heard_of_partridge
	Senator Bailey sits besides someone you do not recognize but whom you presume to be Senator Samson Partridge of Louisville; their hands are entwined in a comfortable intimacy.
*else
	Senator Bailey and another vampire sit together in comfortable intimacy.
The two speak animatedly with Lothar.

*if (met_partridge = false)
	Noticing your arrival, Bailey formally introduces you to @{heard_of_partridge Partridge|Samson Partridge, Senator of Louisville}, who shakes your hand with a firm grip. He is of average height, with brown hair and a close-cropped beard, and—a born orator—his voice booms when he speaks, regardless of any effort to the contrary.
	*if memphis_bailey_couldnt_communicate and (speaks_english = false)
		You are relieved to discover that he has learnt @{common_lang ERROR|French|German|Spanish} since last you bumped into one another.
	
	The two of you exchange a few pleasantries, before you are interrupted by Eliot.
*if met_partridge
	"A pleasure to see you again, Senator," you say by way of greeting.
	
	*if trans
		*set partridge_rapport %+5
		*set bailey_rapport %+10
		Partridge looks at you blankly. "I'm sorry…" he begins, before Bailey leans over and whispers in his ear.

		"Yes, I don't believe we've been reintroduced," Bailey says.

		"You may call me ${given_name} ${surname}," you reply.

		"A pleasure, ${mr} ${surname}," Bailey says with a smile. Turning slightly: "Lothar."

		"[i]Ja,[/i]" Aichinger responds.

		"Won't you welcome ${given_name} ${surname}?"

		Aichinger scowls in your direction. "[i]Ach was auch immer.[/i]"
		*set aichinger_rapport %-5

	*else
		@{(partridge_rapport > 45) "And you, ${mr} ${surname}!" he replies warmly.|"Good evening," he replies coldly.}
		
	It is at this moment that Eliot interjects.
"${given_name}, come meet Sabine!"
*set heard_of_partridge true
*set met_partridge true

You excuse yourself from the Senators and approach Eliot and Bécard. She has high cheekbones and a round face, a somewhat peculiar mix indicative of what you soon learn to be her French and Miami heritage, and her hair is kept in two tight braids that reach down almost to her waist. 
*if ethnicity = "choctaw"
	*set becard_rapport %+15
	She smiles at you and extends her hand. Without hesitation, you extend your own and clasp them in greeting.
	
	"A real pleasure to meet you," she says.
	*temp uncle "uncle"
	*if male = false
		*set uncle "aunt"
	*if m_sib
		*set becard_rapport %+5
		"Should I call you ${uncle}?"
		
		"No, that's quite alright," you reply with a smile.
*else
	You move to ${bow} in greeting, but she interrupts you by extending her hand. After the briefest hesitation, you extend yours, and she shakes it once with vigor.
	
	"Good evening," she says.
	*if m_sib
		*set becard_rapport %+5
		"It is good to meet another member of our lineage."

"Sabine was just catching me up on the news from Jefferson City. The current legislature is a nightmare."

"I suppose it is less of a disaster than the Senate," she says [i]sotto voce[/i]. "But I cannot argue with your conclusion," she finishes at a normal volume. @{(perception > 2) You sense that Bailey caught her remark, but apparently found no reason to pursue the matter.|}

Before you can engage further, you realize that Memeskia has arrived. His ability to enter and leave a room without noise or fanfare
*if m_sib
	reminds you of your maker.
*elseif sire_name = "Wallace Winters"
	has an uncanny familiarity—both like and not like the way your dominus did the same.
*else
	is rather disconcerting.
As the recognition of his arrival skips from vampire to vampire, they turn to hear what he has to say.

*if trans
	He looks at you and sees you, as though for the first time. He nods, as if to say, "very well," but does not waste effort on the words.
*else
	@{m_sib You see him notice you in conversation with Sabine. He nods, as if to say, "I am glad to see the family acquainting itself," but does not waste effort on the words.|} 
"Are there matters that need discussion?" Memeskia proffers.

"The freedmen from Louisiana and Mississippi, Quaestor…" Aichinger begins.

@{exodusters "Some have decided to stay. The rest are continuing on their way.|"Many have already left to continue on their journey. Their community has rallied to support them.} What more needs to be said?"

Aichinger looks a little flustered. "But Quaestor, Quaestors ${new_orleans_quaestor_surname}, Harding, and Withers have all three asked that we return them to their homes. Their departure from their plantations has caused quite the disruption.…"

"Their problems are not my concern. What else?" Memeskia demands.

"There are rumors that we will have a new governor soon, Quaestor," begins Bailey. Partridge opens his mouth to finish the thought, but apparently thinks the better of it. "I believe that we will be assigned to a new province."

"Chicago?"

"It is unclear, Quaestor."
*temp lockridge false

"What else?" Apparently, the matter of a new governor needs no further discussion. When no one else volunteers, Memeskia nods his head and departs with alacrity.

"I'm glad I came all the way from Louisville for that," Partridge quips.

@{(perception > 2) "I hope that's not all you came for," Bailey retorts quietly.|}
*temp redecide_haven false
*temp debt_from_none false
*gosub_scene prestation checkHasDebt
*if lore <= 2
	*if (stlouis_haven = "dutchtown") or ((stlouis_haven = "soulard") or (stlouis_haven = "lafayette"))
	
		*if invitation_to_st_louis = "lockridge"
			*set lockridge true
			*set lockridge_rapport %-25
			*if revolutionary_credentials < 44
				*set revolutionary_credentials %+10
			*if revolutionary_credentials < 35
				*set revolutionary_credentials %+10
			*if revolutionary_credentials > 60
				*set revolutionary_credentials %-10
			"${mr_german} ${surname}," Aichinger says a few minutes later.
			
			"Yes?"
			
			"There are two matters to discuss."
			
			"Oh?"
			
			"You are living in my territory."
			
			"I am?"
			
			"You have taken up residence in 
			*if stlouis_haven = "dutchtown"
				Dutchtown,
			*elseif stlouis_haven = "soulard"
				Soulard,
			*elseif stlouis_haven = "lafayette"
				Lafayette Square,
			have you not?"
			
			You grimace.
			
			"Do not fear. I received @{speaks_german a letter|[i]ein Brief[/i]} from Senator Lockridge. I am certain that he will be disappointed to know that his intervention was necessary, but he suggested that I make you feel welcome here. Consider yourself welcomed."
			
			"Thank you, Herr Aichinger. I feel most welcome."
			
			"[i]Gut.[/i]"
		*else
			
			"There is, in fact, something else that needs to be discussed," Aichinger interrupts.
			
			"Oh?" Partridge inquires.
			
			"Yes. I believe a debt is owed."
			
			"Do tell!" Partridge exclaims.
			
			"${mr} ${surname} here has taken up residence in 
			*if stlouis_haven = "dutchtown"
				Dutchtown.
			*elseif stlouis_haven = "soulard"
				Soulard.
			*elseif stlouis_haven = "lafayette"
				Lafayette Square.
			As this is my territory—and ${he} did so without my permission!—I demand that a debt be acknowledged."
			
			Bailey evinces a pretend-shocked face. "Is this true, ${mr} ${surname}?"
			
			You clench your teeth. "So it is."
			
			"Well, as I see it, you have two options. You can acknowledge the debt…or you can remove yourself from the neighborhood immediately." @{(renter = false) The implication here is that you will need to have a firesale of your haven.|}
			*label aichinger_prestation_loop
			*choice
				#I acknowledge the debt to Aichinger.
					*set independence %+5
					*set debt_to_aichinger true
					"Splendid!" Bailey exclaims. Even Aichinger chuffs happily.
				*if (hasAnyDebt) #I offer to trade him a debt I hold over another instead.
					Considering the debts that are owed to you, you decide to trade Aichinger…
					*gosub_scene prestation findDebt
					*if getVar = "none"
						*goto aichinger_prestation_loop
					*else
						*set debt_from[getVar] false
						Aichinger happily accepts the debt from $!{getVar} in exchange for the right to reside in his territory.
				#I refuse the debt—I will relocate my haven forthwith.
					*set independence %-5
					*set bailey_rapport %-10
					*set aichinger_rapport %-10
					*set eliot_rapport %-5
					*temp haven_halved round(haven_value / 2)
					"So be it," Bailey replies.
					
					*if renter = false
						"I will offer you $${haven_halved} for your property," Aichinger observes. "But you must be out by tomorrow evening either way."
						
						Hearing no better offer, you accept Aichinger's proposition.
						*set haven_value 0
						*set wealth +haven_halved
					
					"Where can I reside that will not incur a debt?" you growl.
					
					"Across the river, in East St. Louis, is unclaimed," Bailey replies sweetly.
					
					"And the Kerry Patch is free territory," Eliot chimes in.
					*set redecide_haven true
					
					"Thank you, gentlemen," you reply.
	*elseif (stlouis_haven = "midtown") or ((stlouis_haven = "downtown") or (stlouis_haven = "chestnut"))
		"Oh, I nearly forgot!" Bailey declares excitedly.
		
		"What now?" Aichinger moans.
		
		"I simply wanted everyone to know that ${mr} ${surname} here owes me a debt."
		
		No one is as surprised by this as you. "A debt, Senator?"
		*comment TODO if invitation_to_stl = lockridge, have Aichinger interrupt/intercede?
		
		"You have taken up residence in
		*if stlouis_haven = "midtown"
			Midtown
		*elseif stlouis_haven = "downtown"
			Downtown
		*elseif stlouis_haven = "chestnut"
			Chestnut Valley
		without obtaining my permission, have you not?"
		
		"That is true, yes."
		
		"@{debt_from_bailey Do you forgive the debt I owe to you?|Then, do you acknowledge the debt?} Or will you vacate your haven and abandon your property by the second sunrise?"
		*label bailey_prestation_loop
		
		*choice
			#@{debt_from_bailey I absolve Bailey of the debt I hold over him.|I acknowledge the debt to Bailey.}
				*set independence %+5
				*if debt_from_bailey
					*set debt_from_bailey false
				*else
					*set debt_to_bailey true
				"Splendid!" Bailey exclaims. Even Aichinger chuffs happily.
			*if (hasAnyDebt and (debt_from_bailey = false)) #I offer to trade him a debt I hold over another instead.
				Considering the debts that are owed to you, you decide to trade Bailey…
				*gosub_scene prestation findDebt
				*if getVar = "none"
					*goto bailey_prestation_loop
				*else
					*set debt_from[getVar] false
					Bailey happily accepts the debt from $!{getVar} in exchange for the right to reside in his territory.
			#I refuse the debt—I will relocate my haven forthwith.
				*set independence %-5
				*set bailey_rapport %-10
				*set aichinger_rapport %-10
				*set eliot_rapport %-5
				*temp haven_halved round(haven_value / 2)
				"So be it," Bailey replies.
				*if renter = false
					*set haven_value 0
					*set wealth +haven_halved
					"I will offer you $${haven_halved} for your property," he continues. "But as stated, you must vacate it by the second sunrise."
					
					Hearing no better offer, you accept Bailey's proposition.
				
				"Where can I reside that will not incur a debt?" you growl.
				
				"Across the river, in East St. Louis, is unclaimed," Bailey replies sweetly.
				
				"And the Kerry Patch is free territory," Eliot chimes in.
				*set redecide_haven true
				
				"Thank you, gentlemen," you reply.

*if (lockridge = false) and (invitation_to_st_louis = "lockridge")
	"${mr_german} ${surname}?" Aichinger begins.
	
	"Yes?"
	
	"You should know that I received a letter from my dear friend Senator Lockridge."
	
	"Oh?"
	
	"[i]Jah.[/i] He suggested that I make you feel welcome here. Do you feel welcome?"
	*set aichinger_rapport %+10
	
	"Yes?"
	
	"[i]Gut.[/i] I will tell him so."
	
	"Thank you…" you reply, giving him a knowing nod. Thanks to Senator Lockridge, you are not entirely alone in the court of St. Louis.
	
There is some time left before the gathering disperses. How would you like to spend it?

*choice
	#I join Bécard and Eliot. They will likely be discussing mortal affairs.
		*set independence %+10
		*set becard_rapport %+5
		*set eliot_rapport %+5
		*set shepherd_credentials %+5
		*if status >= 2
			*set aichinger_rapport %-10
			*set bailey_rapport %-10
			*set partridge_rapport %-10
		Bécard and Eliot draw up a chair for you. They are seated by a window looking out over the [i]biergarten[/i]. Now that the official part of the evening has concluded, they've opened the window to allow the music from below to drift inside. It's a performance of [i]Die Fledermaus;[/i] it's part of the company's repertoire. Of course, it's a little hard to hear over the rhythmic beating of steins and the off-key singing of the patrons.
		
		They are discussing the ill-health of Governor Phelps—the mortal Governor of Missouri—and the prospects for his successor. "My money is on Crittenden," Eliot opines.
		
		They argue back and forth for a while, while you learn about the inner workings of the human political scene of Missouri.

		Eventually, the night draws to a close. You say your goodbyes and return to your haven.
	#I join Aichinger, Bailey, and Partridge. They will surely be discussing politics within the Society.
		*set independence %+15
		*set becard_rapport %-15
		*set aichinger_rapport %+5
		*set bailey_rapport %+5
		*set partridge_rapport %+5
		
		Aichinger and the Senators are discussing the potential for a new governor of the West. You draw up a chair to join them. Bailey seems a little disappointed that there has been no hint of Memeskia being raised to that position, but Memeskia's terseness does him no favors. Several potential names are offered, but the three can arrive at no conclusions. @{(status >= 2) You participate in the conversation almost as an equal. It is a new feeling to be welcomed so.|}
		
		Interestingly, the subject of Carothers or Memphis is not brought up.
		
		Eventually, the night draws to a close. You say your goodbyes and return to your haven.		
	#These soirées bore me. I intend to be here no longer than absolutely necessary.
		*set independence %-20
		*set bailey_rapport %-5
		*set partridge_rapport %-5
		*set eliot_rapport %-5
		*set becard_rapport %+25
		*set aichinger_rapport %-5
		You bid your goodnights to the other guests. As you move for the door, however, Sabine inserts herself in your way.
		
		"Not much of one for gatherings of the Society?"
		
		"No, I can't say that I care for them."
		
		"Nor do I. That's why I prefer Jefferson City."
		
		"And yet, here you are."
		
		"We cannot exist totally outside the circle of the Society, as much as I might wish it were otherwise." She pauses to consider you a moment. "I hope we will have further opportunities to speak, ${given_name}."
		
		"Perhaps. Good night."
				
		You close the door firmly behind yourself.

*if redecide_haven
	On your way home, you consider your options.
	*choice
		#I will relocate to East St. Louis.
			*set stlouis_haven "east"
			Just a few years ago, East St. Louis leveled a massive mound that overlooked the river. The mound took on the moniker "Cemetery Mound" because, as the workers were clearing it away, hundreds of skeletons were discovered carefully arranged in layers. The whole mound was, in fact, some sort of pre-colonial burial site.
				
			Once the initial surprise was surmounted, the skeletons and earth were unceremoniously leveled to make way for further development. Some argued that perhaps De Soto or some other Conquistador had come and built the mound, such as Vaca or Vázquez, but the lack of any Christian iconography eventually undermines this theory. Amateur archaeologists spend hours debating which European civilization—or perhaps aliens?—might have come and overseen such a massive civic undertaking.
			
			Artifacts from the graves were sold as curiosities for a time, but most ended up re-buried or otherwise discarded. Soon, the very idea of a pre-colonial city in the region of St. Louis fades from mind.
			
			The town of East St. Louis has its own struggles separate from those across the river, yet the two are inextricably intertwined. By lowering the tax burden and easing up on supervision, East St. Louis seeks to lure factories from the city, all while discouraging people from actually living on this side of the river. Obviously, this stokes animosity between the two municipalities.
			
			That said, there are homes to be acquired, and you set about doing so.
			*if wealth > 300000
				*set wealth -100000
				*set haven_value 90000
				The house you settle upon is one of the nicer ones on this side of the river. At your direction, it is prepared for your habitation.
			*elseif wealth > 50000
				*set wealth -10000
				*set haven_value 9000
				The house you settle upon is functional. At your direction, it is prepared for your habitation.
			*elseif renter
				You find another boarding house with a basement to let. The landlady is surprised at your requirements, but only too happy to accept a tenant such as yourself.
			*else
				*set renter true
				*if income > 0
					*set income -1
				You let a basement from a widow who runs a boarding house. She is only too happy to let a room where the boarder never eats at her table. Conviently, there are no windows that need sunproofing.
				*set stlouis_valet_num +4
		#I will relocate to the Kerry Patch.
			*set stlouis_haven "kerry"
			Starting with the Potato Famine of 1845, the Irish began relocating to the United States in ever-greater numbers.  Many ended up in St. Louis, giving rise to this neighborhood.
			*if wealth > 300000
				*set wealth -100000
				*set haven_value 100000
				The most fashionable section of the Kerry Patch is St. Louis Place.  You decide to purchase a home there, and begin to outfit it for your needs.
			*elseif ethnicity = "irish"
				Most of the Kerry Patch is one-room shacks built by the Irish squatters.  The land is owned by the Mullanphys, a wealthy family that has not protested its occupation.  Amid this chaos, it is not hard to acquire a home and begin to outfit it for your needs.
				*set haven_value 1500
			*elseif renter
				You find another boarding house with a basement to let. The landlady is surprised at your requirements, but only too happy to accept a tenant such as yourself.
			*else
				There are rooming houses with rooms to let. You take the basement, as it is the largest space and the furthest from the noxious rays of the sun.
				
				Your new landlady is only too happy to take on two boarders while only needing to provide meals for one.
				*if income > 0
					*set income -1
				*set renter true
				*set stlouis_valet_num +4
	*gosub_scene stlouis_haven sleeping_place
	
	Thomas grumbles about the change in his routine. You learn obliquely that he arrives late on several occasions—it seems he has a hard time remembering that the location of your home has changed.

*page_break
The next evening is the Veiled Prophet parade and ball, which goes much as expected. What is unexpected is that, the night after that, the James-Younger gang roars out of retirement, raiding a train returning to Kansas City from the parade. They leave the passengers unharmed but make off with $40,000 in cash. Jesse James, their leader, leaves behind a letter @{(justice < 50) excoriating|full of ravings about} the corrupting influence of corporations on society. His harshest words are reserved for those Democrats who have betrayed their ideals and fallen into the arms of the banks and the industrialists.

*choice
	#Someone should really put an end to this man's villainy.
		*set compassion %-10
		*set shepherd_credentials %+5
		*set watching_james true
		*set laborvscapital %-5
		Perhaps someday soon an opportunity will present itself, that the world might be rid of such disorder.
		
		In the meantime, however, the heists and robberies continue.
	#The James brothers strike against the capitalists that are impoverishing this country.
		*set laborvscapital %+5
		*set shepherd_credentials %+5
		*set watching_james true
		Perhaps someday you will have the opportunity to meet this champion of the people.
	*if (rationalism > 45) and (religious_tradition != "pagan")
		#God will see to it that they are punished.
			*set rationalism %+10
			Whatever crimes the James-Younger gang commits in life, they will spend eternity repenting.
			
			In the meantime, however, they seem to enjoy their life of misdeeds.
	#Should the opportunity present itself, I suspect James' blood would be…unique.
		*set compassion %+10
		*set discretion %+10
		*set watching_james true
		*if stlouis_enterprise = 2
			You go so far as to make it known among the unsavory element that the gang would find succor here.
		Perhaps some day soon they will make an appearance. Time is on your side, after all.
	*if stlouis_enterprise = 1
		#I make sure the letter is reprinted in full as widely as possible.
			*set stlouis_business_climate %-10
			*set shepherd_credentials %+10
			*set anti_james_sentiment %-10
			*set laborvscapital %+5
			At your suggestion, several of the local newspapers decide to reprint the letter from James; several even translate it into German.
			
			For several weeks afterwards, everyone is talking about the influence of banks and railroads on politics throughout the city and state. It makes it difficult to be rich.
			*if (income > 100) or (wealth > 500000)
				
				One might wonder why someone of your means has supported James against their own interests, but there is no one to put this question to you.
		#I make sure the newspapers emphasize the injured passengers and criminal tactics of the gang.
			*set anti_james_sentiment %+10
			*set laborvscapital %-5
			At your suggestion, most of the local newspapers refrain from reprinting James' letter. Instead, they run interviews with the passengers, full of lurid details about black eyes, crushed hats, and the fainting of a young man overcome with fear.
			
			For months afterwards, everyone is talking about the danger that the James-Younger Gang poses to the region.
	#These mortal affairs will be the death of me.
		*set watching_james false
		*set shepherd_credentials %-10
		*set compassion %+5
		*if anachronism > 10
			*set anachronism -1
		The James-Younger Gang will fade into obscurity in time; you are only too ready to forget that they ever existed.

*if (temperance_movement or (stlouis_enterprise = 7)) or ((shepherd_credentials > 40) or (technology > 1))
	*page_break
	*if temperance_movement
		Due to your involvement in the temperance movement, you have lately been hearing about the wonders of soda water. The matrons of the movement extol its virtues, for it is both a health tonic as well as being a substitute for alcohol.
		
		You set out with the intention of experiencing this marvel for yourself. It's a cold November evening and you look forward to the press of warm bodies around you.
		
		@{(stlouis_haven = "downtown") The pharmacy is just a few blocks away from your home; arriving there,|Arriving downtown,} you push the door to the pharmacy door open—S.S. Lippincott is emblazoned on the glass—and step inside.
		*page_break
		At first glance,
	*else
		One evening in late November, you find yourself beset by a chill. Passing a gayly lit pharmacy—S.S. Lippincott is emblazoned on the glass—you decide to step inside and see what the hubbub is about.
	
		Once inside,
	you are astounded by the breadth of the crowd that has gathered in the room. Men and women of a variety of classes rub elbows at the marble counter. The act of creating a soda is itself a source of entertainment, you soon discover: an engraved box must be rocked back and forth several times by the "soda jerk" to impregnate the water with carbonation using a derivative of sulfur. @{(perception > 1) (Though the rest of the room seems oblivious, your fine nose can detect the distinctive "rotten egg" odor that accompanies the sulfur compounds.)|} When the box has been rocked sufficiently, the soda jerk pulls a lever, stirs in a flavored syrup of the customer's choice, and delivers the drink with a flourish.
	*temp soda_booster false
	*if (stlouis_enterprise = 5) or ((stlouis_enterprise = 1) or (stlouis_enterprise = 3))
		*set soda_booster true
	
	This is not, you note, at all like a saloon, tavern, or [i]biergarten[/i]. If anything, it is closer to a coffeehouse. The patrons drink their concoctions, but there is no inebriation nor chemical stimulation. It is, rather, a pleasing sensation on the lips and in the gullet. 
	
	And burping. Lots of burping.
	
	While you could engage an individual and attempt to engage in an assignation, it would be notably more difficult if you or others of your kind were to seek to feed from venues such as this.
	
	*choice
		*if (soda_booster) #Though it will make mine own feeding more difficult, I support the goals of the temperance movement. Pharmacies and soda water must be promoted!
			*set missouri_prohibition +1
			*set bloodflow -1
			*set bailey_rapport %-5
			*set aichinger_rapport %-5
			Using your influence @{stlouis_enterprise among journalists|ERROR|among the forward-thinking|ERROR|among artists and their friends|ERROR|ERROR|ERROR}, you encourage people of all sorts to patronize Lippincott's and other pharmacies for this treat—in place of watering holes of other sorts.
		#I want to spend the evening both sticking-out and blending-in; I want people to notice me—and think that I'm just like them.
			*set discretion %-5
			*if (charm > 1) or (compassion < 30)
				*if exposure > 0
					*set exposure -1
				*if charm >= 3
					*set exposure -1
				You spend the evening socializing with the health-conscious set. They are none-the-wiser for the experience.
			*else
				*set exposure +1
				Your clumsy attempts to be human draws more than a few stares. Your attempt at a burp, for example, fails spectacularly. It sounds more like a frog's ribbit.
				
				You excuse yourself before anyone begins to ask further questions.
		#This is a clear and present danger! I make sure to spread rumors where I can that soda water is no tonic, but instead a dangerous poison.
			*set independence %+5
			*if (stlouis_enterprise = 6)
				*set missouri_prohibition -1
				The temperance movement is deflated by your attestations. A portion of them begin to shy away from the pharmacies and their soda fountains, relying ever more on plain water for sustenance.
			*elseif soda_booster or (stlouis_enterprise = 4)
				*set bailey_rapport %+5
				*set aichinger_rapport %+5
				*set bloodflow +1
				*set missouri_prohibition -1
				You spread the rumors where you can, and it does seem to curtail the growth of the pharmacies in St. Louis. That, in turn, will make feeding here easier.
			*else
				*set exposure +1
				Unfortuantely, your pleas fall on deaf ears. It seems the time for soda fountains has arrived.
		*selectable_if (wealth > 60000) #This seems like an opportunity to invest some money. I find a pharmacy that has not yet bought a fountain and help them expand their operations.
			*set laborvscapital %-5
			*set wealth -20000
			*set income +(finance + 3)
			*if intelligence > 2
				*set income +1
			*if charm > 3
				*set wealth +4000
			You find an older pharmacy in the Kerry Patch that has not yet installed a soda fountain. Buying the fountain, building a counter, and fashioning stools is quite the capital expenditure, but customers are soon clamoring for their fizzy drinks.
		
*finish Next

*label sod_founder_check
*if sod_plot = false
	*set sod_plot true
	*if religious_tradition = "catholic"
		*set sod_founder "oshaughnessy"
	*if religious_tradition = "reformed"
		*set sod_founder "michaels"
	*if gonsoulin
		*set sod_founder "gonsoulin"
*return