*comment ñáéç…—
*hide_reuse
*advertisement
*temp allies "allies"
*if (compassion > 55) and (discretion > 55)
	*set allies "servants"
*if (shepherd_credentials < 40) and (compassion > 60)
	*set allies "minions"
*temp buffalo_soldier false
*temp can_bailey true
*if ((lore > 2) or knows_about_territories) and debt_to_bailey
	*set can_bailey false
*temp can_aichinger true
*if ((lore > 2) or knows_about_territories) and debt_to_aichinger
	*set can_aichinger false
In the days following the Veiled Prophet parade and ball, the city is filled with a vibrant energy.  The populace at large seems on-edge, concerned that the elites may release the recently-organized National Guard Battalion on the city again as a belated coda to the event.

As the days pass, the residents begin to relax, and the threat of violence subsides.

The fair over, and the presenters and attendees returned home, you find yourself considering more permanent lodgings; your present ones will not suffice long-term. @{(stlouis_valet_num = 4) Franklin's assistance during this time is invaluable.|} @{((lore > 2) or knows_about_territories) Of course, taking up residence in Downtown, Midtown, or Chestnut Valley will incur a debt to Bailey, whereas doing so in Dutchtown, Soulard, or Lafayette Square would indebt you to Aichinger.|}
*temp see_methodists false
*if (religious_tradition = "reformed") and (rationalism > 40)
	*set see_methodists true
*label choose_haven
*choice
	*if compassion < 65
		*if ethnicity = "african"
			*if (can_bailey) #The largest community of freedmen is in the Chestnut Valley area, along Chestnut Street.
				*label chestnut
				*set stlouis_haven "chestnut"
				*gosub bailey_debt
				*if (ethnicity != "african")
					*set exposure +1
					The establishment of a home for yourself in Chestnut Valley raises some eyebrows, but no one confronts you over your presence.
					
				*if wealth > 25000
					*set wealth -10000
					*set haven_value 10000
					You purchase a modest house suitable for your needs.  The only difficult part is the sunproofing.
					*gosub sleeping_place
					*goto time_to_die
				*else
					You let an attic from a landlady who is only too happy for you to pay for board but never partake. The small windows are easy to sunproof.
					*if income > 0
						*set income -1
					*set renter true
					*set buffalo_soldier true
					*gosub sleeping_place
					*goto time_to_die
			#Alternatively, there is a small community of free blacks in East St. Louis, just across the river.
				*goto east_stlouis
		*if (religious_tradition = "catholic") and ((rationalism > 40) and (priest = false))
			*if (can_aichinger) #I wish to be near my fellow Catholics@{(rationalism <= 60) —the customs of my life provide an unexpected comfort|}.
				*if rationalism <= 60
					*set compassion %-5
				*set rationalism %+10
				*goto soulard
		*if ethnicity = "choctaw"
			#I will take up residence in East St. Louis—across the river—near the ancient city of Cahokia. Though, the population is sparser there—and that means hunting will be more difficult.
				*label east_stlouis
				*set bloodflow -1
				*set stlouis_haven "east"
				Just a few years ago, East St. Louis leveled a massive mound that overlooked the river. The mound took on the moniker "Cemetery Mound" because, as the workers were clearing it away, hundreds of skeletons were discovered carefully arranged in layers. The whole mound was, in fact, some sort of pre-colonial burial site.
				
				*if ethnicity = "choctaw"
					This reminds you of some stories your grandmother used to tell you when you were little, about great cities where the headmen ruled everything, even the stars. Unfortunately, there are no Natives here. No Illiniwek, Missouria, Fox, or Osage, just colonists.
					
					*if intelligence > 2
						When you first see the mounds, you see them for what they are: massive earthworks along the axes of the seasons, the sun, and the moon. Unfortunately, you can also tell that several of the mounds have been dismantled or levelled. Places where a mound should be is now flattened farmland.
					You soon learn that the settlers gradually dismantled the mounds as their need for farmland grew. They discovered skeletons and artifacts of the city that was, but concluded that savages could not have built such things. Discussions passed among the amateur archaeologists about the possibility that Egyptians had somehow made their way up the Mississippi and built the mounds, or perhaps Martians.
					
					You hear these stories told by the people of East St. Louis and shake your head in dismay at the sacrilege.
				*else
					Once the initial surprise was surmounted, the skeletons and earth were unceremoniously leveled to make way for further development. Some argued that perhaps De Soto or some other Conquistador had come and built the mound, such as Vaca or Vázquez, but the lack of any Christian iconography eventually undermines this theory. Amateur archaeologists spend hours debating which European civilization—or perhaps Martians?—might have come and overseen such a massive civic undertaking.
				
					Artifacts from the graves were sold as curiosities for a time, but most ended up re-buried or otherwise discarded. Soon, the very idea of a pre-colonial city in the region of St. Louis fades from mind.
				
				The town of East St. Louis has its own struggles separate from those across the river, yet the two are inextricably intertwined. By lowering the tax burden and easing up on supervision, East St. Louis seeks to lure factories from the city, all while discouraging people from actually living on this side of the river. Obviously, this stokes animosity between the two municipalities.
				
				That said, there are homes to be acquired, and you set about doing so.
				*if wealth > 250000
					*set wealth -100000
					*set haven_value 90000
					The house you settle upon is one of the nicer ones on this side of the river. At your direction, it is prepared for your habitation.
					*gosub sleeping_place
					*goto time_to_die
				*elseif wealth > 50000
					*set wealth -10000
					*set haven_value 9000
					The house you settle upon is functional. At your direction, it is prepared for your habitation.
					*gosub sleeping_place
					*goto time_to_die
				*else
					*set renter true
					*if income > 0
						*set income -1
					You let a basement from a widow who runs a boarding house. She is only too happy to let a room where the boarder never eats at her table. Conviently, there are no windows that need sunproofing.
					
					*gosub sleeping_place
					*goto time_to_die
		*elseif (knows_about_territories)
			#Across the river in East St. Louis I can establish a haven free of obligations—though the sparse population will make hunting more difficult.
				*goto east_stlouis
		*else
			#Land is cheap across the river in East St. Louis—though the population is correspondingly sparse.
				*goto east_stlouis
		*if (can_aichinger) 
			*if ethnicity = "french"
				#The Soulard neighborhood contains the remaining descendants of the original French settlers of St. Louis.
					*label soulard
					*gosub aichinger_debt
					*set stlouis_haven "soulard"
					Just south of downtown, the Soulard neighborhood tries to retain something of its French character.  At its northern end is the Cathedral of St. Louis, King of France, the first cathedral of the west.
					*if avoided_new_orleans or exiled_from_new_orleans
						In fact, the building was constructed under the supervision of Joseph Rosati, the bishop that quarreled with Padre Segura so many decades ago during your sojourn in St. Charles parish.
					*gosub sleeping_place
					*goto time_to_die
			*if ethnicity = "german"
				#Dutchtown, the enclave of German refugees, seems like the perfect spot to establish a haven.
					@{(lore <= 2) Hopefully, Aichinger will not see your commitment to your people as a challenge to his influence over them.|}
					*label dutchtown
					*gosub aichinger_debt
					*set stlouis_haven "dutchtown"
					
					Dutchtown itself is south of the Soulard neighborhood, and contains the Anheuser-Busch and Lemp breweries.
				
					*if wealth > 100000
						You are soon able to acquire a modest home, and begin to outfit it to your needs.
						*set haven_value 25000
						*set wealth -25000
						*gosub sleeping_place
						*goto time_to_die
					*else
						You find a kindly widow who keeps house and takes on boarders. She turns over most of her basement to you for an acceptable price.
						*if income > 0
							*set income -1
						*set renter true
						*gosub sleeping_place
						*goto time_to_die
		*if ethnicity = "irish"
			*selectable_if (streetwise > 0) #Locals call the Irish ghetto of St. Louis "the Kerry Patch," a rough-and-tumble community on the waterfront north of downtown.
				*label kerry
				*set bloodflow +1
				*set stlouis_haven "kerry"
				Starting with the Potato Famine of 1845, the Irish began relocating to the United States in ever-greater numbers.  Many ended up in St. Louis, giving rise to this neighborhood.
				*if wealth > 200000
					*set wealth -100000
					*set haven_value 100000
					The most fashionable section of the Kerry Patch is the St. Louis Place.  You decide to purchase a home there, and begin to outfit it for your needs.
					*gosub sleeping_place
					*goto time_to_die
				*elseif ethnicity = "irish"
					Most of the Kerry Patch is one-room shacks built by the Irish squatters.  The land is owned by the Mullanphys, a wealthy family that has not protested its occupation.  Amid this chaos, it is not hard to acquire a home and begin to outfit it for your needs.
					*set haven_value 1500
					*gosub sleeping_place
					*goto time_to_die
				*else
					There are rooming houses with rooms to let. You take the basement, as it is the largest space and the furthest from the noxious rays of the sun.
					
					Your new landlady is only too happy to take on a boarders who never eats from her table. 
					*if income > 0
						*set income -1
					*set renter true
					*gosub sleeping_place
					*goto time_to_die
		*if ethnicity = "scotch"
			*if (can_bailey) #@{see_methodists While their Methodist churchs might not appeal to you, the hillfolk of Appalachia|Migrants from Appalachia} have established themselves west of downtown.  I will join my kin there.
				*set compassion %-5
				*set rationalism %-5
				*goto midtown
		*if (religious_tradition = "reformed") and (rationalism > 40)
			*if (can_bailey) #The Presbyterians and Methodists have made their homes west of downtown.
				*label midtown
				*gosub bailey_debt
				*set stlouis_haven "midtown"
				*if wealth > 200000
					*set wealth -100000
					*set haven_value 100000
					You purchase a house on Olive Street.  There is a horse car line that goes down Olive to downtown, making a trip there simple.
					
					You quickly set about outfitting the home to your needs.
					*gosub sleeping_place
					*goto time_to_die
				*elseif ethnicity = "scotch"
					*set haven_value 5000
					You acquire a small property on Locust Street.  It is unimpressive, but it will satisfy your needs for the moment.  You immediately set about outfitting it to suit your noctural nature.
					*gosub sleeping_place
					*goto time_to_die
				*else
					You find a kindly widow who takes on boarders. She is only too happy to turn over her basement to you.
					
					*if income > 0
						*set income -1
					*set renter true
					*gosub sleeping_place
					*goto time_to_die
		*if (can_aichinger) and ((feeding_style = "socialites") or ((wealth > 350000) or (feeding_style = "merchants")))
			*selectable_if (wealth >= 500000) #The rich and powerful of St. Louis live around Lafayette Square.  I intend to make my home in their company.
				*if ((ethnicity = "african") or (ethnicity = "choctaw"))
					*if charm < 3
						Unfortuantely, the neighborhood is openly hostile to the presence of someone such as yourself; moreover, they point to a series of laws recently passed that forbid your residence there.  Frustrated, you turn elsewhere for sanctuary.
						*goto choose_haven
					*else
						*gosub aichinger_debt
						*set exposure +1
						*set wealth -500000
						*set haven_value 250000
						*set stlouis_haven "lafayette"
						*set local_fame %+5
						The neighbors object to your presence in their midst, but your supernatural charm overwhelms their objections one by one.  Thus, despite a number of ordinances forbidding people like you from living in the area, you purchase an older house proximate to Lafayette Square.  Still, though, your presence is a source of wonder for the community at large.
						
						*gosub sleeping_place
						*goto time_to_die
				*else
					*gosub aichinger_debt
					*set wealth -500000
					*set haven_value 250000
					*set stlouis_haven "lafayette"
					*set local_fame %+5
					*set exposure +1
					It costs you a pretty penny, but you are able to acquire one of the older houses adjacent to the Lafayette Square neighborhood.  It may not be ideal, but it is close enough to suit for now.  You immediately begin to outfit it for your needs.
					
					*gosub sleeping_place
					*goto time_to_die
		*if ethnicity = "southern"
			*if (can_bailey) #@{see_methodists While I do not intend to worship with them, I will settle among the Georgian families west of downtime that arrived at the burning of Atlanta|After Sherman burnt Atlanta, a contingent of Georgian families relocated to St. Louis, west of downtown.  I will join them there.}
				*set rationalism %-5
				*set compassion %-5
				*goto midtown
		*if ethnicity = "yankee"
			#The large enclave of Germans is one of the most solidly pro-Union communities in the city; that seems like a good spot to establish a haven.
				*set stlouis_haven "dutchtown"
				*set aichinger_rapport %+10
				Hopefully, Aichinger will appreciate your affection for his people.
				*goto dutchtown
	*if (can_bailey) #I want to be downtown, closer to the centers of power.
		*label downtown
		*gosub bailey_debt
		*set bloodflow +1
		*set stlouis_haven "downtown"
		*if wealth > 100000
			*set wealth -50000
			*set haven_value 50000
			You purchase a townhouse and begin to outfit it for your needs.
			*gosub sleeping_place
			*goto time_to_die
		*elseif wealth > 50000
			*set wealth -20000
			*set haven_value 20000
			You purchase a small house, and begin to outfit it for your needs.  The hardest part is the sunproofing.
			*gosub sleeping_place
			*goto time_to_die
		*else
			You acquire a shack in the downtown area, one more in a sea of them.  The hardest part is the sunproofing.
			*set haven_value 1000
			*gosub sleeping_place
			*goto time_to_die
	*if priest
		*if (can_aichinger) #I wish to be near the Cathedral of St. Louis.
			*set rationalism %+5
			*goto soulard
	*if (can_bailey) 
		*if (feeding_style = "prostitutes")
			#I intend to establish myself in Chestnut Valley, where the juke-joints and brothels are thickest.
				*label chestnut_valley
				*gosub bailey_debt
				*set bloodflow +1
				*set stlouis_haven "chestnut"
				*set bailey_rapport %-10
				*set aichinger_rapport %-10
				*comment Bailey and Aichinger find it distasteful that you live in the comparative squalor of Chestnut Valley.
				Over the course of several nights, you view several rooms for rent and eventually acquire a basement unit in a rooming house. With a private entrance and tiny windows, it is easy enough to sunproof the space. The landlady is only too happy to rent out the whole basement to a single tenant who pays for board but never partakes.
				
				@{(feeding_style = "prostitutes") Meeting and fraternizing with the men and women of the night is simple when they are also your neighbors.|Of course, thanks to the dozen or so saloons within a five-minute walk, you habitually wake to individuals who started early on their night's drinking passed out in the stairwell to your front door.}
				
				It certainly makes feeding simple.
				*if income > 0
					*set income -1
				*set renter true
				*set buffalo_soldier true
				*gosub sleeping_place
				*goto time_to_die
		*if (feeding_style = "drunks") and ((ethnicity != "german") or ((ethnicity = "german") and (compassion >= 65)))
			#I intend to be in Chestnut Valley, where the saloons are thickest.
				*goto chestnut_valley
		*elseif (feeding_style = "gamblers")
			#I intend to be in Chestnut Valley, where the gambling-dens are thickest.
				*goto chestnut_valley
		*elseif (feeding_style = "artists")
			#I intend to be in Chestnut Valley, where the honky-tonks and their talented musicians are thickest.
				*goto chestnut_valley
		*else
			#I intend to be in Chestnut Valley; I can rent a room there for next to nothing.
				*goto chestnut_valley
	*if (ethnicity != "irish")
		*if (memphis_haven = "pinch") and (streetwise > 0)
			#The Kerry Patch is a ghetto of rough-and-tumble immigrants along the waterfront—who also happen to be Irish. It reminds you of the Pinch back in Memphis.
				*goto kerry
		*elseif (streetwise > 1)
			#The Kerry Patch is a ghetto of rough-and-tumble immigrants along the waterfront—who also happen to be Irish.
				*goto kerry
		*elseif (knows_about_territories)
			#As mentioned by Bailey, the Irish ghetto called the Kerry Patch is available for me to take up residence in.
				*goto kerry

*label bailey_debt
*if lore > 2
	*set bailey_rapport %+5
	*set independence %+5
	You inform the Senator of your desire to take up residence in his territory. 
	*if debt_from_bailey
		*set debt_from_bailey false
		Since the Senator owes you a debt already, the matter is quickly settled.
	*else
		*set debt_to_bailey true
		He is only too happy to accept a debt from you.
*return

*label aichinger_debt
*if lore > 2
	*set aichinger_rapport %+5
	*set independence %+5
	You inform Aichinger of your desire to take up residence in his territory.
	*if debt_from_aichinger
		*set debt_from_aichinger false
		Since he already owes you a debt, the matter is quickly settled.
	*else
		*set debt_to_aichinger true
		He is only too happy to accept a debt from you.
*return

*label sleeping_place
Your haven established, you consider your sleeping accommodations proper.

*choice
	#A coffin seems somehow appropriate.
		*set compassion %+15
		*set sleeping_place "coffin"
	#I may be dead, but I still enjoy my bed.
		*set discretion %+5
		*set sleeping_place "bed"
	#Safety first! A crawlspace.
		*set discretion %-20
		*set sleeping_place "crawlspace"
*return

*label define_opium_fiend
*if renter
	Your landlady's son soon arrives in the house. He @{male shakes your hand|bows unsteadily} when he meets you and introduces himself as Thomas; you later learn that he was named for Thomas Paine, the Founding Father who argued most vociferously for the quality of all people. 
	*if ethnicity = "choctaw"
		He was injured in a construction accident. He walks with a noticeable limp and you suspect he also sustained some injury to the abdomen.
	*else
		He has been discharged from the Army after serving on the frontier, having been wounded @{buffalo_soldier in the conflicts with the Apache in Arizona|in the Dakotas fighting the Sioux and Lakota}. He walks with a notable limp, but you suspect he also took a blow to the gut. 
	By what miracle he was able to survive is never explained, but you attribute it to @{(rationalism > 60) divine providence|the recent advancements of medical science}.
	
	Over the course of several months, the conditions of the house deteriorate notably. You suspect that the majority of your rent is going to the nigh-daily visits by a doctor to the young man.
*return

*label time_to_die
*if haven_value >= 100000
	*set bloodflow +1
	*comment having a house that you can entertain in makes it easier to feed.
	*set exposure -1
	*comment having a house that large also makes your eccentricities harder to observe.
	*if haven_value > 200000
		*set exposure -1
*if lore <= 1
	*set exposure +(local_fame / 25)
	*goto valet
*if charm > 3
	*set bloodflow +(charm - 3)
*if oblivio
	*set bloodflow +1
*page_break
Having chosen your new accommodations, you confront another concern: it might behoove you to die.

You've overheard others of your kind discuss this matter. At some point, your agelessness must be accounted for throughout the mortal world. This was not such an issue several centuries ago, but as the systems of documentation and bureaucracy have advanced, so too has the threat to your kind. The most common tactic seems to be to simply announce the death of your original identity, with the designation of a grand@{male son|daughter} or other relative as the sole heir to the entirety of your estate. Other, more complicated, solutions exist as well. @{(lore >= 3) You've even heard rumors of certain vampires who husband lines of their mortal family through the centuries, making sure to have a real person—even better, one that resembles the vampire—to replace when the time comes.|} @{(finance > 0) Of course, any transition of this sort will incur some degree of both expense and loss.|} If you adopt such a solution, it will almost certainly require hiring a lawyer. @{(male and (ethnicity = "southern")) While you may have been one in your mortal life, that was many decades ago. Moreover, you can't exactly appear before a judge in the middle of the day.|}
*temp lawyer_source 1
*label lawyer_question

*choice
	*if ((financial_donor = false) and (exposure < 10)) and (local_fame < 30)
		*selectable_if ((wealth < 250000) and (income < 20)) #My estate is so paltry, there is no need for this process.
			*set discretion %-10
			*set shepherd_credentials %-10
			*if exposure > 0
				*set exposure -1
			*set local_fame %-30
			With little in the way of assets to your name, taking on a new name is no great challenge. You have just moved to St. Louis; there are few to gainsay you here. A few documents forged and you are prepared for your new existence.
			*if priest
				*goto priest_check
			*elseif trans
				*goto new_identity
			*else
				*goto valet
	#I don't care about the so-called dangers of mortal bureaucracy; if they wish to come for me, let them!
		*label dontchange
		*set discretion %+15
		*set exposure +(local_fame / 25)
		*set shepherd_credentials %-10
		*if trans
			*goto new_identity
		*else
			*goto valet
	*if priest
		#As a priest, I am not supposed to have assets that can be transferred; communicating my expiration to the Church while simultaneously maintaining my wealth will be…expensive.
			*set income round(income * 0.75)
			*set wealth round(wealth * 0.75)
			Of course, as priest, you're not supposed to have assets that can be transferred. 
			*label priest_check
			*if trans
				*set priest false
				That said, you cannot not continue serving as a priest now that you have accepted your true identity.
			*else
				Which begs a further question: do you wish to retain your priestly trappings?
				*fake_choice
					#Yes.
					#No, it's time to let the cassock go.
						*set priest false
					#No, I no longer believe in God.
						*set rationalism %-20
						*set priest false
					#No, God has cursed me; why should I continue to serve him?
						*set rationalism %+10
						*set priest false
				So shall it be.
			*if trans
				*goto new_identity
			*else
				*goto valet
	*else
		#I will designate an heir and announce my death.
			The next question, of course, is how will you select a lawyer? You could solicit a stranger, but you have no way of knowing how they will handle the delicacy of your request—evaluating their talents and potential for discretion would be of utmost importance. Alternately, you could entreat another vampire to share a resource with you, but that would surely mean that your affairs would become known to that vampire. You might try handling the affair yourself, but that would surely be intellectually and emotionally taxing in a variety of ways—not to mention dangerous.
			
			*label vampire_for_lawyer
			*temp interlocutor "none"
			*temp inter_honor 1
			*choice
				*if ((interlocutor != "none") and (trans = false)) #I've changed my mind; I'll forgo changing my identity.
					*goto dontchange
				*selectable_if (literate) #I will be mine own lawyer.
					*temp test_stat intelligence
					*set test_stat +(willpower + finance)
					*if speaks_latin
						*set test_stat +0.5
					*set local_fame %-10
					The process is grueling. You spend countless nights writing briefs, researching obscure tax laws, and sending requests for loans of law books from the library.
					*if test_stat > 6
						*set income round(income * 0.85)
						*set wealth round(wealth * 0.85)
						*set dead_in_stlouis 2
						Eventually, however, you file all the necessary paperwork. A drunk of a lawyer who asks no questions stands in for you on the one day that a lawyer must actually be present before a judge, but the paperwork is in such excellent condition that the requests are granted without substantive scrutiny.
					*elseif test_stat > 5
						*set income round(income * 0.70)
						*set wealth round(wealth * 0.70)
						*set exposure +1
						*set dead_in_stlouis 2
						With much gnashing of teeth and sweating of blood, you finally manage to close the book on all the necessary transactions. A drunk of a lawyer who doesn't ask questions stumbles his way through the judge's questions, and after three or four trips to the courthouse, finally secures the final approvals.
					*elseif test_stat > 4
						*set income round(income * 0.55)
						*set wealth round(wealth * 0.55)
						*set exposure +2
						*set dead_in_stlouis 3
						The law does not come easily to you, if it could be said to come at all. You suppose that your efforts are not a complete disaster, but very nearly so. In several instances, you are forced to outright abandon assets, as to transfer them to your new identity would jeopardize the whole affair.
						
						Bringing the matter to a close is frustrating and disheartening. You find yourself wondering who is the blood-sucking predator in this situation, you or the legal system that seeks to part you from your property.
					*else
						*set income round(income * 0.40)
						*set wealth round(wealth * 0.40)
						*set exposure +3
						*set dead_in_stlouis 3
						Moreover, your capabilities are largely insufficient for the task. Despite the nights and early mornings spent reading the law-books, you can make no sense of them. You go through a string of lawyers to help you, but every document you file seems to be in error.
						
						By the time you are concluding the matter, you are outright abandoning assets, because attempting to transfer control to your new identity would draw far too much scrutiny.
						
						Bringing the matter to a close is frustrating and disheartening. You find yourself wondering who is the blood-sucking predator in this situation, you or the legal system that seeks to part you from your property.
					*goto new_identity
				#I will search for a lawyer without help from another vampire.
					*temp test_stat intelligence
					*set test_stat +(perception + (finance / 2))
					*set local_fame %-20
					The process is time-consuming. Interviewing lawyers is about as enjoyable as having your canines pulled—or so you imagine.
					
					*if test_stat > 5
						*set income round(income * 0.875)
						*set wealth round(wealth * 0.875)
						*set dead_in_stlouis 2
						Your final choice, however, is an astute one. The lawyer files the paperwork promptly and efficiently. He understands your needs clearly, and conducts himself himself with the utmost of discretion. He even manages to shelter a number of your assets in such as way as to limit your exposure.
						
						When the final documents are submitted, you are quite pleased with how little of your assets were surrendered to the State of Missouri.
					*elseif test_stat > 4
						*set income round(income * 0.75)
						*set wealth round(wealth * 0.75)
						*set exposure +2
						*set dead_in_stlouis 2
						The lawyer is sharp, but not the sharpest. He files the paperwork dutifully, but there are frequent errors that necessitate corrections.
						
						The matter is ultimately concluded, but not before a full quarter of your assets have been relinquished to taxes, fees, and penalties.
					*else
						*set income round(income * 0.575)
						*set wealth round(wealth * 0.575)
						*set exposure +3
						*set dead_in_stlouis 3
						Unfortunately, the lawyer that you settle on is not as capable as he presents himself as being.
						
						Though he nods along and takes notes as you speak, whenever he repeats back to you your needs, there is always something off, despite his assurances that he understands everything.
						
						His filings are frequently delinquent. Required documents are frequently misplaced. The judge—reportedly—becomes quickly exasperated.
						
						Eventually the matter is put to bed, but not before you have lost more forty percent of your assets.
						*if (discretion > 65) 
							You console yourself by @{(feeding_style = "vegetarian") killing the lawyer|drinking the lawyer dry} and leaving his lying tongue in his bed for his wife to find.
					*goto new_identity
				#I ask Memeskia.
					*set interlocutor "memeskia"
					*set inter_honor 4
					*set lawyer_source 2
					*set stlouis_estate_lawyer "Hardy"
					*label sort_interlocutor
					*set local_fame %-30
					*temp interlocutor_rapport interlocutor & "_rapport"
					
					*if {interlocutor_rapport} > 45
						$!{interlocutor} nods along at your request. When you are finished speaking, he offers the name of a lawyer who will handle the matter quickly and discreetly.
						*goto lawyer_acquired
					*else
						*if interlocutor = "memeskia"
							Memeskia stares at you for an interminable period of time, until you realize he's not going to dignify your request with a reply. You excuse yourself from his presence.
							
							Perhaps someone else will help you?
							*goto vampire_for_lawyer
						*elseif interlocutor = "eliot"
							Eliot looks uncomfortable at your request. He quickly changes the subject to something less intimate.
							
							Perhaps someone else will help you?
							*goto vampire_for_lawyer
						*else
							$!{interlocutor} takes affront at your request. He claims to not have any such resource at his disposal.
							
							Perhaps someone else will help you?
							*goto vampire_for_lawyer
				#I ask Aichinger.
					*set interlocutor "aichinger"
					*set stlouis_estate_lawyer "Keller"
					*set lawyer_source 3
					*goto sort_interlocutor
				#I ask Bailey.
					*set interlocutor "bailey"
					*set stlouis_estate_lawyer "Prince"
					*set lawyer_source 4
					*goto sort_interlocutor
				#I ask Eliot.
					*set interlocutor "eliot"
					*set stlouis_estate_lawyer "Ross"
					*set lawyer_source 5
					*goto sort_interlocutor
				*if literate
					*if jesse_rapport > 65
						#I write to Jesse Whitaker.
							*set interlocutor "whitaker"
							*set stlouis_estate_lawyer "Franklin"
							*set lawyer_source 6
							Jesse responds almost immediately. He doesn't know any lawyers in St. Louis,
							*goto lawyer_through_letter
					*if (withers_rapport > 60) or (debt_from_withers)
						#I write to Samantha Withers. @{debt_from_withers She does owe me a debt, after all.|}
							*set interlocutor "withers"
							*set inter_honor 2
							*set stlouis_estate_lawyer "Schwab"
							*set lawyer_source 7
							*if debt_from_withers and (withers_rapport < 60)
								*set debt_from_withers false
								Withers's response to you is cold and distant. She furnishes you with the address of a lawyer that she claims can be trusted.
								*goto lawyer_acquired
							*elseif debt_from_withers
								*set debt_from_withers false
								Withers's response to you is measured. She is grateful to be quit of the debt she owes you, but there is still some affection laced through the lines of business. She encloses the address of a lawyer and wishes you the best.
								*goto lawyer_acquired
							*else
								Withers's response is effusive. She expounds on the lengths to which she had to go to acquire the name of a trustworthy attorney.
								
								You send an equally effusive thank-you note.
								*goto lawyer_acquired
					*if debt_from_carothers
						#I write to Apollo Carothers and call in the debt he owes me.
							*set interlocutor "carothers"
							*set lawyer_source 8
							*set stlouis_estate_lawyer "Ochs"
							Carothers's reply is terse. You recognize the penmanship of @{applethorp_alive Dido Applethorp|his valet}; you also recognize @{applethorp_alive her|his valet|his valet}'s extrapolations around Carothers's directives.
							
							The address of a lawyer is enclosed.
							*goto lawyer_acquired
					*if debt_from_coffin
						#I write to Abigail Coffin and call in the debt she owes me.
							*set interlocutor "coffin"
							*set inter_honor 3
							*set lawyer_source 9
							*set stlouis_estate_lawyer "Conventry"
							*goto lawyer_acquired
					*if debt_from_page
						#I write to Harold Page and call in the debt he owes me.
							*set interlocutor "page"
							*set lawyer_source 1
							*set stlouis_estate_lawyer "Munier"
							*goto lawyer_acquired			
	#I will take this opportunity to reveal my true gender to the world@{priest , even if this means giving up my role in the Church|}.
		*set trans true
		*set local_fame %-10
		*if male
			*gosub_scene util xtf
		*else
			*gosub_scene util xtm
		*goto lawyer_question

*label lawyer_through_letter
but those lawyers who can be trusted with such matters are a close-knit bunch. The address of ${stlouis_estate_lawyer}, Esq., is enclosed.

*label lawyer_acquired
*page_break

The lawyer greets you @{lawyer_source brusquely|nervously|reservedly|graciously|graciously|graciously|graciously|graciously|graciously}, gesturing for you to take a seat. "Let us discuss your situation," he begins. @{((ethnicity = "african") and (lawyer_source = 3)) "I don't usually take clients…such as yourself…but I've made an exception this time."|}

"Thank you for seeing me. @{inter_honor Mr.|Ms.|Mrs.|} $!{interlocutor} explained my needs to you?" @{((ethnicity = "african") and (lawyer_source = 3)) You grit your teeth at his casual cruelty.|}

"Yes, of course. You will, of course, have to draw up a full list of the assets that you want transferred to the new identity…"

*if literate
	You proffer such a document, which he @{lawyer_source snaps out of your hand|snaps out of your hand|gestures for you to deposit befor him|takes from your hand|takes from your hand|snaps out of your hand|snaps out of your hand|snaps out of your hand|snaps out of your hand}. Perusing the document, his brow furrows. @{(income > 200) "This will take some time|"This should be simple enough}. I will keep you apprised of any further develoments."
*else
	*set discretion %+5
	"You'd best grab a pen," you reply.
	
	He looks at you, confused. But when you begin to list off your assets and their locations, he scrambles for paper and a fountain pen. He begins writing. @{(income > 200) It takes you quite a while to describe everything; ${stlouis_estate_lawyer} has to make a pot of coffee to keep up. But eventually you finish. You hope, anyway.|When you are finished dictating, he looks over the list and assures you that he can see to the disposition of these.}
	*if income > 200
		*set income round(income *0.95)

"Thank you, Mr. ${stlouis_estate_lawyer}."
*label new_identity

As part of this process, you are, of course, given the opportunity to change your name.
*choice
	#I keep the same name; it's common enough for names to be passed down within families.
		*set exposure +1
		*label end_identity
		You are officially a new @{male man|woman}.
		
		Do you want to take this opportunity to build a new wardrobe?
		*choice
			*if priest
				*selectable_if (wealth > 250) #Yes, I could use a new cassock.
					*set wealth -100
					*set discretion %-5
					*set anachronism %-5
					*set rationalism %+10
					The Leicester Longwool cloth is rough and scratchy on your skin, but it is comforting in its familiarity.
					*goto valet
				*selectable_if (wealth > 500) #Yes, I could use a fine new cassock.
					*set wealth -250
					*set anachronism %-5
					*set rationalism %+10
					*set local_fame %+5
					The fine Merino wool—imported from Australia—feels smooth against your skin.  You feel as though you could conquer the world—or give an inspiring mass—in your new outfit.
					*goto valet
				*selectable_if (wealth > 5000) #Yes, I could use an exquisite new cassock.
					*set wealth -2500
					*set discretion %+5
					*set anachronism %-5
					*set rationalism %+10
					*set local_fame %+10
					The tailor has never been asked to craft a cassock from cashmere before—even the most corrupt cardinals stop at Merino wool and silk undergarments—but that does not stop him from taking the commission.
					
					He outdoes himself with his creation. It is soft, supple, and warm. You soon find that when you feed, the heat of the blood stays with you a few minutes longer, kept close by these fine threads.
					*goto valet
			*if anachronism > 50
				*if male
					*selectable_if (wealth > 10000) #A new handmade suit would be most welcome.
						*set wealth -5000
						*set anachronism %+10
						*set shepherd_credentials %-5
						*set independence %+5
						*set local_fame %+5
						It takes several weeeks for the suit to be finished, what with several trips to the tailor to get the measurements just right.  When it is finally finished, you realize that it was worth the wait. It exhilerating to have something that moves with you like a second skin.
						*goto valet
				*else
					*selectable_if (wealth > 10000) #Only the latest fashions from Paris will do.
						*set wealth -5000
						*set discretion %+5
						*set anachronism %+10
						*set shepherd_credentials %-5
						*set independence %+5
						*set local_fame %+10
						Though intensely uncomfortable, you do look fabulous in the dresses that have just arrived.
						
						Of course, there is also a matter of hats: extravagant adornments are [i]à la mode[/i].
						*fake_choice
							#Bat-wings.
							#Crane feathers.
							#Duck feathers.
							#Egret feathers.
							#Flowers.
							#Hummingbirds…taxidermied whole.
							#Ostrich feathers.
							#Peacock feathers.
							#No adornments, thank you.
							
						*goto valet
			*selectable_if (wealth > 25000) #Something stylish and functional.
				*set wealth -5000
				*set discretion %+5
				*set anachronism %+5
				@{male The tailor makes sure to adjust the suit to make it a better fit.  Looking at yourself in the mirror, you have to admit that you cut a dashing figure.|The dressmaker makes sure to adjust the dress to better fit your shape.  Looking at yourself in the mirror, you have to admit that your brighten the room.}
				*goto valet
			*selectable_if (wealth > 10000) #Something understated.  No need to draw attention to myself.
				*set wealth -2500
				*set discretion %-5
				*set local_fame %-5
				Your new clothes are well-made while lacking in ostentation.  @{male An excellent choice, if you do say so yourself.|Of course, you draw unwanted attention to yourself whatever you might wear. Or, rather, unwanted attention is drawn to you. You sometimes wonder what men would think if they knew how close they came to a painful death when making uninvited remarks upon your appearance.}
				*goto valet
			*selectable_if ((wealth > 2500) or (ethnicity = "choctaw")) #I prefer the @{(ethnicity = "choctaw") Native dress of my people|fashions of days gone by}.
				*set discretion %+10
				*set anachronism %-5
				*set independence %+5
				*set wealth -1000
				*set local_fame %+10
				*if ethnicity = "choctaw"
					Since there are no tailors for clothes of the sort you seek, you set about making your own. You spend many nights with bone needle and thread, stitching your clothes in the way your parents taught you.
					
					When you are done, you are more than satisfied with the results.
				*else
					*if male
						The tailor is a little confused by your request, but does not dally overmuch.  He
					*else
						*if ethnicity = "german"
							The tailor is a little confused by your request, but does not dally overmuch.  He
						*else
							The seamstress is a little confused by your request, but does not dally overmuch.  She
					is experienced, and grew up learning to sew the sorts of patterns for which you have asked.
					
					When the new outfit is finished, you rush to pick it up.  You feel a rush of comfort at the sight of yourself in clothing which you understand.  The world has changed so quickly, at least—in some small way—you can remember something of what came before.
				*goto valet
			#Clothes are clothes.  When they rip, I have them mended.  When they can no longer be mended, I have them replaced.
				*if wealth > 100
					*set wealth -100
				*if wealth <= 100
					*set wealth 0
				*set discretion %-10
				*set anachronism %-5
				*set independence %-5
				Never let it be said that you were ahead of the curve.
				*goto valet
	#I keep the same surname, but choose a new given name.
		*set local_fame %-30
		*label set_given_name
		*set original_name given_name
		*label given_name_try_again
		*if choice_randomtest
			*if male
				*set given_name "Robert"
			*else
				*set given_name "Sarah"
			*goto end_identity
		What is your new given name?
		*input_text given_name
		${given_name}, is that right?
		*choice
			#Yes.
				*goto end_identity
			#No.
				*goto given_name_try_again
	#I choose a new name altogether.
		*set local_fame %-40
		*set exposure -1
		*set original_surname surname
		*set changed_surname true
		*label surname_try_again
		*if choice_randomtest
			*if male
				*set given_name "Robert"
			*else
				*set given_name "Sarah"
			*set surname "Smith"
			*goto end_identity
		What is your new surname?
		*input_text surname
		${surname}, is that right?
		*choice
			#Yes.
				*goto set_given_name
			#No.
				*goto surname_try_again

*label valet

*if trans and renter
	Thankfully, following a reintroduction of yourself, your evolution goes otherwise unremarked by your landlady. You suppose that, out of all the queer things you do like refusing to eat and sleeping all day, changing your clothes and assuming a new name is of negligible importance.
*if (stlouis_valet_num = 4)
	*if trans
		
		The change in your gender presentation is sure to surprise Franklin. He has served you for over a decade…will he have difficulty understanding? What will his reaction be?
		*choice
			#His reaction is his responsibility, not mine. I inform him of my new name and pronouns and order him to honor them.
				*set stlouis_valet_loyalty %-5
				*set shepherd_credentials %-5
				Franklin is certainly surprised—you can see it written on his face. But he follows your directions to the letter. You are even surprised by how facile the transition is for him.
			#I introduce the idea to him slowly.
				*set stlouis_valet_loyalty %+10
				You begin by having him assist you with shopping for different clothing. Then you have him help you try things on. Once it seems he's used to the idea of seeing you in your new clothes, you suggest that you would prefer being addressed by your new name.
				
				Franklin takes the whole affair in stride. In retrospect, you wonder if you might have proceeded with more alacrity. At the same time, there was a certain frission to the transition that you enjoyed.
			#I appear before him as my true self, and hope for the best.
				*set stlouis_valet_loyalty %+5
				Somewhat to your surprise, Franklin greets you warmly. He informs you, after some interrogation, that a cousin of his had made a similar transition in his teens. He put away his skirts and started wearing slacks, shortened his name, and in time most people forgot that he'd ever had braids.
				
				So much the better.
*else
	The time has come for you to hire a new valet.  @{(ethnicity = "scotch") Two|Several} candidates present themselves.
	*set stlouis_valet_loyalty 50
	*choice
		#George, a freedman, born here in St. Louis.
			*set stlouis_valet "George"
			*set stlouis_valet_num 1
			*if exodusters
				*set stlouis_valet_loyalty %+15
				Your support of the Exodusters has preceded you; George is only too happy to enroll in your service.
			*if founded_school_for_the_blind or clay_street_foundation
				*set stlouis_valet_loyalty %+15
				@{exodusters In addition, you|When you invite George to interview with you, his demeanor changes noticeably upon your introduction.  You} soon learn that he has heard of @{founded_school_for_the_blind ${blind_school_name}|the Clay Street Foundation} and of your involvement in its founding.  In particular, his nephew is a student there, and George has heard stories of its wonders.
			*if (exodusters = false) and ((founded_school_for_the_blind = false) and (clay_street_foundation = false))
				When George arrives, he stands quietly with his hat in his hand. He answers your questions simply, with "yeses" and "noes" and little in the way of elaboration. He promises hard work and discretion, and you can think of little more that you should ask for.
		*selectable_if (ethnicity != "scotch") #Maeve, an Irishwoman, recently arrived from Cork.
			*set stlouis_valet "Maeve"
			*set stlouis_valet_num 2
			*set valet_he "she"
			*set valet_his "her"
			*set valet_him "her"
			*if ethnicity = "irish"
				*set stlouis_valet_loyalty %+20
				When she discovers that you too were born in Ireland, she immediately warms to you.
				*if compassion < 60
					Some strange corner of your heart is warmed by the presence of her lilt in your haven; it reminds you of home.
		#Ernst, a former Union soldier from Pennsylvania.
			*set stlouis_valet "Ernst"
			*set stlouis_valet_num 3
			Soldier might be a bit of a misnomer; Ernst was an enlistee in the Union Army, yes, but he served in the Quartermaster Corps, organizing the supply of food, pack animals, and munitions for the war effort.
			
			*if background = 7
				*set stlouis_valet_loyalty %+15
				Like you, Ernst is descended from the Hessians of Pennsylvania.  During the interview, he asks if you are related to @{(surname = "Engels") the Engles|the ${surname}s} of Reading.  You grow flustered—he must be referring to the descendants of one of your siblings—and you change the subject.  He does not pick up the topic again.
				*if compassion < 60
					All the same, some strange corner of your heart is warmed by his presence in your haven.

	Of course, you can't just inform ${stlouis_valet} that you are a vampire.  You must make sure that ${valet_he} will be exceedingly reluctant to break the Rule of Reserve.  There are, of course, several tried-and-true methods to compel such silence.
	*choice
		*if (stlouis_valet = "George") and (founded_school_for_the_blind or clay_street_foundation)
			#I am of the opinion that I have already earned George's loyalty due to my philanthropic deeds.
				*set discretion %-5
				*set stlouis_valet_loyalty %+20
				*set stlouis_valet_motivation 6
				On that account you are correct.  He is amazed by your revelation, but he considers himself already in your debt.  His silence is assured.
		#Damn the Rule; I dangle the possibility of becoming a vampire before ${valet_him}.
			*set independence %+10
			*set stlouis_valet_motivation 1
			*set stlouis_valet_loyalty %-10
			The possibility of immortality in exchange for a period of service elicits declarations of loyalty from your new valet.
		#I make sure to dig up some suitable blackmail material on ${valet_him} first.
			*set compassion %+10
			*set discretion %-10
			*set stlouis_valet_loyalty %-20
			*set stlouis_valet_motivation 2
			When you present your findings to ${stlouis_valet}, ${valet_he} is immediately cowed.  You no longer fear betrayal from ${valet_him}.
		*selectable_if (income > 50) #I suspect that cold, hard cash will keep ${valet_him} silent.
			*set income -10
			*set stlouis_valet_motivation 3
			*set stlouis_valet_loyalty %+10
			Your suspicion is correct.  The wealth that you are able to promise ${valet_him} seems to guarantee ${valet_his} silence.
		*selectable_if (charm > 3) #My supernatural charm will keep ${valet_him} loyal.
			*set anachronism %-10
			*set discretion %+10
			*set stlouis_valet_loyalty %+10
			*set stlouis_valet_motivation 5
			It is an exhausting process to adjust someone's attitudes so radically, but over the course of months and years you will bind ${stlouis_valet} to you.
		*if stlouis_valet = "George"
			#I make sure that he knows that his family's lives depend on his coöperation.
				*set compassion %+10
				*set discretion %+10
				*set stlouis_valet_loyalty %-15
				*set stlouis_valet_motivation 4
				George quavers when you present the numerous possibilities for dismemberment to him. He promises on the lives of his nieces and nephews that he will keep your secrets to his grave.

	With your haven established and a valet hired, you begin to feel acclimated to your new home.

*if (heresy_of_masons > 0) and ((observing_kkk) or (joined_kkk))
	Though the mortal Freemason lodges are not something you involve yourself in, you do expend some effort acquainting yourself with them.  You are some surprised, then, to discover that the local lodge was founded by the explorer Meriwether Lewis—a sort of great-uncle to Minor Meriwether, who was so instructive in the recent bankruptcy of Memphis.
*page_break
After spending some time observing the city, you put some thought into how you might integrate yourself with the community.  A vampire needs ${allies}, after all.
*temp knows_spencer_sisters_in_stl false
*if temperance_movement and (wctu = "WCTU")

	If you wish to continue your association with the temperance movement, it will not be through the Women's Christian Association. The WCA does have chapters across the country, but they are all particular to their cities. In St. Louis, the WCTU and the National Women's Suffrage Association are the leading organizations.
*choice
	*if (literate) #@{(creation > 0) I've always fancied myself something of a writer, and|Though I have no talent for writing myself,} these newspapers seem to wield a large amount of influence.
		*set stlouis_enterprise 1
		*set anachronism %+10
		The newspapers of the city are almost entirely an extension of political parties.  The rare exception seems to be the [i]St. Louis Post-Dispatch,[/i] which was recently formed from the merger of the [i]Post[/i] and the [i]Dispatch[/i].  Though it is largely an extension of the Democratic party, its owner, Joseph Pulitzer, and managing editor, John Cockerill, do occasionally buck the party and call out corruption and malfeasance without consideration of the political consequences.
		*goto final_thoughts
	*if (new_orleans_enterprise = 2) or ((whiskey_ring_status = "encouraged") or (whiskey_ring_status = "joined"))
		#I wish to continue my career in the criminal underworld.
			With palms greased and old connections reinvigorated, it is no great matter to acquaint yourself with the criminal element of St. Louis.
			*label enterprise2
			*set shepherd_credentials %-20
			*set stlouis_enterprise 2
			*set income +5
			You are unsurprised to discover that the primary rackets are prostitution, gambling, and extortion.
			*if compassion > 50
				
				Mortals are so unimaginative.
		
			*if stl_met_preston = false
				The most notable scuttlebutt around town is the danger posed by Jerome Preston, the chief of the St. Louis Pinkerton bureau. The various criminal enterprises are convinced that he is not susceptible to bribery and that makes him a significant threat to their operations.
				
			*goto final_thoughts
	*elseif (streetwise > 0)
		#I wish to involve myself with the criminal underworld.
			*set exposure +1
			*if (charm > 2) or (streetwise > 2)
				Your social graces are such that, with some small effort, you are able to acquaint yourself with the notable players in the city.
				*goto enterprise2
			*else
				*set exposure +1
				Unfortunately, your social graces are not such that you are able to establish the appropriate connections. Your inquiries are met with stony silences and sidelong glances.
				*if income > 10
					*set income -5
				*goto final_thoughts
	*if (technology > 0) and ((anachronism > 60) and (intelligence > 1))
		#I wish to involve myself with whatever utopianists and progressives can be found in the city.
			*set anachronism %+20
			*set stlouis_enterprise 3
			The salons of the city are concerned with the ethic of labor and the innovations of science that will relieve humankind of such obligations. In the near future, they posit, all will live in peace and harmony, served by hydraulic- and clockwork-powered servants.
			
			Of course, the real progressives argue that such servants should be treated as sentient beings, and that demanding their labor is tantamount to slavery. But such discussions rapidly fall into arguments with no end.
			*goto final_thoughts
	*if (ethnicity = "german")
		#I @{(new_orleans_enterprise = 4) continue my association with the [i]turnverein.[/i]|will involve myself with the [i]turnverein,[/i] gymnastics clubs with pan-Germanic political overtones.}
			*set stlouis_enterprise 4
			*set shepherd_credentials %-10
			Since the unification of the German Reich in 1871, the [i]turnverein[/i] has become an even more important center of Germanic cultural life in the United States.  In honor of the Fatherland, the immigrants train, compete, and dream together, putting aside the differences of their fractured past.
			*goto final_thoughts
	*if (new_orleans_enterprise = 5)
		#I will continue my role as a patron of the arts.  It's time to bring a little culture to this budding metropolis!
			*label enterprise5
			*set stlouis_enterprise 5
			*set shepherd_credentials %-20
			*set anachronism %+10
			The main artistic contribution of the city is its importation of German music and opera. Hungry for mementos of their homeland, the German immigrants are happy to sponsor exhibitions of spectacles and other demonstrations.
			*goto final_thoughts
	*elseif ((creation > 0) or (feeding_style = "socialites"))
		#I want to patronize the arts in St. Louis.  It's time to bring a little culture to this budding metropolis!
			*goto enterprise5
	*if temperance_movement
		*if (wctu = "WCTU") #I wish to continue my association with the ${wctu}.
			*label join_wctu
			*set stlouis_enterprise 6
			*set anachronism %+20
			*set shepherd_credentials %+10
			The ${wctu} continues its policy of fighting political battles on every front. It seeks to impose a ban on alcohol, gain universal suffrage, Americanize immigrants, abolish tobacco, and otherwise impose bourgeois morality on the entirety of the country.
			
			*if (shepherd_credentials > 65) or ((ethnicity = "african") or (ethnicity = "choctaw"))
				Notably, that morality makes no mention of equality between the races.
			*goto final_thoughts
		*if (wctu = "WCA")
			#I will join the WCTU.
				*goto join_wctu
			#I will join the NWSA.
				*goto join_nwsa
	*if (temperance_movement = false) and (male = false)
		*if (memphis_reception_planner != "Olivia") #I wish to involve myself with the Women's Christian Temperance Movement.
			*goto join_wctu
		#I wish to involve myself with the National Women's Suffrage Association.
			*label join_nwsa
			*set temperance_movement true
			*set stlouis_enterprise 6
			*set wctu "NWSA"
			*set anachronism %+20
			*set shepherd_credentials %+10
			The NWSA—under the leadership of Susan B. Anthony—is not a temperance movement, but rather a suffrage one. It regularly partners with the WCTU and other women's organizations to achieve its goals, however.
			*goto final_thoughts
	*if (intelligence > 1) or ((new_orleans_enterprise = 7) or (technology > 0))
		#I wish to involve myself with Washington University.
			*set stlouis_enterprise 7
			*set anachronism %+10
			*set shepherd_credentials %+10
			*set eliot_rapport %+10
			Named for the the first President of the United States, Washingon University occupies a few buildings in the downtown district. It was cofounded by William Greenleaf Eliot, a Unitarian minister and the brother of Hiram Eliot. Originally founded as a school for continuing education, in recent years it has begun professionalizing into a more formal program complete with fully-employed professors, departments, and students.
			
			It is not long before Eliot learns of your involvement with the University. Presuming beneficient intentions, he thanks you for your attentions.
			*goto final_thoughts
	#I wish to involve myself with the spiritualists and occultists of the city.
		*set stlouis_enterprise 8
		*set rationalism %+10
		*set anachronism %-10
		Spiritualism has flourished in St. Louis since the founding of the First Spiritual Society of St. Louis by the illustrious Andrew Jackson Davis in 1865. The former mayor, Joseph Brown, is a vocal advocate for the movement, organizing lectures and otherwise keeping the flame of belief alive in the city.
		
		Mr. Brown welcomes your interest with open arms. Together, he says, you will bring the awareness of the other side to the people of St. Louis.
		*if (spencer_sister_status > 1) and (spencer_sister_status != 6)
			*set knows_spencer_sisters_in_stl true
			
			In fact, the Spencer sisters fled here from Memphis. They have resumed their ministry, finding willing adherents among those seeking to believe. @{(spencer_sister_status = 7) When you attend one of their revivals, they begrudgingly affirm their ongoing obligation to you.|}
			
			Brown indicates that he is displeased by their presence.
		*elseif spencer_sister_status = 1
			*set knows_spencer_sisters_in_stl true
			*set spencer_sister_status 2
			
			Much to the chagrin of Brown, there are a pair of sisters, Peg and Susie Spencer, who have recently established themselves in St. Louis. Peg is a medium, who communicates with the dead, while Susie preaches the liberation of women and the parity of the sexes. The two have found quite a following among the poor and downtrodden.
		*goto final_thoughts

*label final_thoughts
*if stlouis_enterprise >= 7
	
	Besides this, you also learn of the St. Louis Insane Asylum. Though situated well within the boundaries of the city as defined during the Great Divorce, the magnificent building was the site of a skirmish last year between the mayor and some St. Louis County judges, as the judges sought to occupy the building and claim it for the county. It was a bizarre incident, but one where Mayor Overstolz came out on top.
	
	Besides being a bit of an architectural marvel, the building itself is the first public psychiatric institute west of the Mississippi. @{(stlouis_enterprise = 8) While the doctors and physicians of the city praise it for its scientific rigor and hygenic facilities, rumors of it being haunted by the ghosts of those who have died within its walls abound.|}
*gosub household_maintenance
*gosub define_opium_fiend
*page_break
*set year 1879
*if (knows_spencer_sisters_in_stl = false) and ((spencer_sister_status != 6) and (spencer_sister_status > 1))
	
	Additionally, you observe that the Spencer sisters have reëstablished themselves in St. Louis, following their departure from Memphis. @{(spencer_sister_status = 7) When you attend one of their revivals, they begrudgingly affirm their ongoing obligation to you.|} Their revivals continue to be quite the @{temperance_movement draw, much to the consternation of the ${wctu}. The temperance workers would much rather the women of St. Louis heeded their calls to restraint than concern themselves with mysticism and heresy. The two groups find themselves at cross purposes|draw}.
	*page_break
*if trans
	*set eliot_rapport %+10
	
	One fine evening, while out on the town, you encounter Eliot. He stumbles for a moment upon recognizing you. "Hello!"

	"Oh, yes," you say, gesturing towards your clothes. "You can call me ${given_name} ${surname} now."

	"${given_name} ${surname}." He rolls it around in his mouth. "You'll have to forgive me, it will take a minute."

	"No doubt."

	"Has this been…long in coming?"

	You wince a little. "No, I just woke up one evening and decided I felt different."

	Eliot winces in return, recognizing his blunder. "I'm sorry…"

	"It's alright. Next time, you'll know."

	"So I will."

	The awkwardness aside, the two of you stand and chat for a time, until your respective obligations pull you in separate directions.
	*page_break
There is a feeling which you find yourself experiencing periodically: that some sort of shadowy cabal pulls the levers of power in the world, deciding outcomes at levels which you cannot comprehend. And you're a vampire, cognizant of the machinations of your kind!

The magnificent Eads Bridge, which you utilized when you entered St. Louis, was bought at auction the year after it opened for twenty cents on the dollar. Its production was always under-capitalized, and the corporation declared bankruptcy not long after an elephant was used to demonstrate its safety. The New-York banker, JP Morgan, was one of the creditors who shared in the new ownership. Two years later, through some financial and judicial chicanery, Morgan asserted complete control over the bridge. He then leased the bridge to the industrialist Jay Gould and Gould's railroad empire. Thus, Gould has had a monopoly on cross-river traffic, imposing a tariff on every railcar to pass over the Mississippi.

Gould is variously celebrated and condemned in the newspapers and his name is on the lips of the elite of the city: is he a visionary, making the future by force of will, or is he a corrupt monopolist, exploiting the workers of the world and squeezing blood from every stone within reach?

*choice
	#Sometimes opportunity must be seized—regardless of the collateral damage—for the betterment of all.
		*set laborvscapital %-10
		*set compassion %+5
		You can sympathize with Gould's actions: sometimes the few must be sacrificed for the benefit of the whole.
	#I admire the man for his conscience-free vision of the future.
		*set laborvscapital %-5
		*set anachronism %+5
		*set discretion %+10
		As they say, "Fortune Favors the Bold." And no one can deny the boldness of Jay Gould.
	#Gould's actions are reprehensible and he should be punished.
		*set laborvscapital %+15
		*set compassion %-5
		Perhaps someday you will have the opportunity to punish him yourself.
	#I suspect that Gould cares nothing for morality—an admirable trait in a mortal.
		*set compassion %+10
		You can't help but think that Gould might make a good vampire.
	#His actions may be reprehensible, but they did not raise my ire until they affected my city.
		*set justice %+5
		*set discretion %+5
		*set shepherd_credentials %+5
		You begin to consider how you might thwart Gould's plans.

Besides the bridge, Gould owns several railroads that extend from St. Louis to the south and west, including the famous Union Pacific Railway. Together, he controls much if not most of the rail traffic of the west that does not pass through Chicago.

Gould periodically travels to St. Louis to supervise those things done in his name. Now happens to be one of those occasions. Unsurprisingly, a protest has been organized outside the Planter's House Hotel where he is staying.
*choice
	#As long as Gould leaves me alone, I will leave him alone.
		*set shepherd_credentials %-10
		A small protest does manifest, but it is so small that the police don't even bother to beat any of the protestors.
		*goto after_gould
	#I try to suppress the protests.
		*set shepherd_credentials %+5
		*set laborvscapital %-10
		*if joined_kkk or (stlouis_enterprise = 2)
			*set local_fame %+10
			*set stlouis_business_climate %+5
			*temp thugs "hardened thugs"
			*if joined_kkk
				*set thugs "former Confederates"
			The protest itself is a sorry affair, with barely a hundred attendees. They are not prepared for a band of ${thugs} to show up with batons and the desire to crack skulls.
			
			The police stand by and let the thugs beat the protestors, only stepping forward to arrest the protestors once the thugs have departed.
			*goto after_gould
		*elseif charm >= 3
			*set local_fame %+5
			*set stlouis_business_climate %+5
			You urge the protestors to go home. Gould is not their enemy! They should look instead to their own vices as the sources of their misery. They should accept personal responsibility for their conditions, and not try to blame others for their misfortunes.
			
			Persuaded by your words, @{(charm > 3) many|some} of the protestors disperse.
			
			You can't say that you had a large effect on the labor movement today, but every demoralizing event will hasten its decline.
			*goto after_gould
		*else
			*set local_fame %+5
			Your exhortations come to naught. The protest happens, and even without your efforts it is a sorry affair. The police don't even bother to beat anybody.
			*goto after_gould
	#I try to urge more people to attend the protest.
		*set shepherd_credentials %+5
		*set laborvscapital %+10
		*if (stlouis_enterprise <= 2) or (charm > 3)
			*set local_fame %+15
			*set stlouis_business_climate %-5
			The protest swells larger than anyone was expecting. No one is more surprised than the protestors themselves.
			
			By the time the sun sets, the police wade into the crowd with batons and begin forcibly dispersing the protestors. At least two people die amid the violence.
			
			You can't say that the protest changed anything about Gould or his policies, but it showed the participants that numbers matter, and that the numbers exist. And that matters.
			*goto after_gould
		*else
			*set local_fame %+5
			Your exhortations come to naught. The protest still happens, mind you, but it is a sorry affair. The police don't even bother to beat anybody.
			*goto after_gould
	#I seize the opportunity to feed on him.
		*if (charm > 3) or ((charm = 3) and (local_fame > 50))
			*set fed_from_gould true
			*achieve fedongould
			You manage to talk your way into his inner circle and even steal a few moments with him alone. 
			*label drink_gould
			You waste no time in drinking his blood. @{(perception > 1) It tastes…dry. Cold. Like his heart has already stopped.|}
			*goto after_gould
		*elseif joined_stl_masonic_lodge
			Through your connections with the Freemasons, you arrange access to Gould's inner circle while he is in town. Once that is achieved, it is only a quick matter to get him alone for a few minutes.
			*goto drink_gould
		*else
			Unfortunately, you can find no way to gain access to his circle of acquaintances while he is in town.
			*goto after_gould
			
*label after_gould
*page_break
As the autumn and winter of 1879 wears on, battle lines in Stone's revolution are drawn more firmly. Those that support his deeds are referred to as Revolutionaries, while those who oppose him become known as Loyalists.
*if revolutionary_credentials > 55
	*set revolutionary_credentials %+10
	*set bailey_rapport %+5
	*set memeskia_rapport %+5
	Whether you had intended to or not, your actions have garnered you the reputation of supporting the Revolutionaries.
*elseif revolutionary_credentials >= 45
	*set aichinger_rapport %+5
	Whether you had intended to or not, your actions to date do not firmly place you in either camp.
*else
	*set revolutionary_credentials %-10
	*set aichinger_rapport %+10
	*set bailey_rapport %-10
	*set memeskia_rapport %-10
	Whether you had intended to or not, your actions have garnered you the reputation of supporting the Loyalists.

*if flirting_with_withers
	*if wilson_embraced_by_withers and (maddox_status = "shirked")
		${maddox_status}
		*page_break
		*bug
	About this time, you receive a letter from Quaestor Withers.
	*if literate
		Opening it, you find a poem written in your honor.
	*elseif compassion < 55
		*set stlouis_valet_loyalty %+5
		You ask ${stlouis_valet} to read it aloud; you turn a muted shade of crimson as you realize that it is a poem in your honor. ${stlouis_valet} does ${valet_his} best to conceal ${valet_his} amusement at your discomfort.
	*else
		*set stlouis_valet_loyalty %-5
		You ask ${stlouis_valet} to read it aloud; you listen dispassionately as you he reads a poem composed in your honor. ${stlouis_valet} coughs uncomfortably at a particularly lurid moment, but does his best to continue without losing the rhythm of the piece.
	*if creation <= 1
		You are no judge of poetry, but you can detect no flaw in its composition.
	*elseif creation = 2
		You admire both her use of imagery as well as her deployment of literary devices.
	*else
		The poem is well-crafted, if indicative of an underdeveloped talent. Perhaps, in time, she could become a true wordsmith, but that time is not yet now.
	*if (maddox_status = "freed")
		Apparently, she has not yet realized that you let ${maddox} go.
	
	*choice
		*if (choice_randomtest = false) #I do not bother to reply.
			*set flirting_with_withers false
			*set withers_rapport %-10
			*set discretion %-5
			Sometimes silence is its own message. Withers will understand.
		*if ((creation > 2) and literate) #I reply to Withers with a critique of the poem, pointing out how some of her metaphors are a mess, and how she could better use tmesis to illustrate one particular image.
			*set discretion %+3
			*set flirting_with_withers false
			You send off your critique with the suggestions on how she could improve it.
			
			You wait for a response, but none is forthcoming. Curious.
		#I @{literate write her|dictate} a heartfelt reply.
			*set withers_rapport %+5
			You send the letter off, hoping that it is well-received.
			
			It is.
		*if ((creation > 0) and literate) #I write her my own poem in reply.
			*set withers_rapport %+(creation * 5)
			You craft your own poem in reply and send it off once you are satisfied with it. You @{(creation + 1) ERROR|hope|suspect|imagine|know|know|know} that she will appreciate it.
			
			She does.
*finish Next
	
*label household_maintenance
*if (income <= 4) and (income > 0)
	*set income -1
	*if haven_value > 25000
		*set haven_decrepit true
		*set haven_value * 0.85
		*comment PC is unable to sufficiently maintain the property.
*if income > 4
	*set income -4
	*if (haven_value < 25000) and (renter = false)
		*set haven_value *4
*return