*comment ñáéç…—
*hide_reuse
*advertisement
*temp which_honkey_tonk 0
*rand which_honkey_tonk 1 2
*temp target "none"
*temp tavern "tavern"
*temp hunt_status "none"
*temp quarry_ethnicity "none"
*temp fix_thomas false
*if (stlouis_valet_num > 4)
	*set stlouis_valet_num -4
	*set fix_thomas true
	*if (stlouis_valet_num <= 1) and choice_quicktest
		*set stlouis_valet_num 1
*if skip_hunting_check
	*set skip_hunting_check false
	*goto_scene stlouis_cockerill
You jerk to wakefulness.

The hunger prowls within you.  Tonight, you will drink.
*page_break
As you tend to your toilette, you begin to fantasize about what the evening will bring.  As has been your wont,
*if (feeding_style = "artists")
	*if (ethnicity = "african") or ((ethnicity = "choctaw") or ((anachronism > 80) or (compassion < 25)))
		*set anachronism %+10
		you have been enjoying the community of "ragtime" musicians that has begun to dominate the black social scene.  The new style of music excites you in a way you haven't felt in a long time, and you tend to luxuriate on the dancefloor once the hot blood begins to course through your veins.
	*elseif (ethnicity = "german")
		you have acquainted yourself with the classical musicians of the city. There are a number of Germans who have immigrated in the past twenty years, seeking an escape from the conflicts there.
	*else
		you have gained entrée to the salons of the city, from which you can acquaint yourself with the artists of the city.
*elseif (feeding_style = "children")
	you have preyed indiscriminately upon the innocent.  The purity of their souls communicates directly to their blood.
*elseif (feeding_style = "clergy")
	@{(religious_tradition = "catholic") you have frequented the parish churches of St. Louis.|you have acquainted yourself with the ministers and missionaries of the city.}
*elseif (feeding_style = "drunks")
	*if ethnicity = "german"
		you have frequented the biergartens of Dutchtown.
	*elseif ethnicity = "irish"
		you have frequented the saloons of the Kerry Patch.
	*else
		you have frequented the saloons of the city.
	Curiously, much of the city has taken pride in the spreading popularity of Lemp and Anheuser-Busch beers; their consumption becomes a point of pride that crosses ethnic lines.
*elseif (feeding_style = "gamblers")
	you have frequented the gambling-dens of the city.  Keno is the game of choice in the city, and despite regular raids by the Metropolitan Police, another game is always at hand.
	
	It's a curious game involving no skill—just superstition. For every round, players choose twenty numbers between one and eighty, marking them on a play card. The master of ceremonies has a basket with slips of paper or uniform objects—some way to randomize the number being drawn. Periodically, he pulls out a slip and announces the number, and the players mark their matches. Once the master of ceremonies has called out twenty numbers, payouts are made based on the number of matches on a card. Players frequently reuse cards, believing in the power of their lucky numbers.
	
	@{taught_crapaud You are somewhat disppointed that crapaud has not found wider acceptance here. It is far more refined and, frankly, compelling than keno.|}
*elseif (feeding_style = "itinerants")
	you have spent time in the taverns and saloons along the waterfront. There, the you are best able to find travelers and traders, even if they only come from the other river cities.
*elseif (feeding_style = "laborers")
	you have made your way through the shantytowns at the edge of the city, becoming acquainted with the laborers and tradesmen who reside there.
*elseif (feeding_style = "merchants")
	you have spent your time becoming acquainted with the shopkeepers, merchants, and accountants of the city. 
*elseif (feeding_style = "prostitutes")
	you have made the most of the buoyancy of the times.  The practitioners of the world's oldest profession flocked to Memphis during the war, but their prevalence has receded somewhat in the interim.  All the same, you welcome the breadth of choices on any given evening.
*elseif (feeding_style = "socialites")
	you have gained entrée to the salons and social clubs of the city.
*elseif (feeding_style = "soldiers")
	you drink on the blood of soldiers—both Confederate and Union.  However, this population has begun to age, and the veterans of the Indian Wars to the west are few and far between.  You have taken to feeding from the recently organized Metropolitan Police Department, as well as any of the various independent private watchmen.
*elseif feeding_style = "vegetarian"
	you have staked out the various slaughterhouses of the city, assuring yourself of the proximity of blood as you might find it necessary.
	*set feeding_style "vegetarian"
	*achieve vegetarian
*else
	*bug

Standing, you wipe your hands on a towel and wonder if tonight is a night for something different.
*choice
	#Yes, it is time for a change.
		*set anachronism %+10
		Who, then, will you seek out tonight?
		*choice
			*if (feeding_style != "artists")
				*selectable_if (creation > 0) #The blood of artists and musicians calls to me.
					*label artist
					*set bloodflow +2
					*set feeding_style "artists"
					*set target "musician"
					*goto tavern_sort
			*if (feeding_style != "children") and (stealth > 2)
				*selectable_if (compassion > 40) #The blood of the innocent calls to me.
					*label children
					*set bloodflow -1
					*set target "child"
					*set feeding_style "children"
					*goto soiree
			*if (feeding_style != "clergy")
				#The blood of the holy calls to me.
					*label clergy
					*set bloodflow -1
					*set target "clergy"
					*set feeding_style "clergy"
					*goto soiree
			*if (feeding_style != "drunks")
				#The blood of the intoxicated calls to me.
					*label drunks
					*set bloodflow +3
					*set feeding_style "drunks"
					*set target "drunk"
					*goto tavern_sort
			*if (feeding_style != "gamblers")
				*selectable_if (streetwise > 0) #The thrill of the win and the loss calls to me.
					*label gambler
					*set feeding_style "gamblers"
					*set target "gambler"
					*goto tavern_sort
			*if (feeding_style != "itinerants")
				*selectable_if (discretion < 75) #I think I should be more careful, and drink from those travelers no one will miss.
					*label traveler
					*set bloodflow +1
					*if exposure > 3
						*set exposure -1
					*set feeding_style "itinerants"
					*set target "traveler"
					*goto tavern_sort
			*if (feeding_style != "laborers")
				#The blood of the worker calls to me.
					*label laborer
					*set bloodflow +1
					*set feeding_style "laborers"
					*set target "carpenter"
					*goto tavern_sort
			*if (feeding_style != "merchants")
				*selectable_if (finance > 0) #The blood of the bankers and investors calls to me.
					*label merchant
					*set target "shopkeeper"
					*set feeding_style "merchants"
					*goto soiree
			*if (feeding_style != "prostitutes")
				*selectable_if (streetwise > 0) #The blood of men and women of the night calls to me.
					*label prostitute
					*set bloodflow +1
					*set feeding_style "prostitutes"
					*set target "prostitute"
					*goto tavern_sort
			*if (feeding_style != "socialites")
				*selectable_if (charm > 2) #The blood of the wealthy and high-born calls to me.
					*label socialite
					*set bloodflow +1
					*set target "debutante"
					*set feeding_style "socialites"
					*goto soiree
			*if (feeding_style != "soldiers")
				*selectable_if (fighting > 0) #The blood of soldiers calls to me.
					*label veteran
					*set feeding_style "soldiers"
					*set target "veteran"
					*goto tavern_sort
			*if (feeding_style != "vegetarian") and (knows_about_vegetarianism)
				*selectable_if (willpower > 2) #I abjure the blood of mortals.
					*label stockyard
					*set bloodflow -1
					*set feeding_style "vegetarian"
					Visiting the stockyards is easy enough. The cattle look up at you with their big, dumb eyes and barely seem to notice when you sink your fangs into the veins at their ankles. 
					*if shapeshifting > 1
						*set bloodflow +2

						Thanks to your ability to command such beasts, however, you are able to make the whole process somewhat more…pristine. Sure, they're dirty and smelly, but when you order them to approach, to lay down, to roll over, they do so. It makes feeding from them so much easier.

						Part of you is conflicted by the fact that these animals are intelligent enough to understand your commands, and yet you feed from them still. At least they're not human, though.
					*else
						Climbing through the mounds of their shit is less pleasant, but you remain dedicated to your cause of doing no harm to humans, despite how many outfits it costs you.
						*if income > 5
							*set income -1
						And it does cost you, in both clothes and shoes. And time spent traipsing out to the stockyards and back. But you remain smug in your ethical superiority.
					*finish
	#No, I am convinced of the excellence of my choice.
		*set discretion %+10
		*label hunt_old
		*if (feeding_style = "artists")
			*goto artist
		*elseif (feeding_style = "children")
			*goto children
		*elseif (feeding_style = "clergy")
			*goto clergy
		*elseif (feeding_style = "drunks")
			*goto drunks
		*elseif (feeding_style = "gamblers")
			*goto gambler
		*elseif (feeding_style = "itinerants")
			*if exposure > 3
				*set exposure -1
			*goto traveler
		*elseif (feeding_style = "laborers")
			*goto laborer
		*elseif (feeding_style = "merchants")
			*goto merchant
		*elseif (feeding_style = "prostitutes")
			*goto prostitute
		*elseif (feeding_style = "socialites")
			*goto socialite
		*elseif (feeding_style = "soldiers")
			*goto veteran
		*elseif (feeding_style = "vegetarian") and (knows_about_vegetarianism)
			*achieve vegetarian
			*goto stockyard
		*else
			*bug should be no other feeding style
	#No, I think it best not to risk a change.
		*set anachronism %-10
		*set discretion %-10
		*goto hunt_old

*label tavern_sort
*gosub hunting_stat_check
*gosub hunt_intro

*if ((which_honkey_tonk = 2) and (stlouis_haven != "kerry")) or (stlouis_haven = "chestnut")
	*set tavern "saloon"
	*set three_eyed_jack_visited true
	*set anachronism %+5
	*set quarry_ethnicity "irish"
	*set heard_ragtime true
	
	The Three-Eyed Jack is a saloon in Chestnut Valley, frequented by reprobates of all stripes. The building is a small warren of rooms, offering quiet spaces for card games and sex work. On the stage, a black man plays a piano and sings with aplomb. The music has a peculiar beat which
	*if (anachronism > 65) or (creation > 1)
		you find intriguing.
	*else
		irks your sensibilities.
	You overhear that the style is called "rag," but no one seems to know what the word means. It's vaguely familiar—you've heard similar strains before—but tonight is the first you've stopped to muse on the sound more deeply.
	*if (perception > 1) and (compassion < 40)
		Interestingly, the pianist is not the only black person visible. There are a handful of patrons at the bar with varying shades of skin-tone. You also notice several such patrons going in and out of the back rooms.
		
	Not too deeply, though; there is quarry at hand.
	*label quarry
	*page_break

	*if feeding_style = "prostitutes"
		*goto hunt_prostitute
	*if feeding_style = "gamblers"
		Whereas most honkey-tonks around town make some effort to hide their card-rooms, at the Three-Eyed Jack no such discretion exists. You open the door to the back room and within moments have set your sights on your quarry. 
		
		A few dollars lost over a several hands of cards and you are fast friends with several in the room. 
		*if speaks_english = false	
			As long as you keep losing money, they don't even care that you don't speak English.
		From there, you seize the opportunity to separate your prey from the herd.
		
		*if (perception > 1) and (charm > 2)
			Your quarry fancies himself a cardshark, slipping an ace from his sleeve when he thinks no one else is watching. But you are watching and you are more than willing to use this tidbit of information.
			
			A few choice words and you find yourself alone with the young man. His smile is fast, and fades just as fast when he realizes what you actually want from him.
			
			Thankfully, the haze of feeding will erase anything more than a sense of forboding by the time he wakes up.
			*goto chapter_end
		*else
			*goto quarry_acquired
	Your eyes settle on a ${target} sitting at the bar, alone.
	*if target = "veteran"
		Though his beard is now grizzled, he still has the bearing of a soldier.
	He taps his foot in time with the music.
	*if hunt_status = "success"
		You sidle up beside him, place an order with the bartender, and shortly engage him in conversation. 
		*if speaks_english = false
			You are somewhat embarrassed by the discovery that you do not share a common tongue, but by this point you've learned how to mimic a considerate listener.
		He is flattered by your attentions—it seems that few are interested in the stories he has to tell—and adjourning to a quiet table in the corner requires little in the way of persuasion. Once sequestered, it is only another half-hour before you've managed to take what you need and leave him a tad woozy and already lamenting his drinking habit.
	*elseif hunt_status = "marginal"
		You sidle up beside him, place an order with the bartender, and shortly engage him in conversation. He is flattered by your attentions—it seems that few are interested in the stories he has to tell—and adjourning to a table requires little in the way of persuasion. Unfortunately, the table you had planned to use is filled just as you move to take it, and the two of you are forced into a more conspicuous position.
		*if discretion > 45
			*set exposure +1
			Not that you really care. When the opportunity presents itself, you take what you came for. 
			
			Wiping your lips, you leave the ${target} to nurse his beer and his headache.
			*goto chapter_end
		*else
			Though it takes longer than you would like—and ends with the ${target} getting more drunk that you had intended—you finally position yourself in such a way that you will not be exposed when you drink your fill.
			
			When you are finally done, you wipe your lips and disappear into the night. Not that your companion was cognizant enough to notice.
	*elseif hunt_status = "physical"
		*set exposure +1
		It takes almost two hours for the moment to arrive. You sit patiently—watching without watching—until he stands and heads towards the outhouse.
		
		*if compassion < 45
			You decide to wait for him to conclude his business there before you confront him and send him sprawling with a quick sucker-punch to the jaw. Feeding is much more enjoyable without the odor of urine filling your nostrils.
		*else
			You sucker-punch him across the jaw and he goes sprawling. You drop to one knee, only to be greeted by the stench of urine. You have a tendency to forget that when these pesky mortals need to use the outhouse, it's because they need to use the outhouse. You try not to let it ruin your supper.
			
		You're aware of rustling in the darkness around you; you're not alone out here behind the ${tavern}, but neither does anyone bother you. This is not the place to confront injustice, you suppose. When you have drunk your fill, you wipe your mouth and disappear into the darkness.
	*else
		*set exposure +2
		*set wealth -100
		Though you do not care for the consequences, you find it necessary to lubricate the situation with a good number of drinks. Your new friend the ${target} seems reticent to position himself in such a way that you can take what you need without raising eyebrows. Finally, though, he slips past the point of self-control and you are able to sink your aching fangs into his wrist to drink.
		
		When you stand to leave, the proprietor—eyes suddenly wide when he sees your face—demands payment for the table's bill; you look at the unconscious ${target}, and with a growl of disgust drop a few coins on the table.
		
		Once outside, you wipe your mouth. Suddenly, you understand the fear in the proprietor's eyes. You suppose you will not be returning there anytime soon.
	*goto chapter_end
*else
	*set quarry_ethnicity "german"
	The Lafayette Brewery and Tavern sits on Cass Avenue, amid the architectual riot of the Kerry Patch. The buildings along Cass are relatively stable and permanent-looking, but the homes down the side streets are a mess of primarily clapboard shacks. @{(stlouis_haven = "kerry") In other words, home.|}
	
	The Tavern is frequented by the locals who can afford it; there are several saloons on the side streets who serve an even more destitute clientele. It's owned by a German—and a Lutheran at that—but the food is good and the beer plentiful, so the customers keep their grumbling to a minimum.
	
	Every evening, a rotating set of musicians perform. Piano, fiddle, clarinet, trumpet…the exact composition varies, but the music is lively. They play traditional Irish songs, as well as some of the variations and innovations that have developed over the past two hundred years in the United States.
	
	*if feeding_style = "artists"
		*set target "fiddler"
		It's not difficult to accost the fiddler during one of his breaks. He speaks with a thick brogue; apparently, he only recently arrived in St. Louis via New Orleans. His breath stinks of whiskey.
		*label quarry_acquired
		
		*if ((charm > 2) and (stealth > 1)) or (hunt_status = "success")
			A few sweet words and he agrees to sit with you in a dark corner of the ${tavern}. The lights are already low, and no one gives any thought to an intimate moment between two patrons. It's easy enough to take what you want and be on your way with no one the wiser.
		*elseif (hunt_status = "marginal")
			*set exposure +1
			Your allure is such that your prey is only too happy to follow you into the alley behind the ${tavern} for a rendezvous. When your fangs sink into his neck, all thoughts of protest flee his mind. He'll wake in an hour or so with a sore neck and a hazy memory of pleasure and terror.
		*else
			Adopting the swagger and good cheer of beerhall camaraderie, you manage to guide the ${target} into the alley behind the ${tavern}. Once there, a quick blow 
			*if (strength > 2) or ((fighting >= 2) or (agility > 3))
				to the jaw drops him to the ground.
			
				You take a few coins from his pocket and blood from his veins before leaving him reclining amid a stack of barrels.
				*set exposure +1
			*elseif (willpower > 2)
				*set exposure +1
				glances off his jaw. His head swivels back, anger flashing in his eyes. A moment later, he's landed an uppercut and you see stars.
				
				You stagger back. The beast growls inside you, but you push it down. The man steps forward, intent on punishing you for your hubris. You dodge his next blow, knock an empty barrel into his path, and fleet the alley as quickly as your feet will take you.
			*else
				*set compassion %+15
				*set exposure +1
				glances off his jaw. His head swivels back, anger flashing in his eyes. A moment later, he's landed an uppercut and you see stars.
				
				Little does he realize that he has just signed his death-warrant.
				*page_break
				A few moments later, you wipe the blood from your mouth and cheeks. The ${target} lies at your feet.
				
				*if discretion > (60 + (bloodflow * 2))
					*set exposure +2
					You step over the cooling body and make your way home.
				*else
					You do your best to disguise your crime before fleeing the scene.
		*goto chapter_end
	*elseif feeding_style = "drunks"
		Here, you have your choice of victims. Everyone is inebriated to some degree or another. You select a comely one—as comely as he can be under the layers of sweat and dirt from a long day's work—and begin your approach.
		
		*if (hunt_status = "success") or (hunt_status = "marginal")
			Your wiles are, of course, irresistible. 
			*if speaks_english or speaks_german
				Though, you must admit, you're uncertain how he can appreciate them through the haze of whiskey that clouds his breath and surely his vision. 
			*else
				Not that he comprehends their wit or sagacity. You suppose that, as long as you keep buying drinks, he'll listen to you in any language.
			But no matter; you take what you came for and set out on your way without raising so much as an eyebrow.
		*else
			Your efforts at privacy are either miserable failures, 
			*if speaks_english or speaks_german
				or your quarry is simply too drunk to understand the implication of your words. 
			*else
				or your lack of English is more of an interference than you had anticipated.
			You order another round to further lubricate the situation, though you've barely touched your drink. Apparently, he's not too drunk to notice your temperance, which he apparently takes as a character flaw. His sneer would be epic if it weren't ruined by his intoxication.
			*set wealth -50
			
			Thankfully, you suppose, a few sips more of his beer and the fool discovers that he needs to visit the outhouse behind the ${tavern}. Following him outside, you take what you need and go on your way.
		*goto chapter_end
	*elseif feeding_style = "gamblers"
		*if wealth > 500
			*set wealth -500
		*if wealth > 1000
			*set wealth -1000
		*if (charm > 3) or ((streetwise > 2) or ((perception > 2) and (charm > 2)))
			It takes some effort, but you are able to gain access to the private room where half a dozen men hunch over a hand of cards. @{speaks_english |As long as you keep losing money, they don't even care that you don't speak English.} The participants glance at you with some suspicion, but soft words and money lost soon put them at ease.
			
			Eventually, you settle on a loud-mouthed horse-breaker from eastern Kentucky. He's only too happen to listen in private to your @{male ideas about potential business opportunities.|sweet nothings.}
		*else
			Your efforts to solicit word of a card game sees you two buildings over, at a much danker establishment. Here, cards are played openly amid a riot of noise and beer. Your not even sure what the name of the establishment is—maybe it doesn't have a name—but you soon select a target and begin to separate him from the herd.
		*goto quarry_acquired
	*elseif (feeding_style = "itinerants") or (feeding_style = "soldiers")
		You shake away these thoughts, though. You are here for a different purpose.
		*goto quarry
	*elseif (feeding_style = "laborers")
		It's actually not so easy to find a laborer among this crowd; the room is filled more with small business owners, clerks, and other petite bourgeouisie.
		
		Finally, you settle on a waiter. It takes several minutes for you to find your approach, but soon you see an opening: an outturned leg trips the waiter, who falls into your arms. The waiter blinks and blushes, but you put him on his feet. @{male |He seems all the more embarrassed that it's a woman who has salvaged his evening.} @{speaks_english |You reply, and he is further embarrassed that cannot thank you in your own tongue.}
		
		A few minutes later, 
		*if speaks_english
			you're able to strike up a longer conversation with the waiter between rounds.
		*else
			he returns, doing his best to pantomime a larger expression of gratitude. You dismiss his thanks, but make sure to communicate your interest in other activities.
		*if (charm > 2) and (stealth > 1)
			You're able to guide him carefully into a corner of the ${tavern}, where a quick nip at his throat goes unnoticed by him and the other patrons.
		*elseif (charm > 2)
			You have to stay late, late enough for the waiter to be released. He is only too happy to meet you outside. What he thought was going to be a simple tryst is not quite that idyllic. You leave him, still breathing, in the alley. He'll wake in an hour or so with a sore neck and a hazy memory of pleasure and terror.
		*elseif (strength > 2) or (fighting >= 2)
			*set exposure +1
			You have to stay late, late enough for the waiter to be released. He is only too happy to meet you outside. A quick blow to the back of the neck and he crumples. You leave his pockets a little lighter, and take what you need from his veins.
		*else
			*set exposure +1
			*set wealth -100
			You have to stay late, late enough for the waiter to be released. He is only too happy to join you for another drink.
			
			Unfortunately, it requires several more drinks before you can take what you want from him.
		*goto chapter_end
	*elseif feeding_style = "prostitutes"
		*label hunt_prostitute
		Convincing a lady of the evening to find a few moments alone with you is easy enough; what's difficult is slipping away without paying for her services.
		*if tavern = "tavern"
			Moreover, the Lafayette Tavern tries to maintain a certain amount of propriety; the women must be comparatively discreet.
		*if (charm > 2) and ((stealth > 1) and (perception > 1))
			You, however, have wiles of your own. You don't even have to go to a room; she sits @{male on your lap|at your side} and laughs at your @{speaks_english jokes.|jokes, even if she doesn't understand your tongue.} You then surprise her by taking a few moments to listen to what it is she has to say. Before long, no one cares that you are necking in the corner. She certainly doesn't. 
			
			You leave her feeling a little woozy but otherwise none the worse for wear.
		*elseif (charm > 2)
			Within ten minutes or so, you retire upstairs with your prey. @{speaks_english |It doesn't even matter than you don't share a language; your desires are clear enough.} When you have her to yourself, you're able to take what you need and slip away without a fuss.
		*else
			*if wealth > 2000
				*set wealth -2000
			Within ten minutes or so, you retire upstairs with your chosen victim. @{speaks_english |It doesn't even matter than you don't share a language; your desires are clear enough.} Unfortunately, your charms are not such that you can escape without paying for your services; the madame is not amused when you try to slip by without doing so. She upbraids you before demanding a surcharge. You hand over the money and leave.
		*goto chapter_end
	*else
		*bug there are no other feeding styles that should reach here.

*label soiree
*gosub hunt_intro

*if (stealth > 3) and (anachronism > 50)
	Due to your command of the powers of misdirection, you can move among the mortals while making them ignore the details of your face and skin.
	
	Therefore, you may choose from which community you would like to feed:
	*choice
		#From the community of freedmen.
			*goto wheelers_party
		#From the Democrats and former Southerners.
			*goto overtons_home
		#From the Catholics.
			*goto kenrick_something
		#From the Northerners.
			*goto stone_home
*elseif met_wheeler_and_turner and ((ethnicity = "african") or (ethnicity = "choctaw"))
	Due to your work with the Committee of Twenty-Five, you are frequently invited to celebrations involving its leadership. This particular week, John Wheeler has organized an evening of entertainment at his home. @{(ethnicity = "choctaw") James Milton Turner will be there as well; of late, he has taken it upon himself to lobby for the honoring of treaties with your kinsmen.|}
	
	You can think of no better place to encounter the sort of prey you seek.
	*goto wheelers_party
*elseif ethnicity = "african"
	
	It does not take much for you to gain entrance to the drawing rooms of Chestnut Valley and from there into the social circle of John Wheeler.
	
	Wheeler plays a large role in local politics, having come to prominence with his support of the Exodusters. When he meets you, he greets you as on old friend and welcomes you into his home. He tries to place your accent—after working with the Exodusters, who came from plantations up and down the Mississippi—he has an ear for the different parishes.
	*if anachronism < 65
		Unfortunately, it's the temporal quality of your accent that throws him off, rather than the spatial; you were born before 1800, after all. He is truly fascinated by your speech, and insisted that you return for a soirée that he was organizing.
	*else
		Though you have managed to obscure your most provincial pronunciations over the decades, it leaves your words slippery in a way that intrigues him. You do your best to deflect his more pointed questions and finally he decided that you simply had to attend a soirée that he was organizing at his home.
	
	How could you say no? And so tonight is the night and you have prepared yourself appropriately.
	*label wheelers_party
	*temp minister "minister"
	*set quarry_ethnicity "african"
	*gosub hunting_stat_check
	*page_break
	The home is modest, but well-tended. Its greatest luxury is a yard behind the house. Whereas the neighbors all grow vegetables with their small plot of land, Wheeler has turned it into a social space for events such as these. Small lanterns and candles illuminate the area, and a sturdy wooden platform offers a stage for both the string quintet and the dancers.
	
	*if met_wheeler_and_turner = false
		One of the luminaries of the evening is James Milton Turner, a freedman and recent Ambassador to Liberia. You manage to shake his hand, but his entourage prevents a more serious conversation with him.
		*if (target = "socialite") and (perception > 1)
			Unfortunate, as you suspect his blood would have been…pleasantly tangy.
	*set met_wheeler_and_turner true
	
	*if exodusters and (perception > 0)
		Over the course of the night, you catch the little hints and looks that distinguish the Exodusters from the locals. The integration of the refugees—even now, over a year later—has been mixed at best.
	
	Moving from conversation to conversation, you search for tonight's meal.
	*if target = "shopkeeper"
		*set minister "tobacconist"
		There are many small businessmen here: shopkeepers, wholesalers, entrepreneurs, and salesmen. It is a banquet of delights. 
		
		Soon, you settle on a tobacconist.
		*if (hunt_status = "success") or (hunt_status = "marginal")
			*if speaks_english = false
				He is all the more happy to have made your acquaintance once he discovers that you are from Louisiana as well.
			He started as a tobacco-roller, became a lector, and finally opened his own shop in Chestnut Valley. He makes sure you know he agrees with Wheeler's politics of accommodation, noting that he much prefered to read the works of Dickens when he was lector to the screeds of the trade-unionists.
			
			When the opportunity presents itself, you position him in a corner, and take what you need. You leave him in something of a stupor. Unfortunately, you suspect that his reptutation will be somewhat damaged by the air of intemperance,
			*goto butbut
		*else
			*goto dark_alley
	*elseif target = "debutante"
		The dancers move with the beat of the quintet, switching between waltzes and ballroom steps. You take your own turn on the dance floor, keeping an eye out for a suitable target.
		*if love_hope
			*set minister "young man"
			You settle on a young man whose smile is a little easier than the rest.
			
			He has aspirations of being a lawyer some day, but for the time being, he works in his father's office.
			*if (hunt_status = "success") or (hunt_status = "marginal")
				You maneouver him into a corner to better share your intimacies, a suggestion he is only too willing to accept. Once there, you take what you need from him. You leave him in something of a stupor which in retrospect will likely damage his reputation as being a sign of intemperance,
				*goto butbut
			*else
				*goto dark_alley
		*else
			You settle on a young woman whose eyes sparkle in the candlelight. She expresses her frustration that her mother was not allowed to join the Committee of Twenty-Five, and informs you that the next time the black community of St. Louis is called to great service, she will see her way onto whatever committee organizes the effort.
			
			*if (hunt_status = "success") or (hunt_status = "marginal")
				It is a bit difficult to maneouver her into a corner secluded enough to take what you need from her, but eventually you manage it. @{oblivio Using the [i]verba oblivionis[/i], you|You} leave her somewhat in a stupor, which in retrospect will likely damage her reputation as being a sign of intemperance, but @{(compassion > 50) since when do you care about such things?|you suppose there is nothing you can do about that.}
				*if (hunt_status = "marginal") and ((oblivio = false) and (stealth < 3))
					*set exposure +1
					You only hope that she cannont remember you enough to blame you for her troubles.
				*goto chapter_end
			*else
				*set exposure +2
				*set compassion %+10
				Unfortunately, your charms are not quite what you think they are. You press and press and press until finally she publicly scolds you for your persistence. Several men appear and escort you from the premesis.
				
				You gnash your teeth. The hunger prowls within you.
				
				Frustrated, on edge, you descend upon a workingman returning home late from a saloon. You realize only too late that you have killed him with your thirst. You lick the wounds and abandon the body to the crows.
				*goto chapter_end
	*elseif target = "clergy"
		Among the guests are several ministers of the African Methodist Episcopal Church. From among these august individuals you settle on your quarry.
		
		*if (hunt_status = "success") or (hunt_status = "marginal")
			*if speaks_english = false
				Thankfully, the minister is fluent in French; part of his ministry is to the immigrants from Haiti and Louisiana.
			It is simple enough to express your agreement with your quarry's political views. Since you are new in town, the minister is all-too-interested in seeing you join his flock. A few private moments about potential financial support and you have all that you need.
			
			Of course, the minister's reputation is somewhat damaged for the appearance of intemperance at the soirée, 
			*label butbut
			@{(compassion > 50) but since when do you care about such things?|but you suppose there is nothing you can do about that.}
			*if (hunt_status = "marginal")
				*if oblivio
					You use the [i]verba oblivionis[/i] to conceal any lingering doubts about your interaction.
				*elseif (stealth < 3)
					*set exposure +1
					You just hope that the ${minister} cannot remember enough to blame you for his troubles.
			*goto chapter_end
		*else
			*label dark_alley
			*set exposure +1
			You wait until the night has drawn to a close. When you quarry sets out for home, you follow him.
			
			When he turns down a particularly dark alley, you see your opportunity and knock him unconscious.
			*if hunt_status = "failure"
				*set exposure +1
				As you drink on his blood, you are disturbed by the sound of someone else nearby. Before you can be exposed, you do you best to hide the marks of your crime and flee.
			*goto chapter_end
	*elseif target = "child"
		Wheeler's children have already been put to bed by the time the party is truly underway. You slip into their room while the guests are otherwise distracted, take what you need, and rejoin the party with none the wiser.
		*if hunt_status = "failure"
			*comment the kid remembers enough to repeat stories about you.
			*set exposure +2
		*goto chapter_end
	*else
		What is the PC's target? ${target} 
		*page_break
		What is the PC's style: ${feeding_style}
		*page_break
		*bug no other quarry possibilities.
*elseif ethnicity = "choctaw"
	*set met_wheeler_and_turner true
	Through a sequence of introductions and acquaintanceships, you have made contact with James Milton Turner, a freedman and recent Ambassador to Liberia. He has spent many years seeking to improve the lives of both his brothers and has recently expanded his attentions to the plight of your kinsmen.
	
	It is through his acquaintance that you have been invited to a gathering at the home of John Wheeler, a local politician and newspaperman.
	*goto wheelers_party
*elseif ((ethnicity = "southern") or (ethnicity = "french")) and ((target = "debutante") or (target = "shopkeeper"))
	*label overtons_home
	*set quarry_ethnicity "southern"
	*set local_fame %+5
	
	It may not be the home of the Slaybacks, but it is the home of the Overtons, another prominent family of St. Louis. And, Susie Slayback is here, so it is not a total loss.
	
	The gathered youths—none is older than twenty-five—play cards, smoke cigars, and gossip—conjectures about the ongoing reconstruction of the Southern Hotel is matter under some dispute. Miss Elizabeth Overton scandalizes the room when she smokes a whole cigar herself! Most of the room is related in some way or another, and only the occasional appearance of a chaperone is necessary; they manage to keep each other within broadly acceptable social norms without conflict.
	
	You are, admittedly, a bit of a disturbing element to this otherwise pastoral picture. And when you lead one of their number on a merry chase through the second floor of the house, you fear that you are on the verge of wearing out your welcome. But you return soon enough—well-satiated—and your recent vessel passes his confusion off on the cognac.
	
	*if spencer_sister_status < 3
		It is only upon your return that you discover the presence of two new guests: @{(spencer_sister_status = 2) the infamous|} Peg and Susie Spencer. The round-faced, mousey-haired sisters intend to perform a séance for the attendees. Absent a reason to object, you follow them into the dining room.
		*set spencer_sister_status 3
		
		Once there, candles are lit, mirrors and windows are covered, and incense is lit. Peg begins to meditate while Susie Spencer sets the proverbial stage with a short history of women's connection to the other side. Betty Overton's eyes go wide with anticipation.

		"As the givers of life, we are also the bringers of death. We know it more intimately that any man ever could. Every month, we bleed for the lives of those who have come before, will come after, and those that will never come to be.

		"These talents and inclinations have been passed from mother to daughter for millennia. Among the Hindoos, the pygmies, the mandarins of Canton and Japan, this hidden knowledge is transmitted from one generation to the next. These arts which the Romans and their swords of iron drove into the highlands of Scotland and the tribes of Eire, so too did the Moors and the Mongols seek to exterminate from the Pillars of Hercules to the Land of the Rising Sun.

		"Even here, our foremothers carried these secrets with them across the ocean, and were burnt at the stake for it in Salem.

		"My sister encountered her first ghost at the age of four. We did not understand her at the time, but the words of the dead guided her and us for years. Her primary guide is our grandmother, Adelia, who saved us from a fire when we were babes, at the cost of her own life. Even now, from beyond the grave, she guides us.

		"But the secrets of the dead are not easily relinquished. It comes at great personal cost to my sister, Margaret. But we believe in the words we are here to share with you, and thanks to your generous support, we hope to bring these words to the world at large.

		"Lastly, I would warn you that your belief—or lack thereof—can greatly impact the success of Peg's efforts. Open your hearts and minds to the possibility that there is more to heaven and earth than you can see with your eyes, hear with your ears, or touch with your hands. Let the currents of the underworld flow unimpeded through this room."
		*temp knows_fraud false

		With that, the lamps are extinguished, and the room is reduced to candlelight and baited breath. Betty—who is sitting next to you—squeezes your leg. Everyone joins hands so that the ritual may begin.
		*if (((agility + perception) + streetwise) >= 5) or (creation > 2)
			*set knows_fraud true
			*set spencer_sister_status 5

			As soon as the first knocks resound through the room, it is clear to you that the sisters are frauds. Talented frauds, perhaps, but frauds nonetheless. They use numerous techniques @{(streetwise > 1) quite familiar to you|} to draw and hold the attention of the @{(streetwise > 1) marks|attendees} while the other delivers the next flourish.

			Adelia is the first spirit to "manifest," followed by Betty's grandmother.
		*else

			Moments later, the room jumps at the sound of the first knock. The candles gutter though there is no draught. A great whooshing sound accompanies the moans of Peg as the barrier between the worlds thins.

			Adelia is the first spirit to make herself known. Then the grandmother of Betty, much to her consternation.

		Thence, several other spirits make themselves @{knows_fraud "known"|known} through Peg, answering questions from beyond the grave posed by the enthralled audience. As the event wears on, Peg is clearly exhausted from the effort. Susie opens the floor to one more supplicant.
		*temp contact ""
		*temp contact_he "he"
		*temp contact_his "his"
		*temp contact_him "him"

		*choice
			*if knows_fraud
				#I attempt to expose them subtly.
					*set rationalism %-5
					*set shepherd_credentials %-5

					It doesn't take much; a stray knock here, redirecting the attention against the flow of their act there…but before the affair can be completely exposed, Susie calls the matter to an abrupt end, waring of evil spirits in the room that are seeking to harm her sister. She glares at you from the foot of the table. @{(discretion > 55) You respond with a wink and a grin for her and her alone.|}

					*label goodnight_betty
					The two sisters retreat to another room to recover while Betty and her friends vibrate with excitement over the experience.

					You excuse yourself.
					*goto seance_end
				#Let them keep their charade. It may come in use later.
					*set discretion %-5
					The evening ends with little more fanfare.
					*goto goodnight_betty
				#Stand up and denounce the two hucksters.
					*set discretion %+5
					You stand, kicking your chair back.

					"Cast these thieves and liars from your home. They have deceived you with their moans and groans and sleights-of-hand. They are nothing more than bloodsucking ticks, here to prey upon your generosity!"

					*if charm > 3
						*set spencer_sister_status 6
						The room falls silent under the power of your supernatural charm. The guests stand as one, leaving the indignity of the deception to Betty to address.

						With only the sisters and Betty in the room, she is free to excoriate them for their deception. Peg flees to another room to gather their things while Susie attempts to protest the furious hostess. When Peg finally reappears, she and her sister flee the house, never to return.

						Betty thanks you for saving her from those reprobates. She only lost a few scores of dollars and a bracelet, a small enough price, all told.

						You wave away her effusive gratitude; the night is late and you have obligations other than @{(compassion > 50) tending her wounded pride|comforting her}.
						*goto seance_end
					*else
						Betty looks at you, aghast.

						"${mr} ${surname}, how can you cast such aspersions upon these women? @{male Do you fear the secrets that they have to reveal?|To reject the wisdom and power of your own sex…I cannot comprehend why!} I'm afraid I'm going to have to ask you to leave!"

						You sigh. @{(rationalism > 50) These poor mortals are being lead astray. If they cannot stand to have the truth revealed, you will not waste your time and dignity on their intransigence.|You have seen this obstinence in the face of facts before. It is as though rejecting an article of faith only provokes those who hold it to keep it ever more dear.} There is nothing more for you to do here this evening.

						You excuse yourself.
						*goto seance_end
			*else
				*if (love_clotho) #Clotho.
					*set rationalism %+5
					*set contact "Clotho"
					*set contact_he "she"
					*set contact_his "her"
					*set contact_him "her"
					*label ruse
					Peg goes still. The room falls silent; the spirits have ceased their knocking.
					
					*temp queer_reveal false
					*if male and (contact = "Silas")
						*set queer_reveal true
					*elseif (male = false) and (contact = "Clotho")
						*set queer_reveal true
					"${given_name}?"
					
					${contact}'s voice sounds strange coming from the mouth of Peg Spencer.
					
					"Yes!" you exclaim. "Is it you, ${contact}? Is it really you?"
					
					"It is, dear ${given_name}. But why have you summoned me from beyond the grave?"
					
					"I missed you. I love you. I need you…"
					
					"But I am dead, ${given_name}. You must accept that. You must let me go."
					
					"Your letter, though! You promised you would return…"
					
					*if queer_reveal
						*set knows_fraud true
						*set spencer_sister_status 5
						"${given_name}, it matters not how deep our friendship was. We brought joy into one another's lives, but all good things must come to an end."
						
						"Our…friendship…" you stutter.
						
						"The bonds of friendship extend beyond the veil of life and death. I will waiting for you here. But go: find love, have children…maybe even name one for me. You will find other friends. Let me go so that I may rest."
					*else
						"My love! My dear! I have returned. But this is as close as we will ever be until you join me on this side of death's veil."
						
						"No…it cannot be!"
						
						"I love you, ${given_name}, in a way that consumes the night and illuminates the paths from this world to yours with the fires of memory. But try as I might, those paths are blocked. This is the only way for us to communicate. And even now, I can feel this poor vessel growing weak…"
						
						"No! ${contact}! Stay, please!" you plead. You release the hands that you were holding on either side, and a great sigh goes up in the room.
					
					And with that, Peg's voice returns to normal. She slumps in her chair, spent. @{knows_fraud You stare at her, anger roiling through you. Why would she lie to you and to these people? Why would she prey upon their hopes and dreams and most vulnerable moments in this way?|You are already at her side, but ${contact} is gone.}
					
					Susie calls an end to the event, lighting a lamp and then attending her sister. Betty's guests begin to chatter and remark among themselves at the marvels they witnessed. Peg is escorted out, clearly in need of rest.
					
					@{knows_fraud You excuse yourself, fearing that you will not be able to further contain your rage|You thank Olivia for the night's revelations and excuse yourself}.
					*goto seance_end
				*if (love_hope) #Silas Hope.
					*set rationalism %+5
					*set contact "Silas"
					*goto ruse
				*if (false) #${sire_name}.
					*set rationalism %+5
					*set contact sire_name
					*goto ruse
				#Let the séance end; trucking with the dead is improper.
					*set rationalism %+5
					You let the séance close. It brings the @{(religious_tradition = "pagan") unclean|unholy} ceremony to a quiet end.

					The sisters excuse themselves to recover, while Betty and her guests titter over the evening's excitement. You excuse yourself, wanting nothing more to do with those witches.
					*goto seance_end
				#I attempt to disrupt the séance.
					If the spirits can provoke noises from random corners of the room, so too can you.
					*if (((agility + perception) + streetwise) >= 4)
						*set spencer_sister_status 5
						A knock here, a rap there, and the mood in the room changes. It is then that you realize that the two sisters are frauds.
						
						Before you can quite process the realization, Susie calls an abrupt end to the demonstration,
					*if (((agility + perception) + streetwise) < 4)
						Within a few moments of your first intrusion, Susie Spencer cuts the demonstration short, 
					asserting that evil spirits have begun to infiltrate the room.
					
					When the lights are restored, Peg retreats to another room to recover, while the guests vibrate with excitement. You excuse yourself, having decided that there is little more to be accomplished here tonight.
					*label seance_end
					*if temperance_movement
					
						In later nights, you will learn that the Spencer sisters have a rivalry with the ${wctu}. The two groups vie for the same adherents, and so they frequently find themselves at cross-purposes.
					*goto chapter_end
	*else
		Sometime after midnight, you tire of their innocent prattle and excuse yourself to tend to your affairs.
		*goto chapter_end
*elseif religious_tradition = "catholic"
	*label kenrick_something
	*set quarry_ethnicity "french"
	*gosub hunting_stat_check
	Almost eighty years have passed since the Louisiana Purchase, but the French of St. Louis still keep a separate culture from most of the rest of the city. That said, most of them have stooped to learning English; a singular acknowledgment of the passing of time.
	
	Still, however, they cling to the Catholic Church, even if they rankle under the leadership of Archbishop Kenrick. Kenrick was a vocal opponent of Papal infallibility at the Vatican Council, and the French of St. Louis have taken it as an excuse to undermine his authority. Tonight, what remains of the French social set gathers, including the Rev. Michel Corbett.
	
	The Soulard neighborhood has lost most of its original character, but tonight, the attendees seem to be willfully ignoring that. A string quartet plays chamber music in the drawing room while the attendees dance in the hall between rounds of gossip. The Brigadier-General Gabriel René Paul (retired) is in attendance as well. Of course, he is blind and nearly deaf from wounds sustained at Gettysburg, but the attendees dote on him as a hero.
	
	*if target = "child"
		The hosts' children are tucked away in their room sleeping. While the attendees are outside dancing and laughing, you slip into the bedroom and take what you need, leaving as quickly as you came.
		*goto chapter_end
	*elseif target = "shopkeeper"
		The fur trade is nothing like it used to be, but the French of St. Louis maintain an iron grip on their monopoly. It is not hard to find a young trader—he's a little rougher than you might prefer, as he spends time in the wilderness—but you suppose that his industriousness will carry over into his blood well enough.
		
		*if (hunt_status = "success") or (hunt_status = "marginal")
			The grounds of the property are somewhat limited, and so you are forced to draw the young man down into the basement. Once there, however, you have your way with him, hoping that the effects of your bite will obscure his recollection of your smile.
			*if (hunt_status = "marginal") and (stealth < 3)
				*set exposure +1
			*goto chapter_end
		*else
			That said, you are only able to keep his attentions for so long. A young woman from Montréal is able to pull him away from you, despite your efforts to the contrary.
			
			*goto dark_alley
	*elseif target = "socialites"
		A young scion of the Chouteau family—Michel—manages to attract the most attention in the room. (Other than the good General, of course.) Michel may only be half-French, and not possessed of the Chouteau surname, but he's made a space for himself all the same.
		
		*if (hunt_status = "success") or (hunt_status = "marginal")
			It takes some doing to interject yourself into his immediate circle, but you will not be deterred. Eventually, he's laughing at your jests and promising to invite you to some future salon he may or may not ever get around to organizing.
			
			Unfortunately, the grounds of the house are somewhat limited, and so you are forced to adjourn to the basement with your new friend for your more private activities. You leave him there, a smile on his face, hoping that his stupor will mar any unpleasant memories from you encounter.
			*if (hunt_status = "marginal") and (stealth < 3)
				*set exposure +1
			*goto chapter_end
		*else
			*bug I suspect that this is not actually possible, to be hunting socialites and not have high enough Charm to succeed.
	*elseif target = "clergy"
		Amid the bustle is a young priest, Père Gaston. He smiles awkwardly at your approach—for a moment you fear that he's going to break and run screaming into the night. You even reach to check whether your fangs are prematurely extended, but they are not, and no blood comes away on your hand. As your conversation progresses, you conclude that he is simply skittish; it takes you some time to fully engage him in conversation. Once you do you learn that he is a French colonist from Algiers, a claim supported by his dark complexion.
		
		*if (hunt_status = "success") or (hunt_status = "marginal")
			He is not skittish enough. You eventually cajole him into the garden for private…counseling. He makes funny little moans as you suck at his neck; it is hard not to imagine what he would be like in bed.
			
			When you have drunk as much as you dare, you leave him panting in the dark and return to the soirée.
			*if (hunt_status = "marginal") and (stealth < 3)
				*set exposure +1
			*goto chapter_end
		*else
			However, as much as you try, you cannot entice him away from his charge: a young woman in need of a religious chaperone.
			
			Eventually, the young lady decides that she's had enough of her gilded cage for the evening, and excuses herself; the priest accompanies her out.			
			*goto chapter_end
	*else
		PC Feeding Style: ${feeding_style}
		*comment *bug no other feeding styles!
		*goto chapter_end
*elseif religious_tradition = "reformed"
	*label stone_home
	*set quarry_ethnicity "yankee"
	*gosub hunting_stat_check
	Since the war, a steady stream of Northerners have found themselves in St. Louis. Some simply stopped on their way further west. Others came with the Federal government or due to the efforts of Northern churches, sent to educate and advocate for the former slaves.
	
	You've had little trouble penetrating these social circles. Tonight is a reception at the home of William Henry Stone, a former Democratic Congressman from Missouri. Despite his support of Democratic causes, he himself is from New-York, and helped build ironclads for the Union during the war.
	*if (eliot_rapport > 35) and (shepherd_credentials < 50)
		Hiram's nephew, Henry Ware Eliot, is one of the guests.
	The home is just off Lafayette Square, and is modest for the neighborhood.
	*if stlouis_haven = "lafayette"
		You've taken note of the property several times during perambulations near your haven.
	*comment endif
		
	*if target = "child"
		Once in the house, you have no difficulty slipping into the room with the host's grandchildren. They came for the treats and promptly passed out from the sugar. You take what you came for and leave as quickly as you came.
		*goto chapter_end
	*elseif target = "shopkeeper"
		*set stl_met_stickney true
		You soon find yourself in conversation with Billy Stickney, some sort of manager or supervisor in the cigar trade. You're not quite sure about the details—he has a habit of changing subjects mid-sentence—but he clearly has the sort of ambition that appeals to you.
		
		*label feed_at_stones
		*if (hunt_status = "success") or (hunt_status = "marginal")
			It is simple enough to invite him into the garden and take from him what you need. You leave him with a smile on his face, and hope that his memory is sufficiently muddled to absolve you of any danger.
			*if (hunt_status = "marginal") and (stealth < 3)
				*set exposure +1
			*goto chapter_end
		*else
			Your social graces being at something of a deficit, he eventually excuses himself from the conversation. You resolve to accost him on his way home.
			
			*goto dark_alley
	*elseif target = "clergy"
		You soon find yourself in conversation with a Unitarian minister involved with Washington University.
		*if (lore > 3)
			He is enraptured by your ability to discuss theology with him.
			*if hunt_status = "physical"
				*set hunt_status "marginal"
		*comment endif
		
		*goto feed_at_stones
	*elseif target = "socialite"
		There is a young woman, Harriet, who seems the dear friend of Junior. You feel a tad guilty about coming between the two of them, but you reason that you will be done with be soon enough.
		
		*if (hunt_status = "success") or (hunt_status = "marginal")
			You manage to pull Harriet away from Junior and on to the dance floor.
			*if hunt_status = "success"
				In fact, you do it with such grace that Junior seems almost grateful for it.
			
			After a few spins, you guide her into the garden, where you can take what you need from her and be on your way. You only hope that the effects of your bite are strong enough to obscure her recollection of you.
			*if (hunt_status = "marginal") and (stealth < 3)
				*set exposure +1
			*goto chapter_end
		*else
			*bug I suspect that this is not actually possible, to be hunting socialites and not have high enough Charm to succeed.
	*else
		Player's feeding style: ${feeding_style}
		*comment *bug no other feeding styles!
		*goto chapter_end
*else
	*page_break
	Ethnicity: ${ethnicity}
	*line_break
	Religion: ${religious_tradition}
	*page_break
	*bug no other soiree possibilities.

*label chapter_end
*page_break
Your skin flushed with fresh blood, you return to your home with a spring in your step. Tonight—for this brief moment in time and space—the dread of eternity as a bloodsucking monster seems just a little further away.
*if feeding_style != "vegetarian"
	*if thief
		*page_break
		*set stlouis_valet_loyalty %-5
		*set exposure +1
		You've continued your thieving ways here in St. Louis. As in the past, you take whatever valuables you can from your victims.
		
		${stlouis_valet} likes being paid for ${valet_his} services, but is less excited about cleaning bloodstains from valuables in order to fence them.
	*if ((income < 5) and ((wealth < 50000) and (compassion > 50))) and (thief = false)
		*page_break
		*set wealth +5000
		*set income +3
		*set stlouis_valet_loyalty %-5
		*set exposure +1
		*set shepherd_credentials %-5
		*set thief true
		Finding yourself relatively destitute, you've started stealing from those people you feed from. It's mostly pocket change, but every once in a while you come across something more valuable, and ${stlouis_valet} has to dispose of it on your behalf. Regardless, the thievery does improve your financial situation.
		
		${stlouis_valet} likes being paid, but is not thrilled to be washing bloodstains from valuables only to turn around and fence them.
*if stlouis_cult
	*page_break
	
	The time spent cultivating your flock has not been fruitless; it has grown to the point where you have had to appoint a delegate to speak in you absence. Her name is Amanda. She lost her children to fever and her husband to whiskey, and has since poured her energies into realizing the salvation you have promised her.

	How does she address you?
	
	*choice
		#Heir.
			*set stlouis_cult_address "Heir"
		#@{male Lord|Lady}.
			*if male
				*set stlouis_cult_address "Lord"
			*if male = false
				*set stlouis_cult_address "Lady"
		#@{male Master|Mistress}.
			*if male
				*set stlouis_cult_address "Master"
			*if male = false
				*set stlouis_cult_address "Mistress"
		#Prophet.
			*set stlouis_cult_address "Prophet"
		#Saint.
			*set stlouis_cult_address "Saint"
	
	And do they call you by your given name, your surname, or simply by your title?
	
	*fake_choice
		#${stlouis_cult_address} ${given_name}.
			*set stlouis_cult_address & " "
			*set stlouis_cult_address & given_name
		#${stlouis_cult_address} ${surname}.
			*set stlouis_cult_address & " "
			*set stlouis_cult_address & surname
		#Just "${stlouis_cult_address}."
	
	When your flock gathers, how do they celebrate your message?
	
	*choice
		#Aesceticism: prayer, fasting, and silent contemplation.
			*set discretion %-10
		#Bombastic, emotionally-charged charged sermons.
			*set stlouis_cult_celebration 2
			*set discretion %+10
			*if charm > 2
				*set stlouis_cult_power %+10
				Your talent for oratory draws even more people to the gatherings.
			*else
				*set exposure +1
				Of course, you're not much of a public speaker. 
		#Drunken orgies.
			*set stlouis_cult_celebration 3
			*set exposure +1
			*set discretion %+10
			*set bloodflow +1
		#Blood-celebrating profanities.
			*set stlouis_cult_celebration 4
			*set exposure +2
			*set discretion %+20
			*set compassion %+5
			*set rationalism %+10
			*set bloodflow +1
	
	Lastly, what will you call this cult?

	*choice
		*if (religious_tradition = "pagan") #The Children of Hushtahli.
			*set stlouis_cult_name "The Children of Hushtahli"
		*if (religious_tradition = "catholic") #Satan's Children.
			*set stlouis_cult_name "Satan's Children"
		*if (religious_tradition = "reformed") #The Impious.
			*set stlouis_cult_name "The Impious"
		*if ((intelligence > 1) and (speaks_latin)) #The Maenads.
			*set stlouis_cult_name "The Maenads"
			*if stlouis_cult_celebration = 6
				*set stlouis_cult_power %+5
		*if (stlouis_cult_celebration= 1) #The Benefactors.
			*set stlouis_cult_name "The Benefactors"
		*if (choice_randomtest = false) #Something else.
			*input_text stlouis_cult_name
	
	And so is it done. The flock addresses you as ${stlouis_cult_address} and celebrate your revelations @{stlouis_cult_celebration in studious contemplation of the divine|in sweaty gatherings, enraptured by sound of your voice|in sweaty piles of lust and indulgence|amid black satin and chalices of blood}. At the center of it all, Amanda sits, an extension of your will and a voice in your absence.
*page_break
*gosub_scene util combat_value
*if sleeping_place = "ERROR"
	*bug sleeping place in error?

You rise from your ${sleeping_place} one evening, roused by conflict. Entering @{renter the main room|the common room} of your abode, you find Thomas threatening ${stlouis_valet} with a knife. The room is in some disarray. @{(perception > 1) You immediately surmise that Thomas was rifling through your possessions, seeking valuables.|}
*temp thomas_pinned false
*temp valet_wounded false
*temp problem false

*label thomas_conflict
*choice
	#"What is the meaning of this?" I thunder. @{(speaks_english = false) While Thomas may not understand your words, he must understand their meaning.|}
		*set problem true
		*if thomas_pinned
			@{renter "He was trying to rob us!" ${stlouis_valet} exclaims. "He's a dope fiend."|"I'm sorry for my nephew. He's been possessed by a morphine habit."}
				
			You look at Thomas carefully. He vibrates with excitement—or some sort of unconscious, nervous energy that animates his limbs.
		*else
			*if (fix_thomas) or (renter = false)
				*if speaks_english
					"I need an advance!" he says, brandishing the knife. "Why are you holding out on me, @{stlouis_valet_num uncle|auntie|uncle|uncle}?"
				*else
					Thomas whinges something, still brandishing he knife. 
				
				"I'm sorry for my nephew, ${mr} ${surname}. He's been possessed by his morphine habit," ${stlouis_valet} says.
				
				"Do you make excuses for everyone that holds a knife to your throat, ${stlouis_valet}?"
				
				"No…I…"
			*else
				*if speaks_english
					"Where's your silver?" he demands. "Give it to me or I gut this @{stlouis_valet_num negro|Irish strumpet|kraut|negro}!"
				*else
					Thomas yells something, which you interpret to be a demand for silver. Is he looking for the silverware?
			You note that his hand—the one holding the knife—is quite unsteady. It dips and weaves of its own accord—you conclude that Thomas is not able to hold it still.
		*goto thomas_conflict
	#I subdue Thomas.
		*set thomas_pinned true
		*set discretion %+5
		*if combat > 6
			*if renter
				*set stlouis_valet_loyalty %+5
			You dash across the room, pluck the knife from Thomas's hands, and press his face into the back of the door.
			
			"I don't take kindly to people brandishing knives in my presence," you whisper in his ear. @{speaks_english |You don't think he understands your words, but he gets your meaning.}
			*goto thomas_conflict
		*else
			*set stlouis_valet_loyalty %-10
			*set valet_wounded true
			
			You rush Thomas and try to wrest the knife away from him. With a spray of blood, the knife slices through ${stlouis_valet}'s cheek. With a final burst of rage, ${valet_he} knees Thomas in the groin. Thomas releases his hold on the knife, which you discard, and you pin him to the floor with the entirety of your weight.
			
			${stlouis_valet} rushes to fetch a cloth to blot ${valet_his} face. @{(willpower = 1) You struggle to contain your Beast at the sight of the dripping blood. [i]It's right there…[/i] you think to yourself, before pushing the thought out of your mind.|}
			*goto thomas_conflict
	#I kill Thomas.
		*set discretion %+5
		*set compassion %+10
		*if renter = false
			*set stlouis_valet_loyalty %-20
		*if thomas_pinned
			You extend your fangs and sink them into his neck.
			*label fang_thomas
			@{renter |Behind you, ${stlouis_valet} gasps in horror.} Within moments, Thomas is exsanguinated. @{(perception > 1) The blood itself is thick, as though he was dehydrated. You feel almost…queasy.|}
			*goto body_disposal
		*elseif combat > 7
			You rush towards Thomas, disarming him almost immediately. You pin him against the door, extend your fangs, and sink them into his neck.
			*goto fang_thomas
		*else
			*set valet_wounded true
			*set stlouis_valet_loyalty %-10
			You rush towards Thomas, lunging for the knife. Thomas swings to meet you. As you come to blows, there is a spray of blood, as ${stlouis_valet}'s cheek is cut open.
			
			A few more blows and Thomas manages to sink his knife into your side. It hurts, but you know it will heal shortly. You just need to feed.
			
			Your fangs extend and you sink them into his neck. He starts to howl in pain, but that howl becomes a moan. You drink him dry, holding him with one hand while you yank the knife out of your side with the other. You feel your flesh knitting back together. @{renter |Behind you, ${stlouis_valet} gasps in horror.}
			*label body_disposal
			
			*if renter and (fix_thomas = false)
				"${mr} ${surname}, the landlady will miss her son."
				
				"We can dispose of the body. Dump it in the river…"
				
				"No, there is a much simpler solution."
				
				"What?"
				
				"Give me a few dollars. I will go to an apothecary and buy some of the morphine he was looking for and a syringe. No one will look twice."
				
				"Do it."
				
				${stlouis_valet} leaves your quarters and returns an hour later. The two of you stage his body with the syringe and the box of morphine vials, and leave him to be discovered in the morning.
				
				$!{valet_he} is right: no
			*else
				"That was…my nephew…" ${stlouis_valet} gasps.
				
				"Then you should have kept him in line."
				
				"But…"
				
				"You brought him into my house. You begged me to take him on. He was your responsibility. As he was in life, so is he now in death." You nod your head at the blood-splattered room. "If you will excuse me." With that, you retire to your chamber to attend to your toilette and prepare for your evening.
				
				The next evening, you learn that ${stlouis_valet} staged an overdose. Purchasing a syringe and a few vials of morphine, Thomas's death is ruled accidental. No
			one looks twice @{(ethnicity = "choctaw") at his at demmise|at yet another veteran overcome by his addiction to morphine}.
			*label thomas_funeral
			
			*if renter and (fix_thomas = false)
				Your landlady dresses the house in mourning for days afterwards. She is grief-stricken.
				*if ethnicity != "choctaw"
					When word gets out, several of Thomas's former compatriots come by to pay their respects. Their words of praise are cold comfort to the bereft.
			*else
				${stlouis_valet} writes to Thomas's parents, informing them of his fate. Conveniently, what passes for the funeral takes place during the day, and ${valet_his} service to you is uninterrupted.
			*goto post_thomas
	*if (stlouis_cult) #It seems like Thomas needs to find purpose…purpose in the form of ${stlouis_cult_name}.
		*if renter = false
			*set stlouis_valet_loyalty %-10
			*comment Valet isn't a member of the cult, and doesn't like their cousin joining.
		*set stlouis_cult_power %+2
		*if thomas_pinned
			*label dispatch_thomas
			"You have some place to go, Thomas. My dear friend Amanda is going to cure you of these cravings. They will become but a distant memory."
			
			You bind Thomas's hands and sit him down. Before long, Amanda arrives with several of your other disciples. You give them instructions and they cart Thomas off.
			*page_break
			Amanda later informs you that isolation and prayer greatly weakened Thomas, but eventually brought him some stability and peace. He is reticent to leave the company of the faithful, however, and has now taken up residence with Amanda and some of your other most devoted adherants.
			*goto post_thomas
		*elseif charm > 3
			Exerting your powers of influence, you order Thomas to drop the knife, which he does.
			*goto dispatch_thomas
		*elseif combat > 7
			You rush towards Thomas, disarming him almost immediately. The knife clatters to the ground.
			
			You pin him against the door and hold him there until he stops struggling.
			*goto dispatch_thomas
		*else
			*set valet_wounded true
			*set stlouis_valet_loyalty %-10
			You rush towards Thomas, lunging for the knife. Thomas swings to meet you. As you come to blows, there is a spray of blood, as ${stlouis_valet}'s cheek is cut open.
			
			A few more blows and Thomas manages to sink his knife into your side. It hurts, but you know it will heal shortly. You just need to feed.
			
			Finally, you manage to subdue your opponent. The fact that you were unfazed by the knife in your side seems to finally settle into his mind; some part of him realizes that coöperation may be the best route forward for him.
			*goto dispatch_thomas
	*if (problem) #Surely, there must be a cure for this disease. We will send him to see the very best doctor.
		*set compassion %-10
		*set discretion %-10
		*set wealth -10000
		*if thomas_pinned
			You release Thomas. He massages his jaw, moving it around to test its limits.
		
		*if thomas_pinned or (charm > 2) 
			With careful and supplicating words, you and ${stlouis_valet} convince Thomas to visit a doctor. Thomas is suspicious, but when you promise to pay for the treatment, he assents. ${stlouis_valet} has heard of a sanitarium in Battle Creek, Michigan, run by Dr. Kellogg, that is having amazing results. With good wishes and a full valise, Thomas heads to the train station with ${stlouis_valet}@{renter  and your landlady|}.
			*set heard_of_kelloggs true
			*if (renter = false) or fix_thomas
				*set stlouis_valet_loyalty %+10
				
				When ${stlouis_valet} returns from the station, ${valet_he} thanks you for both your indulgence and your generosity towards ${valet_his} nephew. @{(compassion < 50) You dismiss ${valet_his} thanks good-naturedly.|You bask in ${valet_his} praise as long as is appropriate.}
			
			Several months later, you learn that Thomas has died while in the doctor's care. The body is returned with a note, describing Thomas's rejection of his daily enema. The note describes how the rejection of any part of the prescribed regimen absolves both the doctor and the sanitarium of any responsibility in Thomas's death.
			*goto thomas_funeral
		*else
			You try your best to calm Thomas down, but he spits in your face. He wants none of your empty promises.
			*goto thomas_conflict
	*selectable_if (wealth > 10000) #I pay him to leave. @{renter |He can consider it severance.}
		*set wealth -1000
		*set compassion %+5
		You offer Thomas a generous sum to leave and never return. He accepts it with fervor. @{thomas_pinned You let him stand and, once he has dusted himself off, the|The} two of you shake hands on it.
		*if (renter = false) or fix_thomas
			*set stlouis_valet_loyalty %-5
		
			"Are you sure that's the best solution?" ${stlouis_valet} asks.
			
			"That is not my concern. I do not wish to ever see your nephew again, ${stlouis_valet}. Is that clear?"
			
			"Yes, ${mr} ${surname}."
		
		You drop some silver coins into @{renter his|Thomas's} open hands and send him on his way.
		
		Within three weeks, Thomas is dead, his body found in an alley in the Kerry Patch. His death is blamed on the morphine addiction and no further inquest is held.
		*goto thomas_funeral
	*if (problem and (charm > 3)) #I use my supernatural charm to convince him to let this habit go.
		*set compassion %-5
		*set shepherd_credentials %+5
		With open hands and calming words, you @{thomas_pinned calm Thomas down|convince Thomas to put the knife down}. A few more sentences and he is sitting at your table, ready to do your bidding.
		
		You bid him to let go of this mania that grips him. He smiles at you. Of course he will let it go.
		
		You spend the rest of the night in close proximity to him. By dawn, he is beginning to sweat profusely. The sun is coming and you must retreat to your ${sleeping_place}.
		*if charm > 4
			*bug
		*else
			Almost as soon as you are secured away, you hear Thomas roar and exit your @{renter apartment|home}. From here you cannot follow.
			*page_break
			When you awake that evening, you learn from ${stlouis_valet} that Thomas is missing.
			
			The following night, you learn that he is dead of an overdose.
			*goto thomas_funeral

*label post_thomas
*finish Next

*label hunting_stat_check
*if (charm > 1) and (feeding_style = "gamblers")
	*if (wealth > 500) and (wealth <= 1000)
		*set wealth -500
		*set hunt_status "marginal"
	*if wealth > 1000
		*set wealth -1000
		*set hunt_status "success"
	*return
*elseif (charm > 2)
	*set hunt_status "success"
	*return
*elseif (charm = 2) and ((male = false) or (quarry_ethnicity = ethnicity))
	*set hunt_status "marginal"
	*return
*elseif (charm > 1) and ((stealth > 2) and speaks_english)
	*set hunt_status "marginal"
	*return
*elseif (strength > 2) or (fighting >= 2)
	*set hunt_status "physical"
	*return
*else
	*set hunt_status "failure"
	*return

*label hunt_intro
Your decision made, you realize that it is, in fact, time for such an excursion. The moon is high and the sweet song of the blood calls to you.
*page_break
*return