*comment ñáéç…—
*comment April 1880?
*hide_reuse
*advertisement
*temp vince "Vince"
*temp pavesi "Pavesi"
*temp bespectacled_italian "bespectacled Italian"
*temp sporting_spectacles "sporting spectacles"
*temp italian "Italian"
*temp italian_man "Italian man"
*if (sire_name = "West") and (patricide)
	*goto west_aftermath
*temp wolf false
*temp was_wolf false
*temp bat false
*temp through_roof false
*temp in_cave false
*if (maddox_status = "freed") or (maddox_status = "shirked")
	*if maddox_num = 1
		*set vince "Wilson"
		*set pavesi "Maddox"
		*set bespectacled_italian "one-eared freedman"
		*set sporting_spectacles "with only one ear"
		*temp italian_man "freedman"
		*set italian "freedman"
		*goto wake_as_west
	*else
		*set vince "Anselm"
		*set pavesi "Martin"
		*set bespectacled_italian "one-eyed Cajun"
		*set sporting_spectacles "with a stylish eye-patch"
		*temp italian_man "German-Cajun"
		*set italian "German-Cajun"
		*goto wake_as_west
*elseif (gallagher_status = "freed") or (gallagher_status = "shirked")
	*set vince "Hugh"
	*set pavesi "Gallagher"
	*set bespectacled_italian "gap-toothed Irishman"
	*set sporting_spectacles "with gap-teeth"
	*set italian "Irishman"
	*temp italian_man "Irishman"
	*goto wake_as_west
*else
	*set maddox_num 4
	*goto wake_as_west

*label wake_as_west
*set year 1750
*temp wgiven_name given_name
*temp wsurname surname
*temp wethnicity ethnicity
*temp wagility agility
*temp wcharm charm
*temp wintelligence intelligence
*temp wstrength strength
*temp wwillpower willpower
*temp wcreation creation
*temp wfighting fighting
*temp wlore lore
*temp wperception perception
*temp wshapeshifting shapeshifting
*temp wstatus status
*temp wstealth stealth
*temp wstreetwise streetwise
*temp wtechnology technology
*temp wanachronism anachronism
*temp wcompassion compassion
*temp wdiscretion discretion
*temp windependence independence
*temp wrationalism rationalism
*temp wshepherd shepherd_credentials
*temp wrevolutionary revolutionary_credentials
*temp wwealth wealth
*temp wincome income
*temp wfeeding_style feeding_style
*temp wsire_name sire_name
*temp wliterate literate
*temp wenglish speaks_english
*temp wfrench speaks_french
*temp wgerman speaks_german
*temp wlatin speaks_latin
*temp wspanish speaks_spanish

*set given_name "West"
*set surname "  "
*set ethnicity "unknown"
*set agility 5
*set charm 2
*set intelligence 3
*set strength 4
*set willpower 4
*set creation 1
*set fighting 4
*set lore 4
*set perception 3
*set shapeshifting 6
*set status 0
*set stealth 3
*set streetwise 1
*set technology 0
*set anachronism 20
*set compassion 75
*set discretion 85
*set independence 10
*set rationalism 83
*set shepherd_credentials 5
*set revolutionary_credentials 50
*set wealth 0
*set income 0
*set feeding_style "Vampires"
*set sire_name "Buljan of Kyiv"
*set literate true
*set speaks_english true
*set speaks_french true
*set speaks_german true
*set speaks_latin false
*set speaks_spanish true
*if choice_randomtest
	ATTN Seed Readers: The next several pages take place from a different POV. If a reader looks at their stat screen, they're suddenly playing a different character: West. When West goes to sleep again (below), it reverts back to the normal avatar.

Until a few nights ago, you had been asleep. You have been asleep for a long time. Months? A year? You are unsure.

You sleep so often these days.  The hunt does not thrill you as it once did.  

You emerge from your earthen burrow and stretch.  It is the last of your mammalian affectations.

There is only one type of prey that satisfies your hunger: other vampires.
*page_break
Not that you quite think of it like that.  You think more in terms of smells, sounds, and images than words.  You have left words behind.

And tonight—amid the chirps of cardinals, the hoots of a barnowl, and the caws of crows—the spring breeze carries the scent of one to you. A dead man walking. You first caught his trail two nights ago. He has eluded you so far, but that is because you have been trying to find the joy in the chase. Perhaps another evasion, another deception, another feint will finally awaken your spirit.

Regardless of your enjoyment, however, the hunger is different tonight. Enough playing with your food. It is time to drink.

How will you pursue him?

*choice
	#I take to the sky—in the form of a bat.  The better to spy him.
		*set bat true
		Your body shrinks in on itself, sprouting fur from flesh and leathery wings from your sides.  With a few powerful flaps, you propel yourself above the trees.
		
		From here, there will be no escape.
	#I take to the earth—in the form of a wolf.  The better to smell him.
		*set wolf true
		*set was_wolf true
		Your paws fall to the earth as the change overtakes you.  Your mouth and ears enlongate.  Hair sprouts from every inch of your body.
		
		Sitting on your haunches, you unleash a howl that shakes the countryside; it's a howl that causes mothers to clutch their children close.  A beast is on the loose.
	#I stay as I am.  The better to keep my wits about me.
		Vampires are the most dangerous prey for a reason.  To relinquish what remains of your faculties could put you at a disadvantage.

		You begin to move.  Slowly at first, then faster and faster.  Faster than a human ever could.  You are ancient, and the power in the blood fuels your movements.
*page_break
It seems your quarry has taken refuge in a farmhouse. @{bat You circle above, trying to decide what to do.|} It's a one-storey affair.  Probably no more than three rooms. @{wolf He's not alone. There are humans in there with him.  You can smell them on the breeze as you crouch in the shadow of a bush.|}
*if (wolf = false) and (bat = false)
	Crouching in the shadow of a bush, you look for some way to learn about the inhabitants of the house. Cocking your head, you ask an owl.  The owl replies that several upright, hairless beavers inhabit the dead-tree pile.  They make plants grow and they feed and kill pigs.
	
	The owl finds these behaviors mystifying.
*label farmhouse_decision
*temp brainmatter false
*choice
	*if bat or wolf
		#I take human form and charge into the house.
			*set bat false
			*set wolf false
			It is only about five feet before the door that you transition back to your human form.
			*label charge
			*set discretion %+10
			With one leg extended, you hurl your weight against the portal, shattering it instantly.
			
			Your momentum carries you forward.  Until you stop.
			
			Inside are several humans—a family?—each wielding a cross.
			
			You snarl and gnash your teeth, but are unable to approach any of them.  Behind them you see your quarry, a ${bespectacled_italian}.  He's organizing them!
			*goto surrounded
	*if wolf
		#I unleash another howl.  Maybe it will scare him out.
			*set wolf false
			Instead, there is a crack of a musket.  The bullet strikes your chest, burrowing into your flesh and cutting your howl short. So much for your hiding place.
			
			You transition back to the form of a man and yank the bullet from your breast. The wound closes swiftly once the bullet is removed.
			*goto farmhouse_decision
	*if (bat = false) and (wolf = false)
		#I charge in through the front door.
			Standing from your hiding place, you charge towards the door.
			*goto charge
		#I take a running leap onto the roof.  Once there, I punch through and come in that way.
			*goto roof
	*if bat
		#I land on the roof, take human form, and punch through it.
			*label roof
			*set discretion %-5
			*set through_roof true
			Driving your fist through the roofbeams, you make a hole large enough for you to slip through.  
			
			You lower yourself down and onto the crossbeam which bisects the attic area.  Looking down, you see a family equipped with crosses.  They raise them up at you, clearly terrified, but resolved to hold you at bay.  Behind them your quarry, a ${bespectacled_italian}, urges them on.
			
			You snarl down at them, unable to get any closer.  You look around, seeking some sort of makeshift weapon.  The family seems to be storing winter things up here at the moment—blankets, heavier clothes—and you don't find anything immediately convertible.
			*goto on_crossbeam

*label surrounded
You make several starts to escape the circle, but they stand fast, adjusting themselves to keep you trapped.  The family may have you surrounded—and the crosses hold you captive—but you feel no fear.  You have not made it to this age without facing down much greater challenges.

All you need to do is break the circle and then you will be free.  The ${bespectacled_italian} urges them to stand fast as you draw yourself up to your full height.
*choice
	#Wait until one attacks.
		You wait patiently.  You may be a slavering beast, but beasts are hunters first and foremost. And hunters know how to be patient.
		
		You stop moving. Your stillness is uncanny, but what would one expect from an entity that has set aside mortal concerns? The family begins to wonder aloud if you are still alive, if God has somehow cast the demon from your unmoving corpse. The ${bespectacled_italian} yells at them to stand fast, to wait for the dawn.
		
		You can sense that it will not come to that.
		
		The father manages to get a grip on a pitchfork that was leaning against the wall behind him.  With one hand, he tries to maneuver it into position to stab you.  The ${bespectacled_italian} screams at him to stop. To wait. To be patient.
		
		He should have listened to your quarry.
		
		The pitchfork puts the man off-balance.  He stabs at you with it, and you easily rip it from his hands, moving faster than he can comprehend.  He recovers enough to brandish the cross at you again, but it no longer matters.  Using the pitchfork and your immense strength, you impale the father against the wall of the house, high enough that his feet dangle above the floor.  He looks down at the makeshift weapon in disbelief, and the cross drops to his side as he reaches up to touch the tines and assure himself that he is indeed transfixed.
	#Try to scare one of them.
		Looking into their souls one by one, you determine that the teenage boy is the most likely to crumble.  Summoning the power of the beast, you turn your right hand into a claw.  With a sharp gesture, you turn and push as close to the boy as you can, unleashing a terrible scream and showing him the death that awaits him at the end of your nails.  
		
		The smell of urine fills the room, and when he looks down at himself, the cross droops…just enough for you to launch yourself on him.  Fangs extended, you tear his throat open, crushing the cross in your left hand and ripping his arm from his shoulder with your right.
	#Jump into the rafters, and try to fashion a weapon from what I find there.
		You leap straight up, landing lightly on the crossbeam. The family seems to be storing winter things up here at the moment—blankets, heavier clothes—and you don't find any immediately convertible weapons.
		*label on_crossbeam
		After a moment's reflection, you rip one of the blankets free and drop it like a net over two of the family-members.
		*temp brainmatter true
		
		You drop down neatly, plunging your fist through the blanket and through the skull of the father who writhes underneath.  You pull your hand back up, dripping with grey brain matter.  The sound of the childrens' screams echoes through the night.

After that, it's a simple matter to kill several of the other members of the family. Unfortunately, their blood can provide you with no sustenance.  The mother seems to be holding firm, clutching a little boy to her leg, but you are bored.  The ${bespectacled_italian} has fled during your rampage.  He is the one you came for, after all.
*set west_exposure +1

You smile a bloody grin at the 
*if brainmatter
	*set werewolf_hysteria +1
	@{(compassion >= 70) mother and spit out the cheek-meat of her soon-to-be bled-out husband. You hadn't realized you'd taken a bite out of his cheek—not like you can swallow it or anything—but sometimes you do things without intending it. But spitting the meat at her feet? You meant that.|mother. Some vicious part of you wants her to remember the moment you let her live.} 
*else
	woman and toss the head of her eldest at her feet. Some vicious part of you want her to remember the moment you let her live.
You turn away and find the back door of the farmhouse.  It swings open on its hinges.  Behind the pitiful dwelling is a field of wheat.  It sways lightly in the nighttime breeze.
*page_break
The stalks of wheat fall before you as you pursue the ${italian} through the field. You don't push yourself. Not yet, anyway.  The pursuit is half the fun, after all.

A stream. He entered the stream. His scent disappears into it.

A kindly finch points the way. Upstream. Across. Dead-hairless-beaver walking.

Sunrise is not that far off. @{was_wolf You crouch down and take the form of a wolf again.|Your paws fall to the earth as the change overtakes you.  Your mouth and ears enlongate.  Hair sprouts from every inch of your body.} You leap across the stream and bound after your quarry.

It feels good to hunt again.
*page_break
He's there. In a cave. You can smell him.

If you can even call it a cave.  It would probably provide just enough shelter for a vampire to avoid the sun for the day.  Not much more than that.

He's managed to start a small fire at the mouth of the cave.  It's just a few small flames right now, but they shine in the darkness.
*choice
	#I use my hind legs to kick dirt over the fire.
		*set discretion %-5
		*set in_cave true
		Showing your backside to the ${italian}, you kick your legs out one by one, smothering the fire in a fluid gesture.
		
		Turning, you let out a snarl and charge.
		
		He's ready for you. Or, at least, he thinks he is. A makeshift wooden spear greets you as you leap towards him. It pierces the flesh of your chest, but not enough to bypass your ribcage. Instead the spear shatters in his hands. With one paw you bat the remains of the tip away. Then, with a final snarl, you lunge forward for the kill.
		
		Your weight knocks him over, and you begin to savage his neck with your powerful jaws.
	#I charge into the cave and leap over the fire.
		*set discretion %+10
		*set in_cave true
		You can clear the fire with one solid bound. And you do.
		
		He's ready for you. Or, at least, he thinks he is. A makeshift wooden spear greets you as you leap towards him. It pierces the flesh of your chest, but not enough to bypass your ribcage. Instead the spear shatters in his hands. With one paw you bat the remains of the tip away. You don't have much choice; the fire behind you is singeing your tail.  With a final snarl, you lunge forward for the kill.
		
		Your weight knocks him over, and you begin to savage his neck with your powerful jaws.
	#I summon a swarm of bats to drive him out of the cave.
		*set discretion %-5
		It takes a few minutes for the bats to arrive.  In that time, the fire grows larger, almost respectable.  You can now see the ${bespectacled_italian} in the light of his fire.
		
		The bats take no notice of it, however. They gather above, and as one they dive into the cave.
		
		Your quarry tries to defend himself, slapping at the bats, trying to smother the fear of being bitten and clawed, but it's no use. He's still too human.
		
		Once he crosses over the fire, you leap on him, tearing at his throat.  
You turn back to your human form and begin sucking at the wound; since he lacks a beating heart, you must work for your sustenance. He struggles against you, feeling that his death is imminent, but his strength is nothing compared to yours.

When his limbs have gone limp, you begin to slow your feasting.  You want to enjoy his heartsblood. It always goes fast. Too fast.

There. The first drops hit the tip of your tongue. His soul. Or what remains of it.

And then he sighs—exhales—as though he has finally given up. Relented.

You, on the other hand, thrill at the taste of the heartsblood. Your body sings with the power you are ingesting. You consume immortality itself.
*page_break
When the corpse is well and truly empty, you stand up and walk away with no more regard for it. It no longer concerns you.

It's time to sleep again.

The ${italian}'s blood continues to spread through your body.  It is comforting. You walk for a short time, seeking a place to rest.

You circle a likely resting spot, once, twice, three times.  Your hands—or are they claws?—begin to dig at the earth, parting it smoothly and powerfully so that your resting place can go undetected by passers-by.

Slipping into the earth, you shut your eyes. Now you will rest.

And dream. Already, the sight of @{maddox_num fields of cotton under the hot sun rises before your eyes. Hundreds of enslaved men, women, and children bend over, tending the cotton plants in every direction. Days and days of toil lay before you; the water breaks are few and far between.|sugarcane fields spreads before you under the hot sun. They reach from river to the highway. The enslaved men hack away at the cane while the women gather and bundle them. Shortly, you will follow behind them, making sure nothing was left behind.|your family's potato field stretches around you. Your family has worked this land for generations, but recently, the potatoes rot before you can harvest them. If this harvest fails, you will have to leave to find work somewhere else. Maybe you can send money home? Your youngest sister, Mary Brigid, died during the winter; and Margaret is looking unwell.|vineyards spread in every direction. You can see them whole, but you can also see them demolished. The tyrant Napoleon will march through these vines next month and nothing will be left of your family's livelihood. You will have to flee to Florence to find work, if there is any work to be had.}

Whenever you rest, the dreams of the dead fill every corner of your consciousness. You may have satiated your hunger on their heartsblood, but their memories did not dissolve with their corpses.

*set given_name wgiven_name
*set surname wsurname
*set ethnicity wethnicity
*set agility wagility
*set charm wcharm
*set intelligence wintelligence
*set strength wstrength
*set willpower wwillpower
*set creation wcreation
*set fighting wfighting
*set lore wlore
*set perception wperception
*set shapeshifting wshapeshifting
*set status wstatus
*set stealth wstealth
*set streetwise wstreetwise
*set technology wtechnology
*set anachronism wanachronism
*set compassion wcompassion
*set discretion wdiscretion
*set independence windependence
*set rationalism wrationalism
*set shepherd_credentials wshepherd
*set revolutionary_credentials wrevolutionary
*set wealth wwealth
*set income wincome
*set feeding_style wfeeding_style
*set sire_name wsire_name
*set literate wliterate
*set speaks_english wenglish
*set speaks_french wfrench
*set speaks_german wgerman
*set speaks_latin wlatin
*set speaks_spanish wspanish
*set year 1880
*page_break
*label west_aftermath
*temp mr_german "Herr"
*if male = false
	*set mr_german "Fräulein"
*if priest
	*set mr_german "Hochwürden"
You start yourself awake. The sun has set, and tonight is the monthly gathering at Aichinger's [i]biergarten[/i]. ${stlouis_valet} helps you with your dress and toilette and then you are off in your coupé.

It is a grim scene when you arrive. Even Memeskia is here.

Aichinger is the first to speak. "Have you heard the news?"

"News?  What news?"

*if sire_name = "West"
	*set aichinger_rapport %-10
	"Your dominus has attacked a family. Murdered most of them, and in the process revealed himself and his powers."
	
	*if discretion > 65
		*set memeskia_rapport %-10
		*set aichinger_rapport %+10
		*set bailey_rapport %-5
		"He is Quaestor Memeskia's dominus as well," you point out casually. 
		
		Aichinger's eyes widen from amusement, but he does not let that distract him.
	*else
		"Where?"

	"A little south of here, a farmstead north of Ste. Genevieve," interjects Eliot. 
	*if intelligence > 2
		Ste. Genevieve is a small town further down the Mississippi that predates St. Louis by some ten years. It is about midway between St. Louis and Cairo.
	*if rumors_of_west_dead
		
		You try to show the appropriate amount of surprise. You had previously heard that West was making a mess of things outside of St. Louis, and it is why you came. It seems that whomever is impersonating West has not ceased their activities.
	*if patricide and (rumors_of_west_dead = false)
		*set rumors_of_west_dead true
	
		You reel from the news. That's impossible. You slew your dominus yourself! Of course, you can't tell them that.
	*comment endif
	
	"What was your last communication with your dominus, ${mr_german} ${surname}?"
	
	"As I said before, I have not seen him in decades. As you might imagine, he is not given to lengthy correspondence, so I can't say that I have received any letters from him, either."
	
	The other vampires nod their heads at this.
*if (sire_name != "West")
	"The beast known as West attacked a family. Murdered most of them, revealing himself and his powers in the process."

*if (maddox_num < 3) and (maddox_status = "freed")
	*set maddox_status "west"
*if (maddox_num = 3) and (gallagher_status = "freed")
	*set gallagher_status "west"
"He revealed himself? Why would he be so careless?"

Aichinger and Bailey look at each other uncomfortably. Finally, Aichinger speaks. "He wasn't hunting a mortal. He didn't care if they survived or not."

@{knows_about_vegetarianism "Does he seek to abstain from human blood?"|"He was just murdering them for sport?"}

"Perhaps that's it! I hadn't thought of that," Eliot chimes in.

Bailey pauses a moment before answering the two of you.
*if perception > 1
	You are left with the distinct feeling that he—ever so subtly—just looked over each shoulder for eavesdroppers.
"What I am about to tell you verges on the heretical," he begins. "It is rumored that some vampires, when they grow sufficiently old, lose their taste for human blood. It no longer sustains them."
	
Eliot's eyes go wide with shock. You can only imagine what yours must look like. "What do these elders feed…feed on?"

"Other vampires."
*if taste_for_vampire_blood
	
	You go cold. @{(compassion < 50) You manage to feign a look of horror, but you fear your masque is thin.|You cannot even muster an expression of horror.} Does this same fate wait for you?
	
	"${mr} ${surname}, you do not seem so perturbed by this," Bailey says, peering at you. "Not as perturbed as Mr. Eliot, anyway."
	
	*if (charm < 4) and (intelligence < 4)
		*set bailey_rapport %-10
		You fumble for a lie.
	"I simply don't know what to think," you offer.
	
	"I see," Bailey muses.
*page_break
"So who was he hunting?" you inquire, once @{taste_for_vampire_blood you have regained your footing|this revelation has sunk in}.

"The widow said that West's quarry was an ${italian_man}, ${sporting_spectacles}. I am unacquainted with such a vampire," Aichinger replies.

*if vince = "Vince"
	"His name was Vincenzo Pavesi," Bailey replies. "He was on his way here."
	
	"And how do you know this, Senator?" Memeskia intones.
	
	"He had recently come into conflict with his dominus in Genoa. He was a sympathizer of Stone and was forced to flee to the New World. When I heard of his plight, I recommended that he make his way here."
*if vince != "Vince"
	"That…sounds like @{maddox_num Wilson Maddox|Anselm Martin|Hugh Gallagher|ERROR}," you say.

"Do we know anything else?" Eliot ventures.

"I am told that West fears crosses. It seems that this ${pavesi} fellow had the clever idea of using the family to trap West in a circle of crosses, and then hold him there until daybreak. Unfortunately, West was not so easily tamed," says Aichinger.

"And where is he now?" you say.

"It is unclear. Resting, no doubt. He has given in to the beast fully. And like a beast who has fed, he will now sleep. But it will not be forever. Not by any means," Bailey says, shaking his head. "We will need to prepare some sort of strategem for when next he rises."

"Let us adjourn, then. Think on the matter, and when next we meet, we shall discuss your proposals," says Memeskia.

"Thank you, Quaestor," the rest—including you—reply as he rises from his chair and departs.
*page_break
"Who will handle the widow?" Eliot inquires.

"Do you think we could frame the James-Younger Gang for it? Aren't they criminals?" Aichinger asks.

Eliot tries not to let his bemusement show. "No, no one would believe it. The James brothers would never kill homesteaders like this."

After a moment, all three look at you. @{(sire_name = "West") You are his progeny, after all.|As the newest—and youngest—citizen of St. Louis, they seem to think you should take it upon yourself to rectify the situation.}
*choice
	*if sire_name = "West"
		*if (lore >= 3) #I offer Bailey a debt to block the memories of the tragedy from the widow's mind.
			*set debt_to_bailey true
			*set compassion %-20
			*set eliot_rapport %+20
			*set discretion %-5
			*set west_widow "wiped"
			Bailey extracts a debt from you in exchange for the deed, but otherwise readily agrees. Eliot seems to appreciate your compassionate solution to the problem.
			
			*if patricide
				Of course, you feel a little strange covering up the crimes of someone who is not your dominus, but who is instead immitating him. But this is a puzzle which you will have to solve later.
			*goto wiped
		*selectable_if (independence < 60) #@{patricide Whoever it is, it's not my maker; West is dead. I bear no responsibility.|He may be my dominus, but I am not responsible for him.}
			*set bailey_rapport %-30
			*set eliot_rapport %-30
			*set aichinger_rapport %-30
			*set memeskia_rapport %-40
			*set independence %-50
			*set discretion %+25
			*set west_exposure +1
			The gathered vampires eventually decide that the description of the events are too outlandish for most to heed. Who would believe this poor woman, that an ancient vampire killed her family but left her alive?
			
			Eliot seems concerned about this plan, but does not voice any formal objection.
			*goto sigrid
	*if sire_name != "West"
		#This is not my responsibility. Let the elders of the city address the matter.
			*set aichinger_rapport %-10
			*set memeskia_rapport %-10
			*set bailey_rapport %-20
			*set discretion %-20
			*set west_widow "wiped"
			You sit in uncomfortable silence for a time. Realizing that your presence is no longer required, you stand and excuse yourself.
			*goto sigrid
	#I offer to take care of the widow—by removing her from this world.
		*set west_widow "dead"
		*set compassion %+10
		*set eliot_rapport %-10
		*set bailey_rapport %+5
		*set aichinger_rapport %+5
		@{(perception > 1) A flicker of distress flashes across Eliot's face, but he quickly masks it.|} Aichinger and Bailey nod in acceptance. It seems you have a task at hand.
		
		*goto depart_biergarten
	*if charm > 3
		*selectable_if (charm > 4) #I offer to address the matter—by erasing the memory of West from her mind.
			*set compassion %-5
			*set west_widow "wiped"
			It is a simple enough thing to find the woman and put her mind at ease.
			*label wiped
			*set west_exposure -1
			
			Those who heard the early account conclude that the tragedy drove her out of her right mind. Given a few days of rest, her "memory" corrects itself and she relates a much more understandable tale. The countryside is all too ready to accept such a simpler explanation.
			*goto depart_biergarten
	*if (watching_james) and (stlouis_enterprise = 1)
		#"They will believe what we tell them to believe; I'll have the newspapers opine about the responsibility of the James gang."
			*set shepherd_credentials %+15
			*set anti_james_sentiment %+20
			*set bailey_rapport %+10
			*set aichinger_rapport %+10
			*set memeskia_rapport %+5
			You point out to the other vampires that with a few well-placed questions, the newspapers of the city will speculate wildly about the involvement of Jesse James in the murder of the homesteader. In particular, no one will visit the widow to ask after her side of the story. Bailey and Aichinger both nod in approval at your suggestion.
			
			*goto depart_biergarten

*label depart_biergarten
Gathering your things, you bid the remaining vampires good night. 
*label sigrid
Sigrid greets you at the door of the office and escorts you to your waiting coupé.

Now it is time for home. There is much to contemplate. @{(west_widow = "dead") And a widow to murder.|}
*if west_widow = "dead"
	*temp west_prob false
	*set atrocities +1
	*if (sire_name = "West") and patricide
		*set west_prob true

	A few nights later, you set out for Ste. Genvieve. Locating the farmstead is no challenge. During the night, you descend upon it and murder its remaining inhabitants.
	
	*if compassion >= 65
		The return to St. Louis is uneventful.
	*else
		On your way back to St. Louis, the thought occurs to you: who is more guilty here, you or @{west_prob the imposter|West}? At least he was killing because he was hungry. What did you kill for?
*if west_widow = "alive"
	*comment William "Liam" Parker
	*set stl_kid_origin 5
	*set stl_kid_name "William"
	*set stl_kid_nick "Liam"
*if exodusters
	*page_break
	The Exodusters are still relatively segregated from the general population of St. Louis. They have, in fact, settled their own little village within the city. When asked about their choice of abodes, they spoke of how they were "beyond the bulldozer's reach." In time, the village becomes known as the Reach.
	
	The whole village comes together to celebrate when the first child is born. With new life comes new hope.
	*set stl_kid_origin 2
	*set stl_kid_name "Deliverance"
	*set stl_kid_nick "Del"
*page_break
*comment 1880-07-06

Fires—as one of the two great banes of vampires—are always of interest to you.

Tonight, thankfully, you face no danger. But the whole city is in mourning for a firefighter, Phelim O'Toole. The Irish immigrant died when his fire extinguisher exploded while fighting a fire downtown. The death of a firefighter may not be so remarkable, but this firefighter became famous three years ago when he was on the front lines of the Southern Hotel fire.

Newspapers extol the virtues of the deceased, repeating the story of the hotel fire in extensive detail. Three years ago, April 1877, a fire caught in the basement of the hotel. It spread quickly, trapping numerous people on the upper floors. O'Toole led one team of the brigades of firefighters, going so far as to climb onto the sixth floor of the burning building and lowering people out one-by-one.
*finish Next