*comment ñáéç
*hide_reuse
*advertisement
*gosub_scene util check_flow
*gosub_scene util combat_value_ss
*temp ask_name true
*temp ask_rendezvous false
*set year 1862
A company is levied from the boys of the area during the spring of 1862.  Volunteers flock to the city to sign up for God and the Confederacy.  In honor of the new President, they name themselves the Jeff Davis Rebels.

Though these youths will soon be torn and mangled by artillery fire, that future is still clouded by optimism.  For the time being, they are drilling in a field just outside Vicksburg.  It quickly becomes a day's diversion to take a picque-nicque down to the field and watch them march up and down in their new uniforms, carrying weighted sticks (their standard issue rifles have not yet arrived; the lucky ones bear the muskets their grandfathers used in the War of 1812).

One evening, you decide to take in the sight yourself.  It is difficult not to find a little amusement in the sight of them playing at soldiering.  Try as they might to look dour and serious on the field, they show their true colors as soon as they are dismissed, smiling and laughing in the twilight.

While his companions disperse to mess, a lieutenant stands apart, watching the field slowly fill with cattle; it had been emptied for the afternoon by its owner for the use of the company.  Like something out of a modern pastoral, the lieutenant watches the cattle for a time, and then takes a seat under a tree.  You are about to return with the other picque-nicquers, when a strange music begins issuing from the lieutenant's hands.

Holding them to his face, you can see that he blows into them, thereby effecting the music.  Yet the nature of the device remains a mystery; it must be minuscule.  And yet it makes quite a noise! 
*if (creation = 0) and ((intelligence <= 2) and (anachronism < 70))
	(Of course, the sounds of a piano would probably surprise you—your attention to innovations in the arts is negligible.)

*choice
	#I enjoy the scene from afar, and then return to the city.
		*set compassion %-5
		*set discretion %-5
		Probably wise.  No good could have come of this.
		*if speaks_english

			"Silas?" a voice cries.  As you are turning away, you see a young sergeant hurrying up to the lieutenant.  The lieutenant stands and the two head back to camp.  Apparently, he is needed somewhere.
		*finish Next
	#Who knows what this device is!  It could be dangerous!  I stay far away.
		*set discretion %-10
		*set anachronism %-5
		Probably wise.  Anything that makes such a racket could probably double as an explosive.
		*if speaks_english

			"Silas?" a voice cries.  As you are turning away, you see a young sergeant hurrying up to the the lieutenant.  The lieutenant stands, and the two head back to camp.  Apparently, he is needed somewhere.
		*finish Next
	#Hmmm…tasty!  I wish to feed from him.
		*if (charm > 3) or ((male = false) and (charm = 3))
			A few choice words have the two of you necking under a tree.  His blood really is as tasty as you had imagined.
			*if sod_plot = false
				*set sod_plot true
				*set sod_founder "compton"

			*if speaks_english
				"Silas?" a voice calls out in the darkness.  The lieutenant stirs in your arms.

				Quickly, you right yourself, just in time for a young sergeant to appear.  He looks from you to the comatose lieutenant.  "Is he all right?"

				You assure the sergeant that the lieutenant is only feeling a little under the weather. @{male You help the sergeant to pick up the lieutenant, and watch as he carries him|You watch as the sergeant struggles to pick the lieutenant up, which he eventually does.  He then proceeds to carry the lieutenant} back to the Company's camp.

				That was close, you think to yourself.
				*finish Next
			*else
				A voice calls out in the darkness, the name of the lieutenant, presumably; he stirs in your arms at the sound.

				Quickly, you right yourself, just in time for a young sergeant to appear.  He looks from you to the comatose lieutenant, and asks a question.  "No English," you reply.

				He looks frustrated.
				*if male
					He gestures for you to help him pick up the lieutenant, which you do.  The sergeant carries the lieutenant back to the Company's camp.
				*else
					You watch as the sergeant struggles to pick the lieutenant up, which he eventually does.  He then proceeds to carry the lieutenant back to the Company's camp.

				That was close, you think to yourself.
				*finish Next
		*elseif combat >= 6
			*if sod_plot = false
				*set sod_plot true
				*set sod_founder "compton"
			With a few quick blows about the head, you knock the young musician unconscious.  His blood really is as tasty as you had imagined.
			
			The device he was playing is small, and easily fits in your hands.  It has small chambers running up and down its length.  Blowing into it, it makes the most peculiar noise…nothing like the music the man had mustered.  Mildly irritated, you drop it to the ground beside his body.
			
			*if speaks_english
				"Silas?" a voice calls out in the darkness.  Looking around, you realize someone is coming.
			*else
				A voice calls out in the darkness.  Someone is coming.

			*if stealth > 1
				Invoking your powers of misdirection, you stand and watch as a young sergeant appears.  He rushes to the side of the unconscious lieutenant, and tries to revive him.  He looks around a moment, trying to discover the source of his friend's injuries; and though you stand right next to him, he does not perceive you.

				Picking up the lieutenant, the sergeant struggles to carry him back to the Company's camp.
				*if discretion > 50
					These mortals, so unaware of what goes on around them, you think to yourself.
				*finish Next
			*elseif agility > 3
				Drawing upon your supernatural speed, you dash away from the impending confrontation.  Having to explain the lieutenant's wounds would have been difficult.
				*finish Next
			*elseif (charm > 3) and speaks_english
				You only have to wait a moment for a young sergeant to appear before you.  Turning on your brilliant smile, you spin some tale about finding the wounded lieutenant beneath the tree.

				The sergeant is initially suspicious, but you can see your powers working on him; after a few moments, he relents, his suspicions gone. He thanks you for your aide, and proceeds to pick up the lieutenant and carry him back to the Company's camp.
				*if discretion > 50
					These mortals, so weak-willed, you think to yourself.
				*finish Next
			*else
				Unwilling to confront the approaching individual, you turn and run.  

				The individual—a young sergeant—shouts for you to stop and gives chase, but soon gives up and returns to his wounded friend.

				You return safely to your haven.
				*finish Next
		*else
			Your charms have no effect upon him.  Armed as he is, and trained as a soldier, you decide it best to not try and force him to give you his blood.  Your advances clearly repulsed, you leave the soldier to his alien music.
			*finish Next
	#Approach and greet the young man.
		*if male
			You wait politely for him to finish a tune.  First he rises to greet you, and when you touch, you wonder if your heart beats once again.  You can see that he feels it too; he looks flustered for a moment, and then invites you to take a seat beside him.

			*if speaks_english = false
				You address him, and are grateful to discover that he speaks 
				*if speaks_german
					German.
				*elseif speaks_french
					French.
				*elseif speaks_spanish
					Spanish.
				*else
					*bug
		*else
			He rises awkwardly at your approach.  "No, no, please continue."  He hesitates a moment, and then rushes through the remainder of the tune.  Once finished, he puts down the instrument and addresses you.
			*if speaks_english = false
				(He even has the good sense to address you in the same tongue with which you spoke to him.)

"Evening, ${sir}," he says.

Having closed the distance between you somewhat, you are taken aback by the beauty of this young man.  "Good evening, Lieutenant.  You make quite a tableau sitting here against the moonlit sky."  
*if perception > 1
	Though it is hard to see in the dim light, you think he blushed a little at the compliment.
	*if (ethnicity = "african") or (ethnicity = "choctaw")
		Though you had meant the comment to be flirtatious, you had not expected him to respond with such transparency.

*label question_hope
*choice
	*if (ethnicity = "african")
		#"Do you think it strange that one such as I should be here watching your company's exercises?"
			"I hope you do not hold my service against me, ${sir}."

			"But are you not fighting to keep my people in a state of bondage?"

			"I am fighting an army that has invaded my home.  Could a man do otherwise?"

			You let that question hang between you, unanswered.  "The demonstration has been edifying."

			"I am glad that you found it so."
			*goto question_hope
	*else
		#"Are you satisfied with the performance of your company?"
			He huffs. "They are ill-prepared. Farmboys who have never been more than ten miles from their home. If they have any skill with a musket, it's because they're used to shooting rabbits and pheasant."

			"That dire?"

			"On the bright side, we will not have to use pikes to defend ourselves."

			"Pikes?"

			"For a time, it seemed Davis was not going to be able to provide armaments to the soldiers. We were prepared to drill with pikes. But some exigencies were resolved and now we have rifles."

			"For your sake, I'm grateful," you reply.
			*goto question_hope	
	#"What is this instrument you are playing?  I have never seen such a thing!"
		*set anachronism %+10
		"It's called a harmonica.  Before the war broke out, my family had sent me to the Continent for study.  Much to their chagrin, I discovered this little device in Vienna, and have spent more time learning how to use it than they would have preferred."
		
		"It makes the most wondrous music.  I'm glad I've had the chance to hear it."
		
		"I imagine the craftsmen that made it will see to its being imported here soon.  They were in the midst of developing great machines to multiply their production when I left."

		*if speaks_english = false
			"How amazing!  And is that where you learned to speak things other than English?"

			"It is, ${sir}.  My education was…diverse."

			"So I see," you reply.  He seems somewhat at a loss for words.
		*elseif technology > 0
			*set rationalism %-5
			"Might I have a look at it?"

			"Please," he says, extending the instrument to you.  After a few moments of study, the nature of its mechanism becomes clear to you.
			*if technology > 1
				In fact, after pondering it a moment, you find yourself offering a few suggestions as to how it might be improved. @{ask_name The lieutenant|Silas} listens, but he seems more interested in the sound of your voice than the thoughts you are expressing.
			Soon enough, though, you return it to him.  He seems somewhat at a loss for words.
		*else
			"How amazing!"

		*goto question_hope
	#"Well, I suppose I should let you get back to your mess."
		"Yes, I suppose I should go.  It was a pleasure making your acquaintance, ${sir}."  The two of you part ways.  
		
		Watching @{ask_name the young lieutenant|Silas} leave, you wonder briefly what might have passed between the two of you in other circumstances.
		*finish Next
	#"What is your name, Lieutenant?"
		*set ask_name false
		"I am Silas Hope, First Lieutenant of the Jeff Davis Rebels.  At your service, ${sir}."  

		At his words, you feel a twinge of something.  Something you have not felt for a long time.
		*goto question_hope
	*if (ask_name = false)
		#"Will your company rendezvous with your regiment soon?"
			*set ask_rendezvous true
			"No.  In fact, we leave tomorrow for New Orleans.  The Jeff Davis Rebels have not yet been assigned to a regiment, but we have been tasked with the defense of that city."
			*goto question_hope
	*if ask_rendezvous
		*selectable_if (compassion <= 75) #"Perhaps I can write to you, while you are on campaign.  I would love to hear more about your travels…"
			*if male
				You feel him soften under your gaze.  "You know, if your letters were intercepted…"
					
				"I will be very circumspect in my writings."
					
				Silas reddens, even under his tan.  "Yes, you seem like a man who values circumspection," he replies, after making sure no one is within earshot.  Once assured of privacy, he gives you instructions on how to write to him while with his regiment.

				"Silas?" a voice calls out in the darkness.  Silas steps away from you, before responding, "Mitch?"

				A young sergeant nears—Mitch, you presume—and informs Silas that it is time for mess.  You try not to bristle at this intrusion.  Silas shakes your hand in a formal goodbye, and the two turn away.
					
				You are left with the confusing memory of his scent and a jumble of emotions as you watch him make his way down the hill to the Company's mess.
			*elseif (male = false) and ((ethnicity = "african") or (ethnicity = "choctaw"))
				You feel him soften under your gaze.  "You know, if we are seen together…"
					
				"We must be careful, then."
					
				Silas reddens, even under his tan.  "Yes, you seem like a woman who values circumspection," he replies, after making sure no one is within earshot.  Once assured of privacy, he gives you instructions on how to write to him while with his regiment.

				"Silas?" a voice calls out in the darkness.  Silas steps away from you, before responding, "Mitch?"

				A young sergeant nears—Mitch, you presume—and informs Silas that it is time for mess.  You try not to bristle at this intrusion.  Silas shakes your hand in a formal goodbye, and the two turn away.
					
				You are left with the confusing memory of his scent and a jumble of emotions as you watch him make his way down the hill to the Company's mess.
			*else
				"I would like that, ma'am."  He gives you instructions on how to write to him while with his regiment.

				"Silas?" a voice calls out in the darkness.  Silas steps away from you, before responding, "Mitch?"

				A young sergeant nears—Mitch, you presume—and informs Silas that it is time for mess.  You try not to bristle at this intrusion.  Silas shakes your hand in a formal goodbye, and the two turn away.
*page_break

A few evenings later, you find yourself with a few moments of free time.  Looking at your writing desk, it occurs to you that you could write that lieutenant you met the other evening.

*if literate
	Do you want to write a letter to him?  And if so, what kind of letter?
*else
	But how will you write to him?  You do not know how to write!

	Of course, there is ${wilson}; he could pen the letter for you.  Of course, ${wilson} agrees.  But do you want to send a letter?  And if so, what kind of letter?
*choice
	#Foolishness!  No good can come of such pursuits!
		*set discretion %-10
		Surely, you would make your sire proud, were he here to see such prudence.
		*finish Next
	#Amorous.  I found him most enchanting.
		*if literate
			*set compassion %-5
			The words spill forth from your pen, decorating the page with your observations and anticipations.  The pages fill quickly, and all too soon you must put a period to your ruminations.  With a few drops of wax and scent, you send your words winging to what you hope is the heart of Silas.
	
			It is thus, with great excitement, that you receive a letter in return two weeks later.
		*else
			*set compassion %-5
			*set discretion %+5
			It is with some embarrassment that you ask ${wilson} to record your dictation.  You had never realized just how fortunate you were to acquire his services.
		
			Together, the two of you compose a letter communicating your observations and anticipations.  The pages fill quickly, and all too soon you must put a period to your ruminations.  With a few drops of wax and scent, you send your words winging to what you hope is the heart of Silas.
	
			It is thus, with great excitement, that you receive a letter in return two weeks later.
	#Friendly.  He could be a useful contact within the army.
		*set compassion %+5
		When the response arrives, it is clear that Silas was hoping for more from your missive.  His letter is polite but restrained.  You can @{literate hear|feel} his longing pulsing through the interstices.
		
		Though you seek to maintain the correspondence, you do not hear from him again.  You later learn that he died covering the retreat of his Company from New Orleans.  Upon hearing this, you wonder briefly what might have passed between the two of you in other circumstances, but soon put it from your mind.
		*finish Next
	*if literate
		#Fickle.  The better to inflame his passions.
			*set discretion %+5
			You take your time striking the right balance of entreaties and dismissals.  The letter is not terribly long—you don't want him to think you were pining for him.  

			With a few drops of wax and scent, you send your words winging to what you hope is the heart of Silas.

			You receive a letter in return two weeks later.
*page_break 
*if literate
	Between some mundane affairs and the infernal pestering of ${wilson}, it takes you several hours before you can find a moment of solitude in which you can read the letter in private.
*else
	Unfortunately, you have to ask ${wilson} to translate it for you.  It takes several hours before you can quite bring yourself to do so, but eventually you thrust it towards him and ask that he read it to you.

Hope relates the news of his adventures; in particular, he speaks highly of Mitchel Compton, his dear friend and the sergeant of the Company.
*if discretion > 55
	You feel your hackles rise at the praise lavished on the man.  Silas should be spending his time praising you, not this Mitch fellow.

The best news is held for the end; the Jeff Davis Rebels will be returning to Vicksburg shortly.  It seems that New Orleans has been abandoned by the Confederacy.

Waiting for his return is tortuous.
*if creation > 1
	*set waiting_on_the_war true
	*achieve balladeer
	You find yourself composing a ballad, full of longing, about waiting for your lieutenant to return from the war.  Maybe some night you will have the opportunity to sing it for Silas.
*page_break 

When you are reunited, it is awkward at first.  A single meeting and an exchange of letters separated by long periods of introspection have left the two of you filled with ideas but little actual knowledge of each other.

You spend time moving through the dance of courtship, and as the nights pass you feel something blossoming between you.  It is quite thrilling to find yourself the object of pursuit.  So often, you are pursuing your prey, cajoling them in your way.  With Silas, however, you are the quarry, and with the twin javelins of poetry and twilight serenades on his harmonica, you feel him bringing you down.

One evening, Silas recites one of Shakespeare's sonnets.  As with many of the Bard's sonnets, love and death are closely intertwined.  It ends with the couplet: 

[i]But if thou live remembered not to be,[/i]
*line_break
[i]Die single, and thine image dies with thee.[/i]
*if intelligence > 2

	The speaker in the poem pleads with his young love to reproduce before he dies, that the world will not lose the pleasure of his visage.
*choice
	#I am flattered by his attentions, and tell him so.
		He is clearly pleased that he has pleased you.
	#I dislike these melancholy sonnets…I tell him to find something cheerier next time.
		*set compassion %+5
		He promises that he will find something less somber next time.
	*if intelligence > 2
		*if priest
			#"Your words are pretty but they offer me no solutions, Silas. Long ago I swore that I would never take a wife. There will be no other visage like mine."
				"And yet you repudiate your vows by seeking to become intimate with me."
				
				"One transgression has evidence; the other does not."
				
				"Is that all I am to you, a transgression?"
				
				"Of course not, Silas—" you begin
				
				"When this war is over," he interrupts, "I will marry, and you will return to your ministry. It is only here, now, that we can carry on in this way."
				
				"And will you come to me for guidance in this new regime?" you ask wryly.
				
				"I am not Catholic."
				
				"Then let us enjoy each other as long as we may," you reply.
				*page_break
		*elseif male
			#"Am I to take his words as being your advice?  Do you want me to marry a woman and have her bear a child so that the world will not be without the sight of me?"
				Caressing your face he whispers back, "There is no path under Heaven by which we may be joined in this world, my dearest.  I find the thought that you should wither into oblivion to be untenable.  Your immortality will be through the children you father.  When this war is over, you will marry, and we shall be nothing more than the best of friends.  But that will be enough."
				
				"No, there must be a way that we can be together!"
				
				"None that I can see."
				
				"I shall find a way…" you say before Silas kisses you into silence, clearly unaware of how deadly serious you are.
				*page_break
		*else
			#I ask him if he has any thoughts as to who the father of my reflections ought to be.
				*set compassion %-10
				*set discretion %+5
				He stutters a bit at your candor, but quickly recovers.  It seems clear that he means to propose marriage once the war is over.
				*if (ethnicity = "african") or (ethnicity = "choctaw")
					*set love_hope true

					"And does the color of my skin mean nothing to you?"  He pauses, as though taking the color of your skin into account for the first time.  You continue before he can respond: "For there is no place in this country that would harbor us."

					"I fight for my brothers, the men who have put their faith in me to lead them.  Not the slave-holders and bigots."

					"But aren't your neighbors and some members of your family slave-holders?  How will you separate the two?"

					"We will leave these States, then.  Whoever wins, it does not matter.  We will go to Haiti, or further afield.  Where we can live together in peace."

					"Then why fight at all?"

					*goto wrong_side_of_history
	#Poetry?  Delivered by a Confederate lieutenant?  This is not the man for me.
		*set compassion %+5
		Silas is clearly startled when you spurn him.  "But, your letters…" he says weakly.
		
		You push him away from you and can almost hear his heart breaking as you march away.
		*finish Next

*set love_hope true

That said, the fall of New Orleans weighs heavily upon him; he seems to take it as an almost personal failing that he was unable to prevent it, or at least did not die trying.  When he looks into the distance, you can see the clouds of despair gathering around him.  In these quiet moments, he confesses that he cannot see how the Confederacy will win.

*choice
	*if ethnicity != "southern"
		#"Would that be so bad?"
			*goto wrong_side_of_history
	*if ethnicity = "southern"
		*selectable_if (intelligence > 2) #"Would that be so bad?"
			*goto wrong_side_of_history
	*if (ethnicity = "african") and (compassion < 75)
		#"Then let us celebrate, for the Union will set my people free."
			*set compassion %-10
			*if male
				"Even if Lincoln does free the slaves, we will still have to keep our love secret."

				"Then let us leave now.  There is no need for you to continue this fight.  Let us go where we will be welcomed."

				He looks at you sadly.  "Is there such a place?"

				"We will go where they will not question two brothers-in-arms traveling together.  Where the color of our skin, at least, will not matter.  And if that place does not exist, then we shall fashion it ourselves.  But let us go, now, away from all this…"

				He shakes his head.
				*goto wrong_side_of_history
			*else
				"Even if Lincoln does free the slaves, the people of the South will never accept our love."
				
				"I have no need of their acceptance…only yours.  Tell me truly: do you love me?  Without reservation?"

				"I do," he replies fervently.

				"But how can you?  When this separates us?" you say, taking his hand in yours, interweaving your fingers.

				"When this wretched war is over I will accompany you wherever you wish."

				"But if this war is wretched, why not leave it?"

				"I have a duty to my men."

				"And what of your duty to me?"

				"Until and unless I fulfill my duty to my men, there is no me to be dutiful to you.  I am not Achilles, who had the luxury of retreating to his tent when it suited him.  The enemy has brought the war to my home, and I am simply another Trojan, who by taking the field preserves the honor of his loved ones for one more day."  For the honor of loved ones who subject your people to the horrors of bondage, you observe to yourself ruefully.  "But I promise you that when this duty has been discharged, I will follow you unto the ends of the earth.  Wherever you would lead, I will follow."

				You place your hand upon his chest, feeling the beating of his heart through your palm.  "Then do not worry.  The places we will go, they will not look at us twice, except to beg for our company."

				He sweeps you into his arms, and the two of you fall into a long kiss.
				
				Meanwhile, the Union noose draws tighter.
				*finish Next
	*if (ethnicity = "choctaw") and (compassion < 75)
		#"This will mean the end of my people; the Union will grind us into dust for our support of the Confederacy."
			*set compassion %-10
			*set anachronism %+10
			"I fear that you speak the truth."
			
			"Then how can we stop them?"
			
			"We can't.  We are on the wrong side of history."
			
			"How can you say that?"
			
			"The Confederacy is trying to hold on to a world that no longer exists, that fades every day further into the past.  We were too proud to accept that change peacefully, and so we began a war that will cause that change to be forced upon us."
			
			Meanwhile, the Union noose draws tighter.
			*finish Next
	*selectable_if (rationalism > 30) #"Impossible.  God is on our side, and we shall never be defeated."
		*set rationalism %+20
		*set anachronism %-10
		"I hope that you are right.  For God help us if you are wrong."
		
		Meanwhile, the Union noose draws tighter.
		*finish Next
	#"Do not sorrow.  This too shall pass."
		*set compassion %+10
		"How do you mean?"
		
		"Wars and nations come and go.  This too shall pass.  Dry those tears, and enjoy this repast I made for you."  
		
		Silas seems a little offended at your indifference to his sorrow.  But no matter, soon he will better understand your perspective.
		
		Meanwhile, the Union noose draws tighter.
		*finish Next
	*if male
		#"I hope the war goes on forever, so that we never need part."
			*set compassion %+10
			"As do I, dear ${given_name}.  But it will not.  And when the war ends…"
			
			"Do not speak of it.  I know what you think will happen, but I tell you that we shall find another way."
			
			Meanwhile, the Union noose draws tighter.
			*finish Next

*label wrong_side_of_history
*set wrong_side_of_history_argument true
"We—the Confederacy—are on the wrong side of history; my travels in Europe have shown me that.  And I despair for the carnage and the devastation that must be wrought to bring the Confederacy to its knees.  Only by bringing it to the brink of destruction will it surrender.  Which means that every life lost between now and that point is given not to change the outcome, but to make it irrevocable."

"And so you fight to make the defeat that much more complete?  Is that your idea of heroism?"

"But is that not the very definition of heroism, when one struggles against the Fates despite their having already decided against you?  Achilles took the field when he could have retired home; if you are correct, then so too does the Confederacy bring honor to itself by fighting when it knows its cause is lost."

"That is all well and good for those who fight and die, but what of the children who will grow up without fathers?  I see no honor in abandoning your family for your own glory."

"I do not fight for my own glory."

"Does that mean that you will forsake your company, then?"

"No, I cannot do that."

"But why, when you may very well forsake me in prosecuting this war you acknowledge is already lost?"

"Because I cannot abandon my men.  I have a duty to them."

"Your duty?  And what of your duty to me?"

"Until and unless I fulfill my duty to my men, there is no me to be dutiful to you.  The truth of the matter is, I am not Achilles; I am already home.  Instead, I am simply another Trojan, who by taking the field preserves the honor of his loved ones for one more day."
*if (ethnicity = "african") and (compassion < 65)

	For the honor of loved ones who subject your people to the horrors of bondage, you observe to yourself ruefully.
*comment endif

Meanwhile, the Union noose draws tighter.
*finish Next