*comment ñáéç
*hide_reuse
*advertisement
*temp learn_about_ambuscade false
*gosub_scene util check_flow
*if met_samantha = false
	*set withers_rapport %+20
	*set learn_about_ambuscade true
	There is only one other vampire in Vicksburg, Samantha Withers.  She has been here since sometime in the 1830s, @{((perception > 1) and (intelligence > 1)) and has the air and diction of having been born in the decades before the American Revolution|and has an accent that makes her seem much older than she looks}. @{(lore > 0) Withers was granted the title of Quaestor of Vicksburg in 1843 by Governor Overstreet, her broodmate.|}
	
	Soon, an introduction is arranged…
	*page_break
	"Welcome to Vicksburg, ${mr} ${surname}.  I fancy that your stay here will be in accordance with the norms of the Society?" she inquires. @{speaks_english |You are relieved to see that she speaks your tongue.|}
	*set presented_vicksburg true
	*set met_samantha true
	
	*if taught_three_rules
		"It shall be, Quaestor," you reply.
		
		"Excellent.  I would have you know that I like to play cards.  It is so boring playing with my servants, as they always let me win.  And what passes for mortal society around here…well, the women of it have neither the years of experience nor the dedication to make it challenging.  Thus, your presence would be appreciated on Tuesdays."

		"I…yes of course, Quaestor."

		"I am glad to hear it."
		*if maddox_num = 2
			She finally glances at Anselm. "Is there anything else you wish to tell me?"
			
			"Ah, yes. I bring a valet with me. His name is Anselm Martin." Anselm, hat in hand, bows.

			"You valet is welcome as well, ${mr} ${surname}."

			"Thank you, Quaestor Withers."
		
		*if (speaks_english = false) and (avoided_new_orleans and (sire_name != "West"))
			"Before you go, ${mr} ${surname}: this is not Louisiana—and it most certainly is not the bayou. We speak English here. I suggest you learn it…posthaste."
			
			You nod your head in acknowledgement.
		
		Over the following months and years, the squabble between the North and the South only intensifies…

	*else
		You are flummoxed by this question.  "The Society?" @{(discretion <= 50) you say, hesitantly.|you say without skipping a beat.  There is no need to show weakness before this person.}
		
		Samantha's eyes widen incredulously.  "Yes, the Society."
		
		"What is that?"
		
		"What vampire created you, and left you ignorant of the Society?"
		
		"My maker was ${sire_name}."
		
		*if met_jesse
			@{jesse_is_broodmate "That is funny, he never mentioned you.  I was recently in New Orleans…"|"I have heard of ${sire_name}, but have never had the pleasure of his acquaintance."}
				
			"Yes, our acquaintance was short-lived."
		*elseif jesse_is_broodmate
			*set withers_rapport %+5
			"Oh," she says, disappointed.
			
			"Quaestor?"
			
			"Your broodmate Jesse is quite…rude."
			
			"My broodmate?"
			
			"Jesse Whitaker?"
			
			"I must confess, I am unacquainted."
			
			"You have not met Jesse? Oh, there may be hope for you yet!"
			
			"I have met very few of our kind—"
		*else
			"I have heard of ${sire_name}, but have never had the pleasure of his acquaintance."
		
		"I see.  Well, then, I suppose it falls to me to instruct you in the ways of the Society."
		
		"I would be most honored, Mlle. Withers."
		
		"You can begin by addressing me by my title, Quaestor Withers."
		
		"Yes, Quaestor Withers."

		*if maddox_num = 2
			"And your valet?" she says, nodding towards Anselm.

			"Yes, exactly. His name is Anselm Martin, and he…"

			"Yes, yes…he too is welcome here."

			"Thank you, Quaestor." She smiles, as though it were a treat for a dog that had performed a trick.
		
		She takes her time and, over many hands of cards, does her level best to communicate her understanding of the Three Rules to you: Respect, Restraint and Reserve.  They command (respectively) that you honor a governor and her quaestors, that you refrain from assaulting other vampires, and that you conduct yourself so as to remain hidden from the view of the mortal world.
		*set lore +1
		
		She goes on to explain that her broodmate, Theresa Overstreet, is the Governor of the province; she lives in Savannah, and appoints all the quaestors in the domain.
		*set heard_of_overstreet true
		*set taught_about_governors true
		
		Considering your recent experiences in St. Charles parish, you recognize the need to learn the ways of vampire-kind. 
*elseif met_samantha and (withers_embarrassed = false)
	*set presented_vicksburg true
	*set withers_rapport %+10
	"${mr} ${surname}, what a pleasure it is to welcome you to my city!"  It seems that whatever reservations Samantha Withers might have had regarding your method of elucidation, the warm glow of success has effaced them.

	"Quaestor Withers, I had heard that you had found yourself a new home here."

	"Yes…I am still unsure as to whether it is a blessing or a curse, but I certainly do maintain a lively correspondence with others of our kind, desperate to hear of my victory over Mr. Whitaker and who solicit verses from me for their own amusement."

	"I am grateful to hear it."

	"Well, you should know that I have developed a certain affection for cards…I hope you will join me on Tuesdays?"  It appears that you are the first of your kind to take up residence in her city.
	
	A quaestor without a citizenry…she is right to question the value of the appointment.  "Of course, Quaestor Withers…" you reply, as though you had a choice.
*elseif frenzied_on_jesse
	*set presented_vicksburg true
	*set withers_rapport %+5
	*if status = 0
		*set status +1
	"${mr} ${surname}. What brings you to my city?" inquires the still icy Samantha Withers.
	
	"You were present for my final night in New Orleans, Quaestor. I am given to understand that you are the only reason that I was not put to death then and there.  For that, I cannot thank you enough."
	
	"It was the least I could do for your defense of my honor. Now I understand that Mr. Whitaker was a snake and manipulated you as he did me. I hope that we will see no need for a similar outburst here?"
	
	"No, Quaestor, I cannot imagine the same thing happening here." Your enthusiasm on that point seems to disappoint her a little.
	
	"Very well.  I will expect you here on Tuesdays for a game of cards…"
*else
	*set presented_vicksburg true
	"${mr} ${surname}.  What brings you to my city?" inquires the still seething Samantha Withers; it seems that a few decades have not cooled her rancor.
	*if can_do_nothing_about_withers and ((speaks_english = false) and (speaks_french = false))
		The venom of her questioning cause you to almost overlook the fact that she is addressing you in your native tongue.
	*comment endif
	
	"One might say that it was the same thing that brought you here.  And by 'thing,' I mean individual."

	With a certain cruel delight in her eyes, Samantha presses: "Did Mr. Whitaker deceive, betray, and mortify you as well? Did his maneuverings result in your ostracism from the only society available to our kind? Did he recruit a young, naïve individual such as yourself to aid him in the execution of his schemes?"  Her voice becomes shrill as she concludes.

	*if encourage_withers
		*set withers_rapport %-10
		"Quaestor Withers, it was as much of a lesson in our kind for you as it was for me.  I do not celebrate the role I played in your downfall, but I think that, at this time, you will benefit from my presence in your city.  Though it may assuage your pride to deny me succor, I cannot imagine that you want stories of your want of hospitality to further blacken your name."
		
		Withers looks stunned.  For all her speech a few moments ago, she reveals herself to still be easily outmaneuvered.  "We wouldn't want that, now would we, ${mr} ${surname}?  I don't suppose you play cards?  Because I will expect your attendance on Tuesdays…"
	*else
		*choice
			*if can_do_nothing_about_withers = false
				#"Quaestor Withers, your imaginings were your own.  I was honor-bound to say nothing."
					"Honor?  Honor?  What do you know of honor, ${sir}?"
	
					Before saying something that you might regret further, you pause and draw breath.  "Quaestor Withers, I understand that I failed you in the past.  But now I find myself in need of a home, and you in need of a citizenry.  Perhaps we can come to some sort of detente."
					
					She pauses to consider the merits of your proposal.  "If I find you to have betrayed me again, I will see to it that my verses will be heard in every court in this hemisphere, mocking you and your 'honor.'  Do I make myself understood?"
	
					"You do, madame."
	
					"Very well.  I will expect you here on Tuesdays for a game of cards…"  
			#"Quaestor Withers, I was unaware of his designs.  I meant you no harm, and can only plead for your forgiveness."
				*set withers_rapport %+15
				She seems mollified by your expression of contrition.  "Well, ${mr} ${surname}, I'll have you know that I have been sorely in need of a companion for cards.  I hope you will join me on Tuesdays…"
			*if can_do_nothing_about_withers
				#"Quaestor Withers, there was no tongue that we shared.  Even if I had known his intentions, I could not have warned you."
					*set withers_rapport %+20
					Withers's mien softens a little at that.  "Yes, after our meeting, I decided to learn your language…it seemed somehow appropriate."  After that, conversation turns to simpler things, and before you leave, she invites you to attend her on Tuesdays for a game of cards.
			*if ethnicity = "choctaw"
				#"Quaestor Withers, in the wake of your criticisms of my people, I had other things on my mind than your impending debacle."
					*set discretion %+10
					"Savages, I say.  Even undead, you are incapable of offering consideration for others."

					You grit your teeth.  "Quaestor Withers, I understand that we have had our disagreements in the past.  But now I find myself in need of a home, and you in need of a citizenry.  Perhaps we can come to some sort of a [i]détente[/i]."

					She pauses to consider the merits of your proposal.  "If I hear it told that corpses are turning up scalped, I will not pause to destroy you."

					"Have no fear, Quaestor.  I shall not scalp any of the mortals of your city."  For the first time in your existence, however, you suddenly find yourself lusting after hers.

					"Very well.  I will expect you here on Tuesdays for a game of cards.  You have learned how to play cards, no?"

					"Yes, Quaestor.  I am more than capable of playing a hand of cards…"

*page_break
*temp language_problem false
*if (charm < 3) and ((stealth < 4) and (ethnicity = "african"))
	At first you encounter some difficulties with establishing yourself a haven here—the local citizenry doesn't take kindly to what they assume to be a freeperson trying to find a home among them—but with a few quick words from Withers, you find a house suitable to your needs.  
	*if maddox_num = 1
		Soon after you move into your new haven, you hire a freedman by the name of Wilson.
		*gosub language_problem
*if (charm < 3) and ((stealth < 4) and (ethnicity = "choctaw"))
	At first you encounter some difficulties with establishing yourself a haven here—the local citizenry doesn't take kindly to an "Injun" trying to find a home—but with a few quick words from Withers, you find a house suitable to your needs. 
	*if maddox_num = 1
		Soon after you move into your new haven, you hire a freedman by the name of Wilson.
		*gosub language_problem
	
	Though Withers does extend herself for you in this way, @{(withers_rapport < 45) it is clear that she still holds no love for you or your people.|she is clearly still slow to trust you.  An unlife of prejudice is not washed away quite as easily as one might like.}
*elseif maddox_num = 1
	You have no difficulties establishing a haven here and soon hire a freedman by the name of Wilson.
	*gosub language_problem
*else
	With the help of Anselm, you quickly establish a haven suitable to your needs.
*goto vicksburg_intro_3

*label language_problem
*if language_problem = false
	*if speaks_english = false
		You selected him because, among other talents, he speaks
		*if speaks_french
			French,
		*elseif speaks_german
			German,
		*elseif speaks_spanish
			Spanish,
		*else
			*bug what language??
		making him invaluable as a translator.
*set language_problem true
*return

*label vicksburg_intro_3
He helps organize the sun-proofing of the house, as well as making any other modifications you deem necessary. @{maddox_num He pays very close attention to your instructions; a missing ear testifies to the cruelties of his previous life.|You purchase a professionally-made eyepatch for him; he looks almost dashing with it on.}

*if maddox_num = 1
	It is only a few months before you begin to find his assistance indispensable.
	*choice
		#This is how it should be.  Vampires were made to rule, and mortals to serve.
			*set rationalism %+10
			*set compassion %+20
		#It is not a matter of right and wrong.  I am his employer, and he is my employee.  I will reward him for good service, and fire him should he warrant such.
			*set rationalism %-15
			*set compassion %+10
		#I'm grateful for such loyalties.  I make sure that he knows how appreciative I am.
			*set compassion %-15

Your home established, you begin attending card games on Tuesdays at the home of Withers.
*if ethnicity != "choctaw"
	Part and parcel with the card games on Tuesdays is listening to Withers prattle on about this and that.  One of Withers's favorite topics during these moments is the exodus of the Native Americans to Indian Territory.  Their absence from the streets of Vicksburg is a source of ongoing delight.  To listen to her tell it, Vicksburg was—until recently—a hotbed of Injun thievery; while a pitiful child kept your attention, a father would empty your larder.

*if (charm > 2) and (ethnicity != "choctaw")
	During the course of your card games, Withers eventually confides in you the source of her animosity towards the Indians. 
	*label confidence_re_choctaw
	*set withers_rapport %+10
	It seems that while still a child, she was a witness to the murder of her family by a marauding band of natives.  Hiding in a haystack, she watched the lot of them being hacked to pieces and their farmhouse outside of Middle Plantation burnt to the ground.
	*if (ethnicity = "choctaw")

		When you ask her why she chose to share this detail with you, she looks at you with surprise.

		"You're not like the rest of the redskins. You're…civilized."

		@{((compassion < 60) and (discretion > 40)) You suppress the urge to show her otherwise.|}

	*if intelligence > 2
		In time, and with a bit of research, you are able to determine that the massacre of which she speaks occurred in 1676 during Bacon's Rebellion.

	Most of the rest of your conversations turn on the business of the city.  She is also eager to discuss the events of the day, offering her rather strident opinions unbidden.
	*if (compassion > 50) and (discretion > 50)
		You find it a little strange how concerned she is with the affairs of the mortals.  It's almost as though she still thinks of herself as one of them.
*elseif (ethnicity = "choctaw") and ((withers_rapport >= 55) and (charm > 1))
	During the course of your card games, Withers lets slip her animus towards Indians. Whether embarrassed or no, she proceeds to share some rather intimate details from her life.
	*goto confidence_re_choctaw
*else
	During these games, Withers does her best to gossip with you about the various characters of the city, as well as offering her rather strident opinions on the events of the day.
	*if (compassion > 50) and (discretion > 50)
		You find it a little strange how concerned she is with the affairs of the mortals.  It's almost as though she still thinks of herself as one of them.

*page_break
As your first months pass in Vicksburg, you learn to appreciate the rhythms of the city.  The steamers chug up and down the Mississippi with a nearly clockwork regularity, timed as they are to the arrivals and departures of the trains to the east and west.  From here, you can envision the commerce of the southern states in action, coming and going through the gates of this outpost of civilization that squats on the knee of the Father of Waters.

Most interesting of all is the steady flow west of mortals.  Every day another family sets out into the great unknown to try their hand at something like prosperity. 
*if ((finance > 1) or (intelligence > 2)) or ((intelligence = 2) and (technology > 0))
	In the midst of such commerce, it is almost impossible not to make money by means of the clever application of your resources.
	*set wealth +(income*5000)
	*set income +5

*if background = 3
	*page_break
	You find that life in Vicksburg is not like life in New Orleans. In New Orleans, you were acutely aware of the hierarchy of the races and your place in that hierarchy. But because you were born free and because of the light shade of your skin, little was completely closed off to you. Sure, occassionally a shopkeeper would demand that you enter through the back door, but only rarely would he refuse to serve you. You knew where you were going to be treated like a person, and where you weren't; the Faubourg Ste. Marie, with its Anglo-American arrivals and its streets named for the Muses, was decidely unsafe after dark. And while you were always unfailingly polite to the gendarmes, you generally enjoyed the presumption of innocence when interacting with them.
	
	This is not the case in Vicksburg. Here, you are black; there is no middle ground. White people walk towards you as though you do not exist. The first time you refused to back down, the encounter very nearly necessitated the intercession of a sheriff's deputy. The man—Mr. Troutwine—who bumped into you turned red with outrage and assaulted your ears with vitriol.
	
	Uninterested in drawing any further attention to yourself, you apologized and withdrew.
	
	A few weeks later, you contemplate taking vengeance on Mr. Troutwine for his conduct towards you.
	*choice
		*if (stealth > 2) #I kill him in his sleep.
			*set compassion %+10
			*set discretion %-5
			You do not even deign to drink his blood. You simply slit his throat and leave him choking in his bedclothes.
			
			You slip out of the house before the house has fully awoken.
		#I stalk him until I can drink him dry.
			*set compassion %+5
			*set discretion %+5
			It takes almost six months before you learn his routines enough to strike. However, when you do, you do so without hesistation.
			
			You glory in the taste of his heartsblood as he exhales one final time.
		#I am not so petty as to seek vengeance on a mortal for his ignorant behavior.
			*set justice %-5
			*set compassion %-20
			Mr. Troutwine will never know how close he came to death.
*elseif priest
	*page_break
	You find that life in Vicksburg is not like life in New Orleans. There are very few Catholics here, and the Anglo-Americans treat them with contempt. Catholicism is associated with the French and New Orleans, two corrupt and dissolute entites that the upstanding people of Vicksburg want nothing to do with.
	
	Thus, you are not welcomed into homes here the same way that you were previously; your cassock and collar are more a liability than an asset. You are forced to adapt to new ways of feeding to compensate.
	*set anachronism %+3

*if (avoided_new_orleans = false) and literate
	*page_break
	*set jesse_rapport %+5
	
	To your surprise, you receive a letter from Jesse.
	
	Therein he mostly rambles about the affairs of New Orleans, spending an inordinate amount of time filling you in on the new residents of the city.  It seems that, in the years since your departure, several new vampires have sought and received succor from ${new_orleans_quaestor_surname}.
	
	He spills a significant amount of ink on the subject of the new Senator of New Orleans, an Italian vampire by the name of Chiara Santagostino.  Several senators from throughout the province descended on New Orleans, and by the time they left, she had been chosen for the position.  It is clear that Jesse has yet to make up his mind about her.	
	*set heard_of_chiara_santagostino true
	*if jesse_rapport < 40
		Knowing Jesse, however, he will no doubt make an enemy of her forthwith.
	
		The strangest thing about the letter, however, is the impression you get that Jesse therein expresses a longing for your company.  You are immediately suspicious of this impression, but try as you might, you cannot shake it.  You find yourself turning his words over in your head for weeks, debating on how or whether to reply.
	*elseif jesse_rapport <= 60
		You idly wonder whether he will lay a trap for this one as well.
	
		The strangest thing about the letter, however, is the occasional remark implying that he actually misses your presence.  You are immediately suspicious of these innuendos, but try as you might, you find yourself turning his words over in your head for weeks.
	*else
		For a brief moment, your heart seizes at the thought that she might turn Jesse's thoughts from you, but soon these concerns are put to rest once Jesse expresses his despair since your decision to depart New Orleans.  From his perspective, your next meeting cannot arrive soon enough.

*if maddox_num = 1
	*page_break
	*temp knows_runaway false
	During your daysleep, you sense commotion above. It's voices…quarreling.
	
	When you emerge, you find Wilson and a slightly younger man that must be Wilson's brother.
	
	@{(compassion < 50) "Who is this, Wilson?" you inquire. |"What are you doing in my house?" you demand.}
	
	"Sorry, @{male suh|mam'selle}, this is mah bruthah. He's jus' leavin."
	*if (compassion < 45) and ((perception > 0) or (intelligence > 2))
		*set knows_runaway true
		You know from previous conversations with Wilson that this brother—Harvey—is a slave on a plantation just outside Vicksburg. It doesn't take much to deduce that he is trying to escape his bondage.
	
	*choice
		#"Take your business with your brother out of my house."
			*set discretion %-5
			*set sod_plot true
			*set sod_founder "maddox"
			"Muh apologies, @{male suh|mam'selle}. Ah'll see him out."
			
			Wilson grabs his brother by the scruff and guides him out the door.
			
			*if (shepherd_credentials > 50) and (knows_runaway = false)
				You later discover that Wilson's brother—Harvey—had run away from the plantation where he was enslaved. A hunt is organized for him, but you suspect that, with Wilson's help, he made it onto a boat upriver and thence to freedom.
			*else
				When he returns, you chastise Wilson for bringing his family to your home and endangering you. He begs your forgiveness.
				
				@{(discretion > 50) You do not deign to give it.|}
		*if (knows_runaway) #"Your brother wants his freedom? Let's get him out of the city."
			*label help_harvey
			*set exposure +1
			*set compassion %-10
			You and Wilson spend the evening finalizing the details for Harvey's transit north. Wilson has already arranged most of the affair, but a final dockworker is being intransigent; you take it upon yourself to set the dockworker straight.
			
			Just before dawn, you and Wilson stand on the docks, watching a steamboat pull away. Wilson thanks you profusely.
		#@{knows_runaway Harvey|Wilson's brother} is too much of a threat to me. I separate the two of them and kill the newcomer.
			*set compassion %+5
			*if exposure > 4
				*set exposure -1
			"Welcome!@{knows_runaway  You must be Harvey.|}"
			
			"Thank you, @{male suh|mam'selle}."
			
			"What brings you to my door this evening?"
			
			@{knows_runaway Harvey|Wilson's brother} looks to Wilson and back to you.
			*if knows_runaway = false
				"Mah name's Harvey. You knowd Ah'm Wilson's brother."
				
				"Yes," you reply.
				*line_break
				*line_break	
			"Wul, Ah'm headed north. Ah's done with the beatin's and all dah rest."
			
			"I understand. Wilson, please tend to your chores. I'll see your brother safely onto a boat."
			*label kill_harvey
			
			"But…"
			
			"It's no trouble. I'll handle everything."
			
			"Yes, @{male suh|mam'selle}," Wilson mutters.
			
			You guide Harvey out of your home and to his doom.
			
			When you return home later, Wilson asks after his brother. You affirm that Harvey is now safely away.
			
			Wilson does not bring up his brother again. You suspect that as long as he doesn't ask, he can lie to himself that maybe, just maybe, his brother is living free and happy somewhere.
		*if (knows_runaway = false) #"Why is your brother in my house?"
			It takes several minutes to pull the story from the two men, but finally you learn that Harvey—Wilson's brother—has finally decided to flee the plantation where he is enslaved. Wilson has promised to help him, having arranged most of the necessary details to convey his brother north.
			
			*if compassion > 60
				You momentarily consider simply returning Harvey to his owners, but that would both engender more questions and would seriously undermine Wilson's loyalty. Finding Wilson was hard enough; losing him now would be unfortunate.
			
			*fake_choice
				#I separate them and kill Harvey; he's too much of a danger.
					"Wilson, please tend to your chores. I'll see your brother safely onto the boat."
				#I help Wilson with the final details.
				#Tell them to take their business out of my house.
					*set discretion %-5
					*set sod_plot true
					*set sod_founder "maddox"
					"Muh apologies, @{male suh|mam'selle}. Ah'll see him out."
					
					Wilson grabs his brother by the scruff and guides him out the door. "Ah'll be back shortly," he says over his shoulder.
					
					*if (shepherd_credentials > 50) and (knows_runaway = false)
						You later hear that a hunt is organized for Harvey, but it seems that he has successfully escaped to the north.
					You do not discuss Harvey with Wilson again.
*if maddox_num = 2
	*page_break
	When you awake one evening, you happen upon Anselm hunched over a letter, his face wet with tears. With some coaxing, you learn that his youngest sister has passed.
	
	It has been some years since Anselm fled St. Charles parish with you, abandoned his family and his home. He has never returned, but he has maintained a correspondence with some of his siblings since.
	
	*choice
		#"This is your life now. Put these thoughts away."
			*set compassion %+5
			Anselm dries his tears and stands. You are right that there are chores that need doing.
			
			You do not hear word of the Martin clan again.
		#"You should go home for the funeral."
			*set compassion %-5
			Anselm is @{(compassion < 50) thrilled|surprised} by your recommendation. After thanking you profusely, he packs his things and heads to the docks in the hopes of catching whatever riverboat will next be departing south.
			
			When he returns a week later, he is disconsolate. The loss of his sister is difficult, yes, but his family knows who you are and what sort of creature you are. They cannot understand why he has chosen you over them.
		*selectable_if (wealth > 200000) #I send him home to the funeral with gifts for everyone.
			*set wealth -10000
			*set discretion %+5
			Anselm is overwhelmed with gratitude for your generosity. Of course, acquiring these gifts means a bit of a delay, and he is anxious to depart. Finally, you see him down to the docks and onto a steamer.
			
			When Anselm returns a week later, he is bereft. His family knows who you are and what he did when he chose you over them. They burnt the gifts you sent, seeing them as guilt-money. They told Anselm to leave and never come back.
		
*page_break
	
Elsewhere in the nation, the squabble between the States comes to a head. In October of 1859, the abolitionist John Brown leads a raid on a Federal Armory in Harper's Ferry, Virginia. His objective was to seize the weapons there, free the local slaves, and inspire them to form an army that would end slavery in the United States forever.

The local slaves largely reject his overtures; moreover, they are farmhands…they hardly know one end of a musket from the other. Brown makes several more tactical errors. Soon, he is surrounded and cut-off from escape in a small building, derisively referred to as John Brown's Fort. A unit of US Marines under the command of Robert E. Lee arrives. When negotiations break down, Lee orders the attack. The raid is quashed. Brown is tried, convicted of treason, and hanged about six weeks later. The affair is recorded in exacting detail in reports and magazine articles; the whole country is talking about the audacity of the man and the incivility of these "abolitionists." 

This raid excites the imagination of the slave states. Every visitor from the north is treated with suspicion: is this a spy come to lay the groundwork for another plot? How dare these Northerners come south to steal the property of the righteous, god-fearing Southerners? Editorials decry crimes both real and imaginary.

*if intelligence > 1
	It is unclear to you how much these papers are describing—and how much inciting—this conflict.  
To further inflame the matter, every week another well-known businessman or politician is announcing that there can be no solution other than secession.

When the Republican Senator from Illinois, Abraham Lincoln, is elected 16th President of the United States, representatives of the Slave States begin threatening the lives and well-beings of the President-elect and their Northern counterparts. When pressed on the matter—threatening the lives of their colleagues—they assert that they have been misquoted, misunderstood, or are otherwise being slandered by the urban Northern elites.

On the road to his own inauguration, rumors of an assassination plot convinces Lincoln to change his itinerary and ultimately slip through Baltimore incognito. He is escorted to the White House by the Pinkertons, a private security and detective agency based out of Chicago. When word of Lincoln's precautions become public, he is lambasted for his cowardice. Moreover, since no plot was uncovered, many accuse Alan Pinkerton of fabricating the threat in an effort to raise the profile of his enterprise.

*choice
	#Lincoln was smart to take his safety seriously. Threats of violence are not trifles.
		*set compassion %-5
	#It was a cowardly act. A real man would not diminish the office of the Presidency out of concern for his safety.
		*set discretion %+15
	#I believe the rumors—there was no plot. Rather, this was a scheme by Alan Pinkerton to benefit his agency.
		*set compassion %+5
*set exposure -1

Mississippi secedes from the Union on January 9th, 1861, the second state to do so. On February 9th, representatives of seven states gather in Montgomery, Alabama to organize and elect a president, Jefferson Davis, to lead them.  Two days later, Davis gives his first presidential speech here in Vicksburg, where he states that he has earnestly worked to maintain the Union, but that "our safety and honor required us to dissolve our connection with the United States. I hope that our separation may be peaceful. But whether it be so or not, I am ready, as I have always been, to redeem my pledges to you and the South by shedding every drop of blood in your cause…"

What do you think of President Davis's position?
*temp tick false

*choice
	#He is lying; the secession is a blatant power-grab by the Southern plantation-owners.
		*set compassion %-5
		*set shepherd_credentials %+5
		*set justice %-5
	#He is being righteous; the Federal Government had no right to interfere in the workings of the states.
		*set compassion %-5
		*set shepherd_credentials %+5
		*set justice %+40
	#I do not care about these mortal squabbles.
		*set compassion %+5
		*set shepherd_credentials %-15
		*set tick true
	*if (discretion >= 40) and ((charm > 2) or ((stealth > 3) and (charm > 1)))
		*selectable_if (feeding_style != "vegetarian") #I don't know, but I'll be sure to ask him when I feed from him.
			*label feed_on_davis
			*set fed_from_davis true
			*achieve fedondavis
			*set exposure +2
			*set discretion %+10
			*set shepherd_credentials %-10
			Really, you are too occupied with feeling self-satisfied that you're feeding from the Confederacy's President to bother asking him about his speech.

*if haitian_sugar_plot > 1
	*page_break
	*if haitian_sugar_plot = 3
		*set income -5
	Following Davis's speech in Vicksburg, things begin to move very quickly as other nations begin to place their wagers on the outcome of the impending conflict. Thus, while Thérèse Maffi took a certain pleasure in undercutting the sugar-planters of Louisiana through your smuggling efforts, supporting the Confederacy is unacceptable for her. Therefore, she puts an end to the intrigue.
	
	She does send you a gracious thank-you, however, noting that the revenue from your efforts has contributed to a stronger Haiti.
	
	*choice
		#By ending this intrigue, she has betrayed me and the Confederacy. I will remember this!
			*set maffi_rapport %-10
		#It was becoming difficulty to maintain the matter from Vicksburg anyway; the better to be quit of it.
			*set discretion %-5
		#I was preparing to end it myself! There was no need to suppport the Confederacy with these exchanges.
			*set shepherd_credentials %+5
		
	The matter closed, you turn your attentions closer to home. It is not that war is coming, no; rather, war is here.
*elseif tick = false
	Following Davis's speech in Vicksburg, things begin to move very quickly as other nations begin to place their wagers on the outcome of the impending conflict. It is not that war is coming; rather, war is here.
*if learn_about_ambuscade
	*page_break A Few Weeks Later
	One evening, while intoxicated on the blood of a young dilettante, Withers confesses a shameful episode to you.
	
	It seems that, several decades ago, she and her broodmate, Governor Overstreet, paid a visit to the court of New Orleans. While there, Overstreet formally appointed ${new_orleans_quaestor_surname} to the position of Quaestor. Unfortunately, @{jesse_is_broodmate your broodmate, Jesse|the villain Jesse Whitaker} managed to embarrass her in front of everyone.
	
	"He's a monster. Believe nothing that he says, ${given_name}."
	
	You nod, noncommittal. Whatever this intrigue, you know too little of it to take a stance.
	*if met_jesse
		*if jesse_rapport > 60
			Besides, when you met Jesse, he did not seem nearly as nefarious as Withers would have you believe.
		*elseif jesse_rapport > 43
			Besides, while you and Jesse did not hit it off, he did not seem nefarious when you met.
		*else
			Though, your own engagement with Jesse did leave you with a bitter taste in your mouth.
*finish Next