*comment ñáéç
*hide_reuse
*advertisement
*gosub_scene util check_flow
*gosub_scene util combat_value_ss
*temp love_denied false
*temp lied_to_silas false
*temp hope_suicide false

It becomes clear to those who observe that as long as the Mississippi stays under its control, the Confederacy has a chance: the river divides the two halves of the South, providing a critical north-south artery.  The key to the Union's Anaconda Plan is to take control of the great waterway, and then let the two halves wither and die.  Once New Orleans falls in May of 1862, Vicksburg and Lieutenant General Pemberton are left holding the line.

*if love_hope
	When you wake the next evening, there is a note from Silas.  His regiment has been issued a rendezvous point, and his Company is departing for Meridian in the morning.  He is with his men now and will not be able to see you again before they depart.  He promises to write, however, and professes his undying love.

	He clearly does not understand the irony of his word choice.

	Fortunately, the 46th returns to Vicksburg shortly after its rendezvous.
	*page_break 
	The 46th is assigned to defend Vicksburg, and other than a variety of skirmishes in the Yazoo delta over the next few weeks, it remains bivouacked nearby.

	The rest of 1862 passes with you and Silas meeting furtively whenever he can steal away from his regiment.  Your nights are sweet, and made all the sweeter by the secrecy of your affair.  One evening, though, he presses you to come see his company on parade the next day.  He persists beyond your standard excuses.
	*choice
		*selectable_if (charm > 2) #I use my wiles to make him end this line of questioning.
			*set compassion %+10
			*set discretion %-10
			"…and I really wish you would stop asking me about this, dear Silas."
			
			"You are right…it really was improper for me to press you so…"
		#"You have worn me down…I will see you there." You lie, only so he will stop his badgering of you.
			*set compassion %+10
			*set discretion %+5
			*set lied_to_silas true
			Silas is overjoyed.  After planting a kiss on your lips, the two of you part, he with a spring in his step.

			After he departs, you instruct ${wilson} to attend the parade on your behalf.
			*page_break
			When you meet the next evening, you let him fill in most of the details of the day's events, simply nodding and smiling at the appropriate moments.  A few observations supplied by ${wilson} do the rest.  You judge that Silas does not doubt you, even for a moment. @{(compassion < 45) Unfortunately, this means you are only that much more tormented by the fact that you have lied to him like this.|}
		#"I simply cannot, Silas.  And I must insist that you drop this matter."
			*set compassion %-10
			
			Silas pauses, stunned by the force of your response.  "I'm sorry, I meant no offense…"
			
			"The only offense is your unwillingness to accept 'no' for an answer, my dearest.  Believe me, if I could attend the parade tomorrow, I would be there."  He seems somewhat cheered by this last bit.
		#"The truth is that I am allergic to the sun.  Were I to go out and watch you, I would be ill for days…"
			*set compassion %-5
			*set discretion %-5
			"Oh, my love!  How dreadful!  I had no idea!"  At this, he begins to shower you with kisses…

	*page_break
	*if literate
		A few nights later, you find yourself reading in your study.  Silas has been unavailable since the night of the parade, and so you have been occupying yourself with some of the recent newspapers bringing word of the war from the various fronts.
	*elseif (creation > 0)
		A few nights later, you find yourself sketching in your study.  Silas has been unavailable since the night of the parade, and so you have been occupying yourself with some studies of fruit.
	*else
		A few nights later, you find yourself sunk in thought before a fire in your study.  Try as you might, the flames do little to warm you.  Silas has been unavailable since the night of the parade, and you find your thoughts turning often to him.

	You are startled by a tap at your window.  Looking up quickly, you see Silas smiling through the panes.
		
	"What are you doing?" you scold him as you admit him to your study.

	"I could not stand to be apart from you for another moment!"

	"It is late!  You will be reprimanded if you are discovered away from your Company!"

	"Every lash will be received with joy if you will permit me to spend the night with you."
	*choice
		*if male = false
			#"No!  You have gone too far…I cannot…not yet…"
				*set discretion %-10
				"Have I offended you, my dearest?"
				
				"No…it's not that…"
			
				"What then?"
				
				"Give me a few more days…meet me where I first found you the night after next…"
				
				With a frantic kiss full of longing, Silas departs through the window.  You can almost imagine your heart beating in desire as the sounds of his footfalls fade.
				
				As far as you are concerned, the time for your meeting cannot arrive soon enough.
		*if male
			#"We cannot…if someone saw you outside my house…the punishment for sodomy…"
				*set discretion %-10
				"No one saw me…"
				
				"No, not tonight…please…"
			
				"Then when?"
				
				"Give me a few more days…meet me where I first found you the night after next…"
				
				With a frantic kiss full of longing, Silas departs through the window.  You can almost imagine your heart beating in desire as the sounds of his footfalls fade.
				
				As far as you are concerned, the time for your meeting cannot arrive soon enough.
		*if priest
			#"I am forbidden from doing these things…my vows…"
				*set rationalism %+10
				"I do not understand, dear ${given_name}.  What is this that is between us, then?"
				
				"Give me a few more days…meet me where I first found you the night after next…"
				
				With a frantic kiss full of longing, Silas departs through the window.  You can almost imagine your heart beating in desire as the sounds of his footfalls fade.
				
				As far as you are concerned, the time for your meeting cannot arrive soon enough.
		*if (knows_parts_dont_work = false)
			#I bring him into my arms and into my bed.
				At first, the experience is nothing short of embarrassing and excruciating.  To your dismay, you discover that your parts do not function as they did during your mortal existence.  Were that not embarrassing enough, the actual act of him penetrating you is simply painful, your dead flesh immune to his attentions.  Silas himself is horrified at his inability to arouse you, and soon ceases his efforts.
				
				"Have I done something wrong?" he asks plaintively.
				
				"No…here, let us try something…else."  Pushing his chin away, you expose his throat to your fangs.
				
				Sinking them into his neck, you hear a small gasp.  Within a few moments, though, he is lost in waves of ecstasy.  Wanting to prolong the sensation, you slow the draining of his life-force to the most excruciatingly slow drip, only to find that, as his heartbeat slows, yours spurs to life, soon beating in time with his.
				
				In that moment, you find an intimacy you have not felt since your first death.
				
				When dawn approaches, you tear yourself away from your lover with promises to return soon.
		*else
			#Mortals and their silly fixation on sexual intercourse.  "Come, let me kiss you on your neck…I will show you pleasures you have never imagined."
				Given the leisure to drink his blood slowly, you soon find your heart sparked into motion and your pulse beating in time with his.  The feeling is like nothing you experienced during your mortal days. @{love_clotho Thoughts of Clotho come to mind as his blood slips past your lips.  You wonder briefly whether you are betraying her memory, but soon brush aside these thoughts.|}
				
				In the morning, you send Silas on his way a little light-headed.  You make him promise to meet you two nights hence where the two of you first met.
				
				As far as you are concerned, the time for your meeting cannot arrive soon enough.
	*page_break
	The early March night is crisp and clean, an evening rain having washed the air of the regiment's campfires.  The past few weeks have seen your passion only intensify.  The two of you have spent as much time together as your respective restrictions have allowed.  He has, in fact, grown somewhat thin and drawn from the lack of sleep, trying to satisfy his duties to both his men and you.

	Tonight, though, finds the space between the you pregnant with possibilities.  He gazes deeply into your eyes, waiting for that sign that there is no turning back.
	*choice
		#I profess my love for him.  [i]Amor vincit omnia[/i]!
			*set compassion %-5
			He takes your hand in his and proclaims his love for you as well.  The two of you embrace, and spend the rest of the evening in breathless ecstasy.
			
			You steal away before the break of dawn.
			
			*page_break 
			
			The next few nights are a blur, as you try to reconcile your feelings with the reality not only of your existence but of the war and the Union armies which seem to be closing in around Vicksburg.
			*if waiting_on_the_war
			
				You perform your ballad for him.  He is amazed @{(agility > 2) that you are able to sing and play the fiddle at the same time, but with your supernatural dexterity and concentration, this is no great feat|at the quality of your voice}.  The second time you sing it for him, he joins in with his harmonica, and soon he urges you to perform it for the Jeff Davis Rebels.
				
				The soldiers of the Company are thrilled by the piece, and its tune soon becomes ubiquitous.  The thought that someone is waiting for them back home in Vicksburg, longing for their return, animates their spirit.
			
			The war churns forward…
			*if (creation > 0) and (anachronism > 50)
				*page_break
				You luxuriate in these nights with Silas.  His talents—both literary and musical—kindles something in the depths of what was once your heart.

				One evening, he offers to teach you how to play his harmonica.
				*fake_choice
					#That would please me greatly.
						*set learned_harmonica true
						*set anachronism %+10
						He is right; it takes little effort for you to master the little device.  The fact that you no longer respirate makes the whole affair a little peculiar, but soon enough you are turning this to your advantage, making noises on the instrument that no human could produce.  Silas is clearly amazed by this.
					#No, no…I prefer to listen.
						*set discretion %-5
						Silas smiles at your reticence and soon resumes playing.
					#Truly, I dislike the racket this new device creates.  Let us return to the poetry.
						*set anachronism %-10
						Silas is clearly saddened by your dislike for his music, but he is happy enough to recite Homer to you.

			*page_break
			The 46th Mississippi Infantry is ordered south to the Deer Creek region and set out on March 25th, 1863.  You plead with Silas not to go, to stay with you in Vicksburg, but his sense of honor demands that he stay with his regiment.  You extract more promises from him that he will write to you regularly, promises he seems only too happy to make.
				
			It is, therefore, with terror that you receive a note not in his hand less than two weeks later.  Your relief is overwhelming when you @{literate read the letter|have your valet read the letter to you}, which was dictated by Silas to a medical adjutant.  It seems he was wounded in a small skirmish and seems mostly embarrassed about the matter.  Much to his dismay, the wound necessitates his return to Vicksburg, despite the fact that his Company is remaining at Deer Creek.  The date on the letter makes you think he might have already returned.

		#I tell him that I am disgusted by him.  This road will only lead to misery.
			*set love_denied true
			*set discretion %-15
			*set compassion %+5
			Silas is clearly crushed.  Keeping back tears, he retreats down the hill, waving off your apologies.  But, surely, it is for his own good, right?

		#This has gone on too long.  I put an end to him.
			*set love_hope false
			*set compassion %+20
			*set discretion %+5
			*if sod_plot = false
				*set sod_plot true
				*set sod_founder "compton"
			You take your time draining Silas, allowing his heart to push yours into motion.  The ecstasy of his final breath is something you will cherish for some time.
			*page_break
			A few days later, Mitch comes by, asking if you have seen Silas.  You inform him that you haven't, feigning concern over the news of his disappearance.  Apparently, the Company is preparing to write him off as a deserter.

			You agree with Mitch that Silas would never do such a thing.

			He seems suspicious of you, but eventually relents, leaving you to focus on other things.
*elseif (lore > 2) and (shepherds_and_wolves = false)
	*set shepherds_and_wolves true
	
	Of course, much of the late 1860s is spent playing cards with Withers. That and doing your best to feed surreptitiously amid food shortages and constant struggles between the US Army, the members of the supposedly-disbanded Knights of the Ku Klux Klan, and the freedmens' militias that have organized to defend themselves.
	
	During your conversations, you impress Withers with your knowledge of vampire affairs. However, while discussing the scoundrel Jesse Whitaker one evening, she stumbles upon an oversight in your education.
	
	"He is a Wolf, no doubt about it."
	
	*if heard_of_shepherds_and_wolves 
		"You know, I did overhear a conversation once, but I never had the chance to ask for details."
		
		Withers snaps her handfan closed dramatically. "Let us correct that here and now!"
		
		"@{(withers_rapport > 55) I am your pupil.|I am all ears.}" Withers seems quite delighted to have the opportunity to demonstrate the virtues of being raised in a real vampire court once again.
	*else
		*set withers_rapport %-5
		*set heard_of_shepherds_and_wolves true
		"A…wolf?"
		
		Withers snaps her handfan closed dramatically. "Yes, a Wolf! Do you not know of the Shepherds and Wolves?"
	
		"No, I can't say that I do."
	
		"You've been here for several years now, and this is the first time this has come up?"
		
		"I'm afraid so." You can't quite tell if Withers is delighted to know something that you don't, or disdainful towards your lack of education—perhaps a bit of both.
	
	"Vampires across the globe can broadly be grouped into Shepherds and Wolves. Shepherds believe that we must tend the humans, guide them towards something better—or just make them more pliant to our needs. Wolves, on the other hand, enjoy the thrill of the hunt: if the prey doesn't fight back, what fun is being a predator?"
	
	*choice
		#"No fun at all."
			*set shepherd_credentials %-5
			Withers titters uncomfortably at your statement—she treats it as a jest, though you did not mean it as one.
		#"Must we think of humans as no more than food? Can we not be equals?"
			*set shepherd_credentials %+10
			"Heavens, no! Not even the most ardent Shepherd thinks that we should lower ourselves to such a degree. We tend the flock so that we might cull it when necessary."
		#"I can see the value in this way of thinking."
			*set independence %+5
			"I'm glad to hear it."
	
	"Now, about my dominus…" you begin. She grins; you can tell she is looking forward to more of this conversation.
*elseif (lore > 2) and (senators_representation = false)
	*set withers_rapport %+10
	*gosub withers_senators
*page_break
The Emancipation Proclamation of January 1st, 1863 renders the Confederacy's situation even more dire.  With that document, the Union Army and Navy opens its ranks to blacks, and it further grants freedom to the slaves in territories captured from that point onward.  The steady enlistment of up to 200,000 fresh soldiers and sailors does nothing to hurt the Union cause.

*page_break The Siege Begins
*set year 1863
Vicksburg is eminently defensible, and therefore it is left as one of the last objectives of the Anaconda Plan.  On May 16th, 1863, word arrives that Major General Grant has just captured Jackson, the capital; to the north, Major General Sherman's flanking maneuvers force Lieutenant General Pemberton to withdraw to Vicksburg; following two disastrous encounters, Pemberton's forces limp back through the fortifications in disarray.  Shortly, Grant orders a march on Vicksburg, and early on the morning of the 19th, he is within visual range of the city.

The villages, hamlets, and plantations that surround the city have mostly emptied, refugees streaming into the city and the arms of relatives and strangers alike.  Some of the slaves are abandoned by their fleeing owners, while many others are brought along into the relative safety of the city.

${wilson} stands ready to do your bidding.  The question is, do you flee the city, and risk the open road with no place to sleep when dawn comes, or do you wait and trust in your faculties to see you through the battle and possible occupation?  Fleeing the city will also necessitate leaving behind much of your accumulated wealth.

*if lore > 1
	A final, risky proposition is to have yourself buried, and sleep through the conflict.  Of course, if your friends are killed or forget about you, you could end up stuck in your grave indefinitely.…
*choice
	*if (love_hope = false) or (love_hope and love_denied)
		#I will stay here.  I prefer to be awake and able to respond to approaching dangers.
			*goto may_21
	*if (love_hope = false) and ((lore > 1) or knows_about_torpor)
		*selectable_if (choice_randomtest = false) #While I may end up being there for a long time, asleep and buried is better than dead, right?
			Before the sun rises, you give your ${wilson} orders to see to the digging of a grave.  When you awake in the evening, the grave has been dug and a coffin is waiting for you.  ${wilson} also informs you that the first attack of the Union forces at Stockade Redan was easily repulsed.
			
			@{maddox_num "I wul have 'em dig yous out, y${es_suh}, as soon as the war es ovah,"|"I will have them dig you out as soon as the war is over,"|ERROR} ${wilson} explains.  You gaze down into the coffin, considering.  To lie in rest there may save you from the cannonballs of the Union, but it will also leave you vulnerable to anyone who discovers you by accident.
			
			*choice
				#Yes, into the earth I go.
					*set discretion %-30
					*set blood 0
					The soft thud of dirt hitting the lid of the coffin slowly gives way to the softer sound of dirt hitting dirt.  Before long you close your eyes, and slip into the sleep of the dead.
					
					Time passes while you sleep…
					*set anachronism %-10
					*page_break 
					The crack of the wooden lid jolts you awake, the head of a pickax centimeters from your nose.  Someone has found your resting place.  Whoever it is seems as surprised as you, as you can hear people speaking excitedly above you.
					
					From the receding lethargy in your limbs, you estimate it to be close to sunset.  Your head is foggy with sleep, and you can't remember if you had your grave dug in morning shade or evening shade.  And besides, you could be wrong about it being close to evening.
					
					Do you burst out of your coffin, or wait and see what happens?  You are awfully hungry and very weak.
			
					*choice
						#Let them clear a little more dirt, and then burst out and drink their blood.
							*label kill_diggers
							You burst out of the coffin, spraying wood chips and dirt in all directions.
							*if combat >= 6
								The workers are not trained warriors by any means.  You slay one before the others can blink, and a second before they can even think to defend themselves.  The rest decide enough is enough and turn to run.
								
								You will feast tonight.
								*goto 1866
							*else
								A lucky blow by one of the workmen fells you like a stone.  Within moments, the others fall to and begin hacking at you with their tools.  You scream with rage as they dismember you bit by bit.  Even a mangled skull is not enough to stop your protestations, though, until finally a shovel manages to decapitate you.
								
								You are dead.
								*page_break 
								*set killed_by_mortal true
								*goto_scene scoring
						#Let them clear a little more dirt, and then burst out and make a run for it.
							*if willpower > 2
								Despite your inhuman craving for blood, you manage to resist the urge to tear into the workmen that are shocked to immobility before your ravenous form.  Before they can even raise their tools in defense or cry for help, you are running past them.  The sun singes your hair and skin, but you find shade and shelter within a few moments.  Tonight, you will feast on rats.  Perhaps tomorrow you will feel up to bringing down larger prey.
								*page_break
								*goto 1866
							*else
								*goto kill_diggers
						#Wait to see what happens.
							Half an hour later, the digging begins again, but with something resembling care this time.  Before long, it comes time to act.
							*choice
								#Now it's time to kill them.
									*goto kill_diggers
								*selectable_if (stealth > 2) #Now that they've cleared off the coffin, I'll just saunter out once they open it by making them perceive it as being empty.
									The workers open the coffin, and finding it 'empty'.  You are stretched to the limit to maintain their ignorance of you, but you manage to get past them and slip off into the twilight.  Tonight, you will feast on rats.  Perhaps tomorrow you will feel up to bringing down larger prey.
									*page_break
									*goto 1866
								#I want to try and talk to them.
									The workers begin screaming to everything that is sacred and holy when you open your desiccated lips, draw air into your lungs, and begin speaking.  Most of them turn and run, but one of them holds up a cross and begins trying to pray you away.
									*choice
										*selectable_if (rationalism < 80) #Kill him.
											*set compassion %+20
											*set discretion %+15
											Silly mortal.  His blood is tasty.  So tasty.  After resting for so long.
			
											Feeling somewhat refreshed, you set out into the night.
											*goto 1866
										#Turn and run.
											*set discretion %-10
											*set rationalism %+10
											You flee into the night before this display of faith.  You are too weak and disfigured to prey on a human, so instead you feast on rats.  Perhaps tomorrow…
											*goto 1866
				#On second thought…
					The idea of relinquishing agency turns your stomach.  Your decision means that you will survive or perish on your own decisions, rather than from the whims of fortune.
					*page_break
					*goto may_21
	*if love_hope
		#I cannot abandon Silas! @{love_denied Even though I tried to push him away,|} I must find him!
			*if love_denied
				It takes you and ${wilson} several days to locate Silas. It seems that he was wounded in a recent engagement, and is currently in the infirmary.
			
				When you arrive, it is just in time to see him take his first walk across a room since his wound. When he catches sight of you, a number of emotions play across his face. "You left me."
			
				"Forgive me," you reply.
			
				After a moment,
			*else
				You locate Silas, just in time to see him take his first walk across a room since his wound.  It seems he was waiting to make a grand entrance, rather than sending you word of his location in the infirmary.
			
				You enthusiastically chastise him for keeping you in such suspense.  Once you have finished with your reprimand, 
			he waves off his nurses and then takes you in his arms to kiss you.  You feel the desire within you rising in tides like never before.  You feel that the moment of decision has arrived.
			*choice
				#"My dearest, I have something to tell you…"
				
					His eyes widen in surprise at your revelation.  "That does explain many things," he remarks at one point.
					
					He listens to you carefully, clearly considering the consequences of what it is that you are telling him.  
					*if lied_to_silas
						"You never did attend the parade, did you?"
						
						"No, I regret to say that I did not."
						
						"How can I trust you, if you are so eager to lie to me?"
						
						"Eager?  Never eager.  I simply thought it expedient to let you think I'd attend the parade, until I could be sure of your affection…"
						
						You fall silent, watching him consider this. 
					Finally, he stands and embraces you.  You soften in his arms.
					
					"You are mine.  I love you as you are."
					
					"Then I must make you like me, so that we can be together forever."
					
					"So be it," he concludes.  Taking your head between his hands, he kisses away your tears of blood.
					
					*page_break
					*goto order_of_operations
				#No…this has gone too far.  I concoct some lie to drive him from me.
					*set love_denied true
					*set discretion %-15
					*set compassion %+5
				
					"…and that is why I have come to say goodbye."
					
					"This…this cannot be.  You are lying to me."
					
					"I am not.  You are nothing to me.  Goodbye."  The moment that your fingers finally part, you feel the light of his love extinguished within you, like a candlelit tomb suddenly plunged into darkness.
					
					He chases you to the door of the infirmary, hobbling on his wounded leg.  He calls out to you as you stride resolutely away.
					
					*page_break
					
					When you lie down for the day of May 22nd, you give specific instructions to ${wilson} to survive the day.  Training new mortals is so time-consuming, after all.  He nods and closes the door to your sleeping-place above you.
			
					Your sleep is uneasy.  The smell of flowing blood and the sound of death-screams seeps through the cracks in the floorboards, engendering a not insignificant amount of visceral titillation.  Such thoughts are, however, tempered by your very real fears for Silas; you have heard that he has rejoined his company and will be on the line today while you sleep.
					
					*page_break 
					*goto hope_dies
				#This has gone too far, yes…but I cannot stand to be apart from him.  I drink his blood until he is dry.
					*set love_hope false
					*set compassion %+20
					*set discretion %+5
					With a promise to the nurse to return him shortly, you take Silas on a walk outside the infirmary.  He does not return.
					*page_break 
					*if sod_plot = false
						*set sod_plot true
						*set sod_founder "compton"
					A few days later, Mitch comes by, asking if you have seen Silas; you were the last to see him, after all.  You inform him that you haven't, claiming that you parted ways with him outside the infirmary and feigning concern over the news of his disappearance.  Apparently, the Company is preparing to write him off as a deserter.
			
					You agree with Mitch that Silas would never do such a thing.
			
					He seems suspicious of you, but eventually relents, leaving you to focus on other things.
					*page_break
					*goto may_21
	*selectable_if (choice_randomtest = false) #Armies marching?  Time to turn tail and run!  I am confident in my abilities to survive in the wilderness.
		*set discretion %+5
		*if love_hope and (love_denied = false)
		
			*set compassion %+5
			Apparently, your affections for Silas were not as deep as you imagined.  Self-preservation usually does win out in the end.
			*page_break
		*goto flee_vicksburg

*label order_of_operations

The question at hand, then, is how you want to go about this.

Do you want to turn him yourself?  Or shall you approach Quaestor Withers and gain her permission first?  Or perhaps you could flatter her by asking her to do it for you? @{(lore >= 2) It is important to note that turning a mortal without the permission of a quaestor can mean death for the both of you.|}

*if withers_rapport <= 30
	Of course, your relationship with Withers is less than stellar.  The chances of her granting you this privilege are probably slim.
*elseif (withers_rapport <= 50)
	You are not on exactly the best terms with Withers.  But maybe she'll see the value in having a soldier join the ranks of her citizenry?

*temp request_withers_turn_silas false

*choice
	*selectable_if (discretion >= 40) #I will turn him.  I need no one's permission!
		*set independence %-15
		*set discretion %+10
		*comment it's only 10% because you haven't actually done it; he dies before you have the opportunity to turn him.
		
		Deciding to throw caution to the wind, you arrange a rendezvous with Hope on the night of the 21st.  On your way to meet him, you can hear noises of the Union army preparing for their assault in the morning.
		*page_break
		
		"Dearest Silas, if you are like me, than we can be together forever!  No more war, no more fighting, no more separation!"
		*goto plea_to_defend
	#I will take him to see Quaestor Withers.
		*set independence %+10
		*set discretion %-10
		
		You convince Silas to accompany you to Withers's haven, where you can petition her for the right to turn him.  As the two of you head to meet her, you can hear noises of the Union army preparing for their assault in the morning.  You must hurry.
		
		*page_break

		Arriving at Withers's haven, you leave Silas in an antechamber while you petition her for permission to turn Silas.

		"…and therefore I request the privilege of turning Mr. Hope into a loyal member of the Society."

		*if withers_rapport > 70
			"Dearest ${given_name}!  I cannot tell you how thrilled I am to hear these words.  I wish you only the best!"
			
			"Quaestor, I am honored by your indulgence."  It seems that Samantha is indulging her romantic side again.
			
			"Please, let me make his acquaintance!"
			*page_break Silas Enters
			*goto granted_permission
		*elseif withers_rapport >= 50

			Withers pauses to consider your request.  "${mr} ${surname}, we have had a good relationship, and I am inclined to grant you your request.  However, I must insist that you wait until after the siege is complete."
			
			"After the siege?"
			
			"Yes.  The blood supply is already constrained enough as it is.  We would be hard pressed to welcome another to our ranks, especially one newly-turned."
			
			"You are wise, Quaestor.  I will defer to your decision."
			
			"That is good to see, ${mr} ${surname}.  Please, I would like to meet my future citizen now."
			
			*page_break You Fetch Silas
			*goto granted_permission_postponed
		*elseif withers_rapport >= 35
			*set silas_denied_blood true
			
			"This is not the time to be asking such questions, ${mr} ${surname}."
			
			"Not the time?"
			
			"Yes.  The city is surrounded, the blood supply is dangerously constrained.  And your actions have done nothing to merit this request.  So I suggest you postpone this request for another time."
			
			"Yes, Quaestor."  At that, you withdraw from her presence.
			
			*page_break 
			You relay the news to Silas, who takes it stoically.  You offer words of encouragement, as you think Withers can be persuaded once the siege is over.  As the dawn arrives, he moves to bid you good evening, observing that he must be back with his new Company before dawn.

			"Back with your Company?  But…you are a vampire now!  Or soon!  There is no reason to go back to that nasty war!"
			*goto plea_to_defend
		*else
			*label withers_rejects_request
			"Do you jest with me, ${mr} ${surname}?"
			
			"Jest, Quaestor?"
			
			"Hunting is already difficult enough as it is, what with patrols of soldiers constantly moving through the city.  What makes you think adding another to our ranks now would be a wise decision?"
			
			"But…Quaestor…"
			
			"And have you revealed our nature to Mr. Hope?"	You had best be careful with how you tread here…there are moments when you can sense that mortals are trying to deceive you…perhaps Withers can do the same with vampires?
			*choice
				#I lie.  "No, Quaestor."
					*set withers_rapport %+5
					*set discretion %-5
					*set independence %-5
					
					"At least you have some sense in that head of yours.  See to it that this bull is kept in the dark.  If he survives the siege, we may be able to arrive at some sort of solution.  But until then, I will hear no more of this.  You are excused."
					
					You leave Withers's salon and find Silas waiting for you near the front door.
					*page_break 
				#I tell the truth.  "Yes, Quaestor."
					*set discretion %+5
					*set withers_rapport %-5
					*set independence %+5
					
					Withers shakes her head.  "Yet again, you astound me with your ignorance and brazen disregard for the customs of the Society, ${mr} ${surname}.  Tell me, why should I not put Mr. Hope to death, exile you from my city, and write to Governor Overstreet regarding an order for you to be put to death?"
					
					You leave Withers's salon, and find Silas waiting for you near the front door.
					*page_break 

			"We cannot speak here," you whisper, guiding Silas into the street.  Once safely away from Withers's haven, you inform Silas of your failure.  He does his best to comfort you, but you are despondent.  Soon, the sky begins to brighten.  As you turn towards your haven, Silas observes that he must part ways with you, as he must be back with his new Company before dawn.

			"Your Company?  But…that means you will be in the fight today!"

			"Yes."

			"But…you might die!  My dearest, you cannot do this!"
			*goto plea_to_defend
	#We could always flee the city together.…
		*set independence %-20
		*set discretion %-10
	
		Escaping the city together will be a challenge.  You invite Silas to your haven so that you may attempt to convince him of the wisdom of your plan.

		"We must flee!  Don't you see, the quaestor will deny my request to turn you…we have to leave the city.  And if she finds out that you already know of our kind…it could be the end of both of us!  Once outside of her purview, I can turn you, and then we can set ourselves up in another city…Memphis, maybe.  Or St. Louis!"
		*goto plea_to_defend
	#I will ask her to do it for me.
		*set independence %+20
		*set withers_rapport %+10
		*set discretion %-10
		You convince Silas to accompany you to Withers's haven, where you can petition her for the right to turn him.  As the two of you head to meet her, you can hear noises of the Union army preparing for their assault in the morning.  You must hurry.
		*page_break
		Arriving at Withers's haven, you leave Silas in an antechamber while you petition her.

		"…and therefore I request that you turn Mr. Hope into a loyal member of the Society."

		*if withers_rapport > 70
			She smiles at you.  "It is flattering that you should make this request of me, ${mr} ${surname}, but I am sure that it would mean so much more were you to do it yourself.  After all, he is your love, not mine."

			Your heart leaps at this.  "Quaestor, I am honored by your indulgence."  It seems that Samantha is indulging her romantic side again.

			"Please, let me make his acquaintance!"
			*page_break Silas Enters
			*label granted_permission

			"…and so, Quaestor Withers has granted me permission to admit you to the Society."  At this, Silas bows deeply to Samantha.  As he does so, she shoots you a look of excitement, like a schoolgirl sharing in a secret.
			
			"Oh, but where shall you do it, dear ${given_name}?  Given the leisure, you should take your time in choosing.…"  Conversations along these lines continue for some time more, as Samantha seems intent on making the experience as meaningful as possible for Silas.
			
			All too soon, however, the time comes to retire to your haven.  It is on the way out the door that Silas observes that he must part ways with you, as he must be back with his new Company before dawn.
			
			"Back with your Company?  But…you are a vampire now!  Or soon!  We have been granted permission!"
			*goto plea_to_defend
		*elseif withers_rapport >= 50
			Withers pauses to consider your request.  "${mr} ${surname}, we have had a good relationship, and I know the influence of love on our decision-making.  And while it is flattering that you should ask me for this permission, the romantic in me demands that I grant you that privilege, rather than taking it for myself.  However, I must insist that you wait until after the siege is complete."
	
			"After the siege?"
			
			"Yes.  The blood supply is already constrained enough as it is.  We would be hard pressed to welcome another to our ranks, especially one newly-turned."
			
			"You are wise, Quaestor.  I will defer to your decision."
			
			"That is good to see, ${mr} ${surname}.  Please, I would like to meet my future citizen now."
			
			*page_break You fetch Silas.
			*label granted_permission_postponed

			"…and so, Quaestor Withers has granted me permission to admit you to the Society, once the siege is over."  At this, Silas bows deeply to Samantha.  As he does so, she shoots you a look of approval.
			
			"Oh, but where shall you do it, ${mr} ${surname}?  Given the leisure, you should take your time in choosing.…"  Conversations along these lines continue for some time more.  All too soon, however, the time comes to retire to your haven.  It is on the way out the door that Silas observes that he must part ways with you, as he must be back with his new Company before dawn.
			
			"Back with your Company?  But…you are a vampire now!  Or soon!  We have been granted permission!"
			*goto plea_to_defend
		*else
			*goto withers_rejects_request

*label plea_to_defend

Silas shakes his head firmly.  "My love!  We will be together forever, but tomorrow I must be with my men.  My Company already left me behind because of my wound; I cannot forsake my regiment as well.  Especially when you realize that the Union numbers are overwhelming, and this is the hour of their greatest need!"  You plead with Silas, but he is intransigent.

*choice
	#Accept his decision.
		*set compassion %-5
		With a sigh, you signal your acceptance of his decision.  This is the man you are in love with, being who he is.  The two of you part after some moments of tenderness.
		*page_break 
		*goto plea_to_defend_2
	#Force the turn upon him.
		*set compassion %+10
		*set discretion %+10
		*if (combat > 7) or (agility > 3)
			Your supernatural speed is too much for him.  Before he can blink, you have him on the ground, and you are feasting from his frothing life-force.  "No!  Please…" are the only words he can croak out, before the last of his blood passes through your lips.
			
			Before the light passes totally out of his eyes, you bite your own wrist, and offer him his first taste of eternity.
			*page_break 
			
			Forcing him to stumble alongside of you, the two of you make your way back to your haven.  With whatever energy he can still muster, he pleads with you to let him go to his men.  "You have turned me into a coward!"
			*page_break
			
			You slip into your resting place with Silas, while admonishing ${wilson} to survive the day.  Mortals are so hard to train, after all.
			
			Though Silas struggles against you, he does so with the coordination of a drunk.  Occasionally, he grimaces in pain.  The conversion is clearly not going smoothly.
			*page_break
			
			Your sleep is uneasy.  The smell of flowing blood and the sound of death-screams seeps through the cracks in the floorboards, engendering a not insignificant amount of visceral titillation.
			
			Sometime around noon, you are woken by the violent breaking of the floorboards above you.  Your immediate reaction is to burrow deeper into the darkness, away from the brutal sunlight.  Thus it is too late to intercede when you finally realize that the floorboards were not broken from above, but from below.
			
			Frozen in place, terrified to move, you listen as Silas tears through the front door of your haven.  Moments later, the smell of burning flesh reaches your nostrils.
			
			${wilson} does his best to throw blankets over the damaged floor, which only adds to the suffocating heat of the day.
			*page_break 
			*set compassion %+5
			*set hope_suicide true
			As soon as the sun sets, you come screaming from your grave.  In the street lies the charred remains of Silas Hope.  A medical wagon is loading his body.  They conclude that he was caught in a burning building, even though none were struck by the cannon fire in the neighborhood.
			
			You are inconsolable.
			*page_break
		*else
			He easily fends off your lunge, and then draws his saber to keep you at a distance.  "The sun is rising.  Now go, you to yours and me to mine.  I will be in your arms again this eve, and every one after."
			
			Regaining your composure, you cast your head down in shame.  "Until then!"  With that, you flee to your resting place.
			*page_break
			*label plea_to_defend_2
			
			When you lie down for the day of May 22nd, you give specific instructions to ${wilson} to survive the day.  Training new mortals is so time-consuming, after all.  He nods and closes the door to your sleeping-place above you.
			
			Your sleep is uneasy.  The smell of flowing blood and the sound of death-screams seeps through the cracks in the floorboards, engendering a not insignificant amount of visceral titillation.  Such thoughts are, however, tempered by your very real fears for Silas.
			
			*page_break
			*label hope_dies
			
			When you emerge from your resting place that evening, it is instantly clear that something is very wrong.
			
			${wilson} is standing, hat in hand, waiting for you.  @{maddox_num "Massa Hope, he dead."|"Master Hope is dead."|ERROR}
			
			With those words, your world crumbles. @{love_denied The futility of your attempts to save him through denying your love only pushes the blade of regret deeper.|}
*page_break
Looking around, you search for some sign, some hint of meaning, or even just some way to show the world what has transpired here today.
*choice
	*if wealth > 5000
		*selectable_if (discretion > 25) #I break things. Many things.
			*if wealth > 10000
				*set wealth -5000
			*if (wealth <= 10000) and (wealth > 5000)
				*set wealth -2500
			*set anachronism %+5
			*set compassion %-10
			*set discretion %+10
			There is a certain satisfaction to the sound of shattering glass.  The stretch and fracturing of wood has its own charm.
			
			When you are finished, your home is pratically demolished.  Thankfully, ${wilson} elected to stay out of your way; you're not sure what you would have done to him had he tried to interject himself.  Looking around the room, you realize that you feel no better than when you began.  Silas is still gone; only now, there's a draught in your home.
			*goto hopes_letter
	*if religious_tradition != "pagan"
		*selectable_if (rationalism > 40) #I pray for guidance.
			*set rationalism %+15
			*set compassion %-5
			*set discretion %-10
			*set anachronism %-5
			You successfully redirect your anger into prayer.  No sign appears, but you certainly feel better when you are finished.
			*goto hopes_letter
	*selectable_if (discretion <= 50) #Nothing.  This too must be bourne.
		*set discretion %-20
		*set compassion %+10
		You clench your teeth and keep moving.  What would you do?  Throw a temper-tantrum like a child?  Murder a host of soldiers that are no different from Silas, sending untold wives and children into fits of misery greater than yours?
		
		No, you are above that.  You will honor Silas as he would have wanted: @{literate read some poetry or listen to some music|have someone read you poetry or listen to some music}.  These are the things that Silas loved, and you will do them in memory of him.
		*goto hopes_letter
	*if (hope_suicide = false) and (stealth > 0)
		*selectable_if (discretion > 40) #I will slip into the Union camp and put an end to as many Union soldiers as I can.
			*set discretion %+20
			*set compassion %+20
			You slip through the lines of the Confederate soldiers, slowly crawling your way across the no-man's land between the city and the Union camp.  Even now, the sight of a bored sentry, puffing on his pipe, comes into view…
			*page_break
			*if (combat >= 8) and (stealth > 1)
				The sentry falls beneath your fangs within moments.  He is not the first to fall, either.
				*if religious_tradition = "pagan"
					While your tribe was never one to scalp, the desire to do so rises in you for the first time.  You resist the urge, instead electing to cut the hearts from the dead soldiers.  Painted in the blood of your kills, you slip from tent to tent, putting an end to them one by one.  The only thing that stops you is the approaching dawn.
					
					Throwing a makeshift sack of still-warm hearts over your shoulder, you slip back across the battle-lines.  Before the sun rises, you throw the lot of them onto a bonfire in front of your house.  The iron-heavy smoke offers you some sense of comfort.  From the Union camp, you hear a hue and cry being raised as the first of the dead are discovered.
					*goto hopes_letter
				*else
					Painted in the blood of your kills, you slip from tent to tent, putting an end to the Union soldiers one by one.  The only thing that halts your murdering spree is the approaching dawn.
					
					Slipping back across the lines, you wipe the blood from your face.  From the Union camp, you hear a hue and cry being raised as the first of the dead are discovered.  Your hunger may be satiated, but your soul still cries out for more blood.
					*goto hopes_letter
			*elseif combat >= 8
				Your midnight raid does not go unnoticed.  You slay at least a dozen soldiers before garnering enough attention that you are forced to retreat.  They try to chase you back towards the city, but you lose them in no-man's land.  When the first falls to a Confederate sentry, the rest stop and regroup; clearly, they are not prepared for an attack at this moment.
				*goto hopes_letter
			*elseif combat > 5
				Your midnight raid does not go unnoticed.  You slay at least a half-dozen soldiers before garnering enough attention that you are forced to retreat.  They try to chase you back towards the city, but you lose them in no-man's land.  When the first falls to a Confederate sentry, the rest stop and regroup; clearly, they are not prepared for an attack at this moment.
				*goto hopes_letter
			*elseif stealth > 2
				While you manage to slay the sentry and the first two or three soldiers you encounter after that, your skills as a warrior are not sufficient to fight so many of them.  Even the rage that is boiling in your breast cannot slay an entire army.
				
				Fortunately, though, your powers of misdirection are such that you are able to flee from their bullets and bayonets.  Wounded, sobbing, you cross back across the no-man's land and make your way back to your haven.  A day's rest and the physical wounds will be healed.
				*goto hopes_letter
			*else
				While you manage to slay the sentry and the first two or three soldiers you encounter after that, your skills as a warrior are not sufficient to fight so many of them.  Even the rage that is boiling in your breast cannot slay an entire army.
				
				Though they do not know what you are, your determination in the face of bullets and bayonets eventually results in them putting your mangled body to flame.  Your last thought is that at least you will be with Silas again soon.
				*set killed_by_mortal true
				*page_break
				*goto_scene scoring

*label hopes_letter
*page_break
*if sod_plot = false
	*set sod_plot true
	*set sod_founder "compton"
*if hope_suicide = false
	The Union Army retreated long before sunset, but fighting was particularly heavy along Graveyard Road.  It was there that Hope—with Compton at his side—made a valiant stand, leading his men into a breach in the line, fighting to hold back a Union advance.

${wilson} does his best to comfort you over the next few days.  
*if literate
	You immerse yourself in the letters that he wrote to you.  
*else
	*set compassion %+5
	You resist his comfort, however, instead ordering him to read the letters to you over and over again until he is hoarse from speaking.

*if hope_suicide
	Mitch comes to see you, trying to find answers.  He suspects that you had a role in the affair, but has no way of proving it.

	Thankfully, he is wounded in battle the next day, and his inquiries cease.  Still, however, he manages to stymie your efforts to acquire Silas's personal effects from the Company.  Finally, you have to bribe the quartermaster to lie to Mitch, telling him that they were sent on to Silas's family, while you take them home for safekeeping.
*else
	Wanting more, you decide to try and acquire Silas's personal effects.  

	Apparently, though, Mitch survived the battle.  From his cot in the infirmary, he tries to stymie your efforts, claiming that the effects should be sent to Silas's family.  Greasing a few palms, you have the quartermaster tell Mitch that the effects were forwarded, while you take them home for safekeeping.
*page_break
*achieve silas
Among Silas's effects, you find the harmonica and a scrap a paper with four lines of Ancient Greek.  You pocket both.

It takes you several days to find someone capable of translating the passage, which is from the words of Hector to his wife Andromache at the end of the sixth book of the Iliad.  Roughly:

[i]Heaven-sent [woman], be not grieved too much for me in your heart,[/i]
*line_break
[i]for no man shall send me to Hades before my appointed time,[/i]
*line_break
[i]for I declare that there is no man that has escaped his fate,[/i]
*line_break
[i]neither the base nor even the noble, once he has been born.[/i]
*comment Homer, Iliad, 6.486-9

*if ethnicity = "african"
	"Where's your mistress, @{male boy|girl}?" the translator demands.
	
	"Mistress?"
	
	"Whos this letter's fer. An' whos gunna pay me for my learnin'. You ain't none of that."
	
	You bristle. Your fists clench. There are too many soldiers around for you to kill this one cleanly. Instead, you drop some scrip perilously close to his fire. His eyes go wide and he falls to the ground to collect the bills. At least one catches fire, curling up and vanishing it a puff of ash.
	
	You do not look back.
*else
	*if male
		"Friend o' yourn?" the translator inquires politely.
		
		"You could say that."
		
		"That's a good man, there…tellin' his woman not to grieve too much over 'im.  I don' 'magine too many o' these boys feels the same.  I's sure she'll find another soon eno', though…soon's the war's ovah, they'll all be looking to marry. @{priest I suspect you'll be busy helpin' them get hitched, eh Father?|What 'bout you? You gots yo'self a woman?}"
		
		@{priest "I suspect I will," you choke out your reply.|You try to hold back your tears at the unintentional brutality of the translator's words.}
	*else
		The translator pats your hand in a fatherly manner.  "He's gone to a better place, dear."
		
		You try to hold back the rush of blood-tears.

*page_break
Walking slowly back to your haven, you finger the scrap of paper absently and feel the weight of the harmonica in your palm.  Passing a group of soldiers hunched around a cooking-fire, the thought occurs to you to dispose of them.
*choice
	#Let them burn.
		*set compassion %+5
		*if (ethnicity = "african") or (ethnicity = "choctaw")
			You decide it best not to try to fraternize with the Confederate soldiers.  Instead, you take the effects home and burn them in your own hearth.
			
			You watch the flames consume the paper.  Soon only ash remains.  The harmonica will have to be disposed of in some other means; once ${wilson} is up, all will be discarded.
		*else
			*if male
				Nearing the group, you exchange some greetings and at an opportune moment, drop the items in the fire.
				
				One of the soldiers notices the burning paper, and chides you about wasting paper; apparently he would have preferred if you would have let him use it to wipe himself.
				
				Incensed at the thought of this uncouth soldier cleaning himself with Silas's words, you turn and depart, but not before getting a good look at him.  You don't imagine this soldier will survive the siege.
			*else
				Nearing the group, you are greeted with whistles and catcalls.
				
				Before things get out of hand, you drop the effects in the fire, and then turn away.
				
				Their calls follow you all the way home.
	#Keep them.
		*set compassion %-5
		*set kept_silas_letter true
		Clutching the note and harmonica to your breast, you return home, wrapped in the memory of your love.
*finish Next

*label flee_vicksburg
*if shapeshifting > 3
	*set wealth /2
	*set income /2
	Transforming into a bat, you are able to fly away from the battle, and on to better pastures.
	*page_break
	You make your way north, into the relative safety of the occupied territories.  From there, you can start over.
	*page_break Next Chapter
	*goto_scene timejump3
*elseif stealth > 2
	*set wealth /2
	*set income /2
	You're able to slip through the lines without much fuss by using your powers of stealth.
	*goto the_next_day
*else
	Slipping past the soldiers is going to be difficult, as you have not yet learned to make yourself ignored by mortals.  While approaching the lines to the south of the city, the thinnest of the lot, you find yourself cornered by a patrol.  They have not detected you yet, however, so you still have the opportunity to turn back.
	
	*choice
		*selectable_if (charm >= 3) #I am confident in my ability to convince them to let me pass.
			*set wealth /2
			*set income /2
			
			You are right to trust in your abilities; the soldiers are happy to let you pass.
			*set discretion %+10
			*goto the_next_day
		*if male = false
			*selectable_if (charm >= 2) #These boys haven't seen a woman in weeks.  It will only take some kind words and flirtatious gestures to make my way past them.
				*set wealth /2
				*set income /2
			
				Things may have been on the verge of getting away from you, especially if you had been a mortal, but being one-on-one with a soldier is easily handled by a vampire.
				*goto the_next_day
		#Jump them.
			*set discretion %+10
			*if stealth > 1
				*set combat +stealth
				*set combat -1
			*if combat < 6
				*set wealth /2
				*set income /2
				*if stealth > 1
					*set combat -stealth
					*set combat +1
				
				The soldiers are initially startled, but quickly recover their composure and organize against you.  You are no match for their training and equipment.  Much to their surprise, you continue struggling long past any human limit, but that does not stop them from continuing to hack at your body until you finally are destroyed.
				
				You are dead.
				*set killed_by_mortal true
				*page_break 
				*goto_scene scoring
			*else
				*if stealth > 1
					*set combat -stealth
					*set combat +1
				*set wealth /2
				*set income /2
				
				You incapacitate the soldiers, but are forced to move on before more come along.
				*set compassion %-10
				*goto the_next_day
		*selectable_if (wealth > 10000) #Bribe them with everything you have.
			*set wealth -10000
			*if wealth > 10000
				*set wealth /2
			*set income /2
			
			They are surprisingly amenable to your bargain and allow you through, though with a significantly lighter step.
			*goto the_next_day
		#Fleeing the city will be more challenging than I had realized.  I return to my haven to wait out the siege.
			*goto may_21

*label the_next_day
*set withers_rapport %-20
*comment she's miffed that you abandoned her
*set fled_from_vicksburg true
*set wilson_embraced_by_withers true

Once through the lines, you are free to go in any direction, but they all look equally miserable to you.  The countryside is devastated by the combination of retreating Confederates and advancing Union regiments.
*if (shapeshifting > 0) or (ethnicity = "choctaw")
	You make your way steadily north, doing your best to find shelter and adequate sources of blood.  Eventually you find your way out of the battle zone and into the relative safety of the occupied territories.
	*page_break Next Chapter
	*goto_scene memphis_arrival
*else
	You are a creature of the city, not the wilderness.  Only by allowing the beast inside you to take over can you survive in these circumstances.  Living like an animal, you hunt during the night and sleep as best you can in improvised shelters during the day.
	
	You are forced into depredations that you previously would have considered unacceptable, sleeping in piles of manure and feeding from animals and the recently dead, but to do otherwise would be to perish.

	Eventually you find your way out of the battle zone and into the relative safety of the occupied territories.
	*set independence %-20
	*set compassion %+10
	*set wealth /4
	*set income /2
	*page_break Next Chapter
	*goto_scene memphis_arrival

*label 1866
*set wealth /2
*set income /2
*set wilson_embraced_by_withers true
*set slept_through_vicksburg true

You soon learn that the year is 1866; the war is over and the Union has been restored.  More importantly, however, ${wilson} is nowhere to be found, and your former home on Locust St. has been leveled.  You wonder what else has transpired during your rest.
*choice
	#I seek out Withers.  I assume she is still quaestor.
		*set knows_wilson_embraced true
		Withers's haven still stands.  Knocking at her front door, you are surprised when ${wilson} opens the door.
		
		"${wilson}?  What are you doing here?  I thought you were dead!"
		
		@{maddox_num "Y${es_suh}, I is,"|"Yes ${sir}, I am,"|} he says, before coughing into his hand.
		
		"I'm sorry?"
		
		@{maddox_num "Kwaister Withahs, she made me like yous."|"Quaestor Withers made me like you."|}
		
		Shaking your head in disbelief, you push past ${wilson}, and seek Withers inside.
		*page_break
		
		"Much has transpired during your rest, ${mr} ${surname}," Withers begins.
		
		"So I see."
		
		"No, you do not.  There has been a revolution in the Society."
		
		"A revolution?"
		
		"Yes.  Senator Stone of Baltimore slew Praetor Miele and has declared himself Consul of the Americas.  The whole world is in an uproar!"
		*set heard_about_revolution true
		
		*if consul_praetor_explained
			You freeze. The magnitude of this news is…overwhelming. "Why would he do such a thing?"
			
			*if withers_rapport < 50
				
				Withers looks at you with as much of a steely gaze as she can muster. "I'm sure you are capable of piecing that together yourself, ${mr} ${surname}. I have shared the news of our kind with you. Now you may go."
				
				You sense that she means something more than just leave her presence.
				*goto low_withers
			"I…I don't know. I had heard rumblings of discontent, but there are always rumblings."
			*if met_overstreet
				She pauses. "The worse is that I do not know what to do! Theresa has neither come out in support of Stone nor denounced him."
			*goto already_know_consuls
		
		*if speaks_latin or ((lore + intelligence) >= 4)
			From your extensive classical education, you know that consuls were the elected rulers of the Roman Republic—until they weren't. For generations after the transition to dictatorship, what are now called emperors continued to style themselves consuls in an attempt to maintain the illusion of representative government. Similarly, praetors were judges, appointed by consuls, to adjudicate the law.
			
			"I should have anticipated such titles, I admit, but they are still foreign to me in this context," you say.
		*if (speaks_latin = false) and ((lore + intelligence) < 4)
			"Consul?  Praetor?  These terms are foreign to me."
		
		*if withers_rapport > 50
			*set consul_praetor_explained true
			Withers's eyes widen.  "The Consul is the ruler of the Society!  He has ruled from Rome for millennia.  The praetors are those vampires who investigate treason and heresy within the Society.  Apparently, Praetor Miele was right to be in Baltimore."
			*if praetors_explained = false
				*set praetors_explained true
			
				"Heresy?"
				
				"Yes.  Long nights of solitude lends some to extravagant delusions.  The Society does not welcome such distractions."
				*set praetors_explained true
			*if met_overstreet
			
				"And what does Governor Overstreet think of Stone's deeds?"
				
				"That is what I find so exasperating!  She has not moved against Stone.  But neither has she come out in support of him."
			*label already_know_consuls
				
			"What will you do?"
			
			"I think I am safe here.  No one comes to visit me in Vicksburg.  No one of significance, anyway."  After a moment, she realizes that she might have just insulted you and gets a little flustered.  "I didn't mean…"
			
			"Do not concern yourself, Quaestor Withers.  It is already forgotten.  But I must ask…you have taken ${wilson} for yourself?"
			
			She has a hard time meeting your gaze.  Fidgeting with the ruffle at the end of her sleeve, she replies: "Well, while you were asleep, I decided I needed more substantive company.  And you found such an excellent specimen in ${wilson}."
			*choice
				#"I am happy that you found such a suitable companion, Quaestor Withers."
					*set independence %+5
					*set withers_rapport %+10
					*set overstreet_rapport %+5
					*set discretion %-5
					
					"As am I.  But tell me, now that the war is over, what will you do?"
					*goto now_the_war_has_passed
				*selectable_if (discretion > 40) #"I think it disgraceful that you would take what is mine without my consent."
					*set independence %+5
					*set withers_rapport %-10
					*set discretion %+15
					*set overstreet_rapport %+10
					
					"I…I cannot apologize enough, ${mr} ${surname}."
					
					"Yes, well, what is done cannot be undone."
					
					"No.  But tell me, now that the war is over, what will you do?"
					*goto now_the_war_has_passed
				#"I think that, since you have taken something that was mine, you owe me something in return."
					*set discretion %+10
					*set compassion %+5
					
					"What would you have of me?"
					
					*choice
						*if literate = false
							*selectable_if (discretion < 60) #"I would appreciate it if you would teach me how to read."
								*set literate true
								*set withers_rapport %+5
								"Oh!  I think that can be arranged.  Come in the early evenings, I will instruct you myself."
								
								"Very well."  With that, you take your leave.
								*page_break
								Over the next year, you work laboriously at learning your letters.  In time, it starts to get easier though.
								
								One evening, a short time after you have learned enough to read from the papers on your own, Samantha asks you what your intentions are, now that the war is over (and her debt to you is paid).
								*goto now_the_war_has_passed
						*if speaks_english = false
							*selectable_if (discretion < 70) #"I would appreciate it if you would teach me to speak English.  It would certainly make my dealings with the mortals simpler."
								"Oh!  I think that can be arranged.  Come in the early evenings, I will instruct you myself."
								
								"Very well."  With that, you take your leave.
								*page_break
								*set speaks_english true
								Over the next year, you work laboriously at learning the tongue of the United States.  In time, it starts to get easier though.
								
								One evening, a short time after you have learned enough to hold a conversation competently, Samantha asks you what your intentions are, now that the war is over (and her debt to you is paid).
								*goto now_the_war_has_passed
						*if charm = 3
							#"I have seen the way in which you can hold your servants with your gaze.  I wish to learn the same."
								"I suppose I can teach you something of that.  The powers of the blood manifest differently for everyone, though."
								
								"So I understand."
								
								"Well, let us begin."
								*page_break
								*set overstreet_rapport %-5
								*set charm +1
								Over the next six months, you work laboriously at improving your ability to invoke the powers of your blood to sway mortals.  Eventually, you begin to feel confident in your new abilities.
								
								One evening, your powers of Charm having improved substantively, Samantha asks you what your intentions are now that the war is over (and her debt to you is paid).
								*goto now_the_war_has_passed
						#"I think monetary remuneration would be appropriate.  Do you have any idea how much time I spent training him to be such an excellent valet?"
							*set wealth +5000
							"Very well.  I shall have the bank draft a note on your behalf."
							
							"Excellent."
							
							"Now that that is resolved, I would like to know what you intend to do, seeing as the war is over."
							*goto now_the_war_has_passed
				*selectable_if (compassion > 40) #"It is no matter.  He was just a servant."
					*set compassion %+10
					*set withers_rapport %+5
				
					Withers seems relieved at your response.  "Well, what will you do with yourself, now that the war has passed?"
					*goto now_the_war_has_passed
		*else
			@{withers_embarrassed "As they should be, to one as young and foolish as yourself."  Perhaps she is still sore over that whole Jesse thing?  "But that is no matter.  It is not my responsibility to remedy your ignorance."|"It is unfortunate that your dominus failed so thoroughly in your education.  It is not my responsibility to remedy your ignorance."}

			"I see."
			
			"Well, the war is over.  You are free to leave now."
			
			*label low_withers
			"Are you suggesting that I leave?"
			
			"Well, as you know, the population of Vicksburg is not very great.  And, now that ${wilson} is one of our kind, there just isn't room for you."
			
			*choice
				#"I understand.  Thank you for your hospitality.  I will be gone by week's end."
					*set withers_rapport %+10
					*set overstreet_rapport %+5
					*set discretion %-5
					*set independence %+5
					"That is most gracious of you, ${mr} ${surname}."

					"Once I arrive, I will write to have ${wilson} send my things."

					"I will see that he sends them forthwith."

					You take your leave of Withers.  Considering your recent slumber, you have little in the way of effects to prepare before departing.
					
					The next evening, then, you head north.  Perhaps a brighter future awaits you in Memphis.
					*page_break
					*goto_scene memphis_arrival
				#"I would not stay even if you begged me."
					*set withers_rapport %-10
					*set overstreet_rapport %+5
					*set maddox_rapport %-5
					*set discretion %+15
					*set independence %-10
					"Why…I…"
					
					"Once I arrive, I will write to have ${wilson} send my things."

					"I…"

					"Yes, good evening to you as well."
					
					The very next evening you head north.  Perhaps a brighter future awaits you in Memphis.
					*page_break
					*goto_scene memphis_arrival
				#"No, I think I will stay a while yet."
					*set withers_rapport %-20
					*set maddox_rapport %-5
					*set overstreet_rapport %-5
					*set discretion %+5
					*set independence %-10
					"The governor will hear of this!"
					
					"Yes.  I have politely suggested that you leave, and yet you refuse."
					
					"Perhaps you should have thought about that before taking my servant as your own?"
					
					"Why…I…" she stammers.
					
					"Yes, well, good evening to you as well, Quaestor Withers."  With that, you take your leave of her.
					*page_break
					*goto_scene vicksburg_denouement
	#I leave Vicksburg.  This town holds nothing more for me.
		Taking what little you had in your coffin with you, you set out north.  You will @{literate write|dictate a letter} to ${wilson} once you arrive and direct him to send what remains of your things to your new home.

		Perhaps a brighter future awaits you in Memphis.
		*page_break
		*goto_scene memphis_arrival

*label now_the_war_has_passed

*choice
	#"I have had enough of Vicksburg.  I thank you for your hospitality, but I think it time that I moved on."
		*if withers_rapport > 60
			"I wish you only the best, dear ${given_name}."
			
			"And I you, Quaestor Withers."  Regardless of her feelings for you, she is clearly relieved by your decision.  Your continued presence would no doubt have been a strain on the limited resources of the city.
		*if (withers_rapport >= 40) and (withers_rapport <= 60)
			"Safe travels, ${mr} ${surname}.  I imagine that we shall meet again some night or other."  You can tell that she is rather relieved by your decision.  Your continued presence would no doubt have been a strain on the limited resources of the city.
			
			"Yes, I imagine we shall."
		*if withers_rapport < 40
			"Farewell, ${mr} ${surname}."  You can tell that she is rather relieved by your decision, as your continued presence would have been a strain on the limited resources of the city.
			
			"And you, Quaestor Withers."
		
		"Once I arrive, I will write, so that ${wilson} may send my things."

		"I will see that he does so forthwith."  Your goodbyes said, you take your leave of Quaestor Withers.
		
		The very next night, you set out for Memphis.  
		*if independence >= 30
			You muse that it will be good to circulate with others of your kind.  Withers's company has grown somewhat tiresome.
		*if independence < 30
			Perhaps the company is less tiresome there?
		*page_break
		*goto_scene memphis_arrival
	#"Whatever it is that we vampires ever do.  Shall I come for cards this Tuesday?"
		*set withers_rapport %+5
		*set chasing_wilson true
		"Yes, please do."
		
		"Until then," you conclude.
		*page_break
		*goto_scene vicksburg_denouement

*label may_21

"I have to frequently remind myself that life will go on," Withers remarks one evening.

"Is it so easy to forget?"

"It most certainly is!" she declares. At this moment, the sound of a baby's cry is carried onto the porch by the wind. "You hear that? In the middle of all this, Mrs. Green just had a baby! She's named him 'Siege.'"
*comment http://www.duffgreenmansion.com/

"Siege?"

"Well, William. But his middle-name is Siege." Craning your neck, you can see the home of Duff Green, further up Locust Street.

*choice
	#"Perhaps you will feed on him some night, when he is older?"
		*set shepherd_credentials %-10
		"I suspect I will!" she exclaims. "I've fed on most everyone of any stature in this town, after all."
	#"I don't know how they can keep making more of themselves. Haven't they realized what misery life is?"
		*set compassion %+5
		"Oh, don't be so morose, ${given_name}. You'll wilt the magnolias with your gloom," Withers chides.
	#"Have his parents arranged for a baptism?"
		*set rationalism %+5
		*set withers_rapport %-5
		"Were you always this concerned with the divine, ${given_name}?"
		
		"Aren't you?"
		
		"By no means," she replies.
		
With that, she deals another hand.

*page_break
The sudden influx of soldiers and refugees has the city in an uproar.  Prior to their arrival, the city housed some thirty-five hundred people all told, citizens, freemen, and slaves.  Following the evacuation of Jackson, there are now thirty-thousand Confederate soldiers, as well as thousands of refugees from the farms and plantations around Vicksburg.

*if feeding_style = "vegetarian"
	*set compassion %+5
	Hunting has also become significantly more challenging.  Day and night, the army has been guarding its horses against their being slaughtered for meat.  What remains of actual livestock is being carefully watched as well.  Even the dogs and cats have begun disappearing from the streets.  You are going to have to compromise your principles for the time being.
	*goto may_21_2
*else
	This makes hunting both easier and harder: there are literally thousands of new potential victims but, unfortunately, they are all armed to the teeth.  What's more, whiskey and other stocks of social lubricant evaporate before the thirsty men.
	
	*if feeding_style = "artists"
		Of course, your preference for feeding from artists has been something of a joke since your arrival in Vicksburg.  You have been forced to give piano lessons to some of the youths, just to have an excuse to get mildly aroused by the thought of feeding.  Unfortunately, now is not the time for music, and all the craftsmen that you would turn to in desperation are busy repairing fortifications or shoring up the caves.  You are forced to find another source of sustenance.
		*goto may_21_2
	*elseif feeding_style = "children"
		And while you normally prefer to feed from children, access to them has been severely curtailed by the siege.  You are forced to find another source of sustenance.
		*goto may_21_2
	*elseif feeding_style = "clergy"
		To allow for a little bit of variation, you have made a practice of feeding from some of the elders of the recently incorporated Anshe Chesed congregation, particularly their leader, Bernard Yoste.  They have not yet found themselves a rabbi, but are hoping to soon.  Unfortunately, since the beginning of the siege, they have become even more inseparable than before.  Getting one alone long enough to sink your teeth into him is impossible. 
		*goto may_21_2
	*elseif feeding_style = "drunks"
		Clearly, this has hit you particularly hard.  Not only do you find it substantively harder to feed, but the little highs that keep you going in the night are now denied you.
		*goto may_21_2
	*elseif feeding_style = "gamblers"
		The gathered soldiers have little to do to pass the time, as the women are few and far between, and the price of alcohol on the black market has increased tenfold.  Therefore, they spend their spare time gambling away what little in Confederate script they've been able to accumulate.  Of course, that means you have a wide pool from which to choose your prey.
		*goto may_21_2
	*elseif feeding_style = "itinerants"
		This city used to be perfect for your love of feeding on travelers.  As the river brought people north and south and the railroad east and west, there was a constant flux of people through the town.  Now, though, everything is static.  You feel almost as though you are going out of your mind, no longer able to feed yourself in the manner to which you are accustomed.
		*goto may_21_2
	*elseif feeding_style = "laborers"
		And while you normally prefer to feed from workmen, the soldiers who are building fortifications—dirty and sweaty as they are—can easily stand in for your usual prey.  Unfortunately, the ease of the transition does not insure success.…
		*goto interrupted_feeding
	*elseif feeding_style = "prostitutes"
		Unfortunately for you, while the army did bring a number of camp followers with them, they are all constantly occupied servicing the soldiers.  You cannot get a word in edgewise.  Moreover, even prior to the war, Vicksburg was not a hotspot for prostitutes.
		*goto may_21_2
	*elseif feeding_style = "socialites"
		Your taste for the blood of the sophisticated has gone largely unfulfilled since your arrival in Vicksburg.  When you were able, you took jaunts through the countryside and called on a number of plantation-families throughout the northern part of the State.  But here, now, no such license is available to you.
		*goto may_21_2
	*else
		That said, considering your affinity for warriors of all sorts, you find the influx of soldiers a welcome change.  But such an affinity does not prevent you from being interrupted.…
		*page_break
		*goto interrupted_feeding
	
*label may_21_2

*if (male = false) and (charm > 1)
	That said, if ever there were a time that you were thankful for having been born a woman, it is now.  Feeding from mortals evokes such pleasure in your prey that posing as a virtueless woman is a perfect cover for your needs.  But that doesn't make it infallible. In fact, every night that you go out feels like a cast of the die; there are so many soldiers about, you are constantly in fear of discovery.
	
	*page_break
	*goto interrupted_feeding
*else
	On the bright side, there are always the sick and wounded to feed from, right?  Desperate times call for desperate measures.
	
	*choice
		*if male and (charm > 2)
			*selectable_if (perception > 0) #There is surely a soldier or ten who are interested in sex with an attractive man such as myself.
				You are correct, there are "inverts" to be found among the rebel soldiers that are more than interested in your attentions.
				
				You lead one of these soldiers to something resembling a more private place…
				*goto interrupted_feeding
		*if (streetwise > 1) and ((ethnicity != "african") and (ethnicity != "choctaw"))
			*selectable_if (wealth > 1000) #This is my home; though it will be costly, I can acquire some booze and use it to intoxicate my prey.
				Your new friends among the rebel soldiers repeatedly promise that no harm will come to your house.  They are clearly enjoying your gift.  Of course, that makes it that much easier to find yourself alone with one of them…
				*goto interrupted_feeding
		*if (ethnicity = "southern") or (ethnicity = "scotch")
			#These are my people.  I'm sure I can find some sort of familial connection upon which I may call.

				A soldier from a Georgian regiment is happy to hear from his cousin.  From there, he quickly introduces you to his comrades…
				*goto interrupted_feeding
		#I make my way to the Confederate infirmary.

			These soldiers are dying anyway…today, tomorrow, ten years from now.  The better that they serve you now than waste that precious life-force.  That said, you cannot do this without killing your prey.  And so you harden your heart and prepare to do what is necessary.
			
			*page_break
			*if perception > 1
				Just before biting into some poor soul, you realize that he is not here for his physical wounds.  Sniffing carefully, you realize he has some sort of disease.  Wrinkling your nose, you set about choosing a new victim, this time more carefully.

				You find such a soldier a few pallets over, most of his left arm missing.  With a few kind words, he is only too willing to take a pleasant exit from this existence.

				His final sighs are ragged, drunk on the pleasure of your fangs.  You close his eyes with your fingers and silently leave the infirmary.
				*goto sort_denied
			*else
				Unfortunately, one of the poor souls you fed from was not dying only from the bullet he had taken in his leg.  Some other disease had set in, and you find yourself drastically weakened.  You stumble back to your haven, where you vomit blood until dawn.  ${wilson} does his best to comfort you, but to little avail.
				*page_break
				*set compassion %+10
				*set discretion %-5
				*set blood 6
				*goto sort_denied
		#I'm confident in my ability to subdue a two-man patrol.
			*gosub_scene util combat_value_stealth
			*if combat < 8		
				You have overestimated your prowess; two trained soldiers are more than you can handle.  While you do your best to subdue the first, the second issues a cry for aid.  You are forced to flee before you can get anything more than a drop or two of blood, which only exacerbates your gnawing hunger for more.
				*set discretion %-15
				*set blood 2
				*goto sort_denied
			*else
				You are right to trust in your prowess.  You drag the two soldiers behind some bushes and prepare to feed.
				*goto interrupted_feeding

*label interrupted_feeding
*page_break

The sound of approaching footfalls startles you…you'd been so engrossed in the delicious blood slipping into your mouth that you lost track of the world around you.  You are crouched over a Confederate soldier, delirious with the pleasure of feeding.  You quickly lick his wound, healing it with your saliva, but that does not make the blood evaporate from your lips.  You can tell from the clinking of their armaments that the footfalls belong to a patrol or some other group of soldiers.  If they find you with your prey, it could go poorly for you. @{love_denied Perhaps if they were members of the 46th, you could drop Silas's name…but no, you can tell from here that they are from another regiment.|}

*if stealth > 3
	Fortunately, however, your powers of stealth are such that you are able to not only vanish from before their very eyes, but make them forget that you were ever there.
	
	You vanish into the darkness, obliviating the memory of your visage.
	*label sort_denied
	*if love_denied
		*goto plea_to_defend_2
	*else
		*goto may_22
@{speaks_english "Who goes there?" a voice demands from behind you.  Thankfully, the light of their lanterns is flickering, and probably does not reveal your face, spattered with the blood of your prey.|You look up in time for them to shout something at you in English.  Thankfully, the light of their lanterns is flickering, and probably does not reveal your face, spattered with the blood of your prey.}

*if (male = false) and ((charm > 1) and (intelligence > 1))
	With a quick wipe of your face and a straightening of your garments, you gesture towards the fallen 
	*if speaks_english = false
		soldier.  The patrolmen look down at their comatose companion and issue a loud guffaw.  You begin speaking to them in your native tongue, but they wave you off.  They shoulder the dead weight of your prey and continue into the night.
		*goto sort_denied
	*else
		soldier and observe, "I think I wuz too much for this young maan."  The patrolmen look down at their comatose companion and issue a loud guffaw.  With a lascivious wink, you give them a name to ask for, should they need your services.  With promises of a visit in the near future, they shoulder the dead weight of your prey and continue into the night.
		*goto sort_denied
*if priest and speaks_english
	With a quick wipe of your face and a straightening of your garments, you gesture towards the fallen soldier and exclaim, "Your comrade is ill!  You must rush him to the infirmary!"
	
	The patrolmen, upon seeing your cassock, do not hesitate to follow your orders.  Within moments, they have a stretcher and are hustling him away.
	*goto sort_denied
*else
	*choice
		*if speaks_english
			#I can talk my way past anything.  All I have to do is turn on that charm of mine, and they will believe whatever I tell them.
				"Gentlemen, such a welcome sight you are.  See here, your companion has fallen upon hard times.  I think he has even stopped breathing…"
				*if charm > 2
					The patrolmen look back and forth from you to the incapacitated soldier.  After a moment, the sergeant nods towards the body, and the rest of the patrol bends down to fetch him.  They thank you for your attention and cart your prey back to their bivouac.
					*goto sort_denied
				*if (charm = 2) and ((male = false) and ((ethnicity != "african") and (ethnicity != "choctaw")))
					The patrolmen look back and forth from you to the incapacitated soldier.  After a moment, the sergeant nods towards the body, and the rest of the patrol bends down to fetch him.  They thank you for your attention and cart your prey back to their bivouac.
					*goto sort_denied
				*else
					You are not quite as charming as you think you are.  They lower their bayonets at you and demand your surrender.
					*goto fight_soldiers
		#I'd better run, right now.

			Without even fully standing, you break into a run.  Cries of 'assassin!' and 'spy!' go up from where you were, but this is your town, and these soldiers have been here only a few days.  You retreat to one of your refuges and wait out the day there.
			*goto sort_denied
		*selectable_if (discretion >= 40) #I can take them!
			*set discretion %+10
			*gosub_scene util combat_value_ss
			*label fight_soldiers
			
			*if combat < 8
				You have overestimated your prowess; three trained soldiers are more than you can handle.  Once you are sufficiently wounded, the beast inside you reveals itself.  At first it allows you to turn the tide of the battle, but once a lantern is broken over your head, you flee screaming and burning into the night.
				
				You retreat to one of your more secure refuges and convalesce there.
				*set compassion %+20
				*set discretion %-20
				*set exposure +5
				*set blood 2
				*goto sort_denied
			*else
				You are right to trust in your prowess.  You drag the incapacitated patrolmen behind some bushes and prepare to feed…
				*set blood 15
				*set discretion %+20
				*set exposure +3
				*goto sort_denied

*label may_22
*page_break The Next Evening
The night of May 21st, you remain indoors with ${wilson}, watching for any fires that the Union bombardment might start.  All night long cannonballs whistle through the air, pounding the city from the land around it—north, east, and south—as well as from the ships anchored in the Mississippi to the west.

When you lie down for the day of the 22nd, you give specific instructions to ${wilson} to survive the day.  @{(compassion > 50) Training new mortals is so time-consuming, after all.|You have grown to care for the fellow, after all.} He nods and closes the door to your sleeping-place above you.

Your sleep is uneasy.  The smell of flowing blood and the pitiable cries for home seep through the cracks in the floorboards, putting you in a state of ongoing titillation. @{(compassion > 45) Despite the lethality of the sun's rays, you find yourself tempted to burst from your resting-place to feast on the carnage.|}
*page_break 
By the time the sun sets, the Union army has withdrawn.  General Grant acknowledges the impregnability of Vicksburg and orders his army to dig in for a siege.

The Confederacy responds by shoring up its lines and praying for relief.
*finish Next

*label withers_senators
Of course, much of this time is spent playing cards with Withers. That and doing your best to feed surreptitiously amid @{(year >= 1868) the depredations of the US Army, the baleful eye of the Ku Klux Klan, and the defiant freedmens' militias|food shortages and fears of spies and saboteurs}.
	
During your conversations, you impress Withers with your knowledge of vampire affairs. However, one evening she stumbles upon an oversight in your education.

"@{(laborvscapital > 50) I have to wonder how a Senator balances the needs of a city against their own needs when Senators gather…|It is so unfortunate that Senators have the obligation to listen to all of a city's vampires…}" you are saying, but Withers interrupts you with laughter.

"Oh? Is that so?"

From the tone of her voice you feel a sense of doubt. "Is that not so?"

She flutters her hand-fan against the humid air. "Heavens, no! Senators do not represent a city to the Senate; rather, they represent the Senate to the city."

"What does that mean?"

"It means that they—gently, mind you—enforce the rules of the Society. And by 'enforce,' I mean, they remind those who stray to far that the Senate is gossiping about—ahem, watching—their every move."

"What a peculiar body."

"So it is. But it ensure conformity across the Society."
*set senators_representation true

"Are you relieved, then, not to have one?"

She stops fluttering the fan and out into the night. "It is a double-edged sword. Without a Senator here, I am nothing. I can write to anyone and everyone and tell them of my clever witicisms, and deft political maneuverings, but it comes off as desperate. But a Senator, sharing stories with the other Senators…that is how your fame grows among our kind. But then, at the same time, you must adhere to their pointed suggestions."

@{(independence > 50) That sounds like a fair trade|That sounds wretched} to you.

Looking at your cards, you realize that you have lost the hand. You toss them onto the table and invite Withers to shuffle the deck.
*return