*comment First part of the game.

*title Creatures Such as We
*author Lynnea Glasser
*scene_list
  startup
  self-choice
  day1-arrival
  day1-lunch
  day1-luggage
  day1-afternoon
  day1-dinner
  creatures
  day2-breakfast
  day2-moonwalk
  creatures-act2
  day2-lunch
  day2-exercise
  path-evacuate
  finale
  newending

*create name "blank"

*create age "blank"
*create race "blank"
*create gender "blank"
*create trans true
*create OtherGender false
*create pronounZhe "zhe"
*create pronounZir "zir"

*create oldProfession "none"
*create InitialAnimosity false

*create CreaturesProgress "none"
*create UndeadIntroPlayed false

*create zombie_zhe "zhe"
*create zombie_zir "zir"
*create zombie_zim "zim"

*create elegy_zhe "zhe"
*create elegy_zir "zir"
*create elegy_zim "zim"
*create elegyProfession "medic"

*create ElegyGone false

*create leadAffection 5
*create writerAffection 5
*create QAAffection 5
*create programmerAffection 5
*create artistAffection 5
*create consultantAffection 5
*create NobodyAffection 5

*create fanSelfID false
*create escortSick false
*create pipePromise false

*create helptarget "nobody"
*create helptarget_zhe "zhe"
*create helptarget_zir "zir"
*create helptarget_zim "zim"

*create MaxAffectionTarget "nobody"
*create AffectionTarget_zhe "zhe"
*create AffectionTarget_zir "zir"
*create AffectionTarget_zim "zim"
*create AffectionLove false

*create Villain "nobody"
*create villain_zhe "zhe"
*create villain_zir "zir"
*create villain_zim "zim"

*create AndresLove false
*create DianaLove false
*create JamesLove false
*create SadriLove false
*create RenLove false
*create GrantLove false

*create ProjectAsked false
*create SynthSupported false
*create SynthDenied false

*create washed false

*create touristsKnowSickness false

*create YouHavePoison false
*create StewardHasPoison false

*create SynthHated false

*comment: artist, viewer, none
*create ArtIsFor "nobody"

*comment *image CSAWpic.jpg
*comment *goto skip-ahead

*if (choice_is_web) or (choice_is_steam)
  *image spacejoy.jpg


*if not(choice_is_web or choice_is_steam)
  *temp skip_description
  *config skip_description false
  *if skip_description

    *goto purchased
*check_purchase adfree
*if choice_purchase_supported and not(choice_purchased_adfree)
  [i]Creatures Such as We[/i] is a philosophical interactive romance novel by Lynnea Glasser, where your choices control the story. It's entirely text-based--without graphics or sound effects--and fueled by the vast, unstoppable power of your imagination.

  Living on the moon is lonely, and stressful, and exhausting. Video games have always offered you an escape to a better life. The easy, happy life you wish you had. Which makes it so frustrating when the game you've been playing ends badly. But you have a chance to figure it out, because the next tourist group is the designers. You can debate with them about art, inspire them with the beauty of outer space, get closer to any one specific designer in particular, and finally find out how to get the ending you always wanted.

  Awarded Second Place in the 20th Annual Interactive Fiction Competition (IFComp)[n/]
  "You absolutely need to play through [i]Creatures Such as We[/i]" -- Leigh Alexander[n/]
  "Well-paced and richly written" -- Emily Short[n/]
  "I couldn't tear myself away" -- Game Theory Podcast

  • Immerse in the beautiful setting of a moon-bound tourist destination a tourist destination.[n/]
  • Explore the meaning of gaming as a form of artistic expression with a cast of game designers.[n/]
  • Inspire profound discussions, courage, and even love with the visiting space tourists.[n/]
  • Six unique character paths, with options to be romantic or maintain strict professionalism.[n/]
  • Play both your character, and the character of the game-within-a-game.[n/]
  • Decide for yourself the best way to bridge the gap between game players and designers.[n/]
  • Inclusive options for gender identity, orientation, race, and age.

  *if choice_is_steam
    *if choice_prerelease
      [i]You can play the first part of the game for free today. The rest of the game will be available on ${choice_release_date}.[/i]

      *choice
        #Sign up to be notified when the game is available.
          *subscribe {"now": true}
          *restart
        #Play the first part now for free.
          *goto purchased

    [i]You can play the first part of the game for free. Purchase the rest of the game below.[/i]
    *if choice_is_advertising_supported
      [i]Purchasing the rest of the game will also turn off in-game advertisements.[/i]

    *purchase_discount adfree 2019-07-09 $4.99 $2.99 purchased
    *if choice_is_advertising_supported
      *page_break_advertisement
    *if not(choice_is_advertising_supported)
      *page_break Play Now for Free

    *goto purchased
  *else
    *if choice_is_advertising_supported
      [i]Creatures Such as We[/i] is supported by advertisements, but you can buy the unlimited version to turn off ads forever.
      
      *purchase_discount adfree 2019-01-01 $4.99 $2.99 purchased
      *page_break_advertisement

      *goto purchased
    *else
      [i]You can play through the game once for free, or purchase unlimited replays below.[/i]

      *purchase_discount adfree 2019-01-01 $4.99 $2.99 purchased
      *page_break Play Now for Free

*label purchased

Strolling through the final airlock, you feel satisfied that the facility's in order: the spacesuits are starched, the moon rocks are neatly arranged, and you personally checked that every stateroom is in perfect condition. Twice. Tomorrow's going to go great, and you're finally off the clock. You look back one last time anyway. Time between tourist stays always make you nervous: it feels difficult justifying your non-existent workload while everyone else still has regular maintenance duties.

Compounding the lull in responsibilities has been the temptation of finishing the final level of [i]Creatures Such as We[/i]. Will you wipe out the last of the Traditionalists, or will Lauress elude your grasp at the last minute? Will you and Elegy have a happily ever after? The anticipation is giddily maddening. You hear chatty banter as you approach the passageway to the crew common area and laughter as you pass it. You hurry along. You're about to save the day, be the hero, put everything together.


*choice
  #You wish life was that simple.
    *set washed true

    You wash your face with astringent and brush your teeth with the smallest dab of toothpaste, rinsing with as little water as you can spare. It's so much work, so much sacrifice, living up on the moon. Living anywhere, really. Life is hard, and it's nice to play a story where it's not. Where everything is simple and easy. It's calming, reassuring. Makes all the sacrifice, all the strife feel worthwhile.

    *goto PlayGames

  #You enjoy the escapism.
    *set washed true
    You close your eyes and brush your teeth with the smallest dab of toothpaste, thinking on the digital world, where the colors are sharp, your purpose is clear, your name respected, and you never have to deal with annoyances like cramped quarters, monthly bone treatments, or strict water restrictions. You rinse with the smallest swig of water you can manage and wipe your face with astringent.

    *goto PlayGames

  #You just enjoy experiencing the story.
    *set washed true
    It'll be exciting to see where it all goes next. You hum as you wash your face with astringent and brush your teeth with the smallest dab of toothpaste, rinsing with as little water as you can. It feels like a soothing part of your gaming preparation ritual: the purification of self, the removal of distractions. The ability to just fully immerse yourself in the experience makes everything else feel that much better.

    *goto PlayGames

  #You can't wait to launch right in.
    *label PlayGames
    You set your walkie-talkie down on a nearby drawer, and lean back against the chair backing at the foot of your bed. You close your eyes as [i]Creatures[/i] boots up. The loading music alone just melts the mundane away. It's delicious.

    Your ashen undead avatar walks towards the rubble as your ghost companion Elegy scouts ahead. These ruins are all that's left of your former base: a casualty to the crusade of Traditionalists and internal treachery. Elegy perks at something, then flits back and enters your body. The screen sparkles blue and the GUI updates as your powers mingle. Thanks to heightened senses, you are now aware of the nearby enemy guard. The first one is always the easiest, of course, but the combat will cascade into a heavy hack-and-slash. This is going to be fun. What's your preferred combat style?

    *fake_choice

      #Guns.
        Your avatar unslings a rifle, and as you aim, the ghost's powers allow you to accurately account for everything from your target's trajectory to the air currents along the path. You aim, fire, hit. Elegy commends your character on a beautiful headshot. It was clean, but loud. An alarm sounds. They know you're here.

      #Stealth melee.
        Your avatar unsheathes two large daggers as the ghost enshrouds it in an unnoticeable cloud of apathy. You sneak right up to the guard and make your move: unnaturally silent, instantly deadly. The guard slumps before even making a sound. Elegy commends your character on such professionalism. No alarm sounds. You still have the element of surprise.

      #Biting and clawing.
        You propel your avatar faster than physically possible, bounding towards the target on all fours. She sees you coming, and hits an alarm. She reaches for a weapon next, but it's already too late. You leap into the air as your character's maw and claws are magically enhanced. You tear your target apart with visceral power. Elegy delights with your character at the ruthlessness.

      #Channel ghost powers.
        Elegy delights in helping channel ethereal power into flaming balls of energy, which your avatar flings at the guard. She slams against a wall and crumples. An alarm sounds. They know you're here.
        
You progress through the compound, dispatching more and more guards. You pass piles of undead corpses and ectoplasmic ash: evidence of their cruel conquer. You will make sure this never happens again. Your mastery of the controls is an unstoppable force that leaves none alive. And then, in a flurry of magically enhanced efficiency, you are there: the command center. The final boss chamber. Your avatar's arrival interrupts a woman who was tapping away at a console from behind her personal glass blast shield. She turns to you as you enter, to give "the speech" and you smirk in preparation:

"I…I am sorry, so sorry for the what you have become. I should have been better, I should have been stronger about stopping it. I failed you, I failed you all. After…after my son, I realized how much time I had wasted with speeches, with words. I had to take real action. So I'm here, saving humanity. Saving it against your kind. And I know you're still human in there, somewhere. Please, stop this. Let humanity resurface. Stop being the monster." That was not exactly what you expected.

You're given options on how to respond.

*choice

  #(Just attack.)
    Resolution, revenge. You just know that that her death will put things right, and the faster that happens, the faster you'll reach the positive ending. With supernatural speed and strength, you propel yourself up pipes, up scaffolds. Soon, she will be in reach.  
    *goto hang-head

  #Taunt her.
    Such indignant self-righteousness from the villain. You can one-up that. Your avatar shouts, "You hunted my kind, you murdered your own son; you are just another bigot holding back progress. You're the monster!"
    *goto hang-head 

  #Ask for sympathy.
    There may you be a chance to talk this out, to stop this pointless feud. Your avatar pauses and addresses Lauress, "I understand that someone like me, with my skin, my change in physiology, can be scary. But I am happy this way. Others who have chosen to change, we're happy this way. Please, just can't you accept us how we are? We don't do anyone any harm." 

    You roll your eyes. No way she'll listen to that.

    She laughs. "You think this isn't something I've heard hundreds of times in debates? You monsters seem to think that you're special, you're each unique. But you're all the same: demonic, evil destroyers of humanity. You need to be stopped. And that burden falls to me." Well, you tried.
    *goto hang-head

  #Offer to talk things out.
    Your avatar takes a few steps forward at walking speed. "Listen, I want to end the bloodshed, the pointless feud. Would you agree to a truce, an agreement, even just a plain ceasefire? Let us work together towards peace."
    *goto peace

  #Offer to join her.
    "I…I agree with you." your avatar stammers out, "Can I work for you? I'd like to absolve myself of my condition."

    She is understandably skeptical, "You want to join us? This is…well, one of you finally realizes what needs to happen." She steps backwards, "But forgive me if I don't believe you right away, since you murdered your way in. Why exactly do you want to join our resistance?"

    *fake_choice

      #I'm disgusted with myself.
        Your avatar continues, "It's a burden, you know, being a monster. I hate it. But I can't go back. I want to put things right, to stop others from becoming the monster I see every day in the mirror." She seems genuinely touched, "I know. But part of that means having to let go…and that's what I'm going to have to help you do right now."

      #I just want the violence to stop.

        *label peace

        She sighs at this, "Very noble. But unfortunately, that can really only be achieved when your kind is all dead. I'm sorry that you brought this on yourself."
        *goto hang-head

      #I just want chaos.
        Your avatar continues, "I don't really care which side I'm on, or who I'm fighting for. I just live for the thrill of the chase. I'll join you because it's fun destroying things."

        Lauress bursts out laughing. You are impressed by how genuine-sounding her laugh is. You make a note to look up the voice actor later. "Why, then, would I ever trust you? No. I'm afraid there's only one way to deal with this."

      #I don't actually, I just wanted to hear what you'd say.
        She seems taken aback by this, then quickly regains her composure, "Hmph. I should have known not to let myself give way to hope that you could actually be reached."
                
*label hang-head

She hangs her head, and quietly pulls out a small remote device that she points at some nearby electronics. She presses a button, and strange lights and noises fill the room. They hurt your ears, so you turn the headphone volume down a bit. The ghost companion floats forward, howling in agony, and then freezes in front of your avatar. 

The noise, the light: it's Elegy's resonance frequency. But, how? They're supposed to be so specific, as to be impossible to discover. The traitor. It must be the traitor who gave Elegy's frequency to them. Oh man, you haven't found the traitor yet. They must be the final boss, or maybe a teaser for a sequel?

Lauress turns to you. "You know what is happening. Turn yourself over, allow yourself to be destroyed, and I will turn this off. The ghost will be saved from eternal dissolution."

*fake_choice

  #Turn yourself over.
    Elegy has saved you from death countless times; it's the right thing to do. Plus, you're pretty sure that if you take the route of self-sacrifice on behalf of your ghost, you'll get a more romantically fulfilling ending. Your character allows two monstrous guards to cage you, and as she dutifully turns off the device, Lauress turns with a cruel grin back to you.

    "Thank you for making the right decision. But didn't you ever wonder how we got in, how your friend here managed to save your life so often?" Realization dawns on both yourself and your avatar simultaneously. The villain gestures at Elegy and states the obvious, "It gave us information in exchange for your life. You know: the access codes, its resonance frequency." She chides, "Pity that you threw your end of the bargain away."

  #Attack Lauress.
    *goto attack-fail

  #Attack the equipment.
    *label attack-fail
    Without the additional help of your ghostly powers, you're as slow and sluggish as a regular, untrained human. Your avatar makes it a few feet before two monstrous guards pop out. You attempt to fight them, but your unassisted combat skills are subpar. You only manage to get one to half health by the time they beat you, stun you, and drag you over to a cage on the command of Lauress.

    "How brave of you, ghostwhisperer. Pity you're no match for my Zourobras guard. Now tell me, didn't you ever wonder how we got in, how you managed to have such a knack for staying alive?" Realization dawns on both yourself and your avatar simultaneously. The villain gestures at Elegy and states the obvious, "It traded your life for information: the access codes, its resonance frequency." She chides, "Pity that you threw your end of the bargain away."

Betrayal. Elegy betrayed everyone, for you. It's your fault, Elegy's fault. Your avatar turns to the ghost.

*fake_choice
  #Why did you do it?
    Your character's voice cracks and trails off in a sad whisper,
    *goto SomethingWrong

  #I'm sorry it had to end like this
    Your character's voice cracks and trails off in a sad whisper,
    *goto SomethingWrong

  #You shouldn't have done it
    Your avatar kneels in resignation,
    *goto SomethingWrong

  #I forgive you
    Your avatar bows with clear absolution,
    *goto SomethingWrong

  #I can't forgive you
    Your avatar looks down, away from Elegy,
    *goto SomethingWrong

  #Fuck you, ghost
    Your avatar thrashes against the Zourobras guards to put enough volume and force behind the words,
    *goto SomethingWrong
*label SomethingWrong
but then the camera pans out and the audio fades: something is wrong. The camera immediately zooms back in on Elegy, still vibrating, more furiously than ever. "Is it…" Lauress leans towards it incredulously.

A bright flash! 

Time warps to a near stop. For a brief moment, Elegy solidifies into a human shape and turns to your character. A sad, pale blue figure, it mouths [i]sorry[/i], and then closes its eyes. Time snaps back, and your companion condenses into a miniature black hole. Or at least, that's what the pulsing energy sphere pulling everything into itself reminds you of. Your avatar's body rag dolls against the side of the cage. The guards are sucked in. Lauress is pulled towards it, but she has the fortitude to grab some nearby pipes and scream.

But even the words are pulled into the void as the camera wipes to darkness.

Over the darkness, with accompanying flash-forwards, your character narrates aloud what will happen next, "They'll give me an award for this. They'll rebuild, put me in charge out of pity. But it won't mean anything. It won't mean anything without Elegy. I just wish…I wish I could go back and redo it all.…" A cut-scene triggers, focusing on your outstretching hands. They clench into a fist before the camera pans to catch the black hole thing as it dissipates. Then the game fades out to black and the credits start rolling.

Wait, what? They can't have killed Elegy, just like that. You must have done something wrong. Something preventable. You've been a fan of the Cullected Games studio for a while now, and you've never known them to pull a dick move like this. So what was it?

*fake_choice

  #I should have been better at combat.
    There were several points where you failed at combat, but the game let you continue anyway. It was those points, that's where you messed up. You should have worked harder, been better. You just weren't good enough to get the good ending. But then how could you ever win with Hard Mode? Without any ghost powers? You'd have to be a god.

  #I should have sent Elegy away.
    There were several places where you could send Elegy away, that might have been it. Maybe Elegy can only be saved if you switch the game to Hard Mode without the assistance of ghost powers. Of course, there might be some sort of affection threshold, before or after which Elegy refuses to go away. Or Elegy might just refuse no matter what you do.

  #I didn't say the right things to Lauress.
    There were other opportunities to speak to her, maybe to convince her to change sides, maybe to get to her some other way. You didn't really pursue those well enough during the rest of the game. There was probably some sort of decision counter and you should have been more consistent with how you dealt with her.

  #It was not preventable.
    Probably one of the designers really felt that this would be the most emotionally impacting ending that fit into some kind of hero's journey narrative. They probably went with it even if fans would hate it, to be true to the "story". What a bunch of bullshit. Although, now that you think about it, why include the Story Mode? Maybe they realized that players would fuck it up and created this as an easy way to replay the content and un-fuck yourself.

You'll find the way to fix it. You've unlocked Story Mode, which you're more and more certain is a sign that replay towards the good ending is encouraged.

*if washed = true
  You power down the device and push the computer back up against a wall. You get into the covers and turn it over in your head more. Maybe this internal conflict is the response that the designers wanted? But it doesn't feel satisfying; it doesn't feel right. You just wanted a good ending. As you velcro up your blanket, you wish that your scheduled internet browsing time wasn't a week away. You'd really like to look up the answer.
*if washed = false
  You power down the device. You sit in bed for a few minutes before getting up to go to wash your face and brush your teeth. What went wrong? Maybe this internal conflict is the response that the designers wanted. But it doesn't feel satisfying; it doesn't feel right. You just wanted a good ending. As you velcro up your blanket, you wish that your scheduled internet browsing time wasn't a week away. You'd really like to look up the answer.

*label skip-ahead

*finish Sleep until Tomorrow