*title Choice of the Deathless
*author Max Gladstone
*comment Copyright 2013 by Max Gladstone.
*comment 
*comment Choice of the Deathless
*comment 

*scene_list
	startup
	casinonight
	darkness
	thefirstcase
	darkness2
	devilsasylum
	darkness3
	continuingeducation
	darkness4
	deposition
	darkness5
	demonworld
	demonworld2
	epilogue

*comment I guess we need a name here.  And some sexual equipment.
*create name "Unnamed"
*create surname "O'Nonymouse"
*create char_gender "female"

*comment Fetuses are all female until how many weeks?

*create Ash_gender "female"
*create Ash_pro "she"
*create Ash_pro_cap "She"
*create Ash_pro_pos "her"
*create Ash_pro_obj "her"
*create Ash_pro_abs "hers"
*create Ash_pro_abs_cap "Hers"
*create Ash_pro_pos_cap "Her"
*create Ash_voc "Ms."
*create Ash_binary "woman"
*create Ash_hair "blonde"
*create Ash_craftsperson "Craftswoman"
*create Ash_pro_self "herself"

*create char_pro "she"
*create char_pro_cap "She"
*create char_pro_pos "her"
*create char_pro_obj "her"
*create char_pro_abs "hers"
*create char_voc "Ms."
*create craftsperson "Craftswoman"
*create char_binary "woman"
*create character_is_bi false

*comment Oppositional stats first: "Gunner" is the degree to which the mc is work-driven
*comment Opposed by "Socialite" which is the degree to which the mc is socially driven
*comment "Honor" is opposed by "Duplicity" and represents trust capital.

*create gunner 50
*create honor 50

*comment Then, a basic four-way stat split.  Decided to switch 'consciousness' which had some overlap with 'cunning' for 'power,' which represents more of the 'direct approach'.  Then I decided to rename 'power' to 'determination' at the last moment—it remains 'power' in the codebase.
*comment Setting stats to 1 rather than to 0 because setting to 0 causes fairmath to complain that the value is out of bounds.

*create craft 1
*create charm 1
*create cunning 1
*create power 1

*comment And then some money.
*comment Soulstuff is spent to do magic; if more's spent than you have left, that goes to debt.
*comment Debt, meanwhile, is used to determine your financial autonomy & how much you've paid back your student loans.  Muahaha.
*create debt 200000
*create soul 2000
*create sleep 99
*create soul_funds "low"
*create commute "close"
*create spending_profile "thrifty"
*create rent 0
*create debt_repayment 0
*create sleep_difficulty 0

*comment And a way to die!  Other than debt of course.  Wounds measures the character's physical health.  Characters that 'die', given sufficiently high stats, may be able to become skeletons in the end.  Still a failure condition for most scenes in the game, I think.

*create wounds 0

*create is_skeleton false

*comment Some more variables to represent the many ways you can be screwed up in the head.

*create has_claustrophobia true

*create background "poor"


*comment Relationships are fun and probably won't get you killed.
*comment AHSM Should these be percentile variables?  If so, they shouldn't start at 0--that will cause a bug, as noted before.

*create Varkath 20
*create Nebuchadnezzar 20
*create Stone 20
*create Wakefield 30
*create Chen 30
*create Ngabe 30
*create Vega 35
*create Klint 50
*create Rok 20
*create Smith 20

*create chen_sex 0
*create vega_sex 0
*create wakefield_sex 0

*comment And here are some story bits that will transfer from chapter to chapter!  I hope to keep these to a minimum--one or two per chapter, and with luck a few chapters will have none.

*create claustrophobia false
*create battle_talk false
*create battle_redirect false
*create battle_force false
*create battle_fistpunch false
*create battle_trap false
*create battle_run false
*create battle_disguise false
*create battle_friends false
*create battle_firm true

*create first_kiss "girl"

*comment these are from poker night!

*create beat_varkath false
*create craft_game_won false

*comment These are from The First Case.

*create Stone_Fix false
*create Vega_Fix false
*create Solo_Fix false
*create Cass_Under_Bus false

*comment These are from the Devil's Asylum

*create Rok_here false
*create Rok_job false

*comment these are from Continuing Education

*create panel_success false
*create Wakefield_rival false
*create smith_hurt false
*create wakefield_hurt false
*create rescued_wakefield false
*create fight_hard false
*create gets_it false
*create gets_it_first false

*comment And these are from Deposition

*create goddess_referred false
*create goddess_refuse false
*create goddess_settlement false
*create blessing false
*create ngabe_under_bus false
*create deposition_succeed false
*create deposition_halfway false

*comment And these are from the Demon World

*create in_relationship false
*create vega_relationship false
*create chen_relationship false
*create wakefield_relationship false

*create rok_token false

*comment And these are from Demon World Pt 2

*create friends_save false

*comment And these are from Darkness

*create debt_repaid false

*achievement blessing visible 50 Aid a Goddess
	Earn a goddess's blessing.
	You earned a goddess's blessing.
*achievement partner visible 50 Become a partner
	Make partner.
	You became a partner at Varkath Nebuchadnezzar Stone
*achievement skeleton visible 75 Become a skeleton
	Some damage you can survive, but you can't heal.
	You became an undead abomination. Awesome.
*achievement wakefield visible 15 Bright college years
	Share a meal with an old college "chum."
	You had dinner with Ashleigh Wakefield.
*achievement stonefix visible 10 Brutal politician
	Earn points with a partner through political gamesmanship.
	By bringing in Damien Stone, you exposed Vega's weakness.
*achievement wakefieldhurt visible 25 Consolation Prize
	You can't save them all.
*achievement demonwin visible 10 Demonic Intervention
	Win with a demon's aid.
	You won thanks to the demons' aid.
*achievement depositionwin visible 40 Depose a Goddess
	As in "take a deposition from." You're not that powerful—yet.
	You successfully deposed the goddess Ajaia.
*achievement die visible 15 Die
	It's easier than you expect
	You died! Let's see you get out of this one…
*achievement goddesswin visible 10 Divine Intervention
	Win with a goddess's help.
	You won thanks to divine intervention.
*achievement sexyfuntimes visible 25 Eager romantic
	Start a romance as early as possible.
	You don't wait around, do you?
*achievement win visible 25 Finish the game
	Finish the game
	You finished the game! Care to play again?
*achievement wakefieldoffer visible 25 Firm Moves
	Take a different path.
	You took a job at Kelethres, Albrecht, and Ao.
*achievement chen visible 25 Get with Cass
	Enter a relationship with Cass Chen.
	You started a romance with Cass Chen.
*achievement vega visible 25 Get with Vega
	Enter a relationship with Vega.
	You started a romance with Halcyon Alatriste y Vega.
*achievement wakefieldlove visible 25 Get with Wakefield
	Enter a relationship with Ashleigh Wakefield.
	You started a romance with Ashleigh Wakefield.
*achievement solofix visible 50 Go it alone
	Solve Transdimensional's problem on your own.
	You fixed the Transdimensional case on your own.
*achievement woundzero visible 40 Heal Thyself
	Pull yourself together.
	You put yourself back together again.
*achievement rokoffer visible 25 Hell of a Job
	Take a different path.
	You took a job from a demon.
*achievement wander visible 50 I Want My Life Back
	Take a different path.
	You've freed yourself from the firm.
*achievement goddessoffer visible 25 In-Temple Counsel
	Take a different path.
	You decided to work with the goddess Ajaia.
*achievement poker visible 15 Master player
	Who cares if he's killed gods? You don’t take a hand like that to the river.
	You beat a Deathless King at poker. I hope that doesn't bite you later!
*achievement getsit visible 15 One step ahead
	What's wrong with this picture…
	You figured out that Wakefield was possessed in time to make a difference!
*achievement friendswin visible 10 The Power of Friendship
	Win by the power of friendship.
	Your friends saved you.
*achievement rokfix visible 25 Pro bono
	Work for the public good, well.
	You helped R'ok achieve his dream.
*achievement roksolo visible 50 Pro bono, solo
	Who likes group work anyway?
	You helped R'ok on your own, without backup.
*achievement fistpunch visible 20 Punch a dark god in the face
	Why not use some old-fashioned fisticuffs?
	You punched a nigh-omnipotent horror in the face. How did that work out for you?
*achievement loans visible 70 Repay your debt
	Pay off your student loans.
	You paid off your student loans!
*achievement sacrificewin visible 5 Sacrifice Play
	Win through self-sacrifice.
	You won through self-sacrifice.
*achievement wakefieldsafe visible 25 Save Ash
	Protect your friends—and your enemies.
	You stopped the demon before it could hurt Ash.
*achievement smithsave visible 15 Save Smith
	Protect John Smith.
	You saved John Smith from the assassin. At least for now.
*achievement craftwin visible 10 Sorcerous Rescue
	Win with your firm's help.
	Your firm saved you.

*comment And I was going to put some variables from the epilogue here but those could just as well be temps so don't worry about it.

*comment Remove the '*comment' in front of the following lines to get an easy chapter selector for fast playtesting!  Though you'll probably fail at all the challenges by virtue of lacking skillz and friends.  Maybe someday I'll just *set applicable ability scores inside the choice options for the relevant chapters, but that day is not this day.

*comment This is a test of how much string concatenation I can get away with.

*comment *create quote_test "\""
*comment *set quote_test &"I don't like her very much"

*comment ${quote_test}

*comment Where do you want to start?
*comment *choice
*comment	#The Battle in the Demon World
*comment		*goto_scene battle
*comment	#Casino Night
*comment		*goto_scene casinonight
*comment	#Darkness
*comment		*goto_scene darkness
*comment	#The First Case
*comment		*goto_scene thefirstcase
*comment	#The Devil's Asylum
*comment		*goto_scene devilsasylum
*comment	#Continuing Education
*comment		*goto_scene continuingeducation
*comment	#Deposition
*comment		*goto_scene deposition
*comment	#The Demon World
*comment		*goto_scene demonworld
*comment	#The Demon World, Part 2
*comment		*goto_scene demonworld2
*comment	#Epilogue
*comment		*goto_scene epilogue

*comment	OLD IAP CODE
*comment	*check_purchase adfree
*comment	*if choice_purchase_supported and not(choice_purchased_adfree)
*comment		Battle demons and undead attorneys, and win souls to pay back your student loans! At the elite demonic-law firm of Varkath Nebuchadnezzar Stone, you'll depose a fallen god, find romance, and maybe even make partner, if you don't lose your own soul first.
*comment	
*comment		"Choice of the Deathless" is a necromantic legal thriller by Max Gladstone, Campbell Award-nominated author of [i]Three Parts Dead[/i] and [i]Two Serpents Rise[/i]. The game is entirely text-based--without graphics or sound effects--and powered by the vast, unstoppable power of your imagination. 
*comment	
*comment		• Explore a fantasy realm with a rich and evolving backstory, based on the novels published by Tor Books. 
*comment		*line_break
*comment		• Play as male or female, gay or straight, dead or alive (or both).
*comment		*line_break
*comment		• Build your career on carefully reasoned contracts, or party all night with the skeletal partners at your firm.
*comment		*line_break
*comment		• Navigate intrigue and mystery in a world of scheming magicians and devious monsters. 
*comment		*line_break
*comment		• Look for love in at least some of the right places.
*comment		*line_break
*comment		• Balance student loans, sleep, daily commute, rent payments, and demonic litigation—hey, nobody said being a wizard was always fun.
*comment	
*comment		*if choice_is_trial
*comment			[i]You can play the first part of the game for free right here. (Beware, it ends on a cliffhanger!) The rest of the game is available for purchase; just click on one of the store buttons below.[/i]
*comment	
*comment			*page_break Play Now for Free
*comment			*goto purchased
*comment		*else
*comment			[i]You can play the first part of the game for free. (Beware, it ends on a cliffhanger!) You can purchase the rest of the game below; purchasing the rest of the game will also turn off in-game advertisements.[/i]
*comment	
*comment			*purchase_discount adfree 2019-07-09 $4.99 $2.99 purchased
*comment			*page_break Play Now for Free
*comment			*advertisement

*if not(choice_is_web or choice_is_steam)
	*temp skip_description
	*config skip_description false
	*if skip_description
		*goto purchased
*check_purchase adfree
*if choice_purchase_supported and not(choice_purchased_adfree)
	Battle demons and undead attorneys, and win souls to pay back your student loans! At the elite demonic-law firm of Varkath Nebuchadnezzar Stone, you'll depose a fallen god, find romance, and maybe even make partner, if you don't lose your own soul first.

	[i]Choice of the Deathless[/i] is a necromantic legal thriller by Max Gladstone, Campbell Award-nominated author of [i]Three Parts Dead[/i] and [i]Two Serpents Rise[/i]. The game is entirely text-based--without graphics or sound effects--and powered by the vast, unstoppable power of your imagination.

	• Explore a fantasy realm with a rich and evolving backstory, based on the novels published by Tor Books.[n/]
	• Play as male or female, gay or straight, dead or alive (or both).[n/]
	• Build your career on carefully reasoned contracts, or party all night with the skeletal partners at your firm.[n/]
	• Navigate intrigue and mystery in a world of scheming magicians and devious monsters. [n/]
	• Look for love in at least some of the right places.[n/]
	• Balance student loans, sleep, daily commute, rent payments, and demonic litigation—hey, nobody said being a wizard was always fun.[n/]

	*if choice_is_steam
		*if choice_prerelease
			[i]You can play the first two chapters of the game for free today. The rest of the game will be available on ${choice_release_date}.[/i]

			*choice
				#Sign up to be notified when the game is available.
					*subscribe {"now": true}
					*restart
				#Play the first two chapters now for free.
					*goto purchased

		[i]You can play the first two chapters of the game for free. Purchase the rest of the game below.[/i]
		*if choice_is_advertising_supported
			[i]Purchasing the rest of the game will also turn off in-game advertisements.[/i]

		*purchase_discount adfree 2019-01-01 $4.99 $2.99 purchased
		*page_break Play Now for Free
		*goto purchased
	*else
		*if choice_is_advertising_supported
			[i]Choice of the Deathless[/i] is supported by advertisements, but you can buy the unlimited version
			to turn off ads forever.
			
			*purchase_discount adfree 2019-01-01 $4.99 $2.99 purchased
			*page_break_advertisement

			*goto purchased
		*else
			[i]You can play through the game once for free, or purchase unlimited replays below.[/i]

			*purchase_discount adfree 2019-01-01 $4.99 $2.99 purchased
			*page_break Play Now for Free


*label purchased
The sky over the demon world is broken.  Lightning licks the strange geometries of cloud.  Around you rises the demon-city Akargath, warped crystal and flame, thorns and razor wire.  And this is the nice part of town. 

Gods, you hurt.  Your skin's a burned ruin.  Bones in your ribs grind when you breathe.  Your suit hangs in tatters from your body.

Your enemy stands before you: a towering figure of glass and knives.  Cackling madly, he raises one hand.  Dark power crackles along his talons.

The battle's taken almost all your strength.  Your Craft, your own power, stands at ebb.

If you don't win this thing soon, you're done.

*choice
	#I wait for my enemy to attack, then redirect his power against him!
		*set battle_redirect true
		As the blast scythes toward you, you bind it with your own Craft and cast it back against your foe.  To catch such power in mid-flight is almost impossible, but you manage, a virtuoso display of finesse and improvisation.
		
		If you survive this, you'll return to the Hidden Schools and rub this moment in the face of every professor who ever claimed you'd not amount to anything.
		
		If.
		
		*page_break
		
		The bolt shatters your enemy's chest to crystal shards.  They fall like rain, and reflect your battered face a million times in miniature.
		
		But before your very eyes the crystal melts again and flows back to heal the wound you made.  He stands before you, mighty as before.
				
		The effort's almost exhausted you.  You can't turn another hit like that.
		*set cunning +10
		*choice
			#Strike him down while I still can.
				You throw the last dregs of your soul against him.  After the earlier blast, this seems to have more effect.
				
				He staggers, and roars with agony and rage.  But he recovers all the same.
				
				"No more games," he says.  "Time to die."
				*set craft +10
				*goto Die
			#Say something.  Try to stall him.
				*label Talk
				*set battle_talk true
				You scream into the whirlwind.  "Others will come after me.  And after you."
				
				He laughs.  "Who?  Who do you think cares enough about you to risk their life for vengeance?"
				*set charm +10
				*choice
					#My friends.
						"My friends won't rest until they find you."
						
						"Then they, too, will die."
						*set Ngabe +10
						*set Chen +10
						*set Vega +10
						*set battle_friends true
						*goto Die
					#Ashleigh Wakefield.
						"Ashleigh will."
						
						"Perhaps.  Perhaps Wakefield will only squirm less before dying."
						*set Wakefield +20
						*goto Die
					#My firm.
						"You kill me, and Varkath Nebuchadnezzar Stone will hound you to the end of time.  Do you think my partners can't find you here?  Or in whatever rathole you try to hide?"
						
						His laugh is high and creaking, like a door on a poorly oiled hinge.  "You think they'll seek vengeance on one of their most prized clients?  We'll settle eventually.  And you'll be long dead by then."
						*set battle_firm true
						*set Varkath +20
						*set Nebuchadnezzar +20
						*set Stone +20
						*goto Die 
	#I strike while I can, and give no quarter.
		*set battle_force true
		You're strong.  Stronger than this.  And you won't die here.
		
		Or at least you won't die alone.
		
		Before he can attack, you throw your power against him—all the soulstuff you can summon, merged into a single spear of coruscating light.
		
		*page_break
		
		He staggers, and falls to his knees.
		
		You advance, dragging your broken leg over the ground.  Exquisite pain, but you've won.  You think.
		
		Until he looks up, and smiles jagged teeth.  "Is that all?"
		
		It was.  That was the plan.  What now?
		
		*set craft +10
		
		*choice
		
			#Talk to him.  Try to stall for time.
				*goto Talk
			#Pretend I'm going to blast him again.  Then punch him in the face.
				*set battle_fistpunch true
				*achieve fistpunch
				You raise one hand, fingers curled into claws, and chant mystic nonsense.  He Crafts a shield between you, ready to ward off an assault of pure thaumaturgical power.
				
				His shield's a piece of work.  Certainly would have stopped an assault of pure thaumaturgical power.  Doesn't stop your fist, though.
								
				Unfortunately, while it feels satisfying as hell to deck a nigh-omnipotent demonic horror, you can't say much for the effectiveness of the strategy.
				
				His head snaps back, spins around, and settles onto his shoulders again.  It would be a comical effect if you weren't about to die.
				
				Blood runs down your hand.  You sliced your knuckle open on his cheekbone.  
				
				Great, you think, in the instant before he hits you.
				*set power +20
				*set cunning +10
				*goto Die
			#Spring my trap.
				*set battle_trap true
				You might not have hurt him much, but at least you pushed him into position.
				
				The Craft circle you drew earlier springs to life, and glass shatters in the buildings overhead.  Steel and crystal fall like rain, sharp points and edges descending…    
				
				Only to stop in midair, with a wave of your opponent's hand.
				
				"Nice trick," he says, and strikes.
				
				*set cunning +20
				*goto Die
	#I run and hide.
		*set battle_run true
		Discretion is the better part of valor.  Or at least of surviving long enough to think up a plan.
		
		You sprint left down an alley, and burst through a loading dock into what in your world would be the back room of a clothing store.  The mannequins and racks of garments are interspersed with what look like displays from a torturer's supply company.
		
		*set cunning +10
		
		*page_break
		
		Footsteps approach.  Glass grinds underfoot.  This shop has plenty of hiding spaces, and you have a few seconds to choose.
		
		*choice
			#I hide in the supply closet.
				You dive into the closet, and pull it shut behind you—softly, slowly, so he won't hear the click.
				
				You're in a dark, close space.  Surrounded by pointy objects.  Hope you don't have claustrophobia.
				*choice
					#I do, actually.
						Well.  That wasn't a well-considered decision, was it?
						
						*set claustrophobia true
						*goto Plan
					#Not really.  I swear.
						It's really dark in here.  Are you sure?
						*choice
							#No.
								*set claustrophobia true
								*goto Plan
							#Yes.
								*set claustrophobia false
								*goto Plan
					#Would I have hidden in a closet if I had claustrophobia?
						Maybe.
						*set claustrophobia false
						*goto Plan
			#I disguise myself as a mannequin.
				*set battle_disguise true
				Most of these mannequins have several extra limbs and slick insectile faces, but there are a few humanoids, and a couple of those are draped in flowing hooded robes.
				*choice
					#I hide in a robe.
						Seconds to go.  Footsteps closing.  You whip a robe off a mannequin and wrap it around yourself.
						
						After a second's consideration you hide the now-naked mannequin inside an iron maiden.
						*set cunning +10
						*goto Plan
					#I hide among the humanoids.
						Nothing for it but to stand immobile, and trust the reflections in the glass to confuse him.
						*set cunning +5
						*goto Plan				
			#I crouch behind a rack.
				You crouch behind a rack, upon which a humanoid mannequin that looks an awful lot like you lies splayed.
				
				That's a coincidence.  Has to be.
				
				*goto Plan
		*label Plan
		
		"You can't hide forever," he says from the alley.
		
		He steps inside.
				
		What's your plan?  If you have one?
		*choice
			#What part of "hide" do you not understand?
				You remain silent as his footsteps approach.  You stop breathing.
				
				"This isn't your world," he says.  "I can smell you, here.  I can feel your fear."
				
				Then your hiding place shreds to glittering razor-sharp ribbons, and you stand revealed before him.  Ruby eyes pierce you.
				*set cunning +5
				*goto Die
			#Once he's close enough, I spring my trap.
				*set battle_trap true
				You don't have much power, and you didn't have much time, but enough at least to draw a little Craft circle on the floor in your own blood.  A channel for power.  And with a word, you let that power loose.
				
				The storeroom shatters, and thousands of glass shards sweep toward him, sharp enough to cut him to ribbons.
				
				And then they stop, in midair.  And he laughs.
				
				Well, it was a nice idea, at least.
				
				*set craft +20
				
				*goto Die
			#No plan.  But if I get a shot, I'm taking it.
				*set battle_force true
				One shot should do it.  You think you've judged his position right, from his footsteps and from the weight of his presence on your mind, on this world.  You sharpen your will into a spear.
				
				And you lash out.
				
				The bolt tears through your hiding space, and he stands revealed in its path, slack-jawed with shock in the instant before your power strikes his chest.
				
				And scatters off it ineffectually.
				
				So much for that idea.
				
				*set power +20
				*goto Die
*label Die
*page_break

He closes his clawed hand into a fist.  You crouch, ready for the attack.

He's powerful, but arrogant.  If you just hold out a few seconds more, you'll find some angle, some way to beat him.  As long as you can keep it together.

Then claws of light and power strike you, and you shatter.

*achieve die
*page_break

Your mind comes to pieces and the pieces tumble, sharp, spinning.  Seconds come unmoored from seconds.  Shards catch and reflect images of a once-familiar life: your past, spinning out of reach.

You have to fight back.  Have to stop him.  Defend yourself.  So hard to think.  What does thinking mean, anyway, outside of time?

You scramble amid the shattered, jagged facets of your self.  They cut your fingers, and blood flows into memory. 

*page_break

*comment Character creation through character death!

You must remember.  You must fight.  You are…

Hells.  Who are you, anyway?

There must be an answer here, amid the slivers and glass confetti, among the kaleidoscope shapes.  If only you could grasp it.  You don't even have hands with which to grasp.  Or a body, for that matter.

No.  You have one.  You remember.

You are…

*comment I think the first two options just about cover it.
*comment At least, since we won't be explicitly between the sheets.
*comment But I think the third one's kind of fun.  Let's see how much of a hassle it is.
*choice
	#A man.
		*set char_gender "male"
		*set char_pro "he"
		*set char_pro_cap "He"
		*set char_pro_pos "his"
		*set char_pro_obj "him"
		*set char_pro_abs "his"
		*set char_binary "man"
		*set char_voc "Mr."
		*set craftsperson "Craftsman"
		You are a man.
		*goto Name
	#A woman.
		*set char_gender "female"
		You are a woman.
		*goto Name
*comment  Sexual tension turns out to be too central to the game for this to be an easy option to code.  Maybe.
*comment	#It doesn't matter.
*comment		*set char_gender "neutral"
*comment		You are a human being.  You are…
*comment		*goto Name
		
*label Name

Your name, if you could just remember—names tie lives together, knit memories to memories.  And [i]your[/i] name is…

*choice
	#Jamie.
		*set name "Jamie"
		*goto Surname
	*if char_gender = "female"
		#Sarah.
			*set name "Sarah"
			*goto Surname
	*if char_gender = "female" 
		#Bahati.
			*set name "Bahati"
			*goto Surname
	*if char_gender = "female" 
		#Ailing.
			*set name "Ailing"
			*goto Surname
	*if char_gender = "male" 
		#John.
			*set name "John"
			*goto Surname
	*if char_gender = "male" 
		#Xueyou.
			*set name "Xueyou"
			*goto Surname
	*if char_gender = "male" 
		#Mark.
			*set name "Mark"
			*goto Surname
	#Something else.
		What is it?  So many shards tumbling out of reach, even as you grasp for them.
		*input_text name
		*goto Surname
		
*label Surname

That's only part of it.  ${name}…

*choice
	#Kang.
		*set surname "Kang"
		*goto History
	#Gaspard.
		*set surname "Gaspard"
		*goto History
	#Cavendish.
		*set surname "Cavendish"
		*goto History
	#Bly.
		*set surname "Bly"
		*goto History
	#Shepard.
		*set surname "Shepard"
		*goto History
	#None of these.
		A name for your family, for your people…
		*input_text surname
		*goto History
		
*label History
*comment Some options for how our PC spent his college career.
*comment Maybe add another layer or two of choice?
*comment My goal with stat setup is to provide primary, secondary, tertiary stats.

How did you get here, ${name}?  So many alternative pasts, so many options.  Dreamshards, timepieces.

Childhood: the first stirrings of power.  You caught a falling star in a dead field, and held it burning in your hands.  Smelled the sweet iron of space and the world's heat, as fiery fingers crawled over your skin and into your flesh.

*choice
	#I closed my hands around the star.
		You closed your hands and the star's fire tore through you, burned along the channels of your soul, barbed into your young muscles.  It dragged across you like a steel knife over a guitar string.  As you passed out, you saw the world beneath the world, the world that remains when you close your eyes: a vast net of souls and exchange, a pulsing network of life and story and bargain and consequence.  Yours to twist, yours to command.
		
		When you woke, that vision remained, your first sight of a deeper world.  You would learn to use that strength one day.  But first, you had to grow up. 
		*set power +10
		*goto life_path
	#I released the star into the sky.
		The star twisted, lifelike, in your grip.  You raised your hands and opened your fingers and offered it to the sky.
		
		Burning with hidden wings, it rose, and spread, and rising spread more until it  shone triumphant in the dark.  You closed your eyes, but saw the star still, and more, by its light: a vast net of souls and exchange, a pulsing network of life and story and bargain and consequence.  Every node of the web whispered to every other.  As one, they sang.
		
		You passed out, but when you woke, that vision remained, your first sight of a deeper world.  You would sing one day, with that world, with the stars.
		
		But first, you had to grow up.
		*set charm +10
		*goto life_path
	#I ate the star.
		You pressed the star past your open lips, tasted lightning on your tongue, and swallowed; liquid metal seared your esophagus, and you fell back onto the dead grass, screaming.  Galaxies wheeled above you, moonlight unbearably sharp.  You closed your eyes but that only replaced the punishing stars with another vision.
		
		This is the world beneath the world: a vast net of souls and exchange, a pulsing network of life and story and bargain and consequence.  You see the terms of the Great Deal, the arguments and conditions upon which your world depends.
		
		You could join that bargain.  Shape it.  But first you had to grow up.
		*set craft +10
		*goto life_path
	#I watched the star as it died.
		You sat cross-legged on the grass and watched the star fade, slowly, through the night: first the outer edges of its corona died, and then the death crept inward.  Brilliance gone, you could trace its skeleton, its structure.
		
		Hours passed.  The star was a dying coal in your cupped palms.  Your eyes followed it down, and as it faded you saw more, the fainter, subtler world that endures when you close your eyes: a vast net of souls and exchange, a pulsing net of life and story and bargain and consequence.  You could parse it all, if only you had time.
		
		When you woke up with the dawn, the vision had vanished, but the image remained.  You'd learn the world's secret ways.  But first you had to grow up.
		*set cunning +10
		*goto life_path

*label life_path
And growing up presented its own challenges.  You were…

*choice
	#A beggar.
		…a child of hunger and circumstance, a drifter and occasional thief.  You grew hard, and you grew strong, and you set your sights on the high places of the world.  You would rise, or you would pull them down trying.
		
		Hard to rise from such circumstances to the heights of the Hidden Schools.  Not impossible, but almost.  Your classmates were soft by comparison.

		*set background "beggar"
		*choice
			#And I told them so.
				*set gunner +20
				*set soul -500
				*set power +10
				*goto School
			#But I hid my contempt from them.
				*set gunner -20
				*set cunning +10
				*set soul -500
				*goto School
			#I envied them that security, and tried to blend in.
				*set gunner -10
				*set charm +10
				*set soul -500
				*goto School
	#Poor.
		…a scrapping farmer's child on the edge of the desert, your people survivors of the God Wars.  But city lights always beckoned behind the horizon, and your infant stirrings of power grew.
		
		You set your sights upon the Hidden Schools, where professors who have slain gods in single combat teach their dark Craft to the next generation.
		*set cunning %+10
		*set power %+10
		*set gunner %+10
		*set soul -250
		*set background "poor"
		*goto School 
	#Comfortable.
		…a merchant's child, supported and loved.  You were the product of your family's dreams, and of their determination to rebuild after the God Wars decimated Grandfather's business.  From the first day you showed interest in the Craft, your destiny was never in doubt.  You were bound for the Hidden Schools, to learn sorcery.
		*set background "comfortable"
		*set debt -50000
		*goto School
	#Rich.
		…a scion of a grand old family, with connections and powers stretching back  thousands of years, to the old days when gods ruled the world and human beings did not control their own destiny.
		
		The God Wars destroyed mountain ranges, shattered continents, smote the gates of many heavens—but wealth has a habit of surviving.  Your family is not what it once was, but move by move your clan has reclaimed its ascendancy.
		
		And you are a pawn in that generations-long struggle for privilege and position.  Despite your (in Grandfather's eyes) foolish decision to attend the Hidden Schools rather than focusing your efforts on the family Concern.
		*set background "aristo"
		*comment I'd set it to "aristo swine" but I think that takes too long to type
		*set debt -100000
		*set soul +500
		*goto School

*label School
*page_break

You developed, in those conditions, from child to ${char_binary}.  Here's a cutting, tumbling shard of lips and skin—a first kiss…

*choice
	#A girl I knew.
		A bright afternoon, a brief rest, a pressure of lips and hands and bodies.  Neither one of you was very good at kissing, or at anything else you tried, but it was a start, and it was sweet.  You wonder what became of her.
		
		You'll never know.
		*set first_kiss "girl"
		*goto School_2
	#A boy I knew.
		A bright afternoon, a brief rest, a pressure of lips and hands and bodies.  Neither one of you was very good at kissing, or at anything else you tried, but it was a start, and it was sweet.  You wonder what became of him.
		
		You'll never know.
		*set first_kiss "boy"
		*goto School_2


*label School_2
More flashes from your years at the Hidden Schools, where you studied the dark arts men call Craft.  A century ago, you would have been burned at the stake for learning these skills—how to raise the dead from their graves, how to hold the power of the gods in your own hands.  Then the God Wars happened, and humans won.  The Hidden Schools rose in defiance of divine authority, and life became a lot better for people who chose to twist natural law in to their whims.  People like you.

You see, you remember…
*temp lovers false
*choice
	#Hours and hours of studying, sweating, bent at my desk.
		So many exams.  Demonic voices in dark rooms.  Pentagram after pentagram, drawn by acid on stone, inscribed with forgotten runes.
		
		You summoned demons.  You banished them again.  You raised men from the dead and made them walk, made them fight, made them sing.
		
		You walked a lonely road, and gained strange powers there.
		*set gunner %+20
		*set craft %+40
		*set power %+20
		*set cunning %+10
		*goto AndThen
	#Keg stands and drunken revels, dancing, flesh, and joy.
		Memories of flesh and music.  The world spun as you hung suspended above it: a thousand feet in the air and still you walked the razor's edge.
		
		Lovers' lips and hands and bodies flash and pass into darkness.  The Hidden Schools were the world's greatest party, all the finest minds of your generation gathered into one place and compressed until they either collapsed, or decided to explode.
		
		You exploded.
		
		Every moment's zenith had its nadir.  The one time after your Necro final you ended up wandering drunk through a bad part of southern Oxulhat, and got beaten black and blue by some people you shouldn't have bothered.  Another morning you woke on the Sevenfold Tower without your pants—either kind of pants.  But it was a good run.
		*set lovers true
		*set gunner %-20
		*set charm %+40
		*set power %+20
		*set craft %+10
		*goto AndThen
	#The gym.  The track.  Books when I had to, but always the field.  
		You lived a life of iron.  The Hidden Schools for you were one long, slow, tooth-grinding max load rep.  Any time you weren't in the gym or on the field, you spent in books.  Your body, after all, would only last so long.
		
		You broke your arm once in a clutch.  Pressed harder and harder to make that final yard.  Felt something snag your arm.  Ignored it.  Realized, when the ref called time, that your forearm hung at an odd angle from your elbow.
		
		Your teammates bore you on their shoulders, and you bore them in turn.  You sweated together.  You bled together.  You never were the smartest, but when you set yourself to a thing, it happens.
		*set gunner %+10
		*set charm %+20
		*set craft %+10
		*set power %+40
		*goto AndThen
	#Sneaking through and around the rules.
		You climbed the Sevenfold Tower in a thunderstorm to see the light that played among its many tines.  What you saw there you've never told a single soul.
		
		Professors warned you to stay within the rules, not to meddle in matters you lack the context to comprehend.  Yet you were the first in your class to wake a corpse from slumber.  Admittedly, it attacked the freshman dorms and started a zombie plague that almost infected the whole school.  Nobody tied that to you, though!  At least, not officially.
		
		You learned the Hidden Names of Professor Halcyon.  You found six of the seven Immaterial Volumes of the Great Library.  You think you caught a glimpse of God—or, a God at least—in the outer reaches of the astral plane.  Once.
		
		You were probably a bit unhinged.  But damn if you weren't unhinged in style.
		*set gunner %-10
		*set cunning %+40
		*set craft %+20
		*set power %+10
		*goto AndThen
*label AndThen

The Hidden Schools were a realm of darkness and study, but no one ever accused the students there of monastic discipline.  What pleasures did you indulge in?  What loves?  What faces, what bodies, reflect in the falling shards of what used to be yourself?

*choice
	*if (not(lovers)) #There was no time for love.
		*set power %+10
		You walked a path.  No needs of the flesh would tear you from it.
		*goto AndThen_2 
	*if (first_kiss="boy") #I discovered that I loved women.
		*set charm %+10
		Your career at the Hidden Schools, away from everything you thought you'd known, was an archaeology of the mind.  By brushing and chipping away ossified pieces of your former life, you learned yourself: who you were, and what—and whom—you liked.  Your first kiss with a woman was the opening of a door.  Many more followed.
		*goto AndThen_2 
	*if (first_kiss="girl") #I discovered that I loved men.
		*set charm %+10
		Your career at the Hidden Schools, away from everything you thought you'd known, was an archaeology of the mind.  By brushing and chipping away ossified pieces of your former life, you learned yourself: who you were, and what—and whom—you liked.  Your first kiss with a man was the opening of a door.  Many more followed.
		*set Ash_gender "male"
		*set Ash_pro "he"
		*set Ash_pro_cap "He"
		*set Ash_pro_pos "his"
		*set Ash_pro_obj "him"
		*set Ash_pro_abs "his"
		*set Ash_voc "Mr."
		*set Ash_binary "man"
		*set Ash_hair "blond"
		*set Ash_craftsperson "Craftsman"
		*set Ash_pro_abs_cap "His"
		*set Ash_pro_pos_cap "His"
		*set Ash_pro_self "himself"
		*goto AndThen_2
	*if (first_kiss="boy") #I wanted men, and found men who wanted me.
		*set charm %+10
		They were strong, they were brittle, they were brilliant, they were shortsighted, they were beautiful, they were unformed.  In short, they were young, and so were you.
		
		But the process was fun for all involved.
		*set Ash_gender "male"
		*set Ash_pro "he"
		*set Ash_pro_cap "He"
		*set Ash_pro_pos "his"
		*set Ash_pro_obj "him"
		*set Ash_pro_abs "his"
		*set Ash_voc "Mr."
		*set Ash_binary "man"
		*set Ash_hair "blond"
		*set Ash_craftsperson "Craftsman"
		*set Ash_pro_abs_cap "His"
		*set Ash_pro_pos_cap "His"
		*set Ash_pro_self "himself"
		*goto AndThen_2 
	*if (first_kiss="girl") #I wanted women, and found women who wanted me.
		*set charm %+10
		They were strong, they were brittle, they were brilliant, they were shortsighted, they were beautiful, they were unformed.  In short, they were young, and so were you.
		
		But the process was fun for all involved.
		*goto AndThen_2 
	#I wanted both men and women.
		*set charm %+10
		You chose the ones you loved, no matter the flesh they wore.  They were strong, they were brittle, they were brilliant, they were shortsighted, they were beautiful, they were unformed.  In short, they were young, and so were you.
		
		But the process was fun for all involved.
		*set character_is_bi true
		*temp coin_flip
		*rand coin_flip 1 2
		*if coin_flip = 2
			*set Ash_gender "male"
			*set Ash_pro "he"
			*set Ash_pro_cap "He"
			*set Ash_pro_pos "his"
			*set Ash_pro_obj "him"
			*set Ash_pro_abs "his"
			*set Ash_voc "Mr."
			*set Ash_binary "man"
			*set Ash_hair "blond"
			*set Ash_craftsperson "Craftsman"
			*set Ash_pro_abs_cap "His"
			*set Ash_pro_pos_cap "His"
			*set Ash_pro_self "himself"
			*goto AndThen_2
		*goto AndThen_2 

*label AndThen_2

And then you graduated, and went to work.

*finish_advertisement