*comment *****************************************************************
*comment Neighbourhood Necromancer, chippy
*comment by Gavin Inglis -- www.gavininglis.com
*comment *****************************************************************

*set energy max_energy

It was shortly after you came home with fish suppers that your parents were slaughtered by undead. Therefore, in a way, their deaths are the fault of the fish and chip shop. Plus, the shop prices are steep and their customer service is appalling.

Clearly, the appropriate response is a visit from the undead.

*page_break

*comment *****************************************************************
*label chippy_attack
*set chippy_attacked true

You examine the fish and chip shop. It's a shabby, detached shack on a side street with a patch of waste ground around the back where, apparently, they pile up heaps of stinking bin bags. The back door is fastened with a chain and heavy-duty padlock. But one of the upper windows is slightly ajar. 

You feel a little queasy as you return to the front. It's still daylight. What approach will you take?

*choice
  #Slip an undead inside now and lie in wait.
    *gosub_scene end_trial
    You find a wire hanger among the rubbish and twist it into an extended loop. With a little patience, you manage to work it over the window catch and unlock the window. You can probably get one minion through the resulting gap, if you help push them through.
    *choice
      *selectable_if (skeletons > 0) #Send in a skeleton.
        The skeleton scales the wall without much effort, dry toes scraping against the brick. You guide its feet through the gap, still slightly weirded-out by how the bones stay together without muscles, tendons, and ligaments.

        Now you wait, skulking behind a tree. It's half an hour before Al the fat manager shows up. He messes with the padlock then pulls the chain away and opens the door. You wait for a scream.

        It comes immediately. Pretty high-pitched for a man who works with so much grease.
        *set scommit 1
        *set luck %+5
        *set energy %-30
        *page_break
        *goto secret_assault
      *selectable_if (zombies > 0) #Send in a zombie.
        The zombie stares at the window, inert. Musty breath rasps from its raggedy mouth. You lift it up by the knees and try to cram it through the open window. The top of its head scrapes around on the brick of the walls, leaving a syrupy trail.

        Eventually, you get the torso through the window and shove. There is a crash from the other side and the window swings shut. That was more effort than it should have been. 

        You get some distance and rest behind a tree. It's half an hour before Al the fat manager shows up, carrying two boxes. He messes with the padlock then pulls the chain away and opens the door. You wait for a scream.

        There is a pause.

        "What the hell is this?" Al yells from inside.
        *set zcommit 1
        *set luck %-5
        *set energy %-20
        *page_break
        *goto secret_assault
  #Confront them as they are setting up for the evening.
    *gosub_scene end_trial
    You cool your heels behind a tree.
    *if (zombies > 0)
      A zombie keeps straying out of cover and you end up draping branches over its head as a disguise.
      *set visibility +1
    *comment endif
    
    After half an hour, Al the fat manager shows up, carrying two boxes. He fiddles with the padlock then pulls the chain away and opens the door. A few seconds later, there is a clatter and then a stream of colourful swearing directed at "Rick". You presume this is the other guy.

    *choice
      *selectable_if (skeletons > 0) #Send in a skeleton.
        The skeleton extends its arms and twists its head a little. It seems to be doing some kind of warm-up. It might be your imagination but you think you hear its knuckles crack. Then it marches towards the unlocked back door and grabs it with bony fingers.
  
        *set scommit 1
        *set energy %-20
        *goto secret_assault

      *selectable_if (zombies > 0) #Send in a zombie. 
        The zombie stares at you with one yellowed eyeball. The other seems interested in a pile of leaves three metres away. You grip the humerus and concentrate. It's harder than you expected to instruct the zombie to open the door. Still, in the end, it stumbles through.

        *set zcommit 1
        *set energy %-30
        *set control %+5
        *goto secret_assault
      #Wait until the other guy (presumably Rick) shows up.
        It gets dark while you wait. You check your watch. When does the shop open? Keeping the undead hidden and quiet is a strain. One car pulls up in front of the shop, then another. Al must already be serving customers. There go your chances at a secret attack.

        Finally, Rick shows up, his moustache glistening in the twilight. He scuttles in the back door.

        *set luck %-5
        *set energy %-10
        
        *choice
          #Go ahead and attack even though the shop is now open for business.
            *goto public_assault
          #Give up on revenge against the fish and chip shop.
            Hiding behind a tree, staring at the back of a hot food emporium. This won't go down as the most spectacular evening of your life. Maybe there are more important targets for your wrath than two fish and chip shop guys. You might as well quit for tonight and see what tomorrow brings.

            At least you got some practice in controlling your malodorous minions.

            *set control %+10
            *set humanity +1
            *page_break Next Day
            *goto_scene stageone
  #Confront them while they are serving customers.
    *gosub_scene end_trial
    Their humiliation will only be complete if it takes place in public. You wait as the sun goes down, remembering all the discoloured chips, the "accidental" short change, the queue jumpers, and those late-night pints of milk that were always past their best-before date.

    Revenge is a dish best served deep-fried.
    *page_break
    *goto public_assault

*comment *****************************************************************
*label secret_assault

You slip around the side of the building and peer in the window.
*if (zcommit = 1)
  Al is squaring up to the zombie behind the counter, his hands knotted into beefy fists. "Gerraway!" he shouts. "I just got the hygiene certificate back for this place!" He seems about to throw a punch at the zombie's festering face, then thinks twice and shoves it in the chest. The zombie staggers back against the tiled wall.

  Al, for some reason, takes the opportunity to slip his hands into blue latex gloves. 
  *choice
    #Press the attack.
      You urge the zombie forward while Al is still fiddling with his gloves. It leans its dead weight on him and bears him to the floor. You hear a wet thump like a dropped blancmange.

      *set luck %+15
      *set al_down true
      *set energy %-10
      *goto rick_arrives

    #Topple the boxes of supplies.
      It's easy enough to get the zombie to flail around. It scatters cardboard boxes and knocks bottles to the the floor. Raw burgers spill across the tiles and glass shatters, spraying colourful sauce across the units.

      *if (luck > 46)
        Al rushes the zombie, yelling "That's my margin, you festering f—!" and immediately slips on his ruined stock. He grabs the zombie as he goes down. You hear a wet crunch as they land on the glass together.
 
        *set control %+5
        *set luck %+10
        *set energy %-20
        *set al_down true
        *goto rick_arrives
      *else
        Al rushes the zombie, yelling "That's my margin, you festering f—!" and immediately slips on his ruined stock. He grabs the edge of the fryer to stop his fall. Then he grips the zombie's shoulder and pounds it to the floor.
        *set control %+5
        *set energy %-20
        *goto rick_arrives
    #Contaminate the fryer with zombie fingers.
      You move the zombie's arm, trying to get it to scrape a strip of flesh off into the cooking oil. Wide-eyed, Al yells and takes a swing at it.

      It's difficult to do fine motor control on a staggering zombie while it's being pummeled by an angry chip shop manager. You channel your command through the bone.

      *if (control > 50)
        The zombie leans into a sharp edge and a long strip of putrefying flesh tears off. It drops into the fryer and immediately sinks from view. "Nooooo!" Al howls. "I'll have to sterilise that whole pan again!" He wrestles the zombie to the floor.
        *set energy %-20
        *set luck %+15
        *set al_down true
        *goto rick_arrives
      *else
        The zombie hesitates, confused. Al seizes the moment and kicks it in the stomach with his grubby loafers. It falls back, away from the fryer. He stalks forward, blue latex fists at the ready.
        *set energy %-20
        *set luck %-5
        *goto rick_arrives
*else 
  Al and the skeleton are engaged in some sort of grotesque dance behind the counter. The skeleton shuffles its feet and gives a twisted version of 'jazz hands'. Al snaps at it with his fryer tongs.
  *choice
    #Instruct the skeleton to disarm Al.
      *if (control > 46)
        This skeleton has some kind of freaky phantom muscle memory kung fu thing going on. It blocks the tongs with one arm and plucks them from Al with the other. His eyes widen and he staggers back.

        It advances on him, nipping the tongs near his ears like some kind of reanimated Mr. Miyagi. Backed against the wall, Al drops, protecting his face with an arm.
        *set energy %-15
        *set luck %+15
        *set al_down true
        *goto rick_arrives
      *else 
        The skeleton moves fast but you can't relay your commands quickly enough to react to what Al is doing. He gets a grip on the skeleton's collarbone, twists, and kicks its legs out from beneath it. It clatters to the ground.
        *set energy %-20
        *set luck %-5
        *goto rick_arrives
    #Press the skeleton forward, unarmed.
      The skeleton advances on Al, backing him up against the wall.
      *if (luck > 42)
        He slips on something greasy and goes down with a wet thump.
        *set energy %-10
        *set luck %+10
        *set al_down true
        *goto rick_arrives
      *else
        He lunges with the tongs and gets a lucky grip on the edge of the nasal cavity. You think he might plunge the skeleton into the fryer but he turns it in the other direction and drags it into the doorway. He slams the door on its arm bones and you hear a distinct CRACK. Then he does it again. And again.

        The door begins to warp and snap when he starts on the legs. By now the skeleton is unsteady and it collapses. Al jumps on its chest for a bit, then grabs a metal bin and starts to smash it into the ground. He clearly has issues to work out.

        Eventually the other guy, the one with the droopy moustache, comes through the door to find his manager pulverising a small pile of bones with the now concertina-folded bin. "Everything all right, Al?" he asks, like this is nothing special.

        You drop down from the window and slink away with your remaining undead. Clearly the fish and chip shop was a harder target than you expected.
        *set energy %-20
        *set luck %-15
        *set skeletons -1
        *set minion_count -1
        *page_break
        *goto chippy_fail
    #Improvise a weapon.
      Al's fish tongs are a serious piece of hardware. Through the window, you can't really get a clear look at your skeleton's environment. What will you urge it towards?

      *choice
        #An item from the fryer.
          Your skeleton rakes around in the fryer and comes up with a jumbo sausage in batter. Unfortunately, the soggy sausage disintegrates between the bony fingers. You make a mental note to avoid this kind of delicate manoeuvre in future.

          Al takes advantage of the weaponry malfunction to crash his fists down on the skeleton's shoulders. He howls as his puffy flesh strikes bone, but your light-footed minion goes down under the impact, feet skittering on the tiles.
          *set energy %-20
          *set control %+5
          *page_break
          *goto rick_arrives

        #The floor mop.
          Your skeleton seizes the blue, plastic mop. Al and the skeleton duel like swashbucklers. He lunges towards a ball joint; it catches him in the ear with the dirty mop head. The skeleton swings; Al parries. The combat ranges back and forth behind the counter while the fryers hiss. 

          You feel a terrible weariness. Keeping your eyes up at this window is becoming a strain.
          *if (energy > 50)
            But you shake it off and concentrate. With a deft flick, the skeleton sends Al's fish tongs flying. It rams him with the mop head and bears him to the ground.
            *set energy %-60
            *set luck %+15
            *set control %+10
            *set al_down true
            *page_break
            *goto rick_arrives
          *else
            You close them for a minute, and you [i]feel,[/i] quite clearly, your control of the skeleton end. You hear a dry clatter. When you force your eyes back open, Al is using his shoe to poke a pile of bones which used to be your skeleton. "What the hell?" he says. 

            Leaning against the wall of the chip shop, breathing heavily, you look at your remaining minions and feel your connection with them waver. It would be very easy to just lie down and sleep here.

            You force yourself to begin the march towards home and your bed. You try to tell yourself you learned something here; it wasn't a total failure. What are minions if not expendable?
            *set energy %-75
            *set luck %-20
            *set control %+10
            *set skeletons -1
            *set minion_count -1
            *page_break
            *goto chippy_fail            
        #The strip light from the ceiling.
          Al won't get back up if you can hit him with a metre-long metal light. You direct the skeleton to stretch up and grab it. It's a little too high.
          The skeleton stretches. Al takes the opportunity to plant a boot in its exposed rib cage. The skeleton stumbles and goes down.
          *set energy %-20
          *set control %+5
          *set luck %-5
          *goto rick_arrives

*comment *****************************************************************
*label rick_arrives

Abruptly you hear the scrape of the back door. The guy with the droopy moustache has arrived for work. He stares at the unexpected intruder behind the counter.

*if (al_down) and (zcommit > 0)
  The zombie looms over Al. He waves his hands to keep the dripping ichor off of his face. "Rick! Get this thing away from me!" he yells.
  *goto rick_fight
*elseif (al_down) and (scommit > 0)
  The skeleton appears to be treading on Al's face. "Rick! Gmm thg mway fme!" he yells.
  *goto rick_fight
*else
  "Rick! Keep it down while I get something to smash it with!" he yells.
  *goto rick_fight

*comment *****************************************************************
*label rick_fight

*if (luck > 45)
  Rick stands frozen, staring. His eyes appear to be getting slowly wider.
  *set advantage true
*comment endif

This is the moment for decisive action.

*choice
  *if ((scommit > 0) and (zombies > 0)) #Send in a zombie to finish the job.
    *goto double_team
  *if ((zcommit > 0) and (skeletons > 0)) #Send in a skeleton to finish the job.
    *label double_team
    *gosub_scene end_trial
    *set energy %-50
    Minion Number Two piles through the door and enters the struggle. You feel sweat break on your brow. Controlling the two different types of undead at the same time is extremely difficult. Also, there is not really enough room behind the counter for a four-way fight.

    For a few moments it looks like a tag-team wrestling match inside. You close your eyes to concentrate and hear desperate yells, clackety bones, and throaty moaning.

    *if (((energy + control) + luck) > 110)
      Your necromantic squad eventually gets the upper hand and topples both men to the floor.
      *page_break
      *goto chippy_victory
    *else
      As you tire, Al gets hold of the metal fire extinguisher and crashes it on the zombie's head, bludgeoning it to the floor. You can feel you are about to lose control of the skeleton, so you issue a last command for it to flee. It slips through the back door and sprints for the trees.
      *set zcommit 1
      *set scommit 0
      *page_break
      *goto chippy_defeat

  #Concentrate hard on controlling your minion.
    *gosub_scene end_trial
    *set energy %-40
    *set control %+5
    *if (((advantage) and (al_down)) and (scommit > 0))
      The humerus glows in your hands. You try to inhabit the skeleton's figure, the rhythm of its bones. It responds smoothly, grabbing Rick and knocking his ankles out from under him. 

      He plunges to the floor beside Al. You're tiring quickly, but you scent victory.
      *page_break
      *goto chippy_victory
    *elseif (((advantage) and (al_down)) and (zcommit > 0))
      The humerus glows in your hands. You try to inhabit the zombie's lumbering form, to work within its stiff movements. It seizes Rick and leans down on him with its dead weight.

      His legs fail and he topples to the floor beside Al. You're tiring quickly, but you scent victory.
      *page_break
      *goto chippy_victory
    *elseif (al_down)
      Rick grapples with your minion, mouth stretched open, howling. Together they bounce off the counter and crash against some pizza boxes. Cans of diet cola and a painting of the Virgin Mary thunder to the ground.

      *if (control > 42)
        You're tiring quickly, but you hold it together long enough to trip Rick and toss him to the floor beside Al. 
        *page_break
        *goto chippy_victory
      *else
        You're finding it difficult to keep yourself upright as all your energy is directed into the fight. At a vital point, your concentration slips and Rick smashes the undead to the floor.
        *page_break
        *goto chippy_defeat
    *elseif (advantage)
      While Rick's brain is processing this paranormal situation, you attempt to use him to knock over Al. This may be the wrong way around as Al clearly possesses a lower centre of gravity.

      *if (luck > 38)
        Your minion gets off a clean throw and directs Rick's head into Al's stomach at some velocity. Al gasps. The subtle control takes a lot out of you, but the two men crash to the floor in a tangle of arms and legs.
        *page_break
        *goto chippy_victory
      *else
        Rick wakes up as your minion seizes him. He grabs at the counter, disrupting the throw. Al steps in while your minion's guard is down and smashes it to the floor.
        *page_break
        *goto chippy_defeat
    *else 
      Obviously used to dealing with customer complaints, the two men work well together. They block your minion's swipes and force it back. As it crashes to the floor, you feel your energy falter. You lose control.
      *page_break
      *goto chippy_defeat

  #Enter the fight personally.
    *gosub_scene end_trial
    It's a very strange sensation to move yourself while controlling the actions of an undead minion. You run round to the back door and plunge inside, shouldering Rick as you enter.

    He blinks and shoves you back out through the door. "Get help, kid!" he yells. "There's some kind of drug addicts attacking the shop!" Your feet catch on one of the bin bags and you topple. Your head smacks against something hard and pain flares behind your eyes.

    *set visibility +2

    As you struggle to your feet, you hear the distinctive sound of
    *if (zcommit > 0)
      a zombie being pounded to mush.
      *page_break
      *goto chippy_defeat
    *else
      brittle old bones being fractured.
      *page_break
      *goto chippy_defeat

*comment *****************************************************************
*label public_assault

You step into the fish and chip shop. The fluorescent lighting seems harsh and white after the darkness outside. A girl sits on the windowsill checking her phone. A boy in a dirty tracksuit leans against the wall, eyes closed, rubbing his nose.

You remember coming here, time after time, sent by your father or just because you were hungry. You look at the guys behind the counter. They always sneer. They always skimp on the chips. They know you have nowhere else to go. Theirs is a chip monopoly.

This time, out in the dark, the undead are waiting. This time, it's going to be different.

*page_break

You close the door quietly and stand there looking at them. The fat one yells at the one with the moustache. "That's crap, Rick. She can't have said garlic mushrooms in a roll. Who ever heard of garlic mushrooms in a roll? They'd fall out. She must have said garlic mushrooms and a chip roll."

"Al." The moustache sticks a greasy finger in his partner's face. "She said garlic mushrooms in a roll, and chips. She was maybe pregnant and that. Just do the garlic mushrooms."

"We've only got plain mushrooms."

Neither of them asks you what you would like. This is the level of customer service you've come to expect.

*choice
  *selectable_if (zombies > 0) #Trigger a zombie attack through the rear door.
    *label zombie_chipper
    *gosub_scene end_trial
    *set zcommit zombies
    Your fingers brush the dry surface of the bone. You close your eyes and make the silent call.

    A slow rain of blows begins on the back door. Rick frowns and turns toward it. "Is that you, Denzil?" he says. No answer. He opens it.

    *if (zcommit = 1)
      *set energy %-20
      Your zombie lurches through the door. Rick gasps and tries to backpedal. He trips over his own feet and goes down on the floor with a thump.

      Al sees the intruder. Responding intuitively, he grabs a jumbo smoked sausage from the hot cabinet and flings it at the zombie's face. It slaps against the decaying flesh with a sizzle and drops to the floor.

      The girl screams and runs from the chippy. The boy, now clearly drunk, lurches after her. Al squares up to the zombie with a sauce bottle. 

      *if (control > 33)
        You lift the zombie's arm to block it and use the other to grab the lapels of Al's overalls. The zombie drags him down on top of Rick.
        *goto chippy_victory
      *else
        From the floor, Rick locks arms around the decaying ankles. The zombie's movements are restricted enough for Al to get a lock with his sauce bottle. He smashes it over the zombie's head. Fragments of glass lodge in its flesh and a pile of red sludge begins to drip down its face. Together, the chip shop guys wrestle the zombie to the floor and begin to pulverise it.

        Perhaps this would be a prudent time to leave.
        *set luck %-5
        *set zombies -1
        *set minion_count -1
        *page_break
        *goto chippy_fail
    *else
      *set energy %-30
      Zombies pile through the door. Rick staggers and falls back under the onslaught. The girl screams and runs from the chippy. The boy, now clearly drunk, lurches after her.

      Al stares at the invaders, his eyes wide.
      *if (zcommit > 2)
        He is quickly overcome by the sheer weight of zombies and dragged to the floor.
        *goto chippy_victory
      *elseif (luck > 33)
        He reaches for a sauce bottle but dead hands tear it from his grasp. Their green-tinged flesh makes a nice contrast with the red bottle. The zombies tear at his overalls and pull him to the floor.
        *goto chippy_victory
      *else

        Unfortunately, years of serving drunk customers have prepared the staff for a zombie assault. They work together intuitively, Rick immobilising zombies from the ground while Al goes for the head with bottles, tongs and, eventually, a painting of the Virgin Mary. You have no option but to call a retreat and flee from the shop yourself. One zombie doesn't make it.

        On the way home, you find yourself wondering if Al will deep-fry the parts of the fallen zombie. It is not an appetising thought.
  
        *set luck %-5
        *set zombies -1
        *set minion_count -1
        *page_break
        *goto chippy_fail
  *selectable_if (skeletons > 0) #Launch a skeleton assault through the front windows.
    *label skeleton_chipper
    *gosub_scene end_trial
    *set scommit skeletons
    *if (scommit = 1)
      *set energy %-30
      You close your eyes and reach mentally behind you for your single-handed skeleton horde. There is a two-second pause, then a familiar $!{town} weekend sound—the tinkle of a window smashing under a head butt.

      The bony troublemaker vaults through. The girl screams. The boy screams. It ruffles their hair with splayed fingers and tries to push their heads together in a clunky kiss.

      The girl punches it in the face. "Ow!" she shouts, and shakes bruised knuckles. The skeleton staggers back against the window. Both customers leg it.

      You turn to the counter. To your horror, you see Rick is on the phone. "Yeah, police!" he says. "It's the chip shop! Those skater kids are back and they're on drugs this time!" Al stops staring at the skeleton and stares at Rick instead.

      You're not ready to take on police yet. You bolt. The skeleton sprints after you. Skeletons need a tighter leash than zombies. Better to find that out now.

      *set control %+5
      *set luck %+5
      *set visibility +2
      *goto chippy_fail
    *else
      *set energy %-40
      The windows behind you shatter and a small wave of bony troublemakers clatters through. The shopkeepers freeze. Frozen mushrooms rain to the floor.

      *if (luck < 41)
        Something touches your neck. You lift a hand and find blood on your fingers. A stray spike of glass has scored a line into your flesh. You shiver.
        *set max_energy %-5
        *set energy %-20
      *comment endif

      The customers scatter for the door. The boy's scream is higher pitched than the girl's. You throw the skeletons forward and instruct them to leap over the counter. They pass you on either side, with a skittering sprint.

      *if (energy > 25)
        *if (control > 47)
          The skeletons vault the counter with impressive agility and plunge both white-coated staff directly to the floor.
          *set luck %+10
          *page_break
          *goto chippy_victory
        *else
          The skeletons tumble over the counter in a clutter of flying limbs. Still, the effect is the same. The white-coated staff are knocked off their feet and go down under a tangle of bones.
          *set control %+5
          *set luck %+5
          *page_break
          *goto chippy_victory
      *else
        The skeletons seem to lose momentum at the last moment. Instead of leaping, they thump against the counter. Al and Rick, immobile, stare at them as they try to claw their way over. 

        You try to urge them forward but suddenly lurch against the wall. You feel dizzy, your legs weak. Your link with the skeletons falters. You're going to pass out, right here on the floor of the chip shop.

        Somehow you find the strength to stagger outside. The cold air awakens you a little. You've got to try for home while you still can. With your last reserves, you recall the skeletons. They lurch after you.

        *set luck %-10
        *set control %+5
        *page_break
        *goto chippy_fail

  #Do something threatening with a sauce bottle.
    *gosub_scene end_trial
    You wrap your fingers around the bottle of sauce and unscrew the top. "Hey," you say, just loud enough to attract the attention of the guys behind the counter. "Your service sucks." Then you swing the bottle, the open end pointing in their direction.

    *set visibility +2
    *if (energy > 40)
      Tomato sauce flies from the bottle, painting a sticky red line across the counter, the wall, and in between, Al and Rick. Strained tomato fills Rick's eye socket and smears through Al's hair. You feel a greasy satisfaction.
      *set luck %+15
      *label post_sauce
      *choice
        *selectable_if (skeletons > 0) #SKELETON ATTACK
          *goto skeleton_chipper
        *selectable_if (zombies > 0) #ZOMBIE ATTACK
          *goto zombie_chipper
        *selectable_if ((zombies > 0) and (skeletons > 0)) #COMBO ATTACK
          *goto combo_chipper
        *if (mayonnaise = false) #Follow up with the mayonnaise sachets.
          The mayonnaise is a much trickier sauce to attack with because it comes in little individual packets which need to be opened by hand. You do a couple but it's fiddly, and you can't get any real coverage with such small quantities of creamy goop. 

          You feel a sudden sense of movement nearby—

          *if (control > 46)
            You duck to one side. A mop head, thick with dirty grease, thrusts through the space where your face was. Al has taken advantage of your distraction to counterattack. He pulls the mop back to strike again.

            *set luck %+5
            *set mayonnaise true
            *goto post_sauce
          *else
            SPLUT. You get a mop head in the face. It grinds greasy floor muck into your eyes and nose. You pull away and wipe your stinging eyes. Al pulls it back for another strike. 
            *set luck %-5
            *set max_energy %-5
            *set energy %-5
            *set mayonnaise true
            *goto post_sauce
        #Laugh and run for it.
          It's hardly the work of a ${master} of darkness. But you give a maniacal laugh as you flee through the night. Satisfying.

          Fish suppers are probably off the menu for a couple of months at least. You had better go to the supermarket.
          *set luck %+10
          *set humanity +2
          *page_break Next Day
          *goto_scene stageone
    *else 
      Unfortunately the sauce is so thick that it doesn't leave the bottle. You try another couple of waves. Nothing happens. Everybody stares at you.
      *set energy %-10
      *set luck %-5
      *goto post_sauce
  #Wait and see what they do.
    Al eventually sees you. "Oh! Sorry. What can I get for you?"

    His friendly tone is confusing. Now you think about it, you're not quite so sure that the guys behind the counter are all that bad. Maybe it's just the clientele who pick on you. What should you do?

    *choice
      *selectable_if (skeletons > 0) #SKELETON ATTACK
        *goto skeleton_chipper
      *selectable_if (zombies > 0) #ZOMBIE ATTACK
        *goto zombie_chipper
      *selectable_if ((zombies > 0) and (skeletons > 0)) #COMBO ATTACK
        *goto combo_chipper
      #Buy a bag of chips and go home.
        You have enough money in your pocket for a bag of chips. You pay up and receive a warm bag wrapped in brown paper. It is a cold night, after all, and there is something comforting about a hot packet of salty fried potato.

        As you walk, you slip an occasional chip from the bag. Your undead
        *if (minion_count = 1)
          minion slinks
        *comment endif
        *if (minion_count > 1)
          minions slink
        *comment endif
        after you through the dark. You'll just have to find another place to conduct your terrifying campaign of revenge. You can think about it tomorrow.
        *set humanity +2
        *set luck %+10
        *set max_energy %+5
        *page_break Next Day
        *goto_scene stageone

*comment *****************************************************************
*label combo_chipper

*set zcommit zombies
*set scommit skeletons
*set energy %-50

It's like a horror film shot by a really good action movie director. Skeleton legs spring through the front window; zombie arms thrust through the back door. There are flying fragments of glass, flying pizza boxes, flying frozen mushrooms. Everything seems in slow-motion, and you feel a dark thrill at the power you've deployed.

*if (luck < 35)
  Unfortunately the boy lurches against you as he flees and cracks your head against the wall. Ow!
  *set energy %-25
*comment endif

You blink, and both of the chip shop guys are on the floor. That was easy.

*set luck %+10
*set control %+5
*page_break
*goto chippy_victory

*comment *****************************************************************
*label chippy_defeat

You feel the link with your minion drop. It's like a light going out; a sickly, greenish light inside your brain. You're startled by a sudden, overwhelming feeling of sadness.

Any moment now, Al and Rick are going to come outside and start looking around. You slink off into the night, exhausted.

*set control %+5
*set max_energy %+5

*if (zcommit > 0)
  *set zombies -1
  *set minion_count -1
  *page_break
  *goto chippy_fail
*else
  *set skeletons -1
  *set minion_count -1
  *page_break
  *goto chippy_fail

*comment *****************************************************************
*label chippy_fail

*if (zombies = 0) and (skeletons = 0)
  You have no minions left. Your career as a necromancer has ended early, in a fish and chip shop. Besides the risk of being arrested or killed, you can never show your face around town again because of the embarrassment.

  *page_break
  *goto_scene exile
*comment endif

*if (energy > 32)
  *set max_energy %+5
*comment endif

*if (minion_count = 1)
  Back home, you collapse onto the sofa and watch bad television. Your solitary minion slumps to the floor and leans against the cushions at an awkward angle. This companionship is a little comforting, like some macabre variant of a cat in your lap.

  Your mission of revenge against the fish and chip shop has ended in failure. It could be that they were simply too well-equipped, but perhaps you need to revise your tactics.
  *page_break Next Day
  *goto_scene stageone
*else 
  Back home, you slump onto the sofa and watch bad television. The remaining undead seem infected by your mood and hang around the lounge like party guests who have outstayed their welcome. Soon enough, you shut off the TV and go to bed.

  Your mission of revenge against the fish and chip shop has ended in failure. It could be that they were simply too well-equipped, but perhaps you need to revise your tactics.
  *page_break Next Day
  *goto_scene stageone

*comment *****************************************************************
*label chippy_victory

*if (energy > 32)
  *set max_energy %+10
*comment endif

You enter behind the counter and stare down at the helpless staff. One side of Rick's hair sticks straight up, gleaming with fryer oil. Al's face is puffy and confused. The shadow of your minion weaves across them.

"Don't kill us," says Rick. "Please. This was just a temp job for me. I've got things I want to do."

"Why?" Al says. "Why? What did we do?"

*choice
  #Spare them and leave silently.
    They're frightened enough. They will be doing some serious re-evaluation of their lives in the next week or so. You turn away and stalk out into the night, a mysterious figure whose motivations remain ${his} own. 
    *if (minion_count = 1)
      Your minion lingers on for a moment before following you.
      *set humanity +3
      *goto chippy_end
    *else
      One minion lingers on for a moment before following you.
      *set humanity +3
      *goto chippy_end
  #Lecture them, then spare them.
    You offer a list of suggestions for improvements to the business. It covers prices, hygiene, queue discipline, cooking times, condiments available, and exactly what they should do with that crap chippy milk. At first they hang on your every word but after five minutes you can see the surreal nature of the situation is distracting them. Time to go.
    *if (minion_count = 1)
      Your minion lingers on for a moment before following you.
      *set humanity +5
      *set visibility +1
      *goto chippy_end
    *else
      One minion lingers on for a moment before following you.
      *set humanity +5
      *set visibility +1
      *goto chippy_end
  #Kill them.
    You turn away and issue the command. Al and Rick cringe together, then 
    *if (zcommit > 0)
      shriek as zombie teeth tear at their greasy faces. Blood sprays against the fryer and pools on the tiled floor. You head outside and wipe it from your shoes while you wait for the feast to complete.
      *set bodycount +2
      *set corruption +4
      *set chippy_kill true
      *page_break
      *goto raise_attempt
    *else 
      scream as a skeleton lifts the fire extinguisher high above their heads. After five blows, they stop screaming. You head outside and wait for the grisly tenderising to complete.
      *set bodycount +2
      *set corruption +4
      *set chippy_kill true
      *page_break
      *goto raise_attempt
  #Kill them and dump their bodies in the fryer.
    You turn away and issue the command. Al and Rick cringe together, then 
    *if (zcommit > 0)
      shriek as zombie teeth tear at their greasy faces. Blood sprays against the fryer and pools on the tiled floor. You head outside and wipe it from your shoes while you wait for the feast to complete. With a little extra effort, you direct the zombie to plunge the chewed remains into the cooking oil. One leg sticks out onto the counter, still wearing a grubby, white training shoe. Al appears to have been wearing a wig. It floats on top of the oil, sizzling.
      *set bodycount +2
      *set corruption +6
      *set fryer true
      *set chippy_kill true
      *page_break
      *goto raise_attempt
    *else 
      scream as a skeleton lifts the fire extinguisher high above their heads. After five blows, they stop screaming. You head outside and wait for the grisly tenderising to complete. It's not hard to direct the skeleton to plunge their battered bodies into the cooking oil. One leg sticks out on the counter, still wearing a grubby, white training shoe. Al appears to have been wearing a wig. It floats on top of the oil, sizzling.
      *set bodycount +2
      *set corruption +6
      *set fryer true
      *set chippy_kill true
      *page_break
      *goto raise_attempt

*comment *****************************************************************
*label raise_attempt

Looking at your horde, you realise you may need more of them in time. Could you recruit from the recent dead? Al and Rick are less-than-perfect specimens, but then, you've never seen a zombie win a beauty contest.

On the other hand, all of this undead control has tired you, and maybe you ought to get some distance from the scene of the crime.

*choice
  #Try to reanimate Al and Rick through force of will.
    You confront the corpses in the chip shop and grip the humerus in both hands. Channelling your will as best you can, you pull at their limbs. The key is to move one, then another. The entire body will follow.

    The moment stretches on as you reach through the veil of death.

    *if (fryer)
      *label hot_oil
      Nothing. The oil sputters and one leg sinks a little further in. Perhaps you shouldn't have deep-fried the bodies before attempting to recruit them.

      Still, that doesn't negate your achievement here. You have a feeling that somebody is watching as you leave the chip shop, but nobody is visible.

      *set control %-5
      *set luck %-5
      *set visibility +2
      *goto chippy_end
    *elseif (control < 46)
      Nothing. You might have felt a little tickle or it might have been your imagination. Perhaps this will work once you have more experience. 
      
      As you leave the chip shop, you have a feeling that somebody is watching but you can't see anybody.
      *set control %+10
      *set luck %-5
      *set visibility +2
      *goto chippy_end
    *else
      Rick's arm twitches. It knocks against the fryer a couple of times. Then his legs move in a scissor action. Animation seems to return to his broken body and it claws its way upright. You feel control flood into you from the bone.

      His face is none too pretty, with a massive dent in the skull which squeezes that eyeball out towards you. Still, you don't need him to be pretty, just obedient.

      *set luck %+10
      *set max_energy %+5
      *set energy %+5
      *set visibility +2
      *set zombies +1
      *set minion_count +1
      *set corruption +2
      *if (raised = false)
        *achieve raise
      *comment endif
      *set raised true
      *goto chippy_end

  #Try to reanimate Al and Rick through empathy. 
    You approach the corpses in the chip shop and grip the humerus in both hands. You try to relate to them as human beings.

    Al was smitten by that orange-skinned woman who liked to skip the queue. Rick clearly had some kind of personal inadequacy or he would never have grown a moustache like that. You reach out to those characteristics through the veil of death.

    *if (fryer)
      *goto hot_oil
    *elseif (energy < 39)
      Nothing. You might have felt a little tickle or it might have been your imagination. Perhaps this would work if you weren't so tired.

      As you leave the chip shop, you have a feeling that somebody is watching but you can't see anybody.

      *set max_energy %+10
      *set luck %-5
      *set visibility +2
      *goto chippy_end
    *else
      Rick's body shudders on the floor. The jaw drops open then cracks closed. This motion repeats three times with such violence that he would surely need dental care were he not dead. Then Rick stands up.

      It's an eerie sight. The mustachioed corpse seems at ease despite its shattered nose and the damp organs spilling from its torn side. It waits for instructions.

      *set luck %+10
      *set control %+5
      *set visibility +2
      *set zombies +1
      *set minion_count	+1
      *set corruption +2
      *if (raised = false)
        *achieve raise
      *comment endif
      *set raised true
      *goto chippy_end

  #Make a clean getaway.
    Your undead horde follows as you slip away through the gloom.
 
    *set luck %+5
    *goto chippy_end

*comment *****************************************************************
*label chippy_end

You head home, new purpose in your stride. $!{town} will have to take you seriously now. It's only later, in front of the TV, that you wonder if you did the right thing at the end. 

…Time will tell.

*page_break Next Day
*goto_scene stageone