*temp helotchoice 0
*temp aristochoice 0
*temp bredgender 0
*rand bredgender 1 2
*temp tick 0
*temp ruthless 0
*temp relig 0
*temp shayard 0
*temp cosmop 0
*temp bloodloot 0
*temp bredkiss 0
*temp harrowpinion 0
*temp proselyt 0
*temp helotrefuse false
*temp overseer 0
*temp rebelrebel 0
*temp secondthoughts 0
*temp questions 0
*temp rageluck 0
*rand rageluck 0 15
*temp sicem false
*temp allessfood false
*text_image chap1.png center Chapter One: The Fourth Harrowing

It is a cool, cloudy afternoon, but the hundreds of people in the town square are sweating as if it were the height of summer.  Two dozen club-wielding Alastors have gathered the helots from the fields, disregarding the needs of the barley harvest.  The yeomanry, tradesfolk, and lesser gentry are under no compulsion to attend the Harrowing, but a few of them are present regardless, shifting nervously at the edge of the crowd.

The two Theurges stand in the middle of the agora, dressed in their customary long black coats and iron diadems.  Under their coats, bandoliers with dozens of crimson phials are barely visible.  Rim Square is too small a town to need a permanent Harrower, so the magi have brought their own: an eight-wheeled platform bearing a polished monstrosity of gears, hooks, blades, pipes, and urns.  The machine's oily, coppery smell faintly pervades the square.

The news of the Harrowing reached you an hour ago, at your house.  
*if aristo
  One of your aristarch cousins from House Keriatou mentioned it as an irritating disruption to the afternoon's hunt; there would be no helot beaters to scare the game out of the brush and into bow range.  You waited impatiently for her to take her leave, then informed your father that you were going down to the square.
*if helot
  You couldn't believe it, but the priests' cry was unmistakable: "To the agora!  To the agora for the blessed sacrifice."  You and your father came down early, well before the Alastors started rounding up stragglers; you didn't want to risk a cracked skull or worse.
Now he and you stand in the middle of the crowd, waiting for the rite to begin.
*page_break
*if helot
  *set kuria "Captain"
  *set milady "Captain"
  "Is my memory failing already, or is this the fourth Harrowing we've had this year?"  Your father's growl is as raspy as his sun-scarred skin, but it trembles on the word "fourth," just enough for you to notice.  "I reckon They've come to an exaggerated idea of just how fast we breed."
  
  You remember the first Harrowing you saw as a child, all those years ago, before you learned to hear fear in your father's voice.  He ordered you to stand quietly, no matter what happened, no matter whom the Theurges fed to the machine.  And you did, wide-eyed and swallowing bile, as you have every time since.
  
  "It's the fourth," you confirm bleakly, your eyes scanning the crowd.  "The Wards must be thirstier than usual.  Or maybe our Keriatou masters decided they wanted to try for seven harvests this year."
  
  "Bleeding Angels, don't get cheeky about the aristarchs now, of all times."  Your father's head snaps around to catch you in mid-scan.  "Who you looking for out there?"
  
  You try not to look startled, but the suspicious note in his voice has taken you by surprise.
  *fake_choice
    #"Aunt Joana, of course."  The old woman is very dear to me, if not to my father.
      You don't have to fake the concern in your voice.  Old Joana Orchard may not be a blood relation, or even belong to the same estate as you, but she's one of the few who will still take the time to warmly reminisce about your mother.  If she were taken in a Harrowing, you'd lose not only an honorary aunt but much of the tinder for your own memories.

      Your father snorts; Joana's warmth toward you is equalled by her asperity toward him. "You gone blind, ${girl}?  There she is, in plain view.
    #"What difference does it make to you?"
      Your sullen tone sets your father scowling.  "Think I won't thrash you at a Harrowing, ${girl}? Just wait till I get you home.
    #"No one, especially."
      You gesture around you.  "Just making sure none of our cousins missed the Summons."
  
      "They're all here as far as I can see.  
  Hush now—the Ecclesiast is about to begin speaking, and you don't want to catch his eye."
  *goto uneasy
*if aristo
  "Why exactly were you in such a hurry to come down here?"  Your father's voice is on edge; he's plainly uncomfortable with your choice to stand among the helots.  "You'd think you'd never seen a Harrowing before."
  
  "They don't usually have four in a single year, do they?" you counter, scouring the crowd with your eyes.  "Why do you suppose they're so bloodthirsty this season?  Perhaps they're stocking up for a new campaign to push the border out into the Xaos-lands."
  
  Your father's lips tighten.  "That's no business of ours—unless and until Archon Leilatou requires our aid.  And you should watch your language, ${girl}."  His stare grows sharp as he regards you.  "Which helot exactly are you searching for?"
  
  You try not to look startled, but the accusatory note in his voice has taken you by surprise.  You say:
  *fake_choice
    #"Joana, naturally." The aging helot who maintains my family's groves is very dear to me, if not to my father.
      You don't have to feign the concern in your voice.  For many years now, you've felt stomach-sick during every Harrowing, fearing that Joana Orchard would be one of the sacrificed.  The helot elder is one of the few people who will still freely reminisce with you about your mother, who treated Joana more like an aunt than a field servant.

      Your father scowls.  "There's nothing natural about the bond you've formed with that froward helot, ${girl}.  And look, there she is in plain view."
    #"Why on earth would I be looking for a helot?"
      Your mildly contemptuous riposte catches your father off guard.  "Well, damned if I know, ${girl}.  You seemed to be giving them your full attention."

      You shrug.  "Aren't you the one who says we have to keep an eye on them, and both eyes in a bad year?  I'd have thought that with a fourth Harrowing, this one qualifies."

      "Hmph. No need to make it so plain. Especially at a Harrowing."
    #"I'm not looking for anyone."
      You gesture down to the assembled helotry, in their gray ragged garb.  "Just trying to imagine what they think about the frequency of Harrowings."

      "Another question unworthy of your attention or mine," your father mutters in disgust.
*label uneasy

You meet his eyes for a moment, and uneasily decide that he's probably still ignorant of your secret.  Fond as you are of her, it's not Old Joana who's set your nerves afire today.  It's a helot you've known for barely half a year.  You're hunting for Breden.
*page_break You Remember
*text_image 1_spring.png center SPRING
*if helot
  [b]It was the morning after[/b] Angelday, with the normal order of things beginning gently to reassert itself.  The Keriatou's hired overseers lay bloated, squinting, and indulgent by the stream; the fifty-odd field helots were scarcely less relaxed, enjoying the unaccustomed feeling of full bellies and the slowly dissipating fog of barleywine.  Occasionally a handful of you would take the restive ox-team on a circuit of the great field, but everyone tacitly accepted that the real spring plowing would only begin tomorrow.  

  You had found your way into a group centered around Terret Abler, who was demonstrating how to weave reeds into a hat resembling an Alastor's tall helmet.  "By the end of the day," he was chuckling, "we can have all the oxen wearing these…."
  
  Then you glimpsed a rapidly growing knot of people, with nothing left of Angelday in their stance or the tone of their murmurs.  They were listening intently to a young helot you'd never seen before.  "…His wife was Harrowed two years back," you heard as you approached.  "So his body went to the t'Pelematou elders.  Or what they said was the body, anyway."
  
  Hetten Halt-Hand looked away, his haggard cheeks wrenched with emotion.  "Ah, Xthonos.  They bury him yet?"
  
  "Tomorrow.  The elders of the Pelematou estate have called a wake."
  
  "What, on a plow day?" Gillian Adze glanced around, incredulous.  "You think the overseers will agree to that?"
  
  "You think they can stop us?" the stranger demanded hotly, spurring gasps from all sides.  "Yes, damn their eyes, they'll agree if they know what's good for them.  They know what can happen after a death as ugly as this.  Now's a time for telling, not for asking."
  
  Staring down at the bold young helot, still unsure what was going on, you were struck by…
  *choice
    #…how attractive he was. It wasn't just his lean, strong frame, but his confident stance and voice.
      *label bredmale
      *set xhe "he"
      *set xhis "his"
      *set xhim "him"
      *set xhers "his"
      *set xkuria "kurios"
      *set xmilady "milord"
      *set xgirl "boy"
      *set xsister "brother"
      *set femalepref false
      *set malepref true
      *set zhe "she"
      *set zhis "her"
      *set zhim "her"
      *set zhers "hers"
      *set zkuria "kuria"
      *set zmilady "milady"
      *set zgirl "girl"
      *set zsister "sister"
      *goto overseer
    #…how attractive she was. It wasn't just her lean, strong frame, but her confident stance and voice.
      *goto overseer
    #…the odd spark in so many others' eyes as they looked at this newcomer.  I can usually recognize the signs of desire, though it's not an emotion I've ever felt myself.
      *set acepref true
      After several confused years, you realized that the "lust" that both Ecclesiast Zebed and your fellow young helots spent so much time talking about was a feeling you'd simply never had.  What tends to inspire it remains a bit of a mystery to you, but when you see more than a handful of people take on a certain look of giddy, heightened attention, you can guess what's going on.
      
      Though you were unmoved by whatever the rest were feeling, this newcomer interested you because…
      *choice
        #…she seemed extraordinarily confident, almost magnetic. I wanted to get to know her better.
          *goto overseer
        #…he seemed extraordinarily confident, almost magnetic. I wanted to get to know him better.
          *goto bredmale
        #…anyone who could walk into a crowd of near-strangers and hold them spellbound was someone to keep an eye on.
          *if bredgender = 1
            *goto bredmale
          *goto overseer
*if aristo
  [b]Wind and hoofbeats blurred[/b] Calea Keriatou's words as the two of you picked up speed through the river groves.  She had invited you to ride up to the Grosemere with her, her brother Hector, and two of their retainers.  The chill rains of winter were past, your aristarch cousins had new falcons, and they were keen to see what northward-bound birds they could bring down.

  As you leaned toward Calea to hear better, you glimpsed Breden for the first time—a ragged silhouette springing out in front of you, waving and shouting inaudibly.  You jolted upright in the stirrups and hauled back on your reins with a wordless yelp of warning.  When the dust cleared, you and Calea were barely a yard from the importunate helot.
  
  "Of all the…did you want us to ride you down?" Calea gasped, fingers clenched around her riding whip.  You could see the pulse in her throat, hammering as hard as your own.
  
  "No, kurioi—to warn you."  Breden's reply was quick and disarmingly cordial, the tone of someone reasoning with a friend.  It held virtually none of the deference you'd all been raised to expect.  "The road is flooded a mile up; they say it's dangerous even for horses.  If you're riding east, best to turn off here for the bridge."
  
  Exchanging glances with your cousins, you could see that none of you had met this helot before—nor indeed any chattel with anything like the same poise.
  *choice
    #I was taken aback by how attractive he was. Lean and sun-parched, of course, but his smile and confident stance were strangely charming.
      *set malepref true
      *label bredmale2
      *set femalepref false
      *set xhe "he"
      *set xhis "his"
      *set xhim "him"
      *set xhers "his"
      *set xkuria "kurios"
      *set xmilady "milord"
      *set xgirl "boy"
      *set zhe "she"
      *set zhis "her"
      *set zhim "her"
      *set zhers "hers"
      *set zkuria "kuria"
      *set zmilady "milady"
      *set zgirl "girl"
      *goto memchat
    #I was taken aback by how attractive she was. Lean and sun-parched, of course, but her smile and confident stance were strangely charming.
      *goto memchat
    #When I glanced at cousin Hector, I was only half-surprised to recognize desire for the helot in his eyes. It's not an emotion I've ever felt myself, but I've learned to see it in others.
      *set acepref true
      It had taken several confused years before you concluded that the "lust" that so engrossed both Ecclesiast Zebed and your fellow young nobles was a feeling remote from your own experience.  You still struggle to grasp what tends to inspire it—terribly arbitrary, as far as you can tell—but you know it when you see it, certainly with your Keriatou cousins.
      
      Even though you didn't share Hector's fancy, this helot held your eye because…
      *choice
        #…her confidence was magnetic. I wanted to get to know her better.
          *goto memchat
        #…his confidence was magnetic. I wanted to get to know him better.
          *goto bredmale2
        #…I was curious as to what could inspire such improbable self-assurance.
          *if bredgender = 1
            *goto bredmale2
          *goto memchat
*label overseer
"Strong words," Hetten Halt-hand said pensively.  "You going to talk so strong to their faces, Breden?  'Cause they've seen us."  His finger indicated two overseers striding up the field, willow switches in hand and scowls clear from twenty yards off.

"They'll hear stronger words than what I've said to you.  Any of you willing to stand alongside me?"  Breden's blazing eyes were even more challenging than ${xhis} voice.
*choice
  #I immediately stepped to ${xhis} side.
    *label mutterdisapp
    *set overseer 1
    Gillian and the rest muttered in disapproval, but not surprise; you had a reputation for actions and questions that risked angering the overseers.  [i]Begging the willow[/i], people called it, and [i]baiting the Harrower[/i]…but so far, you'd lost more skin and blood to your father's beatings than to your masters'.
  
    When it became clear that no other Keriatou helot was going to join you, Breden grinned broadly.  "Right.  Two should be enough to see them off."  $!{xhe} set off down the field with you at ${xhis} left hand.
    *goto overchat
  #"Tell them what?  What's happened?"  However little I knew, I found myself keen to join ${xhim}.
    "No time to tell it over again, ${sister}. We need to walk out to meet them."  Breden raised one eyebrow at you. "Coming?"
  
    "Xthonos."  You stared at ${xhim} for a moment, then laughed and walked to ${xhis} side.  "For whatever it's worth.  You'd best do the talking, though."
  
    *goto mutterdisapp
  #I glanced about uncertainly to see if anyone else would join ${xhim}.
    *goto notasoul
  #I held back silently.  I'd seen the overseers flog the living skin off helots for less insolence than Breden was promising to show.
    *label notasoul
    *set rebelrebel -1
    Not a soul volunteered to join the brash outsider.  "So, what happened to Olen hasn't put the anger into any of you?" Breden said curtly.  $!{xhis} eyes lingered on you for an unexpected and unwelcome moment.  "So it is.  Just stand firm here until I'm done with them."  $!{xhe} stalked away; you felt an unaccustomed heat in your cheeks and neck.
    *goto overchat
*label overchat

The lead overseer's lips peeled back from his teeth as he watched
*if rebelrebel = 0
  you and
Breden approach.  His savage squint spoke of a hangover, but his whip hand was steady.  "You're not one of ours, ${xgirl}.  Tell me your name.  And why I shouldn't take your lazy hide for coming down here and raising Xaos on a plow day."
*if rebelrebel = 0
  He jabbed a finger in your direction.  "Yours too, for being a dirty little shirk."

"Willow branches?" Breden replied coolly.  $!{xhis} tone ignited an unfamiliar thrill in you; you'd never heard anyone address an overseer with such open contempt before.  "You want to take someone's hide, man, you use threshing flails.  Like they just did on Olen Stonehewer.  That's how you skin a helot right down to the Angelforsaken bone."

The foreman loomed over the helot, raising his whip-switch in an abrupt but unfulfilled threat.  "What are you jawing about, you insolent turd?"
*page_break
"Olen Stonehewer was beaten to death in front of his children on Angelday," Breden said, voice pitched to carry out to the orchards.  "The trader came to collect his girls at the end of the ceremony—and Big Olen hadn't known.  No idea that the Pelematou had sold them to a new House out east.  He started begging to keep them or be sent with them.  And his pleas were so wretched, they upset kuria Pelematou's little daughter."

"Now you just watch your tongue, ${xgirl}," the other overseer barked, glancing at the fifty-odd helots around him.

"Poor child wouldn't stop sobbing…started pleading with her lady mother and making a great scene.  In the end, she worked herself up so hard, she fell frothing on the floor."  Breden's lips vanished briefly into a thin, dark line.  "So Olen and his daughters were dragged out back, and he was beaten with threshing flails until those who loved him most couldn't tell him from butchers' wares."  

A whisper swept the field, as every remaining Keriatou helot heard and reacted to Breden's news.  Your own face showed no emotion…
*fake_choice
  #…but I felt the tears sparking behind my eyes.  Big Olen had been the most amiable and gentle of men, and his eldest daughter was barely eleven.
  #…because I felt none.  This death was uglier than most, but I'd seen too many to be moved.
  #…but behind it my hatred blazed up, fresh-fueled.
Breden stared down the silent overseers for a few moments more, then concluded, "His wake's tomorrow.  I was sent to pass on the word."

"Tomorrow?"  The beefy man began to laugh, then cut it off in mid-gust; his unease sounded too clear even to him.  He glowered back at the stream, where the remaining overseers were scrambling to their feet and grabbing their sticks.  "Tomorrow, every worthless sod in this field will be steering a plow to make up for all this lazing about.  And you'll be, too, or your master will know the reason.  Are you t'Pelematou, then, or does some other House own you?"

Again, Breden simply ignored the demand for a name.  "Tomorrow afternoon, every helot in this field will be behind a plow.  Tomorrow morning, every helot in and around this town will be sending off Olen Stonehewer.  It is what it is."

*if rebelrebel = 0
  Seeing the fury boiling in the foreman's eyes, you spoke up:
  *fake_choice
    #"Only way to forget a bad death is to have a good wake."
      The foreman blinked in surprise, then yelled, "Xaos eat you, ${girl}, you'll forget what we tell you to forget!"  His long willow whip lashed down twice.  "What kind of damned cheek…a bad death?  You want to know what a bad death is, you keep talking like some rebel.  I'll see every misbegotten one of you pining for the Harrower!"

      You ignored his bluster, like you ignored the blaze of pain along your arm and shoulder; you'd taken worse switchings for failing to plow straight enough.  "Good man can't get a good death, he at least deserves a good wake.  And every soul here knows Olen was a good man."

      "Good helot, maybe.  Not an immodest little shit like you."  Some of the big man's rage seemed to have dissipated.
    #"As when you gave us a day to mourn Elder Jorce."
      The foreman snapped his head round to squint suspiciously at you.  "That wasn't no plow day, and this t'Pelematou was no elder."

      "We're not asking a full day this time, either.  Just a morning.  Send off a good man who died an ugly death."  You kept your voice level and reasonable.

      "Doesn't seem to me you've been asking at all, you immodest little shits."  The big man sounded ever so slightly mollified.
    #"We'll make up the plowing, as late as we must.  No one will know."
      "No, because it's not going to swiving happen," the foreman snarled back at you, raising his long willow whip. "Who by Xaos do you think you are, trying to tell us how things will go on our patch?"
    
      You'd taken enough beatings not to flinch or turn away when the switch lashed down.  "We know our duty.  To Olen Stonehewer as well as to our masters.  We'll make sure we meet both, tomorrow."
    
      "Angels.  Too dull to learn from a whipping, are you?" The big man's voice was just as angry, but held a slight tremor that hadn't been there before.
"You truly think we'll give you a free half-day to, to…run off, drink yourselves blind, talk sedition?"

Breden shook ${xhis} head sharply.  "No time for any of that, overseer.  There's a lot of mourning to be done, and only a few hours to do it in."

"Well…we'll just see what the glorious Keriatou have to say about that!  Their helots asking leave to run off and mourn, on a plow day.  The Alastors won't find that too damned funny, either."  The foreman laughed, a bit shrilly, and stalked back toward the stream.  When he met the other overseers halfway, he unleashed a stream of oaths and went after them with his switch.  "…Next time you see 'em starting to argue, you get off your blasted arses double-quick…." you heard in between yelps and curses.
*page_break
"They'll never tell no Keriatou," Hetten Halt-hand observed equably as
*if rebelrebel = 0
  you and
Breden rejoined the group,  "let alone no Alastor.  They want the masters involved in this even less than we do."

Everyone had been braced for an [i]I told you so[/i], but there was no trace of smugness in Breden's face or voice—just the same assurance and intensity that had seen off the foreman. "You can expect a ready switch when you get back for the plowing."

"Don't expect we'll notice the difference," Gillian said gruffly.  "So where's Olen's wake to be?"

"I'm told his people have a burying-place up the river a ways, close to Callow's Pool…."  The young helot sounded suddenly uncertain.

"Collow's Pool.  Yes, we know it," you told ${xhim}, wondering how recently ${xhe}'d been sold here.  You'd been up to the t'Pelematou helotyard many times after Harrowings, to lay to rest what the machine left behind.

"Good.  But a couple of us will need to stand watch on the river road—tell the nobles some story to send them over the bridge.  Would you join me…?"  $!{xhe} paused, clearly waiting for your name.
*goto helname

*label memchat
Your baffled-looking Keriatou cousins nudged their horses forward to circle Breden.  "Should we thank you or whip you?" Hector laughed.  "You've got some cheek for a field hand.  What's your name, ${xgirl}?"

"Breden, aristarchos," said the young helot.  $!{xhis} deep genuflection was impeccably humble, and took ${xhim} below easy reach.  "Of the de Rose estate."

"So you do know who we are,"  Calea sniffed, lowering the crop.  "Is that why you threw yourself in front of our horses?"

Breden remained bowed to the dust, but ${xhis} voice held a smile and the barest hint of insolence.  "The Canon is very clear that we have the duty of self-sacrifice, mighty kuria.  I'd have thrown myself under your cousin's horse just as eagerly had ${he} been alone."

"Oh?  You know who ${he} is too?"

You felt your temper flare at Calea's affected tone of surprise.  Her and Hector's kermes-dyed riding capes identify them as Keriatou to anyone with eyes, as does the ram crest worked into their saddlery.  To forfend any more mockery, you cut in, "My name is…" at the same time that Breden said, "That's ${kuria}…"
*choice
  *if female
    #Thekla.
      *set fname "Thekla"
      *goto a_lname
    #Alkyone.
      *set fname "Alkyone"
      *goto a_lname
    #Karme.
      *set fname "Karme"
      *goto a_lname
  *if male
    #Iasoun.
      *set fname "Iasoun"
      *goto a_lname
    #Taras.
      *set fname "Taras"
      *goto a_lname
    #Kadmos.
      *set fname "Kadmos"
      *goto a_lname
  #Our family didn't adopt Karagond names, we stayed with the old ways.
    *set natlreal %+5
    *set natl %+5
    Your parents named you:
    *choice
      *if female
        #Peryn.
          *set fname "Peryn"
          *goto a_lname
        #Alya.
          *set fname "Alya"
          *goto a_lname
        #Esme.
          *set fname "Esme"
          *goto a_lname
      *if male
        #Peryn.
          *set fname "Peryn"
          *goto a_lname
        #Hugh.
          *set fname "Hugh"
          *goto a_lname
        #Reynard.
          *set fname "Reynard"
          *goto a_lname
      *if not(choice_randomtest)
        #Choose a better name.   
          You are called:
          *input_text fname
          *goto a_lname
  *if not(choice_randomtest)
    #Choose a different name.
      You are called:
      *input_text fname
      *goto a_lname
*label a_lname
And your family name:
*choice
  #Katenatou.
    *set lname "Katenatou"
    *goto hector
  #Mikilatou.
    *set lname "Mikilatou"
    *goto hector
  #Our family was noble before the Conquest, and we did not take a Karagond family name.
    *set natlreal %+5
    *set natl %+5
    *set cred_a +5
    *set cred_y +5
    Your family name, after the old Shayarin style, was:
    *choice
      #de Eramant.
        *set lname "de Eramant"
        *goto hector
      *if fname != "Peryn"
        #de Serin.
          *set lname "de Serin"
          *goto hector
      *if fname = "Peryn"
        #de Sorel.
          *set lname "de Sorel"
          *goto hector
      *if not(choice_randomtest)
        #Choose a name.
          Your family are known as:
          *input_text lname
          *goto hector
  *if not(choice_randomtest)
    #Choose a name.
      Your family are known as:
      *input_text lname
      *goto hector
*label helname
*choice
  *if female
    #Callen.
      *set fname "Callen"
      *goto h_lname
    #Ronia.
      *set fname "Ronia"
      *goto h_lname
    #Tara.
      *set fname "Tara"
      *goto h_lname
  *if male
    #Starn.
      *set fname "Starn"
      *goto h_lname
    #Callen.
      *set fname "Callen"
      *goto h_lname
    #Jend.
      *set fname "Jend"
      *goto h_lname
  *if not(choice_randomtest)
    #Choose a different name.   
      You are called:
      *input_text fname
      *goto h_lname
*label h_lname
And while the nobles will call you t'Keriatou as long as you're owned by the aristarchs' estate, your family name among helots is:
*choice
  #Oakfell.
    *set lname "Oakfell"
    *goto standwatch
  #Thresher.
    *set lname "Thresher"
    *goto standwatch
  *if not(choice_randomtest)
    #Choose a name.
      Your family are known as:
      *input_text lname
      *goto standwatch
*label standwatch
*gosub namecap
"I'm ${fname} ${lname}," you told Breden.  $!{xhis} flash of a smile hinted at recognition, to your surprise; you'd certainly never heard of ${xhim} before that day.  "And yes, I'll serve watch tomorrow."  

You knew your father would be relieved to hear it.  He tried to keep you from anything that might encourage your seditious tendencies, and funerals often got altogether too bitter and honest for his liking.  But it had been a while since you took your turn keeping watch during a helot memorial or celebration—and you were thoroughly intrigued by Breden's boldness.

Thus it happened that the following morning, you met ${xhim} in the river groves, above the bridge crossroad.  You greeted Breden, stood in awkward silence for a few moments, and finally said, "Seemed like you'd heard my name before.  Was I wrong?"

*if rebelrebel < 0
  Instead of replying, ${xhe} asked, "Why didn't you join me yesterday?"—not sounding accusatory, just curious.

  "I'd not yet overheard what had brought you to us.  Not even Olen's name.  And you sounded like you were going to invite them to skin you alive."  You shrugged.  "Which of course you did.  They just didn't take you up on it.  There…does that earn me an answer, or are you going to keep up the same game you played with the foreman?"

Breden grinned.  "The Pelematou helots said that of all the Keriatou gang, you were the least easily cowed—the most likely to talk back to the overseers, if it came to that.
*if rebelrebel < 0
  I'd like to convince you that next time, you can take a risk on me."

  You found your cheeks growing hot again.
*if rebelrebel = 0
  And so it proved."

  You found your mouth curving into a grin as well.
"You're t'Pelematou, then?"

"No, thank Angels."  Breden shook ${xhis} head vehemently.  "The de Rose are gentler on us by far.  But we live close enough—"  $!{xhe} broke off.  "Riders coming.  Remember—the road's flooded upstream."  $!{xhe} stepped into the road, waving ${xhis} arms.

As the four horses thundered to a halt around you, you felt your throat tighten.  Their kermes-colored capes identified the riders even before you saw their faces: Calea and Hector Keriatou, the two oldest children of your masters' household, along with a couple of retainers carrying caged falcons.
*choice
  #I let Breden do the talking.  Nothing good happens to helots who draw the young masters' attention.
    *label heccalchat
    "Of all the…did you want us to ride you down?" kuria Calea gasped, fingers clenched around her riding whip.  You could see the pulse in her throat, hammering as hard as your own.

    "No, kurioi—to warn you."  Breden's reply was quick and disarmingly cordial, the tone of someone reasoning with a friend; ${xhe} nodded up the road, rather than bowing.  "The road is flooded a mile up; they say it's dangerous even for horses.  If you're riding east, best to turn off here for the bridge."

    Kurios Hector's eyebrows shot up at the startling lack of deference in Breden's voice.  "Should we thank you or whip you?  You've got some cheek for a field hand.  What's your name, ${xgirl}?"

    "Breden t'de Rose, aristarchos," said the young helot.  $!{xhis} deep genuflection then was impeccably humble, and took ${xhim} below easy reach.  You dropped to an inch above the dust yourself, hoping to avoid any questions.

    "So you do know who we are."  Calea sniffed, lowering the crop.  "Is that why you threw yourself in front of our horses?"

    "The Canon is very clear that we have the duty of self-sacrifice, kuria."  There was a smile in Breden's voice—and the merest hint of insolence.

    After a long pause, Hector barked out an uncomfortable laugh.  "By all Angels, ${xgirl}, I don't imagine you escape many thrashings from Mikal de Rose! But we'll get more hawking in today thanks to your warning.  My honest thanks."
    *goto backtalk
  #I spoke up, not wanting Breden to think I was afraid.
    *set calea 1
    "Of all the…did you want us to ride you down?" Kuria Calea's fingers clenched around her riding whip.  You could see the pulse in her throat, hammering as hard as your own.

    "Forgive us, kurioi."  You knelt quickly into the dust of the road.  "We would not presume to counsel you, but the road is flooded a mile and a half up.  They say it's dangerous even for horses.  We were told to stand here and give warning."

    "Indeed?" Calea inquired.
    *if male
      An upward glance revealed her squinting through the dust at you with a small, thoughtful smile, and your throat tightened.  You had seen her eye other helots this way.  
    *if female
      She seemed ever so slightly mollified.
    "Then we owe you our thanks for sparing us an hour's fruitless riding.  You look familiar to me, ${girl}.  Are you one of—"
  
    "Oh, you owe us nothing, kuria," Breden cut in from ${xhis} own deep bow.  To another helot, ${xhis} tone would have been disarmingly cordial; addressed to a noble, it was suicidally bold.  "Though it is most gracious of you to say so."

    "What did you say?" kurios Hector asked in disbelief, as Calea simply stared.  You blinked at Breden, scarcely less astonished.

    "Indeed, so deep are House de Rose's debts to yours, aristarchoi, that by all rights I belong to you already."  Far from apologizing, Breden's voice had acquired a note of conspiratorial humor.  "What further service may I render?"

    Moments passed in sharp-edged silence while the stunned young Keriatou weighed their response to Breden's presumption.  Finally, Hector barked out an uncomfortable laugh, and you dared to look up again.  "Go give yourself the thrashing you know you deserve, villain.  Or rather, go say to Mikal de Rose what you just told us, and see how he pays you back for such loyalty!"  Despite himself, a smug grin broke across the lordling's face.  "But I'll take no more time from my hawking to bandy words with a pert helot."
    *goto backtalk
  #I glanced at Breden and put a finger to my lips.  The less either of us said, the better.
    $!{xhe} grinned wryly and returned the gesture—then turned to face the oncoming nobles.
  
    *goto heccalchat
*label backtalk
He wheeled his horse around and made for the bridge.  Calea kept hard eyes on you both for a moment longer, but then followed her brother, retainers in tow.
*page_break
"They talk to aristos like that where you come from?" you asked incredulously as you rose from your knees.

Breden straightened up with you, brushing the dust from ${xhis} hair.  "Like what?"

"Like what!"  You laughed.  "Like you're half as good as they are—good enough to
*if calea = 0
  advise them, 
joke with them.  Just enough humility to keep them from riding their horses over you, and not a hair more."

"That's enough, isn't it?" ${xhe} said, almost breezy enough to be convincing.  "Look, I'd heard enough about those two to take a risk on their good humor.  They like to be surprised…sometimes.  And I wanted them to remember me, not you.  Last thing you need is 
*if female
  their attention."
*if male
  Calea Keriatou's attention, from what I've heard."

*if calea = 1
  You tried to push back your fear that you'd attracted it already.
"As if belonging to the de Rose will protect you?
*if calea = 1
  You knew the truth of your joke, surely?
The Keriatou treat every helot in the Outer Rim as their birthright."  You couldn't help recalling Dann, the first of your young friends to catch Calea's eye.  The overseers had whipped Dann the first time he vanished for a day—then had begun studiously to ignore his absences, avoiding him with both their eyes and their switches.
*fake_choice
  #Despite my father's dire warnings, I hadn't abandoned Dann, even as he lost most of his friends to fear or resentment.
    Dann was grateful, vowing to you that he had never tried nor wanted to attract the kuria's notice.
  #I stayed as far from Dann as I could, not wanting to be caught up in whatever trouble followed.
  #I had no desire to stay friends with a noble's plaything.
    People muttered that Dann had tried to attract the kuria's notice, seeking the lighter duties and luxuries of a pet.
In the last weeks, you had heard the dread thickening his voice, the certainty that the young noblewoman was tiring of him, that soon one of his disappearances would be permanent.  It had ended at a Harrowing where Dann's name was the first called.  All you had been able to feel was a terrible gratitude that yours didn't follow.  From that point, the pattern had recurred too often to be coincidence—and not just with t'Keriatou helots.

Breden spoke softly but vehemently.  "Yes, they're free enough to break Canon when it suits."  $!{xhe} looked down the bridge road, where the haze of their passage was clearing. "As if their lives—and the whole damned, bloodthirsty Hegemony—didn't rest on us ignoring their example."
*page_break
Your heart quickened at once, and your voice sounded breathless in your own ears.  "Xthonos, Breden.  And they say my words are baiting the Harrower.  How have you talked this free and lived this long?"

"All our roads end at a Harrower, ${fname}.  What price should I pay just to put that off by a few more years?"  The slim young helot's eyes shone as they returned to yours.  "And I know who to trust.  I can recognize the anger in others.
*if rebelrebel < 0
  Even if you damp it down with a blanket of caution."

  "No small risk to take on someone you just met,"
*if rebelrebel = 0
  You burn plainly enough for anyone with eyes to see."

  "Not compared to you,"
you mumbled, dizzy with a blend of fear and longing.  All your little rebellions against the overseers seemed like a mere game; Breden's candor hinted at new, intoxicating possibilities.  "Don't know how you can be so sure."

"So I'm wrong."  Breden's sudden expression of dismay was belied by ${xhis} decidedly impish brows.  "You don't hate the Thaumatarchy, then?"

The laugh that burst out of you felt like the first surge from a breached dam.  "I [i]loathe[/i] it."

"Good, but not good enough," Breden pressed on, grave and eager.  "What do you hate most?"

"Bleeding Angels, where to start…"  Ever since 
*if introhlt
  your childhood encounter with the Theurge and his Plektoi, 
*if introrel
  you watched hieros Zebed have his gentler predecessor beaten and
  *if intro_bad = 0
    banished,
  *if intro_bad > 0
    killed,
*if intronat
  you watched the Alastors 
  *if intro_bad = 0
    try to
  kill Carles the jongler for singing the old songs of Shayard,
you've been learning to despise the Karagond Hegemony.  Then it crystallized in your mind, and you blurted it out to Breden:
*goto loathe1
*label hector
*gosub namecap
"…${fname} ${lname}."  Breden's voice overlapped with yours.  When you glanced at ${xhim}, mildly surprised, ${xhe} lowered ${xhis} eyes in modest silence and pointed to the family crest on your sword:
*choice
  #A heron.
    *set crest "heron"
    *goto hecunclau
  #A four-pointed star.
    *set crest "star"
    *goto hecunclau
  #A stag.
    *set crest "stag"
    *goto hecunclau    
  *if not(choice_randomtest)
    #No, it's something else.
      The symbol of House ${lname} is a:
      *input_text crest
      *goto hecunclau
*label hecunclau
To hear your father tell it, the ${lname} ${crest} is older than the Hegemony—but these days there are few enough places where it is displayed outside your home.  You wouldn't have expected some of your noble peers to remember it, let alone a helot.

Hector barked out another uncomfortable laugh.  "By all Angels, ${xgirl}, I don't imagine you escape many thrashings from Mikal de Rose! But we may yet get some falconing in today thanks to your warning.  My honest thanks."  He wheeled his horse around and made for the bridge, one retainer in tow.

You held back, looking at Calea.  "Cousin…forgive me, but the hour that this will add to our journey…I promised my father I'd visit the agora before dusk…."

She waved you away.  "Cousin, cousin.  There's no need to apologize.  I have always understood that you have responsibilities that we do not.  Just return the horse to our grooms when you're done.  As ever."

Trust Calea to work in a public reminder that your family is too poor to maintain its own stable.  When the Keriatou had galloped out of sight, you dismounted and tied their horse to a tree.  "Stand up, ${xgirl}," you called over your shoulder to Breden.  Your anger at your cousins had subsided by the time you walked over to ${xhim}.
*fake_choice
  #"So.  Water enough to sweep away horses, eh?" I offered ${xhim} an artful smile.
  #"I can't help wondering whether you might have exaggerated the peril we'd have faced uproad. Inadvertently, no doubt."
  #"The thing is," I said bluntly, "I think you're lying about the flood."
Breden blinked at you in astonishment, no trace of a smile remaining on ${xhis} face.  You gave ${xhim} a moment, and when no response was forthcoming gently prompted ${xhim}: "I rode two miles upriver this morning.  The water on that road wouldn't wet a child's shins."

"By the Blessed Angels, ${kuria}! Now that I've heard what your eyes have seen, I'd never believe that foolish helot Starn who spoke to me of a flood." Breden's speech slowed markedly, as if struggling to penetrate the mystery of how ${xhe} came to be misled.  "Indeed, now that you mention this, I recall that Starn cannot swim, and fears any moving water.  I was myself a fool to heed anything he said about a river—or indeed any stream larger than a piss-trickle!  I can only repent, and beg your tolerance for my passing on a falsehood unawares, and throw myself on your mercy."  $!{xhe} paused in a cautious half-bow.   When you just watched ${xhim} levelly, ${xhe} ventured: "Would you…would you then have us hail back your noble cousins, the aristarchs?"

Your lips quirked.  "They'll have ridden further from us with every word you added to that little speech.  And if I meant to spare them the long ride, I'd have spoken before they left.  So tell me, Breden t'de Rose…if I rode up the river, would I meet your friend Starn, who said the road was dangerous for horses?"

The lean young helot straightened to regard you thoughtfully.  "In truth, there may have been something to that fool's warning, ${kuria} ${fname}.  There's water on the road.  And there's danger."  $!{xhis} voice was toneless, but ${xhis} wary eyes were suddenly aflame.  "You might have heard about Olen Stonehewer?"

You wouldn't have, if you hadn't asked Old Joana why she was looking so miserable a day earlier.  "He's the t'Pelematou helot who…"
*fake_choice
  #"…was punished…"
    "Who was beaten to death in front of his children, ${kuria}." Breden folded ${xhis} arms across ${xhis} chest.
  
    You nodded with visible discomfort.  "Brutally punished, yes.  Because
  #"…died…"
    "Who was beaten to death in front of his children, ${kuria}," Breden corrected you.

    You nodded with visible discomfort; Joana's description had been stomach-turning.  "And it was because
  #"…was killed…"
    "By being beaten to death in front of his children, ${kuria}." Breden folded ${xhis} arms across ${xhis} chest.

    You nodded with visible discomfort; Joana's description had been stomach-turning.  "And it was because
  #"…was brutally slaughtered…"
    "…because 
he didn't want to see his children sold east without him?"

Breden nodded, never taking ${xhis} eyes off yours.  "Their new House's trader tried to collect them at the end of the Angelday ceremony.  Big Olen's pleas were so wretched, they upset kuria Pelematou's daughter.  Poor little child wouldn't stop sobbing…started pleading with her lady mother and making a great scene.  She eventually worked herself up into some kind of fit and fell frothing on the floor."  The young helot's lips disappeared into a thin, dark line.  "So Olen was hauled out back and beaten with threshing flails, until those who loved him most couldn't tell him from butchers' wares.  We're burying him today, up the road.  Save for a few of us on watch, most of the hundred-odd helots from the estates around Rim Square are there now."

"And that's the danger."

$!{xhe} gave a grim shrug.  As when you first met ${xhim}, the deference was gone from ${xhis} voice, and this time it no longer sounded friendly.  "It's a damned poor time for a visit from two young aristarchs who might question the gathering.  Who might well mock.  Who might start something that won't end how they think it will."

You stared at ${xhim}, now completely incredulous at ${xhis} audacity.  "How did you know of me, Breden?"

"I knew all your names within a month of being sold here, ${kuria}," ${xhe} replied gravely.  "All of us do.  You have to know which ones to avoid.  I never heard you were one of those, though."

Your shock was turning into something unfamiliar, unsettling.  "What have you heard of me that…that makes you think you can speak this way to me?"

Breden stepped closer, all intensity and freedom.  "Not a thing, ${kuria} ${fname}.  Not a damned thing.  Only what I've seen in your face in the last few minutes."
*choice
  *selectable_if (not(acepref)) #That was when I kissed ${xhim}.
    *set bredkiss 1
    $!{xhe} jerked away clumsily, eyes gone wide and white with alarm.  "Xthonos, ${kuria}.  I wasn't expecting…"

    "Something so reckless?" You tried to keep your voice light, hiding your chagrin at ${xhis} thoroughgoing dismay. If the wrong person saw you breaking the rules of chastity with a helot, your reputation and marriageability would be destroyed—but you were willing to take that risk. "I thought, based on what I've seen in your face in the last few minutes…"  

    "A little more reckless for me than for you."  Breden didn't step back, but ${xhis} stance recalled a 
    *if xhe = "he"
      buck
    *if xhe = "she"
      doe
    poised to spring into the undergrowth.  "Do you recall what happened to the last helot your cousin Calea enjoyed?"

    "I'm no Keriatou," you snapped, and almost immediately felt embarrassed by your own vehemence.  You recognized the trust draining from ${xhis} eyes, the walls going up.  "Breden…I'm sorry.  Truly I am.  I was just…  
    *goto truststifle
  *if acepref
    #That was when I knew I wanted to be closer to ${xhim} than I'd ever been with anyone else.
      *set bred_heart 2
      Even after coming to maturity, you'd never found the chastity code a burden.  The desire for physical contact about which other young nobles complain so feverishly seems to have passed you by.  But for the first time, staring into Breden's eyes, you found yourself yearning for connection on a level deeper than you've known before.  You want to know ${xhim} and be known, at a depth that has nothing to do with bodies.
    
      [i]With a helot?[/i] "Xthonos,
      *if xhe = "he"
        bo…Breden," 
      *if xhe = "she"
        gi…Breden," 
      you mumbled, as much alarmed as exhilarated by what you were feeling. "That's no small risk to take based on a face-reading.  I've, I've never…"
    
      $!{xhe} smiled but took a step back—perhaps made wary by what ${xhe} was seeing on your face at that moment. "Never what, ${kuria}?"
    
      "Never met anyone like you," you blurted out. "Anyone so brave.
      *goto truststifle
  #That was when I knew I had to see ${xhim} again and keep talking.
    "You've got altogether too much confidence in your face-reading skills,
    *if xhe = "he"
      bo…Breden," 
    *if xhe = "she"
      gi…Breden," 
    you mumbled in disbelief.  "But…Xthonos.  You were right, and I had no idea how much I needed to hear what you've just said."

    Breden tilted ${xhis} head to one side. "What?  The idea that anyone might one day give the Keriatou what they deserve?"

    You looked up sharply with new shock and an undeniable twinge of guilt. "Why? They're my father's cousins.  They've always been—their door has always been open to us."

    "I saw the family love in how they talked to you, ${kuria}."

    "Cousin Calea's just…"  You shook your head with sudden, angry vehemence.  "No.  You're right.  But it's so much more than that.
    *label truststifle
    You've got no reason on earth to trust me—but you did.  And I don't remember the last time I heard someone speak so freely!  We all walk around all day stifling our fires, never talking about the things we hate…."

    "Freely?"  Breden gave a raw laugh.  "Angels, ${kuria} ${fname}.  If what I've said is speaking free by your standards, you nobles really are pickling your tongues.  I can speak a lot more free than that."

    "Go ahead, then," you said hungrily.

    $!{xhe} blinked, then shook ${xhis} head. "No, ${milady}.  Your turn to take a 
    *if bredkiss > 0
      real
    risk.  Tell me just what you hate so much."
    *goto volumeposs
  #I could no longer countenance such barefaced impudence!
    *set breden 2
    *set harrowpinion 1
    "You presume far too much, ${xgirl}!"  Breden's shocking lack of restraint had shaken you, left you desperate to give voice to all you'd been stifling—but such candor was nonetheless outrageous in a helot.  "Having you flogged would be a kindness, if it taught you to guard your tongue before it kills you."

    All expression vanished from Breden's face, and ${xhe} jumped back as if you'd just slapped ${xhim}. "Please forgive me, ${kuria}."

    "Lady Pelematou's excessive actions may well explain your sullenness and madcap language, but can not possibly justify it."  You began to pace, a greater fury building in you than one petty serf—however insolent, however attractive—could possibly inspire. "Damn it, ${xgirl}, this is exactly what the Hegemony wants…the helotry embittered and the commons emboldened against the nobility.  You grumble and conspire, we rebuke you, and none of us dare to speak of the real source of our oppression."

    "The Hegemony, ${kuria}?" Breden ventured, glancing around as if expecting Alastors to jump out of the bushes.

    The helot had dared to speak openly at risk of ${xhis} life; would you be more timid than ${xhe}? At that heady moment, it seemed unthinkable. "Yes, and that bloody tyrant the Thaumatarch."

    "Then pray instruct me, ${kuria}."  A blazing excitement was visible behind ${xhis} stilted humility. "You understand the wrongs of the Hegemony better than we do, I'm sure.  If I'm to go back to my folk and explain this to them…what shall I tell them?  If we're complaining of the wrong things, what should we be complaining about?"
    *label volumeposs
    *page_break
    For a moment, you found yourself choking on the volume of possibilities.  Ever since
    *if introhlt
      your childhood encounter with the Theurge and his Plektoi, 
    *if introrel
      you watched hieros Zebed have his gentler predecessor beaten and
      *if intro_bad = 0
        banished,
      *if intro_bad > 0
        killed,
    *if intronat
      you watched the Alastors
      *if intro_bad = 0
        try to
      kill Carles the jongler for singing the old songs of Shayard,
    you've been learning to despise the Karagond Hegemony.  

    Then it crystallized in your mind, and you
    *if breden = 1
      blurted out to 
    *if breden = 2
      told 
    Breden what you loathe most about the Thaumatarchy:
    *label loathe1
    *choice
      *if (aristo) and (aristochoice = 0)
        #Its brutal disregard for the rights of the nobility and other free folk.
          *gosub aristocomp1
          *goto loathe1
      *if (helotchoice = 0) and (breden = 1)
        #All the ways that helots are treated as less than human—above all the harvest of their blood in the Harrowing.
          *if aristo
            *gosub aristocomp2
            *set tick 1
            *set ruthless -3
            *set cred_h +10
            *goto loathe2
          *gosub helotcomp1
          *goto loathe1
      *if (breden = 2)
        #The unrestrained, excessive violence inflicted by the Hegemony on the helotry and drudges.
          *gosub aristocomp3
          *set tick 1
          *set ruthless -3
          *set cred_h +5
          *set ruthreal %-30
          *goto loathe2
      *if (helotchoice = 1)
        #The Hegemony's terrible brutality to non-helots—for example, the torture and assassination of nobles by Kryptast spies.
          *set ruthless -3
          *gosub helotcomp2
          *set ruthreal %-50
          *set helotchoice 2
          *goto loathe2
      #The Thaumatarch's lack of ruthlessness when it comes to punishing his own corrupt and decadent officials.
        *gosub bothruth
        *set ruthless +1
        *set ruthreal %+50
        *goto loathe2
      #The superstitious nonsense the Ecclesiasts teach to justify the evils of Hegemony.
        *gosub bothskep
        *set skepreal %+50
        *set relig +1
        *goto loathe2
      #The corruption of the true faith of Xthonos by the Karagond priesthood.
        *gosub bothdev
        *set skepreal %-50
        *set relig +1
        *goto loathe2
      #The subjugation of Shayard, my homeland, and its forced assimilation into a foreign empire.
        *gosub bothparoch
        *set natlreal %+50
        *set shayard +1
        *goto loathe2
      #The way the Hegemony reinforces the ethnic divides between its subject peoples—and keeps us cut off from the wisdom and wealth of outside nations.
        *gosub bothcosmo
        *set natlreal %-50
        *set cosmop +1
        *goto loathe2

*label loathe2
*set tick +1
Breden nodded slowly.
*if breden = 1
  "Well and good.  What else?"
*if breden = 2
  "Indeed, ${kuria}.  Is there anything else?"

You plunged straight on to another thing you find nearly as appalling:
*label loathe3
*choice
  *if (aristo) and (aristochoice = 0)
    #The Hegemony's brutal disregard for the rights of the nobility and other free folk.
      *gosub aristocomp1
      *goto loathe3
  *if (helotchoice = 0) and ((tick < 2) and (breden = 1))
    #All the ways that helots are treated as less than human—above all the Harrowing.
      *if aristo
        *gosub aristocomp2
        *set cred_h +5
        *set ruthless -3
        *goto youpass
      *gosub helotcomp1
      *goto loathe3
  *if (tick < 2) and (breden = 2)
    #The unrestrained, excessive violence inflicted by the Hegemony on the helotry and drudges.
      *gosub aristocomp3
      *set ruthless -3
      *set cred_h +5
      *set ruthreal %-20
      *goto youpass
  *if helotchoice = 1
    #The Hegemony's terrible brutality to non-helots—for example, the torture and assassination of nobles by Kryptast spies.
      *gosub helotcomp2
      *set ruthreal %-30
      *goto youpass
  *if ruthless < 1
    #The Thaumatarch's lack of ruthlessness when it comes to punishing his own corrupt and decadent officials.
      *gosub bothruth
      *set ruthreal %+30
      *goto youpass
  *if relig = 0
    #The superstitious nonsense the Ecclesiasts teach to justify the evils of Hegemony.
      *gosub bothskep
      *set skepreal %+30
      *goto youpass
  *if relig = 0
    #The corruption of the true faith of Xthonos by the Karagond priesthood.
      *gosub bothdev
      *set skepreal %-30
      *goto youpass
  *if shayard = 0
    #The subjugation of Shayard, my homeland, and its forced assimilation into a foreign empire.
      *gosub bothparoch
      *set natlreal %+30
      *goto youpass
  *if cosmop = 0
    #The way the Hegemony's defensive isolationism keeps its subjects cut off from the wisdom and wealth of neighboring kingdoms. 
      *gosub bothcosmo
      *set natlreal %-30
      *goto youpass

*label aristocomp1
You rapidly poured out the litany of injustices that the other local nobles your age usually skirt around in hints and whispers.  "The Karagonds have always treated the ancient rights of the nobility like so much dirt!  Our lands are whittled away; our houses, stables, and barns claimed for garrison;  our goods stolen through ravenous taxation.  They send Kryptasts to live among us in secret and kill us without explanation or appeal.  We live under constant threat of unjust and arbitrary
*if breden = 1
  death…"

  "A bit like the Harrowing," Breden cut in blandly.

  "Yes!  Well…"  You faltered, vividly recalling the day in your ${girl}hood when Joana became Old Joana—when her limp frame was borne back up from the agora by bleak-faced nephews, her hair newly white, her own nail-tracks scarring her face.  You grew up with the fear of a Kryptast stealing you away, but perhaps it doesn't quite compare to watching family members slaughtered like cattle every few months.

  Breden looked on the verge of a dismissive wave of ${xhis} arm.  "$!{kuria}, forgive me…but doesn't it go without saying that a noble will hate the way that the Hegemony treats its nobles?  I'd have thought you more original than that."

  You shook your head, feeling warm blood rise in your cheeks and neck.  "Have it your way, you outrageous disrespecter of persons.  Setting aside the obvious, then…what I hate about the Hegemony is…"
*if breden = 2
  death."  Your heart raced with the joy of finally uttering your unspeakable thoughts aloud.

  "Indeed, ${kuria}," Breden said impassively.  "The helotry are well aware of the Karagonds' abuse of the aristocracy."

  "And unmoved?" you inquired, exhilaration dissipating slightly.  "You're implying that this will not move them to begin complaining against our Hegemonic oppressors, rather than grumbling about the bloody Pelematou."

  "I would not dare, ${kuria}."

  You scowled at ${xhim}. "Very well, you arrant disrespecter of persons.  The next most hateful thing about the Hegemony—a rather distant next, mind you—is…"  
*set aristochoice 1
*return

*label aristocomp2
"That so?" Breden said skeptically.  "I mean, it's good to hear you say so, ${milady}.  But that's truly what a young aristo hates most about the world we live in?"
*choice
  #Of course not, but I'm going to convince ${xhim} that it is.
    You're used to expressing compassion with the helots' plight.  Since Old Joana Orchard was such a precious source of memories and stories of your late mother, you'd spent many an afternoon with her and the other helots of the ${lname} estate. As they guardedly bemoaned the abuses of Alastors and their dread of being Harrowed, you listened with an air of sympathy.
    *choice
      #And some of that sympathy is genuine.
        *if tick = 1
          *set ruthreal %-10
        *if tick = 0
          *set ruthreal %-20
        *set insincere 1
        The life of those born to till the soil and hew wood will inevitably be a hard one.  But it's harder than it has to be; there are too many cruelties, and not enough nobles living up to their responsibility to the lowest orders.  As for the Harrowing, even if it is necessary to keep Xaos at bay, it's undeniably a horrific process.  You can't blame the helots for desperately wishing there were some other way to fuel the Great Border Wards.
        *goto mothertold
      #But I was never particularly moved by their complaints.
        *set insincere 2
        *goto hewwood
      #It wasn't always easy to hide my distaste for the helot bleating.
        *set insincere 3
        *set ruthreal %+15
        Joana, at least, had a tough-mindedness that kept her from whining in the face of hardship.  Some of the other helots were contemptibly immersed in self-pity.
        
        *label hewwood
        The life of those born to till the soil and hew wood will inevitably be a hard one.  The priests assure you that the faithful helotry can look forward to a rich reward in Elysia.  In the meantime, the order of the world depends on them bearing their appointed burdens; if they weren't Harrowed to keep Xaos at bay, someone else would have to be.  You don't see that their lives are that much worse than they have a right to expect.
        *goto mothertold
    *label mothertold

    You looked Breden in the eye and replied with as much conviction as you could muster: "My mother told me that we were called to keep everyone on our lands safe and fed, especially the ones we rely on for our own food and shelter.  That protecting the defenseless was what it meant to be noble."

    Breden looked away with a pained expression.  "I'm sure your mother was a good soul, ${kuria}.  But in my experience, even the good-souled aristocrats 'protect' their helots in much the same way they protect their pigs…."

    "And you think that's how I see you?" you cut in sharply.  "The way my father and other nobles treat you as no better than talking animals?  As if you're just cattle to be bred and sold and worked until the slaughter.  No, Breden.  We're different, but we aren't that far different.  I abhor Harrowing, as you do."
    
    *return
  #Yes: I sincerely care about the helotry.
    *if tick = 1
      *set ruthreal %-30
    *if tick = 0
      *set ruthreal %-40
    You struggled to articulate the reasons.
    *if intro_bad > 9
      For a moment, you felt as if your mouth were about to open and spill out the story of a child's trembling finger pointing in the direction of a Plektoi-ravaged helot.  But the exhilaration of honesty would only carry you so far.
    "My mother told me…she used to say that we had failed our helots.  That we were called to keep everyone on our lands safe and fed, especially the ones we rely on for our own food and shelter.  That protecting the defenseless was what it meant to be noble."

    Breden looked away with a pained expression.  "I'm sure your mother was a good soul, ${kuria}.  But in my experience, even the good-souled aristocrats 'protect' their helots in much the same way they protect their pigs…."

    "Yes!  And that's what I hate," you cut in furiously.  "The way my father and other nobles treat you as no better than talking animals.  As if you're not due the same compassion we'd extend to any other person—just cattle to be bred and sold and worked until the slaughter.  How can they not see that Harrowing is a monstrosity?…"  
    *fake_choice
      #"There must be some way to keep the Wards up and Xaos at bay without murdering thousands of people."
      #"Even if there's no other way to fend off Xaos, I don't care—it's too high a price."
    "All right—I believe you, ${kuria}."
    *return

*label aristocomp3
"Truly, ${kuria}?" Breden once again looked genuinely surprised. "I'd not thought…"

"…That a noble who insists on proper deference could feel any compassion for your ilk?"

"Of course not, ${kuria}," ${xhe} murmured, unconvincing. "I just hadn't thought you'd feel it to be one of the Thaumatarchy's greatest offenses."

"My mother impressed upon me that we were called to keep everyone on our lands safe and fed.  That protecting the helotry was a sign of true nobility."  You couldn't help remembering the time when she used far stronger language: [i]We've failed our helots.  Nobles are obliged to protect the defenseless—not to sacrifice them to protect ourselves![/i]  

Shaking off the memory, you continued: "The cruelties inflicted on you by the Theurges and Alastors are both excessive and needless.  Far from being a part of the proper order of things, they're intended to keep you embittered against your rightful betters, distracting us all with low-level disorder.  And that is an offense against compassion as well as right order."

"And Harrowing, ${kuria}?  Forgive my boldness, but do I understand you that you consider it needless?"  Breden's eyes were wide and intent.  "That there might be some other way to keep Xaos at bay without the slaughter of helots?"
*choice
  #I genuinely suspect that Harrowing is unnecessary.
    *set harrowpinion 0
    "Of course there's some way to keep the Wards up besides butchering helots," you said with some heat.  "The Harrowing is the least defensible of the Thaumatarch's crimes.  It's simply designed to reduce our numbers and keep us locked in fear."

    *return
  #I suspect it's necessary, but there's no reason to tell a helot that.
    *set insincere 2
    "I'm sure there's some way to keep the Wards up besides butchering helots," you said with brisk assurance.  "The Thaumatarch's just not compassionate enough to seek it."

    *return
  #It's probably a necessary cruelty, and I'll tell ${xhim} so.
    *set cred_h -5
    "Compassion itself requires that we not loose Xaos on the world," you said with stern conviction.  
    *if introrel
      You could vividly remember Ecclesiast Olynna's blessings at the sacrifice ceremonies; if someone as compassionate as she accepted it, it was hard to imagine that there was an alternative.
    "I've heard nothing to suggest that Harrowing is anything other than a necessary evil, which we'd all do well to acknowledge."

    *return

*label helotcomp1
Breden nodded, but ${xhis} voice was surprisingly dismissive.  "You ever know a helot who didn't?  Tell me something that actually tells me something, ${lname}."

Fine.  Setting aside the obvious, what you hate about the Hegemony is:
*set helotchoice 1
*return

*label helotcomp2
Breden regarded you with mild, fascinated incredulity.  "You hate what it does to Them?"

At least ${xhe} didn't scoff; most would have.  "I've seen their eyes when a corrupt Alastor threatens to accuse them of blasphemy," you said intensely, without apology.  "Or when a daughter or son is snatched away in the night by the Kryptasts—no explanation, no appeal.  They live with constant fear of death.  Is that so unfamiliar?"

"Yes, it's just like being slaughtered like cattle every few months…." Breden nodded earnestly.  "Oh, no, wait.  It's not much like that at all."

You wanted to lash back at ${xhim}.  "I'm not saying it's Harrowing.  But damn it, Breden, the whole filthy Hegemony is built on fear and murder, not just the bits that weigh on us. Is it wrong to be angry at it all?  To want it all gone, for the nobles and traders as well as us?"

*return

*label bothruth
*if breden <= 1
  "You 
*if breden > 1
  "Forgive me, ${kuria}…but you
think the Hegemony ought to be [i]more[/i] 
*if breden <= 1
  ruthless." Breden's eyebrows were eloquent.
*if breden > 1
  ruthless?" Breden was politely incredulous.

"It's only ruthless to the weak," you retorted with rising anger.  "If you're rich or powerful enough to buy an Alastor, what crime can't you get away with?"  You've heard that a generation ago the Hegemony's law enforcers could actually be relied upon to resolve disputes, uphold the Canon, and punish criminals fairly.  These days, everyone simply tries to avoid the extortionate Alastors as much as possible.  "It makes me sick.  They need to be purged, without mercy, until the last hint of corruption is gone."

*return

*label bothskep
*set oath "rhupos"
*set sweetoath "bloody rhupos"
*if aristo
  *if breden <= 1
    "You're some sort of Nereish skeptic, ${kuria}?" Breden frowned.
  *if breden > 1
    "Is that a form of Nereish skepticism, ${kuria}?" Breden inquired, a slight frown creasing ${xhis} brow.
  
  "Nothing that I think was learned from a Nere."  Except your favorite oath, [i]rhupos[/i]; instead of swearing by Xthonos, the Neres choose to swear by the Karagond word for filth.  "I just can't believe more people don't laugh in the Ecclesiasts' faces.  How transparently self-serving can any religion be?" You
  *if introrel
    remembered hieros Zebed—[i]Compassion is obedience; that is all[/i]—and
  shook your head fiercely.  "If Xthonos or any other Gods exist, they've got nothing to do with the Karagond Canon."
*if helot
  "Sounds like Nereish talk," Breden said, pensive and frowning.  The pallid folk of the northern province were infamous for their rejection of Divinities and Angels. They also gave you your favorite oath, [i]rhupos[/i]; instead of swearing by Xthonos, the Neres choose to swear by the Karagond word for filth.

  "I heard the Nere skeptics the same way you did—through the priests."  Your smile was mirthless.  "I'll never forget when hieros Zebed read, [i]The heretics say, 'The will of Xthonos on any question can be divined simply by asking what answer will benefit the powers and principalities'[/i]…and then he started to stammer and talk very fast, and stopped reading directly from the scroll.  But nothing he said sounded half as true what he'd read.  If Xthonos or any other Gods exist, they've got nothing to do with the Karagond Canon."

*return

*label bothdev
*if breden = 1
  "You don't think the Compassionate Angels actually fight on the side of the Hegemony?" Breden asked, sounding amused.
*if breden = 2
  "So…you are suggesting that the Compassionate Angels do not in fact punish those who oppose the Hegemony, ${kuria}?" Breden asked carefully.

*if introrel
  You would never forget the day when hiera Olynna pointed out that the Canon seemed to be saying two quite different things about compassion.  Over the years, you had come to believe the popular "heresy" that she herself had never openly acknowledged.
*if aristo
  "The Ecclesiasts have rewritten the sacred texts with countless lies to justify the Thaumatarchy."  There was a barely-contained fervor in your voice.  "I trust that Xthonos has stored up vengeance for the oppressors who take Its name in vain."
*if helot
  "Everyone knows the Ecclesiasts rewrote the sacred texts—packing them with lies to justify the Thaumatarchy."  There was a barely-contained fervor in your voice.  "Xthonos has stored up vengeance for the Karagonds and everyone else who takes Its name in vain."

*return

*label bothparoch
"A Shayard${woman} proud and true?" Breden quoted a much-beloved folk song.

*if intronat
  Remembering Carles singing that song in Iarla's wineroom, you didn't smile.
*if aristo 
  "Can you bear the arrogant Karagonds imposing their alien language, faith, and law on our people?"  You couldn't keep the heat out of your voice. "Three hundred years hasn't healed the wound, or made it any more tolerable to be ruled by foreigners.  Shayard for the Shayardenes!"
*if helot
  "The Karagonds brought all our troubles with them."  You couldn't keep the heat out of your voice.  "They turned our people into Ecclesiasts and Alastors, and taught our nobles to treat helots as nothing but meat.  Until Shayard is ruled by Shayardenes, we'll never see justice."

*return

*label bothcosmo
*if breden = 1
  "You feel strongly about…what exactly?" Breden looked puzzled.
*if breden > 1
  "Begging your grace, ${kuria}, but I don't understand.  What exactly is the offense?"

*if intronat
  You remember vividly the night you first heard Carles sing songs and tell tales from other conties and nations—that intoxicating combination of alien and familiar beauties.
*if aristo
  "The Hegemony waves its omphalos flag and calls itself the center of the world.  Meanwhile, they try to keep us provincials shut up in our separate cages, so we can't join up against them…or see how rich the world beyond the Wards really is!"
  *if intronat
    
    *comment endif
  Living only fifty-odd miles from one of the Great Hegemonic Border Wards, you've always felt a magnetic curiosity about the world Outside.  True, crossing the nearest border would likely leave you dead within hours. But the other Wards which hold back civilizations like Halassur or the Abhuman Federation are obviously different.  

  "Shayardenes, Erretsins, Neres, Whends…you don't believe in the differences between us, ${kuria}?" 
  
  You shook your head fiercely.  "Oh, they're there.  But they're made to look vast, to keep us from seeing what all four conties have in common: that the Karagonds are oppressing us!  Same reason they're so defensive about everything outside the Wards.  What if they allowed Abhuman traders out of the Merchants' Pale in Shayard City—what might we be able to learn from them?"
*if helot
  "You ever get hungry to see what's over the next hill, Breden?  And the one after that, and the one after that?  Every step would take you somewhere where folk saw things a bit different, until you came to somewhere they barely thought the same way at all.  A new world."
  
  Unlike so many of your fellow helots, ${xhis} grin held no hint of scorn.  "Well, can't say it was because I had any hunger for it, ${fname}…but I saw a damned lot of hills when I was sold from the Souther Coast up to the Outer Rim.  And folk were different, no question." 
  
  "How much more in another conty?  Or outside the Hegemony—to meet the Abhumans, or even the Halassurqs?"  The impossible thought elates you, as always; you let it hang half-formed in your imagination. "I said as much near an Alastor when I was small.  She almost had my father flogged.  Told him to make sure his ${daughter} understood that there's nothing worth seeing in the other provinces, let alone across a Border Ward.  Barbarians, all of them, who'd be good for nothing but Xaos if it weren't for the Hegemony."
  
  Breden nods in sympathy.  "We've all heard that often enough."
  
  "Keep to your own folk, don't look for anything good from a Nere or a Whend. Just look to Karagon, the glory of the world.  The Angelic omphalos." You spit on the ground. "It's all so we can't join up against them.  So we can't imagine anything but what we see on the nearest hill.  It's made us weak and poor, Breden…so much poorer than we have to be."
  
*return

*label youpass
*if breden = 2
  Breden's face remained guarded, but ${xhis} eyes were ablaze.  "Everything you're saying, ${kuria}…other helots like myself need to hear it."

  "Well, Xthonos, ${xgirl}…tell them!"  Your heart was still beating at three times the normal rate. "You've charm enough to have kept your skin, even with the most upstart tongue in the four
  *if natlreal > 45
    conties.
  *if natlreal <= 45
    archonties.
  Surely you can convince them that their noble masters aren't truly their enemies."

  "Begging your continued mercy on my upstart tongue, ${kuria}…if I tell my folk that a noble was trying to get us talking against the Karagonds, they'll just say I was speaking to a Kryptast."  $!{xhe} continued to study your face with an intensity that left you uncomfortable.
  *fake_choice
    #"You dare to imply that I'm a murdering spy?"
      "Of course not, ${kuria}.  But then, I've heard the truth in your voice and seen the passion on your own face."  Breden spread ${xhis} hands in helplessness.  "Others won't take my word for a thing like that."

      "What are you saying?"
          
    #"Surely Kryptasts have better ways to occupy themselves than entrapping helots in the Outer Rim."
      A wry smile flashed across Breden's face.  "So I've said myself, ${kuria}.  Many a time.  And yet the fear persists."

      "Well…can you do anything to allay it?"
    
    #"A not entirely unreasonable suspicion.  How do you intend to address it?"
  "It would help if a few of them could hear you speak, ${kuria}," the helot suggested tentatively.  "Perhaps some of the young ones, at first.  The bolder ones."
  *choice
    #"How do you propose to make that happen?"  Part of me badly wanted to take ${xhim} up on it.
      "It wouldn't do to bring them straight to you, ${kuria}—they'd be too afraid."  Breden thought for a minute.  "But I could find a safe place and start bringing together a few friends from the different estates in the evenings.  After a few meetings, once they've got into the habit of talking free…you could come, ${kuria}."
      *choice
        #"Very well."
          *set proselyt 2
          At that moment, it felt unthinkable to quench your tongue and swallow again all the things you'd finally been able to speak aloud.  But sharing any of it with your peers would be far too risky.  Precisely because the Hegemony's Kryptast spies wouldn't bother infiltrating a gang of helots, and because the helotry were more malleable by nature, they would be a safer audience.  "Call your friends together, and when you're ready, get word to me."

          Breden beamed.  "Excellent, ${kuria}.  I'll set things in motion."
          *goto bredupstart
        #"Let me think on it."
          *set proselyt 1
          Breden nodded. "Of course, ${kuria}. With your permission, I'll approach you in a month or two, to know your mind."
          *goto bredupstart
        #"Too risky."  I shook my head firmly.
          *goto toorisky
    #"Absolutely not."  It was far too risky.
      *label toorisky
      Breden sighed.  "Very well.  I'll try to convince them regardless."  
      *label bredupstart
      $!{xhe} paused, then bowed to you.  "Your mercy on my upstart tongue…that's a rare thing, ${kuria}.  Many a noble would have seen only a threat in it—not an opportunity for free-talking, or changing others' minds.  Many would have had me flogged, rather than risking a measure of honesty in return."

      You pointed a finger sternly at ${xhim}.  "Don't remind me—I might yet repent of it."  Of course, it was too late…but at that moment, regret was one of the few emotions entirely absent from the roil in your chest.  "Now take that unnatural boldness and put it to its natural use with your fellows."

      Breden nodded, unsmiling.  "I'll go, ${kuria}. My humble thanks.  And 'scapewell,' as we say in the camps.  Escape all ills, until we see each other again."
      *goto sermon
A slow smile spread across Breden's face. "So how is it, then—breaking the silence?  Sharing the rage?"

"Truly?"  You could barely begin to decipher all the shivers going through you.  
*if aristo
  "I'm terrified.  I don't know why I just said all these things to you.  You've got the power to get me killed now, and you're…you're a helot."  You gave a helpless laugh, tears pricking at the edges of your eyes.  "And I feel alive, like I don't remember ever feeling before.  I'm afire.  There's so much more to say, and I don't know how to say it."

  $!{xhe} held out a cautious hand, looking around.  "If you'll keep trying to say it, ${kuria}…and perhaps listen to more talk from me as well…I'll put myself humbly at your service.  But no more talking here in the road, where just anyone can see."  $!{xhe} dropped ${xhis} voice. "Since kurios Mikal lost the hands to keep the dikes in repair, the whole de Rose North Edge has sunk into marsh.  No one passes that way.  Meet me in the stand of alder between the river pond and the outbuildings—a week from today, at the ninth hour."

  "I will," you promised. "Farewell then, for now…."
  *if bredkiss > 0
    For a moment you were tempted to kiss ${xhim} again—but the memory of ${xhis} flare of fear and distrust when you tried before made it easy to resist.

  "Go well, ${kuria}." Breden watched you unreadably from ${xhis} roadside post as you reclaimed your borrowed horse.  Just before you rode off, ${xhe} abruptly said,
  *if ruthless >= 0
    "Where do Harrowings fall on your list of hates, ${kuria}?  Are they there at all?"
    *choice
      #"Of course they are."
        "Hmmmm."  Breden sounded rather unconvinced.
        
        "They're horrific.  Even if blood is needed for the Wards, surely there's some way to get it besides butchering helots."

        "You'd think so," Breden said softly.
        *goto scapewell
      #"They're the vilest crime of the Hegemony."
        Breden's eyebrows shot up.  "So strong, ${kuria}?"
 
        *if breden = 1
          "Butchering helots in their thousands every day?  Putting hatred and terror at the base of all our intercourse?"
        *if breden = 2
          "This butchery makes mock of every noble virtue.  It counts our obligations toward the lesser orders as worthless."
        You shook your head vehemently.  "Should blood be needed for the Xaos-Wards, surely there is a less murderous way to get it."

        "You'd think so," Breden said softly.
        *goto scapewell
      #"They're horrific.  But I've also always heard that they're necessary to save us from Xaos…."
        *set cred_h -20
        *set harrowpinion 1
        "They do say that, don't they?" Breden said softly.

        You felt intensely uncomfortable, but you weren't about to start dissembling with ${xhim} now.  "I don't pretend to know the truth of the matter.  Until I do, all my sympathies run against Harrowing…but my reason makes me think twice.  If I were you, I'm sure I'd hate them."

        Breden's smile was bitter but genuine.  "A most frank and reasonable answer."
        *goto scapewell
  *label scapewell
  *if ruthless >= 0
    $!{xhe} bowed again and stepped away from you. 
  
  "We don't say farewell to each other in the camps, ${kuria} ${fname}. Just 'scapewell.' Escape the Harrower till I see you again."
  *goto sermon
*if helot
  "I've put my life in your grasp, and you're no kin to me or anyone I know.  How do you think I feel?"

  "Angry?  Alive?"  $!{xhe} reached out to clasp your hand, smile fading.  "And frightened.  And free.  For folk like us, those will always go together."
  *choice
    *selectable_if (not(acepref)) #That was when I kissed ${xhim}.
      *set bred_lover 4
      Breden's surprise 
      *if (female and malepref) or (male and femalepref)
        and uncertainty were plain on ${xhis} face.  "${fname}…I'm not yet looking for a safe-mate…."
        
        "$!{oath}, neither am I!"  Heat prickled across your cheeks and ears.  "Who said anything about a child?  I reckon I've a few years left before the Theurges Harrow me for not breeding."
             
        "I'm sorry, you're right."  Now Breden was the one looking mortified.  "It was just…unexpected."  $!{xhe} pulled away from you.  "Not unpleasant.  But we've 
        *goto trustenough
      lasted an instant; then ${xhe} was disengaging ${xhis} face from yours, stepping gingerly away. "Angels, ${fname}, we've
      *label trustenough
      barely met."

      "I've trusted you with enough else.  I thought…"  You stared at ${xhim} for a moment, then shook your head, hoping ${xhe} couldn't see the full measure of your embarrassment. "But I see it was unwelcome.  I'd not meant that.  Forgive me."
      
      "It would have been good of you to ask.  I've had enough of folk just presuming.  Thought most of us had."
      
      "I'm so sorry."  Though all you wanted was to look away, you forced yourself to hold ${xhis} level stare.  "It won't happen again."
      
      "I didn't say that."  The slightest of smiles touched Breden's lips.  "But before I give you a chance to ask me properly, ${fname}…strange as it may seem for me to be the cautious one, any Alastor within two hundred yards could see us here."
      
      Despite the pounding of your blood you nodded, knowing how ready the Alastors are to take "helot unchastity" as justification for an assault.  "When and where, then?  The overseers will be on us every moment of the next few days…."

      "There's a place."  $!{xhe} leaned in, brushed ${xhis} lips quickly against yours.  
      *goto bredrendez
    *if acepref
      #That was when I knew I wanted to be closer to ${xhim} than I'd ever been with anyone else.
        *set bred_heart 2
        Unlike most of the young helots you grew up with, you'd never been in any danger of being caught "breaking chastity" by the nobles.  The desire for physical contact that most of your friends seemed to feel so strongly barely registered with you.  But for the first time, staring into Breden's eyes, you found yourself yearning for connection on a level deeper than you've known before.  You wanted to know ${xhim} and be known, at a depth that has nothing to do with bodies.
        
        *goto fighttoquell
    #That was when I knew I had to see ${xhim} again, to keep talking.
      Now that you'd said the unthinkable, it was extraordinarily hard to stop.  
      *label fighttoquell
      You fought to quell the flood of words rising in your throat; better to take time to think it through before it all came spilling out.  "Breden…our watch here is only going to last a morning.  Where and how can we meet to talk more on this?  The overseers will be on us every moment of the next few days…."
      
      "There's a place."  $!{xhe} thought for a moment, then nodded. 
      *goto bredrendez
  *label bredrendez
  "Since kurios Mikal lost the hands to keep the dikes in repair, the whole de Rose North Edge has sunk into marsh.  No one passes that way.  Meet me in the stand of alder between the river pond and the outbuildings—a week from today, at the ninth hour."

  "I'll be there," you vowed.
  *goto sermon
*label sermon
*page_break You Are Jolted Out of Your Reverie
*text_image 1_autumn.png center AUTUMN
[b]…both because Ecclesiast Zebed is[/b] reading piercingly from the Codex of Liturgy, and because you have at last spotted Breden, halfway between you and the Harrowing platform.

Breden's face is half-turned toward you, enough that you can glimpse a worried tautness to ${xhis} lips.  $!{xhe} also seems to be searching for someone else in the throng of helots.  You watch ${xhim} for a few moments, but ${xhe} doesn't notice you—and eventually the priestly recitation reaches a volume and intensity where you can no longer ignore it.

*if not(introrel)
  As priest of Rim Square—or "Acron," as he, the Karagonds, and a few assimilated nobles call it—Ecclesiast Zebed presides over sacred ceremonies for nobles and tradesfolk, such as weddings, namings, and heritances.  The only helot ceremonies he takes part in are Harrowings.  He also avidly hunts out sacrilege or lawbreaking in his parish and refers the culprits to the Alastor law enforcers for official punishment.  
*if introrel
  In the eight years since he displaced Ecclesiast Olynna, Zebed has proven himself zealous in rooting out sacrilege and lawbreaking in his parish.
  *if aristo
    You've seen him regularly at the weddings, namings, heritances, and other ceremonies for the nobles and tradesfolk of Rim Square (or "Acron," as he, the Karagonds, and a few assimilated nobles call it). It's given you a great deal of practice in masking your intense dislike.
  *if helot
    You've seen blessedly little of him, however, as he almost immediately closed his Helsday service to the helotry, and the only helot ceremonies he takes part in are Harrowings.
Today his eyes shine as he concludes his reading from the Codex:

[i]For it is the end of all things to praise with the Angels of Xthonos and magnify the glorious Thaumatarch whom They have chosen.[/i]
*line_break
[i]The noble magnify Him by their lands and by their wealth.[/i]
*line_break
[i]The wise magnify Him by their wards and by their wonders.[/i]
*line_break
[i]The helots magnify Him by their toil and by their blood.[/i]
*line_break
[i]Thus shall His dominion grow from glory unto glory, that Xaos may be unmade and all the world rejoice as one Hegemony.[/i]

*if skepreal > 50
  "Charlatan,"
*if skepreal <= 50
  "Blessed Angels forfend," 
you whisper at the contemptible little man, too quietly for even your father to hear. Then you catch Breden's eye at last.  $!{xhe} 
*if helot
  breaks for an instant into a taut, relieved smile; then it fades as ${xhe}
*if aristo and (breden = 1)
  doesn't even smile a greeting, just desperately 
*if aristo and (breden = 2)
  gives you a level stare, then
mouths a name at you: [i]Radmar?[/i]
*page_break  You Remember
*text_image 1_summer.png center SUMMER
*if helot
  [b]"Trust you, Breden?" Radmar growled[/b] dangerously.  Even seated, the big helot came up to Breden's chin, and his knotted fists looked large enough to snap ${xhis} arm without effort.  "Five months you've lived in the Rim, and we're supposed to trust your judgment of what's safe or wise?"

  With twelve helots crowded into the decaying shack, the atmosphere was even more stifling and muggy than in the summer-baked marsh outside.  Yet Breden sounded coolly unfazed.  "Sometimes it takes an outsider to see what risks are worth taking, Rad.  You've trusted me so far."

  "$!{he}'s t'Keriatou, damn it."  Radmar stabbed an accusing finger at you.  "The aristarchs' overseers know whenever one of their hands leaves the camp.  What happens if ${he} gets followed here?  We've never had a Keriatou helot in here before."

  You hesitated in the doorway.  On your six previous visits to the swampy fringes of the de Rose estate, it had been with Breden alone.  Only recently had ${xhe} confided in you that ${xhe}'d invited helots from the other Rim Square estates to meet in a place where they could talk freely—and asked if you'd be the first from your camp to join the discussions.  Now, surrounded by young helots you recognized but didn't know well enough to trust, you were shaken by the same fear you saw on their faces.

  "Calm yourself, Radmar," you said levelly.
  *choice
    #"I've known how to avoid the overseers since I was six."  I took a seat.
      *label fierceeyes
      *set elery 2
      A fierce-eyed young woman leaned forward from one stained wall.  "I've heard of you, ${fname} ${lname}—always talking free, bending rules.  You think the masters aren't watching you, of all people?"

      You felt your temper ignite, just as it did whenever you had this argument with Gillian and your fellow t'Keriatou helots.  "Maybe They are, and've chosen not to trouble me.  But what if They just haven't noticed my talk and my rule-bending?  What if we watch ourselves more closely than they do?"

      The young helot looked you up and down, visibly unconvinced.  "I can think of a third option."  Radmar made an approving sound, halfway between a grunt and a chuckle.

      Anger put flint into your voice, but you managed to keep your fists at your sides.  "Breden and I have been talking for months.  If I were a Kryptast—or if ${xhe} were, for that matter—one of us would be dead by now."

      "They play a long game.  Everyone knows that.  Draw as many fish as possible into the net before hoisting it."

      "You really think that's what the Kryptasts are for, Elery?" Breden cut in, eyes ablaze.  "Look what the Thaumatarchy's done to us.  They make a few people disappear, let it be known it was done by a Kryptast—and suddenly we're all watching everything we say and do, around everyone, because anyone could be one of them.  But they're [i]not[/i] everywhere.  Here in the back end of Shayard, you really think we'll be unlucky enough to draw a Kryptast?"  $!{xhe} let the silence stand for several moments, then grinned. "I'll bet my life we won't."

      As Elery shrugged grudgingly, another, much younger girl—perhaps ten years old?—piped up from her perch on a rafter.  "I'll bet on ${fname} too, Breden.  My friends on the Keriatou estate like ${him} well enough.  And ${he}'s right…their overseers are easier to fool than a blind dog in pepperweed."

      A reluctant chuckle broke the tension in the hut, and you recognized Pilyin Thatcher, a house drudge with friends in every helot camp in Rim Square.  "Thanks, Pin."  You looked around.  "Breden's right—if we don't choose to trust each other, we should just find a corner to cower in until they Harrow us all."
      *page_break
      "Anyone still object to ${fname} joining us?" Breden asked mildly.  When no one spoke, ${xhe} pressed, "And knowing our secrets?"

      "[i]Damn[/i] it, Breden," Radmar rumbled unhappily, but left it at that.

      "Alless—come in," Breden called.  You had only just recognized the name when Olen Stonehewer's eldest daughter appeared: eyes flat, cheeks sunken and scratched, a haggard wisp of the girl you'd known.  Elery quickly folded her into a protective hug.

      "You t'Keriatou know anything about hiding runaways?" Radmar demanded.

      "We know you keep them well out in the woods until you're sure any hunt is done," you replied slowly.  It happened once every few seasons—a fugitive helot or two made it out to the Rim, fleeing one of the huge estates of the Southriding.  This was the first time you'd known a sold helot to run back to their old estate, though.  The chances of Alless being recognized made everything more dangerous. 

      You continued, "Sometimes there's ways to add them to the camp so no one asks questions.  But even with a camp of Keriatou size, they'll probably get noticed come the next Harrowing—and the overseers we have now wouldn't let it go.  The last few runners, we've just sent on up into the wild to look for the Whendward outlaws."  It went without saying that an eleven-year-old couldn't take that road.  "I reckon some of you will have better luck bringing her into your camp, in time.  The Tarakatou, the de Morgane…smaller camps, but friendlier overseers?"

      "All depends on how hard she's being hunted, doesn't it?" Elery cut in. "Rad—you have any more sense of how much the Pelematou care about this?"

      "No one's said a thing, but the overseers have been paying us more surprise visits than usual."  Radmar strode over and patted Alless on the head.  "Don't you worry, duck.  No one outside this room has any idea you're here."  He shot a searing glance at you.  "And no one here's going to spill a word."

      "We'll keep you safe," you promised, feeling:
      *fake_choice
        #Excited at the adventure of protecting a fugitive.
          You couldn't repress a small smile, despite the gravity of the situation.
        #Worried that Breden has dragged me into such a risky scheme.  Harboring runaways will get us sent straight to the Harrower.
          You gave Breden an unsmiling stare.  $!{xhe} returned an apologetic grimace.
        #An ache of sympathy at Alless's haunted silence.
          Your mind shied away from imagining what the once-merry girl had gone through since the Angelday when her father was slaughtered.
        #Angry all over again that a young girl is on the run because of the nobles and the Xthon'damned Hegemony.
          Her father died at an aristocrat's whim, and the rest of the Hegemonic authorities were determined to see that she suffered the same fate.  At that moment, you'd happily have set them all on fire.
        #Hollow and hopeless.  [i]Another one.[/i]
          You tried bleakly to press through, find the will to help.  But it was hard to fight the sense that you're only postponing the inevitable, for a handful of the countless thousands sacrificed to the Hegemony.
      *comment endif
      
      "So," Breden continued to the group, "which of us can help Alless in these next weeks?"

      You decided what you were going to contribute.
      *choice
        #I tried to smuggle food up from my camp.
          The Keriatou can afford plenty of bread for their helots, and meat twice a week; they don't guard the meal tent as closely as some other Houses.  It wasn't hard for you to fold away some loaves in a scarf and walk away with them after the dinner hour.

          Unfortunately, one evening Gillian Adze spotted your contraband.  Her look of disgust made you cringe; she plainly assumed that you were hoarding extra rations from the common table.  Even among the comparably well-fed t'Keriatou hands, this remained one of the great offenses, with the deeply engrained sense that sneaking food leaves less for everyone else.

          It would be different if they knew it was to feed a fugitive, of course—but you weren't about to tell Gillian or any other t'Keriatou about Alless Stonehewer.  The approving looks you got from Breden's little gang almost made up for the disapproving murmurs about you that spread in your own camp.
          *set cred_h -10
          *set allessfood true
          *goto sedit-chat
        #I helped build her a shelter in the woods.
          Over the next few days, you left the fields early and made your way up to the forest behind the de Rose estate.  Alless had been sleeping in a hollow, with just a mound of leaves separating her from the sodden earth and a few pine boughs for shade.  Working briskly, you and Elery Skinner wove her a sturdy willow hut with a floor raised three inches off the mud, and covered it in thatch and leafy branches.

          When Radmar finally managed to steal away from the watchful Pelematou overseers and saw your handiwork, he stood there wearing his typical glower for several moments.  You glanced over to a mildly exasperated Elery.  Just as you were about to ask if the hut met with his disapproval, he spoke huskily.  "I'd have…I thought I'd be in time to help."  He reached out to curl one massive arm around Alless.  "It's a grand nest for you, isn't it, little duck?"  Alless bobbed her head wordlessly at his side.
          *set cred_h +3
          *set r_rel +2
          *goto sedit-chat
        #One of the Keriatou's overseers is a good man.  I tried to find out from him whether Alless was being seriously hunted.
          *set hawarden 1
          San Hawarden used to be a yeoman farmer before his debts to the Keriatou grew too heavy.  When the rains failed two years back, he finally lost his land and came to manage a helot team on the fields he had once plowed himself.  Other farmers who had similarly been reduced to landless overseers avenged themselves fiercely on the helots, perhaps to reiterate that they hadn't fallen [i]that[/i] low.  Hawarden, by contrast, just continued to describe the land as "my corner" and behaved as if you were paid laborers helping him farm it; his caustic sense of humor was aimed strictly at your Keriatou masters.

          When you approached him at the end of a hard day in the field, he jutted his jaw amicably in recognition.  "${lname}.  Solid work out there today."

          "Thanks, Hawarden."  You wiped away your muddy brow-sweat with a corner of your kyrtle.  "Just wondering…was there ever any trouble from the masters about Olen's wake?"

          "You mean after 
          *if rebelrebel >= 0
            you and
          that lippy helot declared a half-holiday on the morning of the plowing?"  He showed his teeth in a grin.  "Don't think any Keriatou had the least idea.  You all lost a bit of skin, and the soil got turned.  What's for them to notice?"

          You nodded ruefully.  "Good.  It's only…I heard an overseer mention Stonehewer as if there was still some unanswered offense.  Didn't know if we should look for any problems there.  Something with a daughter?"
          *page_break
          The foreman turned a sharp squint on you.  "Which one of us you hear that from, then?"

          "Don't know.  Couldn't rightly see him; just heard the question.  Why?"

          "Hmff.  They all thought they'd be discreet on it.  Didn't want any hue and cry in the camps."  San Hawarden stared at you a few moments longer, then shrugged.  "But it costs me no blood to have it out there.  The Pelematou got word to every House in this half of the Outer Rim that if a runaway girl shows up among their helots, the overseer who brings her in will get a gold stater."  He spat into the dirt.  "Not my idea of honest work.  It'll keep them hunting for a few months, though."

          You bowed to hide your reaction, thinking that you'd need to move Alless further out in the woods.  Breden's little gang would be grateful for the news.  "If that's all it is, I can't see it coming to much.  Runaways don't usually come back where they'll be known."

          "Don't suppose they do."  Hawarden scratched his chin and lowered his voice.  "After what the Pelematou did to her papa, fair play to the girl if she did get away.  Hope we never hear her name around these parts again."

          "Hope not," you fervently agreed.
          *set cred_h +3
          *set cred_y +2
          *goto sedit-chat
        #I just tried to be kind to her and draw her out of her shell. Anything more concrete would risk alerting the Keriatou overseers.
          You stayed silent, ignoring Breden's obvious disappointment.  Radmar's and Elery's worries weren't completely groundless, and if you started arousing suspicion among the Keriatou foremen, all their worst fears might come true.

          The other young helots banded together to feed and clothe Alless.  You just did your best to comfort her and gently encourage her to start talking again.  With Pin's help, within a couple months you had the young girl halfway out of her shell; once she even gave you a cautious smile.
          
          Radmar strode up to you one day, gruff and glowering as usual.  "I've seen you spending all your time talking with little Alless, ${lname}."
          
          You eyed him warily, braced for him to demand more—to give savage voice to the disapproval you'd seen in Breden.  "And?"
          
          "And nothing.  Thought you ought to know someone's noticed."  Radmar cleared his throat, mouth working. "It's done her a measure of good, poor duck."  He gave you a sharp nod, then turned and stalked off again.
          *set r_rel +5
          *goto sedit-chat
      *label sedit-chat
      *page_break
      Meanwhile, you kept meeting with Breden's little gang every two or three weeks in the de Rose shack—and your conversations soon began to catch fire.  Even after the bad death of Olen Stonehewer, many helots were reluctant to complain about their noble masters; some of the lesser Houses were kindly enough to the helotry, after all.  So most of the group's verbal rage flowed toward the forces of the Karagond Hegemony in Rim Square: the corrupt and brutal Alastors, the heartless Ecclesiast Zebed, the bloodthirsty Theurges.

      As your caution faded, the group began sharing every story of revolt against the Thaumatarch that any of you knew.  The case you'd previously heard least about was:
      *choice
        #The yeoman rising of Ester Cabel.
          *gosub cabel
          *goto practicalities
        #Sarcifer, the renegade archmage.
          *gosub sarcifer
          *goto practicalities
        #The Laconniers, keepers of the Sovereign Bloodline.
          *gosub laconniers
          *goto practicalities
      *label cabel
      Forty-five years ago, the yeomanry of the Westriding rose up [i]en masse[/i], spurred by the Hegemonic Laws that had steadily stripped them of their lands and commons.  Their rising was carefully timed to coincide with the Court Season, when all the powerful nobles had decamped to Shayard City with their private guards.  In the first few days, the rebels slaughtered every Alastor and Ecclesiast in the Westriding, and spilled over into parts of the Rim, the Coast, and the Reach.  Declaring helots free, they nonetheless spared the remaining Shayardene nobles, appealing to the Archon to join them and lead the whole realm against the Thaumatarchy.

      At the height of the rising, hundreds of thousands mustered in the name of Ester Cabel, the young yeoman leader of the rebellion.  For two months, its sheer scale defied the Hegemony's power to respond.  The Archon claimed that he had assurances from the Thaumatarch that the laws would be changed. But while he temporized, the nobles and yeomanry began to turn on each other.  Mutual massacres soon put paid to Cabel's dreams of a united Shayardene revolt.

      It all ended in the Great Scouring: a thousand Theurges setting the hamlets and woods of the Westriding ablaze, followed by three months of incessant rain to wash away everything that survived the fire.  Cabel was betrayed, Slow-Harrowed and quartered; her remains were dispatched to the four corners of the Hegemony and lashed to the bonetree of each provincial capital.  The Archon's heart stopped beating soon afterward, and the archonty passed to a different noble House.

      "Mentioning Cabel's name will get you locked up and Harrowed by any Alastor in the realm," Elery warned in conclusion.  "But they say her son Jac Cabel has kept the flame of the great rising alive across Shayard."
      *return
      *label sarcifer
      It's hard to keep from shuddering whenever you hear the name of Sarcifer the Goete.  He was the villain in so many childhood fright stories: Sarcifer the Flesh-Eater, Sarcifer the Pallid, slaughtering villages or stealing the blood of children to feed Xaos-demons.  In the tales that ended well—a distinct minority—he would be chased away by the brave knights and Talisman-wielding magi of the realm, never conclusively slain or defeated.

      This also makes him one of the few unambiguously successful rebels against the Thaumatarch, although you'd never heard the story told that way before.  "He used to be one of the Nine," blind Yebben Skinner recounted,  "one of the Thaumatarch's deputies, the Ennearchs who hold up the Great Border Wards.  After he rebelled twenty years ago, he went his own way, killing only servants of the Hegemony—especially other Theurges.  That's why they hate him so much, and spread all the stories that make him out to be a monster.  But he's not; he's just too powerful for any of them to kill."

      "He's still a Goete," Yebben's twin Elery said with a horrified grimace.  "I mean, whatever he does to feed his magic, now that he's no longer a proper Theurge…it can't be good, can it?"

      Yebben shrugged.  "I don't pretend to know good from bad Theurges, sister.  All I know is whatever Sarcifer does, it doesn't involve a Harrower."
      *return
      *label laconniers
      It's been three hundred and fifty years since the Shayardene royal line was supposedly extinguished.  The last Queen fell in battle to the Thaumatarch; the last Prince fled into the forest of Laconne and was never seen again.  But from then until now, there have been rumors of a secret order among the nobility who hid the prince in the woods and ensured the persistence of the lineage.

      Over the past century, at least three Shayardene Pretenders have declared themselves heirs of the Lost Prince of Laconne and won swathes of the nobility to their banner.  All three rebellions were swiftly quelled: two with Kryptast assassins alone, one with massed military and Theurgic force.  Still, the rumors persist that the Pretenders were only lesser scions of the Sovereign Bloodline, sent to test the waters by the deeper Laconnier conspiracy.

      Breden told you all about the Laconnier Order, along with other stories of the old monarchy that ${xhe} had overheard from ${xhis} former masters when they were drunk and seditious.  "They said there were no helots in Shayard before the Karagonds came.  The kings and queens of old fed the realm and held it together without Theurgy—without any need for Harrowing!"  $!{xhis} eyes were bright and distant.  "Four hundred years ago, we would all have been yeomen…growing our own food, defending the realm with our own strength in time of need.  It's the Karagonds and their damned magecraft that turned us into food for a machine.  They're the ones who convinced us all that there's no other way to hold Xaos at bay.  They're the ones who started slaughtering us, and called it self-sacrifice."
      *return

      *label practicalities

      Without anyone explicitly saying so, the meetings began to shift from mere talk to action—preparation for a still unspoken future.  You shared something of your greatest skill:
      *choice
        #Charm and persuasion.
          *gosub helcha

          You tried to pass on some of what you'd discovered to your fellow young helots.  Breden had the same natural charisma as you, and picked up your tricks and advice with ease.  Blind Yebben, Elery's twin, also had a natural way with words, and Pin soaked up your lessons with delight.
          *goto least_skill3
        #Fighting and leading others in a fight.
          *set com 2
          Like most helots, you'd played scrum-ball, where two opposing mobs use friendly violence to deliver a ball to the far side of a field.  The side that takes your tactical advice always triumphs.  You'd also been a good hand with a staff, which many helots practice in secret for self-defense.

          "You think any of us would last five minutes against a blade?" Radmar asked, looking sour after you'd managed to beat him at staves.

          "Against a noble?  Absolutely." The aristocrats' games of swordplay and pygmachia (fist-fighting) are hedged in by an elaborate code of conduct.  "They're used to holding back, to not leaving marks where they can be seen.  But you and me, Radmar…we know that the only rule in battle is to win."

          "I think the Theurges know that rule, too," Elery offered bleakly,  "and we won't be challenging them to a scrum-ball match, ${fname}."

          "We won't be challenging them to anything just yet," Breden cut in.  "One hedge at a time, El."
          *goto least_skill3
        #Reading and knowledge of the world.
          *gosub helint
          *set literate +5
          you brought all four books to the de Rose outbuildings to teach anyone who was interested.  Sharp-eyed Elery started to pick up the letters quickly, as did young Pin. Like you, they particularly enjoyed the [i]Stoicheia[/i] of Hyron, which explains the world in terms of the dynamics of the four elements.  
          
          Others were more skeptical. "We're truly supposed to believe that all this," Radmar rumbled, gesturing at the swamp and forest, "can be whittled down to Four?"
          
          "It seems odd at first," you agree, "but when you've thought about it for a while, you learn to reckon which elements must be at work in different parts of the plant or soil or animal, and it makes sense."

          One day Breden brought a slim codex to the meeting.  "Kuria de Rose left this in the barn—she looked quite flustered when reading it, and jumped a mile when a helot came in.  What's it about?"

          You skimmed it, then handed it to Pin with a smile.  "Interesting.  What do you make of it?"
          *page_break
          "Comes from Karagon," she said instantly.

          "How do you make that out?" Radmar asked, blinking.

          "Look.  This little curve here, this one here…this line exactly so long, and this one just like it.  Each letter looks exactly the same."  The young girl spoke as if it were the most obvious thing in the world.  "No one wrote this with a pen.  It was imprest.  And the Karagonds don't let anyone make imprest books or papers in the provinces."

          Elery leaned in with interest, flipping through the parchment pages.  "You're right.  Here, this says, 'Xthonos'…'will of'…And these pictures, these symbols: it's got to be something Ecclesiastical.  See, the three big seals stamped on the last page.  This one has a picture of the oak and candle—the Archimandrite of Shayard."

          "It condemns a heresy," you agreed, pleased at how quickly they'd understood.  "I'd need to take more time to fully understand what they're talking about, but they're basically condemning a version of the old Shayardene Heresy—the idea that the Karagond Codex of Liturgy is too merciless, and that the original will of the Angels must have been more compassionate."
          *if skepreal < 50
            You were yourself quite sure that the "heretics" had the right of it,
          *if skepreal > 50
            To you, of course, the cruelty of the Codex simply showed the untruth of the whole sorry shambles,
          *if skepreal != 50
            but you kept that back for the time being.
          
          Breden drummed ${xhis} fingers across the great seal.  "Relations between the de Rose and hieros Zebed have seemed a little tense for months.  This probably means that Zebed could condemn them if they don't recant.  Might come in useful down the road.  Good thinking, all."
          *page_break
          "Is it anything to do with this scroll, ${fname}?" Pin asked eagerly, holding up one of your books.  "I think I recognized a few of the same words."

          "No…that's just an odd one." Ganelon had passed you the thin vellum scroll the previous autumn, as the most readily disposable piece of a small library he'd recently inherited from some distant aunt.  It described an odd mental exercise: to meditate on a thing's fundamental nature and then conceive it changing. The text emphasized that by doing so, you create a new world in your mind, governed by slightly different ends and purposes.  Ganelon had rolled his eyes at how abstruse and frivolous it was, but something about it had been nagging at you for months; it had a curiously practical tone for its philosophical subject matter.

          But the litany at its heart seemed pointlessly cryptic.  "…[i]Nothing comes into the world without purpose.  Fear does not cloud my vision.  I see the world without its masks.[/i]"  You read a bit aloud, then shrugged to Pin. "I carry it because I'm trying to figure out if it's good for anything.  No luck so far."
          *goto least_skill3
      *label least_skill3

      To your embarrassment, Breden's friends also soon found out about your greatest area of weakness:
      *choice
        *if com < 2
          #Fighting and leading others in a fight.
            *set com 0
            *if cha = 2
              *set int 1
            *if int = 2
              *set cha 1
            One afternoon you found the group covertly practicing self-defense with staves and clubs.  To your dismay, Breden called you in to join them.  It took Elery all of five seconds to disarm you with her staff, wrenching your wrists and (if the pain was any indication) half-breaking your fingers.

            Ears burning at their suppressed smirks, you retired to the margins and watched them ruefully for the rest of the afternoon.  When they ended with an all-on-all melee, it looked like pure chaos to you; if a real brawl broke out, you have to admit you'd have no idea how you or they could win it.
            *goto poric_helot
        *if cha < 2
          #Charm and persuasion.
            *set cha 0
            *if com = 2
              *set int 1
            *if int = 2
              *set com 1
            One day's topic of discussion was how to convince other people to join your seditious group.  You did your best to articulate a convincing case, but could feel the words falling flat from your tongue.

            The others glanced at each other, visibly unimpressed.  "You'll just have to win people over by the wisdom in your words, ${fname}," Elery said, not without sympathy.  "Leave the charm and sweet talk to folk like our Breden."
            *goto poric_helot
        *if int < 2
          #Reasoning and intellect.
            *set int 0
            *if cha = 2
              *set com 1
            *if com = 2
              *set cha 1
            One day Breden brought a slim codex to the meeting.  "Kuria de Rose left this in the barn—she looked quite flustered when reading it, and jumped a mile when a helot came in.  Don't suppose any of you know enough alphabeta to make out what it's about?"

            "Course not," you said after a glance.  Only one helot in a thousand can read, and you can think of roughly a thousand other things that would be more useful and interesting than learning Karagond letters.  "Might be written in Halassurq for all I know."

            "No, silly—they write in glyphs," Pin piped up.  "This comes from Karagon."

            "How do you make that out?" Radmar asked, blinking.

            "Look.  This little curve here, this one here…this line exactly so long, and this one just like it.  Each letter looks exactly the same."  The young girl spoke as if it were the most obvious thing in the world.  "No one wrote this with a pen.  It was imprest.  And the Karagonds don't let anyone make imprest books or papers in the provinces."

            Elery leaned in with interest.  "You're right.  And these pictures, these symbols…it's got to be something Ecclesiastic.  See, the three big seals stamped on the last page.  That's what they do to show it's on the priests' say-so.  This one has a picture of the rose and tree—the Archimandrite of Shayard."

            "Of course.  Odds are, it's a formal condemnation of some heresy or another."  Breden drummed ${xhis} fingers across the great seal.  "Relations between the de Rose and hieros Zebed have seemed a little tense for months.  This probably means that Zebed could condemn them if they don't recant.  Might come in useful down the road.  Good thinking, Pin, El."

            As they grinned at each other, you felt embarrassed at how quickly they had extracted a meaning that you would never have discovered.  It's the downside of not 
            *if natlreal >= 50
              being particularly curious about the world, or 
            having very strong memory and reasoning skills.  Your understanding of history, theology, geography, and Theurgy doesn't get much past the level of fireside tales.
            *goto poric_helot

    #"There's no gain without some hazard."  I crouched in the doorway, waiting for them to decide what they wanted.
      *goto fierceeyes
    #"I'll not put you at risk."  I turned and left.
      Breden was instantly on your heels as you stumbled back into the dusk-dappled alder grove.  "Where are you going, ${fname}?"

      "Why should I stay where I'm not wanted?" you retorted.  "Breden,
      *if bred_lover > 0
        love,
      it's one thing to risk my life by what I say to you.  It's something else to do it with ten strangers.  Trying was a mistake."

      "Why—because it's too close to an actual rebellion?"  Breden stopped in ${xhis} tracks, folding ${xhis} arms and glaring at you.

      "What did you say?" you hissed, incredulous.

      "Rebellion."  $!{xhis} voice was pitched too low to be heard back in the shack.  "A helot rising, ${fname}.  You'll dance around it when we talk.  But that's where your anger is taking you—and if it's going to actually happen, it's not going to come from you and me alone."
      *choice
        #"I don't know if that's what I want, Breden."
          "Nor do most of the others in there.  But I'm sure it's what's coming."  There was a hint of disappointment in Breden's eyes and voice.  "Come back with me.  Talk me out of it, if you think it's wrong.  But don't run away."
          *goto backhchoice
        #"I'm not ready to…use that word yet."
          "Nor are most of the others in there.  They're just meeting where they can speak free."  Breden strode over to you, a plea in ${xhis} eyes and voice.  "But you and I both know that's where things are moving.  Come back with me.  Talk me out of it, if you think it's wrong.  But don't run away."
          *goto backhchoice
        #"I'm not afraid of rebellion.  But your friends in there?  They are."
          *set rebelrebel 1
          Breden smiled boldly at you.  "Yes, they are.  So come back with me, damn it.  Talk with them.  Help them find their way to what we both know is coming."
          *goto backhchoice
      *label backhchoice
      *if (bred_lover > 0) or (bred_heart = 2)
        
        Your throat tightened as you wondered what your answer would mean for the 
        *if bred_lover > 0
          tentative romance that had been springing up 
        *if bred_heart = 2
          close connection that had been deepening
        between you.
      *choice
        #"Damn your games, Breden.  I want no part of this."
          *set helotrefuse true
          Anger coursed hotly through your chest when you thought about the shocked looks on the other helots' faces.  "You didn't even warn them you were bringing me.  What did you expect?"
          
          "I thought…"
          
          "Thought you'd put them in a place where they couldn't say no?  They said no, damn it.  And I'm saying no now."  Before ${xhe} could respond to your tirade, you stalked away.
          *goto helotreject
        #"No.  I'm sorry, but no."
          *set helotrefuse true
          You shook your head slowly.  "Tell them I'm not going to betray them. 
          *if rebelrebel < 1
            I'm just not ready to take the road you're all on."
            *goto bfacefall
          *else
            And if they get over their terror of being discovered, come back and talk to me again."
            *goto bfacefall
          *label bfacefall

          Breden's face fell.  "But…very well."  Something hardened behind ${xhis} eyes.  "There'll be work waiting back on the estate, then.  You'd best get to it.  And I'll see you when I see you."
          *if (bred_lover > 0) or (bred_heart = 2)

            "That's how things end between us?" you asked softly.

            "Only Xthonos knows the ends of things, ${lname}."  Emotionless, Breden parried with a priest's cliche.  "You've made your choice.  We'll see how it ends."
          *goto helotreject
        #I stared at ${xhim} for a long moment before hearing myself say: "Very well."
          You followed Breden reluctantly back to the shack, meeting the unsettled gazes of the other helots as you took a seat.  "There's no danger of the Keriatou or their minions finding us here," you declared.  "So pluck up your guts, Radmar."

          *goto fierceeyes
      *label helotreject
      *page_break
      The next time you saw any of them was the late summer Harrowing, the third and (you all assumed) final one of the year.  When you heard the Alastors announcing that in a day's time you would all have to face the Theurges, a long-dormant panic sprouted throughout your guts.  What if one of Breden's gang were fed to the machine?  Or what if one of them had already denounced you to the authorities?  The night before, you dreamed of a faceless youth pointing to you and shouting, "$!{him}! $!{he}'s the one! $!{he} spoke against the Thaumatarch!"

      In the event, only three elders were chosen—aged helots who might not have survived the autumn heat in any case.  After the third, your father let slip a small moan deep in his throat; as a widower past his best years, he could easily be chosen if the authorities were culling the barren helotry. You both tried to hide your overwhelming sense of relief when the Theurges closed the ceremony.

      Then you saw Breden and Radmar staring stonily in your direction, and you felt the dread creep back into you.

      To escape the anxiety, you threw yourself into practicing your greatest skill:
      *choice
        #Charm and persuasion.
          *gosub helcha
          *goto least_skill4
        #Fighting and leading others in a fight.
          *gosub helcom
          And unlike the nobles, whose games of swordplay and pygmachia (fist-fighting) are hedged in by an elaborate code of conduct, you know that the only rule in battle is to win.
          *goto least_skill4
        #Reading and knowledge of the world.
          *gosub helint
          after your breach with Breden, you threw yourself again into studying them. The [i]Stoicheia[/i] of Hyron was a particular comfort, the first book that changed the way you see the world.  When you first read it years ago, you had struggled to accept that everything in the cosmos could be made of only four elements; then came the unforgettable leap when you grasped the elegance of Hyron's method.  One of your favorite pastimes now is puzzling out which of the elements and their dynamics must be at work in different objects.
          
          You also found yourself coming back to a thin vellum scroll that Ganelon had passed you the previous autumn, the most readily disposable piece of a small library he'd inherited from some distant aunt.  It described an odd mental exercise: to meditate on a thing's fundamental nature and then conceive it changing. The text emphasized that by doing so, you create a new world in your mind, governed by slightly different ends and purposes.  
          
          Ganelon had rolled his eyes at how abstruse and frivolous it was, but something about it had been nagging at you for months; it had a curiously practical tone for its philosophical subject matter. Still, the litany at its heart seemed pointlessly cryptic.  "…Nothing comes into the world without purpose.  Fear does not cloud my vision.  I see the world without its masks."  Sighing in frustration, you put it away again.
          *goto least_skill4
      *label least_skill4

      Desperate to distract yourself from your gloom, you also devoted a few futile days to practicing something you've always been hopeless at:
      *choice
        *if com < 2
          #Fighting and leading others in a fight.
            *set com 0
            *if cha = 2
              *set int 1
            *if int = 2
              *set cha 1
            You picked up a staff and half-heartedly tried some of the poses you'd
            *if int = 2
              seen illustrated in a book.
            *if cha = 2
              been shown by a friendly fellow helot.
            It all seemed to be going well…until you got the movements of your arms and legs confused, and managed to crack yourself hard on the shins.  You knew that any actual adversary would have had your head off.

            The unfortunate truth is that if a brawl broke out, you'd have no idea how you or your friends could win it.  It would all look like pure chaos to you.
            *goto poric_helot2
        *if cha < 2
          #Charm and persuasion.
            *set cha 0
            *if com = 2
              *set int 1
            *if int = 2
              *set com 1
            You know you're a plain-spoken, unassuming ${woman}, with no particular gift for inspiring or persuading people.  After seeing (and feeling) the effect of Breden's charisma, you tried to be conscious of the words and tones you use, in the hopes of becoming a more compelling speaker.  But you could hear your own attempts falling flat from your tongue, and after a few weeks you gave up.

            Your ideas will have to stand or fall on their own merits, not on your ability to get people to warm to you personally.
            *goto poric_helot2
        *if int < 2
          #Reading, reasoning and memory.
            *set int 0
            *if cha = 2
              *set com 1
            *if com = 2
              *set cha 1
            Only one helot in a thousand can read, and you can think of roughly a thousand other things that would be more useful and interesting than learning the alphabeta.  But after your breach with Breden, seeking for something to entirely absorb your mind, you remembered how 
            *if not(introrel)
              the Keriatou's late Diakon-priest 
            *if introrel
              Ecclesiast Olynna
            had once offered to show you how to read a prayer-book.

            You meekly approached the 
            *if not(introrel)
              new, younger 
            Diakon serving your camp and asked whether he could teach you.  Visibly suspicious, he set you to repeating the names of the letters over and over, barking out corrections when you stumbled or mispronounced something.  Your memory was stretched to its very limits, and after a week, you despaired of ever reliably linking the dozens of similar-sounding names to the similar-looking marks on a scroll.

            Soon you saw sense and returned to practicing
            *if cha = 2
              persuasion and common-sense rhetoric.
            *if com = 2
              with your staff and fists.
            Your understanding of history, theology, geography, and Theurgy will just have to stay at the level of fireside tales.
            *goto poric_helot2
*if aristo
  [b]"Trust you?" Radmar snarled.  With[/b] one bound he crossed the small room and loomed over Breden, fists trembling in ${xhis} face.  "Trust you?  Are you kin to me, to ask such trust?  Or just mad?"

  The atmosphere inside the decayed shack was even more stifling and muggy than the summer-baked marsh outside.  Yet Breden sounded coolly unfazed.  "You've trusted me so far, Rad.  What on earth do you gain by stopping now?"

  *if breden = 1
    You were frozen just inside the doorway, no less astonished than the ten guilty-looking helots gazing up at you.  The six times you'd come here before, it had been with Breden, and of course no one else had been anywhere nearby.  Today, for the first time, you'd ridden out alone to the swampy fringes of the de Rose estate, not really expecting to find ${xhim} there.
  *if (breden = 2) and (proselyt < 2)
    You were frozen just inside the doorway, no less astonished than the ten guilty-looking helots gazing up at you.  Breden had furtively asked you to speak with ${xhim} again in the abandoned outbuildings on the North Edge of the de Rose estate.  
    *if proselyt = 1
      On your ride up through the swampy woodland, you'd been debating whether to risk sharing your thoughts with a wider circle of helots, as Breden had suggested.
    You'd never imagined that  
    *if proselyt = 0
      the insolent scoundrel would actually bring along a pack of ${xhis} friends—in express violation of your orders.
    *if proselyt = 1
      you would arrive to find a pack of ${xhis} friends already there.
    The sole blessing was that you saw no t'${lname} helots in the room.
  *if (breden = 2) and (proselyt = 2)
    You stood inside the doorway, suddenly unsure of the wisdom of explaining the Hegemony's abuses to a gang of helots.  Breden had furtively informed you that ${xhe}'d convened a small group of free-talkers who met in the abandoned outbuildings on the North Edge of the de Rose estate.  But ${xhe} clearly hadn't warned these ten guilty-looking youths that a noble would be visiting them this evening. 

  Radmar's flared nostrils were the size of silver drachems.  "You just told a…you just up and claimed to a Housed aristo of the Realm—begging your grace, ${kuria}—that we were all talking the…the death of the Thaumatarch."

  It had been an outrageous greeting, even by Breden's standards.  $!{xhe} was still wearing 
  *if breden = 1
    ${xhis} mischievous, by-now-familiar 
  *if breden = 2
    a maddeningly mischievous
  grin.  "I just reckoned ${kuria} ${fname} would enjoy the talk. Even add to it!  After all, we were only asking what might become of us when today's Thaumatarch shuffles off to join his two predecessors at the Angels' side.  $!{he}'s more likely to want to plan out how we'll sneak into the Floating Palace and send him there."  Half the helots in the room sucked breath; you don't think the others were breathing at all.  Breden's eyes shone merrily as ${xhe} beckoned to you through the door.  "Won't you join us, ${milady}?"

  You swallowed your shock and replied:
  *choice
    *if (breden = 2) and (proselyt < 2)
      #"This is how you repay my mercy?  There'll be no third chance, ${xgirl}."
        As you stalked out into the dusk-dappled alder grove, Breden was instantly on your heels.  Behind ${xhim}, through an aghast silence, you heard one of the other helots start to weep.  To your annoyance, Breden ${xhim}self sounded neither afraid nor penitent. "$!{kuria}."

        "I'll hear no more of your unnatural impertinence, villain. Nor any plea."  Your father's vocabulary and tone came to you with surprising ease.

        "It spoke well of your House, ${milady}—of your boldness and honesty—when you shared your thoughts on the Hegemony with me."  The helot's voice remained level.  "It deserves a better return than blackmail."

        Spinning on your heel, you fixed ${xhim} with a savage glare. Hopefully it masked the alarm that speared through you, guts to throat.  "You'd already earned a good flogging, helot.  One more word that hints of threat, and you'll die for it."

        Breden glanced back to where Radmar crouched in the hut door, eyeing you both. Then ${xhe} lowered ${xhis} voice so it wouldn't carry that far. "$!{kuria}.
        *gosub bred2speech
        You stared at Breden in utter disbelief.
        *choice
          #"Damnation, ${xgirl}…you almost make me forget what an arrant reprobate you are."
            Breden dared a small smile.  "I'm just praying, ${milady}, that you'll pardon one reprobate helot in exchange for a chance to truly challenge the Hegemony."  When you didn't immediately reply, ${xhe} gestured back toward the shack.  "The others are much less reprobate, you know.  You still have the chance to establish proper order and deference in the group."
            *label back2shack
            *choice
              #I relented…feeling despite myself an odd twinge of affection for this impossible rogue.
                "Very well, blast it." Fury receding, you accompanied ${xhim} back to the broken-down hut.
                *goto seditionhut
              #I relented.  $!{xhe} was an unpardonable villain, but this was more important than punishing ${xhis} antics.
                "Very well, blast it." Thin-lipped and silent, you strode back to the broken-down hut.
                *goto seditionhut
              #I shook my head.  Breden's betrayals only confirmed that sharing my mind with the lower orders was far too dangerous.
                *set breden 3
                *set helotrefuse true
                "Never," you replied curtly.  "I'll say nothing more to someone who's shown ${xhim}self so untrustworthy and degenerate."

                "Very well."  Breden's shoulders slumped a half-inch. "Then I bid you farewell, ${kuria}.  And I promise we'll do our best to keep these meetings safe and secret.  None of us want to end up tormented by Alastors until we give up the names they're seeking."

                "I believe I told you what would happen if you threatened me."  You resumed your walk to your borrowed horse, mind crawling with all-too-plausible futures.

                "I just wanted to allay your fears, ${milady}," ${xhe} called, voice flat and weary. "No threat was intended.  Scapewell."
                *goto summerharrow
          #"Deception, insults, and veiled threats—you truly think I'll forgive such slights to my honor?"
            "Forgive it?  Never."  Breden shook ${xhis} head, keeping ${xhis} eyes steadily on yours.  "But I implore you, ${milady}: overlook it, for now.  For the sake of the change we all know needs to come."
            *goto back2shack
          #"I'll see you dead before I join you, ${xgirl}."
            *set breden 3
            *set bred_heart +10
            *set helotrefuse true
            Breden stepped back, face hardening as ${xhe} beckoned Radmar over.  "I didn't want us to be enemies, ${kuria}.  But if that's to be the way…"

            You briskly resumed walking toward your borrowed horse, resisting the impulse toward an undignified scramble.  Surely no helot would dare to strike at you, not even one so Xaos-corrupted as this.  "You're an enemy of all things natural and orderly, villain.  And don't forget what I said about threats."

            "Every helot here—and others you won't know of—can testify that ${fname} ${lname} has spoken out against the Hegemony," Breden called after you.  "They'll say it under torment, if it should come to that.  And if any misfortune should start to befall us, one by one…well, then, we'll make sure the allegation comes to hieros Zebed's ear, with enough detail that he'll believe it."

            Your throat tightened at the thought of the Ecclesiast's delighted, dogged pursuit of noble treason.
            *if introrel
              How much more intent would he be for the child who had nearly been his first heresy culprit?
            "And if any misfortune befell me, you think you'd live out the week?"

            "At the worst, we can just turn outlaw and flee up to the wilderness, ${milady}.  The bandits out there are our sort; they'd take us in.  Where does a lofty-nosed noble have to run?"  By the time you were mounted, the two of them were standing in the door of the shack again.  Breden's voice crackled with anger. "Scapewell, ${kuria} ${lname}."
            *goto summerharrow
    *if breden = 2
      #"No…I find after all I've no interest in bandying words with you."  I turned and left.
        Breden was instantly on your heels as you stumbled back into the dusk-dappled alder grove.  "Where are you going, ${kuria}?"  There was nothing resembling mirth in ${xhis} tone now.

        *if proselyt = 2
          "Your introduction of me left something to be desired."  You paused to glower back at ${xhim}.  "Assassinating the Thaumatarch?  You've jammed us all into the same winepress with that, ${xgirl}, and no mistake.  If a whisper gets out, the Ecclesiast and Alastors won't rest until they've tormented everyone they can find for every name they know."

          Breden didn't deny it. "And it's done.  Now forgive my audacity, ${milady}, but this is your chance to rouse the helotry as we've spoken of. Do you think such a chance will come in any other form?"  $!{xhe} reached one tentative hand toward you.  "Don't leave now, ${milady}.  Don't lose this.  Come back with me."
          *choice
            #"No.  You ask too much." 
              *label bredslump
              "I could overlook your insolence," you growled, stepping away. "It's the recklessness I want no part of."
              *label bredslump2
              *set helotrefuse true

              Breden stared at you for a moment more; then ${xhis} shoulders slumped a half-inch.  "Then I'll trouble you no more, ${kuria}.  And I promise we'll do our best to keep these meetings safe and secret.  None of us want to end up tormented by Alastors until we give up the names they're seeking."

              You blinked, hardly able to believe your ears.  "Damn your eyes, helot—was that an attempt at a threat?"

              "Not in the least, ${milady}," ${xhe} said, voice flat and weary. "Just an attempt to allay your fears.  Clumsy, and failed, as my other efforts this evening.  I beg your forgiveness, and wish you scapewell."
              *goto summerharrow
            #"You've just proven that rousing the helotry was always the wrong path."
              "I'll look to other, more trustworthy folk when it comes to challenging the Hegemony."
              *goto bredslump2
            #"Very well, blast it."
              You strode back to the broken-down hut without another word.
              *goto seditionhut
        *else
          "I don't recall ever agreeing to contribute to these seditious little chats." You turned a piercing glare on ${xhim}.
          *if proselyt = 0
            "As a matter of fact, I recall explicitly refusing."
          *if proselyt = 1
            "What made you think that deceiving me would be the best way to gain my assent?"

          $!{xhe} had the grace to look ashamed.  "I've brought you out here on false pretenses, there's no denying that."  Breden looked around, then squared ${xhis} shoulders. "So let me be wholly honest now, ${kuria}.
          *gosub bred2speech
          You stared at Breden, shaking your head.
          *choice
            #"Damnation, ${xgirl}…you almost make me forget what an arrant reprobate you are."
              Breden dared a small smile.  "I'm just praying, ${milady}, that you'll pardon one reprobate helot in exchange for a chance to truly challenge the Hegemony."  When you didn't immediately reply, ${xhe} gestured back toward the shack.  "The others are much less reprobate, you know.  You still have the chance to establish proper order and deference in the group."
              *label back2shack2
              *choice
                #I relented…feeling despite myself an odd twinge of affection for this impossible rogue.
                  "Very well, blast it." Fury receding, you accompanied ${xhim} back to the broken-down hut.
                  *goto seditionhut
                #I relented.  $!{xhe} was an unpardonable villain, but this was more important than punishing ${xhis} antics.
                  "Very well, blast it." Thin-lipped and silent, you strode back to the broken-down hut.
                  *goto seditionhut
                #I shook my head.  Breden's betrayals only confirmed that sharing my mind with the lower orders was far too dangerous.
                  *set breden 3
                  *goto bredslump
            #"You truly think I'll forgive your deceptions and insults?"
              "Forgive them?  Never."  Breden shook ${xhis} head, keeping ${xhis} eyes steadily on yours.  "But I implore you, ${milady}: overlook them, for now.  For the sake of the change we all know needs to come."
              *goto back2shack2
            #"No. I want no part of this."
              *set breden 3
              *goto bredslump
    *if breden = 1
      #"I'm sorry…I didn't mean to bother you."  Head spinning, I turned and left.
        *goto instantlyheels
    *if breden = 1
      #"Join you?  $!{oath}, Breden.  Never speak to me again."
        *label instantlyheels
        Breden was instantly on your heels as you stumbled back into the dusk-dappled alder grove.  Behind ${xhim}, through an aghast silence, you heard one of the other helots start to weep.  "What are you doing, ${kuria}?"  There was nothing resembling mirth in ${xhis} tone now.

        "I can't…What are you thinking, Breden?"  You rounded on ${xhim}, unable to distinguish where your terror stopped and fury began.  "All the things we've talked about, all the trust I've placed in you—and you just toss it to a pack of your friends with a jest and a grin?  Are you drunk?  I put my life in your hands.  You just put it in the hands of a dozen helots!"

        $!{xhis} voice was steady.  "As you just took theirs into yours, ${kuria}. By coming out here without warning.  I know it wasn't your intent.  But now…every soul in there?  You could have them killed for no crime other than coming out to a place where they could speak free."

        "That's all your doing," you hissed.  
        *if ruthless < 0
          All your aristocratic reserve lost,
        *if ruthless >= 0
          As you fought to keep yourself from adding, [i]you bloody insolent little helot[/i], 
        your finger shot out to jab against ${xhis} collarbone.  "What by Xaos were you thinking?  You all could have been talking about the barley sowing, for all I knew.  But no, it has to be a joke with you.  Your 
        *if ruthless >= 0
          little 
        friends' lives, and mine…."

        "$!{kuria}," Breden said, unflinching.  "Don't pretend.  As soon as you looked in the door, you knew exactly what we were about.  And they knew you knew."  $!{xhe} looked down at your accusatory finger, then back up to you again, eyes a little colder than before.  "I understand you're angry, noble ${kuria}.  I'm angry.  My friends are angry.  It was reckless of me to invite them to meet in the same place I'd been meeting with you.  But we're all in this together, now…and there's not much point in denying it."  $!{xhe} reached out imploringly toward you.
        *choice
          #"Don't touch me, ${xgirl}." 
            *goto defeatcreep
          #"No.  You ask too much."
            *label defeatcreep
            *set helotrefuse true
            Breden settled back, defeat creeping across ${xhis} face for the first time since you'd known ${xhim}.  "Will you at least come…Ah, Angels.  Will you at least tell them you won't be whispering their names to the Ecclesiast before the next Harrowing?"

            "I don't even know their bloody names," you muttered.  The only thing you wanted was to flee on your borrowed mount back to a Keriatou stable, but something in Breden's expression of helplessness was hard to deny.  

            When you reappeared in the doorway, every head whipped round, and the youngest helot started up with a bleat of fear.  Radmar's craggy knuckles were knotted bloodlessly about a splintered beam; the wild-eyed look he gave you made you feel queasy.  A haggard young field hand knelt quickly.  "We weren't…Please, ${kuria}, we weren't speaking any violence.  Just talking; just venting a little vinegar.  About the Karagonds and the priests.  No slander to the noble aristarchs."

            You almost managed a smile.  "You weren't talking about my cousins?  How disappointing.  I could think up enough choice things to say—and none of them slander."  The eyes fixed on you grew no less wary, and you sighed.  "Listen.  I'm not hypocrite enough to try to see anyone punished for mere talk.  This insufferable troubler of the peace, Breden…yes, ${xhe}'s already heard me talk freely enough.  So don't fear.   I'll do nothing to endanger you—not by my presence here, and not by anything I say elsewhere.  I hope you'll do me the same courtesy.  So…scapewell."

            "Scapewell," came the mumbled chorus from around the room.

            Breden followed you to your horse.  "$!{kuria}…thank you for that."  $!{xhis} face was drawn with some hard-to-read mix of emotion.  "May we yet meet as we did?  In some other place?"

            You were fairly convinced you never wanted to see ${xhim} again.  "Farewell, Breden."
            *label summerharrow
            *page_break
            You stayed as far as you could from the late summer Harrowing, the third and (you assumed) final one of the year.  Just imagining the potential disaster sent cold shudders down your spine.  What if one of those bleak-faced young troublemakers from the shack were fed to the machine?  The night before, you dreamed of a helot pointing to you and shouting, "$!{him}! $!{he}'s the one! $!{he}'s the traitor!"

            Afterward, Joana grimly reported that this time, only three elders had been chosen—aged helots who might not have survived the autumn heat in any case.  You turned away from her, trying to hide your overwhelming sense of relief.  Within an hour, it had thoroughly hidden itself under a renewed cloak of dread.

            To escape the constant anxiety, you threw yourself into your favorite pursuit:
            *choice
              #Practicing rhetoric and the art of persuasion.
                *set cha 2
                You have an instinct for inspiring and convincing others; all your life, people have tended to like you and take you seriously.  When you first began studying rhetoric with your Keriatou cousins' tutor, the cadences and tricks of the discipline came to you as naturally as breathing.

                But during the weeks after
                *if breden = 1
                  your breach with Breden, 
                *if breden = 2
                  your encounter with that maddening helot,
                you tried in vain to immerse yourself in the speeches of the greatest
                *if natlreal > 50
                  Shayardene
                *if natlreal < 51
                  Karagond 
                orators.  "Words, words…fruitless, lifeless, endless words," you finally snapped at the tutor, hurling a scroll across the room.

                She tutted mildly at you.  "Must I say it again, ${kuria}?  Yoke your anger to your purpose, and it will fill your listeners with fire.  Let it yoke you, and you become a pitiable bullock."  Stepping down from her table, she retrieved the speech and waved it at you.  "Mere words accomplished what armies could not, ${fname}."

                "And yet the world remains as it was."
                *goto least_skill1
              #Swordplay, pygmachia, and battlefield tactics.
                *set com 2
                In those unhappy weeks, your regular bouts with
                *if male
                  Hector 
                *if female
                  Calea
                were even more savagely one-sided than usual.  You were of course far too skilled to commit the social misstep of leaving your cousin visibly bruised—but whether fencing or fists, you made grimly sure ${he} left the field battered in torso, shoulder, and thigh.

                Your cousins' burly fighting master shared a sardonic chuckle with you one afternoon as
                *if male
                  Hector
                *if female
                  Calea
                limped gingerly off the court.  "Can't fault a Keriatou for ${his} persistence, I'll give ${him} that.  Stubborn as the ram on their crest.  And all of them so determined to impress you…. They keep cursing me for giving you different lessons than I give them."

                Caught off balance, you looked up sharply.  "Do you?"

                "Ha!  Only the ones where I let you try to make my face a little less pretty.  They're not interested in learning to fight without rules.  Guess they reckon they'll only be duelling nobles."  He squinted over at you.  "Not like you."

                You unwrapped the leather pygmachia bindings from your knuckles.  "From your tales, I'm guessing real enemies occasionally go for the throat."  

                "Mmmm.  If you took nothing else away, Captain ${fname}, I'm glad it's that."  You tried to hide your pleasure at the affectionate title.  

                In truth, you had avidly mined the blademaster's Halassur war stories for lessons on small-group combat tactics.
                *if female
                  You've always admired the great soldiers and generals of Shayardene history, like Samena the Charioteer or the never-defeated Elenor de Varyn.
                On many wretched, sleepless nights after your mother died, you had promised yourself that one day you would leave home, join the Phalangites yourself, and find glory in the lands beyond the Wards.  For the first time in a while, you found yourself toying with the idea again.

                *goto least_skill1
              #Reading every codex and scroll I can find.
                *set int 2
                If the ${lname} have one proud remnant of past glory, it's the family library, filling almost all of the two upper stories of your home.  It has always been a refuge for you, especially in the bitter years after your mother's death; there were enough nooks for you to remain undiscoverable for hours, nose buried in a book.  Your keen reasoning skills and memory served you well as you devoured volumes on geography, history, theology, and natural philosophy.
                
                Few of the other young nobles of Rim Square considered this a worthwhile use of time; in particular, you were much-mocked for your bookishness by your Keriatou cousins. Your father, who never voluntarily touched a scroll or codex as far as you could tell, would occasionally watch you reading with an odd expression on his face.  He didn't offer an approving word, but nor did he toss an unkind one your way, which made your books even more of a refuge.
                
                The only noble who shared your passion was the handsome young Ganelon Tarakatou, and your friendship with him was limited by the adamant grudge your father held against the boy's parents.  When you were both eleven years old, Ganelon was cuffed out of the library like a mere servant by your father, who snarled some incoherent accusation about a torn scroll.
                *fake_choice
                  #I watched in shamefaced silence.
                    You knew from bitter experience that any interference with your father's wrath would only end with a beating.
                  #I protested loudly that Father had got the wrong idea, that Ganelon would never be careless with a book.
                    Your father just cuffed you too, hard enough to make your ears ring.
                  #I actually ran up to my father and clutched at his arm, desperate to stop him from driving away my only friend.
                    For that brazen act of defiance, you were thrown to one corner of the room hard enough to knock the wind from you, and later got the thrashing of your life.
                Ganelon fled your house, weeping from shame more than pain.
                
                He kept a stiff distance for a long time afterward.  But in a community as close as Rim Square, it was impossible for the two of you to remain apart forever, especially as you both hovered around any merchant trader or traveling priest who brought books to sell to the nobility.  You found ways to meet without your father knowing, cautiously trading scrolls and engaging in hushed conversations about what you'd been reading.
                
                Needless to say, you learned more from your times with Ganelon and in the library than you did from your obligatory tutoring.  The [i]Stoicheia[/i] of Hyron was a particular pleasure, the first book that changed the way you see the world.  When you first read it years ago, you and Ganelon had both struggled to accept that everything in the cosmos could be made of only four elements.  Then came the unforgettable leap when you grasped the elegance of Hyron's method.  One of your favorite pastimes now is puzzling out which of the elements and their dynamics must be at work in different objects.
                
                You and Ganelon also managed to dig up some contraband books covering the topics your tutor left out: histories of the Halassurq Empire, 
                *if intronat
                  which had intrigued you ever since hearing Carles's ill-fated tale of Katta-kack;
                *if not(intronat)
                  the Thaumatarchy's decadent arch-enemy to the east; 
                tales of the Unquiet Dead of the ice-lands, which left you unable to sleep for days and (when you recited some) sent your Keriatou cousins shrieking for more candles; a lexicon of obscenities in all the major provincial languages.

                Several months ago, Ganelon passed you a thin vellum scroll, the most readily disposable piece of a small library he'd recently inherited from some distant aunt.  It described an odd mental exercise: to meditate on a thing's fundamental nature and then conceive it changing. The text emphasized that by doing so, you create a new world in your mind, governed by slightly different ends and purposes.  
                
                Ganelon had rolled his eyes at how abstruse and frivolous it was, but something about it had been nagging at you for months; it had a curiously practical tone for its philosophical subject matter.  You came back to it again, restless, in the weeks after your breach with Breden. "…Nothing comes into the world without purpose.  Fear does not cloud my vision.  I see the world without its masks."  The litany seemed pointlessly cryptic, and in frustration you put it away again.

                *goto least_skill1
            *label least_skill1
            Desperate to distract yourself from your gloom, you even devoted a few futile days to practicing something you've always been hopeless at:
            *choice
              *if com < 2
                #Swordplay and combat.
                  *set com 0
                  *if cha = 2
                    *set int 1
                  *if int = 2
                    *set cha 1
                  You picked up a sword and half-heartedly tried some of the poses you'd
                  *if int = 2
                    seen illustrated in a book.
                  *if cha = 2
                    been shown by a friendly young noble.
                  It all seemed to be going well…until you stumbled in a lunge, overcompensated, and felt your blade arm swing wild.  The unfamiliar weight of the sword dragged you sharply off balance.  A few ungainly hops spared you the embarrassment of ending up on your face, but you knew that any actual adversary would have had your head off.

                  If only your father had been able to get you properly trained.  As it is, if a brawl broke out, you'd have no idea how you or your friends could win it; it would all look like pure chaos to you.
                  *goto bredreturn
              *if cha < 2
                #Rhetoric and persuasion.
                  *set cha 0
                  *if com = 2
                    *set int 1
                  *if int = 2
                    *set com 1
                  You'd long been told that rhetoric was the surest path to true power. "Reflect on Her Glory, the Archon Phrygia," your tutor had often simpered.  "She did not rise to preeminence among the aristarchs through force of arms or wealth, but through her winsome and awe-inspiring powers of speech."

                  Once, you had ventured a response: "I always heard the Leilatous were Archons because they were the readiest to trade their own grandparents to the Karagonds."  You'd thought that quite a decent rhetorical flourish, frankly, but it turned out to be merely the surest path to a thrashing.

                  Now, you tried again to familiarize yourself with the speeches and style of the great orators.  Even you could tell that the words were falling flat from your tongue.  You're a plain-spoken, unassuming ${woman}, not particularly witty or compelling in speech.  If you're to win people over, it won't be through either eloquence or native charm.
                  *goto bredreturn
              *if int < 2
                #Reading and reasoning.
                  *set int 0
                  *if com = 2
                    *set cha 1
                  *if cha = 2
                    *set com 1
                  The times must have been dire indeed for you to pay a voluntary visit to the family library on the top two floors of your home. [i]Just pick up something that looks interesting,[/i] you told yourself, [i]and if your eyes glaze, you can stop[/i].

                  After several hours, you were ringed by discarded codexes and scrolls, most of which had lost you within paragraphs.  The logic and philosophy had been the quickest discards.  Granel's [i]Annals of the Conquest of Shayard[/i] had been readable for three pages, but then degenerated into lists of which Houses had held out against the Karagonds and which had decided collaboration was the better part of valor.  The latter list ran to pages, with little obsequious notes on the wisdom and courage of the three-centuries-dead turncoats.
                  *if natlreal > 50
                    (You set that one aside for a discreet burning later.)

                  Finally, you gave up—absorbing all those facts and ideas was simply too much of a struggle.  Your understanding of history, theology, and Theurgy remains at the level of fireside tales for the time being.
                  *goto bredreturn

          #I hesitate before growling, "Very well, blast it."
            You strode back to the broken-down hut without another word.
            *goto seditionhut
    #"Nothing like a little sedition on a summer evening, I always say." Quelling my anxiety, I stepped into the sweltering little hut.
      *if (breden = 2) and (proselyt < 2)
        You favored Breden with a stare that promised more words later—but as ${xhe} had gambled, you weren't about to give up the chance this represented. 
      *label seditionhut
      Breden's friends gaped silently at you as you doffed your riding cap and hung it on a splintered bit of doorframe.  "As that insufferable troubler of the peace said…I'm ${fname} ${lname}.  And yes, ${xhe}'s already heard me talk freely enough.  So let's not stop talking now."

      *set elery 2
      "Shall we talk about Kryptasts, ${kuria}?" a fierce-eyed young woman asked.  Radmar made an approving sound, halfway between a grunt and a chuckle.

      Somehow you didn't think they were asking you to share about nobles' fear of the Hegemony's assassin-spies. "I'm not
      *if breden < 2
        one.
      *if breden >= 2
        about to defend myself to a pack of helots.
      *if breden < 3
        I'm afraid
      *if breden = 3
        Your friend
      Breden's left us with little choice but to trust each other on this.  And if Breden were one, I'd have been dead months ago."
      *if breden > 1
        You think there was enough ice in your voice and expression to make clear what you thought of her disrespectful tone.

      The helot girl sounded unconvinced. "They play a long game.  Everyone knows that.  Draw as many fish as possible into the net before hoisting it."

      "You really think that's what the Kryptasts are for, Elery?" Breden cut in, eyes ablaze.  "Look what the Thaumatarchy's done to us.  They make a few people disappear, let it be known it was done by a Kryptast—and suddenly we're all watching everything we say and do around everyone, because anyone could be one of them.  But they're [i]not[/i] everywhere.  Here in the back end of Shayard, in a meeting that doesn't even include any of the aristarchs' helots…you really think we'll be unlucky enough to draw a Kryptast?"  $!{xhe} let the silence stand for several moments, then grinned. "I'll bet my life we won't."

      As Elery shrugged grudgingly, another, much younger girl—perhaps ten years old?—piped up from her perch on a rafter.  "I'll take that bet, Breden—and bet you my life that we could invite some of my friends from the Keriatou estate to these talks without trouble."

      "Thanks, Pin.  All things in good time."  Breden turned to you with a slightly exaggerated bow.  "In deference to your noble blood, ${kuria}—would you tell us what to talk about next?"
      *page_break
      *if breden > 1
        You led the next few discussions, guiding the helots away from their natural tendency to carp about their betters. Following that unfortunate initial exchange with Elery Skinner, all of the youth in the shack managed at least to feign proper deference.

        *goto cautionfade
      It took a few meetings before the helots trusted you enough to truly open up around you—before they began asking the extraordinarily uncomfortable questions like, "Nobles have a right of self-preservation and we have a duty of self-sacrifice—does it ever work the other way around?" and "Should we be inviting some of the ${lname} helots to join us?"  On the latter point, you quickly convinced them that it would be too risky, and then spent the next few days wondering uneasily about your motives.

      *label cautionfade
      As the helots' caution faded, they began sharing every story of revolt against the Thaumatarch that any of them knew.  The one you'd previously heard least about was:
      *choice
        #The yeoman rising of Ester Cabel.
          *gosub cabel
          *goto heltrustwin
        #Sarcifer, the renegade archmage.
          *gosub sarcifer
          *goto heltrustwin
        #The Laconniers, keepers of the Sovereign Bloodline.
          *gosub laconniers
          *goto heltrustwin
      *label heltrustwin

      You won the helots' trust, in part, by sharing something of your greatest skill:
      *set cred_h +5
      *choice
        #Rhetoric and the art of persuasion.
          *set cha 2
          Breden, like you, had a powerful natural knack for inspiring and convincing others—but of course neither ${xhe} nor any other helot had been taught any skills of rhetoric.  You, on the other hand, had taken to the discipline like breathing, ever since your first session with your cousins' oratory tutor.

          "You want to convince more helots to start talking freely?" you enticed the group.  "Well, there are ways of making an argument—cadences, structures, imagery—that the great rhetors of Karagon and Shayard have been refining for generations…."

          "Tricks," Radmar 
          *if breden = 1
            summed up, 
          *if breden > 1
            whispered when he didn't think you'd hear,
          but 
          *if breden = 1
            his scorn affected you much less than the avid expression on Breden's face.  
          *if breden > 1
            was shushed by an avidly attentive Breden.
          Blind Yebben Skinner, Elery's twin, had a natural way with words, and Pin also soaked up your lessons with delight.  You fought to keep from laughing each time the helot child took a declamatory stance and began piping out the speeches of Oenone Magna.
          *goto least_skill2
        #Swordplay, pygmachia, and battlefield tactics.
          *set com 2
          "You could beat us with your own hands, then, ${kuria}?" Radmar said with obvious skepticism as you headed out into the woods for practice.

          "If we were unarmed and alone, 
          *if breden = 1
            I'd not give myself good odds against you, 
          *if breden > 1
            your raw animal qualities would stand you in good stead,
          Radmar."  Your skill at pygmachia (fist-fighting) would only get you so far against someone with his bulk.  "With swords, of course, any noble would have an obvious advantage.  And if we were both leading groups…yes, I dare say mine would win."  You've practiced extensively with House Keriatou's blademaster on duelling, and you learned a lot about small-group combat tactics from his stories of battling enemies in the lands beyond the Border Wards.

          "Ha!" Radmar grinned ferociously.  "Begging your grace, ${kuria}, if we had enough here for two sides of scrum-ball, I'd test you on that."

          "Scrum-ball?"  You blinked at Breden.

          "You've never seen 
          *if breden = 1
            it?" ${xhe} laughed.
          *if breden > 1
            it, ${kuria}?" ${xhe} inquired in polite tones.
          "Two mobs at opposite ends of a field, each trying to get a bladder to the opposite end.  Lots of friendly violence, occasional broken arm."

          "Ah.  That.  I hadn't realized it had a name."

          "Everyone knows that if you listen to Radmar's advice, you'll win at scrum-ball," the big helot declared smugly.

          "Unless Elery Skinner is on the facing side!" Elery called, smacking Radmar on one muscled shoulder.  "You're a great bull, Rad.  It's too easy to outfox you when you're blind in the midst of the scrum."

          When you arrived in a secluded glen, you began to show Breden's friends:
          *choice
            *if breden > 1
              #Just pygmachia, of course.  Arming helots would be dangerous and, worse, vulgar.
                All the old histories confirmed that a weapon-wielding helotry was a measure for only the direst of emergencies.  You didn't think things had deteriorated to that extent.  

                "Without the honor of your House to defend, none of you will be bound by pygmachia's strict code of conduct," you explained as you squared off against Elery.  "Nobles fight without visible bruises or bleeding.  So nothing to the face or lower arms."  You jabbed one leather-wrapped fist toward her nose, and she barely ducked away in time.  "Needless to say, that's not what I'll be showing you."

                "As if none of us had been in a punch-up?" Radmar murmured to the skies.

                "Shut it, Radmar," Elery growled.  "Come on, then, ${kuria}…show us how you'd do it if you were actually trying to win."
                *goto least_skill2
            *if breden = 1
              #Just pygmachia.  I still felt an unease at teaching helots any combat skills that could be deployed against their masters.
                "In any noble pygmachia bout, they're hedged in by a strict code of conduct," you explained as you squared off against Elery.  "The fight should not result in visible bruises or bleeding.  So nothing to the face or lower arms."  You jabbed one leather-wrapped fist toward her nose, and she barely ducked away in time.  "Needless to say, that's not what I'll be showing you."

                "You truly think we need you to show us how to win a punch-up?" Radmar asked incredulously.

                "Shut it, Radmar," Elery growled.  "Come on, then, ${kuria}…show us how the aristos do it when they're actually trying to win."
                *goto least_skill2
            #Combat tactics.
              *set cred_h +7
              *set cred_a -10
              *if breden > 1
                It was a great gamble on your ability to convince the helotry that the Thaumatarchy was their true enemy…but your presence with the group was all a gamble in any case.
              You wondered what the Keriatou's burly, no-nonsense blademaster would make of his training on small-group tactics being passed on to a helot gang in the woods.  Belying his air of sullen disdain, Radmar soaked up your lessons with an almost alarming eagerness.

              Along with hunting small game, scrum-ball provided the natural language for Radmar and Elery to express their intuitive grasp of basic tactics.  While you didn't ever play an actual game, you soon picked up the "rules" and found it a useful frame for your lessons.  

              You also found out that several of the helots were practicing with clubs and staves in secret for self-defense; when you squared off against them with a sword-stick, they put up a remarkably good fight.  It wasn't easy to explain some of the bruises to your father and cousins.
              *goto least_skill2
        #Encyclopedic knowledge and reasoning skills.
          *set int 2
          If the ${lname} have one proud remnant of past glory, it's the family library, filling almost all of the two upper stories of your home.  Its dusty recesses have always been your refuge, especially in the bitter years after your mother's death.  Needless to say, with your keen memory and reasoning skills, you learned more there than you did from your obligatory tutoring.
          
          Few of the other young nobles of Rim Square considered this a worthwhile use of time; in particular, you were much-mocked for your bookishness by your Keriatou cousins. Your father, who never voluntarily touched a scroll or codex as far as you could tell, would occasionally watch you reading with an odd expression on his face.  He didn't offer an approving word, but nor did he toss an unkind one your way, which made your books even more of a refuge.
                
          The only noble who shared your passion was the handsome young Ganelon Tarakatou, and your friendship with him was limited by the adamant grudge your father held against the boy's parents.  When you were both eleven years old, Ganelon was cuffed out of the library like a mere servant by your father, who snarled some incoherent accusation about a torn scroll.
          *fake_choice
            #I watched in shamefaced silence.
              You knew from bitter experience that any interference with your father's wrath would only end with a beating.
            #I protested loudly that Father had got the wrong idea, that Ganelon would never be careless with a book.
              Your father just cuffed you too, hard enough to make your ears ring.
            #I actually ran up to my father and clutched at his arm, desperate to stop him from driving away my only friend.
              For that brazen act of defiance, you were thrown to one corner of the room hard enough to knock the wind from you, and later got the thrashing of your life.
          Ganelon fled your house, weeping from shame more than pain.
                
          He kept a stiff distance for a long time afterward.  But in a community as close as Rim Square, it was impossible for the two of you to remain apart forever, especially as you both hovered around any merchant trader or traveling priest who brought books to sell to the nobility.  You found ways to meet without your father knowing, cautiously trading scrolls and engaging in hushed conversations about the many topics you both found fascinating—trade, history, even a bit about Theurgy.

          You brought all that knowledge to the covert helot meetings, along with some of your scrolls for reference.  None of the helots had ever learned the alphabeta, of course.
          *choice
            #And I didn't see much point in trying to teach them.
              While you cherish everything you've learned from books, you recognize that reading is a luxury pursuit.  Few except nobles and priests have any use for it, and you doubt that most helots would even have the natural capacity to retain letters in their memories.  You reckoned it would be more useful to share knowledge with them directly.
              *goto thisscroll
            #So I started to teach them.
              Reading may seem like a luxury to others—but you know that it's key to learning anything beyond your immediate sphere of experience.  These helot discussions will be far more effective if they have some idea of what's going on beyond the borders of the district.  Sharp-eyed Elery started to pick up the letters quickly, as did young Pin.
              *set cred_h +6
              *set cred_a -6
              *set literate +10
              *goto thisscroll
          *label thisscroll

          Like you and Ganelon, the helots particularly relished debating the [i]Stoicheia[/i] of Hyron, which explains the world in terms of the dynamics of the four elements.  "We're truly supposed to believe that all this," Radmar rumbled, gesturing at the swamp and forest, "can be whittled down to Four?"
          
          "It seems odd at first," you agree, "but when you've thought about it for a while, you learn to reckon which elements must be at work in different parts of the plant or soil or animal, and it makes sense."
          
          *if breden > 1
            *goto thatscroll
          One day you read to the group from a scroll describing the patterns of tax and trade in Shayardene regions, then glanced around.  "Hear anything of interest in all those words?"  After a few moments' bored silence, you prompted: "I've often heard my Keriatou cousins boast that they 'feed the district' by bringing in Theurges and deploying their helots to give them four or five harvests a year."

          Blind Yebben Skinner, Elery's twin, spoke up. "But in truth, they're selling almost all their grain to the capital."

          "Exactly."  You point to the figures on the scroll that, as of yet, no one else in the group can understand.  "This tells us that when the Keriatou open 'their barns' at Angelday, they're handing out grain they bought cheap from the smaller Houses and yeoman farmers of the Rim…with drachems earned through far more profitable trade with Shayard City and other provinces."

          Radmar scowled in exasperation.  "So?"

          Breden said levelly, "So the greatest part of our blood and labor is spent not on food to bring us all through the hard winter, nor even on Wards to hold back Xaos, but on silver for the aristarchs."  A low mutter went round the hut.
          *page_break
          *goto pinvellum

          *label thatscroll
          One day you had just finished reading from some abbreviated histories of Shayard.
          *label pinvellum
          "What's this one, ${kuria}?" Pin asked, holding up a thin vellum scroll from your bag. 

          You frowned, taking it from her and unrolling it.  "An odd one."  Last autumn, Ganelon passed you the most readily disposable piece of a small library he'd recently inherited from some distant aunt—and something about it had been nagging at you for months.  
          
          The scroll described an odd mental exercise: to meditate on a thing's fundamental nature and then conceive it changing. The text emphasized that by doing so, you create a new world in your mind, governed by slightly different ends and purposes.  Ganelon had just rolled his eyes at how abstruse and frivolous it was.  You almost agreed, but found yourself intrigued by the curiously practical tone wedded to its philosophical subject matter.  
          
          But the litany at its heart seemed pointlessly cryptic.  "…[i]Nothing comes into the world without purpose.  Fear does not cloud my vision.  I see the world without its masks.[/i]"  You read a bit aloud, then shrugged to Pin. "I carry it because I'm trying to figure out if it's good for anything.  No luck so far."
          *goto least_skill2
      *label least_skill2

      To your embarrassment, the helots also soon found out about your greatest area of weakness:
      *choice
        *if com < 2
          #Swordplay and combat.
            *set com 0
            *if cha = 2
              *set int 1
            *if int = 2
              *set cha 1
            One afternoon you found the group covertly practicing self-defense with staves and clubs.  "Show us some of that fancy bladework that you aristos learn, ${kuria}?" Radmar asked, tossing you a roughly sword-length branch.

            "In truth," you ventured, "my House wasn't rich enough to have me properly trained…."  You half-heartedly tried some of the poses you'd
            *if int = 2
              seen illustrated in a book.
            *if cha = 2
              been shown by a friendly young noble.
            They felt decent enough, but it took Elery all of five seconds to disarm you with her staff.

            Ears burning at their suppressed smirks, you retired to the margins and watched them ruefully for the rest of the afternoon.  When they ended with an all-on-all melee, it looked like pure chaos to you; if a real brawl broke out, you have to admit you'd have no idea how you or they could win it.
            *goto poricmullow
        *if cha < 2
          #Rhetoric and persuasion.
            *set cha 0
            *if com = 2
              *set int 1
            *if int = 2
              *set com 1
            When you tried to give an account of how you came to despise the Thaumatarchy, you could feel the words falling flat from your tongue.  The helots glanced at each other, visibly unimpressed.  "You're plain-spoken for a noble, ${kuria}," Pin pointed out with unadorned candor.  "I'd thought you were all trained to win people over with the way you talk."

            "In truth," you ventured, ears aflame with embarrassment, "my House wasn't rich enough to have me properly trained in rhetoric."  

            "You'll just have to win people over by the wisdom in your words, ${kuria}," Elery said, not without sympathy.  "Leave the charm and sweet talk to folk like our Breden."
            *if breden = 3
              
              Of course, the last thing you wanted was to rely on the charm and eloquence of the most unreliable and froward helot you knew; and as you glanced grimly over to Breden, you could tell that ${xhe} knew it.
            *goto poricmullow
        *if int < 2
          #Reading and reasoning.
            *set int 0
            *if cha = 2
              *set com 1
            *if com = 2
              *set cha 1
            At the height of an argument with Blind Yebben on the difference between aristocrats and helots, Breden suddenly appealed to you.  "You can settle this, ${kuria}.  Before the Karagond conquest of Shayard—did Shayardene nobles keep helots?"

            "Um."  It was an elementary historical question, but you found yourself at a loss.
            *if breden > 1
              "I'm sure I can confirm that when I return home tonight."
            *if breden = 1
              "I…I don't believe so, but I should really look…I think our library has a book that might answer that question."  
            You weren't sure, though; you only visited the ${lname} library in the direst of circumstances.  

            "Don't they teach you things like that, ${kuria}?" Pin inquired with unadorned curiosity.

            "Well, yes,
            *if breden > 1
              child,
            I had a tutor, but…"  Absorbing all those facts and ideas had always seemed too much of a struggle; your understanding of history, theology, and Theurgy remains at the level of fireside tales.  "I always felt there were more important things to spend my time on, to be honest."
            *goto poricmullow

*label poricmullow
*page_break
As the season turned, your weekly meetings with the young helots began to seem almost routine.  Then the day came when you went up to the de Rose hut and found no one there.  Scouring the wooded marsh frantically for any sign of Alastors, you finally spied a familiar silhouette atop an old fence, a few hundred yards from your normal meeting place.

"$!{kuria}," Breden acknowledged your approach dully.  $!{xhe} was staring at the late afternoon reds and oranges in the swamp water.

"Where is everyone else?"

"Lying
*goto haventheard

*label bredreturn
*page_break
At the turn of the season, you were walking back from the ${lname} orchards when you saw a familiar silhouette perched on a fence ahead.  
*if breden = 1
  Your pulse quickened despite yourself; you weren't sure whether it was elation or anger.

  "$!{kuria}," Breden dully acknowledged your approach.

  "Breden," you returned warily.  "What brings you here?"

  "There's no one else to talk to, ${kuria}.  Everyone else is lying
  *goto haventheard
*if breden > 1
  You stopped a few paces from ${xhim}, feeling your pulse quicken.  "I'd not thought we'd have anything more to say to each other, ${xgirl}."

  Breden looked back at you, eyes level and unsparing. "Nor did I, ${milady}."  You noted the tension in ${xhis} jaw, the hands clenched in ${xhis} lap. "But I've no one else to talk with today.  And I found myself curious what you thought of the news from the Pelematou estate."

  "I've no idea what you're talking about," you said warily.
  *choice
    #"Nor will I be drawn into any further discourse with you." I gave ${xhim} a wide berth as I resumed my homeward journey.
      *label bedamned
      "Then be damned, ${kuria} ${lname}," Breden said softly as you strode past.
      *if bred_heart < 10
        There was a vehemence to ${xhis} voice that hadn't been there before.
        *set bred_heart +10
      "You're no true threat to our enemy, and you never will be."
      *choice
        #I ignored ${xhis} petty insults.
          *label pettyignore
          *if int < 2
            Breden's venomous words nonetheless haunted you as you walked home.  All the things you'd never spoken aloud before meeting that wretched helot…would they remain only words?  Surely, you told yourself, there would be some way to challenge the evils of the Thaumatarchy without hazarding everything on a gang of treacherous, backbiting chattel.  Given time, you'd find it.
          *goto moreharrowing
        #I cast one final withering retort at ${xhim}.
          "You're a threat only to yourself, ${xgirl}," you snarled. "How you've lived so long, I can't imagine."

          *goto pettyignore
        *if com>0
          #I drew my sword and attacked ${xhim}.  I would tolerate no more insults from this helot.
            *goto bred_sword
        *if com=0 
          #I took my walking cane to ${xhim}.  I would tolerate no more insults from this helot.
            *goto bred_cane
    #"Explain yourself."
      *label explainporic
      "One of the Pelematou helots, Poric Weller, was caught with a fistful of mullow."

      You raised an eyebrow.  "Eating it with some lass?"  Helots were strictly forbidden the herb mullow; it went against their collective duty to maintain their numbers.

      "Some lass?" Breden laughed bitterly.  "Poric and Radmar were happy together, ${kuria}.  No need of mullow there.  No, he was bearing it to lady Pelematou's son Georden.  Naturally, the young man didn't want to admit to his mother that he was breaching chastity. So when Poric let slip his name in the beating, he cried slander."

      "And the penalty?"

      "They took his tongue, ${kuria}.  Broke half the bones in his body, too."  Breden slipped from ${xhis} perch on the fence and walked toward you, ${xhis} face bleak.  "Radmar is caring for him now, and none of the others will venture out of the camp.  Especially the women who might now be accused of eating mullow with Poric."
      *choice
        #"If your friend Radmar were here, I'd offer condolences."
          "No doubt he'd welcome them," Breden said
          *if bred_heart >= 10
            with curled lip.
          *if bred_heart < 10
            tonelessly.
          "And if Georden Pelematou were here, ${milady}?  What would you say then?"
          
          By now ${xhis} impertinence was no surprise, but it still brought a scowl to your face.  "Say what you mean to say."
          
          *goto bredfirstspoke
        #"And you thought this had something to do with me?"
          *label bredfirstspoke
          "When we first spoke, ${kuria}, you said you wanted us to stop railing against our masters and save our energies for our true oppressors.  And believe it or no, we agree that the Thaumatarch is our worst enemy." Breden's face was savage with grief. "But damn it, ${kuria}…can you stand there and tell us not to rail against this?"

          "I'd say…" you began, but ${xhe} disregarded you and kept talking.

          "Our enemy is whoever tortures us, rapes us, kills us, sends us to the Harrower.  Foreign-born or high-born, it doesn't matter."  $!{xhe} stopped within arm's length of you, eyes wide and white.  "What happens with the nobles who are the enemy?  If Radmar swore to feed kurios Georden his own lying tongue?"
          *choice
            #"It would be no more than the perfidious Pelematou coward deserved."
              "Truly?" Breden paused, taken aback. "It's the first I've heard you say such things of your kin, ${milady}…."
              
              "That's because you drove me away first, you little ass."  You pressed in fiercely while ${xhe} was off balance.  "Of course, some aristos are as much the enemy as any Karagond.  That doesn't mean you and your seditious little gang should waste your energies on the first unworthy noble who abuses you.  Attacking lady Pelematou and her worthless son now will only leave the Alastors grinning and the nobility fleeing your cause."

              "Xthonos, ${kuria} ${fname}." Breden gave a hollow chuckle and raised ${xhis} hands.
              *if bred_heart >= 10
                There was a visible softening in ${xhis} face.
                *set bred_heart -10
              "It'll be as much as I can do to convince my friends to meet for talk again.  No one's actually going to do anything to a Pelematou just now."

              "Well…good."  To your surprise, you found yourself not entirely sure you meant it.  [i]A rising![/i] cried the enraged part of you that Breden had reached with ${xhis} questions at the crossroads. [i]Revolt![/i]

              "But if we do begin talking again…" The young helot looked as if ${xhe} were struggling with the words. "What would you say if I invited you to join us?"
              *fake_choice
                #"No.  But for what it's worth, rogue, I wish you well."
                  "And I you, ${kuria}."  Breden searched your face with wary eyes.  "I can't help feeling that we're traveling to the same place.  I wish…well, I hope you find some road that better fits your station."
                #"No.  That chance is gone."
                  Breden looked unsurprised.  "So be it.  Then may the Angels watch your path, ${kuria} ${lname}.  We likely won't speak again."
                #"I might consider it. Were the invitation less manipulative than, say, tossing me unannounced into a pack of helots and telling them I planned to kill the Thaumatarch."
                  "I won't repeat that mistake."  For the first time since you'd met ${xhim}, you thought Breden might be genuinely penitent. "Then I'll ask my friends to consider it as well, ${kuria}.  We may yet find ourselves on the same road again."
              $!{xhe} bowed and vanished into the woods.
              *goto moreharrowing
            #"He'd deserve it.  But it's no place of yours to mete judgment against your betters, ${xgirl}."
              "I thought you'd say so, ${kuria}."  Breden struggled to hide the contempt in ${xhis} voice.  "Then whose place is it?"

              "There is no rightful order while we live in a Thaumatarchy," you temporized,  "but in lieu of a legitimate monarch…well, the aristarch ought to be the one to judge a noble for cruelty or excess…."

              "Your cousin, lord Keriatou?" Breden cut in coolly.  "You know, he's the reason Poric's alive, ${kuria}?  After Olen was beaten to death in the spring, our noble aristarch told off lady Pelematou.  Said it was a waste of a big man with lots of blood in him, and the Theurges wouldn't approve."  $!{xhe} leaned in, glowering at you.  "Your cousins only care about keeping the Hegemony happy, ${kuria} ${lname}.  You know that."

              "Had you not interrupted me, villain, you'd have heard me say so," you snapped.  "The point is, nobles judge nobles.  Even in a corrupted order, that principle must be preserved."

              "So it will be you, ${kuria}?"  You could almost feel Breden's breath on your face. "When the changes we've talked of begin, and judgment is needed—you'll be the one to mete out justice?"

              "Watch and see, helot."  Neither of you spoke for a minute, eyes locked bleakly on each other.  Finally Breden shrugged, offered you a cursory bow, and walked away.
              *goto moreharrowing
            #"Control yourself, helot!  I'll hear no more of this whinging."
              *goto bedamned
        #"I've no interest in hearing any more complaints."
          *goto bedamned
    *if bred_heart < 10
      #"But I'm listening."  I was willing to give ${xhim} one more chance.
        *goto explainporic

*label haventheard
low."  As ${xhe} craned ${xhis} neck to regard you, you noticed the tension in ${xhis} jaw, the hands clenched futilely in ${xhis} lap.  "You haven't heard?"

"Heard what?" you said, perhaps a little defensively.

"The Pelematou?" At your blank expression, ${xhe} looked away again. "One of their helots, Poric Weller, was caught with a fistful of mullow."

You began to understand.  "Ah.  He was eating it with some lass?"  Helots were strictly forbidden the herb mullow; it went against their collective duty to maintain their numbers.

"Some lass?" Breden laughed bitterly.  "Poric and Radmar were happy together, ${kuria}.  No need of mullow there.  No, he was bearing it to lady Pelematou's son Georden.  Naturally, the young man didn't want to admit to his mother that he was breaching chastity. So when Poric let slip his name in the beating, he cried slander."

*if breden > 1
  Breden's voice was beginning to take on an accusatory tone that you didn't quite understand, but found unseemly.
*if breden = 1
  You felt your throat tighten.
"The penalty?"

Breden turned hollow eyes on you.  "They took his tongue, ${kuria}.  Broke half the bones in his body, too.  Radmar is caring for him now, and none of the others will venture out of the camp.  Especially the women who might now be accused of eating mullow with Poric."
*if breden > 1
  *page_break
  "If Radmar were here, I'd offer condolences," you said steadily. "Lady Pelematou is well known for her excesses in discipline."

  "You would consider this excessive, ${kuria}?"

  "Taking someone's tongue—for something they all surely know is no slander?"  Your mouth twisted in disgust.  "For a truth told under ordeal?  Of course it's excessive.  The rights of nobility don't extend to unnecessary brutality."

  "Unlike all the necessary brutality."  Breden gave a soft and mirthless laugh as ${xhe} slid off ${xhis} perch.  "Do you know the reason Poric's alive, ${kuria}?  Because after Olen was beaten to death in the spring, your noble cousin lord Keriatou told off lady Pelematou.  Said it was a waste of a big man with lots of blood in him, and the Theurges wouldn't approve."  $!{xhe} shook ${xhis} head.  "There's no mercy for helots in this world, ${milady}.  It's all cruelty.  It's all monstrosity. And all our roads end at a Harrower."
  *choice
    #I was genuinely shaken.   My affection for these helots had grown over the last few months, and it was easy to imagine one of them suffering Poric's fate.
      *label drymouth
      "Breden…." You found your mouth dry. "I hear you, truly.  And I'd not see you bear so much cruelty.  
      *label longroadoff
      In a better world, I and those like me could protect you."

      "That world's a long road off, ${kuria}," ${xhe} retorted flatly. "And the Hegemony's squarely in the way—along with many of your noble kin.  What do you mean to do about it?"
      *choice
        #"Revolt."
          *set rebelrebel 1
          Breden's little group of helots had been dancing around the word for weeks without speaking it openly. Now it hovered in the air between you, each moment of silence seeming to amplify rather than extinguish it.  You spoke again, thick-tongued: "Revolt…"
          *choice
            #"…against the Karagonds and any of my so-called kin who stand with them."              
              *set breden 2
              *gosub groundswell
              "Of course it's coming to a rebellion.  And of course we'll have to fight some aristos, as well as the Karagonds.  Just don't waste your energies on the first unworthy noble who abuses you.  Attacking lady Pelematou and her worthless coward son now will only leave the Alastors grinning and the nobility fleeing your cause."

              Breden swore softly.  "Bloody Xaos, ${kuria}…if you are a Kryptast, you're a fine one."
              *goto shouldbegone
            #"…against the Hegemony. And bring the Shayardene nobility onto our side."
              *set breden 2
              *gosub groundswell
              "Yes, by all Angels.  Once we've won over enough stout hearts, once we have the numbers to stand against them."

              "And you truly think you'll bring your kin alongside a helot rising?" Breden's face was wistful, belying the note of incredulity in ${xhis} voice. "The aristos didn't even join the great yeoman rising in the Westriding forty years back.  You truly think it'll be different with a pack of helots in the Outer Rim?"

              "As long as we don't make enemies of them," you insisted.  "Show them that the alternative to Karagond oppression is not a Xaos where every soul is at war with every other.  Vouchsafe them their old liberties, and yes, you'll see them rise!  I'm not the only ${woman} who sees that nobles are too few to cast out the Thaumatarch without Shayard's bold commons and helotry."

              Breden swore softly.  "Bloody Xaos, ${kuria}…if you are a Kryptast, you're a fine one."
              *goto shouldbegone
            #"…against the Thaumatarch."  I leave unspoken whether I see my fellow nobles as likely allies or foes.
              *gosub groundswell
              
              To your intense annoyance, Breden refused to ignore the question you chose to. "And when some of your noble kin stand with the Thaumatarchy, ${kuria}?  When it's not only the Karagonds on the other side?"
              
              "When a great Rising begins, ${xgirl}, we'll all see who stands with us and who with the enemy.  Not until then."
              
              Breden stared at you, disappointment plain on ${xhis} face.  "As you say, then, ${kuria}."
              *goto shouldbegone              
        #"To lay down my life."
          "To speak aloud what's true and just, and try to win over all true-hearted folk to a better way."  You swallowed hard, thinking of how few people you know who would listen.  "Even should the Hegemony find out, and kill me for it."
          
          "And you think your talk, your sacrifice, will be enough?" Breden's stare was incredulous.  "You think that will change anything?"
          
          "It's the only way to make a change without throwing all into Xaos," you retorted. "The world we need can only come into being through Orderly change, ${xgirl}."
          
          Breden's lips twisted bitterly. "And through sacrifice.  As we've always heard."
          *goto shouldbegone
        #"Whatever is necessary."
          You weren't sure yourself how far you would go.
          *gosub rebelthoughts
          To your relief, Breden didn't push you any further, just stared at you for a few moments with an expression of disappointment.  "I hope we all recognize the moment when we get there, ${kuria}."
          *goto shouldbegone
        #I fell silent, realizing there was no honest answer I could give ${xhim}.
          In truth, you didn't know what you would be ready for.
          *gosub rebelthoughts
          When you didn't speak, Breden's lips twisted bitterly. "As I'd thought, ${kuria}." 
          *goto shouldbegone
    #I told ${xhim} to come to the point.  What did ${xhe} expect from me?
      *label whatexpect
      "You began talking with us, ${kuria}, because you wanted us to stop railing against our masters and save our energies for our real oppressors.  And you know we all agree that the Thaumatarch is our real enemy." Breden's face was bleak with grief. "But damn it, ${kuria}…at some point we have to stop pretending."

      "I don't want to hear—" you began, but ${xhe} simply disregarded you.

      "Our enemy is whoever tortures us, rapes us, kills us, sends us to the Harrower.  Foreign-born or high-born, it doesn't matter."  $!{xhis} eyes were wide and white.  "What happens with the nobles who are the enemy?  What if Radmar swore to feed kurios Georden his own lying tongue?  What if your Keriatou cousins fight to keep the Karagonds here, because that's where they get their power?  At what point do we lose you?"
      *choice
        #"You lost me, ${xgirl}, with this little outburst."
          Breden nodded ruefully but without surprise.  "Tell me, ${kuria}.  What kind of game do you think we're playing here?"

          "No game, ${xgirl}."  You were already turning to leave.

          *label bred_outburst
          *set breden 3
          *set bred_heart +10
          "You truly think you can just get rid of the
          *if natlreal > 55
            foreign yoke
            *goto getrid
          *elseif skepreal < 46
            blaspheming Karagonds
            *goto getrid
          *elseif skepreal > 55
            lying Ecclesiasts
            *goto getrid
          *elseif ruthreal < 46
            murderous Hegemony
            *goto getrid
          *else
            Hegemony
            *goto getrid
          *label getrid
          while everything else remains unchanged?"  $!{xhe} dogged your heels as you strode away.  "You expect the helots to support you aristos against the Thaumatarch, even as you kill us?"

          "I expected you to respect 
          *if skepreal < 45
            Xthonos's sacred
          *if skepreal > 44
            right 
          order, even in the face of an exceptional provocation.  Perhaps that was an error."

          Breden halted, ${xhis} voice stony.  "Scapewell, then, ${kuria}.  As long as none of our little group is harmed, your treason is safe with us."

          Whirling, you faced ${xhim} with incredulous horror. "You dare?"  Some part of your mind was weighing up 
          *if com = 2
            how quickly you
          *if com < 2
            who
          would win if it came to blows.

          The undisguised flash of rage on Breden's face was more astonishing than anything ${xhe}'d yet said aloud.  "I dare? You bloody arrogant aristo, you still expect…You think you can play at rebels with us and then just walk away?  Leave us quivering, wondering if you'll have us killed, while you put the risk behind you like it's last year's Court fashion?"  $!{xhis} mouth twisted with contempt.  "No, ${kuria} ${fname}.  You get to fear, too.  You've put your life in the hands of a pack of helots…and that's where it will stay for the rest of our days."
          *choice
            *if (com>0)
              #I drew my sword and attacked ${xhim}.  I could never tolerate such a threat from a helot.
                *label bred_sword
                *set breden 4
                For a fragment of a second, Breden's eyes went wide and hurt.  Then ${xhe} ran, rabbit-fleet, vaulting the fence and heading for the woods without looking back.  

                The gap between you widened until it became clear that whatever your advantage with a weapon, Breden could simply outrun you; you could barely see ${xhim} through the thickening forest when you finally stopped.  Turning back to Rim Square, you gradually recovered your breath and temper.
                *label bred_regrets
                *fake_choice
                  #The thought nagged at me that my assault on the helot had perhaps been imprudent.
                  #I didn't regret a damned thing.
                  #I wasn't sure why I felt so…heartbroken.
                *goto moreharrowing
            *if (com=0)
              #I took my walking cane to ${xhim}.  I could never tolerate such a threat from a helot.
                *label bred_cane
                *set breden 3
                *set bred_heart 10
                Breden leapt back across the fence and, five strides away, found a bough of ${xhis} own.  

                Despite everything, you couldn't help but gape at ${xhim}.  "Knave—do you know how painfully I could have you killed for raising your hand to a noble?"

                "$!{kuria}," ${xhe} countered breathlessly, "don't be a fool.  Speak a word against me, and hieros Zebed will hear that ${fname} ${lname} has been inciting helots against the Thaumatarchy."  $!{xhe} nodded at your cane with a savage grin.  "Also, I've seen what you can't do with that thing…remember?"
                *choice
                  #I went for ${xhim} anyway, counting on rage and luck to overcome.
                    You vaulted the fence and lunged for Breden—and
                    *if rageluck = 15
                      while your attack came nowhere near ${xhim}, by a fluke it left your cane in just the right place. You clumsily deflected ${xhis} returning blow.  When the flustered helot pushed forward, trying to disarm you, you let the cane fall and flung yourself savagely onto ${xhim}.

                      "What now, knave?" you shrilled at ${xhim} as the two of you landed in the dust, your fists pummelling at ${xhis} head.

                      $!{xhe} rolled out from under you, face bloodied and bruised, and fled for the trees without another word.  You swayed to your feet, giddy with unexpected triumph.  If only your cousins had been here to see [i]that![/i]
                      
                      As you walked back to Rim Square, though, the memory of Breden's bitter words slowly wrung the elation from you.
                      *goto bred_regrets
                    *else
                      with three swift blows, ${xhe} turned your attack aside, sent your cane flying from your grip, and lightly touched your forehead with ${xhis} stick.  
                      
                      "It's how you nobles fight, isn't it, ${kuria}?" ${xhe} murmured, eyes fixed hotly on yours.  "No bruises where they can be seen?"
                      
                      "Go to Taratur," you barked, almost incoherent with shame and dudgeon.  "Strike me and have done."
                      
                      "Go home, ${kuria}." Breden strode off into the trees.
                      *goto moreharrowing
                  #I threw a final insult in ${xhis} face and stalked away.
                    "Contemptible little plow-rat," you snarled, lowering your cane.  
                    *label unnatural_defy
                    "I'll not dignify your unnatural defiance further."
                    
                    "Go home then, ${kuria}." Breden scowled at you, then 
                    *label bredenraisev
                    raised ${xhis} voice as you walked off.  "Go grumble with your fellow nobles about the wicked Karagonds and knavish helots.  But from now on, every day you draw breath…it's because of our courage!  Our honor!"
                    *goto moreharrowing
            #I rebuked ${xhim} for this despicable show of pique.
              "How low a soul, that when its mask slips such contemptible bile streams out!" Your lip curled.
              *goto unnatural_defy
            #Responding to an honorless helot in any way would only demean me.  I stalked away.
              "Go then, ${kuria}!" Breden
              *goto bredenraisev
        #"If you lose sight of the real enemy…if you can be distracted by the occasional noble abuse?  Yes, you'll lose me."
          "Occasional?"  Breden's mouth stretched with something between laughter and anguish.  "Damn it all, ${kuria} ${lname}.  Harrowing is occasional.  We have to fear Theurges two, maybe three times a year.  But every day, we fear that someone we care for will fall afoul of lady Pelematou's temper, or be taken as a plaything by one of your cousins.  You don't see that?"
          *choice
            #I have to admit I do.
              *set ruthreal %-10
              *goto drymouth
            #I don't have to admit any such thing.  Even if it's true.
              "It's an ugly world, Breden," you said, trying to sound noncommittal.  "The Thaumatarch's cruelty has tainted everything.
              *goto longroadoff
            #This is just helot whinging, and I'll put up with it no longer.
              *set ruthreal %+10
              "No," you said sharply. "I see a helot who is dangerously close to confusing the unnatural dominion of Karagon with the natural dominion of the Shayardene nobility.  The former is never acceptable; the latter does not become unacceptable simply because of the abuses of a few."

              Breden's voice was as harsh as your own.
              *goto bred_outburst
        #"You won't lose me," I promised, to keep ${xhim} and ${xhis} friends from running off.
          "I'm not that easily deterred," you said, hoping ${xhe} believed you, "and I'd not see you abused by anyone, Karagond or Shayardene.
          *goto longroadoff
        #"You won't lose me," I swore sincerely.
          *goto drymouth
    #I warned ${xhim} that ${xhe} was, once again, reaching an unacceptable level of presumption.
      "Damn it, ${kuria}."  $!{xhis} eyes were aflame.  "Life's too short, and this too important, for me to keep curbing my tongue for you."

      "Your life is like to be short indeed, at that rate," you retorted. "One last bit of counsel, then, if you're set on this unruliness.  Don't turn against your masters.  Make us your enemy, and you'll end up devoured by Xaos."

      You could see that the impertinent helot was in no state to heed your words.
      *choice
        #So I left.
          Breden's voice was as harsh as your own.
          *goto bred_outburst
        *if com>0
          #So I drew my sword to chase ${xhim} away.
            *goto bred_sword
        *if com=0
          #So I took my walking cane to ${xhim}.
            *goto bred_cane
        #But I hoped a bit of persistence might yet calm ${xhim} down.
          "Speak, then," you said guardedly.  "What exactly do you mean by all this?"
          
          *goto whatexpect
*if helotrefuse
  *page_break
  "I'm so sorry," you said helplessly.  "$!{oath}, that's barbaric."
  
  "What is?"  To your surprise, Breden sounded genuinely baffled.
  
  "Taking someone's tongue for…for something they all surely know is no slander."  Your mouth twisted in disgust.  "For a truth told under ordeal.  The rights of nobility don't extend to unnecessary brutality.  It's obviously…it's monstrous."
  
  "Unlike all the necessary brutality."  Breden laughed softly and mirthlessly, sliding off ${xhis} perch.  "Do you know the reason Poric's alive, ${kuria}?  Because after Olen was beaten to death in the spring, your noble cousin lord Keriatou told off lady Pelematou.  Said it was a waste of a big man with lots of blood in him, and the Theurges wouldn't approve."  $!{xhe} shook ${xhis} head.  "There's no mercy for helots in this world, ${fname}.  It's all cruelty.  It's all monstrosity.  And all our roads end at a Harrower."
  
  For an instant, you imagined yourself walking away and leaving Breden to ${xhis} own devices—even reporting ${xhim} to the authorities to protect yourself.  And as you imagined it, you knew you couldn't do it.  For all your fear, you couldn't kill what was coming to life in you.  "Breden.  [i]I'm with you.[/i]  I'm not like them."
  
  $!{xhe} stared at you, disbelieving and hurt.
  *goto smoochoice
*fake_choice
  #"I'm so sorry," I offered, feeling sick to my stomach.
    "Sorry." Breden lowered ${xhis} face into ${xhis} hands for a moment. "And when sorry's not enough?"
    
    "Of course it's not enough," you began, and ${xhis} blazing eyes snapped up to yours.
    
    "Shall we speak of the things that would be, ${milady} ${fname}?  Not just hint around them, for fear of the Keriatou cousin in our midst?  If Radmar
  #"If Radmar were here, I'd offer condolences," I said steadily.
    "Would you now," Breden breathed. $!{xhis} drawn face was suddenly savage. "And if Radmar didn't accept them, ${milady}?  If he threw them in your face?  And
  #"This isn't the end," I insisted, trying to hearten ${xhim}.
    "Your friends…they'll be back, surely," you offered in a reassuring tone. "Once this blows over."

    "Back?" Breden's drawn face was suddenly savage.  "Yes, Angels know they'll be back.  Will you be back, ${milady} ${fname}, to hear what they have to say about your kind?  If Radmar 
swore to feed kurios Georden his own lying tongue, or break the neck of the Alastor who caught Poric, would you run off and tell your father?  At what point do we lose you?"

You drew back, stunned.  
*if ruthreal > 49
  Your father's chiding voice echoed in your head: [i]Treat them like [/i]friends, [i]and of course they're going to forget their place.[/i]
Breden's unchecked anger…
*choice
  #…was unacceptable—a liberty too far.
    "How dare you?" you snapped back at ${xhim}.  "I've tolerated endless presumption from you, ${xgirl}—and now you insult me to my face?"

    Breden's eyes remain bright with fury.  "All these weeks, we've been talking as if the Thaumatarch is the enemy. But ${kuria}: our enemy is whoever tortures us, rapes us, kills us, sends us to the Harrower.  Foreign-born or high-born, it doesn't matter."

    "So I'm an enemy now?  You're truly speaking to me as if I were the same as lady Pelematou?"

    $!{xhe} shook ${xhis} head.
    *goto shemonster
  #…took me aback.
    Keeping your voice level, you said, "We're not all like lady Pelematou, Breden."

    *label shemonster
    "She's a monster, is she?  Worse than all the rest?"

    "Taking someone's tongue, for a truth told under ordeal?  That's the worst kind of injustice." Your mouth twisted in disgust.  "The rights of nobility don't extend to unnecessary torture.  Everyone knows she's cruel to helots because…"

    "Because her late husband kept helot concubines from the day they wed until the day he choked?  Yes, believe me, we all know that—better than any aristocrat.  We know how he treated them, and how he treated her, for that matter."  Breden jumped off the decaying fence and strode up to you.  "Do you know the reason Poric's alive, ${kuria}?  Because after Olen was beaten to death in the spring, your noble cousin lord Keriatou told off lady Pelematou.  Said it was a waste of a big man with lots of blood in him, and the Theurges wouldn't approve."  $!{xhe} shook ${xhis} head fiercely.  "There's no mercy for helots in this world, ${fname}.  It's all cruelty.  It's all monstrosity.  And all our roads end at a Harrower."
    
    For an instant, you imagined yourself walking away and leaving Breden to ${xhis} own devices—even reporting ${xhim} to the authorities to protect yourself.  And as you imagined it, you knew you couldn't do it.  For all your fear, you couldn't kill what was coming to life in you. "Breden.  [i]I'm with you.[/i]  I'm not like them."
    
    $!{xhe} stared at you, and you saw the anger drain out of ${xhim}, replaced by something wordless and hurt.
    *goto smoochoice
  #…kindled my own, against the Hegemony.
    *set rebelrebel 1
    Before Breden questioned you that first time by the river, you hadn't realized how deep your rage went. Now it rushed back in full force, familiar and glorious.  "You think I fear a helot rebellion?" you demanded, your voice harsh to your own ears.  "I want to see the Hegemony burn, Breden.
    *if ruthless < 0
      What the Pelematou just did to Poric—it was an abomination.  It has to be stopped.
    And no, 'my kind' aren't going to do it.  But maybe your kind will."

    "Will we now, ${fname}?" Breden said softly.

    "$!{oath}, I hope so!  And I swear I'll do whatever I can to help."

    $!{xhe} stared at you, intent yet hesitant.  "By all Angels, if you are a Kryptast, you're a fine one."
    *goto smoochoice
*label smoochoice
*choice
  *if (not(acepref)) #I swore that when ${xhe} needed me most, I'd be ready.
    *label illbeready
    *if rebelrebel = 1
      "I believe you will be, ${kuria}."
      *goto shouldbegone
    *if rebelrebel = 0
      "Ready for what, ${kuria}?" Breden pressed.
      *choice
        #"Revolt."
          *set rebelrebel 1
          The unthinkable word remained in the air between you, each moment of silence seeming to amplify rather than extinguish it.  You spoke again, thick-tongued. "Revolt against the Hegemony and all its murderous ways."  A groundswell of anger dissolved your fear, surging up from the same place Breden had reached with ${xhis} questions at the crossroads.
          
          *label turnreb
          "You'd truly turn rebel, ${kuria}? Throw in your lot with a pack of helots?"

          "When the moment's right." You've heard whispered stories of noble rebellions and helot uprisings—all unsuccessful, obviously, but not forgotten, despite the best efforts of the Ecclesiasts.  "When we can muster enough people to stand against them and live—yes, by all Angels, I'd fight there at your side."

          *if helotrefuse
            "That might require actually talking to helots other than me."  Breden's tone was half teasing, half serious.

            "Perhaps we should try that again," you conceded. "This time, you might let me share my predilection for sedition with half the helots in Shayard…rather than doing it on my behalf, to force me to stay."

            At that, Breden laughed aloud.  "Perhaps so."
            *goto shouldbegone
          Breden swore softly.  "Bloody Xaos, if you are a Kryptast, you're a fine one."
          *goto shouldbegone
        #"To lay down my life."
          "To stand at your side.  To speak up for you." 
          *if insincere > 1
            You tried to sound as sincere as possible.
          *if insincere <= 1
            As you suddenly wished you could
            *if intronat
              for Carles the jongler, silenced so many years ago.
            *if introhlt
              for a nameless helot savaged by a Plektos in the woods.
            *if introrel
              *if intro_bad != 0
                have
              for
              *if intro_bad = 0
                the long-lost
              Ecclesiast Olynna.
            For all the innocent victims of the Hegemony.  
          "To speak what's true and just, though they kill me for it."
          
          "True-spoken words are well and good, ${milady}, but if we're to lay down our lives…"  Breden's lips narrowed, and ${xhe} glanced back for a moment toward the distant town.  "Will it be in fighting, or just talking?"
          *choice
            #"Fighting as well, of course."
              You couldn't tell from Breden's steady gaze whether ${xhe} believed you or not.
              *goto turnreb
            #"I'd not lightly turn to violence, Breden."
              "Damn it all, ${kuria}."  Breden's voice was low, but ${xhis} eyes were razors again. "You can still talk about 'lightly' after Olen, and Poric?  And thousands more like them, year on year?"
              
              "I'm not saying the violence would be unearned."  You held your own voice steady. "I just don't know whether it would bring about anything new—anything good."
              
              Breden's long, slow exhalation brought with it no relaxation of ${xhis} chest or shoulders. "As long as it brought about something, ${kuria} ${fname}.  Something different."
              *goto shouldbegone
            #"I…" I fell silent, unsure of the answer.
              In all your furious musings on the injustices of the Thaumatarchy, you'd never been sure how far you'd go to overthrow it.
              *gosub rebelthoughts
              When you didn't speak, Breden's lips twisted in a wry smile. "Indeed, ${kuria}." 
              *goto shouldbegone          
        #"Whatever the moment demands."
          You didn't know yourself how far you would go.  
          *gosub rebelthoughts
          To your relief, Breden didn't push you any further.  "I hope we all recognize the moment when we get there, ${kuria}."
          *goto shouldbegone
        #I fell silent, realizing there was no honest answer I could give ${xhim}.
          In truth, you didn't know what you would be ready for.
          *gosub rebelthoughts
          When you didn't speak, Breden's lips twisted in a wry smile. "As I'd feared, ${kuria}." 
          *goto shouldbegone
    *label rebelthoughts
    [i]Rebellion,[/i] said the furious part of you that Breden had tapped with ${xhis} questions at the crossroads.  [i]Show them you won't be trodden down forever.[/i]  But it felt like madness.  You'd heard whispered stories of noble revolts and helot uprisings—not forgotten, despite the best efforts of the Ecclesiasts, but all were crushed without mercy.
    *if ruthless >= 0
      
      Also, despite your affinity for some individual helots like Joana and Breden, something deep in you remained wary of a helot rising.  Was that simply too great a strain to the natural order?  Would it repel all the free folk of the Hegemony, ensuring that none but helots would fight at your side?
      *if harrowpinion > 0
        And what if the Harrowing of the helotry truly was a necessary evil to fend off Xaos?
      *if helotrefuse
        You thought about Breden's huddled mob of friends, meeting to grumble against their masters…and something in you still recoiled in fear.
    *if ruthless < 0
      Would another helot rising really help to end Harrowing, or simply ensure that you all ended up feeding a Harrower?
    
    *return
    *label shouldbegone
    $!{xhe} looked for a moment as if ${xhe} were about to say something else, then shook ${xhis} head.  "We should be gone before anyone starts to ask where we are.  I'll try to muster the group again in two weeks, when they've all regained some heart.
    *if helotrefuse
      If you're truly willing, ${milady}.
    We'll speak more then."
    *goto moreharrowing
  *if bredkiss < 1
    #As steadily as I could manage, I said, "I believe I'm falling in love with you."
      Breden's whole body tensed up as if to flee.  "$!{kuria} ${fname}?" $!{xhis} voice sounded wary, and deeply shaken.
      
      *if not(acepref)
        The painstaking rituals of courtship, learned from a lifetime of dramas and etiquette lessons, all relied on another partner who understood the dance.  Bereft of a common script, you found yourself blurting out words that any noble would have found scandalously direct.
      "Please understand.  I've
      *if acepref
        never felt…never had any desire to be carnally intimate with anyone.  Not a noble, not a helot.  And I don't want that now."  You were suddenly terrified that ${xhe}'d take insult—that ${xhe}'d think this was about the warnings of blood contamination in the Karagond Canon.  A torrent of words tumbled out of your mouth.  "But…I've 
      never met another soul like you, Breden.  No one half so precious.  I want to be with you, to hear everything you have to say.  To know you.  To love you."
      
      "You don't know me, ${kuria} ${fname}." Breden was barely audible.  "I'm just a helot
      *if helotrefuse
        you met in the spring.  And whatever you feel wasn't enough to keep you coming to our meetings."
      
        "I've been going mad since then," you burst out desperately.
      *if not(helotrefuse)
        who's said a few things that you liked to hear."
        
        "More than a few—and more than just liked." You couldn't keep yourself from smiling.
      "Maybe I don't know you well.  But I know I've met only one person who'll say aloud the things I've always felt.  One person honest and brave enough to risk their lives on the truth."
      
      Breden gave one peal of helpless laughter. "Ah, ${milady}.  What am I supposed to say to that?  I know what I'd do if you tried to make free with me…."  $!{xhis} voice broke off. $!{xhe} moistened ${xhis} lips, and there was a frightened sheen in ${xhis} eyes. "Or perhaps I don't, at that.  You unsettle me, ${kuria}, and that's the Angels' truth."
      
      "Enough to make you run away?"
      
      "Angels, ${kuria}. No."  The young helot glanced around to make sure nobody was in view, then took your hands gingerly into ${xhis} own.  $!{xhis} plow-roughened, cracked skin was hot against yours. "Not that."
      *set bred_heart 3
      *goto moreharrowing
  *if acepref
    #No—I've never fallen in love and never will. I tell ${xhim} I'll be ready when I'm needed the most.
      *set aropref true
      *goto illbeready
  *if not(acepref) 
    #I took ${xhim} into my arms and waited for ${xhim} to kiss me.
      At that moment, you didn't care about your reputation, let alone the warnings of blood contamination in the Karagond Canon.  Breden went very still,
      *if bredkiss > 0
        just as ${xhe} had before.  There was a flat, unhappy sound in ${xhis} voice.  "You say you're not like the rest of them, ${kuria}.  I've seen nobles come after helots many a time before.  Just what's different here?"
  
        You kept your gaze steady.  "Say the word, and I'll not embrace you again.  Maybe other nobles want a lover who reminds them of their power.  I just want to be with you."
      *if bredkiss = 0
        ${xhis} unsmiling lips a tantalizing inch from yours.  "I've never heard you were one to make free with the helots, ${kuria}."
  
        "I never have been."  Irrespective of your own feelings about the chastity code, it would have been unthinkable to conduct any helot affairs under the unkind eyes of your father or Keriatou cousins.
  
      "And our talk about Poric somehow brought this on?" Breden said, starting to smolder.  "Tell me, ${kuria}, what do you think they'll carve off me when we're caught kissing?"

      "Are they any more likely to catch us kissing than talking treason?"  You searched for the right words.  "Breden—you know I can't promise we'll be safe.  But I can swear one thing, by all I hold dear: I'm no Georden Pelematou.  I'd never sacrifice you to protect myself."

      You had hoped to mollify ${xhim}, but ${xhe} just sounded shaken.  "Why me?  Truly?"
      *choice
        #"I fell in love with you almost as soon as I saw you."
          Breden let a small groan escape.  "Damn it, ${fname}.  That's the most foolish thing I've heard from you yet."

          But ${xhe} didn't try to move away, and you didn't release ${xhim}. "I'll not argue with that."
  
          "You knew nothing about me…except that I was a helot.  That's grounds for love?"

          "You were an awfully charming helot.  And the bravest person I've ever met."

          Breden shook ${xhis} head, visibly fighting a smile.  "What, because I jumped in front of your cousin's horse?"

          "No. That was just foolish.  Loved that, too."

          *if bredkiss > 0
            $!{xhe} allowed the smile to break across ${xhis} face.  It stayed there 
            *gosub bredbrushoff
            *goto moreharrowing
          "Oh, come here," Breden demanded, an instant before ${xhis} lips met yours.
          *set bred_lover 4
          *goto moreharrowing
        #"You're delightful.  Isn't that reason enough?"
          Breden's eyes remained wary.  "Delightful—like some toy your father bought for you?  Or some sweetmeat from your cousins' larder?"

          But ${xhe} didn't try to move away, and you didn't release ${xhim}. "Delightful…because you're honest in a world of liars, and brave in a world of cowards. And as beautiful as any other soul I've met. Worth taking risks and breaking rules for."

          "And you think I should take a risk on you, too, ${milady}?" Breden inquired.  
          *if bredkiss > 0
            $!{xhis} smile hovered
            *gosub bredbrushoff
            *goto moreharrowing
          As you were opening your mouth to answer, ${xhe} abruptly leaned in and shut it with ${xhis} own.  "Too late," ${xhe} murmured against your lips.  "Here we are."
          *set bred_lover 4
          *goto moreharrowing
        #"Because you're like me."
          A laugh erupted from Breden, ${xhis} wariness overcome by pure shock.  $!{xhe} regained control seconds later, but there was a warmth in ${xhis} eyes that hadn't been there before. "Now those are words I'd never thought to hear from any aristo."
          
          "I'd scarcely imagined saying them to a helot."  Giddy with taboo-breaking, you slipped your hands down to ${xhis} waist.  "Or to anyone—certainly not the pack of cowards and posturing liars from the Houses of the Rim.  But I've met only one person who'll speak aloud the things I've always thought and felt.  One person honest and brave enough to risk their lives on the truth."
          
          *if bredkiss > 0
            Breden's breath was coming fast against your cheek; the heat in ${xhis} eyes grew
            *gosub bredbrushoff
            *goto moreharrowing
          *set bred_lover 4
          "Well, there aren't many like that in the helot camps either." $!{xhis} breath was coming fast and hot against your cheek. "And I've only met one noble who seems as brave.  So you're saying I should take a risk on you too, ${milady}?" 
          
          As you were opening your mouth to answer, ${xhe} abruptly leaned in and shut it with ${xhis} own.  "Too late," ${xhe} murmured against your lips. "Here we are."
          $!{xhe} interrupted ${xhis} own sentence against your lips.
          *goto moreharrowing
  #"But can I rely on you, Breden?"  I felt another sudden jolt of doubt.
    Anger blazed across ${xhis} face. "Forgive my impertinence, ${milady} ${lname}…but you haven't earned the right to doubt me yet."
    
    You're not above visceral outrage at a helot taking such a tone with you. "Earned the right? $!{xgirl}…"
    
    "When were you flogged for your silence, ${kuria}, by foremen determined to get you talking?  Or for speaking out of turn, by Alastors who wanted you silent?" Breden shrugged back ${xhis} kyrtle just far enough to expose the scars on ${xhis} shoulders.  The scandalous sight of that white-lined skin stole all the moisture from your throat. "You've borne nothing, ${kuria},
    *if helotrefuse
      risked almost nothing.  You've no right to demand anything from us.
    *if not(helotrefuse)
      besides a bit of risk in meeting with us.
    But yes: you can rely on me.  And you'll need to."
    
    You finally found your voice.  "I've risked a great deal, Breden."
    
    "Not as much as we do, ${milady}."
    *goto shouldbegone
*label bredbrushoff
for several moments before fading.  "I'm sorry, ${kuria}.  Maybe in time.  I…"  $!{xhe} stepped gently backward, breaking your hold.  "You seem kind.  Kinder than nobles I've known before, at any rate.  Given time, I may even trust you.  That's dangerous, and I need to think on whether it's wise."

You struggled not to let your disappointment speak for you.  "If such are your feelings…I'm sorry.  It's likely best that we not speak of this again."

"$!{kuria}."  Breden's hand on your arm kept you from walking away.  "I've not heard many nobles speak as you do.  About the Hegemony, and justice.
*if harrowpinion = 0
  Certainly not about Harrowing.
Since we first spoke, I've felt…"  $!{xhe} broke off, swallowing hard.  "I've not got the words for it, not now.  But believe me, I'd be grieved if we never spoke of this again."  $!{xhis} lips quickly pressed against your cheek—and then ${xhe} was gone.
*set bred_lover 0.5
*return
*label poric_helot
*page_break
As the season turned, your weekly clandestine meetings began to seem routine.  Then the day came when you went up to the de Rose hut and found no one there.  Scouring the wooded marsh frantically for any sign of Alastors, you finally spied a familiar silhouette atop an old fence, a few hundred yards from your normal meeting place.

"${fname}," Breden acknowledged your approach dully.  $!{xhe} was staring at the late afternoon reds and oranges in the swamp water.

"Where is everyone?"

"Lying low."  As ${xhe} craned ${xhis} neck to regard you, you noticed the tension in ${xhis} jaw, the hands clenched futilely in ${xhis} lap.  "You haven't heard, I take it."

The sharp surge of terror hit you like nausea; you had to swallow back bile.  "Not Alless.  They didn't find Alless?"

"No, thank Angels."  Breden's voice held no real relief.  "It's the Pelematou again.  
*goto the-p-again

*label poric_helot2
*page_break
Around the turn of the season, walking back from a long day's toil, you spied a familiar silhouette by the roadside.  Grim and wordless, Breden watched you approach, and for a nightmarish moment you were sure you were about to be attacked.  You froze and scanned the twilit fields on either side for ambushers.  But there were none, and nowhere obvious for them to hide.

"Breden," you greeted ${xhim}, resuming your former pace.

"${fname}," ${xhe} returned, tilting ${xhis} head curiously.  "Knives at dusk?  From us?  You truly fear that?"
*if bred_lover > 0
  There was a hint of pain in the way ${xhe} said it.

"You were angry when we parted," you pointed out, wary and still slightly shaken.  "You were angry when I saw you across the agora at the Harrowing.  And if something's gone awry with your little chats, there'd be those who would put the finger on me.  Would it come to knives then?  You tell me."

Breden exhaled sharply through ${xhis} nostrils.  "Things have gone wrong, ${fname}.  But no one's pointing to you.  And no one's spoken of knives. Bloody Angels' sake."  $!{xhe} suddenly looked dull-eyed and lost, and folded back into the long grass as if the bones in ${xhis} legs had dissolved.  "I just wanted…I've missed our talks.  And everyone else is lying low."

"What's gone wrong?"
*if bred_lover > 0
  For the moment, you resisted the urge to kiss the grief from ${xhis} eyes.
You'd never seen Breden at a loss before; it was more unnerving than you would have expected.

"It's the Xaos-damned Pelematou.
*label the-p-again
One of their hands, Poric Weller, was caught with a fistful of mullow."

You began to understand the problem, if not Breden's numb response.  Helots were strictly forbidden the herb mullow; it went against your collective duty to maintain your numbers.  "Who was he eating it with?"

"No one.  I don't think Poric and Radmar had any need of mullow." Breden's tone was mirthlessly dry.  "No, he was bearing it to kurios Georden Pelematou when they caught him.  And the young man didn't want to admit to his mother that he was breaching chastity. So when Poric let slip his name in the beating, he cried slander."

"Ah, ${oath}.  The penalty?"

Breden turned hollow eyes on you.  "They took his tongue, ${fname}.  Broke half the bones in his body, too.  Radmar is caring for him now, and none of the others will venture out of the camp.  Especially the women who might be accused of eating mullow with Poric."
*page_break
You sat next to Breden, wordlessly resting one hand on ${xhis} shoulder.  You'd all seen the brutality overwhelm people before.  Helots who'd silently watched their families Harrowed, who had stoically endured the abuses of Alastors and nobles…one day something would crack the calluses and reach them.  It wasn't always the worst cruelty or the greatest injustice, and there was no telling what lasting damage it would leave.

"It's got to stop."  Breden kept speaking, thick-tongued and tearful.  "And I thought I knew how to stop it.  But seeing Radmar's face…"  $!{xhe} choked, lost ${xhis} words, began again.  "Him, and all of us.  I don't know where they sit between anger and fear.  If Radmar curled up and lost his fire, how many would go with him?  If he swore to feed kurios Georden his own lying tongue, or break the neck of the Alastor who caught Poric, who would run away?"
*if helotrefuse
  $!{xhe} shook ${xhis} head.  "As you already did.  As we already lost you."

Seeing Breden on the verge of despair, you felt an unexpected panic rising in your own chest.  Since meeting the fiery young helot, something had been coming to life in you; now you realized that the prospect of losing it was unthinkable.
*choice
  #I tried to talk ${xhim} back into hope.
    "Breden.  This won't break 
    *if not(helotrefuse)
      us.  What we've had out here in these meetings…it's a taste of
    *if helotrefuse
      their souls—those friends of yours.  I could see it in them that day.  They'd tasted
    something too good to be dropped for any damned Pelematou.  Something that will bring back every helot to your side."
    
    Breden looked at you with a dull bitterness.  "What do you imagine they've tasted, ${fname}?"
    *choice
      *if (not(acepref)) #"Freedom."
        *label illbefreedom
        A raw, almost scornful laugh burst from ${xhis} throat.  "Ah, ${fname}. A taste is all we'll ever get.  If any of the others still think meeting to flap our tongues is worth the chance of losing them."
        
        *if helotrefuse
          "It's worth all the more now.
        *if not(helotrefuse)
          "Speaking free as we have been?  
        It's worth everything." You leant in to grip ${xhis} arms. "Breden, we always knew that They could cut us to bits any time They liked.  But to be free to call this business with Olen or Poric what it is—to name it injustice, murder, Xaos, all the words
        *if not(helotrefuse)
          we've 
        *if helotrefuse
          your little band has
        been practicing out in the woods?  That's what's new. And precious. And however frightened the others are just now, they'll come back to it."
        
        $!{xhis} dark eyes were still uncertain. 
        *if helotrefuse
          "Does that mean you're 'coming back to it,' ${fname}?  Even if not everyone trusts you the moment they meet you?"
          
          Your pulse was racing in your throat. "If I'm right? Well, just be sure you tell me when the rest are ready to meet again."
          
          Breden stared at you for some time before venturing a nod.  "I will."
        *if not(helotrefuse)
          "Most don't, ${fname}.  I saw it out east, before I was sold here.  This is the kind of thing that makes folk swallow whatever they've been saying and turn their eyes back to their Elysian reward."
          
          "Not our folk."  You shook your head firmly. "Not Elery, or Radmar, or little Pin."
          
          Breden wanted to believe you; you could see it in ${xhis} face. "Xthonos, I hope you're right."
        *goto musteragain
      #"Rebellion."
        *if rebelrebel = 1
          Breden shook ${xhis} head at once. "You're seeing what you want to see, ${fname}.  The rest…they're not ready.  Not like you
          *if helotrefuse
            claim you
          are."
          
          "They may not know it themselves.  But Olen's death, and now Poric…no one wants to stand for things like this.  This isn't saving anyone from Xaos.  This is Xaos.  And 
          *if not(helotrefuse)
            our 
          *if (helotrefuse)
            your
          little group has come most of the way to saying it outright, Hegemony be damned."
          
          $!{xhe} searched your face with dark, uncertain eyes.  "And if they're not ready, ${fname}?"
          *goto istillwill
        *goto rebelchoice
      *if not(acepref)
        #"Well…I reckon I can't speak for the others."  My cheeks grew hot as I put my arms around ${xhim}.
          *goto bredhelarms
      *if (acepref)
        #"I can't speak for the others.  But I'd follow you anywhere."  My cheeks grew hot.
          *goto bredhelace
      *if acepref
        #No—I've never fallen in love and never will. "Freedom," I reply at once.
          *set aropref true
          *goto illbefreedom
  *if (not(acepref)) #I swore that when ${xhe} needed me most, I'd be ready.
    *label illbeready2
    *if rebelrebel = 1
      *if helotrefuse
        "You haven't lost me," you insisted.  "When 
      *if not(helotrefuse)
        "You already know you can count on me.  When
      the moment comes for the rising, I'll be there."

      Breden searched your face with ${xhis} dark, uncertain eyes.  "And if the others aren't ready?"
      *label istillwill
      
      *if overseer = 1
        "Well…I still will be."  You managed a grin.  "Two of us should be enough to see them off, right?"

        Breden laughed despite ${xhim}self.  "Even so.  We sent the chief field foreman of the Keriatou packing.  What hope does the Thaumatarch have?"        
        *goto musteragain
      *else
        "This from the 
        *if xhe = "she"
          woman 
        *if xhe = "he"
          man 
        who took on the overseers single-handed?"  You managed a grin.  "This time, Breden, it'll be both of us.  Surely that's enough to send the Alastors packing."

        Breden laughed despite ${xhim}self.  "[i]Two[/i] helots.  What hope does the Thaumatarch have?"  
        *goto musteragain
    *else
      "Ready for what, ${fname}?" Breden pressed, searching your face with ${xhis} dark, uncertain eyes.
      *choice
        #"Revolt."
          *label rebelchoice
          *set rebelrebel 1
          Even as the word left your lips, you were choked by the conviction that the fields were full of listening ears.  Your father's voice echoed in your mind: [i]If the Karagonds would call it treason, don't say it, don't whisper it, don't even think it.  You're never safe.  It'll always get back to them.[/i] 

          Then a groundswell of anger dissolved your fear, surging up from the same place Breden had reached with ${xhis} questions at the crossroads, and you croaked, "A rising.  An end to the Hegemony and their Harrowers.  Forever."

          "You'd truly turn rebel, ${fname}?"  Breden kept staring intently at you.

          "When the moment's right?  When we can muster enough people to stand against them and live?  Then Theurges be damned, I'll be there at your side."

          *if helotrefuse
            "That might require spending time with other free-talking folk—even ones who don't trust you the first time they meet you."  $!{xhis} tone was half teasing, half serious.

            "Perhaps we should try that again," you conceded.

            "Perhaps we will."
            *goto musteragain
          *else
            Breden slowly nodded, some semblance of calm returning to ${xhis} face.  "I believe it.  Thanks, ${fname}."
            *goto musteragain
        #"Whatever the moment demands."
          You didn't know yourself how far you would go.
          *gosub rebelthoughts2
          To your relief, Breden didn't push you any further.  $!{xhe} just seemed to sag further into ${xhim}self.  "I hope we all know what the moment demands when we get there, ${fname}."
          *goto musteragain
        #I fell silent, realizing there was no honest answer I could give ${xhim}.
          In truth, you didn't know what you would be ready for.
          *gosub rebelthoughts2
          When you didn't speak, Breden's lips twisted in a bitter smile. "That's what I'd thought, ${fname}." 
          *goto shouldbegone
      *label rebelthoughts2
      [i]Rebellion,[/i] said the furious part of you that Breden had tapped with ${xhis} questions at the crossroads.  [i]Show them you won't be trodden down forever.[/i]  But it felt like madness.

      In every whispered story of noble revolts and helot uprisings you've shared, the ending was the same: they were crushed without mercy.  Would another helot rising really help to end Harrowing, or simply ensure that you all ended up feeding a Harrower?
      
      *return
  *if (bred_lover < 4)
    #As steadily as I could manage, I said, "I think I'm falling in love with you."
      *label bredhelace
      Breden blinked at you in shock. "${fname}?"
      
      *if not(acepref)
        "Did you…is it that unthinkable?" You tried to hide the pang of disappointment beneath a torrent of words.
      "I've 
      *if acepref
        never felt…never wanted to share a bed with anyone, Breden.  And I don't want that now."  You were suddenly terrified that ${xhe}'d take insult, and a torrent of words tumbled out of your mouth.  "But…I've 
      never met another soul like you.  No one half so dear.  I want to be with you, to hear everything you have to say.  To know you.  To love you."
      
      "Angels, ${fname}." $!{xhe} was barely audible. "You don't know a thing about me."
      
      "Enough to want to know more."
      
      "You're in love with talking free."  The words spilled rapid and desperate from Breden's lips.  "You're in love with sedition, and flirting with rebellion.  You're in love with the first person to speak honestly about the things you'd been keeping locked up."
      
      "You talk as if that could have been just anyone," you said, incredulous but smiling.
      
      "It could only have been someone with more charm than sense." For a moment, ${xhe} looked as if ${xhe} were about to weep.  "${fname}…falling in love at a time like this…it's just foolish.  It's blind.  It's dangerous."
      
      You reached out to take ${xhis} hand.  "And you're angry because you've done it too."
      
      Breden opened ${xhis} mouth to retort…then closed it again, exhaled raggedly, and wove ${xhis} fingers tight into your own.  "Ah, Angels."
      *set bred_heart 3
      *goto moreharrowing
  *if acepref
    #No—I've never fallen in love and never will. I tell ${xhim} I'll be ready when I'm needed the most.
      *set aropref true
      *goto illbeready2
  *if not(acepref) 
    #I took ${xhim} into my arms and waited for ${xhim} to kiss me.
      *label bredhelarms
      *if bred_lover >=4
        For once, your embrace seemed to do no good.  You felt all ${xhis} muscles tauten, as if ${xhe} were about to writhe out of your arms and flee.
        *if helotrefuse
          "You don't really want me, ${fname}," ${xhe} whispered.  "Don't…there's no need for this."

          "That wasn't why I stopped coming to the meetings," you protested.  "That had nothing to do with you—with us."
        *if not(helotrefuse)
          "How did I drag you into this?" ${xhe} whispered wretchedly.  "What happened to Poric…if they took you, ${fname}, I'd be lost."

          "You didn't drag me," you retorted.  "I was walking this way already.  You just helped me find a faster pace."
      *if bred_lover < 4
        From so close, the waves of emotion that crashed across Breden's perfect face were almost tangible: shock and alarm, hunger, hope.  "${fname},
        *if (female and malepref) or (male and femalepref)
          I'm not looking for a safe-mate…."
      
          "Xthonos, neither am I!"  An embarrassed heat prickled across your cheeks and ears.  "Who said anything about a child?  I reckon I've a few years left before the Theurges Harrow me for not breeding."
      
          "No, of course. I'm sorry.  I knew that."  You felt all ${xhis} muscles tauten, as if ${xhe} were about to writhe out of your arms and flee.  "But
        you don't really want this.  It…it will just make things harder.  If you'd seen Radmar…"
      
        "I know exactly who I want," you cut in.  "If hard times are coming, all the more reason to seize the joy while we have it in hand."

      You had hoped to ease ${xhis} tension, but ${xhe} looked no less shaken.  "Why me?  Truly?"
      *choice
        #"I fell in love with you almost as soon as I saw you."
          Breden let a small groan escape.  "Damn it, ${fname}.  You barely knew me.  You still barely know
          *if bred_lover < 4
            me."
          *if bred_lover >=4
            me.  A few trysts don't tell you who I am."

          But ${xhe} didn't try to move away, and you didn't release ${xhim}. "All true enough."

          "You're in love with talking free."  The words spilled rapid and desperate from Breden's lips.  "You're in love with sedition, and flirting with rebellion.  You're in love with the first person to speak honestly about the things you'd been keeping locked up."

          "You talk as if that could have been just anyone," you said, incredulous but smiling.

          "It could only have been someone with more charm than sense." For a moment, ${xhe} looked as if ${xhe} were about to weep.  "${fname}…falling in love at a time like this…it's just foolish.  It's blind.  It's dangerous."

          You let your arms fall away, but kept your face inches from ${xhis} own. "And you're angry because you've done it too."

          "[i]Damn[/i] it," Breden repeated fervently, the instant before ${xhis} lips met yours.
          *set bred_lover 4
          *goto moreharrowing
        #"You're delightful.  Isn't that reason enough?"
          Breden's eyes remained wary.  "I'm all for delight, ${fname}.  But this is a dangerous time for
          *if bred_lover < 4
            games."
          *if bred_lover >= 4
            games.  Our trysts have been lovely, but maybe it's time we stopped."

          Still, ${xhe} didn't try to move away, and you didn't release ${xhim}. "I wouldn't call it a game.  Breden…you're honest in a world of liars, brave in a world of cowards.  You're beautiful, you give me joy.  Don't you think that's worth a little risk?"

          "And you think I should take a risk on you, too?" Breden inquired.  As you were opening your mouth to answer,  ${xhe} abruptly leaned in and shut it with ${xhis} own.  "Too late," ${xhe} murmured against your lips.  "Here we are."
          *set bred_lover 4
          *goto moreharrowing
        #"Because you're like me."
          "Just because we've both got more fire than sense?" Breden shook ${xhis} head, looking anguished. "That's not enough, ${fname}.  You don't know 
          *if bred_lover < 4
            me."
          *if bred_lover >= 4
            me.  A few trysts don't tell you who I am."
          
          But ${xhe} didn't try to move away, and you didn't release ${xhim}.  "You didn't see yourself in me, too?  From the first time we spoke?"  The expression on ${xhis} face was answer enough for you. "Sometimes you don't need to know someone to recognize them."
          
          "Two people can care about all the same things and still end up despising each other, ${fname}. Seen it happen often enough."  $!{xhis} pulse was visible in ${xhis} throat. "I don't think…I couldn't live with that.  If when you knew me better, saw me weak as well as strong…if you changed your mind…"
          
          "I've seen you weak, now," you murmured. "I've seen you doubting yourself.  Does it feel like it's changed anything?"
          
          $!{xhe} stared at you for several moments more before closing ${xhis} eyes and leaning into you.  "No," ${xhe} murmured against your lips. "Angels help us both, no."
          *set bred_lover 4
          *goto moreharrowing
*label musteragain
$!{xhe} rose, smoothing ${xhis} kyrtle.  "I'll try to muster the group again in two weeks, then, when they've all regained some heart.
*if helotrefuse
  If you're truly willing, ${fname}.
We'll speak more then."
*goto moreharrowing

*label moreharrowing
*if helot and (int = 2)
  *page_break
  That evening in the camp's meal tent, your father snapped, "Xaos, ${girl}, what's got into you?  You're shifting like a child who hasn't learned to sit on ${his} haunches."  The nervous excitement of your encounter with Breden refused to dissipate, even as you retired to your bedroll.  After hours of tossing, with the first light of dawn touching the horizon, you sighed and slipped out of the big tent.

  You brought Ganelon's perplexing vellum scroll with you; with both moon and sunlight brightening the sky, it was just bright enough to read.  The words slipped off your weary eyes until you scanned the line: "…I see myself without a mirror.  I see the ends of all things.  And I know I am the nature beyond nature…."  Then you found yourself starkly awake, your hands trembling and nerveless.  [i]Nature beyond nature[/i]—you'd never made the link before, but now you clearly remembered reading those words in a philosophy text as a description of Theurgy.

  The shadows of the tents and trees around you seemed suddenly tangible and malevolent.  
  *gosub from_childhood
  *choice
    #So I ran back to the cooking area for a knife.
      *set theurgy 1
      *achieve theurge
      With so much at stake, waiting even a few hours to confirm your intuition was unthinkable.  You found two knives lying on the chopping stump; drawing one blade across your hand, you sat down, feeling slightly light-headed as you watched the blood well up.  Then, using the mental exercises described in the scroll, you tried to concentrate on levitating the other knife.

      Time slowed to a crawl as you mentally repeated the philosophical litany.  Your vision blurred and the shadows thickened as blood rushed from your head…and hours later, your father shook you awake.  His eyes darted around with mixed anger and concern at the knife, scroll, and your bloodied hand, all stark in the mid-morning light.  A small gossiping crowd had gathered around you on the way to break their fast.  "What by Xthonos…"

      "Father," you mumbled, suddenly sick with fear.  "I…I couldn't sleep in the night."  

      "And so you stuck a knife in your hand?"

      Desperately, you came up with, "It was too dark for reading, so I thought I'd try to whittle…."

      A burst of laughter went up from all around you.  Your father just scowled and helped you to your feet.  "All that reading drives too many strong humors to your brainpan, ${girl}.  Makes you clumsy and faint…."  You didn't hear the rest of his rebuke; you were too distracted by the sight of the other knife stuck an inch deep in the stump, as if it had been dropped from a height of several feet.
      *goto bredsecret_h
    #So I waited another day for an afternoon experiment in the woods.
      *set theurgy 1
      *achieve theurge
      You labored only half-heartedly that day, grappling both with fatigue from your sleepless night and with the possibilities implied in the mysterious scroll.  Was it really imaginable that the heart of Theurgy was so simple?  As soon as the field gang was dismissed, you strode up into the woods.

      An hour later, you thought you were far enough away to not be disturbed.  You placed a sizeable slate on top of a boulder, and sat down several yards away.  Then you bit down hard on your own hand, feeling slightly light-headed as you watched the blood well up.  Using the mental exercises described in the scroll, you tried to concentrate on levitating the slate.

      Time slowed to a crawl as you mentally repeated the philosophical litany.  The forest became a haze around you as blood rushed from your head…but as the world went dark you clearly heard the crack of stone on stone.  When you regained consciousness a few hours later, the slate was shattered, as if it had fallen from a height of several feet.
      *label bredsecret_h

      You haven't felt ready to tell Breden about your unnerving discovery.  What if ${xhe} condemned you for sorcery—or on the other hand, pushed you to keep experimenting, whatever the risk to your life?  For now, you just made sure you committed the scroll's litany to your memory.
      *goto shakeoff
    *if (not(choice_randomtest)) #What?  I wasn't about to dabble in something so horrific and dangerous.
      You perched on a boulder as the sun came up, running through the text of the scroll over and over again.  Could something so simple really be the heart of Theurgy?  Could Ganelon really have handed you the key, all unwitting?  Something in it fit with all the hints and history you've read about the sorcerous arts.  But the idea of breaking the taboo and trying the bloody art for yourself remained unthinkable.

      You haven't yet told Breden about your suspicions.  What if ${xhe} started to fear you as a monster?  Or drove you to start experimenting with the scroll, in the hopes of using Theurgy for a helot rising?  Either way, you aren't ready to share the possibility yet.
      *goto shakeoff

*if aristo and (int = 2)
  *page_break
  At dinner that evening, your father sharply commented on your inability to sit still.  The
  *if bred_heart >= 10
    pent-up fury from
    *goto yourencounter
  *elseif breden > 1
    nervous intensity of
    *goto yourencounter
  *else
    nervous excitement of
    *goto yourencounter
  *label yourencounter
  your encounter with Breden refused to dissipate, even after you retired to bed.  After hours of tossing, you reluctantly lit a candle and picked up Ganelon's perplexing vellum scroll, which had served you as a sleep aid before.

  Its words slipped off your eyes until you scanned the line: "…I see myself without a mirror.  I see the ends of all things.  And I know I am the nature beyond nature…."  Then you found yourself starkly awake, your hands trembling and nerveless.  [i]Nature beyond nature[/i]—hadn't you just read that in a philosophy text as a description of Theurgy? 

  The shadows thrown around the room by the candle seemed suddenly tangible and malevolent.  
  *gosub from_childhood
  *choice
    #So I strode across the room for my sword.
      *set theurgy 1
      *achieve theurge
      With so much at stake, waiting even a few hours to confirm your intuition was unthinkable.  You drew the blade across your hand and sat down, feeling slightly light-headed as you watched the blood well up.  Then, using the mental exercises described in the scroll, you tried to concentrate on levitating a ceramic bowl on your escritoire across the room.

      Time slowed to a crawl as you mentally repeated the philosophical litany.  Your vision blurred and the shadows thickened as blood rushed from your head…and many hours later, your father shook you awake.  His eyes darted around with mixed anger and concern at the sword, scroll, candle, and your bloodied hand, all stark in the mid-morning light.  "What in Xthonos's name?"

      "Father," you mumbled, suddenly sick with fear.  "I…I fell ill in the night.  I was trying to get the candle lit, and…I don't know, I felt so faint.  I was stumbling around the room, and then it felt like someone stabbed my hand…."

      "You stabbed yourself," he snapped, scanning the scroll and tossing it aside.  You never thought you'd bless its author for being so maddeningly oblique.  "I'd send for the leech, but you've bled yourself enough already.  Get to your bed, and I'll send up the breakfast you so thoroughly missed.  Just try not to break any more crockery."  He stabbed an accusing finger at the desk as he left.  The ceramic bowl was cracked in two, as if it had been dropped from a height of several feet.
      *goto bredsecret_a
    #So I waited until morning for a daylight experiment in the woods.
      *set theurgy 1
      *achieve theurge
      You couldn't sleep a wink for the rest of the night, grappling with the possibilities implied by the mysterious scroll. Was it really imaginable that the heart of Theurgy was so simple?  At daybreak, you broke your fast early and asked one of the house helots to ready a pack for you.  Before your father had stirred, you were already striding up into the woods.

      An hour later, you thought you were far enough away to not be disturbed.  You placed a sizeable slate on top of a boulder, and sat down several yards away.  Then you drew your sword blade across your hand, feeling slightly light-headed as you watched the blood well up.  Using the mental exercises described in the scroll, you tried to concentrate on levitating the rock.

      Time slowed to a crawl as you mentally repeated the philosophical litany.  The forest became a haze around you as blood rushed from your head…but as the world went dark you clearly heard the crack of stone on stone.  When you regained consciousness a few hours later, the slate was shattered, as if it had fallen from a height of several feet.
      *label bredsecret_a

      *if bred_heart < 10
        You haven't felt ready to tell Breden about your unnerving discovery.  
        *if breden = 1
          What if ${xhe} condemned you for sorcery—or on the other hand, pushed you to start using it against overseers, Alastors, even fellow nobles? 
        *if breden > 1
           Who knows what mad ideas ${xhe} might get into ${xhis} head if ${xhe} thought you could bring Theurgy to bear against your enemies?
        For now, you just made sure you committed the scroll's litany to your memory.
      *goto shakeoff
    *if (not(choice_randomtest)) #What?  I wasn't about to dabble in something so horrific and dangerous.
      You lay awake for the rest of the night, running through the text of the scroll in your mind over and over again.  Could something so simple really be the heart of Theurgy?  Could Ganelon really have handed you the key, all unwitting?  Something in it fit with all the hints and history you've read about the sorcerous arts.  But the idea of breaking the taboo and trying the bloody art for yourself remained unthinkable.
      *if bred_heart < 10
        
        You haven't yet told Breden about your suspicions.  
        *if breden = 1
          What if ${xhe} pushed you to start experimenting with the scroll, in the hopes of using Theurgy against overseers, Alastors, even fellow nobles?  Or what if ${xhe} started to fear you as a monster?  Either way, you aren't ready to share the possibility yet.
        *if breden > 1
          Who knows what mad ideas ${xhe} might get into ${xhis} head if ${xhe} thought you could bring Theurgy to bear against your enemies?
      *goto shakeoff
*label shakeoff
*page_break You Shake Off The Memories…
*text_image 1_autumn.png center AUTUMN
*set ruthless 0
[b]With almost all[/b] 
*if aristo
  the
*if helot
  your fellow
helots facing the Harrower, it's hard to tell one from another, but you're fairly sure big Radmar isn't in the crowd.  
*if bred_heart >= 10
  You have no idea why the vile Breden would be asking you, anyway—as if you have the least concern for ${xhim} and ${xhis} petty gang!  You've only come today to show ${xhim} what you think of ${xhis} threats.  If some lickspittle helot does break and accuse you of treason on ${xhis} way into the Harrower, you think amused, incredulous scorn will make a better defense than absence.

  You answer Breden only with a glare, then return your eyes to the oblivious Ecclesiast Zebed.
*if bred_heart < 10
  You give Breden a barely perceptible head shake and mouth, [i]No[/i].  You haven't seen Radmar since 
  *if helotrefuse
    that summer day 
    *if breden > 1
      when you refused to join the helot meeting on the outskirts of the de Rose estate.
    *if breden = 1
      *if aristo
        when you stumbled upon the meeting
      in the shack; you think Breden has held at least one of ${xhis} 
      *if aristo
        helot
      meetings since Poric's punishment, but you haven't yet been invited back. 
  *if not(helotrefuse)
    Poric's brutal
    *if breden = 3
      punishment.
    *if breden != 3
      punishment; he didn't come when Breden reconvened the meetings.
  Indeed, you don't recognize any of the helots in the crowd from Breden's group of free-talkers.

  Your father clears his throat quietly but pointedly at your 
  *if aristo
    side, as if to say, [i]Is this really the time to make eyes at a helot?[/i]  Your heart sinks; his glare promises a thorough interrogation when the Harrowing is done.
    
    *comment endif
  *if helot
    side; the last thing you need is to be accused of disrupting a Harrowing.
  Fortunately, Ecclesiast Zebed doesn't notice your exchange with Breden.  
Entirely caught up in the ceremony, he bows to the senior mage, a tall, slender woman with close-cropped red hair.  "Exalted Theurge Chirex."

The Alastors give a sharp, rattling salute, tracing the omphalos symbol of the Hegemony on their scale armor with their iron-shod clubs.  Chirex nods curtly to them and to the priest.  Like many Theurges at this point of the Harrowing rite, she looks tense and unhappy.  She pulls a small phial of blood from the bandolier beneath her coat. 

"Only through sacrifice," she proclaims over the crowd, "can the world be preserved."  She closes her fist around the blood capsule—and six paces away, the Harrower whirs to life.  The well-oiled gears begin to turn; the manacles snap closed and open again, the keen blades arrayed in the heart of the machine do a flickering, sickening dance like the legs of a suspended centipede.  You can't suppress a shiver at this display of Theurgical power.

"Those who surrender their lives for our salvation from Xaos are blessed by the Angels of Xthonos," Chirex intones.  "Their reward in Elysia shall be great beyond anything they dreamed in their earthly station.  But those who selfishly try to save only their own bodies will lose both their lives and their Elysian reward.  Who today was found hiding from the sacred summons?"
*page_break
When the Summons comes without notice, as it did today, it's not uncommon for two or three
*if aristo
  helots
*if helot
  people 
to miss the announcement.  Sometimes the whole Harrowing comes down to a hapless handful who chose the wrong day to skip their field work or go hunting.  But today there is an audible intake of breath from the crowd as the Alastors drag forward a cluster of eight bloodied helots from behind the Harrower—and an actual shocked murmur, breaking the silence of the ceremony, as five more unconscious ones are pulled out behind them.

Chirex glowers down at the trembling victims.  "Foolish children.  How long have you been conspiring together to hide a runaway helot?"  Her finger jabs out toward 
*if helotrefuse
  a haggard young girl in the middle of the group.
    
  "Alless Stonehewer," one of the
  *if aristo
    helot
  women nearest you breathes.  "Olen's child.  Oh, oh."

  Of course, you recognize at least four of the captives from your brief summer encounter in the de Rose shack.  You feel as if the ground is plummeting away beneath your feet.
  *if bred_heart >= 10
    Scoffing your way past one condemned helot's allegation would have been one thing; it's quite another to be accused by a group of captured conspirators.
  *goto sentencing
*elseif helot
  Alless Stonehewer.

  You feel as if the ground is plummeting away beneath your feet.  The captives include nearly all the helots you've come to know over the last few turns of the season.  There's Pin, crouched next to Alless, and a battered Yebben blindly shielding them both with his arms.  Elery is one of the ones who's been beaten into unconsciousness.
  *goto sentencing
*else
  a haggard young helot in the middle of the group.  You've never seen the girl before, but that's unmistakably Pin crouched next to her, and a battered Yebben blindly shielding them both with his arms.  Elery is one of the ones who've been beaten into unconsciousness.

  The surprise—[i]they've been hiding a runaway without telling me[/i]—lasts only an instant, replaced by a sickening fear.  For an aristocrat, Harrowing is one of the rarest of penalties, used only for the most shameful treason; you've viewed dozens of ceremonies without the least inkling that it could ever happen to you.  The abrupt loss of that confidence leaves you shaking and breathless.
  *goto sentencing
*label sentencing
How likely is it that within moments, they'll begin to name others who were touched by this sedition…Breden, Radmar (wherever he is),
*if helotrefuse
  or even
yourself?

An uneasy mutter stirs the agora as more and more see that the captives include literal children, including ones clearly no older than twelve.  To Harrow a Canon-breaking child isn't unheard of—but child-murder is a notorious custom of the eastern Halassurq Empire, one of the abominations that have brought them repeatedly to war with the Hegemony.  Seeing the aghast faces, Ecclesiast Zebed extends his hands toward the earth and piercingly addresses the lawbreakers: "You are all reprobates and rebels, Angels stand witness.  Each one of you corrupted by Xaos!  Age offers no protection when innocence is lost."

"The Angels knew of your crime," the triumphant-sounding Theurge Chirex continues, "and brought it to pass that you were caught evading the Summons, in the very act of succoring this fugitive!  Now only the Harrower and Taratur await you."

You look to Breden at the fore of the crowd.  $!{xhe} is an image of unconcealed horror; ${xhis} mouth opens and hangs ajar, as if ${xhe} were about to cry out but had lost all words.
*if bred_heart >= 10
  You'd have rejoiced to see ${xhim} thus undone, if your own life hadn't been so clearly in the balance.
*if (breden > 1)
  *set arrog 1
*choice
  #I need to stop this Harrowing at any cost.
    *goto odds
  *if (not(choice_randomtest)) #I need to stand still and keep a low profile, like any sane person.
    *goto caution
  #I'd normally have held my tongue—but ${oath}, I can't stand by while they Harrow children.
    *goto odds
*label odds
You try to ignore your hammering pulse and objectively gauge the odds.  The helots outnumber the Alastor law enforcers by almost five to one.  Even considering the Theurges' arcane support, you might be able to overwhelm them by force of sheer numbers.  
*if int > 1
  Moreover, you'd guess that the Theurges' bandoliers of blood will be exhausted fairly quickly,
  *if elery = 0
    especially after the amount they've been spending to levitate their victims. 
  *if elery > 0
    after which they'd no longer be much of a threat.

However, you're not sure what it would take to get this crowd of helots to rally against the Hegemonic authorities, even on a much-resented fourth
*if elery > 0
  Harrowing that includes children.
*if elery <= 0
  Harrowing.  The spectacle of the thirteen young evaders being slaughtered has clearly disheartened them.
  
  *comment end_if
You could try to win the crowd over with an eloquent, inspiring speech—though you'd have to make it quick, before you were forcibly silenced.  You could try to cleverly use 
*if int = 2
  your understanding 
*if int < 2
  what 
  *if int = 0
    little 
  you know
of Theurgy to intimidate the Theurges and Alastors with some combination of knowledge and bluff; if the helots smell the authorities' fear, they might believe in their own ability to stop a Harrowing.
*if (int = 2) and (theurgy > 0)
  (You could even try to use actual Theurgy, which would surely frighten the authorities but might also render you unconscious).
Or you could simply try to get the full advantage of surprise by physically attacking the Alastors and hoping the crowd follows your lead.
*if elery = 0
  Frankly, with the Harrowing already underway, it might take more than one of those measures to get the helots behind you. 

Heart pounding, you weigh up your personal strengths and decide which course has the greatest chance of success.  Then you take three steps away from your father, inhale deeply, and:
*if (choice_randomtest)
  *if cha = 2
    *choice
      #Cry, "No Angels would bless this atrocity.  You are a liar, Chirex, and your Thaumatarch is a blaspheming murderer."
        *goto chaway
  *elseif com = 2
    *choice
      #Lunge for the Alastor standing nearest to me.
        *goto comway
  *else
    *choice
      #Call out, "If you know what's good for you, Theurge, you'll let those helots go and leave the town."
        *goto intway
*label samechoice
*choice
  #Cry, "No Angels would bless this atrocity.  You are a liar, Chirex, and your Thaumatarch is a blaspheming murderer."
    *label chaway
    *set cred_p -10
    Your sacrilege transforms the town square into a statuary yard—for an astonished moment, no one moves, no one so much as exhales.
    
    Then hieros Zebed shrieks, "You dare?"  and six Alastors charge toward you, shoving helots roughly aside.  Theurge Chirex, who looks as if she had been about to speak, lowers the phial of blood in her hand and nods curtly at the apoplectic Ecclesiast.  "You dare to utter such filth about the sacred sacrifice?"

    "It is true," you shout back,
    *if (harrowpinion = 0) and (insincere < 1)
      gripped by a careless, joyful vertigo as you finally voice what has been in your heart for years.
    *if (harrowpinion = 0) and (insincere > 0)
      voicing aloud what you'd hinted at in your conversations with Joana and the other helots.  It doesn't matter whether you believe it, as long as you can convince them you do.
    *if (harrowpinion > 0) and (breden = 1)
      quenching your own doubts about whether Harrowing is a necessary evil.  This is what the helots need to hear.
    *if (harrowpinion > 0) and (breden > 1)
      keeping one eye on the helots who are your real audience.  Surely this is what the chattel want to hear?
    "Kill me for saying it, but you all know it is true.  There has to be another way to preserve the world.  And if the Thaumatarch were not a devil, he would have found it."

    Then you
    *if helot
      turn to your fellow helots
    *if aristo
      look at the helots around you
    and spread your hands wide.  "Will you stand for this?  Will you stand quietly by while the Theurges continue to murder your sons and daughters, your brothers and sisters?  Even the smallest of your children?  This is the moment for you to demand a new way—this moment, or none other, ever again!"
    *page_break
    *if cha = 0
      The crowd shrinks fearfully away from you, clearing a path for the oncoming enforcers.  It's hardly surprising, but you still feel a crushing disappointment—not least to see Breden open ${xhis} mouth again, glance around, and close it without speaking.
      
      Moments later, the Alastors reach you, and their iron-shod clubs smash into your head and gut.  You drop to the ground, trying vainly to shield yourself from their blows.
      *goto chirex-x

    *if (cha = 1) or ((cha =2) and (elery = 0))
      The crowd around you breaks out into startled murmurs.
      *if elery = 0
        Your impassioned speech has reawakened some of the anger that the executions drove out of them.  Suspended in the air,
      Breden belatedly calls out, "$!{he} is right!  Why must it always be helot blood that fuels the Wards?"  Some people begin pushing back against the Alastors, slowing their advance toward you.
      
      But most of the crowd are still
      *if cha = 2
        wavering.
      *if cha < 2
        wavering; your charisma is not enough in itself to move them to action.
      Like your father, who's in a half-crouch and covering his face, they're too frightened to resist.  You need to act quickly to rally them, before the Theurges decide that silencing you is the quickest way to restore calm.
      *choice
        #I bellow, "Attack!  They are too few to stand against us!" and charge toward the Alastors.
          *set violence +1
          The helots around you scramble out of your way, clearly terrified that the Theurges are about to strike you down.  Chirex and her fellow mage hold back, however; they seem to be counting on the Alastors beating you.

          The first guardsman you reach is plainly incredulous to see an unarmed 
          *if female
            female 
          *if aristo
            aristocrat
          *if helot
            helot
          charging him.
          *if com = 2
            His surprise and confidence is your greatest asset.  You feint left, then dodge his swing and kick hard at his overextended knee.  As he crumples, instinctively clutching his leg, you grab the iron-shod end of his weapon and yank it out of his grip.  Then you spring toward a second Alastor, parrying his blow and planting your club in his gut.  He also drops, badly winded—and you feel yourself yanked off the ground by an invisible force, tumbling upward in dizzy spirals until you're higher than the house-eaves around the square.

            But the alarmed Theurges have acted too late.  Seeing you take down two Alastors single-handed has given the helots the confidence they were lacking, and the taste for vengeance.  As the tradesmen and nobles at the edges of the agora scatter and flee, the crowd surges forward with an animal-like roar.
            *goto violence
          *else
            Unfortunately for you, his confidence proves justified.  As you try to kick his legs out from under him, his iron-shod club finds your shoulder and knocks you to the ground.  Then the rest of the Alastors reach you, and your gasps of pain blend with the fearful moans of the crowd as their clubs smash into your head and gut.
            *goto chirex-x

        #I shout, "Chirex, don't be a fool—you know your Theurgy can not win against us."
          Chirex thrusts her hand out with a snarl.  You feel yourself yanked off the ground, tumbling upward in dizzy spirals until you're higher than the house-eaves around the square.  "You dare to threaten a Theurge, traitor?"
          *if int = 2
            
            You call back to her with confidence born of the arcane texts you've read.  "Your Theurgy is your weakness, Chirex.  You didn't come with enough magic to put down a mob.  You don't have any oil of vitriol, and those bandoliers of blood won't power an attack strong enough to tear apart more than two or three of us.  So kill me if you will—but if I were you, I'd use that blood to ward myself and start running now."

            Chirex's cheeks drain of color; she visibly struggles and fails to find an answer. Seeing her at a loss gives the helots the confidence they were lacking.  As the tradesmen and nobles at the edges of the agora scatter and flee, the crowd surges forward with a mighty roar.
            *goto violence
          *else

            You call back, "We outnumber you.  Your magic isn't enough to stop us, and you brought too few Alastors to control an angry crowd…."

            Chirex brings her hand down in a sharp chopping motion.  Your voice rises into an involuntary, strangled yelp as you fly groundwards.  When you hit the dirt, for a moment you don't feel anything—you just hear your voice abruptly stop, and a dismal cracking sound from a dozen of your bones and joints.  Then the world goes white with agony, as you fight vainly to suck any air back into your lungs.

            Somewhere above you, Chirex speaks with cold authority.   "I don't see an angry crowd.  I see a town full of loyal subjects of the Thaumatarch, and one sorry rebel."
            *goto chirex-x

    *if (cha = 2) and (elery > 0)
      In any other year, all your charm would have been in vain.  But this is a fourth Harrowing, in the year of Olen Stonehewer's death, and at your impassioned plea the
      *if aristo
        helot
      crowd erupts in angry shouts and cries of assent.  Dozens of them begin shoving back against the charging Alastors, whose advance toward you slows to a halt.  
      
      Theurge Chirex, looking suddenly very pale, snarls something inaudible and raises her hand.  Your stomach plunges as you are jerked off the ground along with Breden and three other of the rowdiest helots.  Your father wails and covers his face. 
      
      Before the Theurge can do anything more drastic than levitation, however, 
      *if helotrefuse
        one of the thirteen captive helots
      *if not(helotrefuse)
        Blind Yebben
      shouts, "$!{he} is right!  We don't deserve to die—none of us!  Why must it always be helot blood that fuels the Wards?"

      "Save them!" Breden cries out.  "Quick, before they feed them to the Harrower!"  As the tradesmen and nobles at the edges of the agora scatter and flee, the crowd surges forward with a mighty roar.
      *goto violence
    *goto chirex-x
  #Call out, "If you know what's good for you, Theurge, you'll let those helots go and leave the town."
    *label intway
    Your threat transforms the agora into a statuary yard—for an astonished moment, no one moves, no one so much as exhales.  You've never seen Ecclesiast Zebed's face so dark, or his eyes bulging so incredulously.

    Then Chirex laughs, pulls another blood phial from her bandolier, and sweeps her fist in an upward arc.  Your stomach lurches as you are jerked off the ground and sail up into the 
    *if elery = 0
      air, higher than any of the other hovering helots chosen for Harrowing.
    *if elery > 0
      air.
    Your father crouches with a moan and covers his face.

    "Forgive me—I can't have heard you correctly."  The Theurge is smiling, but her voice and eyes are flinty.  Behind her, you see the other mage draw three phials from beneath his coat.  "Did you just try to threaten the representatives of the Thaumatarch?"
    *page_break
    *if int = 0
      "We outnumber you," you reply, mind racing as you try to make your threat sound plausible.  "Your magic isn't enough to stop us, and you brought too few Alastors to control an angry crowd…."

      Chirex brings her hand down in a sharp chopping motion.  Your voice rises into an involuntary, strangled yelp as you fly groundwards.  When you hit the dirt, for a moment you don't feel anything—you just hear your voice abruptly stop, and a dismal cracking sound from a dozen of your bones and joints.  Then the world goes white with agony, as you fight vainly to suck any air back into your lungs.

      Somewhere above you, Chirex speaks with cold authority.   "I don't see an angry crowd.  I see a town full of loyal subjects of the Thaumatarch, and one sorry rebel."
      *goto chirex-x
    *else
      "Damned right I did."  You keep your voice steady despite the vertigo of being snatched up to the height of the town rooftops.  "You're afraid of us, Chirex—because today you're secretly weaker than you look."

      The Theurge's lips tighten as murmurs break out among the helots.  You can see that she's weighing whether the crowd would be cowed if she silenced you quickly, or whether they would take that as evidence that your threat was true.
      *if int = 1
        You hurry on before she has a chance to decide.  

        "How much blood do you have with you?  Enough to throw a few of us around, but not many of us.  You're running out of blood in Shayard City—that's why you came for a fourth Harrowing.  The more blood you use now, killing me, the less you'll have to protect yourselves from two hundred helots.  And for the fourth Harrowing in one year, believe me, you need that protection.  You made a mistake."

        Chirex laughs dismissively, but it's drowned out by a rising, angry thrum of conversation.  You still sense uncertainty in the crowd, as well as the outright terror you see in your father.  Unlike Chirex, the
        *if helot
          other
        helots don't know whether you're only bluffing.  You need to do something else, quickly, to galvanize them.

        *label intchoice
        *choice
          #I direct the helots to attack at a point where they can quickly overwhelm the Alastors.
            *set violence +1
            "So take them—now!" you cry to the crowd.  "Break the ring around the Harrower.  Hit that Alastor—and those two there!  Now!"
            *if com = 2

              Your combat instincts are right as usual; you picked not only the most vulnerable guardsmen, but the segments of the crowd that are most primed to fight.  A wave of angry helots immediately swamps the three hapless Alastors—despite the Theurges levitating two young rebels and battering them against their comrades.  The line of club-wielding guards begins to waver.  The tradesmen and nobles at the edges of the agora scatter and flee, as the crowd surges forward with an animal-like roar.
              *goto violence
            *else

              A group of fired-up young helots starts grappling with the first vulnerable guardsmen.  But no one goes for the others.  Too late, you notice that the crowd in that area is mostly disheartened and elderly.  The Theurges immediately levitate four of the would-be rebels and send them flying into their comrades, breaking up their attack.  The Alastors press forward, viciously swinging their iron-shod clubs, and the crowd falls back in terrified disarray.

              Chirex smiles and brings her hand down in a sharp chopping motion.  An involuntary, strangled yelp bursts from your throat as you fly groundwards.  When you hit the dirt, for a moment you don't feel anything—you just hear your voice abruptly stop, and a dismal cracking sound from a dozen of your bones and joints.  Then the world goes white with agony, as you fight vainly to suck any air back into your lungs.
              *goto chirex-x
          #I try to inspire them to rise up through an eloquent appeal.
            "Will you stand for this?  For the murder of children?" you cry out to the crowd.  
            *if cha = 2
              Stirred by the passion and outrage in your voice, the helots respond with a deafening, "NO!"  Chirex's smile vanishes, and her eyes begin darting around as if looking for an escape route.  

              You raise your hands, no longer caring if Chirex tears you in half or dashes you to the ground.
              *if insincere > 0
                It's surprisingly easy to bellow aloud the sympathetic insincerities you've murmured to helots in the past.
              "Will you stand quietly by while the Theurges continue to murder your sons and daughters, your brothers and sisters?  This is the moment for you to claim a new way of life—this moment, or none other, ever again!"

              The crowd erupts in angry shouts and cries of assent.  Breden shouts, "$!{he} is right!  Why should it always be helot blood that fuels the Wards?  Break the Harrower!  Tear it down!"  As the tradesmen and nobles at the edges of the agora scatter and flee, the helots surge forward with a mighty roar.
              *goto violence
            *else
              "Will you stand quietly by while the Theurges continue to murder your—"

              Chirex's lips curl back in a snarl, and she brings her hand down in a sharp chopping motion.  An involuntary, strangled yelp bursts from your throat as you fly groundwards.  When you hit the dirt, for a moment you don't feel anything—you just hear your voice abruptly stop, and a dismal cracking sound from a dozen of your bones and joints.  Then the world goes white with agony, as you fight vainly to suck any air back into your lungs.
              *goto chirex-x

      *else
        You've read enough about Theurgy to lend you confidence as you hurriedly continue.  

        "You didn't come with enough magic to put down a mob.  Enough to hurt me, surely.  But you don't have any oil of vitriol on you.  And those bandoliers of blood?  They won't power an attack strong enough to kill more than two or three of us.  If you want to be able to ward yourselves and escape from an angry crowd, well, that will burn just about all the blood you've got left.  So use it now, Chirex.  Use it now—because after three Harrowings this year, this crowd is in no mood to let you and your gang of murderers get away with a fourth."

        Your words strike home.  Chirex's laugh sounds tremulous and forced, and is in any case almost completely drowned out by the rising, angry voices of the helots.
        *if elery = 0
          Your threat has reawakened some of their confidence.  But you sense that none of them wants to be the first to move against the Theurges after the horror they've just witnessed.  Like your father, they're too terrified to resist.
          
          You need to do something else to galvanize them—quickly, before Chirex recovers from her shock and decides to silence you.
          *goto intchoice
        *else
          *if helotrefuse
            One of the thirteen captive helots
          *if not(helotrefuse)
            Blind Yebben
          shouts, "$!{he}'s right!  We don't deserve to die—none of us!  Why should it always be helot blood that fuels the Wards?"

          "Save them!" Breden cries out.  "Quick, before they feed them to the Harrower!"  As the tradesmen and nobles at the edges of the agora scatter and flee, the crowd surges forward with a mighty roar.
          *goto violence
  *if (int = 2) and (theurgy > 0)
    #Cut my hand to draw blood for my second-ever experiment in Theurgy.
      No one notices you jabbing a
      *if aristo
        brooch 
      *if helot
        bone 
      needle into your palm, or the trickle of blood that follows it out.  You try to stay focused as you mentally run through the exercises from Ganelon's mysterious scroll.  You chant inaudibly, "I look beyond the ephemeral. I see the nature of things, their reasons for being, the final causes of all their motion…."

      As before, you feel light-headed and intensely nauseated, and time seems to slow.  The world shimmers as if you're falling away from it; the faces and hands of the people around you start to look smudged and hazy.  Cursing the unnaturally rapid blood loss, you try to stay focused on the clearest thing around you: the iron-tipped club in the hand of the nearest Alastor.  "I see that nothing comes into the world without purpose.  Fear does not cloud my vision.  I see the world without its masks.  I see myself without a mirror.  I see the ends of all things…."

      Swaying on the very edge of unconsciousness, your perceptions shift.  Your disorientation isn't you falling away from the world; rather, you are directly sensing the world falling all around you, the stones and water striving downward and the air and fire upward, each element seeking its natural resting place in the cosmos.  Behind the clear, bright shapes of their clothing and tools, the people around you have become seething blurs of complexity, so dense in detail that it hurts you to try to focus on them.  

      And the detachment you feel from your own body and brain is not just an impending blackout.  You can sense yourself as a similar blur, a maze of conflicting causes and purposes—a formidable knot to be contemplated, untangled, and retied in any way you choose.
      
      "And I know," you whisper, completing the litany,  "I am the nature behind nature.  I am the cause beyond the final cause.  I am a Maker of Change."  Through the dizziness and nausea, you are flooded with such delirious confidence that you almost laugh aloud.  Even though you don't understand more than a fraction of what you're experiencing, you know you can reach out and change something.  And given that you have only moments before the Theurges feed 
      *if (elery > 0) and not(helotrefuse)
        Pin
      *if helotrefuse and (elery > 0)
        one of Breden's friends
      *if elery = 0
        Breden
      to the Harrower, you had better do it now.
      *set theuknown 10
      *set cred_p -50
      *choice
        #I bring the Harrower to a halt.
          The Harrower is a profoundly complex machine.  Compared to the simpler human artifacts in the square (such as clothes, weapons, and houses), it is blurry to your altered senses; you suspect that you would have to understand its design much better if you wanted to use Theurgy to set it working.  But you understand the spinning gears you see along one side just fine.  With a deep breath, you focus on making them stop.

          Your head explodes with pain, the world fades to a white haze in front of your eyes, and you drop unceremoniously to your knees and vomit.  But you can still hear the machine shriek and judder to a halt, and take satisfaction in the cries from the Theurges and Ecclesiast Zebed as they are jolted off their feet.  The helots cry out too, and in their voices you hear both shock and incredulous hope.

          You cling desperately to consciousness, though you are blind with pain and feel like a wrung-out rag.  "Rise up!" you call thinly,  "Our power is greater than theirs!"

          At once you feel yourself snatched into the air by Theurgy, tumbling upward in dizzy spirals until you're higher than the house-eaves around the square.  Your father wails and covers his face.  But you also hear Breden's voice echo yours more strongly: "Their magic couldn't save the Harrower!  See their fear!  Rise up, now!"  As your vision returns, you see the panicky tradesmen and nobles at the edges of the agora scatter and the helots surge forward with a joyous roar.
          *set theurgy 4.1
          *goto violence
        #I cause the clubs to fly out of the Alastors' hands.
          The Alastors' clubs remain some of the clearest objects in your blurred field of vision.  They are simple tools with a single, violent purpose; their materials are also simple, wood and wrought iron.  You can feel the blend of elements in the wood—fire and earth, mostly, pulling in different directions.  With a deep breath, you push out with your mind toward the elemental fire, encouraging it, blowing on it, spurring it higher.

          Your head thrums with pain, the world turns white in front of your eyes, and you can barely restrain the urge to vomit.  But twenty clubs fly out of the grasp of the Alastors around the square before plummeting quickly back to earth.  The Hegemonic enforcers yell in shock and look incredulously back at Chirex.  When they see the Theurge's face contorted with similar rage and confusion, several begin casting their eyes around frantically for an escape route.

          You cling to consciousness, though you feel like a wrung-out rag.  "Rise up!" you call thinly, "Our power is greater than theirs!"

          At once you feel yourself snatched into the air by Theurgy, tumbling upward in dizzy spirals until you're higher than the house-eaves around the square.  Your father wails and covers his face.  But you also hear Breden's voice echo yours more strongly: "They are unarmed—see their fear!  Rise up, now!"  As your vision returns, you see the panicky tradesmen and nobles at the edges of the agora scatter and the helots surge forward with a joyous roar.
          *set theurgy 4.2
          *goto violence
        #I levitate Chirex off her platform.
          Like everyone else in the square, Theurge Chirex is a painfully complex blur to your altered senses.  You try to focus on her as a mere mixture of physical elements—fire, air, water, and earth, intermingled and interwoven.  Though it makes your head thrum and ache, you think you can feel those basic elements pulling in their different directions.  With a deep breath, you push out with your mind toward the elemental fire, encouraging it, blowing on it, spurring it higher.

          And through the thickening haze of unconsciousness, you feel movement—you know that you have succeeded, even before you see Chirex's feet leave the Harrower platform and her arms pinwheel in undignified shock.  Then you feel a furious mental push back, and you lose your fragile grip.  Your head splits with agony, your knees give out, and you vomit helplessly.

          Prone in the dust, you wait blindly for Chirex to tear you apart.  Instead, you hear her voice, terrified and enraged: "Alastors—someone in this crowd just committed a dire blasphemy using ${his} own blood.  The sorcerer will be bleeding and weak to the point of death.  Find ${him}, kill ${him}.  Now."
          *page_break
          Chirex may have been too distracted by your assault to notice you collapse, but you're sure at least one Alastor will have spotted you.  As you fight vainly to stand, your hear a sharp whisper near your ear: "Are you a Theurge, ${girl}?"

          It has to be one of 
          *if helot
            your fellow 
          *if aristo
            the 
          helots.  You wheeze back, "I'm learning.  How to do it without Harrowing.  Save me…and we can beat them."

          An awed murmur rises all around you; clearly, more than one person has heard your response.  Your father's horrified groan confirms that he's one of them.  Nearby, you hear an Alastor bark, "Stand away there—move away from that ${woman}!"

          "Won't happen," growls the helot, and shouts: "Brothers and sisters—don't let them have ${him}!  You saw what ${he} did to the Theurge!  Rise up!"  

          You feel yourself snatched into the air by Theurgy, tumbling upward in dizzy spirals until you're higher than the house-eaves around the square.  But Chirex has found you too late. As your vision starts to return, you see the panicky tradesmen and nobles at the edges of the agora scatter and the helots surge forward with a joyous roar.
          *set theurgy 4.3
          *goto violence
  #Lunge for the Alastor standing nearest to me.
    *label comway
    *set violence +1
    Your only hope is to take out a couple of the Alastors while you still have surprise on your side.  The nearest guardsman doesn't realize what you're doing until you're almost on top of him.  He yells something wordless and amazed, and every head in the town square turns your way.

    *if com = 0
      Unfortunately, his shock isn't enough to outweigh your combat inexperience.  As you try to kick his legs out from under him, his iron-shod club finds your shoulder and sends you spinning to the ground.  You try to scramble away into the crowd, shouting, "Fight them!  Stop the Harrowing!" but the helots shrink back and three other Alastors quickly surround you.  Your gasps of pain blend with the fearful moans of the crowd as the guardsmen's clubs smash into your head and gut.
      *goto chirex-x

    *else
      Before he can do anything, you head-butt him in the face.  He staggers backward, flailing out with his club, but you stay too close for him to get a good swing at you.  Then, before he can recover and push you away, you stamp down on the inside of his ankle.  As the Alastor crumples, instinctively clutching at his leg, you grab the iron-shod end of his weapon and yank it out of his grip.  Then you drive the club into his gut, and he folds over.  

      The people around you scramble out of your way, clearly terrified that the Theurges are about to strike you down.  You see your father crouch and cover his face, howling a useless denial.  Three more Alastors charge toward you.  With your advantage of surprise spent, 
      *if com = 1
        you've got to do something else to get the crowd on your side in this fight—with your average combat skills, there's no way that you're going to fend off three guardsmen at once.
        *label comchoice
        *choice
          #I shout threateningly, "Chirex, don't be a fool—you know you can not win against us."
            Chirex thrusts her hand out with a snarl.  You feel yourself yanked off the ground, tumbling upward in dizzy spirals until you're higher than the house-eaves around the square.  "You dare to threaten a Theurge, traitor?"

            *if (elery = 0) and (int = 1)
              "How much blood do you have left, Chirex?" you retort, trying to keep your voice loud and steady despite your lurching flight.  "After all you've spent levitating people already today?  Enough to hurt me, surely; enough to throw a few of us around.  But not many of us—not if you still want to be able to ward yourselves.  So kill me if you will.  But if I were you, I'd use that blood to ward myself and start running now."

              Chirex's cheeks drain of color; she visibly struggles and fails to find an answer. Seeing her at a loss gives the helots the confidence they were lacking.  Breden shouts, "$!{he}'s right!  Break the Harrower!  Tear it down!"  As the tradesmen and nobles at the edges of the agora scatter and flee, the crowd surges forward with a mighty roar.
              *goto violence
            *elseif int = 2
              You call back to her with confidence born of the arcane texts you've studied.  "Your Theurgy is your weakness, Chirex.  You didn't come with enough magic to put down a mob.  You don't have any oil of vitriol, and those bandoliers of blood won't power a Change strong enough to tear apart more than two or three of us.  So throw me around, even kill me if you will—but if I were you, I'd use that blood to ward myself and start running now."

              Chirex's cheeks drain of color; she visibly struggles and fails to find an answer. Seeing her at a loss gives the helots the confidence they were lacking.  Breden shouts, "$!{he}'s right!  Break the Harrower!  Tear it down!"  As the tradesmen and nobles at the edges of the agora scatter and flee, the crowd surges forward with a mighty roar.
              *goto violence
            *else
              You call back, "We outnumber you.  Your magic isn't enough to stop us, and you brought too few Alastors to control an angry crowd…."

              Chirex brings her hand down in a sharp chopping motion.  Your voice rises into an involuntary, strangled yelp as you fly groundwards.  When you hit the dirt, for a moment you don't feel anything—you just hear your voice abruptly stop, and a dismal cracking sound from a dozen of your bones and joints.  Then the world goes white with agony, as you fight vainly to suck any air back into your lungs.

              Through the deafening thrum of pain in your head, you hear Chirex speak with cold authority.   "I don't see an angry crowd.  I see a town full of loyal subjects of the Thaumatarch, and one sorry rebel."
              *goto chirex-x
          #I try to inspire the crowd to rise up through an eloquent appeal.
            "Will you stand for this?" you cry out to the helots around you, standing your ground against the oncoming Alastors.  You pour all your passion into the plea, and a rumble rises up from the crowd in response, like an earth tremor.  The club-wielding enforcers pause and look around nervously.
            
            With a snarl, Theurge Chirex thrusts her hand out, and you feel yourself yanked off the ground, tumbling upward in dizzy spirals until you're higher than the house-eaves around the square.  You fight to keep your voice steady despite intense vertigo, calling out, "Will you stand quietly by while the Theurges continue to murder your sons and daughters, your brothers and sisters?  This is the moment for you to claim a new way of life—this moment, or none other, ever again!"
            *if insincere > 0
              It's surprisingly easy to bellow aloud the sympathetic insincerities you've murmured to helots in the past.

            *if cha = 2
              Moved by your powerful personal charisma, the crowd erupts in angry shouts and cries of assent.  Breden shouts, "$!{he}'s right!  Why should it always be helot blood that fuels the Wards?  Break the Harrower!  Tear it down!"  The second Theurge levitates four more of the rowdiest helots and slams them brutally into buildings, but it is too little, too late.  As the tradesmen and nobles at the edges of the agora scatter and flee, the crowd surges forward with a mighty roar.
              *goto violence
            *else
              But your charisma is not enough to outweigh the terrifying sight of you being flung around in the air like a puppet.  The helots fall back into a shame-faced silence, keeping their distance from the Alastors.  It's hardly surprising, but you still feel a crushing disappointment—not least to see Breden open ${xhis} mouth again, glance around, and close it without speaking.

              Chirex smiles and brings her hand down in a sharp chopping motion.  An involuntary, strangled yelp bursts from your throat as you fly groundwards.  When you hit the dirt, for a moment you don't feel anything—you just hear your voice abruptly stop, and a dismal cracking sound from a dozen of your bones and joints.  Then the world goes white with agony, as you fight vainly to suck any air back into your lungs.
              *goto chirex-x

      *else
        you'll have to fight as well as you ever have to get the crowd on your side.  At least you're not unarmed; 
        *if aristo
          the club isn't that far from the wooden practice swords that you started with at House Keriatou.
        *if helot
          the club is a far cry from your quarterstaff, but you think you can make it do.
        *if female
          You recognize the smug look on the Alastors' faces; 
          *if aristo
            just like your male Keriatou cousins,
          *if helot
            like some of the brawnier boys you faced in scrum-ball,
          they're confident of beating you because they've got more height and muscle.  So you will still have some advantage of surprise after all….
        *page_break
        You run toward the leftmost of the three oncoming guards, deflecting his wild swing and driving your own weapon into his throat.  He folds over, croaking, and the other two are on you.  As you dance backward, dodging their blows and returning a few of your own, you hear cheers start to rise behind you.  

        *if elery = 0
          But the cheers are still hesitant, with the horrific executions of the thirteen young helots still fresh in memory; no one is ready to join you and risk being the next one levitated into the Harrower.  You need to spur them into action some other way.
          *goto comchoice
        *else
          "Join me!" you cry, cracking your club against the knee of one of your assailants,  "Together we can beat them!"  This is clearly too much for Theurge Chirex; you feel yourself yanked off the ground, tumbling upward in dizzy spirals until you're higher than the house-eaves around the square.  Your father raises his head, and at the fury and despair in his eyes you momentarily lose heart.
          
          But the alarmed Theurges have acted too late.  Seeing you bring down two Alastors single-handed has given the helots the confidence they were lacking, and the taste for vengeance.  As the tradesmen and nobles at the edges of the agora scatter and flee, the crowd surges forward with an animal-like roar.
          *goto violence
  *if (elery > 0)
    #Exhale again slowly.  [i]Are you mad?[/i]  I'd accomplish nothing but my own death.
     *set secondthoughts 1
     *goto caution
*label violence
*page_break
To your elation, you watch the charging helots overrun the panicking Alastors. 
*if int < 2
  You hold your breath, waiting for the Theurges to begin calling vitriolic fire to consume the crowd, but the only sign of magical intervention is three or four more helots being levitated and wielded as human bludgeons. 
The Theurges plainly don't have enough blood phials to fuel magic more complicated than kinesis—throwing people and objects around—or to turn the tide of the fight through magic alone.

Any moment now, the crowd is going to reach the wheeled platform where the Theurges and Ecclesiast stand next to the Harrower.  
*if aristo
  Your father is waving his hands frantically, eyes fixed on you. "Stop them, ${girl}, stop them!  Angels, just stop!"
  
  *comment endif
Are you going to try to influence what the angry mob does to the Hegemonic authorities?
*choice
  #This is no time for me to say anything.  Let the crowd decide what vengeance is appropriate.
    *set anarchy +6
    You watch silently from the air as the helots disarm the Alastors and beat them senseless with their own clubs.  It's plain that the majority of the hated enforcers won't be getting up again.  Hieros Zebed goes down with a glancing blow to the head.  The second Theurge is grabbed from behind while he's still trying to levitate more helots; he screams as he's pulled off the platform, but three helots with clubs swiftly silence him for good.
    *goto chirexward
  #We need to make a brutal example of the authorities.  Every servant of the Thaumatarch who hears about this day should fear us.
    *set anarchy +10
    *set violence +1
    *set cred_a -20
    *set cred_p -10
    *set cred_m -10
    *set ruth %+20
    *set ruthreal %+20
    You cry, "Let no Alastor or Theurge live!  
    *if theurgy = 4.1
      Tear them apart!
    *if theurgy != 4.1
      Feed them to the Harrower!  
    They came to shed our blood—let theirs be poured out instead!"

    The crowd bays angrily in response.  Within seconds,
    *if theurgy = 4.1
      the Alastors have been beaten to death with their own clubs, and a shrieking Ecclesiast Zebed has been dragged from the platform and trampled by the mob.  The second Theurge is grabbed from behind while he's trying to levitate more helots; his captors attack him with their fingernails and fists until his cries stop.
    *if theurgy != 4.1
      the Alastors have been borne down and a shrieking Ecclesiast Zebed has been dragged from the platform.  The second Theurge is grabbed from behind while he's trying to levitate more helots; his captors quickly thrust him into the blades of the still-chattering Harrower, and drag their other captives over to feed them in as well.
    *goto chirexward
  #We should try to execute them quickly and cleanly, while we have the upper hand.  It's the only just punishment for their crimes.
    *set anarchy +7
    *set violence +1
    *set cred_a -10
    You shout, "Let the Alastors and Theurges be executed for their murders!  Show no mercy—this is the hour of justice, the day of reckoning!"

    Killing people with clubs is an ugly business, but the helots are grimly determined.  The Alastors and Ecclesiast Zebed go down quickly.  The second Theurge is grabbed from behind while he's still trying to levitate more helots, and dragged off the platform to his death.
    *goto chirexward

  #We should try to take them alive and try them for their crimes before we execute them.  We must maintain order, or we're no more than a violent rabble.
    You shout, "Take them alive!  Kill only those who fight to the death.  Before executing them, we will give them a fairer trial than they ever gave their victims."
    *set cred_a -5
    *if (cred_h > 150) and (cha > 0)

      It clearly goes against the grain, but the crowd heeds your call for restraint, thanks to your 
      *if cha = 1
        mild 
      charisma and 
      *if aristo and not(helotrefuse)
        the credibility you've earned in your political dialogues with Breden and ${xhis} friends. 
      *if aristo and helotrefuse
        the credibility you've earned over the years by your
        *if insincere > 1
          feigned
        sympathy with the helots' plight.
      *if helot
        your credibility with your fellow helots.
      One or two of the Alastors, hearing your order, 
      *if theurgy = 4.2
        raise their empty hands 
      *if theurgy !=4.2 
        throw down their clubs 
      and plead for mercy.  The others are borne down and battered, but not killed.  The second Theurge is grabbed from behind while he's still trying to levitate more helots, and clubbed into unconsciousness.  Ecclesiast Zebed continues to shriek curses on you all, until he too is knocked out.
      *set anarchy +3
      *goto chirexward
    *else

      The enraged helots don't listen to 
      *if cha = 0
        you—it would have taken a more charismatic leader than you to turn them from their vengeance.
      *if cha > 0
        you.
      They beat the disarmed Alastors senseless or lifeless with
      *if theurgy = 4.2 
        bricks and bits of wood. 
      *if theurgy !=4.2 
        their own clubs.
      Ecclesiast Zebed goes down with a glancing blow to the head.  The second Theurge is grabbed from behind while he's still trying to levitate more helots; he screams as he's pulled off the platform, but three helots with clubs swiftly silence him for good.
      *set anarchy +7
      *goto chirexward
  #We should try to disarm them and let them live whenever possible.  We need to transform the Hegemony, not to alienate and terrify the people who run it.
    *set ruth %-20
    *set ruthreal %-20
    *set cred_a +10
    *set cred_p +10
    *set cred_m +5
    *set gandhi 1
    You shout, "Take them alive!  Disarm them, but do not kill them unless they force you to.  We are not murderers,
    *if breden = 1
      my brothers and sisters.
    *if breden > 1
      nor Xaos-lovers.
    If we really believe we can make a way of life that doesn't rest on bloodshed, let it start here.  Take them alive!"
    *if (cred_h > 150) and (cha = 2)
      *set anarchy +2
      *set gandhi +1
      *achieve clemency

      Without your extraordinary charisma and credibility with the helots
      *if aristo and not(helotrefuse)
        (earned in your unrestrained conversations with Breden and ${xhis} friends)
      *if aristo and helotrefuse
        (earned by the 
        *if insincere = 0
          obvious
        *if insincere > 1
          feigned
        compassion with their plight that you've shown over the years)
      you're sure that your appeal for clemency would never have been heeded.  You hear more than a few exclamations of disbelief—"Is ${he} serious?"—"Are we supposed to just let the bastards go?"—but enough of them are willing to follow your lead to keep the crowd from rampaging out of control.

      Several of the Alastors, hearing your order,  
      *if theurgy = 4.2 
        raise their empty hands 
      *if theurgy != 4.2 
        throw down their clubs 
      and plead for mercy.  The others are borne down and battered, but not killed.  The second Theurge is grabbed from behind while he's still trying to levitate more helots, and clubbed into unconsciousness.  Ecclesiast Zebed continues to shriek curses on you all, until he too is knocked out.
      *goto chirexward
    *else

      The helots totally disregard 
      *if cha < 2
        you—it would have taken a more charismatic leader than you to turn them from their vengeance.
      *if cha = 2
        you.  
      They beat the disarmed Alastors senseless or lifeless  
      *if theurgy = 4.2 
        with bricks and bits of wood. 
      *if theurgy != 4.2 
        with their own clubs. 
      Ecclesiast Zebed goes down with a glancing blow to the head.  The second Theurge is grabbed from behind while he's still trying to levitate more helots; he screams as he's pulled off the platform, but three helots with clubs swiftly silence him for good.
      *set anarchy +7
      *goto chirexward
*label chirexward

The terrified-looking Theurge Chirex manages to levitate herself just before the helots overrun the Harrower.  Their hurled stones and clubs bounce off her black coat without effect.  As the 
*if (anarchy > 7) and (theurgy != 4.1)
  last screaming Alastor is manhandled into the Harrower and the 
fighting subsides, the eyes of everyone in the town drift upward—to her and to you.
*if elery = 0
  *set followers 279
  *set morale 280
  *goto chirex-x
*else
  *set followers 292
  *set morale 293
  *goto chirex-x

*label caution
You won't let yourself be carried away by daydreams of rebellion.  That's just a good way to get yourself and your father killed.

To your shock,
*if helotrefuse
  one of the supposedly unconscious young helots suddenly
*if not(helotrefuse)
  the battered Elery Skinner springs up from "unconsciousness" and 
launches herself at the two magi, her hands clawed and teeth bared.  But even before the Alastors have a chance to club her down, the second Theurge thrusts out his fist and 
*if helotrefuse
  the helot girl
*if not(helotrefuse)
  Elery
is wrenched backward off her feet.  

"Ah, Angels," she howls as she rises off the ground, floating toward the maw of the Harrower.  "Damn the Thaumatarch!  And damn you all!"  The manacles clack inexorably shut around her wrists and ankles, and you close your eyes.  Her shriek grows more piercing, then ends abruptly in a chattering of blades.  The only sounds are the sobs of the other doomed helots and the splash of blood into the urns at the base of the machine.

The execution of the other twelve goes swiftly; the Alastors manhandle them into the Harrower with no further need for Theurgy.  You keep your eyes averted from both the carnage in the town square and Breden's ashen face.  When the evaders are all dead, Theurge Chirex speaks again, a note of relief clear in her voice.  "Heed well, children.  This is the end of all lawbreakers, heretics, and rebels.  Let no heart dare to harbor disobedience against the Canon of Xthonos."

As you look around the crowd, you are fairly sure that the display has had its desired effect.  Any spark of anger or defiance has been quenched, replaced by dread and resignation.
*set elery 0
*set poric 0
*set pin -20
*set yebben 0
*set alless 0
*set literate 0
*set ruthless +1
*set el_here false
*set morale -20
*page_break
"Now let the Angels reveal the Foreknown," Chirex says briskly.  A murmur of numb disbelief ripples through the crowd.  Thirteen is already far more than the usual Harrowing; are they really going to continue with the typical harvest rite?  "Those predestined for sacrifice will receive joy far outweighing all the pains of this terrestrial life."

The second Theurge once again raises his hand, and a young man flies up out of the crowd.  "Caine Abler," Ecclesiast Zebed names him.  You see Breden flinch;
*if not(helotrefuse)
  while the victim hadn't joined your seditious meetings, you'd seen him eagerly speaking with Breden in the town several times.
*if helotrefuse
  while you don't recognize the victim from your brief encounter in the woods, you can only imagine that he had joined since then.
The unfortunate Poric Weller and one other youth are also pulled magically from their feet to hover in the middle of the town agora.

And then the shout that you knew was coming: "Breden Reaper."

Breden rises off the ground and begins to float toward the Harrower.  $!{xhis} beautiful face is contorted with fury and despair.
*choice
  #Now I really have no choice but to stop the Harrowing.
    *if secondthoughts = 1
      Your choices look roughly the same as they did a minute ago.  You could:
      *goto samechoice
    *else
      *goto odds
  *if (bred_lover > 0) or (bred_heart < 5)
    #I'll grieve for Breden—but I am not going to throw my life away for ${xhim}.
      *set ruthreal %+5
      You choke back the cry forming in your throat and stare fixedly at the ground.  It 
      *goto caution2
  *if bred_heart >= 10
    #$!{xhe}'s only getting what ${xhe} deserves.  Why would I lift a finger to help ${xhim}—let alone throw away my life?
      *set ruthreal %+5
      You stare stonily at the upstart helot.  Even if you'd wanted to help, it
      *goto caution2
  *else
    #I need to stay quiet and hope no one knows that I was involved in Breden's treason.
      You hold your tongue and stare fixedly at the ground.  It 
      *goto caution2

*label caution2
would be insanity to try to take on two Theurges and twenty Alastors—would anyone in this cowed multitude really dare to stand beside you, after so bloody a reminder of the Thaumatarchy's power? 

Chirex selects three more helots from the sullen crowd—all young, all doubtless more of Breden's friends.  They begin to sob as soon as they rise into the air.  Your throat is dust-dry as you wait to be the next one pulled out by the invisible hooks of Theurgy.  But then you hear Ecclesiast Zebed cry out, "Blessed are the Chosen, whose sacrifice saves us all," his voice so detestably smug…and you nearly burst into tears yourself as you realize that the selection has passed you by.

The Theurges propel their second lot of victims into the blades of the Harrower, one by one.
*if breden = 1
  You want nothing more than to keep your eyes on the dirt, but you feel you owe it to the condemned at least to watch their sacrifice.  Six in turn are bled dry by the machine.  You feel something in yourself draining away with each one of them.
*if breden > 1
  You watch numbly as they are drained, hardly daring to believe that you've escaped the purge.

And finally Breden begins to drift toward ${xhis} execution.  $!{xhe} casts ${xhis} head around frantically, ${xhis} face wrung with terror as ${xhe} scans the crowd one final time.  $!{xhis} eyes meet yours, 
*if bred_heart < 10
  transfixing you with shame.  Then your
*if bred_heart >= 10
  and a sudden fury blazes up in them.  Your
heart thuds heavily in your chest as ${xhe} screams, "Help!  Save me!"
*set bred_yell 1
*page_break
Over a chorus of murmurs and gasps, you can hear your father's ragged intake of breath with awful clarity.  Breden stops, hovering mere yards from the manacled heart of the Harrower.  "What is this?" Theurge Chirex purrs.  To your horror, a fleeting glance reveals that she is staring straight at you.  Before you can do anything, you feel yourself lurch upward, tumbling in dizzy spirals until you too are floating higher than the house-eaves.

"Your gracious Ecclesiast knew there was treachery and rebellion in this town," Chirex declares.  The wizened Zebed nods solemnly at her side.  "The Angels have shown us that it is not yet fully rooted
*if aristo
  out! Indeed, it has spread beyond the helots and infected even the aristocracy."
*if helot
  out!"  
Her lip curls up with theatrical repugnance as she regards you.

*if aristo  
  A public accusation of treason from a Theurge is as good as a death sentence—there is no need for a formal trial, and no one would be foolish enough to try defending you.  Most of the other nobles at the fringe of the crowd look like they share Chirex's disgust, in any case.
Your father gazes up at you in desolation, his hands wilted at his sides.  Scanning the crowd of dejected helots, you know that at this point, nothing you can do or say would incite them to fight.  You are about to die in the Harrower.

A remarkable sense of calm and clarity descends on you.  You have only one choice remaining: how best to sum up, in your last words, your defiance of the loathed Karagond Hegemony and its Thaumatarch.
*choice
  *if aristo
    #"Death without trial, based on the outcry of a helot?  How long can your Hegemony so recklessly disdain the ancient liberties of the nobles of Shayard, Theurge?"
      *set cred_a +20
      *set cred_y +5
      *set cred_h -10
      *set natl %+10
      *set natlreal %+10
      *set shayard 3
      A not entirely hostile murmur ripples through the small cluster of high-born spectators.  The much larger helot crowd regards you with emotions ranging from jaded disinterest to vengeful anticipation.
      *if not(helotrefuse)
        The only ones who might have stood up for you have already fed the Harrower.
      
      "Traitors have no liberties," yelps hieros Zebed.
      *if introrel
        "And you have been a friend of traitors since your childhood, ${lname}."

      "To stand up for the right order of things is no treachery," you shout back, gripped by a careless, joyful vertigo as you finally voice what has been in your heart for years.  "The aristocracy and free folk of Shayard have sat in silence for too long while their rights are trampled by Karagonds and their lackeys! I will not be the last to break the silen—"
      *goto crash
  *if aristo     
    #"Your Thaumatarch has built his Hegemony on the murder of helots.  I would rather die alongside them than live with their blood on my hands."
      *set cred_h +20
      *set cred_a -10
      *set cred_m -5
      *set ruth %-20
      *set ruthreal %-20
      There is a sharp intake of breath from around the square.  The helots regard you with suspicious wonder.  Some of the high-born spectators turn away and spit into the dust at this confirmation of your treason.
      *goto helotfriend
  *if helot      
    #"Your Thaumatarch has built his Hegemony on the murder of helots, Chirex.  Their blood cries out for justice—and sooner or later, justice will come."
      *set cred_h +20
      *set cred_a -10
      *set cred_m -5
      There is a sharp intake of breath from around the square.  The tradesmen and aristocrats on the fringe of the crowd glance around nervously to gauge the reaction to your words.  The other helots stare at you with a mixture of resignation and admiration.  
      *label helotfriend
      "You dare?" yelps Ecclesiast Zebed.  "You dare to utter such sacrilege?"
                 
      "It is true," you shout back, gripped by a careless, joyful vertigo as you
      *if harrowpinion = 0
        finally voice what has been in your heart for years.
      *if harrowpinion > 0
        express what's been growing in your heart since your meeting with Breden.
      "Kill me for saying it, but you all know it is true.  There must be a way to preserve the world without slaughtering helots like cattle.  And if the Thaumatarch were not a devil, he would have found it."
      *goto crash
  #"Xthonos and Its mighty Angels reject you and your lies, Chirex.  This is nothing but a murder, and your Thaumatarch is a contemptible blasphemer."
    *set skep %-20 
    *set skepreal %-20 
    Your sacrilege transforms the agora into a statuary yard—for an astonished moment, no one moves, no one so much as exhales.  Then a shocked hum of whispers rises from the crowd, while Ecclesiast Zebed shrieks, "You dare?  You dare to utter such filth about the sacred sacrifice?"
                 
    "It is true," you shout back, gripped by a careless, joyful vertigo as you 
    *if harrowpinion = 0
      finally voice what has been in your heart for years.
    *if harrowpinion > 0
      express what's been growing in your heart since your meeting with Breden.
    "Kill me for saying it, but you all know it is true.  The merciful Angels must know of another way to preserve the world.  And if the Thaumatarch were not a devil, he would have found it."
    *goto crash  
  #"The Angels told you to kill me?  What a pathetic sham, Chirex.  Stop using children's superstitions to justify your master's atrocities."
    *set skep %+20 
    *set skepreal %+20 
    *set cred_p -20
    Your sacrilege transforms the agora into a statuary yard—for an astonished moment, no one moves, no one so much as exhales.  Then a shocked hum of whispers rises from the crowd, while Ecclesiast Zebed shrieks, "You dare?  You dare to utter such blasphemies?"
                 
    "Bleeding Gods, let us speak clearly for once," you shout back, gripped by a careless, joyful vertigo as you finally voice what has been in your heart for years.  "Your Hegemony murders the weak to protect the mighty.  And you claim the 'merciful Angels' told you to do it?  I say if Xthonos exists, and if It really commands the Harrowing, then It and Its damned Thaumatarch are monsters and criminals.  There must be another way to preserve the worl—"
    *goto crash  
  #"You murderous Karagonds can not oppress our people forever.  Shayard will be free again!"
    *set natl %+20
    *set natlreal %+20
    *set cred_a +5
    *set cred_y +10
    *set shayard 2
    There is a sharp intake of breath from around the square.  The strongest reactions come from the aristocrats along the fringe of the crowd.  Those dressed in robes and caps of traditional Shayardene cut look at you with scarcely veiled admiration, while the assimilated minority wearing Karagond coats and circlets begin to shout, "Sedition!  Treason!"
                 
    "You have forgotten who you really are," you shout back, gripped by a careless, joyful vertigo as you finally voice what has been in your heart for years.  "Kill me for saying it, but you all know it is true.  Noble or serf, we are all true Shayardfolk.  The Hegemony has no right to our blood, or our land.  Let Karagonds bleed each other to fend off the Xaos-lands—we are strong enough to fight Xaos ourselves, if only we could throw off the yoke of the Thaumatar—"
    *goto crash  
*label crash     
                 
Chirex brings her hand down in a sharp chopping motion.  An involuntary, strangled yelp bursts from your throat as you fly groundwards.  When you hit the dirt, for a moment you don't feel anything—you just hear your voice abruptly stop, and a dismal cracking sound from a dozen of your bones and joints.  Then the world goes white with agony, as you fight vainly to suck any air back into your lungs.
*page_break
Through the deafening thrum of pain in your head, you hear the Theurge Chirex demand, "What is your name, traitor?"
*goto name       
                 
*label chirex-x  
*page_break
The Theurge Chirex's voice 
*if anarchy > 0  
  is thick with fear and hatred. 
*if anarchy <= 0  
  is barely audible to you through the haze of pain. 
"Who are you, blasphemer?"
                 
*label name      
*if anarchy > 0  
  "My name is ${fname} ${lname}, Theurge," you reply coolly. "Run back to Shayard City and tell them that we'll have no more Harrowings here."
                 
  Chirex glances down at the remaining phials clenched in her fist.  She is clearly weighing her ability to crush you or dash you to the ground and still fuel enough magic to escape herself.  "What do you dream your little rebellion will achieve?" she finally shouts, voice shaking.  "No more Harrowings?  Xthonos be witness, we will wring the blood from every last man, woman, and child who stands in this agora 
  *if theurgy > 4
    today!  And you, Goete, demon…I'll see you burn for your Xaos-loving sorcery."
  *if theurgy <= 4
    today!"      
  Before anyone can respond, she flies away to the east, fast as a stone from a sling.
                 
  *if anarchy < 4
    The crowd mills around uncertainly as your new rebels grasp the full import of their actions.  You need to keep them from losing momentum and courage.  "Tie up those men," you quickly order, pointing at the captive authorities.  "Bind them tight.  And the rest of you: destroy that machine."
                 
    Cheers rise up from every throat in the square.  The helots attack the 
    *if theurgy = 4.1
      stalled    
    *if theurgy != 4.1
      still-clattering 
    Harrower with their bare hands and harvesting tools, prying apart its well-oiled workings and emptying the blood urns into the dust. As they work, Chirex's magic
    *if theurgy = 4.1
      dissipates
    *if theurgy != 4.1
      dissipates, the Harrower's spinning central gear slows to a halt, 
    and you feel yourself sinking slowly back toward the ground.
    *if int = 2  
                 
      If the Harrower hadn't been such an obvious target for the crowd's wrath, would you ever have considered trying to save the blood from the Harrower's urns and using it to fuel your Theurgical experiments?
      *choice    
        #Of course not. That blood came from murdered helots.
          You're eager to learn Theurgy, but not by using unjustly shed blood.
          *if elery = 0
            After seeing those thirteen young helots slaughtered in front of you, the idea of taking their blood for your experiments is grotesque.
                 
          *goto bloodstudy
        *if aristo
          #Alas, no—the helots would never stand for it.
            You're not inclined to be sentimental over blood that's already been spilt, but you can't imagine justifying it to the helots who have just rallied to your cause.
            *if elery = 0
              In particular, taking the blood of those thirteen young helots who were just slaughtered in front of you would be unthinkable.
            Perhaps later, when your hold over them is more secure?
                 
            *goto bloodstudy
        *if helot
          #Alas, no—my fellow helots would never stand for it.
            As far as you're concerned, the good you could do with that blood would redeem the deaths of the sacrificed helots.  But you don't imagine your other new-minted rebels would see it quite the same way, and you don't want to lose their loyalty just as you've gained it.
            *if elery = 0
              In particular, taking the blood of the thirteen youths who were just slaughtered in front of you would be unthinkable.
                 
            *goto bloodstudy
        #I didn't kill those helots, and I can't bring them back. If their blood could help my cause, I'd use it.
          For all you know, you may be the only person outside Hegemonic control who has been able to learn the basics of Theurgy.  You can't let sentimental qualms get in the way of learning the rest.  Becoming powerful enough to challenge the Thaumatarch is too important.
                 
          *set ruthreal %+5
          *goto bloodstudy
      *label bloodstudy
      In any case, from your studies, you're fairly sure that raw blood from a dead person can't fuel magic.  It has to be rarefied in a secret process to produce "aetherial" Theurgic blood. So even if you had been comfortable using the blood of sacrificed helots—and even if the crowd would have tolerated it—the contents of the Harrower's urns would have been useless for your experimentation, since you have no idea of how to rarefy blood.
    *page_break
    *if anarchy = 2
      By the time you touch the earth, the second Theurge has regained consciousness.  He strains against his bonds, beastlike in his terror, with eyes bulging and lips peeled back from his teeth.  Like so many Karagonds, he's been raised on stories of atrocities committed by "the tools of Xaos"—bandits, pirates, and rebel helots.  He clearly expects to be tortured to death by your mob.
                 
      You raise your voice as you approach him.  "You deserve death, Theurge, for all the helots you've slaughtered.  And by Xthonos, I want to punish you for your crimes!"  A grumble of assent rises from the crowd.  "But what I want even more is for the crimes to stop.  That's more important than vengeance.
                 
      "When your compatriots find you and these Alastors, tell them we didn't start this uprising to take revenge on Theurges, or Karagonds, or the nobility.  We'll kill no more people than we need to in reaching our ends."
                 
      Fear and incredulity seem to have stolen the Theurge's voice, but he finally manages a reedy whisper,  "I…I will tell them."
      *set bloodloot 1
      *page_break
      *goto wherenow
    *if anarchy = 3
      *achieve laworder
      Before your feet touch the earth, you scan the crowd and
      *if aristo 
        point to seven of the older helots.
      *if helot  
        beckon to the elders of the five helot camps.
      "Will you be our judges over these captives?  We must see justice done, and we must make it quick."  
      *if aristo 
        The grim-faced men and women nod
      *if helot  
        Facing the dour t'Keriatou elders, for a giddy moment you wonder if they're going to berate you again for "baiting the Harrower," but they just nod with the others
      and join you in the wreckage of the Karagonds' machine.
                 
      The trials are speedy indeed.  This Theurge took part in Harrowings in your town over the past year, and every sacrifice in the last eight years
      *if elery = 0
        (including of course the killing of the thirteen young townsfolk today)
      has been sanctioned and welcomed by Ecclesiast Zebed.  Your judges unanimously condemn them both on the evidence of multiple witnesses.  The Theurge is slain without ever regaining consciousness.  
      *if int > 1
        *set bloodloot 1
                 
        You notice as his body is dragged away that there are still four unused phials on his bandolier. Four drams of aetherial blood is precious stuff; it would allow you to practice Theurgy
        *if theurgy < 1
          (if ever you chose to)
        without opening your own veins and risking unconsciousness or death.
        *choice  
          #I take the phials.
            *set blood +4
            You slip them into your kyrtle.  Before anyone else has the chance to 
            *if theurgy > 4
              question the ethics of using helot blood, 
            *if theurgy <= 4
              ask what you're thinking,
            you brusquely gesture at the Ecclesiast.
            
            *goto zebeddead
          *if (not(choice_randomtest)) #That blood almost certainly came from a Harrowing. I'm not going to touch it.
            You wish you knew how to rarefy blood, but until you do, you're just going to have to keep using it straight from your veins. Grinding the phials underfoot, you brusquely gesture at the Ecclesiast.
                 
            *goto zebeddead
          *if (not(choice_randomtest)) #I don't dare to take the phials with everyone watching me.
            You wish you knew how to rarefy blood, but until you do, you're just going to have to keep using it straight from your veins. Grinding the phials underfoot, you brusquely gesture at the Ecclesiast.
                 
            *goto zebeddead
      *label zebeddead
      "Do you really think your little trial makes this less of a sin?" hieros Zebed howls as two field laborers position a thin, bent Harrower blade over his heart.  "The Angels spit upon this, this…mockery of justice, this blasphemous crime!  You will be damned to Taratur, all of you!"  You see some of the helots glance around in discomfort, despite themselves.
      *if skepreal <= 50
                 
        "You've no right to speak for the compassionate Angels, old man," you reply coolly.  "They are on our side, not on yours.  Make whatever account you can to Them."
      *if skepreal > 50
        *choice  
          #I want them to know I'm a skeptic, and to share my skepticism.
            *set skep skepreal
            *goto skepovert
          #I want to appear devout, hiding my true beliefs.
            "You've no right to speak for the compassionate Angels, old man," you reply coolly.  "They are on our side, not on yours.  Make whatever account you can to Them."
            *set skep %-10
            *goto gesturekill
          #I won't dignify his raving with any response.
            *goto gesturekill
        *label skepovert
        "If any Gods or Angels would call this injustice, then They are criminals too," you reply coolly.  "They may not have stopped your Hegemony from
        *if breden = 1
          murdering the weak.  
        *if breden > 1
          destroying all rightful order.
        But now we will."
      *label gesturekill
      You gesture to the helots, who thrust the blade downward.
                 
      A frantic young Shayardene Alastor cries, "Mercy, ${milady}!  We hate Harrowing the helots—but if we had not followed our orders, we would have been sacrificed ourselves!"
      *choice    
        #He has a point.  We shouldn't punish the Alastors as severely as the Theurges.
          *set ruth %-10
          *set ruthreal %-10
          *if aristo
            You address the seven frowning helot elders.  "If we execute these men for assisting in the Harrowings, we will need to kill every Alastor in Shayard.  I would advise that we execute only Alastors who have grossly abused their power, and give some lesser punishment to those who just followed orders."
          *if helot
            You look to the frowning helot elders.  "If we kill them just for helping with Harrowings, we'll have to kill every Alastor in Shayard."
                 
            "That a problem, ${girl}?" a beady-eyed t'Pelematou elder inquires.
                 
            "I say it is," growls Gillian Adze, before you can reply.  "Let's bite off no more trouble than we have already."
                 
            "They're here to carry out the law.  The law could be bad or good, it's not theirs to change," Hetten Halt-Hand agrees, rubbing his mustaches thoughtfully.
                 
            "What law was that one enforcing when he beat my son and took his lambs?" an elder from the de Rose estate snaps, pointing at a burly local enforcer.
                 
            "None," you cut in, hoping to satisfy both the cautious t'Keriatou elders and the more fiery ones from the other camps.  "So if an Alastor's found guilty of crime beyond their calling, let them pay with their lives.  If they just followed orders, give them some lesser punishment."
          Not all of your impromptu judges look convinced, but for now they're willing to follow your lead.
                 
          It takes three hours to try the Alastors, as the helots of your town are finally free to come forward and describe what they have suffered.  
          *if aristo
            Hearing the accusations, you are
            *if breden = 1
              stunned, sickened, and not a little ashamed.
            *if breden > 1
              stunned and not a little sickened.
            You've heard complaints about Alastors' bullying and extortion from traders and the petty aristocracy; you had no idea how much worse the abuse could be with people who are totally powerless to resist.
            *if breden > 1
              *choice
                #It confirms what I've been telling the helots all along.  No abuses by Shayardene nobles can equal those of the Hegemony!
                  *goto intheendalastor
                #I reflect uneasily on how my noble kin would fare if they were brought before this sort of tribunal.
                  It isn't just the Pelematou; far too many aristocrats, including your Keriatou cousins, have been guilty of the cruelties the helots are describing.
                  
                  *goto intheendalastor
                #I just feel nauseated at having to sit through these filthy tales.
                  *goto intheendalastor
          *if helot
            As you were well aware, nearly all of the town enforcers have abused their power over the helots.  It's a strange, marvelous thing to hear crimes described openly in the town square that for years were only whispered around the embers in your huts.
            
          *label intheendalastor
          In the end, most of the Alastors are executed for murder, rape, or theft.  Three of them, including the young man who appealed for your mercy, are found guilty only of upholding the Thaumatarch's law.  The judges have them whipped and put in the stocks, a common penalty for lesser infractions by helots.  
                 
          You don't have evidence to condemn the five who came with Theurge Chirex of anything but Harrowing.  When all the other punishments have been carried out, you stride over to them, fighting to keep your anger in check.  "I don't believe for a minute that you're less guilty than the dead men over there.  But there's no one we can ask to give evidence of your crimes today.  So remember: you're only alive because we care more about justice than your Theurge masters do."
          *page_break
          *goto wherenow
        #That's no defense.  They're still guilty of countless murders.
          *set ruth %+5
          *set ruthreal %+5
          "If you hated the Harrowings—if you knew they were wrong—what did you do to stop them?" you shout back.  "When did you find a helot who had missed the Summons and let her go free?  Can one man or woman in this square say that they owe their lives to your mercy?"  Neither the stricken-looking Alastors nor the helots utter a word, and after a long pause, you turn away.  "The only mercy you'll get this day is a quick death.  Consider yourselves fortunate that we don't try to repay you in kind for all the pain you've caused."
                 
          The executions go quickly.  When all the Hegemonic authorities are dead, a cathartic silence falls over the crowd.
          *goto wherenow
        #I look to the crowd around me to make the decision.
          They clearly aren't impressed by the man's appeal. "Mercy?" one of the 
          *if helot
            t'Pelematou
          helots beside you yells, seizing the young enforcer by his collar. "What mercy did we ever get from a swiving Alastor?"
          
          A wordless, vengeful clamor goes up again from the mob, and every one of the Hegemonic enforcers is borne to the ground by a dozen helots.  A few elders look hesitant, visibly shying away from the fray. But whatever they may say goes unheard, like the Alastors' pleas.
          
          When all the authorities are dead, a cathartic silence falls over the crowd.
          *goto wherenow          
  *if anarchy > 4
    For a moment, the crowd mills around uncertainly. Then 
    *if helot    
      your old friend Terret Abler
    *if aristo   
      someone    
    whoops, "On to House Keriatou!  The nobles have bled us no less than the Theurges.  It's time for them to pay, too!"  Rough cheers rise up across the square, and another man yells, "Sack the market!  Take the merchants' silver!"  
    
    The helots are primed for more vengeance against their oppressors.  In another eyeblink, they'll surely begin breaking into nearby traders' houses and charging up the hill toward the aristocrats' estates.  
    *if aristo
      You've never seen your father looking so undone.  This is the nightmare at which he hinted so many times: the hour when Xaos prevails, the chattel turn cutthroats, and all Order is swept away.
      
      *comment endif
    You are sinking slowly as Chirex's Theurgy dissipates; anything you shout will still be heard by everyone in the agora.  Breden is looking up to you, seemingly unsure of whether to encourage or attempt to quell the crowd.  What do you want to say?
    *set helotchoice 3
    *choice      
      *if (not(choice_randomtest)) #"Stop!  Don't loot the town.  We're no lawless mob!"
        *set cred_a +5
        *set cred_m +5
        *if (cred_h > 150) and (cha = 2)
          *goto mobshame
        *else    
          *goto mobfail
      *if (not(choice_randomtest)) #"Stop!  The nobles and merchants of Shayard are your own flesh and blood.  Save your vengeance for the foreign occupiers!"
        *set natl %+10
        *set natlreal %+10
        *set cred_a +5
        *set cred_m +5
        *set cred_y +5
        *if (cred_h > 150) and (cha > 0)
          *goto mobshame
        *else    
          *goto mobfail
      *if helot  
        #"Plunder the corrupt nobles; the traders are no enemies to us!"
          *set violence +1
          *set sicem true
          *goto mobnob
      *if aristo
        #"Plunder any House that oppressed you!  This is the day of vengeance!"
          Even after all the snubs and cruelties you've endured from your fellow aristocrats, something in you recoils as soon as the words leave your mouth.  But there's no unsaying them.
          *set violence +1
          *set cred_a -20
          *set sicem true
          *goto mobnob
      #"Plunder the corrupt traders; the noble estates are too well-defended!"
        *set sicem true
        *set violence +1
        *goto mobtrad
      #"Plunder the whole town!  We'll need all the food and wealth we can get!"
        *set sicem true
        *set violence +1
        *set cred_a -20
        *set cred_m -20
        *goto moball
                 
*if anarchy <= 0  
  No one answers at first.  The Theurge looks around, her eyes dangerously flat.  "Who is this ${woman}?"
                 
  "That's        
  *if aristo     
    ${kuria}     
  ${fname} ${lname}."  The hesitant response comes from one of the helots who
  *if aristo     
    worked on your cousins' estates.
  *if helot      
    used to work the fields with you.

  *if aristo     
    "Don't call ${him} '${kuria},'" Chirex retorts at once.  "$!{he} has forfeited all right to the title.  Call ${him} Shame-Veined, for ${his} treachery brings disrepute on all who share ${his} blood."  The nobles around the edge of the crowd murmur resentfully at this, but your vision is swimming too much to tell if their anger is directed more at you or the Theurge.
    *set slur "Shame-Veined"
    *set shameveined true
  *if helot      
    "${lname}?" Chirex repeats mockingly. "Call ${him} Filthborn instead.  Let ${him} be remembered only for the vileness of ${his} treason against the Thaumatarch."
    *set slur "Filthborn"
    *set filthborn true

  You cough and spasm with pain as the ungentle hands of the Alastors haul you upright.
  *if bred_yell = 1
    Chirex confers briefly with her fellow Theurge, then raises her voice again to address the town.  "These two traitors will not know the mercy of the Harrower.  They will be put to the question, that we might know how many others they have led astray.  Their blood will still feed the Great Wards—but we will draw it from them over days, not moments."
                 
    Breden's sobs begin again as ${xhe} is levitated away from the Harrowing machine.  You look around blearily, only half-comprehending what Chirex has said, until an Alastor's iron-tipped club drops onto your skull.  The world vanishes in a colorless, silent eruption of light.
    *goto jail   
  *else          
    "Now let ${him} meet the fate of all traitors," Chirex says.
    *if elery = 0
      "$!{he} will be bled like the other thirteen, as one Forsaken of Xthonos."
    With a flick of her wrist, you are pulled free from the grip of the guardsmen and drift through the air toward the champing blades of the Harrower.
    *page_break
    In the moments before your death, a bitter laugh wells up behind your broken ribs.  After all your daydreams of rebellion against the Hegemony, your great uprising has come no further than this.  You must be the least effective martyr ever to pit yourself against the Thaumatarch.
                 
    Then, just ahead of you, you see
    *if aristo   
      a helot    
    *if helot    
      Shiri Oxlaw from the de Rose estate
    whirl something above her head.  It looks like the sort of bola herders use to entangle the legs of runaway animals—only this one is made of chain, with bits of rusted metal hanging off it.  The Alastors shout an alarm and raise their clubs to fend off her weapon.  But she isn't aiming for them, or for the Theurges.
                 
    Instead, when she releases her weighted chain, it flies into the maw of the Harrower.  The fine blades shriek and warp on the unyielding metal, and the whole machine judders as the spinning gears come to an abrupt halt.  The Theurges and Ecclesiast Zebed are jolted off their feet.
                 
    In the uproar that follows, before the enraged Alastors club you into unconsciousness, all you can think is that 
    *if aristo   
      you'd never met the woman before.
    *if helot    
      you barely knew Shiri
      *if helotrefuse
        and hadn't spotted her in the shack with Breden's conspirators.
      *if not(helotrefuse)
        and she'd never been to Breden's meetings.
    You seem to have inspired one hapless follower after all.
    *set ruthless +2
    *goto jail

*label mobshame  
Without your     
*if cha = 2      
  striking
persuasiveness and     
*if (aristo) and not(helotrefuse)
  the credibility you've earned in your dialogues with Breden and ${xhis} friends
*if (aristo) and (helotrefuse)
  the credibility you've earned over the years by your
  *if insincere > 0
    feigned      
  sympathy with the helots' plight
*if helot        
  credibility with your fellow helots
the town would surely have been sacked.  Instead, the would-be looters stumble to a halt and fall silent, looking shamefaced and hesitant.
                 
*goto wherenow   
                 
*label mobfail   
Some of the people standing closest to you look embarrassed and hesitant, but you don't have sufficient
*if cha < 2    
  persuasiveness
  *if cred_h < 151 
    or
*if cred_h < 151 
  credibility with the helots
to stem the vengeful crowd.  You look on in helpless anger as the looting begins.
             
*set cred_a -5   
*set cred_m -5   
*goto moball     
                 
*label mobnob    
The crowd roars assent and surges toward the high ground where the aristocrats have their estates.

The bright houses and gardens of the lesser noble families were built for beauty, not defensibility, and their owners are all fleeing on horseback by the time you arrive.
*if aristo       
  "Traitor!" old Mikal de Rose bellows, audible from hundreds of yards away.  "Lickspittle, looter, turncoat, @{male bastard|bastarde}!  We'll see you chopped up for the bonetree, ${girl}, I swear it!"
   
  *comment end_if
In the rearguard, a daughter and son of House Tarakatou
*if int > 1      
  (Ganelon's older brother and sister)
expertly fire volleys of arrows back at you.  At first this enrages your charging helot mob, but they can't overtake the noble riders and eventually break and scatter to find cover.  By the time you regroup, you have lost more than a dozen helots and the nobles have escaped.
                 
With their masters fled, only a handful of defenseless retainers are left in the mansions.  Your mob strips the houses of portable food and treasure, sends the servants fleeing, and sets the tapestries and roofs alight.
*if helot        
  *gosub drachem 
*if aristo       
  You            
  *gosub ownhome 
  *page_break
*set anarchy +6  
*set cred_a -20  
*set followers -14
*set morale -20
*if sicem
  *set dead +14
*set wealth +414

Despite much bluster and cursing, in the end no one goes too close to the formidable little keep of House Keriatou.  Even with their Alastors out of commission, the aristarchs still have a blademaster, several well-armed scions, and a house guard of five men armed with bows.  From their tall battlements, the bowmen would likely massacre you.  Instead, your rebels put the family's extensive barley fields and fruit orchards to the torch.
                 
*gosub housekeriatou
You shake off your reverie and try to organize the helots, sending some to bury your casualties and distributing the plunder from the lesser estates so it can be easily carried.  By the time you're done, the sun is setting red among the conflagration.  "To the woods, quickly," you say.  "We'll make no plans where unfriendly ears might yet overhear us."
*goto bredensusp 
                 
*label mobtrad   
The crowd roars assent and swarms over the shuttered shops that ring the town square.
*set cred_m -20  
*if aristo       
  You try to ignore your father's appalled mutter, "Rampant thievery!" pitched at a level only you could hear.
The traders put up no resistance at all, pleading for themselves and their families to be spared from violence.  You see their children, many of whom you recognize, peering down in terror at you from upstairs windows and rooftops.  
*if ruth < 50    
  "Don't break or burn anything!" you shout belatedly.  "Take only what we need and can carry with us."

Many of the trade goods are too heavy to be of any use to you, but your helots pull out grain sacks and the traders' small caches of silver drachems and decadrachms.  Several merchants are dragged out and beaten by helots who believe they have more treasure secreted elsewhere, while your mob pries up floorboards and scours every room in their houses.
*if helot
  
  *gosub drachem 
*set anarchy +8  
*set wealth +243
                 
As time passes and the search bears less and less fruit, you grow uncomfortable with your exposed position.  Who knows when Chirex might return with more Theurges, or the armed aristocrats on the hilltop launch some sort of ambush?  You're sure your
*if aristo       
  cousins        
*if helot        
  former masters 
from House Keriatou will be desperate to crush you—an unpunished helot revolt could easily cost them their role as aristarchs of the district.  "To the woods, quickly," you shout.  "We'll make our plans there, where no unfriendly ears can overhear us."
*goto bredensusp 
                 
*label moball    
*set anarchy +10 
Thirty-odd cheering helots swarm over the shops that ring the town square.  Another, even larger group charges up the road to the nobles' estates.
*if aristo       
  You try to ignore your father's appalled mutter, "Rampant thievery!" pitched at a level only you could hear.
The terrified traders put up no resistance at all, handing over their silver drachems and pleading for their families to be spared from violence.  You watch for a moment as the mob begins prying up floorboards and scouring every room in the merchants' houses in search of unconfessed treasure.  Then you hurry up the hill after the others.
                 
The bright houses and gardens of the lesser noble families were built for beauty, not defensibility, and their owners have all fled on horseback by the time you arrive.  Breden and a few others are busily looting everything of value from the abandoned mansions.
*if bred_heart >= 10
  $!{xhe} hands off a huge bolt of woolen cloth and turns to face you, chest still heaving.  "You
  *if helotrefuse
    wouldn't even sit and talk with us,
  *if not(helotrefuse)
    forsook us,  
  ${kuria}.      
  *if breden = 4 
    You tried to bloody kill me.
  And now…this?" The anger that you'd heard before in ${xhis} voice was tempered by shame and a very reluctant hint of admiration.
                 
  You meet ${xhis} eyes, bleakly triumphant. "Would you have led us here, ${xgirl}?"
*if helot
   
  *gosub drachem
                 
Just as you're about to ask where the other helots have gone, a clamor of screams rises to the east—near the formidable little keep of House Keriatou.
                 
"Xthonos damn it," Breden cries in alarm.  
*if breden = 1   
  "${fname}—forty
*if breden > 1   
  "$!{kuria}—forty 
of the others headed that way, swearing to tear down the gate and come back with the aristarchs' heads."
*set followers -25
*set morale -30
*if sicem
  *set dead +25
*set wealth +657
*page_break
You meet the cowering survivors in a roadside apple orchard.  They had charged straight up to the gate of House Keriatou and tried to rip it off its hinges or pry the staves apart.  Then several bow-wielding guards and scions of the Keriatou appeared above the battlements and fired volleys of arrows straight down into the mob.  Roughly twenty helots were shot dead in the chaos there or picked off as they ran away.  Some of those who escaped have ugly wounds they are unlikely to survive.
                 
While disgusted at their recklessness, you know what they need now is leadership, not rebuke.  "Take heart!  The aristarchs will stay cowering behind their walls.  With their Alastors slain, there's nothing more they can do to us now.  This isn't the time to properly avenge our own dead.  But we won't forget this.  You eight, get torches. Set alight their barley fields and orchards."
                 
*gosub housekeriatou
*page_break
You regather your rebels and distribute the plunder from the merchants and estates so it can be easily carried.  
*if aristo       
  You also       
  *gosub ownhome 
  
  *comment endif
By the time you're done, the sun is setting red among the conflagration.  "To the woods, quickly," you order.  "We'll make no plans where unfriendly ears might yet overhear us."
*goto bredensusp 
                 
*label housekeriatou
For a moment, you stare out over the familiar landscape where you
*if aristo       
  learned riding and played at swords with your cousins.  You remember sitting under those pear trees, listening with mingled curiosity and envy as they recounted the glories and intrigues of the Archon's court in Shayard City.  And you remember the sting of fourteen-year-old Calea laughing, "Oh, ${fname}—what do you mean, when you come up for a Season?  We all know your father couldn't clothe you for a week."
                 
  Now you squint up at the crimson ram banner on the battlements, wondering whether Calea and her brother can see you as their orchards go up in smoke.
*if helot        
  stumbled behind your father as a child, gathering up the reaped grain, and where in time you learned the back-breaking art of the scythe yourself.  How quickly the overseers would scramble out of their enclosure whenever a figure appeared atop the keep wall.  "Keep up, you lazy clods!" they'd bellow histrionically, wading into the grain after you.  "Think the masters will feed you for such piss-poor work?"
                 
  Now instead of the sting of the switch on your shoulders, your eyes sting with the smoke of your masters' property.
*return

*label ownhome
head to your own home with a handful of helots and claim what you can from your old life: some ready silver and plate, the goat herd, 
*if int > 0      
  a few books from the library,
your swords.  Much of your living was tied up in accounts with the traders, all useless to you now.  "The ${lname} have fallen on hard times," you said apologetically to the young herdsman with you, looking around at the ransacked kitchen.  "If only we were wealthier…"
                 
"…you'd never have done what you just did, ${kuria}," he interrupted you, clapping you on the back.  "So don't you say a word against yourself."
*set wealth +63
*set weapon "sword"
*return          
                 
*label wherenow
*if aristo

  As soon as possible you hurry back to your father, scanning him for any sign of injury, Theurgic or otherwise.  "Father, did they do you any harm?"
  
  His mouth works for some time before he manages to croak, "Not yet."
  *if helotchoice != 3
    This, you realize, is the nightmare at which he hinted so many times: the hour when Xaos prevails, the chattel turn cutthroats, and all Order is swept away.  [i]And I'm the one who brought it.[/i]
  *if helotchoice = 3
    The horror you saw earlier in his face is undiminished as he stares at you.

One of the older stonecutters clears her throat uncertainly.  "Well then, ${kuria} ${fname}.  What do we do now?"

With all the helots of your town watching you, you feel a moment of giddy disbelief: not only is the rebellion you've dreamed of suddenly a reality, but you are its recognized leader.  There's no time to adjust to this unsettling fact, though.  If you wait too long here, the Hegemonic authorities will have time to strike back.
*if helotchoice = 3
  "To the woods, quickly.  We'll make no plans where unfriendly ears might yet overhear us."
  *goto bredensusp
*else            
  The only question is whether you need to take anything from the town before you leave—and that's a question not only about your needs, but about what kind of rebel movement you're going to lead.
  *choice
    *if (not(choice_randomtest)) #"To the woods, quickly.  We'll make no plans where unfriendly ears might overhear us."
      *goto bredensusp    
    #"Plunder the nobles' estates before we leave."
      *if aristo
        Even after all the snubs and cruelties you've endured from your fellow aristocrats, something in you recoils as soon as the words leave your mouth.  But there's no unsaying them.
        *set cred_a -20
      *set sicem true
      *set violence +1
      *goto mobnob
    #"Plunder the market before we leave."
      *set sicem true
      *set violence +1
      *goto mobtrad
    #"Plunder the whole town.  We'll need all the food and wealth we can get."
      *set sicem true
      *set violence +1
      *set cred_a -20
      *set cred_m -20
      *goto moball
                 
*label drachem   
One of your fellow helots thrusts a fistful of silver drachems at you, beaming with joyous ferocity.  You feel a moment of vertigo as you stare down at a dozen engraved profiles of the Thaumatarch; it's only the fourth time in your life that you've actually held a coin, and you've never had more than one before.
*return          
                 
*label bredensusp
*page_break
*if (int > 1) and (bloodloot = 0)    
  Before you leave, you return to the battered corpse of the second Theurge. There are still three stoppered phials on his bandolier. Three drams of rarefied, "aetherial" blood is precious stuff; it would allow you to practice Theurgy
  *if theurgy < 1
    (if ever you chose to)
  without opening your own veins and risking unconsciousness or worse.
  *if theurgy = 1
    If you'd had these, you might have dared to try to use Theurgy against Chirex today.
  In a future emergency, it might well mean the difference between life and death.
  *choice        
    #I take the phials.
      *set blood +3
      You slip them into your kyrtle. No one seems inclined to 
      *if theurgy > 4
        question you on your decision;  
      *if theurgy <= 4
        ask what you think you're doing;
      for the moment, apparently, you can do no wrong.
                 
      *goto outtown
    *if (theurgy <= 4) and (not(choice_randomtest))
      #I reluctantly leave the phials.  How would I explain what I wanted with them?
        You don't want to be demonized by the helots of Rim Square when you've just led them into rebellion.  If you do experiment with the bloody art, you'll just have to use blood straight from your own veins.
                 
        *goto outtown
    *if (theurgy > 4) and (not(choice_randomtest))
      #I reluctantly leave the phials.  I don't want my townsfolk to think I'm some sort of monster.
        You don't want to be demonized by the helots of Rim Square when you've just led them into rebellion.  You're just going to have to keep using blood straight from your own veins.
                 
        *goto outtown
    *if (not(choice_randomtest)) #That blood came from murdered helots. All I want to do is destroy it.
      *set ruthreal %-10
      *set ruth %-10
      *set cred_h +10
      You wish you knew how to rarefy blood, but until you do,
      *if theurgy > 4 
        you're just going to have to keep using 
      *if theurgy <= 4 
        the only moral option would be to use 
      it straight from your veins. You pull the abominable phials out of the bandolier and grind them underfoot. The crowd of helots around you murmur their approval.
                 
      *goto outtown
  *label outtown 
  *if theurgy > 4
    You had half-feared that your townsfolk would stone you as a Xaos-loving abomination; in the stories the Ecclesiasts told, the Angels would never bless a rebel with the gift of Theurgy.  But as you search the helots' eyes now, you see only awe and relief.  They have always told their own stories as well, in which the Angels gave them the power to set things right.  For now, at least, they see you through that frame.
    
As you stride out along 
*if introhlt
  one of your childhood routes 
*if not(introhlt)
  a hunters' track
into the wild, you can see that the crowd at your heels is a large one, close to three hundred.  Every helot camp in Rim Square is emptying before the certain vengeance of the Thaumatarch.  
                 
These are your rebels—and every second or third one you see is younger than fourteen years.  The Karagonds cull older helots, and producing many offspring is one of the best-known ways to postpone one's Harrowing.  You've been perfectly aware of the average age of the helotry, but still,
*if rebelrebel >= 1
  in all your imaginings of revolt
*if rebelrebel < 1
  if you'd ever imagined leading a revolt
you'd never      
*if rebelrebel < 1
  have           
pictured this host of children.  Your heart sinks as you try to imagine what it will take to protect them.
*if not(helotrefuse) and (pin > 0)
                 
  Then Pin dashes up to you,
  *if aristo     
    with a grime-covered, skittish young helot in tow.  "$!{kuria}!"
  *if helot      
    Alless Stonehewer in tow.  "${fname}!"
  She throws her arms around you, and you can feel her thin frame shaking.  There's blood on her kyrtle and arms, and she winces as you hug her back, as if her whole torso hurts.  But she doesn't let go.
  *if aristo     
    "I wanted to…this is Alless Stonehewer.  You saved her life.  Our lives."
                 
    You nod gravely to the runaway girl, who looks as if she'd run for the hills if you tried to hug her.  Then you murmur to Pin,
  *if helot      
    "You saved our lives.  Thank you, thank you, thank you."
                 
    You wrap Alless into the hug as well, and she melts into sobs.  Once she and Pin have both stopped crying, you murmur,
  "What          
  *if breden = 1 
    happened?"   
  *if breden > 1 
    happened, child?"

  "We all came to the meeting Breden called.  Except
  *if not(helotrefuse)
    you, and     
  Breden and Radmar."  The ten-year-old swallows hard.  "We thought it would be one of you at the door.  But it was…him.  The Theurge."
  *if gandhi > 0
    The faintest note of reproach enters her voice.  "The one you
    *if gandhi = 1
      tried to
    set free."
  *if gandhi = 0
    A fierce satisfaction thickens her voice.  "The one you killed."

  You nod pensively.  "And Elery and the others tried to fight."
                 
  "Elery and [i]me[/i] tried to fight," Pin retorts indignantly.  "Just because they didn't crack me on the head,
  *if breden > 1 
    ${milady},   
  you think I didn't fight them?  I blacked an Alastor's eye and put an elbow in another's nethers before they kicked all the wind out of me.  And we'll keep fighting them now, right?"  She searches your face.  "We're not just running, are we?  We'll get to fight back?"
  *fake_choice   
    #"We'll fight them as long as we've got breath in our bodies."
      "Good," Pin says gravely, disengaging from the hug.  "Hear that, Alless?  We're going to avenge your da."
                 
      The fugitive girl clasps your hand and speaks in a barely audible voice.  "Thank you, ${kuria} ${fname}."  The two of them bound off into the crowd again.
      
    #"If they come for us, then we'll fight them off."
      "All right," Pin says, sounding disappointed.  "Come on, Alless.  Let's go."  The two of them vanish into the crowd.
      
    #"For now, let's just keep our minds on escaping them."
      Pin shakes her head, looking angry and disappointed.  "Let's go, Alless."  The two of them vanish into the crowd.
  
  *comment endif
  *if allessfood
  
    Turning, you find yourself held in old Gillian Adze's level stare.  "So that's where that food was going, then?"
    
    It takes you a moment to remember what she's talking about.  "Aye. Smuggled it up to her."
    
    "Kept that close, didn't you?"  Her face remains unsmiling, but without any trace of the contempt you'd grown used to.  Could that glint in her eyes actually be respect?  "If all of you had stayed that discreet, we might not be in this mess now."
    *set cred_h +15
    *page_break
*if helotrefuse and (pin > 0)
                 
  A ten-year-old girl hesitantly approaches you; you recognize 
  *if helot      
    Pilyin Thatcher, a house drudge with friends in every helot camp in Rim Square.  You also saw her in the square today, awaiting the Harrower with the rest of Breden's gang.
  *if aristo     
    her from your visit to Breden's shack, and from the square today.
  She's dragging the grime-covered, skittish runaway, Alless Stonehewer.
                 
  "I'm Pin," she announces shakily,  "and…I wanted to thank you, ${kuria} ${fname}.  For saving us.  Me and Elery and Yebben and the rest, but especially Alless.  Her da was killed, you see.  If you hadn't saved us, we wouldn't be able to avenge him."  Alless gives you a tiny, wordless bow.
                 
  "I didn't save you, Pin," you say, weary but smiling.  "We all saved each other.  And we're going to have to keep saving each other for a while yet, I'm afraid."
                 
  She considers this for a minute, then nods with a sudden expression of ferocity.  "Don't worry, ${kuria}.  We're ready to save you too."
  *page_break
  Taking your leave from the two girls, you continue up the hill.
You stop abruptly when you see a large, shadowy form burst out of the brush ahead.  A half-dozen young helots rush in front of you, brandishing their motley array of weapons: axes, knives, staves, threshing flails.  Several more stick close to you, scanning the woods around for other threats.  Without asking for it, you seem to have acquired a guard.
                 
The big man stops and raises his hands.
*if helot        
  "${fname}!"   
*if aristo       
  "$!{kuria}!"   
Despite the familiar voice, it takes you a few seconds to recognize him under the thick half-dried layer of mud.
*choice
  *if aristo and helotrefuse
    #"Radmar, isn't it?" I greet him.  "We're relieved to see you alive."
      *goto radmaryay
  *if helot and helotrefuse
    #"See, Radmar?  I told you could trust me." I throw him a weary grin. "Glad to see you alive."
      *goto radmaryay
  *if (breden > 1) and not(helotrefuse)
    #"Radmar—we're relieved to see you alive."
      *goto radmaryay
  *if ((skepreal <= 50) and (breden = 1)) and not(helotrefuse)
    #"Radmar!" I exclaim.  "Thank Angels you're alive."
      *goto radmaryay
  *if ((skepreal > 50) and (breden = 1)) and not(helotrefuse)
    #"Radmar!" I exclaim gladly.  "We'd feared the worst."
      *label radmaryay
      *set r_rel +1
      Radmar's shoulders slump.  "Who else? Were the others—"
                 
      *if (elery = 0) and (breden > 1)
        "They were Harrowed, Radmar." You try to convey dignified sympathy.  "The Theurges took them. 
        *goto exceptbred
      *if (elery = 0) and (breden = 1)
        "I'm sorry, Radmar," you say after a moment, your throat achingly tight with regret.  "They Harrowed the others.  
        *label exceptbred
        Except for Breden—we saved ${xhim} just in time."
                 
        His face is an unreadable mask.  "And Alless?"
                 
        *if aristo
          "The runaway?"
        You shake your head.  "I'm so sorry."
                 
        Radmar stumbles to one knee, groaning.  "Damn them.  Oh, Xthonos blast them all black."  A savage light comes into his eyes.  "But…the rising started anyway?"
                 
        "It did," you say, gesturing around you.
      *if (elery > 0) and (breden > 1)
        "Not at all," you reassure him.  "All the rest of your little gang lived.  The Harrower's broken, the Alastors and Theurges beaten."
        *goto itsbegun
      *if (elery > 0) and (breden = 1)
        "No, no," you cry.  "Everyone's alive.  The Harrower's broken, the Alastors and Theurges beaten…it's all right, Radmar.  It's begun."
        *label itsbegun
                 
        He blinks, seemingly unable to take in what you've just said.  "The rising's started?  Truly?"
                 
        "Truly," you insist, striding forward to clasp his arms.
      "Where have you been?"
                 
      *goto radmarmud
  *if helot or (aristo and not(helotrefuse))
    #"Radmar," I say coldly. "Where have you been?"
      *goto radmarmud
  *if aristo and helotrefuse
    #"Radmar, isn't it?" I say coldly. "Where have you been?"
      *goto radmarmud
  #"You've missed some excitement, Radmar."
    *goto radmaryay     
*label radmarmud 
"As deep in the de Rose marsh as I could sink myself and still breathe," Radmar
*if (r_rel <= 10)
  snarls.  "Where have you been,
  *if aristo     
    ${kuria}?"   
  *if helot      
    ${lname}?"   
                 
  "Facing down a couple of Theurges," you retort, taken aback by his evident fury.  "Breaking a Harrower."
                 
  He blinks, seemingly unable to take in what you've just said.  "And the others?  Are they…were they…"
                 
  *if elery = 0  
    "They were Harrowed." 
    *if breden = 1
      Your throat is achingly tight with regret.
    *if breden > 1
      You try to convey dignified sympathy.
    "Except for Breden.  We were able to save ${xhim} just in time."
                 
    "And Alless?"  Radmar's eyes shine desperately.
                 
    *if aristo   
      "The runaway?"
    You shake your head.  "I'm
    *if breden = 1
      so         
    sorry."      
                 
    Radmar stumbles to one knee, groaning.  "Damn them.  Oh, Xthonos blast them all black."
                 
    *if breden = 1
      You walk over to him and crouch down, torn between suspicion and sympathy.
    *if breden > 1
      You crouch beside the overwrought helot, your voice stern but not unkind.
    "How did you escape, Radmar?"
                 
    Muddy tears are trailing down his broad cheeks.
  *if elery > 0  
    *if breden = 1
      "No, no," you cry.  "They took no blood from us this day.  It's all right, Radmar.  Everyone's alive…and it's begun."
    *if breden > 1
      "Calm yourself, boy," you say, not unkindly.  "They took no blood from us this day.  Your friends are alive, and what
      *if helotrefuse
        you've   
      *if not(helotrefuse)
        we've    
      talked about has come to pass."

    Radmar stumbles forward, eyes suddenly bright with hope.  "The rising's started?  Truly?"
                 
    "Angels, Radmar, use your eyes."  You gesture at the ring of armed young helots, the growing crowd behind you.  "You think this would happen if the Karagonds had won?  Now: how did you escape being captured with the rest?"
                 
    The hint of a smile vanishes from the big helot's face.
*if (r_rel > 10)
  says, losing the smile that had begun to soften his face.
"I was headed up to the shack for the meeting Breden called.  But I left the camp late—so I was still fifty yards out when the Theurge and the Alastors marched down out of the woods ahead of me."  He gives a helpless shrug.  "There were too many to fight.  I hid,
*if aristo       
  ${kuria}.      
*if helot        
  ${fname}.     
I didn't want to die."
                 
"You hadn't heard the Summons to the Harrowing?"
                 
"You think I'd have been up there if I had?"  Radmar
*if r_rel <= 10  
  glowers at you furiously.
*if r_rel > 10   
  spreads his hands.
"Course I hadn't.  None of us had."  He leans in to growl almost inaudibly, "None of us who were out there, anyhow."
*page_break
A familiar voice cries: "Radmar!  You're alive!"  Breden bursts through the circle, ${xhis} giddy exhilaration plain in every springing step.  $!{xhe} throws ${xhis} arms around the muddy helot, ignoring or not noticing Radmar's grimace.  Then ${xhe} turns to you.
*if bred_heart >= 10
  "$!{kuria}.  We owe you our lives."  $!{xhis} voice and face are neutral.
  *if anarchy > 9
    Both the enmity and the admiration you glimpsed before are buried again.

  *goto bredwnext
"And             
*if breden > 1   
  ${kuria}       
${fname}—I can't believe it!
*if theurgy > 4  
  How by Xthonos did you manage to learn [i]Theurgy[/i]?
*if theurgy <= 4  
  You stood up to the bloody-handed bastards.  
*if breden > 1   
  Forgive my presumption, but you
*if breden = 1   
  You            
were amazing.  And now this—this is what we've always dreamed of!"
                 
*label bredwnext 
"And we need to talk about what comes next."  You stalk away briskly, beckoning Breden after you, until you can exchange murmurs without anyone else overhearing.  "What exactly happened back there?"
                 
$!{xhis}         
*if bred_heart < 10
  smile falters.  
*if bred_heart >= 10
  polite facade collapses.
"What?  What do you mean?"
                 
"Zebed and Chirex knew that 
*if elery = 0    
  you and        
*if helotrefuse  
  your           
*if not(helotrefuse)
  our
  *if breden > 1
    little
friends had been talking treason and blasphemy."  You turn your head to stare straight at ${xhim} for a moment.  "How do you think they found out?"
                 
"Someone likely betrayed us."
*if bred_heart >= 10
  Breden spoke through clenched teeth.  "And now you're going to say it was me."
*if bred_heart < 10
  A note of incredulity enters Breden's whisper.  "And you're wondering if it was me?"

"I'm wondering the same things anyone would," you reply, keeping your voice level.  With so many questions welling up furiously inside you, it's a struggle to pick one to ask first.
*label interrogn 
*if questions = 5
  *goto traitorq 
*if (bred_heart >= 10) and (questions = 4)
  *goto traitorq 
*choice          
  *if helotrefuse
    *hide_reuse #"Why weren't you at the meeting where the others were caught?"
      *goto overseerafter
  *if not(helotrefuse)
    *hide_reuse #"Why weren't you up at the shack with the others?"
      *label overseerafter
      "I had an overseer after me all morning, demanding one petty job after another," Breden replies at once.  "By the time I shook her off, the Alastors had started the Summons.  It was too late by then to get word to the others.  I just hoped they'd stay out there safe until the Harrowing was done."
      *set questions +1
      *goto interrogn
  *if bred_heart < 10
    *hide_reuse #"Why wasn't I invited to the meeting?"
      *if helotrefuse
        "Because I still wasn't sure you wanted to be there, 
        *if breden = 1
          ${fname},"
        *if breden > 1
          ${kuria},"
        Breden sighs.  "And I didn't know if the others would welcome you back yet."
      *if not(helotrefuse) and helot
        "It wasn't a long-planned meeting," Breden says defensively.  "I only found out yesterday that Radmar would be willing to come, and so I thought we'd talk with him, hear the full story of what was happening with Poric.  But I wasn't able to get word to the Keriatou camp without raising suspicions."
      *if not(helotrefuse) and aristo
        "I can't invite you to all of them, ${kuria}," Breden says defensively.  "I only found out yesterday that Radmar was willing to come.  I thought we'd talk with him, hear the full story of what was happening with Poric.  But with so little time, I wasn't able to get to your House without raising suspicions."
      *set questions +1
      *goto interrogn
  *hide_reuse #"How do you think the Hegemony knew where to find them?"
    "Either a traitor told them," Breden offers, "or else they'd managed to follow us somehow.  We were careful, but even so, it's possible someone slipped up.  So mayhap they found out, and had someone watching the route this morning."
    *set questions +1
    *goto interrogn
  *if questions > 2
    *hide_reuse #"So who do you think could have betrayed you?"
      "I don't know,
      *if breden > 1
        ${kuria}
      ${fname}," Breden says levelly.  "It would be easy to point a finger at Radmar, because he also wasn't there this morning.  But I don't believe it was him.  He's honest."
                 
      "Not to be blunt, but wasn't everyone else
      *if elery = 0
        just Harrowed?"
      *if elery > 0
        hauled up for Harrowing?"

      "All those who came regularly, yes."  Breden
      *if elery > 0
        shrugs.  "But
      *if elery = 0
        turns away, face drawn with pain.  "And I nearly was too, you'll recall.  But
      there were people who came once or twice, 
      *if breden = 1
        ${fname}, 
      *if breden > 1
        ${kuria}, 
      and decided not to come again.
      *if helotrefuse
        You weren't the only one.
      I trusted them; clearly I was wrong.  Even if they didn't betray us, they let word slip to someone else who did."
                 
      *if not(helotrefuse)
        $!{xhe}'s right; in your time with the group, at least three young helots came to a meeting or two, then slipped away.
      "Do you remember everyone you invited to a meeting?"
                 
      "I do," Breden confirmed.
      *set questions +1
      *goto interrogn
  *hide_reuse #"Why didn't you try to stop the Harrowing?"
    *if bred_heart >= 10
      *set questions +1
      $!{xhis} face twists with contempt and hate. You recoil slightly before realizing it's not directed at you. "I broke.  When it mattered most…I didn't know what to do."
      *choice    
        #"A coward as well as a scoundrel," I reply scornfully.
          Breden turns a gaze of weary loathing toward you.  "You think you can say anything I won't be saying to myself for the rest of my days, ${fname}?"
          *goto interrogn
        #"Action isn't as easy as talk, it seems."
          "No.  And it's the doing that matters."  $!{xhe} makes a bitter gesture at the young helots who have spontaneously formed your guard.  "So here we are."
          *goto interrogn
        #"That's how it ends when a helot fancies ${xhim}self a leader."
          *set cred_h -3
          Breden's lips peel back from ${xhis} teeth, but ${xhis} voice remains even.  "If you expect all helots to fail, ${kuria}, you've chosen a poor way to begin your rebellion."
                 
          "I don't expect them [i]all[/i] to fail."  You let the silence fester for a moment, then shrug.  "Guided rightly, they'll fight better than any thrall of the Karagonds."
                 
          "Your turn, then, ${kuria}."
          *goto interrogn
    Breden's throat works in silence for a few moments before ${xhe} answers simply, "I was afraid."
    
    When ${xhe} says nothing more, you stop and stare at ${xhim}, wracked by both anger and profound disappointment.
    *fake_choice 
      #I lash out bitterly.
        "Truly?" you demand. "That's all you have to offer?  Breden Reaper, ever-bold provoker of the authorities, organizer of sedition, inspirer of rebellion…silenced by fear at the last moment?"  Hit with the full force of disillusionment, you don't know whether you'd rather it were true or false.
                 
        $!{xhe} turns hurt eyes on you and speaks in a voice thick with self-contempt. "Breden Reaper, loud mouth, user of ${xhis} friends, rebel in ${xhis} own mind…who broke when it mattered most.  Who stood there stuck and self-saving, and left it to
        *if aristo
          a bloody aristo
          *if harrowpinion > 0
            who doesn't even know whether ${he} thinks Harrowing's a bad thing or not
        *if helot
          ${xhis}
          *if bred_lover >= 4
            lover
          *if bred_lover < 4
            friend
        to save us all from the Theurges."  Seeing the other helots approach, ${xhe} sets off again with fleet, hunted steps.  "You think you can say anything I won't be saying to myself for the rest of my days,
        *if breden > 1
          ${kuria}
        ${fname}?"
        *set questions +1
        *goto interrogn
      #I shake my head and resume walking.
        Breden falls in beside you again.  "I broke," ${xhe} explains, voice thick with self-contempt.  "When they needed a leader…I couldn't move, and you were there."  $!{xhe} gestures back at the young helots who have spontaneously formed your guard.  "So here we are."
        *set questions +1
        *goto interrogn
      #But the anger fades quickly in the face of ${xhis} obvious remorse.
        "We were all afraid," you say at last. "You never know how you're going to respond until the moment comes."
        
        "And now we know." $!{xhe} seems almost as hurt by your gentleness as ${xhe} would have been by your wrath.  "Now we all know what to expect from Breden Reaper when lives are at stake."
        
        "No.  No, I'd hope we don't."  But it's hard to put conviction into your voice, as you search ${xhis} face for the answer to an unspeakable question.
        
        "${fname}, just now, what I saw in Radmar's eyes…" Breden shakes ${xhis} head, ${xhis} expression so disbelieving it approaches wonder. "Some folk will be calling me traitor after today.  Will you be one of them?"
        *goto traitorq3
  #I just stare at ${xhim}, the doubts obvious in my eyes.
    *goto traitorq
*label traitorq  

You stride up the trail for several moments without speaking.  At last ${xhe} catches your shoulder, 
*if bred_heart < 10
  still sounding incredulous. 
*if bred_heart >= 10
  ${xhis} voice harsh and brittle. 
*if breden > 1   
  "$!{kuria}.
*if breden = 1   
  "${fname}.
*if elery = 0
  Chirex picked me too!  I would have been fed to the Harrower if you hadn't saved my life.
*if bred_heart >= 10
  I know you've no fondness for me, but insolence isn't treachery.
You truly think I'm a traitor?"
*label traitorq3
*choice
  *if bred_heart >= 10
    #"Insolence is treachery, ${xgirl}: a betrayal of right order.  But I don't suspect you of more treachery than that."
      Breden's eyes search your face. "Believe me in this, ${kuria}.  I'll dig up the real traitor."
                 
      "Well, tell me if you find anything."  You see Breden react to the doubtful note in your voice, and add, "Whoever betrayed us will surely be lying low.  Waiting for the chance to hand us over to the Karagonds again."
                 
      "We'll not give them that chance, ${kuria}."  Breden bows and walks stiffly away.
      *goto father
  *if bred_heart < 10
    #"No, Breden.  You're one of the few I would trust."
      "I understand."  Breden's expression turns somber and uncertain.  "When we make camp tonight, let's talk more.  We'll need to take steps to protect our band against another betrayal while we dig up the traitor."
                 
      *if bred_lover = 4
        You pull ${xhim} close for a long kiss, no longer caring who sees.
      "Yes, we'll talk more then.  Keep your eyes and ears open."  You watch ${xhim} for a long moment as ${xhe} walks away, trying not to let your own uncertainties show on your face.
      *goto father
  *if bred_heart >= 10
    #"Let's just say I'm a damned long way from ruling it out."
      *set bred_trust +10
      The blood leaves Breden's lips as they press hard against each other. "So you truly hope to lead this band without relying on anyone?"
                 
      "That's hardly what I said."  Your voice is cutting, disdainful.  "I'll rely on those who prove themselves trustworthy."
                 
      "Then I'd best go off and start proving myself, ${kuria}." Breden bows stiffly.  "By your leave."
                 
      Looking down the trail after ${xhim}, you meet Radmar's eyes. The big helot nods with grim approval.
      *set r_rel +3
      *goto father
  *if bred_heart < 10
    #"Breden…until I find out who did betray us, I'm not ruling anyone out."
      Breden's face hardens.
      *if breden = 1
        "I thought I'd earned more of your trust than that, ${lname}.  Damn it, how do you hope to lead this band without relying on anyone?"
      *if breden > 1
        "Do you then hope to lead this band without relying on anyone, ${kuria}?"
      *if bred_lover = 4
        You hear hurt beneath the veneer of anger as ${xhe} drops ${xhis} voice.  "Did you not believe any of my promises?  Was I wrong to believe yours?"
                 
        "Don't bring that into it, Breden."  You sound more brusque than you'd meant to.
      *if bred_lover != 4
                 
        You keep your voice and eyes steady.
      "I'll rely only on people who prove themselves trustworthy.  The stakes are too high for me to make an 
      *if breden > 1
        exception."
                 
        Losing ${xhis} veneer of politeness, Breden snaps, "You'd never have got here if I hadn't pushed you, ${kuria}.  That's worth nothing now?"  Before you have time to answer, ${xhe}'s already turned ${xhis} back to you. "Well and good.  See how many helots will give you their trust when you're so sparing with your own."
      *if breden <= 1
        exception for my friends.  Even close friends."

        "Close friends?  Xthonos burn you, you brainsick 
        *if aristo
          dandy.  This isn't about finding traitors.  You're just like the rest—behind all your pretty words, you still believe that only nobles can be trusted to lead."  You open your mouth to protest, but Breden cuts you off.  "See how many helots will give you their trust when you're so sparing with your own."
        *if helot
          clod-kicker.  You're no friend of mine."
      $!{xhe} stalks away.
                 
      Looking down the trail after ${xhim}, you meet Radmar's eyes. The big helot nods with grim approval.
      *set r_rel +3
      *set bred_trust +10
      *goto father
  *if (not(choice_randomtest)) #"Yes, Breden. So start running now."
    *set bred_trust +10
    *set breden +10
    *set bred_here false
    $!{xhis} eyes widen in shock. "You…you'd truly dare…"
    
    *if bred_heart >= 10
      "Not another word, ${xgirl}," you grate out. "You're alive because I don't think you can do any more damage—and killing you without proof of your treason would needlessly upset the others.  But I'll not have you in my band, spreading your poison, waiting for another chance to betray us.  I'd kill you here and now rather than risk that."
    *if bred_heart < 10
      "I'd not dare to trust you again," you cut ${xhim} off at once.
      *if bred_lover >= 4
        Tears sting your eyes, but you don't let your voice quaver.
      "I'd rather not kill you, nor accuse you to the rest.  That much doubt I'd give in your favor.  But I'll not have you in my band, waiting for the next betrayal."

    Breden looks back wildly toward the approaching helots. "Sending me off on my own is a bloody death sentence, 
    *if aristo and (bred_lover < 4)
      ${kuria}.
    *if helot or (bred_lover >= 4)
      ${fname}.  
    The Hegemony will be combing all the camps in the Rim for any trace of us.  Where am I supposed to go?"

    "Anywhere but the wilderness where we'll be. Anywhere, so long as I never see you again."  You point east.  "Run. Now.  And 
    *if bred_heart >= 10
      let me be plain: if I hear that you've been speaking to any of my followers, I'll have you hunted down and killed for the traitor you are."
    *if bred_heart < 10
      don't try to speak to any of my followers—not now, not ever.  Don't force me to hunt you down and kill you as a traitor."
      *set bred_heart +10
      
    Breden's face contorts in despair as ${xhe} stumbles backwards.  "Xaos burn you, 
    *if aristo
      ${kuria} ${fname}.  You could have been great—could have been the leader we need.  But with your damned pride, and this brainsickness that makes you think your allies have betrayed you?  You'll 
    *if helot
      ${fname} ${lname}.  I thought you might have been the leader we need.  But if this is how you treat your friends when things go amiss…you'll fail, and
    die alone.  Remember me when that time comes." Before you can reply, ${xhe}'s gone.
    *goto father
  *if ((bred_heart >= 10) and (weapon = "sword")) and (not(choice_randomtest))
    #My only answer is to draw my sword and attack ${xhim}.
      *if cha < 2
        *set morale -10
        *set cred_h -10
      *if com < 1
        You clumsily pull out your little-used blade.
      Breden's eyes whiten incredulously.  $!{xhe} tumbles under your swing and sprints up the trail toward the forest.
      *if breden > 3
        Already well aware that ${xhe}'s too fast for you, you don't bother to pursue.
      *if breden < 4
        You run after ${xhim}, trying to get in another blow, but ${xhe}'s fleeing with all ${xhis} speed and quickly outpaces you.
      "Xaos burn you, ${lname}! You're mad!" ${xhe} gasps back over ${xhis} shoulder.
                 
      Turning back, you see your helot guard and the fastest-moving of your followers milling about in shock.  Some are brandishing weapons and ready to chase Breden, others just look confused and disheartened. 
                 
      "$!{xhe} betrayed ${xhis} friends to Chirex," you declare.  "$!{xhe} as much as confessed it to me."  Over the inevitable shocked hubbub, you call out:
      *set bred_trust +10
      *set breden 14
      *set bred_here false
      *choice    
        #"So after ${xhim}!  Hunt ${xhim} down.  Don't let ${xhim} live out the day!"
          *if cha = 0
            There's an uncomfortable murmur as no one follows your order.  "$!{kuria}…${xhe}'s one of ours," a grizzled helot says at length.  "We'd hear ${xhim} explain ${xhim}self before we talk of killing.  Don't worry—if ${xhe} comes back, we'll sort it out."
                 
            Their insubordination is infuriating, but this is clearly the wrong time to try to enforce your authority.  You let it go.
            *set cred_h -5
            *set morale -5
          *if cha > 0
            Several vengeful helots charge up the path where Breden vanished.  Given Breden's speed, however, you don't really expect them to catch ${xhim}. 
                 
            You stare after them for a moment, then growl a curse to yourself and put it out of your mind.
          *goto father
        #"Spread the word: if Breden's seen again, ${xhe}'s to be killed on sight."
          "As you say, ${kuria}," a young helot snarls.  "We'll make sure they all know of ${xhis} treachery."
                 
          You give a curt nod.
          *if cha < 2
            A few of the other helots are looking askance at you, apparently unconvinced by your accusation.  You make note of their faces.
          Given ${xhis} charisma, Breden's
          *if elery = 0
            surviving
          friends will probably be slow to believe ${xhim} a traitor, but you'll do your best to ensure the rest of the group believes it.
          *goto father
        #"Let ${xhim} run. $!{xhe}'s not worth killing."
          *if cha = 0
            Many of the helots look askance at you.  You can imagine their thoughts: [i]If ${he} really believed Breden a traitor, would ${he} be so ready to let ${xhim} go?[/i]
            *set cred_h -5
            *set morale -5
            
          "$!{xhe} can do nothing more to harm us now," you explain.  "We need to stay close now, not run off on a rat hunt."
                 
          The helots nod, still looking a bit confused and uncertain.  Given ${xhis} charisma, Breden's
          *if elery = 0
            surviving
          friends will probably be slow to believe ${xhim} a traitor, but you'll do your best to ensure the rest of the group believes it.
          *goto father
                 
*label father    
*page_break
*set rollover4 sicem
*if helotrefuse
  *set rollover3 1
You fall back through the group until you find your father, 
*if aristo
  in the care of Old Joana and three of the other helots who worked your House's small orchards.  All five of them look profoundly uncomfortable.  While your father wasn't a violent master, he always took great pains to keep the family chattel in their rightful place, and you doubt any of them ever heard a kind word from him.  You take a moment to thank them respectfully for keeping him safe.
                 
  As you walk him away from the helots, your father seizes your elbow in a painful clench.  "What have you done?" he whispers.  You've never seen such a fearful, unfocused look in his eyes before today.  "Foolish child, what lunacy possessed you?  We've lost everything—everything."
                 
  *if breden = 1 
    "The helots chosen for Harrowing lose everything, Father," you reply coolly.  "We've lost relatively little by comparison."
  *if breden > 1 
    "We haven't been martyred for the cause yet, Father," you reply coolly.  "I'd say we've lost little, so far."
  
  His nails bite deeper into your arm.  "Don't give me that
  *if breden = 1 
    moralistic   
  prattle!  House ${lname} may not have had much, but you have thrown it all away forever.  You'll lead your little group of bandits in the forest until the Theurges finally catch you; then our name will be cut off and not even our shame will be remembered.  All because of your damned pride!  All because you thought you were stronger than the Hegemony."
                 
  You have always hated it when your father accuses you of disgracing the ${lname} name, and after letting him finish, your anger is raw and audible.  "It cannot last, Father!  By the Angels, don't you see that?
  *if ruthreal < 45
    The harvesting of helots.
  The corruption of the Alastors and Ecclesiasts.
  *if shayard > 0
    The oppression of
    *if shayard = 3
      the nobles of
    Shayard by outsiders.
  *if cosmop > 0 
    The isolation from other civilizations.
  *if relig > 0  
    All the lies in the name of Xthonos.
  It's all starting to crumble at last.  The Thaumatarch is a monster…"
  *fake_choice
    #"…and we will replace his tyranny with a new, just order."
      *gosub trial_end
      *if wealth > 0
        "Order?  I didn't see order on display just now.  I saw a mob running rampant, and my only heir spurring them on.  How do you expect order to grow out of such anarchy?"  You press your lips together angrily, unable to reply.
    #"…and we will tear his bloody Hegemony down, no matter what the cost."
      *gosub trial_end
  Your father shakes his head in scorn.  "Thank the Angels that your mother did not live to see her own child make her into a refugee and a rebel."
                 
  "Don't you dare mention Mother."  You round on your father, who stumbles to a dumbfounded halt.  Before this day, you would never have taken such a tone with him.  "Have you really managed to forget her already?  She didn't just care about honor and safety.  She knew that we could be strong
  *if breden = 1 
    without having to humiliate anyone else—not helots, not other Houses.  
  *if breden > 1 
    as any of the great Houses if we were true to ourselves.
  And you never wore her down, even when she fell sick.  Never broke her.  Don't you speak her name now."
                 
  Your father is the first to look away, and when he speaks again, his voice is thin and tremorous.  "Curse your own father.  Add disgrace to disgrace.  Why not?  I have sired a mad${woman}.  You rave about toppling the Hegemony, but all you have done is banish me from my home and condemn me to death, along with every helot here."
                 
  "No."  Heart pounding, you lean in close and find his eyes again.  "You're wrong.  We're going to win, Father.  We'll do things you never imagined possible."
  *finish        
*if helot        
  walking with some of his old t'Keriatou plow-mates.  "Well, you've done for us proper this time," he calls sourly as he sees you coming.
                 
  "Just wanted to make sure you were well, Father."  You give an apologetic look to his friends, who walk away, chuckling, to leave the two of you alone.
                 
  "For the moment, aye."  He waits until the rest are out of earshot; you wonder whether the tremor in his arms stems from fear or the yearning to thrash you bloody.  "And I'm sure I'll be well until the moment the Theurges scorch us all to ash.  What by Xthonos do you think you're playing at?  You may have saved a few foolish boys and girls from a Harrowing, but you've condemned every helot here to death."
                 
  "We're not going to die, Father."  You try to keep your voice calm and assured.  "We know these woods and hills better than any Theurge—we can stay out of their reach.  And now we've done what every helot in the world talks about doing.  As we spread the word, the others will start to join us."
                 
  Your father snorts with reverberant scorn.  "How did I raise such a mad${woman}?  Child, the helots of the Hegemony aren't going to rise up and join you.  Even the helots of Shayard aren't going to join you.  If they should hear about our little revolt, they'll tell stories about it to make them feel a little better—someone, somewhere is standing up to the Theurges.  But they won't take up their scythes and axes and come looking for us.  They won't trade the chance of being bled in a Harrowing for the certainty of being killed as rebels."
                 
  "Our neighbors and cousins here did," you insist.  "This is the chance to show how weak the Thaumatarchy really is.  We are strong enough…"
  *fake_choice   
    #"…to build a new, just order."
      *gosub trial_end
      *if wealth > 0
        "Order?  Is that what you call what happened just now?  'Cause to me, it looked a lot like a mob doing as it pleased." 
    #"…to tear the Hegemony down to rubble."
      *gosub trial_end
  Your father sighs raspily.  "Madness.  Thank the Angels that your mother isn't here to see her own child lead us all to our deaths."
                 
  "Don't bring Mother into this."  You keep your voice offhand.  "There was an apothecary in town when she fell ill.  His tinctures could have cured her, if you'd brought him."
                 
  "What?"  The old man halts, too shocked to cuff your ears for insolence.  "You…that apothecary was visiting to serve our Keriatou masters, you damned imp.  What do you think would have happened if I had knocked on the aristarchs' door and pleaded for their charity?"
                 
  "They probably would have had you beaten half to death for insolence.  Or…they might have had one of their fits of mercy and sent the herbalist."  You turn and lock eyes with your father.  "So did she die because helots can't afford an apothecary, or because you were too afraid to ask the aristarchs for one?  Either way, it's a damned shame."
                 
  The jagged silence hangs between you for a long time.  "Ten years you've been waiting to say that to me?"
                 
  "I've been waiting to say a lot of things.  Not just to you."  You stalk off toward the rest of the group.  "From now on I won't be holding them back."
  *finish        
                 
*label jail      
*if morale < 20  
  *set morale 20 
*page_break
*if pin > 0
  *set elery 0 
  *set poric 0
  *set pin 0
  *set yebben 0
  *set alless 0  
  *set el_here false
  *set literate 0
You return slowly to consciousness through a haze of pain.  As your eyes adjust to the near-darkness, you realize that you are sprawled on the floor of a windowless cell, small enough for you to touch all three stone walls.  The fourth side of the room is a stout wooden frame fixed with iron bars, facing a corridor of similar cells.
                 
*if aristo       
  You recognize the dungeon of House Keriatou.  Calea and Hector are sure to be nearby, gossiping about your 
  *if bred_yell != 1
    failed rebellion.
  *if bred_yell = 1
    imminent demise.
*if helot        
  This must be your masters' dungeon.  As the aristarchs of your district, House Keriatou share responsibility with the Alastors for dealing with any helot insubordination. 
Ecclesiast Zebed keeps a jail next to his shrine, but it has large windows to the outside street to display lawbreakers in their disgrace.  Clearly, Theurge Chirex has decided that your treason is sensitive enough that you need to be kept out of the public eye.  No mob of helots could rescue you from the Keriatou's formidable little keep.
                 
As you shift onto your shoulder, several of your broken ribs grind together and you choke back a wail.  From a neighboring cell, you hear Breden whisper, "${fname}—you're awake?"
*if bred_yell = 1
  $!{xhe} sounds more miserable and abashed than you've ever heard ${xhim}.

"$!{he}'s awake."  Your heart sinks at your father's haggard voice.
*if elery > 0    
  You weren't entirely surprised to find Breden locked up with you, but you had vainly hoped the Theurges wouldn't pursue your family.
*if aristo       
  "$!{he} hasn't shamed ${his} House enough yet.  $!{he}'ll live to see ${his} own father tortured to death for ${his} filthy, helot-loving treason."
*if helot        
  "$!{he}'s not only fool enough to insult a Theurge at a Harrowing, but fool enough to stay alive and conscious afterward.  We'll all be tortured to death in the morning, ${fname}—you happy?"

"I'm sorry, Father," you groan, close to tears.  "I never…I never wanted to involve you in any of this."
*fake_choice     
  #I can barely think for despair.
  #I'm vainly searching the cell for some way out.
  #I do my best to calmly accept my failure and my fate.
Your father cuts himself off in mid-sentence as the door of the corridor creaks open.
                 
A lone figure steps in.  In the murk, all you can see is that he's wearing a nobleman's cloak with a great, enveloping hood.  When he speaks, his aristocratic
*if aristo       
  Southriding    
lilt makes his words all the more astonishing.  "I've poisoned the dungeon guards.  Happily, neither of them called an alarum before they fainted.  I hope you're well enough to move quickly."
                 
"What?  Who are you?" Breden gasps.
                 
"If I tell you, ${xgirl}, and you're caught again, I'll find myself next to you on the Harrower."  The amused-sounding noble raises his hand with a clink of keys and unlocks your father's cell.  "So you'll have to accept your lives as an anonymous gift.  Keep your voices low, if you please."
                 
"Why are you helping us?" you ask, lurching painfully to your feet and leaning against the bars.
*if helot        
  "Why would someone like you possibly want to save a few condemned helots?"
*if aristo       
  You don't recognize the man's voice; he definitely doesn't sound like any of your Keriatou cousins.
                 
"You set a powerful example back there in the agora.  
*if shayard = 2  
  'Shayard will be free again'—we don't hear much of that these days.
*if shayard = 3  
  'The ancient liberties of the nobles of Shayard'—we don't hear much of them any more.
It's a rare thing for anyone, noble or helot, to have the courage to confront a Theurge."  You think you hear a smile in his voice.  "They'll want to make a proper spectacle of your corpses.  But I'd rather like more people to imitate you.
*if ruthless >= 2 
  Like that woman who destroyed the Harrower today—and died for it.  
So let's see if we can't keep you alive a little longer."  He unlocks the gate to your cell.
*fake_choice
  #It's too good to be true.  I hesitate, looking for the trap.
    After a moment, your benefactor sighs sharply and seizes you by the wrist. "Don't make me repent this risk.  We don't have enough time for your doubts."
  #I try to pull back his hood.
    Your injuries make you slow and clumsy, and the noble cuffs your hand away with ease.  His voice is icy.  "Idiot.  Any more of that, and I'll leave you dead for the Theurges."  You mumble something embarrassed and limp out of your cell.
  #I thank him humbly, whoever he is.
    He shrugs and bows slightly.  "Thank me by surviving.  From the look of you, that may be about all you can manage."
*comment endif

With every step, white flashes of agony burst across your field of vision.  But it's mainly from your battered ribs and back; nothing in your legs seems to be broken.  Breden
*if bred_heart < 10
  hurries over to support you.
*if bred_heart >= 10
  hesitates for a moment, then says, "Lean on me, damn you.  We won't get far if I let you alone."

"I've opened the postern," the hooded noble continues briskly.  "By my reckoning, it will be an hour before they discover you're gone.  They'll come after you with dogs at dawn, so you'd best get to the river and wade up into the hills, into the deep forest where they can't follow on horseback.  If you can make it to Whendward Pass, the outlaws there should take you in.  They'll have heard of this little drama."
                 
"And you?"       
                 
"Never mind me.  Go—now."
*set rescuer 1   
*achieve rescued 
*page_break
You take a break some two hours later on the moonlit riverbank, exhausted and soaked to your chests from your long struggle upstream.  Breden climbs away from the roar of the river to listen intently for a few minutes.  Then ${xhe} returns to the rocks where you've collapsed.  "I don't hear any hounds yet.  They probably will wait for dawn.  Let's rest a moment more and then take the next stream forking west.  That should get us into the hills above the Pass."
                 
Your father grunts and you nod.  After you've got your wind back, you look to Breden.  
*if bred_heart >= 10
  "So, ${xgirl}. Our noble rescuer is well and truly gone. At what point will you run off and leave us for the wolves?"
                 
  Breden crouches next to you, eyes glinting in the dim moonlight.  "I've been wondering that myself, ${kuria}. You've scorned me enough in the past.
  *if breden = 4 
    Even tried to bloody kill me.
  *if bred_yell = 1
    But my calling for your help back there in the square saved me from the Harrower and left you in bad shape.  So it could be said we're even.  Maybe even that I owe you a little."
                 
    "Maybe." You let the word stand, dry and cutting.  Finally you add, 
  *if bred_yell = 0
    But you tried to save
    *if elery > 0
      us,        
    *if elery < 1
      me,        
    back there in the square.  Little as I may like it, I owe you my life."
                 
    "A nice enough story."  You glare at ${xhim}.
  "Or is there another reason you're following us?"
                 
  Breden's face goes stony again.  "What's that supposed to mean, ${kuria}?"
  *goto zebedchix
*if bred_heart < 10
  "Lucky they didn't give you the same punishment I got.  Doesn't look like there's a bruise or a scratch on you."
                 
*if bred_yell = 1
  In the dim moonlight you can't see whether Breden's face has darkened, but ${xhis} lips tighten into a knot of shame.  "I'm sorry, ${fname}.  I shouldn't have…I thought you could save me.  I thought the people would listen to you if you told them to fight.  I was afraid."
*if bred_yell = 0
  "They didn't beat your father, either.  Did you have something you wanted to say?"  Breden sounds suddenly wary.
*label zebedchix 
                 
"Zebed and Chirex knew that you and
*if helotrefuse  
  your           
*if not(helotrefuse)
  our            
friends had been talking treason and blasphemy."  You search ${xhis} face with your eyes.  "How do you think they found out?"
                 
"Someone likely betrayed us."  A note of incredulity enters Breden's whisper.  "And you're wondering if it was me?"
                 
"I'm wondering what anyone would…." you reply, keeping your voice level.  With so many questions welling up furiously inside you, it's a struggle to pick one to ask first.
*label interrogn2
*if questions = 5
                 
  *goto traitorq2
*if (bred_heart >= 10) and (questions = 4)
                 
  *goto traitorq2
*choice          
  *if helotrefuse
    *hide_reuse #"Why weren't you at the meeting where the others were caught?"
      *goto overseerafter2
  *if not(helotrefuse)
    *hide_reuse #"Why weren't you up at the shack with the others?"
      *label overseerafter2
      "I had an overseer after me all morning, demanding one petty job after another," Breden replies at once.  "By the time I shook her off, the Alastors had started the Summons.  It was too late by then to get word to the others.  I just hoped they'd stay out there safe until the Harrowing was done."
      *set questions +1
      *goto interrogn2
  *if bred_heart < 10
    *hide_reuse #"Why wasn't I invited to the meeting?"
      *if helotrefuse
        "Because I still wasn't sure you wanted to be there, ${fname}," Breden sighs.  "And I didn't know if the others would welcome you back yet."
      *if not(helotrefuse) and helot
        "It wasn't a long-planned meeting," Breden says defensively.  "I only found out yesterday that Radmar would be willing to come, and so I thought we'd talk with him, hear the full story of what was happening with Poric.  But I wasn't able to get word to the Keriatou camp without raising suspicions."
      *if not(helotrefuse) and aristo
        "I can't invite you to all of them, ${kuria}," Breden says defensively.  "I only found out yesterday that Radmar was willing to come.  I thought we'd talk with him, hear the full story of what was happening with Poric.  But with so little time, I wasn't able to get to your House without raising suspicions."
      *set questions +1
      *goto interrogn2
  *hide_reuse #"How do you think the Hegemony knew where to find them?"
    "Either a traitor told them," Breden offers, "or else they'd managed to follow us somehow.  We were careful, but even so, it's possible someone slipped up.  So mayhap they found out, and had someone watching the route this morning."
    *set questions +1
    *goto interrogn2
  *if questions > 2
    *hide_reuse #"So who do you think could have betrayed you?"
      "I don't know,
      *if aristo 
        ${kuria} 
      ${fname}," Breden says levelly.  "It would be easy to point a finger at Radmar, because he also wasn't there this morning.  But I don't believe it was him.  He's honest."
                 
      "Not to be blunt, but wasn't everyone else
      *if elery = 0
        just Harrowed?"
      *if elery > 0
        hauled up for Harrowing?"

      "All those who came regularly, yes."  Breden
      *if elery > 0
        shrugs.  "But
      *if elery = 0
        turns away, face drawn with pain.  "And I nearly was too, you'll recall.  But
      there were people who came once or twice and decided not to come again.
      *if helotrefuse
        You weren't the only one.
      I trusted them; clearly I was wrong.  Even if they didn't betray us, they let word slip to someone else who did."
                 
      *if not(helotrefuse)
        $!{xhe}'s right; in your time with the group, at least three young helots came to a meeting or two, then slipped away.
      "Do you remember everyone you invited to a meeting?"
                 
      "I do," Breden confirmed grimly.  "And if we ever get the chance, I'll find out who did this."
      *set questions +1
      *goto interrogn2
  *hide_reuse #"Why didn't you try to stop the Harrowing?"
    *if pin < 0
      "Why didn't you?"  Breden stares at you in anguish.  Then ${xhe} shakes ${xhis} head and turns away.  "I broke, ${fname}.  When it mattered most…I didn't know what to do."
      *set questions +1
      *goto interrogn2
    *if bred_heart >= 10
      *set questions +1
      $!{xhis} face twists with contempt and hate. You recoil before realizing it's not directed at you. "I broke.  When it mattered most…I didn't know what to do."
      *choice    
        #"A coward as well as a scoundrel," I rasp scornfully.
          Breden turns a gaze of loathing toward you.  "You think you can say anything I won't be saying to myself for the rest of my days, ${fname}?"
          *goto interrogn2
        #"Action isn't as easy as talk, it seems."
          Breden looks you over with a sort of angry pity.  "No.  And as you showed us, action isn't all that easy, either."
          *goto interrogn2
        #"That's how it ends when a helot fancies ${xhim}self a leader."
          Breden laughs harshly.  "We've ended in the same place, ${kuria}.  I tried to lead; you tried to spark some kind of rebellion by your actions back there.  We both failed."
          *goto interrogn2
    *else        
      Breden's throat works in silence for a few moments before ${xhe} answers simply, "I was afraid."
                 
      When ${xhe} says nothing more, you find yourself wracked by both anger and profound disappointment.
      *fake_choice
        #I lash out bitterly.
          "Truly?" you demand. "That's all you have to offer?  Breden Reaper, ever-bold provoker of the authorities, organizer of sedition, inspirer of rebellion…silenced by fear at the last moment?"  Hit with the full force of disillusionment, you don't know whether you'd rather it were true or false.
                 
          $!{xhe} turns hurt eyes on you and speaks in a voice thick with self-contempt. "Breden Reaper, loud mouth, user of ${xhis} friends, rebel in ${xhis} own mind…who broke when it mattered most.  Who stood there stuck and self-saving, and left it to
          *if aristo
            a bloody aristo
            *if harrowpinion > 0
              who doesn't even know whether ${he} thinks Harrowing's a bad thing or not
          *if helot
            ${xhis}
            *if bred_lover >= 4
              lover
            *if bred_lover < 4
              friend
          to try to save us all."  $!{xhe} slumps back against a boulder.  "You think you can say anything I won't be saying to myself for the rest of my days, ${fname}?"
          *set questions +1
          *goto interrogn2
        #I shake your head and fall silent.
          Breden slumps back against a boulder.  "I broke," ${xhe} explains, voice thick with self-contempt.  "When they needed a leader 
          *if elery > 0
            you were there, and
          I couldn't move."
          *set questions +1
          *goto interrogn2
        #But the anger fades quickly in the face of ${xhis} obvious remorse.
          "We were all afraid," you say at last. "You never know how you're going to respond until the moment comes."
        
          "And now we know." $!{xhe} seems almost as hurt by your gentleness as ${xhe} would have been by your wrath.  "Now we all know what to expect from Breden Reaper when lives are at stake."
        
          "No.  No, I'd hope we don't."  But it's hard to put conviction into your voice, as you search ${xhis} face for the answer to an unspeakable question.
          *set questions +1
          *goto interrogn2
  *if bred_heart < 10
    #I just stare at ${xhim}, the doubts obvious in my eyes.
      *goto traitorq2
  *if bred_heart >= 10
    #I just stare at ${xhim}, the suspicion obvious in my eyes.
      *goto traitorq2
*label traitorq2

When you say nothing more, ${xhe} leans toward you, voice low and urgent.  "${fname}, 
*if (ruthless = 2)
  I would have been the next one picked for the machine.  After Shiri broke the Harrower, Zebed accused me straightaway of being behind her treachery—he didn't even pause, he already knew where in the crowd I was standing.  Your father saw it.
*if (ruthless != 2)
  Chirex picked me too!  I would have been fed to the Harrower if you hadn't saved my life.
They locked me up with you and they would have killed me with you.  You honestly think I'm a traitor?"
                 
*if (bred_yell = 1) and (int > 0)
  *page_break
  "They locked you up.  But would they have killed you?"  You reach out despite the pain and pull Breden close enough to see every twitch on ${xhis} face.  "You were the last one the Theurges were sending into the machine—and after you called to me, for some reason they decided not to Harrow us on the spot.  Was that really so they could torture more information out of us?  Or was it to save their traitor to send into another camp somewhere else?  Like some kind of helot Kryptast?"
                 
  "That's insane!"  Breden's wide, beautiful eyes stay fixed on yours; if ${xhis} horror and shock aren't genuine, ${xhe}'s a magnificent hypocrite.  "You can't really believe that."
                 
You pause for a moment, then answer ${xhim}.
*choice          
  *if bred_heart >= 10
    #"No.  You're a knave and a villain, but I don't believe you're a traitor."
      "Well, that's the main thing." Breden still looks shaken and angry.
                 
      "Indeed,"  
      *goto radmarappear
  *if bred_heart < 10
    #"No—I trust you.  Someone else must have betrayed us."
      "Of course someone else did."  Breden stares at you, still looking shaken.  "${fname}, we've got to trust each other if we're going to get through this."
                 
      "I said I trust you, 
      *if breden <= 2
        Breden," 
      *if breden > 2
        helot,"  
      you repeat wearily.  
      *if breden < 2
        "I'm sorry.  I'm too hurt and tired to be kind right now.  
      *if breden > 1
        "I may not particularly like it, and I'm in too much pain to sugar-dust my words.
      But we're in this together."
                 
      "Indeed we are,"
      *goto radmarappear
  #"I don't trust you, Breden.  But we've got to stick together for now."
    Breden's face hardens with anger.  "How far am I going to have to carry you to earn your trust back again, ${fname}?  How do you think we're going to get through this if we're constantly suspicious of each other?"
                 
    "I won't play any games with you,
    *if breden > 2
      helot.     
    *if breden <= 2
      Breden.    
    I'd like to believe you're not a traitor.  If we do find the outlaws and they take us in, you'll have the chance to prove it."  A terrible coughing fit wracks you, leaving you barely able to whisper.  "But I'll be watching you—and if I see any reason to suspect you of contacting the Theurges, I'll not keep it to myself.  I want you to know that.  Don't do anything suspicious.  Don't do anything foolish."
                 
    "Xthonos burn you," Breden says bitterly, clearly fighting to keep ${xhis} voice under control.  "You brainsick 
    *if aristo   
      dandy.  You're just like the rest—behind all your pretty words, you still believe that only nobles can be trusted.
    *if helot    
      clod-kicker.
    If I were a traitor, I'd go back now and set the dogs on you."
                 
    "If you were a traitor, you'd be dead now,"
    *set bred_trust +10
    *goto radmarappear
  #"Go away, Breden.  I don't care where."
    *if bred_heart > 10
      Breden's face is bleak.  "You can't be serious.  You think you'll live without me?"
      *goto wonttravel
    *set bred_heart +10
    Breden's face is still disbelieving.  "You don't mean that."
    *if bred_lover = 4
      $!{xhe} holds out one hand to you.  Something in the imploring curve of ${xhis} fingers sends your mind back to the moment when that hand first folded against your face.
    *label wonttravel
                 
    "I won't travel with someone I don't trust."  A terrible coughing fit wracks you, leaving you barely able to whisper.  "And I won't vouch for you to any other rebels you might betray.  If you're not a traitor, you're best making your own way."
                 
    "Xthonos damn you.  If the Alastors catch me, they'll gut me.  But now I can't go looking for the outlaws either, because you'll call me a traitor to them."  Breden looks around wildly, then turns back to you with a violent hatred in ${xhis} eyes you've never seen before.  "I could kill you here, you know.  One old man, and a young ${woman} almost too injured to walk?  I've wrung the necks of chickens that gave me more trouble than you two would."
                 
    Your father recoils, scrabbling for a rock.  Breden half-laughs, half-sobs, and starts clambering away.  Then ${xhe} pauses and calls back, "When the dogs don't find you, ${fname}?  When the bandits of Whendward Pass don't get attacked by Theurges?  That's when you'll know you sent away a friend, not a traitor."
                 
    "A friend, eh?"
    *set bred_trust +10
    *set breden +10
    *set bred_here false
    *goto radmarappear
                 
*label radmarappear
a voice booms from high above you.  A
*if not(helotrefuse)
  massive        
silhouette looms out of the brush at the top of the slope; then a
*if helotrefuse  
  big, familiar-looking man 
*if not(helotrefuse)
  familiar figure
slides down with a clatter of gravel.
*if breden >= 10  
  He casually tosses a rock the size of a melon into the river.

"Radmar?  How did you…" Breden looks stunned for a moment, then backs away while scanning the ridgeline warily.
                 
"Only me," rumbles the big helot.  Even in the dark, you can see that he's caked in mud from head to toe; only his wide, wild eyes reflect the moon.  "I'm not the one who sold us out, Reaper."
                 
Astonished, you wheeze,
*temp radtick 0  
*label radchoice 
*choice          
  *if radtick < 10
    #"Why weren't you at the Harrowing, then?"
      "I don't like your bloody tone,
      *if aristo 
        ${kuria},"
      *if helot  
        ${fname},"
      Radmar snarls.  "And you don't look in any shape to be making more enemies.  So shut up."
                 
      Breden     
      *if bred_trust < 10
        holds up ${xhis} hands as if to make peace,
      *if bred_trust >= 10
        laughs,  
      then recoils in disbelief at the big helot's savage glare.
      *goto radvbred2
  *if radtick < 10
    #"How did you escape the Harrowing?"
      *set r_rel +1
      "I was headed up to the shack for the meeting Breden called.  But I left the camp late—so I was still fifty yards out when the Theurge and the Alastors marched down out of the woods ahead of me."  Radmar brushes a hand angrily across his cheeks, leaving the mud smeared.  "There were too many to fight.  I hid,
      *if aristo 
        ${kuria}.
      *if helot  
        ${fname}.
      Sank myself as deep in the de Rose marsh as I could go and still breathe."
                 
      "You hadn't heard the Summons to the Harrowing?"
                 
      "You think I'd have been up there if I had?"  Radmar spreads his hands. "Course I hadn't.  None of us had.  None of us who were out there, anyhow."
      *set radtick +10
      *if radtick = 11
        *page_break
        "So who do you think betrayed us?" you ask.
                 
        *goto radvbred
      *goto radchoice
  *hide_reuse #"How did you find us?"
    "I heard you'd been taken to the Keriatou dungeon. So I was looking for a way in.  With everyone else Harrowed, seemed all I had left was to break you out or die trying."  Radmar's eyes shift between the three of you as he speaks, his face grim and uncertain.  "Gave me no end of a shock when you walked out.  I didn't know what to think.  But you were moving like you truly feared being caught again, so I thought I'd follow you and hear more."
                 
    "Someone poisoned the postern guards and freed us," you explain quickly,  "some masked noble—no one whose voice I'd ever heard before."
    *if aristo   
                 
      It occurs to you for the first time what your escape is going to mean for Calea and Hector.  They're sure to fall under suspicion of rescuing their cousin—however implausible such an event might be in reality.  In the likely event that there's already a Kryptast on the Keriatou estate, they might well die before the week is out.

    "Heard you talking of him."  Radmar shakes his head.  "Damned lucky, all of us.  Unlikely lucky."
    *set radtick +1
    *if radtick = 11
      *page_break
      "So who do you think betrayed us?" you ask.
                 
      *goto radvbred
    *goto radchoice
  *if radtick > 9
    #"So who do you think betrayed us to Chirex?"
      *label radvbred
      Radmar looks silently at Breden, who recoils, shaking ${xhis} head.  
      *label radvbred2
      "Damn it, Rad!
      *if bred_trust > 10
        Tell me you don't believe this
        *if aristo
          lordling."
        *if helot
          ass."  
      *if bred_trust <= 10
        Didn't you hear enough of ${him} interrogating me?  $!{he}'s satisfied—and you're not?"

      "If I thought you were a traitor, I'd have put a stone through your skull before you knew I was here."  Radmar's lip curls.  "You're worse than a traitor, Breden.  You're a fool."  
                 
      Breden flinches but stands ${xhis} ground.  "That…that much I can't deny."
                 
      "[i]Trust me[/i], you said.  [i]They won't know.  They aren't watching.[/i]  Now they're dead who trusted you, damn it!  All but me."
                 
      "I didn't…how was I to…"
                 
      "No!" roars Radmar. "No more words from you.
      *if helotrefuse
        I'd sooner hear from this
        *if aristo
          *if breden > 1
            pompous,
          failed aristo
        *if helot
          broken plow-pusher
        who at least had the sense not to trust your schemes.
      *if breden >= 10
        Get out of here before I drown you like the cowardly rat you are."  
                 
        Without another word, Breden flees up the slope. Radmar turns to you with a glower. "Good riddance.
      *if not(helotrefuse)
        And no more from you either,
        *if aristo
          ${kuria}.
        *if helot
          ${fname}.
        I don't know how the Alastors found out where we were, but I know the two who put us there in the first place." He spits into the river and storms away.
        *set r_rel -2
        *if breden >= 10
          Like it or not, you know he'll be back; there's only one way of escape for any of you now.
          *goto fatherdrama

        Breden starts after him, then falters, ${xhis} whole body trembling. "He'll be back," ${xhe} says hollowly. "Where else does he have to go, now?"  After a long silence, ${xhe} mutters, "I'll…listen for the dogs again," and clambers back up the slope, not stopping until ${xhe}'s a small shadow against the stars.
        *goto fatherdrama
      *if breden < 10
        I may have to live with you, Breden, but I don't have to listen to you.  Never again."
                 
        Breden sways in place for a moment, then turns on ${xhis} heel and clambers back up the slope.  You hear a throaty sob as ${xhe} nears the top.
                 
        "The cowardly little rat will be back, more's the pity." Radmar's voice remains low and hateful.  "Where else does ${xhe} have to go?
      Now take your rest,
      *if aristo 
        ${kuria}.
      *if helot  
        ${fname}.
      I have to wash off this filth."  He splashes off into the river.
      *goto fatherdrama
                 
*label fatherdrama
*page_break
*if aristo       
  Your father's eyes follow Breden, his mouth twisted in distaste.  "Dishonorable, treacherous lump.  You threw in your lot with one such as ${xhim}?  What lunacy possessed you?  Now we've lost everything."
                 
  *if bred_heart >= 10
    "Threw in my lot?"  You give as vehement a shake of your head as your body can manage. "$!{sweetoath}, Father, I'd done my best to drive ${xhim} away."
    
    "Your best?" His incredulous tone brings an embarrassed heat to your cheeks. "Xthonos, ${girl}, ${xhe}'s a helot.  However you managed to get drawn into ${xhis} treachery, I can't believe ${xhe} somehow did it to you against your will."
    
    Perhaps if your skull weren't throbbing so hard, you could have kept up the argument.  "In any case, we've not yet lost everything.  Where there's breath, there's hope."
  *if bred_heart < 10
    "We're still alive," you reply bleakly.
  
  "Ha!  Even if these hill bandits we're seeking don't kill us, the Alastors will catch us sooner or later.  The name of House ${lname} will be cut off and not even our shame will be remembered."  A frantic note has entered your father's voice.  "And all because of your damned pride!  All because you've always thought you were wiser than the Theurges and stronger than the Hegemony."
                 
  You have always hated it when your father accuses you of disgracing the ${lname} name, and after letting him finish, your anger is raw and audible.  "It cannot last, Father!  By the Angels, don't you see that?
  *if ruthreal < 45
    The harvesting of helots.  
  The corruption of the Alastors and Ecclesiasts.
  *if shayard > 0
    The oppression of Shayard by outsiders.
  *if cosmop > 0 
    The isolation from other civilizations.
  *if relig > 0  
    All the lies in the name of Xthonos.
  It's going to crumble.  The Thaumatarch is a monster…"
  *fake_choice   
    #"…and we have to find a way to replace his tyranny with a new, just order."
    #"…and we have to tear his bloody Hegemony down, no matter what the cost."
  *gosub trial_end
  Your father shakes his head in scorn.  "Damned nonsense.  Thank the Angels that your mother did not live to see her own child make us into refugees and rebels."
                 
  "Don't you dare mention Mother."  Your words burst out forcefully despite the pain in your chest, and your father backs away in surprise.  Before this day, you would never have taken such a tone with him.  "Have you really managed to forget her already?  She didn't just care about honor and safety.  She knew that we could be strong 
  *if breden = 1 
    without having to humiliate anyone else—not helots, not other Houses.  
  *if breden > 1 
    as any of the great Houses if we were true to ourselves.
  And you never wore her down, even when she fell sick.  Never broke her.  Don't you speak her name now."
                 
  Your father is the first to look away, and when he speaks again, his voice is thin and tremorous.  "Curse your own father.  Add disgrace to disgrace.  Why not?  I have sired a mad${woman}.  You rave about toppling the Hegemony, but all you have done is condemn us all to death."
                 
  "No."  You stretch out an arm to him, silently imploring his help as you try to regain your feet.  "You're wrong.  We're going to find the outlaws and we're going to win, Father.  We'll do things you never imagined possible."
  *finish        
*else     
  Your father's eyes follow Breden, his mouth curved in a scowl.  "I'd trust ${xhim} as far as I could toss ${xhim}.  What by Taratur have you been playing at, you ninny?  Trying to start some kind of rebellion?"
                 
  "If we reach the outlaws, it still might happen."  It sounds feeble even to your own ears.
  *if ruthless >= 2
    "Back in the agora, they broke the Harrower today.  That story will spread."

  Your father snorts with reverberant scorn.  "How did I raise such a mad${woman}?  Child, the helots of the Hegemony aren't going to rise up and join you.  Even the helots of Shayard aren't going to join you, whatever that noble may have thought when he freed us.  If they hear about our little escape, they might feel a little better—someone, somewhere is standing up to the Theurges.  But they won't take up their scythes and axes and come looking for us.  Only an idiot would trade the chance of being bled in a Harrowing for the certainty of being killed as rebels."
                 
  You try to shrug off his contempt.  "Sooner or later the rebellion will come, Father.  The Thaumatarch is a monster…"
  *fake_choice   
    #"…and we have to find a way to replace his tyranny with a new, just order."
    #"…and we have to tear his bloody Hegemony down, no matter what the cost."
  *gosub trial_end
  Your father sighs raspily.  "Madness.  Thank the Angels that your mother isn't here to see her own child lead us all to our deaths."
                 
  "Don't bring Mother into this."  Your words burst out forcefully despite the flare of pain in your chest.  "There was an apothecary in town when she fell ill.  His tinctures could have cured her, if you'd brought him."
                 
  "What?"  The old man's mouth flaps wordlessly as your unexpected accusation sinks in.  "You…that apothecary was visiting to serve our Keriatou masters, you damned imp.  What do you think would have happened if I had knocked on the aristarchs' door and pleaded for their charity?"
                 
  "They probably would have had you beaten half to death for insolence.  Or…they might have had one of their fits of mercy and sent the herbalist."  You lock eyes with your father.  "So did she die because helots can't afford an apothecary, or because you were too afraid to ask the aristarchs for one?  Either way, it's a damned shame."
                 
  The jagged silence hangs between you for a long time.  "Ten years you've been waiting to say that to me?"
                 
  "I've been waiting to say a lot of things.  Not just to you."  You stretch out an arm to him, silently imploring his help as you try to regain your feet.  "From now on I won't be holding them back."
  *finish        
                 
*label bred2speech
You think we need convincing that the Thaumatarchy is the real problem?  Sit and listen to my friends for an hour—and you'll see they don't need to learn it.  They already know it.  They know it's not the nobles who Harrow us, or preach that compassion and slaughter come down to the same thing."  $!{xhis} eyes sought yours imploringly.  "I lied when we spoke in the bridge grove.  We don't need you, ${milady}—not to teach us who our enemy is.  But I want you at our side.  A noble with the rage and the passion and the bravery to speak out.  Because you're right—the Karagonds have set us all at each other's throats.  And unless 
*if natlreal > 55
  all good Shayardenes
  *goto inso_shock
*elseif natlreal < 45
  all folk in all four conties
  *goto inso_shock
*elseif skepreal < 45
  all faithful followers of the Angels
  *goto inso_shock
*elseif skepreal > 55
  all folk clear-eyed enough to challenge their lies
  *goto inso_shock
*else            
  all folk of goodwill
  *goto inso_shock
*label inso_shock
come together to oppose them, nothing will change."

*return

*label namecap
*temp let1 lname#1
*temp let2 ""
*if length(lname) > 1
  *set let2 lname#2
*if (let1 != "d") and (let2 != "e")
  *set lname "$!{lname}"
*set fname "$!{fname}"
*set orig_lname lname
*return

*label from_childhood
From childhood you'd always been told that Theurgy was a special gift of the Blessed Angels to a devout few.  The Ecclesiasts darkly insisted that non-Theurges could only use magic through trafficking with Xaos-powers from the Void of Taratur.  

The mysterious scroll had no reference to invoking either Angels or Xaos: nothing religious at all.  But when you picked it up and avidly reread it, lines that had seemed mere nonsense now felt heavy with meaning just beyond your ken.
*if skepreal <= 50
  Could this be how the Blessed Angels grant you Their power—this brief philosophical litany?
*if skepreal > 50
  Could this brief philosophical litany really unlock the power of Theurgy?
  
You've never had access to the rarefied "aetherial" blood that Theurges use to fuel their magic, of course.  But the ancient texts suggested that one could accomplish similar effects by spilling large amounts of one's own living blood….
*return

*label helcha
*set cha 2
You have an instinct for moving and inspiring people; all your life, people have tended to like you and take you seriously.  Since becoming aware of your natural gifts, you've begun consciously to practice the way you talk, seeing how different audiences respond to different words and tones.  You now find that you can reliably sway small groups of people behind your opinion.
*return

*label helcom
*set com 2
Like most helots, you've played scrum-ball, where two opposing mobs use friendly violence to deliver a ball to the far side of a field.  The side that takes your tactical advice always triumphs.  You're also a good hand with a staff, which many helots practice in secret for self-defense.
*return

*label helint
*set int 2
You are one in a thousand: a helot who can read.  
*if not(introrel)
  A friendly old Diakon-priest 
*if introrel
  Hiera Olynna
taught you your alphabeta as a ${girl} so you could read a simple prayer-book.  That was your passage to the cosmos of the written page: the sacred texts and legal doctrines based on them, the histories of the Hegemony and geographies of the known world, systems and games of logic, the records of trade, even some hints and fragments on the mysteries of Theurgy.  
  
You've cautiously learned over the years which Diakons and local tradesmen will lend you a scroll or codex, and which react to your reading with scorn or a disgusted growl of, "Must not be working them hard enough, if they've time to learn their letters!"  You kept your reading entirely hidden from your noble masters, fearing that their disapproval would see you Harrowed. The only one who ever caught you with a scroll was young Ganelon Tarakatou.

Two years ago, the handsome aristocrat had walked past a hayrick where you were immersed in a history of Shayard. Ganelon stared at you for a long moment of mutual shock, then asked indulgently what you made of it.
*fake_choice
  #I couldn't speak—my throat was choked shut with fear.
    Ganelon's smirk faded when you finally overcame your terror and squeaked out a thoughtful answer. 
  #I muttered something about not making head nor tail of it.
    Ganelon wasn't fooled, and persisted until you finally gave him a serious answer.
  #I replied that it would be a better telling if it didn't skim over the great deeds of the Westriding families, as if the Southriding Houses had built Shayard single-handed.
    Ganelon shut his mouth and blinked at you…then began interrogating you with avid curiosity.
You had the feeling that few other nobles in Rim Square shared his passion for books. Once you overcame your own lingering natural wariness, the two of you enjoyed a peculiar, tentative hour's affinity.  Ever since, from time to time, he's found you and passed you some small book he's tired of.

Of course, you avidly seek out learning from non-written sources as well: especially the roving minstrels, caravan merchants, and artisans whose trade takes them to the other cities of the Hegemony.  Your natural gifts of memory and reasoning have served you well in starting to figure out the workings of the world beyond the Shayard Rim.

You currently keep three scrolls and a single codex—an extraordinary library, by helot standards—and
*return

*label groundswell
A groundswell of anger dissolved your fear, surging up from the same place Breden had reached with ${xhis} questions at the crossroads. $!{xhe} just stared at you searchingly. "You'd truly turn rebel, ${kuria}? Throw in your lot with a pack of helots?"

"What else have we been building up to?" You felt as if fire were rushing through your veins.  
*return

*label trial_end
*check_purchase adfree
*if choice_purchased_adfree or not(choice_purchase_supported)
  *label purchased
  *return
Remember earlier how we told you that the first chapter is available for free? This is the end of the free content.

*if choice_prerelease and choice_is_web
  *subscribe {"allowContinue": false}

[i]To find out what happens next, please purchase the remaining chapters.[/i]

*purchase_discount adfree 2024-08-29 $6.99 $4.99 purchased
*abort