*save_checkpoint ch_1
*temp dont_want_to false
	*comment say didn't want to die
*temp killed_soldier false
	*comment how you deal with the first choice
*temp chose_strength 1
	*comment picked skill, 1 = prowess, 2 = contortion, 3 = brilliance, 4 = influence
*temp what_nightmare 1
	*comment 1 = didn't hear it, 2 = partial, 3 = full phrase
*temp already_asked false
	*comment Alek already asked who you are
*temp already_spoke false
	*comment you've already talked as a ghost
*temp alek_tired false
	*comment Alek had to get rid of the ghosts

*text_image chap_1.png center Chapter One: Death of the Hero

Two Vatraian soldiers charge straight at you, their blades held aloft. An archer atop the gate picks off one, and he falls into the muck that surrounds you. His companion doesn't so much as look back. You recognize the look of grim determination in her eyes, the refusal to admit any distractions. If Vatrai can claim the Baron's Gate, they'll have won the day, and they grow closer with every push. She knows how near she is to victory. But she still has to face you.

Her running strike at your neck is obvious, and you parry it without a thought, but you miss the dagger she pulls at first. She aims for your bad side—it's obvious which it is—and your attempt to twist away is sluggish, under the circumstances. She catches you somewhere around your wrist. It's deep, you think. You can't feel the pain, but you feel the fresh blood flowing over the dried. It doesn't matter. It's not your sword arm.

If your muted reaction startles her, it's only for a moment, and she parries your answering blow with ease. She's much lighter on her feet than you are—right now, at least—and for the span of a few heavy breaths, she dances easily around your sword. Finally, you slash her along the arm, but it's a narrow cut, and she takes the opportunity to lunge with the dagger again. Normally, you'd never let someone pull the same trick twice. This time, she buries the blade in your gut and drags it across. There's quite a lot more blood at your feet now.

You don't falter. You don't flinch. You stand.

It's now that she begins to look afraid.
*fake_choice
	#No point in drawing this out. I put my own blade through her chest.
		*set prowess %+20
		*set killed_soldier true
		It's a matter of moments with her speed and bravado gone. She's so occupied staring at her own handiwork in your stomach that you're not sure she even sees it coming. You cut through to her heart, and she falls with a gasping breath to join her friend with the arrow in his neck, and all the other bodies at your feet.
		
		Once she's down, you pull the dagger free from your gut and drop it to the ground. You'd normally take
	#May as well add some finesse. I pull her dagger from my stomach and use it to cut her throat.
		*set contortion %+20
		*set killed_soldier true
		Your limbs are heavy, but you can manage this much at least. You sheathe your sword—an experimental twitch of the fingers tells you your off-hand is in no shape to grip anything—and retrieve the dagger. The soldier is still so thrown that she doesn't seem to notice what you've done until the blade is almost at her throat. "What—" she gasps, and then you slash through her neck and she falls, choking, to join her friend with the arrow in his neck and all the other bodies at your feet.
		
		You let the dagger drop to the ground. You'd normally have taken
	#I look her dead in the eyes and order her to go tell her king the gate is defended.
		*set dread %+20
		It takes some time to meet her eyes, because she's still very distracted by her own handiwork and your lack of reaction. When she finally does look up, she seems overwhelmed all over again by the coldness of your gaze. "What did they [i]do[/i] to you?" she gasps.
		
		You swallow experimentally. It's been some time since you last spoke, but your throat and your lungs are still unimpeded, so there's no reason it should be impossible. "Never mind that," you say, and are pleased to find your voice is steady.
		
		Her eyes flit back down to your gut. "But I don't think even Master Anker could have—"
		
		"She couldn't," you say, "but I said never mind. You know who I am. You know what I'll do to you if you stay. But if you turn around and run back to Kennet and tell him this gate isn't falling today, then I'll let you go."
		
		"I—" She cuts herself off this time, swallowing hard. She takes a look around the pass, no doubt noticing more and more of her comrades falling at the hands of yours. Then, slowly, she starts stepping backward, before she turns and breaks into a full run.
		
		Once she's gone, you pull the dagger free from your gut and let it drop to the ground. You'd normally take
	#I ask her if she can hear death in the air. It's all around us right now.
		*set communion %+20
		You don't think it's just the blood loss, the dizziness. You've always been able to hear it, a little, on the battlefield. Not the sounds that people make while they're dying, but something more. You couldn't say how you identify it as death. What it sounds like, more than anything, is the noise of the sea when you put a shell to your ear.
		
		"They say Jarda is haunted, you know," you add when you've finished explaining this to the soldier, in a meandering kind of way. "No one sees ghosts anymore, but maybe we can hear them. Maybe they're still in the air. Or the water. It sounds more like the water."
		
		The soldier is still gaping in bewilderment at her handiwork in your gut. "What did they [i]do[/i] to you?" she gasps. "I don't think even Master Anker could have—"
		
		"She couldn't have," you agree, "but never mind about her. I was wondering if you could hear it, too? Death? It's everywhere today, you know. Or maybe it is the blood loss. I have lost a lot of it. Well, not lost, I know where it is." You motion vaguely from the lower half of your body down to your feet.
		
		She follows your gesture, then lifts wide eyes to yours. "You're dead, aren't you?" she whispers. "Died and kept going for Galdrin. The way they always said you would. I—This can't—" She breaks, turning to flee from you, out of the pass.
		
		She's wrong, but she's near enough to the truth that it hardly matters. You pull the dagger free from your gut and let it drop to the ground. You'd normally take
a great deal more care in removing a weapon from a wound, but it's a pointless thing to worry about, under the circumstances.

You already know you're going to die today.
*page_break
By all rights, you should no longer even be conscious. The wizards departed some time ago to attend to Queen Ragna, whose safety is paramount, while you, sworn sword to the crown of Galdrin, were left to guard the only way into the city. They're too far away to offer any magical healing now. But before they went, they cast a spell on you, one so complex it required half a dozen of Galdrin's best wizards working together. A spell to dull nearly any pain, and to keep muscles and organs functioning long past the point where they should.

It doesn't heal. You took at least two wounds that could have killed you before the latest to your gut, nasty gashes to the blood vessels in your shoulder and thigh that there hasn't been time to bandage properly. They're still bleeding now, and when enough of your blood runs out, you'll be dead. What the spell will do is keep you standing until then. It's the only reason you're standing now.

Well, that and one other thing.
*fake_choice
	#We'll need a clever plan if anyone else is getting out of this alive. That can only come from me.
		*set brilliance %+20
		*set boastful %+10
		*gosub war_backstory
		
		You've been renowned for your cleverness since you were little more than a child, when you first rose to prominence in the eyes of your nation. It was your tactical thinking that allowed the queen to flee this far in the first place. Now that you've been backed into a corner, the strategies available to you are dwindling. But if anyone is going to come up with a trick to keep Vatrai at bay until the duke's forces arrive, it's going to be you.
	#I'm sworn to Queen Ragna. I will fight for her as long as there's breath in my body.
		*set prowess %+20
		*set dutiful %+10
		*gosub war_backstory
		
		You've wielded your sword for the royal family of Galdrin since you were little more than a child, when you first rose to prominence in the eyes of your nation. You fought for the queen in the capital, and you fought all along the road to Helma, and you're still fighting now. Whenever the duke arrives, whether or not the duke arrives, you'll only stop fighting when you're dead.
	#Everyone looks to me as a leader. Letting on how injured I am would frighten them.
		*set influence %+20
		*set gentle %+10
		*gosub war_backstory
		
		Even when you were little more than a child, first rising to prominence in the eyes of your nation, the people around you have looked to you for guidance. If you falter now, so will they. That you're wounded is obvious, but you can keep your fellow soldiers from realizing just how bad it is. Keep pretending that most of this blood isn't yours, at least until the duke arrives.
	#I didn't want to die today. Before I do, I'm taking down as many of my enemies as I can.
		*set dread %+20
		*set gentle %-10
		*set dont_want_to true
		*gosub war_backstory
		
		You've been terrifying Galdrin's opponents since you were little more than a child, when you first rose to prominence in the eyes of your nation. And there's nothing more infuriating than the assumption that because people have named you a hero, you'd resign yourself to a noble death. The duke may arrive before you fall, but a skilled enough wizard to heal you almost certainly won't. The only avenue left to express your frustration is the soldiers who keep charging your way.

Your head throbs, and darkness bleeds at the edges of your vision. You still don't feel any pain, not really, but faintness and fatigue weigh more and more heavily upon you. Even if any of the wizards were still here, you doubt there's anything more they could do for you now. There's only so far magical healing can go.
*fake_choice
	#I'm prepared to die in Galdrin's service. I always have been.
		*set dutiful %+10
		@{(dont_want_to) Happy about it, no. But you'd never turn your back to your duty.|You accepted this risk long ago. The life you've led has always been worth it.}
	#This isn't fair. Years of loyalty, and they've abandoned me to die.
		*set dutiful %-10
		You were so young when you entered Galdrin's service. You hardly had a choice. You never faltered, you built your own legend and theirs. And they're still going to let you die.
	#I've come close to death a thousand times. It's very familiar now.
		*set spirited %-10
		You've been making peace with death for years. Perhaps it's not accurate to say you welcome it. But you know you can't turn it away.
	#I'm holding out hope of rescue. It's not impossible.
		*set spirited %+10
		It's very unlikely. But if you were the pessimistic sort, you have to think you'd have given up already. Probably years ago.
	#I've never been so brave as everyone thinks I am. I'm just tired. I want to rest.
		*set boastful %-10
		It's always been a mystery how you ended up here. You never felt equal to the challenges everyone set before you. How could you have ever been equal to something like this?

There's a rumbling of the ground beneath you. For a moment you fear magical assault, but then rocks and earth tumble from the sides of the pass around you, blocking off the path for Vatrai's forces and leaving your soldiers untouched.

There's a collective sigh of relief from the warriors around you. The queen must still be safe.

The monarchs of Galdrin and Vatrai bear gifts from the dragons. Bright red gems called the Eyes of the Serpent, implanted in their very bodies. It grants them a connection to the earth, power over each of their halves of the island of Jarda. Queen Ragna of Galdrin can shape the land itself, as can King Kennet of Vatrai. That the queen has found a moment to tap into her connection and help you means that the wizards must have found a safe place for her. It still isn't going to save you, but it will give you a moment to breathe.

The downside to the Eye of the Serpent is that if a monarch is killed while wearing one, that connection to the land rebounds upon itself. The earth itself experiences the death of the monarch. What sort of catastrophes that would entail, you've never known for certain, but it ought to be enough for the other side to win the war. That's why the king and queen are such prominent targets. If Queen Ragna falls, so does Galdrin.

That's the impression the dragons gave you, anyway. They've never been very specific.
*page_break
The queen's intervention likely won't keep the Vatraians at bay forever, particularly not if they put their own wizards to work on it, but it's enough to grant you some respite. You give your soldiers the order to fall back, closer to the Baron's Gate. It's an old gate, and an old name. The Holm family were the barons of Helma, once upon a time. Now they're the monarchs of all of Galdrin, Queen Ragna Holm at their head, and they rule from Istta on the coast.

Old as the Baron's Gate is, it's sturdy enough for you to lean against, which is all you really want right now.

Around you, Galdrin's forces shift and mutter uncomfortably. You've fought alongside some of them for years. Other faces are new to you. But all of them know who you are. A few of them are young enough to have grown up on legends of you. They know you climbed Mount Breakwater, outwitted the dragon Mist, led the charge at the Hill of Souls, rescued Prince Otto. And they know you're dying now.

They're probably expecting you to say something.
*fake_choice
	#"Keep your heads up! We haven't lost yet."
		*set spirited %+10
		You see shoulders start to straighten, and hear quiet breaths exhaled, before
	#"I hope you're all ready to die."
		*set spirited %-10
		You see shoulders start to stiffen, and hear quiet gasps, before
	#"Don't be afraid. The queen's looking out for us. It'll all be all right."
		*set gentle %+10
		You see a few tentative smiles spreading through the group before
	#"Don't just stand there. There must be something for you lot to do."
		*set gentle %-10
		You hear sharp intakes of breath and scrambling footsteps before
	#They can keep expecting it. I don't owe them anything. I'm the one dying here.
		*set dutiful %-10
		Your eyes start to flutter shut, and you can't remember if it's a decision you made or not. But they fly back open once
a rumbling starts up in the pass again.

It's coming from the wall of rocks and mud before you, and for a moment, you dare to hope that Queen Ragna is shoring up your fortifications further. But then the wall starts to shudder, and with a sound almost like breaking glass, it shatters in an instant. "Shatters" isn't quite the word, you realize—the whole thing has disintegrated, turned to nothing more than particles of dust in the air. It's a work of incredible wizardry to dispose of the queen's handiwork in an instant, and you know before the dust clears what you're about to see.

Strolling out of that dust is a pale, lean figure in a robe of Vatraian blue, hair streaming out behind her in red-gold waves. She walks unhurriedly forward, somehow entirely untouched by the cloud of debris. That archer atop the gate seizes their moment and launches an arrow. A foot from the woman's face, the arrow stops in midair and rapidly reverses direction. You hear the archer fall with a scream. The red-haired woman doesn't look at the archer, or the arrow, or even at the gate. Her eyes, blue as her robes, are fixed, as ever, on you.

"My word, what [i]have[/i] they done to you?" says Cecilia Anker in an infuriatingly familiar drawl. "@{(killed_soldier) I was certain the rumors were exaggerated.|When that girl came running up babbling, I thought you'd driven her mad.}"
*page_break
Twenty years ago, you answered the dragons' call. So did Cecilia. You triumphed over every challenge they set you and won your country an Eye of the Serpent for your troubles. So did Cecilia. When one Eye proved insufficient for your masters and the wars began, you were named as your crown's foremost champion, and so was Cecilia. She's your equal and opposite. Vatrai's court wizard and Galdrin's sworn sword. Every legend about you has an answering one in Cecilia. In taverns across Jarda, people place bets on which one of you will finally kill the other.

Half of those bets are probably about to pay out today.
*fake_choice
	#I loathe this woman more than I have ever loathed anyone in my life.
		*set rel_ceci 30
		*set ceci_past 1
	#She's a worthy opponent. She's always had my respect.
		*set rel_ceci 40
		*set ceci_past 2
	#In another life, we'd probably be friends. Perhaps we're friends now, in a way.
		*set rel_ceci 50
		*set ceci_past 3
	#We're closer than anyone realizes. A rivalry like this can be intoxicating. Arousing, even.
		*set rel_ceci 60
		*set ceci_past 4
		*set interest_ceci true

"I'm sure your anatomists were very pleased with themselves, but this isn't even impressive work," Cecilia @{(ceci_past) says, smirking as she studies you|says, looking you over with a clinical eye|says, sounding just faintly troubled as she looks you over|says. Her voice is as steadily superior as ever, but she can't quite look at you for more than a moment at a time}. "I mean, all they've really done is kept a few parts of you from working, so that your body won't notice all the other parts that have stopped working. They haven't done anything to help you. It's crude, really. And what's the point of it? Is it supposed to inspire the masses, seeing you keep standing in spite of it all? Having to look at the mess they've made of you doesn't seem especially heartening to me." She turns from you, toward the rest of the soldiers gathered around you. "Is this inspirational, does this inspire you? This…pile of meat? With a face?"

As has frequently been the case in your encounters with Cecilia, your comrades in arms have gone still and silent, too terrified of her reputation to go after her. Though on further inspection, in at least a few cases, it's less that they're petrified in fear and more that the mud they're standing in has abruptly turned to stone, locking their feet in place. You have to look down to realize the same thing has happened to you—sensation is so dulled to you right now that you didn't feel it happening. Cecilia hasn't even broken a sweat.
*fake_choice
	#"Take one step closer, and I'll show you exactly why they made sure to keep me fighting."
		*set gentle %-10
		@{(ceci_past) Cecilia rolls her eyes. "Perhaps they just wanted to keep you speaking, to annoy me," she murmurs.|Cecilia smiles. "Do you know, I expect you probably will."|"I'd rather you didn't," Cecilia says, raising her eyebrows. "I think you ought to go out with more dignity than that."|Cecilia smirks, though something in her eyes is desperate, a little wild. "You [i]are[/i] still in there," she murmurs.}
	#"Whatever they've done to me, it's more impressive than anything you could have done."
		*set boastful %+10
		Cecilia rolls her eyes. "In this field, certainly. I'm not an anatomist. It's not my specialty. But just putting a great deal of power into something doesn't make it impressive. @{(ceci_past) Hardly surprising that you'd think otherwise.|I hoped you knew better than that.|I know you know better than that.|It's tiresome when you pretend it does. I'm sure I've told you that.}"
	#"I'm sworn to protect Galdrin until my last breath. That's what this is for. And you'd do the same."
		*set dutiful %+10
		@{(ceci_past) Cecilia laughs. "I think Vatrai is better served by not having me cut to ribbons. In your case, though, yes, perhaps your crown ought to thank you for this."|Cecilia's gaze sharpens. "You have no idea what I'd do for Vatrai," she says.|"Die for Vatrai, certainly," Cecilia says, shrugging. "But I hope they wouldn't ask me to do [i]this[/i]."|"We are not as alike as you like to think we are," Cecilia says. She's still having trouble looking at you. "I will not die while Vatrai still requires me."}
	#"You'd have to ask the queen and her wizards what they were thinking. This wasn't my idea. I didn't want it."
		*set dutiful %-10
		@{(ceci_past) "You impugn your queen's decision? In public?" Despite her disdain for the spell, Cecilia seems just as unimpressed that you'd question it. "Perhaps they really did just want you dead."|"You're talking about your queen," Cecilia says, eyes narrowing. "So long as you're not dead yet, you should mind what you say."|"I wonder how one gets to where you are without a genuine sense of loyalty," Cecilia says, eyes narrowing.|"You never did have a genuine sense of loyalty. It's disappointing," Cecilia says. She's still having trouble looking at you.}
	#"Cecilia, can you help me? Please?"
		*set boastful %-10
		*if (ceci_past = 1)
			Cecilia laughs, loud and long, the sound piercing against the silence on your side. "Do you know what I will miss, when you're gone?" she asks. "Your ridiculous questions."
		*if (ceci_past = 2)
			"Oh, I ought to, just on principle," Cecilia muses. "It's as though they tried to repair a fine glasswork by hammering it full of nails. But I'm not an anatomist. Certainly I have some healing at my disposal, but not enough to make a dent in you. Or unmake a dent, as it were."
		*if (ceci_past >= 3)
			Cecilia @{(ceci_past = 4) swallows|sighs}. "I'm not an anatomist," she says, her bravado dropping into sudden curtness. "It's not my specialty. And I'm not sure you comprehend how little time you have left. Of course you don't—part of the spell is to keep you from comprehending. With all the healing at my disposal, I could perhaps close one of those wounds, badly, but the others would have done for you in the meantime. There's nothing I can do. Nothing anyone could."

The noises of the battle beyond the pass rise into the air, shouts and clashes of blades, though no one but Cecilia approaches the gate. Cecilia herself looks over her shoulder for a moment, then back to you, resolute. "No one's coming for you," she says. "We know you sent for the duke. And we know he's not coming. You do know that too, by now, don't you? I'm not sure I could bear how @{(ceci_past = 1) pathetic|tragic} it would be if you didn't realize that."

She doesn't offer any evidence, you notice. She's not one to shy away from fully proving her point, not at a moment like this. If the Vatraians had sunk the duke's fleet, or received some intelligence from the continent, you think she'd have told you. If she knew it for a fact, and wasn't just trying to dispirit you.
*fake_choice
	#"You're lying," I say, staring her dead in the eyes.
		*set dread %+15
		Cecilia laughs softly. "Did they keep you around for intimidation purposes, is that it?" she asks. She offers no other response to the accusation.
	#"She's lying," I say to my soldiers, to encourage them.
		*set influence %+15
		If nothing else, you manage to break the spell of Cecilia's presence enough for your comrades to begin murmuring to each other again. Cecilia scoffs, but offers nothing else.
	#"How do you know we sent for him?" I ask. "Is it because you tried to cut him off, and failed?"
		*set brilliance %+15
		Cecilia blinks, and then stares straight through you. "Do you imagine it was difficult to figure out?" she asks. "Your machinations are not so complex."
	#I don't waste time talking and try to pull my feet out of the stone instead.
		*set contortion %+15
		Even aside from the constriction, you find your limbs are heavier to move than the last time you tried. Still, you manage to wriggle one foot free enough that Cecilia strengthens her spell, spreading the rock further up your ankles. Her lips are taut.

There's another, louder series of cries from the battlefield, though you can't discern the details of what you're hearing. Cecilia looks backward @{(ceci_past >= 3) again, then toward the ground for a long moment before straightening with a sigh.|again, and then returns her gaze to you.} "Well," she says. "@{(ceci_past) I can't say I'm not going to enjoy this.|It was always going to end this way, wasn't it?|I'm sorry. At least it'll be quicker this way.|It'll be quicker this way. I want you to know that.}"

You hear a deep rumble yet again. This time, it comes from behind you. More specifically, from the gate you're currently leaning against, locked in place. The old, stone gate, lined with cracks that are splintering further as you watch the whole thing shake apart into boulders larger than you are.
*fake_choice
	#"Wait. Cecilia, wait."
		*set last_words 3
	#"No, no!"
		*set last_words 4
	#"You're going to pay for this. You and all of Vatrai."
		*set last_words 2
	#"Galdrin is under my protection. Nothing will ever change that."
		*set last_words 1
	#I don't say a word.
		*set last_words 5

The rocks fall.
*page_break
The rocks have fallen.
*page_break
The rocks are falling.
*page_break
You think you're getting confused. The seconds break apart and crash against the edges of your mind—you're dying, you will die, you have died. In the span of your last breath, you can't tell the difference between staring at the rocks above you, knowing they'll crush the life from you, and the moment when that death occurs. What you can do is remember.

You remember twenty years ago, when the dragons emerged from isolation on their frozen isle in the north to make an announcement: they had prizes they were willing to award to Galdrin and Vatrai, if the nations could send representatives to best a series of challenges they'd set. In response, King Frederik of Galdrin, Queen Ragna's father, set his own challenges to determine Galdrin's champion. And you, only sixteen, outshone every competitor.
*fake_choice
	#I overpowered adults twice my age in battle.
		*set prowess %+20
		*set chose_strength 1
		The king's contests weren't only physical fights, but that was where you shone. You fought your opponents to the ground in moments, stunning everyone who saw you. By the time the king put a proper blade into your hands, not one of the training weapons used in the bouts, the whole country knew your name.
	#No one could outpace me in the footraces.
		*set contortion %+20
		*set chose_strength 2
		The king set out all kinds of feats for the hopeful champions to achieve: contests of strength and wit and more. The tests of speed were where you shone, racing across Galdrin's coast and leaving your competitors behind in the sand. By the time the king named you as Galdrin's representative to the dragons, the whole country already knew your name.
	#I didn't need to be faster or stronger than any of them, because I was smarter than all of them.
		*set brilliance %+20
		*set chose_strength 3
		The king laid out contests of all sorts, and you put your wits to use in them all. You saw through your opponents' tactics in the fights. You found the quickest paths in the races. You answered every question and riddle the finest thinkers of Galdrin could pose. By the time the king named you as Galdrin's representative to the dragons, the whole country already knew your name.
	#I made friends out of my opponents, and they helped me triumph.
		*set influence %+20
		*set chose_strength 4
		You heard some at the time questioning how legitimate your victories were, but your competitors wouldn't allow it. Young as you were, you were the darling of the king's contests, your charm shining through in contests of strength, speed, wit, and more. Even if perhaps you weren't the most skilled in all of those areas, the skills that allowed you to triumph were just as valuable. By the time the king named you as Galdrin's representative to the dragons, the whole country already knew your name.

What is your name? The rocks are falling. So much is starting to slip away.
*choice
	#Lian.
		*set name "Lian"
		*goto second_name
	#Linde.
		*set name "Linde"
		*goto second_name
	#Cansu.
		*set name "Cansu"
		*goto second_name
	#Irvine.
		*set name "Irvine"
		*goto second_name
	#Ren.
		*set name "Ren"
		*goto second_name
	#Arnar.
		*set name "Arnar"
		*goto second_name
	*if (choice_randomtest = false) #None of those. Something different.
		*label name_entry
		What is your name?
		*input_text name
		Your name is $!{name}, is that right?
		*choice
			#Yes, that's right.
				*goto second_name
			#No, it's something else.
				*goto name_entry

*label second_name

$!{name}. That's part of it. What's the rest? You have a surname. Had a surname.
*choice
	#Aguado.
		*set surname "Aguado"
		*goto pick_gender
	#Nordin.
		*set surname "Nordin"
		*goto pick_gender
	#Kemp.
		*set surname "Kemp"
		*goto pick_gender
	#Brand.
		*set surname "Brand"
		*goto pick_gender
	#Kanda.
		*set surname "Kanda"
		*goto pick_gender
	#Reyes.
		*set surname "Reyes"
		*goto pick_gender
	*if (choice_randomtest = false) #No. Those are all wrong.
		*label surname_entry
		What is your surname?
		*input_text surname
		Your surname is $!{surname}, is that right?
		*choice
			#Yes, that's right.
				*goto pick_gender
			#No, it's something else.
				*goto name_entry

*label pick_gender

$!{name} $!{surname}. They cheered the name in the streets, even then, before you'd visited the dragons' isle, before your greatest feats. $!{name} $!{surname}…
*choice
	#…the girl who'd bring Galdrin salvation.
		*set gender "female"
		*set manwomanperson "woman"
		*set pc_title "Ms."
		
		What pronouns do you use?
		*choice
			#She/her/hers.
				*label sheher
				*set heshethey "she"
				*set himherthem "her"
				*set hishertheir "her"
				*set hisherstheirs "hers"
				*set hesshestheyre "she's"
				*set hesshestheyve "she's"
				*set s "s"
				*goto donepronouns
			#They/them/theirs.
				*goto theythem
			#He/him/his.
				*goto hehim
			*if (choice_randomtest = false) #I'd like to enter my own.
				*goto ownpronouns
	#…the boy who'd bring Galdrin salvation.
		*set gender "male"
		*set manwomanperson "man"
		*set pc_title "Mr."
		
		What pronouns do you use?
		*choice
			#He/him/his.
				*label hehim
				*set heshethey "he"
				*set himherthem "him"
				*set hishertheir "his"
				*set hisherstheirs "his"
				*set hesshestheyre "he's"
				*set hesshestheyve "he's"
				*set s "s"
				*goto donepronouns
			#They/them/theirs.
				*goto theythem
			#She/her/hers.
				*goto sheher
			*if (choice_randomtest = false) #I'd like to enter my own.
				*goto ownpronouns
	#…the child who'd bring Galdrin salvation.
		*set gender "nb"
		*set manwomanperson "person"
		*set pc_title "Mx."
		
		What pronouns do you use?
		*choice
			#They/them/theirs.
				*label theythem
				*set heshethey "they"
				*set himherthem "them"
				*set hishertheir "their"
				*set hisherstheirs "theirs"
				*set hesshestheyre "they're"
				*set hesshestheyve "they've"
				*set s ""
				*goto donepronouns
			#He/him/his.
				*goto hehim
			#She/her/hers.
				*goto sheher
			*if (choice_randomtest = false) #I'd like to enter my own.
				*label ownpronouns
				
				What pronoun do you use in place of [i]he[/i], [i]she[/i], or [i]they[/i]? ([i]He[/i] saved Galdrin. [i]They[/i] fought the wizard.)
				*input_text heshethey
				
				What pronoun do you use in place of [i]him[/i], [i]her[/i], or [i]them[/i]? (The rocks are falling on [i]him[/i]. I swear my loyalty to [i]her[/i].)
				*input_text himherthem
				
				What pronoun do you use in place of [i]his[/i], [i]her[/i], or [i]their[/i]? (Galdrin is [i]her[/i] country. [i]His[/i] sword is useless now.)
				*input_text hishertheir
				
				What pronoun do you use in place of [i]his[/i], [i]hers[/i], or [i]theirs[/i]? (Galdrin is [i]hers[/i]. The sword is [i]his[/i].)
				*input_text hisherstheirs
				
				What words would you use in place of [i]he is[/i], [i]she is[/i], or [i]they are[/i]? Multiple words or contractions are acceptable. ([i]They are[/i] fading away. [i]She's[/i] waiting to die.)
				*input_text hesshestheyre
				
				What words would you use in place of [i]he has[/i], [i]she has[/i], or [i]they have[/i]? Multiple words or contractions are acceptable. ([i]They've[/i] done all they could. [i]She has[/i] tried to stop the wizard.)
				*input_text hesshestheyve
				
				Are your pronouns grammatically singular or plural? (Plural: [i]They stand[/i] for Galdrin. [i]They are[/i] powerful. Singular: [i]He stands[/i] for Galdrin. [i]He is[/i] powerful.)
				*fake_choice
					#Singular.
						*set s "s"
					#Plural.
						*set s ""
				
				Are these the correct pronouns?
				
				For he/she/they: ${heshethey}
				*line_break
				For him/her/them: ${himherthem}
				*line_break
				For his/her/their: ${hishertheir}
				*line_break
				For his/hers/theirs: ${hisherstheirs}
				*line_break
				For he's/she's/they're: ${hesshestheyre}
				*line_break
				For he's/she's/they've: ${hesshestheyve}
				*line_break
				Grammatically @{(s = "s") singular|plural}.
				
				*choice
					#Yes, that's right.
						*goto donepronouns
					#No, I want to enter them again.
						*goto ownpronouns

*label donepronouns

Salvation, they said, because tensions with Vatrai were climbing even then, and everyone thought the dragon's gifts could finally help Galdrin triumph. That the gifts were also offered to Vatrai seemed immaterial at the time. Whatever they were, surely Galdrin would make better use of them. Assuming, of course, that you didn't outshine Vatrai so thoroughly in the trials that the prizes were awarded to you alone.

You all thought that was a possibility, at the time. The dragons never did make the terms very clear.

Your age was such a point of fascination in Galdrin that it surprised you to find that Vatrai's champion was no older than you were. If she'd also won a series of similar contests in her homeland, she never told you about it. For the first few days of your acquaintance, Cecilia Anker didn't speak to you at all.

@{(ceci_past) You had no way of knowing, at the time, what a blessed relief that ought to have been.|Sizing you up, most likely. You were doing the same.|It's too bad, looking back. You had so little time when you could truly be yourselves around one another. Perhaps you could have made better use of it. It's a strange thing to regret, just now.|You had so few moments like that with her. Quiet ones. Perhaps the two of you should have savored it. Then again, before all the excitement, perhaps it wouldn't have been the same.}
*page_break
You and Cecilia sailed together through frigid waters to the Isle of the Dragons. If the isle has a less literal name, the dragons have never seen fit to inform you. Then again, it likely couldn't be expressed in words. In their natural forms, dragons can't speak aloud, communicating with one another through a kind of psychic exchange that, so far as you understand it, consists more of pure concepts than anything you'd recognize as verbal expression. They can project their thoughts in language you recognize as well, and those that can take human shape can speak as a human would, but most of the dragons you've known were uninterested in both processes at best. It was astonishing when they willingly reached out with the offer of the Eyes—before, while you were not precisely enemies, the lack of communication made it difficult to call them friends.

Vesper was the exception to draconic indifference, a black dragon who greeted you with startling warmth. Dragons' ages are largely a mystery to you except that they don't correlate with humans' in a meaningful way, but you understood two things about Vesper's: that she was more than a century your senior, and that as far as the dragons were concerned, she was hardly older than you and Cecilia, just barely an adult. Newly practiced in both speaking and shapeshifting, she accompanied the two of you on your journey across the isle, not so much guiding you as studying the first humans she had ever met.

"Do not mind the tests," she told you, not long after you met, walking beside you in human skin. Her speech was always surprisingly rapid for someone who had only recently begun to speak at all. You understood that dragons exchanged thoughts faster than words could be formed, and wondered if Vesper was striving for that pace. "Everything is a test with us. We grow bored, otherwise, and we abhor boredom."
*fake_choice
	#"Don't the tests themselves get boring?"
		"Yes, yes!" said Vesper, laughing with a delight you weren't certain the question warranted. "Very much so. That is why I am happy you are here. That as well as other reasons."
	#"So what's the penalty if we fail to amuse you?"
		"There is no penalty, no," Vesper said, shaking her head. "Not from us."
	#"Is that why you're offering these prizes? Boredom?"
		"No, no," Vesper said, shaking her head. "The elders determined that we must. I cannot tell you why. There are things we are all forbidden."
	#"You want to know more about us. So do we, about you. Why won't you just explain yourselves?"
		"I am explaining myself," Vesper said, cheerfully enough. "I cannot explain all the rest of us. And there are things I am forbidden. You, too. There are things everyone is forbidden."

Before you could ask what she meant, she shifted back to her dragon form and began psychically attempting to convince you and Cecilia to ride on her back. [i]The new perspective will delight you,[/i] she insisted. [i]Or at least it will surprise you, and that is near to the same thing! For us. I have not done this before, so I will be delighted as well. You will probably not fall.[/i]

Cecilia had little patience for her, so Vesper attached herself more closely to you, forever chattering and offering to spar with you in both of her forms.

She still visits Istta sometimes, one of the primary emissaries the dragons occasionally send to check in on the Eye. You're never going to see her again.

You're never going to see a lot of people again.

The rocks are falling.
*fake_choice
	#I can't bear to think of what I'm leaving behind.
		*set gentle %+10
	#I can't die. All of Galdrin needs me. No one else can take my place.
		*set boastful %+10
	#I don't want to die. I never wanted to be a hero.
		*set boastful %-10
	#I always knew I'd die in battle, but I'm furious that it's Cecilia killing me.
		*set gentle %-10
	#Ah, well. Death comes for us all.
		*set spirited %-10

Memories are still swirling through your mind, pulling you in a hundred different directions. The dragons set you more tasks than your king had, directing you all across the island. Climbing mountains, solving mazes carved in ice, even fighting the dragons themselves from time to time, though the bouts were strictly never lethal. Whatever their intentions—and you're still not sure you know the whole of those—the dragons had no interest in killing you.

You and Cecilia proved to be evenly matched—not necessarily in every challenge, but on the whole, neither of you was more skilled than the other. @{(chose_strength) You easily bested her in contests of strength,|You were faster and nimbler than her even on the ice,|You saw through the dragons' puzzles and riddles in moments,|You managed to befriend even the dragons,} while Cecilia had her own talents.
*fake_choice
	*if (chose_strength != 1) #She was always stronger than me.
		*set prowess %-15
		She wasn't an anatomist, a wizard specializing in manipulating her own body and those of others, but she had a natural strength all her own, and it served her just as well as her magical skill. It was an obvious source of amusement for her that for all your experience in swordplay, she still outmatched you in sheer vigor.
	*if (chose_strength != 2) #She moved faster.
		*set contortion %-15
		She wasn't an anatomist, a wizard specializing in manipulating her own body and those of others, but she had grace and flexibility all her own, and they served her just as well as her magical skill. It was an obvious source of amusement for her that for all your experience in swordplay, she was always more nimble.
	*if (chose_strength != 3) #She had a facility I lacked for the dragons' riddles.
		*set brilliance %-15
		Dragons are fond of puzzles and tricks, and several of the challenges across the island were hidden behind them. You had no patience for these, but Cecilia lit up in a way you rarely saw, murmuring to herself and making careful notes and sketches.
	*if (chose_strength != 4) #She had a kind of magnetism that drew even the dragons to her, while I struggled to communicate with them.
		*set influence %-15
		You wouldn't call it charm, exactly, but even the dragons roused themselves from their private telepathic discussions to listen when Cecilia spoke. Aside from Vesper, they rarely even looked your way.
	#She had a determination that frightened me, and even frightened the dragons.
		*set dread %-15
		You could tell the dragons expected some of their challenges to cow you, but Cecilia never backed down. She would stride through icy waters and shout to rouse the dragons from their private telepathic discussions, all without so much as flinching.

You had your moments too, of course. You could never quite tell if the dragons were impressed with either of you, but they never sent you home.

The climb up Mount Breakwater was one of the most difficult of the trials you faced, a sheer wall of ice with hardly any safe places to set your feet. You rested at the summit, @{(ceci_past) bandaging your own wounds on opposite sides of|lending each other ointment and bandages for your wounds around|bandaging each other's wounds at|bandaging each other's wounds at} a meager campfire. You had spent the day scaling the mountain and nearly fallen a dozen times each.

"They're trying to kill us," Cecilia announced. @{(ceci_past) You already disliked each other intensely, and rarely spoke when you didn't have to, but she seemed too furious to keep silent.|It was a surprise: the two of you rarely spoke when you didn't have to, though you were always studying each other's movements.|You made conversation most nights by then, but the vehemence in her tone surprised you.|She leaned against you as she spoke, and might have held your hand, but both of your palms had been scraped bloody in the climb. You could feel the taut fury in her posture.} "The only thing I haven't worked out is why they're doing it like this."
*fake_choice
	#"They're not. Galdrin and Vatrai would unite against them."
		@{(ceci_past) "They can handle Galdrin," Cecilia said with a snort.|"Galdrin and Vatrai won't unite for anything," Cecilia said with a snort.|"Vatrai wouldn't," Cecilia said very quietly.|"Vatrai wouldn't," Cecilia said very quietly.} "And do you really think the dragons couldn't sink all of Jarda if they set themselves against us?"
		
		[i]We cannot sink an island![/i] came Vesper's voice in your minds, dark wings beating as she flew up in front of you. [i]We do not have dominion over the sea, and islands do not work like boats. Would you like me to carry you down?[/i]
	#"Vesper wouldn't do that to us."
		Cecilia snorted. "If you believe her act, you're @{(ceci_past) more of a fool than I thought|a fool|ridiculous|ridiculous}."
		
		[i]I do not know how to act![/i] came Vesper's voice in your minds, dark wings beating as she flew up in front of you. [i]We do not know each other's thoughts precisely, but deception is difficult when the method of communication is so little removed from them. Would you like me to carry you down?[/i]
	#"Why would they do it at all? They've always ignored us before."
		"Something's changed. Can't you tell?" Cecilia @{(ceci_past) scoffed|held your gaze|leaned closer|rested her head on your shoulder}. "The very fact that they aren't ignoring us anymore means something's more different than any of us have realized."
		
		[i]Many things change all the time, but that in itself is not a reason to kill you,[/i] came Vesper's voice in your minds, dark wings beating as she flew up in front of you. [i]Also, you are children, by human standards. And infants, by draconic standards! Would you like me to carry you down?[/i]
	#"Well, they're not going to succeed."
		@{(ceci_past) Cecilia snorted. "Not with me, no."|After a moment, Cecilia smiled. "No. I don't think they are."|After a moment, Cecilia nodded. "Of course not. We'll make sure of it."|Cecilia drew back enough to meet your eyes, and for you to see her grin. "Of course they won't, $!{name}. You know we both have to live long enough for me to kill you myself."}
		
		*gosub vesper_murder
	#"Maybe they'll kill you. I'm going to win."
		@{(ceci_past) Cecilia's gaze hardened. "If nothing else, $!{name}, I'm going to live long enough to kill you myself."|After a moment, Cecilia laughed. "I never said they were going to kill me. I said they were going to try."|"Oh, please, you sound ridiculous." Cecilia rolled her eyes, though you saw her trying to conceal a smile.|Cecilia drew back enough to meet your eyes, and for you to see her grin. "Don't be ridiculous, $!{name}. You know I'm going to live long enough to kill you myself."}
		
		*gosub vesper_murder

In the end, when you and Cecilia had sweated and bled across what felt like the whole of the island, the dragons called a halt. They were now content, they said, and they awarded you each a dark red gem somewhat smaller than your palm. The Eyes of the Serpent, to give each of your leaders dominion over half of the island. When asked why they'd give up such valuable prizes, and what this had to do with the trials you'd overcome, the dragons said only that they could not wield the gems themselves, and that they had needed to know your worth.

You asked once where the name had come from, but the dragons gave no answer at all. The Eyes of the Serpent didn't resemble any eyes that you'd ever seen, serpentine or otherwise. They were just cloudy and red.

You brought them home to your leaders, to King Frederik in Istta and Queen Dorothea in Borann. They were pleased, but never satisfied, not while their opposite number held the same prize. It wasn't long after that that the wars began.

The wars that led you here, with the rocks above your head.
*page_break
Time rushes back into place. The rocks are falling. In a moment, they will have fallen, and in another moment, you will be dead.

You think you hear, beyond Cecilia's @{(ceci_past) triumphant grin|level stare|flinching gaze|averted gaze}, the sound of horns blaring on the wind. A sound very like the signal Queen Ragna asked the duke to give when he arrived. But it could just be the air rushing around you.

And then the rocks fall. Have fallen. You stopped feeling anything some time ago, but now everything else has stopped, too. There's nothing more.
*page_break
Not for a very long time, anyway.
*page_break
You don't actually know just how it is that you know it's been a long time, when you come back to consciousness and back to the world. You remember fighting at Helma, and dying at Helma, and then nothing until now, but somehow Helma feels a great distance away.

You're aware of nothing else, in those first moments when some fragment of your being wakes up. You can't see. You can't feel. You have no idea where you are. If you're still crushed under the rubble of the Baron's Gate, there's no pressure or weight above you. You aren't breathing, and you feel no need or desire to. You aren't certain if you have a body at all, or just a mind, a sense of yourself.

The one thing you can do is hear. Or perhaps not even that. It's less like hearing and more like receiving a dragon's psychic communication, though perhaps that's because you don't have ears. There are no words at first, only a discordant impression of sibilant whispers and guttural screams. By the time the voice—or presence, perhaps—manages something that sounds at all like an attempt at language, you can only discern one word.

[i]…eyes…[/i]
*fake_choice
	#[i]What?[/i]
	#[i]Who are you?[/i]
	#[i]Where am I?[/i]
	#[i]Am I dead? I remember dying.[/i]
	#[i]Whose eyes? Mine? Yours?[/i]

You have no idea if your own thoughts carry back to whatever it is that's speaking to you. There's no response but a return to the blend of hisses and screaming, and no change in your senses or your surroundings. That's all you know, for a length of time you have no way of measuring, until the voice suddenly rises into a grotesque shriek that would split your skull if you had any certainty that you had one.

[i]BRING THEM BACK[/i]

Then light floods in, and water is rushing all around you.
*page_break
*set in_the_past false
On a second look, the room you find yourself in is not particularly well-lit. It only felt bright compared to the utter darkness you found yourself in when you first awoke. Wherever you are now, you think it's actually subterranean, and almost the only light you see comes from a deep crack in the wall that seems to lead up to the sky.

You're underground, but you aren't beneath the rocks that crushed the life from you. You're in a chamber, large and deliberately built. Aside from the split in one wall and the water pooling beneath you, it's neatly carved and organized, with niches built into the walls and platforms arrayed across the floor. The sensation of sight is still returning to you, and you have to study the platforms for some time to realize what you're actually looking at: caskets. They're ornately decorated, mostly with a large oak tree with the roots stretching down through the ground to the ocean: the royal crest of the Holms.

You look down, finally, to find the shape of your legs stretching down into another casket, emblazoned with that same crest. [i]$!!{name} $!!{surname}, DEFENDER OF GALDRIN[/i] is engraved across the top.
*fake_choice
	#No, no. It's all coming back. I can't be dead. I had so much left to offer.
		*set boastful %+10
		The haze of death and memory, that strange voice in the place between, they drew you away from the reality of what was happening. There was so much yet to do. So many stories still to be written. It can't have just ended like that. But whatever it is that's happening now, whatever it is you've become, something has ended. That much is true without a doubt.
		
		It's a long time before you can gather yourself enough to look down and study yourself further.
	#Well, this does make sense, actually.
		*set spirited %-10
		You died. You remember dying. If you're still going to exist in some form, it seems reasonable that it would be as a ghost.
		
		Curiosity piqued, you look down to study yourself further.
	#These are the royal catacombs. I'm not a Holm. How could I have been buried here?
		*set boastful %-10
		You died. It's reasonable that you'd be buried, if they could recover your body from the ruins of the gate. But why here, among your betters? You received many honors in your lifetime, but you were never treated as one of the royal family.
		
		Still dazed, you look down to study yourself further.
	#This is a second chance, of some kind or another. I'm certainly not going to complain.
		*set spirited %+10
		Clearly, the circumstances are abnormal, but it appears death isn't going to be the end of your time in this world. Not to put too fine a point on it, but it's a gift many people would kill for. At the least, you ought to seize the opportunity.
		
		Intrigued, you look down to study yourself further.
	#All this and Galdrin still couldn't just let me rest. Typical.
		*set dutiful %-10
		You gave everything you had to Galdrin. You gave your life. And still that wasn't enough. You don't know what this means, how you're here, but the crown must have something to do with it, and they must have a job for you. Again.
		
		You swallow the indignation long enough to look down and study yourself further.
You're wearing the clothes you wore beneath your armor when you died, though the armor itself is gone. You look healthy and whole, as far as you can tell. Certainly there are no signs of a gate having collapsed on top of you. But your colors are muted almost to gray, and your feet are definitely passing through the casket beneath you. You feel the barest hint of a sensation as they do, a slight heaviness, but nothing like the resistance you should be facing. You can't feel anything so much as you can feel the water.

The water, you realize, is running into the chamber through the crack in the wall, filling it almost entirely. You're near enough that the water splashes onto you and flows over one end of your casket. While the water passes through you the same way your feet are passing through the casket, it feels cold and real, nothing like your feet within the stone. That's odd enough that it takes you a moment to realize what else is strange. You know where the royal catacombs lie beneath the castle, and there's no reason that water should be flowing into them. For that matter, there's no reason there should be a hole in the wall, let alone one that's growing before your eyes.

The world around you shakes. An earthquake, you think. You notice it more as a visual sensation than a physical one. The crack in the wall widens further, and you swear the ceiling above you bows, just a little. The ceiling that supports the entire royal castle of Galdrin. Urgency finally returning to your dazed spectral mind, you turn around to study the rest of the scene.
*page_break
Behind you, the rest of the tomb is in such a commotion that you can't quite believe you didn't notice it sooner, though in your defense, there have been a variety of things to occupy your attention. The room is filled nearly to bursting with ghosts. There have always been rumors that the island of Jarda is haunted, legends and storybooks, but you've never seen the evidence until now—and until seeing yourself, of course. The spirits drift through walls, block the sunlight, rise up from the water. They are and aren't like you: they have the same gray translucence, but to a much greater extent. From what you can see, your features are intact, even the scars on your skin and the stitching on your clothes. The other ghosts are so faded that they're hardly discernible at all, sometimes little more than the shape of a face or a shadow. And their touch seems to corrode in a way that yours doesn't: as they pass by the eternal resting places of the monarchs of Galdrin, caskets topple and break open, royal skeletons spilling out across the floor.

They don't respond to the destruction they're inciting, or even to one another, specters passing through each other without a care. The only sign they give of awareness at all is a vague murmuring, a low sound in the background that you can't quite make out.

It's almost, but not quite, like the voice that spoke when you first woke up. You find yourself compelled to listen further, though at the same time, you wonder what makes you different from them. If you risk giving up something that makes you stand apart.
*fake_choice
	#I lean into the sensation. I want to know what drives these spirits.
		*set communion %+25
		*set what_nightmare 2
		You're still becoming accustomed to this body you've woken up to, but one thing is certain: you know who you are. You have the sense that these spirits don't, though perhaps that's because the degradation of their silhouettes gives you no hope of identifying them yourself. Something makes you stand apart from them, and you'll never have a hope of understanding what it is if you don't try to reach them. You're dead already. What point is there in fear?
		
		You lean forward and do your best to listen. The murmuring is still hard to understand, a blend of at least a dozen different voices and other sounds that might not be voices at all, but it becomes clearer the more you open yourself up to the noise. The sentences you discern in the end sound as though each word comes from a different throat, and you have no idea which of the ghosts those throats might belong to, but they're perfectly clear in your spectral ears:
		
		[i]Why? What nightmare lies in the deep? What do you want with me?[/i]
	#I listen, with some hesitation. They unnerve me, but they might need my help.
		*set communion %+20
		*set gentle %+5
		*set what_nightmare 1
		The ghosts are desecrating the royal tombs of Galdrin, but they don't seem to be doing it on purpose, as far as you can tell from only a few moments of study. You feel fairly rational yourself, so perhaps there's some way to get through to them, if you don't fall too far into whatever it is that possesses them.
		
		*gosub few_words
		
		[i]Why? What nightmare…What do you want with me?[/i]
	#I listen cautiously. I can't succumb to their influence, but to stop this chaos, I need to understand them.
		*set communion %+15
		*set dutiful %+10
		The ghosts are desecrating the royal tombs of Galdrin. Whatever they are, they're enemies of the crown. To fight them, you must know them, but you must not stray too far.
		
		*gosub few_words
		
		[i]Why? What…want with me?[/i]
	#I avoid the sound as much as I can. Whatever they are, they're pathetic, and they're clearly my enemies.
		*set communion %+10
		*set gentle %-15
		The ghosts are desecrating the royal tombs of Galdrin. Your time is better suited to figuring out how to destroy them rather than in trying to make some kind of connection. You'd be charging at them already if you had a better sense of this body you've woken up to, and if you had any idea how to fight a ghost.
		
		The murmuring fades away as you resolve to disregard it, and only two words from disparate voices slip past your defenses before it does:
		
		[i]Why?…What…[/i]
	#I shut them out completely. I'm clearly closer to life than they are. I can't risk losing that.
		*set communion %+5
		*set spirited %+20
		It's hard to steel yourself against a sensation you don't understand in a body you've only just woken up to, but you give it the best effort you can. You're too experienced a warrior to shut your eyes or plug your ears in an uncertain situation—not to mention the fact that you aren't quite certain how transparent your eyelids are, though your skin has some solidity to it or you'd be able to see your bones—but you rely on the focus you've honed throughout a hundred battles. Your goal is to figure out what's happened to you, and to keep hold of whatever ounce of life is still yours. You won't admit distractions.
		
		The murmuring fades away to something almost indiscernible, and only one recognizable word slips past your defenses:
		
		[i]Why?[/i]

Your attention is drawn from the ghosts by another rumbling, but one that sounds somehow more deliberate, almost hand-crafted. You turn back to the crack in the wall and find it slowly sealing itself, the stones on either side of the gap stretching until they nearly touch. But then the ground shakes again, the ceiling bows, and the stones spring back. Whatever magical effort was just made has clearly failed, but you hardly dwell on that at all. You're already looking for your liege.

The Eye of the Serpent binds the monarch of Galdrin to the earth of the nation itself. King Frederik found that sensation too overwhelming and too reciprocal: not only could he shape his territory, but he felt all the wounds inflicted on it, and the land felt his in turn. With the help of his royal wizards and a dragon or two, he gave the Eye a focal point in Castle Galdrin itself. He retained his influence over all the nation, and while the empathic connection was stronger than ever, it was tied only to the castle itself. Occasionally, when he was angry, the walls would grow so hot that tapestries burst into flame, but his control over the castle walls was powerful and precise, and no wizard could affect them but him. And Queen Ragna only refined the magic further.

You know what it means when the castle walls move. What you don't know is whom you're looking for. You don't know if Queen Ragna survived that day at Helma, though clearly Galdrin itself did, in some form. And even if she did survive, you don't know how long you've been dead. Queen Ragna was nearing fifty when you last knew her. She could easily have had decades left, if the war didn't intervene. Are you looking for her? One of her surviving children? Even her young grandson, perhaps now grown?

The person who storms into the catacombs with a crown atop his head is none of them.

Perhaps it's been longer than you thought.
*page_break
Your king, you assume, is a man perhaps shy of thirty, short and somewhat rounded in stature. He's darker-complected than Ragna or her children, with coppery skin and eyes, his hair a fall of darker brown curls neatly tied off at the base of his neck in a style you don't recognize. The emerald and gold crown nestled amid those curls is definitely Galdrin's, as is the crest on his cape, green layered on brown. And removing all doubt is the red glow coming from his right hand, held high above his head. The Eye of the Serpent, implanted in the monarch's very body.

A final confirmation is the complement of warriors at his back. It's not unusual, of course, for a monarch to be attended, but King Frederik doubled his bodyguards when he began to wield the Eye, bearing the dragons' warnings in mind. Queen Ragna increased their numbers even further. You were a guard to both of them, when you weren't needed elsewhere on a battlefield.
*fake_choice
	#I practiced with my blade daily to be certain I could keep them safe.
		*set prowess %+15
	#I felt I could sense death in the air, sometimes, and I would not allow it near.
		*set communion %+15
	#I had such a fearsome reputation that no one would approach the monarchs when I was at their side.
		*set dread %+15
	#I learned secret paths and stratagems to keep the crown from harm.
		*set brilliance %+15
	#Even the king and queen looked to me when I told them where to go.
		*set influence %+15

"Your Majesty," says one of the guards, "surely you ought to retire to a safehouse and repair the damage from afar." Her grip on her blade is tight, white-knuckled, and though she looks frantically around the catacombs, she's gazing in entirely the opposite direction when a ghost topples a casket inches away from the king.

"I can't," the king says curtly, stepping over the bones at his feet. "With the disturbances, there's too much…noise. I need to see it. There." Eyes fixed on the crack in the wall, he holds out his glowing hand. His brow furrows as he concentrates, but once again, the stones shudder for a moment and refuse to close the gap. The king's glower deepens. "It's not right. I don't know why it isn't working."

The reason it isn't working seems fairly obvious to you. Two ghosts have risen up from the water pouring through the hole and are pressing at the sides, preventing them from sealing. The ghosts are slightly more formed than the others, with clearly delineated limbs and outlines of faces, but their expressions are utterly blank.

"Master Rask," says the king. "Master" denotes a wizard, and the figure who steps forward through the ankle-deep water bears no weapons or armor. They're wearing a long dark coat, decorated with purple embroidery. Their hair is long, thick, and dark, with a reddish sheen that doesn't seem entirely natural—not beyond the skill of an anatomist wizard who studies the human body, though it seems like a bit of a frivolous embellishment for one in the king's personal service. They're quite tall and broad, with skin a rich brown several shades darker than the king's, and they look perhaps ten years his senior. "Senna," the king says, in a lower tone than before, only just loud enough to carry to you. "Can you see them?"

Senna examines the catacombs with dark, intent eyes. Ghosts are swirling up the walls, filling every corner. "No," Senna proclaims after a moment. "There's a technique I've theorized to refine the vision, but it's not—wait. Wait, yes, I do see one. A rather clear one, too, though it doesn't seem inclined toward havoc. Just there."

They lift a finger and point directly at you.

The rest of the ghosts are indistinct in form but obviously present, at least to you, but it sounds as though the others—the living—can't see any of them. Except, for whatever reason, you.
*fake_choice
	#I wave.
		*set spirited %+10
		Senna looks rather taken aback,
	#I smile.
		*set gentle %+10
		Senna narrows their eyes in what looks like confusion,
	#I glare.
		*set gentle %-10
		Senna blinks in surprise or perhaps confusion,
	#I bow.
		*set dutiful %+10
		When you lift your head, Senna looks taken aback,
	#I stare back without moving.
		*set spirited %-10
		Senna studies you a moment longer and then gently nudges the king to get his attention,
but the king is uninterested. He fixes his gaze on you for just long enough to make it clear that he can see you, too, then shakes his head. "What I need is for the ones who are inclined toward havoc to show themselves. It's all—I can't—what's your technique?"

"Unrefined and experimental," says Senna, still studying you. "Certain adjustments to the lens of the eye that I'm hoping can help it tap into the spectral spectrum, so to speak."

"Hoping?" the king repeats.

"Well, I did go blind when I tried it," Senna admits. "There were cataracts, and other complications. Reversible, obviously, but it took me a few hours, and, ah, this may not be the environment for it."

The king is silent.

"I'm nearly certain I know what went wrong, for the record," Senna goes on. "I'll try it again if you like. On myself, not you, of course. Unless—you were talking about overstimulation, with the disturbances to the castle. Do you think it would help if I were to temporarily disable your vision?"

"Senna," the king says, and pauses a moment. "I could temporarily disable my vision myself, if I thought that would help. I have eyelids."

"Yes, they're very nice," Senna says absently. Their gaze has drifted back to you. "Really, Alek, are you looking at the visible one? It's remarkably clear. And it's staying in one place, just over that casket. Whose casket is that, can you tell?"

Alek—though you very much doubt that's the king's full name, making you wonder what sort of relationship they have—sighs. He looks in your direction again, though he's gazing more through you than at you, and you think he's leaning into his connection with the castle rather than recalling the catacombs' layout. "In that section, someone who died at least two hundred years ago," he says. "I can't tell any more without just reading the plaque."

Two hundred years ago. At least.
*fake_choice
	#That can't be right.
		You'd steeled yourself for years. Decades, even. One century feels incomprehensible, let alone two. It's as though you aren't even looking out at the same world you left. Perhaps you really aren't. It's hard to say. The ghosts blur the edges of your vision.
	#Everyone I knew is gone.
		Your responsibilities to the crown left you with little time for family or personal connections. But even the royal family you dedicated your life to will be gone now. Perhaps their descendants yet live, but you don't know them. And there's every possibility they know nothing of you, tomb in the royal catacombs or not. You've been moldering down here long enough to be forgotten, and there's nothing left of your world.
		
		Except the dragons, perhaps.
	#Why would I lie dormant for that long and wake up now?
		There must be a reason for it. That thought is an anchor, something to steady you as you find yourself suddenly adrift in the centuries. Someone or something woke you up. You heard them. Somewhere in all of this, there's an explanation for why you're looking down at your own moldering casket.
		
		You're going to find it.
	#At least Galdrin is still here.
		The wars over the Eyes gave little certainty of anything. You never knew just how severe the destruction would be if one of the monarchs fell, how the island would change. But even if Jarda didn't reshape itself, there was always the possibility of one side or the other simply winning the war. Claiming the whole island by right of conquest.
		
		You could have woken up to find the crown you gave your life for had become a thing of the past. But you protected Galdrin, and Galdrin endured two hundred years and more.
	#I don't mind the idea. It's a fresh start.
		Your responsibilities to the crown left you with little time for family or personal connections. No chance to build your own life. All those trappings are gone now. Even the trappings of your own physical form. And it's a new world, full of the opportunities time can grant.
		
		It's not a bad starting point, as second lives go.

The king presses his hands to his eyes. "Senna, you know I'll indulge you at any other time," he says. "But the castle is a breath away from crumbling. Can you do this spell or can't you?"

"They don't need to," comes a new voice. The crowd of guards separates to allow a tall young woman through. There's an emerald and gold circlet atop her head. Her skin is a warm brown, her hair is a riot of dark curls much less tamed than the king's, and her eyes are solid white flares of light that shine like the sun.

The last part makes it difficult to take in many more details about her.
*page_break
"Iris," says Senna in a strangled voice. Their jaw works for a moment before they add, "You've been going through my notes again."

"You told me I was allowed," Iris says, not looking their way. Admittedly, it's somewhat difficult to tell if she can see.

Alek glances between Iris and Senna. "Is that your spell?" he asks. He doesn't seem nearly as perturbed as Senna does.

"My unrefined and experimental spell, yes," Senna says tightly.

"You were about to test it on yourself," Iris retorts. "Again."

"And am I a princess of the realm, Iris?" Senna asks, arching an eyebrow.

"I don't know," Iris says, voice suddenly flatter than before. "You'd probably just lie about it if you were."

Something in her tone makes you take another look at her face, and you realize that beneath the glow, she's even younger than you first thought. A girl rather than a woman, no more than sixteen. Senna, at her words, winces and goes silent.

Alek rubs at his eyes again. "The spell, Iris. Can you see the ghosts, or not?"

"I can see…" Iris frowns, concentrating. "Clouds. Or…shadows."

"And that could be the ghosts, or it could be the cataracts," Senna murmurs, arms folded across their chest. "You begin to grasp the difficulty."

There are a great number of things about this situation you still don't understand, but you do know this much: the living can't see the rest of the ghosts. You can. And if you don't get rid of them so the king can repair the castle, it's going to collapse on top of all of you. And that's a very familiar feeling.

Admittedly, it might not mean much for you in your new state. But it's rather early in your afterlife to take the risk.
*choice
	#I direct the others to the ghosts. They sound like they'd know what to do, if they could find them.
		*set already_spoke true
		There's something odd about the idea of talking in your state, but it doesn't feel impossible. You try to clear your throat, find that no sound or sensation registers, and simply begin to speak. "They're in the crack in the wall. They're holding it open."
		
		Everyone gathered at the other end of the tomb jumps, almost in unison. Alek straightens, his shoulders very stiff. "Senna," he says, "your ghost is speaking. Have any of them ever spoken?"
		
		"Not that I've seen," Senna says. They look something close to delighted, particularly in comparison to everyone else. "But it's not as though we have a great deal of experience with them."
		
		"I [i]can[/i] see them," Iris interjects. "That's one of the shadows."
		
		"We can all see that one," Senna mutters, then looks back to you. "What did you say, friend? I fear we were a bit startled."
		
		"The ghosts, they're in that crack in the wall, holding it open so that the king can't repair it," you say.
		
		Senna's eyes widen even further, and they take a step forward, but Alek grabs them by the arm. "We can't just take the thing at its word," he snaps. "It's…different, somehow, but it's still a specter. Why should it be on our side, and not with the other ghosts?"
		
		*if (influence >= 55)
			*set gal_integrity %+15
			*set ghost_auto %+10
			*set already_asked true
			You answer almost without thinking. "I am sworn to the crown of Galdrin," you say. "I am with you now and forever, in life and in death, Your Majesty."
			
			Alek blinks, his mouth falling slightly open. His hand drops away from Senna's arm. "Who are you?" he asks, just loud enough for you to hear.
			
			Senna takes the opportunity to dart forward, up to the crack in the wall. They look to you for reassurance, still unable to see anything there. At your nod, they reach inside their robe and run one hand up and down the other arm. You can't see just what kind of anatomical spell they've performed, but when they thrust their arm forward, there's an incredible rush of force behind it. You can almost hear it connect with the ghosts.
			
			The ghosts dissipate into nothingness as they're pushed backward. You have just a moment to wonder what's become of them before the stones of the wall stretch out and touch again. The hole seals and the ceiling straightens, no longer dropping inward. Senna shakes their arm out carefully.
			*label turn_around
			When you turn around again, Alek is breathing deeply but looks satisfied. Throughout the chamber, the rest of the ghosts start to slip away, too, some of them vanishing entirely like the first two and others slipping through the walls. Bones and rubble are scattered across the floor, floating or submerged where the water is deeper, but the tomb is at peace.
			
			"The shadows are gone," Iris says, before you can make an announcement. "Except that one."
			
			Slowly, everyone looks to you. "@{(already_asked) I'll ask again|You}," says Alek. "Who are you?"
			*goto after_ghosts
		*else
			*set gal_integrity %-10
			"I have no reason to lie to you," you say. "I don't know what's going on any more than you do."
			
			"You think that's a reason we should trust you, do you?" Alek retorts. "That you don't know what's going on?"
			
			"There is something in that hole," Iris says softly. "Shadows. But I'm not sure if it's ghosts or…I can't see very well."
			
			"I told you," Senna says, voice growing sharper. "You shouldn't just—"
			
			Before they can finish the sentence, there's an enormous crash. One of the caskets near yours has toppled to the ground, more bones flying out of it. They land in one of the deeper sections of the water and quickly float off in different directions, mixing with the other scattered bones to a degree that you're not certain any original skeleton could be reconstructed from them.
			
			*label poor_fred
			*set alek_tired true
			
			For a moment, there's silence. Nearly everyone looks stricken, staring at the swirling bones, but Alek strides forward. Fury burns in his eyes, nearly as bright as Iris's. "I know which one that was," he says. "Frederik the Second. First bearer of the Eye. There will be no more of this. Not here."
			
			He thrusts his glowing hand upward, and all at once, the ground before him turns to sharp spikes that burst upward. You're hovering over a casket rather than the floor, so they miss you, but nearly all the rest of the ghosts are skewered where they float. Water flies through the air, and the ghosts dissipate. They don't look disturbed, and they make no murmuring sounds, but are simply there one moment and gone the next. As you're wondering what's become of them, the floor returns to normal and the hole in the wall seals shut. The tomb is covered in bones and rubble, but at peace.
			
			There's a series of gasps behind you, and you turn to see Alek, drenched in sweat and swaying on his feet, supported by Iris's arm. "What are you?" he demands through heaving breaths. "Why are you still here?"
			*goto after_ghosts
	#I attack the ghosts. We're equally corporeal. We ought to be able to fight on equal terms.
		You don't have a weapon, and may not even be able to hold one, but you're a warrior of legend. You can fight with or without one. You try to take a breath, realize that no sound or sensation registers, and then simply dive at the ghosts in the crack in the wall. You aren't sure what to expect when you collide with them, and at first you think you might simply pass through them, but you do come to a halt first, though you feel no pain or sensation of resistance. The ghost beneath you simply stares up at you through the hollows of its eye sockets. You rear back and drive your first into its face.
		
		"Senna," comes Alek's voice from behind you, "your ghost is punching the air."
		
		"No, there's a shadow there!" Iris insists. "I think they're fighting each other!"
		
		The other ghost's form is still too indistinct for you to tell if you're doing any physical damage, but there's a kind of wheezing sound coming from it.
		*if (prowess >= 55)
			*set gal_integrity %+15
			*set ghost_auto %+10
			*set seen_conscious true
			*set saw_student 1
			You continue with your assault, becoming accustomed to the indistinctness of your limbs and the very slight feeling when you make contact. The wheezing continues as you go, turning into something more like gasping breaths.
			
			Then, very suddenly, the ghost changes shape, becoming a young man a few years older than Iris, nearly as distinct as you are. From the gasps behind you, the others can now see him, too. He stares up at you in utter terror, hands flying up to shield his face. But before you can decide what to do, he dissipates into nothingness, as does the other ghost beside him. You have just a moment to wonder what's become of them before the stones around you start to shudder, and you hastily back out of the hole in the wall before it seals itself shut. The ceiling straightens, no longer dropping inward.
			*goto turn_around
		*else
			*set gal_integrity %-10
			At first, it seems stunned. But then it lunges forward, and you discover that as faint as it is in appearance, it still has enough solidity to wrap its hands around your neck.
			
			As you fall backward, there's an enormous crash. You and the other ghost have struck one of the caskets, and it falls to the floor, scattering bones. They float off through the pooling water, mingling with the other spilled bones to the point where you doubt any original skeleton could be reconstructed from them. The other ghost drifts away, as though it doesn't remember attacking you at all, and you scramble back to your own resting place.
			*goto poor_fred
	#I slip into the crack in the wall to force the ghosts out.
		You stretch your limbs experimentally. There's a flexibility to them beyond what you were accustomed to in your mortal body, as though you could resize them at will. You hope that's what you're feeling, at any rate. You're about to find out.
		
		You try to take a breath, realize that no sound or sensation registers, and then simply dive at the ghosts in the crack in the wall. There's a small breath of air between them, far too narrow for a solid body to occupy, but you focus on the idea of shrinking yourself down.
		*if (contortion >= 55)
			*set gal_integrity %+15
			*set ghost_auto %+10
			*set already_spoke true
			Incredibly, it works: you feel yourself fading to a sliver, nearly completely intangible. You fit yourself between the two ghosts, and then, with another effort of thought, you expand.
			
			The ghosts give a hissing, wheezing sound that might pass for surprise as you shove them into the wall. Soon, you occupy the empty space entirely. "Now, Your Majesty!" you shout, a little surprised at how normal it feels to speak, before lunging back toward your casket.
			
			"What?" comes Alek's startled voice, but he doesn't wait for an answer. The stones shudder, and then the crack seals itself. The two ghosts emerge from the wall to stare at it, just for a moment, before they dissipate suddenly into nothingness. You stare, wondering what's become of them, as above you, the ceiling straightens.
			*goto turn_around
		*else
			*set gal_integrity %-10
			But it doesn't work, or at least it doesn't work enough. Your body still feels somewhat indistinct, even to you, and it's hard to get a grasp of its dimensions, let alone to seize control of them. There's no pain, and barely even a feeling of collision, but you bounce against the other ghosts and can't get through.
			
			As you drift backward toward your resting place, another ghost streaks toward another casket. With an enormous crash, the casket falls to the floor, scattering bones. They float off through the pooling water, mingling with the other spilled bones to the point where you doubt any original skeleton could be reconstructed from them.
			*goto poor_fred
	#I try to communicate with the ghosts. Maybe they can be persuaded to stop.
		You drift away from your casket, over to the two ghosts hovering in the broken space in the wall. Something tells you not to speak to them, instead to extend your thoughts the way you did with the voice that spoke when you woke up. [i]Why are you doing this?[/i] you ask.
		
		The ghosts offer no response. They have faces, just barely, but they're turned away from you. You wonder if this is working, if they can truly hear you at all.
		
		[i]You're going to hurt people,[/i] you try.
		
		Slowly, the ghost on the left turns its face toward yours. From the little you can see of the shape of its body, its neck has twisted farther than should be possible. After a moment, a voice echoes in your mind.
		
		[i]What nightmare lies in the deep?[/i]
		
		You struggle to shape your thoughts into words. [i]@{(what_nightmare) What? I don't know what that means.|You said something like that before, or one of you did. Something about a nightmare. What does it mean?|You said that before. Or one of you did. Why? What does it mean?}[/i]
		
		The ghost says nothing in return, only stares at you through the hollows of its eye sockets.
		
		*if (communion >= 55)
			*set ghost_auto %+10
			*set gal_integrity %+15
			*set seen_conscious true
			*set saw_student 1
			You decide to return to the path that got you an answer originally, if not a very helpful one. [i]You're going to hurt people,[/i] you repeat. [i]If you stay where you are, the castle will fall. Everyone in it will be crushed, including the king. Do you know what happens to Galdrin if the king dies? Is that what you want?[/i]
			
			"What?"
			
			It takes you a moment to realize what's strange. That wasn't an impression of sound in your mind, it was a voice spoken aloud.
			
			As you watch, the shades resolve into a young man and woman, as clearly defined as you are. They're just a few years older than Iris, and they look similar enough to be siblings, perhaps twins. From the gasps behind you, you think everyone else can now see them too. "What do you mean?" says the one on the left, the boy, who spoke before. "We were going to go to university on the continent."
			
			He looks utterly terrified, as does the girl beside him, who reaches for his hand. But before you can respond, to comfort them or to try yet again to figure out what's going on, both of them blink and then dissipate entirely. As you look around the tomb, you see all the ghosts doing the same thing, vanishing into nothingness.
			
			There's a moment of silence, and then the sound of stones sliding together as the hole in the wall seals shut. King Alek is striding toward you, glowing hand held high. "What was that?" he demands. "And what are you?"
			*goto after_ghosts
		*else
			*set gal_integrity %-10
			[i]What are you talking about?[/i] you demand, advancing. [i]What is any of this? Why are you here?[/i]
			
			After a moment, the ghost responds in your head again, but it's not in the same voice as before. It is, however, horrifyingly familiar.
			
			[i]BRING THEM BACK[/i]
			
			You shudder, involuntarily drifting backward. As you do, one of the other ghosts dives downward, straight for a casket near you. It falls to the ground with an enormous crash, more bones scattering across the floor. They float off through the pooling water, mingling with the other spilled bones to the point where you doubt any original skeleton could be reconstructed from them.
			*goto poor_fred

*label after_ghosts
*page_break
You stare back at the king—your king—trying to formulate a response. Your sense of identity has never faded, unlike the rest of these shades, and yet you still don't feel prepared to answer the question. @{(already_spoke) It already feels strange that your voice sounds the same as it always did, though perhaps with a bit of an echo.|You aren't even certain what it would feel or sound like to speak in this form.}

"I can answer that," comes a voice. Senna, without your realizing it, has joined you at your casket and is peering down at the engraving. Their eyes are wide. "My word. In our hour of greatest need. The legends have come true."

Alek is suddenly very still, @{(alek_tired) even his exhausted swaying coming to a halt|to the point where you're not certain he's breathing}. "What did you say?"

"King Aleksander," Senna says. They sweep into a bow, but not to Alek—they're facing you. "I present to you your sworn sword. Friend to the dragons and hero of Helma. $!{name} $!{surname} returns to us."
*choice
	#Continue to chapter 2.
		*finish
	*if ((choice_randomtest = false) and (choice_saved_checkpoint_ch_1)) #Return to the start of this chapter.
		*restore_checkpoint ch_1

*comment gosubs

*label war_backstory

You can't count just how long ago the first war between Galdrin and Vatrai began, but the present one has lasted just about two decades. It wasn't long after you were chosen as Galdrin's champion that it broke out. Ever since they killed Prince Elias, Vatrai has taken the advantage. That means they've redoubled their efforts to take out Queen Ragna, which, like as not, will end this. They chased your forces from the capital on the island's coast, up the river Galida to the city of Helma, where the royal wizards are keeping the queen hidden now. There's only one way into Helma, the Baron's Gate, and your mission is to defend it with what remains of your life.

The queen's cousin, a duke on the continent, has promised reinforcements to beat back Vatrai. But the waters between here and Haberna are treacherous, and the Vatraians have been intercepting your messages. You're not certain when he'll reach you, and if you fall before then, it's likely the queen will fall, too. You've already been at your post for nearly a day.
*return

*label few_words

You concentrate on the murmuring, steeling yourself at the same time. Despite your efforts, the noises are muddled in your ears, at least a dozen voices blending together with other sounds that don't much resemble voices at all. In the end, you discern only a handful of words that might come from any number of throats.
*return

*label vesper_murder

[i]This would be a remarkably inefficient method of murder![/i] came Vesper's voice in your minds, dark wings beating as she flew up in front of you. [i]Perhaps efficiency would not be the goal, but I struggle to understand the proposed mindset, as I am not a murderer. Would you like me to carry you down?[/i]
*return