*label FSCheck
*if (fatigue >= 85) and (fatigue < 95)
  You feel hungry and need to eat something soon.
*if fatigue >= 95
  You are famished and require food as soon as possible.
*if (stress >= 85) and (stress < 95)
  As your stress builds, your hands shake and mind feels unfocused. You need to do something to relax.
*if stress >= 95
  You are overwhelmed with stress. Feeling this way for too long will have long-term consequences.
*return

*label CheckAttachments
*set p_suppressor false
*set p_scope false
*set s_suppressor false
*set s_scope false
*if (((p_type = "ranged") and (p_class != "bow")) or ((s_class != "bow") and (s_type = "ranged"))) and (suppressors > 0)
  Suppressors make a ranged weapon much more silent and increase accuracy by a moderate amount.

  You have
  *if suppressors =1
    a suppressor
  *if suppressors >1
    ${suppressors} suppressors
  available.
  *fake_choice
    *if (p_type = "ranged") and (p_class != "bow")
      #I place it on my ${p_weapon}.
        *set p_mod +5
        *set p_suppressor true
    *if (s_class != "bow") and (s_type = "ranged")
      #I place it on my ${s_weapon}.
        *set s_mod +5
        *set s_suppressor true
    *if (suppressors > 1) and (((p_type = "ranged") and (p_class != "bow")) and ((s_class != "bow") and (s_type = "ranged")))
      #I place one on both weapons.
        *set p_mod +5
        *set s_mod +5
        *set p_suppressor true
        *set s_suppressor true
    #I don't place a suppressor.
*if ((p_type = "ranged") or (s_type = "ranged")) and (scopes > 0)
  Scopes allow you to see targets more accurately and aim at targets from a greater distance.

  You have
  *if scopes =1
    a scope
  *if scopes >1
    ${scopes} scopes
  available.
  *fake_choice
    *if p_type = "ranged"
      #I place it on my ${p_weapon}.
        *set p_mod +10
    *if s_type = "ranged"
      #I place it on my ${s_weapon}.
        *set s_mod +10
    *if ((p_type = "ranged") and (s_type = "ranged")) and (scopes > 1)
      #I place one on both weapons.
        *set p_mod +10
        *set s_mod +10
    #I don't place a scope.
*return

*label ChangeUniform
*set clothes_count +1
*set timecount +25
You head
*if chapter_point < 6
  into your closet and put on…
*if chapter_point = 6
  to a secluded area of camp and change into…
*fake_choice
  *if combat_uniform
    #My combat uniform.
      *set uniform "combat"
      *set uniform_desc "combat uniform"
      You put on camouflage pants and a jacket with a tan shirt and combat boots.
  *if formal_uniform
    #My formal service uniform.
      *set uniform "service"
      *set uniform_desc "service uniform"
      You dress in your ASUs,
      *if male or nb
        blue coat and trousers with a long-sleeved white shirt and black tie.
      *if female
        blue coat, skirt, and white shirt with black neck tab.
  *if scrubs
    #Medical scrubs.
      *set uniform "scrubs"
      *set uniform_desc "medical scrubs"
      You put on the same medical scrubs you'd use in the ER.
  *if white_coat
    #White coat and suit.
      *set uniform "white coat"
      *set uniform_desc "white coat"
      You dress in a suit with your white lab coat over it.
  *if police_uniform
    #Service uniform.
      *set uniform "cop"
      *set uniform_desc "police uniform"
      You put on your standard service uniform.
  *if construction_outfit
    #Construction worker's outfit.
      *set uniform "construction"
      *set uniform_desc "construction worker's clothes"
      You dress in a flannel shirt, denim jeans, and heavy work boots.
  #Street clothes.
    *set uniform "street clothes"
    *set uniform_desc "street clothes"
    You dress in a casual and comfortable shirt and pair of pants, along with a pair of sneakers.
  #Hiking clothes.
    *set uniform "hiking"
    *set uniform_desc "hiking clothes"
    You dress in a thick shirt, rugged jeans, and a sturdy pair of hiking boots.
You stare at yourself in the mirror and adjust your clothing. Something about the act of putting on fresh clothes makes you feel confident and renewed.
*return

*label BuryLJ
*set disposed_of_lj true
*if saw_jillian_snooping and (j_gave_back_stolen_items = false)
  *set j_gave_back_stolen_items true
  *if j_batt
    *set batteries +1
  *if j_pain
    *set pain_killers +5
  *set w_flashlight +1
*if lj_inside
  *if not(choked_lj)
    Blood pools beneath Lyle's and Jillian's body in the center of your living room, and already the smell of death permeates the air.
  *if choked_lj
    Lyle and Jillian stare up at the ceiling as if asleep, but the smell of death reminds you otherwise. To keep them from rising as the undead, you pierce their brains with a knife. Brown ooze seeps from their skulls.
  Disposing of their bodies turns out to be no easy feat, and the next hour becomes a challenge of dragging the bodies to the backyard and digging a deep-enough hole to contain them.
*if lj_outside
  *if not(choked_lj)
    Blood pools beneath Lyle's and Jillian's body in the yard, and already the smell of death permeates the air.
  *if choked_lj
    Lyle and Jillian stare up at the night sky as if asleep, but the smell of death reminds you otherwise. To keep them from rising as the undead, you pierce their brains with a knife. Brown ooze seeps from their skulls.
The cold outside does an adequate job of preserving the rotting corpses long enough to bury them, though you search their pockets before the deed.
*if shovel > 0
  *set fatigue %+(round((100-sta)/5))
  *set timecount +75
  Using your shovel helps you through the task.
*if shovel = 0
  *set fatigue %+(round((100-sta)/2.5))
  *set timecount +125
*if athletics >= 60
  *set timecount -25 
*if athletics < 40
  *set timecount +25
The breached ground swallows them up, and once the grave is filled, nothing remains but a mound of disturbed dirt.
*return

*label SlaughterLJ
*set lyle_and_jillian_join false
*set lyle_and_jillian_killed true
*set lyle_alive false
*set jillian_alive false
*set fatigue %+(round((100-sta)/3))
*set survivor_kills +2
*set lj_gear true
*if (p_class = "pistol") or ((p_class = "rifle") or (p_class = "burst"))
  You raise the ${p_weapon} to Lyle's head and pull the trigger. The weapon makes a short pop. Jillian screams, though she blocks her mouth to stifle it. Lyle's head snaps to the side, blood spraying from the exit wound. A short line of smoke rises from the barrel, then disappears. You turn to Jillian as Lyle slumps over.
  
  "I don't want to die," Jillian cries, but you hold the gun up and end her life in one quick gesture.
  *return
*elseif p_class = "bow"
  You raise the ${p_weapon} to Lyle's head and fire ${p_weaponmode}. The bow string twangs. Jillian screams, though she blocks her mouth to stifle it. Lyle's head snaps to the side, blood spraying from the entry wound. As Lyle slumps over, 
  *if p_weapon != "crossbow"
    you nock a new arrow.
  *if p_weapon = "crossbow"
    you slip a bolt into the shaft.
  
  "I don't want to die," Jillian cries, but you hold the ${p_weapon} up and end her life in one quick shot.
  *return
*elseif p_class = "shotgun"
  You raise the ${p_weapon} and fire once at Lyle's head. The weapon blast fills the void of silence in one short boom. Jillian screams, though she blocks her mouth to stifle it. Lyle's head flops to the side, blood and brain matter spray from the opposite side. A short line of smoke rises from the barrel, then disappears. You turn to Jillian as Lyle slumps over.
  
  "I don't want to die," Jillian cries, but you hold the gun up and end her life in one quick gesture.
  *return
*elseif p_class = "hack"
  You raise the ${p_weapon} over Lyle's head and bring it down. The weapon hits his skull with a short [i]thunk[/i], like the sound of chopping wood. Jillian screams, though she blocks her mouth to stifle it. Lyle's head flops to the side, blood spraying up from the wound. You yank the weapon out, and Lyle slumps to the side. More blood spills from his open head and
  *if lj_inside
    soaks into the carpet.
  *if lj_outside
    darkens the ground outside your house.
  
  "I don't want to die," Jillian cries, but you hold the ${p_weapon} up and end her life in one quick gesture.
  *return
*elseif p_class = "club"
  You raise the ${p_weapon} over Lyle's head and bring it down. The weapon hits with a short [i]thunk[/i], like the sound of chopping wood. Jillian screams, though she blocks her mouth to stifle it. Lyle's head flops to the side, blood spraying up from the impact wound. You hold back the weapon and notice a caved-in portion of Lyle's skull as he slumps to the side. More blood spills from his open head and
  *if lj_inside
    soaks into the carpet.
  *if lj_outside
    darkens the ground outside your house.
  
  "I don't want to die," Jillian cries, but you hold the ${p_weapon} up and end her life in one quick gesture.
  *return
*elseif (p_class = "sword") or (p_class = "knife")
  You raise the ${p_weapon} to Lyle's throat and draw it across the flesh. Lyle gurgles, and blood spits from the wound. The gurgle turns into a sputtering as Lyle tries to suck in air through his cut windpipe. Jillian screams, though she blocks her mouth to stifle it. Lyle's head flops to the side, and his body follows. You retract the weapon and notice a thin line of crimson decorating the metal. More blood spills from Lyle's throat and
  *if lj_inside
    soaks into the carpet.
  *if lj_outside
    darkens the ground outside your house.
  
  "I don't want to die," Jillian cries, but you hold the ${p_weapon} up and end her life in one quick gesture.
  *return
*else
  *set choked_lj true
  You loop your arm around Lyle's neck and squeeze. His hands grip your wrist as he struggles to pull away. You lean in and apply pressure to his throat. He gurgles, and his fingernails dig into your skin. The gurgle turns into sputtering. Jillian screams, though she blocks her mouth to stifle it. Lyle tries to stand, but you hold him down and cinch your arms to cut off any air from seeping in. The process takes less time than you expected, and once Lyle's arms go limp, you release. He slumps over, and his head smacks into the
  *if lj_inside
    floor.
  *if lj_outside
    concrete.
  
  "I don't want to die," Jillian cries, but you step next to her and start the process of choking out her life.
  *return

*label CheckLJGear
*set timecount +25
*set lj_gear false
*set w_backpack +1
*set w_binoculars +1
*set duct_tape +1
*set w_food +3
*set sodas +2
*set supplement_pills +20
*set lighters +1
*set w_cigarettes +20
*set pain_killers +1
*set sunscreens +1
*set stress %-(round(wil/5))
You wait until Lyle and Jillian are off in the kitchen and head over to check their gear. You lift Lyle's backpack, which looks only slightly larger than a young child's schoolbag. Inside rests a pair of binoculars, a roll of duct tape, several cans of food, two sodas, and a box of supplement pills.
      
In Jillian's handbag, you find batteries, a lighter, a full pack of cigarettes, a bottle of over-the-counter pain-killers, an assortment of used tissues, and sunscreen.
*if saw_jillian_snooping and (j_gave_back_stolen_items = false)
  *set j_gave_back_stolen_items true
  *if j_batt
    *set batteries +1
  *if j_pain
    *set pain_killers +5
  *set w_flashlight +1
  You also find your batteries and painkillers..
You take the valuable items from both bags, add them to your pile, and throw the trash away.
*return
  
*label LJGearCheck
*set timecount +25
*set lj_gear false
*set w_backpack +1
*set w_binoculars +1
*set duct_tape +1
*set w_food +3
*set sodas +2
*set supplement_pills +20
*set lighters +1
*set w_cigarettes +20
*set pain_killers +1
*set sunscreens +1
*set stress %-(round(wil/5))
You lift Lyle's backpack, which looks only slightly larger than a young child's schoolbag. Inside rests a pair of binoculars, a roll of duct tape, several cans of food, two sodas, and a box of supplement pills.
      
In Jillian's handbag, you find batteries, a lighter, a full pack of cigarettes, a bottle of over-the-counter pain-killers, an assortment of used tissues, and sunscreen.
*if saw_jillian_snooping and (j_gave_back_stolen_items = false)
  *set j_gave_back_stolen_items true
  *if j_batt
    *set batteries +1
  *if j_pain
    *set pain_killers +5
  *set w_flashlight +1
  You also find the stuff she stole from you.
You take the valuable items from both bags, add them to your pile, and throw the trash away.
*return

*label FredsBag
Whatever Fred packed in that duffel bag now lying in the alley must be of great value and worth a quick trip outside. You peek through the front window and 
*if night_blindness and (timecount >= 2000)
  can barely see through the darkness of the night.
  *if w_flashlight = 0
    Without clear sight, there's no way you can sneak outside and grab the bag. You'll have to wait until the sun is up.
    *return
*if (night_blindness = false) or (timecount < 2000)
  see no movement on the street. 
*if dep_home

  "Whatcha lookin' at, ${name_call}?" ${dep_name} asks.
        
  "I'm heading outside to get something."
        
  "The bag Fred dropped?"
        
  "How'd you know about that?"
        
  "I'm keepin' track of things," ${dep_name} says matter-of-factly.
        
  "Stay here and make sure the door stays locked until I come back."
        
  "Got it."
*if cat_owner
      
 ${pet_name} runs to your side as if trying to stop you from leaving, but then quickly darts off.
*if dog_owner
      
  ${pet_name} scratches at the door as if wanting to go out. 
        
  "Sorry, buddy. Not right now," you say, petting his head.
  *if dep_home
        
    "I got him," ${dep_name} says, hugging the dog around the neck.

You walk down the front steps,
*if night_blindness and (timecount >= 2000)
  *set stress %+(round((100-wil)/5))
  using your flashlight to compensate for your poor night vision,
pressing your back against the wall as you follow your house around to the alley. Cold air whistles, but it already feels warmer outside. Your feet slide along the pavement, and you watch for ice that hasn't melted yet.
*set retrieved_freds_bag true
*set fatigue %+(round((100-sta)/5))
*set timecount +50
*if stealth >= 40
  *set crafting_tools +1
  *set hammer +1
  *set duffel_bag +1
  *set sodas +3
  *set retrieved_freds_bag true
  *set stress %-(round(wil/5))
  Creeping along the wall, you hear an animal-like snort, and across the street, one of the infected hobbles along without any indication of noticing your presence. This eases your mind, and you turn the corner to the alley feeling confident in your ability to move without detection. Lying in the midst of the trash and snow is Fred's duffel bag. You unzip it and find a variety of tools, and of course, the duffel bag itself will also come in handy. Beside it are three full cans of soda. Though you're not sure if they fell out of the bag, you take them anyway.
  
  Excited at retrieving the bag, you creep back along the wall and reach your house unscathed.
  *return
*elseif athletics >= 50
  *set crafting_tools +1
  *set hammer +1
  *set retrieved_freds_bag true
  *set duffel_bag +1
  *set sodas +3
  *set stress %-(round(wil/5))
  Moving along the wall, you hear an animal-like snort, and across the street, one of the infected hobbles around. It turns its neck in your direction, so you burst down the pavement towards the alley, confident you can reach the bag before the zombie can reach you. Turning the corner, you spot Fred's duffel bag lying in the midst of the trash and snow, and you grab it and dash back up the alley. The zombie has made it to the middle of the street several houses away, but you easily outrun it, even finding the opportunity to check the contents of the bag. You unzip it and find a variety of tools, and of course, the duffel bag will come in handy. Beside it are three full cans of soda. Though you're not sure if they fell out of the bag, you take them anyway.
  
  Excited at retrieving the bag, you run back along the wall and reach your house unscathed.
  *return
*else
  *set stress %+(round((100-wil)/5))
  Moving along the wall, you hear an animal-like snort, and across the street, one of the infected hobbles around. It turns its neck in your direction. In that split second, you envision your future: dashing to the corner, grabbing the bag, the zombie meeting you back at the corner as you run back, your throat being ripped out, returning to the world as the undead. Instead of letting your nightmare come true, you turn and rush back home. Fred's bag will have to remain outside for now.
  *return

*label TreatWounds
Since the outbreak started, you've suffered scrapes, bruises, and strains. Treating the wounds is just one step in surviving the ordeal.
*if medicine >= 50
  *set timecount +25
*if medicine < 50
  *set timecount +50
*if first_aid_charges > 0
  *set p_health %+(round((medicine)/2))
  *set first_aid_charges -1
  From your first aid kit, you take out alcohol pads and use them to clean your abrasions. Larger cuts receive sterile gauze pads, while smaller ones take simple Band-Aids. When all is done, you feel better and know your body will heal over time.
  *return
*elseif ointments > 0
  *set ointments -1
  *set p_health %+(round((medicine)/2))
  From your inventory, you take out the antiseptic ointment, and after cleaning the area, you apply the salve to your cuts and abrasions.
  *return
*else
  *set p_health %+(round((medicine)/4))
  Without a first aid kit or other resources, the best you can do is clean the area and hope your body heals on its own.
  *return

*label BandageKnee
*set timecount +25
*if already_inspected_knee
  You roll your pant leg up to check out your knee again. It's still swollen and will require some kind of treatment in order to heal properly.
*if not(already_inspected_knee)
  *set already_inspected_knee true
  You roll up your pant leg, stopping midway from a sharp pain as the material constricts your knee. Gingerly easing the rest of it up, you inspect your knee. It appears red and swollen, but not as bad as earlier.
  *if pain_killers > 0
    The first thing you do is take
    *if pain_killers = 1
      *set pain_killers -1
      *set stress %-(round(wil/10))
      your last pain-killer 
    *if pain_killers > 1
      *set pain_killers -2
      *set stress %-(round(wil/5))
      two pain-killers
    to help dull the pain.
  *set p_health %+(round((medicine)/5))  
  *if medicine >= 60
    The area around the joint is tender to the touch, but palpation proves that nothing is broken nor dislocated. Most likely, the fall stretched the lateral ligaments, so immobilization and time will heal it.
  *if (medicine >= 45) and (medicine < 60)
    The joint feels tender as you move it around. It bends without shooting pain, so you are fairly certain the knee isn't broken. Time will heal it, and keeping pressure off of it will also help.
  *if medicine < 45
    It's probably not broken, but you're no doctor. The whole area is tender, but at least you can move it. If you keep pressure off of the leg, maybe it will heal faster.
*choice
  *selectable_if (splints > 0) #Use a splint on my leg.
    *set splints -1
    *set splinted_knee true
    *set p_health %+(round((medicine)/4))
    *set knee_injured false
    You drag the splint out of your inventory and place it around the injured leg. Once set in place, you tighten it to keep your leg straight and provide needed support. You won't be able to bend your knee farther than a few degrees, but at least the ache subsides once you roll your pant leg back over it.
    *return
  *selectable_if (first_aid_charges > 0) #Use my first aid kit.
    *set p_health %+(round((medicine)/5))
    *set knee_injured false
    *set first_aid_charges -1
    You open the first aid kit and search through the items to find something of use. Among the many types of bandages, you find one specific for knees and elbows. Unraveling the bandage, you apply it to the joint and wrap it around in a tight pattern to keep the knee as straight as possible. You won't be able to bend your knee farther than a few degrees, but at least the ache subsides once you roll your pant leg over it.
    *return
  *selectable_if (bandages > 0) #Bandage my knee.
    *set knee_injured false
    You take
    *if bandages = 1
      *set p_health %+(round((medicine)/7.5))
      *set bandages -1
      your last bandage from your inventory. With only one, you won't be able to wrap your knee properly. 
    *if bandages > 1
      *set p_health %+(round((medicine)/5))
      *set bandages -2
      two bandages from your inventory, which should be enough to stabilize the joint.  
    Unraveling the bandage, you apply it to the joint and wrap it around in a tight pattern to keep the knee as straight as possible. You won't be able to bend your knee farther than a few degrees, but at least the ache subsides once you roll your pant leg back over it.
    *return
  #Leave my leg untreated for now.
    You roll your pant leg back up.
    *return

*label FixForearm
*set timecount +25
*set cut_arm false
*set p_health %+(round((medicine)/5))
You move into the kitchen, turn on the faucet, and rinse the wound on your forearm. Red edges of skin show, but luckily the cut doesn't run deep. The blood has already clotted, but rinsing your arm turns the water pink.
      
*if medicine >= 50
  *set stress %-(round(wil/5))
  Since the wound has stopped bleeding, it won't need to be closed or stitched.
  *if first_aid_charges > 0
    *set p_health %+(round((medicine)/5))
    *set first_aid_charges -1
    *set bandages -1
    You take out your first aid kit and spread antiseptic ointment over the cut. Next, you bandage the arm, wrapping it tight to keep pressure but loose enough to let the healing skin breathe.
  *if first_aid_charges = 0
    Without a first aid kit, your choices for tending the wound are limited. You rip some clothing and wrap it around the forearm to keep pressure but loose enough to let the healing skin breathe.
*if medicine < 50
  You're not sure how to treat the
  *if first_aid_charges > 0
    *set p_health %+(round((medicine)/7))
    *set first_aid_charges -1
    *set bandages -1
    wound, but you take out your first aid kit and spread antiseptic ointment over the cut. Next, you bandage the arm, wrapping it tight to keep pressure but loose enough to let the healing skin breathe.
  *if first_aid_charges = 0
    wound and have no first aid kit, so you resort to ripping some clothing and wrapping your forearm in order to protect it from further bumps or scrapes.
      
With your wound cleaned and wrapped, you 
*if pain_killers >= 2
  *set pain_killers -2
  *set stress %-(round(wil/5))
  take two tablets of pain-killers and 
walk back into the living room.
*return

*label GashRibs
*set timecount +25
*set injured_to_zombie false
*set p_health %+(round((medicine)/4))
You head into the first-floor bathroom, flip on the light, and take off your shirt. Now that you examine the gash, it's more of a deep scratch and luckily won't require stitches. The area has scabbed over, but dried yellowish crust surrounds the edges, and a red ring of swollen skin surrounds it.

You clean the wound with soap and water and gently dry it with a towel.
*if medicine >= 50
  *set stress %-(round(wil/5))
  *if first_aid_charges > 0
    *set bandages -1
    *set p_health %+(round((medicine)/5))
    *set first_aid_charges -1
    You take out your first aid kit and spread antiseptic ointment over the cut. Next, you place gauze over the injured skin and tape it down to keep it free from moisture or abrasion.
  *if first_aid_charges = 0
    Without a first aid kit, you have to improvise and use tissue paper as gauze in order to cover the cut. You fasten it with simple tape and hope it keeps the skin dry and free from further injury while it heals on its own.
*if medicine < 50
  You're not sure how to treat this injury, but luckily, the gash isn't serious.
  *set p_health %+(round((sta)/5))
  *if first_aid_charges > 0
    *set bandages -1
    *set p_health %+(round((medicine)/7))
    *set first_aid_charges -1
    You take out your first aid kit and spread antiseptic ointment over the cut. Next, you tape a bandage over the injured skin to keep it free from moisture and dirt while it heals.
  *if first_aid_charges = 0
    Having no first aid kit, you resort to taping tissue paper over the cut in order to protect it from further injury while it heals on its own.
With the cut cleaned and covered, you put your shirt back on and return to the living room.
*return

*label FredRoof
*set w_food +8
*set timecount +50
*set fatigue %+(round((100-sta)/5))
You contact Fred and ask for the supplies he offered. He suggests you meet him up on the rooftop, where he can pass the items to you without fear of attack.
*if dependent and dep_home
  ${dep_name} follows you upstairs.
*if pet_owner
  ${pet_name} walks right behind you, his nails tapping on the hardwood steps.
  
On the second floor, the back bedroom window leads out to a wide terrace.
*if fear_heights
  *set stress %+(round((100-wil)/3))
  As you glance out of the second-floor window, your head spins and heart rate races. The sidewalk below is a far way down, and you can't stand heights.
  *if wil >= 65
    You swallow hard and turn away from the window. These supplies will be very useful, and you can't pass them up. Looking back outside, you convince yourself to go through with this plan and never, ever look down.
  *if wil < 65
    When you think about being on the roof, your body shakes and pulse quickens ever further. There's no way you can go through with this plan.
    
    You call up Fred and tell him you're not coming out for the supplies.
    
    "No problem," he says in an exasperated tone. "Maybe on my way out tomorrow, I'll drop them off."
    
    "Thanks, Fred."
    
    With that, you hang up and head downstairs.
    *return
You climb from that short landing to the side of the roof.
*if night_blindness and (timecount >= 2000)
  The sky is dark, and you can barely see through the inky darkness. You can't help but feel anxious at the thought of moving outside without clear sight.
  *if w_flashlight = 0
    Without the ability to see at night, you can't meet Fred.
    
    You return to the bedroom, head downstairs, and call him to give him the bad news. He suggests meeting him early the next morning.
    *return
  *if w_flashlight > 0
    *set stress %+(round((100-wil)/2))
    Flipping on your flashlight, the top of the house illuminates, but it only helps to calm your concern.
*if dependent and dep_home

  "Where are you going?" ${dep_name} asks and starts out onto the terrace.
  
  "Stay there. I'll be right back," you say, closing the window behind you.
*set met_fred_roof true
      
The crisp air swirls around the rooftops, and heavy clouds coat the 
*if timecount >= 2000
  the night sky.
*if timecount < 2000
  sky in grays and silvers. 
Somewhere in the distance, a howl cuts the quiet and fades in a moment.
      
"Hey there," Fred says, his squat, rotund body jiggling across the flat roof. He carries a duffel bag in one hand and a plastic bag in the other. "How you doing? Good to see you."
      
*if morality >= 60
  "Doing fine. Thanks so much for giving me these supplies."
        
  "My pleasure."
*if morality < 60
  "Fine. I can't believe the city is quarantined."
        
  "This is some biblical stuff going on."
      
Four feet separate the two rooftops, with a slim alley bridging the gap. Fred lifts the plastic bag first and flings it across the short divide. You catch the bag, which holds several cans of food and several bunches of fresh fruit. Fred then hoists the duffel bag and grunts as he moves it to the edge of the roof. He steps back a few feet, spins his body to the side, runs, and flings the large sack up and over the four-foot gap.
*if search >= 55
  You spot his mistake too far into his throw, when his feet plant too close together to provide balance.
As it leaves his hands, the duffel bag twists in the air and Fred's body falls sideways. The bag hits the edge of the building and flops down into the alley. Fred teeters on the roof's edge. You stand on the opposite roof, helpless to react. Your neighbor leans back, then somehow drops to his knees and grabs a cement block jutting from the rooftop. He rolls onto his back safely.
*if short_fuse

  *if wil >= 65
    *set stress %+(round((100-wil)/5))
    Angered at his mistake, you fight back the urge to yell at the man. He's only trying to help, and while you continue to remind yourself of that fact, your hands shake and breathing goes erratic. How could he be so stupid?
  *if wil < 65
    *set stress %+(round((100-wil)/5))
    *set fred_faction %-(round(30-(empathy/5)))
    "Damn it, Fred!" you yell at the top of your lungs. "How could you be so stupid? Now look what happened."
    
    "S—sorry," he says, clearly frazzled. "Don't have to yell at me though. Just trying to do you a favor."
    
    Your hands shake, and all you see is red. Angered at his mistake, you fight back the urge to yell at the man any more. Keeping him as a friend will aid you in the long run.
*achieve strangerhelp

You swallow hard and take a deep breath before collecting the few tools and supplies left in the bag. Fred wishes you luck with the food and says to call him anytime.
*return

*label CallFredsMom
*set timecount +50
*set morality %+10
*set fred_faction %+(round(5+(empathy/5)))
*set asked_contact_freds_mom false
You turn on the CB radio and tune the frequency dial to various channels usually used by truck drivers. 
*if jaime_called
  As you noticed before, most 
*if not(jaime_called)
  Most
channels are filled with chatter by people using it to discuss the outbreak, request help, or find out information.
*if hearing_impaired
  *set stress %+(round((100-wil)/5))
  The static crackles through your hearing aid, and you can barely make out the voices. You're forced to remove the aids from both ears before you can distinguish the sounds.
You search the airwaves for keywords related to the Santa Fe area or truckers who work for K-Mart. After twenty minutes, you come across a frequency with only a few people discussing the highways of New Mexico, and you take your shot and ask if anyone knows Delroy, Fred's uncle.
      
"This is Delroy. Who's this?" he says, voice loud and crackling over the radio.
      
"This is ${name}. I'm a neighbor to your nephew, Fred. He's trying to reach his mother."
      
"She's here. Hold on," Delroy says. You hear him yelling in the background, which becomes static when he clicks off his microphone. Minutes pass. The chatter picks up on the line. More time passes, leading you to wonder if it's really Delroy or whether something might have happened, that Fred's mother isn't coming. After a full ten minutes, you hear a burst of static and the voice of an older woman over the airwaves.
      
"Just hit the button? I am hittin' the button. Oh, I can talk? This is Fred's momma."
      
"Hello, Mrs. Tate. My name is ${firstname}. I'm a friend of your son."
      
"Who? I can barely hear through this radio," she yells.
      
"Fred's friend, ${firstname}."
      
"What happened to Fred?"

*if tried_calling_fred_day2
  "I spoke to him yesterday, and he was fine,"
*if not(tried_calling_fred_day2)
  "He's fine," 
you say, trying to speak in a clear, crisp voice.
      
"He's DYING? Oh, lord!"
      
"No, I said he's fine. F-I-N-E." You spell out each letter in the hopes the old woman understands.

"Gimme the microphone, Thelma," Delroy says, and you hear muffled arguing before he returns. "Sorry about that. She can't hear too good. I'll talk for her. Go ahead with your message."

You let him know that
*if not(tried_calling_fred_day2)
  Fred is alive and well, secure at home as we wait out the quarantine. 
*if tried_calling_fred_day2
  *if not(went_to_freds)
    you spoke to Fred yesterday, and he's alive and well, but he didn't answer the phone today. Delroy asks if you can check on him later.
  *if went_to_freds
    Fred is alive and well and has left his home to travel to his mother's house.
Delroy assures you that all is fine in Santa Fe, they have over a week's worth of food and water, and their ranch home is locked up tighter than an "armadillo's back." The National Guard has moved into the area, and nearby Albuquerque has been hit hard by the outbreak, requiring early evacuations. Delroy thanks you for contacting Thelma and putting her mind at ease, as she's worried about her son.
*if not(tried_calling_fred_day2)
  After saying goodbye to Delroy, you call Fred's house 
  *if chapter_point = 1
    and share the good news about reaching his mother and that she's doing well. You can tell this act has solidified your relationship with Fred, and he'd be willing to do anything to repay your kindness.
    *if not(fred_offered_resources)
      *set fred_offered_resources true
      In fact, he offers to give you food and tools should you need them and requests you call him should you want the supplies.
    *return
  *else
    *set tried_calling_fred_day2 true
    to share the good news about reaching his mother. The line rings six times before voicemail kicks in. The message says to leave a message or call Fred's shop.
      
    You hang up and try the number to the shop, and when no one answers, you call the house again, all with the same result. Is he still alive? Did he abandon his home, or was he forced out? What if he's hurt and needs help? Since he's your neighbor, you could walk over and check on him, but every action has risks in the apocalypse.
    *return
*else
  You end the transmission and sit back in your chair, wondering if Fred will be able to make it to his mother's house.
  *return

*label CheckAddictions
*set add_count +1
*if add_count = 1
  *if add_alc

    *if alcohol = 0
      *set stress %+(round((100-wil)/3))
      Out of instinct, you reach for your flask but realize you've run out of alcohol. Your hands shake and mouth feels dry. Detoxing during such a stressful time won't be easy.
    *if alcohol >= 1  
      *set alcohol -1
      You take out a bottle of alcohol, take a long sip, and for at least a moment, feel your stress slip away.
      *if dep_join and (dep_add_comment = false)
        *set dep_add_comment true
        
        "You're drinking?" ${dep_name} says in a disappointed tone. "Won't it make you all silly if you drink too much?"
            
        *if short_fuse
          *set dep_faction %-(round(25-(empathy/5)))
          "Mind your damn business," you blurt out. Your nephew steps away, and you can feel the weight of his anger toward you. You don't want to yell at the kid, but you
          *if morality >= 50
            can't control your temper in the heat of the moment.
          *if morality < 50
            wish he wouldn't open his mouth and criticize your actions.
        *if not(short_fuse)
          "Nah, it just helps me to relax. I'll be fine."
              
          You take another sip and follow it with a hearty burp, and your nephew doubles over with laughter.
  *if add_nic
        
    *if w_cigarettes = 0
      *set stress %+(round((100-wil)/3))
      You check your pockets for a cigarette but must have run out. You'll need to find some again soon, or it's going to make surviving in this new world even tougher.
    *if w_cigarettes >= 1
      *set w_cigarettes -1
      You light up a cigarette, feeling your stress melt away as you puff on it.
      *if dep_join and (dep_add_comment = false)
        *set dep_add_comment true
      
        "You're smoking?" ${dep_name} says in a disappointed tone. "Cigarettes are bad for you. They make your insides black."
            
        *if short_fuse
          *set dep_faction %-(round(25-(empathy/5)))
          "Mind your damn business," you blurt out. Your nephew steps away and lags behind, and you can feel the weight of his anger toward you. You don't want to yell at the kid, but you
          *if morality >= 50
            can't control your temper in the heat of the moment.
          *if morality < 50
            wish he wouldn't open his mouth and criticize your actions.
        *if not(short_fuse)
          "Nah, it just helps me to relax. I'll be fine."
        
        You take another drag and follow it with a hearty cough, and your nephew raises his eyebrows as if to say "told you so."
*if add_count >= 2
  *if add_alc

    *if alcohol = 0
      *set stress %+(round((100-wil)/3))
      You tap your fingers against your empty flask. Finding something to fill it is a high priority.
    *if alcohol >= 1
      *set alcohol -1
      You unscrew your flask and take a long drink, feeling the liquid chase your stress away.
  *if add_nic
    *if w_cigarettes = 0
      *set stress %+(round((100-wil)/3))
      You really wish you had a cigarette right now.
    *if w_cigarettes >= 1
      *set w_cigarettes -1
      You pop a cigarette into your mouth and light the tip. Smoke blows around you, carrying a bit of stress away with it.
*return

*label ReinforceHome
*choice
  *if not(metal_doors)
    *selectable_if ((metal_parts >= 3) and (crafting >= 60)) #Cover the doors and windows with metal. (requires crafting 60+ and 3 metal parts)
      *set metal_doors true
      *set timecount +75
      *set home_defense +1
      *set max_defense +1
      *set metal_parts -3
      *set fatigue %+(round((100-sta)/2.5))
      Knowing the windows and doors are easy points for break-in, you decide to reinforce them with the strongest material available. Sheets of metal and bars are not in huge supply, but you use what's available. You line the doorframe with the metal and use hot glue to fasten them together. For the windows, you repeat the process but leave gaps for air ventilation and as viewing ports to the outside.
    
      The endeavor takes forty-five minutes, and you hope the glue dries in time for its first test, whenever that may come.
      *return
  *if metal_doors
    *selectable_if (((metal_parts >= 7) and (crafting >= 65)) and (not(heavy_reinforce))) #Reinforce the doors and windows. (requires crafting 65+ and 7 metal parts)
      *set heavy_reinforce true
      *set timecount +100
      *set home_defense +2
      *set max_defense +2
      *set metal_parts -7
      *set fatigue %+(round((100-sta)/2.5))
      Having enough metal to reinforce the doors and windows, you take the available parts and start with the door, fastening them onto the boards and around the seams. You do the same to the windows to strengthen any weak points and keep them from opening from the outside.
      
      After an hour, you review your work and feel confident no one will be breaking in without considerable difficulty and heavy tools.
      *return
  *if not(alarm_system)
    *selectable_if (crafting >= 45) #Set up alarms on the doors and windows to alert you of intruders. (requires crafting 45+)
      *set alarm_system true
      *set timecount +50
      *set fatigue %+(round((100-sta)/5))
      With the number of entry points to the house, you can't monitor them all. Having an early warning system will provide extra time to deal with intruders.
    
      You gather lengths of string and hang them along the windows and the frame of the door. To the strings, you tie some small bells you found in storage, along with empty tin cans. You tie them so they won't ring in a breeze, but if someone tampers with the doors or windows, you'll hear it.
      *return
  *if trap_door = false
    *selectable_if ((metal_parts >= 1) and ((wood_parts >= 2) and (crafting >= 55))) #Place a trap on the front door to injure intruders. (requires crafting 55+, 1 metal part, and 2 wooden parts)
      *set trap_door true
      *set timecount +50
      *set fatigue %+(round((100-sta)/5))
      *set wood_parts -2
      *set metal_parts -1
      Securing the main door is a top priority, so you set out to place a trap should an intruder force entry inside. Using several planks of wood and nails, you rig a simple swing trap. You anchor one end of the board at the wall near the door and bend it away. Using a clothesline, you tie the board and loop the other end to the doorknob, so if the door pops open, the line will go loose, and the barbed edge of the board will swing at the intruder.
      *return
  *if not(secure_perimeter)
    *selectable_if ((metal_parts >= 3) and (crafting >= 45)) #Secure the perimeter. (requires crafting 45+ and 3 metal parts)
      *set secure_perimeter true
      *set home_defense +1
      *set max_defense +1
      *set metal_parts -3
      *set fatigue %+(round((100-sta)/2.5))
      *if crafting >= 65
        *set timecount +50
      *if crafting < 65
        *set timecount +75
      The perimeter of your house is vastly unsecured, and you'd rather deter intruders from as far away as possible. Sneaking out of your house causes some concern, 
      *if stealth >= 45
        but your stealth abilities allow you to move with speed and silence.
      *if stealth < 45
        since the infected may be lurking, but you plan to move fast.
      First, you bar the windows and doors from the outside with tape and hot glue you found in the basement. Next, you
      *if v_loc = "city"
        break some bottles and glue the broken shards of glass onto the outside windowsills and the top of the yard wall as makeshift barbed wire. Next, you glue nail heads onto the sidewalk and steps outside your home, leaving only a small walkway for travel. The infected will not be hampered for long by these traps, but non-infected intruders won't like them.
      *if (v_loc = "suburbs") or (v_loc = "country")
        break some bottles and glue the broken shards of glass onto the outside windowsills and the top of the yard fence as makeshift barbed wire. Next, you glue nail heads onto the path leading to your home, leaving only a small walkway for travel. The infected will not be hampered for long by these traps, but non-infected intruders won't like them.
        *if (shovel > 0) and (v_loc != "city")
          *set home_defense +1
          *set max_defense +1
          *set dug_trench true
          *set timecount +50
          In addition, you dig deep trenches around the perimeter in common areas where people might be walking, in the hope that they'll slow any movement across your property. While easily avoided by the non-infected, these trenches might impede the creatures, who seem unaware and clumsy.
      *return
  *if not(setup_cameras)
    *selectable_if (((crafting >= 50) and (electronics >= 60)) and house_powered) #Set up a camera feed to monitor the house. (requires crafting 50+ and electronics 60+)
      *set setup_cameras true
      *set timecount +75
      *set fatigue %+(round((100-sta)/5))
      Having so much room in this house to monitor, as well as the area just outside, you plan out a camera system for viewing several key locations at once. Taking webcams from an old computer and your laptop, as well as the cameras from your two tablets, you rig them just outside two windows on the second floor, the kitchen window, and the highest point of the window in the living room. You hardwire them with networking cables, since Wi-Fi will become unreliable as time goes on. You set up your laptop to receive the live feeds.
      *return
  *if not(surround_barbed_wire)
    *selectable_if ((crafting >= 60) and (barbed_wire > 0)) #Surround my property with barbed wire. (requires crafting 60+ and barbed wire)
      *set surround_barbed_wire true
      *set timecount +75
      *set fatigue %+(round((100-sta)/5))
      *set barbed_wire -1
      *set home_defense +1
      *set max_defense +1
      Placing barbed wire around the perimeter should keep out looters and deter intruders. With great care, you uncoil the wire and secure it to the outside of your home, focusing on points of entry and windows. You ensure that it doesn't impede your entry and escape should you need it.
      *return
  #On second thought, I don't set up any other reinforcements at this time.
    *return
    
*label CountReinforce
*set reinforce_options 0
*if (((metal_parts >= 7) and (crafting >= 65)) and (not(heavy_reinforce)))
  *set reinforce_options +1
*if ((metal_parts >= 3) and (crafting >= 60)) and (not(metal_doors))
  *set reinforce_options +1
*if ((crafting >= 45) and (not(alarm_system)))
  *set reinforce_options +1
*if ((metal_parts >= 3) and (crafting >= 45)) and (not(secure_perimeter))
  *set reinforce_options +1
*if ((metal_parts >= 1) and (wood_parts >= 2)) and ((crafting >= 55) and (not(trap_door)))
  *set reinforce_options +1
*if ((crafting >= 50) and ((electronics >= 60) and (not(setup_cameras))))
  *set reinforce_options +1
*if ((crafting >= 60) and (surround_barbed_wire = false)) and (barbed_wire > 0)
  *set reinforce_options +1
*return

*label BoardHome
*set home_boarded true
You survey the house.
*if home_damage = 0
  Everything is in good shape so far, with nothing broken and all intact and able to withstand light damage or force.
*if (home_damage > 0) and (home_damage <= 2)
  The door has a large hole near the lock, and one of the living-room windows contains a hairline crack.
*if (home_damage > 2) and (home_damage <= 4)
  The door has a large crack down the center, and a stiff wind could bring it down. Several downstairs windows are broken, allowing the cold air to circulate.
*if home_damage > 4
  The door holds on by one hinge; anything could push it open now. Most of the downstairs windows are broken, letting cold air circulate inside.
*if house_attacked_zombies and (home_damage > 0)
  It certainly won't stop a zombie attack.

*if supplies_gathered
  You locate tools, wood, and nails from the gathered supplies and set out to
*if not(supplies_gathered)
  *set timecount +25
  *set hammer +1
  *set wood_parts 10
  *set metal_parts 4
  You collect tools, wood, and nails from the basement and set out to
*if home_damage = 0
  secure the home as fast as possible given the imminent dangers lurking outside.
*if home_damage > 0
  repair the damage already done to the house.
*if (crafting_tools > 0) and retrieved_freds_bag
  In addition, you bring over the tools that Fred gave you.

*if crafting >= 60
  Your vast crafting knowledge comes in handy in such situations, and your tool chest is invaluable in this case.
  *if home_damage = 0
    *set timecount +50
    *set home_defense 4
    *set fatigue %+(round((100-sta)/3))
    First, you cover the door with the thickest boards you can find and reinforce them with 2x4s a few feet apart, using bolts and screws with wood glue to adhere the surfaces. You fasten boards over the windows as well, anchoring them to the wall with a masonry bit and wood screws. The creatures appear to have superior strength, or at least are determined enough to fight through a boarded window, so you use duct tape to seal any gaps, which also helps keep out the cold air. Since you've blocked so much visibility to the outside, you cut out small viewing ports in several windows. These provide a line of sight to various points outside.
    
    The whole process takes just half an hour, thanks to your tools and know-how.
    *return
  *elseif home_damage = 1
    *set timecount +75
    *set home_damage 0
    *set home_defense 3
    *set fatigue %+(round((100-sta)/2.5))
    First, you cover the hole in the door with plywood. Next, you lay thick boards over the door and reinforce them with 2x4s a few feet apart, using bolts and screws with wood glue to adhere the surfaces. You fasten boards over the windows as well, anchoring them to the wall with a masonry bit and wood screws. The creatures appear to have superior strength, or at least are determined enough to fight through a boarded window, so you use duct tape to seal any gaps, which also helps with keeping out the cold air.
    
    The whole process takes just forty-five minutes, thanks to your tools and know-how.
    *return
  *elseif home_damage = 2
    *set fatigue %+(round((100-sta)/2))
    *set timecount +100
    *set home_damage 0
    *set home_defense 2
    First, you repair the front door by covering it with plywood boards and reinforcing them with 2x4s a few feet apart, using bolts and screws with wood glue to adhere the surfaces. You fasten boards over the windows as well, anchoring them to the wall with a masonry bit and wood screws.
    
    The whole process takes only an hour, thanks to your tools and know-how.
    *return
  *else
    *set timecount +125
    *set home_damage 0
    *set home_defense 1
    *set fatigue %+(round((100-sta)/2))
    First, you repair the hinges to the door as best you can given the limited resources. Next, you cover the front door with plywood boards and reinforce them with 2x4s a few feet apart, using bolts and screws with wood glue to adhere the surfaces. You fasten boards over the windows as well, anchoring them to the wall with a masonry bit and wood screws.
    
    The whole process takes an hour and fifteen minutes. It would have taken much longer without your tools and know-how.
    *return
*elseif crafting >= 45
  You have a fair understanding of carpentry and home repair, and you know that now is the time to put your knowledge to the test.
  *if home_damage = 0
    *set timecount +75
    *set home_defense 3
    *set fatigue %+(round((100-sta)/2.5))
    First, you cover the door with the thickest boards you can find and reinforce them with 2x4s a few feet apart using bolts and screws. You fasten boards over the windows as well, anchoring them to the wall with a masonry bit and wood screws.
    
    The whole process takes just forty-five minutes, thanks to your tools and know-how.
    *return
  *elseif home_damage = 1
    *set timecount +100
    *set home_damage 0
    *set home_defense 2
    *set fatigue %+(round((100-sta)/2))
    First, you cover the hole in the door with plywood. Next, you lay thick boards over the door and reinforce them with 2x4s a few feet apart, using bolts and screws with wood glue to adhere the surfaces. You screw boards over the windows as well, anchoring them to the wall with a masonry bit and wood screws.
    
    The whole process takes only an hour, thanks to your tools and know-how.
    *return
  *elseif home_damage = 2
    *set home_damage 0
    *set home_defense 1
    *set timecount +125
    *set fatigue %+(round((100-sta)/2))
    First, you repair the front door by covering it with plywood boards and reinforcing them with 2x4s a few feet apart. You fasten boards over the windows as well, anchoring them to the wall with a masonry bit and wood screws.
    
    The whole process takes an hour and fifteen minutes, thanks to your tools and know-how.
    *return
  *else
    *set home_damage 1
    *set timecount +150
    *set fatigue %+(round((100-sta)/1.5))
    First, you repair the hinges to the door as best you can given the limited resources. Next, you cover the front door with plywood boards. You fasten boards over the windows as well, anchoring them to the wall with a masonry bit and wood screws. The damage to the home isn't completely repaired, but it'll be more difficult for anyone to break in.
    
    The whole process takes an hour and a half.
    *return
*else
  Crafting and home repair are not your strongest skills, but you do your best given your limited knowledge and resources.
  *if home_damage = 0
    *set home_defense 2
    *set timecount +125
    *set fatigue %+(round((100-sta)/2))
    First, you cover the door with the thickest boards you can find and nail 2x4s a few feet apart as reinforcement. You fasten boards over the windows, as well. The creatures appear to have superior strength, or at least are determined enough to fight through a boarded window, so you use duct tape to seal any gaps, which also helps with keeping out the cold air.
    
    The whole process takes an hour and fifteen minutes of hard labor.
    *return
  *elseif home_damage = 1
    *set timecount +150
    *set home_damage 0
    *set home_defense 1
    *set fatigue %+(round((100-sta)/1.5))
    First, you cover the hole in the door with plywood in order to repair the existing damage. Next, you reinforce the door by nailing thick boards across the surface and nailing them to the existing drywall. You screw boards over the windows, as well.
    
    The whole process takes an hour and a half of hard labor.
    *return
  *elseif home_damage = 2
    *set home_damage 1
    *set timecount +150
    *set fatigue %+(round((100-sta)/1.5))
    First, you repair the front door by covering it with plywood boards and reinforcing them with 2x4s a few feet apart. You fasten boards over the windows to stop easy access and block the cold air. The damage to the home isn't completely repaired, but it'll be more difficult for anyone to break in.
    
    The whole process takes an hour and a half of hard labor.
    *return
  *else
    *set home_damage 2
    *set timecount +175
    *set fatigue %+(round((100-sta)/1.5))
    First, you repair the hinges to the door as best you can given the limited resources. Next, you cover the front door with plywood boards. You fasten boards over the windows as well, nailing them to the drywall. The damage to the home isn't completely repaired, but it'll be more difficult for anyone to break in.
    
    The whole process takes an hour and forty five minutes of hard labor.
    *return
    
*label CheckGear
*set timecount +25
*set check_gear_count +1
You walk over to your pile of gear and check your inventory. You have the following items: ${inventory}.
    
[b]Primary Weapon[/b]: ${p_weapon}
*line_break
[b]Secondary Weapon[/b]: ${s_weapon}
*line_break
[b]Armor[/b]: ${armor}
*choice
  *allow_reuse #I reconsider my primary and secondary weapons.
    *gosub_scene LoadWeapons
    You select a new main weapon…
    *set p_weapon ""
    *set temp_weapon "p_weapon"
    *set temp_mod "p_mod"
    *set temp_weaponmode "p_weaponmode"
    *set temp_range "p_range"
    *set temp_class "p_class"
    *set temp_type "p_type"
    *set temp_ammo "p_ammo"
    *set temp_arrow "p_arrow"
    *set temp_lethal "p_lethal"
    *set temp_ammo_num "p_ammo_num"
    *gosub_scene WeaponSelect
    And a backup weapon…
    *set temp_weapon "s_weapon"
    *set temp_mod "s_mod"
    *set temp_class "s_class"
    *set temp_weaponmode "s_weaponmode"
    *set temp_range "s_range"
    *set temp_type "s_type"
    *set temp_ammo "s_ammo"
    *set temp_arrow "s_arrow"
    *set temp_lethal "s_lethal"
    *set temp_ammo_num "s_ammo_num"
    *gosub_scene WeaponSelect
    *gosub CheckAttachments
    *return
  *if wearing_armor
    #I take off my armor.
      *set armor "none"
      *set wearing_armor false
      You remove all of your armor.
      *return 
  *if have_armor and (wearing_armor = false)
    #I put on armor.
      *set wearing_armor true
      You put on…
      *fake_choice
        *if football_pads > 0
          #Football pads.
            *set armor "Football pads"
            You put on the ${armor} and feel more protected from the dangers of the apocalypse.
        *if leather_armors > 0
          #Leather armor.
            *set armor "Leather armor"
            You put on the ${armor} and feel more protected from the dangers of the apocalypse.
        *if kevlar_vests > 0
          #Kevlar vest.
            *set armor "Kevlar vest"
            You put on the ${armor} and feel more protected from the dangers of the apocalypse.
        *if tactical_vests > 0
          #Tactical vest.
            *set armor "Tactical vest"
            You put on the ${armor} and feel more protected from the dangers of the apocalypse.
        #No armor for now.
          *set armor "none"
          You leave off any additional body armor.
      *return
  *if wearing_helmet
    #I take off my helmet.
      *set helmet "none"
      *set wearing_helmet false
      You remove your helmet.
      *return
  *if have_helmet and (wearing_helmet = false)
    #I put on a helmet.
      *set wearing_helmet true
      You put on…
      *fake_choice
        *if combat_helmets > 0
          #Combat helmet.
            *set helmet "combat helmet"
            You put on the ${helmet} and feel more protected from the dangers of the apocalypse.
        *if football_helmets > 0
          #Football helmet.
            *set helmet "football helmet"
            You put on the ${helmet} and feel more protected from the dangers of the apocalypse.
        #No helmet for now.
          *set helmet "none"
          You don't put on a helmet.
      *return
  *allow_reuse #I am finished with checking my gear.
    *return

*label Bathtubwater
*set filled_bathtub false
*set w_water +15
*set timecount +25
You head upstairs to the bathroom with every empty bottle and plastic container you have in the house. By filling the tub beforehand, you'll have a decent supply of water in reserve. You turn on the faucet, and though the water still flows, it just dribbles out. You doubt the tub or any sink will provide water for much longer, but you fill up every container you can. From sitting in the tub, some dirt and dust lies on the surface, forcing you to strain the water or let some of it go down the drain. At the end of the task, you have twenty more bottles of water than before.
      
You leave the bathroom with your new supply of filled bottles and return to the living room.
*return

*label Cleanwater
*set timecount +50
*set unclean_water false
You head into the kitchen and check the jug of water your nephew collected. Now that the snow has melted, a thin layer of debris lies on top of it, and you spend a few minutes passing the water to a strainer to remove large particles. The water's still cloudy and requires disinfecting to become drinkable.
*if water_purify > 0
  You remember the pack of water-purifying tablets in your inventory and wonder if it's a good time to use them. Boiling the water will evaporate some of it, meaning some will be lost. Using the tablets will neutralize the contaminants and yield more water.
  *choice
    #I use a pack of water-purifying tablets.
      *set water_purify -1
      *set w_water +15
      You pour the water from the jug into a clean, empty pot. Next, you read the instructions on the pack of tablets. It suggests using one tablet per liter of unclean water to remove all contaminants. You estimate the jug contains two gallons of water, which should fill fifteen bottles. To be on the safe side, you drop all of the tablets into the pot and stir the water with a long wooden spoon. The instructions tell you to wait thirty minutes for the water to disinfect, so you plan to check on it later and funnel the water into individual bottles. 
      *return
    #I boil the water and conserve the tablets.
      *goto Boilwater
*else
  *label Boilwater
  *set w_water +12
  You set a large pot on the gas stove and pour the cloudy water into it. You turn on the stove and let the water come to a rolling boil for a full minute. Since the water needs to cool for a while, you plan to check on it later and funnel it into individual bottles. You estimate the process made twelve bottles.
  *return

*label AcquireVehicle
*temp temp_vehicle ""
*set timecount +50
*if acquired_first_vehicle
  You can never have too many vehicles, so you head outside to find a new one.
*if not(acquired_first_vehicle)
  *set acquired_first_vehicle true
  With so many abandoned vehicles outside, finding one suitable to your needs should be an easy task.
  *if dep_join or pet_join

    As you step to the front door to leave,
    *if dependent and pet_owner
      both ${dep_name} and ${pet_name} move beside you. 
      *if pet_join  
        ${pet_name} 
        *if cat_owner
          slinks along the wall, ready to dart outside once the door opens.
        *if dog_owner 
          scratches at the base of the door.
        You guide him to the middle of the living room.
    *if (dep_join = false) and pet_join
      ${pet_name} moves beside you and
      *if cat_owner
        slinks along the wall, ready to dart outside once the door opens.
      *if dog_owner 
        scratches at the base of the door.
      You guide him to the middle of the living room.
    *if dep_join and (pet_join = false)
      ${dep_name} moves beside you.
  *if dependent

    "Where are we going?" your nephew says, so fast it sounds like one word.
  
    "I'm just going to find a car or some vehicle to use. I won't be far.
    *if dep_treat >= 65
      Can you wait here for me, please? It won't take long."
    
      "Sure," your nephew says with an upbeat tone.
    *if (dep_treat > 35) and (dep_treat < 65)
      Wait here for me. Okay?"
    
      "Sure," your nephew says in a flat tone.
    *if dep_treat <= 35
      You're staying here. You'll just get in my way."
    
      "Whatever," your nephew says in a flat tone.

You step outside and look through the area around your home.
*if not(searched_for_car)
  *set searched_for_car true
  *if v_loc = "city"
    Numerous cars are parallel-parked on the street just outside your house and the avenues connected to your street. 
  *if v_loc = "suburbs"
    Numerous cars are parallel-parked on the street just outside your house, and many more sit in driveways and on the road leading out of your development.
  *if v_loc = "country"
    Being in the country, the concept of a 'vehicle' extends beyond just cars, and a quick walk through the neighborhood uncovers numerous options.
After a quick tour of the vehicles available, you inspect the…
*label PickCar
*fake_choice
  *if ((v_loc = "suburbs") or (v_loc = "city")) and (luxury_car = false)
    #Four-door luxury car.
      *set temp_vehicle "luxury_car"
      *set new_car "luxury car"
      You examine the car's sleek exterior and expensive interior, knowing it will provide a smooth ride while still providing moderate durability (important in the apocalypse). Plus, the car provides built-in GPS navigation and other useful features, if they still work.
  #Four-door sedan.
    *set temp_vehicle "sedan"
    *set new_car "sedan"
    A rather average car, the sedan offers good maneuverability while being durable and providing space for numerous passengers.
  *if motorcycle = false
    #Motorcycle.
      *set temp_vehicle "motorcycle"
      *set new_car "motorcycle"
      The motorcycle is the most maneuverable of any readily available vehicle in the area. The main drawbacks are that it makes a lot of noise, which attracts attention, and offers little protection and durability.
  *if ((v_loc = "suburbs") or (v_loc = "country")) and (pickup_truck = false)
    #Pickup truck.
      *set temp_vehicle "pickup_truck"
      *set new_car "pickup truck"
      You run your hand along the truck's exterior and feel confident this beast is built to last. The solid exterior can take a hit, and the flatbed can haul supplies or provide space for extra passengers. 
  *if (v_loc = "city") and (taxi_cab = false)
    #Taxi cab.
      *set temp_vehicle "taxi_cab"
      *set new_car "taxi"
      The taxi cab may not be the most attractive vehicle, but it's reliable and maneuverable through the crowded city streets.
  *if (v_loc = "country") and (tractor = false)
    #Tractor.
      *set temp_vehicle "tractor"
      *set new_car "tractor"
      An unconventional vehicle, the tractor's large metal frame will dominate other vehicles on the road and provide protection if attacked. It's not easy to drive and won't break speed records or navigate an obstacle course with finesse.
  #Two-door coupe.
    *set temp_vehicle "coupe"
    *set new_car "coupe"
    A common car on the road, coupes blend in, take up little space, and provide good maneuverability with low maintenance needs.
    
Do you choose the ${new_car}?
*choice
  #Yes, I take the ${new_car}.
    *set {temp_vehicle} true
    *set vehicle_num +1
    *set vehicle new_car
    Having settled on the ${new_car}, you 
    *if (search >= 60) or (scavenging >= 46)
      search the area and luckily find the keys tucked into the wheel well.
      *return
    *elseif (crafting >= 49) and ((mechanical_tools > 0) or (crafting_tools > 0))
      use your tools to jimmy the lock and hotwire the vehicle.
      *return
    *elseif (mechanical_tools > 0) or (crafting_tools > 0)
      *set vehicle_health %-10
      use your tools to 
      *if new_car != "motorcycle"
        break the lock and 
      hotwire the vehicle. Unfortunately, you did some damage to the 
      *if new_car != "motorcycle"
        door and 
      steering column, but at least you can drive it.
      *return
    *elseif motorcycle
      *set vehicle_health %-10
      hop onto the seat and search for a way to start it up. Of course, the previous owner didn't leave the keys around, so you're forced to break the ignition switch in order to start it.
      *return
    *else
      *set vehicle_health %-20
      break into the car, bust the ignition switch, and hotwire it. Unfortunately, you did some damage to the door and steering column, but at least you can drive it.
      *return
  #No, I'd rather choose another.
    Instead, you look at the…
    *goto PickCar

*label DancingPractice
*set dancing_times +1
*set fatigue %+(round((100-sta)/3))
*set stress %-(round(wil/3))
*set timecount +100
*if dependent or ((woody_introduced) or (jillian_join))
  You head into your bedroom and close the door for a bit of privacy.
*if (dependent = false) and ((woody_introduced = false) and (jillian_join = false))
  You clear an area in the middle of the living room to make space.
*if dancing_times = 1
  With your phone still charged, you flip through your music collection and turn on random play. A song comes on—[i]Dance Until the End[/i]—and you do just that. For the length of the song, you dance. And when that song ends, the next one plays, and the next, and the next. The words and rhythm don't matter. The music consumes all, blotting out all other sounds, all feelings, and any thought of the world outside.
  
  You collapse to the ground, out of breath and disoriented. The clock on the phone tells you an hour has passed. Your body feels tired but renewed, and your mind is as clear as it has been in days.
*if dancing_times = 2
  *if chapter_point = 2
    *if v_loc = "suburbs"
      With power in the area fading in and out, your solar panels may supply enough electricity. To conserve,
    *if v_loc != "suburbs"
      With the electricity fading in and out, 
  *if chapter_point = 3
    *if house_powered or (v_loc = "suburbs")
      With power in the area fading in and out, your solar panels may supply enough electricity. To conserve,
    *if (house_powered = false) and (v_loc != "suburbs")
      With the electricity fading in and out, 
  you don't want to use your phone for music, and you don't even need it. A tune plays in your head, one you haven't heard in a long time, so long you don't remember the lyrics. The beat plays over and over, and before long, your body sways until you're dancing from wall to wall. Time passes as your movements fill the room, and by the time you realize an hour has gone by, you're sweaty and tired. The beat is gone, lost in the madness of your dancing, and whether or not you'll ever remember it again doesn't matter. It did its job.
*if dancing_times = 3
  Before long, your mind is playing a beat over and over, and your legs shift from side to side to the rhythm. It picks up—the beat—and as it flows, it grows and swells, taking over your arms and legs, your head, your spine. The music is all you hear, and you lose all sense of time and place, and the apocalypse melts into the background, out there, somewhere else, far away. When the music ends, you stand in the middle of the room, drawing in deep breaths. Sweat drips into your eyes and your muscles ache, but you feel less stressed.
*return

*label RunningPractice
*set running_times +1
*if night_blindness and (timecount >= 2000)
  Running will surely reduce your stress and provide a bit of exercise. You glance outside to see if the area is clear for your departure from home, but you can barely see through the darkness. There's no way you can run at night, so you'll need to wait until morning.
  *return
*if (woody_introduced and woody_home) and first_woody
  *set first_woody false
  As you step to the door to go for a run, you glance at Woody sitting on the couch. Should you leave him alone in the house? Though he's Jaime's cousin, can you trust him
  *if jillian_join and dependent
    in the house with your nephew?
  *if (jillian_join = false) and dependent
    alone with ${dep_name}?
  *if jillian_join and (dependent = false)
    in the house while you're gone?
  *if (jillian_join = false) and (dependent = false)
    alone?
  *if jillian_join
    Jillian is upstairs, but
    *if morality >= 60
      you don't want to bother her considering all she's been through today.
    *if (morality < 60) and (morality > 40)
      she's not in any state to babysit Woody.
    *if morality <= 40
      *if ideal >= 50
        you can't expect her to stop Woody from robbing you.
      *if ideal < 50
        she seems worthless and wouldn't stop Woody from robbing you. Hell, she'd probably help him.
  *fake_choice
    #I go out anyway. I trust Woody.
      *set ideal %+10
      Woody has done nothing to betray your trust. You feel comfortable leaving him home and have faith everything will be fine.
      
      Before leaving, you step close to Woody. "Hey, I am heading out for a bit. I won't be long."
      
      "Enjoy," Woody says with a brief wave.
      *line_break
      *line_break
    #I go out anyway. Before I go, I make sure Woody knows he better not rob me.
      *set ideal %-10
      *set morality %-10
      *set woody_faction %-(round(25-(empathy/5)))
      Before leaving, you step close to Woody. "Hey, I am heading out for a bit. I won't be long. I trust you'll be here when I get back and all my stuff will be left alone, right?"
      
      One eyebrow arches on Woody's face. "I got no where else to go and don't make a practice of stealin'. Thanks for checkin' though," he says in a snarky tone.
      *line_break
      *line_break
    #I go out anyway. I have no choice but to trust him.
      *set ideal %-10
      You can't stay locked in your house forever, so you have to test Woody at some point.
      *line_break
      *line_break
    #I stay home. It's not worth risking it.
      *set honor %-10
      Leaving Woody is too risky. Maybe your opinion will change, but for now, you abandon the idea to go running.
      *return
*if running_times = 1
  *set fatigue %+(round((100-sta)/3))
  *set stress %-(round(wil/3))
  *set timecount +100
  Running outside during the quarantine may not be the safest course of action, but you can't let the threats of the outbreak stop you.
  *if dependent
    ${dep_name} lies on the couch in the living room, his eyes closed and chest rising and falling in the depths of sleep.
    *if pet_owner
      ${pet_name} is stretched out next to him, equally lost in a nap.
  *if (dependent=false) and pet_owner
    By the living room couch, ${pet_name} is stretched out, lost in a nap.
  
  You slip out of the back door through the kitchen and 
  *if v_loc = "city"
     make your way through your yard and alley. As you reach the front of your home, you
  feel the crisp, cool air hit your skin and bring your body back to life.
  
  You start with a slow jog, but something pushes your motor, driving you forward faster, harder. The sounds of the ${v_loc} come to life, but your mind quiets it all, and they don't return until you're standing in your living room. The last hour of life is a fog, but you feel tired and replenished at the same time.
*if running_times = 2
  *set fatigue %+(round((100-sta)/3))
  *set stress %-(round(wil/3))
  *set timecount +100
  *if dependent
    "I'm going outside for a bit to run," you say to your nephew, and before he could ask to go with you, the door stood in his way.
  Once outside, you breathe in the ${v_loc} in one long draw and trot ahead in a quick but steady pace.
  *if knee_injured
    Your knee aches as soon as you begin, but the pain drops to the background soon enough.
  *if timecount < 1200
    As the sun rises over ${location}, your mind drifts over the thoughts of the day ahead,
  *if (timecount >= 1200) and (timecount < 1950)
    As the sun lights the midday sky over ${location}, your mind drifts over the thoughts of the day,
  *if timecount >= 1950
    With ${location} painted in the dark of night, your mind drifts over the thoughts of the day that passed,
  so much so that you don't notice the infected running at your back until you arrive at home. When your foot first taps the
  *if v_loc = "city"
    bottom step of your house,
  *if v_loc != "city"
    grass of your lawn,
  you turn and see him fifty feet away, shambling in a sprint as best as his crooked, broken legs can carry him. Before you can decide how to handle him, a shot breaks the quiet, and the zombie redirects his ire to whatever made that noise.
  
  You walk into your home, spent but awakened.
*if running_times = 3
  *set fatigue %+(round((100-sta)/7))
  *set stress %-(round(wil/5))
  *set timecount +50
  With the threat of the apocalypse looming outside, how far can you run and remain safe? You leave your home and sprint
  *if v_loc = "city"
    in a complete circle around your block, from one corner of row homes to the next, 
  *if v_loc = "suburbs"
    through your property, back and forth from one end of the lawn to the other,
  *if v_loc = "country"
    through your property, back and forth from one end of your field to the other,
  keenly aware of the sounds and sights that might originate from some sudden danger. After a run of maybe a quarter-mile in total, you hear the screeching of the infected—the high-pitched call of a newly made zombie alive with rage and hunger. It stops you in your tracks as you scan the area for any sign of it. The howl echoes through the
  *if v_loc = "city"
    canal made by the row homes, bouncing off the brick walls and focusing downward as if aimed at you. A siren answers the call, harsh and warbled, 
  *if v_loc = "suburbs"
    neighborhood, bouncing off the wall of each rancher, and mixes with the heavy sound of a helicopter
  *if v_loc = "country"
    valley, running between the brick-and-wood houses, and mixes with the heavy sound of a train
  closing from a distance, until the two distinct sounds mix into a discordant song. You turn in a complete circle, listening and waiting, ready for something to come out. You stay there for who knows how long, then finally return to your home. Some of the stress from before your run has left you, but not as much as expected.
*return

*label DrawingPractice
*set drawing_times +1
*set stress %-(round(wil/3))
*set timecount +100
*if drawing_times = 1
  *if laptop_powered
    With your laptop still working, you set up at the kitchen table and double-click on PrimePaint Pro, your favorite graphics program.
  *if laptop_powered = false
    You set up at the kitchen table with a pad and a set of colored pencils and start with a fresh page.
  Your mind wanders as you freehand-sketch some wavy lines, rounded corners, shaded areas, and irregular shapes. Whatever pops into your head goes into the drawing, and after the area is covered, you dig in to give detail and sharpen what's there. After a full hour, you stop, hands tired, eyes hurting from staring with intent, but you feel mentally less drained than before.
*if drawing_times = 2
  You
  *if laptop_powered
    set your laptop back at the kitchen table and open 
  *if laptop_powered = false
    sit at the kitchen table and turn your sketch pad to the page with
  the image you've been drawing. You still don't know what it is, but the outline is taking shape, and there is some subtle purpose to the movement of your hands. Even if you don't realize it, there's a theme playing out and a direction to each stroke and line. When you draw, the world slips away—that crazy, chaotic, turbulent world doesn't exist for sixty minutes, and the solitary act, so focused and meaningful to you, gives you renewed energy.
*if drawing_times = 3
  Once again, you sit at the kitchen table and resume the drawing from before. Now, it's deeper and darker colors, saturated between bold lines. Shading fills in the empty areas and pops out shapes hidden in the background. It seems the world stands still as the image comes to life—the inanimate objects breathe and coalesce until it's finished with a final mark.
  
  You step back and stare at what you've created, an image of a ${man}, familiar and close. The eyes, the hair, the lips, the teeth—all are familiar, yet twisted and changed. It's an image of you, perverted by the virus, a new version made by the infection. It's a zombie in your likeness, but it only lasts another moment. You 
  *if laptop_powered
    close without saving, delete the file, close your laptop, and walk away.
  *if laptop_powered = false
    tear the page from the pad, light the corner with a flame from the stove's burner, and toss it into the sink to burn itself out.
*return

*label ExercisingPractice
*set exercising_times +1
*set fatigue %+(round((100-sta)/3))
*set stress %-(round(wil/3))
*set timecount +100
*if exercising_times = 1
  Your exercise equipment sits in a corner of the basement,
  *if zombie_in_basement
    and with that area of your house currently occupied by an undead guest, you head to your bedroom, where you keep the 
  *if not(zombie_in_basement)
    so you head downstairs and choose to work with the
  free weights. When you work out, you can forget about the world out there, past the walls, past the area of quarantine where war wages between the living and the dead. For an hour, you concentrate upon your muscles, your barbells, and the weights they hold.
*if exercising_times = 2
  You head to your bedroom and start a series of push-ups, pull-ups, sprints in place, jumping jacks, and any other exercise you can dream up. Slow at first and then driving the pace, you push harder and faster until all thoughts of the apocalypse melt away into an abyss where forethought can't reach. For an hour, you stress your body to relieve the stress in your mind, and though tired and sweaty at the end, your mind feels clear and alert.
*if exercising_times = 3
  Today's workout starts with a short warm-up of stretches and deep breaths. As your heart rate rises, you turn to your free weights, adding every bit to a barbell. Your muscles and tendons strain as you lift the massive weight, and you soon struggle with exhaustion after a few reps. The action takes total focus, and when the bar falls to the floor with a bounce, you drop to one knee to rest. That's when the thoughts creep in—the apocalypse, the quarantine, the infected. You lift the barbell again and do the next cycle, removing the bad images for those short intervals of time, and after an hour, you stop and sit until the pain of the intense workout subsides.
*return

*label KnittingPractice
*set stress %-(round(wil/3))
*set timecount +100
*set knitting_times +1
*if knitting_times = 1
  When you thought about knitting as a way to pass the time and relax during the quarantine, you remembered packing away some supplies in your bedroom. Not knowing exactly where you stored them, you head upstairs and check the most obvious places: under your bed in a bin, in a dresser drawer, and (bingo!) in your closet. Buried under a pile of old clothes and a stack of folded empty boxes, you find a small wooden chest with yarn and needles.
  
  You move to a chair by the window with your supplies and start on a square of material. Your fingers move in nimble steps as you create a slipknot and cast on the first row. While you knit, you stare out the window at the ${v_loc}, and time drifts by. Though it's a bleak world out there, beyond the
  *if v_loc = "city"
    brick and mortar boxes and cement rivers,
  *if v_loc = "suburbs"
    identical town homes and spring-painted trees,
  *if v_loc = "country"
    protective forests and rolling hills,
  you find peace in the repetition of weaving yarn with needles into something new and useful.
*if knitting_times = 2
  You visit your bedroom and take up the project you started, working on purl stitches as the item takes shape. Lost in each row, you forget the worries of the day and focus on the task at hand. Each motion builds on the next, each stitch adding to the thing before it, the sum of the parts making something identifiable on its own. An hour passes like a second, and you've added a fair amount to the object—whatever it turns out to be.
*if knitting_times = 3
  Once again, you head to your bedroom and take up needles and yarn to work on your project. You've finished the length of a short scarf, but it's not finished yet. A pattern is taking shape—somehow, you've been varying the yarn color and building an image stitch-by-stitch. What is it? You hold up the patch of cloth, but you still can't see the big picture, like you're trying to identify the subject of the whole puzzle by examining a single piece. In time, it will become apparent, and for now, you work on today's section.
*return

*label GardeningPractice
*set stress %-(round(wil/2))
*set timecount +100
*set gardening_times +1
*if gardening_times = 1
  Until now, you've focused your gardening on non-edible plants and flowers, but your hobby could help provide a sustainable food source if managed well. Living in the ${v_loc}, you
  *if v_loc = "city"
    don't have a lot of outdoor space to maximize plant growth, but there is a clear four-by-four area perfect for a raised bed and 
  *if v_loc = "suburbs"
    have enough room in your yard for a new area to start growing edibles in a raised bed and a nice space up the side of the wall
  *if v_loc = "country"
    have a large yard with enough clear space for growing edibles, and you select an area close to your house for a raised bed. Also, an area along the back wall is perfect
  for a trellis. You have some supplies for tending your new plants, but you'll need more seeds, specialized plant food, and insecticide if you want to do this right. Luckily, you have a few sample packets with seeds for tomatoes, cucumbers, and snap beans. 
  *if night_blindness and (timecount >= 2000)
    Having such poor night vision, it becomes difficult to work in the dark, so your work suffers.
    *if w_flashlight = 0
      *set stress %+(round((100-wil)/5))
    *if w_flashlight > 0
      Using a flashlight helps.
  For an hour, you spread soil, plant the seeds, and water the area. With your mind focused on the task, thoughts of the apocalypse are pushed to the background, giving you a needed mental break.
*if gardening_times = 2
  Back in your yard, you start your chores for the day to tend the garden. It will take weeks for anything to show above ground and even more time for actual crops, but this time is important for care and maintenance. 
  *if night_blindness and (timecount >= 2000)
    It's difficult to work at night, but you know the area well enough to garden anyway.
    *if w_flashlight = 0
      *set stress %+(round((100-wil)/5))
    *if w_flashlight > 0
      Your flashlight comes in handy.
  First, you bring out your hose to water the soil. Turning on the spigot, the water flows, but you're not sure how long that will last. Next, you check for insects. Though nothing is growing, some insects eat seeds. Luckily, nothing has invaded your soil. Finally, you check for even a hint of weeds in order to clear them away.
  
  After an hour has passed, you hear a strong, close howl. It's shrill and growling, clearly made by an infected. You can't see it, but the sound interrupts your solitude. You stand and
  *if v_loc = "city"
    listen, trying to place the source of the howl. 
  *if v_loc != "city"
    look around for any glimpse of the thing that caused that howl. But you can't see it—all you can hear is the howl.
  It's far and drifting away, moving to chase or to feed.
  
  For now, you're safe, but that's all the gardening you'll do for the day.
*if gardening_times = 3
  *if night_blindness and (timecount >= 2000)
    Gardening at night is never easy with such poor night vision,
    *if w_flashlight = 0
      *set stress %+(round((100-wil)/5))
      but even in the darkness, you'll make progress,
    *if w_flashlight > 0
      but your flashlight will help in this situation.
  You walk back into your yard and check the raised bed and trellis. While it's still too early for anything to grow, you enjoy caring for the soil and working with your own two hands to build something that can last. All around the world is death, but in this small patch of land, there's life and the potential for more and more life as the plants grow and produce vegetables and seeds. Then the cycle begins again, and that's how this small place of soil and seed will survive.
  
  As you water the area, you notice the first leaves of a flower buried just above the surface of the dark soil. Moving away the wet earth, you touch the petal and see it's an infant weed. It grew so soon? Touching it, you feel its leathery texture, almost gritty, and wonder what kind of weed grew over two days. You dig deeper to find the root and, reaching the tiny embedded stalk, you yank it out. It's long and barbed and slightly coiled—not like any weed you've ever seen before. Had you left it there, it would have grown and stolen the nutrients from the soil, starving your plants and ruining the garden. The weed, too, is life, but not the kind you want to grow. It only lives to consume and to reproduce, ruining all around it.
  
  You clear your hands of the dirt and walk back inside your home.
*return

*label MeditatingPractice
*set stress %-(round(wil/3))
*set timecount +100
*set meditating_times +1
*if meditating_times = 1
  You head into your bedroom for a quiet place to meditate and sit by the window in a clear area. On the floor, you cross your legs and settle into a comfortable position, close your eyes, and steady your breathing. Your thoughts of the apocalypse slip away, though it's difficult to keep them out. Every time you push one away, another finds its way to slip into place, like an apparition materializing out of nothing. You try every trick: controlling your breathing, giving attention to safe images, focusing upon various parts of your body. It's a struggle, but by the end of the hour, you've emptied your mind and feel at peace.
*if meditating_times = 2
  You walk into the backyard of your house and sit in a clear spot, tucked with your back to the
  *if timecount < 2000
    wall and a clear view ahead.
  *if timecount >= 2000
    wall, surrounded by darkness in the evening of Nightfall.
    *if night_blindness
      *set stress %+(round((100-wil)/5))
      Though you don't need to see in order to meditate, your night blindness makes you leery about being outside.
  Though it's safe where you rest, protected by
  *if v_loc = "city"
    a high stone wall,
  *if v_loc != "city"
    a high fence,
  the term 'safe' has a different meaning than a few days ago. For now, you focus upon a point on the ground and let your mind drift to better thoughts, of the world before the outbreak and life as you used to know it. For an hour, you sit and relax and keep away any image other than those happy places.
*if meditating_times = 3
  You walk upstairs to your bedroom, open the window, and climb to the roof. Snow still lies in several piles, though almost all of it has melted, and the wet marks show patches of the roof damaged by the melting of ice. You find a clear spot and sit cross-legged with the wind at your back. At first, it's hard to concentrate upon meditating, as the sights of the ${v_loc} are there to distract you:
  *if v_loc = "city"
    the drab houses hiding the living and dead, smoke rising from multiple fires in distant neighborhoods, Army tanks and National Guard checkpoints, and Red Cross trucks stacked along the roadsides.
  *if v_loc = "suburbs"
    town homes lying between patches of trees and dry grass, buildings in the distance now dark and hiding survivors and the infected, and relief vehicles outside of tented areas where the living seek haven.
  *if v_loc = "country"
    farmhouses hiding the living and the infected, fields in the distance, some burning, some scorched, and the military and relief vehicles stacked by the roadsides, some broken, others abandoned.
  For an hour, you shut off your mind and block out all sights and sounds in order to find the peace you need.
*return

*label MusicPractice
*set stress %-(round(wil/3))
*set timecount +100
*set music_times +1
You head to a quiet place in your house and bring out your phone. After putting in your ear buds, you find the song you want…
*if music_times = 1
  *fake_choice
    #[i]1999[/i]—Prince
      You play the song, and its poignant lyrics and melody set 
    #[i]Apocalypse Please[/i]—Muse
      You play the song, and its simple yet poignant lyrics and melody set 
    #[i]Down with the Sickness[/i]—Disturbed
      You play the hard-driving song with its intense lyrics, which sets
    #[i]Echoes[/i]—Ink Spots
      You play the classic, melodic, almost creepy-in-this-setting music, which sets
    #[i]Judgment Day[/i]—Method Man
      You play the apocalyptic-themed hip-hop song, which sets
    #[i]Thriller[/i]—Michael Jackson
      You play the classic pop song with the horror theme, which sets
    #[i]Undying[/i]—Crawling Manifest
      You play the hard-driving song with its intense lyrics, which sets
  the tone for the hour. Every song you play helps you to forget your worries, at least for a while.
*if music_times = 2
  *fake_choice
    #[i]99 Red Balloons[/i]—Goldfinger
      The classic pop song lifts your mood, and 
    #[i]Black Hole Sun[/i]—Soundgarden
      The alt-rock classic's melodic sound captures your mood, and
    #[i]For Whom the Bell Tolls[/i]—Metallica
      The metal classic gets your blood pumping, and
    #[i]In The End[/i]—Linkin Park
      The alt-rock classic's powerful lyrics capture your mood, and
    #[i]Living Dead Girl[/i]—Rob Zombie
      The heavy metal song gets your blood pumping, and
    #[i]The Day the World Went Away[/i]—Nine Inch Nails
      The industrial rock song's melodic sound captures your mood, and
    #[i]Who Wants to Live Forever[/i]—Queen
      The classic rock song's melodic sound captures your mood, and
    #[i]Zombie[/i]—The Cranberries
      Though it's not about the infected, the irony of the title isn't lost on you. Repeating the word in the chorus is cathartic, and
  this leads to an entire playlist based upon that music.
*if music_times = 3
  *fake_choice
    #[i]Blood, Brains & Rock 'n' Roll[/i]—Zombie Girl
    #[i]Everyday Is Like Sunday[/i]—Morrissey
    #[i]It's the End of the World As We Know It (And I Feel Fine)[/i]—R.E.M.
    #[i]Last Night of the World[/i]—Bruce Cockburn
    #[i]This Fire[/i]—Killswitch Engage
    #[i]Left Behind[/i]—Slipknot
    #[i]The Man Comes Around[/i]—Johnny Cash
    #[i]Til the World Ends[/i]—Britney Spears
    #[i]The Earth Died Screaming[/i]—Tom Waits
    #[i]The End[/i]—The Doors
    #[i]What a Wonderful World[/i]—Louis Armstrong
  You play the song, and its poignant lyrics and melody set the tone for the hour.
*return

*label InstrumentPractice
*set stress %-(round(wil/3))
*set timecount +100
*set instrument_times +1
*if instrument_times = 1
  You take your ${instrument} to your bedroom and settle into a comfy chair. The wind rattles the window and whistles as it passes, creating its own music. You haven't played in a while, so you blow a layer of dust off the surface and clean it with the sleeve of your shirt.
  *if instrument = "flute"
    You blow once and hear the soft flutter of notes.
  *if instrument = "keyboard"
    Pressing the keys, you hear the quick reply of notes.
  *if instrument = "guitar"
    Strumming the strings, you hear the quick reply of notes.
  *comment end/
  
  You start with a quick progression through the scales to warm up, but it turns into a somber piece—nothing you've heard before. Your fingers dance
  *if instrument = "flute"
    over the holes,
  *if instrument = "keyboard"
    along the keys,
  *if instrument = "guitar"
    as you pick each chord,
  producing a sound almost as horrific and desolate as the world outside. But in the depressed music you create is a relief from the stress of all you've endured so far, and you play for an hour, finding solace in each moment.
  *if dependent
    At the end of the time, you look up and spot your nephew listening by the door, and he smiles and pulls back from the doorway.
*if instrument_times = 2
  You head to your bedroom and
  *if instrument = "flute"
    place the flute to your lips,
  *if instrument = "keyboard"
    set the keyboard on a stand,
  *if instrument = "guitar"
    settle the guitar into place,
  starting off with warm-up exercises. 
  *if pet_owner
    ${pet_name} lies at your feet, eyes closed, seeming to smile.
  Years ago, when you first learned to play, your teacher had you practicing [i]Twinkle, Twinkle, Little Star[/i] over and over until
  *if instrument = "flute"
    you were out of breath.
  *if instrument != "flute"
    your fingers hurt.
  For an hour, you play it over and over, and in the repetition you are reminded of that simpler time.
*if instrument_times = 3
  You return to your bedroom with your ${instrument} and start with a few quick warm-ups. A few minutes flow by, and the music turns upbeat and faster—a tune of your own making. The notes rise higher and the pace quickens until your
  *if instrument = "flute"
    breath races
  *if instrument != "flute"
    fingers struggle
  to keep up with the song. You push harder to keep it going, feeling that an end to the song means an end to the peace it brings. Eyes closed, you release the pressures and worries, and for that hour, nothing matters but the creation of art that no one else in the world has heard.
*return

*label VideoGamesPractice
*set stress %-(round(wil/3))
*set timecount +100
*set video_games_times +1
*if video_games_times = 1
  With the electricity still working, you breathe a sigh of relief when your LaserStation One console turns on. It's not hard to lose yourself in a video game, and that's exactly what you need—a distraction from the outbreak. Your fingers flip through the game cases, and you settle upon…
  *fake_choice
    #Empty Souls II: Born in Blood—a first-person online shooter based on a fantasy world where you play a classic movie monster.
    #Motor Vehicle Theft IX—an open-world racing game in which you steal cars to race against other players.
    #Drumpy's Quest—a side-scrolling puzzler in which Drumpy must find his brain, which is lost in a world made of pudding.
    #CarnivalSandbox—build a carnival complete with rides and vendors out of pixelated blocks.
  Though you could play it all day, you spend an uninterrupted hour and enjoy the mindless break from life.
*if video_games_times = 2
  With the electricity being so faulty, you can't get your LaserStation to remain on, so you take out your PrimePad, last year's Android model. Dropping into a chair in the kitchen, you check the apps you've downloaded.
  *fake_choice
    #GhoulFest—play as an undead creature that feeds upon the citizens of the town Hopeville.
    #Irritable Penguins—build traps to set against the legions of penguins that are invading your town.
    *if movie_star
      #Forensic Experts: Philadelphia—a game based upon your hit TV show.
    *if not(movie_star)
      #Forensic Experts: Philadelphia—a game based upon the hit TV show.
    #Clash of Border Towns: build your own apocalyptic town and battle other players online.
  You load the game and play for an hour, forgetting about the apocalypse until the battery dies on the PrimePad.
*if video_games_times = 3
  *if (house_powered = false) and (v_loc != "suburbs")
    Without the use of electricity, you bring out your phone to play a mobile game. To conserve what's left of the battery,
  *if house_powered or (v_loc = "suburbs")
    Though you have power in your home, you feel it's best not to use up precious energy on a console or PC game. Instead,
  you play a text-based game…
  *fake_choice
    #Lost Heir: The Fall of Daria—take back your throne from demon-summoning usurpers.
    #Captive of Fortune—Battle necromancers, ogres, and the demon itself!
    #Unnatural—Join the Supernatural Response Team to battle monsters.
    #Dancing with Demons—Play as a contemporary succubus and have fun while saving the world from doom.
  After an hour, you close the game and put your phone away, feeling a bit less stressed after your break from reality.
*return

*label ReadingPractice
*set stress %-(round(wil/3))
*set timecount +100
*set reading_times +1
*if reading_times = 1
  You head to a quiet place with a book you started a few weeks ago but never finished…
  *fake_choice
    #Ashley Hopper and the Translucent Mirror—the fifth book in the series about an adolescent girl with mystical powers.
      *set hobby_book "Ashley Hopper and the Translucent Mirror"
    #Fire in the Barn—a romantic tale of two lovers brought together when they meet in a barn during a rainstorm.
      *set hobby_book "Fire in the Barn"
      *if like_females
        *set kendall_he "she"
        *set kendall_him "her"
        *set kendall_his "her"
        *set kendall_man "woman"
      *if female or nb
        *set ashton_he "she"
        *set ashton_him "her"
        *set ashton_his "her"
    #Compendium to the Tales of Unliving Walkers—the graphic novel set at the end of a long apocalypse.
      *set hobby_book "Compendium to the Tales of Unliving Walkers"
    #Planet Battles—a sci-fi thriller about the war between six factions of aliens all looking to take over the Earth.
      *set hobby_book "Planet Battles"
  You turn to the middle of the book and let yourself slip back into the story, and though the sounds of the
  *if chapter_point < 6
    ${v_loc}
  *if chapter_point = 6
    forest
  try to distract you, and
  *if chapter_point < 6
    gunshots and a passing helicopter jerk your head away,
  *if chapter_point = 6
    passing insects and chatter from the campsite draw your focus,
  you're able to enjoy reading.
*if reading_times = 2
  You walk to a quiet spot with your book, [i]${hobby_book}[/i], and
  *if chapter_point < 6
    sit on the windowsill to make use of the
    *if timecount < 2000
      sunlight.
    *if timecount >= 2000
      ambient light.
  *if chapter_point = 6
    make use of the last of the sunlight.
  Opening to the last bookmark, you read—
  
  ---
  *line_break
  *if hobby_book = "Ashley Hopper and the Translucent Mirror"
    The cruise ship arrived, docking close to the pier, which shook violently. Master Vorlant watched as a gangplank of bone and scales lowered itself from the bow to the dock, and Ashley stepped up next to her mentor, holding her Darklight amulet in hand. The charm bathed her in warmth despite the chill coming off the water, and she squeezed the metal until her fingers ached. The young apprentice's mind raced with thoughts of where they were headed. 
    
    "Prepare yourself, Ashley, and keep your mind clear," Vorlant said, waving her decrepit finger near her forehead. "The ghosts aboard will try to read your very thoughts."
    
    Ashley shook off her jitters and stepped onto the ancient plank of dragonwood.
  *if hobby_book = "Fire in the Barn"
    Ashton wrapped an arm around Kendall's waist and pulled ${kendall_him} tight against ${ashton_his} body. A strand of red hair fell over Kendall's forehead, and Ashton brushed it aside. $!{ashton_he} felt the heat off the younger ${kendall_man}'s body. The temperature in the barn hovered around sixty degrees just after midnight, so the cuddling was welcome to Ashton. $!{ashton_he} never would have guessed that the old farmhouse's barn would not only protect ${ashton_him} from the storm, but become a place where ${ashton_he} would find love.
    
    "Ashton, what's wrong?" Kendall said, ${kendall_his} lip quivering as ${kendall_he} spoke.
    
    "Sorry. I was distracted for a moment. But I'm here now."
  *if hobby_book = "Compendium to the Tales of Unliving Walkers"
    Dirk lifted his Desert Eagle to the head of the Disciple. "Time to say your last words to whatever god you worship."
    
    The Disciple spat blood to the dirt road and tried to stand. Dirk kicked him in the stomach, sending the scarred man back to his knees.
    
    "Dirk! Dirk!" Amanda yelled from the burnt field. She was running and waving her arms furiously, almost tripping over scorched stalks of corn.
    
    Dirk wondered if she was warning him about that herd of Creepers they saw locked in the church lot. As Dirk opened his mouth to call back, his eyes fell on two massive trucks barrelling across the field in the distance, just past the farmhouse.
    
    A smile crept over the Disciple's face. "Looks like my people found me. Maybe it's time you pray to your god."
  *if hobby_book = "Planet Battles"
    Ringo jumped from the cockpit of the StarHowler and held out his laserlance. He was still surprised that something of such brilliant light didn't cast any heat, and in the icy lands of Apollo's third moon, he sorely wished it did. Focusing upon the ancient weapon, he compelled it to intensify its beam until it lit up the sheer surface of the alien planet. Walking forward, he slid over the smooth ground but took his time as he moved toward the green glacier structure he'd spotted from space.
    
    A blast from the left broke his concentration, and the laserlance fell dim. Ringo spun around and saw his StarHowler engulfed in flames. Standing beside it, three Shadow Knights drew laserswords and marched toward the young soldier.
    
    "Death hassss found you, Ringo DarksssStar," the lead one hissed in a reptilian voice.
  *line_break
  ---
*if reading_times = 3
  Again, you walk to a quiet spot with [i]${hobby_book}[/i]. Opening to the last bookmark, you read—
  
  ---
  *line_break
  *if hobby_book = "Ashley Hopper and the Translucent Mirror"
    Ashley fell from the tower and hit the icy waters of the Lost River like a cannonball. Plunged into the water, she felt the sudden urge to take a deep breath as the shocking cold surrounded her body. She longed for rest and thought how easy it would be to give in and let sleep take her.
    
    An image materialized in her mind of a younger Ashley, sitting on a bench outside her Uncle Donatell's castle at the edge of the Immense Divide. A single starflower in a field of moongrass—she spotted that solitary flower hidden in the rough yellow meadow. She plucked it with two fingers, and it felt like gossamer in her hands. As sunlight struck the tiny pink leaves, Ashley felt the warmth of a thousand stars.
    
    In the frigid waters of the Lost River, Ashley opened her eyes.
  *if hobby_book = "Fire in the Barn"
    Kendall walked to the side of the barn and stared through the cracks in the wooden door. Rain fell hard outside against the field of grass in almost a lullaby of sound. $!{kendall_he} looked to the sky—the dark clouds were far in the distance, moving out to sea, and the storm had turned into nothing more than a light drizzle. Soon, the roads would be clear, and this weekend would be over.
    
    Ashton's hands touched Kendall's bare shoulders, causing ${kendall_him} to turn.
    
    "Let's leave together," Ashton said, caressing the back of Kendall's neck with the tips of ${ashton_his} fingers. "This weekend never has to end."
  *if hobby_book = "Compendium to the Tales of Unliving Walkers"
    Dirk stared out of the tower's window. On the runway, the group of Disciples formed a circle at the base of the tower, weapons raised and ready to fire.
    
    "You have until the count of three to throw down your weapon and come outside," Vincent said and sparked the end of his flamethrower. A ball of fire flared from the nozzle and quickly dissipated in the air. "If you do as I say, you will be spared the fire."
    
    Dirk checked the magazine of his Desert Eagle—two bullets. He stood up, tightened his grip on the pistol with one hand, and turned the knob on the tower door. [i]If I can hit that flamethrower's gas tank, I may still have a chance." As he swung the door inward, a flash of light caught his eyes. He blinked hard as the light glinted across his shirt. Slamming the door shut, he rushed to the control board and lifted the binoculars. He scanned the area across the runway for the source of the light, and in another aviation tower across the field stood Amanda and T-Bone, each with a sniper rifle aimed at the Disciples.
    
    With a smile, Dirk raised a thumb in the air and instantly heard two gunshots.
  *if hobby_book = "Planet Battles"
    Ringo stumbled across the rocky banks of the volcano, holding his laserlance high to defend against incoming attacks. The body of the first Shadow Knight sunk into the lava with a deep hiss, and he walked away before it disappeared. There were two left, he thought, and he searched the stone ridge for any signs of his pursuers. Though he had defeated one, the wound in his stomach was deep, and he needed time to heal. 
    
    "How can I survive against the other two?" he wondered.
    
    A natural bridge of rock formed over the lava stream, and Ringo staggered over it on weak legs. As he stepped back onto the volcanic ground, he heard the distinct voices of the two Shadow Knights.
    
    "He mussssst be here, sssssomewhere."
    
    "His sssscent issss sssstrong."
    
    Ringo DarkStar gripped the handle of his laserlance and took a deep breath. "If I charge them now, I'll have the element of—"
    
    He spotted a tiny, translucent orb hovering just above a pile of ash on a lava rock. Though anyone else would have missed the nearly invisible object, Ringo had been trained to detect such anomalies. With its power, not only could he heal his wound, but he'd have the energy to defeat both enemies.
  *line_break
  ---
*if reading_times = 4
  Finding a quiet spot, you open [i]${hobby_book}[/i] to your bookmark.
  
  ---
  *line_break
  *if hobby_book = "Ashley Hopper and the Translucent Mirror"
    Ashley sat upon Felicia's back, the centaur fully making excellent time through the Eversnow Forest. Ashley glanced around her, momentarily entranced by the beauty of the ice-encrusted woods, gleaming like gems dancing in the sunlight.
    
    Suddenly, Ashley clung tightly to Felicia's waist as the centaur leaped over a pit which revealed itself. Looking behind, Ashley shuddered as the bottom of the pit was filled with icicles several feet high, jutting up like frozen spikes.
    
    "How much farther?" Ashley asked, burying her face in Felicia's mane, momentarily warming up her face.
    
    "Only one more hour, and then you have to go on ahead by yourself," Felicia answered.
  *if hobby_book = "Fire in the Barn"
    Ashton tried to sleep that night, but sleep eluded ${kendall_him}, and why shouldn't it? Though the time ${kendall_he} spent with Kendall was magical, the younger
    *if ashton_his = "his"
      man
    *if ashton_his = "her"
      woman
    had rebuffed ${kendall_his} offer to run away together. 
    
    [i]And why not? There is nothing you can offer ${ashton_him} that ${ashton_his} fiance couldn't give ${ashton_him} ten-fold.[/i]
    
    Off in the distance, lightning kissed the ground, followed by the boom of thunder. Ashton rose from bed and made  ${ashton_his} way to the window. $!{ashton_he} stared quietly into the distance, the rain unable to fill the ache in ${ashton_his} heart.
    
    It wasn't that Kendall's fiance was a bad person, far from it, but Ashton knew it was foolish to expect Kendall to throw away ${kendall_his} relationship for a moment of passion.
  *if hobby_book = "Compendium to the Tales of Unliving Walkers"
    Dirk kissed his Desert Eagle for good luck, and ran from the column, shooting into the mass of Creepers before him. Several of the foul undead fell, bullets cleanly taking off their heads, but the horde was too big to be affected by their losses.
    
    Suddenly, Dirk noticed a glint off in the distance and instantly recognized the light reflecting off a rifle's scope. Instantly, he dove behind another pillar just as several bullets buried themselves in the ground behind him.
    
    "You only have to hold on for a few more minutes," Dirk thought. You have to buy the others some time."
    
    The blare of a loud horn cut through the air, and Dirk smiled as he saw Amanda barreling through the horde of zombies, her stolen vehicle casting them left and right.
    
    Dirk raised his Desert Eagle to take a shot, but lowered it again as he realized it would be futile. He stared in horror at the creature before him; a long, sinuous mass of bodies undulating in a snake-like fashion toward him.  It resembled nothing more than a gigantic human millipede, dozens of Creepers crudely attached until they made one writhing abomination.
    
    "Well, what do you think of my little pet?" said the Disciple, a wide smile ruined by the scar running down his nose.
    
    "You monster!" Dirk yelled, training his weapon on the Disciple, knowing that he could take out this flesh-and-blood living person.
    
    "Tsk, tsk," said the Disciple. "I would rethink that if I was you."
    
    The Disciple crooked his fingers, and another Disciple stepped out, T-Bone bound and gagged, with a dagger held at his throat.
  *if hobby_book = "Planet Battles"
    Ringo's lip quirked in satisfaction as he saw his three foes sprawled on the ground, defeated by the power of his laserlance.
    
    He turned on his heel and raised two fingers to his head, as he said, "You should be safe from these, madam."
    
    Before Ringo could say another word, two pairs of fur-covered arms embraced him, pulling tightly on his back, as well as grasping his waist.
    
    "My hero," whispered the beautiful alien.
    
    Suddenly, Ringo felt a prick in the side of his body, and waves of blackness started to float through his body.  
    
    "Hero is another word for fool," said the alien before blessed unconsciousness took him.
  *line_break
  ---
  
After an hour of reading, you close the book.
*page_break
*return

*label SingingPractice
*set stress %-(round(wil/3))
*set timecount +100
*set singing_times +1
*if singing_times = 1
  You step outside into the backyard and walk
  *if v_loc = "city"
    along the stone wall leading to the alley.
  *if v_loc = "suburbs"
    by the perimeter fence next to your neighbor's property.
  *if v_loc = "country"
    along the path leading to the road.
  *if timecount < 1950
    Shade covers the area where you walk, making it colder than it should feel
  *if timecount >= 1950
    Since the sun has gone down, the air is colder than you'd expect on a night
  in May. 
  *if night_blindness and (timecount >= 2000)
    *set stress %+(round((100-wil)/5))
    Though you don't need to see in order to sing, your poor vision at night makes being outside a bit creepy.
  You start with some warm-up exercises to loosen your vocal cords. Mainly, you like to sing…
  *fake_choice
    #Alternative.
      *set hobby_music_genre "alternative"
    #Choir singing.
      *set hobby_music_genre "choir singing"
    #Christian/Gospel.
      *set hobby_music_genre "christian"
    #Country.
      *set hobby_music_genre "country"
    #Folk.
      *set hobby_music_genre "folk"
    #Heavy metal.
      *set hobby_music_genre "metal"
    #Latin.
      *set hobby_music_genre "latin"
    #Pop.
      *set hobby_music_genre "pop"
    #R&B/Hip-Hop.
      *set hobby_music_genre "hip-hop"
    #Rock.
      *set hobby_music_genre "rock"
  Over the next hour, you practice singing, letting your voice fill the open space, and for that time, you focus upon something other than the outbreak.
*if singing_times = 2
  You head into the kitchen and stare out the small window
  *if v_loc = "city"
    at the 
    *if timecount >= 1950
      night
    sky.
  *if v_loc != "city"
    at the branches of an old tree in your yard, how they sway in the breeze.
  You feel the words of a song rising in your throat before even thinking of them,
  *if hobby_music_genre = "alternative"
    a sullen ballad about the apocalypse.
  *if hobby_music_genre = "choir singing"
    a melodious ballad that you'd often sing with your choir to warm up your voices.
  *if hobby_music_genre = "christian"
    an uplifting ballad about God's love.
  *if hobby_music_genre = "country"
    an quick-tempo song about lost love.
  *if hobby_music_genre = "folk"
    a moody tune about the end of time.
  *if hobby_music_genre = "metal"
    a dark ballad about the apocalypse.
  *if hobby_music_genre = "latin"
    an up-tempo tune about lost love.
  *if hobby_music_genre = "pop"
    a quick-tempo song about lost love.
  *if hobby_music_genre = "hip-hop"
    a driving beat about the power of humanity.
  *if hobby_music_genre = "rock"
    a hard-hitting ballad about the end of time.
  *if dependent
    At one point, ${dep_name} walks in, listens for a while, and then leaves, still humming along.
  For an hour, you build the lyrics and the melody, letting them flow out of you with raw emotion. The whole process feels liberating, and your stress has been carried away.
*if singing_times = 3
  You head to your bedroom for some alone time and a chance to work on your music.
  *if stress < 50
    Though your stress has remained in check considering all you've been through, you do need a break, and music has always been a source of relief.
  *if (stress >= 50) and (stress < 80)
    While your stress hasn't reached the red zone, you need to clear your mind and focus upon something other than the apocalypse.
  *if stress >= 80
    Your stress is peaking, and unless you take a break and clear your mind, you don't know how much more of the apocalypse you can take.
  $!{hobby_music_genre}
  *if hobby_music_genre = "alternative"
    is a mix of storytelling and melodic music, and you channel its energy to lift your mood and inspire you to push forward and never give up.
  *if hobby_music_genre = "choir singing"
    entails uniting a group of singers to raise their voices together in song. You close your eyes and imagine yourself in your choir, singing your part.
  *if hobby_music_genre = "christian"
    is all about the power of faith, and singing it brings you great joy even in hard times.
  *if hobby_music_genre = "country"
    at its core is about storytelling, and that's what you do—sing the story of what you've been going through.
  *if hobby_music_genre = "folk"
    is based on storytelling and acts as an oral account of the life of the songwriter. You embrace the tradition.
  *if hobby_music_genre = "metal"
    is intense, aggressive, and powerful, and singing is the ultimate release of adrenaline.
  *if hobby_music_genre = "latin"
    for you reminds you of the rich heritage of the Latin people, which brings you great peace.
  *if hobby_music_genre = "pop"
    is all about catchy beats and lyrics that together lift your mood and remind you everything will be all right.
  *if hobby_music_genre = "hip-hop"
    is all about rhythmic beats and powerful lyrics that together lift your mood and remind you everything will be all right.
  *if hobby_music_genre = "rock"
    is all about hard-edged beats and powerful lyrics that together lift your mood and inspire you to push forward and never give up.
  As the hour progresses, you push yourself to keep singing—to keep sending out the words to tell the world your fire won't be put out.
*return

*label CalcSlots
*set max_count round((scavenging/15)+(str/18))
*set container "pockets"
*if armor = "tactical vest"
  *set max_count +tactical_vest_count
  *set container "tactical vest"
*if w_backpack > 0
  *set max_count +bp_count
  *set container "backpack"
*if duffel_bag > 0
  *set max_count +duffel_count
  *set container "duffel bag"
*return

*label ReviewLegitFiles
*if not(first_time_reviewing)
  You open the LEGIT folder on your laptop and select a series of files to review.
*if first_time_reviewing
  *set first_time_reviewing false
  Bringing up the LEGIT files on your laptop, you open the main folder to review the hundreds of files collected on the Zeta virus and its existence before the outbreak. After perusing the files for several minutes, you determine their contents fall into several categories: the Zeta virus, the government's research on the virus, and the spread of the virus. You could easily spend an hour on each topic, but reading all of the information might bring you closer to learning the truth about this pandemic.
*label FlashDriveFiles
*fake_choice
  *selectable_if (reviewed_zeta = false) #The Zeta virus.
    *set reviewed_zeta true
    *set timecount +75
    LEGIT has collected hundreds of documents on the Zeta virus, mostly recent scholarly papers on what scientists have learned so far about it. Zeta is a double-stranded RNA virus with a polyhedral head and long tail that mimics an antibody to some degree. It enters the body through blood or saliva, passes into the spinal cord and, eventually, the brain. From there, it infects brainstem tissue and feeds off of the other cells of the brain as it multiplies.
    
    The true horror of Zeta is how quickly it incubates. In normal hosts, it takes one to three hours to show symptoms, while in immune-compromised individuals, such as those with cancer or HIV, the infected individual can turn in fifteen minutes. Some articles suggest boosting the immune system as a means of surviving longer.
    
    As you read further, you uncover more about the nature of Zeta and how it transmits and overtakes the body. You jot down notes in a separate file and form a summary of findings:
    
    1. If bitten by an infected person, immediate amputation may limit spread. Once in the body, the virus finds its way to the spinal cord. If the virus is eliminated before this occurs, the host's chance of survival increases. Amputation of a bitten limb may prolong survival.
    *line_break
    2. There is no known cure or treatment. If someone shows signs of infection, termination is the only recourse.
    *line_break
    3. Boosting the immune system has shown to stall symptoms for a longer period.
    *line_break
    4. The virus causes the following early tell-tale symptoms: green freckling or spots, twitching of the limbs, red marks in the iris of the eye, and in some hosts, runny nose.
    
    After forty-five minutes of uninterrupted reading, you rub your eyes and suppress a yawn. You've collected quite a bit of information on the virus, surely the type of info the public should learn if anyone is to have a chance against the disease.
  *selectable_if (reviewed_research = false) #The government's research on Zeta.
    *set reviewed_research true
    *set timecount +75
    Much of the information on the Zeta virus collected by LEGIT involves research conducted by the US and other world-leading countries to understand the nature of the organism and how to stop it. Your mind swims as you delve into official documents and military Intel, all uncovered by LEGIT.
    
    With so many files to review, you think of ways to filter and sort the information. The easiest way is to go back to the start—the oldest documents first. The earliest files show the virus was identified in February of 2011 in a small village in Japan by a joint team of international scientists. For the next fifteen minutes, you peruse articles, reports, and testimonials on the origin of Zeta, though most of it reads like conspiracy theory: government-engineered viruses, military cover-ups, and biotech corporate espionage.
    *if read_about_diangelo
    
      And that's when you see the name Giovanni D'Angelo. His name pops up practically anytime the word Zeta appears.
    *if not(read_about_diangelo)
      *set read_about_diangelo true
      One name appears most often throughout the files—Giovanni D'Angelo.
    This gives you an idea. You run a query using his name and other key phrases related to the origin of the Zeta virus. Sorting this by the oldest files first, you find a series of notes hacked from a US military base in Japan. Code-named Eden, the base is apparently where the earliest research was done on Zeta. Strangely, the date on the paper shows April 10, 2010 when D'Angelo isolated the virus in monkeys, which is eight months earlier than the report filed by the team of international scientists.
    
    You turn away from your laptop and squeeze your eyes shut in frustration. What is the truth and what is the origin of the Zeta virus?
    *page_break
    You turn back to your laptop and scan the document dated April 10, 2010. Hacked from an American military base, the document looks like an official document and has a case number, EDEN72901432. Using this number, you load custom software for connecting to protected servers and begin a series of searches for any information on Eden. The small spinning icon revolves, slow and stuttered as the search tries to return articles or pages related to the case number. After a full minute of waiting, a link pops up to a letter from Major General Zachary Hughes to the project leader of Eden, Dr. Giovanni D'Angelo. The two-page letter and thirty pages of documentation, some of which is redacted with bold black ink, reveals several key pieces of information:
    
    1. The US Military knew of Zeta as early as April 2010, though Dr. D'Angelo had studied the virus much earlier.
    *line_break
    2. Eden was funded by a joint commission of Japan and the US.
    *line_break
    3. D'Angelo's priority was to inject Zeta with something called the Rosa gene, though the origin or purpose of this gene was stricken from the records.
    *line_break
    4. Major General Hughes requested a drug trial to be conducted on humans as early as December 2011.
    
    You close your laptop and try to process all of what you read. Did the governments of the US and Japan know of the threat of Zeta two years ago and fund D'Angelo to find a cure? What is the Rosa gene, and why is it so important? Why were so many details removed from the documents, and by whom?
    
    For now, you've learned as much as you can on the subject.
  *selectable_if (reviewed_spread = false) #The spread of the virus throughout the world.
    *set reviewed_spread true
    *set timecount +75
    With a quick search of LEGIT's accumulated files on the flash drive, you formulate a quick timeline on the spread of Zeta:
    
    - March 2012: Japan and Australia report cases simultaneously. The infected showed stiffened gait, jaundice, skin lesions, and mental impairment. Though the infected showed signs of increased immune response to fight the virus, all patients were eventually dead between thirty minutes and four hours post-infection. 
    *line_break
    - April 2, 2012: a contingent of American, European, and Asian researchers assembled in Japan to study the infected and called these first subjects Abels. Since the lifespan of the infected were so reduced, terminal patients were infected with the virus and called Enochs. Research focused on finding a vaccine to protect uninfected people from Zeta.
    *line_break
    - April 15, 2012: the US has its first cases of Zeta infection. The CDC quickly contained the infected and worked with the government to halt any reports of infection.
    *line_break
    - April 29, 2012: Japan closes all incoming and outgoing transit to the Eden facility in Nago, Japan on Okinawa Island.
    *line_break
    - May 5, 2012: US military officials detain Reginald Scott, a reporter for the Washington Post who was set to break a story on a new virus spreading through Japan and parts of Australia with the potential for pandemic.
    *line_break
    - May 10, 2012: hospitals in Philadelphia, Denver, Los Angeles, London, Delhi, Shanghai, Mexico City, Buenos Aires, Cairo, and Manila report cases of a new viral disease of unknown origin. Resistant to all antiviral drugs and other treatments, the virus took over its host, causing the infected to become agitated, then aggressive, and ultimately to die within hours.
    
    Formulating the timeline takes forty-five minutes, but you now have a clearer picture of the spread of the virus.
*if reviewed_zeta and (reviewed_research and reviewed_spread)
  *set reviewed_legit_files true
*if not(reviewed_legit_files)
  *fake_choice
    #Continuing to review the LEGIT files.
      Next, you review the documents on…
      *goto FlashDriveFiles
    #Stop reviewing the files for now.
*return

*label HackInternet
*set netcount +1
*set timecount +75
*set know_brain_kill true
*set cracked4legit +10
You load your custom software for connecting to protected servers and begin a series of searches for any information on the outbreak. First, you search the major US and global health agencies. Deep within secure archives lies classified reports to the National Institutes of Health from Dr. Giovanni D'Angelo on a virus called Zeta, which invades the body through fluid transfer, either blood or mucous, heading through the central nervous system, and living in the host's brain. 
*if read_about_diangelo
  You remember that name—D'Angelo—from your prior research.
*set read_about_diangelo true
The virus has an accelerated incubation period, eventually taking over basic functions of thought. The infected loses higher brain functions such as speech, cognition, and even pain recognition. Once the virus has filled the brain, the host turns into a hyper-aggressive machine with the sole purpose of passing on the virus, typically by biting other non-infected humans or tearing the flesh and transmitting through blood or saliva. Early tests on a treatment for the infection proved unsuccessful, and only destroying the infected area of the brain caused cessation of bodily functions.
      
Next, you search various American military and United Nations servers for recent articles, memos, and classified documents on the outbreak. Most of the servers are highly trafficked, and the only information you find relates to military orders for civilian defense and mobilizing personnel to support highly populated cities. But then you get the idea to search these servers with the name Giovanni D'Angelo. A series of document titles pop up on the screen. It becomes clear that Dr. D'Angelo had a civilian contract with the Army, and his work with the Zeta virus goes back to almost a year ago. He ran a team in Japan working on highly contagious viruses as early as June 2010, though most of the articles have stricken content or missing files.
      
Your mind reels at the idea that this virus was being studied a year ago. The government sponsored a team to research the virus, yet our country seems so ill-prepared for the outbreak. You log out of the server and stare at the blank screen. [i]Could this all have been prevented?[/i]
*return

*label AcquireSpecimen
*comment specimen_difficulty should be between 10 and 40/
*temp sample_tool "syringe"
*temp sample_chance 0
*temp sample_results_hold 0
Examining the body and your notes, you take a sample of…
*fake_choice
  #Arterial blood.
    *set sample_type_difficulty 25
    *set hold_sample "zeta_arterial_blood"
    You take out a syringe and test tube and find an artery along the inside of the zombie's neck.
  #Brainstem tissue.
    *set sample_type_difficulty 35
    *set hold_sample "zeta_brainstem"
    *set sample_tool "scalpel"
    *if medicine >= 60
      *set sample_type_difficulty -round((medicine/10)-2)
    You take out a scalpel and a tissue sample case.
    *if living_subject
      Holding
    *if not(living_subject)
      Tilting
    the zombie's head to the side, you lean to cut into brain.
  #Cerebrospinal fluid.
    *set sample_type_difficulty 30
    *set hold_sample "zeta_cerebrospinal"
    *if medicine >= 70
      *set sample_type_difficulty -round((medicine/10)-3)
    *if living_subject
      *set sample_type_difficulty +20
      You jam a long needle through the belly of the moving zombie and fish around until you draw out spinal fluid.
    *if not(living_subject)
      You flip the zombie face-down, bare its back, and prepare a syringe and test tube.
  #Skin lesion tissue.
    *set sample_type_difficulty 20
    *set hold_sample "zeta_lesion"
    *set sample_tool "scalpel"
    *if medicine >= 60
      *set sample_type_difficulty -round((medicine/10)-2)
    Locating a sizable greenish patch of flesh, you take out a scalpel and a tissue sample case.
  #Venous blood.
    *set sample_type_difficulty 15
    *set hold_sample "zeta_venous_blood"
    You take out a syringe and test tube and find a raised vein along the inside of the zombie's forearm.
*if science_spec = "clinical laboratory science"
  *set sample_type_difficulty -10
*set sample_type_difficulty -round(science/8)
*set sample_chance (20 + (specimen_difficulty + (sample_type_difficulty + round(stress/10))))
*if science < sample_chance
  As you attempt to acquire the specimen,
  *if stress >= 70
    your hands shake, and the 
    *if sample_tool = "syringe"
      syringe needle pierces the zombie's skin at an awkward angle.
    *if sample_tool = "scalpel"
      scalpel slices deeper than needed, serrating the deep flesh.
    The sample is ruined.
  *if stress < 70
    *if (hold_sample = "zeta_brainstem") or (hold_sample = "zeta_cerebrospinal")
      you struggle with obtaining a clean sample, as your knowledge of anatomy is not as abundant as more scientific pursuits. If you knew more medicine, this might have been successful. For now, the sample is unusable.
    *if (hold_sample != "zeta_brainstem") and (hold_sample != "zeta_cerebrospinal")
      you can't seem to locate the best area from which to take
      *if (hold_sample = "zeta_brainstem") or (hold_sample = "zeta_lesion")
        tissue. You cut along discolored portions of
        *if hold_sample = "zeta_brainstem"
          brain,
        *if hold_sample = "zeta_lesion"
          lesion,
        but the zombie is so decomposed, the task becomes too difficult.
      *if (hold_sample != "zeta_brainstem") and (hold_sample != "zeta_lesion")
        fluid. You plunge the syringe into what you think is
        *if hold_sample = "zeta_arterial_blood"
          an artery,
        *if hold_sample = "zeta_venous_blood"
          a vein,
        *if hold_sample = "zeta_cerebrospinal"
          the spinal cord,
        but when you draw back on the plunger, only air comes out.
      No sample can be obtained.
  *if first_time_sample
    *set first_time_sample false
    
    Next, you take out a syringe and test tube and
    *if living_subject
      move in for an ocular sample. The zombie thrashes and fights, and as you jab in the needle, it breaks. Acquiring a sample is far too difficult on a living subject.
    *if not(living_subject)
      draw a sample of ocular fluid to see if any virus lives in the eye. The fluid filling the syringe's bulb is dark and murky, and though it's only been moments since the infected died, the specimen seems to have putrefied and become unusable. You empty the syringe and plunge the needle into a shallow part of the zombie's arm, and again a thick viscous fluid comes out. After only a few minutes of true death, the infected must quickly decompose, and the virus dies at an accelerated rate. From now on, if you want to take samples, you'll have to be quick.
  *set living_subject false
  *return
*else
  *if not(achieved_specimen)
    *achieve specimenobtained
    *set achieved_specimen true
  You acquire the specimen and place it in your sample kit.
  *label ScienceConvert
  *temp check_change 0
  *set check_change samples_needed_culture
  *set {hold_sample} +1
  *if living_subject
    Since you acquired a specimen from a live subject, you theorize you will gather more information from it than a sample from a dead zombie.
  Specimen Collection has increased from ${samples_needed_culture}
  *if hold_sample = "zeta_arterial_blood"
    *set sample_results_hold round((science/8)/{hold_sample})
  *if hold_sample = "zeta_venous_blood"
    *set sample_results_hold round((science/11)/{hold_sample})
  *if hold_sample = "zeta_brainstem"
    *set sample_results_hold round((science/7)/{hold_sample})
  *if hold_sample = "zeta_lesion"
    *set sample_results_hold round((science/9)/{hold_sample})
  *if hold_sample = "zeta_cerebrospinal"
    *set sample_results_hold round((science/6)/{hold_sample})
  *if living_subject
    *set sample_results_hold +round(sample_results_hold * 0.15)
  *set samples_needed_culture %+sample_results_hold
  *if samples_needed_culture = check_change
    *set samples_needed_culture +1
  to ${samples_needed_culture}.
  *if first_time_sample
    *set first_time_sample false
    
    Next, you take out a syringe and test tube and draw a sample of ocular fluid to see if any virus lives in the eye. The fluid filling the syringe's bulb is dark and murky, and though it's only been moments since the infected died, the specimen seems to have putrefied and become unusable. You empty the syringe and plunge the needle into a shallow part of the zombie's arm, and again a thick viscous fluid comes out. After only a few minutes of true death, the infected must quickly decompose, and the virus dies at an accelerated rate. From now on, if you want to take samples, you'll have to be quick.
  *set living_subject false
  *return

*label ResearchVirus
*set research_virus true
*set science_specimen_kit true
*set science_notebook true
You sit at the desk in your living room and open your laptop. With your science background, you're in a rare position to research a cure for this virus or develop a vaccine. Sure, it will take resources that are in short supply or completely lacking. You'll need a laboratory, and not just a basic high-school lab, but one with advanced tools for examining viruses. You'll need to obtain dozens of samples and specimens taken from the infected and from zombies, live cultures that can be maintained. And you'll spend countless hours of time—time that might be better spent on surviving—for the infinitely difficult chance of a breakthrough.

What are the alternatives? Watching everyone around you succumb to the virus? Becoming infected yourself? You have the mind for research and the background for studying viruses. Mostly, you want to study the virus in order to…
*fake_choice
  #Develop a treatment for those infected.
    *set humanity %+10
    *set science_focus 1
    Until you learn differently, curing the infected is the priority to save humankind. So many people are suffering, and you must find a way to treat them. What's the alternative? If the virus spreads unchecked and kills everyone it has already infected, the world is doomed. Millions will die and society will be devastated, leaving a small percentage of people to survive together in an ongoing uphill struggle. If there's a way to reverse the damage done by the virus or to halt the disease, civilization will be saved. Treating the infected must be your focus.
  #Create a vaccine for those yet to be infected.
    *set humanity %+10
    *set science_focus 2
    The first step in handling a viral outbreak is to stop its spread. The government is trying to quarantine the population, but a vaccine will prevent people from infection. With the short incubation period (people go from infection to zombie in one to four hours), treating the disease might never be possible. The faster you can find a way to vaccinate humankind, the more people can be saved.
  #Create a cure for the power it will bring me.
    *set humanity %-10
    *set science_focus 3
    Saving your species might be your goal, but your motives are far from altruistic. The government is trying to develop a cure, but they'll be too late, and millions will die. Whoever's left will do anything and spend anything for a cure. The faster you can develop one, the more power you'll have in the new era of human civilization.
  #Focus upon something other than my survival. Doing so will keep me sane.
    *set honor %-10
    *set science_focus 4
    With the incredible turmoil in the world and the stress of trying to stay alive, researching the virus and its origin will occupy your time and distract you from destructive thoughts. If you really think about it, finding a cure or treating the infected are far-fetched goals. Whether or not you make any true progress is secondary to having a project to give you a focus other than the outbreak.
  #Learn more about what might have caused the virus.
    *set impulse %-10
    *set science_focus 5
    Before a treatment or vaccine can be developed, a firm understanding of the virus is needed. Where did it come from, and why is it spreading all of a sudden? In this age of scientific breakthroughs and information dissemination, how are we just learning about this world-ending virus? There's a lot to learn about Zeta, and studying its origin will be your focus.
  #Determine if it's possible to alter the virus and somehow take control of it.
    *set ideal %+10
    *set science_focus 6
    The Zeta virus may very well be the most powerful living thing ever to exist on the planet. How can something less than the size of a single human cell alter the history of humankind? If you could somehow understand the virus and harness its power to infect, the applications would be endless.

For now, you can gather samples from the infected to analyze later. You open a spreadsheet on your laptop and enter a column for specimens. Under it, you include space to record collection of the most important samples:

- Arterial blood: an easy sample to obtain, and hopefully you can learn how the virus behaves in a stream of oxygenated blood.
*line_break
- Venous blood: the easiest sample to obtain. Virus should be plentiful here.
*line_break
- Brainstem tissue: dissecting brain tissue can be tricky, but you could learn a lot from examining the virus in it.
*line_break
- Lesion tissue: easier to dissect than the brain, lesions are caused by the virus. Does Zeta leave itself inside these areas of pigmented skin?
*line_break
- Cerebrospinal fluid: since the infected decompose at a rapid pace, obtaining fluid from the spinal column can be tricky. Examining this fluid might give you great insight into Zeta.

All of these could be used for two main objectives: to obtain cultures of live virus and to gain a better understanding of how Zeta operates in humans. You decide to keep a sample kit with you at all times and a notebook for recording your progress. (- accessible through the Stat menu -)
*return

*label HackNetwork
*if already_hacked_nightfall
  You restore your connection to the Nightfall surveillance-and-traffic-cam system, and your laptop screen lights up with a tile of screens depicting various places in the ${v_loc}.
*if not(already_hacked_nightfall)
  *set already_hacked_nightfall true
  Leaving your home to search your area and gather information involves substantial risk to your survival, but you know one way to view your neighborhood and surrounding locations without leaving the safety of your home.
  
  *if not(hacker)
    While learning about common network systems flaws, you spent time about a year ago testing theories and cracking techniques on a real-world model—Nightfall's electronic infrastructure. What you uncovered was a system with abundant security flaws and opportunities for invasion. You were able to not only use the city's surveillance cams, but you could control them, along with the traffic lights.
    
    When you finished using the network for learning purposes, you
    *if morality >= 65
       provided an anonymous report to the city's system administrators. To this date, few of the flaws have been fixed.
    *if (morality > 35) and (morality < 65)
      kept the exploits and routes of access in safe keeping.
    *if morality <= 35
      kept the exploits and routes of access filed away for future use for yourself, or maybe even to the highest bidder.
  *if hacker
    A year ago, you
    *if morality >= 65
      received a commission from the Nightfall City Council to find exploits and security flaws in the city's infrastructure. At that time, you were given free reign to hack into their traffic cameras, video surveillance systems, and other municipal monitoring systems. While you documented dozens of problems for the city to take care of, a routine follow-up a month ago revealed less than half of them had been fixed. That means access still exists for anyone who knows how to get into those networks.
    *if (morality > 35) and (morality < 65)
      worked with a security company to find exploits and flaws in Nightfall's electronic infrastructure. Your client, a competitor of Nightfall's current virtual security vendor, provided your report to the city council, but they chose not to hire your client despite the evidence of dozens of holes in their systems. You retained access to the city's networks, and none of the security flaws were fixed.
    *if morality <= 35
      were hired by a local crime family to infiltrate the city's monitoring systems and provide them the tools to control traffic cameras and police surveillance systems. Months after you provided the access, the largest art heist in Colorado history was reported, and it occurred in Nightfall. During a tour stop in Nightfall's new Milford Museum of Art (now closed), hundreds of rare works of art were stolen. Reports revealed that the thieves monitored police activities through their own supposedly secure channels, bombarded them with fake 911 calls, and diverted them away from the museum. While the crew loaded and escaped in getaway vans, the path was cleared by routing traffic away while responding police vehicles were tied up. 
      
      Fortunately for you, few of the security holes you used for this job were fixed by the city.

*if chapter_point = 1
  *set timecount +50
  You bring up a series of cameras across your screen, tiled for simultaneous viewing. At first, you focus your attention on your
  *if v_loc = "city"
    neighborhood, bringing up a traffic camera as close as the avenue just down the street from your house. Traffic is flowing normally, though most cars are speeding or driving erratically. A pair of civilians in plain clothes cross the street at a red light, both carrying semiautomatic rifles normally used by the military or SWAT team members. In another camera, police surround a row home in yellow tape, and a team of coroners enters the residence. On yet another camera, a trio of National Guard soldiers set up a blockade to the highway on-ramp, restricting access to a main route out of Nightfall.
  *if v_loc = "suburbs"
    community, bringing up traffic cameras on the main avenue near your home. State police have one end blocked off and are allowing only one lane of traffic to pass. Two officers stop each vehicle and check inside with handguns drawn and ready. At the other end of the road, three cars sit in the crosswalk of an intersection, their front ends smashed together. The largest vehicle, a minivan, has a caved-in front end, and smoke rises from its bent hood. A small sports car has the back torn off, and its driver staggers toward the sidewalk. The last car, a luxury sedan, has a cracked windshield covered in a spray of blood.
  *if v_loc = "country"
    community, scanning through traffic cameras for action. Most of the screens show normal activity, though traffic moves out of Stodgy Farms at a faster rate than normal, and police are showing in greater numbers. You pull up one camera outside the River Junction Farmer's Market, where a sea of people crowd the area, buying up anything not nailed down. The vendors can barely keep up with the demands of customers, and theft is rampant. Watching for a short time, you even spot a woman with three small children plucking vegetables from a stand and hiding them in her toddler's stroller.
  
  A flurry of activity catches your eye on the bottom right of your monitor, and you click the small image to go full-screen. A firefighter in full gear aims a hose at a burning house as a figure rushes him from behind. The action is quick and brutal, and you watch with unwavering focus as the female figure tackles the firefighter and claws away his helmet. Her head rises and mouth opens wide to show jagged teeth and bloody saliva, and in that moment, you notice the cracked yellow skin with green lesions. She drives her teeth into the back of his head and tears away a patch of skin and hair. Without audio from the camera, you can only imagine the screams. The hose he held sways and undulates like a moving snake, pouring water across the pavement. The downed firefighter gurgles and spits as his head thrashes. 
  
  From the right of the screen, another firefighter rushes over to his fallen comrade and kicks the attacker. The infected woman's torso curls from the impact, but she continues her assault. The firefighter, who's tall and thick like Jaime, grabs the woman and yanks her arm, but she clings to her victim like a jackal on a carcass, her mouth full of flesh. Jaime's twin slips on the puddle of water and drops the zombie woman. Enraged, he struggles to stand in the weight of his soaked suit and grabs a fire ax from the side of his truck. With one long swing, he buries the blade into her shoulder, cleaving off the limb, which dangles by a thread of tendon and skin. This still doesn't deter the woman. The firefighter winds up to the side of his body and slashes the ax once more, hitting her in the head.
  
  Static fills the camera screen, and you refresh the window. As the connection restores, you notice your laptop battery at 11%, so you log out for now. With power to your home fluctuating, it's best to recharge now while some electricity remains.
  *return
*elseif chapter_point = 2
  *set timecount +75
  The first row of windows shows the main 
  *if v_loc = "city"
    avenue flowing through the center of Nightfall. Police and the National Guard man roadblocks, cutting off traffic leaving or entering the city. Emergency vehicles drive through neighborhoods, patrolling and searching. The citizens of your city are armed and vigilant, traveling in groups and wary of one another.
  *if v_loc = "suburbs"
    road leading through your development. Most of the traffic lights show a steady flow of cars, though few are obeying the rules of the road. A single police car patrols your neighborhood, appearing and disappearing across your screens as it passes traffic cams. It's not until it stops in front of the last camera that you realize the police officer wears civilian clothes.
  *if v_loc = "country"
    road leading through Stodgy Farms. Most of the traffic flows away from Nightfall and leads toward the highway. Cars zoom at high speeds, ignoring traffic signs. Around the bend at Tanner's farm, you spot a sports car smashed into a telephone pole, a victim of the winding road. The driver lies inside, his leg twisted and pierced by the wreckage, as an ambulance pulls up.
    
    On another row of screens, traffic cams show the merging of the highway and on-ramp leading south. Cars and trucks jam the lanes, while the National Guard and state police keep some semblance of order. Still, speeding cars ride the shoulder until blocked or stopped, and in the short time you watch, two groups engage in a gunfight at the edge of an exit ramp.
  *if v_loc != "country"
  
    Another row of cameras focuses upon the area between Nightfall and Chipper Ridge. On one screen, a Red Cross vehicle lies on its side, windows broken, doors open, a trail of blood leading away from the wreckage to the corner of a building and out of view. On another screen, a pack of infected stroll through Civic Center Park near City Hall. They hobble along the cobblestone path like they're scouting for a perfect spot for a
    *if timecount < 1200
      morning
    *if timecount >= 1200
      midday
    picnic.
    
    On still another screen, a row of cars wait for fuel at a gas station. At the head of the line, a stout man on a motorcycle bypasses the lead car, pulls out a pump, and fills his vehicle. The attendant argues with him, and the stout man punches him square in the face, knocking him out.
  *comment end/
  
  A developing scene in the last camera window catches your eye—a military jeep with a machine gun mounted on the back swerving to a stop in front of a van of people.
  *if followed_lj
    *set dillan "Dillan"
    *set rosie "Rosie"
    *set driver "Driver"
    You recognize them immediately: Rosie on the mounted gun, Driver at the wheel, and Dillan riding shotgun.
    
    From the front seat, Dillan hops out of the jeep and swings around his weapon, 
  *if watched_satellite = 2
    You recognize them immediately as the three bandits from the feed earlier, when you spied on Lyle and Jillian. 
    
    From the front seat, one of the men hops out of the jeep and swings around his weapon, 
  *if jillian_join and ((followed_lj = false) and (watched_satellite != 2))
    You peer into the screen. Could these be the same three bandits who attacked Lyle and Jillian earlier?
    
    From the front seat, one of the men hops out of the jeep and swings around his weapon, 
  *if (jillian_join = false) and ((followed_lj = false) and (watched_satellite != 2))
    A woman with flowing red hair stands at the
    *if ranged >= 45
      .50 caliber
    *if ranged < 45
      heavy 
    machine gun and bounces on the back. Neither the woman nor the two men in the front seats wear military uniforms, and as the jeep veers to a halt, the man in the passenger side hops from the vehicle, carrying
  *if ranged >= 45
    an FN P90,
  a futuristic-looking submachine gun with a blunt barrel and top-mounted magazine.
  
  The van doors open and out step a pair of college-age men, and from the back come two women. Though you can't hear through the cameras, you see ${dillan} ordering the young group to the ground. One of the students, a tall blonde woman with a volleyball team shirt and gym shorts, stands by the van and shouts back at the bandit with the submachine gun. She yells and swings her hands around as she argues, but as she glances down at her friends on the ground, ${dillan} throws a fist into her midsection. She doubles over in pain. Her friends start to rise, but ${rosie} aims the mounted machine gun and shouts at them. The three shaken and angry students return to the edge of the sidewalk.
  
  $!{dillan} grabs the blonde student by her long ponytail and yanks her toward the jeep, throwing her into the back hatch. He wears a disturbing smile as he stares at her athletic body, and as she tries to move away from the jeep, the lead bandit shoves her into the back next to the machine-gun mount.
  
  And then the feed drops.
  *page_break
  Static fills the camera for a few seconds, so you refresh the screen. When the connection restores, ${rosie} and ${dillan} are in a heated exchange. The red-haired bandit points to the college woman in the back of the jeep and motions for her to leave, while ${dillan} blocks her from leaving. While they argue, ${driver} rocks back and forth, covering his face with his arm.
  
  Again the camera screen distorts, and this time it dumps the feed. You try to reset the camera remotely, but now you can't even see it on the network. You open a new terminal window and feverishly type commands to locate another camera in the area. You can't work fast enough, and a full minute passes as you search for a way to watch the bandits. Finally, you find a camera atop a bank across the intersection, and when you connect, you see the image of the scene from farther away. All four students are sitting on the curb, including the blonde with the volleyball shirt. $!{driver} takes a few bags and a cooler from the van to the jeep, and ${dillan} sits in the jeep's passenger seat, staring at the four held students. You focus on ${rosie}, who remains in the back of the jeep, still operating the machine gun, but her demeanor has changed. She stares down at ${dillan}, her eyebrows narrowed and forming a V, her cheeks as red as her hair, and her mouth drawn into a thin line. She aims the barrel in a slow arc towards ${dillan}'s back, but when he glances up, she swings the weapon away.
  
  This goes on for a while until ${driver} finishes looting the van. Once finished, the bandits drive away, and you finish your session of camera watching.
  *return
*else
  *set timecount +25
  You log into the system but can't connect. The servers are unreachable, and even when you scan for systems on the Nightfall's security network, nothing shows up. Only a few days into the outbreak and city services are failing.
  
  After a few more minutes of unsuccessful attempts to connect, you abandon the task.
  *return
  
*label RoofPanels
*set got_panels true
*set timecount +25
You head upstairs to the back hallway where the right-corner window overlooks the yard. Directly past the window is a small ledge you've used in the past to access the roof.
*if fear_heights
  *set stress %+(round((100-wil)/5))
  You look outside and immediately turn away at the sight of the ground far below. Your stomach turns, and you feel mind-wrenching dizziness.
  *if wil < 65  
    There's no way you can overcome your fear of heights to retrieve those solar panels. You turn away from the window and head downstairs.
    *return
  Despite the anxiety, you know you need to do this, so you'll just have to overcome your fear of heights.
*set solar_panels +2
You pop open the window and step onto the ledge, following it up a short stretch of incline to the roof. 
*if fear_heights
  It takes all of your willpower not to look at the ground and run back inside.
Your home's solar panels sit squarely in the middle of one side of the sloped roof where the most sunlight hits. Only needing a few panels, you take two which should have no effect on the power to your home.
*return
  
*label TrainDog
*set dog_command true
*set timecount +50
Training a dog can take weeks or months for even a simple task to be performed on command, but ${pet_name} has always proven to be highly teachable. You've been working with him over the past few months to teach him to obey simple commands, and though he listens and obeys, you must reinforce his training every so often.

You bring him into the living room and grab a few of his favorite training treats. Unfortunately, there's only a handful left—enough for this training session, but not enough to use for a meal. 
*if dependent and dep_home
  
  "Can I help?" ${dep_name} asks, kneeling before your attentive dog.
  
  *if dep_treat >= 60
    "Sure," you say and hand him a few treats.
  *if (dep_treat < 60) and (dep_treat > 40)
    "You can watch, but let me do the actual training," you say.
  *if dep_treat <= 40
    "No, just sit and watch if you want, but I need to do this alone," you say.
*if lyle_and_jillian_join and (chapter_point = 2)

  Jillian sits on the floor ten feet away and watches with a smile, but Lyle seems uninterested in the training.

${pet_name}'s tail spins in a circle of excitement as you lead him through a series of commands: stay, sit, come, and heel, all of which will come in very handy should one of the infected cross your path, or even in dealing with a survivor of the outbreak. Each successful time he obeys, he receives a treat, and as you continue the practice, the reward matters less and less as the actions become habitual. After thirty minutes of working with ${pet_name}, he listens with attention and performs the action with faithful obedience.
*return

*label waterUse
*set out_of_water false
*if pet_owner and (w_water = 0)
  *set out_of_water true
*if pet_owner and (w_water >= 1)
  *set w_water -1
*if dependent and (w_water < 2)
  *set out_of_water true
*if dependent and (w_water >= 2)
  *set w_water -2
*if w_water < 3
  *set out_of_water true
*if w_water >= 3
  *set w_water -3
*if out_of_water
  *set fatigue %+(round((100-sta)/5))
  *set stress %+(round((100-wil)/5))
  You look through your inventory for water to drink, but you don't have any left. 
  *if water_message
    *set water_message false
    Without enough water to drink, you will succumb to fatigue and your mental awareness and acuity will diminish. After several days without water, you will die.
*return

*label CheckTraps
*set timecount +50
You check your
*if num_of_traps = 1
  trap
*if num_of_traps > 1
  traps
and find
*if already_trapped_part1
  no
  *if num_of_traps = 1
    animal
  *if num_of_traps > 1
    animals
  caught. You will have to check on
  *if num_of_traps = 1
    it
  *if num_of_traps > 1
    them
  tomorrow.
  *return
*set already_trapped_part1 true
*if num_of_traps = 1
  it contains
  *if placed_small_trap = 1
    a squirrel.
  *if placed_medium_trap = 1
    a rabbit.
  *if placed_large_trap = 1
    an opossum.
  You humanely kill the animal and reset the trap. Once killed, you cut out the internal organs, careful not to pierce them, and skin the hide. Carving away the meat, you acquire
  *if placed_small_trap = 1
    *set w_food +5
    five
  *if placed_medium_trap = 1
    *set w_food +8
    eight
  *if placed_large_trap = 1
    *set w_food +10
    ten
  portions of food.
  *return
*else
  *if num_of_traps = 2
    they
  *if num_of_traps > 2
    two of them
  contain
  *if placed_large_trap > 1
    an opossum and a badger. You humanely kill the animals and reset the traps. Once killed, you cut out the internal organs, careful not to pierce them, and skin the hides. Carving away the meat, you acquire twenty portions of food.
    *set w_food +20
    *return
  *elseif (placed_medium_trap > 0) and (placed_large_trap > 0)
    an opossum and a rabbit. You humanely kill the animals and reset the traps. Once killed, you cut out the internal organs, careful not to pierce them, and skin the hides. Carving away the meat, you acquire eighteen portions of food.
    *set w_food +18
    *return
  *elseif placed_medium_trap > 1
    a weasel and a rabbit. You humanely kill the animals and reset the traps. Once killed, you cut out the internal organs, careful not to pierce them, and skin the hides. Carving away the meat, you acquire sixteen portions of food.
    *set w_food +16
    *return
  *elseif (placed_large_trap > 0) and (placed_small_trap > 0)
    an opossum and a squirrel. You humanely kill the animals and reset the traps. Once killed, you cut out the internal organs, careful not to pierce them, and skin the hides. Carving away the meat, you acquire fifteen portions of food.
    *set w_food +15
    *return
  *elseif (placed_medium_trap > 0) and (placed_small_trap > 0)
    a rabbit and a squirrel. You humanely kill the animals and reset the traps. Once killed, you cut out the internal organs, careful not to pierce them, and skin the hides. Carving away the meat, you acquire thirteen portions of food.
    *set w_food +13
    *return
  *else
    a muskrat and a squirrel. You humanely kill the animals and reset the traps. Once killed, you cut out the internal organs, careful not to pierce them, and skin the hides. Carving away the meat, you acquire ten portions of food.
    *set w_food +10
    *return
    
*label CheckZKills
*if (zombie_kills >= 10) and (z_achieve = 0)
  *set z_achieve +1
  *achieve zombiekiller
*if (zombie_kills >= 20) and (z_achieve < 2)
  *set z_achieve +1
  *achieve zombieslayer
*if (zombie_kills >= 30) and (z_achieve < 3)
  *set z_achieve +1
  *achieve zombieslaughter
*if (zombie_kills >= 40) and (z_achieve < 4)
  *set z_achieve +1
  *achieve zombiedemo
*if (zombie_kills >= 50) and (z_achieve < 5)
  *set z_achieve +1
  *achieve zombieext
*return

*label GasGeneratorSetUp
*set house_powered true
*set gas_gen_set true
*set generator -1
*set gasoline_cans -1
Having a generator available, you plan to make use of it
*if chapter_point = 2
  should the power go out.
*if chapter_point = 3
  now that the power is out.

You carry the generator outside to the yard along with the tools you'll need.
*if woody_home
  Before you start working, Woody wanders out to help.
Hooking the generator up is no easy task, but over the course of
*if woody_home
  *set timecount +75
  forty-five minutes, along with your guest's help,
*if not(woody_home)
  *set timecount +100
  the next hour,
you connect the machine to your house's electrical power breaker. You load it up with gasoline and turn it to ready mode.
*if chapter_point = 2
  In the event of a power outage, the generator should kick in.
*if chapter_point = 3
  Starting the generator, you can almost see your home come back to life.

With your work done, you head back inside your home.
*if laptop_powered = false
  *set laptop_powered true
  The blinking power light on your laptop shows it's charging.
*return

*label SetUpGenerator
*set house_powered true
*set solar_gen_set true
*set solar_powered_generators -1
Having crafted the generator to run on solar power, you plan to make use of it
*if chapter_point = 2
  should the power go out.
*if chapter_point = 3
  now that the power is out.

You carry the generator outside to the yard along with the tools you'll need. Finding a spot without shade or obstruction, you aim the solar panel so it gathers as much sunlight as possible. 
*if woody_home
  Before you start working, Woody wanders out to help.
Hooking the generator up is no easy task, but over the course of
*if woody_home
  *set timecount +75
  forty-five minutes, along with your guest's help,
*if not(woody_home)
  *set timecount +100
  the next hour,
you connect the machine to your house's electrical power breaker.
*if chapter_point = 2
  In the event of a power outage, the generator should kick in.
*if chapter_point = 3
  Starting the generator, you can almost see your home come back to life.

With your work done, you head back inside your home.
*if laptop_powered = false
  *set laptop_powered true
  The blinking power light on your laptop shows it's charging.
*return

*label EatCandy
*set had_candy true
You take out a piece of candy and stare at the wrapper. It's so simple, but will definitely hit the spot.
*if dependent and (dep_home and (shared_snack = false))
  *set shared_snack true
  As you go to eat it, your nephew looks up from his comic.
    
  "Can I have some?"
  *choice
    *selectable_if (candy > 1) #Take out an extra piece for ${dep_name}.
      *set candy -2
      *set stress %-(round(wil/7))
      *set fatigue %-(round(sta/5))
      *label CandyDep
      *set candy_with_dep true
      *set morality %+10
      *set humanity %+5
      *set dep_faction %+(round(empathy/5))
      *set dep_treat %+10
      You hand the piece over, and your nephew rips open the wrapper. 
        
      "Thanks!" he says.
      
      You enjoy the morsel for the few moments it lasts.
      *return
    #Split the candy in half and give a piece to ${dep_name}.
      *set stress %-(round(wil/10))
      *set fatigue %-(round(sta/7))
      *set morality %+10
      *set ideal %-10
      *set candy -1
      *goto CandyDep
    #Give the candy to ${dep_name} and have none myself.
      *set morality %+15
      *set humanity %+10
      *set honor %+15
      *set stress %-(round(wil/10))
      *set fatigue %-(round(sta/7))
      *set dep_faction %+(round(empathy/5))
      *set dep_treat %+10
      *set candy_with_dep true
      *set candy -1
      You stare at the candy and hand it to ${dep_name}. He looks it over for a moment, breaks it in half and hands a piece to you. "We can share."
        
      You take the morsel of candy and enjoy it for the few moments it lasts.
      *return
    #"Sorry, last piece," I say.
      *set morality %-15
      *set dep_treat %-10
      *set dep_faction %-(round(25-(empathy/5)))
      *set stress %-(round(wil/7))
      *set fatigue %-(round(sta/5))
      *set candy -1
      Your nephew lets out a deep sigh and watches you eat the entire piece.
      *return
    #"Go get your own," I say.
      *set honor %-10
      *set dep_treat %-20
      *set dep_faction %-(round(30-(empathy/10)))
      *set stress %-(round(wil/7))
      *set fatigue %-(round(sta/5))
      *set candy -1
      Your nephew's face turns red, and he looks away as you enjoy eating the entire piece.
      *return
*else
  *set stress %-(round(wil/7))
  *set fatigue %-(round(sta/5))
  *set candy -1
  It doesn't last long but definitely satisfies your craving, and you even find yourself licking your fingers afterwards.
  *return

*label DrinkCoffee
*set coffees -1
*set had_coffee true
You
*if (chapter_point >= 3) and ((v_loc != "suburbs") and (house_powered = false))
  *set stress %-(round(wil/7))
  *set fatigue %-(round(sta/7))
  lift the cold cup of coffee. Though you can't heat it, the
*if (chapter_point < 3) or ((v_loc = "suburbs") or house_powered)
  *set stress %-(round(wil/4))
  *set fatigue %-(round(sta/4))
  heat up a cup of coffee, enjoying the aroma even before it's ready. The 
caffeine is surely welcome, and a coffee break reminds you of more normal times.
*if dependent and (dep_home and (shared_snack = false))
  *set shared_snack true
  *if teenager or college_student
    As you go to drink it, your nephew looks up from his comic.
    
    "Are you allowed to drink coffee?
    *if teenager
      It's for adults."
    *if college_student
      You're not really an adult yet."
    *if short_fuse
      Your anger swells at the thought of being questioned by an eight-year-old.
      *if wil >= 60
        You take a deep breath to calm down, as your temper sometimes makes you snap at such statements.
      *if wil < 60
        *set stress %+(round((100-wil)/10))
        You can barely control your sudden rage.
    *choice
      *selectable_if (short_fuse = false) #"I can do whatever I want now. Who's going to stop me?"
        *set honor %-10
        Your nephew tilts his head to the side and squints with one eye. "So does that mean I can do whatever I want too?"
        *fake_choice
          #"Yep, you can do anything within reason."
            *set ideal %+10
            *set dep_faction %+(round(empathy/5))
            *set dep_treat %+10
            "Cool," ${dep_name} says and taps a finger to the side of his head, deep in thought.
          #"Well, we still have to abide by the law and be good people."
            *set honor %+10
            *set dep_faction %+(round(empathy/5))
            *set dep_treat %+10
            "That's true," ${dep_name} says and picks up his comic.
          #"No, I decide what you can and cannot do."
            *set honor %-10
            *set dep_faction %-(round(25-(empathy/5)))
            ${dep_name} frowns and looks away. "Oh."
          #"I guess. Can you stop asking me questions?"
            *set morality %-10
            *set ideal %-10
            *set dep_treat %-10
            *set dep_faction %-(round(25-(empathy/5)))
            ${dep_name} frowns and looks away. "Yeah."
        *goto EndCoffee
      *selectable_if (short_fuse = false) #"I am an adult."
        *set truth %+10
        Your nephew's forehead wrinkles, and he shrugs. "I guess."
        *goto EndCoffee
      #"Mind your business!" I snap.
        *set impulse %+10
        *set dep_treat %-10
        *set dep_faction %-(round(25-(empathy/5)))
        Your nephew's cheeks turn red, and he picks up his comic and covers his face.
        *goto EndCoffee
      #"Can I enjoy a cup of coffee without you questioning what I'm doing?"
        *set ideal %-10
        *set dep_faction %-(round(25-(empathy/5)))
        Your nephew's cheeks turn red, and he picks up his comic and covers his face.
        *goto EndCoffee
      *selectable_if (short_fuse = false) #"Coffee is actually good for you," I say. "Want some?"
        *set ideal %+10
        *set dep_treat %+10
        *set dep_faction %+(round(empathy/5))
        "No thanks," your nephew says, wrinkling his nose and mouth. "Coffee's gross. It smells like old shoes."
        *goto EndCoffee
  *else
    Your nephew walks into the kitchen and stares at your steaming mug. "Is that coffee?"
    
    *if ideal >= 60
      "Sure is, and I'm really looking forward to it,"
    *if (ideal >= 40) and (ideal < 60)
      "Yes it is,"
    *if ideal < 40
      "Yeah. At least I can still have one thing I enjoy during this outbreak,"
    you say and take a sip of the hot liquid. It spreads through your chest as it goes down.
    
    "Mom used to drink coffee," he says in an even tone, neither happy nor sad.
    *fake_choice
      #"You're right, she really loved coffee," I say, keeping the conversation positive.
        *set ideal %+10
        ${dep_name} smiles and traces an imaginary figure with his index finger on the table.
      #"I wish she was having a cup with me right now," I say, saddened at the loss of my sister. "I really miss her."
        *set ideal %-10
        ${dep_name}'s lower lip trembles as he stares at the table and traces an imaginary figure with his index finger.
      #"You drink coffee too, right? Ten cups a day?" I say to make him laugh.
        *set truth %-10
        ${dep_name} breaks out into a wide grin, and his eyes go wide. "No! I don't drink coffee."
        
        "That's not what I heard. From what people tell me, you drink it all day and night."
        
        This brings out hard laughter from your nephew. "No I don't. You're crazy."
      #"I don't remember," I say. I wish he wouldn't bring up my sister. Any memory of her is painful.
        *set honor %-10
        ${dep_name}'s lower lip trembles as he stares at the table and traces an imaginary figure with his index finger.
      #I say nothing. No sense thinking about the past.
        *set morality %-10
        ${dep_name} stares at the table and traces an imaginary figure with his index finger.
    *label EndCoffee
    
    You sit at the kitchen table and sip the warm beverage, feeling like nothing else matters as long as the cup lasts.
    *return
*else
  You sit at the kitchen table and sip the warm beverage, feeling nothing else matters while the cup lasts.
  *return

*label DrinkSoda
*set had_soda true
You pop open a can of soda and listen for a moment to the fizz. Caffeine will definitely feel good right now. Any boost will help get you through one more hour of the apocalypse.
*if dependent and (dep_home and (shared_snack = false))
  *set shared_snack true
  
  *if candy_with_dep
    Your nephew picks up a comic as you drink. "Soda isn't good for me."
    *set stress %-(round(wil/7))
    *set fatigue %-(round(sta/4))
    *return
  *else
    As you go to drink it, your nephew looks up from his comic.
    
    "Can I have some?"
    *choice
      *selectable_if (sodas > 1) #Take out an extra can for ${dep_name}.
        *set sodas -2
        *set stress %-(round(wil/7))
        *set fatigue %-(round(sta/4))
        *set morality %+10
        *set humanity %+5
        *set dep_faction %+(round(empathy/5))
        *set dep_treat %+10
        You hand the can over, and your nephew pops open the top. 
        
        "Thanks!" he says and takes a huge gulp of the brown, bubbly liquid.
        
        The soda only lasts a short time, but the jolt of the caffeine lifts your spirits and provides a boost of energy.
        *return
      #Split the can in half to give a share to ${dep_name}.
        *set stress %-(round(wil/10))
        *set fatigue %-(round(sta/7))
        *set morality %+10
        *set sodas -1
        You pour half the soda into a cup and hand your nephew the half-filled can.
        
        "Thanks!" he says and takes a huge gulp of the brown, bubbly liquid.
        
        Your half only lasts a short time, but the jolt of the caffeine lifts your spirits and provides a boost of energy.
        *return
      #Give the soda to ${dep_name} and have none myself.
        *set morality %+15
        *set humanity %+10
        *set honor %+15
        *set dep_faction %+(round(empathy/5))
        *set dep_treat %+10
        *set stress %-(round(wil/10))
        *set fatigue %-(round(sta/7))
        *set sodas -1
        You stare at the can and hand it to ${dep_name}. He looks it over for a moment, grabs a clean glass from the cupboard, pours half the soda into it, and hands the glass to you. "We can share."
        
        Your half only lasts a short time, but the jolt of the caffeine lifts your spirits and provides a boost of energy.
        *return
      #"Sorry, last one," I say.
        *set morality %-15
        *set dep_treat %-10
        *set dep_faction %-(round(25-(empathy/5)))
        *set stress %-(round(wil/7))
        *set fatigue %-(round(sta/4))
        *set sodas -1
        Your nephew lets out a deep sigh and watches you drink the entire soda.
        *return
      #"Go get your own," I say.
        *set honor %-15
        *set dep_treat %-20
        *set dep_faction %-(round(30-(empathy/10)))
        *set stress %-(round(wil/7))
        *set fatigue %-(round(sta/4))
        *set sodas -1
        Your nephew's face turns red, then he looks away as you enjoy drinking the entire soda.
        *return
*else
  *set stress %-(round(wil/7))
  *set fatigue %-(round(sta/4))
  *set sodas -1
  The soda only lasts a short time, but the jolt of the caffeine lifts your spirits and provides a boost of energy.
  *return
  
*label CalcAllegiance
*temp faction_average 0
*temp faction_total 0
*set faction_total +(bailey_faction)
*set faction_total +(brody_faction)
*set faction_total +(jaime_faction)
*set faction_total +(kelly_faction)
*set faction_total +(madison_faction)
*set faction_total +(nora_faction)
*set faction_total +(rachel_faction)
*set faction_total +(reilly_faction)
*if ben_join
  *set faction_total +(ben_faction)
*if church_join
  *set faction_total +(church_faction)
*if dante_join
  *set faction_total +(dante_faction)
*if driver_join
  *set faction_total +(driver_faction)
*if gina_join
  *set faction_total +(gina_faction)
*if jillian_join
  *set faction_total +(jillian_faction)
*if lopez_join
  *set faction_total +(lopez_faction)
*if nathan_join
  *set faction_total +(nathan_faction)
*if parker_join
  *set faction_total +(parker_faction)
*if rosie_join
  *set faction_total +(rosie_faction)
*if tommy_join
  *set faction_total +(tommy_faction)
*if woody_join
  *set faction_total +(woody_faction)
*set faction_average (round(faction_total/num_of_survivors))
*set allegiance %+((faction_average-40)*2)
*return

*label CalcMorale
*temp faction_average 0
*temp faction_total 0
*set faction_total +(bailey_faction)
*set faction_total +(brody_faction)
*set faction_total +(jaime_faction)
*set faction_total +(kelly_faction)
*set faction_total +(madison_faction)
*set faction_total +(nora_faction)
*set faction_total +(rachel_faction)
*set faction_total +(reilly_faction)
*if ben_join
  *set faction_total +(ben_faction)
*if church_join
  *set faction_total +(church_faction)
*if dante_join
  *set faction_total +(dante_faction)
*if driver_join
  *set faction_total +(driver_faction)
*if gina_join
  *set faction_total +(gina_faction)
*if jillian_join
  *set faction_total +(jillian_faction)
*if lopez_join
  *set faction_total +(lopez_faction)
*if nathan_join
  *set faction_total +(nathan_faction)
*if parker_join
  *set faction_total +(parker_faction)
*if rosie_join
  *set faction_total +(rosie_faction)
*if tommy_join
  *set faction_total +(tommy_faction)
*if woody_join
  *set faction_total +(woody_faction)
*set faction_average (round(faction_total/num_of_survivors))
*set morale %+((50-faction_average)*2)
*return

*label CheckpointSave
*temp slot 0
You have reached @{game_milestone a milestone in the game|the end of a chapter}. Now would be a good time to save a checkpoint.

Which slot do you want to save?
*choice
  #Slot 1: ${save_name_1}
    *set slot 1
    *goto SaveName
  #Slot 2: ${save_name_2}
    *set slot 2
    *goto SaveName
  #Slot 3: ${save_name_3}
    *set slot 3
    *goto SaveName
  #I don't want to save. ([b]For advanced players[/b])
    *set game_milestone false
    *return
*label SaveName
What do you want to call your saved game?
*input_text save_name[slot]
  
Checkpoint saved!
*if slot = 1
  *save_checkpoint slot1
*if slot = 2
  *save_checkpoint slot2
*if slot = 3
  *save_checkpoint slot3
*set game_milestone false
*return