*comment ñáéç
*gosub_scene util check_flow
*label stat_chart
*temp west_prob false
*temp imposter "the imposter"
*if implicit_control_flow = false
	Unfortunately, your game is out of date. Please restart.
	*page_break Restart
	*restart
*if m_sib and patricide
	*set west_prob true
	*if stl_heard_of_wotton
		*set imposter "Wotton"
*text_image stats_header.png center Choice of the Vampire
Vampire Name: ${given_name} ${surname}
*line_break
@{(lore > 1) Dominus|Maker}: $!{sire_name}
*line_break
Choice of Prey: $!{feeding_style}
*line_break
*if presented_st_louis
	Bloodflow: ${bloodflow}
	*line_break
*set income round(income)
Income (US$2012): ${income}
*line_break
*set wealth round(wealth)
Wealth (US$2012): ${wealth}
*line_break
*if municipal_debt > 0
	Face Value of Memphis Municipal Bonds (US$1873): ${municipal_debt}
*if amount_invested_freedmans > 0
	*line_break
	*temp display_freedmans round(amount_invested_freedmans/17)
	Face Value of Freedman's Bank Bonds (US$1873): ${display_freedmans}
*if learned_about_revolution

	Revolutionary Reputation:
	*if year >= 1879
		*if revolutionary_credentials > 70
			An ardent Revolutionary.
		*elseif revolutionary_credentials > 55
			A Revolutionary sympathizer.
		*elseif revolutionary_credentials >= 45
			Uncomitted or indifferent.
		*elseif revolutionary_credentials >= 30
			A Loyalist sympathizer.
		*else
			An ardent Loyalist.
	*else
		*if revolutionary_credentials > 70
			An ardent supporter of Stone.
		*elseif revolutionary_credentials > 55
			A Stone sympathizer.
		*elseif revolutionary_credentials >= 45
			Uncommitted or indifferent.
		*elseif revolutionary_credentials >= 30
			Resistant to Stone's revolution.
		*else
			Ardent Opponent of Stone's revolution.
*if shepherds_and_wolves
	*line_break
	Shepherd and Wolf Reputation: 
	*if shepherd_credentials > 70
		Ardent Shepherd
	*elseif shepherd_credentials > 55
		Moderate Shepherd
	*elseif shepherd_credentials >= 45
		Opportunist
	*elseif shepherd_credentials >= 30
		Moderate Wolf
	*else
		Ardent Wolf
*temp languages ""
*temp comma false
*line_break
Literate? @{literate Yes|No}.
*line_break
*if (ethnicity = "choctaw") and (year != 1750)
	*set languages &"Choctaw"
	*set comma true
*if speaks_english
	*if comma
		*set languages &", "
	*set languages &"English"
	*set comma true
*if speaks_french
	*if comma
		*set languages &", "
	*set languages &"French"
	*set comma true
*if speaks_german
	*if comma
		*set languages &", "
	*set languages &"German"
	*set comma true
*if speaks_latin
	*if comma
		*set languages &", "
	*set languages &"Latin"
	*set comma true
*if speaks_spanish
	*if comma
		*set languages &", "
	*set languages &"Spanish"
	*set comma true
*if languages != ""
	*set languages &"."
Language(s): ${languages}

*gosub_scene prestation checkHasDebt
*gosub_scene prestation checkOwesDebt
*if hasAnyDebt and (year > 1750)
	*temp debts ""
	*temp comma false
	*line_break
	*if debt_from_aichinger
		*if comma
			*set debts &", "
		*set debts &"Aichinger"
		*set comma true
	*if debt_from_bailey
		*if comma
			*set debts &", "
		*set debts &"Bailey"
		*set comma true
	*if debt_from_becard
		*if comma
			*set debts &", "
		*set debts &"Bécard"
		*set comma true
	*if debt_from_bjornsdotter
		*if comma
			*set debts &", "
		*set debts &"Björnsdotter"
		*set comma true
	*if debt_from_bowater
		*if comma
			*set debts &", "
		*set debts &"Bowater"
		*set comma true
	*if debt_from_coffin
		*if comma
			*set debts &", "
		*set debts &"Coffin"
		*set comma true
	*if debt_from_carothers
		*if comma
			*set debts &", "
		*set debts &"Carothers"
		*set comma true
	*if debt_from_memeskia and memeskia_alive
		*if comma
			*set debts &", "
		*set debts &"Memeskia"
		*set comma true
	*if debt_from_page
		*if comma
			*set debts &", "
		*set debts &"Page"
		*set comma true
	*if debt_from_rios and rios_alive
		*if comma
			*set debts &", "
		*set debts &"Rios"
		*set comma true
	*if debt_from_walker
		*if comma
			*set debts &", "
		*set debts &"Walker"
		*set comma true
	*if debt_from_withers
		*if comma
			*set debts &", "
		*set debts &"Withers"
		*set comma true
	Debts Held: ${debts}.
*if owesAnyDebt and (year > 1750)
	*temp favors ""
	*temp comma false
	*line_break
	*if debt_to_aichinger
		*if comma
			*set favors &", "
		*set favors &"Aichinger"
		*set comma true
	*if debt_to_bailey
		*if comma
			*set favors &", "
		*set favors &"Bailey"
		*set comma true
	*if debt_to_becard
		*if comma
			*set favors &", "
		*set favors &"Bécard"
		*set comma true
	*if debt_to_bowater
		*if comma
			*set favors &", "
		*set favors &"Bowater"
		*set comma true
	*comment *if debt_to_coffin
		*comment *if comma
			*comment *set favors &", "
		*comment *set favors &"Coffin"
		*comment *set comma true
	*if debt_to_carothers
		*if comma
			*set favors &", "
		*set favors &"Carothers"
		*set comma true
	*if debt_to_memeskia and memeskia_alive
		*if comma
			*set favors &", "
		*set favors &"Memeskia"
		*set comma true
	*comment *if debt_to_page
		*comment *if comma
			*comment *set favors &", "
		*comment *set favors &"Page"
		*comment *set comma true
	*if debt_to_rios and rios_alive
		*if comma
			*set favors &", "
		*set favors &"Rios"
		*set comma true
	*comment *if debt_to_walker
		*comment *if comma
			*comment *set favors &", "
		*comment *set favors &"Walker"
		*comment *set comma true
	*if debt_to_withers
		*if comma
			*set favors &", "
		*set favors &"Withers"
		*set comma true
	Debts Owed: ${favors}.

*stat_chart
	text Agility
	text Charm
	text Intelligence
	text Strength
	text Willpower
	text Creation
	text Fighting
	text Finance
	text Lore
	text Perception
	text Shapeshifting
	text Stealth
	text Status
	text Streetwise
	text Technology

*stat_chart
	opposed_pair Anachronism
		Adaptation
		Anachronism
	opposed_pair Compassion
		Callousness
		Compassion
	opposed_pair Discretion
		Hubris
		Discretion
	opposed_pair Independence
		Communalism
		Independence
	opposed_pair Rationalism
		Superstition
		Rationalism

*if year > 1750
	*temp object false
	Possessions of Note:
	*if (new_orleans_enterprise = 1) and (memphis_haven_torched = false)
		*set object true
		A small collection of books that are the epitome of Enlightenment theology and philosophy.
	*if tiozzo_portrait_1831 = 3
		*set object true
		A portrait of you by Lady Tiozzo, painted in 1831.
	*if kept_clotho_letter
		*set object true
		A letter from Clotho proclaiming her eternal love for you.
	*if kept_silas_letter
		*set object true
		A letter from Silas proclaiming his eternal love for you, as well as his harmonica.
	*if lockridge_treatise >= 3
		*set object true
		A copy of Lockridge's treatise on Shepherds and Wolves.
	*if photo_1884_circus > 1
		*set object true
		*if photo_1884_circus = 2
			A portrait photograph
		*if photo_1884_circus = 3
			A portrait photograph of you and Sabine Bécard
		*if photo_1884_circus = 4
			A portrait photograph of you and Hiram Eliot
		from P.T. Barnum's circus, taken in 1884.
	*if book_awakening
		*set object true
		A first edition copy of [i]The Awakening[/i], inscribed to you by Kate Chopin.
	*if book_dracula
		*set object true
		A first edition copy of [i]Dracula[/i].
	*if has_saw_manuscript = 3
		*set object true
		A manuscript copy of Eusebius of Damascus's dialogue, [i]Of Shepherds and Wolves,[/i] lent to you by Abel Bowater.
	*if has_saw_manuscript = 4
		*set object true
		A bound Latin copy of Eusebius of Damascus's dialogue, [i]Of Shepherds and Wolves.[/i]
	*if has_saw_manuscript = 5
		*set object true
		A bound, modern Latin transcription of Eusebius of Damascus's dialogue, [i]Of Shepherds and Wolves.[/i]
	*if has_saw_manuscript = 6
		*set object true
		A bound, English translation of Eusebius of Damascus's dialogue, [i]Of Shepherds and Wolves.[/i]
	*if has_saw_manuscript = 7
		*set object true
		A bound, French translation of Eusebius of Damascus's dialogue, [i]Of Shepherds and Wolves.[/i]
	*if has_saw_manuscript = 8
		*set object true
		A bound, German translation of Eusebius of Damascus's dialogue, [i]Of Shepherds and Wolves.[/i]
	*if has_saw_manuscript = 9
		*set object true
		A bound, Spanish translation of Eusebius of Damascus's dialogue, [i]Of Shepherds and Wolves.[/i]
	*if object = false
		None.

	*choice
		*if (choice_randomtest = false)
			*if (choice_saved_checkpoint_vicksburg) #I want to restore to a checkpoint.
				Where do you want to restore to?
				*choice
					*if (choice_saved_checkpoint_vicksburg) #Vicksburg.
						*restore_checkpoint vicksburg
					*if (choice_saved_checkpoint_memphis) #Memphis.
						*restore_checkpoint memphis
					*if (choice_saved_checkpoint_memphis_mid) #Memphis Midpoint.
						*restore_checkpoint memphis_mid
					*if (choice_saved_checkpoint_stlouis) #St. Louis.
						*restore_checkpoint stlouis
					*if (choice_saved_checkpoint_worldsfair) #The St. Louis World's Fair.
						*restore_checkpoint worldsfair
					#I want to restart my game.
						*restart
					#Nevermind, take me back to my game.
						*goto stat_chart
		*selectable_if (sire_name != "unknown") #View the Vampires' Gallery.
			*text_image vampires_gallery.png center Vampires' Gallery
			*goto rogues_gallery
		#View the Mortals' Gallery.
			*text_image mortals_gallery.png center Mortals' Gallery
			*goto mortals_gallery
*else
	*finish

*label rogues_gallery
*choice
	*if (heard_of_philomena or heard_of_buljan) or (heard_of_eusebius or heard_of_ethelmarr)
		#Ancients.
			*text_image vampires_gallery.png center Vampires' Gallery
			*if heard_of_buljan
			
				[b]Buljan[/b] was a bastard Khazar prince of Kyiv in life, and in death a storied beast-hunter. He is—or was—the dominus of West and Gudhrun Björnsdotter.
			*if heard_of_ethelmarr

				[b]Ethelmarr[/b] is the dominus of Arthur Lockridge.
			*if heard_of_eusebius

				[b]Eusebius of Damascus[/b] was a vampire philosopher.  His most famous work, [i]Of Shepherds and Wolves[/i] is considered a central philosophical text of vampires everywhere.
			*if read_dodecagram_scrap

				[b]Horemheb the Legate[/b] was a messenger of Pharoah, consumed by Adonis in the wake of the Battle of Actium.
			*if knows_sack_of_tyre
			
				[b]Muttunbaal the Anointed[/b] was the scion of Nenet the Ancient. She was also destroyed at the Siege of Tyre in 332 BCE.
			
				[b]Nenet the Ancient[/b] was the ruler of the Phoenicians, until she was destroyed at the Siege of Tyre in 332 BCE. 
			*if heard_of_philomena

				[b]Philomena of Ephesus[/b] was a vampire sibyl.  She committed suicide sometime in the first century CE.
			*if read_saw_manuscript
			
				[b]Pinikirid the Elamite[/b] was a vampire of Susa. She is one of the characters in [i]Of Shepherds and Wolves[/i].
				
				[b]Pulueser of Nineveh[/b] was a vampire of Nineveh. He is one of the characters in [i]Of Shepherds and Wolves[/i].
				
				[b]Shabaqo the Nubian[/b] was a vampire of Meroë. He is one of the characters in [i]Of Shepherds and Wolves[/i].
			*if heard_of_tryphon
			
				[b]Tryphon[/b] was a scion of Olympias. He relocated to Cap-Français in the hopes of creating a new Athens, but when his utopia began to crumble due to the uprisings of the enslaved Africans, he fled north. He fought with Memeskia in 1780—an encounter known to mortals as the Battle of Fort San Carlos—and sank into the earth to recuperate.
			*if (heard_of_tryphon = false) and (tryphon_identity > 1)
				
				A mystery vampire, a scion of Olympias, relocated to Cap-Français in the hopes of creating a new Athens. When his utopia began to crumble due to the uprisings of the enslaved Africans, he fled north. He fought with Memeskia in 1780—an encounter known to mortals as the Battle of Fort San Carlos—and sank into the earth to recuperate.
			*goto rogues_gallery
	*if met_jesse or met_estefania
		#Citizens.
			*text_image vampires_gallery.png center Vampires' Gallery
			*if heard_of_aichinger

				[b]Lothar Aichinger[/b] is a citizen of St. Louis.
				*if whiskey_ring_plot
					He was involved with the Whiskey Ring conspiracy in the early and mid 1870s.
				*if met_aichinger
					He is portly and mostly bald, with a bushy, mostly-gray mustache.  He is older, having likely been turned in his early fifties.
			*if presented_memphis

				[b]Dido Applethorp[/b] is the progeny of Apollo Carothers.  She is tall for a woman, and her hair is cut close to her scalp.  She is a former slave, and her often-bare arms are covered by a network of long-healed lashmarks. @{knows_applethorps_age She was born in 1815, and became a vampire in 1840.|}
			*if year > 1879
			
				[b]Sabine Bécard[/b] is a citizen of St. Louis, but she resides in Jefferson City. The offspring of Memeskia, she is the child of a French trapper and a Miami woman, and was turned in her early thirties. She keeps her extremely long hair in two braids.
			*if heard_of_bjornsdotter and (year <= 1882)
			
				[b]Gudhrun Björnsdotter[/b] is a citizen of St. Paul, Minnesota. @{heard_of_buljan She is the scion of Buljan.|}
			*if calkins_status > 1
			
				[b]Andrew Calkins[/b] @{(calkins_status < 4) is|was} a Quaker vampire. @{calkins_status |||You consumed his heartsblood.|He has been destroyed.|You decapitated him.}
			*if heard_of_crisp

				[b]John Crisp[/b] is the dominus of Wallace Winters.  He was a Catholic partisan in Reformation England.
			*if heard_of_draper
			
				[b]James Draper[/b] is a vampire from North Carolina. He travels with [b]Orelia Tiozzo[/b].
			*if heard_of_eliot
				
				[b]Hiram Eliot[/b] is a citizen of St. Louis.
				*if met_eliot
					He is of average height, with dark brown hair with a severe part, a wide face, and a large nose and ears.  He was turned sometime in his late twenties, and still possess a youthful vigor.
				*if year > 1904
					He was slain by West at the Louisiana Purchase Exhibition.
			*if heard_of_fragala and (year <= 1883)
				
				[b]Calogero Fragalà[/b] resides in Kansas City.
				*if met_fragala
					When he was alive, he was infected with leprosy. The disease continues to afflict him in death. He only recently arrived in the United States from Sicily.
			*if gould_plot > 2
			
				[b]Jason "Jay" Gould[/b] @{(gould_plot < 5) is|was} the scion of [b]Edwin Lefferts[/b]. In life, he was a railroad tycoon most famous for nearly cornering the gold market in 1869. @{(year > 1904) He was destroyed during the Louisiana Purchase Exposition.|}
			*if geronimo_vampire
			
				[b]Goyahkla[/b], called Geronimo, was a Chiricahua Apache leader and medicine man. He was apprehended by the US Army for a final time in 1886, and spent the next twenty years as a prisoner of war at Fort Sill, Oklahoma. Memeskia turned him into a vampire in the hope of inducing him to lead a rebellion against the United States.
			
			*if heard_of_krupke
			
				[b]Walter Krupke[/b] is a citizen of Savannah.
				*if met_overstreet
					He seems to be some sort of bodyguard for Governor Overstreet.
				*if met_krupke
					He is not terribly large, but it is easy to imagine him being competent in a fight.  He has sandy-blond hair, a lantern jaw, and a cleft chin.
			*if heard_of_lefferts
			
				[b]Edwin Lefferts[/b] is the broodmate of Siobhan Malloy@{heard_of_ogier  and the offspring of Arnoult Ogier|}.
			*if heard_of_lesczynski
			
				[b]Ascher Lesczynski[/b] is a citizen of New York, and is a candidate for Senator of Memphis.
				*if met_lesczynski and able_to_identify_jews
					He sports a kippah and payot.
				*if lesczynskis_interest_in_memphis
					He is very curious to learn more about circumstances surrounding the founding of Memphis.
				*if malloy_out
					He has professed his support for Isaiah Stone.
				*if pickering_out
					He has professed his opposition to Isaiah Stone.
			*if ((maddox_num = 1) and (chasing_wilson = false)) and (wilson_embraced or (wilson_embraced_by_withers and knows_wilson_embraced))
			
				*if wilson_embraced
					[b]Wilson Maddox[/b] is your offspring and your former mortal valet.
				*if wilson_embraced_by_withers
					[b]Wilson Maddox[/b] is the offspring of Samantha Withers, and your former mortal valet.  
				He is missing an ear from his days as a slave.
				*if (literate = false)
					Unlike many of his former peers, he is literate.  You @{wilson_embraced_by_withers were|are} grateful for this, @{wilson_embraced_by_withers as you relied|and you rely} on this skill often.
			*if heard_of_malloy
			
				[b]Siobhan Malloy[/b] is a citizen of Baltimore, and @{(year > 1878) was|is} a candidate for Senator of Memphis.
				*if met_malloy
					She is a redheaded Irishwoman, with a laugh like baritone windchimes: throaty, deep, and melodic.
				*if heard_of_ogier and (knows_ogier_heretic = false)
					She is the progeny of Arnoult Ogier, a Hugenot vampire from New Paltz.
				*elseif heard_of_ogier
					She is the progeny of Arnoult Ogier, a Hugenot vampire from New Paltz, who was accused of heresy and executed by Praetor Miele.
				*if heard_of_lefferts
					She is the broodmate of Edwin Lefferts.
				In the early days of her unlife, she gained some fame for her ability to wrangle vampires who did not honor the Rule of Respect.  She is a well-known supporter of Isaiah Stone.
			*if (maddox_num = 2) and ((wilson_embraced or wilson_embraced_by_withers) and (chasing_wilson = false))
			
				*if wilson_embraced
					[b]Anselm Martin[/b] is your offspring and your former mortal valet.
				*if wilson_embraced_by_withers and knows_wilson_embraced
					[b]Anselm Martin[/b] is the offspring of Samantha Withers and your former mortal valet.
				He is missing an eye from your flight from St. Charles parish.
			*if heard_of_pickering
			
				[b]Absalom Pickering[/b] is a citizen of Mobile, and is a candidate for Senator of Memphis.
				*if met_pickering
					He is a white man, with brown hair and eyes.  He sports a goatee which hides what would otherwise be a weak chin.  He parts his hair to the side, a bit low for your taste, and he speaks with an Alabaman drawl.  As a mortal, he fought under Andrew Jackson during the conquest of Florida.
				*if pickering_and_pike and (knows_pickering_mason = false)
					He has some involvement with Albert Pike, a famous Freemason and former Confederate officer.
				*if knows_pickering_mason
					He is a Freemason.  Not just a member of the mortal organization, but a member of the vampiric heresy!
				*if met_pickering
					He categorically rejects the deeds of Isaiah Stone.
				*if knows_pickering_is_shepherd
					Curiously, he claims to be a Wolf, but in his heart he is a Shepherd.
			*if read_dodecagram_scrap

				[b]Ludmila Prazan[/b]: A vampire of Prague.

				[b]Tyesca Prazan[/b]: A scion of Ludmila Prazan. She wrote the scrap of history about the Dodecagram that you have. She lived in Brno in the 15th century.
			*if heard_of_radegunda

				[b]Radegunda de Rochefort[/b] is the domina of Guillaume de Sainte-Chapelle.  She is a citizen of Rochefort.
			*if met_estefania
			
				[b]Estefania Rios e Hidalgo[/b] is 
				*if estefania_is_kin
					the broodmate of your dominus, Fernando de Villanueva e Itamaraca.
				*else
					a citizen of New Orleans.
				She has brown—almost black—eyes.  She considers herself a connoisseur of blood, seeking to turn the act of feeding into something akin to an artform.
				*if rios_rapport > 60
					The two of you enjoy each others' company.
				*elseif (rios_rapport >= 40)
					The two of you have a functioning relationship.
				*else
					The two of you do not get along.
			*if heard_of_tiozzo
			
				[b]Orelia Tiozzo[/b] is a painter of great reknown within the Society. She is originally from the Dalmatian city variously known as Fiume and Rijeka. She travels with [b]James Draper[/b].
			*if (heard_of_villanueva and (year <= 1898)) and (sire_name != "Fernando de Villanueva e Itamaraca")
				*if (sire_name != "Pieter van der Velde") or (sire_alive)
				
					[b]Fernando de Villanueva e Itamaraca[/b] is a notorious pirate, known for his association with Jean Lafitte.  He is the broodmate of Estefania Rios e Hidalgo. @{(year > 1898) He is Quaestor of Havana, having deposed Umar al-Baqa amid the Spanish-American War.|}
			*if met_jesse
			
				[b]Jesse Whitaker[/b] is 
				*if jesse_is_broodmate
					your broodmate.
				*else
					the progeny of ${jesse_sire_name}.
				*if jesse_rapport > 60
					You have a strong rapport with him.
				*elseif (jesse_rapport >= 40)
					The two of you have a functioning relationship.
				*else
					The two of you do not get along.
				*if jesses_revolutionary_credentials > 60
					He is a well-known supporter of Stone.
				*if jesses_revolutionary_credentials < 40
					His opposition to Isaiah Stone is well-known.
				*if jesse_for_senator
					He has thrown his hat into the ring for the position of Senator of Memphis.
			*if met_samantha and (presented_vicksburg = false)
			
				[b]Samantha Withers[/b] is a citizen of Savannah.  She is the broodmate of Theresa Overstreet.  She is much more attractive than Overstreet, though she gives off the air of being less serious.
			*if met_robert_yates
			
				[b]Robert Yates[/b] @{(year <= 1904) is|was} a citizen of Chicago. He @{(year <= 1904) is|was} the scion of Seamus O'Donnell@{(year > 1904) , until he was consumed at the Louisiana Purchase Exhibition|}.
			*goto rogues_gallery
	*if consul_praetor_explained
		#Consuls.
			*text_image vampires_gallery.png center Vampires' Gallery
			[b]Adonis[/b] is the Consul of the Society; he was the first vampire to claim that title.  He is ancient, and he leads vampire-kind from his seat in Rome.  

			*if read_dodecagram_scrap
				[b]Pharoah[/b] is the title given to a vampire that sent the legate Horemheb to treat with Adonis in Rome. Prior to Adonis slaying Horemheb, it seems that he had sworn fealty to Pharoah.
			
			[b]Isaiah Stone[/b] claims the title of Consul of the Americas.  He leads his revolution from his home in Baltimore.
			*if knows_partridge_childe_of_stone
				Samson Partridge is his progeny.
			
			*if heard_of_sostrate
				[b]Sostrate[/b] was a Consul; she governed from her seat in Constantinople. Representatives of hers and Adonis negotiated the Three Rules in 325 CE, under the cover of the First Council of Nicaea. @{(tryphon_identity > 1) She was destroyed in 1204 CE during the Sack of Constantinople by the Crusaders.|}
				*if heard_of_olympias
					*if heard_of_nikomedes
						She was the dominus of Nikomedes and Olympias.
					*else
						She was the dominus of Olympias.
				*elseif heard_of_nikomedes
					She was the dominus of Nikomedes.
			*goto rogues_gallery
	#My Dominus.
		*text_image vampires_gallery.png center Vampires' Gallery
		*if sire_alive
			Your dominus is [b]${sire_name}[/b].
			*if sire_name = "Padre Carlos"
				*gosub padre_carlos
			*elseif sire_name = "Guillaume de Sainte-Chapelle"
				*gosub chapelle
			*elseif sire_name = "Pieter van der Velde"
				*gosub vanderahe
			*elseif sire_name = "Wallace Winters"
				*gosub winters
			*elseif sire_name = "Fernando de Villanueva e Itamaraca"
				*gosub villanueva
				*if year > 1898
					In the wake of the Spanish-American War, he has been appointed the Quaestor of Havana, having been instrumental in the deposition of Umar al-Baqa.
			*else
				He is considered a beast by most members of the Society, a vampire who foresakes others of his kind.
				*gosub west
			*goto rogues_gallery
		*else
			Your maker, [b]${sire_name}[/b], was slain by your hand at the Battle of New Orleans.
			*if sire_name = "Padre Carlos"
				*label padre_carlos_dead
				He was a thin, frail-looking man of Aragonian descent.  He fingered his rosary-beads when his hands were not otherwise occupied.
			*elseif sire_name = "Guillaume de Sainte-Chapelle"
				*label chapelle_dead
				He was not terribly tall, and his long chestnut locks were kept in a loose ponytail.  A French nobleman, he was fastidious in both his appearance and the appointment of his home.
			*elseif sire_name = "Pieter van der Velde"
				*label vanderahe_dead
				He was tall, and maintained the dress of the early Dutch settlers.
				*if heard_of_sandersdochter
					He had a broodmate, Beatrijs Sandersdochter.
			*elseif sire_name = "Wallace Winters"
				*label winters_dead
				He was of average height, with brown hair and blue eyes.
			*elseif sire_name = "Fernando de Villanueva e Itamaraca"
				*label villanueva_dead
				He was a dashing Castilian pirate who walked with a cutlass and a swagger.
			*else
				*label west_dead
				He moved like a cougar, conserving his energy in case he needed to pounce. He had piercing blue eyes and sandy blond hair.
			*goto rogues_gallery
	*if taught_about_governors
		#Governors.
			*text_image vampires_gallery.png center Vampires' Gallery
			Governors oversee a province, and appoint Quaestors to administer to specific cities in that province.
			*if heard_of_bjornsdotter and (year > 1882)
			
				[b]Gudhrun Björnsdotter[/b] is the Governor of St. Paul. @{heard_of_buljan She is the scion of Buljan.|}
			*if heard_of_garcia

				[b]Martin Garcia Vargas[/b] is the Governor of Cartagena.  He is the dominus of Fernando de Villanueva e Itamaraca and Estefania Rios e Hidalgo.
			*if heard_of_maffi
			
				[b]Thérèse Maffi[/b] is the functional Governor of Cap-Haïtien. She slew or otherwise deposed Azamet Praz, but refuses to claim the title of governor for herself. She has successfully thwarted any attempt by other vampires to claim the title as well.			
			*if heard_of_dinapoli
			
				[b]Elena of Naples[/b] is the Governor of Naples. She has held the position for at least six hundred years.
			*if heard_of_marcius
			
				[b]Gnaeus Marcius Rufus,[/b] colloquially known as Martial, is the Governor of London. He has held the position for over a thousand years. He is a scion of Adonis.
			*if heard_of_nikomedes
			
				[b]Nikomedes[/b] is the Governor of Paris, and is the scion of Sostrate.
			*if heard_of_olympias
			
				[b]Olympias[/b] is the Governor of Athens. @{heard_of_sostrate She is the offspring of Sostrate.|}
			*if heard_of_ortega

				[b]Tomás Ortega y Cortes[/b] is the Governor of Mexico City.  He is a former conquistador, and is the dominus of Padre Carlos.
			*if heard_of_overstreet
				
				[b]Theresa Overstreet[/b] is the Governor of Savannah.
				*if met_overstreet
					In life, Theresa Overstreet was a short, homely woman with mousy hair.  Undeath has not made her more physically attractive, but she radiates self-assurance and—frankly—power.
				*if great_swap or ashmores_sire
					She is the domina of Rebecca Ashmore, Senator of Philadelphia.
			*if met_maffi > 1
				
				[b]Azamet Praz[/b] was the Governor of Cap-Français, until he was slain by Thérèse Maffi sometime around 1804.
			*if heard_of_saint_cyr

				[b]Louis-Joseph de Saint-Cyr[/b] is the @{(year > 1821) Governor|Quaestor} of Montréal.  
				*if heard_of_sainte_chapelle
					He is the broodmate of Guillaume de Sainte-Chapelle.
				*if heard_of_aregund
					He is the progeny of Aregund de Rochefort and the broodmate of Radegunda de Rochefort.
			*if heard_of_townsend
				
				[b]Henry Townsend[/b] is the Governor of Philadelphia.
				*if great_swap
					He is the dominus of Abel Bowater, Senator of Savannah.
			*goto rogues_gallery
	*if rumors_of_west or (met_lynch or (chasing_wilson or (met_hugh_in_vicksburg or heard_of_macpherson)))
		#Outlaws.
			*text_image vampires_gallery.png center Vampires' Gallery
			*if heard_of_gallagher
				
				*if (gallagher_status = "free") or (((gallagher_status = "freed") or (gallagher_status = "staked")) or (gallagher_status = "buried"))
					[b]Hugh Gallagher[/b] is an Irish vampire.
					*if knows_santagostino_seeks_gallagher
						Chiara Santagostino seeks word of him.
					*if met_hugh
						There is a notable gap between his front teeth.
					*if heard_about_bounty_on_hugh
						According to Siobhan Malloy, there is a bounty on his head.
					*if tasked_hugh
						Carothers has directed you to collect this errant young vampire.
					*if gallagher_status = "freed"
						When you cornered him in 1878, you decided to let him go.
					*elseif gallagher_status = "staked"
						He is currently in your possession.
					*elseif gallagher_status = "buried"
						You buried him in a field outside of Memphis with a stake through his chest; you hope that he will remain there undisturbed, until you can better address his situation.
				*if (gallagher_status = "carothers") or (gallagher_status = "inquiry")
					[b]Hugh Gallagher[/b] is an Irish vampire.  There is a notable gap between his front teeth.  You turned him over to Carothers for disposition.
				*if (gallagher_status = "dead") or (gallagher_status = "decapitated")
					[b]Hugh Gallagher[/b] was an Irish vampire, but you killed him.  There was a notable gap between his front teeth.
				*if (gallagher_status = "west")
					[b]Hugh Gallagher[/b] was an Irish vampire, but @{west_prob ${imposter}|West} consumed him.  There was a notable gap between his front teeth.
				*if gallagher_status = "consumed"
					[b]Hugh Gallagher[/b] was an Irish vampire, but you drank his heartsblood.  There was a notable gap between his front teeth.
				*if gallagher_status = "quaestor"
					[b]Hugh Gallagher[/b] was an Irish vampire with a bounty on his head.  You sent his staked body to the Quaestor of New York for a reward.
			*if met_lynch
	
				*if kill_cecil
					[b]Cecil Lynch[/b] was a vampire who came to New Orleans, and failed to present himself to the quaestor there.  You killed him.
					*if knows_lynch_sire
						He was the offspring of Sir Robert ap Gruffyd.
				*if kill_cecil = false
					[b]Cecil Lynch[/b] is a vampire who came to New Orleans, and failed to present himself to the quaestor there.
					*if knows_lynch_sire
						He is the offspring of Sir Robert ap Gruffyd.
				*if helios_plot
					You sent him off, his head full of tales about the glory of ${helios}.
			*if heard_of_macpherson
			
				[b]Edward MacPherson[/b] is the elder broodmate of Elinor Harding and Apollo Carothers.  He travels between the different courts of the New World.
			
			*if (wilson_embraced or wilson_embraced_by_withers) and (maddox_num = 1)
				*if (maddox_status = "free") or (maddox_status = "fled")
					*if wilson_embraced
						[b]Wilson Maddox[/b] is your progeny.
					*elseif wilson_embraced_by_withers
						[b]Wilson Maddox[/b], your former valet, is the progeny of Samantha Withers.
					He has fled the company of the Society and @{(year <= 1874) is rumored to be in Memphis|is hiding out in or around Memphis}.
				*elseif year >= 1878
					*if wilson_embraced
						[b]Wilson Maddox[/b] was your progeny.
					*elseif wilson_embraced_by_withers
						[b]Wilson Maddox[/b], your former valet, was the progeny of Samanta Withers.
					*if maddox_status = "dead"							
						He is now dead.
					*if maddox_status = "consumed"
						You drank his heartsblood.
					*if maddox = "withers"
						You have sent him to Withers to have his fate adjudicated.
					*if maddox = "freed"
						After confronting him in Memphis, you let him go.
						*if year > 1881
							He was subsequently consumed by @{west_prob ${imposter}|West}.
				In life, he was a freedman, missing an ear from where a foreman tore it off when he was young.
			
			*if (wilson_embraced or wilson_embraced_by_withers)	and (maddox_num = 2)
				*if (maddox_status = "free") or (maddox_status = "fled")
					*if wilson_embraced
						[b]Anselm Martin[/b] is your progeny.
					*if wilson_embraced_by_withers
						[b]Anselm Martin[/b], your former valet, is the progeny of Samantha Withers.
					He has fled the company of the Society and @{(year <= 1874) is rumored to be in Memphis|is hiding out in or around Memphis}.
				*if year >= 1878
					*if wilson_embraced
						[b]Anselm Martin[/b] was your progeny.
					*if wilson_embraced_by_withers
						[b]Anselm Martin[/b], your former valet, was the progeny of Samanta Withers.
					*if maddox_status = "dead"							
						He is now dead.
					*if maddox_status = "consumed"
						You drank his heartsblood.
					*if maddox = "withers"
						You have sent him to Withers to have his fate adjudicated.
					*if maddox = "freed"
						After confronting him in Memphis, you let him go.
						*if year > 1881
							He was subsequently consumed by @{west_prob ${imposter}|West}.
				In life, he was a German-Cajun farmer who lost an eye defending you from the villagers of St. Charles parish.
				
			*if (heard_of_west) and (sire_name != "West")

				[b]West[/b] is a Beast, a vampire who mostly forsakes the company of other vampires.
				*if met_west
					*gosub west
			*if rumors_of_west_dead and (stl_heard_of_wotton = false)
				
				[b]West's Imposter[/b] is a Beast, a vampire who mostly forsakes the company of other vampires.
			*elseif stl_heard_of_wotton
			
				[b]Lewis Wotton[/b] is presumably a Beast, a vampire who mostly forsakes the company of other vampires. In life, he was an English colonist who arrived at Roanoke, Virginia with the White resupply in 1587.
			*goto rogues_gallery
	*if consul_praetor_explained or praetors_explained
		#Praetors.
			*text_image vampires_gallery.png center Vampires' Gallery
			Praetors are traveling investigators and judges, rooting out heresies and other unwanted ideologies that may sprout in the hearts of vampires.

			[b]Gianluca Miele[/b] was the Praetor for the Americas, appointed by Adonis.
			
			*if (sire_name = "Padre Carlos") and (sire_alive = false)
				*goto rogues_gallery
			*elseif (sire_name = "Padre Carlos") and sire_formerly_quaestor
				[b]Padre Chaime Carlos Borcha[/b], your dominus, is the new Praetor for the Americas, appointed by Isaiah Stone.
				*gosub padre_carlos
				*goto rogues_gallery
			*else
				*if heard_of_carlos
					[b]Padre Chaime Carlos Borcha[/b], a former Aragonese priest, is the new Praetor for the Americas, appointed by Isaiah Stone.
					*gosub padre_carlos
				*goto rogues_gallery
	*if (lore > 0)
		#Quaestors.
			*text_image vampires_gallery.png center Vampires' Gallery
			*if taught_about_governors
				Quaestors are appointed by a Governor to administer a city.  In that city, their word is law.  They serve at the pleasure of their Governor.
			*if sire_alive and ((sire_formerly_quaestor = false) and (sire_name != "West"))
			
				Your dominus, [b]${sire_name}[/b] is the Quaestor of New Orleans.
				*if sire_name = "Padre Carlos"
					*gosub padre_carlos
				*if sire_name = "Pieter van der Velde"
					*gosub vanderahe
				*if sire_name = "Wallace Winters"
					*gosub winters
				*if sire_name = "Guillaume de Sainte-Chapelle"
					*gosub chapelle
				*if sire_name = "Fernando de Villanueva e Itamaraca"
					*gosub villanueva
			*if heard_of_aregund

				[b]Aregund de Rochefort[/b] is the Quaestor of Rochefort.  She is the dominus of Radegunda de Rochefort and Louis-Joseph de Saint-Cyr.
			*if heard_of_baqa
				
				*if year <= 1898
					[b]Umar al-Baqa[/b] is the Quaestor of Havana. He is a well-known Loyalist. When Stone slew Miele, Havana—and most of the Caribbean—was reassigned to Governor Ortega y Cortes.
				*if year > 1898
					[b]Umar al-Baqa[/b] was the Quaestor of Havana until the Spanish-American War. He is a well-known Loyalist. When Stone slew Miele, Havana—and most of the Caribbean—was reassigned to Governor Ortega y Cortes.
			*if presented_memphis
				
				[b]Apollo Carothers[/b] is the Quaestor of Memphis.  He is an immense freedman, with hands of unbelievable size, and a voice like the rumble of boulders.  He is the dominus of Dido Applethorp.
				*if met_hester_carothers
					He has a mortal daughter by the name of Hester Carothers, born in 1806.
			*if heard_of_clarkson
			
				[b]Morounranti "Moro" Clarkson[/b] is the Quaestor of @{(year > 1894) Brooklyn|Flatbush}, New York.
			*if heard_of_vdaniels
			
				[b]Vernon Daniels[/b] was the Quaestor of Cleveland. The offspring of Peter Townsend, he was murdered by mortal hunters in
				*if sod_founder = "duplessis"
					1877.
				*else
					1882.
			*if heard_of_fragala and (year > 1883)
				
				[b]Calogero Fragalà[/b] is the Quaestor of Kansas City.
				*if met_fragala
					When he was alive, he was infected with leprosy. The disease continues to afflict him in death.
			*if heard_of_maudlin_hall
				
				[b]Maudlin Hall[/b], the Witch of Wilmington, is the Quaestor of Wilmington, North Carolina. She is the dominus of James Draper.
			*if heard_of_harding
			
				[b]Elinor Harding[/b] is the Quaestor of Louisville and a known Loyalist. She is the @{heard_of_macpherson younger broodmate of Edward MacPherson and the|} elder broodmate of Apollo Carothers. @{knows_hardings_plan She blackmailed Samson Partridge into deadlocking the Memphis senatorial caucus.|}
			*if heard_of_memeskia
			
				[b]Memeskia[/b] is the Quaestor of St. Louis.  He is Native American.
				*if met_memeskia
					He dresses as a European, but keeps his unshorn hair pulled away from his face with a red headwrap.
				*if (sire_name = "West") and (year >= 1879)
					He too is the offspring of West.
			*if heard_of_odonnell
			
				[b]Seamus O'Donnell[/b] is the Quaestor of Chicago.
				*if met_robert_yates
					He is the dominus of Robert Yates@{(met_herbert_walker > 2)  and Herbert Walker|}.
			*if heard_of_page
				
				[b]Harold Page[/b] is the Quaestor of New York.
				*if heard_about_bounty_on_hugh
					*if (gallagher_status = "free") or (gallagher_status = "freed")
						He has announced a reward for the execution of Hugh Gallagher.
					*if debt_from_page
						You hold a debt from him for the execution of Hugh Gallagher.
			*if heard_of_powell
			
				[b]Horace Powell[/b] is the Quaestor of Cincinnati.
			*if heard_of_quarrington

				[b]Giles Quarrington[/b] was the Quaestor of Cumberland, Maryland.  He was slain by a mob of striking workers during the Great Railroad Strike of 1877.
				*if quarringtons_allegiances
					He was a well-known Loyalist.
			*if heard_of_quintana
				
				[b]Isabella Quintaña Garcia[/b] is the Quaestor of Mobile, Alabama, and the dominus of Absalom Pickering.
			*if heard_of_schaap

				[b]Henning Schaap[/b], a Rhinelander, is Quaestor of Baltimore.
			*if sire_alive and (sire_formerly_quaestor and (sire_name != "Pieter van der Velde"))
			
				[b]Pieter van der Velde[/b] is the Quaestor of New Orleans, since replacing your dominus in 1865.
				*gosub vanderahe
			*if ((sire_alive = false) and (sire_name != "Pieter van der Velde")) or (sire_name = "West")
			
				[b]Pieter van der Velde[/b] is the Quaestor of New Orleans.
				*gosub vanderahe
			*if (sire_alive = false) and (sire_name = "Pieter van der Velde")
			
				[b]Fernando de Villanueva e Itamaraca[/b] is the Quaestor of New Orleans.
				*gosub villanueva
			*if (year > 1898) and ((sire_alive) or (sire_name != "Pieter van der Velde"))
			
				[b]Fernando de Villanueva e Itamaraca[/b] is the Quaestor of Havana.
				*gosub villanueva
				*if sire_formerly_quaestor and (sire_name = "Fernando de Villanueva e Itamaraca")
					He was previously the Quaestor of New Orleans, until he was replaced by Pieter van der Velde in 1865.
			*if presented_vicksburg
			
				[b]Samantha Withers[/b] is the Quaestor of Vicksburg.  She is the broodmate of Theresa Overstreet.  She is much more attractive than Overstreet, though she gives off the air of being less serious.
				*if flirting_with_withers
					She has responded positively to your demonstrations of affection.
				*if wilson_embraced_by_withers
					She @{(maddox_status = "dead") was|is} the dominus of Wilson Maddox, your former valet.
					*if chasing_wilson
						She @{(maddox_status = "dead") |has} charged you with retrieving her errant offspring for her.
				*if hasty_exit_from_vicksburg
					Though she did not formally exile you from Vicksburg, she made it painfully clear that you are no longer welcome there.
				*if exiled_from_vicksburg
					She has exiled you from her city.
			*if heard_of_zappas or eliot_in_greece
				
				[b]Evangelis Zappas[/b] [i]histoire[/i] was the Quaestor of Targoviste.  He is the dominus of Hiram Eliot.
			*goto rogues_gallery
	*if senators_representation and ((year > 1866) or (heard_of_schaap or heard_of_maerszen))
		#Senators.
			*text_image vampires_gallery.png center Vampires' Gallery
			Senators represent the larger interests of the Society to a city.
				
			*if heard_of_adamantius
			
				[b]Adamantius the Elder[/b] is the Senator of Baltimore. He is rumored to be over a millenium old.
			*if heard_of_ashmore
				[b]Rebecca Ashmore[/b] is the Senator of Philadelphia.
				*if met_ashmore
					She wears the dress of a southerner—even going so far as to retain a fan—while still keeping up with the latest fashions.
				*if great_swap or ashmores_sire
					She is the progeny of Theresa Overstreet.
			*if heard_of_bailey
			
				[b]John Bailey[/b] is the Senator of St. Louis.
				*if met_bailey
					He is fair-haired, clean-shaven and youthful looking.  Based upon his carriage, it is easy to assume that he was a soldier, likely in the Contintal Army.  His age has not prevented him from keeping up with the fashions, and his outfit is exquisitely assembled. 
				He is well-known for his support of Isaiah Stone.
			*if heard_of_bowater
			
				[b]Abel Bowater[/b] is the Senator of Savannah.
				*if met_bowater
					He continues to dress and speak as a Quaker, even after several decades of undeath.
				*if great_swap or bowaters_sire
					He is the progeny of Henry Townsend.
			*if heard_of_cavendish
			
				[b]Richard Cavendish[/b] is the Senator of Richmond.
			*if heard_of_coffin
			
				[b]Abigail Coffin[/b] is the Senator of Cincinnati.
				*if met_coffin
					Two centuries later, she still dresses like the early Puritan pilgrims of the Massachussetts Bay Colony.  She was clearly given the gift of the blood sometime in her late forties; a life of pious toil took its toll on her body before she became a vampire.
			*if heard_of_davison
			
				[b]Anne Davison[/b] is the Senator of Montréal.
				*if met_davison
					She is not conventionally pretty, but she moves with a predatory grace that has an alluring quality.
				She is a staunch supporter of Consul Stone.
			*if heard_of_lockridge
			
				[b]Arthur Lockridge[/b] is the Senator of Charleston. @{met_lockridge His dress is outmoded by several decades, but his power is undoubted.  A plantation-owner in life and undeath, when he speaks, he expects others to take heed.|} @{knows_lockridge_wolf He is a well-known Wolf.|} He is not shy about his support of Adonis and his disdain for Isaiah Stone.
			*if heard_of_partridge
			
				[b]Samson Partridge[/b] is the Senator of Louisville.
				*if met_partridge
					He is brown-haired, bearded, and youthful looking.  As a mortal, he was an attorney, and still dress as though he were standing before a judge. A born orator, his voice unconsciously booms through a room.
			*if heard_of_sandersdochter

				[b]Beatrijs Sandersdochter[/b] is the Senator of Manhattan.  
				*if heard_of_maerszen
					She is the offspring of Hector Maerszen.
				She is the broodmate of Pieter van der Velde.
			*if heard_of_chiara_santagostino
			
				[b]Chiara Santagostino[/b] is the Senator of New Orleans.
				*if met_chiara
					She was given the gift of the blood as a young woman.  She has curly blond hair and a large nose, which somehow suits her face.
				*if knows_santagostino_seeks_gallagher
					She is seeking Hugh Gallagher, the Irish vampire who has refused to present himself to Quaestor Carothers.
			*if heard_of_schaap and (heard_about_revolution = false)
			
				[b]Isaiah Stone[/b] is the Senator of Baltimore.
			*if heard_of_simmons
			
				[b]Charles Simmons[/b] is the Senator of Mobile.
				*if met_simmons
					He is of average height, with brown hair and eyes.  He has a large head and a strong brow, with a chin that comes down nearly to a point.  He most striking feature, however, is his almost completely bald pate; it consists of whisps around the side of his head.  He wears a wig to hide his baldness.  He also wears a pair of spectacles and smokes a pipe.
				He is generally considered to be a Loyalist.
			*if heard_of_timmers
			
				[b]Gerard Timmers[/b] is the Senator of Buffalo.
				*if met_timmers
					His height and striking blond hair marks him as being of Dutch extraction.
				*if timmers_sire
					His domina is Beatrijs Sandersdochter.
			*goto rogues_gallery
	#View the Mortals' Gallery.
		*text_image mortals_gallery.png center Mortals' Gallery
		*goto mortals_gallery
	#Return to the Stat Chart.
		*goto stat_chart

*label padre_carlos
*if met_carlos
	He is a thin, frail-looking man of Aragonese descent.  He fingers his rosary-beads when his hands are not otherwise occupied.
*return

*label chapelle
He is not terribly tall, and his long chestnut locks are kept in a loose ponytail.  A French nobleman, he is fastidious in both his appearance and the appointment of his home.
*return

*label vanderahe
He is tall, and maintains the dress of the early Dutch settlers.
*if heard_of_sandersdochter
	He has a broodmate, Beatrijs Sandersdochter.
*return

*label villanueva
He is a dashing Castilian pirate who walks with his cutlass and a swagger.
*return

*label west
He moves like a cougar, conserving his energy in case he needs to pounce. He has piercing blue eyes and sandy blond hair.
*if rumors_of_west
	There are rumors that he is going—or perhaps has gone?—mad.
*return

*label winters
He is of average height, with brown hair and blue eyes.
*return

*label mortals_gallery
*choice
	*if (year >= 1874)
		#Chicago.
			*text_image mortals_gallery.png center Mortals' Gallery
			[b]Allan Pinkerton[/b] is the founder of the Pinkerton Security Agency, or "the Pinkertons." The Pinkertons provide private security to those who are willing to pay, as well as serving as private investigators available to pursue criminals in cases such as train and bank robberies. They are also frequently hired to provide infiltrators and [i]agents provacateurs[/i] to be deployed against workers' movements, as well as hiring and organizing scabs and strike-breakers.
			
			*if year > 1892
				[b]Ida B. Wells[/b] is a journalist who attended school in Memphis following the death of her parents in the 1878 Yellow Fever epidemic. She later won a judgment against the Chesapeake, Ohio, and Southwestern Railroad, until the decision was overturned by the Tennessee Supreme Court in 1887. Since then, she has taken a strident role in the examination and denunciation of the pogrom of lynchings across the United States. One particular pamphlet, [i]Southern Horrors: Lynch Law in All Its Phases[/i], led to her newspaper's office being fire-bombed and her eventual flight from Memphis.
				*if year > 1894
					With the assitance of several British abolitionists, Wells traveled to the United Kingdom on two speaking tours. Before the second tour, she persuaded the editor of the [i]The Daily Inter-Ocean[/i] to pay her for her articles, thereby becoming the first black international correspondant for a major white newspaper.
				*if year > 1895
					After her speaking tours were concluded, she settled in Chicago permanently and subsequently married a widower by the name of Ferdinand Barnett. The two continue to publish numerous articles, journals, and newspapers about the black condition in the United States and the manifest cruelties associated with Jim Crow laws, lynchings, and segregation.
			*goto mortals_gallery
	*if presented_memphis
		#Memphis.
			*text_image mortals_gallery.png center Mortals' Gallery
			*if barnum_thompson_plot
				[b]Mr. Barnum[/b] @{(year <= 1874) is|was} the superintendant of schools for Memphis.  
				*if year > 1874
					He was relieved of his duties in the summer of 1874, and returned to his home in Pennsylvania thereafter.
			
			[b]Robert Reed Church[/b] @{(year <= 1912) is|was} a mixed-race entrepreneur of Memphis. He was shot and left for dead during the race riot of 1866.
			*if year > 1878
				During the fever of 1878, he invested heavily in distressed properties; when the citizens returned, he profited greatly. @{(year > 1912) He died in 1912.|}
			
			[b]Nathan Bedford Forrest[/b] was a Lieutenant Colonel in the Confederate Army, famous for his victory at Fort Pillow.  After the war, he was instrumental in the expansion of the Ku Klux Klan, becoming the organization's first Grand Wizard, as well as becoming President of the Marion & Memphis Railroad.
			
			[b]Napoleon Hill[/b] is a merchant-prince of Memphis.  A co-founder of the Memphis Cotton Exchange, he both inherited money and then multiplied it by venturing to California during the Gold Rush.
			
			[b]Olivia Polk Hill[/b] is the daughter of Napoleon Hill.
			
			[b]Harriet Lane[/b] is an Irish temperance worker, who assists Elizabeth Avery Meriwether in the founding of the Women's Christian Temperance Union in Memphis.
			
			*if met_percival_little
				[b]Percival Little[/b] 
				*if year <= 1873
					is a banker with the Freedmans Savings & Trust bank.
				*else
					was a banker with the Freedmans Savings & Trust bank, before it collapsed in 1874.
				*if founded_school_for_the_blind
					He is now the director for the new ${blind_school_name}.
				
				[b]Sally Little[/b] is his wife.
			
			[b]Jeremiah Koonce[/b] is a local dandy. @{(year >= 1874) He is also a prominent member of the People's Protective Union.|}
			
			[b]Minor Meriwether[/b] is a Major in the Confederate Army, and a close associate of Nathan Bedford Forrest.  He is married to Elizabeth Avery Meriwether, and brother to Niles.
			*if year >= 1874
				He organized the People's Protective Union, an organization of former Confederates opposed to the debt obligations incurred by the Republican administrations of Memphis.
			*if year >= 1879
				The PPU succeeds in its petition to the State of Tennessse in 1879, revoking the municipal charter of Memphis and rendering all bonds issued by that entity null and void.
			
			Like his brother, [b]Niles Meriwether[/b] was also a Major in the Confederate Army, assigned to the engineering corps.  He is married to Lide Smith Meriwether.  After the war, he found employment with the Memphis & Charleston Railroad.
			*if year >= 1879
				He is appointed City Engineer of Shelby County in February 1879, remaining in that position for fourteen years.
			*comment Minor and Niles are grandsons of Thomas Meriwether and Nancy Minor.  Thomas was the younger brother of William H., both sons of Nicholas Meriwether.  Their only sister was Elizabeth Meriwether Lewis, mother of Meriwether Lewis (of Lewis & Clark).
			
			*if (year > 1870) and (stlouis_valet_num != 4)
				[b]Franklin Ross[/b] @{(franklin_dead or (year >= 1878)) was|is} your valet in Memphis.
			
			*if met_stennis and (stennis_dead = false)
				[b]Stennis[/b] is a man hired to keep an eye out for ${wilson}.
			*elseif stennis_dead
				[b]Stennis[/b] was hired to keep an eye out for ${wilson}.  He is now dead.
			
			*if barnum_thompson_plot
				[b]Mrs. Thompson[/b] is a 
				*if year <= 1874
					black teacher who is under investigation by Superintendant Barnum.  A lengthy public debate about her competence as a teacher is playing out in the newspapers.
				*else
					teacher at the Clay Street school.  She was educated in Ohio, and returned home to educate other blacks.  Superintendant Barnum had her fired after a lengthy public debate and show trial, but when he was replaced, she was reinstated.
			*if (year >= 1887) and (year <= 1892)
			
				[b]Ida B. Wells[/b] is a young schoolteacher and journalist who won a judgment against the Chesapeake, Ohio, and Southwestern Railroad, until the decision was overturned by the Tennessee Supreme Court in 1887.
			*goto mortals_gallery
	*if avoided_new_orleans = false
		#New Orleans.
			*text_image mortals_gallery.png center Mortals' Gallery
			[b]Pierre-Louis Babineaux[/b] @{((year <= 1827) or (love_clotho = false)) is|was} a wealthy sugar-planter who @{((year <= 1827) or (love_clotho = false)) owns|owned} a plantation outside of New Orleans.
			
			*if love_clotho
				[b]Clotho[/b] @{(year <= 1827) is|was} a Voodoo Priestess of New Orleans.

			*if attended_marignys_party or (priest and ((avoided_new_orleans = false) and (exiled_from_new_orleans = false)))
				[b]Louis-Guillaume-Valentin Dubourg[/b] 
				*if year < 1816
					is the apostolic administrator of Louisiana.
					*if priest
						In theory, he has the power to restore you to your position in the Church.
				*elseif year < 1826
					is the first Bishop of Louisiana, stationed in St. Louis.
					*if priest
						In theory, he has the power to restore you to your position in the Church.
				*elseif year < 1833
					was the first Bishop of Louisiana, stationed in St. Louis until 1826.  He has since been recalled to France.
				*else
					was the first Bishop of Louisiana, stationed in St. Louis.  He was recalled to France in 1826, and died in 1833.
			
			[b]Peter Duplessis[/b] @{(year <= 1827) is|was} the US Marshal of Louisiana. @{(love_clotho and (year > 1827)) Clotho helped him ensnare Pierre-Louis Babineaux.|}
			
			*if love_clotho
				[b]Guidry[/b] @{(year <= 1830) is|was} a fixture of Jackson Square.

			*if (invitation_to_hebert_ignored = false) and (year >= 1823)
				[b]Yves Hébert[/b] @{(year <= 1830) is|was} a local bachelor that lives off the largesse of his family.  @{(perception <= 1) According to Estefania, his|His} blood has a delightful [i]terroir[/i].
			
			[b]General Andrew Jackson[/b] led the American soldiers to victory at the Battle of New Orleans.
			*if met_andrew_jackson
				When you later confronted him at the George Washingon Ball, you were surprised to discover that he knew you for what you were.
			*if year >= 1818
				Along with John Overton, he founded Memphis, TN in 1818.
			*if (year >= 1829)
				He became the seventh President of the United States in 1829.
				*if year >= 1830
					He signed the Indian Removal Act of 1830, authorizing the forced migration of the Five Civilized Tribes of Native Americans west of the Mississippi.
			*elseif year > 1837
				He was the seventh President of the United States, serving from 1829 to 1837.  As President, he signed the Indian Removal Act of 1830, authorizing the forced migration of the Five Civilized Tribes of Native Americans west of the Mississippi.  When his second term concluded he retired to his plantation, the Hermitage, outside of Nashville.
			*if year >= 1845
				He died at home and surrounded by his adopted children and grandchildren in 1845.
			
			*if attended_marignys_party
				[b]Jean Lafitte[/b] @{(year <= 1822) is|was} a pirate that fought alongside the Americans at the Battle of New Orleans.  After the battle he was pardoned for his former crimes, but his colony at Barataria Bay had been destroyed by the British forces.  
				*if year <= 1822
					He has since migrated west, and taken up residence in Galveston Bay.
					*if (sire_surname = "Villanueva") and ((patricide = false) and (avoided_new_orleans = false))
						Your dominus seems to have a particular affection for the man.
				*else
					He migrated west, taking up residence in Galveston Bay, from which he continued his operations until he was mortally wounded trying to seize a pair of Spanish ships off Honduras in 1823.
					*if (sire_surname = "Villanueva") and ((patricide = false) and (avoided_new_orleans = false))
						Your dominus seems to have had a particular affection for the man.  He was deeply grieved by his death.

			[b]Bernard Xavier Philippe de Marigny de Mandeville[/b] @{(year <= 1868) is|was} a Louisiana-born, ethnically French entrepreneur and politician that 
			*if year <= 1828
				dominates the social and political life of New Orleans.  He is responsible for the introduction of [i]crapaud[/i] to the Americas.
			*elseif year <= 1868
				is in the midst of losing his fortune to bad deals and gambling.  He formerly dominated the social and political landscape of the city, and is responsible for bringing [i]crapaud[/i] to the Americas.
			*else
				dominated the social and political life of New Orleans for decades, before a series of bad deals and a penchant for gambling left him destitute.  He was responsible for bringing [i]crapaud[/i] to the Americas.
			*if year > 1838
				He also founded the Louisiana Race Course in 1838, which will later be renamed to the New Orleans Fair Grounds. It is the second oldest race track in the country.
			He @{(year <= 1868) claims|claimed} responsibility for the alliance between General Andrew Jackson and the pirate Jean Lafitte at the Battle of New Orleans.
			*if heard_of_laveau
			
				[b]Marie Laveau[/b] @{(year <= 1881) is|was} the Voodoo Queen of New Orleans.
			
			[b]M. Jacque "James" Pitot[/b] was the third mayor of New Orleans (1804-1805). Prior to the Battle of New Orleans, as president of the Orleans parish police jury board, he authorized the formation of a colored militia, consisting of free men of color. In addition to his civil service, Pitot was involved in the management of the Carondelet Canal.
			
			*if (invitation_to_hebert_ignored = false) and (year >= 1823)
				[b]M. Theriot[/b] @{(year <= 1830) is|was} an ursurer of New Orleans.
			*goto mortals_gallery
	*if avoided_new_orleans or exiled_from_new_orleans
		#St. Charles parish.
			*text_image mortals_gallery.png center Mortals' Gallery
			*temp is "is"
			*if presented_vicksburg
				*set is "was"
			[b]M. Badeau[/b] [i]père[/i] ${is} a local landowner. [b]M. Badeau[/b] [i]fils[/i] ${is} his son.
		
			*if year = 1824
				[b]Père Jean-Théodule le Breton[/b] is a priest newly assigned to St. Charles parish.
			*if year >= 1825
				[b]Père Jean-Théodule le Breton[/b] was a priest assigned to St. Charles parish.  He was made unwelcome, and soon left.
			
			[b]Estrehan's Cupidon[/b] ${is} a slave belonging to M. d'Estrehan.
				
			*if (avoided_new_orleans) or (exiled_from_new_orleans)
				*if (year < 1826)
					[b]Louis-Guillaume-Valentin Dubourg[/b] is the first Bishop of Louisiana, stationed in St. Louis.
					*if priest
						In theory, he has the power to restore you to your position in the Church.
				*if (year >= 1826) and (year < 1833)
					[b]Louis-Guillaume-Valentin Dubourg[/b] was the first Bishop of Louisiana, stationed in St. Louis until 1826.  He has since been recalled to France.
				*if year >= 1833
					[b]Louis-Guillaume-Valentin Dubourg[/b] was the first Bishop of Louisiana, stationed in St. Louis.  He was recalled to France in 1826, and died in 1833.
			
			[b]Badeau's Endymion[/b] ${is} a slave belonging to M. Badeau.
			
			[b]Ansdam Engles[/b] ${is} an impoverished local farmer.
			
			[b]M. d'Estrehan[/b] ${is} a local landowner. He ${is} easily known by his missing arm, lost in a farming accident. He ${is} sheriff of the parish.
			
			[b]M. Heidel[/b] ${is} a sugar-planter and shopkeeper.
			
			[b]Jakob Labranche[/b] ${is} a local landowner. He @{presented_vicksburg had|has} a son, [b]Jost[/b].
			
			*if anselm_hired
				[b]Anselm Martin[/b] ${is} your valet in St. Charles parish.
		
			[b]M. Mayeux[/b] ${is} the parish judge and a local landowner.
			
			[b]Rixner's Ariadne[/b] ${is} an older woman enslaved to M. Rixner.
			
			[b]Rixner's Peter[/b] ${is} a slave belonging to M. Rixner.
		
			[b]M. Riehl[/b] ${is} a local small landowner.  He tend@{presented_vicksburg ed|s} his fields himself, unable to afford slaves.
			
			[b]Sophie Riehl[/b] is the daughter of M. Riehl.
			*if year >= 1826
				The community offered her to you as a maid—or food.
		
			[b]M. Rixner[/b] ${is} a local landowner. He @{presented_vicksburg had|has} a daughter, [b]Clarisse[/b].
			
			[b]M. Rodrigue[/b] ${is} a local landowner.
			
			*if (year >= 1825)
				[b]Padre Segura[/b] ${is} a priest who took up residence in the Red Church of St. Charles Borromeo.
			
			[b]M. Simoneaux[/b] ${is} a physician and local landowner.
			
			[b]Mayeux's Thomas[/b] ${is} a slave belonging to M. Mayeux.
			
			*if year <= 1825
				[b]Mme. Trepagnier[/b] is a wealthy widow of St. Charles parish.  Her husband was killed in the Slave Revolt of 1811.
			*if year > 1825
				[b]Mme. Trepagnier[/b] was a wealthy widow of St. Charles parish.  Her husband was killed in the Slave Revolt of 1811.
			*goto mortals_gallery
	*if presented_st_louis
		#St. Louis.
			*text_image mortals_gallery.png center Mortals' Gallery
			*if (year > 1896)
				[b]Gaetano Baiamonte[/b] is a Sicilian immigrant who has become a leader in the worker's rights movement. To the dismay of Gompers and his ilk, he argues for equity among all workers, without regard to skill or race.
				
			[b]James Overton Broadhead[/b] @{(year < 1882) is|was} a St. Louis-based attorney, originally from Virginia.  He @{(year < 1882) shares|shared} a legal practice with his friend Alonzo Slayback@{(year < 1882) | until 1882}. In addition to being a representative at the Missouri State Constitutional Convention in 1875, he was involved in the investigation and prosecution of the Whiskey Ring bribery cases in 1876.  He became the first president of the American Bar Association in 1878.
			*if year > 1881
				During his campaign to represent the 9th District of Missouri in the United States Congress, his history of questionable dealings and his ongoing relationship with Jay Gould came under fire from the [i]Post-Dispatch[/i] at the direction of John Cockerill.
			*if year > 1882
				Despite the controversies surrounding his campaign, he was elected in 1882.
			
			[b]Robert Brookings[/b] is a partner in Cupples & Marston, a homegoods distributor.
			*if year >= 1895
				Along with Samuel Cupples, Brookings organizes the construction of Cupples Station, an immense railroad station and depot in St. Louis.
			
			[b]Adolphus Busch[/b] is the Hessian-born cofounder of Anheuser-Busch—along with his father-in-law, Eberhard Anheuser.
			
			*if heard_of_jh_cavender
				[b]John H. Cavender[/b] is a real estate developer who was tasked by the Police Board to put down the Great Uprising of 1877.
				*if year >= 1900
					Twenty-three years later, he is again tasked with putting down the Streetcar Strike.
			
			*if (year > 1895) and ((((stlouis_enterprise = 1) or (stlouis_enterprise = 5)) or (creation > 2)) and speaks_english)
				[b]Kate Chopin[/b] @{(year <= 1904) is|was} a journalist and novelist. She @{(year <= 1904) is|was} originally from St. Louis, before moving with her husband to rural Louisiana. Upon his death, she and her children returned to St. Louis, where she @{(year <= 1904) has|} found work as a journalist.
				*if year >= 1899
					Her second novel, [i]The Awakening[/i], has been well-received by local critics.
				*if year > 1904
					She died of a brain aneurism while attending the Louisiana Purchase Exposition.
			
			*if francis_cockrell_resolution > 1
				[b]Francis Cockrell[/b] was a Confederate colonel during the siege of Vicksburg, where he was wounded in the hand. After the war, Cockrell was elected to the United States Senate, serving five terms there. @{(year > 1905) He retired from the Senate in 1905 and went on to serve in several other Federal posts until his death in 1915.|}
				
			*if lpe_member = 2
				[b]Minor Cockrell[/b] is @{(francis_cockrell_resolution > 1) a nephew of Francis Cockrell|a member of an extended political clan of the region}. He was born in 1880.
			
			[b]John Cockerill[/b] @{(year < 1883) is|was} the managing editor of the [i]St. Louis ${post_dispatch}[/i]. He shot Alonzo Slayback to death in November, 1882.
			*if post_dispatch_result = "sacked"
				A large, angry mob gathered outside the newspaper offices that night.  The mob turned violent and sacked the building, destroying the presses in the process.
				*if cockerill_condition = "lynched"
					In their fury, the mob even went to far as to lynch Cockerill.
			*if cockerill_condition = "imprisoned"
				Following a trial, Cockerill was found guilty of manslaughter, and sentenced to five years.
			*if (cockerill_condition != "lynched") and (cockerill_condition != "imprisoned")
				A grand jury refuses to indict Cockerill, but the newspaper experiences a continued decline as long as Cockerill remains editor.  Therefore, Pulitzer sends Cockerill to New York to manage the newly-purchased [i]New York World[/i] in January, 1883.
			
			*if stl_met_slattery > 2
				[b]Judge Cranch[/b] is a corrupt local judge. He and Sergeant Slattery could be described as "in cahoots" with one another.

			[b]Thomas Crittenden[/b]
			*if year < 1882
				is a United States Representative.
			*elseif year <= 1885
				is Governor of Missouri, formerly a United States Congressman (1877-1881).
			*else
				was formerly a United States Congressman (1877-1881) and Governor of Missouri (1881-1885).
			*if heresy_of_masons > 0
				He is a Freemason.
			
			*if year > 1888
				[b]Thomas Stearns Eliot[/b] is the great-nephew of Hiram Eliot. @{(year > 1904) He bears an uncanny resemblance to his great-uncle.|}
				
			*if saw_annie
				[b]Richard "Dick" Elliot[/b] is a carnival barker and the husband of [b]Annie Jones[/b].
				*if (stlouis_affair = 5) or (stlouis_affair = 4)
					You murdered him.
				*elseif stlouis_affair = 6
					He murdered his spouse and fled St. Louis.
				*elseif (year > 1895) and (stlouis_affair < 4)
					He and Jones divorced in 1895.
			
			*if year >= 1900
				[b]Joseph Folk[/b] @{(year <= 1904) is|was} the circuit attorney for St. Louis. He has made himself a name by prosecuting white-collar fraud and corruption cases throughout the city.
				*if year = 1904
					Based upon those successes, he is campaigning for governor.
				*if year > 1904
					Due to those successes, he was elected governor in 1904.
			
			*if (year >= 1885) and (year < 1889)
				[b]David Rowland Francis[/b] is mayor of St. Louis.
			*elseif (year >= 1889)
				[b]David Rowland Francis[/b] is governor of Missouri. He was formerly mayor of St. Louis, 1885-1889.
			*elseif (year >= 1894)
				[b]David Rowland Francis[/b] was formerly mayor of St. Louis, 1885-1889, and governor of Missouri, 1889-1893. He is a grain merchant.
			*elseif (year >= 1898)
				[b]David Rowland Francis[/b] the chairman of the Louisiana Purchase Exhibition. He was formerly mayor of St. Louis, 1885-1889, and governor of Missouri, 1889-1893. He is a grain merchant.
			*if stlouis_valet_num = 3
			
				[b]Ernst Geissler[/b] @{stlouis_valet_alive is|was} your valet in St. Louis.
			
			*if (year > 1895)
			
				[b]Reginald "Reggie" Gilchrist[/b] is a farmer from Ste. Genevieve. Following an attack on a local matron, he was apprehended and subsequently he disclosed the belief that he is a werewolf, cursed to change form under the full moon.
			*if (year > 1865) and (gould_plot < 3)
			
				[b]Jason "Jay" Gould[/b] is a railroad tycoon from New York.
				*if year > 1869
					His first burst of fame comes when he nearly corners the gold market in September, 1869 through his connections with President Grant. Despite the plot being foiled, he still manage to break even on the affair.
			*if (year >= 1886) and (geronimo_vampire = false)
			
				[b]Goyahkla[/b], called Geronimo, @{(geronimo_murdered or (year > 1909)) was|is} a Chiricahua Apache leader and medicine man. He was apprehended by the US Army for a final time in 1886, and @{(geronimo_murdered or (year > 1909)) lived the rest of his life as|has been} a prisoner of war at Fort Sill, Oklahoma@{(geronimo_murdered or (year > 1909)) | ever since}.
			*if saw_annie
			
				[b]Annie Jones,[/b] better known as "the Bearded Lady," 
				*if stlouis_affair = 12
					was a sideshow headliner with the Barnum & Bailey Circus. She was consumed by @{west_prob ${imposter}|West}.
				*elseif stlouis_affair = 11
					was a sideshow headliner with the Barnum & Bailey Circus. She died of tuberculosis in her mother's home in Brooklyn.
				*elseif stlouis_affair = 10
					was a sideshow headliner with the Barnum & Bailey Circus. You drank her dry.
				*elseif stlouis_affair = 5
					was a sideshow headliner with the Barnum & Bailey Circus. You murdered her and her partner, Dick Elliot.
				*elseif stlouis_affair = 13
					was a sideshow headliner with the Barnum & Bailey Circus. After moving to St. Louis to be with you, she died of tuberculosis.
				*elseif stlouis_affair = 6
					was a sideshow headliner with the Barnum & Bailey Circus. She was murdered by her husband, Dick Elliot.
				*else
					@{(year <= 1902) is|was} a sideshow headliner with the Barnum & Bailey Circus. 
			
			*if stlouis_valet_num = 2
				[b]Maeve Keegan[/b] @{stlouis_valet_alive is|was} your valet in St. Louis.
			
			[b]Albert Lambert[/b] is the 
			*if (year < 1896)
				heir to Lambert Pharmaceuticals. The company—which holds the right to the production of Listerine—is held in trust until his twenty-first birthday.
			*elseif (year <= 1925)
				president of Lambert Pharmaceuticals. The company holds the rights to the production of Listerine.
			
			*if year >= 1889
				[b]Jordan Lambert[/b] was a pharmaceutical magnate who died in 1889. He was the father of Albert Lambert.
			
			[b]Meriwether Lewis[/b] was an explorer recruited by President Thomas Jefferson to map the Louisiana Purchase with his friend William Clark.  After the expedition, Lewis settled in St. Louis, where he died in 1809. @{(heresy_of_masons > 0) He was the founder of the first Freemason Lodge of St. Louis.|} He was the cousin once removed of Minor and Niles Meriwether.
			
			*if (stlouis_affair > 12) or (stlouis_affair = 8)
				[b]Hattie Parsons[/b] is a seamstress from New York City.
			
			[b]John G. Priest[/b] is the first to wear the mantle of the Veiled Prophet.  He is acting president of the Metropolitan Police's Board of Commissioners.
			
			[b]Joseph Pulitzer[/b] is the owner of the [i]St. Louis ${post_dispatch}[/i], a newspaper which he formed by purchasing and merging two individually failing newspapers in 1878.
			*if year >= 1883
				Pulitzer was already looking to expand his reach when Cockerill slew Slayback, and purchased the [i]New York World[/i] shortly thereafter.
				*if (cockerill_condition != "lynched") and (cockerill_condition != "imprisoned")
					By the end of 1883, he followed Cockerill to New York.
				*if (cockerill_condition = "lynched") or (cockerill_condition = "imprisoned")
					After appointing a new editor for the [i]Post-Dispatch[/i], he relocated to New York to oversee the [i]World[/i].
			*comment endif
			
			[b]Florence Wyman Richardson[/b] is a local philanthropist @{(missouri_suffrage > 1) and advocate for women's suffrage|}. She is also president of the local Theosophical Society.
			
			*if (stlouis_valet_num = 4) and stlouis_valet_alive
				[b]Franklin Ross[/b] @{stlouis_valet_alive is|was} your valet in Memphis, and you brought him with you to St. Louis.
						
			[b]Sigrid[/b] is the valet of Lothar Aichinger.

			*if stl_met_slattery > 1
				[b]Sergeant Slattery[/b] is a local police officer, in league with Judge Cranch.
			
			[b]Alonzo Slayback[/b] was a colonel in the Confederate army.  Along with his brother Charles, he organized the founding of the Veiled Prophet Society in 1878.
			*if year > 1883
				He was shot to death in November, 1882 when he angrily barged into the office of John Cockerill at the St. Louis [i]Post-Dispatch[/i].
			
			[b]Charles Slayback[/b] was a soldier in the Confederate army.  Along with his brother Charles, he organized the founding of the Veiled Prophet Society in 1878.
			
			[b]Susie Slayback[/b] is the daughter of Charles.  She was the first Queen of Love and Beauty of the Veiled Prophet Society.
			
			*if met_sosostris
				[b]Mme. Sosostris[/b] @{(year <= 1904) is|was} a fortune-teller in the employ of P. T. Barnum's Greatest Show on Earth & Howes' Great London Circus & Sanger's Royal British Menagerie.	
				*if year = 1904
					She has separated from Barnum and set up her own shop on the Pike at the Louisiana Purchase Exhibition.
				*elseif year > 1904
					She broke with the circus and had her own tent on the Pike at the Louisiana Purchase Exhibition. She is presumably still on the exhibition circuit.
			
			*if stlouis_valet_num = 1
				[b]George Sutton[/b] @{stlouis_valet_alive is|was} your valet in St. Louis.
			
			[b]Andrew "Cap" Tilles[/b] is a local entrepreneur in the cigar and horse racing businesses.
			
			[b]James Milton Turner[/b] @{(year < 1881) is|was} a member of the Committee of Twenty-Five, organized to assist the Exodusters. Previously, he was the first US Ambassador to Liberia.
			*if year > 1895
				Since 1895, Turner has lived primarily in Oklahoma, where he has been involved with the fight for recognition by the Cherokee, Choctaw, and Chickasaw Freedmen.
			
			[b]Othello Turner[/b] is the great-nephew of James Milton Turner.
			
			*if memphis_baseball or (year >= 1885)
				[b]Chris Von der Ahe[/b] is the owner of the St. Louis Brown Stockings, a charter member of the American Association baseball league. A saloon-owner, he purchased the team in 1881 as a way to sell beer.
				*if (year >= 1885)
					The team wins pennants four years in a row, beginning in 1885. 
			*comment endif
			
			*if heard_of_ellis_wainwright
				*if year <= 1901
					[b]Ellis Wainwright[/b] is the president of the St. Louis Brewing Association.
					*if (year > 1889) and wainwright_built
						The Wainwright Building is named for him; he owns a controlling interest in it.
			
			*if year >= 1899
				[b]Edward Whitaker[/b] is a local banker who becomes famous when he organizes a streetcar monopoly St. Louis. Upon achieving a monopoly, he immediately hiked fares and cut services, resulting in a massive strike by the city's workers.
			
			*if eliot_in_greece
				[b]Evangelis Zappas[/b] [i]recit[/i] was the mortal descendant of Evangelis Zappas [i]histoire[/i], who served his ancestor and was eventually replaced by him.  He lived in Wallachia for most of his life, except when he was fighting for Greek independence from 1821-1828.
			*goto mortals_gallery
	*if presented_vicksburg
		#Vicksburg.
			*text_image mortals_gallery.png center Mortals' Gallery
			*if love_hope
				[b]Michael Compton[/b] was a sergeant in the Confederate Army and a friend of Silas Hope.
			
			*if (year > 1874)
				[b]Peter Crosby[/b] is the deposed Sheriff of Warren County. He was elected by popular vote, but was deposed by a white militia almost immediately thereafter. His attempt to regain his office was thwarted by the militia and resulted in the militia murdering scores of formerly enslaved people.
			
			[b]Jefferson Davis[/b] @{(year <= 1865) is the first President|was the first—and only—President} of the Confederate States of America.
			
			*if (francis_cockrell_resolution > 2) and (year < 1878)
				[b]Frances Cockrell[/b] was a Confederate colonel who helped defend Vicksburg.

			[b]Duff Green[/b] is a mortal cotton-planter who lives next door to Samantha Withers. @{(year >= 1863) His wife gives birth during the early days of the siege.|}
	
			*if love_hope
				[b]Silas Hope[/b] @{(year <= 1863) is|was} a young lieutenant in the Confederate Army, a member of the Jeff Davis Rebels, Company E, 46th Mississippi Infantry.
			
			*if maddox_num = 2
				[b]Anselm Martin[/b] @{(maddox_status = "alive") is|was} your valet in Vicksburg as well. He lost an eye to the villagers of St. Charles parish when the two of you were fleeing your home there.
			*else
				[b]Wilson Maddox[/b] @{(maddox_status = "alive") is|was} your valet.  He @{(maddox_status = "alive") is|was} missing an ear, lost to the whip of an over-enthusiastic foreman.
			
			*if background = 3
				[b]Mr. Troutwine[/b] is a wealthy landowner who lives in Vicksburg.
			*goto mortals_gallery
	#Go to the Vampires' Gallery
		*text_image vampires_gallery.png center Vampires' Gallery
		*goto rogues_gallery
	#Return to the Stat Chart.
		*goto stat_chart