*comment ñáéç
*page_break
*temp combat
*set combat 0
*set combat +strength
*if shapeshifting > 3
	*set combat +4
*set combat +agility
*if shapeshifting = 3
	*set combat +2
*set combat +(fighting*1.5)
*temp current_location
*set current_location chicago_haven_neighborhood

*label night_check

*if Blood > 15
	*set blood 15
	*goto night_check_2
*if Blood <= 15
	*goto night_check_2

*label night_check_2
*set Blood -1
*if Blood <= 0
	I'm out of blood.
	*page_break
	The hunger is too great... I cannot control it.
	*page_break
	I am covered with blood.  There is a dead body before me... I don't recognize him.  I am full, but now I must flee...
	*set Blood +10
	*set Compassion %+10
	*set Exposure +1
	*set recent_misdeed 3
	*set Wealth +10
	*goto night_check
*if Blood > 0
	*set wealth +income
	*goto night_check_3

*label empty
*goto little_italy

*label night_check_3
*if blood < 4
	It should be noted that you are hungry... if you are forced to any sort of exertion, you could lose control of yourself.
	*gotoref current_location
*else
	*gotoref current_location

*label blood_check
*if Blood > 15
	*set blood 15
	*gotoref current_location
*if Blood <= 15
	*gotoref current_location

*label hunt
*if (combat <= 6) and (charm < 3)
	*if willpower <= 3
		You are not up to the task.  Only by unleashing the animal within are you able to subdue your prey, but that also means killing him.
		*set exposure +1
		*set blood +10
		*set compassion %+10
		*set discretion %+5
		*set wealth +10
		*goto blood_check
	*else
		After an hour of stalking you prey, you are on the verge of losing control of yourself.  Only your iron will manages to suppress the beast inside you.  Desperate, turn to a stray cat nearby to assuage the hunger.
		*set blood +2
		*goto blood_check 
*else
	This is not a problem.
	*set blood +4
	*goto blood_check

*label uptown_2
Current Blood: ${blood}
*choice
	#I need to hunt.
		*set current_location "uptown_2"
		*goto hunt
	#I head to the Stroll to meet with Phineas.
		*goto meet_phineas

*label little_italy
Current Blood: ${blood}
*choice
	#I need to hunt.
		*set current_location "little_italy"
		*goto hunt
	#I head to the Stroll to meet with Phineas.
		*goto meet_phineas

*label lincoln_park
Current Blood: ${blood}
*choice
	#I need to hunt.
		*set current_location "lincoln_park"
		*goto hunt
	#I head to the Stroll to meet with Phineas.
		*goto meet_phineas

*label south_side_2
Current Blood: ${blood}
*choice
	#I need to hunt.
		*set current_location "south_side_2"
		*goto hunt
	#I head to the Stroll to meet with Phineas.
		*goto meet_phineas
		
*label canaryville
Current Blood: ${blood}
*choice
	#I need to hunt.
		*set current_location "canaryville"
		*goto hunt
	#I head to the Stroll to meet with Phineas.
		*goto meet_phineas

*label meet_phineas

Again, the Stroll is populated by a rainbow's spectrum of dames and fellas, sauntering up and down and showing off their glad rags, blissfully unaware of the violence seething around them.

*if anachronism < 30
	Unfortunately for you, your outfit is still so outdated that it draws stares from the passersby.  Not a good way to begin a circumspect operation.
	*goto meet_phineas_3
*else
	*goto meet_phineas_3

*label meet_phineas_3
*if perception > 2
	You notice Phineas approaching from some distance.  You watch him light a cigarette as waits for a car to pass, and then he joins you on the sidewalk.
	*goto meet_phineas_2
*else
	You are startled when Phineas appears on the sidewalk next to you, smoking a cigarette.
	*goto meet_phineas_2

*label meet_phineas_2

"Evening," he begins.

"Evening," you reply.

"Violet's in the Cafe.  I need you to lure her outside.  I think she'll know where we can find Clythenomenes," he says with a grin "and we need to put her on ice anyway."

*if train_charm
	"That should be easy.  She's expecting me.  She's supposed to teach me some pointers on how to better charm my prey."
	
	"Excellent."
	*page_break
	*goto meet_phineas_4
*if Status > 3
	"That should be easy.  I'll just ask her to accompany me outside."
	
	"Excellent."
	*page_break
	*goto meet_phineas_4
*if charm > 4
	"That should be easy.  I'll just ask her to accompany me outside."
	
	"Excellent."
	*page_break
	*goto meet_phineas_4
*else
	"How am I supposed to do that?"
	
	"I don't know!  Tell her you need to show her something!"
	
	"Like she'd go anywhere with me and without her bodyguards!"
	
	"Maybe you tell her that she and O'Donnell need to have a talk?"
	
	"Why would he send me with that message?"  You're getting the distinct impression that Phineas isn't the brightest star in the sky.  The two of you sit in silence for a moment before an idea pops into your head.
	
	"I have it.  I'll tell her that there's some guy yelling about being a 'demon' behind the Cafe... she'll probably bring her bodyguards with her, though, so be prepared to grab her when they go ahead."
	
	"That's good thinking, ${given_name}."
	*page_break
	The ruse works.  A right gee hired off the street makes a racket down and around the corner where Clyde had been the other night.  The bodyguards rush down the alley in that direction, while Phineas appears from the street, gun at the ready.
	
	Violet sees Phineas coming, but it's too late, especially with you so close and blocking her way.  He jabs the gun into the small of her back.
	*goto meet_phineas_5	

*label meet_phineas_4
You lead Violet out to the curb to wait for her driver to come with a car.  At this moment, Phineas appears behind her from out of the crowd, jabbing a gun into the small of her back.
*goto meet_phineas_5

*label meet_phineas_5
"Don't make a sound, sugar.  I know this gun won't really hurt you, not in the long run anyway, but there are far too many people here for you to just get up after I pump you full of lead."

"What do you want?" she demands.  Apparently the threat of O'Donnell and the Society's wrath outweighs the threat of you and Phineas and whatever it is you might be planning for her.

Phineas jerks his head at you: "Lead the way, ${given_name}."
*page_break

A nearby tenement room has been prepared for this.  The three of you traipse up to the third floor, and you shut the door behind you.  Violet is clearly worried.

"Violet, you know as well as we do that Clyde has gone off the deep end.  We need to find him and put an end to his shenanigans.  I also know that, if there's anyone who can tell us where he is, it's you."

"Shove off, Phineas.  I've got nothing for you."
*choice
	*if compassion > 60
		#"I think it's time to hurt her until she talks."
			*goto torture_violet
	*if charm > 2
		#"Violet, you need to understand, Clyde is a threat to us all..."
			*goto persuade_violet
	*if compassion > 60
		*if discretion > 50
			#"She won't give us anything.  Just kill her."
				*goto torture_violet
	#Let Phineas handle this.
		*goto torture_violet_5

*label kill_violet
"You're right, ${given_name}.  But first, we need to find out what she knows.  Hold her down."
*set violet_killed true
*set compassion %+10
*goto torture_violet_2

*label torture_violet
"I like the way you think, ${given_name}.  Sit her down there," he says, pointing.
*goto torture_violet_2

*label torture_violet_5
"Sit her down there," he says, pointing.
*goto torture_violet_2

*label torture_violet_2
You force Violet down into the room's sole chair while Phineas draws a rusty pair of pruning shears from somewhere on his body, wrapped in a handkerchief.  He tosses you the handkerchief, and gestures for you to stuff it in her mouth.  Pulling of one of her high-heeled shoes, he begins to hum a little ditty to himself.

Violet is struggling in your arms.  Apparently, regardless of the fact that the shears won't do any permanent damage, the prospect of losing a toe is still something she does not relish.  This is not exactly your idea of how to spend a Thursday night, but what else is there to do?

It only takes a few clips of the shears before tears of blood are running down Violet's cheeks.

"Where's Clyde?" he asks, simply.  It seems she's ready to talk.

"He has a place, down on west 53rd street, just east of Sherman Park.  You can't miss it."

"Now, that wasn't so hard, was it?  Do you want your toes back?"  Phineas inquires, picking them up and offering them to Violet.  With an expression of exasperation, Violet grabs her severed toes from Phineas, and then turns to recover her heels.

You look at Phineas questioningly.

"${given_name}, why don't you ankle?  Violet and me, we got a few things left to work out."
*set compassion %+10
*set violet_hates_player true
*goto torture_violet_3

*label torture_violet_3
You step outside into the tenement's hallway, closing the door behind you.  A few thumps and a whimper seep through the doorframe.  A few minutes later, Phineas emerges, wiping blood from his hands with the handkerchief.

"Shall we?"  The look on Phineas' face does not invite questions or objections.
*set violet_interrogated true
*page_break
*goto_scene chicago_clyde

*label persuade_violet
Phineas rolls his eyes as you lauch into an argument as to why Violet should help you and Phineas find Clyde.  After all, his antics are clearly a threat to the Society... and besides, if she doesn't help the two of you, she's clearly deluded in the same way, and is also a threat to Society as well...

Mixing in this way an appeal to her self-interest and the general threat of pain and death, you persuade her to identify Clyde's haven on west 53rd, just east of Sherman Park.

"${given_name}, why don't you watch the hallway.  I'll finish up in here."
*set violet_coopted true
*goto torture_violet_3