*comment ñáéç
*temp drake_room
*set drake_room false
*temp met_violet
*set met_violet false
*temp met_rainer
*set met_rainer false
*temp wealth1920
*set wealth1920 0
*temp chance_with_capone
*set chance_with_capone true
*temp combat
*set combat 0
*set combat +strength
*if shapeshifting > 3
	*set combat +4
*set combat +agility
*if shapeshifting = 3
	*set combat +2
*set combat +(fighting*1.5)

*label city_screen
*set current_location "city_screen_2"
*goto night_check

*label city_screen_2

Chicago, a bustling city of almost three million, spreads out from the shores of Lake Michigan in all directions.

Current Blood: ${blood}
*line_break
*set wealth1920 wealth/12
Current Wealth: ${wealth1920}

You should be aware that, as you drop below 5 blood, you become increasingly ravenous and more likely to lose control of yourself.  If you are over 10, you feel satiated and ready to take on the world.

*choice
	*if lore > 0
		#It would be wise to find the city's Quaestor, and make myself known to him.
			Quaestors often post associates in some sort of conspicuous location.  Such associates will know how to find the Quaestor, and can also keep an eye on such valuable hunting grounds.  The trick will be to figure out what that conspicuous location is.
			*choice
				#The Blackstone Hotel.  The favorite of politicians and businessmen.
					*goto blackstone_hotel
				#The Drake Hotel. Opened just last year, it is the spot for the rich and famous.
					*goto drake_hotel
				#The Royal Gardens.  A famous jazz joint on the South Side.
					*goto royal_gardens
				#The Majestic Poolroom.  Pool or billiards could be mistaken for the national pastime, if you were to observe how Chicagoans spend their free time.
					*goto majestic_poolroom
	#I need to hunt.
		Sniffing the wind, you breathe in the heady scent of thousands of mortals just waiting to offer you their lifeblood.
		*choice
			#Head to the Stroll, a hopping strip on the South Side.
				*goto south_side
			#Head uptown... I prefer to prey on the rich and stylish.
				*goto uptown
			#West of the river are the immigrant ghettos... that should be easy pickings.
				*goto little_italy
	*if chicago_haven_neighborhood = "empty"
		#I want to find a place to set up a more permanent residence.
			*choice
				*if ethnicity = "african"
					#The South Side is probably the safest place for you to go.
						*goto south_side
				*if ethnicity = "german"
					#The Germans have made their mark in the Lincoln Park area.
						*goto lincoln_park
				*if ethnicity = "irish"
					#The Irish have made their homes in Canaryville, south of 'South Side'.
						*goto canaryville
				#Little Italy and the Near West Side are composed of a mix of Irish and Italian immigrants.  It should be relatively easy for almost anyone to set up here.
					*goto little_italy
				*if wealth > 550
					#I can afford a month at one of the new residence hotels.
						*goto uptown
	*if chicago_haven_neighborhood != "empty"
		#It's time to explore my new home.
			*choice
				#The South Side is home to Chicago's black population.
					*goto south_side				
				#The Germans have made their mark in the Lincoln Park area.
					*goto lincoln_park
				#The Irish have made their homes in Canaryville, south of 'South Side'.
					*goto canaryville
				#Little Italy and the Near West Side are composed of a mix of Irish and Italian immigrants.
					*goto little_italy
				#Uptown is where the wealthy put on the ritz.
					*goto uptown

*label evanston
*set evanston false
*set blood -2

It is no small thing to find a car willing to take you to Evanston, and from there ferry you around to the different hotspots and such in your attempts to locate this Willie Chapel character.
*if (streetwise = 0) and ((charm < 3) and (perception < 3))
	Unfortunately, no one is willing to speak to this stranger asking about where he can find some jook juice.  As dawn approaches, you are forced to direct your driver to take you back to the city.
	*goto night_check
*else
	*if sire_name = "Guillaume de Sainte-Chapelle"
		*if sire_rapport >= 40
			*set sire_rapport %+10
			Thus it is with relief when you slip into a speakeasy and see your maker, in a pinstripe suit and fedora, sitting at the head of a table.  With a chill down your spine, you look across the room and nearly a century of time to meet his gaze.

			"My dear ${given_name}!  How lovely it is to zhee you," he says, standing to greet you with a kiss on both cheeks.  It seems as though his accent has grown only more accentuated with the decades.

			"It is good to see you as well, dominus," you say, taking a seat beside him.

			"How did jhou find me?  Have jhou been in Chicago long?"

			"I just arrived, in fact.  I heard that a Willie Chapel had set up shop in Evanston, and figured I should see if that was you..." and so begins a conversation that tries to cover decades of unlife.
			
			Some hours pass...
			*page_break 
			Daybreak approaching, you are forced to bid Chapel adieu and return to your car and your haven.
			*goto night_check
		*else
			*set sire_rapport %+10
			It is uncanny how quickly your maker's eyes find you, once you enter his place of relaxation.  From across the speakeasy, he is easy to pick out in his pinstripe suit and fedora, flappers and dewdroppers fawning around him.
			
			"${given_name}!  How delightful it is to zhee you," he says without warmth.  It seems as though his accent has grown only more accentuated with the decades.

			"It is good to see you as well, dominus," you say, taking a seat beside him.

			"How did jhou find me?  Have jhou been in Chicago long?"

			"I just arrived, in fact.  I heard that a Willie Chapel had set up shop in Evanston, and figured I should see if that was you..."

			"And so jhou have found me.  Vhat can I do for my errant offspring?"
			*goto question_chapel
	*else
		*set well_yes true
		That said, once you're in the right place, he is unmistakable.  Dolled up in a pinstripe suit and fedora, he sits at the head of a table as activity buzzes around him.  He must be intentionally ignoring you, because he does not raise his gazes to your until you've been standing before him for several moments.
		*if speaks_english
			"Can I help jhou, my friend?" he says.

			"I am new to this area.  I'm going around and calling on people to make my round of introductions."

			"That is very kind of jhou to come all zhis vay from zhe city.  I zuppose that ze Quaestor told you to make your home out zhis vay?"

			"No, I simply heard that you were here..."

			"And jhou came all zhis vay just to zay 'ello?"
			*goto question_chapel
		*elseif speaks_french
			"Can I help you, my friend?" he inquires.

			"I am new to this area.  I'm going around to make my introductions, as I might wish to stay awhile."
	
			"That is very kind of you to make a trip all the way out here.  I imagine M. le Quaestor O'Donnell told you to make your home out this way?"

			"No, I simply heard that you were here..."

			"And you came all this way just to say hello?"
			*goto question_chapel_french			
		*else
			Willie Chapel looks at you with scorn.  He's clearly insulting you and your mother, and generally mocking you for your failure to learn the language of the land.

			Tired and frustrated, you head back out to your waiting car.
			*page_break
			*goto night_check

*label question_chapel
*if (questions_for_willie > 2) 
	*if well_yes
		"Zhat is enough qwestions.  I am not Philomena, I do not have all zhee answers."
	
		"I thank your for your time, Mr. Chapel."
	
		"Good evening to you, ${given_name}."  Excusing yourself, you head back to your car and the city.  But who is Philomena?
		*page_break
		*goto night_check
	*else
		It grows late, and you have to leave now in order to get back to your haven before daybreak.  Sainte-Chapelle sees you to your car, and waves at you as you turn around a corner.
		*page_break 
		*goto night_check
*else	
	*choice
		*if well_yes
			#"Well, yes."
				*set well_yes false
				"Vell, 'ello, and!, goodbye."  With that, you find yourself summarily dismissed.  You return to your waiting car frustrated and ready for sleep.
				*goto night_check
		#"No, I wanted to know where I can find Rainer Teufel."
			*set knows_about_chicago_union_hall true
			"Vhy bother me vith zees qwestions?  That vrabble-vrowser spends zhees time at zhee Union Hall, vhere zhey speak of zhose fools Marx and Lenin."
			*set questions_for_willie +1
			*goto question_chapel
		*if sire_name = "Guillaume de Sainte-Chapelle"
			#"Why did you change your name?"
				"It became clear to me zhat I was fvalling behind zhee times.  Tout le monde looked at me like I had zhee two heads when zhey met me.  And zho, I decided zhat my name it needed to be made a la courant, if djou know vhat I mean.
				*if archaic_name
					In fact, ${given_name}, djou might consider such a thing djourself."
					*goto question_chapel
				*else
					"TODO"
					*goto question_chapel
		#"TODO"
			*set questions_for_willie +1
			*goto question_chapel

*label question_chapel_french
*if questions_for_willie > 2
	*if well_yes
		"That is enough questions.  I am not Philomena, I do not have all the answers."

		"I thank your for your time, Mr. Chapel."

		"Good evening to you, ${given_name}."  Excusing yourself, you head back to your car and the city.  But who is Philomena?
		*page_break
		*goto night_check
	*else
		It grows late, and you have to leave now in order to get back to your haven before daybreak.  Sainte-Chapelle sees you to your car, and waves at you as you turn around a corner.
		*page_break 
		*goto night_check
*else	
	*choice
		*if well_yes
			#"Well, yes."
				*set well_yes false
				"Well, hello, and!, goodbye."  With that, you find yourself summarily dismissed.  You return to your waiting car frustrated and ready for sleep.
				*goto night_check
		#"No, I wanted to know where I can find Rainer Teufel."
			*set knows_about_chicago_union_hall true
			"Why bother me with these questions?  That rabble-rowser spends his time at the Union Hall, where they speak of those fools Marx and Lenin."
			*set questions_for_willie +1
			*goto question_chapel
		#"TODO"
			*set questions_for_willie +1
			*goto question_chapel

*label night_check
*if Blood > 15
	*set blood 15
	*goto night_check_2
*if Blood <= 15
	*goto night_check_2

*label night_check_2
*set Blood -1
*if Blood = 0
	I'm out of blood.
	*page_break
	The hunger is too great... I cannot control it.
	*page_break
	I am covered with blood.  There is a dead body before me... I don't recognize him.  I am full, but now I must flee...
	*set Blood +10
	*set Compassion %+10
	*set Exposure +1
	*set recent_misdeed 3
	*set Wealth +10
	*goto night_check
*if Blood > 0
	*set wealth +income
	*goto night_check_3

*label night_check_3
*set wealth +income
*if blood < 4
	It should be noted that you are hungry... if you are forced to any sort of exertion, you could lose control of yourself.
	*goto night_check_capone_loan
*else
	*goto night_check_capone_loan

*label night_check_capone_loan
*if loan_to_capone and (progression_in_time >= 4)
	*set loan_to_capone false
	*set wealth +40000
	
	You wake up to a note of thanks and a satchel full of hundred dollar bills.  It seems that Mr. Capone was successful with his endeavor.
	*gotoref current_location
*else
	*gotoref current_location

*label blood_check
*if Blood > 15
	*set blood 15
	*gotoref current_location
*if Blood <= 15
	*gotoref current_location

*label hunt
*if (combat <= 6) and (charm < 3)
	*if willpower <= 3
		You are not up to the task.  Only by unleashing the animal within are you able to subdue your prey, but that also means killing him.
		*set exposure +1
		*set blood +10
		*set compassion %+10
		*set discretion %+5
		*set wealth +10
		*goto blood_check
	*else
		After an hour of stalking you prey, you are on the verge of losing control of yourself.  Only your iron will manages to suppress the beast inside you.  Desperate, turn to a stray cat nearby to assuage the hunger.
		*set blood +2
		*goto blood_check 
*else
	This is not a problem.
	*set blood +4
	*goto blood_check

*label empty
*goto little_italy

*label little_italy

The 18th and 19th wards used to be an Irish neighborhood, but the tide is turning rapidly in favor of Italians, particularly Neapolitans and Sicilians.  Within twenty years, this area will come to be known as Chicago's 'Little Italy', but for now it is still a neighborhood in transition.

Where do you want to go explore?

Current Blood: ${blood}
*line_break
*set wealth1920 wealth/12
Current Wealth: ${wealth1920}

*choice
	*if fled_from_nicky = false
		#The Majestic Poolroom.
			*goto majestic_poolroom
	*if knows_sals = false
		#I want to try to locate a speakeasy.
			*if perception > 2
				That's not a problem.  All you have to do is reach out your mind and you quickly light upon a mac in need of a drink... and who knows where to get one.
				*goto sals_place
			*elseif streetwise > 1
				That's not a problem... you know the signs for how to go about finding such a thing.
				*goto sals_place
			*elseif ethnicity = "irish"
				You just ask one of your countrymen where a poor mick can wet his whistle.
				*page_break
				Strangely, the closest place is owned by an Italian, but no matter.
				*goto sals_place
			*elseif speaks_english
				*if stealth > 3
					You project the image of yourself as being of Irish descent into the minds of the people around you, and soon you find a 'countryman' willing to let you know where a poor mick can wet his whistle.
					*page_break
					Strangely, the closest place is owned by an Italian, but no matter.
					*goto sals_place
				*elseif charm > 2
					With a few well-chosen words, you coax a right gee into pointing the way to Sal's Place.
					*goto sals_place
				*elseif (stealth > 0) and (perception > 0)
					If you stand somewhere inconspicuous long enough, listening in on conversations, you're bound to hear about something, right?
					*goto sals_place
			It seems you lack the skills to locate a place that doesn't want to be found.  This whole Prohibition thing could make hunting difficult.
			*goto little_italy
	*if knows_sals
		#Drop by Sal's Place.
			A quick knock and the door of the juice joint opens before you.
			*goto inside_sals
	#I try to find someone to feed off of on the street... err... drag them into an alley...
		*set current_location "little_italy"
		*goto hunt
	*if evanston and (chicago_haven_neighborhood != "empty")
		*selectable_if (wealth > 500) #Hire a car to take you out to Evanston; maybe you can find this Willie Chapel guy.
			*set current_location chicago_haven_neighborhood
			*set wealth -500
			*goto evanston
	#I want to go to a different neighborhood.
		Not much of one for the 19th ward, eh?
		*choice
			#Canaryville, an old Irish neighborhood.
				*goto canaryville
			#Lincoln Park, home to mostly second-generation German immigrants.
				*goto lincoln_park
			#the South Side, Chicago's soon-to-be-famous black neighborhood.
				*goto south_side
			#Uptown, where the wealthy folks live.
				*goto uptown
	*if chicago_haven_neighborhood != "empty"
		#I want to go to sleep at my haven until tomorrow.
			*set progression_in_time +1
			*set current_location chicago_haven_neighborhood
			*if vigil
				On your way out the next evening, your new landlord stops you.
				
				"You going to the vigil tonight?"
				
				"Vigil?"
				
				"Where you from?  The vigil for Alderman Powers!"
				
				"I'm sorry?"
				
				"It was a year ago tonight that that bastard D'Andrea tried to blow up his house.  It's a damn shame when the politicians take to throwing bombs at each other."
				
				Attending a vigil with lots of open flames to protest the throwing of bombs between mortal politicians sounds like a bad idea to you, so you politely decline and go about your business.
				*set powers_and_dandrea true
				*set vigil false
				*goto night_check
			*else
				*goto night_check

*label sals_place

With a quick knock, knock--pause--knock, a small peephole opens, and you see a brown eye peering out at you.

*if male = false
	A loud whistle finds its way through the peephole, as the eye gets a load of you.  Someone goes so far as to fumble with the bolt as they hurry to get the door open and let you in.
	*goto inside_sals
*if ethnicity = "african"
	*if speaks_english
		*if stealth < 4
			"We don't serve your kind here!"
			The peephole slams shut.
			*goto little_italy
*if ethnicity = "african"
	*if speaks_english = false
		*if stealth < 4
			Someone yells something in English that you can't understand, and then the peephole slams shut.
			*goto little_italy
*if ethnicity = "choctaw"
	*if stealth < 4
		"We don't serve your kind here!"
		The peephole slams shut.
		*goto little_italy
*if speaks_english = false
	Someone yells something in English that you can't understand, and then the peephole slams shut.
	*goto little_italy
*else
	"Show me the kale."  You wave an ace before the peephole, and then you hear the bolt draw back and the door opens.
	*goto inside_sals

*label inside_sals
*set knows_sals true

Once inside Sal's, your eyes adjust and reveal a dingy saloon.  While you've heard of fancy speakeasies with dancing and jazz and cabaret singers, this is just a place where the locals come after work to get tanked.  A man, whom you can only assume to be Sal, stands behind the counter.

*if presented_chicago
	*if chance_with_capone
		There's a young Italian tough here, seems to be here to collect some protection money from Sal.
*goto inside_sals_1

*label inside_sals_1

*choice
	*if charm > 2
		#Get friendly with someone, get them drunk and then 'help' them home.
			A smashing success, if you do say so yourself.
			*set blood +4
			*set current_location "little_italy"
			*set vigil false
			*goto blood_check
	#Follow a drunk out of the place, knock him out and feed.
		*if combat <= 5
			You are not up to the task of knocking a drunk unconscious.  Only by unleashing the animal within are you able to subdue him, but that also means killing him.
			*set exposure +1
			*set blood +10
			*set compassion %+10
			*set discretion %+5
			*set wealth +10
			*set current_location "little_italy"
			*set vigil false
			*goto blood_check
		*else
			This is not a problem.
			*set blood +4
			*set current_location "little_italy"
			*set vigil false
			*goto blood_check
	*if vigil
		#One of the drunken patrons seems to be trying to ask you a question.
			"Are yous comin' to the vergil turmurrow?"
			
			"Vigil?"
			
			"Yeah, fur Powers.  It wuz er year 'go turmurrow night that they threw that dynermite at 'is 'ouse."
			
			"Dynamite?"
			
			"It were that bersterd D'Andrea thert did it..." the drunk's words drift off as his chin falls to his chest, asleep.
			*set powers_and_dandrea true
			*set vigil false
			*goto inside_sals_1
	*if chicago_haven_neighborhood = "empty"
		#Ask about a room to rent.
			A private room is no small matter.  A shopkeeper says he has a room above his store around the corner.  It would only be $5 a month.
			*choice
				#I'll take it.
					The shopkeeper delightedly leads you out of Sal's and around the corner.  The room is nothing more than he promised, but it will do for your purposes.  Conveniently, it is an interior room, with now windows to the outside.
					*set wealth -60
					*set chicago_haven_neighborhood "little_italy"
					*set vigil false
					*goto little_italy
				#Nevermind.
					The shopkeeper seems annoyed that you have wasted his time.
					*set vigil false
					*goto inside_sals_1
	*if presented_chicago
		*if chance_with_capone
			#Ask the young tough if you can buy him a drink.
				*if charm > 2
					*set chance_with_capone false
					*goto meet_capone
				*if charm = 2
					*if male = false
						*set chance_with_capone false
						*goto meet_capone
				*if stealth > 3
					*set chance_with_capone false
					*goto meet_capone
				*else
					*set chance_with_capone false
					
					He looks you up and down, and then snorts.  "I ain' got no time for the likes of you.  Now, clear out of here.  I gots business to attend to."
					
					At that, his bodyguards 'encourage' you to leave.
					*goto little_italy
	#Leave.
		*set vigil false
		*goto little_italy

*label meet_capone

After you've bought the man a drink, he introduces himself as Al... Al Capone.  You sense that this cat has a future ahead of himself.  After talking with him a while, you learn that he needs to cash to bring a load of booze into the country from Canada.  It's one of those high-risk, high-reward sorts of situations, you understand.  And it'll take several days for him to get the money back to you, but he's good for it... he promises.
*goto meet_capone_1

*label meet_capone_1
*if wealth <= 20000
	Unfortunately, you don't have enough money to lend him what he needs.

*choice
	*if wealth > 20000
		#I lend him the money.
			*set wealth -10000
			*set loan_to_capone true
			*set progression_in_time 0
			
			He thanks you, and lets you know that he'll get the money back to you as soon as he can.
			*goto little_italy
	#Let him know how nice it was to make his acquaintance.
		*goto little_italy
	#Feed from him.
		*set fed_from_capone true
		
		Hmmm... spicy.
		
		Now, about that loan?
		*goto meet_capone_1

*label majestic_poolroom

Large windows presume to look out on the street, but it's so dark inside that you can only pick out the general ebb and flow of bodies inside.  An awning overhangs the street, proclaiming the name 'Majestic' to the indifferent numbers on the street.

*choice
	*if presented_chicago = false
		#Enter.
			*if ethnicity = "african"
				The patrons of the Majestic stop and turn almost as one when you open the door.  They make you suddenly aware of the color of your skin.  Against their numbers, you decide to make a hasty retreat, before they turn violent.
				*set discretion %-5
				*goto little_italy
			*if ethnicity = "choctaw"
				The patrons scowl at you as you step inside the Majestic.  As you step further in, it is only your preternatural reflexes that save you from falling face-first into the floor.  A man near the door widens his eyes, surprised that you dodged his attempt to trip you.
				
				The manager, as soon as he notices you, comes around the bar yelling at you, "We don't serve your kind here!"  While you are briefly tempted to tear his throat out, discretion overrides this instinct, and you allow yourself to be thrown out.
				*set discretion %-5
				*goto little_italy
			*if male = false
				Your entrance is greeted with hoots and catcalls.  Everyone seems very interested in this skirt that has dared wander into the masculine domain.
				
				With the first pinch on your keister, you turn and give a sultry look, only to knee the poor mac in the groin; he falls to he knees to a cascade of laughter.  It's best to show these fellas who's in charge straight off.
				*goto inside_majestic
			*else
				While the patrons, in general, send dark scowls in your direction, it seems like they are not going to break you neck at this exact moment.
				*goto inside_majestic
	*if presented_chicago
		#Enter the Majestic.
			*goto inside_majestic_presented
	#Maybe another time.
		*goto little_italy

*label inside_majestic_presented
*temp nicky_vamp_question
*set nicky_vamp_question true

Large windows presume to look out on the street, but it's so dark inside that you can only pick out the general ebb and flow of bodies inside.  An awning overhangs the street, proclaiming the name 'Majestic' to the indifferent numbers on the street.
*goto inside_majestic_presented_1

*label inside_majestic_presented_1

*if pool_trounce
	No one here wants to play pool with you anymore.
	*goto inside_majestic_presented_2
*else
	*goto inside_majestic_presented_2

*label inside_majestic_presented_2
*choice
	*if met_nicky
		*if speaks_english
			#Have a chat with Nicky.
				You take a seat, and before too long Nicky comes around and sits with you.
				*goto talk_with_nicky
	*if met_nicky = false
		*if speaks_english
			#I should introduce myself to Niccolo Ciampa.
				*goto meet_niccolo
	*if pool_trounce = false
		#I want to play a game of pool.
			*temp bet
			You approach a table just as a game is concluding.  How much money do you drop?
			*choice
				#An ace.
					A man sizes you up, and then drops an ace beside yours.
					*set wealth -12
					*set bet 12
					*goto pool_resolve
				*if wealth > 60
					#An Abe.
						A man sizes you up, and then drops a fiver beside yours.
						*set wealth -60
						*set bet 60
						*goto pool_resolve
				*if wealth > 120
					#A sawbuck.
						This sets off a few whistles from the onlookers.  They don't seem to be used to seeing one of those all that often.
						*set wealth -120
						*set bet 120
						*goto pool_resolve
				*if wealth > 240
					#A double-sawbuck.
						The onlookers go silent.  Some have never seen a real $20 before.
						*set wealth -240
						*set bet 240
						*goto pool_resolve		
	#Head back out to the street.
		*goto little_italy

*label meet_niccolo
*set met_nicky true

You ask around about a Mr. Niccolo Ciampa.  People seem uncomfortable with the question.  Before long, an Italian man in a suit stomps in from the back and shouts, "I'm Nicky Chomps!  What's it to yous?"

Trying to diffuse the situation, you gesture to a booth and invite him to sit down.  "Mr. O'Donnell suggested that I introduce myself to you."

"Well, you best get my name right next time, yous hear me?"

"Yes, I do."

"Well, then, whaddya want?
*goto talk_with_nicky

*label talk_with_nicky
*choice
	*if powers_and_dandrea
		#"What is this I hear about Powers and D'Andrea?"
			"Powers is Alderman of the 19th Ward.  His grip on that district is fading with the influx of Italian immigrants.  D'Andrea lost to him in the last election.  Unfortunately, during the campaign the two of them took to arranging for explosive devices to be lain in inconvenient places in their mutual attempts to dissuade the other from continuing in a life of public service."
			
			"These politicians openly use bombs against one another?"
			
			"Much to my i-ration, yes."
			*set powers_and_dandrea false
			*goto talk_with_nicky
	*if nicky_vamp_question
		#"What other of our kind live in Chicago?"
			*set nicky_vamp_question false
			"Well, Senator Powell lives around here somewheres.  I don' see much of him.  And that socialist Teufel... Rainer Teufel... I 'magine he stays around Lincoln Park 'r ther'bouts.  All those p'rades in those parts are his doin, if yous were t' ask me.  He thinks we's all gonna live in u-topia.  I don' know where u-topia is, but if it's anythin liek Topeka, I don' wan' nuthin' t' do wit it."
			*set rainer true
			*goto talk_with_nicky_people
	*if lore > 2
		*if shepherds_and_wolves
			#"I suppose you fancy yourself something of a wolf?"
				*set shepherds_and_wolves false
				Nicky flashes you a toothy grin.  "Leave the shepherdin' to the old an' stuffy.  Me, Isa goin' t' take whut I wants from the sheep."

				"Have you ever seen a copy of the dialogue?"

				"Whatsa die-a-log?"
				*goto talk_with_nicky
	#"Thanks for chatting with me."
		*set shepherds_and_wolves true
		*goto inside_majestic_presented_1

*label talk_with_nicky_people
*if sire_name != "Guillaume de Sainte-Chapelle"
	Thers also this frog, by the name a' Willie Chapel.  He might be ovah 'n Evanston o' there'bouts."
	*set evanston true
	*goto talk_with_nicky_people_1
*if (sire_name = "Guillaume de Sainte-Chapelle") and sire_alive
	Thers also this frog, by the name a' Willie Chapel..."
	*set evanston true
	*goto talk_with_nicky_people_2
*else
	*goto talk_with_nicky_people_1

*label talk_with_nicky_people_1

*goto talk_with_nicky

*label talk_with_nicky_people_2

"Do you mean Guillaume de Sainte-Chapelle?"  You ask, your blood having run cold.

Nicky shifts uncomfortably.  "Mebbe.  Why, you knows 'em?"

"I'm not sure.  Where could I find him?"

"Evanston, I b'lieve."
*goto talk_with_nicky

*label inside_majestic

The manager offers you a cup o' joe, which you accept only under duress.  You've already drawn enough attention to yourself, you don't want to reject the man's drink too.

This place clearly used to be a saloon as well, but the liquor bottles have been cleared out.  As best as you can see, anyway.

*if perception > 2
	You sense, of course, that you could still get a drink if you really wanted one... and could get the manger to trust you enough to offer it.

Numerous pool tables are in use.  Men stand around smoking and drinking joe inbetween turns.  Very few seem to be uninvolved in one game or another.

*choice
	*selectable_if (anachronism > 50) #I want to play a game of pool.
		*temp bet
		You approach a table just as a game is concluding.  How much money do you drop?
		*choice
			#An ace.
				A man sizes you up, and then drops an ace beside yours.
				*set wealth -12
				*set bet 12
				*goto pool_resolve
			*selectable_if (wealth > 60) #An Abe.
				A man sizes you up, and then drops a fiver beside yours.
				*set wealth -60
				*set bet 60
				*goto pool_resolve
			*selectable_if (wealth > 120) #A sawbuck.
				This sets off a few whistles from the onlookers.  They don't seem to be used to seeing one of those all that often.
				*set wealth -120
				*set bet 120
				*goto pool_resolve
			*selectable_if (wealth > 240) #A double-sawbuck.
				The onlookers go silent.  Some have never seen a real $20 before.
				*set wealth -240
				*set bet 240
				*goto pool_resolve
	*if chicago_haven_neighborhood = "empty"
		*selectable_if (speaks_english) #I want to strike up a conversation... see if someone knows of a room for rent.
			It seems that, for $5 a month, you can get a place just around the corner.  Your new landlord is excited to introduce you to his wife.
				
			You follow him to the room.
			*page_break 
			The place will be sufficient.  You decide to settle down for the day to rest.
			*set chicago_haven_neighborhood "little_italy"
			*set current_location "little_italy"
			*goto night_check
	#I sit and watch one of the pool games.
		While sitting and watching a surpringly tense game, you suddenly feel a hand on your arm.  There's a man, gripping you tightly.  He nods to one of the booths.
		*goto meet_nicky

*label pool_resolve
*temp test
*rand test 1 10

Your oppenent racks the balls, and you end up having to break.

*if male = false
	Several of the numbers sidle to the head of the table, the better to watch you prepare for the break.
	*goto pool_resolve_2
*else
	*goto pool_resolve_2
	
*label pool_resolve_2
*if Agility > 4
	You have to restrain yourself from winning too quickly.  Your supernatural dexterity makes this game into a joke.
	*set pool_trounce true
	*if presented_chicago
		You collect your winnings.
		*set wealth +(bet*2)
		*goto inside_majestic_presented_1
	*else
		The onlookers stand agape.  Before anyone can start shouting 'cheater', you feel a hand on your arm.  You turn and see a youngish Italian man, pulling you to a booth.  He doesn't even allow you time to collect your winings.
		*goto meet_nicky
*if Agility = 4
	*set pool_trounce true
	The contest is easy enough.  Your opponent is talented, but is no match for the control you have over your body.  The onlookers stand agape.
	*if presented_chicago
		You collect your winnings.
		*set wealth +(bet*2)
		*goto inside_majestic_presented_1
	*else
		Before anyone can start shouting 'cheater', you feel a hand on your arm.  You turn and see a youngish Italian man, pulling you to a booth.  He doesn't even allow you time to collect your winings.
		*goto meet_nicky
*if Agility = 3
	*if test < 6
		The game is challenging, but you manage to eke out a victory. The crowd that has gather clearly respects your hard-won victory.  With a certain satisfaction, you pick up your winnings, and shake a few hands that are extended to you.
		*set wealth +(bet*2)
		*if presented_chicago
			*goto inside_majestic_presented_1
		*else
			A few moments later, though, an Italian man catches your eye.  He's sitting at a booth, and gestures for you to join him.
			*goto meet_nicky
	*if test >= 6
		The game is challenging, and the hustler managers a lucky shot at the end, resulting in his victory.  The patrons have to give you a certain amount of respect for doing as well as you did, however.  A few hands are extended in congratulations.
		*if presented_chicago
			*goto inside_majestic_presented_1
		*else
			A few moments later, though, an Italian man catches your eye.  He's sitting at a booth, and gestures for you to join him.
			*goto meet_nicky
*if Agility < 3
	You are no match for this guy.
	*if male
		The onlookers begin making fun of this dewdropper that's wandered onto their turf.
		*if presented_chicago
			*goto inside_majestic_presented_1
		*else
			Before being tossed out on your keister, however, an Italian man gestures for you to take a seat at a booth with him.  The rest of the patrons instantly clam up and turn back to their business.
			*goto meet_nicky
	*else
		Even if you have lost the game, you certainly caught their attention.  You are instantly surrounded by bad breath and broken teeth as the patrons are curious to see what else you have to offer.
		*if presented_chicago
			You are feeling decidely ill at ease here.
			*goto inside_majestic_presented_1
		*else
			For better or worse, a strong hand lays itself on your upper arm and drags you towards a booth.
			*goto meet_nicky
	
*label meet_nicky
*set met_nicky true
*if perception > 0
	This man does not have a pulse.  You can only assume that he is one of your kind.
	*goto meet_nicky_2
*else
	*goto meet_nicky_2
		
*label meet_nicky_2
*if speaks_english
	"Who are you?" the man asks imperiously.
	
	"My name is ${given_name} ${surname}.  And you?"
	
	"They call me Nicky Chomps.  And this is my joint, see?  You shouldn't be in here without my say-so."
	
	"I meant no disrespect.  I'm here looking for a new home."
	
	"A new home, eh?  Well, you should see the boss, then."  It seems like, if you want to not go see "the boss", you're going to need to make a break for it.  That said, it probably means you'll never be able to show your mug around here again.
	*choice
		#I follow Nicky Chomps to see "the boss".
			*goto meet_seamus_english
		#I try to make a run for it.
			*goto escape_from_nicky
	
*if speaks_english = false
	He asks you something, probably your name.  He quickly recognizes your lack of facility with English, sighs, and spits out a string of what can only be curses.
	
	He gestures to someone, and then grabs your arm and escorts you outside to a waiting car.  He's clearly taking you somewhere, but where?  If you're going to try to make a break for it, now's the time.  That said, you probably won't be able to show your mug around here again if you do.
	*choice
		#I get in the car.
			*goto meet_seamus_no_english
		#I try to make a break for it.
			*goto escape_from_nicky
			
*label escape_from_nicky

How do you want to do this?

*choice
	*selectable_if (agility > 3) #I invoke my supernatural speed and dash around a corner and down the alley.  Others of my kind will look very poorly on this, but at least I should be able to get away.
		Yes, you do manage to escape.  But only barely.
		*set exposure +1
		*set fled_from_nicky true
		*goto lincoln_park_2
	*selectable_if (stealth > 4) #I simply make this gee forget he's even holding me, and then walk away while his mind clears.
		His hand slips from your upper arm, and he begins chatting up a pro skirt standing on the corner outside the poolhall.  You saunter down the street, and only once you've turned the block do you hear him begin to shout.
		*set fled_from_nicky true
		*goto lincoln_park_2
	#I try to knock his block off.
		*if combat <= 8
			You screw back your fist to knock him a good one, but he catches the blow with ease and twists you arm behind your back, neatly forcing you into the car.
			
			Once inside, he holds a gun to your head until you settle down.  A driver starts up the car, and you rumble forward into the night.
			*if speaks_english = false
				*goto meet_seamus_no_english
			*else
				*goto meet_seamus_english
		*else
			You knock him a good one across the jaw, and he falls to the ground beside his car.  Without pause, you turn and run.
			*set fled_from_nicky true
			*goto lincoln_park_2

*label meet_seamus_no_english

The car jostles up and down as it heads uptown.  It pulls up outside a large, ornate hotel called 'the Drake'.  You are hustled out of the car and into the buildling, and turned over to a large black man in a suit who does not attempt to speak to you.

Within a few minutes, you are unceremoniously cast into a parlor thick with smoke.  There are two individuals in here.  One is a short Irishman, clearly the source of the smoke as he holds a fat cigar in his hand.

*if speaks_latin
	The other individual--a translator, presumably--is quickly pushed out of the room once you address the Irishman in Latin.  He seems pleased that you are so...civilized.
	
	After you introduce yourself, proper conversation can begin. 
	*goto meet_seamus_1
*elseif speaks_german
	The other is a youngish German laborer.  His English must not be the best, but it is at least passable, and he is able to translate for you.
	
	After you introduce yourself, proper conversation can begin. 
	*goto meet_seamus_1
*elseif speaks_french
	The other is a young woman... she must be a local debutante.  Her French is questionable, and you are forced to simplify your answers, but she does well enough in translating for you.
	
	After you introduce yourself, proper conversation can begin. 
	*goto meet_seamus_1
*elseif speaks_spanish
	The other is an older Italian man.  His Castilian is questionable, but apparently he did some business in Spain before immigrating to Chicago.  He seems to do a passable job of making you understood.
	
	After you introduce yourself, proper conversation can begin. 
	*goto meet_seamus_1
*else
	*goto meet_seamus_1

*label meet_seamus_english

The car jostles up and down as it heads uptown.  It pulls up outside a large, ornate hotel called 'the Drake'.  You are hustled out of the car and into the buildling, and turned over to a large black man in a suit who does not speak to you.

You are led into a smoke-filled room, dominated by a short Irishman and his cigars.  When he opens his mouth to speak, you are surprised by his accent: though he looks the part, his English is formal and...almost archaic... even to your ears.
*goto meet_seamus_1

*label meet_seamus_1
But before the conversation begins in earnest, the Irishman turns to a phonograph that was playing when you entered, and turns it off.  The sudden silence after the orderly beat of the music makes your impending conversation seem all the more weighty.
*if (intelligence > 2) and (creation > 0)
	You recognize the music as being Vivaldi's 'The Four Seasons.'
	*goto meet_seamus_2
*else
	*goto meet_seamus_2

*label meet_seamus_2
*temp others_question
*set others_question true
*temp music_question
*set music_question true
*if intelligence > 2
	*set music_question false

"Thou mayest feel free to speak freely here; no one shall betray the secrets of this room, ${mr} ${surname}.  I am Seamus O'Donnell, Quaestor of this city.  I may only assume that thine actions this evening were thine attempt to discover me?"  

"Yes, yes of course," you reply.

"Thus, I conclude that thou art in search of my leave to remain here for some time?"

"Yes, sir."

"I trust, then, that thou art capable of maintaining the Veil which protects us?"

*if lore > 1
	"Yes, of course sir."  The Veil is an older term for the Rule of Reserve, which says that you must remain hidden from mortals.
	*if exposure > 3
		*goto meet_seamus_7
	*else
		*goto meet_seamus_3
*elseif intelligence > 2
	After a moment of stammering, "yes, yes of course."  He must be speaking of the Rule of Reserve that your maker instilled in you, that you must remain hidden from mortals.
	*if exposure > 3
		*goto meet_seamus_7
	*else
		*goto meet_seamus_3
*else
	"The Veil?"
	
	"Thy Dominus clearly failed in his attempts at educating thee.  Allow me to clarify: the mortals shall not know of thine existence, else thou shalt exist no more."
	
	"I understand."
	
	"See to it that thou dost."
	*if exposure > 3
		*goto meet_seamus_7
	*else
		*goto meet_seamus_3

*label meet_seamus_7
*temp train_charm
*set train_charm false
*temp train_stealth
*set train_stealth false

"However, it seems as though thou art already failing in this regard.  How long hast thou been here, and already drawn such attention to thyself?  Dost thou have any defense in this matter?"

*choice
	*if charm < 3
		#"Good sir, I, alas, lack the necessary powers of charm that others of our kind possess."
			*set train_charm true
			*goto meet_seamus_3
	*if stealth < 3
		#"Good sir, I, alas, lack the necessary powers of stealth that others of our kind possess."
			*set train_stealth true
			*goto meet_seamus_3
	#"I have no excuse for my conduct, good sir."
		"I suppose I ought to commend thee for thy honesty.  So allow me to repay in kind: I doubt thou will rest here long."
		*goto meet_seamus_3

*label meet_seamus_3

"If thou hast need of me again, do not come here directly.  Rather, thou shouldst seek out one of mine house.  Thou canst oft find Mr. Niccolo Ciampa at the Majestic and Ms. Violet Jones at the Royal Garden Cafe.  Mr. Herbert Walker, who escorted thee hither, alternately spends time here at the Drake, and on the South Side of the city.  Mr. Clyde Thrasher... maintains his own schedule."

*if perception > 2
	Though it is well-hidden, you clearly sense O'Donnell's exasperation with Thrasher when his name is mentioned.
	*goto meet_seamus_3b
*else
	*goto meet_seamus_3b

*label meet_seamus_3b
*if fled_from_nicky
	*goto meet_seamus_6
*else
	*goto meet_seamus_4

*label meet_seamus_6
"Of course, thou hast already made the acquaintance of Mr. Ciampa.  I am impressed that thou were able to evade his grasp.  I trust that thou shalt not be so foolish as to attempt something like that again."

You make a quick apology for your ignorance.

*goto meet_seamus_4

*label meet_seamus_4

*if train_charm
	"Speaking of Ms. Jones, thou shouldst speak with her regarding thy personal failings.  She is most gifted in that regard.
	*goto meet_seamus_8
*if train_stealth
	"Speaking of Mr. Walker, thou shouldst speak with him regarding thy shortcomings.  He is most gifted in that regard.
	*goto meet_seamus_8
*else
	*goto meet_seamus_8

*label meet_seamus_8
*set presented_chicago true

"Dost thou have any other questions for me?"

*choice
	*if Lore > 2
		#"Might I inquire as to the identity of the Senator of this city?"
			"Horace Powell is the Senator of Chicago."
			*goto meet_seamus_8
	*if drake_room
		#"I was hoping I might be reimbursed for the room I let here..."
			"Consider it the price of ignorance."		
			*goto meet_seamus_8
	*if others_question
		#"Are there others of our kind here?"
			"There art several of our kind in Chicago. I have not the time to acquaint thee with them."
			*set others_question false
			*goto meet_seamus_8
	*if music_question
		#"Might I inquire as to what that was that you were listening to?"
			O'Donnell does his best not to roll his eyes at you.  "Vivaldi's _Four Seasons_.  Thou shouldst broaden thy musical horizons, young one."
			*set music_question false
			*goto meet_seamus_8
	*if powers_and_dandrea
		#"What is this I hear about Powers and D'Andrea?"
			"Powers is Alderman of the 19th Ward.  His grip on that district is fading with the arrival of more of my kinsmen.  Unfortunately, the two of them have taken to arranging for explosive devices to be lain in inconvenient places in their mutual attempts to dissuade the other from continuing in a life of public service."
			*set powers_and_dandrea false
			*goto meet_seamus_8
	*if intelligence > 2
		*if creation > 0
			#"A lover of Vivaldi?"
				"That I am, ${mr} ${surname}.  I do prefer Vivaldi and Bach to that wretched new music of Beethoven and Mozart."  Wretched new music?  Mozart died in 1791 and Beethoven in 1827.  You are amazed that this individual can work a phonograph at all.
				*goto meet_seamus_8
	*if shepherds_and_wolves
		*if lore > 2
			#"I've been trying to find a copy of the Shepherds and Wolves..."
				"I pray that thou find one, ${mr} ${surname}.  It has been many decades since I have had the privilege of resting mine eyes upon such a document."
				
				"So you have seen one?"

				"I have.  I believe it was in the possession of a young vampire by the name of Andrew Calkins."

				"When was this?"

				"Some years before the South sought its independence."
				*set shepherds_and_wolves false
				*goto meet_seamus_8
	#"No, that's all."
		You are escorted into the lobby of the Drake Hotel.
		*set shepherds_and_wolves true
		*if status < 3
			*set drake_room false
		*goto drake_hotel_lobby

*label uptown

Chicago's wealthy Uptown neighborhood hosts a variety of ostenatious hotels, as well as large homes, upscale shops and exclusive businesses.

*if (anachronism <= 40) and (shopping_spree = false)
	The women don't bother hiding their tittering when they observe your dress; apparently, it's a little out of date.
	*goto uptown_2
*if ethnicity = "choctaw"
	Men and women stare at you suspiciously as they pass.
	*goto uptown_2
*else
	*goto uptown_2

*label uptown_2

Looking up and down the streets of Uptown, you have to decide what to do.

Current Blood: ${blood}
*line_break
*set wealth1920 wealth/12
Current Wealth: ${wealth1920}

*choice
	*if (shopping_spree = false) and ((ethnicity != "african") and (ethnicity != "choctaw"))
		*selectable_if (wealth > 2500) #I want to go on a shopping spree.
			It is time to update your warddrobe.
			*page_break
			Your new glad rags are something to behold.
			*set wealth -2500
			*set shopping_spree true
			*set anachronism %+20
			*goto uptown_2
	#The Blackstone Hotel.  The favorite of politicians and businessmen.
		*goto blackstone_hotel
	#The Drake Hotel.  Opened just last year, it is the spot for the rich and famous.
		*goto drake_hotel
	#The Hotel Sherman.  An upscale residence hotel.
		Probably the best bang for your buck.
		*goto sherman_hotel
	#A Temperance Union.  If the people here are really all up in arms about alcohol, maybe they find their mates another way?
		*goto temperance_union
	#I need to hunt.
		*set current_location "uptown_2"
		*goto hunt
	*if evanston and (chicago_haven_neighborhood != "empty")
		*selectable_if (wealth > 500) #Hire a car to take you out to Evanston; maybe you can find this Willie Chapel guy.
			*set current_location chicago_haven_neighborhood
			*set wealth -500
			*goto evanston
	#I want to go to a different neighborhood.
		Not much of one for the hoity-toity folk, eh?
		*choice
			#Canaryville, an old Irish neighborhood.
				*goto canaryville
			#Lincoln Park, home to mostly second-generation German immigrants.
				*goto lincoln_park
			#The 19th Ward, home to a surging population of southern Italians.
				*goto little_italy
			#the South Side, Chicago's soon-to-be-famous black neighborhood.
				*goto south_side
	*if chicago_haven_neighborhood != "empty"
		#I want to go to sleep at my haven until tomorrow.
			*set progression_in_time +1
			*set current_location chicago_haven_neighborhood
			*goto night_check

*label temperance_union
The Woman's Christian Temperance Union was founded in Evanston (a suburb of Chicago) in 1873.  The organization worked stridently on improving labor conditions, prison conditions, civic sanitation, and gaining women's suffrage.  They also worked to 'reform' the morals of prostitutes, and were instrumental in lobbying for Prohibition.
*if male
	That said, the Woman's Christian Temperance Union does not admit men.  They strive for moral perfection, and as the Union hall is filled with young, impressionable women, they wouldn't want you to come and lead any of them astray.
	*goto uptown_2
*else
	*if speaks_english
		*if (ethnicity != "african") and ((ethnicity != "choctaw") and ((ethnicity != "spanish") and (ethnicity != "irish")))
			The women of the Union welcome you with open arms.  They are always looking for another woman who wants to improve the lot of her fellow humans.
			*goto temperance_union_2
		*if ethnicity = "spanish"
			That said, women who are Catholic, Jewish, foreign-born, black or Native American are not admitted to the Woman's Christian Temperance Union.  Your Spanish features tell them--whether true or no--that you are a Catholic, and thus you are unwelcome.
			*goto uptown_2
		*if ethnicity = "irish"
			That said, women who are Catholic, Jewish, foreign-born, black or Native American are not admitted to the Woman's Christian Temperance Union.  Your Irish features tell them--whether true or no--that you are a Catholic, and thus you are unwelcome.
			*goto uptown_2
		*else
			That said, women who are Catholic, Jewish, foreign-born, black or Native American are not admitted to the Woman's Christian Temperance Union.  The color of your skin marks you as unwelcome.
			*goto uptown_2
	*else
		That said, women who are Catholic, Jewish, foreign-born, black or Native American are not admitted to the Woman's Christian Temperance Union.  You inability to speak English marks you as foreign-born, and you are turned away.
		*goto uptown_2

*label temperance_union_2
*choice
	*if chicago_haven_neighborhood = "empty"
		#I explain that I am new to town, and that I am in need of temporary lodging.
			A kindly old woman informs you that you are welcome to stay with her.  The woman's house is immense and mostly uninhabitated, perfect for your needs... as long as you don't bring any suitors or alcohol home with you anyway.
			*set chicago_haven_neighborhood "uptown_2"
			*goto uptown_2
	*if charm > 1
		#I need to hunt.
			There are women here who are so desirous of making friends with a new member that it would be almost criminal to disappoint them.
			*set blood +3
			*set current_location "uptown_2"
			*goto blood_check
	#Leave.
		*goto uptown_2

*label blackstone_hotel

For $75, you can set yourself up here for a whole month.

*if (stealth < 4) and ((ethnicity = "african") or (ethnicity = "choctaw"))
	*goto hotel_discrimination
*else
	*goto blackstone_hotel_2

*label hotel_discrimination
That said, you can't even step foot inside the hotel.  The moment you put your feet on the front steps, a phalanx of bellhops appear to dissuade you from pursuing such a course.  You eye their assumptions with a growing since of fury.

You could tear into them if you wish, but there would be witnesses...
*choice
	#They must be punished for their insolence!
		*set exposure +5
		You bare your fangs and leap at the nearest bellhop, who screams in terror.  The others scatter before you.  By the time you regain your senses, you can hear the approaching sound of the police.  Thinking better of your situation, you flee the area.
		*goto lincoln_park
	#Unfortunately, violence will solve nothing.
		*set discretion %-5
		*set exposure +1
		Discouraged by their ignorance, you withdraw from the steps of the hotel.  If they only knew how close they came to death tonight...
		*page_break
		*goto uptown_2


*label blackstone_hotel_2

*choice
	*if wealth > 900
		#I rent a room.
			*set chicago_haven_neighborhood "uptown_2"
			*set wealth -600
			After giving specific instructions about how you are not to be bothered during the day under any circumstances, you head upstairs and put your things away.
			
			Do you want to rest, or go back out tonight?
			*choice
				#Rest until tomorrow.
					You wake up the next evening.  It is time to explore your new home.
					*set blood -1
					*set progression_in_time +1
					*set current_location "uptown_2"
					*goto night_check
				#Head back out into the city.
					You head downstairs and out to the street.
					*goto uptown_2
	*if charm > 2
		#I'm sure there's a handsome dewdropper around here somewhere, ready to show me a good time in his room.
			My, my... what a tasty young man.
			*set blood +4
			*set current_location "uptown_2"
			*goto blood_check
	#I'll seek accomodations elsewhere.
		*goto uptown_2
		
*label drake_hotel

The Drake is a magnificent building, completed just last year.  As you mount the steps, you catch the glimpse of several fashionable young ladies filing into a car waiting for them on the curb.

*if (stealth < 4) and ((presented_chicago = false) and ((ethnicity = "african") or (ethnicity = "choctaw")))
	*goto hotel_discrimination
*else
	*goto drake_hotel_2

*label drake_hotel_2
*choice
	#I head inside.
		The doors open wide before you, held by bellhops who greet you as you step inside.
		*goto drake_hotel_lobby
	#I go elsewhere.
		*goto uptown_2
		
*label drake_hotel_lobby

The lobby is magnificient, tiled with marble and adorned with velvet and chandeliers.
*if presented_chicago = false
	For $100, you could set yourself up here for a whole month.

*choice
	*if presented_chicago
		#I'm sure I could leave word with someone here that I need to see Mr. O'Donnell.
			Except for the fact that he told you to seek his associates elsewhere, and not to attempt to contact him directly.  Especially not here at the hotel.  You head outside.
			*goto uptown_2
	*if presented_chicago = false
		*if wealth > 1200
			#I want to take a room here.
				*set chicago_haven_neighborhood "uptown_2"
				*set wealth -1200
				After giving specific instructions about how you are not to be bothered during the day under any circumstances, you head upstairs and put your things away.  Your travels having exhausted you, you lay down for the day to rest.
				
				You wake up the next evening.  It is time to explore your new home.
				*set progression_in_time +1
				*set blood -1
				*set drake_room true
				*goto leaving_drake
	*if train_stealth
		*if speaks_english
			*if blood > 4
				#I want to see Mr. Walker about that training.
					Herbert is not the best teacher in the world, but over the course of a few days, he is able to help you learn to better deflect the attention of others from yourself.
					*set train_stealth false
					*set stealth +1
					*set blood -3
					*gotoref chicago_haven_neighborhood
	*if charm > 2
		*if presented_chicago = false
			*if speaks_english
				#Maybe I can find someone tasty around here...
					A bellhop indicates that you should meet him across the street... he can't spend any time with you in the hotel.  He leaves, and you wait a few minutes before following.
					*goto leaving_drake
	#I leave.
		*goto uptown_2
		
*label leaving_drake
*if speaks_english
	As you are exiting the hotel, you almost literally bump into a large black man, whose hand suddenly grips you forcefully and pulls you out of the doorway.
	
	"You need to come with me, ${Mr} ${surname}."
	
	"How dare you lay your hand on me!" you exclaim.  Surprisingly, it seems everyone is looking away from this scene.  Normally, a lynch mob would have been called up by now.
	
	"The Quaestor commands your presence," he whispers through his teeth.  You try not to show your fear, as he drags you sullenly back into the hotel.
	
	After a brief wait in a small room, you are escorted into a parlor where a short Irishman sits chomping on a cigar.
	*goto meet_seamus_5
*else
	As you are exiting the hotel, you almost literally bump into a large black man, whose hand suddenly grips you forcefully and pulls you out of the doorway.  He says something that you don't understand.  You begin to loudly chastise this black man in your own language for daring to grab you, but soon notice that no one is paying attention to either of you.
	
	It is then that you notice that the black man too has no pulse.  Before you can recover from your surprise, he drags you back into the hotel.
	
	You are put into a room to wait, briefly, before being summoned into a parlor with two individuals.  The first is a short Irishman, aggressively chomping a cigar.
	
	*if speaks_latin
		The other individual--a translator, presumably--is quickly pushed out of the room once you address the Irishman in Latin.  He seems pleased that you are so...civilized.
		*goto meet_seamus_5
	*if speaks_german
		The other is a youngish German laborer.  His English must not be the best, but it is at least passable, and he is able to translate for you.
		*goto meet_seamus_5
	*if speaks_french
		The other is a young woman... she must be a local debutante.  Her French is questionable, and you are forced to simplify your answers, but she does well enough in translating for you.
		*goto meet_seamus_5
	*if speaks_spanish
		The other is an older Italian man.  His Castilian is questionable, but apparently he did some business in Valencia before immigrating to Chicago.  He seems to do a passable job of making you understood.
		*goto meet_seamus_5
	*else
		goto meet_seamus_5

*label meet_seamus_5
Before the conversation begins in earnest, the Irishman turns to a phonograph was playing when you entered, and turns it off.  The sudden silence after the orderly beat of the music makes your impending conversation seem all the more weighty.
*if intelligence > 2
	You recognize the turn as Vivaldi's 'The Four Seasons.'
	*goto meet_seamus_5a
*else
	*goto meet_seamus_5a

*label meet_seamus_5a

*if Status < 3
	"I regret to inform thee, ${mr} ${surname}, that thou canst not reside here.  Thine effects have already been packaged, and await thee at the door to the hotel.
	
	"Upon this occasion, I shalt overlook thine indiscretions.  See to it that thou dost not err in this way twice.
	
	"That now behind us, allow me to welcome you, on behalf of the Society, to Chicago.
	*set chicago_haven_neighborhood "empty"
	*goto meet_seamus_2
*if Status >= 3
	"I would not normally permit a newcomer to reside here at the Drake.  However, thy stature among our kind demands that I extend such hospitality.
	
	"I trust, however, that thy residence here wilt be short-lived.  That concluded, allow me to welcome you, on behalf of the Society, to Chicago.
	*set drake_room false
	*goto meet_seamus_2

*label sherman_hotel

For $50, you can set yourself up for a month in some sweet digs here.

*if (stealth < 4) and ((ethnicity = "african") or (ethnicity = "choctaw"))
	*goto hotel_discrimination
*else
	*goto sherman_hotel_2

*label sherman_hotel_2
*if (stealth > 3) and ((ethnicity = "african") or (ethnicity = "choctaw"))
	Using your supernatural Stealth, you project the image of a Yankee into the minds of the people at the hotel, allowing you to make your way inside unmolested.
	*goto sherman_hotel_3
*else
	*goto sherman_hotel_3

*label sherman_hotel_3
*choice
	*if wealth > 600
		#I rent a room.
			*set chicago_haven_neighborhood "uptown_2"
			*set wealth -600
			After giving specific instructions about how you are not to be bothered during the day under any circumstances, you head upstairs and put your things away.
			
			Do you want to rest, or go back out tonight?
			*choice
				#Rest until tomorrow.
					You wake up the next evening.  It is time to explore your new home.
					*set blood -1
					*set progression_in_time +1
					*set current_location "uptown_2"
					*goto night_check
				#Head back out into the city.
					You head downstairs and out to the street.
					*goto uptown_2
	*if charm > 2
		#I'm sure there's a darling flapper, ready to show me a good time in her room.
			My, my... what a tasty young lady.
			*set blood +4
			*goto uptown_2
	#I'll have to find cheaper accomodations elsewhere.
		*goto uptown_2

*label lincoln_park_2

You hurry through the streets and alleys, trying to put as much distance between you and Nicky as possible.  Once you've travelled a fair distance, you start to pay more attention to words instead of people.  It seems that you've made your way into the Lincoln Park neighborhood.
*goto lincoln_park

*label lincoln_park

*if ethnicity = "german"
	You feel strangely at-home here, as people who look like you take note of your presence and then return to their lives.
	*goto lincoln_park_3
*else
	It is clear from the stares that you receive that you are not welcome in this neighborhood.  Sometimes, there are even glares of outright hostility directed your way from the German immigrants on the street.
	
	During the Great War, the German immigrants were treated with great distrust by the rest of the country, fearing spies and infiltrators.  That distrust provoked a reciprocal hostility amongst the Germans that will still take several more years to fade.
	
	You should probably head to another part of town.
	*goto lincoln_park_3

*label lincoln_park_3
*if protest_in_lincoln_park
	
	Before you can do much at all, however, you are interrupted by the sound of chanting.  Before you quite realize what's going on, you find yourself nearly submerged under a tide of people marching on behalf of the Socialist Party, and their imprisoned leader--and presidential candidate--Eugene Debs.
	
	You are carried along with the sea of people for several blocks--you have your eye on a handsome lad who would probably bend quickly to your attentions--when cries of pain and the scream of police whistles erupt from up ahead.  Within moments, the parade devolves into a melee as the marching workers and the police fall into a brawl.
	
	Abandoning the handsome lad, you wisely choose to continue east, leaving Lincoln Park behind.
	*set protest_in_lincoln_park false
	*goto uptown
*else
	*goto lincoln_park_4

*label lincoln_park_4

Current Blood: ${blood}
*line_break
*set wealth1920 wealth/12
Current Wealth: ${wealth1920}

*choice
	#Hunt on the streets.
		*set current_location "lincoln_park_4"
		*goto hunt
	#I want to go to a different neighborhood.
		Where do you want to go?
		*choice
			#Canaryville, an old Irish neighborhood.
				*goto canaryville
			#Little Italy.
				*goto little_italy
			#the South Side, Chicago's soon-to-be-famous black neighborhood.
				*goto south_side
			#Uptown.
				*goto uptown
	*if ethnicity = "german"
		*if chicago_haven_neighborhood = "empty"
			#Seek a room to rent.
				You find a sign for an empty room above a hat-shop.  For $5 a month, the place is yours.
				*choice
					#I'll take it.
						You put you things down in your new room, and ask the landlord if he can see about some heavy curtains for the windows.
						*set wealth -100
						*set chicago_haven_neighborhood "lincoln_park"
						*goto lincoln_park
					#I'll find some place else.
						*goto lincoln_park
	*if rainer
		*if knows_about_chicago_union_hall = false
			#Try to locate Mr. Teufel.
				*goto rainer
	*if knows_about_chicago_union_hall
		#Drop by the Union Hall.
			*if met_rainer
				Rainer greets you warmly upon your return to the Hall.
				*goto chat_with_rainer
			*else
				*set met_rainer true
				*goto intro_to_rainer
	*if chicago_haven_neighborhood != "empty"
		#I want to go to sleep at my haven until tomorrow.
			*set progression_in_time +1
			*set current_location chicago_haven_neighborhood
			*goto night_check

*label rainer
*set met_rainer true

*if (streetwise = 0) and ((perception < 3) and ((charm < 3) and ((stealth < 4) and (ethnicity != "german"))))
	Being neither of German extraction, nor sufficiently charming, you find the locals generally hostile to your questions.  In sum, your efforts to discover Mr. Teufel come to taught.
	*set rainer false
	*goto lincoln_park_4
*else
	*set knows_about_chicago_union_hall true
	*goto intro_to_rainer

*label intro_to_rainer
You find Teufel in a union hall, listening to a series of speeches about the necessity of the proletarians' organization and the oppression of the bourgeoisie.  You are initially hard-pressed to identify him, as he does an excellent job of blending in with the crowd.  But word of a stranger quickly ripples through the crowd, and by the time he shakes your hand, he clearly is aware that you are one of his kind.

After some basic introductions, you find yourself free to ask him some questions.
*goto chat_with_rainer

*label chat_with_rainer

*choice
	#"What do you think of the Quaestor?"
		*goto chat_with_rainer
	#"Why do you spend your time involved with these mortal politics?"
		*goto chat_with_rainer
	*if shepherds_and_wolves
		#"Am I to assume that you consider yourself something of a shepherd?"
			*set shepherds_and_wolves false
			*goto chat_with_rainer
	#"Do you think us damned?"
		"Damned?  How do you mean damned?  You speak as a schoolboy of things of which he knows not.  We are neither damned nor sanctified... we are.  And being as we are, we must determine how we shall be.  Some of our kind comfort themselves with tales of damnation... that they are cursed by God above.  But those are fools who cannot accept their new condition."
		*goto chat_with_rainer
	#"Thank you for your time."
		*set shepherds_and_wolves true
		*goto lincoln_park_4

*label canaryville

Canaryville is a solidly Irish neighborhood, a little east of the South Side.
*if ethnicity = "irish"
	You feel strangely at-home here, as people who look like you take note of your presence, offer a bit of a half-smile, and then return to their lives.
	*goto canaryville_2
*else
	The residents of this neighborhood seem mostly indifferent to you.  They go about their evening business without seeming to pay you any mind.		
	*goto canaryville_2

*label canaryville_2
*if canaryville_commotion
	As you are wandering through the neighborhood, you notice a crowd gathered at the mouth of a sidestreet.  There are women crying.
	*goto canaryville_3
*else
	*goto canaryville_3

*label canaryville_3
	
Current Blood: ${blood}
*line_break
*set wealth1920 wealth/12
Current Wealth: ${wealth1920}

*choice
	#Hunt on the streets.
		*set canaryville_commotion false
		*set current_location "canaryville"
		*goto hunt
	*if chicago_haven_neighborhood = "empty"
		*if ethnicity != "african"
			*if ethnicity != "choctaw"
				#Seek a room to rent.
					You find a sign for an empty room above a butcher.  For $5 a month, the place is yours.
					*choice
						#I'll take it.
							You put you things down in your new room, and ask the landlord if he can see about some heavey curtains for the windows.
							*set wealth -100
							*set chicago_haven_neighborhood "canaryville"
							*goto canaryville
						#I'll find some place else.
							*goto canaryville
	*if evanston and (chicago_haven_neighborhood != "empty")
		*selectable_if (wealth > 500) #Hire a car to take you out to Evanston; maybe you can find this Willie Chapel guy.
			*set current_location chicago_haven_neighborhood
			*set wealth -500
			*goto evanston
	*if canaryville_commotion
		#Investigate the commotion.
			*set canaryville_commotion false
			*goto canaryville_commotion
	#Head to another neighborhood.
		*set canaryville_commotion false
		Where do you want to go?
		*choice
			#Lincoln Park, home to mostly second-generation German immigrants.
				*goto lincoln_park
			#the 19th Ward, home to a new population of southern Italians.
				*goto little_italy
			#the South Side, Chicago's soon-to-be-famous black neighborhood.
				*goto south_side
			#Uptown, where the wealthy folk live.
				*goto uptown
	*if chicago_haven_neighborhood != "empty"
		#I want to go to sleep at my haven until tomorrow.
			*set progression_in_time +1
			*set canaryville_commotion false
			*set current_location chicago_haven_neighborhood
			*goto night_check

*label canaryville_commotion

You shoulder your way to the middle of the crowd.  Several locals are in the midst of trying to cut some poor fella down; he's suspended upside-down from a fire-escape.  Words and symbols have been cut into his flesh, and his back is one large welt from a whip's lashes.

*if speaks_latin
	*if literate
		The words are clearly some miserable attempt at prayers.  Whoever 'wrote' them clearly was a great disappointment to his Latin tutor.
		*goto canaryville_commotion_2
*if (speaks_latin = false) and (literate and (ethnicity != "choctaw"))
	You recognize the words as being Latin, but you can't read them.
	*goto canaryville_commotion_2
*else
	Unfortunately, you can't make any sense of the words.
	*goto canaryville_commotion_2
	
*label canaryville_commotion_2
*if lore > 2
	The symbols look to be a confused mix of Hermetic, Catholic, Kabbalist and Masonic imagery.  Whoever inscribed them is a being of power beyond your conception, or else a raving lunatic.
	*goto canaryville_commotion_3
*else
	And the symbols mean nothing to you.
	*goto canaryville_commotion_3

*label canaryville_commotion_3
*if speaks_english
	The old women are whispering about the devil being on the loose in the neighborhood.  Apparently, this is not the first time something like this has happened.
	*goto canaryville_commotion_4
*else
	The old women are whispering furiously, but you can't understand what they're saying.
	*goto canaryville_commotion_4

*label canaryville_commotion_4
There are too many people around for you to really get any closer to the body.  You decide to get back to the main drag.
*goto canaryville_2

*label south_side

State Street, also known as 'the Stroll', extends in both directions.  Couples, black and white, stride up and down the street on this balmly summer evening.  The Royal Gardens Cafe, at 39th and State, is the hotspot for that new 'race' music, jazz and the blues.  Unfortunately, its popularity has been something of its undoing... when Prohibition came into effect a year and a half ago, the Royal Gardens had to stop serving liquor.  Already the best musical acts are seeking other, hidden venues where the patrons can still drink while listening to the beat.
*if (anachronism <= 40) and (shopping_spree = false)
	People try not to snicker as you walk by in your severely out-of-style clothing.
	*goto south_side_2
*if ethnicity = "choctaw"

	Some passers-by stare at you.  Indians are becoming a curiosity in the big city.
	*goto south_side_2
*else
	*goto south_side_2

*label south_side_2

Where to on the South Side?

Current Blood: ${blood}
*line_break
*set wealth1920 wealth/12
Current Wealth: ${wealth1920}

*choice
	#Hunt on the streets.
		*set current_location "south_side_2"
		*goto hunt
	#The Royal Gardens Cafe.
		Why not start at the beginning?
		*goto royal_gardens
	*if chicago_haven_neighborhood = "empty"
		#Seek a room to rent.
			You find a sign for an empty room above a barber.  For $5 a month, the place is yours.
			*choice
				#I'll take it.
					You put you things down in your new room, and ask the landlord if he can see about some heavy curtains for the windows.
					*set wealth -100
					*set chicago_haven_neighborhood "south_side_2"
					*goto south_side_2
				#I'll find some place else.
					*goto south_side_2
	*if knows_cats_meow = false
		#I want to try to locate a speakeasy.
			*if perception > 2
				That's not a problem.  All you have to do is reach out your mind and you quickly light upon a fellow in need of a drink... and who knows where to get one.
				*goto cats_meow
			*elseif streetwise > 0
				That's not a problem... you know the signs for how to go about finding such a thing.
				*goto cats_meow
			*elseif (ethnicity = "african") and speaks_english
				You just ask one of the residents of this neighborhood where a poor spade can wet his whistle.
				*page_break
				The Cat's Meow is just down that alley over there.
				*goto cats_meow
			*elseif (stealth > 4) and (speaks_english)
				You project the image of yourself as a black into the minds of the people around you, and soon you find a 'countryman' willing to let you know where a poor spade can wet his whistle.
				*page_break
				The Cat's Meow is just down that alley over there.
				*goto cats_meow
			*elseif (charm > 2) and speaks_english
				With a few well-chosen words, you coax a right gee into pointing the way to the Cat's Meow.
				*goto cats_meow
			*elseif (stealth > 0) and ((perception > 0) and speaks_english)
				If you stand somewhere inconspicuous long enough, listening in on conversations, you're bound to hear about something, right?
				*page_break
				It turns out that the Cat's Meow is just down that alley over there.
				*goto cats_meow
			*else
				It seems you lack the skills to locate a place that doesn't want to be found.  This whole Prohibition thing could make hunting difficult.
				*goto south_side_2
	*if knows_cats_meow
		#I head over to the Cat's Meow!
			*goto cats_meow
	*if evanston and (chicago_haven_neighborhood != "empty")
		*selectable_if (wealth > 500) #Hire a car to take you out to Evanston; maybe you can find this Willie Chapel guy.
			*set current_location chicago_haven_neighborhood
			*set wealth -500
			*goto evanston
	*if chicago_haven_neighborhood != "empty"
		#I want to go to sleep at my haven until tomorrow night.
			*set progression_in_time +1
			You feel well rested.
			*set current_location chicago_haven_neighborhood
			*goto night_check
	*if (shopping_spree = false) and (ethnicity = "african")
		*selectable_if (wealth > 2500) #I want to go on a shopping spree.
			It is time to update your warddrobe.
			*page_break
			Your new glad rags are something to behold.
			*set wealth -2500
			*set shopping_spree true
			*set anachronism %+20
			*goto south_side_2
	#I want to go to a different neighborhood.
		Where do you want to go?
		*choice
			#Canaryville, an old Irish neighborhood, just to the east.
				*goto canaryville
			#Lincoln Park, home to mostly second-generation German immigrants.
				*goto lincoln_park
			#The 19th Ward, home to a new population of southern Italians.
				*goto little_italy
			#Uptown, where the wealthy folk live.
				*goto uptown

*label cats_meow
*set knows_cats_meow true

When people talk about 'speakeasies', they dream of juice joints like this.  The music might not be as good as down on the Stroll, but it's much harder to get a sip of hooch on the main drag.  Apparently, the name of this place is the Cat's Meow, and that it is.
*choice
	*selectable_if (charm > 2) #Get friendly with someone, get them drunk and then 'help' them home.
		A smashing success, if you do say so yourself.
		*set blood +4
		*set current_location "south_side_2"
		*goto blood_check
	#Follow a drunk out of the place, knock him out and feed.
		*if combat <= 5
			You are not up to the task of knocking a drunk unconscious.  Only by unleashing the animal within are you able to subdue him, but that also means killing him.
			*set exposure +1
			*set blood +10
			*set compassion %+10
			*set discretion %+5
			*set wealth +10
			*set current_location "south_side_2"
			*goto blood_check
		*else
			This is not a problem.  You leave your prey leaning against a building, a little worse for wear but they should be fine by tomorrow.
			*set blood +4
			*set current_location "south_side_2"
			*goto blood_check
	#Head back out to the Stroll.
		*goto south_side_2

*label royal_gardens

*if (presented_chicago = false) and (met_violet and (progression_in_time >= 2))
	When the bouncer sees you in line, he waves you forward.  By means of an unseen communication, word passes in and out, and you are told that Violet will be with you momentarily.

	"Evenin', ${given_name}.  Are you ready to meet Mr. O'Donnell?

	"I am," you reply.

	"Good.  Our car is here," she says as a car pulls up.  "Please, afta you."  You step into the car and, once situated, Violet signals to the driver who pulls out into traffic.  The car rumbles north towards Uptown.
	*goto meet_seamus_english
*else
	After waiting for a good half hour, impatiently tapping your foot as the line before you slowly shrinks, you are immersed in that new music as the doorman admits you into this holy of holies.  You can only imagine what this place must have been like two years ago.  Even now it jives with music, tobacco and marijuana, and everybody seems to be having a good time.  The mixed-race clientele bops along with the beat, and the dancefloor is filled with hoofers and the occasional floorflusher.

	*if (presented_chicago = false) and ((met_violet = false) and (perception > 2))
		There is another of my kind here.  A white woman, subtly dominating a booth of companions.
		*goto royal_gardens_2
	*if presented_chicago
		Violet Jones is here, sitting with 'friends' in a booth.
		*goto royal_gardens_2
	*else
		You would be surprised if a place like this didn't host some of your kind.  It seems the perfect place to find willing prey.  That said, you can't quite pick anyone specific out as being of your kind.
		*goto royal_gardens_2

*label royal_gardens_2
*choice
	*if presented_chicago
		*if met_violet = false
			#I want to introduce myself to Violet Jones.
				*goto meet_violet
	*if met_violet
		#I want to speak with Violet again.
			*goto chat_with_violet
	*if presented_chicago = false
		*if met_violet = false
			*if perception > 2
				#I want to try and fall into an encounter with the woman in the booth.
					*goto meet_violet
	*if presented_chicago = false
		*if met_violet = false
			#I take a seat and order a drink.
				If this place is as valuable as it seems to be, it's probably best to not hunt here until you've met the 'owner'.
				*set wealth -5
				*goto royal_gardens_3
	#I head back out to the Stroll.
		*if presented_chicago
			Unfortunately, things are crowded by the front door; you decide to leave through the back...
			*goto royal_gardens_rear
		*else
			*goto south_side_2

*label chat_with_violet
TODO
*goto royal_gardens_rear

*label royal_gardens_3

*if perception > 2
	It's not long before a fetching young bird comes and whispers in your ear.  Apparently, you've been invited to join "someone" at their table.  You smile to yourself as your are lead to the table and the characters you noticed when you walked in.
	*goto meet_violet
*else
	It's not long before a fetching young bird comes and whispers in your ear.  Her gestures make it clear that you've been invited to join someone at their table.
	
	You stand and follow her across the room, to a table full of characters in their glad-rags.  The leader of the bunch is a white woman, done up in the latest flapper style and probably in her late twenties.
	*goto meet_violet
	
*label meet_violet
*set met_violet true

*if speaks_english
	"So, what do they call you, sugah?"
	
	"I'm ${given_name} ${surname}."
	*goto meet_violet_2
*elseif speaks_french
	Discovering that you speak French, she quickly switches gears.

	"It has been some time since I've had the opportunity to stretch my tongue.  It is a pleasure to find an excuse to do so.  And what do they they call you?"

	"I am ${given_name} ${surname}."
	*goto meet_violet_2
*elseif presented_chicago
	She is clearly frustrated by your ignorance of English.

	You are lead to the rear exit and unceremoniously ejected from the establishment.
	*goto royal_gardens_rear
*else
	She is clearly frustrated by your ignorance of English.  She rummages through a purse until she finds something; tossing a matchbook with the logo of the Drake Hotel emblazoned on it, she concludes the audience with the universal gesture of dismissal known as the yawn.  At that, a companion approaches to take you from her sight.
	
	You are lead to the rear exit and unceremoniously ejected from the establishment.
	*goto south_side_2

*label meet_violet_2

*if archaic_name and (status < 3)
	"What a funny name.  You should think about changing it... I've heard tales about the prideful among us drawing unwanted attention to themselves because they refused to give up a name long out of fashion...  But no matter.  You are here because...?"
	
	*if discretion > 60
		You try not to bristle at her patronization, but hide it poorly.
		*goto meet_violet_3
	*else
		*goto meet_violet_3
*elseif Status > 2
	*if presented_chicago
		Her eyes widen ever so slightly at your introduction.
	
		"Honey dear!  Welcome to the Royal Garden Cafe!  Please, take a load off!"  An exclamation that is accompanied by her kicking some poor girl off the booth and onto the floor.  The young girl scowls at you before scampering away.
	
		After sitting down, she begins prattling...
	
		"I don't know if I've introduced myself!  I'm Violet Jones, a member of Quaestor O'Donnell's house.  The Royal Garden is mine, but you are welcome to drink from anyone here.  Who do you fancy?  Just point them out and I'll snap my fingers for you!"
	
		Her attempts at flattery continue for several minutes more, until you finally consent to picking out a young floorflusher to feed from.  Violet squeals in excitement.  With a subtle gesture, the young man separates from the crowd and approaches the booth.
	
		"${Mr} ${surname}, this is Soloman.  I'm sure you'll enjoy what he has to offer."
	
		Soloman takes a hold of your hand, leading you through the crowd and towards the rear exit.
		*set discretion %+5
		*goto royal_gardens_rear_prey
	*else
		"${mr} ${surname}!  Have you met Quaestor O'Donnell yet?"

		"No, I was hoping you could arrange an introduction."

		"Well, give me just a moment, and I'll take you to meet him!  It would be my pleasure!"  She disappears for a moment, and then returns, gesturing towards the door.
		
		You head outside.
		*page_break 
		Once there, the two of you wait for a few minutes, until a car rumbles up.  "Please," she says, gesturing for you to get into the car.  Once you've both taken your seats, the driver pulls out into traffic, heading Uptown.
		*goto meet_seamus_english
*elseif train_charm and speaks_english
	"And what can I do for you, ${mr} ${surname}?"
	
	"Mr. O'Donnell said I should seek training in our gifts from you.  I seem to have a hard time influencing the actions of mortals."
	
	"Somehow, that does not surprise me.  Come back the day after tomorrow, and I'll set aside some time to work with you on that."
	
	"Thank you."
	
	She dismisses you with a gesture, and a bodyguard leads you toward the rear exit.
	*goto royal_gardens_rear
*else
	"${given_name}, eh?  Well, don't just sit there flapping your gums."
	*goto meet_violet_3
	
*label meet_violet_3
*if presented_chicago
	
	"Mr. O'Donnell was kind enough to inform me that I could find you here..."
	
	"Then I can only assume that he also informed you that you should not seek sustenance here, as this place belongs to me."
	
	"Yes, of course."
	
	"Do you, then, have business with me?"
	
	"No... not exactly..."
	
	"Then dry up and scram.  I have no time for bootlickers."  With that, she gestures to a large man who escorts you towards the back door.
	*goto royal_gardens_rear
*else
	*set progression_in_time 0
	
	"I have just arrived in town, and have been seeking others like me."
	
	"Well, aren't you fortunate that you found one?"
	
	"Yes I am."
	
	"Well, you should make yourself known to the Quaestor.  I suppose you will need me to make the introduction."
	
	"That would be most appreciated."
	
	"Very well.  You should meet me back here the day after tomorrow.  I will take you to meet him.  Until then, do stay out of trouble.  Sam here will show you out the back."
	
	A large man whom you can only imagine to be Sam leads you to the back door and closes it behind you.
	*set violet_intro_to_quaestor true
	*goto south_side_2

*label royal_gardens_rear_prey
*set blood +2

While you had hoped to bring Soloman somewhere private, he seems to want to get things over quickly.  With little in the way of pomp or circumstance, you nuzzle his neck briefly before sinking your teeth into his skin.

After a few momements, you lick the wound closed.  He grabs you to steady himself, smiles at you, and then heads back into the club.

Once the door closes behind him, your ears close in on the sound of someone in distress.
*choice
	#The sound of a mortal's distress?  This does not interest me.
		*set compassion %+5
		*goto walking_away
	#Distress?  Maybe I can help!
		*set compassion %-10
		*goto find_clyde
	#Distress?  Perhaps I can benefit...
		*set compassion %+5
		*goto find_clyde

*label royal_gardens_rear

The backdoor of the cafe closes behind you, drastically decreasing--but not totally eliminating--the amount of noise in the alley.  While taking a moment to get your bearings, the sound of a mortal's distress echoes from deeper down the alley.

Which way?
*choice
	#The sound of a mortal's distress?  This does not interest me.
		*set compassion %+5
		*goto walking_away
	#Distress?  Maybe I can help!
		*set compassion %-10
		*goto find_clyde
	#Distress?  Perhaps I can benefit...
		*set compassion %+5
		*goto find_clyde

*label walking_away

As you turn towards the street, you see a man hurrying around the corner and into the alley.  He seems to be struggling with... putting something on.  Something that looks like... are those wings?  Yes, those are definitely wings... probably from a theater's discarded props or something.

*if perception > 1
	He's not breathing.
	*goto walking_away_2
*else
	*goto walking_away_2

*label walking_away_2
As the man continues down the alley, he stops and sizes you up.

*if speaks_english
	"Quick, I need your help," he says, as he brushes past you and heads towards the sounds of distress.
	*choice
		#Follow him.
			*goto follow_phineas
		#Scram.
			*set discretion %-5
			*goto abandon_phineas
*else
	He says something in English and gestures for you to follow him down the alley towards the screams.
	*choice
		#Follow him.
			*goto follow_phineas
		#Scram.
			*set discretion %-5
			*goto abandon_phineas

*label find_clyde

The words "You have SINNED!" careen off the walls of the buildings.  You round the corner only to draw up short in surprise.  Two men are clearly in view.  The first is hanging upside down, suspended from a fire-escape.  The screams and whimpers are clearly originating from him.

The second individual, well, would look like a normal Yank.  Except for the fact that he's liberally using a cat o' nine tails on the first.  "I AM YOUR PUNISHMENT!" the second man exclaims.

After observing this for a few moments, you realize that you must make a decision.

*choice
	*selectable_if (speaks_english) #Address the torturer.
		*goto address_clyde
	#Attack the torturer.
		*set discretion %+5
		*goto attack_clyde
	#Get the hell outta Dodge.
		*set discretion %-5
		*goto walking_away_3
		
*label walking_away_3

Turning on your heel, you nearly run into a third man heading up the alley behind you.  This one has... wings?... strapped to his back.

*if perception > 1
	He's not breathing.
	*goto walking_away_4
*else
	*goto walking_away_4

*label walking_away_4
The man with the wings stops and sizes you up.  After a moment, he opens his mouth to speak.

*if speaks_english
	"Quick, I need your help," he says, as he brushes past you and heads towards the scene you just fled.
	*choice
		#Follow him.
			*goto follow_phineas
		#Scram.
			*set discretion %-5
			*goto abandon_phineas
*else
	He says something in English and gestures for you to follow him back around the corner, towards the scene you just fled.
	*choice
		#Follow him.
			*goto follow_phineas
		#Scram.
			*set discretion %-5
			*goto abandon_phineas
	
*label address_clyde

"Who are you and what are you doing?"  You shout at the torturer.

One last crack of the whip echoes down the alley, before the torturer turns to face you.

He shrieks at you: "I am Clythenomenes the Thrasher!  And this man has sinned!  I have been sent by Hell itself to show him the error of his ways!"

*label attack_clyde

You slink down the alley, attempting to remain inconspicuous.  Finally, you are close enough to pounce.

Your first blow knocks the torturer to the ground, blood spraying the buildings.  He slowly rises to his knees, and opens his mouth to scream:

*if speaks_english
	"I am Clythenomenes the Thrasher!  You have interfered with Hell's justice!  Prepare to die."
	*goto attack_clyde_2
*else
	...but you don't understand a word.
	*goto attack_clyde_2

*label attack_clyde_2
*if combat <= 8
	*if speaks_english
		While you may have scored the first blow, this number is much stronger than you were expecting.  Your body is thrown from one side of the alley to the other like a rag doll.
		
		When you think that all is lost, it seems as though... suddenly... an angel comes around the corner from the direction of the Royal Garden.
		
		The angel pulls a blade from beneath his coat, and shouts: "Halt, Clythenomenes!  It is I, Gabriel.  Put that innocent down!"
		
		Clythenomenes, holding you by the throat, turns to face 'Gabriel'.  You take the oppotunity to jam your finger into his eyesocket, causing the eye to pop out and dangle from his skull.
		
		Clythenomenes drops you to the ground while screaming like a banshee.  'Gabriel' moves in with his blade, only to be disarmed by a surprisingly unfazed Clythenomenes.  Clythenomenes pops his eye back in his socket with one hand while pushing the dangling mortal into 'Gabriel' with the other.
		
		Before Gabriel or you can recover, Clythenomenes flees down the alley.
		*set blood -3
		*goto meet_phineas
	*else
		While you may have scored the first blow, this number is much stronger than you were expecting.  Your body is thrown from one side of the alley to the other like a rag doll.
		
		When you think that all is lost, it seems as though... suddenly... an angel comes around the corner from the direction of the Royal Garden.
		
		The angel pulls a blade from beneath his coat, and shouts something unintelligible.
		
		The torturer, holding you by the throat, turns to face the 'angel'.  You take the oppotunity to jam your finger into his eyesocket, causing the eye to pop out and dangle from his skull.
		
		The torturer drops you to the ground while screaming like a banshee.  The 'angel' moves in with his blade, only to be disarmed by a surprisingly unfazed torturer.  He then pops his eye back in his socket with one hand while pushing the dangling mortal into the 'angel' with the other.
		
		Before the 'angel' or you can recover, the torturer flees down the alley.
		*set blood -3
		*goto meet_phineas
*else
	With great effort, you manage to strike a telling blow against your opponent.  You might actually defeat him!  Unfortunately, he manages to get the body of the dangling mortal between the two of you, and uses it to knock you down long enough for him to flee.
	
	Within moments, you are surprised by the sudden arrival of... an angel?... from the direction that you had previously come.
	
	He looks you up and down, apparently surprised that you were able to chase off the torturer.
	*goto meet_phineas

*label follow_phineas

*if speaks_english
	Rounding the corner, you stumble upon the winged man challenging another individual with a cat o' nine tails, who has apparently been using it to good effect on yet a third man, suspended upside down from a fire-escape.
	
	"I am Clythenomenes the Thrasher!  Who dares to interrupt me?"
	
	"I am Gabriel, sent to put an end to your perversion!"  replies the winged man.
	
	"Perversion!  I am the emissary of Hell's justice!  Fall down before me!"
	
	The winged man draws a blade and charges the man with the whip.  They scuffle for several minutes, before the winged man is knocked down long enough for the man with the whip to flee.
	
	The wings are clearly ruined.  That said, the (formerly) winged man accepts your hand to stand.
	*goto meet_phineas
*else
	Rounding the corner, you stumble upon the winged man challenging another individual with a cat o' nine tails, who has apparently been using it to good effect on yet a third man, suspended upside down from a fire-escape.
	
	They exchange several exclamations, until the winged man draws a blade and charges the man with the whip.  They scuffle for several minutes, before the winged man is knocked down long enough for the man with the whip to flee.
	
	The wings are clearly ruined.  That said, the (formerly) winged man accepts your hand to stand.
	*goto meet_phineas

*label abandon_phineas

Meddling in the affairs of strangers with theatrical wings strapped to their backs never lead to anything good.
*goto abandon_phineas_2

*label meet_phineas
*if speaks_english
	"Good evening.  My name is Phineas, Phineas Campbell.  Please pardon the costume."
	
	"I was going to inquire..."
	
	"Yes, that was Clyde Thrasher, one of the Quaestor's house.  He has lost touch with reality in recent weeks, thinking himself a demon tasked with punishing the wicked.  Unfortunately, for us, he is just another vampire, but one who is actively breaking the Rule of Reserve.
	
	"What's more is that I am afraid that his sickness has spread to the other members of the Quaestor's house.  To answer that question, however, I need to capture Clyde.  Will you help me?"
	*choice
		#"Yes," you say, excited at the prospect of a power vacuum into which you can expand.
			*set discretion %+10
			*set independence %+5
			*goto yes_decision
		#"Yes," you say, knowing that this threat to the city must be put down.
			*set compassion %-10
			*set independence %+5
			*goto yes_decision
		#"No."
			You beg off, informing Phineas that you are too new to Chicago to involve yourself in its affairs.  He eyes you with suspicion, but concludes by noting, "I trust that you will keep this matter to yourself.  If our population is in trouble of being led astray by this mental disease, it would be best if the Quaestor did not know I was investigating him."  You assure Phineas that you will not betray his trust.
			
			Phineas turns to the suspended man, apparently of Italian extraction, and they hold a brief conversation before Phineas cuts him down.
			
			Phineas bids you goodbye, and heads away, supporting the Italian.
			
			Now comes a weighty decision.  Do you seek out the Quaestor, and inform him of this plot, or do you attempt to remain neutral?
			
			*if lore > 2
				You must also take into consideration to politics of your kind.  Regardless of the veracity of your claim, if Phineas is better respected than you, a claim of treason such as this will result in your punishment and an official dismissal of the charges.
				
				This is of no concern to you if Phineas is of littel import, but if he has standing here...
				*goto no_decision
			*else
				*goto no_decision
		*if (lore < 1) and (presented_chicago = false)
			#What is the Quaestor?
				Phineas' eyes widen at your ignorance.
				
				"The Quaestor is the vampire that is charged with the security of a city.  He is appointed by the Governor of the province, and it is the duty of all of our kind to make ourselves known to the Quaestor of a city we enter."
				
				"Oh."
				
				"So, will you help me?"
				*choice
					#"Yes," you say, excited at the prospect a power vacuum into which you can expand.
						*set discretion %+10
						*set independence %+5
						*goto yes_decision
					#"Yes," you say, knowing that this threat to the city must be put down.
						*set compassion %-10
						*set independence %+5
						*goto yes_decision
					#"No."
						You beg off, informing Phineas that you are too new to Chicago to involve yourself in its affairs.  He eyes you with suspicion, but concludes by noting, "I trust that you will keep this matter to yourself.  If our population is in trouble of being led astray by this mental disease, it would be best if the Quaestor did not know I was investigating him."  You assure Phineas that you will not betray his trust.
						
						Phineas turns to the suspended man, apparently of Italian extraction, and they hold a brief conversation before Phineas cuts him down.
						
						Phineas bids you goodbye, and heads away, supporting the Italian.
						
						Now comes a weighty decision.  Do you seek out the Quaestor, and inform him of this plot, or do you attempt to remain neutral?
						
						*if lore > 2
							You must also take into consideration to politics of your kind.  Regardless of the veracity of your claim, if Phineas is better respected than you, a claim of treason such as this will result in your punishment and an official dismissal of the charges.
							
							This is of no concern to you if Phineas is of littel import, but if he has standing here...
							*goto no_decision
						*else
							*goto no_decision
*else
	The man with the wings tries to speak with you, but soon discovers your lack of facility with the English language.  He frowns, shakes your hand, and then turns to deal with the suspended man.  He holds a brief conversation with the suspended man, who appears to be of Italian descent.  That concluded, the formerly winged man cuts the suspended man down.  They soon depart.
	*goto abandon_phineas_2
	
*label yes_decision
"I am grateful to hear that.  It is too late tonight, and I'm sure Violet has left the Royal already.  Meet me back on the Stroll tomorrow."
							
"I shall."

"Oh, your name?"

"You can call me ${given_name}," you reply.

"Well, until tomorrow night, ${given_name}."

"Until then," you reply.
*if chicago_haven_neighborhood = "empty"
	With a modicrum of effort, you manage to procure a suitable haven for yourself within the next few hours.  It will take days to make it fully suit your tastes, but it will get you through the next few days without too much discomfort.
	*set chicago_haven_neighborhood "south_side_2"
	*finish
*else
	*finish

*label no_decision
*choice
	#I must find the Quaestor!
		*set independence %+5
		*goto_scene chicago_tattle
	#I want nothing to do with this.
		*set independence %-20
		*goto abandon_phineas_2
		
*label abandon_phineas_2
*if chicago_haven_neighborhood = "empty"
	With a modicum of effort, you manage to procure a suitable haven for yourself within the next few hours.  It will take days to make it fully suit your tastes, but it will get you through the next few days without too much discomfort.
	*set chicago_haven_neighborhood "south_side_2"
	*goto_scene chicago_aloof
*else
	The sun is coming up soon.  You decide it is best to return to your haven for the day.
	*goto_scene chicago_aloof