*comment ñáéç…—
*hide_reuse
*advertisement
*gosub_scene util check_flow
*if revolutionary_credentials > 60
	*set lockridge_rapport %-20
*if revolutionary_credentials < 40
	*set lockridge_rapport %+10
*if rationalism > 70
	*set coffin_rapport %+10
*if rationalism < 40
	*set coffin_rapport %-10
*if ethnicity = "yankee"
	*set bailey_rapport %+10
	*set coffin_rapport %+10
	*set lockridge_rapport %-10
	*set pickering_rapport %-10
*if ethnicity = "scotch"
	*set partridge_rapport %+10
	*set harding_rapport %+10
	*set malloy_rapport %-10
*if ethnicity = "irish"
	*set malloy_rapport %+10
*if ethnicity = "southern"
	*set lockridge_rapport %+10
	*set pickering_rapport %+10
	*set coffin_rapport %+10
*if ethnicity = "african"
	*set pickering_rapport %-15
*if religious_tradition = "catholic"
	*set coffin_rapport %-5
	*set malloy_rapport %+5
	*set partridge_rapport %-5
*if religious_tradition = "pagan"
	*set coffin_rapport %-15
	*set lockridge_rapport %-10
	*set pickering_rapport %-10
*temp invitation_reextended false
*temp learned_of_reception false
*temp noticed_others false
*temp questions 0
*temp cloistered false
*temp here_for_election false
*temp son_of_ham false
*temp just_heard_of_chiara false
*temp pickering_voices false
*if invitation_to_reception_accepted
	It is a Wednesday evening, the night before the reception.  The hunger prowls inside you.  It is not a dire affair, but certainly noticeable.
	*if acquiring_vessels != "na"
		Tonight is really the first night that you can relax since you began rounding up mortals for the arrival of the senators.
	*elseif party_preparations != 1
		Tonight is the first night that you can relax since the preparations for the reception began.  Everything finally seems to be in place.
*else
	Another Wednesday evening in Memphis.  It has been a little over a week since you received the invitation from the quaestor to join him at the [i]crapaud[/i]-den.  The hunger prowls inside you.  It is not a dire affair, but certainly noticeable.

*if met_albert_pike and ((feeding_style = "soldiers") or (heresy_of_masons > 0))
	You decide to pay a call on General Pike.  He moved to Washington shortly after you made his acquaintance, but on occasion he returns to the home of his heart for a visit.  A few nights ago, you received notice that he was in town, and the thought of his blood sliding past your lips sets the tips of your toes a-tingle.  Setting your face into the wind, you stride purposefully towards the Gayoso Hotel, where he has taken rooms for the duration of his visit.
	*page_break
	*set pickering_and_pike true
	*set heard_of_pickering true
	*set met_pickering true
	Arriving at the Gayoso, you have your presence announced.  His valet admits you, and escorts you to the sitting room.  After announcing you, the valet retreats, leaving you alone with Pike and an individual whom you do not recognize: a white man, with brown hair and eyes, and a well-kept goatee that hides what would otherwise be a weak chin.  His hair is parted to side, somewhat low for your taste.  More importantly, however, you see immediately that he is a predator like you.  Pike introduces this vampire as Absalom Pickering, an acquaintance of his from Mobile.

	*if willpower < 3
		Only through a supreme effort of will do you manage to keep your fangs withdrawn.  
	How it is that this vampire has come to town and immediately sought to pluck the ripest of your fruits is unclear, but determined to find out, you struggle to keep your fury under control throughout a discussion of the cotton harvest.  The awkwardness of the conversation is only increased by the general refusal by yourself and Pickering to address each other directly.  As if by some pre-agreement, the two of you speak individually to Pike, and respond to the comments of the other by addressing Pike as though he were the origin of them.

	By the time the discussion of the cotton trade is quite finished, you can see that General Pike is exhausted by the effort of mediating the conversation.  Excusing himself to the privy, you finally have the opportunity to address Pickering directly.

	*if invitation_to_reception_accepted
		*set here_for_election true
		"I assume that you are here for the election?"

		"I am, in fact, here to stand for the election.  And you?"

		"I am a citizen of Memphis."

		"I had not heard that there were any other citizens than Carothers and his offspring."

		"I have only been here a short time."

		"And who is your dominus?"

		"${sire_name}."

		*if sire_alive = false
			"Hmm.  The name is familiar, but I'm afraid I have never met him."

			"Should you happen to, please give him my regards.  I have not had the pleasure of his company in decades myself."

			"That is unfortunate.  For you, I mean.   All young members of the Society need the guiding hand of their maker."

			Doing your best to hide your discomfort, you think it best to change the subject.
		*elseif sire_name = "West"
			"Oh, the beast?  I have heard of his exploits in Texas."

			"Yes, I traveled with him there."

			"And did you participate in his, how should I say, excesses there?"

			"We are vampires.  What more need be said," you reply, attempting to steel your eyes to dissuade any further inquiry.
		*elseif sire_formerly_quaestor
			"Formerly the Quaestor of New Orleans?"

			"The same."

			"How has he been occupying himself since Stone's misdeed?"

			"I cannot say; it has been some time since we conversed."

			"That is unfortunate.  For you, I mean.   All young members of the Society need the guiding hand of their maker."

			"He did well enough in the time that we were together," you reply, somewhat icily.
		*else
			"The Quaestor of New Orleans?"

			"The very same."

			"You are fortunate to have such an esteemed vampire as your dominus."

			"That is kind of you to say."

			"Please, when next you speak with him, extend him my regards."

			"I shall," you reply, smiling to disguise your complete disregard for this little promise.
	*else
		*set son_of_ham true
		*set learned_of_reception true
		"Pardon my ignorance, but I was not aware that another of our kind had taken up residence in our city."

		"Well, I haven't.  Not yet, anyway."

		"How do you mean?"

		Pickering cannot hide his astonishment at your words.  "The election?  For a Senator?"

		"I'm sorry?"

		"There is a reception tomorrow, where a handful of Senators will be gathered to meet the candidates, and Friday we will sit for it."

		"It was so good of the quaestor to inform me of this."
		*set pickering_rapport %+5

		"Somehow, that does not surprise me."

		"Oh?" you say, preparing a rebuttal to what you think must be coming next.

		"Of course.  Just because his maker was possessed of a madness to grant him the gift of immortality, that does not eliminate the nature with which he was born."

		"The nature with which he was born?"

		"A son of Ham, cursed by Noah himself."

		"And that is why he did not invite me?"

		"Clearly."
	*label question_pickering
	*choice
		*if learned_of_reception and (invitation_to_reception_accepted = false)
			#"Where will this reception be held tomorrow?"
				*set invitation_reextended true
				*set pickering_rapport %-5
				*set questions +1
				Pickering rolls his eyes as he informs you of the location of the event.
		*if here_for_election = false
			#"Will you be participating in the election?"
				*set here_for_election true
				*set questions +1
				"No.  I will be standing for it."
	
				"You seek to become the Senator of Memphis?"
	
				"I do."
	
				*if son_of_ham
					*set pickering_bigot true
					"You would take up residency in a city administered by a son of Ham?"
	
					"Where might I better show my prowess than in a city ruled by an incompetent?"
	
					"Incompetent because of his heritage."
	
					"Assuredly so."
		*if here_for_election
			#"What city do you call your home?  At least, until you win the election."
				*set discretion %+3
				*set questions +1
				*set question_quintana_unasked false
				Pickering smiles at this flattery.  "I am a citizen of Mobile.  My domina, Isabella Quintaña Garcia, is the quaestor there."
	
				*if heard_of_quintana
					*set pickering_rapport %+10
					"Of course.
					@{sire_formerly_quaestor My dominus|${new_orleans_quaestor_address}} spoke of her often.  Though, I dare say she never came to visit us in New Orleans.  Is it as dreadful of a town as he claimed?"
				*else
					*set heard_of_quintana true
					*set pickering_rapport %+5
					
					"Quintaña?  I'm afraid I have not had the pleasure of her acquaintance."
	
					"Then I take if you have never called on the city of Mobile?"
	
					You do your best not to wrinkle you nose in disgust.  "Certainly not."

				"It's not as bad as all that, I promise you.  But, after Jackson conquered the Floridas, the citizens of those territories were dispersed, and placed under the jurisdiction of Overstreet.  As you can imagine, this caused quite an uproar, as they had been under the purview of the Governor of Spain until that time.  My domina relocated to Mobile, and by way of amends, Overstreet later acknowledged her claim on the city."
				
				"She resided in St. Augustine originally?" @{met_overstreet The thought that Governor Overstreet needed to make amends with anyone seems a little far-fetched to you, but you refrain from commenting on it.|}
				
				"San Agustín, she would be quick to point out."
				
				"Yes, San Agustín, of course."
		*if here_for_election
			#"Do you know the identity of Carothers' maker?"
				*set discretion %+2
				*set questions +1
				*set pickering_rapport %+3
				Pickering looks decidedly discomforted by this question.  "In fact, I am unsure.  I have heard it whispered, however, that the individual is no more."
	
				"Was he a criminal of some sort?"
	
				"Whatever his crime, it was so heinous that its nature cannot be divulged."
	
				"Cannot, or will not?"
	
				"Unfortunately, I am ignorant of its nature myself."
	
				"And Carothers escapes any suspicion of complicity in this affair?"
	
				"Considering his tenure as Quaestor, it would seem to me that Governor Overstreet does not find the matter to be of concern.  And if the governor finds the matter insignificant, then it is probably best that you let it rest."
		*if knows_pickering_mason = false
			#"What brings you to the home of General Pike?"
				*set questions +1
				"You are aware that the general is a respected member of the Freemasons?"
	
				*if learn_of_masons
					"Yes."
				*else
					*set learn_of_masons true
					"No."
	
				"You must understand, then, that the Freemasons are an influential mortal organization.  As such, it behooves us to maintain good relations with him."
				*if (heresy_of_masons = 0) and (compassion > 50)
	
					"Why should you bother maintaining good relations?  Tell him what you want, and see to it that he obeys you."
	
					Pickering shifts in his seat, evidently trying to invent a suitable retort.  "The Rule of Reserve demands circumspection, ${mr} ${surname}.  While the Order may be the province of mere mortals, that does not mean that it should be discounted."
				*elseif (heresy_of_masons = 0)
					
					"I did not realize we were obligated to concern ourselves with such organizations."
	
					"How else are we to prevent the humans from destroying themselves?"
	
					"Destroying themselves?"
	
					"Have you not noticed their tendency towards ruin?  An organization such as the Freemasons seeks to nurture and preserve the best of human society.  To do so can only benefit our kind."
		*if (heresy_of_masons > 0) #@{knows_pickering_mason Using their secret gestures, I signal my membership in the Freemasons to Pickering.|I signal to Pickering my membership in the Order of Freemasons, in the hopes that he too is a member.}
			*set questions +1
			*if (ethnicity = "african") or (ethnicity = "choctaw")
				*set pickering_rapport %-30
				*if perception > 2
					*set pickering_bigot true
					*set knows_pickering_mason true
					There!  Right there!  A glance of smothered fury.  He saw, he understood, and he has rejected you.

					Apparently, even among the immortal, mortal prejudices remain.

					At this, General Pike re-enters from the privy.  An uncomfortable silence reigns in the room.  Pike tries to bridge this sudden distance, but finds the task insurmountable.  After a few moments of frozen niceties you excuse yourself; you will not be able to feed here this evening, and you have tired of their conversation.
					*goto resolve_end
				*else
					Perhaps you were too subtle in making it?  Regardless, your gesture elicits no reaction from Pickering.  You cast about, wondering how else you might engage this individual.
					*goto question_pickering
			*else
				*set pickering_rapport %+30
				*set knows_pickering_mason true
				A slow smile spreads across Pickering's face.  Standing, he extends his hand to you, offering an embrace.  You rise to meet him.  "Brother, it is an honor."

				"Likewise."

				"What brings you here this evening?"

				"Truly, I thirsted for the blood of the General."

				"I see.  But you should know, his import to our fraternity is great.  You should be careful with him."

				"Have no doubt that I am."
				
				At this, General Pike re-enters from the privy.  He smiles at the sight of the two of you finally speaking to each other.  His smile only broadens when Pickering reveals your membership in their fraternity.
				*page_break
				*set pickering_contactable true
				The rest of the evening consists of you better acquainting yourself with Pike and Pickering, and the concerns of the Order.  During its course, Pike mentions that he and General Forrest have had a falling out, due to Pike's allegiance to the Masons.  He also shares a way to contact him via post, should you have need.

				All too soon, the approaching dawn begins to roil your blood.  You and Pickering excuse yourselves in time to return to your resting places.
				*if learned_of_reception and (invitation_to_reception_accepted = false)
					*set invitation_reextended true
					*set pickering_position true
					During your goodbyes, Pickering makes sure to inform you of the location of the reception for the following evening.  He urges you to attend.  "Those of us who oppose Stone's insurrection must show our solidarity tomorrow evening."
					
					"Of course, Mr. Pickering."
				*goto resolve_end
		#"I would appreciate it, Mr. Pickering, if you would refrain from feeding from Mr. Pike."
			*set discretion %+5
			"He is, as you may have noticed, quite special. And I do not care to share."
			
			*if knows_pickering_mason or ((status > 1) or (revolutionary_credentials < 35))
				Pickering looks at you carefully, his lips pursed. "Of course, ${mr} ${surname}. I am but a guest here; I did not realize that he had been claimed." 
				*if (ethnicity = "african") or (ethnicity = "choctaw")
					*set pickering_rapport %-10
					@{pickering_bigot He visibly squirms in his seat as he says these words.|He almost spits as he says these words.}
					*if (perception > 2) and (pickering_bigot = false)
						*set pickering_bigot true
						You suddenly realize that he despises you…for the color of your skin. And while he may accede to you in this, he hates you for it.
				*else
					*set pickering_rapport %+5
				
				"It is already forgotten, Mr. Pickering."
			*else
				*set pickering_voices true
				*set pickering_rapport %-15
				*set revolutionary_credentials %+5
				Pickering scoffs. "Who are you to demand this of me? You are nothing."
				
				You are taken aback by Pickering's rudeness.
				*if (pickering_bigot = false) and ((ethnicity = "african") or (ethnicity = "choctaw"))
					*set pickering_bigot true
					This disregard for you goes beyond your station in the Society; you realize that he hates you for the color of your skin.
				
				"You are a guest in Memphis. Are you refusing to honor the Rule of Respect?"
				
				"The Rule of Respect honors a governor or her quaestors…not some lowly…"
	
	*if (questions > 1) or pickering_voices
		At this, General Pike re-enters from the privy.
		*if pickering_voices
		
			"Has there been some discord in my absence? I thought I heard you two quarreling."
			
			"No, not at all," @{(discretion < 50) you reply|Pickering replies}.
			
			"I am glad to hear it."
			
			You and Pickering are careful not to look at each other again. Pike seems to take this as an invitation to expound at length on the recent changes in his life. He
		*else
			He smiles at the sight of the two of you finally speaking to each other.

			You and Pickering studiously avoid answering any of Pike's questions about what you discussed in his absence, instead turning the conversation back around, to the luminaries of the city, a subject on which the General is more than happy to expound.  During its course, Pike 
		mentions that he and General Forrest have had a falling out, due to Pike's allegiance to the Masons.  After another twenty minutes or so, you excuse yourself; you will not be able to feed here this evening, and you @{pickering_voices can no longer stand to be in Pickering's presence|have tired of their conversation}.  
		*if (pickering_rapport > 55) and (pickering_voices = false)
			*set pickering_contactable true
			As you go to leave, however, Pickering presses a card into your hand.  It is an address where you may write to him, should you need to.
		*goto resolve_end
	*else
		It seems you have a few more moments before General Pike returns from the privy; what else would you like to ask of Pickering?
		*goto question_pickering
*if feeding_style = "vegetarian"
	Some nights, you like to wander through crowds…tormenting yourself with the smell of flesh begging to be drained of its fluids.  It seems like tonight will be one of those nights.
*else
	You decide to take a jaunt through town, to see if anyone seems particularly…available.
To say that the air is muggy would be a drastic understatement; early September in Memphis is never a pleasant affair.  "No worse than New Orleans, though," you muse to yourself.

*if (feeding_style != "clergy") and ((feeding_style != "socialites") and (feeding_style != "children"))
	Not long after setting out, the sounds of merry-making falls upon your ears.  Turning into a darkened stairway, 
	*if male
		you enter an affair of substantive proportions.
		*goto arrive_event
	*else
		you are stopped by a bouncer.  "This door is for customers, missy.  Whores come in through the back."

		You pause a moment.
		*if charm > 3
			But it is only a moment.  The snarl that issues from your throat is quickly followed by the overwhelming smell of urine.  "If you are so concerned about the customers, I suspect that you should clean that up."

			With that, you brush past the bouncer and make your entrance, making sure to pick your skirts up and over the quickly cooling puddle around his feet.
			*page_break
			*goto arrive_event
		*elseif (combat > 7) and (discretion > 50)
			But it is only a moment.  Because at the end of that moment, the bouncer's face is pressed against the wall, his arm pinned behind his back.  He whimpers in pain.  "Your dedication is admirable, but your discernment somewhat lacking."

			He mumbles an apology.  Throwing him aside in disgust, you set about making your entrance.
			*page_break
			*goto arrive_event
		*elseif streetwise > 1
			Dropping the names of several of the connected individuals around town, you make it clear that you are a customer, and not an employee.  Chastised, the bouncer steps aside and lets you pass.
			*page_break
			*goto arrive_event
		*else
			*set discretion %-5
			At a loss, you turn and make your way around to the back entrance.
			*page_break
			*goto arrive_event		
*elseif (feeding_style = "clergy") or (feeding_style = "socialites")
	*temp social_loc
	*set social_loc "church"
	*if (religious_tradition = "reformed") or (feeding_style = "socialites")
		Somewhere in the back of your head, you recollect an invitation to a soirée for this evening.  Organized by Susanne Davies, it will raise funds for the Methodist church.  It does not take long for you to make your way to the event.
		
		*if charm > 2
			Once inside, you move effortlessly between the circles, greeting those whom you've met, and making the acquaintance of those you have not.
			*gosub catholic_at_methodist
			*goto arrive_social
		*elseif charm = 2
			Once inside, you do your best to move between the groups, but you always seem just a moment late with your jokes and a tad off-color with the sentiments of the audience.
			*gosub catholic_at_methodist
			*goto arrive_social
		*else
			*set compassion %+5
			The guests shudder as you pass them by.  When you move to join their conversations, they turn to cut you out of their circles.  You watch with silent fury as these arrogant bastards tighten their ranks, leaving you out in the cold.  Even the minister gives you only the briefest of considerations before moving on to someone more suitable to his objectives.
			*gosub catholic_at_methodist
			*goto arrive_social
	*else
		*set social_loc "pinch"
		Somewhere in the back of your head, you recall an invitation to an event on behalf of the orphanage affiliated with St. Brigid's.
		
		The event is being held in the Pinch, and the devout of the city are in attendance.
		*goto arrive_social
*else
	*goto arrive_children
	
*label arrive_event
The forced laughter of the whores and the clouds of pipeweed envelop you at much the same time.  Stepping into this morass of sound and smells, you find a room full of celebrants, enjoying a night of revelry.  Spirits flow freely, dice are cast, and friendships are made and broken between puffs on corn-cob pipes.

*if perception > 1
	Within such a tight space, however, it is almost difficult not to notice that you are not the only one of your kind here.

	After surveying the celebrants for a time, you identify three individuals, one woman and two men, whom you conclude to be vampires like you.  The woman is clearly of Irish extraction, who laughs heartily at the efforts of the numerous mortals who vie for her attention.  Meanwhile, the two male vampires seem to be deep in discussion.  
*else
	It would be impossible to not notice the Irishwoman who seems to be holding court amidst the revelry.  She casually sits on a table, surrounded by men who vie for her attention.  It seems as though her hearty laugh could be heard from anywhere in the building. @{(streetwise > 1) You estimate from the way that she carries herself that she is her own woman, not here in a…professional…capacity.|}

*choice
	#@{(perception > 1) I approach the female vampire.|I approach the Irishwoman, and seek to gain her attention.}
		*set independence %+5
		*if perception > 1
			Without her having to say anything, the gathered men part like the Red Sea at your approach.
		*else
			Strangely, the crowd of suitors parts at your approach, allowing you to near the woman without difficulty.
		*set heard_of_malloy true
		*set met_malloy true
		She turns to look at you as you near.
		*if (speaks_english = false) and (speaks_french = false)
			She address you in English, but you are unable to understand her.  Through a few aborted attempts, you learn that her name is Siobhan Malloy, but any further communication is impossible.
			
			You bid her goodbye as best you can, and then take your leave of the event.
			*goto resolve_end
		*set memphis_chance_encounter "siobhan"

		"Good evening to you, ${sir}!"

		"And to you, ma'am," you reply with a ${bow}.

		"Are you a local, or are you guest as well?"

		*if perception <= 1
			You look at her in confusion.  She offers a sly grin in return.  "I'm sorry?" you choke out.

			"Come now, the city is swarming with our kind."
			
			"Our kind…yes."
			
			"You are not acquainted with Bailey and Partridge, then?" she says.
			
			"No?"
			
			She gestures to two white men sitting across from one another at another table. "You must learn to better identify our kind, ${given_name}," she ribs you.
			*set heard_of_bailey true
			*set heard_of_partridge true
			
			"Who are they?"

			"A local, then," she says with a smile that doesn't answer your question.
		*else
			"A local, ma'am."
			*line_break
			*line_break
		"Well, a pleasure to meet you.  I've just arrived myself from New-York.  It's so exciting to be here, in the West.  I feel almost as though, any moment, a band of Indians will break down the door, or perhaps a band of outlaws will come and drag me away to their lair."

		"I would not imagine that you would be long disquieted by such brigandry, ma'am."

		"No, I suppose not."  She pauses a moment, and then extends her hand in that most democratic of greetings.  "Siobhan Malloy.  A pleasure to meet you."  You look down at her extended hand.
		*choice
			*selectable_if (anachronism > 35) #I take her hand and shake it warmly.
				*set anachronism %+5
				*set malloy_rapport %+5
				*if invitation_to_reception_accepted
					*goto question_siobhan
				*else
					*label siobhan_informs_about_reception
					*set learned_of_reception true
					"What brings you to Memphis, Miss Malloy?"
					
					She looks at you in wonder.  "Why, the election, of course!"
					
					"Election?"
					
					"Yes, for the Senator of Memphis.  Senators from across the land have converged here for the reception and caucus."
					
					*if senators_explained = false
						*set senators_explained true
						*set senators_representation true
						*set malloy_rapport %-10	
						"What is a Senator?"
						
						She gapes at you. "The Senate represents itself to the vampiric courts. They make sure that matters of decorum are observed."
						
						You roll your eyes at the thought.
					*elseif senators_representation = false
						*set senators_representation true
						*set malloy_rapport %-5
						"I have heard of Senators, but I'm afraid I don't really understand their function."
						
						"They represent the Senate to the city to which they are appointed. They make sure matters of decorum are observed."
						
						You roll your eyes at the thought.
					"And do you mean to stand for this position?"
					*set malloy_for_senate true
					
					"I do."
					*goto question_siobhan
			*if male and (charm > 2)
				*selectable_if (anachronism < 65) #I bow and kiss her hand.
					*set malloy_rapport %-5
					She seems surprised at the grace with which you convert her proffered hand into a more traditional gesture of greeting.  "${given_name} ${surname}.  A pleasure."

					"The pleasure is mine, ${mr} ${surname}."
					
					*if invitation_to_reception_accepted
						*goto question_siobhan
					*else
						*goto siobhan_informs_about_reception
			*if (male = false) and (charm > 2)
				*selectable_if (anachronism < 65) #I take her hand and curtsy with it.
					*set malloy_rapport %-5
					She seems surprised at the grace with which you convert her proffered hand into a more traditional gesture of greeting.  "${given_name} ${surname}.  A pleasure."

					"The pleasure is mine, ${mr} ${surname}."
					
					*if invitation_to_reception_accepted
						*goto question_siobhan
					*else
						*goto siobhan_informs_about_reception
			*selectable_if (anachronism < 65) #I stare coldly at this gesture of familiarity, nodding only slightly in return.
				*set malloy_rapport %-10
				*set anachronism %-5
				*set revolutionary_credentials %-5
				After a moment of awkward silence, Siobhan withdraws her hand.  "I find such familiarity to be improper, ma'am."

				"So I see."

				"My name is ${given_name} ${surname}; allow me to welcome you to Memphis."
				
				She nods in reply.
				
				*if invitation_to_reception_accepted
					*goto question_siobhan
				*else
					*goto siobhan_informs_about_reception
			*if male and (anachronism < 50)
				*selectable_if (rationalism > 60) #"I find it improper to mix so casually with a stranger of the opposite gender.  In fact, I have to question the wisdom of your presence here alone, ma'am."
					*set malloy_rapport %-15
					*set rationalism %+5
					*set anachronism %-5
					*set cloistered true
					*set malloy_for_senate true
					Siobhan withdraws her hand with an almost audible snap.  "Improper?  What sort of relic are you?"

					"Relic?  I am not that old."

					"How should I feed, if I am not to be out alone after dark, sir?"

					"Have them brought to you."

					"An utterly impractical solution, especially when you consider the fact that I am only just arrived, and know no one in this city."

					"Then you should have stayed in New-York, ma'am."

					She groans in frustration.  "I will not live my unlife cloistered like a nun.  In fact, I hope that I win the election, simply so that you will be discomfited by it."

					*if invitation_to_reception_accepted
						"You are here to stand for the election?"

						"I am."
					*elseif chasing_wilson = false
						*set learned_of_reception true
						"Is that why you are here?"

						"It is."

						"The event has crept up on me; I did not realize it was to be so soon."

						She looks at you queerly.  "Yes, tomorrow evening.  Had you not heard?"

						"Not specifically, no."
					*else
						*set learned_of_reception true
						"Election?"

						"For the position of Senator of Memphis."

						"I had no idea."

						"Do you actively avoid others of your kind?"

						"Often, yes."

						"Well, you shall find it rather difficult over the next few nights.  There is a reception tomorrow, and the election the following evening."

						"And you wish to be considered for this position?"

						"Most certainly."
					*goto question_siobhan
	*if perception > 1
		#I approach the two white male vampires who seem to be deep in discussion.
			*set independence %+5
			They look up from their discussion as you approach.

			*label meet_partridge_and_bailey
			*set met_partridge true
			*set met_bailey true
			*set heard_of_bailey true
			*set heard_of_partridge true
			"Good evening, sirs.  I must say, it is not often that I see new faces in Memphis."
			*if speaks_english = false
				*label partridge_and_bailey_no_english
				*set memphis_bailey_couldnt_communicate true
				They look at you, uncomprehending.  You go back and forth, but cannot find a common tongue with either of them.
				
				You bid them goodbye as best you can, and then take your leave of the event.
				*goto resolve_end

			One of them, the bearded fellow, speaks first.  "It is not often that you have an election for the Senate."

			*if invitation_to_reception_accepted = false
				*set learned_of_reception true
				*if chasing_wilson
					*set partridge_rapport %-5
					*set bailey_rapport %-5
					"Election?"

					The two vampires stare at you in shock.  The clean-shaven one pipes up: "You are unaware of the impending election?"

					"Yes."

					"And yet you call Memphis home?"

					"I do."

					The bearded one interjects: "Tomorrow, there will be a reception, organized by Quaestor Carothers.  The following evening, the Senators will gather to chose a Senator for Memphis."

					"I had not realized.  I have been occupied with other things."

					"That is most curious!" says the clean-shaven one replies.

					"Yes, very curious," repeats the bearded one.

					Thinking it best to take control of this conversation, you elect to introduce yourself.
					*goto question_partridge_and_bailey
				*else
					*if discretion > 50
						"Oh, is that tomorrow?  I hadn't realized."
						
						They look at you, dumbfounded.  The bearded one speaks first, "Yes, tomorrow evening."
						
						*goto question_partridge_and_bailey
					*else
						"Of course!  The election would bring any number of our kind to the city."

						"You will be there, won't you?"

						"Of course I will be there.  That is why I came to Memphis, after all…to make my mark upon the Society."

						"Well, I wish you luck with that."

						*goto question_partridge_and_bailey
			*else
				"True enough.  Please, allow me to welcome you to Memphis."

				"Thank you," replies the bearded one.

				*goto question_partridge_and_bailey
	*if feeding_style != "vegetarian"
		*selectable_if (charm > 1) #I try to enjoy the party…and find some way to feed surreptitiously.
			*set discretion %-5
			*if speaks_english = false
				You are just settling onto a stool when a voice causes you to turn around.
	
				The bearded man stands there, jabbering at you in English.  You introduce yourself.
				*goto partridge_no_english
			"Are you a citizen of Memphis?" inquires a voice that refuses to be ignored. @{(perception > 2) Turning, you take in the sight of the bearded vampire nearing you.|Turning, you see a bearded man addressing you.}
			
			"I am," you reply.
	
			"Won't you come join us?  We're discussing the election." @{(perception < 2) You realize that this individual, and his fair-haired, clean-shaven companion, are both vampires.  How could you have missed them before?|}
	
			You follow him to their table before inquiring as to his meaning. 
			*goto meet_partridge_and_bailey
	*if (perception > 1) and (discretion < 50)
		*selectable_if (independence < 40) #I want no part of these vampires.
			*set independence %-10
			*if stealth > 2
				You make a hasty exit from the event.  It is almost as though you were never there.
				*goto resolve_end
			*else
				*if speaks_english = false
					*goto partridge_no_english
				Unfortunately, you are not the only one who has done the noticing.

				"Are you a citizen of Memphis?" the voice refuses to be ignored.

				Turning, you take in the sight of the bearded vampire nearing you.  "I am."

				"Won't you come join us?  We're discussing the election."
				*goto meet_partridge_and_bailey

*label partridge_no_english
He looks at you, uncomprehending.  You go back and forth, but cannot find a common tongue.  Other than his name, Samson Partridge, you cannot learn anything else from him.

You bid him goodbye as best you can, and then take your leave of the event.
*goto resolve_end

*label question_partridge_and_bailey
*set memphis_chance_encounter "partridge_bailey"

"I am ${given_name} ${surname}, a citizen of this fair city."

*if bailey_correspondence
	"Oh, I should have known!" the clean-shaven one replies. "I am John Bailey. Such a pleasure to put a face with a name."
	
	"Senator Bailey! A pleasure," you reply.
	
	"Please, this is Samson," he continues, gesturing to his companion. "I'm sure you'll get along famously."
	
	The bearded one extends his hand. "Samson Partridge, Senator of Louisville."
	
	"Senator," you reply with a @{male nod|half-curtsy}.
*else
	They both nod.  The clean-shaven one replies first: "I am John Bailey, Senator of St. Louis."
	
	"And I am Samson Partridge, Senator of Louisville," concludes the bearded one.
	*if lore > 2
		*set knows_partridge_childe_of_stone true
		Your eyes go wide at this introduction.  If you are not mistaken, this is the offspring of Isaiah Stone, the new Consul of the Americas.

	"An honor, gentlemen," you reply with a ${bow}.
*label question_partridge_and_bailey_1
*choice
	*if learned_of_reception
		#"You know, now that you mention it…where will the reception be held?"
			*set questions +1
			*set learned_of_reception false
			*set invitation_reextended true
			Partridge takes a moment to relate the directions to the event for tomorrow evening.
	#"Do you know who will stand for the position?"
		*set questions +1
		"We were just discussing that, in fact," replies Bailey.  "There seem to be several candidates for the position."

		"Not the least of which sits yonder," interjects Partridge, gesturing with his head towards the Irishwoman across the room.  "Her name is Siobhan Malloy, recently of New-York."
		*set heard_of_malloy true

		"She has made her position on Consul Stone clear, or so I've heard," says Bailey.

		"Oh?"

		"Yes…she is a staunch supporter."

		"Will that sway your opinion, Senator Bailey?" you inquire.

		"It certainly casts her in a favorable light, ${mr} ${surname}.  Tell me, what do you think of Stone's deed?"

		*choice
			*if knows_partridge_childe_of_stone
				#"Senator Partridge, I think your dominus righteous in his actions."
					*set revolutionary_credentials %+5
					*set discretion %+5
					*set partridge_rapport %+5
					*set bailey_rapport %+5
					*set questions +1
					Partridge smiles at this statement.  "You recognize my name.  You are not totally excluded from the circles of the Society, then."

					"No, not entirely."

					"Well, then, you will not be surprised to discover that I support my dominus's activities."

					"As do I," says Bailey.

					"Then I am in good company."

					"Clearly," concludes Partridge.
			*if knows_partridge_childe_of_stone
				#I will play coy with my knowledge of Partridge's lineage.  "I think it high time that the New World went its own way."
					*set discretion %-10
					*goto went_its_own_way
			*else
				#"I think it high time that the New World went its own way."
					*set revolutionary_credentials %+10
					*label went_its_own_way
					*set questions +1
					*set bailey_rapport %+10
					*set partridge_rapport %+5
					*set discretion %+5
					"Well, I think we are all in agreement, then," says Partridge.

					"It would seem so," concludes Bailey.
			#"I think Stone's rebellion will end soon enough.  The Society will not tolerate such divisions for long."
				*set revolutionary_credentials %-10
				*set bailey_rapport %-10
				*set partridge_rapport %-10
				*set discretion %-5
				*set questions +1
				Both of their eyes narrow at this statement.  Partridge speaks first: "I suppose we shall find out one way or another over the next few days, then."

				It seems you have found yourself a pair of revolutionaries.  "I wonder who will stand against us.  I don't suppose you are here for the position?" inquires Bailey.
				*choice
					*selectable_if (discretion > 40) #"Yes, I do seek the position.  I suppose I am glad to know where we stand with each other."
						*set discretion %+10
						"Yes, I suppose that it is good.  Now, if you will excuse us, we have much to discuss," replies Bailey.

						"Of course.  Until tomorrow, then."

						"Yes, until then, ${mr} ${surname}," concludes Partridge.
					#"No, I do not seek the position."
						"That is probably for the best.  We would not want to find ourselves adversaries so soon after meeting," says Bailey.

						"Certainly not," says Partridge.

						"Well, if you will excuse me, I have some things to take care of, and then I must return to my haven to prepare for tomorrow."

						"Of course, ${mr} ${surname}.  Until then."  Nodding, you take your leave of the Senators.
					*selectable_if (charm > 2) #"Perhaps you misunderstood me.  I do intend to stand for the position, but not in opposition to Stone."
						*set partridge_rapport %+5
						*set bailey_rapport %+5
						"Then, what did you mean, ${mr} ${surname}?" asks Partridge.  Bailey seems to smile as you open your mouth to extract yourself from your faux-pas.

						"I meant simply that it will no longer be considered a rebellion.  Rome and Baltimore are separated by such great distances… a peace will no doubt be made soon.  The Society will not tolerate open hostility."

						Bailey considers this before replying.  "I expect you are correct.  Some sort of understanding will be reached soon."

						Sensing that you have smoothed things over as best you can, you seek an exit.  "Now, if you will excuse me, I must feed before the sun rises."

						"Of course.  Until tomorrow," Partridge replies.

						"Until then, Senators."
				*goto resolve_end
			#"I'm afraid I know little about the affair.  What do you think of it?"
				*set discretion %-5
				*set questions +1
				The two Senators look at each other before Bailey finally speaks.
				*if revolutionary_credentials > 60
					*set bailey_rapport %+5
					*set partridge_rapport %+5
					"You do not have to be so coy, ${mr} ${surname}.  Your commitment to the revolution is not exactly a secret."

					"My commitment…to the revolution?" you stutter.

					"Of course!  And you are in good company here."

					"I am?"

					"I am the Senator of St. Louis.  Other than there, and Baltimore itself, where has the revolution more clearly flourished?"

					"I cannot say."

					"Well, no matter.  The revolution cannot be stopped, and we are proud to count you amongst our numbers."

					"I…thank you, Senator."
				*elseif (revolutionary_credentials >= 40)
					"I am the Senator of St. Louis.  Other than there, and Baltimore itself, where has the revolution more clearly flourished?"

					"So…you support it?"

					"Most certainly.  That mummy that rules from Rome should have lain down to rest centuries ago."

					"I see."
				*else
					*set revolutionary_credentials %-5
					*set bailey_rapport %-5
					*set confrontation_bailey_chance_encounter true
					"Given your reputation, ${mr} ${surname}, I am surprised at your discretion."

					"My reputation?"

					"For being a counter-revolutionary."
					
					"I'm sorry?"

					"Let me make this clear, I fully support Consul Stone.  That mummy that rules from Rome should have lain down to rest centuries ago."

					You struggle to take this all in.  "I see.  Well, I am glad that you have made your position clear."

					"You can go now, and tell whomever you came here to serve that I am not ashamed of my politics."

					"I did not…"

					Partridge waves his hand to silence you, before you infuriate Bailey further.  "Go, now.  Perhaps tomorrow we may continue this conversation."

					"Yes, of course, Senators," you say as you take your leave of them.
					*goto resolve_end
	*if sire_formerly_quaestor
		*if sire_name = "Padre Carlos"
			#"My dominus, Padre Carlos, was, until recently, Quaestor of New Orleans.  Have you heard anything of him as of late?"
				*set partridge_rapport %+5
				*set bailey_rapport %-5
				*set questions +1
				"Why, he serves as the new Praetor!" exclaims Partridge.

				"I was aware of that, but I had not heard of his whereabouts or activities otherwise."

				Partridge considers a moment.  "I believe I heard that he spent some time in the Caribbean, but nothing more specific than that."

				You look to Bailey, who does not meet your gaze.  "No, I have heard nothing of him."
		*elseif sire_name = "Guillaume de Sainte-Chapelle"
			#"My dominus, ${sire_name}, was, until recently, Quaestor of New Orleans.  Have you heard anything of him as of late?"
				*set questions +1
				Partridge shakes his head, but Bailey speaks up: "As a matter of fact, he passed through St. Louis a few years ago.  He stayed for a while, but then continued north."

				"I thank you for this intelligence, sir."

				"You are most welcome, ${mr} ${surname}."
		*else
			#"My dominus, ${sire_name}, was, until recently, Quaestor of New Orleans.  Have you heard anything of him as of late?"
				*set questions +1
				Partridge considers a moment before replying: "I'm afraid I have heard little of ${sire_name} since he was replaced."
	#"Do you find Memphis to your liking?"
		*set rumors_of_plague true
		*set questions +1
		The two Senators look at each other before responding.  "As a matter of fact," the bearded Partridge begins, "we have found things somewhat distressing here."

		"Oh?  How so?"

		"We procured a residence for ourselves, and upon our arrival, found that several of our servants had fallen ill in the days immediately prior."

		*if compassion > 60
			"Your point?" you reply.

			Bailey seems a little surprised by your callousness, but takes it in stride.  "It is simply inconvenient to have to worry about our valets falling ill themselves, besides having to find others to fill the empty roles."

			"Of course.  That is inconvenient."
		*elseif compassion >= 40
			"That is unfortunate.  Will they recover?"

			"I am uncertain," interjects Bailey, "but some have, in fact, already succumbed to the infection."

			"It is virulent, then?"

			"Quite."

			"I shall have to warn mine own servants.  I cannot afford for them to take ill at the moment."
		*else
			"How horrible!  Did any die?"

			"Several!" exclaims Bailey.

			"Have you found the source of the infection?"

			"Unfortunately, no.  In fact, the health officials of the city seem most perplexed by the outbreak."

			"I shall have to warn mine own employees to be especially careful, as long as whatever this is runs rampant."
*if questions > 1

	"Well, I thank you for your time, good sirs, but I'm afraid I must excuse myself.  The evening passes quickly, and I have much to do before the dawn."
	
	"Of course, ${mr} ${surname}.  I trust we shall see you tomorrow, then?"
	
	"Quite possibly, quite possibly," you reply, noncommittal. With a smile and a ${bow}, you turn to leave.
	*if (bailey_rapport > 55) or (partridge_rapport > 55)
		*set bailey_contactable true
		*set partridge_contactable true
		
		"Not so fast!" Partridge exclaims.
	
		*if bailey_correspondence
			"Yes?"
			
			Partridge presses a card into your hand. "Should you want to hear the truth of any lies that John tells you," he says.
		*else
			"Here, take these," Bailey continues, after taking something from Partridge.  Bailey nears, and presses two cards into your hand.  "Should you ever need to write," he says with a wink.
		Nodding, you continue on.
	*goto resolve_end
*else
	A momentary pause comes over the conversation, and you realize that you have the opportunity to ask them another question.
	*goto question_partridge_and_bailey_1

*label question_siobhan
*choice
	*if malloy_for_senate
		#"Do you know who else will stand for the position?"
			*set questions +1
			"Unfortunately, I do not.  But I assume that there will be several candidates."
	*if learned_of_reception
		#"Where will the reception be held tomorrow?"
			*set learned_of_reception false
			*set invitation_reextended true
			*set questions +1
			She takes a moment to give you directions to the event.  You thank her for her indulgence.
	#"If I may, who is your dominus?" 
		*set questions +1
		*set discretion %+5
		*set heard_of_ogier true
		"Forward, aren't you?"

		"Perhaps; most are proud of their lineage, however."

		"Arnoult Ogier.  He was a citizen of New-York.  And you?"

		"${sire_name}.
		*if sire_alive
			*if sire_name = "West"
				*set malloy_rapport %-10
				He roams the edges of civilization, resting wherever he finds himself when the sun's first rays appear."

				"A poetic description for a beast.  Though some find such antisocial behavior admirable, I cannot say that I am one of them."
			*elseif sire_formerly_quaestor
				He was Quaestor of New Orleans until Consul Stone's revolution.  Since then, I have heard little of him."

				"That is unfortunate for you."
			*else
				He is the Quaestor of New Orleans."

				"Yes, I have heard of him, but we have never met."
		*else
			Have you heard of him?  We have lost contact."

			"No, I'm afraid I have not."
		*if lore > 3
			*set knows_ogier_heretic true
			*set praetors_explained true
		
			A thought pops into your head.  
			*if discretion > 50
				*set malloy_rapport %-10
				"Arnoult Ogier?  Wasn't he a heretic?"
			
				Malloy goes very still.  "He was accused of such, yes."
				
				"And executed by Praetor Miele?"
				
				"The same."
				
				"I see."  She looks decidedly uncomfortable at this line of questioning.
			*else
				*set malloy_rapport %+5
				"Do I recall correctly, that your dominus has passed on?"
				
				"You imply it so deftly, ${mr} ${surname}.  Yes, he was accused of heresy, and executed by Praetor Miele."
				
				"My condolences."
				
				"You are too kind," she finishes, clearly desirous of changing the subject.
	*if malloy_for_senate = false
		#"Are you a Senator, here for the election?"
			*set questions +1
			*set malloy_for_senate true
			"No.  I am here, rather, to stand for the election."

			"You would be Senator of Memphis?"

			"I would."
	*if malloy_for_senate
		#"What do you think of Stone's revolution?"
			*set questions +1
			*set discretion %+5
			"I spent several years with Consul Stone in Baltimore.  I think he has taken a bold move, necessary for the progress of our kind."

			"I see."

			"The election must be won by a friend of Stone, lest the tide turn against him."

*if questions > 1
	"Well, I thank you for your time, Miss Malloy, but I'm afraid I must excuse myself.  The evening passes quickly, and I have much to do before the dawn."
	
	"Of course, ${mr} ${surname}.  I trust I shall see you tomorrow, then?"
	
	"Quite possibly, quite possibly," you reply, noncommittal.  With a smile and a ${bow}, you turn to leave.
	*goto resolve_end
*else
	She looks around, but no one else seems willing to interrupt your conversation.
	*goto question_siobhan


*label catholic_at_methodist
*if (religious_tradition = "catholic") and (rationalism > 60)

	At the same time, you do your best not to sneer at the various manifestations of Protestantism around you.  The fact that heaven is closed to these heretics does not seem to enter into their consciousness.
*return

*label arrive_social
*if social_loc = "church"

	You are not surprised to see the Meriwether women here, soliciting support for their temperance efforts.
	*if feeding_style = "drunks"
		You do your best not to glare at them.
*if perception > 1

	*set noticed_others true
	You slowly become aware that you are not the only one of your kind in attendance; there are, in fact, at least two others.  One is a distinguished gentlemen, who speaks with the lilt of the Carolinas.  The other is a woman dressed in the austere garb of the early New England colonists.
	*if social_loc = "pinch"
		She seems a tad out-of-place among all these boisterous Irishfolk.
	*choice
		#I approach the gentleman from the Carolinas.
			*set independence %+5
			*set lockridge_rapport %+5
			*label meet_charleston
			*if (speaks_english = false) and (speaks_french = false)
				*goto failure_to_communicate_lockridge
			"Arthur Lockridge, progeny of Ethelmarr, Senator of Charleston."
			*set heard_of_ethelmarr true
			*set heard_of_lockridge true
			*set met_lockridge true
			
			You bow deeply.  "${given_name} ${surname},
			*if (intelligence > 2) or (lore > 2)
				progeny of ${sire_name},
			citizen of Memphis."
			
			*if (intelligence > 2) or (lore > 2)
				*if (sire_name = "Padre Carlos") and sire_alive
					*set lockridge_rapport %-10
					"Padre Carlos?  The new Praetor?"
					
					"The very same."
					
					His eyes close to slits as he focuses on you.  He quickly changes the topic.
				*elseif sire_name = "West"
					"West?  The beast?  I thought I smelled something of the wolf on you."  You do your best not to bristle at this.  He continues on, changing the topic.
				*elseif (sire_name = "Wallace Winters") and patricide
					"That wretch!  I am grateful that I have not heard one word of him in almost a century.  What has become of your dominus, ${mr} ${surname}?"
					
					You tremble in fear at the memory of your crime.  "I cannot say.  He abandoned me at my creation."
					
					"Somehow, that does not surprise me.  You are fortunate to have made it this long without the guidance of a dominus, however."
					
					"Quaestor Van der Velde was kind enough to take me under his wing."
					
					"Yes, he seems like a stand up sort of fellow."
			
			*set memphis_chance_encounter "arthur"
			*if tiozzo_portrait_1831 = 3
				*set lockridge_rapport %+10
				His eyes widen. "Did you say ${given_name} ${surname}?"
				
				"I…I did?"
				
				"The young one who sat for Lady Tiozzo?"
				
				If you could exhale, you would. "The very same."
				
				"She is very talented. Perhaps you will allow me to see the portrait one evening?"
				
				"But of course, Senator."
				
				He smiles broadly. "I look forward to it." Changing the topic, he rolls his eyes. "What I do not look forward to is meeting your quaestor, but I suppose it will happen soon enough."
			*elseif tiozzo_portrait_1831 = 2
				*set lockridge_rapport %-20
				His eyes widen. "Did you say ${given_name} ${surname}?"
				
				"I…I did?"
				
				"The young one who sat for Lady Tiozzo? And then destroyed that very work of art?"

				If you could exhale, you would. "The very same."

				"Well, I hope you have learned to better control yourself in the intervening decades."

				You glare at the Senator. "Yes, for both our sakes."

				He smiles back at you, as though to say, "Try me," but instead he changes the subject. "On the matter of self-control, I am not looking forward to meeting your Quaestor."
			*else
				"I have yet to meet Carothers, but I suppose that will happen soon enough."
			
			*if invitation_to_reception_accepted = false
				*set lockridge_rapport %-5
				*set invitation_reextended true
				"You have yet to introduce yourself, Senator?"
				
				"Well, considering the reception tomorrow, the rules are somewhat relaxed."
				
				"Reception?"
				
				It occurs to you that this Lockridge fellow rarely shows what he is thinking, but for just this once, he is unable to conceal his amazement.  "The reception before the election?  For the new Senator of Memphis?"
				
				*if chasing_wilson = false
					"Oh, is that happening tomorrow?"
					
					"It is.  I suspect that you will attend as well?"
					
					"Perhaps."  Again, Lockridge seems perplexed by your indifference to the affairs of the Society.  He takes a moment to inform you of the location of the reception for tomorrow, should you change your mind.
				*else
					"Oh.  I hadn't heard."
					
					"Do you eschew the company of your kind?"
					
					"Often, yes."
					
					"Strange.  I have heard of your kind, but I am surprised to encounter one residing in a city."
					
					"Other obligations keep me here."
					
					"I see.  Well, should you change your mind…" He takes a moment to inform you of the location of the reception for tomorrow.

				*if independence > 40
					Casting about, you decide to make a little bit of small talk.
				*else
					He stands there, looking at you.  "Well, if there's nothing else I can do for you, Senator," you venture.

					"No, I suppose not.  Good evening."

					"And to you, Senator."  Turning, you leave the soirée; you are a bit peckish, but not terribly worried about it.  If the city is crawling with visiting vampires, it may be best to avoid hunting for a few days, lest you run into more of your kind as you did tonight.
					*goto resolve_end
			*else
				"Well, I am sure that Quaestor Carothers looks forward to making your acquaintance."
				
				"Yes, it will be quite the event, won't it?"
			
			*if (acquiring_vessels = "success") and (discretion > 40)
				*set lockridge_rapport %+5
				"I do hope you enjoy the refreshments.  I gathered them myself."
				
				"An enterprising young vampire!  How…unexpected!  Yes, I expect that I shall enjoy your refreshments."
			*if (party_preparations > 0) and ((discretion > 40) and (memphis_reception_planner_1873 != "Dido"))
				*set lockridge_judging_party true
				"In fact, I am responsible for organizing the event."
				
				"Is that so?  Well, I will be watching closely."  You are not sure if this is a promise or a threat.  You think it best to change the topic of conversation.
			
			"Are you familiar with the candidates?" you inquire.
			
			"I have only met Mr. Pickering, of Birmingham.  I think him an excellent candidate for Senator.  He has made it clear to me that his priorities lay where they ought."
			
			"What do you mean by 'priorities'?"
			
			"He knows where his loyalties belong.  This whole affair with the imposter."
			
			"Imposter?"
			
			"Yes…this 'Consul Stone'," he says, wrinkling his face as though the very words tasted bad on their exit.  "Don't tell me that you support this foolishness."
			*choice
				#"Actually, I thought it high time the New World went its own way."
					*set revolutionary_credentials %+20
					*set lockridge_rapport %-30
					Lockridge goes very still at this statement.
					
					After a moment, he continues.  "Well, I see that we have nothing further to discuss.  I'm sure you can find your own way out."
					
					Unwilling to provoke any further confrontation, you do as he says, and make your way out of the gathering.
					*page_break
					*goto resolve_end
				#"No, I think his actions a mistake of the highest order."
					*set lockridge_rapport %+15
					*set revolutionary_credentials %-10
					*set lockridge_contactable true
					"I am glad to hear it.  The whole affair is distasteful in the extreme.  I trust, then, that you will be lending your support, such as it is, to Mr. Pickering?"

					"I am not a senator, Senator.  I do not imagine that mine opinion carries much weight."

					"Too true, ${mr} ${surname}.  Well, I have enjoyed this.  I trust we might continue tomorrow?"

					"Yes, Senator."

					"Should you have need of me, ${mr} ${surname}, here is my calling card.  You can write to me in Charleston."  

					"Thank you, Senator."  With that, you take your leave of the church event.  You make your way to your haven, still unfed.
					*page_break
					*goto resolve_end
				#"I am afraid that I do not know enough of this matter…"
					*set lockridge_rapport %+5
					"It is simple, ${mr} ${surname}.  This is the first election since the murder of Praetor Miele.  Should an ally of Stone be elected, all will read it as a sign of support.  If an enemy of Stone is elected, then his so-called 'revolution' will be rather short-lived."

					"I had not realized the import of this gathering."

					"Now that you are aware, I would recommend that you tread carefully."

					"I most certainly shall, Senator.  I thank you for your time."

					"You are most welcome, ${sir}."  With that, you take your leave of the church event.  You make your way to your haven, still unfed.
					*page_break
					*goto resolve_end
		#I approach the lady from New England.
			*set independence %+5
			*set coffin_rapport %+5
			She looks at you with skepticism in her eyes.
			*label meet_cincinnati
			*set met_coffin true
			*set memphis_chance_encounter "abigail"
			*if speaks_english = false
				*set coffin_rapport %-10
				When she speaks, it is in English.  It seems clear that she is trying to communicate introductions, and she is clearly displeased when you try to respond in your own tongue.  After a few more attempts, you suddenly feel the blow of a pickax in your mind.
			"And who art thou?"
			*if speaks_english = false
				*set discovered_telepathy true
				The question resonates in your mind, without the mediation of your ears.

				"But… how do I hear you?"  You stutter in response.

				"Someday thou may possess such powers as well.  But that does not answer my question."
			*comment endif

			You blink at the archaism of her speech.  "${given_name} ${surname}, a citizen of Memphis."
			*if speaks_english = false
				The words are said in your head, rather than aloud; the act of thinking them in your head in order to communicate is new and strange.  You struggle to keep your thoughts on track, unsure of what she stray thoughts she "hears" and what remains "unsaid".
			*comment endif

			"I had not heard that there were such besides Carothers and his progeny." @{priest She eyes your collar and cassock pointedly. "And certainly not a man of the cloth."|}

			"I stand before you, in the flesh."

			"So I see."

			*if invitation_to_reception_accepted
				"I imagine that you are here for the election?"

				"Thou speaks truly."

				"Might I inquire as to your name?"

				"Abigail Coffin.  Senator of Cincinnati."

				"An honor, my lady," you say with a ${bow}.  "I see that you have made yourself at home."

				"Yes.  I do not wish to go hungry at the festivities on the morrow."

				*if (acquiring_vessels = "success") and (discretion > 30)
					*set coffin_rapport %-10
					"You should not burden yourself with such cares, Senator.  I myself acquired the refreshments for tomorrow.  I expect that you will find them to your liking."

					"The vessels for tomorrow?  You gathered them yourself?

					"I did."

					"And did you enjoy that task?"

					*if compassion > 50
						*set coffin_rapport %-15
						*set compassion %+5
						"I suppose that you could say that, Senator.  The whimpers of the humans once they realized their fate was most entertaining."

						"So I see."
						*goto vessels_coffin
					*elseif independence > 50
						"It was out of duty to the Society, nothing more."

						"So I see."
						*goto vessels_coffin
					*elseif debt_from_carothers and (discretion > 40)
						*set coffin_rapport %-10
						"Carothers needed it done.  I was free to do it.  Agreements were made.  Such is the way of our kind."

						"So I see."
						*goto vessels_coffin
					*elseif discretion > 50
						"It was no great bother, Senator.  It needed doing, and I was available to do it."

						"So I see."
						*goto vessels_coffin
					*else
						*set coffin_rapport %+5
						"It was not a deed in which I took pleasure, no."

						"I am relieved to hear it."
						*goto vessels_coffin
				*if acquiring_vessels = "failed"
					You squirm under her gaze, the memory of your recent failure in that regard still fresh in your mind.  You hope that her gaze does not pierce your thoughts, and deduce the extent of your shame.

				"I hear it told that you will not go hungry.  The quaestor has made arrangements."

				"Oh, but the condition under which such refreshments are obtained and maintained is usually so unfortunate.  The fear and suffering does not suit my palate."

				"Then I suppose it fortunate that you have organized this affair."

				"I am not responsible for this.  In fact, I owe a debt of gratitude to Mr. Lockridge there," she says, nodding towards the gentleman from the Carolinas, "for inviting me to this event.  He and I may not see eye to eye on many things, but on some, we do agree."

				"Perhaps I should introduce myself, then."

				"The Senator from Charleston seems preoccupied at this moment.  I will extend your gratitude on your behalf."

				"I thank you, Senator." 
				*set heard_of_lockridge true
				*goto end_coffin
			*else
				*set learned_of_reception true
				"Have you taken up residence in the city?  I was not aware of your arrival."

				"No, I am here for the election."

				*if chasing_wilson
					"Election?"

					"For the new Senator of Memphis."

					"I didn't realize…"

					"Thou must be one who eschews the company of his kind.  I have met those such as thee, yet never did they take up residence in cities where others of their kind did reside."
					*choice
						*selectable_if (rationalism > 40) #"In truth, I find the company of the damned to be trying to my soul.  Alone, I am not provoked to the worst in my nature."
							*set rationalism %+5
							*set independence %-5
							*set coffin_rapport %+10
							She looks at you suspiciously.  "Thou believes thy soul to be damned?"

							"I do."

							"And how came thee to this conclusion?"

							"To what other conclusion could I arrive?  I am forbidden from partaking in the sun, which gives life to the earth and its creatures, and instead find myself cursed to drink on the blood of my neighbors for sustenance.  I am lost in the eyes of God, and only in solitude can I resist the urge to embrace that fell nature further."

							"I see.  Well, we should perhaps discuss this another time.  I urge you to attend the reception tomorrow evening.  You might very well be the most interesting person there, ${mr} ${surname}."  She then takes a moment to inform you of its location.  "Do thou think I shall see thee there?"

							"I make no promises, Senator Coffin."

							"That is most forthright of thee.  Until next we meet, then."

							"Until then."
							*set invitation_reextended true
							*goto end_coffin
						#"It is not a matter of avoiding others of my kind.  I have a task before me, and nothing shall sway me from it."
							*set independence %+5
							"A task?  How mysterious.  Well, I would not wish to pry into thine affairs.  Perhaps you should see to it, then."

							"See to it?"

							"Yes, thy task.  I'm sure thou does not care to let time pass so frivolously as it is now."

							"No, of course…"

							"Well, please, get thee hence, I would not want to be held responsible for thy failure."

							"Thank you, senator.  Good evening to you."  
							*goto end_coffin
						*selectable_if (independence < 60) #"Unfortunately, obligations force me to reside in the city, even if I would prefer solitude."
							*set independence %-5
							"I see.  Well, thine obligations ought to oblige thee to keep better informed of events.  The reception for the Senators transpires on the morrow.  I suspect that thy quaestor would welcome thine attendance."  This observation is followed by a brief description of the location and timing of the party for the following evening.  "Shall I except thy presence there?"

							"Perhaps, Senator."

							"Until then, ${sir}."

							"Until then."  
							*goto end_coffin
				*else
					"Of course!  I did not realize the time for that had arrived."

					"Oh?  Thou art woefully uninformed, then.  The reception for the arriving Senators is tomorrow evening."  She takes a moment to inform you of the necessary details.
					*set invitation_reextended true
					"Shall I enjoy the drudgery of thy company there, ${mr} ${surname}?"

					"Perhaps.  One never knows where the night might take me."

					"Well, perhaps it shall now get thee hence.  Good evening, ${sir}."

					"Good evening, senator."  
					*goto end_coffin
		*if discretion < 50
			*selectable_if (independence < 60) #I leave.  I want no part of the machinations in which these bloodsuckers participate.
				*set independence %-10
				*if stealth > 2
					You make a hasty exit from the event.  It is almost as though you were never there.
					*if invitation_to_reception_accepted
						*finish Next
					*else
						*page_break
						*goto_scene memphis_1873_plague
				*else
					*set lockridge_rapport %-5
					*set met_lockridge true
					*if (speaks_english = false) and (speaks_french = false)
						*goto failure_to_communicate_lockridge
					"Rude, isn't it, to take your leave of a celebration without giving thanks to your host?"
					
					"I'm sorry?"
					
					"As a guest, do you not think it proper to introduce yourself to your host?"
					
					"I didn't realize you had organized this event."

					He frowns at you, before proceeding to introduce himself.
					*goto meet_charleston
		*selectable_if (charm > 1) #I do my best to simply enjoy the party.
			*set independence %-5
			Unfortunately, most other vampires cannot resist the urge to meddle in the affairs of others of their kind.

			Before too long, you can no longer politely ignore the indications from the dour Puritan.  Sighing to yourself, you make your way towards her.
			*goto meet_cincinnati
*else
	You scan the crowd, attempting to identify someone that suits your tastes.  There are several individuals, in fact, from whom you would like to feed…
	
	*if speaks_english or speaks_french
		A gentleman approaches you, addressing you in the lilt of the Carolinas.  "Rude, isn't it, to partake in a celebration without even greeting your host?"
						
		"I'm sorry?"
		
		"As a guest, do you not think it proper to introduce yourself to your host?"
		
		"I didn't realize you had organized this event."

		He frowns at you, before proceeding to introduce himself.
		*goto meet_charleston
	*else
		A gentleman approaches you, his vowels drawn out in the style of the South.
		*goto failure_to_communicate_lockridge

*label end_coffin
*if speaks_english = false
	At that, the voice of Senator Coffin fades from your mind.  You shake your head, trying to rid any last vestiges that may remain.  "What other miracles might we be capable of?" you wonder.
*if (coffin_rapport > 55) and speaks_english
	*set coffin_contactable true
	You turn to leave, but as you do, a man interjects.  Dressed in a similarly antiquated fashion to the Senator, he wordlessly hands you a calling card.  "Should thou need to contact me in the future, ${mr} ${surname}."  You thank her, and then depart.

	You make your way to your haven, still unfed.
	*page_break
	*goto resolve_end
*else
	With that, you take your leave of the church event.  You make your way to your haven, still unfed.
	*page_break
	*goto resolve_end

*label failure_to_communicate_lockridge
*set lockridge_rapport %-10
The gentleman is clearly displeased at the lack of a common tongue between the two of you.  He grasps your wrist, and you are shocked by how cold it is; evidently, he is like you.

After some basic pantomimes, you're able to learn that his name is Arthur Lockridge, but you can glean little more from him.  The "conversation" soon ends.
*set heard_of_lockridge true
*set met_lockridge true
*goto resolve_end

*label vessels_coffin
This exchange concluded, you find yourself with an opportunity to ask her a question.
*choice
	#"Tell me, Senator, are you familiar with any of the candidates in the election?"
		*set independence %+5
		*set questions +1
		*set heard_of_lesczynski true
		*set knows_coffin_anti_semitic true
		"Mr. Lesczynski passed through Cincinnati recently.  Though there was no formal announcement of such—as it would be crass—I expect that he was seeking to garner my support.  He lavished several gifts upon me."

		"And what did you think of him?"

		"He is a Jew.  What more need be said?"

		*if (religious_tradition = "pagan") and (discretion >= 40)
			*set coffin_rapport %-10
			"I suppose you cannot hang that particular albatross around my neck."
			
			"Excuse me?"
			
			"I can't imagine what you must think of my people and their faith."
			
			Coffin looks down her nose at you.  "Barbarians.  Your people have already been chased across the Mississippi.  It will not be long before the last of you has been hunted down and exterminated."
			
			"I appreciate your candor, Senator," you say, before excusing yourself.
			*goto end_coffin
		*elsif priest and (discretion > 35)
			*set coffin_rapport %-10
			"I suspect that you would also be disappointed were I to be elected?"
			
			She glances down to your priest's collar and then meets your eyes again.  "Better a papist than a Jew, I suppose" she muses aloud.
			
			"Thank you for that vote of confidence, Senator," you say, before excusing yourself.
			*goto end_coffin
		*elseif (religious_tradition != "pagan") and ((rationalism > 65) and (compassion < 35))
			*set coffin_rapport %+10
			"A Christkiller must not be allowed to take a seat in the Senate!"

			"Unfortunately, it would not be the first time such had occurred, but I do appreciate thy sentiments, ${mr} ${surname}."

			"Whatever I can do to aide you in preventing this…"

			"I may very well accept thine offer, ${mr} ${surname}."

			"I am at your service, Senator."

			"Until tomorrow, then?"

			"Yes, until then."
			*set offer_to_help_coffin_stop_ascher true
			*goto end_coffin
		*elseif (rationalism < 50) and ((discretion > 50) and (compassion < 50))
			*set coffin_rapport %-10
			"You say that as though it should disqualify him for the position, Senator."

			"As well it should."

			"For practicing a different faith?"

			"For bearing the blood of the Christ on his hands."

			"But, he does not…"

			"His people put Our Lord to death.  All of their kind bear the responsibility for that crime.  If thou canst not recognize that, I am afraid we have nothing more to discuss."

			"Then I suppose I should bid you goodnight, Senator."

			"Yes, good night."  
			*goto end_coffin
		*elseif discretion < 40
			*set coffin_rapport %+2
			"And it would be disastrous were a Jew to join the Senate?" you venture.

			"Unfortunately, if has happened before.  But I am loath to see it happen again."

			"Well, I appreciate your insight into this."

			"The night slips through my fingers.  I am afraid thou must excuse me."

			"Of course, Senator."
			*goto end_coffin
		*else
			"I see."

			Abigail seems to catch herself before embarking upon a rant.  "I suppose thou shalt see for thyself on the morrow."

			"I expect that I shall.  Good night, Senator."
			*goto end_coffin
	#"I notice that we are not alone here."
		*set heard_of_lockridge true
		*set questions +1
		"Thou refers to Senator Lockridge?"

		"The gentleman in the corner?"

		"The very same.  He organized this fundraiser for the church.  Though he and I may not always see eye-to-eye, we do have certain sentiments in common."

		"Ought I to introduce myself?"

		"That is quite alright, ${mr} ${surname}.  I shall be sure to convey thy gratitude to the Senator from Charleston."

		"I am in your debt, Senator," you reply with a ${bow}.
		*goto end_coffin
	*if status > 1
		*selectable_if (discretion > 30) #"I am surprised that you have not heard of me, Senator.  My deeds are hardly unknown."
			*set discretion %+10
			*set questions +1
			"Oh?  Thou art that ${given_name} ${surname}?  Progeny of ${sire_name}?

			"The very same."

			*if exiled_from_new_orleans
				"I have heard tell of thine expulsion from the bower of thy youth.  I believe that I ended any concerns with thee at that moment."

				You bow your head in shame at the events that transpired in New Orleans.  "Yes, well, I have clearly recovered since those nights."

				"I imagine this week shall be the judge of that."

				"No doubt, Senator."

				"Now, if you will excuse me…"

				"Yes, of course."  
				*goto end_coffin
			*elseif jesse_embarrassed and jesse_is_broodmate
				"Yes, I heard the tale of thy betrayal of thy broodmate."

				*if lied_to_jesse_about_poem
					*set coffin_rapport %-5
					"My betrayal?  I thought that matter settled.  I had nothing to do with it!  Samantha's deeds were her own."

					"So I see."

					"I hope you understand my sensitivity to this affair.  My dear brother Jesse has had a hard enough time of it.  Were he to hear such libel spread…it would only inflame old wounds."

					"Yes, of course, ${mr} ${surname}."

					"Now, I believe that I should be going."

					"Yes, it seems that way."

					"Good night, Senator," you conclude, seeking a hasty exit.  
					*goto end_coffin
				*elseif compassion < 40
					*set coffin_rapport %+15
					"He sought to humiliate Ms. Withers.  I simply forewarned her of her predicament."

					"That was very… human of thee, ${mr} ${surname}."

					"Our condition does not require that we become animals, Senator."

					For the first time this evening, you think you see the hint of a smile on Abigail's face.  "Thou speaks truly.  I sense little in the way of deceit in thy heart.  Perhaps we might continue this conversation at the reception tomorrow evening?"

					"Yes, that would please me."

					"Until then."

					"Until then, Senator."  
					*goto end_coffin
				*else
					"That was a youthful error in judgment.  I have sent sought the forgiveness of my dear broodmate."

					"And has he granted such?"

					"I fear it will be some time yet before the matter is fully put aside."

					"No doubt.  Now, if you will excuse me…"

					"Of course, Senator."  
					*goto end_coffin
			*elseif sire_name = "Padre Carlos"
				*set coffin_rapport %-10
				"The new Praetor no doubt finds himself occupied with the obligations of his office.  Hast thou communicated with him?"

				"As you say, he is very busy with his new obligations."

				"I have never met the individual, but then again, as long as he holds this office, I hope I will not have to."

				"I hope, for your sake, the same."

				"Well, if thou wouldst excuse me, ${mr} ${surname}, the night progresses rapidly, and I'm sure thou hast other obligations before the rising of the sun." 

				"Good night, Senator."

				"And to you, ${mr} ${surname}."  
				*goto end_coffin
			*elseif patricide
				"Yes, where is your dominus, little one?"

				"I… I cannot say.  He abandoned me at my making," you stammer.
				*if speaks_english = false
					*set coffin_knows_of_patricide true
					Can she hear your thoughts?  What if she knows?  Will she denounce you?
				*comment endif

				"Of course he did.  It is interesting that there has been no word of him since then, isn't it?"

				*if lore > 1
					"Perhaps he laid himself down to rest."

					"Yes, perhaps."  She observes.
				*if lore <= 1
					"It is interesting."

				*comment endif
				"Now, if thou would excuse me, the night slips through my fingers."

				"Yes, of course, Senator." 
				*goto end_coffin
			*else
				"I heard tell of thine existence, but have heard little else."

				"But… I…"

				"It is no matter.  I am sure thou shalt have the opportunity to make thy mark upon the Society this week.  Though, I do expect many others to seek to do the same."

				"Yes, of course."

				"Now, if thou wouldst excuse me."

				"Of course, Senator."  
				*goto end_coffin

*label arrive_children
*set met_chiara true
Nearing the home of one of your regular hosts, you discover that you are apparently not the first customer of the evening; the father of the household stands at his door, seemingly in the midst of a transaction with someone you do not recognize.  You find yourself tempted to tear this pedophile into shreds for coming between you and your food, when you realize that the stranger is a woman.
*if perception > 2
	And not just any woman, but one of your kind.
*if perception > 3
	Moreover, you can see clearly that she is aware of your presence.
*else
	If she is aware of your presence, she does not show it.

Hesitating a moment, you ponder your next course of action.
*choice
	*if perception > 2
		*selectable_if (discretion > 40) #I approach this strange vampire, and demand to know her identity.
			*set discretion %+5
			"Pardon me, ma'am, but I am afraid that I do not have the pleasure of your acquaintance."

			She looks from you to the father and back. "If you will allow me—" she begins, before turning and whispering something to the man. He nods and retreats inside. She turns back to you, a smile upon her face.
	*if perception > 2
		*selectable_if (independence > 40) #I approach this strange vampire, and demand to know whether she has a right to feed in this city.
			*set independence %+5
			"Excuse me, ma'am," you begin. She looks over her shoulder, spies you, says something to the father who retreats inside, and then turns to introduce herself.
	*if perception <= 2
		*selectable_if (discretion > 40) #I continue my approach.  Whatever the stranger's dealings with the father, it has no bearing on me.
			*set discretion %+5
			"Good evening," you say to the father.

			The stranger turns and looks at you. "Oh!"

			"Oh?" you reply.

			She looks from you to the father and back. "One moment," she says. She turns and whispers something to the father, who retreats inside. Witnesses removed, she introduces herself.
	*selectable_if (discretion < 60) #I will find some other prey for the evening.
		*set discretion %-5
		*if stealth > 2
			You are able to turn away before she takes note of you.

			You call upon another of your regulars, and then return to your haven unperturbed.
			*goto resolve_end
		*else
			Unfortunately, she has already noticed you.  She dismisses the father and introduces herself before you can formulate and execute an escape plan.

"I am Chiara Santagostino…"
*set memphis_chance_encounter "chiara"
*if heard_of_chiara_santagostino

	"…the Senator of New Orleans.  Yes, I have heard of you."

	"And may I have the pleasure of your acquaintance?"

	"I am ${given_name} ${surname}."

	*if (sire_name = "West") and patricide
		*set rumors_of_west_dead true
		"You are the offspring of the beast?"
		
		"I am.  What of it?"
		
		"Have you not heard?"
		
		"Heard what?"
		
		*gosub rumors_of_west
	*elseif avoided_new_orleans and sire_alive
		*if sire_name = "West"
			*label chiara_speaks_of_west
			*set rumors_of_west true
			*if status > 2
				"You are the offspring of the beast?"
				
				"I am."
				
				"But, you are an upstanding member of the Society!"
				
				"I am my own vampire."
				
				"So I see."
				
				"Tell me, is there any news of him?"
				*gosub rumors_of_west
			*else
				"I cannot, then, say the same of you."

				"That does not surprise me.  Most of the past few decades I have spent in Vicksburg."

				"And your dominus?"

				"West."

				"I have heard of that beast.  It makes more sense now, that I would not have heard of you."

				@{(sire_rapport > 40) You do your best not to bristle at this dismal of your maker.|You shrug off this barb; after all, you hold your maker in little esteem.} "But what of him?" you manage to whisper.
				*gosub rumors_of_west
		*else
			"It seems that a reputation proceeds both of us.  Your dominus has spoken often of you in your absence."

			"Truly?  I would have thought he had forgotten me by now."

			"By no means, ${mr} ${surname}, by no means."
			*if priest
				Eyeing your collar and cassock, she continues: "He did not mention that you were a man of the cloth, however."
				
				*if (sires_faith = "faithful") and (sire_religious_tradition = "catholic")
					"I think he wishes to forget.  His turning of a priest was always something of a sin in his eyes."
					
					She seems to give this some consideration.
				*elseif (sires_faith = "faithful")
					"I think he was disappointed that I never willing to trade the cassock for the Geneva gown."
					
					"It is surprising that he would turn a priest instead of a minister," she replies.
				*else
					"Clearly it was of little importance to him."
					
					"I would hazard that he has become no more faithful in your absence."
					
					"That does not surprise me, Senator."
	*elseif exiled_from_new_orleans
		"I have heard of your exploits."

		"Oh?"

		"Of course.  Your departure is the stuff of legend.  We seldom have such unequivocal displays of idiocy."
		*if discretion > 70
			*if willpower > 3
				*label bristle

				You feel the animal inside you rise at this barb, but you manage to hold it tight.  Clenching your teeth, you think it best to change the subject.
			*else
				*set santagostino_rapport %-30
				*set frenzied_on_santagostino true
				You cannot handle this effrontery.  Your vision goes red, and your fangs extend.

				For a brief moment, you see a hint of fear in Santagostino's eyes.  But as you charge towards her, her eyes grow cold as ice, and you feel yourself slowing.  Your anger continues to boil inside you, but all you can do is gnash your teeth in impotent rage.

				Eventually, you calm down.  Finally, Santagostino relaxes her features, and you feel yourself free to move again.

				"Get out of my sight, you pathetic excuse for a vampire."

				Crushed, you slink back to your haven.
				*goto resolve_end
		*elseif discretion > 50
			*goto bristle
		*else

			*if charm > 2
				"I am glad to hear that they are still talking about me.  The worst would be if I had simply been forgotten."

				"No chance of that, ${mr} ${surname}.  No chance of that."
			*else
				"Do you often go about insulting people so?"

				"When they deserve it, yes."

				Gritting your teeth at her effrontery, you think it best to change the subject.
	*else
		*if sire_name = "West"
			*goto chiara_speaks_of_west
		"Ah, yes.
		*if sire_formerly_quaestor
			Your dominus spoke regularly of you, before his departure." 
		*else
			Your dominus speaks regularly of you." 

		*if sire_rapport > 60
			"I should hope so.  I do hold him in the highest esteem."

			"As he does you."
		*elseif sire_rapport >= 40
			"That is interesting.  I did not know I rated so highly in his esteem."

			"His remarks are ambivalent.  Sometimes he praises you and your accomplishments, other times he seems to think that you betrayed him."

			"He is fickle like that."

			"Yes, so he is."
		*else
			"I find that surprising."

			"I did not say that he spoke highly of you."

			"No, I suppose not," you reply with a grimace.

	"I assume that you are here for the election, Senator?"
	
	"I am."
	*label question_santagostino_loop
	*choice
		*if learn_of_jesses_presence_in_memphis
			#"Do you think Jesse@{jesse_is_broodmate | Whitaker} has the necessary support to win the election?"
				*set questions +1
				"I cannot say for certain.  There are actors in this drama, and I am not aware of all their parts."
	
				"But you will support him?"
	
				"Yes, I shall make some effort on his behalf."
		*if just_heard_of_chiara = false
			#"How long have you been Senator of New Orleans?"
				*set questions +1
				"I was elected in 1844.  The Quaestor was most generous with his support of my candidacy."
		
				"I am glad to hear it."
		
				"I did not expect to win the title, but things fell into place."
		#"Do you know any of the other candidates?"
			*set questions +1
			*set heard_of_pickering true
			"I have heard that a citizen of Birmingham, Pickering by name, will be seeking the title."
	
			"What do you know of this vampire?"
	
			"I believe he opposes Stone's revolution.  He seeks to heal the schism in the Society."
		*selectable_if (discretion > 30) #"Do you usually feed upon the innocent?"
			*set discretion %+10
			*set santagostino_rapport %+5
			*set questions +1
			She looks at you askance, surprised by the candor of your question.  "I suppose that I do.  Do you?"
			
			"Yes, usually.  And what draws you to them?"
			
			Her eyes sparkle a little while she reflects upon some memory.  "It reminds me—for just a moment—of what I was like before…"
			
			"Before what?"
			
			"Before becoming a vampire.  Before I had to drink from children to sleep in peace." @{(questions > 1) You open your mouth to ask enough question, but she speaks first.|}
		*if maddox_status = "dead"
			#"Did you come to Memphis alone?"
				*set questions +1
				*set knows_santagostino_seeks_gallagher true
				"I brought a valet, but no other members of the Society accompany me, if that is what you mean."
	
				"Yes, of course."
	
				"Though, it is strange that you should ask, as I am supposed to keep an eye out for a vampire who passed through New Orleans some time ago, an Irishman by the name of Hugh Gallagher."
	
				*if met_hugh_in_Vicksburg
					Your eyes widen in surprise.  "Why, I met such a man, at the docks of Vicksburg."
	
					"How long ago?"
	
					"It was sometime this spring, not long before I came to Memphis."
	
					"Did you shake his hand?"
	
					"I did not.  He did not come ashore, lest he violate the Rule of Respect."
	
					Santagostino chuckles at this.  "The Rule of Respect," she mutters.
	
					"What does ${new_orleans_quaestor_address} seek of him?"
	
					"He wishes to ask a few questions of him.  Tell me, were his eyes watery, when you saw him?"
	
					"In fact, they were.  I thought little of it at the time."
	
					"I would be surprised if it were otherwise."
				*else
					*set heard_of_gallagher true
					"Why do you seek him?"
	
					"It is nothing terribly important, but ${new_orleans_quaestor_address} wishes words with him."
	*if questions <= 1
		She pauses at this, leaving you the opportunity to ask another question.
		*goto question_santagostino_loop
*else
	*if discretion > 60
		*set santagostino_rapport %-5

		"Is that supposed to mean something to me?  Unless I am mistaken, you are not permitted to feed here."

		"I am here for the election, you whelp.  And as a visiting Senator, I suggest you not interfere in my business."

		*if invitation_to_reception_accepted
			"Visiting from where?"

			Her eyes flash in anger at your presumptuousness.  "From New Orleans."
		*else
			*set learned_of_reception true
			"Senator?"
			
			"Yes.  I am the Senator of New Orleans, here for the election."

			"What election?"

			"Are you ignorant as well as rude?  The election of a senator for Memphis."
	*elseif discretion >= 40
		*set just_heard_of_chiara true
		She pauses a moment, as though expecting something.

		"I'm afraid I am unacquainted with that name."

		"I see.  Well, a few decades before the war, I was elected Senator of New Orleans."
	*else
		In the pause after her words, you wonder if that is supposed to mean something to you.  You look at her, trying not to disclose your ignorance.  "…the Senator of New Orleans," she concludes.

		"A pleasure to meet you, Senator."  She nods at this.
	*if avoided_new_orleans
		*if patricide
			*if met_jesse and (sire_name != "Pieter van der Velde")
				*set learn_of_jesses_presence_in_memphis true
				"I have not been to that city since being granted immortality.  Tell me, does Quaestor Van der Velde still hold his title?"

				"He does."

				"Yes, he sent his progeny, Jesse, to visit me while I resided in St. Charles Parish."

				"Yes, Mr. Whitaker still resides there.  Though, I believe he will be here in Memphis, seeking the title of Senator."
				*gosub chiara_alerts_pc_reception

				"@{learned_of_reception And so Whitaker|He} puts himself forward for the position?"

				"He does."
			*elseif met_jesse and (sire_name = "Pieter van der Velde")
				*set learn_of_jesses_presence_in_memphis true
				"I have not been to that city since being granted immortality.  Tell me, does Quaestor Villanueva still hold his title?"

				"He does."

				"Yes, he sent his progeny, Jesse, to visit me while I resided in St. Charles Parish."

				"Yes, Mr. Whitaker still resides there.  Though, I believe he will be here in Memphis, seeking the title of Senator."
				*gosub chiara_alerts_pc_reception

				"@{learned_of_reception And so Whitaker|He} puts himself forward for the position?"

				"He does."
			*elseif (met_jesse = false) and (sire_name != "Pieter van der Velde")
				"I have not been to that city since being granted immortality.  Tell me, does Quaestor Van der Velde still hold his title?"

				"He does."

				"Yes, he sent one of his citizens, a Castillian by the name of Estefania Rios, to visit me while I resided in St. Charles Parish."

				"I had the pleasure of her acquaintance, but she left the city once the war was over."
			*else
				"I have not been to that city since being granted immortality.  Tell me, does Quaestor Villanueva still hold his title?"

				"He does."

				"Yes, he sent one of his citizens, a Castillian by the name of Estefania Rios, to visit me while I resided in St. Charles Parish."

				"I had the pleasure of knowing the Quaestor's broodmate, but she left the city once the war was over."
		*else
			*if sire_name = "Pieter van der Velde"
				"And does my dominus, Van der Velde, still hold sway there?"  

				"In fact, he does.  If he is your dominus, then I deduce that you must be ${mr} ${surname}."

				"The very same, ma'am."

				"The Quaestor regrets the intransigence with which you have treated him."

				"I am what he made me."

				"Well, I am certainly not here as his messenger."

				"I am glad to hear it.  He sent my broodmate, a Mr. Whitaker, to convey his wishes to me in the parish, but I have heard little from him since."

				"Yes, Mr. Whitaker is quite the character."
			*elseif sire_name = "Padre Carlos"
				*set santagostino_rapport %+5
				"And what of my dominus, Padre Carlos?"

				"When he was elevated to the position of Praetor, he left the city to fulfill his new duties.  I have heard little of him since."  She pauses a moment, clearing her throat.

				"Oh, of course.  My apologies.  My name is ${given_name} ${surname}, offspring of Padre Carlos."

				"I see.  Your maker is honored by the Consul with his new position."
			*elseif sire_name = "West"
				"Tell me, what have you heard of my dominus?"

				Chiara snorts.  "I heard that he went north some time ago.  Word of him was scarce enough before he created you; since then, it has become nonexistent."
			*else
				"Tell me, what have you heard of my dominus, since this Van der Velde replaced him?" 

				"I have heard little.  I was barely acquainted with him before departure."
	*label question_santagostino_ignorant
	*choice
		*if invitation_to_reception_accepted or learned_of_reception
			*if learn_of_jesses_presence_in_memphis
				#"@{jesse_is_broodmate Do you think my broodmate, Jesse Whitaker,|Do you think Jesse Whitaker} has the necessary support to win the election?"
					*set questions +1
					"I cannot say for certain.  There are actors in this drama, and I am not aware of all their parts."
	
					"But you will support him?"
	
					"Yes, I shall make some effort on his behalf." 
			#"Do you know any of the other candidates?"
				*set questions +1
				*set heard_of_pickering true
				"I have heard that a citizen of Birmingham, Pickering by name, will be seeking the title."
	
				"What do you know of this vampire?"
	
				"I believe he opposes Stone's revolution.  He is a strong supporter of a healing of the schism in the Society."
		*else
			#"Why are you in Memphis?"
				*set questions +1
				*set learned_of_reception true
				*set independence %+5
				*set santagostino_rapport %-5
				She looks at you queerly. "For the election, of course."
				
				"Election?"
	
				"You reside here, in Memphis, yes?"
				
				"I do."
				
				"And you are unaware of the impending arrival of senators from across the continent to grant Memphis the honor of hosting one of our number?" 
				*set learned_of_reception true
				
				"I had not heard, no."
		*if just_heard_of_chiara = false
			#"How long have you been Senator of New Orleans?"
				*set questions +1
				"I was elected in 1844.  The Quaestor was most generous with his support of my candidacy."
		
				"I am glad to hear it."
		
				"I did not expect to win the title, but things fell into place."
		*selectable_if (discretion > 30) #"Do you usually feed upon the innocent?"
			*set discretion %+10
			*set santagostino_rapport %+5
			*set questions +1
			She looks at you askance, surprised by the candor of your question.  "I suppose that I do.  Do you?"
			
			"Yes, usually.  And what draws you to them?"
			
			Her eyes sparkle a little while she reflects upon some memory.  "It reminds me—for just a moment—of what I was like before…"
			
			"Before what?"
			
			"Before becoming a vampire.  Before I had to drink from children to sleep in peace."
	*if questions <= 1
		She pauses at this, leaving you the opportunity to ask another question.
		*goto question_santagostino_ignorant

She looks around, noticing the passing of the time. "I'm afraid I must now bid you [i]buona notte[/i].  I still need to feed, lest tomorrow's setting sun find me still famished."

"I understand your need." @{frenzied_on_jesse She allows the faintest hint of a smile cross her lips at this admission on your part, for understand her you most certainly do.|}

*if santagostino_rapport > 55
	*set santagostino_contactable true
	"I look forward to having more time to speak tomorrow evening."

	*if (invitation_to_reception_accepted = false)
		*gosub surprised_by_santagostino
	*else
		"And I with you, Senator."  
	
		"And, if not, here is my calling card.  You can always write to me in New Orleans."
	
		"Thank you."  Your goodbyes made, you turn, and allow her to get back to her business with your prey.  You do your best not to let the matter irk you.
*elseif santagostino_rapport >= 40
	"Until tomorrow evening, then?"

	*if invitation_to_reception_accepted = false
		*gosub surprised_by_santagostino
	*else
		"Until then, Senator."  Your goodbyes made, you turn, and allow her to get back to her business with your prey.  You do your best not to let the matter irk you.
*else
	"Then go."
	
	You grit your teeth, but resist any urges to violence.  "Senator," you say, in place of any sort of farewell.  Turning, you allow her to go back to her business with your vessel.  You do your best not to let the matter irk you.

*label resolve_end
*if rumors_of_plague
	*page_break
	*if (rationalism < 75) or (religious_tradition = "pagan")
		Before lying down for the day, you instruct Franklin to guard himself against exposure to anyone who seems ill.
		*if compassion <= 35
			After all, the thought of him falling ill brings you no end of misery.
		*elseif compassion < 60
			After all, the thought of him falling ill is somewhat distressing, especially were he to infect others of your staff.
		*else
			You cannot afford him falling prey to whatever disease stalks the people of Memphis.
	*else
		Before laying down for the day, you instruct Franklin to pray that the Lord does not strike him down with whatever affliction He has seen fit to cast upon the people of Memphis.  He seems suitably terrified.
*if (invitation_to_reception_accepted = false) and (invitation_reextended = false)
	*if wilson_embraced or wilson_embraced_by_withers
		*set letter_directing_to_stennis true
		*page_break
		You wake up the next evening to find a note waiting for you.
		*goto letter_re_stennis
	*else
		*if learned_of_reception
			*set first_memphis_reception_attended 4
		*goto_scene memphis_1873_plague
*page_break

The sun sets on the far side of the Mississippi.  You pause just a moment before opening your eyes, steeling yourself for the night before you.  Laying there, you consider how you will occupy yourself for the night.  You are hungry,
*if acquiring_vessels = "success"
	but the vessels you acquired should be more than enough to tide you over for the evening.
*elseif acquiring_vessels = "failed"
	but Carothers did state that he would find vessels to feed his guests, despite your failure on that account, so you are not overly worried.
*elseif invitation_to_reception_accepted and (feeding_style = "vegetarian")
	but you had Franklin acquire a piglet for you to consume this evening before departing. Your stomach churns unpleasantly at the thought.
*elseif invitation_to_reception_accepted
	but Carothers did say he was going to acquire the means to feed his guests, so you are not overly worried.
*else
	but thankfully not so hungry as to seriously endanger you in the presence of other vampires.

The reception before the election promises to be quite an event.
*if memphis_reception_planner != "Dido"
	You will attend, of course, considering how much effort you've already put into its organization.
	
	Snapping your eyes open, you slip from your resting place and begin to attend to your toilette.
	*finish Next
*choice
	*if chasing_wilson
		#Really, I should be out looking for ${wilson}, not dallying with others of my kind.
			*set independence %-5
	*if chasing_wilson and (invitation_to_reception_accepted or invitation_reextended)
		#Perhaps I can learn something of ${wilson}'s whereabouts at the reception?
			*set independence %+5
			Snapping your eyes open, you slip from your resting place and begin to attend to your toilette.
			*goto_scene memphis_1873_reception
	*if invitation_to_reception_accepted
		#I attend the reception, as I promised.
			*set independence %+5
			Snapping your eyes open, you slip from your resting place and begin to attend to your toilette.
			*goto_scene memphis_1873_reception
	*if invitation_reextended
		#I think perhaps I ought to attend this affair.  Maybe that was what Carothers wanted to speak of last week?
			*set independence %+10
			Snapping your eyes open, you slip from your resting place and begin to attend to your toilette.
			
			*goto_scene memphis_1873_reception
	*if invitation_to_reception_accepted or invitation_reextended
		*selectable_if (independence < 60) #I want nothing to do with that pit of vipers.
			*set independence %-20
	*else
		#Too many vampires make my skin crawl.  I will lie low until these visitors clear out.
			*set independence %-5
	*if learned_of_reception and ((invitation_to_reception_accepted = false) and (invitation_reextended = false))
		#Perhaps I should make an unannounced appearance at this event.  After all, everyone will be there.
			*set independence %+10
			*set discretion %+10
			Snapping your eyes open, you slip from your resting place and begin to attend to your toilette.
			
			It takes a little deduction, but it is easy enough for you discover the location of the reception.  You may be late, but what of it?
			*finish Next

*if wilson_embraced or wilson_embraced_by_withers
	*set letter_directing_to_stennis true
	You wake up on the evening of the election to find a note waiting for you.
	*label letter_re_stennis
	*if literate
		Unfolding it, you scan the lines quickly. Stennis, one of the individuals @{wilson_lately Franklin hired|you hired years ago} to keep an eye out for ${wilson}, claims to have spotted him.
	*else
		You pass it to Franklin, and @{(compassion < 40) ask|order} him to read it aloud.  Stennis, @{wilson_lately one of the men Franklin recently hired|a man you hired several years ago} to keep an eye out for ${wilson}, claims to have spotted your quarry.

	Intrigued, you dress yourself and head towards the Pinch.
	*page_break
*if learned_of_reception
	*set first_memphis_reception_attended 4
*goto_scene memphis_1873_plague

*label rumors_of_west
"There are rumors that he has been driven mad."

"Mad?" @{rumors_of_west_dead Mad?  What mischief is this?  You burned him to ash yourself!|}

"Alas, I know little else.  Perhaps he has simply been more removed from the Society than is typical?"

"Perhaps," you reply, you world aflutter at this intelligence.
*return

*label surprised_by_santagostino
*set learned_of_reception true
*set santagostino_rapport %-10
"Tomorrow evening?"

She looks at you in surprise.  "Of course.  The reception, for the election.  Tomorrow evening…" she finishes, mentioning the location.

"Of course, the reception…" you reply, playing down your ignorance.

She looks at you, still suspicious, but other duties call, and she leaves.
*return

*label chiara_alerts_pc_reception

*if invitation_to_reception_accepted = false
	*set santagostino_rapport %-5
	"Seeking the title of Senator?" you ask, blankly.
	
	"At the election," she replies.
	
	"Election?"
	
	Now it is Santagostino's opportunity to look at you blankly.
	
	"You reside here, in Memphis, yes?"
	
	"I do."
	
	"And you are unaware of the impending arrival of senators from across the continent to grant Memphis the honor of hosting one of our number?" You think it best to not to answer this particular question.
	*set learned_of_reception true
*return