*comment ñáéç…—
*hide_reuse
*advertisement
*temp second_betrayal false
*if notice_partridge_betrayal
	*set second_betrayal true
*set notice_partridge_betrayal false
*temp second_goround false
*temp necktie "necktie"
*if male = false
	*set necktie "hat"
*if priest
	*set necktie "collar"
*temp interlocutor "empty"
*temp i_he "he"
*temp interlocutor_introduced false
*temp support_malloy false
*temp support_lesczynski false
*temp support_pickering false
*temp timmers_for_lesczynski false
*temp ask_carothers true
*temp allegiance_inquiry true
*temp equal_attention true
*temp son "son"
*if male = false
	*set son "miss"
*temp support_flip false
*temp curry_favor false
*temp seat_num 3
*temp seat_count "three"
*temp seat_relinquished false
*if player_for_senator
	*set seat_num +1
*if lesczynski_out
	*set seat_num -1
*if malloy_out
	*set seat_num -1
*if pickering_out
	*set seat_num -1
*if seat_num = 2
	*set seat_count "two"
*if seat_num = 4
	*set seat_count "four"
*temp fragala_name 3
*if intelligence > 2
	*set fragala_name 2
*if heard_of_fragala
	*set fragala_name 1

When you wake in the evening, it is with the knowledge that tonight could determine the fate of the Society. @{memphis_affair You check in on Clotho.  She is much the same as before.  She welcomes the attention but soon sends you on your way.|} Taking one final glance at yourself in the mirror, you straighten your ${necktie} and set off into the night.
*gosub allegiance_count
*page_break
*if first_memphis_caucus_attended
	On the way to the caucus, you try to do the math in your head.
	*if met_lockridge
		Lockridge, of course, will support Mr. @{pickering_out Lesczynski|Pickering}.
	*if (simmons_waylaid = false) and (heard_of_simmons)
		Senator Simmons will surely support Mr. @{pickering_out Lesczynski|Pickering} as well.
	*if met_bailey
		Bailey and Partridge will support @{malloy_out Mr. Lesczynski.|Miss Malloy.}
	*if met_chiara
		Chiara Santagostino will surely support @{malloy_out Mr. Lesczynski.|Miss Malloy.} as well.
	*if met_coffin
		You're fairly certain that Senator Coffin would prefer Mr. Pickering.
		*if pickering_out and knows_coffin_anti_semitic
			But with him out of the race and Mr. Lesczynski standing in for the loyalists, she will vote for Miss Malloy instead.
		*if pickering_out and (knows_coffin_anti_semitic = false)
			But with him out of the race, you can only assume that she will cast her vote for Mr. Lesczynski instead.
	*if bowater_determined
		Then there's Senator Bowater.  He has expressed his support for
		*if bowater_revolutionary
			@{malloy_out Mr. Lesczynski.|Miss Malloy.}
		*if bowater_revolutionary = false
			Mr. @{pickering_out Lesczynski|Pickering}.
	*if ashmore_support > 1
		@{ashmore_support |Senator Ashmore was noncommittal about her favorite.|And Senator Ashmore has expressed her clear support for Malloy.|And Senator Ashmore has expressed her tepid support for Lesczynski.|And Senator Ashmore has expressed her clear support for Pickering.}
	But what of the others?
	*page_break
*set second_memphis_caucus_attended true
You arrive at the gathering.  Hermes is waiting outside and helps you out of your coupé.  @{(compassion < 50) Thanking him, you head inside.|Without so much as a nod of acknowledgement, you sweep past him and head inside.}

Entering the building, you find the attendees and their hangers-on milling about, exchanging pleasantries.
*if first_memphis_caucus_attended = false
	*goto check_interlocutor
*else
	You circulate slowly, making the first greetings of the evening.
	*goto room_relocation

*label check_interlocutor
*if (revolutionary_credentials > 60) and ((met_bailey) and ((speaks_english) or (speaks_french)))
	*set interlocutor "Bailey"
*elseif (revolutionary_credentials < 40) and ((speaks_english) and (met_lockridge))
	*set interlocutor "Lockridge"
*elseif (met_ashmore) and ((speaks_english) and (ashmore_rapport > 50))
	*set interlocutor "Ashmore"
	*set i_he "she"
*else
	*set interlocutor "Santagostino"
	*set i_he "she"

*if met_pickering or (heard_of_pickering or pickering_out)
	*goto check_lesczynski
*else
	*set interlocutor_introduced true
	After an hour or so, it seems that most of the guests from the previous evening have arrived.  You find yourself in conversation with ${interlocutor}, who has just inquired as to whether you are acquainted with all of the candidates for Senate.
	
	"You have not yet met Mr. Pickering?"
	*set heard_of_pickering true
	
	"No, I haven't."
	
	"Absalom Pickering, of Mobile.  I would consider him the favored of the candidates, what with the likely support of Coffin, Lockridge, and Simmons."
	*if simmons_waylaid
		You do your best not to signal that anything is amiss with this statement.  "Even with Simmons absent, however, others will come forward."
	*if heard_of_simmons = false
	
		"Simmons?"
	
		"Yes, Charles Simmons.  The Senator from Mobile."
		
		"And he will support Pickering?"
		
		"I would count on it," ${i_he} replies.
	*if simmons_waylaid = false
		You nod, clearly counting the Senators in the room.  $!{i_he} interrupts your calculations.  "Besides those three, others will step forward."

	"Others?"

	*if (interlocutor = "Lockridge") or (interlocutor = "Ashmore")
		"You can count on it."  There is a brief pause while this sinks in.
	*else
		"Yes, so I fear."  There is a brief pause while this sinks in.

*label check_lesczynski
*if lesczynski_out
	*if interlocutor_introduced
		"Curiously, though, Mr. Lesczynski has withdrawn himself from consideration."

		"Withdrawn himself?"

		"Yes.  I only just learned of it myself.  It does make certain things easier, however."

		"I imagine so."
	*else
		After an hour or so, it seems that most of the guests from the previous evening have arrived.  You find yourself in conversation with ${interlocutor}, who has just inquired as to whether you are acquainted with all of the candidates for Senate.  The subject quickly turns to Ascher Lesczynski…

		"You have not heard?  Mr. Lesczynski has withdrawn from consideration."

		"Withdrawn?"

		"Yes, I only just learned of it myself."

		"I am surprised."
*elseif met_lesczynski or heard_of_lesczynski
	*goto check_malloy
*else
	*if interlocutor_introduced

		"There is also Mr. Lesczynski."
		*label identify_lesczynski
		
		*if able_to_identify_jews
			"The Jew?"
			
			"Ah, of course."
		*else
			"I'm sorry?"
			
			"The man with the hat and curls."
			
		"I see.  And who supports him?"
		*set heard_of_lesczynski true

		*if pickering_out
			*if interlocutor = "Lockridge"
				*if simmons_waylaid = false
					Simmons,
				*if ashmore_determined and (ashmore_revolutionary = false)
					Ashmore,
				*if bowater_determined and (bowater_revolutionary = false)
					Bowater,
				Timmers, and of course myself."
			*else
				"Lockridge, 
				*if simmons_waylaid = false
					Simmons,
				*if ashmore_determined and (ashmore_revolutionary = false)
					Ashmore,
				*if bowater_determined and (bowater_revolutionary = false)
					Bowater,
				and perhaps Timmers."
		*if malloy_out
			"Bailey and Partridge will support him.  As will Coffin and
			*if interlocutor = "Santagostino"
				myself."
			*else
				Santagostino."
		*else
			"No one overtly, but he seems like an acceptable compromise candidate," ${i_he} replies.
	*else
		After an hour or so, it seems that most of the guests from the previous evening have arrived.  You find yourself in conversation with ${interlocutor}, who has just inquired as to whether you are acquainted with all of the candidates for Senate.
		
		"You are not acquainted with Mr. Lesczynski?"
		*goto identify_lesczynski

*label check_malloy
*if met_malloy or (heard_of_malloy or malloy_out)
	*goto conclude_introductions
*else
	*if interlocutor_introduced

		"And then there is Siobhan Malloy."
		*label identify_malloy
		
		"The Irishwoman, I presume?"
		*set heard_of_malloy true
		
		"You are correct.  I assume, then, that you have yet to make her acquaintance."
		
		"No, I haven't."
		
		"She has her charms."
		
		"And who supports her?"
		
		"Partridge and Bailey are her most ardent supporters, but they would support whomever will throw in their lot with Stone, I suspect."
		*if heard_of_partridge
		
			"That seems likely," you reply.
		*else
			*set heard_of_partridge true
			*set heard_of_bailey true
			You do your best not to seem bewildered by these new names.
		
		*goto conclude_introductions
	*else
		After an hour or so, it seems that most of the guests from the previous evening have arrived.  You find yourself in conversation with ${interlocutor}, who has just inquired as to whether you are acquainted with all of the candidates for Senate.
		
		"You have not yet met Miss Malloy?" ${i_he} inquires.
		*goto identify_malloy

*label conclude_introductions
*if interlocutor_introduced
	$!{i_he} looks at you with amusement as you look about the room, visibly reviewing what you have just learned.

	"Thank you for this bit of intelligence," you reply graciously.

	"Well, my work here is done," ${i_he} concludes.  You ${bow} in reply.

*label room_relocation
*if first_memphis_caucus_attended
	When the last of the guests have arrived, Dido and Carothers make it known that the adjacent room is ready.  Entering, you see that the room is laid out as before.  The ${seat_count} chairs are waiting ominously for the candidates. @{player_for_senator With some pretense of self-assurance, you take your seat.|}

	The door to the room locks as the last of the valets and other mortal attendants leave the room.  The election has begun.
*if first_memphis_caucus_attended = false

	With the help of Dido, Carothers invites the gathered vampires into an adjacent room, a room soon to be free of even the most loyal human witnesses.  

	The room itself has a sort of informal formality to it.  There are ${seat_count} chairs placed prominently, yet with an artful haphazardness, throughout the room.  Other slightly less ornate chairs are spread purposefully about the room so that everyone can see what everyone else is doing at any given moment.

	One by one, the candidates take their seats; simultaneously, the valets and other mortal attendants take their leave of the room.  Dido shuts the door firmly behind the last of them; the click of the lock is the only announcement that the election has begun.
*page_break
*if first_memphis_caucus_attended
	As before, the first two hours are spent with the guests floating about the room, exchanging introductory pleasantries with the candidates.
*else
	The first two hours consist of each of the Senators speaking with each of the candidates in turn.  
They must show some degree of respect to all involved, after all.  Most of these conversations are relatively short, with some notable exceptions: Lockridge takes a seat by @{pickering_out Lesczynski|Pickering}, and the two fall into some sort of deep discussion. Meanwhile, Bailey and Partridge spend their time in the company of @{malloy_out Lesczynski|Malloy}, doing their best not to look like they're having a good time.  
*if (lesczynski_out = false)
	@{heard_of_coffin Coffin|The woman in Puritan dress} completely ignores Lesczynski,
	*if pickering_out
		preferring instead the company of Siobhan.
	*elseif malloy_out
		instead indicating her support of Pickering.
	*else
		instead indicating her support of Pickering.

*if (davison_waylaid = false) and ((heard_of_davison) or (met_davison))
	Senator Davison is not shy about her support for @{malloy_out Lesczynski|Malloy}.
*if (simmons_waylaid = false) and ((heard_of_simmons) or (met_simmons))
	Senator Simmons @{pickering_out shows his nominal support for Lesczynski but seems rather distressed to be supporting a northerner.|sticks close to his fellow southerners, Pickering and Lockridge.}
*if player_for_senator
	Of course, it is hard to perceive all this from your seat, but you do your best to observe without being seen to show too much interest.
*if player_for_senator = false
	*if compassion < 40
		You wonder idly how warm this room would be, were it not filled with the walking dead.

These proceedings are interrupted by a moan, however, emanating from the next room. Dido looks mortified and rushes in that direction. It seems that one of the vessels managed to issue a cry for help. You see a few snarls from the gathered attendees as beasts rise to the fore.

But then everyone puts their fangs away and returns to the matter at hand. Dido reëmerges a few minutes later—wiping blood from her face with a lavender-colored handkerchief—and joins the crowd.

*choice
	*if player_for_senator
		#I press my candidacy.
			*if (davison_waylaid = false) and (met_davison = false)
				*gosub meet_davison_candidate
				*goto round_two
			*elseif (simmons_waylaid = false) and (met_simmons = false)
				*gosub meet_simmons_candidate
				*goto round_two
			*else
				*if status > 2
					The vampires gather around you, fawning on your words.  Though the seating prevents you from easily making eye contact with the other candidates, you can feel the heat of their fury.

					The room is in utter confusion; the strength of your candidacy has disrupted the carefully orchestrated political calculus.
					*if revolutionary_credentials > 60
						*if malloy_out
							*set lesczynski_rapport %-10
							*set pickering_rapport %-10
							The supporters of Stone are clearly split in their attentions.  Lesczynski's support has almost entirely migrated to you.  Unfortunately, there that shift is not complete, and that leaves Pickering looking like the winner.
							*goto round_two
						*elseif lesczynski_out
							*set malloy_rapport %-10
							*set pickering_rapport %+10
							The supporters of Stone are clearly split in their attentions.  Unfortunately, that leaves Pickering in a very strong position.
							*goto round_two
						*else
							*set lesczynski_rapport %-10
							*set malloy_rapport %-10
							*set pickering_rapport %-10
							With four viable candidates in the race, the gathered attendees are incapable of coming to any sort of consensus.
							*goto round_two
					*elseif revolutionary_credentials >= 40
						*if malloy_out
							*set lesczynski_rapport %-10
							*set pickering_rapport %-10
							Your political agnosticism must be some sort of virtue.  With Lesczynski representing the supporters of Stone, and Pickering those who oppose him, somehow your indifference seems to be winning the room.
							*goto round_two
						*elseif pickering_out
							*set lesczynski_rapport %-10
							*set malloy_rapport %-10
							Your political agnosticism must be some sort of virtue.  With Malloy representing the supporters of Stone, and Lesczynski those who oppose him, somehow your indifference seems to be winning the room.
							*goto round_two
						*elseif lesczynski_out
							*set malloy_rapport %-10
							*set pickering_rapport %-10
							Your political agnosticism must be some sort of virtue.  With Malloy representing the supporters of Stone, and Pickering those who oppose him, somehow your indifference seems to be winning the room.
							*goto round_two
						*else
							*set lesczynski_rapport %-10
							*set malloy_rapport %-10
							*set pickering_rapport %-10
							With four viable candidates in the race, the gathered attendees are incapable of coming to any sort of consensus.
							*goto round_two
					*else
						*if pickering_out
							*set lesczynski_rapport %-10
							*set malloy_rapport %-10
							The opponents of Stone are clearly split in their attentions.  Lesczynski's support has almost entirely migrated to you.  Unfortunately, there that shift is not complete, and that leaves Malloy looking like the winner.
							*goto round_two
						*elseif lesczynski_out
							*set pickering_rapport %-10
							*set malloy_rapport %+10
							The opponents of Stone are clearly split in their attentions.  Unfortunately, that leaves Malloy in a very strong position.
							*goto round_two
						*else
							*set lesczynski_rapport %-10
							*set malloy_rapport %-10
							*set pickering_rapport %-10
							With four viable candidates in the race, the gathered attendees are incapable of coming to any sort of consensus.
							*goto round_two
				*else
					The gathered vampires do their best to ignore you.  Yes, they come and pay their respects as required by tradition, but once their obligations are discharged, they flee your presence, lest their attentions be misconstrued.
					*goto round_two
		#I relinquish my seat.
			*set player_for_senator false
			*set seat_relinquished true
			*set seat_num -1
			*set discretion %-10
			*if revolutionary_credentials > 60
				*set revolutionary_credentials %+10
				*set bailey_rapport %+10
				*set partridge_rapport %+10
				*if malloy_out
					*set lesczynski_rapport %+10
				*if malloy_out = false
					*set malloy_rapport %+10
				Bailey and Partridge are clearly relieved to see you stand.  You begin to circulate through the room; turning back for a brief moment, you notice that your chair is already gone.
				*goto round_two
			*elseif revolutionary_credentials >= 40
				Standing, you move away from your seat.  Someone takes it and puts it to the side of the room.  Otherwise, your gesture seems to go unnoticed.
				*goto round_two
			*else
				*set revolutionary_credentials %-10
				*set lockridge_rapport %+10
				*if pickering_out
					*set lesczynski_rapport %+10
				*if pickering_out = false
					*set pickering_rapport %+10
				Lockridge and his allies are relieved to see you stand.  You begin to circulate through the room; turning back for a brief moment, you notice that your chair is already gone.
				*goto round_two
	*else
		*if (equal_attention) #I spread my attentions among the candidates more or less equally. 
			*gosub support_equally
			*goto round_two
		*if ask_carothers and (notice_partridge_betrayal = false)
			#I ask Carothers how it is that we are at such an impasse again.
				*gosub ask_carothers
				*goto round_two
		*if (lesczynski_out = false) and heard_of_lesczynski
			#I show my support for Lesczynski.
				*set support_lesczynski true
				*if malloy_out
					*if revolutionary_credentials > 60
						*set revolutionary_credentials %+20
						Senators Bailey and Partridge smile benevolently at this display on behalf of their candidate. @{(status > 2) Your standing in the Society does make this gesture noteworthy, despite your not actually having a vote in the matter.|No one else really seems to care.}
						*goto round_two
					*else
						The attendees observe the attention you pay Lesczynski with surprise.  Apparently, this was an unexpected development.
						*set support_flip true
						*set revolutionary_credentials %+40
						*set malloy_rapport %+20
						*set bailey_rapport %+20
						*set partridge_rapport %+20
						*set lockridge_rapport %-30
						*goto round_two
				*elseif pickering_out
					*if revolutionary_credentials < 40
						*set revolutionary_credentials %-20
						Senator Lockridge nods benevolently at this display on behalf of his candidate. @{(status > 2) Your standing in the Society does make this gesture noteworthy, despite your not actually having a vote in the matter.|No one else really seems to care.}
						*goto round_two
					*else
						The attendees observe the attention you pay Lesczynski with surprise.  Apparently, this was an unexpected development.
						*set support_flip true
						*set revolutionary_credentials %-40
						*set lockridge_rapport %+20
						*set bailey_rapport %-20
						*set partridge_rapport %-20
						*set malloy_rapport %-20
						*set lesczynski_rapport %+20		
						*goto round_two
				*else
					With both Malloy and Pickering still in the running, the gathered vampires cannot account for your support of Lesczynski.
					*if status > 2
						Though you cast no official vote, your standing in the Society is not insignificant, and the Senators pause to consider whether there is something afoot of which they are ignorant.

						You smile a secret smile and leave them to their paranoia.
						*goto round_two
					*else
						However, your opinion carries little weight; though they observe you, they are not changed for having done so.
						*goto round_two
		*if (malloy_out = false) and heard_of_malloy
			#I show my support for Malloy.
				*set support_malloy true
				*if revolutionary_credentials > 60
					*set revolutionary_credentials %+20
					Senators Bailey and Partridge smile at you benevolently as you make a display of support for Malloy. @{(status > 2) Your standing in the Society does make this gesture noteworthy, despite your not actually having a vote in the matter.|No one else really seems to care.}
					*goto round_two
				*else
					The other attendees observe the attention you pay Malloy with surprise.  Apparently, this was an unexpected development.
					*set support_flip true
					*set revolutionary_credentials %+40
					*set malloy_rapport %+20
					*set bailey_rapport %+20
					*set partridge_rapport %+20
					*set lockridge_rapport %-30
					*goto round_two
		*if (pickering_out = false) and heard_of_pickering
			#I show my support for Pickering.
				*set support_pickering true
				*if revolutionary_credentials < 40
					*set revolutionary_credentials %-20
					*set lockridge_rapport %+20
					*set pickering_rapport %+15
					Lockridge smiles benevolently at you as you make a display of support for Pickering.
					@{(status > 2) Your standing in the Society does make this gesture noteworthy, despite your not actually having a vote in the matter.|No one else really seems to care.}
					*goto round_two
				*else
					The attendees observe the attention you pay Pickering with surprise.  Apparently, this was an unexpected development.
					*set support_flip true
					*set revolutionary_credentials %-40
					*set lockridge_rapport %+20
					*set bailey_rapport %-20
					*set partridge_rapport %-20
					*set malloy_rapport %-20
					*set pickering_rapport %+20
					*goto round_two
		#I speak with them all equally; no use in throwing my support behind one or the other so early.
			*set discretion %-10
			*if revolutionary_credentials > 60
				*set lockridge_rapport %+5
			*if revolutionary_credentials < 40
				*set bailey_rapport %+5
				*set partridge_rapport %+5
			The three candidates all sit on edge as you approach, doing their best not to show any dismay as you then drift away without committing yourself.  
			
			On the other hand, several of the individuals in the room seem to have taken note of your political savvy.
			*goto round_two
		*if (simmons_waylaid = false) and (heard_of_simmons and (met_simmons = false))
			#I take the opportunity to introduce myself to the elusive Senator Simmons.
				*gosub meet_simmons
				*goto round_two
		*if (timmers_on_heresy_of_abraham) and (timmers_details_on_abraham = false)
			#I seek out Senator Timmers and press him for more details on the Children of Abraham.
				*gosub timmers_on_abraham
				*goto round_two
	*if (heresy_of_abraham > 0) and (timmers_on_heresy_of_abraham = false)
		#I use the hand-signal taught to me by Estefania, in the hopes that someone here can tell me more of the Children of Abraham.
			*gosub signal_abraham
			*goto round_two
	*if (heresy_of_masons > 0) and (mason_sign_in_memphis = false)
		#I use the hand-signal of the Masons, in the hopes of finding another member of the Order.
			*gosub signal_masons
			*goto round_two
	*if (met_fragala = false) #I introduce myself to @{fragala_name Fragalà|the leper|the disfigured man}.
		*gosub fragala_intro
		*gosub_scene memphis_1877_reception speak_fragala
		*goto round_two
		
		*label fragala_intro
		*set heard_of_fragala true
		*set met_fragala true
		"Good evening," you say, approaching the man.
		
		He smiles as you approach. The flesh on his face ripples with the effort. "And to you, ${mr} ${surname}, I presume?"
		
		"You have me at a disadvantage, sir."
		
		"Calogero Fragalà," he replies.
		*return

*label round_two
*gosub allegiance_count_during
*page_break
*temp rc
*set rc "zero"
*temp crc
*set crc "zero"
*if r_count = 3
	*set rc "three"
*if cr_count = 3
	*set crc "three"
*if r_count = 4
	*set rc "four"
*if cr_count = 4
	*set crc "four"
*if r_count = 5
	*set rc "five"
*if cr_count = 5
	*set crc "five"
Looking around the room, there are clearly ${rc} Senators supporting @{malloy_out Lesczynski|Malloy}, and ${crc} Senators supporting @{pickering_out Lesczynski|Pickering}. @{bowater_for_player Bowater, on the other hand, supports you.|}

A clock strikes one.  The gathered attendees redouble their efforts to secure victory for their side.
*gosub partridge_betrayal
*choice
	*if player_for_senator
		#I press my candidacy.
			*if (davison_waylaid = false) and (met_davison = false)
				*gosub meet_davison_candidate
				*goto round_three
			*elseif (simmons_waylaid = false) and (met_simmons = false)
				*gosub meet_simmons_candidate
				*goto round_three
			*else
				*if status > 2
					The vampires gather around you, fawning on your words.  Though the seating prevents you from easily making eye contact with the other candidates, you can feel the heat of their fury.

					The room is in utter confusion; the strength of your candidacy has disrupted the carefully orchestrated political calculus.
					*if revolutionary_credentials > 60
						*if malloy_out
							*set lesczynski_rapport %-10
							*set pickering_rapport %-10
							The supporters of Stone are clearly split in their attentions.  Lesczynski's support has almost entirely migrated to you.  Unfortunately, there that shift is not complete, and that leaves Pickering looking like the winner.
							*goto round_three
						*elseif lesczynski_out
							*set malloy_rapport %-10
							*set pickering_rapport %+10
							The supporters of Stone are clearly split in their attentions.  Unfortunately, that leaves Pickering in a very strong position.
							*goto round_three
						*else
							*set lesczynski_rapport %-10
							*set malloy_rapport %-10
							*set pickering_rapport %-10
							With four viable candidates in the race, the gathered attendees are incapable of coming to any sort of consensus.
							*goto round_three
					*elseif revolutionary_credentials >= 40
						*if malloy_out
							*set lesczynski_rapport %-10
							*set pickering_rapport %-10
							Your political agnosticism must be some sort of virtue.  With Lesczynski representing the supporters of Stone, and Pickering those who oppose him, somehow your indifference seems to be winning the room.
							*goto round_three
						*elseif pickering_out
							*set lesczynski_rapport %-10
							*set malloy_rapport %-10
							Your political agnosticism must be some sort of virtue.  With Malloy representing the supporters of Stone, and Lesczynski those who oppose him, somehow your indifference seems to be winning the room.
							*goto round_three
						*elseif lesczynski_out
							*set malloy_rapport %-10
							*set pickering_rapport %-10
							Your political agnosticism must be some sort of virtue.  With Malloy representing the supporters of Stone, and Pickering those who oppose him, somehow your indifference seems to be winning the room.
							*goto round_three
						*else
							*set lesczynski_rapport %-10
							*set malloy_rapport %-10
							*set pickering_rapport %-10
							With four viable candidates in the race, the gathered attendees are incapable of coming to any sort of consensus.
							*goto round_three
					*else
						*if pickering_out
							*set lesczynski_rapport %-10
							*set malloy_rapport %-10
							The opponents of Stone are clearly split in their attentions.  Lesczynski's support has almost entirely migrated to you.  Unfortunately, there that shift is not complete, and that leaves Malloy looking like the winner.
							*goto round_three
						*elseif lesczynski_out
							*set pickering_rapport %-10
							*set malloy_rapport %+10
							The opponents of Stone are clearly split in their attentions.  Unfortunately, that leaves Malloy in a very strong position.
							*goto round_three
						*else
							*set lesczynski_rapport %-10
							*set malloy_rapport %-10
							*set pickering_rapport %-10
							With four viable candidates in the race, the gathered attendees are incapable of coming to any sort of consensus.
							*goto round_three
				*else
					The gathered vampires do their best to ignore you.  Yes, they come and pay their respects as required by tradition, but once their obligations are discharged, they flee your presence, lest their attentions be misconstrued.
					*goto round_three
		#I relinquish my seat.
			*set player_for_senator false
			*set seat_relinquished true
			*set seat_num -1
			*set discretion %-10
			*if revolutionary_credentials > 60
				Bailey and Partridge are clearly relieved to see you stand.  You begin to circulate through the room; turning back for a brief moment, you notice that your chair is already gone.
				*goto round_three
			*elseif revolutionary_credentials >= 40
				Standing, you move away from your seat.  Someone takes it and puts it to the side of the room.  Otherwise, you gesture seems to go unnoticed.
				*goto round_three
			*else
				Lockridge and his allies are relieved to see you stand.  You begin to circulate through the room; turning back for a brief moment, you notice that your chair is already gone.
				*goto round_three
	*else
		*if (equal_attention) #I spread my attentions among the candidates more or less equally. 
			*gosub support_equally
			*goto round_three
		*if ask_carothers and (notice_partridge_betrayal = false)
			#I ask Carothers how it is that we are at such an impasse again.
				*gosub ask_carothers
				*goto round_three
		*if (heard_of_memeskia = false) and (ask_carothers = false)
			*selectable_if (speaks_english) #I want to ask Senator Bailey about St. Louis.  What is it like?
				*gosub bailey_on_st_louis
				*goto round_three
		*if support_flip and (curry_favor = false)
			#I attempt to curry favor with my new allies.
				*set curry_favor true
				*if revolutionary_credentials >= 50
					*set bailey_rapport %+20
					*set revolutionary_credentials %+20
					*set lockridge_rapport %-20
					*if malloy_out
						*set lesczynski_rapport %+10
						*set pickering_rapport %-10
					*if pickering_out
						*set lesczynski_rapport %-10
						*set malloy_rapport %+10
					*if (pickering_out = false) and (malloy_out = false)
						*set malloy_rapport %+10
						*set pickering_rapport %-10
					Bailey and the other supporters of Stone keep you at a distance, but your efforts do not go unnoticed.

					You have a long road ahead of you, however.
					*goto round_three
				*else
					*set bailey_rapport %-20
					*set revolutionary_credentials %-20
					*set lockridge_rapport %+20
					*if malloy_out
						*set lesczynski_rapport %-10
						*set pickering_rapport %+10
					*if pickering_out
						*set lesczynski_rapport %+10
						*set malloy_rapport %-10
					*if (pickering_out = false) and (malloy_out = false)
						*set malloy_rapport %-10
						*set pickering_rapport %+10
					Lockridge and his allies keep you at a distance, but your efforts do not go unnoticed.

					You have a long road ahead of you, however.
					*goto round_three
		*if (ask_carothers = false) and (allegiance_inquiry and (bowater_determined and ((calkins_status > 1) and (bowater_revolutionary = false))))
			*if revolutionary_credentials > 55
				*selectable_if (speaks_english) #I ask Senator Bailey who is voting against @{malloy_out Lesczynski|Malloy} that he was not anticipating.
					*set allegiance_inquiry false
					*if met_bailey = false
						*gosub meet_bailey
						
						"About that…tell me, who is voting against @{malloy_out Lesczynski|Malloy} that you were not anticipating?"
						
					He turns to hide his face from the room.  He says a single word: "Bowater."

					"Bowater?"

					"Yes, I had anticipated his support, but he has moved against us."
					
					You wonder, was Bowater's change of heart due to your amity with Andrew Calkins?
					*goto round_three
			*if revolutionary_credentials < 45
				*selectable_if (speaks_english) #I ask Senator Bailey who is voting against @{pickering_out Lesczynski|Pickering} that he was not anticipating.
					*set allegiance_inquiry false
					*set lockridge_rapport %+10
					*set revolutionary_credentials %-10
					*if met_bailey = false
						*gosub meet_bailey
						
						"About that…tell me, who is voting against @{pickering_out Lesczynski|Pickering} that you were not anticipating?"
						
					"As a matter of fact, ${mr} ${surname}, it is not who is voting against us, but rather, who is voting for us."
					
					"Excuse me?"
					
					"Senator Bowater's support was unexpected.  You wouldn't happen to have anything to do with that, would you?"
					
					Unfortunately, he doesn't give you a chance to respond.  Pondering your amity with Andrew Calkins, you wonder if you are the cause of this impasse.
					*goto round_three
		*if (ashmore_banks = 2) and (municipal_debt > 0)
			#I approach Senator Ashmore and see if she has any influence with the banks in Philadelphia.  Perhaps, if they would forgive some of the debt, Memphis would halt its current crash course towards insolvency.
				*set ashmore_banks false
				*set compassion %-5
				*set shepherd_credentials %-10
				The Senator is caught totally off-guard by your inquiry.  It takes her a moment to fully turn her attention to your request, so committed is she to the election at hand.
				*if ashmore_revolutionary or (ashmore_rapport > 65)
					*set ashmore_rapport %+10
					*set ashmore_banks 3
					After a few moments of consideration, she replies in the affirmative.  She will see what she can do to encourage the banks to give the city of Memphis some leeway with its municipal debt—though, if you make use of this offer, you will incur a debt to her.
				*else
					*set ashmore_rapport %-10
					*set ashmore_banks 4
					Finally focusing her eyes on you, she shakes her head dismissively, clearly surprised that would distract her with such things at a time like this.
				*goto round_three
		*if (support_lesczynski = false) and ((lesczynski_out = false) and ((support_flip = false) and (heard_of_lesczynski)))
			#I show my support for Lesczynski.
				*set support_lesczynski true
				*if met_lesczynski = false
					*gosub meet_lesczynski
					And so the two of you begin an animated conversation about the future of Memphis with him as Senator.
				
				*if support_malloy
					*set support_malloy false
					*set malloy_rapport %-30
					*set bailey_rapport %-30
					*set partridge_rapport %-30
					Senators Bailey and Partridge frown in your direction.  Your perfidy has not gone unnoticed.
					*if pickering_out
						*set revolutionary_credentials %-40
						*set support_flip true
						The other vampires are amazed at your conversion to the opponents of Isaiah Stone.  Perhaps the faction of Adonis will in fact prevail here tonight.
					*else
						The rest of the vampires are confused as to why you would defect from the cause of Isaiah Stone to an unaligned individual such as Lesczynski.
						*if status > 2
							You can hear the twitters around you, as they consider whether there is some plot afoot of which they are uninformed.  You smile a secret smile and leave them to wonder at your deed.
						*else
							Your lack of standing within the Society, however, guarantees that no one gives it too much thought.
				*elseif support_pickering
					*set support_pickering false
					*set pickering_rapport %-30
					*set lockridge_rapport %-30
					*set coffin_rapport %-40
					Senator Lockridge frowns in your direction; he is a model of restraint, however, beside Senator Coffin, who looks downright enraged.
					*if malloy_out
						*set revolutionary_credentials %+40
						*set support_flip true
						The other vampires are amazed at your conversion to the supporters of Isaiah Stone.  Perhaps his faction will in fact prevail here tonight.
					*else
						The rest of the vampires are confused as to why you would defect from the cause against Isaiah Stone to an unaligned individual such as Lesczynski.
						*if status > 2
							You can hear the twitters around you, as they consider whether there is some plot afoot of which they are uninformed.  You smile a secret smile and leave them to wonder at your deed.
						*else
							Your lack of standing within the Society, however, guarantees that no one gives it too much thought.
				*else
					*if malloy_out
						*if revolutionary_credentials > 60
							*set revolutionary_credentials %+20
							Senators Bailey and Partridge smile benevolently at this display on behalf of their stand-in candidate.
							*if status > 2
								Your standing in the Society does make this gesture noteworthy, despite your not actually having a vote in the matter.
							*else
								No one else really seems to care.
						*else
							The attendees observe the attention you pay Lesczynski with surprise.  Apparently, this was an unexpected development.
							*set revolutionary_credentials %+40
							*set malloy_rapport %+20
							*set bailey_rapport %+20
							*set partridge_rapport %+20
							*set lockridge_rapport %-30
					*elseif pickering_out
						*if revolutionary_credentials < 40
							*set revolutionary_credentials %-40
							Senator Lockridge nods benevolently at this display on behalf of his candidate.
							*if status > 2
								Your standing in the Society does make this gesture noteworthy, despite your not actually having a vote in the matter.
							*else
								No one else really seems to care.
						*else
							The attendees observe the attention you pay Lesczynski with surprise.  Apparently, this was an unexpected development.
							*set revolutionary_credentials %-40
							*set lockridge_rapport %+20
							*set bailey_rapport %-20
							*set partridge_rapport %-20
							*set malloy_rapport %-20
							*set lesczynski_rapport %+20
					*else
						Considering that Malloy and Pickering are both still in the running, the other vampires are unsure as to why you would demonstrate support for Lesczynski.
						*if status > 2
							Though you cast no official vote, your standing in the Society is not insignificant, and the Senators pause to consider whether there is something afoot of which they are ignorant.

							You smile a secret smile and leave them to their paranoia.
						*else
							However, your opinion carries little weight; though they observe you, they are not changed for having done so.
				*goto round_three
		*if (malloy_out = false) and ((support_malloy = false) and ((support_flip = false) and (heard_of_malloy)))
			#I show my support for Malloy.
				*set support_malloy true
				*if met_malloy = false
					*gosub meet_malloy
				
				*if support_pickering
					*set support_pickering false
					*set support_flip true
					*set lockridge_rapport %-20
					*set pickering_rapport %-20
					Senator Lockridge scowls in your direction.  Your perfidy has not gone unnoticed.
					*if status > 2
						You can hear the twitters around you, as they consider whether there is some plot afoot of which they are uninformed.  You smile a secret smile and leave them to wonder at your deed.
						*goto round_three
					*else
						Your lack of standing within the Society, however, guarantees that no one else gives it too much thought.
						*goto round_three
				*elseif support_lesczynski
					*set support_lesczynski false
					*set lesczynski_rapport %-30
					*if pickering_out
						*set support_flip true
						*set lockridge_rapport %-40
						Senator Lockridge scowls at your sudden change of heart.
						*if status > 2
							You can hear the twitters around you, as they consider whether there is some plot afoot of which they are uninformed.  You smile a secret smile and leave them to wonder at your deed.  

							Abigail Coffin makes certain to press your hand in gratitude.
							*goto round_three
						*else
							Senator Coffin is the only other attendee to acknowledge the change; she smiles in your direction.
							*goto round_three
					*else
						*set bailey_rapport %+10
						*set partridge_rapport %+10
						*set malloy_rapport %+10
						*set revolutionary_credentials %+40
						Malloy is as surprised as anyone to observe your conversion to her cause.  She even goes so far as to welcome your new attentions with a hug.
						
						Senators Bailey and Partridge notice your conversion to their cause.  They welcome you to the support of Isaiah Stone with open arms.
						*if status > 2
							You can hear the twitters around you, as they consider whether there is some plot afoot of which they are uninformed.  You smile a secret smile and leave them to wonder at your deed.
							*goto round_three
						*else
							Your lack of standing within the Society, however, guarantees that no one else gives it too much thought.
							*goto round_three
				*else
					*set support_malloy true
					*if revolutionary_credentials > 60
						*set revolutionary_credentials %+20
						Senators Bailey and Partridge smile at you benevolently as you make a display of support for Malloy.  
						*if status > 2
							Your standing in the Society does make this gesture noteworthy, despite your not actually having a vote in the matter.
							*goto round_three
						*else
							No one else really seems to care.
							*goto round_three
					*else
						*set support_flip true
						*set revolutionary_credentials %+40
						*set malloy_rapport %+10
						*set bailey_rapport %+10
						*set partridge_rapport %+10
						*set lockridge_rapport %-20
						The other attendees observe the attention you pay Malloy with surprise.  Apparently, this was an unexpected development.
						*if status > 2
							Your standing in the Society does make this gesture noteworthy, despite your not actually having a vote in the matter.
							*goto round_three
						*else
							However, your lack of standing assures that this small disruption is soon forgotten.
							*goto round_three
		*if (pickering_out = false) and ((support_pickering = false) and ((support_flip = false) and (heard_of_pickering)))
			#I show my support for Pickering.
				*set support_pickering true
				*if met_pickering = false
					*gosub meet_pickering
					
				*if support_malloy
					*set support_malloy false
					*set revolutionary_credentials %-40
					*set support_flip true
					*set bailey_rapport %-40
					*set partridge_rapport %-40
					*set malloy_rapport %-40
					Senators Bailey and Partridge frown in your direction.  Your perfidy has not gone unnoticed.
					*if status > 2
						You can hear the twitters around you, as they consider whether there is some plot afoot of which they are uninformed.  You smile a secret smile and leave them to wonder at your deed.
						*goto round_three
					*else
						Your lack of standing within the Society, however, guarantees that no one else gives it too much thought.
						*goto round_three
				*elseif support_lesczynski
					*set support_lesczynski false
					*set lesczynski_rapport %-40
					*if malloy_out
						*set revolutionary_credentials %-40
						*set support_flip true
						*set bailey_rapport %-20
						*set partridge_rapport %-20
						Senators Bailey and Partridge frown in your direction.  Your perfidy has not gone unnoticed.
						*if status > 2
							You can hear the twitters around you, as they consider whether there is some plot afoot of which they are uninformed.  You smile a secret smile and leave them to wonder at your deed.
							*goto round_three
						*else
							Your lack of standing within the Society, however, guarantees that no one else gives it too much thought.
							*goto round_three
					*else
						*set lockridge_rapport %+10
						*set pickering_rapport %+10
						*set revolutionary_credentials %-20
						Pickering is as surprised as anyone by your change of heart.  He welcomes your sudden attentions with a firm shake of his hand.
						
						Senator Lockridge notices your conversion to his cause.  A slight twitch on his part might have been a nod of acknowledgement—gratitude, even.
						*goto round_three
				*else
					*if revolutionary_credentials < 40
						*set revolutionary_credentials %-20
						Senator Lockridge nods benevolently at this display on behalf of his candidate.
						*if status > 2
							Your standing in the Society does make this gesture noteworthy, despite your not actually having a vote in the matter.
							*if malloy_out
								*set coffin_rapport %+20
								Senator Coffin in particular is pleased at your demonstration.
							*goto round_three
						*elseif malloy_out
							*set coffin_rapport %+20
							Senator Coffin nods in your direction; she seems to be the only other person to take notice.
							*goto round_three
						*else
							No one else really seems to care.
							*goto round_three
					*else
						The attendees observe the attention you pay Pickering with surprise.
						*set revolutionary_credentials %-40
						*goto round_three
		*if (timmers_on_heresy_of_abraham) and (timmers_details_on_abraham = false)
			#I seek out Senator Timmers and press him for more details on the Children of Abraham.
				*gosub timmers_on_abraham
				*goto round_three
		*if (simmons_waylaid = false) and (heard_of_simmons and (met_simmons = false))
			#I take the opportunity to introduce myself to the elusive Senator Simmons.
				*gosub meet_simmons
				*goto round_three
	*if (heresy_of_abraham > 0) and (timmers_on_heresy_of_abraham = false)
		#I use the hand-signal taught to me by Estefania, in the hopes that someone here can tell me more of the Children of Abraham.
			*gosub signal_abraham
			*goto round_three
	*if (heresy_of_masons > 0) and (mason_sign_in_memphis = false)
		#I use the hand-signal of the Masons, in the hopes of finding another member of the Order.
			*gosub signal_masons
			*goto round_three
	*if (met_fragala = false) #I introduce myself to @{fragala_name Fragalà|the leper|the disfigured man}.
		*gosub fragala_intro
		*gosub_scene memphis_1877_reception speak_fragala
		*goto round_three

*label partridge_betrayal
*if partridge_betrayal and (notice_partridge_betrayal = false)
	*if second_betrayal
		*set notice_partridge_betrayal true
		As with four years ago, the indecision lies with one vampire: Samson Partridge.
	*elseif (notice_partridge_betrayal = false) and (perception > 2)
		*set notice_partridge_betrayal true
		Unfortunately, the indecision seems to arise from a single vampire's deeds: Samson Partridge.
	*if notice_partridge_betrayal
		*set second_goround true
		*if partridge_uncommitted
			Despite his professed support in the past for @{malloy_out Lesczynski|Malloy}, he refuses to commit himself here and now.
		*else
			Despite his former support for @{malloy_out Lesczynski|Malloy}, he has made his support of @{pickering_out Lesczynski|Pickering} plain.
		Senator Bailey is clearly distraught by this perfidy, but Partridge seems indifferent to Bailey's concerns.
*elseif second_goround
	Over the course of the past two hours, Partridge has not conceded an inch. He is not here to be persuaded.
*return

*label meet_bailey
"Senator Bailey?" you begin.

*if bailey_correspondence
	"Oh, yes…${mr} ${surname}? You wrote to me, didn't you?"
	
	"I did, Senator."
	
	"Nice to put a face to the name."
	
	"And you."
	
	"Though, I do wish it were under less trying circumstances," he muses.
*else
	"Yes…${mr} ${surname}, if I have that right?"
	
	"You do. A pleasure to meet you," you begin.
	
	"Yes…though I wish it were in less pressing circumstances."
*set met_bailey true
*return

*label round_three
*gosub allegiance_count_during
*page_break
The clock strikes three.  The gathered vampires redouble their efforts to come to a consensus.
*gosub partridge_betrayal
*choice
	*if player_for_senator
		#I press my candidacy.
			*if (davison_waylaid = false) and (met_davison = false)
				*gosub meet_davison_candidate
				*goto nights_end
			*elseif (simmons_waylaid = false) and (met_simmons = false)
				*gosub meet_simmons_candidate
				*goto nights_end
			*else
				*if status > 2
					The vampires gather around you, fawning on your words.  Though the seating prevents you from easily making eye contact with the other candidates, you can feel the heat of their fury.

					The room is in utter confusion; the strength of your candidacy has disrupted the carefully orchestrated political calculus.
					*if revolutionary_credentials > 60
						*if malloy_out
							*set lesczynski_rapport %-10
							*set pickering_rapport %-10
							The supporters of Stone are clearly split in their attentions.  Lesczynski's support has almost entirely migrated to you.  Unfortunately, there that shift is not complete, and that leaves Pickering looking like the winner.
							*goto nights_end
						*elseif lesczynski_out
							*set malloy_rapport %-10
							*set pickering_rapport %+10
							The supporters of Stone are clearly split in their attentions.  Unfortunately, that leaves Pickering in a very strong position.
							*goto nights_end
						*else
							*set lesczynski_rapport %-10
							*set malloy_rapport %-10
							*set pickering_rapport %-10
							With four viable candidates in the race, the gathered attendees are incapable of coming to any sort of consensus.
							*goto nights_end
					*elseif revolutionary_credentials >= 40
						*if malloy_out
							*set lesczynski_rapport %-10
							*set pickering_rapport %-10
							Your political agnosticism must be some sort of virtue.  With Lesczynski representing the supporters of Stone, and Pickering those who oppose him, somehow your indifference seems to be winning the room.
							*goto nights_end
						*elseif pickering_out
							*set lesczynski_rapport %-10
							*set malloy_rapport %-10
							Your political agnosticism must be some sort of virtue.  With Malloy representing the supporters of Stone, and Lesczynski those who oppose him, somehow your indifference seems to be winning the room.
							*goto nights_end
						*elseif lesczynski_out
							*set malloy_rapport %-10
							*set pickering_rapport %-10
							Your political agnosticism must be some sort of virtue.  With Malloy representing the supporters of Stone, and Pickering those who oppose him, somehow your indifference seems to be winning the room.
							*goto nights_end
						*else
							*set lesczynski_rapport %-10
							*set malloy_rapport %-10
							*set pickering_rapport %-10
							With four viable candidates in the race, the gathered attendees are incapable of coming to any sort of consensus.
							*goto nights_end
					*else
						*if pickering_out
							*set lesczynski_rapport %-10
							*set malloy_rapport %-10
							The opponents of Stone are clearly split in their attentions.  Lesczynski's support has almost entirely migrated to you.  Unfortunately, there that shift is not complete, and that leaves Malloy looking like the winner.
							*goto nights_end
						*elseif lesczynski_out
							*set pickering_rapport %-10
							*set malloy_rapport %+10
							The opponents of Stone are clearly split in their attentions.  Unfortunately, that leaves Malloy in a very strong position.
							*goto nights_end
						*else
							*set lesczynski_rapport %-10
							*set malloy_rapport %-10
							*set pickering_rapport %-10
							With four viable candidates in the race, the gathered attendees are incapable of coming to any sort of consensus.
							*goto nights_end
				*else
					The gathered vampires do their best to ignore you.  Yes, they come and pay their respects as required by tradition, but once their obligations are discharged, they flee your presence, lest their attentions be misconstrued.
					*goto nights_end
		#I relinquish my seat.
			*set player_for_senator false
			*set seat_relinquished true
			*set seat_num -1
			*set discretion %-10
			*if revolutionary_credentials > 60
				Bailey and Partridge are clearly relieved to see you stand.  You begin to circulate through the room; turning back for a brief moment, you notice that your chair is already gone.
				*goto nights_end
			*elseif revolutionary_credentials >= 40
				Standing, you move away from your seat.  Someone takes it and puts it to the side of the room.  Otherwise, you gesture seems to go unnoticed.
				*goto nights_end
			*else
				Lockridge and his allies are relieved to see you stand.  You begin to circulate through the room; turning back for a brief moment, you notice that your chair is already gone.
				*goto nights_end
	*else
		*if (equal_attention) #I spread my attentions among the candidates more or less equally. 
			*gosub support_equally
			*goto nights_end
		*if support_flip and (curry_favor = false)
			#I attempt to curry favor with my new allies.
				*set curry_favor true
				*if revolutionary_credentials >= 50
					*set bailey_rapport %+15
					*set revolutionary_credentials %+15
					*set lockridge_rapport %-20
					*if malloy_out
						*set lesczynski_rapport %+5
						*set pickering_rapport %-5
					*elseif pickering_out
						*set lesczynski_rapport %-5
						*set malloy_rapport %+5
					*else
						*set malloy_rapport %+5
						*set pickering_rapport %-5
					Bailey and the other supporters of Stone keep you at a distance, but your efforts do not go unnoticed.

					You have a long road ahead of you, however.
					*goto nights_end
				*else
					*set bailey_rapport %-20
					*set revolutionary_credentials %-15
					*set lockridge_rapport %+15
					*if malloy_out
						*set lesczynski_rapport %-5
						*set pickering_rapport %+5
					*elseif pickering_out
						*set lesczynski_rapport %+5
						*set malloy_rapport %-5
					*else
						*set malloy_rapport %-5
						*set pickering_rapport %+5
					Lockridge and his allies keep you at a distance, but your efforts do not go unnoticed.

					You have a long road ahead of you, however.
					*goto nights_end
		*if ask_carothers and (notice_partridge_betrayal = false)
			#I ask Carothers how it is that we are at such an impasse again.
				*gosub ask_carothers
				*goto nights_end
		*if (ask_carothers = false) and (allegiance_inquiry and (bowater_determined and ((calkins_status > 1) and (bowater_revolutionary = false))))
			*if revolutionary_credentials > 55
				#I ask Senator Bailey who is voting against @{malloy_out Lesczynski|Malloy} that he was not anticipating.
					*set allegiance_inquiry false
					*if met_bailey = false
						*gosub meet_bailey
						
						"About that…tell me, who is voting against @{malloy_out Lesczynski|Malloy} that you were not anticipating?"
					
					He turns to hide his face from the room.  He says a single word: "Bowater."

					"Bowater?"

					"Yes, I had anticipated his support, but he has moved against us."
					
					You wonder, was Bowater's change of heart due to your amity with Andrew Calkins?
					*goto nights_end
			*if revolutionary_credentials < 45
				#I ask Senator Bailey who is voting against @{pickering_out Lesczynski|Pickering} that he was not anticipating.
					*set allegiance_inquiry false
					*set lockridge_rapport %+10
					*set revolutionary_credentials %-10
					*if met_bailey = false
						*gosub meet_bailey
						
						"About that…tell me, who is voting against @{pickering_out Lesczynski|Pickering} that you were not anticipating?"
						
					"As a matter of fact, ${mr} ${surname}, it is not who is voting against us, but rather, who is voting for us."
					
					"Excuse me?"
					
					"Senator Bowater's support was unexpected.  You wouldn't happen to have anything to do with that, would you?"
					
					Unfortunately, he doesn't give you a chance to respond.  Pondering your amity with Andrew Calkins, you wonder if you are the cause of this impasse.
					*goto nights_end
		*if (heard_of_memeskia = false) and (ask_carothers = false)
			*selectable_if (speaks_english) #I want to ask Senator Bailey about St. Louis.  What is it like?
				*gosub bailey_on_st_louis
				*goto nights_end
		*if notice_partridge_betrayal and ((independence < 80) and speaks_english)
			*selectable_if (discretion > 25) #I confront Partridge about his perfidy.
				*set discretion %+5
				It seems that Partridge does not want to be caught alone, 
				*if (status >= 2) or ((willpower > 2) or (agility > 3))
					and it takes you some time to achieve your goal.  However, your perseverance wins out, and you are able to stand before him with some semblance of privacy (as much as can be achieved in a room full of vampires, anyway).
					*label confront_partridge

					"What are you doing, Senator?"

					"I beg your pardon?"

					"You are the reason that no Senator can be chosen for Memphis.  Everyone else has committed themselves, yet you refuse to do so.  What is the meaning of this?"

					Partridge sputters.  "How dare you question me!"

					"Do you deny me?"
					*goto harding_and_carothers
				*elseif (stealth >= 3)
					In fact, you are forced to block yourself out of his mind, so that he does not see you coming.  Only then are you able to descend upon him unawares.
					*goto confront_partridge
				*else
					and try as you might, you cannot corner him.
					*goto nights_end
		*if (ashmore_banks = 2) and (municipal_debt > 0)
			#I approach Senator Ashmore and see if she has any influence with the banks in Philadelphia.  Perhaps, if they would forgive some of the debt, Memphis would halt its current crash course towards insolvency.
				*set compassion %-5
				*set shepherd_credentials %-10
				The Senator is caught totally off-guard by your inquiry.  It takes her a moment to fully turn her attention to your request, so committed is she to the election at hand.
				*if ashmore_revolutionary or (ashmore_rapport > 65)
					*set ashmore_rapport %+10
					*set ashmore_banks 3
					After a few moments of consideration, she replies in the affirmative.  She will see what she can do to encourage the banks to give the city of Memphis some leeway with its municipal debt—though, if you make use of this offer, you will incur a debt to her.
				*else
					*set ashmore_rapport %-10
					*set ashmore_banks 4
					Finally focusing her eyes on you, she shakes her head dismissively, clearly surprised that would distract her with such things at a time like this.
				*goto round_three
		*if (support_lesczynski = false) and ((lesczynski_out = false) and ((support_flip = false) and (heard_of_lesczynski)))
			#I show my support for Mr. Lesczynski.
				*set support_lesczynski true
				*if met_lesczynski = false
					*gosub meet_lesczynski
					And so the two of you begin an animated discussion about the future of Memphis with him as its Senator.
					
				*if support_malloy
					*set support_malloy false
					*set malloy_rapport %-15
					*set bailey_rapport %-15
					*set partridge_rapport %-15
					Senators Bailey and Partridge frown in your direction.  Your perfidy has not gone unnoticed.
					*if pickering_out
						*set revolutionary_credentials %-40
						*set support_flip true
						The other vampires are amazed at your conversion to the opponents of Isaiah Stone.  Perhaps the faction of Adonis will in fact prevail here tonight.
					*else
						The rest of the vampires are confused as to why you would defect from the cause of Isaiah Stone to an unaligned individual such as Lesczynski.
						*if status > 2
							You can hear the twitters around you, as they consider whether there is some plot afoot of which they are uninformed.  You smile a secret smile and leave them to wonder at your deed.
						*else
							Your lack of standing within the Society, however, guarantees that no one gives it too much thought.
					*goto nights_end
				*elseif support_pickering
					*set support_pickering false
					*set pickering_rapport %-15
					*set lockridge_rapport %-15
					*set coffin_rapport %-30
					Senator Lockridge frowns in your direction; he is a model of restraint, however, beside Senator Coffin, who looks downright enraged.
					*if malloy_out
						*set revolutionary_credentials %+40
						*set support_flip true
						The other vampires are amazed at your conversion to the supporters of Isaiah Stone.  Perhaps his faction will in fact prevail here tonight.
						*goto nights_end
					*else
						The rest of the vampires are confused as to why you would defect from the cause against Isaiah Stone to an unaligned individual such as Lesczynski.
						*if status > 2
							You can hear the twitters around you, as they consider whether there is some plot afoot of which they are uninformed.  You smile a secret smile and leave them to wonder at your deed.
							*goto nights_end
						*else
							Your lack of standing within the Society, however, guarantees that no one gives it too much thought.
							*goto nights_end
				*else
					*if malloy_out
						*if revolutionary_credentials > 60
							*set revolutionary_credentials %+20
							Senators Bailey and Partridge smile benevolently at this display on behalf of their candidate.
							*if status > 2
								Your standing in the Society does make this gesture noteworthy, despite your not actually having a vote in the matter.
							*else
								No one else really seems to care.
						*else
							The attendees observe the attention you pay Lesczynski with surprise.  Apparently, this was an unexpected development.
							*set revolutionary_credentials %+20
							*set malloy_rapport %+10
							*set bailey_rapport %+10
							*set partridge_rapport %+10
							*set lockridge_rapport %-20
					*elseif pickering_out
						*if revolutionary_credentials < 40
							*set revolutionary_credentials %-20
							Senator Lockridge nods benevolently at this display on behalf of his candidate.
							*if status > 2
								Your standing in the Society does make this gesture noteworthy, despite your not actually having a vote in the matter.
							*else
								No one else really seems to care.
						*else
							The attendees observe the attention you pay Lesczynski with surprise.  Apparently, this was an unexpected development.
							*set revolutionary_credentials %-20
							*set lockridge_rapport %+10
							*set bailey_rapport %-10
							*set partridge_rapport %-10
							*set malloy_rapport %-10
							*set lesczynski_rapport %+10		
					*else
						The gathered vampires seem somewhat confused by your demonstration of support.
						*if status > 2
							Though you cast no official vote, your standing in the Society is not insignificant, and the Senators pause to consider whether there is something afoot of which they are ignorant.

							You smile a secret smile and leave them to their paranoia.
						*else
							However, your opinion carries little weight; though they observe you, they are not changed for having done so.
					*goto nights_end
		*if (malloy_out = false) and ((support_malloy = false) and ((support_flip = false) and (heard_of_malloy)))
			#I show my support for Malloy.
				*set support_malloy true
				*if met_malloy = false
					*gosub meet_malloy
					
				*if support_pickering
					*set support_pickering false
					*set support_flip true
					*set lockridge_rapport %-20
					*set pickering_rapport %-20
					*set revolutionary_credentials %+40
					Senator Lockridge scowls in your direction.  Your perfidy has not gone unnoticed.
					*if status > 2
						You can hear the twitters around you, as they consider whether there is some plot afoot of which they are uninformed.  You smile a secret smile and leave them to wonder at your deed.
						*goto nights_end
					*else
						Your lack of standing within the Society, however, guarantees that no one else gives it too much thought.
						*goto nights_end
				*if support_lesczynski
					*set support_lesczynski false
					*set lesczynski_rapport %-30
					*set support_lesczynski false
					*if pickering_out
						*set support_flip true
						*set lockridge_rapport %-20
						Senator Lockridge scowls at your sudden change of heart.
						*if status > 2
							You can hear the twitters around you, as they consider whether there is some plot afoot of which they are uninformed.  You smile a secret smile and leave them to wonder at your deed.  

							Abigail Coffin makes certain to press your hand in gratitude.
							*goto nights_end
						*else
							Senator Coffin is the only other attendee to acknowledge the change; she smiles in your direction.
							*goto nights_end
					*else
						*set bailey_rapport %+10
						*set partridge_rapport %+10
						*set malloy_rapport %+10
						*set revolutionary_credentials %+20
						The Senators Bailey and Partridge notices your conversion to their cause.  They welcome you to the support of Isaiah Stone with open arms.
						*if status > 2
							You can hear the twitters around you, as they consider whether there is some plot afoot of which they are uninformed.  You smile a secret smile and leave them to wonder at your deed.
							*goto nights_end
						*else
							Your lack of standing within the Society, however, guarantees that no one else gives it too much thought.
							*goto nights_end
				*else
					*if revolutionary_credentials > 60
						*set revolutionary_credentials %+20
						Senators Bailey and Partridge smile at you benevolently as you make a display of support for Malloy. @{(status > 2) Your standing in the Society does make this gesture noteworthy, despite your not actually having a vote in the matter.|No one else really seems to care.}
						*goto nights_end
					*elseif revolutionary_credentials >= 40
						*set revolutionary_credentials %+20
						*set malloy_rapport %+10
						*set bailey_rapport %+10
						*set partridge_rapport %+10
						*set lockridge_rapport %-15
						Senators Bailey and Partridge seem pleased by your demonstration of support for their candidate. @{(status > 2) Your standing in the Society does make this gesture noteworthy, despite your not actually having a vote in the matter.|No one else really seems to care.}
						*goto nights_end
					*else
						*set support_flip true
						*set revolutionary_credentials %+40
						*set malloy_rapport %+10
						*set bailey_rapport %+10
						*set partridge_rapport %+10
						*set lockridge_rapport %-20
						The other attendees observe the attention you pay Malloy with surprise.  Apparently, this was an unexpected development. @{(status > 2) Your standing in the Society does make this gesture noteworthy, despite your not actually having a vote in the matter.|No one else really seems to care.}
						*goto nights_end
		*if (pickering_out = false) and ((support_pickering = false) and ((support_flip = false) and (heard_of_pickering)))
			#I show my support for Pickering.
				*set support_pickering true
				*if met_pickering = false
					*gosub meet_pickering
					
				*if support_malloy
					*set support_malloy false
					*set revolutionary_credentials %-40
					*set support_flip true
					*set bailey_rapport %-20
					*set partridge_rapport %-20
					*set malloy_rapport %-20
					Senators Bailey and Partridge frown in your direction.  Your perfidy has not gone unnoticed.
					*if status > 2
						You can hear the twitters around you, as they consider whether there is some plot afoot of which they are uninformed.  You smile a secret smile and leave them to wonder at your deed.
						*goto nights_end
					*else
						Your lack of standing within the Society, however, guarantees that no one else gives it too much thought.
						*goto nights_end
				*elseif support_lesczynski
					*set support_lesczynski false
					*set lesczynski_rapport %-30
					*if malloy_out
						*set revolutionary_credentials %-40
						*set support_flip true
						*set bailey_rapport %-20
						*set partridge_rapport %-20
						Senators Bailey and Partridge frown in your direction.  Your perfidy has not gone unnoticed.
						*if status > 2
							You can hear the twitters around you, as they consider whether there is some plot afoot of which they are uninformed.  You smile a secret smile and leave them to wonder at your deed.
							*goto nights_end
						*else
							Your lack of standing within the Society, however, guarantees that no one else gives it too much thought.
							*goto nights_end
					*else
						*set lockridge_rapport %+10
						*set pickering_rapport %+10
						*set revolutionary_credentials %-20
						Senator Lockridge notices your conversion to his cause.  A slight twitch on his part might have been a nod of acknowledgement—gratitude, even.
						*goto nights_end
				*else
					*if revolutionary_credentials < 40
						*set revolutionary_credentials %-20
						Senator Lockridge nods benevolently at this display on behalf of his candidate.
						*if status > 2
							Your standing in the Society does make this gesture noteworthy, despite your not actually having a vote in the matter.
							*if malloy_out
								*set coffin_rapport %+20
								Senator Coffin in particular is pleased at your demonstration.
							*goto nights_end
						*elseif malloy_out
							*set coffin_rapport %+20
							Senator Coffin nods in your direction; she seems to be the only other person to take notice.
							*goto nights_end
						*else
							No one else really seems to care.
							*goto nights_end
					*else
						The attendees observe the attention you pay Pickering with surprise.
						*set revolutionary_credentials %-20
						*goto nights_end
		*if (simmons_waylaid = false) and (heard_of_simmons and (met_simmons = false))
			#I take the opportunity to introduce myself to the elusive Senator Simmons.
				*gosub meet_simmons
				*goto nights_end
		*if (timmers_on_heresy_of_abraham) and (timmers_details_on_abraham = false)
			#I seek out Senator Timmers and press him for more details on the Children of Abraham.
				*gosub timmers_on_abraham
				*goto nights_end
	*if (heresy_of_abraham > 0) and (timmers_on_heresy_of_abraham = false)
		#I use the hand-signal taught to me by Estefania, in the hopes that someone here can tell me more of the Children of Abraham.
			*gosub signal_abraham
			*goto nights_end
	*if (heresy_of_masons > 0) and (mason_sign_in_memphis = false)
		#I use the hand-signal of the Masons, in the hopes of finding another member of the Order.
			*gosub signal_masons
			*goto nights_end
	*if (met_fragala = false) #I introduce myself to @{fragala_name Fragalà|the leper|the disfigured man}.
		*gosub fragala_intro
		*gosub_scene memphis_1877_reception speak_fragala
		*goto nights_end

*label support_equally
*set equal_attention false
*if curry_favor
	The sudden ecumenism with which you approach the candidates pleases no one.
	*set ashmore_rapport %-20
	*set bailey_rapport %-20
	*set bowater_rapport %-20
	*set coffin_rapport %-20
	*if davison_waylaid = false
		*set davison_rapport %-20
	*set lockridge_rapport %-20
	*set partridge_rapport %-20
	*set santagostino_rapport %-20
	*if simmons_waylaid = false
		*set simmons_rapport %-20
	*set timmers_rapport %-20
	*if lesczynski_out = false
		*set lesczynski_rapport %-20
	*if malloy_out = false
		*set malloy_rapport %-20
	*if pickering_out = false
		*set pickering_rapport %-20
	*if revolutionary_credentials >= 55
		*set revolutionary_credentials %-30
	*if revolutionary_credentials <= 45
		*set revolutionary_credentials %-30
	*set harding_rapport %+10
	*return
*elseif support_flip
	The sudden ecumenism with which you approach the candidates pleases no one.
	*set ashmore_rapport %-10
	*set bailey_rapport %-10
	*set bowater_rapport %-10
	*set coffin_rapport %-10
	*if davison_waylaid = false
		*set davison_rapport %-10
	*set lockridge_rapport %-10
	*set partridge_rapport %-10
	*set santagostino_rapport %-10
	*if simmons_waylaid = false
		*set simmons_rapport %-10
	*set timmers_rapport %-10
	*if lesczynski_out = false
		*set lesczynski_rapport %-10
	*if malloy_out = false
		*set malloy_rapport %-10
	*if pickering_out = false
		*set pickering_rapport %-10
	*if revolutionary_credentials >= 60
		*set revolutionary_credentials %-20
	*if revolutionary_credentials <= 40
		*set revolutionary_credentials %-20
	*set harding_rapport %+10
	*return
*else
	*if status > 2
		Each of the candidates is flattered by your attentions.  Your prestige in the Society means that your favor is noted by all.
		*label equal_support_stat_boost
		*set ashmore_rapport %+10
		*set bailey_rapport %+10
		*set bowater_rapport %+10
		*set coffin_rapport %+10
		*if davison_waylaid = false
			*set davison_rapport %+10
		*set lockridge_rapport %+10
		*set partridge_rapport %+10
		*set santagostino_rapport %+10
		*if simmons_waylaid = false
			*set simmons_rapport %+10
		*set timmers_rapport %+10
		*if lesczynski_out = false
			*set lesczynski_rapport %+15
		*if malloy_out = false
			*set malloy_rapport %+15
		*if pickering_out = false
			*set pickering_rapport %+15
		*if revolutionary_credentials > 70
			*set revolutionary_credentials %-10
		*if revolutionary_credentials < 30
			*set revolutionary_credentials %+10
		*set harding_rapport %+15
		*return
	*elseif charm > 3
		It takes some doing, but your grace and charm allow you to divide your attentions effectively between the candidates without provoking the ire of anyone in particular.  You suspect that you have somehow managed to please everyone with your political acumen.
		*goto equal_support_stat_boost
	*else
		Your lack of both political stature and grace means that your efforts are not quite as effective as they could have been.  At least the candidates with whom you speak seem to appreciate your attentions.
		*if lesczynski_out = false
			*set lesczynski_rapport %+15
		*if malloy_out = false
			*set malloy_rapport %+15
		*if pickering_out = false
			*set pickering_rapport %+15
		*if revolutionary_credentials > 70
			*set revolutionary_credentials %-10
		*if revolutionary_credentials < 30
			*set revolutionary_credentials %+10
		*return

*label ask_carothers
*set carothers_rapport %+5
*set ask_carothers false
*if partridge_uncommitted
	*set allegiance_inquiry false
	To your surprise, he does not bother to lower his voice when he speaks.  "Are you blind?"

	"Excuse me?"

	"It is Partridge.  He is unwilling to commit to a candidate.  He is the swing vote, and he refuses to make his preference clear."

	"That is strange.  I thought him a supporter of Stone."

	"He is Stone's offspring.  Yes, it is very strange."
	*return
*elseif partridge_betrayal
	*if second_betrayal
		*set carothers_rapport %+5
		*set allegiance_inquiry false
		*set notice_partridge_betrayal true
		"It is Senator Partridge again, isn't it."
		
		Carothers lowers his voice to a whisper. "Of course it is!"
		
		"Why would he…?"
		
		"Someone must be manipulating him, ${mr} ${surname}. And I aim to find out who." 
		
		He motions with his head to leave him, which you do.
		*return
	*else
		*set allegiance_inquiry false
		*set notice_partridge_betrayal true
		To your surprise, he does not bother to lower his voice when he speaks.  "Are you blind?"
	
		"Excuse me?"
	
		"It is Senator Partridge.  He is a supporter of Stone, yet here he is, supporting @{pickering_out Lesczynski|Pickering}, leaving the vote count split evenly."
	
		"I…I didn't realize."
	
		"You should pay more attention, ${given_name}."  With that, he waves you away.
		*return
*elseif support_flip
	To your surprise, he does not bother to lower his voice when he speaks.  "Despite all your ridiculous posturing, you have swayed the Senate in neither one direction nor the other."

	"At least I am trying, Quaestor," you retort hotly.

	He waves his hand dismissively.  "It does not matter.  I suspect, instead, that someone seeks to stymie the election as a whole."

	"How do you mean?"

	"I would have expected the Senators Bailey and Lockridge to have been better prepared—to have counted the votes before calling for the election—and yet, we have again reached an impasse.  If one of them were willing to reveal how they had been betrayed, we might better understand this fiasco."

	"I understand, Quaestor."
	*return
*else
	To your surprise, he does not bother to lower his voice when he speaks.  "It is as though someone were seeking to stymie the election of a senator for Memphis."

	"How do you mean?"

	"I would have expected the Senators Bailey and Lockridge to have been better prepared—to have counted the votes before calling for the election—and yet, we have again reached an impasse.  If one of them were willing to reveal how they had been betrayed, we might better understand this fiasco."

	"I understand, Quaestor."
	*return

*label signal_abraham
*set discretion %+10
*set timmers_on_heresy_of_abraham true
"Do the young still pass those secrets around?" whispers a voice in your ear.

Turning, you lay your eyes on
*if heard_of_timmers
	Gerard Timmers, Senator of Buffalo.
*else
	a young-looking vampire, 
	*if anachronism > 60
		in clothes a few decades out of style.
	*elseif ethnicity = "yankee"
		in clothes which make you long for home.  He is clearly from the other side of the Mason-Dixon line.
	*else
		in clothes that are stylish, if a bit Northern for your tastes.
	
	"I don't believe I've had the pleasure," you say.
	
	"Gerard Timmers, Senator of Buffalo."
*set met_timmers true
*gosub check_senators_achieve

"It is an honor, sir.  As I'm sure you already know, I am ${given_name} ${surname}."

He looks at you flatly.  "Allow me to impart to you what little wisdom I have earned over the past two centuries.  You will find no answer with those whom you seek.  They practice mummery and gematria, neither of which lead to any true insights."

"But…" you stutter.

He grabs your elbow and leads you around a corner.  "I offer you a century of experience.  This condition into which we have been thrust…there is no secret to it.  No great mystery.  We are cursed, like Job, to suffer and to watch those that we love suffer.  And we must not turn from Him, we must not curse His name, lest we spend eternity in darkness.  The Children of Abraham have nothing more profound to teach you than that, and I learned that as a child on my grandmother's knee.  Do you understand?"

His eyes are no longer flat.  Instead, they have hardened, determined to batter down any resistance you might offer.

"Yes, I understand," you reply.

"Good.  Do not waste your time in pursuit of them.  At best it will get you killed for heresy.  At worst, you will waste even more time than I did."

"Thank you, Senator."

"Let your deeds thank me, ${mr} ${surname}."

With that, the Senator slips away, leaving you to wonder at his words.
*return

*label timmers_on_abraham
*set timmers_details_on_abraham true
*set discretion %+10
*set heard_of_ogier true
Timmers eyes you suspiciously as you approach him. "I thought I made myself clear, ${mr} ${surname}," he begins.

"But, Senator, there must be more.…"

"You must be very occupied with your duties in this city," he interrupts. "What with it growing in importance so."

"Yes, I do find myself occupied.  But…"

"I cannot recommend enough that you busy yourself with such things, rather than pursuing other…more fruitless…ones."

You pause.  "Fruitless?"

"Take it from one who has grown disillusioned after too many decades spent in the pursuit of something which was already revealed to us.  There are no secrets amongst the Children.  They are misguided fools.  Soon they will all end up staked and left for the sun, not unlike M. Ogier."

"You speak from experience?"

Timmers draws up stiffly, suddenly suspicious.  "I said that I spoke from disillusionment. Now, if you will excuse me…" he says, cutting you off from further inquiry.
*return

*label bailey_on_st_louis
*set bailey_rapport %+10
*set anachronism %+10
*set heard_of_memeskia true
*if met_bailey = false
	*set met_bailey true
	"Senator Bailey?" you begin.
	
	"Yes…${mr} ${surname}, if I have that right?"
	
	"You do. A pleasure to meet you," you begin.
	
	"Yes@{(revolutionary_credentials > 65) , a real pleasure!|.} Though I wish it were in less pressing circumstances."
	
	"Well, if I can turn your thoughts to more pleasant matters, I thought I might inquire about your home of St. Louis. Do you find it hospitable?"

"Really?  You ask me that now?"

"I am making no noticable impact upon this election.  I thought we might speak of something else."

"It is the gateway to the West, ${mr} ${surname}," he says while continuing to evaluate the room.  "Those headed for California and Oregon come to us as the last bit of civilization before the Pacific Ocean."

*if democratic_convention = false
	*set democratic_convention true
	"Is it truly so isolated?"

	"Isolated?  No.  In fact, just last year, we hosted the Democratic convention to nominate their candidate for president.  It may be the wild west, but the nation recognizes its import."

"And who is your Quaestor?"

"It is funny that you should ask.
*if ethnicity = "choctaw"
	Like you, he is an Indian. Memeskia by name."
	
	"An Indian? Is a quaestor?"
	
	"Yes. He is old, older than most that I have met. Thankfully, we have an excellent working relationship."
	
	*if compassion < 50
		"That warms the depths of my heart, Senator," you reply.
		
		"Now, if you will excuse me, I wish to see if I can still effect a victory for this evening."
		
		"Of course, Senator."
	*else
		"That's interesting.  I've never heard of such before," you reply.
		
		"Now, if you will excuse me, I wish to see if I can still effect a victory for this evening."
		
		"Of course, Senator."
*else
	He is an Indian.  Memeskia by name."
	
	"That's interesting.  I've never heard of such before," you reply.
	
	"Now, if you will excuse me, I wish to see if I can still effect a victory for this evening."
		
	"Of course, Senator."
*return

*label meet_davison_candidate
*set met_davison true
*gosub check_senators_achieve
During the course of their introductions, a rather striking woman nears you.  She is not conventionally pretty, but she moves with a predatory grace.  This is an individual who is accustomed to getting her way.
*if heard_of_davison
	You recognize her as Anne Davison, Senator of Montréal.  She introduces herself without fanfare.
*elseif sire_alive and (sire_surname = "Sainte-Chapelle")
	*set heard_of_davison true
	*set davison_rapport %+5
	"You must be ${mr} ${surname}," she says. "Louis-Joseph's blood-nephew, yes?"
	
	*if heard_of_saint_cyr
		"Great-nephew, I believe, but yes. And you are?"	
	*else
		*set heard_of_saint_cyr true
		"Louis-who?"
		
		"Louis-Joseph Saint-Cyr, the Governor of Montréal. But, I suppose I am wrong. His blood-newphew is your dominus, Guillaume. Which would make you—"
		
		"His blood-great-nephew?"
		
		"Yes, that."
	
		"And you are?"
		
	"Anne Davison, Senator of Montréal."
	
	"A pleasure, Senator."	
*else
	*set heard_of_davison true
	"You must be ${mr} ${surname}," she says.  You nod as she takes your hand.  "I am Anne Davison, Senator of Montréal."

	"A pleasure, Senator."

*if revolutionary_credentials < 40
	"It is so good of you to do this."

	"Stand for the Senate?"

	"Split the vote of the loyalists.  Confuse the issue.  It really is quite a service to those of us who support Consul Stone."

	*if pickering_out
		*set davison_rapport %+10
		"I make a stronger candidate than Mr. Lesczynski.  We will see if I am, in fact, splitting the vote."

		Her face breaks into a toothy grin.  "So we shall, ${mr} ${surname}."
	*else
		"Those who are loyal to Adonis will see their way to the correct solution."

		"I had not taken you for a true believer, ${mr} ${surname}."

		"Perhaps I am simply confident in my position."

		"Perhaps," she says, her words trailing off.  She smiles a final wolfish smile and takes her leave of you.
*elseif revolutionary_credentials > 60
	*if malloy_out
		"It is good of you to seek to represent the interests of Consul Stone, ${mr} ${surname}."

		"And yet…?"

		She smiles at you. A wolfish smile. "It truly is a pleasure to meet you, ${mr} ${surname}. Had I known that you were going to stand—or sit, I suppose—for the position, perhaps I might have helped organize support for you. Especially with Miss Malloy unable to attend."

		"You speak with so many caveats, Senator."

		"I worry that you are muddying the situation."

		"I make a stronger candidate than Mr. Lesczynski, Senator."

		"That may be true, but you do not have the organized support that he does."

		"We shall see, Senator."  She bites her lip—a charming gesture, actually—before moving on.
		*return
	*else
		"Don't you think it's time to end this foolishness?"

		"Excuse me?"

		"Do you not count yourself a supporter of Consul Stone?"
		*choice
			#"Yes, of course."
				*set revolutionary_credentials %+10
				"I am elated to hear that.  Now, stop confusing the issue.  Miss Malloy is more than qualified.  Your presence is undermining her support."

				You look at her icily.  "I will take your words under consideration, Senator."

				"See that you do, ${mr} ${surname}."
			#"No."
				*set revolutionary_credentials %-50
				*set discretion %+30
				*set bailey_rapport %-30
				*set santagostino_rapport %-20
				*set partridge_rapport %-10
				*set davison_rapport %-30
				She looks at you in utter surprise.  After taking a moment to gather her wits, she excuses herself.

				Within moments, the whole room is buzzing with word of your response.
*else
	"Are you a glutton for punishment, ${mr} ${surname}?"

	"Excuse me?"

	"You have no base of support among the Senators.  Do you think it likely that they will all set aside their interests and vote for you?"

	"I feel as though I am the best candidate.  It is up to the Senate to recognize that."

	She smirks, apparently deciding that you should be humored rather than pitied.  Soon enough, she bids her farewell and moves on about the room as custom demands.
*return

*label meet_simmons
A cloud of pipesmoke surrounds Charles Simmons, Senator of Mobile.  He wears an outdated wig—you sense that he is mostly bald underneath—and peers at you through a pair of spectacles when you approach him.
*if speaks_english or speaks_spanish
	*set met_simmons true
	*gosub check_senators_achieve
	*set simmons_rapport %+20

	"Senator Simmons," you begin.

	"Good evening, ${mr} ${surname}.  That is your name, isn't it?"
	*if ethnicity = "southern"
		His accent has a hint of softness so often missing from the west.  It makes you think of home; he may be Senator of Mobile, but that is not where he lived.
	*comment endif

	"Yes, Senator."

	"Well, it is a pleasure to make your acquaintance."

	"You are too kind."
	*if democratic_convention
		After a moment, a thought comes to mind.  "Tell me, what do you think of the outcome of the presidential election?"

		He smiles at you.  "I think we have been vindicated.  We may have lost the war, but once allowed to vote again, we won the election.  And now?  We have traded the election for freedom from federal troops.  All in all, it marks a welcome end to this conflict."  He pauses a moment, as if considering how to frame what he means to say next.
	*if democratic_convention = false

		*comment endif
	*if curry_favor and (revolutionary_credentials <= 40)
		*set simmons_contactable true
		"It is gratifying to see you mend your erroneous ways.  As I said, it is a pleasure to finally meet you.  Tell me, was your conversion long in coming?"

		"To be honest, I am unsure as to why so many thought me a supporter of Stone for so long.  I certainly did not mean for it seem so."

		"Of course you didn't.  But now that things are clear, it is important that you know who your friends are.  Please, should need to contact me, feel free to do so."

		It would seem that Simmons has a different method of inspiring loyalty than Lockridge.
		*return
	*elseif support_flip and (status <= 2) 
		"Tell me, did you have a plan for the evening, or are you merely improvising?"

		"Pardon me?"

		"One minute you support one candidate, the next another.  Who can keep track of your allegiances amidst of all these contortions of yours?"

		"My purpose is my own, Senator."

		"Purpose?  Or desperation?"

		He gives you a sly smile and excuses himself.  He must find your political acumen underwhelming.
		*return
	*else
		*set simmons_contactable true
		*set heard_of_quintana true
		"You must come and visit Mobile some day.  It is a beautiful city on the bay.  Quaestor Quintaña does a remarkable job administring to the needs of the city."

		"Perhaps one day I shall have the opportunity to do so, Senator."

		"Here, let me give you a way to write to me, in case you have future need."

		*if (revolutionary_credentials > 40) and (met_lockridge)
			Apparently, Senator Simmons has a different way than Lockridge of inspiring others to join the counter-revolutionary cause.
		*return
*else
	*set simmons_rapport %-20
	Unfortunately, the two of you share no common tongue and are unable to communicate.
	*return

*label meet_simmons_candidate
A cloud of pipesmoke announces the arrival of someone new.  He wears a wig; you suspect that he might have worn something more impressive in days gone by, but with the changing of fashions and a head of hair that no longer grows, he has opted for something less ostentatious.  He holds a pipe in one hand and is drawing a deep breath through it.

*if heard_of_simmons
	"Senator Simmons, I presume?" you begin.
	*if (speaks_english = false) and (speaks_spanish = false)
		*set simmons_rapport %-20
		Unfortunately, when he replies, it is in a tongue which you cannot understand.  You take a few moments to try and find a common tongue, but do not succeed.

		He wanders away in a huff.
		*return
	*comment endif

	"You are correct.  And you must be ${mr} ${surname}," he replies, peering through his spectacles at you.
*if heard_of_simmons = false
	"Good evening…Senator?" you venture, not quite sure whom you are addressing.
	*if (speaks_english = false) and (speaks_spanish = false)
		*set simmons_rapport %-20
		Unfortunately, when he replies, it is in a tongue which you cannot understand.  You take a few moments to try and find a common tongue, but do not succeed.

		He wanders away in a huff.
		*return
	*comment endif

	"Charles Simmons, Senator of Mobile.  And you must be ${mr} ${surname}," he replies, peering through his spectacles at you.
	*set heard_of_simmons true
*comment endif

"You have unmasked me, Senator."
*set met_simmons true
*gosub check_senators_achieve

"I did not realize you were concealed."  
*if ethnicity = "southern"
	His accent has a hint of softness so often missing from the west.  It makes you think of home; he may be Senator of Mobile, but that is not where he lived.
*comment endif

You smile.  "I do not believe I could stay long concealed here, Senator."

"No, I dare say not."  He takes a quick look around the room before continuing.
*if revolutionary_credentials > 60
	"I cannot express my gratitude at what you are doing here this evening."

	"Gratitude?"

	"Why yes!  You sow dissension in the ranks of Stone's allies!  I have to wonder, though, if there is some devious plot of which I am not yet apprised."

	"There is no plot, Senator.  I believe I am the candidate best suited for the position."

	His eyes roll.  "Of course you do, ${son}."

	With that, he takes his leave of you, leaving a trail of pipesmoke in his wake.
	*return
*elseif revolutionary_credentials >= 40
	"You know, there are many ways to make one's mark in the Society."

	"I can only imagine."

	"Yet, I believe I have never seen such a quixotic one.  You are tilting at windmills, ${mr} ${surname}.  But by all means, continue.  It will be a pleasure to relate the story of this evening for decades into the future."

	With that, he takes his leave of you, leaving a trail of pipesmoke in his wake.
	*return
*else
	"I would recommend that you cease these efforts forthwith."

	"My candidacy?"

	"Yes.  You confuse the matter.  Your candidacy is not without merit, but is doomed, destined only to split the vote of the loyalists."

	"I believe that is the kindest thing anyone has said to me this evening, Senator."

	"A commendation it may have been, ${mr} ${surname}, but do not expect many more of them if you continue upon this path."

	"I shall take your words into consideration, Senator."

	He nods graciously; the sweet smell of the pipesmoke lingers long after his departure.
	*return

*label signal_masons
*set mason_sign_in_memphis true
*if (pickering_out = false) and (knows_pickering_mason = false)
	*if (pickering_rapport > 40) or (revolutionary_credentials < 40)
		*set knows_pickering_mason true
		*if (ethnicity = "african") or (ethnicity = "choctaw")
			*set pickering_bigot true
			To your consternation, someone does respond to your gesture.  Taking you by the elbow, Absalom Pickering manages to arrange a word in semi-private with you.

			"Who dared admit you to our Order?" he demands.  This was not quite the greeting you had anticipated.

			"It is a family affair…" you stammer.

			"Of course.  Some have taken these notions of equality too far."

			"Too far?"

			"Admitting those taken from the lesser races.  It is disgusting."  You look at him with shock.  He continues before you can reply.  "Do not be so flagrant in your display of the sign.  If you jeopardize the Order, I shall make your whole lineage regret your introduction to it."

			With that, he turns on his heel and departs.
			*return
		*else
			To your delight, someone does respond to your gesture.  Taking you by the elbow, Absalom Pickering manages to arrange a word in semi-private with you.

			"It is good to make your acquaintance, brother," he begins.

			"And I yours," you reply.  "Please, if you have need of me while you are in my city…"

			"Only that you do everything in your power to assure my victory here."

			Seeing no other possible response, you reply: "Of course, brother."

			The two of you part ways quickly, before you draw too much attention to yourselves.  Were you still alive, your heart would no doubt be beating with excitement at the discovery of a fellow conspirator.
			*return
	*elseif perception > 3
		*set knows_pickering_mason true
		You are disappointed that no one overtly responds to your gesture.  However, you feel as though Absalom Pickering recognizes the gesture but elects to ignore it.  To be generous, you have made your opposition to him clear.
		*return
	*else
		Unfortunately, no one seems to recognize the signs.  Or, at least, no one returns the counter-sign.
		*return
*if (pickering_out = false) and (knows_pickering_mason)
	You make sure to keep your gestures out of the sight of Absalom Pickering, lest he disapprove of your search for other members of the Order.  Unfortunately, no one else in the gathering seems to recognize your secret signs.
	*return
*else
	Unfortunately, no one seems to recognize the signs.  Or, at least, no one returns the counter-sign.
	*return

*label harding_and_carothers
*set carothers_humanity +1

It is at this moment that @{heard_of_harding Quaestor Harding|a woman with a bitter face} interjects.
*if status > 2
	"${mr} ${surname}," she begins.
	*if harding_bigot_known
		You are startled to hear her address you; that she would deign to dirty her mouth with your name.  And yet, even though her words are polite, you can still hear the disgust in her voice.
	*elseif ((ethnicity = "african") or (ethnicity = "choctaw"))
		Though you have never exchanged words with this individual, you can sense her distaste for you in the tone of her otherwise polite words.
	"…those of us who are not Senators are here as their guests.  Come, let us leave the Senator to his deliberations."

	"There are no deliberations happening here, @{heard_of_harding Quaestor.|ma'am.} There is only delay.  The Senator…"

	"Really, ${mr} ${surname}," she interrupts you again, "you must leave dear Samson…"

	"Leave him to do what, Elinor?"  The gravelly voice of Carothers inquires.
*else
	"Really, ${mr} ${surname}," she interjects, her voice in the pitch of a school marm remonstrating an errant child.
	*if harding_bigot_known
		You are startled to hear her address you…that she would deign to dirty her mouth with your name.
	*elseif (ethnicity = "african") or (ethnicity = "choctaw")
		Though you have never exchanged words with this individual, you can sense a distinct distaste for you in the tone of her words.
	"…it is not your place to question the Senator."

	"Then who will question him?  He makes a mockery…"

	"You tread on thin ice, whelp.  Who are you to speak to me in this way?"

	You pause a moment, considering your next words carefully.  When you open your mouth to speak, however, the gravelly voice of Carothers preempts you.  "$!{he} expresses concerns we all share, dear sister."  His voice drips with irony. 
*comment endif

Elinor Harding whirls around to confront Carothers.  She is not a small woman—no doubt drawn from good Scotch-Irish stock—but she is dwarfed by Carothers's giant frame.  She does not flinch though; if anything, she grows more solid as she prepares to confront @{heard_of_harding her broodmate|him}. "Yes, Apollo, I was suggesting to ${mr} ${surname} that ${he} leave Senator Partridge in peace."

"And you believe that Senator Partridge is incapable of voicing such concerns himself?"  The whole room is now watching the exchange.

"I am sure that he is perfectly capable, dear brother, but with such a weighty decision resting on his shoulders, I thought he might appreciate my intervention."

"Yes, I'm sure we all appreciate your interventions, Elinor."

"The conduct of ${mr} ${surname} was inappropriate."

*if carothers_rapport > 50
	"That's why I enjoy ${his} company so.  $!{he} says things sometimes that the rest of us are too polite to express."
*else
	"Yes, ${he} may be uncouth, but even the ill-behaved may serve some purpose."
*set carothers_rapport %+20
*set applethorp_rapport %+15

@{heard_of_harding Quaestor Harding|Elinor} glares at Carothers.  Then, suddenly, she smiles.  "It is really of no consequence to me, dear brother.  Come, don't we have other business to discuss?"

*if (intelligence > 2) and ((streetwise > 0) and ((status > 0) and (perception > 1)))
	*set knows_hardings_plan true
	*achieve perfidy
	Watching this, you finally put the pieces together. @{heard_of_harding Quaestor Harding|Elinor} is presumably blackmailing Partridge with something, thereby inducing him to prevent the Senate to coming to consensus. And due to your maneouverings, this intrigue has been revealed to the gathered vampires.
	
	Why Harding seeks to disrupt the Senatorial election is unclear, nor do you have any idea as to what the source of the blackmail may be. But its effects are now clear to you.
	
	*if promised_debt_from_bailey_over_partridge
		"I suppose I must thank you."
		
		Turning, you find Senator Bailey at your side.  "Thank me?"
		
		"Samson has been so despondent of late.  Now, at least, his secret is exposed and we can set about righting the matter. Whatever hold Harding has on him, we will work to undo." After a moment, he continues.
		*if debt_from_bailey
			*bug
		*elseif debt_to_bailey
			*set debt_to_bailey false
			"I suppose this absolves you of the debt that you owed to me."	
		*else
			*set debt_from_bailey true
			"I suppose that I now owe you a debt. So it was promised, so shall it be."
			
		You nod graciously. "Thank you, Senator."
			
		Bailey nods his head and excuses himself just as quickly as he appeared.
	*elseif bailey_rapport > 60
		"I suppose I should thank you."

		Turning, you find Senator Bailey at your side.  "Thank me?"
	
		"Samson has been so despondent of late.  Now, at least, his secret is exposed and we can set about righting the matter. Whatever hold Harding has on him, we will work to undo."

		"Then…you're welcome."
		
		Bailey nods his head and excuses himself just as quickly as he appeared.
	*if heard_of_harding = false
		*set heard_of_harding true
	*goto nights_end

You stand there, a bit bewildered.

*if (bailey_rapport > 60) or promised_debt_from_bailey_over_partridge
	*set knows_hardings_plan true
	*achieve perfidy
	*if heard_of_harding = false
		*set heard_of_harding true
	"I suppose I should thank you."

	Turning, you find Senator Bailey at your side.  "Thank me?"

	"Samson has been so despondent of late.  Now, at least, his secret is exposed, and we can set about righting the matter."

	"His secret is exposed?"

	"Yes.  That Quaestor Harding is the one manipulating him.  Next time, we shall be prepared to bring this matter to a resolution."

	"Quaestor Harding…" 
	*if promised_debt_from_bailey_over_partridge
		you begin, before Bailey interrupts.
		
		*if debt_from_bailey
			*bug
		*elseif debt_to_bailey
			*set debt_to_bailey false
			"I suppose this absolves you of the debt that you owed to me."	
		*else
			*set debt_from_bailey true
			"I suppose that I now owe you a debt. So it was promised, so shall it be."
		
		You nod graciously. "Thank you, Senator."
			
		Bailey nods his head and excuses himself just as quickly as he appeared.
	*else
		your words trail off, as Bailey has already left your presence.
*elseif lockridge_rapport > 60
	*set knows_hardings_plan true
	*achieve perfidy
	*if heard_of_harding = false
		*set heard_of_harding true
	"Well done, ${mr} ${surname}.  A bit brash for my tastes, but sometimes that is necessary."

	Turning, you find Senator Lockridge beside you; you've never seen an honest smile on his face.  "I'm sorry?"

	"You've solved the great mystery of the evening."

	"I…did what?"

	"You forced Quaestor Harding to expose herself.  She's the one that's been manipulating Senator Partridge, preventing him from committing himself to a side.  Now, we shall be prepared for the next election."

	"Yes, of course we will…" you reply, still somewhat bewildered, only to notice that the uncharacteristically jovial Lockridge has already moved on.
*elseif applethorp_rapport > 60
	*set knows_hardings_plan true
	*achieve perfidy
	"Thankee, $!{massa} ${surname}."

	"For what, Dido?"  The Quaestor's offspring is suddenly at your elbow.

	"Fo' wut you done dis' evenin'."

	You turn a few degrees, to better regard her; does she jest?  "And what is that?"

	"Shown us who been makin' a mess o' dese proceedin's.  It were Quaestah Hardin' who been mis-usin' Massa Pahtrige.  Ah thanks you, an' Ah is sho dat Apollah be thankin you too."

	You look at her, still a tad surprised.  "You're welcome, Dido."

	She puts a hand on your arm, a genuine gesture of friendship, before taking her leave of you.
*elseif santagostino_rapport > 60
	*set knows_hardings_plan true
	*achieve perfidy
	Chiara takes you by the elbow.  "Well done, ${given_name}."

	"Well done?"

	"Of course!"

	"What do you mean?"

	"You've exposed the culprit."

	"The culprit?"

	"Most everyone here has been vying for the new Senator of Memphis to be from their faction, the supporters of Stone and the supporters of Adonis.  But, for some reason, whenever the matter was near to resolution, Senator Partridge would begin to waver.  Your rather impolitic confrontation drew out Quaestor Harding, who has just exposed herself as the one pulling his strings."

	"And she prefers that the election remain unresolved?"

	"So it would seem."

	"But why?"

	"That I cannot say, dear ${given_name}."
*else
	It's as if something momentous has occurred, but no one has bothered to fill you in on the details.  The remaining candidates stand as one, acknowledging that the gathered vampires are saying their farewells.  Without explanation, the evening is over.

	*if perception > 4
		*set knows_hardings_plan true
		*achieve perfidy
		*if heard_of_harding = false
			*set heard_of_harding true
		Casting your consciousness throughout the room, you are finally able to divine the answer: the whole room was curious about the conduct of Senator Partridge—why he would refuse to resolve the election—and it was only your actions which forced Quaestor Harding to expose herself as the one controlling him.  For some reason—open to ongoing conjecture—she wants no one to be the Senator of Memphis.

		Now that the gathered vampires know what the obstacle is, they plan on being better prepared for the next caucus.
		
		The journey back home is swift.  You lay down for the day, wondering what the next few weeks will bring.
	*else
		You do your best to pick up on why the evening is ending so abruptly, but are sure of nothing.

		On your way out, Carothers goes so far as to squeeze your hand in a surprisingly familiar gesture.  You furrow your brow at him, and you think you almost see a smile.
		
		The journey back home is swift.  You lay down for the day, wondering what the next few weeks will bring.
		*if second_betrayal
			*set notice_partridge_betrayal true
	*finish Next

*label nights_end
*page_break
*if knows_hardings_plan
	*if heard_of_harding = false
		*set heard_of_harding true
	*if met_harding = false
		*set met_harding true
	The remaining candidates stand as one, relinquishing their chairs.  The attendees begin their farewells; Harding is clearly on the outside of these pleasantries. Several vampires adjourn to the adjoining room to @{(compassion < 50) murder|drain} one of the vessels before departing for the evening.

	Carothers squeezes your hand with unexpected familiarity during your goodbyes; you furrow your brow at him, and you think that you almost see a smile of gratitude.

	The journey back home is swift.  You lay down for the day, wondering what the next few weeks will bring.
*else
	As the night wears on, the frustration of the gathered vampires becomes palpable.  No consensus can be reached. 

	Eventually, the candidates all stand; their chairs are taken away, and the guests all begin their farewells. Several vampires adjourn to the adjoining room to @{(compassion < 50) murder|drain} one of the vessels before departing for the evening.

	You exchange your own where appropriate, finally bidding Apollo and Dido goodnight.  The journey back home is swift.  Soon, you lay yourself down for the day, wondering what the next few weeks will bring.
	*if second_betrayal
		*set notice_partridge_betrayal true
*page_break
*goto_scene memphis_second_intermission

*label allegiance_count
*set senator_count 10
*set r_count 0
*set cr_count 0
*if bowater_determined and bowater_revolutionary
	*set r_count +1
*if bowater_determined and (bowater_revolutionary = false)
	*set cr_count +1
*set r_count +1
*comment Bailey
*set cr_count +1
*comment Lockridge
*comment the below is for Simmons's voting.
*if simmons_waylaid
	*set senator_count -1
*if simmons_waylaid = false
	*set cr_count +1
*comment the below is for Davison's voting.
*if davison_waylaid
	*set senator_count -1
*if davison_waylaid = false
	*set r_count +1
*comment the below is for Santagostino's voting.
*set r_count +1
*comment the below is for Coffin's voting.
*if pickering_out
	*set r_count +1 
	*comment Coffin hates Lesczynski
*if pickering_out = false
	*set cr_count +1
*comment the below is to determine Ashmore's voting
*if ashmore_determined = false
	*if (ashmore_rapport >= 50) and (revolutionary_credentials >= 50)
		*set r_count +1
		*set ashmore_revolutionary true
	*if (ashmore_rapport < 50) and (revolutionary_credentials < 50)
		*set r_count +1
		*set ashmore_revolutionary true
	*if (ashmore_rapport >= 50) and (revolutionary_credentials < 50)
		*set cr_count +1
	*if (ashmore_rapport < 50) and (revolutionary_credentials >= 50)
		*set cr_count +1
*comment the below is for Bowater's voting
*if bowater_determined
	*goto post_bowater
*if (calkins_status = 3) and (independence > 30)
	*set bowater_determined true
	*if player_for_senator
		*set bowater_for_player true
		*goto post_bowater
	*if (calkins_rapport >= 50) and (revolutionary_credentials >= 50)
		*set r_count +1
		*set bowater_revolutionary true
	*if (calkins_rapport >= 50) and (revolutionary_credentials < 50)
		*set cr_count +1
	*if (calkins_rapport < 50) and (revolutionary_credentials < 50)
		*set r_count +1
		*set bowater_revolutionary true
	*if (calkins_rapport < 50) and (revolutionary_credentials >= 50)
		*set cr_count +1
*if calkins_status > 3
	*set bowater_determined true
	*if ashmore_revolutionary
		*set cr_count +1
	*if ashmore_revolutionary = false
		*set bowater_revolutionary true
		*set r_count +1
*if bowater_determined = false
	*if r_count >= cr_count
		*set cr_count +1
	*if r_count < cr_count
		*set r_count +1
*label post_bowater
*comment the below is for Timmers' voting
*if r_count >= cr_count
	*set cr_count +1
	*goto ashmore_rebalance
*if r_count < cr_count
	*set r_count +1
	*set timmers_cr false
*label ashmore_rebalance
*comment the next four sections are to re-balance too-excellent politicking on the player's part.
*if (r_count < (cr_count-1)) and (simmons_waylaid = false)
	*set simmons_waylaid true
	*set cr_count -1
	*set santagostino_waylays_simmons true
	*goto partridge_before
*if (r_count > (cr_count+1)) and (davison_waylaid = false)
	*set davison_waylaid true
	*set r_count -1
	*set lockridge_waylays_davison true
	*goto partridge_before
*if (r_count > (cr_count+1)) and ((ashmore_determined = false) and (ashmore_revolutionary = true))
	*set ashmore_determined true
	*set ashmore_revolutionary false
	*set r_count -1
	*set cr_count +1
	*goto partridge_before
*if (r_count < (cr_count - 1)) and ((ashmore_determined = false) and (ashmore_revolutionary = false))
	*set ashmore_determined true
	*set ashmore_revolutionary true
	*set r_count +1
	*set cr_count -1
	*goto partridge_before
*comment the below is for Partridge's voting
*label partridge_before
*if (r_count < cr_count)
	*set r_count +1
	*return
*if (r_count = cr_count)
	*set partridge_uncommitted true
	*set partridge_betrayal false
	*return
*if (r_count > cr_count)
	*set partridge_uncommitted false
	*set partridge_betrayal true
	*set cr_count +1
*return

*label allegiance_count_during
*if seat_relinquished and bowater_for_player
	*set bowater_for_player false
	*set bowater_determined false
*set senator_count 10
*set r_count 0
*set cr_count 0
*if bowater_determined and bowater_revolutionary
	*set r_count +1
*if bowater_determined and (bowater_revolutionary = false)
	*set cr_count +1
*set r_count +1
*comment Bailey
*set cr_count +1
*comment Lockridge
*comment the below is for Simmons's voting.
*if simmons_waylaid
	*set senator_count -1
*if simmons_waylaid = false
	*set cr_count +1
*comment the below is for Davison's voting.
*if davison_waylaid
	*set senator_count -1
*if davison_waylaid = false
	*set r_count +1
*comment the below is for Santagostino's voting.
*set r_count +1
*comment the below is for Coffin's voting.
*if pickering_out
	*set r_count +1 
	*comment Coffin hates Lesczynski
*if pickering_out = false
	*set cr_count +1
*comment the below is to determine Ashmore's voting
*if ashmore_determined = false
	*if (ashmore_rapport >= 50) and (revolutionary_credentials >= 50)
		*set r_count +1
		*set ashmore_revolutionary true
	*if (ashmore_rapport < 50) and (revolutionary_credentials < 50)
		*set r_count +1
		*set ashmore_revolutionary true
	*if (ashmore_rapport >= 50) and (revolutionary_credentials < 50)
		*set cr_count +1
	*if (ashmore_rapport < 50) and (revolutionary_credentials >= 50)
		*set cr_count +1
*comment the below is for Bowater's voting
*if bowater_determined
	*goto post_bowater_during
*if (calkins_status = 3) and (independence > 30)
	*set bowater_determined true
	*if player_for_senator
		*set bowater_for_player true
		*goto post_bowater_during
	*if (calkins_rapport >= 50) and (revolutionary_credentials >= 50)
		*set r_count +1
		*set bowater_revolutionary true
	*if (calkins_rapport >= 50) and (revolutionary_credentials < 50)
		*set cr_count +1
	*if (calkins_rapport < 50) and (revolutionary_credentials < 50)
		*set r_count +1
		*set bowater_revolutionary true
	*if (calkins_rapport < 50) and (revolutionary_credentials >= 50)
		*set cr_count +1
*if calkins_status > 3
	*set bowater_determined true
	*if ashmore_revolutionary
		*set cr_count +1
	*if ashmore_revolutionary = false
		*set bowater_revolutionary true
		*set r_count +1
*if bowater_determined = false
	*if r_count >= cr_count
		*set cr_count +1
	*if r_count < cr_count
		*set r_count +1
*label post_bowater_during
*comment the below is for Timmers' voting
*if r_count >= cr_count
	*set cr_count +1
	*goto ashmore_rebalance_during
*if r_count < cr_count
	*set r_count +1
	*set timmers_cr false
*label ashmore_rebalance_during
*comment the next four sections are to re-balance too-excellent politicking on the player's part.
*if (r_count > (cr_count + 1)) and ((ashmore_determined = false) and (ashmore_revolutionary = true))
	*set ashmore_determined true
	*set ashmore_revolutionary false
	*set r_count -1
	*set cr_count +1
	*goto partridge_during
*if (r_count < (cr_count - 1)) and ((ashmore_determined = false) and (ashmore_revolutionary = false))
	*set ashmore_determined true
	*set ashmore_revolutionary true
	*set r_count +1
	*set cr_count -1
	*goto partridge_during
*label partridge_during
*comment the below is for Partridge's voting
*if (r_count < cr_count)
	*set r_count +1
	*return
*if (r_count = cr_count)
	*set partridge_uncommitted true
	*set partridge_betrayal false
	*return
*if (r_count > cr_count)
	*set partridge_uncommitted false
	*set partridge_betrayal true
	*set cr_count +1
*return

*label meet_lesczynski
*set met_lesczynski true
"Good evening, sir, do you have a moment?"

"Of course!  Please," he says, gesturing for you to come closer.

"If you would, allow me to introduce myself.  I am ${given_name} ${surname}, a citizen of this city."

"A pleasure.  I am Ascher Lesczynski.  As you can see, I hope to be your Senator soon."

"That is, in fact, what I wish to speak to you about…"
*return

*label meet_malloy
*set met_malloy true
"Good evening!" you begin.
	
"Good evenin' ta ya!" she replies heartily.

"Please, allow me to introduce myself.  I am ${given_name} ${surname}, a citizen of Memphis."

"A pleasure, ${mr} ${surname}.  I am hopin' ta be a citizen here as well!"

"Actually that's what I wanted to talk to you about," you begin.

"At yer service," she replies.
*return

*label meet_pickering
*set met_pickering true
When the moment seems right, you approach and introduce yourself to Mr. Pickering.  He is a man of English descent, with brown hair and eyes and a well-kept goatee that hides what would otherwise be a weak chin.  His hair is parted to side, somewhat low for your taste.  Moreover, he is not shy about his desire to win the election, and is eager to answer any questions you may have for him.
*return

*label check_senators_achieve
*if (met_ashmore) and (met_bailey and (met_bowater and (met_coffin and (met_davison and (met_lockridge and (met_partridge and (met_chiara and (met_simmons and (met_timmers)))))))))
	*if achieve_meet_senators = false
		*set achieve_meet_senators true
		*achieve tensenators
	*return
*else
	*return