*comment ñáéç…—
*hide_reuse
*advertisement
*temp clotho_attitude "empty"
*temp lover "empty"
*temp fraternity "a…fraternity"
*temp diet false
*temp pursuing_clotho false
*temp notice_hester false
*if male = false
	*set fraternity "an…organization"
*if (avoided_new_orleans or (invitation_to_hebert_ignored = true)) and (compassion <= 60)
	*set pursuing_clotho true
	It was during the early volleys of the Barnum and Thompson affair that you first noticed her.  Her writings in the Daily Appeal during the winter were clear and concise, calling for the equal treatment of white and colored teachers.  When her writing turned to an emotional appeal, however, her words evoked the lives and tribulations of her subjects; the portraits of injustice that she painted with her words moved even you to weep.
	
	The letters are signed with a pseudonym: Clotho.
	*if love_hope
		*set lover "Silas"
		And though your heart still aches from the loss of Silas, the words of this Clotho @{literate leap off the page at you, tugging at the desiccated remains of your heart.|ring in your ears when read to you by Franklin. They rebound and resound and tug at the desiccated remains of yoru heart.}
	*elseif flirting_with_jesse
		*set lover "Jesse"
		And though you have shared intimacies with Jesse, there is something different about the budding passion for this mortal.  Her words @{literate leap off the page at you, tugging at the desiccated remains of your heart.|ring in your ears when read to you by Franklin. They rebound and resound and tug at the desiccated remains of yoru heart.}
	*elseif flirting_with_withers
		*set lover "Samantha"
		And though you have flirted with Samantha, there is something different about the budding passion for this mortal.  Her words @{literate leap off the page at you, tugging at the desiccated remains of your heart.|ring in your ears when read to you by Franklin. They rebound and resound and tug at the desiccated remains of yoru heart.}
	*elseif flirting_with_chiara
		*set lover "Chiara"
		And though you have flirted with Chiara, there is something different about the budding passion for this mortal.  Her words @{literate leap off the page at you, tugging at the desiccated remains of your heart.|ring in your ears when read to you by Franklin. They rebound and resound and tug at the desiccated remains of yoru heart.}
	*else
		And though your desiccated heart has long lain dormant, the words of this woman have stirred it to life.
	
	There is a trial tonight: Mrs. Thompson's competency as a teacher is being decided by the Memphis School Board.  Despite the January cold, you suspect that this Clotho will attend.
	*choice
		*if lover != "empty"
			#And betray my affection for ${lover}?  Not a chance.
				*set compassion %-10
				The School Board decides against Thompson.  The letters to the Daily Caller continue for a while yet, but cease once Barnum is replaced during the summer and Thompson is rehired.  You are a little saddened at this conclusion, but it is no doubt for the best.  No good could come from such a pursuit.
				*finish Next
			#Out of sight, out of mind.  Clotho, here I come.
				*set compassion %+5
				You dress yourself in appropriate attire and set out to meet this [i]provocateuse[/i].
				*goto identify_clotho
		*if lover = "empty"
			#How can I turn away from something that has set my heart aflutter?
				*set compassion %-10
				You dress yourself in appropriate attire and set out to meet this [i]provocateuse[/i].
				*goto identify_clotho
		#I'm really just going because I want to learn more about the Barnum and Thompson affair.
			*set anachronism %+10
			*set pursuing_clotho false
			You dress yourself in appropriate attire and set out for the meeting of the School Board. The trial should be an event to remember.
			*goto board_ignoring_clotho
		#What interest do I have in these mortal affairs?
			*set anachronism %-5
			*set compassion %+10
			*set shepherd_credentials %-5
			Despite your best efforts, you cannot entirely ignore the events unfolding around you in Memphis.  The School Board decides against Thompson.  The letters to the Daily Caller continue for a while yet, but cease once Barnum is replaced during the summer and Thompson is rehired.  You are a little saddened at this conclusion, but it is no doubt for the best.  No good could come from such a pursuit.
			*finish Next
*elseif barnum_thompson_plot
	The conflict between the supporters of Superintendent Barnum and Mrs. Thompson has continued for months now, with supporters and detractors arguing back and forth in the columns of the local newspapers.  Tonight, there will be a trial to determine Thompson's competency as a teacher by the Memphis School Board.
	*label board_ignoring_clotho
	
	A variety of individuals stand and offer their opinions on the matter at hand, the most notable coming from Minor Meriwether.
	*gosub minor_speech
	
	Unfortunately, when all is said and done, Superintendent Barnum disregards both the speeches in her defense as well as the finding of the school board and fires Mrs. Thompson from her position at the Clay Street school.
	*gosub hester_speaks
	
	*gosub pursue_hester
	*finish Next
*else
	*goto_scene memphis_first_intermission_kkk

*label hester_speaks
There are loud shouts of disapproval from the attendees, but several private watchmen maintain order in the room.
*if (discretion > 65) and pursuing_clotho
	There are some other brief matters before the board, but you pay them no mind, and soon enough the meeting is adjourned.  Seeing the discontent on the faces in the room, Superintendant Barnum flees before a riot breaks out.
	*return
*else
	*set notice_hester true
	
	Before the meeting is fully adjourned, however, a matronly black woman stands, rapping her cane on the ground for silence.  Barnum extends the floor to her.
		
	"Superintendent Barnum, weren't there one more thing on the agenda for this evening?" she inquires.
	
	"Ms. Carothers, I'm sorry, but there are simply no funds for a school for the blind.  It is not even a matter that we can entertain.  Now, this meeting is adjourned," he says with a strike of his gavel on its block.  He stands and slips away through a rear door while the watchmen guard his exit.
	*return

*label identify_clotho
Arriving at the Clay Street School, you consider your strategy for the evening.  Discovering the identity of Clotho will be a challenge.

How do you hope to identify her?
*choice
	*if perception > 1
		*selectable_if (perception > 4) #I will hold back and attempt to divine her identity with my supernatural powers of perception.
			*set discretion %-5
			*set clotho_attitude "surprise"
			Scanning the thoughts of the crowd, it takes you most of the night to pick out her thoughts from the background noise.  

			Several individuals give speeches during the evening, the most notable coming from Minor Meriwether.
			*gosub minor_speech

			Unfortunately, when all is said and done, Superintendent Barnum disregards both the speeches in her defense as well as the finding of the school board and fires Mrs. Thompson from her position at the Clay Street school.
			*gosub hester_speaks
			By that time, however, you are certain that you have your advocate.

			Approaching her, you are struck by her beauty.  Clearly of mixed descent, she has a tawny skin—uncommon this far north—and a mop of unruly, kinky hair.  All at once, you wonder how you ever could have imagined anyone else in that crowd as being Clotho.
			*goto meet_clotho
	#I will argue against Mrs. Thompson, hoping to provoke a response from Clotho.
		*set discretion %+15
		*set clotho_attitude "angry"
		Several other individuals give speeches during the evening, the most notable coming from Minor Meriwether.
		*gosub minor_speech

		Soon enough, though, it is your turn.  The room falls to silence as you begin to speak.  By the time you are finished, it is clear that Mrs. Thompson is as well. Without further hesitation, Superintedant Barnum announces the termination of Mrs. Thompson.		
		*gosub hester_speaks

		It only takes a few moments before one of the most striking women you have ever seen storms up to you.  Clearly of mixed descent, she has a tawny skin—uncommon this far north—and a mop of unruly, kinky hair.  All at once, you wonder how you ever could have imagined anyone else in that crowd as being Clotho.
		*goto meet_clotho
	*if (memphis_reception_planner != given_name) and (memphis_reception_planner != "Dido")
		#In the hopes of provoking Clotho, I will fashion an argument against Mrs. Thompson for ${memphis_reception_planner} to give in my place.
			*set discretion %-15
			*set clotho_attitude "angry"
			Of course, your proxy is not the only one granted the floor this evening.  The most notable speech is given by Minor Meriwether.
			*gosub minor_speech

			Soon enough, though, it is ${memphis_reception_planner}'s turn.  The room falls silent as she begins to speak.  By the time she is finished, it is clear that Mrs. Thompson is as well.  Without further hesitation, Superintedant Barnum announces the termination of Mrs. Thompson.
			*gosub hester_speaks
	
			It is only a few moments before one of the most striking women you have ever seen storms up to ${memphis_reception_planner} and begins to harangue her.  ${memphis_reception_planner}, somewhat at a loss, stammers under the assault.  She does not have long to wait; you waste no time in closing the distance between you and your quarry.  Clearly of mixed descent, she has a tawny skin—uncommon this far north—and a mop of unruly, kinky hair.  All at once, you wonder how you ever could have imagined anyone else in that crowd as being Clotho.
			*goto meet_clotho
	#I will use the opportunity to question the other attendees in the hopes of learning her identity.
		*set discretion %-15
		*set clotho_attitude "surprise"
		During the trial, Minor Meriwether stands and delivers a speech.
		*gosub minor_speech

		It takes some persuasion, but by the time Mrs. Thompson has been fired from her position at the Clay Street school, you are able to coax Clotho's identity from one of the schoolteachers that stands near the door.  Within the Beale community, her identity is an open secret.

		Approaching her, you are struck by her beauty.  Clearly of mixed descent, she has a tawny skin—uncommon this far north—and a mop of unruly, kinky hair.  All at once, you wonder how you ever could have imagined anyone else in that crowd as being Clotho.
		*goto meet_clotho
	#I argue for Mrs. Thompson, hoping to elicit some support from Clotho.
		*set discretion %+20
		*set clotho_attitude "favor"
		When you register for the right to address the room, you see that there are several speakers before you, one of whom is Minor Meriwether.
		*gosub minor_speech

		Soon enough, though, it is your turn.  When Barnum raps his gavel for order, the room slowly settles into silence.
		*if ethnicity = "african"
			You sense that the whites in the room are particularly interested in the words of this eloquent negro.  Such individuals could be a threat, after all.

			*label clotho_approaches
			Your words certainly move the gathered assemblage, but to no avail.  Superintendant Barnum disregards you and the recommendation of the teaching committee and fires Mrs. Thompson.
			*gosub hester_speaks

			It only takes a few moments before one of the most striking women you have ever seen approaches you.  Clearly of mixed descent, she has a tawny skin—uncommon this far north—and a mop of unruly, kinky hair.  All at once, you wonder how you ever could have imagined anyone else in that crowd as being Clotho.
			*goto meet_clotho
		*elseif ethnicity = "choctaw"
			You sense that both the whites and the blacks in the room are particularly interested in the words of this Indian.  Such a display of interest in municipal affairs is entirely unique.
			*goto clotho_approaches
		*elseif priest
			You sense the uniform surprise amongst the blacks and the whites that a Catholic priest would stand up and defend Mrs. Thompson.
			*goto clotho_approaches
		*else
			You sense that the whites and the blacks in the room are interested in the words of this strange white person who would so eloquently defend a negro.  Such an expression of interracial concern is looked upon with suspicion by many.
			*if joined_kkk and (perception > 0)
				Of course, Meriwether nods along with your comments, happy to see another brother arguing the cause.
			*goto clotho_approaches
	*if (memphis_reception_planner != given_name) and (memphis_reception_planner != "Dido")
		#I fashion an argument on behalf of Mrs. Thompson, for ${memphis_reception_planner} to deliver in my place, in the hopes of eliciting the support of Clotho.
			*set discretion %-15
			*set clotho_attitude "favor"
			Of course, your proxy is not the only one granted the floor this evening.  The most notable speech is given by Minor Meriwether.
			*gosub minor_speech

			Soon enough, though, it is ${memphis_reception_planner}'s turn.  The room falls silent as she begins to speak.  Her words certainly move the gathered assemblage, but to no avail.  Superintendant Barnum disregards you, your proxy, Minor Meriwether, and even the recommendation of the teaching committee—instead electing to terminate Mrs. Thompson.
			*gosub hester_speaks
	
			It is only a few moments after the meeting is adjourned that a woman approaches ${memphis_reception_planner}.  ${memphis_reception_planner} occupies the stranger as you approach—an individual who has to be one of the most striking women you have ever laid eyes on.  Clearly of mixed descent, she has a tawny skin—uncommon this far north—and a mop of unruly, kinky hair.  All at once, you wonder how you ever could have imagined anyone else in that crowd as being Clotho.
			*goto meet_clotho

*label minor_speech
To the surprise of many, he gives an impassioned defense of Mrs. Thompson, arguing that Superintendent Barnum has overstepped his bounds and that the principal should be the one adjudicating this matter.  When he finishes, there are cheers from the blacks in the room.  They seem to have taken heart from the words of the well-known former Confederate.
*return

*label meet_clotho
"Please, allow me to introduce myself," you begin.

@{(clotho_attitude = "angry") "I don't think I want to hear anything else from you!"|"Yes, please do."}

"I am ${mr} ${given_name} ${surname}.  And I must say, your recent letters to the Daily Appeal have caught my attention."

*if clotho_attitude = "angry"
	"And this is how you introduce yourself to me?"

	"Come now, you knew as well as I did that Mr. Barnum had no intention of retaining Mrs. Thompson.  My words made not the least difference in the world."  You are bluffing, but no reason to let her know that.

	She stews at you in resentment.  Perhaps you were not wrong?
*if clotho_attitude != "angry"
	"I'm flattered, ${sir}, but I am still unsure as to what this is all about."
	*line_break
	*line_break
"The truth of the matter is that I wanted to meet this Clotho, who so moved me with her appeals to my better nature."

At this, a figure who had been hovering nearby finally interjects himself into the conversation.  "Are you all right, my dear?" he inquires.

"Yes, Robert.  ${mr} ${surname} and I were just discussing some recent editorials in the Daily Appeal.  Please, ${mr} ${surname}, may I introduce Robert Reed Church."  You ${bow} in greeting.
*set met_robert_reed_church true

"A pleasure," you say gracefully.

"You do me too much honor.  Now, if you will excuse me…" he says.  Before he goes, though, he leans in to whisper something in Clotho's ear and concludes with a kiss to her cheek. @{(perception > 1) Sharpening your senses, you catch him suggesting to her that she conclude this interview quickly, that they have places to go.|}

She smiles at him as they part.  He disappears into the crowd, and she turns back to you.  "Go on.  I am listening."

"Perhaps you could show me something of these worlds you describe.  And in return, I may be able to aide you in your endeavors."

"You have come so far, I do not see how I could turn you away."

"Tomorrow night, then?"

@{(clotho_attitude = "angry") Still suspicious, she nods silently.|"Very well. Tomorrow."}
*if notice_hester
	Now then, perhaps someone else here attracted your attention?
	*gosub pursue_hester
*page_break
*set anachronism %+10
*temp dead_flesh false
Carrying a lantern in the darkness, Clotho is easy to spot in front of the squat brick building known as the Clay Street school.  You are unsure as to why she has a key—she is not a teacher here—but you do not bother to ask.  She takes you on a tour of the facilities, pointing out the virtues of the new building for colored students.
*choice
	#I listen patiently; I want to know what it is that moves her.
		*set compassion %-20
		She turns to the matter closest to her heart: how the teachers are paid different amounts depending on their race and gender.  She laments how the colored women must still take in laundry to support their families because their salary is not enough.  How, then, are they to tend to the children of others if they cannot tend to their own families?  Moreover, she makes it clear that the patronizing attitude of the northern missionaries is most unwelcome; the community wants the teachers to be black so that the students are not made to feel inferior by virtue of the color of their skin.

		"And what is your interest in all this?"

		"My family comes from New Orleans, where the races lived in harmony before—and even after—the Louisiana Purchase.  I see no reason why that sense of peace cannot exist here.  But to do that, we must make everyone equal."

		"I think time and distance have shrouded your view of these things."

		"Does it matter?  It is the idea that inspires us to move forward.  Without a vision, how can we have direction?  Without a vision, what can we say that we have left to our children?  Real or not, that idea of a New Orleans where the races lived in harmony, it gives us in the mud of Memphis something to strive for.  What vision do you work towards?"

		You pause to consider this question.  It is one that has certainly troubled you over the decades.
		*choice
			#"To find a love that will stir my frozen heart."
				*set compassion %-25
				"Love?  And you chide me for a clouded view of the world."

				You scowl at her; apparently, you are not the only cynic in the room.  Perhaps a change of topic is in order.
				*goto clothos_name
			#"To drink blood as sweet as yours." Enough talking; it's time to feed.
				*set discretion %+10
				You have had enough of her sermonizing.
				*goto feed_clotho
			#"I belong to ${fraternity} to which I am obliged.  In time, I will no doubt see benefit from this association, but for the time being, my efforts are bent to furthering its causes."
				*set independence %+20
				"Don't you see?  You dedicate yourself to something larger than yourself.  You and I are not so different."

				You try not to laugh out loud at this.  "Perhaps not."

				She glares at your smothered mirth.  You decide to change the subject.
				*goto clothos_name
			#"Though you may find it distressing, I must confess, it is wealth that animates me."
				*set discretion %+10
				*set compassion %+10
				"Wealth?"

				"Truly."

				"But…I do not understand."

				@{(compassion < 50) "There is only one thing that can keep the wolves at bay…one thing that can keep your home warm at night…one thing that can protect your offspring from the depredations of your neighbors: gold."|"Money is power.  And power is what makes the world turn, as they say."}

				Clotho is clearly surprised by your response.  "I suppose I should be grateful for your honesty."

				"There is so little of it in this world."  You pause a moment, considering.  "Tell me something."

				"What is that?"

				*goto clothos_name
			*if (compassion < 60) #"I have…lost something of myself. Become something I wish I were not. I hold out hope that this can be undone."
				*set compassion %-10
				She looks you in the eye. "Did you fight for the Confederacy?"
				
				You let out a laugh. "No, I did not fight for the Confederacy."
				
				"Then I am sure that whatever you did can be forgiven."
				
				"It will not be as easy as that."
				
				"This country just fought a war over the possession of my body, and is now on the road to setting things right. If this thing is possible, then isn't everything?"
				
				"I hope with all my heart that you are right," you say with a melancholy smile.
				*goto clothos_name
			*if (creation > 1) #"I am an artist. I live to create."
				*set discretion %+10
				"An artist? Do you paint?"
				
				"Paint, sculpt, @{literate write, |}sing, perform…I have done it all."
				
				"I had no idea."
				
				"My audiences tend to be small."
				
				"Perhaps some day you will invite me to witness your talent."
				
				"Perhaps so," you reply with a smirk.
				*goto clothos_name
			*if sire_alive and (sire_rapport > 45)
				#"I have a…my father…to whom I am indebted.  I struggle to honor the faith he has placed in me."
					*set compassion %-10
					*set independence %+10
					*set sire_rapport %+10
					"That is good of you to be so committed to your family."

					"I can't say the commitment is entirely voluntary, but it is good of you to say so."

					"Parents do have a way of twisting you to their will, don't they?" she says with a grin.

					"Tell me something."  She cocks her head at you, waiting.
					*goto clothos_name
			*if jesse_is_broodmate and (jesse_rapport > 45)
				#"I have a…a brother…about whom I care deeply.  I hope that, one day, we can live in harmony."
					*set jesse_rapport %+10
					*set independence %+10
					*set compassion %-10
					"That is good of you to be so committed to your family."

					"Tell me something."  She cocks her head at you, waiting.
					*goto clothos_name
			*if jesse_is_broodmate and (jesse_rapport < 40)
				#"I have a…a brother…who antagonizes me constantly.  Before it is all over, I hope to put him in his place."
					*set jesse_rapport %-10
					*set compassion %+10
					*set discretion %+10
					"That is unfortunate that you and your brother are not closer."

					"It is his own fault.  He is drunk on power and delights in making others miserable."

					"You must overstate the matter."

					Before you reveal something you shouldn't, you decide to change the topic.
					*goto clothos_name
			*if revolutionary_credentials > 40
				#"There is a cause to which I have committed myself.  A struggle for freedom.  I exist to further this cause."
					*set revolutionary_credentials %+5
					*set discretion %+10
					Clotho brightens at your claim.  "To live for something greater than yourself, that is the only reason to live."

					"Tell me something," you begin.  She cocks her head expectantly.
					*goto clothos_name
			*if revolutionary_credentials < 60
				#"There are dangerous ideas spreading amongst my peers.  I have joined with those who remain loyal to their fellows."
					*set revolutionary_credentials %-5
					*set discretion %+10
					Clotho seems disappointed by this.  "Sometimes, though, new ideas need to be spread."

					Sensing that the conversation could quickly go south from here, you decide to change the subject.
					*goto clothos_name
			*if (religious_tradition != "pagan")
				*if priest or ((discretion > 35) and (rationalism > 50))
					#"To do God's work here on earth."
						*set rationalism %+20
						*set discretion %+10
						*set shepherd_credentials %-10
						"I had not expected those particular words to come from your mouth, ${mr} ${surname}."
	
						"I am full of surprises."
	
						"Do not make light of such things.  For a moment there, I thought you might have had some honor."
	
						"You are right.  Such things should not be spoken of in jest."  She calms at this peace offering.  Now, to change the subject.
						*goto clothos_name
				*if priest or ((compassion < 60) and (rationalism > 50))
					#"To redeem myself in the eyes of God."
						*set compassion %-10
						*set rationalism %+20
						"Are your crimes so great?"
	
						"I could not begin to enumerate them, dear Clotho."  Her gaze softens.  Your self-reproach clearly attracts her.  It seems a change of topic is in order.
						*goto clothos_name
			*if ethnicity = "choctaw"
				#"To bring honor to the spirits of my ancestors."
					*set rationalism %+5
					*set compassion %-5
					"But, your ancestors are dead. How will they ever know?"
					
					"It is not a matter of whether or not they know. I know."
					
					She smiles a soft smile. "I wish…I wish I could have known my ancestors." Her hand reaches out and touches yours ever so timidly. Upon touching your dead flesh, however, she recoils at its chill.
					*set dead_flesh true
					
					Quickly, you must change the subject:
					*goto clothos_name
	#I inquire after her relationship with Robert Reed Church.
		*set discretion %+5
		"Oh, Robbie?  He's a dear."
		
		"So I see."
		
		"He has dreams of being a millionaire one day."
		
		"And what is he today?"
		
		"In debt up to his ears, I believe.  But he has dreams of financing future schools like the Clay Street school."
		
		"Best of luck to him, I suppose."  You decide to change the subject to something less dangerous.
		*goto clothos_name
	#I've always dreamt of killing someone in a schoolroom.  It would provide quite a shock to the students in the morning.
		*set compassion %+20
		*set clotho_schoolroom true
		*if sod_plot = false
			*set sod_plot true
			*set sod_founder "church"
		You decorate the walls and furniture with her blood and leave the body parts strewn across the hallways.  You make sure to hide the eyes, toes, and tongue in a variety of secret spots; it may take weeks for all the bits to be discovered.  The horror will drag on, perpetuating the legend.
		*page_break
		The Beale community is shocked and horrified by the discovery the next morning.  The school is closed for a week while the building is scrubbed and a memorial service is held.  In the turmoil, the sudden cessation of letters from Clotho to the Daily Appeal goes mostly unnoticed.

		Of course, no one even thinks of attributing the murder to you.  Every few days for the next month, a short article appears detailing the latest grisly discovery, as one organ or another is uncovered.
		*page_break
		*goto_scene memphis_first_intermission_continued 
	#Enough prattle!  Time to feed.
		*label feed_clotho
		*set compassion %+10
		Her blood is sweet, as expected.  Her surprise turns to fear, which soon turns to rapture.

		When you are finished, you leave her panting on the desk, begging for more.  They are always so pitiful when they beg for more.
		*page_break
		Within a few weeks, the letters to the Daily Appeal cease.  You hear no more of Clotho and her cause.
		*page_break
		*goto_scene memphis_first_intermission_continued

*label clothos_name
"Is Clotho your real name?"

"Of course not." @{dead_flesh She clearly wants to ask you about your lack of warmth, but you do not give her the opportunity with your rapid-fire questions.|}

"Then what is your real name?"

"Does it matter?  I think you want me to be Clotho.  A woman who reminds you that the yarn is there to be spun."

"How then did you come by this name?"

"It was the name of my great-aunt.  She was a a Voodoo Queen in New Orleans, before she came to an untimely end."

"I'm sorry to hear that.  What became of her?"

"No one knows.  We suspect that she came into conflict with Marie Laveau, but we cannot prove it.  My [i]mémé[/i] Chicory took my mother and aunts and uncles and came here, away from all that hoodoo."

"I myself @{avoided_new_orleans lived in|fled from} New Orleans, a long time ago…" you begin, before realizing the hazardous waters you just entered.  You quickly backtrack, trying to answer her questions as best you can without rousing any suspicions.

Too soon, she begins shifting uncomfortably.  A yawn finally clarifies things; realizing that the hour has grown late, you make the appropriate noises to excuse yourself.

In the nights that follow, you find yourself dwelling on the image of Clotho.
*fake_choice
	#Of course I wish to see her again!
	#Of course I wish to see her again…and better to do it soon, before she becomes aware of my bestial nature.
		*set compassion %+5
	#No, I didn't.
		Of course you didn't.  Those feelings were simply…indigestion.

		Within a few weeks, the letters to the Daily Appeal cease.  You hear no more of Clotho and her cause.
		*page_break
		*goto_scene memphis_first_intermission_continued

You compose a short note and have it sent to Clotho.  It invites her to a stroll along the bluffs with you.

A reply in the affirmative is swift.
*page_break
Arm in arm, the two of you stroll along the bluffs overlooking the river.  Clotho is clearly nervous, fearing the repercussions that might come from being seen here.
*if male = false
	*if (ethnicity = "african") or (ethnicity = "choctaw")
		The two of you are the only colored folk on the bluffs.  Whenever anyone seems like they might protest your presence, a glare from you sets them scurrying away.
	*else
		You calm her fears by pointing out that there is many a maiden in the city who keeps familiar company with her servants.  As long as she keeps close, there is no reason for anyone to think differently.
*elseif (ethnicity = "african") or (ethnicity = "choctaw")
	The two of you are the only coloreds on the bluffs.  Whenever anyone seems like they might protest your presence, a glare from you sets them scurrying away.
*else
	Your presence certainly does elicit stares of alarm: a white man and a colored woman, walking along the bluffs together?
After a time, she finally begins to relax, and the conversation becomes easier.

It covers a range of topics, and you do an admirable job of speaking much but saying little.  After all, the more of substance you say, the easier it is for someone to notice the little lies that don't quite fit together.

Instead, you learn of her life here in Memphis, growing up unchained but still confined to the black community; her joy at the declaration of freedom for all of her people; and the struggle in the wake of the war to realize those liberties.

The hour grows late, and she has clearly tired.  You escort her home, sending her inside with a kiss that nearly sets your heart to beating again.  As you turn towards your haven, a pall settles over the evening.  What can come of a love between a hunter and the hunted?
*temp chest "chest"
*if male = false
	*set chest "breast"
*temp intimate_with_clotho false
*page_break
A few nights later, you find yourself in a similar position, only the hour is not nearly as late.  Standing in her doorway, the two of you kiss passionately.
*choice
	*if knows_parts_dont_work
		#I will push her inside, feed from her, leave her lusting for more.
			*set discretion %+5
			*label lust
			*set intimate_with_clotho true
			She shivers at your touch.  In your passion, you let yourself believe that it is from pleasure and not from your flesh, which consumes the heat from the air around it.

			When the time is right, and she nears the heights of ecstasy, you sink your fangs into her thigh.  She thrashes beneath you, fear and pain soon overtaken by delight.

			When you have drunk your fill, you seal the wound with your spittle and then guide her head to rest on your ${chest}.  From there, she slips easily into a deep sleep.  You remain with her until the dawn, slipping away to your resting place and leaving her to wake alone.
			*goto gift
	*if knows_parts_dont_work
		#I let her guide me inside, and when the moment comes, I will feed from her…as gently as possible.
			*set discretion %-10
			*goto lust
	*if knows_parts_dont_work = false
		#I push her inside.  It is time to have my way with her.
			*set knows_parts_dont_work true
			*set discretion %+5
			*label surprise
			To your surprise, when the moment of intimacy arrives, you find that your parts do not work as they once did.
			*if (willpower = 1) and ((discretion > 50) and (compassion > 50))
				*set compassion %+10
				In frustration, you sink your fangs into the vein on the inside of Clotho's thigh.  You drink deeply, distantly aware that she is thrashing in ecstasy while her pulse pushes your heart into motion.  You drink and drink, and soon she grows still.  Soon enough, your heart stills as well, and the cold begins to settle in your bones once again.
				
				You clean your mouth on her sheets and seal the wound on her leg.  Looking around, you feel some amount of shame at your deeds, but some part of your mind is aware that your shame is not as great as it once would have been.
				*page_break
				Disposing of the body is no great task.  
				*label clotho_missing
				While Mr. Church does offer a reward for information regarding the disappearance of a young woman, no one steps forward to claim the reward.  Rumors abound regarding an affair with a steamboat captain and running away to St. Louis or New Orleans.  Soon enough, her disappearance is forgotten, another soul carried away by the river.
				*page_break
				*goto_scene memphis_first_intermission_continued
			*else
				*set intimate_with_clotho true
				You repress the shame and anger that boils in your chest.  Taking a moment to consider, you press your lips against hers, and then lower yourself between her legs.  Extending your fangs, you sink them into her thigh and drink slowly while she shudders in ecstasy.  Questions about your unresponsive flesh slip from your mind as Clotho's pulse pushes your heart into motion.  You do your best to draw out the experience, luxuriating in the sudden warmth that suffuses your body.
				
				All too soon, her breathing becomes shallow, and you tear yourself away from this font of pleasure.  Sealing the wound, you draw her close and hold her while she drifts into sleep.  When she wakes, it is long after the dawn has chased you away.
				*page_break
				*goto gift
	*if knows_parts_dont_work = false
		#I let her guide me inside.  It is time our love expressed itself.
			*set knows_parts_dont_work true
			*set discretion %-10
			*set compassion %-5
			*goto surprise
	#I take her inside and keep watch over her while she sleeps.
		*set discretion %-10
		She seems disappointed that your intentions are so chaste, but soon enough settles down to sleep.
		
		You remain with her until the dawn, watching her breathe slowly.  Her eyes flutter with her dreams, and you wonder if there has ever been anything so beautiful.  When she wakes, though, she finds you gone.
		*page_break 
		*goto gift
	#A kiss, and then away.
		*goto gift

*label gift
*temp bought_goose false
*temp goose_available false
*if (ethnicity = "choctaw") or ((ethnicity = "african") or ((ethnicity = "irish") or ((ethnicity = "scotch") or (ethnicity = "spanish"))))
	*set goose_available true
Several weeks have passed; you have seen Clotho regularly—if infrequently—in the interim.  Your next rendezvous approaches, and it occurs to you that she might like a gift.
*choice
	#I bring her flowers.
		*if wealth > 25
			*set wealth -25
		"Oh, how thoughtful!" she exclaims upon seeing the bundle of flowers you bear.  Only once she relieves you of them are you able to take a breath and inhale the scent of other flowers.  Looking around her apartment, you are stunned by the number of bouquets that are taking up every available surface, each one more ostentatious than the last.  Seeing your expression, she waves her hands in dismissal. "Oh, Mr. Church was simply expressing his gratitude."
		
		"His gratitude?"
		
		"Yes, for my work on behalf of the Clay Street school.  He is very interested in the advancement of our people."  
	*selectable_if (wealth > 100) #I bring her jewelry.
		What kind of jewelry?
		*choice
			#A trinket of no real value. It's more the thought that counts.
				*set wealth -100
				You arrive at Clotho's rented room, clutching her trinket in your hands.  When she opens the door, you present her with the gift.  She oohs and aahs over it, but seems to be going through motions she has practiced before.  Before the two of you step out for the evening, she opens a drawer to her bureau and drops the trinket inside; you try not to let your heart sink as you glimpse what must be a fortune in jewels therein reflecting the candlelight.
			*selectable_if (wealth > 1000) #Some pearl earrings.
				*set wealth -1000
				You arrive at Clotho's rented room, clutching her earrings in your hands.  When she opens the door, you present her with the gift.  She oohs and aahs over it, but seems to be going through motions she has practiced before.  Before the two of you step out for the evening, she opens a drawer to her bureau and drops them inside; you try not to let your heart sink as you glimpse what must be a fortune in jewels therein reflecting the candlelight.
			*selectable_if (wealth > 5000) #A necklace.
				*set wealth -5000
				You arrive at Clotho's rented room, clutching her necklace in your hands.  When she opens the door, you present her with the gift.  She oohs and aahs over it, but seems to be going through motions she has practiced before.  Before the two of you step out for the evening, she opens a drawer to her bureau and drops the necklace inside; you try not to let your heart sink as you glimpse what must be a fortune in jewels therein reflecting the candlelight.
			*selectable_if (wealth > 10000) #A ring.
				*set wealth -10000
				You arrive at Clotho's rented room, clutching her ring in your hands.  When she opens the door, you present her with the gift.  She oohs and aahs over it, but seems to be going through motions she has practiced before.  Before the two of you step out for the evening, she opens a drawer to her bureau and drops the ring inside; you try not to let your heart sink as you glimpse what must be a fortune in jewels therein reflecting the candlelight.
	*if goose_available and (wealth > 50)
		#I buy her a goose.  Whether she keeps it for the eggs or cooks it for Sunday dinner matters not.
			*set wealth -50
			*set bought_goose true
			Clotho does not try to hide her surprise and amusement when you arrive at her doorstep bearing a rather placid goose in your arms.  After the immediate surprise passes, she laughs and throws her arms around your neck, kissing you.  "I can't imagine a more perfect gift, my dear."
	#I don't think that Clotho wants any gifts.
		*set discretion %+5
		*set compassion %-10
		The choice of someone supremely self-confident.  Perhaps you are right.  The evenings together certainly don't diminish, despite the lack of confirmation by trinkets.		

It is not long before Clotho begins to indicate her desire that you meet her @{male family.|family, even if they will not accept the true depth of your relationship.} You put her off as long as possible, but as your affection increases, it becomes more and more challenging.  Finally, it seems you cannot escape a true answer for much longer.
*choice
	#"I am on a special diet for health reasons.  But I shall join you for the pleasure of your company."
		*set diet true
		*set compassion %+10
		*set discretion %-10
		*goto dinner
	#"I am on a special diet for health reasons, and I must decline the invitation, lest the food tempt me to break my fast."
		She nods in understanding, as that explains many of your peculiarities.

		You suggest a walk down by the water the night after the dinner.  She agrees and bids you goodnight.
		*goto revelation
	#"I would be happy to attend your family function."
		*goto dinner
	#"My presence is required out of the city that evening, but I do wish that I could attend."
		She is clearly distraught by your rejection.  It will take some effort to mend this.

		You suggest a walk down by the water the night after the dinner.  She agrees and excuses herself.
		*page_break 
		*goto revelation

*label dinner
She is thrilled by your acceptance and immediately begins to plan for the occasion.
*if diet
	Thankfully, your lie will help with the awkward questions.  You're sure that she will clear the way for you long before the night in question.
*else
	Part of you begins to worry about how you will avoid the impeding questions.
*page_break
A few nights later, the fateful night arrives.  As you make your way to Clotho's family's home, you wonder whether the condemned suffer as much as you.

You are somewhat surprised to find her family large and welcoming.
*if ethnicity != "african"
	The color of your skin does not go unnoticed, but they are gracious enough to overlook it.

*if diet
	When dinner is served, it takes some wrangling with Clotho's mother to convince her that you, in fact, cannot eat what she has prepared, but Clotho asserts the severity of your condition, and finally the mother relents.

	The rest of the night passes without incident; it is the closest you have felt to life since your death.

	After dinner, you suggest a walk by the river.  She takes your hand and says that she would like nothing better.
	*page_break
	*goto revelation
*else
	When dinner is served, you find yourself forced to make a decision.  It has been some time since you have tried to consume human food; the last time did not go so well.
	*choice
		#I decline the food.
			*set compassion %+5
			The family is offended by your rejection of their comestibles.  The dinner passes in mostly awkward silence.

			When the dinner is over, you ask Clotho to take a walk with you by the river.  Though confused, she accepts.
			*page_break
			*goto revelation
		#I eat anyway.
			*set discretion %-5
			*label forced_to_eat
			*if willpower > 2
				Through a supreme act of will, you manage to swallow enough to make a show of enjoyment.  Amidst the general revelry, your austerity goes unnoticed.  The food tastes of ashes and offers you no pleasure.

				The rest of the night passes without incident; it is the closest you have felt to life since your death.  Despite the roiling of your stomach.

				*label after_dinner
				After dinner, you suggest a walk by the river.  She takes your hand and says that she would like nothing better.

				Before the two of you depart, you make your way to the privy and empty your stomach of its contents.  Miraculously, you manage to keep your clothing unsoiled.
				*page_break
				*goto revelation
			*else
				You do your best to swallow the food, but within moments you are rushing from the table, hand to your mouth.

				Clotho rushes after you, only to find you retching in the bushes.  You make some excuse relating to a stomach flu.

				When the retching is finished, you suggest a walk by the river.  Once you assure her that you are capable of such a constitutional, she agrees.
				*page_break
				*goto revelation
		#I try to distract the other guests, so that they do not notice that I am not eating.
			*set discretion %-10
			*if stealth >= 4
				Using your powers of stealth, you are able to deflect their thoughts from the contents of your plate.  Dinner passes without incident, and they all seem quite charmed by your conversation skills.
				
				*goto after_dinner
			*elseif (charm >= 4)
				Clothos's family is utterly charmed by your stories…so much so that they pay no mind to the untouched plate before you.
				
				*goto after_dinner
			*elseif (charm >= 3) and ((agility >= 2) and (shapeshifting > 0))
				Combining your quick wit with your nimble fingers, you manage to distract the other diners with your stories while slipping bits of food to the dog under the table.  Everyone comes away from the table satisfied—especially the pup.
				
				*goto after_dinner
			*else
				Despite your dissimulations, the looks of disapproval from Clotho's grandmother are too much.  Unwilling to further humiliate her, you careful gather a spoonful of potatoes and guide it towards your mouth.
				*goto forced_to_eat

*label revelation
Gazing out over the Mississippi, you let the evening breeze take your thoughts to fairer shores, where things like your ravening hunger do not tinge every hope with blood and misery.  Walking arm-in-arm with Clotho, you let yourself contemplate things which your rational mind knows are not possible.

Stopping at a gazebo, you draw her inside.  The wisteria vines offer some semblance of protection from the bracing wind, but still lacking their spring foliage and finding no comfort in your proximity, Clotho shivers audibly beneath her woolen clothes.  You make noises of concern, but your fear of exposure prevents you from holding her tight.  At a distance, she may still pretend that your flesh does not siphon the heat from the air around you.

Of late, Clotho has been pressing you about the infrequency of your visits, your nocturnal nature, and your apparent lack of an appetite.  Looking into her eyes, you feel that a resolution must be found, and soon.
*choice
	*selectable_if (compassion > 25) #I drink her dry.  That will explain everything.
		When you bare your fangs, Clotho recoils in horror.
		*if charm > 3
			The power of your gaze stops her in her tracks, and she finds herself unable to move or look away as you glide towards her.  When your fangs sink into her neck, she exhales deeply and collapses into your arms.
			
			You take your time draining her, and when you have finished, you dispose of her body so that it will not be found.
			*page_break
			*goto clotho_missing
		*else
			Before she can get far, however, you close the distance between the two of you.  Holding her fast, you sink your fangs into her neck.  She exhales deeply and collapses into your arms.
			
			You take your time draining her, and when you have finished, you dispose of her body so that it will not be found.
			*page_break
			*goto clotho_missing
	#"I do not love you, Clotho."
		*if intimate_with_clotho
			She draws up stiffly.  "And our nights together?"
			
			"They meant nothing.  And your intrusions into my life of late have been most unwelcome."
			
			You sense the clenching of her jaw.  "I see.  Then I suppose that we are done here?"
			
			Without waiting for an answer, she turns and leaves you alone in the gazebo.
			*page_break
			Clotho disappears from Memphis a few weeks later.
			*goto clotho_missing
		*elseif priest
			"I suppose you love me in the way that a man of the cloth ought to love a whore such as myself?"
			
			"I did not say that…"
			
			"What you say with your tongue and what you say with your eyes are not the same, ${given_name}."
			
			"Please, Clotho…"
			
			"No.  Enough of this farce."  Without giving you a chance to reply, she turns and leaves you alone in the gazebo.
			*page_break
			Clotho disappears from Memphis a few weeks later.
			*goto clotho_missing
		*else
			"I wondered why you kept to yourself like a priest."
			
			"Please, Clotho…"
			
			"No.  Enough of this farce."  Without giving you a chance to reply, she turns and leaves you alone in the gazebo.
			*page_break
			Clotho disappears from Memphis a few weeks later.
			*goto clotho_missing
	*if priest and (intimate_with_clotho = false)
		#"You mistake the nature of my love for you."
			"Says the man of the cloth, whose eyes sing of lust and whose mouth repeats the catechism."
			
			"My vows were made long before you were born…"
			
			"Then you should have more experience with keeping them."  Without giving you a chance to reply, she turns and leaves you alone in the gazebo.
			*page_break
			Clotho disappears from Memphis a few weeks later.
			*goto clotho_missing
	#I reveal my true nature.
		*set love_clotho true
		*achieve clotho
		*set anachronism %+20
		*set compassion %-20
		*set discretion %+10
		"I cannot deceive you any longer, my dear Clotho."
		
		"Deceive me?  How have you deceived me?"
		
		"I love you."
		
		"That is no deception, ${given_name}," she whispers, drawing close, "when I love you too."
		
		"Yes, but I am not like you."
		
		"I dare say you are not.  You are…"
		
		Waving your hands, you interrupt her.  "…a vampire."
		
		She draws away from you.  "A…what?"
		
		"A vampire.  I was once human, but long ago, in New Orleans, another vampire took my life and gave me an unending existence."
		
		"And yet you say that you love me?"
		
		"I do.  With all my heart and soul.  Or with what remains of them."
		
		"What does that mean?"
		
		"I don't know, other than that I wish to spend my existence with you.  Until the stars fall into the sea and the moon rises in the west."
		
		"Would you make me like you?"
		
		"I would, if you would let me."
		
		"You must give me time to consider…"
		
		"Of course.  But you must not divulge what I have told you here tonight with anyone."
		
		"No, I wouldn't betray you…"
		
		"Then let me escort you home, and we shall arrange another rendezvous soon?"
		
		"Yes."
		
		The walk back to her home is short.  You move to speak several times, but she cuts you off when you draw breath; she seems suddenly very attuned to your more inhuman qualities.  She kisses you silently goodnight and retreats inside.
		*page_break
		*goto post_revelation

*label post_revelation
*set memphis_affair true
When next you see Clotho, she throws her arms aboud your neck and kisses you deeply.  She says that she accepts you as you are, but reveals that she does not wish to become like you.

Within a few weeks, she has more or less moved into your house and for the first time in decades it starts to feel like a home.  Meanwhile, Franklin does his best to acclimate himself to his new mistress.
*page_break
*goto_scene memphis_first_intermission_continued

*label pursue_hester
*choice
	#Ms. Carothers?  What a curious name…
		*set independence %+10
	#A school for the blind?
		*set compassion %-10
		*set shepherd_credentials %+5
	#With any luck, that is the end of this affair.  It has occupied enough of the city's attention these past few months.
		*set shepherd_credentials %-10
		You gather your things and depart.
		*return
	*if pursuing_clotho
		#No, it was only Clotho.
			*set independence %-10
			*set shepherd_credentials %-10
			*return

*label meet_hester
*if pursuing_clotho
	The room has mostly emptied by now, and the old woman is making her way to the door.  "May I be of some assistance," you say, sliding up beside her.
	
	"Do I know you?" she says, turning her face in your direction.  Looking in her eyes, you can see that she is blind and has likely been so for a very long time.  "I don't recognize your voice, dear."
	
	"No, I'm afraid we are unacquainted.  My name is ${given_name} ${surname}."
	
	"Well, my name is Hester Carothers.  And if you would be so kind, guide this old woman down to the street, won't you?"
	
	"It would be my pleasure, Mrs. Carothers," you reply.
*else
	You make your way through the crowd to find the woman seated again in her chair.  It seems she is waiting for the room to clear before attempting to exit.
	
	"Ms. Carothers?" you inquire.
	
	"Yes," she replies, turning her face in your direction.  Looking in her eyes, you can see that she is blind and has likely been so for a very long time.  "Do I know you?  I don't recognize your voice, dear."
	
	"No, I'm afraid we are unacquainted.  My name is ${given_name} ${surname}."
	
	"Well, what can I do for you, @{priest Mr.|${mr}} ${surname}?" she inquires.
	*if priest
	
		It's been a long time since anyone has addressed you as Mister. "It's Father, actually," you correct her.
		
		"Oh, forgive me, Father."
		
		You wave your hand to dismiss the mistake, but only belatedly realize that she can't see that either. Before you can correct your mistake,
	*else
		Before you can reply, 
	however, a much younger man of mixed race appears at your elbow.  He introduces himself as Robert Reed Church, and the old woman stands so that he can hug and kiss her on both cheeks.  He flirts with her shamelessly, and she eats it up. She introduces you, a momentary courtesy, before he excuses himself once again.
	*set met_robert_reed_church true
	
	"Now, where were we? Oh, yes. I was asking what I could do for you. But in the meantime, won't you be a dear and walk me down to the street? It sounds like the room has cleared out."  Looking around, you realize that she is correct. Extending your arm, she puts it through yours, and the two of you head towards the exit, the click of her cane marking the way forward.
			
*set met_hester_carothers true
Arriving at the street below, she turns to the left, moving with more assurance now.  She even deftly avoids a broken curb that you nearly trip over.  "Now, what is it that I can do for you, ${mr} ${surname}?"

"That's a very curious name, 'Carothers.'  Is your family from Memphis?"

"Oh, no dear.  I was born on a plantation outside of Nashville…way back in 1806.  The Hermitage…have you heard of it?  I contracted the scarlet fever as a child and lost my eyesight, and my mammie was afraid that I was going to be sold away or something even worse.  But instead, when I got older, the master of the plantation sent away for a tutor, and they had me learn my letters.  Eventually, he even gave me my freedom and sent me to Ohio to get my teaching certificate."

@{(compassion < 35) "That is surprising conduct for a slaveholder," you observe.|"What an extraordinary slaveholder!"}

"Yes, old Master Jackson was good to me."

*if intelligence > 2
	"Master Jackson?  Of the Hermitage?  
	*if anachronism < 70
		Do you mean General Andrew Jackson?"
	
		"Most these days would refer to him as President Jackson, but yes, the very same."
	*else
		Do you mean President Andrew Jackson?"
		
		"Yes, the very same," she replies.

"Go on," you prod.

"Well, I stayed in Ohio until the war was over, and then I came here.  I've been urging the school board to build a school in Memphis, but with the School for the Blind already in Nashville, the white folks have a place to send their children.  Despite that, we were about to do it through private subscriptions, but then Freedmans collapsed.  Everyone who had pledged to support the school was ruined.  So here I am again, back at the School Board, begging for their support…" she trails off.

"It seems that you have set yourself a Sisyphean task."

She sighs heavily. "Yes, it often feels that way.  But I will not let this boulder escape my grasp again."

You look about; you are deep in the Beale district.  
*if memphis_haven = "beale"
	Your own haven is not far.
"And do you live near here?"

"I do.  Thataways…" she says, gesturing with her cane.

It takes a few more moments for you to gin up the courage to ask the next question.  "Pardon the rudeness of this question, Ms. Carothers, but do tell me: who was your father?  And what was he like?"

She stops.  The abrupt cessation of her regularly tapping cane makes the silence of the street all the more profound.  "It is funny that you should ask.  He died.  Before I was born, in fact.  I never met him."

"And his name?"

"They told me his name was Apollo."
*page_break
Is it possible?  Could this be the mortal daughter of Quaestor Carothers?  If it is, is he even aware of her existence?
*if lore > 3
	*set reserve_on_families true
	Mortal families are, of course, a delicate matter in the Society.  At some point, a vampire must fake his own death, before too many questions are raised.  That aside, some Shepherds in particular look after their descendents for generations.
*else
	You suppose that, if she never met her father, she would not be considered a violation of the Rule of Reserve.  But still…

You guide her home, and on her doorstep inquire after the name of her mother: Lolly Carothers.  Once she is safely inside, you turn home.
*if pursuing_clotho
	Between your encounter with Clotho and your introduction to Hester Carothers, your mind is spinning with possibilities.
*else
	Your head spins with the possibilities.
*return