*comment ñáéç…—
*hide_reuse
*advertisement
*gosub_scene util check_flow
*temp pb_not_staked false
*temp pb_present false
*if (lore <= 2) and (knows_about_stakes = false)
	*set pb_not_staked true
*temp learned_from_carothers false
*temp pb_resolved false
*temp got_away false
*temp pb_buried false
*temp let_go false
*if (carothers_humanity >= 6) and (applethorp_alive = 1)
	*set applethorp_alive 2
You wake the next evening to a note from Carothers, summoning you to his presence.
*if carothers_ignorant_of_pb
	*if ((maddox_status = "freed") or (maddox_status = "dead")) or ((maddox_status = "withers") or ((maddox_status = "consumed") or (maddox_status = "buried")))
		You saunter into Carothers' parlor.
		*if ((discretion < 50) and (applethorp_rapport > 45)) and (applethorp_alive < 3)
			You are somewhat surprised to note that Dido is nowhere to be seen.
		Carothers sits behind an impassive face. @{(compassion < 60) Come to think of it, you haven't seen him smile for several years now.|}
		
		*if applethorp_alive < 3
			*set carothers_rapport %+5
			"Someone attacked Dido last night."
			
			"Yes."
			
			"Do you know who this was?"
			
			"No, Quaestor." You've kept ${wilson}'s existence a secret from Carothers this long—you see no reason to change that now.
			
			"Thank you for helping her return home."

			"You're welcome, Quaestor."
			
		*elseif applethorp_alive = 3
			"Have you seen Dido?"
			
			"No, Quaestor."
			
			He wrinkles his face.
		"You must leave the city."

		"I'm sorry?"
		
		"The humans are leaving.  The ones that remain are dying.  There are not enough of them to support the three of us.  
		*if applethorp_alive = 2
			I've already dealt with Dido; now you are all that remains.
		Moreover, I have been humiliated in front of the Senate: three times they set a date to decide on a Senator for this city, and three times the matter went unresolved.  With the city in such disarray, it shall be decades before they are willing to consider the matter again.
		*goto banish1
	*elseif maddox_status = "shirked"
		*goto maddox_apprehended_by_carothers
		
	Maddox Num: ${maddox_num}
	*line_break
	Maddox Status: ${maddox_status}
	*line_break
	Gallagher Status: ${gallagher_status}
	*page_break
	*bug
	
*if gallagher_status = "decapitated"
	Fetching the sack from last night, you find it soaked with blood, but empty of the Gallagher's head.  Instead, there is a mush of bloody ash in the bottom.  His head must have decomposed during the day.  So much for your reward.
	*set gallagher_status "dead"
	*goto quarry_apprehended
Dressing quickly, you hurry to the Quaestor's haven.
*if gallagher_status = "inquiry"
	*gosub saunter
	*set pb_present true

	"Hugh Gallagher.  He claims that he is the source of the plague."

	"The source?"

	"He says that he has had the plague for two decades; that whenever he feeds, he infects his prey with the fever."

	"Where is he?"

	"Your servants are bringing him in. He's ready to be interrogated."

	*if debt_to_carothers
		*set debt_to_carothers false
		*set carothers_rapport %+10
		"You have done me a great service in bringing him to me.  I will investigate this matter further.  But you may consider your debt to me paid in full."

		"Thank you, Quaestor."

		"Unfortunately, that is not all."

	*elseif debt_from_carothers = false
		*set debt_from_carothers true
		*set carothers_rapport %+5
		"You have done a great service in bringing him to me, ${mr} ${surname}.  I will investigate this matter further."

		"I will anxiously await the results of your inquiry, Quaestor.  That aside, I believe that this service warrants a debt."

		Carothers clenches his jaw.  "Yes, I suppose it does."

		"I am glad to hear it."

		"Unfortunately, that does not resolve our business here today."

	*else
		*set carothers_rapport %+20
		"You have done a great service in bringing him to me, ${mr} ${surname}.  I will investigate this matter further."

		"I will anxiously await the results of your inquiry, Quaestor."

		"Unfortunately, that does not resolve our business here today."

	"Oh?"
	*gosub applethorp_alive
	*goto banish
*elseif chasing_wilson and ((maddox_status = "dead") or (maddox_status = "consumed"))
	*goto quarry_apprehended
*elseif ((gallagher_status = "dead") or (gallagher_status = "consumed"))
	*goto quarry_apprehended
*elseif (maddox_status = "staked") or ((maddox_status = "withers") or (gallagher_status = "quaestor"))
	*set pb_present true
	*goto quarry_apprehended
*elseif (maddox_status = "carothers") or (gallagher_status = "carothers")
	*set pb_present true
	*if rejected_sam_wilson
		"What is this?" Carothers demands when you present the @{pb_not_staked bound and gagged ${wilson}.|body of ${wilson}, transfixed by a sharpened stake through his heart.}
	
		"${wilson} ${maddox}.  Alive, no less.
		*if chasing_wilson
			*set maddox_status "withers"
		*else
			*set gallagher_status "dead"
			*bug This should only be for people pursuing Withers's offspring.
		*if debt_to_carothers
			*set debt_to_carothers false
			I believe my debt to you is now clear?"
	
			He nods.  "It is.
		*else
			I believe you now owe me a debt."
			*set debt_from_carothers true
	
			"It seems that I do.  
		@{(applethorp_alive = 1) Dido|Hermes}, please, take the trash out.  See that he is delivered to Quaestor Withers in one piece."

		@{(applethorp_alive = 1) Dido|Hermes} nods, and drags ${wilson} from the room; you suspect that he will not last much past the dawn.  When @{(applethorp_alive = 1) she|he} is gone, Carothers turns to you.
	*else
		"What is this?" Carothers demands, when you present the @{pb_not_staked bound and gagged ${wilson}.|body of ${wilson}, transfixed by a sharpened stake through his heart.}
		
		*if heard_about_bounty_on_hugh
			*set gallagher_status "quaestor"
			*set knows_about_stakes true
	
			"There is a bounty on his head.  I intend to claim it.  However, I hoped you might suggest how I could safely transport him to New York…"
	
			Carothers looks at you in disbelief.  He gestures to @{(applethorp_alive = 1) Dido|Hermes}, who leaves the room, returning a moment later with a stake.  "This is how…" he says.  Moving with a surprisingly grace, he uses but two fingers to drive the stake through the heart of Gallagher.  Gallagher's eyes go wide with shock, before going dim.  "That is how you transport a vampire, ${mr} ${surname}.  He will not stir until the stake is removed."
	
			@{(compassion <= 50) You catch the comatose body of Gallagher before it falls to the floor.|You watch as the comatose body of Gallagher falls to the floor.} Turning your attention back to Carothers, you thank him for his assistance.  He waves away your thanks, his mind clearly on other things.
		*else
			*if wilson_embraced
				"It is my offspring, ${wilson} ${maddox}."
				
				"The one that has been terrorizing this city for a decade?"
				
				"Yes."
				
				"And he is still exists because…"
				
				*choice
					#He's right; I kill ${maddox}.
						*set maddox_status "dead"
						*set compassion %+10
						*if applethorp_alive > 1
							Carothers watches impassively as you pick up a machete and begin to hack at ${maddox}'s skull.
							
							Eventually, you hack away enough viscera that your former valet stops moving.
							
							Carothers gestures to Hermes to deal with the mess.
						*else
							*set carothers_rapport %-10
							"Stop!"
							
							You pause; you had acquired a machete and were preparing to hack at the subdued ${maddox} until he was dead. "Quaestor?"
							
							"I don't…I didn't…"
							
							@{(compassion < 40) The thought occurs to you that Carothers is…soft.|} "Yes?"
							
							"Dido, please take ${maddox} out and leave him for the sun."
							
							Dido nods and drags your former valet away.
							
							When she is gone, Carothers turns to you. 
					#"I cannot bring myself to kill him, Quaestor."
						*set maddox_status "dead"
						*set compassion %-10
						*if applethorp_alive > 1
							*set carothers_rapport %-10
							Carothers strides forward and in one fluid gesture crushes ${maddox}'s skull between his fists.
							
							It takes you a moment to clear your eyes of the brain matter that was obstructing them.
							
						*else
							*set carothers_rapport %+10
							Carothers looks…pained.
							
							"Dido, please, take this man outside and leave him for the sun."
							
							Dido nods and drags your former valet away.  
							
							When she is gone, Carothers turns to you.
			*else
				"It is a gift, Quaestor."
				
				*if maddox_num < 3
					*set maddox_status "withers"
				*if maddox_num = 3
					*set gallagher_status "dead"
				"@{(applethorp_alive = 1) Dido|Hermes}, please, take the trash out."
		
				@{(applethorp_alive = 1) Dido|Hermes} nods, and drags ${wilson} from the room; you suspect that @{wilson_embraced_by_withers he will be on a riverboat to Vicksburg by dawn|he will not last much past the dawn}.  When @{(applethorp_alive = 1) she|he} is gone, Carothers turns to you. 
			"This does not change what I am about to tell you."

			"What is that?"
	*goto banish
*elseif (maddox_status = "buried") or (gallagher_status = "buried")
	*set pb_buried true
	*goto quarry_apprehended
*elseif (maddox_num < 3) and ((maddox_status = "free") or (maddox_status = "shirked"))
	*goto maddox_apprehended_by_carothers
*elseif (maddox_num = 3) and ((gallagher_status = "free") or (gallagher_status = "shirked"))
	
	@{(discretion < 60) When you arrive, you observe that Dido is conspicuously absent.|} Before long, Hermes leads a hooded individual into Carothers's parlor.  When it is removed, you find yourself face-to-face with Hugh Gallagher.
	
	"It seems we have a problem, Mr. Gallagher," Carothers begins.  Gallagher blinks at the lights, trying to get his eyes to adjust.  "You've violated the Rules of Respect and Reserve.  Quite flagrantly, as a matter of fact.  And that demands satisfaction."
	
	"Satisfaction?"  he says, finally.
	
	"Yes.  I have the right to take your life."
	
	"The right.  But that doesn't mean you have to…" he says.
	
	Carothers flashes a predatory smile.  "You are right…I don't have to."  With that, though, Carothers steps forward, and demonstrating the strength for which he is so famous, literally tears the head of Gallagher from his shoulders.  There is a spray of blood, which Carothers does his best to catch in his mouth.
	*set gallagher_status "dead"
	
	When Gallagher's body slumps to the floor, Carothers turns to face you, licking his lips. "This does not change what I am about to tell you."

	"What is that?"
	*goto banish
*else
	*if (maddox_status != "freed") and (gallagher_status != "freed")
		Maddox: ${maddox_status}
		*line_break
		Gallagher: ${gallagher_status}
		*line_break
		Maddox Num: ${maddox_num}
		*page_break
		*bug
	*page_break
	When you arrive, @{(applethorp_alive != 3) Dido is conspicuously absent.  Instead, |}Hermes shows you in to Carothers's parlor.

	Catching sight of Carothers, you can see that he is clearly agitated.  
	
	"Where is ${maddox}?" he demands.
	*choice
		#I lie and tell him that ${maddox} is dead.
			*set lied_to_carothers_about_pb 2
			*set carothers_rapport %+15
			*if applethorp_alive = 1
				*set applethorp_rapport %+10
			Carothers eyes you suspiciously. @{(carothers_rapport < 50) You can feel him weighing whether or not to believe you.|} Finally, he relents. "Congratulations.
			*if maddox_status = "freed"
				*if wilson_embraced
					You have fulfilled your obligations as a dominus. Finally."
					
					You nod.
					
					"It is disappointing that it took you this long."
					
					Considering the knife's edge that you're walking here, you smother any reaction to this chastisement.
					
					*if status > 2
						*set status -1
						"I have concluded that you are not worthy of the respect that has been accorded to you in the Society. I intend to let everyone know."
						
						You clench your jaw and nod.					
				*if wilson_embraced_by_withers
					*if carothers_debt_wilson = 3
						*set debt_to_carothers false
						Your debt to me is absolved."
						
						"Thank you, Quaestor," you reply.
					*elseif rejected_sam_wilson or (carothers_debt_wilson = 2)
						*set debt_from_carothers true
						It seems I owe you a debt."
						
						"So it would seem," you reply.
					*else
						I'm sure Withers would have preferred for you to deliver him alive, but she will surely be grateful that this matter is put to rest."
						
						"Agreed, Quaestor."
			*else
				It seems that I owe you a debt."
				*set debt_from_carothers true
				
				"Thank you, Quaestor," you reply.
		#I tell him that he got away.
			*set carothers_rapport %-20
			Carothers's eyes burn with apoplectic rage.
			
			*label let_go
			*if maddox_num < 3
				*set flirting_with_withers false
			*if (carothers_debt_wilson > 1) or wilson_embraced
				*set got_away true
				"You had one task: to find that vampire and bring him to heel."
				
				"Yes Quaestor."
				
				*if let_go
					"And you let him go."
					
					"I did, Quaestor. I could not bring myself to kill him."
			*elseif wilson_embraced_by_withers
				"Withers never should have let…" you begin.
				
				"Enough. Do not blame your failings on her."
			*elseif maddox_num = 3
				"I do not see how he was my responsibility, Quaestor."
				
				Carothers glares at you. You are not wrong, but that does not assuage his fury.
		#I tell Carothers that I let him go.
			*set independence %-40
			*set let_go true
			
			Carothers's eyes go wide in surprise.
			*goto let_go
	
	*gosub applethorp_alive
	"It does not change what I am about to tell you."

	"What is that?"
	*goto banish

*label maddox_apprehended_by_carothers
Appearing before Carothers, it is impossible to ignore Dido and the hooded individual she holds firmly in place.  Even with the hood, however, you can sense the identity of the captive: ${wilson} ${maddox}.  He spent nearly a decade as your servant; his posture, his clothes, his hands…they all scream his name to you.
*if chasing_wilson
	This will be awkward.
	
	*if carothers_ignorant_of_pb
		*set carothers_rapport %-20
		*set applethorp_rapport %-10
		"Do you know who this is, ${mr} ${surname}?"
		
		"Yes. It is ${wilson} ${maddox}, my former valet."
		
		"What is he doing in my city?"
		
		"I have been trying to apprehend him@{wilson_embraced_by_withers  for Quaestor Withers|}."
		
		"And when I asked you about the stranger that Dido spied in the Pinch, you lied to me?"
		
		You don't have an answer for that.
		
		"Leave. Now. And never return."
		*set maddox_status "dead"
		*set exiled_from_memphis true
		*achieve exiled_from_memphis
		*if status > 0
			*set status -1
		*goto resolve_franklin
		
	"It seems your quarry has been found," Carothers observes.
	
	"It does seem that way, Quaestor.  How ever did you apprehend him?"
	
	"Dido found him skulking about the Pinch, and recalled your description of him."
	
	"I must thank you, then, Ms. Applethorp."
	
	"You bes' be thankin' the Quaestor there."
	
	"Yes, of course," you say, turning back to Carothers.  "Thank you…"
	
	Carothers waves his hands in dismissal.
	*set carothers_ignorant_of_pb false
	*if wilson_embraced
		"He is your progeny, is he not?"
		
		*label wilson_killed_2
		"He is."
		
		"Then you must put an end to him."
		*choice
			*selectable_if (compassion > 30) #"As you command, Quaestor."
				*label kill_wilson
				*set compassion %+20
				*set maddox_status "dead"
				From somewhere, an axe appears in Carothers' hands.  He forces it into your grip.  Dragging ${wilson} into the yard behind Carothers' house, Hermes forces his head onto a stump.  You can hear ${wilson} sobbing under the hood.
				*if strength > 3
					Thankfully, you are strong enough to make the blow a clean one.  One strike, and ${wilson}'s head goes cleanly from his shoulders. 
					
					Carothers nods in appreciation.  "That was well done.
				*elseif strength = 3
					The first blow is true, but not quite forceful enough.  Blood splatters on you, but mostly just begins draining from the wound.  You look to Carothers for some sort of release, but he looks on dispassionately.  Lifting the axe a second time, you swing it, and the deed is done.
					
					Carothers nods in approval.  "That was well done.  
				*elseif strength = 2
					The first blow lands squarely between ${wilson}'s shoulders.  He cries out in pain, and blood lurches up into your face.  Wiping it away with your sleeve, you raise the axe again.  The second blow lands on ${wilson}'s neck, but without sufficient force to cleave through the bone and tendon.  The third does the trick, however, and ${wilson}'s corpse slumps to the ground beside the stump.
					
					Carothers nods.  "It is done. I hope that Withers metes her fury on her errant offspring; he has certainly caused me enough grief.
				*else
					Unfortunately, you were never much of one for chopping wood, and much less for executions.  Your blows fall haphazardly along the back and shoulders of ${wilson}, each one eliciting a wail, but none of them quite sufficient to end his suffering.
					*if compassion < 40
						You find yourself sobbing in horror as you go about trying unsuccessfully to decapitate your former valet.
					*if willpower > 2
						Finally, through sheer force of will, you strike a true blow, and fully sever the head from the neck.  You can almost hear Dido's teeth unclench.
						
						"That was a disgrace," Carothers says, once you've managed to wipe the splatter from you face with a piece of cloth.  You offer nothing in return.  "Such a waste.
					*else
						*set carothers_rapport %-20
						*set applethorp_rapport %-10
						Finally, Carothers seizes the axe from your hands in disgust.  The final blow is swift and sure.
						
						"You are a pitiful excuse for a vampire.  I am surprised your maker has not seen fit to hunt you down and put you out for the crows."
						
						"And yet, here I am," you reply, mustering every little bit of defiance that remains in you.
						
						Carothers shakes his head in disappointment.  "Such a waste.
				*if wilson_embraced
					But this matter is not yet concluded."

					"How do you mean?"

					"That was your offspring that you just slew."

					"Yes, as you ordered me to."

					"He was loose in my city.  Feeding from my people.  Without my permission."

					"Yes, as I told you when I arrived…"

					"Yes," he interrupts, "as you told me when you arrived, you were going to catch him.  But you did not.  I did.  And so I must punish your for your violation of the Three Rules."

					"Quaestor…"

					*if debt_from_carothers
						*set debt_from_carothers false
						*set debt_to_carothers true
						"I hereby pronounce a sentence…"

						"But Quaestor, what of the debt you owe me?" you demand.

						He pauses.  He bares his fangs and snarls.  Clenching his massive fists, he manages to subdue the beast within.  "My debt to you is hereby expunged.  Instead, you owe a debt to me.  Say that you understand."

						"I understand, Quaestor."

						"No, leave my city.  And do not ever return."
						*goto resolve_franklin
					*elseif (status > 2) and (debt_to_carothers = false)
						*set debt_to_carothers true
						*set status -1
						"I hereby pronounce a sentence…"
						
						"But Quaestor, you cannot simply execute someone of my standing."
						
						He pauses.  He bares his fangs and snarls.  Clenching his massive fists, he manages to subdue the beast within.  "Your standing is overstated, and I will be sure to let everyone know.  Instead, you owe a debt to me.  Say that you understand."

						"I understand, Quaestor."

						"No, leave my city.  And do not ever return."
						*goto resolve_franklin
					*else
						"I hereby pronounce a sentence of death upon you, for this flagrant violation of the Rule of Respect."

						"But, Quaestor…" are the last words that issue from your lips.  Before they can form another word, Carothers has torn your head from your very shoulders.  The last sight your eyes take in before everything goes dark, is the look of supreme boredom on the face of Carothers, as though such casual slaughter no longer means anything to him.
						*set killed_by_vampire true
						*page_break
						*goto_scene scoring
				*else
					Now, there is something else we need to discuss."  No rest for the wicked, it would seem.
					*goto post_wilson
			*selectable_if (compassion < 60) #"I cannot kill him, Quaestor."
				*label first_no
				"You will, ${mr} ${surname}.  You will kill him, or I will put an end to you."
				*choice
					#"As you wish, Quaestor."
						*goto kill_wilson
					*selectable_if (willpower > 2) #I stand my ground.
						*set killed_by_vampire true
						*set compassion %-30
						"It is amazing to me that you have lived as long as you have."
						
						And those are the last words that you hear.  Moving faster that you realized was possible, Carothers is on you, fangs extended, tearing your very head from your shoulders.  The last thing you see before the blood drains from your eyes is ${wilson}, still hooded, shivering at the sounds around him.
						*page_break
						*goto_scene scoring
			#"Surely there is another solution, Quaestor?"
				*choice
					#"As you wish, Quaestor."
						*goto kill_wilson
					#"I cannot do this thing, Quaestor."
						*goto first_no
	*else
		"He is the progeny of Quaestor Withers?"
		
		"He is."
		
		"Then what do you intend to do with him?"
		*choice
			*selectable_if (compassion > 30) #"I will end him here and now."
				*goto kill_wilson
			#"I will send him to Quaestor Withers.  Let her resolve the matter."
				*set withers_rapport %-10
				*set maddox_status "withers"
				Withers will be grateful that you have captured her errant offspring, but will not be so excited to be forced to put an end to him herself.  After all, such deeds are best left to others.
				
				*if compassion > 60
					You remove ${wilson}'s hood; you want to look into his eyes as the light goes out of them.
				Taking the proffered stake from Carothers, you impale the heart of ${wilson}.  He slumps into Dido's arms.  Carothers nods in acceptance.  "It is done.  Now, there is something else we must discuss…"
				*goto post_wilson
			#"He has intruded into your city, Quaestor.  It is your right to put an end to him.  I am sure that Withers would only thank you for such a service."
				"You don't think Quaestor Withers would want the honor herself?"
				
				"No…I think she prefers not to dirty her hands."
				
				Carothers does not stop to consider.  
				*label kill_wilson_1
				*set maddox_status "dead"
				He moves towards ${wilson}, and with a strength of what must be ten men, tears ${wilson}'s head from his shoulders.  Blood sprays from the corpse, covering Apollo with the spray.
				*if compassion < 40
					Words of protest falter in your throat.  There will be no mercy tonight.
				
				${wilson}'s body drops to the ground, which is soon followed by the head. Carothers turns to you, blood dripping from his chin onto his shirt. "Now, there is something else I need to discuss with you, ${mr} ${surname}."
				*goto post_wilson
*else
	*if carothers_ignorant_of_pb
		*bug Is this possible?
	*if wilson_embraced
		"He is your progeny, is he not?" Carothers says, pointedly.
		*goto wilson_killed_2
	Of course, none of that is your concern, exactly.  Instead, it seems that Carothers and Withers are about to have a serious problem.
	
	"It seems as though we have a problem, Mr. Maddox."  With that, Carothers tears the hood from ${wilson}, who blinks momentarily as he takes in the scene around him.  "You have broken the rules.  And the rules say that you should die."
	
	@{maddox_num "But Ah don' have ta', does Ah?"|"But yer sayin I…I don' hafta?"}
	
	"No, you don't have to,"  Carothers says.  Looking at you over his shoulder, he gives a brief smile.  "But that doesn't mean I will forgive you."
	*goto kill_wilson_1
	
*label post_wilson

"I am all ears, Quaestor."
*page_break
"You must leave the city," he says.

"I'm sorry?"

"The humans are leaving.  The ones that remain are dying.  There are not enough of them to support the three of us.  Therefore, you must leave."
*choice
	#"Of course, Quaestor."
		*set discretion %-10
		@{(independence > 45) Bowing and scraping|With a curt nod}, you withdraw from Carothers' presence.
	#"Surely there must be another solution…"
		*set carothers_rapport %-10
		"I am sending Dido to ground.  I will wake her when this catastrophe has passed."
		
		"You will send her to ground?"
		
		"Yes, she will be safe."
		
		"But what if…"
		
		"Nothing will happen to me.  Now, go.  There is no longer a home for you here."
		
		"Yes, Quaestor."  With that, you take your leave of Carothers.
	#"You will regret this, Apollo."
		*set discretion %+15
		*set carothers_rapport %-40
		*if (independence < 50) or (discretion > 60)
			He is unsurprised by your flippancy.  "Be that as it may, that time is not yet here.  Now go."
			
			Turning on your heels, you exit the court of Memphis for the last time.
		*else
			He looks at you, surprised at your attitude.  "Be that as it may, that time is not yet here.  Now go."
			
			Turning on your heels, you exit the court of Memphis for the last time.
*goto resolve_franklin

*label saunter
You saunter into Carothers' parlor.
*if ((discretion < 50) and (applethorp_rapport > 45)) and (applethorp_alive < 3)
	You are somewhat surprised to note that Dido is nowhere to be seen.
Carothers sits behind an impassive face.
*if compassion < 60
	Come to think of it, you haven't seen him smile for several years now.

"I caught him."

"Caught who?"
*return

*label quarry_apprehended
*gosub saunter

"${wilson} ${maddox}.  The matter has been resolved." @{pb_buried No need to explain the details of how it has been resolved, you reason.|}

*if carothers_ignorant_of_pb
	Carothers looks at you blankly. You realize, suddenly, that you never told him about your quest on Withers's behalf.
	
	"${maddox}? What are you talking about?" Carothers presses.
	
	"It is nothing, Quaestor. Please, tell me what's on your mind."
	
	Whether there are too many other things on his mind or he is simply indifferent to the topic, you are surprised to see him let it go. That does not make the next words out of his mouth any easier to hear.
*else
	"I am glad to hear it.  
	*if wilson_embraced
		You have fulfilled you duties as a dominus.  They were long overdue.
	*if wilson_embraced_by_withers
		Quaestor Withers will no doubt be grateful that you have saved her from herself.
	*if applethorp_alive = 3
		Which brings me to my next question."
		
		"What is that?"
		
		*gosub applethorp_alive
		"But it does not change what I am about to tell you."
		
		"What is that?"
		*goto banish
But it does not change what I am about to tell you."

"What is that?"
*label banish

"You must leave the city."

"I'm sorry?"

"The humans are leaving.  The ones that remain are dying.  There are not enough of them to support the @{(applethorp_alive < 3) three|two} of us.  
*if applethorp_alive = 2
	I've already dealt with Dido; now you are all that remains.
*if (let_go or got_away) and (applethorp_alive = 3)
	Besides…I cannot stand the sight of you, knowing what you have done."
	
	"But, Quaestor…"
	
	"Go. And do not return."
	*achieve exiled_from_memphis
	*set exiled_from_memphis true
	*if status > 1
		*set status -1
	*goto resolve_franklin
*if let_go or got_away
	And that is not even considering the damage that ${maddox} has yet to wreak.
Moreover, I have been humiliated in front of the Senate: three times they set a date to decide on a Senator for this city, and three times the matter went unresolved.  With the city in such disarray, it shall be decades before they are willing to consider the matter again.
*label banish1

"Therefore, not only do I have no need of you, you are actively a drain on what little resources remain to me. You must leave."
*if maddox_status = "shirked"
	
	"But what of ${wilson} ${maddox}?"

	"Whatever opportunity you had for an amicable reunion with your offspring is gone.  If he is still in Memphis, I will find him and destroy him.  You, however, must leave."
*choice
	*if applethorp_alive = 2
		#"Dealt with her?  What do you mean, Quaestor?"
			*if carothers_humanity >= 9
				*goto carothers_explains_draining_dido
			*else
				*goto carothers_explains_killing_dido
	*selectable_if (discretion < 55) #"Of course, Quaestor."
		*set discretion %-10
		Bowing and scraping, you withdraw from Carothers' presence.
		*goto resolve_franklin
	#"Surely there must be another solution…"
		*set carothers_rapport %-10
		*if (carothers_humanity >= 8) and (applethorp_alive = 2)
			"I could just put an end to you, as I did with Dido.  That would be another solution."
			
			"You did what?"
			
			*label carothers_explains_draining_dido
			*achieve didodrained
			"I drank her heartsblood.  She was a burden the city could not support.  She was my progeny, and I did not want my blood to go to waste.  Reclaiming it was better than letting it go to waste."
			
			"Letting it go to waste?"

			"She was my progeny; I couldn't just send her out into the world unsupervised.  If I would have just slain her, my blood would have gone to waste."
			*if (discretion > 60) and (applethorp_rapport > 65)
				You feel the fury rising up, choking you with its bile.  
				*if (willpower < 3) or (discretion > 80)
					*goto attack_apollo
				*if willpower >= 3
					Your hands clench, but you push the heat back down.  The threat of an angry quaestor makes you think better of saying anything further.  

			"But me…"
			
			"You have not done anything criminal…yet.  So leave now, before you violate the Rule of Respect and I send you to join Dido."
			
			"Yes, Quaestor…" you say, backing away slowly from his murderous presence.
			*goto resolve_franklin
		*elseif (applethorp_alive = 2)
			"I could just put an end to you, as I did with Dido.  That would be another solution."
			
			"You did what?"
			
			*label carothers_explains_killing_dido
			"I slew her.  She was a burden the city could not support.  And she was my progeny; I couldn't just send her out into the world unsupervised."
			
			*if (discretion > 70) and (applethorp_rapport > 65)
				You feel the fury rising up, choking you with its bile.  
				*if willpower < 3
					*label attack_apollo
					*set killed_by_vampire true
					Your fangs @{(shapeshifting > 2) and claws|} extend. With a scream you launch yourself at Apollo.

					He catches you head in his massive right hand, your arm in his left. "So disapppointing," he says. And then he squeezes.
					
					He squeezes until your head explodes in a spray of blood and brain matter. As quaestor, he is well within his rights to end you. You doubt that he will even dignify you death with an announcement.
					
					Who would even mourn your passing?
					*page_break
					*goto_scene scoring
				*else
					Your hands clench, but you push the heat back down.  The threat of an angry quaestor makes you think better of saying anything further.  

					You excuse yourself before you lose any further control of yourself.
					*goto resolve_franklin
			*else
				"But me…"
				
				"You have not done anything criminal…yet.  So leave now, before you violate the Rule of Respect and I send you to join Dido."
				
				"Yes, Quaestor…" you say, backing away slowly from his murderous presence.
				*goto resolve_franklin
		*elseif applethorp_alive = 3
			"There is no other solution. Unless you want me to kill you so that you are no longer a threat to me?"
			
			"No, Quaestor…"
			
			"Then go. There is no longer a home for you here."
			
			"Yes, Quaestor."  With that, you take your leave of Carothers.
			*goto resolve_franklin
		*else
			"I am sending Dido to ground.  I will wake her when this catastrophe has passed."
			
			"You are sending her to ground?"
			
			"Yes, she will be safe."
			
			"But what if…"
			
			"Nothing will happen to me.  Now, go.  There is no longer a home for you here."
			
			"Yes, Quaestor."  With that, you take your leave of Carothers.
			*goto resolve_franklin
	#"You will regret this, Apollo."
		*set discretion %+15
		*set carothers_rapport %-40
		He looks at you, surprised at your attitude.  "Be that as it may, that time is not yet here.  Now go."
		
		Turning on your heels, you exit the court of Memphis for the last time.
		*goto resolve_franklin
	*if knows_hardings_plan
		#"But…I was the one who uncovered Senator Partridge's perfidy!"
			*if carothers_humanity >= 7
				*set carothers_rapport %+5
				*set discretion %+5
				"So you did.  And I thank you for that.  If I were still capable of grief, I would grieve that I must pluck the eyes from my head that finally grasped the nature of the misdeeds surrounding me.  But pluck I must.  So go; and I will be left here, blind and grasping, waiting for the next machination of my broodmate."
				
				"May you see more clearly in the future, Quaestor."  With that, you take your leave of Carothers.
				*goto resolve_franklin
			*else
				*set carothers_rapport %+10
				*set discretion %+10
				"So you did. And I thank you for that. I did not see that the crimes of my dominus must be atoned for. But now I do see, and I see first and foremost that you must go, while I watch for further betrayals."
				
				"May you see more clearly in the future, Quaestor."  With that, you take your leave of Carothers.
				*goto resolve_franklin
	*if debt_from_carothers and ((strength >= 2) and (strength < 6))
		*if (train_strength = false) #"Before I go, I believe you owe me a debt.  I would like for you to teach me something of your great strength."
			*set learned_from_carothers true
			*set debt_from_carothers false
			*set discretion %+5
			*set carothers_rapport %-5
			"That will take time."

			"You are the one in a rush, Quaestor," Carothers growls in frustration, but he is bound by his word.

			"Fine, return tomorrow evening.  It may take weeks, but then you will go."

			"Agreed."
			*page_break
			*set strength +1
			*achieve carothersstrength
			*if memphis_haven_torched
				Since the destruction of your home, you have taken rooms at a boarding house.  Even thought it may yet be a few weeks, you begin to gather what things remain to you.
				*gosub burnt_consequences

			*if (gallagher_status = "quaestor")
				*achieve headhunter
				Additionally, you see that the transfixed Gallagher is sent to New York.  Hopefully, a prize of some sort awaits you.

			Carothers's lessons are short and to the point.  Soon, you feel yourself getting stronger.  When Carothers feels his debt to you has been fulfilled, he urges you on your way.

			During this time, you watch as the fever continuess to rage.  Residents of means take their things and flee; they have no destination in mind, only the certain knowledge that they must put as much distance as possible between themselves and the fire that is consuming Memphis whole.
			*goto resolve_franklin_2

*label burnt_consequences
*if new_orleans_enterprise = 1
	Of course, the library which you had so painstakingly assembled went up in flames with your haven.  One less thing to lug around, you suppose.
*if (kept_clotho_letter = false) and kept_silas_letter
	*set kept_silas_letter false
	The harmonica and letter from Silas were destroyed in the first as well.
*if kept_clotho_letter and (kept_silas_letter = false)
	*set kept_clotho_letter false
	The letter from Clotho was destroyed in the first as well.
*if kept_clotho_letter and kept_silas_letter
	*set kept_clotho_letter false
	*set kept_silas_letter false
	The letters from Clotho and Silas—as well as Silas's harmonica—were also destroyed in the fire.
*return

*label resolve_franklin
*page_break
*if memphis_haven_torched
	Since the confrontation with ${wilson}, you have taken rooms at a boarding house.  Returning there now, you begin to gather what remains of your things in preparation for your departure.
	*gosub burnt_consequences
*else
	Returning to your haven, you immediately begin arranging for your departure.
	*if gallagher_status = "quaestor"
		*achieve headhunter
		The first thing, of course, is sending the transfixed Gallagher to New York.  Hopefully, a prize of some sort awaits you.

*label resolve_franklin_2

*if carothers_ignorant_of_pb and (maddox_status = "withers")
	*if franklin_dead
		*bug
	*elseif knows_about_stakes = false
		*bug
	*else
		You direct Franklin to send the immobilized ${maddox} to Quaestor Withers.
		*achieve sneaky_bastard
	
*if franklin_dead
	With Franklin dead, it is a little more challenging to organize your departure than you were anticipating.  Soon enough, however, things fall into place; ensconced in your traveling-coffin, you are on your way to a new life.
*elseif (compassion < 60) or (discretion < 60)
	If you are leaving Memphis, you must decide what to do about Franklin.
	*choice
		*selectable_if (compassion < 40) #I bid him a fond farewell.
			*set stlouis_valet_num 5
			*set independence %-10
			*if sod_plot = false
				*set sod_plot true
				*set sod_founder "Franklin"
			Your farewells with Franklin border on the tender.  He has served you well for most of the past decade.
			
			As he closes the traveling-coffin above you, you wonder if you have made a mistake leaving him alive.
		*if ((met_olivia_hill) and (ruined_relationship_olivia_hill = false)) #I ask Olivia Polk Hill if she will take him into her employ.
			*set stlouis_valet_num 5
			*set compassion %-5
			*set discretion %+5
			You write to Olivia and beseech her to take Franklin into her household. In a gesture of magnanimity, she agrees. Of course, you tell her to pay no mind to any strange tales he may share of your peculiar habits.
			
			Before he encloses you in your traveling-coffin and sends you on your way, you issue a final warning to him to keep your secrets close. He nods gravely.
		*selectable_if (wealth > 100000) #I give him enough money to flee the city.
			*set stlouis_valet_num 5
			*set wealth -10000
			*set independence %-10
			He thanks you for the funds.  Your farewells border on the tender, as he has served you for most of the past decade.  
			
			He sees you firmly ensconced in your traveling-coffin and on your way before fleeing the city himself.
		*selectable_if (wealth > 1000000) #I give him enough money to establish himself wherever he so chooses.
			*set wealth -100000
			*set independence %-10
			He thanks you profusely for the funds and promises to attend to any business in the city that you need done after your departure.  The farewells between you border on the tender, as he has served you for almost a decade now.
			
			He sees you firmly ensconced in your traveling-coffin and on your way before fleeing the city himself.
		*if maddox_num < 3
			#I kill him.  I learned my lesson last time.
				*set compassion %+10
				*set independence %+10
				*set franklin_dead true
				You wait until the last moment to do it.  He is clearly surprised when the moment comes.  Apparently, he was expecting some other type of reward for his loyal service.
		#I will take him with me.
			*set compassion %+10
			*set stlouis_valet_num 4
			*set stlouis_valet "Franklin"
			He does not seem excited to leave his people, but neither does he have much choice in the matter.
			
			He too packs his things and accompanies your traveling-coffin north.
*else
	*set franklin_dead true
	Once your arrangements are made and your traveling-coffin secured, you kill Franklin and feast on his blood. To do otherwise would be too much of a risk.
*page_break

*if learned_from_carothers = false
	Though you are not there to witness it, you do not shy from news of the destruction visited upon Memphis over the following weeks and months.  The fever continues to rage until the winds of winter start to blow.  Residents of means take their things and flee; they have no destination in mind, only the certain knowledge that they must put as much distance as possible between themselves and the fire that is consuming Memphis whole. 
Fearing for their lives, and resentful of the recent Supreme Court decision affirming a new tax to pay off the bonds from the paving of the streets, the once-great merchant houses of the city relocate themselves to Chicago, St. Louis, and New Orleans. @{learned_from_carothers It is only once the winter winds start to blow that the fever starts to die out.  By then, it is too late.|}

*set year 1879
Only then, fourteen years after the surrender of the Confederacy, does Minor Meriwether strike his greatest blow to the Union: on January 13th, 1879, the State of Tennessee revokes the municipal charter of Memphis and appoints a council to govern the "taxable district of Shelby County" which exists in its place.
*if municipal_debt > 0
	*set municipal_debt 0
	All remaining city bonds are now rendered worthless.

The city of Memphis is no more.  In its place, a council of six former Confederate officers rules. @{knows_hardings_plan And, somewhere in Louisville, Elinor Harding is cackling.|}
*finish Next

*label applethorp_alive
*if applethorp_alive < 3
	*return
*else

	"Have you seen Dido?"
	
	"Yes, Quaestor. And I have bad news." @{(carothers_humanity >= 7) His eyes are dead to you.|You can see the fear in his eyes at your impending words.} "${wilson} killed her before I could reach him."
	
	*if pb_present
		Carothers looks from you to ${wilson} and back. After a beat, Carothers walks to ${wilson} and swings his fist in a wild haymaker. It connects solidly, flinging your prisoner in the wall.
		
		Carothers is on ${wilson} before you can even react. One, two, three blows and ${wilson}'s head is a bloody pulp, his body already shriveling away.
		*if maddox_num < 3
			*set maddox_status "dead"
		*if maddox_num = 3
			*set gallagher_status "dead"
		
		When he stands, he spits on the dead body. He does not bother to wipe his hands.
		*return
	*elseif got_away
		Carothers looks at you. Hate fills his eyes. "Not only did you fail to bring ${maddox} to me, but you allowed him to kill Dido before @{got_away escaping|letting him go}?"
		
		It's hard to fake contrition when Applethorp's blood is still under your fingernails. "He was, I suppose…"
		
		"Enough!" Carothers thunders. And then, he is upon you. Lifting you with one hand into the air, he brings you eye-to-eye with him. You feet kick in the air. "You do not deserve to live," he growls.
		
		And, within moments, you do not.
		*set killed_by_vampire true
		*comment TODO if $combat is high enough, flee the fight? But really, how many people are going to diablerize Dido and let the pb go?
		*page_break
		*goto_scene scoring
	*else
		*if (maddox_status != "dead") and ((maddox_status != "consumed") and ((gallagher_status != "dead") and (gallagher_status != "consumed"))) 
			*if (maddox_status != "freed") and (gallagher_status != "freed")
				Maddox: ${maddox_status}
				*line_break
				Gallagher: ${gallagher_status}
				*page_break
				*bug
		"I suppose it's a good thing that you killed him, then."
		
		"Yes, it is, Quaestor."
		
		He clenches and releases his fists.
		*return