*comment ñáéç…—
*hide_reuse
*advertisement
*gosub_scene util check_flow
*temp whiskey_intermission false
*temp invited_to_crapaud false
*temp son "son"
*if male = false
	*set son "daughter"
*set player_for_senator false
*if carothers_casey
	Reflecting on your deeds of the prior evening, you wonder how to address the matter of Mr. Casey.  His knowledge is a threat to the Rule of Reserve.
	*choice
		#I direct Franklin to dispose of Casey.
			*set compassion %+10
			*set discretion %-10
			*set independence %+10
			When you awake the next evening, Franklin informs you that the matter has been dealt with.  It seems that the issue has been resolved.
		#I send Franklin to watch outside Casey's house; he was sick.  Maybe the fever will claim him?
			*set compassion %+5
			*set discretion %-15
			*set independence %-10
			Franklin returns a few days later to inform you that Casey has passed.  The matter would seem to be resolved.
		#I will go and dispose of him myself.
			*set compassion %+15
			*set discretion %+15
			It is a small thing to find and kill Casey. Lashing out from the shadows, you bring him down before he realizes that you are even there. You think better of drinking from him; though it saddens you to see his blood go to waste, he is clearly still sick with the fever.  Better not to risk drinking from such polluted blood.

			The matter would seem to be resolved.
		*if wealth > 50000
			*selectable_if (streetwise > 2) #I direct some members of a local gang to torch his house.
				*set compassion %+10
				*set discretion %-15
				*set wealth -5000
				*set independence %+10
				In exchange for a small consideration, the gang is only too happy to throw a few torches through the windows of Mr. Casey's home.  

				They return to inform you that the deed is done, and Franklin, after investigating, confirms the news.  The matter would seem to be resolved.
		*if joined_kkk and (wealth > 10000)
			#I inflame the opinions of some of my former brothers in the Ku Klux Klan to lynch the papist.
				*set compassion %+10
				*set independence %+10
				*set wealth -1000
				A handful of former Confederate soldiers are only too happy to take a donation to their efforts in exchange for removing a problem for one of their brothers.

				They return to inform you that the deed is done, and Franklin, after investigating, confirms the news.  The matter would seem to be resolved.
	*page_break

*if first_memphis_caucus_attended and (revolutionary_credentials > 65)
	*set carothers_rapport %+25
	You receive a note from Carothers a few days after the election.  In it, he apologizes for his distress that morning.  He explains that this was, in fact, the best outcome possible; Simmons' absence threw the outcome of the evening into question, and therefore Pickering was unable to organize a clear majority.

	He thanks you in no uncertain terms for your efforts, seemingly convinced that you were in some way responsible for this.
	*if (chasing_wilson = false) and (tasked_hugh = false)
		*set invited_to_crapaud true
		Moreover, he asks that you come call on him in the next few days; there is something he needs to discuss with you in person.

*if (maddox_status = "dead") and ((tasked_hugh = false) and (met_stennis = false))
	*gosub learn_about_hugh
*if ((first_memphis_reception_attended = 2) or (first_memphis_reception_attended = 4))and (invited_to_crapaud = false)
	*gosub learn_about_caucus
*if whiskey_ring_plot and (whiskey_intermission = false)
	You receive a note from Carothers the next night, asking for you to call on him in the next few days; there is something he needs to discuss with you in person.
	*page_break
	*set invited_to_crapaud true
	Arriving at the [i]crapaud[/i]-den, you find Carothers enjoying the throw of the dice.

	After some pleasantries, he turns to the matter which troubles him.
	*gosub whiskey_explanation
*temp sally "blank"
*if barnum_thompson_plot
	After your conversation with Jesse, you begin paying more attention to the struggles over education in Memphis.  It is with fascination that you watch as the colored community stands up and demands the removal of all white teachers of colored children and the installment of a black superintendent.  Concurrently, there is a struggle within the school board over the equalization of pay between male and female teachers.  The two issues roil the still-recovering community.
	*goto rumors_of_plague
*elseif memphis_reception_planner = "Sally"
	*set sally "Sally"
	Since the reception, you have maintained some degree of contact with Sally Little, the wife of Percival Little.
	*label introduced_to_protest
	She has kept you informed of the progress of various women's issues in the city, most notably the increased agitation by the teachers to equalize pay between women and men.
	*goto daily_appeal
*elseif memphis_reception_planner = "Harriet"
	*set sally "Harriet"
	Since the reception, you have maintained some degree of contact with Harriet Lane, the temperance worker.
	*goto introduced_to_protest
*elseif memphis_reception_planner = "Olivia"
	*set sally "Olivia"
	Since the reception, you have maintained some degree of contact with Olivia Hill, the daughter of Napoleon Hill.
	*goto introduced_to_protest
*elseif (compassion < 40) or (shepherd_credentials < 40)
	*page_break
	It is with some surprise that the controversy first erupts into your consciousness: various members of the school board for Memphis have been arguing stridently for the equalization of pay between male and female schoolteachers.
	*goto daily_appeal
*else
	*goto rumors_of_plague

*label learn_about_hugh
*set met_stennis true
*set tasked_hugh true
*set carothers_ignorant_of_pb false
*if invited_to_crapaud = false
	*set invited_to_crapaud true
	A few nights after the caucus, you receive a note from Carothers.  He invites you to join him at the [i]crapaud[/i]-den the next evening.
	@{(carothers_rapport > 40) Though you will have trouble fitting him into your busy schedule, you suppose that you could squeeze him in.|Though less than amused, you decide it best not to antagonize the Quaestor in the wake of his rather humiliating defeat.}
	*page_break
Arriving at the [i]crapaud[/i]-den, Carothers introduces you to Stennis.  "This is Stennis; he is one of many individuals I employ in the city to keep me apprised of the goings-on here."
*if perception > 1
	From a brief glance, you can tell that Stennis is a mortal.
	*if compassion < 40
		You greet him with a ${bow}.
	*if (compassion >= 40) and (compassion <= 60)
		You nod in his general direction.
	*if compassion > 60
		You stare at him dispassionately for a moment, making sure that he knows you could eat him for lunch if you were so moved.
*else
	*set carothers_rapport %-5

	"He is not one of us, I take it?"
	
	"No, certainly not."

"And you called me here to meet him?"
	
"Yes.  
*if mentioned_gallagher_to_carothers
	As you first disclosed to me, Hugh Gallagher has been skulking around the city. He has failed to observe the Rule of Respect."
*else
	He has discovered the presence of an interloper, a vampire who has failed to observe the Rule of Respect."

	"Who is this outlaw?"

	"From what Stennis tells me, his name is Hugh Gallagher, an Irishman with a noticable gap between his front teeth." @{met_hugh_in_vicksburg You remember meeting Hugh on the docks in Vicksburg.  Interesting that he was careful to observe the Rule of Respect there, but flouts it here.|}

"And I take it that you would like for me to apprehend this individual?"

"Stennis may be in contact with you, if Dido and I are otherwise occupied.  Your cooperation would be appreciated."

"Yes, Quaestor."  
*if whiskey_ring_plot and (whiskey_intermission = false)

	*goto whiskey_explanation
*elseif first_memphis_reception_attended = 2
	*set first_memphis_reception_attended 3

	"Now, about your absence from the recent reception and caucus…"
	*if invitation_to_reception_accepted = false
		When you look at him blankly, Dido interjects, explaining that you missed a gathering of senators from across the continent who had come to choose a senator for Memphis.  Unfortunately, they were unable to agree upon a candidate, and the matter was adjourned without resolution.

		Before you take your leave, Carothers urges you in no uncertain terms to reconsider your antisocial behavior.
	*else
		Though such things are clearly of little interest to you, Carothers makes sure that you're aware of the gravity of the mistake you have made.  Senators from across the continent came to elect a senator for Memphis, but they were unable to agree upon a candidate.  The matter was adjourned without resolution.

		Before you take your leave, Carothers urges you in no uncertain terms to reconsider your antisocial behavior.
*else
	With that, you take your leave.
*page_break
*return

*label whiskey_explanation
*set whiskey_intermission true
"Now, about this Aichinger affair…"

"Yes?  What was it that was troubling Senator Bailey?"

"What do you know about these Whiskey Rings?"

"Little, I'm afraid," you reply.

"Yes, well, according to the Senator, several years ago some Republican officials realized that they were in need of funds in order to assure their continued control of Missouri.  With Missouri, you see, would come Presidents Grant's reëlection.  These officials, Federal appointees, are the very individuals charged with assessing and taxing the whiskey.  As you know, however, Grant has been reëlected, but the fraud continues.  And now these officials engage in this activity for their own benefit and even seek to extend their reach, expanding into Chicago, Louisville, and Memphis.  Moreover, it seems that this Aichinger fellow is deeply involved with the conspiracy."

*if shepherd_credentials > 60
	*set carothers_rapport %-10
	"What does this matter to us?"

	"I could take it as an infringement on my territory, if I so chose.  But there are so many ways to handle the matter."
*elseif shepherd_credentials >= 35
	"Obviously, this is a complex matter…"

	"I couldn't agree more, ${mr} ${surname}."
*else
	"The question that occurs to me is this: what is best for the people of Memphis?"

	"It is that very question that troubles me."

*if (carothers_rapport > 60) and (carothers_humanity <= 5)
	For the first time ever, Carothers seems unsure of himself.  "What do you think I should do, ${mr} ${surname}?"

	"What do you think you should do, Quaestor?"

	"Lincoln freed my people.  Grant defeated the Confederacy on the field of battle.  The Republican Congress instituted Reconstruction.  These are great deeds, deeds worthy of loyalty.  But this fraud?  A government stealing from itself to finance the perpetuation of this regime?  Though I detest the Democrats, this does not sit well with me."
*choice
	#"I think you should see to it that the conspiracy does not expand to Memphis; it is an infringement on your territory."
		*set independence %+20
		*set whiskey_ring_counsel 1
		"I will take your words into consideration.  Now, if you will excuse me…"

	#"I think you should see to it that the conspiracy does not expand to Memphis; Senator Bailey will be in your debt."
		*set independence %+20
		*set discretion %+10
		*set whiskey_ring_counsel 2
		"I will take your words under consideration.  Now, if you will excuse me…"

	#"I think you should allow the conspiracy to extend here, but make sure to contact Aichinger and see that you receive your share."
		*set compassion %+10
		*set discretion %+10
		*set carothers_rapport %-10
		*set whiskey_ring_counsel 3
		*set carothers_humanity +1
		"I will take your words under consideration.  Now, if you will excuse me…"

	*selectable_if (discretion > 30) #"What do you care about what another vampire does to make money?"
		*set shepherd_credentials %-15
		*set discretion %+10
		*set carothers_rapport %-10
		*set whiskey_ring_counsel 4
		"It is not a matter of him making money, ${mr} ${surname}.…" He waves his hand in frustration.  "Clearly, you do not understand what is important to me."

		"Clearly not, Quaestor."
	*selectable_if (compassion < 65) #"You must put a stop to this!  This corruption cannot stand!"
		*set compassion %-10
		*set shepherd_credentials %+10
		*set discretion %+5
		*set whiskey_ring_counsel 5
		"I will take your words under consideration.  Now, if you will excuse me…"

At that, you take your leave.
*page_break
*return

*label learn_about_caucus
A few nights after your misadventures with $!{wilson}, you receive a note from Carothers, inviting you to his [i]crapaud[/i]-den.  Not wanting to offend him twice in such rapid succession, you make your way there at the appointed time.

Upon your arrival, Carothers immediately begins to chastise you for your absence from the recent reception and caucus.  
*if (invitation_to_reception_accepted = false) and (first_memphis_reception_attended < 4)
	When you look at him blankly, Applethorp interjects, explaining that you missed a gathering of senators from across the continent who had come to choose a senator for Memphis.  Unfortunately, they were unable to agree upon a candidate, and the matter was adjourned without resolution.

	Before you take your leave, Carothers urges you in no uncertain terms to reconsider your antisocial behavior.
*else
	Though such things are clearly of little interest to you, Carothers makes sure that you're aware of the gravity of the mistake you have made.  Senators from across the continent came to elect a senator for Memphis, but they were unable to agree upon a candidate.  The matter was adjourned without resolution.

	Before you take your leave, Carothers urges you in no uncertain terms to reconsider your antisocial behavior.
*page_break
*return

*label daily_appeal
*set barnum_thompson_plot true
In addition to issues of pay, there is a concurrent push within the black community for the firing of all white teachers at colored schools and for the installment of a colored superintendent.  Together, the two issues roil the community.
*if sally = "Sally"
	Surprisingly, ${sally} twists your ear about how the majority of her people are not fit to govern themselves, and that the Republican presence is necessary to prevent the former Confederates from reasserting their dominance over the South.
*elseif (sally != "blank")
	Of course, ${sally} is happy to fill your ears with reasons why the coloreds are right to demand these changes, and how the Republican missionaries should return from whence they came.

*label rumors_of_plague

*if met_stennis
	*gosub merodach_rants
	*page_break
	Stennis continues sending you updates regarding his search for ${maddox}, but there are no more sightings for the time being.
*elseif rumors_of_plague
	*if (letter_directing_to_stennis) and (met_stennis = false)
		*set met_stennis true
		The next evening, you finally connect with Stennis.  He claims to have seen ${wilson} and directs you to a plague-ridden house in the Pinch.  He even goes so far as to say that ${wilson} himself is ill. You scoff at this and chastise him for wasting your time when he concedes that he has no more intelligence on ${wilson}'s current whereabouts.  He promises to keep you better apprised when next ${wilson} appears.
		*if (compassion > 40) and ((discretion > 50) and (willpower < 4))
		
			Managing these mortal servants often requires more patience than you have.  You find it challenging to not tear his throat from his body.
		The good news is that ${wilson} is—or recently was—still in Memphis.
	*gosub merodach_rants
*else
	*set rumors_of_plague true
	*if (letter_directing_to_stennis) and (met_stennis = false)
		*set met_stennis true
		The next evening, you finally connect with Stennis.  He claims to have seen ${wilson} lurking about the heart of the plague-zones.  He even goes so far as to say that ${wilson} himself is ill.  You scoff at this and chastise him for wasting your time when he concedes that he has no more intelligence on ${wilson}'s current whereabouts.  He promises to keep you better apprised when next ${wilson} appears.
		*if (compassion > 40) and ((discretion > 50) and (willpower < 4))
		
			Managing these mortals servants often requires more patience than you have.  You find it challenging to not tear his throat from his body.
		The good news is that ${wilson} is—or recently was—still in Memphis.
	*elseif letter_directing_to_stennis = false
		So preoccupied were you with the election, you did not realize that the yellow fever had arrived in Memphis.  The physicians are claiming that it must have arrived via steamboat.  Amidst the chaos and death, however, the source of the outbreak takes a secondary role to addressing the needs of the living and the soon to be dead.
	*gosub merodach_rants
	
	Over the next few weeks, the yellow fever roars to its climax.  Thousands fall ill, and hundreds die.  The economy of the city grinds to a halt until the middle of October, when a sudden cold snap coincides with a dramatic decline in new infections.  
	*if rationalism > 50
		*set rationalism %+5
		*set anachronism %-5
		You feel justified in your diagnosis of the miasma: it is clear to you that the cold winds disperse the befouled air; those proponents of the contagion hypothesis are clearly misguided.

During these lean months, you are confronted with the danger this epidemic poses to your kind. 
*if feeding_style = "vegetarian"
	Even though you feed from animals, that has become surprisingly dangerous. As the economy grinds to a halt, people begin to go hungry; when people go hungry, thefts begin. And when thefts begin, property-owners rise to defends their property with zeal.
	
	*if (income < 20)
		Thus, whether you accost a pig, a horse, or a cow, too often a sheepdog or a wary owner comes and interrupts you. 
		*if oblivio
			Thankfully, you are able to use the [i]verba oblivionis[/i] to avoid any further indignities.
		*else
			More than once, you find yourself face-down in the muck, waiting for someone to pass you by.
*else
	Hunting for prey becomes much more difficult, as everyone in the city is on edge. More than once, you are nearly interrupted while in a compromising situation. You lose track of the number of times you give thanks that there are so few of your kind in this city; in truth, you sometimes wonder if there are too many.

By the first of November, the fever has run its course, and the city returns to something resembling normalcy. 
*goto coinage_act

*label merodach_rants
*if speaks_english = false
	*return
*page_break
"And the Lord God Almighty calls upon us to burn away our sins…"

The sun set an hour or so ago, and during an evening perambulation you happened upon this preacher in Market Square, calling upon his neighbors to repent.

"And the angel of the Lord appeared to me, and sent me here to cleanse this city!"  He stands on a simple stage, lit by torchlight.  His hair and beard are wild and unkempt, but his eyes—what you can see of them in the firelight—are unclouded.

"Amen!"

"A blight is upon the land, a blight upon the beasts of the field…."  The impromptu revival has attracted something of a crowd, resulting in the listeners calling out their Amens when moved to do so.  "A blight upon the women, who can bear no children," he howls, gesturing to a woman, wrapped in a shawl, who takes the stage beside him.  She unwraps a parcel in her arms, revealing a stillborn babe, several days dead.  The crowd gasps in horror; one woman faints.  "Do you see?  Or has your pride blinded you?  The wages of sin are death.  We will not find peace until these crimes have been expunged!"

"AMEN!"

"What will you do?  Will you seek out the crimes that have polluted this land, and bring their perpetrators to justice?  And what of your sins?  Will you confess them when called upon to account?"

"AMEN!"

*choice
	#Leave the preacher to his delusions.
		*set rationalism %-5
		*set anachronism %+5
		You have enough of your own troubles.  There is no need to invite mischief by involving yourself with an unbalanced fanatic.
		
		*return
	*if (feeding_style = "clergy") and (discretion > 30)
		#Wait until he finishes, and feed from him.
			He whimpers when your fangs sink into the flesh of his neck.
			*if (rationalism < 50) and (compassion > 45)
				"Where is his God now?" you wonder.
			*page_break
			*return
		*selectable_if (compassion > 40) #Wait until he finishes, feed from him, and then kill him.
			*set merodach_alive false
			*set compassion %+10
			He whimpers when your fangs sink into the flesh of his neck.
			*if (rationalism < 50) and (compassion > 45)
				"Where is his God now?" you wonder.
				
			When you have finished, you lick the wound and leave his body to be discovered by his flock.
			*page_break
			*return
	*selectable_if (rationalism > 60) #Angel?  What angel?  I must find out more!
		*set rationalism %+5
		After the preacher has finished his excoriation of the city and its people, he and his closest disciples extinguish their torches, pack up their rickety stage, and prepare to depart.
		
		You approach the preacher and entreat him to speak more on the angel that appeared to him.
		*label merodachs_discourse
		*set merodach_discourse true
		"My name is Merodach Ross.  My trade is that of a carpenter; formerly, I built houses in Louisville.  There, I was a sinful man; I indulged in the company of women and drink.  But the angel of the Lord appeared to me one night and commanded me to repent of my sins."
		
		"He appeared to you?   While you were awake?  You are sure that it was not a dream?"
		
		"It was more…feminine than masculine.  But yes, she appeared to me…I had never been more awake in my life.  She commanded me to repent of my sins, which I did.  And she told me that she would return, and she did, some months later.  And she told me that I should head west to bring the Word of God to the sinners of Memphis, which I have done."
		
		"Why Memphis?"
		
		"She said that there was a crime at the heart of Memphis, a boil that must be lanced if the wound is to heal.  That until the sins were exposed, there would be no peace."
		
		"When was this?"
		
		"Last fall?  October, in fact."
		
		For the rest of the evening, you muse on Merodach's words. @{met_harding Would Harding stoop so low as to urge this broken man to come here?|} No answer presents itself.
		*page_break
		*return
	#I approach him for a more pointed discussion; perhaps there is some insight to be gleaned from this man's ravings.
		*set rationalism %-5
		After the preacher has finished his excoriation of the city and its people, he and his closest disciples extinguish their torches, pack up their rickety stage, and prepare to depart.
		
		You approach the preacher and entreat him to speak more on the plagues that beset Memphis.  After some assurances that you mean him no harm, he relents and begins to tell his story.
		*goto merodachs_discourse
	*if (choice_randomtest = false) or ((perception >= 3) and (willpower <= 3))
		*if (rationalism > 50) and ((religious_tradition = "catholic") or (religious_tradition = "reformed"))
			*selectable_if (discretion > 40) #I wish to confess my sins to the preacher.
				*set rationalism %+10
				*set discretion %+10
				After the preacher has finished his excoriation of the city and its people, he and his closest disciples extinguish their torches, pack up their rickety stage, and prepare to depart.
				
				You approach the preacher and beg that he listen to your confession.
				*if religious_tradition = "catholic"
					"You know that I cannot shrive your soul, ${son}.  That is the way of papists.  I can only listen to the unburdening of your soul…."
					
					"I understand, Reverend…" you reply.  
					
					After a moment, he nods.  "I have two ears to listen.  What have you to say?"
				*elseif religious_tradition = "reformed"
					"I have two ears to listen.  What have you to say?"
				
				The words fall from your lips.  The death and the blood and the crimes against God.  Tears of blood stream down your cheeks, and you fall to your knees, unburdening yourself before this stranger.
				
				Over an hour has passed by the time that you finish.  He has long since sent his disciples home, and Market Square is empty but for the two of you in the moonlight.
				
				"Do you know what brought me to Memphis, ${son}?"
				
				"No…"
				
				"An angel of the Lord appeared to me, and she commanded me to come here.  To seek out the sin at the heart of Memphis and expunge it.  To cleanse this place of the evil that beset it."  He lifts your chin, so that he can look you in the eye.  "I have been searching high and low for the source of that sin—what could she have meant? And what could I do about it?—I had nearly given up hope.  Shame on me, for doubting her, even for a moment.  Oh!  For the Lord works in mysterious ways!  Even now he redeems me for my sins!  I think that he means for us to be redeemed together.  Is that what you seek?  To be forgiven?"
				
				"I do."
				
				"Then close your eyes, and let us pray together."  
				
				You close your eyes and begin to recite the 23rd Psalm with him.  You can feel your brow relaxing as you intone the prayer.
				*if perception >= 3
					*if willpower <= 3 
						*set compassion %+10
						*set rationalism %+5
						And yet, though your eyes are closed, you can feel the righteous fury that the preacher directs at you.  Try as you might, you are not ready to die tonight.  When he moves to strike you, you cannot stop yourself from intervening.  He clutches a stake in his hand, spitting and cursing your unholy nature.  
						*label exposed
						*set merodach_alive false
						
						Exposed for what you are, furious at his betrayal of your trust and your own inability to submit to his punishment, you unleash the beast that prowls inside you.  It comes out screaming, enveloping the Reverend in its rage.
						*page_break
						When you regain control of your faculties, you note that your clothes will have to be replaced.  They are torn in several places and drenched in blood.  The body of the preacher is mangled as though by some wild beast.
						
						It is some work disposing of the corpse before the factory workers stir from their homes, but you manage it.  You suppose that the Reverend's flock will come searching for him, but you do not think that they offer any further threat to you.
						*page_break
						*return
					*else
						*set killed_by_mortal true
						And though your eyes are closed, you sense the imminent danger.  Concentrating on the words, you restrain yourself, allowing the preacher to drive his stake into your heart unmolested.
						*label fade_out
						
						As your awareness of your environment narrows and finally goes dark, you do your best to keep your mind on the words of the psalm, your guide in the darkness.
						*page_break
						*goto_scene scoring
				*elseif strength > 3
					Unfortunately, the preacher does not realize the strength of your undead form.  The stake which he had so cleverly hidden from you is untempered, and it fails to pierce your ribcage.
					*goto exposed
				*else
					
					Though your ears hear a rustling, you do not realize that it is a stake which he now holds over your chest.  And when he drives it into your heart, it is too late for you to protest.
					*goto fade_out

*label coinage_act
*if finance > 0
	*page_break
	Led by several merchants—including Napoleon Hill—the Memphis Cotton Exchange is incorporated in December. The Exchange regulates the trade of cotton in the city, and promises to help revitalize the local economy.  For a time, it seems the future of Memphis is bright. That is, until a series of decisions in foreign capitals turn out to have local repercussions.
*elseif finance = 0
	That is, until a series of decisions in capitals throughout the world turn out to have local repercussions.
	*page_break

With the Coinage Act of 1873, President Grant demonetizes silver, effectively moving the United States to the gold standard.  The Act follows a pattern set by the nascent German state, as well as Canada.  Unfortunately, the sudden lack of liquidity in the market freezes investment and results in risk-averse decisions by investors.

By the end of 1873, banks across the nation begin to fail as they find themselves unable to meet their obligations.  Most dramatically for Memphis, the Freedmans Savings & Trust declares bankruptcy on June 29th, 1874.  All deposits are lost, and the black community is devastated.

*set carothers_humanity +1
*if amount_invested_freedmans > 0
	*set amount_invested_freedmans 0
	You are not ruined, but the repercussions to your finances are dramatic.
*elseif amount_invested_freedmans = 0
	You suffered no losses at that particular bank, but it is by no means the only symptom of the times.
In later years, this period will be known as the Long Depression.  Across the country, land values plummet, brokerage houses go bankrupt, and speculators close up shop.  
*if finance = 0
	*set income * 0.5
*if finance = 1
	*set income * 0.6
	Due to the occasional attention you pay to the condition of your investments, they were not as devastated as they might have been.
*if finance = 2
	*set income * 0.7
	You give thanks that you pay attention to the condition of your investments; while they have been damaged, it could have been far worse.
*if finance > 2
	*set income * 0.8
	You give thanks that you pay such close attention to the condition of your investments; while they have been damaged, it could have been far worse.
*if whiskey_ring_plot and (streetwise > 0)
	*gosub whiskey_ring_arrives
*if (whiskey_ring_plot = false) and (new_orleans_enterprise = 2)
	*gosub whiskey_back_door
*if (whiskey_ring_plot = false) and (streetwise > 2)
	During this time, you hear whispers of a conspiracy within the Treasury Department of the United States.  It seems that an organization has taken it upon themselves to manufacture and distribute whiskey without paying taxes.
	*gosub whiskey_brute_force
*if barnum_thompson_plot
	*page_break
	At the beginning of the fall term of 1874, a black schoolteacher from Ohio by the name of Thompson is fired by Superintendent Barnum, a white man.  Barnum, a northern missionary, sees it as his spiritual obligation to educate the negro children of Memphis in the ways of the Lord; the local colored community, on the other hand, believes that they are capable of educating their own children.
*goto memphis_debt

*label whiskey_ring_arrives
*page_break
Later that same summer, the Whiskey Ring arrives in Memphis.

It is still in its nascent stages.  Moreover, as best as you can tell, Carothers has taken no steps to involve himself in the affair.  Perhaps there is an opportunity for you here?
*choice
	#I intend to take my share of the profits.
		*label whiskey_joined
		*set whiskey_ring_status "joined"
		*set shepherd_credentials %+5
		*set aichinger_rapport %+10
		*if whiskey_ring_counsel = 1
			After all, if Carothers does not deign to profit from the matter, why shouldn't you do so in his stead?
		*if whiskey_ring_counsel = 3
			Though you had advised Carothers to contact Aichinger, you are unacquainted with the individual.  Moreover, you tell yourself, isn't it his duty to contact you, considering the fact that he extends his affairs into your city?
		*if whiskey_ring_counsel = 5
			*set discretion %-10
			*set compassion %+10
			You are a clever vampire, aren't you?  Counseling Carothers to stop the ring, and then seeking to profit it from it?
		*set income +2
		*set income +finance
		*set wealth +15000
		*set wealth +(finance * 5000)

		It is not hard to insert yourself into the organization.  Soon, you too are receiving a monthly stipend in exchange for your silence.
		*return
	#I will do everything in my power to perpetuate the conspiracy.
		*if (streetwise > 2) or (charm > 3)
			*set whiskey_ring_status "encouraged"
			*set aichinger_rapport %+15
			*set shepherd_credentials %-10
			*if whiskey_ring_counsel = 1
				After all, if Carothers does not deign to profit from the matter, why shouldn't you do so in his stead?
			*if whiskey_ring_counsel = 3
				Though you had advised Carothers to contact Aichinger, you are unacquainted with the individual.  Moreover, you tell yourself, isn't it his duty to contact you, considering the fact that he extends his affairs into your city?
			*if whiskey_ring_counsel = 5
				*set discretion %-10
				*set compassion %+10
				You are a clever vampire, aren't you?  Counseling Carothers to stop the ring, and then seeking to profit it from it?
			*set income +5
			*set income +(finance * 3)
			*set wealth +30000
			*set wealth +(finance * 10000)

			It is not hard to insert yourself into the organization.  Soon, the entire tax assessment office is in on the conspiracy, with journalists writing articles to paper over the activities.  Distillers, shippers, warehousers…everyone is on the take.
			*return
		*else
			*goto whiskey_joined
	#I will not stand for this corruption.  I do my utmost to stop its progress.
		*set compassion %-10
		*set shepherd_credentials %+10
		*if (streetwise > 2) or (charm > 3)
			*set whiskey_ring_status "blocked"
			By means both fair and foul, you stop the expansion of the Whiskey Ring in its tracks.  It soon becomes something of a joke that the only honest men in the Treasury Department are in Memphis.
			*return
		*else
			*set whiskey_ring_status "limited"
			Though you cannot fully block its expansion into the city, you do an admirable job of limiting its activities.
			*return
	#I will not stand for this corruption.  I do my utmost to publicize the matter.
		*set whiskey_ring_status "exposed"
		*set compassion %-10
		*set discretion %+15
		You set about trying to expose the affair, but often find both politicians and journalists unwilling to discuss the matter.  It seems that the ring has its servants littered throughout both fields.

		Nevertheless, you refuse to be dissuaded from your goal.  Though it may take some time, you will see that the matter is ended.
		*return
	#Meddle in the affairs of another vampire?  How uncouth.
		*set shepherd_credentials %-5
		*set independence %+10
		*set discretion %-10
		*set aichinger_rapport %+5
		Surely, Aichinger will appreciate your discretion and respect for his dealings—once you have the opportunity to inform him of such.
		*return
	*if merodach_alive and merodach_discourse
		#I arrange for the preacher Merodach Ross to learn the location of the Whiskey Ring's operations.
			*set discretion %-10
			*set shepherd_credentials %+5
			*set whiskey_ring_status "merodach"
			Merodach incites his flock to rage at this source of corruption in the city.  They burn down a small warehouse that was storing the illegal liquor, but Merodach is arrested when the police find him standing before the flames, preaching hellfire and brimstone.  
			
			The affair barely makes the newspapers; it seems that the ring has its servants littered throughout the journals.  Fortunately for Ross, the absence of individuals willing to claim a loss means that the city is anxious to offer him a plea bargain, which he accepts.  Within a few weeks, he is back on the streets proclaiming the wickedness and corruption of the Republican administration.
			*return

*label whiskey_back_door
*page_break
Though it has been some time, your criminal connections from New Orleans are not entirely dissolved.  Thus, you are only mildy surprised to learn from them of a conspiracy within the Treasury Department to avoid taxes on whiskey.  
*label whiskey_brute_force
*set whiskey_ring_plot true
The conspiracy seems to have begun in St. Louis during the run-up to the recent presidential election, and it has since spread outwards from there.
*choice
	#I intend to take my share of the profits.
		*label whiskey_joined_back_door
		*set whiskey_ring_status "joined"
		*set shepherd_credentials %+5
		*set aichinger_rapport %+10
		*set income +2
		*set income +finance
		*set wealth +15000
		*set wealth +(finance * 5000)
		It is not hard to insert youself into the organization.  Soon, you too are receiving a monthly stipend in exchange for a minimal effort on your part.
		*return
	#I will do everything in my power to perpetuate the conspiracy.
		*if (streetwise > 2) or (charm > 3)
			*set whiskey_ring_status "encouraged"
			*set aichinger_rapport %+15
			*set shepherd_credentials %-10
			*set income +6
			*set income +(finance * 2)
			*set wealth +30000
			*set wealth +(finance * 10000)
			It is not hard to insert yourself into the organization.  Soon, the entire tax assessment office is in on the conspiracy, with journalists writing articles to paper over the activities.  Distillers, shippers, warehousers…everyone is on the take.
			*return
		*else
			*goto whiskey_joined_back_door
	#I will not stand for this corruption.  I do my utmost to stop its progress.
		*set compassion %-10
		*set shepherd_credentials %+10
		*if (streetwise > 2) or (charm > 3)
			*set whiskey_ring_status "blocked"
			By means both fair and foul, you stop the expansion of the Whiskey Ring in its tracks.  It soon becomes something of a joke that the only honest men in the Treasury Department are in Memphis.
			*return
		*else
			*set whiskey_ring_status "limited"
			Though you cannot fully block its expansion into the city, you do an admirable job of limiting its activities.
			*return
	#I will not stand for this corruption.  I do my utmost to publicize the matter.
		*set whiskey_ring_status "exposed"
		*set compassion %-10
		*set discretion %+15
		You set about trying to expose the affair, but often find both politicians and journalists unwilling to discuss the matter.  It seems that the ring has its servants littered throughout both fields.

		Nevertheless, you refuse to be dissuaded from your goal.  Though it may take some time, you will see that the matter is ended.
		*return
	#What do I care about these mortal conspiracies?
		*set shepherd_credentials %-10
		*set independence %+10
		*set discretion %-10
		*set whiskey_ring_plot false
		Surely, Aichinger appreciates your discretion and respect for his dealings.
		*return

*label memphis_debt
*page_break
*if watching_james
	It seems somehow appropriate that Jesse James would swear love and fidelity while banks across the globe collapse under the weight of their debts. Thus, despite these international misfortunes—or perhaps due to them—James takes this opportunity to marry his cousin, Zerelda Mimms, in April of 1874.  Though their wedding is interrupted by US Marshals, the two make good their escape and journey to Texas for a honeymoon on the sly.
	
	The whole affair—especially the incompetence of the Marshals—is recounted with a degree of levity in the newspapers. The US Government is humiliated by its inability to capture the outlaw and his associates.

Meanwhile, in New Orleans, the strife between Republicans and Confederates continues to build. On September 13th, five thousand members of the White League—soon dubbed the Louisiana State Militia by the shadow legislature—cut the telegraph lines of the city and march on the Vieux Carré. Tipped off to the matter, the Republican governor orders the police to defend the city at all costs.

The two forces array themselves at opposite ends of Canal Street; snipers take positions in the windows of the buildings that line the wide boulevard. When signaled, the Militia begins their assault and within fifteen minutes the police are routed. Dozens of people on both sides of the battle are killed, including onlookers who gathered to watch. Within hours, the White League takes over the city—and thence the State. Three days later, a Federal regiment arrives in New Orleans and asserts control of the Federal buildings in the vicinity of Vieux Carré, but other than those few square blocks, the rest of Louisiana is now governed from the Odd Fellows Hall by the shadow governor and his legislature of Confederates.

*temp thirty_five "thirty-five"
*temp fifty "fifty"
At the same time, Memphis has been defaulting on interest payments year after year, causing the value of the bonds issued for the paving of the streets to plummet in value.  Once the Brown case—the contractor who paved the city streets—reaches the Supreme Court, the municipal government is ordered to make good on its debts, to the tune of $500,000.
*if noticed_paving = false
	*set noticed_paving true
	These paving-blocks, of which you only recently took note, were commissioned in the heady days of Reconstruction.  Most of the downtown area was paved with them.  

	Now, however, the blocks are rotting, and the former Confederates—who were denied participation in the decision-making process in the first place—refuse to pay the taxes to fund the debt incurred by these paving blocks.  In their opinion, the debt was incurred by irresponsible freedmen and Republicans; why should they be obligated to pay for it?
*comment endif

Major Minor Meriwether—a Memphis native, former Confederate, and close friend of Nathan Bedford Forrest—organizes the People's Protective Union, arguing for the restructuring of the city's debt, the elimination of municipal offices, and even advocating for the revocation of the city's charter.  They argue in the papers and in city committees that the debt is in large part unlawful, incurred by an illegitimate government from which the actual tax-payers (the former Confederates) had been excluded by the laws of Reconstruction.  Of course, these same former Confederates have often refused to pay these taxes, further damaging the city's ability to right itself.
*temp lawsuit false

Mayor Flippin meets with a large portion of the creditors, offering fifty cents on the dollar.
*if municipal_debt > 0
	You, in fact, hold bonds worth $${municipal_debt}.  The meeting will be held tomorrow evening, and the offer will only be valid if all the creditors agree to it.
*if municipal_debt = 0
	For once, you are grateful for your general lack of means: you do not hold any municipal bonds as part of your @{(finance > 0) investment porfolio|assets}.  That aside, there will be a meeting tomorrow of the creditors, where they will discuss the offer.
*if carothers_rapport > 60
	Carothers has pleaded with you to join with the other creditors and accept Flippin's offer.
*if (carothers_rapport >= 40) and (carothers_rapport <= 60)
	Carothers has made his opinion clear that the city would benefit from the creditors accepting Flippin's offer.
*choice
	*if municipal_debt > 0
		#I send my attorney to join with the creditors and agree to the offer.
			*set carothers_rapport %+10
			*set shepherd_credentials %+5
			The gathered creditors agree to the offer, but assorted individuals refuse and individually sue the municipal government for the debt owed. 
		*selectable_if (finance > 0) #I draw up an argument for why the city should offer more and send my attorney to press for a better offer.
			*set carothers_rapport %+5
			*set shepherd_credentials %+5
			*set discretion %+10
			*set thirty_five "forty"
			*set fifty "fifty-five"
			*set lawsuit true
			With your backing, the creditors are able to negotiate the rate to fifty-five cents on the dollar.  Both the city and the creditors seem pleased with this outcome, but various individuals refuse to join in the agreement and continue to sue the city for the full amount owed.
		#I refrain from participating, and instead seek individual relief.
			*set carothers_rapport %-15
			*set lawsuit true
			Several of the other creditors refuse the terms, and join with you in suing the city for the full amount owed.
		#This is not enough of a concern for me to bother with.
			*set discretion %+15
			*set shepherd_credentials %-10
			You brush off Franklin's concerns and order him to deal with it.
		#Money is of little importance to me. I donate the bonds to charity.
			*set carothers_rapport %-5
			*set discretion %-5
			*set compassion %-5
			*set municipal_debt 0
			*set local_fame %+20
			
			Carothers is not as upset as he would otherwise have been, had you sold them. Donating them to charity means that they are still outstanding, and thus still serve his purposes.
			*goto first_intermission_end
	*if municipal_debt = 0
		#I hold no bonds; I have no need to bother with these affairs.
			*set discretion %+5
			*set shepherd_credentials %-10
			*goto first_intermission_end
		*selectable_if (finance > 0) #Even though I hold no bonds, I draw up an argument for why the city should offer more and send my attorney to press for a better offer.
			*set carothers_rapport %+5
			*set shepherd_credentials %+10
			*set discretion %+10
			*set thirty_five "forty"
			*set fifty "fifty-five"
			With your backing, the creditors are able to negotiate the rate to fifty-five cents on the dollar.  Both the city and the creditors seem pleased with this outcome, but various individuals refuse to join in the agreement and continue to sue the city for the full amount owed.
			*goto first_intermission_end
	#Considering the financial panic and my faith in Carothers's leadership, I think now is the time to buy @{(municipal_debt = 0) some|more} of these bonds.  Of course, I will negotiate for a quality rate.
		*if (charm > 3) or (finance > 1)
			You are able to negotiate a price of thirty cents on the dollar.  What is the face value of the bonds you would like to purchase?
			*choice
				#Nothing.  That is not low enough.
					The creditors are frustrated that you have withdrawn from negotiations, but you doubt there will be any lasting repercussions to your stature in the city.
					*goto first_intermission_end
				*selectable_if (wealth > 12750) #$5,000.
					*set memphis_profiteer true
					*set wealth -25500
					*set municipal_debt +5000
					*set carothers_rapport %+10
				*selectable_if (wealth > 25500) #$10,000.
					*set memphis_profiteer true
					*set wealth -51000
					*set municipal_debt +10000
					*set carothers_rapport %+10
				*selectable_if (wealth > 63750) #$25,000.
					*set memphis_profiteer true
					*set wealth -127500
					*set municipal_debt +25000
					*set carothers_rapport %+5
				*selectable_if (wealth > 127500) #$50,000.
					*set memphis_profiteer true
					*set wealth -255000
					*set municipal_debt +50000
				*selectable_if (wealth > 255000) #$100,000.
					*set memphis_profiteer true
					*set wealth -510000
					*set municipal_debt +100000
					*set carothers_rapport %-10
		*else
			You are able to negotiate a price of forty cents on the dollar.  What is the face value of the bonds you would like to purchase?
			*choice
				#Nothing.  That is not low enough.
					The creditors are frustrated that you have withdrawn from negotiations, but you doubt there will be any lasting repercussions to your stature in the city.
					*goto first_intermission_end
				*selectable_if (wealth > 50000) #$2,000.
					*set wealth -13600
					*set municipal_debt +2000
					*set carothers_rapport %+10
				*selectable_if (wealth > 75000) #$4,000.
					*set wealth -27200
					*set municipal_debt +4000
					*set carothers_rapport %+10
				*selectable_if (wealth > 125000) #$10,000.
					*set wealth -68000
					*set municipal_debt +10000
					*set carothers_rapport %+5
				*selectable_if (wealth > 250000) #$20,000.
					*set wealth -136000
					*set municipal_debt +20000
				*selectable_if (wealth > 500000) #$50,000.
					*set wealth -340000
					*set municipal_debt +50000
					*set carothers_rapport %-10
		The seller of the bonds is only too happy to relieve himself of them.
		
		You hope that you have made a wise investment.
		*goto first_intermission_end

While the matter is still being negotiated in the courts@{lawsuit —including your lawsuit—|, }a speculator approaches Franklin and offers to buy your municipal bonds at ${thirty_five} cents on the dollar. Mayor Flippin has announced that the city will not pay anyone until all creditors have agreed to the discount. @{lawsuit It could be months or years before your lawsuit is resolved.|}
*choice
	#I accept the speculator's offer.  I don't think the city will find a solution to this problem.
		*set carothers_rapport %-15
		Whether Carothers likes it or not, you are now divested from Memphis.  You move your money into safer investments.
		*if thirty_five = "forty"
			*set wealth +((municipal_debt * 0.4) * 17)
		*else
			*set wealth +((municipal_debt * 0.35) * 17)
		*set municipal_debt 0
	#I accept the speculator's offer, but only cash in half of my bonds.  It is important to remain on good terms with Carothers.  Besides, the city may finally bring the creditors to heel.
		*set carothers_rapport %-5
		*set discretion %-15
		*set municipal_debt round(municipal_debt / 2)
		Probably a wise choice: you maintain good relations with Carothers while reducing your exposure.
		*if thirty_five = "forty"
			*set wealth +((municipal_debt * 0.4) * 17)
		*else
			*set wealth +((municipal_debt * 0.35) * 17)
	#I refuse the speculator's offer.  Carothers will surely find a way to make all the creditors agree to the city's offer of ${fifty} cents on the dollar.
		*set carothers_rapport %+10
		*set discretion %+5
		You hope that this mess resolves quickly. @{(discretion > 50) You find it absurd that you even have to consider such mundane matters.|You find it frustrating that you have to spend so much time maintaining your finances.}

*label first_intermission_end
*if speaks_english
	*finish Next
*else
	*page_break
	*goto_scene memphis_first_intermission_continued