*comment ñáéç…—
*hide_reuse
*advertisement
*temp samanthas_poem "jesse"
*temp performed false
*temp performed_well false
*temp learn_of_poem false
*temp go_hungry false
*temp arrive_disheveled false
*temp choctaw_confrontation false
*set heard_of_overstreet true
*temp com_sam false
*temp com_jesse false
*temp com_estefania false
*temp favored (embrace_of_affection and (sire_alive and (sire_name != "West")))
*if speaks_english or speaks_french
	*set com_jesse true
	*set com_sam true
	*set com_estefania true
*if speaks_spanish and ((sire_name = "Fernando de Villanueva e Itamaraca") and sire_alive)
	*set com_jesse true
*if speaks_spanish
	*set com_estefania true
*temp dominus "quaestor"
*if jesse_is_broodmate
	*set dominus "dominus"
*temp deshabille "déshabillé"
*if male = false
	*set deshabille "déshabillée"
*set year 1829
*if wealth > 40000
	*gosub money_to_stat
	*page_break
*if (new_orleans_enterprise = 3) or (new_orleans_enterprise = 5)
	*gosub frankenstein
	*page_break
*if male
	It is over a game of billiards one evening that ${new_orleans_quaestor_surname} informs you of the impending arrival of Governor Overstreet. Jesse does not seem surprised by the news, though it is somewhat challenging to ascertain his expression through the voluminous cigar smoke.
	*if taught_about_governors = false

		"Governor?" you inquire.
	
		"Yes, she appoints quaestors to administer the cities within her province."  Your eyes go wide at this.  He continues, "The Three Rules are hers to enforce or forgive.  I serve only at her convenience."  Who could be so powerful…so old…that they are able to appoint and dismiss ${new_orleans_quaestor_surname} at will?  
	"My status as Quaestor of New-Orleans will no doubt be confirmed during this visit."  Clearly, this will be an important moment for ${new_orleans_quaestor_surname} and his reputation in the Society. Once you've had a moment to digest the news, he continues: "I expect for you to conduct yourself with all due respect.  It might in fact be best if you adhere to that rule for mortal children: do not speak unless spoken to. Am I clear?"
	
	"Yes, ${new_orleans_quaestor_address}," you reply, fidgeting in the direction of the next table over. The billiards players have paused so that ${new_orleans_quaestor_surname} does not have to shout over them. 
	
	"Very good.  There will be a reception at my estate on Friday.  I will expect your attendance."
	
	"But of course, @{(new_orleans_quaestor_surname = "Padre Carlos") Padre|Quaestor}," you say with a ${bow}.  ${new_orleans_quaestor_surname} nods and, the game over, exits the social club.
	
	You reassemble the table, and you and Jesse start a new game.
	*temp tick false
	
	*if (senators_explained = false) and (jesse_rapport > 50)
		*set senators_explained true
		*set tick true
		"You know, once a quaestor is confirmed, it's only a matter of time before the Senate convenes," Jesse observes.
		
		"The Senate?"
		
		Jesse smirks. "@{jesse_is_broodmate Our dominus has truly done a poor job in his education of you.|It makes sense that an orphan such as yourself would be so ill-informed.} The Senate elects a Senator to represent a city. Though, in my experience, they mostly gossip among themselves. A petty, spineless bunch."
	*elseif (senators_representation = false) and (jesse_rapport > 60)
		*set senators_representation true
		*set tick true
		"You know, once a quaestor is confirmed, it's only a matter of time before the Senate convenes," Jesse observes.
		
		"The Senate?"
		
		Jesse smirks. "@{jesse_is_broodmate Our dominus has truly done a poor job in his education of you.|It makes sense that an orphan such as yourself would be so ill-informed.} Senators represent the Senate to the cities to which they are appointed. Though, they mostly gossip among themselves. A petty, spineless bunch."
		
	*if tick
		"And yet, New-Orleans will receive one soon?"
		
		"Assuming ${new_orleans_quaestor_surname} is confirmed? Yes, within a few decades."
		
		But then Jesse sinks a billiard ball in a particularly challenging shot, and further discussion stalls as cheers erupt from the onlookers.
*else
	It is over a game of cards one evening that ${new_orleans_quaestor_surname} informs you of the impending arrival of Governor Overstreet.  Estefania does not seem surprised by the news.
	
	*if taught_about_governors = false
		"Governor?" you inquire.
	
		"Yes, she appoints quaestors to administer the cities within her province."  Your eyes go wide at this.  He continues, "the Three Rules are hers to enforce or forgive.  I serve only at her convenience."  Who could be so powerful…so old…that they are able to appoint and dismiss ${new_orleans_quaestor_surname} at will?  
	"My status as quaestor of New-Orleans will no doubt be confirmed during this visit."  You nod gravely at the importance of this to ${new_orleans_quaestor_surname}, who continues: "I expect for you to conduct yourself with all due respect.  It might in fact be best if you adhere to that rule for mortal children: do not speak unless spoken to.  Am I clear?"
	
	"Yes, ${new_orleans_quaestor_address}."
	
	"Very good.  There will be a reception at my haven on Friday.  I will expect your attendance."
	
	"But of course, sir," you reply.  ${new_orleans_quaestor_surname} nods and the game continues.
	
	*if estefania_is_kin and sire_alive
		"We shall make the most of this opportunity to introduce your worthy offspring to the governor, won't we, brother?"
		
		"Yes, yes of course dear sister."
		*if rios_rapport < 40
			Somehow, you do not think that she is referring to you.
		*if rios_rapport > 60
			You beam in the light of this praise.
			
	*if (senators_explained = false) and (rios_rapport > 50)
		*set senators_explained true
		
		"You know, once a quaestor is confirmed, it's only a matter of time before the Senate convenes," Rios observes.
		
		"The Senate?"
		
		Rios's eyes widen in surprise.
		*if estefania_is_kin and sire_alive
			"Nando, have you taught ${given_name} nothing?" she says, slapping him on the upper arm.
			
			Villanueva shoots Rios a glance; the gesture of familiarity is not to his liking. She makes a sour face at him, before answering your question. "A senator 
		*else
			"${new_orleans_quaestor_address}, you neglect your @{sire_alive scion|ward}'s education," she says.
			
			"All things in due time," ${new_orleans_quaestor_surname} retorts.
			
			"Then allow me," Rios replies. Turning to you, she continues, "Yes, a senator 
		will be elected for New-Orleans. Within a few decades, anyway."
		
		With that, however, Rios lays down a winning hand. ${new_orleans_quaestor_surname} growls in frustration, and further discussion dissipates.
	*elseif (senators_representation = false) and (rios_rapport > 60)
		*set senators_representation true
		
		"You know, once a quaestor is confirmed, it's only a matter of time before the Senate convenes," Rios observes.
		
		"The Senate?"
		
		Rios's eyes widen in surprise. 
		*if estefania_is_kin and sire_alive
			"Nando, have you taught ${given_name} nothing?" she says, slapping him on the upper arm.
			
			Villanueva shoots Rios a glance; the gesture of familiarity is not to his liking. She makes a sour face at him, before answering your question. "Senators represent the Senate to the cities to which they are appointed, maintaining decorum when and where necessary."
		*else
			"${new_orleans_quaestor_address}, you neglect your @{sire_alive scion|ward}'s education," she says.
			
			"All things in due time," ${new_orleans_quaestor_surname} retorts.
			
			"Then allow me," she replies. "Senators represent the Senate to the cities to which they are appointed, maintaining decorum when and where necessary."
		
		"And you believe that New-Orleans will receive one soon?"
		
		"Once @{(estefania_is_kin and sire_alive) Nando|${new_orleans_quaestor_given_name}} is confirmed? Yes, within a few decades."
		
		With that, however, Rios lays down a winning hand. ${new_orleans_quaestor_surname} growls in frustration, and further discussion dissipates.
*page_break
	
Your anxiety mounts as the night of the reception arrives.  Decades of your future could turn on your conduct this evening.  

Your toilette carefully attended to, you set out in a hired coupé.  The carriage arrives, and off you go.

The coupé jostles along the paving stones, at first making concentration difficult, but eventually lulling you into something like a reverie.  Between the smells of unwashed bodies, urine, whiskey, and the primitive sewage system, New-Orleans does its best to distract you from its rotting undercarriage with its brightly painted houses and fanciful facades, both human and architectural.

*page_break
*if new_orleans_enterprise = 3
	*set new_orleans_quaestor_rapport %+20
	*set overstreet_rapport %+10
	*set withers_rapport %+10
	The house of ${new_orleans_quaestor_surname} glitters with newly-installed gas lamps; they are the first in the city.  The quaestor-to-be has truly outdone himself this evening; all the guests marvel at the innovation.  Even so, you wonder idly who between you is more anxious.
*else
	The house of ${new_orleans_quaestor_surname} glitters with candlelight as you draw near.  The quaestor-to-be has truly outdone himself this evening.  You wonder idly who between you is the more anxious.

Apparently, Jesse was in the phaeton before you, as he is waiting at the curb when your driver halts for you to disembark.
*if com_jesse
	*if new_orleans_enterprise = 3
		*set jesse_rapport %+10
		After a brief greeting, Jesse comments on your efforts at civic improvement.  "I was in Baltimore a few years ago, and was amazed when I first saw this wonder.  It was clever of you to see it brought here."
	
		"Thank you, @{jesse_is_broodmate dear brother,"|Mr. Whitaker,"} you reply.  "I saw the opportunity and seized it."
	
		"[i]Carpe diem,[/i] as they say?" he says with that wry smile of his.
	
		*if speaks_latin or ((intelligence > 2) or (lore > 2))
			*set jesse_rapport %+5
			"[i]Carpe noctem,[/i] rather."
	
			Jesse chuckles.  "Yes, I suppose so."
		*else
			"Yes, exactly."
	*else
		After a brief greeting, Jesse sneers at the candles that illuminate the street and the house so cheerily: "I was in Baltimore a few years ago; they have a new mode of civic illumination there, which they've brought over from London. It's called 'gas.' It can be pumped through copper tubing and fed from a central depot. No more replacing candles every other day!  Moreover, they're very much brighter and cleaner than those old candleworks."
	
		*if (technology > 0) and (anachronism > 80)
			*if (jesse_rapport <= 45) or (discretion >= 60)
				"Actually, I'd heard about the exposition at Peale's Museum when it first debuted there. I've been trying to convince ${new_orleans_quaestor_address} to organize a company to bring this wonder of science here, both for our profit and for the civic benefits, but he has proved recalcitrant."
				*set jesse_rapport %-10
				
				*if perception > 1
					"${new_orleans_quaestor_surname} always has had trouble seizing opportunities, I suppose," he mutters to himself as the door of the house opens before you.
				*else
					Jesse seems to mutter something to himself in response, but you miss it in the crash of noise as the door to the house opens before you.
			*else
				"You saw it yourself?  I have heard of this new invention, but never actually seen it.  You must take a moment sometime to tell me what it was like." @{(technology > 1) You're well aware of the arrival of gas in Baltimore, but Jesse likes to think you're interested in what he has to say, so you let him say it.|}
				*set jesse_rapport %+10
				
				"I would be happy to.  It was truly marvelous."
				
				"I will look forward to it," you conclude while the doors part before you.  Just inside them stands Ajax, who nods in greeting as you enter.
				*page_break 
				*goto entrance
		*elseif charm > 2
			*if jesse_rapport < 45
				"How droll!  And here I imagined that ${new_orleans_quaestor_address} had already reviewed your suggestion on the matter and decided running flammable vapors through tubes in the walls of his house ill-advised.  I must have been mistaken."
				*set jesse_rapport %-15
		
				Jesse doesn't let you see him flinch, but you know your words landed a blow. He turns away just as the doors open before you and a wave of noise overwhelms you.
			*else
				*if anachronism > 70
					"Perhaps together we can persuade ${new_orleans_quaestor_address} to make this city the light of the New World."
		
					"Yes, perhaps we can."
					*set jesse_rapport %+5
				*elseif (new_orleans_quaestor_rapport < 60) and (new_orleans_quaestor_surname = "Winters")
					*label winters_candles
					"You know that Winters probably had those candles stolen just for this occasion."
					
					Jesse chuckles.  "Yes, he is thoughtful that way."
				*else
					*if compassion >= 50
						"How amazing!  I simply cannot fathom some of these wondrous things that the mortals keep inventing."
		
						"Perhaps you should consider staying abreast of their world, since we must exist beside it."
						*set jesse_rapport %-5
					*else
						"That sounds dangerous!  I hope you discourage the mortals from trying to bring such things here; the whole city could go up in flames!"
		
						He laughs at you: "It is touching how you still care so for our food."
						*set jesse_rapport %-10
		*elseif jesse_rapport >= 45
			*set jesse_rapport %+5
			*if (new_orleans_quaestor_rapport < 60) and (new_orleans_quaestor_surname = "Winters")
				*goto winters_candles
			*else
				"I hope that someday I can see such a thing.  It sounds marvelous," you reply.  The doors to the house open before you, enveloping you both in a crash of noise.
		*else
			Somewhat at a loss for any sort of witty comeback, you simply nod in agreement as the doors to the house open before you, enveloping you both in a crash of noise.
*else
	Jesse greets you with a gesture, and then motions for you to enter the well-illuminated residence together alongside him.
	
Ajax, standing at the door, nods in greeting as you enter.
*page_break 
*label entrance
*set met_overstreet true
*if speaks_english or speaks_french
	*goto entrance_0
*else
	*if speaks_german and (new_orleans_quaestor_surname = "Van der Velde")
		*set overstreet_rapport %-10
		Walter Krupke, the governor's bodyguard, is about to translate an introduction for you when Van der Velde interjects and insists on doing it himself.  He introduces Theresa Overstreet, the governor; her broodmate, Samantha Withers; and Walter Krupke.
	*elseif speaks_german
		*set overstreet_rapport %-10
		The governor's bodyguard serves as a translator for your introduction.  He introduces Theresa Overstreet, the governor; her broodmate, Samantha Withers; and himself, Walter Krupke.
	*else
		*set overstreet_rapport %-10
		Estefania serves as a translator during your introduction to the governor.  She introduces Theresa Overstreet, the governor; her broodmate, Samantha Withers; and Walter Krupke.
	
	In life, Overstreet was a short, homely woman with mousy hair.  Undeath has not made her physically more attractive, but she radiates self-assurance and—frankly—power.  Withers, on the other hand, was mildly attractive as a mortal, but seems much less grounded than her broodmate.  Krupke, the bodyguard, is not terribly large, but looks like a born warrior.
	*set met_overstreet true
	*set met_samantha true
	*set heard_of_krupke true
	*set met_krupke true
	*if speaks_german and (new_orleans_quaestor_surname = "Van der Velde")
		When the introductions are completed and despite the intervention of Van der Velde, it is clear that the governor seems entirely unimpressed at your inability to communicate directly with her.
	*else
		When the introductions are completed, it is clear that the governor seems entirely unimpressed at your inability to communicate directly with her.
	
	*if perception > 1
		You observe through the first hour or two of the evening that Jesse and Samantha Withers seem to be doing something of a funny dance; each of their movements through the room is taken in light of the other's location.  You recall hearing that Jesse recently spent some time in Savannah in the company of Overstreet and Withers.
	*if male
		*if speaks_german
			While you are standing about trying not to look as isolated as you actually are, Krupke approaches you.  "It is good to meet you, [i]mein Herr[/i]," he begins.
		
			"And you as well," you reply.
			
			*if (jesse_is_broodmate = false) and patricide
				"Who is your dominus?"
				
				You hesitate, the sight of your maker's eyes screaming in pain under the weight of the coals you used to burn him to ash flashing before your eyes.  "${sire_name}.  It has been some time since I have seen him."
		
				"I have heard of him, but not lately."
		
				"Yes, I believe he laid down for a rest."
		
				"Ja, as he should."
				*goto tasked_no_english
			*elseif (jesse_is_broodmate = false)
				"Who is your dominus?"
		
				*if sire_name = "West"
					"West.  He is a beast that roams the spaces between the cities."
		
					"I am acquainted…or at least knowledgeable.  He is a mighty warrior.  I hope that you do him proud.'
		
					"I try."
				*else
					"${sire_name}."
					
					"Where is he?"
		
					"I do not know.  We parted under unpleasant terms."
		
					"[i]Ja,[/i] as our kind does."
			*else
				"${new_orleans_quaestor_address} is your dominus?"
				
				"He is."
		
				"He seems like a good dominus."
		
				*if sire_rapport >= 60
					"I am @{(rationalism >= 75) blessed|fortunate} to have one such as he as my maker."
				*elseif sire_rapport >= 40
					"He has done as he ought."
				*else
					"It is good of you to say so."
	*else
		*if speaks_german
			While you are standing about trying not to look as isolated as you actually are, Krupke approaches you.  "It is good to meet you, [i]mein Fräulein[/i]," he begins.
		
			"[i]Frau[/i] will do, [i]Herr[/i] Krupke."
		
			"You are married?" he asks incredulously.
		
			"No, nor will I be.  But I am not some mincing maiden."
		
			"No.  You carry yourself like you fight."
		
			"I do."
		
			"With what?"
		
			"With whatever is nearby."  At first he seems startled by your self-assuredness, but then he laughs. The next half an hour is spent discussing the merits of the various styles of musket used during the American Revolution.
		
	About an hour later…
	*page_break 
	*goto tasked_no_english

*label entrance_0
*temp theresa_name false
*if (given_name = "Theresa") or (((given_name = "Thérèze") or (given_name = "Thérèse")) or (given_name = "Theresia"))
	*set overstreet_rapport %+5
	*set theresa_name true
"Allow me to introduce @{jesse_is_broodmate my other progeny|one of the other citizens of this fair city}, ${mr} ${given_name} ${surname}," ${new_orleans_quaestor_surname} says, gesturing towards you.  Jesse, as @{jesse_is_broodmate your elder|the offspring of ${new_orleans_quaestor_surname}}, has already been introduced to the visitors.

You ${bow} at the introduction.

*if (status = 0)
	*set overstreet_rapport %-10
	*if sire_name = "West"
		"Is this the child of the beast?" Overstreet inquires.
	*else
		"Is this the individual you were telling me about?" Overstreet inquires.
	In life, she was a short, homely woman with mousy hair.  Undeath has not made her physically more attractive, but she radiates self-assurance and—frankly—power.

	"It is," replies ${new_orleans_quaestor_surname}.

	She sniffs.  "You should be grateful for ${new_orleans_quaestor_surname}'s generosity. Taking you in and educating you in the ways of the Society was not something that he was obligated to do."
	
	*if independence > 75
		"I am most grateful to ${new_orleans_quaestor_address}," you reply @{(new_orleans_quaestor_rapport > 55) honestly|through clenched teeth}.
		
		${new_orleans_quaestor_surname} blossoms under the praise, remembering only belatedly to continue with the introductions. 
	*else
		*choice
			#"I am most grateful to ${new_orleans_quaestor_address}," I reply honestly.
				${new_orleans_quaestor_surname} blossoms under the praise, remembering only belatedly to continue with the introductions. 
			#"I am most grateful to ${new_orleans_quaestor_address}," I reply through clenched teeth.
				*if new_orleans_quaestor_rapport > 55
					Apparently fooled by your flummery, ${new_orleans_quaestor_surname} straightens a little under your praise. Only belatedly does he remember to continue with the introductions.
				*else
					${new_orleans_quaestor_surname} forces a fake smile in response to your flummery. Refusing to be embarrassed, however, he continues with the introductions.
			#"I believe it is a mutually beneficial relationship," I reply.
				*if charm > 2
					*set overstreet_rapport %+5
					Overstreet gives a little chuckle. "I imagine that it is," she says.
				*else
					*set overstreet_rapport %-5
					"I doubt that," she retorts.

				Before the conversation takes any further turns, ${new_orleans_quaestor_surname} continues the introductions.
	"And the governor's broodmate, Mlle. Samantha Withers," indicating a vampire of youthful appearance who stands beside Overstreet.  Withers, with her symmetrical features and high cheekbones, retains something of the air of a haughty [i]ingenue[/i].  She does not deign to look in your direction.
	*set withers_rapport %-10

*elseif status = 1
	*if patricide or (sire_name = "West")
		"Is this the abandoned whelp you were telling me about?" Overstreet inquires. In life, she was a short, homely woman with mousy hair.  Undeath has not made her physically more attractive, but she radiates self-assurance and—frankly—power.
		
		"It is."
		
		She looks at you carefully. "You should be grateful for ${new_orleans_quaestor_surname}'s generosity. Taking you in and educating you in the ways of the Society was not something that he was obligated to do."
	
		"I am most grateful to ${new_orleans_quaestor_address}," you reply @{(new_orleans_quaestor_rapport > 55) honestly|through clenched teeth}.
	
		${new_orleans_quaestor_surname} stands up a little straighter under the governor's praise. When the moment seems right, he continues the introductions.
	*else
		@{theresa_name "Why, what a lovely name you have," Overstreet says|"Charmed, I'm sure," Overstreet observes}.  In life, she was a short, homely woman with mousy hair.  Undeath has not made her physically more attractive, but she radiates self-assurance and—frankly—power.

		"Of course, Your Grace," you reply.  

	"And the governor's broodmate, Mlle. Samantha Withers," ${new_orleans_quaestor_surname} continues, indicating a vampire of youthful appearance who stands beside Overstreet.  Withers, with her symmetrical features and high cheekbones, retains something of the air of an [i]ingenue[/i].

	"A pleasure," you proclaim, as Withers nods in your direction.  This perfunctory gesture complete, she goes back to ignoring you.
*elseif status > 1
	*if patricide or (sire_name = "West")
		*bug this shouldn't be possible
		"Is this the fledgling that you were telling me about?" Overstreet inquires. In life, she was a short, homely woman with mousy hair.  Undeath has not made her physically more attractive, but she radiates self-assurance and—frankly—power.
		
		"It is."
		
		"Despite the adverse conditions of your upbringing, you have managed to demand a certain…respect from ${new_orleans_quaestor_surname} here. Impressive."
		*set overstreet_rapport %+5
		
		"Thank you, Governor," you reply.
	*else
		*set overstreet_rapport %+10
		"It is lovely to meet you," Overstreet says. @{theresa_name "And your parents had exceedingly good taste," she continues with a smile.|} In life, she was a short, homely woman with mousy hair.  Undeath has not made her physically more attractive, but she radiates self-assurance and—frankly—power.
	
		"Of course, Your Grace," you reply.  
	
	"And the governor's broodmate, Mlle. Samantha Withers," ${new_orleans_quaestor_surname} continues, indicating a vampire of youthful appearance who stands beside Overstreet.  Withers, with her symmetrical features and high cheekbones, retains something of the air of an [i]ingenue[/i].

	"A pleasure," you proclaim.

	*if speaks_english or speaks_french
		"The pleasure is mine, ${mr} ${surname}," Withers replies.
		*set withers_rapport %+10
	*else
		She replies warmly to you, but her words are in English.

A third individual is introduced as well, identified as Walter Krupke.  He seems to be something of a bodyguard for the governor; he is not particularly large, but you sense that he could handle himself in a fight.  
*set met_samantha true
*set heard_of_krupke true
*set met_krupke true
*if senators_explained
	Rather than ask for specifics, however, you pause to consider the wisdom of observing ${new_orleans_quaestor_surname}'s admonition to be seen and not heard before speaking.
	*choice
		*selectable_if (discretion <= 65) #Obey the admonition.
			*set discretion %-10
			*set independence %-5
		*selectable_if (discretion >= 35) #"Your Grace, I understand the Senate will be electing a senator for New-Orleans soon.  Might I inquire whom you anticipate will be chosen?"
			*set discretion %+15
			The circle of vampires goes silent at the audacity of your question.
			
			"How funny that you should ask, ${mr} ${surname}.  Whom do you think should be elected Senator?"
			
			*choice
				*if jesse_is_broodmate
					#"Mr. Whitaker, my broodmate."
						*set discretion %-5
						*set rios_rapport %-5
						*set withers_rapport %-5
						*set jesse_rapport %+20
						*set new_orleans_quaestor_rapport %+10
						"Your support of your broodmate is commendable, ${mr} ${surname}.  You must know, however, that the Senate is unlikely to choose a current resident of the city."
						*goto about_senate
				*else
					#"Mr. Whitaker."
						*set discretion %-5
						*set rios_rapport %-5
						*set withers_rapport %-5
						*set jesse_rapport %+20
						*set new_orleans_quaestor_rapport %+10
						"You must know, ${mr} ${surname}, that the Senate is unlikely to choose a current resident of the city.  And while I'm sure Mr. Whitaker is a perfectly reasonable member of the Society, his election is nigh impossible."
						*goto about_senate
				#"Mlle. Withers, your broodmate."
					*set discretion %-5
					*set rios_rapport %-5
					*set withers_rapport %+20
					*set jesse_rapport %-5
					*set new_orleans_quaestor_rapport %-5
					*set overstreet_rapport %+5
					"You flatter my broodmate overmuch, ${mr} ${surname}.  Mlle. Withers is not yet ready for such responsibilities.  No, she will find a nice town somewhere and administer to it as quaestor.  Perhaps after a few decades of that she will be ready for the Senate."  Samantha looks mortified at this thorough dismissal of her political acumen.
			
					"I imagine that Mlle. Withers will make an excellent quaestor, Your Grace," you conclude, seeking an exit from the conversation.
				#"Sra. Rios."
					*set discretion %-5
					*set rios_rapport %+20
					*set withers_rapport %-5
					*set jesse_rapport %-5
					*if estefania_is_kin
						*if sire_alive
							*set new_orleans_quaestor_rapport %+10
						"Your support of your maker's broodmate is noted, ${mr} ${surname}.  You must know, however, that the Senate is unlikely to choose a current resident of the city."
					*else
						The vampires in the circle are taken aback, and even Estefania's eyes widen in surprise at your suggestion.  Overstreet does her best to hide any surprise, but all the same pauses to consider before responding: "You must know, ${mr} ${surname}, the Senate is unlikely to choose a current resident of the city.  And while I'm sure Sra. Rios is a perfectly upstanding member of the Society, her election is unlikely."
					*label about_senate
					*if (senators_representation = false)
						*set senators_representation true
						*set overstreet_rapport %-10
						
						"But why would the Senate not choose someone of New-Orleans?"
					
						Overstreet rolls her eyes at you before launching into her tirade: "What has ${new_orleans_quaestor_surname} been filling your head with, ${mr} ${surname}?  Do you think this a democracy?  No.  The Senate elects a Senator to represent itself to the city.  Not the city to the Senate."
						
						The conversation continues, but you are frozen out of it.
					*else
						*set senators_representation true
						*set overstreet_rapport %+5
						
						"The Senate is a wise and venerable institution.  I am sure they they will appoint a Senator for New-Orleans that serves their needs," you reply.
					
						"As it does, ${mr} ${surname}.  As it does."  With that, your brazenness is forgiven…or at least overlooked.
						
						The conversation continues pleasantly enough.
				#"Someone new to the city."
					*set discretion %-10
					*set rios_rapport %-5
					*set withers_rapport %-5
					*set jesse_rapport %-5
					*set new_orleans_quaestor_rapport %-5
					*set overstreet_rapport %+5
					Overstreet looks at you calmly.  "You are probably right; I would be surprised if the Senate elected someone who lives here already."
			
					@{(jesse_rapport > 55) You sense that Jesse is slightly annoyed that you did not suggest him for the role.|}
					
					You seek an exit from the conversation, a goal achieved easily enough.
				*selectable_if (discretion > 40) #"Me."
					*set discretion %+20
					*set independence %+10
					You didn't think that the room could get any more silent, but somehow it does.  Even the mortals have ceased their breathing, waiting to see Overstreet's response.  
			
					*if status = 0
						"Don't be ridiculous, ${mr} ${surname}."
			
						Turning to ${new_orleans_quaestor_surname}, she says something about children needing to be seen and not heard.  Your face burns with shame.
						*set new_orleans_quaestor_rapport %-15
						*set overstreet_rapport %-20 
					*else
						*set rios_rapport %-5
						*set withers_rapport %-5
						*set jesse_rapport %-5
						*set overstreet_rapport %+20
						Staring directly into her eyes, you are first to see the coming laughter.  You estimate that it has been some decades since the sound of an honest laugh last issued from the throat of Overstreet; in some ways, the laughter sounds like the creaking protests of a house left too long undisturbed.  The rest of the room exhales slowly; laughter of this sort would seem to bode well, but they are right to be fearful of the unknown.  Finally, she recovers enough of herself to speak: "Your dominus must be proud of you, ${mr} ${surname}.  I am afraid that you are yet too young to be elected as a Senator, but I must admire your forthright ambition.  I look forward to the day when the Senate shall make you one of their own."
			
						"You do me too much honor, Your Grace."
						
						The conversation continues breezily.
	*page_break
	
@{(perception > 1) You observe through the first hour or two of the evening that Jesse and Samantha Withers seem to be doing something of a funny dance; each of their movements through the room is taken in light of the other's location.  You recall hearing that Jesse recently spent some time in Savannah in the company of Overstreet and Withers.|Introductions concluded, the vampires break into smaller sets to pursue their individual conversations.} You have positioned yourself in the vicinity of ${new_orleans_quaestor_surname} and Overstreet, doing your best to seem attentive to the dynamics of their discussion without being intrusive. And yet, as far as you can ascertain, they seem to mostly speak of nothing.

Besides the three vampires that have been introduced to you, there are also a handful of mortals in the Governor's entourage. These mortals lounge about making conversation with ${new_orleans_quaestor_surname}'s mortal guests.

Nearby, but not exactly part of the governor's circle, Estefania and Krupke sit in conversation.  Amusingly, the Valencian by way of Panama and the—Prussian?—are forced to resort to French to find a suitable language in which to adequately communicate.
*if (perception > 0) and speaks_french
	*set overheard_rios_and_krupke true
	From this distance, you can't overhear the entirety of their conversation, but much of it seems to be a discussion of "Shepherds" and "Wolves."
	*if shepherds_and_wolves
		This must be the philosophical debat that Rios described to you some nights ago.
	*elseif (lore > 1) or heard_of_shepherds_and_wolves
		*set shepherds_and_wolves true
		They are probably discussing—in broad terms, at least—the common distinction among vampires between those that imagine themselves shepherds of men, and those who position themselves as unrepentant predators.  Whether they realize it or not, most vampires must, in time, come to situate themselves somewhere on this continuum.
	*else
		*set heard_of_shepherds_and_wolves true
		Unfortunately, the context of this debate is unknown to you.

*if patricide
	At one point, the conversation turns to the subject of patrons, a subject you are loath to discuss.  Thankfully, having been commanded to be silent by ${new_orleans_quaestor_surname}, no one notices your lack of contribution on the subject.
	
You remain at the edge of the conversation around the governor until…
*page_break 

"Have you heard some of the latest pieces from the continent?"  Estefania inquires of Governor Overstreet.

"I heard that there is a composer who has fallen completely deaf, and yet his works still send his audiences into paroxysms," Withers interjects.

"A deaf man, making music?  You must be mistaken,"  Governor Overstreet says.

"It's in all the papers!  Lodewijk, I believe his name is.  I wonder if ${new_orleans_quaestor_address} is acquainted with him?"  Withers says.

"I doubt it.  ${new_orleans_quaestor_address} has not been to the Continent in many decades," says Estefania, patting him on the arm.

*if (creation > 0) and ((anachronism > 80) and (discretion > 40))
	It is at this point that you can no longer restrain yourself.  "I believe, ma'am, that you have confused a mortal and his grandson."
	
	"I beg your pardon, ${mr} ${surname}?" Silence falls over the room as Overstreet turns her eyes on you.
	
	"Lodewijk—a musician in his own right—is the grandfather of Ludwig van Beethoven, the deaf composer of whom I believe you are speaking."
	
	"Oh, and do you have an interest in the arts?"
	
	"I do have some small interest, Governor."
	
	"Well, there is a pianoforte around here, isn't there?"  Suddenly, you feel your blood run cold.  As if it weren't already.
	
	"Yes, Governor, I do believe there is a pianoforte in the next room."
	
	"Well, why don't you play something for us?"
	
	"I…I…" you stammer.
	
	"Go on.  You wouldn't want to disappoint your governor, now would you?"
	
	*if (creation = 1) and estefania_is_kin
		"Your Grace, would it be acceptable if I played for you?"
		
		Though slightly annoyed that she didn't have the chance to put you to the test, Overstreet can do naught but indulge Estefania.  "That would please me greatly, Senora Rios."
		
		Catching Estefania's eyes as she departs the circle, you silently communicate your gratitude.  She is aware of your level of skill, and she has saved what little reputation you have by intervening with the Governor.
		*goto estefania_plays
	*else
		"No, ma'am."
	
		"Good."  At that, you turn towards the pianoforte…
		*page_break
		Like an unfortunate wretch to Jack Ketch's stage, you drift across the sitting room to the pianoforte.  Sitting before the keyboard, you announce your fate: "A sonata in C-sharp minor, entitled [i]Quasi una fantasia[/i].  One of his older pieces, to be sure.  But beautiful, nonetheless."
		
		And with that, you put your fingers to the keys and begin to play.
		
		*page_break 
		*goto pianotest
*if (creation > 0) and ((anachronism <= 80) and (discretion > 40))
	It is at this point that you can no longer restrain yourself.  "All this new music I hear…it distresses me so.  I think that Paganini was brilliant but Haydn was really the pinnacle of music.  Everything since his death has been an homage to him."
	
	The crowd seems somewhat taken aback by your sudden interjection.
	
	"Am I to take it, then, that you are a student of the musical arts, ${mr} ${surname}?"  Silence falls over the room as Overstreet turns her eyes on you.
	
	"I am, Governor," you reply, suddenly very aware of the danger of your situation.
	
	"Then perhaps you will grace us with something?  I do believe there is a pianoforte in the adjacent room, is there not?"
	
	"I…I…" you stammer.
	
	"I really must insist," she smiles.
	
	"You are…most kind to…condescend to attend my meager skills…"
	
	"Enough with the modesty, dear ${mr} ${surname}!  Let us to the music!"  And with that, the governor's circle is swept into the next room.  You are carried along with them.
	*page_break
	Like an unfortunate wretch to Jack Ketch's stage, you drift across the sitting room to the pianoforte.  Sitting before the keyboard, you announce your fate: "A sonata in E-flat Major, for which I am unaware of any title.  I find that it…expresses something about our immortal condition."  
	
	And with that, you put your fingers to the keys and begin to play.
	*goto pianotest
*else
	"[i]Señora[/i] Rios, I understand you have some talent with this instruments?" Governor Overstreet says.
	
	Rios nods. "If it would please the Governor.…"
	
	"Very much so," she replies.
	*label estefania_plays
	
	Estefania sits at the pianoforte, and after getting a feeling for its dynamics, launches into a sonata by Haydn.  The room is swept away by the grace of her fingers and remains silent until the final reverberations of the last note dies away before launching into thunderous applause.
	
	Estefania waves off the applause as she rejoins Overstreet's circle.  When Estefania rejoins the circle, however, Withers leaves it, drawing a sharp glance from Overstreet.
	*if com_sam
		*goto tasked
	*label tasked_no_english
	*if speaks_spanish
		Estefania translates a request on the part of Overstreet, that you escort Withers around the city and show her the sights at some point during the week; Tuesday seems like a good choice.  You smile and ${bow} in acceptance.
	*elseif speaks_german
		Krupke translates a 'request' on the part of Overstreet, that you escort Withers around the city and show her the sights at some point during the week; Tuesday seems like a good choice.  You smile and ${bow} in acceptance.
		
	A few nights later, you find yourself walking through Jackson Square in the company of Samantha.
	*page_break 
	*goto escort_samantha 

*label pianotest
*set performed true

*if creation > 2
	*set performed_well true
	*set dazzled_overstreet true
	*achieve dazzle
	*set overstreet_rapport %+25
	*set new_orleans_quaestor_rapport %+10
	Your talent infuses the pianoforte and the room with sublimated passion.  When the last note dies away, the room breaks into wild applause…as wild as a room full of vampires and their attendants can get, anyway.
	*if (ethnicity = "african") or (ethnicity = "choctaw")
		You do your best to ignore the shocked stares of the visiting mortals in the room; it occurs to you that humans in Georgia are not accustomed to seeing a person of color play a European instrument.  Fortunately for everyone, they know better than to say anything aloud; nor could they, struck dumb as they are by the beauty of the performance.
	
	"I believe that ${mr} ${surname} was being coy with me," the governor observes upon your return to her circle.
	
	"I am pleased if you are, Your Grace."
	
	"Perhaps some day you will grace me with your presence in Savannah?"
	
	"I would be most honored."
	
	"Did you know that Mlle. Withers is something of a poet?"
	
	"I did not, Your Grace."
	
	"Yes, I believe that she is preparing something for the party next week."
	*set learn_of_poem true
	
	"My sister does me too much honor," Withers interjects.
	
	"I look forward to hearing you perform, Mlle. Withers."  Withers brushes off the compliment and excuses herself.
	*page_break 
	*goto tasked
*elseif creation = 2
	*set performed_well true
	*set overstreet_rapport %+5
	You have a facility with the instrument and the piece, and you finish to a polite round of applause, to which you respond with a ${bow}. @{(ethnicity = "african") You do your best to ignore the stares of the visiting mortals in the room; it occurs to you that humans in Georgia are not accustomed to seeing a person of color play a European instrument.  Fortunately for everyone, they know better than to say anything aloud.|}
	
	"It seems that ${mr} ${surname} has some knowledge of which ${he} speaks," the Governor observes upon your return to her circle. @{(ethnicity = "choctaw") You do your best to ignore the stares of the visiting mortals in the room; it occurs to you that humans in Georgia are not accustomed to seeing a person of color play a European instrument.  Fortunately for everyone, they know better than to say anything aloud.|}
		
	"I am flattered to hear you say so, Governor."
	
	"Did you know that Mlle. Withers is something of a poet?"
	
	"I did not, Your Grace."
	
	"Yes, I believe that she is preparing something for the party next week."
	*set learn_of_poem true
	
	"My sister does me too much honor," Withers interjects.
	
	"I look forward to hearing you perform, Mlle. Withers."  
	
	Withers brushes off the compliment and excuses herself.
	*page_break 
	*label tasked

	Withers now gone, Overstreet changes the subject: "Well, ${mr} ${surname}, you find Withers pleasing company, yes?"
	
	You've had only the barest exchange with Withers, but now is not the time for truth-telling. @{(independence > 45) "I do, Your Grace."|"We only just met, but—"}
	
	@{(independence > 45) |She interrupts your equivocations. }"Would you be so kind as to show her around the city sometime this week?  She is most anxious to see the sights."
	
	"I would be honored, Your Grace."  With that, you politely excuse yourself from the governor's circle, lest she get any other ideas with which to task you.
*else
	*set overstreet_rapport %-20
	*set new_orleans_quaestor_rapport %-20
	You should never have opened your mouth.  Between your nerves and your middling skill at the piano, most of the room quickly turns away from the horror show before them and resumes their private conversations.
	
	No one even seems to take note when you finish.
	*page_break
	
	Some hours later—you've mostly been occupying yourself by staring at the wallpaper—Jesse fetches you and drags you back before the governor.
	
	"You've met Mlle. Withers, yes?" she asks, not really caring about your response.
	
	"I have, Your Grace."
	
	"Take her around the city Tuesday evening.  She is most anxious to see the sights."
	
	"I would be honored, Your Grace."  Taking that as your dismissal, you exit the governor's immediate circle.
	
*if (performed = false) and ((rios_rapport > 60) and com_estefania)
	A short time later, Rios drifts near you. 
	
	"I enjoyed your performance," you note.
	
	"Thank you! It is not my preferred instrument, but I find the pianoforte acceptable in a pinch."
	
	"Do you perform for others of our kind often?"
	
	"It happens. We must amuse ourselves through these dreary nights, after all. I believe that Mlle. Withers will be performing some poetry at our next gathering, in fact?"
	
	"Oh, I hadn't heard."
	
	"She has some way with words. It should be charming, at least."
	
	With that, she is drawn away by Krupke.

You spend the rest of the evening anxiously awaiting its conclusion; an appropriate moment for your exit cannot come soon enough.
*page_break

Jesse stops you on your way out.
*if (senators_representation = false) and senators_explained
	*set senators_representation true
	Having his attention momentarily, you decide to ask him about the Senate: "Why does it seem that the Senate will not elect a resident of New-Orleans to be its Senator?  This makes no sense."

	Jesse laughs quietly.  "Such a young thing you are!  The Senator does not represent the city to the Senate; the Senator represents the Senate to the city."  It is at this moment that Jesse takes the opportunity to press his own interests:
"I understand that you are taking Mlle. Withers on a tour of the city."

"You are well informed, Mr. Whitaker," you reply warily.

"I assume you are aware of the intense distaste I developed for her while I resided in Savannah?"
*choice
	#"Of course, everyone is talking about it."
		*set jesse_rapport %-15
	*if (perception > 1) #"I observed the strange dance in which the two of you were engaged this evening, but had not quite put the pieces together."
		*set jesse_rapport %-10
	#"No, I hadn't heard."
		*set discretion %-5

"Well, whatever the case, it seems that she is enamored of me.  I trust that you will not reveal my utter distaste for her?  These things must be handled delicately, you understand."
*if jesse_rapport > 60
	By the time he finishes this thought, his eyes have already traveled on, seeking other opportunities to exploit.  His demeanor implies that either he simply expects you to comply or that the significance of your input is negligible.
*elseif jesse_rapport >= 40
	As he finishes this thought, you can see him observing your reaction, attempting to predict your response.  And, perhaps more importantly, whether or not you will follow through on your words.
*else
	By the time he finishes this thought, you feel as though his gaze has clawed its way through you and out the other side.  You wonder briefly whether this is a request or a command.

*choice
	*if (clotho_ordered_killed and (compassion < 60)) #"You were a party to my love's death, and now you're asking me for help…to embarrass someone?"
		*set discretion %+10
		*set jesse_rapport %-10
		*set independence %-5
		"Are you still upset over that, ${given_name}?"
		
		"Clearly, Jesse."
		
		"You will get over it in time, fear not."
		
		"Enough, Jesse."
		
		"Think on it, ${given_name}," he replies. "There is still plenty of time for you to mend our relationship."
		
		You smother your explosive response. As far as you are concerned, it is not your responsibility to mend your relationship. Jesse offers a fake smile and moves to another conversation.
		
		*goto enough
	#"You can rest easy, Mr. Whitaker.  @{((intelligence > 2) or (streetwise > 1)) She will be none the wiser." I surmise that he must be planning something nefarious and desires my|I will keep your secrets," I reply, though I am uncertain as to why this requires such} discretion.
		*if (intelligence > 2) or (streetwise > 1)
			*set compassion %+10
		*set jesse_rapport %+10
		*set discretion %-10	
		*if jesse_rapport >= 50
			"Of course, I knew I could count on you."
		
			"It is no trouble, I know how delicate these things can be."
		
			"I am in your debt.  I wish you a pleasant evening, ${mr} ${surname}."
		*else
			"I am relieved to hear that."
		
			"It is no trouble, I know how delicate these things can be."
		
			"I am in your debt.  I wish you a pleasant evening, ${mr} ${surname}."
	*selectable_if (jesse_rapport >= 40) #"Perhaps I should encourage her affections, dear Jesse?"
		With a laugh, Jesse waves off your offer.  "You need contribute nothing to her predicament, my friend."

		"You are sure?"

		"Yes, yes…now, I must bid you good evening.  It is my duty to escort the Governor and her entourage back to her guest haven.  Fare well, ${mr} ${surname}."
		*set jesse_rapport %+20
		*set compassion %+10
	*selectable_if (compassion <= 60) #"I can make no promises, Mr. Whitaker.  I take a dim view of lying and deceit."
		*set jesse_rapport %-20
		*set compassion %-10
		"It is a wonder you have survived as long as you have, ${mr} ${surname}."
		
		"I beg your pardon?"
		
		"Pay it no mind.  You may forget that I even asked.  Enjoy the rest of your evening."

"And you as well, Mr. Whitaker."  
*label enough
With that, you finally make your way out of the party.

Standing outside, waiting for your coupé, you find yourself exhaling slowly.
*if compassion > 60
	Realizing this, you stop mid-breath.  Looking around quickly, you are relieved to see that no one saw you acting so…human.
*elseif compassion >= 40
	Pausing for a moment, you find yourself suddenly overwhelmed by emotion.  Yes, you were on edge all night, but why are you breathing?  Is an immortal supposed to fear for its existence?  Are you too human…or too inhuman?

	The thought suddenly dawns on you that, for what seems like years now, the only emotions you have felt have been fear, shame, and some sort of perverted, all-consuming desire.  This jumble of thoughts does not sort itself out before you lie down to rest for the day.
*else
	You take a certain comfort in the knowledge that some part of you—however small—still responds to fear and anxiety as a human would.

All too soon, your services as a chaperone will be required.

*page_break 
*label escort_samantha
*if com_sam
	*goto tour
*else
	*set can_do_nothing_about_withers true
	*set withers_rapport %-10
	
	It is with no small amount of awkwardness that you escort Samantha through the city.  You point out the sites and name things, but you are unable to relate anything of what you know about these places to her.
	
	At one point, she stops you on a corner of Jackson Square and tries to ask you something…something about Jesse!  She's clearly waiting for an answer.
	
	*choice
		#I say 'yes' emphatically.
			She is clearly overjoyed by your enthusiastic response.  The rest of the evening, she chatters at you without your understanding a single word.  Beyond "Jesse," that is.
			
			The rest of the week passes quickly.
			*page_break 
		#I just smile and nod.
			She seems somewhat thrilled by your response, and the rest of the evening she chatters at you without your understanding a single word of it.  Beyond "Jesse", that is.
		#Frown and shake my head.
			*set samanthas_poem "love"
			She blurts out an exclamation of despair, and soon tears of blood are rolling down her face.  You look quickly around the square to make sure that she is not drawing any undue attention to the two of you.  Reassured, you draw a handkerchief from a pocket and offer it to her, which she accepts gratefully.
		#I try to reiterate that I have no idea what she's saying.
			At first she looks confused, but then she smiles and nods.  Soon she is back to her excited self, chattering away.  Still, the only word you understand is "Jesse."
	*goto the_hunt_before

*label tour
*if ethnicity = "african"
	Though it would be looked at with some suspicion in most other cities in the United States, here in New-Orleans, people pay little mind to a well-dressed person of African descent escorting a white woman through the streets at night.
*elseif (ethnicity = "choctaw") and (anachronism < 80)
	In most instances, no one would comment on a Choctaw escorting a white woman through the streets of New-Orleans.  However, your insistance on wearing native dress means that you draw stares wherever you go, stares that clearly make Withers uncomfortable.

"When I still took breath, this square was known as the Place d'Armes; it was renamed after the Battle of New-Orleans," you relate, gesturing to the sights for the benefit of Samantha Withers.

*if male and (ethnicity != "african")
	"Were you in the battle, ${mr} ${surname}?"
		
	"I…well…I was there for it, but I wasn't part of it, no."
		
	"Oh," she says, doing little to conceal her disappointment.
	*if ethnicity = "choctaw"
		*goto choctaw_confrontation
*elseif (male = false) and (ethnicity = "german")
	*set withers_rapport %+20
	"But what of you?  I have heard of you!  The vampire who was once a woman and who fights like a man!"
		
	Were you capable of such, your cheeks would warm at that.  "Well, I…my father wanted a son.  Even just one.  But instead he had six girls.  Since I was the eldest of the lot, he decided to teach me to soldier.  And so, after the fields were tended, he would drill me in the yard and teach me to shoot when he could afford to spare the ammunition."
		
	"How amazing!" she exclaims in delight.
*else
	"Were you here for it?  Did you see the battle yourself?  I so wish that I could make the acquaintance of President Jackson; he is an inspiration to us all!"

	*if ethnicity = "choctaw"
		"No, I did not see the main part of the battle."

		She sniffs at you before replying.
		*label choctaw_confrontation
		*set withers_rapport %-10
		"I suppose you were too busy collecting the scalps of the dead, trophies with which to decorate yourself?"  You look at her with shock, at a loss for words over this insulting inquiry.  "I mean, that is what your people do?  Prey on the defenseless?  In fact, I'm somewhat surprised that the gift worked on you; I had always thought your kind were subhuman."
		
		*if compassion >= 60
			"If you seek to anger me, mademoiselle, you will have to seek other methods.  My affection for the natives of this continent has long since withered to nothing."
		
			"Perhaps that is why you seem so filled with good sense, ${mr} ${surname}.  After all, they are a savage race."
		*else
			*if (willpower > 1) and (charm > 2)
				*set withers_rapport %-10
				"It is no more our purpose to prey on the defenseless than it is your people's purpose to mate with sheep," a rebuke which silences her with alacrity.
			*elseif (willpower > 1) and (perception > 2)
				*set withers_rapport %+5
				"I sense the misfortunes of your mortal youth still trouble you.  However, do not mistake the righteous retributions of a few for the policies of the many."  At your words, she seems to diminish before you, reverting momentarily to a scared little girl watching her parents murdered before her.
			*elseif willpower > 2
				It is only through a supreme act of will that you do not bare your fangs and seek to tear out her throat for these remarks.  
			*else
				Before realizing it, your fangs extend and your eyes go red.  Sensing your volcanic fury, Withers turns and forces a gaze of centuries upon you.  Burning with rage and gnashing your teeth, you find yourself immobilized by the strength of her stare.  You have heard of such powers before, but this is the first that you have experienced it firsthand.  Standing there, you are forced to listen while she jeers at you and your people.  When you finally regain control of yourself, you announce that the tour is over.
			
				You part from Samantha, leaving her to find her own way home.  The rest of the week passes quickly.
				*set choctaw_confrontation true
				*set withers_rapport %-10
				*set overstreet_rapport %-10
				*set new_orleans_quaestor_rapport %-10
				*page_break 
				*goto the_hunt_before
	*elseif met_andrew_jackson
		"I'm not so sure you would enjoy that, Mlle. Withers.  He is a dangerous man."

		"Oh?  You have met him?"

		The memory of your foolish confrontation with Old Hickory flashes before your eyes.  Considering the matter was surely a breach of the Rule of Reserve, you choose your next few words very carefully.  "I attended a [i]soirée[/i] at which he was the guest of honor.  Clearly, he has weathered many confrontations, and yet he walks tall.  That is all I meant."

		She pauses a moment, surely curious about your stumbling reply, but shortly loses interest and returns to her preferred subjects. 
	*else		
		*if compassion > 60
			"Yes, I saw something of the battle.  Many soldiers died.  It was really rather boring."

			"Oh, well…I would have liked to have seen it all the same," she replies.
		*elseif compassion >= 40
			"Yes, I did see something of the battle.  I wish I hadn't, to be honest.  There are certain things that one cannot unsee, and many of the sights of that morning I would prefer to forget."

			"For better or worse, ${mr} ${surname}, violence is a part of existence, all the more for those of our kind.  Do not worry…in time those memories will no longer disturb you so."

			As she turns the conversation to other topics, you have a moment to wonder whether you should look forward to that night or whether you should dread it.
		*else
			*set withers_rapport %+5
			"Yes, I was at the battle.  It was horrible.  I still have daymares about the cannon-fire.  I would not wish that experience on anyone."

			Withers seems a little taken aback by the emotional honesty of your response.  But then her demeanor softens, and she turns the conversation to other things.

*if met_guidry

	At one point you pass Guidry, who still sits on his corner. @{love_clotho He glares at you from his perch, clearly suspecting your involvement in the absence of his friend.|}  You do your best to keep Samantha from taking note of him.

You continue the tour, pointing out the St. Louis Cathedral, the Cabildo (where the Louisiana Purchase was signed), and the Presbytere.  "The suggestion has recently been making the rounds that the Presbytere will be converted into a courthouse, but I don't see how the merchants will be convinced to give up their bureaux."

She seems bored by your tour.  While standing on a corner, she puts her hands on your arm to still your descriptions, and turns conversation to a new topic: "${mr} ${surname}, you have known Mr. Whitaker for some time now, yes?"

"We have both lived in the city these past few years, yes."

"I hope you will pardon my directness, but has he said anything about me?  I fancy that he has an unrequited affection."

*choice
	#"No, he hasn't mentioned you."
		*set withers_rapport %-10
		*set compassion %+5
		*set discretion %-10
		*goto no_1
	*if compassion > 40
		*selectable_if (discretion > 40) #"Vampires do not have feelings of the sort you describe, Mlle. Withers."
			*set withers_rapport %-25
			*set compassion %+10
			*set discretion %+10
			*goto yes_1
	#"I tremble to admit that you are correct, Mlle. Withers."
		*set withers_rapport %-50
		*set compassion %+25
		*set encourage_withers true
		*set discretion %+25
		*goto no_3
	#"Did you know, all three of these buildings were financed by Don Andres Almonester y Roxas?"
		*set withers_rapport %-10
		*set compassion %+5
		*set discretion %-20
		She completely ignores your attempts to redirect the conversation.
		*goto no_1
	*selectable_if (discretion < 70) #"Mlle. Withers, I'm afraid you may have misinterpreted things."
		*set withers_rapport %-5
		*set compassion %-15
		*set discretion %-5
		*goto yes_0
	*selectable_if (discretion > 30) #"I'm afraid you are mistaken.  He finds you distasteful."
		*set withers_rapport %-30
		*set compassion %-10
		*set discretion %+10
		*label yes
		*set samanthas_poem "love"
		
		She stops in her tracks.  "I beg your pardon?"
		
		"I said that he finds you distasteful and your company insufferable."
		
		"Why…why…how rude!"  With that, she storms off into the night.
		
		The rest of the week passes quickly.
		*page_break
		*goto the_hunt_before

*label no_1

"Oh, he must be playing coy.  I saw the way he looked at me at the reception the other evening.  He has the most beautiful eyes, you know.  And those fangs!"

"I must admit that I don't see the attraction."

"You simply have not looked into his soul, ${mr} ${surname}.  But I fancy that you shall in time."
*if love_clotho
	
	"His soul?  You have seen into it?"

	"Come now, ${mr} ${surname}…after all, I heard that you yourself have had your own brush with that most tender of flowers."
	
	"I'm sorry?"
	
	"Some poor mortal that you found yourself mixed up with.  But, don't you understand, so many of those problems are passed over when one's love is already one of our kind."

*choice
	#Let her continue.
		Taking your silence as tacit confirmation, her face brightens.
		*set withers_rapport %-10
		*set compassion %+5
		*set discretion %-10
		*label no_4

		At that, Samantha lights upon an endless stream of observations and nightdreams about her eternal future together with Jesse.  It is with some relief that you eventually return her to her temporary haven at the end of the evening.
		
		The rest of the week passes quickly.
		*page_break 
		*goto the_hunt_before
	#"I am sorry to disappoint you, Mlle. Withers, but I think you are mistaken."
		*set withers_rapport %-5
		*set compassion %-15
		*set discretion %-5
		*label yes_0
		*set samanthas_poem "love"
		
		"But how can that be?  Oh, you don't know the kindnesses that he has shown me!"
		
		"Mlle. Withers, I cannot speak to what you have witnessed.  But I can say that he has no romantic feelings for you."
		
		*if priest
			"What do you know of love?  You…you…Papist!" she exclaims, tears of blood streaming down her face.  You quickly offer a handkerchief with which she may wipe away her tears, but she pushes your hand away and stumbles away from you.
			
			The rest of the week passes quickly.
			*page_break 
			*goto the_hunt_before
		*else
			"I am destroyed!"  With that, tears of blood begin to pour down her face.  You look quickly around the square, noting that there is no one of consequence to be disturbed by this sight, and quickly pull a handkerchief to wipe away the blood.
			
			"You do me too much kindness, ${mr} ${surname}."
			
			The rest of the week passes quickly.
			*page_break
			*goto the_hunt_before
	#"You have worn me down, Miss.  I fear that he has made me promise to keep his affection a secret from you…"
		*set withers_rapport %-50
		*set encourage_withers true
		*set compassion %+25
		*set discretion %+25
		*label no_3

		"I knew it!  Oh, happy nights!"
		*goto no_4
	*if compassion > 50
		*selectable_if (discretion > 30) #"Vampires do not have feelings of the sort you describe, Mlle. Withers."
			*set withers_rapport %-25
			*set compassion %+10
			*set discretion %+10
			*label yes_1
			*set samanthas_poem "love"
			
			In one cruel sentence, you have both trivialized her feelings for Jesse and intimated that she is unfit to be a vampire.  She stops and stares at you wordlessly.  You resume her history lesson.
			
			The rest of the week passes quickly.
			*page_break 
			*goto the_hunt_before

*label the_hunt_before

*if speaks_english or speaks_french
	The following Saturday arrives, and you prepare yourself again for an evening of vicious repartee.
*else
	Despite your strong desires to the contrary, the following Saturday arrives all too soon; you have not been looking forward to another evening of social isolation.  However, you are informed in advance that Mlle. Withers, who is apparently something of a poet, will be presenting an original work for the gathering.

Unfortunately for you, you have been so preoccupied with preparations for the evening and running errands for the Quaestor that you have forgotten to feed recently.  Well, not forgotten—you can never forget the hunger—but rather put it aside for more pressing matters.  Now it has reached the point where your need has become urgent.  You must do something…but the [i]soirée[/i] begins shortly!
*if lore > 1

	It is, of course, considered very tacky to arrive hungry to a gathering of vampires.  Hungry vampires tend to have even shorter tempers than usual, and no one wants to see their party ruined by guests who eat the help.

*if feeding_style = "artists"
	Unfortunately, it will be impossible to find a musician or even a blacksmith to feed from and have any chance at being on time.
*if feeding_style = "children"
	Your preference for the @{(rationalism < 60) innocent is often satiated by visits to the Ursuline's orphanage, but such trips are never short.|innocent, combined with your concern for your immortal soul, has caused you, of late, to help place the Ursuline orphans in homes throughout the city.  While you can call on any of those families, doing so will not be quick.}
*if feeding_style = "clergy"
	The convent of Ursuline nuns has played host to you in your moments of need, but your trips there are never short.
*if feeding_style = "drunks"
	And, while finding a drunk in this town will not be a challenge, it will still take more time than you have.
*if feeding_style = "itinerants"
	Making your way to the rue de la Levée, which the sailors frequent, will take time.  Time that you do not have.
*if feeding_style = "laborers"
	There is a gambling house over on the rue de Tremé where the workers gather to play [i]crapaud,[/i] but it will take time to get there.
*if feeding_style = "prostitutes"
	And, while finding a whore in this town will not be a challenge, it will still take more time than you have.
*if feeding_style = "socialites"
	Though you've lately been keeping company with the adult children of Bernard de Marginy, you haven't exactly alerted them that you might be calling on them tonight.  Calling on them without forewarning might be a tad awkward.
*if feeding_style = "vegetarian"
	*if shapeshifting > 1
	
		Luckily for you, the combination of your advanced powers of Shapeshifting and your decision to feed on animals means that you can simply whistle up your dinner from the crevices and dark corners of your neighborhood.  The rats come quickly to your call.  It's not much, but it should get you through the evening safely.
		
		You clean yourself up and head to the party.
		*page_break 
		*goto arrive_on_time
	*else
		*if wealth > 10000
			That said, you do have a horse in your stable…it's getting older, and its blood will be even more unpleasant than that of other beasts.  But time is not on your side…
		*else
			Unfortunately, it will be challenging to find a horse whom you can access quickly and easily.  You have not time, obviously, to go out of the city and find a cow or other large animal.  And, try as you might, you have yet to figure out how to make the rats come to your call.
*else
	The barracks on the rue de Quartier are your normal haunt, but you are awfully pressed for time…

What do you do?
*choice
	#I will risk being late.  Better to be assured of feeding, especially with the Governor in town.
		*set discretion %-5
		Quite possibly a wise decision.

		*if feeding_style = "artists"
			*if creation > 1
				One of your piano students, a child of Bernard de Marigny, should be free…it will just take you a little while to get down to Victory St.
			*else
				Congo Square is full of music-making most every evening.  It should not take you long to go there and back…
		*elseif feeding_style = "children"
			*if rationalism < 55
				The Ursuline nuns welcome you when you knock at their door.  You tell them that you will only be a minute…
			*else
				Making the way to the home of one of your charity cases is easy enough…making your way inside is what takes time.
		*elseif feeding_style = "clergy"
			The Ursuline nuns welcome your arrival.  They are always grateful for your donations…
		*elseif feeding_style = "drunks"
			There are so many saloons to choose from!  Unfortunately, you underestimate the drunkenness of your prey and have to spend a little time sobering up before you dare be seen by others of your kind.
		*elseif feeding_style = "itinerants"
			Finding a sailor on the Rue de la Levée is simple enough.  A short span of privacy, on the other hand…
		*elseif feeding_style = "laborers"
			The room roars with approval over a throw of the dice as you enter.  While the rules of Bernard de Marginy's new game of dice are still being worked out, it does not stop the men of the city from playing it on a regular basis.
			
			Once here, it is a simple matter to find a suitable victim…
		*elseif feeding_style = "merchants"
			There is a tavern near Jackson Square that serves the shopkeepers and merchants of the city. There, they can drink, socialize, and scout for new opportunities all at the same time.
			
			You have no difficulty finding someone to sink you fangs into.
		*elseif feeding_style = "prostitutes"
			You visit a local brothel where you are well-known.  The ladies of the night greet you enthusiastically…you always do show them such a good time.
		*elseif feeding_style = "socialites"
			Marginy's home on Victory St. opens itself up to you, as his children greet you with open arms.  So open, in fact, that you find it hard to extricate yourself in a timely fashion…
		*elseif feeding_style = "vegetarian"
			You are forced to break into a neighbor's stable.  It is therefore somewhat awkward when, standing there with your teeth in the neck of a horse, you hear the approaching footfalls of the master of the house.
			
			You make a hasty retreat…not fully satisfied, but the snack should at least tide you over…
		*else
			The soldiers at the barracks at the foot of the street greet you warmly.  Your patronage has earned you their affection.  Finding one of your regulars will just take a moment…

		Once you have fed, you clean yourself up and head for the party.
		*page_break
		*set new_orleans_quaestor_rapport %-5
		
		Estefania is waiting for you at the door to ${new_orleans_quaestor_surname}'s haven.  She is clearly annoyed at your tardiness.  You are so late that Ajax has been forced to abandon his post to address matters indoors.
		
		*if com_estefania
			"What delayed you so?  It is nearing midnight!  Have you forgotten the Quaestor's guests?"
			
			You make your apologies as best you can as she grabs you by the hand and leads you forcefully into the main salon.
		*else
			You make your incomprehensible apologies as best you can.  She grabs you by the hand and leads you forcefully into the main salon.
		*goto quintana
	#I go to the party hungry.  I am strong enough to control myself.
		*set discretion %+10
		*set go_hungry true
	#I will find something on the way there.
		*set discretion %+5
		*set independence %+5

		Driving through the streets, you spy a drunken Creole being supported by what you assume to be a whore, considering her hair and makeup.  You pull up beside them and offer them a ride, pretending to know the man.  His companion, flattered by the hitherto unknown status of her client, helps you lift him into the hired coupé.
		
		As she struggles to put the man in some sort of order, you guide the coupé around a corner.  As she turns to give you directions, you strike her quickly across the face.  Putting speed ahead of anything resembling decorum, you throw yourself on top of her and do your best to keep her struggles to a minimum.  Thankfully, the young man seems too intoxicated to pay you much mind.
		
		Within a moment or two, she stops struggling, giving in to the pleasure of your fangs.  Once you have drunk your fill, you look both ways and then push both of them out of the coupé and into the street.  Cracking the reins, you speed off, hoping that you are not too late.
		
		You do your best to clean yourself up while guiding the horses to the haven of the Quaestor.
		*set arrive_disheveled true
		*page_break 
	*if feeding_style = "vegetarian"
		*selectable_if (wealth > 10000) #I feed from that horse.
			*set wealth -1000
			Well, you had been planning on selling it.  But here's to expediency.
			
			You clean yourself up as best you can and head for the party.
			*page_break
*label arrive_on_time

You arrive at the party on time.  Ajax gestures for you to enter, but first you pause to greet Estefania, who is also just arriving.
*if go_hungry
	*set rios_rapport %-5
	After greetings are exchanged, she looks you up and down and tsks you quietly.
	
	*if speaks_english or (speaks_french or speaks_spanish)
		"Dear ${given_name}, you should have fed before coming here!  The things you still need to learn. I simply do not understand young vampires these days…" She blathers on like that for a few more minutes, remonstrating you for your decision.  
		
		"It is nothing, I'll be fine."
		
		"Fine!  Fine ${he} says!"  You quietly consider the consequences of feeding off of her, should she not quiet herself soon.
		
		Eventually she finishes chiding you and proceeds to lead you into the main salon.
		
		The first portion of the evening passes in a whirl…
	*else
		Somehow, you sense that she senses the hunger roiling inside you.  Her frown speaks volumes.  Throwing her hands up in despair, she disappears into the party.
		
		The first portion of the evening passes in a whirl…
*elseif arrive_disheveled
	*if (charm > 3) or ((charm = 3) and ((status >= 2) or ((status >= 1) and favored)))
		*set rios_rapport %+5
		*if speaks_english or (speaks_french or speaks_spanish)
			After greetings are exchanged, she looks you up and down.  "I suppose this is what the French call [i]déshabillé@{male |e}?[/i]  I suppose if any of us could carry such a look off, it would be you, dear ${given_name}."
			
			"Yes, it took me all evening to get the look just right…"
			
			"Come, tell me how you got your hair so perfect!" she proclaims, taking your arm and leading you inside.
		*else
			She certainly arches an eyebrow at your state of disheveled appearance.  When all is said and done, however, she seems more impressed than disapproving.
			
			Taking your arm, she guides you into the party.
	*else
		*if rios_rapport > 40
			*set rios_rapport %-5
			*if speaks_english or (speaks_french or speaks_spanish)
				After greetings are exchanged, she looks you up and down, and tsks you quietly.  "You are a mess, ${mr} ${surname}!  Here, come with me to the toilet.  You cannot appear before the governor like this!"
				
				She grabs you by the arm and drags you inside.
				*page_break
				The matter of your [i]${deshabille}[/i] is quickly built upon—Estefania is truly an artist with her powders and pomades—and you find yourself descending to the reception with a whimsical style which will earn you some curious looks if nothing else.
			*else
				She certainly arches an eyebrow at your state of disheveled appearance.  Her subsequent frown speaks volumes.  Throwing her hands up in despair, she disappears into the party.
		
				You find a mirror and put yourself back into order.
		*else
			*set rios_rapport %-10
			*if speaks_english or (speaks_french or speaks_spanish)
				After greetings are exchanged, she looks you up and down and tsks you quietly.  "You are a mess, ${mr} ${surname}!  You should really go to the toilet and straighten yourself out before you are announced.  You really can't be seen by the governor looking the way you do!"
				
				You try not to bristle too much at her chiding.  You find a mirror and put yourself back into order.
			*else
				She certainly arches an eyebrow at your state of disheveled appearance.  Her subsequent scowl speaks volumes.  Throwing her hands up in despair, she disappears into the party.
		
				You find a mirror, and put yourself back into order.
*elseif rios_rapport < 40
	*set rios_rapport %+5
	*if speaks_english or (speaks_french or speaks_spanish)
		"Good evening, ${mr} ${surname}."
		
		"Good evening to you, Sra. Rios."
		
		"Are you ready to face the governor and her party again?"
		
		"As ready as I shall ever be, I suppose."
		
		"I think I feel much the same way.  Shall we?" 
		*label loop_arm
		@{male You extend your arm, through which she loops hers, and the two of you make your entrance, trying to look like the best of friends.|With a nod, you turn and accompany her inside.  The two of you do your best to not let your animosity show as you make your entrance into the salon.}
	*else
		She inclines her head, suggesting that you enter together. 
		*goto loop_arm
*else
	*set rios_rapport %+5
	*if speaks_english or (speaks_french or speaks_spanish)
		"How lovely to see you, dearest ${given_name}!"
		
		"And you, Estefania.  You are breathtaking, as always."
		
		"Shush, you.  Shall we go inside?"
		
		"Yes, let's!" you say with a ${bow}.  At that, the two of you enter the main salon, thick as thieves.
		
		The first portion of the evening passes in a whirl…
	*else
		She smiles at you and inclines her head towards the door.
		*if male
			You extend your arm, through which she loops hers, and the two of you make your entrance, thick as thieves.
		*else
			Taking her arm in yours, the two of you glide into the party.

*label quintana
*page_break
*if speaks_spanish and (perception > 0)
	*set heard_of_quintana true
	At one point, you happen upon Governor Overstreet and Sra. Rios discussing Overstreet's journey to New-Orleans.  Apparently, ${new_orleans_quaestor_address} is not the only quaestor she is confirming during this trip.
	
	"Yes, I have corresponded some with Isabella," says Rios.
	
	"But you have never met?"
	
	"No, she was always preoccupied with things in San Agustín."
	
	"St. Augustine, Sra. Rios.  Ever since that bastard Jackson captured the Floridas for the United States, I have done my best to call it by its new name."
	
	"My apologies, Governor."
	
	"No apology necessary.  All the same, Sra. Quintana has been confirmed as Quaestor of Mobile.  I think the city suits her."
	
	"I am sure she will honor you in the position, Governor," Rios says, glaring in your direction.  Realizing that they have taken notice of you, you continue on, lest you draw their ire.
*elseif speaks_german and ((perception > 0) and (new_orleans_quaestor_surname = "Van der Velde"))
	*set heard_of_quintana true
	At one point, you happen upon Krupke and van der Velde speaking about the Governor's journey; it seems that Van der Velde is not the only Quaestor that has been confirmed to his position during this expedition from Savannah.
	
	"Ja, we took shelter in Mobile for several nights.  The Governor had to assure herself that Sra. Quintana would not bring dishonor upon her."
	
	"What did you think of her, Herr Krupke?" Van der Velde inquires.
	
	"Cunning, Heer Van der Velde.  She has the instincts and ferocity of a mongoose.  I would not underestimate her, were I to cross her."
	
	"Only if necessary, dear friend," Van der Velde says with a jovial laugh, during the course of which he turns his eyes to you and glares; it seems he has noticed your eavesdropping!  You quickly scurry away before he feels it necessary to address you.
*else
	After greeting the guests to New-Orleans, you do your best to mingle, but the conversation seems a little dry.  Everyone seems to be watching their words while waiting for the performance yet to come.
*page_break

Around midnight, it is announced that Samantha will be presenting @{learn_of_poem her|a} poem shortly; apparently she is in another room preparing herself. But before she can be summoned, Jesse takes the floor.

*if speaks_english
	"I don't mean to steal Mlle. Withers's thunder.  I mean, how could one steal the thunder from a beauty such as she?  But I thought you all might indulge me while I read a small composition of my own, to whet your appetites for Mlle. Withers's masterpiece.  May I, Your Grace?"  Overstreet nods in assent.  "Then I shall begin!" he exclaims.
	
	And so Jesse launches into a sonnet, in which he lays out the ways in which a young girl has misread signs of affection from a young man and foolishly fallen in love with an idea that could never have been.  By the end it turns tragicomic as the young lady's admission of love is rebuffed, but she refuses to believe the young man's ardent protestations of disdain.
	
	With a flourish, he concludes, and suddenly the pieces of his plot fall into place before you.  Soon, Samantha will emerge and deliver her poem.  Unfortunately, the die has already been cast; you can only sit and watch as things unfold before you.
*else
	He addresses the crowd in English, and at a nod from Overstreet, reads his own poem to the audience.  The crowd seems somewhat startled by it, even if they clap appreciatively.  He returns to his seat once he is finished, and the crowd quiets in anticipation of Samantha.
	
*page_break
*if samanthas_poem = "jesse"
	*set withers_embarrassed true
	
	Samantha takes the floor with an almost radiant confidence.  Clearing her throat, she begins.
	
	*if speaks_english
		It is a moment that will go down in the history of the Society as a debacle of epic proportions.  Samantha's poem, a tribute to her love, Jesse Whitaker, is met with guffaws.  She passes over the first few laughs without stumbling, but before long, she is brought up short with embarrassment.  Tears pouring down her face, she soldiers on to the poem's conclusion, by which point the room has broken into howls of vicious laughter.
		*if choctaw_confrontation
			*goto response_to_sams_embarrassment
		*elseif (compassion < 40)
			*if go_hungry
				You feel crushed and ashamed by your involvement in her downfall.  What's more, you feel an anger rising inside of you, bubbling forth, hot and red.  This is exactly the sort of thing that you were warned about, should you go to a gathering of your kind while hungry.
				*if (willpower >= 4) or ((willpower = 3) and (discretion <= 60))
					Fortunately, you are just able to keep a lid on your temper.  You only barely manage to excuse yourself from the party, lest you seek to tear Jesse limb from limb.
					*page_break
					*set new_orleans_quaestor_rapport %-15
					*set jesse_rapport %-5
					Later, ${new_orleans_quaestor_surname} remonstrates you for your premature departure from his [i]soirée[/i].  You make up some excuse to explain away your indiscretion.
				*else
					*set frenzied_on_jesse true
					*set jesse_rapport %-40
					*set overstreet_rapport %-30
					*set withers_rapport %+30
					*set new_orleans_quaestor_rapport %-50
					No longer able to contain yourself, you leap from your chair and onto Jesse.  Your fangs bared, you begin tearing at the flesh of his throat, your hands turned to claws of iron seeking to cleave the muscle from his bones.
					
					The gathered vampires are stunned by this sudden outbreak of physical violence.  But before your fangs can even get a solid grip on Jesse's neck, Walter Krupke has you suspended in midair by the scruff of your neck, like a lioness her cub.  You struggle futilely, your arms windmilling and your mouth foaming with rage.
					
					Jesse stands and brushes himself off.  "It seems that Mlle. Withers's affections were misplaced.  Perhaps someone should call her in here, that she might see the dedication of ${mr} ${surname} to her honor."  The crowd titters uncomfortably.
					
					${new_orleans_quaestor_surname} is clearly horrified.  "Herr Krupke, would you be so kind as to take ${mr} ${surname} into the next room?"  Krupke nods and carries you away, still struggling.  You hear ${new_orleans_quaestor_surname} apologizing profusely for your actions as the door falls mercifully shut.
					*set exiled_from_new_orleans true
					*set wealth /2
					*set income 0
					*set status -1
					
					${new_orleans_quaestor_surname}, Jesse and Estefania come to see you a few hours later.  Jesse looks no worse for wear, but glares at you as he enters.
					
					${new_orleans_quaestor_surname} begins: "You have embarrassed me before Governor Overstreet during her first visit to New-Orleans with me as quaestor.  Do you have any idea how long I will be working to undo what you have done this evening?"
					
					You think it best to not point out that ${new_orleans_quaestor_surname} is not yet—officially—quaestor.  Instead, you decide it wiser to simply hang your head in shame.
					
					"I would be well within my rights to put you to death for what you have done…assaulting another vampire!  In the midst of a Society gathering, no less!  Fortunately for you, Mlle. Withers has pleaded on your behalf.  Something about your defending her honor or some such," at this you catch a glance from Estefania.  She knows that you were simply hungry, but she has said nothing.  Since it seems you will be surviving this night after all, you suppose it best that you start keeping tally of your debts.  Because she certainly will be.  "Therefore, I am only here to pronounce your exile from New-Orleans.  You will leave immediately, on pain of death.  And do not return.  I hope I shall never see your wretched visage again."
					*page_break
					
					Dawn finds you digging a shelter for yourself beneath an oak tree on the Bayou St. John.  Tomorrow or the next day, you can make it to St. Charles parish, and from there, you can make your way further north.
						
					And so you flee New-Orleans, tail tucked between your legs… 
					*if lore < 2
						*set lore +1
					*finish Next
			*else
				*set compassion %-10
				You feel crushed and ashamed by your involvement in her downfall.  If only you had betrayed Jesse's confidence when you had the chance…
		*else
			*label response_to_sams_embarrassment
			*choice
				#I laugh along with the crowd.
					*set compassion %+10
					You laugh along with the rest of the crowd.  You can almost feel your already still heart hardening inside your chest.
				*if choctaw_confrontation
					*selectable_if (compassion < 60) #Despite our confrontation, I do not relish this humiliation.
						*set compassion %-5
						You sit there uncomfortably, watching Samantha's former radiance falter and then disappear before the onslaught of the crowd.  Alas, there is nothing for you to do.
				*else
					*selectable_if (compassion < 60) #I am ashamed for my part in this.
						*set compassion %-10
						You feel crushed and ashamed by your involvement in her downfall.  If only you had betrayed Jesse's confidence when you had the chance…
	
		The poem itself would have been delightful, but the content…well, she will never live it down.  Not as long as any of these immortal vultures still see fit to repeat the tale, anyway.
		*page_break
		As the evening winds down, Jesse approaches you.  Laying a hand on your upper arm, he whispers in your ear, "That was quite a show wasn't it, my dear friend?"  At his touch, a thrill of…excitement? fear?…runs down your spine.
		
		"It was extraordinary, yes."
		
		"Your discretion has been noted and is appreciated."
		*choice
			#Nod without comment.
				*set jesse_rapport %+20
				Jesse seems to take your silence for grudging admiration.  "I couldn't have done it without you, you know."
			#"I only wish I had known your plans…perhaps we could have done even more."
				*set jesse_rapport %+25
				"Oh, ${given_name}, it was perfect as it was."
			#"I think you should be ashamed of yourself."
				*set jesse_rapport %-10
				"You are still young, ${mr} ${surname}.  In time you will come to see that this was an appropriate lesson for her…and for you."
		*page_break
	*else
		You can't understand a word of it, but that doesn't prevent you from seeing the reaction of the audience.  They are, to a person, viciously amused.  By the middle of the piece, no one is even trying to conceal their laughter at the increasingly mortified Samantha.  Once she concludes, the room shakes with their howls.  It is a moment that will go down in the history of the Society as a debacle of epic proportions.
		*page_break
		*if com_jesse
			Later that evening, Jesse approaches you.  Laying a hand on your upper arm, you tremble a little at his touch.  "I could not have done it without you, dear ${given_name}.  I wish you could have understood her words; her professions of love and devotion were only too perfect."
				
			*choice
				#Nod without comment.
					*set jesse_rapport %+15
					Jesse seems to take your silence for approval or at least appreciation.  "I couldn't have done it without you, you know."
					
					An appropriate moment for you to take your leave of the party does not arrive soon enough.
				#"I too wish I could have understood; as it is, I can only judge her shame by the laughter of her audience."
					*set jesse_rapport %+25
					"Oh, ${given_name}, it was truly perfect.  Perhaps I will translate them for you, so that years from now, you can relate your part in this [i]pièce-de-théâtre[/i]."
					
					"I would appreciate that greatly, dear Jesse."
	
					The sensation of dawn's impending arrival soon swells in your breast, and you are forced to take your leave.
				#"I think you should be ashamed of yourself."
					*set jesse_rapport %-15
					"You are still young, ${mr} ${surname}.  In time you will come to see that this was an appropriate lesson for her…and for you."
					
					An appropriate moment for you to take your leave of the party does not arrive soon enough.
		*elseif com_estefania
			Later that evening, Estefania approaches you.  "It is too bad you could not understand first-hand what transpired here tonight.  It was a lesson in cunning for us all."
			
			"How so?"
			
			"Jesse managed to encourage Mlle. Withers's affections without becoming entangled with her, to the point that she felt compelled to declare her love in a public forum, but not before he made it clear that he had been politely rebuffing her advances, but that she had foolishly pursued him across the country.  Even though he is almost a century younger than her, he demonstrated this evening that age is not everything among our kind."
			
			"An object lesson, I imagine."
			
			"Yes.  I will take it to heart, myself.  
			*if love_clotho
				Some do not learn these lessons early, however.  You should be grateful that you have ${new_orleans_quaestor_address} and Jesse to instill them in you."
				
				"Yes, I am grateful," you reply, gritting your teeth.
				
				An appropriate moment for you to take your leave of the party does not arrive soon enough.
			*else
				I hope you never make the same mistake as her."
				
				"As do I, Sra. Rios."
				
				The sensation of dawn's impending arrival soon swells in your breast, and you are forced to take your leave.
		*else
			Later that evening, ${new_orleans_quaestor_surname} approaches you.  "It is unfortunate that you could not understand first-hand what transpired here this evening.  It was a true [i]coup-de-grâce[/i] on Jesse's part."
			
			"I understood well enough from the laughter of the audience.  Jesse laid a trap, and Mlle. Withers strided resolutely into it."
			
			"Yes.
			*if love_clotho
				Though you may find it hard to believe, Mlle. Withers learned a valuable lesson this evening.  She will not make the same mistake twice.  After all, it becomes very tedious for your elders to have to teach the same lesson over and over."
				
				"I understand, ${new_orleans_quaestor_address}."
				
				An appropriate moment for you to take your leave of the party does not arrive soon enough.
			*else
				Let this stand as a lesson for you: though you may have vestiges of human feelings in your heart, they are lies.  You should do your best to snuff them out, as they will only lead you to ruin.  My dearest firstmade has taken my lessons to a whole new level."
				
				"Your lessons?"
				
				"Yes, once upon a time, I had to remonstrate him for his own foolishness.  Clearly, he took my words to heart."
				
				"Clearly, ${new_orleans_quaestor_address}."
				
				The sensation of dawn's impending arrival soon swells in your breast, and you are forced to take your leave.
*else
	*set jesse_embarrassed true
	*if speaks_english
		It is a moment that will go down in the history of the Society as a rather deft outmaneuvering.  Instead of the anticipated ode to Jesse, Samantha unleashes a scathing account of a peacock, stuffed with pride and self-importance, who leaves a trail of broken hearts behind him, but soon finds himself plucked of his beautiful feathers to adorn ladies' hats.  The crowd howls with laughter, but their humor is directed at an increasingly furious Jesse.
	*else
		*set withers_rapport %+25
		It is a moment that will go down in the history of the Society as a rather deft outmaneuvering.  Unfortunately, though you are witness to it, full comprehension only comes later.  Apparently, Jesse's poem had anticipated a declaration of love on her part, but somehow she discovered his false nature.  Instead, she delivered a poem about a peacock, stuffed with pride and self-importance, who left a trail of broken hearts behind him, but all too soon found himself plucked of his beautiful feathers so that they could adorn ladies' hats.
		
		As it is, you sit and take in the howls of laughter directed at an increasingly furious Jesse. 
	When the poem finishes, the room bursts into applause.	
	*if withers_rapport > 35
		*set withers_rapport %+25
		From across the room, Samantha flashes you a brief nod of gratitude.  
	*else
		*set withers_rapport %+25
		Though Samantha is clearly thrilled by the reception of her work, you receive no token of thanks for your timely warning.
	
	*temp sir_temp "sir"
	*if jesse_is_broodmate and male
		*set sir_temp "dear brother"
	*elseif jesse_is_broodmate
		*set sir_temp "dear sister"
	*if (jesse_is_broodmate = false) and (male = false)
		*set sir_temp "ma'am"
	
	*if com_sam
		@{(discretion < 50) You do your best not to quake as you sense the approach of Jesse and his palpable fury.|You sense Jesse's fury before you can even identify his angle of approach.  You raise your eyes unflinchingly to meet his gaze.}
		
		"What do you have to say for yourself, ${sir_temp}?"  His words seem to dart out at you from between his clenched teeth.  He struggles to not raise his voice, lest he attract any more undue attention than he already has.
		
		*choice
			#"I could not abide your treatment of that poor woman."
				*set compassion %-10
				*if compassion < 55
					*set jesse_rapport %-20
					"I pity your overly-tender heart, ${mr} ${surname}.  Such compassion shall be your downfall."  With that, he storms from your presence.
				*else
					*set jesse_rapport %-35
					Jesse waves away your lies.  "Do not sully my ears with your false charity; you care for no one but yourself, and yet you suddenly defend Samantha? I do not believe it for a second. No, you chose to ruin me this evening."
					
					Like a fish gasping for air, you open and close your mouth several times, trying to formulate a response.
					
					"Fear not.  I shall find a way to repay you."  With that, he storms from your presence.
			*selectable_if (discretion > 40) #"I expected your congratulations…for a game well played."
				*if jesse_rapport < 35
					"I suppose I should have expected as much."
		
					*if discretion > 60
						*set jesse_rapport %-5
						"You did make the matter very simple.  A few words of remonstrance and she was more than prepared to abandon her affections.  Perhaps next time you should be more circumspect in who you involve in your intrigues."
		
						"I most certainly shall, ${mr} ${surname}."  With that, he storms from your presence.
					*else
						*set jesse_rapport %+10
						"I suppose, then, that we have both learned something this evening, Mr. Whitaker.  Now, if you will excuse me.…" With that, you take your leave of Jesse and join the victor's circle.
				*elseif jesse_rapport < 65
					*set jesse_rapport %-20
					"I knew that we were not on the best of terms, ${mr} ${surname}, but I did not realize you sought my ruination."
		
					"I did not ruin you.  You are charming and ruthless.  Any ground you lost tonight shall be regained within the year.  I do not doubt it for a moment."
		
					"Then why would you do this to me?"
		
					"I did not do this to you, dear Jesse.  Rather, I saved her from you.  Now, if you will excuse me, I have some congratulations to extend."  With that, you take your leave of Jesse and join the victor's circle.
				*else
					*set jesse_rapport %-40
					Jesse is clearly taken aback by your animosity.  "But, dear ${given_name}!  I thought us kindred spirits!  I do not understand this desire to ruin me!"
		
					You offer a grin with only a hint of fang.  "I suppose you shall have to continue in ignorance, dear Jesse.  Now, I bid you good night."  With that you leave Jesse to his unanswered questions.
			#"It was not my doing!  I would not break your trust like that!"
				*if (stealth > 1) or ((stealth > 0) and (discretion < 40))
					*set jesse_rapport %+5
					*set lied_to_jesse_about_poem true
					Jesse draws up short, surprised by your claim.  He studies you for a moment before peering over his shoulder.  "Of course, please forgive my outburst."
					
					"It is already forgotten."
					
					"You must excuse me.  I must discover the source of this embarrassment.  I shall not rest until the culprit has been punished."
				*else
					*set jesse_rapport %-50
					Jesse waves away your protestations.  "Do not sully my ears with your perfidy.  I can hear the lies in the space between your words.  You have ruined me this evening."
					
					Like a fish gasping for air, you open and close your mouth several times, trying to formulate a response.
					
					"Fear not.  I shall find a way to repay you."  With that, he storms from your presence.
	*elseif com_jesse
		"What did you do?" Jesse demands as he descends upon you.
		
		"Me?" you reply innocently.
		
		"Yes, you! You took her on that tour around the city! You must have told her something?"
		
		"Whatever could I have said to her, dear brother?" you reply sweetly. "We don't even share a common tongue."
		
		Jesse's head looks like it's about to explode. You can see the wheels turning in his head: did he misjudge Samantha? Is she cleverer than he realized? Now that he's shown his hand, what further schemes will she enact?
		
		He excuses himself, mumbling a brief apology.
	*else
		Jesse accosts you, his voice raised. You look at him blankly. He's clearly expressing frustration about what just happened, but since you do not share a common tongue with him—or with Samantha, for that matter—his fury quickly burns itself out.
		
		You can see it when the idea hits him that perhaps he misjudged Samantha; as far as he can tell, she thoroughly outfoxed him. What else has he misconstrued?

The rest of Overstreet's stay is uneventful and mercifully short.  Within a few days, the party books passage on a steamer and heads up the Mississippi.
*if withers_embarrassed
	It seems that Overstreet wants to find a place where she can ensconce Withers outside of the regular circles of the Society, to avoid further embarrassment to herself and her bloodline.
*else
	You hear that Withers will be set up somewhere on the river, with the end goal of making her quaestor of a city.  Though she may have dodged a bullet, it wasn't through much foresight on her part, and the consensus is that Withers needs some maturing before she should really be let loose on the Society's circuit again.

Before leaving, however, Overstreet officially names ${new_orleans_quaestor_surname} Quaestor of New-Orleans, an honor he accepts without any humility whatsoever.  His position confirmed, ${new_orleans_quaestor_surname}'s interest in the Governor declines dramatically; Estefania is left with the task of entertaining the guests until their departure.

With Whitaker, Rios, and you as the core of his citizenry, he sets about guiding the city's development to suit his tastes and needs.  Now confirmed to his position, he allows his imagination license to build a city of dreams on the Mississippi.

*if met_andrew_jackson
	*page_break
	
	It is during the fall of 1828 that Andrew Jackson's campaign for the presidency reaches its final stages.  When word of his victory reaches you, you shudder at the recollection of that night you met after the Battle of New-Orleans.  Whatever he is, it cannot be good for your kind.

1830 is just around the corner…
*page_break
"We are expecting a guest," ${new_orleans_quaestor_surname} says.

It's April of 1831. New-Orleans is sweltering in the heat and humidity. Ajax, looking tired and drawn, stands at attention in the corner of the room.

"Who is that?" @{com_jesse Jesse asks.|you inquire.}
	
*set heard_of_draper true
*set met_draper true
*temp to_perform false
"James Draper is his name."

*if com_jesse
	"Draper? That blackguard?"
	
	${new_orleans_quaestor_surname} shoots Jesse a look.
"He's a member of the governor's court in Savannah. I suspect he's here to…assure the governor that all is well."

*choice
	#"I'm sure you have nothing to worry about, ${dominus}."
		*set independence %+5
		*set new_orleans_quaestor_rapport %+5
		*set jesse_rapport %-5
		Jesse shoots a @{(jesse_rapport > 60) glance|scowl} in your direction. You can almost @{com_jesse hear|imagine} him whisper, "Bootlicker."
	*if (performed_well) #"Shall I be prepared with a song and dance?"
		*set to_perform true
		*set discretion %+5
		*set new_orleans_quaestor_rapport %+5
		*set independence %+5
		${new_orleans_quaestor_surname} ignores your sarcasm. "You should be prepared, yes."
	*if (performed_well = false) #"Will Estefania be @{performed performing?|performing again?}"
		*set rios_rapport %+5
		*set independence %+5
		${new_orleans_quaestor_surname} considers a moment. "Yes, I think that 
		*if com_estefania
			appropriate. Estefania?"
		
			She nods. "Of course, Quaestor."
		*else
			appropriate," says, before switching to French to ask Rios a question. She nods in acceptance.
	#"Will my presence be required?"
		*set independence %-10
		*set new_orleans_quaestor_rapport %-5
		"Yes, ${given_name}, your presence is required!" ${new_orleans_quaestor_surname} retorts.
		
		You suppress the urge to roll your eyes. "Then I shall be there."
		
		@{(perception > 0) Out of the corner of your eye, you spot Jesse smothering a smile.|}
		
A month later, you style your hair and set out for the reception. Little do you realize when Ajax opens the door to your carriage that you will be meeting two more of your kind this evening.
*set met_tiozzo true
*temp interlocutor "Estefania"
*if (jesse_rapport > 55) and com_jesse
	*set interlocutor "Jesse"
*elseif com_jesse and (com_estefania = false)
	*set interlocutor "Jesse"
*elseif (com_jesse = false) and (com_estefania = false)
	*page_break
	Entering ${new_orleans_quaestor_surname}'s parlor, you find not one, but two strange vampires. You assume that the man is James Draper, but he has a woman with him.
	
	"${given_name}, come, meet Mr. Draper and Lady Tiozzo."
	
	You ${bow} in greeting. Tiozzo @{male nods while Draper extends his hand for you to shake.|and Draper both nod in greeting.}
	*gosub describe_visitors
	
	"I understand that you do not speak the language here. But I am from Fiume, where we speak many languages." @{((intelligence + lore) >= 5) By calling the city by its Veneto name, Tiozzo is making a political statement. The city to which she refers, more commonly called Rijeka, is a city along the Dalmatian coast. Though it has close ties with Venice, it has been a part of the Habsburg Monarchy for centuries.|}
	
	*set draper_rapport %-10
	*if (charm + perception) >= 4
		*set tiozzo_rapport %+5
		*set new_orleans_quaestor_rapport %+3
		Draper, clearly, does not speak German. He does a poor job of hiding his annoyance that the three of you are conversing without him.
		
		"Please, do not let me distract you from your purpose."
		
		"That is good of you to say," she replies with a smile.
	*else
		"How fortunate for me! Tell me…" you begin.
		
		"Before you begin," she interrupts, "my dear friend James does not speak German. And he becomes such a bore when he is excluded from conversation," she says, looking Draper in the eyes. "We will have to speak more later."
		
		"Of course," you reply, excusing yourself with a second ${bow}.
	*goto lb
*page_break
*comment add bonus if you brought gaslamps to NOLA
*comment add interaction with Draper
*set heard_of_tiozzo true
${interlocutor} grabs you almost as soon as you enter the room, eyes wide. "Draper has brought Orelia Tiozzo!"

"Orelia Tiozzo?"

"She is the most famous vampire painter in the world!"

"And she's here?" you exclaim.

@{(interlocutor = "Estefania") "She is! She will not leave this city without painting me.|"She is. I suspect that Estefania will demand to sit for her.}"

A few moments later, you are in the presence of the illustrious painter and her companion.

"And this," ${interlocutor} says, nearly thrusting you forward, "is @{priest ${mr}|${given_name}} ${surname}."
*gosub describe_visitors

*choice
	#I welcome them humbly.
		*set discretion %-5
		*set tiozzo_rapport %+5
		*set draper_rapport %+5
		You politely welcome the two guests to New-Orleans. They pay the city a few stale compliments in return.
		
		*if (discretion > 50) and (new_orleans_quaestor_surname != "Villanueva")
			*set rios_rapport %-10
			As you withdraw, Rios shoots you a look; she was expecting something more exciting from you than that.
	#I belittle the city and the court of New-Orleans.
		*set discretion %+5
		*set independence %+5
		"You came all the way here? To see us?"
		
		"Yes?" Tiozzo ventures, unsure as to where you are going with this line.
		
		"What whim prompted you so?"
		
		"A dear friend of mine told me that the city was beautiful and not to be missed. That the quaestor was gracious enough—" She pauses for just a moment, glancing in his direction.
		
		At that, you interrupt her: "Did you know, I am also a jewel thief? I just so happen to have the crown jewels of France for sale. I'm sure you'll buy them, sight unseen. As it seems you'll buy anything."
		*temp mod 0
		*if favored
			*set mod +1
		
		*temp testing_stat ((charm + status) + mod)
		*if testing_stat >= 5
			*set tiozzo_rapport %+15
			*set draper_rapport %+15
			*set new_orleans_quaestor_rapport %-5
			Tiozzo and Draper burst into laughter at your gibe, while ${new_orleans_quaestor_surname}'s eyes look like they're ready to pop out of his skull.
			
			"Oh, dear ${dominus}, you know I only jest," you continue, soothing his wounded pride.
		*elseif testing_stat >= 4
			*set tiozzo_rapport %+10
			*set draper_rapport %+10
			*set new_orleans_quaestor_rapport %-10
			*set jesse_rapport %-5
			*if (new_orleans_quaestor_surname != "Villanueva")
				*set rios_rapport %-5
			Tiozzo and Draper burst into laughter at your gibe, while ${new_orleans_quaestor_surname}'s eyes look like they're ready to pop out of his skull. Even Jesse looks annoyed.			
		*elseif testing_stat >= 3
			*set new_orleans_quaestor_rapport %-20
			*set jesse_rapport %-5
			*set rios_rapport %-10
			Tiozzo and Draper look at you, trying to determine if you are jesting or sincerely insulting your ${dominus}. "Thank you, but I have no need of jewels," Tiozzo replies.
		*else
			*set tiozzo_rapport %-15
			*set draper_rapport %-15
			*set new_orleans_quaestor_rapport %-25
			*set jesse_rapport %-10
			*set rios_rapport %-10
			${new_orleans_quaestor_surname}'s jaw clenches. "${given_name} is young and has yet to understand what is appropriate to say to guests and what is not."
			
			"Yes, clearly," Tiozzo replies.
	#I observe the necessary formalities—the faster to end this torture.
		*set independence %-10
		*set new_orleans_quaestor_rapport %-5
		*set tiozzo_rapport %-5
		You ${bow} and welcome them to the city.
		*if independence < 40
			*set draper_rapport %+10
			
			You seem to find some kinship in Draper—he seems sympathetic to your disinterest in these rituals.
		*else
			*set draper_rapport %-5
			Your perfunctory performance pleases no one.

*label lb
*page_break
*temp who_performed 3
*temp to_sit 1
*temp dazzled_tiozzo false
*temp disappointed_tiozzo false
*temp horseflesh false
The six of you make polite coversation for at least another hour, before
*if to_perform
	${new_orleans_quaestor_surname} turns to you. "Are you prepared to perform?"
	
	"Yes, ${dominus}."
	
	"If it would please you, Lady Tiozzo, ${given_name} will play the pianoforte for us."
	
	"Oh, do!" Tiozzo exclaims.
	*gosub perform_for_tiozzo
*elseif performed_well
	${new_orleans_quaestor_surname} turns the conversation back to you. "Our ${given_name} here is a talented musician. Would you like to hear ${him} play?"
	
	"Oh, yes!" Tiozzo exclaims.
	
	*choice
		#I sit down and play.
			*gosub perform_for_tiozzo
		#I refuse.
			*set rios_rapport %+10
			*set new_orleans_quaestor_rapport %-15
			*if status > 1
				*set tiozzo_rapport %+5
			*set draper_rapport %+10
			*set discretion %+5
			*set independence %-10
			"My apologies, Lady Tiozzo, but as much as ${new_orleans_quaestor_surname} seems to think that I am a pony trained to prance at his command, I am not."
			
			Draper smiles at your insolence.
			
			Rios, ever the diplomat, intervenes before ${new_orleans_quaestor_surname} speaks his mind. "If I may, Lady Tiozzo…"
			
			"Oh, do!" she replies.
			
			*gosub rios_performs_tiozzo
		#I suggest that Rios perform instead.
			*set rios_rapport %+10
			*set new_orleans_quaestor_rapport %-5
			*set tiozzo_rapport %+5
			*set discretion %-10
			Rios is surprised but pleased by your deference.
			*gosub rios_performs_tiozzo
*else
	${new_orleans_quaestor_surname} suggests a divertissement.
	
	*choice
		*if (creation > 0) #I volunteer to play the piano.
			*set discretion %+5
			*if performed
				*set new_orleans_quaestor_rapport %-5
				${new_orleans_quaestor_surname} purses his lips. "No, ${given_name}, we shall not have a repeat of that débâcle. Estefania, will you play for us?"
				
				*gosub rios_performs_tiozzo
			*else
				${new_orleans_quaestor_surname} considers a moment, and then nods.
				
				*gosub perform_for_tiozzo
		*if (performed = false) #I suggest that Rios play the piano.
			*set rios_rapport %+10
			Rios throws an appreciative glance your way. ${new_orleans_quaestor_surname} considers a moment, and then nods.
			
			*gosub rios_performs_tiozzo
		*if (attended_marignys_party) #I suggest a game of [i]crapaud[/i].
			*set discretion %+5
			*set draper_rapport %+10
			*set tiozzo_rapport %-5
			*set new_orleans_quaestor_rapport %+5
			*comment Tiozzo and Draper visit Arnoult Ogier before coming to New-Orleans; Draper is ignorant of Tiozzo's true purpose.
			Draper's ears perk up at mention of a game of chance.
			
			You dictate the rules—as best as you remember them—and soon the six of you are throwing dice and betting on their fall. @{(perception > 0) Lady Tiozzo seems the most bored of the lot; clearly, gambling is not her passion.|} 
			
			During the game, Draper mentions how they were recently in New Paltz, a small village in New-York. You try to find out why they would visit such a small town@{(ethnicity = "yankee") —you would know, you visited it once—| }but you can wheedle nothing further from him. Instead, he changes the subject to his new passion: horse racing. He waxes at length about the glories of horseflesh. At some point you excuse yourself when he recognizes an error in his recounting of Diomed's numerous offspring; you sense that he would be happy to work out his error were you to offer him paper and a quill.
			*set horseflesh true
		#I suggest a game of cards.
			*set independence %+5
			Fortunately or unfortunately, bridge does not suit six people. As the youngest, you are right out; Estefania and Jesse draw straws, and Jesse loses.

			The foursome embark on a clever game of bridge, while you and Jesse pretend to look interested.
			*if independence > 55
				*set tiozzo_rapport %+5
				*set new_orleans_quaestor_rapport %+5
			*else
				*set tiozzo_rapport %-5
				*set new_orleans_quaestor_rapport %-5
				You note several stern looks from ${new_orleans_quaestor_surname} during the game—perhaps you have not been successful at feigning interest?
		#I stay mum.
			*set discretion %-10
			After some back-and-forth, it is decided that Estefania will play the piano.

			*gosub rios_performs_tiozzo

The evening is beginning to wind down.
*temp invitation_to_sit 1
*if (who_performed = 1) and (dazzled_tiozzo)
	*set invitation_to_sit 3
	
	Lady Tiozzo accosts you before you can make an escape. "You must sit for me!"

	*if heard_of_tiozzo
		You pause, but only for a moment. "I would be honored, Lady Tiozzo."

	*else
		"Sit for you?"

		She looks taken aback. "Yes?"

		"Sit…in what way?"

		"For a painting, dear. I am a painter."

		"I suppose…"

		"Good!" she interrupts.
	"Here is my address. You should come Tuesday evening."

	"Thank you," you reply, as she loops her arm through Draper's and the two disapper into the night.
*elseif com_estefania and (who_performed = 2)
	*set invitation_to_sit 2
	As the evening draws to a close, you overhear Rios and Tiozzo chatting. It seems that Tiozzo has asked Rios to @{heard_of_tiozzo sit|"sit"} for her. Rios accepts enthusiastically.
*elseif (who_performed = 2)
	*set invitation_to_sit 2
	As the evening draws to a close, you see Rios and Tiozzo in companionable conversation. When they part, Rios is clearly elated.
	
	You wonder what this portends.
*elseif (draper_rapport > 55) and (horseflesh = false)
	*set horseflesh true
	As the evening draws to a close, Draper indulges in a bit of idle conversation while Tiozzo says her goodbyes.
	
	"Has a jockey club formed here?" he inquires.
	
	"A jockey club?" you reply.
	
	"Yes, for horseracing."
	
	"No, not that I'm aware of."
	
	"A shame. The magnificence of thoroughbreds is not to be underestimated."
	
	"Do you attend many horseraces?"
	
	"There are no races at night, my friend. But I find the breeding of the horses fascinating. Not to mention the thrill of success when my favorite wins!"
	
	"Well, I'm sorry to say, there is no jockey club here."
	
	At that, Tiozzo finishes her goodbyes. Grabbing Draper by the elbow, the two excuse themselves.

*temp painted 1
*if invitation_to_sit = 3
	*set painted 3
	As you prepare to leave, Rios accosts you.

	"Orelia asked you to sit for her?"

	"She did."

	"You must let me sit for her instead!"

	"Pardon?"

	"I have wanted to be painted by Orelia Tiozzo for…decades. Please! You must. I…I will owe you a debt…"

	*choice
		#"Certainly not."
			*set rios_rapport %-20
			*set discretion %+5
			Rios storms off without saying another word.
		#"I think it would be rude were you to show up in my place."
			*set rios_rapport %-20
			*set independence %+5
			Rios huffs beforming stomping off without another word.
		#"Very well."
			*set debt_from_rios true
			*set rios_rapport %+30
			*set tiozzo_rapport %-10
			*set independence %+10
			*set painted 2
			Estefania nearly squeals with delight. She takes the address and disappears in a flash.

*elseif (invitation_to_sit = 2)
	*set painted 2
	*if com_estefania and heard_of_tiozzo
		*gosub offer_debt_to_estefania
	*elseif com_estefania
		You approach Rios and ask her what intrigue she has instigated with Lady Tiozzo.

		"No intrigue! I'm going to sit for her."

		"Sit for her?"

		"Don't you know who Orelia Tiozzo is?"

		"I'm afraid not."

		"She is the most famous painter of our kind! To have a portrait done by her is a mark of your standing in the Society!"

		"And she is going to paint one of you?"

		"She is!" Estefania nearly squeals.

		*gosub offer_debt_to_estefania

*temp knows_creole_stakes false
*if painted = 3
	*page_break
	You arrive at Tiozzo's accommodations on Tuesday evening as instructed. You sit for her that night, and the next, and the next.

	She informs you that the painting will be finished soon. You thank her graciously and excuse yourself.
	*comment add the opportunity to have kinky blood-sex
	*page_break @{painted A Week Later|A Week Later|That Saturday Night}
*elseif horseflesh and attended_marignys_party
	*page_break
	*set knows_creole_stakes true
	By happenstance, you cross paths with M. de Marigny one evening that week. To your surprise, he expresses his interest in developing the sport of horse racing in Louisiana. In order to encourage the enterprise, he intends to establish a race for horses born and bred in the State; horses from other States would not be permitted.
	*page_break That Saturday Night
*else
	*page_break A Week Later
*temp jealousy false

You arrive at the haven of ${new_orleans_quaestor_address} after feeding. Upon entering, you find
*if (new_orleans_quaestor_surname = "Van der Velde") or ((new_orleans_quaestor_surname = "Padre Carlos") or ((new_orleans_quaestor_surname = "Villanueva") and (sire_alive = false)))
	${new_orleans_quaestor_surname} looking quite pleased with himself. He and Lady Tiozzo are talking and laughing like they have been friends forever.

	Eventually, Rios suggests that Tiozzo show off the portrait that she has been working on. She plays coy for a time, but finally relents.
*else
	*if (embrace_of_affection and sire_alive) and (sire_name != "West")
		*set jealousy true
	${new_orleans_quaestor_surname} quite angry. Draper has interposed himself between him and Lady Tiozzo.

	"This is unacceptable!" ${new_orleans_quaestor_surname} thunders.

	Tiozzo looks at you and then looks back at ${new_orleans_quaestor_surname}. "This is not the time, Quaestor."

	${new_orleans_quaestor_surname} notices you finally and works to smother his rage.
	*if jealousy
		You, in turn, feel yourself growing hot with jealousy. What were Tiozzo and ${new_orleans_quaestor_surname} doing alone?
	*if painted > 1

		"Perhaps we should admire Lady Tiozzo's portrait of @{painted ERROR|me|${given_name}}," Rios offers, attempting to change the subject.

		"Yes, let us," Tiozzo says, her gaze unwavering before ${new_orleans_quaestor_surname}'s rage.

		"Very well," ${new_orleans_quaestor_surname} says.
	*else
		"Ah, ${given_name}. We were just discussing the future of this city," Tiozzo exclaims.

		"Oh?" you inquire cautiously.

		"Yes. But, as always, the future is uncertain," he says, shooting Tiozzo a glare.

		"So it is, ${dominus}@{jealousy ," you say through clenched teeth.|."}

*if painted > 1
	The painting is magnificent. Orelia Tiozzo is truly the master that Rios described.
	*if (painted = 2) and debt_to_rios
		You can tell that Rios is questioning her decision to trade a debt for a portrait.
	*elseif painted = 2
		Rios melts with pleasure under the attention.
	*elseif debt_from_rios
		Rios is clearly elated with your trade, though you can tell Tiozzo is a bit disappointed.
	*elseif painted = 3
		*set new_orleans_quaestor_rapport %-10
		You can tell that ${new_orleans_quaestor_surname} and Rios both envy your new prize.
	*else
		*bug no other possiblities.
	*if jealousy
		*if painted = 3
			All pleasure that you might derive from this, however, is drained by your preoccupation with Tiozzo and ${new_orleans_quaestor_surname}'s [i]tête-à-tête[/i].
		*elseif painted = 2
			You, however, are focused on trying divine the nature of Tiozzo and ${new_orleans_quaestor_surname}'s [i]tête-à-tête[/i].

	Tiozzo gifts the painting to
	*if painted = 2
		Rios, who vibrates with joy.
	*if painted = 3
		*set tiozzo_portrait_1831 3
		you, which you accept graciously.

*if ((tiozzo_portrait_1831 = 3) and jealousy) and ((discretion > 60) and (willpower = 1))
	*set tiozzo_portrait_1831 2
	*set rios_rapport %-10
	*set new_orleans_quaestor_rapport %-10
	*set jesse_rapport %+20
	*set draper_rapport %+10
	*set tiozzo_rapport %+15
	Then, before everyone's eyes, you tear the painting to shreds. Rios gasps in horror while Tiozzo's peals of laughter echo off the walls.

	"${given_name}, what have you done?" ${new_orleans_quaestor_surname} demands, incredulous.

	"I have been replaced! And my consolation prize is a portrait?" you shout.

	"${given_name}, you misunderstand…"

	"I understand enough! Do not treat me like a child!"

	"Then stop acting like one!" he retorts.

	With that, you storm out of his home.
*elseif knows_creole_stakes
	*set draper_rapport %+5
	You casually mention to Draper that M. de Marigny has already initiated a horse breeding program in Louisiana. Draper's eyes light up at the news. He is clearly excited by the prospect.
*else
	The rest of the evening consists of more gossip and finally goodbyes. Draper and Tiozzo are headed north, up the Mississippi.
	*if tiozzo_portrait_1831 = 3
		You thank Tiozzo once again for her work. When you tell her that you will cherish it always, you mean it.
	When dawn draws near, you return to your haven once again.

*page_break
It seems that ${new_orleans_quaestor_surname} received his appointment just in time, as the coming of the new decade sees a population explosion in New-Orleans. With the influx of immigrants, a smattering of vampires find their way to the city as well. ${new_orleans_quaestor_surname} soon has his hands full playing the various egos against one another, a project to which Jesse's talents are uniquely suited. @{(tiozzo_portrait_1831 = 2) Moreover, after your outburst, it is some time before you are invited back to a [i]soirée[/i] at the home of ${new_orleans_quaestor_surname}.|}

*if heard_of_laveau
	Meanwhile, Marie Laveau has continued her rise to prominence in the city.  @{met_clotho Like that woman whom you briefly met outside Yves's home, the|The} other Voodoo priestesses of the city are either all under her sway or die mysteriously. Laveau claims that through her magic she can make people fall in love, raise or destroy their fortunes, and see the future.
*else
	*set heard_of_laveau true
	One of the stars riding the crest of this population explosion is Marie Laveau, a self-styled Voodoo Queen.  The Voodoo priestesses of the city, one by one, fall under her sway.  She claims that through her magic she can make people fall in love, raise or destroy fortunes, and see the future.

What do you think of this Voodoo Queen and her claims of supernatural power?
*choice
	*selectable_if (rationalism < 65) #Poppycock!  There is no such thing as magic or Voodoo!
		*set rationalism %-10

		Inquiring minds want to know: how do you explain your unliving existence?
		
		*choice
			#In time, the march of knowledge will make everything clear.
				*set discretion %-10
				*set anachronism %+10
				*set rationalism %-10
			#Vampires are cursed by God.  Magic and voodoo are simple superstition.
				*set rationalism %+20
			#Honestly, I have no idea how we came to be or why we exist.
				*set discretion %-20
				*set rationalism %-10
	*selectable_if (rationalism >= 40) #I stay far away from her, lest she curse me with her voodoo magics.
		*set rationalism %+10
		*set discretion %-5
		Probably a wise choice.  You have so many other things on your plate, after all.
	*if charm > 2
		*selectable_if (feeding_style != "vegetarian") #I'll see if her loa can protect her from my fangs!  Which is to say, I want to try and feed from her.
			*set exposure +1
			*set discretion %+5
			*set rationalism %-5
			*set fed_from_laveau true
			*achieve fedonlaveau
	
			The Voodoo Queen of New-Orleans is only too happy to make your acquaintance.  When presented with the opportunity, you feed from Mme. Laveau and leave her begging for more.
	*if love_clotho
		*selectable_if (rationalism >= 40) #Maybe she can contact Clotho's restless spirit?
			*set rationalism %-5

			Your seance with Mme. Laveau is something of a disappointment…it seems that she is unable to contact the late Clotho.  Laveau says that her spirit is not where it should be, and that disrupts her magics.

			*choice
				*selectable_if (feeding_style != "vegetarian") #I take the opportunity to feed from Marie Laveau.
					*set fed_from_laveau true
					*achieve fedonlaveau

					Well, sometimes practicality does trump sentimentality.  She does have a rather pleasant [i]terroir[/i] to her blood.
				#I want nothing more to do with this fraud!
					*set discretion %-5
					*set rationalism %-5
					You push the witch away from you, filled with despair over your lost love, and flee into the night.
				#I thank her for her efforts, though I despair for what it means.
					*set compassion %-5
					*set rationalism %+5
					What does it mean that her soul has been misplaced? 
					*if (religious_tradition != "pagan") and (rationalism > 60)
						Did you ruin her chances at eternal life?
					
					Perhaps you will find answers in time.
	#What do I care about this Marie Laveau?
		*set compassion %+5
		*set anachronism %-5

		Spoken like a true ancient.
*page_break
*if new_orleans_enterprise = 7
	Thanks in no small part to your involvement, Charity Hospital relocates in 1832 to Common Street in the Faubourg St. Marie. The new facility contains hundreds of beds and could be the largest charity hospital in the country. Two years after that, the Sisters of Charity—an order of Catholic nuns—agree to take on the administration and management of the hospital. Under their care, the hospital becomes a beacon of civic spirit.

In February of 1835, news of the attempted assassination of President Jackson races through the young nation.  It seems that a deranged housepainter drew not one but two pistols, aimed, and fired them at President Jackson.  Luckily for Jackson, it is reported that both of the pistols misfired.  Not to be outdone, the enraged Jackson dropped the assassin to the ground with a few quick strikes of his cane before David Crockett subdued him more systematically.
*comment The attack on Jackson is a response by an elder to Jackson's attack on the National Bank.  By breaking the Second National Bank, he seriously damaged that elder's international financial resources.  This was intentional on Jackson's part, as he was seeking to relieve the Federal Government of this elder's influence.  Jackson was, in fact, struck by both bullets, but he was able to shrug off the wounds thanks to his residual vampiric powers.

*if (shepherd_credentials > 45) and literate
	You read in the newspapers that during his interrogation, the attacker, a man by the name of Richard Lawrence, claims that he is, in fact, Richard III, the long-deceased monarch of England, and that Jackson is his disobedient clerk.
	
	Lawrence is deemed insane and institutionalized for the rest of his life.

*if (knows_creole_stakes = false) and (((background = 3) or ((background = 5) or ((background = 11) or (background = 12)))) or (local_fame > 45))
	*if attended_marignys_party
		M. de Marigny continues to be the toast of New-Orleans society.
	*else
		Due to your stature in the city, you have made the acquaintance of Bernard de Marigny, a local landowner and gambler. In the New-Orleans social scene, he is a hard figure to avoid.
	While attending one of his salons, you overhear it said that Marigny has taken it upon himself to develop the horse breeding industry in Louisiana. To this end, he intends to organize a horse race for horses born, bred, and owned in Louisiana.
	
	The matter is being disclosed now, so that those interested in participating can set about studding some foals. Marigny has already acquired land along the Bayou Saint-Jean, with the intention of drawing out the course in the near future.
	*if (love_clotho and male) and (background > 2)
		
		At the mention of the Bayou Saint-Jean, the thought of your picque-nicque on the bank of the bayou floods back. You excuse yourself from the salon.
	*else
		The room is atwitter with speculation around who will make the necessary investments to participate.		
*page_break
*temp forced_out false

*if jesse_is_broodmate
	*if learn_of_masons and (male and (new_orleans_quaestor_rapport > 60))
		As the 1830s wear on, ${new_orleans_quaestor_surname} begins to hint to you—bit by bit—about the possibility of a Masonic Order existing within the Society itself; something related but somehow distinct from the Order to which mortals belong.

		Finally, he seems no longer able to contain himself.

		"Dear ${given_name}, I can hide my secrets from you no longer.  Will you join with me in the Masonic brotherhood?"
		*choice
			*if (religious_tradition = "reformed") and ((ethnicity != "african") and (ethnicity != "choctaw"))
				#"Of course!"
					*gosub masonic_introduction	
			*if religious_tradition = "catholic"
				#"But, I thought the Masons refused to admit Catholics to their Order?"
					"We do not refuse their admittance.  Rather, the Holy Father thinks we seek to undermine him.  But that is not true!  We only wish to free mankind from the shackles of ignorance."

					"I see," you reply, still considering his offer.

					"What say you, then?"
					*gosub masonic_decision
			*if religious_tradition = "pagan"
				#"The Freemasons would welcome a keeper of the old ways into their midst?"
					${new_orleans_quaestor_surname} casts his eyes about the room before answering.  "The Order demands the recognition of a higher power and the immortality of the soul.  That said, we Masons do not claim a greater knowledge of the nature of that higher power than other men."

					"That is generous of you."

					"What say you, then?"
					*choice
						#"I will join."
							*set rationalism %+5
							*set new_orleans_quaestor_rapport %+10
							*gosub masonic_introduction
						#"I cannot join this Order."
							*set new_orleans_quaestor_rapport %-40
							The air in the room, already cool, turns downright chilly.  ${new_orleans_quaestor_surname}'s disappointment is palpable.  "Then I suppose we have nothing more to discuss."

							Nodding, you take your leave.
							*if lore > 2
								As you return to your haven, you wonder whether ${new_orleans_quaestor_surname}'s disappointment was the result of your rejection, or whether he is concerned that you may betray his confidence to someone in the Society.  Though not positive, you suspect that membership in such an organization is frowned upon.
							*gosub masonic_withdrawal
			*if (ethnicity = "african") or (ethnicity = "choctaw")
				#"I did not realize that the Masons accepted my people into their ranks."
					"We seek to free all men from the bondage of ignorance.  The color of your skin matters little to the mortals and less to the vampires."

					"That is generous of them."
			
					"What say you, then?"
					*gosub masonic_decision
			#"You are generous to make such an offer, but I must decline."
				*set new_orleans_quaestor_rapport %-20
				The air in the room, already cool, turns downright chilly.  ${new_orleans_quaestor_surname}'s disappointment is palpable.  "Then I suppose we have nothing more to discuss."

				Nodding, you take your leave.
	*elseif compassion < 40
		As the 1830s wear on, you become disillusioned with the politics of Jesse and your maker.  The pleasure they take in watching new arrivals flounder on the social scene turns your stomach.  In time, it becomes clear to you that this is not the city for you.  Perhaps in other cities, the vampires are not quite so unkind to each other.
		*if sirethoughthewasagod
		
			Moreover, his position as quaestor confirmed by the governor, ${new_orleans_quaestor_surname}'s delusions of divinity begin to show themselves more clearly.  It seems that he has begun to encourage mortals to gather in his name, an activity that certainly skirts the edge of the Rule of Reserve.
	*else
		*if new_orleans_quaestor_rapport < 40
			*set forced_out true
			*if jesse_rapport < 60
				*set new_orleans_quaestor_rapport %-10
				As the 1830s wear on, your maker comes to view you with suspicion and distaste.  Through ways both subtle and overt, he makes it clear to you that it is time for you to move on and find your own path.  When he looks at you, all he sees are the ways in which you have failed him.  There is little to prevent you from assuming that it is Jesse's waxing influence that encourages the mounting animosity between you and ${new_orleans_quaestor_surname}.
			*else
				*set new_orleans_quaestor_rapport %-10
				As the 1830s wear on, your maker comes to view you with suspicion and distaste.  Through ways both subtle and overt, he makes it clear to you that it is time for you to move on and find your own path.  When he looks at you, all he sees are the ways in which you have failed him.
		*else	
			*if independence >= 40
				As the 1830s wear on, you see your star rising in the heavens of the Society.  Under the smug gaze of your maker, you successfully navigate the snake-pit of politics that is the court of New-Orleans.  In time, however, your ambition gets the better of you, and you decide that you must find a new city to hone your political instincts.
			*else
				The 1830s turn slowly towards the 1840s.  Though you are on good terms with your maker, your aversion to the politics of your kind makes you something of a familiar stranger.  The thought that maybe you should find a new home, away from such viciousness, slowly gains currency with you.
		*if sirethoughthewasagod
		
			Moreover, his position as quaestor confirmed by the governor, ${new_orleans_quaestor_surname}'s delusions of divinity begin to show themselves more clearly.  It seems that he has begun to encourage mortals to gather in his name, an activity that certainly skirts the edge of the Rule of Reserve.

	*if jesse_rapport >= 60
		Jesse is distraught to hear that you are leaving.  He does the closest thing that he can to begging for you not to go, but you are resolute in your decision.
		
		"We shall see each other again soon, I am sure," he says instead of a farewell.  This thought is pleasing to you…perhaps a few decades will see some of his rougher edges rounded down?
	*elseif (jesse_rapport >= 40) and (withers_embarrassed)
		Jesse's response to the news of your departure is muted.  The two of you have not always seen eye to eye, but you have garnered a certain favor in his eyes.
	
		"We shall see each other again soon, I am sure," he says instead of a farewell.  You are unsure if that is a hope or a fear on Jesse's part.
	*else
		Jesse greets the news of your departure with an ill-disguised glee.  Your appearance during his extended spat with ${new_orleans_quaestor_surname} was always something of a thorn in his side, after all.
*elseif withers_embarrassed
	Despite Jesse's triumph, 
	*if ((story_of_jesse_in_haiti = false) and (sire_name = "West")) and ((patricide = false) and (fled_from_sire = false))
		he still
	*else
		he still sees himself as being on poor footing among the citizenry of New-Orleans. In light of his previous conflict with ${new_orleans_quaestor_surname}, he 
	seems desperate to prove his loyalty and indispensability.  His frequent machinations, executed on a scale that is impressive—even difficult to grasp for one as young as yourself—end up leaving you socially isolated.  As the years pass, it becomes increasingly clear to you that you ought to find a city less fraught with outright hostility.  If such a thing exists in the Society.
*elseif lied_to_jesse_about_poem
	Despite Jesse's circumspect inquiries into the source of his betrayal, your lie remains undiscovered.  Unfortunately, whether from a basic jealousy of your existence or a general paranoia, he cannot leave you unmolested.  His machinations, executed on a scale that is impressive—even difficult to grasp for one as young as yourself—end up leaving you socially isolated.  As the years pass, it becomes increasingly clear to you that you ought to find a city less fraught with outright hostility.  If such a thing exists in the Society.
*else
	*set jesse_rapport %-10
	The rest of the decade sees Jesse ardently endeavoring to make your unlife miserable.  His embarrassment at Samantha's hands has driven him nearly mad, and you are constantly put into situations that are untenable.  In time, you realize that you will soon end up attempting to break Jesse's neck (and probably failing) if you do not make a graceful exit for yourself in the near term.
*comment TODO add Estefania's reaction to player's departure
*page_break
*if heresy_of_abraham > 0
	With a minimum of fanfare, you bid your [i]adieu[/i] to ${new_orleans_quaestor_surname} and Estefania.

	On your way out of ${new_orleans_quaestor_surname}'s home, however, Estefania corners you.  "There is still so much for you to learn!"

	"Perhaps, but it is time for me to go."

	"Here, let me show you…this is how you will find others who know the truth," she says, making a gesture you will have to practice many times before it will seem effortless.  "In their care, you may progress further in your understanding of our condition."

	"Thank you, dear Estefania.  Until next we meet."

	"Until then, dear ${given_name}."
	*page_break
	You practice the secret sign as you return to your haven, hoping that some night or other it will guide you into the inner circle of the Society.
*elseif rios_rapport > 55
	With a minimum of fanfare, you bid your [i]adieu[/i] to Estefania and ${new_orleans_quaestor_surname}, telling them that the time has come to explore the other courts of the Society. Rios expresses some dismay over your departure, and elicits a promise that you will write to her to tell her of your adventures. She kisses both of your cheeks and proclaims that she already misses you.
*else
	With a minimum of fanfare, you bid your [i]adieu[/i] to Estefania and ${new_orleans_quaestor_surname}, telling them that the time has come to explore the other courts of the Society.  They are polite about the news.

	Though your relationship has been ambivalent at best, your heart heaves a special sigh of sorrow with the decision to leave this city of mystery on the Mississippi.

	But no matter.

A few nights later, you take one last turn in @{(anachronism > 75) Jackson Square|the Place d'Armes} with ${new_orleans_quaestor_surname}, discussing your time in the city.
*if sire_surname = new_orleans_quaestor_surname
	*if forced_out
		He soon informs you that he is formally releasing you from his supervision. @{embrace_of_affection It is a hard bit of news to swallow. You remember very clearly when things between you were not so cold and distant.|} You are now free to seek your own fortune in the world—whether you like it or not.
	*else
		Bending to your wishes, @{embrace_of_affection and with some reluctance, |}${sire_surname} formally releases you from his supervision, freeing you to seek your own fortune in the world. The prospect of leaving your dominus is terrifying, but you know that it is the right choice.
*else
	He takes great pride in what he has taught you over the past decade, giving you ample opportunities to compliment him.
	
	*choice
		#Yes, yes, I compliment him profusely.
			*set independence %+10
			*set discretion %-5
			*set new_orleans_quaestor_rapport %+5
			He beams under your praise.
		#I do not respond to his prompts.
			*set independence %-10
			*set discretion %+10
			*set new_orleans_quaestor_rapport %-5
			The tenor of the conversation changes notably after you rebuff him a third time.
		#I answer perfunctorily.
			*set discretion %+5
			*set independence %+5
			He scowls at your reticence, but acknowledges the motions that you put yourself through.
	
*if exposure > 4
	During the course of your perambulation, you note that several people scowl in your direction. Some spit as you walk by, while others make the sign of the cross or ward themselves against the evil eye.
	
	Observing this, ${new_orleans_quaestor_surname} speaks: "It seems you have attracted some attention to yourself, ${given_name}. Perhaps it is for the best that you are leaving."
	
	"Attracted attention?"
	
	"They know that you are not one of them. They may not have proof, but clearly there are rumors. You are known. Better to flee before they gather the courage to challenge you outright."
	
	A final lesson, you surmise.
Finally, you say good-day and goodbye.	

With firm resolve, you book tickets on a steamer and head up the Mississippi.
*page_break
*goto_scene timejump1

*label money_to_stat
Having assembled some modicum of wealth, the thought occurs to you that you should do something with it.
*if (nola_duel_status = 2) and (creation < 3)
	Unfortunately, your refusal to duel still haunts you, and limits your access to certain artistic circles within the city.
*choice
	*if creation < 3
		*selectable_if (nola_duel_status != 2) #I intend to patronize the arts.
			*set creation +1
			*set anachronism %+10
			*set wealth -40000
			*set wealth +(finance * 2000)
			*set new_orleans_enterprise 5
			*set shepherd_credentials %+15
			Soon, poets, painters, and musicians are flocking to New-Orleans, drawn by the magnificent support being offered to their endeavors.  Amidst this creative explosion, you eagerly absorb new styles and methods of artistry.
	*if (intelligence < 2) and literate
		#I want to assemble a library so that I may educate myself in the great works of theology and philosophy.
			*set intelligence +1
			*set rationalism %+10
			*set anachronism %-10
			*set wealth -40000
			*set wealth +(finance * 2000)
			*set new_orleans_enterprise 1
			*set shepherd_credentials %-10
			It takes months and even years to make sufficient contacts to assemble a respectable library, but soon enough you are consuming the texts avidly.
	*if (streetwise < 3) and (charm > 1)
		#Criminal enterprises have always appealed to me…I will finance brothels, gambling-dens, pirates, and smugglers!
			*set streetwise +1
			*set compassion %+15
			*set discretion %+10
			*set new_orleans_enterprise 2
			*set wealth -40000
			*set wealth +(finance * 2000)
			*set shepherd_credentials %-10
			You begin to spread your money around the already seedy underbelly of New-Orleans.  Soon, the city is even more of a cesspool than it was before.
	*if technology < 2
		#I want to see about bringing some of the latest inventions to New-Orleans.
			*set technology +1
			*set wealth -40000
			*set wealth +(finance * 2000)
			*set anachronism %+10
			*set rationalism %-20
			*set shepherd_credentials %+15
			*set new_orleans_enterprise 3
			In fact, the wonders of 'gas'—a method of illumination that does not require wax—have just been demonstrated at Peale's Museum in Baltimore.  You establish a corporation to bring this marvel to New-Orleans.
	*if (ethnicity = "german") and ((anachronism > 65) and ((strength = 2) or (agility = 2)))
		#I want to fund the establishment of a [i]turnverein,[/i] a gymnastics club with pan-Germanic political overtones.
			*set new_orleans_enterprise 4
			*set wealth -40000
			*set wealth +(finance * 2000)
			*set anachronism %+10
			*set shepherd_credentials %+15
			The German immigrants of New-Orleans are grateful for the club, and it soon becomes a center of cultural life in the city.
			*if agility = 2
				*set agility +1
				You even take some time practicing their programme and find yourself becoming more agile with the exercises.
			*else
				*set strength +1
				You even take some time practicing their programme and find yourself becoming stronger with the exercises.
	*if (compassion < 75) and (finance < 2)
		#[i]L'Hôpital des Pauvres de la Charité[/i] has suffered since its facilities burned to the ground in 1809. It could use a steady hand.
			*set new_orleans_enterprise 7
			*set wealth -40000
			*set discretion %+5
			*set local_fame %+10
			*set anachronism %+5
			*set finance +1
			Charity Hospital, as it will later be known, was founded in 1736 by a shipbuilder who willed his estate to the enterprise. Unfortunately, almost one hundred years have passed since then, and the coffers have been emptied. The city and the state of Louisiana do make some effort to support the institution, but it has become chronically underfunded. Your donation and involvement go a long way to helping the institution right its finances. Moreover, through your involvement you @{finance learn something about accounting and the use of capital.|improve your understanding of financing structures and investments.}
*return

*label frankenstein

"Have you read [i]Frankenstein[/i] yet?"

"I can't say that I have."

"It's simply terrifying!" the woman, Mlle. Leclerc, continues.

"She means ridiculous," M. Courtland interjects.

You are in the home of Mme. Barras. She welcomes some of the educated members of the city to discuss the news of the day in her salons. Everyone drinks too much. @{(feeding_style = "socialites") Sometimes you take a nip from one of the other guests.|} You have become a regular of late. @{((background <= 2) or (ethnicity = "choctaw")) They consider themselves enlightened and see your heritage as something to lord over their friends. [i]"You'll never believe the savage that joins our salons! And somehow, ${he} even manages to hold ${his} own in our debates!"[/i]|} @{(background = 3) They consider themselves as enlightened for deigning to associate with you. It's not a topic that is discussed, but that's because it doesn't need to be: in their opinion, you will never—could never—be their peer.|}

"What is it about?" you inquire.

"A doctor creates a new man from the assembled parts of various cadavers, using electricity to invigorate the entity," Mlle. Leclerc offers.

"A ghastly proposition," M. Courtland says. "You should not…"

"Here, borrow mine!" Mlle. Leclerc interjects, pressing it into your hands. "Have you thought much about what it actually means to die?"

You purse your lips. Of course you have.

*fake_choice
	#"Yes, why do you ask?"
		*set discretion %+5
	#"No, I can't say that I have."
		*set discretion %-5
	#"What madness are you speaking?"

"Could it be that when we die, we are not entirely dead? That we can live on afterwards?" Mlle. Leclerc erupts, her eyes glistening.

"No, dead is dead," M. Courtland retorts.

"But what about Mme. Choquet?"

"You always bring up Mme. Choquet!" M. Courtland replies peevishly.

"She was about to be interred in her family mausoleum when she woke up! She had been pronounced dead three days before! Tell me why I should not bring her up?" Mlle. Leclerc retorts.

"The coroner made a mistake."

"Did he?"

With that, you find the opportunity to put forth your own opinion.

*choice
	#"The barrier between life and the afterlife is more permeable than you realize, M. Courtland."
		*set rationalism %+5
		*if rationalism > 60
			*if religious_tradition = "catholic"
				"The souls of the dead pass on to Purgatory and to Hell, and some to Heaven. It is promised that the resurrection will occur with the Rapture. If Our Father has promised this, why is it so hard to believe it? And with the workings of demons, could the heavenly machinery not sometimes be disrupted?" you continue.
				
				"Are you saying that demons, in their infernal ingenuity, manage to evade God's plan and restore some men and women to life?"
				
				"Is it so preposterous to you? What of this Mme. Choquet?"
				
				M. Courtland chews his lip.
			*elseif religious_tradition = "reformed"
				"God Almighty promises the faithful resurrection. Therefore, the passage between the afterlife and the living exists. If it exists, then it can be found and exploited."
				
				"You plan to appropriate divine powers for yourself?"
				
				"I have no such plans, M. Courtland. I merely assert that the pathways exist, and that soon, the enterprising will learn to utilize them."
				
				The room goes silent at this idea.
			*else
				"I know little of your god and his words, but my people have always known that sometimes the dead endure."
				
				"Oh, tell us more!" exclaims Mlle. Leclerc.
				
				Whatever you might have shared has now become an object of exotic fascination for this woman. "I cannot. But I know it to be true."
				
				M. Courtland scoffs.
		*else
			"How so?" he replies.
			
			"Take it from me. I have died once, yet you see me here before you."
			
			"You do have the most awful pallor, ${mr} ${surname}," Mlle. Leclerc observes with a nervous laugh.
			
			"Perhaps Mrs. Shelley has had a similar experience. I can't say for certain. But those that die—both those like myself and those like Mme. Choquet—can rise again."
	*if (love_clotho) #"My love is dead. I can only pray that some day I will discover how to make contact with her."
		*set rationalism %+5
		"Your love?" Mlle. Leclerc inquires. "What happened?" She is clearly @{priest scandalized by the implications of a priest being in love|taken by the romance of the matter}.
		
		"The details are unimportant. But I intend to see her again some day, by whatever means are necessary."
		
		"You would create a body for her to inhabit? Stealing parts from a graveyard and stitching them together?"
		
		"If necessary, I would."
		
		*if priest
			"Isn't that…sacrilegious?" she presses, enrapt.
			
			"If God did not wish it to happen, he would stop it."
			
			The room fills with Mlle. Leclerc's exclamations of delight. "Oh, how I enjoy your wit, ${mr} ${surname}! If only all priests were so forward-thinking!"
		*else
			*if male
				"Oh! I wish some man loved me the way that you love your dearly departed wife!" Mlle. Leclerc exclaims.
						
				"My wife…yes," you confirm. @{(rationalism < 60) These people think themselves modern, and yet they assume that any love must be enshrined in matrimony. How provincial of them!|}
				
				"Perhaps you will learn to listen, Mlle. Leclerc, and then some gentleman will have the opportunity to press his suit," M. Courtland replies dryly.
				
				Mlle. Leclerc scowls.
			*else
				"Come now, Mlle. Leclerc, ${mr} ${surname} would not do such a thing for a friend."
				
				"A friend?"
				
				"Yes, of course. Women cannot love women in the way that ${mr} ${surname} implies."
				
				"No, I suppose not…" Mlle. Leclerc replies, crestfallen.
				
				You roll your eyes. "Oh, yes, I must be mistaken, M. Courtland. Please, tell me more." Being a vampire doesn't save you from men trying to tell you that you're mistaken about yourself and the people that you love.
	#"Perhaps, as with M. Frankenstein, we will some day discover how to reanimate the dead."
		*set anachronism %+5
		"Would you create a new person whole-flesh, from the parts of the dead?" Mlle. Leclerc says, shuddering. "But who would they be? A combination of all the people whose parts were used? Or perhaps one soul would win out?"
		
		"I don't know. But some day, I am certain that we will find out." You refrain from pointing out that, though that may be several centuries in the future, you intend to still be walking the earth long enough to learn the answer to this question.
		
		The assembled guests collectively shudder at the thought.

"While the idea of creating a new person from the parts of the dead is quite fanciful, I do believe that some day we will learn how to reattach severed limbs, in much the way that Mrs. Shelley implies," says Dr. Desalle. A relatively new addition to the salon, he has gained the trust of Mme. Barras for his suggestions on how to improve her sleep.

"But why would we want to reattach limbs, Dr. Desalle? Most are severed because they are putrifying. Or they are mangled in war," M. Courtland reasons.

"True, but there are instances of limbs being detached [i]en toto[/i]. Think of a carpenter, applying himself with too much enthusiasm to his blessed vocation. We would not want such an individual to be lost to his calling, would we? Not if we could restore his limb and make him a productive member of society once again."

*if lore > 2
	"A Hugenot, M. Desalle?"
	
	"Why, yes, ${mr} ${surname}. Though I don't see why it matters."
	
	"No matter."
*if (lore <= 2) and (religious_tradition = "reformed")
	He certainly argues like a Calvinist. What sort of Frenchman espouses Calvinism, you wonder.

"All the same, if a severed body part can be restored to life, why not a body entire? And if that is possible, what does it tell us about the nature of the soul?"

You wonder if this is a dangerous line of thought for a gathering of humans to be pursuing.

*fake_choice
	#Let them have their idle curiosity. They will not happen by chance upon the existence of our kind. I suggest @{(creation > intelligence) that I perform something on the pianoforte|a parlor game} to change the subject.
		*set discretion %-5
		Mlle. Leclerc claps at your suggestion. "Yes, let's!"
		
		Dr. Desalle is less pleased with your theft of the spotlight, but does not issue a complaint.
	#"Do not traffic with the spirits of the dead if you care for your immortal soul."
		*set rationalism %+5
		The room seems to take you at your word. The seriousness of your voice and the lightning in your eyes disperses any argument.
	*if (rationalism < 50) #"It tells us that the soul is a fiction."
		This elicits a gasp from the room.
		
		You do your best to defend your claim over the next hour or so, but you find refuting Bible quotes to be difficult. Or, at least, those that believe in the Bible are unwilling to let you dismiss its assertions as primitive superstition.

The rest of the evening passes in much the same manner as before. You do your best to enjoy yourself.
*return

*label masonic_decision
*choice
	#"I will join."
		*set rationalism %+5
		*set new_orleans_quaestor_rapport %+10
		*gosub masonic_introduction
	*if rationalism < 45
		*selectable_if (discretion > 40) #"It does not truly matter, as I do not believe in God anyway.  But yes, I will join."
			*set rationalism %-20
			*if sires_faith = "atheist"
				*gosub masonic_introduction
			*else
				*set new_orleans_quaestor_rapport %-20
				"Unfortunately, I must withdraw my offer, then."

				"I'm sorry?"

				"We Masons celebrate the immortality of the soul and the power of God Almighty.  If you do not believe in the same, you would not be welcome among us."

				"I am sorry to hear that."

				"As am I."  As you depart, you detect a distinct change in his attitude towards you.  Gone are the easy smiles, replaced with something more threatening.

				*if lore > 2
					During the walk home, you wonder whether ${new_orleans_quaestor_surname}'s disappointment was the result of your declaration, or whether he is concerned that you may betray his confidence to someone in the Society.  Though not positive, you suspect that membership in such an organization is frowned upon.
				*page_break
				*gosub masonic_withdrawal
	#"I cannot join this Order."
		*set rationalism %+15
		*set new_orleans_quaestor_rapport %-40
		*set rejected_masons true
		The air in the room, already cool, turns downright chilly.  ${new_orleans_quaestor_surname}'s disappointment is palpable.  "Then I suppose we have nothing more to discuss."

		Nodding, you take your leave.
		*if lore > 2
			As you return to your haven, you wonder whether ${new_orleans_quaestor_surname}'s disappointment was the result of your rejection, or whether he is concerned that you may betray his confidence to someone in the Society.  Though not positive, you suspect that membership in such an organization is frowned upon.
		*gosub masonic_withdrawal
*return

*label masonic_introduction
*set heresy_of_masons +1
*set heretic true
*achieve mason
${new_orleans_quaestor_surname} smiles broadly.  "I'm so glad to hear that."  Drawing a cord and a cloth from somewhere, he continues, "Normally, we would need a host to welcome you into the Order, but our numbers are few.  Here, let me tie these around you."  Taking the cord, he ties it around your midriff three times and uses the cloth to cover your eyes.  Thus secured, he takes your hand, and leads you to a door.  He raps upon the door three times, and then opens it, escorting you inside.

And so begins the initiation of his favorite pupil into the first degree of these mysteries.
*page_break
*if lore < 3
	*set lore +1
The next few months continues your education into the ways of the Order.  He does little to differentiate between those belonging to the mortal organization and those belonging to the vampiric one.  Sometimes you wonder how much of a division there really is.
*page_break
Once these early lessons are complete, however, ${new_orleans_quaestor_surname} announces that it is time for you to go out into the world, to see out opportunities to serve the Order.  He leaves no room for argument, and so you begin organizing for your departure.
*return

*label masonic_withdrawal
*page_break
It is clear that you are no longer welcome in New-Orleans after that night.  Before long, it occurs to you that you are free to leave this city, and once imagined, everything else seems untenable.
*return

*label describe_visitors
*if (perception > 0) and ((intelligence > 2) or (creation > 0))
	Tiozzo wears a high-waisted white dress with a low neckline and a nearly vertical silhouette, complemented by a yellow and crimson shawl. The style was the height of French fashion twenty years ago. Draper, on the other hand, wears a pair of breeches, waistcoat, and overcoat, all in the same olive green. His white stockings, shirt, and cravat contrast smartly with the green; he would have been the talk of the town forty years ago.
*else
	Tiozzo wears a white dress and sports a yellow and crimson shawl, while Draper wears an olive outfit with white accents.
*return

*label perform_for_tiozzo
*set who_performed 1
You sit at the pianoforte. After a moment of silent contemplation, 
*if creation > 2
	*set tiozzo_rapport %+20
	*set new_orleans_quaestor_rapport %+5
	*set rios_rapport %-10
	*set dazzled_tiozzo true
	you launch into Chopin's [i]Rondo à la mazur[/i].
	
	When you are finished, the room is speechless. For a moment, you fear that ${new_orleans_quaestor_surname} is going to castigate you, but Tiozzo begins frantically clapping her hands before any such nonsense.
	
	"What piece is that? Who composed it! You must tell me how you came by it. Is it native to these shores…?"
	
	You find yourself drawn into conversation with the visitor.
	*if heard_of_tiozzo = false
		*set heard_of_tiozzo true
		It soon comes to light that Tiozzo is herself a painter. She studied in Venice under Titian, though she herself is from the Dalmatian city of Fiume.
*elseif creation = 2
	*set tiozzo_rapport %+10
	*set new_orleans_quaestor_rapport %+5
	you launch into Cipriani Potter's Sonata in E minor. You performance is as expected—talented, but not extraordinary.
	
	When you are finished, the room applauds you. Afterwards, you play a waltz, whereupon Tiozzo and Draper, ${new_orleans_quaestor_surname} and Rios, stand and dance.
*else
	*set disappointed_tiozzo true
	*set tiozzo_rapport %-25
	*set new_orleans_quaestor_rapport %-20
	*set draper_rapport %-10
	*set jesse_rapport %-10
	*set rios_rapport %-15
	you launch into Mozart's Sonata in C minor. When you hit the first wrong note, you press on. When you hit the second, you realize that you are in trouble.
	
	You do the best you can, but your best is not good enough. When you finish, the silence is telling.
	
	Into the breach, Jesse jumps with an anecdote about his time in the Caribbean. The rest of the vampires quickly move to more pleasant subjects than the embarrassment that you just suffered.
*return

*label rios_performs_tiozzo
*set who_performed 2
Rios sits at the pianoforte. She has grown accustomed to the dynamics of this instrument, and so does not pause to test it. Instead, she launches into
*if creation > 1
	Beethoven's 30th Sonata in E.
*elseif creation > 0
	a sonata which you suspect is by Beethoven.
*else
	a piece which you do not recognize.

When she is finished, Tiozzo and Draper both applaud appreciatively. Rios then launches into a waltz. Tiozzo and Draper stand and dance.
*if (embrace_of_affection and sire_alive) and (sire_name != "West")
	*set new_orleans_quaestor_rapport %+10
	${new_orleans_quaestor_surname} extends his hand, which you accept, and the two of you dance as well.
	
	It's strange. He does not touch you like this—intimately—very often anymore. For a moment, you remember what it was like when he fed from you on an almost nightly basis.

When Rios finishes, everyone applauds again—before returning to their intrigues.
*return

*label offer_debt_to_estefania
You consider the matter: Rios is a creature of the Society. If you were to offer her a debt, she might allow you to sit for Tiozzo in her place.

*choice
	#I offer her a debt.
		*set painted 3
		*set debt_to_rios true
		*set independence %+20
		*set rios_rapport %-10
		Rios is loathe to accept the debt, but finds it impossible to turn it down. She accepts your offer and shares the address for the sitting with you.
	#I have no interest in indebting myself to Rios.
		*set independence %-10
		Remaining free of entanglements with the other vampires; a wise choice.
	#I would not want to take this opportunity from her.
		*set compassion %-5
		That is a generous position for you to adopt.
*return