*comment ñáéç…—
*set year 1884
*hide_reuse
*advertisement
*temp with_eliot false
*temp with_becard false
*temp beneficent false
*temp seen_elephants false
*temp pickpocket_encounter false
*temp pickpocket_unnoticed false
*temp circus_time 0
*temp messy_murder false
*temp dead_electrician 1
*gosub_scene util combat_value
*temp will_test 0
*rand will_test 1 2
*if watching_james
	*comment 1884-05-06
	The newspapers carry word that Charles Ford—one of Jesse James's two assassins—has committed suicide via morphine. They report that he was suffering from tuberculosis, and sought to end the suffering.
	*if stlouis_enterprise = 1
		Your sources in the world of journalism, however, note that Ford did not have tuberculosis, and that his suicide note was filled with descriptions of blood and horrors.
		*if carothers_ford_reveal
			@{(compassion < 50) You shudder at the thought of what Carothers must have done to him to get him to betray his best friend.|Carothers must have used extreme methods to bend Ford to his will.}
		*if carothers_ford_reveal = false
			Could one of your kind be behind his death?
	
	Charlie's brother, Robert, sees his brother in the ground and then departs Missouri. He says he wants to put his past behind him. Fame will not leave him alone, however, and the newspapers continue to report on his doings—becoming a saloon-keeper in Nevada—despite any velleity to privacy.
	*page_break
*if lied_to_carothers_about_pb = 3
	*temp tick false
	*set aichinger_rapport %-10
	*set bailey_rapport %-20
	*set becard_rapport %-5
	*comment Becard is mostly disapproving of the fact that you got caught.
	*set eliot_rapport %+5
	*comment Eliot appreciates your gesture of compassion.
	*set memeskia_rapport %-10
	*if maddox_num < 3
		*set withers_rapport %-20
	To your great shame, one night at Schnaider's, Bailey informs the room that your deceit has been uncovered; you reported to Quaestor Carothers that you slew ${wilson} ${maddox}, but did not.
	
	*if debt_from_carothers
		*set tick true
		*set debt_from_carothers false
		The debt that you held over Carothers has been absolved.
	*elseif carothers_debt_wilson = 3
		*set tick true
		*set debt_to_carothers true
		The debt that you owed to Carothers has been reinstated.
	*if status > 0
		*set status -1
		@{tick Moreover, your|Your} reputation has been severely tarnished by this scandal.
		*if status = 0
			You now formally exist at the edge of the Society, without the wholesale assurances of its protection.
	
	*page_break
*if (stl_electricity > 5) or ((stlouis_enterprise = 1) or (technology > 0))
	*temp the_haven stlouis_haven
	*if stlouis_haven = "kerry"
		*set the_haven "Kerry Patch"
	*if stlouis_haven = "chestnut"
		*set the_haven "Chestnut Valley"
	*if stlouis_haven = "east"
		*set the_haven "East St. Louis"
	*if stlouis_haven = "lafayette"
		*set the_haven "Lafayette Square"
	*set dead_electrician 3
	As efficient and magical as electricity is, it is not entirely safe.
	
	Individuals are hired to string wires to carry current from building to building and block to block. The training of these individuals is, at best, mixed; as with nearly all capitalist enterprises, the safety of the workers is regularly traded for a marginal cost-saving.
	
	And so, one evening, you watch as a lineman reaches out to connect two wires, to thereby illuminate yet another block of @{(stlouis_haven = "kerry") the|} $!{the_haven}. When the lineman touches the second wire, however, a jolt of electricity goes through him. You realize that, if you do nothing, this man will die a horrible death.
	*temp still_alive false
	
	*choice
		*selectable_if (technology > 1) #I can see how to cut the power.
			*set still_alive true
			You have studied enough of the functioning of electricity that with but a glance you can guess how you might break the circuit. Moving expeditiously, you cut the line, and the lineman drops to the ground, shivering and jumping from the after-effects.
		#@{(agility > 3) |I hope that }I'm fast enough to pull him down without being harmed myself.
			*if agility > 3
				*set exposure +1
				*set still_alive true
				There are exclamations of surprise by the other onlookers as you dash forward in a blur, yanking the lineman away from the deadly currently. He falls to the ground, jerking and shivering from the after-effects of the current while the crowd gasp in dismay.
			*elseif strength > 3
				*set exposure +1
				*set still_alive true
				You rush forward and put your hands on the worker, but instantly realize your mistake: now you too are conducting the current. Thankfully, while your hair and clothes begin to smoke, your immense fortitude allows you to push through the pain and wrench the worker down. He falls to the ground, jerking and shivering from the after-effects of the current, while the crowd gasps in dismay.
			*else
				You rush forward and put your hands on the worker, but instantly realize your mistake: now you too are conducting the current. Suddenly, you realize that you cannot let go. Before you quite realize what is happening, you hear an explosion and find yourself on the ground beside the smoking body of the worker. The veins in your arms are blackened as though it were the blood that conducted the electricity through your body. Your hair and clothes smoke and smoulder while a crowd gathers to gawk.
				
				You stumble to your feet and flee before anyone can try to feel for your pulse.
		#Anything that I do would be a danger to the Rule of Reserve. I simply watch.
			*set independence %+5
			A sickening smell fills the air. Tongues of blue fire and arcs of electricity surround the man until another worker appears an hour later to cut the power and pull the body down.
		#Why would I do anything? This man knew the risks when he accepted the job.
			*set shepherd_credentials %-5
			*set laborvscapital %-15
			*set compassion %+10
			*set discretion %+5
			A sickening smell fills the air. Tongues of blue fire and arcs of electricity surround the man until another worker appears an hour later to cut the power and pull the body down.
		
	*if still_alive
		*set local_fame %+5
		*set compassion %-5
		
		The man's heart has stopped.
		
		*choice
			*if (intelligence > 3) #You have read that pressing on an individual's abdomen and alternately pushing air into his lungs may sometimes resuscitate him.
				*set local_fame %+10
				*set compassion %-5
				*set dead_electrician 2
				Calling for assistance, you press on the lineman's chest while an onlooker intermittently pushes air into his lungs.
				
				After several agonizing moments, the lineman's eyes flutter open and the crowd bursts into applause.
			#I knick my wrist with my fang and give him a bit of blood. Hopefully he is not so far gone that it will turn him into a vampire, and it will simply help him heal whatever damage has been done.
				*set discretion %+5
				*set dead_electrician 2
				The sudden appearance of blood around the lineman's mouth will go unremarked; the onlookers do not have a good enough understanding of what just happened to give any thought to the presence of blood.
				
				Several moments later, the lineman's eyes flutter open and, to your relief, he commences breathing. The crowd bursts into applause.
			*selectable_if ((technology > 1) and (intelligence > 2)) #As strange as it sounds, I think another jolt of electricity will restart this man's heart.
				*set local_fame %+10
				*set compassion %-5
				*set dead_electrician 2
				Absent your intervention, the man is dead. The fact that you have little to no control over the voltage and current here—and the absurd odds which you face in your task—matters little.
				
				Grabbing the wires, you touch them to the unconscious man. His body jerks—the crowd screams—but nothing happens.
				
				Again.
				
				The third time, his eyes flutter open and he gasps for air. The crowd bursts into applause.
			#No, I have done enough. The man was dead the moment he touched the wires; I have simply prevented a spectacle.
				*set still_alive false
				*set discretion %-5
				The onlookers gather to gawk at the body. Eventually, other linemen come and cart the body away.
	
	*if still_alive = false
		In the aftermath of the accident, there is a brief period of debate within the city about the relative costs of electrification.
		
		*fake_choice
			*if (stlouis_enterprise = 1) 
				#I urge the journalists to describe this as a terrible accident—but not something to be taken as a regular occurrence.
					*set stl_electricity +1
				#I urge the journalists to question the corporations that are driving these dangerous conditions.
					*set laborvscapital %+5
				#I urge the journalists to openly question the expansion of such an unsafe, new technology.
					*set stl_electricity -1
			*if (stlouis_enterprise = 7)
				#I encourage the spiritualists and mediums of St. Louis to extol the virtues of and expound upon the potentialities of electricity.
					*set rationalism %+10
					*set stl_electricity +1
					Numerous séances are held throughout the city, where the dead lineman gives his blessing to the citizens of the city to continue their pursuit of hidden truths.
			*if (stlouis_enterprise = 8)
				#I urge the men of science of Washington University to calmly explain what happened to the citizenry.
					*set stl_electricity +1
					*set rationalism %-5
			#What can I do? The people will think what they want to think.
		
*if stl_electricity < 5
	
	Though you have done what you can to obstruct the progress of the electrification of the city, the city council intends to bring an ordinance to vote that would allow the creation of any number of new electricity works.
	
	*choice
		#One cannot fight the future.
			*set anachronism %+5
			*set discretion %-5
			*set stl_electricity +1
		#This cannot be allowed to pass! I do everything in my power to stymie its progress.
			*set anachronism %-5
			*set stlouis_business_climate %-5
			*if (charm > 3) or (local_fame > 45)
				*set stl_electricity -1
			
	*if stl_electricity < 5
		The business elites of the city are astounded at the failure of the ordinance to pass. They wonder at the resistence to modernity. In response, they begin reorganizing to better extend the reach of the Laclede Gasworks.
		
	*else
		One of the primary changes to the city as a result of these electricity works is the consumption of coal. Soon, smokestacks tower over the city, seeking to thrust the fumes into the air.
	
		*if perception > 3
			Unfortunately, you can soon begin to taste the coal in the blood of your prey. Something of the odor released by process of combustion begins seeping into food and flesh, and in turn makes its way into the blood that you consume.
*page_break
*comment P. T. Barnum's Greatest Show on Earth & Howes' Great London Circus & Sanger's Royal British Menagerie toured St. Louis 9/15-9/20 of 1884. 
@{literate You first hear of the circus's arrival when you see a bulletin in the ${post_dispatch}.|Word of the impending arrival of the circus is on everyone's lips.} "P.T. Barnum's Greatest Show on Earth & Howes' Great London Circus & Sanger's Royal British Menagerie" is coming to town.

It is due to arrive in the wee hours of the morning on the 15th of September. Interestingly, it does not plan to make use of the same fairgrounds that the Agricultural Fair will use next month, but instead will establish itself at the corner of Jefferson and O'Fallon, right on the edge of the Kerry Patch.
*choice
	*selectable_if (shepherd_credentials < 75) #I want to go watch them unload!
		*goto unload
	*if (eliot_rapport > 45)
		#I want to watch them unload; and I shall invite Hiram to join me.
			*set eliot_rapport %+20
			*set discretion %+5
			*set with_eliot true
			*set circus_1884_date "eliot"
			Eliot summarily assents to your invitation. He meets you downtown at the appointed time.
			*goto unload
	*if (becard_rapport > 45)
		#I want to watch them unload; and I shall invite Sabine to join me.
			*set becard_rapport %+15
			*set discretion %+5
			*set with_becard true
			*set circus_1884_date "becard"
			Bécard summarily assents to your invitation. She agrees to meet you downtown at the appointed time.
			*goto unload
	*if (stlouis_enterprise = 2) or (streetwise > 2)
		#Certainly there will be pickpockets and other thievery during the circus; I want to make sure to get my cut.
			*set shepherd_credentials %-20
			*gosub meet_henshaw
			*goto circus
		#Certainly there will be pickpockets and other scams during the circus; I want to make it clear such deeds will not be tolerated in St. Louis.
			*set compassion %-20
			*set shepherd_credentials %+20
			*set beneficent true
			*gosub meet_henshaw
			*goto circus
	*selectable_if (shepherd_credentials > 25) #I have better things to do than watch the workers set up a circus.
		*goto circus

*label unload
*set shepherd_credentials %+5
You sit in your coupé with ${stlouis_valet}, watching as the tents are raised and animals put out to exercise.

You watch in amazement as three elephants—Mandarin, Hebe, and Columbia—are led from their train cars. You have never seen an elephant before.
*if with_eliot

	"There are two types of elephants, you know. African and Indian. I've seen African ones before, when I was in the Near East. But this is the first time I've seen an Indian one. Much less three!" Hiram exclaims, almost giddy with delight. "And Columbia, the baby—she's the first elephant born in the Americas."
	
	*if perception < 2
		Unfortunately, while you're able to pick out the general shape of the beasts, your vision is not acute enough to make out more than the occasional flap of an ear or swish of the tail. You suppose you will have to buy a ticket like the rest of humanity.
				
		Sensing your limited perceptions, Hiram narrates the events as best he can. Amazingly, Mandarin, Hebe, and Columbia aren't the only elephants. No, in fact, the workers keep unloading the massive beasts. And unloading. All told, there must be about three dozen of them. As well as camels and zebras and other creatures about which you've only @{literate seen|heard tell of} in the most fanciful of storybooks.
		
		You listen intently as he describes the laborers and the performers together striving to arrange things before dawn rises and more gawkers arrive.
		*goto return_home
	*else
		*label see_elephants_with_company
		*set seen_elephants true
		*set anachronism %+20
		*set compassion %-15
		The sight of the creatures, even from this distance, fills you with an undeniable wonder. Though you have walked this planet for almost ninety years, there are still new things to discover.
		*if compassion < 40
			You even feel—dare you think it?—warmth in your heart.
			*if discretion < 50
				You look about yourself fearfully, wondering if anyone can perceive this moment of vulnerability.
		Amazingly, Mandarin, Hebe, and Columbia aren't the only elephants. No, in fact, the workers keep unloading the massive beasts. And unloading. All told, there must be about three dozen of them. As well as camels and zebras and other creatures about which you've only read in the most fanciful of storybooks.
		
		The two of you watch as the laborers and performers strive together to erect the tents before dawn arrives and bring even more gawkers to the show.
		*goto return_home
*elseif with_becard
	Sabine has never seen them either. Her mouth is agape at the sight of them.
	*if perception < 2
		Her vision must be better than yours, though. You are only able to sense the general shape of the beasts—as well as the flap of an ear or the swish of a tail—as they descend from their train cars and into their temporary homes. 
		*if (intelligence > 2) and literate
			You've read that there are two types of the creatures, Indian and African. This circus contains those of the Indian variety.
		You muse that, if you want to see them, you shall have to buy a ticket like the rest of humanity.
		
		Sensing your limited perceptions, Sabine narrates the events as best she can. Amazingly, Mandarin, Hebe, and Columbia aren't the only elephants. No, in fact, the workers keep unloading the massive beasts. And unloading. All told, there must be about three dozen of them. As well as camels and zebras and other creatures about which you've only seen in the most fanciful of storybooks.
		
		You listen intently as she describes the laborers and the performers together striving to arrange things before dawn rises and more gawkers arrive.
		*goto return_home
	*else
		And you can understand why.
		*goto see_elephants_with_company
*else
	*if perception < 2
		Nor can you really see all that much now; it is too dark and the creature are too far away for you make out much more than dim outlines of flapping ears and a swishing tail.
		*if (intelligence > 2) and literate
			Of course, you've read that there are two types, Indian and African. You have read that these are of the Indian variety.
		Amazingly, Mandarin, Hebe, and Columbia aren't the only elephants. No, in fact, the workers keep unloading the massive beasts. And unloading. All told, there must be about three dozen of them. As well as camels and zebras and other creatures about which you've only read in the most fanciful of storybooks.
		
		You do your best to watch as the laborers and performers strive together to erect the tents and close off the space before dawn arrives and brings even more gawkers to the show.
		*goto return_home
	*else
		*set seen_elephants true
		*set anachronism %+20
		*set compassion %-15
		*if (intelligence > 2) and literate
			Of course, you've read that there are two types, Indian and African. You have read that these are of the Indian variety.
		*comment endif
		
		${stlouis_valet} is bewildered by your exclamations of excitement. $!{valet_he} cannot see in the darkness near as well as you can.
		*if (intelligence > 2) and literate
			It is said that Columbia is the first elephant ever born in the Americas.
		The sight of the creatures, even from this distance, fills you with wonder. Though you have walked this planet for almost ninety years, there are still new things to discover.
		*if compassion < 35
			You even feel—dare you think it?—warmth in your heart. 
			*if discretion < 50
				You look about yourself fearfully, wondering if anyone can perceive this moment of vulnerability.
		Amazingly, Mandarin, Hebe, and Columbia aren't the only elephants. No, in fact, the workers keep unloading the massive beasts. And unloading. All told, there must be about three dozen of them. As well as camels and zebras and other creatures about which you've only read in the most fanciful of storybooks.
		
		You watch—fascinated—as the laborers and performers strive together to erect the tents before dawn arrives and brings even more gawkers to the show.
		*goto return_home

*label return_home
Eventually, the sun begins to threaten you with its arrival. The tents are mostly up, and what little you could witness before has been mostly concealed from view. ${stlouis_valet} kicks the horse into gear, and your coupé lurches into motion. 

*if with_eliot
	A short time later, you drop Hiram off where you had fetched him earlier and the two of you wish each other good-day.
*if with_becard
	A short time later, you drop Sabine off where you had fetched her earlier and the two of you wish each other good-day.

You arrive to your haven with little time to spare and rush to your resting place. As you close your eyes for the day, it is with one thought: the circus should be quite the show.
*page_break
*label circus
*set circus_1884 true
The main show goes on about an hour after dark. When you wake that evening, you have to rush to prepare yourself to go out.

${stlouis_valet} runs ahead to fetch the carriage, so that when you emerge from your haven, ${valet_he} is ready and waiting. With a word, ${stlouis_valet} flicks the reins and off you go.
*temp you "you"
*temp hiram "Hiram"
*temp company false
*temp temp_he "he"
*if with_eliot or with_becard
	*set company true
	*if with_eliot
		*set you "you and Hiram"
	*if with_becard
		*set hiram "Sabine"
		*set you "you and Sabine"
		*set temp_he "she"
	You make a short detour to secure your companion. You try to suppress the tapping of your foot.

The ride to the fairgrounds is frustrating; there are numerous other carriages in the road obstructing your progress. It seems everyone is headed to the circus this evening. Despite your late start, however, you make it in time; after purchasing your ticket, ${you} find a seat in the main tent.
*if with_becard
	*set columbia_coterie 2
	As you do, Bécard divulges what is on her mind.
	
	"A small nest of our kind has taken up residence in Columbia."
	
	"Nest?"
	
	"It's a term I've heard used to describe a group of our kind that live and feed together. I've been told that it tends to result in misery." She pauses a moment. "I'm inclined to believe the stories."
	
	"Are they your responsibility?"
	
	"Directly? No. I'm not a Quaestor. One could argue that they are Memeskia's responsibility, as there is no Quaestor of Columbia to deal with them."
	
	"Must they be dealt with?"
	
	"They have not come to pay their respects to Memeskia, nor to Fragalà. I fear the worst."
	
	Before she can say anything else, though, the lights change and an orchestra begins playing; the show has begun.
*else

	After a brief musical introduction, the performance begins. 
"ONE HUNDRED UNCIVILIZED, SUPERSTITIOUS, AND SAVAGE SPECIMENS," or so the ringmaster—William Ducrow—exclaims when he makes his grand entrance. Thus begins the "Ethnological Congress," led by Chang the Giant, a Chinese man who towers over the rest of the parade. Could he really be ten feet tall like they claim? @{company ${hiram} waves away the possibility.|}

You shake your head, but you find it difficult to focus on what follows: individuals of distant cultures of the Asias and Africa; cannibals and pygmies; Esqimaux, Aboriginies, and Hindoo. 
*if lore < 3
	You had never heard of most of these nations, much less seen individuals from them.
*if (ethnicity = "choctaw") and (compassion < 60)
	Your eyes turn to slits when your eyes alight upon the Sioux members of the parade.
*comment endif

Finally, Ducrow describes the contents of the Museum Tent, individuals whom he will not parade before you: Admiral Dot and Major Atom—the smallest men alive!—as well as armless men, bearded women, living skeletons, and other curiosities and freaks of nature. He extols the bizarre and the magnificent about these types, encouraging the attendees to visit the Museum tent once the circus proper has concluded. He also points out that the heathens from the parade of nations can be see in the Menagerie tent, where they are on display alongside the animals. He gives directions: the two tents stand at either end of the pike, with various diversions and food vendors occupying the space between.

And then the show proper begins: acrobats, contortionists, clowns, wild animals, races—camel, foot, and chariot!—and all manner of other diversions float before your eyes over the next few hours.
*if seen_elephants = false
	*set anachronism %+20
	You see so many wonders during this time that you are nearly speechless. You have walked this earth for nearly ninety years, yet within the space of three hours you see more of the world than you have seen in much of the past few decades.
	*if compassion < 35
		You even feel—dare you think it?—warmth in your heart. 
		*if discretion < 50
			You look about yourself fearfully, wondering if anyone can perceive this moment of vulnerability.
	It is bewildering to realize that you have much still to experience in this existence, even if you are confined to the embrace of the night.

The cheers and applause fill the tent as the show draws to a close. One by one, the attendees make their way to the exits, their world somehow bigger—grander—than it was a few hours before.
*if with_eliot and (eliot_rapport > 70)
	You find your hand strangely entangled with Hiram's. That is a problem that is quickly resolved.
*if with_becard and (becard_rapport > 70)
	You find your hand strangely entangled with Sabine's. That is a problem that is quickly resolved.
*page_break

*label sideshow_hub
*if (circus_time > 1) and (pickpocket_encounter = false)
	*gosub pickpocket
*if circus_time > 2
	Unfortunately, the night has grown late; the patrons have dispersed and the workers are closing the tents and tending the animals before finding their berths.
	*if saw_annie
		*gosub meet_annie
	*label leave_circus
	
	As you wait for ${stlouis_valet} to return with the coupé, you take a moment to marvel at all that you have seen this evening.
	*if messy_murder
		*set wealth -250
		Of course, the waiting is made somewhat more complicated by the blood splattered across your clothing. You use some straw to wipe the excess from your face, while keeping to the shadows to avoid the eyes of the curious.
		*if with_eliot
			*set eliot_rapport %-60
		
			Unfortunately, while staying in the shadows may conceal your crimes from the mortal, they do not posses Hiram's keen sense of smell. "What have you gone and done, ${given_name}?" he cries.
			
			"I was hungry."
			
			Hiram looks you up and down. "I believe that I can find my own way home." With that, he turns and disappears into the night.
			
			You shrug and return to waiting for your valet.
		*elseif with_becard
			*set becard_rapport %-60
		
			Unfortunately, while staying in the shadows may conceal your crimes from the mortal, they do not posses Sabine's keen sense of smell. "What have you gone and done, ${given_name}?" she cries.
			
			"I was hungry."
			
			She looks you up and down. "I believe that I can find my own way home." With that, she turns and disappears into the night.
			
			You shrug and return to waiting for your valet.
		*else
			Even this mess cannot suppress your buoyant mood: the world is truly a wider place than you had ever imagined. There are so many peoples' blood to drink!
		*if pickpocket_unnoticed and (discretion < 70)
		
			As you prepare for rest in the early hours of the morning, you discover that the dollars you had on you earlier this evening are gone. A pickpocket must have had his way with you at the circus! You had about fifty dollars on you when the night began.
			
			You resolve to pay closer attention to your surroundings in the future.
		*gosub photo
		*goto first_tuberculosis_encounter
	*else
		*if with_eliot
		
			"The world is a wider place than you had imagined?" Hiram observes.
			
			"I daresay it is, Mr. Eliot. I daresay it is."
		*if with_eliot = false
			The world is truly a wider place than you had ever imagined.
		*if pickpocket_unnoticed and (discretion < 70)
		
			As you prepare for rest in the early hours of the morning, you discover that the dollars you had on you earlier this evening are gone. A pickpocket must have had his way with you at the circus! You had about fifty dollars on you when the night began.
			
			You resolve to pay closer attention to your surroundings in the future.
		*gosub photo
		*goto first_tuberculosis_encounter
*else
	Looking about, you consider what you would like to see next.
	*choice
		#I want to challenge the strongman to an arm-wrestling contest.
			*set circus_time +1
			*goto strongman
		#I want to visit the fortune-teller.
			*set circus_time +1
			*set met_sosostris true
			*set wealth -17
			@{literate [b]LADY SOSOSTRIS[/b] declares the sign above the fortune-teller's tent. "Purveyor of the future, seer of the unseen…" cries the sideshow talker,|"Lady Sosostris!" cries the sideshow barker, "…purveyor of the future, seer of the unseen, will reveal your future." He gestures for you to enter,} using his cane to part the curtains before you.
			*if (love_clotho) and (memphis_affair = false)
				You are somewhat hesitant to enter; will this woman remind you of Clotho?
				*if compassion < 40
					You feel a pang in your heart at the thought. She is never far from your thoughts, after all.
			*if (fed_from_laveau) and ((love_clotho = false) or (memphis_affair))
				Years ago, you had a brief encounter with Marie Laveau, but you were left distinctly unimpressed by her precognitive abilities. She was unable to predict your thirst for her blood, for example.
			
			Inside, the fortune-teller sits at a small table, wrapped in a silk dress and an ornate headwrap that drips with jewels. Her eyes are lined with kohl and she stares intently at the cards on the table before her. "Please, sit down," she says, gesturing at the chair across the table from her. "You come seeking knowledge of your future, yes?" Her accent is thick, presumably Eastern European in origin. @{(perception > 1) And most likely fake.|} "I am Lady Sosostris. I will peer into your future, and tell you what awaits you there."
			*if perception <= 2
				She moves stiffly and has the features of a woman in her fifties.
			*else
				Looking more closely, you can tell that her perceived age is the result of the clever use of makeup. She moves stiffly, but it is an act. Though she no doubt wants to be seen as in her fifties, you place her at no more than thirty years of age.
			
			She gathers the cards and shuffles them together, and then invites you to cut the deck, which you do.
			*if (charm > 3)
				The two of you continue to talk while she shuffles further.
				
				"Lady Sosostris. Such a curious name. How did you come by it?"
				
				She seems unwilling to speak at first, but you smile and push some of your magnetism through it. "It came to me in a dream," she says, the words exploding from her mouth.
				
				"A dream?"
				
				"Yes. I dreamt of a woman in ancient finery. A woman who could see the past and the future; she could even see the worlds of what could have been."
				
				"And her name…"
				
				"Her name was Sostrate. At least, that's what I discovered. I went to the Astor library, and found her. An ancient sibyl of Sinope. She came to me in my dreams and told me to take her name. And so I did."
				*set heard_of_sostrate true
				
				"Even though…"
				
				"Enough questions. Don't you want your reading?" You nod; she has long since finished the necessary shuffling.
			"Let us begin with the place. This may be spiritual, physical, or temporal," she says, as she draws and places a card designated The World, laying it upside down before her. "As you can see, The World is inverted. This could mean a variety of things: the problem could be ongoing, some larger conflict you are supposed to resolve, for example." She furrows her brow before continuing. 
			
			"The second card is the source of the challenge." She draws and places another card, Temperance, upside down before her. "The problem is one of passion. Desires and impulses have trumped reason. Perhaps there is a drunkard in your life, who has lost themselves to the bottle?" 
			
			You try to suppress a smile. A drunkard? What vampire would succumb to drink?
			
			"The third card is the object of this conflict." With a dramatic pause, she draws a third card, placing the Page of Cups rightside up before her. "The Page of Cups is youthful, inspired, and associated with the waters of life."
			
			"The fourth card is the nature of the challenge," she says. With a flourish, she draws another card, placing it crosswise across the Page of Cups.
			*page_break
			You look down on the face of Death. Mme. Sosostris coughs uncomfortably. "Do not fear, this is most likely not a literal death. Perhaps it is the end of a creative endeavor? Are you an artist, perhaps? The Page of Cups is such a creative force."
			
			*if creation > 0
				"How did you know?"
				
				"The cards tell me, ${sir}."
				
				"Curious," you reply.
			*else
				You mold your face into a false image of surprise and offer a small gasp. She really is terrible as a fortune-teller!
			
			"Perhaps, then, it speaks to the conclusion of a work?" You shrug and gesture for her to continue. "The fifth card is a possible future, a likely resolution to the challenge." With a trembling hand, she turns over the fifth card, placing the Knight of Swords before her. "The Knight of Swords is…he is vengeance."
			
			You stare at the cards a moment longer before dismissing them wholly.
			*if (love_clotho) and (memphis_affair = false)
				Moreover, you chide yourself for your concerns over confusing this charlatan with Clotho.
			*if (fed_from_laveau) and ((love_clotho = false) or (memphis_affair))
				This charlatan has no more power than Marie Laveau did.
			You pay her fee and exit the tent. Could it be that vampires are the only supernatural force in the world? You have yet to see evidence to the contrary.
			
			With these heavy thoughts on your mind, you return to the main thoroughfare of the sideshow.
			*goto sideshow_hub
		#I will visit the Museum Tent.
			*set circus_time +1
			*set wealth -16
			*if company
				When you indicate your interest in seeing the Museum Tent, ${hiram} demurs, electing instead to go and feed the elephants. You arrange to regroup in about an hour. After @{with_becard she|he} disappears into the crowd, you enter the tent and
			*else
				Entering the tent, you
			seat yourself as a hush falls over the crowd. The presenter, Frank Hoffman, has taken the stage and begun crowing about the upcoming wonders. 
			*gosub annie_performs
			*goto sideshow_hub
		*if (((perception > 0) and (creation > 0)) or (feeding_style = "artists")) #I hear the sound of an instrument that is unfamiliar to me…
			*set circus_time +1
			Entering a tent decorated with flags of Bourbon Spain, you are greeted by the sight of a dance unlike anything you have ever seen before. Wearing intricate dresses with massive ruffled skirts and tight-fitting tops, three women stomp, click, and twirl on the stage while a man plays a queerly-shaped guitar. Besides attending to the dance itself, the women have small objects in their hands from which they elicit clicks at key moments, emphasizing their steps. @{(ethnicity = "spanish") This must be [i]flamenco,[/i] you conclude; your mother spoke of the dance when you were a child, but it was not part of [i]Isleño[/i] tradition.|You ask another patron what sort of dance this is, and she informs you that it is called the [i]flamenco.[/i]}
			
			*choice
				#I want to ask the guitarist about his guitar.
					*set stl_saw_guitar true
					*set anachronism %+5
					After the dance is over, you approach the guitarist and ask him about his instrument. It is much wider in places than any guitar you have seen before, and when you pluck a string it issues a much richer, fuller, louder sound than usual. The guitarist beams and tells you about the recent modifications to the device by the craftsmen of Seville.
					
					This is no instrument for hushed attendees and quiet spaces; this instrument can fill a room with its sound and provoke a cheer from the crowd. You spend some time with the guitarist, learning its differences from the usual instrument.
				#In the few moments that I can, I want to learn of Spain. @{(ethnicity = "spanish") It is the nation of my ancestors, after all.|}
					*set shepherd_credentials %+10
					*set compassion %-5
					*set anachronism %+3
					There is little that you can learn in the time between sets, but the lead dancer tells you something of the people of Seville, caught between its history as a Roman colony, an Arab Taifa, and most recently as a port to the world, bringing all kinds of foods, spices, and curiosities from Africa, South America, and the Philippines to Spain.
					
					She clearly misses the city and looks forward to her return home.
					
				*if (beast_of_gevaudan) #I wonder if they would perform a piece about the Beast of Gévaudan?
					*set werewolf_hysteria +1
					*set discretion %-5
					They do, in fact, have a piece about the Beast…though, it draws heavily on the tropes of Little Red Riding Hood. Regardless, they agree to add it to their nightly set while they are in St. Louis.
				*if (beast_of_gevaudan = false) #I ask them if there are stories of werewolves in Spain.
					*set beast_of_gevaudan true
					One of the dancers is not from Seville—as the rest of the group—but rather from Cataluña. There, she was raised on the story of the Beast of Gévaudan, a monster that terrorized the countryside near Toulouse. It was said to be a wolf with the cunning of a man, and killed many people over the course of years.
					
					You thank the woman for this tidbit.
			
			Eventually, the tent clears for a new performance, and it is time for you to leave.
			*goto sideshow_hub
		#I want to have my photo taken.
			*set circus_time +1
			*set anachronism %+5
			*set wealth -250
			*set photo_1884_circus 2
			*temp you "you"
			
			*if with_becard or with_eliot
				@{with_becard Sabine|Hiram} is here with you. Would you like to invite @{with_becard her|him} to sit with you for the photograph, or would you rather do it alone?
				
				*choice
					#I will sit alone.
					#I will invite @{with_becard Sabine|Hiram} to sit with me.
						"Come, let us sit for a photograph!" you say.
						
						*if with_becard
							*set photo_1884_circus 3
							*set you "you and Sabine"	
							"A photograph?" Sabine says, scowling. "That seems unwise."
							
							"Why?"
							
							"What if someone finds it in fifty years, and we haven't aged a day?"
							
							"@{(discretion > 50) Oh, don't be such a ninny! Nothing will happen|I promise I will keep it safe}," you reply.
							
							She sighs, and the two of you enter the tent.
						*else
							*set photo_1884_circus 4
							*set you "you and Hiram"
							"A photograph?" Hiram replies, considering it. "Why, that sounds lovely!"
							
							With a nod, he allows you to lead the way into the tent.
				
			There is not much of a line to enter the photographer's tent; the price of a single image is prohibitive for most of the attendees of the circus.
			
			When the current sitting is complete—an elderly woman posed with the corpse of her recently deceased cat—you are welcomed in by the photographer's assistant. The two make a fuss over ${you}, offering tea and trying to ascertain how best to present you to the lens.
			
			"You must do your best to stay absolutely still, ${mr} ${surname}. The camera will absorb even the slightest movements."
			
			"I see."
			
			"This is why it is best to photograph the dead."
			
			"Oh?"
			
			"Yes. They don't move! It makes the image much sharper."
			
			"@{(photo_1884_circus > 2) We will do our|I will do my} best to keep very still."
			
			After some negotiation, ${you} settle on a pose and the exposure begins. 
			*if (technology > 1) or (stlouis_enterprise = 3)
				You are somewhat disappointed with the process; this photographer's equipment is clearly a decade or more out-of-date. The new dry-plate process that you've read about would have sped the sitting-time to just a few moments.
			When it is finished, the photographer takes down your address and promises that the photo will be delivered to your home in a day or so. @{photo_1884_circus ERROR|| Sabine says you are welcome to it.|Hiram does not fight you for it.}
			*goto sideshow_hub
		*if ((choice_randomtest = false) or (circus_time > 1)) #I have had my fill of the sideshow.
			*set discretion %-5
			You file out of the sideshow with the other departing patrons.
			*goto leave_circus

*label pickpocket
*set pickpocket_encounter true
*temp company_notices false
*if ((perception > 2) or ((perception > 0) and (streetwise > 1))) or (streetwise > 2)
	*page_break

	Exiting the tent, you step back out onto the midway. Strolling through the crowds, you happen to notice something awry: a pickpocket who has set his designs on you.
	
	You wait until the little urchin's hand is actually on your person before you confront him.
	*if circus_pickpocket_deal
		*if with_becard or with_eliot
			*set company_notices true
		*if discretion > 50
			"You stupid little mite! Don't you know that you are working for me?"
		*else
			"Child, clearly no one has informed you that you are working for me tonight."
		The urchin's eyes widen as he struggle to free himself from your iron grip. "Now, release my things and go exercise your trade elsewhere."
		*if ((stl_kid_met = false) or (stl_kid_origin = 6)) and (year = 1884)
			*set stl_kid_met true
			*set stl_kid_origin 2
			*set stl_kid_name "Peter"
			*set stl_kid_nick "Petie"
		
		The urchin releases the bills he had and you catch them neatly in your hand. You give him one final glare and then let him go. Henshaw must not have communicated your identity to his team of miscreants. So much the better, you suppose.
		
		*if company_notices
			*if with_becard
				*set becard_rapport %-15
			*else
				*set eliot_rapport %-15
			Turning, you come eye-to-eye with @{with_becard Sabine|Hiram}. "Working for you?"
			
			"Yes. I struck a deal with the ringleader some nights ago."
			
			"And so you have these children stealing on your behalf?"
			
			*if compassion < 55
				"It's not like that, @{with_becard Sabine|Hiram}."
				
				"Then what is it like, ${given_name}?"
				
				"Come, don't be cross…"
				
				You can see, however, that @{with_becard Sabine|Hiram} is looking at you differently now.
			*else
				"What of it?"
				
				"I suppose you are not who I thought you were, that's all," @{with_becard she|he} replies.
			Doing your best to put this behind you, you continue down the midway.
		*else
			Satisfied, you return to the main thoroughfare of the sideshow.
			
		*return
	*elseif (charm > 3) or oblivio
		*temp taunt false
		"Do you really think that's wise, child?" you say, turn to capture him in your gaze.
		
		He freezes. At least, you think it is a he. Suddenly, the pungent smell of urine fills your nostrils.
		
		"Let go of my things before you soil them too," you command. The urchin withdraws his hand slowly. "Why are you still standing here?
		*if oblivio
			[i]Forget![/i]" you command.
			
			When the child comes to a few moments later, he looks around and resumes his trade—all thoughts of you erased from his memory.
			*return
		*elseif (compassion < 60) or (discretion < 60)
			Do you want me to summon the police? Or perhaps you would prefer a thrashing?"
		*else
			*set exposure +1
			*set taunt true
			Do you want me to drink your blood and leave your corpse for the crows to pluck?" you say, showing the barest hint of fang.
		
		The child's eyes widen; without any further prompting, he turns and flees. Satisfied, you return to the main thoroughfare of the sideshow.
		*if company and (taunt = false)
			Out of the corner of your eye, you spy a half-grin on @{with_becard Sabine|Hiram}'s face.
		*elseif with_becard and taunt
			*set becard_rapport %-5
			Out of the corner of your eye, you spy the hint of a frown on Sabine's face; your threat did not amuse her.
		*elseif with_eliot and taunt
			*set becard_rapport %-5
			Out of the corner of your eye, you spy the hint of a frown on Hiram's face; your threat did not amuse him.
			
		*return
	*elseif (agility > 2) or ((perception > 3) or (streetwise > 2))
		"Do you really think that's wise, child?" you say, his wrist trapped in your nimble fingers.
		
		He freezes. At least, you think it is a he.
		
		"Perhaps you should let go of my things?" you suggest. The child is clearly evaluating his options, but you interrupt him before he can make a decision. "The game is up. You have been caught. Now let my things go before I am forced to resort to something other than words."
		
		He looks you in your eyes and something in him gives way. He withdraws his empty hand. 
		
		"Now go, and do not trouble me again." Without any further prompting, he turns and flees. Satisfied, you return to the main thoroughfare of the sideshow.
		
		*return
	*else
		Though you notice him too late to interrupt his picking of your pocket, you are not without recourse.
		*choice
			#I let him go; a few coins are of no import to me.
				*set discretion %+5
				You watch as the boy slips through the crowd and into the night.
				*if with_eliot
				
					Hiram looks at you, somewhat surprised. "You are not concerned?"
					*set eliot_rapport %+5
					
					"Over pocket change? No," you reply, smiling at him.
				*elseif with_becard
				
					Sabine looks at you, somewhat surprised. "You are not concerned?"
					*set becard_rapport %+5
					
					"Over pocket change? No," you reply, smiling at her.
				*goto fail_pickpocket
			#I shout "thief!"
				*if male
					Several circus-goers in your proximity turn to gawk at you, but do little more than that. Growling in annoyance, you decide to give chase to the youth.
					*goto give_chase
				*else
					A strapping young farmboy notices your distress and lights out after the pickpocket. Within moments, he has the struggling youth by the scruff of his neck and is returning him to your presence. You proffer your hand and the pickpocket returns your missing bills. In a gesture of magnanimity, you tell the farmboy to let the pickpocket go, which he does, and then bestow a chaste kiss on the farmboy's cheek as a thanks. He gets an "aww, shucks" look on his face. 
					*if with_eliot
						Hiram tries to smother a smile at this bit of theatre. You bid the farmboy goodnight at the two of you return to your amusements.
					*elseif with_becard
						Sabine tries to smother a smile at this bit of theatre. You bid the farmboy goodnight at the two of you return to your amusements.
					*else
						You bid him goodnight and return to your amusements.
					*return
			#I chase him down and force him to return my things.
				*label give_chase
				*if agility > 1
					He is fast, but you are faster. You grasp him by the collar, and give him a good shake. He pleads with you to let him go. You stick out your hand and he returns your money to you. With a quick glance to make sure that it's all there, you send him on his way. Satisfied, you return the main thoroughfare of the sideshow.
				*else
					Unfortunately, your lack of grace makes it difficult to pursue the pickpocket in the crowd. Within moments, the youth is gone…and with him, your pocketmoney. Defeated, you return reluctantly to the main thoroughfare of the sideshow.
					*label fail_pickpocket
					*if wealth <= 1700
						*set wealth /2
					*else
						*set wealth -850
				*return
			*if (perception > 1) #I try to get a good whiff of him so I can track him down.
				*set discretion %-10
				*if perception > 2
					You follow the boy's scent through the crowd until you find him huddled behind a wagon, hurriedly counting his billfold. You catch him by the collar and demand the return of your money. Terrified, he obliges without further protest. Once you have assured yourself that your money has been returned, you release the boy with the recommendation that he find another line of employment.
					
					Satisfied, you return to the main thoroughfare of the sideshow.
					*return
				*else
					Unfortunately, amid the sea of unwashed workers and exotic animals, you are unable to get a strong enough sense of the pickpocket's musk. Try as you might, you are unable to find the boy. Reluctantly, you return to the main thoroughfare of the sideshow.
					*goto fail_pickpocket
			*if ((streetwise > 0) and (met_henshaw = false)) #I will look around for the ringleader; this pickpocket must not be working alone.
				*if streetwise > 1
					*set met_henshaw true
					His name is Henshaw, William Henshaw. He sports a short beard and an imposing mustache; his eyes are quick and take in every aspect of your dress and demeanor. Officially, he manages the sideshow performers. Unofficially, you infer, he manages the pickpockets and conmen that fleece the attendees.
					
					In exchange for your discretion, Henshaw summons the boy and has him return the bills he stole from you. After assuring yourself that you have been made whole, you thank Henshaw and return to the main thoroughfare of the sideshow.
					*return
				*else
					Unfortunately, though you search high and low, you are not able to locate any such ringleader. You return reluctantly to the main thoroughfare of the sideshow.
					*goto fail_pickpocket
			*if (company) #I urge ${hiram} to chase him down for me.
				*set discretion %-10
				*if with_eliot
					*set eliot_rapport %+5
				*if with_becard
					*set becard_rapport %+5
				${hiram} moves with supernatural speed and grace, weaving through the crowd in pursuit of the pickpocket. Within a few minutes, ${temp_he} has returned with the boy in tow. You proffer your hand and the pickpocket returns your missing bills. In a gesture of magnanimity, you tell ${hiram} to let the boy go, so that the two of you might return to your amusements.
				*return
			*if (company) #I urge ${hiram} to chase him down with me.
				*if with_eliot
					*set eliot_rapport %+20
				*if with_becard
					*set becard_rapport %+20
				*set discretion %+10
				*set shepherd_credentials %-10
				Something gleams in ${hiram}'s eyes when you make your desires known. Without another word, the two of you give chase to the pickpocket. Normally, vampires are solitary hunters, but sometimes they can find enjoyment in coöperation. This is such an occasion.
				
				It takes some twenty minutes for the two of you to finally corner the pickpocket. He's trapped between two wagons, with you and ${hiram} closing in from either side.
				*if perception > 1
					You can smell his fear and hear the pounding of his heart.
				${hiram} grabs him by the collar and addresses him forcefully: "You took something that doesn't belong to you."
				
				*if (discretion >= 55) and (compassion >= 55)
					You look at ${hiram} in surprise. Didn't the two of you just hunt this thief down? Why aren't you drinking from him right now?
					
					The boy holds your money out to you, his hand wavering. With a snarl, you snatch it from him. ${hiram} pushes the boy away roughly, recommending in the process that he find a new line of employment. 
					
					"What was that?" you demand. "I know you felt that…felt it as much as I did."
					
					"I do not deny it, ${given_name}. But we have indugled that part of ourselves enough. Come, let us return to the festivities."
					
					You reluctantly allow yourself to be coaxed back to the main thoroughfare of the sideshow.
					*return
				*else
					You extend your hand and the boy returns your bills to you. After you recommend that he find a new line of employment, ${hiram} releases him and the two of you return to the main thoroughfare of the sideshow.
					*return
*elseif wealth <= 1700
	*set wealth /2
	*set pickpocket_unnoticed true
	*return
*else
	*set wealth -850
	*set pickpocket_unnoticed true
	*return

*label strongman
*if male
	The circus-goers look at you with some skepticism when you propose an arm-wrestling match between yourself and Robert Gilfort, one of the gladiators from the evening's entertainment. Gilfort, along with his brother William, amazed the crowd with his feats of strength in the main tent.
*else
	There is a chorus of laughter when you proprose an arm-wrestling match between yourself and Robert Gilfort, one of the gladiators from the evening's entertainment, who along with his brother William had amazed the crowd with their feats of strength.
*choice
	#I intend to win. By any means necessary.
		*set circus_time +1
		*set discretion %+10
		*set local_fame %+5
		You grasp your hands together to the cheers of the crowd.
		*if male = false
			*set local_fame %+20
			*set exposure +1
			There are gasps all around that you would dare compete with a man in such a sport.
		*if strength > 3
			*label straight_win
			*set local_fame %+20
			*set exposure +1
			*if male = false
				*set exposure +1
			The contest has barely begun when you gentle press the back of his hand against the table. The room is silent at your simple victory.
			*goto after_wrestling
		*elseif strength = 3
			He is, in fact, about as strong as you are.
			*if willpower > 3
				*label will_victory
				*set exposure +1
				*set local_fame %+20
				*if male = false
					*set exposure +1
				The two of you stay locked for what seems like hours, but which is surely no more than a minute. Incrementally, almost imperceptibly, you begin to force his hand down. His eyes widen in disbelief. He may be just as strong as he is, but you want it more. And you refuse to let him defeat you.
				
				Finally, as the cheers of the crowd soar in response to your dramatic effort, the back of his hand touches the table and your victory is declared.
				*goto after_wrestling
			*elseif willpower = 3
				*label will_match
				*if will_test = 1
					*goto will_victory
				*else
					*goto will_loss
			*elseif charm > 3
				At first, you hold your own. The two of you are about evenly matched in raw strength. It soon becomes clear, however, that he wants it more. 
				*label win_by_charm
				But you have a secret weapon: your supernatural powers of persuasion. While the crowd roars, you whisper sweet nothings across your clenched fists, and after a good show, you best Mr. Gilfort after a stunning near-loss.
				*set local_fame %+20
				*if male = false
					*set exposure +1
				*comment endif
			
				The crowd goes wild.
				*goto after_wrestling
			*else
				*label will_loss
				*set local_fame %+10
				*if male = false
					*set local_fame %+10
					*set exposure +1
				The two of you stay locked for what seems like hours, but which is surely no more than a minute. Incrementally, almost imperceptibly, his hand begins to force yours down. You may be as strong as he is, but his determination is greater than yours. He capitalizes upon every mistake you make, while he offers none in return.
				
				Finally, as the cheers of the crowd soar in response to your dramatic effort, the back of your hand touches the table and his victory is declared.
				*goto after_wrestling
		*elseif charm > 3
			From the moment you lock hands, you know that he is stronger than you are. 
			*goto win_by_charm
		*else
			*label straight_loss
			When the two of you clasp hands, it becomes clear instantly that he is stronger than you.
			*if male
				He is kind enough to let you make a show of challenging him, but in the end he defeats you without breaking a sweat. All the same, the crowd seems to appreciate the show. 
				*goto after_wrestling
			*else
				In fact, he wastes no time in vanquishing you. The crowd boos you and you hear mutterings about your not knowing your place.
				*goto after_wrestling
	#I will do my best to win.
		*set circus_time +1
		*set discretion %+10
		*if strength > 3
			*goto straight_win
		*elseif strength = 3
			He is, in fact, about as strong as you are.
			*if willpower > 3
				*goto will_victory
			*elseif willpower = 3
				*goto will_match
			*else
				*goto will_loss
		*else
			*goto straight_loss
	*if male
		#I will let him win. I don't want to reveal myself.
			*set circus_time +1
			*set discretion %-10
			*if strength >= 3
				*set local_fame %+10
				You put on a show for the crowd, offering an amazing rally, during which you bring him to the brink of defeat, and finally allow him his victory. The crowd roars in response.
				
				He eyes you suspiciously, suspecting that you in fact let him win—but he clearly has no idea why you would do such a thing.
				*goto after_wrestling
			*else
				His strength is real, and there is no trickery to your loss. You could not have beat him had you wanted to.
				
				The crowd is unimpressed by the display.
				*goto after_wrestling
	*else
		#I will let him win. I wouldn't want to embarrass him.
			*set circus_time +1
			*if strength >= 3
				*set local_fame %+20
				*set exposure +2
				You put on a show for the crowd, offering an amazing rally, during which you bring him to the brink of defeat, and finally allow him his victory. The crowd roars in response.
				
				He eyes you suspiciously, suspecting that you in fact let him win. He clearly has no idea why anyone—especially a woman—would do such a thing. 
				*if discretion > 55
					*set local_fame %+10
					You take his hand in yours, and raise it up in the air in a show of good sportsmanship. The crowd goes wild again.
				*goto after_wrestling
			*else
				His strength is real, and there is no trickery to your loss. You could not have beat him had you wanted to.
				
				The crowd is unimpressed by the display. Mutterings about your not knowing your place reach your ears and do nothing to assuage your pride.
				*goto after_wrestling
	*selectable_if (discretion < 60) #I will simply watch the spectacle.
		*set discretion %-10
		*set circus_time +1
		One after another, men approach the table and see themselves defeated by the Gilfort brothers. The two men are not only strong, but they are determined. At the same time, however, they know how to work a crowd. They let some of their opponents think they are winning—for a time—only to rally on to victory.
		*goto after_wrestling
		
*label after_wrestling

The match over, you return to the main thoroughfare of the sideshow.
*goto sideshow_hub

*label annie_performs
*set saw_annie true
Over the next hour, you see all manner of marvels—John Darrington, the Living Skeleton; Charles B. Tripp, the Armless Wonder; and Mme. Milo, the Long Haired Wonder are but examples—leading up to the headliner of the night, Ms. Annie Jones, the Bearded Lady. Her husband, the barker who was standing outside the tent before the show began shouting himself hoarse with entreaties to passers-by, takes the stage beside Ms. Jones.

*if (anachronism > 80) or ((stlouis_enterprise = 5) or (perception >= 3))
	She is dressed in the latest fashion, with a lavender dress and corset to accentuate her curves.
*else
	She is dressed somewhat strangely. The cut of her dress is something you have never seen before, accentuating her curves in a very forward manner. Even the color—lavender!—strikes you as scandalous.
Her beard—a coarse and wiry affair—contrasts sharply with the softness of the dress's color. In addition to her beard, her hair is astonishingly long, reaching to her knees.

She begins her performance by playing a mandolin and singing. She has a clear and pleasant voice, and her rendition of an Irish ballad leaves the Irishmen in the audience teary. Her song finished, Richard Elliot, her husband, proceeds to tell a number of ribald tales, confirming in no uncertain terms that he has inspected all the various parts of his wife, and that she is entirely woman.
*if perception > 2
	It is not hard to see that the affection between the two is entirely performed. It seems that the two can barely stand each other.
The crowd guffaws at the innuendos.
*if (compassion < 35) and (discretion < 35)
	You, on the other hand, find the humor somewhat distasteful.

"When should we expect a young Esau?" someone yells from the crowd.

"Believe you me, sir, it's not for lack of trying!" Elliot quips in response. Apparently, the question of his wife's fertility is one to which he is accustomed.

Eventually, the show draws to a close to raucus cheers and loud applause. The attendees file out, you with them.
*return

*label meet_annie
@{company Momentarily separated from ${hiram}, you find yourself wandering amid the performers' tents.|Momentarily lost, you find yourself wandering amid the performers' tents, searching for the exit from the circus.} The sound of a heated argument reaches your ears. @{(perception > 1) Your supernatural hearing focuses on the words, and though you cannot make them out, you suspect that the voices belong to Annie Jones and Richard Elliot.|}

With a few more steps, you find yourself outside the offending tent.
*choice
	*if perception > 1
		#It is none of my business what passes between Ms. Jones and her husband.
			*label dont_investigate_commotion
			*set discretion %-10
			You put one foot in front of the other, moving quickly away from the commotion.
			*if compassion > 60
				After all, the petty travails of mortals holds no interest for you.
			*return
	*else
		#It is none of my business what passes between these performers.
			*goto dont_investigate_commotion
	#I wait and listen, to see if I can determine the nature of the conflict.
		*set discretion %-10
		It is, in fact, but a moment before you hear a cry of pain @{(perception > 1) from Ms. Jones.|from within.} It is shortly followed by a reverberating clang and a crashing thud.
		
		You push through the tentflap and drink in the scene before you. Richard Elliot is splayed on the ground, unmoving.
		*label elliot_down
		Annie Jones stands above him, an iron skillet in her hands. She looks up at you, her face flushed with indignation.
		*choice
			#"What is the meaning of this?"
				*set discretion %+5
				*label annie_explains
				*set stlouis_affair 2
				"He's drunk," she says, simply.
				
				"And that deserved this?"
				
				"He'll sleep it off, like he always does."
				
				"This is a regular occurrence?"
				
				"You could say that."
				
				*if stlouis_enterprise = 6
					"It is unfortunate that you will be leaving in the morning. There is a temperance meeting tomorrow. You and Richard should attend. Or you should, at least."
					
					"A temperance meeting?"
					
					"Yes. We come together to offer counsel and support to each other. Alcohol is a blight on this earth. Alone, wives are at the mercy of their husbands. But together, we can make a difference."
					
					"I thank you for your kind words, ${sir}, but I need no counsel. All I need is my frying pan. Now, if you will excuse me, I have packing to do, and the hour is already quite late."
					
					"Yes, of course. But before I go…"
					
					"What is it?" she says, scowling at you. And in that moment, you feel a slight twinge.
					
					"…allow me to introduce myself. I am ${given_name} ${surname}."
					
					"Well, ${mr} ${surname}, you've introduced yourself. And I'm sure you know me…I'm Annie Jones. And that there is my husband, Richard Elliot."
					
					"A pleasure," you say, enjoying the moment.
					
					Perhaps she isn't enjoying it as much as you. As the silence lengthens, you suddenly realize that she is waiting for you to leave. With a start, you excuse yourself and make your way from the tent.
					*return
				*else
					"I am sorry to hear it."
					
					"Don't be sorry. Mind your own business."
					
					"Excuse me?"
					
					"You see, that's what Dick's problem is. He's always trying to tell me what to do. And he tries all the harder when he's in his cups. And when he tries too hard, I lay 'im low. So don't you go tryin' to put your nose where it doesn't belong."
					
					"No…forgive me, I wouldn't…"
					
					"Now, if you will excuse me, ${mr}…"
					
					"${surname}. ${given_name} ${surname}," you supply.
					
					She shoots you an exasperated look. "Yes, ${mr} ${surname}. I have packing to do, and the hour is quite late."
					
					"Of course, Ms. Jones. Good evening."
					
					You pause a moment, somewhat taken by the sight of the hirsute woman, frying pan in hand, standing over her unconscious husband. It dawns on you slowly that she is waiting for you to depart, which you do hastily.
					*return
			#I rush to Richard's side.
				*if (discretion > 65) and ((feeding_style = "laborers") or ((feeding_style = "itinerants") or (feeding_style = "drunks")))
					*set messy_murder true
					*set stlouis_affair 5
					*set exposure +2
					The site of the prostrate man is too much for you. Your fangs extend and you sink them into Richard's throat, drinking deeply. Whatever you had intended, now all that you can think of is the salty blood flowing past your lips.
					
					It takes several moments before Annie Jones realizes what is happening. And then it takes a few moments more before the cries of horror begin to escape her throat.  Thankfully, the trumpeting of terrified elephants obscures the sound.
					
					Her screams have angered you long enough. With a brief dash, you bring her down and drink from her as well.
					*return
				*else
					*set compassion %-10
					*set discretion %-10
					Richard is still breathing. He stinks of whiskey.
					*goto annie_explains
			#One down…one to go. I kill them both.
				*set stlouis_affair 5
				*set compassion %+20
				*set discretion %+20
				*set wealth +250
				*if combat > 4
					You make short work of the couple. You drink deeply of both of them before leaving the tent.
					*return
				*else
					*set messy_murder true
					*set exposure +2
					The woman swings a mean skillet and lands the first blow across the side of your head.
					
					Once you let the beast free, however, she poses no further threat. Thankfully, the trumpeting of terrified elephants nearby covers her screams.
					*return
	#I enter the tent.
		*set discretion %+10
		As you move to enter the tent, you hear a cry of pain. Your pace quickens, and you push aside the flap to a second sound: a reverberating clang. Looking inside, you watch as Richard Elliot weaves, unsteady on his feet, and finally crashes to the ground.
		*goto elliot_down

*label meet_henshaw
*set met_henshaw true
It is a small thing to arrange a meeting with William Henshaw, the director of the sideshow for the circus. It seems that he has the unofficial title of manager for the pickpockets and scam-artists of the circus as well. He sports a short beard and an imposing mustache. His eyes move quickly, darting about the room and your attire, taking in every angle as they are presented to him.
*label meet_henshaw_again
*if year > 1884
	*temp beneficent false
	*temp pickpocket_encounter false

*if beneficent
	*if charm > 3
		*set circus_pickpockets_nixed true
		*if year != 1884
			*set pickpocket_encounter true
		Thankfully, your powers of persuasion are up to the task, and he agrees that peripheral activities will be curtailed for the duration of the circus' stay in St. Louis. You thank him for his understanding.
		
		*goto post_henshaw
	*else
		How do you intend to bend him to your will?
		*choice
			*selectable_if (streetwise > 1) #I threaten him with unfortunate repercussions. All sorts of things can go wrong when people start to get rowdy at a circus.
				*set discretion %+5
				*set circus_pickpockets_nixed true
				*if year != 1884
					*set pickpocket_encounter true
				*goto post_henshaw
			*selectable_if (combat > 7) #I threaten him physically.
				*set discretion %+15
				*set circus_pickpockets_nixed true
				*if year != 1884
					*set pickpocket_encounter true
				You make your point simply enough. He agrees to curtail the activities of his associates, though he seems distinctly displeased by your methods of conflict resolution.
				
				You bid him goodnight and exit his wagon.
				
				*goto post_henshaw
			#I offer to compensate him for any income lost during the period.
				*set discretion %-10
				He ventures an amount that you would have to deliver to compensate his associates for their inactivity.
				*if wealth >= 30000
					*set compassion %-10
					*set wealth -20000
					*set circus_pickpockets_nixed true
					*if year != 1884
						*set pickpocket_encounter true
					You agree to the amount and the two of you shake hands.
					*if (male = false) and (compassion < 35)
						You smile at the ease with which he takes your hand over the matter. Whatever else he may be, he does not think you too delicate for a handshake.
					Your business concluded, you step lightly down from his wagon and bid him farewell.
					
					*goto post_henshaw
				*else
					*set beneficent false
					He laughs when you acknowledge that you are unable to meet his price.
					
					You exit the wagon, dejected, and return home.
					*page_break
					*return
*else
	*set circus_pickpocket_deal true
	*if streetwise > 2
		*set wealth +4000
		*if streetwise > 3
			*set wealth +1000
		You make your point regarding the exercise of the talents of his associates with relative ease. He offers you a noteworthy payment up front for the right to operate for the next five days without further interference. You thank him for his congeniality, promise him that the newsies of the Kerry Patch will offer him no competition,
		*goto end_henshaw
	*elseif streetwise > 1
		*set wealth +3000
		You make your point regarding the exercise of the talents of his associates without incident. He offers you a reasonable payment up front for the right to operate for the next five days without further interference. You thank him for his congeniality, promise him that the newsies of the Kerry Patch will offer him no competition,
		*goto end_henshaw
	*elseif streetwise = 1
		*set wealth +2000
		You make your point regarding the exercise of the talents of his associates with only minor difficulty. He offers you a small payment up front for the right to operate for the next five days without further interference. You thank him for his offer, promise him that the newsies of the Kerry Patch will offer him no competition,
		*goto end_henshaw
	*else
		*set wealth +1000
		You make your point regarding the exercise of the talents of his associates with some difficulty. You feel as though, in the end, he is mostly humoring you when he offers you a small sum to leave him be. You thank him begrudingly for his offer, promise him that the newsies of the Kerry Patch will offer him no competition,
		*label end_henshaw
		and the two of you shake hands on the deal.
		*if (male = false) and (compassion < 35)
			You smile at the ease with which he takes your hand over the matter. Whatever else he may be, he does not think you too delicate for a handshake.
		Your business concluded, you step lightly down from his wagon and bid him farewell.
		
		*label post_henshaw
		You return home, satisfied in a night's work. 
		*if year = 1884
			Moreover, after looking around the camp for a few brief moments on your way to and from Mr. Kuzmenko's wagon, you are certain that the circus will be quite the show.
		*page_break
		*return

*label photo
*if photo_1884_circus > 1
	*page_break
	As promised, the photo is delivered to your house the next evening. It is a handsome photo of ${you} staring into the camera, stone-faced.
	
	There is a note from the photographer
	*if literate 
		remarking on the crispness of the image. [i]You@{(photo_1884_circus = 2) | two} were able to keep your@{(photo_1884_circus = 2) self|selves} remarkably still! It's as though you were already dead![/i] he remarks.
	*else
		which you pass to ${stlouis_valet}. It seems that the photographer marvels at how you@{(photo_1884_circus = 2) | two} were able to keep your@{(photo_1884_circus = 2) self|selves} still, as though you were already dead. You try not to laugh about that in front of ${stlouis_valet}.
	
	You hang the photo on the wall, a memento to your evening at the circus.
*return

*label first_tuberculosis_encounter
*page_break
*comment 1884-07 ?
*if stlouis_cult
	"${stlouis_cult_address}?"
	
	"Yes, Amanda?"
	
	"One of your disciples, Jeremiah, is sick."
	
	"Oh?"
	
	"Yes. They say she has consumption."
	
	"I see." 
	
	This is difficult. Does Jeremiah's illness demonstrate the limits of your power? What kind of deity are you if you cannot heal those who worship you? Or perhaps that's just not the kind of deity that you are.
	
	*choice
		#I kill him, though I make it look like a natural passing. No reason to prolong his suffering.
			*set compassion %+5
			*set discretion %+5
			You slip into Jeremiah's home and suffocate him. @{(compassion > 50) A pity that his blood will go undrunk, you muse.|}
			
			You lead a celebration honoring Jeremiah's devotion and sacrifice to the cause. @{stlouis_cult_purpose Your other disciples spend the rest of the night cooking in prepartion for serving breakfast to the poor in the morning.|Your disciples take your words to heart—he died due to the corruption at the heart of settler ways.|Of course, you have to also denigrate Jeremiah some; you have to explain why he did not sacrifice enough to the cause, such that he was cursed with a short life and painful death.|The other disciples hang on your every word before begging to be your vessel for the night.|Your other disciples cheer his escape from God's reach. He is now safely in Hell, where he can join Satan's legions.|The other disciples spend the rest of the evening discussing next steps in the fight for equality.}
		#I ordered him tended to until his expiration.
			*set compassion %-5
			*if (stlouis_cult_purpose <= 2) or (stlouis_cult_purpose >= 5)
				*set stlouis_cult_power %+5
			Amanda @{stlouis_cult_purpose nods; this is the way of your disciples, after all.|nods; the community cares for its own, unlike the settlers and their belief that everyone should tend to themselves.|looks at you a bit quizzically; she is more accustomed to collecting tithes than offering comfort.|nods.|nods; no clergy must be allowed to offer him repentance before his death!|nods; she and the rest of your disciples have spent plenty of time tending to the indigent.}
			
			A few months later, Jeremiah expires, @{stlouis_cult_purpose surrounded by fellow disciples who pray with him through his final moments.|surrounded by fellow disciples who cheer him on to embrace of the Corn Mother.|a nurse and a mourner on hand to watch and witness the occasion. Providing a witness to his last moments is the least that you can offer.|a nurse and a fellow disciple on hand to watch and witness the moment. The attentions of a fellow devotee are the least that you can offer.|his final blasphemies recorded and repeated for the entire community to hear. They celebrate his final liberation from salvation, now that he has joined Satan's legions.|surrounded by fellow disciples who pray with him through his final moments.}
		#I send him to a sanitarium@{(stlouis_cult_purpose = 3) ; as he gave to me, so I give to him|}.
			*set income -2
			*if stlouis_cult_purpose = 3
				*set stlouis_cult_power %+5
				
				The best sanitarium in the country@{heard_of_kelloggs , of course, is the Kelloggs's in Minneapolis. Thomas, the son of your landlord, was clearly an exception.| is that of Dr. Kellogg, in Minneapolis.} It is not cheap to send Jeremiah there, but doing so demonstrates your devotion to your flock.
				
				Of course, there is no cure for consumption. Jeremiah dies a short time after arriving, but by that point, your disciples are happy to attribute his passing to the sanitarium, not to you.
			*else
				*set stlouis_cult_power %-5
				Amanda and the rest of your disciples are mildly surprised by your decision, but do as you instruct. @{heard_of_kelloggs The best sanitarium in the country, of course, is in Minneapolis; Thomas's premature death there nonwithstanding.|Amanda reports to you upon some research that there is a well-respected sanitarium in Minneapolis run by a Dr. Kellogg.} Jeremiah's things are packed and he is sent on his way.
				
				Of course, there is no cure for consumption; Jeremiah dies a few months after arriving. His letters of appreciation are shared widely among your flock and offer them some small comfort for his sudden separation from them.
			*set heard_of_kelloggs true
		*if (stlouis_cult_purpose = 5) #I sacrifice him in an elaborate ceremony.
			*set stlouis_cult_power %+5
			*set compassion %+5
			*set discretion %+5
			*achieve temple_of_doom
			Jeremiah jumps at the chance to be the centerpiece of such a ceremony.
			
			On the appointed evening, the entire community gathers to witness Jeremiah's sacrifice. He blasphemes at length, rejecting numerous ritualistic opportunities to repent and ask for forgiveness. When he has thoroughly damned his soul, he lies back on an altar whereupon you cut out his heart and show it, still beating, to the adoring crowd.
			
			You anoint them in Jeremiah's blood and lead them in a chant to guide his soul down to Satan's legions.
*elseif renter
	"${mr} ${surname}?"
	
	"Yes, ${stlouis_valet}?"
	
	"You've heard Mrs. Silver coughing?" How could you miss it? It sounds like she's dying. "She's dying, ${sir}, of consumption." 
	
	Mrs. Silver lets another room in the house. @{(perception > 1) Due to her coughing, you'd made your diagnosis months ago through the flimsy walls of the building; consumption has a particular quality to its rasp.|} She's a widow and mostly exists on the charity of your landlady.
	
	*choice
		#I instruct ${stlouis_valet} to stay far away from her; I do not want to lose ${valet_him} to this disease!
			*set discretion %-5
			${stlouis_valet} nods at your directive and carries on with ${valet_his} duties.
			*label silvers_death
			
			Over the course of the next few months you have to listen as Mrs. Silver hacks herself to death@{(perception >= 2) ; you can even hear it during your daysleep|}. Finally, the end arrives and she is carried out of the house feet-first to be buried in Potter's Field.
		*if ((wealth > 50000) or (income > 5)) #I pay to send her to a sanitarium where she can die in comfort.
			*if wealth <= 50000
				*set income -1
			*else
				*set wealth -10000
			*set stlouis_valet_loyalty %+5
			${stlouis_valet} and your landlady are both surprised by your generosity, but they are happy to see Mrs. Silver conveyed out and away. Inspired by your largesse, several neighbors band together and collect donations to add to yours, and soon enough money is raised to send her to Kellogg's sanitarium in Minneapolis. @{heard_of_kelloggs Your landlady was touched by Dr. Kellogg's handling of her son and his very kind note upon his demise; she expects him to tend to Mrs. Silver with the same degree of care.|}
			
			Of course, she dies a few months after arriving in Minneapolis, but at least she spends her last days in comfort.
			*set heard_of_kelloggs true
		#I slip into her room early one morning and put her out of her misery.
			*set compassion %+5
			*if (stealth + streetwise) > 2
				It is a small thing to make your way into her room, pull one of her pillows from the side of her bed, and gently smother her with them. Small for you, anyway; when the fabric comes into contact with her face, she wakes and begins struggling. Of course, a sick old person is no match for you. @{(compassion < 60) Though her fists do not move you, the bleakness of your deed sits with you for many nights afterwards.|}
			*else
				Unfortunately, you wake Mrs. Silver during your skulduggery. She cries out and you are forced to flee the building. Soon, the whole place is in an uproar and the police are called. Thankfully, ${stlouis_valet} covers for you until you can slip back in through a window.
				*goto silvers_death
*else
	"${mr} ${surname}?"
	
	"Yes, ${stlouis_valet}?"
	
	"You've seen the neighbor, the Widow Silver, on her evening constitutional?"
	
	"I have. She seems…not well."
	
	"She has consumption."
	
	@{(compassion < 50) "I'm sorry to hear it."|"That is unfortunate."} @{(perception >= 2) Of course, you'd diagnosed the condition months ago; the rasp of consumptives has a particular quality.|}
	
	*choice
		#This is not really my concern. She will die alone like the rest of them.
			*set shepherd_credentials %-5
			Nor should it be.
		#I direct @{(stlouis_cult and (stlouis_cult_purpose = 1)) Amanda|${stlouis_valet}} to periodically bring her meals.
			*set local_fame %+5
			*set compassion %-5
			*if (stlouis_cult = false) or (stlouis_cult_purpose != 1)
				*set stlouis_valet_loyalty %+5
				${stlouis_valet} is @{(compassion > 50) surprised at|pleased by} your magnanimity, @{(compassion > 50) but accedes to|and immediately complies with} your request.
			*if stlouis_cult and (stlouis_cult_purpose = 1)
				*set stlouis_cult_power %+5
				Amanda and your disciples are overjoyed to tend to your neighbor.
			
			A few months later, the Widow Silver finally expires. Her family descends on her estate like locusts and strips it bare. Within sixty days, the house is occupied by a new family.
		*if ((wealth > 100000) or (income > 10)) #I pay to send her to a sanitarium.
			*if income <= 10
				*set wealth -20000
			*else
				*set income -2
			*set stlouis_valet_loyalty %+10
			*set compassion %-5
			*set local_fame %+10
			${stlouis_valet} is surprised by your generosity, but is happy to see the Widow Silver tended to. @{heard_of_kelloggs ${stlouis_valet} recommends sending her to Kellogg's sanitarium. Though ${valet_his} nephew Thomas's death there was unfortuante, Kellogg clearly cares deeply about his patients—his death letters say so. And it's not like there's any better outcome to be hoped for.|After some research, ${valet_he} recommends Dr. Kellogg's sanitarium in Minneapolis. At your urging, the widow accepts the offer.}
			
			She dies a few months after arriving there, but at least she spends her last days in comfort. Before her body is even cold, her family descends on her estate like locusts and strips it bare. Within sixty days, the house is occupied by a new family.
			*set heard_of_kelloggs true
		*if (haven_value >= 50000) #A dying widow with some money to her name? I think a redrafting of her will is in order! @{(stlouis_estate_lawyer != "empty") I send for ${stlouis_estate_lawyer}.|}
			*set compassion %+5
			You've been neighbors now for…six-odd years. That could be the basis for being included in her last will and testament, you reason. 
			*if stlouis_estate_lawyer != "empty"
				${stlouis_estate_lawyer} is only too happy to be of service to you again.
			
			*if charm > 3
				*set stlouis_valet_loyalty %-10
				*set wealth -10000
				*set income +5
				Using your powers of charm, you induce her to sign over a significant portion of her estate. With the assistance of @{(stlouis_estate_lawyer != "empty") ${stlouis_estate_lawyer}|a lawyer}, you craft a new will that will be difficult to overturn. It does not take everything, but certainly takes the best parts.
				
				Of course, it is tiresome to revisit her and reinforce your influence on a nightly basis. You can't let her regain her senses and repudiate the new will, after all!
				
				A few months later, the Widow Silver finally expires. Her family descends on her estate like locusts, but are dismayed to discover the best parts have already been stripped away. They try to contest the will, but soon realize that they have more to lose than to gain. Within sixty days, a new family is occupying the vacated house.
			*elseif (charm = 3) and (perception > 1)
				*set stlouis_valet_loyalty %-20
				*set wealth -10000
				*set income +5
				Your charm and sensitivity to social cues enables you to gain the widow's confidence quickly. Within a few weeks, you have her head spinning, and have isolated her from everyone except you and ${stlouis_valet}. As her condition deteriorates, she begins to lose track of reality.
				
				Around this time, @{(stlouis_estate_lawyer != "empty") ${stlouis_estate_lawyer}|a lawyer} visits and revises her will. He does it carefully. You do not take everything; that would leave you too open to lawsuit and the entirety of the matter might be discarded. But to acquire a portion of her estate for a few weeks' work is a useful exercise.
				
				The Widow Silver dies shortly thereafter. Her family descends on her estate like locusts, but are dismayed to discover the best parts have already been stripped away. They try to contest the will, but soon realize that they have more to lose than to gain. Within sixty days, a new family is occupying the vacated house.
			*else
				Unfortunately, the crotchety old woman rejects all of your advances. She defended a homestead during the Bleeding Kansas conflict, and refuses to indulge your greed.
				
				A few months later, she expires. Her family descends on her estate like locusts and strips it bare. Within sixty days, the house is occupied by a new family.

*temp tick false
*temp electrical "electrical"
*temp electricity "electricity"
*temp lighting_level 3
*if (stl_electricity < 5)
	*set electrical "gas-powered"
	*set electricity "gas pipes"

*if ((stlouis_enterprise = 3) or (stlouis_enterprise = 7)) or ((shepherd_credentials > 70) or ((feeding_style = "socialites") or (feeding_style = "merchants")))
	*page_break
	With the proliferation of @{(stl_electricity < 5) natural gas distribution centers|coal-fired power plants} in St. Louis, the élite of the city begin to debate the wider deployment of @{(stl_electricity < 5) illumination|electricity}.
	
	@{(stl_electricity < 5) Gas lighting|Electricity} can encourage people to go out and stay out later and later in the evening, making it easier for you to find prey. On the other hand, more light makes it harder for you to slink away from your crimes.
	
	*choice
		*if (feeding_style = "vegetarian") #Let the light be plentiful! Since I do not feed from mortals, I will not suffer, whereas other vampires will.
			*set discretion %+5
			*set independence %-10
			*set lighting_level +2
		*if (finance > 0) #Yes, the city should borrow heavily in order to finance the expansion of ${electricity} throughout the community. Every business and street should be illuminated!
			*set discretion %+5
			*set laborvscapital %-10
			*set justice %+10
			*set lighting_level +2
		*if (finance > 0) #The city should borrow heavily in order to finance the delivery of ${electricity} to homes. Everyone should benefit from this wonder.
			*set discretion %+5
			*set justice %-15
			*set laborvscapital %+5
			*set lighting_level +1
		#The city should pass an ordinance requiring businesses to illuminate their storefronts; once they've illumianted their storefronts, they will surely bring lighting inside.
			*set discretion %+5
			*set laborvscapital %+5
			*set lighting_level +1
		#I stand aside and let the mortals decide for themselves; no need to expose myself over this.
			*set discretion %-15
		*if ((stl_electricity >= 5) and (perception > 3)) #I want to slow the expansion of electricity; I do not like what coal is doing to the flavor of the blood.
			*set discretion %+5
			*set lighting_level -1
			*set shepherd_credentials %-15
			*set discretion %-5
		*if ((stl_electricity >= 5) and (dead_electrician = 3)) #Electricity is clearly very dangerous, as attested to by the death I witnessed. Though it will slow the expansion of civic lighting, no one else will die from faulty wiring.
			*set discretion %+5
			*set lighting_level -1
			*set laborvscapital %-15
		#I prefer the darkness. Whatever influence I have, I wield it to slow or stop the expansion of public illumination.
			*set discretion %+5
			*set lighting_level -1
			*if local_fame > 55
				*set lighting_level -1
			*set discretion %-15
	*page_break
	Over the course of the next year,
	*if lighting_level = 5
		*set bloodflow +2
		*set exposure +2
		${electrical} lights spring up along every commercial and almost every residential street in the city. Businesses bring the illumination inside. A whole new world flowers under the lights.
	*elseif lighting_level = 4
		*set bloodflow +1
		*set exposure +1
		${electrical} lights spring up along every commercial and the wealthier residential streets in the city. Any business worth its salt brings interior illumination. A whole new world flowers under the lights. 
	*elseif lighting_level = 3
		${electrical} lights spring up along most commercial streets and in the wealthier neighborhoosds. The largest businesses pay to bring the wonder indoors. Without public support, adoption will be slow, but eventually a whole new world will flower under the artificial light.
	*elseif lighting_level = 2
		*set exposure -1
		*set anachronism %-5
		*set stlouis_business_climate %-10
		${electrical} lights spring up along a number of the larger commercial streets. The wealthiest businesses and homes—as well as hotels and some specialty venues such as theaters—bring in illumination. However, without public support, and with some working actively against it, St. Louis will begin to be seen as backwards and provincial by the wealthy and educated.
	*elseif lighting_level = 1
		*set exposure -2
		*set stlouis_business_climate %-20
		${electrical} lights spring up along a handful of the larger commercial streets. The wealthiest businesses and homes—as well as hotels and some specialty venues such as theaters—bring in illumination. But without public support, and with some working actively against it, St. Louis will begin to be seen as backwards and provincial by the wealthy and educated, becoming almost a laughingstock for its resistence to modernity.

*if (priest or trans) or (((stlouis_enterprise = 5) or (feeding_style = "artists")) or ((shepherd_credentials > 85) or (feeding_style = "clergy")))
	*temp source 1
	*if priest or (feeding_style = "clergy")
		*set source 2
	*set stl_neopronouns true
	*page_break
	In the fall, a bit of scholarly debate arises when an attorney and hymn-writer from Erie, Pennsylvania by the name of Charles Converse publishes a hymn referring to God as [i]thon,[/i] rather than as [i]he[/i]. In an accompanying article, he explains the origin of the pronoun as a contraction of "that one," claims that he and his associates have been using it for nearly twenty-five years to good effect, and offers it for situations where the gender of an individual is unknown, unknowable, concealed, or irrelevant. He makes a theological argument that God could not be specifically a man, as why would terrestial conceptions of gender apply to the divine?
	
	He further argues against the use of the singular [i]they[/i]—an alternative that has been offered from other quarters—as being a "hideous solecism." @{source Several of the writers and artists you have befriended quite like the new word.|The clergymen you maintain an acquaintance with are quite incensed by the affrontery of this hymn.} In the subsequent weeks and months, further articles are published offering other possibilities: some recall the Scottish idiom [i]ou,[/i] a professor from Baltimore offers [i]hiser,[/i] and a minister from Toronto champions the cause for [i]they;[/i] others object to the very idea of a new pronoun, while still others argue that the idea is noble but [i]thon[/i] itself might lead to confusion with [i]thou[/i] and the Plain Speech of the Quakers.

	@{source (At least one mortal aquaintance of yours immediately adopts the [i]thon[/i] pronouns; thon had become quite tired of being met with confusion around thon use of [i]they[/i].)|}
	
	*choice
		*if (religious_tradition != "pagan")
			*selectable_if (rationalism > 40) #These heretical notions are an affront to God.
				*set anachronism %-5
				*set rationalism %+10
				You comfort yourself with the rigidity of tradition.
		*selectable_if (rationalism > 40) #The idea that @{(religious_tradition = "pagan") the divine|God} has no gender is one that makes sense to me; it reaffirms my faith.
			*set anachronism %+5
			*set rationalism %+10
			You embrace the notion that the divine is not constrained by human ideas of gender.
		*selectable_if ((rationalism < 65) and (compassion < 50)) #This vocabulary gives voice to @{trans those who identify as neither male nor female|a suspicion I've had that gender is something more than the body parts a person is born with}.
			*set anachronism %+5
			*set rationalism %-5
			If gender can be separated from biology…then that means that gender is a performance.
			
			There are strong corollaries here with your own vampiric nature: what purpose does gender serve a vampire? To blend in with the humans and observe the Rule of Reserve, yes, but otherwise, gender is little more than a routine.
		*if (trans) #I wish I had been aware of this vocabulary when I changed my identity!
			*set compassion %-5
			Thankfully, your existence is indefinite and you will find the opportunity to reinvent yourself again.
		#Because vampires have superseded their mortal flesh, perhaps we should all adopt these pronouns? Gender is irrelevant to our kind.
			*set compassion %+5
			*set shepherd_credentials %-5
			You wonder how many vampires that you have already met arrived at similar conclusions?
		#If mortals want to call themselves sheep, it won't change my opinion of them.
			*set compassion %+5
			*set discretion %+5
			*set shepherd_credentials %-10
			With the passage of time, the taxonomy of mortals has become increasingly irrelevant to you.

*page_break
*set tick ((compassion < 60) and (perception > 1))
In mid-December, you find yourself out on what the mortals would call a lovely winter evening. The @{(stl_electricity < 5) gaslamps|electrical lights} @{lighting_level barely|barely||gayly|gayly} illuminate the city streets@{(lighting_level < 3) |, and young folk use the opportunity to sled down any hills that they can find or create}. 

You, on the other hand, are cold to your core. Not that a stove warms you—only blood really achieves that. But the cold is still something especially miserable.

Tonight, however, snow begins to drift down from the sky. You pause a moment to catch a flake on your hand, only to realize that the snow is @{(stl_electricity < 5) tinged|jet} black. Fearing a fire, you look in every direction and strain your ears for alarms, but you can spy no disturbance. You hurry to your destination, keeping a watchful gaze over your shoulder as the black snow falls all around you.

Over the next few days, you learn that local men of science attribute the black snow to the coal ash in the air. @{(stl_electricity < 5) Though there are no electrical plants in the city, many factories still use coal for fuel.|Between the electricity factories and the other foundries, coal fires burn throughout the day and night.} The men of science assure the locals that there is nothing to be concerned about; the coal ash surely can cause no harm.

*choice
	*if (stl_electricity < 5) #I'm glad I stopped the electrical plants@{(perception > 3) ; the taste of the coal ash in the blood would be overwhelming if I hadn't|}.
		*set discretion %-5
		*if perception > 3
			*set shepherd_credentials %+5
			The costs of advancement are greater than the mortal realize. You have done what you can to stem that tide, but you are but one vampire.
		*else
			*set anachronism %-3
			Though the men of science claim that the coal ash is safe, you cannot see how something so unnatural can be good for the mortals.
	*if (stl_electricity > 5) #Did I make a mistake by encouraging the development of the electrical plants?
		*set discretion %-5
		You are left with the thought tumbling over and over in your mind; you will never know what might have been.
	#The sacrifices—and the foul-tasting blood—are necessary for the advancement of capital. @{(haven_value >= 250000) How else could I afford such splendid accommodations?|I do not wish to spend my eternal existence living in squalor.}
		*set discretion %+5
		*set compassion %+5
		*set anachronism %+3
		*set laborvscapital %-10
		*set shepherd_credentials %-20
		You will bend these forces to your will or die trying. And the humans who will be crushed under your heels? They are not worth the thought.
	#I try to take the long view: if these phenomena are dangerous, the mortals will figure that out and correct for it themselves. No need for me to be involved.
		*set discretion %-10
		*set compassion %+5
		*set laborvscapital %-5
		*set shepherd_credentials %-10
		*set rationalism %+5
		These things have a way of working themselves out in time.
	*if (perception > 3) #I spend some time musing on what it means that the coal ash has afflicted the snow and tainted the blood of the mortals.
		*set rationalism %-10
		*if (tuberculosis_vaccine > 0) and (knows_pb_diseased = 3)
			*set tuberculosis_vaccine +1
			Spending some time considering the problem, several ideas occur to you that might contribute to Dr. Cousins's research. You make a plan to meet and discuss these ideas with him next week. 
		*elseif (knows_pb_diseased = 3)
			*set anachronism %+5
			Spending some time considering this, you can't help but wonder about ${maddox} and the Yellow Fever. It seems that the number of microscopic things that might play an outsized role in the events of the world is greater than you had realized.
		*elseif (knows_pb_diseased = 2) and (intelligence > 1)
			*set knows_pb_diseased 3
			*set anachronism %+5
			It's hard to believe that something so small could have an effect upon mortals—or even moreso on you. But there is no other possibility.
			
			While ${maddox} haunted Memphis, the question of whether or not he was responsible for the spread of the Yellow Fever was unanswered. Now, you cannot think otherwise. He @{((maddox_status = "buried") or (gallagher_status = "buried")) is, even now,|was} infected with the disease, and passed it on to those from whom he fed.
		*elseif (knows_pb_diseased = 1) and (intelligence > 1)
			*set knows_pb_diseased 2
			*set anachronism %+5
			It's hard to believe that something so small could have an effect upon mortals—or even moreso on you.
			
			Is it possible that such microscopic things could play an outsized role in the world? Could something like this have been the cause of the Yellow Fever outbreaks in Memphis? Might ${maddox} @{((maddox_status = "buried") or (gallagher_status = "buried")) be|have been} afflicted with something entirely out of his control, inadvertently spreading the disease to mortals as he fed?
			
			You resolve to ponder this possibility further.
		*else
			*comment TODO more *elseifs here?
			*set anachronism %+5
			You do not see how this affects any of your current concerns, but confronting the reality of microscopic entities in your environment does force you to reexamine some of your own beliefs about how nature functions.
	#@{tick I wonder if this is why Memeskia is so melancholy. What changes to the land and sky has he seen in his centuries of unlife?|I fight back despair.}
		*if tick
			*set investigate_memeskia +0.5
			*set memeskia_rapport %+5
			*set compassion %-5
			You have survived two wars and watched railroads encircle the land. How many wars has Memeskia seen? How many friends and lovers has he lost? What happens to a vampire when the last person who knew them as a mortal dies? Do they become as disconnected as he?
		*else
			*set compassion %-5
			What could you do? Burn down all the factories? That would stop the coal ash for a time, but the mortals will only build new ones.
			
			Is this what immortality is? Watching the decades pass and having so little ability to affect the things around you?
*finish Next