*comment ñáéç…—
*hide_reuse
*advertisement
*if charm > 4
	Unfortunately, something seems to have gone wrong. This game file has been corrupted. You'll need to restart the game from the beginning.
	*restart
*set municipal_debt 0
*temp soaked false
*temp mr_german "Herr"
*temp man "man"
*if male = false
	*set man "woman"
	*set mr_german "Fräulein"
*if priest
	*set mr_german "Hochwürden"
*temp red_indian "red Indian"
*if (ethnicity = "choctaw") or (intelligence > 3)
	*set red_indian "Native man"
You arrive at Schnaider's Beer Garden on Chouteau Ave. There is a wall separating the patrons from the street, but inside those walls the garden is open to the sky and littered with trees. Gaslamps line the walkways of the garden, their flames dancing cheerily in the crisp autumn air.
*if ethnicity = "german"
	@{male You smile at the sight of your people swaying together and swinging their tankards.  It reminds you of your youth in Pennsylvania, though on a much larger scale.|You stare at the ethnic Germans swaying together while singing lustily and swinging their tankards in the air.  Though it was too warm along the [i]Côte des Allemands[/i] for beer-making, still you recall hearing the words at some point in your youth.  It is uncanny to hear these strangers giving voice to your long-forgotten memories.}
*else
	The ethnic German patrons are singing together while swinging their tankards.  It is quite a sight.

[i]Ein Märchen aus alten Zeiten[/i]
*line_break
[i]Das kommt mir nicht aus dem Sinn.[/i]

*if speaks_german
	"A tale known for many a season will not allow me to rest," @{(ethnicity = "german") two lines from [i]Lorelei,[/i] a poem set to music and sung in [i]biergärten[/i] throughout the world.  It tells the story of a boatman of the Rhine who wrecks his dingy on a rock at the beckoning of a golden-haired water-nymph.|or something to that effect, you muse.  Before you can listen any closer, however, you are beckoned towards the rear of the establishment.}
*else
	Though you are tempted to watch the spectacle for a while longer, you are beckoned towards the rear of the establishment.
Tearing your attention away, you make your way through the crowd.

*if agility > 3
	A [i]bierfrau[/i] backs into you, but you steady her without thinking about it.  She smiles in gratitude, and you continue on.
*elseif perception > 3
	In a flash of precognition, you notice a [i]bierfrau[/i] backing into you, and drenching you with beer.  Pausing just in time, she steps directly into your path, and is clearly startled by your presence.  You smile at her—a predatory grin—before moving around her.  She thanks you with her eyes, and returns to her business.
*elseif strength > 3
	A [i]bierfrau[/i] backs into you, but sort of bounces off, unprepared for the supernatural might of your frame.  The tankards she was carrying splash away from you, soaking the patrons around her.  Thankfully, they seem to take the beer-shower in stride, and do not miss even a whole bar of the song.
*else
	*set soaked true
	A [i]bierfrau[/i] backs into you, spilling the contents of several tankards on you.  You pause in frustration, using a dramatic gesture to sweep some of the beer from your clothes.
	
	She looks at you in terror, stuttering an incoherent apology.  @{(compassion > 40) Were others of your kind not waiting for you, you wonder whether you would have been able to resist the urge to take out some sort of vengeance on the poor girl|You feel a strange anger rise in you—how dare she muss your clothes!—but you check yourself. She surely didn't mean it. No need to ruin the poor woman's life over a mistake…or so you repeat to yourself as you set her right and continue on your way}.

The woman who beckoned you is tall, blonde, and buxom.  She does not smile at you when she curtsies. "I am Sigrid, @{speaks_german yes?|[i]ja?[/i]}  If you need anything while you are in the home of Herr Aichinger, I would be happy to provide it to you." @{((speaks_english = false) and (speaks_german = false)) You are surprised that she speaks your tongue.|}

*choice
	#I brush past her.
		*set discretion %+5
		*set compassion %+5
		You wait for her to step aside.  Once she does, you extend the briefest nod of acknowledgment and enter the brewery at the center of the grounds.
	#I greet her.  She is—presumably—human, after all.
		*set compassion %-5
		"It is a pleasure to make your acquaintance, @{speaks_german Miss.|[i]Fräulein.[/i]} I imagine I will be most comfortable under your care," you say with a ${bow}.
		
		She raises her eyes to look at you, her face still 
		*if perception > 2
			impassive, but her energy clearly shifts.  Though you could never tell by just looking her, you can feel how her opinion of you—of her whole night, in fact—just changed.  You smile at her silence, and continue into the brewery at the center of the grounds.
		*elseif perception > 1
			impassive, but her eyes show the smallest hint of softening.  You smile at her silence, and continue into the brewery at the center of the grounds.
		*else
			impassive.  Finding no warmth there, you smile awkwardly and push past her into the brewery at the center of the grounds.
	*selectable_if (discretion > 35) #How dare she address me?
		*set discretion %+10
		*set compassion %+10
		*set aichinger_rapport %-10
		You give her a withering glance.  "I'm sure that if there were anything that I needed, you would be entirely incapable of attending to it."
		
		She does not deign to respond to your dismissal.  You brush past her and push your way into the brewery at the center of the grounds.
	*if (feeding_style = "prostitutes") and (speaks_english or speaks_german)
		#Maybe, for the right price, she might meet me later for a…bite to eat?
			*set aichinger_rapport %-5
			*if charm > 3
				"I do not think Herr Aichinger would like it were I to shirk my duties, ${mr_german}," she says in response to your advances.
				
				You give her a sly grin and continue on into the brewery at the center of the grounds.
			*elseif agility > 3
				Her hand flies up to slap you, but you easily catch her arm.  "I am not that kind of girl," she says, her face still emotionless.
				
				You smile cruelly at her.  "It seems that I struck a nerve.  Perhaps another time, then," you say.  She wrenches her arm from your grasp.  Shrugging, you walk past her and into the brewery at the center of the grounds.
			*elseif strength > 3
				The room does not pause at the sound of the ensuing slap, but Sigrid's face winces in pain.  She was clearly not prepared for the resilience of your immortal frame, and she holds her striking hand gingerly.  "I am not that kind of girl," she hisses, her jaw clenched.
				
				You shrug, and walk past her into the brewery at the center of the grounds.
			*else
				The room does not pause at the sound of the ensuing slap, but the way your world is spinning, you half expect it to.  "I am not that kind of girl," she says, still surprisingly emotionless.
				*if (soaked = false) and male
					But her fury is not yet spent, and to add insult to injury, she tosses the contents of a stein in your face.
				
				When your senses return, you straighten, and do your best to enter the brewery proper with some degree of
				*if (soaked = false) and male
					*set soaked true
					dignity, a task made all the more difficult with beer dripping from your chin.
				*else
					dignity.
*page_break
*temp common_lang 1
*if speaks_english = false
	*if speaks_french
		*set common_lang 2
	*elseif speaks_german
		*set common_lang 3
	*else
		*set common_lang 4
Inside the room,
*if invitation_to_st_louis = "self"
	you spy John Bailey from the Planter's House Hotel. He is engrossed in a conversation with a pasty-skinned, portly fellow, who is mostly bald yet sports a bushy mustache. @{(perception > 2) As well, there is a third vampire, near but not immediately involved in the discussion.|}
	
	"You came!" he exclaims.
	
	"How could I not, Senator?"
	
	"Quite right. We wouldn't want any unpleasantness here. There's been enough of that lately," he sniffs.
	
	At that, the portly vampire coughs. A strange sound, since it is so obviously contrived.
*else
	you @{met_bailey immediately recognize John Bailey, the Senator of St. Louis. He is| see a clean-shaven blond man sitting in an overstuffed chair, deeply} engrossed in a conversation with a pasty-skinned, portly fellow, who is mostly bald yet sports a bushy mustache. @{(perception > 2) As well, there is a third vampire, near but not immediately involved in the discussion.|}
	
	The two stand at your entrance @{male and extend their hands|and bow} in greeting.
	*if met_bailey
		*if status = 0
			"Oh, it's you," Bailey says.
			
			"Me?"
			
			"I'm surprised you would dare show your face around here."
			
			"I'm sorry?"
			
			"Your actions indicate a disregard for the Society and its customs. And yet, here you are."
			*if memphis_bailey_couldnt_communicate and (speaks_english = false)
				Some part of you observes that Bailey has learned @{common_lang ERROR|French|German|Spanish} since you last met, but now does not seem like the time to dwell on the matter.
			
			*if intelligence > 2 
				*set bailey_rapport %+5
				"[i]A vampire without a city is either a god or a beast,[/i]" you say, paraphrasing Aristotle.
				
				"And yet you are neither."
				
				"So then give me a city to belong to," you entreat.
			*else
				"We are social creatures. I am in need of a home."
				
			"We will leave it to Memeskia to decide," he replies.
			
			At that, the portly vampire coughs. A strange sound, since it is so obviously contrived.
		*elseif bailey_rapport > 45
			"It is good to see you again, ${mr} ${surname}," Bailey says. @{(invitation_to_st_louis = "coffin") "Abigail said you were going to stop by."|}
			
			*if memphis_bailey_couldnt_communicate and (speaks_english = false)
				*label sudden_communicate
				You are surprised to hear him greeting you in your tongue.
				*set bailey_rapport %-5
				"You have learned @{common_lang ERROR|French|German|Spanish} since the last we met?"
	
				"Yes. It is important to be able to communciate without intermediaries. I'm surprised you haven't yet learned English, though."
	
				"There is so little time, Senator."
	
				"I suppose."
				
				At that, the portly vampire coughs. A strange sound, since it is so obviously contrived.
			*else
				"And you, Senator.  Though I did not expect it would be so soon after our last encounter."
				
				"Nor did any of us, I suppose," he muses.  Though he makes no overt gesture—that would be far too rude—you suddenly imagine the portly man tapping his foot impatiently.  Bailey seems to have the same epiphany, as he suddenly turns to include the other vampire.
		*else
			"${mr} ${surname}. I did not expect to have the pleasure of your company again so soon.@{(invitation_to_st_louis = "coffin")  You should thank Abigail for speaking on your behalf.|}"
			*if memphis_bailey_couldnt_communicate and (speaks_english = false)
				*goto sudden_communicate
			
			@{(invitation_to_st_louis = "coffin") You nod your head; it seems Senator Coffin has done you a favor, even if it was not judged as such. "|You narrow your eyes at the disingenuousness of these words. "Nor I you, Senator. }Please, would you be so kind as to introduce us…" you say, indicating the portly third ever so subtly.
	*else
		"You must be ${given_name} ${surname}," the blond begins.  "I am John Bailey, Senator of St. Louis.@{(invitation_to_st_louis = "coffin")  Abigail said you'd be coming.|}"
		*set met_bailey true
		*set heard_of_bailey true
		
		"A pleasure, sir," you reply graciously.
		
		*if status = 0
			"For you, perhaps. What is a reprobate such as yourself doing on my doorstep?"
			
			"Seeking a home, Senator."
			
			"You have lost the respect of the Society, and yet you wish to live among us?"
			
			"I do, Senator."
			
			He considers. "We shall let Memeskia consider this." 
			
			At that, the portly vampire coughs. A strange sound, since it is so obviously contrived.
		*else
			"It was unfortunate that we did not have the opportunity to meet in Memphis; I would have thought you would have attended the caucuses there."
			
			*if second_memphis_caucus_attended and first_memphis_caucus_attended
				"In fact, I attended both!"
				
				"And yet we did not meet? Well, there were so many of our kind there."
				
				"Yes, there were."
				
				At that, the portly vampire coughs. A strange sound, since it is so obviously contrived.
			*elseif first_memphis_caucus_attended
				"In fact, I attended the one in '73."
				
				"Oh, yes, perhaps I did spy you there. Misfortunate that we were not introduced."
				
				"Yes."
				
				At that, the portly vampire coughs. A strange sound, since it is so obviously contrived.
			*elseif second_memphis_caucus_attended
				"In fact, I attended the one in '77."
				
				"Oh, yes, perhaps I did spy you there. Misfortunate that we were not introduced."
				
				"Yes, misfortunate," you reply. "But I believe…" you begin, indicating the portly one.
			*else
				"I was otherwise occupied, Senator.  There were…problems that needed to be addressed."
				
				"If that is the case, I imagine that Quaestor Carothers misses his agent, now that you have come here."
				
				"If he misses me, I have seen no evidence of it. Rather, he demanded that I leave the city."
				
				"Yes, the plague. Of course. Unfortunate matter, that."
				
				"But we must move forward," interjects the portly one.

*if ethnicity = "german"
	*set aichinger_rapport %+25
*set met_aichinger true
*temp whiskey_involvement_disclosed false
*if heard_of_aichinger and ((discretion >= 55) and whiskey_ring_plot)
	*set whiskey_involvement_disclosed true
	"Yes, allow me…" he begins.
	
	*if (whiskey_ring_status = "exposed") or ((whiskey_ring_status = "merodach") or ((whiskey_ring_status = "blocked") or (whiskey_ring_status = "limited")))
		
		"Lothar Aichinger? Of the Whiskey Ring?"
		*set aichinger_rapport %-15
		
		There is a moment of tension in the room, as each of the vampires present piece together your involvement in the downfall of the Whiskey Ring.

		*if (whiskey_ring_status = "merodach")
			*set aichinger_rapport %+10
			Finally, Aichinger gives a single laugh. "Using that clergyman was quite clever, ${mr} ${surname}."
			
			"Thank you, sir," you reply, feeling a bit of the tension drain from the room.
		
		Aichinger @{(whiskey_ring_status != "merodach") is the one to finally break the silence.|gives a small nod of approval before continuing.} "As I was saying, the successes of yesterday are behind us."
	*else
		*set aichinger_rapport %+10
		
		"Herr Aichinger, I imagine?" you interject. "The mind behind the Whiskey Ring?"
		
		Aichinger chuffs in surprise or pleasure, you can't be quite sure which. "[i]Ja,[/i] this is true."
		*if (whiskey_ring_status != "none")
			*set aichinger_rapport %+10
			He pauses for a moment. "And you are ${mr} ${surname}? I should thank you for your contributions to the cause."
		
		"A real pleasure, sir," you say with a ${bow}.
		
		"Yes, well, as much as I would like to…think backwards?…we must move forward. The successes of yesterday are behind us," Aichinger continues.
*else
	"Of course," Bailey says, chagrined.  "Allow me to introduce Lothar Aichinger, a citizen of St. Louis."
	*set heard_of_aichinger true

	"A pleasure, sir," you say with a ${bow}.

	"Welcome to St. Louis, ${mr_german} ${surname}.  As I was saying, though, we must move forward.  No use to…think backwards?"

"I'm sorry?"

"The dead are dead.  We can do nothing for them.  We must do our best to improve the conditions of the living, instead."
*choice
	#"I couldn't agree with you more, Herr Aichinger."
		*set aichinger_rapport %+10
		*set anachronism %+10
		He looks a little startled by your quick assent, as though he was prepared to expound on his position quite a bit further.  In the moment that Aichinger takes to regroup, however, Bailey interjects.
		
		"Improve the conditions of the living? To what end? To sweeten their blood, I hope!" Bailey gibes.
		
		Aichinger growls at Bailey. You get the sense that the two of them have had this conversation many times before. Before the interaction can get any more fraught, however, you try to redirect its flow. "Tell me, Mr. Aichinger. Is this your establishment?"
		
		Aichinger calms a little, turning away from Bailey and towards you. "[i]Ja,[/i] this is true. Joseph Schnaider and I have an agreement, you understand."
		
		"It is…quite the establishment!" you exclaim.
		
		"@{speaks_german Thank you.|[i]Danke.[/i]} Wait until you have the chance to see an operetta! They come from Bavaria and the Rhineland to perform here," he says, swelling with pride.
	#"We should both honor and remember the dead.  It is due to their efforts that we find ourselves where we are today…"
		"That's all well and good, ${mr_german} ${surname}, but we honor them best by continuing to build on their efforts, not by sitting about, gazing at our navels and lamenting days gone by!"
	#"And what of us?  Can we vampires do nothing?  Or, rather, can nothing be done for us?"
		*set aichinger_rapport %-10
		*if (status = 0) and (aichinger_rapport < 60)
			"@{speaks_german Bah!|[i]Ach.[/i]}  I have heard of this one," he says to no one in particular.  "Do not be dense, ${mr_german} ${surname}.
		*else
			He smiles politely at your jest.  "@{speaks_german Not at all.|[i]Nacht[/i].} You know what I mean, ${mr_german} ${surname}.
		There is no point in dwelling over-long on the mistakes of the past, except in considering how the study of them might be used to surmount future obstacles.  But what can be done about a plague?  You bury the dead and move on.  Enough of this wailing and moaning."
			
		"Wailing and moaning that has emptied a city of her people, and even disrupted an election for the Senate?"
		
		"Yes, ${mr_german} ${surname}, this too shall pass.  We shall live forever.  It seems that you—and Quaestor Carothers, I surmise—need to start thinking like it."

Before you can say anything more, a slight noise brings all the attention in the room to @{(perception > 2) the third individual, whom you had not previously noticed.| a third individual, whom you had not previously noticed.} Bailey gestures towards him. "Oh, and of course, Mr. Eliot.  Hiram, please meet ${mr} ${surname}."  He is a man of average height, clean-shaven, with dark brown hair with a severe part, a wide face, and a large nose and ears.  He must have been turned in his late twenties, as he retains a youthful vigor.
*set heard_of_eliot true
*set met_eliot true

You greet Hiram with a ${bow}.  "A pleasure to make your acquaintance, ${mr} ${surname}," he replies.

*if (independence >= 40) or (discretion <= 60)
	*set bailey_rapport %+5
	*set aichinger_rapport %+5
	"The pleasure is all mine, Mr. Eliot," you say politely.
*else
	*set bailey_rapport %-10
	*set aichinger_rapport %-10
	*set eliot_rapport %-10
	"You have only just met me.  I'd recommend withholding your judgments a while yet."
	
	The other three vampires look at you, surprised by your rudeness.
"If I may," you say, changing the subject.
*if heard_of_memeskia
	"Quaestor Memeskia…" you search for the right words. 
*else
	*set heard_of_memeskia true
	"Who is the Quaestor of St. Louis?"
	
	"Quaestor Memeskia, of course," Bailey replies.
	
	"Memeskia? What sort of name is that?"
	
	There is a moment of silence. "He is a Native of this land," Bailey replies.
	*line_break
	*line_break
"I have not heard of another Native Quaestor. How did he come by his position?"
	
Aichinger chuffs. Eliot looks away. Finally, Bailey answers your question. "Quaestor Memeskia is old. He has been a vampire since before Columbus discovered the Caribbean."

*if (intelligence > 1) and (lore > 2)
	You have to wonder, what does this mean for the history of your kind? Where did vampirism originate? Who was Quaestor Memeskia's dominus, if he was a vampire before Europeans came to the Americas?
Just then, another door to the room opens; you had not previously noticed it. And yet, there is now a ${red_indian} standing before you. He wears tan trousers and a dark vest over a white shirt.  The only indications of his ancestry are the simple red cloth wrapped around his head, which keeps his black, unshorn hair out of his face, and a pair of earrings. He does not introduce himself, but you assume this must be Memeskia, Quaestor of St. Louis.

He studies you carefully.
*temp chickasaw false
*if soaked
	*set memeskia_rapport %-5
	If he is affected by your beer-stained clothes, he does not show it.
*choice
	*if ethnicity = "choctaw"
		#I am an interpreter: I try to greet him in one of the Illiniwek tongues.
			*if (intelligence >= 3)
				*set memeskia_rapport %+25
				*set chickasaw true
				Though you do not address him in the tongue of his tribe, the dialect your choose is close enough—and your command of it sufficiently fluent—that you make your introduction with clarity and confidence.
				
				He nods his head at your words, and greets you in turn.  He is clearly impressed by both you your effort. However, he switches to Chickasaw, which you are much more comfortable with.
			*else
				Unfortunately, you never were very good with the Illiniwek verbs.  
				*if memeskia_rapport > 55
					Thankfully, he takes your efforts in good humor, and greets you in turn, offering subtle hints as to how you might have better phrased your greeting.
				*else
					He remains stone-faced, and returns your greeting in English.  Apparently, your mastery of the Illiniwek tongues was not as great as you remembered.
	#I wait for him to speak before introducing myself.
		*set discretion %-10
		*set memeskia_rapport %+10
		*if status = 0
			Senator Bailey clears his throat. "Quaestor, this is ${given_name} ${surname}, scion of ${sire_name}." You ${bow}. "$!{he} has been deemed disgraced in the eyes of the Society."
			
			Is this it? Will Memeskia put an end to you here and now?
			*page_break
	#I introduce myself.
		*set independence %-5
		He listens to you, stone-faced, as you introduce yourself.
		*if status = 0
			*set memeskia_rapport %-10
			*set bailey_rapport %-10
			"You speak when you ought to remain silent, ${mr} ${surname}.  It seems that you still have much to learn."
			
			"Forgive me, Quaestor."
			
			He seems molified by your laconic response.  At least, you hope so.  It is difficult to tell.
		*else
			He considers your introduction for several moments before responding.
	*if (invitation_to_st_louis = "bailey") or (bailey_rapport > 65)
		#I look to Senator Bailey; perhaps he will introduce me?
			*set memeskia_rapport %+15
			After a period of observation, you begin to wonder whether you have made the wrong choice.  However, just as you move to make an introduction, Bailey intercedes.  Probably for the better.
			
			He introduces you, pointing out that you were lately a citizen of Memphis, driven out by the misfortunes that had so recently befallen that place.
			
			Memeskia listens to all this impassively.  Once Bailey falls silent, you take it upon yourself to express your own gratitude.

"Welcome to St. Louis, ${mr} ${surname}."
*set presented_st_louis true
*temp m_sib_rumors false
*if sire_name = "West"
	*set m_sib true
	*set memeskia_rapport %+20
	*set shepherd_credentials %+10
	*set revolutionary_credentials %-25
	There is a pause. "Have you seen our dominus?"
		
	@{chickasaw The rest of the room, unable to understand the exchange, do not grasp the enormity of what was just said.|Everyone in the room grows unnaturally still, as only a room full of unliving predators can.} "Excuse me, Quaestor…our dominus?"
	
	"Are you not the scion of West?"
	
	"Yes, but…"
	
	"Then we are broodmates. Have you seen him?"
	
	*if patricide or fled_from_sire
		"Not since the Battle of New 
		*if rumors_of_west or rumors_of_west_dead
			Orleans…but I heard it whispered that he was somewhere near St. Louis?"
			*label rumor
			
			Memeskia frowns. "There is something in the countryside, yes."
			*set m_sib_rumors true
			
			You wait for something more, but he offers nothing.
			*goto other_departure
		*else
			Orleans…"
	*else
		"Not since we parted ways somewhere in Texas, in 1823. But I have heard it whispered that he was somewhere near St. Louis?"
		*if rumors_of_west or rumors_of_west_dead
			*goto rumor
	
	Memeskia stares at you for a long time, as though trying to divine the contents of your soul. 
	*label other_departure
	Finally, he shakes his head and departs.
	
	*if chickasaw
		"What was that about?" Bailey inquires.
		
		"It seems the Quaestor and I are broodmates," you reply.
		
		Eliot's eyes widen. "Welcome home?" he suggests tentatively.
		
		"I could have told you that," Bailey sniffs to himself.
		
		Eliot ignores Bailey. "The Quaestor is not much of a conversationalist, is he?"
	*else
		If Eliot, Bailey, or Aichinger breathed, you suspect that they would be exhaling now.
		
		Aichinger is the first to speak. "You didn't know?"
		
		"No, certainly not."
		
		"I did," Bailey interjects, rolling his eyes.
		
		"Once again, the Senator establishes just how good he is at his vocation," Aichinger says to no one in particular. He returns his gaze to you. "The Quaestor does not indulge in the pleasures of conversation, does he?"
*else
	There is a pause.  In previous iterations of this formal greeting, quaestors have normally asked several questions or demanded certain concessions.  Memeskia seems to have no intention of doing either.
	*choice
		#"Thank you, Quaestor.  I promise to uphold the Three Rules and do my best to serve you during my time here."
			*set independence %+10
			*if revolutionary_credentials > 55
				*set bailey_rapport %+10
				You notice a slight nod of approval from Bailey at this formality.
			*elseif revolutionary_credentials < 45
				*set bailey_rapport %-10
			
			"I hope that you do not come to regret your promises, ${mr} ${surname}."
		*selectable_if (discretion > 25) #"Thank you, Quaestor.  But have you no questions for me?"
			*set independence %+10
			*set discretion %+10
			*set aichinger_rapport %+10
			*set memeskia_rapport %-10
			"A ${man} is as ${he} does, not who ${he} was, or who ${he} says ${he} is. Words are breath, and as you know, we have no further need of that."
		*selectable_if (discretion < 70) #"Thank you, Quaestor."
			*set discretion %-5
			*if revolutionary_credentials > 55
				*set bailey_rapport %-5
			A simple answer for a simple greeting.
		*selectable_if (discretion < 60) #I simply wait.
			*set discretion %-5
			*set memeskia_rapport %+10
			*set bailey_rapport %-5
			*set aichinger_rapport %-5
			*set independence %-5
		*if (rumors_of_west or rumors_of_west_dead) #"You say that there is something in the countryside; but what of the rumors that West…our dominus…has gone mad?"
			*set discretion %+5
			*set independence %+5
			The room stills. Memeskia looks at you studiously.
			
			"What do you think of these rumors?"
			
			"I…well, I have not seen him, so I cannot say one way or another…"
			
			"Nor have I," Memeskia replies.
			
			You pause, waiting for him to continue. But he doesn't.
	
	Apparently satisfied, Memeskia turns and leaves by the same way he entered.
	
	"@{speaks_german Yes,|[i]Ja,[/i]} welcome to St. Louis," Aichinger says, once Memeskia has departed.  "He does not much enjoy the pleasures of conversation, does he?"

*choice
	*selectable_if (independence < 75) #"I appreciate his brevity," I reply.
		*set independence %-10
		*set aichinger_rapport %-5
		*set bailey_rapport %-5
		Aichinger and Bailey both look at you.
		*if status = 0
			What should they expect, though, of one who has so shirked the customs of the Society?
	*if m_sib = false
		#"No, not at all.  Does he receive other members of the Society with such brusqueness as well?"
			*set aichinger_rapport %+5
			*set bailey_rapport %+5
			"Depending on the guest, he makes an effort to be more accommodating.  But that was the real Memeskia," Aichinger replies.
			
			"I suppose I should be flattered?"
			
			"Yes, quite," Bailey replies.
	*if m_sib
		#"Perhaps he was as shocked as I?"
			*set compassion %-5
			*set discretion %-5
			Aichinger smirks. "Perhaps."
			
			"I think I might have learned more about our dear Quaestor in the past five minutes then in all my years of living in St. Louis," Hiram interjects.
			*if perception > 1
				Out of the corner of your eye, you notice Bailey smirk at this.
	#"He is the Quaestor.  I suppose he can conduct his affairs as he wishes."
		*set discretion %-10
		*set aichinger_rapport %-5
		*set bailey_rapport %+5
		Apparently, that was not what Aichinger wanted to hear.  But he does a fair job of hiding his displeasure.
	*if (rumors_of_west or rumors_of_west_dead) #"Is he not concerned about these rumors of West's madness?"
		*set independence %+5
		"Without evidence to support them, I think we all prefer to hope that these rumors are unfounded."
		
		"Is the possibility truly so terrifying?"
		
		"@{speaks_german Yes,|[i]Ja,[/i]} it is."
		
@{m_sib Thinking it best to change the subject, you cast about for a new topic.|} "Are there any others of our kind in the city?" you inquire.

@{m_sib Bailey and Aichinger look at one another.|} "Yes…well, after a fashion. Sabine Bécard resides in Jefferson City, but she is considered a part of Memeskia's court," Bailey answers. "She is the offspring of the Quaestor."
*if m_sib
	
	You try to disguise your shock. "A broodmate and their offspring? My family has grown beyond my comprehension in the course of a few minutes!"
	
	"Quite," replies Aichinger.
	
	The subject of your bloodline having once again silenced the room, you decide to change the topic to mortal affairs.
*else
	
	"And no others?"
	
	"Not of late, no."
	
	You decide to let that remark remain unexamined, directing the conversation to mortal affairs instead.
*if heard_about_great_railroad_strike
	"Does he involve himself with the mortal world?  The occupation of St. Louis by the railroad workers would seem to suggest no," you inquire.
	
	"No, he does not trouble himself overly with the mortals," Bailey replies.
	
	"Which is most unfortunate.  When the workingmen are not supervised, they are given to mischief," Aichinger adds.
	
	"I would not exactly call their protests mischief," Bailey replies.
	
	"What would you call them, then, Senator?" Aichinger says.
	
	"A legitimate response to a grievance."
	
	"Legitimate?  They immobilized the country for a month!  The workingmen
*else
	*set heard_about_great_railroad_strike true
	"From what little I have seen, St. Louis appears to be a lovely city."
	
	Aichinger rolls his eyes.  "When it is not being occupied by the communists."
	
	"Pardon me?"
	
	"Did you not hear about the Great Railroad Strike last year?"
	
	"No, I can't say that I did."
	
	"It began in the east, around the Cumberland Narrows, where the Baltimore & Ohio Railroad crosses the Appalachians.  Railroad workers struck for weeks, taking over the railroad yards.  There was a mass revolt in Baltimore, but when the Governor of Maryland tried to send the National Guard to quell the strike, the people of Baltimore blockaded the railroad yard there and prevented the militia from traveling west to the site of the strike.  Soon, the strike spread to other cities: Cleveland, Chicago, and here.  They took over the whole city!"  He pauses a moment to reflect.  "@{speaks_english [i]Ach,[/i]|Alas,} it was 1848 all over again," he says, somewhat more subdued.
	
	Now Bailey rolls his eyes.  "After that travesty of a presidential election, what could you expect?  The Republican party is corrupt to its core, as you yourself have fostered!  And when the railroad lowered their wages, did you expect the workers to quietly acquiesce?"
	
	The rolling of Eliot's eyes confirms your suspicion that this is a quarrel these two vampires have engaged in several times before.
	
	"The workingmen
must be shown that their antics are an impediment to progress!" Aichinger asserts.

"An impediment to progress?  The sort of progress that produces the Whiskey Rings?"

"The ends justify the means, Senator."

"And anything done in the name of progress is justifiable."

"Yes, quite," Aichinger retorts.

"What were their demands, if I might inquire?" you say, in an attempt to calm their tempers.

"They were demanding that their work day be halved, from sixteen to eight hours.  A restoration of the 10% paycut.  And an end to the employment of children in factories.  A totally unreasonable list of demands," Aichinger thunders.

Bailey winces, clearly outmaneouvered by the list of the protestors' extraordinary demands.  "At least the railroad could have reversed the 10% paycut…" he says, before trailing off.

Thrilled with his victory, Aichinger turns to you.  "And what do you think we should be doing about these lawless peasants, ${mr} ${surname}?"
*label saw_choice
*choice
	#"I find myself in agreement with the Quaestor: we should leave the mortals to their own devices."
		*set shepherd_credentials %-20
		*set eliot_rapport %-5
		*set aichinger_rapport %-5
		*set bailey_rapport %-5
		*set memeskia_rapport %+15
		*set discretion %+5
		*set anachronism %-5
		"To their own devices?" Bailey replies.
		
		"Yes. Let us live out our existence, and let them lead theirs."
		
		"You are not concerned about them discovering us?"
		
		"We are immortal. We can simply relocate to a new city. @{knows_about_torpor Or even go to sleep for a time.|} They pose no danger to us—and so they are not worthy of consideration."
		
		Your position on the matter is a bit extreme, even for Bailey. All three seem displeased, though to differing degrees. @{((discretion > 60) or (independence < 50)) Not that you particularly care what they think.|}
	#"I find myself in agreement with the Senator: we should be involved with the mortals. They exist to satisfy our needs."
		*set shepherd_credentials %-5
		*set compassion %-10
		*set bailey_rapport %+20
		*set aichinger_rapport %-5
		*set eliot_rapport %-25
		*set memeskia_rapport %-5
		Eliot seems disgusted by your position on the matter, while Bailey nods approvingly. Aichinger, however, has a more mixed reaction.
	#"I find myself in agreement with Mr. Aichinger: we should be involved with the mortals.  They are lost without our guidance."
		*set shepherd_credentials %+20
		*set compassion %+5
		*set discretion %+5
		*set aichinger_rapport %+20
		*set bailey_rapport %-10
		*set memeskia_rapport %-5
		*set eliot_rapport %-5
		Aichinger seems pleased by your position on the matter.
	#I try to deflect the question.
		*set discretion %-10
		*if (charm > 3) or (status > 2)
			You cleverly evade their questions, leaving them unwilling or unable to press you further on the matter.
		*else
			Unfortunately, they will not let you evade their interrogations so easily.  It seems you must take some sort of stand.
			*goto saw_choice

*if whiskey_ring_plot and ((whiskey_involvement_disclosed = false) and (whiskey_ring_status != "none"))
	"Now, tell me, @{male [i]Herr[/i]|[i]Fräulein[/i]} ${surname}. Are you the same @{male [i]Junge[/i]|[i]Fräulein[/i]} that
	*if (whiskey_ring_status = "joined") or (whiskey_ring_status = "encouraged")
		@{(whiskey_ring_status = "joined") joined|aided} the Whiskey Ring in Memphis?"
		*set aichinger_rapport %+10
		
		You purse your lips; there is no point in lying. "I am, Herr Aichinger."
		
		"Well, it was effective while it lasted," he says, nodding in approval. "Thank you for your efforts. They were appreciated."
		
		"My pleasure, sir."
	*elseif (whiskey_ring_status = "exposed") or ((whiskey_ring_status = "merodach") or ((whiskey_ring_status = "blocked") or (whiskey_ring_status = "limited")))
		interfered with the Whiskey Ring in Memphis?"
		
		@{(discretion < 50) You are not accustomed to such direct confrontations, especially in the company of other vampires.|You bristle at the challenge.} "I am." The other vampires in the room have fall silent, as only a pack of predators in the presence of potential violence can.
		
		*if (whiskey_ring_status = "merodach")
			*set aichinger_rapport %-5
			Aichinger lets out a small chuckle. "That trick with the clergyman. That was quite clever of you."
			
			You can feel the tension drain from the room. "Thank you, Herr Aichinger."
		*else
			*set aichinger_rapport %-15
			*if (status > 1) and ((whiskey_ring_status = "blocked") or (whiskey_ring_status = "exposed"))
				"Your maneouvers were effective. I cannot deny that."
				
				@{(discretion > 50) "Well, once I noticed the falsified bills of lading, which were really rather sloppily done…"|"It was no simple task…"} you begin, but he cuts you off.
				
				"I hope that, now that you are here, we will work together, rather than against each other."
				
				"I hope so as well, Herr Aichinger."
			*else
				"I trust that you have learned to not involve yourself in affairs that are not your own?" @{(discretion > 50) Your blood boils in your veins and you feel your face getting flushed.|} You grit your teeth and nod. "Good. Now, let us put this behind us."
				
				"Yes, let us."
	*page_break
*if (debt_from_coffin = false) and (lesczynski_out and offer_to_help_coffin_stop_ascher)
	*set coffin_contactable true
	*set debt_from_coffin true
	*set coffin_rapport %+20
	*set aichinger_rapport %+10
	*set eliot_rapport %+10
	*set bailey_rapport %-5
	"Oh, I almost forgot…" begins Bailey, reaching into his suit.  "I received this letter from Senator Coffin.  It seems that she had no way to contact you directly."
	
	The eyebrows of both Aichinger and Eliot raise at this.  To have a letter from the senator of another city waiting for you at your new home clearly impresses them.
	
	"Thank you, Senator," you say, taking the letter.
	
	"Go ahead," Bailey prompts, as you fumble with it, unsure as to what to do.
	*if status = 0
		*set status +1
	*if literate
		Opening it, your eyes scan the contents.  To begin, she thanks you both for warning Senator Lockridge about the resurgant plague, before turning to praise you for seeing to it that Mr. Lesczynski will never be Senator of Memphis.  You are not certain that she is correct in that conclusion, but her subsequent acknowledgment of a debt pushes those particular thoughts out of your head.
		
		A grin breaks out on your face.  A debt from a senator!  That is quite a prize indeed. @{(independence < 35) You're actually a little disgusted by the thrill that courses through your body at the news.  You have often sought to distance yourself from the machinations of the Society, and here you find yourself rejoicing in them.|}
		
		"Good news?" Bailey observes.
		
		"The good Senator acknowledges a debt incurred.  That is all."  All three of your companions find themselves shocked into silence.  
		
		After a moment, Bailey finds his tongue again.
	*else
		*set bailey_rapport %-5
		"I…I cannot read, Senator."
		
		Bailey seizes the letter from your hands and tears it open.  "She thanks you for the warning that you conveyed to Senator Lockridge in August about the resurgance of the yellow fever.  She goes on to…to praise you for a service you did her.  She further acknowledges a debt owed in exchange for this service.  She concludes by offering a way to contact her, should need to do so in the future."
		
		A grin breaks out on your face.  A debt from a senator!  That is quite a prize indeed. @{(independence < 35) You're actually a little disgusted by the thrill that courses through your body at the news.  You have often sought to distance yourself from the machinations of the Society, and here you find yourself rejoicing in them.|}
	
	"I trust I will not need to serve as your postbox again, ${mr} ${surname}?"
	
	"I…I apologize, Senator."  With that, you try to turn the conversation to more mundane things.
	*page_break
*if (lore > 2) or knows_about_territories
	*set knows_about_territories true
	Being new to the city, you will soon have to establish a home for yourself. As you well know, vampires can be quite territorial. The safest thing to do is to simply ask if there are portions of the city that have been claimed by one or another of your kind.
	*set bailey_rapport %+3
	
	"Pardon me," you begin. "I will need to…put down roots somewhere, and soon."
	
	Bailey's eyes light up. "So you will!"
	
	"I would not want to tread on anyone's toes.…"
	
	"Certainly not!" Bailey confirms.
	
	"Therefore, please tell me: what neighborhoods have been claimed?"
	
	"Well, I'm sure you will be surprised to hear that Aichinger has laid claim to Dutchtown. But also to the neighboring Soulard and Lafayette Square," Bailey wrinkles his nose at this. You suspect it's a sore subject. "I, on the other hand, have laid claim to Downtown, Midtown, and Chestnut Valley."
	
	Thinking it over in your head, you reply, "And what of the Kerry Patch? Or across the river in East St. Louis?"
	
	"You are welcome to establish yourself in either of those places without…incurring any debts."
	
	"Thank you, Senator."
	
	Whereupon the conversation turns to less contentious topics for a while.
	*page_break
*if bailey_rapport >= aichinger_rapport
	
	Bailey manages to get you alone for a few moments. "You should be careful around Aichinger. In addition to the Whiskey Rings, he was instrumental in the recent Great Divorce."
	
	"Great Divorce?"
	
	"Yes. Two years ago, the City of St. Louis and the County of St. Louis became two separate entities, with the City of St. Louis its own county. The whole affair is a disaster."
	
	"Why would he do that?"
	
	"He was angry that he did not control the County Court, and so he rent the whole thing asunder!"
	*if intelligence > 2
		*set bailey_rapport %-5
		That would be quite a feat, and one that you are suspicious of. How could one vampire convince so many humans to make such a significant change? You suspect that Bailey is either lying, deluded, or paranoid.
	
	"Why would the mortals agree to this?"
	
	"Oh, they were complaining about taxation and home rule and such. They did not recognize the value of a well-governed whole."
	
	*if (((ethnicity = "african") or (ethnicity = "choctaw")) or (shepherd_credentials > 80)) and (compassion < 55)
		"And who ran this well-governed whole?"
		
		"The landowners, of course."
		
		"The white landowners?"
		
		"Who else?" Bailey says, looking at you quizzically.
	
	*choice
		#"I will be sure to offer him a wide berth."
			*set bailey_rapport %+5
			*set aichinger_rapport %-5
			*set revolutionary_credentials %+5
			"I'm so glad to hear it," he replies.
		#"Would it not be possible to heal the rift between the two?"
			"Certainly not as long as the city continues in its demands. The city wants to govern the county! That's like asking fieldhands to run a plantation."
			
			*if (status > 0) and ((ethnicity = "african") and (discretion > 45))
				*set bailey_rapport %-5
				*set revolutionary_credentials %-5
				"In my experience, the fieldhands know more about the plantation than the owners."
				
				Bailey suddenly goes cold. "Well, I see that my concerns have fallen on deaf ears."
			*if (status = 0) or ((ethnicity != "african") or (discretion <= 45))
				*set bailey_rapport %+5
				"And that's why the previous system worked so well? Because the fieldhands…stayed in the city?"
				
				"Exactly! I'm so glad you see it my way."
		#"Perhaps the two are better separated?"
			*set bailey_rapport %-5
			*set aichinger_rapport %+5
			*set independence %-5
			*set discretion %+5
			Bailey recoils at the suggestion. "I know you have only just arrived in St. Louis, ${mr} ${surname}, but perhaps you should take a moment to acquaint yourself with the community and its most esteemed members before you opine on it."
			
			"I will take that under advisement, Senator," you reply.
	
	Noticing that Aichinger and Eliot are rotating back into earshot, you quietly thank Bailey for his counsel.

	"Have you found a new home yet, Senator?" Eliot inquires as he and Aichinger rejoin you.
		
*else
	
	Aichinger manages to get you alone for a few minutes, away from the prying ears of Bailey and Eliot. "You must be careful around Senator Bailey," he whispers conspiratorially.
	
	"Oh?"
	
	"He says that he is on the side of the people—you heard him!—but he is not. He wants to be in control, and he sees people not like him as being necessarily out of control."
	*comment basically, Bailey is a white supremacist, and Aichinger is a die-hard capitalist. Aichinger believes in capitalism because he believes it will make the world better, and is more than willing to overlook its failings the pursuit of the larger goal.
	
	"And his support of the Uprising?"
	
	"Totally feigned. He supports the Democrats, who seek to end Republican rule. He will support anything that can help him achieve that. That is why he defends the County."
	
	"The County?"
	
	"Yes. Here in St. Louis, just before the Uprising—two years ago, now—we went throught the Great Divorce, where the City split away from the County of St. Louis, and now the two are neighbors, not one…[i]Meister[/i]…to the other. This is better for the City, and much worse for the County."
	
	"How so?"
	
	"Police, fire, schools, roads…the city was paying money to the County, and the County was using that money for the territory outside the city. The city then had to levy its own taxes to provide those services, so the residents were paying twice but only benefitting once. Clearly unfair and unjust…but very profitable for those in the County."
	
	*choice
		#"Does no one support the actual workers?"
			*set laborvscapital %+10
			*set shepherd_credentials %+10
			"Workers are there to work. They are replaceable. If they did not wish to be workers, they would refashion themselves into capitalists. No one is on their side, not even themselves. If you ask a worker what he wants, he tells you that he wants to become [i]der Meister.[/i]"
			
			"But…"
			
			"Do not waste your energy even thinking of them. I don't."
		#"Would it be possible to heal the rift between the city and the County?"
			Aichinger ponders a moment. "In principle, yes. A more equitable process for determining the seats on the County Court could be found. But at this point, there is so much animosity between the two sides that I cannot imagine the mortals would consider any such proposal."	
		#"I will be sure to mind my tongue around him."
			*set aichinger_rapport %+5
			*set bailey_rapport %-5
			*set revolutionary_credentials %-5
			"[i]Ja, gut.[/i] That is wise."
	
	Noticing Bailey and Eliot rotating back into earshot, you quietly thank Aichinger for his advice.

	"But have you found a new home yet, Senator?" Eliot says, just as the other two vampires rejoin you and Aichinger.

Bailey glares at Eliot, who withers under that gaze. "Yes, I have returned to the Planter's House Hotel. It is, at least, familiar."

"I'm sorry, Senator, I meant no offense…" he says.

"I'm sure you didn't, Hiram."

Later, when you have a moment alone with Eliot, you inquire after the eruption by Bailey.

"The Senator spent much time at the Southern Hotel. It was a magnificent institution, replacing Planter's as the most impressive hotel of the city. But it burned to the ground a year and a half ago. As he mentioned, he as been forced to return to Planter's for the time being."

*choice
	#"Do you think it was an attack on the Senator?"
		*set independence %+5
		*set discretion %+5
		He searches your eyes for something.
		*if (revolutionary_credentials > 60) and (eliot_rapport > 60)
			*set aichinger_southern_hotel true
			His decision made, he eyes the back of Aichinger's head meaningfully.
			
			You furrow your brow in disbelief.
			
			He shrugs as if to say, who else?
			
			You nod ever so slightly.
		*elseif revolutionary_credentials > 60
			*set aichinger_southern_hotel true
			"Senator Bailey is one of the more outspoken supporters of Consul Stone in this region—and I could imagine many of our kind might wish to prosecute him for it."
			
			"But who…"
			
			"There is only one Loyalist in St. Louis…" he says, looking meaningfully in the direction of Aichinger. You furrow your brow and then open your mouth to speak, but Eliot shushes you. "Another time."
			
			After a moment, you nod.
		*elseif eliot_rapport > 60
			"Dear ${given_name}—as much as I enjoy your company, you have not made yourself out to be an ally of the Senator and his cause. I feel it would out of turn for me to opine on such a matter."
			
			"Very well," you reply.
		*else
			"Whatever would make you say that?" he says evasively.
			
			"Well, if the Senator…"
			
			"I leave you to draw your own conclusions, ${mr} ${surname}."
	#"A year and a half ago? Wasn't that just after the Great Divorce?"
		*set shepherd_credentials %+5
		"So it was."
		
		"Might it have had something to do with that?"
		
		"If you mean, did the élites of the county set fire to the hotel in retribution for the Divorce, I would say not. It was one of their favorite social clubs."
		
		"Perhaps the people of the city targeted the élites? Seeking to expel such a club from the city?"
		
		"I doubt it. 
		*if revolutionary_credentials > 60
			*set aichinger_southern_hotel true
			If anything, I would suspect it was an attack on the Senator."
			
			"An attack on the Senator?"
			
			Eliot eyes Aichinger meaningfully. "Best not to continue this discussion here," he finishes.
		*else
			Too many residents of the city found it a useful place to conduct business as well," he says.
			
			"Perhaps it was simply an accident."
			
			"Perhaps," he says, unconvincingly.			
	#"Did everyone make it out alive?"
		*set compassion %-5
		"Alas, no. At least two dozen people perished, mostly housekeepers who were suffocated in the basement before an alarm was raised."
		
		"How terrible! Did they find out what caused it?"
		
		"They say it was the furnace."
		
		"You seem unconvinced."
		
		*if eliot_rapport > 60
			"Perhaps I am."
			
			You look at him. "What are you…"
			
			He shakes his head no. Not now, he means.
		*else
			"What else could it be?" he says, before excusing himself.
*if (fayette_railroad_bonds = "dissuaded")
	*set aichinger_rapport %+25
	*page_break
	"One last thing, ${mr} ${surname}," Aichinger says, as things begin to wind down.
	
	"Yes?"
	
	"I have heard it said that an individual fitting your description was responsible for dissuading a pack of Klansmen from lynching some Republican officials and a railroad executive outside of Memphis a few years back.  Was you, in fact, that individual?" Caught somewhat off-guard, you are just about to ask for further details when Aichinger cuts you off.  "I knew it had to be you.  It really is good to finally meet you.  I have to say, you handled that masterfully." @{male He claps you on the back.|He pats your hand.} It's been a while since you've been praised and patronized with the same gesture.
	*page_break
*if (fayette_railroad_bonds = "shapeshifting")
	*set aichinger_rapport %+25
	*page_break
	"One last thing, ${mr} ${surname}," Aichinger says, as things begin to wind down.
	
	"Yes?"
	
	"I have heard it said that a pack Klansmen were intent on lynching some Republican officials and a railroad executive outside of Memphis a few years back, but when it came time, their horses refused to obey them.  Darnedest thing, wouldn't you agree?  I don't suppose you were involved with that?" Caught somewhat off-guard, you are just about to ask for further details when Aichinger cuts you off.  "I knew it had to be you.  It really is good to finally meet you.  I have to say, you handled that masterfully." @{male He claps you on the back.|He pats your hand.} It's been a while since you've been praised and patronized with the same gesture.
	*page_break
*if (fayette_railroad_bonds = "recovered")
	*set aichinger_rapport %+10
	*page_break
	"One last thing, ${mr} ${surname}," Aichinger says, as things begin to wind down.
	
	"Yes?"
	
	"I have heard it said that a pack Klansmen were intent on lynching some Republican officials and a railroad executive outside of Memphis a few years back, but that someone talked them out of it.  Someone that looked a lot like you.  I don't suppose you know anything about that, do you?" Caught somewhat off-guard, you are just about to ask for further details when Aichinger cuts you off.  "I knew it had to be you.  It was unfortunate that the bonds were destroyed, but at least you saved those men's lives." @{male He claps you on the back.|He pats your hand.} It's been a while since you've been praised and patronized with the same gesture.
	*page_break
*if m_sib_rumors

	"Before we conclude this reception, I have one last question." The three look at you warily. "The Quaestor said there is something out in the countryside. Do you really think it is West?"
	
	The three look at each other, but it seems to be confusion rather than collusion. 
	
	"Our dear Quaestor is attuned to the land in the ways that I am not. I can't say I've ever seen him mistaken about these feelings, but I do not know what he is referring to," Aichinger offers by way of explanation. Bailey and Hiram offer no opinions of their own.
	
The evening concluded, they each offer a way to contact
*if bailey_contactable
	them—an unnecessary formality in the case of Senator Bailey—should
*else
	*set bailey_contactable true
	them, should
you have need of them, and then excuse themselves.  
*if (aichinger_rapport > 40) or (invitation_to_st_louis = "lockridge")
	Before you depart, Aichinger invites you to feed freely within the beerhall—on this occasion, at least.  A small gift to the new arrival.
	*choice
		#I do not trust this gesture; I return to my haven.
			*set discretion %-10
			You thank him before closing the door behind you.
			
			You head home, avoiding any temptations that the beerhall might offer.
			*finish Next
		#It is likely that hunting here would be too easy; I prefer more of a thrill.  I return to my haven.
			*set compassion %+10
			*set discretion %+10
			*label decline_feed
			You thank him @{(independence > 50) profusely|politely} before closing the door behind you.
			
			You head home, avoiding any temptations that the beerhall might offer.
			*finish Next
		*if feeding_style = "artists"
			#I did notice the singer on the way in…
				*set aichinger_rapport %+5
				You thank him before closing the door behind you.
				
				You make your way to the musicians, and 
				*if speaks_german or speaks_english
					you find it easy enough to separate the singer away from his companions.  You find his blood delicious.
					
					Your return home afterwards is without incident.
					*finish
				*elseif charm > 3
					though you cannot communicate with them, your supernatural charms are enough to separate the singer from the group.  You find his blood delicious.
					
					Your return home afterwards is without incident.
					*finish Next
				*else
					but find yourself unable to communicate with them.  Frustrated, you turn and leave.
					
					Your return home is otherwise without incident.
					*finish Next
		*elseif (feeding_style = "clergy") and (religious_tradition != "pagan")
			#A gathering of Germans?  Are they Catholics or Protestants?
				You thank him before closing the door behind you.
			
				You survey the crowd, trying to ascertain their religious affiliations.
				*if religious_tradition = "catholic"
					They are Catholic, in fact.  And picking out the priest celebrating alongside his countrymen is no difficult feat.
					
					*label feed_priest
					*set aichinger_rapport %+5
					Approaching the priest is easy enough, and soon you are drinking his hot, sticky blood.
					
					When you have drunk your fill, you set out for home.
					*finish Next
				*else
					Unfortunately, these Germans seem to mostly be Catholics.  You can spot no ministers or reverends, but you do spot a Catholic priest in the crowd, singing along with his countrymen.
					
					*choice
						#I approach the priest; I have no fear of clergymen.
							*set rationalism %-10
							*set anachronism %+10
							*goto feed_priest
						#I do not approach him; I am not hungry.
							*set discretion %-10
							Disappointed, you exit the beerhall, and return to your haven.  The rest of the night passes without incident.
							*finish Next
						#I do not approach him, lest his sanctity excoriate me.
							*set rationalism %+15
							Turning, you hie from the beerhall and return to you haven, far from the burning fire of the God above.
							*finish
		*elseif feeding_style = "drunks"
			#Drunkards!  My favorite!
				*set aichinger_rapport %+5
				You thank him before closing the door behind you.
				
				It is almost too easy.
				
				*label drunk
				When you have drunk your fill, you set out for home.  
				*if perception > 1
					Your mouth tastes of beer, and you are unsteady on your feet.  You pause for a moment, resting against a gaslamp, to gather your wits before continuing on.  Thankfully, you make it home without further incident.
				*finish Next
		*elseif feeding_style = "gamblers"
			#There must be some dice being thrown around here somewhere…
				*set aichinger_rapport %+5
				You thank him before closing the door behind you.
				
				And you are right about there being gamblers about.  There are a handful of men playing cards in the corner, paying little attention to the singing and merry-making that goes on around them.
				
				When you have drunk your fill, you set out for home.  The rest of the evening passes without incident.
				*finish Next
		*elseif feeding_style = "itinerants"
			#Surely there are newcomers to this beerhall.
				*set aichinger_rapport %+5
				You thank him before closing the door behind you.
				
				Taking stock of the beerhall, you soon find several recent arrivals from Chicago.  Soon, you are drinkg their warm, beer-flavored blood.
				
				*goto drunk
		*elseif feeding_style = "laborers"
			#Surely there are daylaborers amongst these revelers.
				*set aichinger_rapport %+5
				You thank him before closing the door behind you.
				
				Taking stock of the beerhall, you find that laborers are here aplenty.  Soon, you are drinking their warm, beer-flavored blood.
				
				*goto drunk
		*elseif feeding_style = "prostitutes"
			#Ladies of the night?  Don't mind if I do.
				*set aichinger_rapport %+5
				You thank him before closing the door behind you.
				
				Stepping into the beerhall proper, you are unsurprised to find a nice selection of options.
				
				When you have drunk your fill, you set out for home.  The rest of the evening passes without incident.
				*finish Next
		*elseif feeding_style = "vegetarian"
			#Aichinger does not realize that I refuse to feed from humans.
				*set compassion %-10
				*set discretion %-10
				*set shepherd_credentials %+5
				You thank him before closing the door behind you.
				
				You head home.  The rest of the night passes without incident.
				*finish Next
		*else
			#I politely decline, as none of these are to my taste.
				*set independence %+5
				*goto decline_feed
				
*else
	Aichinger bids you [i]auf Wiedersehen[/i] on your way out.
	*finish Next