*comment ñáéç…—
*set year 1885
*hide_reuse
*advertisement
*temp met_vonderahe false
*temp heard_of_vonderahe false
*temp tasked_aichinger false
*temp mr_german "Herr"
*if male = false
	*set mr_german "Fräulein"
*if priest
	*set mr_german "Hochwürden"
*temp ogleby_dead false
*temp ogleby "Ogleby"
*temp widow "widow"
*temp wesleyan "New Wesleyan"
*temp invited false
*temp ogleby_num 1
*temp bailey_conspiracy false
*temp skip_gwathney false

The spring of 1885 brings with it an outbreak of consumption in the city. Dozens of new cases are reported, particularly in the Midtown, Downtown, @{exodusters the Reach,|} and Chestnut Valley areas. Some are agitating for quarantining the afflicted. The Insane Asylum has a small ward for those suffering from the disease, but there are not enough beds for all the cases.
*if stlouis_enterprise < 7

	As you have observed during your tenure in the city, the asylum is something of a marvel, both architecturally, and because it is the first public psychiatric institute west of the Mississippi. It is perhaps a strange thing for the city to take pride in, but it does.

*choice
	*if (stlouis_enterprise = 7) or (technology >= 2) 
		#Surely, there must be a cure for this disease! What do the men of science at the university say on this?
			*set rationalism %-10
			*set shepherd_credentials %+10
			*set tuberculosis_vaccine +1
			*set anachronism %+5
			@{stl_met_cousins You approach Dr. Cousins, the professor who was so intrigued by your conversation years ago, and ask him his thoughts on the matter. In the interim, he has not been idle. He explains|Dr. Cousins, a professor at Washington University, informs you} that a very tiny entity—termed a "bacterium"—was isolated just a few years ago by Dr. Robert Koch. This bacterium has been demonstrated to be the cause of consumption—or [i]tuberculosis[/i]—in humans.
			
			Whether that information can be used to cure the disease is a matter of time, research, and funding.
			*choice
				#I spend neither time nor money on this.
				*if ((technology > 0) and (intelligence > 2)) #I will do what I can to assist Dr. Cousins myself.
					*set anachronism %+10
					*if technology = 1
						*set tuberculosis_vaccine +1
					*if technology = 2
						*set tuberculosis_vaccine +2
					*if technology > 2
						*set tuberculosis_vaccine +4
					*if intelligence = 3
						*set tuberculosis_vaccine +1
					*if intelligence > 3
						*set tuberculosis_vaccine +3
					*if willpower > 2
						*set tuberculosis_vaccine +1
					You spend many long nights in the laboratory with Dr. Cousins. He is amazed by the steadiness of your hand and the intensity of your focus.
					*set skip_gwathney true
				*selectable_if (income > 14) #I endow his laboratory.
					How much income would you like to donate?
					*choice
						#[Five points of income.]
							*set tuberculosis_vaccine +1
						*selectable_if (income > 19) #[Ten points of income.]
							*set tuberculosis_vaccine +2
						*selectable_if (income > 24) #[Fifteen points of income.]
							*set tuberculosis_vaccine +4
					The virtue of a donation, of course, is that it frees you up to do other things.
				#I embark upon a campaign to solicit donations from the community.
					*set tuberculosis_vaccine +1
					*if local_fame > 65
						*set tuberculosis_vaccine +1
					*if local_fame > 55
						*set tuberculosis_vaccine +1
					*if (local_fame <= 40)
						*set tuberculosis_vaccine -1
					*if charm > 3
						*set tuberculosis_vaccine +1
					*if (intelligence + technology) > 5
						*set tuberculosis_vaccine +1
					You spend many nights throughout the spring and summer in meeting halls and drawing rooms, churches and schoolrooms, exhorting whoever will listen to support Dr. Cousins and his research.
					
					*if tuberculosis_vaccine <= 1
						Unfortunately, your efforts seem to be mostly for naught. Your pleas fall on deaf ears.
					*else
						Your efforts do not go unrewarded. You collect a number of donations on behalf of Dr. Cousins and make sure they get to where they belong.
					*set skip_gwathney true
	*if (priest) #It is when a soul recognizes their mortality that they are best prepared to ask for forgiveness.
		*set rationalism %+5
		*set local_fame %+5
		You take some time to minister to the ill and offer them their last rites. Though some spit in your face, others welcome your words of comfort.
		
		You do the best that you can.
	*if ((compassion < 40) and (discretion < 40)) #I tend to the sick and the dying.
		*set local_fame %+15
		*set exposure +1
		*set shepherd_credentials %+10
		You call on the ill and hold their hand while they wheeze. Sometimes you're there for their final breaths. They thank you for not leaving them to die alone.
		
		After the twentieth or so, they begin to blur together. Was Mrs. Simpson the one who asked you to water her plants? Or was that Mrs. Cartwright?
		
		Regardless, people begin to call on you for your perceived fearlessness—and imperviousness. You are welcomed into their homes, yes, but the religious pray after you depart and the superstitious do their best to cleanse their homes of your spiritual pollution. They are grateful and hateful at the same time.
		*if (bloodflow < 5) and (willpower < 3)
			*set exposure +1
			
			On the other hand, constantly being around people coughing up blood is very difficult for you. While you can't say the smell of the diseased blood is appetizing, its constant presence is vexing.
			
			Finally, one evening while holding the hand of the young [i]Herr[/i] Schoemer, you are overwhelmed by your Beast. You have been doing a poor job lately of keeping it fed, and the smell of the blood is simply too much. You launch yourself at the young man and sink your teeth into his neck, drinking deeply. You don't stop until he is drained dry.
			
			You lick the wound of course. And he was already pale and sickly from the disease. All the same, the parents look at you with suspicion and distrust when you call them in to say goodbye to their son. You retreat as quickly as you can, cursing yourself for losing control like that.
	#I take the opportunity to engage with those who are dying; it gives me an excuse to watch the process without the usual danger of revealing myself.
		*set compassion %+5
		You find a young bohemian man living by himself in Midtown. He has pretentions of being an artist and a poet and tends to his windowbox garden while searching for inspiration.
		
		You spend long nights in his company, watching the blood well up from his gut and onto the waiting linens. His friends cease visiting within a few weeks, afraid of contracting the illness themselves; besides, a man loved for his exuberance loses something of his charm when confined to his deathbed.
		
		His death is long and miserable. In his final moments, he curses your name; you offered him no compassion, and your morbid curiosity only exacerbated his misery. @{(compassion > 60) That said, you find the whole process fascinating.|}
		*if (creation > 1) and (discretion > 45)
			No great loss, you suppose; his poetry was derivative and his painting uninspired.
		*if stlouis_enterprise = 5
			*set local_fame %+5
			
			Throughout the summer and fall, those artists of the city who knew him but were largely too fearful to visit will sing your praises, expressing amazement at your fearlessness and dedication to one of their number. You do nothing to temper the approbation.
	#I use the opportunity to prey on the desperate, developing and distributing a fake cure @{(stlouis_enterprise = 8) through the spiritualists of the city|to the affliction}.
		*set discretion %+5
		*set local_fame %+5
		*set wealth +5000
		*if charm > 3
			*set wealth +100000
		*if charm = 3
			*set wealth +25000
		*if charm = 2
			*set wealth +10000
		*if finance > 1
			*set wealth +30000
		*if finance = 1
			*set wealth +10000
		*if oblivio
			*set wealth +25000
		Tonics, brews, mixtures, oils, and ointments are all for sale. Producing and marketing a product with the goal of parting the foolish from their wealth is a simple affair when regulations on pharmacological products are negligible. 
		*if stlouis_enterprise = 8
			*set wealth +25000
			Using your contacts among the mediums, seers, and palm-readers of the city means that your name remains mostly clear of an unsavory connections.
		*elseif stlouis_enterprise = 7
			*set wealth +50000
			*set exposure +1
			You even to convince two doctors from Washington University to offer testimonials for your line of products. Lending their name and faces to your enterprise significant increases sales.
		*else
			*set exposure +1
			Of course, your involvement in the selling of the product means that your name ends up being discussed in ways that you'd prefer it weren't.
	*if (false and (stlouis_enterprise = 8)) #I consort with a dying individual and prepare to commune with them after their death.
		*comment TODO a scene where you hang out with a dying person, introduce them to a medium, and then try to contact them after they're dead.
	#I steer clear of the ill. I do not want to expose myself, in the case that it can be passed to me. @{afflicted_memphis I have had enough of mortal disease.|}
		*set discretion %-10
		You give the sick and the ill a wide berth.
		*if (stlouis_haven = "downtown") or ((stlouis_haven = "midtown") or (stlouis_haven = "chestnut"))
			This is particularly difficult because you live in one of the worst-afflicted neighborhoods.
		Thankfully, you seem to be able to steer clear of the mess.
		*set skip_gwathney true

*if columbia_coterie = 1
	*page_break
	*temp interlocutor "Bailey"
	*temp ia false
	*temp loc 1
	*if revolutionary_credentials < 50
		*set interlocutor "Aichinger"
		*set ia true
		*set loc 2
	*elseif eliot_rapport > 60
		*set interlocutor "Eliot"
		*set ia false
		*set loc 3
	*set columbia_coterie 2
	"Have you heard about the nest of vampires in Columbia?" ${interlocutor} asks. You are @{loc at the Southern Hotel|at Schnaider's|in his drawing room} in mid-April. @{loc |On your way in, you noticed that the beergarden was mostly empty of patrons.|}
	
	"Nest of vampires?" you reply.
	
	"Yes, sometimes a group of vampires decide to live together. It quickly becomes…very dangerous. And one has lodged itself in Columbia."
	
	*choice
		#"Is it not Memeskia's responsibility to handle this?"
			*set independence %+5
			"Columbia is not St. Louis, but one could make the argument that it falls under his purview, yes," ${interlocutor} replies.
			
			"And yet…?"
			
			"And yet, have you known Memeskia to lift a finger to enforce the rules of the Society?"
			
			"Why is he Quaestor, then?"
			
			"Because no one dares to challenge him."
			
			Silence falls between the two of you as you both consider those words.
		#"So much the better—let West consume them before us."
			*set compassion %+3
			*if loc = 1
				*set bailey_rapport %+5
				Bailey smiles at you. "You truly have the makings of one of our kind."
				
				"Do you not feel the same way?"
				
				"I suppose it offends me to have them flaunt the rules of the Society. However, you are right, as long as West is loose, they could prove useful."
				
				"I'm glad that we are in agreement, then," you say with a smile.
			*elseif loc = 2
				Aichinger furrows his brow as though he had not considered this possibility. "That is…"
				
				"Exactly what you were thinking?" you prompt.
				
				Aichingers salt-and-pepper mustaches twitches. He seems reticent to admit to this calculation. "I did not say that."
				
				"But you would not be dismayed if they were to be consumed instead of you?"
				
				"No, I would not."
				
				You smile and turn the conversation to other topics.
			*else
				*set eliot_rapport %-5
				Eliot scowls at you. "I do not like your jest."
				
				"I didn't mean it as a jest, Hiram."
				
				"Sometimes I can't stand you, ${given_name}," he replies before standing to leave.
		#"Live and let live, or so say I."
			*set independence %-10
			*if loc = 1
				*set bailey_rapport %-10
				"In violation of the Three Rules and all that holds the Society together?"
				
				"Yes. If they do not disturb us here…"
				
				"You are a fool. And a child," Bailey says.
				
				Realizing that you are no longer welcome here, you leave the Hotel.
			*elseif loc = 2
				*set aichinger_rapport %-10
				"In violation of the Three Rules and all that holds the Society together?"
				
				"Yes. If they do not disturb us here…"
				
				"You are a fool. And a child," Aichinger says.
				
				Realizing that you are no longer welcome here, you leave Schnaider's.
			*else
				"An understandable position," Eliot muses.
				
				The two of you turn the conversation to other subjects.
		#"Should we hunt them down and bring them to heel?"
			*set independence %+5
			*if loc = 1
				"I like your initiative, ${given_name}."
				
				"Does that mean yes?"
				
				"You know very well that I cannot endorse a violation of the Rule of Restraint."
				
				"I understand," you reply.
			*elseif loc = 2
				"I have no intention of dying for the betterment of one of Stone's Quaestors."
				
				"Then I should let this fester?"
				
				"Yes."
				
			*else
				"I admire your enthusiasm, ${given_name}, but invading another vampire's city is never easy," Eliot replies.
				
				"That wasn't a no."
				
				"I suppose you could ask Memeskia's permission to bring them to heel."
				
				"I will consider that."
				
			The two of you turn the conversation to other subjects.

*if has_saw_manuscript = 3
	*page_break
	*temp language
	*temp language_bump 0
	*if speaks_spanish
		*set language "spanish"
		*set language_bump +3
	*if speaks_german
		*set language "german"
		*set language_bump +2
	*if speaks_french
		*set language "french"
		*set language_bump +1
	*if speaks_english
		*set language "english"
	*if speaks_latin and (willpower > 2)
		*gosub_scene util read_saw
	*else
		The time has come to for you to do something with Bowater's manuscript.
	
	You can, of course, return the manuscript now to Bowater. You could also hire someone to make a copy of the manuscript, but if you do, there are three ways to do so: a direct copy, meaning in Latin and still in the classical orthography; a modernized copy in Latin, making it much easier to read for someone used to things like spaces between words; or a translation into a modern language.
	
	Notably, you could pay a scrivener to make a direct copy of the text without breaking the Rule of Reserve. Assuming the scrivener doesn't read Latin, simply copying a manuscript would be an arduous but relatively-safe task.
		
	*choice
		#I return the manuscript to Bowater.
			*set has_saw_manuscript 2
			*set bowater_rapport %+5
			You @{(discretion < 55) carefully|} package the book and return it to the Senator of Philadelphia.
			
			He writes you a thank-you note, expressing his delight at the care with which you treated his prized possession.
		*if (speaks_latin and ((intelligence > 2) and (willpower > 2))) #I will studiously apply myself to deciphering it and then return the text to Bowater.
			*gosub_scene util read_saw
			
			When you are finished, you @{(discretion < 55) carefully|} package the book and return it to the Senator of Philadelphia.
			
			He writes you a thank-you note, expressing his delight at the care with which you treated his prized possession.
		*if (priest or (stlouis_enterprise = 7)) 
			*selectable_if (income >= 20) #I find a monk at St. Louis University to directly copy the text@{(speaks_latin and (willpower > 2)) |—even though I still won't be able to read it}.
				*set income -4
				*set has_saw_manuscript 4
				*gosub monk
			*selectable_if (income >= 40) #I find a monk at St. Louis University to make an updated copy of the text@{speaks_latin |—even though I still won't be able to read it}.
				*set has_saw_manuscript 5
				*set income -8
				*gosub monk
			*selectable_if (income >= 80) #I find a monk at St. Louis University to translate the text into $!{language}.
				*set has_saw_manuscript (6 + language_bump)
				*set income -16
				*gosub monk
		*selectable_if (wealth >= (500000 - (finance * 20000))) #I hire a scrivener to directly copy the text@{(speaks_latin and (willpower > 2)) |—even though I still won't be able to read it}.
			*set has_saw_manuscript 14
			*set wealth -(80000 - (finance * 4000))
			The scrivener agrees to the project in exchange for a regular salary. He anticipates the project taking him two years. You inform him that ${stlouis_valet} will be checking on him regularly.
		*selectable_if (wealth >= (750000 - (finance * 20000))) #I hire a student at Washington University to make an updated copy of the text@{speaks_latin |—even though I still won't be able to read it}.
			*set has_saw_manuscript 15
			*set wealth -(120000 - (finance * 4000))
			The student agrees to suspend his studies in exchange for a regular salary for the next three years while he transcribes and updates the text.
			*if (intelligence > 2) or ((perception > 2) or (stlouis_enterprise = 7))
				You can see that he is imagining using this project as the basis of his thesis once he's done with the transcription.
			You inform him that ${stlouis_valet} will be checking on him regularly.
			
			When the project is finished, you will have to do something about him.
		*selectable_if ((speaks_english) and (wealth >= (1250000 - (finance * 20000)))) #I hire a professor at Washington University to translate the text into English.
			*set has_saw_manuscript 16
			*set wealth -(240000 - (finance * 4000))
			When you dangle the prospect of an unknown text before him, a young assistant professor who is looking to make his mark upon the world of philology and philosophy leaps at the opportunity. He agrees to a significant salary over the course of the next five years in exchange. You inform him that ${stlouis_valet} will be checking on him regularly.
			
			When the project is finished, you will have to do something about him.

*if skip_gwathney
	*goto post_exhumation
	
	*label monk
	With the assistance of the Provost, you are introduced to a young Jesuit brother. In exchange for a
	*if has_saw_manuscript = 4
		transfer of assets to the Univerity, the brother will spend most of the next two years transcribing the manuscript for you.
	*elseif has_saw_manuscript = 5
		notable transfer of assets to the University, the brother will spend most of the next three years transcribing and updating the manuscript for you.
		
		And when he is done, the Provost will make sure that the brother takes a vow of silence until the end of his days.
	*else
		significant transfer of assets to the University, the brother will spend most of the next five years translating the manuscript into $!{language} for you.
		
		And when he is done, the Provost will make sure that the brother takes a vow of silence until the end of his days.
	*return
*page_break
As April draws to an end and May begins, you hear word of a Rev. Dr. Gwathney. Gwathney has brought up the subject of "vampires" in the mortal saloons and salons of the city. He asserts that these vampires are the cause of the cases of consumption now afflicting the city, and that he knows how to stop them.

Of course, the use of the word "vampire" sends chills through Aichinger, Bailey, and Eliot. They debate what should be done about the good Reverend Doctor.

The god-fearing widow Ogleby, a resident of Midtown, seems to be his current target. She has lost three children and her husband to consumption over the past few years; she is desperate to save herself and her two remaining children from the affliction that stalks her household.

*choice
	#I kill Gwathney before he can stir up any further trouble.
		*set compassion %+5
		*set discretion %+10
		*set exposure +2
		*if discretion > 60
			*set exposure +1
		*temp seen true
		*if stealth > 1
			*set exposure -1
		*if stealth > 2
			*set exposure -1
			*set seen false
		*set werewolf_hysteria +1
		The Rev. Dr. Gwathney is more than surprised to discover you in his quarters one evening. You do not give him time to offer protest, however; you sink your fangs into his throat and leave his drained body for others to find.
		
		Of course, certain segments of the city are scandalized by the murder. Some blame the werewolf. Others blame the "vampires" of which Gwathney warned. Still others argue that he was an old man whose maker finally reached out to him. @{seen It does not help that someone saw you both coming and going from his quarters, and you are wanted for questioning.|}
		*goto post_exhumation
	#I want to approach Gwathney and try to ascertain how much he knows.
		*set invited true
		On a given evening, Gwathney can be found at any of several saloons downtown.
		
		When you approach him, he is only too eager to engage you in conversation. He informs you that he is from Vermont, that he attended Brown University, and that he intends to bring the cure for vampirism to St. Louis.
		
		"Cure?"
		
		"Of course. The vampires, they feed on the living. They must be destroyed."
		
		"And how do you know a vampire?"
		
		"It is best that I show you rather than tell you, ${mr} ${surname}," he looks over his shoulders theatrically. "You never know who might be listening."
		
		"And who are you afraid might be listening?"
		
		"Thieves, of course. My knowledge and methods come through great study and sacrifice; I will not reveal them for casual inspection."
		
		"And so what do you propose?"
		
		"If you wish to see, then you may attend the ceremony tomorrow evening. We will rendez-vous tomorrow at the New Wesleyan Cemetery, just after dusk."
		
		"Thank you, Reverend Doctor."		
	#I try to convince the widow Ogleby to reject his entreaties.
		*if charm > 3
			*set ogleby "Hampe"
			*set widow "widower"
			*set wesleyan "Lutheran"
			*set ogleby_num 2
			Your powers of persuasion are notable, and they serve you well here. The widow closes her door to Gwathney.
			
			Unfortunately, the Ogleby family is not the only one to have suffered losses to consumption. The Hampe family of Dutchtown has similarly suffered, and the widower patriarch accepts Gwathney's offer of help immediately.
		*else
			Unfortunately, the widow Ogleby is desperate, and her desperation inures her to your counsel.
		
		After some further questioning, you learn that the ${widow} ${ogleby} will meet Gwathney at the ${wesleyan} cemetery tomorrow evening at dusk.
	#If this vampire-hunter is here for me, let him come. If not, I will bury my head and live to see another night.
		*set discretion %-5
		*set independence %-5
		You tighten your hunting routine; you warn ${stlouis_valet} to watch out for spies; and you keep a close watch over your shoulder.
		
		About a week later, you hear that the vampire has been slain. At the next gathering at Schnaider's, however, everyone is there.
		
		Gwathney is celebrated in certain circles for his success, and vows to continue on with his crusade. However, that crusade takes him to Kansas City.
		
		You find the whole affair somewhat confusing in retrospect. When you ask Eliot about it, he seems just as mystified as you.
		
		The plague of consumption continues in St. Louis unabated.
		*goto post_exhumation

*page_break

You arrive just after dusk. Gwathney and the ${widow} ${ogleby} are there, as well as ${ogleby}'s pastor and a neighbor. @{invited Gwathney introduces you to ${ogleby}, who seems generally bewildered.|You introduce yourself to the gathered individuals. They are mildly suspicious, but the whole affair is so suspicious that one more set of eyes cannot be said to substantively change it.} Before embarking on this adventure, he hands a satchel to @{male the neighbor|you} to carry. "The necessary implements to slay a vampire," he intones. @{(perception > 1) Do you smell…garlic? And…mustard?|}

Gwathney leads the sorry party into the cemetery, following the directions issued by ${ogleby} to @{ogleby_num her|his} @{ogleby_num husband|wife}'s grave.

Once you are all assembled, Gwathney hands @{male you|the neighbor} a shovel. "We dig."

"You're going to exhume a corpse?"

"We're going to exhume all of them until we find the vampire."

@{(sleeping_place = "coffin") While you may sleep in a coffin, you would never sleep|Though you have heard of vampires sleeping in coffins, you have never heard of one sleeping} in a graveyard. Why would you? How unpleasant would it be to wake and have to dig through the earth every evening? It would be even more bone-chilling than your current existence.

And yet, @{male you|they} dig.
*page_break
A short time later, the shovels hit the wooden coffin. @{(perception > 1) You can already smell the putrefaction within, and take a precautionary step back.|} With a short invocation, Gwathney lifts the  lid with a grimace. The smell causes the pastor to vomit. Peering down into the hole, you can see the mostly-rotted flesh and putrid goop that has not yet seeped into the earth below.

"This is a vampire?" ${ogleby} inquires.

"No, no…" Gwathney replies, pushing the coffin back into place. "Certainly not. Your blessed @{ogleby_num husband|wife} is clearly dead. I would apologize for disturbing their rest, but we had to know."

"Is that all, then?" you reply.

"By no means! We must exhume the rest of the family as well!"

He sounds disconcertingly chipper for someone advocating such a macabre task.

And so you move to the grave of the eldest ${ogleby} child, a young man by the name of Martin. The shovels are distributed and the digging begins anew.
*page_break
Again, the shovels strike a wooden lid. @{(perception > 1) You will admit, this one smells different. Still rotten, but to a much more limited degree.|} Again, Gwathney offers a short prayer before lifting the coffin lid.

Within, you see the drawn face of Martin ${ogleby}. You must admit, you are surprised by the condition of the body.

"Ah-ha!" Gwathney exclaims. "We have found him!"

The ${widow} ${ogleby} lets out a wail, falling to @{ogleby_num her|his} knees. "Not my Martin!"

"This is the vampire! Can't you see, he's not fully dead!"

"It can't be!"

"Hand me my satchel! Quickly!" he demands.

@{male You hand|The neighbor hands} the satchel over. Gwathney hastily rips it open, burrowing inside until he emerges with a sack. "Distribute these around the grave," he says, opening the sack for you to reach inside. The neighbor reaches in and pulls out a handful of mustard seeds. "Quickly now!" You reach in as well and get a handful.

At Gwathney's direction, you scatter the mustard seeds around the open grave. "This way, if he rises, he will pose no threat to you tonight."

"How so?" you inquire.

"Why, he must count all the seeds before he can cross the line."

You try not to laugh in his face. When you see that he is serious, you do your best to hide your bemusement and proceed to scatter the seeds around the grave. Behind you, the pastor comforts the ${widow} ${ogleby}, who is too stunned to protest.

Next, Gwathney brandishes a mallet and a wooden stake. You do your best not to recoil; how does he know about stakes? The man jumps down into the grave, and with a few sharp blows, drives the stake into poor Martin's heart. "Garlic!"

@{male You stand|The neighbor stands} there, holding the satchel. Gwathney cocks his head at @{male you, until you|the neighbor, until he} realizes what is meant. "Here," @{male you say|he says}, handing several bulbs of garlic over. Gwathney opens Martin's mouth and stuffs it full of the bulbs, even shoving one down the corpse's throat. "Blade!"

This time, @{male you are|the neighbor is} more prepared. Blade in hand, Gwathney puts all his weight into severing Martin's head from his body. After several minutes of huffing and puffing, there is a thunk as the blade strikes the bottom of the coffin.

"It is done! You are saved, @{ogleby_num Mrs.|Mr.} ${ogleby}!"

Only a wail answers.

You look at Gwathney. His chest is splattered with blood and gore. "A dirty business."

"Yes, it certainly is. I'm so glad, though, that you were here to save us from this vampire."

"It was my duty, ${mr} ${surname}."
*page_break
Martin's coffin is reassembled and the soil once again covers the grave. The ${widow} pays the agreed-upon sum, while the pastor says a prayer for the dead.

Over the course of the next month, Gwathney performs several more of these exhumations, before continuing on to Kansas City. @{(stlouis_enterprise = 8) Unsurprisingly, the spiritualists of the city are abuzz with the stories of his deeds.|}
*set ogleby_dead true

You, on the other hand, are not quite sure what to make of the matter. Stakes and severed heads are…surprisingly accurate. Yet…garlic and mustard? Where did that come from? Are any of your kind actually in danger? It is hard to say, because though he knew how to kill you, he did not know how to find you.

That is a small comfort, you suppose.

*label post_exhumation
*page_break
*if (((ethnicity = "african") or (stlouis_enterprise <= 2)) or (shepherd_credentials > 80)) or ((stlouis_haven = "chestnut") or (temperance_movement))
	*comment 1885-08?
	Arson claims yet another tenement in Chestnut Valley—or so the city fire inspector concludes. It's possible that Mrs. Reed—the proprietor of the former rooming-house—could have let her stove get out of control, but since she died in the conflagration, no one can ask her. 
	
	Suddenly, there's a vacant plot of land at a key intersection in Chestnut Valley, with no one alive to claim it.
	
	The ${wctu} is clamoring for the city to claim the land to build a park with a fountain; by offering fresh water, they hope to combat the drunkenness of the negro man. Alternately, you could attempt to acquire the land yourself; the rental income on the property could be a nice investment. Of course, you could also spend some time investigating the culprit. 
	
	*choice
		*if (wealth > 400000) #Using my charm and knowledge of bureaucracy, I try to acquire the land for free. Otherwise, the investment isn't worth it.
			*if ((charm + finance) >= 5)
				*set compassion %+5
				*set justice %+5
				*set laborvscapital %-5
				*set wealth -50000
				*set income +5
				The right forged documents mixed with honeyed words secures the deed to the land for you at the cost of a few evenings' work. The land acquired, you set about having the debris cleared and building a new structure.
				
				*gosub design_tenement
				
				*if creation > 1
					*set income +5
				When the tenement is built, you direct ${stlouis_valet} to fill it with renters.
			*else
				Alas, your efforts come to naught. The forged documents you offer don't pass muster, and your words are not quite honeyed enough.
				
				The land eventually passes to a remote cousin of Mrs. Reed, while the burnt-out shell stands untouched for years.
		*if (wealth > 600000) #I'm willing to buy the land from the city outright as an investment.
			*set wealth -150000
			*set laborvscapital %-5
			*set income +5
			The cost of the land seems like a small price to pay. You sign a bank draft over to the city and then immediately turn to having the debris cleared and a new tenement constructed.
			*gosub design_tenement
			*if creation > 1
				*set income +5
			When the tenement is built, you direct ${stlouis_valet} to fill it with renters.
		*if ((wealth > 600000) and ((laborvscapital > 65) and (compassion < 35))) #I want to acquire the land by any means necessary, and turn it into a resident-owned cooperative.
			*set shepherd_credentials %+5
			*set laborvscapital %+30
			*set stlouis_race_relations %+5
			*set exposure +1
			*set local_fame %+10
			*if ((charm + finance) >= 5)
				*set compassion %+5
				*set wealth -50000
				Faking a number of documents and using your powers of persuasion, you purchase the land at a steep discount.
			*else
				*set wealth -100000
				Lacking any other ideas, you purchase the land outright.
			*gosub design_tenement
			
			Once you are finished, you turn the building over to the residents. The deal provokes outrage among the élite of the city, who are not only angry that @{(creation > 1) such a beautiful|a} building was simply given away, but that all the beneficiaries are black. However, the new owners take the management of their building seriously, making the most of the oppotunity that you have presented to them.
			
			You gain quite a bit of notoriety for it.
		*if (stlouis_enterprise = 6) #I join the ${wctu} in organizing for the construction of a public park.
			*label wctu_picket
			The women of the ${wctu} begin protesting and picketing immediately. There are a number of objections from speculators who wish to acquire the land for themselves, but the focused attention of the women eventually forces the city to claim the land for itself.
			
			*achieve temperance_park
			*set local_fame %+10
			*set compassion %-5
			*set shepherd_credentials %-5
			*set missouri_prohibition +1
			*if stl_kid_met = false
				*set stl_kid_origin 4
				*set stl_kid_name "William"
				*set stl_kid_nick "Billy"
				*set stl_kid_met true
				Most children tend to shy away from you, especially the younger ones. But, amid the hustle and bustle of the ${wctu}'s organizing, one young boy seems fascinated by you. He hides behind his mother's skirts, yes, but his eyes never leave you when you are near. You try to not let it bother you.
			
			Once the land is declared public property, the women begin selling subscriptions to finance the construction of pipes and a fountain. Within a few months, the necessary funds have been organized, and construction begins. The fountain is complete by Christmas, and is unveiled as a gift to the community of Chestnut Valley.
			
			As with Temperance Fountains in other parts of the country, the advocates hope that by offering free and clean drinking water, their neighbors will no longer drink alcohol out of desire for unpolluted water. Over time, you observe that providing clean drinking water certainly lowers the instances of certain disease outbreaks in and around Chestnut Valley.
		*if ((stlouis_enterprise = 3) or (stlouis_enterprise = 7)) #I will help organize support for the ${wctu}. Free and clean drinking water for the masses is a laudable goal.
			*goto wctu_picket
		*if (wealth > 250000) and (stlouis_hideout = false)
			*if (stlouis_enterprise = 2) #An empty lot, fronting an intersection? That sounds like the opportunity for mischief.
				*set local_fame %+10
				*set wealth -150000
				*set income +3
				*achieve stlouis_hideout
				*set stlouis_hideout true
				With the help of your friends—and a pretty penny of your own—you acquire the property, have its zoning changed, and begin construction on a mixed-use property.
				
				Of course, this mixed-use property has several secret rooms to host illicit activities and hide ill-gotten gains from curious officials.
		#I spend some time trying to track down the arsonist.
			*if perception > 0
				*set stlouis_arsonist_investigation +1
				While you find little in the way of evidence in the rubble, your questioning of the neighbors does yield some useful intelligence: it seems that a white man was seen in the vicinity of the tenement right before it caught fire.
				
				*comment some confirmation that it's the same person?
			*else
				Unfortunately, your skills at investigation are negligible. You spend several evenings picking through the rubble and posing questions to neighbors, but your efforts come to naught.
		*if stl_chinese_soul_food
			*selectable_if (wealth > 500000) #This seems like an excellent location for Ma Wang's to open another location.
				*set local_fame %+5
				*set wealth -100000
				*set wealth +(finance * 10000)
				*set income +5
				At your urging, Ma Wang opens a second restaurant, this time in the middle of Chestnut Valley. More spacious and comfortable than the original location, it brings a new legitimacy to the cuisine. 
				
				When the doors open, the restaurant is an instant success. Soon, even white customers are coming to Chestnut Valley to "slum" it with the locals.
		*if ((stl_opium_smuggler) and (wealth > 500000)) #The new building should be a front for an opium den.
			*set wealth -100000
			*set income +10
			*set discretion %+5
			*set shepherd_credentials %-5
			You partner with a grocery store to construct a building with a secret basement that is soon filled with opium pipes and bunk beds stacked from floor to ceiling. It's a place where people go to forget themselves.
			*if feeding_style = "narcotics"
				*set bloodflow +1
				It also makes it that much easier for you to indulge in your preferences for blood.
	*page_break

*temp already_seen_vonderahe false
@{robert_yates_baseball As noted by Robert Yates, there is a St. Louis base ball team. They have made strides over their first few years as a franchise, but this year, they make|Reorganized in 1882, the St. Louis Browns—a base ball team—begins} a long and spectacular march to the pennant in the late spring @{robert_yates_baseball |of 1885} under the management of Charlie Comiskey. @{(compassion < 40) Against the backdrop of the tuberculosis outbreak, the game is a welcome distraction to the St. Louisans.|}
*if memphis_baseball
	In the years since you noticed the arrival of the sport in Memphis, its popularity has grown immensely. Every major city and most minor ones now field a team in some league or other.
*else
	The sport has taken the country by storm. It was originated in New-York in the mid-1850s, formalized and professionalized with the formation of the National League in 1876, and now draws crowds to ballparks in every major and many minor cities.
*if ((shepherd_credentials > 60) and (anachronism > 60)) or ((feeding_style = "drunks") or memphis_baseball)
	*set heard_of_vonderahe true
	The popularity of the sport in St. Louis is due in no small part to Chris Von der Ahe, a German immigrant who purchased the Brown Stockings so that he could sell beer at their games.
*if (stlouis_enterprise = 1) or (shepherd_credentials > 75)
	Further, the newspapers have even created a new section: the Sports section. In the past few years, reports of base ball games and other sporting events have begun to capture the imagination of St. Louisan readers.
*if (temperance_movement) or ((finance > 0) or memphis_baseball)
	Unlike the National League, however, the Browns are part of the American Association. The National League forbids play on Sundays, as attendees would want to drink beer on the Sabbath. The American Association, despite the objections of temperance workers, happily plays on Sundays. 
	
	The money from the beer sales flows into team owners' pockets@{heard_of_vonderahe |—like Chris Von der Ahe, the owner of the Browns}. Across the country, brewers, distillers, and saloon-keepers become the primary owners of base ball teams.
	*set heard_of_vonderahe true
*comment NB: the Browns win four pennants in a row, 85-88.

When Fair Week arrives that October, a parade is organized to celebrate the champions on that Wednesday—the day after the Veiled Prophet's parade and ball.  In the afternoon, the champions stage an exhibition at the ballfield before taking to the streets to wind their way to Schnaider's [i]biergarten,[/i] halfway across town. @{heard_of_vonderahe Von der Ahe|The owner of the Browns} hires a massive wagon to carry signs proclaiming "Brown Stockings, Champions of the World" to everyone near and far. Schnaider's, capable of hosting ten thousand patrons at a time, is the perfect venue for the celebrants.

Aichinger invites the rest of the vampires of the city to join him at Schnaider's for the evening; he makes it clear that it is a joyous occasion and as long as no rules are broken, you are welcome to enjoy yourself for the evening.
*if (feeding_style = "drunks")
	Considering your affection for the drunken, it is indeed a night to celebrate.
*elseif (feeding_style = "vegetarian")
	While you may refrain from consuming the blood of humans, you find it hard to resist attending the celebration anyway. The revelry is infectious.
And though Schnaider himself died of cancer a few years prior, his son, also named Joseph, seems to have the business well in hand. The affair goes off without a hitch—despite the attendant vampires' depredations.

*choice
	*if (feeding_style != "vegetarian") #I take the opportunity to feed from Charles Comiskey, the mastermind behind these victories.
		*achieve fedoncomiskey
		*set discretion %+5
		Comiskey is drunk—which makes keeping his attention challenging. It also does not help that everyone in the [i]biergarten[/i] wants to shake his hand. But eventually you manage to get him alone long enough to feed from him. @{(perception > 1) The blood is surprisingly refined—this man was born to privilege that his current circumstances do not indicate.|}
	*if ((stlouis_enterprise = 2) or ((feeding_style = "gamblers") and (charm > 1))) #I want to sniff out which of the Brown Stockings might be open to…bribery.
		*if charm <= 3
			*set wealth -3000
		*if wealth < 0
			*set wealth 0
		*set stlouis_baseball_corruption 2
		*set exposure +1
		You make the acquaintance of Lyndon Farrow, the rightfielder, when you happen upon him being muscled by a handful of toughs. Apparently, he bet against his own team.
		
		With @{(charm > 3) a wave of your hand|a gift of a hundred dollars} you send the toughs on their way. Lyndon thanks you and doesn't seem to think twice as you buy him a beer.		
	#No, this venue is too exposed. It would be wiser not to feed here.
		*set exposure -1
		*set discretion %-5
		You observe the revelry and try to make yourself look…human.
		*if compassion < 40
			*set exposure -1
			You do a competent job, if you do say so yourself.

*page_break
*comment 1886-03-01 to 05-04
*set year 1886
*temp party false
*if (stlouis_enterprise = 5) or ((feeding_style = "socialites") or (feeding_style = "merchants"))
	*set party true

For the first time in his life, Jay Gould is forced to the negotiating table.

A strike, organized by the Knights of Labor, has paralyzed freight traffic on the Wabash Rail line in Texas throughout the summer. The grip of the Knights is such that other rail lines are refusing to carry Wabash traffic, lest the strike spread to the other lines.

During the negotiations, Gould makes concessions to the Knights of Labor: rehiring individuals who had been fired and restoring wages that had been cut in a cost-saving measure.

In response, the ranks of the Knights of Labor swell throughout the nation. Labor action shows signs of success here and there—rays of hope amid the gloom that has clouded the labor movement since the Great Uprising of 1877 was crushed.

Of course, that hasn't stopped Gould from consolidating his control of the railroad system of St. Louis under the banner of the Terminal Rail Road Association. The TRRA's monopoly over the Eads Bridge now includes an "arbitrary"—or tariff—on all railcars crossing the river.
*if stlouis_haven = "east"
	This is part of what has caused the rise of East St. Louis during your sojourn there, as the tariff on transporting coal over the river is sufficient to encourage industry to stop short and produce on the far side. It likely has something to do with the murder of the former mayor, John Bowman, last November. He was deeply involved in a lawsuit involving the Wiggins Ferry Company, another player in this whole cross-river trade.
*elseif (finance > 0)
	This has precipitated the rise of industry in East St. Louis: the tariff is high enough on coal in particular that many industries have set up shop on the far shore to avoid the tax.

The idea of a "free" bridge has been making the rounds: a bridge owned either by the city or some group of merchants, with the goal of breaking the Gould monopoly on river-crossing traffic. 
*if (finance > 0) or ((local_fame > 50) or (feeding_style = "merchants"))
	You are peripherally acquainted with some of these men—and they are men—that seek to join together to organize financing of such an enterprise.

*choice
	*if ((stlouis_enterprise = 2) and (stl_electricity >= 5)) #If coal is so expensive, it sounds like a prime opportunity for a smuggling operation.
		*set laborvscapital %+5
		*set local_fame %+5
		*set stl_coal_smuggler true
		*achieve coal_smuggler
		*set shepherd_credentials %-5
		*set income +3
		It's not terribly lucrative, but with a little bit of effort, a crew of reprobates organize and begin buying coal in East St. Louis and transporting it across the river for sale.
		
		Unfortunately, the Wiggins Ferry Company—a rival to Gould's empire—controls most of the riverfront on both sides of the river, so the routes are more complicated than they initially seemed. However, coal being sold at a discount is snapped up by both individuals and industry. The market absorbs as much of it as can be conveyed across the river.
		*if stlouis_hideout
			*set income +1
			
			The whole affair is coordinated from your base of operations in Chestnut Valley, allowing you to better coordinate the smuggler's efforts.
		*if (stlouis_hideout = false) and (stealth < 4)
			*set exposure +1
		*comment TODO another origin for stl_kid?
		
		While you are busy smuggling coal, the Merchant's Exchange organizes a corporation to construct a bridge. The corporation promises fair rates and—more importantly—an alternative to the Gould monopoly.
	*if (finance > 0) or ((local_fame > 45) or (feeding_style = "merchants"))
		*selectable_if (wealth > 500000) #The business-owners of St. Louis should join together and build a new bridge!
			*set shepherd_credentials %+5
			*set local_fame %+5
			*set stl_merchants_bridge 2
			*set shepherd_credentials %+5
			*if wealth > 3000000
				*set wealth -50000
				*set municipal_debt 50000
				*set local_fame %+5
			*if wealth > 2000000
				*set wealth -100000
				*set municipal_debt +100000
				*set local_fame %+5
			*if wealth > 1000000
				*set wealth -100000
				*set municipal_debt +100000
				*set local_fame %+5
			*if wealth > 500000
				*set wealth -50000
				*set municipal_debt +50000
			You join with several other business leaders to invest in the construction of a new bridge. 
			*if ((ethnicity = "choctaw") or (ethnicity = "african")) or (male = false)
				They require you to form a company to put some distance between you and them, but your capital opens doors that might otherwise be closed to you.
			Construction begins immediately.
		#The merchants of St. Louis should really partner with Gould on a new bridge; monopolies aren't all bad, and the real enemy here is the strikers.
			*set shepherd_credentials %+5
			*set laborvscapital %-10
			*if (local_fame > 60) or ((local_fame > 50) and (charm > 3))
				*set stl_merchants_bridge 3
				*set stlouis_business_climate %+10
				
				Gould and the Merchants Exchange sit down to the negotiating table and hash out a deal. Gould will own a portion of the bridge, and will have some input on the pricing. Not everyone gets what they want, but isn't that the hallmark of a fair deal? Construction begins almost immediately.
			*else
				The bridge corporation rebuffs your advice and proceeds as originally intended.
				
				Construction on the new bridge begins later in the year.
	#I wish a truly free bridge could be built, one owned and operated by the city for the good of all.
		*set laborvscapital %+5
		*set justice %-5
		The Merchant's Exchange organize their corporation, purchase the necessary land, and begin construction just a few months later.
		
		Perhaps the competition will help bring Gould to the negotiating table? But, in your heart-of-hearts, you doubt it; rather, the Merchant's Exchange will use the leverage of the new bridge to come to an agreement that benefits both them and Gould, to the detriment of the people of St. Louis.
	#Let the humans build their bridges; I will continue to use the ferry.
		*set shepherd_credentials %-10
		*set anachronism %-5
		The Merchant's Exchange organize their corporation, purchase the necessary land, and begin construction just a few months later.
		
		You, on the other hand, continue to utilize the Wiggins Ferry Company whenever possible. Yes, you suppose a boat could capsize, but water poses no danger to you. The collapse of the Eads Bridge, on the other hand, could crush you in a heartbeat.
	*if (party)
		*selectable_if (((renter = false) and (wealth > 500000)) or (wealth > 1000000)) #In fact, I want to host a soirée where the élite of the city can fret over these dirty workers and their absurd demands.
			*set laborvscapital %-20
			*if charm < 3
				*set exposure +1
			*if (ethnicity = "african") or (ethnicity = "choctaw")
				*set exposure +1
			*set local_fame %+10
			*if renter
				*set wealth -100000
				To host this soirée, you rent a ballroom at the Planter's House Hotel.
			*else
				*set wealth -50000
			*if stlouis_haven = "lafayette"
				*set local_fame %+5
			*temp performance 1
			*temp sources false
			*temp recruits false
			*if creation > 2
			
				Considering your creative talents, would you prefer to direct the party planning, or perform a piece of music?
				*choice
					#I will plan the party.
						*set local_fame %+5
						You lose track of how many times you are complemented on the presentation and organization of the soirée.
					#I will play a music piece.
						*set local_fame %+5
						What instrument will you play?
						*choice
							*if (speaks_spanish or stl_saw_guitar) #Guitar.
								*set performance 2
								*set stlouis_race_relations %+3
								*set anachronism %+3
								*set local_fame %+3
								About thirty years ago, @{(ethnicity = "spanish") an Andaluz|a Spaniard} by the name of Antonio de Torres Jurado invented a new shape to the guitar, giving it a deeper resonance and dynamic range. @{stl_saw_guitar Ever since you saw one at the circus,|These instruments are still only just catching on in Spain, but when you saw one come through St. Louis recently,} you knew you had to own one.
							#Piano.
								*set performance 3
							#Violin.
								*set performance 4
					#I'm going to dazzle some specific individuals, with the goal of increasing my fortune.
						*set sources true
					*if (stlouis_cult) #I'm going to focus on recruiting devotees.
						*set stlouis_cult_power %+15
						*set recruits true

			The evening goes off without a hitch. Several esteemed individuals attend—including Mayor David Francis—and a good time is had by all. @{performance |Your guitar recital provokes exclamations of delirium from the attendees.|Your piano recital provokes a standing ovation from the attendees.|Your violin recital provokes a standing ovation from the attendees.}
			*if ((perception > 1) and (finance > 1)) and (sources = false)
				*set income +3
			
				Amid the hubbub, you even manage to overhear a few tidbits that will provide investment opportunities in the future.
			*if sources
				*set income +5
				
				Using a number of theatrical tricks—in some cases, literal smoke and mirrors—you bring a local heiress to tears, sobbing at the beauty of the world and the finite nature of mortality. When she raves to her confidantes about the revelations that you have offered her, you seize upon the new connections for the purposes of exploitation later.
			*if recruits
			
				Amanda is, of course, present for this soirée. She looks a uncomfortable in her stiff-necked dress and bustle—she was not born to these sorts of clothes—but when you indicate a pliable target, she pounces with ferocity.
				
				Over the course of the evening, the two of you working together find several new recruits.
			*if temperance_movement
				*set missouri_prohibition -1
			
				Unfortunately, at least one mainstay of the temperence movement is in attendence; she is most displeased by the flow of alcohol at the event. You suspect that you have damaged the cause of prohibition this evening.
			
			At some point, discussion of the bridge returns to the forefront of conversation. The construction of a free bridge will be a massive undertaking, but it seems as though the stewards of the city have decided to move forward with it.

It is a massive undertaking, one that promises to change the makeup of the city for decades into the future.
*page_break

Though Gould conceded at the negotiating table, his promises were writ on water.

Throughout the winter, Gould's railroads test the resolve of the Knights of Labor. Finally, Gould devises the clever plan of letting one of his railways go bankrupt, officially negating any agreements between the railway and the Knights. With the courts unwilling to enforce the agreements, the Knights see no choice but to strike.

Thus begins the Great Southwestern Rail Strike, targeting the entirety of Gould's rail empire. White and black, skilled and unskilled, the workers of the Gould empire join in their rejection of monopoly, exploitation, and the importation of cheap labor from China. 

*page_break
*temp haymarket false
*if (shepherd_credentials > 55) or ((laborvscapital > 60) or (laborvscapital < 35))
	*comment 5/4/1886
	Across the nation, workers have been striking for an eight-hour day.
	*if stlouis_business_climate > 70
		@{(laborvscapital > 50) Conveniently|Unfortunately}, the workers of St. Louis @{(laborvscapital > 50) are too cowed|know better than} to dare engage in such activities.
	*else
	
		The strikes have occurred in St. Louis as well, but to a smaller degree than in Chicago. Here, the workers are still disorganized from 1877. @{(sporting_goods = 1) |With dismay, you note that the strikes are certainly doing nothing for the patronage of ${spalding_sporting_goods}.} The various civic groups of the city are clamoring for the police to intervene, though the strikers have not yet engaged in any violence. @{(joined_kkk or observing_kkk) The elements of the Klan that continue despite their abolishment agigtate for the suppression of these radicals.|}
	
	*choice
		#An eight-hour work day? What sort of radicals would dare put forth such a demand?
			*set compassion %+5
			*set laborvscapital %-5
		#Political power must be seized; it is never given. I admire these protestors for that, even if I am ambivalent to their objectives.
			*set discretion %+5
		#The protestors should have the courage of their convinctions; only violence will achieve the ends they seek.
			*set compassion %+5
			*set discretion %+5
			*set laborvscapital %+5
	
	Before the matter can gather momentum here, news arrives from Chicago of a massive clash between police and protestors: during a gathering of strikers, an unidentified individual threw dynamite into the path of an advancing police column. In the chaos, the police opened fire on the crowd, killing several, but also wounding many of their own number in the darkness and confusion.
	
	Over the next few days, newspapers carry lurid accounts of the encounter; it soon takes on the moniker of the "Haymarket Riot," though it could hardly be described as one. The city of Chicago rallies around the wounded police, raising money for their care and recovery. @{(laborvscapital > 50) No such fund is established for the protestors who were wounded or slain by the police in the aftermath of the explosion.|}
	
	Over the course of the next few weeks, ethnic Germans, socialists, and trade unionists are arrested and imprisoned in a desperate search for someone to blame. Eventually, eight individuals are put on trial, several with only tangential connection to the event. They are all found guilty. None of them claim—or are even accused—of being the bomb-thrower themselves. @{((laborvscapital > 50) or (stlouis_enterprise = 2)) Rumors swirl among the working class that the whole affair was incited by the Pinkertons, but without evidence, the theory is treated as little more than hysteria.|}
	
	*choice
		*if ((laborvscapital > 50) or (stlouis_enterprise = 2)) #Encourage the rumors of Pinkerton involvement.
			*set laborvscapital %+5
			*if (stlouis_enterprise = 1) or (((stlouis_cult and (stlouis_cult_power > 40)) or (charm > 3)) or (stlouis_enterprise = 5))
				*set stlouis_business_climate %-10
				*label honeyed_words
				The rumor mill spins with your honeyed words. The citizens of St. Louis increasingly look upon the capitalists and industrialists as willing to engage in dirty tricks to suppress the demands of labor.
			*elseif charm = 3
				*set stlouis_business_climate %-5
				*goto honeyed_words
			*else
				*set stlouis_business_climate %+5
				The tales of Pinkerton involvement are treated with scorn by the citizens of St. Louis and support for the outrageous demands of the workers declines.
		#The tarring of the ethnic Germans is dangerous and reprehensible. The citizens of St. Louis must not fall prey to this xenophobia.
			*if (stlouis_cult and (stlouis_cult_power > 40)) or ((charm > 3) or (stlouis_enterprise = 1))
				*set anti_german_sentiment %-5
				The full-throated defense of the ethnic Germans seems to do some good: The typical screeds against their presence and influence in the city seems to subside. @{(stlouis_enterprise = 4) The [i]turnverein[/i] appreciate your efforts on their behalf.|}
			*else
				*set anti_german_sentiment %+5
				A full-throated defense of the ethnic Germans seems to misfire: the typical screeds against their presence and influences in the city do not abate.
		#Now is the time to strike the labor movement, while they are on the defensive!
			*set laborvscapital %-10
			*set discretion %+10
			*if (stlouis_cult and (stlouis_cult_power > 40)) or (((stlouis_enterprise = 2) or (charm >= 3)) or (stlouis_enterprise = 1))
				*set stlouis_business_climate %+5
				Your efforts bear some fruit, as the citizens of St. Louis harden towards the needs of the workers.
				
				*if stl_met_preston
					*set stlouis_business_climate %+5
					Jerome Preston is even hired to further persecute the unions that do exist. 
					
					In the subsequent days, one cigar lector in particular has his eyes burnt out with a hot poker; he can still wrap cigars—his livelihood is not endangered—but he is no longer able to read the newspapers, novels, and tracts that were stirring up his listeners.
					
					The businessmen at the Southern Hotel consider this a fair resolution to the situation.
			*else
				*set stlouis_business_climate %-5
				Though your seek to discredit the labor movement, your efforts misfire; the citizens of St. Louis see through the propaganda, and soften towards the needs of the workers.
		#The workers of St. Louis should go on strike in solidarity.
			*set laborvscapital %+15
			The goal is not, [i]per se,[/i] to topple the government. But a one-day strike that demonstrates the power of the labor movement—and it's opposition to the treatement of the Haymarket Eight—could be an important step towards change.
			
			*if (stlouis_enterprise = 1) and (creation > 2)
				Several of the newspapers talk up the strike. You compose an impassioned editorial that ignites the imagination of its readers.
				*label strike_success
				The day of the strike, even the weather agrees with you. The sky is clear, the breeze is cool, and workers walk away hin unison from their workstations across the city.
				
				*if (stlouis_race_relations > 60)
					*set stlouis_business_climate %-10
					The plan for the day is a march across the Eads Bridge—where a contingent of freedpeople from East St. Louis joins the formation—and back, then a demonstration before City Hall, and finally a pique-nique in the evening. The affair has a fair-like quality to it, with families and children singing protest songs@{(stlouis_enterprise = 4) —sometimes in English, othertimes in German—| }and enjoying the beautiful day together.
					
					*gosub temperance_movement_check
					
					For a brief, cloudless day, the people taste what the world might be like without the oppression of capital.
				*else
					*set stlouis_business_climate %-5
					The plan for the day is a march across the Eads Bridge and back, a demonstration before City Hall, and finally a pique-nique. The affair has a fair-like quality to it, with families and children singing protest songs@{(stlouis_enterprise = 4) —sometimes in English, othertimes in German—| }and enjoying the beautiful day together.
					*label race_musing
					
					@{((ethnicity = "african") or (ethnicity = "choctaw")) When you arrive at the gathering after dark, one thing does strike you: everyone here is white. This movement will never succeed as long as race divides it.|Observing the crowd, you are surprised to note that there are only white faces here. Why aren't the freedmen here, you wonder? Don't they know that they have everything to gain by joining this protest?}
			*elseif (stlouis_enterprise = 1)
				Several of the newspapers do their best to paint the upcoming strike in a flattering light. However, there is not a unified or articulate voice to make the case.
				*label strike_moderate_success
				The day of the strike itself is, thankfully, a fair day. That helps attendance.
				
				The usual suspects show up—cigar rollers, railyard workers, bricklayers—but it is not what is considered a resounding success.
				*if (stlouis_race_relations > 65)
					*set stlouis_business_climate %-7
					The plan for the day is a march across the Eads Bridge—where a contingent of freedpeople from East St. Louis joins the formation—and back, then a demonstration before City Hall, and finally a pique-nique in the evening. The affair has a festive quality to it, with families and children singing protest songs and enjoying the day together.
					
					*gosub temperance_movement_check
					
					It is not everything that you hoped, but it is better than you had feared.
				*else
					*set stlouis_business_climate %-3
					The plan for the day is a march across the Eads Bridge and back, a demonstration before City Hall, and finally a pique-nique. The affair has a festive quality to it, with families and children singing protest songs and enjoying the beautiful day together.
					*goto race_musing
			*elseif (stlouis_enterprise = 4) and (creation > 2)
				The turners pledge their support of the strike. What's more, you compose an impassioned editorial on behalf of the workers, and it is printed in several German-language newspapers. It ignites the imaginations of those who read it.
				*goto strike_success
			*elseif (stlouis_enterprise = 4)
				The turners pledge their support of the strike and dedicate themselves to helping organize it.
				*goto strike_moderate_success
			*elseif temperance_movement and (creation > 2)
				The ${wctu} pledges itself to the cause. Though the ${wctu} tries to stay out of labor matters, an impassioned letter that you compose and distribute sways the hearts and minds of the decision-makers. The local chapter votes to support the strike.
				*goto strike_success
			*elseif temperance_movement and (charm > 3)
				The ${wctu} pledges itself to the cause. Though the ${wctu} tries to stay out of labor matters, your powers of persuasion changes the minds of the key decision-makers. 
				
				The local chapter votes to support the strike.
				*goto strike_moderate_success
			*else
				*set stlouis_business_climate %+10
				Unfortunately, the strike is a miserable affair. Some four dozen individuals attend, but most of those are either already unemployed or aren't what anyone would consider a member of the working class.
				
				When the strikers attempt to commandeer a streetcar, the police descend on them with their batons.
				
				No one is killed, but several individuals are arrested, and the newspapers use the affair as an opportunity to mock the labor movement and its goals.
	*set haymarket true
	*page_break

@{haymarket In the comparative calm following the aftermath of the Haymarket affair, you find yourself sitting at Schnaider's|Towards the end of May, you sit at the [i]biergarten[/i]} once again. Aichinger asked you to meet him here, though he did not offer a reason why. The garden is thinly populated tonight; Sigrid was able to seat you at your favorite table without trouble. There is an operetta being performed on the center stage by a troupe from New-York. @{(creation > 1) The soprano is, in your estimation, supremely talented.|} Despite the ethusiastic efforts of the cast, the audience is nearly empty.

The St. Louis Browns, the local American Association base ball team, played a home game this afternoon; the attendees stayed at Sportsman's Park and at the neighboring saloons. Since the pennant victory the prior year, Schnaider's popularity has waned dramatically. Musical and theatrical performances do not have the draw they did previously, especially when scheduled opposite base ball games.

"@{speaks_german Oh, bother,|[i]Ach,[/i]}" begins Aichinger as he takes a seat beside you. The patrons are so few and far between that you need not be discreet in your conversation. "Someone seeks to ruin me."

"Ruin you?"

"Look around, ${mr} ${surname}! My [i]biergarten[/i] is empty! I bring the finest operetta that I can from New-York and no one comes to see them. They go to watch men hit balls with sticks and call it a game! This is what children do, not men!"

*if (laborvscapital < 50) and (discretion > 30)
	*set aichinger_rapport %+5
	"And would you rather them hit balls with sticks, or come here to drink and conspire to march for better working conditions?"
	
	Aichinger is surprised by your retort. "It is better that they are focused on a game. But can they not come and drink and not conspire?"
	
	"Perhaps. But perhaps you are correct, and someone seeks to undermine your business.…if that were the case, whom would you suspect of such intrigue?"	
*else
	You look at him askance. "And whom do you suspect of such intrigue?" 
	
His bushy mustache twitches with thought. "That is why I asked you here. You are new to St. Louis still. It has been less than a decade, [i]ja?[/i] Your eyes are still fresh."
*temp debt_offered_aichinger false

You consider your response carefully.
*choice
	#"Quaestor Memeskia seems a likely candidate. I imagine he feels threatened by the influx of your people to the city."
		*set discretion %+10
		*set aichinger_rapport %+10
		*set independence %+5
		"But we are vampires. Vat loyalty do we have to the people of our birth? None." He emphasizes that last bit with a gesture of dismissal.

	#"Senator Bailey seems a likely candidate. I'm sure he fears for his seat on the Senate."
		*set discretion %+10
		*set aichinger_rapport %+10
		*set independence %+5
		*set bailey_conspiracy true
		Aichinger's mustache twitches again. "That is preposterous. I have no designs on his seat. He cannot truly think that…can he?"
		
		"I cannot say, Mr. Aichinger."

	*if (revolutionary_credentials <= 55) #"Senator Bailey seems a likely candidate. You are the closest thing that St. Louis has to a Loyalist, after all."
		*set discretion %+10
		*set aichinger_rapport %+10
		*set independence %+5
		*set revolutionary_credentials %-5
		*set bailey_conspiracy true
		Aichinger's mustache twitches again. Somewhat more violently this time. "Vye vould he complicate the politics of this city in this way? Ve have done such a good job of keeping the peace here."
		
		"I cannot say, Mr. Aichinger."

	#"Perhaps it is Mr. Eliot. Perhaps he wants to make a name for himself among the Revolutionaries by driving you from their stronghold?"
		*set discretion %+10
		*set aichinger_rapport %+10
		*set independence %+5
		*set revolutionary_credentials %-5
		Aichinger pulls his head back in surprise. "Mr. Eliot? I vould never have thought of him as being such a partisan. He cannot be the source of this intrigue himself."
		
		"I cannot say, Mr. Aichinger."

	*if (heard_of_vonderahe) #"Have you considered that there is none of our kind involved, but simply the result of the efforts of Mr. Von der Ahe?"
		*set aichinger_rapport %-10
		*set compassion %-5
		"I have heard of this man. But he is a puppet, surely. I want to know who pulls his strings, ${mr} ${surname}."
		
		"I cannot answer that, Mr. Aichinger."

	#"Perhaps there is no plot against you, Mr. Aichinger. Perhaps it is simply that the people of St. Louis prefer base ball to the opera."
		*set aichinger_rapport %-15
		*set anachronism %+10
		"Impossible," he sputters. "This is centuries of musical refinement you see before you. This is progress itself!"
		
		"Perhaps progress is not quite what you think it is, Mr. Aichinger."
		
		He looks at you crossly.
*if aichinger_rapport > 40
	"Let me ask of you this, then, ${mr} ${surname}. Whether your suspicions are correct or no, will you endeavor to confirm them for me?"

	*choice
		*if (revolutionary_credentials < 50) #"Yes, I will do this if it will aid a fellow Loyalist."
			*set revolutionary_credentials %-15
			*set aichinger_rapport %+15
			*set discretion %+5
			*set independence %+10
			*set tasked_aichinger true
			He smiles broadly and thanks you for your camaraderie.
		*selectable_if (status > 0) #"Yes, I will do this, but I will expect @{debt_to_aichinger the absolution of my debt to you|an acknowledgment of a debt}."
			*set aichinger_rapport %+10
			*set discretion %+10
			*set independence %+15
			*set tasked_aichinger true
			*set debt_offered_aichinger true
			He nods slowly, considering. Finally, he says simply, "I accept."
		#I assure him that there is no plot against him. But later I will still go investigate@{heard_of_vonderahe  Von der Ahe|} anyway.
			*set discretion %-10
			*set aichinger_rapport %-5
			*set independence %-5
			Aichinger seems unconvinced by your assurances, but finally accepts that you will not indulge his request. 
		#I assure him that there is no plot against him, but that if I happen upon such a thing, I will be sure to inform him.
			*set discretion %-10
			*set aichinger_rapport %-5
			*set independence %+5
			He is clearly disappointed by your indifference to his plight. He assures you that someone moves against him and that he will find out who.
			
			*goto abrupt_goodbye
	He excuses himself without further ado, and you are left to enjoy the soprano's soaring aria.
	*page_break
*else
	"You have given me something to think about, ${mr} ${surname}. Thank you. Please enjoy the performance."
	
	*label abrupt_goodbye
	With that, he rises from his seat and leaves you alone to enjoy the soprano's soaring aria.
	*page_break
	The next evening you spend contemplating the strange questions of Lothar Aichinger.
	*choice
		#I pay them no mind. If there is a plot against him, I want to avoid any entanglements.
			*set independence %-10
			*set discretion %-10
			*if shepherd_credentials > 45
				Several months later, you first notice the presence of a new type of mercantile, a "sporting goods" store, specifically ${spalding_sporting_goods}. It seems they sell the gloves and sticks used in the game that offered such disquiet to Aichinger. 
				*if anachronism < 60
					You can't help but find the whole thing ludicrous.
				*page_break
			*goto post_aichinger
		#There may not be a plot against him, but that doesn't mean there shouldn't be one.
			*set independence %+5
		*if (compassion < 50) #If someone is treating mortals like pawns, I must put a stop to it.
			*set compassion %-10
			*set shepherd_credentials %+5
		#If there is a plot against him, I want to be a part of it.
			*set compassion %+5
			*set shepherd_credentials %+5
			*set independence %+10

*if heard_of_vonderahe
	The next evening you rouse yourself and set out for Von der Ahe's drinking establishment.
	*if ogleby_dead and (shepherd_credentials > 40)
		Before you depart, ${stlouis_valet} informs you that the ${widow} ${ogleby} and @{ogleby_num her|his} remaining child have both died of consumption.
		
		On your ride to the Golden Lion, you muse that Gwathney's charade seems to have served no purpose whatsoever.
*else
	*set heard_of_vonderahe true
	It does not take much investigation to discover the primary source of Aichinger's distress: Chris Von der Ahe, owner of the St. Louis Browns, and his saloon The Golden Lion.
	*if ogleby_dead and (shepherd_credentials > 40)
		Amid this investigations, you also learn that the ${widow} ${ogleby} and @{ogleby_num her|his} remaining child have both died of consumption.
		
		Gwathney's charade seems to have served no purpose whatsoever.
*page_break

*set met_vonderahe true
The Golden Lion is on the northwest side of town, on the way to Elleardsville.
*if (stlouis_haven = "midtown") or (stlouis_haven = "kerry")
	It's not far at all from your haven.
	*if (feeding_style = "drunks") or (feeding_style = "laborers")
		*set already_seen_vonderahe true
		You have, in fact, frequented it during your hunting expeditions.
*if (stlouis_haven = "dutchtown") or (stlouis_haven = "soulard")
	That is clear across town from your haven in @{(stlouis_haven = "soulard") Soulard|Dutchtown}.
Arriving there, 
*if (stl_kid_origin = 2)
	*set stl_kid_met true
	*if male
		you are accosted by a young bootblack. He points to the pile of horsehit you just walked through. "I can fix that right up for you, sir!" He can't be more than…six years old?
		
		You sit in his chair and watch the top of his head bob and weave while he addresses the unwanted additions to your outfit. You notice a small @{literate sign—[i]Del's Shoe Shine[/i]—written in crude block-letters|presumably announcing the name of his enterprise}.
		
		Your footwear cleaned and buffed, you pay the boy and proceed on your way to the Golden Lion.
	*else
		your attention is captured by a young bootblack. "Ma'am!" he yelps. Pausing, you note the steaming pile of horseshit that was about to muss your footwear. "Sorry, ma'am, but I don' have the right polish for those." He can't be more than…six years old?
		
		The bootblack has a small stand outside the Golden @{literate Lion: [i]Del's Shoe-Shine,[/i] it reads|Lion}. @{(compassion < 55) You thank the boy, smiling and handing him a tip before pushing past.|You roll your eyes at the boy and push past him into the Golden Lion.}
	Once inside,
*if already_seen_vonderahe
	you seek out the proprietor: Chris Von der Ahe. You have previously mused that, if you didn't know better, you would say that he was the son or grandson of Aichinger; they even trim their moustaches in the same way. He greets you as he does all his regulars, calling to you by name and welcoming you to his establishment.
*else
	you are struck by the sight of Chris Von der Ahe. If you didn't know better, you would say that he was the son or grandson of Aichinger. They even trim their moustaches in the same way. Shaking away the impression, you introduce yourself. Von der Ahe greets you @{speaks_german warmly, especially once he realizes that the two of you can speak together in German.| enthusiastically, always willing to make contact with new customers. His accent is thick and almost comical; he seems to take a certain amount of pride in being hard to understand.}

Though you could be wrong, after an hour-long conversation, you are inclined to believe that Von der Ahe is nothing more than a businessman—though he does demonstrate a pronounced facility with remembering names and faces; he greets almost every patron that enters during your conversation by name. On the matter of base ball, however, you can divine nothing untoward; he found an opportunity and exploited it. It just so happens that St. Louisans were hungry for beer and sports and had grown tired of stuffy European music. "Besides, zese Americans, zey love a vinner!" Von der Ahe exclaims, his well-chewed cigar drawing circles in the air with his gesticulations. "And ve are vinning!"

He even points to a framed newspaper article that hangs beside the bar as proof of his success. Peering closer, you see that it is an article from 1882 about the opening of Sportsman's Park. "Look around chentlemen, because this is the largest dimundt in the welt ist," it quotes him as saying. It then notes that Comiskey quietly pointed out that all base ball diamonds are the same size, upon which Von der Ahe rephrased hist statement to "Vot I meant to say vas this the larchest infield in the welt ist"—which does not seem to have been any more accurate. The article proceeds to poke fun at Von der Ahe's ignorance of the game, his accent, and just about every other aspect of his business. But this is only one article about Von der Ahe—the wall is covered with more, and they continue into the dining room and the office. It's clear that the journalists look on him with a certain amount of disdain, but they cannot resist reporting every deed of his—and his antics sell papers.

*if bailey_conspiracy
	Throughout the conversation, you drop hints about any possible connection to John Bailey. As best as you can ascertain, Von der Ahe has never met the vampire. Though, you would not be surprised if Bailey's powers of persuasion were strong enough to cause a mortal to misremember events.
As the conversation draws to a close, you begin to contemplate what to do with your results from the evening.
*if finance > 0
	You admit, after speaking with Von der Ahe, you admire his business acumen. You also come to the epiphany that these people who watch base ball are likely to want to play base ball. And that involves bats, balls, gloves, and other necessities. Perhaps a store devoted to selling these items would be a profitable enterprise.

*choice
	*if (finance > 0) #"What would be even better would be to sell the instruments of the sport to the attendees, Mr. Von der Ahe."
		*set rationalism %-5
		*set shepherd_credentials %-5
		*set stlouis_business_climate %+5
		*set spalding_sporting_goods "Golden Lion Sporting Goods"
		@{speaks_german "What|"Vat} do you mean, ${mr_german} ${surname}?"

		"I am saying that we should start a business together, Mr. Von der Ahe. Where we sell…what are they…bats? And base balls, and those leather gloves…to the attendees. They may think they can earn their place on the team. And we will sell them that dream."
		
		Von der Ahe's eyes light up. "Ist you proposing a partnership?"
		
		*if wealth > 500000
			*set sporting_goods 3
			*set wealth -125000
			*set income +20
			"I have some money to invest in such a venture, yes."
			
			Von der Ahe's mouth now splits into a wide grin. He extends his hand, which you grasp in turn, and he shakes it firmly.
		*else
			*set income +5
			*set sporting_goods 2
			"I simply want a small consideration for the idea, Mr. Von der Ahe."
			
			@{speaks_german "So much of my income is tied up in the team and the saloon right now. But we will see what we can do."|"So much of mine income is tied up in ze team and ze saloon vight now. But ve vill zee vhat ve can do."}
		*goto resolve_aichinger
	*if (finance > 0) and (wealth > 1000000)
		#I will cut this meeting short. I intend to found a mercantile to sell sporting goods to Mr. Von der Ahe's patrons.
			*set rationalism %-5
			*set stlouis_business_climate %+5
			*set discretion %+10
			*set exposure +1
			*set local_fame %+10
			*set sporting_goods 4
			*set wealth -500000
			*set income +50
			It is no small affair, establishing a business. It requires all sorts of efforts: the hiring of talented individuals, interminable meetings, and dealing with petulant customers who seem to think that they are the center of the world. But you embark upon it all for the satisfaction of creating something greater than yourself.
			
			${stlouis_valet} plays a key role in the whole thing, representing you during the daytime hours.
			
			*page_break
			What will you call your sporting goods store?
			*choice
				#St. Louis Sporting Goods.
					*set spalding_sporting_goods "St. Louis Sporting Goods"
				#${surname} Sporting Goods.
					*set spalding_sporting_goods "${surname} Sporting Goods"
					*set exposure +1
					*set local_fame %+20
					*set discretion %+15
				#Something else.
					*label input_spalding_name
					*input_text spalding_sporting_goods
					${spalding_sporting_goods}? Is that right?
					*fake_choice
						#Yes.
						#No.
							*goto input_spalding_name
			*label resolve_aichinger
			*if debt_offered_aichinger
				*goto aichinger_furious
			*elseif tasked_aichinger
				*page_break
				You receive a note from Aichinger inquiring as to the results of your investigations.
				*choice
					#I should be forthright about my betrayal.
						*set discretion %+15
						*set aichinger_rapport %-10
						Your reply is direct and to the point: you investigated his concerns, and found the opportunity to exploit the situation.
						
						You are a vampire, after all, you muse to yourself.
					#I couch my betrayal in the kindest terms.
						*set discretion %-15
						*set aichinger_rapport %-30
						The letter is considered and eloquent, but the purpose is ultimatley unmistakeable. You do not receive any further correspondence on the matter.
					#I send no reply.
						*set discretion %+5
						*set aichinger_rapport %-20
						You trust that he will get the message.
			*else
			
				*if (sporting_goods > 1)
					*set aichinger_rapport %-20
					It occurs to you that Aichinger may be displeased by your entrepreneurial activities. @{(discretion > 60) For better or worse, though, you aren't terribly concerned with Aichinger's pleasurs and displeasures.|}
	*if (stlouis_enterprise = 1) 
		#I will have the newspapers of the city stop covering sports. Absent these plebian distractions, business will return to Schnaider's.
			*set rationalism %-5
			*set aichinger_rapport %+40
			*set local_fame %+10
			*set exposure +1
			*set stlouis_business_climate %-10
			*set baseball_failed true
			
			By the time the St. Louis Browns are forced to relocate their franchise at the end of the 1887 season, Schnaider's is already roaring again.
			*gosub sort_aichinger_debt
	*if (stlouis_enterprise = 4) 
		#I encourage the German community, through the [i]turnverein,[/i] to stop attending the base ball games in favor of traditional pasttimes.
			*set rationalism %-5
			*set aichinger_rapport %+20
			*set anachronism %-15
			*set local_fame %+5
			*set anti_german_sentiment %+10
			The nationalist fervor of the [i]turnverein[/i] is only inflamed by your encouragements to hold their customs close. @{(perception > 2) The rest of the city certainly notices the way its German residents refuse assimilation.|}
			
			Von der Ahe's saloon and ticket sales are mostly unaffected, but the German community rallies around the [i]biergärten[/i].
			*gosub sort_aichinger_debt
		#I encourage the German community, through the [i]turnverein,[/i] to attend the base ball games instead of the traditional [i]biergärten[/i].
			*set rationalism %-5
			*set aichinger_rapport %-50
			*set anachronism %+10
			*set local_fame %+5
			*set anti_german_sentiment %-15
			*set revolutionary_credentials %+15
			*set stlouis_orchestra 3
			At your urging, the [i]turnverein[/i] abandon Schnaider's in favor of more modern entertainments.
			*if perception > 2
				The rest of the city welcomes the further assimilation of its German residents. In the hopes of becoming more American, several of the German-language newspapers begin running dual-language papers, to help the citizens become fluent in English.	
			*label aichinger_furious
			
			By the fall of 1887, Schnaider's is forced to close. 
			*set schnaiders_closed true
			*if debt_offered_aichinger
				*set status -1
				*set bjornsdotter_rapport %-15
				*set townsend_rapport %-15
				*set overstreet_rapport %-15
				Aichinger explains to Senator Bailey what occured: how you accepted the offer of a debt in exchange for a task—and then betrayed that task. Senator Bailey agrees that this is reprehensible conduct, and he makes sure the other Senators know.
				
				*if status = 0
					Unfortunately, this means that you are no longer protected by the rules of the Society. You are technically [i]persona non grata[/i], until and unless you can earn the respect of those capable of restoring you.
			*else
				Though you see Aichinger only rarely this period, you sense that his anger towards you is deep and hot.
	*if (wealth > 250000) and ((stlouis_enterprise = 5) or ((creation > 0) or (feeding_style = "artists")))
		#Though it may come at some expense, I encourage Aichinger to make the musical performances more permanent.
			*set rationalism %-5
			*set local_fame %+5
			*set anti_german_sentiment %-5
			*set stlouis_orchestra 1
			*set wealth -25000
			*set stlouis_business_climate %+10
			Aichinger loves your idea of making the musical attractions more permanent. He decides to hire musicians to perform nightly. This does involve enticing individuals to relocate from other cities—New Orleans, Chicago, even New-York—but they come in the name of regular employment.
			
			Though you are not directly involved in their recruitment or employment, you do find that their arrival is incurring some expense. @{(stlouis_enterprise = 5) However, you see the expense as necessary in pursuit of developing the arts in the city.|} @{(creation > 0) Of course, you don't mind the new ideas that they bring in exchange, ideas that contribute to your own musical development.|} @{(feeding_style = "artists") Besides, having more artists to feed from in the city is invaluable.|}
			
			*gosub sort_aichinger_debt
	*if ((stlouis_enterprise = 6) or temperance_movement)
		#These base ball games are a travesty; the attendees come home drunk. At best, with their pockets empty; at worst, possessed of an anger which they take out on their wives and children.
			*set rationalism %-5
			*set local_fame %+5
			*set stlouis_business_climate %-5
			*set exposure +1
			*set missouri_prohibition +1
			With a little bit of urging, the ${wctu} takes up your cause with abandon. The women stage weekly protests, marching directly from Sunday services to the base ball field.
			
			While it doesn't exactly shut down the base ball games, it certainly impacts attendance.
			
			*if debt_offered_aichinger
				*set aichinger_rapport %-5
				Aichinger refuses to acknowledge a debt to you. The wave of temperance you have encouraged may have damaged base ball, yes, but it has also damaged the business at Schnaider's.
			*elseif tasked_aichinger
				*set aichinger_rapport %+5
				You later receive a note from Aichinger, thanking you for your effort on his behalf. Reading between the lines, however, you observe that Aichinger is unsure what your efforts have achieved; the wave of temperance has impacted his establishment as well.
			*else
				*set aichinger_rapport %+15
				You later receive a note from Aichinger, expressing surprise that you should expend effort on his behalf, but thanking you all the same.
	#I report to Aichinger that there is no plot against him and that he should rest easy.
		*set aichinger_rapport %+10
		*set compassion %-5
		*set discretion %-5
		*set independence %+5
		*set stlouis_business_climate %+5
		*set spalding_sporting_goods "Schnaider's Sporting Goods"
		*if tasked_aichinger = false
			*set aichinger_rapport %+10
			Aichinger is surprised by your arrival. Pleasantly surprised, you hope.
		He is somewhat relieved by the news, yet still troubled at the idea that Von der Ahe has somehow grasped the [i]zeitgeist[/i] and he hasn't.
		*if perception > 2
			You feel that he is struggling to develop a response to this information.
		
		*if shepherd_credentials < 65
			*page_break
			It is about a year later that you will pass ${spalding_sporting_goods}, a mercantile near the Sportman's Field. It is easy to conclude that Schnaider's [i]biergarten[/i] has expanded its operations, diversifying into sporting goods. From what you glimpse from the outside, the shop conducts a brisk business selling base balls, bats, gloves, and other sporting goods.
	*if (religious_tradition != "pagan") #I urge Von der Ahe to respect the Sabbath and not compete on Sundays.
		*set rationalism %+15
		*if (charm > 3) or ((ethnicity = "german") and ((religious_tradition = "reformed") and ((charm = 3) and (perception > 1))))
			*set local_fame %+5
			*set browns_sundays_moved true
			*set exposure +1
			It is with great reluctance that Von der Ahe agrees to no longer schedule games for Sundays.
			
			The announcement is received poorly by the public. In the following months the churches of St. Louis do see their attendance increase modestly.
			*if debt_offered_aichinger
				*set aichinger_rapport %-5
				Aichinger refuses to acknowledge a debt to you. The wave of temperance you have encouraged may have damaged base ball, yes, but sending worshippers to church is not sending patrons to Schnaider's.
			*elseif tasked_aichinger
				*set aichinger_rapport %+5
				You later receive a note from Aichinger, offering half-hearted thanks you for your effort on his behalf. Reading between the lines, however, you observe that Aichinger is unsure what your efforts have achieved; the wave of temperance has impacted his establishment as well.
			*else
				*set aichinger_rapport %+5
		*else
			*set aichinger_rapport %-10
			You make an impassioned case for respecting the Sabbath. 
			*if (charm = 3) or (ethnicity = "german")
				For a brief moment, Von der Ahe seems like he might accede to your wishes.
			But in the end he draws himself up straight and shakes his head. @{speaks_german "I cannot do this, friend. If I do not, someone else will. I cannot walk away from such an opportunity."|"I cannot do zis, [i]Freund[/i]. I cannot valk avay from zuch an opportunity."}
			
			You excuse yourself.
			*if debt_offered_aichinger
				*page_break
				*set aichinger_rapport %-15
				You send a note to Aichinger informing him of your efforts to set Von der Ahe on a better path. Aichinger refuses to acknowledge a debt to you, as he sees not benefit from your deeds.
			*elseif tasked_aichinger
				*page_break
				*set aichinger_rapport %-10
				You send a note to Aichinger informing him of your efforts to set Von der Ahe on a better path. He does not reply.

*label post_aichinger
*if temperance_movement or (shepherd_credentials > 75)
	*page_break
	A few years ago, the legislation arm of the WCTU managed to implement a long-held policy goal: the mandatory education of schoolchildren as to the dangers of alcohol. The educational program, referred to as "scientific temperance," has its first successes in Vermont, Michigan, and New Hampshire. As of this past winter, fourteen States have enacted these laws.
	
	The WCTU vows to continue the push to make sure that all children in the nation are alerted to the dangers of intemperance.
*page_break
*comment TODO needs segue
	
Now, Jay Gould and his @{(discretion > 60) minions|allies} have found the audacity to purchase Union Depot, all the railyards on both sides of the river, and all auxiliary rail corporations. His stranglehold on the rail traffic through St. Louis is virtually complete.

In response, the merchants of St. Louis have begun agitating for a new, "free" bridge to be built—a bridge to be owned by the city and the community as a whole, and not subject to arbitrary tariffs. @{(laborvscapital > 50) Of course, by "the community," they mean the corporation that owns the bridge.|}

*page_break
*if (ethnicity = "choctaw") or ((sire_name = "West") or (shepherd_credentials > 80))
	*comment 9/4/1886
	It's late September when the ${post_dispatch} trumpets the news: the savage Apache, Geronimo, and his @{(ethnicity = "choctaw") band of warriors|tribe of rebels} has surrendered unconditionally. @{((ethnicity = "choctaw") and (compassion < 65)) It is a sad day; you had read the accounts of his exploits with glee.|}
	
	A lurid article recounts the recent history of the Southwest: despite the free food and land provided to them, the rebellious and ungrateful Apache, led by Geronimo, had periodically forsaken these gifts to go plundering through the American and Mexican countryside. They had returned to the San Carlos reservation at least twice before, but this latest breakout was considered unforgivable by the US Army.
	
	After a bruising pursuit across the parched landscape, on both sides of the border, the cowardly Geronimo was finally hounded into capitulation on September 4th. The newspaper goes on to report that the Army had escorted them to Fort Sam Houston while the government debates what to do with the prisoners of war.
	*choice
		#Good riddance. He was a threat to the governance of the western Territories.
			*set discretion %+10
			No doubt he would say the same about you.
		#The time of the Native has passed; modernity arrives.
			*set anachronism %+10
			*set compassion %+10
			And what does that say about vampires?
		#The @{(ethnicity = "choctaw") old ways|traditions of the past} crumble all around me. @{(ethnicity = "choctaw") I cry for what passes unmarked.|In the mirror of their loss, I see the reflection of the destruction of the history of my people as well.}
			*set anachronism %-10
			*set compassion %-10
			Unfortunately, your tears will not bring back what has been lost.
	*page_break
*if (baseball_failed = false) and ((memphis_baseball or (stlouis_baseball_corruption > 1)) or ((temperance_movement) or (sporting_goods > 1)))
	Under Comisky's management, the Brown Stockings win a second league championship, but that is not enough for Von der Ahe. He challeges Al Spalding, owner of the Chicago White Stockings, to an inter-league series of seven games—the White Stockings are the perennial champions of the National League. Spalding accepts, and a substantial wager is placed between the two men on the outcome of the series—which includes an award of $15,000 to be distributed among the actual players.
		
	The White Stockings win two of the first three matches on their home field, whereupon the two teams decamp for Sportman's Park to play the next three games. The fourth and fifth games go to the Brown Stockings. The White Stockings take an early 3-0 lead in the sixth game, until a dramatic eighth-inning comeback by the Browns ties up the game. No one scores in the ninth, pushing the game to extra innings.
	
	Then, in the bottom of the tenth, the Browns' Curt Welch makes it to third.
	*if stlouis_baseball_corruption > 1
		Then, Lyndon Farrow steps up to the plate. The pitcher winds up and throws…and Farrow hits the ball for a pop fly. Welch dashes towards home, hoping that the catcher will drop the ball…but he doesn't. Catching the ball, he then neatly tags Welch and the inning is over.
		
		Their momentum stalled, the Browns give up another point in the next inning and the series is over.
		
		*set wealth +100000
		That evening, you send ${stlouis_valet} to collect your winnings from the various bookies.
		*if sporting_goods > 1
			
			*set income -1
			Unfortunately, the dramatic loss diminishes some of the enthusiasm for ${spalding_sporting_goods} products; the revenue from the venture takes a notable hit.
	*if stlouis_baseball_corruption = 1
		The White Stockings' pitcher winds up for the next batter, but the ball goes astray. The catcher scrambles to regain the ball, but Welch sees his opportunity and dashes for home base. The catcher having recovered the ball, Welch throws caution into the wind and makes his slide…stealing home and winning the series. This "$15,000 slide" becomes the most famous base ball play of the century.
	*page_break
*set year 1887

To the relief of corporations and segregationists everywhere, the Tennessee Supreme Court overturns a judgement against the Chesapeake, Ohio, & Southwestern Railroad Company in April 1887. Three years prior, a young teacher by the name of Ida Wells was dragged from the first-class ladies' car despite having a ticket to the same. The train did not have a black-only first-class car—something to which blacks were entitled under the "Separate but Equal" doctrine—and so was in clear violation of the law. But the Tennessee Supreme Court—drawing on the decisions in the [i]Civil Rights Cases[/i] of 1883—held that the second-class car was, in fact, equal to a first-class car, and moreover it found that Wells was clearly pursuing the case in order to persecute and harass the railroad and that she did not want, in truth, a comfortable seat "for the short ride."
*choice
	#Laws cannot change hearts and minds, nor should they seek to.
		*set justice %+25
		If society is to change, then it must be given the time and space to change. Those seeking change cannot issue demands and expect immediate results.
	*if ((ethnicity != "african") and (ethnicity != "choctaw")) #As a vampire, this does not affect me. Let the mortals sort these matters out themselves.
		*set shepherd_credentials %-30
		*set justice %+5
	#Tens of thousands of people died fighting over this—it is infuriating that their deaths have been rendered pointless by these regressive judicial decisions.
		*set justice %-10
		*set independence %-5
		*set compassion %-5
		This is clearly the goal of the Southern Democrats and their efforts at voter intimidation. By electing former Confederates and their sympathizers, they are able to appoint judges to State and Federal courts. Those judges, in turn, hand-down decisions that chip away at—over even completely overturn—the hard-won advances that were fought and bled for.
	*if (ethnicity = "african") #Perhaps there is something to Wells's declaration that blacks should head west, as there is no freedom to be found in these Confederate states.
		*set justice %-10
		*set compassion %-5
		Can that truly be the answer? Oregon is to the west, and your people are forbidden from residing there.
		
		North, south, east, west…all directions look equally bleak to you.
	#The forces of capital will never relinquish power of their own volition. This is one more blow with the goal of dividing blacks from poor whites.
		*set laborvscapital %+15
		*set justice %-5
		*set compassion %-5
		This is clearly the goal of the Southern Democrats and their efforts at voter intimidation. By electing former Confederates and their sympathizers, they redirect the social goals of segregation towards the maintenance of the systems of capital that protect the rich.  Those elected officials in turn see to the appointment of judges that enforce those systems with their decisions that limit or even overturn established protections.
		
		It is an elegant and ruthless proposition.
	#No one can expect for businesses to provide two sets of identical accommodations for patrons; it is too burdensome. A mild inconvenience for some keeps prices lower for everyone.
		*set laborvscapital %-25
		*set compassion %+5
		*set discretion %+5
		This is the line that the wealthy whites repeat to each other when they are afraid to say what they really think.
		
		In reality, businesses charge higher prices to blacks for inferior services. Because they can.
			
*page_break
*comment July, 1887

Misfortune strikes the Planter's House Hotel the following July. Sometime in the middle of the afternoon, fire catches hold in the kitchen and soon spreads to much of the rest of the hotel. The damage is extensive and the facility closes for the time being.

*if stlouis_baseball_corruption > 1
	Come August, Farrow approaches you about the upcoming World Series. He offers to make sure the Browns lose again—but his price is higher this time. @{(perception > 1) You note that he is drunk.|}
	
	You reason that some money is better than none, and agree to Farrow's demands. @{(discretion > 50) You can always kill him afterwards, after all.|}
	
	The Browns do make it to the World Series, facing off against the Detroit Wolverines in a fifteen-game series. It seems as though Farrow's offer was of little value: the Browns lose ten games to five.
	
	*choice
		#I pay Farrow's fee.
			*set stlouis_baseball_corruption 4
			*set wealth +50000
		#I reject Farrow's demands; he did nothing to earn it.
			*set stlouis_baseball_corruption 3
			*set wealth +100000
			*set exposure +2
			Farrow spits at your feet and storms away, proclaiming loudly that you will regret it.
		#I kill Farrow when he comes to collect.
			*set stlouis_baseball_corruption 2
			*set discretion %+5
			*set exposure +1
			*set wealth +100000
			The body of Farrow is found in Mill Creek three days later. Von der Ahe gives a quote to the [i]Missouri Republican[/i] where he notes Farrow's descent into drunkenness and association with known gamblers. No one looks too closely into the matter.
		#I give Farrow all the winnings, and tell him I never want to see him again.
			*set stlouis_baseball_corruption 2
			*set compassion %-5
			The immense amount of cash you have just handed to Farrow is too much for him to handle.
			
			Within three months, a death notice appears in the newspapers. Though they are too circumspect to come out and say it, you infer that he died of an opium overdose.
	
	*if sporting_goods > 1
			
		*set income -1
		The lop-sided loss further diminishes the enthusiasm for ${spalding_sporting_goods} products. 
		*if stlouis_baseball_corruption = 2
			*set income -1
			Farrow's death further adds to the sense that the sport is not…sportsmanlike.
		*if stlouis_baseball_corruption = 3
			*set income -2
			Further, Farrow knows of your involvement there; he constantly rags on the emporium's products to any journalist with a pad.
		The revenue from @{(sporting_goods = 4) your|the} venture takes another hit.

*page_break
*comment late 1887

You wake one evening to find the strangest illustration in the newspaper. It depicts a shoot-out between a cowboy and a werewolf.

@{literate Picking up the paper, you read the article.|Calling out to ${stlouis_valet}, you have ${valet_him} read the article to you.} Apparently, the Werewolf of St. Louis has struck again, this time in Hannibal, a river town to the north. While the details are sketchy, some hardcase former Confederate got into a gunbattle with someone or something that witnesses described as a werewolf, much like the one that attacked the poor woman at the Terre Haute train station four years ago.

The gunslinger's mangled body was recovered by the coroner. No sign remains of the werewolf. The sheriffs of Marion and Ralls Counties have posted a reward for any information that could lead to the unmasking of the culprit.

*choice
	*if (spencer_sister_status = 7) #I encourage the Spencer sisters to work the story of the werewolf into their sermons.
		*set werewolf_hysteria +2
		*set west_exposure +1
		*set stlouis_business_climate %-5
		The Spencer sisters decry the beast that is roaming the land. They identify this beast as a sign of God's judgement on the region.
		
		The sisters' flock swells as one of the only congregations to attempt to grapple with the rumors. Most of the churches are content to laugh off the idea of a werewolf loose on the prairie and the Ozark plateau.
	*if (stlouis_enterprise = 8) #I urge the spiritualists and mediums of the city to fan the flames of fear over these attacks.
		*set werewolf_hysteria +1
		*set west_exposure +1
		*set stlouis_business_climate %-5
		*set discretion %+5
		The spiritualists and mediums make the werewolf a part of every fortune told and séance held. Soon, the gullible and the conspiracy-minded can speak of nothing else.
	*if (priest) #I use my position as a priest to spread rumors of the werewolf as God's judgement.
		*set exposure +1
		*set west_exposure +1
		*set werewolf_hysteria +1
		*if speaks_spanish
			*set werewolf_hysteria +1
		*set discretion %+10
		*set stlouis_business_climate %-5
		You don't have a congregation to preach to, but you do have a cassock, erudition, and the demeanor of a priest.
		
		Your words, initially received as words of comfort, instead leave people up at night, fearing for the safety of themselves and their loved ones. @{speaks_spanish Though you do not speak Italian, your Spanish is enough to help you spread the rumors to the Italian community as well. The language barrier previously hindered the spread of the story, but once infected with the idea it spreads through the community rapidly.|}
	*if (stlouis_enterprise = 1) #I urge the newspapers to cover the shoot-out extensively and to play up the werewolf angle.
		*set exposure +1
		*set west_exposure +1
		*set werewolf_hysteria +1
		*set discretion %+5
		*set stlouis_business_climate %-5
		The newspapers opine loudly on the rumors of a werewolf. Of course, without a specimen to study, the conversation is mostly the repetition of old stories and the feverdreams of attention-seeking men of science.
	*if (stlouis_enterprise = 1) #I urge the newspapers to heap scorn on the idea of a werewolf.
		*set exposure -1
		*set werewolf_hysteria -1
		*set discretion %-5
		*set stlouis_business_climate %+5
	*if (stlouis_enterprise = 7) #I urge the professors and men of science at Washington University to heap scorn on the idea of a werewolf.
		*set exposure -1
		*set werewolf_hysteria -1
		*set discretion %-5
		*set stlouis_business_climate %+5
		The intellectual elite of the city pen white papers and newspaper editorials ridiculuing the idea of a werewolf. Their words seem to calm some of the most outrageous rumors.
	*if ((feeding_style = "socialities") or (stlouis_enterprise = 5)) #While in the salons of the city, I encourage the rumors of a werewolf.
		*set exposure +1
		*set west_exposure +1
		*set werewolf_hysteria +1
		*set discretion %+5
		*set stlouis_business_climate %-5
		The doyennes and the grand-dames of the city flutter their fans and nod their taxidermied-animal-laden hats at every twist and turn of the story. They begin to take the existence of werewolves as fact, and chuckle among themselves at those simpletons who deny the existence of such a creature.
	#I think it best to lay low. Any attempt to meddle in this could be interpreted as a violation of the Rule of Reserve.
		*set independence %+10
		*set discretion %-10
		*set exposure -1
		And lay low you do. You keep to your regular feeding grounds and wait for the hysteria to pass.

*if schnaiders_closed
	Now that Schnaider's has been shuttered, court has relocated to the Eurydice, an underground theater that makes use of the natural caves under St Louis. There is, of course, an above-ground element to the structure, but the acoustics of the stone chamber are magnificent.
	
	If Memeskia even notices the change in venue, he gives no indication. @{(aichinger_rapport < 45) Aichinger, conversely, has not spoken to you in years.|}
	
	There is a gnawing question at the back of your mind: could the two events be connected?

@{schnaiders_closed Regardless,|Of course,} the other vampires of the city are at a loss to explain why West would get into a fight with a mortal. Aichinger suggests that West simply sought the challenge of dangerous prey. Bailey offers the idea that the gunslinger simply disturbed West's rest. The debate lasts late into the night, but no conclusion is reached.
*finish Next

*label temperance_movement_check
*if temperance_movement
	*if wctu = "NWSA"
		And, of course, the suffragettes take the opportunity to press for converts to their cause.
		*set missouri_suffrage +1
	*if wctu = "WCTU"
		And, of course, the temperance workers take the opportunity to preach the gospel of temperance.
		*set missouri_prohibition +1
*return

*label design_tenement
*if creation > 1
	*achieve tenement_design
	*set local_fame %+10
	*set wealth -25000
	Of course, you cannot leave well-enough alone. You spend more time than you should drafting and re-drafting plans for the new building—how to use the space most efficiently, while allowing light and fresh air to reach the occupants.
	
	When the building is finally erected, you look on it with pride. In time, your design becomes a template for buildings in the neighborhood and beyond.
*else
	You hire a contractor to build a tenement like all the others in the city.
*return

*label sort_aichinger_debt
In the subsequent nights, 
*if debt_offered_aichinger
	you clear your debt 
	*if debt_to_aichinger
		*set debt_to_aichinger false
		to Aichinger. He thanks you for your service.
	*else
		*set debt_from_aichinger true
		from Aichinger. Senator Bailey duly notes the exchange.
*elseif tasked_aichinger
	*set aichinger_rapport %+5
	you receive a note from Aichinger thanking you for your assistance in this matter.
	*if status = 0
		*set status +1
		What's more, he informs you that he will speak to Memeskia and Senator Bailey about your service to him, and see that you are formally readmitted to the Society.
*else
	*set aichinger_rapport %+10
	you receive a note from Aichinger expressing surprise that you would put yourself out in this way for him. But he thanks you graciously nonetheless.
*return