*comment ñáéç…—
*hide_reuse
*advertisement
*gosub_scene util combat_value_ss
*gosub combat_check
*temp weapon "fists"
*temp weapon_is "fists are"
*temp weapon_num 1
*gosub claw_check
*temp interlocutor_1 0
*temp interlocutor_2 0
*temp interlocutor ""
*temp interlocutor_num 1
*temp departer ""
*temp murdered_at_fair false
*temp find_west 0
*comment first encounter: July; second encounter: September; third encounter: November
*comment antagonist encounters: first in August, second in October.
*temp valet_betrayal false
*temp betrayal_revealed false
*temp stl_hunt 1
*comment 1 = pinkertons hunt cult 2 = pinkertons 3 = not hunted 4 = SOD 5 = SOD hunt cult
*temp stl_cult_formerly false
*temp cult_power_struggle false
*temp stl_kid_alive true
*temp noticed_hunters false
*temp doom false
*temp doom_avoided false
*temp west_prob (m_sib and patricide)
*temp imposter "the imposter"
*if west_prob and stl_heard_of_wotton
	*set imposter "Wotton"
*temp skip_sod false
*temp pc_honeytrap false
*temp npc_honeytrap false
*temp emptied_house false
*temp noticed_walker 1
*temp spoke_stl_bjornsdotter false
*temp spoke_stl_fragala false
*temp spoke_stl_lefferts false
*temp spoke_stl_maffi false
*temp spoke_stl_withers false
*temp spoke_stl_yates false
*temp sod_hunt_cult false
*temp negro_day 1
*temp result 3
*temp withers_trinket 1
*temp stlouis_cult_formerly false
*temp seen_carlos false
*temp pinkerton_trap false
*temp quarry "West"
*temp told_becard_silver false
*temp becard_hunts_gould false
*temp has_gould_staked false
*temp gould_dead false
*temp hunter_threshold 15
*temp knows_gabriel false
*temp gabriel "Gabriel"
*temp g_he "he"
*temp g_him "him"
*temp g_his "his"
*temp gabriel_status 1
*comment 1 = unencountered 2 = killed Gabriel 3 = Gabriel survives fight, knows PC vampire 4 = knows Gabriel mortal, told to flee 5 = knows Gabriel mortal, let go 6 = saw, didn't confront, doesn't know mortal 7 = mind wiped
*temp knows_gun false
*temp kill_gabriel false
*temp knows_vampire false
*temp mentioned_quaestor false
*temp gabriel_pinned false
*temp knows_afab false
*temp knows_gender false
*temp becard_gabriel_status 1
*temp spoke_becard_fair false
*temp tells_eliot_cant_help false
*temp promised_jesse 2
*comment 1 = refused 2 = neutral/ignorant/etc 3 = promised
*temp betrayed_jesse false
*temp requested_by_jesse false
*temp knows_jesse_race false
*temp knows_draper_race false
*temp com_gudhrun ((speaks_english or speaks_french) or speaks_german)
*if west_prob
	*set quarry imposter
*if (sod_founder = "oshaughnessy") or ((sod_founder = "michaels") or (sod_founder = "gonsoulin"))
	*set skip_sod true	
*if stlouis_valet_loyalty < 38
	*set valet_betrayal true
*if stlouis_cult and ((sod_plot and (exposure > hunter_threshold)) and (skip_sod = false))
	*set stl_hunt 5
	*set stl_cult_formerly true
	*if valet_betrayal
		*set doom true
		*comment the PC is dead, they just don't know it yet. Unless they can trigger $doom_avoided.
	*goto post_climax_determination
*elseif stlouis_cult and (exposure > hunter_threshold)
	*set stl_hunt 1
	*set stl_cult_formerly true
	*if valet_betrayal
		*set doom true
		*comment the PC is dead, they just don't know it yet. Unless they can trigger $doom_avoided.
	*goto post_climax_determination
*elseif stlouis_cult and sod_plot
	*set sod_hunt_cult true
	*set stl_cult_formerly true
	*comment cf betrayal_sort
	*goto post_climax_determination
*elseif stlouis_cult
	*set stl_cult_formerly true
	*set cult_power_struggle true
	*gosub honeytrap_check
	*goto post_climax_determination
*elseif sod_plot and ((exposure > hunter_threshold) and (skip_sod = false))
	*set stl_hunt 4
	*if valet_betrayal
		*set doom true
		*comment the PC is dead, they just don't know it yet. Unless they can trigger $doom_avoided.
	*goto post_climax_determination
*elseif exposure > hunter_threshold
	*set stl_hunt 2
	*if valet_betrayal
		*set doom true
		*comment the PC is dead, they just don't know it yet. Unless they can trigger $doom_avoided.
	*goto post_climax_determination
*else
	*gosub honeytrap_check
	*goto post_climax_determination

*label honeytrap_check
*if (stlouis_business_climate < 35) and (laborvscapital > 60)
	*if exposure > 6
		*set pc_honeytrap true
		*comment Pinkerton honeytrap for PC, unaware that you're a vampire
	*else
		*set npc_honeytrap true
		*comment Pinkerton honeytrap for NPC, revenge for success of PC.
*return
		
*label post_climax_determination
*if stlouis_cult_power > 70
	*set exposure +2
	*set discretion %+30
	Your cult has grown so vast that sometimes it feels like the entire city bends to your will. @{(feeding_style != "vegetarian") You no longer need to go out to feed if you don't want to; the members of your cult either volunteer for the honor or furnish you with victims.|}

	Some small part of you recognizes the danger of this line of thinking, but the constant invocations of your title, ${stlouis_cult_address}, clouds your thoughts. The adoration is intoxicating.

	You are a god. It is only a matter of time before the whole world bows down before you.
	*page_break
*if stl_hunt != 3
	*if perception > 1
		*set noticed_hunters true
		You begin to get the feeling that someone is following you.

		It's a strange sensation, one you've never felt before. To be the hunted instead of being the hunter.

		You begin surveying your surroundings more carefully, trying to pick out anyone who might be paying too much attention to you. Here and there, you suspect a man, or a woman, or a child…but anyone who attracts your gaze eventually turns off on their own path.

		*if stlouis_cult
			You deploy some of the members of your cult to help you identify your stalker, but they come to no better conclusion than you.

			*if stlouis_cult_power > 70
				Out of an abundance of caution, @{(feeding_style != "vegetarian") you stop hunting altogether; your disciplines tend to your needs.|you cease fetching your own animals to feed from. Better to send your disciplines to acquire the necessary livestock.}

		Whatever this new condition is, you do not care for it.
		*page_break
	*if valet_betrayal and (perception > 3)
		Your fears are confirmed one evening shortly thereafter, but in the most unexpected manner.
		
		${stlouis_valet} is fussing over your outfit before
		*if stlouis_cult
			you attend a ceremonial gathering
		*else
			you attend @{stlouis_enterprise a birthday party for the editor of the ${post_dispatch}|a birthday party for one of the upright men of St. Louis|a birthday party for one of your inventor acquaintances|a gymnastics display at the Turner club|a salon|a ${wctu} meeting|a birthday party for a professor at the university|a séance}, 
		when the brush ${valet_he}'s using slips and falls to the floor. $!{valet_he} bends over to pick it up, and something rolls out of ${valet_his} pocket. You reach down to pick it up—it's a simple locket—and as you straighten, your perception of time dilates and distorts.
		*set doom_avoided true
	
		Inside the locket is a photograph of ${valet_his}
		*if stlouis_valet_lover
			@{stlouis_valet_num wife|husband|partner|wife}.
		*else
			former lover.
		You don't have to open it to sense that. But what you see next is what surprises you: ${stlouis_valet} meeting with a strange man with a thin mustache and derby hat.

		It is then that you realize that your paranoia was not misplaced. ${stlouis_valet} is conspiring to kill you with @{(stl_hunt = 1) a Pinkerton|some crazed vampire-hunter}, and they intend to execute their plan this very evening.

		Without skipping a beat, you hand the locket back to ${stlouis_valet}. "You should be more careful with that; I can see that it is valuable to you," you say with a smile.

		"Thank you, ${sir}," ${valet_he} replies, trying to disguise ${valet_his} nervousness. $!{valet_he} does not know the full extent of your powers, but knows enough to be wary of them. Right now, ${valet_he}'s wondering whether or not ${valet_he}'s been found out.
		*label betrayal_choice

		*choice
			#I confront ${stlouis_valet} and demand to know who the man with the thin mustache is.
				*set betrayal_revealed true
				${stlouis_valet} gasps in surprise. "How did…"
				
				"You know what I am. Did you think you could keep secrets from me?"
			
				"But…"
				
				"Who is he?"
				
				@{(stl_hunt <= 2) "A Pinkerton come to arrest you."|"I'm not really sure; he says that the dawn has sent him. But he is here to put an end to you."}
				
				*goto betrayal_choice
			#Whatever threat this is, it is a mortal one. To have turned my own valet against me? I must flee the city right now.
				*set discretion %-5
				*set compassion %+5
				*set early_chicago_entry true
				*set stlouis_valet_alive false
				Whoever this man is, he has reached @{stlouis_cult into your innermost sanctum|into your haven itself} and corrupted it.
				
				Unfortunately, ${stlouis_valet} clearly knows too much. You kill ${valet_him} without another thought.
				
				While ${valet_his} blood begins to cool on the floor of your kitchen, you pack your things. A hasty exit is never tidy, but you do your best not to leave anything notable behind.
				*page_break
				*if stlouis_cult
					*set wealth *0.9
					As you depart your haven, you find ${stl_kid_nick} approaching alone. "${stlouis_cult_address}," he says, before realizing that he should be more circumspect with your title.
					
					"Come, help me carry my things," you say.
					
					"What's going on?"
					
					"Betrayal. Someone is here to kill me."
					
					"But…how can gods die?"
					
					"The same way they always have. When those closest to them grow envious of them."
					
					${stl_kid_nick}'s eyes grow wide. "Yes, of course, ${stlouis_cult_address}."
				*else
					*temp finery false
					*if wealth > 500000
						*set finery true
					*set wealth * 0.7
					As you depart your haven, you struggle with your bags. You end up dropping several of them in the street. @{finery When the contents spill out into the street, several passers-by remark upon the finery spilling into the mud. Spooked, you leave it, provoking confusion and cries of "thief!" in your wake.|} No time for that; you flee as though @{(rationalism < 50) Cerberus himself|the Four Horsemen} were in pursuit.
				
				*set stl_postscript "After some inquiries, you learn that "
				*if stl_hunt = 1
					*set stl_postscript &"Amanda and several others of your key disciples were arrested by the Pinkertons. They are turned over to US Marshals, and you never hear from them again. The rest of your adherants return to their normal lives and attempt to reintegrate with society at large, having been abandoned by their unliving god@{male |dess}."
				*if stl_hunt = 2
					*set stl_postscript &"your haven was firebombed by the Pinkertons the very night of your departure. Only your decisive flight saved your skin."
				*if stl_hunt = 4
					*set stl_postscript &"your haven was firebombed by unknown parties the very night of your departure. Only your decisive flight saved your skin."
				*if stl_hunt = 5
					*set stl_postscript &"Amanda and several others of your key disciples were unceremoniously executed by unknown parties. The rest of your adherants go to ground, abandoned by their unliving god@{male |dess}."
				*goto_scene timejump5
			#Whatever trap this is, I must turn it on its perpetrators; I must give no sign that it has been uncovered. Instead, I will crush it without mercy.
				"Don't we have a ceremony to officiate?"
		
				"Yes, of course," ${valet_he} says, leaping back into action.
				*page_break
*if stlouis_cult
	Tonight you are holding a massive @{stlouis_cult_celebration prayer session|revival|black mass|celebration}. With so many visitors in the city for the Exhibition, it is only natural that you would open your doors to new adherents. Now is the opportunity for you to expand your reach beyond St. Louis.
	*if cult_power_struggle
		Over the past few years, the cult has grown so numerous that you no longer know all the members. Amanda and ${stl_kid_nick} are increasingly invested with power and authority.

	Amanda joins you as the event is about to begin. @{doom_avoided Scanning about, you see that you have a few precious moments alone with her. You give her some directions, kiss her on her forehead, and send her out to bring this grand experiment to an end.|}

	You step out into the adoring crowd. The awe washes over you. It feels even better than feeding.

	"Welcome!" you @{(stlouis_cult_celebration = 1) intone|cry}, and the crowd answers back@{(stlouis_cult_celebration = 1)  with a silent bow|}.
	*if doom_avoided
		You look out over your disciples. They love you, fear you, respect you, adore you. And tonight, they will give their lives for you.
		
		As it should be.
	
	The ceremony begins. @{stlouis_cult_celebration The room has never felt this so attuned. It is as though everyone is breathing as one.|Your words have never been so inspired; the sermon brings the audience to tears.|Your words have never been so impious…so blasphemous. The crowd is ravished by your sermon and begging for more.|The room vibrates with the sexual energies unleashed by the invocation to do so. These poor humans—all they want is someone to tell them that they can and should idulge themselves without hesitation or regret.}
	
	*if cult_power_struggle
		To your surprise, ${stl_kid_name} drives a knife into Amanda's heart. Simultaneously, worshippers throughout the room draw knives and drive them into their neighbors. You quickly note that the knife-wielders all sport red kerchiefs on their wrists to distinguish themselves from the others.
		
		You cry for them to stop, but they are listening to ${stl_kid_name}—not to you. As the screams of the murdered begin to still, ${stl_kid_nick} turns to face you.
		
		"${stlouis_cult_address}, we have reached the end of this charade."
		
		"Charade?" you intone.
		
		"You do not hear the cries of your faithful. You are indifferent to our plight. That ends today."
		*temp dismantled false
		*temp offer false
		
		*label kid_loop
		*choice
			#I offer him Amanda's role and responsibilities.
				"Amanda's role? Is that what you think I'm after?" he laughs.
				
				"What else would you be seeking?"
				
				"Your blood!"
				
				You look at him quizzically. You have—for good reason, you observe—never divulged much of anything about your true nature—certainly not how others of your kind are created. ${stl_kid_nick} has made a guess, but he has guessed incorrectly.
				*set offer true
				*goto kid_loop
			*if (offer) #I "offer" to make him like me—I can betray him when the odds are more in my favor.
				*set compassion %+15
				*set discretion %+5
				"I can make you like me," you begin.
				
				"A god?"
				
				"Yes."
				
				He licks his lips. "Do it."
				
				*if charm > 3
					Exerting your will—just the smallest amount, lest you raise suspicions—you beckon him closer. He doesn't hesitate, gesturing dismissively to the rebellious disciples to withdraw.
					
					When he nears, you extend your fangs—slowly—and maintaining eye contact, you cut open your wrist and offer it to him. He seizes your arm in his hands and begins to drink.
					
					You see his eyes go wide at the taste—both delicious and putrid at the same time. He falls to his knees, enraptured. You address his disciples: "You may go now. The change will take some time—and it is not appropriate for you to witness it."
					
					${stl_kid_nick}'s associates looks to him, but he has other priorities. Confused, they withdraw.
					
					${stl_kid_nick}'s eyes dilate. He stands and laughs, like a villain on a nickel stage. "I feel it! I feel—alive! It courses through my soul!"
					
					"Do you feel it in you fingers? In the tips of your toes?" you suggest.
					
					"I do! And even the hair on my head…and my scars most of all! Where I cut my leg as a child.…" He holds his hands out before him, marveling at the experience.
					
					"Perhaps that is healing, perhaps not. The blood is capricious," you reply coyly.
					
					"How do you live with it?" he asks, flexing his fists.
					
					"I don't," you reply. He looks up at you—too late to interrupt your blade from slitting his throat.

					His hands go to his neck instantly. He looks at you—the closest thing he's had to a @{male father|mother} in his life—begging you wordlessly to reverse time just a few moments.
					
					Instead, you step forward and reclaim what is yours.
					*page_break
					*goto cult_dismantled
				*else
					You beckon him closer. His squints, still uncertain. @{(willpower < 3) Striving for|Demonstrating a feigned} nonchalance, you extend your fangs and open your wrist. Blood dripping, you hold it out to him. "There is only so much of it, my child."
					
					One of the rebellious disciples begins to interrupt, but ${stl_kid_nick} cuts him off. "And your blood…it will make me like you?"
					
					"It's more complicated than that."
					
					"Make it simple."
					
					You look at the traitors that surround the two of you, eyes and knives glinting in the lamplight. "Drink."
					
					He nears you, suspicious. Your options have narrowed drastically: he seems unwilling to be alone with you.
					*choice
						#I attack. Perhaps if you take him out first, the others will flee?
							His caution is not misplaced.
							*goto attack_kid
						#I flee.
							*goto flee_kid
			#I kill him.
				*label attack_kid
				You extend your @{(shapeshifting > 2) claws and|} fangs and leap at ${stl_kid_nick}.
				*label attack_kid_1
				One blow, two, three…he sinks his knife into your eye in desperation.
				*if combat > 5
					*set stl_kid_alive false
					*set dismantled true
					You scream in pain, but press on. You have been circumspect in the nature and extent of your powers before the cult; now is the time to show them.
					
					You tear his throat open and begin drinking his blood. You bathe in the arterial spurts. He dies with his mouth open in surprise.
					
					You yank the knife from your skull and throw it onto the ground; a hush descends upon the room. Taking a moment to evaluate yourself, you conclude that you need more blood if you are to repair your eye promptly. You make another leap, descending on one of the rebels in a flash of fang. She screams until you @{(strength > 3) yank her jaw from her skull|chew open her throat as well}. Again, you drink as deeply as you can, funneling the power to your eye. You can feel it knitting back together.
					
					Around you, what remains of your disciples are now fleeing in terror. They may have worshipped you as a god, but tonight they saw some portion of your true power and they were unprepared for the encounter.
					*label cult_dismantled
					*set stlouis_cult false
					*set cult_power_struggle false
					*set exposure +2
					*set income -5
					*if income < 0
						*set income 0
					
					In the days that follow, you do your best to pick up the pieces of your organization, but it has been thoroughly dismantled. The faithful were murdered and the rebels want nothing to do with you. 
					*if (dismantled = false) and stl_kid_alive
						From a distance, you observe that ${stl_kid_nick} trying to set himself up as a potentate in your absence, but without your powers, the flock dwindles in numbers.
					
					You are, once again, a god without believers.
					*page_break
					*goto norris_resolution
				*else
					You scream in pain—a great mistake. The rebels were already preparing to attack. Now that you have shown weakness, they fall upon you in greater numbers. They begin hacking and tearing with their blades. Any one, two, or three you could take on your own, but a mob of them simply overwhelms you. When they begin sawing off your limbs, you realize that your end is near.
					
					You see them drinking your blood—trying to take some portion of your power for themselves—but they do not know the mysteries of your kind. When they finally sever your head from your neck, you find it to be almost a relief.
					*set killed_by_mortal true
					*goto_scene scoring
			#I flee.
				*label flee_kid
				*if agility > 2
					You leap past the rebellious disciples, down a hallway and out a rear exit of your makeshift temple. When the moonlight and a cool breeze graces your cheeks, you know that you will survive another night.
					*goto cult_dismantled
				*else
					You are surrounded by the rebellious disciples. Though you seek to push through, they rebuff you. Turning, you see that you have no choice but to attack ${stl_kid_nick}.
					*goto attack_kid
	*elseif doom_avoided
		With bloodtears in your eyes, you turn the affair over to ${stl_kid_nick}, who takes your place @{stlouis_cult_celebration at the head of the circle|at the pulpit|at the pulpit|in your throne}. Amanda nods at you from the far side of the room; she is ready.
		
		"What are you doing?" ${stlouis_valet} inquires. $!{valet_he} is between you and the exit. @{betrayal_revealed During a normal celebration, ${valet_he} would not be here, but since you uncovered ${valet_his} betrayal, ${valet_he} has been waiting, hoping that ${valet_his} doom might somehow be averted.|Of course, ${valet_he} should not be here, but you knew that ${valet_he} would be.} The smell of smoke hits your nostrils.
		
		You draw ${valet_him} close, and whisper "@{speaks_latin [i]sic semper proditoribus[/i]|thus always to traitors}" into ${valet_his} ear. With your off-hand, you drive a blade between ${valet_his} ribs and pierce ${valet_his} lung. $!{valet_his} eyes widen in shock; when ${valet_he} tries to inhale, things only get worse.
		
		You continue past towards the door. From behind, you hear someone calling your name. "Stop! In the name of @{(stl_hunt = 1) the law!|the Dawn!}"
		
		Turning, you spy the man with the thin mustache trying to reach you, but he is obstructed by Amanda and a few other of your disciples. They let him pass just in time for ${stlouis_valet} to collapse in his arms.
		
		You shut the door to the sanctuary behind you, dropping a veritable timber to block the only remaining exit.
		
		The sound of screams mix with the sounds of prayers from within. The man with the mustache bangs on the door; he demands that you open it. You laugh at him. "You were here to murder me, and now you want me to let you go?"
		
		"You must!"
		
		"Whose story do you think this is?"
		
		"Me! I'm the hero of this story!"
		
		"There no heroes in this story," you retort.
		
		On the other side of the door, the smoke must have grown too great, as you the sound of coughing as ceased. Soon, the building is in flames.
		*set stlouis_cult false
		*set stlouis_valet_alive false
		*set compassion %+5
		*set discretion %+5
		*set income -5
		*if income > 50
			*set income -5
		*if income > 100
			*set income -5
		*page_break
		*achieve stl_doom_avoided
		
		Amanda is dead. ${stl_kid_nick} is dead. ${stlouis_valet} is dead. Your cult is ashes. But the man with the thin mustache is dead as well…and you are very much alive.
		*page_break
		*goto norris_resolution
	*else
		*temp charm_mod 0
		As the ceremony progresses, something begins to feel awry. Looking around the space, you realize that there are @{doom numerous|several} faces that you do not recognize. You try to dismiss the sensation; the cult is large now and there are many adherants who are strangers to you. But as the climax of the evening nears, some of those strange faces begin to close around you.
		
		*choice
			#I direct Amanda to sound the alarm; my disciples will defend me!
				Amanda stands forth and bellows "Hear the words of ${stlouis_cult_address}! We are under assault! There are strangers in our midst! If you do not know your neighbor, then hold them fast!"
				
				At these words, a general mêlée breaks out. @{(stlouis_cult_celebration = 4) It's unclear whether the fact that most of the people in the room are nude helps or hinders the matter.|} Within a few moments, the matter begins to resolve, as the interlopers and your flock largely distinguish themselves from one another.

				It's then that you see him: a man with a thin mustache and a derby hat. He is making his way through the brawl, eyes locked on you.
				*if doom
					The determination of your disciples has suddenly turned to screams. The smell of blood begins to fill the air. Your disciples are bleeding for you.
					
					*if discretion > 50
						You extend your fangs @{(shapeshifting > 2) and claws|} in preparation for some bloodletting of your own. The man in the mustache draws a revolver and raises it while you crouch, steeling yourself to leap out of the way. You smirk; even if the bullet hits you, bullets are much less effective against dead flesh than living. Whoever planned this attack was clearly an imbecile.
						
						Suddenly, you're struck from the rear. You struggle, unable to turn your chest or shoulders. Whatever struck you is being driven deeper into your body. Turning your head, you spy ${stlouis_valet} behind you, wielding a…hay fork? You try to reach back, but the haft is far too long; you try to whip around, but ${valet_he} is determined. The only option is forward, back towards the man in the moustache…
						
						Only then do you feel the hay fork in your chest.
					*else
						You turn to seek an exit—discretion is the better part of valor—when you find yourself suddenly impaled on a hay fork. Looking up, you lock eyes with ${stlouis_valet}. $!{valet_he} does not smile, but rather pushes forward on the hay fork, driving the tines deeper into your flesh.
						
						It hurts, yes, but that's not exactly the problem. The problem is that the shaft of the hay fork is both heavy and unwieldy—and the far end is held by a very determined ${stlouis_valet}. You try to back up and pull yourself off the weapon, only to feel another one pierce your flesh from the rear.
						
					Your vision begins to redden. You thrash. You've been betrayed by ${stlouis_valet} and trapped amid your own disciples.
						
					It's then that several individuals descend on you with machetes, hacking at your flesh with their thick blades. 
					*label cult_hacking
					The man with the thin mustache stands a safe distance away, watching your bloody end. @{(discretion > 50) He never bothered to fire his revolver.|}
					
					@{(stl_hunt = 1) As your vision begins to go dark, some part of your mind latches on to the tin badge on the man's vest, partially hidden by his overcoat: the badge of a Pinkerton. What did the Pinkertons want with you?|}
					
					In time, they manage to sever your head from your neck. And so you reach your bloody end.
					*set killed_by_hunter true
					*goto_scene scoring
				*elseif stlouis_cult_power > 60
					*label cultDefends
					For a few moments, it seems as though all is lost. The attackers and their wooden batons make a swath through the crowd, trying to reach you. But you pull yourself up to your full height and call to your flock: "Defend me from these intruders!"
					
					You can almost see the charge go through the crowd. They take heart from your words and redouble their efforts, and it shows. First one, then a second, then several more of the attackers are grappled and dragged to the floor, arrested by the sheer numbers of your faithful.
					
					Mustache is holding several of them at bay with a revolver. @{(stl_hunt = 1) Attached to his waistcoat, to your surprise you observe the silver badge of the Pinkertons. What do the Pinkertons want with you? you muse.|} When he finally fires it, it is right in the face of one of your charging faithful. The sound of gunfire changes the tenor of the conflict; whereas before, the interlopers were showing some sort of restraint with their batons, now machetes emerge in greater numbers. In turn, your faithful redouble their efforts.
					
					*comment TODO Should this result in the cult being dismantled? Or just severely damaged?
					*goto cult_barely_survives
				*else
					You call to your disciples, trying to direct them to defend you, but they crumble before the interlopers. The sound of bones breaking under blows from wooden batons echoes through the room; whoever these people are, they're not trying to outright kill your disciplines. @{(compassion < 35) At least they won't have to die for you, some part of you muses.|} As the interlopers—and Mustache—approach, several machetes appear. While they may not want to kill your disciples, they do not seem so concerned about you.
					
					*choice
						*if (charm > 3) #Before attacking, I try to frighten away as many of the attackers as I can.
							Drawing yourself to your full height, you turn your normal sense of grace and majesty into something terrible. You eyes testify to the hells of suffering that you will inflict upon those who have dared to challenge you. @{(shapeshifting > 2) These individuals clearly know you're a vampire, so you use this moment to turn your hands to claws in dramatic fashion.|}
							*if charm > 4
								*bug
							*else
								*set charm_mod 2
								
								Several of the interlopers drop their machetes or batons and run. You don't know if it's enough to turn the tide, but at this moment, every bit counts.
								
								@{(shapeshifting > 2) |Lacking another weapon, you grab a knife from one of your fallen disciples and prepare to defend yourself.}
								
								You and Mustache begin to circle one another; he is clearly made of stronger stuff than his companions. Those that remain, however, begin to form a deferential circle around the two of you.
								*goto final_cult_fight_postcharm
						#I attack the man with the mustache.
							*label final_cult_fight
							*gosub_scene util combat_value_ss
							@{(shapeshifting > 2) This man clearly knows that you are a vampire; no point in hiding it now. You turn your hands to claws and prepare to charge.|Lacking a better weapon, you grab a knife from the unconscious form of one of your disciples.} 
							
							The problem is that Mustache has friends; alone you could surely defeat him, but his companions complicate things. The two of you do a little dance, circling one another. Mustache's companions give the two of you a respectful distance—not that they would hesitate to intervene if necessary.
							*label final_cult_fight_postcharm
							
							*if combat > (10 - charm_mod)
								Finally, the battle is joined. It is clear that you have the upper hand—a blow here, a forearm block there, your fangs tearing through the flesh of his upper arm—while Mustache's companions stand around in awe.
								
								Then, you're on top of Mustache. You raise your @{(shapeshifting > 2) claws|knife} high, you prepare to finish him. At that moment, however, you catch sight of the revolver in Mustache's hand. He fires it directly into your throat.
								
								The pain blossoms into your vision. Some part of your consciousness knows that you can survive worse, but that does not stop you from clutching at your gaping wound with one hand and knocking the revolver from Mustache's hand with the other.
								
								It skitters across the floor, but it is too late; the spell has been broken over Mustache's companions. They jump forward with their machetes, ready to dismember you.
								
								With a hiss and a spit, you leap away from Mustache and past the line of companions. Once out of their ring, you dash through a curtain and down a corridor.
								*goto flee_cult
							*elseif combat > (8 - charm_mod)
								Finally, the two of you clash. After a moment, it becomes clear that you have the upper hand—but only for a moment. Mustache's friends see it too and they do not hesitate to defend their leader.
								*goto mid_fail
							*else
								Finally, the two of you clash.
								*label mid_fail
								A few grunts, the sound of bones breaking, and a long sigh fill the air.
								
								You sink to your knees, clutching your crushed hands, your kneecap shattered, your femur sticking from your thigh.
								
								One of the interlopers hands Mustache a machete. @{(stl_hunt = 1) As your vision begins to go dark, some part of your mind latches on to the silver badge on the man's vest, partially hidden by his overcoat: the badge of a Pinkerton. What did the Pinkertons want with you?|} After swinging it once to get a feel for its weight, he uses it to decapitate you.
								*set killed_by_hunter true
								*goto_scene scoring
						#I look for an exit.
							*label quickExitCult
							*set discretion %-5
							*if agility > 3
								You run. You run as fast as your feet will carry you. You leap over one of the invaders and run along the wall of a hallway for ten feet at one point.
								
								You refuse to be stopped. Whether through sheer force of will or the blood in your veins, you burst into the street and rejoice as moonlight and an easy breeze kiss your face.
								*goto flee_cult_2
							*elseif (stealth > 3) and (agility > 2)
								You can change your appearance in the minds of others—you just need to break their line of sight long enough to let it disrupt their perceptions.
								
								And so you run. You run as fast as your feet will carry you. Finally, through a curtain and down a hallway and you slow your pace: no longer a fleeing vampire, but an enraged attacker or a terrified disciple. 
								
								Your first encounter with one of the baton-wielding thugs almost goes awry—you can see the indecision on her face, trying to figure out who you are, whether friend or foe—but then someone calls your name, and some part of her brain shuts off. She smiles and carries on, leaving you a clear path to the exit.
								*label flee_cult
								
								You burst into the street. The moonlight and an easy breeze kiss your face.
								*label flee_cult_2
								You might just survive long enough to see another night.
								*goto flee_cult_final
							*else
								You run. You run as fast as your feet will carry you. But that is only so fast.
								
								Before you can reach the curtain and the safety of the hallway beyond, two thugs interject themselves. A initial scuffle rebuffs you. Turning, you see Mustache closing on you.
								*goto final_cult_fight
			#I look for an exit.
				*if doom
					There is a curtain and a hallway beyond; from there, an exit to the street. Less than one hundred feet to freedom.
					
					You turn and begin to make your exit. You push through the curtain, you turn into the hallway, and there you encounter ${stlouis_valet}.
					
					Your jaw drops. "What are you doing here?" you demand.
					
					Only then do you take note of the hay fork in ${valet_his} hands. "Waiting for you," ${valet_he} replies, before impaling you with it.
					
					You look down in disbelief. It hurts, but not so much as to be a real problem. You @{(discretion < 50) shake your head in confusion|snicker}. "Did you think a hay fork would hurt me?" you @{(discretion < 50) ask|thunder}.
					
					"No, not really," ${valet_he} replies.
					
					It's only then that you feel yourself impaled from the rear. Turning your head, you see some of Mustache's thugs holding another fork.
					
					And here you are, trapped in this hallway, impaled by two hay forks. They begin to push you back out onto the stage, where Mustache can more easily confront you. You struggle against the tines of the forks. That is all the permission the rest of the thugs need; they descend on you with their machetes, hacking at your arms and legs.
					*goto cult_hacking
				*elseif stlouis_cult_power > 60
					*comment I thought about raising the threshold because you don't command the cult to defend you first, but then I thought it should be lowered because it was your first action, and am currently leaving it where it is.
					*goto cultDefends
				*else
					*goto quickExitCult
			#How dare this insect interrupt my ceremony! I attack the man with the mustache.
				*set discretion %+10
				*goto final_cult_fight
		
	*label flee_cult_final
	*set stlouis_cult false
	*set income -5
	*if income > 50
		*set income -5
	*if income > 100
		*set income -5
	*page_break
	*goto norris_resolution
	
	*label cult_barely_survives
	*set stlouis_cult_power %-40
	*set income -2
	*if income > 50
		*set income -2
	*if income > 100
		*set income -2
	*page_break
	*goto norris_resolution
	
*if ((stl_hunt = 2) and (valet_betrayal)) or (stl_hunt = 4)
	*comment if hunt = 2, then the hunters don't necessarily know what the PC is. I wonder if they think he's a serial killer, like HH Holmes? 
	*temp hunting_spot 1
	*comment 1 = Patrick's saloon, 2 = salon, 3 = livestock yard, 4 = Planter's House Hotel, 5 = Rosebud
	*temp prey 1
	*comment 1 = musician, 2 = priest, 3 = minister, 4 = Rough Rider, 5 = card shark, 6 = traveling salesman, 7 = brewery scion, 8 = male prostitute
	*if feeding_style = "artists"
		*set hunting_spot 2
	*if feeding_style = "children"
		*set hunting_spot 2
	*if feeding_style = "clergy"
		*if ((ethnicity = "french") or (ethnicity = "southern"))
			*set hunting_spot 2
		*if (religious_tradition = "catholic") or (religious_tradition = "pagan")
			*set prey 2
		*if religious_tradition = "reformed"
			*set prey 3
	*if feeding_style = "drunks"
		*if ethnicity = "african"
			*set hunting_spot 5
	*if feeding_style = "gamblers"
		*if ethnicity = "african"
			*set hunting_spot 5
	*if feeding_style = "itinerants"
		
		*if ((ethnicity = "french") or (ethnicity = "southern")) or (finance > 1)
			*set hunting_spot 4
			*set prey 6
	*if feeding_style = "laborers"
		*if ethnicity = "african"
			*set hunting_spot 5
	*if feeding_style = "merchants"
		*set hunting_spot 4
		*set prey 6
	*if feeding_style = "prostitutes"
		*set prey 8
		*if ethnicity = "african"
			*set hunting_spot 5
	*if feeding_style = "socialites"
		*set hunting_spot 2
		*set prey 7
	*if feeding_style = "soldiers"
		*set prey 4
		*if ((ethnicity = "french") or (ethnicity = "southern"))
			*set hunting_spot 2
		*if ethnicity = "african"
			*set hunting_spot 5
	*if feeding_style = "vegetarian"
		*set hunting_spot 3
	
	As is your wont, you set out to find a mortal to satisfy your cravings for blood. It has been a few days since you have fed, and the hunger gnaws from the inside of your fingers and toes, trying to burst out into the world if only you would grip someone hard enough. ${stlouis_valet} knows this particular look well, and upon seeing your face, immediately goes to prepare the carriage.
	
	With ${valet_him} driving, you make your way to @{hunting_spot Patrick's, a saloon at the edge of the Kerry Patch|the home of Mrs. Collins, who is hosting a dinner for a number of her friends|the stockyards on the southwest side of town|the Planter's House Hotel; you can always find someone in the hotel bar|the Rosebud}.
	
	*if (feeding_style != "vegetarian") and (feeding_style != "children")
		Upon entering, it doesn't take long for you to settle on your prey: @{prey the piano-player|a priest|a Southern Baptist minister|a former Rough Rider, still eating on his time under Roosevelt|a card shark|a businessman, here seeking a way to distribute his patented soap at the Fair|a member of the Griesedieck clan|a young hustler with a winning smile}. Before long, you have engaged his attention, and its not too long afterwards that you sink your fangs into his neck. He shudders at the sensation and you take your time, making sure to drink as much as you safely can.
	*if feeding_style = "children"
		Once in the home, it does not take you long to ascertain where the children are sleeping. When the festivities get properly underway, you slip away, drink your fill, and return before anyone is the wiser.
	*if feeding_style = "vegetarian"
		You pay one of the workers for access to the abbatoir. There, you drink the lifeblood of a hog. When you are finished, you leave the corpse for the butcher; one less pig for him to kill.

	Straightening your clothes, you do a quick once-over, making sure that no blood has splattered onto them. 
	*if doom_avoided
		Detecting none, you gather your things and leave. From your interrogation of ${stlouis_valet}, you know that tonight is the night that someone intends to kill you.
		
		But not if you kill them first.
		*page_break
		Once outside, you pause for a moment. As you do not respire, the delights of a good cigar have always been beyond your ken. But that does not mean you can't suck and blow air when necessary.
		
		Standing in the doorway, you pull a cigar from one of your pockets, cut off the tip with a pocketknife, and take a moment to light a match. Across the street, ${stlouis_valet} gets down from the carriage and comes round the horses to open the door for you.
		
		You cross the street, carefully keeping the match alive as you feign lighting the cigar. Finally, you pause at the door to your carriage. "Hold a moment, ${stlouis_valet}, let me light this."
		
		"Of course, @{male sir|mistress}," ${valet_he} replies, handling you a small bottle.
		
		Taking the bottle, you hurl it into the open carriage. It shatters, spraying its contents all over a man waiting in the shadows for you with a revolver. With a flick of your wrist, you toss the match in afterwards and slam the door.
		
		There are screams from inside the carriage. A gunshot rings out. You look over and @{(compassion < 50) catch ${stlouis_valet}'s body as it slumps to the ground, lifeless. After a moment, you let ${valet_him} go; the danger has not yet passed.|watch dispasstionately as ${stlouis_valet} drops to the ground, dead.} The man inside tries to push open the carriage door, but you @{male |hike up your skirts} and kick it closed again. His screams echo up and down the street.
		
		At this point, the horses are understandibly terrified. 
		*achieve stl_doom_avoided
		*if shapeshifting > 1
			You move to release them their harnesses. You throw the body of ${stlouis_valet} over one and mount the other. With a kick, you urge the horses forward. You pass several individuals sporting hay-forks and machetes as you ride down the street; they look at you in awe and when you turn your gaze upon them, they flee.
			*goto norris_resolution
		*elseif shapeshifting > 0
			They despise you—you are a dead monster of eternal hunger—but your words calm them enough to let you disconnect them from the burning carriage and to let you throw ${stlouis_valet}'s corpse across one of their backs. Once situated, you grab their reins and lead them home.
			
			Behind you, you hear several other individuals—compatriots of your adversary, presumably—half-heartedly investigating the fire. They do not pursue you.
			*goto norris_resolution
		*else
			*set exposure +1
			They want nothing to do with you—a dead creature of eternal hunger—and eventually begin careening down the street, dragging the flaming carriage behind them. Soon, a hue and cry is raised as people fear a conflagration.
			
			*if feeding_style = "vegetarian"
				You throw ${stlouis_valet}'s body to the pigs in the stockyard and make your way home.
				*goto norris_resolution
			*else
				You have to drag ${stlouis_valet}'s corpse away from the scene to obscure your involvement in the matter. Once you find a hiding place, you resolve to return the next evening to move the body to a more permanent home.
				
				As it is, you retreat to your home, grateful for having survived another night.				
				*goto norris_resolution
	*elseif doom
		Detecting none, you gather your things and return to the carriage @{hunting_spot behind the saloon|behind Mrs. Collins's house|in front of the stockyards|on a side-street near the hotel|behind the Rosebud}; when ${valet_he} catches sight of you, ${stlouis_valet} rushes to open the door for you.
		
		As you begin to step into the carriage, you are surprised to find yourself looking down the barrel of a revolver. "${mr} ${surname}, a pleasure to make your acquaintance. Won't you hold still a moment?" @{(charm > 3) Interestingly, is not looking directly at you, but rather at your chest.|}
		
		As the man says this, you feel  against your back; turning ever so slightly, you find yourself hemmed in by three hay-forks, each sharpened to a fine point. You look through the window of the carriage door at ${stlouis_valet}; ${valet_he} mouths an "I'm sorry" to you. Then the tines of the hay-forks are plunged into you.
		
		Reacting to the pain, you start to jump into the carriage to escape the forks, but Mustache's revolver fires first, the echo reverberating in the cabin; the bullet hits you directly in the face, shattering your cheek and jawbone, and slamming you back onto the tines of one of the forks; you watch as they emerge from your chest in a spray of cold, viscous blood.
		
		While you are trying to grasp the forks and break their hafts, two more men appear with machetes; every time you try to grasp a fork, one of the machete blades cuts into your flesh. The pain is driving you mad and you can feel the beast howling inside of you.
		
		Finally, Mustache unveils the [i]coup de grâce[/i]: a small bottle of grain alcohol and a single-strike match@{(perception > 1) ; you can smell the fumes of evaporating alcohol from here|}.
		
		And so, there @{hunting_spot behind Patrick's saloon|behind the home of Mrs. Collins|in front of a St. Louis stockyard|around the corner from the Planter's House Hotel|behind the Rosebud}, you meet your fiery end.
		*set killed_by_hunter true
		*goto_scene scoring
	*else
		Detecting none, you gather your things and return to the carriage @{hunting_spot behind the saloon|behind Mrs. Collins's house|in front of the stockyards|on a side-street near the hotel|behind the Rosebud}; when ${valet_he} catches sight of you, ${stlouis_valet} rushes to open the door for you. Taking ${valet_his} profferd hand, you step into the carriage. $!{valet_he} returns to ${valet_his} perch and snaps the reins, jerking the carriage into motion.
		
		What cannot be more than one hundred feet later, the carriage comes to a sudden halt. You can hear the horses whinny in surprise and ${stlouis_valet}'s voice rise in a challenge. You peer out the window and see several individuals milling about, throwing something on the carriage. Taking a sniff, you realize that it is grain alcohol.
		
		That's when you spy a man in a long coat and sporting a mustache light a match.
		*temp on_fire false
		*label exit_carriage_loop
		
		*choice
			#I kick open the door and launch myself at the man with the mustache.
				*gosub_scene util combat_value
				*label burst_of_fury
				*if combat >= 9
					You fly out of the coach in a burst of fury, landing squarely on Mustache's chest. Several lighting-quick blows turn his face to pulp. The match falls to the ground.
					
					Arrayed to either side of Mustache are a number of men with hay-forks and machetes. They look at you, but the speed and ferocity with which you dispatched their leader has clearly sapped them of their enthusiasm. One plunges his hay-fork in to your side—painful, certainly—but you rip it out and turn it on its former bearer, plunging it straight through the bone of his face and out the back of his skull.
					
					Counting discretion the better part of valor, the remaining assailants break and run.
					*label mustache_success
					*page_break
					Searching Mustache's body, you find @{(stl_hunt = 2) a Pinkerton's badge. Why would the Pinkertons want you dead? How do they know who you are?|little to indicate his interest in you.}
					*if (stl_hunt = 2) and (stl_met_preston)
						Does Preston know who and what you are? Did you give it away, somehow?
					
					You growl in frustration. This body will tell you nothing more.
					*goto norris_resolution
				*elseif combat >= 7
					You fly out of the coach in a burst of fury, landing squarely on Mustache's chest. You raise your hands to pummel his face to a pulp, when one of Mustache's compatriots jabs you with a hay-fork. The tines of the fork have been sharpened to a wicked point, and it pierces your dead flesh with ease. You scream in pain—it is not often that your dinner fights back.
					
					You twist and rip the fork out of the man's hands, only to face the tines of several more. Rolling off of Mustache and under the sharpened tips, you trip one of the men and bring him down on top of you. Twisting, you use his body to block a jab by a third man; the one you are holding spits blood in your face as the tines pierce his lungs.
					
					Tumbling forward yet again, you come to your feet and begin to flee. There is a crack of a revolver behind you, but it misses.
					*goto abandon_valet
				*else
					You fly out of the coach in a burst of fury, landing squarely on Mustache's chest. You raise your hands to pummel his face to a pulp, when one of Mustache's compatriots jabs you with a hay-fork. The tines of the fork have been sharpened to a wicked point, and it pierces your dead flesh with ease. You scream in pain—it is not often that your dinner fights back.
					
					You twist and rip the fork out of the man's hands, only to face the tines of several more. You dodge to the side, but find yourself corralled. Two, three, four more jabs and you are pinned to the ground, the shouts of your assailants jubliant in the quiet night. Finally, Mustache fetches a mustache from an associate and begins hacking at your neck. Several blows later, your head detaches from your shoulders and everything goes dark.
					*set killed_by_hunter true
					*goto_scene scoring
			*selectable_if (speaks_english) #I throw open the door and demand to know what is happening here.
				You throw open the door and call out, "What is the meaning of this!"
				*if (charm > 3) and (stl_hunt = 2)
					*set stlouis_valet_loyalty %-20
					Mustache makes the mistake of meeting your eyes. In the space of a heartbeat, he is clay in your potter's hands. "Why don't you put out that match, good sir," a command which he hurries to obey.
					
					Surveying the rest of the scene, you note a number of other assailants with hay-forks and machetes, presumably ready to impale and dismember you. "Perhaps you should tell your friends that we would like to be alone?" you offer.
					
					Mustache waves his hand. The hay-forks lower and machetes lower. "But, sir!" one of the hay-forks protests.
					
					"It's ok…" Mustache begins. At that moment, the match burns down to his fingers. He barely registers it, beyond dropping the match reflexively.
					
					The lieutenant sense that something is amiss, but before he announce the attack, you are fleeing. It takes Mustache several moments to recover, but by that point you have disappeared around a corner.
					*goto abandon_valet
				*else
					*set on_fire true
					@{(charm > 3) You try to catch Mustache's eyes, but he refuses to meet your gaze.|}
					
					"Your doom!" he intones, before tossing the match against the carriage.
					
					The fabric—though sold to you as flame-resistant—soon catches alight. You don't have long.
					*goto exit_carriage_loop
			#I flee out the opposite door.
				*set discretion %-5
				Turning, you throw open the door on the other side of the carriage, and come face-to-face with a hay-fork.
				
				*if (charm > 3) or (agility > 3)
					@{(charm > 3) You look at the man sporting the fork and unleash a menacing growl. He drops the farm implement and you leap past him and into the night.|You look at the man sporting the fork and—in the blink of an eye—you dart around his tool and into the night.}
					*label abandon_valet
					You hear the chaos behind you as they continue to accost ${stlouis_valet}, but ${valet_he} will have to tend to ${valet_his} own situation.
					
					You do not stop running until you make it home—but you stop short. If those hunters—for lack of a better word—were following you, then surely they know where you live. Retreating here would be unwise.
					
					*if stlouis_hideout
						Thank goodness you have your hideout in Chestnut Valley. Hopefully they know nothing about it.
						
						Slipping inside, you make your way to your reserve quarters. When you finally close your eyes, it is with the sincere hope that you will open them again in a few hours.
						*goto reunite_valet
					*comment other ways to get out of this for free? Staying with blood dolls?
						
					The sun is not far away. You make your way to the Southern Hotel; surely, Bailey will offer you a place to stay in exchange for @{debt_from_bailey the debt he owes you|a debt}.
					*label southern_hotel
					*page_break
					Bailey is at the bar, as you had hoped he would be.
					*if debt_from_bailey
						*set debt_from_bailey false
						As expected, he demands the nullification of the debt he owes you. Lacking other options, you accept.
						
						Of course, for that price, he showers you with the finest delights that the hotel can provide.
						*goto reunite_valet
					*else
						*set debt_to_bailey true
						He happily accepts a debt from you in exchange for a temporary haven. Begrudgingly, you accept his terms and retreat to its confines to lick you wounds.
						
						*label reunite_valet
						*page_break
						The next evening, you set out in search of ${stlouis_valet}. $!{valet_he} is back at your haven, but you do spot several individuals in the proximity that seem suspicious.
						
						You manage to get word to ${stlouis_valet}, and the two of you reunite at the Lafayette Tavern.
						*goto norris_resolution
				*elseif strength > 3
					You jump down to the ground with the intention of charging past the bearer of the hay-fork, but you are too slow. The tines dig into your skin, but miraculously bend before actually piercing your flesh. The man looks at you, astonished. You throw him and his fork out of the way and flee into the night.
					*goto abandon_valet
				*else
					You jump down to the ground with the intention of charging past the bearer of the hay-fork, but you are too slow. The tines pierce your chest, pushing you back towards the carriage.
					
					You muster the courage to push yourself forward onto the tines, attempting to reach the man, but his shouts have brought his friends, who soon impale you as well.
					
					Finally, Mustache rounds the rear of the carriage. Taking a machete from his associate, he begins hacking at your neck. One, two, three blows, and everything goes dark.
					*set killed_by_hunter true
					*goto_scene scoring
			*if ((stealth >= 3) and (on_fire = false)) #I redirect their attention away from me and slip away.
				*set discretion %-10
				*set exposure +1
				Kicking open the doors on both sides of the carriage, you withdraw into the shadows, attempting to obstruct their view of you.
				
				Frustrated, you here Mustache call out for you to surrender. When you do not respond, he tosses the alcohol onto the carriage and sets it alight with the match. The fabric—though sold to you as flame-resistant—soon catches alight.
				*if willpower > 2
					No matter; you don't intend to stay in here for much longer.
					
					One heartbeat; two. The flames are licking up the left side of the carriage. The horses are whinnying outside.
					
					Amid the chaos, you carefully slide into the doorway. When the assailants do not respond, you step out the right side door and down to the ground. Amazingly, the assailants are oblivious to your movements, still watching the carriage for movement. 
					
					You crouch under the tines of the hay-forks and dash down the street.
					
					*goto norris_resolution
				*else
					*set combat -1
					The fire sends a spear of fear through you. The urge to flee its licking tongues compels you to exit the carriage before the time is right.
					*goto burst_of_fury
*if valet_betrayal and stlouis_valet_alive
	*temp exposed false
	*page_break
	Sleep—or whatever condition it is that vampires engage in while the sun is out—is a fitful affair. You are sometimes aware of your surroundings, but other times it is more dreamlike, and other times you have no sense of consciousness whatsoever.
	
	Today, however, things are different.
	
	*if sleeping_place = "coffin"
		Someone is in your sleeping room. Your coffin is hoisted up and is now being carried by several individuals.
		
		You fight through the lethargy of the daysleep. "${stlouis_valet}?" you cry.
		
		"There is nothing to worry about, ${mr} ${surname}. We just need to move you," ${valet_he} replies immediately.
		
		Move you? What is ${valet_he} talking about?
		
		There is something wrong. You are certain of it.
		
		*if willpower >= 3
			Summoning every fragment of your will, you push through the drowsiness and open your eyes. With a growl, you push the lid of the coffin above you open, catching everyone by surprise.
			
			You are in your kitchen, carried by four men, while ${stlouis_valet} seems to be leading them—and you—out into the back yard. And the sunlight.
			
			"What are you doing?" you scream.
			
			"I…" ${stlouis_valet} stammers. There is no point in lying; ${valet_he} was trying to kill you.
			*if charm > 3
				
				"Close the door," you demand. Unable to resist, ${stlouis_valet} obeys.
				
				The danger of the sunlight having passed, you end the threat to your life. The fact that the four porters are caught in the crossfire is just something you will have to live with.
				*set stlouis_valet_alive false
				*goto norris_resolution
			*else
				*gosub_scene util combat_value_ss
				
				You are going to have to fight for your life. Fortunately, neither ${stlouis_valet} nor these porters look much like fighters. You extend your fangs@{(shapeshifting > 2) and claws|} and reach for the closest one.
				*if combat > 6
					
					Within moments, the porters are dead; their splattered blood is a new, macabre choice in décor for your kitchen. ${stlouis_valet} screams and runs for the door, but trips and falls half inside and half outside. $!{valet_he} scrambles to draw ${valet_him}self into the sunlight and out of the reach of your hungry grasp, but you seize ${valet_his} ankle and shrug off ${valet_his} kicks.
					
					With one forceful yank, you pull ${valet_him} back into the house and slam the door shut.
					*set stlouis_valet_alive false
					*goto norris_resolution
				*else
					
					You fumble your first few blows, wounding one of the porters but not killing him. In a spark of ingenuity, ${stlouis_valet} draws the curtains on the window, and suddenly the room is bathed in sunlight from multiple directions.
					
					You feel your flesh pricking up and finally bursting into flame under the sun's hungry rays. You pinwheel your arms, trying to suppress the flames, but this no natural fire. The porters scream in horror at the sight, while ${stlouis_valet} watches in delight at your misery.
					
					You fall to your knees, to your chest…and finally your awareness of your surroundings fades to nothingness.
					*set killed_by_mortal true
					*goto_scene scoring
		*else
			Suddenly, you can sense that your coffin is outside; it is warmed by the sun's rays. Whoever is carrying you puts you down…it feels like it's the middle of the street.  Or maybe the back yard?
			
			It's then that your worst possible fear is realized as the lid of the coffin is lifted open.
			
			You only have the briefest moment to take in what is happening: you are, as you surmised, in the back yard of your home. There are at least three or four men standing about, besides ${stlouis_valet}. They seem as terrified as you—you surmise that ${stlouis_valet} did not fully explain the undertaking.
			
			And then you feel your skin begin to burst into flame.
			*page_break
			*if strength > 3
				Thankfully, your immense strength seems to buy you a few moments of endurance. Leaping from the coffin, you barrel through the gaping onlookers and into the cool embrace of the kitchen's darkness.
				*label escaped_flames
				
				You quickly pat out the flames and then look out onto the yard. ${stlouis_valet} stands there, while ${valet_his} companions drop their implements and flee; ${valet_he} took ${valet_his} shot and missed. You cannot allow ${valet_him} another.
				
				@{(strength >= agility) Suddenly confident in your ability to survive a few moments of the sun's fury, you bound towards ${stlouis_valet}; with one blow, you crush ${valet_his} skull, and quickly retreat back into the darkness.|Pulling a knife from a shelf, you dash into the yard, slit ${valet_his} throat, and return to the cook darkness before ${valet_his} body has slumped to the ground.}
				*set exposure +2
				*set stlouis_valet_alive false
				
				*gosub introspection
				
				You will have much to tend to when the sun sets, but for now, you can feel the need for rest tugging at your edges. You close the door on the corpse of your servant and retreat into the formerly-inviolate safety of your haven.
				*page_break
				When you awake, you survey the damage to your home. It will take you several hours to put things right. What's more, you will have to dispose of the body of your valet. You are not looking forward to these tasks. 
				*if stlouis_enterprise = 2 
					*set exposure -1
					Thankfully, your connections with the shadier elements of the city means that you can call on people to do some of these things for you.
				
				*gosub new_valet
				*comment what about the dead body? what about the witnesses? Should you be forced to abandon your haven?
				*goto norris_resolution
			*elseif agility > 3
				Thankfully, your superhuman speed allows you to cover the distance between the coffin and the cool darkness of the kitchen in the space between breaths.
				*goto escaped_flames
			*else
				You stand and lunge for the open door of the house. The pain is overwhelming. Your flesh is melting from your bones. You wheel your arms in some desperate instinct to stiffle the blaze, but this is no natural flame.
				
				You are mere feet from the cool darkness of the kitchen when ${stlouis_valet} interposes ${valet_him}self; wielding nothing more menacing that a broom, ${valet_he} pushes you back. The bristles of the broom catch fire, and ${valet_he} shoves the flames in the direction of your face.
				
				Below you, your shin-bone shears above the ankle and you stumble. You raise your hand, reaching for the darkness. With a contemptuous shove, ${stlouis_valet} pushes you back one final time, forcing you onto your back.
				
				And there you expire, consumed by the sun's vengeful gaze.
				*set killed_by_mortal true
				*goto_scene scoring
	*elseif sleeping_place = "bed"
		Someone is in your sleeping room. Though your eyes are closed, you can feel their sudden presence.
		
		You reach out, in, anywhere, trying to find the strength to open your eyes and respond to this threat.
		
		You hear the creaking of wood. You have massive curtains over the windows, yes, but you are not so foolish as to trust in curtains alone to protect you. The curtains are there to fool anyone passing by into thinking that you are just a normal person. But on the inside of your windows are shutters well-anchored to the wall.
		
		But someone is trying to pull the shutters away; no, someone is trying to set you aflame.
		*page_break
		*if willpower >= 3
			You tear your eyes open. ${stlouis_valet} is directing four individuals with crowbars on how to dismantle your shades.
			
			You are livid. How dare ${valet_he} betray you like this?
			
			"${stlouis_valet}," you intone. $!{valet_he} turns to look at you. You can see the terror in ${valet_his} eyes; ${valet_he} did not expect you to wake.
			*if charm > 3
				"Come closer," you whisper.
				
				And ${valet_he} does.
				*label dispose_valet_bodies
				*set stlouis_valet_alive false
				*if stlouis_enterprise != 2
					*set exposure +2
				*page_break				
				*gosub introspection
				
				*if exposed
					Setting such thoughts aside, you regard the massive ray of sunlight now streaming into your bedroom. With no one to call on to fix the matter and the urge to fight draining from your limbs, you are forced to make a quick decision. You open your wardrobe, shoving out the shoes that fill its bottom, and close yourself inside.
					
					Being curled up inside your wardrobe for the day with five bodies cooling just outside is not the most dignified way to spend the day, @{(independence > 50) but thankfully none of the other vampires of the city will see this mess|and hopefully no one will come looking for any of these ruffians at your door}.
			
				The next evening you wake to the disaster of your home. It has been some time since you have disposed of bodies by yourself; you @{(compassion < 60 ) do not|} relish the task. You never find out who ${stlouis_valet}'s compatriots were, but you dispose of them just the same. @{(stlouis_enterprise = 2) Thankfully, your connections with the criminals of the city are able to aid you in this.|}
				
				You further have to spend hours repairing what has been broken, but in time you complete that as well.
				*gosub new_valet
				*goto norris_resolution
			*else
				*set exposed true
				
				"${mr} ${surname}," ${valet_he} stammers. But then ${valet_he} seems to find the steel in ${valet_his} spine. "Hurry!" ${valet_he} shouts.
				
				With a great crack, one of the boards comes loose, filling the room—and your bed—with sunlight.
				
				*if agility > 3
					But you are no longer there.
					*label survive_bed
					
					Calling once again on the powers of your undead flesh, you fly across the room, slamming ${stlouis_valet} into the wall. By the time ${valet_his} body hits the ground, he is already dead.
					*goto dispose_valet_bodies
				*else
					*label hand_on_fire
					The first thing to catch fire is your hand. The sensation not only reverberates throughout your body, but straight through to the core of your damned soul.
					
					When you finally do move, you are too terrified for rational thought. You manage to beat out the flames that are consuming your hand, but from there you can do little more than cower in the corner.
					
					When ${stlouis_valet} and ${valet_his} compatriots rip down another wooden slat, the sunlight engulfs you in its cleansing fire.
					
					The poor fools are left with your screams ringing in their ears, a sound which will haunt their nightmares until they individually drink themselves to death over the next decade. But you will not be there to savor it.
					*set killed_by_mortal true
					*goto_scene scoring
		*else
			You try to scream, but you are buried beneath hundreds of damp blankets, drowning in a placid lake of sleep, suffocating under the ash of a thousand fires.
			
			It's only when the first rays of the sun penetrate your room and land on your blankets that your eyelids fly open.
			*if (strength > 4) or (agility > 4)
				@{(strength >= agility) Your inhuman fortitude saves you, as your flesh is hesitant to set alight even under the sun's fiercest mid-morning rays.|But you are no longer there.}
				*goto survive_bed
			*else
				*goto hand_on_fire
	*elseif sleeping_place = "crawlspace"
		Someone is in your dressing room.
		
		For anyone else, it would be their bedroom. You have a bed there—for appearances sake—but you, of course, sleep under the floorboards.
		
		Through the mists of sleep, you hear the confusion. Voices bewildered. You would smile if you could.
		
		But then the sounds begin. The cracking of wood. The prying loose of boards. Reaching out, you sense that nothing has changed in your crawlspace…what could be happening? And who is in your bedroom?
		
		Suddenly, the nature of the intrigue becomes clear to you: the interlopers have taken down the slats that covered your windows. You had curtains, of course, but you wisely did not trust your safety to a few yards of cloth. The curtains were, in fact, enclosed by wooden boards, insulating the room from the sunlight.
		
		With those boards removed and the curtains open, your bedroom would swim in sunlight. And that means two things: whoever this is knows how to kill you…and they intend to do so.
		
		But…maybe…they don't know where you are?
		*page_break
		The crack of an axe against the floorboards shatters your fantasy. They know where you are…and they are coming for you.
		
		You start to push against the daysleep, trying to rouse yourself to action.
		*if willpower >= 3
			Finally, you push through the suffocating waves of morbid inertia and scream into wakefulness.
			
			You fly out the crawlspace and slam one of the intruders against a wall. Their throat is already torn open and gushing blood. You take a quick gulp and then spin to use the body to block the rays of sunlight from reaching you. Already, you can feel your hands smoking from its holy fury.
			
			*goto dispose_valet_bodies
		*else
			But you are buried beneath hundreds of damp blankets, drowning in a placid lake of sleep, suffocating under the ash of a thousand fires.
			
			The floorboards shatter. The sun is reaching for you, hungry. Unforgiving.
			
			*if (strength >= 4)
				It's when the sun finally strikes your foot that you coming screaming into full consciousness. Thanks to your inhuman fortitude, your skin only begins to smoke before you yank it deeper into the dark.
				
				But now you are awake. And you are angry.
				*if renter
					*set emptied_house true
					*set stlouis_valet_alive false
					*if stlouis_enterprise != 2
						*set exposure +2
					You pull yourself the bottom of the floorboards until you are under what you estimate to be the pantry. Struggling for leverage, you finally break through the wood and burst upwards.
					
					You will have much to explain to your landlady, but now that you are free to move, your outlook is much improved.
					
					The pantry is under the kitchen. You can hear ${stlouis_valet} and ${valet_his} companions debating burning you out; but they have made the mistake of standing above you. Leaping into the air, you punch through the floorboards and pull both ${stlouis_valet} and one of the others down into the pantry with you. Within moments, their intestines are almost indistinguishable from the sausage links that are stored down here. Meanwhile, above, the others flee.
					
					This is going to be difficult to explain. You will likely need to kill everyone else in the house. But for the moment, you must sleep.
					
					As you try to make yourself comfortable, you reflect on what just transpired.
					*gosub introspection
					*gosub new_valet
					*goto norris_resolution
				*elseif (haven_value >= 50000) or haven_decrepit
					They may have ruined your bedroom, but this is your home.
					
					You pull yourself along under the house, until you come to a trapdoor in another bedroom.
					
					Once you are awake and on your feet, ${stlouis_valet} and ${valet_his} compatriots are no longer a threat. They are not warriors or soldiers. At best, they are a handful of barroom toughs or religious fanatics.
					
					They die, one by one, as you slip through the shadows of your home.
					
					When the threat has passed, you take refuge in the wardrobe in ${stlouis_valet}'s bedroom, ${valet_his} body cooling just outside. $!{valet_he} cursed your name as ${valet_he} expired.
					*goto dispose_valet_bodies
				*else
					*set emptied_house true
					*set stlouis_valet_alive false
					*if stlouis_enterprise != 2
						*set exposure +2
					You scrounge for an escape. Your haven has only two rooms, the kitchen and the bedroom. The only adjacent structure is the stables, where you keep the horse that powers your carriage, and the stable is not sunproof. But you see no other option.
					
					Scrambling into the stable, you pull a horseblanket down and try to cover yourself with it as best you can. Your hands and face begin smoking from the reflected light of the sun, and your vision swims from the pain. Soon, ${stlouis_valet} appears at the door to the stables, clearly surprised both by your smoking flesh and the fact that you are, in fact, still animate.
					
					Very much animate.
					
					Though your forearm catches on fire, you extend it out and grab ${stlouis_valet} by the throat and pull ${valet_him} into the shade of the stables. You douse the flames in the fluids of ${valet_his} stomach, drinking the blood that spurts forth with abandon. Whatever courage your valet's companions had summoned disappears at this sight and they break.
					
					Left alone, you drink as much as you can before diving into a pile of hay and praying for the pain to cease.
					
					*gosub introspection
					
					The next evening, you rise to find your arm blackened from the flames. It should heal in time, but the pain is immense. You will also have to repair your home as well as dispose of the body—something you have not had to do in a long time.
					*gosub new_valet
					*goto norris_resolution
			*else
				You scrounge for an escape. Your haven has only two rooms, the kitchen and the bedroom. The only adjacent structure is the stables, where you keep the horse that powers your carriage, and the stable is not sunproof.
				
				While you are considering your options—scrambling madly along the underside of the floorboards—you are suddenly interrupted by a great tearing sound as another comes free. Your eyes haven't even focused when a massive hay-fork pierces your chest, and you find yourself pinned to the earth as the sun brings you into its warm embrace.
				
				Within a few moments, you have caught fire. ${stlouis_valet} holds the haft of the hay-fork as long as ${valet_he} can, but eventually the flames grow too hot. Your final screams will haunt ${valet_his} dreams for the rest of ${valet_his} life.
				*set killed_by_mortal true
				*goto_scene scoring
	*else
		*bug no sleeping place declared

	*label introspection
	*set compassion %+5
	*set discretion %+5
	@{(discretion > 60) How dare ${stlouis_valet} betray you like this? How ungrateful can ${valet_he} be?|Should you have paid ${valet_him} more? Did someone buy ${valet_his} loyalty?} @{(compassion > 50) You should have kept ${valet_him} alive to interrogate, you muse.|Perhaps you were too merciful granting ${valet_him} a swift death.}
	*return
	
	*label new_valet
	It will be difficult to maintain your household without a valet, but it will take you time to find one. Time that you don't have while the fair is ongoing. You resolve to tend to your own needs for the time being. If the right candidate appears, you will seize the moment, but until then, the fair is here!
	
	And somehow you have managed to survive to see another night yet again.
	*return

*label norris_resolution
*if cuba_return > 0
	*page_break
	*set wealth +(cuba_return * 0.5)
	*set cuba_return * 0.5
	You are delighted to receive a letter from your banker indicating that half of the remaining capital due to you from the Cuban affair has been deposited in your account.
*if (stlouis_valet_alive = false) and (income > 50)
	*page_break
	The sudden demise of ${stlouis_valet} does leave you in something of a predicament; $!{valet_he} did know a lot about your business. In some instances, ${valet_he} was the signatory or owner-of-record on property or other investments.
	
	You do your best to recover your assets—going so far as to fake a will—but some things slip through the cracks.
	*if finance > 2
		*set income *0.95
	*if finance = 2
		*set income *0.9
	*if finance = 1
		*set income *0.8
	*if finance = 0
		*set income *0.7
*set month 5
*page_break
*temp norris_betrayal 1
*rand norris_betrayal 1 2
*temp test false
*temp assistants "ERROR"
*temp assistants_present false
*temp assistants_num 1
*temp zulus "ERROR"
*temp has_silver_bullets false
The first nights of the fair are greeted with jubilation. The Exposition is a phenomenon, drawing attendees from across the country and beyond. Over it all—for the members of the Society, anyway—the pall of @{west_prob ${imposter}|West} hangs. How long until the next vampire is brought down by his fangs?

Notably, the Exposition has representatives from cultures across the globe. Each of the States and Canadian Provinces, for example, have sent some representative elements to the fair to serve as ambassadors, establishing pavilions to promote and display their accomplishments. Similarly, the civilized nations of the world have been invited to demonstrate their achievements and their history; the United Kingdom, for example, has sent the British Crown Jewels. All told, there are almost a hundred of these pavilions in the Exposition.

Conversely, there are many cultures on display here that were not invited to erect a pavilion. Dozens of scouts have scoured the globe over the past three years, recruiting individuals of hard-to-reach societies to come join the human zoological garden at the Fair. The largest contingent are twelve hundred people from the different regions of the recently-conquered Philippines; Igorots, Moros, Mangyans, Palaweños…as a demonstration of American imperial might, they have been brought to St. Louis to reveal their savage and backward natures to the tourists.

Besides the Filipinos, there is a whole Cheyenne village; the Apache warrior Geronimo, on temporary release from his prison at Fort Sill, Oklahoma; Ainus, Australian Aboriginals, Esquimaux, Patagonians, Pygmies, Siberians…dozens upon dozens of ethnic groups hired to perform their culture on a daily basis for subsistence wages and with no guarantee of a return trip home. @{(shepherd_credentials > 55) Interestingly, there is a contingent of Tyrolians—a County of the Austro-Hungarian Empire—who are consigned to the zoo.|}

The number of white women who daily faint at these sights is reported breathlessly in the ${post_dispatch}.

The Anglo-Boer War Concession, as it is termed, contains veterans of the Boer War as well as Zulus, Sans, Swazis, and Ndebeles, who were brought along both to establish native villages and to tend the animals of the veterans. Those veterans—some six hundred in number—reenact several battles of the Boer War twice daily, complete with horses that have been trained to limp and collapse at the sound of gunfire. It goes almost unremarked by the tourists that the white veterans camp on the concession alongside their African indentured servants.

In addition to the Boer War reenactment, Buffalo Bill's Wild West Show evokes a variety of scenes from the Indian Wars, best exemplified by Custer's Last Stand. The Pawnee and Sioux riders—besides the renactments—have several demonstrations of their horsemanship and sharpshooting. All told, there is a lot of gunfire from various corners of the Exposition throughout the day.

*choice
	#I am excited to learn as much about the world as I can.
		*set anachronism %+5
		*set compassion %+5
	#I am angered by the treatment of these people; it only shows the savagery and limited imagination of Americans.
		*set compassion %-5
	#I look forward to feeding from the cornucopia of flavors.
		*set shepherd_credentials %-5
		*set discretion %+5
		*set compassion %+5

Winding amid the pavilions and concessions is the Pike: a thoroughfare full of restaurants, music halls, games, and all manner of divertissements. @{schnaiders_closed |Aichinger has even managed to erect a satellite of Schnaider's, complete with a small stage and nightly operettas.} @{(sporting_goods = 1) |${spalding_sporting_goods} has erected a storefront in a prominent location.} @{stl_chinese_soul_food Ma Wang's can only afford an out-of-the-way spot, but soon becomes one of the most popular food vendors of the fair. There is regularly an hour-long queue for a seat. The bowl of noodles with smoked okra, andouille sausage, and collard greens is a particular hit.|} @{met_sosostris Mme. Sosostris, unsurprisingly, has a booth at the fair. It seems she has left—at least temporarily—the employ of P.T. Barnum.|} @{((spencer_sister_status > 1) and (spencer_sister_status != 6)) The Spencer sisters have a tent where they conduct their revivals, focusing on the power of spirits to guide our present circumstances.|}
*temp silver_dagger false
*temp knows_about_bullets false
*temp refined_silver_bullets false
*temp tick false

*if stlouis_tribune or (west_exposure >= 4)
	You muse on how to prepare for a showdown with West. 
	*if weapon_num = 1
		*set tick true
		First among your priorities is the acquisition of a weapon. What sort of instrument would you like to acquire?
		*gosub weapon_choice
		
		*comment endif
	@{tick A weapon acquired, you further consider how you might turn the mortals of the Exposition to your service. There|Thanks to the Exposition, there} are a number of groups of individuals who are trained fighters that you might draw upon.
	
	*choice
		*if ((ethnicity = "southern") or (ethnicity = "scotch")) #Cowboys are a superstitious lot; perhaps they will believe what I have to tell them.
			*set assistants "cowboys"
			*set zulus "cowboys"
			*set assistants_num 8
			*goto assistant_merge
		*if (ethnicity = "african") #If battle is going to be waged, perhaps some of the Zulu warriors would be willing to aid me.
			*set assistants "Zulu warriors"
			*set zulus "Zulus"
			*set assistants_num 2
			*label assistant_merge
			*set shepherd_credentials %-10
			You spend as much of June as you can acquainting yourself with the ${zulus} and preparing them for combat. Individually, they are no match for @{west_prob ${imposter}|West}, but brandishing torches and working in concert, they may be able to hold him at bay long enough for a vampire to bring him down.
			
			The obvious advantage to using these particular pawns being that few white Americans will believe any stories of ancient vampires and circles of flame.
		*if (ethnicity = "choctaw") #If battle is going to be waged, perhaps some of the Cheyenne warriors would be willing to aid me.
			*set assistants "Cheyenne warriors"
			*set zulus "Cheyenne"
			*set assistants_num 3
			*goto assistant_merge
		#There are hundreds of Igorots; if battle is to be waged, perhaps I can find some warriors among their number?
			*set assistants "Igorot warriors"
			*set zulus "Igorots"
			*set assistants_num 4
			*goto assistant_merge
		#I recruit mortals to watch and try to plot @{west_prob ${imposter}|West}'s trajectory. Knowing his patterns can help with cornering him.
			*set find_west +1
			*if stlouis_enterprise = 7
				*set find_west +1
				You also recruit some a mathmatician—he calls himself a statistician, whatever that is—to plot some of the places where West has appeared and where he might appear next.
			Together, you try to ascertain a pattern or routine, but if there is such a thing, it remains frustratingly out-of-reach.
		*if (beast_of_gevaudan) #There must be some weakness we've overlooked. I will try to learn more about the Beast of Gévaudan.
			*set knows_about_silver true
			During your research, you read about the Beast of Gévaudan. The Beast was some sort of wolf-man creature that was reportedly slain by the silver bullet of a hunter in 1767.
			
			Could vampires who have lost all connection to their humanity be the source of the stories of werewolves? You have never had difficulty with silver, but perhaps there is some mystical connection between the loss of humanity and silver?
			
			@{(technology > 1) It would be easy enough for you to fashion silver bullets for a gun, if you were so inclined. Of course, you'd have to have a specific gun in mind, as different guns use different calibers of ammunition.|You could hire someone to fashion some silver bullets for you, but you'd have to have a particular gun in mind.}
		*if (weapon_num = 2) #My claws are not sufficient; I must arm myself if I am to do battle.
			What sort of weapon would you like to acquire?
			*gosub weapon_choice

*if (jesse_rapport > 35) and met_jesse
	*page_break A@{(jesse_rapport > 55)  |n (Un)}Welcome Arrival
	*comment early May?
	
	To your surprise, you receive a note from Senator Bailey to join him at the Southern. You arrive on the appointed evening to find Jesse Whitaker sitting at Bailey's table.
	
	*if trans
		"${original_name}?"
		*if original_name != given_name
		
			"It's ${given_name}. ${given_name} ${surname}, now."
		*else
		
			"The one and only."
		
		"You are…different."
		
		"No, not different. Just more me."
		
		Though you sense Bailey rolling his eyes at you, Jesse seems to take this statement in stride. He gestures for you to take the seat beside him.
	*elseif jesse_rapport > 60
		*if jesse_is_broodmate
			"Dear @{male brother|sister}!" 
		*else
			"${given_name}!"
		he exclaims, rising from his seat to embrace you. You suppose that the hug is as warm as a hug between vampires can be.
		
		"Jesse!"
	
		"Please, sit with us!" he exclaims, gesturing to the seat beside him.
	*elseif jesse_rapport > 45
		*if jesse_is_broodmate
			"My @{male brother|sister},"
		*else
			"${given_name}! I had heard that you were residing here,"
		he says with a smirk. "Please, won't you join us?" he says, gesturing to the seat beside him.
	*else
		"Really?" he remarks, glancing at Bailey.
	
		"Were you expecting someone else, @{jesse_is_broodmate brother|Jesse}?" you reply.
		
		"I thought you might know each other," Bailey replies. "Please, ${mr} ${surname}, join us," he says, gesturing to a seat.
	
	Taking the proffered seat, you inquire as to Jesse's visit. "To see the fair, of course!" he exclaims.
	
	*if jesses_revolutionary_credentials < 40
		"Yes, but last time I saw you, you were…consorting with a different sort."
		
		"Oh, you must mean Senator Lockridge! Well, I found his company pales in comparison to that of Senator Bailey here."
		
		"And it is certainly a pleasure to be graced by Mr. Whitaker's presence," Bailey replies.
		
		"I am but a humble guest in your city. Come to sup at the horn of plenty that is the Exposition."
		
		"Come now, there is no use in keeping ${mr} ${surname} in suspense."
	*else
		"Now, don't be modest, Mr. Whitaker," Bailey replies.
	
	"Very well. I suppose it will not be a secret for long."
	
	"Secret?" you interject.
	
	"Yes. There is a horserace—the World's Fair Handicap—and I intend to win it."
	
	*if independence < 40
		*set jesse_rapport %+5
		Your eyes widen. "You would allow a jockey to mount you and whip you into a lather?" you exclaim with a mock gasp.
		
		Jesse rolls his eyes at you. "No one whips me into a lather, ${given_name}. I do the whipping." He shakes his head.
	*else
		"I never knew you to be interested in horseflesh, Jesse."
		
		"Come now, you know I am happy to gamble on most any sport." You nod in agreement.
	"Well, I find myself with a horse, and a race that I want to win."
	
	"I understand that the purse is fifty-thousand dollars," Bailey says.
	
	"So it is!" Jesse agrees.
	
	"When is it?" you inquire.
	
	"In about six weeks. The afternoon of June 26th. It is unfortunate that it is being held during the day; I had hoped that these electric-light tracks would sway the organizers to hold the event after dark, but I was insufficiently persuasive."
	*set knows_jesse_race true
	
	"I'm sorry to hear that."
	
	"Well, you may place you money on Moharib; I'm certain that he will win."
	
	"I will take that under advisement," you say with a nod.
	
	From there, the conversation turns to the vagaries of the Society, with @{(status > 2) you, Bailey, and Whitaker|Bailey and Whitaker} swapping court gossip for the rest of the evening.
	*if (jesse_embarrassed = false) or lied_to_jesse_about_poem
		*page_break
		*set requested_by_jesse true
		
		You and Jesse rise to depart at approximately the same time. Once in the cloakroom, he finally shares what's on his mind.
		
		"As much as I have confidence in my horse's jockey, there is always the opportunity to further guarantee success."
		
		"Out with it, Jesse."
		
		"I'm simply saying, while I have sworn to not interfere in the outcome of the Handicap, that does not mean that you cannot…tilt the scales, shall we say?"
		
		"You want me to rig the race."
		
		"Well, when you put it like that…yes, yes I do."
		
		"I suppose I should have expected nothing less."
		
		"Will you, dear ${given_name}?"
		
		*choice
			#"Consider it done."
				*set promised_jesse 3
				"Excellent! We shall celebrate after the race."
			#"I will muse on it. But I make no promises."
				"Of course! I wouldn't want to force anything upon you," he says with a fake smile.
			#"I will not interfere in this, Jesse. Whatever your scheme, I want no part of it."
				*set promised_jesse 1
				*set jesse_rapport %-10
				*set independence %-5
				Jesse clucks his tongue at you. "Always such a drag. I don't know why I even bother."
		
		He puts his gloves on and the two of you go your separate ways.

*page_break
*comment 1904-06-03
*if ((norris_arena = 1) or (norris_arena >= 5)) and (shepherd_credentials > 40)
	@{(stlouis_enterprise = 6) The ${wctu}|A local women's association} is up in arms over @{(norris_arena = 5) the|an} upcoming bullfight scheduled for this Sunday, June 5th. @{(norris_arena = 5) It seems that Norris has found a backer, for he has|A local entrepreneur, Richard Norris, has} built an arena across from the fairgrounds.
	
	Interestingly, bullfighting is against the law: an animal cruelty law was passed a few years ago, and the death of animals for sport is forbidden in the state. This hasn't stopped the workers from erecting a wooden edifice for the event, however.
	*temp stopping_bullfight false
	*choice
		#This is an unsupportable cruelty. This bullfight must be stopped!
			*set compassion %-10
			*set stopping_bullfight true
			*label stop_bullfight
			*set lpe_success %-5
			*set norris_arena 8
			*if stlouis_enterprise = 1
				The newspapers immediately begin to run exposes on the upcoming event, making all sorts of allegations about the unsavory connections of Mr. Norris.
				
			*if stopping_bullfight
				*if stlouis_cult_power > 45
					${stlouis_cult_name} stand ready to protest at a moment's notice.
				*if stlouis_enterprise = 6
					The ${wctu} is @{(stlouis_cult_power > 45) also|} ready to protest.
					
			When the day comes, a large crowd gathers outside the arena. Some eight thousand tickets have been sold. The crowd is angry that the arena hasn't opened yet, and when it's announced that no bullfight will be happening due to the animal cruelty law, the crowd goes wild.
			
			The crowd storms the arena. @{(norris_arena >= 4) They soon discover that the only bull is an emaciated old thing, not fit for a fight; this only enrages them further.|} Soon, a torch is lit, and from there it's only a few more minutes until the torch meets the fresh wood of the stands. 
			
			By nightfall, most of the arena is only ash.
		*if (ethnicity = "spanish") #It's unfortunate that I cannot attend; I've never had a chance to see a real bullfight, as much as my father spoke of them.
			*set anachronism %-5
			*set compassion %-10
			Your father only ever attended one bullfight in his life, but he regaled you with tales of it when you were young: while on a trade expedition, he traveled all the way to Veracruz, where he had the oppotunity to spend a hot afternoon watching the theatrics.

			You push away the thought of his shining eyes. Thoughts of your mortal life will bring you no peace.

			You're told that the day is beautiful: the sun shines and there is not a cloud in the sky.
			*goto bullfight
		#I hope they enjoy themselves.
			*set discretion %-5
			*goto stop_bullfight
		*if (sporting_goods > 1) #Attending a bullfight means that they're not attending a baseball game; I cannot allow such distractions.
			*set discretion %+10
			*goto stop_bullfight
		*if (stlouis_enterprise = 6) #I tell the ${wctu} to relent and let the fight go forward.
			The day of the bullfight is a glorious June day. The sky is clear and the weather perfect for being outdoors.
			*label bullfight
			*set norris_arena 5
			*set lpe_success %+5
			
			To celebrate this glorious weather, the bullfight is a magnificent spectacle of blood and finesse. The crowd cheers on the matador who delivers the killing blow; he will be toasted for days in honor of his bravery in the face of insensate danger.
		*if (stlouis_enterprise = 2) #I organize some strike-breakers to stop the protestors.
			*set stlouis_business_climate %+5
			Your hired toughs deter the women from their protests. It takes several thrown punches before the women back down, but they eventually relent and leave the vicinity of the arena.

			A good thing too, as it is glorious day to be outdoors: not a cloud in the sky and a cool breeze from the east.
			*goto bullfight
		#Attending a bullfight on the Sabbath? How sacrilegious!
			*set rationalism %+10
			*set test true
			*goto stop_bullfight
		*if (shapeshifting > 1) #They wish to see unspeakable cruelty? Then let them see the true fury of a bull!
			*achieve bulls_vengeance
			*set discretion %+5
			*set lpe_success %+5
			*set norris_arena 9
			*temp bullfate 1
			*rand bullfate 1 2
			You make your way to the bull's pen a few nights before the fight. With a red cloth in your hand, you teach the bull where to look and where not to.
			
			The day of the fight, the weather is clear and glorious. The first [i]tercios[/i] of the day are simple affairs, leaving the bull wounded and angry and the [i]banderilleros[/i] untouched.
			
			When the final match begins, however, the bull pushes past the pain and rage, and remembers what you taught it; the [i]muleta[/i] offers the matador no defense. The bull's horns tear the intestines from the matador's stomach. It stomps on the man's chest and skull. Finally, it expels its bowels on the still-warm corpse.
			
			The sudden silence is so deafening that it can be heard for blocks around. The whole thing happens so quickly and brutally that the [i]banderilleros[/i] have no time—or even impetus—to intervene.
			
			The bull, bleeding from its earlier wounds, trots to the center of the arena and lays in the dirt, awaiting its fate.
			*page_break
			You read of how there was a great debate—or, rather, shouting back-and-forth—about whether or not the bull should be killed. Finally, @{bullfate Norris himself emerged, and announced that the bull will be returned with honors to the ranch that raised him. Surprisingly docile, the triumphant bull was lead out of the arena|one of the [i]banderilleros[/i] seized a rifle and shot the bull through the eye, to a gasp from the crowd. The bull's corpse was dragged away} and the dead matador's remains were collected for burial.
*elseif (norris_arena >= 3) and ((norris_arena != 5) and (norris_arena != 6))
	*if test
		*bug
	Norris is good as his word. He takes your money, leases the land, and builds the @{(norris_arena = 4) fake|} arena.
	
	Somewhere along the line, however, a local women's group catches wind of the project. It seems that bullfighting runs counter to a recent animal cruelty law. They have vowed to stop the event. @{(norris_arena = 4) Not that you or Norris really care; as long as tickets are selling, nothing else matters.|}

	With your support, Norris sells some ten thousand tickets.
	*temp finance_adjust (finance * 0.5)
	*if norris_arena = 3
		*set wealth +(25000 +(25000 * finance_adjust))
		*set lpe_success %+10
		*comment there will be other events over the course of the summer to further boost the value of this investment.
		From the look of things, the rest of the fair will be simiarly profitable. Assuming nothing interrupts the proceedings, anyway.
	*elseif (norris_betrayal = 2) and ((perception > 2) and (finance > 0))
		*page_break
		Two days before the bullfight, you summon Norris to your home.

		His nervousness bleeds through his calm demeanor, screaming his impending betrayal to your sensitive ears.

		"You should not have sought to betray me, Richard."

		"I…I wouldn't betray…"

		"There's no point in lying, Richard. I know that you were going to skip town with all of the money."

		"But…"

		Conveniently, you've already had documents drawn up transfering the Norris Arena corporation to a fictious individual, as well as dissolution documents for the corporation. All you have to do is get Norris to sign the papers, and then he is no longer necessary.

		*choice
			#Have him sign the papers and then drink him dry.
				*set compassion %+10
				*set exposure +1
				*set lpe_success %-10
				*set wealth +(50000 +(50000 * finance_adjust))
				You have to be careful about not spilling his blood on the contracts; that might be difficult to explain.

				Transfering the money between corporations and then redepositing it in multiple banks will be difficult, and costly, but at least you've made a profit on the transaction.
				
				The ticket-holders, of course, are livid at the deception. The arena itself is burnt to ash when the fraud is uncovered. But with Norris's body found on the riverfront, their anger has limited outlets.
			#Have him sign the papers, and then order him from the city.
				*set compassion %-10
				*set exposure +1
				*set lpe_success %-10
				*set wealth +(50000 +(50000 * finance_adjust))
				He trembles at your injunction to flee the city, but he seems to take you at his word.

				He signs the papers and ${stlouis_valet} escorts him to the door.
				
				The ticket-holders, of course, are livid at the deception. The arena itself is burnt to ash when the fraud is uncovered. Warrants are issued for his arrest in every direction.
			#I send him to the arena to face the angry mob.
				*set compassion %+5
				*set discretion %+5
				*set stlouis_business_climate %-5
				*set stlouis_valet_loyalty %-5
				*set wealth +(50000 +(50000 * finance_adjust))
				After signing the papers, you confine Norris for the intervening period. On the morning of the 5th, ${stlouis_valet} and a hired tough escort Norris to the arena and lock him in the ticket booth.

				When the attendees catch wind of the fact that there will be no bullfight—that there aren't even seats in the arena, just a frame to block the view from the street—their mood grows dark. Norris pleads with various angry ticket-holders to unlock the booth, but to no avail. By 11 am, the crowd has dragged Norris from the ticket booth and strung up a makeshift gallows from the leftover lumber.

				Police arrive to disperse the crowd, but it's too late for Norris. In the chaos, someone even sets fire to the arena; the wooden frame goes up in flames with little hesitation.

				${stlouis_valet} reports these events to you with no small amount of disgust for ${valet_his} own involvement in the affair.
			*selectable_if (charm > 4) #I cause him to forget my involvement in the affair.
				*set compassion %-5
				*set discretion %-5
				*set wealth +(25000 +(25000 * finance_adjust))
				*set lpe_success %-10
				Norris signs over a smaller portion of the proceeds—enough to @{(finance = 1) almost|} compensate you for your initial investment—before resuming his plans to flee the city.

				With a careful tip to the police, he'll be caught, tried, and convicted.

				The arena itself is burnt to the ground when the crowd of ticket-holders get impatient and break in, only to discover that the building was a sham.

				Norris is arrested in Chicago a week later. His trial for fraud will be swift and sure.
	*elseif norris_betrayal = 1
		*set wealth +(50000 +(25000 * finance_adjust))
		*set norris_arena 7
		*set lpe_success %-15
		Norris delivers the cash to you before heading to the train station.

		You shake hands when you part. He has chosen a hard road. He claims that he will go to California and set himself up among the prospectors.

		When the 5th arrives, the arena is burnt to the ground by the impatient crowd of ticket-holders who decide to storm the facility, only to discover that the building was a sham.
	*else
		*set norris_arena 8
		*set lpe_success %-15
		Two days before the bullfight is supposed to occur—or not occur, as the case may be—Norris goes missing. Or, rather, he flees St. Louis. With the entirty of the money.

		You suppose you should have known better than to trust a thief—but you have a long memory.
*elseif stlouis_valet_alive
	${stlouis_valet} @{literate delivers|reads the highlights from} the ${post_dispatch} to you when you rise. The most amusing story of the day is a bullfight gone wrong: apparently, a local entrepreneur tried to organize a bullfight on the fair's off-day, but the whole matter was a scam. There weren't even bullfighters to kill the three emaciated bulls that were found by the patrons when they finally broke into the arena. The recently-erected building was burnt to the ground in the chaos.

*if stlouis_valet_alive = false
	*page_break
	You cannot endure for long without a valet to tend to your daytime needs. You hire a young woman, Martha, to keep house for you. She will suffice until the Exposition is over.

*if ((shepherd_credentials > 80) or (justice > 70)) or ((ethnicity = "african") and (compassion < 45))
	*gosub negro_day_prep

*if met_draper
	*page_break 
	One evening in mid-June, you are startled to find yourself face-to-face with James Draper.

	"Mr. Draper?" you venture.

	*if trans
		"Yes? Have we met?" 
	*else 
		"${mr}…I'm sorry, but I've forgotten your name. You're ${jesse_sire_name}'s youngest?"

	*if jesse_is_broodmate
		"${given_name} ${surname}, yes," you say with a gentle nod. 
	*else 
		You resist the urge to roll your eyes. "I understand why you would think that, but no, ${jesse_sire_name} is not my dominus. I am the scion of ${sire_name}."

		"Ah, my mistake."

		You wave away the apology.
	"What brings you to St. Louis? Here to see the Exposition?"

	"I'm here to win a race!"
	
	"A race?"
	
	"A horserace, in fact."
	
	*if knows_jesse_race
		"That wouldn't be the World's Fair Handicap, perchance?"
	
		"The very same! I hope you haven't put a wager against me," he says with a smile.
		
		"Which horse is yours?"
		
		"Hermis, the champion of the world!"
	*else
		"Oh? Which race?"
		
		"The World's Fair Handicap. It's been held at the end of June at the Fairgrounds."
		
		"There are so many events, it's hard to keep track of them all."
		
		"It most certainly is! I'm only here for a few weeks, and my calendar is overflowing with obligations," Draper agrees.
	
	"Is there a large purse?"
	
	"Fifty thousand dollars. The largest purse for a handicap race in the history of the nation."
	
	"A handsome prize."
	
	"And it is one that I fully expect to win."
	
	"How can you be so certain?"
	
	"There is no other possible outcome. The closest competition is a third-rate dasher by the name of Moharib."
	*set knows_draper_race true
	*if draper_rapport > 50
		He looks around. "Would you like to meet Hermis? I'm headed to the barn now."
		
		After a moment's consideration, you accept.
		*page_break
		Some twenty minutes later, you find yoruself at the Fairgrounds, walking through the barn. Dozens of horses are quartered here in preparation for their races. @{(shapeshifting = 0) They snort and stamp as you pass their stalls, doing their best to flee your presence.|They watch the two of you carefully, their spirits squelched by your power. You suspect that Draper knows something of how to command animals, otherwise they would be reacting to him with pronounced fear.}
		
		Draper eventually stops outside a stall in the middle of the row. "The king," he says. He opens the stall and whistles, and out walks a magnificent stallion, nearly seventeen hands high. Draper strokes Hermis's face and pats his neck. Hermis endures the attention without complaint@{(shapeshifting = 0) —though he clearly would prefer to be very far away from you|}.
		
		@{jesse_is_broodmate "Your brother|"The scion of ${jesse_sire_name}} challenged me to a wager: whoever wins the race wins the loser's horse."
		
		"That is quite a wager. Are you certain that was wise?"
		
		"Whitaker has promised that he will not interfere in the outcome of the race. And I have seen Moharib run; there is no question that Hermis is the better horse."
		
		"That does not mean that he will win."
		
		"No, it does not. But when Jesse offered the wager, against such a clearly inferior horse, I could not refuse."
		
		*if requested_by_jesse
			*choice
				#I reveal that Jesse asked me to tilt the outcome of the race.
					*set discretion %+5
					*set draper_rapport %+15
					*set tiozzo_rapport %+5
					*set betrayed_jesse true
					Draper pauses. "I see. I assume, then, that you have not yet put any plans into motion?"
					
					"I have not."
					
					"Good. I suppose it makes sense that he would approach you to effect such a scheme—an old friend who has lived here for a time. You likely have connections that would allow you to penetrate any defenses an outsider would erect during a brief sojourn. If I were he, I suppose I would approach you as well."
					
					"What will you do?"
					
					"Nothing. If you do not intend to interfere, Hermis will win, and the victory will be all the sweeter for it." He grimaces. "Well, now you know how to place your wager."
					
					"That I do," you affirm.
					
					"Good night, then," Draper says.
					
					With that, you exit the barn and continue on your way.
				#I say nothing about Jesse's request@(promised_jesse = 3) —and my promise to help him win|}.
					*set discretion %-5
					"How could you?" you reply rhetorically.
					
					"Well, now you know who to place your wager on."
					
					"I have seen the winner in the flesh," you affirm.
					
					"Good night, then," Draper says.
					
					With that, you continue on your way.
		*else
			"I can see why."
			
			"Well, now that you have seen this magnificent creature, you know how to wager."
			
			"Most assuredly."
			
			"Good night, then," Draper says.
	*else
		"I see. Well, I wish you and Hermis the best, Mr. Draper."
		
		"Thank you. Perhaps we will meet again."
		
		"I imagine we will." With that you press on with you obligations for the evening.

*temp vda_race false
*if (sporting_goods > 1) or (browns_saved > 1)
	*page_break A Pounding At The Door
	*set vda_race true
	"Open zis door!" Someone shouts. The pounding continues.
	
	@{stlouis_valet_alive ${stlouis_valet}|Martha} opens the door; upon doing so, Chris Von der Ahe spills into the hall, spins his arms in an attempt to maintain his balance, falls flat on his rotund stomach, and vomits the contents of his stomach onto the floor —a vile morass of sauerkraut and whiskey.
	
	"You must help me, ${given_name}, please!" He lays there, sniveling. @{((compassion > 65) and (discretion > 65)) This display of weakness is revolting. You barely suppress the urge to crush his skull under you heel.|}
	
	"Clean him up, please," you say to @{stlouis_valet_alive ${stlouis_valet}|Martha}, before turning on your heel and retreating into your private quarters.
	
	An hour or so later, Von der Ahe is clean, fed, and drinking coffee in an attempt to sober himself up. The hall has been mopped, but stench of bile lingers.
	
	"Why are you here?"
	
	"You know vat a state I am in, @{speaks_german yes|[i]ja[/i]}?"
	
	Gesturing to the pile of clothes he was recently wearing, you say, "yes, I can see."
	
	"@{speaks_german Please|[i]Bitte[/i]}, you do not understand."
	
	*if browns_saved = 1
		"What? You've lost your baseball team through you own incompetence.
		
		*if (sporting_goods = 2) or (sporting_goods  = 3)
			Are ${spalding_sporting_goods} and the Golden Lion not maintaining you in the lifestyle to which you are accustomed?"
		*else
			The only thing keeping you afloat is the Golden Lion. Don't tell me you've ruined that, too?"
	*elseif browns_saved = 2
		"What? You sold off your baseball team to settle your debts.
		
		*if (sporting_goods = 2) or (sporting_goods  = 3)
			Are ${spalding_sporting_goods} and the Golden Lion not maintaining you in the lifestyle to which you are accustomed?"
		*else
			The only thing keeping you afloat is the Golden Lion. Don't tell me you've ruined that, too?"
	*elseif browns_saved = 3
		"What? Your matter in Pittsburg was resolved. You still have your baseball team, despite your best efforts to the contrary. Or have you nearly lost them again?"
	
	"Vy are you so cruel?"
	
	"I'm simply pointing out your own failings, Chris."

	"Perhaps I should just leave, then."
	
	"You've come all this way. No reason to turn back now."
	
	He takes a deep breath. "My friend Otto…"
	
	"Otto Stifel?"
	
	"@{speaks_german Yes|[i]ja[/i]}, the same."
	
	"What of him?"
	
	"He has a horse."
	
	*if knows_jesse_race or knows_draper_race
		"Let me guess, he's racing in the World's Fair Handicap?"
		
		"You know, but you do not know!" he says, eyes wide.
		
		"What are you talking about?"
		
		"@{speaks_german Otto owns a mare.|She ist a he. No…he is [i]ein[/i] she.} But yes, she races in ze Handicap. Her name ist Colonial Girl."
		
		"The purse is quite large."
		
		"So it ist!"
		
		"And you want me to assure you of her victory?"
		
		"@{speaks_german Please|[i]Bitte[/i]}!"
	*else
		"A horse?"
		
		"@{speaks_german Yes|[i]Ja[/i]}, a good horse. She vins many races."
		
		"You've bet your money on a horse, and now you want me to save you?"
		
		"I knew you vould understand!"
		
		"Chris, I…"
		
		"Her name ist Colonial Girl, and she is racing in the World's Fair Handicap. It is only a few days away! You see that she vins!"
		
		"I thought you said that she wins many races?"
		
		"She cannot lose! @{speaks_german Please|[i]Bitte[/i]}, ${given_name}."
		
	"Leave, now."
		
	"But, ${given_name}," he whinges.
	
	"Maybe I will, maybe I will not. But you reek of whiskey and I want you out of my home," you say, pushing him towards the door. @{(strength < 3) He is surprisingly pliable in your hands.|}
	
	"But, but…"
	
	"Good night, Chris," you say, pushing him out the door and closing it behind him.
	
	It seems that quite a lot is riding on this horserace.

*if vda_race or (knows_jesse_race or (knows_draper_race or stl_met_tilles))
	*gosub handicap
*comment 1904-06-26 World's Fair Handicap, $50k purse, won by Colonial Girl, a mare, owned by Otto Stifel of St. Louis. It was the fourth of seven races that day.
*comment https://cdnc.ucr.edu/?a=d&d=SFC19040626.2.104.10&e=-------en--20--1--txt-txIN--------1

*page_break
	
The rest of June passes without incident…until you spy some others of your kind at the Exposition one evening.
*set month +1
*page_break
*gosub calibrate_interlocutors
*temp just_spoke_yates false
*label fair_central_hub
*advertisement
*if month = 7
	*gosub democratic_national_convention
	*if npc_honeytrap
		*gosub npc_honeypot
	*comment Full Moon 7/27
	*if withers_trinket > 1
		*gosub return_trinket
	*if ((feeding_style = "socialites") or (feeding_style = "artists")) and (gabriel_status = 1)
		*gosub gabriel_arrives
	*set month +1
	*goto fair_central_hub
*elseif month = 8
	*gosub calibrate_interlocutors
	*if negro_day > 1
		*gosub negro_day
	*if (norris_arena = 3) and ((stl_met_slattery = 8) or (stl_met_slattery = 5))
		*gosub slattery_vs_norris
	*comment *gosub across_the_bow_sort
	*comment what tf was this supposed to be?
	*if knows_about_silver and (knows_about_bullets = false)
		
		You commission the creation of several dozen silver bullets. If this battle with @{west_prob ${imposter}|West} is nearing, you intend to be prepared.
		*gosub blacksmith_bullets
	*if lpe_event = 2
		*gosub nawsa_debates
	*gosub anthropology_days
	*gosub chopins_demise
	*gosub olympics
*elseif month = 9
	*if in_the_railyard
		*gosub in_the_railyard
	*gosub resolve_gabriel
	*if (stl_met_slattery = 8) and (sporting_goods > 2)
		*gosub slattery_vs_spaldings
	*comment Full Moon 9/24
	*set month +1
	*goto fair_central_hub
*elseif month = 10
	*gosub calibrate_interlocutors
	*gosub betrayal_sort
	*comment *gosub california_arrow
	*comment A zepplin race! https://welweb.org/ThenandNow/California%20Arrow.html
*elseif month = 11
	*if egans_rats_plot > 1
		*page_break
		@{(egans_rats_plot = 5) Baldy Higgins's|Snake Kinney's} campaign for state Senate is a resounding success. At the behest of ${egans_rats}, a record number of voters turn out in the district. In fact, a number of the Third Ward's dead voters manage to make it to the polls to cast a vote; if that didn't happen every election, it might have been considered a miracle.
		
		@{(egans_rats_plot = 5) Higgins's|Kinney's} saloon celebrates the event with open taps for his guests. @{(egans_rats_plot = 5) Higgins|Kinney} knows that whatever money's been squandered in the election will be recovered in spades once he is in office.
	*if dynamiteWest > 1
		*page_break
		With Robert Yates dead, you feel the time has come to make a decision about acquiring some dynamite—with the intent to use it.
		*choice
			#Yes, the risk is worth the reward.
				*set discretion %+5
				*set dynamiteWest 3
				It is simple enough to purchase some dynamite. There are even some instructions for various potential uses: detonating beaver dams, mining, and stump disposal. If only your needs were so mundane.
			#No, it will be too dangerous.
				*set discretion %-10
	*set month +1
	*goto fair_central_hub
	*comment Full Moon 11/23
*elseif month = 12
	*temp carlos_present false
	*if stl_praetor_carlos > 1
		*set carlos_present true

		Thanksgiving arrives. It is a curious holiday, instantiated by President Lincoln to celebrate the successes and sacrifices of the Union soldiers in the war—and it is only sporadically recognized by St. Louisans.
		
		But this Thanksgiving, Praetor Carlos arrives in St. Louis—or so a short note from Senator Bailey informs you@{stlouis_tribune , when it summons you to meet him at the Southern Hotel|}.
		
		It seems your prayers have been answered.
		*page_break
		*if stlouis_tribune
			*set seen_carlos true
			Arriving at the Southern Hotel, you brace yourself for what is to come.
			*if sire_name = "Padre Carlos"
				*if sire_rapport > 60
					You quiver with anticipation at the thought of seeing your dominus once again.
				*elseif sire_rapport > 45
					You steel yourself at the thought of seeing your dominus once again. You do not expect this confrontation to be simple.
				*else
					You quaver at the thought of seeing your dominus once again.
			*else
				*set met_carlos true
				You are preparing to the meet the Praetor of the Americas. @{(independence > 50) You intend to conduct yourself appropriately.|You wonder if he's going to make you stand on ceremony.}
			
			Entering the bar of the Hotel, you spy Bailey and @{(sire_name = "Padre Carlos") your dominus|the praetor} at a corner table. @{(sire_name = "Padre Carlos") Your dominus still|The Praetor} wears a cassock and collar. @{priest As you cross the room in your own cassock, you observe several raised eyebrows at the sight of two priests meeting in such a locale.|}
			
			You offer a ${bow} when you reach the table.
			*temp the_praetor "the Praetor"
			*if sire_name = "Padre Carlos"
				*set the_praetor "your dominus"
				*if embrace_of_affection
					A thrill goes through you—or perhaps more of a shudder. There was something between you once, yes. But the affection that he showed you was interspersed with—nay, overshadowed by—torment.
				*else
					You nod gravely at your former patron.
				
				*if trans
					*set sire_rapport %-20
					He looks at you with disdain. "What is this?" he says, gesturing to your clothing.
					
					"This is me, dominus."
					
					"This is an abomination."
					
					*if (rationalism > 50) and (discretion > 40)
						*set bailey_rapport %+10
						*set sire_rapport %-10
						You look at him askance. "I am as God made me; this was who I was before I became a vampire. But you…you are a vampire who murders God's people indiscriminately. Who, then, is the abomination?"
						
						Your dominus stands as though to strike you, but Bailey's arm shoots out and stills him. "We have greater problems at the moment, Praetor."
					*elseif (intelligence > 2) and (discretion > 40)
						*set bailey_rapport %+15
						*set sire_rapport %-10
						You look at him askance. "I have never understood the attachment people like you have to the idea of God's genitals. If your God is so transcendent, do you really think he has a penis? Do you think there is a big, shriveled scrotum up in the sky? What would he use them for, to make it rain?
						
						"No. You assume his gender. Just like you assumed mine. Your bluster only makes you that much smaller."
						
						Your dominus stands as though to strike you, but Bailey's arm shoots out and stills him. "We have greater problems at the moment, Praetor." When Carlos sits down, Bailey shoots you a private nod of approval.
					*elseif (discretion > 75)
						*set bailey_rapport %-10
						*set sire_rapport %-5
						Your vision goes red and your fangs extend. You crouch and prepare to throw yourself at your maker—despite all the witnesses.	
						
						"${given_name}," Bailey snaps. You look at him ever so briefly, but it's enough. Suddenly, you are calm once again. Or, at least, you find yourself unable to act upon your rage.
						
						Carlos is shaking his head. "What a disappointment you are."
						
						"Praetor, ${given_name} is the Tribune of St. Louis. He is here to aid you in bringing down the Beast. Perhaps you could be more generous…"
						
						"${original_name} can serve as the decoy. When @{male she|he} expires, I will dispose of West."
						
						"Perhaps you could intervene before ${he} expires?"
						
						"Not likely."
						
						With that, you dominus stands and leaves the bar.
						*goto post_carlos
					*else
						You burn with humiliation. You try to find the words, but everything sounds ridiculous in your head.
						
						Bailey sees your distress and tries to intervene.
				*else	
					"${given_name}," he says.
					
					"@{(sire_rapport > 65) Chaime|Dominus}," you @{embrace_of_affection whisper|utter}.
					
					"There is little time for reunions. West is on the prowl."
					
					"@{(sire_rapport > 65) Chaime|Dominus}…" you repeat, weakly.
					
			*else
				
				Bailey introduces you to the Praetor, who @{(status + 1) BUG not possible|barely nods in your direction.|sizes you up and nods in greeting.|stands to greet you in turn.|stands to greet you in turn.}
				
			"We were just discussing your appointment as Tribune," Bailey notes.
			
			"Not an easy role, ${mr} ${surname}," ${the_praetor} says.
			
			"We do not do things because they are easy, 
			*if sire_name = "Padre Carlos"
				@{(sire_rapport > 65) Chaime|dominus}," you retort, regaining some of your strength.
			*else
				Praetor," you reply.
			
			"No, I suppose not."
			
			@{(discretion > 50) "Might I ask, then, what your intentions are for the confrontation?"|You listen to the two trade barbs for a while before the matter of the hunt—and plans for its execution—finally arises.}
			
			*if (sire_name = "Padre Carlos") and (compassion < 40)
				You push your emotions further down.
			"West seems focused on the Exposition. I suggest that you confront him there, amid the Human Zoological Gardens. Most of the mortals do not speak English, and whatever they do or do not see will be easier to explain away if they cannot communicate with the residents of the city."
			
			"A wise decision, Praetor," Bailey nods.
			
			"Tribune, I expect you to be in the middle of the confrontation. Your young blood will draw him out."
			
			So…you're the bait.
			
			"I will conceal myself nearby and strike when the moment is right."
			
			*if discretion > 45
				"By which you mean, when he has severed my head from my body? Or when he has consumed my soul?"
				
				"@{(sire_name = "Padre Carlos") My scion|Tribune}, would you rather have a chance at me saving you, when I am lurking nearby and ready to pounce, or to hide in your hovel and with no expectation of me coming to your rescue?"
				
				"Forgive me, Praetor."
				
			*else
				"May you strike true, Praetor."
				
				"I always do, @{(sire_name = "Padre Carlos") my scion|Tribune}." Seeing no more objections from you or Bailey, he stands.
			"So shall it be," he concludes.
			*label post_carlos
		
	*gosub hunt_west
	*page_break
	And like that, the Exposition is over.
	
	Much of the fair is broken down within a week; some of it is in boxcars within twelve hours, bound for another exposition in San Francisco. Several of the buildings were intended to be permanent, and will become the new home of Washington University. @{((stlouis_enterprise = 7) or (stlouis_enterprise = 3)) The scientists and academics of the city are salivating at the thought.|}
	*temp lpe_return 2500000
	*temp climate_bonus 1
	
	*if lpe_success > 80
		*set lpe_return +250000
		The Exposition is considered an extraordinary success.
	*elseif lpe_success > 65
		*set lpe_return +100000
		The Exposition is considered a fantastic success.
	*elseif lpe_success > 52
		The Exposition is considered quite a success.
	*elseif lpe_success > 40
		*set lpe_return -100000
		The Exposition is considered a reasonable success.
	*elseif lpe_success > 30
		*set lpe_return -250000
		The Exposition was not much of a success.
	*else
		*set lpe_return -1000000
		The Exposition was a failure. Tickets went unsold, crowds were underwhelming, and vendors packed up and left before the event was concluded—spurning their contracts and foregoing their deposits.
	
	*if lpe_member > 1	
		*if stlouis_business_climate > 75
			*set climate_bonus 1.3
			The financial returns were further aided by the negligible regulations around industry and worker safety in St. Louis. Through stolen wages, shoddy workmanship, exhorbitant fees, and general chicanery, the Committee was able to squeeze even more money out of the affair.
		*elseif stlouis_business_climate > 65
			*set climate_bonus 1.1
			The financial returns were aided by the ability of vendors to underpay workers and cut corners around building safety. Through a variety of shoddy practices, the Committee was able to squeeze a little more money out of the event.
		*elseif stlouis_business_climate > 55
			*set climate_bonus 1.025
			The financial returns were minutely boosted by the inability of the workers to organize against the vendors, yet the vendors were themselves not so unscrupulous as to take advantage of the situation. Scams such as shoddy materials and wage theft were not uncommon throughout the Exposition, but they were not so systematic as to notably blight the affair.
		*elseif stlouis_business_climate > 45
			*set climate_bonus 0.95
			The financial returns were negatively impacted by the disorganized demands of the workers and the attempted predations of the vendors. At several points, the Committee and its agents had to step in and pay off various parties in order to keep the fair running smoothly.
		*elseif stlouis_business_climate > 38
			*set climate_bonus 0.9
			The financial returns were negatively impacted by the conflicts between the workers and the attempted predations of the vendors. The workers were eventually put in their place, but the police had to be called on numerous occasions to force the matter.
		*else
			*set climate_bonus 1.05
			While the vendors of the fair were constrained at almost every turn by union actions and demands for better working conditions, the ultimate result was more local workers and their families were able to attend and had money in the pockets to spend.
		*set wealth +(lpe_return * climate_bonus)
	*finish
*set just_spoke_yates false
*if becard_hunts_gould
	*gosub becard_hunts_gould
*gosub departure_notification
*choice
	*if ((interlocutor_1 = 2) or (interlocutor_2 = 2)) #Dido Applethorp is here; she's headed to see the Yoruba exhibit.
		*gosub_scene stlouis_gudhrun applethorp_in_stl_convo
		*set interlocutor "Applethorp"
		*set interlocutor_num 2
	#Bécard must be around here somewhere.
		*gosub becard_at_fair
		*set interlocutor "Bécard"
		*set interlocutor_num 1
	*if ((interlocutor_1 = 8) or (interlocutor_2 = 8)) #Governor Björnsdotter is here; she seems to be headed to the Swedish pavilion.
		*gosub_scene stlouis_fair_opening bjornsdotter_convo
		*set spoke_stl_bjornsdotter true
		*set interlocutor "Björnsdotter"
	*comment #Hiram Eliot is here.
		*comment *gosub eliot_at_fair
		*comment TODO
	*if ((interlocutor_1 = 5) or (interlocutor_2 = 5)) #@{met_fragala I need to speak with Calogero Fragalà.|There is a lesion-covered vampire with a Mediterranean skin-tone here.}
		*gosub fragala_at_fair
		*set interlocutor "Fragalà"
		*set interlocutor_num 5
	*if (month <= 8) and (gabriel_status = 1)
		*if (knows_gabriel or (perception > 1)) #@{knows_gabriel Gabriel, the Vampire of Cincinnati, is headed to the pleasure garden.|Is that Gabriel, the Vampire of Cincinnati, headed for the pleasure gardens?}
			*gosub gabriel_at_fair
	*if ((met_lefferts) or (heard_of_lefferts and (gould_plot = 4))) #Edwin Lefferts and Jay Gould are here@{(gould_plot < 3) —which is strange, because you had heard that Gould died of tuberculosis?|.}
		*gosub lefferts_at_fair
		*set interlocutor "Edwin"
		*set interlocutor_num 9
	*if ((interlocutor_1 = 6) or (interlocutor_2 = 6)) #@{(met_maffi > 1) Thérèse Maffi is here from Haiti?|There is a mixed-race woman here.}
		*gosub maffi_at_fair
		*set interlocutor "Maffi"
		*set interlocutor_num 6
	*if ((interlocutor_1 = 4) or (interlocutor_2 = 4)) #@{met_estefania Estefania is here?|There is a Spanish vampire here.}
		*gosub rios_at_fair
		*set interlocutor "Rios"
		*set interlocutor_num 4
	*if ((interlocutor_1 = 3) or (interlocutor_2 = 3)) #I approach the black male vampire.
		*gosub herbert_walker_at_fair
		*set interlocutor "Walker"
		*set interlocutor_num 3
	*if ((interlocutor_1 = 7) or (interlocutor_2 = 7)) #Samantha Withers has come to St. Louis!
		*gosub withers_at_fair
		*set interlocutor "Withers"
		*set interlocutor_num 7
	*if (month > 6) #I think I see Robert Yates.
		*gosub yates_at_fair
		*set interlocutor "Yates"
		*set interlocutor_num 8
		*comment Yates replaces Gudhrun for num.
*if month = 10
	*gosub west_hunts_yates
*set month +1
*page_break
*goto fair_central_hub

*label calibrate_interlocutors
*comment place where readers can't use the stats page to scum for different options.

*if choice_randomtest
	Debug Month: ${month}

*if month > 6
	*set interlocutor_2 interlocutor_1
*gosub get_i1 1
*if month = 6
	*gosub get_i2 2
*return

*label blacksmith_bullets
*if werewolf_hysteria > 4
	
	The blacksmith issues a belly-laugh when you make your request; apparently, you are not the only person to commission some. Several fearful St. Louisans, concerned about the rumors of a werewolf, have already commissioned some.
	*set refined_silver_bullets true
*return

*label departure_notification
*if bailey_rapport > 60
	*if (interlocutor_2 = 2) and (spoke_stl_applethorp = false)

		You hear from Bailey that Applethorp is preparing to depart St. Louis; this is likely your last chance to speak with her.
	*if (interlocutor_2 = 8) and (spoke_stl_bjornsdotter = false)

		You hear from Bailey that Björnsdotter is preparing to depart St. Louis; this is likely your last chance to speak with her.
	*if (interlocutor_2 = 5) and (spoke_stl_fragala = false)
		
		*if heard_of_fragala
			You learn from Bailey that Fragalà is preparing to depart St. Louis; this is likely your last chance to speak with him.
		*else
			*set heard_of_fragala true
			You learn from Bailey that the Mediterranean-toned vampire is the Quaestor of Kansas City, Calogero Fragalà; and the Quaestor is preparing to depart the city. This is likely your last chance to introduce yourself.

	*if (interlocutor_2 = 6) and (spoke_stl_maffi = false)

		*if heard_of_maffi
			You hear from Bailey that Maffi is preparing to depart St. Louis; this is likely your last chance to speak with her.
		*else
			*set heard_of_maffi true
			You learn from Bailey that the mixed-race vampire is Thérèse Maffi, an important vampire from Haiti. What's more, she is preparing to depart; this is likely your last chance to introduce yourself.

	*if (interlocutor_2 = 4) and (spoke_stl_rios = false)

		*if met_estefania
			You hear from Bailey that Rios is preparing to depart St. Louis; this is likely your last chance to speak with her.
		*else
			*set heard_of_rios true
			You hear from Bailey that the Spanish vampire, Estefania Rios e Hidalgo, is preparing to depart St. Louis; this is likely your last chance to speak with her.

	*if (interlocutor_2 = 3) and (spoke_stl_rios = false)

		*if heard_of_herbert_walker
			You hear from Bailey that the black male vampire is Herbert Walker, 
		*else
			*set heard_of_herbert_walker true
			You hear from Bailey that the black male vampire is Herbert Walker of Chicago,
		and that he is preparing to depart. This is likely your last chance to speak with him.

	*if (month = 10) and (spoke_stl_yates = false)

		You hear from Bailey that Yates is preparing to depart St. Louis; this is likely your last chance to speak with him.

*if heard_of_herbert_walker = false
	*if ((interlocutor_1 = 3) or (interlocutor_2 = 3)) and (met_herbert_walker < 3)
		*if noticed_walker = 2
			That black male vampire is still here.
		*if noticed_walker = 1
			*set noticed_walker +1
			You notice a black man that you are sure is a vampire enjoying the fair. You don't recognize him.
*return

*label betrayal_sort
*comment if the cult is still around at this point, some sort of betrayal arises. At least, I'm guessing that was the logic here.
*if sod_hunt_cult
	*page_break
	*set stlouis_cult_power %-10
	From the depths of your daysleep, you sense something amiss.
	
	Knocking, pounding, voices, distress.
	
	When rouse yourself from your ${sleeping_place}, you find ${stlouis_valet} and Amanda waiting for you.
	
	"What is it?" you @{(discretion > 50) demand|ask}.
	
	"The temple! It's on fire!"
	
	No time for modesty; you strip your sleeping clothes away and replace them with something functional. Within minutes, ${stlouis_valet} is guiding the ${coupe} towards your site of worship.
	*page_break
	The temple was @{stlouis_cult_celebration a simple affair, built to resemble a rooming house.|a proper church, outfitted with a steeple and bell.|an extensive brothel, with spacious rooms to satisfy your congregation's needs.|an abandoned church, reclaimed and repurposed to spit on the icons of Christianity.} Now, it's a roaring fire.
	
	Your congregation—those that were inside or lived nearby—are standing around, sobbing. Some are trying to throw water on the conflagration, but it's no use. Thankfully, the building stands alone, and therefore no other buildings are threatened.
	*if stlouis_arsonist_investigation > 1
		Could there be another arsonist about? @{((ethnicity = "african") or (ethnicity = "choctaw")) You suppose so; there's nothing stopping another adherent to the Lost Cause picking up the torch and continuing where Freddie Parke left off. And anything you're associated with could certainly be a target.|But why would such an arsonist target you and your congregation?}
	
	"Who is responsible for this?" you thunder.
	
	Silence greets your question.
	
	"Amanda?"
	
	"A few individuals. Mostly men, at least one woman. Five, six, people altogether."
	
	"Which way did they go? What did they say?"
	
	"Nothing. Nobody knows. They fled after throwing their torches into the temple."
	
	You let out a cry of frustration. You fall to your knees. @{((discretion < 50) and (stlouis_cult_celebration != 1)) It is a bit theatrical, but sometimes your congregation needs theatrics.|}
	
	And there, in the dirt, you something catches your eye, reflecting the firelight. Picking it up, you turn it over in your hand. It's likely made of tin, and bears a resemblance to a sheriff's star. Except, instead of five or six points, there are eight rays—making a crude sun.
	
	*choice
		#I disband the cult. Their lives are more important than my convenience.
			*set stlouis_cult false
			*set exposure -3
			*set compassion %-30
			*set discretion %-10
			*set shepherd_credentials %+10
			Amanda, ${stl_kid_nick}, and the others are distraught by the news. You encourage them to hold the tenets of your faith close—perhaps you will call upon them again one day—but for now, they must scatter like seeds in the wind.
		#I do nothing to defend the cult. Eventually, whoever this is will grow bored and move on. And the faithful will consider a test of their faith.
			*set exposure -2
			*set compassion %+10
			*set discretion %-10
			*set stlouis_cult_power %-50
			*set local_fame %-5
			Your disciples find their homes and businesses burned to the ground. They are fired from their factory jobs. They are shunned by their friends and neighbors.
			*if stlouis_cult_power < 25
				*set stlouis_cult false
				Unfortunately, their faith is not strong enough. In time, even Amanda and ${stl_kid_nick} turn from you.
				
				The faithful are no more.
			*else
				Though the road is challenging, a core group endures.
				
				Eventually, as predicted, the assault wanes. Whoever this is obviously has not been defeated, but, for the time being, they have moved on.
		*if (perception > 2) #There must be a mole. Though it will be destructive to the organization, I will interrogate the membership until I find him or her.
			*set exposure -1
			*set compassion %+5
			*set stlouis_cult_power %-20
			To your surprise, it is ${stl_kid_nick} that is feeding information to whoever is hunting your faithful.
			
			Unfortunately, ${stl_kid_nick} does not know who they are—other than the fact that they seem to have some fascination with the sun—but they clearly want your destruction.
			
			When you ask him why he betrayed you, he shrugs. @{stl_kid_origin ERROR|"I was happy with the circus. They was my family. You took me away from everyone that I knew and made me serve Amanda. What did you expect?"|"You think makin my family stay in this town was a blessing? The Reach ain't nothin like Kansas. This here was a state with slaves, and it won't never be nothing but a state with slaves. And we could have gone! Erreyone of us! But you made us stay in this hellhole."|"You think that just because you tried to get folks to stop drinking that you helped them? At least when he was drinking, my pops would eventually go to sleep! But once them temperance workers took away the bottle, all he had was God, and God don' never sleep. The things he did to my moms, now that he was awake enough to remember? Damn you."|"You is just like the monster that killed my family. If I could kill you three times, I would."|"You think we should worship you? I lived in the streets. I killed another boy when I was eight for his supper. You don't know anything about what's like out there. And you ain't worth no worship as long as you don' know what's goin' on under your nose!"|"You broke the strike at the cigar factory and my pops weren't never the same. He used to believe in something. He read to folks and they looked up to him. And then that was all washed away. And there you were behind it all, laughing. You don't deserve the peace of death."}
			
			*set discretion %+5
			Outraged at this betrayal, you crush the life out of him.
			
			You direct Amanda to dispose of the body. You remonstrate your remaining disciples, urging them to watch one another for signs of betrayal or heresy.
			
		#I set a trap@{stlouis_hideout  using my hideout in Chestnut Valley|}; when they spring it, I will kill them all.
			*if stlouis_hideout
				*set stlouis_hideout false
				*set compassion %+10
				*set discretion %+10
				*set exposure +2
				*set wealth +20000
				*set stlouis_cult_power %-5
				You make use of the hideout you established in Chestnut Valley to serve as the location of your trap. The place is ideal, as it's already outfitted with secret rooms, hidden exits, and other useful features.
				
				Of course, you must keep the full scope of the plan to yourself—but when your persecutors attack, your disciples are ready.
				
				They try to set fire to the building first, but that is quickly extinguished. Meanwhile, a squad of assailants try to enter by the back door. However, once they have entered, a second, emergency door closes behind them, trapping them inside.
				
				A few minutes later, four sets of hands are thrown down from the roof.
				
				The assailants then take a few pot-shots at the building, but with no visible targets, the gunfire does nothing more than draw the attention of the police.
				
				You have to grease the wheels of the District Attorney to not ask too many questions about the bloody machetes that the police find, but you had already made plans to dispose of the bodies. 
				*if stlouis_enterprise = 2
					The hideout is burned—you sell it to @{(egans_rats_plot = 5) Baldy Higgins|Thomas Egan} at a steep discount—but
				*else
					The hideout is burned, but 
				your organization survives almost unscathed.
				
			*else
				*set compassion %+10
				*set discretion %+20
				*set exposure +6
				*if income > 10
					*set income -2
				*if income > 100
					*set income -2
				*set stlouis_cult_power %-10
				*set local_fame %-5
				*set stlouis_business_climate %-5
				Setting up a fake headquarters for your organization is no mean feat. Keeping the plan to yourself—so that no one can leak it to your hidden persecutors—is even more challenging.
				
				One evening, the assault begins. Your disciples respond with gunfire. Soon, a pitched battle unfolds on the streets of the Soulard. @{(stlouis_haven = "soulard") It is uncomfortably close to your haven, in fact.|}
				
				The assailants were not prepared for your aggressive response. At least four attackers, men and women, die during the assault. @{(discretion < 65) (You lose at least twice that many disciples.)|Some of your disciples die as well, but you can't be bothered to count them.} Unfortunately, ${stl_kid_nick} dies in the battle.
				
				You spy the man who must be their leader—he watches from a distance, nervously twisting his mustache—and he orders the retreat when it becomes clear that his subordinates will not win the night.
				
				During the police inquest into the matter, your disciples are recognized as a community of faith that was under attack from unidentified drifters. One of your lieutenants is sentenced to three years at the State Penitentiary, but the lawyers you hire are able to negotiate very favorable terms for the rest.
				
				The downside is that, while you never step forward and publicly announce that you are a deity in need of worship, word of your association ripples through the city like wildfire. Whatever life anonymity you held before evaporates almost overnight.
	*page_break
*elseif cult_power_struggle
	*page_break
	As time has passed, the relationship between Amanda and ${stl_kid_nick} has become more and more fraught. The two bicker constantly. When one evening's @{stlouis_cult_celebration prayer circle|revival session|orgy|blood-soaked rapture} goes awry, each blames the other.
	
	You urge them to work out their differences, but instead the matter continues to the point that ${stl_kid_nick} kills Amanda.
	
	Your disciples are up in arms over the murder. @{(stlouis_cult_celebration > 2) Many of them outright celebrate Amanda's death.|} ${stl_kid_nick} himself accuses the dead woman of all sorts of nefarious deeds—and more than half the church believes him.
	
	Ultimately, ${stl_kid_nick} isn't wrong. Amanda did do the things of which he accused her—but she did them at your direction.
	
	Regardless, now you must decide what to do with ${stl_kid_nick}.
	
	*choice
		#Fortune favors the bold; ${stl_kid_nick} will be the new leader of my disciples.
			*set compassion %+5
			*set discretion %+5
			*set stlouis_cult_power %-35
			*set income -5
			*if income > 50
				*set income -5
			*if income > 100
				*set income -5
			Many disciples who were loyal to Amanda feel that you have betrayed her years of service to you by embracing ${stl_kid_nick}. You don't really care about their feelings.
		#${stl_kid_nick} must be punished; I expel him from ${stlouis_cult_name}.
			*set discretion %-5
			*set stlouis_cult_power %-50
			*set income -8
			*if income > 50
				*set income -8
			*if income > 100
				*set income -8
			Unfortunately, ${stl_kid_nick} had amassed quite a loyal following. When he leaves, he takes his faction with him. ${stlouis_cult_name} folds in on itself in his absence.
		#I quitely dispose of ${stl_kid_nick} and concoct a lie about his depature from St. Louis.
			*set compassion %+10
			*set stlouis_cult_power %-25
			*set local_fame %-5
			*set exposure +1
			*set income -3
			*if income > 50
				*set income -3
			*if income > 100
				*set income -3
			Your disciples just don't quite buy the idea that ${stl_kid_nick} decided that Alaska was for him, that he hopped a train and is now panning for gold on the Yukon.
			
			Many drift away, suddenly suspicious of you and your failure of leadership.
	*page_break
*return

*label rios_at_fair
*temp es_name "Rios"
*temp just_met_rios false
*temp rios_time 2

*if met_estefania
	Your throat constricts. It has been decades since you last laid eyes on Estefania Rios e Hidalgo. From beneath her wide-brimmed hat, she affixes you with her dark brown eyes; you wonder for a moment if they might swallow your soul.
	*if flirting_with_estefania and (rios_rapport <= 45)
		*set flirting_with_estefania false
		But something has changed. The charge that once existed between the two of you is gone; now there is only an immeasurable gulf.
	*if trans
		
		"Good evening, @{estefania_is_kin Estefania|Sra. Rios}," you begin.
		
		She looks at you, recognition dawning. You can almost see the wheels turning, calculations being made, decisions reached…if you could breathe, you would now be holding your breath.
		
		"I see that things have changed with you," she replies.
		
		"Indeed, they have. Many things can change over the course of decades apart."
		
		A decision has been reached. "What should I call you?"
		
		"@{changed_surname ${given_name} ${surname} is my name now|I go by ${given_name} now; I kept my family name}."
		
		*if estefania_is_kin
			*set es_name "Estefania"
			She takes your hand into hers. "It's a pleasure to re-meet you, ${given_name}." A pause. "Have you told my brother?"
			
			@{sire_alive "No, I have not seen Nando since I left New Orleans. I thought it best to tell him in person."|"No, I still have not seen him," you reply. You have grown used to lying about your patricide over the years, but the matter is somehow harder with people that knew Villanueva.}
		*if estefania_is_kin = false
			@{(rios_rapport > 50) "A pleasure to re-meet you, ${given_name}."|"${given_name}. Very well," she nods.}
		*goto rios_after_intro
*else
	*set met_estefania true
	*set just_met_rios true
	Approaching the woman, you suddenly realize that she's been aware of you longer than you have been of her. As you draw up beside her, she points and remarks on the architecture of one of the nearby pavilions. A nonsense statement, but the subtext is clear: she does not fear you.
	*if (speaks_english = false) and ((speaks_french = false) and (speaks_spanish = false))
		Of course, it takes another moment for the two of you to find a common tongue, but thankfully she speaks German.
	
	"${mr} ${given_name} ${surname}," you say with a ${bow}.
	
	She smiles at you, extending her hand. "I am Estefania Rios e Hidalgo. A pleasure to make your acquaintance, ${mr} ${surname}."
	*if estefania_is_kin
		She pauses. "I have heard of you. you are the scion of my broodmate, Nando."
		
		"So I am, [i]Señora[/i]."
		
		*if sire_alive
			"Well, then, truly a pleasure, ${mr} ${surname}."
			
			She smiles at you graciously.
		*else
			"Have you seen him?" she says, her eyes boring into you. "We have not heard from him in…decades."
			
			You choose your words very carefully. "No, I have not heard from him." 
			
			You fumble to change the subject.
	*else
		
		"The pleasure is mine, [i]Señora[/i]."
		
		She smiles at you graciously.
	*goto rios_after_intro

*comment the choice below is only available to non-trans players who have previously met Rios.
*choice
	*if (estefania_is_kin) #"Good evening, cousin@{flirting_with_estefania ," you say with a raised eyebrow.|."}
		*if flirting_with_estefania and (rios_rapport > 55)
			"@{speaks_spanish Auntie|[i]Tía[/i]} might be more appropriate, little one."
			
			"Little one!" you exclaim. "I'll show you!"
			
			With that you pull her into an embrace.
			*label hug_estefania
			*set es_name "Estefania"
			
			*gosub_scene util experience_unfed_hug
			After a moment, the two of you separate, none the closer for it.
		*elseif rios_rapport > 50
			"And a good evening to you, ${given_name}."
			
			"It has been too long, Estefania."
			*set es_name "Estefania"
			
			"I agree," she says with a smile.
		*else
			She rolls her eyes. "I suppose I should be grateful that you aren't calling me @{speaks_spanish auntie|[i]tía[/i]}."
			
			"Would you prefer that?"
			
			"Certainly not."
	#The formal route: "How is your maker, Sra. Rios?"
		*if status > 2
			"I see your standing in the Society has made you officious," @{flirting_with_estefania she says with a wry grin|she observes dryly}.
			
			"Officious!
			*label stuffy
			*set es_name "Estefania"
			*if flirting_with_estefania and estefania_is_kin
				Would you rather me greet you with a 'hello, @{speaks_spanish auntie|[i]tía[/i]}'?"
				
				"Do not tease me so, ${given_name}."
				
				"Or what?"
				
				"I might have to punish you."
				
				"We couldn't have that, now could we?"
				
				"You are absolutely no fun, ${given_name}."
			*else
				I prefer courteous."
				
				"Courteous, then," she confirms. You don't believe her for a second.
		*elseif rios_rapport > 50
			"Why so formal? Or have you grown too stuffy for your old @{estefania_is_kin cousin|friend}?"
			
			"Stuffy?" you rejoin. "Really?
			*goto stuffy
		*else
			"He is well, thank you," she replies.
			
			"I am glad to hear it."
	*if (flirting_with_estefania) #"I do not know if I should be moved to joy or rage, Estefania."
		"@{speaks_spanish Why not both|[i]Por que no los dos[/i]}?"
		
		"And by that you mean?"
		
		"Have you ever known me to be satisfied with just one thing?"
		
		"No, I suppose not."
		
		"Then let us start with joy," she says, moving to embrace you.
		*goto hug_estefania
	*if (heresy_of_abraham > 0) #I greet her with the signs of the Children.
		Rios responds with the signs of acknowledgement.
		*if flirting_with_estefania
			*set rios_rapport %-10
			*if perception > 1
				You sense that she is disappointed that you greeted her as a fellow member of the cult first, rather than as something…more.
		*if estefania_is_kin and (rios_rapport > 50)
			Formal greetings done, Estefania breaks into a wide grin. "It is good to see you, cousin."
			
			"And you, Estefania," you reply.
			*set es_name "Estefania"
		*else
		
			"It has been a long time, ${given_name}."
			
			"That it has, Sra. Rios."
*label rios_after_intro

"What brings you to St. Louis?" You try not to stare at the taxidermied owl that nestles in the [i]tableau[/i] of her hat. You didn't notice it at first, but now you realize what—besides ${es_name} herself—was staring back at you.

${es_name} raises her hands, gesturing to the people, the fair, the world…all of it, you suppose. "How could I not come? It is a cornucopia of blood." @{just_met_rios That is a curious turn of phrase, you note.|}

"How long have you been here?"

"A few @{just_met_rios days."|days. I'm sorry I did not reach out to you sooner."}
*if (perception > 1) and (just_met_rios = false)
	@{(rios_rapport > 55) You sense that she is being sincere.|Her insincerity is grating.}

*temp rios_time 3
*temp more_about_abraham true
*label rios_convo
*if rios_time < 3
	You sense the opportunity to ask another question.
*if rios_time = 0
	
	"The time has come for me to depart, ${mr} ${surname}."
	
	"Thank you for your time, Sra. Rios," you reply.
	*return
*choice
	*if ((just_met_rios = false) or (estefania_is_kin)) #"Then let us feed together!"
		*temp rios_prey 1
		*set rios_time -1
		*set exposure +1
		${es_name}'s eyes go wide with anticipation. "And whom shall we feed upon, dear ${given_name}?"
		
		*fake_choice
			#"Have you heard of the Ainu? They are native to some corner or other of the Japanese Empire…"
				"The Ainu? No, I've never even heard of them!"
				
				"A people you have never even heard of; I must say I'm surprised."
			#"There must be a whole village of Cheyenne…"
				*temp rios_prey 2
				*if ethnicity = "choctaw"
					She looks at you quizzically. "You are not bothered by offering your kin to me?"
					
					"@{(compassion < 60) I am Choctaw; do you have a problem feeding from Austrians?|Mortals are food; why should I distinguish between the different breeds?}"
				
				"I have fed from the Indians of the east and the south…as well as throughout the Caribbean…but I don't suppose I've ever fed from a Cheyenne."
				
				"I'm curious to know what you think."
			#"Have you ever met an Igorot? There is a whole village of them here."
				*temp rios_prey 3
				"A whole village? How did they get here?"
				
				"Several ships, I expect. It is said that there are over a thousand of them."
			#"There are Mbuti here. You might know of them as pygmies?"
				*temp rios_prey 4
				You've never seen ${es_name} alarmed before, but that is the best word you can summon for her current reaction.
				
				"Pygmies? I…I don't know what to say."
				
				"Yea or nay would suffice."
			#"Have you ever met a Zulu? There are several dozen of them with the Boer War recreationists…"
				*temp rios_prey 5
				"Recreationists?"
				
				"Yes, they reënact a few battles from the war for the crowds."
		
		"Let us do that, then."
		*page_break
		The @{rios_prey Ainu camp is|Cheyenne camp is|Igorot village is|Mbuti village is|perfomers' bunkhouses are} not far. The difficulty, of course, is isolating one of them from their companions.
		*if (rios_prey = 2) and (ethnicity = "choctaw")
			You may share some resemblances with your prey, but you do not speak the Cheyenne tongue, nor are you dressed in the costumes that are requried by the fair.
		*if (rios_prey = 5) and (ethnicity = "african")
			You may share a general tone of skin with your prey, but everything else about the way you look, speak, and dress is different from the Zulus.
		The classic tactic, of course, is to wait for one to heed the call of nature. Eventually, one of them does.
		
		*if flirting_with_estefania and ((status < 3) or (independence < 50))
			After the @{rios_prey Ainu|Cheyenne|Igorot|Mbuti|Zulu} man has finished his business, he turns to find you and Rios waiting. Though he understands @{rios_prey no|only a little|no|no|only a little} English, ${es_name}'s supernatural charms do not truly rely upon words. Soon, the young man is nodding along as though he fully understands, and the three of you find a dark corner to experience what he has to offer.
			
			*if (status >= 3) and (independence < 50)
				Technically, ${es_name} should be defering to you while the two of you feed. However, such niceties are quickly thrown to the wind.
			You sink your teeth into his neck, while Estefania attends to his inner thigh. A moment later, your heart begins to beat, and the three of you exist as one.
			*page_break
						
			You wipe the blood from your lips with your handkerchief. Looking down, you realize that a few drops have stained your @{male pants|skirt}. 
			
			"Oh, that will never do!" Estefania exclaims. She begins to fuss over it, but you grab her by the wrist. She looks into your eyes, her cheeks flushed by the recent infusion.
			
			*choice
				#"Estefania, if you wish to kiss me, kiss me. There is no need for pretenses."
					*set rios_time -1
					*set rios_rapport %+15
					And so she kisses you. After removing her hat, and carefully laying it down, of course; her hands tremble the entire way down and back. The desire burns within you…as long as the blood runs hot. Soon, it is not only your @{male pants|skirt} that @{male are|is} stained.
					
					But as it ever is, the blood runs cold and the desire fades. The two of you separate and begin to readjust your clothes and hair. Your meal groans from the corner, weak from bloodloss.
					
					Estefania glances at you sidelong. "We don't have to stop, you know. No one will miss @{rios_prey an Ainu tribesman|a Cheyenne warrior|an Igorot tribesman|a pygmy|this Zulu performer}." She straightens her hat. "I once spent an entire week in a villa outside Bogota. We drank and drank, such that we were almost alive again from dusk until dawn. We reminded ourselves of what—who—we once had been."
					
					*if (compassion < 40) and ((discretion > 60) and (shepherd_credentials < 40))
						*label excoriate_rios
						*set rios_rapport %-30
						"And how many people died for your indulgence?" you snap at her. "How many children lost their parents that week?"
						
						"${given_name}, it's nothing…they weren't really people. They were just savages."
						
						"You should know better than that, Estefania. Vampirism proves that humans are not different in quality from one another."
						
						"I…"
						
						"To answer your question, no, I do want to stop. If that man dies, he will be missed. His parents, his siblings, his children…they will all miss him."
						
						"All savages…"
						
						"Enough. If you will excuse me, I've had enough of your company for the evening."
						
						And with that, you take your leave of @{estefania_is_kin your aunt|Sra. Rios}.
						*return
					*else
						*choice
							#No one will miss him? How self-absorbed can she be?
								*set compassion %-5
								*set discretion %+5
								*set shepherd_credentials %+10
								*goto excoriate_rios
							#That does sound rather delightful. "We can't replicate that now, but you're right that we don't have to stop."
								*set rios_time -1
								*set compassion %+10
								*set independence %+15
								*set shepherd_credentials %-20
								*set discretion %+15
								*set rios_rapport %+25
								*set murdered_at_fair true
								Her eyes flash mischieviously. "By your leave…" she says with a small curstey.
								
								"After you," @{male you say with a bow|you return the curstey}.
								
								With that, her fangs extend and she latches on to the @{rios_prey Ainu tribesman|Cheyenne warrior|Igorot tribesman|pygmy|Zulu performer}'s neck. You pause for a moment, admiring the venality of the scene: an embodiment of insatiable hunger consuming the life of an insensate man, wedged between some crates in the space between tents and makeshift buildings, situated in the navel of the world.
								
								And then you push away such thoughts and join her in her feast.
								*page_break
								Your clothes, face, and hair are mussed and bloody. The two of you pressed yourselves against one another until the blood cooled. @{(discretion < 50) (${stlouis_valet} is going to be irate at what ${valet_he} has to do to fix this.)|}
								
								You right yourself as best you can, while Estefania adjusts her skirt and replaces her hat on her head. Arm-in-arm, the two of you set out into the fair.								
							#"Tempting, but the Quaestor has forbidden consuming mortals at the fair, lest it bring unwanted attention."
								*set independence %+20
								*set discretion %-15
								*set rios_rapport %-10
								Estefania does not attempt to hide her disappointment. "Very well, ${given_name}."
								
								"Come, there are plenty of things to see, and we do have much to discuss."
								
								She replace the hat on her head, loops her arm in yours, and off you go back into the fair.
							#"Time is short, Estefania, and I wish to hear more of your doings before we part again."
								*set discretion %-5
								Estefania does not attempt to hide her disappointment. "Very well, ${given_name}."
								
								She replace the hat on her head, loops her arm in yours, and off you go back into the fair.
						*goto rios_convo
				#"I promise you, it is nothing. Come, let us see more of the fair!"		
					*set rios_rapport %-5
					*set discretion %-5
					
					Estefania hands suddenly find new tasks in the vicinity of her hat. It takes her a few moments to return the hat to her head and set it properly, but when that is done, she loops her arm in yours and off you go, back to the fair.
					*goto rios_convo
		*elseif status >= 3
			You are mildly surprised to realize that ${es_name} is continually defering to you. When your prey finishes his business and turns to find the two of you, it is up to you to subdue him. Once you sink your fangs into his throat, you realize that she has gone so far as to wait for permission to join you. Your newfound rank in the Society must have something to do with it.
			*choice
				#I invite her to join me.
					*set rios_rapport %+5
					*set independence %-10
				#I make her wait until I've had my fill.
					*set rios_rapport %-20
					*set independence %+10
				#"Let us not stand on ceremony. The customs of times past should be buried."
					*set independence %-20
					*set rios_rapport %-5
					*set discretion %+10
					This does not seem to be what ${es_name} wanted to hear. Nevertheless, she cannot deny her hunger, and joins you in feasting on the @{rios_prey Ainu tribesman|Cheyenne warrior|Igorot tribesman|pygmy|Zulu performer}.
				
			When you have both had your fill, the two of you take a moment to adjust your clothing and otherwise put yourselves right. The final touch is ${es_name} restoring her grand hat to her head. That done, she laces her arm through yours and the two of you step back out into the fair, leaving your comatose victim moaning for help.
			*goto rios_convo
		*else
			After the @{rios_prey Ainu|Cheyenne|Igorot|Mbuti|Zulu} man has finished his business, he turns to find you and Rios waiting. Though he understands @{rios_prey no|only a little|no|no|only a little} English, ${es_name}'s supernatural charms do not truly rely upon words. Soon, the young man is nodding along as though he fully understands, and the three of you find a dark corner to experience what he has to offer.
		
			With a sigh, ${es_name} opens her mouth and extends her fangs. With a final smile, she turns and sinks her teeth into the inner thigh of the young man. He lets out a cry of surprise, but that quickly quiets to a groan as he succumbs to her.
			
			*if discretion > (60 + (bloodflow * 2))
				Without a second thought, you close the distance between you and his exposed throat.
				*label reach_for_meal
				*set rios_rapport %-10
				*if rios_rapport > 60
					*if perception > 1
						You sense Rios bristle, but then settle down. It seems that she trusts you enough to share her meal with you.
					
					When you have both had your fill, the two of you take a moment to adjust your clothing and otherwise put yourselves right. The final touch is ${es_name} restoring her grand hat to her head. That done, she laces her arm through yours and the two of you step back out into the fair, leaving your comatose victim moaning for help.
					*goto rios_convo
				*else
					Suddely, however, Rios is standing between you and the @{rios_prey Ainu tribesman|Cheyenne warrior|Igorot tribesman|pygmy|Zulu performer}, her hand on your chest.
					
					"What do you think you're doing?"
					*temp fought_rios false
					
					Possessed of an all-consuming hunger—or, rather, possessed by such—you lunge again for the @{rios_prey Ainu tribesman|Cheyenne warrior|Igorot tribesman|pygmy|Zulu performer} laying before you. It's at that moment that
					*if (agility + perception) >= 4
						you arrest ${es_name}'s forearm mid-strike. Your eyes flash in the darkness.
						
						"He is mine, you whelp!" she exclaims.
						*choice
							#"I…hunger…"
								*label fight_rios
								*set rios_rapport %-25
								*set exposure +1
								*gosub_scene util combat_value_ss
								*set fought_rios true
								*if shapeshifting > 2
									Drawing on the power of your blood, your hands morph into claws.
								*if combat > 8
									The engagement is brief. You bleed, as does she.
									*if estefania_is_kin 
										"My dear brother taught you well," she observes between clashes.
										
										"Maybe he should have taught you better," you retort.
									
									"Enough!" she exclaims after another clash sees both of your life-forces watering the earth.
									
									"Then let me feed!" you demand.
									
									"It is not your place to feed before your superiors."
									
									@{(revolutionary_credentials > 50) "Then what did Stone slay Miele for, if not to cast off the old ways?"|"First, you must show me that you are my superior."}
									
									"Are you finished? You are clearly an accomplished warrior. Let me feed and let us go our separate ways."
									
									*choice
										#"I will not submit to you, ${es_name}."
											With that, the two of you launch yourselves at one another.
											*if combat > 9
												And somehow, you come out on top.
												
												Your fangs are buried in Rios's neck, and you suck as though your unlife depends on it. For it absolutely does. @{diablerie When the moment of her expiration nears, you welcome it. This is not the first time you have consumed the heartsblood of another of your kind, nor will it likely be the last.|At some point, you feel something change. Suddenly, she stops fighting, but you can no longer stop yourself from drinking. The quality of the blood changes. You are now drinking what feels like her soul itself.}
												
												When you are finished, you watch as her body withers in on itself and soon crumbles to dust. Her blood-soaked garments lie neatly on ground, as though someone had arranged them for their mistress while waiting for her to return from a bath; only, these clothes' mistress will never enjoy them again.
												
												*gosub_scene util diablerie
												*set rios_alive false
												*set consumed_rios true
												*return
											*else
												*set killed_by_vampire true
												
												It is a frequent misconception that battles are long or drawn-out. When combatants are mis-matched, conflicts are frequently quite one-sided.
												
												And so it is here. You quickly realize that you are no match for the Castilian. She starts by breaking your arm, a move that sends a surprising wave of pain through you. When she breaks your spine a few moments later, you have no energy to cry out in protest.
												
												Given time and blood, you'd be able to recover from these wounds. Certainly. But Rios offers neither. You're only peripherally aware as she leaves your limp body for a few moments and then returns with something sharp. The first blow fails to sever your head from you neck, but the second one succeeds.
												
												In the moments after you death, you skin dries to paper and the flesh melts from you bones. Shortly, someone will find this skeleton in modern clothes and wonder who would go to such lengths to no discernable purpose.
												
												No answer will be forthcoming.
												*goto_scene scoring
										*selectable_if (willpower >= 3) #Relent.
											*goto rios_relent
										*selectable_if (discretion < 65) #I flee while I still can.
											*goto flee_rios
								*else
									You may have caught her hand, but you must have been lucky. When the fight begins in earnest, you are not match for her. Every strike is anticipated, every blow you think you are about to land turns out to be passing through empty space, and when she finally strikes you, it sends you crashing to the ground.
									
									Standing to your feet, you gain a moment's clarity: your story doesn't have to end here.
									
									*choice
										*selectable_if (discretion < 65) #Relent.
											*goto rios_relent
										#But that's not who you are. You do not shirk from violence; you will not begin now.
											*set killed_by_vampire true
											With a roar, you make your final charge. @{knows_about_stakes Only now do you see the stake in ${es_name}'s hands.|Some part of your mind registers that ${es_name} is holding a jagged piece of wood in her hands. You're not sure where it came from. It can't hurt you, can it?} You watch, dumfounded, as the wood pierces your chest—she is, of course, no longer where you expected her to be, and your heroic blow passes through empty air yet again.
											
											But this time, you feel yourself…somewhat further away. It's suddenly quite hard to care that you're falling to the ground in a heap. You sense her, and the @{rios_prey Ainu tribesman|Cheyenne warrior|Igorot tribesman|pygmy|Zulu performer}, but no longer precisely see them. In fact, it's impossible to keep your eyes open. Or perhaps they've already been closed for a very long time.
											
											"You could have been great, ${given_name} ${surname}."								
											*page_break
											*goto_scene scoring
							*selectable_if (willpower >= 3) #Relent.
								*label rios_relent
								*set discretion %-15
								*set independence %+20
								*set rios_rapport %+10
								It takes all your sharp edges working in concert to bring the beast inside you under control. With a growl, you withdraw your fangs and the rage recedes from your vision.
								*if fought_rios
								
									"Are you done?"
								
								"Yes, Sra. Rios."
								
								"@{(stlouis_tribune and fought_rios) It's unfortunate Memeskia put his faith in you; you do not make much of a Tribune. A bit of advice: wait your turn."|You must learn your place. And like all the riffraff, you must wait for your betters to take what is theirs."}
								
								You swallow your anger and watch as she turns and feeds on the @{rios_prey Ainu tribesman|Cheyenne warrior|Igorot tribesman|pygmy|Zulu performer}. @{fought_rios you clench your fists throughout, but you can sense that she is listening very carefully for any hint of betrayal.|}
								
								When she is done, you have no stomach for conversation. You excuse yourself and put as much distance between you and @{estefania_is_kin your aunt|Sra. Rios} as possible.
								*return
							*selectable_if (discretion < 65) #I flee while I still can.
								*label flee_rios
								*set discretion %-15
								*set rios_rapport %-15
								*if estefania_is_kin
									*set sire_rapport %-10
								Looking at ${es_name}, you see your end. And when confronted with your end, you decide that you want to live to see another moonrise.
								
								You turn and flee into the night. ${es_name} does not give chase.
								*return
					*else
						Rios's backhanded blow catches you across your cheek. Your head snaps back, your eyes flashing and teeth bared. Your posture shifts subtly, as your instincts demand blood as payment for the fact that she dared to strike you.
						
						"He is mine, you whelp!" she exclaims.	
										
						*choice
							#"I…hunger…"
								*goto fight_rios
							#"You dare strike me?"
								*goto fight_rios
							*selectable_if (willpower >= 3) #Relent.
								*goto rios_relent
							*selectable_if (discretion < 65) #I flee while I still can.
								*goto flee_rios
			*else
				You can somehow sense the blood welling into her mouth; you can see the small bit that seeps beyond the seal of her lips.
				
				The beast inside you roars. You hunger.
				
				*choice
					#I reach for his neck.
						*goto reach_for_meal
					#It is proper to wait until she has had her fill; I wait.
						*set discretion %-5
						*set rios_rapport %+10
						Your fists clench and you do your best to turn your mind to other things while Rios enjoys her repast. 
						
						When she is finished, she wipes her mouth, and then finally indicates her permission for you to begin.
						
						Of course, by that time the @{rios_prey Ainu tribesman|Cheyenne warrior|Igorot tribesman|pygmy|Zulu performer} is weak and has little blood left to offer. But you take what you can and then tear yourself away from his throat.
						
						"Is he not divine? I have truly never tasted anything like him!"
						
						"Is he your first?"
						
						"Most certainly. This was a lovely idea, ${given_name}."
						
						You nod in agreement as you seek to clean yourself up.
						*goto rios_convo
					#I leave. I have no interest in standing on these protocols.
						*set independence %-10
						*set rios_rapport %-15
						*set discretion %-5
						While Rios drinks her fill, you turn and leave.
						
						You suspect that she will be disappointed when she opens her eyes and finds you gone, but existence is fully of such little disappointments.
						*return
	#"What news of other cities?"
		*set rios_time -1
		*if ((sire_name = "Fernando de Villanueva e Itamaraca") and sire_alive) or (sire_name != "Fernando de Villanueva e Itamaraca")
			"Well, dear Nando is now Quaestor of Havana! I would call that quite a bit of news!"
			
			"Yes, so I heard! And were you part of his effort to oust al-Baqa?"
			
			She smiles demurely. "I was not on the island, no."
			
			You note that she did not answer your question.
		
		*if heard_of_fragala = false
			"Have you met the new Quaestor of Kansas City?"
			
			"No!" you exclaim, surprised that you have not encountered such an individual.
			*set heard_of_fragala true
			
			"He's a leper…you'll know him the moment you see him. Calogero Fragalà," she shudders. "I think it means his family were strawberry-pickers? And his face…his face is bloated and distended by the disease. I cannot imagine how he lives with himself. Or why his maker decided to give him the gift of immortality." @{(compassion < 35) You had almost forgotten how casually cruel Estefania can be.|She wrinkles her nose in disgust.} "I certainly wish someone would have advised him otherwise."
			
			*choice
				#"If he is Quaestor, he must be competent."
					Estefania sighs. "I'm not saying he's not competent. I'm saying it's an affront that I have to rest my eyes on him. That I have to know that he exists and that I will have to interact with him again some day."
				#"You could depose him and claim Kansas City for yourself," you note.
					"Yes, but then I would have to live in Kansas City."
					
					"Have you ever been?"
					
					She laughs. "[i]Aye, @{male muñeco|muñeca},[/i] I've only barely deigned to come to St. Louis."
				#"Do you hate everyone who is not beautiful?"
					"Of course I do, ${given_name}. Don't you?"
				#"Have you always been this cruel and I simply did not notice before?"
					*set compassion %-5
					*set rios_rapport %-5
					"You may see it as cruel, but to me, I am simply being honest. I have no more time for beings whose existence offends my very eyes."
				#"What's wrong with strawberries?"
					She rolls her eyes at you. "I have no problem with strawberries, ${given_name}. I have a problem with strawberry-pickers."

		*elseif heard_of_maffi = false
			*set heard_of_maffi true
			"Haiti's protector manages to hold on to her position, despite efforts to the contrary."
			
			"Haiti's protector?"
			
			"Yes, a woman by the name of Thérèse Maffi. She deposed the old Governor of Cap—Français yet refuses to claim the title for herself—and prevents any other from claiming the same. Consul Stone is somewhat at a loss as to what he should do about her."
			
			"How do you mean?"
			
			"She murdered a Governor loyal to Adonis decades before Stone slew Miele. She espouses ideals of freedom and equality. Yet she refuses to submit to his leadership."
			
			"Does Stone espouse ideals of freedom and equality?"
			
			Rios sniffs. "Freedom from Adonis, yes."
		*elseif heard_of_lefferts = false
			*set heard_of_lefferts true
			*set gould_plot 3
			"You have heard that Jay Gould has become one of us, yes?"
			
			"No?"
			
			"Edwin Lefferts, a young vampire from New York, has given him this cursed gift."
			
			"That sounds…dangerous."
			
			"I couldn't agree more, ${mr} ${surname}. I'm surprised your Quaestor has not put both of them down."
			
			"Are they here?"
			
			"I would be very surprised if they did not show their faces."
			
			You purse your lips as you consider what this means.
		*else
			*set heard_of_page true
			*set heard_of_clarkson true
			"The question of the moment, as I understand it, is what is to be done about New York."
			
			"How do you mean?"
			
			"Currently, New York is projected to surpass Philadelphia is size. It is already the center of finance and trade in this country. It belongs to Townsend's province, but for how long? How long will Harold Page and Moro Clarkson submit to him?"
			
			"Will Stone intervene?"
			
			"Presumably. I'm sure Page would not want to swear fealty to Adonis, and declaring himself Governor without Stone's approval would…well, it is simply not done."
			
			"I see."
		*goto rios_convo
	*if ((knows_about_silver = false) and (west_prob = false)) #"If you were going to try and confront West, how would you do it?"
		*if heresy_of_abraham > 0
			*set rios_time -1
			*set knows_about_silver true
			"I have heard it said that, as we lose our connection to our humanity and succumb to the beast, we become vulnerable to silver."

			"What?"

			"I know it sounds ridiculous, but there are rumors of such. We Children must prepare to defend ourselves from those who have fallen away from the Word."

			"Have you ever tested those rumors? Or know anyone that has?"

			"That would require having a Beast to test them on."

			"I see your point."

			"Do you mean to confront West?"

			*choice
				#"I do."
					*set rios_rapport %+5
					"Then I shall pray for you, @{male brother|sister}," she says.

					"Thank you."
				#"No."
					*set independence %-10
					*if stlouis_tribune
						"Memeskia will be displeased; is that not the obligation of your office?"

						"Staying alive is more important to me than my office."

						"I can see that."
					*else
						"I cannot judge you for a decision that I myself would make."
				#"I intend to be prepared, in case he confronts me."
					"A wise strategy," she replies.
		*else
			"I wouldn't be so foolish," she replies simply. It does not appear as though she wishes to elaborate.
		*goto rios_convo
	*if more_about_abraham
		*if (heresy_of_abraham > 0) #"Should we not greet each other more formally?"
			*set rios_rapport %+5
			Rios takes stock of your surroundings. The people, the buildings, the crates, and the animals are all potential sources of danger when heresy is being discussed.
			
			Satisfied, a small smile spreads across Rios's face. She offers the signs of inquiry, and you respond with the signs of acknowledgement.
			
			"It is good to see that you have not forgotten the Children."
			
			*if heresy_of_abraham = 1
				"How could I? I have burned with anticipation since you promised me the truth of our kind."
				
				"I am glad to see it."
				*goto more_about_abraham
			*bug not currently possible to have heresy_of_abraham > 1
			*goto rios_convo
		*if (heresy_of_abraham = 1) #"Before we parted ways in New Orleans, you promised me the truth of our kind."
			"So I did."
			*label more_about_abraham
			*set heresy_of_abraham +1
			*set more_about_abraham false
			
			"I wish I had more concrete to tell you. We are all seekers of the truth."
			
			"Then tell me what you know!"
			
			Rios sighs. "We Children have discovered that Elohim, the Lord God, Allah—however you address Him—created our kind, and left record of it in the holy texts of those three faiths. In fact, those texts serve as guides to our kind, if we can only decipher their meaning."
			
			*if religious_tradition != "pagan"
				"@{(rationalism > 60) Our Lord in Heaven|The Chrisitan god} created our kind?"
				
				"@{(rationalism > 60) He is not only our Lord|The Christian…he's not just the Christian God}! That's the whole point: he's the God of all the faiths of Abraham!"
				
				@{((rationalism > 50) or (lore <= 1)) |You decide to let that particular theological question go unremarked. }"And he willed vampires into being?"
				
				"In the Bible, we read the story of the binding of Isaac, where Abraham was instructed to sacrifice his only legitimate son on an altar. Did you really think that was about an old shepherd and his illiterate son? No!"
				
				"But…how do you mean?"
				
			*if religious_tradition = "pagan"
				"You believe that your god created our kind?"
				
				"Yes. There is a story in our holy texts known as the Binding of Isaac, where a shepherd is told by an angel to take his only son atop a high mountain and sacrifice him. But the texts say that before the blow could fall, the angel once again called out, and stopped Abraham from the murder. Instead, a ram appeared, and Abraham sacrificed that, and the father and son were in turn promised prosperity and fertility unto the end of time."
				
				You look at Rios askance. Then again, you often find yourself looking askance at the colonists when they discuss their peculiar faith. "An old man imagines a voice in his head telling him to murder his only son, gets distracted by a ram when the moment arrives, and decides that this all means that he is blessed by your god?"
				
				"I do not expect a heathen such as yourself to treat the mysteries of the civilization with respect," Rios sniffs.
				*set rios_rapport %-5
				
				You resist the urge to roll your eyes. Here she is explaining the core points of a heretical socity, and she has the temerity to call you a heathen. You decide to humor her for the moment. She, on the other hand, steels herself for the next part.
			"Many seek the answers to our kind in the early stories of humanity: Cain and his mark, Lilith and her demons, Osiris and his resurrection…but those are all mistaken. No, the moment of revelation—the moment of creation—is when Abraham murdered his son in the name of the Lord.
					
			"And that is how we came to be?"
			
			"Not exactly."
			
			"Please, continue."
			*page_break
			
			"There was no ram. Abraham simply failed in his duty. See, in the Qu'ran, the Mohammedans believe that Abraham sought to sacrifice his elder, illigimate son, Ishmael. The theolgians of the three faiths have argued for centuries about which son was bound and then saved. What the mortals don't realize is that Abraham did this twice. When he failed to sacrifice Isaac, he left his family and went south into Arabia, where he had sent Ishmael and his mother Hagar. Ishmael had grown up there among the tribes and made his own family. He received his father with grace, and when he was told what God had commanded, he agreed to be sacrificed.
			
			"They set out to climb a mountain, whereupon they met bandits. The bandits asked what the two were doing, and Abraham said that he was going to the mountain to make a great sacrifice. The bandits did not understand, but they took the only thing of value that the two had: the sacrificial knife. Having already failed the Lord God once, however, Abraham pressed on, determined not to fail again.
			
			"Once they had climbed the mountain, they built an altar. But there was no knife for the sacrifice, so Ishmael took a piece of wood and carved it with stone into a stake and gave it to his father, commanding him to fulfill the words of Adonai.
			
			"With tears in his eyes, Abraham watched as Ishmael lay himself upon the altar. Finally, father plunged the stake into the heart of his eldest son, and watched as the coppery blood drained away. 
			*comment He lit the pyre, but at the last moment pulled the stake from his son's chest, that he might go whole into the afterlife. And when he pulled that stake out, Ishmael's eyes opened, and seeing himself on a funeral pyre, he lept off.
			
			"Little did Abraham realize that the bandits had been watching all this time. When they showed themselves to mock him for the murder of his son, threatening to send him to join Ishmael, Abraham drew the stake from his son's chest, as it was the only weapon at hand.
			
			"Dutiful Ishmael then rose from the altar to defend his father. He drank the blood of the bandits. And so the first of our kind rose from the dead and fed upon the living."		
			
			"And why must we keep all this a secret?"
			
			"Adonis has his own ideas about our origins. And, truth be told, the very question of an origin is fraught. He forbid their discussion as being a source of discord within the Society."
			
			"But, if this is the truth, we should spread word of it."
			
			"We do. When we can. With eternity at stake, trust is a rare commodity."
			
			"What of Ishmael, then?"
			
			"How do you mean?"
			
			"Is he still alive? I mean, does he still exist?"
			
			A small smile creases Rios's face. "That is the objective of the Children: to discover the resting-place of Ishmael and revive him."
			
			Your eyes go wide. "Do you have some sense of where that might be?"
			
			"The Great Powers have been seeking for decades—if not centuries—to stabilize the Levant. When our kind can, we go and organize digs in person. Many of the archaeologists who are there now are, in fact, working for us. Whether they realize it or not."
			
			"Are you saying that there are no vampires in the Orient, except those that come from the Great Powers?"
			
			"Hah, no, of course not!"
			
			"Then why do we need the Great Powers as cover?"
			
			"Because of Pharoah, of course."
			
			*return
	*if ((heresy_of_abraham = 0) and (just_met_rios = false)) #"Is this all that there is? Drinking blood and scheming against one another?"
		*set rios_rapport %+5
		"How do you mean, ${given_name}?"
		
		"We exist, that is clear. We watch as mortals grow and organize and evolve. We feed, we indulge our whims…but where does it end? What purpose does it serve?"
		
		*if rios_rapport > 60
			@{(perception > 2) You sense Rios making a decision.|} "There are answers to be had, if you are willing to pursue them."
			*set heresy_of_abraham +1
			*set heretic true
			
			"Go on."
			
			"You must know that to share in these secrets is to risk death as a heretic."
			
			@{(discretion > 50) "I would rather know my purpose than not."|"I am capable of keeping a secret."}
			
			She purses her lips. "There is a collection of individuals who seek the truth of our kind. We call ourselves the Children of Abraham. The Bible tells us something of our history, if you only know how to read it."
			
			"How is it to be read, then?"
			
			"Elohim, Adonai, our Lord God in Heaven…he has done many great and terrible things. Much blood has been split by Him and in His name. If you realize that we are the drinkers of blood, it is not so hard to find moments of sacrifice that are not consonant with the rest of the text."
			
			"I still do not know what you mean."
			
			"That is as it should be. I will watch you, and if you prove true, someone will teach you more. But first, let me show you the signs, so that you may know the others of our circle." With that, Rios shows you the signs of greeting and acknowledgment, signs that are subtle but pointed when made to one who would recognize them. "Of course, you must be careful with our kind. Those who can read minds could pluck the truth out of you if they suspect you of heresy. So be most careful about whom to signal."
			
			"I shall."
			
			"Good. Let us enjoy the fair."
			*return			
		*elseif (rios_rapport > 50) and (heresies_explained = false)
			*set heresies_explained true
			*if perception > 2
				It's just a glimmer, but for a moment you see the distrust in her eyes, before she locks it away because the bounds of protocol.
			"There are…those of our kind who seek the origin of our kind."
			
			"The origin of our kind?"
			
			"Yes. If we know where we came from, perhaps we can discover our purpose. There are many theories."
			
			"Such as?"
			
			"Well, the belief in these theories is…heretical. It is forbidden in the Society. If I did know, to admit such could be a death sentence."
			
			"You do not trust me."
			
			"Should I? Has Stone made his position on this matters clear? Will he break with Adonis here, or will he maintain the injunction?"
			
			@{(revolutionary_credentials > 50) "What did Stone begin his revolution for if not to end these outdated taboos?"|"I am so grateful that Stone has put us all in this precarious position," you retort sarcastically.}
			
			"Whatever the case," she continues, "I certainly know nothing of these heresies, beyond the most basic outlines. Some of the most common revolve around Osiris, Abraham, Lazarus, and Lilith."
			*set heard_of_heresy_of_abraham true
			*set heard_of_heresy_of_osiris true
			*set heard_of_heresy_of_lilith true
			
			"Go on," you urge.
			
			"I wish I could tell you more, but there is nothing left for me to tell."
			
			You grit your teeth in frustration. "Well, if there is nothing else then…"
			*return			
		*else
			*if perception > 2
				It's only the briefest glimmer, but you see the change as Rios makes the decision to lie to you.
			"I wish I could say that I had found some purpose in this world. I suppose that is why I find the blood so fascinating: I always want to know what is underneath a thing. The quest for flavors and experiences not yet known, then, is the closest I can find to such a purpose.
			
			"Whatever it may be, I would recommend that you find your own such purpose. These nights are long, lonely, and full of terrors. Prayer certainly helps, but a purpose such as mine is a small comfort when Satan's messengers rage outside my door."
			
			"Thank you for the advice, Sra. Rios."
			
			"My pleasure, ${mr} ${surname}. Now, I fear it is time for me to go."
			
			"Very well."
			
			And so the two of you part ways: you to your haven and Rios into the night.
			*return
	*if (just_met_rios) #"A cornucopia of blood, you say?"
		*set rios_time -1
		*set rios_rapport %+5
		*set just_met_rios false
		Rios looks at you. "[i]Jajaja,[/i]" she exclaims. "There are so many flavors to be enjoyed. You can truly feel the essence of a mortal's circumstances when you give yourself over to the sensation of the taste."
		
		@{(perception > 1) Reflecting for a moment, you do have some sense as to what she means. When you feed from mortals, you can taste the food that they eat, the work that they do, the smell of their bedding.…|You have no idea what she's talking about.}
		
		"Do you consider yourself an expert in these matters?"
		
		"An expert? No. But an enthusiastic amateur!"
		
		"Who are you most looking forward to feeding from, while you are here?"
		
		Her eyes go wide and she searches the faces of the passers-by for answers. You can sense the thrill of her excitement at the question. "Perhaps…an Esquimau. It is said that during the summer the sun never sets on them. I wonder if I could taste that sun in their blood. If it would warm me through and through once again."
		
		"Do the nights make you as cold as all that?"
		
		She grows serious. "Yes. Yes, they do."
		*goto rios_convo
		
*label becard_at_fair
*if gabriel_status > 1
	*set spoke_becard_fair true
*temp convo_time 3

She is, in fact, watching a basketball game.

The home team is a squad of Sioux girls. They are on loan from the Fort Shaw Indian School in Montana, where they have resided since they were stolen from their parents and forced to learn English and other white skills at a young age. Now model students—they are residing in the Model Indian School that is part of the anthropology exhibit of the fair—they have further distinguished themselves by excelling at this sport, taking the Montana state championship.

Mostly, they have been playing against themselves, but tonight, a team of white girls from North Carolina are here to challenge them for the title of World Champions.

*label becard_convo
*if convo_time = 2
	The basketball game is tied. Both sides are sweaty and beginning to show signs of being winded.
*if convo_time = 1
	The basketball game is going poorly for the Carolinans. They are several points behind and can barely keep up with the Native girls' assault.
*if convo_time = 0
	The game is over; the Sioux girls maintained and extended their lead in the final minutes of the game. 
	
	The audience's reaction is mixed; some celebrate the teamwork and sportsmanship on display; others point out that they have unfair advantages—though the nature of those advantages goes unstated. Still others throw their refuse onto the field in protest. Regardless, the Indian School's title remains intact.
	
	Bécard stands. "They have done it again!" she exclaims.
	
	"Have you come to see them before?"
	
	"Every time they play! To see the settlers defeated at the hands of these young women week after week is one of the few things that makes my time here bearable."
	
	*if ethnicity = "choctaw"
		"I understand."
		
		You think you see a single bloodtear form at the edge of her eye. She quickly wipes it away. "I should go."
		
		"Thank you."
		
		"No, ${given_name}, thank you."
		*return
	*else
		"Are we all your enemies, then?"
		
		*if ethnicity = "african"
			She looks you in your eyes. "No, you are not our enemy."
			
			"I am glad to hear it."
			
			"For now, anyways."
			
			With that, she turns and leaves.
			*return
		*else
			She looks at you sadly. "What else could we be?"
			
			"Friends? Allies?"
			
			"Prison guards?" she retorts.
			
			"I…"
			
			"Until you and your people pack up and go back to Europe, you will never be anything better than prison guards to us. There can be no friendship."
			*if ethnicity = "french"
			
				"But you are part French!" you exclaim.
				
				"Because a Frenchman raped my mother. You and all your kind are a boil that should be lanced and cauterized. We want nothing to do with you."
			
			With that, she turns and leaves.
			*return
*choice
	*if ((gabriel_status > 1) and (becard_gabriel_status = 1)) #"@{gabriel_status ERROR|The Vampire of Cincinnati is dead." No need to mention that ${g_he} was not one of us.|I encountered the Vampire of Cincinnati."|I encountered the Vampire of Cincinnati."|The Vampire of Cincinnati is not a vampire."|I have seen the Vampire of Cincinnati."|Senator Bailey has handled the Vampire of Cincinnati."}
		*set convo_time -1
		*if stlouis_tribune
			*set independence %+5
			*if gabriel_status = 2
				*set becard_rapport %+5
				Bécard looks at you. "I suppose it was your task to complete."
				
				You nod. 
			*elseif gabriel_status = 3
				*set becard_gabriel_status 2
				*set becard_rapport %-5
				"And?"
				
				"He…fought me off."
				
				Bécard looks at you askance. "I see." She sighs. "I suppose someone is going to have to clean up your mess."
			*elseif gabriel_status <= 5
				*set becard_rapport %+10
				*set becard_gabriel_status 5
				Bécard looks at you, surprise on her face. "What do you mean?"
				
				"Not a vampire. Just a charismatic young @{knows_afab woman|man}."
				
				Bécard looks at you, a small smile at the corner of her mouth.
			*elseif gabriel_status = 6
				*set becard_gabriel_status 2
				*set becard_rapport %-20
				"And?" she prompts you further.
				
				"And nothing."
				
				"You didn't confront him?"
				
				"No."
				
				"Why not?"
				
				"I couldn't bring myself to kill him."
				
				"Then why would you seek to become Tribune, ${given_name}?" she spits.
				
				You don't have an answer for that.
			*elseif gabriel_status = 7
				*set becard_rapport %+5
				"I'm glad to hear it."
				
				"$!{g_he} wasn't even a vampire."
				
				That catches Bécard by surprise. "Oh?"
				
				"Not a vampire, no. Just a charismatic young @{knows_afab woman|man}."
				
				Bécard looks at you, a small smile at the corner of her mouth.
			*else
				Gabriel Status: ${gabriel_status}
				*page_break
				*comment 3918
				*bug
		*else
			*if gabriel_status = 2
				*set becard_rapport %+5
				"I suppose I should thank you."
				
				"You're welcome."
				
				"But you are not the Quaestor, nor the Tribune. It is not your place to kill a vampire."
				
				"He wasn't a vampire."
				
				"What?" she exclaims.
				
				"Just a charismatic mortal. And quite tasty."
				
				"If he was just a mortal, why did you kill him?"
				
				"It was…unavoidable," you reply. You have no interest in letting this line of questioning go any further.
			*elseif gabriel_status = 3
				"Oh?"
				
				*if knows_vampire
					"No need to pursue him, however," you note.
					
					"Why not?"
					
					"He wasn't a vampire."
					
					"What?" she exclaims.
					
					"Just a charismatic mortal. Nothing to worry about." Other than the fact that he saw you take a bullet and keep moving.
					
					Bécard looks at you, nods, and accepts you at your word.
				*else
					*set becard_gabriel_status 3
					You proceed to describe to Bécard the manner of Gabriel's hunting. She thanks you; she intends to make use of it.
					
					You make no mention of the gunshot wound you sustained.
			*elseif gabriel_status <= 5
				*set becard_gabriel_status 5
				"Truly?"
				
				"Yes, simply a charismatic mortal. Nothing to concern ourselves with."
				
				She muses a moment. "Except, he draws attention to our kind."
				
				"Or perhaps redirects it?"
				
				She goes silent for a long time, considering.
			*elseif gabriel_status = 6
				*set becard_gabriel_status 3
				*set becard_rapport %+5
				"Oh?"
				
				You spend several minutes explaining what you know of his feeding routine. Bécard thanks you for this intelligence.
			*elseif gabriel_status = 7
				*set becard_rapport %+5
				"I suppose I should thank you."
				
				"You're welcome."
				
				"Who was his dominus?"
				
				"$!{g_he} wasn't a vampire."
				
				"What?" she exclaims.
				
				"Just a charismatic mortal with no regard for the bonds of matrimony."
				
				"I can't blame@{knows_afab …her?…|him }for that," she replies.
			*else
				Gabriel Status: ${gabriel_status}
				*page_break
				*bug
		*goto becard_convo
	*if ((noticed_walker = 2) and (met_herbert_walker <= 2)) #"There's a vampire here that I don't recognize," I note, describing the black man.
		*set heard_of_herbert_walker true
		*set convo_time -1
		Bécard tilts her head as she considers. "I suspect that is Herbert Walker. He belongs to O'Donnell."
		
		*if ethnicity = "african"
			"An unfortunate turn of phrase," you observe.
			
			She shrugs. "It is accurate."
		
		"Have you spoken with him at any length?"
		
		"I can't say that I have. I've only met him once or twice."
		
		*if (revolutionary_credentials > 65) and (stlouis_tribune = false)
			"So you are not disturbed by his presence?"
			
			"Why would I be?"
			
			"Some plot afoot by the Loyalists?"
			
			"I would be surprised if that were the case."
			
			"By definition, yes, you would be," you @{(status + 1) mutter under your breath|mutter|mutter|reply|snap|snap}.
		*goto becard_convo
	*if ((knows_about_silver) and (stlouis_tribune = false)) #"I believe I know how you might have a chance to bring down West."
		*set convo_time -1
		*set told_becard_silver true
		*set becard_rapport %+20
		Bécard shoots you a glance. "Do not raise false hopes, ${given_name}."
		
		"I cannot say for certain if they are true, but it is the best that I can do."
		
		"Spit it out!"
		
		"Silver! I believe that Beasts are vulnerable to silver."
		
		"Silver?"
		
		"Yes. Think of it! The stories of werewolves relate the story of their susceptibility to silver. If the stories of werewolves are a fable to disguise the rampage of Beasts, then I believe that silver might, in fact, be a weapon that we could use against West."
		
		Bécard looks at you cautiously, trying not to let her hopes get away from her. "Thank you, ${given_name}. I hope that you are right."
		
		A silence falls between you.
		*goto becard_convo
	*if (month > 8) #"What did you think of the Anthropology Days and the Special Olympics?"
		*set convo_time -1
		*if (ethnicity = "choctaw") or (ethnicity = "african")
			Bécard looks at you with surprise. Surely you must be jesting?
			
			"It was a disgrace."
			
			"No surprise there. Did you see the fool who was organizing the whole thing?"
			
			"The one running around with a tape measure and his little logbook? Measuring the contestants and noting it all down?"
			
			"Yes, that's the one."
			
			"It would be amusing if it weren't terrifying."
			
			This makes you pause. "Terrifying?"
			
			"That's how it begins. When Europeans start to write things down, the rest of the world laughs at them and their funny ideas…until they die. This was the source of their power: one plus one equals two. X is x and y is y. You do that enough, and you start to pull the heavens down from on high and think that all of nature's bounty is yours to command. And when you command something, you do with it as you like. That little man is seeking the death of everyone that does not look like him."
			
			"Surely you don't think he intends to kill everyone…then who would we drink from?" you say to lighten the mood.
			
			"He may not know where his tape measure leads, but I do. I've seen it, read about it, heard about it. It is not only the logical conclusion to the questions he is asking…it the only conclusion." She pauses. "Look what happened to your people. It began with a funny man and his notebook. Now where is your kin?"
			
			Her words sting.
			*goto becard_convo			
		*else
			"It was a disgrace."
			
			"A disgrace? I thought he was making a fool of himself with his tape measure and his little book of notes."
			
			"An undertaker must measure you before he can build your casket."
			
			That stops you short. "I'm afraid I don't understand what you mean."
			
			"That's alright. Perhaps someday you will."
			*goto becard_convo
	*if (stlouis_tribune = false) #"How goes your duties? Any sign of West?"
		*set convo_time -1
		"He is close. I can feel it. I think the number of our kind who are visiting the Fair has pushed him awake. Now it is only a matter of time before he strikes again."
		
		"You are counting on him killing one of us?"
		
		"He must be drawn out. I know of no other way to bring down a creature such as him."
		
		"What will we use as bait?"
		
		"Don't you mean, whom will we use?"
		
		"Yes…I suppose I do."
		
		"Let us say…I don't intend to use a single individual. But this Exposition will be a great draw for him. Just as millions of humans will come, so too will dozens of our kind. He will be drawn to the blood of our kind. I am sure of it."
		
		"We just hope to…bring him down before anyone dies."
		
		"Yes," she says, unconvincingly.
		
		"Should we…warn our guests about this danger?"
		
		"They already know. And if they don't, they are not members of the Society, and not under its protection.@{(ethnicity = "choctaw")  Besides, they're colonists; what do you or I care about another colonist vampire meeting their second demise?|}"
		
		"I hope he does not catch my scent." @{west_prob Not that he could of course. But whoever is impersonating him, perhaps?|}
		
		@{m_sib "I'm sure he already has|"Try not to think about it}."
		*goto becard_convo
	#"Why did you want to be tribune?"
		*set convo_time -1
		*set becard_rapport %+5
		"I didn't. Not really." She sighs.
		*if stlouis_tribune = false
		
			"And yet you succeeded. Admirably."
			
			She scowls at you.
		"Forgive me if I am less sanguine on the matter."
		
		"You didn't want to hunt young vampires and stake them out to greet the sun?"
		
		"Well, yes, in fact, I did. But that meant being here for an extended period of time, surrounded by all these settlers. @{(stlouis_tribune = false) It makes my skin crawl|But thankfully, you defeated me}."
		
		@{(stlouis_tribune = false) You nod; she has always looked uncomfortable in the city.|"Glad to be of service," you quip.}
		*goto becard_convo
	*if ((stlouis_tribune = false) and (gould_plot = 4)) #"Are you concerned about Lefferts and Gould being at the fair?"
		*set convo_time -1
		*set independence %+5
		*set discretion %-5
		*set becard_rapport %+15
		*set becard_hunts_gould true
		Bécard tilts her head. "Pardon?"
		
		You carefully point out the presence of Gould and Lefferts. You suspect that Bécard will have to verify with Memeskia before acting.
		*goto becard_convo
	#"Did you ever meet West?"
		*set convo_time -1
		"I did. Briefly. He came north once, during the war."
		
		"The Revolution?"
		
		"No, the war with the French."
		
		*if ethnicity = "choctaw"
			"There are so many between the colonists. It's hard to keep track of them."
			
			"It's too bad they didn't kill more of each other."
		*else
			"The French and Indian War?"
			
			"That's what the colonists call it, yes."
		
		"What was he doing there?"
		
		"Killing."
		
		That stops you short.
		*if m_sib and ((patricide = false) and (fled_from_sire = false))
			You spent some time traveling in northern Mexico during their War of Independence. You saw West kill. You have seen his ferocity. But those were small engagements—raids, skirmishes, the occasional ambush of one band of desperados by another. What would he do—could he do—on a true battlefield?
		"I see." You pause. "It was not a social call."
		
		Is that a smile? "No, most certainly not. He and Memeskia barely even spoke. Memeskia has few words for any of the colonists, and West…West seemed to have almost forgotten how to speak."
		
		*if (m_sib and (patricide = false)) and (fled_from_sire = false)
			"I spent eight years ranging with him in northern Mexico. I know exactly of what you speak." You pause.
		"I suspect he has not grown more loquacious in the meantime."
		
		"No, I suspect not."		
		*goto becard_convo
	#I ask if she would care to feed together.
		*gosub get_t_prey
		*if becard_rapport > 70
			She smiles a wicked smile at you. "I thought you'd never ask."
			
			*gosub becard_hunt_gosub
			At the same moment, Bécard sinks her fangs into the inside of his elbow and drinks. You can feel your heart stir. You grab her by her hair, and hold her to his arm, feeling her blood course through her corpse as well. Too soon, the ${t_prey}'s heart begins to falter. You release Bécard's hair, and you lick the wounds you caused.
			
			Bécard's eyes flash in the electric lights. She wipes her mouth. "That was…unexpected."
			
			"Perhaps I was a bit too forward…"
			
			"No. It was…stimulating. But now I must go."
			
			"So soon?"
			
			"I'm afraid so. You'll take care of ${t_prey_him}?" she says, gesturing towards the ${t_prey}.
			
			"Yes."
			
			With that, the two of you embrace—longer than you were anticipating—and she leaves you to your own devices.
			
			You watch the end of the basketball game; the Sioux girls trounce the Carolinians. The crowd has a mixed reaction at best—several pieces of food are thrown at the victors. The Sioux girls keep their heads held high as they shake hands with the Carolinians and then quit the field.
			*return
		*elseif (status > 2) or (stlouis_tribune)
			*set becard_rapport %+5
			@{(perception > 2) Bécard smothers her reticence.|} "Yes, let us."
			
			*gosub becard_hunt_gosub
			Bécard waits for you to finish, and at your sign, consumes what you have left for her.
			
			When you are finished, you leave the ${t_prey_man} propped up against a wall, breathing heavily.
			
			Before parting ways, you bid Bécard a good-day. She nods and makes her own way home.
			*return
		*else
			"No, thank you."
			
			"Are you sure, we could…"
			
			"No, that's alright. If you'll excuse me, I have some other matters to attend to."
			
			"Yes, of course."
			
			"Good-day to you, ${mr} ${surname}."
			
			With that, she leaves you to your own devices.
			*return
		
		*label becard_hunt_gosub
		*set convo_time -1
		The two of you wander the fair until you set eyes on ${t_prey}; you stalk the ${t_prey} through the crowds. $!{t_prey_he} senses the danger, but cannot perceive its direction. $!{t_prey_he} begins moving through the crowd, seeking safety while yet surrounded by people. That is ${t_prey_his} mistake: thinking that the danger comes from the crowd. No, the crowd is safety.
			
		In a flash, you and Bécard have the ${t_prey_man} cornered in the alley behind the Pike. Your fangs flash and within moments you are drinking from his throat.
		*return
	*if (watching_james and (carothers_ford_reveal = false)) #"Did you have a hand in Crittenden's bounty on Jesse James?"
		*set convo_time -1
		Bécard looks at you carefully. "Did I? No."
		
		"But you know something about the whole thing?"
		
		*if becard_rapport > 50
			"You could say that, yes."
			
			"And do I have to wheedle—"
			
			"No. [i]Voilà[/i]…Charlie Ford and his suicide? Because he was tubercular?"
			
			"Yes, it was in all the papers."
			
			"He wasn't tubercular. Bob would have likely have caught it too, if that were the case. No, Charlie committed suicide alright, but not because he was dying. It was the guilt."
			
			"The guilt?"
			
			"Betraying your friend like that? And doing so at the behest of one of our kind?"
			
			"One of our kind?"
			
			"Yes. Your former Quaestor, Carothers. I believe he put Charlie up to it."
			*set carothers_ford_reveal true
			
			"Why would he…"
			
			"Don't be so dense, ${given_name}."
			
			"You're saying Carothers wanted to take out an icon of the Confederate resistance. But isn't Kansas City a bit out of his domain?"
			
			"Sometimes a task must be completed regardless of where that is."
			*goto becard_convo
		*else
			"I know that Charles Ford did not suffer from tuberculosis."
			
			"What? How do you know that?"
			
			"I have it on good authority."
			
			"He was murdered, then? And someone covered it up?"
			
			"I leave that to you to uncover, ${mr} ${surname}."
			*goto becard_convo
	*if (becard_aliens > 1) #"You said something before about our kind coming from the sky?"
		*set convo_time -1
		*set discretion %+5
		Bécard looks over both shoulders. The bleachers here are mostly empty, and those mortals nearby are watching the game intently.
		
		"Yes, I did."
		
		"I…wondered if you could elaborate. I'm interested in the origin of our kind as well."
		
		Bécard, clearly hesistant, leans closer. "I believe that we come from beyond this world."
		
		"Like, the moon?"
		
		"I…they say the moon is so close. Maybe Mars? I don't know. But from the sky, yes."
		
		You search for any sign that she might be jesting, but you can detect none. "And our kind…came from the sky?"
		
		"Yes. Mortals learned to sail the seas centuries ago, why is it impossible to believe that others learned out to sail the skies?"
		
		"But…"
		
		"There are stories of beings arriving in skyboats throughout the Americas. I think those beings were vampires."
		
		"Then…we are…space creatures?"
		
		"I think there is some spirit that is communicated when one of our kind is made, yes. That spirit is from the skies, yes."
		
		*if intelligence > 2
			*set becard_rapport %+5
			"Were the beings in skyboats similarly possessed by this spirit? Or were they somehow the spirit in tangible form?"
			
			She blinks. "I don't know. I hadn't thought of that before."
			
		"And do you think they will return someday?"
		
		"I do…and that is why we are able to continue existing indefinitely. We await their return."
		
		"I certainly had not considered such a possibility."
		
		"Few have. I do not trust many with these ideas. I fear they would think me mad."
		
		"I suppose…if we exist, then why should beings not live in the @{(rationalism > 50) heavens|sky}?"
		
		"Exactly!" she exclaims.
		*goto becard_convo		

*label herbert_walker_at_fair
*temp convo_time 0
*temp walker_hospitality false
*if ethnicity = "african"
	*set walker_rapport %+10

"Hello," you begin.

The man is startled. He is well-dressed; his white cuffs and collar accentuate the darkness of his skin. "Can I help you?" he replies.

"I am ${given_name} @{stlouis_tribune ${surname}, Tribune of St. Louis.|${surname}}."

*if met_herbert_walker = 2
	*if trans
		"I could swear that I have met you before."
		
		Your brow furrows. You have met many people in your decades of unlife. "I'm sorry.…"
		
		"Did you…are you…used to be…"
		
		"Oh! Yes. I used to be ${original_name} ${original_surname}, but I think ${given_name} ${surname} suits me much better." You find it best to brush past these moments of reorientation; no reason to put an interlocutor on the spot for being slow on the uptake.
		
		"I…you…saved me."
		
		"I'm sorry?"
		
		"In Vicksburg. You put me on a skiff and sent me across the river when I killed my foreman. I saw you take a bayonet in the gut."
		
		"So I did," you reply, astounded. "Herbet Walker," the name comes to you. The
	*else
		The man is clearly stunned. "Yes, we've…we've met before."
		
		Your brow furrows. You have met many people in your decades of unlife. "I'm sorry.…"
		
		"You helped me escape from Vicksburg. I killed my foreman. I saw you take a bayonet in the gut."
		
		Of course. Herbert Walker, the young
	boy with the bloody spike. "You were just a skinny beanpole when I put you on that skiff. Life has been eventful, I see."
	
	"Thanks to you."
*elseif met_herbert_walker = 1
	*if stlouis_tribune
		*set walker_hospitality true
		"An honor, ${sir}. I am Herbert Walker."
		
		"Where are you from, Mr. Walker?"
		
		"Chicago."
		
		"And you will respect the Three Rules while you are here?"
		
		"Of course."
		
		"Quaestor Memeskia will likely be holding a court soon. You should attend if you can."
		
		"Thank you for informing me."
	*else
		"I am Herbert Walker."
		
		"I haven't seen you in St. Louis before."
		
		"I live in Chicago."
		
		@{(independence > 40) "Welcome, then."|"That makes sense."}

*temp convo_time 0
*label walker_convo
*if (convo_time = 1) and ((stlouis_tribune) and (walker_hospitality = false))
	
	"If I may, you have observed the Rule of Respect, yes?"
	
	"Of course. I called on the Southern Hotel and Quaestor Memeskia granted it to me."
	
	"I am glad to hear it. Now, if you will…"
*if convo_time = 3
	*set met_herbert_walker +2
	
	The night has grown late. Walker bids you goodnight and continues on his way.
	*return
*choice
	*if met_herbert_walker = 2
		#"Tell me, what happened after you fled Vicksburg?"
			*set convo_time +1
			*achieve all_grown_up
			"That night, I rowed to the gunships. They welcomed me aboard and fed me. Then I was sent to the care of the African Brigade.
			
			"The brigade had just won the Battle of Milliken's Bend, and was in dire need of reinforcements. I didn't know one end of a musket from another, but I could dig and I could cook. I signed up that morning as a laborer for that unit.
			
			"I never forgot what you did for me that night, though. I wondered how you killed that guard, when he had stuck you with his bayonet. It made me ask questions…questions I probably shouldn't have been asking.
			
			"After the war was over, I settled in Chicago. I worked there for a while. I suppose I asked too many questions, because eventually I met Quaestor O'Donnell."
			*set heard_of_odonnell true
			
			"And so you became one of us?"
			
			"I did." @{debt_from_walker Perhaps that debt he owes you will turn out to be of some value after all.|}
			
			"It was not what I intended when I helped you that night, but I suppose it is somewhat appropriate."
			
			"It is what it is, ${mr} ${surname}."
			*goto walker_convo
	*if met_herbert_walker = 1
		#"Where are you from?"
			*set convo_time +1
			"During my mortal life, I was a slave on a plantation outside of Vicksburg. During the siege, we were all sequestered in the city. Then, one night, a white man with a funny accent helped me escape the city on a skiff."
			
			*if calkins_status > 2
				"What do you mean by funny accent?"
				
				"As I later learned, he was a Quaker. He used Plain Speech. All those old 'thees' and 'thous.'"
				*label id_calkins
				
				"Andrew Calkins saved you."
				
				"You know the man?"
				
				"The vampire. Yes." @{(calkins_status > 3) Knew him, anyway. You did kill him.|}
				
				"A vampire? That certainly explains some things. Things I…I saw that night. It made me ask questions. They must have been the right questions, as I eventually met Quaestor O'Donnell."
				*set heard_of_odonnell true
				
				"And the Quaestor made you as you are?"
				
				"He did."
			*elseif calkins_status = 2
				"Did he have blue eyes and a rounded beard?"
				
				"He did."
				*goto id_calkins
			*elseif calkins_status = 1
				"How peculiar. I was there in Vicksburg during the siege."
				
				"You were?"
				
				"Well, under it. When the Union began to encircle the city, I had myself buried deep underground. I slept through the battle…the rest of the war, really."
				*set walker_rapport %-15
				
				"You missed much misery."
				
				"Yes…feeding in that mess would have been miserable."
			*goto walker_convo
	*if (heard_of_odonnell) #"What can you tell me of Quaestor O'Donnell?"
		*set convo_time +1
		*set independence %+10
		"He is old. And…particular."
		
		"Set in his ways?"
		
		"Yes."
		
		"Have you met Quaestor Memeskia?"
		
		"No, I have not."
		
		*if discretion > 55
			*set walker_rapport %+5
			"Perhaps they are brothers."
			
			You sense the slightest hint of a smile. "Brothers from another mother, perhaps?" he rejoins.
		*else
			"You should, especially if you intend to stay for a while."
			
			"I shall consider it."
		*goto walker_convo
	*if (month > 10) #"Yates is dead. Does this mean…war?"
		*set convo_time +1
		*set walker_rapport %+5
		"Are you saying Quaestor Memeskia arranged for West to kill my broodmate?"
		
		"Certainly not."
		
		"While this certainly lowers Memeskia in the eyes of my dominus, I don't see war as the likely outcome."
		
		"But not impossible?"
		
		Walker shakes his head. "Perhaps, but O'Donnell is no fool. While he may find a sympathetic ear in Quaestor Harding, he is functionally surrounded."
		
		"I wonder if that was the true purpose of Björnsdotter's appointment; to surround Chicago."
		
		"Perhaps. He could always leave, I suppose. But he has been Quaestor there for nearly one hundred years; it will be difficult to dislodge him."
		
		"And will you defend him?" you ask.
		
		"I don't really have a choice, do I?"
		
		*if revolutionary_credentials > 40
			"Of course you have a choice, Herbert. @{(met_herbert_walker = 4) I could have left you to die in Vicksburg, but I didn't.|} You don't have to fight for him."
			
			Herbert grunts. "We'll see about that."
		*else
			"No, not if Stone's revolution is to be undone."
			
			"It's good to know where you stand."
			
			You incline your head.
		
		"Besides, I would think that Memeskia would be more concerned about defending himself, than going on the offense."
		
		"How do you mean?"
		
		"He has this Beast in his domain, and he has let at least two guests be extinguished. I would think that, if anyone were surrounded, it was he."
		
		You had not considered this particular angle.
		*return
	#"Have you heard of the Vampire of Cincinnati?"
		*set convo_time +1
		*temp mentioned_d false
		Walker smiles. "Yes. Quaestor O'Donnell is quite bemused that Stone's Society has been so unable to handle such a figure."
		
		*if month > 9	
			"In fact, ${g_he} has been dealt with. $!{g_he} wasn't even a vampire, in fact."
			
			"Oh? But all the news reports?"
			
			*if knows_afab and (justice < 40)
				"It was white Protestant hysteria over women and their bodies. Nothing more."
				
				"I am quite familiar with that hysteria," Walker nods.
			*else
				*set mentioned_d true
				"It was [i]Dracula[/i]-induced hysteria. Nothing more."
				
				"That book will be the death of us," Walker curses.
			*if (gabriel_status = 4) or (gabriel_status = 2)
				"Who handled the matter?"
				*set walker_rapport %+5
				
				"I did," you reply, preening just a bit.
				
				"Well done, ${mr} ${surname}," he replies. Then a cloud comes over his face.
			"Regardless, the news story was a threat to all of us."
			
		*choice
			#"Stone's revolution is inherently flawed. Its membership cannot handle even small matters such as this."
				*set revolutionary_credentials %-5
				*set odonnell_rapport %+5
				You're surprised by Walker's equivocal response. "I suppose you could say that," he replies. "Though, I'm not sure what's different from Adonis's rule."
			*if (mentioned_d) #"This was all the fault of the Governor of London. The Society there never should have allowed this book to be published."
				*set revolutionary_credentials %+3
				*set independence %+3
				Walker clenches his jaw. "If there's one thing I've learned in the past fifty years, it's that we vampires are not nearly as omnipotent as we like to think ourselves to be."
			#"It @{(month > 9) was|will be} handled in due time. Trust in the Governor and her Quaestors."
				*set independence %+5
				Walker huffs. "I trust no one."
			*if (stlouis_tribune = false) #"It is all of our responsibility to enforce the Rule of Reserve—regardless of our loyalties."
				*set independence %-5
				Walker huffs. "That's a position that's hard to argue with."
				
		*goto walker_convo

*label fragala_at_fair
*set spoke_stl_fragala true
*temp knows_quae_kc false
*temp knows_leper false
*temp hand false
*if met_fragala
	*set knows_leper true
	"Quaestor Fragalà," you begin. "It has been some years."
	
	He turns to face you. Time has not improved his horrific visage.
	*if trans
		He squints and, after a moment, nods. "It has. Have you…adopted a new name?"
		
		"${given_name} ${surname}, in fact."
		
		"And so we met anew."
	*else
		"It has."
*else
	*set knows_quae_kc true
	*if ((afflicted_vicksburg and (compassion < 50)) and (intelligence > 2))
		*set hand true
	You approach the leper. "${mr} ${surname}, a pleasure to finally meet you," he says at your approach.
	
	*if heard_of_fragala
		*if hand
			*set fragala_rapport %+5
		"Quaestor Fragalà, I presume?" @{hand you say, extending your hand.|}
		
		"Guilty as charged," he replies@{hand , taking your hand in his. After a moment, he gives it a strong shake, as though he has not done that in a long while|}.
		
		"Welcome to St. Louis."
		
		"Thank you."
	*else
		*set heard_of_fragala true
		"I'm afraid you have me at a disadvantage, sir."
		
		"Calogero Fragalà, Quaestor of Kansas City."
		
		"Quaestor? Of Kansas City?"
		
		"The one and only," he replies.
		
		*if hand and (discretion > 50)
			*set fragala_rapport %+5
			On an impulse, you extend your hand in greeting. He looks at it, surprised. After only a moment's hesitation, however, he grasps it in his own and shakes it firmly.

The two of you take a seat at a table outside of the Italian pavilion. The waiters come and bring you 
*if perception <= 1
	espresso. You push the demitasse aside, as it offers nothing to you.
*else
	espresso, which you delight in smelling. You are, of course, familiar with the smell of coffee, but this is more intense. The smell hits the back of your sinuses rather than the back of your throat.
	*set anachronism %+3
*temp convo_time 0
*temp knows_palermo false
*temp knows_fra_rev false
*temp hubris_of_vampires false
*temp tick1 true
*temp tick2 true
*label fragala_loop
*if (convo_time = 1) and tick1
	*set tick1 false
	*if hand
		"Why are you not afraid to touch me?" he asks.
		
		"I have had some experience with diseases and how they affect our kind. I surmised that I had nothing to fear from you. Was I wrong?"
		
		"No, you were not." He considers a moment.
	*if (gould_plot < 3) and (debt_to_fragala = false)
		"What do you think of Mr. Gould?"
		
		"Mr. Gould?"
		
		"Jay Gould."
		
		"The railroad tycoon, who died a decade ago?"
		
		Fragalà's eyes go wide. "You don't know?"
		
		"Know what?"
		
		"Information is not free, my friend. Will you owe me a debt?"
		*choice
			#"Yes, what is it?"
				*set debt_to_fragala true
				*set independence %+5
				*set gould_plot 4
				*set heard_of_lefferts true
				*set heard_of_malloy true
				*set heard_of_ogier true
				"Edwin Lefferts, the scion of Arnoult Ogier the Huguenot and broodmate to Siobhan Malloy, turned the tycoon Jay Gould into a vampire."
				
				"That seems unwise."
				
				"So it is. He is a walking, talking violation of the Rule of Reserve."
				
				"And has no one done anything about this?"
				
				"Not yet."
				
				"And what would you have me do?"
				
				"I would have you do nothing. But the two of them are here at the Exposition, and neither of them have presented themselves before Quaestor Memeskia in observation of the Rule of Respect."
				
				Meaning, both of them @{(compassion < 50) are in danger|are at your mercy}. "Thank you, Quaestor," you reply.
			#"No, thank you."
				*set fragala_rapport %-5
				"Very well," he nods.
				
				The matter closed, you cast about for another topic of conversation.
*if (convo_time = 2) and tick2
	*set tick2 false
	The waiter nears, only to turn away in dismay when he sees that your demitasses remain full.
	*if stlouis_cult_formerly
		
		Fragalà clears his throat. "I'm given to understand you've had a rough go of things lately."
		
		"How do you mean?"
		
		"Come now. You don't really think you can organize a religion and have it go unnoticed by the rest of us?" You stop cold. He continues: "you are fortunate that worse did not befall you. Our entire history is riddled with stories of the hubris of vampires."
		*set hubris_of_vampires true
		
		*if discretion > 60
			You flash your fangs at him. "Why should I not kill you right here?"
			
			The creases around the lesions on his face seem to flare in anger. "Go ahead. See how that works out for you."
			
			After a further moment of preening, you back down.
		"What do you want?"
		
		"A debt. In exchange for my silence in this matter."
		
		"Do I have a choice?"
		
		"I don't believe so, no."
		*set debt_to_fragala true
		
		After a moment's consideration, you nod. The deal is done.
		
*if convo_time >= 3
	*set met_fragala true
	*if egans_rats_plot > 2
	
		"I have something to ask of you, ${mr} ${surname}."
		
		"Do tell."
		
		"@{(egans_rats_plot = 5) Baldy Higgins|Snake Kinney}. He will be a state Senator soon. I understand that you are…acquainted with him."
		*if egans_rats_plot = 5
			*set stl_kinney "Higgins"
		
		You glance around. "Yes, he will. And yes, I am."
		
		"If you could arrange a meeting with him, that would be appreciated. There are certain mutually beneficial affairs related to my city."
		
		*if debt_to_fragala
			"Would this satisfy the debt that is owed to you?"
			
			"Why yes, yes it would, ${mr} ${surname}."
			
			"Then it will be so."
		*else
			"Of course, Quaestor."
		*set egans_rats_plot 6
	
	"Now, if you'll excuse me, the night grows late," he finishes.
	
	"So it does. A pleasure."
	
	Fragalà nods. The espresso has long since grown cold. You stand and leave him to his still-full cup.
	*return
*comment TODO have a way for the PC to learn that Harding was behind Carothers's embarrassment during the caucuses from Fragala?
*comment 13
*choice
	*if ((hre_theory = false) and knows_palermo) #"Did you ever meet Adonis or Praetor Miele while you were in Sicily?"
		*set convo_time +1
		*set independence %+3
		*set hre_theory true
		*set heard_of_heresy_of_lazarus true
		"Miele? Yes. He came to Naples once. He was a cruel vampire."
		
		"Oh?"
		
		"I witnessed his interrogation of a heretic."
		
		"You mean torture."
		
		"Yes. He found a Lazarene and was determined to uncover her accomplices."
		
		"Did he succeed?"
		
		"Yes."
		
		"Pardon my ignorance, but what is a Lazarene?"
		
		"You've heard the story of Jesus resurrecting Lazarus, yes?"
		
		*if (intelligence > 1) or priest
			"Of course."
			
			"They believe that when Jesus resurrected Lazarus, he in fact made him into a vampire."
		*else
			"No…"
			
			Fragalà looks at you in surprise. "In the Gospel of John, chapter 11, it is said that a respected man—Lazarus—died, while waiting for Jesus to come and heal him. Jesus, in fact, waited for the man to die before coming to town. Arriving at the tomb, four days after the man's death, Jesus ordered the man to 'come forth!' and he did."
			
			"He brought a man back to life?"
			
			"Did he? Or did he make him a vampire?"
			
		"You're saying Jesus was a vampire?"
		
		"I never met the man."
		
		"The Lazarenes, then…they say that Jesus was a vampire?"
		
		"I've never met a Lazarene."
		
		"Other than the one that you saw tortured?"
		
		"I didn't know she was a Lazarene at the time."
		
		You growl at Fragalà's obfuscations. "What do you know, then?"
		
		"I know that a heresy revolving around Lazarus exists, and that it involves Lazarus rising from the dead. The rest I must leave to your conjecture."
		
		"So why do you think that Miele was sent here?" you say, trying to return the conversation to your original question.
		
		"As punishment, surely."
		
		"Punishment? What did the vampires of the New World do to deserve him?"
		
		"They destroyed the Roman Empire."
		
		You frown. "The Roman Empire fell a thousand years before America was colonized."
		
		"The Holy Roman Empire was vanquished in 1806. Which was the heir to the Roman Empire, which was the heir to the Republic, which was the heir to the Roman kings."
		
		"I still don't see what that has to do—"
		
		"Napoléon Bonaparte sold Louisiana to President Thomas Jefferson in 1803. He used that money to finance his conquest of Europe. Now you have a Fair," he says, gesturing to the extravagance around you, "and a two-thousand year old polity, beloved by numerous older vampires, is gone."
		
		You stop. "Is that…that can't be…"
		
		Fragalà shrugs. "It's just a thought I had."
		
		You fall silent as you try to weave what you know of vampiric rumor with the ebb and flow of human history.
	*if ((met_fragala = false) or (heard_of_dinapoli = false)) #"@{met_fragala Do you miss Sicily?|Where are you from?}"
		*set fragala_rapport %+5
		*set knows_palermo true
		*if met_fragala
			"Yes, very much so."
			
			"Was there a particular city…?"
			
			"Palermo. Perhaps you've heard of it?"
		*else
			"Palermo. It's a city on the island of Sicily. Perhaps you've heard of it?"
		
		"@{intelligence No.|Perhaps?|Yes, of course.|Yes. It was unfortunate for Palermo when Sicily was merged with Naples.|Yes. It was unfortunate for Palermo when Sicily was merged with Naples.}"
		
		@{(intelligence > 3) He nods in agreement.|} "It was my home for decades, but I relocated to Naples as it eclipsed Palermo. Everything is different now. Garibaldi has unified the country to the detriment of Naples and Sicily…and to those vampires who lived there. I have come to these shores in the hopes of new fortunes."
		
		"Was Adonis involved in this?"
		
		"What makes you say that?"
		
		"I would think that a unified Italy would be something to which Adonis aspires."
		
		Fragalà cuts his eyes at you. "You did not hear it from me."
		*if (intelligence > 2) and (revolutionary_credentials > 60)
			*set fragala_rapport %+15
			*set knows_fra_rev true
			
			"Can I assume, then, that you were attracted to Stone's revolution?"
			
			"You may."
			
			"I see."
	*if (knows_palermo and ((intelligence > 2) or (anachronism > 75))) #"What did you do during 1848?" There were numerous revolutions throughout Italy that year.
		*set fragala_rapport %+10
		*set convo_time +1
		*set heard_of_dinapoli true
		"I fled Palermo, in fact. It was the site of the very first revolution."
		
		"Oh? What was it like?"
		
		"The revolutionaries had no idea what they were getting in to. Into this leadership vacuum stepped the local gentry. Had they not been at war with Naples, the transition might have been peaceful. But the island was ill-prepared for a sustained conflict and soon King Ferdinand's armies recaptured the island."
		
		"And you?"
		
		"I was already looking to leave the city of my birth. I had been there for too long already. When it became clear that the revolution was going to fail, I slipped through the blockade and established myself in Naples."
		
		"And were you welcomed there?"
		
		Fragalà smirks. "You could say that. Elena was suspicious of everyone that came to her court, seeing minions of Adonis everywhere."
		
		"Elena?"
		
		"Elena of Naples. One of the oldest vampires that I know of. Other than Adonis, of course."
		
		"Is she the governor?"
		
		"She is."
		
		"And if she is a loyal governor…"
		
		"If she is a loyal governor, she should have nothing to fear from Adonis. Yes, in theory. In practice, one must always be wary of Adonis and his inquisitions."
	*if (knows_leper = false) #@{(discretion > 60) "You have something wrong with your face," you observe.|"Your skin…" I begin, unsure as to how to ask about his condition.}
		*set discretion %+5
		*set knows_leper true
		*set hand false
		"Yes, I have leprosy."
		
		"Is it…communicable?"
		
		"Not to you, no."
		
		"And to mortals?"
		
		"Yes, unfortunately."
	*if (hubris_of_vampires) #"How did you hear about my…organization?"
		*set convo_time +0.5
		*set fragala_rapport %+5
		"I listen. I listen even when people don't realize that they are speaking."
		
		"Do you have a long history of listening?"
		
		"I do. Even when I was alive, it was easy to listen given my condition. It never ceases to astound me what people will say in front of you when they don't consider you to be a person. As a beggar on the streets of Palermo and then Naples, the rich and powerful would pay me no mind while they shared all their secrets."
		
		"And have you kept that tradition alive, once you came to these shores?"
		
		"In a manner of speaking," he replies.		
	*if (hubris_of_vampires) #"You said something about the history of our kind being one of hubris?"
		*set convo_time +0.5
		*set fragala_rapport %+5
		*set knows_sack_of_tyre true
		"So I did."
		
		"Such as?"
		
		Fragalà goes silent as some other patrons of the fair pass by your table on their way into the pavilion. "You have heard of Alexander the Great, I assume?"
		
		*if intelligence > 1
			"Of course."
			
			"Then you know of his conquests. One of those
		*else
			*set fragala_rapport %-15
			"No?"
			
			Fragalà rolls his eyes. "He was a Macedonian prince that had the great philosopher Aristotle as his tutor. He took his father's army and conquered most of the known world by the time he was thirty-three. One of his most 
		audacious victories was when he turned his attentions to Tyre, an island that controlled a vast sea-based empire."
		
		"Audacious how?"
		
		"Since he could not land his ships on the island, he turned the island into a penninsula."
		
		"Excuse me?"
		
		"He moved the earth, building a causeway from the shore in the direction of the island. Eventually, enough earth was moved that he could place siege engines within the range of the island's fortifications. Those who ruled Tyre had never considered the posssiblity that their island could be otherwise."
		
		"Those who ruled Tyre?"
		
		"Yes. Several of our kind. Ancestors of mine, in fact. Or so I was told. But the vampires there, including the Nenet the Ancient and her scions, first among them Muttunbaal the Anointed, thought themselves and their island fortress invincible. That they could live in their fountains of blood without the possibility of consequence.
		
		"They were wrong."
	*if ((knows_leper) and (met_fragala = false)) #"How do you feed without…sharing your affliction?"
		*set hand false
		*set convo_time +1
		*set discretion %+5
		*set fragala_rapport %-5
		*if status <= 2
			"Do you usually ask after the feeding habits of your new acquaintances?"
			
			"I suppose not."
			
			"Then let me be the first to inform you that it is quite rude."
			
			*if discretion > (55 + (bloodflow * 2))
				*set fragala_rapport %-50
				"No more rude than you daring to show your face here."
				
				He looks as though you have slapped him. "Well, it is clear that this conversation is over," he concludes.
				*return
			*else
				"Forgive me, Quaestor."
				
				He accepts your apology with a nod.
		*else
			He looks uncomfortable and shifts his weight to his other foot. "We do not need to drink directly from the source, as I'm sure you're aware."
			
			"I am," you reply.
			
			"I simply have to be discreet about how I draw the blood."
			
			"Clever."
			*if (compassion > 50) and (discretion > 50)
				You consider a moment. "But doesn't it get…boring after a while? Suppressing your nature in that way?"
				
				He shifts again. "Boring isn't the word that I would choose, no."
				
				"Torturous?" you say with a sharp grin.
				
				He doesn't answer.
	#"What do you think of the pavilion?"
		*set convo_time +1
		The mottled flesh on his face jiggles maliciously in response to your question. "[i]Curnutu[/i]. The Italian pavilion. They celebrate Milan, Florence, Genoa, Venice…even Parma. But Naples? Nothing. Palermo? Nothing. Messina? Nothing. The Italian government would prefer that the Neapolitans, Calabrians, and Sicilians would simply die. They want us to work in the fields to grow their food, but to ask for nothing in exchange: no education, no doctors, no political representation."
		
		*if compassion < 50
			"Surely it can't…"
			
			"It is. Believe me."
		
		"So you would not recommend that I wander through it?"
		
		"Oh, I will not stop you from going through its doors. But it is a pavilion of the northern penninsula; it does not acknowledge the south. Much like the pavilions of each of the States: they do not acknowledge the contributions of the Africans whose labor built this country. Or the native tribes that were murdered or expelled in order to make room for those States. No, better to pretend that the land was empty and the crops arise without effort."
		
		"Then why are you here?" you note, gesturing to the pavilion before you.
		
		"The [i]terroir,[/i] of course. Since relocating to these shores, it has been hard to taste the flavors of my youth."
		
		"I see."
	*if (knows_palermo or met_fragala) #"Why Kansas City? What is there for you?"
		*set convo_time +1
		"Many Sicilians have come to these shores in search of a better life. They were brought to the South to compete with or replace negro labor, but when it was discovered that they would not demean their freedmen neighbors, they became suddenly much less attractive as employees.
		
		"And in the cities of the East, New York, Philadelphia, Baltimore, they are at a loss. They are people of the land. They wither and die in factories.
		
		"But in Kansas City, the land is broad. There are many opportunities for the Sicilians to come and make room for themselves."
		
		"To govern themselves?"
		
		"Yes, and to govern themselves. If I have my way, for the first time in centuries they will not live under the thumb of another power."
		
		"Is such an outcome possible? It is not as though you aspire to place a Sicilian in the governor's mansion?"
		
		"No. We learned long ago about the flow of power outside of public channels."
	*if (knows_palermo or met_fragala) #"Have you seen evidence of West in Kansas City?"
		"Yes. He consumed one of my scions, a young person by the name of Roz."
		
		"When was this?"
		
		"Some time ago now. They came to join me in Kansas City after I had established myself there."
		
		@{(compassion < 40) "I'm sorry for your loss."|"He is implacable."}
		
		@{(compassion < 40) "That is kind of you to say."|"So he is."}
		
		*if stlouis_tribune
			*set independence %+5
			"We are, understandably, concerned about his activities."
			
			"As should we all be! I do not intend to be his next meal!"
		*else
			"I hope someone stops him before anyone else falls prey to him."
			
			"As do I."
	*if (pinkerton_trap) #"The strangest thing happened the other evening…" you begin, sharing some of what happened in the warehouse with the tickets.
		*set convo_time +1
		Fragalà nods sagely.
		
		"Jerome Preston the Pinkerton, and Lieutenant General (retired) John H. Cavender. You have earned yourself a pair of enemies, ${mr} ${surname}."
		*set heard_of_jh_cavender true
		*set stl_met_preston true
		
		"What would they want with me?"
		
		"You are an outspoken advocate for the workers of this city. What do you think they want with you?"
		
		"They plotted to kill me?"
		
		"It seems that way. Though, you're lucky…it seems that they do not realize that you are a vampire. They would have come better prepared if they had. Perhaps you should be more circumspect in your dealings with the mortals?"
		
		You nod, considering this new threat.
	*if (stone_in_stl = 2) #"Have you heard a story about Stone fleeing Baltimore, sometime around the 1800?"
		*set convo_time +1
		*set independence %+5
		*set stone_in_stl 3
		Fragalà nods. "I do, in fact. The death of Miele was not his first attempt to break the Society in two."
		
		"Oh?"
		
		"Well, perhaps I am being overly dramatic. But I believe that he did try to displace or perhaps replace Henning Schaap, Quaestor of Baltimore."
		*set heard_of_schaap true
		
		"And what happened?"
		
		"I'm not really certain. He fled west for a time. Then he returned and made peace with the Quaestor."
		
		"How strange!"
		
		"I'm given to understand that some sort of debt was traded—the senators of Vienna and Paris were both involved. But when all was concluded, Stone was welcomed back to the court of Baltimore."
	
		You pause to consider the implications.
	#I broach the subject of the Vampire of Cincinnati.
		*set convo_time +1
		*if gabriel_status = 2
			"Didn't you kill her?"
				
			*if knows_afab
				"So I did."
				
				"Unfortunate, really. I would have enjoyed meeting her."
				
				"Whyso?"
				
				"Anyone who has discarded conventional roles is someone that I want to meet, ${mr} ${surname}.
				*if (independence > 60) and (trans = false)
					You, for example, are disappointingly conventional."
				*elseif (trans = false)
					You are less of a conformist than most, I suppose."
				*else
					You have certainly sloughed off several of those."
				
				"I see."
			*else
				*set fragala_rapport %-5
				"She?"
				
				Fragalà shakes his head. "Learn to look before you murder, ${mr} ${surname}."
				
				You pull up abruptly at this chastisement.
		*elseif gabriel_status = 4
			"Were you the one that sent her on to Kansas City?"
			
			*if knows_afab
				"I wouldn't say that I sent her to Kansas City. I simply suggested that she depart St. Louis."
				
				"She is now in Kansas City. I should thank you, in fact. I look forward to speaking to her—at some length."
				
				"You're welcome," you reply hesitantly.
			*else
				*set fragala_rapport %-5
				"Her?"
				
				Fragalà shakes his head. "Learn to look before you murder, ${mr} ${surname}."
				
				You pull up abruptly at this chastisement.
		*elseif gabriel_status = 7
			"Didn't Bailey adjust her memories?"
			
			*if knows_afab
				"So he did."
				
				"Pity. I have to imagine that nothing could be worse for her.
			*else
				*set fragala_rapport %-5
				"Her?"
				
				Fragalà shakes his head. "Learn to look before you destroy someone's mind, ${mr} ${surname}."
				
				You pull up abruptly at this chastisement.
		*elseif becard_gabriel_status = 4
			"Did Bécard deal with her?"
			
			*if knows_afab
				"So she did."
				
				"What more needs to be said?"
				
				"You don't think she was a danger to our kind?"
				
				"Not at all. If anything, she would have been a blessing had she been left alone."
				
				"A blessing?"
				
				"Every rumor of vampires given a concrete explanation that is not, in fact, vampires, is a blessing to us."
				
				"A fair point."
			*else
				"Her?" you reply.
				
				"Do try to keep up, ${mr} ${surname}."
			
				You pull up abruptly at this chastisement.
		*elseif (gabriel_status = 1)
			*comment TODO Fragala ask PC to sent Gabriel to Kansas City? Fragala might even embrace her?
			Fragalà peers at you for a long time before speaking. "${mr} ${surname}, as you may have well noticed, not everything in this world is as it seems at first."
			
			"Of couse not."
			
			"If I were you, then, I would recommend not jumping to any conclusions should you pursue the so-called Vampire of Cincinnati."
			
			*if discretion > 60
				*set fragala_rapport %-5
				"What do you know, Quaestor?"
				
				His eyes glitter against the backdrop of his puffy, diseased skin. "More than you could ever imagine," he retorts, the slightest hint of fang showing over his bottom lip. "I believe this interview is concluded. Go, now."
				
				You stand, throw your napkin on the table—it knocks over your still-full demitasse—and stalk away into the night.
				*return
			*else
				"I will take that under advisement, Quaestor."
		*elseif gabriel_status > 1
			Fragalà peers at you for a long time before speaking. "I'm not so worried."
			
			"No?"
			
			"The Vampire of Cincinnati will be found. I have no doubt of it."
			
			"Your confidence is assuring, Quaestor."
		*else
			Gabriel Status: ${gabriel_status}
			*line_break
			Becard-Gabriel Status: ${becard_gabriel_status}
			*line_break
			Month: ${month}
			*page_break
			*bug what is this outcome?
			*comment 1436
*goto fragala_loop

*label gabriel_at_fair

You stalk Gabriel as he makes his way through the pleasure garden. @{(perception > 0) He has a peculiar build for a man, being stocky and barrel-chested but with most of his weight centered in his hips and thighs.|} Looking both ways, he ducks through some bushes. 
*if perception > 1
	*set knows_gun true
	As he does so, you observe a bulge in his coat-pocket. You surmise that he is armed.
Following, you watch as he approaches a young lady on a bench. She recognizes Gabriel, inviting him to take a seat beside her. He takes a final puff on his cigar, extinguishes it, washes his mouth out with some sort of cleanser, and then accepts her invitation. 

The two are seated for no more than five minutes before they begin kissing. Soon, he moves to her neck, while his hand finds its way under her skirt and between her legs. He bites down as she gasps in pleasure. 
*if trans
	*set knows_vampire true
	*set knows_afab true
	
	You blink and take a second look. You can smell no blood, despite the attentions that Gabriel is paying to the woman's neck. Peering closely, you observe the depth of Gabriel's chest, the shape of his thighs, the absence of an Adam's apple—whoever or whatever Gabriel is, he was likely not born with that name.
*else
	You feel some strange sense of shame—though your fangs seem to be received with delight by your prey, this woman's gasps are not sordid like the ones you elicit.

Some minutes later, the woman is slumped on the bench, faint from Gabriel's attentions. You watch as Gabriel wipes his hand, pulls out the cigar, and rekindles it. A curl of smoke rises over the two of them.

*if trans
	You ponder what to do. There are no signs of blood on the woman; you surmise that Gabriel is not a vampire. @{speaks_english |Moreover, you suspect that you do not share a language with him.} Do you still want to approach him?
	*choice
		#Yes@{stlouis_tribune , if only to warn him off|}.
			*gosub confront_gabriel
		#I feed from them and then leave them be.
			*set gabriel_status 5
			You emerge from the shadows with a wry smile. At first Gabriel is startled, but when he sees your open hands and your wink, he invites you to help him with his companion. The two of you have your way with her, and then you have your way with Gabriel. There is something intoxicating about Gabriel's sweat mixed with the stink of the cigar. You enjoy it for what it is, and then leave them both heaving with exhaustion.
		#No.
			*set compassion %-10
			*set discretion %-5
			*set gabriel_status 5
			You leave Gabriel and his companion to their human delights.
*else
	@{speaks_english |Though you suspect that you will not be able to communicate with Gabriel, you consider emerging from your ambuscade to confront him.}
	*label watch_gabriel_loop
	*choice
		*if (discretion < 50)
			*if (perception > 1) #First, I take a moment to watch Gabriel closely.
				*set knows_vampire true
				After several moments observing Gabriel, you conclude that he is not a vampire. He's breathing, for one. @{(perception > 2) And, looking closer, the edges of his soul are not deadened, as they are in vampires.|}
				
				What do you do with this realization?
				*goto watch_gabriel_loop
		#I attack Gabriel; @{knows_vampire he's caused our kind too much grief.|I will kill him for his indiscretions.}
			*set discretion %+5
			*if knows_vampire
				*set compassion %+5
			*set kill_gabriel true
			*gosub surprise_gabriel
		#I attack Gabriel; I will subdue him and bring him before Memeskia@{knows_vampire | for judgment}.
			*gosub surprise_gabriel
		#I emerge from the bushes and confront him.
			*gosub confront_gabriel
		*if knows_vampire
			#Since Gabriel is not a vampire, I leave him to his pleasures.
				*set gabriel_status 5
				*set discretion %-5
				You leave the two lovers to their tryst and return to enjoy the fair.
		*else
			#@{stlouis_tribune Though I violate my office by doing so, I will leave him in peace.|I have seen his hunting style; I will direct Bécard to deal with him.}
				*set gabriel_status 6
				*set discretion %-5
				*if stlouis_tribune
					*set independence %-15
				You leave the two lovers to their tryst and return to enjoy the fair.
*return

*label confront_gabriel
You emerge from the bushes to confront Gabriel. He looks at you askance, his hand traveling to @{knows_gun the gun in |}his coat pocket. @{speaks_english "What the fuck do you want, pervert!" he shouts.[n/]|He says something, which you interpret as a "fuck off, pal."} His companion has recovered from her ordeal and is huddling behind him, terrified at your approach.

When you insist on trying to engage him, Gabriel pulls @{knows_gun his|a} revolver from his pocket and uses it to indicate that you should leave. He has you dead to rights—if you attack, you're sure to take a bullet.
*label confront_gabriel_loop	

*choice
	*if (knows_vampire)
		*if knows_afab
			#"Who are you…really? The newspapers are certainly wrong about you."
				*set gabriel "Gabrielle"
				*set g_he "she"
				*set g_him "her"
				*set g_his "her"
				"What do you mean?" Gabriel replies.
				
				"What's your name?"
				
				"They call me Gabriel. Obviously, you've read about me."
				
				"You didn't answer the question, though. If Gabriel is your name, I understand, but you did not answer my question."
				
				The Vampire of Cincinnati looks at you closely. "Gabrielle is my name. Someone misheard me once, and I didn't have to do much from there."

				"Is it the name you prefer?"

				They ponder for a moment. "It is."
				
				"Well, Gabrielle, you have certainly left a trail of broken hearts behind you."
				
				"Those hearts were already broken by fathers, brothers, and husbands-to-be. I just helped those young women to recognize the pieces."
				
				*gosub fuck_you
				*return		
		*else
			#"Who are you?" you demand.
				"Who the fuck are you?" he spits back.
				
				"You don't belong here."
				
				"People have been tellin' me that my entire life."
				
				*if knows_vampire
					"Your monniker is misplaced, I mean."
					
					"Ida know. I kinda like it. 'The Vampire of Cincinnati!' Let me tell you, the women around here are so bored they want a vampire to come and take them away to Transylvania."
					
					"And is that what you're going to do? Take them to Transylvania?"
					
					"God no. I'm just showing them what they're missing out on."
					
					"You know you've attracted a lot of attention?"
					
					"What's your point?"
					
					*gosub fuck_you
					*return
				*else
					"Don't you know? I'm the 'Vampire of Cincinnati!'"
					
					You clench your teeth. "Didn't your maker teach you anything?"
					
					"If you mean my pappy, I put him in the ground."
					
					"You killed your maker?" you ask, incredulously. @{patricide How can he admit to such a thing so freely?|If only you could admit your crimes so freely.}
					
					Gabriel spits. "I did. Did you know him?"
					
					"What was his name?"
					
					"Horace Quarrington."
					
					"I can't say that I did."
					
					"Then why the fuck are you here hasslin' me?"
					
					Not only is he feeding recklessly, but he's admitted to patricide. @{stlouis_tribune As Tribune, you are well within your rights to put an end to him.|} @{mentioned_quaestor And you did mention the word Quaestor to him.|}
					*goto confront_gabriel_loop
	*if ((knows_afab = false) and ((perception > 2) or (stl_neopronouns and (perception > 0)))) #I look more closely at Gabriel—though it will potentially open me to attack.
		*set knows_afab true
		Looking more closely—observing the shape of Gabriel's torso and hips and the lack of an Adam's apple—you realize that Gabriel was likely not born with that name.
		*if gabriel_pinned
			The stranger struggles against your weight, but they can do nothing pinned as they are.
		*elseif agility > 2
			Gabriel attempts to punch you, but you deflect the blow effortlessly. A good thing, too—it seems like there was some power there. "What are you doin' lookin' at me like I'm a piece of meat? I ain't no piece of meat!" he shrieks.
			
			You push off from Gabriel as you consider what to do next.
		*else
			Gabriel's fist connects firmly with your jaw. "What are you doin' lookin' at me like I'm a piece of meat? I ain't no piece of meat."
			
			You rub your jaw as you consider what to do about this character.
		*goto confront_gabriel_loop
	#I let ${gabriel} go@{oblivio —after using the [i]verba oblivionis[/i] on ${g_him}|}.
		*if oblivio
			*set gabriel_status 5
			@{gabriel_pinned You stand up, releasing ${g_him}. ${gabriel} wheezes as ${g_he} scrambles to ${g_his} feet. |}You look ${g_him} in the eye and whisper sweet nothings. 
			
			When ${g_his} focus returns, ${g_he} is alone in the darkness and the snow.
		*elseif gabriel_pinned
			You stand up. ${gabriel} wheezes as ${g_he} gets up.
			
			Before ${g_he} can ask you any more questions, you vanish into the night.
		*else
			$!{g_he} shakes ${g_his} head in confusion as you disappear into the night. 
		*return
	#I kill ${gabriel}@{mentioned_quaestor . After all, I broke the Rule of Reserve when I mentioned the Quaestor|}.
		*gosub fight_gabriel
		*return

*label fight_gabriel
*set gabriel_status 2
*if gabriel_pinned
	You sink your teeth into ${gabriel}'s neck and drink deeply. The combination of ${g_his} blood and the cigar smoke titillates your senses. 
	
	When you are done, you leave ${g_his} body for the custodians to find.
*elseif strength > 3
	*set knows_vampire true
	When the bullet hits you, you barely flinch. You knock the revolver out of ${g_his} hand and sink your teeth into ${g_his} neck. You drink deeply. The combination of ${g_his} blood and the cigar smoke titillates your senses.
	
	When you are done, you leave ${g_his} body for the custodians to find.
*elseif willpower > 2
	The bullet explodes into your chest. You set your jaw and press forward. ${gabriel}'s jaw drops at the sight.
	
	You sink your fangs into ${gabriel}'s neck. @{knows_vampire |To your surprise, hot, delicious blood fills your mouth—he's not a vampire! But between your anger at being shot and the taste of the blood on your lips, you cannot stop yourself from proceeding.} The combination of ${g_his} blood and the cigar smoke titillates your senses. You drink deeply and finally drop ${g_his} body to the ground.
	
	You leave ${g_his} body for the custodians to find.
	*set knows_vampire true
*else
	*set gabriel_status 3
	The bullet explodes into your chest. You scream in pain—it was more than you were anticipating. You fall to your knees as ${gabriel} @{speaks_english screams at you to stay down|screams at you}. But the Beast inside you is too much. You stand and scramble away into the night.
*return

*label fuck_you
"You should be more careful."

"Fuck you."

"I'm serious. You have attracted attention that you do not want."

"I've been attracting attention that 'I don't want' since I was old enough to wrestle with my older brothers. But I ain't no criminal. And I'll shoot anyone that says otherwise."

"It's not the law that's coming for you."

"Yeah, I figured the Trents would send the Pinkertons for me. That Trent boy deserved every bullet he got."

"Ahem. No doubt he did. But, yes, the Pinkertons. You should go to a small town and…not ruin any more engagements for a while."

"Thanks for the warning," ${g_he} replies, before sizing you up. "You know, there's this bench around here. Folks seem to like sitting on it with me…" ${g_he} says with a lascivious wink.

*if mentioned_quaestor
	There's just one problem: you did mention the word Quaestor to a mortal. Which puts you in danger of breaking the Rule of Reserve. If ${gabriel} were to say anything to anyone.…

*choice
	#"There's no time for that. You should go. Now."
		*set discretion %-5
		*set gabriel_status 4
		"See, that's the thing about men. They don't know how to listen. I hear you loud and clear."
		
		With that, ${g_he} vanishes into the night.
		*if mentioned_quaestor
			*set exposure +1
			You hope that you will not regret your decision.
	#You offer your hand out of idle curiosity.
		*set anachronism %+5
		*set gabriel_status 5
		${gabriel} is surprised by the lack of a response when ${g_he} seeks to stimulate you. However, you take mental notes for your own seductions. When ${g_he} begins to doubt ${g_him}self, you feed from ${g_him} gently, drinking enough to cloud these few moments and leave ${g_him} thinking that a good time was had by all.
		
		You leave ${g_him} there to recover.
		*if mentioned_quaestor
			*set exposure +1
			You hope that you will not regret your decision.
	#I kill ${g_him}. @{mentioned_quaestor I have an obligation.|}
		*set independence %+5
		*set compassion %+5
		*set justice %+5
		*gosub fight_gabriel
*return

*label surprise_gabriel
@{(knows_vampire and (kill_gabriel = false)) You leave for a moment in order to gather a few implements for what you are about to do. When you return, you find Gabriel enjoying his cigar again and contemplating the stars.|When the lady departs, Gabriel waits a few minutes, presumably so the two aren't seen in public together. In the meantime, he enjoys his cigar and contemplates the stars.} 

Eventually, he stands and begins walking back to the thoroughfare. When the moment is right, you leap out of the darkness.

*if knows_vampire and kill_gabriel
	*set gabriel_status 2
	You sink your teeth into his neck and tear a huge chunk of flesh away. The arterial blood splatters across the bushes in a Beast-pleasing spray. The taste is exhilerating—something about the sweat and cigar smoke sets your senses aflame.
	
	You drink deeply, savoring the taste. When you are done, you lick the wound closed and disappear into the night.
	*return
*elseif knows_vampire
	*set gabriel_status 7
	You club Gabriel over the back of his head. He yelps and falls to the ground. You bind his feet and cast a hood over his head.
	
	*if stlouis_cult
		You commend Gabriel to Amanda's care for the day.
	*elseif stlouis_valet_alive
		You commend Gabriel to ${stlouis_valet}'s care for the day.		
	*elseif stlouis_hideout
		You confine Gabriel at your hideout in Chestnut Valley for the day.
	*else
		*set aichinger_rapport %-5
		Lacking a better solution, you deposit him @{schnaiders_closed at the Eurydice|at Schnaider's}, hoping that Sigrid will be able to manage him.
	
	The next evening, you drag Gabriel before Memeskia. "What is this?" he asks.
	*if stlouis_tribune
		*set bailey_rapport %+5
	*if stlouis_tribune = false
		*set independence %+5
		
	"The Vampire of Cincinnati, Quaestor."
	
	"The book."
	
	"[i]Dracula[/i], yes. It has muddied the waters."
	
	"Take him to John."
	*comment TODO could have a convo with Gabriel here
	
	Later that night, you render Gabriel to Senator Bailey. Bailey spends a few minutes talking with Gabriel, making him forget what he has seen tonight. He also orders Gabriel to stop encouraging the idea that he is a vampire.
	
	Your task complete, you return to enjoy the Fair.
	*return
*elseif kill_gabriel
	*set gabriel_status 2
	You sink your teeth into his neck and tear a huge chunk of flesh away. Arterial blood sprays over the foliage. To your surprise, though, that blood is hot and…alive. The taste is exhilerating—something about the sweat and cigar smoke sets your senses aflame.
	
	Looking at Gabriel, you see he's already dead, he just doesn't know it yet. Not wanting that blood to go to waste, you pounce again.
	*page_break
	Several minutes later, you look down at the now-bloodless body of Gabriel. The wound from you first attack is too severe for your saliva to repair it. Taking his revolver, you aim it at the wound and pull the trigger, blowing an ever larger whole in his neck. 
	
	Then, you flee the scene before anyone can investigate.
	
	In later days, Gabriel's death will be reported as a most peculiar suicide.
	*return
*elseif speaks_english
	*set knows_vampire true
	*set mentioned_quaestor true
	*set gabriel_pinned true
	Gabriel is clearly surprised by the attack. You push him to the ground and pin his arm behind his back. He yelps in surprise and pain. "What the fuck?"
	
	"You're coming to see the Quaestor," you hiss.
	
	"What the fuck are you talking about?"
	
	"Don't play dumb," you retort.
	
	"I don't know what you're talking about!" he shouts, "but I can't breathe! Please, let me go!"
	
	It's at this moment that you realize that he's speaking the truth—he's breathing. This is no vampire!
	*goto confront_gabriel_loop
*else
	Gabriel is clearly surprised by the attack. You push him to the ground and pin his arm behind his back. He yelps in surprise and pain, screaming some curse at you.
	
	You pin his arms behind his back while he kicks and screams. You punch him in the side to quiet him down, and he exhales at the pain.
	
	He exhales.
	
	He's alive.
	
	*choice
		#I just kill him and drink his blood. Whatever this is, he's caused enough problems.
			*set compassion %+5
			*set gabriel_status 2
			And so you do.
		#I let him go with an incoherent apology.
			*set gabriel_status 5
			He curses at you in pain and confusion as you retreat into the night.
	*return

*label lefferts_at_fair
*set spoke_stl_lefferts true
*temp convo_time 0
*temp com_gould speaks_english
You approach Lefferts and Gould carefully. The two are doing little to disguise themselves as they marvel at the sights.
*if (gould_plot < 3) and (perception > 1)
	*set gould_plot 3
	You quickly ascertain that Gould is, in fact, a vampire, as he does not respire.
*elseif gould_plot < 3
	For someone who is supposed to be dead, Gould certainly seems animated. Did someone—Lefferts?—give him the @{(compassion < 50) curse|gift} of eternal life?
*if gould_plot >= 4
	Do you want to reveal yourself to them?
*else
	*goto confront_lefferts
*choice
	#Yes.
		*set independence %+5
		*if (gould_plot > 3) and (discretion > 55)
			*set discretion %-10
		*gosub confront_lefferts
		*return
		
		*label confront_lefferts
		*if met_lefferts
			You greet Edwin and Jay familiarly. Edwin shakes your hand and claps you on the upper-arm.
			
			"It is good to see you, ${given_name}," Edwin says.
			
			"And you, Edwin. But Jay, something has…changed.@{(gould_plot < 3)  I suppose the rumors of your death were greatly exaggerated?|}"
			
			Jay smiles, showing the smallest hint of fang in the moonlight. @{(gould_plot < 3) "Not that exaggerated."|"So it has! I feel…wonderful!"}
			
			"Has he been fed recently?" you ask Edwin@{(gould_plot < 3) , surmising that Gould has, in fact, been turned|}.
			*if gould_plot < 3
				*set gould_plot 3
			
			"Oh! Come, let us feed together!" Jay exclaims.
			
			You stiffen. Such a proposal usually arises after a long courtship. "I am…"
			
			Edwin waves his hand. "Jay has spent so much time draining the lifesblood from people across the world, he is only too happy to do it for real now."
			
			"I see."
			
			Gould peers at you, his eyes a little too wide.
		*else
			You approach the two, hands before you. "Good evening," you begin.
			*if speaks_english = false
				Unfortunately, Gould does not speak
				*if speaks_french
					French,
				*elseif speaks_german
					German,
				*elseif speaks_spanish
					Spanish,
				but Lefferts does.
			
			Lefferts introduces the two of them.
			
			"Are you enjoying the Exposition?"
			
			*if com_gould
				"I am!" Gould exclaims.
				
				"Is he new?" you ask.
				
				"He is. A decade now, but still lost in the experience. Personally, I think that he spent so much time draining the lifeblood from the workers of the world that he is simply beside himself that he now gets to do it for real."
				
				"I see."
				
				Gould peers at you, his eyes a little too wide.
			*else
				"We are, thank you."
				
				Gould peers at you, his eyes a little too wide.
				
				"Is he…alright?" you inquire, indicating the former tycoon.
				
				"A decade as a vampire and he is still besotted with the experience," Edwin yawns.
			
		*label gould_loop
		*if convo_time = 2
			Gould is still looking at you with his too-wide eyes. He is vibrating with excitement at the prospect of feeding soon.
		*if convo_time = 3
			
			"I believe that Jay here will not be restrained from feeding much longer. If you will excuse us…" Lefferts says.
			
			"But of course," you finish.
			
			The two brush past you and disappear into the crowds.
			*return
		*choice
			#"Will you stay in St. Louis for long?"
				*set convo_time +1
				"Oh, absolutely. Until the end of the fair, at least. Jay here wants to understand everything he can about the wider world."
				
				"Has he not seen much of it already?"
				
				"London, Paris, Barcelona, Montréal…maybe a few others?…but now that he is immortal, I suspect he wants to venture further afield."
				
				"And this is how he will establish his itinerary?"
				
				"Where a human might enjoy the cuisines of all these cultures, Jay intends to experience them…more directly," Edwin says with a snort.
			*if (gould_plot = 4) #"You do realize that his existence—" you say, indicating Gould "—is a threat to all of us?"
				*set convo_time +1
				"Oh, you worry to much! Everyone knows that Jay Gould died of consumption. Besides, most of the people that knew him will themselves die after another ten years or so."
				
				"And yet, here you are, at the World's Fair, parading about without a care in the world?"
				
				"So we are," Edwin replies. You can almost imagine him sticking his tongue out at you.
			#"How did you convince the world that Jay died of consumption?"
				*set convo_time +1
				*if com_gould = false
					Edwin relays your question to Jay with a smile. 
				Jay coughs into a handkerchief. Taking it away, you see that there is blood. @{com_gould "I did have consumption, don't you see!"|"As you can see, he did have consumption."}
				
				*if (intelligence > 2) or ((anachronism > 70) or ((tuberculosis_vaccine > 1) or ((stlouis_enterprise = 7) or (knows_pb_diseased = 3))))
					"But…aren't you concerned about him spreading the disease to others?"
					
					"Spreading the disease?" Edwin marvels at you. "That's not how consumption is spread!"
					
					"You are a fool, Mr. Lefferts. Jay here is an immortal carrier of a disease that can be spread to mortals."
					
					Edwin scoffs at you.
					*if com_gould
					
						"So what if I am?" Gould says ghoulishly.
				*else
					"Curious. And @{com_gould you|he} still cough@{com_gould |s} up blood?"
					
					"On occasion."
			#"How are his affairs being managed after his death?"
				*set convo_time +1
				"Much of his wealth has passed on to his heirs, but there is enough squirreled away that we will have no concerns for money for centuries."
				
				"And Mr. Gould will continue to seek to dominate the railroads of the United States?"
				
				"Of course!"
				
				*if independence > 35
					"Won't people notice that someone with the same style and gumption as Gould is still seeking to dominate the railroads?"
					
					"Humans are not that clever."
					
					You blink at his stupidity.
			*if (stlouis_tribune) #"I demand that you come and present yourselves before the Quaestor."
				*set independence %+5
				Lefferts and Gould break into laughter. "Or what?" Lefferts says.
				
				He's right. You are surrounded by mortals. Any conflict here would mean a death sentence for you as well.
				
				"Scurry back to that savage of a master and tell him that we don't fear him. Do we, Jay?" Gould just grins maniacally. "Good evening, ${given_name}," Lefferts concludes.
				
				With that, the two strike off into the crowd.
				*return
		*goto gould_loop
	#No.
		You stalk the two vampires as they make their way down the Pike. They play a few games—neither of them has quite learned how to throw a baseball—and marvel at the baby incubators. @{((perception > 1) and (com_gould)) You overhear Gould say something about the infants looking like an early-evening snack.|}
	
		*choice
			*if (taste_for_vampire_blood) #I wait for them to separate, and then I drink the heartsblood of of Gould.
				*gosub stalk_gould
				*gosub consume_gould
				
				*gosub dispose_goulds_body
			#I wait for them to separate, and then I kill Gould.
				*gosub stalk_gould
				*if taste_for_vampire_blood and (discretion > (55 + (bloodflow * 2)))
					At the sight of the woman's blood and Gould's precarious position, you feel the beast surge to the fore.
					*gosub consume_gould
					
					*gosub dispose_goulds_body
				*else
					
					You raise a machete you brought for the occasion and swing it down on Gould's skull. It cuts through the flesh, bone, and brain with surprising ease. You yank it out and swing again, splitting his skull in two.
					
					After a moment, the flesh on Gould's frame withers as though all the moisture were evaporated away. He looks almost mummified. His blood is thick and stagnant, however, and pools on the ground in unpleasant ways.
					
					*gosub dispose_goulds_body
			*if (knows_about_stakes) #I wait for them to separate, and then I stake Gould and take him to Memeskia.
				*gosub stalk_gould
				
				You leap forward, preparing to drive a stake through his heart.
				*if (combat < 7) or (taste_for_vampire_blood and (discretion > (55 + (bloodflow * 2))))
					He catches your forearm and spits in your face. His head lunges towards you, snapping for your blood. You feel the beast rising within you, and find yourself unable to resist.
					*gosub consume_gould
					
					*gosub dispose_goulds_body
				*else
					He catches your forearm, but you drop the stake, catch it in your other hand, and plunge it into his chest. In an instant, his eyes freeze and his body goes limp.
					
					Peering down, you see that the woman is alive, covered in Gould's foul blood and unconscious from bloodloss. You leave her to wake amid an abbatoir.
					*page_break
					*set has_gould_staked true
					It takes some doing sneaking Gould's body out of the Exposition, threading the crowds and an increasingly-panicked Lefferts. Eventually you make your way out of Forest Park and on to your way to your haven.
			#I leave them alone.
				*set independence %-5
				*set discretion %-10
			#In fact, I approach them.
				*gosub confront_lefferts
		*return
		
		*label stalk_gould
		Stalking the young vampire is surprisingly easy. When he chases a young woman through a service door in the Ottoman pavilion, you give it a few minutes and then follow.
	
		When you burst in on them, you find the woman pale and insensate; you suspect that Gould did not intend to leave her alive. He snaps his head in your direction, hissing over his kill.
		*return
	
		*label consume_gould
		*gosub_scene util diablerie
		*set discretion %+10
		*set compassion %+10
		You leap at him, fangs extended.
		
		His blood is foul and polluted. You gag as you suck it down. On several occasions, in fact, you spit out mouthfuls of the stuff. Finally, however, you get to the heartsblood, and despite the noxious overtones, you no longer pull away. You suck and suck until Gould is a withered husk.
		*return
		
		*label dispose_goulds_body
		*set gould_dead true
		The woman is alive, covered in Gould's foul blood and unconscious from bloodloss. You leave her to wake amid an abbatoir.
		*page_break
		It takes the rest of the evening for you to dispose of Gould's body while avoiding the increasingly-panicked Lefferts. You try to feed Gould to the tigers at the Indian pavilion, but they recoil from Gould's polluted corpse. 
		
		Eventually, however, you dump his body in the alligator pen that is part of the Louisiana pavilion. The reptiles have no such compunctions.
		*return

*label desc_maffi
She is wearing a wide-brimmed hat that sits atop her natural hair, a tan duster that reaches to her ankles, English riding boots, and a revolver on her hip. It's strikingly different from the bustled dresses of the other women at the fair, yet something about her prevents most people from noticing.
*return

*label maffi_at_fair
*set spoke_stl_maffi true
*temp convo_time 0
*temp no_governor false
*temp super_rude false
*temp begin_again false
*temp prohibition true
*temp carry_revolution false
*if (missouri_suffrage > missouri_prohibition) or ((missouri_suffrage = missouri_prohibition) and (rationalism < 50))
	*set prohibition false
*if met_maffi > 1
	*if trans
		*set maffi_rapport %+10
		When you approach Thérèse, she cocks her head. "I believe reintroductions are due," she says. 
		*gosub desc_maffi
		
		"${given_name} ${surname}," you offer. "You are not surprised?"
		
		"During the early days of the revolution, everything was questioned. Some things have no answers. Other things have answers, but they are answers that the majority abhors. Courageous individuals are those who accept the answers without opprobrium."
		
		You're not quite sure where that leaves Thérèse's opinion of you: does she embrace your change, or does she simply accept that any unease on her part is irrational? "It is good to see you too, Thérèse," you rely.
	*else
		*if maffi_rapport > 50
			"Welcome, friend," she says, extending her hand for you to shake. @{male It is rare for you to shake a woman's hand, but you take it and give it a good shake.|You have shaken precious few hands in your nights, but can find no reason decline.}
			*gosub desc_maffi
			
			"Thank you. But I should be welcoming you to St. Louis," you reply.
		*else
			"Ah, you," she says. "All grown up, I see."
			*gosub desc_maffi
			
			"Thérèse," you nod.
			
			"I'm surprised that West has not consumed you yet."
			
			"Were you hoping that he had?"
			
			"Hoping is too strong a word, ${given_name}." You are a little startled by the expression of familiarity.
			*line_break
			*line_break
	*if haitian_sugar_plot > 1
		"Were you able to make use of the funds from our enterprise?"
		
		"I was. The people of Haiti thank you. As do I," she says with a bow.
	*elseif haitian_sugar_plot = 1
		"It seems that you have come through your trials in one piece."
		
		"So we have."
*else
	*if ethnicity = "african"
		*set maffi_rapport %+20
	*if ethnicity = "choctaw"
		*set maffi_rapport %+10
	"I'm sorry, but I don't believe we've been introduced," you begin.
	
	"Thérèse," she replies.
	*gosub desc_maffi
	
	"Thérèse…" you prompt.
	
	"They call me Maffi, but Thérèse is sufficient."
	
	*if independence > 60
		*set maffi_rapport %-5
		"Ms. Maffi…"
		
		"What did I just tell you?" she scolds.
		
	"Thérèse, then. I am ${given_name} ${surname}@{stlouis_tribune , Tribune of St. Louis|}." She nods. @{stlouis_tribune She seems singularly unimpressed by your title.|} When she says nothing, you continue. "What brings you to St. Louis?"
	
	"Other than the Exposition, you mean?"
	
	"Yes, of course."
	
	"Nothing."
	
	*if stlouis_tribune
		"I presume you know the Three Rules?" you begin, at a loss as to how to handle this laconic visitor.
		
		"Yes."
		
		"Recite them to me," you demand.
		
		"Reserve, Respect, and Restraint."
		
		You fish about for something else to ask her. "And I trust that you are in good standing with the Society?"
		
		"No."
		
		That was unexpected. "No?"
		
		"Are you going to arrest me, then? Kill me?"
		
		It's not typical for the guilty to proclaim their crimes. At the same time, you have no way of knowing whether this woman is five years dead or five hundred. "Perhaps you had better explain your crimes?"
		
		"I slew Azamet Praz, Governor of Cap—Français."
		
		"And assumed his position? There's no crime…"
		
		"No, I did not assume his position."
		
		"What about the new governor…"
		
		"There is no 'new governor.'"
		
		"Then who rules the vampires of…Cap-Haïtien—" the name was changed when Haiti rebelled from France "—in Praz's absence?"
		
		"No one."
		*set no_governor true
	*else
		*if maffi_rapport > 40
			"Do you always rebuff new acquaintances with such force?"
			*set begin_again true
			
			She gives that a moment's thought. "Forgive me, ${given_name}. There are many individuals in this world who are not worth my time. Who, in fact, waste it with their pleasantries and indolent questions. Perhaps my customary mode is unwarranted here."
			
			"Then shall we begin again?"
			
			She smiles. "Yes, let's."
		*else
			*set super_rude true
			Whoever this rather rude individual is, she apparently wants little to do with you.

*label maffi_loop
*if convo_time >= 3
	*set met_maffi 4
	"If you will excuse me, the night grows late. And I did not come all the way here to spend the entire time in conversation with @{(maffi_rapport > 45) others of our kind|you}."
	
	"Of course, Thérèse," you reply.
	
	*if month <= 9
		She fades into the night.
	*return
*choice
	*if (super_rude) #"Perhaps I should excuse myself."
		*set maffi_rapport %+15
		*set compassion %-5
		*set discretion %-5
		"Yes, perhaps that would be best."
		
		*if perception > 1
			You sense that, perhaps counterintuitively, you have earned some esteem in the eyes of Thérèse for observing and respecting her desire not to speak to you.
		"Perhaps we will meet again some night, Thérèse," you say with a ${bow}, and depart.
		*return
	*if (no_governor) #"How long have you not-governed Cap-Haïtien?"
		*set convo_time +1
		*set maffi_rapport %-5
		"I told you, I am not the governor…"
		
		"And how long have you not been the governor?"
		
		"Over a hundred years now," she concedes.
		
		"Do you make decisions through popular vote?"
		
		"I mean, there are other vampires there, yes?"
		
		"Of course."
		
		"And do you make decisions by vote? Or do you decide things yourself?"
		
		"We come to a consensus and then act accordingly."
		
		*if compassion > 40
			*set maffi_rapport %-10
			"Vampires…coming to a consensus? You are either lying to me or lying to yourself, Thérèse."
			
			She scowls at you.
		*else
			"Is such a thing possible?" you exclaim.
			*line_break
			*line_break
		"We manage as best we can."
	*if ((met_maffi = 3) and (feeding_style = "vegetarian")) #"I have a confession to make. When we met in New Orleans, you told me how you only feed from animals.…"
		*set maffi_rapport %+40
		*set met_maffi 2
		"Yes?"
		
		"I heard what you said. I mean…I really heard it. I too find feeding from mortals to be repugnant."
		
		"And…what have you done about it?"
		
		"I have committed myself to not feed from them as well."
		
		Her eyes widen in surprise. "That is not what I would have expected of you, Comrade ${surname}."
	
		"Comrade?"
		
		"What else could I call you?"
		
		"Are there…many like us?"
		
		"No, certainly not. And it is difficult for us to gather. Tempers flare, heated words turn to claws and fangs, and humans die as a result."
		
		"Is that why you refuse to call yourself Governor? Because you do not want other vampires around to govern?"
		
		"It is one reason, yes."
		
	*if haitian_sugar_plot > 1
		#"Did you profit from our smuggling operation?"
			*set convo_time +1
			"Did I profit?
			*if haitian_sugar_plot = 2
				No. But Haïti did."
				
				"I am glad to hear it."
				*line_break
				*line_break
			*if haitian_sugar_plot = 3
				*set maffi_rapport %-10
				No, not like you did. Though, I suppose, I should have not expected more of you."
				
				"Scorpions and frogs," you reply.
				
				"Yes, exactly." She pauses to retrench.
			"The Republic thanks you for your service. But, I'm afraid, there are no medals to dispense."
			
			"None are needed, Thérèse."
			
	*if haitian_sugar_plot = 1
		#@{(met_maffi > 1) "What has transpired in Haïti since you came to New Orleans?"|"Tell me of your country."}
			*set convo_time +1
			*if met_maffi > 1
				"It has been a hard road, I will not lie. But we recently paid off the principal of that damned indemnity to France. Once again, we have able individuals at the head of our government. The pretensions of empire have fallen to the wayside. I hope that soon we will carry forward the principles of the Revolution."
				
				"You still hope to see the revolution through on Haitian soil?"
				
				"It is the only place where it can truly blossom." She looks around the Exposition. "Maybe, some day, it could happen here. Or Brazil. But in both cases, the power of the hierarchies will need to be rent asunder. And you are not yet there," she finishes, indicating the vast display of wealth and power around you.
			*else
				"My country? Haïti is the most-free country in the world."
				
				"The most free?"
				
				"We fought the French and the British Empires to a standstill. We rule ourselves. We have even paid off the blood-tax that France imposed upon us as a condition of that freedom. The spirit of our people is strong, and soon the world will know the depths of our courage."
				
				"I am sure that we will," you reply agreeably.
	*if (temperance_movement) #@{prohibition "Have you considered banning the consumption of alcohol in your country?"|"Have you established women's suffrage in Haiti?"}
		*set convo_time +1
		*if prohibition
			A scowl crosses Thérèse's face. "I understand your goals, but I believe they are misplaced."
			
			"Oh?"
			
			"I sympathize with the plight of women in your country. The abuse that they sustain at the hands of their husbands, fathers, and brothers is abhorrent."
			
			"And the women of Haiti do not suffer in this way?"
			
			"I am not saying that we are blameless. But the issue is not with the drink; it is with the drunk. And, more broadly, with the circumstances of the drunk that cause him to act in such a way. To assert power over those weaker than himself, because he himself feels weak."
			
			"I'm afraid I don't understand."
			
			"Who is it that abuses the women in their lives? Those men who do not feel in control of their fates and fortunes. Who feel as though they have failed. This is not a symptom of their own failure, but a symptom of the systems of capital that dictate the ordering of society."
			
			*if laborvscapital > 60
				*set maffi_rapport %+10
				"I understand your point."
				
				"Then why do you focus on the sympton instead of the disease?"
				
				@{(discretion > 50) "Because I didn't have you here to explain it to me," you snap.|"Mine own oversight, I suppose."}
				
				@{(discretion > 50) "A wounded pride has no value, ${given_name}," she chastises.|"That is gracious of you to say," she proffers.}
				
				You nod, considering her words.
			*elseif (intelligence > 2) or (finance > 1)
				*set maffi_rapport %-10
				"How else would you organize society, but through the productive application of capital?"
				
				"Through the democratic apportionment of goods. Through developing a culture of equality and fraternity."
				
				"That is absurd. You expect those who have accrued power and resources through their own sweat and tears to share that power and resources with the rabble?"
				
				"I do, in fact."
				
				You practically gape at the audacity of her vision for humanity.
			*else
				"Systems of capital?"
				
				She rolls her eyes at you. "I do not have the time to explain economics to you. But yes, capital—accrued wealth—seeks to perpetuate itself. And that perpetuation has pernicious effects on how humans—and vampires—associate."
				
				"And you seek to end those systems?"
				
				"That is the heart of the revolution. The end of hierarchies: the king, the church, the patriarchy, the bourgeoisie, imperialism…"
				
				"Then what is left?"
				
				"I'll let you know when we get there," she says with a smile.
		*else
			*set maffi_rapport %+10
			"Yes, very much so.
			*if missouri_suffrage > 4
				*set maffi_rapport %+20
				In fact, I have heard about what you have been advocating for here in Missouri and I must say that I am amazed.
			For the revolution to come to fruition, everyone in society must be equal."
			
			"And in Haiti?"
			
			"I have many obstacles to convincing the people of my country of the righteousness of such a change. But finally, in the flowering of our nation in the wake of the 1874 constitution, the resolution seems within reach."
			
			"That is most exciting to hear!" you exclaim.			
	*if (heard_ragtime) #"What do you think of ragtime, the new music of St. Louis?"
		*set convo_time +1
		*set anachronism %+2
		*set maffi_rapport %+5
		Thérèse smiles, perhaps for the first time. "I love it."
		
		"You love it?"
		
		"I do. It is revolutionary."
		
		"Well, yes, but…"
		
		"No, truly. It takes what was known and brings it forward. The rules that were observed for centuries are shown to be flexible, if not outright arbitrary. I am anxious to see what developments are next."
	*if (tryphon_identity > 1) #"What do you know of an ancient who relocated from Haiti here?"
		*set convo_time +1
		*set tryphon_identity +1
		Thérèse looks startled by your question. "You have heard of him?"
		
		"I have."
		
		"What do you know?"
		
		You consider answering her question—you're not sure why you should offer your information first—but decide to press on anyway: "Little. That he came here from Saint-Domingue and fought a great battle with Memeskia. When the battle concluded, he slipped into the earth, and sleeps there still."
		
		"I did not know this. But yes, I have heard rumors of an ancient Athenian who came to Saint-Domingue, looking to recreate the so-called democracy of his youth."
		
		*if intelligence > 2
			*set maffi_rapport %+5
			"What is it with ancient vampires trying to recreate the circumstances of their youth?"
			
			Maffi smiles. "Nostalgia. The sense that, if only things had gone slightly differently, they would not find themselves in these circumstances."
			
			"And yet?"
			
			"And yet they do not account for the one constant. Themselves."
		*else
			"Wasn't Saint-Domingue mostly a slave camp?"
			
			"So it was. As was Athens. A mighty city-state, where a few men ruled through voting an empire of people who could not."
			
		"And you know nothing more about him? His name?"
		
		"I do not know his name, but he was surely one of Sostrate's brood."
		
		*if heard_of_sostrate
			*set heard_of_nikomedes true
			"Was she prolific?"
			
			"As Consul? Very. Her scion, Nikomedes, is still the Governor of Paris."
			*if heard_of_olympias
				*set maffi_rapport %+5
			
				"The Governors of Athens and the Governor of Paris are broodmates?"
				
				"So they are, ${given_name}."
		*else
			*set heard_of_sostrate true
			"Sostrate?"
			
			"She was Consul of Constantinople until 1204, whereupon she was murdered by the Crusaders."
			
			"And I'm sure you think Adonis was behind that?"
			
			She looks at you, disappointed.
		
		"But he left? Whyso?"
		
		"Having never met him, I can't say. But if he thought he would recreate Athens in Haiti, I'm sure that he was ultimately disappointed."
	*if ((convo_time >= 2) and (maffi_contactable = false)) #"Perhaps you would provide me with a way to contact you in the future?"
		*set convo_time +1
		*comment TODO remove the time increment once more #options are written.
		*set maffi_rapport %+5
		Maffi considers a moment.
		*if revolutionary_credentials > 35
			*set maffi_contactable true
			"You have not pledged yourself to Adonis, which I appreciate. Very well, this is how you may write to me…" she offers.
		*else
			"I am not interested in corresponding with one who has pledged their allegiance to Adonis, as you have."
	#"Do you intend to carry your revolution to other lands?"
		*set carry_revolution true
		*set convo_time +1
		*if (maffi_rapport > 60) or (justice < 35)
			She sighs. "It is surprisingly difficult. Humans are greedy. They seek opportunities for profit at every turn—well, not all of them. But in every village, some number of them will pursue their own interests at the expense of their neighbors."
			
			"And how do you intend to combat this instinct?"
			
			"There are many proposals, but they resolve to just two: education and surveillance."
			
			"You think you can teach away greed?"
			
			"Perhaps. But all such proposals soon conclude that everyone over a certain age must be…separated from the children. Lest they perpetuate their shortcomings."
			
			"And by 'separated' you mean murdered."
			
			"Yes."
			
			"And the other solution? Surveillance?"
			
			"It means that the people of the society must exist as John Calvin proposed, only for the good of the village instead of the good of the soul: everyone must observe both themselves and all of their neighbors, and share moments of failure. Only through constant and unrelenting surveillance can the revolution continue forward instead of being betrayed from within."
			
			"Calvin was a preacher."
			
			"A preacher and a theologian who was obsessed with the organization of society for the purpose of saving souls. Who else would come up with such an intrusive scheme?"
			
			You think a moment. "And so, which will you pursue?"
			
			Maffi looks into the distance. "Honestly, I haven't decided. Both are repugnant to me."
			
			*if discretion > 60
				"Then you will fail."
				
				She clenches her jaw. "Better a failure than a monster."
				
				"We're already monsters, Thérèse," you retort.
				
				She doesn't reply to that.
			*elseif (compassion < 35) or (justice < 30)
				*set maffi_rapport %+5
				"Perhaps there is another way? Kindness? Compassion?"
				
				"Perhaps there is," she replies wistfully.
		*else
			She doesn't look at you as she answers. "The revolution in Haïti is incomplete. I see no purpose in pushing forward as long as my flank is exposed."
	*if (carry_revolution) #"Which goal will you prioritize, though? Equality between the sexes, or between the races?"
		*set convo_time +1
		*comment TODO not the best. Write more later.
		She scowls at you. "Neither can be achieved without the other. The two are inextricably linked, ${given_name}."
		
		"How do you mean?"
		
		"The current system depends on dividing the two, making it seem as though they are separate and distinct, rather than two sides of the same coin. We must liberate both, together, in order to liberate either."
		
		*if justice > 50
			*set convo_time +1
			*set maffi_rapport %-5
			"Are you so idealistic? Or simply naïve?"
			
			"Neither, you child," she spits.
		*elseif justice > 30
			"Must you move so quickly?" you ask. "You're asking a lot of mortals and vampires alike. It is too much…"
			
			"Why must we wait for others to acknowledge that we are human, ${given_name}?"
			
			"But…we aren't human."
			
			"You know what I mean," she retorts.
		*else
			"I look forward to that day, Thérèse."
			
			"As do I," she replies.
*goto maffi_loop

*label withers_at_fair
*set spoke_stl_withers true
*if lpe_masterwork
	*set withers_rapport %+25
*if flirting_with_withers
	If your heart were still beating, if would have just skipped a few.

The crowd parts and Withers is standing there. She is outfitted in the latest French style, with a ruffled-lace cravat spilling out from her high-necked dress, and a hat adorned with massive ostrich plumes. A belt beaded with pearls cinches her waist, and she sports a useless-in-the-dark parasol that matches her dress.

*if withers_rapport > 70
	She lights up at your approach.
*elseif withers_rapport > 55
	She smiles at your approach.
*elseif withers_rapport > 45
	She nods at your approach.
*else
	She stands a little straighter when you approach.

*if lpe_masterwork
	*set overstreet_rapport %+10
	"${given_name}! I would recognize your handiwork anywhere."
	
	"What do you mean?"
	
	"Look at this place!" she says, gesturing to the Exposition. "From the columns to the porticoes, from the fountains to the pavement, I see your touches everywhere. You did this, didn't you?"
	
	You grin and @{(discretion > 50) bow with an exaggerated swagger|nod, somewhat sheepishly}. "I did."
	
	"It is like a dream make reality. You have truly outdone yourself."
	
	"Thank you, Samantha."

*if lied_to_carothers_about_pb = 3
	"@{lpe_masterwork And yet I should not be too effusive. |}You lied to Carothers! How could you do that?"
	
	You look her straight in the eye. "I did not feel that ${maddox} deserved death."
	
	*if maddox_num < 3
		"Death! That was the least of what he deserved!" she exclaims.
		
		"Fleeing one's dominus is a reasonable response to our condition, Samantha," you reply.
	
	"And so you let him go."
	
	"I did. Not that it matters now."
	
	"How do you mean?"
		
	"West consumed him."
	
	Though it is hard to see in this light, you suspect that Withers's face just turned a pale shade of green.
*elseif wilson_embraced
	*if (maddox_status = "dead") or ((maddox_status = "consumed") or (maddox_status = "buried"))
		"@{lpe_masterwork Allow me to also congratulate|Congratulations} on bringing your scion to heel," she says.
		
		You nod. "@{(compassion < 50) It brought me no joy, Quaestor," you reply.|It had to be done," you shrug.} @{(maddox_status = "buried") Of course, no one other than you knows that he is buried in a field outside of Memphis with a stake through his heart.|}
		
		"We all have to make choices. ${maddox} made his." @{(maddox_status = "consumed") No need to mention how he tasted when you drank his heartsblood.|}
		
		You're unsure if that was supposed to be comforting or not.
	*elseif maddox_status = "west"
		"@{lpe_masterwork I wish I could also congratulate you on corraling your scion. But it seems you failed in that task.|I was disappointed to hear that you were unable to corral your scion, ${given_name}.}"
		
		"It doesn't matter now."
		
		"How do you mean?"
		
		"West consumed him."
		
		Though it is hard to see in this light, you suspect that Withers's face just turned a pale shade of green.
		
	*else
		What is ${maddox}'s status? ${maddox_status}
		*page_break
		*bug
		
*elseif wilson_embraced_by_withers
	*if maddox_status = "withers"
		"@{lpe_masterwork I should be thanking|Thank} you for returning ${maddox} to me," Withers offers.
		
		You nod. "At your service, Quaestor," @{(withers_rapport > 55) you reply|you reply, barely bothering to conceal your disdain}.
	*elseif maddox_status = "west"
		"@{lpe_masterwork And yet I should not be too effusive. |}I hear that you failed in your task of dealing with ${maddox}."
		
		"It doesn't matter now," you grouse.
		
		"How do you mean?"
		
		"West consumed him."
		
		Though it is hard to see in this light, you suspect that Withers's face just turned green.
		
	*elseif ((maddox_status = "dead") or (maddox_status = "consumed")) or (maddox_status = "buried")
		"@{lpe_masterwork I should be thanking|Thank} you for disposing of ${maddox}," Withers says.
		
		@{(independence < 50) "As you should," you reply. She rolls her eyes but lets your insolence pass.|"You're welcome," you reply graciously.}
		
		@{(maddox_status = "consumed") No need to mention how he tasted when you drank his heartsblood.|} @{(maddox_status = "buried") No need to mention that he exists still, buried in a field outside Memphis with a stake through his heart.|}
	*else
		What is ${maddox}'s status? ${maddox_status}
		*page_break
		*bug
*else
	*if ((gallagher_status = "dead") or (gallagher_status = "consumed")) or (gallagher_status = "inquiry")
		"I hear you helped Carothers with a certain problem…a vampire spreading the yellow fever?"
		
		"I did."
		
		"That was good of you, ${given_name}," she smiles.
	*elseif gallagher_status = "west"
		"Quaestor Carothers seems have have had some difficulty during your stay with him."
		
		"How do you mean?"
		
		"One of our kind, running about and spreading a fever among the humans? And Carothers was unable to stop him?"
		
		"Perhaps, but he has since been destroyed."
		
		Withers sniffs, incurious as to how. "I'm not even sure that Carothers should still be Quaestor of Memphis. Perhaps I should speak with the Governor."
		
		"If you think that's best," you reply.
	*else
		What is Gallagher's status? ${gallagher_status}
		*page_break
		*bug
		
*if flirting_with_withers
	*if maddox_status = "west"
		*set flirting_with_withers false
		*set withers_rapport %-15
		"It's really too bad you failed me, you know. I enjoyed your letters."
		
		She turns at a right angle to you, keeping a formal distance between you as you walk down the Pike.
	*elseif lied_to_carothers_about_pb = 3
		"I suppose I should shun you for your deceitful conduct."
		
		"But are we, if we are not creatures of deceit?" you reply.
		
		She shrugs. "I cannot find fault in your reasoning," she says with a smile. "After all, I have found your letters…invigorating."
	*else
		She pauses a moment considering her next words. "I have enjoyed your letters. They were…invigorating."
		
	*if flirting_with_withers
		"As I have enjoyed yours," you reply.
		
		*if withers_rapport > 55
			Taking you at your word, she threads her arm through yours and the two of you set out to enjoy the sights.
		*else
			As the two of you turn to walk, you note that keeps a formal distance between you.
*elseif withers_rapport > 55
	"${given_name}," she begins. "I thought I might see you here."
	
	"I hope that I have not put you out."
	
	"Not at all. It is a pleasure to see you again, in fact."
	
	She threads her arm through yours and the two of you set out to enjoy the sights.
*else
	"${mr} ${surname}," she begins.
	
	"Quaestor," you reply.
	
	The two of you turn to walk; you note that she keeps a formal distance between the two of you.

*temp convo_time 0
*temp discussed_james false
*label withers_convo
*if convo_time >= 3
	
	"If you will excuse me, ${given_name}, the night has quite gotten away from us."
	
	"So it has."
	
	"We shall meet again," she nods at you before you part.
	*return
*choice
	#"How is Vicksburg?"
		*set convo_time +1
		"It is fine, @{depot_burned no thanks to you.|thank you for asking.}"
		
		*if depot_burned
			"Are you still upset about that?"
			
			*if withers_rapport > 55
				"Upset? No. But I cannot forget it."
			*else
				"What do you think?"
			
			You try to pivot.
		"Do you have citizens?"
		
		"No, the town is still too small to support more than me."
		
		"I remember," you reply, shuddering at those nights of trying to feed from dead and dying Confederate @{(feeding_style = "vegetarian") pack-mules|soldiers}.
		
		"I assume the city has been rebuilt?"
		
		"It has."
		*comment TODO I want to say something about Confederate monuments here.
		
		"What of commerce?"
		
		"It has returned. Everything is as it should be."
		
		The pause is weighty; you take the bait. "How do you mean? What of the uprising against Peter Crosby?"
		
		"He resigned his position. It was improper for a black man to have authority over white men."
		
		*if ((justice < 35) and (discretion > 50)) or ((ethnicity = "african") and (compassion < 40))
			*set withers_rapport %-30
			"Were you always this much of a bigot?"
			
			"Excuse me?
			
			"The coloreds are where they belong? Tens of thousands of people just died to free the colored race. And you are happy that they are 'back where they belong?'"
			
			"I am."
			
			"Enough, then. Goodnight, Quaestor," you conclude before turning on your heel and marching away.
			*if flirting_with_withers
				*set flirting_with_withers false
				
				You do not imagine that your flirtation will continue after that particular confrontation.
			*return
		*elseif joined_kkk
			*comment really?
		*else
			"I see."
	#"How did your broodmate survive Sherman's March?"
		*set independence %+5
		*set convo_time +1
		Withers spits. Thankfully, in the dark, the blood-spittle will go unnoticed by the passers-by. "That monster nearly destroyed the entire State of Georgia."
		
		"So I have heard."
		
		"Theresa is fine, thank you for asking. But I suspect that she will relocate her court to Atlanta. Savannah, while charming, now seems too vulnerable."
		
		"I glad to hear that she is in one piece." You consider your next words very carefully. "Tell me, though: if you were in Sherman's position, would you have done things differently?"
		
		That question pulls her up short. She considers for several moments. "No, I would not. But that is cold comfort to my broodmate. And thus it is cold comfort to me."
		
		"Do you suspect another of our kind behind it?"
		
		Withers gets a faraway look her eyes. "I have struggled with that question. Mightily, in fact. But whatever machinations lie behind that campaign remain obscured to me."
		
		*if (compassion < 40) and (shepherd_credentials > 70)
			"Have you considered that it may have only been the doings of mortals?"
			
			"I suspect you mean that as some balm to my soul, but it is more of an irritant. In fact, it makes me wish to torture Sherman until the end of his days."
			
			"Fortunately for him, I suppose, he has already passed."
			
			"True, but his children thrive still."
		
	*if (maddox_status = "withers") #"What did you do with ${maddox}?"
		*set discretion %+5
		*set maddox_status "dead"
		"What do you think I did?"
		
		"Put him out to greet the sun?"
		
		"I leave it to your imagination, then," she replies.
	*if (watching_james) #Did Jesse James ever come through Vicksburg?"
		*set convo_time +1
		*set shepherd_credentials %+5
		*set discussed_james true
		"What a funny question! But, yes. Several times."
		
		"And you knew about it?"
		
		"Of course! I gave him a place to stay."
		
		"You…gave him a place to stay? Was he…one of us?"
		
		"No, of course not."
		
		"Then why would you give him a place to stay?"
		
		Withers bites her bottom lip. @{(perception > 2) You sense that she's preparing to deceive you in some way.|} "I agree with his causes. Why wouldn't I give him a place to stay?" @{(perception > 2) That wasn't a lie…but there's more to the story that she's not telling you.|}
		
		"I didn't realize you were so close to bandits."
		
		"One State's bandit is another's champion, ${given_name}."
	*if (discussed_james and carothers_ford_reveal) #"Then I suppose it was fortuitous that Carothers had James killed."
		*set discretion %+5
		*comment TODO what plot does this push forward?
		*if (withers_rapport > 65) or (willpower >= 3)
			Withers gasps. "What are you talking about?"
		
			"Carothers cultivated Charles Ford. It was a long gambit, but eventually Ford managed to kill James for him."
			
			"That…cretin! I cannot forgive him for this! I must tell Elinor immediately."
			
			"Tell Elinor?" you prompt.
			
			Withers's eyes go wide before she recovers her composure. "I'm sorry, dear ${given_name}. You must forgive me, but I should go."
			
			"Go? But we've only…"
			
			Picking her dress up from the dusty ground, looks at you, visibly makes a decision, and then strides away from you purposefully.
		*else
			You're standing in the middle of the Pike. You were just having a pleasant conversation with Withers. She must have excused herself, as you can see her nowhere about.
			
			Funny, you don't remember her saying goodbye.
		*return
	*if (shepherd_credentials > 65) and (intelligence > 1)
		*if ((month = 6) and ((francis_cockrell_resolution < 5) and (francis_cockrell_resolution > 1))) #"I hear that Francis Cockrell is vying to be the Democratic nominee at the upcoming convention. I met him during the siege."
			*set withers_trinket 2
			*set convo_time +1
			@{francis_cockrell_resolution |Clearly, Cockrell survived the night.|As you recall, Cockrell nearly got himself killed while you were watching.|As you recall, you helped Cockrell save a wounded soldier.|As you recall, Cockrell helped you save one of his wounded soldiers.}
			
			"Oh, Francis!"
			
			"You know him too?"
			
			"Of course! He came to dine several times at my home during the war…and after."
			
			"Did you intend to support him?"
			
			"He will never succeed. Roosevelt is too popular."
			
			"Then perhaps he should remove himself from the running…to save himself the embarrassment."
			
			She chews on her bottom lip for a moment.
			
			"Show him this, if you dare," she says. And, to your surprise, she takes off her necklace and hands it to you. "I expect for you to return that promptly, ${given_name}."
			
			"Yes, Quaestor," you reply, slipping the necklace into your @{male coat pocket|handpurse}.
	#I propose feeding together.
		*if (flirting_with_withers and (withers_rapport > 50))
			She relaxes ever so slightly. "I thought you'd never ask," she smiles, almost shyly.
		*elseif withers_rapport > 65
			She pulls away for a moment—almost offended—before she realizes it's you. She relaxes again. "Very well. Let's."
		*else
			*set overstreet_rapport %-10
			She pulls herself up as tall as she can, straigtening her shoulders. "I don't know what makes you think I am that kind of lady."
			
			"I thought you were a vampire."
			
			Her eyes narrow to slits. "You have severely misjudged me, ${mr} ${surname}. Goodnight."
			
			With that, she turns and melts into the crowd.
			*return
		
		The two of you spend the next hour seducing a young man from the Boer Concession. He speaks with a thick Afrikaans accent and enjoys the local lagers. He's more than happy to retire to a hotel room with the two of you—he thinks he's quite prepared to handled the two of you.
		
		The Afrikaaner is not prepared to be drained nearly to the point of death, and then for you and Withers writhe against one another while coated in his blood. Thankfully, when the two of you are finished, Withers makes sure he remembers nothing of the encounter.
		
		As Withers dresses, she shoots you a look. "I'm not the sort of vampire that just feeds with anyone, you know."
		
		"No, of course not."
		
		*if flirting_with_withers and (withers_rapport > 65)
			"This is, in fact, the first time I've done this," she confesses. "It was…"
			
			"Glorious?" you offer.
			
			She smiles. "Something like that."
		*set flirting_with_withers true
		
		The two of you part ways as night grows late.
		*return
	#"Have you seen any evidence of West in Vicksburg?"
		*set convo_time +1
		*set independence %+5
		Withers shakes her head no. "Thankfully, no. Everything that I have heard is him searching around St. Louis."
		
		"You heard of the death of one of Quaestor Fragalà's scions, yes?"
		
		"I had not!"
		
		"It seems he consumed one."
		
		"He likely deserved it."
		
		"The individual consumed?" you reply, incredulously.
		
		"No, Fragalà. Horrid little man that he is."
		
		"Horrid?"
		
		"Have you seen him?"
		
		"Well, yes. @{(compassion < 40) He has leprosy. That doesn't make him a terrible person.|I don't know if I would describe him as horrid, though.}"
		
		"To each their own, I suppose," she sniffs.
		*comment TODO what transpired in Vicksburg between Withers and Fragalà?
*goto withers_convo

*label yates_at_fair
*set spoke_stl_yates true

"Hello, Mr. Yates." 

He turns. @{(stealth > 2) He's clearly startled by your appearance. You forget, sometimes, to not hide yourself from the everyone.|} "Ah.
*if stlouis_tribune
	Our illustrious Tribune. How
*elseif ((ethnicity = "african") or (ethnicity = "choctaw")) and (robert_yates_rapport < 55)
	It's you." His tone drips with disdain. "How
*elseif trans and (robert_yates_rapport < 55)
	@{male Ms.|Mr.} ${surname}." His tone drips with disdain. "How
*else
	@{male Mr.|Ms.} ${surname}. How
may I be of assistance?"

*temp convo_time 3
Yates looks dashing in his suit and top-hat; the vest flatters his shape, and his cardinal tie is a surprisingly avante-garde choice.

"Shall we walk?" you say, gesturing towards the Chinese pavilion.

"Very well."
*temp harrison_question false
*if ((intelligence > 1) and ((shepherd_credentials > 55) or (independence > 55))) 
	*comment Carter Harrison, mayor of Chicago, was assassinated at the conclusion of the Columbia Exposition in Chicago in 1893.
	*set harrison_question true
*label yates_convo

*if convo_time = 0
	*if month = 9
		*return
	*else
		"Well, I should be off. The night is getting late and there are divertissements still to be enjoyed." He doffs his hat to you.
		
		"Goodnight to you, Mr. Yates."
		*return
*if convo_time < 3
	You sense the opportunity to ask another question.
*if convo_time = 3
	Entering the Chinese pavilion, you find it hard to concentrate on Yates's words. Between the tapestries, tea pots, suits of armor, and other objects that you don't even have words for, you find no end of things to marvel at. 

*label yates_convo_1
*choice
	#"I did not expect to see you here again, after your encounter with the Governor." Perhaps he will respond to sympathy?
		*set convo_time -1
		*set robert_yates_rapport %+5
		Yates sighs. "I can't say that she was wrong. O'Donnell did send me as a provocation."
		
		"It's not like you had much choice in the matter. She didn't have to treat you so horribly."
		
		"I would have done the same in her position. Or perhaps worse. I do not fault her for it."
		
		"That is very generous of you."
		
		He looks at you more closely. @{(perception > 4) [i]Idle flattery? Sycophancy? Deceit?[/i] All these thoughts run through his head as he seeks to judge the nature of your words.|You can sense his attempts to divine your intent.} "Generous. Yes."
		*goto yates_convo
	*if (harrison_question) #"Have you considered whether our mayor will expire before the Exposition is concluded?"
		*set convo_time -1
		Yates laughs. "I have heard that bets have been placed, yes, but I have no hand in them."
		
		@{(perception > 1) He's lying about something, but you're not sure what.|} "I suppose I'm glad to hear that," you quip.
		
		"Nasty business, that."
		
		"And O'Donnell had no hand in it?"
		
		Yates purses his lips. "I didn't say that."
		
		"Why would O'Donnell want to kill Mayor Harrison? Why not simply bend him to his will?"
		
		"Perhaps we should change the subject, ${mr} ${surname}," Yates suggests.
	#"Where are you from…from before all this," you say, gesturing towards the world, yet somehow indicating your condition of interminable unlife.
		*set convo_time -1
		*set robert_yates_rapport %+5
		"I was born in Setauket before the War of Independence. O'Donnell was new to New York at the time and needed someone to help him adapt. I came to the city on some business and he had his way with me."
		
		"Did you ever go back home?"
		
		"How could I? I was so hungry. I would have killed all of them."
		
		"Not even years later?"
		
		"I haven't been back since we left after the War of 1812. We eventually made it to Chicago, where O'Donnell planted his flag."
		
		"Would you go back if you could?"
		
		"And see my children's graves? Meet my grandchildren who believe that I abandoned them all? No, I could not do that."
		
		"We must all reconcile ourselves to our actions, Mr. Yates."
		
		"And some actions are irreconcilable," he retorts.
	#I propose feeding together—though it will likely take the rest of the evening.
		*set convo_time 0
		He looks at you and blinks—he was not expecting that.
		*if (revolutionary_credentials > 60) or (robert_yates_rapport < 35)
			"You disgust me."
			
			You pause. "That wasn't a no."
			
			You can see him struggling with something inside. "Lead the way," he says finally.
		*else
			"Why not?"
		
		The two of you spend the next hour tracking down the Ambassador from Mexico, who happens to be at the Fair. Getting past the Ambassador's entourage is a feat, but working together, the two of you manage to get the Ambassador alone in a private room in the rear of the Mexican pavilion. The two of you drink from him; while you are thrumming with his blood, Yates gets down on his knees and sinks his fangs into your inner thigh. You have never let a vampire drink your blood like this, but it is strangely intoxicating—knowing that he could probably kill you if he lost control for even a moment.
		
		He sucks the Ambassador's blood out of you and soon your body has grown cool again. The two of you reassemble your clothes and leave the Ambassador to his fitful dreams of tooth and claw.
		*set robert_yates_rapport %+5
		
		The two of you find yourselves outside the Chinese Pavilion once again. As a final act of tenderness, he wipes a fleck of blood from your cheek—then he is all business once again. "Was that all, ${mr} ${surname}?"
		
		"I believe so, Mr. Yates."
		
		"Well, I should be off. The night is getting late and there are divertissements still to be enjoyed." He doffs his hat to you.
		
		"Goodnight to you."
		
		"And to you," he says with a final wink.
		*return
	*if (convo_time < 3) #"How does this compare with the White City?"
		*set robert_yates_rapport %+5
		Yates pauses to consider.

		"The Ivory City is larger, I cannot deny it. I suppose it is more wondrous, yes. And the Olympics were certainly a coup. But the White City was the first time I saw a massive display of electricity; I'm sure you've felt it as well. How does one describe such a feeling of amazement? It is simply unforgettable."
		
		"Yes. I remember when @{pitchforks_in_saintcharles I arrived in Vicksburg and I saw gaslamps for the first time.|they first turned on the gaslamps in New Orleans.} It was wonderous."
		
		"You can understand why, then, I am hesistant to choose one over the other."
		
		"I do."
		
		"And yours has been…simpler, shall we say?"
		
		*if harrison_question
			"No dead mayors, no," you reply.
		*else
			*set harrison_question true
			He may be referring to the assassination of the mayor of Chicago, Carter Harrison, at the conclusion of the Exposition. Or he could be referring to H.H. Holmes and his murder hotel. Hard to say.
	*if (met_herbert_walker > 2) #"Are you close with Herbert?"
		*if met_herbert_walker = 4
			*set robert_yates_rapport %+5
			"He said that you helped him escape Vicksburg. During the war."
			
			"I did."
		*if met_herbert_walker = 3
			"He mentioned that he had met you. We are broodmates. We serve our dominus."
			
			"So, not terribly," you remark. 
			
			"No, I suppose not." He pauses. "You were in Vicksburg during the war as well?"
			
			"Yes."
			
		"Terrible business, that. Such a waste."
		
		@{(compassion < 50) With a niggling sense of dread, you ask:|} "How do you mean?"
		
		"All that human blood spilt. And for what? So some humans could be treated marginally better than they were before?"
		
		*if (compassion < 50) and (shepherd_credentials > 50)
			*if (ethnicity = "african")
				You suppress the urge to tear his throat out.
			"Did your people not coming to these shores looking to be treated marginally better than before?"
			
			"My mortal kin? Yes. But if you're seeking empathy from me, you will find none. Humans are sustenance. How they treat one another is of no import to me."
		*else
			*set robert_yates_rapport %+10
			"Did you feed well at the time, at least?"
			
			"That is hard to say. I drank my fill, yes, but the prey did not resist. Mortals that are too weak or sick to be afraid…that welcome my fangs…do not rouse my spirit, if you understand me."
			
			"You enjoy the hunt."
			
			"I do."
	*if (robert_yates_baseball = false) #"How do you occupy your eternal nights?"
		*set convo_time -1
		*set robert_yates_rapport %+10
		*set robert_yates_baseball true
		Yates laughs. "Of all the questions, that is not the one that I expected."
		
		"No? Does no one take interest in you?"
		
		That stops his laugh short. "No, they are interested in Seamus."
		
		"Well, tell me, how do you pass your immortality? You clearly enjoy distractions such as these…" you say, gesturing to the Exposition at large.
		
		"Actually, I am fascinated by the sport of baseball."
		
		*if baseball_failed
			*set robert_yates_rapport %-20
			"Oh, that," you snort.
			
			Yates looks you, clearly put off by your condescension. "I know that the sport did not find fertile ground here in St. Louis…"
			
			"It certainly did not."
			
			"But I'm sure it's only a matter of time before its appeal is rediscovered."
			
			"Not if the locals have anything to say about it."
			
			"I understand that the baseball franchise was somewhat at odds with more traditional Sunday entertainments here…"
			
			"It was."
			
			"You know, Germans throughout Michigan, Wisconsin, Ohio, and Pennsylvania enjoy both their baseball games in the afternoon and an operetta in the evening."
			
			"Is that so? How many touring groups have come to Chicago from London in the past decade?"
			
			"I don't…"
			
			"Very few. They come here. Maybe they go to Chicago for a long weekend, but they come here and stay for weeks, because they know they are appreciated."
			
			"You mean, they sell tickets."
			
			"How else would you say the public should show it's appreciation? By proclaiming their love and affection for something, and then never spending the time or money to support it?"
			
			*if convo_time = 0
				*if month = 9
					*return
				*else
					Yates bristles in frustration. "Well, if you will excuse me, I think this conversation has reached its logical conclusion."
					
					"Don't be angry, Mr. Yates. I only speak the truth.…" But he has already turned and moved away through the crowd.
					*return
			*else
				Yates starts to retort, but thinks the better of it. "Perhaps we should change the subject," he recommends.
				*goto yates_convo_1
		*elseif stl_vda_drama
			*set robert_yates_rapport %+5
			"By the sport, or by the antics of Mr. Von der Ahe?"
			
			Yates smirks at you. "I see I am not the only one fascinated by the man."
			
			"Certainly not!"
			
			"How someone can be that self-absorbed, egotistical…and yet convince others of his clarity of vision…I will never understand!"
			
			*if (rationalism < 40) and (intelligence > 2)
				"If you don't understand how people can wish to follow a leader…I mean, they see his success, and by supporting him—by allowing themselves to be duped by him—they imagine that a little bit of his shine reflects back onto them. Moreover, by buying into his vision, it means they don't have to work so hard at figuring things out themselves: they're given a story to believe, and they believe in it with all their might."
				
				"That is a rather bleak assessment of the matter, ${mr} ${surname}."
				
				"Do you think his patrons are all just idiots? People who, given just the right piece of evidence, would reject him?"
				
				"Of course! How could they not?"
				
				"When have you ever seen a devotee like that reject their idol based upon being shown contradictory evidence?"
				
				Yates purses his lips. "I don't suppose that I have."
			*else
				*set robert_yates_rapport %+5
				"Nor I! They are all fools."
				
				"It is fortunate that we are not so deceived."
				
				"Agreed!" Yates replies, companionably.
		*elseif memphis_baseball
			"Yes, I remember when I first noticed the game in Memphis. Mostly because the fever made people anxious to attend the games."
			
			"Yes, the fever. It was wretched, wasn't it?"
			
			@{bloodsweats "You have no idea."|"It was tragic."}
			
			"But the game? Have you watched one?"
			
			"I can't say that I have. They tend to be only during the day."
			
			"Of course! But you should make every effort to see one, given the opportunity. The team has recently be sold—twice—and is now known as the ${stl_cardinals}."
			
			"Thank you for the advice."
		*else
			"Baseball?"

			"Yes. They have sticks, and they try to hit a little ball 'out of the park,' as they say."
			
			"And why do they do this?"
			
			"I can't rightly say, but I cannot get enough of watching it."
			
			"I wonder if they have baseball here?"
			
			"They do! St. Louis has a team called the Browns. Or they were, anyway. Then the Perfectos, now the ${stl_cardinals}. It's a mess; I'm surprised you've managed to avoid it. You should go see them play sometime."
*goto yates_convo

*label democratic_national_convention
*comment July 6-9
*temp dem_parker "Parker"
*page_break
To add to the madness of the Exposition, the Democratic National Committee has chosen St. Louis to host the nominating convention this year. Of course, the last time the national convention was held in St. Louis, a Democrat won the vote but lost the election in exchange for the end of Reconstruction.

The past few elections have been dominated by Bryan and his advocacy for Free Silver, but his abstention from the race leaves Democrats scrambling for a candidate. Many have concluded that Teddy Roosevelt is simply too popular to defeat.

The leading candidates seem to be Alton Parker, a judge from New York; William Randolph Hearst, the newspaper magnate; Francis Cockrell, Senator of Missouri; Richard Olney, formerly Attorney General and then Secretary of State under Cleveland; as well as several other lesser candidates. 
*if (laborvscapital > 65) or (laborvscapital < 35)
	Parker recently upheld the right of States to limit the number of hours a week an employee can work. He is also a fierce opponent of the Free Silver movement.
*if (stlouis_enterprise = 1) or ((fed_from_pulitzer) or ((shepherd_credentials > 75) or (finance > 1)))
	Hearst is Joseph Pulitzer's main rival for command of the newspapers of the country. Hearst styles himself a supporter of the "little guy," as long as that little guy is white; his thirst of American imperialism is unquenchable.
*if (local_fame > 40) or (francis_cockrell_resolution > 1)
	Cockrell comes from a large family of politicians. He served with the Confederacy during the Vicksburg campaign.
*if (laborvscapital > 65) or (laborvscapital < 30)
	Olney was the individual who authorized and directed the use of force against the Pullman strikers in 1894.

Parker emerges as the frontrunner in the months prior to the convention. The wildcard here is Bryan; despite his defeats in the prior two elections, he is still the most popular Democrat in the country. If he supports Hearst, Hearst could win the nomination. If he supports Cockrell or Olney, Parker is likely to win. A number of influential individuals are seeking to cinch the win for Park in the first round of ballots, in the hopes that a protracted debate can be avoided.

With the delegates crowded into several hotels near the Coliseum, it would be quite easy for you to enter the fray. 
*if withers_trinket > 1
	As you discussed with Withers, the colonel whom you encountered in Vicksburg is standing for the nomination.
*else
	@{(francis_cockrell_resolution > 1) Observing several of the broadsides and pamphlets, you realize that you encountered Cockrell in Vicksburg. Yes, of course. He was the colonel drilling his men while Vicksburg was being shelled.|} @{francis_cockrell_resolution |Apparently, he survived the night.|He nearly got himself killed while you were watching.|You helped him save a wounded soldier.|He helped you save one of his wounded soldiers.}

*if francis_cockrell_resolution > 1
	Of course, simply introducing yourself to Cockrell would be dangerous; you are @{trans in some ways|} unchanged in forty years.

*choice
	#Roosevelt is so popular, I doubt that the Democrat will win whoever he is.
		*label parker_wins
		Perhaps you are correct.
	
		Parker wins the nomination in the first round, once a handful of votes are mysteriously re-cast. Bryan is incensed, but it is too late. The only moment of surprise arises when Parker threatens to reject the nomination if the gold standard is not added to the Democratic platform. Since the convention is in the hands of the conservative easterners, this demand is met almost immediately. The platform is revised and the convention concludes without further drama.
		*return
	#Interfering with presidential politics would be unwise; more powerful vampires than I are surely much more invested.
		*set discretion %-5
		*set independence %+5
		*goto parker_wins		
	#I seek out Bryan and encourage him to throw his authority behind Hearst.
		*set laborvscapital %+5
		You manage to make your way into an event at the Planter's House Hotel where numerous decision-makers have gathered to politick off of the convention floor. Almost every man in the room alternates between toking on his cigar or sniffing his brandy as they gossip about the candidates.
		*if (local_fame + (charm * 2)) >= 65
			Whether its your winning smile or your honeyed tongue, somehow you manage to convince Bryan that Hearst is the right candidate.
			*label hearst_wins
			*set exposure +2
			*set dem_parker "Hearst"
			
			The Democratic convention falls into chaos when Parker loses the first round of balloting. From there, speeches are given, hands are shook, and candidates withdraw their names.
			
			In ballot after ballot, the Hearst continues to hold the line while picking up the votes of the candidates who have withdrawn. Bryan gives another one of his electrifying speeches, and the tide begins to turn agaist Parker.
			*comment could do more here, with what/how to trade support of the NY delegation.
			
			Finally, Hearst is declared the winner. Parker and Bryan both pledge to do their utmost in electing their champion. In the following days, Hearst's newspaper empire carries the story of the reversed tide to readers across the country. In a nod to Bryan, Hearst even flirts with a return to bimetalism.
			*return
		*else
			Alas, you are not able to sway enough figures in the room to your side.
			
			You muse that Parker was destined to win.
			*goto parker_wins
	*if (francis_cockrell_resolution > 1) 
		*if (withers_trinket > 1) #I seek out Cockrell and show him Withers's necklace.
			*set discretion %+3
			*set withers_trinket +1
			You manage to make your way into an event at the Planter's House Hotel where numerous decision-makers have gathered to politick off of the convention floor. Almost every man in the room alternates between toking on his cigar or sniffing his brandy as they gossip about the candidates. 
			
			When you spot your quarry alone for a moment, you seize the opportunity: Cockrell blanches at the sight of the necklace.
			
			The next day, the word goes out that Cockrell has withdrawn his name from consideration. Hearst will clearly benefit from this change.
			*goto hearst_wins
		#I want Hearst to win; perhaps my knowledge of Cockrell can drive him from the race?
			*set laborvscapital %+5
			There is, in fact, a salon being held the night before the convention. It is mostly men in their suits, smoking cigars, drinking cognac, and reminiscing about the last gentleman's war, when soldiers stood up straight and tall, ready to be shot down by their enemies.
			
			In due time, the conversation comes around to Cockrell, and he is urged to relate the story of how he earned the Southern Cross of Honor. When he begins, you already know the story: the night he was drilling his soldiers and came under artillery fire.		
			*if francis_cockrell_resolution = 5
				*temp person "blank"
				*if trans
					*if male
						*set person "woman"
					*else
						*set person "man"
				*else
					*if male
						*set person "man"
					*else
						*set person "woman"
				Curiously, though, there is no mention of you in this story. When the soldiers are wounded by the shells, he describes how he ran to save them, despite the continued barrage. He gestures towards his scarred hand as proof.
				
				But you were prepared for this. @{(charm > 2) With sweet words|With a substantial donation}, you planted a question on one of the audience member's lips. When Cockrell finishes, your proxy stands and asks, "What about the ${person} that helped you?"
				
				Cockrell chuffs. "What ${person}?"
				
				"I have it on good authority that a ${person} carried your subordinate out of that field and into the bombproof that evening. That you wounded your hand cowering in the dark."
				
				The room erupts into shouting. Cockrell's face explodes with rage. You make a quiet exit.
				*page_break
				Cockrell's name is withdrawn from consideration before the convention officially begins. Bryan, apparently chastised, throws his support behind Hearst.
				*goto hearst_wins			
			*else
				He tells the story without embellishment. What he did that evening was an act worthy of an award, if an award was to be given to anyone. The fact that he was wounded in the action, and yet still saved the soldiers under his command, only confirms it.	
				
				Absent leverage, you leave the old men to their war stories.			
				*goto parker_wins

*label npc_honeypot
*page_break

About this time, you learn that an acquaintance of yours, Gaetano Baiamonte, has been arrested—nay, kidnapped—by the Pinkertons. You had warned Baiamonte that you didn't trust his new lover. Unfortunately, he did not listen to you; now the lover is being prepped to be the star witness in a trial for multiple counts of criminal sodomy@{stl_met_preston ; Jerome Preston's fingerprints are all over this particular intrigue|}.

Upon conviction, the laws in Missouri demand a minimum of ten years imprisonment—but life in prison is a sentence available to the judge to issue. 

The worker's movement is teeters on the edge of rage and embarrassement—some are angry at Gaetano for his perversions, others are furious that his sex life is deemed a criminal matter at all, still others see his arrest as the sign of a backlash against their successes.

*choice
	*selectable_if (wealth > 250000) #I fund Baiamonte's defense against these charges.
		*set wealth -50000
		*set stlouis_business_climate %+10
		*set compassion %-10
		*set exposure +1
		The trial is delayed several time due to Baiamonte's attorney's machinations. That gives the worker's movement time to distance themselves from Baiamonte and for the affair to fade from the news. Preston—or the people that hired him—see the matter stirred up again periodically, but then it too dies down.
		
		As for Baiamonte, he is ultimately found guilty and sentenced to ten years, but the lawyer you hired wins him confinement to the St. Louis Asylum instead of prison. A small concession, but an important one.
	#He was foolish to ignore my warnings; the movement can and will continue without him.
		*set stlouis_business_climate %+20
		*set discretion %+5
		*set compassion %+5
		*set shepherd_credentials %-15
		*if exposure > 6
			*set exposure -1
		Abandoning one of the motivating forces of the worker's movement to the judicial system goes over poorly. However, in time, new leaders will step forward to carry the burden on.
		
		Baiamonte, you later learn, is sentenced to fifteen years in prison.
	#I urge the unions to distance themselves from him.
		*set stlouis_business_climate %+15
		*set discretion %-5
		*set compassion %+10
		*set shepherd_credentials %-5
		Distancing themselves from one of the motivating forces of the worker's movement is a bitter pill to swallow; however, the disavowals do limit the damage that Baiamonte's trial and conviction inflict upon the cause.
		
		Baiamonte himself is sentenced to fifteen years in prison.
	*if ((streetwise > 2) and (charm > 2)) and speaks_english
		*selectable_if (wealth > 250000) #I bribe and cajole my way to freeing Baiamonte.
			*set wealth -20000
			*set discretion %+5
			*set compassion %-10
			*set stlouis_business_climate %+25
			The underpaid police are only too happy to look the other way as you establish an interlocking chain of corruption that results in Baiamonte being rendered to a waiting carriage at the rear of the prison.
			
			When his hood is lifted and he spies you waiting for him, he doesn't hesitate; leaping into the carriage, he shouts "[i]Andiamo[/i]!"
			
			Unfortunately, Baiamonte's escape is devastating for the worker's movement; fleeing from justice means that he is convicted of both his perversions and for disorder in the minds of the populace. 
			
			You are able to convey Baiamonte beyond the reach of the St. Louis authorities. You can only hope that some day he will balance the scales.
*return

*label pc_honeypot_1
*page_break
*temp eavesdropping false
*temp eaves_info false
*temp doubt false
*temp name_disclosed false
*if perception > 1
	*set eavesdropping true

Over the past few weeks, you have caught wind of an effort to organize a strike on behalf of the workers of the Exposition. The disparity in wages between men and women, blacks and whites, is notable—and the wage paid to white men is still nothing to celebrate.

The socialists and unionizers have been organizing meetings in a beerhall just south of Chouteau Ave.

This evening, a local firebrand by the name of Gaetano Baiamonte has just delivered a speech demanding better—and equal—pay for all the workers of the Exposition. A cheer has gone up. Then, the event breaks out into drinking and small discussions, while organizers work the crowd for donations.

You spy a stranger—an Irishman, by the sound of his lilt and the mop of ginger on his head—making a pitch to Baiamonte. Curious, you approach to where you can hear. @{(perception > 1) You suspect that they do not realize your interest, as, thanks to your vampiric senses, you are able to keep some distance between you. Though, the background noise of the hall does make the feavesdropping difficult.|}
*if lpe_member > 1
	*bug super-rare? why would a member of the LPE want to raid their own operation?

"I'm telling you, you can do it! One blow, and you'll bring them to their knees!"

"You get your hand on those tickets, and they'll have to listen to you. If you distribute them, the whole scheme will collapse. They can't print new ones. Not in time, and the people who've already bought theirs would be put out by that.

"You capture those tickets, and threaten to distribute them, or set them on fire, and they'll have to come to the table. And the best part is, you can't really be charged with nuthin'. It's just paper. It ain't money, food, whiskey…what are they goin' to do if this goes sideways? Making a bonfire?"

Baiamonte strokes his chin.
*if eavesdropping = false
	*gosub eavesdropping_convo
*label eavesdropping_choice

*choice
	*if (eavesdropping) #I want to approach the two and make sure I understand the details.
		*gosub eavesdropping_convo
		*goto eavesdropping_choice
	*if (eaves_info) #"How did you come by this information?" you inquire.
		The Irishman—Gregory, by name—toes the dirt. "My cousin works for the management office. He tipped me off."
		
		"And they're not going to look at him when this happens?"
		
		"Nah, he's a clerk in the livestock department."
		
		*if perception > 2
			*set doubt true
			Gregory's lying about something, but you're not sure what.
		*goto eavesdropping_choice
	*if (doubt) #"Did the Exposition bosses put you up to this? What's the scam here?"
		Gregory's eyes go wide. "No…no ${sir}! The bosses didn't do nuthin! They don't know anything about me!" he squeals.
		
		@{(perception > 2) On that account, at least, he's telling the truth.|}
	#"Seize the opportunity, Gaetano. Make them pay."
		*set laborvscapital %+10
		"You'll come with us, won't you? We can't do this without you, ${given_name}."
		
		*choice
			#"Of course I'll come with you."
				*set discretion %+5
				"That's the spirit!" he yells.

				The room breaks out into a cheer–even if the other workers don't quite know what they're cheering.
				*label ticket_raid
				*page_break A Few Nights Later
				The plan, such as it is, is for the workers to descend on the warehouse on the fairgrounds. There are plenty of torches and other flammable materials on the grounds that can be acquired and staged so that they are easily accessed on the night of the raid.
				
				The outlines of the plan are to subdue the guards around the building—a quick scouting trip reveals that there are four—and then for the workers to barricade the warehouse from the inside. Once inside, they'll wait for the security personnel and the police to arrive, at which point they will issue their demands.
				
				When the contract is signed, everyone will go home.
				
				You will not be able to stay through the day, which means that you cannot actually participate in the raid with them. But you can stand at a distance and watch.
				*page_break
				Everything goes according to plan…until the police show up much earlier than expected. But it's not only the police, but members of the posse that assaulted the streetcar strikers four years ago. 
				*temp dudes 1
				*if heard_of_jh_cavender 
					*set dudes 3
					*if met_stl_preston
						*set dudes 4
					You recognize John Cavender directing them, along with @{met_stl_preston the Pinkerton, Jerome Preston|a man whom you don't recognize}.
				*else
					*if met_stl_preston
						*set dudes 2
						The Pinkerton, Jerome Preston, is directing them along with a man with a military bearing whom you do not recognize.
					*else
						The police are under the direction of two men who are not in uniform; you do not recognize either of them. One has a military bearing, while the other is smaller and scrappier.
				
				From here, you can hear the police preparing to raid the warehouse. 
				*if perception > 1
					@{dudes The men in charge|Preston and the other man|Cavender and the other man|Preston and Cavender} inform the police captain that the warehouse contains rifles and other armaments and they don't want to give the criminals the opportunity to put them to use.
				*else
					You approach one of the police offers and express your dismay over what's happening. He tells you not to worry: some criminals have seized some rifles, but the ammunition is kept elsewhere. The police will handle the situation promptly.
				
				You return to your vantage point where you can watch this debacle unfold. The National Guards' torches illuminate the truncheons and rifles that their companions sport.
				
				Gaetano strides out of the warehouse. You can tell by his gait he hasn't opened the crates yet and assumes they were simply unlucky.
				
				@{(dudes > 2) Cavender|The military man} marches forward from to speak with Gaetano.
				*if (perception > 1) and speaks_english
					
					"Where is ${surname}?" @{(dudes > 2) Cavender|the military man} demands.
					
					Gaetano pulls up in surprise. "${mr} ${surname}? What do you want with him?"
					
					"Where is ${he}?"
					
					"Not here."
				*else
					The two exchange some heated words—Gaetano is clearly surprised and confused by the exchange. He says something with finality.
				And with that, @{(dudes > 2) Cavender|the military man} pulls out a revolver and shoots Gaetano dead between the eyes. His body crumples to the ground.
				
				*if speaks_english 
					"Arrest them all. If they resist, kill them," @{(dudes > 2) Cavender|the military man} says to the police.
				*else
					He barks something to the police.} Without hesitation, they descend on the warehouse with a battering ram.
				*set stlouis_business_climate %+15
				*set local_fame %-10
				
				There's no point in staying and watching the massacre.
				*page_break
				
				Over the next few days, the story is repeated breathlessly in the newspapers, how Gaetano Baiamonte and his band of violent socialists had raided an armory with the intention of starting an insurrection at the Fair. But, once again thanks to the brave leadership of John Cavender, the matter was stopped before it could begin.
				*set heard_of_jh_cavender true
				
				@{met_stl_preston There is no mention of Preston or the Pinkertons in any of the articles.|There is no mention of the scrappier man or any other involved organizations in the articles.}
				
				*if (perception > 1) and speaks_english
					Was all this to capture you?
				*else
					What was that all about?
				*set pinkerton_trap true
				
			#"It's best if you do it without me. I wouldn't want to steal the limelight."
				*set discretion %-5
				*set stlouis_business_climate %+5
				Gaetano nods; he really doesn't want you to take the limelight from him.
				
				Unfortunately, the matter seems to have been some sort of trap. News reports are confused, but there were no tickets in the building in question. Instead, there was a cache of Winchester rifles, kept on hand in case of emergency.
				
				When the socialists and unionists subdued the guards and broke into the warehouse, they were dismayed by their discovery—but more dismayed when the police arrived and immediately demanded their surrender.
				
				Baiamonte faces twelve years in jail for his role as a leader in the plot to arm the socialists and attack the "good, peaceful fairgoers."
				
				It goes almost without saying that, in the subsequent weeks, rumors proliferate among the workers that the whole matter was orchestrated by @{met_stl_preston Jerome Preston of|} the Pinkertons.
	#Actually, I'm going to find out where this cache of tickets is being held and steal some; surely, someone will want to buy discounted tickets to the Fair.
		*set laborvscapital %-10
		*set discretion %-10
		*gosub_scene util combat_value_ss
		"It's not worth it, Gaetano."
		
		"Good, I'm glad you see it my way," he replies.
		
		Gregory looks crestfallen, but turns to leave. While Gaetano moves on, you escort Gregory out of the beer-hall—and wheedle the location of the tickets from him along the way.
		*page_break A Few Nights Later
		When you arrive at the building, you note that it has four guards. @{(combat > 12) While you could probably kill them all, that would be pointlessly messy.|You don't think you could kill them all without losing control of yourself.}
		*if perception > 4
		
			Looking around, you have the sense that something is wrong.
			*bug
		
		*if stealth > 3
			However, waiting for the right moment, you can slip by them—assuming the door isn't locked, anyway.
			*page_break
			The doors are most certainly locked. However, the guards are not terribly careful with locking them every time they go in and out.

			You wait for the guards to leave the door open for just a moment too long and slip through unnoticed.
			*label pilfer

			Once inside, you pilfer through the crates. Strangely, you find no tickets. Instead, you find a number of rifles—even a Gatling gun!
			*if intelligence > 1
				Looking around further, you observe that there is no ammunition in the buildling.
				
				This was a trap of some sort. The lure of the tickets were meant to bring the workers here; but armed workers would clearly be a threat to the Fair and the city itself.
				
				Someone wanted a massacre.
				*set pinkerton_trap true
			*else
				Very strange indeed.
			
			You return the crates to their undisturbed condition and depart.
			
		*elseif agility > 3
			However, waiting for the right moment, you can run up the side of the building and scramble your way to the roof. As long as there's some way in up there.
			*page_break
			Eventually, you find a hatch that you are able to pry open. Carefully, you slip inside and down to the floor below.
			*goto pilfer
		*else
			You don't have a clever way to slip past the guards yourself.
			*temp thugs 1
			
			*choice
				*if (perception > 4) #I want to indulge my bad feeling and investigate the surrounding area.
					*set discretion %-5
					You walk through this portion of the Fair—mostly devoted to makeshift kitchens, loading and unloading of wagons, and the slaughtering of livestock—until you happen upon what must be a hundred police and National Guard sitting, smoking, and joking with one another.
				
					*comment TODO if I care; shouldn't be possible.
					*bug
				*selectable_if (charm > 3) #I will simply walk up to them and demand admission.
					*set discretion %+5
					*set thugs 2
					Emerging from the shadows, you approach the guard who looks most authoritative. You exert your will upon him and he submits almost instantaneously.
					
					You have him direct the other guards to follow you into the warehouse.
					*goto pilfer_public
				*if (stlouis_enterprise = 2) #I brought some thugs from the Kerry Patch to deal with these fellows.
					*set thugs 3
					You send the thugs in. Within moments, the guards are corralled and tied up.
					
					You leave one of the thugs at the door while the rest of you enter the warehouse.
					*label pilfer_public
					*page_break Ten Minutes Later
					There are no tickets here. There are, however, several crates full of rifles—even a Gatling gun—but no tickets.
					
					You also note that there's no ammunition, either.
					
					Realizing that this is bad news, you start @{thugs |to lead the guards|to lead your thugs} out of the warehouse, only to confront a platoon or more of police and National Guard waiting for you outside. They variously carry truncheons, rifles, and torches.
					*temp dudes 1
					*if heard_of_jh_cavender 
						*set dudes 3
						*if met_stl_preston
							*set dudes 4
						You recognize John Cavender directing them, along with @{met_stl_preston the Pinkerton, Jerome Preston|a man whom you don't recognize}.
					*else
						*if met_stl_preston
							*set dudes 2
							The Pinkerton, Jerome Preston, is directing them along with a man with a military bearing whom you do not recognize.
						*else
							The police are under the direction of two men who are not in uniform; you do not recognize either of them. One has a military bearing, while the other is smaller and scrappier.
					
					You are trapped.
					*set pinkerton_trap true
					*page_break
					
					*if stealth > 1
						*if thugs = 1
							You wait until the police raid the building. You hide until they've thoroughly searched the premises—one policeman screams in horror at the state of the corpses; they conclude that you must have fled before their arrival.
							
							@{dudes The men in charge express their frustration, even referring to you by name.|Preston and the other man stomp about, referring to you by name.|Cavender and the other man stomp about, referring to you by name.|Cavender and Preston stomp about, referring to you by name.} This was a trap for you.
						*elseif stealth > 2
							You direct the @{thugs ERROR|guards|thugs} to open the door for you. Trusting in your powers of misdirection, you walk out and away.
						*else
							You abandon the @{thugs ERROR|guards|thugs} to their own devices.
							
							They thrown down their weapons and plead for mercy from the police. @{dudes The two men in charge interrogate them, and then growl in disgust.|Preston and the other man interrogate the guards and then growl in disgust.|Cavender and the other man interrogate the guards and then growl in disgust.|Cavender and Preston interrogate the guards and then growl in disgust.} Notably, they refer to you by name.
							*if thugs = 2
								
								Finished with the guards, the men who hunt you wave them off and discuss.
								
								Clearly, this was a trap for you.
							*else
								*set local_fame %-5
								
								Finished with your thugs, @{heard_of_jh_cavender Cavender|the military man} pulls out a revolver and executes one…two…three…the fourth manages to scramble and run, but @{met_stl_preston Preston|the scrappier man} shoots him from behind.
								
								Clearly, this was a trap for you.
					*elseif (perception > 0) and ((agility > 2) or (strength > 3))
						Casting about, you spy a single hatch in the roof. @{(strength > 3) You can leap up there in a single bound.|You see how you can clamber up some crates and shimmy along a rafter until you reach it.}
						*if strength > 3
							Once there, you snap the lock with your bare fist and open the hatch.
						*elseif streetwise > 0
							Once there, you pick the lock as quickly as you can.
						*else
							*bug how does PC escape?
						
						Now on the roof, you can see the whole affair. Thankfully, everyone is concentrating on the only door, rather than the roof. The police are preparing to breach the building with a battering ram.
						
						You take the opportunity to climb down the back of the building and disappear into the night. The sounds of the police raid rise behind you.
					
					*else
						And there, in a warehouse full of weapons with no ammunition, you make your last stand.
						
						The police were apparently anticipating something more than a handful a toughs. They come in with their guns blazing.
						
						You try to take as many of them down with you as you can, but their numbers are too great.
						
						Finally, your body riddled with bullets, a machete is drawn by @{dudes the military man|the military man|Cavender|Cavender}. It falls on your head several times, until your eyes are crushed, and again until the blackness swallows you.
						
						*set killed_by_hunter true
						*goto_scene scoring
						
				*selectable_if (combat > 12) #Messy is acceptable to me. I kill the guards.
					*set discretion %+10
					*set compassion %+10
					*set exposure +1
					@{(shapeshifting > 2) Claws|Fangs} extended, you pounce.
					
					When you come to your senses, the exterior of the warehouse is sprayed with blood and gore. You drag the bodies inside, take a few moments to clean your face and otherwise make yourself presentable, and proceed to pilfer through the crates.
					*goto pilfer_public
										
				#Better to let the matter drop.
					*set discretion %-5
					You return home, some what disappointed.
					
					*if finance > 0
						However, a few hundred scalped tickets would have almost been more work than they were worth. You decision was probably wise.

	*if (doubt) #"Thank you, Gregory. No need to tell us anything more. We're not interested"
		*set discretion %-5
		Gregory looks at you, confused. But with a little glare, he wilts and retreats.
		
		"${given_name}?"
		
		"I didn't trust him."
		
		"If you say so," he replies.
	#This man is a fool. The executive director will never negotiate with them. I'm done with this nonsense.
		*set discretion %-5
		*temp mind_business true
		*if eavesdropping
			Your decision made, you fade into the night.
			
			To your relief, Gaetano does not pursue the matter further.
		*else
			"Gregory, neither the city nor the executive director will negotiate with you. I appreciate your enthusiasm, but I suggest you either swipe a few to line your own pockets or let the matter drop entirely."
			
			"You know, I heard that ${given_name} had stones. I guess I heard wrong." He raises his voice. The volume in the room drops noticeably, as the workers stop to observe.
			*label got_stones
			
			*choice
				*if (charm > 3) #I exercise my powers of persuasion to drop the matter and leave.
					*set discretion %-5
					"I think you should let the matter drop, comrade. The night is late and you should be in bed."
					
					Gregory's mouth opens and closes like a struggling fish, before he nods and departs.
					
					The room rumbles in mild disappointment.
				*if (male = false) #"Clearly, you are mistaken," you reply. You are a woman, after all.
					The evokes a bit of a laugh from the room.
					
					Gregory huffs, turns, and leaves. You hear nothing more of the matter.
				*if ((discretion < 45) or (willpower > 3)) #"You heard wrong."
					*label sighs_in_disappointment
					*set discretion %-10
					*set local_fame %-10
					The room sighs in disappointment.
					
					Gregory huffs, turns, and leaves. You hear nothing more of the matter.
				#"And what of it?" You can't let him shame you in front of your associates. Your influence with them would surely diminish.
					*set discretion %+5
					The room goes still with anticipation.
					
					"@{male A man with stones|The word I hear about you, you} wouldn't turn away from an opportunity like this."
					
					You survey the room. He's right.
					*label stuck
					
					*choice
						#"Gaetano, let's seize those tickets."
							*set discretion %+5
							Gaetano smiles. "[i]Bravissimo, @{male fratello|sorella}[/i]!"
							*goto ticket_raid
						*if ((discretion < 45) or (willpower > 3)) #"Then perhaps you misunderstood this situation."
							*goto sighs_in_disapppointment
						*if (mind_business) #"Perhaps you should mind your own business."
							*goto gregory_mind_business
						#"Why don't we take this out back?"
							*set discretion %+5
							You lead the way out back. 
							*if male = false
								*set combat -1
								Once outside, he looks left and right as though seeking confirmation that he's really about to scrap with a woman. But no one intervenes on your behalf.
							The two of you raise your fists, and when the moment seems right, the fight begins.
								
							*if combat > 7
								*if male = false
									*set exposure +1
								*set local_fame %+5
								With a single blow from you, his head snaps back and he collapse into the arms of the onlookers. Blood dribbles from his nose and mouth.
								
								"Didn't anyone tell him not to make me angry?" you say, trying to turn this little display ito a joke. The workers laugh it off; several of them drag Gregory out to the street and leave him there.
							*elseif (combat > 5) and (willpower > 1)
								*set local_fame %+5
								*set exposure -1
								Several minutes—and a number of grunts and groans by both parties—later, Gregory is crying "uncle!" while you press his face into the dirt. You very much want to drink his blood, but that would be the wrong whim to indulge in front of this crowd.
								
								You release him and return inside with Gaetano and the rest of the workers.
							*else
								*bug what do do here?
				#"Perhaps you should mind your own business."
					*label gregory_mind_business
					*set mind_business false
					He puffs out his chest. "What's the problem. Are you scared of what these folks might accomplish if you get out of their way?"
					
					"Be careful, Gregory."
					
					"Be careful or what? Of making you look bad?"
					
					*if discretion > (65 + (bloodflow * 2))
						You stand up and get in his face. No mortal can insult you like this. Certainly not in public. Not in front of those who do your bidding.
						
						"Of making me angry," you say.
						*if strength > 3
							*set exposure +2
							*if male = false
								*set exposure +1
							Putting your hand on his chest, you send him flying backwards.
							
							He flies through the crowd, through a window, and out into the street. The sound of shattering glass brings the entire room to a standstill. The workers don't quite understand whether they should cower in fear or cheer your name.
							
							Some base instinct tell them to pretend it all didn't happen—lest you turn your attention to them next. And so, like little mice, they go back to their beers and their individual conversations.
							
							Gregory has the good sense not to come back inside.
						*elseif combat > 7
							*if male = false
								*set exposure +1
							*set local_fame %+5
							With a single blow from you, his head snaps back and he collapse into the arms of the onlookers. Blood dribbles from his nose and mouth.
							
							"Didn't anyone tell him not to make me angry?" you say, trying to turn this little display ito a joke. The workers laugh it off; several of them drag Gregory out to the street and leave him there.
						*elseif (combat > 5) and (willpower > 1)
							*set local_fame %+5
							*set exposure -1
							
							You step forward and slap him across the face. He looks at you in surprise.
							
							You turn and head into street behind the beer-hall.
							*page_break
							Several minutes later, Gregory is crying "uncle!" while you press his face into the dirt. You very much want to drink his blood, but that would be the wrong whim to indulge in front of this crowd.
							
							You release him and return inside with Gaetano and the rest of the workers.
						*else
							*bug what do do here?
					*elseif charm > 3
						You glare at him. But when you glare at someone—a mortal, anyway—it takes on a new dimension.
						
						Something inside Gregory breaks. He takes his hat off, apologizes, and flees the beer-hall.
						
						You hear nothing more of these tickets.
					*else
						
						If you back down now, you will look the coward.
						
						You could "take this outside," and do your best to beat Gregory down outside, but if you lost control of your beast, it could get very messy very quickly.
						*goto stuck
			
	*if (eavesdropping) #I'm going to let Baiamonte make his own decision here.
		*set discretion %-5
		*set name_disclosed true
		"Come on! What kind of leader are you?" the Irishman presses. "Where's ${given_name}? I hear ${he}'s got some stones."
		
		That catches your attention.
		*choice
			*selectable_if (discretion < 60) #I approach. "How do you know my name?"
				The Irishman wheels to face you. 
			#I approach. "No one calls me a coward."
				*goto mind_business
			*selectable_if (discretion < 40) #I remain hidden. I find it suspicious that this man knows my name.
				"${given_name} is around here somewhere. I saw ${him} earlier this evening. Maybe you can convince ${him} to help you pull this off."
				
				"Oh! Where is ${he}?"
				
				*if stealth > 1
					Thankfully, you'd concealed yourself out of instinct.
					
					"I'm not sure. But ${he}'s around here somewhere. I just saw ${him}," Gaetano affirms.
					
					The Irishman nods, thanks Baiamonte, and then begins to peregrinate through the beer-hall.
				*else
					"Right there," he says, pointing you out.
					
					You scowl at Gaetano as the Irishman approaches. "I'm Gregory…and I hear you're the @{male man|woman} I should talk to."
					
					"Oh?" you reply, skeptically.
					
					"You want a revolution, don't you?"
					
					*if (laborvscapital > 60) and (justice > 55)
						"I'm listening."
						
						"Well, I can't help you with that. But the wages at the Fair are shit. It barely covers room and board."
						
						"And?"
						
						"If we seize their tickets and threaten to sell them or burn them, they'll have to negotiate."
						
						*choice
							#"Gaetano, let's seize those tickets."
								*set discretion %+5
								Gaetano smiles. "[i]Bravissimo, @{male fratello|sorella}[/i]!"
								*goto ticket_raid
							*if ((discretion < 45) or (willpower > 3)) #"Then perhaps you misunderstood this situation."
								*goto sighs_in_disapppointment
							*if (mind_business) #"Perhaps you should mind your own business."
								*goto gregory_mind_business
					*else
						"You heard wrong."
						
						Gregory seems surprised. "But…I heard told you wanted what's best fer the workers, and that you had the stones to see something like this through."
						
						"The stones?"
						
						Gregory raises his voice. "Yeah, the stones." The volume in the room has noticeably diminished, as the workers turn to watch the drama.
						*goto got_stones
*return
	

*label eavesdropping_convo
"What do you think, ${given_name}?"
*set eaves_info true
*set eavesdropping false
	
"Your friend here wants you to seize the Exposition's tickets? To force them to negotiate with you over wages?"

"Yes."

"Clever. Do you think they'll negotiate?"

"How can they not? It'll take weeks to get new ones printed. They'll have to either try and take money at the gates, which would invite robberies, pickpockets, and con-men, or let everyone in for free—and bankrupt themselves."
*return

*label return_trinket
*page_break
About this time, you realize that you should return Withers's necklace to her.
*if withers_trinket = 2
	Though you never used it, you @{literate write|dictate} a note to her, thanking her for lending it to you.
*else
	You @{literate write|dictate} a note to her, thanking her for the favor.
*comment TODO give opportunity to keep the trinket?
*return

*label negro_day_prep
*page_break
*comment August 1st. Organized by Walter Farmer and David E Gordon. They had invited Booker T. Washington, who had assented to come, but had to cancel the day because the Fair refused to pay for uniforms and accommodations for the 8th Illinois Regiment, a colored regiment that had intended to parade as part of Negro Day. Without the parade, the event was preemptively declared a failure and cancelled.

As part of the festivities associated with the Exposition, August 1st has been declared as Negro Day. The 8th Illinois Regiment, the first regiment in history to be commanded by black officers, was to lead a parade through the Exposition. Black intellectuals, led by Booker T. Washington, had announced their intention to come and deliver speeches and lectures on the state of the colored race in the United States, forty years after the Civil War. The day is being organized by Walter Farmer, the lawyer who defended Harrison Duncan in his murder trial.

However, as June's long days—and short nights—slip by, a controversy erupts; the Exposition had promised the pay for uniforms and accommodations for the soldiers coming from Chicago, but suddenly, the LPE Committee has changed its mind. In particular, whereas the other regiments on display will be quartered in the Exposition's barracks, housing the 8th there would violate segregation laws; the Committee has offered a field for the 8th to camp in, but they would have to supply their own tents. Similarly, the white cooks tending the older soldiers cannot serve meals to the black soldiers; therefore, the 8th would have to provide its own rations.

Farmer and the other organizers are on the verge of cancelling the entire event; without the parade, much of the draw of the day will be lost.

*choice
	#If the LPE Committee does not wish to honor its agreements, then why should the black community spend its money at the LPE?
		*set discretion %-5
		*comment any other effects?
		Absent any intervention, the parade is cancelled; without the parade, on July 3rd, Farmer cancels the rest of the associated events.
		
		The Committee has made it clear: the only blacks at the Fair belong in the human exhibitions wearing primitive costumes or performing in the mistrel shows.
	*if (lpe_member > 1) #I urge the LPE Committee to honor its agreements. 
		*set justice %-5
		*if stlouis_race_relations > 60
			*set negro_day 3
			*set lpe_success %+10
			The LPE Committes considers your plea, and after much debate, reverses their previous decision.
			
			The Committee sends a telegram to Chicago, while several tailors are hired to begin work on the uniforms.
			
			The city steels itself for the day.
		*else
			The LPE Committee considers your plea, but ultimately rejects it. In their rejection, they point to any number of recent racially-motivated clashes in the city; to support the event would be to invite violence.
	*selectable_if (wealth > 500000) #Some tents, uniforms, and meals? I can pay for the soldiers' needs.
		*set wealth -50000
		*set exposure +1
		*set local_fame %+10
		*set discretion %+10
		*set negro_day 4
		*set result -1
		Farmer is thanks you for your offer, but does express some concern—this is not ultimately about money. But you insist, and you see that his own pride is on your side.
	#Even if there is no parade, the lectures can still be given! I will urge Farmer to press on.
		*if (local_fame > 45) and (wealth > 50000)
			*set negro_day 2
			*set wealth -10000
			Farmer listens to you carefully, finally assenting to your request—on the condition that you use your influence to make sure every seat in the lecture hall is occupied.
			
			You promise him that those seats will be filled if you have to buy the tickets and hand them out yourself.
		*else
			Farmer thanks you for your interest, but declines. Without the parade, the attendance will be minimal. A minimal attendance will be embarrassing both to the lecturers and to those who are seeking to organize the event. More importantly, a poorly-attended event will become fodder for whites' arguments about the hierarchy of the races.
	#It's better that there isn't a Negro Day; the Exposition shouldn't be politicized by making a day all about freedmen.
		*set justice %+20
		Surely not. This is a exhibition of the successes of these United States and the progress of human history leading up towards this moment in history. There are no political agendas here.
*return

*label handicap
*page_break
*temp race 1
*temp follow_race false
*temp vda_interfere false
*temp jesse_text "I'm not helping Jesse."

The World's Fair Handicap will be here in only a few days. It's being held at the Fairgrounds@{stl_met_tilles —one more track owned by Tilles and his partners|}. Everyone who cares about such things is atwitter over the arrival of the famous Hermis and his jockey Redfern. Many celebrities will come to the Exposition, yes, but not all of them are sixteen hands high.

*if promised_jesse = 3
	Of course, you promised Jesse that you would help his horse Moharib win the race…by any means necessary. @{betrayed_jesse And then you turned around and divulged his plan to Draper.|}
*elseif requested_by_jesse
	Of course, Jesse wants you to help his horse win, but you have not promised that you will interfere. @{betrayed_jesse And then you turned around and divulged his plan to Draper. However, if|If} you are to meddle, now is the time. 
*elseif promised_jesse = 1
	*set jesse_text "As I told Jesse, I'm not getting involved."
	Of course, you told Jesse that you wanted no part of his @{betrayed_jesse scheme, and then you revealed it to Draper|scheme}.
*else
	*choice
		#I don't care about this horse race. @{vda_race Von der Ahe is on his own.|}
		#@I'm curious to @{knows_jesse_race see if Jesse's Moharib|know who} wins.
			*set follow_race true
		*if (vda_race) #I might want to help Von der Ahe and his friend's horse, Colonial Girl.
			*set vda_interfere true
*if vda_race and (vda_interfere = false)
	*set jesse_text "I'm not helping Jesse or Von der Ahe."
	
*if knows_jesse_race
	*set follow_race true
	*choice
		#${jesse_text} Whoever wins the race will win it fair and square.
			*if promised_jesse = 3
				*set jesse_rapport %-10
		*if (shapeshifting > 0)
			*selectable_if (shapeshifting > 1) #@{(shapeshifting > 1) I convince the horses to let Moharib win.|My powers are not developed enough to allow me to command the horses.}
				*set discretion %+3
				*if stealth > 1
					*set race 2
					It is no small feat infiltrating the stables. There are numerous guards posted to keep a watchful eye out for shenanigans. But you make your way inside and, after a lengthy conversation about oat allotments, you convince the horses to defer to Moharib. Hermis is particularly amused by the whole thing; he likes the idea of letting the younger man take the lead for once.
				*else
					Unfortunately, your talent for infiltration is not as developed as you might like. Try as you might, you cannot penetrate the stables without being discovered.
					
					You resign yourself to letting the race play out as fate intends.
			*selectable_if (shapeshifting > 1) #@{(shapeshifting > 1) I betray Jesse by convincing the horses to let Hermis win.|My powers are not developed enough to allow me to command the horses to let Hermis win.}
				*set discretion %+5
				*if stealth > 1
					*set race 3
					It is no small feat infiltrating the stables. There are numerous guards posted to keep a watchful eye out for shenanigans. But you make your way inside and, after a lengthy conversation about oat allotments, you convince the horses to defer to Hermis. The other horses begrudingly agree to steer clear of the champion.
				*else
					Unfortunately, your talent for infiltration is not as developed as you might like. Try as you might, you cannot penetrate the stables without being discovered.
					
					You resign yourself to letting the race play out as fate intends.
			*if vda_interfere
				*selectable_if (shapeshifting > 1) #@{(shapeshifting > 1) I convince the horses to let Colonial Girl win.|My powers are not developed enough to allow me to command the horses.}
					*set discretion %+3
					*if stealth > 1
						*set race 4
						It is no small feat infiltrating the stables. There are numerous guards posted to keep a watchful eye out for shenanigans. But you make your way inside and, after a lengthy conversation about oat allotments, you convince the horses to defer to Colonial Girl. Hermis is particularly amused by the whole thing; he likes the idea of letting a mom take the lead for once.
					*else
						Unfortunately, your talent for infiltration is not as developed as you might like. Try as you might, you cannot penetrate the stables without being discovered.
						
						You resign yourself to letting the race play out as fate intends.
		*if (((stlouis_enterprise = 2) or (streetwise > 2)) and (wealth > 50000))
			#I use my connections in the underworld to lean on the jockeys and make sure Moharib wins.
				*set race 2
				*set wealth -5000
				It costs you a surprising amount of money to grease the wheels, but you do. Moharib is guaranteed to win.
			#Though I betray Jesse's confidence, I will use my connections in the underworld to lean on the jockeys and make sure Hermis wins.
				*set race 3
				*set wealth -5000
				It costs you a surprising amount of money to grease the wheels, but you do. Hermis is guaranteed to win.
			*if vda_interfere
				#I use my connections in the underworld to lean on the jockeys and make sure Colonial Girl wins.
					*set race 4
					*set wealth -5000
					It costs you a surprising amount of money to grease the wheels, but you do. Colonial Girl is guaranteed to win.
*elseif vda_interfere
	*set follow_race true
	*choice
		#I do nothing to benefit Chris Von der Ahe. Whoever wins the race will win it fair and square.
			*set discretion %-5
		*if (shapeshifting > 0)
			*selectable_if (shapeshifting > 1) #@{(shapeshifting > 1) I convince the horses to let Colonial Girl win.|My powers are not developed enough to allow me to command the horses.}
				*set discretion %+3
				*if stealth > 1
					*set race 4
					It is no small feat infiltrating the stables. There are numerous guards posted to keep a watchful eye out for shenanigans. But you make your way inside and, after a lengthy conversation about oat allotments, you convince the horses to defer to Colonial Girl. Hermis is particularly amused by the whole thing; he likes the idea of letting a mom take the lead for once.
				*else
					Unfortunately, your talent for infiltration is not as developed as you might like. Try as you might, you cannot penetrate the stables without being discovered.
		*if (((stlouis_enterprise = 2) or (streetwise > 2)) and (wealth > 50000))
			#I use my connections in the underworld to lean on the jockeys and make sure Colonial Girl wins.
				*set race 4
				*set wealth -5000
				It costs you a surprising amount of money to grease the wheels, but you do. Colonial Girl is guaranteed to win.
				
*if follow_race
	You arise the night of the race to discover that @{race Colonial Girl|Moharib|Hermis|Colonial Girl} has won.
	*if race = 1
		Apparently, just out of the starting gate, Judge Himes—another of the horses—kicked Hermis in the leg. While Hermis recovered and was in the lead for most of the race, Colonial Girl seized the opportunity coming down the home stretch to pass Hermis just in time for the win. @{knows_jesse_race Apparently, Moharib wasn't much of a challenger.|}
		
		@{knows_jesse_race You hope Jesse has learned his lesson.|}
	*elseif race <= 3
		You hurry to the Fairgrounds to watch the exchange. The journey is relatively swift, as most are leaving the Fairgrounds, rather than attempting to gain entry. ${stlouis_valet} stops for only a moment before you burst from your coupé and rush to the stands.
		
		Arriving there, you spy Jesse in the flesh. He stands at one end of parade ground. At the far end is @{met_draper John Draper|a man who must be John Draper|an individual you don't recognize}. There are a number of grooms and other hangers-on standing about, preparing for the exchange.
		
		*if race = 2
			Jesse stands haughtily, waiting for Draper to approach him. Finally, Draper strides forward stiffly, leading Hermis with surprising care. @{betrayed_jesse You can sense his anger at the situation.|}
			
			Just before reaching Jesse, he turns Hermis's head and touches his forehead to that of the horse. He strokes Hermis's neck and whispers something to him.
			
			When the moment passes, he returns his attention to Jesse. @{(perception > 1) "A bargain made is a bargain fulfilled."|He says something, but they are too far away for you to catch it.} Jesse extends his hand, gesturing for Draper to hand over the reins. Finally, he does. @{(perception > 1) "Take care of him," Draper says, before backing away.|Draper backs away, slowly.}
			
			@{(perception > 1) "I will," replies Jesse.|Jesse says something with a smile.} At which point he pulls a derringer from his sleeve and shoots Hermis in the skull.
			
			*page_break
			*temp tock false
			
			Draper howls in fury. He lunges towards Jesse, but Jesse stands firm, gesturing every so slightly to the dozens of mortal witnesses watching in shock and horror. Draper pulls himself up just before striking Jesse, resorting instead to angry gesticulations.
			*if betrayed_jesse
				*set draper_rapport %-50
				*set tiozzo_rapport %-40
				*set compassion %+5
				*set jesse_rapport %+15
				*set tock true
				Amid these, he catches sight of you.
				
				"And you!" he practically screams. "Why would you reveal Whitaker's scheme, only to follow through on it?"
				
				Jesse looks at you with a mixture of surprise and amusement. When you do not shout an answer down to the field, Draper turns on his heel and stalks away.
				
				You descend to the track, where Jesse greets you warily. "You betrayed my confidence?"
				
				"So I did."
				
				"And yet you rigged the outcome anyway?"
				
				"You're about caught up."
				
				Jesse guffaws. "I didn't think it was possible to make him more miserable, but you have succeeded. Well done, ${given_name}, well done!"
			*else
			
				The derringer has long-since disappeared. Jesse turns his back on Draper and saunters off the field.
				
				*page_break
				
				"Well done, ${given_name}," Jesse says, clapping his hands in delight at your appearance.
			*temp tick false
			
			*if (compassion < 35) and (tock = false)
				*set jesse_rapport %-15
				"You killed Hermis!"
				
				"So I did. What use did I have for a horse?"
				
				"You did all that…"
				
				He rolls his eyes at you. "Come now, ${given_name}. You are nearly a century dead now!
				*if jesse_is_broodmate and (avoided_new_orleans = false)
					Did you not learn the lessons our dear dominus sought to teach us? I have no interest in being your mentor in his absence.
				*elseif jesse_is_broodmate
					Though you spurned our dominus's education, I would have thought that you would have learned the ways of unlife by now.
				*elseif (avoided_new_orleans = false)
					I suppose that my dominus wasted his time trying to teach you the ways of unlife. Well, I have no intention of doing the same.
				*else
					I know you spent your early years in the bayou, but surely by now someone has taught you something of our kind? Regardless, it is not my duty to do so.
				Moreover, you helped me! Are you rejecting my favor?"
				
				"I am."
				
				He sniffs. "So be it."
				
				You turn and storm away into the night.
				*if jesse_rapport < 50
					You chastise yourself all the way home—you should have known better than to trust that monster.
				*return
			*elseif compassion < 55
				*set tick true
				*set debt_from_jesse true
				"Was that truly necessary?"
				
				"Why, yes, it was!"
				
				"I think you have gained yourself quite an enemy this evening."
				
				"He was already an enemy, he just didn't know it yet."
				
				"We never discussed the terms of this favor…" you venture.
				
				"Yes, yes, a debt is owed."
			*else
				*set debt_from_jesse true
				"That was quite a show."
				
				"Thank you," he replies with the faintest hint of a bow. A moment passes. You clear your throat. "Ah, yes, well, I suppose a debt is now owed. Very well."
				
			You nod your head. "A fair exchange."
			
			*if jesse_rapport > 60
				"Would you like to feed together?" he offers.
				
				*choice
					#I politely decline.
						He accepts your refusal with grace and the two of you part ways.
					*if (tick) #I decline abruptly. I'm quite disappointed in Jesse's conduct here.
						*set jesse_rapport %-5
						He seems surprised at your disapproval. The two of you part ways without further discussion.
					#How could I resist?
						*set jesse_rapport %+5
						*set compassion %+5
						The two of you find a young man selling his body near the train station. The three of you retire to Jesse's accommodations at the Southern, where you feast on the youth.
						
						Jesse reclines in the afterglow of both victory and consumption. In a moment of intimacy, you lay your head on his breast while prostitute's body grows cool on the floor beside the bed.
						
						Jesse will owe an apology to Bailey—at the least—for the mess that the two of you have made here.
						
						As dawn draws near, Jesse informs you that he is leaving St. Louis soon. He came only for the race—other obligations call him away. You nod, straighten your clothes, and leave for your ${sleeping_place}.
			*else
				"Now, if you will excuse me, I wish to enjoy the afterglow of my victory."
				
				"Good evening, then," you say before departing.
		*else
			Draper waits for Jesse to lead Moharib to him. He takes the reins from Jesse and pats Moharib affectionately on his neck. They exchange a few words before Jesse departs.

			*if betrayed_jesse
				*set draper_rapport %+10
				*set tiozzo_rapport %+5
				Draper takes Moharib and Hermis back to the stables, whereupon you join him.
				
				"Yes?" he inquires.
				
				"I wanted to congratulate…"
				
				"I don't take kindly to cajolery, ${mr} ${surname}. You come seeking a debt, but I have offered and do offer you none."
				
				"Mr. Draper…"
				
				"You did nothing, as you should ought to have. I will not reward you for that. Be grateful for my gratitude."
				
				You nod your head; you will achieve nothing further here.

				Draper turns back to Hermis, who stomps impatiently; it seems he is ready to race again.
			*else
				Draper takes Moharib and Hermis back to the stables; Hermis has another race in just a few weeks.
	*else
		You arrive at the Golden Lion to find Von der Ahe beside himself with delight. When he sees you, he grasps your face with both hands and kisses you square on the lips. "[i]Herrlich[/i]!" he exclaims, rushing to fetch you a whiskey.
		
		You wave his proffered drink away. "My assistance comes with a price, Mr. Von der Ahe."
			
		"Anything!"
		
		*if sporting_goods = 2
			"I want to be a full partner in ${spalding_sporting_goods}." He blanches. "You wouldn't want…" you leave the sentence unfinished.
			
			"Vine! You are now my partner!"
			*set sporting_goods 3
			*set income +15
			*set wealth -10000
			
			"My lawyer will see to the papers," you say. You rap your knuckles on the bar and depart.
		*elseif sporting_goods = 3
			"I want you to sell me your half of ${spalding_sporting_goods}. For a very good price." He blanches. "You wouldn't want…" you leave the sentence unfinished.
			
			"Vine! It ist yours!"
			*set sporting_goods 4
			*set income +15
			*set wealth -125000
			*if wealth < 0
				*bug Run wealth loop!
			
			"My lawyer will see to the papers," you say. You rap your knuckles on the bar and depart.
		*elseif (browns_saved > 2)
			TODO What else would you want from VDA?
		*else
			TODO What else would you want from VDA?
*return

*label gabriel_arrives
*page_break
*set knows_gabriel true
You can't say that you're surprised when one of your confidantes among the city's demimonde informs you that a young man has been seen at the Fair that fits the description of Gabriel, the Vampire of Cincinnati. Apparently, the stories of his affection for cigars are not overstated.
*return

*label negro_day
*page_break
Negro Day arrives.
*if negro_day = 2
	Unfortunately, you have had to buy tickets and organize their distribution yourself. The black community of @{exodusters the Reach,|} Mill Valley, Chestnut Valley, and Elleardsville are suspicious of the white-dominated Exposition.
	
	However, when the day arrives, you anticipate the lecture being full—it has, of course, been moved to the evening, so that you could attend.
	
	*if stlouis_race_relations > 40
		*gosub washingtons_speech
		
		The rest of the evening proceeds as anticipated. A reception is held for Washington and the other luminaries. Everyone considers the day a success. Walter Farmer, in particular, thanks you for encouraging him to go forward with it.
	*else
		*set local_fame %-10
		Unfortunately, a crowd of whites gathered at the entrances to the Exposition and refuse to let any non-whites in.
		
		An engraving is made in time for the newspaper the next day, showing Washington haranguing three audience-members in a hall meant for hundreds.
		
		Farmer is crushed and wants nothing more to do with you.
*if negro_day > 2
	*temp has_weapons false
	The day before, the 8th Illinois arrives into town on a train to Union Station. They disembark in the black section of the station and then march in formation to Forest Park along Chouteau Ave; an informal crowd gathers to watch. @{(stlouis_race_relations > 50) |The mood is tense; there is a lot of spitting, dirty looks, and heckling.}
	
	Arriving at the Exposition, the regiment bivouacs with the tents @{(negro_day = 3) provided by the Committee|that you purchased for them}.
	
	*if stlouis_race_relations < 65
		*set has_weapons false
		The next day, a representative—accompanied by both the police chief and the major of the local National Guard regiment—from the Committee arrives to demand that the 8th surrender its rifles. The representative notes that so many colored men bearing arms will be considered a provocation by the residents of the city.
		
		The colonel of the regiment demands to know what his troops should march with; the representative suggests that they collect sticks from the park.
		
		Seeing no other option, the colonel assents. The weapons are held in trust by the National Guard major. The colonel fights back a tear when he hands his revolver over.
	
		The soldiers go out in the forest, as well as through the Exposition, and collect sticks, timber, and other objects that vaguely approximate the size and shape of their rifles.
	
	At the appointed time, the regiment forms up and prepares to march through the exposition. Their new uniforms are starched and stiff in the morning heat. The pipers and drummers begin their song.
	*if local_fame > 50
		The crowd is mixed. Blacks and whites line up along the Pike and down the fairway to the parade grounds for the spectacle.
	*elseif local_fame > 35
		The crowd is mostly white. They mass along the Pike and down the fairway to the parade grounds, anxious for the spectacle.
	*else
		*set result -1
		The crowd is almost entirely white. They fill the Pike and the fairway, seemingly oblivious to the upcoming spectacle.
		
		Another representative from the Committee tries to clear the way by shouting that the 8th Illinois is preparing to march, but the man—barely surmounting five feet in height—cannot be heard over the murmur of the crowd.
		
		Finally, the colonel gives the signal to advance.
	
	*if stlouis_race_relations > 70
		*set result +2
	*elseif stlouis_race_relations > 55
		*set result +1
	*elseif stlouis_race_relations > 45
		*comment
	*elseif stlouis_race_relations > 30
		*set result -1
	*else
		*set result -2
	
	*if result <= 2
		*set lpe_success %-15
		*set stlouis_race_relations %-15
		*if has_weapons
			*bug extremely unlikely
		When the soldiers march forward, it is instant bedlam.
		
		The crowd refuses to part. Within moments—like a living thing—it has noticed the soldiers in uniform and perceived a threat.
		
		A melee breaks out between the soldiers and the crowd. Within moments, the police have been summoned—apparently, they were being held nearby in case of just such an eventuality—and numerous soldiers are arrested and charged with inciting a riot.
		
		*if result <= 1
			The management office tries to close the Exposition for the day, but dozens of white men are marching around the Pike, strutting and emulating the imagined traits of the black soldiers, sporting stolen hats, sticks, pipes, and even the regiment's flag. Unable to corral these men, the management office relents.

		The lecture series for the evening is cancelled. The management hangs a sign on the door of the auditorium, describing the speakers as preaching hate that is unwelcome at the Exposition.

		Over the next few days, Farmer does his best to get the soldiers medical care and released from prison. The whole thing becomes something of a scandal, as the colonel is blamed for relinquishing his weapons; he is forced to resign his commission and forfeit his pension.
	*elseif result = 3
		*set lpe_success %-5
		When the soldiers march forward, they are met with jeers, rotten vegetables, and phlegm.

		*if has_weapons
			When one particularly foolhardy young white man jumps forward and tries to wrest a rifle from the soldier that holds it, the entire crowd stops for a moment. But the soldier, thinking quickly, stops on the youth's foot, who howls and lets go of the rifle. The column marches on without missing a beat.

		When the soldiers arrive at the parade grounds, they demonstrate a number of maneouvers to the oohs and aahs of the blacks in the crowd.

		Finally, the parade concludes, and the soldiers disperse to shake the hands of the black locals; the whites largely grumble but go about their business.

		You learn all about this in a rush that evening, as you arrive for the lectures.
		*gosub washingtons_speech

		The day may not have been everything you wanted, but it was not an abject failure.
	*elseif result = 4
		When the soldiers march forward, they are met by cheers from the blacks and a begruding silence from the whites.

		There is a brief moment of drama, when a young white man spits at the ground as the soldiers pass him, but one of his companions strikes him upside the head. Regardless, the regiment receives a lot of sullen looks.

		*gosub parade_grounds

		The day may not have been everything you wanted, but many things that could have gone wrong did not.
	*elseif result = 5
		*set lpe_success %+8
		The crowd cheers as the soldiers march down the Pike, along the fairway, and to the parade grounds. Sure, there are handful of whites that give dirty looks, but the large number of blacks and the handful of supporting whites silences them.

		*gosub parade_grounds

		The day went about as best as you can imagine.
	*else
		*set lpe_success %+15
		The crowd cheers as the soldiers march down the Pike, along the fairway, and to the parade grounds. THere may be some discontented whites, but they are swallowed by the celebrants both black and white.

		*gosub parade_grounds
		
		The day went better than you could have imagined.
*return

*label washingtons_speech
Booker T. Washington gives an impassioned keynote speech to the crowd, who rise and cheer at almost every other line. At least three people faint. He feeds on the call-and-response, challenging the crowd to find within themselves the industry and thrift to advance their material well-being.
		
"I encourage you to work together to buy the land that you live on. To own the businesses that you patronize. Build a bank, so when you borrow money, your brothers are the ones that collect the interest on the debt. If the police mistreat you, then pool your taxes to create your own police force. Only by freeing yourselves from the economic shackles of white America will you free yourselves from the political shackles.

"I have learned that there is a community near Oklahoma City that has done just this! You here in St. Louis, you must do as they have done! Whether you live in @{exodusters the Reach,|} Mill Valley, Chestnut Valley, or Elleardsville, you must work together, live together, make a community of your own—a community that is owned by you. In Oklahoma City, they own every stitch of land in that district, every business; the bank, the schools, and the mercantiles. And I mean to go there next year and tell them just what I am telling you: this is the only way forward for us that does not end in bloodshed and misery."
*return

*label parade_grounds
When the soldiers arrive at the parade grounds, they demonstrate a number of maneouvers to the oohs and aahs of the blacks in the crowd.

Finally, the parade concludes, and the soldiers disperse to shake the hands of the black locals; the whites largely grumble but go about their business.

You learn all about this in a rush that evening, as you arrive for the lectures. You listen to the opening acts, but really, you're here for one man.

*gosub washingtons_speech
*return

*label slattery_vs_norris
*temp slat_tit "Captain Slattery"
*temp the_police "the police"
*if stl_met_slattery = 5
	*set slat_tit "Slattery"
	*set the_police "some Irish thugs"

You awaken one evening to word that Norris has been @{(stl_met_slattery = 5) beaten within an inch of his life|arrested} and the entire stock of bulls for the arena have been put down by ${the_police}. It does not take you long to discover that ${slat_tit} is behind this assault. It would be extremely expensive to replace the bulls on such short notice.

*choice
	#I let Norris rot; I owe him nothing. Moving against Slattery@{(stl_met_slattery = 5)  and Cranch|}, however, is too great a risk.
		*set discretion %-5
		*set shepherd_credentials %-10
		*set norris_arena 1
		Whatever the @{(stl_met_slattery = 5) condition of|charges are against} Norris, they are no concern of yours.
		
		As for Slattery and Cranch…well, you let them think they have gotten the better of you.
	*selectable_if ((fighting > 0) or (streetwise > 0)) #I murder ${slat_tit}.
		*set discretion %+5
		*set exposure +1
		*set compassion %+5
		You have long-since identified the home of ${slat_tit}. It's a short walk from McGillicuddy's Tavern, and he takes the same route home every evening. No mortal would dare ambush a @{(stl_met_slattery = 5) former |}police captain. But you are no mere mortal.
				
		You jam a knife into his lung and push him into an alley off Dickson Street. He struggles to draw breath to scream, but his deflating lung fails him. The last thing he sees are your fangs and the hungry gleam in your eye.
		
		*if stl_met_slattery = 5
			This does nothing to help Norris, who is convalescing in a hospital.
		*else
			The charges against Norris were, of course, trumped up; with Slattery dead, Cranch folds and orders his release.
		
		*gosub more_bulls
		*if stl_met_slattery = 5
			When you call on him, you sense that he is
		*else
			He is, of course, quite grateful for his rapid release—if 
		concerned that he has partnered with someone who would murder a @{(stl_met_slattery = 5) former |}police captain so brazenly.
		*set stl_met_slattery 7
	*selectable_if (wealth > 500000) #I hire a @{(stl_met_slattery = 5) doctor to tend to|lawyer to represent} Norris.
		*set wealth -50000
		*set discretion %-5
		*set shepherd_credentials %+5
		*if stl_met_slattery = 5
			Norris will regain full use of his limbs, thanks to the doctor. He is walking again within a week, though a full recovery will take months.
		*else
			Within forty-eight hours, Norris is free. Within a week, the charges have been dismissed. 
		However, there are still no bulls to fight.
		
		*gosub more_bulls
		He is deeply grateful for your intervention in the matter.
*return

*label murder_slattery
*if stl_met_slattery = 10
	*set income +2
*set stl_met_slattery 7
*set exposure +1
*set compassion %+5
You have long-since identified the home of Captain Slattery. It's a short walk from McGillicuddy's Tavern, and he takes the same route home every evening. No mortal would dare ambush a police captain. But you are no mere mortal.
		
You jam a knife into his lung and push him into an alley off Dickson Street. He struggles to draw breath to scream, but his deflating lung fails him. The last thing he sees are your fangs and the hungry gleam in your eye.
*page_break
*return

*label more_bulls
*if wealth > 1000000
	*set wealth -100000
	Norris sets about procuring more bulls and the show resumes a week later.
*else
	*set wealth +20000
	*set norris_arena 1
	Based upon your current finances, you think it best to let the arena go. Norris puts it up for sale and shares the proceeds with you. 
*return

*label nawsa_debates
*set missouri_suffrage +1
*set lpe_success %+3

The debates organized by NAWSA are scheduled for the first two weeks of August and will be held in the Pavilion of Temperance.
*if intelligence > 2
	*set missouri_suffrage +1
	*set lpe_success %+3
	In preparation for the event, you have spent many hours coaching the women on the finer points of rhetoric and honing their debate skills.

The event is somewhat poorly attended the first few nights. Those that do come are there more for a laugh at women thinking they can participate in political discourse at the same level as a man. It is only when Joseph Folk, the local circuit attorney and candidate for governor, attends one evening and deigns to take the stage against Florence Wyman Richardson that imaginations catch fire. 

The discussion—about the restoration of voting rights to members of the Confederate armed forces—stretches for much longer than initially anticipated. Richardson and Folk spar from their respective podiums to sighs, exclamations, jeers, and laughter from the audience. Finally, the organizers call the debate a draw, which Folk genteelly acknowledges, going so far as to stride across the stage and shake Richardson's hand.

For the rest of the nights, most if not all of the seats are occupied. 
*if intelligence > 2
	When the run is concluded, NAWSA goes so far as to rent a hall adjacent to Forrest Park and continues the debates for another six weeks.
The suffragists—both locally and nationally—are thrilled with the results of the endeavor.
*if (intelligence > 2) or (missouri_suffrage > 4)
	Susan B. Anthony even composes a letter to the St. Louis chapter, commending them for their contributions to the cause.
	
	The letter is framed and put on display at all future meetings of the chapter.
*return

*label anthropology_days
*comment August 12-13

To better demonstrate the superiority of Europeans, James Sullivan concluded that simply gawking at the indigenous folk was insufficient. So, he has organized Anthropology Days, a two-day special Olympics for the residents of the various habitats.

The first day consists of footraces, shotput, javelin-throw, and other classic Olympic events. When Sullivan explains in English to the contestants the rules of tennis, he appears confounded when they they begin hitting each other with the rackets. Losing the crowd, he decides to do a quick demonstration of hitting a ball. The tribesmen do their best to imitate the movements—and quite seem to enjoy the whack of the racket—but with no grasp of the rules or the scoring, they cannot even begin to play a match. The crowd begins to drift away while Sullivan pontificates about the inferiority of these savages.

The second day is little better. The high point is a lacrosse match between Mohawks and Seneca. The mock-fights end up with several black eyes and broken noses. An Ainu man takes the tree-climbing award, but only after being promised an extra week's pay by an enterprising huckster.

*if shepherd_credentials > 60
	(The Ainu man never sees his bonus.)

*return

*label chopins_demise
*comment August 20
*return

*label olympics
*return

*label in_the_railyard
*achieve in_the_railyard

While you are walking down the Pike one evening, the sound of a crooner reaches your ears. Passing through an open doorway, you find a small band fronted by a mixed-race woman, keeping the audience entranced with her voice.

She sings about a poor soldier who came home from the war carrying a piece of shrapnel in his side; who was killed in a railyard; a who was celebrated by his neighbors, but who everyone knew was up to no good.

She's singing about Freddie Parke. @{(compassion > 45) You stay and listen, fascinated at your how a murder you committed has become a ballad.|You turn and go, unable to confront the consequences of your actions.}
*return

*label slattery_vs_spaldings

You awake one evening—the first weekend of September—to word that there's been a break-in at the largest of the ${spalding_sporting_goods} locations. 
*if sporting_goods = 3
	Chris Von der Ahe—his face purple with rage and his mustache quivering—relates to you how, when he arrived, the police were swarming over the emporium, breaking and smashing things as they investigated for evidence.
	
	It seems that Captain Slattery has sent you some sort of message.
*else
	When you arrive to investigate, you find the manager in a state of despair. He relates to you how the police swarmed the emporium, breaking and smashing both products and fixtures as they investigated the scene of the crime. The manager wails, "what crime? We did not call for them!"
	
	You ask if there was a lead investigator, and you are unsurprised to hear that Captain Slattery was the individual in charge of the raid.

*choice
	*selectable_if (wealth > 1000000) #We restock the shelves, repair the fixtures, and ignore this affront.
		*set wealth -100000
		*if (discretion > (60 + (bloodflow *2))) and ((combat > 0) or (streetwise > 1))
			That sounds good in theory. In practice, your temper is far too hot for such a restrained response. Such a slight cannot go unpunished.
			
			*gosub murder_slattery
			
			Of course, that does not solve the inventory problem. Once you have calmed down, you set about fixing the damage.
		*else
			You direct the manager to make the necessary repairs and reörder the missing or ruined merchandise. Within a week, the store is running again as though nothing had happened.			
	#I @{(sporting_goods = 3) my portion of the business to Von der Ahe|sell the enterprise—damaged as it is—to some enterprising individual}.
		*set income -1
		*if finance < 3
			*set income -1
		*set sporting_goods 5
		*set spalding_sporting_goods "Spalding Sporting Goods"
		*if sporting_goods = 3
			Unfortunately, Von der Ahe is not in a position to purchase your portion of the company. He proposes instead that both you sell the entirety of the enterprise to Al Spalding.
		*else
			There is, in fact, a rival enterprise headed by Al Spalding. 
		Previously, Spalding played baseball for Boston and Chicago before becoming manager for the White Stockings. However, he has seen too much success with his chain of sporting goods stores and has been running that business full time for the past twenty-five years. @{(stlouis_enterprise = 8) Notably, he moved to San Diego four years ago to form a lodge of the Theosophical Society there.|He has since moved to San Diego, leaving day-to-day management to others.} His chain has long sought to enter the St. Louis market, but refrained from doing so out of deference or respect to you.
			
		A representative from the company is only too happy to trade your existing enterprise for a block of stock in the Spalding company.
	*selectable_if ((fighting > 0) or (streetwise > 1)) #I murder Slattery.
		*set discretion %+5
		*gosub murder_slattery
*return

*label teddy_roosevelt
*set month 11

*if dem_parker = "Parker"
	Roosevelt cruises to reëlection, defeating Alton Parker handily. Once the votes are in, Roosevelt finally makes the trip to St. Louis. In later years, he will note that he did not wish to attend the Exposition lest he be seen as pandering for votes.
*if dem_parker = "Hearst"
	*comment Hearst wins Nevada, Idaho, Montana, Utah, and Colorado with the silver argument (+17), Illinois with the support of the Democratic governor and his newspaper (+27), which bled over into Indiana (+15). New York (39) as the deciding factor; if Hearst won NY, it would have been a tie. Without a win, Roosevelt wins by almost 80 votes. This isn't helped by the chaos in Maryland, where the vote for the president is only notional, and the vote for the delegates is what matters; though the state voted for Roosevelt, seven of its eight electors were Democrats, and voted accordingly.
	Roosevelt's reëlection was a narrow affair. Hearst's newspapers put up a significant fight, resulting in a stronger showing by the Democrats than anticipated across the North and West. New York itself is hotly contested between the two candidates. So much so that the results of the election are delayed by two weeks as there are recounts in several districts on Long Island. The [i]New York Journal[/i] screams every day over the delays and the frauds committed by Republicans, while Pulitzer's [i]New York World[/i] urges calm.
	
	Finally—after Odell uses the police to obstruct the distribution of the [i]New York Journal[/i] on charges of inciting riots—Roosevelt is declared the victor.
	
	Hearst tries to sue Odell for the abridgement of his First Amendment rights, but when the case reaches the New York Court of Appeals, Chief Judge Alton Parker writes a dubious decision that overturns the case. With the Supreme Court strongly tilted against him, Hearst finally abandons the suit.
	*comment since Parker didn't resign to run for President, he would still be Chief Judge.
*return

*label becard_hunts_gould
*set becard_hunts_gould false
*set gould_plot 6
*set lefferts_status 2
*set memeskia_rapport %+25
*set becard_rapport %+20
You are at the Southern Hotel one evening when Bécard arrives, looking like a cat that has just caught a canary. Memeskia gestures for her to speak.

"Quaestor, I have slain the vampire known as Jay Gould."

Memeskia nods.

"Quaestor, I have also captured the vampire known as Edwin Lefferts."

Memeskia takes a moment before speaking. "These vampires did not observe the Rule of Respect," he says. "Justice is done."

Bécard bends her head. Bailey, on the other hand, looks apoplectic.

Later, Bécard approaches you, thanking you for the intelligence about the two vampires. She assures you that the Quaestor is aware of your role in the affair.
*if debt_from_becard = false
	*set debt_from_becard true
	Moreover, she acknowledges the debt that she now owes you.

*if heard_of_malloy
	You wonder what Malloy will think of her broodmate's incapacitation. Will she take offense? Or send a note of gratitude?
It seems you have taken one more piece off the board.
*return

*label get_i1
*params which
*rand interlocutor_1 1 8
*label get_i1_cont
*if interlocutor[which] = 1
	*comment TODO who's 1?
	*label fail_test1
	*set interlocutor[which] +1
	*goto get_i1_cont
*if interlocutor[which] = 2
	*if (applethorp_alive = 1) and (spoke_stl_applethorp = false)
		*return
	*goto fail_test1
*if interlocutor[which] = 3
	*if met_herbert_walker < 3
		*return
	*goto fail_test1
*if interlocutor[which] = 4
	*if spoke_stl_rios = false
		*return
	*goto fail_test1
*if interlocutor[which] = 5
	*if spoke_stl_fragala = false
		*return
	*goto fail_test1
*if interlocutor[which] = 6
	*if spoke_stl_maffi = false
		*return
	*goto fail_test1
*if interlocutor[which] = 7
	*if spoke_stl_withers = false
		*return
	*goto fail_test1
*if interlocutor[which] = 8
	*comment Gudhrun
	*if (stl_bjornsdotter_convo = false) and ((month <= 7) and com_gudhrun)
		*comment if month > 7, then Bjornsdotter will be potentially present when West hunts Yates. She needs to leave before that.
		*return
	*set interlocutor[which] 1
	*goto get_i1_cont
*bug

*label get_i2
*params which
*label get_i2_cont
*rand interlocutor_2 1 7
*goto get_i1_cont

*label west_hunts_yates
Suddenly, from somewhere in the direction of the human zoo, you hear a howl. A massive, deep howl. Some primal portion of your being roots you in place, temporarily stuck in some temporal dilation where eternity ends and begins anew.

*if (interlocutor_num = 4) and (rios_alive = false)
	As you regain command of your bodily functions, you look down at Estefania's clothes. Would she have preferred to have been consumed by ${quarry}, given the option?
*else
	From the periphery of your vision, you see ${interlocutor} start to move again. You too find again the power of motion all at once.
	
	The mortals around you almost don't seem to notice. How can they not notice the cry of a wolf in their midst? Could the howl of a Beast be inaudible to humans? An idle thought for another time. For the moment, all you can think of is @{(discretion < 50) shelter|preparing your defense}.
	
	@{interlocutor_num "It's him!"[n/][n/]"Yes…" you begin.|"Like dah rabbits, Ahm goin ta ground," Applethorp says.|"I don't know about you, ${given_name}, but I don't want to be out in the open any longer," Herbert says.|"I must find shelter," ${interlocutor} says.|"I must find shelter," ${interlocutor} says.|"[i]Enculé,[/i]" she curses. "I must go."|"Is that…him?" she says, clearly terrified.[n/][n/]"West? I suspect so."[n/][n/]"Please excuse me, I must find shelter," she says, picking up the hem of her skirt and hurrying into the night.|"I can't stay here," Yates chokes out.|"What is that?" Edwin exclaims. "Jay, we must go."[n/][n/]Jay looks at Edwin, but then turns and begins to head towards the howl. Having none of that, Edwin grasps Jay by the arm, and drags him in the opposite direction.}
	
	With that,
	*if interlocutor_num = 9
		they run into the crowd.
	*else
		${interlocutor} runs into the crowd.

Looking around, you try to figure out what to do. You can feel the fear rising in you, but without a heart to clench, it crashes against you indiscriminately. @{(find_west > 2) As best as you can tell, the howl came from the Concessions.|}
*temp see_corpse false
*temp see_gash false

*choice
	#I head home. The sooner I'm indoors, the better.
		*set discretion %-10
	#@{stlouis_tribune It's my duty to seek out the Beast. Off I go.|Bécard could surely use my help.}
		*set find_west +1
		*if perception > 1
			*set find_west +1
		*set independence %+10
		*set exposure +1
		*set see_corpse true
		You dash into the crowd. The mortals scream and shout in your wake, seeking in vain to understand why fury incarnate is passing them by.
		
		@{(find_west > 4) You heard the howl; despite the terror in your gut, you plot a course directly for the Igorot village.|Some part of you demands to turn away from the Igorot village; suffocating that instinct, you set a course directly there.}
		*page_break
		*if stlouis_tribune
			When you arrive, it's already too late. There is an extremely well-dressed skeleton wearing what used to be Yates's clothes. With the exception of one arm, whose sleeve is in one place, and neither of which are attached to the rest.
			
			*if west_prob and (find_west > 4)
				Fleeing into the night is a short, dark-haired figure.
				
				On the ground you spy the expired Yates, his chest ripped open and his dessicated organs sprayed across the ground.
			*elseif find_west > 4
				Standing above, however, is West, covered in the blood of the expired Yates. A great, lumbering beast, like a man and a dire wolf conjoined, fighting to inhabit the same space. The creature's gaze turns towards you
				*if sire_name = "West"
					and for a moment, you sense a glimmer of recognition.
					
					"Dominus?" you whisper.
				*else
					and seems to consider you with no more regard than an insect.
				Then it blinks—its baleful red eyes closing out the misery of the world for the briefest of moments—and the creature is loping away into the night.
		*else
			*set becard_rapport %+10
			When you arrive, you find Sabine struggling to get to her feet. 
			*if west_prob = false
				*set becard_scarred true
				*set see_gash true
				She has a nasty gash across her face.
			About ten feet from her is the body of Yates, his flesh already melting away.
			
			*if west_prob
				Bécard is muttering something to herself.
				
				"Sabine!" you shout, trying to focus her attention.
				
				"It's…it's not…"
				
				"What are you talking about?"
				
				"That wasn't West."
				
				Your already-stagnant blood freezes.
				
				"Of course it was West. I saw him myself."
				
				"But…it wasn't him…"
				
				"Who else could it be?"
				
				"I…don't understand?…"
		
		The Igorots are standing around, shock and incomprehension on their faces. One raises his spear at you@{stlouis_tribune | and Bécard}.
		
		*if (stlouis_tribune = false) and (west_prob)
			"Now is not the time for this. We need to go."
			
			You help Bécard to her feet and the two of you make a hasty exit from the scene.
		*elseif (stlouis_tribune = false)
			You help Bécard to her feet. "@{(compassion < 50) That gash…it's not healing."|He left you something to remember him by," you observe wryly.}
			
			"Nothing to be done about it now. Let's go, before these people find their courage."
			
			"If you insist."
		*else
			Yates is clearly dead, and @{west_prob West's impersonator|West} is gone. Best to disappear before your audience finds their courage.
		
		Behind you, an Igorot woman wrests a spear from its brandisher and begins poking at the skeleton of Yates.
		*page_break
		The next evening, you @{stlouis_tribune |and Bécard} report to Memeskia. Of course, he was already aware of your failure.
		*goto yates_death_aftermath
	#If ${quarry} is going to hunt me down, it makes little difference where I try to hide.
		*set discretion %+10
		*if interlocutor_num = 9
			Edwin and Jay may have fled before @{west_prob West's impersonator|West},
		*else
			${interlocutor} may be gone, 
		but that doesn't mean you can't still enjoy the fair. 

*page_break

It's a few days later when you receive a note from Bailey that Memeskia has called for court.

When you arrive, Bailey greets you somberly. It seems that Yates has been killed by West.
*label yates_death_aftermath
*if (stlouis_tribune = false) and (west_prob = false)
	*set becard_scarred true

Besides the misfortune of having another dead vampire in the @{see_corpse city, this|city—not that Yates was young enough to leave much in the way of a corpse—this} also threatens to bring the animosity between Quaestor O'Donnell and the neighboring cities to a boil. @{(revolutionary_credentials < 50) You can only hope that you will not be painted with the same brush as the rest of this city's denizens.|}

*if stlouis_tribune
	"${mr} ${surname}, can you explain to me why we have another dead vampire in St. Louis?" Memeskia thunders.

	"I…I have not been able to locate West yet, Quaestor."

	"You do not have much time left, ${mr} ${surname}. The fair will be over soon, and with the fair complete, West will disappear into the wilds once again."

*else
	"Bécard!" Memeskia thunders. "Where is West? Why has he not yet been brought to heel?"

	Bécard stands tall, 
	*if becard_scarred and see_gash
		the gash on her face still unhealed.
	*elseif becard_scarred
		a nasty gash across her face, a wound surely inflicted by West.
	*else
		uncowed by Memeskia's fury. 
	"I will find him, Quaestor."
	*if west_prob
		After a moment, she continues. "I'm not sure that it is actually West, Quaestor."
		
		He blinks.
		
		"I met your dominus before…I dont't think this was him."
		
		"That would surprise me, Sabine. Are you certain?"
		
		"No…"
		
		"If it is someone else, would that change our tactics?"
		
		"No, I suppose not…"

	"What I note, then, is that you are running out of vampires to draw him out."

	"Yes, Quaestor." @{west_prob She sighs; her warnings have been ignored.|}

	"Soon, the Governor will have me hang Hiram or ${given_name} out to dry."

	@{(becard_rapport > 50) |The idea of you serving as the lure does not seem to totally displease the Tribune. }"That would be unfortunate," @{(becard_rapport > 55) Sabine|Bécard} replies.

	"Let us not come to that," he says.

Eliot shoots you a look. @{stlouis_tribune "I will help you as best I can," he whispers.|"We should help her, ${given_name}," he whispers.}

*if stlouis_tribune
	"Thank you, @{(eliot_rapport > 50) Hiram|Mr. Eliot}."
	
	You can use all the help you can get.
	*page_break
*else
	*choice
		#"I suppose you're right."
			*set eliot_rapport %+10
			*set becard_rapport %+10
			Bécard nods her thanks.
			
			Before you leave, you, Eliot, and Bécard agree upon a time to meet and strategize on how you will take down the Beast.
		#"Help her? Are you mad?"
			*set eliot_rapport %-10
			*set becard_rapport %-5
			"What are you going to do when he comes for you, then? Plead for him to leave you be?"
			
			"I don't have to be the fastest, but I shan't be the slowest."
			
			Eliot looks disappointed. "I suppose you are counting on me being slower than you. I will remember that," he snaps.
			
			Memeskia has already departed; soon, you beg your leave as well.
		*if (stlouis_tribune = false) #"Aiding her would only mean our certain destruction, @{(eliot_rapport > 55) Hiram|Mr. Eliot}."
			*set tells_eliot_cant_help true
			*set discretion %-5
			*if combat < 6
				*set eliot_rapport %-5
				Eliot looks at you sadly. "I understand that you are not a soldier, ${given_name}."
				
				"I am not," you reply.
				
				"It is for the best, then. Keep safe," he says, before turning away.
			*else
				*set eliot_rapport %-15
				*set becard_rapport %-5
				Eliot looks at you. "I did not take you for a coward, ${given_name}."
				
				"Discretion, as they say, is the better part of valor, @{(eliot_rapport > 55) Hiram|Mr. Eliot}," you retort.
				
				"Well, I'm glad to know where you stand," replies.
				
			Looking around, you observe that Memeskia has already left. Since there is nothing more for you here, you depart.
		*if (sire_name = "West") #"This is my responsibility. She shouldn't be involved at all."
			*set discretion %+5
			*set independence %-5
			*set becard_rapport %+5
			*set eliot_rapport %+5
			"Whoever's responsibility it is doesn't matter at this moment, ${given_name}. What matters is that this Beast is hunting us down one by one. Either we do this together or we perish alone."
			
			You have no counter to that.
			
			Before you leave, you, Eliot, and Bécard agree upon a time to meet and strategize on how you will take down the Beast.
*return

*label hunt_west
*gosub_scene util combat_value_ss
*if weapon_num > 2
	*set combat +1
*if refined_silver_bullets and (west_prob = false)
	*set combat +1
*temp west_downfall 0
*temp b_present false
*temp hiram "Eliot"
*set stl_fought_west true
*if eliot_rapport > 55
	*set hiram "Hiram"
*temp sabine "Bécard"
*temp tigers false
*if becard_rapport > 55
	*set sabine "Sabine"

*if stlouis_tribune
	You rise from your ${sleeping_place} the next night. Your skin tingles; it's as though there's electricity in the air. @{west_prob ${imposter}|West} is on the prowl.
	
	You need a plan. How can you defeat your enemy, @{west_prob someone able to imitate|} an ancient vampire who has become one with the hunger inside of him?
*else
	*if tells_eliot_cant_help
		You rise from your ${sleeping_place} one evening like all the others. You attend to your toilette and observe the correspondence that has arrived during the daylight hours.
		
		In the distance, you hear the howl of a wolf. The hairs on the back of your neck stand to attention.
		
		$!{quarry} is on the prowl.
	*elseif stlouis_valet_alive
		${stlouis_valet} @{literate hands|shows} you a note when you rise from your ${sleeping_place} for the 
		*if literate
			evening. [i]It's time. Meet Bécard and me at the Exhibition entrance. —Hiram[/i] is all it says.
		*else
			evening; ${valet_he} says that Eliot has requested your presence at the Exposition entrance.
	*elseif renter
		Your landlady is banging on the door to your quarters.
		
		Your growl in frustration. The death of ${stlouis_valet} is constantly inconvenient.
		
		"Sleeping all day, I don't understand! How will you ever find a @{male wife|husband} if you don't have a job? Do you want to me to introduce you to some eligible individuals…" she trails off as you close the door in her face.
		
		*if literate
			[i]It's time. Meet Bécard and me at the Exhibition entrance. —Hiram[/i] is all it says.
		*else
			You reopen the door and politely ask her to read the note to you.
			
			"What about your marriage prospects?" she demands.
			
			"The note, please."
			
			"All it says is, 'It's time. Meet us at the Expo-dition,' and it's signed 'Hiram.'"
			
			"Thank you," you say, closing the door again.
			
			@{male |The gesture is not quite fast enough to block the sight of her eyes going wide at the thought of you going out to meet a gentleman caller in the middle of the night.}
	*else
		You wake to find a note in the mail cubby.
		*if literate
			[i]It's time. Meet Bécard and me at the Exposition entrance. —Hiram[/i] is all it says.
		*else
			You are forced to accost the neighbor's boy to read it to you—he has come to appreciate the coins you drop in his outstreched hands on these occasions.
			
			"'It's time. Meet Be-card and me at the Exposition entrance. —Hiram' is wha' it says," he informs you.
			
			You nod and send him on his way.

*temp met_folks true
*if carlos_present and (seen_carlos = false)
	Where is Praetor Carlos? Has he made contact with Eliot?
@{tells_eliot_cant_help Is ${quarry} coming for you?|}
*temp stand_down false
*choice
	#Facing down an elder Beast is the last way I intend to end my existence. Eliot @{(stlouis_tribune = false) and Bécard are on their|is on his} own.
		*label dodge_west
		*set stl_fought_west false

		Perhaps it's just your imagination, but you would swear @{((religious_tradition != "pagan") and (rationalism > 60)) on a Bible|} that you could hear the roar of West from your haven. Like some mythic battle between Titans or deities of old, the sky crackles with the conflict.
		
		In its aftermath, you learn that @{west_prob ${imposter}|West} was finally brought down—but not before he @{(carlos_present or west_prob) slew Hiram Eliot.|drank the heartsblood of Hiram Eliot.}
		*if west_prob
			There are rumors, of course, that it was not, in fact, West that was slain. But whoever it was, the corpse crumbled to dust and thus offered no testimony to the contrary. @{stlouis_tribune |Bécard tries for a while to set the record straight, but no one cares to hear the truth.}
			
			It seems your crime is finally dead and buried.
		*if stlouis_tribune
			*set bailey_rapport %-30
			*if memeskia_alive
				*set memeskia_rapport %-50
			*set bjornsdotter_rapport %-40
			*set overstreet_rapport %-25
			*set becard_scarred true
			
			You are, of course, stripped of your title as Tribune of St. Louis. Your cowardice could not go unaddressed.
			*if status > 1
				Moreover, your reputation has been severely tarnished.
			You are summarily exiled from St. Louis, on pain of death.
			*set exiled_from_stlouis true
			*goto_scene timejump5
		*else
			*if eliot_rapport > 60
				You are struck by the loss of Hiram. But it was your decision to abandon him to his cause. @{love_hope And this is not the first time a soldier has put his duty before you.|}
			*if told_becard_silver
				*set becard_rapport %+5
				Bécard took your advice and equipped herself and Eliot with weapons of silver. She thanks you from behind clenched teeth.
			*elseif (becard_scarred = false) and (west_prob = false)
				*set becard_scarred true
				Bécard sustained a gruesome blow in the fight—her face now sports a scar that looks like it might somehow be permanent.
			*elseif becard_scarred
				To your horror, it seems that the blow Bécard sustained while hunting West might somehow be permanent.
			*if becardeliot_romance and (perception > 1)
				She is distraught by Eliot's death, withdrawing to Jefferson to be alone.
			*else
				In the aftermath of the battle, she retreats to Jefferson to be alone.
			*if carlos_present
				You later learn that Padre Carlos revealed himself at an opportune moment and struck a killing blow. Too late to save Hiram, yes, but in time to capitalize on Eliot's pyrrhic efforts.
			*elseif west_prob or told_becard_silver
				You later learn that Memeskia struck at an opportune moment, slaying ${quarry}. You surmise that he waited too long to save Hiram, instead using Eliot's sacrifice as an opening ploy to ease his victory.
			*else
				*set memeskia_alive false
				
				Perhaps more importantly, Memeskia was slain by West as well. The court reels from the loss.
			*return
	#@{stlouis_tribune I send notes to Bécard and Eliot, imploring them to meet me at the entrance to the exhibition.|I set out to meet Bécard and Eliot.}
		*set b_present true
		*if stlouis_tribune = false
			*set becard_rapport %+10
			*set eliot_rapport %+10
		You pull on your clothes and head to the Exposition.
	*if (stlouis_tribune = false) #I go to the Exposition to convince Bécard and Eliot to stand down. They shouldn't die at ${quarry}'s hands!
		*set b_present true
		*set discretion %-10
		*set stand_down true
	#I head for the Exposition, alone.
		*set independence %-30
		Arriving at the front entrace, you pause briefly to survey the scene.
		*if stlouis_tribune = false

			"${given_name}?"

			Turning, you spy ${sabine}. "I suppose you're here for the same reason as me."

			"Actually, I was here for the waffle-cones," she retorts.

			"Waffle-cones?"

			"I'll explain later. Let's go."
	*if ((shapeshifting > 1) and (intelligence < 3)) #There are tigers on display in the Indian pavilion. They may provide some assistance.
		*set met_folks false
		*set tigers true
		*set discretion %+5
		You arrive at the Indian pavilion and its tiger enclosure. The three of them prowl back and forth, disturbed by your presence. One unleashes a roar. You extend your will, whispering sweet words, and they calm.
			
		You open the cage and the three magnificent beasts emerge, one by one.
		
		"Come," you say simply.
		
		You and your entourage advance towards the Philippine concession.
	*if ((false) and (west_prob)) #I have to get to ${imposter} first and discover his identity.
	*if assistants_num = 1
		*if (stlouis_cult_power > 55) or ((stlouis_enterprise = 2) or (stlouis_enterprise = 4))
			#I summon some mortals to help; I may not be able to handle torches, but they can.
				*set met_folks false
				*set assistants_present true
				*if stlouis_enterprise = 2
					*set assistants "Egan's Rats"
					*set assistants_num 5
					*set zulus "thugs"
				*if stlouis_enterprise = 4
					*set assistants "[i]Turners[/i]"
					*set assistants_num 6
					*set zulus "[i]Turners[/i]"
				*if ((stlouis_cult_power > 55) and stlouis_cult) and (zulus = "Zulus")
					*set assistants "disciples"
					*set assistants_num 7
					*set zulus "disciples"
					*set stlouis_cult_power %-20
				*if assistants_num = 5
					*if egans_rats_plot = 1
						*set egans_rats_plot 2
						Egan's Rats are a gang of thugs, criminals, extortionists, and vote-collectors based in the Kerry Patch. They work with Thomas Kinney—a State Senator—and his good friend Thomas Egan. You've had some dealings with them in the past, and you are able to summon them now
					*elseif egans_rats_plot = 5
						*set assistants "Baldy's Boys"
						You send for some of ${assistants}
					*else
						You send for some of ${assistants}
				*else
					You send for some ${assistants}
				to meet you at the entrance to the Exposition.
				*if becardeliot_romance and (eliot_rapport > 65)
					*set b_present true
				
				When you arrive, you find them gathered at the entrance. 
				*if stlouis_valet_alive
					Demonstrating ${valet_his} foresight yet again, ${stlouis_valet} has acquired enough tickets to get them all in.
				
				The attendants at the turnstiles are flummoxed by the wave of ${assistants} and their unlit torches. The rules for the park don't preclude such, however, and so they pass unmolested.
	*elseif assistants_num > 1
		#I signal the ${assistants} to meet me in the Exposition.
			*set met_folks false
			You slip into the Exhibition park with a minimum of fanfare. The equipment that you need is already in place.
			
			Arriving at the @{assistants_num ERROR|Anglo-Boer Concession|Cheyenne village|Igorot village|ERROR|ERROR|ERROR|Buffalo Bill's camp}, you find them waiting for you, their faces steeled for what is to come. @{(assistants_num = 8) You told them not to bring their Winchesters and revolvers, but they have largely ignored you; before your eyes they are checking their rounds and assuring themselves that their barrels are clear of obstructions. Those|They carry no guns—you told them to leave those at home—but instead sport mostly hatchets, machetes, and spears. Even those} will be almost useless against @{west_prob ${imposter}|West}, but their unlit torches are another matter.

*if met_folks
	*if b_present
		*page_break
		${hiram} and ${sabine} are waiting for you at the entrance. You greet them; their faces are grim. @{becardeliot_romance Their hands—previously joined—fall to their sides; now is not the time for tenderness.|}
		
		Amusingly, the two of them are dressed in costumes that make the fair-visitors ignore them: ${sabine} in her Miami leathers, ${hiram} in his blue British Navy frock coat. (The Winchester rifle slung over his shoulder doesn't fit the image of the 1830s-era Navy officer, but you can't imagine that the patrons are all that concerned with historical accuracy.)
		*if stand_down
			
			"You can't do this," you begin.
			
			"Do what?"
			
			"This. Fight him. Fight West."
			
			Bécard and Eliot look at you. "Is that why you came? To tell us to go home?" Bécard snaps.
			
			"It is. Please, I beg of you. West is over a thousand years old. He drinks the heartsblood of his victims. You don't stand a chance against him!"
			
			You can see Sabine waver. She looks to Hiram, who shakes his head. "I can't. Tommy's here."
			
			"What?" you and Bécard say in unison.
			
			"He snuck out of his father's house. I told him to keep him close, but he didn't listen."
			
			"And you think he's in the Exposition?" you say, incredulous.
			
			"I know he is. He wants to @{(werewolf_hysteria > 5) see the werewolf|disprove the existence of the werewolf}."
			
			Bécard shakes her head. "Do I even have to ask?"
			
			"No. I'm going."
			
			They look at you.
			
			*choice
				#I go with them.
				#I apologize and tell them that I won't sacrifice myself over a mortal.
					*set becard_rapport %-20
					*set eliot_rapport %-20
					*set discretion %-20
					*set shepherd_credentials %-10
					They nod in understanding. A moment of silence passes between the three of you, and then they turn and enter the park, while you retreat home.
					*goto dodge_west
				
			They can see as your resistance melts. Hiarm slaps you on the back. "That's the spirit!"
			
			"This is a good night to die," Bécard agrees.
			
			"Way to bring up the mood, Sabine," Hiram replies.
		*if has_silver_bullets
			
			"These are for you," you say, offering a small box to ${hiram}.
			
			"What are these?" he says, opening them. When he sees the silver bullets, his head cocks to the side. "Really?"
			
			"Do you have a better idea?"
			
			"I suppose not." With that, he begins emptying the magazine.
		*if stand_down
			"You don't have a weapon, though," he observes. "Unless you intend to pummel West into submission?"
			
			You open your coat to reveal a revolver@{(dynamiteWest = 3)  and several sticks of dynamite|}. "I came prepared to change my mind."
			*set weapon "revolver"
			*set weapon_is "revolver is"
			*set weapon_num 6
		*elseif dynamiteWest = 3
			
			You check your bag again for the sticks of dynamite. You hope they will help.
		
		Rather than taking your tickets, one of the attendants at the entrance takes one look at your outfits and ushers you through a side gate, chastising you in the process for not coming through the performers' entrance. "Don't let me see you trying to enter the park with the other visitors again!" he scolds.
		
		"Yes, sir!" ${hiram} replies with a mocking salute.
		
		The three of you march into the park.
	*else
		*if stlouis_tribune = false
			*set b_present true
		*page_break
		"${given_name}!"
		
		@{b_present You and Bécard pull up short. ${hiram} is hurrying to catch up with you.|Turning, you spy ${hiram}.} You almost laugh; he is outfitted in his blue British Navy frock coat and has a Winchester rifle slung over his shoulder. (The passers-by seem to take him for one of the performers; the anachronism of the rifle does not ruin the illusion.)
		
		"What are you doing here?"
		*label merge_arrival
		
		"Tommy snuck out of the house."
		
		"Tommy?"
		
		"Yes, I told his father to keep him home, but he snuck out of the house."
		
		"And so you came to fetch him? Dressed like that?"
		
		${hiram} huffs. "If I have to shoot a ravening wolf-man, the more ridiculous I look, the easier it will be to explain away."
		
		"Then the Rule of Reserve will be unperturbed this evening."
		*if has_silver_bullets
			The moment of levity having passed, you offer a small box to ${hiram}. "These are for you."
			
			"What are these?" he says, opening them. When he sees the silver bullets, his head cocks to the side. "Really?" @{refined_silver_bullets He rolls this bullets in his hand, clearly impressed by their workmanship.|}
			
			"Do you have a better idea?"
			
			"I suppose not." With that, he begins emptying his magazine.
		*if (b_present = false) and (becardeliot_romance)
			*page_break
			*set b_present true
			"What are you two doing?" The voice comes from behind you.
			*if tigers
				She pets one of the tigers are she threads their number.
			*elseif assistants_present
				"And who are these people?" she adds.
	
			Turning, you see ${sabine} approaching. "West is on the prowl.@{assistants_present  They're here to help.|}"
	
			"And you thought you could take him down without me?"
	
			"I didn't…" you begin.
	
			"No need for both of us to die tonight, Sabine."
	
			"And maybe if we work together, none of us will, Hiram."
	
			The two glare at each other for a moment. Apparently, this is a point of contention between the two of them.
	
			"We should go," you offer.
	
			"Fine," Hiram replies.
	
			"Fine," Sabine concludes.
*else
	*if (stlouis_tribune = false)
		*set b_present true
	Somewhere in the middle of the Pike, you hear your name.
	*if tigers
		You motion for the tigers to sit.
	*elseif assistants_present
		You raise your hand to silence the ${zulus}.
	
	"Hiram?"
	
	"${given_name}! What are you doing?" It's Eliot@{b_present  and Bécard|}.
	
	"What does it look like?" you retort.
	*if tigers
		The tigers begin cleaning themselves.
	*elseif assistants_present
		The ${zulus} welcome the arrival of another ally.
	You take a moment to survey Hiram—he's dressed in a blue British Navy frock coat and has a Winchester rifle slung over his shoulder. @{b_present Beside him, ${sabine} is wearing her Miami leathers.|} The @{b_present two|} of them look like they are part of the entertainment, and the fair-goers seem to pay them no particular mind.	"What are you doing here?"
	*goto merge_arrival
*if seen_carlos
	
	"Praetor Carlos is nearby," you offer.
	
	"Where?"
	
	"Hiding. Watching. Waiting for West to show himself."
	
	"We're the lure for the ancient vampire?" @{b_present Bécard|Eliot} replies.
	
	"I'm afraid so."
	
	"Remind me never to follow you into battle again, ${given_name}," Hiram quips.
*elseif carlos_present

	"Has anyone heard from Praetor Carlos?"
	
	*if b_present 
		"He's here."
		
		"Where?"
		
		"Nearby."
		
		*if intelligence > 1
			You surmise that Carlos must be using his powers of misdirection to hide himself from the three of you.
		*if intelligence = 1
			"Where?"
			
			${sabine} cocks her head and looks at you, disappointed. "He is at least a hundred years older than I am. His powers of misdirection are mighty. He's here…just not visible."
			
			"Of course," you mumble.
	*else
		*bug this shouldn't be possible
		"He's nearby."
		
		"Nearby?"
		
		"Hiding."
		
		"Of course." You surmise that he must be using his powers of misdirection to remain invisible to you—and hopefully West.		
*page_break

It's certainly cold. The late November night air is well below freezing and clouds fill the sky. The wind is blowing.

"Did I ever tell you about the time we were nearly crushed by a whirlpool?" ${hiram} asks no one in particular. "The very inspiration for Charybdis. It's a phenomenon in the Straits of Messina. Not nearly as large or terrifying as the creature of legend, but when you're caught in it…for a moment, it was like I was in a myth, about to meet a mythic end."

"I don't think you have to worry about any whirlpools around here, ${hiram}," @{b_present ${sabine} quips|you quip}.

He turns and faces the wind. It blows his hair back, framing his face. "No, but I feel like that again. Caught in a story that isn't mine."

*if b_present
	"Consider this," ${sabine} continues with a grin, "you're too pretty to be caught in someone else's story." Eliot rolls his eyes.
	*if male
		"You might even be as tall and handsome as ${given_name}."
		
		"I never knew you as one for flattery, Sabine," you interject.
		
		"If it's going to keep me alive, I'll say whatever I need to," she replies grimly.
	*else
		"You're taller than ${given_name}, and maybe even prettier."
		
		"Yes, definitely prettier," you confirm.
		
		"You're just jealous of my coat," ${hiram} sniffs.

@{(zulus = "Igorots") The Igorot leader informs you that the rest of the village has fled the beast-man, taking refuge within the Navajo pueblo and leaving this section of the park empty.|Once again, you're in the Igorot village.} The village straddles the edge of a massive lake that was dug for this very purpose. @{(zulus = "Igorots") The cookfires are still smouldering.|There are smouldering cookfires, but no one tends them.}

*if assistants_present
	You deploy the ${assistants} in the doorways and alleyways of the huts. 
	*if zulus != "Igorots"
		Thankfully, none of them have locks. This must be the only time the village has been empty since it was erected.
	They look at you expectantly, their unlit torches screaming for an open flame. @{tigers They pretend to ignore the tigers, but you can sense their fear.|}
	
	*if (zulus != "Igorots")
		"Where did they all go?" ${hiram} asks.
		
		"They probably did the smart thing and fled."
		
		"We're not very smart are we?"
		
		"No, not at all," @{b_present Bécard interjects.|you reply.}

"Is this where we make our stand?" ${hiram} asks.

@{(stlouis_affair = 12) "Either he dies here or I do."|"Do you have a better idea?"}

He shakes his head.

With that, the clouds part. The full moon shines down on you. And in the distance, you hear a howl.

"He's here," you announce.
*page_break
*temp e_alive false
*if west_prob
	*set combat +2

From that moment, time begins to move very quickly. Or perhaps slowly. It can be so hard to tell.

With a wet crash, ${hiram} is thrown through the wall of a hut on stilts over the lake; it wobbles and creaks and comes to rest at a precarious pitch. @{b_present Bécard brandishes her knives and charges. She scores a few slashes on ${quarry}, but a second impact sees her flying through the wall of an earthbound hut as well.|}

And there he is: taking the form of a wolf-man, ${quarry} rises nearly nine feet tall, a whirlwind of fur, fangs, and claws.
*temp converted_tigers false

*if assistants_present
	*set west_downfall +1
	"Light 'em up!" you shout. At your command, the ${assistants} begin igniting their torches.
	
	Perhaps you should have told them to start earlier, as the lighting of matches is not an immediate affair. But lighting the torches ahead of time would have alerted ${quarry} to the presence of ${assistants}. But do you really think ${quarry} was unaware of the ${assistants}? How could he? Which means, you suppose, that he just doesn't care.
	
	That is not a comforting thought. And you wonder why you are thinking it, instead of doing something about the very large, angry wolf-vampire in front of you.
	*if tigers and (west_prob = false)
		*set west_downfall -1
		*set assistants_present false
		
		With an imperious gesture, you indicate ${quarry} to the tigers. They look at ${quarry}, who looks back at them. From the direction of ${quarry}, you think you hear a laugh. Or whatever passes for a laugh from a creature such as ${quarry}.
		
		They leap, but not in the direction you were expecting; they each sinks their teeth into one of the unsuspecting ${zulus}. The enmawed ${zulus} scream, while their companions struggle with their torches. When their first targets stop struggling, the tigers move to new ones. Within moments, the ${zulus}'s morale has broken; they turn and flee into the night.
		
		The wounded men make some cries for help; the tigers return to their gruesome task. The sound of bones snapping echoes off the village huts.
*elseif tigers
	*set tigers false
	"Attack!" you shout, pointing at the wolf-man. Your three tigers crouch and growl.
	
	*if west_prob
		For a moment, it looks like the tigers may defeat ${quarry}: they seize his limbs in their jaws and tear at him with their claws. But, one by one, he dispatches them in a shower of gore.
	*else
		*set converted_tigers true		
		But West simply stares back at their leader. The tiger rises and approaches West, before rolling on his back and offering up his belly. The other two tigers follow suit.
		
		A grin spreads across West's lupine face.

*temp blown false
From the direction of the building that ${hiram} went crashing through you hear the cock rapport of a rifle; his Winchester survived the crash. The bullets are striking ${quarry} full in the chest, @{has_silver_bullets and ${quarry} is howling in pain. He swings his head around and fixes his gaze on the barrel of the rifle, peaking out from the rubble.|though ${quarry} seems barely fazed by the impact.}
*if dynamiteWest = 3
	*if (agility > 2) and (willpower > 2)
		*set west_downfall +1
		As ${quarry} adjusts to this new threat, you seize the opportunity to throw a stick of dynamite at his feet. It explodes in a shower of earth and you hear ${quarry} issue a roar of rage; surely, that hurt him. But you doubt it will work again.
	*elseif agility > 2
		As ${quarry} adjusts to this new threat, you seize the opportunity to throw a stick of dynamite at his feet. Unfortunately, you throw the stick too early—the thought of it exploding in your hand is too much. $!{quarry} catches the stick and throws it right 
		*if assistants_present
			*set assistants_present false
			at the ${zulus}, mangling several of them and scattering the rest.
		*else
			*set blown true
			back at you. You dive for cover, but the explosion is massive, nearly tearing your legs off. It's going to take you several minutes to mend them enough to rejoin the fight.
	*elseif willpower > 2
		As ${quarry} adjusts to this new threat, you seize the opportunity to light a stick of dynamite. However, your aim is off, and instead of landing near ${quarry}, it lands 
		*if assistants_present
			*set assistants_present false
			amid the ${zulus}. They don't even realize what's about to happen—and then limbs and torsos are flying through the air. @{(compassion > 50) They won't be much help now, you muse.|}
		*else
			behind ${quarry}, who manages to take sufficient shelter before the explosion rocks the battlefield. When your senses clear, you hear ${hiram}'s rifle firing once again.
	*else
		*set blown true
		As ${quarry} adjusts to this new threat, you seize the opportunity to light a stick of dynamite. Unfortunately, a flying bit of debris forces interrupts your throw, and once you've recovered, you fear you are too late. You dive for cover, and the dynamite explodes in a burst of light and heat. Your legs are nearly torn from your body; it will take you several minutes to repair the damage.

*if converted_tigers
	As West looks in the direction of ${hiram}, he flicks his clawed hand in your direction, and the tigers attack you.
	*gosub resolve_tigers

*if assistants_present
	At this point, the ${assistants}'s torches are lit and they begin to approach ${quarry}. They swing their torches back and forth, attempting to surround him.
	*if has_silver_bullets = false
		He's about to turn one of the ${zulus} to a spray of blood and cartilage when a bullet sinks into his forearm.
He drops to all fours and bounds @{assistants_present over the ${zulus}'s torches|} towards ${hiram}.
*if blown
	*set combat -3
	You watch helplessly, willing the blood in your veins to repair the damage to your legs so you can stand again.

*if b_present
	Bécard flies out of the night, but once again, ${quarry} knocks her aside.
Tossing aside what passed for construction materials, he lifts ${hiram} from the wet wreckage and sinks his fangs into his shoulder. ${hiram} screams.
*if (quarry = "West")
	*if has_silver_bullets and (blown = false)
		*set e_alive true
		One final blast from the Winchester straight into the underside of ${quarry}'s jaw releases Hiram, who falls to the ground. $!{quarry} knocks the now-empty rifle aside, while ${hiram} scrambles backwards and under a wagon.
	*else
		There, while you watch, ${quarry} drains the heartsblood from ${hiram}. Something deep inside you quails at the sight.
		*set eliot_consumed true
	
		In moments, Eliot's skin shrivels around his corpse before disintegrating to ash. His skeleton—now just bones in a funny costume—drops to the ground with a rattle.
	
		@{(eliot_rapport > 60) Your friend|The sailor} is no more.
*else
	$!{quarry} gnaws, tears, and rips at the neck of ${hiram}, finally severing his spine.
	
	In moments, ${hiram}'s skin shrivels around his corpse before disintegrating to ash. His skeleton—now just bones in a funny costume—drops to the ground with a rattle.
*page_break

It's at that moment that you hear a scream. A distinctly out-of-place scream.

Turning, you spy a wide-eyed Hiram, paralyzed by terror.

How can there be two?

When the other-${hiram} starts to move, you realize that it isn't ${hiram}. It can't be. Other-${hiram} is alive.

Other-${hiram} finally finds his courage—or his adrenaline—and turns to run. $!{quarry} is clearly confused by the sudden appearance of Other-${hiram} as well; he looks from the @{e_alive wagon where Hiram is hiding|frock coat still in his hands} to the fleeing figure. @{assistants_present He yelps in surprise as the ${zulus} singe him with their torches while he's distracted.|}

@{assistants_present That's the first time he's really taken notice of them. Until now, they've been a nuisance, but that apparently hurt.|}

*if e_alive
	He leaps into the air, crossing the space in a single bound and landing atop Other-Hiram. In a blue flash, ${hiram} erupts from beneath the wagon and slams into ${quarry}. 
	
	"Run, Tommy!" ${hiram} screams.
	*achieve death_by_water
	
	${quarry} turns his attention back to the supine ${hiram}, his blue coat now soaked with muck. Reaching down, @{(west_prob) he pulls out a pointed blade and drives it deep into ${hiram}'s eyesocket and out the other side. With a great roar, he grasps both ends of the blade and wrenches ${hiram}'s head from his neck.|with one final swipe of his claws, he severs ${hiram}'s head from his shoulders.}
	
	*if (perception > 1) 
		Out of the corner of your eye, you see Tommy splashing through the reeds, desperately trying to flee the battle.
*else
	He discards the coat and turns to face you@{assistants_present , swiping the torches of the ${zulus} out of his way|}. @{becardeliot_romance Behind him, you see ${sabine} trying to fish ${hiram}'s skull from the water. You can't imagine what good a skull will do for you right now.|}

*page_break

*if b_present 
	*set west_downfall +1
*if has_silver_bullets and (quarry = "West")
	*set west_downfall +1
	
*if tigers = false
	*if weapon_num < 5
		You charge @{west_prob ${imposter}|West} with your ${weapon}. @{weapon_num They glance off his hide, ineffectual.|Your claws rend his flesh, splattering you with blood|Your sword slices his flesh, which knits itself back together before your very eyes.|The head of the axe stops when it hits bone; when you pull it back to hack again, you see the flesh knit itself back together before your very eyes.}
	*else
		You level your rifle at @{west_prob ${imposter}|West}. You fire indiscriminately, just trying to slow the beast down.
		*if has_silver_bullets
			The silver bullets gouge ${quarry}'s flesh, leaving smoking pits in his hide and provoking howls of pain.
		*else
			The bullets seem to bounce of his hide—at best, they leave little knicks and cuts that seem to enrage you more than him.
*elseif west_prob = false
	*set tigers false
	You try to focus on ${quarry}, but the tigers have finished with their current occupations and turned their attention to you.
	*gosub resolve_tigers
*else
	*comment tigers against Wotton
	*set west_downfall +1
	The roar of the tigers rumbles through the darkness. You wonder if ${imposter} can feel fear.
	
	They leap out, claws extended.
	
	He raises his hand, clearly trying to dissuade them by the force of his will. Several of them break off, or turn on their comrades, but the majority fall upon him, and he is forced to fight them off with claw and fang.
	
	Soon, the roars turn to yelps of pain and meows of fear.
	*page_break
	$!{imposter} still stands, surrounded by the bodies of a dozen tigers. Your spell over the remainder has broken, and the ones that can have fled.

*if assistants_present
	The ${zulus} close around him, their torches held out before them. He tries to push them back, but they hold their formation and cluster their flames whenever he tries to close the distance. @{has_silver_bullets Between the flames and the silver, he is starting to show signs of his wounds.|}

Finally, battle is joined.
*temp carlos_saves_mem false
*temp memeskia_visible false

====
*line_break
Combat: ${combat}
*line_break
West Downfall: ${west_downfall}
*line_break
====

*if combat < 6
	*label battle_fail
	Or, what passes for battle. 
	
	The wolf-creature's claws pass through your meagre defenses with ease. He lifts you off the ground and sinks his fangs into your throat.

	You struggle as best you can, but you feel your soul being pulled from your body. 
	*if ((west_downfall < 3) and (combat < 6)) or ((west_downfall < 2) and (combat < 10))
		*if embrace_of_affection and ((sire_name = "West") and (patricide = false))
			In the moments before your consciousness disintegrates, you hear West's voice: "And now, I will take your soul into mine. You will be with me for eternity."
			
			Fitting, you suppose. Ninety years ago he murdered you out of something resembling desire, and now he condemns you to an eternity inside his blackened heart.
		*else
			In the moments before your consciousness disintegrates, you scream your frustration, your rage, your impotence. This cannot be the end.
	
			This cannot be the end.
	
			This cannot…
		*set killed_by_vampire true
		*set diablerized true
		*achieve diablerized
		*goto_scene scoring
	*else
		Suddenly, ${quarry} lets go. Through the haze of pain, you see 
		*if b_present 
			${sabine} attached to his back, her knives sunk into the meat of the interstices of his collarbone.
			*if carlos_saves_mem and (becard_scarred = false)
				*set becard_scarred true
				${quarry} reaches over his shoulder and sinks his claws into ${sabine}'s face, exploding her left eye in vitreous humors. She screams, loosening her grip on the daggers. He flings her away into the darkness.
				
			Amid this chaos,
		*elseif assistants_present
			that the ${zulus} have summoned their courage and jammed their torches in every crevice of his that they could reach.
			
			Amid this chaos,
		*elseif tigers
			that a final, stubborn tiger has leapt onto ${imposter}'s back, knocking him to his knees.
			
			But only for a moment—a great thrust of his arm and the tiger goes flying out of sight.
			
			Amid this chaos,
		@{carlos_saves_mem two more forms fly|another form flies} through the moonlight.
		
		*if carlos_saves_mem
			*set memeskia_visible true
			In the light of the full moon, Carlos and Memeskia do battle with ${quarry}. He is already @{((west_downfall > 2) and (carlos_saves_mem = false)) significantly|} wounded from your efforts, yet still the two of them still struggle to pierce his skin.
			
			Finally, Carlos and Memeskia fall into a rhythm of defense-and-harry: one parrys and blocks ${quarry} while the other assaults his rear.
			
			And then, ${quarry} is pinned. Drawing a knife of silver from his cassock, Carlos plunges the blade into ${quarry}'s heart; you can hear the sizzle as the immortal flesh recoils from the blessed metal.
			
			From there, Carlos pushes the blade deeper, finally severing the spine. The body goes still. Memeskia and Carlos collapse to the ground as the skeleton turns to dust under their weight.
			*goto severed_spine
		*else
			There, in the light of the full moon, @{west_prob two monsters|father and son} do battle. $!{quarry} is already @{((west_downfall > 2) and (carlos_saves_mem = false)) significantly|} wounded from your efforts. All the same, it is a mighty battle.
	
			Finally, ${quarry} is pinned.
	
			For a moment, you think Memeskia might offer mercy. Or demand answers. Or say something. Anything.
			
			$!{quarry} graps Memeskia around the neck, digging his claws into the flesh. The two @{west_prob |ancient} vampires' powers clash in the moonlight, with hardended skin slowly giving way to sharpened claws. And then, it's done. The neck is broken.
			
			But so too is the spine of ${quarry}. Together, the two disintegrate to ash. You watch, astounded, as a stiff breeze carries them both away.
			*set memeskia_alive false
			*if west_prob
				*if sire_alive and (sire_name = "West")
					*bug
			*if west_prob = false
				*achieve father_and_son
			*goto denouement
*elseif combat < 10
	*if west_downfall < 3
		*if carlos_present
			*set west_downfall +1
			*set carlos_saves_mem true
		*goto battle_fail
	*else
		
		West's movements have slowed. He's favoring one of his legs over the other.
		
		But it's not enough.
		
		The wolf-creature's claws pass through your meagre defenses with ease. He lifts you off the ground and sinks his fangs into your throat. You struggle as best you can, but you feel your soul being pulled from your body.
		*label west_lets_go
		
		*if b_present
			Suddenly, West lets go. Through the haze of pain, you see ${sabine} attached to his back, her knives sunk into the meat of the interstices of his collarbone.
			*if carlos_present and (becard_scarred = false)
				*set becard_scarred true
				${quarry} reaches over his shoulder and sinks his claws into ${sabine}'s face, exploding her left eye in vitreous humors. She screams, loosening her grip on the daggers. He flings her away into the darkness.
		*elseif assistants_present
			Suddenly, West lets go. Through the haze of pain, you see that the ${zulus} have summoned their courage and jammed their torches in every crevice of his that they could reach.
		*label saved_by_memeskia
	
		Amid this chaos, another form flies through the moonlight.
		
		There, in the light of the full moon, 
		*if carlos_present
			the Praetor and the Beast do battle.
		*else
			father and son do battle. 
		$!{quarry} is already @{(west_downfall > 2) significantly|} wounded from your efforts. All the same, it is a mighty battle.
	
		Finally, ${quarry} is pinned.
	
		For a moment, you think @{carlos_present Memeskia|Carlos} might offer mercy. Or demand answers. Or say something. Anything.
	
		But then ${quarry}'s throat is @{carlos_present cut out with a silver dagger; the sound of sizzling flesh makes you recoil in instinctual terror|torn out}.
	
		That does not stop ${quarry}, of course. He continues to struggle. 
		*if carlos_present
			Carlos changes his grip on the dagger and digs it into the exposed bone of ${quarry}'s spine. After wedging it for a moment, it finds purchase; he puts all his centuries-old strength into it and finally the blade sinks through.
		*else
			Memeskia draws a knife, however, and digs it into the exposed bone of ${quarry}'s spine. After wedging it for a moment, it finds purchase; he puts all his centuries-old strength into it and finally the blade sinks through.
	
		The spine severed, the body goes still. @{carlos_present Carlos|Memeskia} collapses to the ground as the skeleton turns to dust under his weight.
		*label severed_spine
		*if carlos_present = false
			*set memeskia_visible true
		
		*if tigers
			@{carlos_present Carlos|Memeskia} looks at the tigers. "He is hundreds of years older than you and was shapeshifting @{(ethnicity = "choctaw") before your ancestors arrived among the dancing rabbits|before your ancestors knew this land existed}. Did you think you could control animals better than him?"
			
			"I…"
			
			"Enough."
		*if west_prob
			"Well…" you begin.
			
			"That wasn't West," @{carlos_present Carlos|Memeskia} remarks.
			
			"What are you talking about?" @{b_present ${sabine} exlaims|you exclaim}.
			
			*if carlos_present
				*set stl_patricide_tribunal true
				"I met West two or three times. That was not him."
			*else
				*comment TODO what variable to set??
				"I know mine own dominus. As @{b_present he should know his," he says, nodding in your direction.|you should know yours."}
			
			"But…who else…" you @{(charm >= 2) say, feigning ignorance|sputter}.
			
			@{carlos_present Carlos|Memeskia}'s eyes narrow. "@{b_present You should be asking ${given_name}|I feel as though I should be asking you} that question."
			
			You suddenly wish the moon weren't shining quite so brightly.
		*goto denouement
*elseif combat < 12
	*if west_downfall < 2
		*goto battle_fail
	*else
		${quarry}'s movements have slowed. He's favoring one of his legs over the other. @{has_silver_bullets His right arm is hanging limply from where it's been shot.|}
		
		But it's not enough.
		
		$!{quarry} charges you. You raise your ${weapon} in preparation. The first few blows you manage to parry. @{weapon_num Your forearms ache from the impact.|Your forearms ache from the impact.|His claws send sparks into the night when they bounce off your ${weapon}.|His claws send sparks into the night when they bounce off your ${weapon}.|His claws leave gashes in the stock of your rifle as you desperately seek to defend yourself.}
		
		*label finally
		Finally, he @{(weapon_num > 2) knocks the weapon from your hands|slips through your guard} and seizes you by the throat. With one hand, he lifts you off the ground, your legs kicking in futility. You grasp at his wrist, doing everything you can to free yourself@{eliot_consumed  before you end up like ${hiram}|}. But your gestures come to naught before the might of ${quarry}.
		
		*if carlos_present
			Suddenly, a silver-bright maul smashes into the back of ${quarry}'s head, who drops you and crumples to the ground. Looking past ${quarry}, you see
			*if sire_name = "Padre Carlos"
				your dominus
			*elseif met_carlos
				Praetor Carlos
			*else
				a man that you have to assume is Praetor Carlos
			preparing for another blow.
			
			Before you can intercede, the second blow crashes down on the skull of the weakened ${quarry}. The flesh smokes from the contact with the silver. He tries to rise, but a third blow crushes the spine.
			
			And like that, ${quarry} turns to ash.
		*else
			*set memeskia_visible true
			Suddenly, a massive wolf-man appears behind ${quarry}, grabbing him and closing his jaws on his neck. The wolf-man—Memeskia, surely—tears and rips until finally a spray of blood soaks you and you fall to the ground.
			
			$!{quarry} and Memeskia spar, but ${quarry} is clearly losing.
			*if silver_dagger
				When you see your opportunity, you pull out your silver dagger and thrust it into ${quarry}'s back; the immortal's flesh sizzles from the contact and he lets out an immense howl—that is cut short by Memeskia's claws tearing out ${quarry}'s throat.
			*else
				Finally, beset on all sides, ${quarry} leaves his defenses open for a moment too long—and Memeskia seizes the opportunity to tear away much of his throat.
			
			$!{quarry} stumbles to one knee, but Memeskia gives him no respite, grasping at the exposed spine and seeking to snap it with his undead strength.
			
			A crack echoes through the night. And a moment later, where the mighty Beast once stood, there is only ash.
		*goto denouement
*elseif combat < 20
	*comment 19 is the max: 14 from stats, +2 claws or +1 weapon, +1 refined silver bullets, +2 if fighting Wotton.
	*if west_downfall >= 2
		West's movements have clearly slowed. He's favoring one leg over the other. His arm is hanging limply from all the gunshots he's sustained.
		
		But what will it take to finish him?
		*page_break
	You raise your ${weapon} and square off. With a snarl, he charges.
	
	The first few blows you manage to parry; @{weapon_num your forearms ache from the impact.|your forearms ache from the impact.|his claws send sparks into the night when they bounce off your ${weapon}.|his claws send sparks into the night when they bounce off your ${weapon}.|his claws leave gashes in the stock of your rifle as you desperately seek to defend yourself.|your forearms ache from impact.} In between his blows, however, you glimpse moments to strike; just…so.
	
	$!{quarry} leaps back, eyes wide. He felt that.
	
	You press the advantage.
	*if weapon_num >= 5
		*set combat -1
		*set weapon "fists"
		*set weapon_is "fists are"
		*gosub claw_check
		As best you can, anyway. @{(weapon_num = 5) Your rifle is long-since empty of shot. You've been using it as something like a staff, but it is now bent and gouged from ${quarry}'s claws. Another blow deflected splits the rifle in two. Growling in frustration, you discard the useless halves|Your revoler is long-since empty of bullets. You've tried to reload, but can rarely find a moment to load more than one or two bullets at a time. When you turn the revolver around and use it as a club, you realize that the barrel is now hopelessly bent. You discard it} and leap to the attack with your ${weapon} raised to grapple him.
		*set weapon_num 1
		
	*if west_downfall >= 3
		With @{weapon_num your fists pounding on ${quarry}'s wounds|your claws striking ${quarry}'s open wounds|your axe hacking again and again at the wounded ${quarry}|your sword slashing again and again at the wounded ${quarry}'s defenses}, he begins to retreat. You redouble your efforts; the sight of his weakness revives your flagging spirits.
		
		You press forward. @{assistants_present The ${zulus} unleash a ragged cheer at the sight.|} @{b_present ${sabine} appears at your side, adding to your onslaught; the wounded ${quarry} is clearly unprepared for the two of you.|}
		
		Finally, it's done. He's still fighting, but you can sense that you've won. ${quarry} is looking for an exit. He pulls back into the water, trying to let his supernatural constitution repair some of the damage you've wrought.
		*temp try_diablerize false
		
		*choice
			#"Surrender!"
				*if west_prob = false
					*achieve freefolk
					"I will never kneel," ${quarry} replies.
					
					You're surprised to hear West speak. You had thought him too far gone for that.
					*if m_sib
						"But, dominus, I beg you…"
						
						*if trans
							"Dominus?" he interrupts.
							
							"Can't you tell? Can't you see who I am?"
							
							West sniffs the air. His eyes narrow as he examines you more closely. "${original_name}?"
							
							"My name is ${given_name}."
							
							"I thought I recognized the smell of your blood. I often wondered if you had been touched by Loki Laufeyjarson. It seems I was right."
							
							@{(intelligence > 1) "I suppose you could say that…" you reply. It's unclear if West sees that as a blessing or a curse.|You tilt your head in confusion. Touched by Loki?} 
							
							"You had best do what you intend to do," he continues.
							
							*if compassion < 50
								"Why, dominus? Why have you killed all of these other vampires?"
								
								"It is the only way. The earth must be cleansed of our corruption. Our kind will fight on the side of darkness when Ragnarok arrives."
								
								"And killing us is the only way?"
								
								"It is. I will extinguish every last one of us. Unless you stop me."
								
							*else
								"No need to ask me twice," you reply
								*goto finish_this
						*else
							*if fled_from_sire
								"Beg me?" he croaks. "You left me pinned in a burning house. What right do you have to beg me?"
								
								@{(discretion > 50) "Perhaps I should have finished you off when I had the chance," you muse aloud.|"Forgive me, dominus," you reply.}
								
								"You made a mistake. Just as I have made mine. We must all live with the consequences of our choices."
								
								"And what would those be?"
								
								"Death."
							*else
								"There is only one solution to the problem of our kind, ${given_name}. To extinguish every last one."
							*line_break
							*line_break
						"That is your objective? To end our kind?"
						
						"I have lived for centuries and I have realized that we are a plague upon this world. We must be exterminated."
						
						"And you took it upon yourself to effect this crusade?"
						*if b_present
							
							"Why are you talking to him, ${given_name}? Kill him! Look, he's healing!" ${sabine} exclaims. She's right; his flesh is knitting back together as the moments tick by.
						
						"I did.@{fled_from_sire | You saw what we did in Texas, Nuevo Léon, and Tamaulipas. The carnage we wrought. What sort of war did you think I was preparing for?}"
						
						"Why did you let yourself be caught?"
						
						"Who says I let myself be caught?"
						*if goal = 12
							he smirks. "Don't you want the same thing I do? To see and end to vampires everywhere?"
							
							He's right. In the past, you have held close the idea that you could eradicate the curse of vampires from this earth.
							
							"What are you saying?" you ask.
							
							"Come with me, ${given_name}. Together, we will cleanse the earth of our kind."
							
							"And when we're done?"
							
							"When we're done? We'll greet the sun together."
							
							*choice
								#I join him.
									A smile slowly spreads across his wolfman face. "I knew that you would."
									*if b_present
										He looks in the direction of Sabine. "Now show me."
										
										And so you do.
									*page_break
									
									You and West set out to bring down every vampire in the world. Together, you persuade Memeskia to join the two of you—he is more intereseted in slaughtering colonists, but colonist-vampires are acceptable as well.
									
									Spiraling outwards from St. Louis, more and more vampires fall to your fangs. You drink their heartsblood with abandon.
									
									It's nearly twenty years later when the humans finally surprise you during daylight hours. You scream at them that you are trying to save them, but they are indifferent to your pleas. 
									
									And so you finally meet your end.
									*achieve dark_side
									[Here ends this storyline.]
									*page_break
									*goto_scene scoring
									
								*if (becard_rapport > 50) #No, I'm not ready to turn on my friends yet.
									*set compassion %-5
								#No, I do not trust this beast to ever surrender.
									*set discretion %-5
							
							"I cannot join you, dominus."			
							
							West howls in fury. "Enough talking, then. I will see you in Hel."
						*else
							"I do. Here we are. I have defeated you. The famous West, scion of Buljan, the greatest Beast-hunter in history. Brought low by his last scion, ${given_name} ${surname}."
							
							West howls. "Enough talking. I will see you in Hel."
				*else
					*if b_present
						*set patricide_exposed true
					"Surrender? Why would you allow me to surrender, you murderer?"
					
					That stops you cold. You were not expecting a response.
					
					"Who are you?" you demand.
					
					"Does it matter? Aren't you just going to kill me as well?"
					
					"What are you talking about?"
					
					"You murdered West, didn't you?" the wolf-man retorts. @{b_present A noise of surprise erupts from Bécard.|}
					
					"I…"
					
					"It's too late for your dissimulations, ${given_name}. That's your name, isn't it? You drank the heartsblood of our dominus. Admit it!"
					
					*choice
						#"You're right, I did. And now I'm going to drink yours!"
							*set try_diablerize true
							*set discretion %+5
							*if b_present
								*set discretion %+5
								*set independence %-5
								You hear Bécard gasp at your admission. No matter; you will deal with her later.
								
							"You are a blight upon this earth, ${given_name}. I pray that the ground will open up and hellfire will swallow you whole."
							
							"Perhaps, but you will not live to see that," you reply.
						#"I did not drink his heartsblood—but I did kill him. And I regret it every day."
							*set compassion %-10
							*if b_present
								*set atrocities -1
								You look at Bécard as you say this, knowing that you are putting yourself in the worst possible situation with regard to the Society by admitting to your crime.
							
							"You didn't?"
							
							"No."
							
							His eyes grow distant—his entire purpose has been dashed. The deaths of dozens of vampires—sins unaccountable—rendered meaningless. He shakes his head and refocuses his eyes on you. "It doesn't matter. I will avenge our maker's death."
							
							"Why did West matter? When all those other vampires didn't?"
							
							"Because he made me. He made you. And to kill one's maker is the gravest crime." He spits in your face.
						#"I would never kill my maker!" you lie.
							*set discretion %-10
							"Liar!" ${imposter} yells, before leaping to attack you.
			*if ((west_prob = false) and (tryphon_identity > 1)) #"Do you seek the one who sleeps? Who is he?"
				*set heard_of_olympias true
				West smiles at you. "I do. It is a scion of Olympias."
				
				"And he's here? Under the Exposition?"
				
				West spits on the ground. "You would steal his power for yourself." @{taste_for_vampire_blood He peers at you queerly. "I can see your hunger for it. The very idea of it dances through your mind. Seductive. Beckoning. You will fall victim to it, I have no doubt."|}
				
				@{b_present "Why are you talking to him, ${given_name}? Kill him! Look, he's healing!" ${sabine} exclaims. She's right; his flesh is knitting back together as the moments tick by.|You observe from the corner of your eye that his flesh is beginning to knit back together.}
								
				"Tell me!" you cry.
				
				"Never," he says, the faintest hint of a smile on his face.
			#I can't let him heal! I press the attack.
				*if taste_for_vampire_blood and ((discretion > 45) and (willpower < 3))
					*set try_diablerize true
			#I want to drink his heartsblood.
				*set try_diablerize true
		*label finish_this
				
		You press your advantage. You sustain a solid blow to your abdomen for your troubles; if you were alive, you might be worried about your intestines hanging from the gash in your side. As it is, you must simply be careful not to step on them. @{((agility > 2) and (intelligence > 2)) Though, they'd probably just disintegrate or something if that were to happen—withered and dessicated as they are. You put that thought aside for another time.|}
				
		A final blow and he staggers to his knees.
		*if try_diablerize
			You bare your fangs and sink them into his neck. You catch a tendon—inelegant, but now is not the time for reproach—and bite through it. After a great exhalation, you begin to suck.
			
			$!{quarry} struggles at first. It slows in time. You can feel what remains of his blood flowing out his neck and into your gullet.
			*if b_present
			
				"${given_name}! What are you doing?"
				
				You ignore the distant interruption of ${sabine}. She can't understand what it's like to drink the heartsblood of another vampire. @{m_sib And certainly not your dominus, at that.|}
				
				"${given_name}! Stop!" 
				
				The shouting continues. Why can't she just go away? You can feel the first hints of the heartsblood. The soul of ${quarry} being drawn out of his body and into yours.
				*if strength > 3
					*gosub_scene util diablerie
					*set stl_public_diablerie true
					*achieve exiled_from_stl
					*set becard_rapport %-30
					You can feel her hands on you, trying to pull you away, but you are too strong.
					
					You continue sucking until the last of ${quarry}'s heartsblood passes from him to you. When the last drop has crossed your lips, his body turns to ash.
					
					"What have you done?" ${sabine} demands.
					*page_break
					You come back to your senses to find Sabine standing over you. $!{quarry} is no more; the ashes that were once him are already dispersing at the behest of the nighttime breeze.
					
					Strangely, Memeskia is there as well. His eyes are flashing in anger.
					
					"You have slain West, but you have done so by drinking his heartsblood."
					
					"How…"
					
					"Sabine saw you. Do you deny it?"
					
					"No."
					
					"Leave. Leave now. Do not return. Never return. If you are still within the city by the time the sun rises, I will destroy you myself."
					
					You stand.
					*if eliot_rapport > 60
						You look in the direction of Eliot's remains.
						*if becardeliot_romance
							Bécard sees your glance and
							*if agility > 3
								tries to slap you, but you catch her hand.
								
								"He's gone, Sabine."
								
								"Fuck you, ${given_name}."
								
								You release her wrist.
							*else
								slaps you as hard as she can.
								
								"A creature as cruel and evil as you has no friends," Bécard admonishes you. "Don't for a moment think that he was one."
					*else
						If you were more sentimental, perhaps you might be sad that this will be your last glimpse of St. Louis. Or that you're saying farewell to these people that you've lived among for the past three decades.
						
						But that's not you.
							
					You turn and set off into the night.
					*page_break
					*goto_scene timejump5
				*else
					*set becard_rapport %-20
					You scream as she pulls you away from ${quarry}. What is she doing?
					
					"ENOUGH!" she growls.
					
					She lets go of your head just long enough to take her silver dagger and plunge it into the wound that your fangs made. ${quarry}'s skin sizzles at the contact, and she works it through until she can sever the spine.
					
					"No!" you scream as ${quarry} dissolves to ash in your arms.
					
					"You are disgusting, ${given_name}," she spits. "What did you think was going to happen if you consumed him? Soon, it'd be your neck that I was cutting in to."					
					*goto denouement
		*else
			You climb atop him and begin hacking at his neck with a blade.
			
			It's a grisly business. His skin is hard as granite, and even when you do manage to chip away a bit of meat, you can see the meat begin to knit back together.
			
			But he is clearly weakened: @{has_silver_bullets his flesh sizzles from the silver bullets,|} @{assistants_present his left side a massive char from the ${zulus}' torches,|} @{(weapon = "claws") the gashes from your claws weep dead blood onto the earth,|} struggling to put himself back together.
			
			You strike three, five, ten times…until the bone finally cracks, the tendons still holding this ancient beast together, his eyes wide and screaming against the eternal darkness.
			
			And then, it is done. Within moments, there is only ash in your hands.
			
			${quarry} is no more.
			*if carlos_present
				*page_break
				You hear a faint clapping. Turning, you spy
				*if sire_name = "Padre Carlos"
					your dominus
				*elseif met_carlos
					Praetor Carlos
				*else
					*set met_carlos true
					a man in a cassock whom you suppose is Praetor Carlos
				advance upon you.
				
				"I have to wonder why you summoned me," he begins.
				
				You snarl. "Yes, I wonder that as well."
				
				"You had this well in hand, I see."
				
				*if eliot_rapport > 60
					"Perhaps if you had stepped in, Hiram wouldn't be dead now."
					
					"The sailor? He was a heretic. I felt no need to save him."
					
					*if (discretion > 80) and (eliot_rapport > 80)
						*set killed_by_vampire true
						Something within you snaps. This callous wretch@{(sire_name = "Padre Carlos") —your maker, no less—| }stood by and watched while ${quarry} @{eliot_consumed consumed|murdered} Hiram.
						
						Your fangs extend and your vision clouds. You launch yourself at the Praetor.
						
						Perhaps, if you were rested, you could have taken him. But you are already wounded and spent from your battle with ${quarry}.
						
						Within a few minutes, Praetor Carlos has crushed your skull in with a silver-capped maul.
						*goto_scene scoring
					*elseif (religious_tradition = "reformed")
						You suppose you would also count as a heretic, where Praetor Carlos is concerned.
					*elseif (religious_tradition = "pagan")
						You shudder to think how he would describe you.
					You are no stranger to cruelties, yet at this moment, even you are surprised by the callousness of @{(sire_name = "Padre Carlos") your maker|the praetor}.
					
					*fake_choice
						#"That should have been you," you spit.
							*set independence %-10
							*if sire_name = "Padre Carlos"
								*set sire_rapport %-10
							*else
								*set carlos_rapport %-10
							"But it wasn't," he shrugs.
						*if (religious_tradition != "pagan") #"Clearly, it was God's will."
							*set rationalism %+10
							*if religious_tradition = "catholic"
								*if sire_name = "Padre Carlos"
									*set sire_rapport %+5
								*else
									*set carlos_rapport %+5
								"A bit theologically simplistic, I suppose, but I take your meaning," he replies.
							*else
								*if sire_name = "Padre Carlos"
									*set sire_rapport %-10
								*else
									*set carlos_rapport -10
								"I'm not surprised a heretic such as yourself would resort to such pablums," he replies.
						*if (eliot_consumed) #"No one deserves such a fate," you reply.
							*set compassion %-5
							"And yet many have suffered it," he retorts.
						#I bite back any retort.
							*set discretion %-5
							
					Satisfied that there is no more need for him, Carlos nods. "Well, I'm sure I will see you at Memeskia's court. Goodnight."
			*goto denouement
	*else
		Your success is short-lived. He leaps forward, eyes flashing red. His claws sing as they fly the through the air.
		*goto finally
*else
	*bug combat this high shouldn't be possible.

*label denouement
*page_break
*if carlos_present
	
	Carlos stands and dusts off his cassock. He puts his weapons away.
	
	*if assistants_present
		"You!" he commands, addressing one of the ${zulus}.
		
		A young man, no more than seventeen, steps timidly forward.
		
		*if met_carlos
			@{(sire_name = "Padre Carlos") Dominus|Praetor}, is this really necessary?"
		*else
			"Excuse me, Praetor…I know that we haven't met, but…"
			
		"Send your servants home, ${mr} ${surname}. I hunger."
			
		*if compassion < 55
			You grasp for a response. These humans just fought and bled for you, and now Carlos is going to kill another one?
			
			*if (zulus = "Cheyenne") and memeskia_visible
				*label dont_feed_cheyenne
				*if sire_name = "Padre Carlos"
					*set sire_rapport %-5
				*else
					*set carlos_rapport %-5
				*set carlos_present false
				"Praetor, now is not the time. These warriors have served us well," Memeskia interjects.
				
				Carlos looks surprised at Memeskia's intervention. He sets his jaw, turns, and marches away into the night.
			*elseif memeskia_visible
				You look to Memeskia, but you find no alliance there.
			*else
				Your eyes dart around the village square, seeking some solution to this problem, but find none.
				*if sire_name = "Padre Carlos"
					*set sire_rapport %-5
					Carlos grunts, disappointed by your softness.
		*else
			*if (zulus = "Cheyenne") and memeskia_visible
				*goto dont_feed_cheyenne
		
		You thank the ${assistants} and send them on their way.
		*if carlos_present
			*set carlos_rapport %+5
			Meanwhile, Carlos drags the young man into a nearby hut. The screams echo through the darkness.
			*if met_carlos = false
			
				Not exactly how you'd imagined meeting the Praetor of the Americas.
		
		@{memeskia_visible Memeskia, for his part, vanishes into the night as well.|}

*if b_present
	"${given_name}?" Bécard ventures. 
	*if memeskia_alive 
		"Is he gone?"
		
		*if eliot_consumed
			"He consumed Hiram."
	*else
		"They're…both gone?"
		
		"Yes."
		
		*if becardeliot_romance
			"And Hiram too…"
			
			You can sense her choking back tears.
			
			"Yes, Hiram as well."
	
	"What about Tommy?"
	
	*if ((compassion < 35) and (discretion < 40)) and (becard_rapport > 60)
		"We have to protect him."
		
		"But Memeskia…" Sabine begins.
		
		"You can convince him to keep his mouth shut, yes?"
		
		Sabine hangs her head. "Yes…I can."
	*else
		"What do you propose?" you snap.
		
		Bécard stiffens. "I will make sure nothing is said."
		
		*if (compassion > 50) and (discretion > 50)
			*set becard_rapport %-10
			"I could…" you begin.
		
			"Don't you dare," she retorts.

*return

*label claw_check
*if shapeshifting > 2
	*set weapon "claws"
	*set weapon_is "claws are"
	*set weapon_num 2
*return

*label weapon_choice
*set combat +1
*choice
	#A rifle.
		*set weapon "rifle"
		*set weapon_is "rifle is"
		*set weapon_num 5
	#A sword.
		*set weapon "sword"
		*set weapon_is "sword is"
		*set weapon_num 3
	#An axe.
		*set weapon "axe"
		*set weapon_is "axe is"
		*set weapon_num 4
You acquire a ${weapon} and hope that it will aid you when the final confrontation with @{west_prob ${imposter}|West} comes.
*if knows_about_silver
	*if weapon = "rifle"
		*set knows_about_bullets true
		In addition, you commission the creation of silver bullets for use in the rifle.
		*gosub blacksmith_bullets
	*else
		*set silver_dagger true
		The problem, however, is that silver is difficult if not impossible to forge.
		
		After investigating the matter, you conclude that the only solution is to commission the creation of a silver dagger. You will not be able to use it in the initial skirmish, but the right opportunity may yet arise.
*return

*label combat_check
*if combat >= 5
	*if combat >= 6
		*if combat >= 7
			*if combat >= 8
				*if combat >= 9
					*if combat >= 10
						*if combat >= 11
							*if combat >= 12
								*if combat >= 13
									*if combat >= 14
										*if combat >= 15
											Boo!
*return

*label get_t_prey
*temp t_prey "prey"
*temp t_prey_he "he"
*temp t_prey_his "his"
*temp t_prey_him "him"
*temp t_prey_man "man"
*return

*label resolve_tigers
*set west_downfall -1
*if weapon_num = 1
	You ready your fists. The first blow lands on the square on the lead tiger's nose, eliciting a yelp and a quick retreat. You seize the second tiger and use its weight and velocity to throw it over you. The third, however, knocks you down and pins you to the ground.
*elseif (weapon_num < 5)
	You ready your ${weapon}. The first blow splits the skull of the first tiger in two. The second catches an artery on the second, and it leaps away with a howl. The third, however, bats the ${weapon} away, and pins you to the ground.
*if weapon_num = 5
	You lower your rifle and begin firing. The hot blood sprays over you. One down. Two. The third bats your rifle to the side.
*if weapon_num > 1
	*set combat -2
*if combat < 8
	With a roar, the tiger's maw closes around your head and snaps shut. With a wrench, your head is severed from your body.
	*goto_scene scoring
*else
	*achieve tigerkiller
	Summoning whatever reserves of energy you have, you punch your fingers deep into the tiger's eyeball and into its brain. It explodes in a geyser of viscous tissue.
	
	You push the tiger off your body and attempt to ascertain the status of the battlefield.
	*if (weapon_num = 1) and e_alive
		To your relief, you see that ${hiram} shot both of the other tigers dead while you were pinned.
	*elseif (weapon_num = 1) and b_present
		To your relief, you see that ${sabine} dispatched both of the other tigers while you were pinned.
*return

*label resolve_gabriel
*if ((gabriel_status = 2) or ((gabriel_status = 7) or (gabriel_status = 4))) or (becard_gabriel_status = 5)
	*comment Nothing. Gabriel is dead, mind-wiped, or fled.
	*comment if 2 or 4, maybe have a moment where Bailey thanks the PC for dealing with Gabriel?
*else
	*page_break
	One evening at the Southern Hotel, Bécard announces that the Vampire of Cincinnati has been handled. She informs the court that Gabriel was not in fact a vampire, but rather a charismatic mortal.
	*if becardeliot_romance
		@{(eliot_rapport > 60) Eliot confides in you that |}Bécard urged him to continue his perigrination elsewhere. @{(gabriel_status = 3) You grit your teeth; that was not the outcome you were hoping for.|}
	*else
		She disposed of the body safely. @{(gabriel_status = 3) That certainly resolves any lingering problems around your breach of the Rule of Reserve.|}
	*if stlouis_tribune
			
		Bailey is very curious to know why you were not the one to handle the situation. @{(becard_gabriel_status = 2) Thankfully, Bécard does not add fuel to Bailey's fire by disclosing that you had in fact encountered Gabriel and failed to do anything about ${g_him}.|}
		
		*choice
			#I point out that since ${g_he} wasn't a vampire, it wasn't my responsibility.
				*set independence %-10
				*set bailey_rapport %-5
				Bailey scowls at your response; he clearly believes that you still should have taken the matter in hand.
			*if (gabriel_status = 5) #"I did, in fact, encounter Gabriel. When I realized that ${g_he} was not a vampire, I sent ${g_him} on ${g_his} way."
				Bécard shoots you a look.
				*if spoke_becard_fair
					*set becard_rapport %-5
					*set bailey_rapport %-5
					*if becardeliot_romance
						*set eliot_rapport %-5
					"We just watched a basketball game together and chattered the night away. You did not think to mention this then?"
					
					"It must have slipped my mind."
					
					She scowls at you, clearly displeased.			
				*elseif becardeliot_romance
					"You could have saved me several evenings hunting him down."
					
					"I apologize; I did not have the chance to speak with you before you took action."
					
					She backs off, satisfied with your apology.
				*else
					*set becard_rapport %-5
					You suspect that she regrets killing Gabriel—and now blames you for her deed. "And you said nothing?"
					
					"I did not have the chance to inform you," you reply.
			#I assert that I am focused on finding West, and that she should not dare to question me.
				*if status > 2
					*set bailey_rapport %+5
					Bailey interjects. "I'm sure Ms. Bécard was happy to take care of this for you, ${mr} ${surname}. The quest for West certainly does take precedence."
					
					You nod. Even Bécard seems mollified.
				*else
					*set becard_rapport %-10
					*set bailey_rapport %-15
					*set eliot_rapport %-5
					*set bjornsdotter_rapport %-5
					The room breaks into guffaws.
					
					"Ms. Bécard has far more standing in the Society than you, ${mr} ${surname}. She can and will question your actions to her heart's content."
	*elseif becard_gabriel_status = 3
		*set bailey_rapport %+5
		*set bjornsdotter_rapport %+5
		She even thanks you publicly for your assistance in tracking down this individual. There is a polite round of applause.
				
	The rest of the evening passes without incident. You return to your haven in your ${coupe}, wondering what other surprises the Fair has in store for you.
	*set becard_gabriel_status 4
*return