*comment ñáéç…—
*hide_reuse
*advertisement
*set year 1904
*temp mr_german "Herr"
*if male = false
	*set mr_german "Fräulein"
*if priest
	*set mr_german "Hochwürden"
*temp spoke_b_and_p false
*temp com_gudhrun ((speaks_english or speaks_french) or speaks_german)
*label bullfight_setup
*comment 1904-03-??
*if (shepherd_credentials > 65) or ((stlouis_enterprise = 1) or (intelligence > 2))
	To the amazement of everyone attending to matters of foreign policy and international conflict, the Empire of Japan launched a surprise attack on the Russian fleet moored at Port Arthur, Manchuria. Four hours after the attack began, the Empire cabled Tsar Nicholas II to announce their declaration of war.
	
	It takes eight days for Tsar Nicholas to fully grasp the situation and declare war in response.
	
	The idea that a "lesser nation" such as Japan would dare to strike one of the greatest European powers is mocked and ridiculed by the élite of the United States. Everyone is certain that Japan will soon regret their actions.
	
*if local_fame > 55
	*set norris_arena 5
	Sometime in March, a local entrepreneur by the name of Richard Norris knocks on your door, proverbial hat in-hand. Once announced by ${stlouis_valet}, he suggest a business partnership.
	
	"${mr} ${surname}, there's gunna be a whole host a' folks who ain't interested in attendin' no church during the fair. Seein as the fair is gunna be closed on Sundays, I wanna give 'um sumthin' to do." @{renter He seems uncomfortable with your threadbare accommodations; you can sense his hesitation. Why would someone of your reputation be living in a rooming house?|}
	
	"Go on, Mr. Norris."
	
	"There's a piece of land just across from the fairgrounds. I can lease it real cheap, and we'll be the only game in town on Sundays."
	
	*if browns_sundays_moved
		*set norris_arena 7
		"Your pleas fall on deaf ears, Mr. Norris. There is no entertainment on Sundays for a reason: it is the day dedicated to Our Lord and Savior. Now, if you will excuse me…"
		
		Mr. Norris sputters in disbelief and excuses himself.
		*goto inaugural_court
	
	"And you want me to invest in this endeavor?"
	
	"I do. We can build an arena, and sell tickets. We'll make a killing."
	
	@{(compassion > 55) "I like killing," you say with a smug smile. Norris doesn't seem to know how to react to that.|"I don't care for that expression," you reply. Norris apologizes for the euphemism.} "How much of an investment do you need?"
	
	"Two thousand dollars would allow me to lease the land and build an arena. I thought I might start by organizing a bullfight?"
	
	*choice
		*selectable_if (wealth > 50000) #I have the liquid funds. I will have a bank draft drawn.
			*set wealth -50000
			*goto norris_partnership
		*selectable_if (income > 5) #I have sufficient investments; I can divest to raise the necessary capital.
			*set income -5
			*label norris_partnership
			*set norris_arena 3
			Norris is clearly delighted with your partnership.
		*selectable_if (wealth > 25000) #"Why give them what they want, when you can overpromise and underdeliver?"
			*set norris_arena 4
			*set compassion %+10
			*set wealth -25000
			"What do you mean, ${sir}?"
			
			"Lease the land, build a frame, sell some tickets. And have at train ticket for the morning of the display."

			"But, why make one sale, when we could keep the racket going all summer and fall?"

			"Sometimes you have to seize what is offered; too many things might go awry."
			
			Norris rotates his hat in his hands as he considers. "Let's do it."
		#I thank Norris for the opportunity, but decline. I'm not one to make deals with mortals.
			*set discretion %+5
			Norris seems surprised, but doesn't try to argue with you.
	You direct ${stlouis_valet} to see him out.
	*if (norris_arena = 3) and (ethnicity = "spanish")
	
		Your father only ever attended one bullfight in his life, but he regaled you with tales of it when you were young: while on a trade expedition, he traveled all the way to Veracruz, where he had the oppotunity to spend a hot afternoon watching the theatrics.

		You push away the thought of his shining eyes. Thoughts of your mortal life will bring you no peace.
	*page_break
*else
	*set norris_arena 6
*if werewolf_hysteria > 6
	*set stlouis_business_climate %+5
	To your surprise, several entrepreneurs have taken it upon themselves to develop and sell werewolf-themed merchandise for the Exhibition. It begins with the werewolf-themed cigars and rolling tobacco, but soon Lemp Brewery gets in on the action and releases a special Werewolf Lager.
	
	You suppose that it is good that the St. Louisans are taking the threat of violent death with good humor.
	*page_break

*label inaugural_court
*page_break
*comment 1904-04-29 Friday
*temp tribune_favor_points 0
*set month 4

The crystal chandeliers of the Southern Hotel glitter above you, casting their soft light to all corners of the room. 

"This is not your home. Don't overstay."

It's unclear whether Memeskia is referring to St. Louis, Missouri, or the Americas as a whole, but the attendant vampires do their best to take the terse welcome in stride. When it becomes clear that he has nothing else to say, Bailey @{(perception > 1) squeezes Partridge's hand and|} steps forward.

"On behalf of the Senate and Quaestor Memeskia, allow me to welcome Governor Gudhrun Björnsdotter once again to St. Louis."

The Governor inclines her head.
*temp not_tribune true

"Thank you, Quaestor Memeskia, for hosting us in your city. I trust that all your guests will conduct themselves with discretion." You look around the room; in your estimation, no one here this evening would endanger the city or the Society. "However, to ensure the safety of us all, I invite Memeskia to appoint a tribune for the duration of the fair."

There is a small rustle through the crowd. @{((perception > 1) and becardeliot_romance) Eliot grips Bécard's hand.|}
*temp told_by_eliot false

"I imagine this is something of a surprise. Let us adjourn and give the Quaestor some time to consider. We'll reconvene to announce the appointment in three hours."
*if tribune_explained

	You, however, were expecting this. Have you already been seeding the idea that you would be appropriate for this over the past few months?
	*choice
		#Yes.
			*set discretion %+5
			*set independence %+5
			*set tribune_favor_points +2
		#No, I value my existence more than this!
			*set discretion %-10
		#No, I am not an instrument of the Society's sense of order.
			*set independence %-20
			*set compassion %-5
			*set not_tribune false
		
*if (lore > 2) and (tribune_explained = false)
	*set tribune_explained true
	A tribune is an individual invested with the authority to maintain order. In particular, tribunes are of value when there are too many vampires for a quaestor to manage alone.

The gathering breaks apart.
*temp becard_explained false
*temp eliot_explained false
*if (lore > 2) or tribune_explained
	You muse a moment on whom you will approach.
*elseif (eliot_rapport > 45) and (tribune_explained = false)
	*set eliot_rapport %-5
	*set tribune_explained true
	*set eliot_explained true
	You grab Eliot's forearm as he passes. "What's a tribune?" you whisper.
	
	"Sort of like a sheriff. Someone to keep the riff-raff in line. Like this Vampire of Cincinnati character…should he dare show his face here," Eliot shakes his head.
	*if heard_of_malloy
	
		"Is that the position that Siobhan Malloy used to occupy, in Manhattan?"
		
		"Yes."
	
	"Do you want to be one?"
	
	"Me? Heaven's no."
	*if stl_west_volunteer
		*set told_by_eliot true
		He looks at you briefly. "But I'm sure you do."
		
		"How did you know?"
		
		"You see West as your responsibility, don't you?"
		
		"Yes…"
		
		"Then it stands to reason…"
		
		"Oh, shush, Hiram," you reply.
*elseif (becard_rapport > 50) and (tribune_explained = false)
	*set becard_rapport %-5
	*set tribune_explained true
	*set becard_explained true
	"Sabine!" you whisper as she passes you. She half-turns, so that you are not facing one another, but you can speak into one another's ears.
	
	"What, ${given_name}?"
	
	"What is a tribune?"
	
	"Where were you raised, child?"
	
	"Enough, Sabine."
	
	"A tribune is like a patrolman. They keep an eye out for other vampires who are unknown, unwelcome, or otherwise breaking the Three Rules. Like the Vampire of Cincinnati, should he come here."
	
	"Isn't that what the Quaestor does?"
	
	"Well, yes, but sometimes…occasions such as this…when the task is clearly beyond the capabilities of a single vampire. Now, I must go."
	
	"Thanks," you reply.
*else
	You are left wondering what a tribune is.

*temp knows_becard_candidate false
*if perception > 2
	*set knows_becard_candidate true
	Observing the room, you get the sense that there is only one candidate for the position: Bécard.

*temp aichingers_favor false
*temp baileys_favor false
*temp bjornsdotters_favor false
*temp favor_time 0
*temp announced_intention false
*temp becard_torpedo false
*if (becard_rapport <= 40) and stl_pig_farm
	*set becard_torpedo true
*temp just_spoke 1
*label court_convo_picker
*if announced_intention and (becard_torpedo and ((just_spoke != 3) and (just_spoke != 4)))

	From across the room you hear Bécard's intentionally too-loud voice. "The pig farmer wants to be tribune?" she says with a laugh.
	
	Whirling, you spy Bécard in conversation with @{just_spoke Bailey and Partridge|Aichinger|ERROR|ERROR|Bailey and Partridge|Aichinger}.
	
	@{just_spoke Aichinger looks|Bailey and Partridge look|ERROR|ERROR|Gudhrun looks|Memeskia looks} at you in surprise. "You feed from pigs?"
	
	Seeing no point in denying it, "I do."
	
	The room laughs uproariously. You do your best to ignore the laughter as you try to continue your lobbying efforts.
	*set aichinger_rapport %-10
	*set bailey_rapport %-10
	*set bjornsdotter_rapport %-10
	*set eliot_rapport %+20
	*set memeskia_rapport %-10
	*set partridge_rapport %-10
	*set tribune_favor_points -1

*if favor_time <= 2
	*set favor_time +1
	With whom would you like to speak?
	*choice
		#Aichinger.
			*temp convo_time 3
			You approach Aichinger, who turns to greet you @{(aichinger_rapport > 55) with some enthusiasm|reluctanty}. "@{speaks_german Yes?|[i]Ja?[/i]}"
		
			*label aichinger_questions
			*if convo_time = 0
				*label end_aichinger
					
				You nod.
				
				"Was there anything else?"
				
				"No, thank you."
				
				Your conversation finished, you consider your next move.
				*goto court_convo_picker
			*choice
				*if (tribune_explained = false) #"What is a tribune?"
					*set convo_time -1
					*set discretion %+2
					*set independence %+5
					*set aichinger_rapport %-3
					*set tribune_explained true
					"@{speaks_german God in heaven,|[i]Ach,[/i]} ${mr_german} ${surname}! Did your dominus teach you nothing?"

					"Just spit it out."

					"The tribune is the eyes, ears, and hands of the quaestor. It is the tribune's obligation to seek out unwelcome vampires and deal with them."

					"Police?"

					"Something like that, yes."
				*if (tribune_explained and not_tribune) #"I wish to be Tribune."
					*set announced_intention true
					*set convo_time -1
					*if aichinger_rapport > 60
						*set aichingers_favor true
						*set tribune_favor_points +1
						@{speaks_german "As well you should.|"This I can see.} I will support you."
					*elseif (aichinger_rapport > 50) or (revolutionary_credentials < 40)
						*set tribune_favor_points +0.5
						@{speaks_german "I will not stand in your way|"If you must}."
					*else
						@{speaks_german "I cannot support you in you this.|"And you wish for my support in this?} Fräulein Bécard is clearly more suited to the position."
						
						*if knows_becard_candidate = false
							*set knows_becard_candidate true
							"She is standing for the position?"
							
							Aichinger rolls his eyes. "I do not think she can escape it."
				*if (knows_becard_candidate = false) #"Who is likely to be named Tribune?"
					*set convo_time -1
					*set knows_becard_candidate true
					"Fräulein Bécard, of course."
					
					"She is standing for the position?"
					
					Aichinger rolls his eyes. "I do not think she can escape it."
				#"How long until Germany hosts an Olympics?"
					*set convo_time -1
					*set aichinger_rapport %+5
					"@{speaks_german God in heaven,|[i]Ach,[/i]}" he exclaims, waving his hand. "I am sure the Kaiser will be seeking one soon enough, but Coubertin will never allow it."
					
					"No?"
					
					"@{speaks_german Definitely not.|[i]Nein.[/i]} The whole matter is an attempt by that Frenchman to prepare France for war against Germany."
					
					"What?"
					
					"Have you read any of his speeches? He complains that the French are unfit for military duty. He wants the youth of his country to prepare themselves for war. And when France goes to war, Germany suffers."
					
					*if intelligence > 2
						*set aichinger_rapport %+5
						"Germany didn't exactly suffer in 1870."
						
						"Only because Bismarck was prepared and anticipated France's aggression!"
						
						"Or did Bismarck provoke France?"
						
						Aichinger snorts. You sense that he agrees with you, but is stuck between pride at Bismarck's cleverness and his own protestations of innocence. As a gesture of mercy, you return to the topic at hand.
					
					"I did not realize Coubertin's purpose in this."
					
					"It is the same in England. They have amassed great wealth and now the elder generation frets that the youth does not have the grit that they did in their youth. Coubertin is one of these types."
					
					*if shepherd_credentials > 40
						"Would it not be better for the mortals to work out their disagreements on the field of sport rather than the field of battle?"
						
						"Perhaps, but how long do you really think that would continue?"
						
						*if compassion <= 30
							"Ideally? Forever."
							
							"You have much more faith in humans than me, @{male [i]Herr[/i]|[i]Fräulein[/i]} ${surname}."
						*else
							"A few years, at least."
							
							"What is the point of a solution that only lasts a few years?"
							
							"Perhaps it is better than none?"
							
							"Perhaps," he replies.
					*else
						*if feeding_style = "vegetarian"
							You ponder how to respond to Aichinger. Since you do not feed from mortals, the question of their physical fitness is not one that concerns you. After a moment, "A man concerned for the future of his country."
							
							"[i]Ja,[/i] exactly!"
						*else
							"I suppose I do prefer my prey to put up a bit of a fight."
							
							"Yes, but it is not about whether or not the youth can put up a fight, but ideas of purity and corruption, and the consequences of a generation grappling with its own mortality."
							
							"And do you grapple with your mortality, [i]Herr[/i] Aichinger?"
							
							"Not as much as I should, I suspect."
				*if (speaks_german) #"Do you ever visit Hermann?" Hermann is a German colony up the Missouri.
					*set convo_time -1
					*set aichinger_rapport %+5
					"Yes, I have been. Several times. But it is not my Bavaria."
					
					"What do you mean?"
					
					"Very few of the people who live there were born in Germany…many of them were born in Pennsylvania! And their parents came from the Rhineland, Hesse, and other western portions of the Empire. They drink wine," he spits out the word, "instead of beer."
					
					"And so…"
					
					"And so it does not provide the comfort you seem to think it would.
					*if ethnicity = "german"
						*if male
							But you, they are your people. I'm not surprised you find them comforting. Though, they are mostly Catholic."
							*comment TODO go to Hermann and find relatives??
						*else
							They are more your sort. I'm surprised you do not find them comforting."
					*else
						Not that you would know anything about that."
					He sighs. "Germany is a very large place, only loosely connected by a language. I know that you have never been, but sometimes it seems I have more in common with Bohemians than Rhinelanders."
					
					*if anachronism > 75
						"Do such distinctions serve you, though?"
						
						"How do you mean?"
						
						"I don't see any colonies of Bavarians settling in Missouri."
						
						"Other than Dutchtown, you mean?"
						
						"Well, yes."
						
						"I have no need to befriend the people of Hermann. I am quite satisfied with the people of Dutchtown."
				*if (heard_of_fragala) #"What do you think of the new Quaestor of Kansas City?"
					*set convo_time -1
					*set independence %+5
					*if aichinger_rapport > 60
						Aichinger glances in both directions, trying to ascertain who might be listening to your conversation.
						
						"The leper? Do not underestimate him. He is clever and knows things that he should not."
						
						"What sorts of things?"
						
						"Gossip. Mortal gossip, in particular. How he gathers secrets is a mystery to me, but he does. And he uses it to good effect."
						
						"I see."
					*else
						"I am sure that he will do a fine job in his new role, ${mr} ${surname}. Do you have some reason to doubt him?"
						
						"No, but his arrival was something of a surprise to me."
						
						"Then you must learn to be more careful."
				#"Do you think the Vampire of Cincinnati will come here?"
					*set convo_time -1
					*set independence %+3
					*set aichinger_rapport %+3
					Aichinger's mustache twitches. "I have no doubt, ${mr_german} ${surname}. But that is not the real question!"
					
					"Oh? What is the real question?"
					
					"Who is behind this Vampire of Cincinnati? Don't you think it @{speaks_german convenient|[i]praktisch[/i]} that he should appear so soon after the publication of that Stoker filth?"
					
					"You're saying that you think another of our kind is manipulating the Vampire of Cincinnati? To what end?"
					
					*if aichinger_rapport > 55
						"That is what we must discover! Though we might think ourselves masters of our fates, I have long since learned that we are all pawns within some great game. And someone like this? Clearly the lowliest of pawns. But that does not mean that we cannot observe the pawn's moves in an attempt to divine the shape of the board."
						
						"That is…quite the tortured metaphor, [i]Herr[/i] Aichinger."
						
						*if speaks_german = false
							"[i]Ja?[/i]  Is [i]die Schachfigure[/i] not called a pawn?"
							
							"No, I think you're right." 
						*if tribune_explained
							You pause to collect your thoughts. "So, you expect the new Tribune to hunt down this individual, should he show his face?"
							
							"@{speaks_german Absolutely!|[i]Absolut![/i]}. Why else would such a person be appointed?"
							
							"To hunt West?"
							
							Aichinger gives a dark chuckle. "No one vampire will defeat West, my young friend."
							*comment TODO patronizing German expression for "my young friend"
						
							You ponder that statement for a moment.
						*else
						
							"But you understand my meaning?" he replies.
							
							"I do," you reply.
					*else
						"If only I knew the answer to that question, my young friend."
						
						You sense that Aichinger does not trust you enough to expound further on the matter.
				#"Are you worried about mortals hunting us?"
					*set convo_time -1
					"No. No one here is stupid like Quarrington."
					
					*if heard_of_quarrington
						"Quarrington was stupid?"
						
						"He was."
						
						"How so?"
					*else
						*set heard_of_quarrington true
						"Quarrington?"
						
						"Yes, the Quaestor of Cumberland, Maryland. A vain, foolish beast of a vampire."
						
						"Mortals slew him?"
						
						"They did. During the so-called Great Uprising of '77."
						
						"How was he stupid?"
					
					*if speaks_german
						"He sought to control the passage of goods and people across the Appalachians. It was foolish to attempt to control—rather than influence—such a thing. Anyone who attempts to assert control in that way risks provoking the ire of men. Look at Jay Gould and what he achieved in St. Louis with the Terminal Association!" he chuckles. "To put oneself in such a position is remunerative, yes, but also dangerous. And Quarrington was not sufficiently prepared."
					*else
						"He was trying to…[i]den Fluss zu steuern[/i] of things across [i]die Appalachen[/i]. It was foolish to seek to [i]steuern[/i] instead of [i]beeinflussen[/i], you see. No one responds well to being steered; we all want to do this ourselves! Just look at Jay Gould and his intrigue with the Termainal Association!" he chuckles. "You make money, yes, but draw attention to yourself as well. And Quarrington drew too much attention to himself."
			*goto aichinger_questions
		*if (spoke_b_and_p = false) #Bailey.
			*label bailey_and_partridge
			*set just_spoke 2
			*temp convo_time 3
			You approach Senators Bailey and Partridge. Partridge extends his hand for you to kiss@{met_partridge , an affectation you do not recall from your prior encounters with him|}.
			*temp interject false
			*if met_partridge = false
				
				"Oh, forgive me, ${given_name}! Please allow me to introduce you to Samson Partridge, the Senator of Louisville."
				
				*if (lore > 2) 
					"And the scion of @{(revolutionary_credentials > 50) Consul|Isaiah} Stone, if I am not mistaken?"
					
					Partridge nods his head.
				"A pleasure." His eyes narrow a moment. "Weren't you, until recently, a citizen of Memphis?"
				
				"I was."
				
				"I was there several time in the '70s, for the senatorial election. How is it that I never met you there?"
				
				*choice
					#"I felt as though the intrigues of court were beyond my capabilities."
						*if status = 0
							*set interject true
							*set partridge_rapport %+15
							Partridge sniffs. "Yes, that was a wise decision. Almost…admirable."
							
							His companion coughs.
						*elseif status = 1
							"I see. An understandable decision, I suppose. But, really, you should have shown your face. Such an opportunity to meet other members of the Society!"
							
							"And to spend time flattering him," Bailey ribs.
							
							"Oh, shush, you," Partridge rejoins.
							
							You clear your throat to remind the two of them of your presence.
							
						*else
							*set partridge_rapport %-10
							*set interject true
							Partridge recoils at your self-abnegation. "I cannot believe that, ${mr} ${surname}; your reputation proceeds you."
							
							"Be that as it may…"
							
							His companion coughs.
					#"I apologize, Senator. I was preoccupied."
						*if (status > 0) and (independence > 45)
								*set partridge_rapport %+10
								"Well, I suppose you must have had your reasons. I hope your objectives were completed."
								
								"You could say that," you reply.
						*else
							*set partridge_rapport %-10
							*set interject true
							"I don't know what else you could have been preoccupied with.…"
							
							His companion coughs.
					#"There was a herd of angry goats. They might have been possessed by a demon, in fact. But they…"
						*if (charm > 2) or (independence > 55)
							*set partridge_rapport %+5	
							*set bailey_rapport %+5
							Partridge and Bailey's eyes all go wide.
							
							"But they periodically chased me around Memphis, crying for me to feed them my blood, while seeking to impale my feet on their horns!"
							
							"How awful!" Partridge says.
							
							"Terrifying!"
							
							You continue your tall tale for several more minutes, until it has reached its natural conclusion.
							
						*else
							*set partridge_rapport %-10
							*set bailey_rapport %-10
							"Come now, ${mr} ${surname}, now is not the time for jests," Bailey interrupts you.
							
							"Forgive me, Senator."
							
							He waves away your apology.	
			"Tell us, what can we do for you?" Bailey @{interject interjects|says}.
			*set met_partridge true
			*temp who_tribune false
			*label partridge_and_bailey_qs
			*set spoke_b_and_p true
			*if convo_time = 0
				*label end_bailey_and_partridge
			
				"Well, thank you for your time, Senators," you reply. @{knows_partridges_secret They both smile benevolently at you.|They are both clearly relieved by your departure.|Partridge seems relieved by your departure.|Partridge seems ot be pretending that you don't exist.|Partridge seems relieved by your departure.}
				
				You withdraw and consider your next move.
				*goto court_convo_picker
			*choice
				*if (tribune_explained = false) #"What is a tribune?"
					*set tribune_explained true
					*set independence %+5
					*set discretion %+3
					*set bailey_rapport %-3
					*set partridge_rapport %-3
					*set convo_time -1
					They look at each other. "A tribune runs around so the quaestor doesn't have to…" Bailey begins.

					"…and makes sure all the good little vampires are observing the Three Rules," Partridge continues.

					"Because when a lot of vampires spend time in one place together…" Bailey rejoins.

					"…the Rules can end up broken."

					"I see. So their job is to…corral the errant." @{met_lynch This is a task that you have had some experience with before—Cecil Lynch being the first instance.|}

					"Exactly," Partridge exclaims.
				*if (tribune_explained and not_tribune) #"I wish to be Tribune."
					*set announced_intention true
					*set who_tribune true
					*set convo_time -1
					"Why would you want that musty old title?" Partridge inquires.
					
					"Skulking around in the muck, dirtying your hands with the unclean…you're liable to catch something," Bailey continues.
					
					@{bloodsweats "I've already survived worse," you observe.|"I'm not worried," you reply.}
					
					*if bailey_rapport > 60
						*set baileys_favor true
						*set tribune_favor_points +1
						"Well, if you wish for our support, you have it."
						
						"Yes, absolutely," Partridge chimes in.
					*elseif bailey_rapport > 50
						*set tribune_favor_points +0.5
						"We won't stand in your way, dear ${given_name}."
						
						"No, we wouldn't object," Partridge enjoins.
					*else
						"We find it strange…" Bailey begins.
						
						"…that you would come to us for support," Partridge finishes. "Did you expect us to give it?"
						
						"Besides, Bécard is suited to the task."
						
						"@{(discretion > 55) Apparently not. |}Thank you for being candid with me," you reply.
						
						They nod @{(discretion > 55) perfunctorily|graciously}. "Best to get such things out in the open. We wouldn't want a misunderstanding about such a thing," Bailey says.
				*if (knows_becard_candidate = false) #"Who @{who_tribune else might|is likely to} be named Tribune?"
					*set convo_time -1
					*set knows_becard_candidate true
					"Mlle. Bécard, of course."
					
					"She is standing for the position?"
					
					Partridge gives a little laugh while Bailey answers you: 
					*if who_tribune
						"I don't know why either of you would want it."
					*else
						"I do not think anyone else would endure it."
					
					"Is it as bad as all that?"
					
					"I certainly wouldn't want the job," Partridge answers.
					
					"I see," you reply.
					
					"Is there anything else?" Bailey poses.
				*if (convo_time = 1) #I @{(knows_partridges_secret = 2) want nothing more to do with these two|have nothing more to ask}.
					*goto end_bailey_and_partridge
				#@{(discretion > 50) "I haven't heard any ideas from you about how to bring down West."|"Do you have any thoughts on how we can bring down West?"}
					*set convo_time -1
					"I'm not convinced that this is a problem that needs addressing."
					
					"What?"
					
					"Are you sure that he's coming here? Have you seen him?"
					
					"No…"
					
					"Have you seen any evidence of these murders? Any bodies of vampires?"
					
					"Most vampires don't leave corpses…"
					
					"So what are you so concerned about?"
					
					"A Beast hunting us down, one-by-one, and drinking our heartsblood."
					
					"Unsubstantiated rumors."
					
					"You were the one who told @{(eliot_rapport > 60) Hiram|Eliot} and me that this is what West was doing!"
					
					"You must be misremembering, ${mr} ${surname}. And if you wish for this conversation to remain civil, I suggest you change the subject."
					
					You stare at him, unsure how to proceed.
				*if (knows_hardings_plan = false) #I make small talk until Partridge seems suitably distracted, at which point I ask Bailey why no one was chosen to be the Senator of Memphis.
					*set convo_time -1
					*set independence %+10
					*if (bailey_rapport > 65) and (revolutionary_credentials > 65)
						*set knows_hardings_plan true
						Bailey looks over his shoulder at Partridge, who has found other companions. "Quaestor Harding was blackmailing Samson."
						*if heard_of_harding = false
						
							"Quaestor Harding? Who is that?"
							
							Bailey cranes his head at you. "Harding is the quaestor of Louisville, where Samson is the senator. She and Carothers are broodmates."
								
							You frown. "And she was blackmailing Partridge…to not vote?"
						*else
							"Blackmailing him? To not vote?"
						
						"Yes."
						
						*if intelligence > 2
							*if heard_of_harding = false
								"Does she support Stone?"
								
								"No, not at all."
								
								You think on that a moment. Whatever her exact motives, you conclude that 
							*else
								You know that Harding is a Loyalist, which means that whatever her exact motives,
							it was more important to her that Memphis not have a senator at all than it was for it to have a Loyalist one.
						*else
							*if heard_of_harding
								"But she's a Loyalist, isn't she? Why
							*else
								"Wait…does he support Stone? Or does she side with Adonis?"
								
								"She thinks Stone was misguided."
								
								"If she's a Loyalist, then why
							didn't she just have him support Pickering?"
							
							"Apparently it was more important to her that Memphis not have a senator at all."
							
						You peer at the back of Samson Partridge's head. What could Harding be holding over him? And what is so important to Harding that she would trade a seat on the senate for…spite? Against her broodmate Carothers, no less?
						*set heard_of_harding true
					*else
						*set bailey_rapport %+10
						Bailey throws a glance towards the back of Partridge's head. "I suppose it was because the Senate could not agree on a suitable candidate."
						
						"Aren't these things decided in advance, with the event itself being simply theater?"
						
						"Not always, ${mr} ${surname}."
						
						"I suppose I'm surprised to hear that."
						
						"If I have learned anything in my time, ${mr} ${surname}, it's that politics is a messy business."
						
						"So it would seem," you say with a smile.
				*if ((notice_partridge_betrayal) and (knows_partridges_secret = 1)) #"Why did you betray Stone's cause during the caucus in Memphis, Senator Partridge?"
					*set convo_time -1
					*set discretion %+10
					*set independence %-10
					*set carothers_rapport %+5
					*set applethorp_rapport %+5
					*set bailey_rapport %-10
					*set partridge_rapport %-10
					*set revolutionary_credentials %+10
					*set aichinger_rapport %+5
					Partridge and Bailey both look as though they've been slapped.
					
					"How dare you!" @{(bailey_rapport >= partridge_rapport) Bailey|Partridge} snaps.
					
					You continue before you can be silenced. "It's a fair question. You were supporting the Revolutionary cause until they were positioned to win. And then you abandoned it, leading to a stalemate. Surely this did not happen by accident."
					
					*if status = 0
						"${mr} ${surname}, you are no longer welcome here. Please leave," Bailey says.
						
						Bécard appears at your side, a grimace on her face. "Please, ${given_name}, let's go."
						
						She escorts you from premises of the hotel.
						*goto first_night
					*elseif status = 1
						"${mr} ${surname}, it is not your place to question a senator," Bailey intones.
						
						"Are you saying you don't have the same question, Senator Bailey? Or are you blinded to his perfidy by your affection for him?"
						*set tribune_favor_points -1
						
						Bailey stands. His eyes are flashing.
						
						Suddenly, Bécard is standing between the two of you. "Enough. The fair hasn't even opened yet, and you're already misbehaving?"
						
						"I'm not the one—" Bailey begins.
						
						"Why won't he answer the question?" you demand.
						
						"${given_name}, come with me."
						
						Bécard pushes you out of the hall. She sits with you while you pace back and forth in frustration. "Why can't they ever just answer a question?"
						
						"I learned long ago not to ask questions. Not of the sort you care about, anyway." You growl in frustration. "If you're finished, shall we return? I don't want to miss the rest of the evening."
						*set favor_time 2
						*goto court_convo_picker
					*else
						"${mr} ${surname}, now is not the time nor the place to have this discussion," Bailey replies.
						
						"Then when and where is that time and place? It's been a quarter of a century already!"
						
						"If you would lower your voice…" Bailey says, trying to shush you.
						
						"Is there a problem, Senator?" Gudhrun inquires from across the room.
						
						"No, no problem, Governor," Bailey replies.
						
						"Actually…" you begin.
						
						Partridge steps forward, breaking the line of sight between you and the governor. "I did not do it willingly, ${mr} ${surname}. I'm sorry, but there's nothing that can be done about it now."
						
						Did Senator Partridge just apologize to you? And he admitted to being blackmailed? By Harding, presumably.
						*achieve partridge_confession
						*set knows_partridges_secret 2
				*if ((knows_partridges_secret > 1) and (compassion < 40)) #"Have you apologized to Carothers?" you ask, when Bailey is suitably distracted.
					*set compassion %-10
					*set independence %+5
					*set carothers_humanity -1
					*set carothers_rapport %+25
					*set applethorp_rapport %+20
					"No, but if that's what it will take to…"
					
					"Yes, please."
					
					"Very well," he says with a nod.
				*if (knows_partridges_secret = 3) #When the opportunity presents itself, I try to ask Partridge about his cult.
					*set convo_time -1
					*set knows_partridges_secret 4
					*set discretion %+5
					*set independence %-5
					When Bailey has been suitably distracted, you turn to Partridge. "Your disciples…"
					
					"This again?"
					
					"How do you do it? More importantly, why do you do it?"
					
					*if stlouis_cult
						*set knows_partridges_secret 5
						He looks at you carefully. "Why do you do it?" You @{(discretion > 50) sputter a brief denial|go still}. "No, I've heard of your indiscretions as well, ${stlouis_cult_address}," he says with a disdainful smile. "I wasn't certain, but once you confronted me about it, the truth was plain as day."
						
						"And what of it?"
						
						*if partridge_rapport > 65
							He looks at Bailey's back a moment, then returns his gaze to you. "If I were you, I would be rid of it. And quickly. It will bring you nothing but misery." He pauses another moment.
							
							What compromises has the scion of Stone made to retain his position and his stature in the Society? Who has he had to betray and who will he betray next?
							
							Now that he knows your secret, will it be you?
							
							*choice
								#"Perhaps I will."
									*set partridge_rapport %+5
									*set independence %+5
									*set discretion %-10
									"See that you do," Partridge says with solemnity.
								#"But…a god should not abandon ${his} disciples. What kind of god would ${he} be?"
									*set partridge_rapport %-10
									*set discretion %+20
									"Even gods can be brought low by their own hubris."
									
									"Some would say that is what makes them divine."
									
									"This is not some Greek tragedy, ${mr} ${surname}."
									
									"Well, we won't know unless we see it to the end, now will we?" you retort.
								#"I will simply learn from your mistakes."
									*set discretion %+10
									He gives you a disappointed smile. "See that you do."
							
							At this point, Bailey returns from his conversation with Bécard. 
						*else
							"You know, I believe I've recently learned a term for this."
							
							"Oh?"
							
							"A Mexican standoff."
							
							@{literate "Oh, I've read that too!"|You look at him, perplexed.}
							
							"Yes…a situation in which neither party has a route to victory."
							
							@{literate "Perhaps."|You nod.} He knows your secret now, just as you know his.
							
							Before your conversation can get any more dangerous, Bailey returns from his converation with Bécard.
					*else
						He looks at you, considering his options.

						His decision made,		
						*if partridge_rapport > 65
							he sighs. "At this what choice do I have? I might as well continue to benefit from it; I have suffered and will suffer for it indefinitely."
							
							@{(compassion < 40) "I am sorry to add to your burdens."|"Perhaps you should have been more circumspect."}
							
							@{(compassion < 40) "That is kind of you to say,"|"Epimetheus was ridiculed for a reason, ${mr} ${surname},"} he replies.
							
							"What now?"
							
							"As before. You should keep this matter to yourself. You never know when having a friend like me will be of use to you."
							
							You nod—an acceptance of sorts—just as Bailey returns from his conversation with Bécard.
						*else
							he squares his shoulders. "I owe you no explanation. Unless you want his whole charade to come tumbling down, I suggest you keep your observations to yourself. When you are ready to make your needs known, @{partridge_contactable you know how to reach me."|you can reach me here," he says, offering you a calling card.}
							*set partridge_contactable true
							
							"And until then?"
							
							"Do not think I wish to become chummy with my blackmailer."
							
							You nod—an acceptance of sorts—just as Bailey returns from his conversation with Bécard.
			*goto partridge_and_bailey_qs
		*if ((becard_explained = false) or (favor_time > 0)) #Bécard.
			*temp convo_time 3
			*set just_spoke 3
			*set becard_rapport %+5
			*label becard_convo_picker
			*if (favor_time = 1) and becard_explained
				*set knows_becard_candidate true
				Bécard rolls her eyes when you corner her. "What?" she exclaims, exasperated.
				
				"I wanted to ask you something…" you begin.
				
				"I'm trying to make sure the Quaestor choose me to be Tribune. Are you questions more important than that?"
				
				*choice
					#Yes.
						*set becard_rapport %-5
						*set discretion %+5
						"Go on, then," she prompts.
					#No.
						*set becard_rapport %+5
						*set favor_time -1
						"I appreciate that. We'll talk later," she says, before continuing her rounds.
						
						*goto court_convo_picker
			*elseif (favor_time = 2) and (convo_time = 0)
				Bécard eyes the rest of the room. "I think Memeskia's ready to announce his decision."
				
				"So it seems," you reply.
				*goto out_of_favor
			*elseif convo_time = 0
				Bécard eyes the rest of the room. "Well, if you'll excuse me, I have my own matters to attend to."
				
				"Of course," you reply.
				
				She excuses herself and leaves you to your own devices.
				*goto court_convo_picker
			*choice
				#"Are you worried about mortal hunters pursuing us?"
					*set convo_time -1
					*set discretion %-5
					Bécard considers a moment. "You mean, after the destruction of Quarrington and Daniels?"
					
					*if heard_of_quarrington and heard_of_vdaniels
						"Yes," you reply.
					*elseif heard_of_quarrington
						*set heard_of_vdaniels true
						"Daniels?"
						
						"Vernon Daniels, the Quaestor of Cleveland and scion of Governor Townsend."
						
						"He was destroyed?"
						
						"Yes, @{(sod_founder = "duplessis") during the Great Uprising, much like Quarrington|in 1882}."
						
						"Suspicious."
					*elseif heard_of_vdaniels
						*set heard_of_quarrington true
						"Quarrington?"
						
						"Giles Quarrington, the Quaestor of Cumberland, Maryland."
						
						@{((intelligence > 2) or (finance > 1)) You know that Cumberland is the site of a pass through the Applachian mountains; it's a critical juncture of highways, railroads, and canals, linking the Eastern seaboard with Ohio and points west.|You wrack your brain, but you've never heard of this town.} "When was he killed?"
						
						"In 1877, during the Great Uprising. I'm surprised you hadn't heard."
						
						"I had not."
					*else
						*set heard_of_quarrington true
						*set heard_of_vdaniels true
						*set becard_rapport %-5
						"Quarrington? Daniels?"
						
						Bécard looks at you with surprise. "Quaestors Giles Quarrington of Cumberland and Vernon Daniels of Cleveland?"
						
						You look at her blankly.
						
						"Quarrington was slain during the Great Uprising in 1877. Daniels was destroyed 
						*if sod_founder = "duplessis"
							just a few days later.
						*else
							in 1882.
						I'm surprised you hadn't heard."
						
						"As am I."
					
					"To answer your question then, yes, I am concerned. Troubled, even.
					*if exposure > 15
						For you, specifically. You have drawn a lot of attention to yourself, ${mr} ${surname}."
					*elseif exposure > 9
						For you, in fact. You have drawn some attention to yourself, ${mr} ${surname}."
					*else
						We cannot remain hidden forever."
					
					"And there is no chance for peace with the mortals?"
					
					She shoots you a look. "Do you think they would ever make peace with their cattle?"
					
					"No, I suppose not."
				*if ((tribune_explained) and (knows_becard_candidate = false)) #"Do you intend to seek the position of Tribune?"
					*set convo_time -1
					"I do."
					
					"Why?"
					
					"As the scion of Memeskia, I feel it is my duty."
					
					"Has he instructed you so?"
					
					"No…" she trails off.
					
					"And yet you would throw yourself in the path of danger? For what? For him?" you say, indicating Memeskia. "Or him?" you say, indicating Bailey.
					
					"Not for him," she says, her fangs poking out over her lips as she glares at Bailey across the room.
					
					"Memeskia then?"
					
					She clenches her jaw. You suspect that she wants you to change the subject.			
				*if (tribune_explained = false) #"What is a Tribune?"
					*set tribune_explained true
					*set convo_time -1
					*set independence %+5
					"A vampire appointed with the responsibility of bringing errant vampires to heel," she replies.

					"I see. Thank you," you reply.
				#"Why do you reside in Jefferson City?"
					*set convo_time -1
					*set becard_rapport %+5
					"The better to not have to answer questions like these?" she says.
					
					*if independence < 50
						"I see. I am not much of one for the Society either."
						
						"You could have fooled me," she replies.
					*else
						"Do you reject all overtures thusly?"
						
						Bécard sighs. "I apologize. The social pressures of the Society are simply too much to bear sometimes."
						
					"And yet you are here for many of our evenings?" you say@{(independence < 50) , ignoring her challenge|}.
					
					"My dominus has his limitations. And while he may appear to be indifferent to both the Society and the mortal world, he is not, in fact. From Jefferson I am able to exert some amount of influence over the state government on his behalf."
					
					"Have you not been released?"
					
					"I was released decades ago."
					
					"And yet you serve him still?"
					
					*if ethnicity = "choctaw"
						"There are very few of our kind in the world. I do not have to serve him, but I cannot help but think that my existence would be much harder outside of the shadow he casts."
						
						"He does cast a very long shadow."
						
						"My growth may be stifled by that shadow, yes, but I have accepted that trade."
						
						"I wonder what I would do in your place."
						
						After a moment: "What would you do?"
						*choice
							#"Maybe for a different dominus, but not for Memeskia."
								*set independence %+5
								*set memeskia_rapport %-5
								"Such is your choice," she replies. "Not that your wishes matter in this."
								
								"No, they do not."
							#"A home and companionship among our kind? It is a beautiful thought. I am envious."
								*set becard_rapport %+5
								*set independence %+5
								"Let me not overstate the matter…"
								
								"You do not need to backtrack. I understand that it is complicated. But I do find the idea appealing."
								
								"If only…"
								
								"If only," you conclude.
							#"No, I wish to stand on mine own."
								*set independence %-5
								*set becard_rapport %-5
								*set discretion %+5
								"You know why trees grow in forests?"
								
								"Yes, yes, so that they may break the wind for their neighbors. And the tree that stands along grows crooked. I know the stories."
								
								"And yet you do not heed them."
								
								"I am not a tree."
								
								She shakes her head, disappointed in you.
					*elseif ethnicity = "african"
						"There are few of our kind in the world. Even fewer than yours. I hope you understand the desire to be able to share a space of mutual understanding."
						
						"I do."
						
						"Then you have your answer."						
					*else
						"Have you ever found yourself entirely alone in the world? Without friends or connections? Without even the possiblity of sympathy from anyone that you meet? Let me answer that question for you: no, you have not. Believe me when I tell you that when you are beset on all sides, even the smallest shred of mutual understanding—of shared history—can be a lifeline that is only spurned by the foolish."
						
						"And that is why you serve him? Because of mutual understanding?"
						
						She sighs and shakes her head. "Yes, if that is what you understood me to have said."
				*if (becard_explained = false) #"Do you think the Vampire of Cincinnati will come here?"
					*set convo_time -1
					*set independence %+3
					"Where else would he go? He's been making his way west. And how could he resist such an event?" she replies.
					
					"Who would be so irresponsible that they would allow themselves to be identified in the papers like this?"
					
					"I don't know, but both he and his dominus should be staked and put out for the sun. Did you know that they are threatening to close the parks after sunset in Indiana as a result of this?"
					
					"No!"
					
					"The court of Indianapolis must be beside itself."
					
					"I can imagine!"
				*if (becardeliot_romance) #"It seems you and Eliot have been spending some time together."
					*set convo_time -1
					*set becard_rapport %-5
					*set discretion %+3
					Bécard stares at you. @{(willpower < 3) You quaver under that gaze.|} @{(perception > 0) She is visibly suppressing the urge to gut you where you stand.|}

					"Perhaps…"

					"The private affairs of Mr. Eliot and I are none of your concern, ${mr} ${surname}."

					"I was simply—"

					"Enough."

					A sore subject? Or simply a matter of privacy? @{(perception > 1) You suspect the latter.|}
				*if (convo_time < 2) #"Do you believe in the Christian God? @{(ethnicity = "choctaw") Or do you follow the old ways?|Or perhaps some Native deity?}"
					*set convo_time -1
					Bécard glances around the room, placing each of the other vampires in some mental map of the space.
					
					Her eyes finally return to you. "No, I do not."
					
					@{(rationalism > 50) "I'm sorry to hear that."|"I'm glad to hear it."}
					
					"I cannot imagine that any merciful being would allow those such as us to exist."
					
					"If we do not come from the divine, where then do we come from?"
					
					*if becard_rapport > 55
						*set becard_aliens 2
						"The sky."
						
						"The sky?"
						
						"Yes."
						
						"What are you even talking about?" you reply, exasperated.
						
						Bécard eyes the rest of the room. This next part she says louder than before: "Well, if you'll excuse me, I have my own matters to attend to."
					
						"What…" you begin, watching in confusion as she abandons you.
						*goto court_convo_picker
					*else
						"I don't know."
						
						"Do you have any thoughts on the matter?" you ask, probing.
						
						"No, I'm afraid I don't. I learned a long time ago that there is no value in asking questions that have no answers."
						
						"But what if there is an answer?" you demand.
						
						"Then it is unknown to me, and I see no route to discovering it."
			*goto becard_convo_picker
		*selectable_if (status > 1) #Björnsdotter.
			*set just_spoke 4
			*gosub bjornsdotter_convo
			*goto court_convo_picker
		#Eliot.
			*set just_spoke 5
			*set eliot_rapport %+5
			*temp convo_time 3
			*temp next_tommy_q false
			*label eliot_convo_picker
			*if convo_time = 0
				
				At this moment, Gudhrun passes @{(bjornsdotter_rapport > 60) by|through the middle of} your converstion, and the two of you are forced apart.
				*goto court_convo_picker
			*if (convo_time = 1) and (heard_ragtime = false)
				*set eliot_rapport %-10
				
				"Tell me something, ${given_name}."
				
				"Yes?"
				
				"Have you been to the Rosebud? The Silver Dollar Saloon? Or any of the supper clubs in Chestnut Valley? The music is inescapable."
				
				"I'm sorry to say that I have not."
				
				"You should broaden your horizons, ${given_name}. This world is wide. While you are consuming its blood, you should also consume what else it has to offer."
				
				"I'll take that under advisement," you reply. You suspect that you have the opportunity to ask him one more question.
			*choice
				#"Are you afraid of West?"
					*set convo_time -1
					"Of course I am."
					
					"Why?"
					
					"Because I don't want to die. More to the point—" he shudders, "—I do not want him to drink my soul. I don't believe in hell, but spending eternity in the breast of that monster sounds like the closest thing imaginable."
										
					"Come now, you don't think it's really that bad?"
					
					"I do. The act is heinous and punishments meted are just."
					
					"You would kill every vampire who has consumed the heartsblood of another?"
					
					"Without question." 
					
					@{(vampires_consumed > 0) Apparently, any desire to confess your sins to Hiram should be quashed.|You take note of that—for future reference.} "I see."
				#"Are you worried about the publication of [i]Dracula?[/i]"
					*set convo_time -1
					*set eliot_rapport %+5
					"I am. Very worried."
					
					"You think that it exposes us?"
					
					"Very much so. I have to agree with Bailey that we should burn the copies of the magazines and shutter the publisher."
					
					*if justice < 35
						*set eliot_rapport %+5
						"You don't think you're overreacting? That perhaps a response such as you describe will only exacerbate the situation?"
						
						"What else can we do? This is our very existence at stake!"
						
						"Overreaction often produces the opposite result, Hiram."
						
						His shoulders slump. "I hate the idea that there's nothing to be done."
						
						"There are things to do, but repression is one of them," you reply.
					*else
						"You think that would work?"
						
						"I do."
						
						You nod. Repression is the way power instinctually responds to threats, after all.
				#"Do you think it strange that the Vampire of Cincinnati would come here, much as @{(sire_name = "West") my dominus|West} has?"
					*set convo_time -1
					*set independence %+3
					"It is hard for me to not see the confluence of events and not seek to find a pattern, yes."
					
					"And what is the pattern that you see?"
					
					"Honestly? That St. Louis is a shining beacon, attracting vampires to it like moths to a flame."
					
					"You need no other explanation?"
					
					"No. Anything else would be to invent a God to explain."
					
					"And what of…other vampires?"
					
					"Let us not imagine other vampires to be gods, ${given_name}," Hiram says. "Such things only end with misery."
					
					*if stlouis_cult
						"Must they? I see innumerable advantages to us being considered gods."
						
						Eliot cocks his head in your direction. "Such things are forbidden in the Society, and with good reason."
						
						"Such as?"
						
						"It always ends badly, ${given_name}."
						
						"I see," though, really, you don't.
				*selectable_if ((compassion < 60) and (shepherd_credentials > 40)) #"How is your family?"
					*set next_tommy_q true
					*set convo_time -1
					*set compassion %-5
					*set eliot_rapport %+5
					Eliot's face brightens at your question. "You should see little Tommy! He's so smart. A regular wordsmith!"
					
					"What has he been writing?"
					
					"Poems, mostly."
					
					*if memorial_poem_memphis
						"The words of poets have a way of capturing the spirit of a moment in amber."
						
						"Yes, frozen in time, as though still living."
						
						"I'm happy for you."
						
						"Truly, I live through him," Eliot affirms.
					
					"And what is he reading?"
					
					"Right now? The [i]Rubaiyat of Omar Khayyam[/i]."
					
					"I am unfamiliar."
					
					"It's a marvelous collection of poetry, where the astronomer muses on the transitory nature of existence. He struggles with questions of divinity and eternal life, caught between the observable universe of the stars and the mysticism of the Sufis."
					
					*if rationalism > 70
						"And you are not worried about his being led into heresies?"
						
						Eliot laughs. "I would be more concerned about me leading him into heresies, ${given_name}."
					*else
						"Is he old enough to contemplate such mysteries?"
						
						"I think we all ask these questions, regardless of our age. Reading these books simply gives him the vocabulary to better ask the questions. And whom am I to stand in the way of that?"
				*if (next_tommy_q) 
					*selectable_if (compassion < 75) #"What will you do when Tommy grows up, and you are still ageless?"
						*set next_tommy_q false
						*set convo_time -1
						*set eliot_rapport %+5
						A pained look crosses his face.
						
						"I will adjust his memories. Make him forget knowing me in his youth, so the thoughts will not conflict with our present acquaintance."
						
						"But…destroying his memories like that…"
						
						"He will not remember our conversations? The chess games late into the night? No."
						
						"That seems cruel. To both of you."
						
						"This existence is cruel, ${given_name}."
					*if (histoire_recit and ((discretion > 40) and (compassion > 40))) #"When do you plan on replacing him?"
						*set next_tommy_q false
						*set eliot_rapport %-30
						*set compassion %+5
						*set discretion %+5
						*if becardeliot_romance
							*set becard_rapport %-10
						"Replace him! ${given_name}! What kind of monster do you think I am?"
						
						"A monster like I am, Hiram. Like we all are."
						
						Eliot's eyes glint in the reflection of the gaslamps. "No one of our kind will ever touch Tommy," he vows. "Now, if you will excuse me," he concludes, turning and stalking away from you.
						*goto court_convo_picker
				*if (becardeliot_romance) #"It seems you and Bécard are still enjoying one another."
					*set convo_time -1
					*set eliot_rapport %+5
					"If you can believe it. I don't know if I thought I would feel like this again."

					"Like what?"

					"I don't know. Calm? Still? Intimate?"

					"Those do not sound like the words to describe a vampire."

					"I know!"

					"How long can it possibly last?"

					"Our very existence defies both nature and science. How can I evaluate a future when the present is already impossible?"

					"Surely you can, you simply don't want to. You evaluate the future in every other aspect of your existence, despite the irrationality of our existence."

					"I can't say that you're wrong, ${given_name}."
				*if (tribune_explained = false) #"What is a tribune?"
					*set tribune_explained true
					*set convo_time -1
					*set independence %+5
					He rolls his eyes at you. "Why do you even want to know?"

					You glare at him. "Are you going to tell me or not?"

					"It's the Tribune's job to keep an eye out for vampires who have not presented themselves before the quaestor. And adjudicate their…situation."

					"I see," you reply.
				*if (tribune_explained and not_tribune) #"I wish to be Tribune."
					*set convo_time -1
					*set announced_intention true
					*if told_by_eliot
						"I knew it."
						
						"Yes, yes, you were right."
						
						He sighs.
						*if becardeliot_romance
							*set eliot_rapport %+10
							*set tribune_favor_points +2
							"Fine. I will do what I can to help you, ${given_name}."
							
							"Thank you, Hiram."
						*elseif (eliot_rapport > 60)
							*set tribune_favor_points +1
							"I will do what I can to help you, ${given_name}."
							
							"Thank you, Hiram."
						*else
							"I can't say that you're the best vampire for the task."
							
							You purse your lips. "I'm sorry you feel that way."
					*elseif stl_west_volunteer
						"Of course you do," he replies.
						
						"Was it so obvious?"
						
						"Being tribune and hunting down your dominus are not the same thing, but the connection is clear."
						
						"Does that mean you will support me?"
						
						Hiram sighs.
						*if becardeliot_romance
							*set eliot_rapport %+10
							*set tribune_favor_points +2
							"Yes, I will do everything I can to support you."
						*elseif eliot_rapport > 60
							*set tribune_favor_points +1
							"Yes, I will support you."
						*else
							"I can't say that you're the best vampire for the task."
							
							You purse your lips. "I'm sorry you feel that way."
					*else
						"You do?"
	
						*if becardeliot_romance
							*set eliot_rapport %+10
							*set tribune_favor_points +2
							"Don't act so surprised."
	
							"I will do everything in my power to help you, ${given_name}."
						*elseif (eliot_rapport > 60)
							*set tribune_favor_points +1
							"Don't act so surprised."
							
						*elseif m_sib
							*set eliot_rapport %+10
							"Yes. Does it really surprise you so?"
	
							"I suppose not. He is your maker. It's your responsibility."
	
							"So everyone keeps telling me."
	
							"I wish you luck in your endeavor."
	
							"Thank you?" you reply. Does that mean he will support you? Whatever the case, his mien implies that the subject is concluded.
						*else
							"Oh?"
	
							"Yes. Would you be willing to put in a good word for me?"
	
							"I really think Bécard would be better equipped for this, ${given_name}."
	
							"I see."
			*goto eliot_convo_picker
		#Memeskia.
			*set just_spoke 6
			*temp convo_time 0
			*temp quaes_quest false
			*label memeskia_convo_picker
			*if convo_time >= 3
			
				Several more moments pass without comment from either of you. Memeskia seems more than comfortable to sit in silence, as though you were of no more importance to him than a flea.
				
				Eventually, you excuse yourself.
				*goto court_convo_picker
			*choice
				*if (tribune_explained and not_tribune) #I wish to be Tribune.
					*set announced_intention true
					*set convo_time +1
					*if speaks_english
						You start to make your petition, but the words die in your throat. He already knows what you are going to ask; he has already made his decision whether or not to tilt the scales in your favor. No need to bother with saying anything further on the matter.
						
						*if memeskia_rapport > 60
							*set tribune_favor_points +1
						*if status > 2
							*set tribune_favor_points +1
					*else
						"You cannot speak the tongue of this city. Whether or not you are qualified, I cannot choose you."
						
						"But…"
						
						"No."
						
						You purse your lips in frustration.
				*if quaes_quest
					#"Do you still want to be Quaestor?"
						*set memeskia_rapport %+10
						*set convo_time +1
						*set discretion %+5
						*if (status < 2) and ((discretion < 60) and (independence > 40))
							Memeskia looks at you quizzically. It is both improper and surprising for you to ask this question. But perhaps that does not matter so much to this ancient.
						"No."
						
						"Then why do you still do it?"
						
						He takes a moment before he answers. "Do what, exactly?"
						
						You've never heard Memeskia refer to himself as Quaestor. He accepts the deference of the other vampires, yes, but he barely interests himself in the goings-on of the court. He demands submission, but other than that…he is not like any other quaestor you have met or heard of.						
					#"Have you ever met Consul Stone?"
						*set independence %+5
						*set stone_in_stl 2
						"Yes."
						
						You wait, hoping he will expand on that statement. When he doesn't, you try and prompt him. "Did you meet him when he was Senator of Baltimore? At some election or other?"
						
						"No."
						
						Memeskia is looking about the room. Trying to hide your impatience, you do your best to be polite. "Then how did you meet him?"
						
						"He came here. With Lewis and Clark. You would call that 1803."
						
						"Stone came to St. Louis in 1803?"
						
						"He did."
						
						"Did he stay long?"
						
						"Several months."
						
						"Why did he come?"
						
						"I believe he was fleeing Baltimore."
						
						"Fleeing Baltimore?"
						
						"Yes."
						
						"But…he stayed here for a few months, and then went back?"
						
						"Yes."
						
						"Did he explain his change of thought? It seems like quite a change for him to flee here and then go right back."
						
						"No, but neither did I ask."
						
						You clench your teeth in frustration. You are unsure what else to ask of him.
				#"Why did you not petition Consul Stone to become Governor yourself?"
					*set convo_time +1
					*set bjornsdotter_rapport %-5
					*set independence %+5
					*set quaes_quest true
					Memeskia looks exhausted by your question. "What would I gain by becoming Governor? Would I be able to stop the colonists from tearing down the mounds? Would I be able to freely kill those who cross the sea to these shores? Would I be able to turn back time to before their arrival? What good would it do to me?"
					
					*if (independence > 50) and (ethnicity != "choctaw")
						"But…you're ancient. You are entitled to the position. You know this land better than anyone…"
						
						Memeskia shakes his head. "You make it sound like I rule the land. No, the land simply exists, as I do."
					*elseif (ethnicity = "choctaw")
						"I hear you. There is no going back."
						
						Memeskia shakes his head sadly.
					*else
						"What if you could turn back time to before you were turned?"
						
						Memeskia scowls. "There is no point in dwelling on such thoughts."
				#"Why is West so focused on St. Louis? Is it because of you?@{(sire_name != "West")  It certainly isn't because of me.|}"
					*set convo_time +1
					Memeskia scowls at you. "No, it's not because of me."
					
					You look at him.
					
					"But that doesn't mean you don't know why he's here. There are vampires all over the world that he could feed from, but he is spiraling around this city."
					
					"There was a battle fought here during what you call the Revolution."
					
					*if intelligence > 2
						"The battle of Fort San Carlos? Where the Spanish defended themselves against the British?"
						
						"If by British you mean a company of Sioux, Chippewa, Menominee, Winnebago, Sac, and Fox warriors."
					*else
						"Battle? Between whom?"
						
						"Sioux, Chippewa, Menominee, Winnebago, Sac, and Fox warriors against the Spanish fort that was here."
						
						"There was a Spanish fort here?"
						
						He does not dignify that with a reponse.
					
					"So…what happened?"
					
					"It was the last time I sought to fight the settlers outright."
					
					"You were behind the attack?"
					
					*if investigate_memeskia > 3
						*set west_exposure +1
						*set tryphon_identity +1
						*comment TODO this doesn't make sense
						"Yes, but there was another here."
						
						"Another vampire? Do you mean West?"
						
						"No. Older. I don't even know his name. But I believe he came from Sante-Domingue." @{met_maffi Haiti? The ancient came from Haiti?|}
						
						"What happened?"
						
						"We fought from dusk until dawn. When it was over, we both sank into the earth to recuperate. To my knowledge, he never emerged again.
						
						"There's an ancient vampire sleeping under the city? That's what West is after…to drink the heartsblood of an ancient."
						
						He seems unmoved by the danger that this poses to your kind.
						
						"Where did this fight occur?"
						
						"On the land @{((ethnicity = "choctaw") or (ethnicity = "african")) the|you} settlers call Forest Park."
						
						Otherwise known as the site of the Louisiana Purchase Exposition.
					*else
						"Yes."
						
						You wait for him to elaborate, but he does not.						
				*if (met_lefferts) #"Has Edwin Lefferts presented himself before you?"
					*set convo_time +1
					*set memeskia_rapport %+5
					"Lefferts?"
					
					"Yes, he came visiting about ten years ago in the company of his boon companion, Jay Gould. The two of them stayed at the Southern Hotel, presumably under the aegis of Senator Bailey."
					
					"No."
					
					You stop. "Does that mean…he does not have your permission to feed here?"
					
					"He does not."
					
					"I see," you reply.
				#"Will the Tribune be tasked with confronting the Vampire of Cincinnati, should he show his face here?"
					*set convo_time +1
					*set independence %+3
					*set memeskia_rapport %-5
					Memeskia looks at you. You realize after several moments that he will not deign to answer your question.
			*goto memeskia_convo_picker
		*if (spoke_b_and_p = false) #@{met_partridge Partridge|The individual with whom Senator Bailey is entertwined}.
			*goto bailey_and_partridge
*label out_of_favor

The clock chimes three. @{(just_spoke = 6) Memeskia takes his place in the center of the gathering.|Memeskia has reappeared, standing stoically amid the other vampires as though preparing for his own execution.} The room grows silent.

"I have reached a decision. The Tribune will be
*if (tribune_favor_points > 2) and speaks_english
	*set stlouis_tribune true
	${given_name} ${surname}. $!{he}
*else
	Sabine Bécard. She
will be tasked with keeping order in the city during the fair. Let it be known that it is forbidden to kill a mortal on the fairgrounds during this time." You don't think you've ever heard Memeskia speak so many words at a stretch.

It seems he has a few left: "Tribune, a few words?"
*if stlouis_tribune
	You follow Memeskia into another room.
	
	"Do you understand the duties associated with your new position?"
	
	*if tribune_explained = false
		"No, Quaestor."
		
		You are certain that, were Memeskia mortal, he would be sighing right now.
		
		"It will be your duty to accost any vampires you don't recognize and extract promises that they will observe the Rule of Respect. You are released from the Rule of Reserve while performing these duties. You are to help me keep order during this time."
		
		"I think I understand."
	*if tribune_explained
		"Yes, Quaestor."
		
	"Good. Then go forth with my blessing. If you need to reach me in haste, you may leave word with Chula. You can find her at the horse-trader on Waterman."
	
	"Thank you, Quaestor."
	*goto first_night
*else
	You watch as Bécard follows Memeskia into another room.
	
	The intrigue for the evening complete, the gathered vampires begin to disperse. You call for ${stlouis_valet} and make your own way home.
	*goto first_night

*label first_night
*page_break

Just after one in the afternoon, President Roosevelt presses a golden key in Washington, DC, and through the magic of electricity, the fountains of the Fair begin to bubble and cascade and the lights burst into illumination. A massive brass band, led by John Philips Sousa, erupts into patriotic song. The overwhelming attendance far exceeds the expectations of the organizers, and they have to scramble to restock foods and goods earlier than they were anticipating. America has come to St. Louis, and she intends to enjoy her time here.

Once the sun has set, you buy your packet of tickets and pass through the turnstile with throngs of other people. The fair is almost unimaginable in scope, covering 1272 acres, or almost two square miles. It is estimated that a thorough accounting of the exhibits will take no less than a month—and that does not account for the limited-run events, such as the Olympics or the first-ever aeroplane race.

Through the machinations of Bailey and Aichinger, the fair will stay open later than originally intended—going as late as two in the morning along the restaurants and carnival exhibits of the Pike. This will also give the vampires an easier time of it. Even so, you will be frequently pressed for time on the evenings that you visit.
*finish Next

*label bjornsdotter_convo
*hide_reuse
*if month > 4
	*temp bjornsdotters_favor false
	*temp tribune_favor_points 0
*set stl_bjornsdotter_convo true
*temp convo_time 0
*comment accessible from fair_opening or random encounters at the fair itself.
*if month = 4
	"Hello, ${mr} ${surname}."
				
	"Welcome back to St. Louis."
	
	"Thank you.
	*if m_sib
		Your broodmate does you proud. If only @{heard_of_buljan my broodmate|your dominus} were so…compliant."
		
		"No one would ever call West compliant, Governor. Nor—from what I understand—would anyone want him to be compliant. Was he not the best Beast-hunter there was?"
		
		"Until he became the greatest threat to our kind in centuries."
		
		You purse your lips. It is unclear how you should respond to that.
	*else
		It is a pleasure to be back. I hope that the fair is something that everyone can enjoy."
		
		"As do I, Governor."
	
		There is an awkward pause in the conversation.
*if month > 4
	*temp bjornsdotters_favor false
	*temp tribune_favor_points 0
	The Swedish pavilion is a magnificent structure dominating one section of the park. There is a Norwegian one next door, but it is intentionally smaller and less impressive, as Norway has been in a political union under Sweden for ninety years. Similarly, the Danish pavilion is nearby, but the Danes were simply unable or unwilling to field as impressive of a pavilion as Sweden. Lastly, Finland has a pavilion as well, but it has been designed and financed by the Swedes. Finland was lost to the Russian Empire in 1809, but Sweden, ever eying its former dependency, has paid for the Finns to come and assert themselves before the world.
	
	*if (status >= 2) or (independence > 65)
		*set bjornsdotter_rapport %+5
		"I'm sorry we did not get to speak at the last gathering," you begin.
		
		"There is no need to apologize, ${mr} ${surname}. There are many concerns that occupy us both, I am certain."
		
		You nod agreeably.
"What did you wish to discuss?" she finally inquires.
*label bjornsdotter_picker
*if convo_time = 1

	You consider what else you might like to ask the Governor.
*if convo_time = 2
	
	You sense that Gudhrun's interest in this conversation is waning.
*if convo_time >= 3

	@{(independence > 55) With the proper gestures of respect, you|You} back away carefully@{(month = 4) , considering your next move.|. You do not wish to rile the Governor.}
	*return
*choice
	*if (month = 4)
		*if (tribune_explained and not_tribune) #"I wish to be Tribune."
			*set convo_time +1
			*if bjornsdotter_rapport > 55
				*set bjornsdotters_favor true
				*set tribune_favor_points +2
				"I think that's a fine idea. I'll suggest as much to the Quaestor."
				
				"I'm flattered, Governor."
				
				She simply nods in response.
				
				"Thank you," you say by means of farewell.
			*else
				"Do you believe you are the most qualified?"
				
				"Yes…"
				
				"I do not."
				
				"I see. Thank you for your candor, Governor."
	*if (month <= 6)	
		*if (sire_alive or (sire_name != "Padre Carlos"))
			*if ((heard_of_carlos) and (stl_praetor_carlos = 1)) #"Can you summon Praetor Carlos to help defend us?"
				*set convo_time +1
				*if status >= 2
					"Do you feel that Quaestor Memeskia is incapable of handling this threat himself?" The danger of your request hangs between you.
					
					*choice
						#"No, no…I am sure Quaestor Memeskia will be able to handle West himself."
							*set independence %+5
							"I am sure that you are right. But still…"
							
							"Still what?"
							
							"Forgive me, Governor."
							
							She nods. The matter is hopefully forgotten.
						#"Clearly. Otherwise, I would not be asking."
							*set stl_praetor_carlos 3
							*set discretion %+5
							*if status = 2
								*set memeskia_rapport %-25
								*set bailey_rapport %-10
							*else
								*set memeskia_rapport %-10
								*set bailey_rapport %-5
							Björnsdotter nods. "Very well."
				*else
					*set bjornsdotter_rapport %-25
					*set memeskia_rapport %-15
					"${mr} ${surname}, do you know what I do when I hear mice squeaking?"
					
					Glancing around, you spy no axes handy.
					
					"Yes?"
					
					"Do not be a mouse, then."
					
					"Yes, Governor."
	*if (month > 4) #"Sweden has put on quite the show with these pavilions," you say, gesturing to your environs.
		*set convo_time +1
		*set bjornsdotter_rapport %+5
		"So they have. It will only be a matter of time before these nations set aside their differences and rejoin."
		
		"Rejoin?"
		
		"Yes. During my youth, all these nations were united under one king."
		
		"And you would see those days return?"
		
		"I would. The Finns will not tolerate their subjection to the Russians for much longer. But more importantly, the peoples of these four countries have too much in common with each other to not join together."
		
		"Under a king?"
		
		She sighs. "The time of kings is passed. No…it will be some other form of governance. But mark my words, they have more to gain through unity than division."
		
		*if (perception > 1) and (intelligence > 1)
			From your vantage, you compare the Swedish and Norwegian pavilions.
			*if discretion > 50
				"Unity under Sweden?"
				
				"How do you mean?"
				
				"Look at the Norwegian pavilion, Governor. At a glance, we can see who rules. Do you think the Norwegians are grateful for being subordinated in this way? As you just said, the Finns will not long tolerate their subjection to the Russians."
				
				"I agree with you, in fact. All four nations would need to be equal partners for the government to have legitimacy."
			*else
				To your eye, any such union would be led by the Swedes—and considering the way Norway has been treated, you suspect that not everyone would be happy about that.
	*if (gould_plot = 4) #"Do you think it was wise to give Jay Gould the gift of immortality?"
		*set convo_time +1
		*set gould_plot 4
		Björnsdotter's mien darkens. "No, I do not."
		
		"Will there be…consequences?"
		
		"Gould has not entered my province. But I do consider his very existence to be a threat to the Rule of Reserve."
		
		"I see."
	#I attempt to flatter Björnsdotter; it may pay dividends later.
		*set convo_time +1
		*if independence > 65
			*set bjornsdotter_rapport %+15
			It is, you admit to yourself, challenging to curry favor with someone who is several centuries old. However, you have spent enough time observing the flow of conversation in court to have some sense of how to do it. Your words are carefully placed to shine favorably upon the new Governor, without being too obsequious. Of course, the key part of a successful sally is knowing when to retreat.
		*elseif independence > 40
			It is, you admit to yourself, challenging to curry favor with someone who is several centuries old. After several attempts to ingratiate yourself, you conclude that you have not spent quite enough time attending to the flow of court gossip to succeed, but you also do not think you have harmed your position.
		*else
			*set bjornsdotter_rapport %-5
			Unfortunately, your streak of independence is not well-suited to idle flattery. Your attempts at statements of support come across as crass bootlicking. 
			
			Aware that your efforts are misplaced, you find a way to bring your observations to a close. At her nod of dismissal, you back away carefully and consider your next move.
			*return
	#"Did you ever meet West?"
		*set convo_time +1
		*achieve history_of_west
		*set heard_of_buljan true
		*set history_of_west true
		"No. He was created centuries ago. When he was still quite young, he traveled with the Vikings to Vinland and stayed, even when they left and returned home.
		
		"He was out-of-contact with the Society for centuries, until the colonization of North America."
		
		"How could he have such a reputation as a Beast-hunter when he was out of contact with the Society for such a long period?"
		
		"When the Americas were discovered, a number of individuals who chafed at the rule of Adonis fled here in an attempt to build a new world for themselves."
		
		"What does that have to do with West?"
		
		"West dealt with those scofflaws."
		
		*if (ethnicity = "african")
			"So…West was the slave patrol?"
			
			"Slave patrol?"
			
			"Yes. The States had patrols that would capture runaway slaves and return them to their masters. When and where slavery was legal."
			
			Björnsdotter looks at you, slightly puzzled. "West just killed the ones who fled."
		
		"And that was the source of his reputation?"
		
		"Well, no. He was actually turned into a vampire in order to help his maker, Buljan, bring down a great Beast. He happened to survive that process. It is said that he even struck the killing blow."
		
		"And so we have come full circle."
		
		"Yes, I suppose we have."
		
		You consider a moment. "How do you know so much of West? Is this the sort of thing that our kind discuss in the courts of Europe?"
		
		"No. I know of West because we are broodmates. Buljan was my maker as well."
		*if m_sib
			
			That makes Gudhrun…your aunt?
		
		You consider your next words carefully.
	*if ((m_sib and patricide) and history_of_west) #I wonder if Björnsdotter has any idea who might be impersonating West.
		*set convo_time +1
		"Would Buljan ever come to the Americas?"
		
		"I very much doubt it."
		
		"Did he have any other scions?"
		
		"I'm sure of it. It is rumored that one of them was responsible for the destruction of the Roanoke colony."
		
		*if (discretion > 60) and (independence < 50)
			*set bjornsdotter_rapport %-5
			"But you've never met any other scions?"
			
			"How could? I only arrived to the Americas quite recently, if you recall."
			
			"Yes, of course, Governor." You pause.
		"Did you ever hear of West having…lovers? Close friends?"
		
		"No, I cannot say that I did. I never heard of West having much use for others of our kind. Those he made, like you, being the rare exception to that. I suspect that's what drove him mad."
		
		A dead end? You pause to consider.
	*if ((m_sib and (patricide = false)) and history_of_west) #"Do you have any thoughts about how to draw West out?"
		*set convo_time +1
		"It is hard to say. Part of the problem is, are we certain that he has lost control of his faculties? Or is some other game at play?"
		
		"If he has truly lost his faculties, then only blood will out. He seeks the heartsblood of our kind. He will come for it."
		
		"If he seeks the heartsblood of our kind, then the Exposition seems like a dangerous time."
		
		"It does indeed."
		
		"And if he has some other purpose?"
		
		"Then you would have to discern that other purpose. But attempting to discern the purpose of a being who is a thousand years older than you seems like folly."
		
		*if discretion > 40
			"Truly? I would think the motivations for our kind are few: hunger, shelter, and vengeance."
			
			Is that a whisper of a smile you see on the Governor's lips? "Vengeance, yes. But against whom? For what reason? That is what would be so hard to determine."
		
		"Yes, of course."
	#"Are you concerned about the publication of [i]Dracula?[/i]"
		*set convo_time +1
		*set independence %+5
		*set heard_of_marcius true
		Gudhrun pulls herself to her full height. "The Rule of Reserve has existed for millennia. Some say the Siege of Tyre was over violations of the Rule of Reserve; others say it is even older."
		
		"Stories have a way of spreading themselves and mutating. Some say Odin Allfather and his maimed son are inspirations for @{(religious_tradition = "pagan") our |}God and his son Jesus. The mortals have told stories about us around their campfires. Someone putting such a story to paper and distributing it was inevitable."
		
		"You make it sound unavoidable."
		
		"It was. Your Senator Bailey may blame the court of Martial, but I cannot."
		
		"Martial, the Governor of London?"
		
		"Yes, and the scion of Adonis."
	
		"Do you think he has trouble adapting to modern nights? Could this failure be a result of his age?"
		
		"I have not doubt that it is. But as I said, it was inevitable. I imagine I will make a similar mistake some night in the future."
		*comment TODO have Gudhrun make a mistake w/r/t internet technology		
*goto bjornsdotter_picker