*comment ñáéç…—
*set year 1890
*hide_reuse
*advertisement

*if has_saw_manuscript > 14
	The @{(has_saw_manuscript = 10) student who is reproducing|professor who is translating} Bowater's text alerts you to the fact that he has finished the project.

	He arrives a few nights later, looking over his shoulder as he crosses your threshold.

	"Do you know what this is?" he asks, incredulously.

	"No?" you reply. "Why don't you tell me?"

	He drops the Bowater's text and a package—presumably the @{(has_saw_manuscript = 10) transcription|translation}—on your kitchen table.

	"There's…it's…I…think there's been some sort of misunderstanding," he finishes, looking at you with widening eyes.

	"Oh, what sort of misunderstanding?"

	He turns, only to find ${stlouis_valet} between him and the door. He looks back at you. "Please don't kill me," he grovels.
	*gosub_scene prestation checkHasDebt

	*choice
		*if (debt_from_bailey) #I trade the debt that Bailey owes me to have him adjust the @{(has_saw_manuscript = 10) student|professor}'s memories of the project.
			*set debt_from_bailey false
			*set independence %+5
			Bailey was happy to make this exchange when you offered it to him last night. 

			There is a knock at the door. ${stlouis_valet} opens it, announcing the arrival of Senator Bailey.

			The @{(has_saw_manuscript = 10) student|professor} leaves your home about two hours later, the memory of the past few years hazy, indistinct, and entirely lacking any reference to vampires.
		*if ((debt_from_bailey = false) and (debt_to_bailey = false)) #I offer Bailey a debt to adjust the @{(has_saw_manuscript = 10) student|professor}'s memories of the project.
			*set debt_to_bailey true
			*set independence %+5
			Bailey was happy to make this exchange when you offered it to him last night. 

			There is a knock at the door. ${stlouis_valet} opens it, announcing the arrival of Senator Bailey.

			The @{(has_saw_manuscript = 10) student|professor} leaves your home about two hours later, the memory of the past few years hazy, indistinct, and entirely lacking any reference to vampires.
		*if (false) #I offer Bailey a debt that I hold over someone else.
		#I kill the @{(has_saw_manuscript = 10) student|professor}.
			*label kill_scrivener
			*set stlouis_valet_loyalty %-10
			*set compassion %+5
			*if perception > 0
				Out of the corner of your eye, you notice ${stlouis_valet} grimacing as you descend upon the hapless man.
			*else
				You leap forward and sink your teeth into the neck of the hapless man.
			He's dead before he hits the ground.
		*selectable_if (wealth > 250000) #I try to convince him that I am simply a collector of esoteric manuscripts.
			*if charm > 3
				*set wealth -25000
				*set exposure +2
				*set stlouis_valet_loyalty %+5
				Exerting your supernatural charm on the man, you extract a promise that he will not disclose this transaction to anyone in exchange for a small sum—on top of the salary you have already paid him these past few years. A severance, if you will.

				You do not believe for a moment that the @{(has_saw_manuscript = 10) student|professor} will keep his word indefinitely, but between your powers and the money in his pocket, you hope that he will see reason.
			*elseif charm = 3
				*set exposure +3
				*set wealth -50000
				*set stlouis_valet_loyalty %-5
				You make a strongc case as to why it would be in the @{(has_saw_manuscript = 10) student|professor}'s best interest to never mention this to another soul. He pleads for his life, promising that he will never tell anyone anything.

				After almost an hour, you finally let him go. There is no way he will truly keep silent, but you hope that time will soften the repercussions.
			*else
				He doesn't believe you for a moment. You sigh in disappointment; you had hoped such a talented individual would survive the transaction.
				*goto kill_scrivener
	*set has_saw_manuscript -10

	You now have a copy of [i]Of Shepherds and Wolves[/i] in @{(has_saw_manuscript = 5) legible Latin|English}.
	*if speaks_latin or (has_saw_manuscript = 6)
		
		*if read_saw_manuscript = false
			*gosub_scene util read_saw
	*else
		Of course, you still can't read the text. But no matter.

	You have it bound, so that it more closely resembles a book, and deposit it in your library.
	*page_break

The winter of 1889 gives rise to a new phenomenon in the history of humankind: a global pandemic.

The first deaths to the Russian Flu are recorded in St. Petersburg, Russia, in late November. By late February, 1890, people are dying in St. Louis. Due to the advent of new forms of travel and the relentless motion of steam-powered ships, the virus circles the globe in a matter of months.

This particular evening, Bailey is beside himself with worry over the matter. There is a hospital near the Southern Hotel that is overflowing with patients. He fears that the medical infrastructure of St. Louis is not equipped to handle the number of severe cases. Currently, he is seeking to cajole Aichinger into helping the city.

"Lothar, please. Dutchtown has two hospitals that have been almost untouched by the infection. Won't they take in some of these patients?"

"[i]Ach wo![/i]" Aichinger replies. "If they are not equipped to take care of themselves, then they should suffer the consequences! The hospitals of Dutchtown have provisioned for just this outcome, but they are not prepared to moderate the failures of others!"

The two bicker for a time, with Eliot also urging Aichinger to use his influence for their benefit.

"Just think what will happen if this disease spreads further!"

"That is what I was thinking," he retorts.
*temp asked_m false

*label after_m
*choice
	#I urge Aichinger to relent and let the Germans help with the care of the ill.
		*if revolutionary_credentials > 45
			*set aichinger_rapport %-20
		*set anti_german_sentiment %-10
		*set compassion %-5
		Faced with united opposition, Aichinger finally relents.
		
		By May, the pandemic subsides; despite its relative brevity, over a million people are dead across the globe. Yet, thanks to the coöperation between the different medical facilities of St. Louis—across ethnic and linguistic lines—the matter did not get out of hand here.
	#@{asked_m I urge Bailey to heed Memeskia's words.|I argue that the best way to deal with this is to kill the ill and burn the bodies.}
		*set atrocities +1
		*set shepherd_credentials %-15
		*set eliot_rapport %-20
		*set memeskia_rapport %+15
		Eliot is horrified at your suggestion and states that he wants no part of it.
		*if asked_m
			The others, however, bend to Memeskia's directive.
		*else
			*set compassion %+25
			*set discretion %-5
			Memeskia, on the other hand, looks almost pleased at your suggestion. You point out that eliminating the source of the disease is one of the best ways to prevent its further transmission. Eventually, Bailey sees the logic in your words.
		No one wants to feed from a sick human. Or, worse, have to scramble to feed at all.
		*label clear_hospital
			
		The medical staff is cleared from the hospital one evening by an "accident" of the head administrator. The wooden building is set aflame, taking some three hundred souls with it.
		
		The newspapers treat the matter as a fortuitous tragedy: terrible for the victims and their families, but perhaps the dead were called to a higher purpose, saving the city from further misery? These questions offer little comfort to the families of the deceased, many of whom would have recovered given time and care.
	*if (compassion < 65) #Aichinger is right to keep @{(ethnicity = "german") our|his} people safe.
		*set compassion %+5
		*set eliot_rapport %-5
		*label aichinger_stands_firm
		*set anti_german_sentiment %+10
		The matter ends in a draw@{asked_m  despite Memeskia's declaration|}. Dutchtown resolves to take care of itself…and it does. The rest of the city pulls through—the disease begins to naturally peak and subside approximately six weeks after its arrival in a community—with about seven thousand dead.
		
		The Germans' refusal to share their resources provokes hostility and anger in the Anglophone community, a resentment that will surely fester for years afterwards.
	*if (choice_randomtest = false) #I let them sort this out themselves.
		*set independence %-15
		*if asked_m
			The gathered vampires are loathe to ignore the wishes of their quaestor. Eliot looks like he might be sick. When no one else volunteers, Bailey shoulders the responsibility to execute the directive.
			*goto clear_hospital
		*else
			*goto aichinger_stands_firm
	#"Quaestor, do you have an opinion on this?" I ask Memeskia.
		*set independence %+10
		*if memeskia_rapport > 55
			*set asked_m true
			*set investigate_memeskia +1
			
			"Is it settlers in these hospitals?" he asks.
			
			"As opposed to whom, Quaestor?"
			
			"Slaves. Former slaves. Chickasaw. Kickapoo. Illini. Osage. Missouria. Otoe. Ioway. Quapaw."
			
			"No, Quaestor, this is a white hospital."
			
			"Then burn it to the ground."
			
			The room goes silent. @{(shepherd_credentials <= 50) From the perspective of a Wolf, Memeskia speaks wisely: why endanger the herd when you can excise the cancer. What's more, it would free up the physicians and nurses to focus on those who are newly infected, as opposed to tending to those who are most in need of resources.|You're not sure that you realized that Memeskia was a Wolf, but with a statement like that, it is hard to conclude otherwise.} "But…they would all die," @{(compassion < 50) you reply|Eliot replies}.
			
			"And?"
			
			"And…that would be…cruel. They need our help."
			
			"You asked my opinion. Burn it to the ground."
			
			He stands and departs @{schnaiders_closed the Eurydice|Schnaider's}. He has made his will known.	
		*else
			"No," he replies.
			
			You wait a moment to see if he has anything else to add. He does not.
		*goto after_m

*if (stlouis_enterprise = 3) or (stlouis_enterprise = 7)
	*page_break
	*set anachronism %+3
	@{(compassion < 50) Interestingly|Frustratingly}, this pandemic forces you to confront the fact that time is well and truly advancing around you. Throughout your entire life and unlife, the term "man of science" has been the catch-all term for chemists, mathmaticians, physicists, and the like. However, while discussing the pandemic with 
	*if stlouis_enterprise = 3
		some local intellectuals,
	*elseif religious_tradition = "catholic"
		some professors from St. Louis University,
	*else
		some professors from Washington University,
	you can't help but notice that they are on the verge of laugher. When you finally confront them, one speaks up and observes that no one has called this type a "man of science" in years; the term is now "scientist."
	
	@{(discretion > 55) You suppress the urge to tear the face off the man who informs you of this with such disdain. Regardless, you|You} take note of the change to the lexicon.

*page_break
*if temperance_movement or ((shepherd_credentials > 75) or ((male = false) and (compassion < 40)))
	*if wctu = "NWSA"
		*set wctu "NAWSA"	
	In May, the National Women's Suffrage Association merges with its rival organization, the American Woman Suffrage Association, creating the National American Woman Suffrage Association. Under the leadership of Susan B. Anthony, the organization dedicates itself to fighting for white women's suffrage in state legislatures.
	
	In July, Wyoming is officially admitted to the Union. It is the first state to grant women's suffrage, as the right to vote is enshrined in the State constitution. NAWSA is understandably jubliant.
*if ((perception = 3) and (stl_electricity > 4)) or ((perception >= 3) and (stl_electricity <= 4))
	*page_break
	There's no denying it. You have long resisted the idea that the coal furnaces were having any effect on the blood, but now it is undeniable. Except for on the rarest of occasions, the bitter aftertaste of coal ash sits with you for hours when you sup on the blood that sustains you.
	
Bowing to pressures from the farmers and miners of the West, the Congress passes the Silver Purchase Act, which goes into effect on July 14th. By the terms of this bill, the US Treasury will buy four and a half million ounces of silver per month on the open market and mint them into silver dollars. The objective of this plan was to inflate the prices of crops by increasing the number of dollars in circulation—thereby easing payments of the farmers' debts—and to support the mining industry, whose profits had declined with the discovery of significant prospects in and around Denver, Colorado.

*if (finance > 0) or ((technology > 1) or (intelligence > 3))
	The problem with this is that the value of the dollar and the value of the silver in the dollar are not the same, and the Treasury does not have the authority to modify the weight of the coins based on the value of the metal. The arbitrage between these two values is ripe for exploitation.

*if (baseball_failed = false) and (stl_vda_drama or (finance > 0))
	*page_break
	Chris Von der Ahe suffers his biggest set-back yet this summer. He had purchased the land around Sportsman's Park and built houses around it. Unfortunately, due to the fluctuations of currency, real estate prices have receded notably.
	
	To date, the Northwestern Savings Bank of St. Louis has freely loaned Von der Ahe without securing collateral. With his real estate ventures in peril, the bank has demanded the assignment of collateral should his empire collapse.
	
	In response, Von der Ahe files suit against the bank for breach of its fiduciary duty—as a shareholder himself, he alleges that it was a breach of trust for the bank to lend him money without having secured collateral from him.
	*if (stlouis_enterprise = 1)
	
		You've discussed Von der Ahe with several editors of city newspapers. With his overblown persona and his ridiculous accent, he is a perfect prop for selling papers. Moreover, there's not a little bit of jealousy on their part—how has this upstart immigrant grocer become one of the richest men in St. Louis? They spill their ink, seeking to mock him, but they only drive his popularity to new heights.
		
		They seem to think, most importantly, that their worldview is shared by everyone—and anyone who doesn't share this worldview clearly doesn't matter. Only, Von der Ahe now owns hundreds of rental units across the city, @{(sporting_goods > 1) a chain of sporting goods emporiums,|} an entertainment park known as the Coney Island of the West, and one of the most successful baseball teams in the country—and they're still trying to make fun of his manner of speech.
	
	*choice
		*if ((sporting_goods = 2) or (sporting_goods = 3))
			*selectable_if (wealth > 2000000) #I offer to pay off the debt of $20,000, if Von der Ahe promises to be more careful going forward.
				*set wealth -480000
				*set stl_vda_debt true
				Von der Ahe gruffly thanks you for the debt. The two of you have made some good money together, and he does not want to jeopardize that relationship.
				
				Not yet, anyway.				
		*if ((false) and (sporting_goods = 4)) #If you had ever wanted to buy a baseball team, this may be your chance.
			TODO
		*if (sporting_goods = 4) #I urge the bank to drop the demands; if Von der Ahe loses, ${spalding_sporting_goods} could be in trouble.
			*set laborvscapital %-5
			Von der Ahe and the bank both put down their proverbial weapons and return to the [i]status quo ante[/i]—which means Von der Ahe is going further into debt every month. He begins selling off his better players in an attempt to raise capital to keep the machine running.
		#I feel as though I have something to learn from this man's audacity!
			*set discretion %+5
			Amazingly, Von der Ahe succeeds in forcing the bank to withdraw its demands. Soon, things are back to normal—though Von der Ahe is going further into debt every month. He begins selling off his better players in an attempt to raise capital to keep the machine running.
		*if ((finance > 1) or (local_fame > 50)) #I urge the bank to stand firm. @{sporting_goods |I will use this opportunity to become a full partner in ${spalding_sporting_goods}.|I will use this opportunity to buy Von der Ahe out of ${spalding_sporting_goods}.|${spalding_sporting_goods} can absorb the losses.}
			*set local_fame %+5
			The bank presses its demands.
			*if (sporting_goods = 1) or (sporting_goods = 4)
				*set baseball_failed true
				*set stlouis_business_climate %-5
				Eventually, Von der Ahe is forced to admit defeat. He sells the franchise—which is relocated to Cincinnati—and Sportsman's Park is auctioned off to the highest bidder.
				
				Von der Ahe returns to the Golden Lion to live the rest of his days in the reflection of his framed newspaper articles.
			*if (sporting_goods = 4)
			
				*set income -15
				Of course, ${spalding_sporting_goods} takes a hit from the affair. Von der Ahe's meteoric rise was good for business—and his fall is equally bad.
			*if (sporting_goods = 2) or (sporting_goods = 3)
				*set laborvscapital %-5
				You approach Von der Ahe with your offer to pay off some of his debts in exchange for @{(sporting_goods = 2) an equal share|complete ownership} of ${spalding_sporting_goods}.
				
				He reluctantly agrees to your terms.
				*if sporting_goods = 2
					*set wealth -100000
					*set income +15
				*elseif sporting_goods = 3
					*set wealth -200000
					*set income +15
					Of course, ${spalding_sporting_goods} takes a hit from the affair. Von der Ahe's meteoric rise was good for business—and his fall is equally bad.
				@{(sporting_goods = 2) Thanks to|But with} your infusion of capital, he lives to fight another day. He and the bank come to an understanding, and business resumes much as before.
				*set sporting_goods +1
		*if (stlouis_enterprise = 1)
			*if (sporting_goods = 1) #This man is a danger to the city; I make sure the newspapers depict him as such.
				*set baseball_failed true
				The bank presses its demands. Eventually, Von der Ahe is forced to admit defeat. He sells the franchise—which is relocated to Cincinnati—and Sportsman's Park is auctioned off to the highest bidder.
					
				Von der Ahe returns to the Golden Lion to live the rest of his days in the reflection of his framed newspaper articles.
			#He just needs a little time; I try to turn popular sentiment in his favor.
				*set stlouis_business_climate %+5
				The newspapers argue on behalf of Von der Ahe, and secure him an acquittal in the court of popular opinion.
				
				Eventually, the bank relents and business resumes as before—only, now, Von der Ahe is going further into debt every month.
		*if (temperance_movement) #A few protests outside Sportsman's Park could ruin the venue—and further the cause of prohibition!
			*set missouri_prohibition +1
			*set stlouis_business_climate %-5
			*set baseball_failed true
			The temperance workers organize prayer-ins outside of Sportsman's Park, obstructing the entrances and further deterring attendance. Pressured from all sides, Von der Ahe is forced to admit defeat. He sells the baseball franchise—which is relocated to Cincinnati—and Sportsman's Park is auctioned off to the highest bidder.
					
			Von der Ahe returns to the Golden Lion to live the rest of his days in the reflection of his framed newspaper articles.
*if stl_met_slattery = 3
	*page_break
	*set stl_met_slattery 4
	*if (local_fame > 45) and ((background > 3) and (background != 6))
		Judge Cranch reaches out to you and lets you know that Sergeant Slattery is up for a promotion and could use a letter of commendation from an upstanding member of society such as yourself.

		*choice
			#I @{literate write|dictate} a terse letter of recommendation.
				*set justice %+3
				The letter is delivered promptly. You hear a few weeks later that Slattery is now Captain Slattery.
			#I @{literate write|dictate} a flowery letter of recommendation.
				*set justice %+3
				*set discretion %-3
				The letter is delivered promptly. You hear a few weeks later that Slattery is now Captain Slattery.
			#I reply to Judge Cranch that I will not support the career of a monster like Sergeant Slattery.
				*set stl_met_slattery 8
				*set exposure +1
				The judge does not reply. You suspect that he will never forget nor forgive such a betrayal.
	*else
		Judge Cranch reaches out to you to let you know that Sergeant Slattery is in need of an alibi. An official will be visiting your home to take your statement.

		When the official arrives, you consider what to do.
		*choice
			#I refuse him entry. I want nothing to do with defending Slattery's actions.
				*set compassion %-3
				*set shepherd_credentials %-3
				*set stl_met_slattery 8
				You later hear that Slattery got out of his jam anyway. However, you doubt that Judge Cranch will forgive or forget your betrayal.
			#I give a statement that does not alibi Slattery.
				*set discretion %+3
				*set shepherd_credentials %-3
				*set stl_met_slattery 8
				You later hear that Slattery got out of his jam anyway. However, you doubt that Judge Cranch will forgive or forget your betrayal.
			#I relate the alibi as requested.
				*set independence %+3
				*set justice %+3
				Slattery is cleared of the inquiry. A few months later, in fact, he is promoted to captain.

*page_break
The August night is warm. The year is 1890.
*if municipal_debt > 0
	*set wealth +(municipal_debt * 0.0025)
	You have just received your first dividend payment on the Merchant's Bridge investment; it's small, but it's something.

You walk through the city on your way to @{schnaiders_closed Schnaider's brewery. The neighboring [i]biergarten[/i] is up for sale, but the brewery continues producing beer, if somewhat reduced in volume now that their primary outlet is closed.|Schnaider's [i]biergarten[/i].} Memeskia called you together tonight for some purpose or other.
*if (independence < 60) and (anachronism > 60)
	You try not to roll your eyes at his concerns about the changes occurring in the city.
*page_break

The topic at hand is apparently the upcoming construction of the ${wainwright} Building. The word being bandied about in the newspapers is "skyscraper." At ten stories, it will be one of the tallest buildlings in the world, rivaling two other skyscrapers recently constructed in Chicago.
*if slba_subjugated
	The building is named for Adolphus Busch, as the president of Anheuser-Busch Brewing Association, and will be the new center for the Association's business operations.
*else
	*if heard_of_ellis_wainwright
		You surmise that the building is named for Ellis Wainwright, the president of the St. Louis Brewing Association, and will be the new center for the Association's business operations.
	*elseif (shepherd_credentials > 60) and (intelligence > 2)
		*set heard_of_ellis_wainwright true
		The building will be named for Ellis Wainwright, the president of the St. Louis Brewing Association, and will be the new center for the Association's business operations.

"It is a sign of our glorious progress…" Aichinger continues. "Quaestor, I am afraid that I do not see the source of your concern."

"I believe the Quaestor is concerned for the upstanding citizens of the city, Mr. Aichinger. What if there is a fire? What guarantee do we have that the building will not fall over? The whole affair seems presumptuous to me," Bailey retorts.

"But that is what progress is built upon, Senator. One must take risks. One must invest in the future. Even now, as our citizens prepare their proposals to Congress to host the Columbian Exposition, we must consider what it means that Chicago has two of these buildings, and when offered the opportunity to build one, we reject it? No. If we do this, that city will surpass us in influence, both in the mortal world and in the Society. We must not stand in the way of this project." You sense that, were Aichinger still mortal, he would be out of breath at this point. Perhaps even red in the face.
*if (shepherd_credentials > 45) or (stlouis_enterprise = 1)
	
	You have read in the newspapers about this bid for the Columbian Exposition. It will be a World's Fair dedicated to commemorating the 400th anniversary of the discovery of the Americas by Christopher Columbus. Many of the local industrialists are involved with the proposal, hoping to draw attention to the virtues of the St. Louis economy.

Now would be the time for you to speak your mind, were you so inclined.
*choice
	#I too urge Memeskia to allow the project to proceed.
		*set anachronism %+5
		*set discretion %+5
		*if status = 0
			*set discretion %+10
			*set aichinger_rapport %-10
			*set bailey_rapport %-10
		*else
			*set discretion %+5
		"Quaestor, I find myself in agreement with Mr. Aichinger. How are we to draw investment to the city if we reject these technological advances?"
		*goto eliot_asks
	*if (technology < 2) #I express my concerns about the safety of those constructing the building.
		*set anachronism %-5
		*set compassion %-5
		*if status = 0
			*set discretion %+10
			*set aichinger_rapport %-10
			*set bailey_rapport %-10
		*if status > 0
			*set discretion %+5
		"Quaestor," you begin, "I must agree with the Senator. How can we be sure that those who build this edifice know what they are doing? Dozens of people could die if anyone makes a mistake!"
		
		Aichinger huffs. "Dozens of men died building the Eads bridge! Their legs burst open from the inside, and yet the Eads is magnificent, a true testament to the spirit of St. Louis."
		
		*if compassion < 35
			You look at him, incredulous. "And the beauty of the bridge makes all those deaths worthwhile?"
			
			"They accepted the job. They were paid for their labor. If they died, they died fulfilling their contract. What else is there?"
		
		*goto eliot_asks
	*if (technology < 2) #I express my concerns about the safety of those inhabiting the building.
		*set anachronism %-5
		*set compassion %-5
		*set discretion %+5
		*set shepherd_credentials %-10
		*if status = 0
			*set discretion %+10
			*set aichinger_rapport %-10
			*set bailey_rapport %-10
		*if status > 0
			*set discretion %+5
		"Such a building will be a danger to any who sets foot inside. Who knows when it will collapse?"
		
		Eliot coughs. "I must admit, I have seen buildings grander than what is here proposed." All heads turn to look at Hiram. "When I was in Egypt, I saw the pyramids. They were taller than this Wainwright building, and they have stood for thousands of years. Even the Hagia Sophia—"
		
		"Yes, but those were built of marble and stone, not these modern materials…" you interrupt. Before you can continue, though, Memeskia gestures for silence; it seems he has something to say.
	*if status = 0
		#I keep my mouth shut. I know that it is not appropriate for me to speak in these circumstances.
			*set independence %+10
			*label keep_silent
			*set discretion %-5
			*set aichinger_rapport %+5
			*set bailey_rapport %+5
			Both Bailey and Aichinger seem pleased at your decision to keep your opinions to yourself. Or, at least, they don't seem displeased.
			*label eliot_asks
			
			After a moment, Eliot clears his throat. "Quaestor, if I may, I would ask you what it is that concerns you so. Not since the pyramids in Egypt has man built something so tall. I would think that we should be eager to see this thing done."
	*if (status > 0) and (discretion < 65)
		#I keep silent. No need to show my colors at this time.
			*set discretion %-5
			*set bailey_rapport %+5
			*set aichinger_rapport %+5
			Whether Bailey or Aichinger note your silence is unclear; they seem perfectly happy to have their conversation without you.
			*goto eliot_asks
	#I do my best to ask Memeskia about his concerns.
		*if status = 0
			*set discretion %+10
			*set aichinger_rapport %-10
			*set bailey_rapport %-10
		*if status > 0
			*set discretion %+5
		"Quaestor, if I may," you begin, "perhaps you could tell us what your concerns are?"

Memeskia's words are long in coming.

"The last time we sought to reach the sky, our city was destroyed. The place which you call Cahokia, across the river to the east, was once a great city. It was a city where many nations gathered. Together, those nations built mounds that reached to the sky. And where is that city today, I ask you? Abandoned, buried, and forgotten. Its people scattered to the four winds. Its very name forgotten. Forgive me if I do not wish to see the same fate befall this city. There is only so much devastation one man may witness."
*if (ethnicity = "choctaw") and (intelligence > 1)
	
	You look on Memeskia with some awe. As a child, there were tales of the great city to the north, but even your parents thought it a myth. Yet, here before you is an individual who both saw the city at its height and witnessed its downfall.

Aichinger scoffs. "Quaestor, surely you do not believe that the failure of a…" Aichinger pauses here, clearly searching for a word that will not offend Memeskia, "…primitive village in the distant past should impact our decisions now."

Memeskia's eyes narrow, but Eliot interrupts. "I think the quaestor's concerns can be expressed by the story of Icarus, Mr. Aichinger. I think the quaestor feels that the city may fly too close to the sun and that the wax holding our wings together may melt."

"Thank you, Hiram, but I am capable of speaking for myself," Memeskia interjects. "Mr. Aichinger, man is filled with hubris. Not only my people, but yours as well. I have seen that hubris destroy an empire. I do not wish to see history repeat itself."

Looking about the room, you surmise that Bailey and Aichinger are suppressing the urge to burst out laughing. They clearly do not share Memeskia's concerns.

*if (compassion < 40) and ((status > 0) and ((discretion > 35) and (independence > 60)))
	Before things get ugly, you decide to speak. "Perhaps we can all agree, at the very least, to discourage the construction of any more of these skyscrapers until this first one is complete? Would that be amenable to all?
	*set eliot_rapport %+10
	
	You look
*else
	Before things get ugly, Hiram speaks. "Perhaps we can agree, at the very least, to discourage the construction of any more of these skyscrapers until this first one is complete? Would that be amenable to all?"
	
	He looks
around the room; Memeskia, Aichinger, and Bailey seem equally disappointed with this result. Perhaps that is a sign of a well-made compromise.

The meeting adjourned, you each go your separate ways.
*page_break
Over the next few nights, you consider what you want to do about the imminent construction of the ${wainwright} building.

*choice
	*if finance > 0
		#Those who are financing the building are clearly overextended. I try to force them to abandon the project.
			*set discretion %+10
			*set anachronism %-10
			*if finance > 1
				*set stlouis_business_climate %-20
				You manage to arrange for several loans to be called in prematurely, and the financial backing for the project collapses. The site is abandoned.
				*goto wainwright_abandoned
			*else
				Unfortunately, your efforts to provoke the withdrawal of loans meet with naught. The construction of the building continues uninterrupted.
				*goto wainwright_built
	*if (stl_met_slattery = 4) #I partner with Judge Cranch to divert some of the building's funding.
		Cranch is only too happy to cooperate with your scheme, and the two of you set about putting the pieces into place.

		*goto interfere_building
	*if (technology > 0) #I want to investigate these steel innovations. Why must they stop at ten stories?
		*if (intelligence + technology) > 4
			*set exposure +1
			*set local_fame %+20
			After many late nights staring at the plans, you finally devise a way to better distribute weight loads.
			*label wainwright_improved
			*set wainwright_stories "twelve"
			*set stlouis_business_climate %+15
			With plans in hand, you encourage the on-site architect to adopt the engineering improvements. He does.
			
			Construction begins apace.
			*goto wainwright_built
		*else
			Unfortunately, despite many late nights, you are unable to devise any possible improvements to the building's plans or construction techniques.
			*goto wainwright_built
	*if (stlouis_enterprise = 1)
		#I make sure the newspapers cover every facet of the building's construction. I want the whole world to know about the marvels of St. Louis.
			*set stlouis_business_climate %+10
			*goto wainwright_built
	*if (stlouis_enterprise = 2)
		#I just want to make sure I profit from the construction of the building.
			Your connections with the city's criminals turn the project into something of a boondoggle. 
			*label interfere_building
			*set stlouis_business_climate %-20
			*set wainwright_stories "eight"
			*set exposure +1
			*set wealth +5000
			*set local_fame %+10
			*if (streetwise > 2) or (charm > 3)
				*set wealth +5000
			It will end up costing almost twice as much as originally projected, and ends up being two stories shorter than intended.
			*if shepherd_credentials > 40
				The business leaders of the city publicly grumble about the challenges of doing business in the city.
			*goto wainwright_built
	*if (stlouis_enterprise = 3)
		#I gather the technologists of the city to try to improve upon the ${wainwright} designs.
			*set local_fame %+5
			You gather several of the brightest minds of the city to discuss how the ${wainwright} building might be improved. After many late nights, ideas about better ways to distribute loads crystalize.
			*goto wainwright_improved
	#I personally sabotage the construction of the building.
		*set discretion %+15
		*set anachronism %-10
		*set stlouis_business_climate %-30
		*set exposure +2
		*set compassion %+10
		Slipping out at night, you set fire to wood piles, damage equipment, and lay traps for the workers. 
		
		After a few such incidents, guards are posted, but you slip past them with little trouble.
		
		Eventually, the financiers withdraw their support from the project, and the construction site is abandoned.
		*goto wainwright_abandoned
	*selectable_if (shepherd_credentials < 76) #When I am out and about in town, I make a point of observing the building's progress. I'm intrigued by what it means for the city.
		*set anachronism %+10
		*set shepherd_credentials %-10
		*goto wainwright_built
	#I avoid the construction site. These men tinker with forces beyond their understanding.
		*set rationalism %+10
		*set anachronism %-10
		*set discretion %-10
		*if stlouis_haven = "downtown"
			It is difficult to avoid the construction site, since your haven is located not that far away. It means going out of your way when traveling to certain locales. An annoyance, surely, but not an insurmountable one.
			*finish Next
		*elseif ((ethnicity != "german") and (ethnicity != "black")) and ((feeding_style = "drunks") or ((feeding_style = "prostitutes") or (feeding_style = "gamblers")))
			It is difficult to avoid the construction site, since many of your favorite haunts are in the downtown area. It often means going out of your way to approach those establishments from peculiar directions.
			*goto post_wainwright
		*else
			You make it a point to avoid downtown in your perambulations.
			*goto post_wainwright

*label wainwright_built

*if (shepherd_credentials > 40)
	*set anachronism %+10
	You watch with some interest as the building is constructed. By the time it is halfway done, it is already higher than any building you've ever seen.
	*page_break
	The newspapers are filled with praise for the ${wainwright} building and the bright future which awaits St. Louis.
*goto post_wainwright

*label wainwright_abandoned
*set wainwright_built false
*if shepherd_credentials < 60
	*page_break
	The business leaders of the city are clearly distressed by the cancellation of the ${wainwright} building. It prompts a number of editorials in the newspapers by individuals pointing fingers at each other and contemplating the future of the city. How will St. Louis compete with Chicago if it refuses innovation?
*goto post_wainwright

*label post_wainwright
*if false
	*page_break
	*comment duncan_and_brady
	*comment 10/6/1890
	
	In early October, the death of a police officer during a barroom gunbattle
	*if stlouis_race_relations > 65
		provokes expressions of concern and dismay by the citizens of the city.
	*elseif stlouis_race_relations > 50
		results in the typical tirades about the danger of the mixing of races in the United States.
	*elseif stlouis_race_relations > 40
		provokes calls for the lynching of the suspect.
	*else
		provokes calls for another lynching, if not an outright massacre of the city's black population.
	
	The initial version of the story is that the suspect assaulted a trio of officers before fleeing into the Charles Starkes saloon on North 11th Street. The officers followed, whereupon the suspect bludgeoned the lead officer and stole his gun. A gunbattle ensued, during which the disarmed officer was shot, as was the suspect, Harry Duncan.
	
	At this point, James Brady, a fourth officer, entered the saloon, and was shot dead.
	
	But who shot Brady? The three officers assert that Duncan fired the killing shot. Duncan, on the other hand, asserts his innocence, claiming that the gun he took from the first officer had already been emptied by the time Brady entered the saloon. 
	
	A young black lawyer, Walter Farmer, takes the case. He makes an impassioned defense, trying to throw blame on the saloon-keeper, Charles Starkes. The judge refuses to allow Starkes to be called; on cross-examination, the police officers testify that they did not recover any weapons from the scene of the crime; and when a witness for the defense testifies to Starkes's guilt, the prosecutor derides the witness as untrustworthy, as he had since been arrested on a murder charge of his own. 
	
	The all-white jury takes one look at a black defendant accused of killing a white police officer and votes to convict.
	
	Within weeks, the black balladeers of St. Louis are singing about how Brady with his shining star was [i]looking to shoot someone just to watch him die[/i]. Duncan's guilt or innocence seems irrelevant; he is cast as a hero who fought back against a corrupt cop at the cost of his own life.
	
	Farmer appeals the case all the way to the Supreme Court, becoming one of the first African-Americans to argue a case there; but the Court declines to take the case and Duncan ordered hanged.
	
	In the weeks before the hanging, cards begin to appear throughout town, advertising the event. The community is invited to come and watch and celebrate justice being done.
	
	The abuse heaped on Duncan on his journey to the gallows makes him crumple to his knees. The executioners finally pick him up and carry him the rest of the way. When the trapdoor opens, a cheer goes up from the crowd, while numerous onlookers jeer at the accused.
	
	The State of Missouri is considerate enough to cut the body down within a few hours and render it to the family; this isn't a lynching, after all.

*if (egans_rats_plot > 1) or (stlouis_enterprise = 1)
	*page_break
	*if (egans_rats_plot > 1)
		Ever the crook, @{(egans_rats_plot = 5) Baldy Higgins|Snake Kinney} has realized that graft is remarkably similar to extortion. With the assistance of the Ashley Street Gang, he announces his candidacy for the Democratic Central Committee of St. Louis.
	*elseif (egans_rats_plot = 1) and (stlouis_enterprise = 1)
		*set egans_rats_plot 2
		Somewhat to the dismay of the finer set of St. Louis, an upstart Irish gangster by the name of Thomas "Snake" Kinney has announced his candidacy for the Democratic Central Committee of St. Louis. He is the leader of a group of ruffians known as the Ashley Street gang.
	It's a small position—mostly reponsible for helping to turn out the vote and staffing poll sites—but is a legitimate basis for the dispensation of patronage as well as being a stepping-stone to further political ambitions. 
	
	He wins the election easily.
	
	It becomes immediately clear that @{(egans_rats_plot = 5) Baldy|Snake}—with the assistance of his gang—will be well-positioned to turn out votes in the Kerry Patch for any and every matter. Every legislator that wants or needs those votes must now compensate @{(egans_rats_plot = 5) Baldy|Snake}.
*if (baseball_failed = false) and (stl_vda_drama or (sporting_goods > 1))
	*page_break
	
	Having sold off several of his better players to pay the interest on his debts, Von der Ahe has to hold try-outs for the Browns.
	
	A local teenager, John McGraw, has recently been playing for the Cedar Rapids Canaries, a Minor League team in Iowa. He comes home to try out for his hometown team at the suggestion of one of Von der Ahe's former players, Bill Gleason. Bill has now retired from playing, but since returned home to St. Louis and takes more than a passing interest in the fate of the team he spent six years playing for.
	
	After no more than twenty minutes, Von der Ahe reportedly storms off of the field, exclaiming that McGraw would make a better horse jockey than baseball player.
	
	That night at the Golden Lion, Gleason makes a final pitch to Von der Ahe on McGraw's behalf.
	*label mcgraw_loop
	*choice
		*if (perception > 2) #First, I want to look into McGraw's heart and see if I can divine anything.
			McGraw has an undeniable enthusiasm for both life and the game of baseball. Your senses cannot tell you if he has any talent, but he has heart and hustle. He also has an affable gregariousness that infects anyone he spends time with.
			*goto mcgraw_loop
		*if (charm > 3) #I use my powers to persuade Von der Ahe to hire McGraw.
			*set browns_saved +1
			Gleason is surprised by your intervention on McGraw's behalf, but he is too grateful to think twice about your intentions.
		*selectable_if (wealth > 200000) #I offer to pay the first year of McGraw's contract.
			*set browns_saved +1
			*set wealth -50000
			Gleason is surprised by your intervention on McGraw's behalf, but he is too grateful to think twice about your intentions. Von der Ahe, surprised by your willingness to put your own money on the line, warms to the idea. He eventually convinces himself that hiring McGraw was his own stroke of brilliance—he did let him try out, after all—but that does not stop him from accepting your money.
		#Von der Ahe has dug his own grave; let him lie in it.
			*set discretion %-5
			Von der Ahe refuses to change his mind. McGraw packs his things and returns to Iowa.
	*if browns_saved = 1
		
		A few months later, McGraw is signed by the Baltimore Orioles. He will become a star, inspiring the team to numerous pennants over his career.
		
		Once again, Von der Ahe has pointedly rejected the advice of an expert in favor of absolute trust in his own ill-formed opinions.
*if baseball_failed
	*set stl_vda_drama false
*page_break
*comment 1891-02
*temp knows_gould false
*temp going_gould false
*if speaks_english
	*if ((finance > 0) or (stlouis_enterprise = 1)) or ((feeding_style = "merchants") or (feeding_style = "socialites"))
		In February of 1891, you are surprised to learn that Jay Gould will be coming to St. Louis. He has reserved rooms at the Southern Hotel.
		
		*choice
			#I want to @{fed_from_gould reacquaint myself with|meet} this scoundrel!
				*set discretion %+5
				*set going_gould true
			#I sense business opportunities.
				*set going_gould true
			#I intend to give Gould a piece of my mind!
				*set justice %-5
				*set going_gould true
			#I want nothing to do with Gould.
				*set discretion %-5
	*elseif bailey_rapport > 60
		*set knows_gould true
		*set going_gould true
		In February of 1891, you are surprised to receive a note from John Bailey inviting you to join him at the Southern Hotel the follow Thursday evening. He promises a surprise guest.
		
		It would be terribly rude to turn down his invitation, so you return your acceptance and prepare yourself for this encounter.
		*page_break
	*if going_gould
		Arriving at the Southern Hotel, you find the sidewalk filled with throngs of 
		*if knows_gould
			people hoping to catch sight of the famous @{(compassion < 50) robber-baron|industrialist}. ${stlouis_valet} lets you off and the footmen open the front doors for you. 
		*else
			people.
	
			"Do you know what this is all about?" you ask ${stlouis_valet}.
	
			"No, I don'," ${valet_he} replies.
	
			The crowd does not look angry or agitated—more…excited. Whatever it is, they are not here to see you burnt to a crisp. Casting fears aside, you order ${stlouis_valet} to stop and let you off.
		You are well-acquainted with the Hotel due to Senator Bailey's patronage of it—and glide quickly into the hotel bar.
	
		You immediately spy Bailey sitting at his usual table in the corner. With him are @{knows_gould Jay Gould and another white man whom you do not recognize. You should have known that Bailey would be mixed up with Jay Gould!|two white men whom you do not recognize—though one of them does look familiar.}
	
		When you approach, two bodyguards intervene. @{(perception > 1) You note two others in the wings, at the ready.|} They look to @{knows_gould Gould|one of the unknown men}, who looks to @{knows_gould the man whom you don't recognize|the other unknown man}, who in turn looks to Bailey, who waves you forward.
	
		"Senator Bailey," you begin.
	
		"Dear ${given_name}, allow me to introduce you to Edwin Lefferts—" he says, gesturing towards @{knows_gould the man you don't recognize|one of the men}, "—and Jay Gould."
	
		*set met_lefferts true
		*if heard_of_lefferts
			"Edwin Lefferts? I believe we know someone in common!" you observe. Is Jay Gould Lefferts's valet? Surely Jay Gould is no one's valet. Is Jay Gould a vampire? @{(perception > 1) No, he breathes.|You cannot be sure at a glance, but you suspect not.} And yet why is Gould sitting here with Malloy's broodmate and Senator Bailey?
	
			"Other than John here?" Edwin replies lazily.
	
			Malloy did say he was not to be trusted. "Siobhan, in fact."
	
			"My not-so-dear sister! What horrible things did she say about me?" 
	
			You look from Lefferts to Gould to Bailey and back again.
			*if discretion > 50
				"That you'd been fooled into giving your money to this shark," you say, indicating Gould.
	
				Gould laughs. "So he did."
				
				Edwin rolls his eyes at Gould before turning to you. "Please, call me Edwin."
			*else
				"Nothing untoward," you reply.
	
				Lefferts snorts. "Unlikely. But please, call me Edwin."
		*else
			@{knows_gould |This is…quite the surprise guest. However, you have spent too much time among vampires to let your consternation show.}
			*if perception > 1
				Peering at the two men, you divine that Lefferts is a vampire, but Gould is not. Is Jay Gould Lefferts's valet? Surely Jay Gould is no one's valet. Is Jay Gould a vampire? @{(perception > 1) No, he breathes.|You cannot be sure at a glance, but you suspect not.} And yet why is Gould sitting here with two vampires?
				
				While any normal situation would call for greeting Gould first, if Gould is not a vampire, and Lefferts is.…
				
				"Mr. Lefferts, a pleasure to meet you. Are you…just visiting, or intending on taking up residence here?"
				
				"Oh, just visiting. Jay here wanted to come out this way. Some business dealing or other. I simply couldn't say no. And please, call me Edwin. Mr. Lefferts is a long-dead slaveholder in Flatbush." @{(gould_plot = 2) You heard it said once that Gould was involved with vampires—that several lost fortunes in his chicanery. And yet here, someone is consorting with him like they are the best of friends!|}
				
				You nod, and then, "Mr. Gould, a pleasure to meet you."
				
				"And you, ${given_name}. And please, call me Jay."
			*else
				*set bailey_rapport %-5
				"Mr. Gould," you begin, "welcome to St. Louis…"
				
				Bailey clears his throat. It's then that you realize that Lefferts is a vampire and you have just greeted a mortal first. "Oh, forgive me, Mr. Lefferts."
				
				Lefferts waves it away. "No trouble. You wouldn't believe the people that are more interested in Jay than me. But, I suppose Stone wants it that way." @{(gould_plot = 2) You heard it said once that Gould was involved with vampires—that several lost fortunes in his chicanery. And yet here, someone is consorting with him like they are the best of friends!|}
				
				"Would you have it another?"
				
				"I can't say that I would object to being known, no. But keeping pace with Jay here seems to be about the best I can manage under the current circumstances. And please, call me Edwin. Mr. Lefferts is a long-dead slaveholder in Flatbush."

		"Do you reside in New-York, Edwin?"
		
		"I do. Where else? I mean, I suppose there's London and Paris, but I don't think I'd be welcome there."
		
		"No, I think not," Bailey says. "Won't you sit?" he continues, gesturing for you to take a seat.
		
		*if independence > 40
			"Have you had a chance to present yourself before Memeskia?" you ask before sitting.
			
			"We won't be here as long as all that," Lefferts replies.
			
			"It's fine, ${given_name}. I've extended them the Quaestor's hospitality," Bailey says. "Now, sit."
					
		*if (discretion > 50) 
			And so you do.
		*elseif independence < 50
			You clench your teeth. You can already imagine the gossip columns tomorrow—but you cannot say no.
		*else
			You clench your teeth. You do not like the idea of consorting with a vampire who has not presented themselves before the Quaestor.
		*set local_fame %+5
		*if (ethnicity = "african") or (ethnicity = "choctaw")
			*set local_fame %+5
		*if male = false
			*set local_fame %+5
		*set heard_of_lefferts true
		*if fed_from_gould
			
			Throughout this exchange, you've noticed Gould eying you. "Have we met?" he inquires at last.
			
			You look to Edwin and then back at Gould. "Yes, briefly."
			
			"I thought so. You fed from me, didn't you."
			
			Seeing no reason to lie, you say, "In fact, I did."
			
			"Yes, when I was here ten years ago."
			
			"That seems right. No hard feelings, I trust?"
			
			"No hard feelings," he echoes.
		*page_break
		Gould is, in fact, here to see to the workings of the Terminal Railroad Association. And Lefferts…is his boon companion, as best as you can tell. Though you'd had your suspicions before, it soon becomes clear that Bailey is deeply involved with the railroads as well.
		*if stl_electricity < 5

			"What I don't understand is why you city doesn't use electricity. You rely on blue water gas instead."

			"Do you have a problem with that?" you quip.

			"Yes! Electricity is much safer and it consumes much more coal than blue water gas. If you don't need as much coal, I have much less need to ship it to you. If there's no need to ship coal to you, why did anyone bother building a railroad here!" Gould exclaims.

			"There are other cities to the east and west consuming no end of coal. No need to fret."

			"I don't like it. Not one bit," Gould grouses.
		
		At some point, you have the opportunity to speak to Lefferts one-on-one.
		*choice
			#I comment on the strange relationship the two have.
				*set independence %+5
				Lefferts laughs. "Ah, yes, I'm sure it does look quite queer to most of our kind. But I promise you, all is in order."
				
				"What order is that?" you reply.
				
				"We are business associates."
				
				"But he knows what we are?" you say, incredulous.
				
				"He does! But given his reach and influence, he would have discovered us eventually anyway. Better to have invited him in to the party than leave him outside wanting to burn it down."
				
				"And you think this relationship is wise?"
				
				"I do! What could go wrong?"
				
				So many things, you hazard.
			#I want a cut of the railroad empire.
				*set laborvscapital %-15
				Lefferts laughs at you. "Then you must bring something to the table! Find something that Jay wants, and I am sure he will pay you handsomely for it."
			#I want to ply Lefferts for any details of the TRRA. Valuable intelligence may allow me to break Gould's monopoly on cross-river traffic.
				*set laborvscapital %-15
				Alas, Lefferts is used to people pumping him for information. He does an admirable job of turning aside your half-articulated queries and ignoring your verbal feints.
				
				He may be dissolute, but he is not a fool.
			#I want to ply Lefferts for any details of the TRRA. Valuable intelligence may allow the workers to win in their next round of negotiations.
				*set laborvscapital %+20
				Alas, Lefferts is used to people pumping him for information. He does an admirable job of turning aside your half-articulated queries and ignoring your verbal feints.
				
				He may be dissolute, but he is not a fool.
			*if ((feeding_style = "merchants") or (feeding_style = "socialites")) #I really just want to feed from Gould@{fed_from_gould  again|}.
				*set discretion %+5
				*set shepherd_credentials %-5
				Try as you might, though, Lefferts baffles any attempt of yours to sink your teeth into Gould. You suspect that you are not the only vampire that wants to drink Gould's blood, and Lefferts deftly intercepts each of your ploys, turning them aside with practiced grace.
			*if (perception > 1) #I ask about Gould's tuberculosis.
				*set compassion %-5
				For a moment, you think you spy a hint of sadness in Lefferts. "We all must die sometime," he says.
				
				"But your friend is actively dying."
				
				"So he is. Do you have a cure at hand?"
				
				*if tuberculosis_vaccine > 1
					"In fact, the University here is working on a vaccine. But no, no cure for those already afflicted."
					
					Lefferts perks up as you begin, but then becomes even more crestfallen.
				*else
					"No, I do not."
					*line_break
					*line_break
				"Then there is nothing to be done," he replies.
		
		About a week later, Lefferts and Gould mount a train and return to New-York.
*finish Next