*comment ñáéç…—
*hide_reuse
*advertisement
*gosub_scene util check_flow
*temp paid_off_wilson false
*temp lied_to_withers_about_pb false
*temp embrace_request_denied false
*if wilson_embraced_by_withers
	*goto wilson_flees
*set year 1865
It is only a few short years until the Confederacy surrenders.

During the celebrations of the soldiers and now permanently free blacks, you notice that ${wilson} does not celebrate like the others; doing some quick calculations, you realize that he has grown old in your service.  Though, it could be that fever he's been wrestling with recently.  He still looks young enough@{(compassion > 50) …but, then again, it's so hard to tell about these things now|}.

Perhaps you should consider some sort of retirement for the fellow?
*label wilson_choice
*choice
	#I release him from service.
		*set compassion %+5
		*set discretion %+10
		*set maddox_rapport %-5
		*set wilson_embraced_by_withers true
		*set exposure +1
		You make sure to let ${wilson} know that, if he ever breathes a word of what he has seen and done while in your employ, you will find him and make the rest of his existence long and miserable.
		*goto pre_revolution
	*selectable_if (wealth > 100000) #I set him up with a farm of his own.
		*set wealth -50000
		*set compassion %-15
		*set maddox_rapport %+20
		*set paid_off_wilson true
		*set wilson_embraced_by_withers true
		${wilson} is astounded at your generosity.  The land isn't much, but it is his.  With it as his own, he will be able to find a wife and raise a family.
		*goto pre_revolution
	*selectable_if (lore > 1) #I ask Withers if I can give ${wilson} the gift of immortality.
		*set compassion %+10
		*set independence %+5
		*if withers_rapport >= 45
			*set knows_wilson_embraced true
		
			Withers seems delighted by the idea.
			*set wilson_embraced true
			@{love_hope She even intimates that ${wilson} may provide some of the companionship you had sought in Silas.  You try not to scoff at the suggestion.|}
			
			When you propose your solution to ${wilson}, he seems excited by the prospect of eternal life.  On the bright side, he will not have to worry about that pesky fever any more now. 
			
			When the time comes for that transcendental moment, you do your best to wipe away the sudden fear that you are condemning this poor soul to an existence of eternal, unearthly hunger…
			*page_break 
			*goto embrace_wilson
		*else
			*set embrace_request_denied true
		
			Withers laughs in your face.  "What aspect of your existence merits propagation unto another generation?  If such merit exists, I have yet to see it, ${mr} ${surname}."  With that, she will hear no more of the idea.
			*goto wilson_choice
	#I kill him.  He knows too much.
		*set compassion %+15
		*set discretion %-10
		*set maddox_status "dead"
		*set wilson "Hugh"
		*set maddox "Gallagher"
		*set maddox_num 3
		Probably a wise choice.  Certainly the safest and most efficient one.
		*goto pre_revolution
	*if charm > 3
		*selectable_if (compassion > 60) #Work him to death.
			*set compassion %+25
			*set discretion %-5
			*set maddox_status "dead"
			*set wilson "Hugh"
			*set maddox "Gallagher"
			*set maddox_num 3
			It is only a few months before ${wilson}'s heart stops beneath a load of firewood.  You direct your new valet to have ${wilson}'s body dumped with the rest of the city's trash.
			*goto pre_revolution

*label embrace_wilson
*achieve wilson
*set compassion %+15
*if feeding_style = "vegetarian"
	Considering your abstension from the blood of humans, the conversion of ${wilson} is rather impersonal: you use @{male your|his} straight-razor to let his blood, offering him a sip of yours once he has reached the threshold of death.

	His eyes flutter open at the taste of you, and he sucks hungrily at your wrist.  It takes all of your strength to fight him off, but you do.

	He is wild at first, but will calm down soon.  You are sure of it.
	*goto wilson_embraced
*elseif compassion >= 65
	*set exposed_plague true
	When the time comes for ${wilson}'s conversion, you drink his blood dispassionately.  Once you sense that his heart has stilled, you bite your wrist and force your own blood past his lips.

	His eyes flutter open at the taste of you, and he sucks hungrily at your wrist.  It takes all of your strength to fight him off, but you do.

	He is wild at first, but will calm down soon.  You are sure of it.
	*goto wilson_embraced
*elseif (ethnicity = "african") or (compassion >= 45)
	*set exposed_plague true
	When the time comes for ${wilson}'s conversion, you take the opportunity to savor the taste of his blood.  His heartbeat pushes your own into motion, and you thrill at the feeling of warmth that spreads throughout your body.

	When his heart begins to slow and his breathing stills, you break yourself away from his neck.  You must hurry, lest the last vestiges of life flee.  Biting your wrist, you push your own blood past his lips.

	His eyes flutter open, and he sucks hungrily at your wrist.  It takes all of your strength ot fight him off, but you do.

	He is wild at first, but will calm down soon.  Or, at least, you hope so.
	*page_break
	*set bloodsweats true
	The next evening, you awake from your dayslumber to find your linens and sleeping clothes ruined, discolored by a thin sheen of blood.

	You toss the ruined garments into a fire, and when there is no recurrence, you push any lingering concerns from your mind.  Besides, you have a fledgling vampire to educate.
	*goto wilson_embraced
*else
	*set afflicted_vicksburg true
	*set maddox_status "fled"
	*set exposed_plague true
	When the time comes for ${wilson}'s conversion, you take the opportunity to savor the taste of his blood.  His heartbeat pushes your own into motion, and you thrill at the feeling of warmth that spreads throughout your body.

	When his heart begins to slow and his breathing stills, you break yourself away from his neck.  You must hurry, lest the last vestiges of life flee.  Biting your wrist, you push your own blood past his lips.

	His eyes flutter open, and he sucks hungrily at your wrist.  It takes all of your strength ot fight him off, but you do.

	He is wild at first, but will calm down soon.  Or, at least, you hope so.
	*page_break
	*set bloodsweats true
	You awake the next night to discover yourself nearly immobile.  Pain shoots through your joints, and you are enveloped by the smell of blood.

	Once you are able to calm yourself down, you notice that you are covered in blood, with your linens and sleepingclothes ruined.  You scream in horror.

	${wilson} rushes into the room.  Overcome by the smell of blood, he falls to his knees, and begins licking at the blood that coats your skin.  You are too weak to push him off, and the young vampire is insensible to your protests.  To make matters worse, you realize that the skin of your arms—and presumably the rest of you—has taken on a distinctively yellow cast beneath the sheen of blood.

	Your cries of horror do not wake you; you are forced to confront the fact that this nightmare is real.
	*page_break
	When ${wilson} finally regains use of his faculties, he is horrified by his actions.  You order him to fetch you a mortal to feed from, to restore your strength, and your authoritative commands break through the fog of confusion that has settled upon him.  Shaking his head, he seems to regain control.  "Ah wuls find ya' somebody ta feed on!"
	
	*set compassion %+15
	Over the next few days, victim after victim falls beneath your fangs.  Admittedly, ${wilson} must bring them to you already unconscious, but you drink them dry, only to find their blood excreted from your pores during the worst of your fevers.
	
	After four or five nights, your body finally begins to recover.  The fevers cease, and the pain subsides.  After ${wilson} helps you to clean yourself one evening, you start to try to make sense of the past few nights.

	As your questions become more pointed, he becomes more agitated.  Finally, he turns and flees, leaving you sitting before your vanity.  You move to chase him down, but the pain in your limbs is too great, and you fall to the ground, calling after your progeny.

	He does not return.
	*set exposure +5
	*if (streetwise > 1) and (wealth > 100000)
		*page_break
		*set exposure -4
		*set wealth -25000
		It costs you dearly to silence the families whom ${wilson} destroyed in order to see you through your affliction.  But with the expenditure of enough coin, @{pitchforks_in_saintcharles you prevent a recurrence of your unceremonious ejection from St. Charles parish.|you prevent a mob from knocking down your door in search of vengeance.}
		Thankfully, because of your connections with what passes for a criminal underworld in post-War Vicksburg, you generous offers of restitution are accepted without further attempts at negotation.
	*if (wealth > 150000) and (streetwise <= 1)
		*page_break
		*set exposure -4
		*set wealth -40000
		It costs you dearly to silence the families who ${wilson} destroyed in order to see you through your affliction.  But with the expenditure of enough coin, @{pitchforks_in_saintcharles you prevent a recurrence of your ejection from St. Charles parish.|you prevent a mob from knocking down your door in search of vengeance.}
	*page_break
	Walking stiffly, you descend from your coupé to the street before the home of Withers.  You missed last Tuesday's salon, and she is expecting you.

	Her servant welcomes you inside, announcing you a few moments later.  Noticing that you are alone, she inquires after ${wilson}.
	*choice
		#"The transformation…it didn't take."
			*set discretion %-10
			*set independence %-5
			*set lied_to_withers_about_pb true
			"It happens," she replies, nonchalantly.

			You spend the next few weeks wondering if your lie will be discovered, but Withers seems to have accepted your story without suspicion.
			*page_break
			*goto pre_revolution
		*selectable_if (discretion > 30) #"He has fled."
			*set withers_rapport %-15
			*set discretion %+10
			*set chasing_wilson true
			*set maddox_status "free"
			"Fled?"

			"Yes."

			"What do you mean, fled?"

			"He left and did not come back."

			She looks at you exasperatedly.  "Then you must go and find him!  You are responsible for your offspring, ${mr} ${surname}.  Their crimes are yours to bear!"
			*page_break
			After some investigation, you learn that he was spotted on a steamboat bound for Memphis.

			Packing your things, you begin your pursuit.
			*finish Next
		#"I am, in fact, here to inform you that I must leave.  He has fled my keeping…"
			*set withers_rapport %-10
			*set discretion %+5
			*set independence %+10
			*set chasing_wilson true
			*set maddox_status "free"
			"Fled!"

			"Indeed."

			"I am glad to hear that you take your responsibilities seriously."

			"I do, Quaestor."
			*page_break
			*set introduction_made_to_carothers_by_withers true
			After some investigation, you learn that he was spotted on a steamboat bound for Memphis.

			Packing your things, you begin your pursuit.  When you mention your destination to Withers, she offers to write a letter of introduction to the Quaestor of Memphis for you.  You take the letter, thank her, and bid farewell to Vicksburg.
			*finish Next

*label wilson_embraced
*page_break
Finding yourself in the position of a maker for the first time, you realize just how much there is to know.  More importantly, how much there is to teach your offspring.

Of course, one of the most important things to communicate to ${wilson} is how you think a vampire should conduct themselves during the course of their unlife.
*choice
	*if shepherds_and_wolves
		*selectable_if (compassion < 70) #I teach ${wilson} in accordance with the philosophy of the Shepherds: we must do our best to guide the humans away from the worst of their inclinations, for our sakes.
			*set shepherd_credentials %+15
			*set compassion %-10
			*set discretion %-5
			*set rationalism %-5
			*goto wilson_embraced_post
	*else
		*selectable_if (compassion < 70) #It is best that we vampires not flaunt our supernatural natures, and moreover strive to curb our baser instincts.  After all, it is much easier to avoid unwanted attention if we behave ourselves.
			*set shepherd_credentials %+10
			*set compassion %-10
			*set discretion %-5
			*set rationalism %-5
			*goto wilson_embraced_post
	*if shepherds_and_wolves
		*selectable_if (compassion > 30) #I teach ${wilson} in accordance with the philosophy of the Wolves: the humans are a lesser species, and should be treated as such.
			*set shepherd_credentials %-15
			*set compassion %+10
			*set discretion %+5
			*set rationalism %-5
			*goto wilson_embraced_post
	*else
		*selectable_if (compassion > 30) #Humans are food and servants.  They should be treated as such.
			*set shepherd_credentials %-10
			*set compassion %+10
			*set discretion %+5
			*set rationalism %-5
			*goto wilson_embraced_post
	*if compassion > 30
		*selectable_if (rationalism > 30) #It is self-evident that we are cursed by God.  If he has turned his back on us, then I see no reason for us to do aught but what we wish to His children.
			*set shepherd_credentials %-10
			*set rationalism %+10
			*set compassion %+10
			*goto wilson_embraced_post
		*selectable_if (rationalism < 70) #There is no God.  And if there is no God, then there are no consequences.  Therefore, we have an obligation of sorts to explore the edges of experience.  If that means that the humans are nothing more than tools in that exploration, so be it.
			*set shepherd_credentials %-10
			*set maddox_rapport %-20
			*set rationalism %-10
			*set compassion %+10
			*goto wilson_embraced_post
	*if compassion < 70
		*selectable_if (rationalism > 30) #The condition in which we find ourselves is a test put before us by God.  We must strive to with all our might to meet the challenges he has presented to us, and continue to conduct ourselves as he would wish.
			*set maddox_rapport %+20
			*set rationalism %+10
			*set compassion %-10
			*goto wilson_embraced_post
		*selectable_if (rationalism < 70) #There is no God, so we must define our own moral code.  Only by defining a morality of our own will we survive the centuries without tearing each other to pieces or provoking the mortals to put an end to us.
			*set shepherd_credentials %-10
			*set maddox_rapport %-10
			*set rationalism %-10
			*set compassion %-10
			*goto wilson_embraced_post
	*if knows_about_vegetarianism
		*if willpower > 2
			*selectable_if (compassion < 40) #Together, we will strive to feed only from animals.
				*set shepherd_credentials %+15
				*set feeding_style "vegetarian"
				*set compassion %-20
				*goto wilson_embraced_post
		*else
			*selectable_if (compassion < 50) #I hope someday that I will have the strength of will to abstain from feeding on humans, and I teach him accordingly.
				*set shepherd_credentials %+10
				*set compassion %-10
				*goto wilson_embraced_post

*label wilson_embraced_post

${wilson} takes your lessons in stride, and seems relatively earnest in his desire to learn as much about his condition in as short of a time as possible. @{(shepherd_credentials < 50) Unfortunately, ${wilson} seems to be having a hard time with the idea of leaving his prey alive.  You chastise him for his waste, and the unwanted attention that it brings, and you direct him to feed only from those already on the verge of death until he can learn to restrain himself.|}
*label pre_revolution
*page_break
During these months, as something resembling peace spreads across the land, you continue to attend the weekly soirées at the home of Withers.
*label revolution

While you are shuffling the cards one evening, Samantha takes a moment to open a letter from
*if met_overstreet
	her broodmate.
*else
	*set heard_of_overstreet true
	Governor Overstreet, who administers her province from Savannah.  Moments ago, Samantha revealed to you that they share a maker.
As her eyes scan the first lines of the letter, her hand rises reflexively to her mouth.  You had not thought it possible, but the already pale face of Quaestor Withers blanches at the words before her.

"What is it?"

"There has been a revolution."

"A revolution? Is the governor just learning about the secession?"

"No. In the Society."

"What do you mean?"

"Senator Stone, of Baltimore…he has slain Praetor Miele, and declared himself Consul of the Americas."
*set heard_about_revolution true

*if consul_praetor_explained
	"That is…unprecedented!" you exclaim. The magnitude of the news makes you dizzy.
	
	"I cannot believe it myself!" Withers replies. She reads the letter again to assure herself that she did not misconstrue her sister's words. Eventually she raises her eyes to yours…there are no more answers to be had there.
	
	You shake your head, trying to come to grips with this. "What does it mean?"
*else
	*if speaks_latin or (intelligence > 2)
		From your extensive classical education, you know that consuls were the elected rulers of the Roman Republic—until they weren't. For generations after the transition to dictatorship, what are now called emperors continued to style themselves consuls in an attempt to maintain the illusion of representative government. Similarly, praetors were judges, appointed by consuls, to adjudicate the law.
		
		"I should have anticipated such titles, I admit, but they are still foreign to me in this context," you say.
	*else
		"Consul?  Praetor?  I have never heard these terms."
	
	"Consul Adonis has led the Society from Rome for millennia.  The praetors are those who are tasked with seeking out heresy and treason within the Society."
	*set consul_praetor_explained true
	*if discretion > 60
	
		"Well, if seems he found some treasonous activity."
		
		"Yes, I suppose he did."

	"What does all this mean?"

"Honestly, I don't know."

"What of the governor?  Whom does she support?"

"That's just it, she doesn't say.  Please, I'm sorry, but I think I have to excuse myself.  I have many letters to write."

"Yes, of course."  You stand and ${bow} as she departs.
*page_break

*if (jesse_rapport >= 40) and ((independence >= 30) and (literate and ((avoided_new_orleans = false) and (jesse_is_broodmate))))
	*set letter_from_jesse_about_quaestor_of_new_orleans true
	*set heard_about_new_orleans_quaestor_change true
	Not long afterwards, you receive a letter from Jesse. In it, he confirms the news about the murder of Praetor Miele.
	*if (new_orleans_quaestor_surname = "Van der Velde")
		*set jesses_sire_formerly_quaestor false
		*set jesses_revolutionary_credentials %+15
		*if sire_alive
			*set revolutionary_credentials %+15
			Apparently, your maker is horrified by these deeds.
		*else
			Apparently, Van der Velde is horrified by these deeds.
	*else
		*if new_orleans_quaestor_surname = "Padre Carlos"
			*set jesses_revolutionary_credentials %+30
			More importantly—in your opinion—he further informs you that Consul Stone has named Padre Carlos the first praetor of the Americas.  Consequently, a Dutch vampire by the name of Pieter van der Velde has been appointed Quaestor of New Orleans by Governor Overstreet.
			*if jesse_is_broodmate
				*set revolutionary_credentials %+20
				*set sire_rapport new_orleans_quaestor_rapport
				*set sire_formerly_quaestor true
		*else
			*if new_orleans_quaestor_surname = "Winters"
				*set jesses_revolutionary_credentials %+10
				*set revolutionary_credentials %+10
			*if new_orleans_quaestor_surname = "Villanueva e Itamaraca"
				*set jesses_revolutionary_credentials %+15
				*set revolutionary_credentials %+15
			*if new_orleans_quaestor_surname = "Sainte-Chapelle"
				*set jesses_revolutionary_credentials %-20
				*set revolutionary_credentials %-10
			More importantly—in your opinion—he further informs you that ${new_orleans_quaestor_surname} has been displaced as Quaestor of New Orleans.  Only days after the word of the murder reached New Orleans, a letter was presented by a Dutch vampire by the name of Pieter van der Velde, which declared him the new Quaestor, serving at the pleasure of Governor Overstreet.
			
			He assures you that your dominus is fine and well, and will seek accommodations elsewhere. Clearly, New Orleans is no longer to his liking. @{(new_orleans_quaestor_surname = "Villanueva e Itamaraca") Besides, he had been too long from the battlefield and had grown bored with the administration of a city.|}
			*set sire_rapport new_orleans_quaestor_rapport
			*set sire_formerly_quaestor true
		*set new_orleans_quaestor_given_name "Pieter"
		*set new_orleans_quaestor_surname "Van der Velde"
		*set new_orleans_quaestor_address "Heer Van der Velde"
		*set new_orleans_quaestor_rapport 50
	*if jesse_rapport < 55
		
		In addition to relaying the news, Jesse also expresses some remorse about how the two of you parted ways. He implies that the two of you should be closer than you are—though it's hard to tell if he means those words or whether he is only seeking to manipulate you.
	
	You @{literate write|dictate a letter} back to point out that Vicksburg lacks a senator. @{(jesse_rapport < 55) You also take the opporunity to offer a few half-apologies. A step towards reconciliation, if such is to happen, you reason.|}
	
	Jesse response confirms what you had previously suspected: Withers's appointment as Quaestor of Vicksburg is a sinecure. According to Jesse, the city will never have a Senator. @{(jesse_rapport < 55) At the same time, Jesse seems quite appreciative of your half-apologies. Perhaps, some day, the two of you will be allies.|}
	*set jesse_rapport %+10
	*page_break

About a week later, you find yourself again in the company of Withers.  During the course of the conversation, she inquires about what you intend to do now that the war is over.
	
*label stay_in_vicksburg
*temp things_packed false
*choice
	*if maddox_status = "fled"
		#"In fact, I have business that takes me elsewhere…" Such as finding your errant progeny, ${wilson}.
			*set discretion %-5
			*set independence %+15
			*goto goodbye_withers
	#"I have had enough of Vicksburg.  I thank you for your hospitality, but I think it time that I moved on."
		*label goodbye_withers
		*if withers_rapport > 60
			"I wish you only the best, dear ${given_name}."
			
			"And I you, Quaestor Withers."

			"Tell me, where do you intend to go?"

			"I have heard great things about Memphis…"

			"Oh, please, allow me to write a letter of introduction to the Quaestor there.  Apollo Carothers is his name…"

			*label offer_of_introduction
			*set introduction_made_to_carothers_by_withers true
			"That would be most kind of you, Quaestor."

			She puts quill to @{(anachronism > 40) paper—she has not yet adopted the use of fountain pens—and|paper, and} writes out a note.  "He will be expecting you, ${mr} ${surname}," she observes, dusting the paper to dry the ink.  Without hesitation, she folds the letter, drips some wax on the lip, and presses her seal to formalize the matter.  "It is done.  It will be in the post tomorrow."
			*goto leavetaking
		*elseif (withers_rapport >= 40)
			"Safe travels, ${mr} ${surname}.  I imagine that we shall meet again some night or other."
			
			"Yes, I imagine we shall."
			*if status > 1

				"Perhaps a letter of introduction would be in order?"
				*goto offer_of_introduction
			*else
				*goto leavetaking
		*elseif (status > 2) and (lore > 2)
			*set introduction_made_to_carothers_by_withers true
			"Fare well, ${mr} ${surname}."

			"Perhaps a letter of introduction is in order, Quaestor?"

			"Oh, of course."

			She puts quill to @{(anachronism > 40) paper—she has not yet adopted the use of fountain pens—and|paper, and} writes out a note.  "He will be expecting you, ${mr} ${surname}," she observes, dusting the paper to dry the ink.  Without hesitation, she folds the letter, drips some wax on the lip, and presses her seal to formalize the matter.  "It is done.  It will be in the post tomorrow."

			"Thank you, Quaestor."
			*goto leavetaking
		*else
			"Goodnight, ${mr} ${surname}."
			
			"And you, Quaestor Withers."
			*goto leavetaking

		*label leavetaking

		*if lied_to_withers_about_pb
			*set things_packed true
			*page_break
			You thought you had gotten away with it. Your things are already packed, your passage secured…it only remains to say a final goodbye to Withers.
			
			You make the short jaunt to her haven, only to discover that you have been exposed.
			*goto pb_masq_breach
			
		Your goodbyes said, you take your leave of Quaestor Withers.
		
		A few weeks later, you set out for Memphis.  
		*if wilson_embraced
			*set maddox_status "with"
			${wilson} expresses his enthusiasm about the move.  It seems he is looking forward to seeing something of the world besides Vicksburg, now that he is a vampire. @{(independence >= 30) It will, moreover, be good to circulate with others of your kind.  Withers's company has grown somewhat tiresome.  Besides, ${wilson} should be exposed to the Society sooner rather than later.|As much as as you dislike the other members of your kind, it is important for ${wilson} to be exposed to the Society.  And, if the Society will not come to Vicksburg, then you must bring him to it.}
		*else
			*if independence >= 30
				You muse that it will be good to circulate with others of your kind.  Withers's company has grown somewhat tiresome.
			*else
				Perhaps the company will be less interested in meddling with your nightly existence there?
		*finish Next
	#"Whatever it is that we vampires ever do.  Please, deal another hand."
		*set withers_rapport %+5
		*set independence %+10
		"But of course!"  With that, Samantha begins to deal another hand.
		*goto resolve_ending
	*selectable_if (compassion < 60) #"I'd like to stay a little longer yet; there is rebuilding here that needs to be done."
		*set withers_rapport %+10
		*set shepherd_credentials %+15
		*set compassion %-10
		"You are always so concerned with the welfare of the community.  I'm sure that your help will be appreciated.  But first, another hand?"

		"Of course, my Quaestor," you reply.
		*label resolve_ending
		*if lied_to_withers_about_pb
			*goto pb_masq_breach
		*elseif wilson_embraced
			*goto wilson_flees
		*elseif wilson_embraced_by_withers
			*goto samantha_embraces_wilson
		*else
			*page_break Volume Three
			*goto_scene timejump3
	#"Vicksburg is devastated.  There are so many ways to profit in the rebuilding of it.  I think I will stay a while yet."
		*set withers_rapport %+5
		*set compassion %+10
		*set shepherd_credentials %-10
		*set income +5
		"But of course!"  With that, Samantha begins to deal another hand.
		*goto resolve_ending

*label pb_masq_breach
*page_break
*set exposure +2
*set chasing_wilson true

You enter Withers's home one evening to find it in an uproar.

"YOU!" Withers exclaims when you enter her drawing room.

"Yes, quaestor?"

"You lied to me!"

"I'm sorry?"

"You told me that turning ${wilson} into a vampire didn't work."

"I…"

"Don't make it worse by lying to me again, ${given_name}." @{things_packed She paces the room. "And to think, you were going to just leave here and say nothing about this!"|}

"What's happened?"

"I should be asking you that! Why is ${wilson} murdering Confederate veterans outside of Greenville?" You are aware that Greenville is a town further up the river from Vicksburg; the next town of note. Really, the only town of note between here and Memphis.

*if (discretion <= 50) or (maddox_num = 2)
	"That's…terrible," you reply.

*if (discretion > 50) and (maddox_num = 1)
	*set withers_rapport %-10
	"Can you blame him?" you reply, before realizing that those words were probably ill-considered.
	
	Withers's face sudden turns an almost-human shade of pink, a distinct difference from the normal pallor. "I cannot even imagine what possesses you to be so flippant about something so dangerous!"
	
	"I simply meant…"
	
	She raises her hand. "Enough."
Her eyes are closed and she is shaking. "You will find ${wilson} and either bring him to heel or kill him. He is yours and therefore he is your responsibility."
*if status > 1
	She opens her eyes. "How could someone of your standing behave this way? Didn't your dominus teach you anything?"
	
	"Excuse me?"
	
	She waves the question away. "Stay focused, ${given_name}."

	You cock your head suspiciously.
"I should go to Greenville and ask if anyone has seen a @{maddox_num one-eared freedman|one-eyed German-Cajun}?"

"He killed those men in Greenville. I suspect that he is headed to Memphis, since it's the next city that could support him."

"Are you certain…"

"No I'm not certain, you imbecile! But you are leaving this city @{things_packed by morning|the day after tomorrow}, and if you wish to have any sort of future in the Society, you will make finding him your purpose in life."

*if (independence < 40) and (discretion > 60)
	"Fair enough. I was actually coming here this evening to tell you that I was leaving Vicksburg anyway."
	
	"As long as your path takes you to Memphis, I can only commend your swift departure."

"Then I @{things_packed suppose it is fortunate that I am already packed|should go and pack my things}." 
*set withers_rapport %-30

"Goodbye."

*if compassion < 50
	You pause a moment. You have been here for several years. That is an extremely abrupt farewell after all this time. Then again, her face is still flush with anger, so you decide it best not to dally further.

"Goodnight to you, quaestor."

@{things_packed Your things already packed, you head to the waterfront. By morning,|You return home to pack. The next evening, you organize passage by steamer, and by the second morning} you are ensconced in a traveling-coffin, headed to Memphis.
*finish Next

*label samantha_embraces_wilson
*page_break
*set knows_wilson_embraced true

Several months later, you arrive at Withers's on a Tuesday evening.  You are surprised to see ${wilson} answering the door.

"${wilson}?  What are you doing here?@{paid_off_wilson  Why aren't you on your farm?|}"

@{maddox_num "Wul, Kwaistah Withahs went and made me like you."|"Well, Quaestor Withers has made me like you."|}

"I'm sorry?"

@{maddox_num "Ah is uh vam-piah."|"I am a vampire."|}

Shaking your head in disbelief, you push past ${wilson} and seek Withers inside.
*page_break
@{embrace_request_denied "You rejected my request to give the gift to ${wilson}, and then you turned him yourself?"|"I released ${wilson} from my service, so that he could live out the rest of his days in peace."}
	
"What can I say, you did an excellent job training him."  You pause to consider this before responding.

*choice
	*selectable_if (discretion < 70) #"I am happy that you found such a suitable companion, Quaestor Withers."
		*set independence %+5
		*set withers_rapport %+20
		*set overstreet_rapport %+10
		*set discretion %-5
		"That is very kind of you to say, dear ${given_name}."
		
		"Now, shall the three of us sit down to a game?"
	*selectable_if (discretion > 40) #"I think it disgraceful that you would take what is mine without my consent."
		*set independence %+5
		*set withers_rapport %-10
		*set discretion %+15
		*if status > 1
			"I…I cannot apologize enough, ${mr} ${surname}."
			
			"Yes, well, what is done cannot be undone."
			
			"Yes, well, shall the three of us sit down to a game?"
		*else
			"Those are strong words coming from one such as you, ${mr} ${surname}."
			
			"That does not change their validity."
			
			"What is done cannot be undone.  And remember, here, my word is law."
			
			You grit you teeth and bid her an [i]adieu[/i].
	#"I think that, since you have taken something that was mine, you owe me something in return."
		*set discretion %+10
		*set compassion %+5
		
		"What would you have of me?"
		
		*choice
			*if literate = false
				*selectable_if (discretion < 60) #"I would appreciate it if you would teach me how to read."
					*set literate true
					*set withers_rapport %+5
					"Oh!  I think that can be arranged.  Come in the early evenings, I will instruct you myself."
					
					"Very well."  With that, you take your leave.
					
					Over the next year, you work laboriously at learning your letters.  In time, it starts to get easier though.
			*if speaks_english = false
				*selectable_if (discretion < 70) #"I would appreciate it if you would teach me to speak English.  It would certainly make my dealings with the mortals simpler."
					*set speaks_english true
					"Oh!  I think that can be arranged.  Come in the early evenings, I will instruct you myself."
					
					"Very well."  With that, you take your leave.
					
					Over the next year, you work laboriously at learning the tongue of the United States.  In time, it starts to get easier though.
			*if (charm > 1) and (oblivio = false)
				#"I have seen the way in which you dismiss recent memories from your prey. I wish to learn the same."
					*set oblivio true
					*set overstreet_rapport %-5
					"I suppose I can teach you something of that.  The powers of the blood manifest differently for everyone, though."
					
					"So I understand."
					
					"Well, let us begin."

					Over the next six months, you work laboriously at improving your ability to invoke the powers of your blood to sway mortals.  Eventually, you begin to feel confident in your new abilities.
			*if charm = 3
				#"I have seen the way in which you can hold your servants with your gaze.  I wish to learn the same."
					"I suppose I can teach you something of that.  The powers of the blood manifest differently for everyone, though."
					
					"So I understand."
					
					"Well, let us begin."

					*set overstreet_rapport %-5
					*set charm +1
					*achieve witherscharm
					Over the next six months, you work laboriously at improving your ability to invoke the powers of your blood to sway mortals.  Eventually, you begin to feel confident in your new abilities.
			*if status = 0
				#"I think that my lack of standing in the Society is disgraceful.  Perhaps you could better acknowledge the role I play?"
					*set status +1
					*set withers_rapport %+10
					"Of course.  I will make sure that everyone knows what a service you have been to me."

					Withers immediately sets to writing letters to various individuals, extolling your virtues as a member of the Society.
			*if paid_off_wilson
				#"When I released him from my service, I purchased a plot of land for him as recompense.  I expect to be reimbursed for that expense, and then further compensated for the time I spent training him.
					*set wealth +100000
					"Your request is fair.  I shall have the bank draft a note on your behalf."
					
					"Excellent."
					
					"Now, shall the three of us sit down to a game?"
			*else
				#"I think monetary remuneration would be appropriate.  Do you have any idea how much time I spent training him to be such an excellent valet?"
					*set wealth +50000
					"Very well.  I shall have the bank draft a note on your behalf."
					
					"Excellent."
					
					"Now, shall the three of us sit down to a game?"
	*selectable_if (compassion > 40) #"It is no matter.  He was just a servant."
		*set compassion %+5
		*set independence %-10
		*set withers_rapport %+15
		*set overstreet_rapport %+15
		*set shepherd_credentials %-15
	
		Withers seems relieved at your response.  "Now, shall we sit down to a game?"

		The thought of playing cards with your former valet does not please you, but you do your best to hide your annoyance: "It would be good to have another of our kind to play with."

		"Who?  ${wilson}?  Certainly not.  He is not yet fit for company."

		"Forgive me, Quaestor," you say, suddenly in a much better mood.  It seems ${wilson}'s unlife will be rather trying, at least for the next few years anyway.  
		*if withers_rapport < 45
			You can only imagine the misery that comes with being the offspring of Samantha Withers.

*label wilson_flees
*set chasing_wilson true
*set maddox_status "free"
*page_break
*if wilson_embraced
	*temp knows_wilson_went_to_memphis false
	It is with surprise when, a few months later, you discover that ${wilson} has gone missing.  This, of course, is serious business.  As your offspring, he is your responsibility; his crimes are your own.
	*choice
		*if independence < 50
			*selectable_if (discretion > 50) #That ingrate!  Let him go.  I didn't care that much for him anyway.
				*set compassion %+5
				*set discretion %+10
				*set independence %-10
				*goto withers_inquires_about_wilson
		#I seek to discover where he has gone off to.
			*set knows_wilson_went_to_memphis true
			After extensive inquiries, you piece together a trail that leads north.  It seems that ${wilson} booked passage to Memphis.
			*choice
				#I follow him.  It is inappropriate for a young vampire to abandon his dominus in this way.
					*set withers_rapport %+10
					*set overstreet_rapport %+5
					*set introduction_made_to_carothers_by_withers true
					You inform Withers of ${wilson}'s disappearance, and your decision to pursue him.  She commends you for this, and moreover offers to write a letter to the Quaestor of Memphis, Apollo Carothers, to inform him of your impending arrival.
					
					Your goodbyes said, you set out upriver.  Memphis awaits.
					*finish Next
				*selectable_if (discretion > 40) #Let him go.
					*set independence %-5
					*set discretion %+10
					*goto withers_inquires_about_wilson
		#I ask Withers if she has any idea as to what happened to ${wilson}.
			*set independence %+5
			"No, but that is terrible news!  You must find him!"  She is clearly disturbed that you have managed to misplace your offspring.
			
			"Of course, Quaestor.  I shall find him shortly."
			*page_break
			After searching high and low, you eventually determine that ${wilson} booked passage to Memphis.  When you inform Withers of this, she is relieved that he has not been slain.  That said, she makes it clear to you that he is your responsibility, and that you are obliged to find and corral him.
			*if withers_rapport > 40
			
				That said, Withers offers to write to the Quaestor of Memphis, Apollo Carothers, and inform him of your impending arrival.  This is an offer you accept graciously.
				*set introduction_made_to_carothers_by_withers true
			
			Bidding goodbye to Withers and Vicksburg itself, you too book passage to Memphis.
			*finish Next
*else
	Arriving one Tuesday evening at the home of Withers, you are startled to find the house in an uproar.
	
	Once you are finally announced, Withers rushes to your side.  "${mr} ${surname}!  How good of you to come so quickly!  It's ${wilson}—he's gone!"  You received no request for your presence, but that thought is only fleeting as the significance of ${wilson}'s disappearance begins to sink in.
	
	"Gone?"
	
	"Yes, he has gone to Memphis, and he has done so without my consent!"
	
	*if withers_rapport < 35
		"He has?  Fled from your nuturing bosom?  How surprising."  You do not try very hard to conceal your contempt.
	*if (withers_rapport >= 35) and (withers_rapport <= 60)
		"How unfortunate for you," you say, flatly.  After all, she did take him from you.
	*if withers_rapport > 60
		"Oh no!" you exclaim.  The consequences of this for Withers are potentially immense.
	
	"Please, ${mr} ${surname}, you must go and find him for me!"
	
	*choice
		#"It would be my honor, Quaestor Withers."
			*set withers_rapport %+20
			*set overstreet_rapport %+10
			*set independence %+10
			*set compassion %-5
			*set chasing_wilson true
			*set introduction_made_to_carothers_by_withers true
			"I shall write to the Governor immediately, to inform her of the service you render me."
			
			"I will depart for Memphis tomorrow evening."
			
			"Dear ${given_name}, you really are too kind.  But do not go too hastily.  I shall also write a letter to the Quaestor of Memphis, Apollo Carothers, and inform him of your impending arrival."  After a moment's consideration, Withers continues, "${wilson} should be easy enough to find.  He has the annoying tendency to feed too deeply from his prey, and they do not survive the experience.  Just follow the corpses."
			
			You thank Withers for this final bit of intelligence.  After saying your goodbyes, you pack up your things and book passage upriver.  Memphis awaits.
			*finish Next
		#"Of course, I would be happy to do so, Quaestor Withers.  Unfortunately, I had many financial dealings planned over the next few weeks…to go now will mean that I will miss out on them…"
			*set withers_rapport %+5
			*set independence %+5
			*set discretion %+10
			*set compassion %+5
			*set wealth +10000
			*set chasing_wilson true
			*set introduction_made_to_carothers_by_withers true
			"I will compensate you for the lost opportunities, ${mr} ${surname}, have no fear."
			
			"Then I shall depart for Memphis tomorrow evening."
			
			"Dear ${given_name}, you really are too kind.  But do not go too hastily.  I shall write a letter to the Quaestor of Memphis, Apollo Carothers, and inform him of your impending arrival."  After a moment's consideratin, Withers continues, "${wilson} should be easy enough to find.  He has the annoying tendency to feed too deeply from his prey, and they do not survive the experience.  Just follow the corpses."
			
			You thank Withers for this final bit of intelligence.  After saying your goodbyes, you pack up your things and book passage upriver.  Memphis awaits.
			*finish Next
		*if independence < 60
			*selectable_if (discretion > 40) #"Find him yourself.  He is not my responsibility."
				*set chasing_wilson false
				*set withers_rapport %-30
				*set overstreet_rapport %-15
				*set independence %-20
				*set exiled_from_vicksburg true
				*set rejected_sam_wilson true
				*set discretion %+20
				*if wealth > 10000
					*set wealth /2
				*set income /2
				Withers is clearly floored by your flippancy.  She takes a moment to take stock of things before replying.
				
				"${mr} ${surname}, you are hereby exiled from Vicksburg.  You have until dawn to vacate the city, or I shall write to the Governor and demand your execution.  Now, go, before I lose my temper."
				
				Leaving the card game unfinished, you stand and depart.  As you gather your things, you muse that being exiled is no great matter.  It is rather boring here in Vicksburg anyway.
				
				Before dawn breaks, you have arranged for transportation upriver.  Memphis awaits.
				*finish Next

*label withers_inquires_about_wilson

"Where is ${wilson}?  You have not brought him to the past few soirées," Withers says while dealing a hand.
*choice
	#"I don't know.  One evening, he just did not return."
		*set withers_rapport %-15
		*set overstreet_rapport %-10
		*set discretion %+10
		
		"And you have not sought to find him."
		
		"No."
		
		"You do know that he is your responsibility, don't you?"
		
		"Yes."
		
		"Then I suggest you seek him out immediately."
		
		"As you will, quaestor."
		*page_break
		After some inquiries, you discover that ${wilson} booked passage to Memphis.  Gathering your things, you arrange to follow him.  Withers if happy to hear that you have found his trail, but is unwilling to see you before you depart.
		
		She is disappointed with your self-absorption.  But she is rather boring herself, so why should you care?		
		*finish Next
	*if knows_wilson_went_to_memphis
		#"He abandoned me, and fled to Memphis."
			*set withers_rapport %-5
			"And you have not gone after him?"
			
			"No.  Should I have?"
			
			"But of course!  He is your responsibility, after all.  You did create him."
			
			"So?"
			
			"So?  Go and find him!  Now!  If you do not, I shall have to write to the governor, and explain to her how you have abandoned your responsibilities as a dominus."
			
			"Very well."
			*page_break
			You spend the next few nights gathering your things in preparation to depart.  While Withers expresses satisfaction that you have agreed to pursue your errant offspring, she refuses to see you again before you depart.			
			
			It seems that she is disappointed with your self-absorption.  But she is boring, so why should you care?		
			*finish Next
	#"Oh, he's still here.  I just haven't brought him around.  I prefer to have you all to myself."
		*set independence %-5
		*set compassion %+5
		*set withers_rapport %-10
		*if knows_wilson_went_to_memphis
			*set discretion %+10
		Withers's eyes narrow.  "That's funny, because I heard that he had gone to Memphis."
		
		You try to hide your surprise.
		*if knows_wilson_went_to_memphis
			How did she find out so quickly?  It took you some time to piece it together yourself!
		"I had not heard that."
		
		"Perhaps you should go and find him."
		
		"Oh?"
		
		"As your offspring, he is your responsibility.  I really must insist."
		
		"And if I dont?"
		
		"I'm sure the governor would be most intersted to hear how the young dominus abandoned his offspring."
		
		"Then I suppose I should be going."
		
		"Yes.  And please, do not return until you have straightened this matter out."
		
		The next few nights are spent gathering your things and preparing to depart.  Memphis awaits.
		*finish Next