*comment ñáéç
*gosub_scene util combat_value
*advertisement
*gosub_scene util check_flow
*temp calkins_pinned false
*temp character_wounded false
*temp calkins_subdued false
*temp calkins_helped false
*temp guards_dead false
*temp seen_withers false
*temp diablerized_calkins false
*temp bloody_clothes false
*temp calkins_walker false
*temp reason 0
*comment 1863-05-31

Unsurpisingly, the slaves get the worst of the new situation. They are put on work details, building fortifications and digging bombproofs—hovels in the ridges, ostensibly safe from shelling—round the clock. The whole city is on half-rations, but after a week, the slaves are put on quarter rations. Between the lack of food and sleep, the slaves are at their limit.

One evening, you pass a crew digging a ditch. A foreman strikes a young man—no more than fifteen or sixteen—while the rest of the slaves do their best to ignore the fracas. Within moments, the young man is back at work—his eye already swelling shut—and the foreman has moved on to screaming at someone else.

*if pitchforks_in_saintcharles
	*comment 1863-06-02
	*page_break
	The following Tuesday, the three of you gather at the home of Withers, as requested.  Over the game of cards, the subject of your recent departure from St. Charles parish comes up.
	*if speaks_english
		*if ending_saintcharles_rapport = "good"
			*set calkins_rapport %+10
			Withers insists that you relate the story of how your neighbors in the parish chased you from your home with their pitchforks.  She seems to find the whole thing to be a source of endless amusement.
			
			You conclude with your standard expression of exasperation: "I was very kind to the people of the parish.  To this night, I do not understand why they turned against me."
			
			"What did thou expect?  We are vampires," Calkins observes without pausing the playing of his cards.
			
			"I'm sorry?"
			
			"Mortals will always fear us.  Even if they do not understand why.  It is because they are our food, and on some primal level, they know this, even if their conscious mind denies it.  If thou ask me, the best we can do is to help them to make the right choices, and try not to be too surprised when the scorpion tries to sting the frog."
			
			At this, Samantha interjects: "But aren't we the scorpions here, dear Andrew?"
			
			"When it comes to guiding the humans away from their own worse natures, no, we are the frogs."
			
			From there, Samantha drags Andrew into a conversation about the old parable of the scorpion and the frog.  You are only too thankful when it becomes late enough to plead to be excused.
			*goto wasting_disease
		*elseif ending_saintcharles_rapport = "fair"
			*set calkins_rapport %+5
			Withers insists that you relate the story of the citizens of Saint Charles parish chasing you from your home with their pitchforks.  She seems to find the whole thing to be a source of endless amusement.
			
			You conclude with your standard expression of exasperation: "I wasn't malicious towards them.  I certainly didn't cater to their whims, but neither did I terrorize them, as perhaps I should have.  To this night, I do not understand why they turned against me."
			
			"What did thou expect?  We are vampires," Calkins observes without pausing the playing of his cards.
			
			"I'm sorry?"
			
			"Mortals will always fear us.  Even if they do not understand why.  It is because they are our food, and on some primal level, they know this, even if their conscious mind denies it.  If you ask me, the best we can do is to help them to make the right choices, and try not to be too surprised when the scorpion tries to sting the frog."
			
			At this, Samantha interjects: "But aren't we the scorpions here, dear Andrew?"
			
			"When it comes to guiding the humans away from their own worse natures, no, we are the frogs."
			
			From there, Samantha drags Andrew into a conversation about the old parable of the scorpion and the frog.  You are only too thankful when it becomes late enough to plead to be excused.
			*goto wasting_disease
		*else
			Withers insists that you relate the story of the citizens of Saint Charles parish chasing you from your home with their pitchforks.  She seems to find the whole thing to be a source of endless amusement.
			
			*if compassion > 60
				You conclude with your standard expression of exasperation: "And I could have been so much more of a menace than I was; I barely killed any of them!  Sometimes I think I should stop pretending so hard to be what I am not."
				
				You are only too thankful when it becomes late enough to plead to be excused.
				*goto wasting_disease
			*elseif compassion >= 40
				You conclude with your standard expression of exasperation: "And to think that I was not trying to anger them.  It's just that, well, sometimes they had things that I needed."
				
				"And it surprises thou that they would respond with violence?"
				
				"Well…"
				
				"That is why we have the Rule of Reserve.  Because we must remember that we are, in fact, vulnerable to them.  We can't just take what we want, because there will be a reaction."
				
				"Yes!  We must simply encourage them to give us what we want!" interjects Samantha with a laugh.  Andrew rolls his eyes, and the conversation returns to the game at hand.  You are only too thankful when it becomes late enough to plead to be excused.
				*goto wasting_disease
			*else
				You conclude with your standard expression of exasperation: "And to think, I still don't understand how I angered them so.  I certainly did not seek to upset them.  And I just feel horrible about how they misinterpreted my intentions so."
				
				"What did thou expect?  We are vampires," Calkins observes without pausing the playing of his cards.
			
				"I'm sorry?"
				
				"Mortals will always fear us.  Even if they do not understand why.  It is because they are our food, and on some primal level, they know this, even if their conscious mind denies it.  If you ask me, the best we can do is to help them to make the right choices, and try to be too surprised when the scorpion tries to sting the frog."
				
				At this, Samantha interjects: "But aren't we the scorpions here, dear Andrew?"
				
				"When it comes to guiding the humans away from their own worse natures, no, we are the frogs."
				
				From there, Samantha drags Andrew into a conversation about the old parable of the scorpion and the frog.  You are only too thankful when it becomes late enough to plead to be excused.
				*goto wasting_disease
	*else
		Withers insists on relating the story of the citizens of Saint Charles parish, who chased you from your home with their pitchforks.  Calkins wrinkles his forehead at the conclusion of the story, while Samantha inquires what you had expected from the situation.
			
		"Expected?"
		
		"Yes.  They will always hate and fear us, for they are our food.  How can they not?  It is like the scorpion and the frog…" here Samantha gets sidetracked—translating constantly between you and Calkins does nothing to help the situation—and they devolve into an argument about who here is the scorpion, and who the frog.  You are only too thankful when it becomes late enough to plead to be excused.
		*goto wasting_disease

*label wasting_disease
*page_break
By the middle of June, a wasting disease seems to be afflicting the horses of the Confederate cavalry.  They are growing weak, but the army wastes no time in butchering them for their meat.  The city's stores were not made to support so many troops, and many of the soldiers are so hungry that they are willing to risk diseased meat if only their stomachs will stop growling.

Interestingly, while dysentery, scurvy, and malaria has begun to ravage the soldiers, the 'diseased' horsemeat seems to provoke no additional illness.

*if shapeshifting > 0
	Curious, you decide to pay a visit to the horses; maybe they can tell you more.
	
	You head towards the stables.
	*page_break 
	After spending an evening at the stables, you piece together from the horses' descriptions that someone—probably Mr. Calkins—is feeding from them.  It seems that a man comes to them during the night, and then they smell blood, and soon the one that was bled is taken away—and slaughtered.
	*set knows_about_vegetarianism true
	
	@{(feeding_style = "vegetarian") |How strange that a vampire feeds from horses.}
	*page_break 
	
*if (streetwise > 0) or (ethnicity = "scotch")
	Word reaches you through 
	*if streetwise > 0
		what passes for an underground here that someone's been spreading around silver, looking for some rum.  It only takes a few questions put in the right places to identify
	*else
		your fellow Appalachians that someone's been spreading around silver, looking for some rum.  It only takes a few questions to pin 
	Calkins as the culprit.

	Do you want to tell Samantha about this? @{warned_sam_about_calkins Could this have something to do with Calkins's lie?|}
	*choice
		#@{warned_sam_about_calkins I keep her apprised of my investigation.|Yes!}
			*if warned_sam_about_calkins
				*set withers_rapport %+10
				Withers agrees that there is intrigue afoot. But there is not enough rum in the city to render the entire defending army insensate. The two of you muse over the possibilities but come to no conclusions. She asks you to continue your investigations.
			*elseif withers_rapport >=40
				*set withers_rapport %+5
				She appreciates your concern and suggests you keep an eye on him.
			*else
				*set withers_rapport %-5
				She seems to think that you are trying to trick her somehow.  She receives the intelligence icily, and then thanks you for your studiousness.
		#@{warned_sam_about_calkins No, not until I learn more.|No.}
			You're right, it's probably nothing.
		*if (warned_sam_about_calkins = false) #Not yet; I shall keep an ear out before disturbing her unnecessarily.
			*set discretion %-5
			*set independence %+5
			While it is probably nothing, one can never be too sure. You resolve to keep your ears pricked in the hopes of find the truth of the matter.

*if (ethnicity = "african") or ((compassion < 30) and speaks_english)
	*page_break
	"Damn you!" someone cries. This is followed by a thud. You wouldn't have heard it if you weren't so close—the shelling is heavy tonight—but you are, so you do.
	
	Turning a corner, you stumble on the young man and the foreman who was beating him. Only now, the foreman is bleeding out from a wound to the head. The young man—already tall and skinny, now almost emaciated from the limited rations—is holding some sort of spike in his hand.
	
	The young man notices your approach and begins stammering. "I didn' mean…he wuz.…" Tears are streaming down his cheeks. The spike falls to the ground.
	
	"You killed him."
	
	"Maybe…if we find a doctah…"
	
	"No, he's dead."
	
	You can see the boy's spirit disintegrate before your very eyes.
	
	*choice
		*if (choice_randomtest = false) #I kill him. He's already a dead man walking.
			*set compassion %+5
			You drink the young man dry. He offers no resistence.
		#I help him flee the city.
			*set compassion %-5
			*set walker_rapport %+40
			*set met_herbert_walker 2
			"If you flee the city, the Union Army will take you in. You'll probably never be able to come home, but you'll be free."
			
			His eyes light up. "My moms is already gone. I nevah knew my pops. My brothers and sister…I don' even know where I'd start. You point me in the direction, an' I'll go."
			*gosub skewer_guard
		#I offer to help him flee the city…if he can pay.
			*set met_herbert_walker 2
			*set walker_rapport %+10
			*set debt_from_walker true
			"If you flee the city, the Union Army will take you in. You'll probably never be able to come home, but you'll be free."
			
			His eyes light up. "My moms is already gone. I nevah knew my pops. My brothers and sister…I don' even know where I'd start. You point me in the direction, an' I'll go."
			
			"And what would you pay for freedom?"
			
			"I don' have anything to pay you with, @{male suh|mam'selle}."
			
			You ponder a moment. "Life is long. Perhaps we shall cross paths again. You will owe me a debt."
			
			He's clearly skeptical, but absent a better option, he takes it. You shake on it.
			*gosub skewer_guard
*elseif ((ethnicity = "southern") or (ethnicity = "scotch")) or (feeding_style = "soldiers")
	*page_break
	
	Despite the heavy shelling, one colonel is drilling his men even in the darkness.
	
	Shouts of "Forward March!", "Form Up!", "Load!", and "Fire!"—the city may be low on food, but there is a massive amount of weapons and ammunition. Whether from curiosity or gallows humor, you have come to watch this colonel and his drills the past few evenings.
	
	Tonight, however, the Union artillery finds its targets.
	*page_break
	The explosion amid the formation is met with cries of horror. At least two soldiers have been dismembered, while several others are riddled with shrapnel.
	
	The next command from the colonel's mouth is a new one: "Scatter!"
	
	With no enemy to target, all the soldiers can do is drag their wounded to the infirmary and take shelter from the shelling. And they mostly do so.
	
	Another shell lands. The drilling soldiers had already fled that particular spot, but two who were preparing to rescue a wounded man are dissuaded. They break and run.
	
	The colonel dismounts from his horse, preparing to charge into the field.
	*choice
		#I just came for a snack, not to be blown to bits. I help carry the wounded to the infirmary and feed.
			*set discretion %-5
			*set francis_cockrell_resolution 2
			One more dead soldier goes unremarked in the annals of history. You, however, return to your haven flush with your spoils.
		*if (willpower > 1) #I stay and watch this foolhardy colonel.
			The colonel charges into the field. He hefts the wounded man onto his shoulders, and turns to carry him to shelter.
			
			Another shell lands. It is a good distance away, but there is a splatter of blood as the colonel is hit. He staggers.
			*if (compassion < 50) and (discretion > 50)
				You leap into action. Within moments, you are at his side, helping him to his feet and guiding him into shelter. He is clearly in a lot of pain. He doesn't even have time to register that you aren't one of his @{male soldiers.|soldiers, much less a woman.}
				*set exposure +1
				
				"Thank you!" he says, breathless.
				*set francis_cockrell_resolution 4
				
				"You're welcome. That was a brave thing you did."
				
				"A stupid thing, more like it."
				
				Looking over, you see the soldier the colonel saved; from your estimation, he will survive. "Not as far as he's concerned."	

				You turn to leave. You've already drawn too much attention to yourself.
				
				"Wait! Who are you?"
				
				You look back from the doorway. "${given_name}. You?"
				
				"Frank. How can I…"
				
				You wave away his words and disappear into the night.
			*else
				You watch in @{(compassion > 50) fascination|dismay} as this colonel struggles to save the man under his command. With a supreme demonstration of will, he rises to his feet again, and pushes forward. One of his subordinates finally summons the courage to rush into the field to aid him, and the two get the wounded man into shelter.
				
				You wander into the shelter. "That was a brave thing you did," you observe @{(compassion > 50) dryly|admiringly}.
				
				"A stupid thing, more like it."
				
				Looking over, you see the soldier the colonel saved; from your estimation, he will survive. "Not as far as he's concerned."
				
				The colonel huffs. 
				*set francis_cockrell_resolution 3
				
				Realizing that you have no place here, you leave. You later learn the colonel's name: Francis Cockrell. You wonder if your paths will cross again someday.				
		*if ((agility > 2) and (willpower > 1)) #I'm surely faster than this foolish colonel. I pull the wounded man from the field.
			*set discretion %+10
			*set exposure +1
			*set francis_cockrell_resolution 5
			*if male = false
				*set exposure +1
			You dash onto the field. You @{(strength > 2) lift the wounded man onto your soldiers and run for the shelter|grip the wounded soldier by the arms and begin dragging him back to shelter}. You see the colonel ahead of you, holding the door to a bombproof open and gesturing for you to come inside. You struggle forward was more shells explode around you. You begin to wonder if this was not the wisest decision on your part.
			
			But then you're through the door with the wounded man. Suddenly, the colonel lets out a cry of pain. Looking up, there is blood everywhere—and it's coming from the colonel's hand. Something fell on it, perhaps, in his haste to get out of your way? To make room for his subordinate?
			
			Carefully, you inspect the wounded soldier; you suspect that he will live. Standing, you turn and the colonel finally meets your eyes; he's in a lot of pain, but he's finally registering that @{male |not only are} you not one of his @{male soldiers.|soldiers, but a woman.} "Who are you?" he stammers.
			
			Now is really not the time for questions. You begin to move for the door. "${given_name}. You?"
			
			"Frank. How can I…"
				
			"Take care of that," you say, gesturing to his hand. You wave away any further words and push your way outside. Behind you, Frank stands at the door, calling after you as you disappear into the night.
*else
	
	A few nights later, there is an uproar over a murdered foreman. Apparently, a slave killed his supervisor and then escaped on a skiff—with the help of a white man, who stayed behind to distract the guards—across the water to the Union blockade. The heavy shelling helped disguise the intrigue.
	
	Patrols at the docks are tightened further, while the officers are on the watch for anyone who might be sympathetic to the plight of the slaves. A revolt is the last thing they need right now.
	*set calkins_walker true
	
*page_break
It is now Tuesday again, the 16th of June.  The evening bombardment has been comparatively light the past few days; it seems that the Union armies, still encamped around the city, is in need of a resupply.  And while there is no sign of General Johnston, there is a game of bridge that you are expected to attend.  For better or worse, it's a new moon tonight, but that does not prevent you from identifying Calkins as he crosses the street in front of you.  He should be on his way to Withers's haven, but instead he seems to be headed towards the Confederate lines. @{warned_sam_about_calkins Could now be the moment that he reveals himself?|}

It's so dark, it should be easy to follow him…but why are you doing this?
*comment Dan, you say I should put a choice here as to whether or not the player follows Calkins; I strongly disagree.  The reason I disagree is actually something you've said to me on numerous occasions: don't let the player bypass plot.  I appreciate the irony of us being on opposite side of this question here.  That said, if your concern is about the wall-o-text, I'm going to put in a fake choice to break things up a bit.
*choice
	#@{warned_sam_about_calkins Calkins's plot unfolds here and now|Calkins is clearly up to no good}; whatever it is, I intend to stop him.
		*set independence %+10
		*set discretion %+10
	#@{warned_sam_about_calkins Calkins's plot unfolds here and now|Calkins is clearly up to no good}; whatever it is, I can use it to blackmail him.
		*set compassion %+10
	#@{warned_sam_about_calkins Calkins's plot unfolds here and now|Calkins is clearly up to no good}; after I've seen what it is, I can inform Withers of his deeds.
		*set independence %+10
		*set discretion %-10
	#Maybe he's just lost.…
		*set compassion %-5
	#Whatever he's doing, it has to be more interesting than playing cards with Withers.
		*set independence %-10
	*if (stealth > 0) #I just like skulking around in the dark; it helps me hone my powers of Stealth.
		*set discretion %-5
		*set independence %-5

Mustering every trick you ever knew or imagined, you follow Calkins until he reaches the main munitions dump for the Confederate army.  The ammunition, cannonballs, gunpowder and spare firearms are kept here under constant guard.  It is with some surprise that, even from here, you can tell that the two guards at the door of the depot are drunk, barely able to stand on their feet.  
*if (streetwise > 0) or (ethnicity = "scotch")
	It occurs to you that this must have been why Calkins needed that rum.
*else
	Which is strange, for the city has been without rum since the siege began.

When the guards see Calkins, they give a sloppy gesture of greeting; they clearly recognize him.  He nears them, gesturing as he speaks.  With the grace and speed that only professional dancers, fencers, and vampires can muster, Calkins knocks both of the guards unconscious.  Before they can even fall to the ground, it looks like he hooks their coats onto something on the wall, and shortly the two guards are propped up, scarecrows for any human scavengers.

Taking a final look around, Calkins opens the door and slips into the depot.  He's up to something, but what?  You resolve to follow him into the depot.
*page_break
It is with some comfort that you note that Calkins is carrying some sort of small lantern.  It does little to illuminate the inside of the depot, but it does give away his position immediately, as he carries it through the building.  Calkins, by the light of the lantern, seems to be collecting the barrels of gunpowder into a single stack.  Then, with a quick strike of a pick, he drives holes into several of them, allowing them to spill their contents onto the ground around them.  Finally, taking a smaller barrel, he begins drawing a line of gunpowder away from the stack of barrels and towards you and the door.

It seems fairly obvious that he's trying to blow up the depot; if he succeeds, it will seriously damage the defenders' efforts and morale.  This is, moreover, something for which Withers could punish him severely, as this would not qualify as acceptable behavior under the Rule of Respect.

What to do, what to do?
*choice
	#I wait for him to make way, and then I sneak back outside.  Quaestor Withers must know of this immediately!
		*set independence %+5
		*set discretion %-5
		*label take_cover
		*if depot_burned = false
			*set depot_burned true
			*achieve depot
		
		From a vantage point down the street, you take cover and pause to watch the fireworks. @{(calkins_status <= 3) Moments later, the door to the depot opens and then quickly shuts behind Calkins.  Taking in his surroundings, he notices the two guards slumped by the door.  He drags their comatose forms away from the building, finding cover for them just in time.…|With some satisfaction, you see the door suddenly bulge from Calkins trying to open it on the other side.  The first long, slow bulge quickly gives way to a series of quick ones, as Calkins panics with the realization that he is trapped.  For a moment, it looks like the rifles might give way…but only for a moment.}
		
		With a resonant boom, first one and then most of the stacked barrels of gunpowder explode.  The depot is obliterated, and you quickly discover that you were a little too close yourself when the heat wave singes your clothing and eyebrows.  You wisely hunch down in time for another large explosion, and then decide it is time to @{warneD_sam_about_calkins reveal this intrigue to Withers|check in for that game of cards}.
		*goto see_withers
	#I wait for him to make way, and then I sneak back outside.  Then I barricade the door; if he is going to blow up the depot, why not let him blow himself up as well?
		*set calkins_status 4
		*set compassion %+10
		*set discretion %-10
		*set independence %+5
		
		When Calkins has again moved deep into the depot, you open the door and slip outside again.  Taking the rifles from the comatose guards, you jam the heavy door, in the hopes that Calkins will be unable to pry it open in time.
		
		*choice
			#Leave the guards to their fates.
				*set compassion %+20
				*set discretion %-20
				*set guards_dead true
				*goto take_cover
			#Drag the guards away from the building.
				*set compassion %-20
				*set discretion %+10
				*goto take_cover
	#I attempt to jump him; he must not destroy the depot!
		*set discretion %+15
		*set calkins_rapport %-10
		*gosub_scene util combat_value_stealth
		You position yourself as best you can to tackle him without damaging the lantern and putting a quick end to both of your lives.  Calkins circles back towards you, and the moment arrives.
		
		*if combat > 7
			*set calkins_pinned true
			Springing from the darkness, you tackle Calkins, and within moments have him pinned to the ground.
			*choice
				*if (speaks_english) #Interrogate him.
					"I demand to know what is the meaning of this!"
					*goto andrews_soliloquy
				*if (speaks_english = false) #Drag him before Withers.
					*set calkins_subdued true
				#Kill him.
					*gosub kill_calkins_pinned
					*page_break 
				*if (diablerie) #Drink his heartsblood.
					*gosub drain_calkins_intentionally
					*page_break
			*goto see_withers
		*else			
			You leap out of the darkness, but Calkins is too fast for you.  He pivots and uses your momentum to send you flying into a stack of crates.  While you regain your footing, you see Calkins standing over the open gunpowder, lantern in hand.
			*if speaks_english
			
				"What are you trying to accomplish by this, Calkins?" you demand.
				*goto andrews_soliloquy
			*else
				*set depot_burned true
				You look at him soberly.  You will not be able to stop him now.
				
				He drops the lantern and heads for the door.  He leaves it open so you too can escape.
				
				Once outside, you see him trying to drag the guards to safety.
				*choice
					#Help him drag them to safety.
						*set compassion %-5
						You help him drag the guards to safety, just in time for the depot to explode into the night.  The fire raging, you set off for Withers's haven.  It seems that he is following you, or at least going to the same place.
					#Head straight to Withers.
						*set compassion %+5
						*set independence %+5
						Behind you, the depot explodes into the night sky.
				*page_break
				*goto see_withers
	*if (speaks_english) #I address him, demanding to know why he is doing this!
		"Mr. Calkins! I demand to know what is the meaning of this!"
		*goto andrews_soliloquy

*label andrews_soliloquy

With a sigh, Andrew Calkins unburdens his soul: "Do thou not see, ${mr} ${surname}?  Without their munitions, the rebels will not be able to defend the city.  They will surrender within days!"

"But…why do you want that?"

"The Confederacy is a blight upon this earth!  The institution of slavery is an abomination, and must be ended.  Even if I die by lighting this fire, I shall set nearly three thousand souls free.  I think that a noble exchange."

"What are you talking about?"

"The Emancipation Proclamation, ${mr} ${surname}.  All slaves in territories captured from the Confederacy are automatically set free by the Union.  If Vicksburg falls, all the slaves within its borders will become freedmen.  Not to mention the devastation the city's loss will wreak upon the Confederate war effort.  Thou must help me!" @{(perception > 2) Well, that explains how he was lying about the siege being lifted.|}

*if compassion > 40
	*set shepherd_credentials %-5
	"But we are vampires, immortal beings…what care we for such things?"
	
	"Though we may be tormented by God, is our condition so different from that of Job?  No, and like Job I will not curse His name.  When I was alive, I was a Quaker.  In my undeath, I can do naught but serve Him still."

*if ethnicity = "choctaw"
	"This war is not about slavery!  It is about the arrogance of the colonists!  The Confederacy has promised my people both their freedom and their participation in the new government.  The Union pushed us from our homes and slew those who refused to go to make way for their new cities.  With the Confederacy, we will have a place, a voice and a home."
	
	"How can thou trade the enslavement of one people for that of another?"
	
	"Because one is mine, and the other is not."
	
	He looks at you with regret.
*if ethnicity = "southern"
	
	"I cannot speak to your cause.  What I can say, however, is that these are my people whom you dare frustrate, and I will defend them whether they are right or wrong."
*if ((intelligence > 2) and (lore > 1)) and ((ethnicity = "french") or ((ethnicity = "spanish") or ((ethnicity = "irish") or ((ethnicity = "scotch") or (ethnicity = "german")))))
	
	"But slaves have always existed.  Does not Job himself have slaves, before they are slain by pestilence?"
	
	"But that was the Old Testament.  Christ taught us that we are all equal, breaking bread with the prostitutes and the tax collectors.  If you believe in Him, then thou cannot believe in slavery."

*label andrews_soliloquy_choice

*if calkins_walker
	A thought occurs to you. "Did you set that slave free, who killed his foreman? Just the other evening?"
	
	"I did."
	
	"Even though he murdered someone?"
	
	"He was a boy in chains; I cannot blame him for his actions. Now he is free. I hope that he will live a pious life."

What now?
*choice
	*if calkins_pinned
		#Enough of this tripe!  I have him pinned; kill him!
			*gosub kill_calkins_pinned
			*page_break 
			*goto see_withers
		*if (taste_for_vampire_blood) #I will drink his heartsblood!
			*gosub drain_calkins_intentionally
			*page_break
			*goto see_withers
		#Drag him before Withers.  He must answer to her.
			*set calkins_subdued true
			*set calkins_rapport %-10
			*set independence %+20
			You tie Calkins's hands together, and escort him from the depot.
			
			*page_break
			*goto see_withers
	#Let him execute his plan.
		*set calkins_rapport %+30
		Why are you doing this?
		*choice
			*if calkins_pinned = false
				#Because I'm not capable of stopping him.
					*set discretion %-10
					*set reason 1
					*goto let_it_go
			*selectable_if (compassion < 60) #Because slavery is wrong, and the Confederacy should fall.
				*set compassion %-20
				*set reason 2
				*goto let_it_go
			#Because I will relate his deeds to Withers, and she will put an end to his unlife.
				*set independence %+10
				*set discretion %-10
				*set reason 3
				*goto let_it_go
			*if lore > 1
				*selectable_if (compassion > 40) #Because, just as the war is a petty mortal affair, so is destroying this depot.
					*set shepherd_credentials %-15
					*set discretion %-10
					*set compassion %+20
					*set reason 4
					*goto let_it_go
			#Because I want this siege to end quickly and my existence to get back to normal.
				*set discretion %-10
				*set compassion %+10
				*set reason 5
				*goto let_it_go
			*if wrong_side_of_history_argument
				#Silas was right; the Confederacy is on the wrong side of history and it is destined to fail.
					*set anachronism %+10
					*set compassion %-10
					*set reason 6
					*goto let_it_go
	*if calkins_pinned = false
		*if ((choice_randomtest = false) or (combat >= 6)) #Rush him.
			*set calkins_rapport %-10
			*gosub_scene util combat_value
			Doing your best to not alert him to your tensing muscles, you spring at him, trying to knock the lantern away from the exposed gunpowder.
			*if combat > 6
				You manage to knock the lantern away from the gunpowder, and wrestle Calkins to the ground.  He is now pinned beneath you.
				
				*choice
					#Enough of this tripe!  Kill him!
						*gosub kill_calkins_pinned
						*page_break 
						*goto see_withers
					*if (taste_for_vampire_blood) #I drink his heartsblood!
						*gosub drain_calkins_intentionally
						*page_break
						*goto see_withers
					#Drag him before Withers.  He must answer to her.
						*set independence %+20
						*set calkins_subdued true
						You tie Calkins's hands together, and escort him from the depot.
						*page_break
						*goto see_withers
			*else
				*set depot_burned true
				Unfortunately, Calkins senses your movements, and milliseconds before your body impacts with his, the lantern strikes the floor and sets the gunpowder aflame.
				*if (agility > 2) and (strength > 1)
					While your martial skills may be lacking, your speed is not.  Abandoning the slower Calkins, you dash for a window, bursting through it as the first barrel of gunpowder explodes.  You are severely wounded by the subsequent explosions, but you live.
					
					It's a long, painful walk to Withers's card game.
					*page_break 
					*set character_wounded true
					*goto see_withers
				*else
					With an almost beatific smile, Calkins's grip slows you down just enough to make the dash to the door of the depot impossible.  With a rush of air, the gunpowder ignites; you are annihilated.
					*set killed_by_vampire true
					*page_break
					*goto_scene scoring	

*label let_it_go
*if depot_burned = false
	*set depot_burned true
	*achieve depot
*set calkins_helped true

The two of you close the door of the depot behind you.  Calkins gestures for you to grab one of the guards, and you drag them out of harm's way.  Shelter obtained, you turn to watch the explosion as it illuminates the pitch-dark night.

"Thy assistance was most welcomed, ${given_name} ${surname}," Calkins says to you.

"We have a card game to attend, Mr. Calkins," you remind him in return.  "What will you say to Quaestor Withers?"

"I will apologize for my actions.  But I have done a good thing this evening, and I will stand by that."  With that, you adjourn to Withers's haven.

*page_break 
*label see_withers
*set seen_withers true
*temp nyahnyah false

You arrive at Withers's haven shortly.  When you are admitted to her sitting room, you see that she is clearly annoyed that you are so late for the game of bridge.  Or rather, not annoyed, but more distraught.  As though she thought you weren't going to come, and she was about to cry from the rejection. 
*if (discretion >= 65) or (bloody_clothes or character_wounded)
	*goto see_withers_0
*if calkins_subdued or calkins_helped
	*goto see_withers_0
*else
	*choice
		*if diablerized_calkins
				#@{warned_sam_about_calkins "Calkins's plan is revealed—he has burned the depot!" I exclaim…but I will leave|I immediately tell Withers what happened…leaving} out the bit about drinking Calkins' heartsblood.
					*set independence %+10
					*goto see_withers_0
		*if diablerized_calkins = false
			#@{warned_sam_about_calkins "Calkins's plan is revealed—he has burned the depot!"|I immediately tell Withers what happened.}
				*set independence %+15
				*goto see_withers_0
		*if warned_sam_about_calkins
			*if (depot_burned) #"You should have listened to me! Calkins has burnt the depot!"
				*set nyahnyah true
				*set withers_rapport %-10
				*set discretion %+5
				She gasps at your rebuke.
				*goto see_withers_0
			*if (calkins_subdued) #"The infiltrator's plot has been dismantled," you proclaim, throwing Calkins before her.
				*set withers_rapport %+10
				*goto calkins_subdued
		*else
			*if depot_burned
				*if (calkins_status <= 3) and ((calkins_helped = false) and (warned_sam_about_calkins = false))
					#"The munitions depot has been destroyed!  We are lost!"  I will play dumb.
						*set independence %+5
					
						"But, who could be responsible for such a thing?"
						
						"I have no idea!"  
						
						Withers falls into a chair, fanning herself.  "We are lost!" she wails after a moment.
						
						Before you can open your mouth to respond, Calkins is announced.
						
						He strides through the door confidently.
						
						*if speaks_english
							"YOU!  Are you responsible for this?" Withers demands as Calkins approaches.
							
							You can see Calkins deciding on something before he opens his mouth to speak.
							
							"I am, Madame Quaestor.  I blew up the depot. 
							*goto calkins_argument
						*else
							*goto calkins_argument_no_english
				*if (calkins_status > 3) and (warned_sam_about_calkins = false)
					#"The munitions depot has been destroyed!  We are lost!"  I will play dumb; I don't want the death of Calkins to be construed as a violation of the Rule of Restraint.
						*set discretion %-20
						
						"But, who could be responsible for such a thing?"
							
						"I have no idea!"  
						
						Withers falls into a chair, fanning herself.  "We are lost!" she wails after a moment.  You spend most of the rest of the evening attempting to console her.
						
						*page_break
						
						Withers wonders aloud several times over the next few weeks about the sudden disappearance of Andrew Calkins, but you remain tight-lipped.  Each time his name is mentioned, she seems to grow more angry; you suspect that she attributes the explosion to Calkins, and that he subsequently fled the city.
						
						*page_break
						*goto fall_of_vicksburg
			*else
				*if (calkins_status > 3) and (warned_sam_about_calkins = false)
					#I say nothing.  Calkins is dead, the depot still stands.  I make a small excuse for my tardiness, and let the whole matter pass.
						*set independence %-10
				
						"I am tired of waiting.  We shall begin without Mr. Calkins."
						
						"As we should.  Besides, when he partnered with you, he mostly seemed like dead weight."
						
						Withers looks around conspiratorially, before whispering, "He really does, doesn't he?"
						
						*page_break
						
						Withers wonders aloud several more times over the next few weeks about the sudden disappearance of Andrew Calkins, but you remain tight-lipped.  Apparently, she thinks his absence unimportant, as she soon drops the matter altogether.
						
						*page_break 
						*goto fall_of_vicksburg		

*label see_withers_0
*if calkins_status > 3
	*if depot_burned
		*set withers_rapport %-20
		You immediately launch into the tale of your encounter with Calkins at the depot, elaborating on how you locked him in the depot and thereby condemned him to suicide.
		*if withers_rapport >= 40
		
			"Could you not have stopped him, dear ${mr} ${surname}?"
			
			"I regret that I could not.  It was clear that I could not engage him directly, and I did not wish to give him the opportunity to perpetrate any other betrayals on us or the city."
	
			"I suppose you were wise to do so.  But why would he risk himself in such a way?  It makes no sense!"
	
			"I know not, Quaestor Withers.  I know not."
			
			She shakes her head sadly. You take that as your cue to excuse yourself.
	
			*goto fall_of_vicksburg
		*else
	
			"You should have stopped him, you fool!  You let him succeed, and now we are lost!  The whole Confederacy is lost!"
			
			*if nyahnyah or (warned_sam_about_calkins and (discretion > 50))
				"Me? I'm the one who told you that he was lying! You should never have admitted him to the city!"
				
				Withers is stunned by your rebuke. She paces the room angrily, silently chastising herself.
				
				"Leave me. I wish to be alone."
				
				"Very well, quaestor."
				*goto fall_of_vicksburg
	
			"But…Quaestor Withers…"
	
			"SILENCE!  I hereby exile you from Vicksburg, returning only on pain of extermination!  OUT OF MY SIGHT!"  Considering your limited options, you elect to beat a hasty retreat from the irate Quaestor's presence.
			
			*page_break
			*set exiled_from_vicksburg true
			*set withers_rapport %-20
			*goto fall_of_vicksburg
	*else
		*set withers_rapport %+30
		You immediately launch into the tale of your encounter with Calkins at the depot, elaborating on how you stopped him from blowing up the depot but @{bloody_clothes how he refused to come peaceably. You were forced to kill him as a matter of self-defense.|accidentally killed him in the process.}
		
		"While Mr. Calkins's death is regrettable, you have truly done both me and the Confederacy a service this night, ${mr} ${surname}.  I cannot thank you enough."
		
		"It is my pleasure, madame."
		*if warned_sam_about_calkins
		
			"And to think, you tried to warn me about this monster. I should have listened to you, dear ${given_name}."
			
			"I did what I could."

		*if bloody_clothes
			*set withers_rapport %+10
			"Please, there must be something you can change into. It just wouldn't do to force you to play cards in such a state."
			
			"I thank you, Quaestor."
		
			"Think nothing of it, dear ${given_name}. My brave defender! It is unfortuante, though, that we will both need partners for bridge now."
		*if bloody_clothes = false
			"Shall we sit down to our game?" she inquires.  "I suppose we shall both need partners now."
		
		"Really, Mr. Calkins was a drag on you anyway," you rib her with a smirk.
		
		"Yes, perhaps now I shall finally win a hand or two…"
			
		And so the siege wears on…
		*page_break 
		*goto reward
*elseif character_wounded
	*set withers_rapport %+10
	*if nyahnyah
		"How dare you speak to me in this way?" she demands.
		
		You point to your tattered clothes and charred skin. "I have earned my words tonight, quaestor."
		
		She takes a moment before finally asking: "What happened?
		*goto nyahexplain
	*elseif withers_rapport >= 45
		Your tattered clothes and charred skin, however, immediately shift her countenance from distress to dismay.
	
		"What happened to you, dear ${given_name}!"
		*label nyahexplain
	
		"It was Calkins.  He detonated the munitions depot.  I tried to stop him, but I was too slow."
	
		"What!  Why would he do such a thing?"
	
		"To force the city to surrender.  With the munitions destroyed, we are lost!  The city will fall!"
	
		"Oh!  Oh!  Woe is me!  We are lost!  I'm going to faint!"  And with that, Withers crumples onto her handy fainting couch.
		
		*if nyahnyah
			Looking at her on that couch, you have a hard time finding the energy to further remonstrate her for letting Calkins into the city. Instead, you just shake your haad.
	
		When she comes to, she is no less disconsolate.  She inquires after Calkins's well-being, and seems comforted by the news that he died in the explosion as well.
		*goto reward
	*else
		Your tattered clothes and charred skin, however, immediately shift her countenance from distress to fear and suspicion.
	
		"What happened to you, ${mr} ${surname}!"
	
		"It was Calkins.  He detonated the munitions depot.  I tried to stop him, but I was too slow."
	
		"What!  Why would he do such a thing?"
	
		"To force the city to surrender.  With the munitions destroyed, we are lost!  The city will fall!"
	
		"And you could not stop him?"

		"I tried, Quaestor, but I could not stop him.  It may be cold comfort, but he was extinguished in the blast."

		"That is cold comfort, ${mr} ${surname}.  The city will fall, and that due to your failings.  @{warned_sam_about_calkins I warned you that he was lying; now we must live with the consequences.|There is nothing more that can be done.}"
		
		*page_break
		*set overstreet_rapport %-10
		*goto fall_of_vicksburg
*elseif calkins_subdued
	Her expression changes to one of surprise, however, when you bring the restrained Calkins before her.  
	*label calkins_subdued
	*set withers_rapport %+20
	You explain how you discovered Calkins trying to set the depot on fire, but how you also managed to stop him.  Withers is enamoured of your tale of victory, and nearly swoons with delight at your recounting of it.
	
	When you are finished, the moment comes to decide what to do with Mr. Calkins.  Her heart not yet hardened by age, Withers instructs you to lead Calkins to the cliffs above the river, and push him into the water.  Exile, if you will.  She informs Calkins that, if he returns to her city, there will be no more mercy for him.
	
	*if speaks_english
		*set knows_about_shepherds_and_wolves_text true
		You escort Calkins to the bluffs over the river.  The two of you are alone, and he is still bound.  He looks sadly from the river below, and back to you.  "${given_name}, have you ever read the Shepherds and the Wolves?"  
		
		*if overheard_rios_and_krupke
			This text is what Rios and Krupke must have been discussing at the governor's reception in New Orleans.  
		*if shepherds_and_wolves
			"I am familiar with the debate, yes," you reply.

			"You should seek out a copy—read it for yourself—as I think you have some decisions to make about your future."
			
			"There is an actual text?"
			
			"There is."
			*goto calkins_subdued_choice
		*if (shepherds_and_wolves = false) and (lore <= 2)
			*set shepherds_and_wolves true
			*if heard_of_shepherds_and_wolves
				"I have heard the words, but am unclear on their meaning."
				
				"It is simple enough.  At some point, we must all make a choice.  Will we work to lead the humans, or will we be lead?"
				*goto calkins_subdued_choice
			*else
				When you look at him blankly, he continues: "At some point, we must all make a choice.  Will we work to lead the humans, or will we be lead?"
				*goto calkins_subdued_choice
		*else
			*set shepherds_and_wolves true
			"I am familiar with the debate, yes."  The text outlines two approaches to immortality and the treatment of mortals: whether they should be managed and guided, or whether they should be treated as things to be taken from without regard.

			"You should seek out a copy—read it for yourself—as I think you have some decisions to make about your future."	
			*goto calkins_subdued_choice
	*else
		You escort Calkins to the bluffs over the river.  The two of you are alone, and he is still bound.
		*goto calkins_subdued_choice_1
*elseif calkins_helped
	*set withers_rapport %-10
	The arrival of the two of you together does not exactly help things.  It seems that she imagines that the two of you have been having a fine time without her, and she begins to evince jealousy.
	
	At this point, Calkins begins to explain the events of the evening.  When he finishes, Withers turns to you.
	
	"Is this true, ${mr} ${surname}?"
	*if discretion > 45
		*goto reason_calkins_helped
	*else
	
		*choice
			#I stand by my reasons for helping Calkins.
				*goto reason_calkins_helped
			#I lie about my reasons for helping Calkins.
				*set discretion %-10
				*set compassion %+5
				*goto lie_about_reasons
*else
	*set calkins_rapport %-20
	*set withers_rapport %+10
	Trying not to reflect too much on this, you launch into your tale of discovering Calkins and his nefarious plan.  You have only just finished when Mr. Calkins's arrival is announced.  He strides into the room as if nothing has happened.
	
	*if speaks_english
		"My apologies for my tardiness, Quaestor.  Are we ready for a game?"
		
		"Mr. Calkins, I'm afraid I have to ask you about the condition of the weapons depot and that loud explosion I heard not long hence."
		
		"I'm sorry, Quaestor?"
		
		"${mr} ${surname} here was just explaining to me how ${he} witnessed you putting the fire to the depot.  Would you care to explain yourself?"
		
		With a sigh, Calkins begins to speak: "${given_name} ${surname} speaks plainly.  I did set the depot ablaze. 
		*goto calkins_argument
	*else
		*goto calkins_argument_no_english

*label calkins_argument_no_english

Withers screams at Calkins, which stops him dead in his tracks. When she finally calms down enough to form coherent sentences, she interrogates him about the explosion, the responsibility for which he stoically accepts.

"It seems Mr. Calkins here thinks that the war is a danger to the Society, and that the best way to remove the danger is to speed the end of the war.  For that to happen, he is correct that Vicksburg must fall.  He claims that he has acted in the best interests of the Society.  What do you think of this, ${mr} ${surname}?"

*choice
	#Argue for mercy.  There is a logic to his claim.
		*set calkins_rapport %+10
		
		You exhort Withers to hear the wisdom of his position.  Sometimes one must seek extraordinary solutions to extraordinary situations.
		
		"I suppose there is a certain sense to your words, ${mr} ${surname}.  As much as it pains me to admit it, I do wish an end to this abominable war, even if it does mean the fall of the Confederacy.  You are right, ${given_name}, it will be better for all of us if it ends quickly and with a minimum of bloodshed."

		And so the siege goes on…
		*page_break 
		*goto fall_of_vicksburg
	#"I am not wise enough to advise you in this, Madame Quaestor."
		*set calkins_rapport %-10
		*set discretion %-10

		Withers rolls her eyes at your dodge, but then opens her mouth to chide Andrew.  When she is done, she informs you that she has exiled him.  She orders him from her sight.  He says some final words, and then departs.
		
		*page_break
		*goto fall_of_vicksburg
	#Urge that he be given the strictest of punishments.
		*set calkins_status 4

		You wax eloquent on the violation of trust that Mr. Calkins has committed by doing this.  By the time you are finished, you have worked Samantha up into a frothing rage.  
		
		"Seize him!" she exclaims.
	
		As you lay your hands on Calkins, you are somewhat surprised to discover that he does not even resist.  
		
		"${mr} ${surname}, take this abomination to the roof and leave him for the sun."
		
		"Yes, ma'am," you reply.
		
		You lead an unresisting Calkins upstairs.
		*page_break 
		You tie Calkins to the roof.  He offers no more resistance, merely praying with his eyes closed as you see to the strength of the bindings.  That finished, you return downstairs, where Withers is waiting.
		*goto reward
		
*label calkins_argument
It is my opinion that the best thing for the Society is a quick end to the war.  For that to happen, Vicksburg must fall.  If setting that fire brings an end to the war and an end to the danger for those of our kind, then I have acted in its best interests.  If I have violated your grant of succor, then I accept your punishment."
	
Withers raises an eyebrow at you.

*choice
	#Argue for mercy.  There is a logic to his claim.
		*set calkins_rapport %+10
		You exhort Withers to hear the wisdom of his position.  Sometimes one must seek extraordinary solutions to extraordinary situations.
		
		"I suppose there is a certain sense to your words, ${mr} ${surname}.  As much as it pains me to admit it, I do wish an end to this abominable war, even if it does mean the fall of the Confederacy.  You are right, ${given_name}, it will be better for all of us if it ends quickly and with a minimum of bloodshed.
	
		"Mr. Calkins, your methods are questionable, but I suppose I should laud you for your initiative.  That said, I am still of the opinion that you should find yourself a new home once the siege is concluded.  Until then, I imagine that I need not see you again.  Goodnight, Mr. Calkins."  With this curt conclusion, Mr. Calkins finds himself dismissed.
		
		"As you wish, Quaestor," he notes, heading for the door.  There is silence once the door closes behind him.
		
		"Shall we sit down to our game?" she inquires.
		
		And so the siege wears on…
		*page_break 
		*goto fall_of_vicksburg
	#Remain uninvolved.  This is not my affair.
		*set calkins_rapport %-10
		*set discretion %-10
		Withers rolls her eyes at your silence, but then opens her mouth to chide Andrew: "I am disappointed in you, Mr. Calkins.  Perhaps if you had included me in your plans I might have assented to them.  As it is, I am required by our customs to reprimand you.
		
		"Mr. Calkins, you are hereby banished from Vicksburg.  Return on pain of an end to your undeath."  Calkins looks somewhat stricken, but quickly regains his composure.  "As you wish, Quaestor.  I hope that someday you will come to understand what I have accomplished here."
		
		"SILENCE!  Leave now!"
		
		With that, Calkins departs.
		
		*page_break 
		*goto fall_of_vicksburg
	#Urge that he be given the strictest of punishments.
		*set calkins_status 4
		You wax eloquent on the violation of trust that Mr. Calkins has committed by doing this.  By the time you are finished, you have worked Samantha up into a frothing rage.  
		
		"Seize him!" she exclaims.
	
		As you lay your hands on Calkins, you are somewhat surprised to discover that he does not even resist.  "Do with me as thou will, Quaestor.  I am at peace with myself and my God."
		
		"Blasphemy!  There is no God!  How can there be a God where there are vampires! ${mr} ${surname}, take this abomination to the roof and leave him for the sun."
		
		*if priest and (rationalism > 60)
			*set withers_rapport %-10
			"Excuse me, Quaestor, but you are the one who blasphemes. The existence of vampires does not disprove the existence of God."
			
			Withers turns nearly apoplectic. "You choose now to engage me in a theological debate?"
			
			"I cannot abide your denial of God's existence, no."
			
			Withers considers for a moment, and then, relents. "Forgive me, Father. I did not mean to offend you."
			
			You nod.
			
			"Will you please take this ruffian to the roof and leave him for the sun now?"
			
			"With pleasure, Quaestor," you reply.	
		*else
			"Yes, ma'am," you reply.
			
		You lead an unresisting Calkins upstairs.…
		*page_break 
		You tie Calkins to the roof.  He offers no more resistance, merely praying with his eyes closed as you see to the strength of the bindings.  That finished, you return downstairs, where Withers is waiting.
		*goto reward

*label lie_about_reasons

How do you explain yourself?
*choice
	*if reason != 1
		#Because I was not capable of stopping him.
			*set reason 1
			*goto reason_calkins_helped
	*if reason != 2
		#Because slavery is wrong, and the Confederacy should fall.
			*set reason 2
			*goto reason_calkins_helped
	*if reason != 4
		*if lore > 1
			#Because, just as the war is a petty mortal affair, so was destroying this depot.
				*set reason 4
				*goto reason_calkins_helped
	*if reason != 5
		#Because I want this siege to end quickly and my existence to get back to normal.
			*set reason 5
			*goto reason_calkins_helped
	*if reason != 6
		*if wrong_side_of_history_argument
			#Because Silas was right; the Confederacy is on the wrong side of history, and it is doomed to fail.
				*set reason 6
				*goto reason_calkins_helped

*label reason_calkins_helped

*if reason = 1
	*set calkins_rapport %-75
	"It is true, Quaestor Withers. You should know that I wanted to stop him, but he was too strong for me to subdue.  It was either let him succeed or find myself part of that pyre."
	
	Calkins looks shocked at your declaration.  Withers turns with fury on Calkins.  "You have violated the Rule of Respect, and spurned the succor that I extended to you.  I hereby exile you from this city, and know that I will be speaking with Governor Overstreet about the value of your continued existence among our kind.  Now, leave, and do not return."
	
	Calkins exits the room like a somnambulist.
	*set withers_rapport %-30
	*if withers_rapport >= 35
		Withers turns to you: "I suppose we'll both need partners for bridge now."
		*page_break
		*goto fall_of_vicksburg
	*else
		Withers turns to you: "And YOU!  Whether or not Mr. Calkins had any sense in his body or mind I know not, but I now see clearly what sort of creature you are!  Out of my sight!  Out of my city!  Return only upon pain of extinction!"
		*set exiled_from_vicksburg true
		*page_break
		*goto fall_of_vicksburg
*if reason = 2
	*set calkins_rapport %+10
	*set exiled_from_vicksburg true
	*set wealth /2
	*set shepherd_credentials %-20
	*set withers_rapport %-30
	"It is true, Quaestor Withers.  But you must understand, his cause is just.  The Confederacy is predicated on an institution that is cruel and vicious.  Whatever can be done to contribute to its downfall should be undertaken."
	
	Withers's eyes widen in surprise.  "How young and ignorant are you, ${given_name}?  I am afraid that I misjudged you.  Both of you.  It is not our place to meddle in the affairs of mortals, not like this, anyway.  Moreover, slavery is not our concern: all humans are cattle before us.  It makes no difference how they organize themselves."
	
	She pauses a moment before continuing: "I think you both need to leave, right now.  You are hereby exiled from my city.  Do not return."
	*page_break
	You exit Withers's haven immediately.  Calkins attempts to apologize for involving you in this, but you wave him off.  "I made my decision."
	*goto rush_home
*if reason = 3
	*set calkins_status 4
	*set withers_rapport %+10
	"It is true, Quaestor Withers.  But you must understand, this man is insane.  He has been plotting this since he arrived here.  If you ask me, he was probably involved with the sack of Jackson as well!  He must be stopped, before he reveals us to the mortals, and gets us all killed!"
	
	"Then seize him!" she exclaims.
	
	As you lay your hands on Calkins, you are somewhat surprised to discover that he does not even resist.  "Do with me as thou will, Quaestor.  I am at peace with myself and my God."
	
	"Blasphemy!  There is no God!  How can there be a God where there are vampires!  ${mr} ${surname}, take this abomination to the roof and leave him for the sun."
	
	"Yes, ma'am," you reply.
	
	*page_break
	
	You tie Calkins to the roof.  He offers no more resistance, merely praying with his eyes closed as you see to the strength of the bindings.  That finished, you return downstairs, where Withers is waiting.
	*goto reward
*if reason = 4
	*set calkins_rapport %-20
	*set withers_rapport %-10
	*set shepherd_credentials %-10
	"It is true, Quaestor Withers.  But you must understand, what does this meddling matter to us?  Whether the Confederacy wins or loses is of no interest to me.  I didn't help him, but I also didn't bother to stop him."
	
	Withers looks at you askance.  "You just let him do this?"
	
	"Would there have been a better response on my part?  One that would not have threatened a breach of the Rule of Restraint?"  Withers seems flummoxed by this question.  After sputtering a moment, she decides to address the easier concern.
	
	"Mr. Calkins, you are hereby banished from Vicksburg.  Return on pain of an end to your undeath."  Calkins looks somewhat stricken, but quickly regains his composure.  "As you wish, Quaestor.  I hope that some day you will come to understand what I have accomplished here."
	
	"SILENCE!  Leave NOW!"
	
	With that, Calkins departs.
	*page_break 
	*set hasty_exit_from_vicksburg true
	"I am disappointed in you, ${mr} ${surname}.  When the siege is over, I expect your immediate departure.  Do I make myself clear?"
	
	"Yes, ma'am."
	
	"Good.  Now get out of my sight."  At that, you beat a hasty retreat from Withers's haven.
	
	*page_break 
	*goto fall_of_vicksburg
*if reason = 6
	*set withers_rapport %-40
	*set calkins_rapport %+20
	*set overstreet_rapport %-10
	*set discretion %+20
	*set compassion %-20
	*set independence %-20
	*set anachronism %+20
	*if sire_alive and (sire_name != "West")
		*set new_orleans_quaestor_rapport %-10
	*set shepherd_credentials %+20
	*set income /2
	*set wealth /2
	"It is true, Quaestor Withers.  But you must understand something that I was recently told: the Confederacy is on the wrong side of history.  The world has gone and left us behind, but our pride refuses to accept that we are no longer of the present, but rather of a piece with the past.  The sooner we acknowledge and accept this, the sooner we can move forward."
	
	"Your impudence knows no bounds, ${mr} ${surname}."
	
	"I only speak the truth, Madame Quaestor."
	
	"You speak filth and lies.  Go!  Both of you!  Do not ever return, or I shall have you both staked out to greet the sun."
	
	"As you wish, Madame Quaestor," you reply with a ${bow}.  It seems that Samantha Withers too is on the wrong side of history.
	
	Regardless, the two of you beat a hasty retreat from Withers's presence.
	
	*page_break 
	
	"Perhaps we shall meet another day, ${given_name} ${surname}?"
	
	"Yes, perhaps we shall, Mr. Calkins."
	
	"Until then, please know that I am proud to call thee a friend."
	
	*choice
		#"And I you."
			*set calkins_rapport %+5
			@{male You shake hands and watch him retreat|You bid him [i]adieu[/i] and watch as he retreats} into the darkness.
				
			*page_break
			*set exiled_from_vicksburg true
			*goto rush_home
		#"I did not do this for you, Mr. Calkins."
			*set calkins_rapport %-5
			He looks at you with wonder.  "Then whoever brought this about should be honored by thy devotion."
			
			You say nothing in response, biting back tears as you ${bow} your farewell.  You turn and fade into the darkness.
			
			*page_break 
			*set exiled_from_vicksburg true
			*goto rush_home
*else
	*set calkins_rapport %-20
	*set withers_rapport %+10
	*set shepherd_credentials %-20
	"It is true, Quaestor Withers.  But you must understand, Mr. Calkins is right to seek an end to the siege.  While his methods may be unorthodox, we must accept that General Johnston is not coming to relieve us.  As such, the best way to protect ourselves and the Society is to seek an end to the war.  By igniting the depot, Mr. Calkins has given Vicksburg to the Union.  With Vicksburg captured, the Confederacy is split in half.
	
	"Moreover, once the city falls, our lives can begin to return to normal.  The soldiers will mostly leave, and the difficulties with feeding with decrease enormously.  Though unanticipated, Mr. Calkins has provided us with a clear path to survival, and perhaps even to prosperity."
	
	Calkins is clearly disappointed in your position, but can respect the logic in it.  Even Withers seems moved from her former fury.
	
	"I suppose there is a certain sense to your words, ${mr} ${surname}.  As much as it pains me to admit it, I do wish an end to this abominable war, even if it does mean the fall of the Confederacy.  You are right, ${given_name}, it will be better for all of us if it ends quickly and with a minimum of bloodshed.
	
	"Mr. Calkins, your methods are questionable, but I suppose I should laud you for your initiative.  That said, I am still of the opinion that you should find yourself a new home once the siege is concluded.  Until then, I imagine that I need not see you again.  Goodnight, Mr. Calkins."  With this curt conclusion, Mr. Calkins finds himself dismissed.  
	
	"As you wish, Quaestor," he notes, heading for the door.  There is silence once the door closes behind him.
	
	"Shall we sit down to our game?" she inquires.
	
	And so the siege goes on…
	*page_break 
	*goto fall_of_vicksburg

*label calkins_subdued_choice
Your discussion seems at an end.
*label calkins_subdued_choice_1
*choice
	#Kill him.
		*set compassion %+20
		An easy affair, really, considering his fetters and his unwillingness to resist.  At least this way Withers really has no fear of retribution from the maniac.
		*if norestraint = false
			*set norestraint true
			*achieve norestraint
		*if (vampires_consumed > 0) and (discretion > 55)
			*set discretion %+20
			*gosub_scene util diablerie
			*set calkins_status 5
			Though there is an axe at hand, the defenseless Calkins is too much of a temptation for you. You bare your fangs and sink them into his neck, drinking deeply, searching for the nectar that is a vampire's heartsblood. He resists, warning you that you endanger your soul, but you are insensate to his protests.
			
			There it is. The first drops of his liquid soul. His body has become almost dessicated from your draining, but that's when you can finally reach what you're seeking.
			*goto consume_calkins
		*elseif discretion > 65
			*gosub_scene util diablerie
			*set discretion %+20
			*set calkins_status 5
			There is an axe at hand, but a better idea occurs to you.  Instead, you bare your fangs and sink them into his neck, drinking deeply.  He resists, warning you that you endanger your soul, but you are insensate to his protests.
			
			Eventually, you taste something different.  His body has become almost dessicated from your draining, but there is some reserve left…and it is delightful.  
			*label consume_calkins
			You suck harder, consuming every last drop. He exhales one final time—as though he had been holding his breath since he became a vampire—and Andrew Calkins is no more.
			
			You stand and wipe your face. @{(vampires_consumed < 2) That was…different.|}
			
			You leave his dessicated body for the sun to disintegrate and return to Quaestor Withers; she will be happy to know that the problem has been resolved.
			*goto reward
		*elseif shapeshifting > 2
			*set bloody_clothes true
			*set calkins_status 6
			*if wealth > 5000
				*set wealth -1000
			You extend your claws one final time and decapitate Calkins. The spray of blood and gore covers your chest as his head rolls away. His flesh melts from his bones and in moments you find yourself straddling a well-preserved skeleton. The nearby skull—which somehow managed to land upright—stares at you balefully.
			
			You do your best to wipe your face, but you suspect you are only smearing things; you are certain that your clothes are ruined. You return to Withers to inform her that Calkins has been dealt with.
			*goto reward
		*else
			*set calkins_status 6
			Hefting a handy axe, you set about the bloody work of severing his head from his shoulders. His flesh melts from his bones and in moments you find yourself staring at a well-preserved skeleton. The nearby skull—which rolled away once it was separated from the body and yet managed to land upright—stares at you balefully.
			
			With the deed done you simply walk away.  Some may ask about a stray skeleton, but the army beyond the bulwarks will surely be a more pressing concern.
			
			You return to Quaestor Withers, and tell her that Calkins has been dealt with.
			*goto reward
	*if (taste_for_vampire_blood) #Drink him dry.
		*gosub drain_calkins_intentionally
		*goto reward
	#Push him off the bluffs.
		*set compassion %+5
		*set calkins_rapport %-50
		With a shove, you send Calkins falling end over end into the water below.
		
		You return to Quaestor Withers, and tell her that Calkins has been dealt with.
		*goto reward
	#Order him to jump.
		*set calkins_rapport %-10
		You undo the restraints, and order Calkins to leap.  He looks at you one last time, and without another word leaps into the water below.
			
		You return to Quaestor Withers, and tell her that Calkins has been dealt with.
		*set compassion %-5
		*goto reward	
	
*label reward
She thanks you for your service, and lets you know that her broodmate Governor Overstreet will hear of this.
*set overstreet_rapport %+25
*if sire_alive and (sire_name != "West")
	She also says that she will write to your dominus, and let him know how much of a service you have been to her.
	*set new_orleans_quaestor_rapport %+15
*label fall_of_vicksburg

*if depot_burned
	The burning of the depot clearly demoralizes both the troops and the citizens of the city.  An inquest is held, @{guards_dead but absent testimony from incinerated guards, the investigation goes nowhere.  Moreover, no amount of investigating will return the lost bullets, cannonballs, and powder.|and the drunken guards are hanged for their dereliction of duty.  But that does not bring back the lost bullets, cannonballs, and—most importantly—powder.}
	*goto fall_of_vicksburg_1
*else
	The siege continues unabated. As you walk through the streets, you consider how these mortals are so ignorant of the debt they owe you.  You foiled Calkins's plan, and their well-being—such as it is—is entirely owed to you.
	*if compassion < 50
		Though, some part of you does wonder if Calkins was right, and that it would be better for all if Vicksburg were to fall.
	*goto fall_of_vicksburg_1

*label rush_home

You make your way to your haven quickly.  You gather what you can, and instruct ${wilson} to meet you in Memphis after liquidating the rest.  He nods in agreement, and wishes you luck as you leave to find a way through the Confederate lines.
*page_break
	
*label fall_of_vicksburg_1
*page_break
Absent any sign of relief from General Johnston, General Pemberton is forced to write an offer of surrender to General Grant on the 3rd of July, hoping for a merciful response due to the symbolism of the following day.  After some negotiation, Grant agrees to grant the Confederate soldiers parole, and the Union soldiers are admitted to the city on the 4th.

When word reaches President Lincoln of the fall of Vicksburg (and the surrender of Port Hudson on the 9th), he exclaims: "The Father of Waters again goes unvexed to the sea."

The arrival of the Union army more or less liberates the slaves of Vicksburg and the surrounding area.  They gather for a huge celebration on the night of the 6th, the same day the paroled Confederates are sent packing.
*if exiled_from_vicksburg

	Of course, most of this you learn from afar.  Your journey from Vicksburg is fraught with danger, but at this moment, the ferociousness of the wilderness seems nothing compared to the fury of a scorned quaestor.
	*page_break
	*goto_scene memphis_arrival
*elseif hasty_exit_from_vicksburg
	
	Soon after this celebration, you depart for Memphis.  Withers made her desire for your departure clear, and you are obligated to respect her wishes.

	You leave ${wilson} behind to see to the disposition of your things.  He promises to forward them to you when you have established a new haven.
	*page_break
	*goto_scene memphis_arrival
*else
	The Union army garrisons the city, and life resumes a sense of normalcy.  Coinciding with the fall of Vicksburg is the defeat of General Lee at Gettysburg.  Between these two losses, it is clear the Confederacy will not last long.
	
	Over many games of cards, you and Withers do your best to make the most of it.
	*set withers_rapport %+10
	*finish Next

*label drain_calkins_intentionally
*set diablerized_calkins true
*if norestraint = false
	*set norestraint true
	*achieve norestraint
*gosub_scene util diablerie
@{seen_withers An easy affair, really, considering his fetters and his unwillingness to resist.  At least this way Withers really has no fear of retribution from the maniac.|}

Baring your fangs, you sink your teeth into his neck and suck until you taste his heartsblood, and then you suck some more. The taste is delightful, different from that of humans. You suck harder, consuming every last drop. He exhales one final time—as though he had been holding his breath since he became a vampire—and Andrew Calkins is no more.

You stand up and wipe your mouth. @{(vampires_consumed <2) That was…different.|}

*if seen_withers = false
	The thought occurs to you that you are missing a very important card game.
*if seen_withers
	You return to Quaestor Withers, and tell her that Calkins has been dealt with.
*set compassion %+30
*set discretion %+20
*set calkins_status 5
*return

*label kill_calkins_pinned
*set compassion %+20
*set discretion %+5
*if norestraint = false
	*set norestraint true
	*achieve norestraint
*if (vampires_consumed > 0) and ((discretion > 55) and (willpower < 2))
	*gosub_scene util diablerie
	*set calkins_status 4
	Unfortunately, the only tools you have at hand are your fangs. You extend them and then drive them into his neck, biting and tearing. Without even quite intending it, you know what you're seeking: the taste of his heartsblood. It takes several minutes—he cries out in protest, claiming that you endanger your mortal soul—but you are insensate to his cries. There it is again, that delightful taste, different from that of humans.  You suck harder, consuming every last drop.  He exhales one final time—as though he had been holding his breath since he became a vampire—and Andrew Calkins is no more.
	
	You stand up and wipe your mouth.  That was delightful.
	
	Then the thought occurs to you: aren't you missing a very important card game?
	*return
*elseif (discretion > 65) and (willpower < 3)
	*gosub_scene util diablerie
	*set calkins_status 4
	Unfortunately, the only tools you have at hand are your fangs. You extend them and then drive them into his neck, biting and tearing. Without even quite intending it, you don't just bite and tear at his neck, but suck as well.  In fact, soon that's all you're doing.  Suckling at his neck like a newborn piglet on its mother's teat. At some point, Calkins's protests grow more sharp—he says something about your endangering your immortal soul—but you are insensate to his cries. You suck harder, consuming every last drop.  He exhales one final time—as though he had been holding his breath since he became a vampire—and Andrew Calkins is no more.
	
	You stand up and wipe your mouth.  That was delightful.
	
	Then the thought occurs to you: aren't you missing a very important card game?
	*return
*elseif shapeshifting > 2
	*set bloody_clothes true
	*set calkins_status 6
	You extend your claws one final time and decapitate Calkins. The spray of blood and gore covers your chest as his head rolls away. His flesh melts from his bones and in moments you find yourself straddling a well-preserved skeleton. The nearby skull—which somehow managed to land upright—stares at you balefully.
	
	You do your best to wipe your face, but you suspect you are only smearing things. You clothes are ruined and Withers is expecting you.
	*return
*else
	*set bloody_clothes true
	*set calkins_status 5
	You bite at his neck, taking chunks of his flesh into your mouth and then spitting them out.
	*if depot_burned
		This goes on until the only thing left connecting his head to his body is his spine, which your fangs aren't strong enough to sever. At that point you stand and, putting your heel upon his chest, break the spinal column.
	
		You wipe the blood from your face, but your clothes are ruined. And Withers is expecting you.
		*return
	*else
		Eventully, he is too weakened from the loss of blood to put up much more of a fight.  You are then able to fetch his lantern, drag his body to a place that won't ignite the gunpowder, and set him aflame.  He tries to scream as flames ignite his clothes and his unholy skin, but little more than a whisper passes from between his lips.

		The thought occurs to you that you are missing a very important card game.
		*return

*label skewer_guard
On the way to the docks, he introduces himself as Herbert Walker. He was enslaved on a plantation just outside Vicksburg, but his master was away fighting with General Lee; when the Union armies approached, the entire plantation was brought into the city. Arriving at the waterfront, your skulduggery enables you to steal a skiff. You push him off just as a guard catches sight of you.

You turn and, to Herbert's shock, take a bayonet blade to the gut. When you do not falter, the guard goes slack-jawed. You pull the bayonet from your stomach, wrest the gun from his grasp, and skewer him on a post.

The pain is immense. You try to push the thought of it out of your mind. As long as you feed soon, this will only be a distant memory.

As long as you feed soon.
*page_break
Your skirmish with the guard draws the attention of others. You draw them away as best you can while the skiff disappears into the darkness. You just hope Walker isn't shot on sight for being a spy or saboteur.
*return